etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is439(){
 148     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 #f1# Checks whether or not you're running grml
 154 isgrml(){
 155     [[ -f /etc/grml_version ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running a grml cd
 160 isgrmlcd(){
 161     [[ -f /etc/grml_cd ]] && return 0
 162     return 1
 163 }
 164
 165 if isgrml ; then
 166 #f1# Checks whether or not you're running grml-small
 167     isgrmlsmall() {
 168         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 169             return 0
 170         fi
 171         return 1
 172     }
 173 else
 174     isgrmlsmall() { return 1 }
 175 fi
 176
 177 isdarwin(){
 178     [[ $OSTYPE == darwin* ]] && return 0
 179     return 1
 180 }
 181
 182 #f1# are we running within an utf environment?
 183 isutfenv() {
 184     case "$LANG $CHARSET $LANGUAGE" in
 185         *utf*) return 0 ;;
 186         *UTF*) return 0 ;;
 187         *)     return 1 ;;
 188     esac
 189 }
 190
 191 # check for user, if not running as root set $SUDO to sudo
 192 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 193
 194 # change directory to home on first invocation of zsh
 195 # important for rungetty -> autologin
 196 # Thanks go to Bart Schaefer!
 197 isgrml && checkhome() {
 198     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 199         export ALREADY_DID_CD_HOME=$HOME
 200         cd
 201     fi
 202 }
 203
 204 # check for zsh v3.1.7+
 205
 206 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 207      || ${ZSH_VERSION} == 3.<2->.<->*    \
 208      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 209
 210     printf '-!-\n'
 211     printf '-!- In this configuration we try to make use of features, that only\n'
 212     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 213     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 214     printf '-!- advanced features in all supported versions.\n'
 215     printf '-!-\n'
 216     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 217     printf '-!-\n'
 218     printf '-!- While this *may* work, it might as well fail.\n'
 219     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 220     printf '-!-\n'
 221     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 222     printf '-!- If it does today, you'\''ve been lucky.\n'
 223     printf '-!-\n'
 224     printf '-!- Ye been warned!\n'
 225     printf '-!-\n'
 226
 227     function zstyle() { : }
 228 fi
 229
 230 # autoload wrapper - use this one instead of autoload directly
 231 # We need to define this function as early as this, because autoloading
 232 # 'is-at-least()' needs it.
 233 function zrcautoload() {
 234     emulate -L zsh
 235     setopt extended_glob
 236     local fdir ffile
 237     local -i ffound
 238
 239     ffile=$1
 240     (( found = 0 ))
 241     for fdir in ${fpath} ; do
 242         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 243     done
 244
 245     (( ffound == 0 )) && return 1
 246     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 247         autoload -U ${ffile} || return 1
 248     else
 249         autoload ${ffile} || return 1
 250     fi
 251     return 0
 252 }
 253
 254 # Load is-at-least() for more precise version checks Note that this test will
 255 # *always* fail, if the is-at-least function could not be marked for
 256 # autoloading.
 257 zrcautoload is-at-least || is-at-least() { return 1 }
 258
 259 # set some important options (as early as possible)
 260
 261 # append history list to the history file; this is the default but we make sure
 262 # because it's required for share_history.
 263 setopt append_history
 264
 265 # import new commands from the history file also in other zsh-session
 266 is4 && setopt share_history
 267
 268 # save each command's beginning timestamp and the duration to the history file
 269 setopt extended_history
 270
 271 # If a new command line being added to the history list duplicates an older
 272 # one, the older command is removed from the list
 273 is4 && setopt histignorealldups
 274
 275 # remove command lines from the history list when the first character on the
 276 # line is a space
 277 setopt histignorespace
 278
 279 # if a command is issued that can't be executed as a normal command, and the
 280 # command is the name of a directory, perform the cd command to that directory.
 281 setopt auto_cd
 282
 283 # in order to use #, ~ and ^ for filename generation grep word
 284 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 285 # don't forget to quote '^', '~' and '#'!
 286 setopt extended_glob
 287
 288 # display PID when suspending processes as well
 289 setopt longlistjobs
 290
 291 # try to avoid the 'zsh: no matches found...'
 292 setopt nonomatch
 293
 294 # report the status of backgrounds jobs immediately
 295 setopt notify
 296
 297 # whenever a command completion is attempted, make sure the entire command path
 298 # is hashed first.
 299 setopt hash_list_all
 300
 301 # not just at the end
 302 setopt completeinword
 303
 304 # Don't send SIGHUP to background processes when the shell exits.
 305 setopt nohup
 306
 307 # make cd push the old directory onto the directory stack.
 308 setopt auto_pushd
 309
 310 # avoid "beep"ing
 311 setopt nobeep
 312
 313 # don't push the same dir twice.
 314 setopt pushd_ignore_dups
 315
 316 # * shouldn't match dotfiles. ever.
 317 setopt noglobdots
 318
 319 # use zsh style word splitting
 320 setopt noshwordsplit
 321
 322 # don't error out when unset parameters are used
 323 setopt unset
 324
 325 # setting some default values
 326 NOCOR=${NOCOR:-0}
 327 NOMENU=${NOMENU:-0}
 328 NOPRECMD=${NOPRECMD:-0}
 329 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 330 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 331 BATTERY=${BATTERY:-0}
 332 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 333 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 334
 335 typeset -ga ls_options
 336 typeset -ga grep_options
 337 if ls --help 2> /dev/null | grep -q GNU; then
 338     ls_options=( --color=auto )
 339 elif [[ $OSTYPE == freebsd* ]]; then
 340     ls_options=( -G )
 341 fi
 342 if grep --help 2> /dev/null | grep -q GNU || \
 343    [[ $OSTYPE == freebsd* ]]; then
 344     grep_options=( --color=auto )
 345 fi
 346
 347 # utility functions
 348 # this function checks if a command exists and returns either true
 349 # or false. This avoids using 'which' and 'whence', which will
 350 # avoid problems with aliases for which on certain weird systems. :-)
 351 # Usage: check_com [-c|-g] word
 352 #   -c  only checks for external commands
 353 #   -g  does the usual tests and also checks for global aliases
 354 check_com() {
 355     emulate -L zsh
 356     local -i comonly gatoo
 357
 358     if [[ $1 == '-c' ]] ; then
 359         (( comonly = 1 ))
 360         shift
 361     elif [[ $1 == '-g' ]] ; then
 362         (( gatoo = 1 ))
 363     else
 364         (( comonly = 0 ))
 365         (( gatoo = 0 ))
 366     fi
 367
 368     if (( ${#argv} != 1 )) ; then
 369         printf 'usage: check_com [-c] <command>\n' >&2
 370         return 1
 371     fi
 372
 373     if (( comonly > 0 )) ; then
 374         [[ -n ${commands[$1]}  ]] && return 0
 375         return 1
 376     fi
 377
 378     if   [[ -n ${commands[$1]}    ]] \
 379       || [[ -n ${functions[$1]}   ]] \
 380       || [[ -n ${aliases[$1]}     ]] \
 381       || [[ -n ${reswords[(r)$1]} ]] ; then
 382
 383         return 0
 384     fi
 385
 386     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 387         return 0
 388     fi
 389
 390     return 1
 391 }
 392
 393 # creates an alias and precedes the command with
 394 # sudo if $EUID is not zero.
 395 salias() {
 396     emulate -L zsh
 397     local only=0 ; local multi=0
 398     while [[ $1 == -* ]] ; do
 399         case $1 in
 400             (-o) only=1 ;;
 401             (-a) multi=1 ;;
 402             (--) shift ; break ;;
 403             (-h)
 404                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 405                 printf '  -h      shows this help text.\n'
 406                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 407                 printf '          be careful using this option.\n'
 408                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 409                 return 0
 410                 ;;
 411             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 412         esac
 413         shift
 414     done
 415
 416     if (( ${#argv} > 1 )) ; then
 417         printf 'Too many arguments %s\n' "${#argv}"
 418         return 1
 419     fi
 420
 421     key="${1%%\=*}" ;  val="${1#*\=}"
 422     if (( EUID == 0 )) && (( only == 0 )); then
 423         alias -- "${key}=${val}"
 424     elif (( EUID > 0 )) ; then
 425         (( multi > 0 )) && val="${val// ; / ; sudo }"
 426         alias -- "${key}=sudo ${val}"
 427     fi
 428
 429     return 0
 430 }
 431
 432 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 433 # usage: uprint foo
 434 #   Where foo is the *name* of the parameter you want printed.
 435 #   Note that foo is no typo; $foo would be wrong here!
 436 if ! is42 ; then
 437     uprint () {
 438         emulate -L zsh
 439         local -a u
 440         local w
 441         local parameter=$1
 442
 443         if [[ -z ${parameter} ]] ; then
 444             printf 'usage: uprint <parameter>\n'
 445             return 1
 446         fi
 447
 448         for w in ${(P)parameter} ; do
 449             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 450         done
 451
 452         builtin print -l $u
 453     }
 454 fi
 455
 456 # Check if we can read given files and source those we can.
 457 xsource() {
 458     if (( ${#argv} < 1 )) ; then
 459         printf 'usage: xsource FILE(s)...\n' >&2
 460         return 1
 461     fi
 462
 463     while (( ${#argv} > 0 )) ; do
 464         [[ -r "$1" ]] && source "$1"
 465         shift
 466     done
 467     return 0
 468 }
 469
 470 # Check if we can read a given file and 'cat(1)' it.
 471 xcat() {
 472     emulate -L zsh
 473     if (( ${#argv} != 1 )) ; then
 474         printf 'usage: xcat FILE\n' >&2
 475         return 1
 476     fi
 477
 478     [[ -r $1 ]] && cat $1
 479     return 0
 480 }
 481
 482 # Remove these functions again, they are of use only in these
 483 # setup files. This should be called at the end of .zshrc.
 484 xunfunction() {
 485     emulate -L zsh
 486     local -a funcs
 487     funcs=(salias xcat xsource xunfunction zrcautoload)
 488
 489     for func in $funcs ; do
 490         [[ -n ${functions[$func]} ]] \
 491             && unfunction $func
 492     done
 493     return 0
 494 }
 495
 496 # this allows us to stay in sync with grml's zshrc and put own
 497 # modifications in ~/.zshrc.local
 498 zrclocal() {
 499     xsource "/etc/zsh/zshrc.local"
 500     xsource "${HOME}/.zshrc.local"
 501     return 0
 502 }
 503
 504 # locale setup
 505 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 506     xsource "/etc/default/locale"
 507 fi
 508
 509 for var in LANG LC_ALL LC_MESSAGES ; do
 510     [[ -n ${(P)var} ]] && export $var
 511 done
 512
 513 xsource "/etc/sysconfig/keyboard"
 514
 515 TZ=$(xcat /etc/timezone)
 516
 517 # set some variables
 518 if check_com -c vim ; then
 519 #v#
 520     export EDITOR=${EDITOR:-vim}
 521 else
 522     export EDITOR=${EDITOR:-vi}
 523 fi
 524
 525 #v#
 526 export PAGER=${PAGER:-less}
 527
 528 #v#
 529 export MAIL=${MAIL:-/var/mail/$USER}
 530
 531 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 532 export SHELL='/bin/zsh'
 533
 534 # color setup for ls:
 535 check_com -c dircolors && eval $(dircolors -b)
 536 # color setup for ls on OS X:
 537 isdarwin && export CLICOLOR=1
 538
 539 # do MacPorts setup on darwin
 540 if isdarwin && [[ -d /opt/local ]]; then
 541     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 542     # zshenv.
 543     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 544     MANPATH="/opt/local/share/man:$MANPATH"
 545 fi
 546 # do Fink setup on darwin
 547 isdarwin && xsource /sw/bin/init.sh
 548
 549 # load our function and completion directories
 550 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 551     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 552     if [[ ${fpath} == '/usr/share/grml/zsh/functions' ]] ; then
 553         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 554             zrcautoload ${func:t}
 555         done
 556     fi
 557 done
 558 unset fdir func
 559
 560 # support colors in less
 561 export LESS_TERMCAP_mb=$'\E[01;31m'
 562 export LESS_TERMCAP_md=$'\E[01;31m'
 563 export LESS_TERMCAP_me=$'\E[0m'
 564 export LESS_TERMCAP_se=$'\E[0m'
 565 export LESS_TERMCAP_so=$'\E[01;44;33m'
 566 export LESS_TERMCAP_ue=$'\E[0m'
 567 export LESS_TERMCAP_us=$'\E[01;32m'
 568
 569 # mailchecks
 570 MAILCHECK=30
 571
 572 # report about cpu-/system-/user-time of command if running longer than
 573 # 5 seconds
 574 REPORTTIME=5
 575
 576 # watch for everyone but me and root
 577 watch=(notme root)
 578
 579 # automatically remove duplicates from these arrays
 580 typeset -U path cdpath fpath manpath
 581
 582 # keybindings
 583 if [[ "$TERM" != emacs ]] ; then
 584     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 585     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 586     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 587     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 588     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 589     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 590     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 591     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 592     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 593     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 594     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 595     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 596     # ncurses stuff:
 597     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 598     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 599     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 600     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 601     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 602     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 603     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 604     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 605 fi
 606
 607 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 608 # use emacs style per default:
 609 bindkey -e
 610 # use vi style:
 611 # bindkey -v
 612
 613 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 614 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 615 beginning-or-end-of-somewhere() {
 616     local hno=$HISTNO
 617     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 618       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 619         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 620     else
 621         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 622         if (( HISTNO != hno )); then
 623             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 624         fi
 625     fi
 626 }
 627 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 628 zle -N end-of-somewhere beginning-or-end-of-somewhere
 629
 630
 631 #if [[ "$TERM" == screen ]] ; then
 632
 633 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 634 ## to beginning/end of buffer on second keypress
 635 ## and to beginning/end of history on (at most) the third keypress
 636 # terminator & non-debian xterm
 637 bindkey '\eOH' beginning-of-somewhere  # home
 638 bindkey '\eOF' end-of-somewhere        # end
 639 # freebsd console
 640 bindkey '\e[H' beginning-of-somewhere   # home
 641 bindkey '\e[F' end-of-somewhere         # end
 642 # xterm,gnome-terminal,quake,etc
 643 bindkey '^[[1~' beginning-of-somewhere  # home
 644 bindkey '^[[4~' end-of-somewhere        # end
 645 # if terminal type is set to 'rxvt':
 646 bindkey '\e[7~' beginning-of-somewhere  # home
 647 bindkey '\e[8~' end-of-somewhere        # end
 648 #fi
 649
 650 bindkey '\e[A'  up-line-or-search       # cursor up
 651 bindkey '\e[B'  down-line-or-search     # <ESC>-
 652
 653 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 654 bindkey "\e[5C" forward-word
 655 bindkey "\e[5D" backward-word
 656 bindkey "\e[1;5C" forward-word
 657 bindkey "\e[1;5D" backward-word
 658 ## the same for alt-left-arrow and alt-right-arrow
 659 bindkey '^[[1;3C' forward-word
 660 bindkey '^[[1;3D' backward-word
 661
 662 # Search backward in the history for a line beginning with the current
 663 # line up to the cursor and move the cursor to the end of the line then
 664 zle -N history-beginning-search-backward-end history-search-end
 665 zle -N history-beginning-search-forward-end  history-search-end
 666 #k# search history backward for entry beginning with typed text
 667 bindkey '^xp'   history-beginning-search-backward-end
 668 #k# search history forward for entry beginning with typed text
 669 bindkey '^xP'   history-beginning-search-forward-end
 670 #k# search history backward for entry beginning with typed text
 671 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 672 #k# search history forward for entry beginning with typed text
 673 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 674
 675 # bindkey -s '^l' "|less\n"             # ctrl-L pipes to less
 676 # bindkey -s '^b' " &\n"                # ctrl-B runs it in the background
 677
 678 # insert unicode character
 679 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 680 # See for example http://unicode.org/charts/ for unicode characters code
 681 zrcautoload insert-unicode-char
 682 zle -N insert-unicode-char
 683 #k# Insert Unicode character
 684 bindkey '^xi' insert-unicode-char
 685
 686 #m# k Shift-tab Perform backwards menu completion
 687 if [[ -n "$terminfo[kcbt]" ]]; then
 688     bindkey "$terminfo[kcbt]" reverse-menu-complete
 689 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 690     bindkey "$terminfo[cbt]"  reverse-menu-complete
 691 fi
 692
 693 ## toggle the ,. abbreviation feature on/off
 694 # NOABBREVIATION: default abbreviation-state
 695 #                 0 - enabled (default)
 696 #                 1 - disabled
 697 NOABBREVIATION=${NOABBREVIATION:-0}
 698
 699 grml_toggle_abbrev() {
 700     if (( ${NOABBREVIATION} > 0 )) ; then
 701         NOABBREVIATION=0
 702     else
 703         NOABBREVIATION=1
 704     fi
 705 }
 706
 707 #k# Toggle abbreviation expansion on/off
 708 zle -N grml_toggle_abbrev
 709 bindkey '^xA' grml_toggle_abbrev
 710
 711 # add a command line to the shells history without executing it
 712 commit-to-history() {
 713     print -s ${(z)BUFFER}
 714     zle send-break
 715 }
 716 zle -N commit-to-history
 717 bindkey "^x^h" commit-to-history
 718
 719 # only slash should be considered as a word separator:
 720 slash-backward-kill-word() {
 721     local WORDCHARS="${WORDCHARS:s@/@}"
 722     # zle backward-word
 723     zle backward-kill-word
 724 }
 725 zle -N slash-backward-kill-word
 726
 727 #k# Kill left-side word or everything up to next slash
 728 bindkey '\ev' slash-backward-kill-word
 729 #k# Kill left-side word or everything up to next slash
 730 bindkey '\e^h' slash-backward-kill-word
 731 #k# Kill left-side word or everything up to next slash
 732 bindkey '\e^?' slash-backward-kill-word
 733
 734 # use the new *-pattern-* widgets for incremental history search
 735 if is439 ; then
 736     bindkey '^r' history-incremental-pattern-search-backward
 737     bindkey '^s' history-incremental-pattern-search-forward
 738 fi
 739
 740 # a generic accept-line wrapper
 741
 742 # This widget can prevent unwanted autocorrections from command-name
 743 # to _command-name, rehash automatically on enter and call any number
 744 # of builtin and user-defined widgets in different contexts.
 745 #
 746 # For a broader description, see:
 747 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 748 #
 749 # The code is imported from the file 'zsh/functions/accept-line' from
 750 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 751 # distributed under the same terms as zsh itself.
 752
 753 # A newly added command will may not be found or will cause false
 754 # correction attempts, if you got auto-correction set. By setting the
 755 # following style, we force accept-line() to rehash, if it cannot
 756 # find the first word on the command line in the $command[] hash.
 757 zstyle ':acceptline:*' rehash true
 758
 759 function Accept-Line() {
 760     setopt localoptions noksharrays
 761     local -a subs
 762     local -xi aldone
 763     local sub
 764     local alcontext=${1:-$alcontext}
 765
 766     zstyle -a ":acceptline:${alcontext}" actions subs
 767
 768     (( ${#subs} < 1 )) && return 0
 769
 770     (( aldone = 0 ))
 771     for sub in ${subs} ; do
 772         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 773         zle ${sub}
 774
 775         (( aldone > 0 )) && break
 776     done
 777 }
 778
 779 function Accept-Line-getdefault() {
 780     emulate -L zsh
 781     local default_action
 782
 783     zstyle -s ":acceptline:${alcontext}" default_action default_action
 784     case ${default_action} in
 785         ((accept-line|))
 786             printf ".accept-line"
 787             ;;
 788         (*)
 789             printf ${default_action}
 790             ;;
 791     esac
 792 }
 793
 794 function Accept-Line-HandleContext() {
 795     zle Accept-Line
 796
 797     default_action=$(Accept-Line-getdefault)
 798     zstyle -T ":acceptline:${alcontext}" call_default \
 799         && zle ${default_action}
 800 }
 801
 802 function accept-line() {
 803     setopt localoptions noksharrays
 804     local -ax cmdline
 805     local -x alcontext
 806     local buf com fname format msg default_action
 807
 808     alcontext='default'
 809     buf="${BUFFER}"
 810     cmdline=(${(z)BUFFER})
 811     com="${cmdline[1]}"
 812     fname="_${com}"
 813
 814     Accept-Line 'preprocess'
 815
 816     zstyle -t ":acceptline:${alcontext}" rehash \
 817         && [[ -z ${commands[$com]} ]]           \
 818         && rehash
 819
 820     if    [[ -n ${com}               ]] \
 821        && [[ -n ${reswords[(r)$com]} ]] \
 822        || [[ -n ${aliases[$com]}     ]] \
 823        || [[ -n ${functions[$com]}   ]] \
 824        || [[ -n ${builtins[$com]}    ]] \
 825        || [[ -n ${commands[$com]}    ]] ; then
 826
 827         # there is something sensible to execute, just do it.
 828         alcontext='normal'
 829         Accept-Line-HandleContext
 830
 831         return
 832     fi
 833
 834     if    [[ -o correct              ]] \
 835        || [[ -o correctall           ]] \
 836        && [[ -n ${functions[$fname]} ]] ; then
 837
 838         # nothing there to execute but there is a function called
 839         # _command_name; a completion widget. Makes no sense to
 840         # call it on the commandline, but the correct{,all} options
 841         # will ask for it nevertheless, so warn the user.
 842         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 843             # Okay, we warned the user before, he called us again,
 844             # so have it his way.
 845             alcontext='force'
 846             Accept-Line-HandleContext
 847
 848             return
 849         fi
 850
 851         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 852             alcontext='normal'
 853             Accept-Line-HandleContext
 854         else
 855             # prepare warning message for the user, configurable via zstyle.
 856             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 857
 858             if [[ -z ${msg} ]] ; then
 859                 msg="%c will not execute and completion %f exists."
 860             fi
 861
 862             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 863
 864             zle -M -- "${msg}"
 865         fi
 866         return
 867     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 868         # If we are here, the commandline contains something that is not
 869         # executable, which is neither subject to _command_name correction
 870         # and is not empty. might be a variable assignment
 871         alcontext='misc'
 872         Accept-Line-HandleContext
 873
 874         return
 875     fi
 876
 877     # If we got this far, the commandline only contains whitespace, or is empty.
 878     alcontext='empty'
 879     Accept-Line-HandleContext
 880 }
 881
 882 zle -N accept-line
 883 zle -N Accept-Line
 884 zle -N Accept-Line-HandleContext
 885
 886 # power completion - abbreviation expansion
 887 # power completion / abbreviation expansion / buffer expansion
 888 # see http://zshwiki.org/home/examples/zleiab for details
 889 # less risky than the global aliases but powerful as well
 890 # just type the abbreviation key and afterwards ',.' to expand it
 891 declare -A abk
 892 setopt extendedglob
 893 setopt interactivecomments
 894 abk=(
 895 #   key   # value                  (#d additional doc string)
 896 #A# start
 897     '...'  '../..'
 898     '....' '../../..'
 899     'BG'   '& exit'
 900     'C'    '| wc -l'
 901     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
 902     'H'    '| head'
 903     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 904     'L'    '| less'
 905     'LL'   '|& less -r'
 906     'M'    '| most'
 907     'N'    '&>/dev/null'           #d (No Output)
 908     'R'    '| tr A-z N-za-m'       #d (ROT13)
 909     'SL'   '| sort | less'
 910     'S'    '| sort -u'
 911     'T'    '| tail'
 912     'V'    '|& vim -'
 913 #A# end
 914     'co'   './configure && make && sudo make install'
 915 )
 916
 917 zleiab() {
 918     emulate -L zsh
 919     setopt extendedglob
 920     local MATCH
 921
 922     if (( NOABBREVIATION > 0 )) ; then
 923         LBUFFER="${LBUFFER},."
 924         return 0
 925     fi
 926
 927     matched_chars='[.-|_a-zA-Z0-9]#'
 928     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 929     LBUFFER+=${abk[$MATCH]:-$MATCH}
 930 }
 931
 932 zle -N zleiab && bindkey ",." zleiab
 933
 934 #f# display contents of assoc array $abk
 935 help-show-abk()
 936 {
 937   zle -M "$(print "Type ,. after these abbreviations to expand them:"; print -a -C 2 ${(kv)abk})"
 938 }
 939 #k# Display list of abbreviations that expand when followed by ,.
 940 zle -N help-show-abk && bindkey '^xb' help-show-abk
 941
 942 # autoloading
 943 zrcautoload zmv    # who needs mmv or rename?
 944 zrcautoload history-search-end
 945
 946 # we don't want to quote/espace URLs on our own...
 947 # if autoload -U url-quote-magic ; then
 948 #    zle -N self-insert url-quote-magic
 949 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 950 # else
 951 #    print 'Notice: no url-quote-magic available :('
 952 # fi
 953 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 954
 955 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 956 alias run-help >&/dev/null && unalias run-help
 957 for rh in run-help{,-git,-svk,-svn}; do
 958     zrcautoload $rh
 959 done; unset rh
 960
 961 # completion system
 962 if zrcautoload compinit ; then
 963     compinit || print 'Notice: no compinit available :('
 964 else
 965     print 'Notice: no compinit available :('
 966     function zstyle { }
 967     function compdef { }
 968 fi
 969
 970 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 971
 972 is4 && \
 973 for mod in complist deltochar mathfunc ; do
 974     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 975 done
 976
 977 # autoload zsh modules when they are referenced
 978 if is4 ; then
 979     zmodload -a  zsh/stat    zstat
 980     zmodload -a  zsh/zpty    zpty
 981     zmodload -ap zsh/mapfile mapfile
 982 fi
 983
 984 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 985     #k# Insert files and test globbing
 986     bindkey "^xf" insert-files # C-x-f
 987 fi
 988
 989 bindkey ' '   magic-space    # also do history expansion on space
 990 #k# Trigger menu-complete
 991 bindkey '\ei' menu-complete  # menu completion via esc-i
 992
 993 # press esc-e for editing command line in $EDITOR or $VISUAL
 994 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 995     #k# Edit the current line in \kbd{\$EDITOR}
 996     bindkey '\ee' edit-command-line
 997 fi
 998
 999 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
1000     #k# menu selection: pick item but stay in the menu
1001     bindkey -M menuselect '\e^M' accept-and-menu-complete
1002     # also use + and INSERT since it's easier to press repeatedly
1003     bindkey -M menuselect "+" accept-and-menu-complete
1004     bindkey -M menuselect "^[[2~" accept-and-menu-complete
1005
1006     # accept a completion and try to complete again by using menu
1007     # completion; very useful with completing directories
1008     # by using 'undo' one's got a simple file browser
1009     bindkey -M menuselect '^o' accept-and-infer-next-history
1010 fi
1011
1012 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1013 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1014 zle -N insert-datestamp
1015
1016 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1017 bindkey '^ed' insert-datestamp
1018
1019 # press esc-m for inserting last typed word again (thanks to caphuso!)
1020 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1021 zle -N insert-last-typed-word;
1022
1023 #k# Insert last typed word
1024 bindkey "\em" insert-last-typed-word
1025
1026 function grml-zsh-fg() {
1027   if (( ${#jobstates} )); then
1028     zle .push-input
1029     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1030     BUFFER="${BUFFER}fg"
1031     zle .accept-line
1032   else
1033     zle -M 'No background jobs. Doing nothing.'
1034   fi
1035 }
1036 zle -N grml-zsh-fg
1037 #k# A smart shortcut for \kbd{fg<enter>}
1038 bindkey '^z' grml-zsh-fg
1039
1040 # run command line as user root via sudo:
1041 sudo-command-line() {
1042     [[ -z $BUFFER ]] && zle up-history
1043     if [[ $BUFFER != sudo\ * ]]; then
1044         BUFFER="sudo $BUFFER"
1045         CURSOR=$(( CURSOR+5 ))
1046     fi
1047 }
1048 zle -N sudo-command-line
1049
1050 #k# prepend the current command with "sudo"
1051 bindkey "^os" sudo-command-line
1052
1053 ### jump behind the first word on the cmdline.
1054 ### useful to add options.
1055 function jump_after_first_word() {
1056     local words
1057     words=(${(z)BUFFER})
1058
1059     if (( ${#words} <= 1 )) ; then
1060         CURSOR=${#BUFFER}
1061     else
1062         CURSOR=${#${words[1]}}
1063     fi
1064 }
1065 zle -N jump_after_first_word
1066 #k# jump to after first word (for adding options)
1067 bindkey '^x1' jump_after_first_word
1068
1069 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1070 zle -C hist-complete complete-word _generic
1071 zstyle ':completion:hist-complete:*' completer _history
1072 #k# complete word from history with menu
1073 bindkey "^x^x" hist-complete
1074
1075 ## complete word from currently visible Screen or Tmux buffer.
1076 if check_com -c screen || check_com -c tmux; then
1077     _complete_screen_display() {
1078         [[ "$TERM" != "screen" ]] && return 1
1079
1080         local TMPFILE=$(mktemp)
1081         local -U -a _screen_display_wordlist
1082         trap "rm -f $TMPFILE" EXIT
1083
1084         # fill array with contents from screen hardcopy
1085         if ((${+TMUX})); then
1086             #works, but crashes tmux below version 1.4
1087             #luckily tmux -V option to ask for version, was also added in 1.4
1088             tmux -V &>/dev/null || return
1089             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1090         else
1091             screen -X hardcopy $TMPFILE
1092             # screen sucks, it dumps in latin1, apparently always. so recode it
1093             # to system charset
1094             check_com recode && recode latin1 $TMPFILE
1095         fi
1096         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1097         # remove PREFIX to be completed from that array
1098         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1099         compadd -a _screen_display_wordlist
1100     }
1101     #k# complete word from currently visible GNU screen buffer
1102     bindkey -r "^xS"
1103     compdef -k _complete_screen_display complete-word '^xS'
1104 fi
1105
1106 # history
1107
1108 ZSHDIR=$HOME/.zsh
1109
1110 #v#
1111 HISTFILE=$HOME/.zsh_history
1112 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1113 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1114
1115 # dirstack handling
1116
1117 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1118 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1119
1120 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1121     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1122     # "cd -" won't work after login by just setting $OLDPWD, so
1123     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1124 fi
1125
1126 chpwd() {
1127     local -ax my_stack
1128     my_stack=( ${PWD} ${dirstack} )
1129     if is42 ; then
1130         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1131     else
1132         uprint my_stack >! ${DIRSTACKFILE}
1133     fi
1134 }
1135
1136 # directory based profiles
1137
1138 if is433 ; then
1139
1140 # chpwd_profiles(): Directory Profiles, Quickstart:
1141 #
1142 # In .zshrc.local:
1143 #
1144 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1145 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1146 #   chpwd_profiles
1147 #
1148 # For details see the `grmlzshrc.5' manual page.
1149 function chpwd_profiles() {
1150     local profile context
1151     local -i reexecute
1152
1153     context=":chpwd:profiles:$PWD"
1154     zstyle -s "$context" profile profile || profile='default'
1155     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1156
1157     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1158         typeset -g CHPWD_PROFILE
1159         local CHPWD_PROFILES_INIT=1
1160         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1161     elif [[ $profile != $CHPWD_PROFILE ]]; then
1162         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1163             && chpwd_leave_profile_${CHPWD_PROFILE}
1164     fi
1165     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1166         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1167     fi
1168
1169     CHPWD_PROFILE="${profile}"
1170     return 0
1171 }
1172
1173 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1174
1175 fi # is433
1176
1177 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1178 if [[ $BATTERY -gt 0 ]] ; then
1179     if ! check_com -c acpi ; then
1180         BATTERY=0
1181     fi
1182 fi
1183
1184 battery() {
1185 if [[ $BATTERY -gt 0 ]] ; then
1186     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1187     if [[ -z "$PERCENT" ]] ; then
1188         PERCENT='acpi not present'
1189     else
1190         if [[ "$PERCENT" -lt 20 ]] ; then
1191             PERCENT="warning: ${PERCENT}%%"
1192         else
1193             PERCENT="${PERCENT}%%"
1194         fi
1195     fi
1196 fi
1197 }
1198 # set colors for use in prompts
1199 if zrcautoload colors && colors 2>/dev/null ; then
1200     BLUE="%{${fg[blue]}%}"
1201     RED="%{${fg_bold[red]}%}"
1202     GREEN="%{${fg[green]}%}"
1203     CYAN="%{${fg[cyan]}%}"
1204     MAGENTA="%{${fg[magenta]}%}"
1205     YELLOW="%{${fg[yellow]}%}"
1206     WHITE="%{${fg[white]}%}"
1207     NO_COLOUR="%{${reset_color}%}"
1208 else
1209     BLUE=$'%{\e[1;34m%}'
1210     RED=$'%{\e[1;31m%}'
1211     GREEN=$'%{\e[1;32m%}'
1212     CYAN=$'%{\e[1;36m%}'
1213     WHITE=$'%{\e[1;37m%}'
1214     MAGENTA=$'%{\e[1;35m%}'
1215     YELLOW=$'%{\e[1;33m%}'
1216     NO_COLOUR=$'%{\e[0m%}'
1217 fi
1218
1219 # gather version control information for inclusion in a prompt
1220
1221 if zrcautoload vcs_info; then
1222     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1223     # function, which can cause a lot of trouble with our directory-based
1224     # profiles. So:
1225     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1226         function VCS_INFO_realpath () {
1227             setopt localoptions NO_shwordsplit chaselinks
1228             ( builtin cd -q $1 2> /dev/null && pwd; )
1229         }
1230     fi
1231
1232     zstyle ':vcs_info:*' max-exports 2
1233
1234     if [[ -o restricted ]]; then
1235         zstyle ':vcs_info:*' enable NONE
1236     fi
1237 fi
1238
1239 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1240 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1241 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1242 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1243 #       to $vcs_info_msg_N_ as soon as we use the included version.
1244 if [[ "$TERM" == dumb ]] ; then
1245     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1246     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1247 else
1248     # these are the same, just with a lot of colours:
1249     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
1250                                        "zsh: %r"
1251     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
1252                                        "zsh: %r"
1253     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1254 fi
1255
1256 # command not found handling
1257
1258 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1259 function command_not_found_handler() {
1260     emulate -L zsh
1261     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1262         ${GRML_ZSH_CNF_HANDLER} $1
1263     fi
1264     return 1
1265 }
1266
1267 # set prompt
1268 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1269     promptinit # people should be able to use their favourite prompt
1270 else
1271     print 'Notice: no promptinit available :('
1272 fi
1273
1274 setopt prompt_subst
1275
1276 # make sure to use right prompt only when not running a command
1277 is41 && setopt transient_rprompt
1278
1279
1280 function ESC_print () {
1281     info_print $'\ek' $'\e\\' "$@"
1282 }
1283 function set_title () {
1284     info_print  $'\e]0;' $'\a' "$@"
1285 }
1286
1287 function info_print () {
1288     local esc_begin esc_end
1289     esc_begin="$1"
1290     esc_end="$2"
1291     shift 2
1292     printf '%s' ${esc_begin}
1293     printf '%s' "$*"
1294     printf '%s' "${esc_end}"
1295 }
1296
1297 # TODO: revise all these NO* variables and especially their documentation
1298 #       in zsh-help() below.
1299 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1300     [[ $NOPRECMD -gt 0 ]] && return 0
1301     # update VCS information
1302     (( ${+functions[vcs_info]} )) && vcs_info
1303
1304     if [[ $TERM == screen* ]] ; then
1305         if [[ -n ${vcs_info_msg_1_} ]] ; then
1306             ESC_print ${vcs_info_msg_1_}
1307         else
1308             ESC_print "zsh"
1309         fi
1310     fi
1311     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1312     if [[ ${DONTSETRPROMPT:-} -eq 0 ]] ; then
1313         if [[ $BATTERY -gt 0 ]] ; then
1314             # update battery (dropped into $PERCENT) information
1315             battery
1316             RPROMPT="%(?..:() ${PERCENT}"
1317         else
1318             RPROMPT="%(?..:() "
1319         fi
1320     fi
1321     # adjust title of xterm
1322     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1323     [[ ${NOTITLE:-} -gt 0 ]] && return 0
1324     case $TERM in
1325         (xterm*|rxvt*)
1326             set_title ${(%):-"%n@%m: %~"}
1327             ;;
1328     esac
1329 }
1330
1331 # preexec() => a function running before every command
1332 is4 && [[ $NOPRECMD -eq 0 ]] && \
1333 preexec () {
1334     [[ $NOPRECMD -gt 0 ]] && return 0
1335 # set hostname if not running on host with name 'grml'
1336     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1337        NAME="@$HOSTNAME"
1338     fi
1339 # get the name of the program currently running and hostname of local machine
1340 # set screen window title if running in a screen
1341     if [[ "$TERM" == screen* ]] ; then
1342         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1343         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1344         ESC_print ${CMD}
1345     fi
1346 # adjust title of xterm
1347     [[ ${NOTITLE} -gt 0 ]] && return 0
1348     case $TERM in
1349         (xterm*|rxvt*)
1350             set_title "${(%):-"%n@%m:"}" "$1"
1351             ;;
1352     esac
1353 }
1354
1355 EXITCODE="%(?..%?%1v )"
1356 # secondary prompt, printed when the shell needs more information to complete a
1357 # command.
1358 PS2='\`%_> '
1359 # selection prompt used within a select loop.
1360 PS3='?# '
1361 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1362 PS4='+%N:%i:%_> '
1363
1364 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1365 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1366     debian_chroot=$(cat /etc/debian_chroot)
1367 fi
1368
1369 # don't use colors on dumb terminals (like emacs):
1370 if [[ "$TERM" == dumb ]] ; then
1371     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
1372 else
1373     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended
1374     # prompt set variable identifying the chroot you work in (used in the
1375     # prompt below)
1376     if [[ $GRMLPROMPT -gt 0 ]] ; then
1377         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1378 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1379     else
1380         # This assembles the primary prompt string
1381         if (( EUID != 0 )); then
1382             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1383         else
1384             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1385         fi
1386     fi
1387 fi
1388
1389 PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
1390
1391 # if we are inside a grml-chroot set a specific prompt theme
1392 if [[ -n "$GRML_CHROOT" ]] ; then
1393     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1394 fi
1395
1396 # 'hash' some often used directories
1397 #d# start
1398 hash -d deb=/var/cache/apt/archives
1399 hash -d doc=/usr/share/doc
1400 hash -d linux=/lib/modules/$(command uname -r)/build/
1401 hash -d log=/var/log
1402 hash -d slog=/var/log/syslog
1403 hash -d src=/usr/src
1404 hash -d templ=/usr/share/doc/grml-templates
1405 hash -d tt=/usr/share/doc/texttools-doc
1406 hash -d www=/var/www
1407 #d# end
1408
1409 # some aliases
1410 if check_com -c screen ; then
1411     if [[ $UID -eq 0 ]] ; then
1412         if [[ -r /etc/grml/screenrc ]]; then
1413             alias screen="${commands[screen]} -c /etc/grml/screenrc"
1414         fi
1415     elif [[ -r $HOME/.screenrc ]] ; then
1416         alias screen="${commands[screen]} -c $HOME/.screenrc"
1417     else
1418         if [[ -r /etc/grml/screenrc_grml ]]; then
1419             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1420         else
1421             if [[ -r /etc/grml/screenrc ]]; then
1422                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
1423             fi
1424         fi
1425     fi
1426 fi
1427
1428 # do we have GNU ls with color-support?
1429 if [[ "$TERM" != dumb ]]; then
1430     #a1# execute \kbd{@a@}:\quad ls with colors
1431     alias ls='ls -b -CF '${ls_options:+"${ls_options[*]}"}
1432     #a1# execute \kbd{@a@}:\quad list all files, with colors
1433     alias la='ls -la '${ls_options:+"${ls_options[*]}"}
1434     #a1# long colored list, without dotfiles (@a@)
1435     alias ll='ls -l '${ls_options:+"${ls_options[*]}"}
1436     #a1# long colored list, human readable sizes (@a@)
1437     alias lh='ls -hAl '${ls_options:+"${ls_options[*]}"}
1438     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1439     alias l='ls -lF '${ls_options:+"${ls_options[*]}"}
1440 else
1441     alias ls='ls -b -CF'
1442     alias la='ls -la'
1443     alias ll='ls -l'
1444     alias lh='ls -hAl'
1445     alias l='ls -lF'
1446 fi
1447
1448 alias mdstat='cat /proc/mdstat'
1449 alias ...='cd ../../'
1450
1451 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1452 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1453     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1454 fi
1455
1456 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1457 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1458 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1459
1460 # make sure it is not assigned yet
1461 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1462 utf2iso() {
1463     if isutfenv ; then
1464         for ENV in $(env | command grep -i '.utf') ; do
1465             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1466         done
1467     fi
1468 }
1469
1470 # make sure it is not assigned yet
1471 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1472 iso2utf() {
1473     if ! isutfenv ; then
1474         for ENV in $(env | command grep -i '\.iso') ; do
1475             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1476         done
1477     fi
1478 }
1479
1480 # especially for roadwarriors using GNU screen and ssh:
1481 if ! check_com asc &>/dev/null ; then
1482   asc() { autossh -t "$@" 'screen -RdU' }
1483   compdef asc=ssh
1484 fi
1485
1486 #f1# Hints for the use of zsh on grml
1487 zsh-help() {
1488     print "$bg[white]$fg[black]
1489 zsh-help - hints for use of zsh on grml
1490 =======================================$reset_color"
1491
1492     print '
1493 Main configuration of zsh happens in /etc/zsh/zshrc.
1494 That file is part of the package grml-etc-core, if you want to
1495 use them on a non-grml-system just get the tar.gz from
1496 http://deb.grml.org/ or (preferably) get it from the git repository:
1497
1498   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1499
1500 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1501 The file is still there, but it is empty for backwards compatibility.
1502
1503 For your own changes use these two files:
1504     $HOME/.zshrc.pre
1505     $HOME/.zshrc.local
1506
1507 The former is sourced very early in our zshrc, the latter is sourced
1508 very lately.
1509
1510 System wide configuration without touching configuration files of grml
1511 can take place in /etc/zsh/zshrc.local.
1512
1513 For information regarding zsh start at http://grml.org/zsh/
1514
1515 Take a look at grml'\''s zsh refcard:
1516 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1517
1518 Check out the main zsh refcard:
1519 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1520
1521 And of course visit the zsh-lovers:
1522 % man zsh-lovers
1523
1524 You can adjust some options through environment variables when
1525 invoking zsh without having to edit configuration files.
1526 Basically meant for bash users who are not used to the power of
1527 the zsh yet. :)
1528
1529   "NOCOR=1    zsh" => deactivate automatic correction
1530   "NOMENU=1   zsh" => do not use auto menu completion
1531                       (note: use ctrl-d for completion instead!)
1532   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1533   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1534                       preexec() and precmd() completely
1535   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1536   "COMMAND_NOT_FOUND=1 zsh"
1537                    => Enable a handler if an external command was not found
1538                       The command called in the handler can be altered by setting
1539                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1540                       "/usr/share/command-not-found/command-not-found"
1541
1542 A value greater than 0 is enables a feature; a value equal to zero
1543 disables it. If you like one or the other of these settings, you can
1544 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1545 zshrc.'
1546
1547     print "
1548 $bg[white]$fg[black]
1549 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1550 Enjoy your grml system with the zsh!$reset_color"
1551 }
1552
1553 # debian stuff
1554 if [[ -r /etc/debian_version ]] ; then
1555     #a3# Execute \kbd{apt-cache search}
1556     alias acs='apt-cache search'
1557     #a3# Execute \kbd{apt-cache show}
1558     alias acsh='apt-cache show'
1559     #a3# Execute \kbd{apt-cache policy}
1560     alias acp='apt-cache policy'
1561     #a3# Execute \kbd{apt-get dist-upgrade}
1562     salias adg="apt-get dist-upgrade"
1563     #a3# Execute \kbd{apt-get install}
1564     salias agi="apt-get install"
1565     #a3# Execute \kbd{aptitude install}
1566     salias ati="aptitude install"
1567     #a3# Execute \kbd{apt-get upgrade}
1568     salias ag="apt-get upgrade"
1569     #a3# Execute \kbd{apt-get update}
1570     salias au="apt-get update"
1571     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1572     salias -a up="aptitude update ; aptitude safe-upgrade"
1573     #a3# Execute \kbd{dpkg-buildpackage}
1574     alias dbp='dpkg-buildpackage'
1575     #a3# Execute \kbd{grep-excuses}
1576     alias ge='grep-excuses'
1577
1578     # get a root shell as normal user in live-cd mode:
1579     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1580        alias su="sudo su"
1581      fi
1582
1583     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1584     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1585     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1586     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1587 fi
1588
1589 # sort installed Debian-packages by size
1590 if check_com -c dpkg-query ; then
1591     #a3# List installed Debian-packages sorted by size
1592     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1593 fi
1594
1595 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1596 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1597     if check_com -c wodim; then
1598         cdrecord() {
1599             cat <<EOMESS
1600 cdrecord is not provided under its original name by Debian anymore.
1601 See #377109 in the BTS of Debian for more details.
1602
1603 Please use the wodim binary instead
1604 EOMESS
1605             return 1
1606         }
1607     fi
1608 fi
1609
1610 # Use hard limits, except for a smaller stack and no core dumps
1611 unlimit
1612 is425 && limit stack 8192
1613 isgrmlcd && limit core 0 # important for a live-cd-system
1614 limit -s
1615
1616 # completion system
1617
1618 # called later (via is4 && grmlcomp)
1619 # note: use 'zstyle' for getting current settings
1620 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
1621 grmlcomp() {
1622     # TODO: This could use some additional information
1623
1624     # allow one error for every three characters typed in approximate completer
1625     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1626
1627     # don't complete backup files as executables
1628     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1629
1630     # start menu completion only if it could find no unambiguous initial string
1631     zstyle ':completion:*:correct:*'       insert-unambiguous true
1632     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1633     zstyle ':completion:*:correct:*'       original true
1634
1635     # activate color-completion
1636     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1637
1638     # format on completion
1639     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1640
1641     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1642     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1643
1644     # insert all expansions for expand completer
1645     zstyle ':completion:*:expand:*'        tag-order all-expansions
1646     zstyle ':completion:*:history-words'   list false
1647
1648     # activate menu
1649     zstyle ':completion:*:history-words'   menu yes
1650
1651     # ignore duplicate entries
1652     zstyle ':completion:*:history-words'   remove-all-dups yes
1653     zstyle ':completion:*:history-words'   stop yes
1654
1655     # match uppercase from lowercase
1656     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1657
1658     # separate matches into groups
1659     zstyle ':completion:*:matches'         group 'yes'
1660     zstyle ':completion:*'                 group-name ''
1661
1662     if [[ "$NOMENU" -eq 0 ]] ; then
1663         # if there are more than 5 options allow selecting from a menu
1664         zstyle ':completion:*'               menu select=5
1665     else
1666         # don't use any menus at all
1667         setopt no_auto_menu
1668     fi
1669
1670     zstyle ':completion:*:messages'        format '%d'
1671     zstyle ':completion:*:options'         auto-description '%d'
1672
1673     # describe options in full
1674     zstyle ':completion:*:options'         description 'yes'
1675
1676     # on processes completion complete all user processes
1677     zstyle ':completion:*:processes'       command 'ps -au$USER'
1678
1679     # offer indexes before parameters in subscripts
1680     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1681
1682     # provide verbose completion information
1683     zstyle ':completion:*'                 verbose true
1684
1685     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1686     # for commands (read: 1st word in the line) that it will list for the user
1687     # to choose from. The following disables that, because it's not exactly fast.
1688     zstyle ':completion:*:-command-:*:'    verbose false
1689
1690     # set format for warnings
1691     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1692
1693     # define files to ignore for zcompile
1694     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1695     zstyle ':completion:correct:'          prompt 'correct to: %e'
1696
1697     # Ignore completion functions for commands you don't have:
1698     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1699
1700     # Provide more processes in completion of programs like killall:
1701     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1702
1703     # complete manual by their section
1704     zstyle ':completion:*:manuals'    separate-sections true
1705     zstyle ':completion:*:manuals.*'  insert-sections   true
1706     zstyle ':completion:*:man:*'      menu yes select
1707
1708     # provide .. as a completion
1709     zstyle ':completion:*' special-dirs ..
1710
1711     # run rehash on completion so new installed program are found automatically:
1712     _force_rehash() {
1713         (( CURRENT == 1 )) && rehash
1714         return 1
1715     }
1716
1717     ## correction
1718     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1719     if [[ "$NOCOR" -gt 0 ]] ; then
1720         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1721         setopt nocorrect
1722     else
1723         # try to be smart about when to use what completer...
1724         setopt correct
1725         zstyle -e ':completion:*' completer '
1726             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1727                 _last_try="$HISTNO$BUFFER$CURSOR"
1728                 reply=(_complete _match _ignored _prefix _files)
1729             else
1730                 if [[ $words[1] == (rm|mv) ]] ; then
1731                     reply=(_complete _files)
1732                 else
1733                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1734                 fi
1735             fi'
1736     fi
1737
1738     # command for process lists, the local web server details and host completion
1739     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1740
1741     # caching
1742     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1743                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1744
1745     # host completion
1746     if is42 ; then
1747         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1748         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1749     else
1750         _ssh_hosts=()
1751         _etc_hosts=()
1752     fi
1753     hosts=(
1754         $(hostname)
1755         "$_ssh_hosts[@]"
1756         "$_etc_hosts[@]"
1757         grml.org
1758         localhost
1759     )
1760     zstyle ':completion:*:hosts' hosts $hosts
1761     # TODO: so, why is this here?
1762     #  zstyle '*' hosts $hosts
1763
1764     # use generic completion system for programs not yet defined; (_gnu_generic works
1765     # with commands that provide a --help option with "standard" gnu-like output.)
1766     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
1767                    pal stow tail uname ; do
1768         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
1769     done; unset compcom
1770
1771     # see upgrade function in this file
1772     compdef _hosts upgrade
1773 }
1774
1775 # grmlstuff
1776 grmlstuff() {
1777 # people should use 'grml-x'!
1778     if check_com -c 915resolution; then
1779         855resolution() {
1780             echo "Please use 915resolution as resolution modifying tool for Intel \
1781 graphic chipset."
1782             return -1
1783         }
1784     fi
1785
1786     #a1# Output version of running grml
1787     alias grml-version='cat /etc/grml_version'
1788
1789     if check_com -c rebuildfstab ; then
1790         #a1# Rebuild /etc/fstab
1791         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1792     fi
1793
1794     if check_com -c grml-debootstrap ; then
1795         debian2hd() {
1796             echo "Installing debian to harddisk is possible by using grml-debootstrap."
1797             return 1
1798         }
1799     fi
1800 }
1801
1802 # now run the functions
1803 isgrml && checkhome
1804 is4    && isgrml    && grmlstuff
1805 is4    && grmlcomp
1806
1807 # keephack
1808 is4 && xsource "/etc/zsh/keephack"
1809
1810 # wonderful idea of using "e" glob qualifier by Peter Stephenson
1811 # You use it as follows:
1812 # $ NTREF=/reference/file
1813 # $ ls -l *(e:nt:)
1814 # This lists all the files in the current directory newer than the reference file.
1815 # You can also specify the reference file inline; note quotes:
1816 # $ ls -l *(e:'nt ~/.zshenv':)
1817 is4 && nt() {
1818     if [[ -n $1 ]] ; then
1819         local NTREF=${~1}
1820     fi
1821     [[ $REPLY -nt $NTREF ]]
1822 }
1823
1824 # shell functions
1825
1826 #f1# Reload an autoloadable function
1827 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1828 compdef _functions freload
1829
1830 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1831 sll() {
1832     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1833     for file in "$@" ; do
1834         while [[ -h "$file" ]] ; do
1835             ls -l $file
1836             file=$(readlink "$file")
1837         done
1838     done
1839 }
1840
1841 # TODO: Is it supported to use pager settings like this?
1842 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
1843 # with respect to wordsplitting. (ie. ${=PAGER})
1844 if check_com -c $PAGER ; then
1845     #f1# View Debian's changelog of a given package
1846     dchange() {
1847         emulate -L zsh
1848         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
1849             $PAGER /usr/share/doc/$1/changelog.Debian.gz
1850         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1851             $PAGER /usr/share/doc/$1/changelog.gz
1852         else
1853             if check_com -c aptitude ; then
1854                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1855                 if isgrml ; then
1856                     aptitude -t unstable changelog $1
1857                 else
1858                     aptitude changelog $1
1859                 fi
1860             else
1861                 echo "No changelog for package $1 found, sorry."
1862                 return 1
1863             fi
1864         fi
1865     }
1866     _dchange() { _files -W /usr/share/doc -/ }
1867     compdef _dchange dchange
1868
1869     #f1# View Debian's NEWS of a given package
1870     dnews() {
1871         emulate -L zsh
1872         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
1873             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
1874         else
1875             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
1876                 $PAGER /usr/share/doc/$1/NEWS.gz
1877             else
1878                 echo "No NEWS file for package $1 found, sorry."
1879                 return 1
1880             fi
1881         fi
1882     }
1883     _dnews() { _files -W /usr/share/doc -/ }
1884     compdef _dnews dnews
1885
1886     #f1# View upstream's changelog of a given package
1887     uchange() {
1888         emulate -L zsh
1889         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1890             $PAGER /usr/share/doc/$1/changelog.gz
1891         else
1892             echo "No changelog for package $1 found, sorry."
1893             return 1
1894         fi
1895     }
1896     _uchange() { _files -W /usr/share/doc -/ }
1897     compdef _uchange uchange
1898 fi
1899
1900 # zsh profiling
1901 profile() {
1902     ZSH_PROFILE_RC=1 $SHELL "$@"
1903 }
1904
1905 #f1# Edit an alias via zle
1906 edalias() {
1907     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1908 }
1909 compdef _aliases edalias
1910
1911 #f1# Edit a function via zle
1912 edfunc() {
1913     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
1914 }
1915 compdef _functions edfunc
1916
1917 # use it e.g. via 'Restart apache2'
1918 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
1919 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
1920 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
1921 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
1922 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
1923 if [[ -d /etc/init.d || -d /etc/service ]] ; then
1924     __start_stop() {
1925         local action_="${1:l}"  # e.g Start/Stop/Restart
1926         local service_="$2"
1927         local param_="$3"
1928
1929         local service_target_="$(readlink /etc/init.d/$service_)"
1930         if [[ $service_target_ == "/usr/bin/sv" ]]; then
1931             # runit
1932             case "${action_}" in
1933                 start) if [[ ! -e /etc/service/$service_ ]]; then
1934                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
1935                        else
1936                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1937                        fi ;;
1938                 # there is no reload in runits sysv emulation
1939                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
1940                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
1941             esac
1942         else
1943             # sysvinit
1944             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1945         fi
1946     }
1947
1948     _grmlinitd() {
1949         local -a scripts
1950         scripts=( /etc/init.d/*(x:t) )
1951         _describe "service startup script" scripts
1952     }
1953
1954     for i in Start Restart Stop Force-Reload Reload ; do
1955         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
1956         compdef _grmlinitd $i
1957     done
1958 fi
1959
1960 #f1# Provides useful information on globbing
1961 H-Glob() {
1962     echo -e "
1963     /      directories
1964     .      plain files
1965     @      symbolic links
1966     =      sockets
1967     p      named pipes (FIFOs)
1968     *      executable plain files (0100)
1969     %      device files (character or block special)
1970     %b     block special files
1971     %c     character special files
1972     r      owner-readable files (0400)
1973     w      owner-writable files (0200)
1974     x      owner-executable files (0100)
1975     A      group-readable files (0040)
1976     I      group-writable files (0020)
1977     E      group-executable files (0010)
1978     R      world-readable files (0004)
1979     W      world-writable files (0002)
1980     X      world-executable files (0001)
1981     s      setuid files (04000)
1982     S      setgid files (02000)
1983     t      files with the sticky bit (01000)
1984
1985   print *(m-1)          # Files modified up to a day ago
1986   print *(a1)           # Files accessed a day ago
1987   print *(@)            # Just symlinks
1988   print *(Lk+50)        # Files bigger than 50 kilobytes
1989   print *(Lk-50)        # Files smaller than 50 kilobytes
1990   print **/*.c          # All *.c files recursively starting in \$PWD
1991   print **/*.c~file.c   # Same as above, but excluding 'file.c'
1992   print (foo|bar).*     # Files starting with 'foo' or 'bar'
1993   print *~*.*           # All Files that do not contain a dot
1994   chmod 644 *(.^x)      # make all plain non-executable files publically readable
1995   print -l *(.c|.h)     # Lists *.c and *.h
1996   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
1997   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
1998 }
1999 alias help-zshglob=H-Glob
2000
2001 #v1# set number of lines to display per page
2002 HELP_LINES_PER_PAGE=20
2003 #v1# set location of help-zle cache file
2004 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
2005 #f1# helper function for help-zle, actually generates the help text
2006 help_zle_parse_keybindings()
2007 {
2008     emulate -L zsh
2009     setopt extendedglob
2010     unsetopt ksharrays  #indexing starts at 1
2011
2012     #v1# choose files that help-zle will parse for keybindings
2013     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
2014
2015     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
2016         local load_cache=0
2017         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
2018         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
2019     fi
2020
2021     #fill with default keybindings, possibly to be overwriten in a file later
2022     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2023     local -A help_zle_keybindings
2024     help_zle_keybindings['<Ctrl>@']="set MARK"
2025     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
2026     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
2027     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
2028     help_zle_keybindings['<Ctrl>_']="undo"
2029     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
2030     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
2031     help_zle_keybindings['<Ctrl>e']="goto end of line"
2032     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2033     help_zle_keybindings['<Alt>t']="transpose words"
2034     help_zle_keybindings['<Alt>s']="spellcheck word"
2035     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
2036     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
2037     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2038     help_zle_keybindings["<Alt>'"]="quote line"
2039     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2040     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2041     help_zle_keybindings['<Alt>u']="make next word Uppercase"
2042     help_zle_keybindings['<Alt>l']="make next word lowercase"
2043     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
2044     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2045     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2046     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2047     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2048     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
2049     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2050     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2051     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
2052
2053     #init global variables
2054     unset help_zle_lines help_zle_sln
2055     typeset -g -a help_zle_lines
2056     typeset -g help_zle_sln=1
2057
2058     local k v
2059     local lastkeybind_desc contents     #last description starting with #k# that we found
2060     local num_lines_elapsed=0            #number of lines between last description and keybinding
2061     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2062     for f in $HELPZLE_KEYBINDING_FILES; do
2063         [[ -r "$f" ]] || continue   #not readable ? skip it
2064         contents="$(<$f)"
2065         for cline in "${(f)contents}"; do
2066             #zsh pattern: matches lines like: #k# ..............
2067             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2068                 lastkeybind_desc="$match[*]"
2069                 num_lines_elapsed=0
2070             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2071             #             ignores lines that are commentend out
2072             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2073             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2074                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2075                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2076                     #substitute keybinding string with something readable
2077                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2078                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2079                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2080                     help_zle_keybindings[${k}]=$lastkeybind_desc
2081                 fi
2082                 lastkeybind_desc=""
2083             else
2084               ((num_lines_elapsed++))
2085             fi
2086         done
2087     done
2088     unset contents
2089     #calculate length of keybinding column
2090     local kstrlen=0
2091     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2092     #convert the assoc array into preformated lines, which we are able to sort
2093     for k v in ${(kv)help_zle_keybindings[@]}; do
2094         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2095         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2096     done
2097     #sort lines alphabetically
2098     help_zle_lines=("${(i)help_zle_lines[@]}")
2099     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2100     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2101     zcompile $HELP_ZLE_CACHE_FILE
2102 }
2103 typeset -g help_zle_sln
2104 typeset -g -a help_zle_lines
2105
2106 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2107 help-zle()
2108 {
2109     emulate -L zsh
2110     unsetopt ksharrays  #indexing starts at 1
2111     #help lines already generated ? no ? then do it
2112     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2113     #already displayed all lines ? go back to the start
2114     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2115     local sln=$help_zle_sln
2116     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2117     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2118     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2119 }
2120 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2121 zle -N help-zle && bindkey '^xz' help-zle
2122
2123 # grep for running process, like: 'any vim'
2124 any() {
2125     emulate -L zsh
2126     unsetopt KSH_ARRAYS
2127     if [[ -z "$1" ]] ; then
2128         echo "any - grep for process(es) by keyword" >&2
2129         echo "Usage: any <keyword>" >&2 ; return 1
2130     else
2131         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
2132     fi
2133 }
2134
2135
2136 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2137 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2138 [[ -r /proc/1/maps ]] && \
2139 deswap() {
2140     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2141     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2142     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2143 }
2144
2145 # a wrapper for vim, that deals with title setting
2146 #   VIM_OPTIONS
2147 #       set this array to a set of options to vim you always want
2148 #       to have set when calling vim (in .zshrc.local), like:
2149 #           VIM_OPTIONS=( -p )
2150 #       This will cause vim to send every file given on the
2151 #       commandline to be send to it's own tab (needs vim7).
2152 vim() {
2153     VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2154 }
2155
2156 # make a backup of a file
2157 bk() {
2158     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2159 }
2160
2161 ssl_hashes=( sha512 sha256 sha1 md5 )
2162
2163 for sh in ${ssl_hashes}; do
2164     eval 'ssl-cert-'${sh}'() {
2165         emulate -L zsh
2166         if [[ -z $1 ]] ; then
2167             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2168             return 1
2169         fi
2170         openssl x509 -noout -fingerprint -'${sh}' -in $1
2171     }'
2172 done; unset sh
2173
2174 ssl-cert-fingerprints() {
2175     emulate -L zsh
2176     local i
2177     if [[ -z $1 ]] ; then
2178         printf 'usage: ssl-cert-fingerprints <file>\n'
2179         return 1
2180     fi
2181     for i in ${ssl_hashes}
2182         do ssl-cert-$i $1;
2183     done
2184 }
2185
2186 ssl-cert-info() {
2187     emulate -L zsh
2188     if [[ -z $1 ]] ; then
2189         printf 'usage: ssl-cert-info <file>\n'
2190         return 1
2191     fi
2192     openssl x509 -noout -text -in $1
2193     ssl-cert-fingerprints $1
2194 }
2195
2196 # make sure our environment is clean regarding colors
2197 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2198
2199 # "persistent history"
2200 # just write important commands you always need to ~/.important_commands
2201 if [[ -r ~/.important_commands ]] ; then
2202     fc -R ~/.important_commands
2203 fi
2204
2205 # load the lookup subsystem if it's available on the system
2206 zrcautoload lookupinit && lookupinit
2207
2208 # variables
2209
2210 # set terminal property (used e.g. by msgid-chooser)
2211 export COLORTERM="yes"
2212
2213 # aliases
2214
2215 # general
2216 #a2# Execute \kbd{du -sch}
2217 alias da='du -sch'
2218 #a2# Execute \kbd{jobs -l}
2219 alias j='jobs -l'
2220
2221 # listing stuff
2222 #a2# Execute \kbd{ls -lSrah}
2223 alias dir="ls -lSrah"
2224 #a2# Only show dot-directories
2225 alias lad='ls -d .*(/)'
2226 #a2# Only show dot-files
2227 alias lsa='ls -a .*(.)'
2228 #a2# Only files with setgid/setuid/sticky flag
2229 alias lss='ls -l *(s,S,t)'
2230 #a2# Only show symlinks
2231 alias lsl='ls -l *(@)'
2232 #a2# Display only executables
2233 alias lsx='ls -l *(*)'
2234 #a2# Display world-{readable,writable,executable} files
2235 alias lsw='ls -ld *(R,W,X.^ND/)'
2236 #a2# Display the ten biggest files
2237 alias lsbig="ls -flh *(.OL[1,10])"
2238 #a2# Only show directories
2239 alias lsd='ls -d *(/)'
2240 #a2# Only show empty directories
2241 alias lse='ls -d *(/^F)'
2242 #a2# Display the ten newest files
2243 alias lsnew="ls -rtlh *(D.om[1,10])"
2244 #a2# Display the ten oldest files
2245 alias lsold="ls -rtlh *(D.Om[1,10])"
2246 #a2# Display the ten smallest files
2247 alias lssmall="ls -Srl *(.oL[1,10])"
2248 #a2# Display the ten newest directories and ten newest .directories
2249 alias lsnewdir="ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
2250 #a2# Display the ten oldest directories and ten oldest .directories
2251 alias lsolddir="ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
2252
2253 # some useful aliases
2254 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir $OLDCWD}
2255 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2256
2257 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2258 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2259 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2260
2261 # work around non utf8 capable software in utf environment via $LANG and luit
2262 if check_com isutfenv && check_com luit ; then
2263     if check_com -c mrxvt ; then
2264         isutfenv && [[ -n "$LANG" ]] && \
2265             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2266     fi
2267
2268     if check_com -c aterm ; then
2269         isutfenv && [[ -n "$LANG" ]] && \
2270             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2271     fi
2272
2273     if check_com -c centericq ; then
2274         isutfenv && [[ -n "$LANG" ]] && \
2275             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2276     fi
2277 fi
2278
2279 # useful functions
2280
2281 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2282 bk() {
2283     emulate -L zsh
2284     cp -b $1 $1_`date --iso-8601=m`
2285 }
2286
2287 #f5# cd to directoy and list files
2288 cl() {
2289     emulate -L zsh
2290     cd $1 && ls -a
2291 }
2292
2293 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2294 cd() {
2295     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2296         [[ ! -e ${1:h} ]] && return 1
2297         print "Correcting ${1} to ${1:h}"
2298         builtin cd ${1:h}
2299     else
2300         builtin cd "$@"
2301     fi
2302 }
2303
2304 #f5# Create Directoy and \kbd{cd} to it
2305 mkcd() {
2306     if (( ARGC != 1 )); then
2307         printf 'usage: mkcd <new-directory>\n'
2308         return 1;
2309     fi
2310     if [[ ! -d "$1" ]]; then
2311         command mkdir -p "$1"
2312     else
2313         printf '`%s'\'' already exists: cd-ing.\n' "$1"
2314     fi
2315     builtin cd "$1"
2316 }
2317
2318 #f5# Create temporary directory and \kbd{cd} to it
2319 cdt() {
2320     local t
2321     t=$(mktemp -d)
2322     echo "$t"
2323     builtin cd "$t"
2324 }
2325
2326 #f5# Create directory under cursor or the selected area
2327 # Press ctrl-xM to create the directory under the cursor or the selected area.
2328 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2329 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2330 # directory does not exist yet -> press ctrl-XM and problem solved
2331 inplaceMkDirs() {
2332     local PATHTOMKDIR
2333     if ((REGION_ACTIVE==1)); then
2334         local F=$MARK T=$CURSOR
2335         if [[ $F -gt $T ]]; then
2336             F=${CURSOR}
2337             T=${MARK}
2338         fi
2339         # get marked area from buffer and eliminate whitespace
2340         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2341         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2342     else
2343         local bufwords iword
2344         bufwords=(${(z)LBUFFER})
2345         iword=${#bufwords}
2346         bufwords=(${(z)BUFFER})
2347         PATHTOMKDIR="${(Q)bufwords[iword]}"
2348     fi
2349     [[ -z "${PATHTOMKDIR}" ]] && return 1
2350     PATHTOMKDIR=${~PATHTOMKDIR}
2351     if [[ -e "${PATHTOMKDIR}" ]]; then
2352         zle -M " path already exists, doing nothing"
2353     else
2354         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2355         zle end-of-line
2356     fi
2357 }
2358 #k# mkdir -p <dir> from string under cursor or marked area
2359 zle -N inplaceMkDirs && bindkey '^xM' inplaceMkDirs
2360
2361 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2362 accessed() {
2363     emulate -L zsh
2364     print -l -- *(a-${1:-1})
2365 }
2366
2367 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2368 changed() {
2369     emulate -L zsh
2370     print -l -- *(c-${1:-1})
2371 }
2372
2373 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2374 modified() {
2375     emulate -L zsh
2376     print -l -- *(m-${1:-1})
2377 }
2378 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2379 check_com new || alias new=modified
2380
2381 # use colors when GNU grep with color-support
2382 #a2# Execute \kbd{grep -{}-color=auto}
2383 (( $#grep_options > 0 )) && alias grep='grep '${grep_options:+"${grep_options[*]}"}
2384
2385 # Translate DE<=>EN
2386 # 'translate' looks up fot a word in a file with language-to-language
2387 # translations (field separator should be " : "). A typical wordlist looks
2388 # like at follows:
2389 #  | english-word : german-transmission
2390 # It's also only possible to translate english to german but not reciprocal.
2391 # Use the following oneliner to turn back the sort order:
2392 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2393 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2394 #f5# Translates a word
2395 trans() {
2396     emulate -L zsh
2397     case "$1" in
2398         -[dD]*)
2399             translate -l de-en $2
2400             ;;
2401         -[eE]*)
2402             translate -l en-de $2
2403             ;;
2404         *)
2405             echo "Usage: $0 { -D | -E }"
2406             echo "         -D == German to English"
2407             echo "         -E == English to German"
2408     esac
2409 }
2410
2411 # Usage: simple-extract <file>
2412 # Using option -d deletes the original archive file.
2413 #f5# Smart archive extractor
2414 simple-extract() {
2415     emulate -L zsh
2416     setopt extended_glob noclobber
2417     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2418     local RC=0
2419     zparseopts -D -E "d=DELETE_ORIGINAL"
2420     for ARCHIVE in "${@}"; do
2421         case $ARCHIVE in
2422             *.(tar.bz2|tbz2|tbz))
2423                 DECOMP_CMD="tar -xvjf -"
2424                 USES_STDIN=true
2425                 USES_STDOUT=false
2426                 ;;
2427             *.(tar.gz|tgz))
2428                 DECOMP_CMD="tar -xvzf -"
2429                 USES_STDIN=true
2430                 USES_STDOUT=false
2431                 ;;
2432             *.(tar.xz|txz|tar.lzma))
2433                 DECOMP_CMD="tar -xvJf -"
2434                 USES_STDIN=true
2435                 USES_STDOUT=false
2436                 ;;
2437             *.tar)
2438                 DECOMP_CMD="tar -xvf -"
2439                 USES_STDIN=true
2440                 USES_STDOUT=false
2441                 ;;
2442             *.rar)
2443                 DECOMP_CMD="unrar x"
2444                 USES_STDIN=false
2445                 USES_STDOUT=false
2446                 ;;
2447             *.lzh)
2448                 DECOMP_CMD="lha x"
2449                 USES_STDIN=false
2450                 USES_STDOUT=false
2451                 ;;
2452             *.7z)
2453                 DECOMP_CMD="7z x"
2454                 USES_STDIN=false
2455                 USES_STDOUT=false
2456                 ;;
2457             *.(zip|jar))
2458                 DECOMP_CMD="unzip"
2459                 USES_STDIN=false
2460                 USES_STDOUT=false
2461                 ;;
2462             *.deb)
2463                 DECOMP_CMD="ar -x"
2464                 USES_STDIN=false
2465                 USES_STDOUT=false
2466                 ;;
2467             *.bz2)
2468                 DECOMP_CMD="bzip2 -d -c -"
2469                 USES_STDIN=true
2470                 USES_STDOUT=true
2471                 ;;
2472             *.(gz|Z))
2473                 DECOMP_CMD="gzip -d -c -"
2474                 USES_STDIN=true
2475                 USES_STDOUT=true
2476                 ;;
2477             *.(xz|lzma))
2478                 DECOMP_CMD="xz -d -c -"
2479                 USES_STDIN=true
2480                 USES_STDOUT=true
2481                 ;;
2482             *)
2483                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2484                 RC=$((RC+1))
2485                 continue
2486                 ;;
2487         esac
2488
2489         if ! check_com ${DECOMP_CMD[(w)1]}; then
2490             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2491             RC=$((RC+2))
2492             continue
2493         fi
2494
2495         GZTARGET="${ARCHIVE:t:r}"
2496         if [[ -f $ARCHIVE ]] ; then
2497
2498             print "Extracting '$ARCHIVE' ..."
2499             if $USES_STDIN; then
2500                 if $USES_STDOUT; then
2501                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
2502                 else
2503                     ${=DECOMP_CMD} < "$ARCHIVE"
2504                 fi
2505             else
2506                 if $USES_STDOUT; then
2507                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
2508                 else
2509                     ${=DECOMP_CMD} "$ARCHIVE"
2510                 fi
2511             fi
2512             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
2513
2514         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
2515             if check_com curl; then
2516                 WGET_CMD="curl -L -k -s -o -"
2517             elif check_com wget; then
2518                 WGET_CMD="wget -q -O - --no-check-certificate"
2519             else
2520                 print "ERROR: neither wget nor curl is installed" >&2
2521                 RC=$((RC+4))
2522                 continue
2523             fi
2524             print "Downloading and Extracting '$ARCHIVE' ..."
2525             if $USES_STDIN; then
2526                 if $USES_STDOUT; then
2527                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
2528                     RC=$((RC+$?))
2529                 else
2530                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
2531                     RC=$((RC+$?))
2532                 fi
2533             else
2534                 if $USES_STDOUT; then
2535                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
2536                 else
2537                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
2538                 fi
2539             fi
2540
2541         else
2542             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
2543             RC=$((RC+8))
2544         fi
2545     done
2546     return $RC
2547 }
2548
2549 __archive_or_uri()
2550 {
2551     _alternative \
2552         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
2553         '_urls:Remote Archives:_urls'
2554 }
2555
2556 _simple_extract()
2557 {
2558     _arguments \
2559         '-d[delete original archivefile after extraction]' \
2560         '*:Archive Or Uri:__archive_or_uri'
2561 }
2562 compdef _simple_extract simple-extract
2563 alias se=simple-extract
2564
2565 #f5# Set all ulimit parameters to \kbd{unlimited}
2566 allulimit() {
2567     ulimit -c unlimited
2568     ulimit -d unlimited
2569     ulimit -f unlimited
2570     ulimit -l unlimited
2571     ulimit -n unlimited
2572     ulimit -s unlimited
2573     ulimit -t unlimited
2574 }
2575
2576 #f5# Change the xterm title from within GNU-screen
2577 xtrename() {
2578     emulate -L zsh
2579     if [[ $1 != "-f" ]] ; then
2580         if [[ -z ${DISPLAY} ]] ; then
2581             printf 'xtrename only makes sense in X11.\n'
2582             return 1
2583         fi
2584     else
2585         shift
2586     fi
2587     if [[ -z $1 ]] ; then
2588         printf 'usage: xtrename [-f] "title for xterm"\n'
2589         printf '  renames the title of xterm from _within_ screen.\n'
2590         printf '  also works without screen.\n'
2591         printf '  will not work if DISPLAY is unset, use -f to override.\n'
2592         return 0
2593     fi
2594     print -n "\eP\e]0;${1}\C-G\e\\"
2595     return 0
2596 }
2597
2598 # Create small urls via http://goo.gl using curl(1).
2599 # API reference: https://code.google.com/apis/urlshortener/
2600 function zurl() {
2601     emulate -L zsh
2602     if [[ -z $1 ]]; then
2603         print "USAGE: zurl <URL>"
2604         return 1
2605     fi
2606
2607     local PN url prog api json data
2608     PN=$0
2609     url=$1
2610
2611     # Prepend 'http://' to given URL where necessary for later output.
2612     if [[ ${url} != http(s|)://* ]]; then
2613         url='http://'${url}
2614     fi
2615
2616     if check_com -c curl; then
2617         prog=curl
2618     else
2619         print "curl is not available, but mandatory for ${PN}. Aborting."
2620         return 1
2621     fi
2622     api='https://www.googleapis.com/urlshortener/v1/url'
2623     contenttype="Content-Type: application/json"
2624     json="{\"longUrl\": \"${url}\"}"
2625     data=$($prog --silent -H ${contenttype} -d ${json} $api)
2626     # Match against a regex and print it
2627     if [[ $data =~ '"id": "(http://goo.gl/[[:alnum:]]+)"' ]]; then
2628         print $match;
2629     fi
2630 }
2631
2632 #f2# Find history events by search pattern and list them by date.
2633 whatwhen()  {
2634     emulate -L zsh
2635     local usage help ident format_l format_s first_char remain first last
2636     usage='USAGE: whatwhen [options] <searchstring> <search range>'
2637     help='Use `whatwhen -h'\'' for further explanations.'
2638     ident=${(l,${#${:-Usage: }},, ,)}
2639     format_l="${ident}%s\t\t\t%s\n"
2640     format_s="${format_l//(\\t)##/\\t}"
2641     # Make the first char of the word to search for case
2642     # insensitive; e.g. [aA]
2643     first_char=[${(L)1[1]}${(U)1[1]}]
2644     remain=${1[2,-1]}
2645     # Default search range is `-100'.
2646     first=${2:-\-100}
2647     # Optional, just used for `<first> <last>' given.
2648     last=$3
2649     case $1 in
2650         ("")
2651             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
2652             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2653         ;;
2654         (-h)
2655             printf '%s\n\n' ${usage}
2656             print 'OPTIONS:'
2657             printf $format_l '-h' 'show help text'
2658             print '\f'
2659             print 'SEARCH RANGE:'
2660             printf $format_l "'0'" 'the whole history,'
2661             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
2662             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
2663             printf '\n%s\n' 'EXAMPLES:'
2664             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
2665             printf $format_l 'whatwhen zsh -250'
2666             printf $format_l 'whatwhen foo 1 99'
2667         ;;
2668         (\?)
2669             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2670         ;;
2671         (*)
2672             # -l list results on stout rather than invoking $EDITOR.
2673             # -i Print dates as in YYYY-MM-DD.
2674             # -m Search for a - quoted - pattern within the history.
2675             fc -li -m "*${first_char}${remain}*" $first $last
2676         ;;
2677     esac
2678 }
2679
2680 # mercurial related stuff
2681 if check_com -c hg ; then
2682     # gnu like diff for mercurial
2683     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
2684     #f5# GNU like diff for mercurial
2685     hgdi() {
2686         emulate -L zsh
2687         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
2688     }
2689
2690     # build debian package
2691     #a2# Alias for \kbd{hg-buildpackage}
2692     alias hbp='hg-buildpackage'
2693
2694     # execute commands on the versioned patch-queue from the current repos
2695     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
2696
2697     # diffstat for specific version of a mercurial repository
2698     #   hgstat      => display diffstat between last revision and tip
2699     #   hgstat 1234 => display diffstat between revision 1234 and tip
2700     #f5# Diffstat for specific version of a mercurial repos
2701     hgstat() {
2702         emulate -L zsh
2703         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
2704     }
2705
2706 fi # end of check whether we have the 'hg'-executable
2707
2708 # grml-small cleanups
2709
2710 # The following is used to remove zsh-config-items that do not work
2711 # in grml-small by default.
2712 # If you do not want these adjustments (for whatever reason), set
2713 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
2714 # sources if it is there).
2715
2716 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
2717
2718     unset abk[V]
2719     unalias    'V'      &> /dev/null
2720     unfunction vman     &> /dev/null
2721     unfunction viless   &> /dev/null
2722     unfunction 2html    &> /dev/null
2723
2724     # manpages are not in grmlsmall
2725     unfunction manzsh   &> /dev/null
2726     unfunction man2     &> /dev/null
2727
2728 fi
2729
2730 zrclocal
2731
2732 ## genrefcard.pl settings
2733
2734 ### doc strings for external functions from files
2735 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
2736
2737 ### example: split functions-search 8,16,24,32
2738 #@# split functions-search 8
2739
2740 ## END OF FILE #################################################################
2741 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
2742 # Local variables:
2743 # mode: sh
2744 # End: