etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is439(){
 148     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 #f1# Checks whether or not you're running grml
 154 isgrml(){
 155     [[ -f /etc/grml_version ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running a grml cd
 160 isgrmlcd(){
 161     [[ -f /etc/grml_cd ]] && return 0
 162     return 1
 163 }
 164
 165 if isgrml ; then
 166 #f1# Checks whether or not you're running grml-small
 167     isgrmlsmall() {
 168         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 169             return 0
 170         fi
 171         return 1
 172     }
 173 else
 174     isgrmlsmall() { return 1 }
 175 fi
 176
 177 isdarwin(){
 178     [[ $OSTYPE == darwin* ]] && return 0
 179     return 1
 180 }
 181
 182 isfreebsd(){
 183     [[ $OSTYPE == freebsd* ]] && return 0
 184     return 1
 185 }
 186
 187 #f1# are we running within an utf environment?
 188 isutfenv() {
 189     case "$LANG $CHARSET $LANGUAGE" in
 190         *utf*) return 0 ;;
 191         *UTF*) return 0 ;;
 192         *)     return 1 ;;
 193     esac
 194 }
 195
 196 # check for user, if not running as root set $SUDO to sudo
 197 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 198
 199 # change directory to home on first invocation of zsh
 200 # important for rungetty -> autologin
 201 # Thanks go to Bart Schaefer!
 202 isgrml && checkhome() {
 203     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 204         export ALREADY_DID_CD_HOME=$HOME
 205         cd
 206     fi
 207 }
 208
 209 # check for zsh v3.1.7+
 210
 211 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 212      || ${ZSH_VERSION} == 3.<2->.<->*    \
 213      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 214
 215     printf '-!-\n'
 216     printf '-!- In this configuration we try to make use of features, that only\n'
 217     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 218     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 219     printf '-!- advanced features in all supported versions.\n'
 220     printf '-!-\n'
 221     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 222     printf '-!-\n'
 223     printf '-!- While this *may* work, it might as well fail.\n'
 224     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 225     printf '-!-\n'
 226     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 227     printf '-!- If it does today, you'\''ve been lucky.\n'
 228     printf '-!-\n'
 229     printf '-!- Ye been warned!\n'
 230     printf '-!-\n'
 231
 232     function zstyle() { : }
 233 fi
 234
 235 # autoload wrapper - use this one instead of autoload directly
 236 # We need to define this function as early as this, because autoloading
 237 # 'is-at-least()' needs it.
 238 function zrcautoload() {
 239     emulate -L zsh
 240     setopt extended_glob
 241     local fdir ffile
 242     local -i ffound
 243
 244     ffile=$1
 245     (( ffound = 0 ))
 246     for fdir in ${fpath} ; do
 247         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 248     done
 249
 250     (( ffound == 0 )) && return 1
 251     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 252         autoload -U ${ffile} || return 1
 253     else
 254         autoload ${ffile} || return 1
 255     fi
 256     return 0
 257 }
 258
 259 # Load is-at-least() for more precise version checks Note that this test will
 260 # *always* fail, if the is-at-least function could not be marked for
 261 # autoloading.
 262 zrcautoload is-at-least || is-at-least() { return 1 }
 263
 264 # set some important options (as early as possible)
 265
 266 # append history list to the history file; this is the default but we make sure
 267 # because it's required for share_history.
 268 setopt append_history
 269
 270 # import new commands from the history file also in other zsh-session
 271 is4 && setopt share_history
 272
 273 # save each command's beginning timestamp and the duration to the history file
 274 setopt extended_history
 275
 276 # If a new command line being added to the history list duplicates an older
 277 # one, the older command is removed from the list
 278 is4 && setopt histignorealldups
 279
 280 # remove command lines from the history list when the first character on the
 281 # line is a space
 282 setopt histignorespace
 283
 284 # if a command is issued that can't be executed as a normal command, and the
 285 # command is the name of a directory, perform the cd command to that directory.
 286 setopt auto_cd
 287
 288 # in order to use #, ~ and ^ for filename generation grep word
 289 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 290 # don't forget to quote '^', '~' and '#'!
 291 setopt extended_glob
 292
 293 # display PID when suspending processes as well
 294 setopt longlistjobs
 295
 296 # try to avoid the 'zsh: no matches found...'
 297 setopt nonomatch
 298
 299 # report the status of backgrounds jobs immediately
 300 setopt notify
 301
 302 # whenever a command completion is attempted, make sure the entire command path
 303 # is hashed first.
 304 setopt hash_list_all
 305
 306 # not just at the end
 307 setopt completeinword
 308
 309 # Don't send SIGHUP to background processes when the shell exits.
 310 setopt nohup
 311
 312 # make cd push the old directory onto the directory stack.
 313 setopt auto_pushd
 314
 315 # avoid "beep"ing
 316 setopt nobeep
 317
 318 # don't push the same dir twice.
 319 setopt pushd_ignore_dups
 320
 321 # * shouldn't match dotfiles. ever.
 322 setopt noglobdots
 323
 324 # use zsh style word splitting
 325 setopt noshwordsplit
 326
 327 # don't error out when unset parameters are used
 328 setopt unset
 329
 330 # setting some default values
 331 NOCOR=${NOCOR:-0}
 332 NOMENU=${NOMENU:-0}
 333 NOPRECMD=${NOPRECMD:-0}
 334 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 335 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 336 BATTERY=${BATTERY:-0}
 337 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 338 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 339
 340 typeset -ga ls_options
 341 typeset -ga grep_options
 342 if ls --help 2> /dev/null | grep -q GNU; then
 343     ls_options=( --color=auto )
 344 elif [[ $OSTYPE == freebsd* ]]; then
 345     ls_options=( -G )
 346 fi
 347 if grep --help 2> /dev/null | grep -q GNU || \
 348    [[ $OSTYPE == freebsd* ]]; then
 349     grep_options=( --color=auto )
 350 fi
 351
 352 # utility functions
 353 # this function checks if a command exists and returns either true
 354 # or false. This avoids using 'which' and 'whence', which will
 355 # avoid problems with aliases for which on certain weird systems. :-)
 356 # Usage: check_com [-c|-g] word
 357 #   -c  only checks for external commands
 358 #   -g  does the usual tests and also checks for global aliases
 359 check_com() {
 360     emulate -L zsh
 361     local -i comonly gatoo
 362
 363     if [[ $1 == '-c' ]] ; then
 364         (( comonly = 1 ))
 365         shift
 366     elif [[ $1 == '-g' ]] ; then
 367         (( gatoo = 1 ))
 368     else
 369         (( comonly = 0 ))
 370         (( gatoo = 0 ))
 371     fi
 372
 373     if (( ${#argv} != 1 )) ; then
 374         printf 'usage: check_com [-c] <command>\n' >&2
 375         return 1
 376     fi
 377
 378     if (( comonly > 0 )) ; then
 379         [[ -n ${commands[$1]}  ]] && return 0
 380         return 1
 381     fi
 382
 383     if   [[ -n ${commands[$1]}    ]] \
 384       || [[ -n ${functions[$1]}   ]] \
 385       || [[ -n ${aliases[$1]}     ]] \
 386       || [[ -n ${reswords[(r)$1]} ]] ; then
 387
 388         return 0
 389     fi
 390
 391     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 392         return 0
 393     fi
 394
 395     return 1
 396 }
 397
 398 # creates an alias and precedes the command with
 399 # sudo if $EUID is not zero.
 400 salias() {
 401     emulate -L zsh
 402     local only=0 ; local multi=0
 403     while [[ $1 == -* ]] ; do
 404         case $1 in
 405             (-o) only=1 ;;
 406             (-a) multi=1 ;;
 407             (--) shift ; break ;;
 408             (-h)
 409                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 410                 printf '  -h      shows this help text.\n'
 411                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 412                 printf '          be careful using this option.\n'
 413                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 414                 return 0
 415                 ;;
 416             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 417         esac
 418         shift
 419     done
 420
 421     if (( ${#argv} > 1 )) ; then
 422         printf 'Too many arguments %s\n' "${#argv}"
 423         return 1
 424     fi
 425
 426     key="${1%%\=*}" ;  val="${1#*\=}"
 427     if (( EUID == 0 )) && (( only == 0 )); then
 428         alias -- "${key}=${val}"
 429     elif (( EUID > 0 )) ; then
 430         (( multi > 0 )) && val="${val// ; / ; sudo }"
 431         alias -- "${key}=sudo ${val}"
 432     fi
 433
 434     return 0
 435 }
 436
 437 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 438 # usage: uprint foo
 439 #   Where foo is the *name* of the parameter you want printed.
 440 #   Note that foo is no typo; $foo would be wrong here!
 441 if ! is42 ; then
 442     uprint () {
 443         emulate -L zsh
 444         local -a u
 445         local w
 446         local parameter=$1
 447
 448         if [[ -z ${parameter} ]] ; then
 449             printf 'usage: uprint <parameter>\n'
 450             return 1
 451         fi
 452
 453         for w in ${(P)parameter} ; do
 454             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 455         done
 456
 457         builtin print -l $u
 458     }
 459 fi
 460
 461 # Check if we can read given files and source those we can.
 462 xsource() {
 463     if (( ${#argv} < 1 )) ; then
 464         printf 'usage: xsource FILE(s)...\n' >&2
 465         return 1
 466     fi
 467
 468     while (( ${#argv} > 0 )) ; do
 469         [[ -r "$1" ]] && source "$1"
 470         shift
 471     done
 472     return 0
 473 }
 474
 475 # Check if we can read a given file and 'cat(1)' it.
 476 xcat() {
 477     emulate -L zsh
 478     if (( ${#argv} != 1 )) ; then
 479         printf 'usage: xcat FILE\n' >&2
 480         return 1
 481     fi
 482
 483     [[ -r $1 ]] && cat $1
 484     return 0
 485 }
 486
 487 # Remove these functions again, they are of use only in these
 488 # setup files. This should be called at the end of .zshrc.
 489 xunfunction() {
 490     emulate -L zsh
 491     local -a funcs
 492     funcs=(salias xcat xsource xunfunction zrcautoload)
 493
 494     for func in $funcs ; do
 495         [[ -n ${functions[$func]} ]] \
 496             && unfunction $func
 497     done
 498     return 0
 499 }
 500
 501 # this allows us to stay in sync with grml's zshrc and put own
 502 # modifications in ~/.zshrc.local
 503 zrclocal() {
 504     xsource "/etc/zsh/zshrc.local"
 505     xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
 506     return 0
 507 }
 508
 509 # locale setup
 510 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 511     xsource "/etc/default/locale"
 512 fi
 513
 514 for var in LANG LC_ALL LC_MESSAGES ; do
 515     [[ -n ${(P)var} ]] && export $var
 516 done
 517
 518 xsource "/etc/sysconfig/keyboard"
 519
 520 TZ=$(xcat /etc/timezone)
 521
 522 # set some variables
 523 if check_com -c vim ; then
 524 #v#
 525     export EDITOR=${EDITOR:-vim}
 526 else
 527     export EDITOR=${EDITOR:-vi}
 528 fi
 529
 530 #v#
 531 export PAGER=${PAGER:-less}
 532
 533 #v#
 534 export MAIL=${MAIL:-/var/mail/$USER}
 535
 536 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 537 export SHELL='/bin/zsh'
 538
 539 # color setup for ls:
 540 check_com -c dircolors && eval $(dircolors -b)
 541 # color setup for ls on OS X / FreeBSD:
 542 isdarwin && export CLICOLOR=1
 543 isfreebsd && export CLICOLOR=1
 544
 545 # do MacPorts setup on darwin
 546 if isdarwin && [[ -d /opt/local ]]; then
 547     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 548     # zshenv.
 549     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 550     MANPATH="/opt/local/share/man:$MANPATH"
 551 fi
 552 # do Fink setup on darwin
 553 isdarwin && xsource /sw/bin/init.sh
 554
 555 # load our function and completion directories
 556 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 557     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 558     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 559         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 560             zrcautoload ${func:t}
 561         done
 562     fi
 563 done
 564 unset fdir func
 565
 566 # support colors in less
 567 export LESS_TERMCAP_mb=$'\E[01;31m'
 568 export LESS_TERMCAP_md=$'\E[01;31m'
 569 export LESS_TERMCAP_me=$'\E[0m'
 570 export LESS_TERMCAP_se=$'\E[0m'
 571 export LESS_TERMCAP_so=$'\E[01;44;33m'
 572 export LESS_TERMCAP_ue=$'\E[0m'
 573 export LESS_TERMCAP_us=$'\E[01;32m'
 574
 575 # mailchecks
 576 MAILCHECK=30
 577
 578 # report about cpu-/system-/user-time of command if running longer than
 579 # 5 seconds
 580 REPORTTIME=5
 581
 582 # watch for everyone but me and root
 583 watch=(notme root)
 584
 585 # automatically remove duplicates from these arrays
 586 typeset -U path cdpath fpath manpath
 587
 588 # Remove zle-line-{init,finish} if it looks like it turns smkx. This would be
 589 # better fixed by working with those modes too, but we use way too many
 590 # hardcoded bindings for now.
 591 function remove_widget () {
 592     local name=$1
 593     local cap=$2
 594     if (( ${+functions[$name]} )) && [[ ${functions[$name]} == *${cap}* ]]; then
 595         local w=${widgets[$name]}
 596         zle -D $name
 597         [[ $w == user:* ]] && unfunction ${w#*:}
 598     fi
 599 }
 600 remove_widget zle-line-init smkx
 601 remove_widget zle-line-finish rmkx
 602 unfunction remove_widget
 603
 604 # keybindings
 605 if [[ "$TERM" != emacs ]] ; then
 606     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 607     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 608     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 609     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 610     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 611     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 612     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 613     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 614     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 615     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 616     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 617     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 618     # ncurses stuff:
 619     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 620     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 621     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 622     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 623     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 624     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 625     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 626     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 627 fi
 628
 629 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 630 # use emacs style per default:
 631 bindkey -e
 632 # use vi style:
 633 # bindkey -v
 634
 635 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 636 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 637 beginning-or-end-of-somewhere() {
 638     local hno=$HISTNO
 639     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 640       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 641         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 642     else
 643         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 644         if (( HISTNO != hno )); then
 645             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 646         fi
 647     fi
 648 }
 649 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 650 zle -N end-of-somewhere beginning-or-end-of-somewhere
 651
 652
 653 #if [[ "$TERM" == screen ]] ; then
 654
 655 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 656 ## to beginning/end of buffer on second keypress
 657 ## and to beginning/end of history on (at most) the third keypress
 658 # terminator & non-debian xterm
 659 bindkey '\eOH' beginning-of-somewhere  # home
 660 bindkey '\eOF' end-of-somewhere        # end
 661 # freebsd console
 662 bindkey '\e[H' beginning-of-somewhere   # home
 663 bindkey '\e[F' end-of-somewhere         # end
 664 # xterm,gnome-terminal,quake,etc
 665 bindkey '^[[1~' beginning-of-somewhere  # home
 666 bindkey '^[[4~' end-of-somewhere        # end
 667 # if terminal type is set to 'rxvt':
 668 bindkey '\e[7~' beginning-of-somewhere  # home
 669 bindkey '\e[8~' end-of-somewhere        # end
 670 #fi
 671
 672 bindkey '\e[A'  up-line-or-search       # cursor up
 673 bindkey '\e[B'  down-line-or-search     # <ESC>-
 674
 675 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 676 bindkey "\e[5C" forward-word
 677 bindkey "\e[5D" backward-word
 678 bindkey "\e[1;5C" forward-word
 679 bindkey "\e[1;5D" backward-word
 680 ## the same for alt-left-arrow and alt-right-arrow
 681 bindkey '^[[1;3C' forward-word
 682 bindkey '^[[1;3D' backward-word
 683
 684 # Search backward in the history for a line beginning with the current
 685 # line up to the cursor and move the cursor to the end of the line then
 686 zle -N history-beginning-search-backward-end history-search-end
 687 zle -N history-beginning-search-forward-end  history-search-end
 688 #k# search history backward for entry beginning with typed text
 689 bindkey '^xp'   history-beginning-search-backward-end
 690 #k# search history forward for entry beginning with typed text
 691 bindkey '^xP'   history-beginning-search-forward-end
 692 #k# search history backward for entry beginning with typed text
 693 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 694 #k# search history forward for entry beginning with typed text
 695 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 696
 697 # bindkey -s '^l' "|less\n"             # ctrl-L pipes to less
 698 # bindkey -s '^b' " &\n"                # ctrl-B runs it in the background
 699
 700 # insert unicode character
 701 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 702 # See for example http://unicode.org/charts/ for unicode characters code
 703 zrcautoload insert-unicode-char
 704 zle -N insert-unicode-char
 705 #k# Insert Unicode character
 706 bindkey '^xi' insert-unicode-char
 707
 708 #m# k Shift-tab Perform backwards menu completion
 709 if [[ -n "$terminfo[kcbt]" ]]; then
 710     bindkey "$terminfo[kcbt]" reverse-menu-complete
 711 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 712     bindkey "$terminfo[cbt]"  reverse-menu-complete
 713 fi
 714
 715 ## toggle the ,. abbreviation feature on/off
 716 # NOABBREVIATION: default abbreviation-state
 717 #                 0 - enabled (default)
 718 #                 1 - disabled
 719 NOABBREVIATION=${NOABBREVIATION:-0}
 720
 721 grml_toggle_abbrev() {
 722     if (( ${NOABBREVIATION} > 0 )) ; then
 723         NOABBREVIATION=0
 724     else
 725         NOABBREVIATION=1
 726     fi
 727 }
 728
 729 #k# Toggle abbreviation expansion on/off
 730 zle -N grml_toggle_abbrev
 731 bindkey '^xA' grml_toggle_abbrev
 732
 733 # add a command line to the shells history without executing it
 734 commit-to-history() {
 735     print -s ${(z)BUFFER}
 736     zle send-break
 737 }
 738 zle -N commit-to-history
 739 bindkey "^x^h" commit-to-history
 740
 741 # only slash should be considered as a word separator:
 742 slash-backward-kill-word() {
 743     local WORDCHARS="${WORDCHARS:s@/@}"
 744     # zle backward-word
 745     zle backward-kill-word
 746 }
 747 zle -N slash-backward-kill-word
 748
 749 #k# Kill left-side word or everything up to next slash
 750 bindkey '\ev' slash-backward-kill-word
 751 #k# Kill left-side word or everything up to next slash
 752 bindkey '\e^h' slash-backward-kill-word
 753 #k# Kill left-side word or everything up to next slash
 754 bindkey '\e^?' slash-backward-kill-word
 755
 756 # use the new *-pattern-* widgets for incremental history search
 757 if is439 ; then
 758     bindkey '^r' history-incremental-pattern-search-backward
 759     bindkey '^s' history-incremental-pattern-search-forward
 760 fi
 761
 762 # a generic accept-line wrapper
 763
 764 # This widget can prevent unwanted autocorrections from command-name
 765 # to _command-name, rehash automatically on enter and call any number
 766 # of builtin and user-defined widgets in different contexts.
 767 #
 768 # For a broader description, see:
 769 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 770 #
 771 # The code is imported from the file 'zsh/functions/accept-line' from
 772 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 773 # distributed under the same terms as zsh itself.
 774
 775 # A newly added command will may not be found or will cause false
 776 # correction attempts, if you got auto-correction set. By setting the
 777 # following style, we force accept-line() to rehash, if it cannot
 778 # find the first word on the command line in the $command[] hash.
 779 zstyle ':acceptline:*' rehash true
 780
 781 function Accept-Line() {
 782     setopt localoptions noksharrays
 783     local -a subs
 784     local -xi aldone
 785     local sub
 786     local alcontext=${1:-$alcontext}
 787
 788     zstyle -a ":acceptline:${alcontext}" actions subs
 789
 790     (( ${#subs} < 1 )) && return 0
 791
 792     (( aldone = 0 ))
 793     for sub in ${subs} ; do
 794         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 795         zle ${sub}
 796
 797         (( aldone > 0 )) && break
 798     done
 799 }
 800
 801 function Accept-Line-getdefault() {
 802     emulate -L zsh
 803     local default_action
 804
 805     zstyle -s ":acceptline:${alcontext}" default_action default_action
 806     case ${default_action} in
 807         ((accept-line|))
 808             printf ".accept-line"
 809             ;;
 810         (*)
 811             printf ${default_action}
 812             ;;
 813     esac
 814 }
 815
 816 function Accept-Line-HandleContext() {
 817     zle Accept-Line
 818
 819     default_action=$(Accept-Line-getdefault)
 820     zstyle -T ":acceptline:${alcontext}" call_default \
 821         && zle ${default_action}
 822 }
 823
 824 function accept-line() {
 825     setopt localoptions noksharrays
 826     local -ax cmdline
 827     local -x alcontext
 828     local buf com fname format msg default_action
 829
 830     alcontext='default'
 831     buf="${BUFFER}"
 832     cmdline=(${(z)BUFFER})
 833     com="${cmdline[1]}"
 834     fname="_${com}"
 835
 836     Accept-Line 'preprocess'
 837
 838     zstyle -t ":acceptline:${alcontext}" rehash \
 839         && [[ -z ${commands[$com]} ]]           \
 840         && rehash
 841
 842     if    [[ -n ${com}               ]] \
 843        && [[ -n ${reswords[(r)$com]} ]] \
 844        || [[ -n ${aliases[$com]}     ]] \
 845        || [[ -n ${functions[$com]}   ]] \
 846        || [[ -n ${builtins[$com]}    ]] \
 847        || [[ -n ${commands[$com]}    ]] ; then
 848
 849         # there is something sensible to execute, just do it.
 850         alcontext='normal'
 851         Accept-Line-HandleContext
 852
 853         return
 854     fi
 855
 856     if    [[ -o correct              ]] \
 857        || [[ -o correctall           ]] \
 858        && [[ -n ${functions[$fname]} ]] ; then
 859
 860         # nothing there to execute but there is a function called
 861         # _command_name; a completion widget. Makes no sense to
 862         # call it on the commandline, but the correct{,all} options
 863         # will ask for it nevertheless, so warn the user.
 864         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 865             # Okay, we warned the user before, he called us again,
 866             # so have it his way.
 867             alcontext='force'
 868             Accept-Line-HandleContext
 869
 870             return
 871         fi
 872
 873         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 874             alcontext='normal'
 875             Accept-Line-HandleContext
 876         else
 877             # prepare warning message for the user, configurable via zstyle.
 878             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 879
 880             if [[ -z ${msg} ]] ; then
 881                 msg="%c will not execute and completion %f exists."
 882             fi
 883
 884             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 885
 886             zle -M -- "${msg}"
 887         fi
 888         return
 889     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 890         # If we are here, the commandline contains something that is not
 891         # executable, which is neither subject to _command_name correction
 892         # and is not empty. might be a variable assignment
 893         alcontext='misc'
 894         Accept-Line-HandleContext
 895
 896         return
 897     fi
 898
 899     # If we got this far, the commandline only contains whitespace, or is empty.
 900     alcontext='empty'
 901     Accept-Line-HandleContext
 902 }
 903
 904 zle -N accept-line
 905 zle -N Accept-Line
 906 zle -N Accept-Line-HandleContext
 907
 908 # power completion - abbreviation expansion
 909 # power completion / abbreviation expansion / buffer expansion
 910 # see http://zshwiki.org/home/examples/zleiab for details
 911 # less risky than the global aliases but powerful as well
 912 # just type the abbreviation key and afterwards ',.' to expand it
 913 declare -A abk
 914 setopt extendedglob
 915 setopt interactivecomments
 916 abk=(
 917 #   key   # value                  (#d additional doc string)
 918 #A# start
 919     '...'  '../..'
 920     '....' '../../..'
 921     'BG'   '& exit'
 922     'C'    '| wc -l'
 923     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
 924     'H'    '| head'
 925     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 926     'L'    '| less'
 927     'LL'   '|& less -r'
 928     'M'    '| most'
 929     'N'    '&>/dev/null'           #d (No Output)
 930     'R'    '| tr A-z N-za-m'       #d (ROT13)
 931     'SL'   '| sort | less'
 932     'S'    '| sort -u'
 933     'T'    '| tail'
 934     'V'    '|& vim -'
 935 #A# end
 936     'co'   './configure && make && sudo make install'
 937 )
 938
 939 zleiab() {
 940     emulate -L zsh
 941     setopt extendedglob
 942     local MATCH
 943
 944     if (( NOABBREVIATION > 0 )) ; then
 945         LBUFFER="${LBUFFER},."
 946         return 0
 947     fi
 948
 949     LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
 950     LBUFFER+=${abk[$MATCH]:-$MATCH}
 951 }
 952
 953 zle -N zleiab && bindkey ",." zleiab
 954
 955 #f# display contents of assoc array $abk
 956 help-show-abk()
 957 {
 958   zle -M "$(print "Type ,. after these abbreviations to expand them:"; print -a -C 2 ${(kv)abk})"
 959 }
 960 #k# Display list of abbreviations that expand when followed by ,.
 961 zle -N help-show-abk && bindkey '^xb' help-show-abk
 962
 963 # autoloading
 964 zrcautoload zmv    # who needs mmv or rename?
 965 zrcautoload history-search-end
 966
 967 # we don't want to quote/espace URLs on our own...
 968 # if autoload -U url-quote-magic ; then
 969 #    zle -N self-insert url-quote-magic
 970 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 971 # else
 972 #    print 'Notice: no url-quote-magic available :('
 973 # fi
 974 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 975
 976 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 977 alias run-help >&/dev/null && unalias run-help
 978 for rh in run-help{,-git,-svk,-svn}; do
 979     zrcautoload $rh
 980 done; unset rh
 981
 982 # completion system
 983 if zrcautoload compinit ; then
 984     compinit || print 'Notice: no compinit available :('
 985 else
 986     print 'Notice: no compinit available :('
 987     function compdef { }
 988 fi
 989
 990 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 991
 992 is4 && \
 993 for mod in complist deltochar mathfunc ; do
 994     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 995 done
 996
 997 # autoload zsh modules when they are referenced
 998 if is4 ; then
 999     zmodload -a  zsh/stat    zstat
1000     zmodload -a  zsh/zpty    zpty
1001     zmodload -ap zsh/mapfile mapfile
1002 fi
1003
1004 if is4 && zrcautoload insert-files && zle -N insert-files ; then
1005     #k# Insert files and test globbing
1006     bindkey "^xf" insert-files # C-x-f
1007 fi
1008
1009 bindkey ' '   magic-space    # also do history expansion on space
1010 #k# Trigger menu-complete
1011 bindkey '\ei' menu-complete  # menu completion via esc-i
1012
1013 # press esc-e for editing command line in $EDITOR or $VISUAL
1014 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
1015     #k# Edit the current line in \kbd{\$EDITOR}
1016     bindkey '\ee' edit-command-line
1017 fi
1018
1019 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
1020     #k# menu selection: pick item but stay in the menu
1021     bindkey -M menuselect '\e^M' accept-and-menu-complete
1022     # also use + and INSERT since it's easier to press repeatedly
1023     bindkey -M menuselect "+" accept-and-menu-complete
1024     bindkey -M menuselect "^[[2~" accept-and-menu-complete
1025
1026     # accept a completion and try to complete again by using menu
1027     # completion; very useful with completing directories
1028     # by using 'undo' one's got a simple file browser
1029     bindkey -M menuselect '^o' accept-and-infer-next-history
1030 fi
1031
1032 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1033 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1034 zle -N insert-datestamp
1035
1036 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1037 bindkey '^ed' insert-datestamp
1038
1039 # press esc-m for inserting last typed word again (thanks to caphuso!)
1040 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1041 zle -N insert-last-typed-word;
1042
1043 #k# Insert last typed word
1044 bindkey "\em" insert-last-typed-word
1045
1046 function grml-zsh-fg() {
1047   if (( ${#jobstates} )); then
1048     zle .push-input
1049     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1050     BUFFER="${BUFFER}fg"
1051     zle .accept-line
1052   else
1053     zle -M 'No background jobs. Doing nothing.'
1054   fi
1055 }
1056 zle -N grml-zsh-fg
1057 #k# A smart shortcut for \kbd{fg<enter>}
1058 bindkey '^z' grml-zsh-fg
1059
1060 # run command line as user root via sudo:
1061 sudo-command-line() {
1062     [[ -z $BUFFER ]] && zle up-history
1063     if [[ $BUFFER != sudo\ * ]]; then
1064         BUFFER="sudo $BUFFER"
1065         CURSOR=$(( CURSOR+5 ))
1066     fi
1067 }
1068 zle -N sudo-command-line
1069
1070 #k# prepend the current command with "sudo"
1071 bindkey "^os" sudo-command-line
1072
1073 ### jump behind the first word on the cmdline.
1074 ### useful to add options.
1075 function jump_after_first_word() {
1076     local words
1077     words=(${(z)BUFFER})
1078
1079     if (( ${#words} <= 1 )) ; then
1080         CURSOR=${#BUFFER}
1081     else
1082         CURSOR=${#${words[1]}}
1083     fi
1084 }
1085 zle -N jump_after_first_word
1086 #k# jump to after first word (for adding options)
1087 bindkey '^x1' jump_after_first_word
1088
1089 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1090 zle -C hist-complete complete-word _generic
1091 zstyle ':completion:hist-complete:*' completer _history
1092 #k# complete word from history with menu
1093 bindkey "^x^x" hist-complete
1094
1095 ## complete word from currently visible Screen or Tmux buffer.
1096 if check_com -c screen || check_com -c tmux; then
1097     _complete_screen_display() {
1098         [[ "$TERM" != "screen" ]] && return 1
1099
1100         local TMPFILE=$(mktemp)
1101         local -U -a _screen_display_wordlist
1102         trap "rm -f $TMPFILE" EXIT
1103
1104         # fill array with contents from screen hardcopy
1105         if ((${+TMUX})); then
1106             #works, but crashes tmux below version 1.4
1107             #luckily tmux -V option to ask for version, was also added in 1.4
1108             tmux -V &>/dev/null || return
1109             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1110         else
1111             screen -X hardcopy $TMPFILE
1112             # screen sucks, it dumps in latin1, apparently always. so recode it
1113             # to system charset
1114             check_com recode && recode latin1 $TMPFILE
1115         fi
1116         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1117         # remove PREFIX to be completed from that array
1118         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1119         compadd -a _screen_display_wordlist
1120     }
1121     #k# complete word from currently visible GNU screen buffer
1122     bindkey -r "^xS"
1123     compdef -k _complete_screen_display complete-word '^xS'
1124 fi
1125
1126 # history
1127
1128 ZSHDIR=${ZDOTDIR:-${HOME}/.zsh}
1129
1130 #v#
1131 HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1132 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1133 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1134
1135 # dirstack handling
1136
1137 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1138 DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1139
1140 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1141     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1142     # "cd -" won't work after login by just setting $OLDPWD, so
1143     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1144 fi
1145
1146 chpwd() {
1147     local -ax my_stack
1148     my_stack=( ${PWD} ${dirstack} )
1149     if is42 ; then
1150         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1151     else
1152         uprint my_stack >! ${DIRSTACKFILE}
1153     fi
1154 }
1155
1156 # directory based profiles
1157
1158 if is433 ; then
1159
1160 # chpwd_profiles(): Directory Profiles, Quickstart:
1161 #
1162 # In .zshrc.local:
1163 #
1164 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1165 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1166 #   chpwd_profiles
1167 #
1168 # For details see the `grmlzshrc.5' manual page.
1169 function chpwd_profiles() {
1170     local profile context
1171     local -i reexecute
1172
1173     context=":chpwd:profiles:$PWD"
1174     zstyle -s "$context" profile profile || profile='default'
1175     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1176
1177     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1178         typeset -g CHPWD_PROFILE
1179         local CHPWD_PROFILES_INIT=1
1180         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1181     elif [[ $profile != $CHPWD_PROFILE ]]; then
1182         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1183             && chpwd_leave_profile_${CHPWD_PROFILE}
1184     fi
1185     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1186         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1187     fi
1188
1189     CHPWD_PROFILE="${profile}"
1190     return 0
1191 }
1192
1193 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1194
1195 fi # is433
1196
1197 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1198 if [[ $BATTERY -gt 0 ]] ; then
1199     if ! check_com -c acpi ; then
1200         BATTERY=0
1201     fi
1202 fi
1203
1204 battery() {
1205 if [[ $BATTERY -gt 0 ]] ; then
1206     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1207     if [[ -z "$PERCENT" ]] ; then
1208         PERCENT='acpi not present'
1209     else
1210         if [[ "$PERCENT" -lt 20 ]] ; then
1211             PERCENT="warning: ${PERCENT}%%"
1212         else
1213             PERCENT="${PERCENT}%%"
1214         fi
1215     fi
1216 fi
1217 }
1218 # set colors for use in prompts
1219 if zrcautoload colors && colors 2>/dev/null ; then
1220     BLUE="%{${fg[blue]}%}"
1221     RED="%{${fg_bold[red]}%}"
1222     GREEN="%{${fg[green]}%}"
1223     CYAN="%{${fg[cyan]}%}"
1224     MAGENTA="%{${fg[magenta]}%}"
1225     YELLOW="%{${fg[yellow]}%}"
1226     WHITE="%{${fg[white]}%}"
1227     NO_COLOR="%{${reset_color}%}"
1228 else
1229     BLUE=$'%{\e[1;34m%}'
1230     RED=$'%{\e[1;31m%}'
1231     GREEN=$'%{\e[1;32m%}'
1232     CYAN=$'%{\e[1;36m%}'
1233     WHITE=$'%{\e[1;37m%}'
1234     MAGENTA=$'%{\e[1;35m%}'
1235     YELLOW=$'%{\e[1;33m%}'
1236     NO_COLOR=$'%{\e[0m%}'
1237 fi
1238
1239 # gather version control information for inclusion in a prompt
1240
1241 if zrcautoload vcs_info; then
1242     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1243     # function, which can cause a lot of trouble with our directory-based
1244     # profiles. So:
1245     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1246         function VCS_INFO_realpath () {
1247             setopt localoptions NO_shwordsplit chaselinks
1248             ( builtin cd -q $1 2> /dev/null && pwd; )
1249         }
1250     fi
1251
1252     zstyle ':vcs_info:*' max-exports 2
1253
1254     if [[ -o restricted ]]; then
1255         zstyle ':vcs_info:*' enable NONE
1256     fi
1257 fi
1258
1259 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1260 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1261 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1262 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1263 #       to $vcs_info_msg_N_ as soon as we use the included version.
1264 if [[ "$TERM" == dumb ]] ; then
1265     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1266     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1267 else
1268     # these are the same, just with a lot of colors:
1269     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} " \
1270                                        "zsh: %r"
1271     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR}%} " \
1272                                        "zsh: %r"
1273     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1274 fi
1275
1276 # command not found handling
1277
1278 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1279 function command_not_found_handler() {
1280     emulate -L zsh
1281     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1282         ${GRML_ZSH_CNF_HANDLER} $1
1283     fi
1284     return 1
1285 }
1286
1287 function prompt_grml_help () {
1288     cat <<__EOF0__
1289   prompt grml
1290
1291     This is the prompt as used by the grml-live system <http://grml.org>.
1292     It is a rather simple one-line prompt, that by default looks like this:
1293
1294         <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1295
1296     The prompt itself integrates with zsh's prompt themes system (as you are
1297     witnessing right now) and is configurable to a certain degree. In
1298     particular, these aspects are customisable:
1299
1300         - The items used in the prompt (e.g. you can remove \`user' from
1301           the list of activated items, which will cause the user name to
1302           be omitted from the prompt string).
1303
1304         - The attributes used with the items are customisable via strings
1305           used before and after the actual item.
1306
1307     The available items are: rc, rc-always, change-root, user, at, host, path,
1308     vcs, percent, sad-smiley.
1309
1310     The actual configuration is done via zsh's \`zstyle' mechanism. The
1311     context, that is used while looking up styles is:
1312
1313         ':prompt:grml:<sub-context>'
1314
1315     Here <sub-context> is either 'items:<item>' or 'setup'. The available
1316     styles in the \`setup' context are: use-rprompt, items. For example,
1317     default \`items' style could be configured like this:
1318
1319         zstyle ':prompt:grml:setup' items user at host path \\
1320                                           vcs percent
1321
1322     The styles:
1323
1324         - use-rprompt (boolean): If \`true' (the default), print a sad smiley
1325           in $RPROMPT if the last command a returned non-successful error
1326           code.
1327
1328         - items (list): The list of items used in the prompt. If \`vcs' is
1329           present in the list, the theme's code invokes \`vcs_info'
1330           accordingly. Default: rc user change-root at host path vcs precent
1331
1332     Available styles in 'items:<item>' are: pre, post. These are strings that
1333     are inserted before (pre) and after (post) the item in question. Thus, the
1334     following would cause the user name to be printed in red instead of the
1335     default blue:
1336
1337         zstyle ':prompt:grml:items:user' pre '%F{red}'
1338
1339     Note, that the \`post' style may remain at its default value, because its
1340     default value is '%f', which turns the foreground text attribute off (which
1341     is exactly, what is still required with the new \`pre' value).
1342 __EOF0__
1343 }
1344
1345 function prompt_grml_setup () {
1346 }
1347
1348 function prompt_grml_precmd () {
1349 }
1350
1351 # set prompt
1352 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1353     promptinit # people should be able to use their favourite prompt
1354 else
1355     print 'Notice: no promptinit available :('
1356 fi
1357
1358 setopt prompt_subst
1359
1360 # make sure to use right prompt only when not running a command
1361 is41 && setopt transient_rprompt
1362
1363
1364 function ESC_print () {
1365     info_print $'\ek' $'\e\\' "$@"
1366 }
1367 function set_title () {
1368     info_print  $'\e]0;' $'\a' "$@"
1369 }
1370
1371 function info_print () {
1372     local esc_begin esc_end
1373     esc_begin="$1"
1374     esc_end="$2"
1375     shift 2
1376     printf '%s' ${esc_begin}
1377     printf '%s' "$*"
1378     printf '%s' "${esc_end}"
1379 }
1380
1381 # TODO: revise all these NO* variables and especially their documentation
1382 #       in zsh-help() below.
1383 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1384     [[ $NOPRECMD -gt 0 ]] && return 0
1385     # update VCS information
1386     (( ${+functions[vcs_info]} )) && vcs_info
1387
1388     if [[ $TERM == screen* ]] ; then
1389         if [[ -n ${vcs_info_msg_1_} ]] ; then
1390             ESC_print ${vcs_info_msg_1_}
1391         else
1392             ESC_print "zsh"
1393         fi
1394     fi
1395     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1396     if [[ ${DONTSETRPROMPT:-} -eq 0 ]] ; then
1397         if [[ $BATTERY -gt 0 ]] ; then
1398             # update battery (dropped into $PERCENT) information
1399             battery
1400             RPROMPT="%(?..:() ${PERCENT}"
1401         else
1402             RPROMPT="%(?..:() "
1403         fi
1404     fi
1405     # adjust title of xterm
1406     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1407     [[ ${NOTITLE:-} -gt 0 ]] && return 0
1408     case $TERM in
1409         (xterm*|rxvt*)
1410             set_title ${(%):-"%n@%m: %~"}
1411             ;;
1412     esac
1413 }
1414
1415 # preexec() => a function running before every command
1416 is4 && [[ $NOPRECMD -eq 0 ]] && \
1417 preexec () {
1418     [[ $NOPRECMD -gt 0 ]] && return 0
1419 # set hostname if not running on host with name 'grml'
1420     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1421        NAME="@$HOSTNAME"
1422     fi
1423 # get the name of the program currently running and hostname of local machine
1424 # set screen window title if running in a screen
1425     if [[ "$TERM" == screen* ]] ; then
1426         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1427         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1428         ESC_print ${CMD}
1429     fi
1430 # adjust title of xterm
1431     [[ ${NOTITLE} -gt 0 ]] && return 0
1432     case $TERM in
1433         (xterm*|rxvt*)
1434             set_title "${(%):-"%n@%m:"}" "$1"
1435             ;;
1436     esac
1437 }
1438
1439 EXITCODE="%(?..%?%1v )"
1440 # secondary prompt, printed when the shell needs more information to complete a
1441 # command.
1442 PS2='\`%_> '
1443 # selection prompt used within a select loop.
1444 PS3='?# '
1445 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1446 PS4='+%N:%i:%_> '
1447
1448 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1449 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1450     debian_chroot=$(cat /etc/debian_chroot)
1451 fi
1452
1453 # don't use colors on dumb terminals (like emacs):
1454 if [[ "$TERM" == dumb ]] ; then
1455     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
1456 else
1457     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended
1458     # prompt set variable identifying the chroot you work in (used in the
1459     # prompt below)
1460     if [[ $GRMLPROMPT -gt 0 ]] ; then
1461         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1462 ${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "
1463     else
1464         # This assembles the primary prompt string
1465         if (( EUID != 0 )); then
1466             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "
1467         else
1468             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "
1469         fi
1470     fi
1471 fi
1472
1473 PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
1474
1475 # if we are inside a grml-chroot set a specific prompt theme
1476 if [[ -n "$GRML_CHROOT" ]] ; then
1477     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1478 fi
1479
1480 # 'hash' some often used directories
1481 #d# start
1482 hash -d deb=/var/cache/apt/archives
1483 hash -d doc=/usr/share/doc
1484 hash -d linux=/lib/modules/$(command uname -r)/build/
1485 hash -d log=/var/log
1486 hash -d slog=/var/log/syslog
1487 hash -d src=/usr/src
1488 hash -d templ=/usr/share/doc/grml-templates
1489 hash -d tt=/usr/share/doc/texttools-doc
1490 hash -d www=/var/www
1491 #d# end
1492
1493 # some aliases
1494 if check_com -c screen ; then
1495     if [[ $UID -eq 0 ]] ; then
1496         if [[ -r /etc/grml/screenrc ]]; then
1497             alias screen="${commands[screen]} -c /etc/grml/screenrc"
1498         fi
1499     elif [[ -r $HOME/.screenrc ]] ; then
1500         alias screen="${commands[screen]} -c $HOME/.screenrc"
1501     else
1502         if [[ -r /etc/grml/screenrc_grml ]]; then
1503             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1504         else
1505             if [[ -r /etc/grml/screenrc ]]; then
1506                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
1507             fi
1508         fi
1509     fi
1510 fi
1511
1512 # do we have GNU ls with color-support?
1513 if [[ "$TERM" != dumb ]]; then
1514     #a1# execute \kbd{@a@}:\quad ls with colors
1515     alias ls='ls -b -CF '${ls_options:+"${ls_options[*]}"}
1516     #a1# execute \kbd{@a@}:\quad list all files, with colors
1517     alias la='ls -la '${ls_options:+"${ls_options[*]}"}
1518     #a1# long colored list, without dotfiles (@a@)
1519     alias ll='ls -l '${ls_options:+"${ls_options[*]}"}
1520     #a1# long colored list, human readable sizes (@a@)
1521     alias lh='ls -hAl '${ls_options:+"${ls_options[*]}"}
1522     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1523     alias l='ls -lF '${ls_options:+"${ls_options[*]}"}
1524 else
1525     alias ls='ls -b -CF'
1526     alias la='ls -la'
1527     alias ll='ls -l'
1528     alias lh='ls -hAl'
1529     alias l='ls -lF'
1530 fi
1531
1532 alias mdstat='cat /proc/mdstat'
1533 alias ...='cd ../../'
1534
1535 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1536 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1537     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1538 fi
1539
1540 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1541 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1542 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1543
1544 # make sure it is not assigned yet
1545 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1546 utf2iso() {
1547     if isutfenv ; then
1548         for ENV in $(env | command grep -i '.utf') ; do
1549             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1550         done
1551     fi
1552 }
1553
1554 # make sure it is not assigned yet
1555 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1556 iso2utf() {
1557     if ! isutfenv ; then
1558         for ENV in $(env | command grep -i '\.iso') ; do
1559             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1560         done
1561     fi
1562 }
1563
1564 # especially for roadwarriors using GNU screen and ssh:
1565 if ! check_com asc &>/dev/null ; then
1566   asc() { autossh -t "$@" 'screen -RdU' }
1567   compdef asc=ssh
1568 fi
1569
1570 #f1# Hints for the use of zsh on grml
1571 zsh-help() {
1572     print "$bg[white]$fg[black]
1573 zsh-help - hints for use of zsh on grml
1574 =======================================$reset_color"
1575
1576     print '
1577 Main configuration of zsh happens in /etc/zsh/zshrc.
1578 That file is part of the package grml-etc-core, if you want to
1579 use them on a non-grml-system just get the tar.gz from
1580 http://deb.grml.org/ or (preferably) get it from the git repository:
1581
1582   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1583
1584 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1585 The file is still there, but it is empty for backwards compatibility.
1586
1587 For your own changes use these two files:
1588     $HOME/.zshrc.pre
1589     $HOME/.zshrc.local
1590
1591 The former is sourced very early in our zshrc, the latter is sourced
1592 very lately.
1593
1594 System wide configuration without touching configuration files of grml
1595 can take place in /etc/zsh/zshrc.local.
1596
1597 For information regarding zsh start at http://grml.org/zsh/
1598
1599 Take a look at grml'\''s zsh refcard:
1600 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1601
1602 Check out the main zsh refcard:
1603 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1604
1605 And of course visit the zsh-lovers:
1606 % man zsh-lovers
1607
1608 You can adjust some options through environment variables when
1609 invoking zsh without having to edit configuration files.
1610 Basically meant for bash users who are not used to the power of
1611 the zsh yet. :)
1612
1613   "NOCOR=1    zsh" => deactivate automatic correction
1614   "NOMENU=1   zsh" => do not use auto menu completion
1615                       (note: use ctrl-d for completion instead!)
1616   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1617   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1618                       preexec() and precmd() completely
1619   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1620   "COMMAND_NOT_FOUND=1 zsh"
1621                    => Enable a handler if an external command was not found
1622                       The command called in the handler can be altered by setting
1623                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1624                       "/usr/share/command-not-found/command-not-found"
1625
1626 A value greater than 0 is enables a feature; a value equal to zero
1627 disables it. If you like one or the other of these settings, you can
1628 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1629 zshrc.'
1630
1631     print "
1632 $bg[white]$fg[black]
1633 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1634 Enjoy your grml system with the zsh!$reset_color"
1635 }
1636
1637 # debian stuff
1638 if [[ -r /etc/debian_version ]] ; then
1639     #a3# Execute \kbd{apt-cache search}
1640     alias acs='apt-cache search'
1641     #a3# Execute \kbd{apt-cache show}
1642     alias acsh='apt-cache show'
1643     #a3# Execute \kbd{apt-cache policy}
1644     alias acp='apt-cache policy'
1645     #a3# Execute \kbd{apt-get dist-upgrade}
1646     salias adg="apt-get dist-upgrade"
1647     #a3# Execute \kbd{apt-get install}
1648     salias agi="apt-get install"
1649     #a3# Execute \kbd{aptitude install}
1650     salias ati="aptitude install"
1651     #a3# Execute \kbd{apt-get upgrade}
1652     salias ag="apt-get upgrade"
1653     #a3# Execute \kbd{apt-get update}
1654     salias au="apt-get update"
1655     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1656     salias -a up="aptitude update ; aptitude safe-upgrade"
1657     #a3# Execute \kbd{dpkg-buildpackage}
1658     alias dbp='dpkg-buildpackage'
1659     #a3# Execute \kbd{grep-excuses}
1660     alias ge='grep-excuses'
1661
1662     # get a root shell as normal user in live-cd mode:
1663     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1664        alias su="sudo su"
1665      fi
1666
1667     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1668     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1669     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1670     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1671 fi
1672
1673 # sort installed Debian-packages by size
1674 if check_com -c dpkg-query ; then
1675     #a3# List installed Debian-packages sorted by size
1676     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1677 fi
1678
1679 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1680 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1681     if check_com -c wodim; then
1682         cdrecord() {
1683             cat <<EOMESS
1684 cdrecord is not provided under its original name by Debian anymore.
1685 See #377109 in the BTS of Debian for more details.
1686
1687 Please use the wodim binary instead
1688 EOMESS
1689             return 1
1690         }
1691     fi
1692 fi
1693
1694 # Use hard limits, except for a smaller stack and no core dumps
1695 unlimit
1696 is425 && limit stack 8192
1697 isgrmlcd && limit core 0 # important for a live-cd-system
1698 limit -s
1699
1700 # completion system
1701
1702 # called later (via is4 && grmlcomp)
1703 # note: use 'zstyle' for getting current settings
1704 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
1705 grmlcomp() {
1706     # TODO: This could use some additional information
1707
1708     # allow one error for every three characters typed in approximate completer
1709     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1710
1711     # don't complete backup files as executables
1712     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1713
1714     # start menu completion only if it could find no unambiguous initial string
1715     zstyle ':completion:*:correct:*'       insert-unambiguous true
1716     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1717     zstyle ':completion:*:correct:*'       original true
1718
1719     # activate color-completion
1720     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1721
1722     # format on completion
1723     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1724
1725     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1726     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1727
1728     # insert all expansions for expand completer
1729     zstyle ':completion:*:expand:*'        tag-order all-expansions
1730     zstyle ':completion:*:history-words'   list false
1731
1732     # activate menu
1733     zstyle ':completion:*:history-words'   menu yes
1734
1735     # ignore duplicate entries
1736     zstyle ':completion:*:history-words'   remove-all-dups yes
1737     zstyle ':completion:*:history-words'   stop yes
1738
1739     # match uppercase from lowercase
1740     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1741
1742     # separate matches into groups
1743     zstyle ':completion:*:matches'         group 'yes'
1744     zstyle ':completion:*'                 group-name ''
1745
1746     if [[ "$NOMENU" -eq 0 ]] ; then
1747         # if there are more than 5 options allow selecting from a menu
1748         zstyle ':completion:*'               menu select=5
1749     else
1750         # don't use any menus at all
1751         setopt no_auto_menu
1752     fi
1753
1754     zstyle ':completion:*:messages'        format '%d'
1755     zstyle ':completion:*:options'         auto-description '%d'
1756
1757     # describe options in full
1758     zstyle ':completion:*:options'         description 'yes'
1759
1760     # on processes completion complete all user processes
1761     zstyle ':completion:*:processes'       command 'ps -au$USER'
1762
1763     # offer indexes before parameters in subscripts
1764     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1765
1766     # provide verbose completion information
1767     zstyle ':completion:*'                 verbose true
1768
1769     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1770     # for commands (read: 1st word in the line) that it will list for the user
1771     # to choose from. The following disables that, because it's not exactly fast.
1772     zstyle ':completion:*:-command-:*:'    verbose false
1773
1774     # set format for warnings
1775     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1776
1777     # define files to ignore for zcompile
1778     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1779     zstyle ':completion:correct:'          prompt 'correct to: %e'
1780
1781     # Ignore completion functions for commands you don't have:
1782     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1783
1784     # Provide more processes in completion of programs like killall:
1785     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1786
1787     # complete manual by their section
1788     zstyle ':completion:*:manuals'    separate-sections true
1789     zstyle ':completion:*:manuals.*'  insert-sections   true
1790     zstyle ':completion:*:man:*'      menu yes select
1791
1792     # Search path for sudo completion
1793     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
1794                                                /usr/local/bin  \
1795                                                /usr/sbin       \
1796                                                /usr/bin        \
1797                                                /sbin           \
1798                                                /bin            \
1799                                                /usr/X11R6/bin
1800
1801     # provide .. as a completion
1802     zstyle ':completion:*' special-dirs ..
1803
1804     # run rehash on completion so new installed program are found automatically:
1805     _force_rehash() {
1806         (( CURRENT == 1 )) && rehash
1807         return 1
1808     }
1809
1810     ## correction
1811     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1812     if [[ "$NOCOR" -gt 0 ]] ; then
1813         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1814         setopt nocorrect
1815     else
1816         # try to be smart about when to use what completer...
1817         setopt correct
1818         zstyle -e ':completion:*' completer '
1819             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1820                 _last_try="$HISTNO$BUFFER$CURSOR"
1821                 reply=(_complete _match _ignored _prefix _files)
1822             else
1823                 if [[ $words[1] == (rm|mv) ]] ; then
1824                     reply=(_complete _files)
1825                 else
1826                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1827                 fi
1828             fi'
1829     fi
1830
1831     # command for process lists, the local web server details and host completion
1832     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1833
1834     # caching
1835     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1836                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1837
1838     # host completion
1839     if is42 ; then
1840         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1841         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1842     else
1843         _ssh_hosts=()
1844         _etc_hosts=()
1845     fi
1846     hosts=(
1847         $(hostname)
1848         "$_ssh_hosts[@]"
1849         "$_etc_hosts[@]"
1850         localhost
1851     )
1852     zstyle ':completion:*:hosts' hosts $hosts
1853     # TODO: so, why is this here?
1854     #  zstyle '*' hosts $hosts
1855
1856     # use generic completion system for programs not yet defined; (_gnu_generic works
1857     # with commands that provide a --help option with "standard" gnu-like output.)
1858     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
1859                    pal stow tail uname ; do
1860         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
1861     done; unset compcom
1862
1863     # see upgrade function in this file
1864     compdef _hosts upgrade
1865 }
1866
1867 # grmlstuff
1868 grmlstuff() {
1869 # people should use 'grml-x'!
1870     if check_com -c 915resolution; then
1871         855resolution() {
1872             echo "Please use 915resolution as resolution modifying tool for Intel \
1873 graphic chipset."
1874             return -1
1875         }
1876     fi
1877
1878     #a1# Output version of running grml
1879     alias grml-version='cat /etc/grml_version'
1880
1881     if check_com -c rebuildfstab ; then
1882         #a1# Rebuild /etc/fstab
1883         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1884     fi
1885
1886     if check_com -c grml-debootstrap ; then
1887         debian2hd() {
1888             echo "Installing debian to harddisk is possible by using grml-debootstrap."
1889             return 1
1890         }
1891     fi
1892 }
1893
1894 # now run the functions
1895 isgrml && checkhome
1896 is4    && isgrml    && grmlstuff
1897 is4    && grmlcomp
1898
1899 # keephack
1900 is4 && xsource "/etc/zsh/keephack"
1901
1902 # wonderful idea of using "e" glob qualifier by Peter Stephenson
1903 # You use it as follows:
1904 # $ NTREF=/reference/file
1905 # $ ls -l *(e:nt:)
1906 # This lists all the files in the current directory newer than the reference file.
1907 # You can also specify the reference file inline; note quotes:
1908 # $ ls -l *(e:'nt ~/.zshenv':)
1909 is4 && nt() {
1910     if [[ -n $1 ]] ; then
1911         local NTREF=${~1}
1912     fi
1913     [[ $REPLY -nt $NTREF ]]
1914 }
1915
1916 # shell functions
1917
1918 #f1# Reload an autoloadable function
1919 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1920 compdef _functions freload
1921
1922 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1923 sll() {
1924     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1925     for file in "$@" ; do
1926         while [[ -h "$file" ]] ; do
1927             ls -l $file
1928             file=$(readlink "$file")
1929         done
1930     done
1931 }
1932
1933 # TODO: Is it supported to use pager settings like this?
1934 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
1935 # with respect to wordsplitting. (ie. ${=PAGER})
1936 if check_com -c $PAGER ; then
1937     #f1# View Debian's changelog of a given package
1938     dchange() {
1939         emulate -L zsh
1940         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
1941             $PAGER /usr/share/doc/$1/changelog.Debian.gz
1942         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1943             $PAGER /usr/share/doc/$1/changelog.gz
1944         else
1945             if check_com -c aptitude ; then
1946                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1947                 if isgrml ; then
1948                     aptitude -t unstable changelog $1
1949                 else
1950                     aptitude changelog $1
1951                 fi
1952             else
1953                 echo "No changelog for package $1 found, sorry."
1954                 return 1
1955             fi
1956         fi
1957     }
1958     _dchange() { _files -W /usr/share/doc -/ }
1959     compdef _dchange dchange
1960
1961     #f1# View Debian's NEWS of a given package
1962     dnews() {
1963         emulate -L zsh
1964         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
1965             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
1966         else
1967             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
1968                 $PAGER /usr/share/doc/$1/NEWS.gz
1969             else
1970                 echo "No NEWS file for package $1 found, sorry."
1971                 return 1
1972             fi
1973         fi
1974     }
1975     _dnews() { _files -W /usr/share/doc -/ }
1976     compdef _dnews dnews
1977
1978     #f1# View Debian's copyright of a given package
1979     dcopyright() {
1980         emulate -L zsh
1981         if [[ -r /usr/share/doc/$1/copyright ]] ; then
1982             $PAGER /usr/share/doc/$1/copyright
1983         else
1984             echo "No copyright file for package $1 found, sorry."
1985             return 1
1986         fi
1987     }
1988     _dcopyright() { _files -W /usr/share/doc -/ }
1989     compdef _dcopyright dcopyright
1990
1991     #f1# View upstream's changelog of a given package
1992     uchange() {
1993         emulate -L zsh
1994         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1995             $PAGER /usr/share/doc/$1/changelog.gz
1996         else
1997             echo "No changelog for package $1 found, sorry."
1998             return 1
1999         fi
2000     }
2001     _uchange() { _files -W /usr/share/doc -/ }
2002     compdef _uchange uchange
2003 fi
2004
2005 # zsh profiling
2006 profile() {
2007     ZSH_PROFILE_RC=1 $SHELL "$@"
2008 }
2009
2010 #f1# Edit an alias via zle
2011 edalias() {
2012     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2013 }
2014 compdef _aliases edalias
2015
2016 #f1# Edit a function via zle
2017 edfunc() {
2018     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2019 }
2020 compdef _functions edfunc
2021
2022 # use it e.g. via 'Restart apache2'
2023 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2024 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2025 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2026 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2027 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2028 #m# f6 Status() \kbd{/etc/init.d/\em{process}}\quad\kbd{status}
2029 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2030     __start_stop() {
2031         local action_="${1:l}"  # e.g Start/Stop/Restart
2032         local service_="$2"
2033         local param_="$3"
2034
2035         local service_target_="$(readlink /etc/init.d/$service_)"
2036         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2037             # runit
2038             case "${action_}" in
2039                 start) if [[ ! -e /etc/service/$service_ ]]; then
2040                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2041                        else
2042                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2043                        fi ;;
2044                 # there is no reload in runits sysv emulation
2045                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2046                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2047             esac
2048         else
2049             # sysvinit
2050             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2051         fi
2052     }
2053
2054     _grmlinitd() {
2055         local -a scripts
2056         scripts=( /etc/init.d/*(x:t) )
2057         _describe "service startup script" scripts
2058     }
2059
2060     for i in Start Restart Stop Force-Reload Reload Status ; do
2061         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2062         compdef _grmlinitd $i
2063     done
2064 fi
2065
2066 #f1# Provides useful information on globbing
2067 H-Glob() {
2068     echo -e "
2069     /      directories
2070     .      plain files
2071     @      symbolic links
2072     =      sockets
2073     p      named pipes (FIFOs)
2074     *      executable plain files (0100)
2075     %      device files (character or block special)
2076     %b     block special files
2077     %c     character special files
2078     r      owner-readable files (0400)
2079     w      owner-writable files (0200)
2080     x      owner-executable files (0100)
2081     A      group-readable files (0040)
2082     I      group-writable files (0020)
2083     E      group-executable files (0010)
2084     R      world-readable files (0004)
2085     W      world-writable files (0002)
2086     X      world-executable files (0001)
2087     s      setuid files (04000)
2088     S      setgid files (02000)
2089     t      files with the sticky bit (01000)
2090
2091   print *(m-1)          # Files modified up to a day ago
2092   print *(a1)           # Files accessed a day ago
2093   print *(@)            # Just symlinks
2094   print *(Lk+50)        # Files bigger than 50 kilobytes
2095   print *(Lk-50)        # Files smaller than 50 kilobytes
2096   print **/*.c          # All *.c files recursively starting in \$PWD
2097   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2098   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2099   print *~*.*           # All Files that do not contain a dot
2100   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2101   print -l *(.c|.h)     # Lists *.c and *.h
2102   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2103   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2104 }
2105 alias help-zshglob=H-Glob
2106
2107 #v1# set number of lines to display per page
2108 HELP_LINES_PER_PAGE=20
2109 #v1# set location of help-zle cache file
2110 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
2111 #f1# helper function for help-zle, actually generates the help text
2112 help_zle_parse_keybindings()
2113 {
2114     emulate -L zsh
2115     setopt extendedglob
2116     unsetopt ksharrays  #indexing starts at 1
2117
2118     #v1# choose files that help-zle will parse for keybindings
2119     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
2120
2121     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
2122         local load_cache=0
2123         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
2124         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
2125     fi
2126
2127     #fill with default keybindings, possibly to be overwriten in a file later
2128     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2129     local -A help_zle_keybindings
2130     help_zle_keybindings['<Ctrl>@']="set MARK"
2131     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
2132     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
2133     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
2134     help_zle_keybindings['<Ctrl>_']="undo"
2135     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
2136     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
2137     help_zle_keybindings['<Ctrl>e']="goto end of line"
2138     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2139     help_zle_keybindings['<Alt>t']="transpose words"
2140     help_zle_keybindings['<Alt>s']="spellcheck word"
2141     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
2142     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
2143     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2144     help_zle_keybindings["<Alt>'"]="quote line"
2145     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2146     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2147     help_zle_keybindings['<Alt>u']="make next word Uppercase"
2148     help_zle_keybindings['<Alt>l']="make next word lowercase"
2149     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
2150     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2151     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2152     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2153     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2154     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
2155     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2156     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2157     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
2158
2159     #init global variables
2160     unset help_zle_lines help_zle_sln
2161     typeset -g -a help_zle_lines
2162     typeset -g help_zle_sln=1
2163
2164     local k v
2165     local lastkeybind_desc contents     #last description starting with #k# that we found
2166     local num_lines_elapsed=0            #number of lines between last description and keybinding
2167     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2168     for f in $HELPZLE_KEYBINDING_FILES; do
2169         [[ -r "$f" ]] || continue   #not readable ? skip it
2170         contents="$(<$f)"
2171         for cline in "${(f)contents}"; do
2172             #zsh pattern: matches lines like: #k# ..............
2173             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2174                 lastkeybind_desc="$match[*]"
2175                 num_lines_elapsed=0
2176             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2177             #             ignores lines that are commentend out
2178             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2179             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2180                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2181                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2182                     #substitute keybinding string with something readable
2183                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2184                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2185                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2186                     help_zle_keybindings[${k}]=$lastkeybind_desc
2187                 fi
2188                 lastkeybind_desc=""
2189             else
2190               ((num_lines_elapsed++))
2191             fi
2192         done
2193     done
2194     unset contents
2195     #calculate length of keybinding column
2196     local kstrlen=0
2197     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2198     #convert the assoc array into preformated lines, which we are able to sort
2199     for k v in ${(kv)help_zle_keybindings[@]}; do
2200         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2201         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2202     done
2203     #sort lines alphabetically
2204     help_zle_lines=("${(i)help_zle_lines[@]}")
2205     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2206     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2207     zcompile $HELP_ZLE_CACHE_FILE
2208 }
2209 typeset -g help_zle_sln
2210 typeset -g -a help_zle_lines
2211
2212 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2213 help-zle()
2214 {
2215     emulate -L zsh
2216     unsetopt ksharrays  #indexing starts at 1
2217     #help lines already generated ? no ? then do it
2218     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2219     #already displayed all lines ? go back to the start
2220     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2221     local sln=$help_zle_sln
2222     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2223     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2224     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2225 }
2226 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2227 zle -N help-zle && bindkey '^xz' help-zle
2228
2229 # grep for running process, like: 'any vim'
2230 any() {
2231     emulate -L zsh
2232     unsetopt KSH_ARRAYS
2233     if [[ -z "$1" ]] ; then
2234         echo "any - grep for process(es) by keyword" >&2
2235         echo "Usage: any <keyword>" >&2 ; return 1
2236     else
2237         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
2238     fi
2239 }
2240
2241
2242 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2243 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2244 [[ -r /proc/1/maps ]] && \
2245 deswap() {
2246     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2247     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2248     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2249 }
2250
2251 # a wrapper for vim, that deals with title setting
2252 #   VIM_OPTIONS
2253 #       set this array to a set of options to vim you always want
2254 #       to have set when calling vim (in .zshrc.local), like:
2255 #           VIM_OPTIONS=( -p )
2256 #       This will cause vim to send every file given on the
2257 #       commandline to be send to it's own tab (needs vim7).
2258 if check_com vim; then
2259     vim() {
2260         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2261     }
2262 fi
2263
2264 # make a backup of a file
2265 bk() {
2266     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2267 }
2268
2269 ssl_hashes=( sha512 sha256 sha1 md5 )
2270
2271 for sh in ${ssl_hashes}; do
2272     eval 'ssl-cert-'${sh}'() {
2273         emulate -L zsh
2274         if [[ -z $1 ]] ; then
2275             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2276             return 1
2277         fi
2278         openssl x509 -noout -fingerprint -'${sh}' -in $1
2279     }'
2280 done; unset sh
2281
2282 ssl-cert-fingerprints() {
2283     emulate -L zsh
2284     local i
2285     if [[ -z $1 ]] ; then
2286         printf 'usage: ssl-cert-fingerprints <file>\n'
2287         return 1
2288     fi
2289     for i in ${ssl_hashes}
2290         do ssl-cert-$i $1;
2291     done
2292 }
2293
2294 ssl-cert-info() {
2295     emulate -L zsh
2296     if [[ -z $1 ]] ; then
2297         printf 'usage: ssl-cert-info <file>\n'
2298         return 1
2299     fi
2300     openssl x509 -noout -text -in $1
2301     ssl-cert-fingerprints $1
2302 }
2303
2304 # make sure our environment is clean regarding colors
2305 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2306
2307 # "persistent history"
2308 # just write important commands you always need to ~/.important_commands
2309 if [[ -r ~/.important_commands ]] ; then
2310     fc -R ~/.important_commands
2311 fi
2312
2313 # load the lookup subsystem if it's available on the system
2314 zrcautoload lookupinit && lookupinit
2315
2316 # variables
2317
2318 # set terminal property (used e.g. by msgid-chooser)
2319 export COLORTERM="yes"
2320
2321 # aliases
2322
2323 # general
2324 #a2# Execute \kbd{du -sch}
2325 alias da='du -sch'
2326 #a2# Execute \kbd{jobs -l}
2327 alias j='jobs -l'
2328
2329 # listing stuff
2330 #a2# Execute \kbd{ls -lSrah}
2331 alias dir="ls -lSrah"
2332 #a2# Only show dot-directories
2333 alias lad='ls -d .*(/)'
2334 #a2# Only show dot-files
2335 alias lsa='ls -a .*(.)'
2336 #a2# Only files with setgid/setuid/sticky flag
2337 alias lss='ls -l *(s,S,t)'
2338 #a2# Only show symlinks
2339 alias lsl='ls -l *(@)'
2340 #a2# Display only executables
2341 alias lsx='ls -l *(*)'
2342 #a2# Display world-{readable,writable,executable} files
2343 alias lsw='ls -ld *(R,W,X.^ND/)'
2344 #a2# Display the ten biggest files
2345 alias lsbig="ls -flh *(.OL[1,10])"
2346 #a2# Only show directories
2347 alias lsd='ls -d *(/)'
2348 #a2# Only show empty directories
2349 alias lse='ls -d *(/^F)'
2350 #a2# Display the ten newest files
2351 alias lsnew="ls -rtlh *(D.om[1,10])"
2352 #a2# Display the ten oldest files
2353 alias lsold="ls -rtlh *(D.Om[1,10])"
2354 #a2# Display the ten smallest files
2355 alias lssmall="ls -Srl *(.oL[1,10])"
2356 #a2# Display the ten newest directories and ten newest .directories
2357 alias lsnewdir="ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
2358 #a2# Display the ten oldest directories and ten oldest .directories
2359 alias lsolddir="ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
2360
2361 # some useful aliases
2362 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir $OLDCWD}
2363 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2364
2365 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2366 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2367 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2368
2369 # work around non utf8 capable software in utf environment via $LANG and luit
2370 if check_com isutfenv && check_com luit ; then
2371     if check_com -c mrxvt ; then
2372         isutfenv && [[ -n "$LANG" ]] && \
2373             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2374     fi
2375
2376     if check_com -c aterm ; then
2377         isutfenv && [[ -n "$LANG" ]] && \
2378             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2379     fi
2380
2381     if check_com -c centericq ; then
2382         isutfenv && [[ -n "$LANG" ]] && \
2383             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2384     fi
2385 fi
2386
2387 # useful functions
2388
2389 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2390 bk() {
2391     emulate -L zsh
2392     cp -b $1 $1_`date --iso-8601=m`
2393 }
2394
2395 #f5# cd to directoy and list files
2396 cl() {
2397     emulate -L zsh
2398     cd $1 && ls -a
2399 }
2400
2401 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2402 cd() {
2403     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2404         [[ ! -e ${1:h} ]] && return 1
2405         print "Correcting ${1} to ${1:h}"
2406         builtin cd ${1:h}
2407     else
2408         builtin cd "$@"
2409     fi
2410 }
2411
2412 #f5# Create Directoy and \kbd{cd} to it
2413 mkcd() {
2414     if (( ARGC != 1 )); then
2415         printf 'usage: mkcd <new-directory>\n'
2416         return 1;
2417     fi
2418     if [[ ! -d "$1" ]]; then
2419         command mkdir -p "$1"
2420     else
2421         printf '`%s'\'' already exists: cd-ing.\n' "$1"
2422     fi
2423     builtin cd "$1"
2424 }
2425
2426 #f5# Create temporary directory and \kbd{cd} to it
2427 cdt() {
2428     local t
2429     t=$(mktemp -d)
2430     echo "$t"
2431     builtin cd "$t"
2432 }
2433
2434 #f5# Create directory under cursor or the selected area
2435 # Press ctrl-xM to create the directory under the cursor or the selected area.
2436 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2437 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2438 # directory does not exist yet -> press ctrl-XM and problem solved
2439 inplaceMkDirs() {
2440     local PATHTOMKDIR
2441     if ((REGION_ACTIVE==1)); then
2442         local F=$MARK T=$CURSOR
2443         if [[ $F -gt $T ]]; then
2444             F=${CURSOR}
2445             T=${MARK}
2446         fi
2447         # get marked area from buffer and eliminate whitespace
2448         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2449         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2450     else
2451         local bufwords iword
2452         bufwords=(${(z)LBUFFER})
2453         iword=${#bufwords}
2454         bufwords=(${(z)BUFFER})
2455         PATHTOMKDIR="${(Q)bufwords[iword]}"
2456     fi
2457     [[ -z "${PATHTOMKDIR}" ]] && return 1
2458     PATHTOMKDIR=${~PATHTOMKDIR}
2459     if [[ -e "${PATHTOMKDIR}" ]]; then
2460         zle -M " path already exists, doing nothing"
2461     else
2462         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2463         zle end-of-line
2464     fi
2465 }
2466 #k# mkdir -p <dir> from string under cursor or marked area
2467 zle -N inplaceMkDirs && bindkey '^xM' inplaceMkDirs
2468
2469 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2470 accessed() {
2471     emulate -L zsh
2472     print -l -- *(a-${1:-1})
2473 }
2474
2475 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2476 changed() {
2477     emulate -L zsh
2478     print -l -- *(c-${1:-1})
2479 }
2480
2481 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2482 modified() {
2483     emulate -L zsh
2484     print -l -- *(m-${1:-1})
2485 }
2486 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2487 check_com new || alias new=modified
2488
2489 # use colors when GNU grep with color-support
2490 #a2# Execute \kbd{grep -{}-color=auto}
2491 (( $#grep_options > 0 )) && alias grep='grep '${grep_options:+"${grep_options[*]}"}
2492
2493 # Translate DE<=>EN
2494 # 'translate' looks up fot a word in a file with language-to-language
2495 # translations (field separator should be " : "). A typical wordlist looks
2496 # like at follows:
2497 #  | english-word : german-transmission
2498 # It's also only possible to translate english to german but not reciprocal.
2499 # Use the following oneliner to turn back the sort order:
2500 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2501 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2502 #f5# Translates a word
2503 trans() {
2504     emulate -L zsh
2505     case "$1" in
2506         -[dD]*)
2507             translate -l de-en $2
2508             ;;
2509         -[eE]*)
2510             translate -l en-de $2
2511             ;;
2512         *)
2513             echo "Usage: $0 { -D | -E }"
2514             echo "         -D == German to English"
2515             echo "         -E == English to German"
2516     esac
2517 }
2518
2519 # Usage: simple-extract <file>
2520 # Using option -d deletes the original archive file.
2521 #f5# Smart archive extractor
2522 simple-extract() {
2523     emulate -L zsh
2524     setopt extended_glob noclobber
2525     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2526     local RC=0
2527     zparseopts -D -E "d=DELETE_ORIGINAL"
2528     for ARCHIVE in "${@}"; do
2529         case $ARCHIVE in
2530             *(tar.bz2|tbz2|tbz))
2531                 DECOMP_CMD="tar -xvjf -"
2532                 USES_STDIN=true
2533                 USES_STDOUT=false
2534                 ;;
2535             *(tar.gz|tgz))
2536                 DECOMP_CMD="tar -xvzf -"
2537                 USES_STDIN=true
2538                 USES_STDOUT=false
2539                 ;;
2540             *(tar.xz|txz|tar.lzma))
2541                 DECOMP_CMD="tar -xvJf -"
2542                 USES_STDIN=true
2543                 USES_STDOUT=false
2544                 ;;
2545             *tar)
2546                 DECOMP_CMD="tar -xvf -"
2547                 USES_STDIN=true
2548                 USES_STDOUT=false
2549                 ;;
2550             *rar)
2551                 DECOMP_CMD="unrar x"
2552                 USES_STDIN=false
2553                 USES_STDOUT=false
2554                 ;;
2555             *lzh)
2556                 DECOMP_CMD="lha x"
2557                 USES_STDIN=false
2558                 USES_STDOUT=false
2559                 ;;
2560             *7z)
2561                 DECOMP_CMD="7z x"
2562                 USES_STDIN=false
2563                 USES_STDOUT=false
2564                 ;;
2565             *(zip|jar))
2566                 DECOMP_CMD="unzip"
2567                 USES_STDIN=false
2568                 USES_STDOUT=false
2569                 ;;
2570             *deb)
2571                 DECOMP_CMD="ar -x"
2572                 USES_STDIN=false
2573                 USES_STDOUT=false
2574                 ;;
2575             *bz2)
2576                 DECOMP_CMD="bzip2 -d -c -"
2577                 USES_STDIN=true
2578                 USES_STDOUT=true
2579                 ;;
2580             *(gz|Z))
2581                 DECOMP_CMD="gzip -d -c -"
2582                 USES_STDIN=true
2583                 USES_STDOUT=true
2584                 ;;
2585             *(xz|lzma))
2586                 DECOMP_CMD="xz -d -c -"
2587                 USES_STDIN=true
2588                 USES_STDOUT=true
2589                 ;;
2590             *)
2591                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2592                 RC=$((RC+1))
2593                 continue
2594                 ;;
2595         esac
2596
2597         if ! check_com ${DECOMP_CMD[(w)1]}; then
2598             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2599             RC=$((RC+2))
2600             continue
2601         fi
2602
2603         GZTARGET="${ARCHIVE:t:r}"
2604         if [[ -f $ARCHIVE ]] ; then
2605
2606             print "Extracting '$ARCHIVE' ..."
2607             if $USES_STDIN; then
2608                 if $USES_STDOUT; then
2609                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
2610                 else
2611                     ${=DECOMP_CMD} < "$ARCHIVE"
2612                 fi
2613             else
2614                 if $USES_STDOUT; then
2615                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
2616                 else
2617                     ${=DECOMP_CMD} "$ARCHIVE"
2618                 fi
2619             fi
2620             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
2621
2622         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
2623             if check_com curl; then
2624                 WGET_CMD="curl -L -k -s -o -"
2625             elif check_com wget; then
2626                 WGET_CMD="wget -q -O - --no-check-certificate"
2627             else
2628                 print "ERROR: neither wget nor curl is installed" >&2
2629                 RC=$((RC+4))
2630                 continue
2631             fi
2632             print "Downloading and Extracting '$ARCHIVE' ..."
2633             if $USES_STDIN; then
2634                 if $USES_STDOUT; then
2635                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
2636                     RC=$((RC+$?))
2637                 else
2638                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
2639                     RC=$((RC+$?))
2640                 fi
2641             else
2642                 if $USES_STDOUT; then
2643                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
2644                 else
2645                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
2646                 fi
2647             fi
2648
2649         else
2650             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
2651             RC=$((RC+8))
2652         fi
2653     done
2654     return $RC
2655 }
2656
2657 __archive_or_uri()
2658 {
2659     _alternative \
2660         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
2661         '_urls:Remote Archives:_urls'
2662 }
2663
2664 _simple_extract()
2665 {
2666     _arguments \
2667         '-d[delete original archivefile after extraction]' \
2668         '*:Archive Or Uri:__archive_or_uri'
2669 }
2670 compdef _simple_extract simple-extract
2671 alias se=simple-extract
2672
2673 #f5# Set all ulimit parameters to \kbd{unlimited}
2674 allulimit() {
2675     ulimit -c unlimited
2676     ulimit -d unlimited
2677     ulimit -f unlimited
2678     ulimit -l unlimited
2679     ulimit -n unlimited
2680     ulimit -s unlimited
2681     ulimit -t unlimited
2682 }
2683
2684 #f5# Change the xterm title from within GNU-screen
2685 xtrename() {
2686     emulate -L zsh
2687     if [[ $1 != "-f" ]] ; then
2688         if [[ -z ${DISPLAY} ]] ; then
2689             printf 'xtrename only makes sense in X11.\n'
2690             return 1
2691         fi
2692     else
2693         shift
2694     fi
2695     if [[ -z $1 ]] ; then
2696         printf 'usage: xtrename [-f] "title for xterm"\n'
2697         printf '  renames the title of xterm from _within_ screen.\n'
2698         printf '  also works without screen.\n'
2699         printf '  will not work if DISPLAY is unset, use -f to override.\n'
2700         return 0
2701     fi
2702     print -n "\eP\e]0;${1}\C-G\e\\"
2703     return 0
2704 }
2705
2706 # Create small urls via http://goo.gl using curl(1).
2707 # API reference: https://code.google.com/apis/urlshortener/
2708 function zurl() {
2709     emulate -L zsh
2710     setopt extended_glob
2711
2712     if [[ -z $1 ]]; then
2713         print "USAGE: zurl <URL>"
2714         return 1
2715     fi
2716
2717     local PN url prog api json contenttype item
2718     local -a data
2719     PN=$0
2720     url=$1
2721
2722     # Prepend 'http://' to given URL where necessary for later output.
2723     if [[ ${url} != http(s|)://* ]]; then
2724         url='http://'${url}
2725     fi
2726
2727     if check_com -c curl; then
2728         prog=curl
2729     else
2730         print "curl is not available, but mandatory for ${PN}. Aborting."
2731         return 1
2732     fi
2733     api='https://www.googleapis.com/urlshortener/v1/url'
2734     contenttype="Content-Type: application/json"
2735     json="{\"longUrl\": \"${url}\"}"
2736     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
2737     # Parse the response
2738     for item in "${data[@]}"; do
2739         case "$item" in
2740             ' '#'"id":'*)
2741                 item=${item#*: \"}
2742                 item=${item%\",*}
2743                 printf '%s\n' "$item"
2744                 return 0
2745                 ;;
2746         esac
2747     done
2748     return 1
2749 }
2750
2751 #f2# Find history events by search pattern and list them by date.
2752 whatwhen()  {
2753     emulate -L zsh
2754     local usage help ident format_l format_s first_char remain first last
2755     usage='USAGE: whatwhen [options] <searchstring> <search range>'
2756     help='Use `whatwhen -h'\'' for further explanations.'
2757     ident=${(l,${#${:-Usage: }},, ,)}
2758     format_l="${ident}%s\t\t\t%s\n"
2759     format_s="${format_l//(\\t)##/\\t}"
2760     # Make the first char of the word to search for case
2761     # insensitive; e.g. [aA]
2762     first_char=[${(L)1[1]}${(U)1[1]}]
2763     remain=${1[2,-1]}
2764     # Default search range is `-100'.
2765     first=${2:-\-100}
2766     # Optional, just used for `<first> <last>' given.
2767     last=$3
2768     case $1 in
2769         ("")
2770             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
2771             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2772         ;;
2773         (-h)
2774             printf '%s\n\n' ${usage}
2775             print 'OPTIONS:'
2776             printf $format_l '-h' 'show help text'
2777             print '\f'
2778             print 'SEARCH RANGE:'
2779             printf $format_l "'0'" 'the whole history,'
2780             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
2781             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
2782             printf '\n%s\n' 'EXAMPLES:'
2783             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
2784             printf $format_l 'whatwhen zsh -250'
2785             printf $format_l 'whatwhen foo 1 99'
2786         ;;
2787         (\?)
2788             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2789         ;;
2790         (*)
2791             # -l list results on stout rather than invoking $EDITOR.
2792             # -i Print dates as in YYYY-MM-DD.
2793             # -m Search for a - quoted - pattern within the history.
2794             fc -li -m "*${first_char}${remain}*" $first $last
2795         ;;
2796     esac
2797 }
2798
2799 # mercurial related stuff
2800 if check_com -c hg ; then
2801     # gnu like diff for mercurial
2802     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
2803     #f5# GNU like diff for mercurial
2804     hgdi() {
2805         emulate -L zsh
2806         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
2807     }
2808
2809     # build debian package
2810     #a2# Alias for \kbd{hg-buildpackage}
2811     alias hbp='hg-buildpackage'
2812
2813     # execute commands on the versioned patch-queue from the current repos
2814     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
2815
2816     # diffstat for specific version of a mercurial repository
2817     #   hgstat      => display diffstat between last revision and tip
2818     #   hgstat 1234 => display diffstat between revision 1234 and tip
2819     #f5# Diffstat for specific version of a mercurial repos
2820     hgstat() {
2821         emulate -L zsh
2822         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
2823     }
2824
2825 fi # end of check whether we have the 'hg'-executable
2826
2827 # grml-small cleanups
2828
2829 # The following is used to remove zsh-config-items that do not work
2830 # in grml-small by default.
2831 # If you do not want these adjustments (for whatever reason), set
2832 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
2833 # sources if it is there).
2834
2835 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
2836
2837     unset abk[V]
2838     unalias    'V'      &> /dev/null
2839     unfunction vman     &> /dev/null
2840     unfunction viless   &> /dev/null
2841     unfunction 2html    &> /dev/null
2842
2843     # manpages are not in grmlsmall
2844     unfunction manzsh   &> /dev/null
2845     unfunction man2     &> /dev/null
2846
2847 fi
2848
2849 zrclocal
2850
2851 ## genrefcard.pl settings
2852
2853 ### doc strings for external functions from files
2854 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
2855
2856 ### example: split functions-search 8,16,24,32
2857 #@# split functions-search 8
2858
2859 ## END OF FILE #################################################################
2860 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
2861 # Local variables:
2862 # mode: sh
2863 # End: