etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is439(){
 148     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 #f1# Checks whether or not you're running grml
 154 isgrml(){
 155     [[ -f /etc/grml_version ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running a grml cd
 160 isgrmlcd(){
 161     [[ -f /etc/grml_cd ]] && return 0
 162     return 1
 163 }
 164
 165 if isgrml ; then
 166 #f1# Checks whether or not you're running grml-small
 167     isgrmlsmall() {
 168         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 169             return 0
 170         fi
 171         return 1
 172     }
 173 else
 174     isgrmlsmall() { return 1 }
 175 fi
 176
 177 isdarwin(){
 178     [[ $OSTYPE == darwin* ]] && return 0
 179     return 1
 180 }
 181
 182 #f1# are we running within an utf environment?
 183 isutfenv() {
 184     case "$LANG $CHARSET $LANGUAGE" in
 185         *utf*) return 0 ;;
 186         *UTF*) return 0 ;;
 187         *)     return 1 ;;
 188     esac
 189 }
 190
 191 # check for user, if not running as root set $SUDO to sudo
 192 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 193
 194 # change directory to home on first invocation of zsh
 195 # important for rungetty -> autologin
 196 # Thanks go to Bart Schaefer!
 197 isgrml && checkhome() {
 198     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 199         export ALREADY_DID_CD_HOME=$HOME
 200         cd
 201     fi
 202 }
 203
 204 # check for zsh v3.1.7+
 205
 206 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 207      || ${ZSH_VERSION} == 3.<2->.<->*    \
 208      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 209
 210     printf '-!-\n'
 211     printf '-!- In this configuration we try to make use of features, that only\n'
 212     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 213     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 214     printf '-!- advanced features in all supported versions.\n'
 215     printf '-!-\n'
 216     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 217     printf '-!-\n'
 218     printf '-!- While this *may* work, it might as well fail.\n'
 219     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 220     printf '-!-\n'
 221     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 222     printf '-!- If it does today, you'\''ve been lucky.\n'
 223     printf '-!-\n'
 224     printf '-!- Ye been warned!\n'
 225     printf '-!-\n'
 226
 227     function zstyle() { : }
 228 fi
 229
 230 # autoload wrapper - use this one instead of autoload directly
 231 # We need to define this function as early as this, because autoloading
 232 # 'is-at-least()' needs it.
 233 function zrcautoload() {
 234     emulate -L zsh
 235     setopt extended_glob
 236     local fdir ffile
 237     local -i ffound
 238
 239     ffile=$1
 240     (( found = 0 ))
 241     for fdir in ${fpath} ; do
 242         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 243     done
 244
 245     (( ffound == 0 )) && return 1
 246     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 247         autoload -U ${ffile} || return 1
 248     else
 249         autoload ${ffile} || return 1
 250     fi
 251     return 0
 252 }
 253
 254 # Load is-at-least() for more precise version checks Note that this test will
 255 # *always* fail, if the is-at-least function could not be marked for
 256 # autoloading.
 257 zrcautoload is-at-least || is-at-least() { return 1 }
 258
 259 # set some important options (as early as possible)
 260
 261 # append history list to the history file; this is the default but we make sure
 262 # because it's required for share_history.
 263 setopt append_history
 264
 265 # import new commands from the history file also in other zsh-session
 266 is4 && setopt share_history
 267
 268 # save each command's beginning timestamp and the duration to the history file
 269 setopt extended_history
 270
 271 # If a new command line being added to the history list duplicates an older
 272 # one, the older command is removed from the list
 273 is4 && setopt histignorealldups
 274
 275 # remove command lines from the history list when the first character on the
 276 # line is a space
 277 setopt histignorespace
 278
 279 # if a command is issued that can't be executed as a normal command, and the
 280 # command is the name of a directory, perform the cd command to that directory.
 281 setopt auto_cd
 282
 283 # in order to use #, ~ and ^ for filename generation grep word
 284 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 285 # don't forget to quote '^', '~' and '#'!
 286 setopt extended_glob
 287
 288 # display PID when suspending processes as well
 289 setopt longlistjobs
 290
 291 # report the status of backgrounds jobs immediately
 292 setopt notify
 293
 294 # whenever a command completion is attempted, make sure the entire command path
 295 # is hashed first.
 296 setopt hash_list_all
 297
 298 # not just at the end
 299 setopt completeinword
 300
 301 # Don't send SIGHUP to background processes when the shell exits.
 302 setopt nohup
 303
 304 # make cd push the old directory onto the directory stack.
 305 setopt auto_pushd
 306
 307 # avoid "beep"ing
 308 setopt nobeep
 309
 310 # don't push the same dir twice.
 311 setopt pushd_ignore_dups
 312
 313 # * shouldn't match dotfiles. ever.
 314 setopt noglobdots
 315
 316 # use zsh style word splitting
 317 setopt noshwordsplit
 318
 319 # don't error out when unset parameters are used
 320 setopt unset
 321
 322 # setting some default values
 323 NOCOR=${NOCOR:-0}
 324 NOMENU=${NOMENU:-0}
 325 NOPRECMD=${NOPRECMD:-0}
 326 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 327 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 328 BATTERY=${BATTERY:-0}
 329 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 330 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 331
 332 # utility functions
 333 # this function checks if a command exists and returns either true
 334 # or false. This avoids using 'which' and 'whence', which will
 335 # avoid problems with aliases for which on certain weird systems. :-)
 336 # Usage: check_com [-c|-g] word
 337 #   -c  only checks for external commands
 338 #   -g  does the usual tests and also checks for global aliases
 339 check_com() {
 340     emulate -L zsh
 341     local -i comonly gatoo
 342
 343     if [[ $1 == '-c' ]] ; then
 344         (( comonly = 1 ))
 345         shift
 346     elif [[ $1 == '-g' ]] ; then
 347         (( gatoo = 1 ))
 348     else
 349         (( comonly = 0 ))
 350         (( gatoo = 0 ))
 351     fi
 352
 353     if (( ${#argv} != 1 )) ; then
 354         printf 'usage: check_com [-c] <command>\n' >&2
 355         return 1
 356     fi
 357
 358     if (( comonly > 0 )) ; then
 359         [[ -n ${commands[$1]}  ]] && return 0
 360         return 1
 361     fi
 362
 363     if   [[ -n ${commands[$1]}    ]] \
 364       || [[ -n ${functions[$1]}   ]] \
 365       || [[ -n ${aliases[$1]}     ]] \
 366       || [[ -n ${reswords[(r)$1]} ]] ; then
 367
 368         return 0
 369     fi
 370
 371     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 372         return 0
 373     fi
 374
 375     return 1
 376 }
 377
 378 # creates an alias and precedes the command with
 379 # sudo if $EUID is not zero.
 380 salias() {
 381     emulate -L zsh
 382     local only=0 ; local multi=0
 383     while [[ $1 == -* ]] ; do
 384         case $1 in
 385             (-o) only=1 ;;
 386             (-a) multi=1 ;;
 387             (--) shift ; break ;;
 388             (-h)
 389                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 390                 printf '  -h      shows this help text.\n'
 391                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 392                 printf '          be careful using this option.\n'
 393                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 394                 return 0
 395                 ;;
 396             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 397         esac
 398         shift
 399     done
 400
 401     if (( ${#argv} > 1 )) ; then
 402         printf 'Too many arguments %s\n' "${#argv}"
 403         return 1
 404     fi
 405
 406     key="${1%%\=*}" ;  val="${1#*\=}"
 407     if (( EUID == 0 )) && (( only == 0 )); then
 408         alias -- "${key}=${val}"
 409     elif (( EUID > 0 )) ; then
 410         (( multi > 0 )) && val="${val// ; / ; sudo }"
 411         alias -- "${key}=sudo ${val}"
 412     fi
 413
 414     return 0
 415 }
 416
 417 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 418 # usage: uprint foo
 419 #   Where foo is the *name* of the parameter you want printed.
 420 #   Note that foo is no typo; $foo would be wrong here!
 421 if ! is42 ; then
 422     uprint () {
 423         emulate -L zsh
 424         local -a u
 425         local w
 426         local parameter=$1
 427
 428         if [[ -z ${parameter} ]] ; then
 429             printf 'usage: uprint <parameter>\n'
 430             return 1
 431         fi
 432
 433         for w in ${(P)parameter} ; do
 434             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 435         done
 436
 437         builtin print -l $u
 438     }
 439 fi
 440
 441 # Check if we can read given files and source those we can.
 442 xsource() {
 443     if (( ${#argv} < 1 )) ; then
 444         printf 'usage: xsource FILE(s)...\n' >&2
 445         return 1
 446     fi
 447
 448     while (( ${#argv} > 0 )) ; do
 449         [[ -r "$1" ]] && source "$1"
 450         shift
 451     done
 452     return 0
 453 }
 454
 455 # Check if we can read a given file and 'cat(1)' it.
 456 xcat() {
 457     emulate -L zsh
 458     if (( ${#argv} != 1 )) ; then
 459         printf 'usage: xcat FILE\n' >&2
 460         return 1
 461     fi
 462
 463     [[ -r $1 ]] && cat $1
 464     return 0
 465 }
 466
 467 # Remove these functions again, they are of use only in these
 468 # setup files. This should be called at the end of .zshrc.
 469 xunfunction() {
 470     emulate -L zsh
 471     local -a funcs
 472     funcs=(salias xcat xsource xunfunction zrcautoload)
 473
 474     for func in $funcs ; do
 475         [[ -n ${functions[$func]} ]] \
 476             && unfunction $func
 477     done
 478     return 0
 479 }
 480
 481 # this allows us to stay in sync with grml's zshrc and put own
 482 # modifications in ~/.zshrc.local
 483 zrclocal() {
 484     xsource "/etc/zsh/zshrc.local"
 485     xsource "${HOME}/.zshrc.local"
 486     return 0
 487 }
 488
 489 # locale setup
 490 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 491     xsource "/etc/default/locale"
 492 fi
 493
 494 for var in LANG LC_ALL LC_MESSAGES ; do
 495     [[ -n ${(P)var} ]] && export $var
 496 done
 497
 498 xsource "/etc/sysconfig/keyboard"
 499
 500 TZ=$(xcat /etc/timezone)
 501
 502 # set some variables
 503 if check_com -c vim ; then
 504 #v#
 505     export EDITOR=${EDITOR:-vim}
 506 else
 507     export EDITOR=${EDITOR:-vi}
 508 fi
 509
 510 #v#
 511 export PAGER=${PAGER:-less}
 512
 513 #v#
 514 export MAIL=${MAIL:-/var/mail/$USER}
 515
 516 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 517 export SHELL='/bin/zsh'
 518
 519 # color setup for ls:
 520 check_com -c dircolors && eval $(dircolors -b)
 521 # color setup for ls on OS X:
 522 isdarwin && export CLICOLOR=1
 523
 524 # do MacPorts setup on darwin
 525 if isdarwin && [[ -d /opt/local ]]; then
 526     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 527     # zshenv.
 528     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 529     MANPATH="/opt/local/share/man:$MANPATH"
 530 fi
 531 # do Fink setup on darwin
 532 isdarwin && xsource /sw/bin/init.sh
 533
 534 # load our function and completion directories
 535 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 536     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 537     if [[ ${fpath} == '/usr/share/grml/zsh/functions' ]] ; then
 538         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 539             zrcautoload ${func:t}
 540         done
 541     fi
 542 done
 543 unset fdir func
 544
 545 # support colors in less
 546 export LESS_TERMCAP_mb=$'\E[01;31m'
 547 export LESS_TERMCAP_md=$'\E[01;31m'
 548 export LESS_TERMCAP_me=$'\E[0m'
 549 export LESS_TERMCAP_se=$'\E[0m'
 550 export LESS_TERMCAP_so=$'\E[01;44;33m'
 551 export LESS_TERMCAP_ue=$'\E[0m'
 552 export LESS_TERMCAP_us=$'\E[01;32m'
 553
 554 # mailchecks
 555 MAILCHECK=30
 556
 557 # report about cpu-/system-/user-time of command if running longer than
 558 # 5 seconds
 559 REPORTTIME=5
 560
 561 # watch for everyone but me and root
 562 watch=(notme root)
 563
 564 # automatically remove duplicates from these arrays
 565 typeset -U path cdpath fpath manpath
 566
 567 # keybindings
 568 if [[ "$TERM" != emacs ]] ; then
 569     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 570     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 571     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 572     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 573     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 574     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 575     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 576     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 577     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 578     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 579     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 580     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 581     # ncurses stuff:
 582     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 583     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 584     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 585     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 586     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 587     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 588     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 589     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 590 fi
 591
 592 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 593 # use emacs style per default:
 594 bindkey -e
 595 # use vi style:
 596 # bindkey -v
 597
 598 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 599 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 600 beginning-or-end-of-somewhere() {
 601     local hno=$HISTNO
 602     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 603       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 604         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 605     else
 606         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 607         if (( HISTNO != hno )); then
 608             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 609         fi
 610     fi
 611 }
 612 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 613 zle -N end-of-somewhere beginning-or-end-of-somewhere
 614
 615
 616 #if [[ "$TERM" == screen ]] ; then
 617
 618 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 619 ## to beginning/end of buffer on second keypress
 620 ## and to beginning/end of history on (at most) the third keypress
 621 # terminator & non-debian xterm
 622 bindkey '\eOH' beginning-of-somewhere  # home
 623 bindkey '\eOF' end-of-somewhere        # end
 624 # freebsd console
 625 bindkey '\e[H' beginning-of-somewhere   # home
 626 bindkey '\e[F' end-of-somewhere         # end
 627 # xterm,gnome-terminal,quake,etc
 628 bindkey '^[[1~' beginning-of-somewhere  # home
 629 bindkey '^[[4~' end-of-somewhere        # end
 630 # if terminal type is set to 'rxvt':
 631 bindkey '\e[7~' beginning-of-somewhere  # home
 632 bindkey '\e[8~' end-of-somewhere        # end
 633 #fi
 634
 635 bindkey '\e[A'  up-line-or-search       # cursor up
 636 bindkey '\e[B'  down-line-or-search     # <ESC>-
 637
 638 ## alt-backspace is already the default for backwards-delete-word
 639 ## let's also set alt-delete for deleting current word (right of cursor)
 640 #k# Kill right-side word
 641 bindkey '^[[3~'   delete-word # Modeswitch
 642 bindkey '^[[3;3~' delete-word # Alt_L
 643
 644 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 645 bindkey "\e[5C" forward-word
 646 bindkey "\e[5D" backward-word
 647 bindkey "\e[1;5C" forward-word
 648 bindkey "\e[1;5D" backward-word
 649 ## the same for alt-left-arrow and alt-right-arrow
 650 bindkey '^[[1;3C' forward-word
 651 bindkey '^[[1;3D' backward-word
 652
 653 # Search backward in the history for a line beginning with the current
 654 # line up to the cursor and move the cursor to the end of the line then
 655 zle -N history-beginning-search-backward-end history-search-end
 656 zle -N history-beginning-search-forward-end  history-search-end
 657 #k# search history backward for entry beginning with typed text
 658 bindkey '^xp'   history-beginning-search-backward-end
 659 #k# search history forward for entry beginning with typed text
 660 bindkey '^xP'   history-beginning-search-forward-end
 661 #k# search history backward for entry beginning with typed text
 662 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 663 #k# search history forward for entry beginning with typed text
 664 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 665
 666 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 667 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 668
 669 # insert unicode character
 670 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 671 # See for example http://unicode.org/charts/ for unicode characters code
 672 zrcautoload insert-unicode-char
 673 zle -N insert-unicode-char
 674 #k# Insert Unicode character
 675 bindkey '^Xi' insert-unicode-char
 676
 677 #m# k Shift-tab Perform backwards menu completion
 678 if [[ -n "$terminfo[kcbt]" ]]; then
 679     bindkey "$terminfo[kcbt]" reverse-menu-complete
 680 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 681     bindkey "$terminfo[cbt]"  reverse-menu-complete
 682 fi
 683
 684 ## toggle the ,. abbreviation feature on/off
 685 # NOABBREVIATION: default abbreviation-state
 686 #                 0 - enabled (default)
 687 #                 1 - disabled
 688 NOABBREVIATION=${NOABBREVIATION:-0}
 689
 690 grml_toggle_abbrev() {
 691     if (( ${NOABBREVIATION} > 0 )) ; then
 692         NOABBREVIATION=0
 693     else
 694         NOABBREVIATION=1
 695     fi
 696 }
 697
 698 zle -N grml_toggle_abbrev
 699 bindkey '^xA' grml_toggle_abbrev
 700
 701 # add a command line to the shells history without executing it
 702 commit-to-history() {
 703     print -s ${(z)BUFFER}
 704     zle send-break
 705 }
 706 zle -N commit-to-history
 707 bindkey "^x^h" commit-to-history
 708
 709 # only slash should be considered as a word separator:
 710 slash-backward-kill-word() {
 711     local WORDCHARS="${WORDCHARS:s@/@}"
 712     # zle backward-word
 713     zle backward-kill-word
 714 }
 715 zle -N slash-backward-kill-word
 716
 717 #k# Kill left-side word or everything up to next slash
 718 bindkey '\ev' slash-backward-kill-word
 719 #k# Kill left-side word or everything up to next slash
 720 bindkey '\e^h' slash-backward-kill-word
 721 #k# Kill left-side word or everything up to next slash
 722 bindkey '\e^?' slash-backward-kill-word
 723
 724 # use the new *-pattern-* widgets for incremental history search
 725 if is439 ; then
 726     bindkey '^r' history-incremental-pattern-search-backward
 727     bindkey '^s' history-incremental-pattern-search-forward
 728 fi
 729
 730 # a generic accept-line wrapper
 731
 732 # This widget can prevent unwanted autocorrections from command-name
 733 # to _command-name, rehash automatically on enter and call any number
 734 # of builtin and user-defined widgets in different contexts.
 735 #
 736 # For a broader description, see:
 737 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 738 #
 739 # The code is imported from the file 'zsh/functions/accept-line' from
 740 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 741 # distributed under the same terms as zsh itself.
 742
 743 # A newly added command will may not be found or will cause false
 744 # correction attempts, if you got auto-correction set. By setting the
 745 # following style, we force accept-line() to rehash, if it cannot
 746 # find the first word on the command line in the $command[] hash.
 747 zstyle ':acceptline:*' rehash true
 748
 749 function Accept-Line() {
 750     setopt localoptions noksharrays
 751     local -a subs
 752     local -xi aldone
 753     local sub
 754     local alcontext=${1:-$alcontext}
 755
 756     zstyle -a ":acceptline:${alcontext}" actions subs
 757
 758     (( ${#subs} < 1 )) && return 0
 759
 760     (( aldone = 0 ))
 761     for sub in ${subs} ; do
 762         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 763         zle ${sub}
 764
 765         (( aldone > 0 )) && break
 766     done
 767 }
 768
 769 function Accept-Line-getdefault() {
 770     emulate -L zsh
 771     local default_action
 772
 773     zstyle -s ":acceptline:${alcontext}" default_action default_action
 774     case ${default_action} in
 775         ((accept-line|))
 776             printf ".accept-line"
 777             ;;
 778         (*)
 779             printf ${default_action}
 780             ;;
 781     esac
 782 }
 783
 784 function Accept-Line-HandleContext() {
 785     zle Accept-Line
 786
 787     default_action=$(Accept-Line-getdefault)
 788     zstyle -T ":acceptline:${alcontext}" call_default \
 789         && zle ${default_action}
 790 }
 791
 792 function accept-line() {
 793     setopt localoptions noksharrays
 794     local -ax cmdline
 795     local -x alcontext
 796     local buf com fname format msg default_action
 797
 798     alcontext='default'
 799     buf="${BUFFER}"
 800     cmdline=(${(z)BUFFER})
 801     com="${cmdline[1]}"
 802     fname="_${com}"
 803
 804     Accept-Line 'preprocess'
 805
 806     zstyle -t ":acceptline:${alcontext}" rehash \
 807         && [[ -z ${commands[$com]} ]]           \
 808         && rehash
 809
 810     if    [[ -n ${com}               ]] \
 811        && [[ -n ${reswords[(r)$com]} ]] \
 812        || [[ -n ${aliases[$com]}     ]] \
 813        || [[ -n ${functions[$com]}   ]] \
 814        || [[ -n ${builtins[$com]}    ]] \
 815        || [[ -n ${commands[$com]}    ]] ; then
 816
 817         # there is something sensible to execute, just do it.
 818         alcontext='normal'
 819         Accept-Line-HandleContext
 820
 821         return
 822     fi
 823
 824     if    [[ -o correct              ]] \
 825        || [[ -o correctall           ]] \
 826        && [[ -n ${functions[$fname]} ]] ; then
 827
 828         # nothing there to execute but there is a function called
 829         # _command_name; a completion widget. Makes no sense to
 830         # call it on the commandline, but the correct{,all} options
 831         # will ask for it nevertheless, so warn the user.
 832         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 833             # Okay, we warned the user before, he called us again,
 834             # so have it his way.
 835             alcontext='force'
 836             Accept-Line-HandleContext
 837
 838             return
 839         fi
 840
 841         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 842             alcontext='normal'
 843             Accept-Line-HandleContext
 844         else
 845             # prepare warning message for the user, configurable via zstyle.
 846             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 847
 848             if [[ -z ${msg} ]] ; then
 849                 msg="%c will not execute and completion %f exists."
 850             fi
 851
 852             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 853
 854             zle -M -- "${msg}"
 855         fi
 856         return
 857     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 858         # If we are here, the commandline contains something that is not
 859         # executable, which is neither subject to _command_name correction
 860         # and is not empty. might be a variable assignment
 861         alcontext='misc'
 862         Accept-Line-HandleContext
 863
 864         return
 865     fi
 866
 867     # If we got this far, the commandline only contains whitespace, or is empty.
 868     alcontext='empty'
 869     Accept-Line-HandleContext
 870 }
 871
 872 zle -N accept-line
 873 zle -N Accept-Line
 874 zle -N Accept-Line-HandleContext
 875
 876 # power completion - abbreviation expansion
 877 # power completion / abbreviation expansion / buffer expansion
 878 # see http://zshwiki.org/home/examples/zleiab for details
 879 # less risky than the global aliases but powerful as well
 880 # just type the abbreviation key and afterwards ',.' to expand it
 881 declare -A abk
 882 setopt extendedglob
 883 setopt interactivecomments
 884 abk=(
 885 #   key   # value                  (#d additional doc string)
 886 #A# start
 887     '...'  '../..'
 888     '....' '../../..'
 889     'BG'   '& exit'
 890     'C'    '| wc -l'
 891     'G'    '|& grep --color=auto '
 892     'H'    '| head'
 893     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 894     'L'    '| less'
 895     'LL'   '|& less -r'
 896     'M'    '| most'
 897     'N'    '&>/dev/null'           #d (No Output)
 898     'R'    '| tr A-z N-za-m'       #d (ROT13)
 899     'SL'   '| sort | less'
 900     'S'    '| sort -u'
 901     'T'    '| tail'
 902     'V'    '|& vim -'
 903 #A# end
 904     'co'   './configure && make && sudo make install'
 905 )
 906
 907 zleiab() {
 908     emulate -L zsh
 909     setopt extendedglob
 910     local MATCH
 911
 912     if (( NOABBREVIATION > 0 )) ; then
 913         LBUFFER="${LBUFFER},."
 914         return 0
 915     fi
 916
 917     matched_chars='[.-|_a-zA-Z0-9]#'
 918     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 919     LBUFFER+=${abk[$MATCH]:-$MATCH}
 920 }
 921
 922 zle -N zleiab
 923 bindkey ",." zleiab
 924
 925 # autoloading
 926 zrcautoload zmv    # who needs mmv or rename?
 927 zrcautoload history-search-end
 928
 929 # we don't want to quote/espace URLs on our own...
 930 # if autoload -U url-quote-magic ; then
 931 #    zle -N self-insert url-quote-magic
 932 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 933 # else
 934 #    print 'Notice: no url-quote-magic available :('
 935 # fi
 936 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 937
 938 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 939 alias run-help >&/dev/null && unalias run-help
 940 for rh in run-help{,-git,-svk,-svn}; do
 941     zrcautoload $rh
 942 done; unset rh
 943
 944 # completion system
 945 if zrcautoload compinit ; then
 946     compinit || print 'Notice: no compinit available :('
 947 else
 948     print 'Notice: no compinit available :('
 949     function zstyle { }
 950     function compdef { }
 951 fi
 952
 953 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 954
 955 is4 && \
 956 for mod in complist deltochar mathfunc ; do
 957     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 958 done
 959
 960 # autoload zsh modules when they are referenced
 961 if is4 ; then
 962     zmodload -a  zsh/stat    zstat
 963     zmodload -a  zsh/zpty    zpty
 964     zmodload -ap zsh/mapfile mapfile
 965 fi
 966
 967 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 968     #k# Insert files and test globbing
 969     bindkey "^Xf" insert-files # C-x-f
 970 fi
 971
 972 bindkey ' '   magic-space    # also do history expansion on space
 973 #k# Trigger menu-complete
 974 bindkey '\ei' menu-complete  # menu completion via esc-i
 975
 976 # press esc-e for editing command line in $EDITOR or $VISUAL
 977 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 978     #k# Edit the current line in \kbd{\$EDITOR}
 979     bindkey '\ee' edit-command-line
 980 fi
 981
 982 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 983     #k# menu selection: pick item but stay in the menu
 984     bindkey -M menuselect '\e^M' accept-and-menu-complete
 985     # also use + and INSERT since it's easier to press repeatedly
 986     bindkey -M menuselect "+" accept-and-menu-complete
 987     bindkey -M menuselect "^[[2~" accept-and-menu-complete
 988
 989     # accept a completion and try to complete again by using menu
 990     # completion; very useful with completing directories
 991     # by using 'undo' one's got a simple file browser
 992     bindkey -M menuselect '^o' accept-and-infer-next-history
 993 fi
 994
 995 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 996 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
 997 zle -N insert-datestamp
 998
 999 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1000 bindkey '^Ed' insert-datestamp
1001
1002 # press esc-m for inserting last typed word again (thanks to caphuso!)
1003 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1004 zle -N insert-last-typed-word;
1005
1006 #k# Insert last typed word
1007 bindkey "\em" insert-last-typed-word
1008
1009 function grml-zsh-fg() {
1010   if (( ${#jobstates} )); then
1011     zle .push-input
1012     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1013     BUFFER="${BUFFER}fg"
1014     zle .accept-line
1015   else
1016     zle -M 'No background jobs. Doing nothing.'
1017   fi
1018 }
1019 zle -N grml-zsh-fg
1020 #k# A smart shortcut for \kbd{fg<enter>}
1021 bindkey '^z' grml-zsh-fg
1022
1023 # run command line as user root via sudo:
1024 sudo-command-line() {
1025     [[ -z $BUFFER ]] && zle up-history
1026     if [[ $BUFFER != sudo\ * ]]; then
1027         BUFFER="sudo $BUFFER"
1028         CURSOR=$(( CURSOR+5 ))
1029     fi
1030 }
1031 zle -N sudo-command-line
1032
1033 #k# prepend the current command with "sudo"
1034 bindkey "^Os" sudo-command-line
1035
1036 ### jump behind the first word on the cmdline.
1037 ### useful to add options.
1038 function jump_after_first_word() {
1039     local words
1040     words=(${(z)BUFFER})
1041
1042     if (( ${#words} <= 1 )) ; then
1043         CURSOR=${#BUFFER}
1044     else
1045         CURSOR=${#${words[1]}}
1046     fi
1047 }
1048 zle -N jump_after_first_word
1049 #k# jump to after first word (for adding options)
1050 bindkey '^x1' jump_after_first_word
1051
1052 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1053 zle -C hist-complete complete-word _generic
1054 zstyle ':completion:hist-complete:*' completer _history
1055 #k# complete word from history with menu
1056 bindkey "^X^X" hist-complete
1057
1058 ## complete word from currently visible Screen or Tmux buffer.
1059 if check_com -c screen || check_com -c tmux; then
1060     _complete_screen_display() {
1061         [[ "$TERM" != "screen" ]] && return 1
1062
1063         local TMPFILE=$(mktemp)
1064         local -U -a _screen_display_wordlist
1065         trap "rm -f $TMPFILE" EXIT
1066
1067         # fill array with contents from screen hardcopy
1068         if ((${+TMUX})); then
1069             #works, but crashes tmux below version 1.4
1070             #luckily tmux -V option to ask for version, was also added in 1.4
1071             tmux -V &>/dev/null || return
1072             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1073         else
1074             screen -X hardcopy $TMPFILE
1075             # screen sucks, it dumps in latin1, apparently always. so recode it
1076             # to system charset
1077             check_com recode && recode latin1 $TMPFILE
1078         fi
1079         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1080         # remove PREFIX to be completed from that array
1081         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1082         compadd -a _screen_display_wordlist
1083     }
1084     #k# complete word from currently visible GNU screen buffer
1085     bindkey -r "^XS"
1086     compdef -k _complete_screen_display complete-word '^XS'
1087 fi
1088
1089 # history
1090
1091 ZSHDIR=$HOME/.zsh
1092
1093 #v#
1094 HISTFILE=$HOME/.zsh_history
1095 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1096 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1097
1098 # dirstack handling
1099
1100 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1101 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1102
1103 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1104     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1105     # "cd -" won't work after login by just setting $OLDPWD, so
1106     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1107 fi
1108
1109 chpwd() {
1110     local -ax my_stack
1111     my_stack=( ${PWD} ${dirstack} )
1112     if is42 ; then
1113         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1114     else
1115         uprint my_stack >! ${DIRSTACKFILE}
1116     fi
1117 }
1118
1119 # directory based profiles
1120
1121 if is433 ; then
1122
1123 CHPWD_PROFILE='default'
1124 function chpwd_profiles() {
1125     # Say you want certain settings to be active in certain directories.
1126     # This is what you want.
1127     #
1128     # zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1129     # zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1130     #
1131     # When that's done and you enter a directory that matches the pattern
1132     # in the third part of the context, a function called chpwd_profile_grml,
1133     # for example, is called (if it exists).
1134     #
1135     # If no pattern matches (read: no profile is detected) the profile is
1136     # set to 'default', which means chpwd_profile_default is attempted to
1137     # be called.
1138     #
1139     # A word about the context (the ':chpwd:profiles:*' stuff in the zstyle
1140     # command) which is used: The third part in the context is matched against
1141     # ${PWD}. That's why using a pattern such as /foo/bar(|/|/*) makes sense.
1142     # Because that way the profile is detected for all these values of ${PWD}:
1143     #   /foo/bar
1144     #   /foo/bar/
1145     #   /foo/bar/baz
1146     # So, if you want to make double damn sure a profile works in /foo/bar
1147     # and everywhere deeper in that tree, just use (|/|/*) and be happy.
1148     #
1149     # The name of the detected profile will be available in a variable called
1150     # 'profile' in your functions. You don't need to do anything, it'll just
1151     # be there.
1152     #
1153     # Then there is the parameter $CHPWD_PROFILE is set to the profile, that
1154     # was is currently active. That way you can avoid running code for a
1155     # profile that is already active, by running code such as the following
1156     # at the start of your function:
1157     #
1158     # function chpwd_profile_grml() {
1159     #     [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1160     #   ...
1161     # }
1162     #
1163     # The initial value for $CHPWD_PROFILE is 'default'.
1164     #
1165     # Version requirement:
1166     #   This feature requires zsh 4.3.3 or newer.
1167     #   If you use this feature and need to know whether it is active in your
1168     #   current shell, there are several ways to do that. Here are two simple
1169     #   ways:
1170     #
1171     #   a) If knowing if the profiles feature is active when zsh starts is
1172     #      good enough for you, you can put the following snippet into your
1173     #      .zshrc.local:
1174     #
1175     #   (( ${+functions[chpwd_profiles]} )) && print "directory profiles active"
1176     #
1177     #   b) If that is not good enough, and you would prefer to be notified
1178     #      whenever a profile changes, you can solve that by making sure you
1179     #      start *every* profile function you create like this:
1180     #
1181     #   function chpwd_profile_myprofilename() {
1182     #       [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1183     #       print "chpwd(): Switching to profile: $profile"
1184     #     ...
1185     #   }
1186     #
1187     #      That makes sure you only get notified if a profile is *changed*,
1188     #      not everytime you change directory, which would probably piss
1189     #      you off fairly quickly. :-)
1190     #
1191     # There you go. Now have fun with that.
1192     local -x profile
1193
1194     zstyle -s ":chpwd:profiles:${PWD}" profile profile || profile='default'
1195     if (( ${+functions[chpwd_profile_$profile]} )) ; then
1196         chpwd_profile_${profile}
1197     fi
1198
1199     CHPWD_PROFILE="${profile}"
1200     return 0
1201 }
1202 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1203
1204 fi # is433
1205
1206 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1207 if [[ $BATTERY -gt 0 ]] ; then
1208     if ! check_com -c acpi ; then
1209         BATTERY=0
1210     fi
1211 fi
1212
1213 battery() {
1214 if [[ $BATTERY -gt 0 ]] ; then
1215     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1216     if [[ -z "$PERCENT" ]] ; then
1217         PERCENT='acpi not present'
1218     else
1219         if [[ "$PERCENT" -lt 20 ]] ; then
1220             PERCENT="warning: ${PERCENT}%%"
1221         else
1222             PERCENT="${PERCENT}%%"
1223         fi
1224     fi
1225 fi
1226 }
1227 # set colors for use in prompts
1228 if zrcautoload colors && colors 2>/dev/null ; then
1229     BLUE="%{${fg[blue]}%}"
1230     RED="%{${fg_bold[red]}%}"
1231     GREEN="%{${fg[green]}%}"
1232     CYAN="%{${fg[cyan]}%}"
1233     MAGENTA="%{${fg[magenta]}%}"
1234     YELLOW="%{${fg[yellow]}%}"
1235     WHITE="%{${fg[white]}%}"
1236     NO_COLOUR="%{${reset_color}%}"
1237 else
1238     BLUE=$'%{\e[1;34m%}'
1239     RED=$'%{\e[1;31m%}'
1240     GREEN=$'%{\e[1;32m%}'
1241     CYAN=$'%{\e[1;36m%}'
1242     WHITE=$'%{\e[1;37m%}'
1243     MAGENTA=$'%{\e[1;35m%}'
1244     YELLOW=$'%{\e[1;33m%}'
1245     NO_COLOUR=$'%{\e[0m%}'
1246 fi
1247
1248 # gather version control information for inclusion in a prompt
1249
1250 if zrcautoload vcs_info; then
1251     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1252     # function, which can cause a lot of trouble with our directory-based
1253     # profiles. So:
1254     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1255         function VCS_INFO_realpath () {
1256             setopt localoptions NO_shwordsplit chaselinks
1257             ( builtin cd -q $1 2> /dev/null && pwd; )
1258         }
1259     fi
1260
1261     zstyle ':vcs_info:*' max-exports 2
1262
1263     if [[ -o restricted ]]; then
1264         zstyle ':vcs_info:*' enable NONE
1265     fi
1266 fi
1267
1268 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1269 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1270 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1271 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1272 #       to $vcs_info_msg_N_ as soon as we use the included version.
1273 if [[ "$TERM" == dumb ]] ; then
1274     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1275     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1276 else
1277     # these are the same, just with a lot of colours:
1278     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
1279                                        "zsh: %r"
1280     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
1281                                        "zsh: %r"
1282     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1283 fi
1284
1285 # command not found handling
1286
1287 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1288 function command_not_found_handler() {
1289     emulate -L zsh
1290     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1291         ${GRML_ZSH_CNF_HANDLER} $1
1292     fi
1293     return 1
1294 }
1295
1296 # set prompt
1297 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1298     promptinit # people should be able to use their favourite prompt
1299 else
1300     print 'Notice: no promptinit available :('
1301 fi
1302
1303 setopt prompt_subst
1304
1305 # make sure to use right prompt only when not running a command
1306 is41 && setopt transient_rprompt
1307
1308
1309 function ESC_print () {
1310     info_print $'\ek' $'\e\\' "$@"
1311 }
1312 function set_title () {
1313     info_print  $'\e]0;' $'\a' "$@"
1314 }
1315
1316 function info_print () {
1317     local esc_begin esc_end
1318     esc_begin="$1"
1319     esc_end="$2"
1320     shift 2
1321     printf '%s' ${esc_begin}
1322     printf '%s' "$*"
1323     printf '%s' "${esc_end}"
1324 }
1325
1326 # TODO: revise all these NO* variables and especially their documentation
1327 #       in zsh-help() below.
1328 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1329     [[ $NOPRECMD -gt 0 ]] && return 0
1330     # update VCS information
1331     (( ${+functions[vcs_info]} )) && vcs_info
1332
1333     if [[ $TERM == screen* ]] ; then
1334         if [[ -n ${vcs_info_msg_1_} ]] ; then
1335             ESC_print ${vcs_info_msg_1_}
1336         else
1337             ESC_print "zsh"
1338         fi
1339     fi
1340     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1341     if [[ ${DONTSETRPROMPT:-} -eq 0 ]] ; then
1342         if [[ $BATTERY -gt 0 ]] ; then
1343             # update battery (dropped into $PERCENT) information
1344             battery
1345             RPROMPT="%(?..:() ${PERCENT}"
1346         else
1347             RPROMPT="%(?..:() "
1348         fi
1349     fi
1350     # adjust title of xterm
1351     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1352     [[ ${NOTITLE:-} -gt 0 ]] && return 0
1353     case $TERM in
1354         (xterm*|rxvt*)
1355             set_title ${(%):-"%n@%m: %~"}
1356             ;;
1357     esac
1358 }
1359
1360 # preexec() => a function running before every command
1361 is4 && [[ $NOPRECMD -eq 0 ]] && \
1362 preexec () {
1363     [[ $NOPRECMD -gt 0 ]] && return 0
1364 # set hostname if not running on host with name 'grml'
1365     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1366        NAME="@$HOSTNAME"
1367     fi
1368 # get the name of the program currently running and hostname of local machine
1369 # set screen window title if running in a screen
1370     if [[ "$TERM" == screen* ]] ; then
1371         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1372         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1373         ESC_print ${CMD}
1374     fi
1375 # adjust title of xterm
1376     [[ ${NOTITLE} -gt 0 ]] && return 0
1377     case $TERM in
1378         (xterm*|rxvt*)
1379             set_title "${(%):-"%n@%m:"}" "$1"
1380             ;;
1381     esac
1382 }
1383
1384 EXITCODE="%(?..%?%1v )"
1385 # secondary prompt, printed when the shell needs more information to complete a
1386 # command.
1387 PS2='\`%_> '
1388 # selection prompt used within a select loop.
1389 PS3='?# '
1390 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1391 PS4='+%N:%i:%_> '
1392
1393 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1394 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1395     debian_chroot=$(cat /etc/debian_chroot)
1396 fi
1397
1398 # don't use colors on dumb terminals (like emacs):
1399 if [[ "$TERM" == dumb ]] ; then
1400     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
1401 else
1402     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended
1403     # prompt set variable identifying the chroot you work in (used in the
1404     # prompt below)
1405     if [[ $GRMLPROMPT -gt 0 ]] ; then
1406         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1407 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1408     else
1409         # This assembles the primary prompt string
1410         if (( EUID != 0 )); then
1411             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1412         else
1413             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1414         fi
1415     fi
1416 fi
1417
1418 PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
1419
1420 # if we are inside a grml-chroot set a specific prompt theme
1421 if [[ -n "$GRML_CHROOT" ]] ; then
1422     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1423 fi
1424
1425 # 'hash' some often used directories
1426 #d# start
1427 hash -d deb=/var/cache/apt/archives
1428 hash -d doc=/usr/share/doc
1429 hash -d linux=/lib/modules/$(command uname -r)/build/
1430 hash -d log=/var/log
1431 hash -d slog=/var/log/syslog
1432 hash -d src=/usr/src
1433 hash -d templ=/usr/share/doc/grml-templates
1434 hash -d tt=/usr/share/doc/texttools-doc
1435 hash -d www=/var/www
1436 #d# end
1437
1438 # some aliases
1439 if check_com -c screen ; then
1440     if [[ $UID -eq 0 ]] ; then
1441         if [[ -r /etc/grml/screenrc ]]; then
1442             alias screen="${commands[screen]} -c /etc/grml/screenrc"
1443         fi
1444     elif [[ -r $HOME/.screenrc ]] ; then
1445         alias screen="${commands[screen]} -c $HOME/.screenrc"
1446     else
1447         if [[ -r /etc/grml/screenrc_grml ]]; then
1448             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1449         else
1450             if [[ -r /etc/grml/screenrc ]]; then
1451                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
1452             fi
1453         fi
1454     fi
1455 fi
1456
1457 # do we have GNU ls with color-support?
1458 if ls --help 2>/dev/null | grep -- --color= >/dev/null \
1459    && [[ "$TERM" != dumb ]]
1460 then
1461     #a1# execute \kbd{@a@}:\quad ls with colors
1462     alias ls='ls -b -CF --color=auto'
1463     #a1# execute \kbd{@a@}:\quad list all files, with colors
1464     alias la='ls -la --color=auto'
1465     #a1# long colored list, without dotfiles (@a@)
1466     alias ll='ls -l --color=auto'
1467     #a1# long colored list, human readable sizes (@a@)
1468     alias lh='ls -hAl --color=auto'
1469     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1470     alias l='ls -lF --color=auto'
1471 else
1472     alias ls='ls -b -CF'
1473     alias la='ls -la'
1474     alias ll='ls -l'
1475     alias lh='ls -hAl'
1476     alias l='ls -lF'
1477 fi
1478
1479 alias mdstat='cat /proc/mdstat'
1480 alias ...='cd ../../'
1481
1482 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1483 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1484     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1485 fi
1486
1487 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1488 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1489 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1490
1491 # make sure it is not assigned yet
1492 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1493 utf2iso() {
1494     if isutfenv ; then
1495         for ENV in $(env | command grep -i '.utf') ; do
1496             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1497         done
1498     fi
1499 }
1500
1501 # make sure it is not assigned yet
1502 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1503 iso2utf() {
1504     if ! isutfenv ; then
1505         for ENV in $(env | command grep -i '\.iso') ; do
1506             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1507         done
1508     fi
1509 }
1510
1511 # especially for roadwarriors using GNU screen and ssh:
1512 if ! check_com asc &>/dev/null ; then
1513   asc() { autossh -t "$@" 'screen -RdU' }
1514   compdef asc=ssh
1515 fi
1516
1517 #f1# Hints for the use of zsh on grml
1518 zsh-help() {
1519     print "$bg[white]$fg[black]
1520 zsh-help - hints for use of zsh on grml
1521 =======================================$reset_color"
1522
1523     print '
1524 Main configuration of zsh happens in /etc/zsh/zshrc.
1525 That file is part of the package grml-etc-core, if you want to
1526 use them on a non-grml-system just get the tar.gz from
1527 http://deb.grml.org/ or (preferably) get it from the git repository:
1528
1529   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1530
1531 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1532 The file is still there, but it is empty for backwards compatibility.
1533
1534 For your own changes use these two files:
1535     $HOME/.zshrc.pre
1536     $HOME/.zshrc.local
1537
1538 The former is sourced very early in our zshrc, the latter is sourced
1539 very lately.
1540
1541 System wide configuration without touching configuration files of grml
1542 can take place in /etc/zsh/zshrc.local.
1543
1544 For information regarding zsh start at http://grml.org/zsh/
1545
1546 Take a look at grml'\''s zsh refcard:
1547 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1548
1549 Check out the main zsh refcard:
1550 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1551
1552 And of course visit the zsh-lovers:
1553 % man zsh-lovers
1554
1555 You can adjust some options through environment variables when
1556 invoking zsh without having to edit configuration files.
1557 Basically meant for bash users who are not used to the power of
1558 the zsh yet. :)
1559
1560   "NOCOR=1    zsh" => deactivate automatic correction
1561   "NOMENU=1   zsh" => do not use auto menu completion
1562                       (note: use ctrl-d for completion instead!)
1563   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1564   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1565                       preexec() and precmd() completely
1566   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1567   "COMMAND_NOT_FOUND=1 zsh"
1568                    => Enable a handler if an external command was not found
1569                       The command called in the handler can be altered by setting
1570                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1571                       "/usr/share/command-not-found/command-not-found"
1572
1573 A value greater than 0 is enables a feature; a value equal to zero
1574 disables it. If you like one or the other of these settings, you can
1575 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1576 zshrc.'
1577
1578     print "
1579 $bg[white]$fg[black]
1580 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1581 Enjoy your grml system with the zsh!$reset_color"
1582 }
1583
1584 # debian stuff
1585 if [[ -r /etc/debian_version ]] ; then
1586     #a3# Execute \kbd{apt-cache search}
1587     alias acs='apt-cache search'
1588     #a3# Execute \kbd{apt-cache show}
1589     alias acsh='apt-cache show'
1590     #a3# Execute \kbd{apt-cache policy}
1591     alias acp='apt-cache policy'
1592     #a3# Execute \kbd{apt-get dist-upgrade}
1593     salias adg="apt-get dist-upgrade"
1594     #a3# Execute \kbd{apt-get install}
1595     salias agi="apt-get install"
1596     #a3# Execute \kbd{aptitude install}
1597     salias ati="aptitude install"
1598     #a3# Execute \kbd{apt-get upgrade}
1599     salias ag="apt-get upgrade"
1600     #a3# Execute \kbd{apt-get update}
1601     salias au="apt-get update"
1602     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1603     salias -a up="aptitude update ; aptitude safe-upgrade"
1604     #a3# Execute \kbd{dpkg-buildpackage}
1605     alias dbp='dpkg-buildpackage'
1606     #a3# Execute \kbd{grep-excuses}
1607     alias ge='grep-excuses'
1608
1609     # get a root shell as normal user in live-cd mode:
1610     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1611        alias su="sudo su"
1612      fi
1613
1614     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1615     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1616     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1617     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1618 fi
1619
1620 # sort installed Debian-packages by size
1621 if check_com -c dpkg-query ; then
1622     #a3# List installed Debian-packages sorted by size
1623     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1624 fi
1625
1626 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1627 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1628     if check_com -c wodim; then
1629         cdrecord() {
1630             cat <<EOMESS
1631 cdrecord is not provided under its original name by Debian anymore.
1632 See #377109 in the BTS of Debian for more details.
1633
1634 Please use the wodim binary instead
1635 EOMESS
1636             return 1
1637         }
1638     fi
1639 fi
1640
1641 # Use hard limits, except for a smaller stack and no core dumps
1642 unlimit
1643 is425 && limit stack 8192
1644 isgrmlcd && limit core 0 # important for a live-cd-system
1645 limit -s
1646
1647 # completion system
1648
1649 # called later (via is4 && grmlcomp)
1650 # note: use 'zstyle' for getting current settings
1651 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
1652 grmlcomp() {
1653     # TODO: This could use some additional information
1654
1655     # allow one error for every three characters typed in approximate completer
1656     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1657
1658     # don't complete backup files as executables
1659     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1660
1661     # start menu completion only if it could find no unambiguous initial string
1662     zstyle ':completion:*:correct:*'       insert-unambiguous true
1663     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1664     zstyle ':completion:*:correct:*'       original true
1665
1666     # activate color-completion
1667     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1668
1669     # format on completion
1670     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1671
1672     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1673     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1674
1675     # insert all expansions for expand completer
1676     zstyle ':completion:*:expand:*'        tag-order all-expansions
1677     zstyle ':completion:*:history-words'   list false
1678
1679     # activate menu
1680     zstyle ':completion:*:history-words'   menu yes
1681
1682     # ignore duplicate entries
1683     zstyle ':completion:*:history-words'   remove-all-dups yes
1684     zstyle ':completion:*:history-words'   stop yes
1685
1686     # match uppercase from lowercase
1687     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1688
1689     # separate matches into groups
1690     zstyle ':completion:*:matches'         group 'yes'
1691     zstyle ':completion:*'                 group-name ''
1692
1693     if [[ "$NOMENU" -eq 0 ]] ; then
1694         # if there are more than 5 options allow selecting from a menu
1695         zstyle ':completion:*'               menu select=5
1696     else
1697         # don't use any menus at all
1698         setopt no_auto_menu
1699     fi
1700
1701     zstyle ':completion:*:messages'        format '%d'
1702     zstyle ':completion:*:options'         auto-description '%d'
1703
1704     # describe options in full
1705     zstyle ':completion:*:options'         description 'yes'
1706
1707     # on processes completion complete all user processes
1708     zstyle ':completion:*:processes'       command 'ps -au$USER'
1709
1710     # offer indexes before parameters in subscripts
1711     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1712
1713     # provide verbose completion information
1714     zstyle ':completion:*'                 verbose true
1715
1716     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1717     # for commands (read: 1st word in the line) that it will list for the user
1718     # to choose from. The following disables that, because it's not exactly fast.
1719     zstyle ':completion:*:-command-:*:'    verbose false
1720
1721     # set format for warnings
1722     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1723
1724     # define files to ignore for zcompile
1725     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1726     zstyle ':completion:correct:'          prompt 'correct to: %e'
1727
1728     # Ignore completion functions for commands you don't have:
1729     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1730
1731     # Provide more processes in completion of programs like killall:
1732     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1733
1734     # complete manual by their section
1735     zstyle ':completion:*:manuals'    separate-sections true
1736     zstyle ':completion:*:manuals.*'  insert-sections   true
1737     zstyle ':completion:*:man:*'      menu yes select
1738
1739     # provide .. as a completion
1740     zstyle ':completion:*' special-dirs ..
1741
1742     # run rehash on completion so new installed program are found automatically:
1743     _force_rehash() {
1744         (( CURRENT == 1 )) && rehash
1745         return 1
1746     }
1747
1748     ## correction
1749     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1750     if [[ "$NOCOR" -gt 0 ]] ; then
1751         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1752         setopt nocorrect
1753     else
1754         # try to be smart about when to use what completer...
1755         setopt correct
1756         zstyle -e ':completion:*' completer '
1757             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1758                 _last_try="$HISTNO$BUFFER$CURSOR"
1759                 reply=(_complete _match _ignored _prefix _files)
1760             else
1761                 if [[ $words[1] == (rm|mv) ]] ; then
1762                     reply=(_complete _files)
1763                 else
1764                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1765                 fi
1766             fi'
1767     fi
1768
1769     # command for process lists, the local web server details and host completion
1770     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1771
1772     # caching
1773     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1774                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1775
1776     # host completion
1777     if is42 ; then
1778         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1779         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1780     else
1781         _ssh_hosts=()
1782         _etc_hosts=()
1783     fi
1784     hosts=(
1785         $(hostname)
1786         "$_ssh_hosts[@]"
1787         "$_etc_hosts[@]"
1788         grml.org
1789         localhost
1790     )
1791     zstyle ':completion:*:hosts' hosts $hosts
1792     # TODO: so, why is this here?
1793     #  zstyle '*' hosts $hosts
1794
1795     # use generic completion system for programs not yet defined; (_gnu_generic works
1796     # with commands that provide a --help option with "standard" gnu-like output.)
1797     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
1798                    pal stow tail uname ; do
1799         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
1800     done; unset compcom
1801
1802     # see upgrade function in this file
1803     compdef _hosts upgrade
1804 }
1805
1806 # grmlstuff
1807 grmlstuff() {
1808 # people should use 'grml-x'!
1809     if check_com -c 915resolution; then
1810         855resolution() {
1811             echo "Please use 915resolution as resolution modifying tool for Intel \
1812 graphic chipset."
1813             return -1
1814         }
1815     fi
1816
1817     #a1# Output version of running grml
1818     alias grml-version='cat /etc/grml_version'
1819
1820     if check_com -c rebuildfstab ; then
1821         #a1# Rebuild /etc/fstab
1822         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1823     fi
1824
1825     if check_com -c grml-debootstrap ; then
1826         debian2hd() {
1827             echo "Installing debian to harddisk is possible by using grml-debootstrap."
1828             return 1
1829         }
1830     fi
1831 }
1832
1833 # now run the functions
1834 isgrml && checkhome
1835 is4    && isgrml    && grmlstuff
1836 is4    && grmlcomp
1837
1838 # keephack
1839 is4 && xsource "/etc/zsh/keephack"
1840
1841 # wonderful idea of using "e" glob qualifier by Peter Stephenson
1842 # You use it as follows:
1843 # $ NTREF=/reference/file
1844 # $ ls -l *(e:nt:)
1845 # This lists all the files in the current directory newer than the reference file.
1846 # You can also specify the reference file inline; note quotes:
1847 # $ ls -l *(e:'nt ~/.zshenv':)
1848 is4 && nt() {
1849     if [[ -n $1 ]] ; then
1850         local NTREF=${~1}
1851     fi
1852     [[ $REPLY -nt $NTREF ]]
1853 }
1854
1855 # shell functions
1856
1857 #f1# Reload an autoloadable function
1858 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1859 compdef _functions freload
1860
1861 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1862 sll() {
1863     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1864     for file in "$@" ; do
1865         while [[ -h "$file" ]] ; do
1866             ls -l $file
1867             file=$(readlink "$file")
1868         done
1869     done
1870 }
1871
1872 # TODO: Is it supported to use pager settings like this?
1873 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
1874 # with respect to wordsplitting. (ie. ${=PAGER})
1875 if check_com -c $PAGER ; then
1876     #f1# View Debian's changelog of a given package
1877     dchange() {
1878         emulate -L zsh
1879         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
1880             $PAGER /usr/share/doc/$1/changelog.Debian.gz
1881         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1882             $PAGER /usr/share/doc/$1/changelog.gz
1883         else
1884             if check_com -c aptitude ; then
1885                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1886                 if isgrml ; then
1887                     aptitude -t unstable changelog $1
1888                 else
1889                     aptitude changelog $1
1890                 fi
1891             else
1892                 echo "No changelog for package $1 found, sorry."
1893                 return 1
1894             fi
1895         fi
1896     }
1897     _dchange() { _files -W /usr/share/doc -/ }
1898     compdef _dchange dchange
1899
1900     #f1# View Debian's NEWS of a given package
1901     dnews() {
1902         emulate -L zsh
1903         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
1904             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
1905         else
1906             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
1907                 $PAGER /usr/share/doc/$1/NEWS.gz
1908             else
1909                 echo "No NEWS file for package $1 found, sorry."
1910                 return 1
1911             fi
1912         fi
1913     }
1914     _dnews() { _files -W /usr/share/doc -/ }
1915     compdef _dnews dnews
1916
1917     #f1# View upstream's changelog of a given package
1918     uchange() {
1919         emulate -L zsh
1920         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1921             $PAGER /usr/share/doc/$1/changelog.gz
1922         else
1923             echo "No changelog for package $1 found, sorry."
1924             return 1
1925         fi
1926     }
1927     _uchange() { _files -W /usr/share/doc -/ }
1928     compdef _uchange uchange
1929 fi
1930
1931 # zsh profiling
1932 profile() {
1933     ZSH_PROFILE_RC=1 $SHELL "$@"
1934 }
1935
1936 #f1# Edit an alias via zle
1937 edalias() {
1938     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1939 }
1940 compdef _aliases edalias
1941
1942 #f1# Edit a function via zle
1943 edfunc() {
1944     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
1945 }
1946 compdef _functions edfunc
1947
1948 # use it e.g. via 'Restart apache2'
1949 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
1950 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
1951 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
1952 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
1953 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
1954 if [[ -d /etc/init.d || -d /etc/service ]] ; then
1955     __start_stop() {
1956         local action_="${1:l}"  # e.g Start/Stop/Restart
1957         local service_="$2"
1958         local param_="$3"
1959
1960         local service_target_="$(readlink /etc/init.d/$service_)"
1961         if [[ $service_target_ == "/usr/bin/sv" ]]; then
1962             # runit
1963             case "${action_}" in
1964                 start) if [[ ! -e /etc/service/$service_ ]]; then
1965                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
1966                        else
1967                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1968                        fi ;;
1969                 # there is no reload in runits sysv emulation
1970                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
1971                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
1972             esac
1973         else
1974             # sysvinit
1975             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1976         fi
1977     }
1978
1979     _grmlinitd() {
1980         local -a scripts
1981         scripts=( /etc/init.d/*(x:t) )
1982         _describe "service startup script" scripts
1983     }
1984
1985     for i in Start Restart Stop Force-Reload Reload ; do
1986         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
1987         compdef _grmlinitd $i
1988     done
1989 fi
1990
1991 #f1# Provides useful information on globbing
1992 H-Glob() {
1993     echo -e "
1994     /      directories
1995     .      plain files
1996     @      symbolic links
1997     =      sockets
1998     p      named pipes (FIFOs)
1999     *      executable plain files (0100)
2000     %      device files (character or block special)
2001     %b     block special files
2002     %c     character special files
2003     r      owner-readable files (0400)
2004     w      owner-writable files (0200)
2005     x      owner-executable files (0100)
2006     A      group-readable files (0040)
2007     I      group-writable files (0020)
2008     E      group-executable files (0010)
2009     R      world-readable files (0004)
2010     W      world-writable files (0002)
2011     X      world-executable files (0001)
2012     s      setuid files (04000)
2013     S      setgid files (02000)
2014     t      files with the sticky bit (01000)
2015
2016   print *(m-1)          # Files modified up to a day ago
2017   print *(a1)           # Files accessed a day ago
2018   print *(@)            # Just symlinks
2019   print *(Lk+50)        # Files bigger than 50 kilobytes
2020   print *(Lk-50)        # Files smaller than 50 kilobytes
2021   print **/*.c          # All *.c files recursively starting in \$PWD
2022   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2023   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2024   print *~*.*           # All Files that do not contain a dot
2025   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2026   print -l *(.c|.h)     # Lists *.c and *.h
2027   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2028   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2029 }
2030 alias help-zshglob=H-Glob
2031
2032 #v1# set number of lines to display per page
2033 HELP_LINES_PER_PAGE=20
2034 #v1# set location of help-zle cache file
2035 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
2036 #f1# helper function for help-zle, actually generates the help text
2037 help_zle_parse_keybindings()
2038 {
2039     emulate -L zsh
2040     setopt extendedglob
2041     unsetopt ksharrays  #indexing starts at 1
2042
2043     #v1# choose files that help-zle will parse for keybindings
2044     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
2045
2046     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
2047         local load_cache=0
2048         for f ($KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
2049         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
2050     fi
2051
2052     #fill with default keybindings, possibly to be overwriten in a file later
2053     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2054     local -A help_zle_keybindings
2055     help_zle_keybindings['<Ctrl>@']="set MARK"
2056     help_zle_keybindings['<Ctrl>X<Ctrl>J']="vi-join lines"
2057     help_zle_keybindings['<Ctrl>X<Ctrl>B']="jump to matching brace"
2058     help_zle_keybindings['<Ctrl>X<Ctrl>U']="undo"
2059     help_zle_keybindings['<Ctrl>_']="undo"
2060     help_zle_keybindings['<Ctrl>X<Ctrl>F<c>']="find <c> in cmdline"
2061     help_zle_keybindings['<Ctrl>A']="goto beginning of line"
2062     help_zle_keybindings['<Ctrl>E']="goto end of line"
2063     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2064     help_zle_keybindings['<Alt>T']="transpose words"
2065     help_zle_keybindings['<Alt>s']="spellcheck word"
2066     help_zle_keybindings['<Ctrl>K']="backward kill buffer"
2067     help_zle_keybindings['<Ctrl>U']="forward kill buffer"
2068     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2069     help_zle_keybindings["<Alt>'"]="quote line"
2070     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2071     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2072     help_zle_keybindings['<Alt>U']="make next word Uppercase"
2073     help_zle_keybindings['<Alt>l']="make next word lowercase"
2074     help_zle_keybindings['<Ctrl>Xd']="preview expansion under cursor"
2075     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2076     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2077     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2078     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2079     help_zle_keybindings['<Ctrl>V']="insert next keypress symbol literally (e.g. for bindkey)"
2080     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2081     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2082     help_zle_keybindings['<Alt>H']="run help on current command"
2083
2084     #init global variables
2085     unset help_zle_lines help_zle_sln
2086     typeset -g -a help_zle_lines
2087     typeset -g help_zle_sln=1
2088
2089     local k v
2090     local lastkeybind_desc contents     #last description starting with #k# that we found
2091     local num_lines_elapsed=0            #number of lines between last description and keybinding
2092     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2093     for f in $HELPZLE_KEYBINDING_FILES; do
2094         [[ -r "$f" ]] || continue   #not readable ? skip it
2095         contents="$(<$f)"
2096         for cline in "${(f)contents}"; do
2097             #zsh pattern: matches lines like: #k# ..............
2098             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2099                 lastkeybind_desc="$match[*]"
2100                 num_lines_elapsed=0
2101             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2102             #             ignores lines that are commentend out
2103             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2104             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2105                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2106                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2107                     #substitute keybinding string with something readable
2108                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2109                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2110                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2111                     help_zle_keybindings[${k}]=$lastkeybind_desc
2112                 fi
2113                 lastkeybind_desc=""
2114             else
2115               ((num_lines_elapsed++))
2116             fi
2117         done
2118     done
2119     unset contents
2120     #calculate length of keybinding column
2121     local kstrlen=0
2122     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2123     #convert the assoc array into preformated lines, which we are able to sort
2124     for k v in ${(kv)help_zle_keybindings[@]}; do
2125         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2126         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2127     done
2128     #sort lines alphabetically
2129     help_zle_lines=("${(i)help_zle_lines[@]}")
2130     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2131     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2132     zcompile $HELP_ZLE_CACHE_FILE
2133 }
2134 typeset -g help_zle_sln
2135 typeset -g -a help_zle_lines
2136
2137 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2138 help-zle()
2139 {
2140     emulate -L zsh
2141     unsetopt ksharrays  #indexing starts at 1
2142     #help lines already generated ? no ? then do it
2143     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2144     #already displayed all lines ? go back to the start
2145     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2146     local sln=$help_zle_sln
2147     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2148     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2149     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2150 }
2151 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2152 zle -N help-zle && bindkey '^Xz' help-zle
2153
2154 # grep for running process, like: 'any vim'
2155 any() {
2156     emulate -L zsh
2157     unsetopt KSH_ARRAYS
2158     if [[ -z "$1" ]] ; then
2159         echo "any - grep for process(es) by keyword" >&2
2160         echo "Usage: any <keyword>" >&2 ; return 1
2161     else
2162         ps xauwww | grep -i --color=auto "[${1[1]}]${1[2,-1]}"
2163     fi
2164 }
2165
2166
2167 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2168 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2169 [[ -r /proc/1/maps ]] && \
2170 deswap() {
2171     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2172     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2173     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2174 }
2175
2176 # a wrapper for vim, that deals with title setting
2177 #   VIM_OPTIONS
2178 #       set this array to a set of options to vim you always want
2179 #       to have set when calling vim (in .zshrc.local), like:
2180 #           VIM_OPTIONS=( -p )
2181 #       This will cause vim to send every file given on the
2182 #       commandline to be send to it's own tab (needs vim7).
2183 vim() {
2184     VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2185 }
2186
2187 # make a backup of a file
2188 bk() {
2189     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2190 }
2191
2192 ssl_hashes=( sha512 sha256 sha1 md5 )
2193
2194 for sh in ${ssl_hashes}; do
2195     eval 'ssl-cert-'${sh}'() {
2196         emulate -L zsh
2197         if [[ -z $1 ]] ; then
2198             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2199             return 1
2200         fi
2201         openssl x509 -noout -fingerprint -'${sh}' -in $1
2202     }'
2203 done; unset sh
2204
2205 ssl-cert-fingerprints() {
2206     emulate -L zsh
2207     local i
2208     if [[ -z $1 ]] ; then
2209         printf 'usage: ssl-cert-fingerprints <file>\n'
2210         return 1
2211     fi
2212     for i in ${ssl_hashes}
2213         do ssl-cert-$i $1;
2214     done
2215 }
2216
2217 ssl-cert-info() {
2218     emulate -L zsh
2219     if [[ -z $1 ]] ; then
2220         printf 'usage: ssl-cert-info <file>\n'
2221         return 1
2222     fi
2223     openssl x509 -noout -text -in $1
2224     ssl-cert-fingerprints $1
2225 }
2226
2227 # make sure our environment is clean regarding colors
2228 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2229
2230 # "persistent history"
2231 # just write important commands you always need to ~/.important_commands
2232 if [[ -r ~/.important_commands ]] ; then
2233     fc -R ~/.important_commands
2234 fi
2235
2236 # load the lookup subsystem if it's available on the system
2237 zrcautoload lookupinit && lookupinit
2238
2239 # variables
2240
2241 # set terminal property (used e.g. by msgid-chooser)
2242 export COLORTERM="yes"
2243
2244 # aliases
2245
2246 # general
2247 #a2# Execute \kbd{du -sch}
2248 alias da='du -sch'
2249 #a2# Execute \kbd{jobs -l}
2250 alias j='jobs -l'
2251
2252 # listing stuff
2253 #a2# Execute \kbd{ls -lSrah}
2254 alias dir="ls -lSrah"
2255 #a2# Only show dot-directories
2256 alias lad='ls -d .*(/)'                # only show dot-directories
2257 #a2# Only show dot-files
2258 alias lsa='ls -a .*(.)'                # only show dot-files
2259 #a2# Only files with setgid/setuid/sticky flag
2260 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
2261 #a2# Only show 1st ten symlinks
2262 alias lsl='ls -l *(@)'                 # only symlinks
2263 #a2# Display only executables
2264 alias lsx='ls -l *(*)'                 # only executables
2265 #a2# Display world-{readable,writable,executable} files
2266 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
2267 #a2# Display the ten biggest files
2268 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
2269 #a2# Only show directories
2270 alias lsd='ls -d *(/)'                 # only show directories
2271 #a2# Only show empty directories
2272 alias lse='ls -d *(/^F)'               # only show empty directories
2273 #a2# Display the ten newest files
2274 alias lsnew="ls -rtlh *(D.om[1,10])"   # display the newest files
2275 #a2# Display the ten oldest files
2276 alias lsold="ls -rtlh *(D.Om[1,10])"   # display the oldest files
2277 #a2# Display the ten smallest files
2278 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
2279
2280 # some useful aliases
2281 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir $OLDCWD}
2282 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2283
2284 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2285 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2286 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2287
2288 # simple webserver
2289 check_com -c python && alias http="python -m SimpleHTTPServer"
2290
2291 # work around non utf8 capable software in utf environment via $LANG and luit
2292 if check_com isutfenv && check_com luit ; then
2293     if check_com -c mrxvt ; then
2294         isutfenv && [[ -n "$LANG" ]] && \
2295             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2296     fi
2297
2298     if check_com -c aterm ; then
2299         isutfenv && [[ -n "$LANG" ]] && \
2300             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2301     fi
2302
2303     if check_com -c centericq ; then
2304         isutfenv && [[ -n "$LANG" ]] && \
2305             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2306     fi
2307 fi
2308
2309 # useful functions
2310
2311 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2312 bk() {
2313     emulate -L zsh
2314     cp -b $1 $1_`date --iso-8601=m`
2315 }
2316
2317 #f5# cd to directoy and list files
2318 cl() {
2319     emulate -L zsh
2320     cd $1 && ls -a
2321 }
2322
2323 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2324 cd() {
2325     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2326         [[ ! -e ${1:h} ]] && return 1
2327         print "Correcting ${1} to ${1:h}"
2328         builtin cd ${1:h}
2329     else
2330         builtin cd "$@"
2331     fi
2332 }
2333
2334 #f5# Create Directoy and \kbd{cd} to it
2335 mkcd() {
2336     mkdir -p "$@" && cd "$@"
2337 }
2338
2339 #f5# Create temporary directory and \kbd{cd} to it
2340 cdt() {
2341     local t
2342     t=$(mktemp -d)
2343     echo "$t"
2344     builtin cd "$t"
2345 }
2346
2347 #f5# Create directory under cursor or the selected area
2348 # Press ctrl-xM to create the directory under the cursor or the selected area.
2349 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2350 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2351 # directory does not exist yet -> press ctrl-XM and problem solved
2352 inplaceMkDirs() {
2353     local PATHTOMKDIR
2354     if ((REGION_ACTIVE==1)); then
2355         local F=$MARK T=$CURSOR
2356         if [[ $F -gt $T ]]; then
2357             F=${CURSOR}
2358             T=${MARK}
2359         fi
2360         # get marked area from buffer and eliminate whitespace
2361         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2362         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2363     else
2364         local bufwords iword
2365         bufwords=(${(z)LBUFFER})
2366         iword=${#bufwords}
2367         bufwords=(${(z)BUFFER})
2368         PATHTOMKDIR="${(Q)bufwords[iword]}"
2369     fi
2370     [[ -z "${PATHTOMKDIR}" ]] && return 1
2371     if [[ -e "${PATHTOMKDIR}" ]]; then
2372         zle -M " path already exists, doing nothing"
2373     else
2374         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2375         zle end-of-line
2376     fi
2377 }
2378 #k# mkdir -p <dir> from string under cursor or marked area
2379 zle -N inplaceMkDirs && bindkey '^XM' inplaceMkDirs
2380
2381 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2382 accessed() {
2383     emulate -L zsh
2384     print -l -- *(a-${1:-1})
2385 }
2386
2387 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2388 changed() {
2389     emulate -L zsh
2390     print -l -- *(c-${1:-1})
2391 }
2392
2393 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2394 modified() {
2395     emulate -L zsh
2396     print -l -- *(m-${1:-1})
2397 }
2398 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2399 check_com new || alias new=modified
2400
2401 # use colors when GNU grep with color-support
2402 #a2# Execute \kbd{grep -{}-color=auto}
2403 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
2404
2405 # Translate DE<=>EN
2406 # 'translate' looks up fot a word in a file with language-to-language
2407 # translations (field separator should be " : "). A typical wordlist looks
2408 # like at follows:
2409 #  | english-word : german-transmission
2410 # It's also only possible to translate english to german but not reciprocal.
2411 # Use the following oneliner to turn back the sort order:
2412 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2413 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2414 #f5# Translates a word
2415 trans() {
2416     emulate -L zsh
2417     case "$1" in
2418         -[dD]*)
2419             translate -l de-en $2
2420             ;;
2421         -[eE]*)
2422             translate -l en-de $2
2423             ;;
2424         *)
2425             echo "Usage: $0 { -D | -E }"
2426             echo "         -D == German to English"
2427             echo "         -E == English to German"
2428     esac
2429 }
2430
2431 # Usage: simple-extract <file>
2432 # Using option -d deletes the original archive file.
2433 #f5# Smart archive extractor
2434 simple-extract() {
2435     emulate -L zsh
2436     setopt extended_glob noclobber
2437     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2438     local RC=0
2439     zparseopts -D -E "d=DELETE_ORIGINAL"
2440     for ARCHIVE in "${@}"; do
2441         case $ARCHIVE in
2442             *.(tar.bz2|tbz2|tbz))
2443                 DECOMP_CMD="tar -xvjf -"
2444                 USES_STDIN=true
2445                 USES_STDOUT=false
2446                 ;;
2447             *.(tar.gz|tgz))
2448                 DECOMP_CMD="tar -xvzf -"
2449                 USES_STDIN=true
2450                 USES_STDOUT=false
2451                 ;;
2452             *.(tar.xz|txz|tar.lzma))
2453                 DECOMP_CMD="tar -xvJf -"
2454                 USES_STDIN=true
2455                 USES_STDOUT=false
2456                 ;;
2457             *.tar)
2458                 DECOMP_CMD="tar -xvf -"
2459                 USES_STDIN=true
2460                 USES_STDOUT=false
2461                 ;;
2462             *.rar)
2463                 DECOMP_CMD="unrar x"
2464                 USES_STDIN=false
2465                 USES_STDOUT=false
2466                 ;;
2467             *.lzh)
2468                 DECOMP_CMD="lha x"
2469                 USES_STDIN=false
2470                 USES_STDOUT=false
2471                 ;;
2472             *.7z)
2473                 DECOMP_CMD="7z x"
2474                 USES_STDIN=false
2475                 USES_STDOUT=false
2476                 ;;
2477             *.(zip|jar))
2478                 DECOMP_CMD="unzip"
2479                 USES_STDIN=false
2480                 USES_STDOUT=false
2481                 ;;
2482             *.deb)
2483                 DECOMP_CMD="ar -x"
2484                 USES_STDIN=false
2485                 USES_STDOUT=false
2486                 ;;
2487             *.bz2)
2488                 DECOMP_CMD="bzip2 -d -c -"
2489                 USES_STDIN=true
2490                 USES_STDOUT=true
2491                 ;;
2492             *.(gz|Z))
2493                 DECOMP_CMD="gzip -d -c -"
2494                 USES_STDIN=true
2495                 USES_STDOUT=true
2496                 ;;
2497             *.(xz|lzma))
2498                 DECOMP_CMD="xz -d -c -"
2499                 USES_STDIN=true
2500                 USES_STDOUT=true
2501                 ;;
2502             *)
2503                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2504                 RC=$((RC+1))
2505                 continue
2506                 ;;
2507         esac
2508
2509         if ! check_com ${DECOMP_CMD[(w)1]}; then
2510             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2511             RC=$((RC+2))
2512             continue
2513         fi
2514
2515         GZTARGET="${ARCHIVE:t:r}"
2516         if [[ -f $ARCHIVE ]] ; then
2517
2518             print "Extracting '$ARCHIVE' ..."
2519             if $USES_STDIN; then
2520                 if $USES_STDOUT; then
2521                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
2522                 else
2523                     ${=DECOMP_CMD} < "$ARCHIVE"
2524                 fi
2525             else
2526                 if $USES_STDOUT; then
2527                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
2528                 else
2529                     ${=DECOMP_CMD} "$ARCHIVE"
2530                 fi
2531             fi
2532             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
2533
2534         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
2535             if check_com curl; then
2536                 WGET_CMD="curl -L -k -s -o -"
2537             elif check_com wget; then
2538                 WGET_CMD="wget -q -O - --no-check-certificate"
2539             else
2540                 print "ERROR: neither wget nor curl is installed" >&2
2541                 RC=$((RC+4))
2542                 continue
2543             fi
2544             print "Downloading and Extracting '$ARCHIVE' ..."
2545             if $USES_STDIN; then
2546                 if $USES_STDOUT; then
2547                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
2548                     RC=$((RC+$?))
2549                 else
2550                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
2551                     RC=$((RC+$?))
2552                 fi
2553             else
2554                 if $USES_STDOUT; then
2555                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
2556                 else
2557                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
2558                 fi
2559             fi
2560
2561         else
2562             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
2563             RC=$((RC+8))
2564         fi
2565     done
2566     return $RC
2567 }
2568
2569 __archive_or_uri()
2570 {
2571     _alternative \
2572         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
2573         '_urls:Remote Archives:_urls'
2574 }
2575
2576 _simple_extract()
2577 {
2578     _arguments \
2579         '-d[delete original archivefile after extraction]' \
2580         '*:Archive Or Uri:__archive_or_uri'
2581 }
2582 compdef _simple_extract simple-extract
2583 alias se=simple-extract
2584
2585 #f5# Set all ulimit parameters to \kbd{unlimited}
2586 allulimit() {
2587     ulimit -c unlimited
2588     ulimit -d unlimited
2589     ulimit -f unlimited
2590     ulimit -l unlimited
2591     ulimit -n unlimited
2592     ulimit -s unlimited
2593     ulimit -t unlimited
2594 }
2595
2596 #f5# Change the xterm title from within GNU-screen
2597 xtrename() {
2598     emulate -L zsh
2599     if [[ $1 != "-f" ]] ; then
2600         if [[ -z ${DISPLAY} ]] ; then
2601             printf 'xtrename only makes sense in X11.\n'
2602             return 1
2603         fi
2604     else
2605         shift
2606     fi
2607     if [[ -z $1 ]] ; then
2608         printf 'usage: xtrename [-f] "title for xterm"\n'
2609         printf '  renames the title of xterm from _within_ screen.\n'
2610         printf '  also works without screen.\n'
2611         printf '  will not work if DISPLAY is unset, use -f to override.\n'
2612         return 0
2613     fi
2614     print -n "\eP\e]0;${1}\C-G\e\\"
2615     return 0
2616 }
2617
2618 # TODO:
2619 # Rewrite this by either using tinyurl.com's API
2620 # or using another shortening service to comply with
2621 # tinyurl.com's policy.
2622 #
2623 # Create small urls via http://tinyurl.com using wget(1).
2624 #function zurl() {
2625 #    emulate -L zsh
2626 #    [[ -z $1 ]] && { print "USAGE: zurl <URL>" ; return 1 }
2627 #
2628 #    local PN url tiny grabber search result preview
2629 #    PN=$0
2630 #    url=$1
2631 ##   Check existence of given URL with the help of ping(1).
2632 ##   N.B. ping(1) only works without an eventual given protocol.
2633 #    ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
2634 #        read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
2635 #
2636 #    if (( $? == 0 )) ; then
2637 ##           Prepend 'http://' to given URL where necessary for later output.
2638 #            [[ ${url} != http(s|)://* ]] && url='http://'${url}
2639 #            tiny='http://tinyurl.com/create.php?url='
2640 #            if check_com -c wget ; then
2641 #                grabber='wget -O- -o/dev/null'
2642 #            else
2643 #                print "wget is not available, but mandatory for ${PN}. Aborting."
2644 #            fi
2645 ##           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
2646 #            search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
2647 #            result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
2648 ##           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
2649 #            preview='http://preview.'${result#http://}
2650 #
2651 #            printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
2652 #            printf '%s\t%s\n\n' 'Given URL:' ${url}
2653 #            printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
2654 #    else
2655 #        return 1
2656 #    fi
2657 #}
2658
2659 #f2# Find history events by search pattern and list them by date.
2660 whatwhen()  {
2661     emulate -L zsh
2662     local usage help ident format_l format_s first_char remain first last
2663     usage='USAGE: whatwhen [options] <searchstring> <search range>'
2664     help='Use `whatwhen -h'\'' for further explanations.'
2665     ident=${(l,${#${:-Usage: }},, ,)}
2666     format_l="${ident}%s\t\t\t%s\n"
2667     format_s="${format_l//(\\t)##/\\t}"
2668     # Make the first char of the word to search for case
2669     # insensitive; e.g. [aA]
2670     first_char=[${(L)1[1]}${(U)1[1]}]
2671     remain=${1[2,-1]}
2672     # Default search range is `-100'.
2673     first=${2:-\-100}
2674     # Optional, just used for `<first> <last>' given.
2675     last=$3
2676     case $1 in
2677         ("")
2678             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
2679             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2680         ;;
2681         (-h)
2682             printf '%s\n\n' ${usage}
2683             print 'OPTIONS:'
2684             printf $format_l '-h' 'show help text'
2685             print '\f'
2686             print 'SEARCH RANGE:'
2687             printf $format_l "'0'" 'the whole history,'
2688             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
2689             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
2690             printf '\n%s\n' 'EXAMPLES:'
2691             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
2692             printf $format_l 'whatwhen zsh -250'
2693             printf $format_l 'whatwhen foo 1 99'
2694         ;;
2695         (\?)
2696             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2697         ;;
2698         (*)
2699             # -l list results on stout rather than invoking $EDITOR.
2700             # -i Print dates as in YYYY-MM-DD.
2701             # -m Search for a - quoted - pattern within the history.
2702             fc -li -m "*${first_char}${remain}*" $first $last
2703         ;;
2704     esac
2705 }
2706
2707 # mercurial related stuff
2708 if check_com -c hg ; then
2709     # gnu like diff for mercurial
2710     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
2711     #f5# GNU like diff for mercurial
2712     hgdi() {
2713         emulate -L zsh
2714         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
2715     }
2716
2717     # build debian package
2718     #a2# Alias for \kbd{hg-buildpackage}
2719     alias hbp='hg-buildpackage'
2720
2721     # execute commands on the versioned patch-queue from the current repos
2722     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
2723
2724     # diffstat for specific version of a mercurial repository
2725     #   hgstat      => display diffstat between last revision and tip
2726     #   hgstat 1234 => display diffstat between revision 1234 and tip
2727     #f5# Diffstat for specific version of a mercurial repos
2728     hgstat() {
2729         emulate -L zsh
2730         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
2731     }
2732
2733 fi # end of check whether we have the 'hg'-executable
2734
2735 # grml-small cleanups
2736
2737 # The following is used to remove zsh-config-items that do not work
2738 # in grml-small by default.
2739 # If you do not want these adjustments (for whatever reason), set
2740 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
2741 # sources if it is there).
2742
2743 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
2744
2745     unset abk[V]
2746     unalias    'V'      &> /dev/null
2747     unfunction vman     &> /dev/null
2748     unfunction viless   &> /dev/null
2749     unfunction 2html    &> /dev/null
2750
2751     # manpages are not in grmlsmall
2752     unfunction manzsh   &> /dev/null
2753     unfunction man2     &> /dev/null
2754
2755 fi
2756
2757 zrclocal
2758
2759 ## genrefcard.pl settings
2760
2761 ### doc strings for external functions from files
2762 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
2763
2764 ### example: split functions-search 8,16,24,32
2765 #@# split functions-search 8
2766
2767 ## END OF FILE #################################################################
2768 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
2769 # Local variables:
2770 # mode: sh
2771 # End: