etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is437(){
 148     [[ $ZSH_VERSION == 4.3.<7->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 is439(){
 154     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 155                                  || $ZSH_VERSION == <5->* ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running grml
 160 isgrml(){
 161     [[ -f /etc/grml_version ]] && return 0
 162     return 1
 163 }
 164
 165 #f1# Checks whether or not you're running a grml cd
 166 isgrmlcd(){
 167     [[ -f /etc/grml_cd ]] && return 0
 168     return 1
 169 }
 170
 171 if isgrml ; then
 172 #f1# Checks whether or not you're running grml-small
 173     isgrmlsmall() {
 174         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 175             return 0
 176         fi
 177         return 1
 178     }
 179 else
 180     isgrmlsmall() { return 1 }
 181 fi
 182
 183 GRML_OSTYPE=$(uname -s)
 184
 185 islinux(){
 186     [[ $GRML_OSTYPE == "Linux" ]]
 187 }
 188
 189 isdarwin(){
 190     [[ $GRML_OSTYPE == "Darwin" ]]
 191 }
 192
 193 isfreebsd(){
 194     [[ $GRML_OSTYPE == "FreeBSD" ]]
 195 }
 196
 197 isopenbsd(){
 198     [[ $GRML_OSTYPE == "OpenBSD" ]]
 199 }
 200
 201 issolaris(){
 202     [[ $GRML_OSTYPE == "SunOS" ]]
 203 }
 204
 205 #f1# are we running within an utf environment?
 206 isutfenv() {
 207     case "$LANG $CHARSET $LANGUAGE" in
 208         *utf*) return 0 ;;
 209         *UTF*) return 0 ;;
 210         *)     return 1 ;;
 211     esac
 212 }
 213
 214 # check for user, if not running as root set $SUDO to sudo
 215 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 216
 217 # change directory to home on first invocation of zsh
 218 # important for rungetty -> autologin
 219 # Thanks go to Bart Schaefer!
 220 isgrml && checkhome() {
 221     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 222         export ALREADY_DID_CD_HOME=$HOME
 223         cd
 224     fi
 225 }
 226
 227 # check for zsh v3.1.7+
 228
 229 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 230      || ${ZSH_VERSION} == 3.<2->.<->*    \
 231      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 232
 233     printf '-!-\n'
 234     printf '-!- In this configuration we try to make use of features, that only\n'
 235     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 236     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 237     printf '-!- advanced features in all supported versions.\n'
 238     printf '-!-\n'
 239     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 240     printf '-!-\n'
 241     printf '-!- While this *may* work, it might as well fail.\n'
 242     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 243     printf '-!-\n'
 244     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 245     printf '-!- If it does today, you'\''ve been lucky.\n'
 246     printf '-!-\n'
 247     printf '-!- Ye been warned!\n'
 248     printf '-!-\n'
 249
 250     function zstyle() { : }
 251 fi
 252
 253 # autoload wrapper - use this one instead of autoload directly
 254 # We need to define this function as early as this, because autoloading
 255 # 'is-at-least()' needs it.
 256 function zrcautoload() {
 257     emulate -L zsh
 258     setopt extended_glob
 259     local fdir ffile
 260     local -i ffound
 261
 262     ffile=$1
 263     (( ffound = 0 ))
 264     for fdir in ${fpath} ; do
 265         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 266     done
 267
 268     (( ffound == 0 )) && return 1
 269     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 270         autoload -U ${ffile} || return 1
 271     else
 272         autoload ${ffile} || return 1
 273     fi
 274     return 0
 275 }
 276
 277 # The following is the ‘add-zsh-hook’ function from zsh upstream. It is
 278 # included here to make the setup work with older versions of zsh (prior to
 279 # 4.3.7) in which this function had a bug that triggers annoying errors during
 280 # shell startup. This is exactly upstreams code from f0068edb4888a4d8fe94def,
 281 # with just a few adjustments in coding style to make the function look more
 282 # compact. This definition can be removed as soon as we raise the minimum
 283 # version requirement to 4.3.7 or newer.
 284 function add-zsh-hook() {
 285     # Add to HOOK the given FUNCTION.
 286     # HOOK is one of chpwd, precmd, preexec, periodic, zshaddhistory,
 287     # zshexit, zsh_directory_name (the _functions subscript is not required).
 288     #
 289     # With -d, remove the function from the hook instead; delete the hook
 290     # variable if it is empty.
 291     #
 292     # -D behaves like -d, but pattern characters are active in the function
 293     # name, so any matching function will be deleted from the hook.
 294     #
 295     # Without -d, the FUNCTION is marked for autoload; -U is passed down to
 296     # autoload if that is given, as are -z and -k. (This is harmless if the
 297     # function is actually defined inline.)
 298     emulate -L zsh
 299     local -a hooktypes
 300     hooktypes=(
 301         chpwd precmd preexec periodic zshaddhistory zshexit
 302         zsh_directory_name
 303     )
 304     local usage="Usage: $0 hook function\nValid hooks are:\n  $hooktypes"
 305     local opt
 306     local -a autoopts
 307     integer del list help
 308     while getopts "dDhLUzk" opt; do
 309         case $opt in
 310         (d) del=1 ;;
 311         (D) del=2 ;;
 312         (h) help=1 ;;
 313         (L) list=1 ;;
 314         ([Uzk]) autoopts+=(-$opt) ;;
 315         (*) return 1 ;;
 316         esac
 317     done
 318     shift $(( OPTIND - 1 ))
 319     if (( list )); then
 320         typeset -mp "(${1:-${(@j:|:)hooktypes}})_functions"
 321         return $?
 322     elif (( help || $# != 2 || ${hooktypes[(I)$1]} == 0 )); then
 323         print -u$(( 2 - help )) $usage
 324         return $(( 1 - help ))
 325     fi
 326     local hook="${1}_functions"
 327     local fn="$2"
 328     if (( del )); then
 329         # delete, if hook is set
 330         if (( ${(P)+hook} )); then
 331             if (( del == 2 )); then
 332                 set -A $hook ${(P)hook:#${~fn}}
 333             else
 334                 set -A $hook ${(P)hook:#$fn}
 335             fi
 336             # unset if no remaining entries --- this can give better
 337             # performance in some cases
 338             if (( ! ${(P)#hook} )); then
 339                 unset $hook
 340             fi
 341         fi
 342     else
 343         if (( ${(P)+hook} )); then
 344             if (( ${${(P)hook}[(I)$fn]} == 0 )); then
 345                 set -A $hook ${(P)hook} $fn
 346             fi
 347         else
 348             set -A $hook $fn
 349         fi
 350         autoload $autoopts -- $fn
 351     fi
 352 }
 353
 354 # Load is-at-least() for more precise version checks Note that this test will
 355 # *always* fail, if the is-at-least function could not be marked for
 356 # autoloading.
 357 zrcautoload is-at-least || is-at-least() { return 1 }
 358
 359 # set some important options (as early as possible)
 360
 361 # append history list to the history file; this is the default but we make sure
 362 # because it's required for share_history.
 363 setopt append_history
 364
 365 # import new commands from the history file also in other zsh-session
 366 is4 && setopt share_history
 367
 368 # save each command's beginning timestamp and the duration to the history file
 369 setopt extended_history
 370
 371 # If a new command line being added to the history list duplicates an older
 372 # one, the older command is removed from the list
 373 is4 && setopt histignorealldups
 374
 375 # remove command lines from the history list when the first character on the
 376 # line is a space
 377 setopt histignorespace
 378
 379 # if a command is issued that can't be executed as a normal command, and the
 380 # command is the name of a directory, perform the cd command to that directory.
 381 setopt auto_cd
 382
 383 # in order to use #, ~ and ^ for filename generation grep word
 384 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 385 # don't forget to quote '^', '~' and '#'!
 386 setopt extended_glob
 387
 388 # display PID when suspending processes as well
 389 setopt longlistjobs
 390
 391 # try to avoid the 'zsh: no matches found...'
 392 setopt nonomatch
 393
 394 # report the status of backgrounds jobs immediately
 395 setopt notify
 396
 397 # whenever a command completion is attempted, make sure the entire command path
 398 # is hashed first.
 399 setopt hash_list_all
 400
 401 # not just at the end
 402 setopt completeinword
 403
 404 # Don't send SIGHUP to background processes when the shell exits.
 405 setopt nohup
 406
 407 # make cd push the old directory onto the directory stack.
 408 setopt auto_pushd
 409
 410 # avoid "beep"ing
 411 setopt nobeep
 412
 413 # don't push the same dir twice.
 414 setopt pushd_ignore_dups
 415
 416 # * shouldn't match dotfiles. ever.
 417 setopt noglobdots
 418
 419 # use zsh style word splitting
 420 setopt noshwordsplit
 421
 422 # don't error out when unset parameters are used
 423 setopt unset
 424
 425 # setting some default values
 426 NOCOR=${NOCOR:-0}
 427 NOMENU=${NOMENU:-0}
 428 NOPRECMD=${NOPRECMD:-0}
 429 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 430 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 431 GRML_DISPLAY_BATTERY=${GRML_DISPLAY_BATTERY:-${BATTERY:-0}}
 432 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 433 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 434
 435 typeset -ga ls_options
 436 typeset -ga grep_options
 437 if ls --color=auto / >/dev/null 2>&1; then
 438     ls_options+=( --color=auto )
 439 elif ls -G / >/dev/null 2>&1; then
 440     ls_options+=( -G )
 441 fi
 442 if grep --color=auto -q "a" <<< "a" >/dev/null 2>&1; then
 443     grep_options+=( --color=auto )
 444 fi
 445
 446 # utility functions
 447 # this function checks if a command exists and returns either true
 448 # or false. This avoids using 'which' and 'whence', which will
 449 # avoid problems with aliases for which on certain weird systems. :-)
 450 # Usage: check_com [-c|-g] word
 451 #   -c  only checks for external commands
 452 #   -g  does the usual tests and also checks for global aliases
 453 check_com() {
 454     emulate -L zsh
 455     local -i comonly gatoo
 456
 457     if [[ $1 == '-c' ]] ; then
 458         (( comonly = 1 ))
 459         shift
 460     elif [[ $1 == '-g' ]] ; then
 461         (( gatoo = 1 ))
 462     else
 463         (( comonly = 0 ))
 464         (( gatoo = 0 ))
 465     fi
 466
 467     if (( ${#argv} != 1 )) ; then
 468         printf 'usage: check_com [-c] <command>\n' >&2
 469         return 1
 470     fi
 471
 472     if (( comonly > 0 )) ; then
 473         [[ -n ${commands[$1]}  ]] && return 0
 474         return 1
 475     fi
 476
 477     if   [[ -n ${commands[$1]}    ]] \
 478       || [[ -n ${functions[$1]}   ]] \
 479       || [[ -n ${aliases[$1]}     ]] \
 480       || [[ -n ${reswords[(r)$1]} ]] ; then
 481
 482         return 0
 483     fi
 484
 485     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 486         return 0
 487     fi
 488
 489     return 1
 490 }
 491
 492 # creates an alias and precedes the command with
 493 # sudo if $EUID is not zero.
 494 salias() {
 495     emulate -L zsh
 496     local only=0 ; local multi=0
 497     local key val
 498     while getopts ":hao" opt; do
 499         case $opt in
 500             o) only=1 ;;
 501             a) multi=1 ;;
 502             h)
 503                 printf 'usage: salias [-hoa] <alias-expression>\n'
 504                 printf '  -h      shows this help text.\n'
 505                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 506                 printf '          be careful using this option.\n'
 507                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 508                 return 0
 509                 ;;
 510             *) salias -h >&2; return 1 ;;
 511         esac
 512     done
 513     shift "$((OPTIND-1))"
 514
 515     if (( ${#argv} > 1 )) ; then
 516         printf 'Too many arguments %s\n' "${#argv}"
 517         return 1
 518     fi
 519
 520     key="${1%%\=*}" ;  val="${1#*\=}"
 521     if (( EUID == 0 )) && (( only == 0 )); then
 522         alias -- "${key}=${val}"
 523     elif (( EUID > 0 )) ; then
 524         (( multi > 0 )) && val="${val// ; / ; sudo }"
 525         alias -- "${key}=sudo ${val}"
 526     fi
 527
 528     return 0
 529 }
 530
 531 # Check if we can read given files and source those we can.
 532 xsource() {
 533     if (( ${#argv} < 1 )) ; then
 534         printf 'usage: xsource FILE(s)...\n' >&2
 535         return 1
 536     fi
 537
 538     while (( ${#argv} > 0 )) ; do
 539         [[ -r "$1" ]] && source "$1"
 540         shift
 541     done
 542     return 0
 543 }
 544
 545 # Check if we can read a given file and 'cat(1)' it.
 546 xcat() {
 547     emulate -L zsh
 548     if (( ${#argv} != 1 )) ; then
 549         printf 'usage: xcat FILE\n' >&2
 550         return 1
 551     fi
 552
 553     [[ -r $1 ]] && cat $1
 554     return 0
 555 }
 556
 557 # Remove these functions again, they are of use only in these
 558 # setup files. This should be called at the end of .zshrc.
 559 xunfunction() {
 560     emulate -L zsh
 561     local -a funcs
 562     local func
 563     funcs=(salias xcat xsource xunfunction zrcautoload zrcautozle)
 564     for func in $funcs ; do
 565         [[ -n ${functions[$func]} ]] \
 566             && unfunction $func
 567     done
 568     return 0
 569 }
 570
 571 # this allows us to stay in sync with grml's zshrc and put own
 572 # modifications in ~/.zshrc.local
 573 zrclocal() {
 574     xsource "/etc/zsh/zshrc.local"
 575     xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
 576     return 0
 577 }
 578
 579 # locale setup
 580 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 581     xsource "/etc/default/locale"
 582 fi
 583
 584 for var in LANG LC_ALL LC_MESSAGES ; do
 585     [[ -n ${(P)var} ]] && export $var
 586 done
 587 builtin unset -v var
 588
 589 # set some variables
 590 if check_com -c vim ; then
 591 #v#
 592     export EDITOR=${EDITOR:-vim}
 593 else
 594     export EDITOR=${EDITOR:-vi}
 595 fi
 596
 597 #v#
 598 export PAGER=${PAGER:-less}
 599
 600 #v#
 601 export MAIL=${MAIL:-/var/mail/$USER}
 602
 603 # color setup for ls:
 604 check_com -c dircolors && eval $(dircolors -b)
 605 # color setup for ls on OS X / FreeBSD:
 606 isdarwin && export CLICOLOR=1
 607 isfreebsd && export CLICOLOR=1
 608
 609 # do MacPorts setup on darwin
 610 if isdarwin && [[ -d /opt/local ]]; then
 611     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 612     # zshenv.
 613     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 614     MANPATH="/opt/local/share/man:$MANPATH"
 615 fi
 616 # do Fink setup on darwin
 617 isdarwin && xsource /sw/bin/init.sh
 618
 619 # load our function and completion directories
 620 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 621     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 622     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 623         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 624             zrcautoload ${func:t}
 625         done
 626     fi
 627 done
 628 unset fdir func
 629
 630 # support colors in less
 631 export LESS_TERMCAP_mb=$'\E[01;31m'
 632 export LESS_TERMCAP_md=$'\E[01;31m'
 633 export LESS_TERMCAP_me=$'\E[0m'
 634 export LESS_TERMCAP_se=$'\E[0m'
 635 export LESS_TERMCAP_so=$'\E[01;44;33m'
 636 export LESS_TERMCAP_ue=$'\E[0m'
 637 export LESS_TERMCAP_us=$'\E[01;32m'
 638
 639 # mailchecks
 640 MAILCHECK=30
 641
 642 # report about cpu-/system-/user-time of command if running longer than
 643 # 5 seconds
 644 REPORTTIME=5
 645
 646 # watch for everyone but me and root
 647 watch=(notme root)
 648
 649 # automatically remove duplicates from these arrays
 650 typeset -U path cdpath fpath manpath
 651
 652 # Load a few modules
 653 is4 && \
 654 for mod in parameter complist deltochar mathfunc ; do
 655     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 656 done && builtin unset -v mod
 657
 658 # autoload zsh modules when they are referenced
 659 if is4 ; then
 660     zmodload -a  zsh/stat    zstat
 661     zmodload -a  zsh/zpty    zpty
 662     zmodload -ap zsh/mapfile mapfile
 663 fi
 664
 665 # completion system
 666 COMPDUMPFILE=${COMPDUMPFILE:-${ZDOTDIR:-${HOME}}/.zcompdump}
 667 if zrcautoload compinit ; then
 668     compinit -d ${COMPDUMPFILE} || print 'Notice: no compinit available :('
 669 else
 670     print 'Notice: no compinit available :('
 671     function compdef { }
 672 fi
 673
 674 # completion system
 675
 676 # called later (via is4 && grmlcomp)
 677 # note: use 'zstyle' for getting current settings
 678 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
 679 grmlcomp() {
 680     # TODO: This could use some additional information
 681
 682     # Make sure the completion system is initialised
 683     (( ${+_comps} )) || return 1
 684
 685     # allow one error for every three characters typed in approximate completer
 686     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
 687
 688     # don't complete backup files as executables
 689     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
 690
 691     # start menu completion only if it could find no unambiguous initial string
 692     zstyle ':completion:*:correct:*'       insert-unambiguous true
 693     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
 694     zstyle ':completion:*:correct:*'       original true
 695
 696     # activate color-completion
 697     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
 698
 699     # format on completion
 700     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
 701
 702     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
 703     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
 704
 705     # insert all expansions for expand completer
 706     zstyle ':completion:*:expand:*'        tag-order all-expansions
 707     zstyle ':completion:*:history-words'   list false
 708
 709     # activate menu
 710     zstyle ':completion:*:history-words'   menu yes
 711
 712     # ignore duplicate entries
 713     zstyle ':completion:*:history-words'   remove-all-dups yes
 714     zstyle ':completion:*:history-words'   stop yes
 715
 716     # match uppercase from lowercase
 717     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
 718
 719     # separate matches into groups
 720     zstyle ':completion:*:matches'         group 'yes'
 721     zstyle ':completion:*'                 group-name ''
 722
 723     if [[ "$NOMENU" -eq 0 ]] ; then
 724         # if there are more than 5 options allow selecting from a menu
 725         zstyle ':completion:*'               menu select=5
 726     else
 727         # don't use any menus at all
 728         setopt no_auto_menu
 729     fi
 730
 731     zstyle ':completion:*:messages'        format '%d'
 732     zstyle ':completion:*:options'         auto-description '%d'
 733
 734     # describe options in full
 735     zstyle ':completion:*:options'         description 'yes'
 736
 737     # on processes completion complete all user processes
 738     zstyle ':completion:*:processes'       command 'ps -au$USER'
 739
 740     # offer indexes before parameters in subscripts
 741     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
 742
 743     # provide verbose completion information
 744     zstyle ':completion:*'                 verbose true
 745
 746     # recent (as of Dec 2007) zsh versions are able to provide descriptions
 747     # for commands (read: 1st word in the line) that it will list for the user
 748     # to choose from. The following disables that, because it's not exactly fast.
 749     zstyle ':completion:*:-command-:*:'    verbose false
 750
 751     # set format for warnings
 752     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
 753
 754     # define files to ignore for zcompile
 755     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
 756     zstyle ':completion:correct:'          prompt 'correct to: %e'
 757
 758     # Ignore completion functions for commands you don't have:
 759     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
 760
 761     # Provide more processes in completion of programs like killall:
 762     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
 763
 764     # complete manual by their section
 765     zstyle ':completion:*:manuals'    separate-sections true
 766     zstyle ':completion:*:manuals.*'  insert-sections   true
 767     zstyle ':completion:*:man:*'      menu yes select
 768
 769     # Search path for sudo completion
 770     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
 771                                                /usr/local/bin  \
 772                                                /usr/sbin       \
 773                                                /usr/bin        \
 774                                                /sbin           \
 775                                                /bin            \
 776                                                /usr/X11R6/bin
 777
 778     # provide .. as a completion
 779     zstyle ':completion:*' special-dirs ..
 780
 781     # run rehash on completion so new installed program are found automatically:
 782     _force_rehash() {
 783         (( CURRENT == 1 )) && rehash
 784         return 1
 785     }
 786
 787     ## correction
 788     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
 789     if [[ "$NOCOR" -gt 0 ]] ; then
 790         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
 791         setopt nocorrect
 792     else
 793         # try to be smart about when to use what completer...
 794         setopt correct
 795         zstyle -e ':completion:*' completer '
 796             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
 797                 _last_try="$HISTNO$BUFFER$CURSOR"
 798                 reply=(_complete _match _ignored _prefix _files)
 799             else
 800                 if [[ $words[1] == (rm|mv) ]] ; then
 801                     reply=(_complete _files)
 802                 else
 803                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
 804                 fi
 805             fi'
 806     fi
 807
 808     # command for process lists, the local web server details and host completion
 809     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
 810
 811     # caching
 812     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
 813                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
 814
 815     # host completion
 816     if is42 ; then
 817         [[ -r ~/.ssh/config ]] && _ssh_config_hosts=(${${(s: :)${(ps:\t:)${${(@M)${(f)"$(<$HOME/.ssh/config)"}:#Host *}#Host }}}:#*[*?]*}) || _ssh_config_hosts=()
 818         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
 819         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
 820     else
 821         _ssh_config_hosts=()
 822         _ssh_hosts=()
 823         _etc_hosts=()
 824     fi
 825     hosts=(
 826         $(hostname)
 827         "$_ssh_config_hosts[@]"
 828         "$_ssh_hosts[@]"
 829         "$_etc_hosts[@]"
 830         localhost
 831     )
 832     zstyle ':completion:*:hosts' hosts $hosts
 833     # TODO: so, why is this here?
 834     #  zstyle '*' hosts $hosts
 835
 836     # use generic completion system for programs not yet defined; (_gnu_generic works
 837     # with commands that provide a --help option with "standard" gnu-like output.)
 838     for compcom in cp deborphan df feh fetchipac gpasswd head hnb ipacsum mv \
 839                    pal stow uname ; do
 840         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
 841     done; unset compcom
 842
 843     # see upgrade function in this file
 844     compdef _hosts upgrade
 845 }
 846
 847 # Keyboard setup: The following is based on the same code, we wrote for
 848 # debian's setup. It ensures the terminal is in the right mode, when zle is
 849 # active, so the values from $terminfo are valid. Therefore, this setup should
 850 # work on all systems, that have support for `terminfo'. It also requires the
 851 # zsh in use to have the `zsh/terminfo' module built.
 852 #
 853 # If you are customising your `zle-line-init()' or `zle-line-finish()'
 854 # functions, make sure you call the following utility functions in there:
 855 #
 856 #     - zle-line-init():      zle-smkx
 857 #     - zle-line-finish():    zle-rmkx
 858
 859 # Use emacs-like key bindings by default:
 860 bindkey -e
 861
 862 # Custom widgets:
 863
 864 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 865 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 866 beginning-or-end-of-somewhere() {
 867     local hno=$HISTNO
 868     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 869       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 870         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 871     else
 872         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 873         if (( HISTNO != hno )); then
 874             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 875         fi
 876     fi
 877 }
 878 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 879 zle -N end-of-somewhere beginning-or-end-of-somewhere
 880
 881 # add a command line to the shells history without executing it
 882 commit-to-history() {
 883     print -s ${(z)BUFFER}
 884     zle send-break
 885 }
 886 zle -N commit-to-history
 887
 888 # only slash should be considered as a word separator:
 889 slash-backward-kill-word() {
 890     local WORDCHARS="${WORDCHARS:s@/@}"
 891     # zle backward-word
 892     zle backward-kill-word
 893 }
 894 zle -N slash-backward-kill-word
 895
 896 # a generic accept-line wrapper
 897
 898 # This widget can prevent unwanted autocorrections from command-name
 899 # to _command-name, rehash automatically on enter and call any number
 900 # of builtin and user-defined widgets in different contexts.
 901 #
 902 # For a broader description, see:
 903 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 904 #
 905 # The code is imported from the file 'zsh/functions/accept-line' from
 906 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 907 # distributed under the same terms as zsh itself.
 908
 909 # A newly added command will may not be found or will cause false
 910 # correction attempts, if you got auto-correction set. By setting the
 911 # following style, we force accept-line() to rehash, if it cannot
 912 # find the first word on the command line in the $command[] hash.
 913 zstyle ':acceptline:*' rehash true
 914
 915 function Accept-Line() {
 916     setopt localoptions noksharrays
 917     local -a subs
 918     local -xi aldone
 919     local sub
 920     local alcontext=${1:-$alcontext}
 921
 922     zstyle -a ":acceptline:${alcontext}" actions subs
 923
 924     (( ${#subs} < 1 )) && return 0
 925
 926     (( aldone = 0 ))
 927     for sub in ${subs} ; do
 928         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 929         zle ${sub}
 930
 931         (( aldone > 0 )) && break
 932     done
 933 }
 934
 935 function Accept-Line-getdefault() {
 936     emulate -L zsh
 937     local default_action
 938
 939     zstyle -s ":acceptline:${alcontext}" default_action default_action
 940     case ${default_action} in
 941         ((accept-line|))
 942             printf ".accept-line"
 943             ;;
 944         (*)
 945             printf ${default_action}
 946             ;;
 947     esac
 948 }
 949
 950 function Accept-Line-HandleContext() {
 951     zle Accept-Line
 952
 953     default_action=$(Accept-Line-getdefault)
 954     zstyle -T ":acceptline:${alcontext}" call_default \
 955         && zle ${default_action}
 956 }
 957
 958 function accept-line() {
 959     setopt localoptions noksharrays
 960     local -a cmdline
 961     local -x alcontext
 962     local buf com fname format msg default_action
 963
 964     alcontext='default'
 965     buf="${BUFFER}"
 966     cmdline=(${(z)BUFFER})
 967     com="${cmdline[1]}"
 968     fname="_${com}"
 969
 970     Accept-Line 'preprocess'
 971
 972     zstyle -t ":acceptline:${alcontext}" rehash \
 973         && [[ -z ${commands[$com]} ]]           \
 974         && rehash
 975
 976     if    [[ -n ${com}               ]] \
 977        && [[ -n ${reswords[(r)$com]} ]] \
 978        || [[ -n ${aliases[$com]}     ]] \
 979        || [[ -n ${functions[$com]}   ]] \
 980        || [[ -n ${builtins[$com]}    ]] \
 981        || [[ -n ${commands[$com]}    ]] ; then
 982
 983         # there is something sensible to execute, just do it.
 984         alcontext='normal'
 985         Accept-Line-HandleContext
 986
 987         return
 988     fi
 989
 990     if    [[ -o correct              ]] \
 991        || [[ -o correctall           ]] \
 992        && [[ -n ${functions[$fname]} ]] ; then
 993
 994         # nothing there to execute but there is a function called
 995         # _command_name; a completion widget. Makes no sense to
 996         # call it on the commandline, but the correct{,all} options
 997         # will ask for it nevertheless, so warn the user.
 998         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 999             # Okay, we warned the user before, he called us again,
1000             # so have it his way.
1001             alcontext='force'
1002             Accept-Line-HandleContext
1003
1004             return
1005         fi
1006
1007         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
1008             alcontext='normal'
1009             Accept-Line-HandleContext
1010         else
1011             # prepare warning message for the user, configurable via zstyle.
1012             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
1013
1014             if [[ -z ${msg} ]] ; then
1015                 msg="%c will not execute and completion %f exists."
1016             fi
1017
1018             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
1019
1020             zle -M -- "${msg}"
1021         fi
1022         return
1023     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
1024         # If we are here, the commandline contains something that is not
1025         # executable, which is neither subject to _command_name correction
1026         # and is not empty. might be a variable assignment
1027         alcontext='misc'
1028         Accept-Line-HandleContext
1029
1030         return
1031     fi
1032
1033     # If we got this far, the commandline only contains whitespace, or is empty.
1034     alcontext='empty'
1035     Accept-Line-HandleContext
1036 }
1037
1038 zle -N accept-line
1039 zle -N Accept-Line
1040 zle -N Accept-Line-HandleContext
1041
1042 # power completion / abbreviation expansion / buffer expansion
1043 # see http://zshwiki.org/home/examples/zleiab for details
1044 # less risky than the global aliases but powerful as well
1045 # just type the abbreviation key and afterwards 'ctrl-x .' to expand it
1046 declare -A abk
1047 setopt extendedglob
1048 setopt interactivecomments
1049 abk=(
1050 #   key   # value                  (#d additional doc string)
1051 #A# start
1052     '...'  '../..'
1053     '....' '../../..'
1054     'BG'   '& exit'
1055     'C'    '| wc -l'
1056     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
1057     'H'    '| head'
1058     'Hl'   ' --help |& less -r'    #d (Display help in pager)
1059     'L'    '| less'
1060     'LL'   '|& less -r'
1061     'M'    '| most'
1062     'N'    '&>/dev/null'           #d (No Output)
1063     'R'    '| tr A-z N-za-m'       #d (ROT13)
1064     'SL'   '| sort | less'
1065     'S'    '| sort -u'
1066     'T'    '| tail'
1067     'V'    '|& vim -'
1068 #A# end
1069     'co'   './configure && make && sudo make install'
1070 )
1071
1072 zleiab() {
1073     emulate -L zsh
1074     setopt extendedglob
1075     local MATCH
1076
1077     LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
1078     LBUFFER+=${abk[$MATCH]:-$MATCH}
1079 }
1080
1081 zle -N zleiab
1082
1083 help-show-abk()
1084 {
1085   zle -M "$(print "Available abbreviations for expansion:"; print -a -C 2 ${(kv)abk})"
1086 }
1087
1088 zle -N help-show-abk
1089
1090 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1091 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1092 zle -N insert-datestamp
1093
1094 # press esc-m for inserting last typed word again (thanks to caphuso!)
1095 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1096 zle -N insert-last-typed-word;
1097
1098 function grml-zsh-fg() {
1099   if (( ${#jobstates} )); then
1100     zle .push-input
1101     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1102     BUFFER="${BUFFER}fg"
1103     zle .accept-line
1104   else
1105     zle -M 'No background jobs. Doing nothing.'
1106   fi
1107 }
1108 zle -N grml-zsh-fg
1109
1110 # run command line as user root via sudo:
1111 sudo-command-line() {
1112     [[ -z $BUFFER ]] && zle up-history
1113     if [[ $BUFFER != sudo\ * ]]; then
1114         BUFFER="sudo $BUFFER"
1115         CURSOR=$(( CURSOR+5 ))
1116     fi
1117 }
1118 zle -N sudo-command-line
1119
1120 ### jump behind the first word on the cmdline.
1121 ### useful to add options.
1122 function jump_after_first_word() {
1123     local words
1124     words=(${(z)BUFFER})
1125
1126     if (( ${#words} <= 1 )) ; then
1127         CURSOR=${#BUFFER}
1128     else
1129         CURSOR=${#${words[1]}}
1130     fi
1131 }
1132 zle -N jump_after_first_word
1133
1134 #f5# Create directory under cursor or the selected area
1135 inplaceMkDirs() {
1136     # Press ctrl-xM to create the directory under the cursor or the selected area.
1137     # To select an area press ctrl-@ or ctrl-space and use the cursor.
1138     # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
1139     # directory does not exist yet -> press ctrl-XM and problem solved
1140     local PATHTOMKDIR
1141     if ((REGION_ACTIVE==1)); then
1142         local F=$MARK T=$CURSOR
1143         if [[ $F -gt $T ]]; then
1144             F=${CURSOR}
1145             T=${MARK}
1146         fi
1147         # get marked area from buffer and eliminate whitespace
1148         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
1149         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
1150     else
1151         local bufwords iword
1152         bufwords=(${(z)LBUFFER})
1153         iword=${#bufwords}
1154         bufwords=(${(z)BUFFER})
1155         PATHTOMKDIR="${(Q)bufwords[iword]}"
1156     fi
1157     [[ -z "${PATHTOMKDIR}" ]] && return 1
1158     PATHTOMKDIR=${~PATHTOMKDIR}
1159     if [[ -e "${PATHTOMKDIR}" ]]; then
1160         zle -M " path already exists, doing nothing"
1161     else
1162         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
1163         zle end-of-line
1164     fi
1165 }
1166
1167 zle -N inplaceMkDirs
1168
1169 #v1# set number of lines to display per page
1170 HELP_LINES_PER_PAGE=20
1171 #v1# set location of help-zle cache file
1172 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
1173 # helper function for help-zle, actually generates the help text
1174 help_zle_parse_keybindings()
1175 {
1176     emulate -L zsh
1177     setopt extendedglob
1178     unsetopt ksharrays  #indexing starts at 1
1179
1180     #v1# choose files that help-zle will parse for keybindings
1181     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
1182
1183     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
1184         local load_cache=0
1185         local f
1186         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
1187         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
1188     fi
1189
1190     #fill with default keybindings, possibly to be overwriten in a file later
1191     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
1192     local -A help_zle_keybindings
1193     help_zle_keybindings['<Ctrl>@']="set MARK"
1194     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
1195     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
1196     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
1197     help_zle_keybindings['<Ctrl>_']="undo"
1198     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
1199     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
1200     help_zle_keybindings['<Ctrl>e']="goto end of line"
1201     help_zle_keybindings['<Ctrl>t']="transpose charaters"
1202     help_zle_keybindings['<Alt>t']="transpose words"
1203     help_zle_keybindings['<Alt>s']="spellcheck word"
1204     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
1205     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
1206     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
1207     help_zle_keybindings["<Alt>'"]="quote line"
1208     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
1209     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
1210     help_zle_keybindings['<Alt>u']="make next word Uppercase"
1211     help_zle_keybindings['<Alt>l']="make next word lowercase"
1212     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
1213     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
1214     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
1215     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
1216     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
1217     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
1218     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
1219     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
1220     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
1221
1222     #init global variables
1223     unset help_zle_lines help_zle_sln
1224     typeset -g -a help_zle_lines
1225     typeset -g help_zle_sln=1
1226
1227     local k v f cline
1228     local lastkeybind_desc contents     #last description starting with #k# that we found
1229     local num_lines_elapsed=0            #number of lines between last description and keybinding
1230     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
1231     for f in $HELPZLE_KEYBINDING_FILES; do
1232         [[ -r "$f" ]] || continue   #not readable ? skip it
1233         contents="$(<$f)"
1234         for cline in "${(f)contents}"; do
1235             #zsh pattern: matches lines like: #k# ..............
1236             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
1237                 lastkeybind_desc="$match[*]"
1238                 num_lines_elapsed=0
1239             #zsh pattern: matches lines that set a keybinding using bind2map, bindkey or compdef -k
1240             #             ignores lines that are commentend out
1241             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
1242             elif [[ "$cline" == [^#]#(bind2maps[[:space:]](*)-s|bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
1243                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
1244                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
1245                     #substitute keybinding string with something readable
1246                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
1247                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
1248                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
1249                     help_zle_keybindings[${k}]=$lastkeybind_desc
1250                 fi
1251                 lastkeybind_desc=""
1252             else
1253               ((num_lines_elapsed++))
1254             fi
1255         done
1256     done
1257     unset contents
1258     #calculate length of keybinding column
1259     local kstrlen=0
1260     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
1261     #convert the assoc array into preformated lines, which we are able to sort
1262     for k v in ${(kv)help_zle_keybindings[@]}; do
1263         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
1264         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
1265     done
1266     #sort lines alphabetically
1267     help_zle_lines=("${(i)help_zle_lines[@]}")
1268     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
1269     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
1270     zcompile $HELP_ZLE_CACHE_FILE
1271 }
1272 typeset -g help_zle_sln
1273 typeset -g -a help_zle_lines
1274
1275 # Provides (partially autogenerated) help on keybindings and the zsh line editor
1276 help-zle()
1277 {
1278     emulate -L zsh
1279     unsetopt ksharrays  #indexing starts at 1
1280     #help lines already generated ? no ? then do it
1281     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
1282     #already displayed all lines ? go back to the start
1283     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
1284     local sln=$help_zle_sln
1285     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
1286     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
1287     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
1288 }
1289 zle -N help-zle
1290
1291 ## complete word from currently visible Screen or Tmux buffer.
1292 if check_com -c screen || check_com -c tmux; then
1293     _complete_screen_display() {
1294         [[ "$TERM" != "screen" ]] && return 1
1295
1296         local TMPFILE=$(mktemp)
1297         local -U -a _screen_display_wordlist
1298         trap "rm -f $TMPFILE" EXIT
1299
1300         # fill array with contents from screen hardcopy
1301         if ((${+TMUX})); then
1302             #works, but crashes tmux below version 1.4
1303             #luckily tmux -V option to ask for version, was also added in 1.4
1304             tmux -V &>/dev/null || return
1305             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1306         else
1307             screen -X hardcopy $TMPFILE
1308             # screen sucks, it dumps in latin1, apparently always. so recode it
1309             # to system charset
1310             check_com recode && recode latin1 $TMPFILE
1311         fi
1312         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1313         # remove PREFIX to be completed from that array
1314         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1315         compadd -a _screen_display_wordlist
1316     }
1317     #m# k CTRL-x\,\,\,S Complete word from GNU screen buffer
1318     bindkey -r "^xS"
1319     compdef -k _complete_screen_display complete-word '^xS'
1320 fi
1321
1322 # Load a few more functions and tie them to widgets, so they can be bound:
1323
1324 function zrcautozle() {
1325     emulate -L zsh
1326     local fnc=$1
1327     zrcautoload $fnc && zle -N $fnc
1328 }
1329
1330 function zrcgotwidget() {
1331     (( ${+widgets[$1]} ))
1332 }
1333
1334 function zrcgotkeymap() {
1335     [[ -n ${(M)keymaps:#$1} ]]
1336 }
1337
1338 zrcautozle insert-files
1339 zrcautozle edit-command-line
1340 zrcautozle insert-unicode-char
1341 if zrcautoload history-search-end; then
1342     zle -N history-beginning-search-backward-end history-search-end
1343     zle -N history-beginning-search-forward-end  history-search-end
1344 fi
1345 zle -C hist-complete complete-word _generic
1346 zstyle ':completion:hist-complete:*' completer _history
1347
1348 # The actual terminal setup hooks and bindkey-calls:
1349
1350 # An array to note missing features to ease diagnosis in case of problems.
1351 typeset -ga grml_missing_features
1352
1353 function zrcbindkey() {
1354     if (( ARGC )) && zrcgotwidget ${argv[-1]}; then
1355         bindkey "$@"
1356     fi
1357 }
1358
1359 function bind2maps () {
1360     local i sequence widget
1361     local -a maps
1362
1363     while [[ "$1" != "--" ]]; do
1364         maps+=( "$1" )
1365         shift
1366     done
1367     shift
1368
1369     if [[ "$1" == "-s" ]]; then
1370         shift
1371         sequence="$1"
1372     else
1373         sequence="${key[$1]}"
1374     fi
1375     widget="$2"
1376
1377     [[ -z "$sequence" ]] && return 1
1378
1379     for i in "${maps[@]}"; do
1380         zrcbindkey -M "$i" "$sequence" "$widget"
1381     done
1382 }
1383
1384 if (( ${+terminfo[smkx]} )) && (( ${+terminfo[rmkx]} )); then
1385     function zle-smkx () {
1386         emulate -L zsh
1387         printf '%s' ${terminfo[smkx]}
1388     }
1389     function zle-rmkx () {
1390         emulate -L zsh
1391         printf '%s' ${terminfo[rmkx]}
1392     }
1393     function zle-line-init () {
1394         zle-smkx
1395     }
1396     function zle-line-finish () {
1397         zle-rmkx
1398     }
1399     zle -N zle-line-init
1400     zle -N zle-line-finish
1401 else
1402     for i in {s,r}mkx; do
1403         (( ${+terminfo[$i]} )) || grml_missing_features+=($i)
1404     done
1405     unset i
1406 fi
1407
1408 typeset -A key
1409 key=(
1410     Home     "${terminfo[khome]}"
1411     End      "${terminfo[kend]}"
1412     Insert   "${terminfo[kich1]}"
1413     Delete   "${terminfo[kdch1]}"
1414     Up       "${terminfo[kcuu1]}"
1415     Down     "${terminfo[kcud1]}"
1416     Left     "${terminfo[kcub1]}"
1417     Right    "${terminfo[kcuf1]}"
1418     PageUp   "${terminfo[kpp]}"
1419     PageDown "${terminfo[knp]}"
1420     BackTab  "${terminfo[kcbt]}"
1421 )
1422
1423 # Guidelines for adding key bindings:
1424 #
1425 #   - Do not add hardcoded escape sequences, to enable non standard key
1426 #     combinations such as Ctrl-Meta-Left-Cursor. They are not easily portable.
1427 #
1428 #   - Adding Ctrl characters, such as '^b' is okay; note that '^b' and '^B' are
1429 #     the same key.
1430 #
1431 #   - All keys from the $key[] mapping are obviously okay.
1432 #
1433 #   - Most terminals send "ESC x" when Meta-x is pressed. Thus, sequences like
1434 #     '\ex' are allowed in here as well.
1435
1436 bind2maps emacs             -- Home   beginning-of-somewhere
1437 bind2maps       viins vicmd -- Home   vi-beginning-of-line
1438 bind2maps emacs             -- End    end-of-somewhere
1439 bind2maps       viins vicmd -- End    vi-end-of-line
1440 bind2maps emacs viins       -- Insert overwrite-mode
1441 bind2maps             vicmd -- Insert vi-insert
1442 bind2maps emacs             -- Delete delete-char
1443 bind2maps       viins vicmd -- Delete vi-delete-char
1444 bind2maps emacs viins vicmd -- Up     up-line-or-search
1445 bind2maps emacs viins vicmd -- Down   down-line-or-search
1446 bind2maps emacs             -- Left   backward-char
1447 bind2maps       viins vicmd -- Left   vi-backward-char
1448 bind2maps emacs             -- Right  forward-char
1449 bind2maps       viins vicmd -- Right  vi-forward-char
1450 #k# Perform abbreviation expansion
1451 bind2maps emacs viins       -- -s '^x.' zleiab
1452 #k# Display list of abbreviations that would expand
1453 bind2maps emacs viins       -- -s '^xb' help-show-abk
1454 #k# mkdir -p <dir> from string under cursor or marked area
1455 bind2maps emacs viins       -- -s '^xM' inplaceMkDirs
1456 #k# display help for keybindings and ZLE
1457 bind2maps emacs viins       -- -s '^xz' help-zle
1458 #k# Insert files and test globbing
1459 bind2maps emacs viins       -- -s "^xf" insert-files
1460 #k# Edit the current line in \kbd{\$EDITOR}
1461 bind2maps emacs viins       -- -s '\ee' edit-command-line
1462 #k# search history backward for entry beginning with typed text
1463 bind2maps emacs viins       -- -s '^xp' history-beginning-search-backward-end
1464 #k# search history forward for entry beginning with typed text
1465 bind2maps emacs viins       -- -s '^xP' history-beginning-search-forward-end
1466 #k# search history backward for entry beginning with typed text
1467 bind2maps emacs viins       -- PageUp history-beginning-search-backward-end
1468 #k# search history forward for entry beginning with typed text
1469 bind2maps emacs viins       -- PageDown history-beginning-search-forward-end
1470 bind2maps emacs viins       -- -s "^x^h" commit-to-history
1471 #k# Kill left-side word or everything up to next slash
1472 bind2maps emacs viins       -- -s '\ev' slash-backward-kill-word
1473 #k# Kill left-side word or everything up to next slash
1474 bind2maps emacs viins       -- -s '\e^h' slash-backward-kill-word
1475 #k# Kill left-side word or everything up to next slash
1476 bind2maps emacs viins       -- -s '\e^?' slash-backward-kill-word
1477 # Do history expansion on space:
1478 bind2maps emacs viins       -- -s ' ' magic-space
1479 #k# Trigger menu-complete
1480 bind2maps emacs viins       -- -s '\ei' menu-complete  # menu completion via esc-i
1481 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1482 bind2maps emacs viins       -- -s '^ed' insert-datestamp
1483 #k# Insert last typed word
1484 bind2maps emacs viins       -- -s "\em" insert-last-typed-word
1485 #k# A smart shortcut for \kbd{fg<enter>}
1486 bind2maps emacs viins       -- -s '^z' grml-zsh-fg
1487 #k# prepend the current command with "sudo"
1488 bind2maps emacs viins       -- -s "^os" sudo-command-line
1489 #k# jump to after first word (for adding options)
1490 bind2maps emacs viins       -- -s '^x1' jump_after_first_word
1491 #k# complete word from history with menu
1492 bind2maps emacs viins       -- -s "^x^x" hist-complete
1493
1494 # insert unicode character
1495 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
1496 # See for example http://unicode.org/charts/ for unicode characters code
1497 #k# Insert Unicode character
1498 bind2maps emacs viins       -- -s '^xi' insert-unicode-char
1499
1500 # use the new *-pattern-* widgets for incremental history search
1501 if zrcgotwidget history-incremental-pattern-search-backward; then
1502     for seq wid in '^r' history-incremental-pattern-search-backward \
1503                    '^s' history-incremental-pattern-search-forward
1504     do
1505         bind2maps emacs viins vicmd -- -s $seq $wid
1506     done
1507     builtin unset -v seq wid
1508 fi
1509
1510 if zrcgotkeymap menuselect; then
1511     #m# k Shift-tab Perform backwards menu completion
1512     bind2maps menuselect -- BackTab reverse-menu-complete
1513
1514     #k# menu selection: pick item but stay in the menu
1515     bind2maps menuselect -- -s '\e^M' accept-and-menu-complete
1516     # also use + and INSERT since it's easier to press repeatedly
1517     bind2maps menuselect -- -s '+' accept-and-menu-complete
1518     bind2maps menuselect -- Insert accept-and-menu-complete
1519
1520     # accept a completion and try to complete again by using menu
1521     # completion; very useful with completing directories
1522     # by using 'undo' one's got a simple file browser
1523     bind2maps menuselect -- -s '^o' accept-and-infer-next-history
1524 fi
1525
1526 # Finally, here are still a few hardcoded escape sequences; Special sequences
1527 # like Ctrl-<Cursor-key> etc do suck a fair bit, because they are not
1528 # standardised and most of the time are not available in a terminals terminfo
1529 # entry.
1530 #
1531 # While we do not encourage adding bindings like these, we will keep these for
1532 # backward compatibility.
1533
1534 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on
1535 ## the command line.
1536 # URxvt sequences:
1537 bind2maps emacs viins vicmd -- -s '\eOc' forward-word
1538 bind2maps emacs viins vicmd -- -s '\eOd' backward-word
1539 # These are for xterm:
1540 bind2maps emacs viins vicmd -- -s '\e[1;5C' forward-word
1541 bind2maps emacs viins vicmd -- -s '\e[1;5D' backward-word
1542 ## the same for alt-left-arrow and alt-right-arrow
1543 # URxvt again:
1544 bind2maps emacs viins vicmd -- -s '\e\e[C' forward-word
1545 bind2maps emacs viins vicmd -- -s '\e\e[D' backward-word
1546 # Xterm again:
1547 bind2maps emacs viins vicmd -- -s '^[[1;3C' forward-word
1548 bind2maps emacs viins vicmd -- -s '^[[1;3D' backward-word
1549 # Also try ESC Left/Right:
1550 bind2maps emacs viins vicmd -- -s '\e'${key[Right]} forward-word
1551 bind2maps emacs viins vicmd -- -s '\e'${key[Left]}  backward-word
1552
1553 # autoloading
1554
1555 zrcautoload zmv
1556 zrcautoload zed
1557
1558 # we don't want to quote/espace URLs on our own...
1559 # if autoload -U url-quote-magic ; then
1560 #    zle -N self-insert url-quote-magic
1561 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
1562 # else
1563 #    print 'Notice: no url-quote-magic available :('
1564 # fi
1565 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
1566
1567 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
1568 alias run-help >&/dev/null && unalias run-help
1569 for rh in run-help{,-git,-svk,-svn}; do
1570     zrcautoload $rh
1571 done; unset rh
1572
1573 # command not found handling
1574
1575 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1576 function command_not_found_handler() {
1577     emulate -L zsh
1578     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1579         ${GRML_ZSH_CNF_HANDLER} $1
1580     fi
1581     return 1
1582 }
1583
1584 # history
1585
1586 ZSHDIR=${ZDOTDIR:-${HOME}/.zsh}
1587
1588 #v#
1589 HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1590 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1591 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1592
1593 # dirstack handling
1594
1595 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1596 DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1597
1598 typeset -gaU GRML_PERSISTENT_DIRSTACK
1599 function grml_dirstack_filter() {
1600     local -a exclude
1601     local filter entry
1602     if zstyle -s ':grml:chpwd:dirstack' filter filter; then
1603         $filter $1 && return 0
1604     fi
1605     if zstyle -a ':grml:chpwd:dirstack' exclude exclude; then
1606         for entry in "${exclude[@]}"; do
1607             [[ $1 == ${~entry} ]] && return 0
1608         done
1609     fi
1610     return 1
1611 }
1612
1613 chpwd() {
1614     (( $DIRSTACKSIZE <= 0 )) && return
1615     [[ -z $DIRSTACKFILE ]] && return
1616     grml_dirstack_filter $PWD && return
1617     GRML_PERSISTENT_DIRSTACK=(
1618         $PWD "${(@)GRML_PERSISTENT_DIRSTACK[1,$DIRSTACKSIZE]}"
1619     )
1620     builtin print -l ${GRML_PERSISTENT_DIRSTACK} >! ${DIRSTACKFILE}
1621 }
1622
1623 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1624     # Enabling NULL_GLOB via (N) weeds out any non-existing
1625     # directories from the saved dir-stack file.
1626     dirstack=( ${(f)"$(< $DIRSTACKFILE)"}(N) )
1627     # "cd -" won't work after login by just setting $OLDPWD, so
1628     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1629 fi
1630
1631 if zstyle -T ':grml:chpwd:dirstack' filter-on-load; then
1632     for i in "${dirstack[@]}"; do
1633         if ! grml_dirstack_filter "$i"; then
1634             GRML_PERSISTENT_DIRSTACK=(
1635                 "${GRML_PERSISTENT_DIRSTACK[@]}"
1636                 $i
1637             )
1638         fi
1639     done
1640 else
1641     GRML_PERSISTENT_DIRSTACK=( "${dirstack[@]}" )
1642 fi
1643
1644 # directory based profiles
1645
1646 if is433 ; then
1647
1648 # chpwd_profiles(): Directory Profiles, Quickstart:
1649 #
1650 # In .zshrc.local:
1651 #
1652 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1653 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1654 #   chpwd_profiles
1655 #
1656 # For details see the `grmlzshrc.5' manual page.
1657 function chpwd_profiles() {
1658     local profile context
1659     local -i reexecute
1660
1661     context=":chpwd:profiles:$PWD"
1662     zstyle -s "$context" profile profile || profile='default'
1663     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1664
1665     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1666         typeset -g CHPWD_PROFILE
1667         local CHPWD_PROFILES_INIT=1
1668         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1669     elif [[ $profile != $CHPWD_PROFILE ]]; then
1670         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1671             && chpwd_leave_profile_${CHPWD_PROFILE}
1672     fi
1673     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1674         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1675     fi
1676
1677     CHPWD_PROFILE="${profile}"
1678     return 0
1679 }
1680
1681 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1682
1683 fi # is433
1684
1685 # Prompt setup for grml:
1686
1687 # set colors for use in prompts (modern zshs allow for the use of %F{red}foo%f
1688 # in prompts to get a red "foo" embedded, but it's good to keep these for
1689 # backwards compatibility).
1690 if is437; then
1691     BLUE="%F{blue}"
1692     RED="%F{red}"
1693     GREEN="%F{green}"
1694     CYAN="%F{cyan}"
1695     MAGENTA="%F{magenta}"
1696     YELLOW="%F{yellow}"
1697     WHITE="%F{white}"
1698     NO_COLOR="%f"
1699 elif zrcautoload colors && colors 2>/dev/null ; then
1700     BLUE="%{${fg[blue]}%}"
1701     RED="%{${fg_bold[red]}%}"
1702     GREEN="%{${fg[green]}%}"
1703     CYAN="%{${fg[cyan]}%}"
1704     MAGENTA="%{${fg[magenta]}%}"
1705     YELLOW="%{${fg[yellow]}%}"
1706     WHITE="%{${fg[white]}%}"
1707     NO_COLOR="%{${reset_color}%}"
1708 else
1709     BLUE=$'%{\e[1;34m%}'
1710     RED=$'%{\e[1;31m%}'
1711     GREEN=$'%{\e[1;32m%}'
1712     CYAN=$'%{\e[1;36m%}'
1713     WHITE=$'%{\e[1;37m%}'
1714     MAGENTA=$'%{\e[1;35m%}'
1715     YELLOW=$'%{\e[1;33m%}'
1716     NO_COLOR=$'%{\e[0m%}'
1717 fi
1718
1719 # First, the easy ones: PS2..4:
1720
1721 # secondary prompt, printed when the shell needs more information to complete a
1722 # command.
1723 PS2='\`%_> '
1724 # selection prompt used within a select loop.
1725 PS3='?# '
1726 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1727 PS4='+%N:%i:%_> '
1728
1729 # Some additional features to use with our prompt:
1730 #
1731 #    - battery status
1732 #    - debian_chroot
1733 #    - vcs_info setup and version specific fixes
1734
1735 # display battery status on right side of prompt using 'GRML_DISPLAY_BATTERY=1' in .zshrc.pre
1736
1737 battery() {
1738 if [[ $GRML_DISPLAY_BATTERY -gt 0 ]] ; then
1739     if islinux ; then
1740         batterylinux
1741     elif isopenbsd ; then
1742         batteryopenbsd
1743     elif isfreebsd ; then
1744         batteryfreebsd
1745     elif isdarwin ; then
1746         batterydarwin
1747     else
1748         #not yet supported
1749         GRML_DISPLAY_BATTERY=0
1750     fi
1751 fi
1752 }
1753
1754 batterylinux(){
1755 GRML_BATTERY_LEVEL=''
1756 local batteries bat capacity
1757 batteries=( /sys/class/power_supply/BAT*(N) )
1758 if (( $#batteries > 0 )) ; then
1759     for bat in $batteries ; do
1760         capacity=$(< $bat/capacity)
1761         case $(< $bat/status) in
1762         Charging)
1763             GRML_BATTERY_LEVEL+=" ^"
1764             ;;
1765         Discharging)
1766             if (( capacity < 20 )) ; then
1767                 GRML_BATTERY_LEVEL+=" !v"
1768             else
1769                 GRML_BATTERY_LEVEL+=" v"
1770             fi
1771             ;;
1772         *) # Full, Unknown
1773             GRML_BATTERY_LEVEL+=" ="
1774             ;;
1775         esac
1776         GRML_BATTERY_LEVEL+="${capacity}%%"
1777     done
1778 fi
1779 }
1780
1781 batteryopenbsd(){
1782 GRML_BATTERY_LEVEL=''
1783 local bat batfull batwarn batnow num
1784 for num in 0 1 ; do
1785     bat=$(sysctl -n hw.sensors.acpibat${num} 2>/dev/null)
1786     if [[ -n $bat ]]; then
1787         batfull=${"$(sysctl -n hw.sensors.acpibat${num}.amphour0)"%% *}
1788         batwarn=${"$(sysctl -n hw.sensors.acpibat${num}.amphour1)"%% *}
1789         batnow=${"$(sysctl -n hw.sensors.acpibat${num}.amphour3)"%% *}
1790         case "$(sysctl -n hw.sensors.acpibat${num}.raw0)" in
1791             *" discharging"*)
1792                 if (( batnow < batwarn )) ; then
1793                     GRML_BATTERY_LEVEL+=" !v"
1794                 else
1795                     GRML_BATTERY_LEVEL+=" v"
1796                 fi
1797                 ;;
1798             *" charging"*)
1799                 GRML_BATTERY_LEVEL+=" ^"
1800                 ;;
1801             *)
1802                 GRML_BATTERY_LEVEL+=" ="
1803                 ;;
1804         esac
1805         GRML_BATTERY_LEVEL+="${$(( 100 * batnow / batfull ))%%.*}%%"
1806     fi
1807 done
1808 }
1809
1810 batteryfreebsd(){
1811 GRML_BATTERY_LEVEL=''
1812 local num
1813 local -A table
1814 for num in 0 1 ; do
1815     table=( ${=${${${${${(M)${(f)"$(acpiconf -i $num 2>&1)"}:#(State|Remaining capacity):*}%%( ##|%)}//:[ $'\t']##/@}// /-}//@/ }} )
1816     if [[ -n $table ]] && [[ $table[State] != "not-present" ]] ; then
1817         case $table[State] in
1818             *discharging*)
1819                 if (( $table[Remaining-capacity] < 20 )) ; then
1820                     GRML_BATTERY_LEVEL+=" !v"
1821                 else
1822                     GRML_BATTERY_LEVEL+=" v"
1823                 fi
1824                 ;;
1825             *charging*)
1826                 GRML_BATTERY_LEVEL+=" ^"
1827                 ;;
1828             *)
1829                 GRML_BATTERY_LEVEL+=" ="
1830                 ;;
1831         esac
1832         GRML_BATTERY_LEVEL+="$table[Remaining-capacity]%%"
1833     fi
1834 done
1835 }
1836
1837 batterydarwin(){
1838 GRML_BATTERY_LEVEL=''
1839 local -a table
1840 table=( ${$(pmset -g ps)[(w)7,8]%%(\%|);} )
1841 if [[ -n $table[2] ]] ; then
1842     case $table[2] in
1843         charging)
1844             GRML_BATTERY_LEVEL+=" ^"
1845             ;;
1846         discharging)
1847             if (( $table[1] < 20 )) ; then
1848                 GRML_BATTERY_LEVEL+=" !v"
1849             else
1850                 GRML_BATTERY_LEVEL+=" v"
1851             fi
1852             ;;
1853         *)
1854             GRML_BATTERY_LEVEL+=" ="
1855             ;;
1856     esac
1857     GRML_BATTERY_LEVEL+="$table[1]%%"
1858 fi
1859 }
1860
1861 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1862 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1863     debian_chroot=$(</etc/debian_chroot)
1864 fi
1865
1866 # gather version control information for inclusion in a prompt
1867
1868 if zrcautoload vcs_info; then
1869     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1870     # function, which can cause a lot of trouble with our directory-based
1871     # profiles. So:
1872     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1873         function VCS_INFO_realpath () {
1874             setopt localoptions NO_shwordsplit chaselinks
1875             ( builtin cd -q $1 2> /dev/null && pwd; )
1876         }
1877     fi
1878
1879     zstyle ':vcs_info:*' max-exports 2
1880
1881     if [[ -o restricted ]]; then
1882         zstyle ':vcs_info:*' enable NONE
1883     fi
1884 fi
1885
1886 typeset -A grml_vcs_coloured_formats
1887 typeset -A grml_vcs_plain_formats
1888
1889 grml_vcs_plain_formats=(
1890     format "(%s%)-[%b] "    "zsh: %r"
1891     actionformat "(%s%)-[%b|%a] " "zsh: %r"
1892     rev-branchformat "%b:%r"
1893 )
1894
1895 grml_vcs_coloured_formats=(
1896     format "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR} "
1897     actionformat "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} "
1898     rev-branchformat "%b${RED}:${YELLOW}%r"
1899 )
1900
1901 typeset GRML_VCS_COLOUR_MODE=xxx
1902
1903 grml_vcs_info_toggle_colour () {
1904     emulate -L zsh
1905     if [[ $GRML_VCS_COLOUR_MODE == plain ]]; then
1906         grml_vcs_info_set_formats coloured
1907     else
1908         grml_vcs_info_set_formats plain
1909     fi
1910     return 0
1911 }
1912
1913 grml_vcs_info_set_formats () {
1914     emulate -L zsh
1915     #setopt localoptions xtrace
1916     local mode=$1 AF F BF
1917     if [[ $mode == coloured ]]; then
1918         AF=${grml_vcs_coloured_formats[actionformat]}
1919         F=${grml_vcs_coloured_formats[format]}
1920         BF=${grml_vcs_coloured_formats[rev-branchformat]}
1921         GRML_VCS_COLOUR_MODE=coloured
1922     else
1923         AF=${grml_vcs_plain_formats[actionformat]}
1924         F=${grml_vcs_plain_formats[format]}
1925         BF=${grml_vcs_plain_formats[rev-branchformat]}
1926         GRML_VCS_COLOUR_MODE=plain
1927     fi
1928
1929     zstyle ':vcs_info:*'              actionformats "$AF" "zsh: %r"
1930     zstyle ':vcs_info:*'              formats       "$F"  "zsh: %r"
1931     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat  "$BF"
1932     return 0
1933 }
1934
1935 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1936 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1937 if [[ "$TERM" == dumb ]] ; then
1938     grml_vcs_info_set_formats plain
1939 else
1940     grml_vcs_info_set_formats coloured
1941 fi
1942
1943 # Now for the fun part: The grml prompt themes in `promptsys' mode of operation
1944
1945 # This actually defines three prompts:
1946 #
1947 #    - grml
1948 #    - grml-large
1949 #    - grml-chroot
1950 #
1951 # They all share the same code and only differ with respect to which items they
1952 # contain. The main source of documentation is the `prompt_grml_help' function
1953 # below, which gets called when the user does this: prompt -h grml
1954
1955 function prompt_grml_help () {
1956     <<__EOF0__
1957   prompt grml
1958
1959     This is the prompt as used by the grml-live system <http://grml.org>. It is
1960     a rather simple one-line prompt, that by default looks something like this:
1961
1962         <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1963
1964     The prompt itself integrates with zsh's prompt themes system (as you are
1965     witnessing right now) and is configurable to a certain degree. In
1966     particular, these aspects are customisable:
1967
1968         - The items used in the prompt (e.g. you can remove \`user' from
1969           the list of activated items, which will cause the user name to
1970           be omitted from the prompt string).
1971
1972         - The attributes used with the items are customisable via strings
1973           used before and after the actual item.
1974
1975     The available items are: at, battery, change-root, date, grml-chroot,
1976     history, host, jobs, newline, path, percent, rc, rc-always, sad-smiley,
1977     shell-level, time, user, vcs
1978
1979     The actual configuration is done via zsh's \`zstyle' mechanism. The
1980     context, that is used while looking up styles is:
1981
1982         ':prompt:grml:<left-or-right>:<subcontext>'
1983
1984     Here <left-or-right> is either \`left' or \`right', signifying whether the
1985     style should affect the left or the right prompt. <subcontext> is either
1986     \`setup' or 'items:<item>', where \`<item>' is one of the available items.
1987
1988     The styles:
1989
1990         - use-rprompt (boolean): If \`true' (the default), print a sad smiley
1991           in $RPROMPT if the last command a returned non-successful error code.
1992           (This in only valid if <left-or-right> is "right"; ignored otherwise)
1993
1994         - items (list): The list of items used in the prompt. If \`vcs' is
1995           present in the list, the theme's code invokes \`vcs_info'
1996           accordingly. Default (left): rc change-root user at host path vcs
1997           percent; Default (right): sad-smiley
1998
1999     Available styles in 'items:<item>' are: pre, post. These are strings that
2000     are inserted before (pre) and after (post) the item in question. Thus, the
2001     following would cause the user name to be printed in red instead of the
2002     default blue:
2003
2004         zstyle ':prompt:grml:*:items:user' pre '%F{red}'
2005
2006     Note, that the \`post' style may remain at its default value, because its
2007     default value is '%f', which turns the foreground text attribute off (which
2008     is exactly, what is still required with the new \`pre' value).
2009 __EOF0__
2010 }
2011
2012 function prompt_grml-chroot_help () {
2013     <<__EOF0__
2014   prompt grml-chroot
2015
2016     This is a variation of the grml prompt, see: prompt -h grml
2017
2018     The main difference is the default value of the \`items' style. The rest
2019     behaves exactly the same. Here are the defaults for \`grml-chroot':
2020
2021         - left: grml-chroot user at host path percent
2022         - right: (empty list)
2023 __EOF0__
2024 }
2025
2026 function prompt_grml-large_help () {
2027     <<__EOF0__
2028   prompt grml-large
2029
2030     This is a variation of the grml prompt, see: prompt -h grml
2031
2032     The main difference is the default value of the \`items' style. In
2033     particular, this theme uses _two_ lines instead of one with the plain
2034     \`grml' theme. The rest behaves exactly the same. Here are the defaults
2035     for \`grml-large':
2036
2037         - left: rc jobs history shell-level change-root time date newline user
2038                 at host path vcs percent
2039         - right: sad-smiley
2040 __EOF0__
2041 }
2042
2043 function grml_prompt_setup () {
2044     emulate -L zsh
2045     autoload -Uz vcs_info
2046     # The following autoload is disabled for now, since this setup includes a
2047     # static version of the ‘add-zsh-hook’ function above. It needs to be
2048     # reenabled as soon as that static definition is removed again.
2049     #autoload -Uz add-zsh-hook
2050     add-zsh-hook precmd prompt_$1_precmd
2051 }
2052
2053 function prompt_grml_setup () {
2054     grml_prompt_setup grml
2055 }
2056
2057 function prompt_grml-chroot_setup () {
2058     grml_prompt_setup grml-chroot
2059 }
2060
2061 function prompt_grml-large_setup () {
2062     grml_prompt_setup grml-large
2063 }
2064
2065 # These maps define default tokens and pre-/post-decoration for items to be
2066 # used within the themes. All defaults may be customised in a context sensitive
2067 # matter by using zsh's `zstyle' mechanism.
2068 typeset -gA grml_prompt_pre_default \
2069             grml_prompt_post_default \
2070             grml_prompt_token_default \
2071             grml_prompt_token_function
2072
2073 grml_prompt_pre_default=(
2074     at                ''
2075     battery           ' '
2076     change-root       ''
2077     date              '%F{blue}'
2078     grml-chroot       '%F{red}'
2079     history           '%F{green}'
2080     host              ''
2081     jobs              '%F{cyan}'
2082     newline           ''
2083     path              '%B'
2084     percent           ''
2085     rc                '%B%F{red}'
2086     rc-always         ''
2087     sad-smiley        ''
2088     shell-level       '%F{red}'
2089     time              '%F{blue}'
2090     user              '%B%F{blue}'
2091     vcs               ''
2092 )
2093
2094 grml_prompt_post_default=(
2095     at                ''
2096     battery           ''
2097     change-root       ''
2098     date              '%f'
2099     grml-chroot       '%f '
2100     history           '%f'
2101     host              ''
2102     jobs              '%f'
2103     newline           ''
2104     path              '%b'
2105     percent           ''
2106     rc                '%f%b'
2107     rc-always         ''
2108     sad-smiley        ''
2109     shell-level       '%f'
2110     time              '%f'
2111     user              '%f%b'
2112     vcs               ''
2113 )
2114
2115 grml_prompt_token_default=(
2116     at                '@'
2117     battery           'GRML_BATTERY_LEVEL'
2118     change-root       'debian_chroot'
2119     date              '%D{%Y-%m-%d}'
2120     grml-chroot       'GRML_CHROOT'
2121     history           '{history#%!} '
2122     host              '%m '
2123     jobs              '[%j running job(s)] '
2124     newline           $'\n'
2125     path              '%40<..<%~%<< '
2126     percent           '%# '
2127     rc                '%(?..%? )'
2128     rc-always         '%?'
2129     sad-smiley        '%(?..:()'
2130     shell-level       '%(3L.+ .)'
2131     time              '%D{%H:%M:%S} '
2132     user              '%n'
2133     vcs               '0'
2134 )
2135
2136 function grml_theme_has_token () {
2137     if (( ARGC != 1 )); then
2138         printf 'usage: grml_theme_has_token <name>\n'
2139         return 1
2140     fi
2141     (( ${+grml_prompt_token_default[$1]} ))
2142 }
2143
2144 function GRML_theme_add_token_usage () {
2145     <<__EOF0__
2146   Usage: grml_theme_add_token <name> [-f|-i] <token/function> [<pre> <post>]
2147
2148     <name> is the name for the newly added token. If the \`-f' or \`-i' options
2149     are used, <token/function> is the name of the function (see below for
2150     details). Otherwise it is the literal token string to be used. <pre> and
2151     <post> are optional.
2152
2153   Options:
2154
2155     -f <function>   Use a function named \`<function>' each time the token
2156                     is to be expanded.
2157
2158     -i <function>   Use a function named \`<function>' to initialise the
2159                     value of the token _once_ at runtime.
2160
2161     The functions are called with one argument: the token's new name. The
2162     return value is expected in the \$REPLY parameter. The use of these
2163     options is mutually exclusive.
2164
2165     There is a utility function \`grml_theme_has_token', which you can use
2166     to test if a token exists before trying to add it. This can be a guard
2167     for situations in which a \`grml_theme_add_token' call may happen more
2168     than once.
2169
2170   Example:
2171
2172     To add a new token \`day' that expands to the current weekday in the
2173     current locale in green foreground colour, use this:
2174
2175       grml_theme_add_token day '%D{%A}' '%F{green}' '%f'
2176
2177     Another example would be support for \$VIRTUAL_ENV:
2178
2179       function virtual_env_prompt () {
2180         REPLY=\${VIRTUAL_ENV+\${VIRTUAL_ENV:t} }
2181       }
2182       grml_theme_add_token virtual-env -f virtual_env_prompt
2183
2184     After that, you will be able to use a changed \`items' style to
2185     assemble your prompt.
2186 __EOF0__
2187 }
2188
2189 function grml_theme_add_token () {
2190     emulate -L zsh
2191     local name token pre post
2192     local -i init funcall
2193
2194     if (( ARGC == 0 )); then
2195         GRML_theme_add_token_usage
2196         return 0
2197     fi
2198
2199     init=0
2200     funcall=0
2201     pre=''
2202     post=''
2203     name=$1
2204     shift
2205     if [[ $1 == '-f' ]]; then
2206         funcall=1
2207         shift
2208     elif [[ $1 == '-i' ]]; then
2209         init=1
2210         shift
2211     fi
2212
2213     if (( ARGC == 0 )); then
2214         printf '
2215 grml_theme_add_token: No token-string/function-name provided!\n\n'
2216         GRML_theme_add_token_usage
2217         return 1
2218     fi
2219     token=$1
2220     shift
2221     if (( ARGC != 0 && ARGC != 2 )); then
2222         printf '
2223 grml_theme_add_token: <pre> and <post> need to by specified _both_!\n\n'
2224         GRML_theme_add_token_usage
2225         return 1
2226     fi
2227     if (( ARGC )); then
2228         pre=$1
2229         post=$2
2230         shift 2
2231     fi
2232
2233     if grml_theme_has_token $name; then
2234         printf '
2235 grml_theme_add_token: Token `%s'\'' exists! Giving up!\n\n' $name
2236         GRML_theme_add_token_usage
2237         return 2
2238     fi
2239     if (( init )); then
2240         $token $name
2241         token=$REPLY
2242     fi
2243     grml_prompt_pre_default[$name]=$pre
2244     grml_prompt_post_default[$name]=$post
2245     if (( funcall )); then
2246         grml_prompt_token_function[$name]=$token
2247         grml_prompt_token_default[$name]=23
2248     else
2249         grml_prompt_token_default[$name]=$token
2250     fi
2251 }
2252
2253 function grml_typeset_and_wrap () {
2254     emulate -L zsh
2255     local target="$1"
2256     local new="$2"
2257     local left="$3"
2258     local right="$4"
2259
2260     if (( ${+parameters[$new]} )); then
2261         typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
2262     fi
2263 }
2264
2265 function grml_prompt_addto () {
2266     emulate -L zsh
2267     local target="$1"
2268     local lr it apre apost new v
2269     local -a items
2270     shift
2271
2272     [[ $target == PS1 ]] && lr=left || lr=right
2273     zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
2274     typeset -g "${target}="
2275     for it in "${items[@]}"; do
2276         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
2277             || apre=${grml_prompt_pre_default[$it]}
2278         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" post apost \
2279             || apost=${grml_prompt_post_default[$it]}
2280         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
2281             || new=${grml_prompt_token_default[$it]}
2282         typeset -g "${target}=${(P)target}${apre}"
2283         if (( ${+grml_prompt_token_function[$it]} )); then
2284             ${grml_prompt_token_function[$it]} $it
2285             typeset -g "${target}=${(P)target}${REPLY}"
2286         else
2287             case $it in
2288             battery)
2289                 grml_typeset_and_wrap $target $new '' ''
2290                 ;;
2291             change-root)
2292                 grml_typeset_and_wrap $target $new '(' ')'
2293                 ;;
2294             grml-chroot)
2295                 if [[ -n ${(P)new} ]]; then
2296                     typeset -g "${target}=${(P)target}(CHROOT)"
2297                 fi
2298                 ;;
2299             vcs)
2300                 v="vcs_info_msg_${new}_"
2301                 if (( ! vcscalled )); then
2302                     vcs_info
2303                     vcscalled=1
2304                 fi
2305                 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
2306                     typeset -g "${target}=${(P)target}${(P)v}"
2307                 fi
2308                 ;;
2309             *) typeset -g "${target}=${(P)target}${new}" ;;
2310             esac
2311         fi
2312         typeset -g "${target}=${(P)target}${apost}"
2313     done
2314 }
2315
2316 function prompt_grml_precmd () {
2317     emulate -L zsh
2318     local grmltheme=grml
2319     local -a left_items right_items
2320     left_items=(rc change-root user at host path vcs percent)
2321     right_items=(sad-smiley)
2322
2323     prompt_grml_precmd_worker
2324 }
2325
2326 function prompt_grml-chroot_precmd () {
2327     emulate -L zsh
2328     local grmltheme=grml-chroot
2329     local -a left_items right_items
2330     left_items=(grml-chroot user at host path percent)
2331     right_items=()
2332
2333     prompt_grml_precmd_worker
2334 }
2335
2336 function prompt_grml-large_precmd () {
2337     emulate -L zsh
2338     local grmltheme=grml-large
2339     local -a left_items right_items
2340     left_items=(rc jobs history shell-level change-root time date newline
2341                 user at host path vcs percent)
2342     right_items=(sad-smiley)
2343
2344     prompt_grml_precmd_worker
2345 }
2346
2347 function prompt_grml_precmd_worker () {
2348     emulate -L zsh
2349     local -i vcscalled=0
2350
2351     grml_prompt_addto PS1 "${left_items[@]}"
2352     if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
2353         grml_prompt_addto RPS1 "${right_items[@]}"
2354     fi
2355 }
2356
2357 grml_prompt_fallback() {
2358     setopt prompt_subst
2359     precmd() {
2360         (( ${+functions[vcs_info]} )) && vcs_info
2361     }
2362
2363     p0="${RED}%(?..%? )${WHITE}${debian_chroot:+($debian_chroot)}"
2364     p1="${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "'${vcs_info_msg_0_}'"%# "
2365     if (( EUID == 0 )); then
2366         PROMPT="${BLUE}${p0}${RED}${p1}"
2367     else
2368         PROMPT="${RED}${p0}${BLUE}${p1}"
2369     fi
2370     unset p0 p1
2371 }
2372
2373 if zrcautoload promptinit && promptinit 2>/dev/null ; then
2374     # Since we define the required functions in here and not in files in
2375     # $fpath, we need to stick the theme's name into `$prompt_themes'
2376     # ourselves, since promptinit does not pick them up otherwise.
2377     prompt_themes+=( grml grml-chroot grml-large )
2378     # Also, keep the array sorted...
2379     prompt_themes=( "${(@on)prompt_themes}" )
2380 else
2381     print 'Notice: no promptinit available :('
2382     grml_prompt_fallback
2383 fi
2384
2385 if is437; then
2386     # The prompt themes use modern features of zsh, that require at least
2387     # version 4.3.7 of the shell. Use the fallback otherwise.
2388     if [[ $GRML_DISPLAY_BATTERY -gt 0 ]]; then
2389         zstyle ':prompt:grml:right:setup' items sad-smiley battery
2390         add-zsh-hook precmd battery
2391     fi
2392     if [[ "$TERM" == dumb ]] ; then
2393         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" pre ''
2394         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" post ' '
2395         for i in rc user path jobs history date time shell-level; do
2396             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" pre ''
2397             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" post ''
2398         done
2399         unset i
2400         zstyle ':prompt:grml(|-large|-chroot):right:setup' use-rprompt false
2401     elif (( EUID == 0 )); then
2402         zstyle ':prompt:grml(|-large|-chroot):*:items:user' pre '%B%F{red}'
2403     fi
2404
2405     # Finally enable one of the prompts.
2406     if [[ -n $GRML_CHROOT ]]; then
2407         prompt grml-chroot
2408     elif [[ $GRMLPROMPT -gt 0 ]]; then
2409         prompt grml-large
2410     else
2411         prompt grml
2412     fi
2413 else
2414     grml_prompt_fallback
2415 fi
2416
2417 # Terminal-title wizardry
2418
2419 function ESC_print () {
2420     info_print $'\ek' $'\e\\' "$@"
2421 }
2422 function set_title () {
2423     info_print  $'\e]0;' $'\a' "$@"
2424 }
2425
2426 function info_print () {
2427     local esc_begin esc_end
2428     esc_begin="$1"
2429     esc_end="$2"
2430     shift 2
2431     printf '%s' ${esc_begin}
2432     printf '%s' "$*"
2433     printf '%s' "${esc_end}"
2434 }
2435
2436 function grml_reset_screen_title () {
2437     # adjust title of xterm
2438     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
2439     [[ ${NOTITLE:-} -gt 0 ]] && return 0
2440     case $TERM in
2441         (xterm*|rxvt*)
2442             set_title ${(%):-"%n@%m: %~"}
2443             ;;
2444     esac
2445 }
2446
2447 function grml_vcs_to_screen_title () {
2448     if [[ $TERM == screen* ]] ; then
2449         if [[ -n ${vcs_info_msg_1_} ]] ; then
2450             ESC_print ${vcs_info_msg_1_}
2451         else
2452             ESC_print "zsh"
2453         fi
2454     fi
2455 }
2456
2457 function grml_maintain_name () {
2458     # set hostname if not running on host with name 'grml'
2459     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
2460        NAME="@$HOSTNAME"
2461     fi
2462 }
2463
2464 function grml_cmd_to_screen_title () {
2465     # get the name of the program currently running and hostname of local
2466     # machine set screen window title if running in a screen
2467     if [[ "$TERM" == screen* ]] ; then
2468         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME"
2469         ESC_print ${CMD}
2470     fi
2471 }
2472
2473 function grml_control_xterm_title () {
2474     case $TERM in
2475         (xterm*|rxvt*)
2476             set_title "${(%):-"%n@%m:"}" "$1"
2477             ;;
2478     esac
2479 }
2480
2481 # The following autoload is disabled for now, since this setup includes a
2482 # static version of the ‘add-zsh-hook’ function above. It needs to be
2483 # reenabled as soon as that static definition is removed again.
2484 #zrcautoload add-zsh-hook || add-zsh-hook () { :; }
2485 if [[ $NOPRECMD -eq 0 ]]; then
2486     add-zsh-hook precmd grml_reset_screen_title
2487     add-zsh-hook precmd grml_vcs_to_screen_title
2488     add-zsh-hook preexec grml_maintain_name
2489     add-zsh-hook preexec grml_cmd_to_screen_title
2490     if [[ $NOTITLE -eq 0 ]]; then
2491         add-zsh-hook preexec grml_control_xterm_title
2492     fi
2493 fi
2494
2495 # 'hash' some often used directories
2496 #d# start
2497 hash -d deb=/var/cache/apt/archives
2498 hash -d doc=/usr/share/doc
2499 hash -d linux=/lib/modules/$(command uname -r)/build/
2500 hash -d log=/var/log
2501 hash -d slog=/var/log/syslog
2502 hash -d src=/usr/src
2503 hash -d www=/var/www
2504 #d# end
2505
2506 # some aliases
2507 if check_com -c screen ; then
2508     if [[ $UID -eq 0 ]] ; then
2509         if [[ -r /etc/grml/screenrc ]]; then
2510             alias screen="${commands[screen]} -c /etc/grml/screenrc"
2511         fi
2512     elif [[ -r $HOME/.screenrc ]] ; then
2513         alias screen="${commands[screen]} -c $HOME/.screenrc"
2514     else
2515         if [[ -r /etc/grml/screenrc_grml ]]; then
2516             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
2517         else
2518             if [[ -r /etc/grml/screenrc ]]; then
2519                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
2520             fi
2521         fi
2522     fi
2523 fi
2524
2525 # do we have GNU ls with color-support?
2526 if [[ "$TERM" != dumb ]]; then
2527     #a1# List files with colors (\kbd{ls \ldots})
2528     alias ls="command ls ${ls_options:+${ls_options[*]}}"
2529     #a1# List all files, with colors (\kbd{ls -la \ldots})
2530     alias la="command ls -la ${ls_options:+${ls_options[*]}}"
2531     #a1# List files with long colored list, without dotfiles (\kbd{ls -l \ldots})
2532     alias ll="command ls -l ${ls_options:+${ls_options[*]}}"
2533     #a1# List files with long colored list, human readable sizes (\kbd{ls -hAl \ldots})
2534     alias lh="command ls -hAl ${ls_options:+${ls_options[*]}}"
2535     #a1# List files with long colored list, append qualifier to filenames (\kbd{ls -l \ldots})\\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2536     alias l="command ls -l ${ls_options:+${ls_options[*]}}"
2537 else
2538     alias la='command ls -la'
2539     alias ll='command ls -l'
2540     alias lh='command ls -hAl'
2541     alias l='command ls -l'
2542 fi
2543
2544 alias mdstat='cat /proc/mdstat'
2545 alias ...='cd ../../'
2546
2547 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2548 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2549     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2550 fi
2551
2552 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2553 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2554 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2555
2556 # make sure it is not assigned yet
2557 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
2558 utf2iso() {
2559     if isutfenv ; then
2560         local ENV
2561         for ENV in $(env | command grep -i '.utf') ; do
2562             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2563         done
2564     fi
2565 }
2566
2567 # make sure it is not assigned yet
2568 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
2569 iso2utf() {
2570     if ! isutfenv ; then
2571         local ENV
2572         for ENV in $(env | command grep -i '\.iso') ; do
2573             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2574         done
2575     fi
2576 }
2577
2578 # especially for roadwarriors using GNU screen and ssh:
2579 if ! check_com asc &>/dev/null ; then
2580   asc() { autossh -t "$@" 'screen -RdU' }
2581   compdef asc=ssh
2582 fi
2583
2584 #f1# Hints for the use of zsh on grml
2585 zsh-help() {
2586     print "$bg[white]$fg[black]
2587 zsh-help - hints for use of zsh on grml
2588 =======================================$reset_color"
2589
2590     print '
2591 Main configuration of zsh happens in /etc/zsh/zshrc.
2592 That file is part of the package grml-etc-core, if you want to
2593 use them on a non-grml-system just get the tar.gz from
2594 http://deb.grml.org/ or (preferably) get it from the git repository:
2595
2596   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2597
2598 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2599 The file is still there, but it is empty for backwards compatibility.
2600
2601 For your own changes use these two files:
2602     $HOME/.zshrc.pre
2603     $HOME/.zshrc.local
2604
2605 The former is sourced very early in our zshrc, the latter is sourced
2606 very lately.
2607
2608 System wide configuration without touching configuration files of grml
2609 can take place in /etc/zsh/zshrc.local.
2610
2611 For information regarding zsh start at http://grml.org/zsh/
2612
2613 Take a look at grml'\''s zsh refcard:
2614 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2615
2616 Check out the main zsh refcard:
2617 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2618
2619 And of course visit the zsh-lovers:
2620 % man zsh-lovers
2621
2622 You can adjust some options through environment variables when
2623 invoking zsh without having to edit configuration files.
2624 Basically meant for bash users who are not used to the power of
2625 the zsh yet. :)
2626
2627   "NOCOR=1    zsh" => deactivate automatic correction
2628   "NOMENU=1   zsh" => do not use auto menu completion
2629                       (note: use ctrl-d for completion instead!)
2630   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2631   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2632                       preexec() and precmd() completely
2633   "GRML_DISPLAY_BATTERY=1  zsh"
2634                    => activate battery status on right side of prompt (WIP)
2635   "COMMAND_NOT_FOUND=1 zsh"
2636                    => Enable a handler if an external command was not found
2637                       The command called in the handler can be altered by setting
2638                       the GRML_ZSH_CNF_HANDLER variable, the default is:
2639                       "/usr/share/command-not-found/command-not-found"
2640
2641 A value greater than 0 is enables a feature; a value equal to zero
2642 disables it. If you like one or the other of these settings, you can
2643 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2644 zshrc.'
2645
2646     print "
2647 $bg[white]$fg[black]
2648 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2649 Enjoy your grml system with the zsh!$reset_color"
2650 }
2651
2652 # debian stuff
2653 if [[ -r /etc/debian_version ]] ; then
2654     #a3# Execute \kbd{apt-cache search}
2655     alias acs='apt-cache search'
2656     #a3# Execute \kbd{apt-cache show}
2657     alias acsh='apt-cache show'
2658     #a3# Execute \kbd{apt-cache policy}
2659     alias acp='apt-cache policy'
2660     #a3# Execute \kbd{apt-get dist-upgrade}
2661     salias adg="apt-get dist-upgrade"
2662     #a3# Execute \kbd{apt-get install}
2663     salias agi="apt-get install"
2664     #a3# Execute \kbd{aptitude install}
2665     salias ati="aptitude install"
2666     #a3# Execute \kbd{apt-get upgrade}
2667     salias ag="apt-get upgrade"
2668     #a3# Execute \kbd{apt-get update}
2669     salias au="apt-get update"
2670     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2671     salias -a up="aptitude update ; aptitude safe-upgrade"
2672     #a3# Execute \kbd{dpkg-buildpackage}
2673     alias dbp='dpkg-buildpackage'
2674     #a3# Execute \kbd{grep-excuses}
2675     alias ge='grep-excuses'
2676
2677     # get a root shell as normal user in live-cd mode:
2678     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2679        alias su="sudo su"
2680     fi
2681
2682     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2683     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2684     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2685     salias tlog="tail -f /var/log/syslog"    # follow the syslog
2686 fi
2687
2688 # sort installed Debian-packages by size
2689 if check_com -c dpkg-query ; then
2690     #a3# List installed Debian-packages sorted by size
2691     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
2692 fi
2693
2694 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2695 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
2696     if check_com -c wodim; then
2697         cdrecord() {
2698             <<__EOF0__
2699 cdrecord is not provided under its original name by Debian anymore.
2700 See #377109 in the BTS of Debian for more details.
2701
2702 Please use the wodim binary instead
2703 __EOF0__
2704             return 1
2705         }
2706     fi
2707 fi
2708
2709 # Use hard limits, except for a smaller stack and no core dumps
2710 unlimit
2711 is425 && limit stack 8192
2712 isgrmlcd && limit core 0 # important for a live-cd-system
2713 limit -s
2714
2715 # grmlstuff
2716 grmlstuff() {
2717 # people should use 'grml-x'!
2718     if check_com -c 915resolution; then
2719         855resolution() {
2720             echo "Please use 915resolution as resolution modifying tool for Intel \
2721 graphic chipset."
2722             return -1
2723         }
2724     fi
2725
2726     #a1# Output version of running grml
2727     alias grml-version='cat /etc/grml_version'
2728
2729     if check_com -c grml-debootstrap ; then
2730         debian2hd() {
2731             echo "Installing debian to harddisk is possible by using grml-debootstrap."
2732             return 1
2733         }
2734     fi
2735 }
2736
2737 # now run the functions
2738 isgrml && checkhome
2739 is4    && isgrml    && grmlstuff
2740 is4    && grmlcomp
2741
2742 # keephack
2743 is4 && xsource "/etc/zsh/keephack"
2744
2745 # wonderful idea of using "e" glob qualifier by Peter Stephenson
2746 # You use it as follows:
2747 # $ NTREF=/reference/file
2748 # $ ls -l *(e:nt:)
2749 # This lists all the files in the current directory newer than the reference file.
2750 # You can also specify the reference file inline; note quotes:
2751 # $ ls -l *(e:'nt ~/.zshenv':)
2752 is4 && nt() {
2753     if [[ -n $1 ]] ; then
2754         local NTREF=${~1}
2755     fi
2756     [[ $REPLY -nt $NTREF ]]
2757 }
2758
2759 # shell functions
2760
2761 #f1# Reload an autoloadable function
2762 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2763 compdef _functions freload
2764
2765 #
2766 # Usage:
2767 #
2768 #      e.g.:   a -> b -> c -> d  ....
2769 #
2770 #      sll a
2771 #
2772 #
2773 #      if parameter is given with leading '=', lookup $PATH for parameter and resolve that
2774 #
2775 #      sll =java
2776 #
2777 #      Note: limit for recursive symlinks on linux:
2778 #            http://git.kernel.org/cgit/linux/kernel/git/torvalds/linux.git/tree/fs/namei.c?id=refs/heads/master#l808
2779 #            This limits recursive symlink follows to 8,
2780 #            while limiting consecutive symlinks to 40.
2781 #
2782 #      When resolving and displaying information about symlinks, no check is made
2783 #      that the displayed information does make any sense on your OS.
2784 #      We leave that decission to the user.
2785 #
2786 #      The zstat module is used to detect symlink loops. zstat is available since zsh4.
2787 #      With an older zsh you will need to abort with <C-c> in that case.
2788 #      When a symlink loop is detected, a warning ist printed and further processing is stopped.
2789 #
2790 #      Module zstat is loaded by default in grml zshrc, no extra action needed for that.
2791 #
2792 #      Known bugs:
2793 #      If you happen to come accross a symlink that points to a destination on an other partition
2794 #      with the same inode number, that will be marked as symlink loop though it is not.
2795 #      Two hints for this situation:
2796 #      I)  Play lottery the same day, as you seem to be rather lucky right now.
2797 #      II) Send patches.
2798 #
2799 #      return status:
2800 #      0 upon success
2801 #      1 file/dir not accesible
2802 #      2 symlink loop detected
2803 #
2804 #f1# List symlinks in detail (more detailed version of 'readlink -f', 'whence -s' and 'namei -l')
2805 sll() {
2806     if [[ -z ${1} ]] ; then
2807         printf 'Usage: %s <symlink(s)>\n' "${0}"
2808         return 1
2809     fi
2810
2811     local file jumpd curdir
2812     local -i RTN LINODE i
2813     local -a SEENINODES
2814     curdir="${PWD}"
2815     RTN=0
2816
2817     for file in "${@}" ; do
2818         SEENINODES=()
2819         ls -l "${file:a}"   || RTN=1
2820
2821         while [[ -h "$file" ]] ; do
2822             if is4 ; then
2823                 LINODE=$(zstat -L +inode "${file}")
2824                 for i in ${SEENINODES} ; do
2825                     if (( ${i} == ${LINODE} )) ; then
2826                         builtin cd "${curdir}"
2827                         print "link loop detected, aborting!"
2828                         return 2
2829                     fi
2830                 done
2831                 SEENINODES+=${LINODE}
2832             fi
2833             jumpd="${file:h}"
2834             file="${file:t}"
2835
2836             if [[ -d ${jumpd} ]] ; then
2837                 builtin cd "${jumpd}"  || RTN=1
2838             fi
2839             file=$(readlink "$file")
2840
2841             jumpd="${file:h}"
2842             file="${file:t}"
2843
2844             if [[ -d ${jumpd} ]] ; then
2845                 builtin cd "${jumpd}"  || RTN=1
2846             fi
2847
2848             ls -l "${PWD}/${file}"     || RTN=1
2849         done
2850         shift 1
2851         if (( ${#} >= 1 )) ; then
2852             print ""
2853         fi
2854         builtin cd "${curdir}"
2855     done
2856     return ${RTN}
2857 }
2858
2859 # TODO: Is it supported to use pager settings like this?
2860 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2861 # with respect to wordsplitting. (ie. ${=PAGER})
2862 if check_com -c $PAGER ; then
2863     #f3# View Debian's changelog of given package(s)
2864     dchange() {
2865         emulate -L zsh
2866         [[ -z "$1" ]] && printf 'Usage: %s <package_name(s)>\n' "$0" && return 1
2867
2868         local package
2869         for package in "$@" ; do
2870             if [[ -r /usr/share/doc/${package}/changelog.Debian.gz ]] ; then
2871                 $PAGER /usr/share/doc/${package}/changelog.Debian.gz
2872             elif [[ -r /usr/share/doc/${package}/changelog.gz ]] ; then
2873                 $PAGER /usr/share/doc/${package}/changelog.gz
2874             elif [[ -r /usr/share/doc/${package}/changelog ]] ; then
2875                 $PAGER /usr/share/doc/${package}/changelog
2876             else
2877                 if check_com -c aptitude ; then
2878                     echo "No changelog for package $package found, using aptitude to retrieve it."
2879                     aptitude changelog "$package"
2880                 elif check_com -c apt-get ; then
2881                     echo "No changelog for package $package found, using apt-get to retrieve it."
2882                     apt-get changelog "$package"
2883                 else
2884                     echo "No changelog for package $package found, sorry."
2885                 fi
2886             fi
2887         done
2888     }
2889     _dchange() { _files -W /usr/share/doc -/ }
2890     compdef _dchange dchange
2891
2892     #f3# View Debian's NEWS of a given package
2893     dnews() {
2894         emulate -L zsh
2895         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2896             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2897         else
2898             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2899                 $PAGER /usr/share/doc/$1/NEWS.gz
2900             else
2901                 echo "No NEWS file for package $1 found, sorry."
2902                 return 1
2903             fi
2904         fi
2905     }
2906     _dnews() { _files -W /usr/share/doc -/ }
2907     compdef _dnews dnews
2908
2909     #f3# View Debian's copyright of a given package
2910     dcopyright() {
2911         emulate -L zsh
2912         if [[ -r /usr/share/doc/$1/copyright ]] ; then
2913             $PAGER /usr/share/doc/$1/copyright
2914         else
2915             echo "No copyright file for package $1 found, sorry."
2916             return 1
2917         fi
2918     }
2919     _dcopyright() { _files -W /usr/share/doc -/ }
2920     compdef _dcopyright dcopyright
2921
2922     #f3# View upstream's changelog of a given package
2923     uchange() {
2924         emulate -L zsh
2925         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2926             $PAGER /usr/share/doc/$1/changelog.gz
2927         else
2928             echo "No changelog for package $1 found, sorry."
2929             return 1
2930         fi
2931     }
2932     _uchange() { _files -W /usr/share/doc -/ }
2933     compdef _uchange uchange
2934 fi
2935
2936 # zsh profiling
2937 profile() {
2938     ZSH_PROFILE_RC=1 zsh "$@"
2939 }
2940
2941 #f1# Edit an alias via zle
2942 edalias() {
2943     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2944 }
2945 compdef _aliases edalias
2946
2947 #f1# Edit a function via zle
2948 edfunc() {
2949     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2950 }
2951 compdef _functions edfunc
2952
2953 # use it e.g. via 'Restart apache2'
2954 #m# f6 Start() \kbd{service \em{process}}\quad\kbd{start}
2955 #m# f6 Restart() \kbd{service \em{process}}\quad\kbd{restart}
2956 #m# f6 Stop() \kbd{service \em{process}}\quad\kbd{stop}
2957 #m# f6 Reload() \kbd{service \em{process}}\quad\kbd{reload}
2958 #m# f6 Force-Reload() \kbd{service \em{process}}\quad\kbd{force-reload}
2959 #m# f6 Status() \kbd{service \em{process}}\quad\kbd{status}
2960 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2961     __start_stop() {
2962         local action_="${1:l}"  # e.g Start/Stop/Restart
2963         local service_="$2"
2964         local param_="$3"
2965
2966         local service_target_="$(readlink /etc/init.d/$service_)"
2967         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2968             # runit
2969             case "${action_}" in
2970                 start) if [[ ! -e /etc/service/$service_ ]]; then
2971                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2972                        else
2973                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2974                        fi ;;
2975                 # there is no reload in runits sysv emulation
2976                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2977                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2978             esac
2979         else
2980             # sysv/sysvinit-utils, upstart
2981             if check_com -c service ; then
2982               $SUDO service "$service_" "${action_}" "$param_"
2983             else
2984               $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2985             fi
2986         fi
2987     }
2988
2989     _grmlinitd() {
2990         local -a scripts
2991         scripts=( /etc/init.d/*(x:t) )
2992         _describe "service startup script" scripts
2993     }
2994
2995     for i in Start Restart Stop Force-Reload Reload Status ; do
2996         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2997         compdef _grmlinitd $i
2998     done
2999     builtin unset -v i
3000 fi
3001
3002 #f1# Provides useful information on globbing
3003 H-Glob() {
3004     echo -e "
3005     /      directories
3006     .      plain files
3007     @      symbolic links
3008     =      sockets
3009     p      named pipes (FIFOs)
3010     *      executable plain files (0100)
3011     %      device files (character or block special)
3012     %b     block special files
3013     %c     character special files
3014     r      owner-readable files (0400)
3015     w      owner-writable files (0200)
3016     x      owner-executable files (0100)
3017     A      group-readable files (0040)
3018     I      group-writable files (0020)
3019     E      group-executable files (0010)
3020     R      world-readable files (0004)
3021     W      world-writable files (0002)
3022     X      world-executable files (0001)
3023     s      setuid files (04000)
3024     S      setgid files (02000)
3025     t      files with the sticky bit (01000)
3026
3027   print *(m-1)          # Files modified up to a day ago
3028   print *(a1)           # Files accessed a day ago
3029   print *(@)            # Just symlinks
3030   print *(Lk+50)        # Files bigger than 50 kilobytes
3031   print *(Lk-50)        # Files smaller than 50 kilobytes
3032   print **/*.c          # All *.c files recursively starting in \$PWD
3033   print **/*.c~file.c   # Same as above, but excluding 'file.c'
3034   print (foo|bar).*     # Files starting with 'foo' or 'bar'
3035   print *~*.*           # All Files that do not contain a dot
3036   chmod 644 *(.^x)      # make all plain non-executable files publically readable
3037   print -l *(.c|.h)     # Lists *.c and *.h
3038   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
3039   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
3040 }
3041 alias help-zshglob=H-Glob
3042
3043 # grep for running process, like: 'any vim'
3044 any() {
3045     emulate -L zsh
3046     unsetopt KSH_ARRAYS
3047     if [[ -z "$1" ]] ; then
3048         echo "any - grep for process(es) by keyword" >&2
3049         echo "Usage: any <keyword>" >&2 ; return 1
3050     else
3051         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
3052     fi
3053 }
3054
3055
3056 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
3057 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
3058 [[ -r /proc/1/maps ]] && \
3059 deswap() {
3060     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
3061     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
3062     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
3063 }
3064
3065 # a wrapper for vim, that deals with title setting
3066 #   VIM_OPTIONS
3067 #       set this array to a set of options to vim you always want
3068 #       to have set when calling vim (in .zshrc.local), like:
3069 #           VIM_OPTIONS=( -p )
3070 #       This will cause vim to send every file given on the
3071 #       commandline to be send to it's own tab (needs vim7).
3072 if check_com vim; then
3073     vim() {
3074         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
3075     }
3076 fi
3077
3078 ssl_hashes=( sha512 sha256 sha1 md5 )
3079
3080 for sh in ${ssl_hashes}; do
3081     eval 'ssl-cert-'${sh}'() {
3082         emulate -L zsh
3083         if [[ -z $1 ]] ; then
3084             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
3085             return 1
3086         fi
3087         openssl x509 -noout -fingerprint -'${sh}' -in $1
3088     }'
3089 done; unset sh
3090
3091 ssl-cert-fingerprints() {
3092     emulate -L zsh
3093     local i
3094     if [[ -z $1 ]] ; then
3095         printf 'usage: ssl-cert-fingerprints <file>\n'
3096         return 1
3097     fi
3098     for i in ${ssl_hashes}
3099         do ssl-cert-$i $1;
3100     done
3101 }
3102
3103 ssl-cert-info() {
3104     emulate -L zsh
3105     if [[ -z $1 ]] ; then
3106         printf 'usage: ssl-cert-info <file>\n'
3107         return 1
3108     fi
3109     openssl x509 -noout -text -in $1
3110     ssl-cert-fingerprints $1
3111 }
3112
3113 # make sure our environment is clean regarding colors
3114 for var in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $var
3115 builtin unset -v var
3116
3117 # "persistent history"
3118 # just write important commands you always need to ~/.important_commands
3119 if [[ -r ~/.important_commands ]] ; then
3120     fc -R ~/.important_commands
3121 fi
3122
3123 # load the lookup subsystem if it's available on the system
3124 zrcautoload lookupinit && lookupinit
3125
3126 # variables
3127
3128 # set terminal property (used e.g. by msgid-chooser)
3129 export COLORTERM="yes"
3130
3131 # aliases
3132
3133 # general
3134 #a2# Execute \kbd{du -sch}
3135 alias da='du -sch'
3136
3137 # listing stuff
3138 #a2# Execute \kbd{ls -lSrah}
3139 alias dir="command ls -lSrah"
3140 #a2# Only show dot-directories
3141 alias lad='command ls -d .*(/)'
3142 #a2# Only show dot-files
3143 alias lsa='command ls -a .*(.)'
3144 #a2# Only files with setgid/setuid/sticky flag
3145 alias lss='command ls -l *(s,S,t)'
3146 #a2# Only show symlinks
3147 alias lsl='command ls -l *(@)'
3148 #a2# Display only executables
3149 alias lsx='command ls -l *(*)'
3150 #a2# Display world-{readable,writable,executable} files
3151 alias lsw='command ls -ld *(R,W,X.^ND/)'
3152 #a2# Display the ten biggest files
3153 alias lsbig="command ls -flh *(.OL[1,10])"
3154 #a2# Only show directories
3155 alias lsd='command ls -d *(/)'
3156 #a2# Only show empty directories
3157 alias lse='command ls -d *(/^F)'
3158 #a2# Display the ten newest files
3159 alias lsnew="command ls -rtlh *(D.om[1,10])"
3160 #a2# Display the ten oldest files
3161 alias lsold="command ls -rtlh *(D.Om[1,10])"
3162 #a2# Display the ten smallest files
3163 alias lssmall="command ls -Srl *(.oL[1,10])"
3164 #a2# Display the ten newest directories and ten newest .directories
3165 alias lsnewdir="command ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
3166 #a2# Display the ten oldest directories and ten oldest .directories
3167 alias lsolddir="command ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
3168
3169 # some useful aliases
3170 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir \$OLDCWD}
3171 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
3172
3173 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3174 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3175 #a2# scp with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3176 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3177
3178 # work around non utf8 capable software in utf environment via $LANG and luit
3179 if check_com isutfenv && check_com luit ; then
3180     if check_com -c mrxvt ; then
3181         isutfenv && [[ -n "$LANG" ]] && \
3182             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3183     fi
3184
3185     if check_com -c aterm ; then
3186         isutfenv && [[ -n "$LANG" ]] && \
3187             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3188     fi
3189
3190     if check_com -c centericq ; then
3191         isutfenv && [[ -n "$LANG" ]] && \
3192             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3193     fi
3194 fi
3195
3196 # useful functions
3197
3198 #f5# Backup \kbd{file_or_folder {\rm to} file_or_folder\_timestamp}
3199 bk() {
3200     emulate -L zsh
3201     local current_date=$(date -u "+%Y-%m-%dT%H:%M:%SZ")
3202     local clean keep move verbose result all to_bk
3203     setopt extended_glob
3204     keep=1
3205     while getopts ":hacmrv" opt; do
3206         case $opt in
3207             a) (( all++ ));;
3208             c) unset move clean && (( ++keep ));;
3209             m) unset keep clean && (( ++move ));;
3210             r) unset move keep && (( ++clean ));;
3211             v) verbose="-v";;
3212             h) <<__EOF0__
3213 bk [-hcmv] FILE [FILE ...]
3214 bk -r [-av] [FILE [FILE ...]]
3215 Backup a file or folder in place and append the timestamp
3216 Remove backups of a file or folder, or all backups in the current directory
3217
3218 Usage:
3219 -h    Display this help text
3220 -c    Keep the file/folder as is, create a copy backup using cp(1) (default)
3221 -m    Move the file/folder, using mv(1)
3222 -r    Remove backups of the specified file or directory, using rm(1). If none
3223       is provided, remove all backups in the current directory.
3224 -a    Remove all (even hidden) backups.
3225 -v    Verbose
3226
3227 The -c, -r and -m options are mutually exclusive. If specified at the same time,
3228 the last one is used.
3229
3230 The return code is the sum of all cp/mv/rm return codes.
3231 __EOF0__
3232 return 0;;
3233             \?) bk -h >&2; return 1;;
3234         esac
3235     done
3236     shift "$((OPTIND-1))"
3237     if (( keep > 0 )); then
3238         if islinux || isfreebsd; then
3239             for to_bk in "$@"; do
3240                 cp $verbose -a "${to_bk%/}" "${to_bk%/}_$current_date"
3241                 (( result += $? ))
3242             done
3243         else
3244             for to_bk in "$@"; do
3245                 cp $verbose -pR "${to_bk%/}" "${to_bk%/}_$current_date"
3246                 (( result += $? ))
3247             done
3248         fi
3249     elif (( move > 0 )); then
3250         while (( $# > 0 )); do
3251             mv $verbose "${1%/}" "${1%/}_$current_date"
3252             (( result += $? ))
3253             shift
3254         done
3255     elif (( clean > 0 )); then
3256         if (( $# > 0 )); then
3257             for to_bk in "$@"; do
3258                 rm $verbose -rf "${to_bk%/}"_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z
3259                 (( result += $? ))
3260             done
3261         else
3262             if (( all > 0 )); then
3263                 rm $verbose -rf *_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z(D)
3264             else
3265                 rm $verbose -rf *_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z
3266             fi
3267             (( result += $? ))
3268         fi
3269     fi
3270     return $result
3271 }
3272
3273 #f5# cd to directoy and list files
3274 cl() {
3275     emulate -L zsh
3276     cd $1 && ls -a
3277 }
3278
3279 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
3280 cd() {
3281     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
3282         [[ ! -e ${1:h} ]] && return 1
3283         print "Correcting ${1} to ${1:h}"
3284         builtin cd ${1:h}
3285     else
3286         builtin cd "$@"
3287     fi
3288 }
3289
3290 #f5# Create Directoy and \kbd{cd} to it
3291 mkcd() {
3292     if (( ARGC != 1 )); then
3293         printf 'usage: mkcd <new-directory>\n'
3294         return 1;
3295     fi
3296     if [[ ! -d "$1" ]]; then
3297         command mkdir -p "$1"
3298     else
3299         printf '`%s'\'' already exists: cd-ing.\n' "$1"
3300     fi
3301     builtin cd "$1"
3302 }
3303
3304 #f5# Create temporary directory and \kbd{cd} to it
3305 cdt() {
3306     builtin cd "$(mktemp -d)"
3307     builtin pwd
3308 }
3309
3310 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
3311 accessed() {
3312     emulate -L zsh
3313     print -l -- *(a-${1:-1})
3314 }
3315
3316 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
3317 changed() {
3318     emulate -L zsh
3319     print -l -- *(c-${1:-1})
3320 }
3321
3322 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
3323 modified() {
3324     emulate -L zsh
3325     print -l -- *(m-${1:-1})
3326 }
3327 # modified() was named new() in earlier versions, add an alias for backwards compatibility
3328 check_com new || alias new=modified
3329
3330 # use colors when GNU grep with color-support
3331 if (( $#grep_options > 0 )); then
3332     o=${grep_options:+"${grep_options[*]}"}
3333     #a2# Execute \kbd{grep -{}-color=auto}
3334     alias grep='grep '$o
3335     alias egrep='egrep '$o
3336     unset o
3337 fi
3338
3339 # Translate DE<=>EN
3340 # 'translate' looks up a word in a file with language-to-language
3341 # translations (field separator should be " : "). A typical wordlist looks
3342 # like the following:
3343 #  | english-word : german-translation
3344 # It's also only possible to translate english to german but not reciprocal.
3345 # Use the following oneliner to reverse the sort order:
3346 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3347 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3348 #f5# Translates a word
3349 trans() {
3350     emulate -L zsh
3351     case "$1" in
3352         -[dD]*)
3353             translate -l de-en $2
3354             ;;
3355         -[eE]*)
3356             translate -l en-de $2
3357             ;;
3358         *)
3359             echo "Usage: $0 { -D | -E }"
3360             echo "         -D == German to English"
3361             echo "         -E == English to German"
3362     esac
3363 }
3364
3365 # Usage: simple-extract <file>
3366 # Using option -d deletes the original archive file.
3367 #f5# Smart archive extractor
3368 simple-extract() {
3369     emulate -L zsh
3370     setopt extended_glob noclobber
3371     local ARCHIVE DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
3372     local RC=0
3373     zparseopts -D -E "d=DELETE_ORIGINAL"
3374     for ARCHIVE in "${@}"; do
3375         case $ARCHIVE in
3376             *(tar.bz2|tbz2|tbz))
3377                 DECOMP_CMD="tar -xvjf -"
3378                 USES_STDIN=true
3379                 USES_STDOUT=false
3380                 ;;
3381             *(tar.gz|tgz))
3382                 DECOMP_CMD="tar -xvzf -"
3383                 USES_STDIN=true
3384                 USES_STDOUT=false
3385                 ;;
3386             *(tar.xz|txz|tar.lzma))
3387                 DECOMP_CMD="tar -xvJf -"
3388                 USES_STDIN=true
3389                 USES_STDOUT=false
3390                 ;;
3391             *tar)
3392                 DECOMP_CMD="tar -xvf -"
3393                 USES_STDIN=true
3394                 USES_STDOUT=false
3395                 ;;
3396             *rar)
3397                 DECOMP_CMD="unrar x"
3398                 USES_STDIN=false
3399                 USES_STDOUT=false
3400                 ;;
3401             *lzh)
3402                 DECOMP_CMD="lha x"
3403                 USES_STDIN=false
3404                 USES_STDOUT=false
3405                 ;;
3406             *7z)
3407                 DECOMP_CMD="7z x"
3408                 USES_STDIN=false
3409                 USES_STDOUT=false
3410                 ;;
3411             *(zip|jar))
3412                 DECOMP_CMD="unzip"
3413                 USES_STDIN=false
3414                 USES_STDOUT=false
3415                 ;;
3416             *deb)
3417                 DECOMP_CMD="ar -x"
3418                 USES_STDIN=false
3419                 USES_STDOUT=false
3420                 ;;
3421             *bz2)
3422                 DECOMP_CMD="bzip2 -d -c -"
3423                 USES_STDIN=true
3424                 USES_STDOUT=true
3425                 ;;
3426             *(gz|Z))
3427                 DECOMP_CMD="gzip -d -c -"
3428                 USES_STDIN=true
3429                 USES_STDOUT=true
3430                 ;;
3431             *(xz|lzma))
3432                 DECOMP_CMD="xz -d -c -"
3433                 USES_STDIN=true
3434                 USES_STDOUT=true
3435                 ;;
3436             *)
3437                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
3438                 RC=$((RC+1))
3439                 continue
3440                 ;;
3441         esac
3442
3443         if ! check_com ${DECOMP_CMD[(w)1]}; then
3444             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
3445             RC=$((RC+2))
3446             continue
3447         fi
3448
3449         GZTARGET="${ARCHIVE:t:r}"
3450         if [[ -f $ARCHIVE ]] ; then
3451
3452             print "Extracting '$ARCHIVE' ..."
3453             if $USES_STDIN; then
3454                 if $USES_STDOUT; then
3455                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
3456                 else
3457                     ${=DECOMP_CMD} < "$ARCHIVE"
3458                 fi
3459             else
3460                 if $USES_STDOUT; then
3461                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
3462                 else
3463                     ${=DECOMP_CMD} "$ARCHIVE"
3464                 fi
3465             fi
3466             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
3467
3468         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
3469             if check_com curl; then
3470                 WGET_CMD="curl -L -s -o -"
3471             elif check_com wget; then
3472                 WGET_CMD="wget -q -O -"
3473             elif check_com fetch; then
3474                 WGET_CMD="fetch -q -o -"
3475             else
3476                 print "ERROR: neither wget, curl nor fetch is installed" >&2
3477                 RC=$((RC+4))
3478                 continue
3479             fi
3480             print "Downloading and Extracting '$ARCHIVE' ..."
3481             if $USES_STDIN; then
3482                 if $USES_STDOUT; then
3483                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
3484                     RC=$((RC+$?))
3485                 else
3486                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
3487                     RC=$((RC+$?))
3488                 fi
3489             else
3490                 if $USES_STDOUT; then
3491                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
3492                 else
3493                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
3494                 fi
3495             fi
3496
3497         else
3498             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
3499             RC=$((RC+8))
3500         fi
3501     done
3502     return $RC
3503 }
3504
3505 __archive_or_uri()
3506 {
3507     _alternative \
3508         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
3509         '_urls:Remote Archives:_urls'
3510 }
3511
3512 _simple_extract()
3513 {
3514     _arguments \
3515         '-d[delete original archivefile after extraction]' \
3516         '*:Archive Or Uri:__archive_or_uri'
3517 }
3518 compdef _simple_extract simple-extract
3519 alias se=simple-extract
3520
3521 #f5# Set all ulimit parameters to \kbd{unlimited}
3522 allulimit() {
3523     ulimit -c unlimited
3524     ulimit -d unlimited
3525     ulimit -f unlimited
3526     ulimit -l unlimited
3527     ulimit -n unlimited
3528     ulimit -s unlimited
3529     ulimit -t unlimited
3530 }
3531
3532 #f5# Change the xterm title from within GNU-screen
3533 xtrename() {
3534     emulate -L zsh
3535     if [[ $1 != "-f" ]] ; then
3536         if [[ -z ${DISPLAY} ]] ; then
3537             printf 'xtrename only makes sense in X11.\n'
3538             return 1
3539         fi
3540     else
3541         shift
3542     fi
3543     if [[ -z $1 ]] ; then
3544         printf 'usage: xtrename [-f] "title for xterm"\n'
3545         printf '  renames the title of xterm from _within_ screen.\n'
3546         printf '  also works without screen.\n'
3547         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3548         return 0
3549     fi
3550     print -n "\eP\e]0;${1}\C-G\e\\"
3551     return 0
3552 }
3553
3554 # Create small urls via http://goo.gl using curl(1).
3555 # API reference: https://code.google.com/apis/urlshortener/
3556 function zurl() {
3557     emulate -L zsh
3558     setopt extended_glob
3559
3560     if [[ -z $1 ]]; then
3561         print "USAGE: zurl <URL>"
3562         return 1
3563     fi
3564
3565     local PN url prog api json contenttype item
3566     local -a data
3567     PN=$0
3568     url=$1
3569
3570     # Prepend 'http://' to given URL where necessary for later output.
3571     if [[ ${url} != http(s|)://* ]]; then
3572         url='http://'${url}
3573     fi
3574
3575     if check_com -c curl; then
3576         prog=curl
3577     else
3578         print "curl is not available, but mandatory for ${PN}. Aborting."
3579         return 1
3580     fi
3581     api='https://www.googleapis.com/urlshortener/v1/url'
3582     contenttype="Content-Type: application/json"
3583     json="{\"longUrl\": \"${url}\"}"
3584     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
3585     # Parse the response
3586     for item in "${data[@]}"; do
3587         case "$item" in
3588             ' '#'"id":'*)
3589                 item=${item#*: \"}
3590                 item=${item%\",*}
3591                 printf '%s\n' "$item"
3592                 return 0
3593                 ;;
3594         esac
3595     done
3596     return 1
3597 }
3598
3599 #f2# Find history events by search pattern and list them by date.
3600 whatwhen()  {
3601     emulate -L zsh
3602     local usage help ident format_l format_s first_char remain first last
3603     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3604     help='Use `whatwhen -h'\'' for further explanations.'
3605     ident=${(l,${#${:-Usage: }},, ,)}
3606     format_l="${ident}%s\t\t\t%s\n"
3607     format_s="${format_l//(\\t)##/\\t}"
3608     # Make the first char of the word to search for case
3609     # insensitive; e.g. [aA]
3610     first_char=[${(L)1[1]}${(U)1[1]}]
3611     remain=${1[2,-1]}
3612     # Default search range is `-100'.
3613     first=${2:-\-100}
3614     # Optional, just used for `<first> <last>' given.
3615     last=$3
3616     case $1 in
3617         ("")
3618             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3619             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3620         ;;
3621         (-h)
3622             printf '%s\n\n' ${usage}
3623             print 'OPTIONS:'
3624             printf $format_l '-h' 'show help text'
3625             print '\f'
3626             print 'SEARCH RANGE:'
3627             printf $format_l "'0'" 'the whole history,'
3628             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
3629             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
3630             printf '\n%s\n' 'EXAMPLES:'
3631             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
3632             printf $format_l 'whatwhen zsh -250'
3633             printf $format_l 'whatwhen foo 1 99'
3634         ;;
3635         (\?)
3636             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3637         ;;
3638         (*)
3639             # -l list results on stout rather than invoking $EDITOR.
3640             # -i Print dates as in YYYY-MM-DD.
3641             # -m Search for a - quoted - pattern within the history.
3642             fc -li -m "*${first_char}${remain}*" $first $last
3643         ;;
3644     esac
3645 }
3646
3647 # mercurial related stuff
3648 if check_com -c hg ; then
3649     # gnu like diff for mercurial
3650     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
3651     #f5# GNU like diff for mercurial
3652     hgdi() {
3653         emulate -L zsh
3654         local i
3655         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
3656     }
3657
3658     # build debian package
3659     #a2# Alias for \kbd{hg-buildpackage}
3660     alias hbp='hg-buildpackage'
3661
3662     # execute commands on the versioned patch-queue from the current repos
3663     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
3664
3665     # diffstat for specific version of a mercurial repository
3666     #   hgstat      => display diffstat between last revision and tip
3667     #   hgstat 1234 => display diffstat between revision 1234 and tip
3668     #f5# Diffstat for specific version of a mercurial repos
3669     hgstat() {
3670         emulate -L zsh
3671         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
3672     }
3673
3674 fi # end of check whether we have the 'hg'-executable
3675
3676 # grml-small cleanups
3677
3678 # The following is used to remove zsh-config-items that do not work
3679 # in grml-small by default.
3680 # If you do not want these adjustments (for whatever reason), set
3681 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
3682 # sources if it is there).
3683
3684 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
3685
3686     unset abk[V]
3687     unalias    'V'      &> /dev/null
3688     unfunction vman     &> /dev/null
3689     unfunction viless   &> /dev/null
3690     unfunction 2html    &> /dev/null
3691
3692     # manpages are not in grmlsmall
3693     unfunction manzsh   &> /dev/null
3694     unfunction man2     &> /dev/null
3695
3696 fi
3697
3698 zrclocal
3699
3700 ## genrefcard.pl settings
3701
3702 ### doc strings for external functions from files
3703 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
3704
3705 ### example: split functions-search 8,16,24,32
3706 #@# split functions-search 8
3707
3708 ## END OF FILE #################################################################
3709 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
3710 # Local variables:
3711 # mode: sh
3712 # End: