etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is437(){
 148     [[ $ZSH_VERSION == 4.3.<7->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 is439(){
 154     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 155                                  || $ZSH_VERSION == <5->* ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running grml
 160 isgrml(){
 161     [[ -f /etc/grml_version ]] && return 0
 162     return 1
 163 }
 164
 165 #f1# Checks whether or not you're running a grml cd
 166 isgrmlcd(){
 167     [[ -f /etc/grml_cd ]] && return 0
 168     return 1
 169 }
 170
 171 if isgrml ; then
 172 #f1# Checks whether or not you're running grml-small
 173     isgrmlsmall() {
 174         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 175             return 0
 176         fi
 177         return 1
 178     }
 179 else
 180     isgrmlsmall() { return 1 }
 181 fi
 182
 183 isdarwin(){
 184     [[ $OSTYPE == darwin* ]] && return 0
 185     return 1
 186 }
 187
 188 isfreebsd(){
 189     [[ $OSTYPE == freebsd* ]] && return 0
 190     return 1
 191 }
 192
 193 #f1# are we running within an utf environment?
 194 isutfenv() {
 195     case "$LANG $CHARSET $LANGUAGE" in
 196         *utf*) return 0 ;;
 197         *UTF*) return 0 ;;
 198         *)     return 1 ;;
 199     esac
 200 }
 201
 202 # check for user, if not running as root set $SUDO to sudo
 203 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 204
 205 # change directory to home on first invocation of zsh
 206 # important for rungetty -> autologin
 207 # Thanks go to Bart Schaefer!
 208 isgrml && checkhome() {
 209     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 210         export ALREADY_DID_CD_HOME=$HOME
 211         cd
 212     fi
 213 }
 214
 215 # check for zsh v3.1.7+
 216
 217 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 218      || ${ZSH_VERSION} == 3.<2->.<->*    \
 219      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 220
 221     printf '-!-\n'
 222     printf '-!- In this configuration we try to make use of features, that only\n'
 223     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 224     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 225     printf '-!- advanced features in all supported versions.\n'
 226     printf '-!-\n'
 227     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 228     printf '-!-\n'
 229     printf '-!- While this *may* work, it might as well fail.\n'
 230     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 231     printf '-!-\n'
 232     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 233     printf '-!- If it does today, you'\''ve been lucky.\n'
 234     printf '-!-\n'
 235     printf '-!- Ye been warned!\n'
 236     printf '-!-\n'
 237
 238     function zstyle() { : }
 239 fi
 240
 241 # autoload wrapper - use this one instead of autoload directly
 242 # We need to define this function as early as this, because autoloading
 243 # 'is-at-least()' needs it.
 244 function zrcautoload() {
 245     emulate -L zsh
 246     setopt extended_glob
 247     local fdir ffile
 248     local -i ffound
 249
 250     ffile=$1
 251     (( ffound = 0 ))
 252     for fdir in ${fpath} ; do
 253         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 254     done
 255
 256     (( ffound == 0 )) && return 1
 257     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 258         autoload -U ${ffile} || return 1
 259     else
 260         autoload ${ffile} || return 1
 261     fi
 262     return 0
 263 }
 264
 265 # Load is-at-least() for more precise version checks Note that this test will
 266 # *always* fail, if the is-at-least function could not be marked for
 267 # autoloading.
 268 zrcautoload is-at-least || is-at-least() { return 1 }
 269
 270 # set some important options (as early as possible)
 271
 272 # append history list to the history file; this is the default but we make sure
 273 # because it's required for share_history.
 274 setopt append_history
 275
 276 # import new commands from the history file also in other zsh-session
 277 is4 && setopt share_history
 278
 279 # save each command's beginning timestamp and the duration to the history file
 280 setopt extended_history
 281
 282 # If a new command line being added to the history list duplicates an older
 283 # one, the older command is removed from the list
 284 is4 && setopt histignorealldups
 285
 286 # remove command lines from the history list when the first character on the
 287 # line is a space
 288 setopt histignorespace
 289
 290 # if a command is issued that can't be executed as a normal command, and the
 291 # command is the name of a directory, perform the cd command to that directory.
 292 setopt auto_cd
 293
 294 # in order to use #, ~ and ^ for filename generation grep word
 295 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 296 # don't forget to quote '^', '~' and '#'!
 297 setopt extended_glob
 298
 299 # display PID when suspending processes as well
 300 setopt longlistjobs
 301
 302 # try to avoid the 'zsh: no matches found...'
 303 setopt nonomatch
 304
 305 # report the status of backgrounds jobs immediately
 306 setopt notify
 307
 308 # whenever a command completion is attempted, make sure the entire command path
 309 # is hashed first.
 310 setopt hash_list_all
 311
 312 # not just at the end
 313 setopt completeinword
 314
 315 # Don't send SIGHUP to background processes when the shell exits.
 316 setopt nohup
 317
 318 # make cd push the old directory onto the directory stack.
 319 setopt auto_pushd
 320
 321 # avoid "beep"ing
 322 setopt nobeep
 323
 324 # don't push the same dir twice.
 325 setopt pushd_ignore_dups
 326
 327 # * shouldn't match dotfiles. ever.
 328 setopt noglobdots
 329
 330 # use zsh style word splitting
 331 setopt noshwordsplit
 332
 333 # don't error out when unset parameters are used
 334 setopt unset
 335
 336 # setting some default values
 337 NOCOR=${NOCOR:-0}
 338 NOMENU=${NOMENU:-0}
 339 NOPRECMD=${NOPRECMD:-0}
 340 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 341 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 342 BATTERY=${BATTERY:-0}
 343 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 344 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 345
 346 typeset -ga ls_options
 347 typeset -ga grep_options
 348 if ls --help 2> /dev/null | grep -q GNU; then
 349     ls_options=( --color=auto )
 350 elif [[ $OSTYPE == freebsd* ]]; then
 351     ls_options=( -G )
 352 fi
 353 if grep --help 2> /dev/null | grep -q GNU || \
 354    [[ $OSTYPE == freebsd* ]]; then
 355     grep_options=( --color=auto )
 356 fi
 357
 358 # utility functions
 359 # this function checks if a command exists and returns either true
 360 # or false. This avoids using 'which' and 'whence', which will
 361 # avoid problems with aliases for which on certain weird systems. :-)
 362 # Usage: check_com [-c|-g] word
 363 #   -c  only checks for external commands
 364 #   -g  does the usual tests and also checks for global aliases
 365 check_com() {
 366     emulate -L zsh
 367     local -i comonly gatoo
 368
 369     if [[ $1 == '-c' ]] ; then
 370         (( comonly = 1 ))
 371         shift
 372     elif [[ $1 == '-g' ]] ; then
 373         (( gatoo = 1 ))
 374     else
 375         (( comonly = 0 ))
 376         (( gatoo = 0 ))
 377     fi
 378
 379     if (( ${#argv} != 1 )) ; then
 380         printf 'usage: check_com [-c] <command>\n' >&2
 381         return 1
 382     fi
 383
 384     if (( comonly > 0 )) ; then
 385         [[ -n ${commands[$1]}  ]] && return 0
 386         return 1
 387     fi
 388
 389     if   [[ -n ${commands[$1]}    ]] \
 390       || [[ -n ${functions[$1]}   ]] \
 391       || [[ -n ${aliases[$1]}     ]] \
 392       || [[ -n ${reswords[(r)$1]} ]] ; then
 393
 394         return 0
 395     fi
 396
 397     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 398         return 0
 399     fi
 400
 401     return 1
 402 }
 403
 404 # creates an alias and precedes the command with
 405 # sudo if $EUID is not zero.
 406 salias() {
 407     emulate -L zsh
 408     local only=0 ; local multi=0
 409     while [[ $1 == -* ]] ; do
 410         case $1 in
 411             (-o) only=1 ;;
 412             (-a) multi=1 ;;
 413             (--) shift ; break ;;
 414             (-h)
 415                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 416                 printf '  -h      shows this help text.\n'
 417                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 418                 printf '          be careful using this option.\n'
 419                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 420                 return 0
 421                 ;;
 422             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 423         esac
 424         shift
 425     done
 426
 427     if (( ${#argv} > 1 )) ; then
 428         printf 'Too many arguments %s\n' "${#argv}"
 429         return 1
 430     fi
 431
 432     key="${1%%\=*}" ;  val="${1#*\=}"
 433     if (( EUID == 0 )) && (( only == 0 )); then
 434         alias -- "${key}=${val}"
 435     elif (( EUID > 0 )) ; then
 436         (( multi > 0 )) && val="${val// ; / ; sudo }"
 437         alias -- "${key}=sudo ${val}"
 438     fi
 439
 440     return 0
 441 }
 442
 443 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 444 # usage: uprint foo
 445 #   Where foo is the *name* of the parameter you want printed.
 446 #   Note that foo is no typo; $foo would be wrong here!
 447 if ! is42 ; then
 448     uprint () {
 449         emulate -L zsh
 450         local -a u
 451         local w
 452         local parameter=$1
 453
 454         if [[ -z ${parameter} ]] ; then
 455             printf 'usage: uprint <parameter>\n'
 456             return 1
 457         fi
 458
 459         for w in ${(P)parameter} ; do
 460             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 461         done
 462
 463         builtin print -l $u
 464     }
 465 fi
 466
 467 # Check if we can read given files and source those we can.
 468 xsource() {
 469     if (( ${#argv} < 1 )) ; then
 470         printf 'usage: xsource FILE(s)...\n' >&2
 471         return 1
 472     fi
 473
 474     while (( ${#argv} > 0 )) ; do
 475         [[ -r "$1" ]] && source "$1"
 476         shift
 477     done
 478     return 0
 479 }
 480
 481 # Check if we can read a given file and 'cat(1)' it.
 482 xcat() {
 483     emulate -L zsh
 484     if (( ${#argv} != 1 )) ; then
 485         printf 'usage: xcat FILE\n' >&2
 486         return 1
 487     fi
 488
 489     [[ -r $1 ]] && cat $1
 490     return 0
 491 }
 492
 493 # Remove these functions again, they are of use only in these
 494 # setup files. This should be called at the end of .zshrc.
 495 xunfunction() {
 496     emulate -L zsh
 497     local -a funcs
 498     funcs=(salias xcat xsource xunfunction zrcautoload
 499                                            zrcautozle
 500                                            zrcbindkey
 501                                            zrcgotkeymap
 502                                            zrcgotwidget)
 503     for func in $funcs ; do
 504         [[ -n ${functions[$func]} ]] \
 505             && unfunction $func
 506     done
 507     return 0
 508 }
 509
 510 # this allows us to stay in sync with grml's zshrc and put own
 511 # modifications in ~/.zshrc.local
 512 zrclocal() {
 513     xsource "/etc/zsh/zshrc.local"
 514     xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
 515     return 0
 516 }
 517
 518 # locale setup
 519 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 520     xsource "/etc/default/locale"
 521 fi
 522
 523 for var in LANG LC_ALL LC_MESSAGES ; do
 524     [[ -n ${(P)var} ]] && export $var
 525 done
 526
 527 xsource "/etc/sysconfig/keyboard"
 528
 529 TZ=$(xcat /etc/timezone)
 530
 531 # set some variables
 532 if check_com -c vim ; then
 533 #v#
 534     export EDITOR=${EDITOR:-vim}
 535 else
 536     export EDITOR=${EDITOR:-vi}
 537 fi
 538
 539 #v#
 540 export PAGER=${PAGER:-less}
 541
 542 #v#
 543 export MAIL=${MAIL:-/var/mail/$USER}
 544
 545 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 546 export SHELL='/bin/zsh'
 547
 548 # color setup for ls:
 549 check_com -c dircolors && eval $(dircolors -b)
 550 # color setup for ls on OS X / FreeBSD:
 551 isdarwin && export CLICOLOR=1
 552 isfreebsd && export CLICOLOR=1
 553
 554 # do MacPorts setup on darwin
 555 if isdarwin && [[ -d /opt/local ]]; then
 556     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 557     # zshenv.
 558     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 559     MANPATH="/opt/local/share/man:$MANPATH"
 560 fi
 561 # do Fink setup on darwin
 562 isdarwin && xsource /sw/bin/init.sh
 563
 564 # load our function and completion directories
 565 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 566     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 567     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 568         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 569             zrcautoload ${func:t}
 570         done
 571     fi
 572 done
 573 unset fdir func
 574
 575 # support colors in less
 576 export LESS_TERMCAP_mb=$'\E[01;31m'
 577 export LESS_TERMCAP_md=$'\E[01;31m'
 578 export LESS_TERMCAP_me=$'\E[0m'
 579 export LESS_TERMCAP_se=$'\E[0m'
 580 export LESS_TERMCAP_so=$'\E[01;44;33m'
 581 export LESS_TERMCAP_ue=$'\E[0m'
 582 export LESS_TERMCAP_us=$'\E[01;32m'
 583
 584 # mailchecks
 585 MAILCHECK=30
 586
 587 # report about cpu-/system-/user-time of command if running longer than
 588 # 5 seconds
 589 REPORTTIME=5
 590
 591 # watch for everyone but me and root
 592 watch=(notme root)
 593
 594 # automatically remove duplicates from these arrays
 595 typeset -U path cdpath fpath manpath
 596
 597 # Load a few modules
 598 is4 && \
 599 for mod in complist deltochar mathfunc ; do
 600     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 601 done
 602
 603 # autoload zsh modules when they are referenced
 604 if is4 ; then
 605     zmodload -a  zsh/stat    zstat
 606     zmodload -a  zsh/zpty    zpty
 607     zmodload -ap zsh/mapfile mapfile
 608 fi
 609
 610 # completion system
 611 if zrcautoload compinit ; then
 612     compinit || print 'Notice: no compinit available :('
 613 else
 614     print 'Notice: no compinit available :('
 615     function compdef { }
 616 fi
 617
 618 # completion system
 619
 620 # called later (via is4 && grmlcomp)
 621 # note: use 'zstyle' for getting current settings
 622 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
 623 grmlcomp() {
 624     # TODO: This could use some additional information
 625
 626     # Make sure the completion system is initialised
 627     (( ${+_comps} )) || return 1
 628
 629     # allow one error for every three characters typed in approximate completer
 630     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
 631
 632     # don't complete backup files as executables
 633     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
 634
 635     # start menu completion only if it could find no unambiguous initial string
 636     zstyle ':completion:*:correct:*'       insert-unambiguous true
 637     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
 638     zstyle ':completion:*:correct:*'       original true
 639
 640     # activate color-completion
 641     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
 642
 643     # format on completion
 644     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
 645
 646     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
 647     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
 648
 649     # insert all expansions for expand completer
 650     zstyle ':completion:*:expand:*'        tag-order all-expansions
 651     zstyle ':completion:*:history-words'   list false
 652
 653     # activate menu
 654     zstyle ':completion:*:history-words'   menu yes
 655
 656     # ignore duplicate entries
 657     zstyle ':completion:*:history-words'   remove-all-dups yes
 658     zstyle ':completion:*:history-words'   stop yes
 659
 660     # match uppercase from lowercase
 661     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
 662
 663     # separate matches into groups
 664     zstyle ':completion:*:matches'         group 'yes'
 665     zstyle ':completion:*'                 group-name ''
 666
 667     if [[ "$NOMENU" -eq 0 ]] ; then
 668         # if there are more than 5 options allow selecting from a menu
 669         zstyle ':completion:*'               menu select=5
 670     else
 671         # don't use any menus at all
 672         setopt no_auto_menu
 673     fi
 674
 675     zstyle ':completion:*:messages'        format '%d'
 676     zstyle ':completion:*:options'         auto-description '%d'
 677
 678     # describe options in full
 679     zstyle ':completion:*:options'         description 'yes'
 680
 681     # on processes completion complete all user processes
 682     zstyle ':completion:*:processes'       command 'ps -au$USER'
 683
 684     # offer indexes before parameters in subscripts
 685     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
 686
 687     # provide verbose completion information
 688     zstyle ':completion:*'                 verbose true
 689
 690     # recent (as of Dec 2007) zsh versions are able to provide descriptions
 691     # for commands (read: 1st word in the line) that it will list for the user
 692     # to choose from. The following disables that, because it's not exactly fast.
 693     zstyle ':completion:*:-command-:*:'    verbose false
 694
 695     # set format for warnings
 696     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
 697
 698     # define files to ignore for zcompile
 699     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
 700     zstyle ':completion:correct:'          prompt 'correct to: %e'
 701
 702     # Ignore completion functions for commands you don't have:
 703     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
 704
 705     # Provide more processes in completion of programs like killall:
 706     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
 707
 708     # complete manual by their section
 709     zstyle ':completion:*:manuals'    separate-sections true
 710     zstyle ':completion:*:manuals.*'  insert-sections   true
 711     zstyle ':completion:*:man:*'      menu yes select
 712
 713     # Search path for sudo completion
 714     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
 715                                                /usr/local/bin  \
 716                                                /usr/sbin       \
 717                                                /usr/bin        \
 718                                                /sbin           \
 719                                                /bin            \
 720                                                /usr/X11R6/bin
 721
 722     # provide .. as a completion
 723     zstyle ':completion:*' special-dirs ..
 724
 725     # run rehash on completion so new installed program are found automatically:
 726     _force_rehash() {
 727         (( CURRENT == 1 )) && rehash
 728         return 1
 729     }
 730
 731     ## correction
 732     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
 733     if [[ "$NOCOR" -gt 0 ]] ; then
 734         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
 735         setopt nocorrect
 736     else
 737         # try to be smart about when to use what completer...
 738         setopt correct
 739         zstyle -e ':completion:*' completer '
 740             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
 741                 _last_try="$HISTNO$BUFFER$CURSOR"
 742                 reply=(_complete _match _ignored _prefix _files)
 743             else
 744                 if [[ $words[1] == (rm|mv) ]] ; then
 745                     reply=(_complete _files)
 746                 else
 747                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
 748                 fi
 749             fi'
 750     fi
 751
 752     # command for process lists, the local web server details and host completion
 753     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
 754
 755     # caching
 756     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
 757                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
 758
 759     # host completion
 760     if is42 ; then
 761         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
 762         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
 763     else
 764         _ssh_hosts=()
 765         _etc_hosts=()
 766     fi
 767     hosts=(
 768         $(hostname)
 769         "$_ssh_hosts[@]"
 770         "$_etc_hosts[@]"
 771         localhost
 772     )
 773     zstyle ':completion:*:hosts' hosts $hosts
 774     # TODO: so, why is this here?
 775     #  zstyle '*' hosts $hosts
 776
 777     # use generic completion system for programs not yet defined; (_gnu_generic works
 778     # with commands that provide a --help option with "standard" gnu-like output.)
 779     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
 780                    pal stow tail uname ; do
 781         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
 782     done; unset compcom
 783
 784     # see upgrade function in this file
 785     compdef _hosts upgrade
 786 }
 787
 788 # Keyboard setup: The following is the same code, we wrote for debian's setup.
 789 # It ensures the terminal is in the right mode, when zle is active, so the
 790 # values from $terminfo are valid. Therefore, this setup should work on all
 791 # systems, that have support for `terminfo'. It also requires the zsh in use to
 792 # have the `zsh/terminfo' module built.
 793 #
 794 # If you are customising your `zle-line-init()' or `zle-line-finish()'
 795 # functions, make sure you call the following utility functions in there:
 796 #
 797 #     - zle-line-init():      zle-smkx
 798 #     - zle-line-finish():    zle-rmkx
 799
 800 # Use emacs-like key bindings by default:
 801 bindkey -e
 802
 803 # Custom widgets:
 804
 805 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 806 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 807 beginning-or-end-of-somewhere() {
 808     local hno=$HISTNO
 809     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 810       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 811         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 812     else
 813         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 814         if (( HISTNO != hno )); then
 815             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 816         fi
 817     fi
 818 }
 819 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 820 zle -N end-of-somewhere beginning-or-end-of-somewhere
 821
 822 ## toggle the ,. abbreviation feature on/off
 823 # NOABBREVIATION: default abbreviation-state
 824 #                 0 - enabled (default)
 825 #                 1 - disabled
 826 NOABBREVIATION=${NOABBREVIATION:-0}
 827
 828 grml_toggle_abbrev() {
 829     if (( ${NOABBREVIATION} > 0 )) ; then
 830         NOABBREVIATION=0
 831     else
 832         NOABBREVIATION=1
 833     fi
 834 }
 835 zle -N grml_toggle_abbrev
 836
 837 # add a command line to the shells history without executing it
 838 commit-to-history() {
 839     print -s ${(z)BUFFER}
 840     zle send-break
 841 }
 842 zle -N commit-to-history
 843
 844 # only slash should be considered as a word separator:
 845 slash-backward-kill-word() {
 846     local WORDCHARS="${WORDCHARS:s@/@}"
 847     # zle backward-word
 848     zle backward-kill-word
 849 }
 850 zle -N slash-backward-kill-word
 851
 852 # a generic accept-line wrapper
 853
 854 # This widget can prevent unwanted autocorrections from command-name
 855 # to _command-name, rehash automatically on enter and call any number
 856 # of builtin and user-defined widgets in different contexts.
 857 #
 858 # For a broader description, see:
 859 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 860 #
 861 # The code is imported from the file 'zsh/functions/accept-line' from
 862 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 863 # distributed under the same terms as zsh itself.
 864
 865 # A newly added command will may not be found or will cause false
 866 # correction attempts, if you got auto-correction set. By setting the
 867 # following style, we force accept-line() to rehash, if it cannot
 868 # find the first word on the command line in the $command[] hash.
 869 zstyle ':acceptline:*' rehash true
 870
 871 function Accept-Line() {
 872     setopt localoptions noksharrays
 873     local -a subs
 874     local -xi aldone
 875     local sub
 876     local alcontext=${1:-$alcontext}
 877
 878     zstyle -a ":acceptline:${alcontext}" actions subs
 879
 880     (( ${#subs} < 1 )) && return 0
 881
 882     (( aldone = 0 ))
 883     for sub in ${subs} ; do
 884         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 885         zle ${sub}
 886
 887         (( aldone > 0 )) && break
 888     done
 889 }
 890
 891 function Accept-Line-getdefault() {
 892     emulate -L zsh
 893     local default_action
 894
 895     zstyle -s ":acceptline:${alcontext}" default_action default_action
 896     case ${default_action} in
 897         ((accept-line|))
 898             printf ".accept-line"
 899             ;;
 900         (*)
 901             printf ${default_action}
 902             ;;
 903     esac
 904 }
 905
 906 function Accept-Line-HandleContext() {
 907     zle Accept-Line
 908
 909     default_action=$(Accept-Line-getdefault)
 910     zstyle -T ":acceptline:${alcontext}" call_default \
 911         && zle ${default_action}
 912 }
 913
 914 function accept-line() {
 915     setopt localoptions noksharrays
 916     local -ax cmdline
 917     local -x alcontext
 918     local buf com fname format msg default_action
 919
 920     alcontext='default'
 921     buf="${BUFFER}"
 922     cmdline=(${(z)BUFFER})
 923     com="${cmdline[1]}"
 924     fname="_${com}"
 925
 926     Accept-Line 'preprocess'
 927
 928     zstyle -t ":acceptline:${alcontext}" rehash \
 929         && [[ -z ${commands[$com]} ]]           \
 930         && rehash
 931
 932     if    [[ -n ${com}               ]] \
 933        && [[ -n ${reswords[(r)$com]} ]] \
 934        || [[ -n ${aliases[$com]}     ]] \
 935        || [[ -n ${functions[$com]}   ]] \
 936        || [[ -n ${builtins[$com]}    ]] \
 937        || [[ -n ${commands[$com]}    ]] ; then
 938
 939         # there is something sensible to execute, just do it.
 940         alcontext='normal'
 941         Accept-Line-HandleContext
 942
 943         return
 944     fi
 945
 946     if    [[ -o correct              ]] \
 947        || [[ -o correctall           ]] \
 948        && [[ -n ${functions[$fname]} ]] ; then
 949
 950         # nothing there to execute but there is a function called
 951         # _command_name; a completion widget. Makes no sense to
 952         # call it on the commandline, but the correct{,all} options
 953         # will ask for it nevertheless, so warn the user.
 954         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 955             # Okay, we warned the user before, he called us again,
 956             # so have it his way.
 957             alcontext='force'
 958             Accept-Line-HandleContext
 959
 960             return
 961         fi
 962
 963         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 964             alcontext='normal'
 965             Accept-Line-HandleContext
 966         else
 967             # prepare warning message for the user, configurable via zstyle.
 968             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 969
 970             if [[ -z ${msg} ]] ; then
 971                 msg="%c will not execute and completion %f exists."
 972             fi
 973
 974             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 975
 976             zle -M -- "${msg}"
 977         fi
 978         return
 979     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 980         # If we are here, the commandline contains something that is not
 981         # executable, which is neither subject to _command_name correction
 982         # and is not empty. might be a variable assignment
 983         alcontext='misc'
 984         Accept-Line-HandleContext
 985
 986         return
 987     fi
 988
 989     # If we got this far, the commandline only contains whitespace, or is empty.
 990     alcontext='empty'
 991     Accept-Line-HandleContext
 992 }
 993
 994 zle -N accept-line
 995 zle -N Accept-Line
 996 zle -N Accept-Line-HandleContext
 997
 998 # power completion - abbreviation expansion
 999 # power completion / abbreviation expansion / buffer expansion
1000 # see http://zshwiki.org/home/examples/zleiab for details
1001 # less risky than the global aliases but powerful as well
1002 # just type the abbreviation key and afterwards ',.' to expand it
1003 declare -A abk
1004 setopt extendedglob
1005 setopt interactivecomments
1006 abk=(
1007 #   key   # value                  (#d additional doc string)
1008 #A# start
1009     '...'  '../..'
1010     '....' '../../..'
1011     'BG'   '& exit'
1012     'C'    '| wc -l'
1013     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
1014     'H'    '| head'
1015     'Hl'   ' --help |& less -r'    #d (Display help in pager)
1016     'L'    '| less'
1017     'LL'   '|& less -r'
1018     'M'    '| most'
1019     'N'    '&>/dev/null'           #d (No Output)
1020     'R'    '| tr A-z N-za-m'       #d (ROT13)
1021     'SL'   '| sort | less'
1022     'S'    '| sort -u'
1023     'T'    '| tail'
1024     'V'    '|& vim -'
1025 #A# end
1026     'co'   './configure && make && sudo make install'
1027 )
1028
1029 zleiab() {
1030     emulate -L zsh
1031     setopt extendedglob
1032     local MATCH
1033
1034     if (( NOABBREVIATION > 0 )) ; then
1035         LBUFFER="${LBUFFER},."
1036         return 0
1037     fi
1038
1039     LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
1040     LBUFFER+=${abk[$MATCH]:-$MATCH}
1041 }
1042
1043 zle -N zleiab
1044
1045 help-show-abk()
1046 {
1047   zle -M "$(print "Type ,. after these abbreviations to expand them:"; print -a -C 2 ${(kv)abk})"
1048 }
1049
1050 zle -N help-show-abk
1051
1052 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1053 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1054 zle -N insert-datestamp
1055
1056 # press esc-m for inserting last typed word again (thanks to caphuso!)
1057 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1058 zle -N insert-last-typed-word;
1059
1060 function grml-zsh-fg() {
1061   if (( ${#jobstates} )); then
1062     zle .push-input
1063     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1064     BUFFER="${BUFFER}fg"
1065     zle .accept-line
1066   else
1067     zle -M 'No background jobs. Doing nothing.'
1068   fi
1069 }
1070 zle -N grml-zsh-fg
1071
1072 # run command line as user root via sudo:
1073 sudo-command-line() {
1074     [[ -z $BUFFER ]] && zle up-history
1075     if [[ $BUFFER != sudo\ * ]]; then
1076         BUFFER="sudo $BUFFER"
1077         CURSOR=$(( CURSOR+5 ))
1078     fi
1079 }
1080 zle -N sudo-command-line
1081
1082 ### jump behind the first word on the cmdline.
1083 ### useful to add options.
1084 function jump_after_first_word() {
1085     local words
1086     words=(${(z)BUFFER})
1087
1088     if (( ${#words} <= 1 )) ; then
1089         CURSOR=${#BUFFER}
1090     else
1091         CURSOR=${#${words[1]}}
1092     fi
1093 }
1094 zle -N jump_after_first_word
1095
1096 #f5# Create directory under cursor or the selected area
1097 inplaceMkDirs() {
1098     # Press ctrl-xM to create the directory under the cursor or the selected area.
1099     # To select an area press ctrl-@ or ctrl-space and use the cursor.
1100     # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
1101     # directory does not exist yet -> press ctrl-XM and problem solved
1102     local PATHTOMKDIR
1103     if ((REGION_ACTIVE==1)); then
1104         local F=$MARK T=$CURSOR
1105         if [[ $F -gt $T ]]; then
1106             F=${CURSOR}
1107             T=${MARK}
1108         fi
1109         # get marked area from buffer and eliminate whitespace
1110         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
1111         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
1112     else
1113         local bufwords iword
1114         bufwords=(${(z)LBUFFER})
1115         iword=${#bufwords}
1116         bufwords=(${(z)BUFFER})
1117         PATHTOMKDIR="${(Q)bufwords[iword]}"
1118     fi
1119     [[ -z "${PATHTOMKDIR}" ]] && return 1
1120     PATHTOMKDIR=${~PATHTOMKDIR}
1121     if [[ -e "${PATHTOMKDIR}" ]]; then
1122         zle -M " path already exists, doing nothing"
1123     else
1124         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
1125         zle end-of-line
1126     fi
1127 }
1128
1129 #k# mkdir -p <dir> from string under cursor or marked area
1130 zle -N inplaceMkDirs
1131
1132 #v1# set number of lines to display per page
1133 HELP_LINES_PER_PAGE=20
1134 #v1# set location of help-zle cache file
1135 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
1136 # helper function for help-zle, actually generates the help text
1137 help_zle_parse_keybindings()
1138 {
1139     emulate -L zsh
1140     setopt extendedglob
1141     unsetopt ksharrays  #indexing starts at 1
1142
1143     #v1# choose files that help-zle will parse for keybindings
1144     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
1145
1146     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
1147         local load_cache=0
1148         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
1149         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
1150     fi
1151
1152     #fill with default keybindings, possibly to be overwriten in a file later
1153     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
1154     local -A help_zle_keybindings
1155     help_zle_keybindings['<Ctrl>@']="set MARK"
1156     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
1157     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
1158     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
1159     help_zle_keybindings['<Ctrl>_']="undo"
1160     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
1161     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
1162     help_zle_keybindings['<Ctrl>e']="goto end of line"
1163     help_zle_keybindings['<Ctrl>t']="transpose charaters"
1164     help_zle_keybindings['<Alt>t']="transpose words"
1165     help_zle_keybindings['<Alt>s']="spellcheck word"
1166     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
1167     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
1168     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
1169     help_zle_keybindings["<Alt>'"]="quote line"
1170     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
1171     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
1172     help_zle_keybindings['<Alt>u']="make next word Uppercase"
1173     help_zle_keybindings['<Alt>l']="make next word lowercase"
1174     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
1175     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
1176     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
1177     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
1178     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
1179     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
1180     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
1181     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
1182     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
1183
1184     #init global variables
1185     unset help_zle_lines help_zle_sln
1186     typeset -g -a help_zle_lines
1187     typeset -g help_zle_sln=1
1188
1189     local k v
1190     local lastkeybind_desc contents     #last description starting with #k# that we found
1191     local num_lines_elapsed=0            #number of lines between last description and keybinding
1192     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
1193     for f in $HELPZLE_KEYBINDING_FILES; do
1194         [[ -r "$f" ]] || continue   #not readable ? skip it
1195         contents="$(<$f)"
1196         for cline in "${(f)contents}"; do
1197             #zsh pattern: matches lines like: #k# ..............
1198             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
1199                 lastkeybind_desc="$match[*]"
1200                 num_lines_elapsed=0
1201             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
1202             #             ignores lines that are commentend out
1203             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
1204             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
1205                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
1206                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
1207                     #substitute keybinding string with something readable
1208                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
1209                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
1210                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
1211                     help_zle_keybindings[${k}]=$lastkeybind_desc
1212                 fi
1213                 lastkeybind_desc=""
1214             else
1215               ((num_lines_elapsed++))
1216             fi
1217         done
1218     done
1219     unset contents
1220     #calculate length of keybinding column
1221     local kstrlen=0
1222     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
1223     #convert the assoc array into preformated lines, which we are able to sort
1224     for k v in ${(kv)help_zle_keybindings[@]}; do
1225         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
1226         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
1227     done
1228     #sort lines alphabetically
1229     help_zle_lines=("${(i)help_zle_lines[@]}")
1230     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
1231     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
1232     zcompile $HELP_ZLE_CACHE_FILE
1233 }
1234 typeset -g help_zle_sln
1235 typeset -g -a help_zle_lines
1236
1237 # Provides (partially autogenerated) help on keybindings and the zsh line editor
1238 help-zle()
1239 {
1240     emulate -L zsh
1241     unsetopt ksharrays  #indexing starts at 1
1242     #help lines already generated ? no ? then do it
1243     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
1244     #already displayed all lines ? go back to the start
1245     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
1246     local sln=$help_zle_sln
1247     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
1248     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
1249     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
1250 }
1251 zle -N help-zle
1252
1253 ## complete word from currently visible Screen or Tmux buffer.
1254 if check_com -c screen || check_com -c tmux; then
1255     _complete_screen_display() {
1256         [[ "$TERM" != "screen" ]] && return 1
1257
1258         local TMPFILE=$(mktemp)
1259         local -U -a _screen_display_wordlist
1260         trap "rm -f $TMPFILE" EXIT
1261
1262         # fill array with contents from screen hardcopy
1263         if ((${+TMUX})); then
1264             #works, but crashes tmux below version 1.4
1265             #luckily tmux -V option to ask for version, was also added in 1.4
1266             tmux -V &>/dev/null || return
1267             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1268         else
1269             screen -X hardcopy $TMPFILE
1270             # screen sucks, it dumps in latin1, apparently always. so recode it
1271             # to system charset
1272             check_com recode && recode latin1 $TMPFILE
1273         fi
1274         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1275         # remove PREFIX to be completed from that array
1276         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1277         compadd -a _screen_display_wordlist
1278     }
1279     #m# k CTRL-x\,\,\,S Complete word from GNU screen buffer
1280     bindkey -r "^xS"
1281     compdef -k _complete_screen_display complete-word '^xS'
1282 fi
1283
1284 # Load a few more functions and tie them to widgets, so they can be bound:
1285
1286 function zrcautozle() {
1287     emulate -L zsh
1288     local fnc=$1
1289     zrcautoload $fnc && zle -N $fnc
1290 }
1291
1292 function zrcgotwidget() {
1293     (( ${+widgets[$i]} ))
1294 }
1295
1296 function zrcgotkeymap() {
1297     [[ -n ${(M)keymaps:#$1} ]]
1298 }
1299
1300 zrcautozle insert-files
1301 zrcautozle edit-command-line
1302 zrcautozle insert-unicode-char
1303 if zrcautoload history-search-end; then
1304     zle -N history-beginning-search-backward-end history-search-end
1305     zle -N history-beginning-search-forward-end  history-search-end
1306 fi
1307 zle -C hist-complete complete-word _generic
1308 zstyle ':completion:hist-complete:*' completer _history
1309
1310 # The actual terminal setup hooks and bindkey-calls:
1311
1312 # An array to note missing features to ease diagnosis in case of problems.
1313 typeset -ga grml_missing_features
1314
1315 function zrcbindkey() {
1316     if (( ARGC && ${+widgets[${argv[-1]}]} )); then
1317         bindkey "$@"
1318     fi
1319 }
1320
1321 function bind2maps () {
1322     local i sequence widget
1323     local -a maps
1324
1325     while [[ "$1" != "--" ]]; do
1326         maps+=( "$1" )
1327         shift
1328     done
1329     shift
1330
1331     sequence="${key[$1]}"
1332     widget="$2"
1333
1334     [[ -z "$sequence" ]] && return 1
1335
1336     for i in "${maps[@]}"; do
1337         zrcbindkey -M "$i" "$sequence" "$widget"
1338     done
1339 }
1340
1341 if (( ${+terminfo[smkx]} )) && (( ${+terminfo[rmkx]} )); then
1342     function zle-smkx () {
1343         printf '%s' ${terminfo[smkx]}
1344     }
1345     function zle-rmkx () {
1346         printf '%s' ${terminfo[rmkx]}
1347     }
1348     function zle-line-init () {
1349         zle-smkx
1350     }
1351     function zle-line-finish () {
1352         zle-rmkx
1353     }
1354     zle -N zle-line-init
1355     zle -N zle-line-finish
1356 else
1357     for i in {s,r}mkx; do
1358         (( ${+terminfo[$i]} )) || grml_missing_features+=($i)
1359     done
1360     unset i
1361 fi
1362
1363 typeset -A key
1364 key=(
1365     Home     "${terminfo[khome]}"
1366     End      "${terminfo[kend]}"
1367     Insert   "${terminfo[kich1]}"
1368     Delete   "${terminfo[kdch1]}"
1369     Up       "${terminfo[kcuu1]}"
1370     Down     "${terminfo[kcud1]}"
1371     Left     "${terminfo[kcub1]}"
1372     Right    "${terminfo[kcuf1]}"
1373     PageUp   "${terminfo[kpp]}"
1374     PageDown "${terminfo[knp]}"
1375     BackTab  "${terminfo[kcbt]}"
1376 )
1377
1378 bind2maps emacs             -- Home   beginning-of-somewhere
1379 bind2maps       viins vicmd -- Home   vi-beginning-of-line
1380 bind2maps emacs             -- End    end-of-somewhere
1381 bind2maps       viins vicmd -- End    vi-end-of-line
1382 bind2maps emacs viins       -- Insert overwrite-mode
1383 bind2maps             vicmd -- Insert vi-insert
1384 bind2maps emacs             -- Delete delete-char
1385 bind2maps       viins vicmd -- Delete vi-delete-char
1386 bind2maps emacs viins vicmd -- Up     up-line-or-search
1387 bind2maps emacs viins vicmd -- Down   down-line-or-search
1388 bind2maps emacs             -- Left   backward-char
1389 bind2maps       viins vicmd -- Left   vi-backward-char
1390 bind2maps emacs             -- Right  forward-char
1391 bind2maps       viins vicmd -- Right  vi-forward-char
1392 bind2maps       viins vicmd -- Right  vi-forward-char
1393
1394 if zrcgotkeymap menuselect; then
1395     bind2maps menuselect -- BackTab reverse-menu-complete
1396
1397     #k# menu selection: pick item but stay in the menu
1398     zrcbindkey -M menuselect '\e^M' accept-and-menu-complete
1399     # also use + and INSERT since it's easier to press repeatedly
1400     zrcbindkey -M menuselect "+" accept-and-menu-complete
1401     zrcbindkey -M menuselect "^[[2~" accept-and-menu-complete
1402
1403     # accept a completion and try to complete again by using menu
1404     # completion; very useful with completing directories
1405     # by using 'undo' one's got a simple file browser
1406     zrcbindkey -M menuselect '^o' accept-and-infer-next-history
1407 fi
1408
1409 #k# Display list of abbreviations that expand when followed by ,.
1410 zrcbindkey ",." zleiab
1411 zrcbindkey '^xb' help-show-abk
1412 zrcbindkey '^xM' inplaceMkDirs
1413 #k# display help for keybindings and ZLE
1414 zrcbindkey '^xz' help-zle
1415
1416 #k# Insert files and test globbing
1417 zrcbindkey "^xf" insert-files # C-x-f
1418
1419 #k# Edit the current line in \kbd{\$EDITOR}
1420 zrcbindkey '\ee' edit-command-line
1421
1422 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
1423 zrcbindkey "\e[5C" forward-word
1424 zrcbindkey "\e[5D" backward-word
1425 zrcbindkey "\e[1;5C" forward-word
1426 zrcbindkey "\e[1;5D" backward-word
1427 ## the same for alt-left-arrow and alt-right-arrow
1428 zrcbindkey '^[[1;3C' forward-word
1429 zrcbindkey '^[[1;3D' backward-word
1430
1431 #k# search history backward for entry beginning with typed text
1432 zrcbindkey '^xp'   history-beginning-search-backward-end
1433 #k# search history forward for entry beginning with typed text
1434 zrcbindkey '^xP'   history-beginning-search-forward-end
1435 #k# search history backward for entry beginning with typed text
1436 zrcbindkey "\e[5~" history-beginning-search-backward-end # PageUp
1437 #k# search history forward for entry beginning with typed text
1438 zrcbindkey "\e[6~" history-beginning-search-forward-end  # PageDown
1439
1440 # insert unicode character
1441 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
1442 # See for example http://unicode.org/charts/ for unicode characters code
1443 #k# Insert Unicode character
1444 zrcbindkey '^xi' insert-unicode-char
1445
1446 #m# k Shift-tab Perform backwards menu completion
1447 if [[ -n "$terminfo[kcbt]" ]]; then
1448     zrcbindkey "$terminfo[kcbt]" reverse-menu-complete
1449 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
1450     zrcbindkey "$terminfo[cbt]"  reverse-menu-complete
1451 fi
1452
1453 #k# Toggle abbreviation expansion on/off
1454 zrcbindkey '^xA' grml_toggle_abbrev
1455 zrcbindkey "^x^h" commit-to-history
1456
1457 #k# Kill left-side word or everything up to next slash
1458 zrcbindkey '\ev' slash-backward-kill-word
1459 #k# Kill left-side word or everything up to next slash
1460 zrcbindkey '\e^h' slash-backward-kill-word
1461 #k# Kill left-side word or everything up to next slash
1462 zrcbindkey '\e^?' slash-backward-kill-word
1463
1464 # use the new *-pattern-* widgets for incremental history search
1465 if zrcgotwidget history-incremental-pattern-search-backward; then
1466     zrcbindkey '^r' history-incremental-pattern-search-backward
1467     zrcbindkey '^s' history-incremental-pattern-search-forward
1468 fi
1469
1470 # Do history expansion on space:
1471 zrcbindkey ' ' magic-space
1472 #k# Trigger menu-complete
1473 zrcbindkey '\ei' menu-complete  # menu completion via esc-i
1474 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1475 zrcbindkey '^ed' insert-datestamp
1476 #k# Insert last typed word
1477 zrcbindkey "\em" insert-last-typed-word
1478 #k# A smart shortcut for \kbd{fg<enter>}
1479 zrcbindkey '^z' grml-zsh-fg
1480 #k# prepend the current command with "sudo"
1481 zrcbindkey "^os" sudo-command-line
1482 #k# jump to after first word (for adding options)
1483 zrcbindkey '^x1' jump_after_first_word
1484 #k# complete word from history with menu
1485 zrcbindkey "^x^x" hist-complete
1486
1487 # autoloading
1488
1489 zrcautoload zmv
1490 zrcautoload zed
1491
1492 # we don't want to quote/espace URLs on our own...
1493 # if autoload -U url-quote-magic ; then
1494 #    zle -N self-insert url-quote-magic
1495 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
1496 # else
1497 #    print 'Notice: no url-quote-magic available :('
1498 # fi
1499 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
1500
1501 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
1502 alias run-help >&/dev/null && unalias run-help
1503 for rh in run-help{,-git,-svk,-svn}; do
1504     zrcautoload $rh
1505 done; unset rh
1506
1507 # command not found handling
1508
1509 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1510 function command_not_found_handler() {
1511     emulate -L zsh
1512     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1513         ${GRML_ZSH_CNF_HANDLER} $1
1514     fi
1515     return 1
1516 }
1517
1518 # history
1519
1520 ZSHDIR=${ZDOTDIR:-${HOME}/.zsh}
1521
1522 #v#
1523 HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1524 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1525 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1526
1527 # dirstack handling
1528
1529 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1530 DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1531
1532 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1533     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1534     # "cd -" won't work after login by just setting $OLDPWD, so
1535     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1536 fi
1537
1538 chpwd() {
1539     local -ax my_stack
1540     my_stack=( ${PWD} ${dirstack} )
1541     if is42 ; then
1542         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1543     else
1544         uprint my_stack >! ${DIRSTACKFILE}
1545     fi
1546 }
1547
1548 # directory based profiles
1549
1550 if is433 ; then
1551
1552 # chpwd_profiles(): Directory Profiles, Quickstart:
1553 #
1554 # In .zshrc.local:
1555 #
1556 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1557 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1558 #   chpwd_profiles
1559 #
1560 # For details see the `grmlzshrc.5' manual page.
1561 function chpwd_profiles() {
1562     local profile context
1563     local -i reexecute
1564
1565     context=":chpwd:profiles:$PWD"
1566     zstyle -s "$context" profile profile || profile='default'
1567     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1568
1569     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1570         typeset -g CHPWD_PROFILE
1571         local CHPWD_PROFILES_INIT=1
1572         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1573     elif [[ $profile != $CHPWD_PROFILE ]]; then
1574         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1575             && chpwd_leave_profile_${CHPWD_PROFILE}
1576     fi
1577     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1578         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1579     fi
1580
1581     CHPWD_PROFILE="${profile}"
1582     return 0
1583 }
1584
1585 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1586
1587 fi # is433
1588
1589 # Prompt setup for grml:
1590
1591 # set colors for use in prompts (modern zshs allow for the use of %F{red}foo%f
1592 # in prompts to get a red "foo" embedded, but it's good to keep these for
1593 # backwards compatibility).
1594 if zrcautoload colors && colors 2>/dev/null ; then
1595     BLUE="%{${fg[blue]}%}"
1596     RED="%{${fg_bold[red]}%}"
1597     GREEN="%{${fg[green]}%}"
1598     CYAN="%{${fg[cyan]}%}"
1599     MAGENTA="%{${fg[magenta]}%}"
1600     YELLOW="%{${fg[yellow]}%}"
1601     WHITE="%{${fg[white]}%}"
1602     NO_COLOR="%{${reset_color}%}"
1603 else
1604     BLUE=$'%{\e[1;34m%}'
1605     RED=$'%{\e[1;31m%}'
1606     GREEN=$'%{\e[1;32m%}'
1607     CYAN=$'%{\e[1;36m%}'
1608     WHITE=$'%{\e[1;37m%}'
1609     MAGENTA=$'%{\e[1;35m%}'
1610     YELLOW=$'%{\e[1;33m%}'
1611     NO_COLOR=$'%{\e[0m%}'
1612 fi
1613
1614 # First, the easy ones: PS2..4:
1615
1616 # secondary prompt, printed when the shell needs more information to complete a
1617 # command.
1618 PS2='\`%_> '
1619 # selection prompt used within a select loop.
1620 PS3='?# '
1621 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1622 PS4='+%N:%i:%_> '
1623
1624 # Some additional features to use with our prompt:
1625 #
1626 #    - battery status
1627 #    - debian_chroot
1628 #    - vcs_info setup and version specific fixes
1629
1630 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1631 if [[ $BATTERY -gt 0 ]] ; then
1632     if ! check_com -c acpi ; then
1633         BATTERY=0
1634     fi
1635 fi
1636
1637 battery() {
1638 if [[ $BATTERY -gt 0 ]] ; then
1639     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1640     if [[ -z "$PERCENT" ]] ; then
1641         PERCENT='acpi not present'
1642     else
1643         if [[ "$PERCENT" -lt 20 ]] ; then
1644             PERCENT="warning: ${PERCENT}%%"
1645         else
1646             PERCENT="${PERCENT}%%"
1647         fi
1648     fi
1649 fi
1650 }
1651
1652 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1653 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1654     debian_chroot=$(</etc/debian_chroot)
1655 fi
1656
1657 # gather version control information for inclusion in a prompt
1658
1659 if zrcautoload vcs_info; then
1660     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1661     # function, which can cause a lot of trouble with our directory-based
1662     # profiles. So:
1663     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1664         function VCS_INFO_realpath () {
1665             setopt localoptions NO_shwordsplit chaselinks
1666             ( builtin cd -q $1 2> /dev/null && pwd; )
1667         }
1668     fi
1669
1670     zstyle ':vcs_info:*' max-exports 2
1671
1672     if [[ -o restricted ]]; then
1673         zstyle ':vcs_info:*' enable NONE
1674     fi
1675 fi
1676
1677 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1678 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1679 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1680 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1681 #       to $vcs_info_msg_N_ as soon as we use the included version.
1682 if [[ "$TERM" == dumb ]] ; then
1683     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1684     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1685 else
1686     # these are the same, just with a lot of colors:
1687     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} " \
1688                                        "zsh: %r"
1689     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR}%} " \
1690                                        "zsh: %r"
1691     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1692 fi
1693
1694 # Now for the fun part: The grml prompt themes in `promptsys' mode of operation
1695
1696 # This actually defines three prompts:
1697 #
1698 #    - grml
1699 #    - grml-large
1700 #    - grml-chroot
1701 #
1702 # They all share the same code and only differ with respect to which items they
1703 # contain. The main source of documentation is the `prompt_grml_help' function
1704 # below, which gets called when the user does this: prompt -h grml
1705
1706 function prompt_grml_help () {
1707     cat <<__EOF0__
1708   prompt grml
1709
1710     This is the prompt as used by the grml-live system <http://grml.org>. It is
1711     a rather simple one-line prompt, that by default looks something like this:
1712
1713         <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1714
1715     The prompt itself integrates with zsh's prompt themes system (as you are
1716     witnessing right now) and is configurable to a certain degree. In
1717     particular, these aspects are customisable:
1718
1719         - The items used in the prompt (e.g. you can remove \`user' from
1720           the list of activated items, which will cause the user name to
1721           be omitted from the prompt string).
1722
1723         - The attributes used with the items are customisable via strings
1724           used before and after the actual item.
1725
1726     The available items are: at, battery, change-root, date, grml-chroot,
1727     history, host, jobs, newline, path, percent, rc, rc-always, sad-smiley,
1728     shell-level, time, user, vcs
1729
1730     The actual configuration is done via zsh's \`zstyle' mechanism. The
1731     context, that is used while looking up styles is:
1732
1733         ':prompt:grml:<left-or-right>:<subcontext>'
1734
1735     Here <left-or-right> is either \`left' or \`right', signifying whether the
1736     style should affect the left or the right prompt. <subcontext> is either
1737     \`setup' or 'items:<item>', where \`<item>' is one of the available items.
1738
1739     The styles:
1740
1741         - use-rprompt (boolean): If \`true' (the default), print a sad smiley
1742           in $RPROMPT if the last command a returned non-successful error code.
1743           (This in only valid if <left-or-right> is "right"; ignored otherwise)
1744
1745         - items (list): The list of items used in the prompt. If \`vcs' is
1746           present in the list, the theme's code invokes \`vcs_info'
1747           accordingly. Default (left): rc change-root user at host path vcs
1748           percent; Default (right): sad-smiley
1749
1750     Available styles in 'items:<item>' are: pre, post. These are strings that
1751     are inserted before (pre) and after (post) the item in question. Thus, the
1752     following would cause the user name to be printed in red instead of the
1753     default blue:
1754
1755         zstyle ':prompt:grml:*:items:user' pre '%F{red}'
1756
1757     Note, that the \`post' style may remain at its default value, because its
1758     default value is '%f', which turns the foreground text attribute off (which
1759     is exactly, what is still required with the new \`pre' value).
1760 __EOF0__
1761 }
1762
1763 function prompt_grml-chroot_help () {
1764     cat <<__EOF0__
1765   prompt grml-chroot
1766
1767     This is a variation of the grml prompt, see: prompt -h grml
1768
1769     The main difference is the default value of the \`items' style. The rest
1770     behaves exactly the same. Here are the defaults for \`grml-chroot':
1771
1772         - left: grml-chroot user at host path percent
1773         - right: (empty list)
1774 __EOF0__
1775 }
1776
1777 function prompt_grml-large_help () {
1778     cat <<__EOF0__
1779   prompt grml-large
1780
1781     This is a variation of the grml prompt, see: prompt -h grml
1782
1783     The main difference is the default value of the \`items' style. In
1784     particular, this theme uses _two_ lines instead of one with the plain
1785     \`grml' theme. The rest behaves exactly the same. Here are the defaults
1786     for \`grml-large':
1787
1788         - left: rc jobs history shell-level change-root time date newline user
1789                 at host path vcs percent
1790         - right: sad-smiley
1791 __EOF0__
1792 }
1793
1794 function grml_prompt_setup () {
1795     emulate -L zsh
1796     autoload -Uz vcs_info
1797     autoload -Uz add-zsh-hook
1798     add-zsh-hook precmd prompt_$1_precmd
1799 }
1800
1801 function prompt_grml_setup () {
1802     grml_prompt_setup grml
1803 }
1804
1805 function prompt_grml-chroot_setup () {
1806     grml_prompt_setup grml-chroot
1807 }
1808
1809 function prompt_grml-large_setup () {
1810     grml_prompt_setup grml-large
1811 }
1812
1813 # These maps define default tokens and pre-/post-decoration for items to be
1814 # used within the themes. All defaults may be customised in a context sensitive
1815 # matter by using zsh's `zstyle' mechanism.
1816 typeset -gA grml_prompt_pre_default \
1817             grml_prompt_post_default \
1818             grml_prompt_token_default \
1819             grml_prompt_token_function
1820
1821 grml_prompt_pre_default=(
1822     at                ''
1823     battery           ' '
1824     change-root       ''
1825     date              '%F{blue}'
1826     grml-chroot       '%F{red}'
1827     history           '%F{green}'
1828     host              ''
1829     jobs              '%F{cyan}'
1830     newline           ''
1831     path              '%B'
1832     percent           ''
1833     rc                '%F{red}'
1834     rc-always         ''
1835     sad-smiley        ''
1836     shell-level       '%F{red}'
1837     time              '%F{blue}'
1838     user              '%B%F{blue}'
1839     vcs               ''
1840 )
1841
1842 grml_prompt_post_default=(
1843     at                ''
1844     battery           ''
1845     change-root       ''
1846     date              '%f'
1847     grml-chroot       '%f '
1848     history           '%f'
1849     host              ''
1850     jobs              '%f'
1851     newline           ''
1852     path              '%b'
1853     percent           ''
1854     rc                '%f'
1855     rc-always         ''
1856     sad-smiley        ''
1857     shell-level       '%f'
1858     time              '%f'
1859     user              '%f%b'
1860     vcs               ''
1861 )
1862
1863 grml_prompt_token_default=(
1864     at                '@'
1865     battery           'PERCENT'
1866     change-root       'debian_chroot'
1867     date              '%D{%Y-%m-%d}'
1868     grml-chroot       'GRML_CHROOT'
1869     history           '{history#%!} '
1870     host              '%m '
1871     jobs              '[%j running job(s)] '
1872     newline           $'\n'
1873     path              '%40<..<%~%<< '
1874     percent           '%# '
1875     rc                '%(?..%? )'
1876     rc-always         '%?'
1877     sad-smiley        '%(?..:()'
1878     shell-level       '%(3L.+ .)'
1879     time              '%D{%H:%M:%S} '
1880     user              '%n'
1881     vcs               '0'
1882 )
1883
1884 function GRML_theme_add_token_usage () {
1885     cat <<__EOF__
1886   Usage: grml_theme_add_token <name> [-f|-i] <token/function> [<pre> <post>]
1887
1888     <name> is the name for the newly added token. If the \`-f' or \`-i' options
1889     are used, <token/function> is the name of the function (see below for
1890     details). Otherwise it is the literal token string to be used. <pre> and
1891     <post> are optional.
1892
1893   Options:
1894
1895     -f <function>   Use a function named \`<function>' each time the token
1896                     is to be expanded.
1897
1898     -i <function>   Use a function named \`<function>' to initialise the
1899                     value of the token _once_ at runtime.
1900
1901     The functions are called with one argument: the token's new name. The
1902     return value is expected in the \$REPLY parameter. The use of these
1903     options is mutually exclusive.
1904
1905   Example:
1906
1907     To add a new token \`day' that expands to the current weekday in the
1908     current locale in green foreground colour, use this:
1909
1910       grml_theme_add_token day '%D{%A}' '%F{green}' '%f'
1911
1912     Another example would be support for \$VIRTUAL_ENV:
1913
1914       function virtual_env_prompt () {
1915         REPLY=\${VIRTUAL_ENV+\${VIRTUAL_ENV:t} }
1916       }
1917       grml_theme_add_token virtual-env -f virtual_env_prompt
1918
1919     After that, you will be able to use a changed \`items' style to
1920     assemble your prompt.
1921 __EOF__
1922 }
1923
1924 function grml_theme_add_token () {
1925     emulate -L zsh
1926     local name token pre post
1927     local -i init funcall
1928
1929     if (( ARGC == 0 )); then
1930         GRML_theme_add_token_usage
1931         return 0
1932     fi
1933
1934     init=0
1935     funcall=0
1936     pre=''
1937     post=''
1938     name=$1
1939     shift
1940     if [[ $1 == '-f' ]]; then
1941         funcall=1
1942         shift
1943     elif [[ $1 == '-i' ]]; then
1944         init=1
1945         shift
1946     fi
1947
1948     if (( ARGC == 0 )); then
1949         printf '
1950 grml_theme_add_token: No token-string/function-name provided!\n\n'
1951         GRML_theme_add_token_usage
1952         return 1
1953     fi
1954     token=$1
1955     shift
1956     if (( ARGC != 0 && ARGC != 2 )); then
1957         printf '
1958 grml_theme_add_token: <pre> and <post> need to by specified _both_!\n\n'
1959         GRML_theme_add_token_usage
1960         return 1
1961     fi
1962     if (( ARGC )); then
1963         pre=$1
1964         post=$2
1965         shift 2
1966     fi
1967
1968     if (( ${+grml_prompt_token_default[$name]} )); then
1969         printf '
1970 grml_theme_add_token: Token `%s'\'' exists! Giving up!\n\n' $name
1971         GRML_theme_add_token_usage
1972         return 2
1973     fi
1974     if (( init )); then
1975         $token $name
1976         token=$REPLY
1977     fi
1978     grml_prompt_pre_default[$name]=$pre
1979     grml_prompt_post_default[$name]=$post
1980     if (( funcall )); then
1981         grml_prompt_token_function[$name]=$token
1982         grml_prompt_token_default[$name]=23
1983     else
1984         grml_prompt_token_default[$name]=$token
1985     fi
1986 }
1987
1988 function grml_typeset_and_wrap () {
1989     emulate -L zsh
1990     local target="$1"
1991     local new="$2"
1992     local left="$3"
1993     local right="$4"
1994
1995     if (( ${+parameters[$new]} )); then
1996         typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
1997     fi
1998 }
1999
2000 function grml_prompt_addto () {
2001     emulate -L zsh
2002     local target="$1"
2003     local lr it apre apost new v
2004     local -a items
2005     shift
2006
2007     [[ $target == PS1 ]] && lr=left || lr=right
2008     zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
2009     typeset -g "${target}="
2010     for it in "${items[@]}"; do
2011         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
2012             || apre=${grml_prompt_pre_default[$it]}
2013         zstyle -s ":prompt:grml:${grmltheme}:${lr}:$it" post apost \
2014             || apost=${grml_prompt_post_default[$it]}
2015         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
2016             || new=${grml_prompt_token_default[$it]}
2017         typeset -g "${target}=${(P)target}${apre}"
2018         if (( ${+grml_prompt_token_function[$it]} )); then
2019             ${grml_prompt_token_function[$it]} $it
2020             typeset -g "${target}=${(P)target}${REPLY}"
2021         else
2022             case $it in
2023             battery)
2024                 grml_typeset_and_wrap $target $new '' ''
2025                 ;;
2026             change-root)
2027                 grml_typeset_and_wrap $target $new '(' ')'
2028                 ;;
2029             grml-chroot)
2030                 if [[ -n ${(P)new} ]]; then
2031                     typeset -g "${target}=${(P)target}(CHROOT)"
2032                 fi
2033                 ;;
2034             vcs)
2035                 v="vcs_info_msg_${new}_"
2036                 if (( ! vcscalled )); then
2037                     vcs_info
2038                     vcscalled=1
2039                 fi
2040                 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
2041                     typeset -g "${target}=${(P)target}${(P)v}"
2042                 fi
2043                 ;;
2044             *) typeset -g "${target}=${(P)target}${new}" ;;
2045             esac
2046         fi
2047         typeset -g "${target}=${(P)target}${apost}"
2048     done
2049 }
2050
2051 function prompt_grml_precmd () {
2052     emulate -L zsh
2053     local grmltheme=grml
2054     local -a left_items right_items
2055     left_items=(rc change-root user at host path vcs percent)
2056     right_items=(sad-smiley)
2057
2058     prompt_grml_precmd_worker
2059 }
2060
2061 function prompt_grml-chroot_precmd () {
2062     emulate -L zsh
2063     local grmltheme=grml-chroot
2064     local -a left_items right_items
2065     left_items=(grml-chroot user at host path percent)
2066     right_items=()
2067
2068     prompt_grml_precmd_worker
2069 }
2070
2071 function prompt_grml-large_precmd () {
2072     emulate -L zsh
2073     local grmltheme=grml-large
2074     local -a left_items right_items
2075     left_items=(rc jobs history shell-level change-root time date newline
2076                 user at host path vcs percent)
2077     right_items=(sad-smiley)
2078
2079     prompt_grml_precmd_worker
2080 }
2081
2082 function prompt_grml_precmd_worker () {
2083     emulate -L zsh
2084     local -i vcscalled=0
2085
2086     grml_prompt_addto PS1 "${left_items[@]}"
2087     if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
2088         grml_prompt_addto RPS1 "${right_items[@]}"
2089     fi
2090 }
2091
2092 grml_prompt_fallback() {
2093     setopt prompt_subst
2094     precmd() {
2095         (( ${+functions[vcs_info]} )) && vcs_info
2096     }
2097
2098     p0="${RED}%(?..%? )${WHITE}${debian_chroot:+($debian_chroot)}"
2099     p1="${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "'${vcs_info_msg_0_}'"%# "
2100     if (( EUID == 0 )); then
2101         PROMPT="${BLUE}${p0}${RED}${p1}"
2102     else
2103         PROMPT="${RED}${p0}${BLUE}${p1}"
2104     fi
2105     unset p0 p1
2106 }
2107
2108 if zrcautoload promptinit && promptinit 2>/dev/null ; then
2109     # Since we define the required functions in here and not in files in
2110     # $fpath, we need to stick the theme's name into `$prompt_themes'
2111     # ourselves, since promptinit does not pick them up otherwise.
2112     prompt_themes+=( grml grml-chroot grml-large )
2113     # Also, keep the array sorted...
2114     prompt_themes=( "${(@on)prompt_themes}" )
2115 else
2116     print 'Notice: no promptinit available :('
2117     grml_prompt_fallback
2118 fi
2119
2120 if is437; then
2121     # The prompt themes use modern features of zsh, that require at least
2122     # version 4.3.7 of the shell. Use the fallback otherwise.
2123     if [[ $BATTERY -gt 0 ]]; then
2124         zstyle ':prompt:grml:right:setup' items sad-smiley battery
2125         add-zsh-hook precmd battery
2126     fi
2127     if [[ "$TERM" == dumb ]] ; then
2128         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" pre ''
2129         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" post ' '
2130         for i in rc user path jobs history date time shell-level; do
2131             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" pre ''
2132             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" post ''
2133         done
2134         unset i
2135         zstyle ':prompt:grml(|-large|-chroot):right:setup' use-rprompt false
2136     elif (( EUID == 0 )); then
2137         zstyle ':prompt:grml(|-large|-chroot):*:items:user' pre '%F{red}'
2138     fi
2139
2140     # Finally enable one of the prompts.
2141     if [[ -n $GRML_CHROOT ]]; then
2142         prompt grml-chroot
2143     elif [[ $GRMLPROMPT -gt 0 ]]; then
2144         prompt grml-large
2145     else
2146         prompt grml
2147     fi
2148 else
2149     grml_prompt_fallback
2150 fi
2151
2152 # Terminal-title wizardry
2153
2154 function ESC_print () {
2155     info_print $'\ek' $'\e\\' "$@"
2156 }
2157 function set_title () {
2158     info_print  $'\e]0;' $'\a' "$@"
2159 }
2160
2161 function info_print () {
2162     local esc_begin esc_end
2163     esc_begin="$1"
2164     esc_end="$2"
2165     shift 2
2166     printf '%s' ${esc_begin}
2167     printf '%s' "$*"
2168     printf '%s' "${esc_end}"
2169 }
2170
2171 function grml_reset_screen_title () {
2172     # adjust title of xterm
2173     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
2174     [[ ${NOTITLE:-} -gt 0 ]] && return 0
2175     case $TERM in
2176         (xterm*|rxvt*)
2177             set_title ${(%):-"%n@%m: %~"}
2178             ;;
2179     esac
2180 }
2181
2182 function grml_vcs_to_screen_title () {
2183     if [[ $TERM == screen* ]] ; then
2184         if [[ -n ${vcs_info_msg_1_} ]] ; then
2185             ESC_print ${vcs_info_msg_1_}
2186         else
2187             ESC_print "zsh"
2188         fi
2189     fi
2190 }
2191
2192 function grml_maintain_name () {
2193     # set hostname if not running on host with name 'grml'
2194     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
2195        NAME="@$HOSTNAME"
2196     fi
2197 }
2198
2199 function grml_cmd_to_screen_title () {
2200     # get the name of the program currently running and hostname of local
2201     # machine set screen window title if running in a screen
2202     if [[ "$TERM" == screen* ]] ; then
2203         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME"
2204         ESC_print ${CMD}
2205     fi
2206 }
2207
2208 function grml_control_xterm_title () {
2209     case $TERM in
2210         (xterm*|rxvt*)
2211             set_title "${(%):-"%n@%m:"}" "$1"
2212             ;;
2213     esac
2214 }
2215
2216 zrcautoload add-zsh-hook || add-zsh-hook () { :; }
2217 if [[ $NOPRECMD -eq 0 ]]; then
2218     add-zsh-hook precmd grml_reset_screen_title
2219     add-zsh-hook precmd grml_vcs_to_screen_title
2220     add-zsh-hook preexec grml_maintain_name
2221     add-zsh-hook preexec grml_cmd_to_screen_title
2222     if [[ $NOTITLE -eq 0 ]]; then
2223         add-zsh-hook preexec grml_control_xterm_title
2224     fi
2225 fi
2226
2227 # 'hash' some often used directories
2228 #d# start
2229 hash -d deb=/var/cache/apt/archives
2230 hash -d doc=/usr/share/doc
2231 hash -d linux=/lib/modules/$(command uname -r)/build/
2232 hash -d log=/var/log
2233 hash -d slog=/var/log/syslog
2234 hash -d src=/usr/src
2235 hash -d templ=/usr/share/doc/grml-templates
2236 hash -d tt=/usr/share/doc/texttools-doc
2237 hash -d www=/var/www
2238 #d# end
2239
2240 # some aliases
2241 if check_com -c screen ; then
2242     if [[ $UID -eq 0 ]] ; then
2243         if [[ -r /etc/grml/screenrc ]]; then
2244             alias screen="${commands[screen]} -c /etc/grml/screenrc"
2245         fi
2246     elif [[ -r $HOME/.screenrc ]] ; then
2247         alias screen="${commands[screen]} -c $HOME/.screenrc"
2248     else
2249         if [[ -r /etc/grml/screenrc_grml ]]; then
2250             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
2251         else
2252             if [[ -r /etc/grml/screenrc ]]; then
2253                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
2254             fi
2255         fi
2256     fi
2257 fi
2258
2259 # do we have GNU ls with color-support?
2260 if [[ "$TERM" != dumb ]]; then
2261     #a1# List files with colors (\kbd{ls -b -CF \ldots})
2262     alias ls='ls -b -CF '${ls_options:+"${ls_options[*]}"}
2263     #a1# List all files, with colors (\kbd{ls -la \ldots})
2264     alias la='ls -la '${ls_options:+"${ls_options[*]}"}
2265     #a1# List files with long colored list, without dotfiles (\kbd{ls -l \ldots})
2266     alias ll='ls -l '${ls_options:+"${ls_options[*]}"}
2267     #a1# List files with long colored list, human readable sizes (\kbd{ls -hAl \ldots})
2268     alias lh='ls -hAl '${ls_options:+"${ls_options[*]}"}
2269     #a1# List files with long colored list, append qualifier to filenames (\kbd{ls -lF \ldots})\\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2270     alias l='ls -lF '${ls_options:+"${ls_options[*]}"}
2271 else
2272     alias ls='ls -b -CF'
2273     alias la='ls -la'
2274     alias ll='ls -l'
2275     alias lh='ls -hAl'
2276     alias l='ls -lF'
2277 fi
2278
2279 alias mdstat='cat /proc/mdstat'
2280 alias ...='cd ../../'
2281
2282 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2283 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2284     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2285 fi
2286
2287 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2288 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2289 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2290
2291 # make sure it is not assigned yet
2292 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
2293 utf2iso() {
2294     if isutfenv ; then
2295         for ENV in $(env | command grep -i '.utf') ; do
2296             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2297         done
2298     fi
2299 }
2300
2301 # make sure it is not assigned yet
2302 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
2303 iso2utf() {
2304     if ! isutfenv ; then
2305         for ENV in $(env | command grep -i '\.iso') ; do
2306             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2307         done
2308     fi
2309 }
2310
2311 # especially for roadwarriors using GNU screen and ssh:
2312 if ! check_com asc &>/dev/null ; then
2313   asc() { autossh -t "$@" 'screen -RdU' }
2314   compdef asc=ssh
2315 fi
2316
2317 #f1# Hints for the use of zsh on grml
2318 zsh-help() {
2319     print "$bg[white]$fg[black]
2320 zsh-help - hints for use of zsh on grml
2321 =======================================$reset_color"
2322
2323     print '
2324 Main configuration of zsh happens in /etc/zsh/zshrc.
2325 That file is part of the package grml-etc-core, if you want to
2326 use them on a non-grml-system just get the tar.gz from
2327 http://deb.grml.org/ or (preferably) get it from the git repository:
2328
2329   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2330
2331 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2332 The file is still there, but it is empty for backwards compatibility.
2333
2334 For your own changes use these two files:
2335     $HOME/.zshrc.pre
2336     $HOME/.zshrc.local
2337
2338 The former is sourced very early in our zshrc, the latter is sourced
2339 very lately.
2340
2341 System wide configuration without touching configuration files of grml
2342 can take place in /etc/zsh/zshrc.local.
2343
2344 For information regarding zsh start at http://grml.org/zsh/
2345
2346 Take a look at grml'\''s zsh refcard:
2347 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2348
2349 Check out the main zsh refcard:
2350 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2351
2352 And of course visit the zsh-lovers:
2353 % man zsh-lovers
2354
2355 You can adjust some options through environment variables when
2356 invoking zsh without having to edit configuration files.
2357 Basically meant for bash users who are not used to the power of
2358 the zsh yet. :)
2359
2360   "NOCOR=1    zsh" => deactivate automatic correction
2361   "NOMENU=1   zsh" => do not use auto menu completion
2362                       (note: use ctrl-d for completion instead!)
2363   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2364   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2365                       preexec() and precmd() completely
2366   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
2367   "COMMAND_NOT_FOUND=1 zsh"
2368                    => Enable a handler if an external command was not found
2369                       The command called in the handler can be altered by setting
2370                       the GRML_ZSH_CNF_HANDLER variable, the default is:
2371                       "/usr/share/command-not-found/command-not-found"
2372
2373 A value greater than 0 is enables a feature; a value equal to zero
2374 disables it. If you like one or the other of these settings, you can
2375 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2376 zshrc.'
2377
2378     print "
2379 $bg[white]$fg[black]
2380 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2381 Enjoy your grml system with the zsh!$reset_color"
2382 }
2383
2384 # debian stuff
2385 if [[ -r /etc/debian_version ]] ; then
2386     #a3# Execute \kbd{apt-cache search}
2387     alias acs='apt-cache search'
2388     #a3# Execute \kbd{apt-cache show}
2389     alias acsh='apt-cache show'
2390     #a3# Execute \kbd{apt-cache policy}
2391     alias acp='apt-cache policy'
2392     #a3# Execute \kbd{apt-get dist-upgrade}
2393     salias adg="apt-get dist-upgrade"
2394     #a3# Execute \kbd{apt-get install}
2395     salias agi="apt-get install"
2396     #a3# Execute \kbd{aptitude install}
2397     salias ati="aptitude install"
2398     #a3# Execute \kbd{apt-get upgrade}
2399     salias ag="apt-get upgrade"
2400     #a3# Execute \kbd{apt-get update}
2401     salias au="apt-get update"
2402     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2403     salias -a up="aptitude update ; aptitude safe-upgrade"
2404     #a3# Execute \kbd{dpkg-buildpackage}
2405     alias dbp='dpkg-buildpackage'
2406     #a3# Execute \kbd{grep-excuses}
2407     alias ge='grep-excuses'
2408
2409     # get a root shell as normal user in live-cd mode:
2410     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2411        alias su="sudo su"
2412      fi
2413
2414     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2415     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2416     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2417     salias tlog="tail -f /var/log/syslog"    # follow the syslog
2418 fi
2419
2420 # sort installed Debian-packages by size
2421 if check_com -c dpkg-query ; then
2422     #a3# List installed Debian-packages sorted by size
2423     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
2424 fi
2425
2426 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2427 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
2428     if check_com -c wodim; then
2429         cdrecord() {
2430             cat <<EOMESS
2431 cdrecord is not provided under its original name by Debian anymore.
2432 See #377109 in the BTS of Debian for more details.
2433
2434 Please use the wodim binary instead
2435 EOMESS
2436             return 1
2437         }
2438     fi
2439 fi
2440
2441 # Use hard limits, except for a smaller stack and no core dumps
2442 unlimit
2443 is425 && limit stack 8192
2444 isgrmlcd && limit core 0 # important for a live-cd-system
2445 limit -s
2446
2447 # grmlstuff
2448 grmlstuff() {
2449 # people should use 'grml-x'!
2450     if check_com -c 915resolution; then
2451         855resolution() {
2452             echo "Please use 915resolution as resolution modifying tool for Intel \
2453 graphic chipset."
2454             return -1
2455         }
2456     fi
2457
2458     #a1# Output version of running grml
2459     alias grml-version='cat /etc/grml_version'
2460
2461     if check_com -c grml-debootstrap ; then
2462         debian2hd() {
2463             echo "Installing debian to harddisk is possible by using grml-debootstrap."
2464             return 1
2465         }
2466     fi
2467 }
2468
2469 # now run the functions
2470 isgrml && checkhome
2471 is4    && isgrml    && grmlstuff
2472 is4    && grmlcomp
2473
2474 # keephack
2475 is4 && xsource "/etc/zsh/keephack"
2476
2477 # wonderful idea of using "e" glob qualifier by Peter Stephenson
2478 # You use it as follows:
2479 # $ NTREF=/reference/file
2480 # $ ls -l *(e:nt:)
2481 # This lists all the files in the current directory newer than the reference file.
2482 # You can also specify the reference file inline; note quotes:
2483 # $ ls -l *(e:'nt ~/.zshenv':)
2484 is4 && nt() {
2485     if [[ -n $1 ]] ; then
2486         local NTREF=${~1}
2487     fi
2488     [[ $REPLY -nt $NTREF ]]
2489 }
2490
2491 # shell functions
2492
2493 #f1# Reload an autoloadable function
2494 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2495 compdef _functions freload
2496
2497 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2498 sll() {
2499     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2500     for file in "$@" ; do
2501         while [[ -h "$file" ]] ; do
2502             ls -l $file
2503             file=$(readlink "$file")
2504         done
2505     done
2506 }
2507
2508 # TODO: Is it supported to use pager settings like this?
2509 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2510 # with respect to wordsplitting. (ie. ${=PAGER})
2511 if check_com -c $PAGER ; then
2512     #f3# View Debian's changelog of a given package
2513     dchange() {
2514         emulate -L zsh
2515         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
2516             $PAGER /usr/share/doc/$1/changelog.Debian.gz
2517         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2518             $PAGER /usr/share/doc/$1/changelog.gz
2519         else
2520             if check_com -c aptitude ; then
2521                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2522                 if isgrml ; then
2523                     aptitude -t unstable changelog $1
2524                 else
2525                     aptitude changelog $1
2526                 fi
2527             else
2528                 echo "No changelog for package $1 found, sorry."
2529                 return 1
2530             fi
2531         fi
2532     }
2533     _dchange() { _files -W /usr/share/doc -/ }
2534     compdef _dchange dchange
2535
2536     #f3# View Debian's NEWS of a given package
2537     dnews() {
2538         emulate -L zsh
2539         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2540             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2541         else
2542             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2543                 $PAGER /usr/share/doc/$1/NEWS.gz
2544             else
2545                 echo "No NEWS file for package $1 found, sorry."
2546                 return 1
2547             fi
2548         fi
2549     }
2550     _dnews() { _files -W /usr/share/doc -/ }
2551     compdef _dnews dnews
2552
2553     #f3# View Debian's copyright of a given package
2554     dcopyright() {
2555         emulate -L zsh
2556         if [[ -r /usr/share/doc/$1/copyright ]] ; then
2557             $PAGER /usr/share/doc/$1/copyright
2558         else
2559             echo "No copyright file for package $1 found, sorry."
2560             return 1
2561         fi
2562     }
2563     _dcopyright() { _files -W /usr/share/doc -/ }
2564     compdef _dcopyright dcopyright
2565
2566     #f3# View upstream's changelog of a given package
2567     uchange() {
2568         emulate -L zsh
2569         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2570             $PAGER /usr/share/doc/$1/changelog.gz
2571         else
2572             echo "No changelog for package $1 found, sorry."
2573             return 1
2574         fi
2575     }
2576     _uchange() { _files -W /usr/share/doc -/ }
2577     compdef _uchange uchange
2578 fi
2579
2580 # zsh profiling
2581 profile() {
2582     ZSH_PROFILE_RC=1 $SHELL "$@"
2583 }
2584
2585 #f1# Edit an alias via zle
2586 edalias() {
2587     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2588 }
2589 compdef _aliases edalias
2590
2591 #f1# Edit a function via zle
2592 edfunc() {
2593     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2594 }
2595 compdef _functions edfunc
2596
2597 # use it e.g. via 'Restart apache2'
2598 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2599 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2600 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2601 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2602 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2603 #m# f6 Status() \kbd{/etc/init.d/\em{process}}\quad\kbd{status}
2604 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2605     __start_stop() {
2606         local action_="${1:l}"  # e.g Start/Stop/Restart
2607         local service_="$2"
2608         local param_="$3"
2609
2610         local service_target_="$(readlink /etc/init.d/$service_)"
2611         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2612             # runit
2613             case "${action_}" in
2614                 start) if [[ ! -e /etc/service/$service_ ]]; then
2615                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2616                        else
2617                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2618                        fi ;;
2619                 # there is no reload in runits sysv emulation
2620                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2621                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2622             esac
2623         else
2624             # sysvinit
2625             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2626         fi
2627     }
2628
2629     _grmlinitd() {
2630         local -a scripts
2631         scripts=( /etc/init.d/*(x:t) )
2632         _describe "service startup script" scripts
2633     }
2634
2635     for i in Start Restart Stop Force-Reload Reload Status ; do
2636         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2637         compdef _grmlinitd $i
2638     done
2639 fi
2640
2641 #f1# Provides useful information on globbing
2642 H-Glob() {
2643     echo -e "
2644     /      directories
2645     .      plain files
2646     @      symbolic links
2647     =      sockets
2648     p      named pipes (FIFOs)
2649     *      executable plain files (0100)
2650     %      device files (character or block special)
2651     %b     block special files
2652     %c     character special files
2653     r      owner-readable files (0400)
2654     w      owner-writable files (0200)
2655     x      owner-executable files (0100)
2656     A      group-readable files (0040)
2657     I      group-writable files (0020)
2658     E      group-executable files (0010)
2659     R      world-readable files (0004)
2660     W      world-writable files (0002)
2661     X      world-executable files (0001)
2662     s      setuid files (04000)
2663     S      setgid files (02000)
2664     t      files with the sticky bit (01000)
2665
2666   print *(m-1)          # Files modified up to a day ago
2667   print *(a1)           # Files accessed a day ago
2668   print *(@)            # Just symlinks
2669   print *(Lk+50)        # Files bigger than 50 kilobytes
2670   print *(Lk-50)        # Files smaller than 50 kilobytes
2671   print **/*.c          # All *.c files recursively starting in \$PWD
2672   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2673   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2674   print *~*.*           # All Files that do not contain a dot
2675   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2676   print -l *(.c|.h)     # Lists *.c and *.h
2677   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2678   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2679 }
2680 alias help-zshglob=H-Glob
2681
2682 # grep for running process, like: 'any vim'
2683 any() {
2684     emulate -L zsh
2685     unsetopt KSH_ARRAYS
2686     if [[ -z "$1" ]] ; then
2687         echo "any - grep for process(es) by keyword" >&2
2688         echo "Usage: any <keyword>" >&2 ; return 1
2689     else
2690         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
2691     fi
2692 }
2693
2694
2695 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2696 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2697 [[ -r /proc/1/maps ]] && \
2698 deswap() {
2699     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2700     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2701     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2702 }
2703
2704 # a wrapper for vim, that deals with title setting
2705 #   VIM_OPTIONS
2706 #       set this array to a set of options to vim you always want
2707 #       to have set when calling vim (in .zshrc.local), like:
2708 #           VIM_OPTIONS=( -p )
2709 #       This will cause vim to send every file given on the
2710 #       commandline to be send to it's own tab (needs vim7).
2711 if check_com vim; then
2712     vim() {
2713         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2714     }
2715 fi
2716
2717 # make a backup of a file
2718 bk() {
2719     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2720 }
2721
2722 ssl_hashes=( sha512 sha256 sha1 md5 )
2723
2724 for sh in ${ssl_hashes}; do
2725     eval 'ssl-cert-'${sh}'() {
2726         emulate -L zsh
2727         if [[ -z $1 ]] ; then
2728             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2729             return 1
2730         fi
2731         openssl x509 -noout -fingerprint -'${sh}' -in $1
2732     }'
2733 done; unset sh
2734
2735 ssl-cert-fingerprints() {
2736     emulate -L zsh
2737     local i
2738     if [[ -z $1 ]] ; then
2739         printf 'usage: ssl-cert-fingerprints <file>\n'
2740         return 1
2741     fi
2742     for i in ${ssl_hashes}
2743         do ssl-cert-$i $1;
2744     done
2745 }
2746
2747 ssl-cert-info() {
2748     emulate -L zsh
2749     if [[ -z $1 ]] ; then
2750         printf 'usage: ssl-cert-info <file>\n'
2751         return 1
2752     fi
2753     openssl x509 -noout -text -in $1
2754     ssl-cert-fingerprints $1
2755 }
2756
2757 # make sure our environment is clean regarding colors
2758 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2759
2760 # "persistent history"
2761 # just write important commands you always need to ~/.important_commands
2762 if [[ -r ~/.important_commands ]] ; then
2763     fc -R ~/.important_commands
2764 fi
2765
2766 # load the lookup subsystem if it's available on the system
2767 zrcautoload lookupinit && lookupinit
2768
2769 # variables
2770
2771 # set terminal property (used e.g. by msgid-chooser)
2772 export COLORTERM="yes"
2773
2774 # aliases
2775
2776 # general
2777 #a2# Execute \kbd{du -sch}
2778 alias da='du -sch'
2779 #a2# Execute \kbd{jobs -l}
2780 alias j='jobs -l'
2781
2782 # listing stuff
2783 #a2# Execute \kbd{ls -lSrah}
2784 alias dir="ls -lSrah"
2785 #a2# Only show dot-directories
2786 alias lad='ls -d .*(/)'
2787 #a2# Only show dot-files
2788 alias lsa='ls -a .*(.)'
2789 #a2# Only files with setgid/setuid/sticky flag
2790 alias lss='ls -l *(s,S,t)'
2791 #a2# Only show symlinks
2792 alias lsl='ls -l *(@)'
2793 #a2# Display only executables
2794 alias lsx='ls -l *(*)'
2795 #a2# Display world-{readable,writable,executable} files
2796 alias lsw='ls -ld *(R,W,X.^ND/)'
2797 #a2# Display the ten biggest files
2798 alias lsbig="ls -flh *(.OL[1,10])"
2799 #a2# Only show directories
2800 alias lsd='ls -d *(/)'
2801 #a2# Only show empty directories
2802 alias lse='ls -d *(/^F)'
2803 #a2# Display the ten newest files
2804 alias lsnew="ls -rtlh *(D.om[1,10])"
2805 #a2# Display the ten oldest files
2806 alias lsold="ls -rtlh *(D.Om[1,10])"
2807 #a2# Display the ten smallest files
2808 alias lssmall="ls -Srl *(.oL[1,10])"
2809 #a2# Display the ten newest directories and ten newest .directories
2810 alias lsnewdir="ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
2811 #a2# Display the ten oldest directories and ten oldest .directories
2812 alias lsolddir="ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
2813
2814 # some useful aliases
2815 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir \$OLDCWD}
2816 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2817
2818 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2819 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2820 #a2# scp with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2821 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2822
2823 # work around non utf8 capable software in utf environment via $LANG and luit
2824 if check_com isutfenv && check_com luit ; then
2825     if check_com -c mrxvt ; then
2826         isutfenv && [[ -n "$LANG" ]] && \
2827             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2828     fi
2829
2830     if check_com -c aterm ; then
2831         isutfenv && [[ -n "$LANG" ]] && \
2832             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2833     fi
2834
2835     if check_com -c centericq ; then
2836         isutfenv && [[ -n "$LANG" ]] && \
2837             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2838     fi
2839 fi
2840
2841 # useful functions
2842
2843 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2844 bk() {
2845     emulate -L zsh
2846     cp -b $1 $1_`date --iso-8601=m`
2847 }
2848
2849 #f5# cd to directoy and list files
2850 cl() {
2851     emulate -L zsh
2852     cd $1 && ls -a
2853 }
2854
2855 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2856 cd() {
2857     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2858         [[ ! -e ${1:h} ]] && return 1
2859         print "Correcting ${1} to ${1:h}"
2860         builtin cd ${1:h}
2861     else
2862         builtin cd "$@"
2863     fi
2864 }
2865
2866 #f5# Create Directoy and \kbd{cd} to it
2867 mkcd() {
2868     if (( ARGC != 1 )); then
2869         printf 'usage: mkcd <new-directory>\n'
2870         return 1;
2871     fi
2872     if [[ ! -d "$1" ]]; then
2873         command mkdir -p "$1"
2874     else
2875         printf '`%s'\'' already exists: cd-ing.\n' "$1"
2876     fi
2877     builtin cd "$1"
2878 }
2879
2880 #f5# Create temporary directory and \kbd{cd} to it
2881 cdt() {
2882     local t
2883     t=$(mktemp -d)
2884     echo "$t"
2885     builtin cd "$t"
2886 }
2887
2888 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2889 accessed() {
2890     emulate -L zsh
2891     print -l -- *(a-${1:-1})
2892 }
2893
2894 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2895 changed() {
2896     emulate -L zsh
2897     print -l -- *(c-${1:-1})
2898 }
2899
2900 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2901 modified() {
2902     emulate -L zsh
2903     print -l -- *(m-${1:-1})
2904 }
2905 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2906 check_com new || alias new=modified
2907
2908 # use colors when GNU grep with color-support
2909 #a2# Execute \kbd{grep -{}-color=auto}
2910 (( $#grep_options > 0 )) && alias grep='grep '${grep_options:+"${grep_options[*]}"}
2911
2912 # Translate DE<=>EN
2913 # 'translate' looks up fot a word in a file with language-to-language
2914 # translations (field separator should be " : "). A typical wordlist looks
2915 # like at follows:
2916 #  | english-word : german-transmission
2917 # It's also only possible to translate english to german but not reciprocal.
2918 # Use the following oneliner to turn back the sort order:
2919 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2920 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2921 #f5# Translates a word
2922 trans() {
2923     emulate -L zsh
2924     case "$1" in
2925         -[dD]*)
2926             translate -l de-en $2
2927             ;;
2928         -[eE]*)
2929             translate -l en-de $2
2930             ;;
2931         *)
2932             echo "Usage: $0 { -D | -E }"
2933             echo "         -D == German to English"
2934             echo "         -E == English to German"
2935     esac
2936 }
2937
2938 # Usage: simple-extract <file>
2939 # Using option -d deletes the original archive file.
2940 #f5# Smart archive extractor
2941 simple-extract() {
2942     emulate -L zsh
2943     setopt extended_glob noclobber
2944     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2945     local RC=0
2946     zparseopts -D -E "d=DELETE_ORIGINAL"
2947     for ARCHIVE in "${@}"; do
2948         case $ARCHIVE in
2949             *(tar.bz2|tbz2|tbz))
2950                 DECOMP_CMD="tar -xvjf -"
2951                 USES_STDIN=true
2952                 USES_STDOUT=false
2953                 ;;
2954             *(tar.gz|tgz))
2955                 DECOMP_CMD="tar -xvzf -"
2956                 USES_STDIN=true
2957                 USES_STDOUT=false
2958                 ;;
2959             *(tar.xz|txz|tar.lzma))
2960                 DECOMP_CMD="tar -xvJf -"
2961                 USES_STDIN=true
2962                 USES_STDOUT=false
2963                 ;;
2964             *tar)
2965                 DECOMP_CMD="tar -xvf -"
2966                 USES_STDIN=true
2967                 USES_STDOUT=false
2968                 ;;
2969             *rar)
2970                 DECOMP_CMD="unrar x"
2971                 USES_STDIN=false
2972                 USES_STDOUT=false
2973                 ;;
2974             *lzh)
2975                 DECOMP_CMD="lha x"
2976                 USES_STDIN=false
2977                 USES_STDOUT=false
2978                 ;;
2979             *7z)
2980                 DECOMP_CMD="7z x"
2981                 USES_STDIN=false
2982                 USES_STDOUT=false
2983                 ;;
2984             *(zip|jar))
2985                 DECOMP_CMD="unzip"
2986                 USES_STDIN=false
2987                 USES_STDOUT=false
2988                 ;;
2989             *deb)
2990                 DECOMP_CMD="ar -x"
2991                 USES_STDIN=false
2992                 USES_STDOUT=false
2993                 ;;
2994             *bz2)
2995                 DECOMP_CMD="bzip2 -d -c -"
2996                 USES_STDIN=true
2997                 USES_STDOUT=true
2998                 ;;
2999             *(gz|Z))
3000                 DECOMP_CMD="gzip -d -c -"
3001                 USES_STDIN=true
3002                 USES_STDOUT=true
3003                 ;;
3004             *(xz|lzma))
3005                 DECOMP_CMD="xz -d -c -"
3006                 USES_STDIN=true
3007                 USES_STDOUT=true
3008                 ;;
3009             *)
3010                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
3011                 RC=$((RC+1))
3012                 continue
3013                 ;;
3014         esac
3015
3016         if ! check_com ${DECOMP_CMD[(w)1]}; then
3017             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
3018             RC=$((RC+2))
3019             continue
3020         fi
3021
3022         GZTARGET="${ARCHIVE:t:r}"
3023         if [[ -f $ARCHIVE ]] ; then
3024
3025             print "Extracting '$ARCHIVE' ..."
3026             if $USES_STDIN; then
3027                 if $USES_STDOUT; then
3028                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
3029                 else
3030                     ${=DECOMP_CMD} < "$ARCHIVE"
3031                 fi
3032             else
3033                 if $USES_STDOUT; then
3034                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
3035                 else
3036                     ${=DECOMP_CMD} "$ARCHIVE"
3037                 fi
3038             fi
3039             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
3040
3041         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
3042             if check_com curl; then
3043                 WGET_CMD="curl -L -k -s -o -"
3044             elif check_com wget; then
3045                 WGET_CMD="wget -q -O - --no-check-certificate"
3046             else
3047                 print "ERROR: neither wget nor curl is installed" >&2
3048                 RC=$((RC+4))
3049                 continue
3050             fi
3051             print "Downloading and Extracting '$ARCHIVE' ..."
3052             if $USES_STDIN; then
3053                 if $USES_STDOUT; then
3054                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
3055                     RC=$((RC+$?))
3056                 else
3057                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
3058                     RC=$((RC+$?))
3059                 fi
3060             else
3061                 if $USES_STDOUT; then
3062                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
3063                 else
3064                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
3065                 fi
3066             fi
3067
3068         else
3069             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
3070             RC=$((RC+8))
3071         fi
3072     done
3073     return $RC
3074 }
3075
3076 __archive_or_uri()
3077 {
3078     _alternative \
3079         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
3080         '_urls:Remote Archives:_urls'
3081 }
3082
3083 _simple_extract()
3084 {
3085     _arguments \
3086         '-d[delete original archivefile after extraction]' \
3087         '*:Archive Or Uri:__archive_or_uri'
3088 }
3089 compdef _simple_extract simple-extract
3090 alias se=simple-extract
3091
3092 #f5# Set all ulimit parameters to \kbd{unlimited}
3093 allulimit() {
3094     ulimit -c unlimited
3095     ulimit -d unlimited
3096     ulimit -f unlimited
3097     ulimit -l unlimited
3098     ulimit -n unlimited
3099     ulimit -s unlimited
3100     ulimit -t unlimited
3101 }
3102
3103 #f5# Change the xterm title from within GNU-screen
3104 xtrename() {
3105     emulate -L zsh
3106     if [[ $1 != "-f" ]] ; then
3107         if [[ -z ${DISPLAY} ]] ; then
3108             printf 'xtrename only makes sense in X11.\n'
3109             return 1
3110         fi
3111     else
3112         shift
3113     fi
3114     if [[ -z $1 ]] ; then
3115         printf 'usage: xtrename [-f] "title for xterm"\n'
3116         printf '  renames the title of xterm from _within_ screen.\n'
3117         printf '  also works without screen.\n'
3118         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3119         return 0
3120     fi
3121     print -n "\eP\e]0;${1}\C-G\e\\"
3122     return 0
3123 }
3124
3125 # Create small urls via http://goo.gl using curl(1).
3126 # API reference: https://code.google.com/apis/urlshortener/
3127 function zurl() {
3128     emulate -L zsh
3129     setopt extended_glob
3130
3131     if [[ -z $1 ]]; then
3132         print "USAGE: zurl <URL>"
3133         return 1
3134     fi
3135
3136     local PN url prog api json contenttype item
3137     local -a data
3138     PN=$0
3139     url=$1
3140
3141     # Prepend 'http://' to given URL where necessary for later output.
3142     if [[ ${url} != http(s|)://* ]]; then
3143         url='http://'${url}
3144     fi
3145
3146     if check_com -c curl; then
3147         prog=curl
3148     else
3149         print "curl is not available, but mandatory for ${PN}. Aborting."
3150         return 1
3151     fi
3152     api='https://www.googleapis.com/urlshortener/v1/url'
3153     contenttype="Content-Type: application/json"
3154     json="{\"longUrl\": \"${url}\"}"
3155     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
3156     # Parse the response
3157     for item in "${data[@]}"; do
3158         case "$item" in
3159             ' '#'"id":'*)
3160                 item=${item#*: \"}
3161                 item=${item%\",*}
3162                 printf '%s\n' "$item"
3163                 return 0
3164                 ;;
3165         esac
3166     done
3167     return 1
3168 }
3169
3170 #f2# Find history events by search pattern and list them by date.
3171 whatwhen()  {
3172     emulate -L zsh
3173     local usage help ident format_l format_s first_char remain first last
3174     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3175     help='Use `whatwhen -h'\'' for further explanations.'
3176     ident=${(l,${#${:-Usage: }},, ,)}
3177     format_l="${ident}%s\t\t\t%s\n"
3178     format_s="${format_l//(\\t)##/\\t}"
3179     # Make the first char of the word to search for case
3180     # insensitive; e.g. [aA]
3181     first_char=[${(L)1[1]}${(U)1[1]}]
3182     remain=${1[2,-1]}
3183     # Default search range is `-100'.
3184     first=${2:-\-100}
3185     # Optional, just used for `<first> <last>' given.
3186     last=$3
3187     case $1 in
3188         ("")
3189             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3190             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3191         ;;
3192         (-h)
3193             printf '%s\n\n' ${usage}
3194             print 'OPTIONS:'
3195             printf $format_l '-h' 'show help text'
3196             print '\f'
3197             print 'SEARCH RANGE:'
3198             printf $format_l "'0'" 'the whole history,'
3199             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
3200             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
3201             printf '\n%s\n' 'EXAMPLES:'
3202             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
3203             printf $format_l 'whatwhen zsh -250'
3204             printf $format_l 'whatwhen foo 1 99'
3205         ;;
3206         (\?)
3207             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3208         ;;
3209         (*)
3210             # -l list results on stout rather than invoking $EDITOR.
3211             # -i Print dates as in YYYY-MM-DD.
3212             # -m Search for a - quoted - pattern within the history.
3213             fc -li -m "*${first_char}${remain}*" $first $last
3214         ;;
3215     esac
3216 }
3217
3218 # mercurial related stuff
3219 if check_com -c hg ; then
3220     # gnu like diff for mercurial
3221     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
3222     #f5# GNU like diff for mercurial
3223     hgdi() {
3224         emulate -L zsh
3225         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
3226     }
3227
3228     # build debian package
3229     #a2# Alias for \kbd{hg-buildpackage}
3230     alias hbp='hg-buildpackage'
3231
3232     # execute commands on the versioned patch-queue from the current repos
3233     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
3234
3235     # diffstat for specific version of a mercurial repository
3236     #   hgstat      => display diffstat between last revision and tip
3237     #   hgstat 1234 => display diffstat between revision 1234 and tip
3238     #f5# Diffstat for specific version of a mercurial repos
3239     hgstat() {
3240         emulate -L zsh
3241         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
3242     }
3243
3244 fi # end of check whether we have the 'hg'-executable
3245
3246 # grml-small cleanups
3247
3248 # The following is used to remove zsh-config-items that do not work
3249 # in grml-small by default.
3250 # If you do not want these adjustments (for whatever reason), set
3251 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
3252 # sources if it is there).
3253
3254 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
3255
3256     unset abk[V]
3257     unalias    'V'      &> /dev/null
3258     unfunction vman     &> /dev/null
3259     unfunction viless   &> /dev/null
3260     unfunction 2html    &> /dev/null
3261
3262     # manpages are not in grmlsmall
3263     unfunction manzsh   &> /dev/null
3264     unfunction man2     &> /dev/null
3265
3266 fi
3267
3268 zrclocal
3269
3270 ## genrefcard.pl settings
3271
3272 ### doc strings for external functions from files
3273 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
3274
3275 ### example: split functions-search 8,16,24,32
3276 #@# split functions-search 8
3277
3278 ## END OF FILE #################################################################
3279 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
3280 # Local variables:
3281 # mode: sh
3282 # End: