etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is439(){
 148     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 #f1# Checks whether or not you're running grml
 154 isgrml(){
 155     [[ -f /etc/grml_version ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running a grml cd
 160 isgrmlcd(){
 161     [[ -f /etc/grml_cd ]] && return 0
 162     return 1
 163 }
 164
 165 if isgrml ; then
 166 #f1# Checks whether or not you're running grml-small
 167     isgrmlsmall() {
 168         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 169             return 0
 170         fi
 171         return 1
 172     }
 173 else
 174     isgrmlsmall() { return 1 }
 175 fi
 176
 177 isdarwin(){
 178     [[ $OSTYPE == darwin* ]] && return 0
 179     return 1
 180 }
 181
 182 isfreebsd(){
 183     [[ $OSTYPE == freebsd* ]] && return 0
 184     return 1
 185 }
 186
 187 #f1# are we running within an utf environment?
 188 isutfenv() {
 189     case "$LANG $CHARSET $LANGUAGE" in
 190         *utf*) return 0 ;;
 191         *UTF*) return 0 ;;
 192         *)     return 1 ;;
 193     esac
 194 }
 195
 196 # check for user, if not running as root set $SUDO to sudo
 197 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 198
 199 # change directory to home on first invocation of zsh
 200 # important for rungetty -> autologin
 201 # Thanks go to Bart Schaefer!
 202 isgrml && checkhome() {
 203     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 204         export ALREADY_DID_CD_HOME=$HOME
 205         cd
 206     fi
 207 }
 208
 209 # check for zsh v3.1.7+
 210
 211 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 212      || ${ZSH_VERSION} == 3.<2->.<->*    \
 213      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 214
 215     printf '-!-\n'
 216     printf '-!- In this configuration we try to make use of features, that only\n'
 217     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 218     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 219     printf '-!- advanced features in all supported versions.\n'
 220     printf '-!-\n'
 221     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 222     printf '-!-\n'
 223     printf '-!- While this *may* work, it might as well fail.\n'
 224     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 225     printf '-!-\n'
 226     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 227     printf '-!- If it does today, you'\''ve been lucky.\n'
 228     printf '-!-\n'
 229     printf '-!- Ye been warned!\n'
 230     printf '-!-\n'
 231
 232     function zstyle() { : }
 233 fi
 234
 235 # autoload wrapper - use this one instead of autoload directly
 236 # We need to define this function as early as this, because autoloading
 237 # 'is-at-least()' needs it.
 238 function zrcautoload() {
 239     emulate -L zsh
 240     setopt extended_glob
 241     local fdir ffile
 242     local -i ffound
 243
 244     ffile=$1
 245     (( ffound = 0 ))
 246     for fdir in ${fpath} ; do
 247         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 248     done
 249
 250     (( ffound == 0 )) && return 1
 251     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 252         autoload -U ${ffile} || return 1
 253     else
 254         autoload ${ffile} || return 1
 255     fi
 256     return 0
 257 }
 258
 259 # Load is-at-least() for more precise version checks Note that this test will
 260 # *always* fail, if the is-at-least function could not be marked for
 261 # autoloading.
 262 zrcautoload is-at-least || is-at-least() { return 1 }
 263
 264 # set some important options (as early as possible)
 265
 266 # append history list to the history file; this is the default but we make sure
 267 # because it's required for share_history.
 268 setopt append_history
 269
 270 # import new commands from the history file also in other zsh-session
 271 is4 && setopt share_history
 272
 273 # save each command's beginning timestamp and the duration to the history file
 274 setopt extended_history
 275
 276 # If a new command line being added to the history list duplicates an older
 277 # one, the older command is removed from the list
 278 is4 && setopt histignorealldups
 279
 280 # remove command lines from the history list when the first character on the
 281 # line is a space
 282 setopt histignorespace
 283
 284 # if a command is issued that can't be executed as a normal command, and the
 285 # command is the name of a directory, perform the cd command to that directory.
 286 setopt auto_cd
 287
 288 # in order to use #, ~ and ^ for filename generation grep word
 289 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 290 # don't forget to quote '^', '~' and '#'!
 291 setopt extended_glob
 292
 293 # display PID when suspending processes as well
 294 setopt longlistjobs
 295
 296 # try to avoid the 'zsh: no matches found...'
 297 setopt nonomatch
 298
 299 # report the status of backgrounds jobs immediately
 300 setopt notify
 301
 302 # whenever a command completion is attempted, make sure the entire command path
 303 # is hashed first.
 304 setopt hash_list_all
 305
 306 # not just at the end
 307 setopt completeinword
 308
 309 # Don't send SIGHUP to background processes when the shell exits.
 310 setopt nohup
 311
 312 # make cd push the old directory onto the directory stack.
 313 setopt auto_pushd
 314
 315 # avoid "beep"ing
 316 setopt nobeep
 317
 318 # don't push the same dir twice.
 319 setopt pushd_ignore_dups
 320
 321 # * shouldn't match dotfiles. ever.
 322 setopt noglobdots
 323
 324 # use zsh style word splitting
 325 setopt noshwordsplit
 326
 327 # don't error out when unset parameters are used
 328 setopt unset
 329
 330 # setting some default values
 331 NOCOR=${NOCOR:-0}
 332 NOMENU=${NOMENU:-0}
 333 NOPRECMD=${NOPRECMD:-0}
 334 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 335 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 336 BATTERY=${BATTERY:-0}
 337 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 338 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 339
 340 typeset -ga ls_options
 341 typeset -ga grep_options
 342 if ls --help 2> /dev/null | grep -q GNU; then
 343     ls_options=( --color=auto )
 344 elif [[ $OSTYPE == freebsd* ]]; then
 345     ls_options=( -G )
 346 fi
 347 if grep --help 2> /dev/null | grep -q GNU || \
 348    [[ $OSTYPE == freebsd* ]]; then
 349     grep_options=( --color=auto )
 350 fi
 351
 352 # utility functions
 353 # this function checks if a command exists and returns either true
 354 # or false. This avoids using 'which' and 'whence', which will
 355 # avoid problems with aliases for which on certain weird systems. :-)
 356 # Usage: check_com [-c|-g] word
 357 #   -c  only checks for external commands
 358 #   -g  does the usual tests and also checks for global aliases
 359 check_com() {
 360     emulate -L zsh
 361     local -i comonly gatoo
 362
 363     if [[ $1 == '-c' ]] ; then
 364         (( comonly = 1 ))
 365         shift
 366     elif [[ $1 == '-g' ]] ; then
 367         (( gatoo = 1 ))
 368     else
 369         (( comonly = 0 ))
 370         (( gatoo = 0 ))
 371     fi
 372
 373     if (( ${#argv} != 1 )) ; then
 374         printf 'usage: check_com [-c] <command>\n' >&2
 375         return 1
 376     fi
 377
 378     if (( comonly > 0 )) ; then
 379         [[ -n ${commands[$1]}  ]] && return 0
 380         return 1
 381     fi
 382
 383     if   [[ -n ${commands[$1]}    ]] \
 384       || [[ -n ${functions[$1]}   ]] \
 385       || [[ -n ${aliases[$1]}     ]] \
 386       || [[ -n ${reswords[(r)$1]} ]] ; then
 387
 388         return 0
 389     fi
 390
 391     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 392         return 0
 393     fi
 394
 395     return 1
 396 }
 397
 398 # creates an alias and precedes the command with
 399 # sudo if $EUID is not zero.
 400 salias() {
 401     emulate -L zsh
 402     local only=0 ; local multi=0
 403     while [[ $1 == -* ]] ; do
 404         case $1 in
 405             (-o) only=1 ;;
 406             (-a) multi=1 ;;
 407             (--) shift ; break ;;
 408             (-h)
 409                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 410                 printf '  -h      shows this help text.\n'
 411                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 412                 printf '          be careful using this option.\n'
 413                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 414                 return 0
 415                 ;;
 416             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 417         esac
 418         shift
 419     done
 420
 421     if (( ${#argv} > 1 )) ; then
 422         printf 'Too many arguments %s\n' "${#argv}"
 423         return 1
 424     fi
 425
 426     key="${1%%\=*}" ;  val="${1#*\=}"
 427     if (( EUID == 0 )) && (( only == 0 )); then
 428         alias -- "${key}=${val}"
 429     elif (( EUID > 0 )) ; then
 430         (( multi > 0 )) && val="${val// ; / ; sudo }"
 431         alias -- "${key}=sudo ${val}"
 432     fi
 433
 434     return 0
 435 }
 436
 437 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 438 # usage: uprint foo
 439 #   Where foo is the *name* of the parameter you want printed.
 440 #   Note that foo is no typo; $foo would be wrong here!
 441 if ! is42 ; then
 442     uprint () {
 443         emulate -L zsh
 444         local -a u
 445         local w
 446         local parameter=$1
 447
 448         if [[ -z ${parameter} ]] ; then
 449             printf 'usage: uprint <parameter>\n'
 450             return 1
 451         fi
 452
 453         for w in ${(P)parameter} ; do
 454             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 455         done
 456
 457         builtin print -l $u
 458     }
 459 fi
 460
 461 # Check if we can read given files and source those we can.
 462 xsource() {
 463     if (( ${#argv} < 1 )) ; then
 464         printf 'usage: xsource FILE(s)...\n' >&2
 465         return 1
 466     fi
 467
 468     while (( ${#argv} > 0 )) ; do
 469         [[ -r "$1" ]] && source "$1"
 470         shift
 471     done
 472     return 0
 473 }
 474
 475 # Check if we can read a given file and 'cat(1)' it.
 476 xcat() {
 477     emulate -L zsh
 478     if (( ${#argv} != 1 )) ; then
 479         printf 'usage: xcat FILE\n' >&2
 480         return 1
 481     fi
 482
 483     [[ -r $1 ]] && cat $1
 484     return 0
 485 }
 486
 487 # Remove these functions again, they are of use only in these
 488 # setup files. This should be called at the end of .zshrc.
 489 xunfunction() {
 490     emulate -L zsh
 491     local -a funcs
 492     funcs=(salias xcat xsource xunfunction zrcautoload)
 493
 494     for func in $funcs ; do
 495         [[ -n ${functions[$func]} ]] \
 496             && unfunction $func
 497     done
 498     return 0
 499 }
 500
 501 # this allows us to stay in sync with grml's zshrc and put own
 502 # modifications in ~/.zshrc.local
 503 zrclocal() {
 504     xsource "/etc/zsh/zshrc.local"
 505     xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
 506     return 0
 507 }
 508
 509 # locale setup
 510 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 511     xsource "/etc/default/locale"
 512 fi
 513
 514 for var in LANG LC_ALL LC_MESSAGES ; do
 515     [[ -n ${(P)var} ]] && export $var
 516 done
 517
 518 xsource "/etc/sysconfig/keyboard"
 519
 520 TZ=$(xcat /etc/timezone)
 521
 522 # set some variables
 523 if check_com -c vim ; then
 524 #v#
 525     export EDITOR=${EDITOR:-vim}
 526 else
 527     export EDITOR=${EDITOR:-vi}
 528 fi
 529
 530 #v#
 531 export PAGER=${PAGER:-less}
 532
 533 #v#
 534 export MAIL=${MAIL:-/var/mail/$USER}
 535
 536 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 537 export SHELL='/bin/zsh'
 538
 539 # color setup for ls:
 540 check_com -c dircolors && eval $(dircolors -b)
 541 # color setup for ls on OS X / FreeBSD:
 542 isdarwin && export CLICOLOR=1
 543 isfreebsd && export CLICOLOR=1
 544
 545 # do MacPorts setup on darwin
 546 if isdarwin && [[ -d /opt/local ]]; then
 547     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 548     # zshenv.
 549     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 550     MANPATH="/opt/local/share/man:$MANPATH"
 551 fi
 552 # do Fink setup on darwin
 553 isdarwin && xsource /sw/bin/init.sh
 554
 555 # load our function and completion directories
 556 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 557     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 558     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 559         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 560             zrcautoload ${func:t}
 561         done
 562     fi
 563 done
 564 unset fdir func
 565
 566 # support colors in less
 567 export LESS_TERMCAP_mb=$'\E[01;31m'
 568 export LESS_TERMCAP_md=$'\E[01;31m'
 569 export LESS_TERMCAP_me=$'\E[0m'
 570 export LESS_TERMCAP_se=$'\E[0m'
 571 export LESS_TERMCAP_so=$'\E[01;44;33m'
 572 export LESS_TERMCAP_ue=$'\E[0m'
 573 export LESS_TERMCAP_us=$'\E[01;32m'
 574
 575 # mailchecks
 576 MAILCHECK=30
 577
 578 # report about cpu-/system-/user-time of command if running longer than
 579 # 5 seconds
 580 REPORTTIME=5
 581
 582 # watch for everyone but me and root
 583 watch=(notme root)
 584
 585 # automatically remove duplicates from these arrays
 586 typeset -U path cdpath fpath manpath
 587
 588 # Remove zle-line-{init,finish} if it looks like it turns smkx. This would be
 589 # better fixed by working with those modes too, but we use way too many
 590 # hardcoded bindings for now.
 591 function remove_widget () {
 592     local name=$1
 593     local cap=$2
 594     if (( ${+functions[$name]} )) && [[ ${functions[$name]} == *${cap}* ]]; then
 595         local w=${widgets[$name]}
 596         zle -D $name
 597         [[ $w == user:* ]] && unfunction ${w#*:}
 598     fi
 599 }
 600 remove_widget zle-line-init smkx
 601 remove_widget zle-line-finish rmkx
 602 unfunction remove_widget
 603
 604 # keybindings
 605 if [[ "$TERM" != emacs ]] ; then
 606     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 607     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 608     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 609     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 610     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 611     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 612     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 613     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 614     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 615     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 616     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 617     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 618     # ncurses stuff:
 619     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 620     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 621     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 622     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 623     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 624     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 625     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 626     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 627 fi
 628
 629 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 630 # use emacs style per default:
 631 bindkey -e
 632 # use vi style:
 633 # bindkey -v
 634
 635 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 636 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 637 beginning-or-end-of-somewhere() {
 638     local hno=$HISTNO
 639     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 640       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 641         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 642     else
 643         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 644         if (( HISTNO != hno )); then
 645             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 646         fi
 647     fi
 648 }
 649 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 650 zle -N end-of-somewhere beginning-or-end-of-somewhere
 651
 652
 653 #if [[ "$TERM" == screen ]] ; then
 654
 655 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 656 ## to beginning/end of buffer on second keypress
 657 ## and to beginning/end of history on (at most) the third keypress
 658 # terminator & non-debian xterm
 659 bindkey '\eOH' beginning-of-somewhere  # home
 660 bindkey '\eOF' end-of-somewhere        # end
 661 # freebsd console
 662 bindkey '\e[H' beginning-of-somewhere   # home
 663 bindkey '\e[F' end-of-somewhere         # end
 664 # xterm,gnome-terminal,quake,etc
 665 bindkey '^[[1~' beginning-of-somewhere  # home
 666 bindkey '^[[4~' end-of-somewhere        # end
 667 # if terminal type is set to 'rxvt':
 668 bindkey '\e[7~' beginning-of-somewhere  # home
 669 bindkey '\e[8~' end-of-somewhere        # end
 670 #fi
 671
 672 bindkey '\e[A'  up-line-or-search       # cursor up
 673 bindkey '\e[B'  down-line-or-search     # <ESC>-
 674
 675 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 676 bindkey "\e[5C" forward-word
 677 bindkey "\e[5D" backward-word
 678 bindkey "\e[1;5C" forward-word
 679 bindkey "\e[1;5D" backward-word
 680 ## the same for alt-left-arrow and alt-right-arrow
 681 bindkey '^[[1;3C' forward-word
 682 bindkey '^[[1;3D' backward-word
 683
 684 # Search backward in the history for a line beginning with the current
 685 # line up to the cursor and move the cursor to the end of the line then
 686 zle -N history-beginning-search-backward-end history-search-end
 687 zle -N history-beginning-search-forward-end  history-search-end
 688 #k# search history backward for entry beginning with typed text
 689 bindkey '^xp'   history-beginning-search-backward-end
 690 #k# search history forward for entry beginning with typed text
 691 bindkey '^xP'   history-beginning-search-forward-end
 692 #k# search history backward for entry beginning with typed text
 693 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 694 #k# search history forward for entry beginning with typed text
 695 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 696
 697 # bindkey -s '^l' "|less\n"             # ctrl-L pipes to less
 698 # bindkey -s '^b' " &\n"                # ctrl-B runs it in the background
 699
 700 # insert unicode character
 701 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 702 # See for example http://unicode.org/charts/ for unicode characters code
 703 zrcautoload insert-unicode-char
 704 zle -N insert-unicode-char
 705 #k# Insert Unicode character
 706 bindkey '^xi' insert-unicode-char
 707
 708 #m# k Shift-tab Perform backwards menu completion
 709 if [[ -n "$terminfo[kcbt]" ]]; then
 710     bindkey "$terminfo[kcbt]" reverse-menu-complete
 711 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 712     bindkey "$terminfo[cbt]"  reverse-menu-complete
 713 fi
 714
 715 ## toggle the ,. abbreviation feature on/off
 716 # NOABBREVIATION: default abbreviation-state
 717 #                 0 - enabled (default)
 718 #                 1 - disabled
 719 NOABBREVIATION=${NOABBREVIATION:-0}
 720
 721 grml_toggle_abbrev() {
 722     if (( ${NOABBREVIATION} > 0 )) ; then
 723         NOABBREVIATION=0
 724     else
 725         NOABBREVIATION=1
 726     fi
 727 }
 728
 729 #k# Toggle abbreviation expansion on/off
 730 zle -N grml_toggle_abbrev
 731 bindkey '^xA' grml_toggle_abbrev
 732
 733 # add a command line to the shells history without executing it
 734 commit-to-history() {
 735     print -s ${(z)BUFFER}
 736     zle send-break
 737 }
 738 zle -N commit-to-history
 739 bindkey "^x^h" commit-to-history
 740
 741 # only slash should be considered as a word separator:
 742 slash-backward-kill-word() {
 743     local WORDCHARS="${WORDCHARS:s@/@}"
 744     # zle backward-word
 745     zle backward-kill-word
 746 }
 747 zle -N slash-backward-kill-word
 748
 749 #k# Kill left-side word or everything up to next slash
 750 bindkey '\ev' slash-backward-kill-word
 751 #k# Kill left-side word or everything up to next slash
 752 bindkey '\e^h' slash-backward-kill-word
 753 #k# Kill left-side word or everything up to next slash
 754 bindkey '\e^?' slash-backward-kill-word
 755
 756 # use the new *-pattern-* widgets for incremental history search
 757 if is439 ; then
 758     bindkey '^r' history-incremental-pattern-search-backward
 759     bindkey '^s' history-incremental-pattern-search-forward
 760 fi
 761
 762 # a generic accept-line wrapper
 763
 764 # This widget can prevent unwanted autocorrections from command-name
 765 # to _command-name, rehash automatically on enter and call any number
 766 # of builtin and user-defined widgets in different contexts.
 767 #
 768 # For a broader description, see:
 769 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 770 #
 771 # The code is imported from the file 'zsh/functions/accept-line' from
 772 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 773 # distributed under the same terms as zsh itself.
 774
 775 # A newly added command will may not be found or will cause false
 776 # correction attempts, if you got auto-correction set. By setting the
 777 # following style, we force accept-line() to rehash, if it cannot
 778 # find the first word on the command line in the $command[] hash.
 779 zstyle ':acceptline:*' rehash true
 780
 781 function Accept-Line() {
 782     setopt localoptions noksharrays
 783     local -a subs
 784     local -xi aldone
 785     local sub
 786     local alcontext=${1:-$alcontext}
 787
 788     zstyle -a ":acceptline:${alcontext}" actions subs
 789
 790     (( ${#subs} < 1 )) && return 0
 791
 792     (( aldone = 0 ))
 793     for sub in ${subs} ; do
 794         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 795         zle ${sub}
 796
 797         (( aldone > 0 )) && break
 798     done
 799 }
 800
 801 function Accept-Line-getdefault() {
 802     emulate -L zsh
 803     local default_action
 804
 805     zstyle -s ":acceptline:${alcontext}" default_action default_action
 806     case ${default_action} in
 807         ((accept-line|))
 808             printf ".accept-line"
 809             ;;
 810         (*)
 811             printf ${default_action}
 812             ;;
 813     esac
 814 }
 815
 816 function Accept-Line-HandleContext() {
 817     zle Accept-Line
 818
 819     default_action=$(Accept-Line-getdefault)
 820     zstyle -T ":acceptline:${alcontext}" call_default \
 821         && zle ${default_action}
 822 }
 823
 824 function accept-line() {
 825     setopt localoptions noksharrays
 826     local -ax cmdline
 827     local -x alcontext
 828     local buf com fname format msg default_action
 829
 830     alcontext='default'
 831     buf="${BUFFER}"
 832     cmdline=(${(z)BUFFER})
 833     com="${cmdline[1]}"
 834     fname="_${com}"
 835
 836     Accept-Line 'preprocess'
 837
 838     zstyle -t ":acceptline:${alcontext}" rehash \
 839         && [[ -z ${commands[$com]} ]]           \
 840         && rehash
 841
 842     if    [[ -n ${com}               ]] \
 843        && [[ -n ${reswords[(r)$com]} ]] \
 844        || [[ -n ${aliases[$com]}     ]] \
 845        || [[ -n ${functions[$com]}   ]] \
 846        || [[ -n ${builtins[$com]}    ]] \
 847        || [[ -n ${commands[$com]}    ]] ; then
 848
 849         # there is something sensible to execute, just do it.
 850         alcontext='normal'
 851         Accept-Line-HandleContext
 852
 853         return
 854     fi
 855
 856     if    [[ -o correct              ]] \
 857        || [[ -o correctall           ]] \
 858        && [[ -n ${functions[$fname]} ]] ; then
 859
 860         # nothing there to execute but there is a function called
 861         # _command_name; a completion widget. Makes no sense to
 862         # call it on the commandline, but the correct{,all} options
 863         # will ask for it nevertheless, so warn the user.
 864         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 865             # Okay, we warned the user before, he called us again,
 866             # so have it his way.
 867             alcontext='force'
 868             Accept-Line-HandleContext
 869
 870             return
 871         fi
 872
 873         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 874             alcontext='normal'
 875             Accept-Line-HandleContext
 876         else
 877             # prepare warning message for the user, configurable via zstyle.
 878             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 879
 880             if [[ -z ${msg} ]] ; then
 881                 msg="%c will not execute and completion %f exists."
 882             fi
 883
 884             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 885
 886             zle -M -- "${msg}"
 887         fi
 888         return
 889     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 890         # If we are here, the commandline contains something that is not
 891         # executable, which is neither subject to _command_name correction
 892         # and is not empty. might be a variable assignment
 893         alcontext='misc'
 894         Accept-Line-HandleContext
 895
 896         return
 897     fi
 898
 899     # If we got this far, the commandline only contains whitespace, or is empty.
 900     alcontext='empty'
 901     Accept-Line-HandleContext
 902 }
 903
 904 zle -N accept-line
 905 zle -N Accept-Line
 906 zle -N Accept-Line-HandleContext
 907
 908 # power completion - abbreviation expansion
 909 # power completion / abbreviation expansion / buffer expansion
 910 # see http://zshwiki.org/home/examples/zleiab for details
 911 # less risky than the global aliases but powerful as well
 912 # just type the abbreviation key and afterwards ',.' to expand it
 913 declare -A abk
 914 setopt extendedglob
 915 setopt interactivecomments
 916 abk=(
 917 #   key   # value                  (#d additional doc string)
 918 #A# start
 919     '...'  '../..'
 920     '....' '../../..'
 921     'BG'   '& exit'
 922     'C'    '| wc -l'
 923     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
 924     'H'    '| head'
 925     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 926     'L'    '| less'
 927     'LL'   '|& less -r'
 928     'M'    '| most'
 929     'N'    '&>/dev/null'           #d (No Output)
 930     'R'    '| tr A-z N-za-m'       #d (ROT13)
 931     'SL'   '| sort | less'
 932     'S'    '| sort -u'
 933     'T'    '| tail'
 934     'V'    '|& vim -'
 935 #A# end
 936     'co'   './configure && make && sudo make install'
 937 )
 938
 939 zleiab() {
 940     emulate -L zsh
 941     setopt extendedglob
 942     local MATCH
 943
 944     if (( NOABBREVIATION > 0 )) ; then
 945         LBUFFER="${LBUFFER},."
 946         return 0
 947     fi
 948
 949     LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
 950     LBUFFER+=${abk[$MATCH]:-$MATCH}
 951 }
 952
 953 zle -N zleiab && bindkey ",." zleiab
 954
 955 #f# display contents of assoc array $abk
 956 help-show-abk()
 957 {
 958   zle -M "$(print "Type ,. after these abbreviations to expand them:"; print -a -C 2 ${(kv)abk})"
 959 }
 960 #k# Display list of abbreviations that expand when followed by ,.
 961 zle -N help-show-abk && bindkey '^xb' help-show-abk
 962
 963 # autoloading
 964 zrcautoload zmv    # who needs mmv or rename?
 965 zrcautoload history-search-end
 966
 967 # we don't want to quote/espace URLs on our own...
 968 # if autoload -U url-quote-magic ; then
 969 #    zle -N self-insert url-quote-magic
 970 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 971 # else
 972 #    print 'Notice: no url-quote-magic available :('
 973 # fi
 974 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 975
 976 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 977 alias run-help >&/dev/null && unalias run-help
 978 for rh in run-help{,-git,-svk,-svn}; do
 979     zrcautoload $rh
 980 done; unset rh
 981
 982 # completion system
 983 if zrcautoload compinit ; then
 984     compinit || print 'Notice: no compinit available :('
 985 else
 986     print 'Notice: no compinit available :('
 987     function compdef { }
 988 fi
 989
 990 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 991
 992 is4 && \
 993 for mod in complist deltochar mathfunc ; do
 994     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 995 done
 996
 997 # autoload zsh modules when they are referenced
 998 if is4 ; then
 999     zmodload -a  zsh/stat    zstat
1000     zmodload -a  zsh/zpty    zpty
1001     zmodload -ap zsh/mapfile mapfile
1002 fi
1003
1004 if is4 && zrcautoload insert-files && zle -N insert-files ; then
1005     #k# Insert files and test globbing
1006     bindkey "^xf" insert-files # C-x-f
1007 fi
1008
1009 bindkey ' '   magic-space    # also do history expansion on space
1010 #k# Trigger menu-complete
1011 bindkey '\ei' menu-complete  # menu completion via esc-i
1012
1013 # press esc-e for editing command line in $EDITOR or $VISUAL
1014 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
1015     #k# Edit the current line in \kbd{\$EDITOR}
1016     bindkey '\ee' edit-command-line
1017 fi
1018
1019 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
1020     #k# menu selection: pick item but stay in the menu
1021     bindkey -M menuselect '\e^M' accept-and-menu-complete
1022     # also use + and INSERT since it's easier to press repeatedly
1023     bindkey -M menuselect "+" accept-and-menu-complete
1024     bindkey -M menuselect "^[[2~" accept-and-menu-complete
1025
1026     # accept a completion and try to complete again by using menu
1027     # completion; very useful with completing directories
1028     # by using 'undo' one's got a simple file browser
1029     bindkey -M menuselect '^o' accept-and-infer-next-history
1030 fi
1031
1032 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1033 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1034 zle -N insert-datestamp
1035
1036 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1037 bindkey '^ed' insert-datestamp
1038
1039 # press esc-m for inserting last typed word again (thanks to caphuso!)
1040 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1041 zle -N insert-last-typed-word;
1042
1043 #k# Insert last typed word
1044 bindkey "\em" insert-last-typed-word
1045
1046 function grml-zsh-fg() {
1047   if (( ${#jobstates} )); then
1048     zle .push-input
1049     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1050     BUFFER="${BUFFER}fg"
1051     zle .accept-line
1052   else
1053     zle -M 'No background jobs. Doing nothing.'
1054   fi
1055 }
1056 zle -N grml-zsh-fg
1057 #k# A smart shortcut for \kbd{fg<enter>}
1058 bindkey '^z' grml-zsh-fg
1059
1060 # run command line as user root via sudo:
1061 sudo-command-line() {
1062     [[ -z $BUFFER ]] && zle up-history
1063     if [[ $BUFFER != sudo\ * ]]; then
1064         BUFFER="sudo $BUFFER"
1065         CURSOR=$(( CURSOR+5 ))
1066     fi
1067 }
1068 zle -N sudo-command-line
1069
1070 #k# prepend the current command with "sudo"
1071 bindkey "^os" sudo-command-line
1072
1073 ### jump behind the first word on the cmdline.
1074 ### useful to add options.
1075 function jump_after_first_word() {
1076     local words
1077     words=(${(z)BUFFER})
1078
1079     if (( ${#words} <= 1 )) ; then
1080         CURSOR=${#BUFFER}
1081     else
1082         CURSOR=${#${words[1]}}
1083     fi
1084 }
1085 zle -N jump_after_first_word
1086 #k# jump to after first word (for adding options)
1087 bindkey '^x1' jump_after_first_word
1088
1089 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1090 zle -C hist-complete complete-word _generic
1091 zstyle ':completion:hist-complete:*' completer _history
1092 #k# complete word from history with menu
1093 bindkey "^x^x" hist-complete
1094
1095 ## complete word from currently visible Screen or Tmux buffer.
1096 if check_com -c screen || check_com -c tmux; then
1097     _complete_screen_display() {
1098         [[ "$TERM" != "screen" ]] && return 1
1099
1100         local TMPFILE=$(mktemp)
1101         local -U -a _screen_display_wordlist
1102         trap "rm -f $TMPFILE" EXIT
1103
1104         # fill array with contents from screen hardcopy
1105         if ((${+TMUX})); then
1106             #works, but crashes tmux below version 1.4
1107             #luckily tmux -V option to ask for version, was also added in 1.4
1108             tmux -V &>/dev/null || return
1109             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1110         else
1111             screen -X hardcopy $TMPFILE
1112             # screen sucks, it dumps in latin1, apparently always. so recode it
1113             # to system charset
1114             check_com recode && recode latin1 $TMPFILE
1115         fi
1116         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1117         # remove PREFIX to be completed from that array
1118         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1119         compadd -a _screen_display_wordlist
1120     }
1121     #k# complete word from currently visible GNU screen buffer
1122     bindkey -r "^xS"
1123     compdef -k _complete_screen_display complete-word '^xS'
1124 fi
1125
1126 # history
1127
1128 ZSHDIR=${ZDOTDIR:-${HOME}/.zsh}
1129
1130 #v#
1131 HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1132 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1133 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1134
1135 # dirstack handling
1136
1137 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1138 DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1139
1140 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1141     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1142     # "cd -" won't work after login by just setting $OLDPWD, so
1143     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1144 fi
1145
1146 chpwd() {
1147     local -ax my_stack
1148     my_stack=( ${PWD} ${dirstack} )
1149     if is42 ; then
1150         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1151     else
1152         uprint my_stack >! ${DIRSTACKFILE}
1153     fi
1154 }
1155
1156 # directory based profiles
1157
1158 if is433 ; then
1159
1160 # chpwd_profiles(): Directory Profiles, Quickstart:
1161 #
1162 # In .zshrc.local:
1163 #
1164 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1165 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1166 #   chpwd_profiles
1167 #
1168 # For details see the `grmlzshrc.5' manual page.
1169 function chpwd_profiles() {
1170     local profile context
1171     local -i reexecute
1172
1173     context=":chpwd:profiles:$PWD"
1174     zstyle -s "$context" profile profile || profile='default'
1175     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1176
1177     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1178         typeset -g CHPWD_PROFILE
1179         local CHPWD_PROFILES_INIT=1
1180         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1181     elif [[ $profile != $CHPWD_PROFILE ]]; then
1182         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1183             && chpwd_leave_profile_${CHPWD_PROFILE}
1184     fi
1185     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1186         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1187     fi
1188
1189     CHPWD_PROFILE="${profile}"
1190     return 0
1191 }
1192
1193 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1194
1195 fi # is433
1196
1197 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1198 if [[ $BATTERY -gt 0 ]] ; then
1199     if ! check_com -c acpi ; then
1200         BATTERY=0
1201     fi
1202 fi
1203
1204 battery() {
1205 if [[ $BATTERY -gt 0 ]] ; then
1206     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1207     if [[ -z "$PERCENT" ]] ; then
1208         PERCENT='acpi not present'
1209     else
1210         if [[ "$PERCENT" -lt 20 ]] ; then
1211             PERCENT="warning: ${PERCENT}%%"
1212         else
1213             PERCENT="${PERCENT}%%"
1214         fi
1215     fi
1216 fi
1217 }
1218 # set colors for use in prompts
1219 if zrcautoload colors && colors 2>/dev/null ; then
1220     BLUE="%{${fg[blue]}%}"
1221     RED="%{${fg_bold[red]}%}"
1222     GREEN="%{${fg[green]}%}"
1223     CYAN="%{${fg[cyan]}%}"
1224     MAGENTA="%{${fg[magenta]}%}"
1225     YELLOW="%{${fg[yellow]}%}"
1226     WHITE="%{${fg[white]}%}"
1227     NO_COLOR="%{${reset_color}%}"
1228 else
1229     BLUE=$'%{\e[1;34m%}'
1230     RED=$'%{\e[1;31m%}'
1231     GREEN=$'%{\e[1;32m%}'
1232     CYAN=$'%{\e[1;36m%}'
1233     WHITE=$'%{\e[1;37m%}'
1234     MAGENTA=$'%{\e[1;35m%}'
1235     YELLOW=$'%{\e[1;33m%}'
1236     NO_COLOR=$'%{\e[0m%}'
1237 fi
1238
1239 # gather version control information for inclusion in a prompt
1240
1241 if zrcautoload vcs_info; then
1242     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1243     # function, which can cause a lot of trouble with our directory-based
1244     # profiles. So:
1245     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1246         function VCS_INFO_realpath () {
1247             setopt localoptions NO_shwordsplit chaselinks
1248             ( builtin cd -q $1 2> /dev/null && pwd; )
1249         }
1250     fi
1251
1252     zstyle ':vcs_info:*' max-exports 2
1253
1254     if [[ -o restricted ]]; then
1255         zstyle ':vcs_info:*' enable NONE
1256     fi
1257 fi
1258
1259 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1260 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1261 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1262 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1263 #       to $vcs_info_msg_N_ as soon as we use the included version.
1264 if [[ "$TERM" == dumb ]] ; then
1265     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1266     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1267 else
1268     # these are the same, just with a lot of colors:
1269     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} " \
1270                                        "zsh: %r"
1271     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR}%} " \
1272                                        "zsh: %r"
1273     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1274 fi
1275
1276 # command not found handling
1277
1278 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1279 function command_not_found_handler() {
1280     emulate -L zsh
1281     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1282         ${GRML_ZSH_CNF_HANDLER} $1
1283     fi
1284     return 1
1285 }
1286
1287 function prompt_grml_help () {
1288     cat <<__EOF0__
1289   prompt grml
1290
1291     This is the prompt as used by the grml-live system <http://grml.org>. It is
1292     a rather simple one-line prompt, that by default looks something like this:
1293
1294         <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1295
1296     The prompt itself integrates with zsh's prompt themes system (as you are
1297     witnessing right now) and is configurable to a certain degree. In
1298     particular, these aspects are customisable:
1299
1300         - The items used in the prompt (e.g. you can remove \`user' from
1301           the list of activated items, which will cause the user name to
1302           be omitted from the prompt string).
1303
1304         - The attributes used with the items are customisable via strings
1305           used before and after the actual item.
1306
1307     The available items are: rc, rc-always, change-root, user, at, host, path,
1308     vcs, percent, sad-smiley, battery.
1309
1310     The actual configuration is done via zsh's \`zstyle' mechanism. The
1311     context, that is used while looking up styles is:
1312
1313         ':prompt:grml:<left-or-right>:<subcontext>'
1314
1315     Here <left-or-right> is either \`left' or \`right', signifying whether the
1316     style should affect the left or the right prompt. <subcontext> is either
1317     \`setup' or 'items:<item>', where \`<item>' is one of the available items.
1318
1319     The styles:
1320
1321         - use-rprompt (boolean): If \`true' (the default), print a sad smiley
1322           in $RPROMPT if the last command a returned non-successful error code.
1323           (This in only valid if <left-or-right> is "right"; ignored otherwise)
1324
1325         - items (list): The list of items used in the prompt. If \`vcs' is
1326           present in the list, the theme's code invokes \`vcs_info'
1327           accordingly. Default: rc user change-root at host path vcs precent
1328
1329     Available styles in 'items:<item>' are: pre, post. These are strings that
1330     are inserted before (pre) and after (post) the item in question. Thus, the
1331     following would cause the user name to be printed in red instead of the
1332     default blue:
1333
1334         zstyle ':prompt:grml:*:items:user' pre '%F{red}'
1335
1336     Note, that the \`post' style may remain at its default value, because its
1337     default value is '%f', which turns the foreground text attribute off (which
1338     is exactly, what is still required with the new \`pre' value).
1339 __EOF0__
1340 }
1341
1342 function grml_prompt_setup () {
1343     emulate -L zsh
1344     autoload -Uz vcs_info
1345     autoload -Uz add-zsh-hook
1346     add-zsh-hook precmd prompt_$1_precmd
1347 }
1348
1349 function prompt_grml_setup () {
1350     grml_prompt_setup grml
1351 }
1352
1353 function prompt_grml-chroot_setup () {
1354     grml_prompt_setup grml-chroot
1355 }
1356
1357 function prompt_grml-large_setup () {
1358     grml_prompt_setup grml-large
1359 }
1360
1361 typeset -gA grml_prompt_pre_default \
1362             grml_prompt_post_default \
1363             grml_prompt_token_default
1364
1365 grml_prompt_pre_default=(
1366     rc                '%F{red}'
1367     rc-always         ''
1368     change-root       ''
1369     user              '%B%F{blue}'
1370     at                ''
1371     host              ''
1372     path              '%b'
1373     vcs               ''
1374     percent           ''
1375     sad-smiley        ''
1376     battery           ' '
1377     newline           ''
1378     jobs              '%F{cyan}'
1379     history           '%F{green}'
1380     date              '%F{blue}'
1381     time              '%F{blue}'
1382     shell-level       '%F{red}'
1383     grml-chroot       '%F{red}'
1384 )
1385
1386 grml_prompt_post_default=(
1387     rc                '%f'
1388     rc-always         ''
1389     change-root       ''
1390     user              '%f%b'
1391     at                ''
1392     host              ''
1393     path              '%B'
1394     vcs               ''
1395     percent           ''
1396     sad-smiley        ''
1397     battery           ''
1398     newline           ''
1399     jobs              '%f'
1400     history           '%f'
1401     date              '%f'
1402     time              '%f'
1403     shell-level       '%f'
1404     grml-chroot       '%f '
1405 )
1406
1407 grml_prompt_token_default=(
1408     rc                '%(?..%? )'
1409     rc-always         '%?'
1410     change-root       'debian_chroot'
1411     user              '%n'
1412     at                '@'
1413     host              '%m '
1414     path              '%40<..<%~%<< '
1415     vcs               '0'
1416     percent           '%% '
1417     sad-smiley        '%(?..:()'
1418     battery           'PERCENT'
1419     newline           $'\n'
1420     jobs              '[%j running job(s)] '
1421     history           '{history#%!} '
1422     date              '%D{%Y-%m-%d}'
1423     time              '%D{%H:%M:%S} '
1424     shell-level       '%(3L.+ .)'
1425     grml-chroot       'GRML_CHROOT'
1426 )
1427
1428 function grml_typeset_and_wrap () {
1429     emulate -L zsh
1430     local target="$1"
1431     local new="$2"
1432     local left="$3"
1433     local right="$4"
1434
1435     if (( ${+parameters[$new]} )); then
1436         typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
1437     fi
1438 }
1439
1440 function grml_prompt_addto () {
1441     emulate -L zsh
1442     local target="$1"
1443     local lr it apre apost new v
1444     local -a items
1445     shift
1446
1447     [[ $target == PS1 ]] && lr=left || lr=right
1448     zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
1449     typeset -g "${target}="
1450     for it in "${items[@]}"; do
1451         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
1452             || apre=${grml_prompt_pre_default[$it]}
1453         zstyle -s ":prompt:grml:${grmltheme}:${lr}:$it" post apost \
1454             || apost=${grml_prompt_post_default[$it]}
1455         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
1456             || new=${grml_prompt_token_default[$it]}
1457         typeset -g "${target}=${(P)target}${apre}"
1458         case $it in
1459             battery)
1460                 grml_typeset_and_wrap $target $new '' ''
1461                 ;;
1462             change-root)
1463                 grml_typeset_and_wrap $target $new '(' ')'
1464                 ;;
1465             grml-chroot)
1466                 if [[ -n ${(P)new} ]]; then
1467                     typeset -g "${target}=${(P)target}(CHROOT)"
1468                 fi
1469                 ;;
1470             vcs)
1471                 v="vcs_info_msg_${new}_"
1472                 if (( ! vcscalled )); then
1473                     vcs_info
1474                     vcscalled=1
1475                 fi
1476                 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
1477                     typeset -g "${target}=${(P)target}${(P)v}"
1478                 fi
1479                 ;;
1480             *) typeset -g "${target}=${(P)target}${new}" ;;
1481         esac
1482         typeset -g "${target}=${(P)target}${apost}"
1483     done
1484 }
1485
1486 function prompt_grml_precmd () {
1487     emulate -L zsh
1488     local grmltheme=grml
1489     local -a left_items right_items
1490     left_items=(rc change-root user at host path vcs percent)
1491     right_items=(sad-smiley)
1492
1493     prompt_grml_precmd_worker
1494 }
1495
1496 function prompt_grml-chroot_precmd () {
1497     emulate -L zsh
1498     local grmltheme=grml-chroot
1499     local -a left_items right_items
1500     left_items=(grml-chroot user at host path percent)
1501     right_items=()
1502
1503     prompt_grml_precmd_worker
1504 }
1505
1506 function prompt_grml-large_precmd () {
1507     emulate -L zsh
1508     local grmltheme=grml-large
1509     local -a left_items right_items
1510     left_items=(rc jobs history shell-level change-root time date newline
1511                 user at host path vcs percent)
1512     right_items=(sad-smiley)
1513
1514     prompt_grml_precmd_worker
1515 }
1516
1517 function prompt_grml_precmd_worker () {
1518     emulate -L zsh
1519     local -i vcscalled=0
1520
1521     grml_prompt_addto PS1 "${left_items[@]}"
1522     if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
1523         grml_prompt_addto RPS1 "${right_items[@]}"
1524     fi
1525 }
1526
1527 # set prompt
1528 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1529     promptinit # people should be able to use their favourite prompt
1530
1531     # Since we define the required functions in here and not in files in
1532     # $fpath, we need to stick the theme's name into `$prompt_themes'
1533     # ourselves, since promptinit does not pick them up otherwise.
1534     prompt_themes+=( grml grml-chroot grml-large )
1535     # Also, keep the array sorted...
1536     prompt_themes=( "${(@on)prompt_themes}" )
1537
1538     if [[ $BATTERY -gt 0 ]]; then
1539         zstyle ':prompt:grml:right:setup' items sad-smiley battery
1540         add-zsh-hook precmd battery
1541     fi
1542     if [[ "$TERM" == dumb ]] ; then
1543         for i in rc user path jobs history date time shell-level; do
1544             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" pre ''
1545             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" post ''
1546         done
1547         unset i
1548         zstyle ':prompt:grml(|-large|-chroot):right:setup' use-rprompt false
1549     elif (( EUID == 0 )); then
1550         zstyle ':prompt:grml(|-large|-chroot):*:items:user' pre '%F{red}'
1551     fi
1552
1553     prompt grml
1554 else
1555     print 'Notice: no promptinit available :('
1556 fi
1557
1558 setopt prompt_subst
1559
1560 # make sure to use right prompt only when not running a command
1561 is41 && setopt transient_rprompt
1562
1563
1564 function ESC_print () {
1565     info_print $'\ek' $'\e\\' "$@"
1566 }
1567 function set_title () {
1568     info_print  $'\e]0;' $'\a' "$@"
1569 }
1570
1571 function info_print () {
1572     local esc_begin esc_end
1573     esc_begin="$1"
1574     esc_end="$2"
1575     shift 2
1576     printf '%s' ${esc_begin}
1577     printf '%s' "$*"
1578     printf '%s' "${esc_end}"
1579 }
1580
1581 function grml_reset_screen_title () {
1582     # adjust title of xterm
1583     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1584     [[ ${NOTITLE:-} -gt 0 ]] && return 0
1585     case $TERM in
1586         (xterm*|rxvt*)
1587             set_title ${(%):-"%n@%m: %~"}
1588             ;;
1589     esac
1590 }
1591
1592 function grml_vcs_to_screen_title () {
1593     if [[ $TERM == screen* ]] ; then
1594         if [[ -n ${vcs_info_msg_1_} ]] ; then
1595             ESC_print ${vcs_info_msg_1_}
1596         else
1597             ESC_print "zsh"
1598         fi
1599     fi
1600 }
1601
1602 zrcautoload add-zsh-hook || add-zsh-hook () { :; }
1603 if [[ $NOPRECMD -gt 0 ]]; then
1604     add-zsh-hook precmd grml_reset_screen_title
1605     add-zsh-hook precmd grml_vcs_to_screen_title
1606 fi
1607
1608 # preexec() => a function running before every command
1609 is4 && [[ $NOPRECMD -eq 0 ]] && \
1610 preexec () {
1611     [[ $NOPRECMD -gt 0 ]] && return 0
1612 # set hostname if not running on host with name 'grml'
1613     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1614        NAME="@$HOSTNAME"
1615     fi
1616 # get the name of the program currently running and hostname of local machine
1617 # set screen window title if running in a screen
1618     if [[ "$TERM" == screen* ]] ; then
1619         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1620         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1621         ESC_print ${CMD}
1622     fi
1623 # adjust title of xterm
1624     [[ ${NOTITLE} -gt 0 ]] && return 0
1625     case $TERM in
1626         (xterm*|rxvt*)
1627             set_title "${(%):-"%n@%m:"}" "$1"
1628             ;;
1629     esac
1630 }
1631
1632 EXITCODE="%(?..%?%1v )"
1633 # secondary prompt, printed when the shell needs more information to complete a
1634 # command.
1635 PS2='\`%_> '
1636 # selection prompt used within a select loop.
1637 PS3='?# '
1638 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1639 PS4='+%N:%i:%_> '
1640
1641 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1642 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1643     debian_chroot=$(cat /etc/debian_chroot)
1644 fi
1645
1646 # don't use colors on dumb terminals (like emacs):
1647 if [[ "$TERM" == dumb ]] ; then
1648     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
1649 else
1650     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended
1651     # prompt set variable identifying the chroot you work in (used in the
1652     # prompt below)
1653     if [[ $GRMLPROMPT -gt 0 ]] ; then
1654         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1655 ${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "
1656     else
1657         # This assembles the primary prompt string
1658         if (( EUID != 0 )); then
1659             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "
1660         else
1661             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "
1662         fi
1663     fi
1664 fi
1665
1666 PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
1667
1668 # if we are inside a grml-chroot set a specific prompt theme
1669 if [[ -n "$GRML_CHROOT" ]] ; then
1670     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1671 fi
1672
1673 # 'hash' some often used directories
1674 #d# start
1675 hash -d deb=/var/cache/apt/archives
1676 hash -d doc=/usr/share/doc
1677 hash -d linux=/lib/modules/$(command uname -r)/build/
1678 hash -d log=/var/log
1679 hash -d slog=/var/log/syslog
1680 hash -d src=/usr/src
1681 hash -d templ=/usr/share/doc/grml-templates
1682 hash -d tt=/usr/share/doc/texttools-doc
1683 hash -d www=/var/www
1684 #d# end
1685
1686 # some aliases
1687 if check_com -c screen ; then
1688     if [[ $UID -eq 0 ]] ; then
1689         if [[ -r /etc/grml/screenrc ]]; then
1690             alias screen="${commands[screen]} -c /etc/grml/screenrc"
1691         fi
1692     elif [[ -r $HOME/.screenrc ]] ; then
1693         alias screen="${commands[screen]} -c $HOME/.screenrc"
1694     else
1695         if [[ -r /etc/grml/screenrc_grml ]]; then
1696             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1697         else
1698             if [[ -r /etc/grml/screenrc ]]; then
1699                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
1700             fi
1701         fi
1702     fi
1703 fi
1704
1705 # do we have GNU ls with color-support?
1706 if [[ "$TERM" != dumb ]]; then
1707     #a1# execute \kbd{@a@}:\quad ls with colors
1708     alias ls='ls -b -CF '${ls_options:+"${ls_options[*]}"}
1709     #a1# execute \kbd{@a@}:\quad list all files, with colors
1710     alias la='ls -la '${ls_options:+"${ls_options[*]}"}
1711     #a1# long colored list, without dotfiles (@a@)
1712     alias ll='ls -l '${ls_options:+"${ls_options[*]}"}
1713     #a1# long colored list, human readable sizes (@a@)
1714     alias lh='ls -hAl '${ls_options:+"${ls_options[*]}"}
1715     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1716     alias l='ls -lF '${ls_options:+"${ls_options[*]}"}
1717 else
1718     alias ls='ls -b -CF'
1719     alias la='ls -la'
1720     alias ll='ls -l'
1721     alias lh='ls -hAl'
1722     alias l='ls -lF'
1723 fi
1724
1725 alias mdstat='cat /proc/mdstat'
1726 alias ...='cd ../../'
1727
1728 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1729 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1730     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1731 fi
1732
1733 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1734 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1735 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1736
1737 # make sure it is not assigned yet
1738 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1739 utf2iso() {
1740     if isutfenv ; then
1741         for ENV in $(env | command grep -i '.utf') ; do
1742             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1743         done
1744     fi
1745 }
1746
1747 # make sure it is not assigned yet
1748 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1749 iso2utf() {
1750     if ! isutfenv ; then
1751         for ENV in $(env | command grep -i '\.iso') ; do
1752             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1753         done
1754     fi
1755 }
1756
1757 # especially for roadwarriors using GNU screen and ssh:
1758 if ! check_com asc &>/dev/null ; then
1759   asc() { autossh -t "$@" 'screen -RdU' }
1760   compdef asc=ssh
1761 fi
1762
1763 #f1# Hints for the use of zsh on grml
1764 zsh-help() {
1765     print "$bg[white]$fg[black]
1766 zsh-help - hints for use of zsh on grml
1767 =======================================$reset_color"
1768
1769     print '
1770 Main configuration of zsh happens in /etc/zsh/zshrc.
1771 That file is part of the package grml-etc-core, if you want to
1772 use them on a non-grml-system just get the tar.gz from
1773 http://deb.grml.org/ or (preferably) get it from the git repository:
1774
1775   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1776
1777 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1778 The file is still there, but it is empty for backwards compatibility.
1779
1780 For your own changes use these two files:
1781     $HOME/.zshrc.pre
1782     $HOME/.zshrc.local
1783
1784 The former is sourced very early in our zshrc, the latter is sourced
1785 very lately.
1786
1787 System wide configuration without touching configuration files of grml
1788 can take place in /etc/zsh/zshrc.local.
1789
1790 For information regarding zsh start at http://grml.org/zsh/
1791
1792 Take a look at grml'\''s zsh refcard:
1793 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1794
1795 Check out the main zsh refcard:
1796 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1797
1798 And of course visit the zsh-lovers:
1799 % man zsh-lovers
1800
1801 You can adjust some options through environment variables when
1802 invoking zsh without having to edit configuration files.
1803 Basically meant for bash users who are not used to the power of
1804 the zsh yet. :)
1805
1806   "NOCOR=1    zsh" => deactivate automatic correction
1807   "NOMENU=1   zsh" => do not use auto menu completion
1808                       (note: use ctrl-d for completion instead!)
1809   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1810   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1811                       preexec() and precmd() completely
1812   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1813   "COMMAND_NOT_FOUND=1 zsh"
1814                    => Enable a handler if an external command was not found
1815                       The command called in the handler can be altered by setting
1816                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1817                       "/usr/share/command-not-found/command-not-found"
1818
1819 A value greater than 0 is enables a feature; a value equal to zero
1820 disables it. If you like one or the other of these settings, you can
1821 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1822 zshrc.'
1823
1824     print "
1825 $bg[white]$fg[black]
1826 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1827 Enjoy your grml system with the zsh!$reset_color"
1828 }
1829
1830 # debian stuff
1831 if [[ -r /etc/debian_version ]] ; then
1832     #a3# Execute \kbd{apt-cache search}
1833     alias acs='apt-cache search'
1834     #a3# Execute \kbd{apt-cache show}
1835     alias acsh='apt-cache show'
1836     #a3# Execute \kbd{apt-cache policy}
1837     alias acp='apt-cache policy'
1838     #a3# Execute \kbd{apt-get dist-upgrade}
1839     salias adg="apt-get dist-upgrade"
1840     #a3# Execute \kbd{apt-get install}
1841     salias agi="apt-get install"
1842     #a3# Execute \kbd{aptitude install}
1843     salias ati="aptitude install"
1844     #a3# Execute \kbd{apt-get upgrade}
1845     salias ag="apt-get upgrade"
1846     #a3# Execute \kbd{apt-get update}
1847     salias au="apt-get update"
1848     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1849     salias -a up="aptitude update ; aptitude safe-upgrade"
1850     #a3# Execute \kbd{dpkg-buildpackage}
1851     alias dbp='dpkg-buildpackage'
1852     #a3# Execute \kbd{grep-excuses}
1853     alias ge='grep-excuses'
1854
1855     # get a root shell as normal user in live-cd mode:
1856     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1857        alias su="sudo su"
1858      fi
1859
1860     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1861     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1862     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1863     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1864 fi
1865
1866 # sort installed Debian-packages by size
1867 if check_com -c dpkg-query ; then
1868     #a3# List installed Debian-packages sorted by size
1869     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1870 fi
1871
1872 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1873 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1874     if check_com -c wodim; then
1875         cdrecord() {
1876             cat <<EOMESS
1877 cdrecord is not provided under its original name by Debian anymore.
1878 See #377109 in the BTS of Debian for more details.
1879
1880 Please use the wodim binary instead
1881 EOMESS
1882             return 1
1883         }
1884     fi
1885 fi
1886
1887 # Use hard limits, except for a smaller stack and no core dumps
1888 unlimit
1889 is425 && limit stack 8192
1890 isgrmlcd && limit core 0 # important for a live-cd-system
1891 limit -s
1892
1893 # completion system
1894
1895 # called later (via is4 && grmlcomp)
1896 # note: use 'zstyle' for getting current settings
1897 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
1898 grmlcomp() {
1899     # TODO: This could use some additional information
1900
1901     # allow one error for every three characters typed in approximate completer
1902     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1903
1904     # don't complete backup files as executables
1905     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1906
1907     # start menu completion only if it could find no unambiguous initial string
1908     zstyle ':completion:*:correct:*'       insert-unambiguous true
1909     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1910     zstyle ':completion:*:correct:*'       original true
1911
1912     # activate color-completion
1913     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1914
1915     # format on completion
1916     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1917
1918     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1919     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1920
1921     # insert all expansions for expand completer
1922     zstyle ':completion:*:expand:*'        tag-order all-expansions
1923     zstyle ':completion:*:history-words'   list false
1924
1925     # activate menu
1926     zstyle ':completion:*:history-words'   menu yes
1927
1928     # ignore duplicate entries
1929     zstyle ':completion:*:history-words'   remove-all-dups yes
1930     zstyle ':completion:*:history-words'   stop yes
1931
1932     # match uppercase from lowercase
1933     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1934
1935     # separate matches into groups
1936     zstyle ':completion:*:matches'         group 'yes'
1937     zstyle ':completion:*'                 group-name ''
1938
1939     if [[ "$NOMENU" -eq 0 ]] ; then
1940         # if there are more than 5 options allow selecting from a menu
1941         zstyle ':completion:*'               menu select=5
1942     else
1943         # don't use any menus at all
1944         setopt no_auto_menu
1945     fi
1946
1947     zstyle ':completion:*:messages'        format '%d'
1948     zstyle ':completion:*:options'         auto-description '%d'
1949
1950     # describe options in full
1951     zstyle ':completion:*:options'         description 'yes'
1952
1953     # on processes completion complete all user processes
1954     zstyle ':completion:*:processes'       command 'ps -au$USER'
1955
1956     # offer indexes before parameters in subscripts
1957     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1958
1959     # provide verbose completion information
1960     zstyle ':completion:*'                 verbose true
1961
1962     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1963     # for commands (read: 1st word in the line) that it will list for the user
1964     # to choose from. The following disables that, because it's not exactly fast.
1965     zstyle ':completion:*:-command-:*:'    verbose false
1966
1967     # set format for warnings
1968     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1969
1970     # define files to ignore for zcompile
1971     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1972     zstyle ':completion:correct:'          prompt 'correct to: %e'
1973
1974     # Ignore completion functions for commands you don't have:
1975     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1976
1977     # Provide more processes in completion of programs like killall:
1978     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1979
1980     # complete manual by their section
1981     zstyle ':completion:*:manuals'    separate-sections true
1982     zstyle ':completion:*:manuals.*'  insert-sections   true
1983     zstyle ':completion:*:man:*'      menu yes select
1984
1985     # Search path for sudo completion
1986     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
1987                                                /usr/local/bin  \
1988                                                /usr/sbin       \
1989                                                /usr/bin        \
1990                                                /sbin           \
1991                                                /bin            \
1992                                                /usr/X11R6/bin
1993
1994     # provide .. as a completion
1995     zstyle ':completion:*' special-dirs ..
1996
1997     # run rehash on completion so new installed program are found automatically:
1998     _force_rehash() {
1999         (( CURRENT == 1 )) && rehash
2000         return 1
2001     }
2002
2003     ## correction
2004     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
2005     if [[ "$NOCOR" -gt 0 ]] ; then
2006         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
2007         setopt nocorrect
2008     else
2009         # try to be smart about when to use what completer...
2010         setopt correct
2011         zstyle -e ':completion:*' completer '
2012             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
2013                 _last_try="$HISTNO$BUFFER$CURSOR"
2014                 reply=(_complete _match _ignored _prefix _files)
2015             else
2016                 if [[ $words[1] == (rm|mv) ]] ; then
2017                     reply=(_complete _files)
2018                 else
2019                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
2020                 fi
2021             fi'
2022     fi
2023
2024     # command for process lists, the local web server details and host completion
2025     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
2026
2027     # caching
2028     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
2029                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
2030
2031     # host completion
2032     if is42 ; then
2033         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
2034         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
2035     else
2036         _ssh_hosts=()
2037         _etc_hosts=()
2038     fi
2039     hosts=(
2040         $(hostname)
2041         "$_ssh_hosts[@]"
2042         "$_etc_hosts[@]"
2043         localhost
2044     )
2045     zstyle ':completion:*:hosts' hosts $hosts
2046     # TODO: so, why is this here?
2047     #  zstyle '*' hosts $hosts
2048
2049     # use generic completion system for programs not yet defined; (_gnu_generic works
2050     # with commands that provide a --help option with "standard" gnu-like output.)
2051     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
2052                    pal stow tail uname ; do
2053         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
2054     done; unset compcom
2055
2056     # see upgrade function in this file
2057     compdef _hosts upgrade
2058 }
2059
2060 # grmlstuff
2061 grmlstuff() {
2062 # people should use 'grml-x'!
2063     if check_com -c 915resolution; then
2064         855resolution() {
2065             echo "Please use 915resolution as resolution modifying tool for Intel \
2066 graphic chipset."
2067             return -1
2068         }
2069     fi
2070
2071     #a1# Output version of running grml
2072     alias grml-version='cat /etc/grml_version'
2073
2074     if check_com -c rebuildfstab ; then
2075         #a1# Rebuild /etc/fstab
2076         alias grml-rebuildfstab='rebuildfstab -v -r -config'
2077     fi
2078
2079     if check_com -c grml-debootstrap ; then
2080         debian2hd() {
2081             echo "Installing debian to harddisk is possible by using grml-debootstrap."
2082             return 1
2083         }
2084     fi
2085 }
2086
2087 # now run the functions
2088 isgrml && checkhome
2089 is4    && isgrml    && grmlstuff
2090 is4    && grmlcomp
2091
2092 # keephack
2093 is4 && xsource "/etc/zsh/keephack"
2094
2095 # wonderful idea of using "e" glob qualifier by Peter Stephenson
2096 # You use it as follows:
2097 # $ NTREF=/reference/file
2098 # $ ls -l *(e:nt:)
2099 # This lists all the files in the current directory newer than the reference file.
2100 # You can also specify the reference file inline; note quotes:
2101 # $ ls -l *(e:'nt ~/.zshenv':)
2102 is4 && nt() {
2103     if [[ -n $1 ]] ; then
2104         local NTREF=${~1}
2105     fi
2106     [[ $REPLY -nt $NTREF ]]
2107 }
2108
2109 # shell functions
2110
2111 #f1# Reload an autoloadable function
2112 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2113 compdef _functions freload
2114
2115 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2116 sll() {
2117     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2118     for file in "$@" ; do
2119         while [[ -h "$file" ]] ; do
2120             ls -l $file
2121             file=$(readlink "$file")
2122         done
2123     done
2124 }
2125
2126 # TODO: Is it supported to use pager settings like this?
2127 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2128 # with respect to wordsplitting. (ie. ${=PAGER})
2129 if check_com -c $PAGER ; then
2130     #f1# View Debian's changelog of a given package
2131     dchange() {
2132         emulate -L zsh
2133         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
2134             $PAGER /usr/share/doc/$1/changelog.Debian.gz
2135         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2136             $PAGER /usr/share/doc/$1/changelog.gz
2137         else
2138             if check_com -c aptitude ; then
2139                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2140                 if isgrml ; then
2141                     aptitude -t unstable changelog $1
2142                 else
2143                     aptitude changelog $1
2144                 fi
2145             else
2146                 echo "No changelog for package $1 found, sorry."
2147                 return 1
2148             fi
2149         fi
2150     }
2151     _dchange() { _files -W /usr/share/doc -/ }
2152     compdef _dchange dchange
2153
2154     #f1# View Debian's NEWS of a given package
2155     dnews() {
2156         emulate -L zsh
2157         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2158             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2159         else
2160             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2161                 $PAGER /usr/share/doc/$1/NEWS.gz
2162             else
2163                 echo "No NEWS file for package $1 found, sorry."
2164                 return 1
2165             fi
2166         fi
2167     }
2168     _dnews() { _files -W /usr/share/doc -/ }
2169     compdef _dnews dnews
2170
2171     #f1# View Debian's copyright of a given package
2172     dcopyright() {
2173         emulate -L zsh
2174         if [[ -r /usr/share/doc/$1/copyright ]] ; then
2175             $PAGER /usr/share/doc/$1/copyright
2176         else
2177             echo "No copyright file for package $1 found, sorry."
2178             return 1
2179         fi
2180     }
2181     _dcopyright() { _files -W /usr/share/doc -/ }
2182     compdef _dcopyright dcopyright
2183
2184     #f1# View upstream's changelog of a given package
2185     uchange() {
2186         emulate -L zsh
2187         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2188             $PAGER /usr/share/doc/$1/changelog.gz
2189         else
2190             echo "No changelog for package $1 found, sorry."
2191             return 1
2192         fi
2193     }
2194     _uchange() { _files -W /usr/share/doc -/ }
2195     compdef _uchange uchange
2196 fi
2197
2198 # zsh profiling
2199 profile() {
2200     ZSH_PROFILE_RC=1 $SHELL "$@"
2201 }
2202
2203 #f1# Edit an alias via zle
2204 edalias() {
2205     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2206 }
2207 compdef _aliases edalias
2208
2209 #f1# Edit a function via zle
2210 edfunc() {
2211     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2212 }
2213 compdef _functions edfunc
2214
2215 # use it e.g. via 'Restart apache2'
2216 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2217 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2218 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2219 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2220 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2221 #m# f6 Status() \kbd{/etc/init.d/\em{process}}\quad\kbd{status}
2222 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2223     __start_stop() {
2224         local action_="${1:l}"  # e.g Start/Stop/Restart
2225         local service_="$2"
2226         local param_="$3"
2227
2228         local service_target_="$(readlink /etc/init.d/$service_)"
2229         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2230             # runit
2231             case "${action_}" in
2232                 start) if [[ ! -e /etc/service/$service_ ]]; then
2233                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2234                        else
2235                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2236                        fi ;;
2237                 # there is no reload in runits sysv emulation
2238                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2239                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2240             esac
2241         else
2242             # sysvinit
2243             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2244         fi
2245     }
2246
2247     _grmlinitd() {
2248         local -a scripts
2249         scripts=( /etc/init.d/*(x:t) )
2250         _describe "service startup script" scripts
2251     }
2252
2253     for i in Start Restart Stop Force-Reload Reload Status ; do
2254         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2255         compdef _grmlinitd $i
2256     done
2257 fi
2258
2259 #f1# Provides useful information on globbing
2260 H-Glob() {
2261     echo -e "
2262     /      directories
2263     .      plain files
2264     @      symbolic links
2265     =      sockets
2266     p      named pipes (FIFOs)
2267     *      executable plain files (0100)
2268     %      device files (character or block special)
2269     %b     block special files
2270     %c     character special files
2271     r      owner-readable files (0400)
2272     w      owner-writable files (0200)
2273     x      owner-executable files (0100)
2274     A      group-readable files (0040)
2275     I      group-writable files (0020)
2276     E      group-executable files (0010)
2277     R      world-readable files (0004)
2278     W      world-writable files (0002)
2279     X      world-executable files (0001)
2280     s      setuid files (04000)
2281     S      setgid files (02000)
2282     t      files with the sticky bit (01000)
2283
2284   print *(m-1)          # Files modified up to a day ago
2285   print *(a1)           # Files accessed a day ago
2286   print *(@)            # Just symlinks
2287   print *(Lk+50)        # Files bigger than 50 kilobytes
2288   print *(Lk-50)        # Files smaller than 50 kilobytes
2289   print **/*.c          # All *.c files recursively starting in \$PWD
2290   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2291   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2292   print *~*.*           # All Files that do not contain a dot
2293   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2294   print -l *(.c|.h)     # Lists *.c and *.h
2295   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2296   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2297 }
2298 alias help-zshglob=H-Glob
2299
2300 #v1# set number of lines to display per page
2301 HELP_LINES_PER_PAGE=20
2302 #v1# set location of help-zle cache file
2303 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
2304 #f1# helper function for help-zle, actually generates the help text
2305 help_zle_parse_keybindings()
2306 {
2307     emulate -L zsh
2308     setopt extendedglob
2309     unsetopt ksharrays  #indexing starts at 1
2310
2311     #v1# choose files that help-zle will parse for keybindings
2312     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
2313
2314     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
2315         local load_cache=0
2316         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
2317         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
2318     fi
2319
2320     #fill with default keybindings, possibly to be overwriten in a file later
2321     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2322     local -A help_zle_keybindings
2323     help_zle_keybindings['<Ctrl>@']="set MARK"
2324     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
2325     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
2326     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
2327     help_zle_keybindings['<Ctrl>_']="undo"
2328     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
2329     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
2330     help_zle_keybindings['<Ctrl>e']="goto end of line"
2331     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2332     help_zle_keybindings['<Alt>t']="transpose words"
2333     help_zle_keybindings['<Alt>s']="spellcheck word"
2334     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
2335     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
2336     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2337     help_zle_keybindings["<Alt>'"]="quote line"
2338     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2339     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2340     help_zle_keybindings['<Alt>u']="make next word Uppercase"
2341     help_zle_keybindings['<Alt>l']="make next word lowercase"
2342     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
2343     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2344     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2345     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2346     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2347     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
2348     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2349     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2350     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
2351
2352     #init global variables
2353     unset help_zle_lines help_zle_sln
2354     typeset -g -a help_zle_lines
2355     typeset -g help_zle_sln=1
2356
2357     local k v
2358     local lastkeybind_desc contents     #last description starting with #k# that we found
2359     local num_lines_elapsed=0            #number of lines between last description and keybinding
2360     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2361     for f in $HELPZLE_KEYBINDING_FILES; do
2362         [[ -r "$f" ]] || continue   #not readable ? skip it
2363         contents="$(<$f)"
2364         for cline in "${(f)contents}"; do
2365             #zsh pattern: matches lines like: #k# ..............
2366             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2367                 lastkeybind_desc="$match[*]"
2368                 num_lines_elapsed=0
2369             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2370             #             ignores lines that are commentend out
2371             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2372             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2373                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2374                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2375                     #substitute keybinding string with something readable
2376                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2377                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2378                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2379                     help_zle_keybindings[${k}]=$lastkeybind_desc
2380                 fi
2381                 lastkeybind_desc=""
2382             else
2383               ((num_lines_elapsed++))
2384             fi
2385         done
2386     done
2387     unset contents
2388     #calculate length of keybinding column
2389     local kstrlen=0
2390     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2391     #convert the assoc array into preformated lines, which we are able to sort
2392     for k v in ${(kv)help_zle_keybindings[@]}; do
2393         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2394         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2395     done
2396     #sort lines alphabetically
2397     help_zle_lines=("${(i)help_zle_lines[@]}")
2398     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2399     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2400     zcompile $HELP_ZLE_CACHE_FILE
2401 }
2402 typeset -g help_zle_sln
2403 typeset -g -a help_zle_lines
2404
2405 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2406 help-zle()
2407 {
2408     emulate -L zsh
2409     unsetopt ksharrays  #indexing starts at 1
2410     #help lines already generated ? no ? then do it
2411     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2412     #already displayed all lines ? go back to the start
2413     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2414     local sln=$help_zle_sln
2415     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2416     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2417     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2418 }
2419 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2420 zle -N help-zle && bindkey '^xz' help-zle
2421
2422 # grep for running process, like: 'any vim'
2423 any() {
2424     emulate -L zsh
2425     unsetopt KSH_ARRAYS
2426     if [[ -z "$1" ]] ; then
2427         echo "any - grep for process(es) by keyword" >&2
2428         echo "Usage: any <keyword>" >&2 ; return 1
2429     else
2430         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
2431     fi
2432 }
2433
2434
2435 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2436 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2437 [[ -r /proc/1/maps ]] && \
2438 deswap() {
2439     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2440     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2441     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2442 }
2443
2444 # a wrapper for vim, that deals with title setting
2445 #   VIM_OPTIONS
2446 #       set this array to a set of options to vim you always want
2447 #       to have set when calling vim (in .zshrc.local), like:
2448 #           VIM_OPTIONS=( -p )
2449 #       This will cause vim to send every file given on the
2450 #       commandline to be send to it's own tab (needs vim7).
2451 if check_com vim; then
2452     vim() {
2453         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2454     }
2455 fi
2456
2457 # make a backup of a file
2458 bk() {
2459     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2460 }
2461
2462 ssl_hashes=( sha512 sha256 sha1 md5 )
2463
2464 for sh in ${ssl_hashes}; do
2465     eval 'ssl-cert-'${sh}'() {
2466         emulate -L zsh
2467         if [[ -z $1 ]] ; then
2468             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2469             return 1
2470         fi
2471         openssl x509 -noout -fingerprint -'${sh}' -in $1
2472     }'
2473 done; unset sh
2474
2475 ssl-cert-fingerprints() {
2476     emulate -L zsh
2477     local i
2478     if [[ -z $1 ]] ; then
2479         printf 'usage: ssl-cert-fingerprints <file>\n'
2480         return 1
2481     fi
2482     for i in ${ssl_hashes}
2483         do ssl-cert-$i $1;
2484     done
2485 }
2486
2487 ssl-cert-info() {
2488     emulate -L zsh
2489     if [[ -z $1 ]] ; then
2490         printf 'usage: ssl-cert-info <file>\n'
2491         return 1
2492     fi
2493     openssl x509 -noout -text -in $1
2494     ssl-cert-fingerprints $1
2495 }
2496
2497 # make sure our environment is clean regarding colors
2498 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2499
2500 # "persistent history"
2501 # just write important commands you always need to ~/.important_commands
2502 if [[ -r ~/.important_commands ]] ; then
2503     fc -R ~/.important_commands
2504 fi
2505
2506 # load the lookup subsystem if it's available on the system
2507 zrcautoload lookupinit && lookupinit
2508
2509 # variables
2510
2511 # set terminal property (used e.g. by msgid-chooser)
2512 export COLORTERM="yes"
2513
2514 # aliases
2515
2516 # general
2517 #a2# Execute \kbd{du -sch}
2518 alias da='du -sch'
2519 #a2# Execute \kbd{jobs -l}
2520 alias j='jobs -l'
2521
2522 # listing stuff
2523 #a2# Execute \kbd{ls -lSrah}
2524 alias dir="ls -lSrah"
2525 #a2# Only show dot-directories
2526 alias lad='ls -d .*(/)'
2527 #a2# Only show dot-files
2528 alias lsa='ls -a .*(.)'
2529 #a2# Only files with setgid/setuid/sticky flag
2530 alias lss='ls -l *(s,S,t)'
2531 #a2# Only show symlinks
2532 alias lsl='ls -l *(@)'
2533 #a2# Display only executables
2534 alias lsx='ls -l *(*)'
2535 #a2# Display world-{readable,writable,executable} files
2536 alias lsw='ls -ld *(R,W,X.^ND/)'
2537 #a2# Display the ten biggest files
2538 alias lsbig="ls -flh *(.OL[1,10])"
2539 #a2# Only show directories
2540 alias lsd='ls -d *(/)'
2541 #a2# Only show empty directories
2542 alias lse='ls -d *(/^F)'
2543 #a2# Display the ten newest files
2544 alias lsnew="ls -rtlh *(D.om[1,10])"
2545 #a2# Display the ten oldest files
2546 alias lsold="ls -rtlh *(D.Om[1,10])"
2547 #a2# Display the ten smallest files
2548 alias lssmall="ls -Srl *(.oL[1,10])"
2549 #a2# Display the ten newest directories and ten newest .directories
2550 alias lsnewdir="ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
2551 #a2# Display the ten oldest directories and ten oldest .directories
2552 alias lsolddir="ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
2553
2554 # some useful aliases
2555 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir $OLDCWD}
2556 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2557
2558 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2559 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2560 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2561
2562 # work around non utf8 capable software in utf environment via $LANG and luit
2563 if check_com isutfenv && check_com luit ; then
2564     if check_com -c mrxvt ; then
2565         isutfenv && [[ -n "$LANG" ]] && \
2566             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2567     fi
2568
2569     if check_com -c aterm ; then
2570         isutfenv && [[ -n "$LANG" ]] && \
2571             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2572     fi
2573
2574     if check_com -c centericq ; then
2575         isutfenv && [[ -n "$LANG" ]] && \
2576             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2577     fi
2578 fi
2579
2580 # useful functions
2581
2582 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2583 bk() {
2584     emulate -L zsh
2585     cp -b $1 $1_`date --iso-8601=m`
2586 }
2587
2588 #f5# cd to directoy and list files
2589 cl() {
2590     emulate -L zsh
2591     cd $1 && ls -a
2592 }
2593
2594 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2595 cd() {
2596     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2597         [[ ! -e ${1:h} ]] && return 1
2598         print "Correcting ${1} to ${1:h}"
2599         builtin cd ${1:h}
2600     else
2601         builtin cd "$@"
2602     fi
2603 }
2604
2605 #f5# Create Directoy and \kbd{cd} to it
2606 mkcd() {
2607     if (( ARGC != 1 )); then
2608         printf 'usage: mkcd <new-directory>\n'
2609         return 1;
2610     fi
2611     if [[ ! -d "$1" ]]; then
2612         command mkdir -p "$1"
2613     else
2614         printf '`%s'\'' already exists: cd-ing.\n' "$1"
2615     fi
2616     builtin cd "$1"
2617 }
2618
2619 #f5# Create temporary directory and \kbd{cd} to it
2620 cdt() {
2621     local t
2622     t=$(mktemp -d)
2623     echo "$t"
2624     builtin cd "$t"
2625 }
2626
2627 #f5# Create directory under cursor or the selected area
2628 # Press ctrl-xM to create the directory under the cursor or the selected area.
2629 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2630 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2631 # directory does not exist yet -> press ctrl-XM and problem solved
2632 inplaceMkDirs() {
2633     local PATHTOMKDIR
2634     if ((REGION_ACTIVE==1)); then
2635         local F=$MARK T=$CURSOR
2636         if [[ $F -gt $T ]]; then
2637             F=${CURSOR}
2638             T=${MARK}
2639         fi
2640         # get marked area from buffer and eliminate whitespace
2641         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2642         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2643     else
2644         local bufwords iword
2645         bufwords=(${(z)LBUFFER})
2646         iword=${#bufwords}
2647         bufwords=(${(z)BUFFER})
2648         PATHTOMKDIR="${(Q)bufwords[iword]}"
2649     fi
2650     [[ -z "${PATHTOMKDIR}" ]] && return 1
2651     PATHTOMKDIR=${~PATHTOMKDIR}
2652     if [[ -e "${PATHTOMKDIR}" ]]; then
2653         zle -M " path already exists, doing nothing"
2654     else
2655         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2656         zle end-of-line
2657     fi
2658 }
2659 #k# mkdir -p <dir> from string under cursor or marked area
2660 zle -N inplaceMkDirs && bindkey '^xM' inplaceMkDirs
2661
2662 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2663 accessed() {
2664     emulate -L zsh
2665     print -l -- *(a-${1:-1})
2666 }
2667
2668 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2669 changed() {
2670     emulate -L zsh
2671     print -l -- *(c-${1:-1})
2672 }
2673
2674 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2675 modified() {
2676     emulate -L zsh
2677     print -l -- *(m-${1:-1})
2678 }
2679 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2680 check_com new || alias new=modified
2681
2682 # use colors when GNU grep with color-support
2683 #a2# Execute \kbd{grep -{}-color=auto}
2684 (( $#grep_options > 0 )) && alias grep='grep '${grep_options:+"${grep_options[*]}"}
2685
2686 # Translate DE<=>EN
2687 # 'translate' looks up fot a word in a file with language-to-language
2688 # translations (field separator should be " : "). A typical wordlist looks
2689 # like at follows:
2690 #  | english-word : german-transmission
2691 # It's also only possible to translate english to german but not reciprocal.
2692 # Use the following oneliner to turn back the sort order:
2693 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2694 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2695 #f5# Translates a word
2696 trans() {
2697     emulate -L zsh
2698     case "$1" in
2699         -[dD]*)
2700             translate -l de-en $2
2701             ;;
2702         -[eE]*)
2703             translate -l en-de $2
2704             ;;
2705         *)
2706             echo "Usage: $0 { -D | -E }"
2707             echo "         -D == German to English"
2708             echo "         -E == English to German"
2709     esac
2710 }
2711
2712 # Usage: simple-extract <file>
2713 # Using option -d deletes the original archive file.
2714 #f5# Smart archive extractor
2715 simple-extract() {
2716     emulate -L zsh
2717     setopt extended_glob noclobber
2718     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2719     local RC=0
2720     zparseopts -D -E "d=DELETE_ORIGINAL"
2721     for ARCHIVE in "${@}"; do
2722         case $ARCHIVE in
2723             *(tar.bz2|tbz2|tbz))
2724                 DECOMP_CMD="tar -xvjf -"
2725                 USES_STDIN=true
2726                 USES_STDOUT=false
2727                 ;;
2728             *(tar.gz|tgz))
2729                 DECOMP_CMD="tar -xvzf -"
2730                 USES_STDIN=true
2731                 USES_STDOUT=false
2732                 ;;
2733             *(tar.xz|txz|tar.lzma))
2734                 DECOMP_CMD="tar -xvJf -"
2735                 USES_STDIN=true
2736                 USES_STDOUT=false
2737                 ;;
2738             *tar)
2739                 DECOMP_CMD="tar -xvf -"
2740                 USES_STDIN=true
2741                 USES_STDOUT=false
2742                 ;;
2743             *rar)
2744                 DECOMP_CMD="unrar x"
2745                 USES_STDIN=false
2746                 USES_STDOUT=false
2747                 ;;
2748             *lzh)
2749                 DECOMP_CMD="lha x"
2750                 USES_STDIN=false
2751                 USES_STDOUT=false
2752                 ;;
2753             *7z)
2754                 DECOMP_CMD="7z x"
2755                 USES_STDIN=false
2756                 USES_STDOUT=false
2757                 ;;
2758             *(zip|jar))
2759                 DECOMP_CMD="unzip"
2760                 USES_STDIN=false
2761                 USES_STDOUT=false
2762                 ;;
2763             *deb)
2764                 DECOMP_CMD="ar -x"
2765                 USES_STDIN=false
2766                 USES_STDOUT=false
2767                 ;;
2768             *bz2)
2769                 DECOMP_CMD="bzip2 -d -c -"
2770                 USES_STDIN=true
2771                 USES_STDOUT=true
2772                 ;;
2773             *(gz|Z))
2774                 DECOMP_CMD="gzip -d -c -"
2775                 USES_STDIN=true
2776                 USES_STDOUT=true
2777                 ;;
2778             *(xz|lzma))
2779                 DECOMP_CMD="xz -d -c -"
2780                 USES_STDIN=true
2781                 USES_STDOUT=true
2782                 ;;
2783             *)
2784                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2785                 RC=$((RC+1))
2786                 continue
2787                 ;;
2788         esac
2789
2790         if ! check_com ${DECOMP_CMD[(w)1]}; then
2791             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2792             RC=$((RC+2))
2793             continue
2794         fi
2795
2796         GZTARGET="${ARCHIVE:t:r}"
2797         if [[ -f $ARCHIVE ]] ; then
2798
2799             print "Extracting '$ARCHIVE' ..."
2800             if $USES_STDIN; then
2801                 if $USES_STDOUT; then
2802                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
2803                 else
2804                     ${=DECOMP_CMD} < "$ARCHIVE"
2805                 fi
2806             else
2807                 if $USES_STDOUT; then
2808                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
2809                 else
2810                     ${=DECOMP_CMD} "$ARCHIVE"
2811                 fi
2812             fi
2813             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
2814
2815         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
2816             if check_com curl; then
2817                 WGET_CMD="curl -L -k -s -o -"
2818             elif check_com wget; then
2819                 WGET_CMD="wget -q -O - --no-check-certificate"
2820             else
2821                 print "ERROR: neither wget nor curl is installed" >&2
2822                 RC=$((RC+4))
2823                 continue
2824             fi
2825             print "Downloading and Extracting '$ARCHIVE' ..."
2826             if $USES_STDIN; then
2827                 if $USES_STDOUT; then
2828                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
2829                     RC=$((RC+$?))
2830                 else
2831                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
2832                     RC=$((RC+$?))
2833                 fi
2834             else
2835                 if $USES_STDOUT; then
2836                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
2837                 else
2838                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
2839                 fi
2840             fi
2841
2842         else
2843             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
2844             RC=$((RC+8))
2845         fi
2846     done
2847     return $RC
2848 }
2849
2850 __archive_or_uri()
2851 {
2852     _alternative \
2853         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
2854         '_urls:Remote Archives:_urls'
2855 }
2856
2857 _simple_extract()
2858 {
2859     _arguments \
2860         '-d[delete original archivefile after extraction]' \
2861         '*:Archive Or Uri:__archive_or_uri'
2862 }
2863 compdef _simple_extract simple-extract
2864 alias se=simple-extract
2865
2866 #f5# Set all ulimit parameters to \kbd{unlimited}
2867 allulimit() {
2868     ulimit -c unlimited
2869     ulimit -d unlimited
2870     ulimit -f unlimited
2871     ulimit -l unlimited
2872     ulimit -n unlimited
2873     ulimit -s unlimited
2874     ulimit -t unlimited
2875 }
2876
2877 #f5# Change the xterm title from within GNU-screen
2878 xtrename() {
2879     emulate -L zsh
2880     if [[ $1 != "-f" ]] ; then
2881         if [[ -z ${DISPLAY} ]] ; then
2882             printf 'xtrename only makes sense in X11.\n'
2883             return 1
2884         fi
2885     else
2886         shift
2887     fi
2888     if [[ -z $1 ]] ; then
2889         printf 'usage: xtrename [-f] "title for xterm"\n'
2890         printf '  renames the title of xterm from _within_ screen.\n'
2891         printf '  also works without screen.\n'
2892         printf '  will not work if DISPLAY is unset, use -f to override.\n'
2893         return 0
2894     fi
2895     print -n "\eP\e]0;${1}\C-G\e\\"
2896     return 0
2897 }
2898
2899 # Create small urls via http://goo.gl using curl(1).
2900 # API reference: https://code.google.com/apis/urlshortener/
2901 function zurl() {
2902     emulate -L zsh
2903     setopt extended_glob
2904
2905     if [[ -z $1 ]]; then
2906         print "USAGE: zurl <URL>"
2907         return 1
2908     fi
2909
2910     local PN url prog api json contenttype item
2911     local -a data
2912     PN=$0
2913     url=$1
2914
2915     # Prepend 'http://' to given URL where necessary for later output.
2916     if [[ ${url} != http(s|)://* ]]; then
2917         url='http://'${url}
2918     fi
2919
2920     if check_com -c curl; then
2921         prog=curl
2922     else
2923         print "curl is not available, but mandatory for ${PN}. Aborting."
2924         return 1
2925     fi
2926     api='https://www.googleapis.com/urlshortener/v1/url'
2927     contenttype="Content-Type: application/json"
2928     json="{\"longUrl\": \"${url}\"}"
2929     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
2930     # Parse the response
2931     for item in "${data[@]}"; do
2932         case "$item" in
2933             ' '#'"id":'*)
2934                 item=${item#*: \"}
2935                 item=${item%\",*}
2936                 printf '%s\n' "$item"
2937                 return 0
2938                 ;;
2939         esac
2940     done
2941     return 1
2942 }
2943
2944 #f2# Find history events by search pattern and list them by date.
2945 whatwhen()  {
2946     emulate -L zsh
2947     local usage help ident format_l format_s first_char remain first last
2948     usage='USAGE: whatwhen [options] <searchstring> <search range>'
2949     help='Use `whatwhen -h'\'' for further explanations.'
2950     ident=${(l,${#${:-Usage: }},, ,)}
2951     format_l="${ident}%s\t\t\t%s\n"
2952     format_s="${format_l//(\\t)##/\\t}"
2953     # Make the first char of the word to search for case
2954     # insensitive; e.g. [aA]
2955     first_char=[${(L)1[1]}${(U)1[1]}]
2956     remain=${1[2,-1]}
2957     # Default search range is `-100'.
2958     first=${2:-\-100}
2959     # Optional, just used for `<first> <last>' given.
2960     last=$3
2961     case $1 in
2962         ("")
2963             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
2964             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2965         ;;
2966         (-h)
2967             printf '%s\n\n' ${usage}
2968             print 'OPTIONS:'
2969             printf $format_l '-h' 'show help text'
2970             print '\f'
2971             print 'SEARCH RANGE:'
2972             printf $format_l "'0'" 'the whole history,'
2973             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
2974             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
2975             printf '\n%s\n' 'EXAMPLES:'
2976             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
2977             printf $format_l 'whatwhen zsh -250'
2978             printf $format_l 'whatwhen foo 1 99'
2979         ;;
2980         (\?)
2981             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2982         ;;
2983         (*)
2984             # -l list results on stout rather than invoking $EDITOR.
2985             # -i Print dates as in YYYY-MM-DD.
2986             # -m Search for a - quoted - pattern within the history.
2987             fc -li -m "*${first_char}${remain}*" $first $last
2988         ;;
2989     esac
2990 }
2991
2992 # mercurial related stuff
2993 if check_com -c hg ; then
2994     # gnu like diff for mercurial
2995     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
2996     #f5# GNU like diff for mercurial
2997     hgdi() {
2998         emulate -L zsh
2999         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
3000     }
3001
3002     # build debian package
3003     #a2# Alias for \kbd{hg-buildpackage}
3004     alias hbp='hg-buildpackage'
3005
3006     # execute commands on the versioned patch-queue from the current repos
3007     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
3008
3009     # diffstat for specific version of a mercurial repository
3010     #   hgstat      => display diffstat between last revision and tip
3011     #   hgstat 1234 => display diffstat between revision 1234 and tip
3012     #f5# Diffstat for specific version of a mercurial repos
3013     hgstat() {
3014         emulate -L zsh
3015         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
3016     }
3017
3018 fi # end of check whether we have the 'hg'-executable
3019
3020 # grml-small cleanups
3021
3022 # The following is used to remove zsh-config-items that do not work
3023 # in grml-small by default.
3024 # If you do not want these adjustments (for whatever reason), set
3025 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
3026 # sources if it is there).
3027
3028 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
3029
3030     unset abk[V]
3031     unalias    'V'      &> /dev/null
3032     unfunction vman     &> /dev/null
3033     unfunction viless   &> /dev/null
3034     unfunction 2html    &> /dev/null
3035
3036     # manpages are not in grmlsmall
3037     unfunction manzsh   &> /dev/null
3038     unfunction man2     &> /dev/null
3039
3040 fi
3041
3042 zrclocal
3043
3044 ## genrefcard.pl settings
3045
3046 ### doc strings for external functions from files
3047 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
3048
3049 ### example: split functions-search 8,16,24,32
3050 #@# split functions-search 8
3051
3052 ## END OF FILE #################################################################
3053 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
3054 # Local variables:
3055 # mode: sh
3056 # End: