etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is439(){
 148     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 #f1# Checks whether or not you're running grml
 154 isgrml(){
 155     [[ -f /etc/grml_version ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running a grml cd
 160 isgrmlcd(){
 161     [[ -f /etc/grml_cd ]] && return 0
 162     return 1
 163 }
 164
 165 if isgrml ; then
 166 #f1# Checks whether or not you're running grml-small
 167     isgrmlsmall() {
 168         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 169             return 0
 170         fi
 171         return 1
 172     }
 173 else
 174     isgrmlsmall() { return 1 }
 175 fi
 176
 177 isdarwin(){
 178     [[ $OSTYPE == darwin* ]] && return 0
 179     return 1
 180 }
 181
 182 isfreebsd(){
 183     [[ $OSTYPE == freebsd* ]] && return 0
 184     return 1
 185 }
 186
 187 #f1# are we running within an utf environment?
 188 isutfenv() {
 189     case "$LANG $CHARSET $LANGUAGE" in
 190         *utf*) return 0 ;;
 191         *UTF*) return 0 ;;
 192         *)     return 1 ;;
 193     esac
 194 }
 195
 196 # check for user, if not running as root set $SUDO to sudo
 197 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 198
 199 # change directory to home on first invocation of zsh
 200 # important for rungetty -> autologin
 201 # Thanks go to Bart Schaefer!
 202 isgrml && checkhome() {
 203     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 204         export ALREADY_DID_CD_HOME=$HOME
 205         cd
 206     fi
 207 }
 208
 209 # check for zsh v3.1.7+
 210
 211 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 212      || ${ZSH_VERSION} == 3.<2->.<->*    \
 213      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 214
 215     printf '-!-\n'
 216     printf '-!- In this configuration we try to make use of features, that only\n'
 217     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 218     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 219     printf '-!- advanced features in all supported versions.\n'
 220     printf '-!-\n'
 221     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 222     printf '-!-\n'
 223     printf '-!- While this *may* work, it might as well fail.\n'
 224     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 225     printf '-!-\n'
 226     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 227     printf '-!- If it does today, you'\''ve been lucky.\n'
 228     printf '-!-\n'
 229     printf '-!- Ye been warned!\n'
 230     printf '-!-\n'
 231
 232     function zstyle() { : }
 233 fi
 234
 235 # autoload wrapper - use this one instead of autoload directly
 236 # We need to define this function as early as this, because autoloading
 237 # 'is-at-least()' needs it.
 238 function zrcautoload() {
 239     emulate -L zsh
 240     setopt extended_glob
 241     local fdir ffile
 242     local -i ffound
 243
 244     ffile=$1
 245     (( ffound = 0 ))
 246     for fdir in ${fpath} ; do
 247         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 248     done
 249
 250     (( ffound == 0 )) && return 1
 251     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 252         autoload -U ${ffile} || return 1
 253     else
 254         autoload ${ffile} || return 1
 255     fi
 256     return 0
 257 }
 258
 259 # Load is-at-least() for more precise version checks Note that this test will
 260 # *always* fail, if the is-at-least function could not be marked for
 261 # autoloading.
 262 zrcautoload is-at-least || is-at-least() { return 1 }
 263
 264 # set some important options (as early as possible)
 265
 266 # append history list to the history file; this is the default but we make sure
 267 # because it's required for share_history.
 268 setopt append_history
 269
 270 # import new commands from the history file also in other zsh-session
 271 is4 && setopt share_history
 272
 273 # save each command's beginning timestamp and the duration to the history file
 274 setopt extended_history
 275
 276 # If a new command line being added to the history list duplicates an older
 277 # one, the older command is removed from the list
 278 is4 && setopt histignorealldups
 279
 280 # remove command lines from the history list when the first character on the
 281 # line is a space
 282 setopt histignorespace
 283
 284 # if a command is issued that can't be executed as a normal command, and the
 285 # command is the name of a directory, perform the cd command to that directory.
 286 setopt auto_cd
 287
 288 # in order to use #, ~ and ^ for filename generation grep word
 289 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 290 # don't forget to quote '^', '~' and '#'!
 291 setopt extended_glob
 292
 293 # display PID when suspending processes as well
 294 setopt longlistjobs
 295
 296 # try to avoid the 'zsh: no matches found...'
 297 setopt nonomatch
 298
 299 # report the status of backgrounds jobs immediately
 300 setopt notify
 301
 302 # whenever a command completion is attempted, make sure the entire command path
 303 # is hashed first.
 304 setopt hash_list_all
 305
 306 # not just at the end
 307 setopt completeinword
 308
 309 # Don't send SIGHUP to background processes when the shell exits.
 310 setopt nohup
 311
 312 # make cd push the old directory onto the directory stack.
 313 setopt auto_pushd
 314
 315 # avoid "beep"ing
 316 setopt nobeep
 317
 318 # don't push the same dir twice.
 319 setopt pushd_ignore_dups
 320
 321 # * shouldn't match dotfiles. ever.
 322 setopt noglobdots
 323
 324 # use zsh style word splitting
 325 setopt noshwordsplit
 326
 327 # don't error out when unset parameters are used
 328 setopt unset
 329
 330 # setting some default values
 331 NOCOR=${NOCOR:-0}
 332 NOMENU=${NOMENU:-0}
 333 NOPRECMD=${NOPRECMD:-0}
 334 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 335 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 336 BATTERY=${BATTERY:-0}
 337 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 338 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 339
 340 typeset -ga ls_options
 341 typeset -ga grep_options
 342 if ls --help 2> /dev/null | grep -q GNU; then
 343     ls_options=( --color=auto )
 344 elif [[ $OSTYPE == freebsd* ]]; then
 345     ls_options=( -G )
 346 fi
 347 if grep --help 2> /dev/null | grep -q GNU || \
 348    [[ $OSTYPE == freebsd* ]]; then
 349     grep_options=( --color=auto )
 350 fi
 351
 352 # utility functions
 353 # this function checks if a command exists and returns either true
 354 # or false. This avoids using 'which' and 'whence', which will
 355 # avoid problems with aliases for which on certain weird systems. :-)
 356 # Usage: check_com [-c|-g] word
 357 #   -c  only checks for external commands
 358 #   -g  does the usual tests and also checks for global aliases
 359 check_com() {
 360     emulate -L zsh
 361     local -i comonly gatoo
 362
 363     if [[ $1 == '-c' ]] ; then
 364         (( comonly = 1 ))
 365         shift
 366     elif [[ $1 == '-g' ]] ; then
 367         (( gatoo = 1 ))
 368     else
 369         (( comonly = 0 ))
 370         (( gatoo = 0 ))
 371     fi
 372
 373     if (( ${#argv} != 1 )) ; then
 374         printf 'usage: check_com [-c] <command>\n' >&2
 375         return 1
 376     fi
 377
 378     if (( comonly > 0 )) ; then
 379         [[ -n ${commands[$1]}  ]] && return 0
 380         return 1
 381     fi
 382
 383     if   [[ -n ${commands[$1]}    ]] \
 384       || [[ -n ${functions[$1]}   ]] \
 385       || [[ -n ${aliases[$1]}     ]] \
 386       || [[ -n ${reswords[(r)$1]} ]] ; then
 387
 388         return 0
 389     fi
 390
 391     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 392         return 0
 393     fi
 394
 395     return 1
 396 }
 397
 398 # creates an alias and precedes the command with
 399 # sudo if $EUID is not zero.
 400 salias() {
 401     emulate -L zsh
 402     local only=0 ; local multi=0
 403     while [[ $1 == -* ]] ; do
 404         case $1 in
 405             (-o) only=1 ;;
 406             (-a) multi=1 ;;
 407             (--) shift ; break ;;
 408             (-h)
 409                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 410                 printf '  -h      shows this help text.\n'
 411                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 412                 printf '          be careful using this option.\n'
 413                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 414                 return 0
 415                 ;;
 416             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 417         esac
 418         shift
 419     done
 420
 421     if (( ${#argv} > 1 )) ; then
 422         printf 'Too many arguments %s\n' "${#argv}"
 423         return 1
 424     fi
 425
 426     key="${1%%\=*}" ;  val="${1#*\=}"
 427     if (( EUID == 0 )) && (( only == 0 )); then
 428         alias -- "${key}=${val}"
 429     elif (( EUID > 0 )) ; then
 430         (( multi > 0 )) && val="${val// ; / ; sudo }"
 431         alias -- "${key}=sudo ${val}"
 432     fi
 433
 434     return 0
 435 }
 436
 437 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 438 # usage: uprint foo
 439 #   Where foo is the *name* of the parameter you want printed.
 440 #   Note that foo is no typo; $foo would be wrong here!
 441 if ! is42 ; then
 442     uprint () {
 443         emulate -L zsh
 444         local -a u
 445         local w
 446         local parameter=$1
 447
 448         if [[ -z ${parameter} ]] ; then
 449             printf 'usage: uprint <parameter>\n'
 450             return 1
 451         fi
 452
 453         for w in ${(P)parameter} ; do
 454             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 455         done
 456
 457         builtin print -l $u
 458     }
 459 fi
 460
 461 # Check if we can read given files and source those we can.
 462 xsource() {
 463     if (( ${#argv} < 1 )) ; then
 464         printf 'usage: xsource FILE(s)...\n' >&2
 465         return 1
 466     fi
 467
 468     while (( ${#argv} > 0 )) ; do
 469         [[ -r "$1" ]] && source "$1"
 470         shift
 471     done
 472     return 0
 473 }
 474
 475 # Check if we can read a given file and 'cat(1)' it.
 476 xcat() {
 477     emulate -L zsh
 478     if (( ${#argv} != 1 )) ; then
 479         printf 'usage: xcat FILE\n' >&2
 480         return 1
 481     fi
 482
 483     [[ -r $1 ]] && cat $1
 484     return 0
 485 }
 486
 487 # Remove these functions again, they are of use only in these
 488 # setup files. This should be called at the end of .zshrc.
 489 xunfunction() {
 490     emulate -L zsh
 491     local -a funcs
 492     funcs=(salias xcat xsource xunfunction zrcautoload)
 493
 494     for func in $funcs ; do
 495         [[ -n ${functions[$func]} ]] \
 496             && unfunction $func
 497     done
 498     return 0
 499 }
 500
 501 # this allows us to stay in sync with grml's zshrc and put own
 502 # modifications in ~/.zshrc.local
 503 zrclocal() {
 504     xsource "/etc/zsh/zshrc.local"
 505     xsource "${HOME}/.zshrc.local"
 506     return 0
 507 }
 508
 509 # locale setup
 510 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 511     xsource "/etc/default/locale"
 512 fi
 513
 514 for var in LANG LC_ALL LC_MESSAGES ; do
 515     [[ -n ${(P)var} ]] && export $var
 516 done
 517
 518 xsource "/etc/sysconfig/keyboard"
 519
 520 TZ=$(xcat /etc/timezone)
 521
 522 # set some variables
 523 if check_com -c vim ; then
 524 #v#
 525     export EDITOR=${EDITOR:-vim}
 526 else
 527     export EDITOR=${EDITOR:-vi}
 528 fi
 529
 530 #v#
 531 export PAGER=${PAGER:-less}
 532
 533 #v#
 534 export MAIL=${MAIL:-/var/mail/$USER}
 535
 536 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 537 export SHELL='/bin/zsh'
 538
 539 # color setup for ls:
 540 check_com -c dircolors && eval $(dircolors -b)
 541 # color setup for ls on OS X / FreeBSD:
 542 isdarwin && export CLICOLOR=1
 543 isfreebsd && export CLICOLOR=1
 544
 545 # do MacPorts setup on darwin
 546 if isdarwin && [[ -d /opt/local ]]; then
 547     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 548     # zshenv.
 549     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 550     MANPATH="/opt/local/share/man:$MANPATH"
 551 fi
 552 # do Fink setup on darwin
 553 isdarwin && xsource /sw/bin/init.sh
 554
 555 # load our function and completion directories
 556 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 557     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 558     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 559         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 560             zrcautoload ${func:t}
 561         done
 562     fi
 563 done
 564 unset fdir func
 565
 566 # support colors in less
 567 export LESS_TERMCAP_mb=$'\E[01;31m'
 568 export LESS_TERMCAP_md=$'\E[01;31m'
 569 export LESS_TERMCAP_me=$'\E[0m'
 570 export LESS_TERMCAP_se=$'\E[0m'
 571 export LESS_TERMCAP_so=$'\E[01;44;33m'
 572 export LESS_TERMCAP_ue=$'\E[0m'
 573 export LESS_TERMCAP_us=$'\E[01;32m'
 574
 575 # mailchecks
 576 MAILCHECK=30
 577
 578 # report about cpu-/system-/user-time of command if running longer than
 579 # 5 seconds
 580 REPORTTIME=5
 581
 582 # watch for everyone but me and root
 583 watch=(notme root)
 584
 585 # automatically remove duplicates from these arrays
 586 typeset -U path cdpath fpath manpath
 587
 588 # Remove zle-line-{init,finish} if it looks like it turns smkx. This would be
 589 # better fixed by working with those modes too, but we use way too many
 590 # hardcoded bindings for now.
 591 function remove_widget () {
 592     local name=$1
 593     local cap=$2
 594     if (( ${+functions[$name]} )) && [[ ${functions[$name]} == *${cap}* ]]; then
 595         local w=${widgets[$name]}
 596         zle -D $name
 597         [[ $w == user:* ]] && unfunction ${w#*:}
 598     fi
 599 }
 600 remove_widget zle-line-init smkx
 601 remove_widget zle-line-finish rmkx
 602 unfunction remove_widget
 603
 604 # keybindings
 605 if [[ "$TERM" != emacs ]] ; then
 606     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 607     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 608     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 609     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 610     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 611     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 612     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 613     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 614     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 615     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 616     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 617     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 618     # ncurses stuff:
 619     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 620     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 621     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 622     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 623     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 624     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 625     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 626     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 627 fi
 628
 629 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 630 # use emacs style per default:
 631 bindkey -e
 632 # use vi style:
 633 # bindkey -v
 634
 635 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 636 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 637 beginning-or-end-of-somewhere() {
 638     local hno=$HISTNO
 639     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 640       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 641         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 642     else
 643         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 644         if (( HISTNO != hno )); then
 645             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 646         fi
 647     fi
 648 }
 649 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 650 zle -N end-of-somewhere beginning-or-end-of-somewhere
 651
 652
 653 #if [[ "$TERM" == screen ]] ; then
 654
 655 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 656 ## to beginning/end of buffer on second keypress
 657 ## and to beginning/end of history on (at most) the third keypress
 658 # terminator & non-debian xterm
 659 bindkey '\eOH' beginning-of-somewhere  # home
 660 bindkey '\eOF' end-of-somewhere        # end
 661 # freebsd console
 662 bindkey '\e[H' beginning-of-somewhere   # home
 663 bindkey '\e[F' end-of-somewhere         # end
 664 # xterm,gnome-terminal,quake,etc
 665 bindkey '^[[1~' beginning-of-somewhere  # home
 666 bindkey '^[[4~' end-of-somewhere        # end
 667 # if terminal type is set to 'rxvt':
 668 bindkey '\e[7~' beginning-of-somewhere  # home
 669 bindkey '\e[8~' end-of-somewhere        # end
 670 #fi
 671
 672 bindkey '\e[A'  up-line-or-search       # cursor up
 673 bindkey '\e[B'  down-line-or-search     # <ESC>-
 674
 675 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 676 bindkey "\e[5C" forward-word
 677 bindkey "\e[5D" backward-word
 678 bindkey "\e[1;5C" forward-word
 679 bindkey "\e[1;5D" backward-word
 680 ## the same for alt-left-arrow and alt-right-arrow
 681 bindkey '^[[1;3C' forward-word
 682 bindkey '^[[1;3D' backward-word
 683
 684 # Search backward in the history for a line beginning with the current
 685 # line up to the cursor and move the cursor to the end of the line then
 686 zle -N history-beginning-search-backward-end history-search-end
 687 zle -N history-beginning-search-forward-end  history-search-end
 688 #k# search history backward for entry beginning with typed text
 689 bindkey '^xp'   history-beginning-search-backward-end
 690 #k# search history forward for entry beginning with typed text
 691 bindkey '^xP'   history-beginning-search-forward-end
 692 #k# search history backward for entry beginning with typed text
 693 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 694 #k# search history forward for entry beginning with typed text
 695 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 696
 697 # bindkey -s '^l' "|less\n"             # ctrl-L pipes to less
 698 # bindkey -s '^b' " &\n"                # ctrl-B runs it in the background
 699
 700 # insert unicode character
 701 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 702 # See for example http://unicode.org/charts/ for unicode characters code
 703 zrcautoload insert-unicode-char
 704 zle -N insert-unicode-char
 705 #k# Insert Unicode character
 706 bindkey '^xi' insert-unicode-char
 707
 708 #m# k Shift-tab Perform backwards menu completion
 709 if [[ -n "$terminfo[kcbt]" ]]; then
 710     bindkey "$terminfo[kcbt]" reverse-menu-complete
 711 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 712     bindkey "$terminfo[cbt]"  reverse-menu-complete
 713 fi
 714
 715 ## toggle the ,. abbreviation feature on/off
 716 # NOABBREVIATION: default abbreviation-state
 717 #                 0 - enabled (default)
 718 #                 1 - disabled
 719 NOABBREVIATION=${NOABBREVIATION:-0}
 720
 721 grml_toggle_abbrev() {
 722     if (( ${NOABBREVIATION} > 0 )) ; then
 723         NOABBREVIATION=0
 724     else
 725         NOABBREVIATION=1
 726     fi
 727 }
 728
 729 #k# Toggle abbreviation expansion on/off
 730 zle -N grml_toggle_abbrev
 731 bindkey '^xA' grml_toggle_abbrev
 732
 733 # add a command line to the shells history without executing it
 734 commit-to-history() {
 735     print -s ${(z)BUFFER}
 736     zle send-break
 737 }
 738 zle -N commit-to-history
 739 bindkey "^x^h" commit-to-history
 740
 741 # only slash should be considered as a word separator:
 742 slash-backward-kill-word() {
 743     local WORDCHARS="${WORDCHARS:s@/@}"
 744     # zle backward-word
 745     zle backward-kill-word
 746 }
 747 zle -N slash-backward-kill-word
 748
 749 #k# Kill left-side word or everything up to next slash
 750 bindkey '\ev' slash-backward-kill-word
 751 #k# Kill left-side word or everything up to next slash
 752 bindkey '\e^h' slash-backward-kill-word
 753 #k# Kill left-side word or everything up to next slash
 754 bindkey '\e^?' slash-backward-kill-word
 755
 756 # use the new *-pattern-* widgets for incremental history search
 757 if is439 ; then
 758     bindkey '^r' history-incremental-pattern-search-backward
 759     bindkey '^s' history-incremental-pattern-search-forward
 760 fi
 761
 762 # a generic accept-line wrapper
 763
 764 # This widget can prevent unwanted autocorrections from command-name
 765 # to _command-name, rehash automatically on enter and call any number
 766 # of builtin and user-defined widgets in different contexts.
 767 #
 768 # For a broader description, see:
 769 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 770 #
 771 # The code is imported from the file 'zsh/functions/accept-line' from
 772 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 773 # distributed under the same terms as zsh itself.
 774
 775 # A newly added command will may not be found or will cause false
 776 # correction attempts, if you got auto-correction set. By setting the
 777 # following style, we force accept-line() to rehash, if it cannot
 778 # find the first word on the command line in the $command[] hash.
 779 zstyle ':acceptline:*' rehash true
 780
 781 function Accept-Line() {
 782     setopt localoptions noksharrays
 783     local -a subs
 784     local -xi aldone
 785     local sub
 786     local alcontext=${1:-$alcontext}
 787
 788     zstyle -a ":acceptline:${alcontext}" actions subs
 789
 790     (( ${#subs} < 1 )) && return 0
 791
 792     (( aldone = 0 ))
 793     for sub in ${subs} ; do
 794         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 795         zle ${sub}
 796
 797         (( aldone > 0 )) && break
 798     done
 799 }
 800
 801 function Accept-Line-getdefault() {
 802     emulate -L zsh
 803     local default_action
 804
 805     zstyle -s ":acceptline:${alcontext}" default_action default_action
 806     case ${default_action} in
 807         ((accept-line|))
 808             printf ".accept-line"
 809             ;;
 810         (*)
 811             printf ${default_action}
 812             ;;
 813     esac
 814 }
 815
 816 function Accept-Line-HandleContext() {
 817     zle Accept-Line
 818
 819     default_action=$(Accept-Line-getdefault)
 820     zstyle -T ":acceptline:${alcontext}" call_default \
 821         && zle ${default_action}
 822 }
 823
 824 function accept-line() {
 825     setopt localoptions noksharrays
 826     local -ax cmdline
 827     local -x alcontext
 828     local buf com fname format msg default_action
 829
 830     alcontext='default'
 831     buf="${BUFFER}"
 832     cmdline=(${(z)BUFFER})
 833     com="${cmdline[1]}"
 834     fname="_${com}"
 835
 836     Accept-Line 'preprocess'
 837
 838     zstyle -t ":acceptline:${alcontext}" rehash \
 839         && [[ -z ${commands[$com]} ]]           \
 840         && rehash
 841
 842     if    [[ -n ${com}               ]] \
 843        && [[ -n ${reswords[(r)$com]} ]] \
 844        || [[ -n ${aliases[$com]}     ]] \
 845        || [[ -n ${functions[$com]}   ]] \
 846        || [[ -n ${builtins[$com]}    ]] \
 847        || [[ -n ${commands[$com]}    ]] ; then
 848
 849         # there is something sensible to execute, just do it.
 850         alcontext='normal'
 851         Accept-Line-HandleContext
 852
 853         return
 854     fi
 855
 856     if    [[ -o correct              ]] \
 857        || [[ -o correctall           ]] \
 858        && [[ -n ${functions[$fname]} ]] ; then
 859
 860         # nothing there to execute but there is a function called
 861         # _command_name; a completion widget. Makes no sense to
 862         # call it on the commandline, but the correct{,all} options
 863         # will ask for it nevertheless, so warn the user.
 864         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 865             # Okay, we warned the user before, he called us again,
 866             # so have it his way.
 867             alcontext='force'
 868             Accept-Line-HandleContext
 869
 870             return
 871         fi
 872
 873         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 874             alcontext='normal'
 875             Accept-Line-HandleContext
 876         else
 877             # prepare warning message for the user, configurable via zstyle.
 878             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 879
 880             if [[ -z ${msg} ]] ; then
 881                 msg="%c will not execute and completion %f exists."
 882             fi
 883
 884             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 885
 886             zle -M -- "${msg}"
 887         fi
 888         return
 889     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 890         # If we are here, the commandline contains something that is not
 891         # executable, which is neither subject to _command_name correction
 892         # and is not empty. might be a variable assignment
 893         alcontext='misc'
 894         Accept-Line-HandleContext
 895
 896         return
 897     fi
 898
 899     # If we got this far, the commandline only contains whitespace, or is empty.
 900     alcontext='empty'
 901     Accept-Line-HandleContext
 902 }
 903
 904 zle -N accept-line
 905 zle -N Accept-Line
 906 zle -N Accept-Line-HandleContext
 907
 908 # power completion - abbreviation expansion
 909 # power completion / abbreviation expansion / buffer expansion
 910 # see http://zshwiki.org/home/examples/zleiab for details
 911 # less risky than the global aliases but powerful as well
 912 # just type the abbreviation key and afterwards ',.' to expand it
 913 declare -A abk
 914 setopt extendedglob
 915 setopt interactivecomments
 916 abk=(
 917 #   key   # value                  (#d additional doc string)
 918 #A# start
 919     '...'  '../..'
 920     '....' '../../..'
 921     'BG'   '& exit'
 922     'C'    '| wc -l'
 923     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
 924     'H'    '| head'
 925     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 926     'L'    '| less'
 927     'LL'   '|& less -r'
 928     'M'    '| most'
 929     'N'    '&>/dev/null'           #d (No Output)
 930     'R'    '| tr A-z N-za-m'       #d (ROT13)
 931     'SL'   '| sort | less'
 932     'S'    '| sort -u'
 933     'T'    '| tail'
 934     'V'    '|& vim -'
 935 #A# end
 936     'co'   './configure && make && sudo make install'
 937 )
 938
 939 zleiab() {
 940     emulate -L zsh
 941     setopt extendedglob
 942     local MATCH
 943
 944     if (( NOABBREVIATION > 0 )) ; then
 945         LBUFFER="${LBUFFER},."
 946         return 0
 947     fi
 948
 949     matched_chars='[.-|_a-zA-Z0-9]#'
 950     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 951     LBUFFER+=${abk[$MATCH]:-$MATCH}
 952 }
 953
 954 zle -N zleiab && bindkey ",." zleiab
 955
 956 #f# display contents of assoc array $abk
 957 help-show-abk()
 958 {
 959   zle -M "$(print "Type ,. after these abbreviations to expand them:"; print -a -C 2 ${(kv)abk})"
 960 }
 961 #k# Display list of abbreviations that expand when followed by ,.
 962 zle -N help-show-abk && bindkey '^xb' help-show-abk
 963
 964 # autoloading
 965 zrcautoload zmv    # who needs mmv or rename?
 966 zrcautoload history-search-end
 967
 968 # we don't want to quote/espace URLs on our own...
 969 # if autoload -U url-quote-magic ; then
 970 #    zle -N self-insert url-quote-magic
 971 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 972 # else
 973 #    print 'Notice: no url-quote-magic available :('
 974 # fi
 975 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 976
 977 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 978 alias run-help >&/dev/null && unalias run-help
 979 for rh in run-help{,-git,-svk,-svn}; do
 980     zrcautoload $rh
 981 done; unset rh
 982
 983 # completion system
 984 if zrcautoload compinit ; then
 985     compinit || print 'Notice: no compinit available :('
 986 else
 987     print 'Notice: no compinit available :('
 988     function compdef { }
 989 fi
 990
 991 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 992
 993 is4 && \
 994 for mod in complist deltochar mathfunc ; do
 995     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 996 done
 997
 998 # autoload zsh modules when they are referenced
 999 if is4 ; then
1000     zmodload -a  zsh/stat    zstat
1001     zmodload -a  zsh/zpty    zpty
1002     zmodload -ap zsh/mapfile mapfile
1003 fi
1004
1005 if is4 && zrcautoload insert-files && zle -N insert-files ; then
1006     #k# Insert files and test globbing
1007     bindkey "^xf" insert-files # C-x-f
1008 fi
1009
1010 bindkey ' '   magic-space    # also do history expansion on space
1011 #k# Trigger menu-complete
1012 bindkey '\ei' menu-complete  # menu completion via esc-i
1013
1014 # press esc-e for editing command line in $EDITOR or $VISUAL
1015 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
1016     #k# Edit the current line in \kbd{\$EDITOR}
1017     bindkey '\ee' edit-command-line
1018 fi
1019
1020 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
1021     #k# menu selection: pick item but stay in the menu
1022     bindkey -M menuselect '\e^M' accept-and-menu-complete
1023     # also use + and INSERT since it's easier to press repeatedly
1024     bindkey -M menuselect "+" accept-and-menu-complete
1025     bindkey -M menuselect "^[[2~" accept-and-menu-complete
1026
1027     # accept a completion and try to complete again by using menu
1028     # completion; very useful with completing directories
1029     # by using 'undo' one's got a simple file browser
1030     bindkey -M menuselect '^o' accept-and-infer-next-history
1031 fi
1032
1033 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1034 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1035 zle -N insert-datestamp
1036
1037 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1038 bindkey '^ed' insert-datestamp
1039
1040 # press esc-m for inserting last typed word again (thanks to caphuso!)
1041 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1042 zle -N insert-last-typed-word;
1043
1044 #k# Insert last typed word
1045 bindkey "\em" insert-last-typed-word
1046
1047 function grml-zsh-fg() {
1048   if (( ${#jobstates} )); then
1049     zle .push-input
1050     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1051     BUFFER="${BUFFER}fg"
1052     zle .accept-line
1053   else
1054     zle -M 'No background jobs. Doing nothing.'
1055   fi
1056 }
1057 zle -N grml-zsh-fg
1058 #k# A smart shortcut for \kbd{fg<enter>}
1059 bindkey '^z' grml-zsh-fg
1060
1061 # run command line as user root via sudo:
1062 sudo-command-line() {
1063     [[ -z $BUFFER ]] && zle up-history
1064     if [[ $BUFFER != sudo\ * ]]; then
1065         BUFFER="sudo $BUFFER"
1066         CURSOR=$(( CURSOR+5 ))
1067     fi
1068 }
1069 zle -N sudo-command-line
1070
1071 #k# prepend the current command with "sudo"
1072 bindkey "^os" sudo-command-line
1073
1074 ### jump behind the first word on the cmdline.
1075 ### useful to add options.
1076 function jump_after_first_word() {
1077     local words
1078     words=(${(z)BUFFER})
1079
1080     if (( ${#words} <= 1 )) ; then
1081         CURSOR=${#BUFFER}
1082     else
1083         CURSOR=${#${words[1]}}
1084     fi
1085 }
1086 zle -N jump_after_first_word
1087 #k# jump to after first word (for adding options)
1088 bindkey '^x1' jump_after_first_word
1089
1090 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1091 zle -C hist-complete complete-word _generic
1092 zstyle ':completion:hist-complete:*' completer _history
1093 #k# complete word from history with menu
1094 bindkey "^x^x" hist-complete
1095
1096 ## complete word from currently visible Screen or Tmux buffer.
1097 if check_com -c screen || check_com -c tmux; then
1098     _complete_screen_display() {
1099         [[ "$TERM" != "screen" ]] && return 1
1100
1101         local TMPFILE=$(mktemp)
1102         local -U -a _screen_display_wordlist
1103         trap "rm -f $TMPFILE" EXIT
1104
1105         # fill array with contents from screen hardcopy
1106         if ((${+TMUX})); then
1107             #works, but crashes tmux below version 1.4
1108             #luckily tmux -V option to ask for version, was also added in 1.4
1109             tmux -V &>/dev/null || return
1110             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1111         else
1112             screen -X hardcopy $TMPFILE
1113             # screen sucks, it dumps in latin1, apparently always. so recode it
1114             # to system charset
1115             check_com recode && recode latin1 $TMPFILE
1116         fi
1117         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1118         # remove PREFIX to be completed from that array
1119         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1120         compadd -a _screen_display_wordlist
1121     }
1122     #k# complete word from currently visible GNU screen buffer
1123     bindkey -r "^xS"
1124     compdef -k _complete_screen_display complete-word '^xS'
1125 fi
1126
1127 # history
1128
1129 ZSHDIR=$HOME/.zsh
1130
1131 #v#
1132 HISTFILE=$HOME/.zsh_history
1133 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1134 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1135
1136 # dirstack handling
1137
1138 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1139 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1140
1141 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1142     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1143     # "cd -" won't work after login by just setting $OLDPWD, so
1144     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1145 fi
1146
1147 chpwd() {
1148     local -ax my_stack
1149     my_stack=( ${PWD} ${dirstack} )
1150     if is42 ; then
1151         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1152     else
1153         uprint my_stack >! ${DIRSTACKFILE}
1154     fi
1155 }
1156
1157 # directory based profiles
1158
1159 if is433 ; then
1160
1161 # chpwd_profiles(): Directory Profiles, Quickstart:
1162 #
1163 # In .zshrc.local:
1164 #
1165 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1166 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1167 #   chpwd_profiles
1168 #
1169 # For details see the `grmlzshrc.5' manual page.
1170 function chpwd_profiles() {
1171     local profile context
1172     local -i reexecute
1173
1174     context=":chpwd:profiles:$PWD"
1175     zstyle -s "$context" profile profile || profile='default'
1176     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1177
1178     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1179         typeset -g CHPWD_PROFILE
1180         local CHPWD_PROFILES_INIT=1
1181         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1182     elif [[ $profile != $CHPWD_PROFILE ]]; then
1183         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1184             && chpwd_leave_profile_${CHPWD_PROFILE}
1185     fi
1186     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1187         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1188     fi
1189
1190     CHPWD_PROFILE="${profile}"
1191     return 0
1192 }
1193
1194 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1195
1196 fi # is433
1197
1198 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1199 if [[ $BATTERY -gt 0 ]] ; then
1200     if ! check_com -c acpi ; then
1201         BATTERY=0
1202     fi
1203 fi
1204
1205 battery() {
1206 if [[ $BATTERY -gt 0 ]] ; then
1207     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1208     if [[ -z "$PERCENT" ]] ; then
1209         PERCENT='acpi not present'
1210     else
1211         if [[ "$PERCENT" -lt 20 ]] ; then
1212             PERCENT="warning: ${PERCENT}%%"
1213         else
1214             PERCENT="${PERCENT}%%"
1215         fi
1216     fi
1217 fi
1218 }
1219 # set colors for use in prompts
1220 if zrcautoload colors && colors 2>/dev/null ; then
1221     BLUE="%{${fg[blue]}%}"
1222     RED="%{${fg_bold[red]}%}"
1223     GREEN="%{${fg[green]}%}"
1224     CYAN="%{${fg[cyan]}%}"
1225     MAGENTA="%{${fg[magenta]}%}"
1226     YELLOW="%{${fg[yellow]}%}"
1227     WHITE="%{${fg[white]}%}"
1228     NO_COLOR="%{${reset_color}%}"
1229 else
1230     BLUE=$'%{\e[1;34m%}'
1231     RED=$'%{\e[1;31m%}'
1232     GREEN=$'%{\e[1;32m%}'
1233     CYAN=$'%{\e[1;36m%}'
1234     WHITE=$'%{\e[1;37m%}'
1235     MAGENTA=$'%{\e[1;35m%}'
1236     YELLOW=$'%{\e[1;33m%}'
1237     NO_COLOR=$'%{\e[0m%}'
1238 fi
1239
1240 # gather version control information for inclusion in a prompt
1241
1242 if zrcautoload vcs_info; then
1243     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1244     # function, which can cause a lot of trouble with our directory-based
1245     # profiles. So:
1246     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1247         function VCS_INFO_realpath () {
1248             setopt localoptions NO_shwordsplit chaselinks
1249             ( builtin cd -q $1 2> /dev/null && pwd; )
1250         }
1251     fi
1252
1253     zstyle ':vcs_info:*' max-exports 2
1254
1255     if [[ -o restricted ]]; then
1256         zstyle ':vcs_info:*' enable NONE
1257     fi
1258 fi
1259
1260 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1261 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1262 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1263 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1264 #       to $vcs_info_msg_N_ as soon as we use the included version.
1265 if [[ "$TERM" == dumb ]] ; then
1266     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1267     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1268 else
1269     # these are the same, just with a lot of colors:
1270     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} " \
1271                                        "zsh: %r"
1272     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR}%} " \
1273                                        "zsh: %r"
1274     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1275 fi
1276
1277 # command not found handling
1278
1279 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1280 function command_not_found_handler() {
1281     emulate -L zsh
1282     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1283         ${GRML_ZSH_CNF_HANDLER} $1
1284     fi
1285     return 1
1286 }
1287
1288 # set prompt
1289 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1290     promptinit # people should be able to use their favourite prompt
1291 else
1292     print 'Notice: no promptinit available :('
1293 fi
1294
1295 setopt prompt_subst
1296
1297 # make sure to use right prompt only when not running a command
1298 is41 && setopt transient_rprompt
1299
1300
1301 function ESC_print () {
1302     info_print $'\ek' $'\e\\' "$@"
1303 }
1304 function set_title () {
1305     info_print  $'\e]0;' $'\a' "$@"
1306 }
1307
1308 function info_print () {
1309     local esc_begin esc_end
1310     esc_begin="$1"
1311     esc_end="$2"
1312     shift 2
1313     printf '%s' ${esc_begin}
1314     printf '%s' "$*"
1315     printf '%s' "${esc_end}"
1316 }
1317
1318 # TODO: revise all these NO* variables and especially their documentation
1319 #       in zsh-help() below.
1320 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1321     [[ $NOPRECMD -gt 0 ]] && return 0
1322     # update VCS information
1323     (( ${+functions[vcs_info]} )) && vcs_info
1324
1325     if [[ $TERM == screen* ]] ; then
1326         if [[ -n ${vcs_info_msg_1_} ]] ; then
1327             ESC_print ${vcs_info_msg_1_}
1328         else
1329             ESC_print "zsh"
1330         fi
1331     fi
1332     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1333     if [[ ${DONTSETRPROMPT:-} -eq 0 ]] ; then
1334         if [[ $BATTERY -gt 0 ]] ; then
1335             # update battery (dropped into $PERCENT) information
1336             battery
1337             RPROMPT="%(?..:() ${PERCENT}"
1338         else
1339             RPROMPT="%(?..:() "
1340         fi
1341     fi
1342     # adjust title of xterm
1343     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1344     [[ ${NOTITLE:-} -gt 0 ]] && return 0
1345     case $TERM in
1346         (xterm*|rxvt*)
1347             set_title ${(%):-"%n@%m: %~"}
1348             ;;
1349     esac
1350 }
1351
1352 # preexec() => a function running before every command
1353 is4 && [[ $NOPRECMD -eq 0 ]] && \
1354 preexec () {
1355     [[ $NOPRECMD -gt 0 ]] && return 0
1356 # set hostname if not running on host with name 'grml'
1357     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1358        NAME="@$HOSTNAME"
1359     fi
1360 # get the name of the program currently running and hostname of local machine
1361 # set screen window title if running in a screen
1362     if [[ "$TERM" == screen* ]] ; then
1363         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1364         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1365         ESC_print ${CMD}
1366     fi
1367 # adjust title of xterm
1368     [[ ${NOTITLE} -gt 0 ]] && return 0
1369     case $TERM in
1370         (xterm*|rxvt*)
1371             set_title "${(%):-"%n@%m:"}" "$1"
1372             ;;
1373     esac
1374 }
1375
1376 EXITCODE="%(?..%?%1v )"
1377 # secondary prompt, printed when the shell needs more information to complete a
1378 # command.
1379 PS2='\`%_> '
1380 # selection prompt used within a select loop.
1381 PS3='?# '
1382 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1383 PS4='+%N:%i:%_> '
1384
1385 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1386 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1387     debian_chroot=$(cat /etc/debian_chroot)
1388 fi
1389
1390 # don't use colors on dumb terminals (like emacs):
1391 if [[ "$TERM" == dumb ]] ; then
1392     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
1393 else
1394     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended
1395     # prompt set variable identifying the chroot you work in (used in the
1396     # prompt below)
1397     if [[ $GRMLPROMPT -gt 0 ]] ; then
1398         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1399 ${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "
1400     else
1401         # This assembles the primary prompt string
1402         if (( EUID != 0 )); then
1403             PROMPT="%B${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%b%n${NO_COLOR}@${CYAN}%m${NO_COLOR} %40<...<%B%~%b%<< "
1404         else
1405             PROMPT="%B${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%b%n${NO_COLOR}@${CYAN}%m${NO_COLOR} %40<...<%B%~%b%<< "
1406         fi
1407     fi
1408 fi
1409
1410 PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
1411
1412 # if we are inside a grml-chroot set a specific prompt theme
1413 if [[ -n "$GRML_CHROOT" ]] ; then
1414     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1415 fi
1416
1417 # 'hash' some often used directories
1418 #d# start
1419 hash -d deb=/var/cache/apt/archives
1420 hash -d doc=/usr/share/doc
1421 hash -d linux=/lib/modules/$(command uname -r)/build/
1422 hash -d log=/var/log
1423 hash -d slog=/var/log/syslog
1424 hash -d src=/usr/src
1425 hash -d templ=/usr/share/doc/grml-templates
1426 hash -d tt=/usr/share/doc/texttools-doc
1427 hash -d www=/var/www
1428 #d# end
1429
1430 # some aliases
1431 if check_com -c screen ; then
1432     if [[ $UID -eq 0 ]] ; then
1433         if [[ -r /etc/grml/screenrc ]]; then
1434             alias screen="${commands[screen]} -c /etc/grml/screenrc"
1435         fi
1436     elif [[ -r $HOME/.screenrc ]] ; then
1437         alias screen="${commands[screen]} -c $HOME/.screenrc"
1438     else
1439         if [[ -r /etc/grml/screenrc_grml ]]; then
1440             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1441         else
1442             if [[ -r /etc/grml/screenrc ]]; then
1443                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
1444             fi
1445         fi
1446     fi
1447 fi
1448
1449 # do we have GNU ls with color-support?
1450 if [[ "$TERM" != dumb ]]; then
1451     #a1# execute \kbd{@a@}:\quad ls with colors
1452     alias ls='ls -b -CF '${ls_options:+"${ls_options[*]}"}
1453     #a1# execute \kbd{@a@}:\quad list all files, with colors
1454     alias la='ls -la '${ls_options:+"${ls_options[*]}"}
1455     #a1# long colored list, without dotfiles (@a@)
1456     alias ll='ls -l '${ls_options:+"${ls_options[*]}"}
1457     #a1# long colored list, human readable sizes (@a@)
1458     alias lh='ls -hAl '${ls_options:+"${ls_options[*]}"}
1459     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1460     alias l='ls -lF '${ls_options:+"${ls_options[*]}"}
1461 else
1462     alias ls='ls -b -CF'
1463     alias la='ls -la'
1464     alias ll='ls -l'
1465     alias lh='ls -hAl'
1466     alias l='ls -lF'
1467 fi
1468
1469 alias mdstat='cat /proc/mdstat'
1470 alias ...='cd ../../'
1471
1472 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1473 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1474     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1475 fi
1476
1477 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1478 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1479 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1480
1481 # make sure it is not assigned yet
1482 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1483 utf2iso() {
1484     if isutfenv ; then
1485         for ENV in $(env | command grep -i '.utf') ; do
1486             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1487         done
1488     fi
1489 }
1490
1491 # make sure it is not assigned yet
1492 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1493 iso2utf() {
1494     if ! isutfenv ; then
1495         for ENV in $(env | command grep -i '\.iso') ; do
1496             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1497         done
1498     fi
1499 }
1500
1501 # especially for roadwarriors using GNU screen and ssh:
1502 if ! check_com asc &>/dev/null ; then
1503   asc() { autossh -t "$@" 'screen -RdU' }
1504   compdef asc=ssh
1505 fi
1506
1507 #f1# Hints for the use of zsh on grml
1508 zsh-help() {
1509     print "$bg[white]$fg[black]
1510 zsh-help - hints for use of zsh on grml
1511 =======================================$reset_color"
1512
1513     print '
1514 Main configuration of zsh happens in /etc/zsh/zshrc.
1515 That file is part of the package grml-etc-core, if you want to
1516 use them on a non-grml-system just get the tar.gz from
1517 http://deb.grml.org/ or (preferably) get it from the git repository:
1518
1519   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1520
1521 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1522 The file is still there, but it is empty for backwards compatibility.
1523
1524 For your own changes use these two files:
1525     $HOME/.zshrc.pre
1526     $HOME/.zshrc.local
1527
1528 The former is sourced very early in our zshrc, the latter is sourced
1529 very lately.
1530
1531 System wide configuration without touching configuration files of grml
1532 can take place in /etc/zsh/zshrc.local.
1533
1534 For information regarding zsh start at http://grml.org/zsh/
1535
1536 Take a look at grml'\''s zsh refcard:
1537 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1538
1539 Check out the main zsh refcard:
1540 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1541
1542 And of course visit the zsh-lovers:
1543 % man zsh-lovers
1544
1545 You can adjust some options through environment variables when
1546 invoking zsh without having to edit configuration files.
1547 Basically meant for bash users who are not used to the power of
1548 the zsh yet. :)
1549
1550   "NOCOR=1    zsh" => deactivate automatic correction
1551   "NOMENU=1   zsh" => do not use auto menu completion
1552                       (note: use ctrl-d for completion instead!)
1553   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1554   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1555                       preexec() and precmd() completely
1556   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1557   "COMMAND_NOT_FOUND=1 zsh"
1558                    => Enable a handler if an external command was not found
1559                       The command called in the handler can be altered by setting
1560                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1561                       "/usr/share/command-not-found/command-not-found"
1562
1563 A value greater than 0 is enables a feature; a value equal to zero
1564 disables it. If you like one or the other of these settings, you can
1565 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1566 zshrc.'
1567
1568     print "
1569 $bg[white]$fg[black]
1570 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1571 Enjoy your grml system with the zsh!$reset_color"
1572 }
1573
1574 # debian stuff
1575 if [[ -r /etc/debian_version ]] ; then
1576     #a3# Execute \kbd{apt-cache search}
1577     alias acs='apt-cache search'
1578     #a3# Execute \kbd{apt-cache show}
1579     alias acsh='apt-cache show'
1580     #a3# Execute \kbd{apt-cache policy}
1581     alias acp='apt-cache policy'
1582     #a3# Execute \kbd{apt-get dist-upgrade}
1583     salias adg="apt-get dist-upgrade"
1584     #a3# Execute \kbd{apt-get install}
1585     salias agi="apt-get install"
1586     #a3# Execute \kbd{aptitude install}
1587     salias ati="aptitude install"
1588     #a3# Execute \kbd{apt-get upgrade}
1589     salias ag="apt-get upgrade"
1590     #a3# Execute \kbd{apt-get update}
1591     salias au="apt-get update"
1592     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1593     salias -a up="aptitude update ; aptitude safe-upgrade"
1594     #a3# Execute \kbd{dpkg-buildpackage}
1595     alias dbp='dpkg-buildpackage'
1596     #a3# Execute \kbd{grep-excuses}
1597     alias ge='grep-excuses'
1598
1599     # get a root shell as normal user in live-cd mode:
1600     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1601        alias su="sudo su"
1602      fi
1603
1604     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1605     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1606     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1607     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1608 fi
1609
1610 # sort installed Debian-packages by size
1611 if check_com -c dpkg-query ; then
1612     #a3# List installed Debian-packages sorted by size
1613     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1614 fi
1615
1616 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1617 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1618     if check_com -c wodim; then
1619         cdrecord() {
1620             cat <<EOMESS
1621 cdrecord is not provided under its original name by Debian anymore.
1622 See #377109 in the BTS of Debian for more details.
1623
1624 Please use the wodim binary instead
1625 EOMESS
1626             return 1
1627         }
1628     fi
1629 fi
1630
1631 # Use hard limits, except for a smaller stack and no core dumps
1632 unlimit
1633 is425 && limit stack 8192
1634 isgrmlcd && limit core 0 # important for a live-cd-system
1635 limit -s
1636
1637 # completion system
1638
1639 # called later (via is4 && grmlcomp)
1640 # note: use 'zstyle' for getting current settings
1641 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
1642 grmlcomp() {
1643     # TODO: This could use some additional information
1644
1645     # allow one error for every three characters typed in approximate completer
1646     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1647
1648     # don't complete backup files as executables
1649     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1650
1651     # start menu completion only if it could find no unambiguous initial string
1652     zstyle ':completion:*:correct:*'       insert-unambiguous true
1653     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1654     zstyle ':completion:*:correct:*'       original true
1655
1656     # activate color-completion
1657     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1658
1659     # format on completion
1660     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1661
1662     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1663     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1664
1665     # insert all expansions for expand completer
1666     zstyle ':completion:*:expand:*'        tag-order all-expansions
1667     zstyle ':completion:*:history-words'   list false
1668
1669     # activate menu
1670     zstyle ':completion:*:history-words'   menu yes
1671
1672     # ignore duplicate entries
1673     zstyle ':completion:*:history-words'   remove-all-dups yes
1674     zstyle ':completion:*:history-words'   stop yes
1675
1676     # match uppercase from lowercase
1677     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1678
1679     # separate matches into groups
1680     zstyle ':completion:*:matches'         group 'yes'
1681     zstyle ':completion:*'                 group-name ''
1682
1683     if [[ "$NOMENU" -eq 0 ]] ; then
1684         # if there are more than 5 options allow selecting from a menu
1685         zstyle ':completion:*'               menu select=5
1686     else
1687         # don't use any menus at all
1688         setopt no_auto_menu
1689     fi
1690
1691     zstyle ':completion:*:messages'        format '%d'
1692     zstyle ':completion:*:options'         auto-description '%d'
1693
1694     # describe options in full
1695     zstyle ':completion:*:options'         description 'yes'
1696
1697     # on processes completion complete all user processes
1698     zstyle ':completion:*:processes'       command 'ps -au$USER'
1699
1700     # offer indexes before parameters in subscripts
1701     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1702
1703     # provide verbose completion information
1704     zstyle ':completion:*'                 verbose true
1705
1706     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1707     # for commands (read: 1st word in the line) that it will list for the user
1708     # to choose from. The following disables that, because it's not exactly fast.
1709     zstyle ':completion:*:-command-:*:'    verbose false
1710
1711     # set format for warnings
1712     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1713
1714     # define files to ignore for zcompile
1715     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1716     zstyle ':completion:correct:'          prompt 'correct to: %e'
1717
1718     # Ignore completion functions for commands you don't have:
1719     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1720
1721     # Provide more processes in completion of programs like killall:
1722     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1723
1724     # complete manual by their section
1725     zstyle ':completion:*:manuals'    separate-sections true
1726     zstyle ':completion:*:manuals.*'  insert-sections   true
1727     zstyle ':completion:*:man:*'      menu yes select
1728
1729     # Search path for sudo completion
1730     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
1731                                                /usr/local/bin  \
1732                                                /usr/sbin       \
1733                                                /usr/bin        \
1734                                                /sbin           \
1735                                                /bin            \
1736                                                /usr/X11R6/bin
1737
1738     # provide .. as a completion
1739     zstyle ':completion:*' special-dirs ..
1740
1741     # run rehash on completion so new installed program are found automatically:
1742     _force_rehash() {
1743         (( CURRENT == 1 )) && rehash
1744         return 1
1745     }
1746
1747     ## correction
1748     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1749     if [[ "$NOCOR" -gt 0 ]] ; then
1750         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1751         setopt nocorrect
1752     else
1753         # try to be smart about when to use what completer...
1754         setopt correct
1755         zstyle -e ':completion:*' completer '
1756             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1757                 _last_try="$HISTNO$BUFFER$CURSOR"
1758                 reply=(_complete _match _ignored _prefix _files)
1759             else
1760                 if [[ $words[1] == (rm|mv) ]] ; then
1761                     reply=(_complete _files)
1762                 else
1763                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1764                 fi
1765             fi'
1766     fi
1767
1768     # command for process lists, the local web server details and host completion
1769     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1770
1771     # caching
1772     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1773                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1774
1775     # host completion
1776     if is42 ; then
1777         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1778         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1779     else
1780         _ssh_hosts=()
1781         _etc_hosts=()
1782     fi
1783     hosts=(
1784         $(hostname)
1785         "$_ssh_hosts[@]"
1786         "$_etc_hosts[@]"
1787         grml.org
1788         localhost
1789     )
1790     zstyle ':completion:*:hosts' hosts $hosts
1791     # TODO: so, why is this here?
1792     #  zstyle '*' hosts $hosts
1793
1794     # use generic completion system for programs not yet defined; (_gnu_generic works
1795     # with commands that provide a --help option with "standard" gnu-like output.)
1796     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
1797                    pal stow tail uname ; do
1798         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
1799     done; unset compcom
1800
1801     # see upgrade function in this file
1802     compdef _hosts upgrade
1803 }
1804
1805 # grmlstuff
1806 grmlstuff() {
1807 # people should use 'grml-x'!
1808     if check_com -c 915resolution; then
1809         855resolution() {
1810             echo "Please use 915resolution as resolution modifying tool for Intel \
1811 graphic chipset."
1812             return -1
1813         }
1814     fi
1815
1816     #a1# Output version of running grml
1817     alias grml-version='cat /etc/grml_version'
1818
1819     if check_com -c rebuildfstab ; then
1820         #a1# Rebuild /etc/fstab
1821         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1822     fi
1823
1824     if check_com -c grml-debootstrap ; then
1825         debian2hd() {
1826             echo "Installing debian to harddisk is possible by using grml-debootstrap."
1827             return 1
1828         }
1829     fi
1830 }
1831
1832 # now run the functions
1833 isgrml && checkhome
1834 is4    && isgrml    && grmlstuff
1835 is4    && grmlcomp
1836
1837 # keephack
1838 is4 && xsource "/etc/zsh/keephack"
1839
1840 # wonderful idea of using "e" glob qualifier by Peter Stephenson
1841 # You use it as follows:
1842 # $ NTREF=/reference/file
1843 # $ ls -l *(e:nt:)
1844 # This lists all the files in the current directory newer than the reference file.
1845 # You can also specify the reference file inline; note quotes:
1846 # $ ls -l *(e:'nt ~/.zshenv':)
1847 is4 && nt() {
1848     if [[ -n $1 ]] ; then
1849         local NTREF=${~1}
1850     fi
1851     [[ $REPLY -nt $NTREF ]]
1852 }
1853
1854 # shell functions
1855
1856 #f1# Reload an autoloadable function
1857 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1858 compdef _functions freload
1859
1860 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1861 sll() {
1862     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1863     for file in "$@" ; do
1864         while [[ -h "$file" ]] ; do
1865             ls -l $file
1866             file=$(readlink "$file")
1867         done
1868     done
1869 }
1870
1871 # TODO: Is it supported to use pager settings like this?
1872 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
1873 # with respect to wordsplitting. (ie. ${=PAGER})
1874 if check_com -c $PAGER ; then
1875     #f1# View Debian's changelog of a given package
1876     dchange() {
1877         emulate -L zsh
1878         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
1879             $PAGER /usr/share/doc/$1/changelog.Debian.gz
1880         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1881             $PAGER /usr/share/doc/$1/changelog.gz
1882         else
1883             if check_com -c aptitude ; then
1884                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1885                 if isgrml ; then
1886                     aptitude -t unstable changelog $1
1887                 else
1888                     aptitude changelog $1
1889                 fi
1890             else
1891                 echo "No changelog for package $1 found, sorry."
1892                 return 1
1893             fi
1894         fi
1895     }
1896     _dchange() { _files -W /usr/share/doc -/ }
1897     compdef _dchange dchange
1898
1899     #f1# View Debian's NEWS of a given package
1900     dnews() {
1901         emulate -L zsh
1902         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
1903             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
1904         else
1905             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
1906                 $PAGER /usr/share/doc/$1/NEWS.gz
1907             else
1908                 echo "No NEWS file for package $1 found, sorry."
1909                 return 1
1910             fi
1911         fi
1912     }
1913     _dnews() { _files -W /usr/share/doc -/ }
1914     compdef _dnews dnews
1915
1916     #f1# View upstream's changelog of a given package
1917     uchange() {
1918         emulate -L zsh
1919         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1920             $PAGER /usr/share/doc/$1/changelog.gz
1921         else
1922             echo "No changelog for package $1 found, sorry."
1923             return 1
1924         fi
1925     }
1926     _uchange() { _files -W /usr/share/doc -/ }
1927     compdef _uchange uchange
1928 fi
1929
1930 # zsh profiling
1931 profile() {
1932     ZSH_PROFILE_RC=1 $SHELL "$@"
1933 }
1934
1935 #f1# Edit an alias via zle
1936 edalias() {
1937     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1938 }
1939 compdef _aliases edalias
1940
1941 #f1# Edit a function via zle
1942 edfunc() {
1943     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
1944 }
1945 compdef _functions edfunc
1946
1947 # use it e.g. via 'Restart apache2'
1948 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
1949 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
1950 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
1951 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
1952 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
1953 #m# f6 Status() \kbd{/etc/init.d/\em{process}}\quad\kbd{status}
1954 if [[ -d /etc/init.d || -d /etc/service ]] ; then
1955     __start_stop() {
1956         local action_="${1:l}"  # e.g Start/Stop/Restart
1957         local service_="$2"
1958         local param_="$3"
1959
1960         local service_target_="$(readlink /etc/init.d/$service_)"
1961         if [[ $service_target_ == "/usr/bin/sv" ]]; then
1962             # runit
1963             case "${action_}" in
1964                 start) if [[ ! -e /etc/service/$service_ ]]; then
1965                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
1966                        else
1967                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1968                        fi ;;
1969                 # there is no reload in runits sysv emulation
1970                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
1971                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
1972             esac
1973         else
1974             # sysvinit
1975             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1976         fi
1977     }
1978
1979     _grmlinitd() {
1980         local -a scripts
1981         scripts=( /etc/init.d/*(x:t) )
1982         _describe "service startup script" scripts
1983     }
1984
1985     for i in Start Restart Stop Force-Reload Reload Status ; do
1986         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
1987         compdef _grmlinitd $i
1988     done
1989 fi
1990
1991 #f1# Provides useful information on globbing
1992 H-Glob() {
1993     echo -e "
1994     /      directories
1995     .      plain files
1996     @      symbolic links
1997     =      sockets
1998     p      named pipes (FIFOs)
1999     *      executable plain files (0100)
2000     %      device files (character or block special)
2001     %b     block special files
2002     %c     character special files
2003     r      owner-readable files (0400)
2004     w      owner-writable files (0200)
2005     x      owner-executable files (0100)
2006     A      group-readable files (0040)
2007     I      group-writable files (0020)
2008     E      group-executable files (0010)
2009     R      world-readable files (0004)
2010     W      world-writable files (0002)
2011     X      world-executable files (0001)
2012     s      setuid files (04000)
2013     S      setgid files (02000)
2014     t      files with the sticky bit (01000)
2015
2016   print *(m-1)          # Files modified up to a day ago
2017   print *(a1)           # Files accessed a day ago
2018   print *(@)            # Just symlinks
2019   print *(Lk+50)        # Files bigger than 50 kilobytes
2020   print *(Lk-50)        # Files smaller than 50 kilobytes
2021   print **/*.c          # All *.c files recursively starting in \$PWD
2022   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2023   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2024   print *~*.*           # All Files that do not contain a dot
2025   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2026   print -l *(.c|.h)     # Lists *.c and *.h
2027   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2028   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2029 }
2030 alias help-zshglob=H-Glob
2031
2032 #v1# set number of lines to display per page
2033 HELP_LINES_PER_PAGE=20
2034 #v1# set location of help-zle cache file
2035 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
2036 #f1# helper function for help-zle, actually generates the help text
2037 help_zle_parse_keybindings()
2038 {
2039     emulate -L zsh
2040     setopt extendedglob
2041     unsetopt ksharrays  #indexing starts at 1
2042
2043     #v1# choose files that help-zle will parse for keybindings
2044     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
2045
2046     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
2047         local load_cache=0
2048         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
2049         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
2050     fi
2051
2052     #fill with default keybindings, possibly to be overwriten in a file later
2053     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2054     local -A help_zle_keybindings
2055     help_zle_keybindings['<Ctrl>@']="set MARK"
2056     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
2057     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
2058     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
2059     help_zle_keybindings['<Ctrl>_']="undo"
2060     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
2061     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
2062     help_zle_keybindings['<Ctrl>e']="goto end of line"
2063     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2064     help_zle_keybindings['<Alt>t']="transpose words"
2065     help_zle_keybindings['<Alt>s']="spellcheck word"
2066     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
2067     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
2068     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2069     help_zle_keybindings["<Alt>'"]="quote line"
2070     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2071     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2072     help_zle_keybindings['<Alt>u']="make next word Uppercase"
2073     help_zle_keybindings['<Alt>l']="make next word lowercase"
2074     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
2075     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2076     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2077     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2078     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2079     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
2080     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2081     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2082     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
2083
2084     #init global variables
2085     unset help_zle_lines help_zle_sln
2086     typeset -g -a help_zle_lines
2087     typeset -g help_zle_sln=1
2088
2089     local k v
2090     local lastkeybind_desc contents     #last description starting with #k# that we found
2091     local num_lines_elapsed=0            #number of lines between last description and keybinding
2092     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2093     for f in $HELPZLE_KEYBINDING_FILES; do
2094         [[ -r "$f" ]] || continue   #not readable ? skip it
2095         contents="$(<$f)"
2096         for cline in "${(f)contents}"; do
2097             #zsh pattern: matches lines like: #k# ..............
2098             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2099                 lastkeybind_desc="$match[*]"
2100                 num_lines_elapsed=0
2101             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2102             #             ignores lines that are commentend out
2103             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2104             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2105                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2106                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2107                     #substitute keybinding string with something readable
2108                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2109                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2110                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2111                     help_zle_keybindings[${k}]=$lastkeybind_desc
2112                 fi
2113                 lastkeybind_desc=""
2114             else
2115               ((num_lines_elapsed++))
2116             fi
2117         done
2118     done
2119     unset contents
2120     #calculate length of keybinding column
2121     local kstrlen=0
2122     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2123     #convert the assoc array into preformated lines, which we are able to sort
2124     for k v in ${(kv)help_zle_keybindings[@]}; do
2125         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2126         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2127     done
2128     #sort lines alphabetically
2129     help_zle_lines=("${(i)help_zle_lines[@]}")
2130     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2131     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2132     zcompile $HELP_ZLE_CACHE_FILE
2133 }
2134 typeset -g help_zle_sln
2135 typeset -g -a help_zle_lines
2136
2137 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2138 help-zle()
2139 {
2140     emulate -L zsh
2141     unsetopt ksharrays  #indexing starts at 1
2142     #help lines already generated ? no ? then do it
2143     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2144     #already displayed all lines ? go back to the start
2145     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2146     local sln=$help_zle_sln
2147     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2148     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2149     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2150 }
2151 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2152 zle -N help-zle && bindkey '^xz' help-zle
2153
2154 # grep for running process, like: 'any vim'
2155 any() {
2156     emulate -L zsh
2157     unsetopt KSH_ARRAYS
2158     if [[ -z "$1" ]] ; then
2159         echo "any - grep for process(es) by keyword" >&2
2160         echo "Usage: any <keyword>" >&2 ; return 1
2161     else
2162         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
2163     fi
2164 }
2165
2166
2167 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2168 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2169 [[ -r /proc/1/maps ]] && \
2170 deswap() {
2171     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2172     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2173     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2174 }
2175
2176 # a wrapper for vim, that deals with title setting
2177 #   VIM_OPTIONS
2178 #       set this array to a set of options to vim you always want
2179 #       to have set when calling vim (in .zshrc.local), like:
2180 #           VIM_OPTIONS=( -p )
2181 #       This will cause vim to send every file given on the
2182 #       commandline to be send to it's own tab (needs vim7).
2183 if check_com vim; then
2184     vim() {
2185         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2186     }
2187 fi
2188
2189 # make a backup of a file
2190 bk() {
2191     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2192 }
2193
2194 ssl_hashes=( sha512 sha256 sha1 md5 )
2195
2196 for sh in ${ssl_hashes}; do
2197     eval 'ssl-cert-'${sh}'() {
2198         emulate -L zsh
2199         if [[ -z $1 ]] ; then
2200             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2201             return 1
2202         fi
2203         openssl x509 -noout -fingerprint -'${sh}' -in $1
2204     }'
2205 done; unset sh
2206
2207 ssl-cert-fingerprints() {
2208     emulate -L zsh
2209     local i
2210     if [[ -z $1 ]] ; then
2211         printf 'usage: ssl-cert-fingerprints <file>\n'
2212         return 1
2213     fi
2214     for i in ${ssl_hashes}
2215         do ssl-cert-$i $1;
2216     done
2217 }
2218
2219 ssl-cert-info() {
2220     emulate -L zsh
2221     if [[ -z $1 ]] ; then
2222         printf 'usage: ssl-cert-info <file>\n'
2223         return 1
2224     fi
2225     openssl x509 -noout -text -in $1
2226     ssl-cert-fingerprints $1
2227 }
2228
2229 # make sure our environment is clean regarding colors
2230 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2231
2232 # "persistent history"
2233 # just write important commands you always need to ~/.important_commands
2234 if [[ -r ~/.important_commands ]] ; then
2235     fc -R ~/.important_commands
2236 fi
2237
2238 # load the lookup subsystem if it's available on the system
2239 zrcautoload lookupinit && lookupinit
2240
2241 # variables
2242
2243 # set terminal property (used e.g. by msgid-chooser)
2244 export COLORTERM="yes"
2245
2246 # aliases
2247
2248 # general
2249 #a2# Execute \kbd{du -sch}
2250 alias da='du -sch'
2251 #a2# Execute \kbd{jobs -l}
2252 alias j='jobs -l'
2253
2254 # listing stuff
2255 #a2# Execute \kbd{ls -lSrah}
2256 alias dir="ls -lSrah"
2257 #a2# Only show dot-directories
2258 alias lad='ls -d .*(/)'
2259 #a2# Only show dot-files
2260 alias lsa='ls -a .*(.)'
2261 #a2# Only files with setgid/setuid/sticky flag
2262 alias lss='ls -l *(s,S,t)'
2263 #a2# Only show symlinks
2264 alias lsl='ls -l *(@)'
2265 #a2# Display only executables
2266 alias lsx='ls -l *(*)'
2267 #a2# Display world-{readable,writable,executable} files
2268 alias lsw='ls -ld *(R,W,X.^ND/)'
2269 #a2# Display the ten biggest files
2270 alias lsbig="ls -flh *(.OL[1,10])"
2271 #a2# Only show directories
2272 alias lsd='ls -d *(/)'
2273 #a2# Only show empty directories
2274 alias lse='ls -d *(/^F)'
2275 #a2# Display the ten newest files
2276 alias lsnew="ls -rtlh *(D.om[1,10])"
2277 #a2# Display the ten oldest files
2278 alias lsold="ls -rtlh *(D.Om[1,10])"
2279 #a2# Display the ten smallest files
2280 alias lssmall="ls -Srl *(.oL[1,10])"
2281 #a2# Display the ten newest directories and ten newest .directories
2282 alias lsnewdir="ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
2283 #a2# Display the ten oldest directories and ten oldest .directories
2284 alias lsolddir="ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
2285
2286 # some useful aliases
2287 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir $OLDCWD}
2288 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2289
2290 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2291 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2292 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2293
2294 # work around non utf8 capable software in utf environment via $LANG and luit
2295 if check_com isutfenv && check_com luit ; then
2296     if check_com -c mrxvt ; then
2297         isutfenv && [[ -n "$LANG" ]] && \
2298             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2299     fi
2300
2301     if check_com -c aterm ; then
2302         isutfenv && [[ -n "$LANG" ]] && \
2303             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2304     fi
2305
2306     if check_com -c centericq ; then
2307         isutfenv && [[ -n "$LANG" ]] && \
2308             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2309     fi
2310 fi
2311
2312 # useful functions
2313
2314 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2315 bk() {
2316     emulate -L zsh
2317     cp -b $1 $1_`date --iso-8601=m`
2318 }
2319
2320 #f5# cd to directoy and list files
2321 cl() {
2322     emulate -L zsh
2323     cd $1 && ls -a
2324 }
2325
2326 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2327 cd() {
2328     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2329         [[ ! -e ${1:h} ]] && return 1
2330         print "Correcting ${1} to ${1:h}"
2331         builtin cd ${1:h}
2332     else
2333         builtin cd "$@"
2334     fi
2335 }
2336
2337 #f5# Create Directoy and \kbd{cd} to it
2338 mkcd() {
2339     if (( ARGC != 1 )); then
2340         printf 'usage: mkcd <new-directory>\n'
2341         return 1;
2342     fi
2343     if [[ ! -d "$1" ]]; then
2344         command mkdir -p "$1"
2345     else
2346         printf '`%s'\'' already exists: cd-ing.\n' "$1"
2347     fi
2348     builtin cd "$1"
2349 }
2350
2351 #f5# Create temporary directory and \kbd{cd} to it
2352 cdt() {
2353     local t
2354     t=$(mktemp -d)
2355     echo "$t"
2356     builtin cd "$t"
2357 }
2358
2359 #f5# Create directory under cursor or the selected area
2360 # Press ctrl-xM to create the directory under the cursor or the selected area.
2361 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2362 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2363 # directory does not exist yet -> press ctrl-XM and problem solved
2364 inplaceMkDirs() {
2365     local PATHTOMKDIR
2366     if ((REGION_ACTIVE==1)); then
2367         local F=$MARK T=$CURSOR
2368         if [[ $F -gt $T ]]; then
2369             F=${CURSOR}
2370             T=${MARK}
2371         fi
2372         # get marked area from buffer and eliminate whitespace
2373         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2374         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2375     else
2376         local bufwords iword
2377         bufwords=(${(z)LBUFFER})
2378         iword=${#bufwords}
2379         bufwords=(${(z)BUFFER})
2380         PATHTOMKDIR="${(Q)bufwords[iword]}"
2381     fi
2382     [[ -z "${PATHTOMKDIR}" ]] && return 1
2383     PATHTOMKDIR=${~PATHTOMKDIR}
2384     if [[ -e "${PATHTOMKDIR}" ]]; then
2385         zle -M " path already exists, doing nothing"
2386     else
2387         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2388         zle end-of-line
2389     fi
2390 }
2391 #k# mkdir -p <dir> from string under cursor or marked area
2392 zle -N inplaceMkDirs && bindkey '^xM' inplaceMkDirs
2393
2394 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2395 accessed() {
2396     emulate -L zsh
2397     print -l -- *(a-${1:-1})
2398 }
2399
2400 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2401 changed() {
2402     emulate -L zsh
2403     print -l -- *(c-${1:-1})
2404 }
2405
2406 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2407 modified() {
2408     emulate -L zsh
2409     print -l -- *(m-${1:-1})
2410 }
2411 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2412 check_com new || alias new=modified
2413
2414 # use colors when GNU grep with color-support
2415 #a2# Execute \kbd{grep -{}-color=auto}
2416 (( $#grep_options > 0 )) && alias grep='grep '${grep_options:+"${grep_options[*]}"}
2417
2418 # Translate DE<=>EN
2419 # 'translate' looks up fot a word in a file with language-to-language
2420 # translations (field separator should be " : "). A typical wordlist looks
2421 # like at follows:
2422 #  | english-word : german-transmission
2423 # It's also only possible to translate english to german but not reciprocal.
2424 # Use the following oneliner to turn back the sort order:
2425 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2426 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2427 #f5# Translates a word
2428 trans() {
2429     emulate -L zsh
2430     case "$1" in
2431         -[dD]*)
2432             translate -l de-en $2
2433             ;;
2434         -[eE]*)
2435             translate -l en-de $2
2436             ;;
2437         *)
2438             echo "Usage: $0 { -D | -E }"
2439             echo "         -D == German to English"
2440             echo "         -E == English to German"
2441     esac
2442 }
2443
2444 # Usage: simple-extract <file>
2445 # Using option -d deletes the original archive file.
2446 #f5# Smart archive extractor
2447 simple-extract() {
2448     emulate -L zsh
2449     setopt extended_glob noclobber
2450     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2451     local RC=0
2452     zparseopts -D -E "d=DELETE_ORIGINAL"
2453     for ARCHIVE in "${@}"; do
2454         case $ARCHIVE in
2455             *(tar.bz2|tbz2|tbz))
2456                 DECOMP_CMD="tar -xvjf -"
2457                 USES_STDIN=true
2458                 USES_STDOUT=false
2459                 ;;
2460             *(tar.gz|tgz))
2461                 DECOMP_CMD="tar -xvzf -"
2462                 USES_STDIN=true
2463                 USES_STDOUT=false
2464                 ;;
2465             *(tar.xz|txz|tar.lzma))
2466                 DECOMP_CMD="tar -xvJf -"
2467                 USES_STDIN=true
2468                 USES_STDOUT=false
2469                 ;;
2470             *tar)
2471                 DECOMP_CMD="tar -xvf -"
2472                 USES_STDIN=true
2473                 USES_STDOUT=false
2474                 ;;
2475             *rar)
2476                 DECOMP_CMD="unrar x"
2477                 USES_STDIN=false
2478                 USES_STDOUT=false
2479                 ;;
2480             *lzh)
2481                 DECOMP_CMD="lha x"
2482                 USES_STDIN=false
2483                 USES_STDOUT=false
2484                 ;;
2485             *7z)
2486                 DECOMP_CMD="7z x"
2487                 USES_STDIN=false
2488                 USES_STDOUT=false
2489                 ;;
2490             *(zip|jar))
2491                 DECOMP_CMD="unzip"
2492                 USES_STDIN=false
2493                 USES_STDOUT=false
2494                 ;;
2495             *deb)
2496                 DECOMP_CMD="ar -x"
2497                 USES_STDIN=false
2498                 USES_STDOUT=false
2499                 ;;
2500             *bz2)
2501                 DECOMP_CMD="bzip2 -d -c -"
2502                 USES_STDIN=true
2503                 USES_STDOUT=true
2504                 ;;
2505             *(gz|Z))
2506                 DECOMP_CMD="gzip -d -c -"
2507                 USES_STDIN=true
2508                 USES_STDOUT=true
2509                 ;;
2510             *(xz|lzma))
2511                 DECOMP_CMD="xz -d -c -"
2512                 USES_STDIN=true
2513                 USES_STDOUT=true
2514                 ;;
2515             *)
2516                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2517                 RC=$((RC+1))
2518                 continue
2519                 ;;
2520         esac
2521
2522         if ! check_com ${DECOMP_CMD[(w)1]}; then
2523             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2524             RC=$((RC+2))
2525             continue
2526         fi
2527
2528         GZTARGET="${ARCHIVE:t:r}"
2529         if [[ -f $ARCHIVE ]] ; then
2530
2531             print "Extracting '$ARCHIVE' ..."
2532             if $USES_STDIN; then
2533                 if $USES_STDOUT; then
2534                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
2535                 else
2536                     ${=DECOMP_CMD} < "$ARCHIVE"
2537                 fi
2538             else
2539                 if $USES_STDOUT; then
2540                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
2541                 else
2542                     ${=DECOMP_CMD} "$ARCHIVE"
2543                 fi
2544             fi
2545             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
2546
2547         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
2548             if check_com curl; then
2549                 WGET_CMD="curl -L -k -s -o -"
2550             elif check_com wget; then
2551                 WGET_CMD="wget -q -O - --no-check-certificate"
2552             else
2553                 print "ERROR: neither wget nor curl is installed" >&2
2554                 RC=$((RC+4))
2555                 continue
2556             fi
2557             print "Downloading and Extracting '$ARCHIVE' ..."
2558             if $USES_STDIN; then
2559                 if $USES_STDOUT; then
2560                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
2561                     RC=$((RC+$?))
2562                 else
2563                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
2564                     RC=$((RC+$?))
2565                 fi
2566             else
2567                 if $USES_STDOUT; then
2568                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
2569                 else
2570                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
2571                 fi
2572             fi
2573
2574         else
2575             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
2576             RC=$((RC+8))
2577         fi
2578     done
2579     return $RC
2580 }
2581
2582 __archive_or_uri()
2583 {
2584     _alternative \
2585         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
2586         '_urls:Remote Archives:_urls'
2587 }
2588
2589 _simple_extract()
2590 {
2591     _arguments \
2592         '-d[delete original archivefile after extraction]' \
2593         '*:Archive Or Uri:__archive_or_uri'
2594 }
2595 compdef _simple_extract simple-extract
2596 alias se=simple-extract
2597
2598 #f5# Set all ulimit parameters to \kbd{unlimited}
2599 allulimit() {
2600     ulimit -c unlimited
2601     ulimit -d unlimited
2602     ulimit -f unlimited
2603     ulimit -l unlimited
2604     ulimit -n unlimited
2605     ulimit -s unlimited
2606     ulimit -t unlimited
2607 }
2608
2609 #f5# Change the xterm title from within GNU-screen
2610 xtrename() {
2611     emulate -L zsh
2612     if [[ $1 != "-f" ]] ; then
2613         if [[ -z ${DISPLAY} ]] ; then
2614             printf 'xtrename only makes sense in X11.\n'
2615             return 1
2616         fi
2617     else
2618         shift
2619     fi
2620     if [[ -z $1 ]] ; then
2621         printf 'usage: xtrename [-f] "title for xterm"\n'
2622         printf '  renames the title of xterm from _within_ screen.\n'
2623         printf '  also works without screen.\n'
2624         printf '  will not work if DISPLAY is unset, use -f to override.\n'
2625         return 0
2626     fi
2627     print -n "\eP\e]0;${1}\C-G\e\\"
2628     return 0
2629 }
2630
2631 # Create small urls via http://goo.gl using curl(1).
2632 # API reference: https://code.google.com/apis/urlshortener/
2633 function zurl() {
2634     emulate -L zsh
2635     setopt extended_glob
2636
2637     if [[ -z $1 ]]; then
2638         print "USAGE: zurl <URL>"
2639         return 1
2640     fi
2641
2642     local PN url prog api json contenttype item
2643     local -a data
2644     PN=$0
2645     url=$1
2646
2647     # Prepend 'http://' to given URL where necessary for later output.
2648     if [[ ${url} != http(s|)://* ]]; then
2649         url='http://'${url}
2650     fi
2651
2652     if check_com -c curl; then
2653         prog=curl
2654     else
2655         print "curl is not available, but mandatory for ${PN}. Aborting."
2656         return 1
2657     fi
2658     api='https://www.googleapis.com/urlshortener/v1/url'
2659     contenttype="Content-Type: application/json"
2660     json="{\"longUrl\": \"${url}\"}"
2661     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
2662     # Parse the response
2663     for item in "${data[@]}"; do
2664         case "$item" in
2665             ' '#'"id":'*)
2666                 item=${item#*: \"}
2667                 item=${item%\",*}
2668                 printf '%s\n' "$item"
2669                 return 0
2670                 ;;
2671         esac
2672     done
2673     return 1
2674 }
2675
2676 #f2# Find history events by search pattern and list them by date.
2677 whatwhen()  {
2678     emulate -L zsh
2679     local usage help ident format_l format_s first_char remain first last
2680     usage='USAGE: whatwhen [options] <searchstring> <search range>'
2681     help='Use `whatwhen -h'\'' for further explanations.'
2682     ident=${(l,${#${:-Usage: }},, ,)}
2683     format_l="${ident}%s\t\t\t%s\n"
2684     format_s="${format_l//(\\t)##/\\t}"
2685     # Make the first char of the word to search for case
2686     # insensitive; e.g. [aA]
2687     first_char=[${(L)1[1]}${(U)1[1]}]
2688     remain=${1[2,-1]}
2689     # Default search range is `-100'.
2690     first=${2:-\-100}
2691     # Optional, just used for `<first> <last>' given.
2692     last=$3
2693     case $1 in
2694         ("")
2695             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
2696             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2697         ;;
2698         (-h)
2699             printf '%s\n\n' ${usage}
2700             print 'OPTIONS:'
2701             printf $format_l '-h' 'show help text'
2702             print '\f'
2703             print 'SEARCH RANGE:'
2704             printf $format_l "'0'" 'the whole history,'
2705             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
2706             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
2707             printf '\n%s\n' 'EXAMPLES:'
2708             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
2709             printf $format_l 'whatwhen zsh -250'
2710             printf $format_l 'whatwhen foo 1 99'
2711         ;;
2712         (\?)
2713             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2714         ;;
2715         (*)
2716             # -l list results on stout rather than invoking $EDITOR.
2717             # -i Print dates as in YYYY-MM-DD.
2718             # -m Search for a - quoted - pattern within the history.
2719             fc -li -m "*${first_char}${remain}*" $first $last
2720         ;;
2721     esac
2722 }
2723
2724 # mercurial related stuff
2725 if check_com -c hg ; then
2726     # gnu like diff for mercurial
2727     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
2728     #f5# GNU like diff for mercurial
2729     hgdi() {
2730         emulate -L zsh
2731         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
2732     }
2733
2734     # build debian package
2735     #a2# Alias for \kbd{hg-buildpackage}
2736     alias hbp='hg-buildpackage'
2737
2738     # execute commands on the versioned patch-queue from the current repos
2739     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
2740
2741     # diffstat for specific version of a mercurial repository
2742     #   hgstat      => display diffstat between last revision and tip
2743     #   hgstat 1234 => display diffstat between revision 1234 and tip
2744     #f5# Diffstat for specific version of a mercurial repos
2745     hgstat() {
2746         emulate -L zsh
2747         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
2748     }
2749
2750 fi # end of check whether we have the 'hg'-executable
2751
2752 # grml-small cleanups
2753
2754 # The following is used to remove zsh-config-items that do not work
2755 # in grml-small by default.
2756 # If you do not want these adjustments (for whatever reason), set
2757 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
2758 # sources if it is there).
2759
2760 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
2761
2762     unset abk[V]
2763     unalias    'V'      &> /dev/null
2764     unfunction vman     &> /dev/null
2765     unfunction viless   &> /dev/null
2766     unfunction 2html    &> /dev/null
2767
2768     # manpages are not in grmlsmall
2769     unfunction manzsh   &> /dev/null
2770     unfunction man2     &> /dev/null
2771
2772 fi
2773
2774 zrclocal
2775
2776 ## genrefcard.pl settings
2777
2778 ### doc strings for external functions from files
2779 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
2780
2781 ### example: split functions-search 8,16,24,32
2782 #@# split functions-search 8
2783
2784 ## END OF FILE #################################################################
2785 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
2786 # Local variables:
2787 # mode: sh
2788 # End: