etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is439(){
 148     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 #f1# Checks whether or not you're running grml
 154 isgrml(){
 155     [[ -f /etc/grml_version ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running a grml cd
 160 isgrmlcd(){
 161     [[ -f /etc/grml_cd ]] && return 0
 162     return 1
 163 }
 164
 165 if isgrml ; then
 166 #f1# Checks whether or not you're running grml-small
 167     isgrmlsmall() {
 168         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 169             return 0
 170         fi
 171         return 1
 172     }
 173 else
 174     isgrmlsmall() { return 1 }
 175 fi
 176
 177 isdarwin(){
 178     [[ $OSTYPE == darwin* ]] && return 0
 179     return 1
 180 }
 181
 182 #f1# are we running within an utf environment?
 183 isutfenv() {
 184     case "$LANG $CHARSET $LANGUAGE" in
 185         *utf*) return 0 ;;
 186         *UTF*) return 0 ;;
 187         *)     return 1 ;;
 188     esac
 189 }
 190
 191 # check for user, if not running as root set $SUDO to sudo
 192 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 193
 194 # change directory to home on first invocation of zsh
 195 # important for rungetty -> autologin
 196 # Thanks go to Bart Schaefer!
 197 isgrml && checkhome() {
 198     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 199         export ALREADY_DID_CD_HOME=$HOME
 200         cd
 201     fi
 202 }
 203
 204 # check for zsh v3.1.7+
 205
 206 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 207      || ${ZSH_VERSION} == 3.<2->.<->*    \
 208      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 209
 210     printf '-!-\n'
 211     printf '-!- In this configuration we try to make use of features, that only\n'
 212     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 213     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 214     printf '-!- advanced features in all supported versions.\n'
 215     printf '-!-\n'
 216     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 217     printf '-!-\n'
 218     printf '-!- While this *may* work, it might as well fail.\n'
 219     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 220     printf '-!-\n'
 221     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 222     printf '-!- If it does today, you'\''ve been lucky.\n'
 223     printf '-!-\n'
 224     printf '-!- Ye been warned!\n'
 225     printf '-!-\n'
 226
 227     function zstyle() { : }
 228 fi
 229
 230 # autoload wrapper - use this one instead of autoload directly
 231 # We need to define this function as early as this, because autoloading
 232 # 'is-at-least()' needs it.
 233 function zrcautoload() {
 234     emulate -L zsh
 235     setopt extended_glob
 236     local fdir ffile
 237     local -i ffound
 238
 239     ffile=$1
 240     (( found = 0 ))
 241     for fdir in ${fpath} ; do
 242         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 243     done
 244
 245     (( ffound == 0 )) && return 1
 246     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 247         autoload -U ${ffile} || return 1
 248     else
 249         autoload ${ffile} || return 1
 250     fi
 251     return 0
 252 }
 253
 254 # Load is-at-least() for more precise version checks Note that this test will
 255 # *always* fail, if the is-at-least function could not be marked for
 256 # autoloading.
 257 zrcautoload is-at-least || is-at-least() { return 1 }
 258
 259 # set some important options (as early as possible)
 260
 261 # append history list to the history file; this is the default but we make sure
 262 # because it's required for share_history.
 263 setopt append_history
 264
 265 # import new commands from the history file also in other zsh-session
 266 is4 && setopt share_history
 267
 268 # save each command's beginning timestamp and the duration to the history file
 269 setopt extended_history
 270
 271 # If a new command line being added to the history list duplicates an older
 272 # one, the older command is removed from the list
 273 is4 && setopt histignorealldups
 274
 275 # remove command lines from the history list when the first character on the
 276 # line is a space
 277 setopt histignorespace
 278
 279 # if a command is issued that can't be executed as a normal command, and the
 280 # command is the name of a directory, perform the cd command to that directory.
 281 setopt auto_cd
 282
 283 # in order to use #, ~ and ^ for filename generation grep word
 284 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 285 # don't forget to quote '^', '~' and '#'!
 286 setopt extended_glob
 287
 288 # display PID when suspending processes as well
 289 setopt longlistjobs
 290
 291 # try to avoid the 'zsh: no matches found...'
 292 setopt nonomatch
 293
 294 # report the status of backgrounds jobs immediately
 295 setopt notify
 296
 297 # whenever a command completion is attempted, make sure the entire command path
 298 # is hashed first.
 299 setopt hash_list_all
 300
 301 # not just at the end
 302 setopt completeinword
 303
 304 # Don't send SIGHUP to background processes when the shell exits.
 305 setopt nohup
 306
 307 # make cd push the old directory onto the directory stack.
 308 setopt auto_pushd
 309
 310 # avoid "beep"ing
 311 setopt nobeep
 312
 313 # don't push the same dir twice.
 314 setopt pushd_ignore_dups
 315
 316 # * shouldn't match dotfiles. ever.
 317 setopt noglobdots
 318
 319 # use zsh style word splitting
 320 setopt noshwordsplit
 321
 322 # don't error out when unset parameters are used
 323 setopt unset
 324
 325 # setting some default values
 326 NOCOR=${NOCOR:-0}
 327 NOMENU=${NOMENU:-0}
 328 NOPRECMD=${NOPRECMD:-0}
 329 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 330 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 331 BATTERY=${BATTERY:-0}
 332 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 333 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 334
 335 # utility functions
 336 # this function checks if a command exists and returns either true
 337 # or false. This avoids using 'which' and 'whence', which will
 338 # avoid problems with aliases for which on certain weird systems. :-)
 339 # Usage: check_com [-c|-g] word
 340 #   -c  only checks for external commands
 341 #   -g  does the usual tests and also checks for global aliases
 342 check_com() {
 343     emulate -L zsh
 344     local -i comonly gatoo
 345
 346     if [[ $1 == '-c' ]] ; then
 347         (( comonly = 1 ))
 348         shift
 349     elif [[ $1 == '-g' ]] ; then
 350         (( gatoo = 1 ))
 351     else
 352         (( comonly = 0 ))
 353         (( gatoo = 0 ))
 354     fi
 355
 356     if (( ${#argv} != 1 )) ; then
 357         printf 'usage: check_com [-c] <command>\n' >&2
 358         return 1
 359     fi
 360
 361     if (( comonly > 0 )) ; then
 362         [[ -n ${commands[$1]}  ]] && return 0
 363         return 1
 364     fi
 365
 366     if   [[ -n ${commands[$1]}    ]] \
 367       || [[ -n ${functions[$1]}   ]] \
 368       || [[ -n ${aliases[$1]}     ]] \
 369       || [[ -n ${reswords[(r)$1]} ]] ; then
 370
 371         return 0
 372     fi
 373
 374     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 375         return 0
 376     fi
 377
 378     return 1
 379 }
 380
 381 # creates an alias and precedes the command with
 382 # sudo if $EUID is not zero.
 383 salias() {
 384     emulate -L zsh
 385     local only=0 ; local multi=0
 386     while [[ $1 == -* ]] ; do
 387         case $1 in
 388             (-o) only=1 ;;
 389             (-a) multi=1 ;;
 390             (--) shift ; break ;;
 391             (-h)
 392                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 393                 printf '  -h      shows this help text.\n'
 394                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 395                 printf '          be careful using this option.\n'
 396                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 397                 return 0
 398                 ;;
 399             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 400         esac
 401         shift
 402     done
 403
 404     if (( ${#argv} > 1 )) ; then
 405         printf 'Too many arguments %s\n' "${#argv}"
 406         return 1
 407     fi
 408
 409     key="${1%%\=*}" ;  val="${1#*\=}"
 410     if (( EUID == 0 )) && (( only == 0 )); then
 411         alias -- "${key}=${val}"
 412     elif (( EUID > 0 )) ; then
 413         (( multi > 0 )) && val="${val// ; / ; sudo }"
 414         alias -- "${key}=sudo ${val}"
 415     fi
 416
 417     return 0
 418 }
 419
 420 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 421 # usage: uprint foo
 422 #   Where foo is the *name* of the parameter you want printed.
 423 #   Note that foo is no typo; $foo would be wrong here!
 424 if ! is42 ; then
 425     uprint () {
 426         emulate -L zsh
 427         local -a u
 428         local w
 429         local parameter=$1
 430
 431         if [[ -z ${parameter} ]] ; then
 432             printf 'usage: uprint <parameter>\n'
 433             return 1
 434         fi
 435
 436         for w in ${(P)parameter} ; do
 437             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 438         done
 439
 440         builtin print -l $u
 441     }
 442 fi
 443
 444 # Check if we can read given files and source those we can.
 445 xsource() {
 446     if (( ${#argv} < 1 )) ; then
 447         printf 'usage: xsource FILE(s)...\n' >&2
 448         return 1
 449     fi
 450
 451     while (( ${#argv} > 0 )) ; do
 452         [[ -r "$1" ]] && source "$1"
 453         shift
 454     done
 455     return 0
 456 }
 457
 458 # Check if we can read a given file and 'cat(1)' it.
 459 xcat() {
 460     emulate -L zsh
 461     if (( ${#argv} != 1 )) ; then
 462         printf 'usage: xcat FILE\n' >&2
 463         return 1
 464     fi
 465
 466     [[ -r $1 ]] && cat $1
 467     return 0
 468 }
 469
 470 # Remove these functions again, they are of use only in these
 471 # setup files. This should be called at the end of .zshrc.
 472 xunfunction() {
 473     emulate -L zsh
 474     local -a funcs
 475     funcs=(salias xcat xsource xunfunction zrcautoload)
 476
 477     for func in $funcs ; do
 478         [[ -n ${functions[$func]} ]] \
 479             && unfunction $func
 480     done
 481     return 0
 482 }
 483
 484 # this allows us to stay in sync with grml's zshrc and put own
 485 # modifications in ~/.zshrc.local
 486 zrclocal() {
 487     xsource "/etc/zsh/zshrc.local"
 488     xsource "${HOME}/.zshrc.local"
 489     return 0
 490 }
 491
 492 # locale setup
 493 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 494     xsource "/etc/default/locale"
 495 fi
 496
 497 for var in LANG LC_ALL LC_MESSAGES ; do
 498     [[ -n ${(P)var} ]] && export $var
 499 done
 500
 501 xsource "/etc/sysconfig/keyboard"
 502
 503 TZ=$(xcat /etc/timezone)
 504
 505 # set some variables
 506 if check_com -c vim ; then
 507 #v#
 508     export EDITOR=${EDITOR:-vim}
 509 else
 510     export EDITOR=${EDITOR:-vi}
 511 fi
 512
 513 #v#
 514 export PAGER=${PAGER:-less}
 515
 516 #v#
 517 export MAIL=${MAIL:-/var/mail/$USER}
 518
 519 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 520 export SHELL='/bin/zsh'
 521
 522 # color setup for ls:
 523 check_com -c dircolors && eval $(dircolors -b)
 524 # color setup for ls on OS X:
 525 isdarwin && export CLICOLOR=1
 526
 527 # do MacPorts setup on darwin
 528 if isdarwin && [[ -d /opt/local ]]; then
 529     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 530     # zshenv.
 531     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 532     MANPATH="/opt/local/share/man:$MANPATH"
 533 fi
 534 # do Fink setup on darwin
 535 isdarwin && xsource /sw/bin/init.sh
 536
 537 # load our function and completion directories
 538 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 539     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 540     if [[ ${fpath} == '/usr/share/grml/zsh/functions' ]] ; then
 541         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 542             zrcautoload ${func:t}
 543         done
 544     fi
 545 done
 546 unset fdir func
 547
 548 # support colors in less
 549 export LESS_TERMCAP_mb=$'\E[01;31m'
 550 export LESS_TERMCAP_md=$'\E[01;31m'
 551 export LESS_TERMCAP_me=$'\E[0m'
 552 export LESS_TERMCAP_se=$'\E[0m'
 553 export LESS_TERMCAP_so=$'\E[01;44;33m'
 554 export LESS_TERMCAP_ue=$'\E[0m'
 555 export LESS_TERMCAP_us=$'\E[01;32m'
 556
 557 # mailchecks
 558 MAILCHECK=30
 559
 560 # report about cpu-/system-/user-time of command if running longer than
 561 # 5 seconds
 562 REPORTTIME=5
 563
 564 # watch for everyone but me and root
 565 watch=(notme root)
 566
 567 # automatically remove duplicates from these arrays
 568 typeset -U path cdpath fpath manpath
 569
 570 # keybindings
 571 if [[ "$TERM" != emacs ]] ; then
 572     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 573     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 574     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 575     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 576     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 577     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 578     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 579     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 580     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 581     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 582     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 583     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 584     # ncurses stuff:
 585     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 586     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 587     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 588     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 589     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 590     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 591     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 592     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 593 fi
 594
 595 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 596 # use emacs style per default:
 597 bindkey -e
 598 # use vi style:
 599 # bindkey -v
 600
 601 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 602 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 603 beginning-or-end-of-somewhere() {
 604     local hno=$HISTNO
 605     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 606       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 607         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 608     else
 609         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 610         if (( HISTNO != hno )); then
 611             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 612         fi
 613     fi
 614 }
 615 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 616 zle -N end-of-somewhere beginning-or-end-of-somewhere
 617
 618
 619 #if [[ "$TERM" == screen ]] ; then
 620
 621 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 622 ## to beginning/end of buffer on second keypress
 623 ## and to beginning/end of history on (at most) the third keypress
 624 # terminator & non-debian xterm
 625 bindkey '\eOH' beginning-of-somewhere  # home
 626 bindkey '\eOF' end-of-somewhere        # end
 627 # freebsd console
 628 bindkey '\e[H' beginning-of-somewhere   # home
 629 bindkey '\e[F' end-of-somewhere         # end
 630 # xterm,gnome-terminal,quake,etc
 631 bindkey '^[[1~' beginning-of-somewhere  # home
 632 bindkey '^[[4~' end-of-somewhere        # end
 633 # if terminal type is set to 'rxvt':
 634 bindkey '\e[7~' beginning-of-somewhere  # home
 635 bindkey '\e[8~' end-of-somewhere        # end
 636 #fi
 637
 638 bindkey '\e[A'  up-line-or-search       # cursor up
 639 bindkey '\e[B'  down-line-or-search     # <ESC>-
 640
 641 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 642 bindkey "\e[5C" forward-word
 643 bindkey "\e[5D" backward-word
 644 bindkey "\e[1;5C" forward-word
 645 bindkey "\e[1;5D" backward-word
 646 ## the same for alt-left-arrow and alt-right-arrow
 647 bindkey '^[[1;3C' forward-word
 648 bindkey '^[[1;3D' backward-word
 649
 650 # Search backward in the history for a line beginning with the current
 651 # line up to the cursor and move the cursor to the end of the line then
 652 zle -N history-beginning-search-backward-end history-search-end
 653 zle -N history-beginning-search-forward-end  history-search-end
 654 #k# search history backward for entry beginning with typed text
 655 bindkey '^xp'   history-beginning-search-backward-end
 656 #k# search history forward for entry beginning with typed text
 657 bindkey '^xP'   history-beginning-search-forward-end
 658 #k# search history backward for entry beginning with typed text
 659 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 660 #k# search history forward for entry beginning with typed text
 661 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 662
 663 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 664 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 665
 666 # insert unicode character
 667 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 668 # See for example http://unicode.org/charts/ for unicode characters code
 669 zrcautoload insert-unicode-char
 670 zle -N insert-unicode-char
 671 #k# Insert Unicode character
 672 bindkey '^Xi' insert-unicode-char
 673
 674 #m# k Shift-tab Perform backwards menu completion
 675 if [[ -n "$terminfo[kcbt]" ]]; then
 676     bindkey "$terminfo[kcbt]" reverse-menu-complete
 677 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 678     bindkey "$terminfo[cbt]"  reverse-menu-complete
 679 fi
 680
 681 ## toggle the ,. abbreviation feature on/off
 682 # NOABBREVIATION: default abbreviation-state
 683 #                 0 - enabled (default)
 684 #                 1 - disabled
 685 NOABBREVIATION=${NOABBREVIATION:-0}
 686
 687 grml_toggle_abbrev() {
 688     if (( ${NOABBREVIATION} > 0 )) ; then
 689         NOABBREVIATION=0
 690     else
 691         NOABBREVIATION=1
 692     fi
 693 }
 694
 695 zle -N grml_toggle_abbrev
 696 bindkey '^xA' grml_toggle_abbrev
 697
 698 # add a command line to the shells history without executing it
 699 commit-to-history() {
 700     print -s ${(z)BUFFER}
 701     zle send-break
 702 }
 703 zle -N commit-to-history
 704 bindkey "^x^h" commit-to-history
 705
 706 # only slash should be considered as a word separator:
 707 slash-backward-kill-word() {
 708     local WORDCHARS="${WORDCHARS:s@/@}"
 709     # zle backward-word
 710     zle backward-kill-word
 711 }
 712 zle -N slash-backward-kill-word
 713
 714 #k# Kill left-side word or everything up to next slash
 715 bindkey '\ev' slash-backward-kill-word
 716 #k# Kill left-side word or everything up to next slash
 717 bindkey '\e^h' slash-backward-kill-word
 718 #k# Kill left-side word or everything up to next slash
 719 bindkey '\e^?' slash-backward-kill-word
 720
 721 # use the new *-pattern-* widgets for incremental history search
 722 if is439 ; then
 723     bindkey '^r' history-incremental-pattern-search-backward
 724     bindkey '^s' history-incremental-pattern-search-forward
 725 fi
 726
 727 # a generic accept-line wrapper
 728
 729 # This widget can prevent unwanted autocorrections from command-name
 730 # to _command-name, rehash automatically on enter and call any number
 731 # of builtin and user-defined widgets in different contexts.
 732 #
 733 # For a broader description, see:
 734 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 735 #
 736 # The code is imported from the file 'zsh/functions/accept-line' from
 737 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 738 # distributed under the same terms as zsh itself.
 739
 740 # A newly added command will may not be found or will cause false
 741 # correction attempts, if you got auto-correction set. By setting the
 742 # following style, we force accept-line() to rehash, if it cannot
 743 # find the first word on the command line in the $command[] hash.
 744 zstyle ':acceptline:*' rehash true
 745
 746 function Accept-Line() {
 747     setopt localoptions noksharrays
 748     local -a subs
 749     local -xi aldone
 750     local sub
 751     local alcontext=${1:-$alcontext}
 752
 753     zstyle -a ":acceptline:${alcontext}" actions subs
 754
 755     (( ${#subs} < 1 )) && return 0
 756
 757     (( aldone = 0 ))
 758     for sub in ${subs} ; do
 759         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 760         zle ${sub}
 761
 762         (( aldone > 0 )) && break
 763     done
 764 }
 765
 766 function Accept-Line-getdefault() {
 767     emulate -L zsh
 768     local default_action
 769
 770     zstyle -s ":acceptline:${alcontext}" default_action default_action
 771     case ${default_action} in
 772         ((accept-line|))
 773             printf ".accept-line"
 774             ;;
 775         (*)
 776             printf ${default_action}
 777             ;;
 778     esac
 779 }
 780
 781 function Accept-Line-HandleContext() {
 782     zle Accept-Line
 783
 784     default_action=$(Accept-Line-getdefault)
 785     zstyle -T ":acceptline:${alcontext}" call_default \
 786         && zle ${default_action}
 787 }
 788
 789 function accept-line() {
 790     setopt localoptions noksharrays
 791     local -ax cmdline
 792     local -x alcontext
 793     local buf com fname format msg default_action
 794
 795     alcontext='default'
 796     buf="${BUFFER}"
 797     cmdline=(${(z)BUFFER})
 798     com="${cmdline[1]}"
 799     fname="_${com}"
 800
 801     Accept-Line 'preprocess'
 802
 803     zstyle -t ":acceptline:${alcontext}" rehash \
 804         && [[ -z ${commands[$com]} ]]           \
 805         && rehash
 806
 807     if    [[ -n ${com}               ]] \
 808        && [[ -n ${reswords[(r)$com]} ]] \
 809        || [[ -n ${aliases[$com]}     ]] \
 810        || [[ -n ${functions[$com]}   ]] \
 811        || [[ -n ${builtins[$com]}    ]] \
 812        || [[ -n ${commands[$com]}    ]] ; then
 813
 814         # there is something sensible to execute, just do it.
 815         alcontext='normal'
 816         Accept-Line-HandleContext
 817
 818         return
 819     fi
 820
 821     if    [[ -o correct              ]] \
 822        || [[ -o correctall           ]] \
 823        && [[ -n ${functions[$fname]} ]] ; then
 824
 825         # nothing there to execute but there is a function called
 826         # _command_name; a completion widget. Makes no sense to
 827         # call it on the commandline, but the correct{,all} options
 828         # will ask for it nevertheless, so warn the user.
 829         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 830             # Okay, we warned the user before, he called us again,
 831             # so have it his way.
 832             alcontext='force'
 833             Accept-Line-HandleContext
 834
 835             return
 836         fi
 837
 838         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 839             alcontext='normal'
 840             Accept-Line-HandleContext
 841         else
 842             # prepare warning message for the user, configurable via zstyle.
 843             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 844
 845             if [[ -z ${msg} ]] ; then
 846                 msg="%c will not execute and completion %f exists."
 847             fi
 848
 849             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 850
 851             zle -M -- "${msg}"
 852         fi
 853         return
 854     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 855         # If we are here, the commandline contains something that is not
 856         # executable, which is neither subject to _command_name correction
 857         # and is not empty. might be a variable assignment
 858         alcontext='misc'
 859         Accept-Line-HandleContext
 860
 861         return
 862     fi
 863
 864     # If we got this far, the commandline only contains whitespace, or is empty.
 865     alcontext='empty'
 866     Accept-Line-HandleContext
 867 }
 868
 869 zle -N accept-line
 870 zle -N Accept-Line
 871 zle -N Accept-Line-HandleContext
 872
 873 # power completion - abbreviation expansion
 874 # power completion / abbreviation expansion / buffer expansion
 875 # see http://zshwiki.org/home/examples/zleiab for details
 876 # less risky than the global aliases but powerful as well
 877 # just type the abbreviation key and afterwards ',.' to expand it
 878 declare -A abk
 879 setopt extendedglob
 880 setopt interactivecomments
 881 abk=(
 882 #   key   # value                  (#d additional doc string)
 883 #A# start
 884     '...'  '../..'
 885     '....' '../../..'
 886     'BG'   '& exit'
 887     'C'    '| wc -l'
 888     'G'    '|& grep --color=auto '
 889     'H'    '| head'
 890     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 891     'L'    '| less'
 892     'LL'   '|& less -r'
 893     'M'    '| most'
 894     'N'    '&>/dev/null'           #d (No Output)
 895     'R'    '| tr A-z N-za-m'       #d (ROT13)
 896     'SL'   '| sort | less'
 897     'S'    '| sort -u'
 898     'T'    '| tail'
 899     'V'    '|& vim -'
 900 #A# end
 901     'co'   './configure && make && sudo make install'
 902 )
 903
 904 zleiab() {
 905     emulate -L zsh
 906     setopt extendedglob
 907     local MATCH
 908
 909     if (( NOABBREVIATION > 0 )) ; then
 910         LBUFFER="${LBUFFER},."
 911         return 0
 912     fi
 913
 914     matched_chars='[.-|_a-zA-Z0-9]#'
 915     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 916     LBUFFER+=${abk[$MATCH]:-$MATCH}
 917 }
 918
 919 zle -N zleiab
 920 bindkey ",." zleiab
 921
 922 # autoloading
 923 zrcautoload zmv    # who needs mmv or rename?
 924 zrcautoload history-search-end
 925
 926 # we don't want to quote/espace URLs on our own...
 927 # if autoload -U url-quote-magic ; then
 928 #    zle -N self-insert url-quote-magic
 929 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 930 # else
 931 #    print 'Notice: no url-quote-magic available :('
 932 # fi
 933 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 934
 935 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 936 alias run-help >&/dev/null && unalias run-help
 937 for rh in run-help{,-git,-svk,-svn}; do
 938     zrcautoload $rh
 939 done; unset rh
 940
 941 # completion system
 942 if zrcautoload compinit ; then
 943     compinit || print 'Notice: no compinit available :('
 944 else
 945     print 'Notice: no compinit available :('
 946     function zstyle { }
 947     function compdef { }
 948 fi
 949
 950 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 951
 952 is4 && \
 953 for mod in complist deltochar mathfunc ; do
 954     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 955 done
 956
 957 # autoload zsh modules when they are referenced
 958 if is4 ; then
 959     zmodload -a  zsh/stat    zstat
 960     zmodload -a  zsh/zpty    zpty
 961     zmodload -ap zsh/mapfile mapfile
 962 fi
 963
 964 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 965     #k# Insert files and test globbing
 966     bindkey "^Xf" insert-files # C-x-f
 967 fi
 968
 969 bindkey ' '   magic-space    # also do history expansion on space
 970 #k# Trigger menu-complete
 971 bindkey '\ei' menu-complete  # menu completion via esc-i
 972
 973 # press esc-e for editing command line in $EDITOR or $VISUAL
 974 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 975     #k# Edit the current line in \kbd{\$EDITOR}
 976     bindkey '\ee' edit-command-line
 977 fi
 978
 979 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 980     #k# menu selection: pick item but stay in the menu
 981     bindkey -M menuselect '\e^M' accept-and-menu-complete
 982     # also use + and INSERT since it's easier to press repeatedly
 983     bindkey -M menuselect "+" accept-and-menu-complete
 984     bindkey -M menuselect "^[[2~" accept-and-menu-complete
 985
 986     # accept a completion and try to complete again by using menu
 987     # completion; very useful with completing directories
 988     # by using 'undo' one's got a simple file browser
 989     bindkey -M menuselect '^o' accept-and-infer-next-history
 990 fi
 991
 992 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 993 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
 994 zle -N insert-datestamp
 995
 996 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 997 bindkey '^Ed' insert-datestamp
 998
 999 # press esc-m for inserting last typed word again (thanks to caphuso!)
1000 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1001 zle -N insert-last-typed-word;
1002
1003 #k# Insert last typed word
1004 bindkey "\em" insert-last-typed-word
1005
1006 function grml-zsh-fg() {
1007   if (( ${#jobstates} )); then
1008     zle .push-input
1009     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1010     BUFFER="${BUFFER}fg"
1011     zle .accept-line
1012   else
1013     zle -M 'No background jobs. Doing nothing.'
1014   fi
1015 }
1016 zle -N grml-zsh-fg
1017 #k# A smart shortcut for \kbd{fg<enter>}
1018 bindkey '^z' grml-zsh-fg
1019
1020 # run command line as user root via sudo:
1021 sudo-command-line() {
1022     [[ -z $BUFFER ]] && zle up-history
1023     if [[ $BUFFER != sudo\ * ]]; then
1024         BUFFER="sudo $BUFFER"
1025         CURSOR=$(( CURSOR+5 ))
1026     fi
1027 }
1028 zle -N sudo-command-line
1029
1030 #k# prepend the current command with "sudo"
1031 bindkey "^Os" sudo-command-line
1032
1033 ### jump behind the first word on the cmdline.
1034 ### useful to add options.
1035 function jump_after_first_word() {
1036     local words
1037     words=(${(z)BUFFER})
1038
1039     if (( ${#words} <= 1 )) ; then
1040         CURSOR=${#BUFFER}
1041     else
1042         CURSOR=${#${words[1]}}
1043     fi
1044 }
1045 zle -N jump_after_first_word
1046 #k# jump to after first word (for adding options)
1047 bindkey '^x1' jump_after_first_word
1048
1049 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1050 zle -C hist-complete complete-word _generic
1051 zstyle ':completion:hist-complete:*' completer _history
1052 #k# complete word from history with menu
1053 bindkey "^X^X" hist-complete
1054
1055 ## complete word from currently visible Screen or Tmux buffer.
1056 if check_com -c screen || check_com -c tmux; then
1057     _complete_screen_display() {
1058         [[ "$TERM" != "screen" ]] && return 1
1059
1060         local TMPFILE=$(mktemp)
1061         local -U -a _screen_display_wordlist
1062         trap "rm -f $TMPFILE" EXIT
1063
1064         # fill array with contents from screen hardcopy
1065         if ((${+TMUX})); then
1066             #works, but crashes tmux below version 1.4
1067             #luckily tmux -V option to ask for version, was also added in 1.4
1068             tmux -V &>/dev/null || return
1069             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1070         else
1071             screen -X hardcopy $TMPFILE
1072             # screen sucks, it dumps in latin1, apparently always. so recode it
1073             # to system charset
1074             check_com recode && recode latin1 $TMPFILE
1075         fi
1076         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1077         # remove PREFIX to be completed from that array
1078         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1079         compadd -a _screen_display_wordlist
1080     }
1081     #k# complete word from currently visible GNU screen buffer
1082     bindkey -r "^XS"
1083     compdef -k _complete_screen_display complete-word '^XS'
1084 fi
1085
1086 # history
1087
1088 ZSHDIR=$HOME/.zsh
1089
1090 #v#
1091 HISTFILE=$HOME/.zsh_history
1092 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1093 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1094
1095 # dirstack handling
1096
1097 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1098 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1099
1100 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1101     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1102     # "cd -" won't work after login by just setting $OLDPWD, so
1103     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1104 fi
1105
1106 chpwd() {
1107     local -ax my_stack
1108     my_stack=( ${PWD} ${dirstack} )
1109     if is42 ; then
1110         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1111     else
1112         uprint my_stack >! ${DIRSTACKFILE}
1113     fi
1114 }
1115
1116 # directory based profiles
1117
1118 if is433 ; then
1119
1120 CHPWD_PROFILE='default'
1121 function chpwd_profiles() {
1122     # Say you want certain settings to be active in certain directories.
1123     # This is what you want.
1124     #
1125     # zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1126     # zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1127     #
1128     # When that's done and you enter a directory that matches the pattern
1129     # in the third part of the context, a function called chpwd_profile_grml,
1130     # for example, is called (if it exists).
1131     #
1132     # If no pattern matches (read: no profile is detected) the profile is
1133     # set to 'default', which means chpwd_profile_default is attempted to
1134     # be called.
1135     #
1136     # A word about the context (the ':chpwd:profiles:*' stuff in the zstyle
1137     # command) which is used: The third part in the context is matched against
1138     # ${PWD}. That's why using a pattern such as /foo/bar(|/|/*) makes sense.
1139     # Because that way the profile is detected for all these values of ${PWD}:
1140     #   /foo/bar
1141     #   /foo/bar/
1142     #   /foo/bar/baz
1143     # So, if you want to make double damn sure a profile works in /foo/bar
1144     # and everywhere deeper in that tree, just use (|/|/*) and be happy.
1145     #
1146     # The name of the detected profile will be available in a variable called
1147     # 'profile' in your functions. You don't need to do anything, it'll just
1148     # be there.
1149     #
1150     # Then there is the parameter $CHPWD_PROFILE is set to the profile, that
1151     # was is currently active. That way you can avoid running code for a
1152     # profile that is already active, by running code such as the following
1153     # at the start of your function:
1154     #
1155     # function chpwd_profile_grml() {
1156     #     [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1157     #   ...
1158     # }
1159     #
1160     # The initial value for $CHPWD_PROFILE is 'default'.
1161     #
1162     # Version requirement:
1163     #   This feature requires zsh 4.3.3 or newer.
1164     #   If you use this feature and need to know whether it is active in your
1165     #   current shell, there are several ways to do that. Here are two simple
1166     #   ways:
1167     #
1168     #   a) If knowing if the profiles feature is active when zsh starts is
1169     #      good enough for you, you can put the following snippet into your
1170     #      .zshrc.local:
1171     #
1172     #   (( ${+functions[chpwd_profiles]} )) && print "directory profiles active"
1173     #
1174     #   b) If that is not good enough, and you would prefer to be notified
1175     #      whenever a profile changes, you can solve that by making sure you
1176     #      start *every* profile function you create like this:
1177     #
1178     #   function chpwd_profile_myprofilename() {
1179     #       [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1180     #       print "chpwd(): Switching to profile: $profile"
1181     #     ...
1182     #   }
1183     #
1184     #      That makes sure you only get notified if a profile is *changed*,
1185     #      not everytime you change directory, which would probably piss
1186     #      you off fairly quickly. :-)
1187     #
1188     # There you go. Now have fun with that.
1189     local -x profile
1190
1191     zstyle -s ":chpwd:profiles:${PWD}" profile profile || profile='default'
1192     if (( ${+functions[chpwd_profile_$profile]} )) ; then
1193         chpwd_profile_${profile}
1194     fi
1195
1196     CHPWD_PROFILE="${profile}"
1197     return 0
1198 }
1199 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1200
1201 fi # is433
1202
1203 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1204 if [[ $BATTERY -gt 0 ]] ; then
1205     if ! check_com -c acpi ; then
1206         BATTERY=0
1207     fi
1208 fi
1209
1210 battery() {
1211 if [[ $BATTERY -gt 0 ]] ; then
1212     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1213     if [[ -z "$PERCENT" ]] ; then
1214         PERCENT='acpi not present'
1215     else
1216         if [[ "$PERCENT" -lt 20 ]] ; then
1217             PERCENT="warning: ${PERCENT}%%"
1218         else
1219             PERCENT="${PERCENT}%%"
1220         fi
1221     fi
1222 fi
1223 }
1224 # set colors for use in prompts
1225 if zrcautoload colors && colors 2>/dev/null ; then
1226     BLUE="%{${fg[blue]}%}"
1227     RED="%{${fg_bold[red]}%}"
1228     GREEN="%{${fg[green]}%}"
1229     CYAN="%{${fg[cyan]}%}"
1230     MAGENTA="%{${fg[magenta]}%}"
1231     YELLOW="%{${fg[yellow]}%}"
1232     WHITE="%{${fg[white]}%}"
1233     NO_COLOUR="%{${reset_color}%}"
1234 else
1235     BLUE=$'%{\e[1;34m%}'
1236     RED=$'%{\e[1;31m%}'
1237     GREEN=$'%{\e[1;32m%}'
1238     CYAN=$'%{\e[1;36m%}'
1239     WHITE=$'%{\e[1;37m%}'
1240     MAGENTA=$'%{\e[1;35m%}'
1241     YELLOW=$'%{\e[1;33m%}'
1242     NO_COLOUR=$'%{\e[0m%}'
1243 fi
1244
1245 # gather version control information for inclusion in a prompt
1246
1247 if zrcautoload vcs_info; then
1248     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1249     # function, which can cause a lot of trouble with our directory-based
1250     # profiles. So:
1251     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1252         function VCS_INFO_realpath () {
1253             setopt localoptions NO_shwordsplit chaselinks
1254             ( builtin cd -q $1 2> /dev/null && pwd; )
1255         }
1256     fi
1257
1258     zstyle ':vcs_info:*' max-exports 2
1259
1260     if [[ -o restricted ]]; then
1261         zstyle ':vcs_info:*' enable NONE
1262     fi
1263 fi
1264
1265 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1266 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1267 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1268 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1269 #       to $vcs_info_msg_N_ as soon as we use the included version.
1270 if [[ "$TERM" == dumb ]] ; then
1271     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1272     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1273 else
1274     # these are the same, just with a lot of colours:
1275     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
1276                                        "zsh: %r"
1277     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
1278                                        "zsh: %r"
1279     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1280 fi
1281
1282 # command not found handling
1283
1284 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1285 function command_not_found_handler() {
1286     emulate -L zsh
1287     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1288         ${GRML_ZSH_CNF_HANDLER} $1
1289     fi
1290     return 1
1291 }
1292
1293 # set prompt
1294 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1295     promptinit # people should be able to use their favourite prompt
1296 else
1297     print 'Notice: no promptinit available :('
1298 fi
1299
1300 setopt prompt_subst
1301
1302 # make sure to use right prompt only when not running a command
1303 is41 && setopt transient_rprompt
1304
1305
1306 function ESC_print () {
1307     info_print $'\ek' $'\e\\' "$@"
1308 }
1309 function set_title () {
1310     info_print  $'\e]0;' $'\a' "$@"
1311 }
1312
1313 function info_print () {
1314     local esc_begin esc_end
1315     esc_begin="$1"
1316     esc_end="$2"
1317     shift 2
1318     printf '%s' ${esc_begin}
1319     printf '%s' "$*"
1320     printf '%s' "${esc_end}"
1321 }
1322
1323 # TODO: revise all these NO* variables and especially their documentation
1324 #       in zsh-help() below.
1325 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1326     [[ $NOPRECMD -gt 0 ]] && return 0
1327     # update VCS information
1328     (( ${+functions[vcs_info]} )) && vcs_info
1329
1330     if [[ $TERM == screen* ]] ; then
1331         if [[ -n ${vcs_info_msg_1_} ]] ; then
1332             ESC_print ${vcs_info_msg_1_}
1333         else
1334             ESC_print "zsh"
1335         fi
1336     fi
1337     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1338     if [[ ${DONTSETRPROMPT:-} -eq 0 ]] ; then
1339         if [[ $BATTERY -gt 0 ]] ; then
1340             # update battery (dropped into $PERCENT) information
1341             battery
1342             RPROMPT="%(?..:() ${PERCENT}"
1343         else
1344             RPROMPT="%(?..:() "
1345         fi
1346     fi
1347     # adjust title of xterm
1348     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1349     [[ ${NOTITLE:-} -gt 0 ]] && return 0
1350     case $TERM in
1351         (xterm*|rxvt*)
1352             set_title ${(%):-"%n@%m: %~"}
1353             ;;
1354     esac
1355 }
1356
1357 # preexec() => a function running before every command
1358 is4 && [[ $NOPRECMD -eq 0 ]] && \
1359 preexec () {
1360     [[ $NOPRECMD -gt 0 ]] && return 0
1361 # set hostname if not running on host with name 'grml'
1362     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1363        NAME="@$HOSTNAME"
1364     fi
1365 # get the name of the program currently running and hostname of local machine
1366 # set screen window title if running in a screen
1367     if [[ "$TERM" == screen* ]] ; then
1368         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1369         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1370         ESC_print ${CMD}
1371     fi
1372 # adjust title of xterm
1373     [[ ${NOTITLE} -gt 0 ]] && return 0
1374     case $TERM in
1375         (xterm*|rxvt*)
1376             set_title "${(%):-"%n@%m:"}" "$1"
1377             ;;
1378     esac
1379 }
1380
1381 EXITCODE="%(?..%?%1v )"
1382 # secondary prompt, printed when the shell needs more information to complete a
1383 # command.
1384 PS2='\`%_> '
1385 # selection prompt used within a select loop.
1386 PS3='?# '
1387 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1388 PS4='+%N:%i:%_> '
1389
1390 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1391 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1392     debian_chroot=$(cat /etc/debian_chroot)
1393 fi
1394
1395 # don't use colors on dumb terminals (like emacs):
1396 if [[ "$TERM" == dumb ]] ; then
1397     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
1398 else
1399     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended
1400     # prompt set variable identifying the chroot you work in (used in the
1401     # prompt below)
1402     if [[ $GRMLPROMPT -gt 0 ]] ; then
1403         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1404 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1405     else
1406         # This assembles the primary prompt string
1407         if (( EUID != 0 )); then
1408             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1409         else
1410             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1411         fi
1412     fi
1413 fi
1414
1415 PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
1416
1417 # if we are inside a grml-chroot set a specific prompt theme
1418 if [[ -n "$GRML_CHROOT" ]] ; then
1419     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1420 fi
1421
1422 # 'hash' some often used directories
1423 #d# start
1424 hash -d deb=/var/cache/apt/archives
1425 hash -d doc=/usr/share/doc
1426 hash -d linux=/lib/modules/$(command uname -r)/build/
1427 hash -d log=/var/log
1428 hash -d slog=/var/log/syslog
1429 hash -d src=/usr/src
1430 hash -d templ=/usr/share/doc/grml-templates
1431 hash -d tt=/usr/share/doc/texttools-doc
1432 hash -d www=/var/www
1433 #d# end
1434
1435 # some aliases
1436 if check_com -c screen ; then
1437     if [[ $UID -eq 0 ]] ; then
1438         if [[ -r /etc/grml/screenrc ]]; then
1439             alias screen="${commands[screen]} -c /etc/grml/screenrc"
1440         fi
1441     elif [[ -r $HOME/.screenrc ]] ; then
1442         alias screen="${commands[screen]} -c $HOME/.screenrc"
1443     else
1444         if [[ -r /etc/grml/screenrc_grml ]]; then
1445             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1446         else
1447             if [[ -r /etc/grml/screenrc ]]; then
1448                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
1449             fi
1450         fi
1451     fi
1452 fi
1453
1454 # do we have GNU ls with color-support?
1455 if ls --help 2>/dev/null | grep -- --color= >/dev/null \
1456    && [[ "$TERM" != dumb ]]
1457 then
1458     #a1# execute \kbd{@a@}:\quad ls with colors
1459     alias ls='ls -b -CF --color=auto'
1460     #a1# execute \kbd{@a@}:\quad list all files, with colors
1461     alias la='ls -la --color=auto'
1462     #a1# long colored list, without dotfiles (@a@)
1463     alias ll='ls -l --color=auto'
1464     #a1# long colored list, human readable sizes (@a@)
1465     alias lh='ls -hAl --color=auto'
1466     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1467     alias l='ls -lF --color=auto'
1468 else
1469     alias ls='ls -b -CF'
1470     alias la='ls -la'
1471     alias ll='ls -l'
1472     alias lh='ls -hAl'
1473     alias l='ls -lF'
1474 fi
1475
1476 alias mdstat='cat /proc/mdstat'
1477 alias ...='cd ../../'
1478
1479 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1480 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1481     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1482 fi
1483
1484 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1485 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1486 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1487
1488 # make sure it is not assigned yet
1489 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1490 utf2iso() {
1491     if isutfenv ; then
1492         for ENV in $(env | command grep -i '.utf') ; do
1493             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1494         done
1495     fi
1496 }
1497
1498 # make sure it is not assigned yet
1499 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1500 iso2utf() {
1501     if ! isutfenv ; then
1502         for ENV in $(env | command grep -i '\.iso') ; do
1503             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1504         done
1505     fi
1506 }
1507
1508 # especially for roadwarriors using GNU screen and ssh:
1509 if ! check_com asc &>/dev/null ; then
1510   asc() { autossh -t "$@" 'screen -RdU' }
1511   compdef asc=ssh
1512 fi
1513
1514 #f1# Hints for the use of zsh on grml
1515 zsh-help() {
1516     print "$bg[white]$fg[black]
1517 zsh-help - hints for use of zsh on grml
1518 =======================================$reset_color"
1519
1520     print '
1521 Main configuration of zsh happens in /etc/zsh/zshrc.
1522 That file is part of the package grml-etc-core, if you want to
1523 use them on a non-grml-system just get the tar.gz from
1524 http://deb.grml.org/ or (preferably) get it from the git repository:
1525
1526   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1527
1528 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1529 The file is still there, but it is empty for backwards compatibility.
1530
1531 For your own changes use these two files:
1532     $HOME/.zshrc.pre
1533     $HOME/.zshrc.local
1534
1535 The former is sourced very early in our zshrc, the latter is sourced
1536 very lately.
1537
1538 System wide configuration without touching configuration files of grml
1539 can take place in /etc/zsh/zshrc.local.
1540
1541 For information regarding zsh start at http://grml.org/zsh/
1542
1543 Take a look at grml'\''s zsh refcard:
1544 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1545
1546 Check out the main zsh refcard:
1547 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1548
1549 And of course visit the zsh-lovers:
1550 % man zsh-lovers
1551
1552 You can adjust some options through environment variables when
1553 invoking zsh without having to edit configuration files.
1554 Basically meant for bash users who are not used to the power of
1555 the zsh yet. :)
1556
1557   "NOCOR=1    zsh" => deactivate automatic correction
1558   "NOMENU=1   zsh" => do not use auto menu completion
1559                       (note: use ctrl-d for completion instead!)
1560   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1561   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1562                       preexec() and precmd() completely
1563   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1564   "COMMAND_NOT_FOUND=1 zsh"
1565                    => Enable a handler if an external command was not found
1566                       The command called in the handler can be altered by setting
1567                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1568                       "/usr/share/command-not-found/command-not-found"
1569
1570 A value greater than 0 is enables a feature; a value equal to zero
1571 disables it. If you like one or the other of these settings, you can
1572 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1573 zshrc.'
1574
1575     print "
1576 $bg[white]$fg[black]
1577 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1578 Enjoy your grml system with the zsh!$reset_color"
1579 }
1580
1581 # debian stuff
1582 if [[ -r /etc/debian_version ]] ; then
1583     #a3# Execute \kbd{apt-cache search}
1584     alias acs='apt-cache search'
1585     #a3# Execute \kbd{apt-cache show}
1586     alias acsh='apt-cache show'
1587     #a3# Execute \kbd{apt-cache policy}
1588     alias acp='apt-cache policy'
1589     #a3# Execute \kbd{apt-get dist-upgrade}
1590     salias adg="apt-get dist-upgrade"
1591     #a3# Execute \kbd{apt-get install}
1592     salias agi="apt-get install"
1593     #a3# Execute \kbd{aptitude install}
1594     salias ati="aptitude install"
1595     #a3# Execute \kbd{apt-get upgrade}
1596     salias ag="apt-get upgrade"
1597     #a3# Execute \kbd{apt-get update}
1598     salias au="apt-get update"
1599     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1600     salias -a up="aptitude update ; aptitude safe-upgrade"
1601     #a3# Execute \kbd{dpkg-buildpackage}
1602     alias dbp='dpkg-buildpackage'
1603     #a3# Execute \kbd{grep-excuses}
1604     alias ge='grep-excuses'
1605
1606     # get a root shell as normal user in live-cd mode:
1607     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1608        alias su="sudo su"
1609      fi
1610
1611     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1612     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1613     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1614     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1615 fi
1616
1617 # sort installed Debian-packages by size
1618 if check_com -c dpkg-query ; then
1619     #a3# List installed Debian-packages sorted by size
1620     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1621 fi
1622
1623 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1624 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1625     if check_com -c wodim; then
1626         cdrecord() {
1627             cat <<EOMESS
1628 cdrecord is not provided under its original name by Debian anymore.
1629 See #377109 in the BTS of Debian for more details.
1630
1631 Please use the wodim binary instead
1632 EOMESS
1633             return 1
1634         }
1635     fi
1636 fi
1637
1638 # Use hard limits, except for a smaller stack and no core dumps
1639 unlimit
1640 is425 && limit stack 8192
1641 isgrmlcd && limit core 0 # important for a live-cd-system
1642 limit -s
1643
1644 # completion system
1645
1646 # called later (via is4 && grmlcomp)
1647 # note: use 'zstyle' for getting current settings
1648 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
1649 grmlcomp() {
1650     # TODO: This could use some additional information
1651
1652     # allow one error for every three characters typed in approximate completer
1653     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1654
1655     # don't complete backup files as executables
1656     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1657
1658     # start menu completion only if it could find no unambiguous initial string
1659     zstyle ':completion:*:correct:*'       insert-unambiguous true
1660     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1661     zstyle ':completion:*:correct:*'       original true
1662
1663     # activate color-completion
1664     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1665
1666     # format on completion
1667     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1668
1669     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1670     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1671
1672     # insert all expansions for expand completer
1673     zstyle ':completion:*:expand:*'        tag-order all-expansions
1674     zstyle ':completion:*:history-words'   list false
1675
1676     # activate menu
1677     zstyle ':completion:*:history-words'   menu yes
1678
1679     # ignore duplicate entries
1680     zstyle ':completion:*:history-words'   remove-all-dups yes
1681     zstyle ':completion:*:history-words'   stop yes
1682
1683     # match uppercase from lowercase
1684     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1685
1686     # separate matches into groups
1687     zstyle ':completion:*:matches'         group 'yes'
1688     zstyle ':completion:*'                 group-name ''
1689
1690     if [[ "$NOMENU" -eq 0 ]] ; then
1691         # if there are more than 5 options allow selecting from a menu
1692         zstyle ':completion:*'               menu select=5
1693     else
1694         # don't use any menus at all
1695         setopt no_auto_menu
1696     fi
1697
1698     zstyle ':completion:*:messages'        format '%d'
1699     zstyle ':completion:*:options'         auto-description '%d'
1700
1701     # describe options in full
1702     zstyle ':completion:*:options'         description 'yes'
1703
1704     # on processes completion complete all user processes
1705     zstyle ':completion:*:processes'       command 'ps -au$USER'
1706
1707     # offer indexes before parameters in subscripts
1708     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1709
1710     # provide verbose completion information
1711     zstyle ':completion:*'                 verbose true
1712
1713     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1714     # for commands (read: 1st word in the line) that it will list for the user
1715     # to choose from. The following disables that, because it's not exactly fast.
1716     zstyle ':completion:*:-command-:*:'    verbose false
1717
1718     # set format for warnings
1719     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1720
1721     # define files to ignore for zcompile
1722     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1723     zstyle ':completion:correct:'          prompt 'correct to: %e'
1724
1725     # Ignore completion functions for commands you don't have:
1726     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1727
1728     # Provide more processes in completion of programs like killall:
1729     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1730
1731     # complete manual by their section
1732     zstyle ':completion:*:manuals'    separate-sections true
1733     zstyle ':completion:*:manuals.*'  insert-sections   true
1734     zstyle ':completion:*:man:*'      menu yes select
1735
1736     # provide .. as a completion
1737     zstyle ':completion:*' special-dirs ..
1738
1739     # run rehash on completion so new installed program are found automatically:
1740     _force_rehash() {
1741         (( CURRENT == 1 )) && rehash
1742         return 1
1743     }
1744
1745     ## correction
1746     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1747     if [[ "$NOCOR" -gt 0 ]] ; then
1748         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1749         setopt nocorrect
1750     else
1751         # try to be smart about when to use what completer...
1752         setopt correct
1753         zstyle -e ':completion:*' completer '
1754             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1755                 _last_try="$HISTNO$BUFFER$CURSOR"
1756                 reply=(_complete _match _ignored _prefix _files)
1757             else
1758                 if [[ $words[1] == (rm|mv) ]] ; then
1759                     reply=(_complete _files)
1760                 else
1761                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1762                 fi
1763             fi'
1764     fi
1765
1766     # command for process lists, the local web server details and host completion
1767     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1768
1769     # caching
1770     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1771                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1772
1773     # host completion
1774     if is42 ; then
1775         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1776         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1777     else
1778         _ssh_hosts=()
1779         _etc_hosts=()
1780     fi
1781     hosts=(
1782         $(hostname)
1783         "$_ssh_hosts[@]"
1784         "$_etc_hosts[@]"
1785         grml.org
1786         localhost
1787     )
1788     zstyle ':completion:*:hosts' hosts $hosts
1789     # TODO: so, why is this here?
1790     #  zstyle '*' hosts $hosts
1791
1792     # use generic completion system for programs not yet defined; (_gnu_generic works
1793     # with commands that provide a --help option with "standard" gnu-like output.)
1794     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
1795                    pal stow tail uname ; do
1796         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
1797     done; unset compcom
1798
1799     # see upgrade function in this file
1800     compdef _hosts upgrade
1801 }
1802
1803 # grmlstuff
1804 grmlstuff() {
1805 # people should use 'grml-x'!
1806     if check_com -c 915resolution; then
1807         855resolution() {
1808             echo "Please use 915resolution as resolution modifying tool for Intel \
1809 graphic chipset."
1810             return -1
1811         }
1812     fi
1813
1814     #a1# Output version of running grml
1815     alias grml-version='cat /etc/grml_version'
1816
1817     if check_com -c rebuildfstab ; then
1818         #a1# Rebuild /etc/fstab
1819         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1820     fi
1821
1822     if check_com -c grml-debootstrap ; then
1823         debian2hd() {
1824             echo "Installing debian to harddisk is possible by using grml-debootstrap."
1825             return 1
1826         }
1827     fi
1828 }
1829
1830 # now run the functions
1831 isgrml && checkhome
1832 is4    && isgrml    && grmlstuff
1833 is4    && grmlcomp
1834
1835 # keephack
1836 is4 && xsource "/etc/zsh/keephack"
1837
1838 # wonderful idea of using "e" glob qualifier by Peter Stephenson
1839 # You use it as follows:
1840 # $ NTREF=/reference/file
1841 # $ ls -l *(e:nt:)
1842 # This lists all the files in the current directory newer than the reference file.
1843 # You can also specify the reference file inline; note quotes:
1844 # $ ls -l *(e:'nt ~/.zshenv':)
1845 is4 && nt() {
1846     if [[ -n $1 ]] ; then
1847         local NTREF=${~1}
1848     fi
1849     [[ $REPLY -nt $NTREF ]]
1850 }
1851
1852 # shell functions
1853
1854 #f1# Reload an autoloadable function
1855 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1856 compdef _functions freload
1857
1858 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1859 sll() {
1860     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1861     for file in "$@" ; do
1862         while [[ -h "$file" ]] ; do
1863             ls -l $file
1864             file=$(readlink "$file")
1865         done
1866     done
1867 }
1868
1869 # TODO: Is it supported to use pager settings like this?
1870 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
1871 # with respect to wordsplitting. (ie. ${=PAGER})
1872 if check_com -c $PAGER ; then
1873     #f1# View Debian's changelog of a given package
1874     dchange() {
1875         emulate -L zsh
1876         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
1877             $PAGER /usr/share/doc/$1/changelog.Debian.gz
1878         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1879             $PAGER /usr/share/doc/$1/changelog.gz
1880         else
1881             if check_com -c aptitude ; then
1882                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1883                 if isgrml ; then
1884                     aptitude -t unstable changelog $1
1885                 else
1886                     aptitude changelog $1
1887                 fi
1888             else
1889                 echo "No changelog for package $1 found, sorry."
1890                 return 1
1891             fi
1892         fi
1893     }
1894     _dchange() { _files -W /usr/share/doc -/ }
1895     compdef _dchange dchange
1896
1897     #f1# View Debian's NEWS of a given package
1898     dnews() {
1899         emulate -L zsh
1900         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
1901             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
1902         else
1903             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
1904                 $PAGER /usr/share/doc/$1/NEWS.gz
1905             else
1906                 echo "No NEWS file for package $1 found, sorry."
1907                 return 1
1908             fi
1909         fi
1910     }
1911     _dnews() { _files -W /usr/share/doc -/ }
1912     compdef _dnews dnews
1913
1914     #f1# View upstream's changelog of a given package
1915     uchange() {
1916         emulate -L zsh
1917         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1918             $PAGER /usr/share/doc/$1/changelog.gz
1919         else
1920             echo "No changelog for package $1 found, sorry."
1921             return 1
1922         fi
1923     }
1924     _uchange() { _files -W /usr/share/doc -/ }
1925     compdef _uchange uchange
1926 fi
1927
1928 # zsh profiling
1929 profile() {
1930     ZSH_PROFILE_RC=1 $SHELL "$@"
1931 }
1932
1933 #f1# Edit an alias via zle
1934 edalias() {
1935     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1936 }
1937 compdef _aliases edalias
1938
1939 #f1# Edit a function via zle
1940 edfunc() {
1941     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
1942 }
1943 compdef _functions edfunc
1944
1945 # use it e.g. via 'Restart apache2'
1946 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
1947 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
1948 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
1949 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
1950 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
1951 if [[ -d /etc/init.d || -d /etc/service ]] ; then
1952     __start_stop() {
1953         local action_="${1:l}"  # e.g Start/Stop/Restart
1954         local service_="$2"
1955         local param_="$3"
1956
1957         local service_target_="$(readlink /etc/init.d/$service_)"
1958         if [[ $service_target_ == "/usr/bin/sv" ]]; then
1959             # runit
1960             case "${action_}" in
1961                 start) if [[ ! -e /etc/service/$service_ ]]; then
1962                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
1963                        else
1964                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1965                        fi ;;
1966                 # there is no reload in runits sysv emulation
1967                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
1968                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
1969             esac
1970         else
1971             # sysvinit
1972             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1973         fi
1974     }
1975
1976     _grmlinitd() {
1977         local -a scripts
1978         scripts=( /etc/init.d/*(x:t) )
1979         _describe "service startup script" scripts
1980     }
1981
1982     for i in Start Restart Stop Force-Reload Reload ; do
1983         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
1984         compdef _grmlinitd $i
1985     done
1986 fi
1987
1988 #f1# Provides useful information on globbing
1989 H-Glob() {
1990     echo -e "
1991     /      directories
1992     .      plain files
1993     @      symbolic links
1994     =      sockets
1995     p      named pipes (FIFOs)
1996     *      executable plain files (0100)
1997     %      device files (character or block special)
1998     %b     block special files
1999     %c     character special files
2000     r      owner-readable files (0400)
2001     w      owner-writable files (0200)
2002     x      owner-executable files (0100)
2003     A      group-readable files (0040)
2004     I      group-writable files (0020)
2005     E      group-executable files (0010)
2006     R      world-readable files (0004)
2007     W      world-writable files (0002)
2008     X      world-executable files (0001)
2009     s      setuid files (04000)
2010     S      setgid files (02000)
2011     t      files with the sticky bit (01000)
2012
2013   print *(m-1)          # Files modified up to a day ago
2014   print *(a1)           # Files accessed a day ago
2015   print *(@)            # Just symlinks
2016   print *(Lk+50)        # Files bigger than 50 kilobytes
2017   print *(Lk-50)        # Files smaller than 50 kilobytes
2018   print **/*.c          # All *.c files recursively starting in \$PWD
2019   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2020   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2021   print *~*.*           # All Files that do not contain a dot
2022   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2023   print -l *(.c|.h)     # Lists *.c and *.h
2024   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2025   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2026 }
2027 alias help-zshglob=H-Glob
2028
2029 #v1# set number of lines to display per page
2030 HELP_LINES_PER_PAGE=20
2031 #v1# set location of help-zle cache file
2032 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
2033 #f1# helper function for help-zle, actually generates the help text
2034 help_zle_parse_keybindings()
2035 {
2036     emulate -L zsh
2037     setopt extendedglob
2038     unsetopt ksharrays  #indexing starts at 1
2039
2040     #v1# choose files that help-zle will parse for keybindings
2041     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
2042
2043     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
2044         local load_cache=0
2045         for f ($KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
2046         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
2047     fi
2048
2049     #fill with default keybindings, possibly to be overwriten in a file later
2050     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2051     local -A help_zle_keybindings
2052     help_zle_keybindings['<Ctrl>@']="set MARK"
2053     help_zle_keybindings['<Ctrl>X<Ctrl>J']="vi-join lines"
2054     help_zle_keybindings['<Ctrl>X<Ctrl>B']="jump to matching brace"
2055     help_zle_keybindings['<Ctrl>X<Ctrl>U']="undo"
2056     help_zle_keybindings['<Ctrl>_']="undo"
2057     help_zle_keybindings['<Ctrl>X<Ctrl>F<c>']="find <c> in cmdline"
2058     help_zle_keybindings['<Ctrl>A']="goto beginning of line"
2059     help_zle_keybindings['<Ctrl>E']="goto end of line"
2060     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2061     help_zle_keybindings['<Alt>T']="transpose words"
2062     help_zle_keybindings['<Alt>s']="spellcheck word"
2063     help_zle_keybindings['<Ctrl>K']="backward kill buffer"
2064     help_zle_keybindings['<Ctrl>U']="forward kill buffer"
2065     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2066     help_zle_keybindings["<Alt>'"]="quote line"
2067     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2068     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2069     help_zle_keybindings['<Alt>U']="make next word Uppercase"
2070     help_zle_keybindings['<Alt>l']="make next word lowercase"
2071     help_zle_keybindings['<Ctrl>Xd']="preview expansion under cursor"
2072     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2073     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2074     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2075     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2076     help_zle_keybindings['<Ctrl>V']="insert next keypress symbol literally (e.g. for bindkey)"
2077     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2078     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2079     help_zle_keybindings['<Alt>H']="run help on current command"
2080
2081     #init global variables
2082     unset help_zle_lines help_zle_sln
2083     typeset -g -a help_zle_lines
2084     typeset -g help_zle_sln=1
2085
2086     local k v
2087     local lastkeybind_desc contents     #last description starting with #k# that we found
2088     local num_lines_elapsed=0            #number of lines between last description and keybinding
2089     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2090     for f in $HELPZLE_KEYBINDING_FILES; do
2091         [[ -r "$f" ]] || continue   #not readable ? skip it
2092         contents="$(<$f)"
2093         for cline in "${(f)contents}"; do
2094             #zsh pattern: matches lines like: #k# ..............
2095             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2096                 lastkeybind_desc="$match[*]"
2097                 num_lines_elapsed=0
2098             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2099             #             ignores lines that are commentend out
2100             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2101             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2102                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2103                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2104                     #substitute keybinding string with something readable
2105                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2106                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2107                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2108                     help_zle_keybindings[${k}]=$lastkeybind_desc
2109                 fi
2110                 lastkeybind_desc=""
2111             else
2112               ((num_lines_elapsed++))
2113             fi
2114         done
2115     done
2116     unset contents
2117     #calculate length of keybinding column
2118     local kstrlen=0
2119     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2120     #convert the assoc array into preformated lines, which we are able to sort
2121     for k v in ${(kv)help_zle_keybindings[@]}; do
2122         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2123         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2124     done
2125     #sort lines alphabetically
2126     help_zle_lines=("${(i)help_zle_lines[@]}")
2127     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2128     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2129     zcompile $HELP_ZLE_CACHE_FILE
2130 }
2131 typeset -g help_zle_sln
2132 typeset -g -a help_zle_lines
2133
2134 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2135 help-zle()
2136 {
2137     emulate -L zsh
2138     unsetopt ksharrays  #indexing starts at 1
2139     #help lines already generated ? no ? then do it
2140     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2141     #already displayed all lines ? go back to the start
2142     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2143     local sln=$help_zle_sln
2144     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2145     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2146     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2147 }
2148 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2149 zle -N help-zle && bindkey '^Xz' help-zle
2150
2151 # grep for running process, like: 'any vim'
2152 any() {
2153     emulate -L zsh
2154     unsetopt KSH_ARRAYS
2155     if [[ -z "$1" ]] ; then
2156         echo "any - grep for process(es) by keyword" >&2
2157         echo "Usage: any <keyword>" >&2 ; return 1
2158     else
2159         ps xauwww | grep -i --color=auto "[${1[1]}]${1[2,-1]}"
2160     fi
2161 }
2162
2163
2164 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2165 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2166 [[ -r /proc/1/maps ]] && \
2167 deswap() {
2168     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2169     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2170     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2171 }
2172
2173 # a wrapper for vim, that deals with title setting
2174 #   VIM_OPTIONS
2175 #       set this array to a set of options to vim you always want
2176 #       to have set when calling vim (in .zshrc.local), like:
2177 #           VIM_OPTIONS=( -p )
2178 #       This will cause vim to send every file given on the
2179 #       commandline to be send to it's own tab (needs vim7).
2180 vim() {
2181     VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2182 }
2183
2184 # make a backup of a file
2185 bk() {
2186     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2187 }
2188
2189 ssl_hashes=( sha512 sha256 sha1 md5 )
2190
2191 for sh in ${ssl_hashes}; do
2192     eval 'ssl-cert-'${sh}'() {
2193         emulate -L zsh
2194         if [[ -z $1 ]] ; then
2195             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2196             return 1
2197         fi
2198         openssl x509 -noout -fingerprint -'${sh}' -in $1
2199     }'
2200 done; unset sh
2201
2202 ssl-cert-fingerprints() {
2203     emulate -L zsh
2204     local i
2205     if [[ -z $1 ]] ; then
2206         printf 'usage: ssl-cert-fingerprints <file>\n'
2207         return 1
2208     fi
2209     for i in ${ssl_hashes}
2210         do ssl-cert-$i $1;
2211     done
2212 }
2213
2214 ssl-cert-info() {
2215     emulate -L zsh
2216     if [[ -z $1 ]] ; then
2217         printf 'usage: ssl-cert-info <file>\n'
2218         return 1
2219     fi
2220     openssl x509 -noout -text -in $1
2221     ssl-cert-fingerprints $1
2222 }
2223
2224 # make sure our environment is clean regarding colors
2225 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2226
2227 # "persistent history"
2228 # just write important commands you always need to ~/.important_commands
2229 if [[ -r ~/.important_commands ]] ; then
2230     fc -R ~/.important_commands
2231 fi
2232
2233 # load the lookup subsystem if it's available on the system
2234 zrcautoload lookupinit && lookupinit
2235
2236 # variables
2237
2238 # set terminal property (used e.g. by msgid-chooser)
2239 export COLORTERM="yes"
2240
2241 # aliases
2242
2243 # general
2244 #a2# Execute \kbd{du -sch}
2245 alias da='du -sch'
2246 #a2# Execute \kbd{jobs -l}
2247 alias j='jobs -l'
2248
2249 # listing stuff
2250 #a2# Execute \kbd{ls -lSrah}
2251 alias dir="ls -lSrah"
2252 #a2# Only show dot-directories
2253 alias lad='ls -d .*(/)'                # only show dot-directories
2254 #a2# Only show dot-files
2255 alias lsa='ls -a .*(.)'                # only show dot-files
2256 #a2# Only files with setgid/setuid/sticky flag
2257 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
2258 #a2# Only show 1st ten symlinks
2259 alias lsl='ls -l *(@)'                 # only symlinks
2260 #a2# Display only executables
2261 alias lsx='ls -l *(*)'                 # only executables
2262 #a2# Display world-{readable,writable,executable} files
2263 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
2264 #a2# Display the ten biggest files
2265 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
2266 #a2# Only show directories
2267 alias lsd='ls -d *(/)'                 # only show directories
2268 #a2# Only show empty directories
2269 alias lse='ls -d *(/^F)'               # only show empty directories
2270 #a2# Display the ten newest files
2271 alias lsnew="ls -rtlh *(D.om[1,10])"   # display the newest files
2272 #a2# Display the ten oldest files
2273 alias lsold="ls -rtlh *(D.Om[1,10])"   # display the oldest files
2274 #a2# Display the ten smallest files
2275 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
2276 #a2# Display the ten newest directories and ten newest .directories
2277 alias lsnewdir="ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
2278 #a2# Display the ten oldest directories and ten oldest .directories
2279 alias lsolddir="ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
2280
2281 # some useful aliases
2282 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir $OLDCWD}
2283 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2284
2285 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2286 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2287 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2288
2289 # simple webserver
2290 check_com -c python && alias http="python -m SimpleHTTPServer"
2291
2292 # work around non utf8 capable software in utf environment via $LANG and luit
2293 if check_com isutfenv && check_com luit ; then
2294     if check_com -c mrxvt ; then
2295         isutfenv && [[ -n "$LANG" ]] && \
2296             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2297     fi
2298
2299     if check_com -c aterm ; then
2300         isutfenv && [[ -n "$LANG" ]] && \
2301             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2302     fi
2303
2304     if check_com -c centericq ; then
2305         isutfenv && [[ -n "$LANG" ]] && \
2306             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2307     fi
2308 fi
2309
2310 # useful functions
2311
2312 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2313 bk() {
2314     emulate -L zsh
2315     cp -b $1 $1_`date --iso-8601=m`
2316 }
2317
2318 #f5# cd to directoy and list files
2319 cl() {
2320     emulate -L zsh
2321     cd $1 && ls -a
2322 }
2323
2324 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2325 cd() {
2326     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2327         [[ ! -e ${1:h} ]] && return 1
2328         print "Correcting ${1} to ${1:h}"
2329         builtin cd ${1:h}
2330     else
2331         builtin cd "$@"
2332     fi
2333 }
2334
2335 #f5# Create Directoy and \kbd{cd} to it
2336 mkcd() {
2337     mkdir -p "$@" && cd "$@"
2338 }
2339
2340 #f5# Create temporary directory and \kbd{cd} to it
2341 cdt() {
2342     local t
2343     t=$(mktemp -d)
2344     echo "$t"
2345     builtin cd "$t"
2346 }
2347
2348 #f5# Create directory under cursor or the selected area
2349 # Press ctrl-xM to create the directory under the cursor or the selected area.
2350 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2351 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2352 # directory does not exist yet -> press ctrl-XM and problem solved
2353 inplaceMkDirs() {
2354     local PATHTOMKDIR
2355     if ((REGION_ACTIVE==1)); then
2356         local F=$MARK T=$CURSOR
2357         if [[ $F -gt $T ]]; then
2358             F=${CURSOR}
2359             T=${MARK}
2360         fi
2361         # get marked area from buffer and eliminate whitespace
2362         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2363         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2364     else
2365         local bufwords iword
2366         bufwords=(${(z)LBUFFER})
2367         iword=${#bufwords}
2368         bufwords=(${(z)BUFFER})
2369         PATHTOMKDIR="${(Q)bufwords[iword]}"
2370     fi
2371     [[ -z "${PATHTOMKDIR}" ]] && return 1
2372     if [[ -e "${PATHTOMKDIR}" ]]; then
2373         zle -M " path already exists, doing nothing"
2374     else
2375         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2376         zle end-of-line
2377     fi
2378 }
2379 #k# mkdir -p <dir> from string under cursor or marked area
2380 zle -N inplaceMkDirs && bindkey '^XM' inplaceMkDirs
2381
2382 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2383 accessed() {
2384     emulate -L zsh
2385     print -l -- *(a-${1:-1})
2386 }
2387
2388 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2389 changed() {
2390     emulate -L zsh
2391     print -l -- *(c-${1:-1})
2392 }
2393
2394 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2395 modified() {
2396     emulate -L zsh
2397     print -l -- *(m-${1:-1})
2398 }
2399 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2400 check_com new || alias new=modified
2401
2402 # use colors when GNU grep with color-support
2403 #a2# Execute \kbd{grep -{}-color=auto}
2404 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
2405
2406 # Translate DE<=>EN
2407 # 'translate' looks up fot a word in a file with language-to-language
2408 # translations (field separator should be " : "). A typical wordlist looks
2409 # like at follows:
2410 #  | english-word : german-transmission
2411 # It's also only possible to translate english to german but not reciprocal.
2412 # Use the following oneliner to turn back the sort order:
2413 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2414 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2415 #f5# Translates a word
2416 trans() {
2417     emulate -L zsh
2418     case "$1" in
2419         -[dD]*)
2420             translate -l de-en $2
2421             ;;
2422         -[eE]*)
2423             translate -l en-de $2
2424             ;;
2425         *)
2426             echo "Usage: $0 { -D | -E }"
2427             echo "         -D == German to English"
2428             echo "         -E == English to German"
2429     esac
2430 }
2431
2432 # Usage: simple-extract <file>
2433 # Using option -d deletes the original archive file.
2434 #f5# Smart archive extractor
2435 simple-extract() {
2436     emulate -L zsh
2437     setopt extended_glob noclobber
2438     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2439     local RC=0
2440     zparseopts -D -E "d=DELETE_ORIGINAL"
2441     for ARCHIVE in "${@}"; do
2442         case $ARCHIVE in
2443             *.(tar.bz2|tbz2|tbz))
2444                 DECOMP_CMD="tar -xvjf -"
2445                 USES_STDIN=true
2446                 USES_STDOUT=false
2447                 ;;
2448             *.(tar.gz|tgz))
2449                 DECOMP_CMD="tar -xvzf -"
2450                 USES_STDIN=true
2451                 USES_STDOUT=false
2452                 ;;
2453             *.(tar.xz|txz|tar.lzma))
2454                 DECOMP_CMD="tar -xvJf -"
2455                 USES_STDIN=true
2456                 USES_STDOUT=false
2457                 ;;
2458             *.tar)
2459                 DECOMP_CMD="tar -xvf -"
2460                 USES_STDIN=true
2461                 USES_STDOUT=false
2462                 ;;
2463             *.rar)
2464                 DECOMP_CMD="unrar x"
2465                 USES_STDIN=false
2466                 USES_STDOUT=false
2467                 ;;
2468             *.lzh)
2469                 DECOMP_CMD="lha x"
2470                 USES_STDIN=false
2471                 USES_STDOUT=false
2472                 ;;
2473             *.7z)
2474                 DECOMP_CMD="7z x"
2475                 USES_STDIN=false
2476                 USES_STDOUT=false
2477                 ;;
2478             *.(zip|jar))
2479                 DECOMP_CMD="unzip"
2480                 USES_STDIN=false
2481                 USES_STDOUT=false
2482                 ;;
2483             *.deb)
2484                 DECOMP_CMD="ar -x"
2485                 USES_STDIN=false
2486                 USES_STDOUT=false
2487                 ;;
2488             *.bz2)
2489                 DECOMP_CMD="bzip2 -d -c -"
2490                 USES_STDIN=true
2491                 USES_STDOUT=true
2492                 ;;
2493             *.(gz|Z))
2494                 DECOMP_CMD="gzip -d -c -"
2495                 USES_STDIN=true
2496                 USES_STDOUT=true
2497                 ;;
2498             *.(xz|lzma))
2499                 DECOMP_CMD="xz -d -c -"
2500                 USES_STDIN=true
2501                 USES_STDOUT=true
2502                 ;;
2503             *)
2504                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2505                 RC=$((RC+1))
2506                 continue
2507                 ;;
2508         esac
2509
2510         if ! check_com ${DECOMP_CMD[(w)1]}; then
2511             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2512             RC=$((RC+2))
2513             continue
2514         fi
2515
2516         GZTARGET="${ARCHIVE:t:r}"
2517         if [[ -f $ARCHIVE ]] ; then
2518
2519             print "Extracting '$ARCHIVE' ..."
2520             if $USES_STDIN; then
2521                 if $USES_STDOUT; then
2522                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
2523                 else
2524                     ${=DECOMP_CMD} < "$ARCHIVE"
2525                 fi
2526             else
2527                 if $USES_STDOUT; then
2528                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
2529                 else
2530                     ${=DECOMP_CMD} "$ARCHIVE"
2531                 fi
2532             fi
2533             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
2534
2535         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
2536             if check_com curl; then
2537                 WGET_CMD="curl -L -k -s -o -"
2538             elif check_com wget; then
2539                 WGET_CMD="wget -q -O - --no-check-certificate"
2540             else
2541                 print "ERROR: neither wget nor curl is installed" >&2
2542                 RC=$((RC+4))
2543                 continue
2544             fi
2545             print "Downloading and Extracting '$ARCHIVE' ..."
2546             if $USES_STDIN; then
2547                 if $USES_STDOUT; then
2548                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
2549                     RC=$((RC+$?))
2550                 else
2551                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
2552                     RC=$((RC+$?))
2553                 fi
2554             else
2555                 if $USES_STDOUT; then
2556                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
2557                 else
2558                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
2559                 fi
2560             fi
2561
2562         else
2563             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
2564             RC=$((RC+8))
2565         fi
2566     done
2567     return $RC
2568 }
2569
2570 __archive_or_uri()
2571 {
2572     _alternative \
2573         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
2574         '_urls:Remote Archives:_urls'
2575 }
2576
2577 _simple_extract()
2578 {
2579     _arguments \
2580         '-d[delete original archivefile after extraction]' \
2581         '*:Archive Or Uri:__archive_or_uri'
2582 }
2583 compdef _simple_extract simple-extract
2584 alias se=simple-extract
2585
2586 #f5# Set all ulimit parameters to \kbd{unlimited}
2587 allulimit() {
2588     ulimit -c unlimited
2589     ulimit -d unlimited
2590     ulimit -f unlimited
2591     ulimit -l unlimited
2592     ulimit -n unlimited
2593     ulimit -s unlimited
2594     ulimit -t unlimited
2595 }
2596
2597 #f5# Change the xterm title from within GNU-screen
2598 xtrename() {
2599     emulate -L zsh
2600     if [[ $1 != "-f" ]] ; then
2601         if [[ -z ${DISPLAY} ]] ; then
2602             printf 'xtrename only makes sense in X11.\n'
2603             return 1
2604         fi
2605     else
2606         shift
2607     fi
2608     if [[ -z $1 ]] ; then
2609         printf 'usage: xtrename [-f] "title for xterm"\n'
2610         printf '  renames the title of xterm from _within_ screen.\n'
2611         printf '  also works without screen.\n'
2612         printf '  will not work if DISPLAY is unset, use -f to override.\n'
2613         return 0
2614     fi
2615     print -n "\eP\e]0;${1}\C-G\e\\"
2616     return 0
2617 }
2618
2619 # TODO:
2620 # Rewrite this by either using tinyurl.com's API
2621 # or using another shortening service to comply with
2622 # tinyurl.com's policy.
2623 #
2624 # Create small urls via http://tinyurl.com using wget(1).
2625 #function zurl() {
2626 #    emulate -L zsh
2627 #    [[ -z $1 ]] && { print "USAGE: zurl <URL>" ; return 1 }
2628 #
2629 #    local PN url tiny grabber search result preview
2630 #    PN=$0
2631 #    url=$1
2632 ##   Check existence of given URL with the help of ping(1).
2633 ##   N.B. ping(1) only works without an eventual given protocol.
2634 #    ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
2635 #        read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
2636 #
2637 #    if (( $? == 0 )) ; then
2638 ##           Prepend 'http://' to given URL where necessary for later output.
2639 #            [[ ${url} != http(s|)://* ]] && url='http://'${url}
2640 #            tiny='http://tinyurl.com/create.php?url='
2641 #            if check_com -c wget ; then
2642 #                grabber='wget -O- -o/dev/null'
2643 #            else
2644 #                print "wget is not available, but mandatory for ${PN}. Aborting."
2645 #            fi
2646 ##           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
2647 #            search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
2648 #            result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
2649 ##           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
2650 #            preview='http://preview.'${result#http://}
2651 #
2652 #            printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
2653 #            printf '%s\t%s\n\n' 'Given URL:' ${url}
2654 #            printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
2655 #    else
2656 #        return 1
2657 #    fi
2658 #}
2659
2660 #f2# Find history events by search pattern and list them by date.
2661 whatwhen()  {
2662     emulate -L zsh
2663     local usage help ident format_l format_s first_char remain first last
2664     usage='USAGE: whatwhen [options] <searchstring> <search range>'
2665     help='Use `whatwhen -h'\'' for further explanations.'
2666     ident=${(l,${#${:-Usage: }},, ,)}
2667     format_l="${ident}%s\t\t\t%s\n"
2668     format_s="${format_l//(\\t)##/\\t}"
2669     # Make the first char of the word to search for case
2670     # insensitive; e.g. [aA]
2671     first_char=[${(L)1[1]}${(U)1[1]}]
2672     remain=${1[2,-1]}
2673     # Default search range is `-100'.
2674     first=${2:-\-100}
2675     # Optional, just used for `<first> <last>' given.
2676     last=$3
2677     case $1 in
2678         ("")
2679             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
2680             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2681         ;;
2682         (-h)
2683             printf '%s\n\n' ${usage}
2684             print 'OPTIONS:'
2685             printf $format_l '-h' 'show help text'
2686             print '\f'
2687             print 'SEARCH RANGE:'
2688             printf $format_l "'0'" 'the whole history,'
2689             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
2690             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
2691             printf '\n%s\n' 'EXAMPLES:'
2692             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
2693             printf $format_l 'whatwhen zsh -250'
2694             printf $format_l 'whatwhen foo 1 99'
2695         ;;
2696         (\?)
2697             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2698         ;;
2699         (*)
2700             # -l list results on stout rather than invoking $EDITOR.
2701             # -i Print dates as in YYYY-MM-DD.
2702             # -m Search for a - quoted - pattern within the history.
2703             fc -li -m "*${first_char}${remain}*" $first $last
2704         ;;
2705     esac
2706 }
2707
2708 # mercurial related stuff
2709 if check_com -c hg ; then
2710     # gnu like diff for mercurial
2711     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
2712     #f5# GNU like diff for mercurial
2713     hgdi() {
2714         emulate -L zsh
2715         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
2716     }
2717
2718     # build debian package
2719     #a2# Alias for \kbd{hg-buildpackage}
2720     alias hbp='hg-buildpackage'
2721
2722     # execute commands on the versioned patch-queue from the current repos
2723     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
2724
2725     # diffstat for specific version of a mercurial repository
2726     #   hgstat      => display diffstat between last revision and tip
2727     #   hgstat 1234 => display diffstat between revision 1234 and tip
2728     #f5# Diffstat for specific version of a mercurial repos
2729     hgstat() {
2730         emulate -L zsh
2731         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
2732     }
2733
2734 fi # end of check whether we have the 'hg'-executable
2735
2736 # grml-small cleanups
2737
2738 # The following is used to remove zsh-config-items that do not work
2739 # in grml-small by default.
2740 # If you do not want these adjustments (for whatever reason), set
2741 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
2742 # sources if it is there).
2743
2744 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
2745
2746     unset abk[V]
2747     unalias    'V'      &> /dev/null
2748     unfunction vman     &> /dev/null
2749     unfunction viless   &> /dev/null
2750     unfunction 2html    &> /dev/null
2751
2752     # manpages are not in grmlsmall
2753     unfunction manzsh   &> /dev/null
2754     unfunction man2     &> /dev/null
2755
2756 fi
2757
2758 zrclocal
2759
2760 ## genrefcard.pl settings
2761
2762 ### doc strings for external functions from files
2763 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
2764
2765 ### example: split functions-search 8,16,24,32
2766 #@# split functions-search 8
2767
2768 ## END OF FILE #################################################################
2769 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
2770 # Local variables:
2771 # mode: sh
2772 # End: