etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is437(){
 148     [[ $ZSH_VERSION == 4.3.<7->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 is439(){
 154     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 155                                  || $ZSH_VERSION == <5->* ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running grml
 160 isgrml(){
 161     [[ -f /etc/grml_version ]] && return 0
 162     return 1
 163 }
 164
 165 #f1# Checks whether or not you're running a grml cd
 166 isgrmlcd(){
 167     [[ -f /etc/grml_cd ]] && return 0
 168     return 1
 169 }
 170
 171 if isgrml ; then
 172 #f1# Checks whether or not you're running grml-small
 173     isgrmlsmall() {
 174         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 175             return 0
 176         fi
 177         return 1
 178     }
 179 else
 180     isgrmlsmall() { return 1 }
 181 fi
 182
 183 GRML_OSTYPE=$(uname -s)
 184
 185 islinux(){
 186     [[ $GRML_OSTYPE == "Linux" ]]
 187 }
 188
 189 isdarwin(){
 190     [[ $GRML_OSTYPE == "Darwin" ]]
 191 }
 192
 193 isfreebsd(){
 194     [[ $GRML_OSTYPE == "FreeBSD" ]]
 195 }
 196
 197 isopenbsd(){
 198     [[ $GRML_OSTYPE == "OpenBSD" ]]
 199 }
 200
 201 issolaris(){
 202     [[ $GRML_OSTYPE == "SunOS" ]]
 203 }
 204
 205 #f1# are we running within an utf environment?
 206 isutfenv() {
 207     case "$LANG $CHARSET $LANGUAGE" in
 208         *utf*) return 0 ;;
 209         *UTF*) return 0 ;;
 210         *)     return 1 ;;
 211     esac
 212 }
 213
 214 # check for user, if not running as root set $SUDO to sudo
 215 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 216
 217 # change directory to home on first invocation of zsh
 218 # important for rungetty -> autologin
 219 # Thanks go to Bart Schaefer!
 220 isgrml && checkhome() {
 221     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 222         export ALREADY_DID_CD_HOME=$HOME
 223         cd
 224     fi
 225 }
 226
 227 # check for zsh v3.1.7+
 228
 229 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 230      || ${ZSH_VERSION} == 3.<2->.<->*    \
 231      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 232
 233     printf '-!-\n'
 234     printf '-!- In this configuration we try to make use of features, that only\n'
 235     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 236     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 237     printf '-!- advanced features in all supported versions.\n'
 238     printf '-!-\n'
 239     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 240     printf '-!-\n'
 241     printf '-!- While this *may* work, it might as well fail.\n'
 242     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 243     printf '-!-\n'
 244     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 245     printf '-!- If it does today, you'\''ve been lucky.\n'
 246     printf '-!-\n'
 247     printf '-!- Ye been warned!\n'
 248     printf '-!-\n'
 249
 250     function zstyle() { : }
 251 fi
 252
 253 # autoload wrapper - use this one instead of autoload directly
 254 # We need to define this function as early as this, because autoloading
 255 # 'is-at-least()' needs it.
 256 function zrcautoload() {
 257     emulate -L zsh
 258     setopt extended_glob
 259     local fdir ffile
 260     local -i ffound
 261
 262     ffile=$1
 263     (( ffound = 0 ))
 264     for fdir in ${fpath} ; do
 265         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 266     done
 267
 268     (( ffound == 0 )) && return 1
 269     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 270         autoload -U ${ffile} || return 1
 271     else
 272         autoload ${ffile} || return 1
 273     fi
 274     return 0
 275 }
 276
 277 # The following is the ‘add-zsh-hook’ function from zsh upstream. It is
 278 # included here to make the setup work with older versions of zsh (prior to
 279 # 4.3.7) in which this function had a bug that triggers annoying errors during
 280 # shell startup. This is exactly upstreams code from f0068edb4888a4d8fe94def,
 281 # with just a few adjustments in coding style to make the function look more
 282 # compact. This definition can be removed as soon as we raise the minimum
 283 # version requirement to 4.3.7 or newer.
 284 function add-zsh-hook() {
 285     # Add to HOOK the given FUNCTION.
 286     # HOOK is one of chpwd, precmd, preexec, periodic, zshaddhistory,
 287     # zshexit, zsh_directory_name (the _functions subscript is not required).
 288     #
 289     # With -d, remove the function from the hook instead; delete the hook
 290     # variable if it is empty.
 291     #
 292     # -D behaves like -d, but pattern characters are active in the function
 293     # name, so any matching function will be deleted from the hook.
 294     #
 295     # Without -d, the FUNCTION is marked for autoload; -U is passed down to
 296     # autoload if that is given, as are -z and -k. (This is harmless if the
 297     # function is actually defined inline.)
 298     emulate -L zsh
 299     local -a hooktypes
 300     hooktypes=(
 301         chpwd precmd preexec periodic zshaddhistory zshexit
 302         zsh_directory_name
 303     )
 304     local usage="Usage: $0 hook function\nValid hooks are:\n  $hooktypes"
 305     local opt
 306     local -a autoopts
 307     integer del list help
 308     while getopts "dDhLUzk" opt; do
 309         case $opt in
 310         (d) del=1 ;;
 311         (D) del=2 ;;
 312         (h) help=1 ;;
 313         (L) list=1 ;;
 314         ([Uzk]) autoopts+=(-$opt) ;;
 315         (*) return 1 ;;
 316         esac
 317     done
 318     shift $(( OPTIND - 1 ))
 319     if (( list )); then
 320         typeset -mp "(${1:-${(@j:|:)hooktypes}})_functions"
 321         return $?
 322     elif (( help || $# != 2 || ${hooktypes[(I)$1]} == 0 )); then
 323         print -u$(( 2 - help )) $usage
 324         return $(( 1 - help ))
 325     fi
 326     local hook="${1}_functions"
 327     local fn="$2"
 328     if (( del )); then
 329         # delete, if hook is set
 330         if (( ${(P)+hook} )); then
 331             if (( del == 2 )); then
 332                 set -A $hook ${(P)hook:#${~fn}}
 333             else
 334                 set -A $hook ${(P)hook:#$fn}
 335             fi
 336             # unset if no remaining entries --- this can give better
 337             # performance in some cases
 338             if (( ! ${(P)#hook} )); then
 339                 unset $hook
 340             fi
 341         fi
 342     else
 343         if (( ${(P)+hook} )); then
 344             if (( ${${(P)hook}[(I)$fn]} == 0 )); then
 345                 set -A $hook ${(P)hook} $fn
 346             fi
 347         else
 348             set -A $hook $fn
 349         fi
 350         autoload $autoopts -- $fn
 351     fi
 352 }
 353
 354 # Load is-at-least() for more precise version checks Note that this test will
 355 # *always* fail, if the is-at-least function could not be marked for
 356 # autoloading.
 357 zrcautoload is-at-least || is-at-least() { return 1 }
 358
 359 # set some important options (as early as possible)
 360
 361 # append history list to the history file; this is the default but we make sure
 362 # because it's required for share_history.
 363 setopt append_history
 364
 365 # import new commands from the history file also in other zsh-session
 366 is4 && setopt share_history
 367
 368 # save each command's beginning timestamp and the duration to the history file
 369 setopt extended_history
 370
 371 # If a new command line being added to the history list duplicates an older
 372 # one, the older command is removed from the list
 373 is4 && setopt histignorealldups
 374
 375 # remove command lines from the history list when the first character on the
 376 # line is a space
 377 setopt histignorespace
 378
 379 # if a command is issued that can't be executed as a normal command, and the
 380 # command is the name of a directory, perform the cd command to that directory.
 381 setopt auto_cd
 382
 383 # in order to use #, ~ and ^ for filename generation grep word
 384 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 385 # don't forget to quote '^', '~' and '#'!
 386 setopt extended_glob
 387
 388 # display PID when suspending processes as well
 389 setopt longlistjobs
 390
 391 # report the status of backgrounds jobs immediately
 392 setopt notify
 393
 394 # whenever a command completion is attempted, make sure the entire command path
 395 # is hashed first.
 396 setopt hash_list_all
 397
 398 # not just at the end
 399 setopt completeinword
 400
 401 # Don't send SIGHUP to background processes when the shell exits.
 402 setopt nohup
 403
 404 # make cd push the old directory onto the directory stack.
 405 setopt auto_pushd
 406
 407 # avoid "beep"ing
 408 setopt nobeep
 409
 410 # don't push the same dir twice.
 411 setopt pushd_ignore_dups
 412
 413 # * shouldn't match dotfiles. ever.
 414 setopt noglobdots
 415
 416 # use zsh style word splitting
 417 setopt noshwordsplit
 418
 419 # don't error out when unset parameters are used
 420 setopt unset
 421
 422 # setting some default values
 423 NOCOR=${NOCOR:-0}
 424 NOMENU=${NOMENU:-0}
 425 NOPRECMD=${NOPRECMD:-0}
 426 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 427 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 428 GRML_DISPLAY_BATTERY=${GRML_DISPLAY_BATTERY:-${BATTERY:-0}}
 429 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 430 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 431
 432 typeset -ga ls_options
 433 typeset -ga grep_options
 434 if ls --color=auto / >/dev/null 2>&1; then
 435     ls_options+=( --color=auto )
 436 elif ls -G / >/dev/null 2>&1; then
 437     ls_options+=( -G )
 438 fi
 439 if grep --color=auto -q "a" <<< "a" >/dev/null 2>&1; then
 440     grep_options+=( --color=auto )
 441 fi
 442
 443 # utility functions
 444 # this function checks if a command exists and returns either true
 445 # or false. This avoids using 'which' and 'whence', which will
 446 # avoid problems with aliases for which on certain weird systems. :-)
 447 # Usage: check_com [-c|-g] word
 448 #   -c  only checks for external commands
 449 #   -g  does the usual tests and also checks for global aliases
 450 check_com() {
 451     emulate -L zsh
 452     local -i comonly gatoo
 453     comonly=0
 454     gatoo=0
 455
 456     if [[ $1 == '-c' ]] ; then
 457         comonly=1
 458         shift 1
 459     elif [[ $1 == '-g' ]] ; then
 460         gatoo=1
 461         shift 1
 462     fi
 463
 464     if (( ${#argv} != 1 )) ; then
 465         printf 'usage: check_com [-c|-g] <command>\n' >&2
 466         return 1
 467     fi
 468
 469     if (( comonly > 0 )) ; then
 470         (( ${+commands[$1]}  )) && return 0
 471         return 1
 472     fi
 473
 474     if     (( ${+commands[$1]}    )) \
 475         || (( ${+functions[$1]}   )) \
 476         || (( ${+aliases[$1]}     )) \
 477         || (( ${+reswords[(r)$1]} )) ; then
 478         return 0
 479     fi
 480
 481     if (( gatoo > 0 )) && (( ${+galiases[$1]} )) ; then
 482         return 0
 483     fi
 484
 485     return 1
 486 }
 487
 488 # creates an alias and precedes the command with
 489 # sudo if $EUID is not zero.
 490 salias() {
 491     emulate -L zsh
 492     local only=0 ; local multi=0
 493     local key val
 494     while getopts ":hao" opt; do
 495         case $opt in
 496             o) only=1 ;;
 497             a) multi=1 ;;
 498             h)
 499                 printf 'usage: salias [-hoa] <alias-expression>\n'
 500                 printf '  -h      shows this help text.\n'
 501                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 502                 printf '          be careful using this option.\n'
 503                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 504                 return 0
 505                 ;;
 506             *) salias -h >&2; return 1 ;;
 507         esac
 508     done
 509     shift "$((OPTIND-1))"
 510
 511     if (( ${#argv} > 1 )) ; then
 512         printf 'Too many arguments %s\n' "${#argv}"
 513         return 1
 514     fi
 515
 516     key="${1%%\=*}" ;  val="${1#*\=}"
 517     if (( EUID == 0 )) && (( only == 0 )); then
 518         alias -- "${key}=${val}"
 519     elif (( EUID > 0 )) ; then
 520         (( multi > 0 )) && val="${val// ; / ; sudo }"
 521         alias -- "${key}=sudo ${val}"
 522     fi
 523
 524     return 0
 525 }
 526
 527 # Check if we can read given files and source those we can.
 528 xsource() {
 529     if (( ${#argv} < 1 )) ; then
 530         printf 'usage: xsource FILE(s)...\n' >&2
 531         return 1
 532     fi
 533
 534     while (( ${#argv} > 0 )) ; do
 535         [[ -r "$1" ]] && source "$1"
 536         shift
 537     done
 538     return 0
 539 }
 540
 541 # Check if we can read a given file and 'cat(1)' it.
 542 xcat() {
 543     emulate -L zsh
 544     if (( ${#argv} != 1 )) ; then
 545         printf 'usage: xcat FILE\n' >&2
 546         return 1
 547     fi
 548
 549     [[ -r $1 ]] && cat $1
 550     return 0
 551 }
 552
 553 # Remove these functions again, they are of use only in these
 554 # setup files. This should be called at the end of .zshrc.
 555 xunfunction() {
 556     emulate -L zsh
 557     local -a funcs
 558     local func
 559     funcs=(salias xcat xsource xunfunction zrcautoload zrcautozle)
 560     for func in $funcs ; do
 561         [[ -n ${functions[$func]} ]] \
 562             && unfunction $func
 563     done
 564     return 0
 565 }
 566
 567 # this allows us to stay in sync with grml's zshrc and put own
 568 # modifications in ~/.zshrc.local
 569 zrclocal() {
 570     xsource "/etc/zsh/zshrc.local"
 571     xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
 572     return 0
 573 }
 574
 575 # locale setup
 576 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 577     xsource "/etc/default/locale"
 578 fi
 579
 580 for var in LANG LC_ALL LC_MESSAGES ; do
 581     [[ -n ${(P)var} ]] && export $var
 582 done
 583 builtin unset -v var
 584
 585 # set some variables
 586 if check_com -c vim ; then
 587 #v#
 588     export EDITOR=${EDITOR:-vim}
 589 else
 590     export EDITOR=${EDITOR:-vi}
 591 fi
 592
 593 #v#
 594 export PAGER=${PAGER:-less}
 595
 596 #v#
 597 export MAIL=${MAIL:-/var/mail/$USER}
 598
 599 # color setup for ls:
 600 check_com -c dircolors && eval $(dircolors -b)
 601 # color setup for ls on OS X / FreeBSD:
 602 isdarwin && export CLICOLOR=1
 603 isfreebsd && export CLICOLOR=1
 604
 605 # do MacPorts setup on darwin
 606 if isdarwin && [[ -d /opt/local ]]; then
 607     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 608     # zshenv.
 609     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 610     MANPATH="/opt/local/share/man:$MANPATH"
 611 fi
 612 # do Fink setup on darwin
 613 isdarwin && xsource /sw/bin/init.sh
 614
 615 # load our function and completion directories
 616 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 617     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 618     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 619         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 620             zrcautoload ${func:t}
 621         done
 622     fi
 623 done
 624 unset fdir func
 625
 626 # support colors in less
 627 export LESS_TERMCAP_mb=$'\E[01;31m'
 628 export LESS_TERMCAP_md=$'\E[01;31m'
 629 export LESS_TERMCAP_me=$'\E[0m'
 630 export LESS_TERMCAP_se=$'\E[0m'
 631 export LESS_TERMCAP_so=$'\E[01;44;33m'
 632 export LESS_TERMCAP_ue=$'\E[0m'
 633 export LESS_TERMCAP_us=$'\E[01;32m'
 634
 635 # mailchecks
 636 MAILCHECK=30
 637
 638 # report about cpu-/system-/user-time of command if running longer than
 639 # 5 seconds
 640 REPORTTIME=5
 641
 642 # watch for everyone but me and root
 643 watch=(notme root)
 644
 645 # automatically remove duplicates from these arrays
 646 typeset -U path cdpath fpath manpath
 647
 648 # Load a few modules
 649 is4 && \
 650 for mod in parameter complist deltochar mathfunc ; do
 651     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 652 done && builtin unset -v mod
 653
 654 # autoload zsh modules when they are referenced
 655 if is4 ; then
 656     zmodload -a  zsh/stat    zstat
 657     zmodload -a  zsh/zpty    zpty
 658     zmodload -ap zsh/mapfile mapfile
 659 fi
 660
 661 # completion system
 662 COMPDUMPFILE=${COMPDUMPFILE:-${ZDOTDIR:-${HOME}}/.zcompdump}
 663 if zrcautoload compinit ; then
 664     compinit -d ${COMPDUMPFILE} || print 'Notice: no compinit available :('
 665 else
 666     print 'Notice: no compinit available :('
 667     function compdef { }
 668 fi
 669
 670 # completion system
 671
 672 # called later (via is4 && grmlcomp)
 673 # note: use 'zstyle' for getting current settings
 674 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
 675 grmlcomp() {
 676     # TODO: This could use some additional information
 677
 678     # Make sure the completion system is initialised
 679     (( ${+_comps} )) || return 1
 680
 681     # allow one error for every three characters typed in approximate completer
 682     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
 683
 684     # don't complete backup files as executables
 685     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
 686
 687     # start menu completion only if it could find no unambiguous initial string
 688     zstyle ':completion:*:correct:*'       insert-unambiguous true
 689     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
 690     zstyle ':completion:*:correct:*'       original true
 691
 692     # activate color-completion
 693     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
 694
 695     # format on completion
 696     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
 697
 698     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
 699     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
 700
 701     # insert all expansions for expand completer
 702     zstyle ':completion:*:expand:*'        tag-order all-expansions
 703     zstyle ':completion:*:history-words'   list false
 704
 705     # activate menu
 706     zstyle ':completion:*:history-words'   menu yes
 707
 708     # ignore duplicate entries
 709     zstyle ':completion:*:history-words'   remove-all-dups yes
 710     zstyle ':completion:*:history-words'   stop yes
 711
 712     # match uppercase from lowercase
 713     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
 714
 715     # separate matches into groups
 716     zstyle ':completion:*:matches'         group 'yes'
 717     zstyle ':completion:*'                 group-name ''
 718
 719     if [[ "$NOMENU" -eq 0 ]] ; then
 720         # if there are more than 5 options allow selecting from a menu
 721         zstyle ':completion:*'               menu select=5
 722     else
 723         # don't use any menus at all
 724         setopt no_auto_menu
 725     fi
 726
 727     zstyle ':completion:*:messages'        format '%d'
 728     zstyle ':completion:*:options'         auto-description '%d'
 729
 730     # describe options in full
 731     zstyle ':completion:*:options'         description 'yes'
 732
 733     # on processes completion complete all user processes
 734     zstyle ':completion:*:processes'       command 'ps -au$USER'
 735
 736     # offer indexes before parameters in subscripts
 737     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
 738
 739     # provide verbose completion information
 740     zstyle ':completion:*'                 verbose true
 741
 742     # recent (as of Dec 2007) zsh versions are able to provide descriptions
 743     # for commands (read: 1st word in the line) that it will list for the user
 744     # to choose from. The following disables that, because it's not exactly fast.
 745     zstyle ':completion:*:-command-:*:'    verbose false
 746
 747     # set format for warnings
 748     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
 749
 750     # define files to ignore for zcompile
 751     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
 752     zstyle ':completion:correct:'          prompt 'correct to: %e'
 753
 754     # Ignore completion functions for commands you don't have:
 755     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
 756
 757     # Provide more processes in completion of programs like killall:
 758     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
 759
 760     # complete manual by their section
 761     zstyle ':completion:*:manuals'    separate-sections true
 762     zstyle ':completion:*:manuals.*'  insert-sections   true
 763     zstyle ':completion:*:man:*'      menu yes select
 764
 765     # Search path for sudo completion
 766     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
 767                                                /usr/local/bin  \
 768                                                /usr/sbin       \
 769                                                /usr/bin        \
 770                                                /sbin           \
 771                                                /bin            \
 772                                                /usr/X11R6/bin
 773
 774     # provide .. as a completion
 775     zstyle ':completion:*' special-dirs ..
 776
 777     # run rehash on completion so new installed program are found automatically:
 778     _force_rehash() {
 779         (( CURRENT == 1 )) && rehash
 780         return 1
 781     }
 782
 783     ## correction
 784     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
 785     if [[ "$NOCOR" -gt 0 ]] ; then
 786         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
 787         setopt nocorrect
 788     else
 789         # try to be smart about when to use what completer...
 790         setopt correct
 791         zstyle -e ':completion:*' completer '
 792             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
 793                 _last_try="$HISTNO$BUFFER$CURSOR"
 794                 reply=(_complete _match _ignored _prefix _files)
 795             else
 796                 if [[ $words[1] == (rm|mv) ]] ; then
 797                     reply=(_complete _files)
 798                 else
 799                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
 800                 fi
 801             fi'
 802     fi
 803
 804     # command for process lists, the local web server details and host completion
 805     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
 806
 807     # Some functions, like _apt and _dpkg, are very slow. We can use a cache in
 808     # order to speed things up
 809     if [[ ${GRML_COMP_CACHING:-yes} == yes ]]; then
 810         GRML_COMP_CACHE_DIR=${GRML_COMP_CACHE_DIR:-${ZDOTDIR:-$HOME}/.cache}
 811         if [[ ! -d ${GRML_COMP_CACHE_DIR} ]]; then
 812             command mkdir -p "${GRML_COMP_CACHE_DIR}"
 813         fi
 814         zstyle ':completion:*' use-cache  yes
 815         zstyle ':completion:*:complete:*' cache-path "${GRML_COMP_CACHE_DIR}"
 816     fi
 817
 818     # host completion
 819     if is42 ; then
 820         [[ -r ~/.ssh/config ]] && _ssh_config_hosts=(${${(s: :)${(ps:\t:)${${(@M)${(f)"$(<$HOME/.ssh/config)"}:#Host *}#Host }}}:#*[*?]*}) || _ssh_config_hosts=()
 821         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
 822         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
 823     else
 824         _ssh_config_hosts=()
 825         _ssh_hosts=()
 826         _etc_hosts=()
 827     fi
 828     hosts=(
 829         $(hostname)
 830         "$_ssh_config_hosts[@]"
 831         "$_ssh_hosts[@]"
 832         "$_etc_hosts[@]"
 833         localhost
 834     )
 835     zstyle ':completion:*:hosts' hosts $hosts
 836     # TODO: so, why is this here?
 837     #  zstyle '*' hosts $hosts
 838
 839     # use generic completion system for programs not yet defined; (_gnu_generic works
 840     # with commands that provide a --help option with "standard" gnu-like output.)
 841     for compcom in cp deborphan df feh fetchipac gpasswd head hnb ipacsum mv \
 842                    pal stow uname ; do
 843         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
 844     done; unset compcom
 845
 846     # see upgrade function in this file
 847     compdef _hosts upgrade
 848 }
 849
 850 # Keyboard setup: The following is based on the same code, we wrote for
 851 # debian's setup. It ensures the terminal is in the right mode, when zle is
 852 # active, so the values from $terminfo are valid. Therefore, this setup should
 853 # work on all systems, that have support for `terminfo'. It also requires the
 854 # zsh in use to have the `zsh/terminfo' module built.
 855 #
 856 # If you are customising your `zle-line-init()' or `zle-line-finish()'
 857 # functions, make sure you call the following utility functions in there:
 858 #
 859 #     - zle-line-init():      zle-smkx
 860 #     - zle-line-finish():    zle-rmkx
 861
 862 # Use emacs-like key bindings by default:
 863 bindkey -e
 864
 865 # Custom widgets:
 866
 867 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 868 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 869 beginning-or-end-of-somewhere() {
 870     local hno=$HISTNO
 871     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 872       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 873         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 874     else
 875         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 876         if (( HISTNO != hno )); then
 877             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 878         fi
 879     fi
 880 }
 881 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 882 zle -N end-of-somewhere beginning-or-end-of-somewhere
 883
 884 # add a command line to the shells history without executing it
 885 commit-to-history() {
 886     print -s ${(z)BUFFER}
 887     zle send-break
 888 }
 889 zle -N commit-to-history
 890
 891 # only slash should be considered as a word separator:
 892 slash-backward-kill-word() {
 893     local WORDCHARS="${WORDCHARS:s@/@}"
 894     # zle backward-word
 895     zle backward-kill-word
 896 }
 897 zle -N slash-backward-kill-word
 898
 899 # a generic accept-line wrapper
 900
 901 # This widget can prevent unwanted autocorrections from command-name
 902 # to _command-name, rehash automatically on enter and call any number
 903 # of builtin and user-defined widgets in different contexts.
 904 #
 905 # For a broader description, see:
 906 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 907 #
 908 # The code is imported from the file 'zsh/functions/accept-line' from
 909 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 910 # distributed under the same terms as zsh itself.
 911
 912 # A newly added command will may not be found or will cause false
 913 # correction attempts, if you got auto-correction set. By setting the
 914 # following style, we force accept-line() to rehash, if it cannot
 915 # find the first word on the command line in the $command[] hash.
 916 zstyle ':acceptline:*' rehash true
 917
 918 function Accept-Line() {
 919     setopt localoptions noksharrays
 920     local -a subs
 921     local -xi aldone
 922     local sub
 923     local alcontext=${1:-$alcontext}
 924
 925     zstyle -a ":acceptline:${alcontext}" actions subs
 926
 927     (( ${#subs} < 1 )) && return 0
 928
 929     (( aldone = 0 ))
 930     for sub in ${subs} ; do
 931         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 932         zle ${sub}
 933
 934         (( aldone > 0 )) && break
 935     done
 936 }
 937
 938 function Accept-Line-getdefault() {
 939     emulate -L zsh
 940     local default_action
 941
 942     zstyle -s ":acceptline:${alcontext}" default_action default_action
 943     case ${default_action} in
 944         ((accept-line|))
 945             printf ".accept-line"
 946             ;;
 947         (*)
 948             printf ${default_action}
 949             ;;
 950     esac
 951 }
 952
 953 function Accept-Line-HandleContext() {
 954     zle Accept-Line
 955
 956     default_action=$(Accept-Line-getdefault)
 957     zstyle -T ":acceptline:${alcontext}" call_default \
 958         && zle ${default_action}
 959 }
 960
 961 function accept-line() {
 962     setopt localoptions noksharrays
 963     local -a cmdline
 964     local -x alcontext
 965     local buf com fname format msg default_action
 966
 967     alcontext='default'
 968     buf="${BUFFER}"
 969     cmdline=(${(z)BUFFER})
 970     com="${cmdline[1]}"
 971     fname="_${com}"
 972
 973     Accept-Line 'preprocess'
 974
 975     zstyle -t ":acceptline:${alcontext}" rehash \
 976         && [[ -z ${commands[$com]} ]]           \
 977         && rehash
 978
 979     if    [[ -n ${com}               ]] \
 980        && [[ -n ${reswords[(r)$com]} ]] \
 981        || [[ -n ${aliases[$com]}     ]] \
 982        || [[ -n ${functions[$com]}   ]] \
 983        || [[ -n ${builtins[$com]}    ]] \
 984        || [[ -n ${commands[$com]}    ]] ; then
 985
 986         # there is something sensible to execute, just do it.
 987         alcontext='normal'
 988         Accept-Line-HandleContext
 989
 990         return
 991     fi
 992
 993     if    [[ -o correct              ]] \
 994        || [[ -o correctall           ]] \
 995        && [[ -n ${functions[$fname]} ]] ; then
 996
 997         # nothing there to execute but there is a function called
 998         # _command_name; a completion widget. Makes no sense to
 999         # call it on the commandline, but the correct{,all} options
1000         # will ask for it nevertheless, so warn the user.
1001         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
1002             # Okay, we warned the user before, he called us again,
1003             # so have it his way.
1004             alcontext='force'
1005             Accept-Line-HandleContext
1006
1007             return
1008         fi
1009
1010         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
1011             alcontext='normal'
1012             Accept-Line-HandleContext
1013         else
1014             # prepare warning message for the user, configurable via zstyle.
1015             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
1016
1017             if [[ -z ${msg} ]] ; then
1018                 msg="%c will not execute and completion %f exists."
1019             fi
1020
1021             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
1022
1023             zle -M -- "${msg}"
1024         fi
1025         return
1026     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
1027         # If we are here, the commandline contains something that is not
1028         # executable, which is neither subject to _command_name correction
1029         # and is not empty. might be a variable assignment
1030         alcontext='misc'
1031         Accept-Line-HandleContext
1032
1033         return
1034     fi
1035
1036     # If we got this far, the commandline only contains whitespace, or is empty.
1037     alcontext='empty'
1038     Accept-Line-HandleContext
1039 }
1040
1041 zle -N accept-line
1042 zle -N Accept-Line
1043 zle -N Accept-Line-HandleContext
1044
1045 # power completion / abbreviation expansion / buffer expansion
1046 # see http://zshwiki.org/home/examples/zleiab for details
1047 # less risky than the global aliases but powerful as well
1048 # just type the abbreviation key and afterwards 'ctrl-x .' to expand it
1049 declare -A abk
1050 setopt extendedglob
1051 setopt interactivecomments
1052 abk=(
1053 #   key   # value                  (#d additional doc string)
1054 #A# start
1055     '...'  '../..'
1056     '....' '../../..'
1057     'BG'   '& exit'
1058     'C'    '| wc -l'
1059     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
1060     'H'    '| head'
1061     'Hl'   ' --help |& less -r'    #d (Display help in pager)
1062     'L'    '| less'
1063     'LL'   '|& less -r'
1064     'M'    '| most'
1065     'N'    '&>/dev/null'           #d (No Output)
1066     'R'    '| tr A-z N-za-m'       #d (ROT13)
1067     'SL'   '| sort | less'
1068     'S'    '| sort -u'
1069     'T'    '| tail'
1070     'V'    '|& vim -'
1071 #A# end
1072     'co'   './configure && make && sudo make install'
1073 )
1074
1075 zleiab() {
1076     emulate -L zsh
1077     setopt extendedglob
1078     local MATCH
1079
1080     LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
1081     LBUFFER+=${abk[$MATCH]:-$MATCH}
1082 }
1083
1084 zle -N zleiab
1085
1086 help-show-abk()
1087 {
1088   zle -M "$(print "Available abbreviations for expansion:"; print -a -C 2 ${(kv)abk})"
1089 }
1090
1091 zle -N help-show-abk
1092
1093 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1094 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1095 zle -N insert-datestamp
1096
1097 # press esc-m for inserting last typed word again (thanks to caphuso!)
1098 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1099 zle -N insert-last-typed-word;
1100
1101 function grml-zsh-fg() {
1102   if (( ${#jobstates} )); then
1103     zle .push-input
1104     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1105     BUFFER="${BUFFER}fg"
1106     zle .accept-line
1107   else
1108     zle -M 'No background jobs. Doing nothing.'
1109   fi
1110 }
1111 zle -N grml-zsh-fg
1112
1113 # run command line as user root via sudo:
1114 sudo-command-line() {
1115     [[ -z $BUFFER ]] && zle up-history
1116     if [[ $BUFFER != sudo\ * ]]; then
1117         BUFFER="sudo $BUFFER"
1118         CURSOR=$(( CURSOR+5 ))
1119     fi
1120 }
1121 zle -N sudo-command-line
1122
1123 ### jump behind the first word on the cmdline.
1124 ### useful to add options.
1125 function jump_after_first_word() {
1126     local words
1127     words=(${(z)BUFFER})
1128
1129     if (( ${#words} <= 1 )) ; then
1130         CURSOR=${#BUFFER}
1131     else
1132         CURSOR=${#${words[1]}}
1133     fi
1134 }
1135 zle -N jump_after_first_word
1136
1137 #f5# Create directory under cursor or the selected area
1138 inplaceMkDirs() {
1139     # Press ctrl-xM to create the directory under the cursor or the selected area.
1140     # To select an area press ctrl-@ or ctrl-space and use the cursor.
1141     # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
1142     # directory does not exist yet -> press ctrl-XM and problem solved
1143     local PATHTOMKDIR
1144     if ((REGION_ACTIVE==1)); then
1145         local F=$MARK T=$CURSOR
1146         if [[ $F -gt $T ]]; then
1147             F=${CURSOR}
1148             T=${MARK}
1149         fi
1150         # get marked area from buffer and eliminate whitespace
1151         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
1152         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
1153     else
1154         local bufwords iword
1155         bufwords=(${(z)LBUFFER})
1156         iword=${#bufwords}
1157         bufwords=(${(z)BUFFER})
1158         PATHTOMKDIR="${(Q)bufwords[iword]}"
1159     fi
1160     [[ -z "${PATHTOMKDIR}" ]] && return 1
1161     PATHTOMKDIR=${~PATHTOMKDIR}
1162     if [[ -e "${PATHTOMKDIR}" ]]; then
1163         zle -M " path already exists, doing nothing"
1164     else
1165         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
1166         zle end-of-line
1167     fi
1168 }
1169
1170 zle -N inplaceMkDirs
1171
1172 #v1# set number of lines to display per page
1173 HELP_LINES_PER_PAGE=20
1174 #v1# set location of help-zle cache file
1175 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
1176 # helper function for help-zle, actually generates the help text
1177 help_zle_parse_keybindings()
1178 {
1179     emulate -L zsh
1180     setopt extendedglob
1181     unsetopt ksharrays  #indexing starts at 1
1182
1183     #v1# choose files that help-zle will parse for keybindings
1184     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
1185
1186     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
1187         local load_cache=0
1188         local f
1189         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
1190         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
1191     fi
1192
1193     #fill with default keybindings, possibly to be overwriten in a file later
1194     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
1195     local -A help_zle_keybindings
1196     help_zle_keybindings['<Ctrl>@']="set MARK"
1197     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
1198     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
1199     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
1200     help_zle_keybindings['<Ctrl>_']="undo"
1201     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
1202     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
1203     help_zle_keybindings['<Ctrl>e']="goto end of line"
1204     help_zle_keybindings['<Ctrl>t']="transpose charaters"
1205     help_zle_keybindings['<Alt>t']="transpose words"
1206     help_zle_keybindings['<Alt>s']="spellcheck word"
1207     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
1208     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
1209     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
1210     help_zle_keybindings["<Alt>'"]="quote line"
1211     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
1212     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
1213     help_zle_keybindings['<Alt>u']="make next word Uppercase"
1214     help_zle_keybindings['<Alt>l']="make next word lowercase"
1215     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
1216     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
1217     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
1218     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
1219     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
1220     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
1221     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
1222     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
1223     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
1224
1225     #init global variables
1226     unset help_zle_lines help_zle_sln
1227     typeset -g -a help_zle_lines
1228     typeset -g help_zle_sln=1
1229
1230     local k v f cline
1231     local lastkeybind_desc contents     #last description starting with #k# that we found
1232     local num_lines_elapsed=0            #number of lines between last description and keybinding
1233     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
1234     for f in $HELPZLE_KEYBINDING_FILES; do
1235         [[ -r "$f" ]] || continue   #not readable ? skip it
1236         contents="$(<$f)"
1237         for cline in "${(f)contents}"; do
1238             #zsh pattern: matches lines like: #k# ..............
1239             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
1240                 lastkeybind_desc="$match[*]"
1241                 num_lines_elapsed=0
1242             #zsh pattern: matches lines that set a keybinding using bind2map, bindkey or compdef -k
1243             #             ignores lines that are commentend out
1244             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
1245             elif [[ "$cline" == [^#]#(bind2maps[[:space:]](*)-s|bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
1246                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
1247                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
1248                     #substitute keybinding string with something readable
1249                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
1250                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
1251                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
1252                     help_zle_keybindings[${k}]=$lastkeybind_desc
1253                 fi
1254                 lastkeybind_desc=""
1255             else
1256               ((num_lines_elapsed++))
1257             fi
1258         done
1259     done
1260     unset contents
1261     #calculate length of keybinding column
1262     local kstrlen=0
1263     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
1264     #convert the assoc array into preformated lines, which we are able to sort
1265     for k v in ${(kv)help_zle_keybindings[@]}; do
1266         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
1267         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
1268     done
1269     #sort lines alphabetically
1270     help_zle_lines=("${(i)help_zle_lines[@]}")
1271     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
1272     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
1273     zcompile $HELP_ZLE_CACHE_FILE
1274 }
1275 typeset -g help_zle_sln
1276 typeset -g -a help_zle_lines
1277
1278 # Provides (partially autogenerated) help on keybindings and the zsh line editor
1279 help-zle()
1280 {
1281     emulate -L zsh
1282     unsetopt ksharrays  #indexing starts at 1
1283     #help lines already generated ? no ? then do it
1284     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
1285     #already displayed all lines ? go back to the start
1286     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
1287     local sln=$help_zle_sln
1288     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
1289     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
1290     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
1291 }
1292 zle -N help-zle
1293
1294 ## complete word from currently visible Screen or Tmux buffer.
1295 if check_com -c screen || check_com -c tmux; then
1296     _complete_screen_display() {
1297         [[ "$TERM" != "screen" ]] && return 1
1298
1299         local TMPFILE=$(mktemp)
1300         local -U -a _screen_display_wordlist
1301         trap "rm -f $TMPFILE" EXIT
1302
1303         # fill array with contents from screen hardcopy
1304         if ((${+TMUX})); then
1305             #works, but crashes tmux below version 1.4
1306             #luckily tmux -V option to ask for version, was also added in 1.4
1307             tmux -V &>/dev/null || return
1308             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1309         else
1310             screen -X hardcopy $TMPFILE
1311             # screen sucks, it dumps in latin1, apparently always. so recode it
1312             # to system charset
1313             check_com recode && recode latin1 $TMPFILE
1314         fi
1315         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1316         # remove PREFIX to be completed from that array
1317         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1318         compadd -a _screen_display_wordlist
1319     }
1320     #m# k CTRL-x\,\,\,S Complete word from GNU screen buffer
1321     bindkey -r "^xS"
1322     compdef -k _complete_screen_display complete-word '^xS'
1323 fi
1324
1325 # Load a few more functions and tie them to widgets, so they can be bound:
1326
1327 function zrcautozle() {
1328     emulate -L zsh
1329     local fnc=$1
1330     zrcautoload $fnc && zle -N $fnc
1331 }
1332
1333 function zrcgotwidget() {
1334     (( ${+widgets[$1]} ))
1335 }
1336
1337 function zrcgotkeymap() {
1338     [[ -n ${(M)keymaps:#$1} ]]
1339 }
1340
1341 zrcautozle insert-files
1342 zrcautozle edit-command-line
1343 zrcautozle insert-unicode-char
1344 if zrcautoload history-search-end; then
1345     zle -N history-beginning-search-backward-end history-search-end
1346     zle -N history-beginning-search-forward-end  history-search-end
1347 fi
1348 zle -C hist-complete complete-word _generic
1349 zstyle ':completion:hist-complete:*' completer _history
1350
1351 # The actual terminal setup hooks and bindkey-calls:
1352
1353 # An array to note missing features to ease diagnosis in case of problems.
1354 typeset -ga grml_missing_features
1355
1356 function zrcbindkey() {
1357     if (( ARGC )) && zrcgotwidget ${argv[-1]}; then
1358         bindkey "$@"
1359     fi
1360 }
1361
1362 function bind2maps () {
1363     local i sequence widget
1364     local -a maps
1365
1366     while [[ "$1" != "--" ]]; do
1367         maps+=( "$1" )
1368         shift
1369     done
1370     shift
1371
1372     if [[ "$1" == "-s" ]]; then
1373         shift
1374         sequence="$1"
1375     else
1376         sequence="${key[$1]}"
1377     fi
1378     widget="$2"
1379
1380     [[ -z "$sequence" ]] && return 1
1381
1382     for i in "${maps[@]}"; do
1383         zrcbindkey -M "$i" "$sequence" "$widget"
1384     done
1385 }
1386
1387 if (( ${+terminfo[smkx]} )) && (( ${+terminfo[rmkx]} )); then
1388     function zle-smkx () {
1389         emulate -L zsh
1390         printf '%s' ${terminfo[smkx]}
1391     }
1392     function zle-rmkx () {
1393         emulate -L zsh
1394         printf '%s' ${terminfo[rmkx]}
1395     }
1396     function zle-line-init () {
1397         zle-smkx
1398     }
1399     function zle-line-finish () {
1400         zle-rmkx
1401     }
1402     zle -N zle-line-init
1403     zle -N zle-line-finish
1404 else
1405     for i in {s,r}mkx; do
1406         (( ${+terminfo[$i]} )) || grml_missing_features+=($i)
1407     done
1408     unset i
1409 fi
1410
1411 typeset -A key
1412 key=(
1413     Home     "${terminfo[khome]}"
1414     End      "${terminfo[kend]}"
1415     Insert   "${terminfo[kich1]}"
1416     Delete   "${terminfo[kdch1]}"
1417     Up       "${terminfo[kcuu1]}"
1418     Down     "${terminfo[kcud1]}"
1419     Left     "${terminfo[kcub1]}"
1420     Right    "${terminfo[kcuf1]}"
1421     PageUp   "${terminfo[kpp]}"
1422     PageDown "${terminfo[knp]}"
1423     BackTab  "${terminfo[kcbt]}"
1424 )
1425
1426 # Guidelines for adding key bindings:
1427 #
1428 #   - Do not add hardcoded escape sequences, to enable non standard key
1429 #     combinations such as Ctrl-Meta-Left-Cursor. They are not easily portable.
1430 #
1431 #   - Adding Ctrl characters, such as '^b' is okay; note that '^b' and '^B' are
1432 #     the same key.
1433 #
1434 #   - All keys from the $key[] mapping are obviously okay.
1435 #
1436 #   - Most terminals send "ESC x" when Meta-x is pressed. Thus, sequences like
1437 #     '\ex' are allowed in here as well.
1438
1439 bind2maps emacs             -- Home   beginning-of-somewhere
1440 bind2maps       viins vicmd -- Home   vi-beginning-of-line
1441 bind2maps emacs             -- End    end-of-somewhere
1442 bind2maps       viins vicmd -- End    vi-end-of-line
1443 bind2maps emacs viins       -- Insert overwrite-mode
1444 bind2maps             vicmd -- Insert vi-insert
1445 bind2maps emacs             -- Delete delete-char
1446 bind2maps       viins vicmd -- Delete vi-delete-char
1447 bind2maps emacs viins vicmd -- Up     up-line-or-search
1448 bind2maps emacs viins vicmd -- Down   down-line-or-search
1449 bind2maps emacs             -- Left   backward-char
1450 bind2maps       viins vicmd -- Left   vi-backward-char
1451 bind2maps emacs             -- Right  forward-char
1452 bind2maps       viins vicmd -- Right  vi-forward-char
1453 #k# Perform abbreviation expansion
1454 bind2maps emacs viins       -- -s '^x.' zleiab
1455 #k# Display list of abbreviations that would expand
1456 bind2maps emacs viins       -- -s '^xb' help-show-abk
1457 #k# mkdir -p <dir> from string under cursor or marked area
1458 bind2maps emacs viins       -- -s '^xM' inplaceMkDirs
1459 #k# display help for keybindings and ZLE
1460 bind2maps emacs viins       -- -s '^xz' help-zle
1461 #k# Insert files and test globbing
1462 bind2maps emacs viins       -- -s "^xf" insert-files
1463 #k# Edit the current line in \kbd{\$EDITOR}
1464 bind2maps emacs viins       -- -s '\ee' edit-command-line
1465 #k# search history backward for entry beginning with typed text
1466 bind2maps emacs viins       -- -s '^xp' history-beginning-search-backward-end
1467 #k# search history forward for entry beginning with typed text
1468 bind2maps emacs viins       -- -s '^xP' history-beginning-search-forward-end
1469 #k# search history backward for entry beginning with typed text
1470 bind2maps emacs viins       -- PageUp history-beginning-search-backward-end
1471 #k# search history forward for entry beginning with typed text
1472 bind2maps emacs viins       -- PageDown history-beginning-search-forward-end
1473 bind2maps emacs viins       -- -s "^x^h" commit-to-history
1474 #k# Kill left-side word or everything up to next slash
1475 bind2maps emacs viins       -- -s '\ev' slash-backward-kill-word
1476 #k# Kill left-side word or everything up to next slash
1477 bind2maps emacs viins       -- -s '\e^h' slash-backward-kill-word
1478 #k# Kill left-side word or everything up to next slash
1479 bind2maps emacs viins       -- -s '\e^?' slash-backward-kill-word
1480 # Do history expansion on space:
1481 bind2maps emacs viins       -- -s ' ' magic-space
1482 #k# Trigger menu-complete
1483 bind2maps emacs viins       -- -s '\ei' menu-complete  # menu completion via esc-i
1484 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1485 bind2maps emacs viins       -- -s '^ed' insert-datestamp
1486 #k# Insert last typed word
1487 bind2maps emacs viins       -- -s "\em" insert-last-typed-word
1488 #k# A smart shortcut for \kbd{fg<enter>}
1489 bind2maps emacs viins       -- -s '^z' grml-zsh-fg
1490 #k# prepend the current command with "sudo"
1491 bind2maps emacs viins       -- -s "^os" sudo-command-line
1492 #k# jump to after first word (for adding options)
1493 bind2maps emacs viins       -- -s '^x1' jump_after_first_word
1494 #k# complete word from history with menu
1495 bind2maps emacs viins       -- -s "^x^x" hist-complete
1496
1497 # insert unicode character
1498 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
1499 # See for example http://unicode.org/charts/ for unicode characters code
1500 #k# Insert Unicode character
1501 bind2maps emacs viins       -- -s '^xi' insert-unicode-char
1502
1503 # use the new *-pattern-* widgets for incremental history search
1504 if zrcgotwidget history-incremental-pattern-search-backward; then
1505     for seq wid in '^r' history-incremental-pattern-search-backward \
1506                    '^s' history-incremental-pattern-search-forward
1507     do
1508         bind2maps emacs viins vicmd -- -s $seq $wid
1509     done
1510     builtin unset -v seq wid
1511 fi
1512
1513 if zrcgotkeymap menuselect; then
1514     #m# k Shift-tab Perform backwards menu completion
1515     bind2maps menuselect -- BackTab reverse-menu-complete
1516
1517     #k# menu selection: pick item but stay in the menu
1518     bind2maps menuselect -- -s '\e^M' accept-and-menu-complete
1519     # also use + and INSERT since it's easier to press repeatedly
1520     bind2maps menuselect -- -s '+' accept-and-menu-complete
1521     bind2maps menuselect -- Insert accept-and-menu-complete
1522
1523     # accept a completion and try to complete again by using menu
1524     # completion; very useful with completing directories
1525     # by using 'undo' one's got a simple file browser
1526     bind2maps menuselect -- -s '^o' accept-and-infer-next-history
1527 fi
1528
1529 # Finally, here are still a few hardcoded escape sequences; Special sequences
1530 # like Ctrl-<Cursor-key> etc do suck a fair bit, because they are not
1531 # standardised and most of the time are not available in a terminals terminfo
1532 # entry.
1533 #
1534 # While we do not encourage adding bindings like these, we will keep these for
1535 # backward compatibility.
1536
1537 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on
1538 ## the command line.
1539 # URxvt sequences:
1540 bind2maps emacs viins vicmd -- -s '\eOc' forward-word
1541 bind2maps emacs viins vicmd -- -s '\eOd' backward-word
1542 # These are for xterm:
1543 bind2maps emacs viins vicmd -- -s '\e[1;5C' forward-word
1544 bind2maps emacs viins vicmd -- -s '\e[1;5D' backward-word
1545 ## the same for alt-left-arrow and alt-right-arrow
1546 # URxvt again:
1547 bind2maps emacs viins vicmd -- -s '\e\e[C' forward-word
1548 bind2maps emacs viins vicmd -- -s '\e\e[D' backward-word
1549 # Xterm again:
1550 bind2maps emacs viins vicmd -- -s '^[[1;3C' forward-word
1551 bind2maps emacs viins vicmd -- -s '^[[1;3D' backward-word
1552 # Also try ESC Left/Right:
1553 bind2maps emacs viins vicmd -- -s '\e'${key[Right]} forward-word
1554 bind2maps emacs viins vicmd -- -s '\e'${key[Left]}  backward-word
1555
1556 # autoloading
1557
1558 zrcautoload zmv
1559 zrcautoload zed
1560
1561 # we don't want to quote/espace URLs on our own...
1562 # if autoload -U url-quote-magic ; then
1563 #    zle -N self-insert url-quote-magic
1564 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
1565 # else
1566 #    print 'Notice: no url-quote-magic available :('
1567 # fi
1568 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
1569
1570 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
1571 alias run-help >&/dev/null && unalias run-help
1572 for rh in run-help{,-git,-svk,-svn}; do
1573     zrcautoload $rh
1574 done; unset rh
1575
1576 # command not found handling
1577
1578 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1579 function command_not_found_handler() {
1580     emulate -L zsh
1581     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1582         ${GRML_ZSH_CNF_HANDLER} $1
1583     fi
1584     return 1
1585 }
1586
1587 # history
1588
1589 #v#
1590 HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1591 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1592 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1593
1594 # dirstack handling
1595
1596 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1597 DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1598
1599 if zstyle -T ':grml:chpwd:dirstack' enable; then
1600     typeset -gaU GRML_PERSISTENT_DIRSTACK
1601     function grml_dirstack_filter() {
1602         local -a exclude
1603         local filter entry
1604         if zstyle -s ':grml:chpwd:dirstack' filter filter; then
1605             $filter $1 && return 0
1606         fi
1607         if zstyle -a ':grml:chpwd:dirstack' exclude exclude; then
1608             for entry in "${exclude[@]}"; do
1609                 [[ $1 == ${~entry} ]] && return 0
1610             done
1611         fi
1612         return 1
1613     }
1614
1615     chpwd() {
1616         (( ZSH_SUBSHELL )) && return
1617         (( $DIRSTACKSIZE <= 0 )) && return
1618         [[ -z $DIRSTACKFILE ]] && return
1619         grml_dirstack_filter $PWD && return
1620         GRML_PERSISTENT_DIRSTACK=(
1621             $PWD "${(@)GRML_PERSISTENT_DIRSTACK[1,$DIRSTACKSIZE]}"
1622         )
1623         builtin print -l ${GRML_PERSISTENT_DIRSTACK} >! ${DIRSTACKFILE}
1624     }
1625
1626     if [[ -f ${DIRSTACKFILE} ]]; then
1627         # Enabling NULL_GLOB via (N) weeds out any non-existing
1628         # directories from the saved dir-stack file.
1629         dirstack=( ${(f)"$(< $DIRSTACKFILE)"}(N) )
1630         # "cd -" won't work after login by just setting $OLDPWD, so
1631         [[ -d $dirstack[1] ]] && cd -q $dirstack[1] && cd -q $OLDPWD
1632     fi
1633
1634     if zstyle -t ':grml:chpwd:dirstack' filter-on-load; then
1635         for i in "${dirstack[@]}"; do
1636             if ! grml_dirstack_filter "$i"; then
1637                 GRML_PERSISTENT_DIRSTACK=(
1638                     "${GRML_PERSISTENT_DIRSTACK[@]}"
1639                     $i
1640                 )
1641             fi
1642         done
1643     else
1644         GRML_PERSISTENT_DIRSTACK=( "${dirstack[@]}" )
1645     fi
1646 fi
1647
1648 # directory based profiles
1649
1650 if is433 ; then
1651
1652 # chpwd_profiles(): Directory Profiles, Quickstart:
1653 #
1654 # In .zshrc.local:
1655 #
1656 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1657 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1658 #   chpwd_profiles
1659 #
1660 # For details see the `grmlzshrc.5' manual page.
1661 function chpwd_profiles() {
1662     local profile context
1663     local -i reexecute
1664
1665     context=":chpwd:profiles:$PWD"
1666     zstyle -s "$context" profile profile || profile='default'
1667     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1668
1669     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1670         typeset -g CHPWD_PROFILE
1671         local CHPWD_PROFILES_INIT=1
1672         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1673     elif [[ $profile != $CHPWD_PROFILE ]]; then
1674         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1675             && chpwd_leave_profile_${CHPWD_PROFILE}
1676     fi
1677     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1678         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1679     fi
1680
1681     CHPWD_PROFILE="${profile}"
1682     return 0
1683 }
1684
1685 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1686
1687 fi # is433
1688
1689 # Prompt setup for grml:
1690
1691 # set colors for use in prompts (modern zshs allow for the use of %F{red}foo%f
1692 # in prompts to get a red "foo" embedded, but it's good to keep these for
1693 # backwards compatibility).
1694 if is437; then
1695     BLUE="%F{blue}"
1696     RED="%F{red}"
1697     GREEN="%F{green}"
1698     CYAN="%F{cyan}"
1699     MAGENTA="%F{magenta}"
1700     YELLOW="%F{yellow}"
1701     WHITE="%F{white}"
1702     NO_COLOR="%f"
1703 elif zrcautoload colors && colors 2>/dev/null ; then
1704     BLUE="%{${fg[blue]}%}"
1705     RED="%{${fg_bold[red]}%}"
1706     GREEN="%{${fg[green]}%}"
1707     CYAN="%{${fg[cyan]}%}"
1708     MAGENTA="%{${fg[magenta]}%}"
1709     YELLOW="%{${fg[yellow]}%}"
1710     WHITE="%{${fg[white]}%}"
1711     NO_COLOR="%{${reset_color}%}"
1712 else
1713     BLUE=$'%{\e[1;34m%}'
1714     RED=$'%{\e[1;31m%}'
1715     GREEN=$'%{\e[1;32m%}'
1716     CYAN=$'%{\e[1;36m%}'
1717     WHITE=$'%{\e[1;37m%}'
1718     MAGENTA=$'%{\e[1;35m%}'
1719     YELLOW=$'%{\e[1;33m%}'
1720     NO_COLOR=$'%{\e[0m%}'
1721 fi
1722
1723 # First, the easy ones: PS2..4:
1724
1725 # secondary prompt, printed when the shell needs more information to complete a
1726 # command.
1727 PS2='\`%_> '
1728 # selection prompt used within a select loop.
1729 PS3='?# '
1730 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1731 PS4='+%N:%i:%_> '
1732
1733 # Some additional features to use with our prompt:
1734 #
1735 #    - battery status
1736 #    - debian_chroot
1737 #    - vcs_info setup and version specific fixes
1738
1739 # display battery status on right side of prompt using 'GRML_DISPLAY_BATTERY=1' in .zshrc.pre
1740
1741 battery() {
1742 if [[ $GRML_DISPLAY_BATTERY -gt 0 ]] ; then
1743     if islinux ; then
1744         batterylinux
1745     elif isopenbsd ; then
1746         batteryopenbsd
1747     elif isfreebsd ; then
1748         batteryfreebsd
1749     elif isdarwin ; then
1750         batterydarwin
1751     else
1752         #not yet supported
1753         GRML_DISPLAY_BATTERY=0
1754     fi
1755 fi
1756 }
1757
1758 batterylinux(){
1759 GRML_BATTERY_LEVEL=''
1760 local batteries bat capacity
1761 batteries=( /sys/class/power_supply/BAT*(N) )
1762 if (( $#batteries > 0 )) ; then
1763     for bat in $batteries ; do
1764         capacity=$(< $bat/capacity)
1765         case $(< $bat/status) in
1766         Charging)
1767             GRML_BATTERY_LEVEL+=" ^"
1768             ;;
1769         Discharging)
1770             if (( capacity < 20 )) ; then
1771                 GRML_BATTERY_LEVEL+=" !v"
1772             else
1773                 GRML_BATTERY_LEVEL+=" v"
1774             fi
1775             ;;
1776         *) # Full, Unknown
1777             GRML_BATTERY_LEVEL+=" ="
1778             ;;
1779         esac
1780         GRML_BATTERY_LEVEL+="${capacity}%%"
1781     done
1782 fi
1783 }
1784
1785 batteryopenbsd(){
1786 GRML_BATTERY_LEVEL=''
1787 local bat batfull batwarn batnow num
1788 for num in 0 1 ; do
1789     bat=$(sysctl -n hw.sensors.acpibat${num} 2>/dev/null)
1790     if [[ -n $bat ]]; then
1791         batfull=${"$(sysctl -n hw.sensors.acpibat${num}.amphour0)"%% *}
1792         batwarn=${"$(sysctl -n hw.sensors.acpibat${num}.amphour1)"%% *}
1793         batnow=${"$(sysctl -n hw.sensors.acpibat${num}.amphour3)"%% *}
1794         case "$(sysctl -n hw.sensors.acpibat${num}.raw0)" in
1795             *" discharging"*)
1796                 if (( batnow < batwarn )) ; then
1797                     GRML_BATTERY_LEVEL+=" !v"
1798                 else
1799                     GRML_BATTERY_LEVEL+=" v"
1800                 fi
1801                 ;;
1802             *" charging"*)
1803                 GRML_BATTERY_LEVEL+=" ^"
1804                 ;;
1805             *)
1806                 GRML_BATTERY_LEVEL+=" ="
1807                 ;;
1808         esac
1809         GRML_BATTERY_LEVEL+="${$(( 100 * batnow / batfull ))%%.*}%%"
1810     fi
1811 done
1812 }
1813
1814 batteryfreebsd(){
1815 GRML_BATTERY_LEVEL=''
1816 local num
1817 local -A table
1818 for num in 0 1 ; do
1819     table=( ${=${${${${${(M)${(f)"$(acpiconf -i $num 2>&1)"}:#(State|Remaining capacity):*}%%( ##|%)}//:[ $'\t']##/@}// /-}//@/ }} )
1820     if [[ -n $table ]] && [[ $table[State] != "not-present" ]] ; then
1821         case $table[State] in
1822             *discharging*)
1823                 if (( $table[Remaining-capacity] < 20 )) ; then
1824                     GRML_BATTERY_LEVEL+=" !v"
1825                 else
1826                     GRML_BATTERY_LEVEL+=" v"
1827                 fi
1828                 ;;
1829             *charging*)
1830                 GRML_BATTERY_LEVEL+=" ^"
1831                 ;;
1832             *)
1833                 GRML_BATTERY_LEVEL+=" ="
1834                 ;;
1835         esac
1836         GRML_BATTERY_LEVEL+="$table[Remaining-capacity]%%"
1837     fi
1838 done
1839 }
1840
1841 batterydarwin(){
1842 GRML_BATTERY_LEVEL=''
1843 local -a table
1844 table=( ${$(pmset -g ps)[(w)7,8]%%(\%|);} )
1845 if [[ -n $table[2] ]] ; then
1846     case $table[2] in
1847         charging)
1848             GRML_BATTERY_LEVEL+=" ^"
1849             ;;
1850         discharging)
1851             if (( $table[1] < 20 )) ; then
1852                 GRML_BATTERY_LEVEL+=" !v"
1853             else
1854                 GRML_BATTERY_LEVEL+=" v"
1855             fi
1856             ;;
1857         *)
1858             GRML_BATTERY_LEVEL+=" ="
1859             ;;
1860     esac
1861     GRML_BATTERY_LEVEL+="$table[1]%%"
1862 fi
1863 }
1864
1865 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1866 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1867     debian_chroot=$(</etc/debian_chroot)
1868 fi
1869
1870 # gather version control information for inclusion in a prompt
1871
1872 if zrcautoload vcs_info; then
1873     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1874     # function, which can cause a lot of trouble with our directory-based
1875     # profiles. So:
1876     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1877         function VCS_INFO_realpath () {
1878             setopt localoptions NO_shwordsplit chaselinks
1879             ( builtin cd -q $1 2> /dev/null && pwd; )
1880         }
1881     fi
1882
1883     zstyle ':vcs_info:*' max-exports 2
1884
1885     if [[ -o restricted ]]; then
1886         zstyle ':vcs_info:*' enable NONE
1887     fi
1888 fi
1889
1890 typeset -A grml_vcs_coloured_formats
1891 typeset -A grml_vcs_plain_formats
1892
1893 grml_vcs_plain_formats=(
1894     format "(%s%)-[%b] "    "zsh: %r"
1895     actionformat "(%s%)-[%b|%a] " "zsh: %r"
1896     rev-branchformat "%b:%r"
1897 )
1898
1899 grml_vcs_coloured_formats=(
1900     format "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR} "
1901     actionformat "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} "
1902     rev-branchformat "%b${RED}:${YELLOW}%r"
1903 )
1904
1905 typeset GRML_VCS_COLOUR_MODE=xxx
1906
1907 grml_vcs_info_toggle_colour () {
1908     emulate -L zsh
1909     if [[ $GRML_VCS_COLOUR_MODE == plain ]]; then
1910         grml_vcs_info_set_formats coloured
1911     else
1912         grml_vcs_info_set_formats plain
1913     fi
1914     return 0
1915 }
1916
1917 grml_vcs_info_set_formats () {
1918     emulate -L zsh
1919     #setopt localoptions xtrace
1920     local mode=$1 AF F BF
1921     if [[ $mode == coloured ]]; then
1922         AF=${grml_vcs_coloured_formats[actionformat]}
1923         F=${grml_vcs_coloured_formats[format]}
1924         BF=${grml_vcs_coloured_formats[rev-branchformat]}
1925         GRML_VCS_COLOUR_MODE=coloured
1926     else
1927         AF=${grml_vcs_plain_formats[actionformat]}
1928         F=${grml_vcs_plain_formats[format]}
1929         BF=${grml_vcs_plain_formats[rev-branchformat]}
1930         GRML_VCS_COLOUR_MODE=plain
1931     fi
1932
1933     zstyle ':vcs_info:*'              actionformats "$AF" "zsh: %r"
1934     zstyle ':vcs_info:*'              formats       "$F"  "zsh: %r"
1935     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat  "$BF"
1936     return 0
1937 }
1938
1939 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1940 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1941 if [[ "$TERM" == dumb ]] ; then
1942     grml_vcs_info_set_formats plain
1943 else
1944     grml_vcs_info_set_formats coloured
1945 fi
1946
1947 # Now for the fun part: The grml prompt themes in `promptsys' mode of operation
1948
1949 # This actually defines three prompts:
1950 #
1951 #    - grml
1952 #    - grml-large
1953 #    - grml-chroot
1954 #
1955 # They all share the same code and only differ with respect to which items they
1956 # contain. The main source of documentation is the `prompt_grml_help' function
1957 # below, which gets called when the user does this: prompt -h grml
1958
1959 function prompt_grml_help () {
1960     <<__EOF0__
1961   prompt grml
1962
1963     This is the prompt as used by the grml-live system <http://grml.org>. It is
1964     a rather simple one-line prompt, that by default looks something like this:
1965
1966         <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1967
1968     The prompt itself integrates with zsh's prompt themes system (as you are
1969     witnessing right now) and is configurable to a certain degree. In
1970     particular, these aspects are customisable:
1971
1972         - The items used in the prompt (e.g. you can remove \`user' from
1973           the list of activated items, which will cause the user name to
1974           be omitted from the prompt string).
1975
1976         - The attributes used with the items are customisable via strings
1977           used before and after the actual item.
1978
1979     The available items are: at, battery, change-root, date, grml-chroot,
1980     history, host, jobs, newline, path, percent, rc, rc-always, sad-smiley,
1981     shell-level, time, user, vcs
1982
1983     The actual configuration is done via zsh's \`zstyle' mechanism. The
1984     context, that is used while looking up styles is:
1985
1986         ':prompt:grml:<left-or-right>:<subcontext>'
1987
1988     Here <left-or-right> is either \`left' or \`right', signifying whether the
1989     style should affect the left or the right prompt. <subcontext> is either
1990     \`setup' or 'items:<item>', where \`<item>' is one of the available items.
1991
1992     The styles:
1993
1994         - use-rprompt (boolean): If \`true' (the default), print a sad smiley
1995           in $RPROMPT if the last command a returned non-successful error code.
1996           (This in only valid if <left-or-right> is "right"; ignored otherwise)
1997
1998         - items (list): The list of items used in the prompt. If \`vcs' is
1999           present in the list, the theme's code invokes \`vcs_info'
2000           accordingly. Default (left): rc change-root user at host path vcs
2001           percent; Default (right): sad-smiley
2002
2003     Available styles in 'items:<item>' are: pre, post. These are strings that
2004     are inserted before (pre) and after (post) the item in question. Thus, the
2005     following would cause the user name to be printed in red instead of the
2006     default blue:
2007
2008         zstyle ':prompt:grml:*:items:user' pre '%F{red}'
2009
2010     Note, that the \`post' style may remain at its default value, because its
2011     default value is '%f', which turns the foreground text attribute off (which
2012     is exactly, what is still required with the new \`pre' value).
2013 __EOF0__
2014 }
2015
2016 function prompt_grml-chroot_help () {
2017     <<__EOF0__
2018   prompt grml-chroot
2019
2020     This is a variation of the grml prompt, see: prompt -h grml
2021
2022     The main difference is the default value of the \`items' style. The rest
2023     behaves exactly the same. Here are the defaults for \`grml-chroot':
2024
2025         - left: grml-chroot user at host path percent
2026         - right: (empty list)
2027 __EOF0__
2028 }
2029
2030 function prompt_grml-large_help () {
2031     <<__EOF0__
2032   prompt grml-large
2033
2034     This is a variation of the grml prompt, see: prompt -h grml
2035
2036     The main difference is the default value of the \`items' style. In
2037     particular, this theme uses _two_ lines instead of one with the plain
2038     \`grml' theme. The rest behaves exactly the same. Here are the defaults
2039     for \`grml-large':
2040
2041         - left: rc jobs history shell-level change-root time date newline user
2042                 at host path vcs percent
2043         - right: sad-smiley
2044 __EOF0__
2045 }
2046
2047 function grml_prompt_setup () {
2048     emulate -L zsh
2049     autoload -Uz vcs_info
2050     # The following autoload is disabled for now, since this setup includes a
2051     # static version of the ‘add-zsh-hook’ function above. It needs to be
2052     # reenabled as soon as that static definition is removed again.
2053     #autoload -Uz add-zsh-hook
2054     add-zsh-hook precmd prompt_$1_precmd
2055 }
2056
2057 function prompt_grml_setup () {
2058     grml_prompt_setup grml
2059 }
2060
2061 function prompt_grml-chroot_setup () {
2062     grml_prompt_setup grml-chroot
2063 }
2064
2065 function prompt_grml-large_setup () {
2066     grml_prompt_setup grml-large
2067 }
2068
2069 # These maps define default tokens and pre-/post-decoration for items to be
2070 # used within the themes. All defaults may be customised in a context sensitive
2071 # matter by using zsh's `zstyle' mechanism.
2072 typeset -gA grml_prompt_pre_default \
2073             grml_prompt_post_default \
2074             grml_prompt_token_default \
2075             grml_prompt_token_function
2076
2077 grml_prompt_pre_default=(
2078     at                ''
2079     battery           ' '
2080     change-root       ''
2081     date              '%F{blue}'
2082     grml-chroot       '%F{red}'
2083     history           '%F{green}'
2084     host              ''
2085     jobs              '%F{cyan}'
2086     newline           ''
2087     path              '%B'
2088     percent           ''
2089     rc                '%B%F{red}'
2090     rc-always         ''
2091     sad-smiley        ''
2092     shell-level       '%F{red}'
2093     time              '%F{blue}'
2094     user              '%B%F{blue}'
2095     vcs               ''
2096 )
2097
2098 grml_prompt_post_default=(
2099     at                ''
2100     battery           ''
2101     change-root       ''
2102     date              '%f'
2103     grml-chroot       '%f '
2104     history           '%f'
2105     host              ''
2106     jobs              '%f'
2107     newline           ''
2108     path              '%b'
2109     percent           ''
2110     rc                '%f%b'
2111     rc-always         ''
2112     sad-smiley        ''
2113     shell-level       '%f'
2114     time              '%f'
2115     user              '%f%b'
2116     vcs               ''
2117 )
2118
2119 grml_prompt_token_default=(
2120     at                '@'
2121     battery           'GRML_BATTERY_LEVEL'
2122     change-root       'debian_chroot'
2123     date              '%D{%Y-%m-%d}'
2124     grml-chroot       'GRML_CHROOT'
2125     history           '{history#%!} '
2126     host              '%m '
2127     jobs              '[%j running job(s)] '
2128     newline           $'\n'
2129     path              '%40<..<%~%<< '
2130     percent           '%# '
2131     rc                '%(?..%? )'
2132     rc-always         '%?'
2133     sad-smiley        '%(?..:()'
2134     shell-level       '%(3L.+ .)'
2135     time              '%D{%H:%M:%S} '
2136     user              '%n'
2137     vcs               '0'
2138 )
2139
2140 function grml_theme_has_token () {
2141     if (( ARGC != 1 )); then
2142         printf 'usage: grml_theme_has_token <name>\n'
2143         return 1
2144     fi
2145     (( ${+grml_prompt_token_default[$1]} ))
2146 }
2147
2148 function GRML_theme_add_token_usage () {
2149     <<__EOF0__
2150   Usage: grml_theme_add_token <name> [-f|-i] <token/function> [<pre> <post>]
2151
2152     <name> is the name for the newly added token. If the \`-f' or \`-i' options
2153     are used, <token/function> is the name of the function (see below for
2154     details). Otherwise it is the literal token string to be used. <pre> and
2155     <post> are optional.
2156
2157   Options:
2158
2159     -f <function>   Use a function named \`<function>' each time the token
2160                     is to be expanded.
2161
2162     -i <function>   Use a function named \`<function>' to initialise the
2163                     value of the token _once_ at runtime.
2164
2165     The functions are called with one argument: the token's new name. The
2166     return value is expected in the \$REPLY parameter. The use of these
2167     options is mutually exclusive.
2168
2169     There is a utility function \`grml_theme_has_token', which you can use
2170     to test if a token exists before trying to add it. This can be a guard
2171     for situations in which a \`grml_theme_add_token' call may happen more
2172     than once.
2173
2174   Example:
2175
2176     To add a new token \`day' that expands to the current weekday in the
2177     current locale in green foreground colour, use this:
2178
2179       grml_theme_add_token day '%D{%A}' '%F{green}' '%f'
2180
2181     Another example would be support for \$VIRTUAL_ENV:
2182
2183       function virtual_env_prompt () {
2184         REPLY=\${VIRTUAL_ENV+\${VIRTUAL_ENV:t} }
2185       }
2186       grml_theme_add_token virtual-env -f virtual_env_prompt
2187
2188     After that, you will be able to use a changed \`items' style to
2189     assemble your prompt.
2190 __EOF0__
2191 }
2192
2193 function grml_theme_add_token () {
2194     emulate -L zsh
2195     local name token pre post
2196     local -i init funcall
2197
2198     if (( ARGC == 0 )); then
2199         GRML_theme_add_token_usage
2200         return 0
2201     fi
2202
2203     init=0
2204     funcall=0
2205     pre=''
2206     post=''
2207     name=$1
2208     shift
2209     if [[ $1 == '-f' ]]; then
2210         funcall=1
2211         shift
2212     elif [[ $1 == '-i' ]]; then
2213         init=1
2214         shift
2215     fi
2216
2217     if (( ARGC == 0 )); then
2218         printf '
2219 grml_theme_add_token: No token-string/function-name provided!\n\n'
2220         GRML_theme_add_token_usage
2221         return 1
2222     fi
2223     token=$1
2224     shift
2225     if (( ARGC != 0 && ARGC != 2 )); then
2226         printf '
2227 grml_theme_add_token: <pre> and <post> need to by specified _both_!\n\n'
2228         GRML_theme_add_token_usage
2229         return 1
2230     fi
2231     if (( ARGC )); then
2232         pre=$1
2233         post=$2
2234         shift 2
2235     fi
2236
2237     if grml_theme_has_token $name; then
2238         printf '
2239 grml_theme_add_token: Token `%s'\'' exists! Giving up!\n\n' $name
2240         GRML_theme_add_token_usage
2241         return 2
2242     fi
2243     if (( init )); then
2244         $token $name
2245         token=$REPLY
2246     fi
2247     grml_prompt_pre_default[$name]=$pre
2248     grml_prompt_post_default[$name]=$post
2249     if (( funcall )); then
2250         grml_prompt_token_function[$name]=$token
2251         grml_prompt_token_default[$name]=23
2252     else
2253         grml_prompt_token_default[$name]=$token
2254     fi
2255 }
2256
2257 function grml_typeset_and_wrap () {
2258     emulate -L zsh
2259     local target="$1"
2260     local new="$2"
2261     local left="$3"
2262     local right="$4"
2263
2264     if (( ${+parameters[$new]} )); then
2265         typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
2266     fi
2267 }
2268
2269 function grml_prompt_addto () {
2270     emulate -L zsh
2271     local target="$1"
2272     local lr it apre apost new v
2273     local -a items
2274     shift
2275
2276     [[ $target == PS1 ]] && lr=left || lr=right
2277     zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
2278     typeset -g "${target}="
2279     for it in "${items[@]}"; do
2280         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
2281             || apre=${grml_prompt_pre_default[$it]}
2282         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" post apost \
2283             || apost=${grml_prompt_post_default[$it]}
2284         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
2285             || new=${grml_prompt_token_default[$it]}
2286         typeset -g "${target}=${(P)target}${apre}"
2287         if (( ${+grml_prompt_token_function[$it]} )); then
2288             ${grml_prompt_token_function[$it]} $it
2289             typeset -g "${target}=${(P)target}${REPLY}"
2290         else
2291             case $it in
2292             battery)
2293                 grml_typeset_and_wrap $target $new '' ''
2294                 ;;
2295             change-root)
2296                 grml_typeset_and_wrap $target $new '(' ')'
2297                 ;;
2298             grml-chroot)
2299                 if [[ -n ${(P)new} ]]; then
2300                     typeset -g "${target}=${(P)target}(CHROOT)"
2301                 fi
2302                 ;;
2303             vcs)
2304                 v="vcs_info_msg_${new}_"
2305                 if (( ! vcscalled )); then
2306                     vcs_info
2307                     vcscalled=1
2308                 fi
2309                 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
2310                     typeset -g "${target}=${(P)target}${(P)v}"
2311                 fi
2312                 ;;
2313             *) typeset -g "${target}=${(P)target}${new}" ;;
2314             esac
2315         fi
2316         typeset -g "${target}=${(P)target}${apost}"
2317     done
2318 }
2319
2320 function prompt_grml_precmd () {
2321     emulate -L zsh
2322     local grmltheme=grml
2323     local -a left_items right_items
2324     left_items=(rc change-root user at host path vcs percent)
2325     right_items=(sad-smiley)
2326
2327     prompt_grml_precmd_worker
2328 }
2329
2330 function prompt_grml-chroot_precmd () {
2331     emulate -L zsh
2332     local grmltheme=grml-chroot
2333     local -a left_items right_items
2334     left_items=(grml-chroot user at host path percent)
2335     right_items=()
2336
2337     prompt_grml_precmd_worker
2338 }
2339
2340 function prompt_grml-large_precmd () {
2341     emulate -L zsh
2342     local grmltheme=grml-large
2343     local -a left_items right_items
2344     left_items=(rc jobs history shell-level change-root time date newline
2345                 user at host path vcs percent)
2346     right_items=(sad-smiley)
2347
2348     prompt_grml_precmd_worker
2349 }
2350
2351 function prompt_grml_precmd_worker () {
2352     emulate -L zsh
2353     local -i vcscalled=0
2354
2355     grml_prompt_addto PS1 "${left_items[@]}"
2356     if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
2357         grml_prompt_addto RPS1 "${right_items[@]}"
2358     fi
2359 }
2360
2361 grml_prompt_fallback() {
2362     setopt prompt_subst
2363     precmd() {
2364         (( ${+functions[vcs_info]} )) && vcs_info
2365     }
2366
2367     p0="${RED}%(?..%? )${WHITE}${debian_chroot:+($debian_chroot)}"
2368     p1="${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "'${vcs_info_msg_0_}'"%# "
2369     if (( EUID == 0 )); then
2370         PROMPT="${BLUE}${p0}${RED}${p1}"
2371     else
2372         PROMPT="${RED}${p0}${BLUE}${p1}"
2373     fi
2374     unset p0 p1
2375 }
2376
2377 if zrcautoload promptinit && promptinit 2>/dev/null ; then
2378     # Since we define the required functions in here and not in files in
2379     # $fpath, we need to stick the theme's name into `$prompt_themes'
2380     # ourselves, since promptinit does not pick them up otherwise.
2381     prompt_themes+=( grml grml-chroot grml-large )
2382     # Also, keep the array sorted...
2383     prompt_themes=( "${(@on)prompt_themes}" )
2384 else
2385     print 'Notice: no promptinit available :('
2386     grml_prompt_fallback
2387 fi
2388
2389 if is437; then
2390     # The prompt themes use modern features of zsh, that require at least
2391     # version 4.3.7 of the shell. Use the fallback otherwise.
2392     if [[ $GRML_DISPLAY_BATTERY -gt 0 ]]; then
2393         zstyle ':prompt:grml:right:setup' items sad-smiley battery
2394         add-zsh-hook precmd battery
2395     fi
2396     if [[ "$TERM" == dumb ]] ; then
2397         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" pre ''
2398         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" post ' '
2399         for i in rc user path jobs history date time shell-level; do
2400             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" pre ''
2401             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" post ''
2402         done
2403         unset i
2404         zstyle ':prompt:grml(|-large|-chroot):right:setup' use-rprompt false
2405     elif (( EUID == 0 )); then
2406         zstyle ':prompt:grml(|-large|-chroot):*:items:user' pre '%B%F{red}'
2407     fi
2408
2409     # Finally enable one of the prompts.
2410     if [[ -n $GRML_CHROOT ]]; then
2411         prompt grml-chroot
2412     elif [[ $GRMLPROMPT -gt 0 ]]; then
2413         prompt grml-large
2414     else
2415         prompt grml
2416     fi
2417 else
2418     grml_prompt_fallback
2419 fi
2420
2421 # Terminal-title wizardry
2422
2423 function ESC_print () {
2424     info_print $'\ek' $'\e\\' "$@"
2425 }
2426 function set_title () {
2427     info_print  $'\e]0;' $'\a' "$@"
2428 }
2429
2430 function info_print () {
2431     local esc_begin esc_end
2432     esc_begin="$1"
2433     esc_end="$2"
2434     shift 2
2435     printf '%s' ${esc_begin}
2436     printf '%s' "$*"
2437     printf '%s' "${esc_end}"
2438 }
2439
2440 function grml_reset_screen_title () {
2441     # adjust title of xterm
2442     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
2443     [[ ${NOTITLE:-} -gt 0 ]] && return 0
2444     case $TERM in
2445         (xterm*|rxvt*)
2446             set_title ${(%):-"%n@%m: %~"}
2447             ;;
2448     esac
2449 }
2450
2451 function grml_vcs_to_screen_title () {
2452     if [[ $TERM == screen* ]] ; then
2453         if [[ -n ${vcs_info_msg_1_} ]] ; then
2454             ESC_print ${vcs_info_msg_1_}
2455         else
2456             ESC_print "zsh"
2457         fi
2458     fi
2459 }
2460
2461 function grml_maintain_name () {
2462     # set hostname if not running on host with name 'grml'
2463     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
2464        NAME="@$HOSTNAME"
2465     fi
2466 }
2467
2468 function grml_cmd_to_screen_title () {
2469     # get the name of the program currently running and hostname of local
2470     # machine set screen window title if running in a screen
2471     if [[ "$TERM" == screen* ]] ; then
2472         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME"
2473         ESC_print ${CMD}
2474     fi
2475 }
2476
2477 function grml_control_xterm_title () {
2478     case $TERM in
2479         (xterm*|rxvt*)
2480             set_title "${(%):-"%n@%m:"}" "$1"
2481             ;;
2482     esac
2483 }
2484
2485 # The following autoload is disabled for now, since this setup includes a
2486 # static version of the ‘add-zsh-hook’ function above. It needs to be
2487 # reenabled as soon as that static definition is removed again.
2488 #zrcautoload add-zsh-hook || add-zsh-hook () { :; }
2489 if [[ $NOPRECMD -eq 0 ]]; then
2490     add-zsh-hook precmd grml_reset_screen_title
2491     add-zsh-hook precmd grml_vcs_to_screen_title
2492     add-zsh-hook preexec grml_maintain_name
2493     add-zsh-hook preexec grml_cmd_to_screen_title
2494     if [[ $NOTITLE -eq 0 ]]; then
2495         add-zsh-hook preexec grml_control_xterm_title
2496     fi
2497 fi
2498
2499 # 'hash' some often used directories
2500 #d# start
2501 hash -d deb=/var/cache/apt/archives
2502 hash -d doc=/usr/share/doc
2503 hash -d linux=/lib/modules/$(command uname -r)/build/
2504 hash -d log=/var/log
2505 hash -d slog=/var/log/syslog
2506 hash -d src=/usr/src
2507 hash -d www=/var/www
2508 #d# end
2509
2510 # some aliases
2511 if check_com -c screen ; then
2512     if [[ $UID -eq 0 ]] ; then
2513         if [[ -r /etc/grml/screenrc ]]; then
2514             alias screen='screen -c /etc/grml/screenrc'
2515         fi
2516     elif [[ ! -r $HOME/.screenrc ]] ; then
2517         if [[ -r /etc/grml/screenrc_grml ]]; then
2518             alias screen='screen -c /etc/grml/screenrc_grml'
2519         else
2520             if [[ -r /etc/grml/screenrc ]]; then
2521                 alias screen='screen -c /etc/grml/screenrc'
2522             fi
2523         fi
2524     fi
2525 fi
2526
2527 # do we have GNU ls with color-support?
2528 if [[ "$TERM" != dumb ]]; then
2529     #a1# List files with colors (\kbd{ls \ldots})
2530     alias ls="command ls ${ls_options:+${ls_options[*]}}"
2531     #a1# List all files, with colors (\kbd{ls -la \ldots})
2532     alias la="command ls -la ${ls_options:+${ls_options[*]}}"
2533     #a1# List files with long colored list, without dotfiles (\kbd{ls -l \ldots})
2534     alias ll="command ls -l ${ls_options:+${ls_options[*]}}"
2535     #a1# List files with long colored list, human readable sizes (\kbd{ls -hAl \ldots})
2536     alias lh="command ls -hAl ${ls_options:+${ls_options[*]}}"
2537     #a1# List files with long colored list, append qualifier to filenames (\kbd{ls -l \ldots})\\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2538     alias l="command ls -l ${ls_options:+${ls_options[*]}}"
2539 else
2540     alias la='command ls -la'
2541     alias ll='command ls -l'
2542     alias lh='command ls -hAl'
2543     alias l='command ls -l'
2544 fi
2545
2546 alias mdstat='cat /proc/mdstat'
2547 alias ...='cd ../../'
2548
2549 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2550 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2551     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2552 fi
2553
2554 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2555 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2556 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2557
2558 # make sure it is not assigned yet
2559 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
2560 utf2iso() {
2561     if isutfenv ; then
2562         local ENV
2563         for ENV in $(env | command grep -i '.utf') ; do
2564             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2565         done
2566     fi
2567 }
2568
2569 # make sure it is not assigned yet
2570 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
2571 iso2utf() {
2572     if ! isutfenv ; then
2573         local ENV
2574         for ENV in $(env | command grep -i '\.iso') ; do
2575             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2576         done
2577     fi
2578 }
2579
2580 # especially for roadwarriors using GNU screen and ssh:
2581 if ! check_com asc &>/dev/null ; then
2582   asc() { autossh -t "$@" 'screen -RdU' }
2583   compdef asc=ssh
2584 fi
2585
2586 #f1# Hints for the use of zsh on grml
2587 zsh-help() {
2588     print "$bg[white]$fg[black]
2589 zsh-help - hints for use of zsh on grml
2590 =======================================$reset_color"
2591
2592     print '
2593 Main configuration of zsh happens in /etc/zsh/zshrc.
2594 That file is part of the package grml-etc-core, if you want to
2595 use them on a non-grml-system just get the tar.gz from
2596 http://deb.grml.org/ or (preferably) get it from the git repository:
2597
2598   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2599
2600 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2601 The file is still there, but it is empty for backwards compatibility.
2602
2603 For your own changes use these two files:
2604     $HOME/.zshrc.pre
2605     $HOME/.zshrc.local
2606
2607 The former is sourced very early in our zshrc, the latter is sourced
2608 very lately.
2609
2610 System wide configuration without touching configuration files of grml
2611 can take place in /etc/zsh/zshrc.local.
2612
2613 For information regarding zsh start at http://grml.org/zsh/
2614
2615 Take a look at grml'\''s zsh refcard:
2616 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2617
2618 Check out the main zsh refcard:
2619 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2620
2621 And of course visit the zsh-lovers:
2622 % man zsh-lovers
2623
2624 You can adjust some options through environment variables when
2625 invoking zsh without having to edit configuration files.
2626 Basically meant for bash users who are not used to the power of
2627 the zsh yet. :)
2628
2629   "NOCOR=1    zsh" => deactivate automatic correction
2630   "NOMENU=1   zsh" => do not use auto menu completion
2631                       (note: use ctrl-d for completion instead!)
2632   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2633   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2634                       preexec() and precmd() completely
2635   "GRML_DISPLAY_BATTERY=1  zsh"
2636                    => activate battery status on right side of prompt (WIP)
2637   "COMMAND_NOT_FOUND=1 zsh"
2638                    => Enable a handler if an external command was not found
2639                       The command called in the handler can be altered by setting
2640                       the GRML_ZSH_CNF_HANDLER variable, the default is:
2641                       "/usr/share/command-not-found/command-not-found"
2642
2643 A value greater than 0 is enables a feature; a value equal to zero
2644 disables it. If you like one or the other of these settings, you can
2645 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2646 zshrc.'
2647
2648     print "
2649 $bg[white]$fg[black]
2650 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2651 Enjoy your grml system with the zsh!$reset_color"
2652 }
2653
2654 # debian stuff
2655 if [[ -r /etc/debian_version ]] ; then
2656     #a3# Execute \kbd{apt-cache search}
2657     alias acs='apt-cache search'
2658     #a3# Execute \kbd{apt-cache show}
2659     alias acsh='apt-cache show'
2660     #a3# Execute \kbd{apt-cache policy}
2661     alias acp='apt-cache policy'
2662     #a3# Execute \kbd{apt-get dist-upgrade}
2663     salias adg="apt-get dist-upgrade"
2664     #a3# Execute \kbd{apt-get install}
2665     salias agi="apt-get install"
2666     #a3# Execute \kbd{aptitude install}
2667     salias ati="aptitude install"
2668     #a3# Execute \kbd{apt-get upgrade}
2669     salias ag="apt-get upgrade"
2670     #a3# Execute \kbd{apt-get update}
2671     salias au="apt-get update"
2672     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2673     salias -a up="aptitude update ; aptitude safe-upgrade"
2674     #a3# Execute \kbd{dpkg-buildpackage}
2675     alias dbp='dpkg-buildpackage'
2676     #a3# Execute \kbd{grep-excuses}
2677     alias ge='grep-excuses'
2678
2679     # get a root shell as normal user in live-cd mode:
2680     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2681        alias su="sudo su"
2682     fi
2683
2684     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2685     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2686     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2687     salias tlog="tail -f /var/log/syslog"    # follow the syslog
2688 fi
2689
2690 # sort installed Debian-packages by size
2691 if check_com -c dpkg-query ; then
2692     #a3# List installed Debian-packages sorted by size
2693     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
2694 fi
2695
2696 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2697 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
2698     if check_com -c wodim; then
2699         cdrecord() {
2700             <<__EOF0__
2701 cdrecord is not provided under its original name by Debian anymore.
2702 See #377109 in the BTS of Debian for more details.
2703
2704 Please use the wodim binary instead
2705 __EOF0__
2706             return 1
2707         }
2708     fi
2709 fi
2710
2711 if isgrmlcd; then
2712     # No core dumps: important for a live-cd-system
2713     limit -s core 0
2714 fi
2715
2716 # grmlstuff
2717 grmlstuff() {
2718 # people should use 'grml-x'!
2719     if check_com -c 915resolution; then
2720         855resolution() {
2721             echo "Please use 915resolution as resolution modifying tool for Intel \
2722 graphic chipset."
2723             return -1
2724         }
2725     fi
2726
2727     #a1# Output version of running grml
2728     alias grml-version='cat /etc/grml_version'
2729
2730     if check_com -c grml-debootstrap ; then
2731         debian2hd() {
2732             echo "Installing debian to harddisk is possible by using grml-debootstrap."
2733             return 1
2734         }
2735     fi
2736 }
2737
2738 # now run the functions
2739 isgrml && checkhome
2740 is4    && isgrml    && grmlstuff
2741 is4    && grmlcomp
2742
2743 # keephack
2744 is4 && xsource "/etc/zsh/keephack"
2745
2746 # wonderful idea of using "e" glob qualifier by Peter Stephenson
2747 # You use it as follows:
2748 # $ NTREF=/reference/file
2749 # $ ls -l *(e:nt:)
2750 # This lists all the files in the current directory newer than the reference file.
2751 # You can also specify the reference file inline; note quotes:
2752 # $ ls -l *(e:'nt ~/.zshenv':)
2753 is4 && nt() {
2754     if [[ -n $1 ]] ; then
2755         local NTREF=${~1}
2756     fi
2757     [[ $REPLY -nt $NTREF ]]
2758 }
2759
2760 # shell functions
2761
2762 #f1# Reload an autoloadable function
2763 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2764 compdef _functions freload
2765
2766 #
2767 # Usage:
2768 #
2769 #      e.g.:   a -> b -> c -> d  ....
2770 #
2771 #      sll a
2772 #
2773 #
2774 #      if parameter is given with leading '=', lookup $PATH for parameter and resolve that
2775 #
2776 #      sll =java
2777 #
2778 #      Note: limit for recursive symlinks on linux:
2779 #            http://git.kernel.org/cgit/linux/kernel/git/torvalds/linux.git/tree/fs/namei.c?id=refs/heads/master#l808
2780 #            This limits recursive symlink follows to 8,
2781 #            while limiting consecutive symlinks to 40.
2782 #
2783 #      When resolving and displaying information about symlinks, no check is made
2784 #      that the displayed information does make any sense on your OS.
2785 #      We leave that decission to the user.
2786 #
2787 #      The zstat module is used to detect symlink loops. zstat is available since zsh4.
2788 #      With an older zsh you will need to abort with <C-c> in that case.
2789 #      When a symlink loop is detected, a warning ist printed and further processing is stopped.
2790 #
2791 #      Module zstat is loaded by default in grml zshrc, no extra action needed for that.
2792 #
2793 #      Known bugs:
2794 #      If you happen to come accross a symlink that points to a destination on an other partition
2795 #      with the same inode number, that will be marked as symlink loop though it is not.
2796 #      Two hints for this situation:
2797 #      I)  Play lottery the same day, as you seem to be rather lucky right now.
2798 #      II) Send patches.
2799 #
2800 #      return status:
2801 #      0 upon success
2802 #      1 file/dir not accesible
2803 #      2 symlink loop detected
2804 #
2805 #f1# List symlinks in detail (more detailed version of 'readlink -f', 'whence -s' and 'namei -l')
2806 sll() {
2807     if [[ -z ${1} ]] ; then
2808         printf 'Usage: %s <symlink(s)>\n' "${0}"
2809         return 1
2810     fi
2811
2812     local file jumpd curdir
2813     local -i RTN LINODE i
2814     local -a SEENINODES
2815     curdir="${PWD}"
2816     RTN=0
2817
2818     for file in "${@}" ; do
2819         SEENINODES=()
2820         ls -l "${file:a}"   || RTN=1
2821
2822         while [[ -h "$file" ]] ; do
2823             if is4 ; then
2824                 LINODE=$(zstat -L +inode "${file}")
2825                 for i in ${SEENINODES} ; do
2826                     if (( ${i} == ${LINODE} )) ; then
2827                         builtin cd "${curdir}"
2828                         print "link loop detected, aborting!"
2829                         return 2
2830                     fi
2831                 done
2832                 SEENINODES+=${LINODE}
2833             fi
2834             jumpd="${file:h}"
2835             file="${file:t}"
2836
2837             if [[ -d ${jumpd} ]] ; then
2838                 builtin cd "${jumpd}"  || RTN=1
2839             fi
2840             file=$(readlink "$file")
2841
2842             jumpd="${file:h}"
2843             file="${file:t}"
2844
2845             if [[ -d ${jumpd} ]] ; then
2846                 builtin cd "${jumpd}"  || RTN=1
2847             fi
2848
2849             ls -l "${PWD}/${file}"     || RTN=1
2850         done
2851         shift 1
2852         if (( ${#} >= 1 )) ; then
2853             print ""
2854         fi
2855         builtin cd "${curdir}"
2856     done
2857     return ${RTN}
2858 }
2859
2860 # TODO: Is it supported to use pager settings like this?
2861 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2862 # with respect to wordsplitting. (ie. ${=PAGER})
2863 if check_com -c $PAGER ; then
2864     #f3# View Debian's changelog of given package(s)
2865     dchange() {
2866         emulate -L zsh
2867         [[ -z "$1" ]] && printf 'Usage: %s <package_name(s)>\n' "$0" && return 1
2868
2869         local package
2870         for package in "$@" ; do
2871             if [[ -r /usr/share/doc/${package}/changelog.Debian.gz ]] ; then
2872                 $PAGER /usr/share/doc/${package}/changelog.Debian.gz
2873             elif [[ -r /usr/share/doc/${package}/changelog.gz ]] ; then
2874                 $PAGER /usr/share/doc/${package}/changelog.gz
2875             elif [[ -r /usr/share/doc/${package}/changelog ]] ; then
2876                 $PAGER /usr/share/doc/${package}/changelog
2877             else
2878                 if check_com -c aptitude ; then
2879                     echo "No changelog for package $package found, using aptitude to retrieve it."
2880                     aptitude changelog "$package"
2881                 elif check_com -c apt-get ; then
2882                     echo "No changelog for package $package found, using apt-get to retrieve it."
2883                     apt-get changelog "$package"
2884                 else
2885                     echo "No changelog for package $package found, sorry."
2886                 fi
2887             fi
2888         done
2889     }
2890     _dchange() { _files -W /usr/share/doc -/ }
2891     compdef _dchange dchange
2892
2893     #f3# View Debian's NEWS of a given package
2894     dnews() {
2895         emulate -L zsh
2896         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2897             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2898         else
2899             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2900                 $PAGER /usr/share/doc/$1/NEWS.gz
2901             else
2902                 echo "No NEWS file for package $1 found, sorry."
2903                 return 1
2904             fi
2905         fi
2906     }
2907     _dnews() { _files -W /usr/share/doc -/ }
2908     compdef _dnews dnews
2909
2910     #f3# View Debian's copyright of a given package
2911     dcopyright() {
2912         emulate -L zsh
2913         if [[ -r /usr/share/doc/$1/copyright ]] ; then
2914             $PAGER /usr/share/doc/$1/copyright
2915         else
2916             echo "No copyright file for package $1 found, sorry."
2917             return 1
2918         fi
2919     }
2920     _dcopyright() { _files -W /usr/share/doc -/ }
2921     compdef _dcopyright dcopyright
2922
2923     #f3# View upstream's changelog of a given package
2924     uchange() {
2925         emulate -L zsh
2926         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2927             $PAGER /usr/share/doc/$1/changelog.gz
2928         else
2929             echo "No changelog for package $1 found, sorry."
2930             return 1
2931         fi
2932     }
2933     _uchange() { _files -W /usr/share/doc -/ }
2934     compdef _uchange uchange
2935 fi
2936
2937 # zsh profiling
2938 profile() {
2939     ZSH_PROFILE_RC=1 zsh "$@"
2940 }
2941
2942 #f1# Edit an alias via zle
2943 edalias() {
2944     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2945 }
2946 compdef _aliases edalias
2947
2948 #f1# Edit a function via zle
2949 edfunc() {
2950     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2951 }
2952 compdef _functions edfunc
2953
2954 # use it e.g. via 'Restart apache2'
2955 #m# f6 Start() \kbd{service \em{process}}\quad\kbd{start}
2956 #m# f6 Restart() \kbd{service \em{process}}\quad\kbd{restart}
2957 #m# f6 Stop() \kbd{service \em{process}}\quad\kbd{stop}
2958 #m# f6 Reload() \kbd{service \em{process}}\quad\kbd{reload}
2959 #m# f6 Force-Reload() \kbd{service \em{process}}\quad\kbd{force-reload}
2960 #m# f6 Status() \kbd{service \em{process}}\quad\kbd{status}
2961 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2962     __start_stop() {
2963         local action_="${1:l}"  # e.g Start/Stop/Restart
2964         local service_="$2"
2965         local param_="$3"
2966
2967         local service_target_="$(readlink /etc/init.d/$service_)"
2968         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2969             # runit
2970             case "${action_}" in
2971                 start) if [[ ! -e /etc/service/$service_ ]]; then
2972                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2973                        else
2974                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2975                        fi ;;
2976                 # there is no reload in runits sysv emulation
2977                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2978                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2979             esac
2980         else
2981             # sysv/sysvinit-utils, upstart
2982             if check_com -c service ; then
2983               $SUDO service "$service_" "${action_}" "$param_"
2984             else
2985               $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2986             fi
2987         fi
2988     }
2989
2990     _grmlinitd() {
2991         local -a scripts
2992         scripts=( /etc/init.d/*(x:t) )
2993         _describe "service startup script" scripts
2994     }
2995
2996     for i in Start Restart Stop Force-Reload Reload Status ; do
2997         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2998         compdef _grmlinitd $i
2999     done
3000     builtin unset -v i
3001 fi
3002
3003 #f1# Provides useful information on globbing
3004 H-Glob() {
3005     echo -e "
3006     /      directories
3007     .      plain files
3008     @      symbolic links
3009     =      sockets
3010     p      named pipes (FIFOs)
3011     *      executable plain files (0100)
3012     %      device files (character or block special)
3013     %b     block special files
3014     %c     character special files
3015     r      owner-readable files (0400)
3016     w      owner-writable files (0200)
3017     x      owner-executable files (0100)
3018     A      group-readable files (0040)
3019     I      group-writable files (0020)
3020     E      group-executable files (0010)
3021     R      world-readable files (0004)
3022     W      world-writable files (0002)
3023     X      world-executable files (0001)
3024     s      setuid files (04000)
3025     S      setgid files (02000)
3026     t      files with the sticky bit (01000)
3027
3028   print *(m-1)          # Files modified up to a day ago
3029   print *(a1)           # Files accessed a day ago
3030   print *(@)            # Just symlinks
3031   print *(Lk+50)        # Files bigger than 50 kilobytes
3032   print *(Lk-50)        # Files smaller than 50 kilobytes
3033   print **/*.c          # All *.c files recursively starting in \$PWD
3034   print **/*.c~file.c   # Same as above, but excluding 'file.c'
3035   print (foo|bar).*     # Files starting with 'foo' or 'bar'
3036   print *~*.*           # All Files that do not contain a dot
3037   chmod 644 *(.^x)      # make all plain non-executable files publically readable
3038   print -l *(.c|.h)     # Lists *.c and *.h
3039   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
3040   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
3041 }
3042 alias help-zshglob=H-Glob
3043
3044 # grep for running process, like: 'any vim'
3045 any() {
3046     emulate -L zsh
3047     unsetopt KSH_ARRAYS
3048     if [[ -z "$1" ]] ; then
3049         echo "any - grep for process(es) by keyword" >&2
3050         echo "Usage: any <keyword>" >&2 ; return 1
3051     else
3052         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
3053     fi
3054 }
3055
3056
3057 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
3058 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
3059 [[ -r /proc/1/maps ]] && \
3060 deswap() {
3061     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
3062     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
3063     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
3064 }
3065
3066 # a wrapper for vim, that deals with title setting
3067 #   VIM_OPTIONS
3068 #       set this array to a set of options to vim you always want
3069 #       to have set when calling vim (in .zshrc.local), like:
3070 #           VIM_OPTIONS=( -p )
3071 #       This will cause vim to send every file given on the
3072 #       commandline to be send to it's own tab (needs vim7).
3073 if check_com vim; then
3074     vim() {
3075         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
3076     }
3077 fi
3078
3079 ssl_hashes=( sha512 sha256 sha1 md5 )
3080
3081 for sh in ${ssl_hashes}; do
3082     eval 'ssl-cert-'${sh}'() {
3083         emulate -L zsh
3084         if [[ -z $1 ]] ; then
3085             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
3086             return 1
3087         fi
3088         openssl x509 -noout -fingerprint -'${sh}' -in $1
3089     }'
3090 done; unset sh
3091
3092 ssl-cert-fingerprints() {
3093     emulate -L zsh
3094     local i
3095     if [[ -z $1 ]] ; then
3096         printf 'usage: ssl-cert-fingerprints <file>\n'
3097         return 1
3098     fi
3099     for i in ${ssl_hashes}
3100         do ssl-cert-$i $1;
3101     done
3102 }
3103
3104 ssl-cert-info() {
3105     emulate -L zsh
3106     if [[ -z $1 ]] ; then
3107         printf 'usage: ssl-cert-info <file>\n'
3108         return 1
3109     fi
3110     openssl x509 -noout -text -in $1
3111     ssl-cert-fingerprints $1
3112 }
3113
3114 # make sure our environment is clean regarding colors
3115 for var in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $var
3116 builtin unset -v var
3117
3118 # "persistent history"
3119 # just write important commands you always need to ~/.important_commands
3120 if [[ -r ~/.important_commands ]] ; then
3121     fc -R ~/.important_commands
3122 fi
3123
3124 # load the lookup subsystem if it's available on the system
3125 zrcautoload lookupinit && lookupinit
3126
3127 # variables
3128
3129 # set terminal property (used e.g. by msgid-chooser)
3130 export COLORTERM="yes"
3131
3132 # aliases
3133
3134 # general
3135 #a2# Execute \kbd{du -sch}
3136 alias da='du -sch'
3137
3138 # listing stuff
3139 #a2# Execute \kbd{ls -lSrah}
3140 alias dir="command ls -lSrah"
3141 #a2# Only show dot-directories
3142 alias lad='command ls -d .*(/)'
3143 #a2# Only show dot-files
3144 alias lsa='command ls -a .*(.)'
3145 #a2# Only files with setgid/setuid/sticky flag
3146 alias lss='command ls -l *(s,S,t)'
3147 #a2# Only show symlinks
3148 alias lsl='command ls -l *(@)'
3149 #a2# Display only executables
3150 alias lsx='command ls -l *(*)'
3151 #a2# Display world-{readable,writable,executable} files
3152 alias lsw='command ls -ld *(R,W,X.^ND/)'
3153 #a2# Display the ten biggest files
3154 alias lsbig="command ls -flh *(.OL[1,10])"
3155 #a2# Only show directories
3156 alias lsd='command ls -d *(/)'
3157 #a2# Only show empty directories
3158 alias lse='command ls -d *(/^F)'
3159 #a2# Display the ten newest files
3160 alias lsnew="command ls -rtlh *(D.om[1,10])"
3161 #a2# Display the ten oldest files
3162 alias lsold="command ls -rtlh *(D.Om[1,10])"
3163 #a2# Display the ten smallest files
3164 alias lssmall="command ls -Srl *(.oL[1,10])"
3165 #a2# Display the ten newest directories and ten newest .directories
3166 alias lsnewdir="command ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
3167 #a2# Display the ten oldest directories and ten oldest .directories
3168 alias lsolddir="command ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
3169
3170 # some useful aliases
3171 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir \$OLDCWD}
3172 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
3173
3174 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3175 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3176 #a2# scp with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3177 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3178
3179 # work around non utf8 capable software in utf environment via $LANG and luit
3180 if check_com isutfenv && check_com luit ; then
3181     if check_com -c mrxvt ; then
3182         isutfenv && [[ -n "$LANG" ]] && \
3183             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3184     fi
3185
3186     if check_com -c aterm ; then
3187         isutfenv && [[ -n "$LANG" ]] && \
3188             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3189     fi
3190
3191     if check_com -c centericq ; then
3192         isutfenv && [[ -n "$LANG" ]] && \
3193             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3194     fi
3195 fi
3196
3197 # useful functions
3198
3199 #f5# Backup \kbd{file_or_folder {\rm to} file_or_folder\_timestamp}
3200 bk() {
3201     emulate -L zsh
3202     local current_date=$(date -u "+%Y-%m-%dT%H:%M:%SZ")
3203     local clean keep move verbose result all to_bk
3204     setopt extended_glob
3205     keep=1
3206     while getopts ":hacmrv" opt; do
3207         case $opt in
3208             a) (( all++ ));;
3209             c) unset move clean && (( ++keep ));;
3210             m) unset keep clean && (( ++move ));;
3211             r) unset move keep && (( ++clean ));;
3212             v) verbose="-v";;
3213             h) <<__EOF0__
3214 bk [-hcmv] FILE [FILE ...]
3215 bk -r [-av] [FILE [FILE ...]]
3216 Backup a file or folder in place and append the timestamp
3217 Remove backups of a file or folder, or all backups in the current directory
3218
3219 Usage:
3220 -h    Display this help text
3221 -c    Keep the file/folder as is, create a copy backup using cp(1) (default)
3222 -m    Move the file/folder, using mv(1)
3223 -r    Remove backups of the specified file or directory, using rm(1). If none
3224       is provided, remove all backups in the current directory.
3225 -a    Remove all (even hidden) backups.
3226 -v    Verbose
3227
3228 The -c, -r and -m options are mutually exclusive. If specified at the same time,
3229 the last one is used.
3230
3231 The return code is the sum of all cp/mv/rm return codes.
3232 __EOF0__
3233 return 0;;
3234             \?) bk -h >&2; return 1;;
3235         esac
3236     done
3237     shift "$((OPTIND-1))"
3238     if (( keep > 0 )); then
3239         if islinux || isfreebsd; then
3240             for to_bk in "$@"; do
3241                 cp $verbose -a "${to_bk%/}" "${to_bk%/}_$current_date"
3242                 (( result += $? ))
3243             done
3244         else
3245             for to_bk in "$@"; do
3246                 cp $verbose -pR "${to_bk%/}" "${to_bk%/}_$current_date"
3247                 (( result += $? ))
3248             done
3249         fi
3250     elif (( move > 0 )); then
3251         while (( $# > 0 )); do
3252             mv $verbose "${1%/}" "${1%/}_$current_date"
3253             (( result += $? ))
3254             shift
3255         done
3256     elif (( clean > 0 )); then
3257         if (( $# > 0 )); then
3258             for to_bk in "$@"; do
3259                 rm $verbose -rf "${to_bk%/}"_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z
3260                 (( result += $? ))
3261             done
3262         else
3263             if (( all > 0 )); then
3264                 rm $verbose -rf *_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z(D)
3265             else
3266                 rm $verbose -rf *_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z
3267             fi
3268             (( result += $? ))
3269         fi
3270     fi
3271     return $result
3272 }
3273
3274 #f5# cd to directoy and list files
3275 cl() {
3276     emulate -L zsh
3277     cd $1 && ls -a
3278 }
3279
3280 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
3281 cd() {
3282     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
3283         [[ ! -e ${1:h} ]] && return 1
3284         print "Correcting ${1} to ${1:h}"
3285         builtin cd ${1:h}
3286     else
3287         builtin cd "$@"
3288     fi
3289 }
3290
3291 #f5# Create Directoy and \kbd{cd} to it
3292 mkcd() {
3293     if (( ARGC != 1 )); then
3294         printf 'usage: mkcd <new-directory>\n'
3295         return 1;
3296     fi
3297     if [[ ! -d "$1" ]]; then
3298         command mkdir -p "$1"
3299     else
3300         printf '`%s'\'' already exists: cd-ing.\n' "$1"
3301     fi
3302     builtin cd "$1"
3303 }
3304
3305 #f5# Create temporary directory and \kbd{cd} to it
3306 cdt() {
3307     builtin cd "$(mktemp -d)"
3308     builtin pwd
3309 }
3310
3311 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
3312 accessed() {
3313     emulate -L zsh
3314     print -l -- *(a-${1:-1})
3315 }
3316
3317 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
3318 changed() {
3319     emulate -L zsh
3320     print -l -- *(c-${1:-1})
3321 }
3322
3323 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
3324 modified() {
3325     emulate -L zsh
3326     print -l -- *(m-${1:-1})
3327 }
3328 # modified() was named new() in earlier versions, add an alias for backwards compatibility
3329 check_com new || alias new=modified
3330
3331 # use colors when GNU grep with color-support
3332 if (( $#grep_options > 0 )); then
3333     o=${grep_options:+"${grep_options[*]}"}
3334     #a2# Execute \kbd{grep -{}-color=auto}
3335     alias grep='grep '$o
3336     alias egrep='egrep '$o
3337     unset o
3338 fi
3339
3340 # Translate DE<=>EN
3341 # 'translate' looks up a word in a file with language-to-language
3342 # translations (field separator should be " : "). A typical wordlist looks
3343 # like the following:
3344 #  | english-word : german-translation
3345 # It's also only possible to translate english to german but not reciprocal.
3346 # Use the following oneliner to reverse the sort order:
3347 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3348 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3349 #f5# Translates a word
3350 trans() {
3351     emulate -L zsh
3352     case "$1" in
3353         -[dD]*)
3354             translate -l de-en $2
3355             ;;
3356         -[eE]*)
3357             translate -l en-de $2
3358             ;;
3359         *)
3360             echo "Usage: $0 { -D | -E }"
3361             echo "         -D == German to English"
3362             echo "         -E == English to German"
3363     esac
3364 }
3365
3366 # Usage: simple-extract <file>
3367 # Using option -d deletes the original archive file.
3368 #f5# Smart archive extractor
3369 simple-extract() {
3370     emulate -L zsh
3371     setopt extended_glob noclobber
3372     local ARCHIVE DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
3373     local RC=0
3374     zparseopts -D -E "d=DELETE_ORIGINAL"
3375     for ARCHIVE in "${@}"; do
3376         case $ARCHIVE in
3377             *(tar.bz2|tbz2|tbz))
3378                 DECOMP_CMD="tar -xvjf -"
3379                 USES_STDIN=true
3380                 USES_STDOUT=false
3381                 ;;
3382             *(tar.gz|tgz))
3383                 DECOMP_CMD="tar -xvzf -"
3384                 USES_STDIN=true
3385                 USES_STDOUT=false
3386                 ;;
3387             *(tar.xz|txz|tar.lzma))
3388                 DECOMP_CMD="tar -xvJf -"
3389                 USES_STDIN=true
3390                 USES_STDOUT=false
3391                 ;;
3392             *tar)
3393                 DECOMP_CMD="tar -xvf -"
3394                 USES_STDIN=true
3395                 USES_STDOUT=false
3396                 ;;
3397             *rar)
3398                 DECOMP_CMD="unrar x"
3399                 USES_STDIN=false
3400                 USES_STDOUT=false
3401                 ;;
3402             *lzh)
3403                 DECOMP_CMD="lha x"
3404                 USES_STDIN=false
3405                 USES_STDOUT=false
3406                 ;;
3407             *7z)
3408                 DECOMP_CMD="7z x"
3409                 USES_STDIN=false
3410                 USES_STDOUT=false
3411                 ;;
3412             *(zip|jar))
3413                 DECOMP_CMD="unzip"
3414                 USES_STDIN=false
3415                 USES_STDOUT=false
3416                 ;;
3417             *deb)
3418                 DECOMP_CMD="ar -x"
3419                 USES_STDIN=false
3420                 USES_STDOUT=false
3421                 ;;
3422             *bz2)
3423                 DECOMP_CMD="bzip2 -d -c -"
3424                 USES_STDIN=true
3425                 USES_STDOUT=true
3426                 ;;
3427             *(gz|Z))
3428                 DECOMP_CMD="gzip -d -c -"
3429                 USES_STDIN=true
3430                 USES_STDOUT=true
3431                 ;;
3432             *(xz|lzma))
3433                 DECOMP_CMD="xz -d -c -"
3434                 USES_STDIN=true
3435                 USES_STDOUT=true
3436                 ;;
3437             *)
3438                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
3439                 RC=$((RC+1))
3440                 continue
3441                 ;;
3442         esac
3443
3444         if ! check_com ${DECOMP_CMD[(w)1]}; then
3445             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
3446             RC=$((RC+2))
3447             continue
3448         fi
3449
3450         GZTARGET="${ARCHIVE:t:r}"
3451         if [[ -f $ARCHIVE ]] ; then
3452
3453             print "Extracting '$ARCHIVE' ..."
3454             if $USES_STDIN; then
3455                 if $USES_STDOUT; then
3456                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
3457                 else
3458                     ${=DECOMP_CMD} < "$ARCHIVE"
3459                 fi
3460             else
3461                 if $USES_STDOUT; then
3462                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
3463                 else
3464                     ${=DECOMP_CMD} "$ARCHIVE"
3465                 fi
3466             fi
3467             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
3468
3469         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
3470             if check_com curl; then
3471                 WGET_CMD="curl -L -s -o -"
3472             elif check_com wget; then
3473                 WGET_CMD="wget -q -O -"
3474             elif check_com fetch; then
3475                 WGET_CMD="fetch -q -o -"
3476             else
3477                 print "ERROR: neither wget, curl nor fetch is installed" >&2
3478                 RC=$((RC+4))
3479                 continue
3480             fi
3481             print "Downloading and Extracting '$ARCHIVE' ..."
3482             if $USES_STDIN; then
3483                 if $USES_STDOUT; then
3484                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
3485                     RC=$((RC+$?))
3486                 else
3487                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
3488                     RC=$((RC+$?))
3489                 fi
3490             else
3491                 if $USES_STDOUT; then
3492                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
3493                 else
3494                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
3495                 fi
3496             fi
3497
3498         else
3499             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
3500             RC=$((RC+8))
3501         fi
3502     done
3503     return $RC
3504 }
3505
3506 __archive_or_uri()
3507 {
3508     _alternative \
3509         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
3510         '_urls:Remote Archives:_urls'
3511 }
3512
3513 _simple_extract()
3514 {
3515     _arguments \
3516         '-d[delete original archivefile after extraction]' \
3517         '*:Archive Or Uri:__archive_or_uri'
3518 }
3519 compdef _simple_extract simple-extract
3520 alias se=simple-extract
3521
3522 #f5# Change the xterm title from within GNU-screen
3523 xtrename() {
3524     emulate -L zsh
3525     if [[ $1 != "-f" ]] ; then
3526         if [[ -z ${DISPLAY} ]] ; then
3527             printf 'xtrename only makes sense in X11.\n'
3528             return 1
3529         fi
3530     else
3531         shift
3532     fi
3533     if [[ -z $1 ]] ; then
3534         printf 'usage: xtrename [-f] "title for xterm"\n'
3535         printf '  renames the title of xterm from _within_ screen.\n'
3536         printf '  also works without screen.\n'
3537         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3538         return 0
3539     fi
3540     print -n "\eP\e]0;${1}\C-G\e\\"
3541     return 0
3542 }
3543
3544 # Create small urls via http://goo.gl using curl(1).
3545 # API reference: https://code.google.com/apis/urlshortener/
3546 function zurl() {
3547     emulate -L zsh
3548     setopt extended_glob
3549
3550     if [[ -z $1 ]]; then
3551         print "USAGE: zurl <URL>"
3552         return 1
3553     fi
3554
3555     local PN url prog api json contenttype item
3556     local -a data
3557     PN=$0
3558     url=$1
3559
3560     # Prepend 'http://' to given URL where necessary for later output.
3561     if [[ ${url} != http(s|)://* ]]; then
3562         url='http://'${url}
3563     fi
3564
3565     if check_com -c curl; then
3566         prog=curl
3567     else
3568         print "curl is not available, but mandatory for ${PN}. Aborting."
3569         return 1
3570     fi
3571     api='https://www.googleapis.com/urlshortener/v1/url'
3572     contenttype="Content-Type: application/json"
3573     json="{\"longUrl\": \"${url}\"}"
3574     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
3575     # Parse the response
3576     for item in "${data[@]}"; do
3577         case "$item" in
3578             ' '#'"id":'*)
3579                 item=${item#*: \"}
3580                 item=${item%\",*}
3581                 printf '%s\n' "$item"
3582                 return 0
3583                 ;;
3584         esac
3585     done
3586     return 1
3587 }
3588
3589 #f2# Find history events by search pattern and list them by date.
3590 whatwhen()  {
3591     emulate -L zsh
3592     local usage help ident format_l format_s first_char remain first last
3593     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3594     help='Use `whatwhen -h'\'' for further explanations.'
3595     ident=${(l,${#${:-Usage: }},, ,)}
3596     format_l="${ident}%s\t\t\t%s\n"
3597     format_s="${format_l//(\\t)##/\\t}"
3598     # Make the first char of the word to search for case
3599     # insensitive; e.g. [aA]
3600     first_char=[${(L)1[1]}${(U)1[1]}]
3601     remain=${1[2,-1]}
3602     # Default search range is `-100'.
3603     first=${2:-\-100}
3604     # Optional, just used for `<first> <last>' given.
3605     last=$3
3606     case $1 in
3607         ("")
3608             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3609             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3610         ;;
3611         (-h)
3612             printf '%s\n\n' ${usage}
3613             print 'OPTIONS:'
3614             printf $format_l '-h' 'show help text'
3615             print '\f'
3616             print 'SEARCH RANGE:'
3617             printf $format_l "'0'" 'the whole history,'
3618             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
3619             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
3620             printf '\n%s\n' 'EXAMPLES:'
3621             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
3622             printf $format_l 'whatwhen zsh -250'
3623             printf $format_l 'whatwhen foo 1 99'
3624         ;;
3625         (\?)
3626             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3627         ;;
3628         (*)
3629             # -l list results on stout rather than invoking $EDITOR.
3630             # -i Print dates as in YYYY-MM-DD.
3631             # -m Search for a - quoted - pattern within the history.
3632             fc -li -m "*${first_char}${remain}*" $first $last
3633         ;;
3634     esac
3635 }
3636
3637 # mercurial related stuff
3638 if check_com -c hg ; then
3639     # gnu like diff for mercurial
3640     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
3641     #f5# GNU like diff for mercurial
3642     hgdi() {
3643         emulate -L zsh
3644         local i
3645         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
3646     }
3647
3648     # build debian package
3649     #a2# Alias for \kbd{hg-buildpackage}
3650     alias hbp='hg-buildpackage'
3651
3652     # execute commands on the versioned patch-queue from the current repos
3653     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
3654
3655     # diffstat for specific version of a mercurial repository
3656     #   hgstat      => display diffstat between last revision and tip
3657     #   hgstat 1234 => display diffstat between revision 1234 and tip
3658     #f5# Diffstat for specific version of a mercurial repos
3659     hgstat() {
3660         emulate -L zsh
3661         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
3662     }
3663
3664 fi # end of check whether we have the 'hg'-executable
3665
3666 # grml-small cleanups
3667
3668 # The following is used to remove zsh-config-items that do not work
3669 # in grml-small by default.
3670 # If you do not want these adjustments (for whatever reason), set
3671 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
3672 # sources if it is there).
3673
3674 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
3675
3676     unset abk[V]
3677     unalias    'V'      &> /dev/null
3678     unfunction vman     &> /dev/null
3679     unfunction viless   &> /dev/null
3680     unfunction 2html    &> /dev/null
3681
3682     # manpages are not in grmlsmall
3683     unfunction manzsh   &> /dev/null
3684     unfunction man2     &> /dev/null
3685
3686 fi
3687
3688 zrclocal
3689
3690 ## genrefcard.pl settings
3691
3692 ### doc strings for external functions from files
3693 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
3694
3695 ### example: split functions-search 8,16,24,32
3696 #@# split functions-search 8
3697
3698 ## END OF FILE #################################################################
3699 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
3700 # Local variables:
3701 # mode: sh
3702 # End: