etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* || $ZSH_VERSION == <5->* ]] && return 0
 143     return 1
 144 }
 145
 146 is439(){
 147     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* || $ZSH_VERSION == <5->* ]] && return 0
 148     return 1
 149 }
 150
 151 #f1# Checks whether or not you're running grml
 152 isgrml(){
 153     [[ -f /etc/grml_version ]] && return 0
 154     return 1
 155 }
 156
 157 #f1# Checks whether or not you're running a grml cd
 158 isgrmlcd(){
 159     [[ -f /etc/grml_cd ]] && return 0
 160     return 1
 161 }
 162
 163 if isgrml ; then
 164 #f1# Checks whether or not you're running grml-small
 165     isgrmlsmall() {
 166         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 167     }
 168 else
 169     isgrmlsmall() { return 1 }
 170 fi
 171
 172 isdarwin(){
 173     [[ $OSTYPE == darwin* ]] && return 0
 174     return 1
 175 }
 176
 177 #f1# are we running within an utf environment?
 178 isutfenv() {
 179     case "$LANG $CHARSET $LANGUAGE" in
 180         *utf*) return 0 ;;
 181         *UTF*) return 0 ;;
 182         *)     return 1 ;;
 183     esac
 184 }
 185
 186 # check for user, if not running as root set $SUDO to sudo
 187 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 188
 189 # change directory to home on first invocation of zsh
 190 # important for rungetty -> autologin
 191 # Thanks go to Bart Schaefer!
 192 isgrml && checkhome() {
 193     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 194         export ALREADY_DID_CD_HOME=$HOME
 195         cd
 196     fi
 197 }
 198
 199 # check for zsh v3.1.7+
 200
 201 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 202      || ${ZSH_VERSION} == 3.<2->.<->*    \
 203      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 204
 205     printf '-!-\n'
 206     printf '-!- In this configuration we try to make use of features, that only\n'
 207     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 208     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 209     printf '-!- advanced features in all supported versions.\n'
 210     printf '-!-\n'
 211     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 212     printf '-!-\n'
 213     printf '-!- While this *may* work, it might as well fail.\n'
 214     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 215     printf '-!-\n'
 216     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 217     printf '-!- If it does today, you'\''ve been lucky.\n'
 218     printf '-!-\n'
 219     printf '-!- Ye been warned!\n'
 220     printf '-!-\n'
 221
 222     function zstyle() { : }
 223 fi
 224
 225 # autoload wrapper - use this one instead of autoload directly
 226 # We need to define this function as early as this, because autoloading
 227 # 'is-at-least()' needs it.
 228 function zrcautoload() {
 229     emulate -L zsh
 230     setopt extended_glob
 231     local fdir ffile
 232     local -i ffound
 233
 234     ffile=$1
 235     (( found = 0 ))
 236     for fdir in ${fpath} ; do
 237         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 238     done
 239
 240     (( ffound == 0 )) && return 1
 241     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 242         autoload -U ${ffile} || return 1
 243     else
 244         autoload ${ffile} || return 1
 245     fi
 246     return 0
 247 }
 248
 249 # Load is-at-least() for more precise version checks
 250 # Note that this test will *always* fail, if the is-at-least
 251 # function could not be marked for autoloading.
 252 zrcautoload is-at-least || is-at-least() { return 1 }
 253
 254 # set some important options (as early as possible)
 255 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 256 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 257 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 258 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 259                             # list duplicates an older one, the older command is removed from the list
 260 setopt histignorespace      # remove command lines from the history list when
 261                             # the first character on the line is a space
 262 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 263                             # and the command is the name of a directory, perform the cd command to that directory
 264 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 265                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 266                             # -> searches for word not in compressed files
 267                             # don't forget to quote '^', '~' and '#'!
 268 setopt longlistjobs         # display PID when suspending processes as well
 269 setopt notify               # report the status of backgrounds jobs immediately
 270 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 271                             # the entire command path is hashed first.
 272 setopt completeinword       # not just at the end
 273 setopt nohup                # and don't kill them, either
 274 setopt auto_pushd           # make cd push the old directory onto the directory stack.
 275 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 276 setopt nobeep               # avoid "beep"ing
 277 setopt pushd_ignore_dups    # don't push the same dir twice.
 278 setopt noglobdots           # * shouldn't match dotfiles. ever.
 279 setopt noshwordsplit        # use zsh style word splitting
 280 setopt unset                # don't error out when unset parameters are used
 281
 282 # setting some default values
 283
 284 NOCOR=${NOCOR:-0}
 285 NOMENU=${NOMENU:-0}
 286 NOPRECMD=${NOPRECMD:-0}
 287 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 288 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 289 BATTERY=${BATTERY:-0}
 290 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 291 GRML_ALWAYS_LOAD_ALL=${GRML_ALWAYS_LOAD_ALL:-0}
 292 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 293
 294 # utility functions
 295 # this function checks if a command exists and returns either true
 296 # or false. This avoids using 'which' and 'whence', which will
 297 # avoid problems with aliases for which on certain weird systems. :-)
 298 # Usage: check_com [-c|-g] word
 299 #   -c  only checks for external commands
 300 #   -g  does the usual tests and also checks for global aliases
 301 check_com() {
 302     emulate -L zsh
 303     local -i comonly gatoo
 304
 305     if [[ $1 == '-c' ]] ; then
 306         (( comonly = 1 ))
 307         shift
 308     elif [[ $1 == '-g' ]] ; then
 309         (( gatoo = 1 ))
 310     else
 311         (( comonly = 0 ))
 312         (( gatoo = 0 ))
 313     fi
 314
 315     if (( ${#argv} != 1 )) ; then
 316         printf 'usage: check_com [-c] <command>\n' >&2
 317         return 1
 318     fi
 319
 320     if (( comonly > 0 )) ; then
 321         [[ -n ${commands[$1]}  ]] && return 0
 322         return 1
 323     fi
 324
 325     if   [[ -n ${commands[$1]}    ]] \
 326       || [[ -n ${functions[$1]}   ]] \
 327       || [[ -n ${aliases[$1]}     ]] \
 328       || [[ -n ${reswords[(r)$1]} ]] ; then
 329
 330         return 0
 331     fi
 332
 333     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 334         return 0
 335     fi
 336
 337     return 1
 338 }
 339
 340 # creates an alias and precedes the command with
 341 # sudo if $EUID is not zero.
 342 salias() {
 343     emulate -L zsh
 344     local only=0 ; local multi=0
 345     while [[ $1 == -* ]] ; do
 346         case $1 in
 347             (-o) only=1 ;;
 348             (-a) multi=1 ;;
 349             (--) shift ; break ;;
 350             (-h)
 351                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 352                 printf '  -h      shows this help text.\n'
 353                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 354                 printf '          be careful using this option.\n'
 355                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 356                 return 0
 357                 ;;
 358             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 359         esac
 360         shift
 361     done
 362
 363     if (( ${#argv} > 1 )) ; then
 364         printf 'Too many arguments %s\n' "${#argv}"
 365         return 1
 366     fi
 367
 368     key="${1%%\=*}" ;  val="${1#*\=}"
 369     if (( EUID == 0 )) && (( only == 0 )); then
 370         alias -- "${key}=${val}"
 371     elif (( EUID > 0 )) ; then
 372         (( multi > 0 )) && val="${val// ; / ; sudo }"
 373         alias -- "${key}=sudo ${val}"
 374     fi
 375
 376     return 0
 377 }
 378
 379 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 380 # usage: uprint foo
 381 #   Where foo is the *name* of the parameter you want printed.
 382 #   Note that foo is no typo; $foo would be wrong here!
 383 if ! is42 ; then
 384     uprint () {
 385         emulate -L zsh
 386         local -a u
 387         local w
 388         local parameter=$1
 389
 390         if [[ -z ${parameter} ]] ; then
 391             printf 'usage: uprint <parameter>\n'
 392             return 1
 393         fi
 394
 395         for w in ${(P)parameter} ; do
 396             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 397         done
 398
 399         builtin print -l $u
 400     }
 401 fi
 402
 403 # Check if we can read given files and source those we can.
 404 xsource() {
 405     if (( ${#argv} < 1 )) ; then
 406         printf 'usage: xsource FILE(s)...\n' >&2
 407         return 1
 408     fi
 409
 410     while (( ${#argv} > 0 )) ; do
 411         [[ -r "$1" ]] && source "$1"
 412         shift
 413     done
 414     return 0
 415 }
 416
 417 # Check if we can read a given file and 'cat(1)' it.
 418 xcat() {
 419     emulate -L zsh
 420     if (( ${#argv} != 1 )) ; then
 421         printf 'usage: xcat FILE\n' >&2
 422         return 1
 423     fi
 424
 425     [[ -r $1 ]] && cat $1
 426     return 0
 427 }
 428
 429 # Remove these functions again, they are of use only in these
 430 # setup files. This should be called at the end of .zshrc.
 431 xunfunction() {
 432     emulate -L zsh
 433     local -a funcs
 434     funcs=(salias xcat xsource xunfunction zrcautoload)
 435
 436     for func in $funcs ; do
 437         [[ -n ${functions[$func]} ]] \
 438             && unfunction $func
 439     done
 440     return 0
 441 }
 442
 443 # this allows us to stay in sync with grml's zshrc and put own
 444 # modifications in ~/.zshrc.local
 445 zrclocal() {
 446     xsource "/etc/zsh/zshrc.local"
 447     xsource "${HOME}/.zshrc.local"
 448     return 0
 449 }
 450
 451 # locale setup
 452 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 453     xsource "/etc/default/locale"
 454 fi
 455
 456 for var in LANG LC_ALL LC_MESSAGES ; do
 457     [[ -n ${(P)var} ]] && export $var
 458 done
 459
 460 xsource "/etc/sysconfig/keyboard"
 461
 462 TZ=$(xcat /etc/timezone)
 463
 464 # set some variables
 465 if check_com -c vim ; then
 466 #v#
 467     export EDITOR=${EDITOR:-vim}
 468 else
 469     export EDITOR=${EDITOR:-vi}
 470 fi
 471
 472 #v#
 473 export PAGER=${PAGER:-less}
 474
 475 #v#
 476 export MAIL=${MAIL:-/var/mail/$USER}
 477
 478 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 479 export SHELL='/bin/zsh'
 480
 481 # color setup for ls:
 482 check_com -c dircolors && eval $(dircolors -b)
 483 # color setup for ls on OS X:
 484 isdarwin && export CLICOLOR=1
 485
 486 # do MacPorts setup on darwin
 487 if isdarwin && [[ -d /opt/local ]]; then
 488     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 489     # zshenv.
 490     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 491     MANPATH="/opt/local/share/man:$MANPATH"
 492 fi
 493 # do Fink setup on darwin
 494 isdarwin && xsource /sw/bin/init.sh
 495
 496 # load our function and completion directories
 497 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 498     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 499     if [[ ${fpath} == '/usr/share/grml/zsh/functions' ]] ; then
 500         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 501             zrcautoload ${func:t}
 502         done
 503     fi
 504 done
 505 unset fdir func
 506
 507 # support colors in less
 508 export LESS_TERMCAP_mb=$'\E[01;31m'
 509 export LESS_TERMCAP_md=$'\E[01;31m'
 510 export LESS_TERMCAP_me=$'\E[0m'
 511 export LESS_TERMCAP_se=$'\E[0m'
 512 export LESS_TERMCAP_so=$'\E[01;44;33m'
 513 export LESS_TERMCAP_ue=$'\E[0m'
 514 export LESS_TERMCAP_us=$'\E[01;32m'
 515
 516 MAILCHECK=30       # mailchecks
 517 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 518 watch=(notme root) # watch for everyone but me and root
 519
 520 # automatically remove duplicates from these arrays
 521 typeset -U path cdpath fpath manpath
 522
 523 # keybindings
 524 if [[ "$TERM" != emacs ]] ; then
 525     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 526     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 527     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 528     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 529     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 530     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 531     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 532     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 533     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 534     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 535     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 536     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 537     # ncurses stuff:
 538     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 539     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 540     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 541     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 542     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 543     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 544     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 545     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 546 fi
 547
 548 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 549 # use emacs style per default:
 550 bindkey -e
 551 # use vi style:
 552 # bindkey -v
 553
 554 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 555 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 556 beginning-or-end-of-somewhere() {
 557     local hno=$HISTNO
 558     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 559       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 560         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 561     else
 562         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 563         if (( HISTNO != hno )); then
 564             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 565         fi
 566     fi
 567 }
 568 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 569 zle -N end-of-somewhere beginning-or-end-of-somewhere
 570
 571
 572 #if [[ "$TERM" == screen ]] ; then
 573
 574 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 575 ## to beginning/end of buffer on second keypress
 576 ## and to beginning/end of history on (at most) the third keypress
 577 # terminator & non-debian xterm
 578 bindkey '\eOH' beginning-of-somewhere  # home
 579 bindkey '\eOF' end-of-somewhere        # end
 580 # freebsd console
 581 bindkey '\e[H' beginning-of-somewhere   # home
 582 bindkey '\e[F' end-of-somewhere         # end
 583 # xterm,gnome-terminal,quake,etc
 584 bindkey '^[[1~' beginning-of-somewhere  # home
 585 bindkey '^[[4~' end-of-somewhere        # end
 586 # if terminal type is set to 'rxvt':
 587 bindkey '\e[7~' beginning-of-somewhere  # home
 588 bindkey '\e[8~' end-of-somewhere        # end
 589 #fi
 590
 591 bindkey '\e[A'  up-line-or-search       # cursor up
 592 bindkey '\e[B'  down-line-or-search     # <ESC>-
 593
 594 ## alt-backspace is already the default for backwards-delete-word
 595 ## let's also set alt-delete for deleting current word (right of cursor)
 596 #k# Kill right-side word
 597 bindkey '^[[3~'   delete-word # Modeswitch
 598 bindkey '^[[3;3~' delete-word # Alt_L
 599
 600 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 601 bindkey "\e[5C" forward-word
 602 bindkey "\e[5D" backward-word
 603 bindkey "\e[1;5C" forward-word
 604 bindkey "\e[1;5D" backward-word
 605 ## the same for alt-left-arrow and alt-right-arrow
 606 bindkey '^[[1;3C' forward-word
 607 bindkey '^[[1;3D' backward-word
 608
 609 # Search backward in the history for a line beginning with the current
 610 # line up to the cursor and move the cursor to the end of the line then
 611 zle -N history-beginning-search-backward-end history-search-end
 612 zle -N history-beginning-search-forward-end  history-search-end
 613 #k# search history backward for entry beginning with typed text
 614 bindkey '^xp'   history-beginning-search-backward-end
 615 #k# search history forward for entry beginning with typed text
 616 bindkey '^xP'   history-beginning-search-forward-end
 617 #k# search history backward for entry beginning with typed text
 618 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 619 #k# search history forward for entry beginning with typed text
 620 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 621
 622 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 623 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 624
 625 # insert unicode character
 626 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 627 # See for example http://unicode.org/charts/ for unicode characters code
 628 zrcautoload insert-unicode-char
 629 zle -N insert-unicode-char
 630 #k# Insert Unicode character
 631 bindkey '^Xi' insert-unicode-char
 632
 633 #m# k Shift-tab Perform backwards menu completion
 634 if [[ -n "$terminfo[kcbt]" ]]; then
 635     bindkey "$terminfo[kcbt]" reverse-menu-complete
 636 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 637     bindkey "$terminfo[cbt]"  reverse-menu-complete
 638 fi
 639
 640 ## toggle the ,. abbreviation feature on/off
 641 # NOABBREVIATION: default abbreviation-state
 642 #                 0 - enabled (default)
 643 #                 1 - disabled
 644 NOABBREVIATION=${NOABBREVIATION:-0}
 645
 646 grml_toggle_abbrev() {
 647     if (( ${NOABBREVIATION} > 0 )) ; then
 648         NOABBREVIATION=0
 649     else
 650         NOABBREVIATION=1
 651     fi
 652 }
 653
 654 zle -N grml_toggle_abbrev
 655 bindkey '^xA' grml_toggle_abbrev
 656
 657 # add a command line to the shells history without executing it
 658 commit-to-history() {
 659     print -s ${(z)BUFFER}
 660     zle send-break
 661 }
 662 zle -N commit-to-history
 663 bindkey "^x^h" commit-to-history
 664
 665 # only slash should be considered as a word separator:
 666 slash-backward-kill-word() {
 667     local WORDCHARS="${WORDCHARS:s@/@}"
 668     # zle backward-word
 669     zle backward-kill-word
 670 }
 671 zle -N slash-backward-kill-word
 672
 673 #k# Kill left-side word or everything up to next slash
 674 bindkey '\ev' slash-backward-kill-word
 675 #k# Kill left-side word or everything up to next slash
 676 bindkey '\e^h' slash-backward-kill-word
 677 #k# Kill left-side word or everything up to next slash
 678 bindkey '\e^?' slash-backward-kill-word
 679
 680 # use the new *-pattern-* widgets for incremental history search
 681 if is439 ; then
 682     bindkey '^r' history-incremental-pattern-search-backward
 683     bindkey '^s' history-incremental-pattern-search-forward
 684 fi
 685
 686 # a generic accept-line wrapper
 687
 688 # This widget can prevent unwanted autocorrections from command-name
 689 # to _command-name, rehash automatically on enter and call any number
 690 # of builtin and user-defined widgets in different contexts.
 691 #
 692 # For a broader description, see:
 693 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 694 #
 695 # The code is imported from the file 'zsh/functions/accept-line' from
 696 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 697 # distributed under the same terms as zsh itself.
 698
 699 # A newly added command will may not be found or will cause false
 700 # correction attempts, if you got auto-correction set. By setting the
 701 # following style, we force accept-line() to rehash, if it cannot
 702 # find the first word on the command line in the $command[] hash.
 703 zstyle ':acceptline:*' rehash true
 704
 705 function Accept-Line() {
 706     setopt localoptions noksharrays
 707     local -a subs
 708     local -xi aldone
 709     local sub
 710     local alcontext=${1:-$alcontext}
 711
 712     zstyle -a ":acceptline:${alcontext}" actions subs
 713
 714     (( ${#subs} < 1 )) && return 0
 715
 716     (( aldone = 0 ))
 717     for sub in ${subs} ; do
 718         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 719         zle ${sub}
 720
 721         (( aldone > 0 )) && break
 722     done
 723 }
 724
 725 function Accept-Line-getdefault() {
 726     emulate -L zsh
 727     local default_action
 728
 729     zstyle -s ":acceptline:${alcontext}" default_action default_action
 730     case ${default_action} in
 731         ((accept-line|))
 732             printf ".accept-line"
 733             ;;
 734         (*)
 735             printf ${default_action}
 736             ;;
 737     esac
 738 }
 739
 740 function Accept-Line-HandleContext() {
 741     zle Accept-Line
 742
 743     default_action=$(Accept-Line-getdefault)
 744     zstyle -T ":acceptline:${alcontext}" call_default \
 745         && zle ${default_action}
 746 }
 747
 748 function accept-line() {
 749     setopt localoptions noksharrays
 750     local -ax cmdline
 751     local -x alcontext
 752     local buf com fname format msg default_action
 753
 754     alcontext='default'
 755     buf="${BUFFER}"
 756     cmdline=(${(z)BUFFER})
 757     com="${cmdline[1]}"
 758     fname="_${com}"
 759
 760     Accept-Line 'preprocess'
 761
 762     zstyle -t ":acceptline:${alcontext}" rehash \
 763         && [[ -z ${commands[$com]} ]]           \
 764         && rehash
 765
 766     if    [[ -n ${com}               ]] \
 767        && [[ -n ${reswords[(r)$com]} ]] \
 768        || [[ -n ${aliases[$com]}     ]] \
 769        || [[ -n ${functions[$com]}   ]] \
 770        || [[ -n ${builtins[$com]}    ]] \
 771        || [[ -n ${commands[$com]}    ]] ; then
 772
 773         # there is something sensible to execute, just do it.
 774         alcontext='normal'
 775         Accept-Line-HandleContext
 776
 777         return
 778     fi
 779
 780     if    [[ -o correct              ]] \
 781        || [[ -o correctall           ]] \
 782        && [[ -n ${functions[$fname]} ]] ; then
 783
 784         # nothing there to execute but there is a function called
 785         # _command_name; a completion widget. Makes no sense to
 786         # call it on the commandline, but the correct{,all} options
 787         # will ask for it nevertheless, so warn the user.
 788         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 789             # Okay, we warned the user before, he called us again,
 790             # so have it his way.
 791             alcontext='force'
 792             Accept-Line-HandleContext
 793
 794             return
 795         fi
 796
 797         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 798             alcontext='normal'
 799             Accept-Line-HandleContext
 800         else
 801             # prepare warning message for the user, configurable via zstyle.
 802             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 803
 804             if [[ -z ${msg} ]] ; then
 805                 msg="%c will not execute and completion %f exists."
 806             fi
 807
 808             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 809
 810             zle -M -- "${msg}"
 811         fi
 812         return
 813     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 814         # If we are here, the commandline contains something that is not
 815         # executable, which is neither subject to _command_name correction
 816         # and is not empty. might be a variable assignment
 817         alcontext='misc'
 818         Accept-Line-HandleContext
 819
 820         return
 821     fi
 822
 823     # If we got this far, the commandline only contains whitespace, or is empty.
 824     alcontext='empty'
 825     Accept-Line-HandleContext
 826 }
 827
 828 zle -N accept-line
 829 zle -N Accept-Line
 830 zle -N Accept-Line-HandleContext
 831
 832 # power completion - abbreviation expansion
 833 # power completion / abbreviation expansion / buffer expansion
 834 # see http://zshwiki.org/home/examples/zleiab for details
 835 # less risky than the global aliases but powerful as well
 836 # just type the abbreviation key and afterwards ',.' to expand it
 837 declare -A abk
 838 setopt extendedglob
 839 setopt interactivecomments
 840 abk=(
 841 #   key   # value                  (#d additional doc string)
 842 #A# start
 843     '...'  '../..'
 844     '....' '../../..'
 845     'BG'   '& exit'
 846     'C'    '| wc -l'
 847     'G'    '|& grep --color=auto '
 848     'H'    '| head'
 849     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 850     'L'    '| less'
 851     'LL'   '|& less -r'
 852     'M'    '| most'
 853     'N'    '&>/dev/null'           #d (No Output)
 854     'R'    '| tr A-z N-za-m'       #d (ROT13)
 855     'SL'   '| sort | less'
 856     'S'    '| sort -u'
 857     'T'    '| tail'
 858     'V'    '|& vim -'
 859 #A# end
 860     'co'   './configure && make && sudo make install'
 861 )
 862
 863 zleiab() {
 864     emulate -L zsh
 865     setopt extendedglob
 866     local MATCH
 867
 868     if (( NOABBREVIATION > 0 )) ; then
 869         LBUFFER="${LBUFFER},."
 870         return 0
 871     fi
 872
 873     matched_chars='[.-|_a-zA-Z0-9]#'
 874     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 875     LBUFFER+=${abk[$MATCH]:-$MATCH}
 876 }
 877
 878 zle -N zleiab
 879 bindkey ",." zleiab
 880
 881 # autoloading
 882 zrcautoload zmv    # who needs mmv or rename?
 883 zrcautoload history-search-end
 884
 885 # we don't want to quote/espace URLs on our own...
 886 # if autoload -U url-quote-magic ; then
 887 #    zle -N self-insert url-quote-magic
 888 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 889 # else
 890 #    print 'Notice: no url-quote-magic available :('
 891 # fi
 892 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 893
 894 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 895 alias run-help >&/dev/null && unalias run-help
 896 for rh in run-help{,-git,-svk,-svn}; do
 897     zrcautoload $rh
 898 done; unset rh
 899
 900 # completion system
 901 if zrcautoload compinit ; then
 902     compinit || print 'Notice: no compinit available :('
 903 else
 904     print 'Notice: no compinit available :('
 905     function zstyle { }
 906     function compdef { }
 907 fi
 908
 909 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 910
 911 is4 && \
 912 for mod in complist deltochar mathfunc ; do
 913     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 914 done
 915
 916 # autoload zsh modules when they are referenced
 917 if is4 ; then
 918     zmodload -a  zsh/stat    zstat
 919     zmodload -a  zsh/zpty    zpty
 920     zmodload -ap zsh/mapfile mapfile
 921 fi
 922
 923 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 924     #k# Insert files and test globbing
 925     bindkey "^Xf" insert-files # C-x-f
 926 fi
 927
 928 bindkey ' '   magic-space    # also do history expansion on space
 929 #k# Trigger menu-complete
 930 bindkey '\ei' menu-complete  # menu completion via esc-i
 931
 932 # press esc-e for editing command line in $EDITOR or $VISUAL
 933 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 934     #k# Edit the current line in \kbd{\$EDITOR}
 935     bindkey '\ee' edit-command-line
 936 fi
 937
 938 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 939     #k# menu selection: pick item but stay in the menu
 940     bindkey -M menuselect '\e^M' accept-and-menu-complete
 941     # also use + and INSERT since it's easier to press repeatedly
 942     bindkey -M menuselect "+" accept-and-menu-complete
 943     bindkey -M menuselect "^[[2~" accept-and-menu-complete
 944
 945     # accept a completion and try to complete again by using menu
 946     # completion; very useful with completing directories
 947     # by using 'undo' one's got a simple file browser
 948     bindkey -M menuselect '^o' accept-and-infer-next-history
 949 fi
 950
 951 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 952 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
 953 zle -N insert-datestamp
 954
 955 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 956 bindkey '^Ed' insert-datestamp
 957
 958 # press esc-m for inserting last typed word again (thanks to caphuso!)
 959 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 960 zle -N insert-last-typed-word;
 961
 962 #k# Insert last typed word
 963 bindkey "\em" insert-last-typed-word
 964
 965 function grml-zsh-fg() {
 966   if (( ${#jobstates} )); then
 967     zle .push-input
 968     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
 969     BUFFER="${BUFFER}fg"
 970     zle .accept-line
 971   else
 972     zle -M 'No background jobs. Doing nothing.'
 973   fi
 974 }
 975 zle -N grml-zsh-fg
 976 #k# A smart shortcut for \kbd{fg<enter>}
 977 bindkey '^z' grml-zsh-fg
 978
 979 # run command line as user root via sudo:
 980 sudo-command-line() {
 981     [[ -z $BUFFER ]] && zle up-history
 982     if [[ $BUFFER != sudo\ * ]]; then
 983         BUFFER="sudo $BUFFER"
 984         CURSOR=$(( CURSOR+5 ))
 985     fi
 986 }
 987 zle -N sudo-command-line
 988
 989 #k# prepend the current command with "sudo"
 990 bindkey "^Os" sudo-command-line
 991
 992 ### jump behind the first word on the cmdline.
 993 ### useful to add options.
 994 function jump_after_first_word() {
 995     local words
 996     words=(${(z)BUFFER})
 997
 998     if (( ${#words} <= 1 )) ; then
 999         CURSOR=${#BUFFER}
1000     else
1001         CURSOR=${#${words[1]}}
1002     fi
1003 }
1004 zle -N jump_after_first_word
1005 #k# jump to after first word (for adding options)
1006 bindkey '^x1' jump_after_first_word
1007
1008 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1009 zle -C hist-complete complete-word _generic
1010 zstyle ':completion:hist-complete:*' completer _history
1011 #k# complete word from history with menu
1012 bindkey "^X^X" hist-complete
1013
1014 ## complete word from currently visible Screen or Tmux buffer.
1015 if check_com -c screen || check_com -c tmux; then
1016     _complete_screen_display() {
1017         [[ "$TERM" != "screen" ]] && return 1
1018
1019         local TMPFILE=$(mktemp)
1020         local -U -a _screen_display_wordlist
1021         trap "rm -f $TMPFILE" EXIT
1022
1023         # fill array with contents from screen hardcopy
1024         if ((${+TMUX})); then
1025             #works, but crashes tmux below version 1.4
1026             #luckily tmux -V option to ask for version, was also added in 1.4
1027             tmux -V &>/dev/null || return
1028             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1029         else
1030             screen -X hardcopy $TMPFILE
1031             #screen sucks, it dumps in latin1, apparently always. so recode it to system charset
1032             check_com recode && recode latin1 $TMPFILE
1033         fi
1034         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1035         # remove PREFIX to be completed from that array
1036         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1037         compadd -a _screen_display_wordlist
1038     }
1039     #k# complete word from currently visible GNU screen buffer
1040     bindkey -r "^XS"
1041     compdef -k _complete_screen_display complete-word '^XS'
1042 fi
1043
1044 # history
1045
1046 ZSHDIR=$HOME/.zsh
1047
1048 #v#
1049 HISTFILE=$HOME/.zsh_history
1050 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1051 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1052
1053 # dirstack handling
1054
1055 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1056 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1057
1058 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1059     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1060     # "cd -" won't work after login by just setting $OLDPWD, so
1061     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1062 fi
1063
1064 chpwd() {
1065     local -ax my_stack
1066     my_stack=( ${PWD} ${dirstack} )
1067     if is42 ; then
1068         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1069     else
1070         uprint my_stack >! ${DIRSTACKFILE}
1071     fi
1072 }
1073
1074 # directory based profiles
1075
1076 if is433 ; then
1077
1078 CHPWD_PROFILE='default'
1079 function chpwd_profiles() {
1080     # Say you want certain settings to be active in certain directories.
1081     # This is what you want.
1082     #
1083     # zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1084     # zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1085     #
1086     # When that's done and you enter a directory that matches the pattern
1087     # in the third part of the context, a function called chpwd_profile_grml,
1088     # for example, is called (if it exists).
1089     #
1090     # If no pattern matches (read: no profile is detected) the profile is
1091     # set to 'default', which means chpwd_profile_default is attempted to
1092     # be called.
1093     #
1094     # A word about the context (the ':chpwd:profiles:*' stuff in the zstyle
1095     # command) which is used: The third part in the context is matched against
1096     # ${PWD}. That's why using a pattern such as /foo/bar(|/|/*) makes sense.
1097     # Because that way the profile is detected for all these values of ${PWD}:
1098     #   /foo/bar
1099     #   /foo/bar/
1100     #   /foo/bar/baz
1101     # So, if you want to make double damn sure a profile works in /foo/bar
1102     # and everywhere deeper in that tree, just use (|/|/*) and be happy.
1103     #
1104     # The name of the detected profile will be available in a variable called
1105     # 'profile' in your functions. You don't need to do anything, it'll just
1106     # be there.
1107     #
1108     # Then there is the parameter $CHPWD_PROFILE is set to the profile, that
1109     # was is currently active. That way you can avoid running code for a
1110     # profile that is already active, by running code such as the following
1111     # at the start of your function:
1112     #
1113     # function chpwd_profile_grml() {
1114     #     [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1115     #   ...
1116     # }
1117     #
1118     # The initial value for $CHPWD_PROFILE is 'default'.
1119     #
1120     # Version requirement:
1121     #   This feature requires zsh 4.3.3 or newer.
1122     #   If you use this feature and need to know whether it is active in your
1123     #   current shell, there are several ways to do that. Here are two simple
1124     #   ways:
1125     #
1126     #   a) If knowing if the profiles feature is active when zsh starts is
1127     #      good enough for you, you can put the following snippet into your
1128     #      .zshrc.local:
1129     #
1130     #   (( ${+functions[chpwd_profiles]} )) && print "directory profiles active"
1131     #
1132     #   b) If that is not good enough, and you would prefer to be notified
1133     #      whenever a profile changes, you can solve that by making sure you
1134     #      start *every* profile function you create like this:
1135     #
1136     #   function chpwd_profile_myprofilename() {
1137     #       [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1138     #       print "chpwd(): Switching to profile: $profile"
1139     #     ...
1140     #   }
1141     #
1142     #      That makes sure you only get notified if a profile is *changed*,
1143     #      not everytime you change directory, which would probably piss
1144     #      you off fairly quickly. :-)
1145     #
1146     # There you go. Now have fun with that.
1147     local -x profile
1148
1149     zstyle -s ":chpwd:profiles:${PWD}" profile profile || profile='default'
1150     if (( ${+functions[chpwd_profile_$profile]} )) ; then
1151         chpwd_profile_${profile}
1152     fi
1153
1154     CHPWD_PROFILE="${profile}"
1155     return 0
1156 }
1157 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1158
1159 fi # is433
1160
1161 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1162 if [[ $BATTERY -gt 0 ]] ; then
1163     if ! check_com -c acpi ; then
1164         BATTERY=0
1165     fi
1166 fi
1167
1168 battery() {
1169 if [[ $BATTERY -gt 0 ]] ; then
1170     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1171     if [[ -z "$PERCENT" ]] ; then
1172         PERCENT='acpi not present'
1173     else
1174         if [[ "$PERCENT" -lt 20 ]] ; then
1175             PERCENT="warning: ${PERCENT}%%"
1176         else
1177             PERCENT="${PERCENT}%%"
1178         fi
1179     fi
1180 fi
1181 }
1182 # set colors for use in prompts
1183 if zrcautoload colors && colors 2>/dev/null ; then
1184     BLUE="%{${fg[blue]}%}"
1185     RED="%{${fg_bold[red]}%}"
1186     GREEN="%{${fg[green]}%}"
1187     CYAN="%{${fg[cyan]}%}"
1188     MAGENTA="%{${fg[magenta]}%}"
1189     YELLOW="%{${fg[yellow]}%}"
1190     WHITE="%{${fg[white]}%}"
1191     NO_COLOUR="%{${reset_color}%}"
1192 else
1193     BLUE=$'%{\e[1;34m%}'
1194     RED=$'%{\e[1;31m%}'
1195     GREEN=$'%{\e[1;32m%}'
1196     CYAN=$'%{\e[1;36m%}'
1197     WHITE=$'%{\e[1;37m%}'
1198     MAGENTA=$'%{\e[1;35m%}'
1199     YELLOW=$'%{\e[1;33m%}'
1200     NO_COLOUR=$'%{\e[0m%}'
1201 fi
1202
1203 # gather version control information for inclusion in a prompt
1204
1205 if zrcautoload vcs_info; then
1206     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1207     # function, which can cause a lot of trouble with our directory-based
1208     # profiles. So:
1209     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1210         function VCS_INFO_realpath () {
1211             setopt localoptions NO_shwordsplit chaselinks
1212             ( builtin cd -q $1 2> /dev/null && pwd; )
1213         }
1214     fi
1215
1216     zstyle ':vcs_info:*' max-exports 2
1217
1218     if [[ -o restricted ]]; then
1219         zstyle ':vcs_info:*' enable NONE
1220     fi
1221 fi
1222
1223 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1224 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1225 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1226 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1227 #       to $vcs_info_msg_N_ as soon as we use the included version.
1228 if [[ "$TERM" == dumb ]] ; then
1229     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1230     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1231 else
1232     # these are the same, just with a lot of colours:
1233     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
1234                                        "zsh: %r"
1235     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
1236                                        "zsh: %r"
1237     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1238 fi
1239
1240 # command not found handling
1241
1242 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1243 function command_not_found_handler() {
1244     emulate -L zsh
1245     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1246         ${GRML_ZSH_CNF_HANDLER} $1
1247     fi
1248     return 1
1249 }
1250
1251 # set prompt
1252 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1253     promptinit # people should be able to use their favourite prompt
1254 else
1255     print 'Notice: no promptinit available :('
1256 fi
1257
1258 setopt prompt_subst
1259
1260 # make sure to use right prompt only when not running a command
1261 is41 && setopt transient_rprompt
1262
1263
1264 function ESC_print () {
1265     info_print $'\ek' $'\e\\' "$@"
1266 }
1267 function set_title () {
1268     info_print  $'\e]0;' $'\a' "$@"
1269 }
1270
1271 function info_print () {
1272     local esc_begin esc_end
1273     esc_begin="$1"
1274     esc_end="$2"
1275     shift 2
1276     printf '%s' ${esc_begin}
1277     printf '%s' "$*"
1278     printf '%s' "${esc_end}"
1279 }
1280
1281 # TODO: revise all these NO* variables and especially their documentation
1282 #       in zsh-help() below.
1283 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1284     [[ $NOPRECMD -gt 0 ]] && return 0
1285     # update VCS information
1286     (( ${+functions[vcs_info]} )) && vcs_info
1287
1288     if [[ $TERM == screen* ]] ; then
1289         if [[ -n ${vcs_info_msg_1_} ]] ; then
1290             ESC_print ${vcs_info_msg_1_}
1291         else
1292             ESC_print "zsh"
1293         fi
1294     fi
1295     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1296     if [[ ${DONTSETRPROMPT:-} -eq 0 ]] ; then
1297         if [[ $BATTERY -gt 0 ]] ; then
1298             # update battery (dropped into $PERCENT) information
1299             battery
1300             RPROMPT="%(?..:() ${PERCENT}"
1301         else
1302             RPROMPT="%(?..:() "
1303         fi
1304     fi
1305     # adjust title of xterm
1306     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1307     [[ ${NOTITLE:-} -gt 0 ]] && return 0
1308     case $TERM in
1309         (xterm*|rxvt*)
1310             set_title ${(%):-"%n@%m: %~"}
1311             ;;
1312     esac
1313 }
1314
1315 # preexec() => a function running before every command
1316 is4 && [[ $NOPRECMD -eq 0 ]] && \
1317 preexec () {
1318     [[ $NOPRECMD -gt 0 ]] && return 0
1319 # set hostname if not running on host with name 'grml'
1320     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1321        NAME="@$HOSTNAME"
1322     fi
1323 # get the name of the program currently running and hostname of local machine
1324 # set screen window title if running in a screen
1325     if [[ "$TERM" == screen* ]] ; then
1326         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1327         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1328         ESC_print ${CMD}
1329     fi
1330 # adjust title of xterm
1331     [[ ${NOTITLE} -gt 0 ]] && return 0
1332     case $TERM in
1333         (xterm*|rxvt*)
1334             set_title "${(%):-"%n@%m:"}" "$1"
1335             ;;
1336     esac
1337 }
1338
1339 EXITCODE="%(?..%?%1v )"
1340 PS2='\`%_> '      # secondary prompt, printed when the shell needs more information to complete a command.
1341 PS3='?# '         # selection prompt used within a select loop.
1342 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1343
1344 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1345 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1346     debian_chroot=$(cat /etc/debian_chroot)
1347 fi
1348
1349 # don't use colors on dumb terminals (like emacs):
1350 if [[ "$TERM" == dumb ]] ; then
1351     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
1352 else
1353     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
1354     # set variable identifying the chroot you work in (used in the prompt below)
1355     if [[ $GRMLPROMPT -gt 0 ]] ; then
1356         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1357 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1358     else
1359         # This assembles the primary prompt string
1360         if (( EUID != 0 )); then
1361             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1362         else
1363             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1364         fi
1365     fi
1366 fi
1367
1368 PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
1369
1370 # if we are inside a grml-chroot set a specific prompt theme
1371 if [[ -n "$GRML_CHROOT" ]] ; then
1372     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1373 fi
1374
1375 # 'hash' some often used directories
1376 #d# start
1377 hash -d deb=/var/cache/apt/archives
1378 hash -d doc=/usr/share/doc
1379 hash -d linux=/lib/modules/$(command uname -r)/build/
1380 hash -d log=/var/log
1381 hash -d slog=/var/log/syslog
1382 hash -d src=/usr/src
1383 hash -d templ=/usr/share/doc/grml-templates
1384 hash -d tt=/usr/share/doc/texttools-doc
1385 hash -d www=/var/www
1386 #d# end
1387
1388 # some aliases
1389 if check_com -c screen ; then
1390     if [[ $UID -eq 0 ]] ; then
1391         [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
1392     elif [[ -r $HOME/.screenrc ]] ; then
1393         alias screen="${commands[screen]} -c $HOME/.screenrc"
1394     else
1395         if [[ -r /etc/grml/screenrc_grml ]]; then
1396             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1397         else
1398             [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
1399         fi
1400     fi
1401 fi
1402
1403 # do we have GNU ls with color-support?
1404 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
1405     #a1# execute \kbd{@a@}:\quad ls with colors
1406     alias ls='ls -b -CF --color=auto'
1407     #a1# execute \kbd{@a@}:\quad list all files, with colors
1408     alias la='ls -la --color=auto'
1409     #a1# long colored list, without dotfiles (@a@)
1410     alias ll='ls -l --color=auto'
1411     #a1# long colored list, human readable sizes (@a@)
1412     alias lh='ls -hAl --color=auto'
1413     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1414     alias l='ls -lF --color=auto'
1415 else
1416     alias ls='ls -b -CF'
1417     alias la='ls -la'
1418     alias ll='ls -l'
1419     alias lh='ls -hAl'
1420     alias l='ls -lF'
1421 fi
1422
1423 alias mdstat='cat /proc/mdstat'
1424 alias ...='cd ../../'
1425
1426 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1427 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1428     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1429 fi
1430
1431 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1432 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1433 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1434
1435 # make sure it is not assigned yet
1436 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1437 utf2iso() {
1438     if isutfenv ; then
1439         for ENV in $(env | command grep -i '.utf') ; do
1440             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1441         done
1442     fi
1443 }
1444
1445 # make sure it is not assigned yet
1446 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1447 iso2utf() {
1448     if ! isutfenv ; then
1449         for ENV in $(env | command grep -i '\.iso') ; do
1450             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1451         done
1452     fi
1453 }
1454
1455 # especially for roadwarriors using GNU screen and ssh:
1456 if ! check_com asc &>/dev/null ; then
1457   asc() { autossh -t "$@" 'screen -RdU' }
1458   compdef asc=ssh
1459 fi
1460
1461 #f1# Hints for the use of zsh on grml
1462 zsh-help() {
1463     print "$bg[white]$fg[black]
1464 zsh-help - hints for use of zsh on grml
1465 =======================================$reset_color"
1466
1467     print '
1468 Main configuration of zsh happens in /etc/zsh/zshrc.
1469 That file is part of the package grml-etc-core, if you want to
1470 use them on a non-grml-system just get the tar.gz from
1471 http://deb.grml.org/ or (preferably) get it from the git repository:
1472
1473   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1474
1475 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1476 The file is still there, but it is empty for backwards compatibility.
1477
1478 For your own changes use these two files:
1479     $HOME/.zshrc.pre
1480     $HOME/.zshrc.local
1481
1482 The former is sourced very early in our zshrc, the latter is sourced
1483 very lately.
1484
1485 System wide configuration without touching configuration files of grml
1486 can take place in /etc/zsh/zshrc.local.
1487
1488 Normally, the root user (EUID == 0) does not get the whole grml setup.
1489 If you want to force the whole setup for that user, too, set
1490 GRML_ALWAYS_LOAD_ALL=1 in .zshrc.pre in root'\''s home directory.
1491
1492 For information regarding zsh start at http://grml.org/zsh/
1493
1494 Take a look at grml'\''s zsh refcard:
1495 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1496
1497 Check out the main zsh refcard:
1498 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1499
1500 And of course visit the zsh-lovers:
1501 % man zsh-lovers
1502
1503 You can adjust some options through environment variables when
1504 invoking zsh without having to edit configuration files.
1505 Basically meant for bash users who are not used to the power of
1506 the zsh yet. :)
1507
1508   "NOCOR=1    zsh" => deactivate automatic correction
1509   "NOMENU=1   zsh" => do not use auto menu completion (note: use ctrl-d for completion instead!)
1510   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1511   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1512                       preexec() and precmd() completely
1513   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1514   "COMMAND_NOT_FOUND=1 zsh"
1515                    => Enable a handler if an external command was not found
1516                       The command called in the handler can be altered by setting
1517                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1518                       "/usr/share/command-not-found/command-not-found"
1519
1520 A value greater than 0 is enables a feature; a value equal to zero
1521 disables it. If you like one or the other of these settings, you can
1522 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1523 zshrc.'
1524
1525     print "
1526 $bg[white]$fg[black]
1527 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1528 Enjoy your grml system with the zsh!$reset_color"
1529 }
1530
1531 # debian stuff
1532 if [[ -r /etc/debian_version ]] ; then
1533     #a3# Execute \kbd{apt-cache search}
1534     alias acs='apt-cache search'
1535     #a3# Execute \kbd{apt-cache show}
1536     alias acsh='apt-cache show'
1537     #a3# Execute \kbd{apt-cache policy}
1538     alias acp='apt-cache policy'
1539     #a3# Execute \kbd{apt-get dist-upgrade}
1540     salias adg="apt-get dist-upgrade"
1541     #a3# Execute \kbd{apt-get install}
1542     salias agi="apt-get install"
1543     #a3# Execute \kbd{aptitude install}
1544     salias ati="aptitude install"
1545     #a3# Execute \kbd{apt-get upgrade}
1546     salias ag="apt-get upgrade"
1547     #a3# Execute \kbd{apt-get update}
1548     salias au="apt-get update"
1549     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1550     salias -a up="aptitude update ; aptitude safe-upgrade"
1551     #a3# Execute \kbd{dpkg-buildpackage}
1552     alias dbp='dpkg-buildpackage'
1553     #a3# Execute \kbd{grep-excuses}
1554     alias ge='grep-excuses'
1555
1556     # get a root shell as normal user in live-cd mode:
1557     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1558        alias su="sudo su"
1559      fi
1560
1561     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1562     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1563     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1564     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1565 fi
1566
1567 # sort installed Debian-packages by size
1568 if check_com -c dpkg-query ; then
1569     #a3# List installed Debian-packages sorted by size
1570     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1571 fi
1572
1573 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1574 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1575     if check_com -c wodim; then
1576         cdrecord() {
1577             cat <<EOMESS
1578 cdrecord is not provided under its original name by Debian anymore.
1579 See #377109 in the BTS of Debian for more details.
1580
1581 Please use the wodim binary instead
1582 EOMESS
1583             return 1
1584         }
1585     fi
1586 fi
1587
1588 # Use hard limits, except for a smaller stack and no core dumps
1589 unlimit
1590 is425 && limit stack 8192
1591 isgrmlcd && limit core 0 # important for a live-cd-system
1592 limit -s
1593
1594 # completion system
1595
1596 # called later (via is4 && grmlcomp)
1597 # note: use 'zstyle' for getting current settings
1598 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
1599 grmlcomp() {
1600     # TODO: This could use some additional information
1601
1602     # allow one error for every three characters typed in approximate completer
1603     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1604
1605     # don't complete backup files as executables
1606     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1607
1608     # start menu completion only if it could find no unambiguous initial string
1609     zstyle ':completion:*:correct:*'       insert-unambiguous true
1610     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1611     zstyle ':completion:*:correct:*'       original true
1612
1613     # activate color-completion
1614     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1615
1616     # format on completion
1617     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1618
1619     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1620     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1621
1622     # insert all expansions for expand completer
1623     zstyle ':completion:*:expand:*'        tag-order all-expansions
1624     zstyle ':completion:*:history-words'   list false
1625
1626     # activate menu
1627     zstyle ':completion:*:history-words'   menu yes
1628
1629     # ignore duplicate entries
1630     zstyle ':completion:*:history-words'   remove-all-dups yes
1631     zstyle ':completion:*:history-words'   stop yes
1632
1633     # match uppercase from lowercase
1634     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1635
1636     # separate matches into groups
1637     zstyle ':completion:*:matches'         group 'yes'
1638     zstyle ':completion:*'                 group-name ''
1639
1640     if [[ "$NOMENU" -eq 0 ]] ; then
1641         # if there are more than 5 options allow selecting from a menu
1642         zstyle ':completion:*'               menu select=5
1643     else
1644         # don't use any menus at all
1645         setopt no_auto_menu
1646     fi
1647
1648     zstyle ':completion:*:messages'        format '%d'
1649     zstyle ':completion:*:options'         auto-description '%d'
1650
1651     # describe options in full
1652     zstyle ':completion:*:options'         description 'yes'
1653
1654     # on processes completion complete all user processes
1655     zstyle ':completion:*:processes'       command 'ps -au$USER'
1656
1657     # offer indexes before parameters in subscripts
1658     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1659
1660     # provide verbose completion information
1661     zstyle ':completion:*'                 verbose true
1662
1663     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1664     # for commands (read: 1st word in the line) that it will list for the user
1665     # to choose from. The following disables that, because it's not exactly fast.
1666     zstyle ':completion:*:-command-:*:'    verbose false
1667
1668     # set format for warnings
1669     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1670
1671     # define files to ignore for zcompile
1672     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1673     zstyle ':completion:correct:'          prompt 'correct to: %e'
1674
1675     # Ignore completion functions for commands you don't have:
1676     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1677
1678     # Provide more processes in completion of programs like killall:
1679     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1680
1681     # complete manual by their section
1682     zstyle ':completion:*:manuals'    separate-sections true
1683     zstyle ':completion:*:manuals.*'  insert-sections   true
1684     zstyle ':completion:*:man:*'      menu yes select
1685
1686     # provide .. as a completion
1687     zstyle ':completion:*' special-dirs ..
1688
1689     # run rehash on completion so new installed program are found automatically:
1690     _force_rehash() {
1691         (( CURRENT == 1 )) && rehash
1692         return 1
1693     }
1694
1695     ## correction
1696     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1697     if [[ "$NOCOR" -gt 0 ]] ; then
1698         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1699         setopt nocorrect
1700     else
1701         # try to be smart about when to use what completer...
1702         setopt correct
1703         zstyle -e ':completion:*' completer '
1704             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1705                 _last_try="$HISTNO$BUFFER$CURSOR"
1706                 reply=(_complete _match _ignored _prefix _files)
1707             else
1708                 if [[ $words[1] == (rm|mv) ]] ; then
1709                     reply=(_complete _files)
1710                 else
1711                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1712                 fi
1713             fi'
1714     fi
1715
1716     # command for process lists, the local web server details and host completion
1717     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1718
1719     # caching
1720     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1721                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1722
1723     # host completion
1724     if is42 ; then
1725         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1726         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1727     else
1728         _ssh_hosts=()
1729         _etc_hosts=()
1730     fi
1731     hosts=(
1732         $(hostname)
1733         "$_ssh_hosts[@]"
1734         "$_etc_hosts[@]"
1735         grml.org
1736         localhost
1737     )
1738     zstyle ':completion:*:hosts' hosts $hosts
1739     # TODO: so, why is this here?
1740     #  zstyle '*' hosts $hosts
1741
1742     # use generic completion system for programs not yet defined; (_gnu_generic works
1743     # with commands that provide a --help option with "standard" gnu-like output.)
1744     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
1745                    pal stow tail uname ; do
1746         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
1747     done; unset compcom
1748
1749     # see upgrade function in this file
1750     compdef _hosts upgrade
1751 }
1752
1753 # grmlstuff
1754 grmlstuff() {
1755 # people should use 'grml-x'!
1756     if check_com -c 915resolution; then
1757         855resolution() {
1758             echo "Please use 915resolution as resolution modifying tool for Intel \
1759 graphic chipset."
1760             return -1
1761         }
1762     fi
1763
1764     #a1# Output version of running grml
1765     alias grml-version='cat /etc/grml_version'
1766
1767     if check_com -c rebuildfstab ; then
1768         #a1# Rebuild /etc/fstab
1769         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1770     fi
1771
1772     if check_com -c grml-debootstrap ; then
1773         debian2hd() {
1774             echo "Installing debian to harddisk is possible by using grml-debootstrap."
1775             return 1
1776         }
1777     fi
1778 }
1779
1780 # now run the functions
1781 isgrml && checkhome
1782 is4    && isgrml    && grmlstuff
1783 is4    && grmlcomp
1784
1785 # keephack
1786 is4 && xsource "/etc/zsh/keephack"
1787
1788 # wonderful idea of using "e" glob qualifier by Peter Stephenson
1789 # You use it as follows:
1790 # $ NTREF=/reference/file
1791 # $ ls -l *(e:nt:)
1792 # This lists all the files in the current directory newer than the reference file.
1793 # You can also specify the reference file inline; note quotes:
1794 # $ ls -l *(e:'nt ~/.zshenv':)
1795 is4 && nt() {
1796     if [[ -n $1 ]] ; then
1797         local NTREF=${~1}
1798     fi
1799     [[ $REPLY -nt $NTREF ]]
1800 }
1801
1802 # shell functions
1803
1804 #f1# Reload an autoloadable function
1805 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1806 compdef _functions freload
1807
1808 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1809 sll() {
1810     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1811     for file in "$@" ; do
1812         while [[ -h "$file" ]] ; do
1813             ls -l $file
1814             file=$(readlink "$file")
1815         done
1816     done
1817 }
1818
1819 # TODO: Is it supported to use pager settings like this?
1820 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
1821 # with respect to wordsplitting. (ie. ${=PAGER})
1822 if check_com -c $PAGER ; then
1823     #f1# View Debian's changelog of a given package
1824     dchange() {
1825         emulate -L zsh
1826         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
1827             $PAGER /usr/share/doc/$1/changelog.Debian.gz
1828         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1829             $PAGER /usr/share/doc/$1/changelog.gz
1830         else
1831             if check_com -c aptitude ; then
1832                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1833                 if isgrml ; then
1834                     aptitude -t unstable changelog $1
1835                 else
1836                     aptitude changelog $1
1837                 fi
1838             else
1839                 echo "No changelog for package $1 found, sorry."
1840                 return 1
1841             fi
1842         fi
1843     }
1844     _dchange() { _files -W /usr/share/doc -/ }
1845     compdef _dchange dchange
1846
1847     #f1# View Debian's NEWS of a given package
1848     dnews() {
1849         emulate -L zsh
1850         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
1851             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
1852         else
1853             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
1854                 $PAGER /usr/share/doc/$1/NEWS.gz
1855             else
1856                 echo "No NEWS file for package $1 found, sorry."
1857                 return 1
1858             fi
1859         fi
1860     }
1861     _dnews() { _files -W /usr/share/doc -/ }
1862     compdef _dnews dnews
1863
1864     #f1# View upstream's changelog of a given package
1865     uchange() {
1866         emulate -L zsh
1867         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1868             $PAGER /usr/share/doc/$1/changelog.gz
1869         else
1870             echo "No changelog for package $1 found, sorry."
1871             return 1
1872         fi
1873     }
1874     _uchange() { _files -W /usr/share/doc -/ }
1875     compdef _uchange uchange
1876 fi
1877
1878 # zsh profiling
1879 profile() {
1880     ZSH_PROFILE_RC=1 $SHELL "$@"
1881 }
1882
1883 #f1# Edit an alias via zle
1884 edalias() {
1885     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1886 }
1887 compdef _aliases edalias
1888
1889 #f1# Edit a function via zle
1890 edfunc() {
1891     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
1892 }
1893 compdef _functions edfunc
1894
1895 # use it e.g. via 'Restart apache2'
1896 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
1897 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
1898 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
1899 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
1900 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
1901 if [[ -d /etc/init.d || -d /etc/service ]] ; then
1902     __start_stop() {
1903         local action_="${1:l}"  # e.g Start/Stop/Restart
1904         local service_="$2"
1905         local param_="$3"
1906
1907         local service_target_="$(readlink /etc/init.d/$service_)"
1908         if [[ $service_target_ == "/usr/bin/sv" ]]; then
1909             # runit
1910             case "${action_}" in
1911                 start) if [[ ! -e /etc/service/$service_ ]]; then
1912                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
1913                        else
1914                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1915                        fi ;;
1916                 # there is no reload in runits sysv emulation
1917                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
1918                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
1919             esac
1920         else
1921             # sysvinit
1922             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1923         fi
1924     }
1925
1926     _grmlinitd() {
1927         local -a scripts
1928         scripts=( /etc/init.d/*(x:t) )
1929         _describe "service startup script" scripts
1930     }
1931
1932     for i in Start Restart Stop Force-Reload Reload ; do
1933         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
1934         compdef _grmlinitd $i
1935     done
1936 fi
1937
1938 #f1# Provides useful information on globbing
1939 H-Glob() {
1940     echo -e "
1941     /      directories
1942     .      plain files
1943     @      symbolic links
1944     =      sockets
1945     p      named pipes (FIFOs)
1946     *      executable plain files (0100)
1947     %      device files (character or block special)
1948     %b     block special files
1949     %c     character special files
1950     r      owner-readable files (0400)
1951     w      owner-writable files (0200)
1952     x      owner-executable files (0100)
1953     A      group-readable files (0040)
1954     I      group-writable files (0020)
1955     E      group-executable files (0010)
1956     R      world-readable files (0004)
1957     W      world-writable files (0002)
1958     X      world-executable files (0001)
1959     s      setuid files (04000)
1960     S      setgid files (02000)
1961     t      files with the sticky bit (01000)
1962
1963   print *(m-1)          # Files modified up to a day ago
1964   print *(a1)           # Files accessed a day ago
1965   print *(@)            # Just symlinks
1966   print *(Lk+50)        # Files bigger than 50 kilobytes
1967   print *(Lk-50)        # Files smaller than 50 kilobytes
1968   print **/*.c          # All *.c files recursively starting in \$PWD
1969   print **/*.c~file.c   # Same as above, but excluding 'file.c'
1970   print (foo|bar).*     # Files starting with 'foo' or 'bar'
1971   print *~*.*           # All Files that do not contain a dot
1972   chmod 644 *(.^x)      # make all plain non-executable files publically readable
1973   print -l *(.c|.h)     # Lists *.c and *.h
1974   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
1975   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
1976 }
1977 alias help-zshglob=H-Glob
1978
1979 #v1# set number of lines to display per page
1980 HELP_LINES_PER_PAGE=20
1981 #v1# set location of help-zle cache file
1982 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
1983 #f1# helper function for help-zle, actually generates the help text
1984 help_zle_parse_keybindings()
1985 {
1986     emulate -L zsh
1987     setopt extendedglob
1988     unsetopt ksharrays  #indexing starts at 1
1989
1990     #v1# choose files that help-zle will parse for keybindings
1991     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
1992
1993     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
1994         local load_cache=0
1995         for f ($KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
1996         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
1997     fi
1998
1999     #fill with default keybindings, possibly to be overwriten in a file later
2000     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2001     local -A help_zle_keybindings
2002     help_zle_keybindings['<Ctrl>@']="set MARK"
2003     help_zle_keybindings['<Ctrl>X<Ctrl>J']="vi-join lines"
2004     help_zle_keybindings['<Ctrl>X<Ctrl>B']="jump to matching brace"
2005     help_zle_keybindings['<Ctrl>X<Ctrl>U']="undo"
2006     help_zle_keybindings['<Ctrl>_']="undo"
2007     help_zle_keybindings['<Ctrl>X<Ctrl>F<c>']="find <c> in cmdline"
2008     help_zle_keybindings['<Ctrl>A']="goto beginning of line"
2009     help_zle_keybindings['<Ctrl>E']="goto end of line"
2010     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2011     help_zle_keybindings['<Alt>T']="transpose words"
2012     help_zle_keybindings['<Alt>s']="spellcheck word"
2013     help_zle_keybindings['<Ctrl>K']="backward kill buffer"
2014     help_zle_keybindings['<Ctrl>U']="forward kill buffer"
2015     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2016     help_zle_keybindings["<Alt>'"]="quote line"
2017     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2018     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2019     help_zle_keybindings['<Alt>U']="make next word Uppercase"
2020     help_zle_keybindings['<Alt>l']="make next word lowercase"
2021     help_zle_keybindings['<Ctrl>Xd']="preview expansion under cursor"
2022     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2023     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2024     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2025     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2026     help_zle_keybindings['<Ctrl>V']="insert next keypress symbol literally (e.g. for bindkey)"
2027     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2028     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2029     help_zle_keybindings['<Alt>H']="run help on current command"
2030
2031     #init global variables
2032     unset help_zle_lines help_zle_sln
2033     typeset -g -a help_zle_lines
2034     typeset -g help_zle_sln=1
2035
2036     local k v
2037     local lastkeybind_desc contents     #last description starting with #k# that we found
2038     local num_lines_elapsed=0            #number of lines between last description and keybinding
2039     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2040     for f in $HELPZLE_KEYBINDING_FILES; do
2041         [[ -r "$f" ]] || continue   #not readable ? skip it
2042         contents="$(<$f)"
2043         for cline in "${(f)contents}"; do
2044             #zsh pattern: matches lines like: #k# ..............
2045             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2046                 lastkeybind_desc="$match[*]"
2047                 num_lines_elapsed=0
2048             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2049             #             ignores lines that are commentend out
2050             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2051             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2052                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2053                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2054                     #substitute keybinding string with something readable
2055                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2056                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2057                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2058                     help_zle_keybindings[${k}]=$lastkeybind_desc
2059                 fi
2060                 lastkeybind_desc=""
2061             else
2062               ((num_lines_elapsed++))
2063             fi
2064         done
2065     done
2066     unset contents
2067     #calculate length of keybinding column
2068     local kstrlen=0
2069     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2070     #convert the assoc array into preformated lines, which we are able to sort
2071     for k v in ${(kv)help_zle_keybindings[@]}; do
2072         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2073         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2074     done
2075     #sort lines alphabetically
2076     help_zle_lines=("${(i)help_zle_lines[@]}")
2077     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2078     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2079     zcompile $HELP_ZLE_CACHE_FILE
2080 }
2081 typeset -g help_zle_sln
2082 typeset -g -a help_zle_lines
2083
2084 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2085 help-zle()
2086 {
2087     emulate -L zsh
2088     unsetopt ksharrays  #indexing starts at 1
2089     #help lines already generated ? no ? then do it
2090     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2091     #already displayed all lines ? go back to the start
2092     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2093     local sln=$help_zle_sln
2094     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2095     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2096     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2097 }
2098 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2099 zle -N help-zle && bindkey '^Xz' help-zle
2100
2101 # grep for running process, like: 'any vim'
2102 any() {
2103     emulate -L zsh
2104     unsetopt KSH_ARRAYS
2105     if [[ -z "$1" ]] ; then
2106         echo "any - grep for process(es) by keyword" >&2
2107         echo "Usage: any <keyword>" >&2 ; return 1
2108     else
2109         ps xauwww | grep -i --color=auto "[${1[1]}]${1[2,-1]}"
2110     fi
2111 }
2112
2113
2114 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2115 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2116 [[ -r /proc/1/maps ]] && \
2117 deswap() {
2118     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2119     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2120     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2121 }
2122
2123 # a wrapper for vim, that deals with title setting
2124 #   VIM_OPTIONS
2125 #       set this array to a set of options to vim you always want
2126 #       to have set when calling vim (in .zshrc.local), like:
2127 #           VIM_OPTIONS=( -p )
2128 #       This will cause vim to send every file given on the
2129 #       commandline to be send to it's own tab (needs vim7).
2130 vim() {
2131     VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2132 }
2133
2134 # make a backup of a file
2135 bk() {
2136     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2137 }
2138
2139 ssl_hashes=( sha512 sha256 sha1 md5 )
2140
2141 for sh in ${ssl_hashes}; do
2142     eval 'ssl-cert-'${sh}'() {
2143         emulate -L zsh
2144         if [[ -z $1 ]] ; then
2145             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2146             return 1
2147         fi
2148         openssl x509 -noout -fingerprint -'${sh}' -in $1
2149     }'
2150 done; unset sh
2151
2152 ssl-cert-fingerprints() {
2153     emulate -L zsh
2154     local i
2155     if [[ -z $1 ]] ; then
2156         printf 'usage: ssl-cert-fingerprints <file>\n'
2157         return 1
2158     fi
2159     for i in ${ssl_hashes}
2160         do ssl-cert-$i $1;
2161     done
2162 }
2163
2164 ssl-cert-info() {
2165     emulate -L zsh
2166     if [[ -z $1 ]] ; then
2167         printf 'usage: ssl-cert-info <file>\n'
2168         return 1
2169     fi
2170     openssl x509 -noout -text -in $1
2171     ssl-cert-fingerprints $1
2172 }
2173
2174 # make sure our environment is clean regarding colors
2175 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2176
2177 # "persistent history"
2178 # just write important commands you always need to ~/.important_commands
2179 if [[ -r ~/.important_commands ]] ; then
2180     fc -R ~/.important_commands
2181 fi
2182
2183 # load the lookup subsystem if it's available on the system
2184 zrcautoload lookupinit && lookupinit
2185
2186 ### non-root (EUID != 0) code below
2187 ###
2188
2189 if (( GRML_ALWAYS_LOAD_ALL == 0 )) && (( $EUID == 0 )) ; then
2190     zrclocal
2191     return 0
2192 fi
2193
2194 # variables
2195
2196 # set terminal property (used e.g. by msgid-chooser)
2197 export COLORTERM="yes"
2198
2199 # aliases
2200
2201 # general
2202 #a2# Execute \kbd{du -sch}
2203 alias da='du -sch'
2204 #a2# Execute \kbd{jobs -l}
2205 alias j='jobs -l'
2206
2207 # listing stuff
2208 #a2# Execute \kbd{ls -lSrah}
2209 alias dir="ls -lSrah"
2210 #a2# Only show dot-directories
2211 alias lad='ls -d .*(/)'                # only show dot-directories
2212 #a2# Only show dot-files
2213 alias lsa='ls -a .*(.)'                # only show dot-files
2214 #a2# Only files with setgid/setuid/sticky flag
2215 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
2216 #a2# Only show 1st ten symlinks
2217 alias lsl='ls -l *(@)'                 # only symlinks
2218 #a2# Display only executables
2219 alias lsx='ls -l *(*)'                 # only executables
2220 #a2# Display world-{readable,writable,executable} files
2221 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
2222 #a2# Display the ten biggest files
2223 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
2224 #a2# Only show directories
2225 alias lsd='ls -d *(/)'                 # only show directories
2226 #a2# Only show empty directories
2227 alias lse='ls -d *(/^F)'               # only show empty directories
2228 #a2# Display the ten newest files
2229 alias lsnew="ls -rtlh *(D.om[1,10])"   # display the newest files
2230 #a2# Display the ten oldest files
2231 alias lsold="ls -rtlh *(D.Om[1,10])"   # display the oldest files
2232 #a2# Display the ten smallest files
2233 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
2234
2235 # some useful aliases
2236 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir $OLDCWD}
2237 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2238
2239 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2240 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2241 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2242
2243 # simple webserver
2244 check_com -c python && alias http="python -m SimpleHTTPServer"
2245
2246 # work around non utf8 capable software in utf environment via $LANG and luit
2247 if check_com isutfenv && check_com luit ; then
2248     if check_com -c mrxvt ; then
2249         isutfenv && [[ -n "$LANG" ]] && \
2250             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2251     fi
2252
2253     if check_com -c aterm ; then
2254         isutfenv && [[ -n "$LANG" ]] && \
2255             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2256     fi
2257
2258     if check_com -c centericq ; then
2259         isutfenv && [[ -n "$LANG" ]] && \
2260             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2261     fi
2262 fi
2263
2264 # useful functions
2265
2266 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2267 bk() {
2268     emulate -L zsh
2269     cp -b $1 $1_`date --iso-8601=m`
2270 }
2271
2272 #f5# cd to directoy and list files
2273 cl() {
2274     emulate -L zsh
2275     cd $1 && ls -a
2276 }
2277
2278 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2279 cd() {
2280     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2281         [[ ! -e ${1:h} ]] && return 1
2282         print "Correcting ${1} to ${1:h}"
2283         builtin cd ${1:h}
2284     else
2285         builtin cd "$@"
2286     fi
2287 }
2288
2289 #f5# Create Directoy and \kbd{cd} to it
2290 mkcd() {
2291     mkdir -p "$@" && cd "$@"
2292 }
2293
2294 #f5# Create temporary directory and \kbd{cd} to it
2295 cdt() {
2296     local t
2297     t=$(mktemp -d)
2298     echo "$t"
2299     builtin cd "$t"
2300 }
2301
2302 #f5# Create directory under cursor or the selected area
2303 # Press ctrl-xM to create the directory under the cursor or the selected area.
2304 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2305 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2306 # directory does not exist yet -> press ctrl-XM and problem solved
2307 inplaceMkDirs() {
2308     local PATHTOMKDIR
2309     if ((REGION_ACTIVE==1)); then
2310         local F=$MARK T=$CURSOR
2311         if [[ $F -gt $T ]]; then
2312             F=${CURSOR}
2313             T=${MARK}
2314         fi
2315         # get marked area from buffer and eliminate whitespace
2316         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2317         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2318     else
2319         local bufwords iword
2320         bufwords=(${(z)LBUFFER})
2321         iword=${#bufwords}
2322         bufwords=(${(z)BUFFER})
2323         PATHTOMKDIR="${(Q)bufwords[iword]}"
2324     fi
2325     [[ -z "${PATHTOMKDIR}" ]] && return 1
2326     if [[ -e "${PATHTOMKDIR}" ]]; then
2327         zle -M " path already exists, doing nothing"
2328     else
2329         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2330         zle end-of-line
2331     fi
2332 }
2333 #k# mkdir -p <dir> from string under cursor or marked area
2334 zle -N inplaceMkDirs && bindkey '^XM' inplaceMkDirs
2335
2336 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2337 accessed() {
2338     emulate -L zsh
2339     print -l -- *(a-${1:-1})
2340 }
2341
2342 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2343 changed() {
2344     emulate -L zsh
2345     print -l -- *(c-${1:-1})
2346 }
2347
2348 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2349 modified() {
2350     emulate -L zsh
2351     print -l -- *(m-${1:-1})
2352 }
2353 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2354 check_com new || alias new=modified
2355
2356 # use colors when GNU grep with color-support
2357 #a2# Execute \kbd{grep -{}-color=auto}
2358 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
2359
2360 # Translate DE<=>EN
2361 # 'translate' looks up fot a word in a file with language-to-language
2362 # translations (field separator should be " : "). A typical wordlist looks
2363 # like at follows:
2364 #  | english-word : german-transmission
2365 # It's also only possible to translate english to german but not reciprocal.
2366 # Use the following oneliner to turn back the sort order:
2367 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2368 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2369 #f5# Translates a word
2370 trans() {
2371     emulate -L zsh
2372     case "$1" in
2373         -[dD]*)
2374             translate -l de-en $2
2375             ;;
2376         -[eE]*)
2377             translate -l en-de $2
2378             ;;
2379         *)
2380             echo "Usage: $0 { -D | -E }"
2381             echo "         -D == German to English"
2382             echo "         -E == English to German"
2383     esac
2384 }
2385
2386 # Usage: simple-extract <file>
2387 # Using option -d deletes the original archive file.
2388 #f5# Smart archive extractor
2389 simple-extract() {
2390     emulate -L zsh
2391     setopt extended_glob noclobber
2392     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2393     local RC=0
2394     zparseopts -D -E "d=DELETE_ORIGINAL"
2395     for ARCHIVE in "${@}"; do
2396         case $ARCHIVE in
2397             *.(tar.bz2|tbz2|tbz))
2398                 DECOMP_CMD="tar -xvjf -"
2399                 USES_STDIN=true
2400                 USES_STDOUT=false
2401                 ;;
2402             *.(tar.gz|tgz))
2403                 DECOMP_CMD="tar -xvzf -"
2404                 USES_STDIN=true
2405                 USES_STDOUT=false
2406                 ;;
2407             *.(tar.xz|txz|tar.lzma))
2408                 DECOMP_CMD="tar -xvJf -"
2409                 USES_STDIN=true
2410                 USES_STDOUT=false
2411                 ;;
2412             *.tar)
2413                 DECOMP_CMD="tar -xvf -"
2414                 USES_STDIN=true
2415                 USES_STDOUT=false
2416                 ;;
2417             *.rar)
2418                 DECOMP_CMD="unrar x"
2419                 USES_STDIN=false
2420                 USES_STDOUT=false
2421                 ;;
2422             *.lzh)
2423                 DECOMP_CMD="lha x"
2424                 USES_STDIN=false
2425                 USES_STDOUT=false
2426                 ;;
2427             *.7z)
2428                 DECOMP_CMD="7z x"
2429                 USES_STDIN=false
2430                 USES_STDOUT=false
2431                 ;;
2432             *.(zip|jar))
2433                 DECOMP_CMD="unzip"
2434                 USES_STDIN=false
2435                 USES_STDOUT=false
2436                 ;;
2437             *.deb)
2438                 DECOMP_CMD="ar -x"
2439                 USES_STDIN=false
2440                 USES_STDOUT=false
2441                 ;;
2442             *.bz2)
2443                 DECOMP_CMD="bzip2 -d -c -"
2444                 USES_STDIN=true
2445                 USES_STDOUT=true
2446                 ;;
2447             *.(gz|Z))
2448                 DECOMP_CMD="gzip -d -c -"
2449                 USES_STDIN=true
2450                 USES_STDOUT=true
2451                 ;;
2452             *.(xz|lzma))
2453                 DECOMP_CMD="xz -d -c -"
2454                 USES_STDIN=true
2455                 USES_STDOUT=true
2456                 ;;
2457             *)
2458                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2459                 RC=$((RC+1))
2460                 continue
2461                 ;;
2462         esac
2463
2464         if ! check_com ${DECOMP_CMD[(w)1]}; then
2465             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2466             RC=$((RC+2))
2467             continue
2468         fi
2469
2470         GZTARGET="${ARCHIVE:t:r}"
2471         if [[ -f $ARCHIVE ]] ; then
2472
2473             print "Extracting '$ARCHIVE' ..."
2474             if $USES_STDIN; then
2475                 if $USES_STDOUT; then
2476                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
2477                 else
2478                     ${=DECOMP_CMD} < "$ARCHIVE"
2479                 fi
2480             else
2481                 if $USES_STDOUT; then
2482                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
2483                 else
2484                     ${=DECOMP_CMD} "$ARCHIVE"
2485                 fi
2486             fi
2487             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
2488
2489         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
2490             if check_com curl; then
2491                 WGET_CMD="curl -L -k -s -o -"
2492             elif check_com wget; then
2493                 WGET_CMD="wget -q -O - --no-check-certificate"
2494             else
2495                 print "ERROR: neither wget nor curl is installed" >&2
2496                 RC=$((RC+4))
2497                 continue
2498             fi
2499             print "Downloading and Extracting '$ARCHIVE' ..."
2500             if $USES_STDIN; then
2501                 if $USES_STDOUT; then
2502                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
2503                     RC=$((RC+$?))
2504                 else
2505                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
2506                     RC=$((RC+$?))
2507                 fi
2508             else
2509                 if $USES_STDOUT; then
2510                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
2511                 else
2512                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
2513                 fi
2514             fi
2515
2516         else
2517             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
2518             RC=$((RC+8))
2519         fi
2520     done
2521     return $RC
2522 }
2523
2524 __archive_or_uri()
2525 {
2526     _alternative \
2527         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
2528         '_urls:Remote Archives:_urls'
2529 }
2530
2531 _simple_extract()
2532 {
2533     _arguments \
2534         '-d[delete original archivefile after extraction]' \
2535         '*:Archive Or Uri:__archive_or_uri'
2536 }
2537 compdef _simple_extract simple-extract
2538 alias se=simple-extract
2539
2540 # Usage: smartcompress <file> (<type>)
2541 #f5# Smart archive creator
2542 smartcompress() {
2543     emulate -L zsh
2544     if [[ -n $2 ]] ; then
2545         case $2 in
2546             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
2547             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
2548             tar.Z)          tar -Zcvf$1.$2 $1 ;;
2549             tar)            tar -cvf$1.$2  $1 ;;
2550             gz | gzip)      gzip           $1 ;;
2551             bz2 | bzip2)    bzip2          $1 ;;
2552             *)
2553                 echo "Error: $2 is not a valid compression type"
2554                 ;;
2555         esac
2556     else
2557         smartcompress $1 tar.gz
2558     fi
2559 }
2560
2561 # Usage: show-archive <archive>
2562 #f5# List an archive's content
2563 show-archive() {
2564     emulate -L zsh
2565     if [[ -f $1 ]] ; then
2566         case $1 in
2567             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
2568             *.tar)         tar -tf $1 ;;
2569             *.tgz)         tar -ztf $1 ;;
2570             *.zip)         unzip -l $1 ;;
2571             *.bz2)         bzless $1 ;;
2572             *.deb)         dpkg-deb --fsys-tarfile $1 | tar -tf - -- ;;
2573             *)             echo "'$1' Error. Please go away" ;;
2574         esac
2575     else
2576         echo "'$1' is not a valid archive"
2577     fi
2578 }
2579
2580 # TODO: So, this is the third incarnation of this function!?
2581 #f5# Reload given functions
2582 refunc() {
2583     for func in $argv ; do
2584         unfunction $func
2585         autoload $func
2586     done
2587 }
2588 compdef _functions refunc
2589
2590 #f5# Set all ulimit parameters to \kbd{unlimited}
2591 allulimit() {
2592     ulimit -c unlimited
2593     ulimit -d unlimited
2594     ulimit -f unlimited
2595     ulimit -l unlimited
2596     ulimit -n unlimited
2597     ulimit -s unlimited
2598     ulimit -t unlimited
2599 }
2600
2601 #f5# Change the xterm title from within GNU-screen
2602 xtrename() {
2603     emulate -L zsh
2604     if [[ $1 != "-f" ]] ; then
2605         if [[ -z ${DISPLAY} ]] ; then
2606             printf 'xtrename only makes sense in X11.\n'
2607             return 1
2608         fi
2609     else
2610         shift
2611     fi
2612     if [[ -z $1 ]] ; then
2613         printf 'usage: xtrename [-f] "title for xterm"\n'
2614         printf '  renames the title of xterm from _within_ screen.\n'
2615         printf '  also works without screen.\n'
2616         printf '  will not work if DISPLAY is unset, use -f to override.\n'
2617         return 0
2618     fi
2619     print -n "\eP\e]0;${1}\C-G\e\\"
2620     return 0
2621 }
2622
2623 # TODO:
2624 # Rewrite this by either using tinyurl.com's API
2625 # or using another shortening service to comply with
2626 # tinyurl.com's policy.
2627 #
2628 # Create small urls via http://tinyurl.com using wget(1).
2629 #function zurl() {
2630 #    emulate -L zsh
2631 #    [[ -z $1 ]] && { print "USAGE: zurl <URL>" ; return 1 }
2632 #
2633 #    local PN url tiny grabber search result preview
2634 #    PN=$0
2635 #    url=$1
2636 ##   Check existence of given URL with the help of ping(1).
2637 ##   N.B. ping(1) only works without an eventual given protocol.
2638 #    ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
2639 #        read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
2640 #
2641 #    if (( $? == 0 )) ; then
2642 ##           Prepend 'http://' to given URL where necessary for later output.
2643 #            [[ ${url} != http(s|)://* ]] && url='http://'${url}
2644 #            tiny='http://tinyurl.com/create.php?url='
2645 #            if check_com -c wget ; then
2646 #                grabber='wget -O- -o/dev/null'
2647 #            else
2648 #                print "wget is not available, but mandatory for ${PN}. Aborting."
2649 #            fi
2650 ##           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
2651 #            search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
2652 #            result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
2653 ##           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
2654 #            preview='http://preview.'${result#http://}
2655 #
2656 #            printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
2657 #            printf '%s\t%s\n\n' 'Given URL:' ${url}
2658 #            printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
2659 #    else
2660 #        return 1
2661 #    fi
2662 #}
2663
2664 #f2# Find history events by search pattern and list them by date.
2665 whatwhen()  {
2666     emulate -L zsh
2667     local usage help ident format_l format_s first_char remain first last
2668     usage='USAGE: whatwhen [options] <searchstring> <search range>'
2669     help='Use `whatwhen -h'\'' for further explanations.'
2670     ident=${(l,${#${:-Usage: }},, ,)}
2671     format_l="${ident}%s\t\t\t%s\n"
2672     format_s="${format_l//(\\t)##/\\t}"
2673     # Make the first char of the word to search for case
2674     # insensitive; e.g. [aA]
2675     first_char=[${(L)1[1]}${(U)1[1]}]
2676     remain=${1[2,-1]}
2677     # Default search range is `-100'.
2678     first=${2:-\-100}
2679     # Optional, just used for `<first> <last>' given.
2680     last=$3
2681     case $1 in
2682         ("")
2683             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
2684             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2685         ;;
2686         (-h)
2687             printf '%s\n\n' ${usage}
2688             print 'OPTIONS:'
2689             printf $format_l '-h' 'show help text'
2690             print '\f'
2691             print 'SEARCH RANGE:'
2692             printf $format_l "'0'" 'the whole history,'
2693             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
2694             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
2695             printf '\n%s\n' 'EXAMPLES:'
2696             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
2697             printf $format_l 'whatwhen zsh -250'
2698             printf $format_l 'whatwhen foo 1 99'
2699         ;;
2700         (\?)
2701             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2702         ;;
2703         (*)
2704             # -l list results on stout rather than invoking $EDITOR.
2705             # -i Print dates as in YYYY-MM-DD.
2706             # -m Search for a - quoted - pattern within the history.
2707             fc -li -m "*${first_char}${remain}*" $first $last
2708         ;;
2709     esac
2710 }
2711
2712 # mercurial related stuff
2713 if check_com -c hg ; then
2714     # gnu like diff for mercurial
2715     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
2716     #f5# GNU like diff for mercurial
2717     hgdi() {
2718         emulate -L zsh
2719         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
2720     }
2721
2722     # build debian package
2723     #a2# Alias for \kbd{hg-buildpackage}
2724     alias hbp='hg-buildpackage'
2725
2726     # execute commands on the versioned patch-queue from the current repos
2727     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
2728
2729     # diffstat for specific version of a mercurial repository
2730     #   hgstat      => display diffstat between last revision and tip
2731     #   hgstat 1234 => display diffstat between revision 1234 and tip
2732     #f5# Diffstat for specific version of a mercurial repos
2733     hgstat() {
2734         emulate -L zsh
2735         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
2736     }
2737
2738 fi # end of check whether we have the 'hg'-executable
2739
2740 # grml-small cleanups
2741
2742 # The following is used to remove zsh-config-items that do not work
2743 # in grml-small by default.
2744 # If you do not want these adjustments (for whatever reason), set
2745 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
2746 # sources if it is there).
2747
2748 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
2749
2750     unset abk[V]
2751     unalias    'V'      &> /dev/null
2752     unfunction vman     &> /dev/null
2753     unfunction viless   &> /dev/null
2754     unfunction 2html    &> /dev/null
2755
2756     # manpages are not in grmlsmall
2757     unfunction manzsh   &> /dev/null
2758     unfunction man2     &> /dev/null
2759
2760 fi
2761
2762 zrclocal
2763
2764 ## genrefcard.pl settings
2765
2766 ### doc strings for external functions from files
2767 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
2768
2769 ### example: split functions-search 8,16,24,32
2770 #@# split functions-search 8
2771
2772 ## END OF FILE #################################################################
2773 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
2774 # Local variables:
2775 # mode: sh
2776 # End: