etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 function is4 () {
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 function is41 () {
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 function is42 () {
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 function is425 () {
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 function is43 () {
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 function is433 () {
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 function is437 () {
 148     [[ $ZSH_VERSION == 4.3.<7->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 function is439 () {
 154     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 155                                  || $ZSH_VERSION == <5->* ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running grml
 160 function isgrml () {
 161     [[ -f /etc/grml_version ]] && return 0
 162     return 1
 163 }
 164
 165 #f1# Checks whether or not you're running a grml cd
 166 function isgrmlcd () {
 167     [[ -f /etc/grml_cd ]] && return 0
 168     return 1
 169 }
 170
 171 if isgrml ; then
 172 #f1# Checks whether or not you're running grml-small
 173     function isgrmlsmall () {
 174         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 175             return 0
 176         fi
 177         return 1
 178     }
 179 else
 180     function isgrmlsmall () { return 1 }
 181 fi
 182
 183 GRML_OSTYPE=$(uname -s)
 184
 185 function islinux () {
 186     [[ $GRML_OSTYPE == "Linux" ]]
 187 }
 188
 189 function isdarwin () {
 190     [[ $GRML_OSTYPE == "Darwin" ]]
 191 }
 192
 193 function isfreebsd () {
 194     [[ $GRML_OSTYPE == "FreeBSD" ]]
 195 }
 196
 197 function isopenbsd () {
 198     [[ $GRML_OSTYPE == "OpenBSD" ]]
 199 }
 200
 201 function issolaris () {
 202     [[ $GRML_OSTYPE == "SunOS" ]]
 203 }
 204
 205 #f1# are we running within an utf environment?
 206 function isutfenv () {
 207     case "$LANG $CHARSET $LANGUAGE" in
 208         *utf*) return 0 ;;
 209         *UTF*) return 0 ;;
 210         *)     return 1 ;;
 211     esac
 212 }
 213
 214 # check for user, if not running as root set $SUDO to sudo
 215 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 216
 217 # change directory to home on first invocation of zsh
 218 # important for rungetty -> autologin
 219 # Thanks go to Bart Schaefer!
 220 isgrml && function checkhome () {
 221     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 222         export ALREADY_DID_CD_HOME=$HOME
 223         cd
 224     fi
 225 }
 226
 227 # check for zsh v3.1.7+
 228
 229 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 230      || ${ZSH_VERSION} == 3.<2->.<->*    \
 231      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 232
 233     printf '-!-\n'
 234     printf '-!- In this configuration we try to make use of features, that only\n'
 235     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 236     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 237     printf '-!- advanced features in all supported versions.\n'
 238     printf '-!-\n'
 239     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 240     printf '-!-\n'
 241     printf '-!- While this *may* work, it might as well fail.\n'
 242     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 243     printf '-!-\n'
 244     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 245     printf '-!- If it does today, you'\''ve been lucky.\n'
 246     printf '-!-\n'
 247     printf '-!- Ye been warned!\n'
 248     printf '-!-\n'
 249
 250     function zstyle () { : }
 251 fi
 252
 253 # autoload wrapper - use this one instead of autoload directly
 254 # We need to define this function as early as this, because autoloading
 255 # 'is-at-least()' needs it.
 256 function zrcautoload () {
 257     emulate -L zsh
 258     setopt extended_glob
 259     local fdir ffile
 260     local -i ffound
 261
 262     ffile=$1
 263     (( ffound = 0 ))
 264     for fdir in ${fpath} ; do
 265         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 266     done
 267
 268     (( ffound == 0 )) && return 1
 269     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 270         autoload -U ${ffile} || return 1
 271     else
 272         autoload ${ffile} || return 1
 273     fi
 274     return 0
 275 }
 276
 277 # The following is the ‘add-zsh-hook’ function from zsh upstream. It is
 278 # included here to make the setup work with older versions of zsh (prior to
 279 # 4.3.7) in which this function had a bug that triggers annoying errors during
 280 # shell startup. This is exactly upstreams code from f0068edb4888a4d8fe94def,
 281 # with just a few adjustments in coding style to make the function look more
 282 # compact. This definition can be removed as soon as we raise the minimum
 283 # version requirement to 4.3.7 or newer.
 284 function add-zsh-hook () {
 285     # Add to HOOK the given FUNCTION.
 286     # HOOK is one of chpwd, precmd, preexec, periodic, zshaddhistory,
 287     # zshexit, zsh_directory_name (the _functions subscript is not required).
 288     #
 289     # With -d, remove the function from the hook instead; delete the hook
 290     # variable if it is empty.
 291     #
 292     # -D behaves like -d, but pattern characters are active in the function
 293     # name, so any matching function will be deleted from the hook.
 294     #
 295     # Without -d, the FUNCTION is marked for autoload; -U is passed down to
 296     # autoload if that is given, as are -z and -k. (This is harmless if the
 297     # function is actually defined inline.)
 298     emulate -L zsh
 299     local -a hooktypes
 300     hooktypes=(
 301         chpwd precmd preexec periodic zshaddhistory zshexit
 302         zsh_directory_name
 303     )
 304     local usage="Usage: $0 hook function\nValid hooks are:\n  $hooktypes"
 305     local opt
 306     local -a autoopts
 307     integer del list help
 308     while getopts "dDhLUzk" opt; do
 309         case $opt in
 310         (d) del=1 ;;
 311         (D) del=2 ;;
 312         (h) help=1 ;;
 313         (L) list=1 ;;
 314         ([Uzk]) autoopts+=(-$opt) ;;
 315         (*) return 1 ;;
 316         esac
 317     done
 318     shift $(( OPTIND - 1 ))
 319     if (( list )); then
 320         typeset -mp "(${1:-${(@j:|:)hooktypes}})_functions"
 321         return $?
 322     elif (( help || $# != 2 || ${hooktypes[(I)$1]} == 0 )); then
 323         print -u$(( 2 - help )) $usage
 324         return $(( 1 - help ))
 325     fi
 326     local hook="${1}_functions"
 327     local fn="$2"
 328     if (( del )); then
 329         # delete, if hook is set
 330         if (( ${(P)+hook} )); then
 331             if (( del == 2 )); then
 332                 set -A $hook ${(P)hook:#${~fn}}
 333             else
 334                 set -A $hook ${(P)hook:#$fn}
 335             fi
 336             # unset if no remaining entries --- this can give better
 337             # performance in some cases
 338             if (( ! ${(P)#hook} )); then
 339                 unset $hook
 340             fi
 341         fi
 342     else
 343         if (( ${(P)+hook} )); then
 344             if (( ${${(P)hook}[(I)$fn]} == 0 )); then
 345                 set -A $hook ${(P)hook} $fn
 346             fi
 347         else
 348             set -A $hook $fn
 349         fi
 350         autoload $autoopts -- $fn
 351     fi
 352 }
 353
 354 # Load is-at-least() for more precise version checks Note that this test will
 355 # *always* fail, if the is-at-least function could not be marked for
 356 # autoloading.
 357 zrcautoload is-at-least || function is-at-least () { return 1 }
 358
 359 # set some important options (as early as possible)
 360
 361 # append history list to the history file; this is the default but we make sure
 362 # because it's required for share_history.
 363 setopt append_history
 364
 365 # import new commands from the history file also in other zsh-session
 366 is4 && setopt share_history
 367
 368 # save each command's beginning timestamp and the duration to the history file
 369 setopt extended_history
 370
 371 # If a new command line being added to the history list duplicates an older
 372 # one, the older command is removed from the list
 373 is4 && setopt histignorealldups
 374
 375 # remove command lines from the history list when the first character on the
 376 # line is a space
 377 setopt histignorespace
 378
 379 # if a command is issued that can't be executed as a normal command, and the
 380 # command is the name of a directory, perform the cd command to that directory.
 381 setopt auto_cd
 382
 383 # in order to use #, ~ and ^ for filename generation grep word
 384 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 385 # don't forget to quote '^', '~' and '#'!
 386 setopt extended_glob
 387
 388 # display PID when suspending processes as well
 389 setopt longlistjobs
 390
 391 # report the status of backgrounds jobs immediately
 392 setopt notify
 393
 394 # whenever a command completion is attempted, make sure the entire command path
 395 # is hashed first.
 396 setopt hash_list_all
 397
 398 # not just at the end
 399 setopt completeinword
 400
 401 # Don't send SIGHUP to background processes when the shell exits.
 402 setopt nohup
 403
 404 # make cd push the old directory onto the directory stack.
 405 setopt auto_pushd
 406
 407 # avoid "beep"ing
 408 setopt nobeep
 409
 410 # don't push the same dir twice.
 411 setopt pushd_ignore_dups
 412
 413 # * shouldn't match dotfiles. ever.
 414 setopt noglobdots
 415
 416 # use zsh style word splitting
 417 setopt noshwordsplit
 418
 419 # don't error out when unset parameters are used
 420 setopt unset
 421
 422 # setting some default values
 423 NOCOR=${NOCOR:-0}
 424 NOMENU=${NOMENU:-0}
 425 NOPRECMD=${NOPRECMD:-0}
 426 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 427 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 428 GRML_DISPLAY_BATTERY=${GRML_DISPLAY_BATTERY:-${BATTERY:-0}}
 429 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 430 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 431
 432 typeset -ga ls_options
 433 typeset -ga grep_options
 434 if ls --color=auto / >/dev/null 2>&1; then
 435     ls_options+=( --color=auto )
 436 elif ls -G / >/dev/null 2>&1; then
 437     ls_options+=( -G )
 438 fi
 439 if grep --color=auto -q "a" <<< "a" >/dev/null 2>&1; then
 440     grep_options+=( --color=auto )
 441 fi
 442
 443 # utility functions
 444 # this function checks if a command exists and returns either true
 445 # or false. This avoids using 'which' and 'whence', which will
 446 # avoid problems with aliases for which on certain weird systems. :-)
 447 # Usage: check_com [-c|-g] word
 448 #   -c  only checks for external commands
 449 #   -g  does the usual tests and also checks for global aliases
 450 function check_com () {
 451     emulate -L zsh
 452     local -i comonly gatoo
 453     comonly=0
 454     gatoo=0
 455
 456     if [[ $1 == '-c' ]] ; then
 457         comonly=1
 458         shift 1
 459     elif [[ $1 == '-g' ]] ; then
 460         gatoo=1
 461         shift 1
 462     fi
 463
 464     if (( ${#argv} != 1 )) ; then
 465         printf 'usage: check_com [-c|-g] <command>\n' >&2
 466         return 1
 467     fi
 468
 469     if (( comonly > 0 )) ; then
 470         (( ${+commands[$1]}  )) && return 0
 471         return 1
 472     fi
 473
 474     if     (( ${+commands[$1]}    )) \
 475         || (( ${+functions[$1]}   )) \
 476         || (( ${+aliases[$1]}     )) \
 477         || (( ${+reswords[(r)$1]} )) ; then
 478         return 0
 479     fi
 480
 481     if (( gatoo > 0 )) && (( ${+galiases[$1]} )) ; then
 482         return 0
 483     fi
 484
 485     return 1
 486 }
 487
 488 # creates an alias and precedes the command with
 489 # sudo if $EUID is not zero.
 490 function salias () {
 491     emulate -L zsh
 492     local only=0 ; local multi=0
 493     local key val
 494     while getopts ":hao" opt; do
 495         case $opt in
 496             o) only=1 ;;
 497             a) multi=1 ;;
 498             h)
 499                 printf 'usage: salias [-hoa] <alias-expression>\n'
 500                 printf '  -h      shows this help text.\n'
 501                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 502                 printf '          be careful using this option.\n'
 503                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 504                 return 0
 505                 ;;
 506             *) salias -h >&2; return 1 ;;
 507         esac
 508     done
 509     shift "$((OPTIND-1))"
 510
 511     if (( ${#argv} > 1 )) ; then
 512         printf 'Too many arguments %s\n' "${#argv}"
 513         return 1
 514     fi
 515
 516     key="${1%%\=*}" ;  val="${1#*\=}"
 517     if (( EUID == 0 )) && (( only == 0 )); then
 518         alias -- "${key}=${val}"
 519     elif (( EUID > 0 )) ; then
 520         (( multi > 0 )) && val="${val// ; / ; sudo }"
 521         alias -- "${key}=sudo ${val}"
 522     fi
 523
 524     return 0
 525 }
 526
 527 # Check if we can read given files and source those we can.
 528 function xsource () {
 529     if (( ${#argv} < 1 )) ; then
 530         printf 'usage: xsource FILE(s)...\n' >&2
 531         return 1
 532     fi
 533
 534     while (( ${#argv} > 0 )) ; do
 535         [[ -r "$1" ]] && source "$1"
 536         shift
 537     done
 538     return 0
 539 }
 540
 541 # Check if we can read a given file and 'cat(1)' it.
 542 function xcat () {
 543     emulate -L zsh
 544     if (( ${#argv} != 1 )) ; then
 545         printf 'usage: xcat FILE\n' >&2
 546         return 1
 547     fi
 548
 549     [[ -r $1 ]] && cat $1
 550     return 0
 551 }
 552
 553 # Remove these functions again, they are of use only in these
 554 # setup files. This should be called at the end of .zshrc.
 555 function xunfunction () {
 556     emulate -L zsh
 557     local -a funcs
 558     local func
 559     funcs=(salias xcat xsource xunfunction zrcautoload zrcautozle)
 560     for func in $funcs ; do
 561         [[ -n ${functions[$func]} ]] \
 562             && unfunction $func
 563     done
 564     return 0
 565 }
 566
 567 # this allows us to stay in sync with grml's zshrc and put own
 568 # modifications in ~/.zshrc.local
 569 function zrclocal () {
 570     xsource "/etc/zsh/zshrc.local"
 571     xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
 572     return 0
 573 }
 574
 575 # locale setup
 576 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 577     xsource "/etc/default/locale"
 578 fi
 579
 580 for var in LANG LC_ALL LC_MESSAGES ; do
 581     [[ -n ${(P)var} ]] && export $var
 582 done
 583 builtin unset -v var
 584
 585 # set some variables
 586 if check_com -c vim ; then
 587 #v#
 588     export EDITOR=${EDITOR:-vim}
 589 else
 590     export EDITOR=${EDITOR:-vi}
 591 fi
 592
 593 #v#
 594 export PAGER=${PAGER:-less}
 595
 596 #v#
 597 export MAIL=${MAIL:-/var/mail/$USER}
 598
 599 # color setup for ls:
 600 check_com -c dircolors && eval $(dircolors -b)
 601 # color setup for ls on OS X / FreeBSD:
 602 isdarwin && export CLICOLOR=1
 603 isfreebsd && export CLICOLOR=1
 604
 605 # do MacPorts setup on darwin
 606 if isdarwin && [[ -d /opt/local ]]; then
 607     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 608     # zshenv.
 609     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 610     MANPATH="/opt/local/share/man:$MANPATH"
 611 fi
 612 # do Fink setup on darwin
 613 isdarwin && xsource /sw/bin/init.sh
 614
 615 # load our function and completion directories
 616 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 617     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 618     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 619         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 620             zrcautoload ${func:t}
 621         done
 622     fi
 623 done
 624 unset fdir func
 625
 626 # support colors in less
 627 export LESS_TERMCAP_mb=$'\E[01;31m'
 628 export LESS_TERMCAP_md=$'\E[01;31m'
 629 export LESS_TERMCAP_me=$'\E[0m'
 630 export LESS_TERMCAP_se=$'\E[0m'
 631 export LESS_TERMCAP_so=$'\E[01;44;33m'
 632 export LESS_TERMCAP_ue=$'\E[0m'
 633 export LESS_TERMCAP_us=$'\E[01;32m'
 634
 635 # mailchecks
 636 MAILCHECK=30
 637
 638 # report about cpu-/system-/user-time of command if running longer than
 639 # 5 seconds
 640 REPORTTIME=5
 641
 642 # watch for everyone but me and root
 643 watch=(notme root)
 644
 645 # automatically remove duplicates from these arrays
 646 typeset -U path PATH cdpath CDPATH fpath FPATH manpath MANPATH
 647
 648 # Load a few modules
 649 is4 && \
 650 for mod in parameter complist deltochar mathfunc ; do
 651     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 652 done && builtin unset -v mod
 653
 654 # autoload zsh modules when they are referenced
 655 if is4 ; then
 656     zmodload -a  zsh/stat    zstat
 657     zmodload -a  zsh/zpty    zpty
 658     zmodload -ap zsh/mapfile mapfile
 659 fi
 660
 661 # completion system
 662 COMPDUMPFILE=${COMPDUMPFILE:-${ZDOTDIR:-${HOME}}/.zcompdump}
 663 if zrcautoload compinit ; then
 664     compinit -d ${COMPDUMPFILE} || print 'Notice: no compinit available :('
 665 else
 666     print 'Notice: no compinit available :('
 667     function compdef { }
 668 fi
 669
 670 # completion system
 671
 672 # called later (via is4 && grmlcomp)
 673 # note: use 'zstyle' for getting current settings
 674 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
 675 function grmlcomp () {
 676     # TODO: This could use some additional information
 677
 678     # Make sure the completion system is initialised
 679     (( ${+_comps} )) || return 1
 680
 681     # allow one error for every three characters typed in approximate completer
 682     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
 683
 684     # don't complete backup files as executables
 685     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
 686
 687     # start menu completion only if it could find no unambiguous initial string
 688     zstyle ':completion:*:correct:*'       insert-unambiguous true
 689     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
 690     zstyle ':completion:*:correct:*'       original true
 691
 692     # activate color-completion
 693     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
 694
 695     # format on completion
 696     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
 697
 698     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
 699     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
 700
 701     # insert all expansions for expand completer
 702     zstyle ':completion:*:expand:*'        tag-order all-expansions
 703     zstyle ':completion:*:history-words'   list false
 704
 705     # activate menu
 706     zstyle ':completion:*:history-words'   menu yes
 707
 708     # ignore duplicate entries
 709     zstyle ':completion:*:history-words'   remove-all-dups yes
 710     zstyle ':completion:*:history-words'   stop yes
 711
 712     # match uppercase from lowercase
 713     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
 714
 715     # separate matches into groups
 716     zstyle ':completion:*:matches'         group 'yes'
 717     zstyle ':completion:*'                 group-name ''
 718
 719     if [[ "$NOMENU" -eq 0 ]] ; then
 720         # if there are more than 5 options allow selecting from a menu
 721         zstyle ':completion:*'               menu select=5
 722     else
 723         # don't use any menus at all
 724         setopt no_auto_menu
 725     fi
 726
 727     zstyle ':completion:*:messages'        format '%d'
 728     zstyle ':completion:*:options'         auto-description '%d'
 729
 730     # describe options in full
 731     zstyle ':completion:*:options'         description 'yes'
 732
 733     # on processes completion complete all user processes
 734     zstyle ':completion:*:processes'       command 'ps -au$USER'
 735
 736     # offer indexes before parameters in subscripts
 737     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
 738
 739     # provide verbose completion information
 740     zstyle ':completion:*'                 verbose true
 741
 742     # recent (as of Dec 2007) zsh versions are able to provide descriptions
 743     # for commands (read: 1st word in the line) that it will list for the user
 744     # to choose from. The following disables that, because it's not exactly fast.
 745     zstyle ':completion:*:-command-:*:'    verbose false
 746
 747     # set format for warnings
 748     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
 749
 750     # define files to ignore for zcompile
 751     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
 752     zstyle ':completion:correct:'          prompt 'correct to: %e'
 753
 754     # Ignore completion functions for commands you don't have:
 755     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
 756
 757     # Provide more processes in completion of programs like killall:
 758     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
 759
 760     # complete manual by their section
 761     zstyle ':completion:*:manuals'    separate-sections true
 762     zstyle ':completion:*:manuals.*'  insert-sections   true
 763     zstyle ':completion:*:man:*'      menu yes select
 764
 765     # Search path for sudo completion
 766     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
 767                                                /usr/local/bin  \
 768                                                /usr/sbin       \
 769                                                /usr/bin        \
 770                                                /sbin           \
 771                                                /bin            \
 772                                                /usr/X11R6/bin
 773
 774     # provide .. as a completion
 775     zstyle ':completion:*' special-dirs ..
 776
 777     # run rehash on completion so new installed program are found automatically:
 778     function _force_rehash () {
 779         (( CURRENT == 1 )) && rehash
 780         return 1
 781     }
 782
 783     ## correction
 784     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
 785     if [[ "$NOCOR" -gt 0 ]] ; then
 786         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
 787         setopt nocorrect
 788     else
 789         # try to be smart about when to use what completer...
 790         setopt correct
 791         zstyle -e ':completion:*' completer '
 792             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
 793                 _last_try="$HISTNO$BUFFER$CURSOR"
 794                 reply=(_complete _match _ignored _prefix _files)
 795             else
 796                 if [[ $words[1] == (rm|mv) ]] ; then
 797                     reply=(_complete _files)
 798                 else
 799                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
 800                 fi
 801             fi'
 802     fi
 803
 804     # command for process lists, the local web server details and host completion
 805     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
 806
 807     # Some functions, like _apt and _dpkg, are very slow. We can use a cache in
 808     # order to speed things up
 809     if [[ ${GRML_COMP_CACHING:-yes} == yes ]]; then
 810         GRML_COMP_CACHE_DIR=${GRML_COMP_CACHE_DIR:-${ZDOTDIR:-$HOME}/.cache}
 811         if [[ ! -d ${GRML_COMP_CACHE_DIR} ]]; then
 812             command mkdir -p "${GRML_COMP_CACHE_DIR}"
 813         fi
 814         zstyle ':completion:*' use-cache  yes
 815         zstyle ':completion:*:complete:*' cache-path "${GRML_COMP_CACHE_DIR}"
 816     fi
 817
 818     # host completion
 819     if is42 ; then
 820         [[ -r ~/.ssh/config ]] && _ssh_config_hosts=(${${(s: :)${(ps:\t:)${${(@M)${(f)"$(<$HOME/.ssh/config)"}:#Host *}#Host }}}:#*[*?]*}) || _ssh_config_hosts=()
 821         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
 822         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
 823     else
 824         _ssh_config_hosts=()
 825         _ssh_hosts=()
 826         _etc_hosts=()
 827     fi
 828     hosts=(
 829         $(hostname)
 830         "$_ssh_config_hosts[@]"
 831         "$_ssh_hosts[@]"
 832         "$_etc_hosts[@]"
 833         localhost
 834     )
 835     zstyle ':completion:*:hosts' hosts $hosts
 836     # TODO: so, why is this here?
 837     #  zstyle '*' hosts $hosts
 838
 839     # use generic completion system for programs not yet defined; (_gnu_generic works
 840     # with commands that provide a --help option with "standard" gnu-like output.)
 841     for compcom in cp deborphan df feh fetchipac gpasswd head hnb ipacsum mv \
 842                    pal stow uname ; do
 843         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
 844     done; unset compcom
 845
 846     # see upgrade function in this file
 847     compdef _hosts upgrade
 848 }
 849
 850 # Keyboard setup: The following is based on the same code, we wrote for
 851 # debian's setup. It ensures the terminal is in the right mode, when zle is
 852 # active, so the values from $terminfo are valid. Therefore, this setup should
 853 # work on all systems, that have support for `terminfo'. It also requires the
 854 # zsh in use to have the `zsh/terminfo' module built.
 855 #
 856 # If you are customising your `zle-line-init()' or `zle-line-finish()'
 857 # functions, make sure you call the following utility functions in there:
 858 #
 859 #     - zle-line-init():      zle-smkx
 860 #     - zle-line-finish():    zle-rmkx
 861
 862 # Use emacs-like key bindings by default:
 863 bindkey -e
 864
 865 # Custom widgets:
 866
 867 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 868 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 869 function beginning-or-end-of-somewhere () {
 870     local hno=$HISTNO
 871     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 872       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 873         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 874     else
 875         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 876         if (( HISTNO != hno )); then
 877             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 878         fi
 879     fi
 880 }
 881 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 882 zle -N end-of-somewhere beginning-or-end-of-somewhere
 883
 884 # add a command line to the shells history without executing it
 885 function commit-to-history () {
 886     print -s ${(z)BUFFER}
 887     zle send-break
 888 }
 889 zle -N commit-to-history
 890
 891 # only slash should be considered as a word separator:
 892 function slash-backward-kill-word () {
 893     local WORDCHARS="${WORDCHARS:s@/@}"
 894     # zle backward-word
 895     zle backward-kill-word
 896 }
 897 zle -N slash-backward-kill-word
 898
 899 # a generic accept-line wrapper
 900
 901 # This widget can prevent unwanted autocorrections from command-name
 902 # to _command-name, rehash automatically on enter and call any number
 903 # of builtin and user-defined widgets in different contexts.
 904 #
 905 # For a broader description, see:
 906 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 907 #
 908 # The code is imported from the file 'zsh/functions/accept-line' from
 909 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 910 # distributed under the same terms as zsh itself.
 911
 912 # A newly added command will may not be found or will cause false
 913 # correction attempts, if you got auto-correction set. By setting the
 914 # following style, we force accept-line() to rehash, if it cannot
 915 # find the first word on the command line in the $command[] hash.
 916 zstyle ':acceptline:*' rehash true
 917
 918 function Accept-Line () {
 919     setopt localoptions noksharrays
 920     local -a subs
 921     local -xi aldone
 922     local sub
 923     local alcontext=${1:-$alcontext}
 924
 925     zstyle -a ":acceptline:${alcontext}" actions subs
 926
 927     (( ${#subs} < 1 )) && return 0
 928
 929     (( aldone = 0 ))
 930     for sub in ${subs} ; do
 931         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 932         zle ${sub}
 933
 934         (( aldone > 0 )) && break
 935     done
 936 }
 937
 938 function Accept-Line-getdefault () {
 939     emulate -L zsh
 940     local default_action
 941
 942     zstyle -s ":acceptline:${alcontext}" default_action default_action
 943     case ${default_action} in
 944         ((accept-line|))
 945             printf ".accept-line"
 946             ;;
 947         (*)
 948             printf ${default_action}
 949             ;;
 950     esac
 951 }
 952
 953 function Accept-Line-HandleContext () {
 954     zle Accept-Line
 955
 956     default_action=$(Accept-Line-getdefault)
 957     zstyle -T ":acceptline:${alcontext}" call_default \
 958         && zle ${default_action}
 959 }
 960
 961 function accept-line () {
 962     setopt localoptions noksharrays
 963     local -a cmdline
 964     local -x alcontext
 965     local buf com fname format msg default_action
 966
 967     alcontext='default'
 968     buf="${BUFFER}"
 969     cmdline=(${(z)BUFFER})
 970     com="${cmdline[1]}"
 971     fname="_${com}"
 972
 973     Accept-Line 'preprocess'
 974
 975     zstyle -t ":acceptline:${alcontext}" rehash \
 976         && [[ -z ${commands[$com]} ]]           \
 977         && rehash
 978
 979     if    [[ -n ${com}               ]] \
 980        && [[ -n ${reswords[(r)$com]} ]] \
 981        || [[ -n ${aliases[$com]}     ]] \
 982        || [[ -n ${functions[$com]}   ]] \
 983        || [[ -n ${builtins[$com]}    ]] \
 984        || [[ -n ${commands[$com]}    ]] ; then
 985
 986         # there is something sensible to execute, just do it.
 987         alcontext='normal'
 988         Accept-Line-HandleContext
 989
 990         return
 991     fi
 992
 993     if    [[ -o correct              ]] \
 994        || [[ -o correctall           ]] \
 995        && [[ -n ${functions[$fname]} ]] ; then
 996
 997         # nothing there to execute but there is a function called
 998         # _command_name; a completion widget. Makes no sense to
 999         # call it on the commandline, but the correct{,all} options
1000         # will ask for it nevertheless, so warn the user.
1001         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
1002             # Okay, we warned the user before, he called us again,
1003             # so have it his way.
1004             alcontext='force'
1005             Accept-Line-HandleContext
1006
1007             return
1008         fi
1009
1010         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
1011             alcontext='normal'
1012             Accept-Line-HandleContext
1013         else
1014             # prepare warning message for the user, configurable via zstyle.
1015             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
1016
1017             if [[ -z ${msg} ]] ; then
1018                 msg="%c will not execute and completion %f exists."
1019             fi
1020
1021             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
1022
1023             zle -M -- "${msg}"
1024         fi
1025         return
1026     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
1027         # If we are here, the commandline contains something that is not
1028         # executable, which is neither subject to _command_name correction
1029         # and is not empty. might be a variable assignment
1030         alcontext='misc'
1031         Accept-Line-HandleContext
1032
1033         return
1034     fi
1035
1036     # If we got this far, the commandline only contains whitespace, or is empty.
1037     alcontext='empty'
1038     Accept-Line-HandleContext
1039 }
1040
1041 zle -N accept-line
1042 zle -N Accept-Line
1043 zle -N Accept-Line-HandleContext
1044
1045 # power completion / abbreviation expansion / buffer expansion
1046 # see http://zshwiki.org/home/examples/zleiab for details
1047 # less risky than the global aliases but powerful as well
1048 # just type the abbreviation key and afterwards 'ctrl-x .' to expand it
1049 declare -A abk
1050 setopt extendedglob
1051 setopt interactivecomments
1052 abk=(
1053 #   key   # value                  (#d additional doc string)
1054 #A# start
1055     '...'  '../..'
1056     '....' '../../..'
1057     'BG'   '& exit'
1058     'C'    '| wc -l'
1059     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
1060     'H'    '| head'
1061     'Hl'   ' --help |& less -r'    #d (Display help in pager)
1062     'L'    '| less'
1063     'LL'   '|& less -r'
1064     'M'    '| most'
1065     'N'    '&>/dev/null'           #d (No Output)
1066     'R'    '| tr A-z N-za-m'       #d (ROT13)
1067     'SL'   '| sort | less'
1068     'S'    '| sort -u'
1069     'T'    '| tail'
1070     'V'    '|& vim -'
1071 #A# end
1072     'co'   './configure && make && sudo make install'
1073 )
1074
1075 function zleiab () {
1076     emulate -L zsh
1077     setopt extendedglob
1078     local MATCH
1079
1080     LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
1081     LBUFFER+=${abk[$MATCH]:-$MATCH}
1082 }
1083
1084 zle -N zleiab
1085
1086 function help-show-abk () {
1087   zle -M "$(print "Available abbreviations for expansion:"; print -a -C 2 ${(kv)abk})"
1088 }
1089
1090 zle -N help-show-abk
1091
1092 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1093 function insert-datestamp () { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1094 zle -N insert-datestamp
1095
1096 # press esc-m for inserting last typed word again (thanks to caphuso!)
1097 function insert-last-typed-word () { zle insert-last-word -- 0 -1 };
1098 zle -N insert-last-typed-word;
1099
1100 function grml-zsh-fg () {
1101   if (( ${#jobstates} )); then
1102     zle .push-input
1103     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1104     BUFFER="${BUFFER}fg"
1105     zle .accept-line
1106   else
1107     zle -M 'No background jobs. Doing nothing.'
1108   fi
1109 }
1110 zle -N grml-zsh-fg
1111
1112 # run command line as user root via sudo:
1113 function sudo-command-line () {
1114     [[ -z $BUFFER ]] && zle up-history
1115     if [[ $BUFFER != sudo\ * ]]; then
1116         BUFFER="sudo $BUFFER"
1117         CURSOR=$(( CURSOR+5 ))
1118     fi
1119 }
1120 zle -N sudo-command-line
1121
1122 ### jump behind the first word on the cmdline.
1123 ### useful to add options.
1124 function jump_after_first_word () {
1125     local words
1126     words=(${(z)BUFFER})
1127
1128     if (( ${#words} <= 1 )) ; then
1129         CURSOR=${#BUFFER}
1130     else
1131         CURSOR=${#${words[1]}}
1132     fi
1133 }
1134 zle -N jump_after_first_word
1135
1136 #f5# Create directory under cursor or the selected area
1137 function inplaceMkDirs () {
1138     # Press ctrl-xM to create the directory under the cursor or the selected area.
1139     # To select an area press ctrl-@ or ctrl-space and use the cursor.
1140     # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
1141     # directory does not exist yet -> press ctrl-XM and problem solved
1142     local PATHTOMKDIR
1143     if ((REGION_ACTIVE==1)); then
1144         local F=$MARK T=$CURSOR
1145         if [[ $F -gt $T ]]; then
1146             F=${CURSOR}
1147             T=${MARK}
1148         fi
1149         # get marked area from buffer and eliminate whitespace
1150         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
1151         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
1152     else
1153         local bufwords iword
1154         bufwords=(${(z)LBUFFER})
1155         iword=${#bufwords}
1156         bufwords=(${(z)BUFFER})
1157         PATHTOMKDIR="${(Q)bufwords[iword]}"
1158     fi
1159     [[ -z "${PATHTOMKDIR}" ]] && return 1
1160     PATHTOMKDIR=${~PATHTOMKDIR}
1161     if [[ -e "${PATHTOMKDIR}" ]]; then
1162         zle -M " path already exists, doing nothing"
1163     else
1164         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
1165         zle end-of-line
1166     fi
1167 }
1168
1169 zle -N inplaceMkDirs
1170
1171 #v1# set number of lines to display per page
1172 HELP_LINES_PER_PAGE=20
1173 #v1# set location of help-zle cache file
1174 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
1175 # helper function for help-zle, actually generates the help text
1176 function help_zle_parse_keybindings () {
1177     emulate -L zsh
1178     setopt extendedglob
1179     unsetopt ksharrays  #indexing starts at 1
1180
1181     #v1# choose files that help-zle will parse for keybindings
1182     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
1183
1184     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
1185         local load_cache=0
1186         local f
1187         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
1188         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
1189     fi
1190
1191     #fill with default keybindings, possibly to be overwriten in a file later
1192     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
1193     local -A help_zle_keybindings
1194     help_zle_keybindings['<Ctrl>@']="set MARK"
1195     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
1196     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
1197     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
1198     help_zle_keybindings['<Ctrl>_']="undo"
1199     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
1200     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
1201     help_zle_keybindings['<Ctrl>e']="goto end of line"
1202     help_zle_keybindings['<Ctrl>t']="transpose charaters"
1203     help_zle_keybindings['<Alt>t']="transpose words"
1204     help_zle_keybindings['<Alt>s']="spellcheck word"
1205     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
1206     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
1207     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
1208     help_zle_keybindings["<Alt>'"]="quote line"
1209     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
1210     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
1211     help_zle_keybindings['<Alt>u']="make next word Uppercase"
1212     help_zle_keybindings['<Alt>l']="make next word lowercase"
1213     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
1214     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
1215     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
1216     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
1217     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
1218     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
1219     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
1220     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
1221     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
1222
1223     #init global variables
1224     unset help_zle_lines help_zle_sln
1225     typeset -g -a help_zle_lines
1226     typeset -g help_zle_sln=1
1227
1228     local k v f cline
1229     local lastkeybind_desc contents     #last description starting with #k# that we found
1230     local num_lines_elapsed=0            #number of lines between last description and keybinding
1231     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
1232     for f in $HELPZLE_KEYBINDING_FILES; do
1233         [[ -r "$f" ]] || continue   #not readable ? skip it
1234         contents="$(<$f)"
1235         for cline in "${(f)contents}"; do
1236             #zsh pattern: matches lines like: #k# ..............
1237             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
1238                 lastkeybind_desc="$match[*]"
1239                 num_lines_elapsed=0
1240             #zsh pattern: matches lines that set a keybinding using bind2map, bindkey or compdef -k
1241             #             ignores lines that are commentend out
1242             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
1243             elif [[ "$cline" == [^#]#(bind2maps[[:space:]](*)-s|bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
1244                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
1245                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
1246                     #substitute keybinding string with something readable
1247                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
1248                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
1249                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
1250                     help_zle_keybindings[${k}]=$lastkeybind_desc
1251                 fi
1252                 lastkeybind_desc=""
1253             else
1254               ((num_lines_elapsed++))
1255             fi
1256         done
1257     done
1258     unset contents
1259     #calculate length of keybinding column
1260     local kstrlen=0
1261     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
1262     #convert the assoc array into preformated lines, which we are able to sort
1263     for k v in ${(kv)help_zle_keybindings[@]}; do
1264         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
1265         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
1266     done
1267     #sort lines alphabetically
1268     help_zle_lines=("${(i)help_zle_lines[@]}")
1269     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
1270     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
1271     zcompile $HELP_ZLE_CACHE_FILE
1272 }
1273 typeset -g help_zle_sln
1274 typeset -g -a help_zle_lines
1275
1276 # Provides (partially autogenerated) help on keybindings and the zsh line editor
1277 function help-zle () {
1278     emulate -L zsh
1279     unsetopt ksharrays  #indexing starts at 1
1280     #help lines already generated ? no ? then do it
1281     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
1282     #already displayed all lines ? go back to the start
1283     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
1284     local sln=$help_zle_sln
1285     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
1286     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
1287     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
1288 }
1289 zle -N help-zle
1290
1291 ## complete word from currently visible Screen or Tmux buffer.
1292 if check_com -c screen || check_com -c tmux; then
1293     function _complete_screen_display () {
1294         [[ "$TERM" != "screen" ]] && return 1
1295
1296         local TMPFILE=$(mktemp)
1297         local -U -a _screen_display_wordlist
1298         trap "rm -f $TMPFILE" EXIT
1299
1300         # fill array with contents from screen hardcopy
1301         if ((${+TMUX})); then
1302             #works, but crashes tmux below version 1.4
1303             #luckily tmux -V option to ask for version, was also added in 1.4
1304             tmux -V &>/dev/null || return
1305             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1306         else
1307             screen -X hardcopy $TMPFILE
1308             # screen sucks, it dumps in latin1, apparently always. so recode it
1309             # to system charset
1310             check_com recode && recode latin1 $TMPFILE
1311         fi
1312         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1313         # remove PREFIX to be completed from that array
1314         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1315         compadd -a _screen_display_wordlist
1316     }
1317     #m# k CTRL-x\,\,\,S Complete word from GNU screen buffer
1318     bindkey -r "^xS"
1319     compdef -k _complete_screen_display complete-word '^xS'
1320 fi
1321
1322 # Load a few more functions and tie them to widgets, so they can be bound:
1323
1324 function zrcautozle () {
1325     emulate -L zsh
1326     local fnc=$1
1327     zrcautoload $fnc && zle -N $fnc
1328 }
1329
1330 function zrcgotwidget () {
1331     (( ${+widgets[$1]} ))
1332 }
1333
1334 function zrcgotkeymap () {
1335     [[ -n ${(M)keymaps:#$1} ]]
1336 }
1337
1338 zrcautozle insert-files
1339 zrcautozle edit-command-line
1340 zrcautozle insert-unicode-char
1341 if zrcautoload history-search-end; then
1342     zle -N history-beginning-search-backward-end history-search-end
1343     zle -N history-beginning-search-forward-end  history-search-end
1344 fi
1345 zle -C hist-complete complete-word _generic
1346 zstyle ':completion:hist-complete:*' completer _history
1347
1348 # The actual terminal setup hooks and bindkey-calls:
1349
1350 # An array to note missing features to ease diagnosis in case of problems.
1351 typeset -ga grml_missing_features
1352
1353 function zrcbindkey () {
1354     if (( ARGC )) && zrcgotwidget ${argv[-1]}; then
1355         bindkey "$@"
1356     fi
1357 }
1358
1359 function bind2maps () {
1360     local i sequence widget
1361     local -a maps
1362
1363     while [[ "$1" != "--" ]]; do
1364         maps+=( "$1" )
1365         shift
1366     done
1367     shift
1368
1369     if [[ "$1" == "-s" ]]; then
1370         shift
1371         sequence="$1"
1372     else
1373         sequence="${key[$1]}"
1374     fi
1375     widget="$2"
1376
1377     [[ -z "$sequence" ]] && return 1
1378
1379     for i in "${maps[@]}"; do
1380         zrcbindkey -M "$i" "$sequence" "$widget"
1381     done
1382 }
1383
1384 if (( ${+terminfo[smkx]} )) && (( ${+terminfo[rmkx]} )); then
1385     function zle-smkx () {
1386         emulate -L zsh
1387         printf '%s' ${terminfo[smkx]}
1388     }
1389     function zle-rmkx () {
1390         emulate -L zsh
1391         printf '%s' ${terminfo[rmkx]}
1392     }
1393     function zle-line-init () {
1394         zle-smkx
1395     }
1396     function zle-line-finish () {
1397         zle-rmkx
1398     }
1399     zle -N zle-line-init
1400     zle -N zle-line-finish
1401 else
1402     for i in {s,r}mkx; do
1403         (( ${+terminfo[$i]} )) || grml_missing_features+=($i)
1404     done
1405     unset i
1406 fi
1407
1408 typeset -A key
1409 key=(
1410     Home     "${terminfo[khome]}"
1411     End      "${terminfo[kend]}"
1412     Insert   "${terminfo[kich1]}"
1413     Delete   "${terminfo[kdch1]}"
1414     Up       "${terminfo[kcuu1]}"
1415     Down     "${terminfo[kcud1]}"
1416     Left     "${terminfo[kcub1]}"
1417     Right    "${terminfo[kcuf1]}"
1418     PageUp   "${terminfo[kpp]}"
1419     PageDown "${terminfo[knp]}"
1420     BackTab  "${terminfo[kcbt]}"
1421 )
1422
1423 # Guidelines for adding key bindings:
1424 #
1425 #   - Do not add hardcoded escape sequences, to enable non standard key
1426 #     combinations such as Ctrl-Meta-Left-Cursor. They are not easily portable.
1427 #
1428 #   - Adding Ctrl characters, such as '^b' is okay; note that '^b' and '^B' are
1429 #     the same key.
1430 #
1431 #   - All keys from the $key[] mapping are obviously okay.
1432 #
1433 #   - Most terminals send "ESC x" when Meta-x is pressed. Thus, sequences like
1434 #     '\ex' are allowed in here as well.
1435
1436 bind2maps emacs             -- Home   beginning-of-somewhere
1437 bind2maps       viins vicmd -- Home   vi-beginning-of-line
1438 bind2maps emacs             -- End    end-of-somewhere
1439 bind2maps       viins vicmd -- End    vi-end-of-line
1440 bind2maps emacs viins       -- Insert overwrite-mode
1441 bind2maps             vicmd -- Insert vi-insert
1442 bind2maps emacs             -- Delete delete-char
1443 bind2maps       viins vicmd -- Delete vi-delete-char
1444 bind2maps emacs viins vicmd -- Up     up-line-or-search
1445 bind2maps emacs viins vicmd -- Down   down-line-or-search
1446 bind2maps emacs             -- Left   backward-char
1447 bind2maps       viins vicmd -- Left   vi-backward-char
1448 bind2maps emacs             -- Right  forward-char
1449 bind2maps       viins vicmd -- Right  vi-forward-char
1450 #k# Perform abbreviation expansion
1451 bind2maps emacs viins       -- -s '^x.' zleiab
1452 #k# Display list of abbreviations that would expand
1453 bind2maps emacs viins       -- -s '^xb' help-show-abk
1454 #k# mkdir -p <dir> from string under cursor or marked area
1455 bind2maps emacs viins       -- -s '^xM' inplaceMkDirs
1456 #k# display help for keybindings and ZLE
1457 bind2maps emacs viins       -- -s '^xz' help-zle
1458 #k# Insert files and test globbing
1459 bind2maps emacs viins       -- -s "^xf" insert-files
1460 #k# Edit the current line in \kbd{\$EDITOR}
1461 bind2maps emacs viins       -- -s '\ee' edit-command-line
1462 #k# search history backward for entry beginning with typed text
1463 bind2maps emacs viins       -- -s '^xp' history-beginning-search-backward-end
1464 #k# search history forward for entry beginning with typed text
1465 bind2maps emacs viins       -- -s '^xP' history-beginning-search-forward-end
1466 #k# search history backward for entry beginning with typed text
1467 bind2maps emacs viins       -- PageUp history-beginning-search-backward-end
1468 #k# search history forward for entry beginning with typed text
1469 bind2maps emacs viins       -- PageDown history-beginning-search-forward-end
1470 bind2maps emacs viins       -- -s "^x^h" commit-to-history
1471 #k# Kill left-side word or everything up to next slash
1472 bind2maps emacs viins       -- -s '\ev' slash-backward-kill-word
1473 #k# Kill left-side word or everything up to next slash
1474 bind2maps emacs viins       -- -s '\e^h' slash-backward-kill-word
1475 #k# Kill left-side word or everything up to next slash
1476 bind2maps emacs viins       -- -s '\e^?' slash-backward-kill-word
1477 # Do history expansion on space:
1478 bind2maps emacs viins       -- -s ' ' magic-space
1479 #k# Trigger menu-complete
1480 bind2maps emacs viins       -- -s '\ei' menu-complete  # menu completion via esc-i
1481 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1482 bind2maps emacs viins       -- -s '^ed' insert-datestamp
1483 #k# Insert last typed word
1484 bind2maps emacs viins       -- -s "\em" insert-last-typed-word
1485 #k# A smart shortcut for \kbd{fg<enter>}
1486 bind2maps emacs viins       -- -s '^z' grml-zsh-fg
1487 #k# prepend the current command with "sudo"
1488 bind2maps emacs viins       -- -s "^os" sudo-command-line
1489 #k# jump to after first word (for adding options)
1490 bind2maps emacs viins       -- -s '^x1' jump_after_first_word
1491 #k# complete word from history with menu
1492 bind2maps emacs viins       -- -s "^x^x" hist-complete
1493
1494 # insert unicode character
1495 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
1496 # See for example http://unicode.org/charts/ for unicode characters code
1497 #k# Insert Unicode character
1498 bind2maps emacs viins       -- -s '^xi' insert-unicode-char
1499
1500 # use the new *-pattern-* widgets for incremental history search
1501 if zrcgotwidget history-incremental-pattern-search-backward; then
1502     for seq wid in '^r' history-incremental-pattern-search-backward \
1503                    '^s' history-incremental-pattern-search-forward
1504     do
1505         bind2maps emacs viins vicmd -- -s $seq $wid
1506     done
1507     builtin unset -v seq wid
1508 fi
1509
1510 if zrcgotkeymap menuselect; then
1511     #m# k Shift-tab Perform backwards menu completion
1512     bind2maps menuselect -- BackTab reverse-menu-complete
1513
1514     #k# menu selection: pick item but stay in the menu
1515     bind2maps menuselect -- -s '\e^M' accept-and-menu-complete
1516     # also use + and INSERT since it's easier to press repeatedly
1517     bind2maps menuselect -- -s '+' accept-and-menu-complete
1518     bind2maps menuselect -- Insert accept-and-menu-complete
1519
1520     # accept a completion and try to complete again by using menu
1521     # completion; very useful with completing directories
1522     # by using 'undo' one's got a simple file browser
1523     bind2maps menuselect -- -s '^o' accept-and-infer-next-history
1524 fi
1525
1526 # Finally, here are still a few hardcoded escape sequences; Special sequences
1527 # like Ctrl-<Cursor-key> etc do suck a fair bit, because they are not
1528 # standardised and most of the time are not available in a terminals terminfo
1529 # entry.
1530 #
1531 # While we do not encourage adding bindings like these, we will keep these for
1532 # backward compatibility.
1533
1534 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on
1535 ## the command line.
1536 # URxvt sequences:
1537 bind2maps emacs viins vicmd -- -s '\eOc' forward-word
1538 bind2maps emacs viins vicmd -- -s '\eOd' backward-word
1539 # These are for xterm:
1540 bind2maps emacs viins vicmd -- -s '\e[1;5C' forward-word
1541 bind2maps emacs viins vicmd -- -s '\e[1;5D' backward-word
1542 ## the same for alt-left-arrow and alt-right-arrow
1543 # URxvt again:
1544 bind2maps emacs viins vicmd -- -s '\e\e[C' forward-word
1545 bind2maps emacs viins vicmd -- -s '\e\e[D' backward-word
1546 # Xterm again:
1547 bind2maps emacs viins vicmd -- -s '^[[1;3C' forward-word
1548 bind2maps emacs viins vicmd -- -s '^[[1;3D' backward-word
1549 # Also try ESC Left/Right:
1550 bind2maps emacs viins vicmd -- -s '\e'${key[Right]} forward-word
1551 bind2maps emacs viins vicmd -- -s '\e'${key[Left]}  backward-word
1552
1553 # autoloading
1554
1555 zrcautoload zmv
1556 zrcautoload zed
1557
1558 # we don't want to quote/espace URLs on our own...
1559 # if autoload -U url-quote-magic ; then
1560 #    zle -N self-insert url-quote-magic
1561 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
1562 # else
1563 #    print 'Notice: no url-quote-magic available :('
1564 # fi
1565 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
1566
1567 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
1568 alias run-help >&/dev/null && unalias run-help
1569 for rh in run-help{,-git,-ip,-openssl,-p4,-sudo,-svk,-svn}; do
1570     zrcautoload $rh
1571 done; unset rh
1572
1573 # command not found handling
1574
1575 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1576 function command_not_found_handler () {
1577     emulate -L zsh
1578     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1579         ${GRML_ZSH_CNF_HANDLER} $1
1580     fi
1581     return 1
1582 }
1583
1584 # history
1585
1586 #v#
1587 HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1588 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1589 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1590
1591 # dirstack handling
1592
1593 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1594 DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1595
1596 if zstyle -T ':grml:chpwd:dirstack' enable; then
1597     typeset -gaU GRML_PERSISTENT_DIRSTACK
1598     function grml_dirstack_filter () {
1599         local -a exclude
1600         local filter entry
1601         if zstyle -s ':grml:chpwd:dirstack' filter filter; then
1602             $filter $1 && return 0
1603         fi
1604         if zstyle -a ':grml:chpwd:dirstack' exclude exclude; then
1605             for entry in "${exclude[@]}"; do
1606                 [[ $1 == ${~entry} ]] && return 0
1607             done
1608         fi
1609         return 1
1610     }
1611
1612     function chpwd () {
1613         (( ZSH_SUBSHELL )) && return
1614         (( $DIRSTACKSIZE <= 0 )) && return
1615         [[ -z $DIRSTACKFILE ]] && return
1616         grml_dirstack_filter $PWD && return
1617         GRML_PERSISTENT_DIRSTACK=(
1618             $PWD "${(@)GRML_PERSISTENT_DIRSTACK[1,$DIRSTACKSIZE]}"
1619         )
1620         builtin print -l ${GRML_PERSISTENT_DIRSTACK} >! ${DIRSTACKFILE}
1621     }
1622
1623     if [[ -f ${DIRSTACKFILE} ]]; then
1624         # Enabling NULL_GLOB via (N) weeds out any non-existing
1625         # directories from the saved dir-stack file.
1626         dirstack=( ${(f)"$(< $DIRSTACKFILE)"}(N) )
1627         # "cd -" won't work after login by just setting $OLDPWD, so
1628         [[ -d $dirstack[1] ]] && cd -q $dirstack[1] && cd -q $OLDPWD
1629     fi
1630
1631     if zstyle -t ':grml:chpwd:dirstack' filter-on-load; then
1632         for i in "${dirstack[@]}"; do
1633             if ! grml_dirstack_filter "$i"; then
1634                 GRML_PERSISTENT_DIRSTACK=(
1635                     "${GRML_PERSISTENT_DIRSTACK[@]}"
1636                     $i
1637                 )
1638             fi
1639         done
1640     else
1641         GRML_PERSISTENT_DIRSTACK=( "${dirstack[@]}" )
1642     fi
1643 fi
1644
1645 # directory based profiles
1646
1647 if is433 ; then
1648
1649 # chpwd_profiles(): Directory Profiles, Quickstart:
1650 #
1651 # In .zshrc.local:
1652 #
1653 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1654 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1655 #   chpwd_profiles
1656 #
1657 # For details see the `grmlzshrc.5' manual page.
1658 function chpwd_profiles () {
1659     local profile context
1660     local -i reexecute
1661
1662     context=":chpwd:profiles:$PWD"
1663     zstyle -s "$context" profile profile || profile='default'
1664     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1665
1666     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1667         typeset -g CHPWD_PROFILE
1668         local CHPWD_PROFILES_INIT=1
1669         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1670     elif [[ $profile != $CHPWD_PROFILE ]]; then
1671         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1672             && chpwd_leave_profile_${CHPWD_PROFILE}
1673     fi
1674     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1675         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1676     fi
1677
1678     CHPWD_PROFILE="${profile}"
1679     return 0
1680 }
1681
1682 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1683
1684 fi # is433
1685
1686 # Prompt setup for grml:
1687
1688 # set colors for use in prompts (modern zshs allow for the use of %F{red}foo%f
1689 # in prompts to get a red "foo" embedded, but it's good to keep these for
1690 # backwards compatibility).
1691 if is437; then
1692     BLUE="%F{blue}"
1693     RED="%F{red}"
1694     GREEN="%F{green}"
1695     CYAN="%F{cyan}"
1696     MAGENTA="%F{magenta}"
1697     YELLOW="%F{yellow}"
1698     WHITE="%F{white}"
1699     NO_COLOR="%f"
1700 elif zrcautoload colors && colors 2>/dev/null ; then
1701     BLUE="%{${fg[blue]}%}"
1702     RED="%{${fg_bold[red]}%}"
1703     GREEN="%{${fg[green]}%}"
1704     CYAN="%{${fg[cyan]}%}"
1705     MAGENTA="%{${fg[magenta]}%}"
1706     YELLOW="%{${fg[yellow]}%}"
1707     WHITE="%{${fg[white]}%}"
1708     NO_COLOR="%{${reset_color}%}"
1709 else
1710     BLUE=$'%{\e[1;34m%}'
1711     RED=$'%{\e[1;31m%}'
1712     GREEN=$'%{\e[1;32m%}'
1713     CYAN=$'%{\e[1;36m%}'
1714     WHITE=$'%{\e[1;37m%}'
1715     MAGENTA=$'%{\e[1;35m%}'
1716     YELLOW=$'%{\e[1;33m%}'
1717     NO_COLOR=$'%{\e[0m%}'
1718 fi
1719
1720 # First, the easy ones: PS2..4:
1721
1722 # secondary prompt, printed when the shell needs more information to complete a
1723 # command.
1724 PS2='\`%_> '
1725 # selection prompt used within a select loop.
1726 PS3='?# '
1727 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1728 PS4='+%N:%i:%_> '
1729
1730 # Some additional features to use with our prompt:
1731 #
1732 #    - battery status
1733 #    - debian_chroot
1734 #    - vcs_info setup and version specific fixes
1735
1736 # display battery status on right side of prompt using 'GRML_DISPLAY_BATTERY=1' in .zshrc.pre
1737
1738 function battery () {
1739 if [[ $GRML_DISPLAY_BATTERY -gt 0 ]] ; then
1740     if islinux ; then
1741         batterylinux
1742     elif isopenbsd ; then
1743         batteryopenbsd
1744     elif isfreebsd ; then
1745         batteryfreebsd
1746     elif isdarwin ; then
1747         batterydarwin
1748     else
1749         #not yet supported
1750         GRML_DISPLAY_BATTERY=0
1751     fi
1752 fi
1753 }
1754
1755 function batterylinux () {
1756 GRML_BATTERY_LEVEL=''
1757 local batteries bat capacity
1758 batteries=( /sys/class/power_supply/BAT*(N) )
1759 if (( $#batteries > 0 )) ; then
1760     for bat in $batteries ; do
1761         if [[ -e $bat/capacity ]]; then
1762             capacity=$(< $bat/capacity)
1763         else
1764             typeset -F energy_full=$(< $bat/energy_full)
1765             typeset -F energy_now=$(< $bat/energy_now)
1766             typeset -i capacity=$(( 100 * $energy_now / $energy_full))
1767         fi
1768         case $(< $bat/status) in
1769         Charging)
1770             GRML_BATTERY_LEVEL+=" ^"
1771             ;;
1772         Discharging)
1773             if (( capacity < 20 )) ; then
1774                 GRML_BATTERY_LEVEL+=" !v"
1775             else
1776                 GRML_BATTERY_LEVEL+=" v"
1777             fi
1778             ;;
1779         *) # Full, Unknown
1780             GRML_BATTERY_LEVEL+=" ="
1781             ;;
1782         esac
1783         GRML_BATTERY_LEVEL+="${capacity}%%"
1784     done
1785 fi
1786 }
1787
1788 function batteryopenbsd () {
1789 GRML_BATTERY_LEVEL=''
1790 local bat batfull batwarn batnow num
1791 for num in 0 1 ; do
1792     bat=$(sysctl -n hw.sensors.acpibat${num} 2>/dev/null)
1793     if [[ -n $bat ]]; then
1794         batfull=${"$(sysctl -n hw.sensors.acpibat${num}.amphour0)"%% *}
1795         batwarn=${"$(sysctl -n hw.sensors.acpibat${num}.amphour1)"%% *}
1796         batnow=${"$(sysctl -n hw.sensors.acpibat${num}.amphour3)"%% *}
1797         case "$(sysctl -n hw.sensors.acpibat${num}.raw0)" in
1798             *" discharging"*)
1799                 if (( batnow < batwarn )) ; then
1800                     GRML_BATTERY_LEVEL+=" !v"
1801                 else
1802                     GRML_BATTERY_LEVEL+=" v"
1803                 fi
1804                 ;;
1805             *" charging"*)
1806                 GRML_BATTERY_LEVEL+=" ^"
1807                 ;;
1808             *)
1809                 GRML_BATTERY_LEVEL+=" ="
1810                 ;;
1811         esac
1812         GRML_BATTERY_LEVEL+="${$(( 100 * batnow / batfull ))%%.*}%%"
1813     fi
1814 done
1815 }
1816
1817 function batteryfreebsd () {
1818 GRML_BATTERY_LEVEL=''
1819 local num
1820 local -A table
1821 for num in 0 1 ; do
1822     table=( ${=${${${${${(M)${(f)"$(acpiconf -i $num 2>&1)"}:#(State|Remaining capacity):*}%%( ##|%)}//:[ $'\t']##/@}// /-}//@/ }} )
1823     if [[ -n $table ]] && [[ $table[State] != "not-present" ]] ; then
1824         case $table[State] in
1825             *discharging*)
1826                 if (( $table[Remaining-capacity] < 20 )) ; then
1827                     GRML_BATTERY_LEVEL+=" !v"
1828                 else
1829                     GRML_BATTERY_LEVEL+=" v"
1830                 fi
1831                 ;;
1832             *charging*)
1833                 GRML_BATTERY_LEVEL+=" ^"
1834                 ;;
1835             *)
1836                 GRML_BATTERY_LEVEL+=" ="
1837                 ;;
1838         esac
1839         GRML_BATTERY_LEVEL+="$table[Remaining-capacity]%%"
1840     fi
1841 done
1842 }
1843
1844 function batterydarwin () {
1845 GRML_BATTERY_LEVEL=''
1846 local -a table
1847 table=( ${$(pmset -g ps)[(w)7,8]%%(\%|);} )
1848 if [[ -n $table[2] ]] ; then
1849     case $table[2] in
1850         charging)
1851             GRML_BATTERY_LEVEL+=" ^"
1852             ;;
1853         discharging)
1854             if (( $table[1] < 20 )) ; then
1855                 GRML_BATTERY_LEVEL+=" !v"
1856             else
1857                 GRML_BATTERY_LEVEL+=" v"
1858             fi
1859             ;;
1860         *)
1861             GRML_BATTERY_LEVEL+=" ="
1862             ;;
1863     esac
1864     GRML_BATTERY_LEVEL+="$table[1]%%"
1865 fi
1866 }
1867
1868 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1869 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1870     debian_chroot=$(</etc/debian_chroot)
1871 fi
1872
1873 # gather version control information for inclusion in a prompt
1874
1875 if zrcautoload vcs_info; then
1876     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1877     # function, which can cause a lot of trouble with our directory-based
1878     # profiles. So:
1879     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1880         function VCS_INFO_realpath () {
1881             setopt localoptions NO_shwordsplit chaselinks
1882             ( builtin cd -q $1 2> /dev/null && pwd; )
1883         }
1884     fi
1885
1886     zstyle ':vcs_info:*' max-exports 2
1887
1888     if [[ -o restricted ]]; then
1889         zstyle ':vcs_info:*' enable NONE
1890     fi
1891 fi
1892
1893 typeset -A grml_vcs_coloured_formats
1894 typeset -A grml_vcs_plain_formats
1895
1896 grml_vcs_plain_formats=(
1897     format "(%s%)-[%b] "    "zsh: %r"
1898     actionformat "(%s%)-[%b|%a] " "zsh: %r"
1899     rev-branchformat "%b:%r"
1900 )
1901
1902 grml_vcs_coloured_formats=(
1903     format "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR} "
1904     actionformat "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} "
1905     rev-branchformat "%b${RED}:${YELLOW}%r"
1906 )
1907
1908 typeset GRML_VCS_COLOUR_MODE=xxx
1909
1910 function grml_vcs_info_toggle_colour () {
1911     emulate -L zsh
1912     if [[ $GRML_VCS_COLOUR_MODE == plain ]]; then
1913         grml_vcs_info_set_formats coloured
1914     else
1915         grml_vcs_info_set_formats plain
1916     fi
1917     return 0
1918 }
1919
1920 function grml_vcs_info_set_formats () {
1921     emulate -L zsh
1922     #setopt localoptions xtrace
1923     local mode=$1 AF F BF
1924     if [[ $mode == coloured ]]; then
1925         AF=${grml_vcs_coloured_formats[actionformat]}
1926         F=${grml_vcs_coloured_formats[format]}
1927         BF=${grml_vcs_coloured_formats[rev-branchformat]}
1928         GRML_VCS_COLOUR_MODE=coloured
1929     else
1930         AF=${grml_vcs_plain_formats[actionformat]}
1931         F=${grml_vcs_plain_formats[format]}
1932         BF=${grml_vcs_plain_formats[rev-branchformat]}
1933         GRML_VCS_COLOUR_MODE=plain
1934     fi
1935
1936     zstyle ':vcs_info:*'              actionformats "$AF" "zsh: %r"
1937     zstyle ':vcs_info:*'              formats       "$F"  "zsh: %r"
1938     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat  "$BF"
1939     return 0
1940 }
1941
1942 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1943 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1944 if [[ "$TERM" == dumb ]] ; then
1945     grml_vcs_info_set_formats plain
1946 else
1947     grml_vcs_info_set_formats coloured
1948 fi
1949
1950 # Now for the fun part: The grml prompt themes in `promptsys' mode of operation
1951
1952 # This actually defines three prompts:
1953 #
1954 #    - grml
1955 #    - grml-large
1956 #    - grml-chroot
1957 #
1958 # They all share the same code and only differ with respect to which items they
1959 # contain. The main source of documentation is the `prompt_grml_help' function
1960 # below, which gets called when the user does this: prompt -h grml
1961
1962 function prompt_grml_help () {
1963     <<__EOF0__
1964   prompt grml
1965
1966     This is the prompt as used by the grml-live system <http://grml.org>. It is
1967     a rather simple one-line prompt, that by default looks something like this:
1968
1969         <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1970
1971     The prompt itself integrates with zsh's prompt themes system (as you are
1972     witnessing right now) and is configurable to a certain degree. In
1973     particular, these aspects are customisable:
1974
1975         - The items used in the prompt (e.g. you can remove \`user' from
1976           the list of activated items, which will cause the user name to
1977           be omitted from the prompt string).
1978
1979         - The attributes used with the items are customisable via strings
1980           used before and after the actual item.
1981
1982     The available items are: at, battery, change-root, date, grml-chroot,
1983     history, host, jobs, newline, path, percent, rc, rc-always, sad-smiley,
1984     shell-level, time, user, vcs
1985
1986     The actual configuration is done via zsh's \`zstyle' mechanism. The
1987     context, that is used while looking up styles is:
1988
1989         ':prompt:grml:<left-or-right>:<subcontext>'
1990
1991     Here <left-or-right> is either \`left' or \`right', signifying whether the
1992     style should affect the left or the right prompt. <subcontext> is either
1993     \`setup' or 'items:<item>', where \`<item>' is one of the available items.
1994
1995     The styles:
1996
1997         - use-rprompt (boolean): If \`true' (the default), print a sad smiley
1998           in $RPROMPT if the last command a returned non-successful error code.
1999           (This in only valid if <left-or-right> is "right"; ignored otherwise)
2000
2001         - items (list): The list of items used in the prompt. If \`vcs' is
2002           present in the list, the theme's code invokes \`vcs_info'
2003           accordingly. Default (left): rc change-root user at host path vcs
2004           percent; Default (right): sad-smiley
2005
2006     Available styles in 'items:<item>' are: pre, post. These are strings that
2007     are inserted before (pre) and after (post) the item in question. Thus, the
2008     following would cause the user name to be printed in red instead of the
2009     default blue:
2010
2011         zstyle ':prompt:grml:*:items:user' pre '%F{red}'
2012
2013     Note, that the \`post' style may remain at its default value, because its
2014     default value is '%f', which turns the foreground text attribute off (which
2015     is exactly, what is still required with the new \`pre' value).
2016 __EOF0__
2017 }
2018
2019 function prompt_grml-chroot_help () {
2020     <<__EOF0__
2021   prompt grml-chroot
2022
2023     This is a variation of the grml prompt, see: prompt -h grml
2024
2025     The main difference is the default value of the \`items' style. The rest
2026     behaves exactly the same. Here are the defaults for \`grml-chroot':
2027
2028         - left: grml-chroot user at host path percent
2029         - right: (empty list)
2030 __EOF0__
2031 }
2032
2033 function prompt_grml-large_help () {
2034     <<__EOF0__
2035   prompt grml-large
2036
2037     This is a variation of the grml prompt, see: prompt -h grml
2038
2039     The main difference is the default value of the \`items' style. In
2040     particular, this theme uses _two_ lines instead of one with the plain
2041     \`grml' theme. The rest behaves exactly the same. Here are the defaults
2042     for \`grml-large':
2043
2044         - left: rc jobs history shell-level change-root time date newline user
2045                 at host path vcs percent
2046         - right: sad-smiley
2047 __EOF0__
2048 }
2049
2050 function grml_prompt_setup () {
2051     emulate -L zsh
2052     autoload -Uz vcs_info
2053     # The following autoload is disabled for now, since this setup includes a
2054     # static version of the ‘add-zsh-hook’ function above. It needs to be
2055     # reenabled as soon as that static definition is removed again.
2056     #autoload -Uz add-zsh-hook
2057     add-zsh-hook precmd prompt_$1_precmd
2058 }
2059
2060 function prompt_grml_setup () {
2061     grml_prompt_setup grml
2062 }
2063
2064 function prompt_grml-chroot_setup () {
2065     grml_prompt_setup grml-chroot
2066 }
2067
2068 function prompt_grml-large_setup () {
2069     grml_prompt_setup grml-large
2070 }
2071
2072 # These maps define default tokens and pre-/post-decoration for items to be
2073 # used within the themes. All defaults may be customised in a context sensitive
2074 # matter by using zsh's `zstyle' mechanism.
2075 typeset -gA grml_prompt_pre_default \
2076             grml_prompt_post_default \
2077             grml_prompt_token_default \
2078             grml_prompt_token_function
2079
2080 grml_prompt_pre_default=(
2081     at                ''
2082     battery           ' '
2083     change-root       ''
2084     date              '%F{blue}'
2085     grml-chroot       '%F{red}'
2086     history           '%F{green}'
2087     host              ''
2088     jobs              '%F{cyan}'
2089     newline           ''
2090     path              '%B'
2091     percent           ''
2092     rc                '%B%F{red}'
2093     rc-always         ''
2094     sad-smiley        ''
2095     shell-level       '%F{red}'
2096     time              '%F{blue}'
2097     user              '%B%F{blue}'
2098     vcs               ''
2099 )
2100
2101 grml_prompt_post_default=(
2102     at                ''
2103     battery           ''
2104     change-root       ''
2105     date              '%f'
2106     grml-chroot       '%f '
2107     history           '%f'
2108     host              ''
2109     jobs              '%f'
2110     newline           ''
2111     path              '%b'
2112     percent           ''
2113     rc                '%f%b'
2114     rc-always         ''
2115     sad-smiley        ''
2116     shell-level       '%f'
2117     time              '%f'
2118     user              '%f%b'
2119     vcs               ''
2120 )
2121
2122 grml_prompt_token_default=(
2123     at                '@'
2124     battery           'GRML_BATTERY_LEVEL'
2125     change-root       'debian_chroot'
2126     date              '%D{%Y-%m-%d}'
2127     grml-chroot       'GRML_CHROOT'
2128     history           '{history#%!} '
2129     host              '%m '
2130     jobs              '[%j running job(s)] '
2131     newline           $'\n'
2132     path              '%40<..<%~%<< '
2133     percent           '%# '
2134     rc                '%(?..%? )'
2135     rc-always         '%?'
2136     sad-smiley        '%(?..:()'
2137     shell-level       '%(3L.+ .)'
2138     time              '%D{%H:%M:%S} '
2139     user              '%n'
2140     vcs               '0'
2141 )
2142
2143 function grml_theme_has_token () {
2144     if (( ARGC != 1 )); then
2145         printf 'usage: grml_theme_has_token <name>\n'
2146         return 1
2147     fi
2148     (( ${+grml_prompt_token_default[$1]} ))
2149 }
2150
2151 function GRML_theme_add_token_usage () {
2152     <<__EOF0__
2153   Usage: grml_theme_add_token <name> [-f|-i] <token/function> [<pre> <post>]
2154
2155     <name> is the name for the newly added token. If the \`-f' or \`-i' options
2156     are used, <token/function> is the name of the function (see below for
2157     details). Otherwise it is the literal token string to be used. <pre> and
2158     <post> are optional.
2159
2160   Options:
2161
2162     -f <function>   Use a function named \`<function>' each time the token
2163                     is to be expanded.
2164
2165     -i <function>   Use a function named \`<function>' to initialise the
2166                     value of the token _once_ at runtime.
2167
2168     The functions are called with one argument: the token's new name. The
2169     return value is expected in the \$REPLY parameter. The use of these
2170     options is mutually exclusive.
2171
2172     There is a utility function \`grml_theme_has_token', which you can use
2173     to test if a token exists before trying to add it. This can be a guard
2174     for situations in which a \`grml_theme_add_token' call may happen more
2175     than once.
2176
2177   Example:
2178
2179     To add a new token \`day' that expands to the current weekday in the
2180     current locale in green foreground colour, use this:
2181
2182       grml_theme_add_token day '%D{%A}' '%F{green}' '%f'
2183
2184     Another example would be support for \$VIRTUAL_ENV:
2185
2186       function virtual_env_prompt () {
2187         REPLY=\${VIRTUAL_ENV+\${VIRTUAL_ENV:t} }
2188       }
2189       grml_theme_add_token virtual-env -f virtual_env_prompt
2190
2191     After that, you will be able to use a changed \`items' style to
2192     assemble your prompt.
2193 __EOF0__
2194 }
2195
2196 function grml_theme_add_token () {
2197     emulate -L zsh
2198     local name token pre post
2199     local -i init funcall
2200
2201     if (( ARGC == 0 )); then
2202         GRML_theme_add_token_usage
2203         return 0
2204     fi
2205
2206     init=0
2207     funcall=0
2208     pre=''
2209     post=''
2210     name=$1
2211     shift
2212     if [[ $1 == '-f' ]]; then
2213         funcall=1
2214         shift
2215     elif [[ $1 == '-i' ]]; then
2216         init=1
2217         shift
2218     fi
2219
2220     if (( ARGC == 0 )); then
2221         printf '
2222 grml_theme_add_token: No token-string/function-name provided!\n\n'
2223         GRML_theme_add_token_usage
2224         return 1
2225     fi
2226     token=$1
2227     shift
2228     if (( ARGC != 0 && ARGC != 2 )); then
2229         printf '
2230 grml_theme_add_token: <pre> and <post> need to by specified _both_!\n\n'
2231         GRML_theme_add_token_usage
2232         return 1
2233     fi
2234     if (( ARGC )); then
2235         pre=$1
2236         post=$2
2237         shift 2
2238     fi
2239
2240     if grml_theme_has_token $name; then
2241         printf '
2242 grml_theme_add_token: Token `%s'\'' exists! Giving up!\n\n' $name
2243         GRML_theme_add_token_usage
2244         return 2
2245     fi
2246     if (( init )); then
2247         $token $name
2248         token=$REPLY
2249     fi
2250     grml_prompt_pre_default[$name]=$pre
2251     grml_prompt_post_default[$name]=$post
2252     if (( funcall )); then
2253         grml_prompt_token_function[$name]=$token
2254         grml_prompt_token_default[$name]=23
2255     else
2256         grml_prompt_token_default[$name]=$token
2257     fi
2258 }
2259
2260 function grml_typeset_and_wrap () {
2261     emulate -L zsh
2262     local target="$1"
2263     local new="$2"
2264     local left="$3"
2265     local right="$4"
2266
2267     if (( ${+parameters[$new]} )); then
2268         typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
2269     fi
2270 }
2271
2272 function grml_prompt_addto () {
2273     emulate -L zsh
2274     local target="$1"
2275     local lr it apre apost new v
2276     local -a items
2277     shift
2278
2279     [[ $target == PS1 ]] && lr=left || lr=right
2280     zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
2281     typeset -g "${target}="
2282     for it in "${items[@]}"; do
2283         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
2284             || apre=${grml_prompt_pre_default[$it]}
2285         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" post apost \
2286             || apost=${grml_prompt_post_default[$it]}
2287         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
2288             || new=${grml_prompt_token_default[$it]}
2289         typeset -g "${target}=${(P)target}${apre}"
2290         if (( ${+grml_prompt_token_function[$it]} )); then
2291             ${grml_prompt_token_function[$it]} $it
2292             typeset -g "${target}=${(P)target}${REPLY}"
2293         else
2294             case $it in
2295             battery)
2296                 grml_typeset_and_wrap $target $new '' ''
2297                 ;;
2298             change-root)
2299                 grml_typeset_and_wrap $target $new '(' ')'
2300                 ;;
2301             grml-chroot)
2302                 if [[ -n ${(P)new} ]]; then
2303                     typeset -g "${target}=${(P)target}(CHROOT)"
2304                 fi
2305                 ;;
2306             vcs)
2307                 v="vcs_info_msg_${new}_"
2308                 if (( ! vcscalled )); then
2309                     vcs_info
2310                     vcscalled=1
2311                 fi
2312                 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
2313                     typeset -g "${target}=${(P)target}${(P)v}"
2314                 fi
2315                 ;;
2316             *) typeset -g "${target}=${(P)target}${new}" ;;
2317             esac
2318         fi
2319         typeset -g "${target}=${(P)target}${apost}"
2320     done
2321 }
2322
2323 function prompt_grml_precmd () {
2324     emulate -L zsh
2325     local grmltheme=grml
2326     local -a left_items right_items
2327     left_items=(rc change-root user at host path vcs percent)
2328     right_items=(sad-smiley)
2329
2330     prompt_grml_precmd_worker
2331 }
2332
2333 function prompt_grml-chroot_precmd () {
2334     emulate -L zsh
2335     local grmltheme=grml-chroot
2336     local -a left_items right_items
2337     left_items=(grml-chroot user at host path percent)
2338     right_items=()
2339
2340     prompt_grml_precmd_worker
2341 }
2342
2343 function prompt_grml-large_precmd () {
2344     emulate -L zsh
2345     local grmltheme=grml-large
2346     local -a left_items right_items
2347     left_items=(rc jobs history shell-level change-root time date newline
2348                 user at host path vcs percent)
2349     right_items=(sad-smiley)
2350
2351     prompt_grml_precmd_worker
2352 }
2353
2354 function prompt_grml_precmd_worker () {
2355     emulate -L zsh
2356     local -i vcscalled=0
2357
2358     grml_prompt_addto PS1 "${left_items[@]}"
2359     if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
2360         grml_prompt_addto RPS1 "${right_items[@]}"
2361     fi
2362 }
2363
2364 function grml_prompt_fallback () {
2365     setopt prompt_subst
2366     local p0 p1
2367
2368     p0="${RED}%(?..%? )${WHITE}${debian_chroot:+($debian_chroot)}"
2369     p1="${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "'${vcs_info_msg_0_}'"%# "
2370     if (( EUID == 0 )); then
2371         PROMPT="${BLUE}${p0}${RED}${p1}"
2372     else
2373         PROMPT="${RED}${p0}${BLUE}${p1}"
2374     fi
2375 }
2376
2377 if zrcautoload promptinit && promptinit 2>/dev/null ; then
2378     # Since we define the required functions in here and not in files in
2379     # $fpath, we need to stick the theme's name into `$prompt_themes'
2380     # ourselves, since promptinit does not pick them up otherwise.
2381     prompt_themes+=( grml grml-chroot grml-large )
2382     # Also, keep the array sorted...
2383     prompt_themes=( "${(@on)prompt_themes}" )
2384 else
2385     print 'Notice: no promptinit available :('
2386     grml_prompt_fallback
2387     function precmd () { (( ${+functions[vcs_info]} )) && vcs_info; }
2388 fi
2389
2390 if is437; then
2391     # The prompt themes use modern features of zsh, that require at least
2392     # version 4.3.7 of the shell. Use the fallback otherwise.
2393     if [[ $GRML_DISPLAY_BATTERY -gt 0 ]]; then
2394         zstyle ':prompt:grml:right:setup' items sad-smiley battery
2395         add-zsh-hook precmd battery
2396     fi
2397     if [[ "$TERM" == dumb ]] ; then
2398         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" pre ''
2399         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" post ' '
2400         for i in rc user path jobs history date time shell-level; do
2401             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" pre ''
2402             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" post ''
2403         done
2404         unset i
2405         zstyle ':prompt:grml(|-large|-chroot):right:setup' use-rprompt false
2406     elif (( EUID == 0 )); then
2407         zstyle ':prompt:grml(|-large|-chroot):*:items:user' pre '%B%F{red}'
2408     fi
2409
2410     # Finally enable one of the prompts.
2411     if [[ -n $GRML_CHROOT ]]; then
2412         prompt grml-chroot
2413     elif [[ $GRMLPROMPT -gt 0 ]]; then
2414         prompt grml-large
2415     else
2416         prompt grml
2417     fi
2418 else
2419     grml_prompt_fallback
2420     function precmd () { (( ${+functions[vcs_info]} )) && vcs_info; }
2421 fi
2422
2423 # Terminal-title wizardry
2424
2425 function ESC_print () {
2426     info_print $'\ek' $'\e\\' "$@"
2427 }
2428 function set_title () {
2429     info_print  $'\e]0;' $'\a' "$@"
2430 }
2431
2432 function info_print () {
2433     local esc_begin esc_end
2434     esc_begin="$1"
2435     esc_end="$2"
2436     shift 2
2437     printf '%s' ${esc_begin}
2438     printf '%s' "$*"
2439     printf '%s' "${esc_end}"
2440 }
2441
2442 function grml_reset_screen_title () {
2443     # adjust title of xterm
2444     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
2445     [[ ${NOTITLE:-} -gt 0 ]] && return 0
2446     case $TERM in
2447         (xterm*|rxvt*)
2448             set_title ${(%):-"%n@%m: %~"}
2449             ;;
2450     esac
2451 }
2452
2453 function grml_vcs_to_screen_title () {
2454     if [[ $TERM == screen* ]] ; then
2455         if [[ -n ${vcs_info_msg_1_} ]] ; then
2456             ESC_print ${vcs_info_msg_1_}
2457         else
2458             ESC_print "zsh"
2459         fi
2460     fi
2461 }
2462
2463 function grml_maintain_name () {
2464     # set hostname if not running on host with name 'grml'
2465     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
2466        NAME="@$HOSTNAME"
2467     fi
2468 }
2469
2470 function grml_cmd_to_screen_title () {
2471     # get the name of the program currently running and hostname of local
2472     # machine set screen window title if running in a screen
2473     if [[ "$TERM" == screen* ]] ; then
2474         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME"
2475         ESC_print ${CMD}
2476     fi
2477 }
2478
2479 function grml_control_xterm_title () {
2480     case $TERM in
2481         (xterm*|rxvt*)
2482             set_title "${(%):-"%n@%m:"}" "$1"
2483             ;;
2484     esac
2485 }
2486
2487 # The following autoload is disabled for now, since this setup includes a
2488 # static version of the ‘add-zsh-hook’ function above. It needs to be
2489 # reenabled as soon as that static definition is removed again.
2490 #zrcautoload add-zsh-hook || add-zsh-hook () { :; }
2491 if [[ $NOPRECMD -eq 0 ]]; then
2492     add-zsh-hook precmd grml_reset_screen_title
2493     add-zsh-hook precmd grml_vcs_to_screen_title
2494     add-zsh-hook preexec grml_maintain_name
2495     add-zsh-hook preexec grml_cmd_to_screen_title
2496     if [[ $NOTITLE -eq 0 ]]; then
2497         add-zsh-hook preexec grml_control_xterm_title
2498     fi
2499 fi
2500
2501 # 'hash' some often used directories
2502 #d# start
2503 hash -d deb=/var/cache/apt/archives
2504 hash -d doc=/usr/share/doc
2505 hash -d linux=/lib/modules/$(command uname -r)/build/
2506 hash -d log=/var/log
2507 hash -d slog=/var/log/syslog
2508 hash -d src=/usr/src
2509 hash -d www=/var/www
2510 #d# end
2511
2512 # some aliases
2513 if check_com -c screen ; then
2514     if [[ $UID -eq 0 ]] ; then
2515         if [[ -r /etc/grml/screenrc ]]; then
2516             alias screen='screen -c /etc/grml/screenrc'
2517         fi
2518     elif [[ ! -r $HOME/.screenrc ]] ; then
2519         if [[ -r /etc/grml/screenrc_grml ]]; then
2520             alias screen='screen -c /etc/grml/screenrc_grml'
2521         else
2522             if [[ -r /etc/grml/screenrc ]]; then
2523                 alias screen='screen -c /etc/grml/screenrc'
2524             fi
2525         fi
2526     fi
2527 fi
2528
2529 # do we have GNU ls with color-support?
2530 if [[ "$TERM" != dumb ]]; then
2531     #a1# List files with colors (\kbd{ls \ldots})
2532     alias ls="command ls ${ls_options:+${ls_options[*]}}"
2533     #a1# List all files, with colors (\kbd{ls -la \ldots})
2534     alias la="command ls -la ${ls_options:+${ls_options[*]}}"
2535     #a1# List files with long colored list, without dotfiles (\kbd{ls -l \ldots})
2536     alias ll="command ls -l ${ls_options:+${ls_options[*]}}"
2537     #a1# List files with long colored list, human readable sizes (\kbd{ls -hAl \ldots})
2538     alias lh="command ls -hAl ${ls_options:+${ls_options[*]}}"
2539     #a1# List files with long colored list, append qualifier to filenames (\kbd{ls -l \ldots})\\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2540     alias l="command ls -l ${ls_options:+${ls_options[*]}}"
2541 else
2542     alias la='command ls -la'
2543     alias ll='command ls -l'
2544     alias lh='command ls -hAl'
2545     alias l='command ls -l'
2546 fi
2547
2548 if [[ -r /proc/mdstat ]]; then
2549     alias mdstat='cat /proc/mdstat'
2550 fi
2551
2552 alias ...='cd ../../'
2553
2554 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2555 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2556     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2557 fi
2558
2559 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2560 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2561 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2562
2563 # make sure it is not assigned yet
2564 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
2565 function utf2iso () {
2566     if isutfenv ; then
2567         local ENV
2568         for ENV in $(env | command grep -i '.utf') ; do
2569             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2570         done
2571     fi
2572 }
2573
2574 # make sure it is not assigned yet
2575 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
2576 function iso2utf () {
2577     if ! isutfenv ; then
2578         local ENV
2579         for ENV in $(env | command grep -i '\.iso') ; do
2580             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2581         done
2582     fi
2583 }
2584
2585 # especially for roadwarriors using GNU screen and ssh:
2586 if ! check_com asc &>/dev/null ; then
2587   function asc () { autossh -t "$@" 'screen -RdU' }
2588   compdef asc=ssh
2589 fi
2590
2591 #f1# Hints for the use of zsh on grml
2592 function zsh-help () {
2593     print "$bg[white]$fg[black]
2594 zsh-help - hints for use of zsh on grml
2595 =======================================$reset_color"
2596
2597     print '
2598 Main configuration of zsh happens in /etc/zsh/zshrc.
2599 That file is part of the package grml-etc-core, if you want to
2600 use them on a non-grml-system just get the tar.gz from
2601 http://deb.grml.org/ or (preferably) get it from the git repository:
2602
2603   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2604
2605 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2606 The file is still there, but it is empty for backwards compatibility.
2607
2608 For your own changes use these two files:
2609     $HOME/.zshrc.pre
2610     $HOME/.zshrc.local
2611
2612 The former is sourced very early in our zshrc, the latter is sourced
2613 very lately.
2614
2615 System wide configuration without touching configuration files of grml
2616 can take place in /etc/zsh/zshrc.local.
2617
2618 For information regarding zsh start at http://grml.org/zsh/
2619
2620 Take a look at grml'\''s zsh refcard:
2621 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2622
2623 Check out the main zsh refcard:
2624 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2625
2626 And of course visit the zsh-lovers:
2627 % man zsh-lovers
2628
2629 You can adjust some options through environment variables when
2630 invoking zsh without having to edit configuration files.
2631 Basically meant for bash users who are not used to the power of
2632 the zsh yet. :)
2633
2634   "NOCOR=1    zsh" => deactivate automatic correction
2635   "NOMENU=1   zsh" => do not use auto menu completion
2636                       (note: use ctrl-d for completion instead!)
2637   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2638   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2639                       preexec() and precmd() completely
2640   "GRML_DISPLAY_BATTERY=1  zsh"
2641                    => activate battery status on right side of prompt (WIP)
2642   "COMMAND_NOT_FOUND=1 zsh"
2643                    => Enable a handler if an external command was not found
2644                       The command called in the handler can be altered by setting
2645                       the GRML_ZSH_CNF_HANDLER variable, the default is:
2646                       "/usr/share/command-not-found/command-not-found"
2647
2648 A value greater than 0 is enables a feature; a value equal to zero
2649 disables it. If you like one or the other of these settings, you can
2650 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2651 zshrc.'
2652
2653     print "
2654 $bg[white]$fg[black]
2655 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2656 Enjoy your grml system with the zsh!$reset_color"
2657 }
2658
2659 # debian stuff
2660 if [[ -r /etc/debian_version ]] ; then
2661     if [[ -z "$GRML_NO_APT_ALIASES" ]]; then
2662         #a3# Execute \kbd{apt-cache search}
2663         alias acs='apt-cache search'
2664         #a3# Execute \kbd{apt-cache show}
2665         alias acsh='apt-cache show'
2666         #a3# Execute \kbd{apt-cache policy}
2667         alias acp='apt-cache policy'
2668         #a3# Execute \kbd{apt-get dist-upgrade}
2669         salias adg="apt-get dist-upgrade"
2670         #a3# Execute \kbd{apt-get install}
2671         salias agi="apt-get install"
2672         #a3# Execute \kbd{aptitude install}
2673         salias ati="aptitude install"
2674         #a3# Execute \kbd{apt-get upgrade}
2675         salias ag="apt-get upgrade"
2676         #a3# Execute \kbd{apt-get update}
2677         salias au="apt-get update"
2678         #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2679         salias -a up="aptitude update ; aptitude safe-upgrade"
2680         #a3# Execute \kbd{dpkg-buildpackage}
2681         alias dbp='dpkg-buildpackage'
2682         #a3# Execute \kbd{grep-excuses}
2683         alias ge='grep-excuses'
2684     fi
2685
2686     # get a root shell as normal user in live-cd mode:
2687     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2688        alias su="sudo su"
2689     fi
2690
2691 fi
2692
2693 # use /var/log/syslog iff present, fallback to journalctl otherwise
2694 if [ -e /var/log/syslog ] ; then
2695   #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog || journalctl}
2696   salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2697   #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog || journalctl}
2698   salias tlog="tail -f /var/log/syslog"    # follow the syslog
2699 elif check_com -c journalctl ; then
2700   salias llog="journalctl"
2701   salias tlog="journalctl -f"
2702 fi
2703
2704 # sort installed Debian-packages by size
2705 if check_com -c dpkg-query ; then
2706     #a3# List installed Debian-packages sorted by size
2707     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
2708 fi
2709
2710 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2711 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
2712     if check_com -c wodim; then
2713         function cdrecord () {
2714             <<__EOF0__
2715 cdrecord is not provided under its original name by Debian anymore.
2716 See #377109 in the BTS of Debian for more details.
2717
2718 Please use the wodim binary instead
2719 __EOF0__
2720             return 1
2721         }
2722     fi
2723 fi
2724
2725 if isgrmlcd; then
2726     # No core dumps: important for a live-cd-system
2727     limit -s core 0
2728 fi
2729
2730 # grmlstuff
2731 function grmlstuff () {
2732 # people should use 'grml-x'!
2733     if check_com -c 915resolution; then
2734         function 855resolution () {
2735             echo "Please use 915resolution as resolution modifying tool for Intel \
2736 graphic chipset."
2737             return -1
2738         }
2739     fi
2740
2741     #a1# Output version of running grml
2742     alias grml-version='cat /etc/grml_version'
2743
2744     if check_com -c grml-debootstrap ; then
2745         function debian2hd () {
2746             echo "Installing debian to harddisk is possible by using grml-debootstrap."
2747             return 1
2748         }
2749     fi
2750 }
2751
2752 # now run the functions
2753 isgrml && checkhome
2754 is4    && isgrml    && grmlstuff
2755 is4    && grmlcomp
2756
2757 # keephack
2758 is4 && xsource "/etc/zsh/keephack"
2759
2760 # wonderful idea of using "e" glob qualifier by Peter Stephenson
2761 # You use it as follows:
2762 # $ NTREF=/reference/file
2763 # $ ls -l *(e:nt:)
2764 # This lists all the files in the current directory newer than the reference file.
2765 # You can also specify the reference file inline; note quotes:
2766 # $ ls -l *(e:'nt ~/.zshenv':)
2767 is4 && function nt () {
2768     if [[ -n $1 ]] ; then
2769         local NTREF=${~1}
2770     fi
2771     [[ $REPLY -nt $NTREF ]]
2772 }
2773
2774 # shell functions
2775
2776 #f1# Reload an autoloadable function
2777 function freload () { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2778 compdef _functions freload
2779
2780 #
2781 # Usage:
2782 #
2783 #      e.g.:   a -> b -> c -> d  ....
2784 #
2785 #      sll a
2786 #
2787 #
2788 #      if parameter is given with leading '=', lookup $PATH for parameter and resolve that
2789 #
2790 #      sll =java
2791 #
2792 #      Note: limit for recursive symlinks on linux:
2793 #            http://git.kernel.org/cgit/linux/kernel/git/torvalds/linux.git/tree/fs/namei.c?id=refs/heads/master#l808
2794 #            This limits recursive symlink follows to 8,
2795 #            while limiting consecutive symlinks to 40.
2796 #
2797 #      When resolving and displaying information about symlinks, no check is made
2798 #      that the displayed information does make any sense on your OS.
2799 #      We leave that decission to the user.
2800 #
2801 #      The zstat module is used to detect symlink loops. zstat is available since zsh4.
2802 #      With an older zsh you will need to abort with <C-c> in that case.
2803 #      When a symlink loop is detected, a warning ist printed and further processing is stopped.
2804 #
2805 #      Module zstat is loaded by default in grml zshrc, no extra action needed for that.
2806 #
2807 #      Known bugs:
2808 #      If you happen to come accross a symlink that points to a destination on an other partition
2809 #      with the same inode number, that will be marked as symlink loop though it is not.
2810 #      Two hints for this situation:
2811 #      I)  Play lottery the same day, as you seem to be rather lucky right now.
2812 #      II) Send patches.
2813 #
2814 #      return status:
2815 #      0 upon success
2816 #      1 file/dir not accesible
2817 #      2 symlink loop detected
2818 #
2819 #f1# List symlinks in detail (more detailed version of 'readlink -f', 'whence -s' and 'namei -l')
2820 function sll () {
2821     if [[ -z ${1} ]] ; then
2822         printf 'Usage: %s <symlink(s)>\n' "${0}"
2823         return 1
2824     fi
2825
2826     local file jumpd curdir
2827     local -i RTN LINODE i
2828     local -a SEENINODES
2829     curdir="${PWD}"
2830     RTN=0
2831
2832     for file in "${@}" ; do
2833         SEENINODES=()
2834         ls -l "${file:a}"   || RTN=1
2835
2836         while [[ -h "$file" ]] ; do
2837             if is4 ; then
2838                 LINODE=$(zstat -L +inode "${file}")
2839                 for i in ${SEENINODES} ; do
2840                     if (( ${i} == ${LINODE} )) ; then
2841                         builtin cd "${curdir}"
2842                         print "link loop detected, aborting!"
2843                         return 2
2844                     fi
2845                 done
2846                 SEENINODES+=${LINODE}
2847             fi
2848             jumpd="${file:h}"
2849             file="${file:t}"
2850
2851             if [[ -d ${jumpd} ]] ; then
2852                 builtin cd "${jumpd}"  || RTN=1
2853             fi
2854             file=$(readlink "$file")
2855
2856             jumpd="${file:h}"
2857             file="${file:t}"
2858
2859             if [[ -d ${jumpd} ]] ; then
2860                 builtin cd "${jumpd}"  || RTN=1
2861             fi
2862
2863             ls -l "${PWD}/${file}"     || RTN=1
2864         done
2865         shift 1
2866         if (( ${#} >= 1 )) ; then
2867             print ""
2868         fi
2869         builtin cd "${curdir}"
2870     done
2871     return ${RTN}
2872 }
2873
2874 # TODO: Is it supported to use pager settings like this?
2875 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2876 # with respect to wordsplitting. (ie. ${=PAGER})
2877 if check_com -c $PAGER ; then
2878     #f3# View Debian's changelog of given package(s)
2879     function dchange () {
2880         emulate -L zsh
2881         [[ -z "$1" ]] && printf 'Usage: %s <package_name(s)>\n' "$0" && return 1
2882
2883         local package
2884         for package in "$@" ; do
2885             if [[ -r /usr/share/doc/${package}/changelog.Debian.gz ]] ; then
2886                 $PAGER /usr/share/doc/${package}/changelog.Debian.gz
2887             elif [[ -r /usr/share/doc/${package}/changelog.gz ]] ; then
2888                 $PAGER /usr/share/doc/${package}/changelog.gz
2889             elif [[ -r /usr/share/doc/${package}/changelog ]] ; then
2890                 $PAGER /usr/share/doc/${package}/changelog
2891             else
2892                 if check_com -c aptitude ; then
2893                     echo "No changelog for package $package found, using aptitude to retrieve it."
2894                     aptitude changelog "$package"
2895                 elif check_com -c apt-get ; then
2896                     echo "No changelog for package $package found, using apt-get to retrieve it."
2897                     apt-get changelog "$package"
2898                 else
2899                     echo "No changelog for package $package found, sorry."
2900                 fi
2901             fi
2902         done
2903     }
2904     function _dchange () { _files -W /usr/share/doc -/ }
2905     compdef _dchange dchange
2906
2907     #f3# View Debian's NEWS of a given package
2908     function dnews () {
2909         emulate -L zsh
2910         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2911             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2912         else
2913             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2914                 $PAGER /usr/share/doc/$1/NEWS.gz
2915             else
2916                 echo "No NEWS file for package $1 found, sorry."
2917                 return 1
2918             fi
2919         fi
2920     }
2921     function _dnews () { _files -W /usr/share/doc -/ }
2922     compdef _dnews dnews
2923
2924     #f3# View Debian's copyright of a given package
2925     function dcopyright () {
2926         emulate -L zsh
2927         if [[ -r /usr/share/doc/$1/copyright ]] ; then
2928             $PAGER /usr/share/doc/$1/copyright
2929         else
2930             echo "No copyright file for package $1 found, sorry."
2931             return 1
2932         fi
2933     }
2934     function _dcopyright () { _files -W /usr/share/doc -/ }
2935     compdef _dcopyright dcopyright
2936
2937     #f3# View upstream's changelog of a given package
2938     function uchange () {
2939         emulate -L zsh
2940         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2941             $PAGER /usr/share/doc/$1/changelog.gz
2942         else
2943             echo "No changelog for package $1 found, sorry."
2944             return 1
2945         fi
2946     }
2947     function _uchange () { _files -W /usr/share/doc -/ }
2948     compdef _uchange uchange
2949 fi
2950
2951 # zsh profiling
2952 function profile () {
2953     ZSH_PROFILE_RC=1 zsh "$@"
2954 }
2955
2956 #f1# Edit an alias via zle
2957 function edalias () {
2958     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2959 }
2960 compdef _aliases edalias
2961
2962 #f1# Edit a function via zle
2963 function edfunc () {
2964     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2965 }
2966 compdef _functions edfunc
2967
2968 # use it e.g. via 'Restart apache2'
2969 #m# f6 Start() \kbd{service \em{process}}\quad\kbd{start}
2970 #m# f6 Restart() \kbd{service \em{process}}\quad\kbd{restart}
2971 #m# f6 Stop() \kbd{service \em{process}}\quad\kbd{stop}
2972 #m# f6 Reload() \kbd{service \em{process}}\quad\kbd{reload}
2973 #m# f6 Force-Reload() \kbd{service \em{process}}\quad\kbd{force-reload}
2974 #m# f6 Status() \kbd{service \em{process}}\quad\kbd{status}
2975 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2976     function __start_stop () {
2977         local action_="${1:l}"  # e.g Start/Stop/Restart
2978         local service_="$2"
2979         local param_="$3"
2980
2981         local service_target_="$(readlink /etc/init.d/$service_)"
2982         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2983             # runit
2984             case "${action_}" in
2985                 start) if [[ ! -e /etc/service/$service_ ]]; then
2986                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2987                        else
2988                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2989                        fi ;;
2990                 # there is no reload in runits sysv emulation
2991                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2992                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2993             esac
2994         else
2995             # sysv/sysvinit-utils, upstart
2996             if check_com -c service ; then
2997               $SUDO service "$service_" "${action_}" "$param_"
2998             else
2999               $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
3000             fi
3001         fi
3002     }
3003
3004     function _grmlinitd () {
3005         local -a scripts
3006         scripts=( /etc/init.d/*(x:t) )
3007         _describe "service startup script" scripts
3008     }
3009
3010     for i in Start Restart Stop Force-Reload Reload Status ; do
3011         eval "function $i () { __start_stop $i \"\$1\" \"\$2\" ; }"
3012         compdef _grmlinitd $i
3013     done
3014     builtin unset -v i
3015 fi
3016
3017 #f1# Provides useful information on globbing
3018 function H-Glob () {
3019     echo -e "
3020     /      directories
3021     .      plain files
3022     @      symbolic links
3023     =      sockets
3024     p      named pipes (FIFOs)
3025     *      executable plain files (0100)
3026     %      device files (character or block special)
3027     %b     block special files
3028     %c     character special files
3029     r      owner-readable files (0400)
3030     w      owner-writable files (0200)
3031     x      owner-executable files (0100)
3032     A      group-readable files (0040)
3033     I      group-writable files (0020)
3034     E      group-executable files (0010)
3035     R      world-readable files (0004)
3036     W      world-writable files (0002)
3037     X      world-executable files (0001)
3038     s      setuid files (04000)
3039     S      setgid files (02000)
3040     t      files with the sticky bit (01000)
3041
3042   print *(m-1)          # Files modified up to a day ago
3043   print *(a1)           # Files accessed a day ago
3044   print *(@)            # Just symlinks
3045   print *(Lk+50)        # Files bigger than 50 kilobytes
3046   print *(Lk-50)        # Files smaller than 50 kilobytes
3047   print **/*.c          # All *.c files recursively starting in \$PWD
3048   print **/*.c~file.c   # Same as above, but excluding 'file.c'
3049   print (foo|bar).*     # Files starting with 'foo' or 'bar'
3050   print *~*.*           # All Files that do not contain a dot
3051   chmod 644 *(.^x)      # make all plain non-executable files publically readable
3052   print -l *(.c|.h)     # Lists *.c and *.h
3053   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
3054   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
3055 }
3056 alias help-zshglob=H-Glob
3057
3058 # grep for running process, like: 'any vim'
3059 function any () {
3060     emulate -L zsh
3061     unsetopt KSH_ARRAYS
3062     if [[ -z "$1" ]] ; then
3063         echo "any - grep for process(es) by keyword" >&2
3064         echo "Usage: any <keyword>" >&2 ; return 1
3065     else
3066         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
3067     fi
3068 }
3069
3070
3071 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
3072 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
3073 [[ -r /proc/1/maps ]] && \
3074 function deswap () {
3075     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
3076     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
3077     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
3078 }
3079
3080 # a wrapper for vim, that deals with title setting
3081 #   VIM_OPTIONS
3082 #       set this array to a set of options to vim you always want
3083 #       to have set when calling vim (in .zshrc.local), like:
3084 #           VIM_OPTIONS=( -p )
3085 #       This will cause vim to send every file given on the
3086 #       commandline to be send to it's own tab (needs vim7).
3087 if check_com vim; then
3088     function vim () {
3089         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
3090     }
3091 fi
3092
3093 ssl_hashes=( sha512 sha256 sha1 md5 )
3094
3095 for sh in ${ssl_hashes}; do
3096     eval 'ssl-cert-'${sh}'() {
3097         emulate -L zsh
3098         if [[ -z $1 ]] ; then
3099             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
3100             return 1
3101         fi
3102         openssl x509 -noout -fingerprint -'${sh}' -in $1
3103     }'
3104 done; unset sh
3105
3106 function ssl-cert-fingerprints () {
3107     emulate -L zsh
3108     local i
3109     if [[ -z $1 ]] ; then
3110         printf 'usage: ssl-cert-fingerprints <file>\n'
3111         return 1
3112     fi
3113     for i in ${ssl_hashes}
3114         do ssl-cert-$i $1;
3115     done
3116 }
3117
3118 function ssl-cert-info () {
3119     emulate -L zsh
3120     if [[ -z $1 ]] ; then
3121         printf 'usage: ssl-cert-info <file>\n'
3122         return 1
3123     fi
3124     openssl x509 -noout -text -in $1
3125     ssl-cert-fingerprints $1
3126 }
3127
3128 # make sure our environment is clean regarding colors
3129 builtin unset -v BLUE RED GREEN CYAN YELLOW MAGENTA WHITE
3130
3131 # "persistent history"
3132 # just write important commands you always need to $GRML_IMPORTANT_COMMANDS
3133 # defaults for backward compatibility to ~/.important_commands
3134 if [[ -r ~/.important_commands ]] ; then
3135     GRML_IMPORTANT_COMMANDS=~/.important_commands
3136 else
3137     GRML_IMPORTANT_COMMANDS=${GRML_IMPORTANT_COMMANDS:-${ZDOTDIR:-${HOME}}/.important_commands}
3138 fi
3139 [[ -r ${GRML_IMPORTANT_COMMANDS} ]] && builtin fc -R ${GRML_IMPORTANT_COMMANDS}
3140
3141 # load the lookup subsystem if it's available on the system
3142 zrcautoload lookupinit && lookupinit
3143
3144 # variables
3145
3146 # set terminal property (used e.g. by msgid-chooser)
3147 export COLORTERM="yes"
3148
3149 # aliases
3150
3151 # general
3152 #a2# Execute \kbd{du -sch}
3153 [[ -n "$GRML_NO_SMALL_ALIASES" ]] || alias da='du -sch'
3154
3155 # listing stuff
3156 #a2# Execute \kbd{ls -lSrah}
3157 alias dir="command ls -lSrah"
3158 #a2# Only show dot-directories
3159 alias lad='command ls -d .*(/)'
3160 #a2# Only show dot-files
3161 alias lsa='command ls -a .*(.)'
3162 #a2# Only files with setgid/setuid/sticky flag
3163 alias lss='command ls -l *(s,S,t)'
3164 #a2# Only show symlinks
3165 alias lsl='command ls -l *(@)'
3166 #a2# Display only executables
3167 alias lsx='command ls -l *(*)'
3168 #a2# Display world-{readable,writable,executable} files
3169 alias lsw='command ls -ld *(R,W,X.^ND/)'
3170 #a2# Display the ten biggest files
3171 alias lsbig="command ls -flh *(.OL[1,10])"
3172 #a2# Only show directories
3173 alias lsd='command ls -d *(/)'
3174 #a2# Only show empty directories
3175 alias lse='command ls -d *(/^F)'
3176 #a2# Display the ten newest files
3177 alias lsnew="command ls -rtlh *(D.om[1,10])"
3178 #a2# Display the ten oldest files
3179 alias lsold="command ls -rtlh *(D.Om[1,10])"
3180 #a2# Display the ten smallest files
3181 alias lssmall="command ls -Srl *(.oL[1,10])"
3182 #a2# Display the ten newest directories and ten newest .directories
3183 alias lsnewdir="command ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
3184 #a2# Display the ten oldest directories and ten oldest .directories
3185 alias lsolddir="command ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
3186
3187 # some useful aliases
3188 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir \$OLDCWD}
3189 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
3190
3191 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3192 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3193 #a2# scp with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3194 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3195
3196 # work around non utf8 capable software in utf environment via $LANG and luit
3197 if check_com isutfenv && check_com luit ; then
3198     if check_com -c mrxvt ; then
3199         isutfenv && [[ -n "$LANG" ]] && \
3200             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3201     fi
3202
3203     if check_com -c aterm ; then
3204         isutfenv && [[ -n "$LANG" ]] && \
3205             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3206     fi
3207
3208     if check_com -c centericq ; then
3209         isutfenv && [[ -n "$LANG" ]] && \
3210             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3211     fi
3212 fi
3213
3214 # useful functions
3215
3216 #f5# Backup \kbd{file_or_folder {\rm to} file_or_folder\_timestamp}
3217 function bk () {
3218     emulate -L zsh
3219     local current_date=$(date -u "+%Y-%m-%dT%H:%M:%SZ")
3220     local clean keep move verbose result all to_bk
3221     setopt extended_glob
3222     keep=1
3223     while getopts ":hacmrv" opt; do
3224         case $opt in
3225             a) (( all++ ));;
3226             c) unset move clean && (( ++keep ));;
3227             m) unset keep clean && (( ++move ));;
3228             r) unset move keep && (( ++clean ));;
3229             v) verbose="-v";;
3230             h) <<__EOF0__
3231 bk [-hcmv] FILE [FILE ...]
3232 bk -r [-av] [FILE [FILE ...]]
3233 Backup a file or folder in place and append the timestamp
3234 Remove backups of a file or folder, or all backups in the current directory
3235
3236 Usage:
3237 -h    Display this help text
3238 -c    Keep the file/folder as is, create a copy backup using cp(1) (default)
3239 -m    Move the file/folder, using mv(1)
3240 -r    Remove backups of the specified file or directory, using rm(1). If none
3241       is provided, remove all backups in the current directory.
3242 -a    Remove all (even hidden) backups.
3243 -v    Verbose
3244
3245 The -c, -r and -m options are mutually exclusive. If specified at the same time,
3246 the last one is used.
3247
3248 The return code is the sum of all cp/mv/rm return codes.
3249 __EOF0__
3250 return 0;;
3251             \?) bk -h >&2; return 1;;
3252         esac
3253     done
3254     shift "$((OPTIND-1))"
3255     if (( keep > 0 )); then
3256         if islinux || isfreebsd; then
3257             for to_bk in "$@"; do
3258                 cp $verbose -a "${to_bk%/}" "${to_bk%/}_$current_date"
3259                 (( result += $? ))
3260             done
3261         else
3262             for to_bk in "$@"; do
3263                 cp $verbose -pR "${to_bk%/}" "${to_bk%/}_$current_date"
3264                 (( result += $? ))
3265             done
3266         fi
3267     elif (( move > 0 )); then
3268         while (( $# > 0 )); do
3269             mv $verbose "${1%/}" "${1%/}_$current_date"
3270             (( result += $? ))
3271             shift
3272         done
3273     elif (( clean > 0 )); then
3274         if (( $# > 0 )); then
3275             for to_bk in "$@"; do
3276                 rm $verbose -rf "${to_bk%/}"_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z
3277                 (( result += $? ))
3278             done
3279         else
3280             if (( all > 0 )); then
3281                 rm $verbose -rf *_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z(D)
3282             else
3283                 rm $verbose -rf *_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z
3284             fi
3285             (( result += $? ))
3286         fi
3287     fi
3288     return $result
3289 }
3290
3291 #f5# cd to directoy and list files
3292 function cl () {
3293     emulate -L zsh
3294     cd $1 && ls -a
3295 }
3296
3297 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
3298 function cd () {
3299     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
3300         [[ ! -e ${1:h} ]] && return 1
3301         print "Correcting ${1} to ${1:h}"
3302         builtin cd ${1:h}
3303     else
3304         builtin cd "$@"
3305     fi
3306 }
3307
3308 #f5# Create Directoy and \kbd{cd} to it
3309 function mkcd () {
3310     if (( ARGC != 1 )); then
3311         printf 'usage: mkcd <new-directory>\n'
3312         return 1;
3313     fi
3314     if [[ ! -d "$1" ]]; then
3315         command mkdir -p "$1"
3316     else
3317         printf '`%s'\'' already exists: cd-ing.\n' "$1"
3318     fi
3319     builtin cd "$1"
3320 }
3321
3322 #f5# Create temporary directory and \kbd{cd} to it
3323 function cdt () {
3324     builtin cd "$(mktemp -d)"
3325     builtin pwd
3326 }
3327
3328 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
3329 function accessed () {
3330     emulate -L zsh
3331     print -l -- *(a-${1:-1})
3332 }
3333
3334 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
3335 function changed () {
3336     emulate -L zsh
3337     print -l -- *(c-${1:-1})
3338 }
3339
3340 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
3341 function modified () {
3342     emulate -L zsh
3343     print -l -- *(m-${1:-1})
3344 }
3345 # modified() was named new() in earlier versions, add an alias for backwards compatibility
3346 check_com new || alias new=modified
3347
3348 # use colors when GNU grep with color-support
3349 if (( $#grep_options > 0 )); then
3350     o=${grep_options:+"${grep_options[*]}"}
3351     #a2# Execute \kbd{grep -{}-color=auto}
3352     alias grep='grep '$o
3353     alias egrep='egrep '$o
3354     unset o
3355 fi
3356
3357 # Translate DE<=>EN
3358 # 'translate' looks up a word in a file with language-to-language
3359 # translations (field separator should be " : "). A typical wordlist looks
3360 # like the following:
3361 #  | english-word : german-translation
3362 # It's also only possible to translate english to german but not reciprocal.
3363 # Use the following oneliner to reverse the sort order:
3364 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3365 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3366 #f5# Translates a word
3367 function trans () {
3368     emulate -L zsh
3369     case "$1" in
3370         -[dD]*)
3371             translate -l de-en $2
3372             ;;
3373         -[eE]*)
3374             translate -l en-de $2
3375             ;;
3376         *)
3377             echo "Usage: $0 { -D | -E }"
3378             echo "         -D == German to English"
3379             echo "         -E == English to German"
3380     esac
3381 }
3382
3383 # Usage: simple-extract <file>
3384 # Using option -d deletes the original archive file.
3385 #f5# Smart archive extractor
3386 function simple-extract () {
3387     emulate -L zsh
3388     setopt extended_glob noclobber
3389     local ARCHIVE DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
3390     local RC=0
3391     zparseopts -D -E "d=DELETE_ORIGINAL"
3392     for ARCHIVE in "${@}"; do
3393         case $ARCHIVE in
3394             *(tar.bz2|tbz2|tbz))
3395                 DECOMP_CMD="tar -xvjf -"
3396                 USES_STDIN=true
3397                 USES_STDOUT=false
3398                 ;;
3399             *(tar.gz|tgz))
3400                 DECOMP_CMD="tar -xvzf -"
3401                 USES_STDIN=true
3402                 USES_STDOUT=false
3403                 ;;
3404             *(tar.xz|txz|tar.lzma))
3405                 DECOMP_CMD="tar -xvJf -"
3406                 USES_STDIN=true
3407                 USES_STDOUT=false
3408                 ;;
3409             *tar)
3410                 DECOMP_CMD="tar -xvf -"
3411                 USES_STDIN=true
3412                 USES_STDOUT=false
3413                 ;;
3414             *rar)
3415                 DECOMP_CMD="unrar x"
3416                 USES_STDIN=false
3417                 USES_STDOUT=false
3418                 ;;
3419             *lzh)
3420                 DECOMP_CMD="lha x"
3421                 USES_STDIN=false
3422                 USES_STDOUT=false
3423                 ;;
3424             *7z)
3425                 DECOMP_CMD="7z x"
3426                 USES_STDIN=false
3427                 USES_STDOUT=false
3428                 ;;
3429             *(zip|jar))
3430                 DECOMP_CMD="unzip"
3431                 USES_STDIN=false
3432                 USES_STDOUT=false
3433                 ;;
3434             *deb)
3435                 DECOMP_CMD="ar -x"
3436                 USES_STDIN=false
3437                 USES_STDOUT=false
3438                 ;;
3439             *bz2)
3440                 DECOMP_CMD="bzip2 -d -c -"
3441                 USES_STDIN=true
3442                 USES_STDOUT=true
3443                 ;;
3444             *(gz|Z))
3445                 DECOMP_CMD="gzip -d -c -"
3446                 USES_STDIN=true
3447                 USES_STDOUT=true
3448                 ;;
3449             *(xz|lzma))
3450                 DECOMP_CMD="xz -d -c -"
3451                 USES_STDIN=true
3452                 USES_STDOUT=true
3453                 ;;
3454             *)
3455                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
3456                 RC=$((RC+1))
3457                 continue
3458                 ;;
3459         esac
3460
3461         if ! check_com ${DECOMP_CMD[(w)1]}; then
3462             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
3463             RC=$((RC+2))
3464             continue
3465         fi
3466
3467         GZTARGET="${ARCHIVE:t:r}"
3468         if [[ -f $ARCHIVE ]] ; then
3469
3470             print "Extracting '$ARCHIVE' ..."
3471             if $USES_STDIN; then
3472                 if $USES_STDOUT; then
3473                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
3474                 else
3475                     ${=DECOMP_CMD} < "$ARCHIVE"
3476                 fi
3477             else
3478                 if $USES_STDOUT; then
3479                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
3480                 else
3481                     ${=DECOMP_CMD} "$ARCHIVE"
3482                 fi
3483             fi
3484             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
3485
3486         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
3487             if check_com curl; then
3488                 WGET_CMD="curl -L -s -o -"
3489             elif check_com wget; then
3490                 WGET_CMD="wget -q -O -"
3491             elif check_com fetch; then
3492                 WGET_CMD="fetch -q -o -"
3493             else
3494                 print "ERROR: neither wget, curl nor fetch is installed" >&2
3495                 RC=$((RC+4))
3496                 continue
3497             fi
3498             print "Downloading and Extracting '$ARCHIVE' ..."
3499             if $USES_STDIN; then
3500                 if $USES_STDOUT; then
3501                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
3502                     RC=$((RC+$?))
3503                 else
3504                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
3505                     RC=$((RC+$?))
3506                 fi
3507             else
3508                 if $USES_STDOUT; then
3509                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
3510                 else
3511                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
3512                 fi
3513             fi
3514
3515         else
3516             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
3517             RC=$((RC+8))
3518         fi
3519     done
3520     return $RC
3521 }
3522
3523 function __archive_or_uri () {
3524     _alternative \
3525         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
3526         '_urls:Remote Archives:_urls'
3527 }
3528
3529 function _simple_extract () {
3530     _arguments \
3531         '-d[delete original archivefile after extraction]' \
3532         '*:Archive Or Uri:__archive_or_uri'
3533 }
3534 compdef _simple_extract simple-extract
3535 [[ -n "$GRML_NO_SMALL_ALIASES" ]] || alias se=simple-extract
3536
3537 #f5# Change the xterm title from within GNU-screen
3538 function xtrename () {
3539     emulate -L zsh
3540     if [[ $1 != "-f" ]] ; then
3541         if [[ -z ${DISPLAY} ]] ; then
3542             printf 'xtrename only makes sense in X11.\n'
3543             return 1
3544         fi
3545     else
3546         shift
3547     fi
3548     if [[ -z $1 ]] ; then
3549         printf 'usage: xtrename [-f] "title for xterm"\n'
3550         printf '  renames the title of xterm from _within_ screen.\n'
3551         printf '  also works without screen.\n'
3552         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3553         return 0
3554     fi
3555     print -n "\eP\e]0;${1}\C-G\e\\"
3556     return 0
3557 }
3558
3559 # Create small urls via http://goo.gl using curl(1).
3560 # API reference: https://code.google.com/apis/urlshortener/
3561 function zurl () {
3562     emulate -L zsh
3563     setopt extended_glob
3564
3565     if [[ -z $1 ]]; then
3566         print "USAGE: zurl <URL>"
3567         return 1
3568     fi
3569
3570     local PN url prog api json contenttype item
3571     local -a data
3572     PN=$0
3573     url=$1
3574
3575     # Prepend 'http://' to given URL where necessary for later output.
3576     if [[ ${url} != http(s|)://* ]]; then
3577         url='http://'${url}
3578     fi
3579
3580     if check_com -c curl; then
3581         prog=curl
3582     else
3583         print "curl is not available, but mandatory for ${PN}. Aborting."
3584         return 1
3585     fi
3586     api='https://www.googleapis.com/urlshortener/v1/url'
3587     contenttype="Content-Type: application/json"
3588     json="{\"longUrl\": \"${url}\"}"
3589     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
3590     # Parse the response
3591     for item in "${data[@]}"; do
3592         case "$item" in
3593             ' '#'"id":'*)
3594                 item=${item#*: \"}
3595                 item=${item%\",*}
3596                 printf '%s\n' "$item"
3597                 return 0
3598                 ;;
3599         esac
3600     done
3601     return 1
3602 }
3603
3604 #f2# Find history events by search pattern and list them by date.
3605 function whatwhen () {
3606     emulate -L zsh
3607     local usage help ident format_l format_s first_char remain first last
3608     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3609     help='Use `whatwhen -h'\'' for further explanations.'
3610     ident=${(l,${#${:-Usage: }},, ,)}
3611     format_l="${ident}%s\t\t\t%s\n"
3612     format_s="${format_l//(\\t)##/\\t}"
3613     # Make the first char of the word to search for case
3614     # insensitive; e.g. [aA]
3615     first_char=[${(L)1[1]}${(U)1[1]}]
3616     remain=${1[2,-1]}
3617     # Default search range is `-100'.
3618     first=${2:-\-100}
3619     # Optional, just used for `<first> <last>' given.
3620     last=$3
3621     case $1 in
3622         ("")
3623             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3624             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3625         ;;
3626         (-h)
3627             printf '%s\n\n' ${usage}
3628             print 'OPTIONS:'
3629             printf $format_l '-h' 'show help text'
3630             print '\f'
3631             print 'SEARCH RANGE:'
3632             printf $format_l "'0'" 'the whole history,'
3633             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
3634             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
3635             printf '\n%s\n' 'EXAMPLES:'
3636             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
3637             printf $format_l 'whatwhen zsh -250'
3638             printf $format_l 'whatwhen foo 1 99'
3639         ;;
3640         (\?)
3641             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3642         ;;
3643         (*)
3644             # -l list results on stout rather than invoking $EDITOR.
3645             # -i Print dates as in YYYY-MM-DD.
3646             # -m Search for a - quoted - pattern within the history.
3647             fc -li -m "*${first_char}${remain}*" $first $last
3648         ;;
3649     esac
3650 }
3651
3652 # mercurial related stuff
3653 if check_com -c hg ; then
3654     # gnu like diff for mercurial
3655     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
3656     #f5# GNU like diff for mercurial
3657     function hgdi () {
3658         emulate -L zsh
3659         local i
3660         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
3661     }
3662
3663     # build debian package
3664     #a2# Alias for \kbd{hg-buildpackage}
3665     alias hbp='hg-buildpackage'
3666
3667     # execute commands on the versioned patch-queue from the current repos
3668     [[ -n "$GRML_NO_SMALL_ALIASES" ]] || alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
3669
3670     # diffstat for specific version of a mercurial repository
3671     #   hgstat      => display diffstat between last revision and tip
3672     #   hgstat 1234 => display diffstat between revision 1234 and tip
3673     #f5# Diffstat for specific version of a mercurial repos
3674     function hgstat () {
3675         emulate -L zsh
3676         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
3677     }
3678
3679 fi # end of check whether we have the 'hg'-executable
3680
3681 # grml-small cleanups
3682
3683 # The following is used to remove zsh-config-items that do not work
3684 # in grml-small by default.
3685 # If you do not want these adjustments (for whatever reason), set
3686 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
3687 # sources if it is there).
3688
3689 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
3690
3691     unset abk[V]
3692     unalias    'V'      &> /dev/null
3693     unfunction vman     &> /dev/null
3694     unfunction viless   &> /dev/null
3695     unfunction 2html    &> /dev/null
3696
3697     # manpages are not in grmlsmall
3698     unfunction manzsh   &> /dev/null
3699     unfunction man2     &> /dev/null
3700
3701 fi
3702
3703 zrclocal
3704
3705 ## genrefcard.pl settings
3706
3707 ### doc strings for external functions from files
3708 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
3709
3710 ### example: split functions-search 8,16,24,32
3711 #@# split functions-search 8
3712
3713 ## END OF FILE #################################################################
3714 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
3715 # Local variables:
3716 # mode: sh
3717 # End: