etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is439(){
 148     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 #f1# Checks whether or not you're running grml
 154 isgrml(){
 155     [[ -f /etc/grml_version ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running a grml cd
 160 isgrmlcd(){
 161     [[ -f /etc/grml_cd ]] && return 0
 162     return 1
 163 }
 164
 165 if isgrml ; then
 166 #f1# Checks whether or not you're running grml-small
 167     isgrmlsmall() {
 168         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 169             return 0
 170         fi
 171         return 1
 172     }
 173 else
 174     isgrmlsmall() { return 1 }
 175 fi
 176
 177 isdarwin(){
 178     [[ $OSTYPE == darwin* ]] && return 0
 179     return 1
 180 }
 181
 182 #f1# are we running within an utf environment?
 183 isutfenv() {
 184     case "$LANG $CHARSET $LANGUAGE" in
 185         *utf*) return 0 ;;
 186         *UTF*) return 0 ;;
 187         *)     return 1 ;;
 188     esac
 189 }
 190
 191 # check for user, if not running as root set $SUDO to sudo
 192 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 193
 194 # change directory to home on first invocation of zsh
 195 # important for rungetty -> autologin
 196 # Thanks go to Bart Schaefer!
 197 isgrml && checkhome() {
 198     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 199         export ALREADY_DID_CD_HOME=$HOME
 200         cd
 201     fi
 202 }
 203
 204 # check for zsh v3.1.7+
 205
 206 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 207      || ${ZSH_VERSION} == 3.<2->.<->*    \
 208      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 209
 210     printf '-!-\n'
 211     printf '-!- In this configuration we try to make use of features, that only\n'
 212     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 213     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 214     printf '-!- advanced features in all supported versions.\n'
 215     printf '-!-\n'
 216     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 217     printf '-!-\n'
 218     printf '-!- While this *may* work, it might as well fail.\n'
 219     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 220     printf '-!-\n'
 221     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 222     printf '-!- If it does today, you'\''ve been lucky.\n'
 223     printf '-!-\n'
 224     printf '-!- Ye been warned!\n'
 225     printf '-!-\n'
 226
 227     function zstyle() { : }
 228 fi
 229
 230 # autoload wrapper - use this one instead of autoload directly
 231 # We need to define this function as early as this, because autoloading
 232 # 'is-at-least()' needs it.
 233 function zrcautoload() {
 234     emulate -L zsh
 235     setopt extended_glob
 236     local fdir ffile
 237     local -i ffound
 238
 239     ffile=$1
 240     (( found = 0 ))
 241     for fdir in ${fpath} ; do
 242         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 243     done
 244
 245     (( ffound == 0 )) && return 1
 246     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 247         autoload -U ${ffile} || return 1
 248     else
 249         autoload ${ffile} || return 1
 250     fi
 251     return 0
 252 }
 253
 254 # Load is-at-least() for more precise version checks Note that this test will
 255 # *always* fail, if the is-at-least function could not be marked for
 256 # autoloading.
 257 zrcautoload is-at-least || is-at-least() { return 1 }
 258
 259 # set some important options (as early as possible)
 260
 261 # append history list to the history file; this is the default but we make sure
 262 # because it's required for share_history.
 263 setopt append_history
 264
 265 # import new commands from the history file also in other zsh-session
 266 is4 && setopt share_history
 267
 268 # save each command's beginning timestamp and the duration to the history file
 269 setopt extended_history
 270
 271 # If a new command line being added to the history list duplicates an older
 272 # one, the older command is removed from the list
 273 is4 && setopt histignorealldups
 274
 275 # remove command lines from the history list when the first character on the
 276 # line is a space
 277 setopt histignorespace
 278
 279 # if a command is issued that can't be executed as a normal command, and the
 280 # command is the name of a directory, perform the cd command to that directory.
 281 setopt auto_cd
 282
 283 # in order to use #, ~ and ^ for filename generation grep word
 284 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 285 # don't forget to quote '^', '~' and '#'!
 286 setopt extended_glob
 287
 288 # display PID when suspending processes as well
 289 setopt longlistjobs
 290
 291 # try to avoid the 'zsh: no matches found...'
 292 setopt nonomatch
 293
 294 # report the status of backgrounds jobs immediately
 295 setopt notify
 296
 297 # whenever a command completion is attempted, make sure the entire command path
 298 # is hashed first.
 299 setopt hash_list_all
 300
 301 # not just at the end
 302 setopt completeinword
 303
 304 # Don't send SIGHUP to background processes when the shell exits.
 305 setopt nohup
 306
 307 # make cd push the old directory onto the directory stack.
 308 setopt auto_pushd
 309
 310 # avoid "beep"ing
 311 setopt nobeep
 312
 313 # don't push the same dir twice.
 314 setopt pushd_ignore_dups
 315
 316 # * shouldn't match dotfiles. ever.
 317 setopt noglobdots
 318
 319 # use zsh style word splitting
 320 setopt noshwordsplit
 321
 322 # don't error out when unset parameters are used
 323 setopt unset
 324
 325 # setting some default values
 326 NOCOR=${NOCOR:-0}
 327 NOMENU=${NOMENU:-0}
 328 NOPRECMD=${NOPRECMD:-0}
 329 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 330 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 331 BATTERY=${BATTERY:-0}
 332 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 333 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 334
 335 # utility functions
 336 # this function checks if a command exists and returns either true
 337 # or false. This avoids using 'which' and 'whence', which will
 338 # avoid problems with aliases for which on certain weird systems. :-)
 339 # Usage: check_com [-c|-g] word
 340 #   -c  only checks for external commands
 341 #   -g  does the usual tests and also checks for global aliases
 342 check_com() {
 343     emulate -L zsh
 344     local -i comonly gatoo
 345
 346     if [[ $1 == '-c' ]] ; then
 347         (( comonly = 1 ))
 348         shift
 349     elif [[ $1 == '-g' ]] ; then
 350         (( gatoo = 1 ))
 351     else
 352         (( comonly = 0 ))
 353         (( gatoo = 0 ))
 354     fi
 355
 356     if (( ${#argv} != 1 )) ; then
 357         printf 'usage: check_com [-c] <command>\n' >&2
 358         return 1
 359     fi
 360
 361     if (( comonly > 0 )) ; then
 362         [[ -n ${commands[$1]}  ]] && return 0
 363         return 1
 364     fi
 365
 366     if   [[ -n ${commands[$1]}    ]] \
 367       || [[ -n ${functions[$1]}   ]] \
 368       || [[ -n ${aliases[$1]}     ]] \
 369       || [[ -n ${reswords[(r)$1]} ]] ; then
 370
 371         return 0
 372     fi
 373
 374     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 375         return 0
 376     fi
 377
 378     return 1
 379 }
 380
 381 # creates an alias and precedes the command with
 382 # sudo if $EUID is not zero.
 383 salias() {
 384     emulate -L zsh
 385     local only=0 ; local multi=0
 386     while [[ $1 == -* ]] ; do
 387         case $1 in
 388             (-o) only=1 ;;
 389             (-a) multi=1 ;;
 390             (--) shift ; break ;;
 391             (-h)
 392                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 393                 printf '  -h      shows this help text.\n'
 394                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 395                 printf '          be careful using this option.\n'
 396                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 397                 return 0
 398                 ;;
 399             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 400         esac
 401         shift
 402     done
 403
 404     if (( ${#argv} > 1 )) ; then
 405         printf 'Too many arguments %s\n' "${#argv}"
 406         return 1
 407     fi
 408
 409     key="${1%%\=*}" ;  val="${1#*\=}"
 410     if (( EUID == 0 )) && (( only == 0 )); then
 411         alias -- "${key}=${val}"
 412     elif (( EUID > 0 )) ; then
 413         (( multi > 0 )) && val="${val// ; / ; sudo }"
 414         alias -- "${key}=sudo ${val}"
 415     fi
 416
 417     return 0
 418 }
 419
 420 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 421 # usage: uprint foo
 422 #   Where foo is the *name* of the parameter you want printed.
 423 #   Note that foo is no typo; $foo would be wrong here!
 424 if ! is42 ; then
 425     uprint () {
 426         emulate -L zsh
 427         local -a u
 428         local w
 429         local parameter=$1
 430
 431         if [[ -z ${parameter} ]] ; then
 432             printf 'usage: uprint <parameter>\n'
 433             return 1
 434         fi
 435
 436         for w in ${(P)parameter} ; do
 437             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 438         done
 439
 440         builtin print -l $u
 441     }
 442 fi
 443
 444 # Check if we can read given files and source those we can.
 445 xsource() {
 446     if (( ${#argv} < 1 )) ; then
 447         printf 'usage: xsource FILE(s)...\n' >&2
 448         return 1
 449     fi
 450
 451     while (( ${#argv} > 0 )) ; do
 452         [[ -r "$1" ]] && source "$1"
 453         shift
 454     done
 455     return 0
 456 }
 457
 458 # Check if we can read a given file and 'cat(1)' it.
 459 xcat() {
 460     emulate -L zsh
 461     if (( ${#argv} != 1 )) ; then
 462         printf 'usage: xcat FILE\n' >&2
 463         return 1
 464     fi
 465
 466     [[ -r $1 ]] && cat $1
 467     return 0
 468 }
 469
 470 # Remove these functions again, they are of use only in these
 471 # setup files. This should be called at the end of .zshrc.
 472 xunfunction() {
 473     emulate -L zsh
 474     local -a funcs
 475     funcs=(salias xcat xsource xunfunction zrcautoload)
 476
 477     for func in $funcs ; do
 478         [[ -n ${functions[$func]} ]] \
 479             && unfunction $func
 480     done
 481     return 0
 482 }
 483
 484 # this allows us to stay in sync with grml's zshrc and put own
 485 # modifications in ~/.zshrc.local
 486 zrclocal() {
 487     xsource "/etc/zsh/zshrc.local"
 488     xsource "${HOME}/.zshrc.local"
 489     return 0
 490 }
 491
 492 # locale setup
 493 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 494     xsource "/etc/default/locale"
 495 fi
 496
 497 for var in LANG LC_ALL LC_MESSAGES ; do
 498     [[ -n ${(P)var} ]] && export $var
 499 done
 500
 501 xsource "/etc/sysconfig/keyboard"
 502
 503 TZ=$(xcat /etc/timezone)
 504
 505 # set some variables
 506 if check_com -c vim ; then
 507 #v#
 508     export EDITOR=${EDITOR:-vim}
 509 else
 510     export EDITOR=${EDITOR:-vi}
 511 fi
 512
 513 #v#
 514 export PAGER=${PAGER:-less}
 515
 516 #v#
 517 export MAIL=${MAIL:-/var/mail/$USER}
 518
 519 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 520 export SHELL='/bin/zsh'
 521
 522 # color setup for ls:
 523 check_com -c dircolors && eval $(dircolors -b)
 524 # color setup for ls on OS X:
 525 isdarwin && export CLICOLOR=1
 526
 527 # do MacPorts setup on darwin
 528 if isdarwin && [[ -d /opt/local ]]; then
 529     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 530     # zshenv.
 531     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 532     MANPATH="/opt/local/share/man:$MANPATH"
 533 fi
 534 # do Fink setup on darwin
 535 isdarwin && xsource /sw/bin/init.sh
 536
 537 # load our function and completion directories
 538 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 539     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 540     if [[ ${fpath} == '/usr/share/grml/zsh/functions' ]] ; then
 541         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 542             zrcautoload ${func:t}
 543         done
 544     fi
 545 done
 546 unset fdir func
 547
 548 # support colors in less
 549 export LESS_TERMCAP_mb=$'\E[01;31m'
 550 export LESS_TERMCAP_md=$'\E[01;31m'
 551 export LESS_TERMCAP_me=$'\E[0m'
 552 export LESS_TERMCAP_se=$'\E[0m'
 553 export LESS_TERMCAP_so=$'\E[01;44;33m'
 554 export LESS_TERMCAP_ue=$'\E[0m'
 555 export LESS_TERMCAP_us=$'\E[01;32m'
 556
 557 # mailchecks
 558 MAILCHECK=30
 559
 560 # report about cpu-/system-/user-time of command if running longer than
 561 # 5 seconds
 562 REPORTTIME=5
 563
 564 # watch for everyone but me and root
 565 watch=(notme root)
 566
 567 # automatically remove duplicates from these arrays
 568 typeset -U path cdpath fpath manpath
 569
 570 # keybindings
 571 if [[ "$TERM" != emacs ]] ; then
 572     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 573     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 574     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 575     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 576     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 577     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 578     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 579     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 580     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 581     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 582     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 583     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 584     # ncurses stuff:
 585     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 586     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 587     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 588     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 589     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 590     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 591     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 592     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 593 fi
 594
 595 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 596 # use emacs style per default:
 597 bindkey -e
 598 # use vi style:
 599 # bindkey -v
 600
 601 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 602 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 603 beginning-or-end-of-somewhere() {
 604     local hno=$HISTNO
 605     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 606       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 607         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 608     else
 609         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 610         if (( HISTNO != hno )); then
 611             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 612         fi
 613     fi
 614 }
 615 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 616 zle -N end-of-somewhere beginning-or-end-of-somewhere
 617
 618
 619 #if [[ "$TERM" == screen ]] ; then
 620
 621 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 622 ## to beginning/end of buffer on second keypress
 623 ## and to beginning/end of history on (at most) the third keypress
 624 # terminator & non-debian xterm
 625 bindkey '\eOH' beginning-of-somewhere  # home
 626 bindkey '\eOF' end-of-somewhere        # end
 627 # freebsd console
 628 bindkey '\e[H' beginning-of-somewhere   # home
 629 bindkey '\e[F' end-of-somewhere         # end
 630 # xterm,gnome-terminal,quake,etc
 631 bindkey '^[[1~' beginning-of-somewhere  # home
 632 bindkey '^[[4~' end-of-somewhere        # end
 633 # if terminal type is set to 'rxvt':
 634 bindkey '\e[7~' beginning-of-somewhere  # home
 635 bindkey '\e[8~' end-of-somewhere        # end
 636 #fi
 637
 638 bindkey '\e[A'  up-line-or-search       # cursor up
 639 bindkey '\e[B'  down-line-or-search     # <ESC>-
 640
 641 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 642 bindkey "\e[5C" forward-word
 643 bindkey "\e[5D" backward-word
 644 bindkey "\e[1;5C" forward-word
 645 bindkey "\e[1;5D" backward-word
 646 ## the same for alt-left-arrow and alt-right-arrow
 647 bindkey '^[[1;3C' forward-word
 648 bindkey '^[[1;3D' backward-word
 649
 650 # Search backward in the history for a line beginning with the current
 651 # line up to the cursor and move the cursor to the end of the line then
 652 zle -N history-beginning-search-backward-end history-search-end
 653 zle -N history-beginning-search-forward-end  history-search-end
 654 #k# search history backward for entry beginning with typed text
 655 bindkey '^xp'   history-beginning-search-backward-end
 656 #k# search history forward for entry beginning with typed text
 657 bindkey '^xP'   history-beginning-search-forward-end
 658 #k# search history backward for entry beginning with typed text
 659 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 660 #k# search history forward for entry beginning with typed text
 661 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 662
 663 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 664 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 665
 666 # insert unicode character
 667 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 668 # See for example http://unicode.org/charts/ for unicode characters code
 669 zrcautoload insert-unicode-char
 670 zle -N insert-unicode-char
 671 #k# Insert Unicode character
 672 bindkey '^Xi' insert-unicode-char
 673
 674 #m# k Shift-tab Perform backwards menu completion
 675 if [[ -n "$terminfo[kcbt]" ]]; then
 676     bindkey "$terminfo[kcbt]" reverse-menu-complete
 677 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 678     bindkey "$terminfo[cbt]"  reverse-menu-complete
 679 fi
 680
 681 ## toggle the ,. abbreviation feature on/off
 682 # NOABBREVIATION: default abbreviation-state
 683 #                 0 - enabled (default)
 684 #                 1 - disabled
 685 NOABBREVIATION=${NOABBREVIATION:-0}
 686
 687 grml_toggle_abbrev() {
 688     if (( ${NOABBREVIATION} > 0 )) ; then
 689         NOABBREVIATION=0
 690     else
 691         NOABBREVIATION=1
 692     fi
 693 }
 694
 695 #k# Toggle abbreviation expansion on/off
 696 zle -N grml_toggle_abbrev
 697 bindkey '^xA' grml_toggle_abbrev
 698
 699 # add a command line to the shells history without executing it
 700 commit-to-history() {
 701     print -s ${(z)BUFFER}
 702     zle send-break
 703 }
 704 zle -N commit-to-history
 705 bindkey "^x^h" commit-to-history
 706
 707 # only slash should be considered as a word separator:
 708 slash-backward-kill-word() {
 709     local WORDCHARS="${WORDCHARS:s@/@}"
 710     # zle backward-word
 711     zle backward-kill-word
 712 }
 713 zle -N slash-backward-kill-word
 714
 715 #k# Kill left-side word or everything up to next slash
 716 bindkey '\ev' slash-backward-kill-word
 717 #k# Kill left-side word or everything up to next slash
 718 bindkey '\e^h' slash-backward-kill-word
 719 #k# Kill left-side word or everything up to next slash
 720 bindkey '\e^?' slash-backward-kill-word
 721
 722 # use the new *-pattern-* widgets for incremental history search
 723 if is439 ; then
 724     bindkey '^r' history-incremental-pattern-search-backward
 725     bindkey '^s' history-incremental-pattern-search-forward
 726 fi
 727
 728 # a generic accept-line wrapper
 729
 730 # This widget can prevent unwanted autocorrections from command-name
 731 # to _command-name, rehash automatically on enter and call any number
 732 # of builtin and user-defined widgets in different contexts.
 733 #
 734 # For a broader description, see:
 735 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 736 #
 737 # The code is imported from the file 'zsh/functions/accept-line' from
 738 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 739 # distributed under the same terms as zsh itself.
 740
 741 # A newly added command will may not be found or will cause false
 742 # correction attempts, if you got auto-correction set. By setting the
 743 # following style, we force accept-line() to rehash, if it cannot
 744 # find the first word on the command line in the $command[] hash.
 745 zstyle ':acceptline:*' rehash true
 746
 747 function Accept-Line() {
 748     setopt localoptions noksharrays
 749     local -a subs
 750     local -xi aldone
 751     local sub
 752     local alcontext=${1:-$alcontext}
 753
 754     zstyle -a ":acceptline:${alcontext}" actions subs
 755
 756     (( ${#subs} < 1 )) && return 0
 757
 758     (( aldone = 0 ))
 759     for sub in ${subs} ; do
 760         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 761         zle ${sub}
 762
 763         (( aldone > 0 )) && break
 764     done
 765 }
 766
 767 function Accept-Line-getdefault() {
 768     emulate -L zsh
 769     local default_action
 770
 771     zstyle -s ":acceptline:${alcontext}" default_action default_action
 772     case ${default_action} in
 773         ((accept-line|))
 774             printf ".accept-line"
 775             ;;
 776         (*)
 777             printf ${default_action}
 778             ;;
 779     esac
 780 }
 781
 782 function Accept-Line-HandleContext() {
 783     zle Accept-Line
 784
 785     default_action=$(Accept-Line-getdefault)
 786     zstyle -T ":acceptline:${alcontext}" call_default \
 787         && zle ${default_action}
 788 }
 789
 790 function accept-line() {
 791     setopt localoptions noksharrays
 792     local -ax cmdline
 793     local -x alcontext
 794     local buf com fname format msg default_action
 795
 796     alcontext='default'
 797     buf="${BUFFER}"
 798     cmdline=(${(z)BUFFER})
 799     com="${cmdline[1]}"
 800     fname="_${com}"
 801
 802     Accept-Line 'preprocess'
 803
 804     zstyle -t ":acceptline:${alcontext}" rehash \
 805         && [[ -z ${commands[$com]} ]]           \
 806         && rehash
 807
 808     if    [[ -n ${com}               ]] \
 809        && [[ -n ${reswords[(r)$com]} ]] \
 810        || [[ -n ${aliases[$com]}     ]] \
 811        || [[ -n ${functions[$com]}   ]] \
 812        || [[ -n ${builtins[$com]}    ]] \
 813        || [[ -n ${commands[$com]}    ]] ; then
 814
 815         # there is something sensible to execute, just do it.
 816         alcontext='normal'
 817         Accept-Line-HandleContext
 818
 819         return
 820     fi
 821
 822     if    [[ -o correct              ]] \
 823        || [[ -o correctall           ]] \
 824        && [[ -n ${functions[$fname]} ]] ; then
 825
 826         # nothing there to execute but there is a function called
 827         # _command_name; a completion widget. Makes no sense to
 828         # call it on the commandline, but the correct{,all} options
 829         # will ask for it nevertheless, so warn the user.
 830         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 831             # Okay, we warned the user before, he called us again,
 832             # so have it his way.
 833             alcontext='force'
 834             Accept-Line-HandleContext
 835
 836             return
 837         fi
 838
 839         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 840             alcontext='normal'
 841             Accept-Line-HandleContext
 842         else
 843             # prepare warning message for the user, configurable via zstyle.
 844             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 845
 846             if [[ -z ${msg} ]] ; then
 847                 msg="%c will not execute and completion %f exists."
 848             fi
 849
 850             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 851
 852             zle -M -- "${msg}"
 853         fi
 854         return
 855     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 856         # If we are here, the commandline contains something that is not
 857         # executable, which is neither subject to _command_name correction
 858         # and is not empty. might be a variable assignment
 859         alcontext='misc'
 860         Accept-Line-HandleContext
 861
 862         return
 863     fi
 864
 865     # If we got this far, the commandline only contains whitespace, or is empty.
 866     alcontext='empty'
 867     Accept-Line-HandleContext
 868 }
 869
 870 zle -N accept-line
 871 zle -N Accept-Line
 872 zle -N Accept-Line-HandleContext
 873
 874 # power completion - abbreviation expansion
 875 # power completion / abbreviation expansion / buffer expansion
 876 # see http://zshwiki.org/home/examples/zleiab for details
 877 # less risky than the global aliases but powerful as well
 878 # just type the abbreviation key and afterwards ',.' to expand it
 879 declare -A abk
 880 setopt extendedglob
 881 setopt interactivecomments
 882 abk=(
 883 #   key   # value                  (#d additional doc string)
 884 #A# start
 885     '...'  '../..'
 886     '....' '../../..'
 887     'BG'   '& exit'
 888     'C'    '| wc -l'
 889     'G'    '|& grep --color=auto '
 890     'H'    '| head'
 891     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 892     'L'    '| less'
 893     'LL'   '|& less -r'
 894     'M'    '| most'
 895     'N'    '&>/dev/null'           #d (No Output)
 896     'R'    '| tr A-z N-za-m'       #d (ROT13)
 897     'SL'   '| sort | less'
 898     'S'    '| sort -u'
 899     'T'    '| tail'
 900     'V'    '|& vim -'
 901 #A# end
 902     'co'   './configure && make && sudo make install'
 903 )
 904
 905 zleiab() {
 906     emulate -L zsh
 907     setopt extendedglob
 908     local MATCH
 909
 910     if (( NOABBREVIATION > 0 )) ; then
 911         LBUFFER="${LBUFFER},."
 912         return 0
 913     fi
 914
 915     matched_chars='[.-|_a-zA-Z0-9]#'
 916     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 917     LBUFFER+=${abk[$MATCH]:-$MATCH}
 918 }
 919
 920 zle -N zleiab && bindkey ",." zleiab
 921
 922 #f# display contents of assoc array $abk
 923 help-show-abk()
 924 {
 925   zle -M "$(print "Type ,. after these abbreviations to expand them:"; print -a -C 2 ${(kv)abk})"
 926 }
 927 #k# Display list of abbreviations that expand when followed by ,.
 928 zle -N help-show-abk && bindkey '^Xb' help-show-abk
 929
 930 # autoloading
 931 zrcautoload zmv    # who needs mmv or rename?
 932 zrcautoload history-search-end
 933
 934 # we don't want to quote/espace URLs on our own...
 935 # if autoload -U url-quote-magic ; then
 936 #    zle -N self-insert url-quote-magic
 937 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 938 # else
 939 #    print 'Notice: no url-quote-magic available :('
 940 # fi
 941 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 942
 943 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 944 alias run-help >&/dev/null && unalias run-help
 945 for rh in run-help{,-git,-svk,-svn}; do
 946     zrcautoload $rh
 947 done; unset rh
 948
 949 # completion system
 950 if zrcautoload compinit ; then
 951     compinit || print 'Notice: no compinit available :('
 952 else
 953     print 'Notice: no compinit available :('
 954     function zstyle { }
 955     function compdef { }
 956 fi
 957
 958 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 959
 960 is4 && \
 961 for mod in complist deltochar mathfunc ; do
 962     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 963 done
 964
 965 # autoload zsh modules when they are referenced
 966 if is4 ; then
 967     zmodload -a  zsh/stat    zstat
 968     zmodload -a  zsh/zpty    zpty
 969     zmodload -ap zsh/mapfile mapfile
 970 fi
 971
 972 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 973     #k# Insert files and test globbing
 974     bindkey "^Xf" insert-files # C-x-f
 975 fi
 976
 977 bindkey ' '   magic-space    # also do history expansion on space
 978 #k# Trigger menu-complete
 979 bindkey '\ei' menu-complete  # menu completion via esc-i
 980
 981 # press esc-e for editing command line in $EDITOR or $VISUAL
 982 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 983     #k# Edit the current line in \kbd{\$EDITOR}
 984     bindkey '\ee' edit-command-line
 985 fi
 986
 987 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 988     #k# menu selection: pick item but stay in the menu
 989     bindkey -M menuselect '\e^M' accept-and-menu-complete
 990     # also use + and INSERT since it's easier to press repeatedly
 991     bindkey -M menuselect "+" accept-and-menu-complete
 992     bindkey -M menuselect "^[[2~" accept-and-menu-complete
 993
 994     # accept a completion and try to complete again by using menu
 995     # completion; very useful with completing directories
 996     # by using 'undo' one's got a simple file browser
 997     bindkey -M menuselect '^o' accept-and-infer-next-history
 998 fi
 999
1000 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1001 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1002 zle -N insert-datestamp
1003
1004 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1005 bindkey '^Ed' insert-datestamp
1006
1007 # press esc-m for inserting last typed word again (thanks to caphuso!)
1008 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1009 zle -N insert-last-typed-word;
1010
1011 #k# Insert last typed word
1012 bindkey "\em" insert-last-typed-word
1013
1014 function grml-zsh-fg() {
1015   if (( ${#jobstates} )); then
1016     zle .push-input
1017     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1018     BUFFER="${BUFFER}fg"
1019     zle .accept-line
1020   else
1021     zle -M 'No background jobs. Doing nothing.'
1022   fi
1023 }
1024 zle -N grml-zsh-fg
1025 #k# A smart shortcut for \kbd{fg<enter>}
1026 bindkey '^z' grml-zsh-fg
1027
1028 # run command line as user root via sudo:
1029 sudo-command-line() {
1030     [[ -z $BUFFER ]] && zle up-history
1031     if [[ $BUFFER != sudo\ * ]]; then
1032         BUFFER="sudo $BUFFER"
1033         CURSOR=$(( CURSOR+5 ))
1034     fi
1035 }
1036 zle -N sudo-command-line
1037
1038 #k# prepend the current command with "sudo"
1039 bindkey "^Os" sudo-command-line
1040
1041 ### jump behind the first word on the cmdline.
1042 ### useful to add options.
1043 function jump_after_first_word() {
1044     local words
1045     words=(${(z)BUFFER})
1046
1047     if (( ${#words} <= 1 )) ; then
1048         CURSOR=${#BUFFER}
1049     else
1050         CURSOR=${#${words[1]}}
1051     fi
1052 }
1053 zle -N jump_after_first_word
1054 #k# jump to after first word (for adding options)
1055 bindkey '^x1' jump_after_first_word
1056
1057 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1058 zle -C hist-complete complete-word _generic
1059 zstyle ':completion:hist-complete:*' completer _history
1060 #k# complete word from history with menu
1061 bindkey "^X^X" hist-complete
1062
1063 ## complete word from currently visible Screen or Tmux buffer.
1064 if check_com -c screen || check_com -c tmux; then
1065     _complete_screen_display() {
1066         [[ "$TERM" != "screen" ]] && return 1
1067
1068         local TMPFILE=$(mktemp)
1069         local -U -a _screen_display_wordlist
1070         trap "rm -f $TMPFILE" EXIT
1071
1072         # fill array with contents from screen hardcopy
1073         if ((${+TMUX})); then
1074             #works, but crashes tmux below version 1.4
1075             #luckily tmux -V option to ask for version, was also added in 1.4
1076             tmux -V &>/dev/null || return
1077             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1078         else
1079             screen -X hardcopy $TMPFILE
1080             # screen sucks, it dumps in latin1, apparently always. so recode it
1081             # to system charset
1082             check_com recode && recode latin1 $TMPFILE
1083         fi
1084         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1085         # remove PREFIX to be completed from that array
1086         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1087         compadd -a _screen_display_wordlist
1088     }
1089     #k# complete word from currently visible GNU screen buffer
1090     bindkey -r "^XS"
1091     compdef -k _complete_screen_display complete-word '^XS'
1092 fi
1093
1094 # history
1095
1096 ZSHDIR=$HOME/.zsh
1097
1098 #v#
1099 HISTFILE=$HOME/.zsh_history
1100 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1101 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1102
1103 # dirstack handling
1104
1105 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1106 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1107
1108 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1109     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1110     # "cd -" won't work after login by just setting $OLDPWD, so
1111     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1112 fi
1113
1114 chpwd() {
1115     local -ax my_stack
1116     my_stack=( ${PWD} ${dirstack} )
1117     if is42 ; then
1118         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1119     else
1120         uprint my_stack >! ${DIRSTACKFILE}
1121     fi
1122 }
1123
1124 # directory based profiles
1125
1126 if is433 ; then
1127
1128 CHPWD_PROFILE='default'
1129 function chpwd_profiles() {
1130     # Say you want certain settings to be active in certain directories.
1131     # This is what you want.
1132     #
1133     # zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1134     # zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1135     #
1136     # When that's done and you enter a directory that matches the pattern
1137     # in the third part of the context, a function called chpwd_profile_grml,
1138     # for example, is called (if it exists).
1139     #
1140     # If no pattern matches (read: no profile is detected) the profile is
1141     # set to 'default', which means chpwd_profile_default is attempted to
1142     # be called.
1143     #
1144     # A word about the context (the ':chpwd:profiles:*' stuff in the zstyle
1145     # command) which is used: The third part in the context is matched against
1146     # ${PWD}. That's why using a pattern such as /foo/bar(|/|/*) makes sense.
1147     # Because that way the profile is detected for all these values of ${PWD}:
1148     #   /foo/bar
1149     #   /foo/bar/
1150     #   /foo/bar/baz
1151     # So, if you want to make double damn sure a profile works in /foo/bar
1152     # and everywhere deeper in that tree, just use (|/|/*) and be happy.
1153     #
1154     # The name of the detected profile will be available in a variable called
1155     # 'profile' in your functions. You don't need to do anything, it'll just
1156     # be there.
1157     #
1158     # Then there is the parameter $CHPWD_PROFILE is set to the profile, that
1159     # was is currently active. That way you can avoid running code for a
1160     # profile that is already active, by running code such as the following
1161     # at the start of your function:
1162     #
1163     # function chpwd_profile_grml() {
1164     #     [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1165     #   ...
1166     # }
1167     #
1168     # The initial value for $CHPWD_PROFILE is 'default'.
1169     #
1170     # Version requirement:
1171     #   This feature requires zsh 4.3.3 or newer.
1172     #   If you use this feature and need to know whether it is active in your
1173     #   current shell, there are several ways to do that. Here are two simple
1174     #   ways:
1175     #
1176     #   a) If knowing if the profiles feature is active when zsh starts is
1177     #      good enough for you, you can put the following snippet into your
1178     #      .zshrc.local:
1179     #
1180     #   (( ${+functions[chpwd_profiles]} )) && print "directory profiles active"
1181     #
1182     #   b) If that is not good enough, and you would prefer to be notified
1183     #      whenever a profile changes, you can solve that by making sure you
1184     #      start *every* profile function you create like this:
1185     #
1186     #   function chpwd_profile_myprofilename() {
1187     #       [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1188     #       print "chpwd(): Switching to profile: $profile"
1189     #     ...
1190     #   }
1191     #
1192     #      That makes sure you only get notified if a profile is *changed*,
1193     #      not everytime you change directory, which would probably piss
1194     #      you off fairly quickly. :-)
1195     #
1196     # There you go. Now have fun with that.
1197     local -x profile
1198
1199     zstyle -s ":chpwd:profiles:${PWD}" profile profile || profile='default'
1200     if (( ${+functions[chpwd_profile_$profile]} )) ; then
1201         chpwd_profile_${profile}
1202     fi
1203
1204     CHPWD_PROFILE="${profile}"
1205     return 0
1206 }
1207 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1208
1209 fi # is433
1210
1211 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1212 if [[ $BATTERY -gt 0 ]] ; then
1213     if ! check_com -c acpi ; then
1214         BATTERY=0
1215     fi
1216 fi
1217
1218 battery() {
1219 if [[ $BATTERY -gt 0 ]] ; then
1220     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1221     if [[ -z "$PERCENT" ]] ; then
1222         PERCENT='acpi not present'
1223     else
1224         if [[ "$PERCENT" -lt 20 ]] ; then
1225             PERCENT="warning: ${PERCENT}%%"
1226         else
1227             PERCENT="${PERCENT}%%"
1228         fi
1229     fi
1230 fi
1231 }
1232 # set colors for use in prompts
1233 if zrcautoload colors && colors 2>/dev/null ; then
1234     BLUE="%{${fg[blue]}%}"
1235     RED="%{${fg_bold[red]}%}"
1236     GREEN="%{${fg[green]}%}"
1237     CYAN="%{${fg[cyan]}%}"
1238     MAGENTA="%{${fg[magenta]}%}"
1239     YELLOW="%{${fg[yellow]}%}"
1240     WHITE="%{${fg[white]}%}"
1241     NO_COLOUR="%{${reset_color}%}"
1242 else
1243     BLUE=$'%{\e[1;34m%}'
1244     RED=$'%{\e[1;31m%}'
1245     GREEN=$'%{\e[1;32m%}'
1246     CYAN=$'%{\e[1;36m%}'
1247     WHITE=$'%{\e[1;37m%}'
1248     MAGENTA=$'%{\e[1;35m%}'
1249     YELLOW=$'%{\e[1;33m%}'
1250     NO_COLOUR=$'%{\e[0m%}'
1251 fi
1252
1253 # gather version control information for inclusion in a prompt
1254
1255 if zrcautoload vcs_info; then
1256     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1257     # function, which can cause a lot of trouble with our directory-based
1258     # profiles. So:
1259     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1260         function VCS_INFO_realpath () {
1261             setopt localoptions NO_shwordsplit chaselinks
1262             ( builtin cd -q $1 2> /dev/null && pwd; )
1263         }
1264     fi
1265
1266     zstyle ':vcs_info:*' max-exports 2
1267
1268     if [[ -o restricted ]]; then
1269         zstyle ':vcs_info:*' enable NONE
1270     fi
1271 fi
1272
1273 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1274 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1275 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1276 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1277 #       to $vcs_info_msg_N_ as soon as we use the included version.
1278 if [[ "$TERM" == dumb ]] ; then
1279     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1280     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1281 else
1282     # these are the same, just with a lot of colours:
1283     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
1284                                        "zsh: %r"
1285     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
1286                                        "zsh: %r"
1287     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1288 fi
1289
1290 # command not found handling
1291
1292 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1293 function command_not_found_handler() {
1294     emulate -L zsh
1295     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1296         ${GRML_ZSH_CNF_HANDLER} $1
1297     fi
1298     return 1
1299 }
1300
1301 # set prompt
1302 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1303     promptinit # people should be able to use their favourite prompt
1304 else
1305     print 'Notice: no promptinit available :('
1306 fi
1307
1308 setopt prompt_subst
1309
1310 # make sure to use right prompt only when not running a command
1311 is41 && setopt transient_rprompt
1312
1313
1314 function ESC_print () {
1315     info_print $'\ek' $'\e\\' "$@"
1316 }
1317 function set_title () {
1318     info_print  $'\e]0;' $'\a' "$@"
1319 }
1320
1321 function info_print () {
1322     local esc_begin esc_end
1323     esc_begin="$1"
1324     esc_end="$2"
1325     shift 2
1326     printf '%s' ${esc_begin}
1327     printf '%s' "$*"
1328     printf '%s' "${esc_end}"
1329 }
1330
1331 # TODO: revise all these NO* variables and especially their documentation
1332 #       in zsh-help() below.
1333 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1334     [[ $NOPRECMD -gt 0 ]] && return 0
1335     # update VCS information
1336     (( ${+functions[vcs_info]} )) && vcs_info
1337
1338     if [[ $TERM == screen* ]] ; then
1339         if [[ -n ${vcs_info_msg_1_} ]] ; then
1340             ESC_print ${vcs_info_msg_1_}
1341         else
1342             ESC_print "zsh"
1343         fi
1344     fi
1345     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1346     if [[ ${DONTSETRPROMPT:-} -eq 0 ]] ; then
1347         if [[ $BATTERY -gt 0 ]] ; then
1348             # update battery (dropped into $PERCENT) information
1349             battery
1350             RPROMPT="%(?..:() ${PERCENT}"
1351         else
1352             RPROMPT="%(?..:() "
1353         fi
1354     fi
1355     # adjust title of xterm
1356     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1357     [[ ${NOTITLE:-} -gt 0 ]] && return 0
1358     case $TERM in
1359         (xterm*|rxvt*)
1360             set_title ${(%):-"%n@%m: %~"}
1361             ;;
1362     esac
1363 }
1364
1365 # preexec() => a function running before every command
1366 is4 && [[ $NOPRECMD -eq 0 ]] && \
1367 preexec () {
1368     [[ $NOPRECMD -gt 0 ]] && return 0
1369 # set hostname if not running on host with name 'grml'
1370     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1371        NAME="@$HOSTNAME"
1372     fi
1373 # get the name of the program currently running and hostname of local machine
1374 # set screen window title if running in a screen
1375     if [[ "$TERM" == screen* ]] ; then
1376         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1377         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1378         ESC_print ${CMD}
1379     fi
1380 # adjust title of xterm
1381     [[ ${NOTITLE} -gt 0 ]] && return 0
1382     case $TERM in
1383         (xterm*|rxvt*)
1384             set_title "${(%):-"%n@%m:"}" "$1"
1385             ;;
1386     esac
1387 }
1388
1389 EXITCODE="%(?..%?%1v )"
1390 # secondary prompt, printed when the shell needs more information to complete a
1391 # command.
1392 PS2='\`%_> '
1393 # selection prompt used within a select loop.
1394 PS3='?# '
1395 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1396 PS4='+%N:%i:%_> '
1397
1398 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1399 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1400     debian_chroot=$(cat /etc/debian_chroot)
1401 fi
1402
1403 # don't use colors on dumb terminals (like emacs):
1404 if [[ "$TERM" == dumb ]] ; then
1405     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
1406 else
1407     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended
1408     # prompt set variable identifying the chroot you work in (used in the
1409     # prompt below)
1410     if [[ $GRMLPROMPT -gt 0 ]] ; then
1411         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1412 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1413     else
1414         # This assembles the primary prompt string
1415         if (( EUID != 0 )); then
1416             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1417         else
1418             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1419         fi
1420     fi
1421 fi
1422
1423 PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
1424
1425 # if we are inside a grml-chroot set a specific prompt theme
1426 if [[ -n "$GRML_CHROOT" ]] ; then
1427     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1428 fi
1429
1430 # 'hash' some often used directories
1431 #d# start
1432 hash -d deb=/var/cache/apt/archives
1433 hash -d doc=/usr/share/doc
1434 hash -d linux=/lib/modules/$(command uname -r)/build/
1435 hash -d log=/var/log
1436 hash -d slog=/var/log/syslog
1437 hash -d src=/usr/src
1438 hash -d templ=/usr/share/doc/grml-templates
1439 hash -d tt=/usr/share/doc/texttools-doc
1440 hash -d www=/var/www
1441 #d# end
1442
1443 # some aliases
1444 if check_com -c screen ; then
1445     if [[ $UID -eq 0 ]] ; then
1446         if [[ -r /etc/grml/screenrc ]]; then
1447             alias screen="${commands[screen]} -c /etc/grml/screenrc"
1448         fi
1449     elif [[ -r $HOME/.screenrc ]] ; then
1450         alias screen="${commands[screen]} -c $HOME/.screenrc"
1451     else
1452         if [[ -r /etc/grml/screenrc_grml ]]; then
1453             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1454         else
1455             if [[ -r /etc/grml/screenrc ]]; then
1456                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
1457             fi
1458         fi
1459     fi
1460 fi
1461
1462 # do we have GNU ls with color-support?
1463 if ls --help 2>/dev/null | grep -- --color= >/dev/null \
1464    && [[ "$TERM" != dumb ]]
1465 then
1466     #a1# execute \kbd{@a@}:\quad ls with colors
1467     alias ls='ls -b -CF --color=auto'
1468     #a1# execute \kbd{@a@}:\quad list all files, with colors
1469     alias la='ls -la --color=auto'
1470     #a1# long colored list, without dotfiles (@a@)
1471     alias ll='ls -l --color=auto'
1472     #a1# long colored list, human readable sizes (@a@)
1473     alias lh='ls -hAl --color=auto'
1474     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1475     alias l='ls -lF --color=auto'
1476 else
1477     alias ls='ls -b -CF'
1478     alias la='ls -la'
1479     alias ll='ls -l'
1480     alias lh='ls -hAl'
1481     alias l='ls -lF'
1482 fi
1483
1484 alias mdstat='cat /proc/mdstat'
1485 alias ...='cd ../../'
1486
1487 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1488 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1489     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1490 fi
1491
1492 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1493 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1494 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1495
1496 # make sure it is not assigned yet
1497 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1498 utf2iso() {
1499     if isutfenv ; then
1500         for ENV in $(env | command grep -i '.utf') ; do
1501             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1502         done
1503     fi
1504 }
1505
1506 # make sure it is not assigned yet
1507 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1508 iso2utf() {
1509     if ! isutfenv ; then
1510         for ENV in $(env | command grep -i '\.iso') ; do
1511             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1512         done
1513     fi
1514 }
1515
1516 # especially for roadwarriors using GNU screen and ssh:
1517 if ! check_com asc &>/dev/null ; then
1518   asc() { autossh -t "$@" 'screen -RdU' }
1519   compdef asc=ssh
1520 fi
1521
1522 #f1# Hints for the use of zsh on grml
1523 zsh-help() {
1524     print "$bg[white]$fg[black]
1525 zsh-help - hints for use of zsh on grml
1526 =======================================$reset_color"
1527
1528     print '
1529 Main configuration of zsh happens in /etc/zsh/zshrc.
1530 That file is part of the package grml-etc-core, if you want to
1531 use them on a non-grml-system just get the tar.gz from
1532 http://deb.grml.org/ or (preferably) get it from the git repository:
1533
1534   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1535
1536 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1537 The file is still there, but it is empty for backwards compatibility.
1538
1539 For your own changes use these two files:
1540     $HOME/.zshrc.pre
1541     $HOME/.zshrc.local
1542
1543 The former is sourced very early in our zshrc, the latter is sourced
1544 very lately.
1545
1546 System wide configuration without touching configuration files of grml
1547 can take place in /etc/zsh/zshrc.local.
1548
1549 For information regarding zsh start at http://grml.org/zsh/
1550
1551 Take a look at grml'\''s zsh refcard:
1552 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1553
1554 Check out the main zsh refcard:
1555 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1556
1557 And of course visit the zsh-lovers:
1558 % man zsh-lovers
1559
1560 You can adjust some options through environment variables when
1561 invoking zsh without having to edit configuration files.
1562 Basically meant for bash users who are not used to the power of
1563 the zsh yet. :)
1564
1565   "NOCOR=1    zsh" => deactivate automatic correction
1566   "NOMENU=1   zsh" => do not use auto menu completion
1567                       (note: use ctrl-d for completion instead!)
1568   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1569   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1570                       preexec() and precmd() completely
1571   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1572   "COMMAND_NOT_FOUND=1 zsh"
1573                    => Enable a handler if an external command was not found
1574                       The command called in the handler can be altered by setting
1575                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1576                       "/usr/share/command-not-found/command-not-found"
1577
1578 A value greater than 0 is enables a feature; a value equal to zero
1579 disables it. If you like one or the other of these settings, you can
1580 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1581 zshrc.'
1582
1583     print "
1584 $bg[white]$fg[black]
1585 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1586 Enjoy your grml system with the zsh!$reset_color"
1587 }
1588
1589 # debian stuff
1590 if [[ -r /etc/debian_version ]] ; then
1591     #a3# Execute \kbd{apt-cache search}
1592     alias acs='apt-cache search'
1593     #a3# Execute \kbd{apt-cache show}
1594     alias acsh='apt-cache show'
1595     #a3# Execute \kbd{apt-cache policy}
1596     alias acp='apt-cache policy'
1597     #a3# Execute \kbd{apt-get dist-upgrade}
1598     salias adg="apt-get dist-upgrade"
1599     #a3# Execute \kbd{apt-get install}
1600     salias agi="apt-get install"
1601     #a3# Execute \kbd{aptitude install}
1602     salias ati="aptitude install"
1603     #a3# Execute \kbd{apt-get upgrade}
1604     salias ag="apt-get upgrade"
1605     #a3# Execute \kbd{apt-get update}
1606     salias au="apt-get update"
1607     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1608     salias -a up="aptitude update ; aptitude safe-upgrade"
1609     #a3# Execute \kbd{dpkg-buildpackage}
1610     alias dbp='dpkg-buildpackage'
1611     #a3# Execute \kbd{grep-excuses}
1612     alias ge='grep-excuses'
1613
1614     # get a root shell as normal user in live-cd mode:
1615     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1616        alias su="sudo su"
1617      fi
1618
1619     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1620     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1621     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1622     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1623 fi
1624
1625 # sort installed Debian-packages by size
1626 if check_com -c dpkg-query ; then
1627     #a3# List installed Debian-packages sorted by size
1628     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1629 fi
1630
1631 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1632 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1633     if check_com -c wodim; then
1634         cdrecord() {
1635             cat <<EOMESS
1636 cdrecord is not provided under its original name by Debian anymore.
1637 See #377109 in the BTS of Debian for more details.
1638
1639 Please use the wodim binary instead
1640 EOMESS
1641             return 1
1642         }
1643     fi
1644 fi
1645
1646 # Use hard limits, except for a smaller stack and no core dumps
1647 unlimit
1648 is425 && limit stack 8192
1649 isgrmlcd && limit core 0 # important for a live-cd-system
1650 limit -s
1651
1652 # completion system
1653
1654 # called later (via is4 && grmlcomp)
1655 # note: use 'zstyle' for getting current settings
1656 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
1657 grmlcomp() {
1658     # TODO: This could use some additional information
1659
1660     # allow one error for every three characters typed in approximate completer
1661     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1662
1663     # don't complete backup files as executables
1664     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1665
1666     # start menu completion only if it could find no unambiguous initial string
1667     zstyle ':completion:*:correct:*'       insert-unambiguous true
1668     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1669     zstyle ':completion:*:correct:*'       original true
1670
1671     # activate color-completion
1672     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1673
1674     # format on completion
1675     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1676
1677     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1678     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1679
1680     # insert all expansions for expand completer
1681     zstyle ':completion:*:expand:*'        tag-order all-expansions
1682     zstyle ':completion:*:history-words'   list false
1683
1684     # activate menu
1685     zstyle ':completion:*:history-words'   menu yes
1686
1687     # ignore duplicate entries
1688     zstyle ':completion:*:history-words'   remove-all-dups yes
1689     zstyle ':completion:*:history-words'   stop yes
1690
1691     # match uppercase from lowercase
1692     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1693
1694     # separate matches into groups
1695     zstyle ':completion:*:matches'         group 'yes'
1696     zstyle ':completion:*'                 group-name ''
1697
1698     if [[ "$NOMENU" -eq 0 ]] ; then
1699         # if there are more than 5 options allow selecting from a menu
1700         zstyle ':completion:*'               menu select=5
1701     else
1702         # don't use any menus at all
1703         setopt no_auto_menu
1704     fi
1705
1706     zstyle ':completion:*:messages'        format '%d'
1707     zstyle ':completion:*:options'         auto-description '%d'
1708
1709     # describe options in full
1710     zstyle ':completion:*:options'         description 'yes'
1711
1712     # on processes completion complete all user processes
1713     zstyle ':completion:*:processes'       command 'ps -au$USER'
1714
1715     # offer indexes before parameters in subscripts
1716     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1717
1718     # provide verbose completion information
1719     zstyle ':completion:*'                 verbose true
1720
1721     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1722     # for commands (read: 1st word in the line) that it will list for the user
1723     # to choose from. The following disables that, because it's not exactly fast.
1724     zstyle ':completion:*:-command-:*:'    verbose false
1725
1726     # set format for warnings
1727     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1728
1729     # define files to ignore for zcompile
1730     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1731     zstyle ':completion:correct:'          prompt 'correct to: %e'
1732
1733     # Ignore completion functions for commands you don't have:
1734     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1735
1736     # Provide more processes in completion of programs like killall:
1737     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1738
1739     # complete manual by their section
1740     zstyle ':completion:*:manuals'    separate-sections true
1741     zstyle ':completion:*:manuals.*'  insert-sections   true
1742     zstyle ':completion:*:man:*'      menu yes select
1743
1744     # provide .. as a completion
1745     zstyle ':completion:*' special-dirs ..
1746
1747     # run rehash on completion so new installed program are found automatically:
1748     _force_rehash() {
1749         (( CURRENT == 1 )) && rehash
1750         return 1
1751     }
1752
1753     ## correction
1754     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1755     if [[ "$NOCOR" -gt 0 ]] ; then
1756         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1757         setopt nocorrect
1758     else
1759         # try to be smart about when to use what completer...
1760         setopt correct
1761         zstyle -e ':completion:*' completer '
1762             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1763                 _last_try="$HISTNO$BUFFER$CURSOR"
1764                 reply=(_complete _match _ignored _prefix _files)
1765             else
1766                 if [[ $words[1] == (rm|mv) ]] ; then
1767                     reply=(_complete _files)
1768                 else
1769                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1770                 fi
1771             fi'
1772     fi
1773
1774     # command for process lists, the local web server details and host completion
1775     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1776
1777     # caching
1778     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1779                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1780
1781     # host completion
1782     if is42 ; then
1783         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1784         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1785     else
1786         _ssh_hosts=()
1787         _etc_hosts=()
1788     fi
1789     hosts=(
1790         $(hostname)
1791         "$_ssh_hosts[@]"
1792         "$_etc_hosts[@]"
1793         grml.org
1794         localhost
1795     )
1796     zstyle ':completion:*:hosts' hosts $hosts
1797     # TODO: so, why is this here?
1798     #  zstyle '*' hosts $hosts
1799
1800     # use generic completion system for programs not yet defined; (_gnu_generic works
1801     # with commands that provide a --help option with "standard" gnu-like output.)
1802     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
1803                    pal stow tail uname ; do
1804         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
1805     done; unset compcom
1806
1807     # see upgrade function in this file
1808     compdef _hosts upgrade
1809 }
1810
1811 # grmlstuff
1812 grmlstuff() {
1813 # people should use 'grml-x'!
1814     if check_com -c 915resolution; then
1815         855resolution() {
1816             echo "Please use 915resolution as resolution modifying tool for Intel \
1817 graphic chipset."
1818             return -1
1819         }
1820     fi
1821
1822     #a1# Output version of running grml
1823     alias grml-version='cat /etc/grml_version'
1824
1825     if check_com -c rebuildfstab ; then
1826         #a1# Rebuild /etc/fstab
1827         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1828     fi
1829
1830     if check_com -c grml-debootstrap ; then
1831         debian2hd() {
1832             echo "Installing debian to harddisk is possible by using grml-debootstrap."
1833             return 1
1834         }
1835     fi
1836 }
1837
1838 # now run the functions
1839 isgrml && checkhome
1840 is4    && isgrml    && grmlstuff
1841 is4    && grmlcomp
1842
1843 # keephack
1844 is4 && xsource "/etc/zsh/keephack"
1845
1846 # wonderful idea of using "e" glob qualifier by Peter Stephenson
1847 # You use it as follows:
1848 # $ NTREF=/reference/file
1849 # $ ls -l *(e:nt:)
1850 # This lists all the files in the current directory newer than the reference file.
1851 # You can also specify the reference file inline; note quotes:
1852 # $ ls -l *(e:'nt ~/.zshenv':)
1853 is4 && nt() {
1854     if [[ -n $1 ]] ; then
1855         local NTREF=${~1}
1856     fi
1857     [[ $REPLY -nt $NTREF ]]
1858 }
1859
1860 # shell functions
1861
1862 #f1# Reload an autoloadable function
1863 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1864 compdef _functions freload
1865
1866 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1867 sll() {
1868     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1869     for file in "$@" ; do
1870         while [[ -h "$file" ]] ; do
1871             ls -l $file
1872             file=$(readlink "$file")
1873         done
1874     done
1875 }
1876
1877 # TODO: Is it supported to use pager settings like this?
1878 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
1879 # with respect to wordsplitting. (ie. ${=PAGER})
1880 if check_com -c $PAGER ; then
1881     #f1# View Debian's changelog of a given package
1882     dchange() {
1883         emulate -L zsh
1884         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
1885             $PAGER /usr/share/doc/$1/changelog.Debian.gz
1886         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1887             $PAGER /usr/share/doc/$1/changelog.gz
1888         else
1889             if check_com -c aptitude ; then
1890                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1891                 if isgrml ; then
1892                     aptitude -t unstable changelog $1
1893                 else
1894                     aptitude changelog $1
1895                 fi
1896             else
1897                 echo "No changelog for package $1 found, sorry."
1898                 return 1
1899             fi
1900         fi
1901     }
1902     _dchange() { _files -W /usr/share/doc -/ }
1903     compdef _dchange dchange
1904
1905     #f1# View Debian's NEWS of a given package
1906     dnews() {
1907         emulate -L zsh
1908         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
1909             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
1910         else
1911             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
1912                 $PAGER /usr/share/doc/$1/NEWS.gz
1913             else
1914                 echo "No NEWS file for package $1 found, sorry."
1915                 return 1
1916             fi
1917         fi
1918     }
1919     _dnews() { _files -W /usr/share/doc -/ }
1920     compdef _dnews dnews
1921
1922     #f1# View upstream's changelog of a given package
1923     uchange() {
1924         emulate -L zsh
1925         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1926             $PAGER /usr/share/doc/$1/changelog.gz
1927         else
1928             echo "No changelog for package $1 found, sorry."
1929             return 1
1930         fi
1931     }
1932     _uchange() { _files -W /usr/share/doc -/ }
1933     compdef _uchange uchange
1934 fi
1935
1936 # zsh profiling
1937 profile() {
1938     ZSH_PROFILE_RC=1 $SHELL "$@"
1939 }
1940
1941 #f1# Edit an alias via zle
1942 edalias() {
1943     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1944 }
1945 compdef _aliases edalias
1946
1947 #f1# Edit a function via zle
1948 edfunc() {
1949     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
1950 }
1951 compdef _functions edfunc
1952
1953 # use it e.g. via 'Restart apache2'
1954 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
1955 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
1956 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
1957 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
1958 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
1959 if [[ -d /etc/init.d || -d /etc/service ]] ; then
1960     __start_stop() {
1961         local action_="${1:l}"  # e.g Start/Stop/Restart
1962         local service_="$2"
1963         local param_="$3"
1964
1965         local service_target_="$(readlink /etc/init.d/$service_)"
1966         if [[ $service_target_ == "/usr/bin/sv" ]]; then
1967             # runit
1968             case "${action_}" in
1969                 start) if [[ ! -e /etc/service/$service_ ]]; then
1970                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
1971                        else
1972                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1973                        fi ;;
1974                 # there is no reload in runits sysv emulation
1975                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
1976                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
1977             esac
1978         else
1979             # sysvinit
1980             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1981         fi
1982     }
1983
1984     _grmlinitd() {
1985         local -a scripts
1986         scripts=( /etc/init.d/*(x:t) )
1987         _describe "service startup script" scripts
1988     }
1989
1990     for i in Start Restart Stop Force-Reload Reload ; do
1991         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
1992         compdef _grmlinitd $i
1993     done
1994 fi
1995
1996 #f1# Provides useful information on globbing
1997 H-Glob() {
1998     echo -e "
1999     /      directories
2000     .      plain files
2001     @      symbolic links
2002     =      sockets
2003     p      named pipes (FIFOs)
2004     *      executable plain files (0100)
2005     %      device files (character or block special)
2006     %b     block special files
2007     %c     character special files
2008     r      owner-readable files (0400)
2009     w      owner-writable files (0200)
2010     x      owner-executable files (0100)
2011     A      group-readable files (0040)
2012     I      group-writable files (0020)
2013     E      group-executable files (0010)
2014     R      world-readable files (0004)
2015     W      world-writable files (0002)
2016     X      world-executable files (0001)
2017     s      setuid files (04000)
2018     S      setgid files (02000)
2019     t      files with the sticky bit (01000)
2020
2021   print *(m-1)          # Files modified up to a day ago
2022   print *(a1)           # Files accessed a day ago
2023   print *(@)            # Just symlinks
2024   print *(Lk+50)        # Files bigger than 50 kilobytes
2025   print *(Lk-50)        # Files smaller than 50 kilobytes
2026   print **/*.c          # All *.c files recursively starting in \$PWD
2027   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2028   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2029   print *~*.*           # All Files that do not contain a dot
2030   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2031   print -l *(.c|.h)     # Lists *.c and *.h
2032   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2033   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2034 }
2035 alias help-zshglob=H-Glob
2036
2037 #v1# set number of lines to display per page
2038 HELP_LINES_PER_PAGE=20
2039 #v1# set location of help-zle cache file
2040 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
2041 #f1# helper function for help-zle, actually generates the help text
2042 help_zle_parse_keybindings()
2043 {
2044     emulate -L zsh
2045     setopt extendedglob
2046     unsetopt ksharrays  #indexing starts at 1
2047
2048     #v1# choose files that help-zle will parse for keybindings
2049     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
2050
2051     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
2052         local load_cache=0
2053         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
2054         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
2055     fi
2056
2057     #fill with default keybindings, possibly to be overwriten in a file later
2058     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2059     local -A help_zle_keybindings
2060     help_zle_keybindings['<Ctrl>@']="set MARK"
2061     help_zle_keybindings['<Ctrl>X<Ctrl>J']="vi-join lines"
2062     help_zle_keybindings['<Ctrl>X<Ctrl>B']="jump to matching brace"
2063     help_zle_keybindings['<Ctrl>X<Ctrl>U']="undo"
2064     help_zle_keybindings['<Ctrl>_']="undo"
2065     help_zle_keybindings['<Ctrl>X<Ctrl>F<c>']="find <c> in cmdline"
2066     help_zle_keybindings['<Ctrl>A']="goto beginning of line"
2067     help_zle_keybindings['<Ctrl>E']="goto end of line"
2068     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2069     help_zle_keybindings['<Alt>T']="transpose words"
2070     help_zle_keybindings['<Alt>s']="spellcheck word"
2071     help_zle_keybindings['<Ctrl>K']="backward kill buffer"
2072     help_zle_keybindings['<Ctrl>U']="forward kill buffer"
2073     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2074     help_zle_keybindings["<Alt>'"]="quote line"
2075     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2076     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2077     help_zle_keybindings['<Alt>U']="make next word Uppercase"
2078     help_zle_keybindings['<Alt>l']="make next word lowercase"
2079     help_zle_keybindings['<Ctrl>Xd']="preview expansion under cursor"
2080     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2081     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2082     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2083     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2084     help_zle_keybindings['<Ctrl>V']="insert next keypress symbol literally (e.g. for bindkey)"
2085     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2086     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2087     help_zle_keybindings['<Alt>H']="run help on current command"
2088
2089     #init global variables
2090     unset help_zle_lines help_zle_sln
2091     typeset -g -a help_zle_lines
2092     typeset -g help_zle_sln=1
2093
2094     local k v
2095     local lastkeybind_desc contents     #last description starting with #k# that we found
2096     local num_lines_elapsed=0            #number of lines between last description and keybinding
2097     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2098     for f in $HELPZLE_KEYBINDING_FILES; do
2099         [[ -r "$f" ]] || continue   #not readable ? skip it
2100         contents="$(<$f)"
2101         for cline in "${(f)contents}"; do
2102             #zsh pattern: matches lines like: #k# ..............
2103             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2104                 lastkeybind_desc="$match[*]"
2105                 num_lines_elapsed=0
2106             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2107             #             ignores lines that are commentend out
2108             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2109             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2110                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2111                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2112                     #substitute keybinding string with something readable
2113                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2114                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2115                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2116                     help_zle_keybindings[${k}]=$lastkeybind_desc
2117                 fi
2118                 lastkeybind_desc=""
2119             else
2120               ((num_lines_elapsed++))
2121             fi
2122         done
2123     done
2124     unset contents
2125     #calculate length of keybinding column
2126     local kstrlen=0
2127     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2128     #convert the assoc array into preformated lines, which we are able to sort
2129     for k v in ${(kv)help_zle_keybindings[@]}; do
2130         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2131         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2132     done
2133     #sort lines alphabetically
2134     help_zle_lines=("${(i)help_zle_lines[@]}")
2135     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2136     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2137     zcompile $HELP_ZLE_CACHE_FILE
2138 }
2139 typeset -g help_zle_sln
2140 typeset -g -a help_zle_lines
2141
2142 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2143 help-zle()
2144 {
2145     emulate -L zsh
2146     unsetopt ksharrays  #indexing starts at 1
2147     #help lines already generated ? no ? then do it
2148     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2149     #already displayed all lines ? go back to the start
2150     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2151     local sln=$help_zle_sln
2152     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2153     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2154     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2155 }
2156 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2157 zle -N help-zle && bindkey '^Xz' help-zle
2158
2159 # grep for running process, like: 'any vim'
2160 any() {
2161     emulate -L zsh
2162     unsetopt KSH_ARRAYS
2163     if [[ -z "$1" ]] ; then
2164         echo "any - grep for process(es) by keyword" >&2
2165         echo "Usage: any <keyword>" >&2 ; return 1
2166     else
2167         ps xauwww | grep -i --color=auto "[${1[1]}]${1[2,-1]}"
2168     fi
2169 }
2170
2171
2172 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2173 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2174 [[ -r /proc/1/maps ]] && \
2175 deswap() {
2176     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2177     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2178     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2179 }
2180
2181 # a wrapper for vim, that deals with title setting
2182 #   VIM_OPTIONS
2183 #       set this array to a set of options to vim you always want
2184 #       to have set when calling vim (in .zshrc.local), like:
2185 #           VIM_OPTIONS=( -p )
2186 #       This will cause vim to send every file given on the
2187 #       commandline to be send to it's own tab (needs vim7).
2188 vim() {
2189     VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2190 }
2191
2192 # make a backup of a file
2193 bk() {
2194     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2195 }
2196
2197 ssl_hashes=( sha512 sha256 sha1 md5 )
2198
2199 for sh in ${ssl_hashes}; do
2200     eval 'ssl-cert-'${sh}'() {
2201         emulate -L zsh
2202         if [[ -z $1 ]] ; then
2203             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2204             return 1
2205         fi
2206         openssl x509 -noout -fingerprint -'${sh}' -in $1
2207     }'
2208 done; unset sh
2209
2210 ssl-cert-fingerprints() {
2211     emulate -L zsh
2212     local i
2213     if [[ -z $1 ]] ; then
2214         printf 'usage: ssl-cert-fingerprints <file>\n'
2215         return 1
2216     fi
2217     for i in ${ssl_hashes}
2218         do ssl-cert-$i $1;
2219     done
2220 }
2221
2222 ssl-cert-info() {
2223     emulate -L zsh
2224     if [[ -z $1 ]] ; then
2225         printf 'usage: ssl-cert-info <file>\n'
2226         return 1
2227     fi
2228     openssl x509 -noout -text -in $1
2229     ssl-cert-fingerprints $1
2230 }
2231
2232 # make sure our environment is clean regarding colors
2233 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2234
2235 # "persistent history"
2236 # just write important commands you always need to ~/.important_commands
2237 if [[ -r ~/.important_commands ]] ; then
2238     fc -R ~/.important_commands
2239 fi
2240
2241 # load the lookup subsystem if it's available on the system
2242 zrcautoload lookupinit && lookupinit
2243
2244 # variables
2245
2246 # set terminal property (used e.g. by msgid-chooser)
2247 export COLORTERM="yes"
2248
2249 # aliases
2250
2251 # general
2252 #a2# Execute \kbd{du -sch}
2253 alias da='du -sch'
2254 #a2# Execute \kbd{jobs -l}
2255 alias j='jobs -l'
2256
2257 # listing stuff
2258 #a2# Execute \kbd{ls -lSrah}
2259 alias dir="ls -lSrah"
2260 #a2# Only show dot-directories
2261 alias lad='ls -d .*(/)'                # only show dot-directories
2262 #a2# Only show dot-files
2263 alias lsa='ls -a .*(.)'                # only show dot-files
2264 #a2# Only files with setgid/setuid/sticky flag
2265 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
2266 #a2# Only show 1st ten symlinks
2267 alias lsl='ls -l *(@)'                 # only symlinks
2268 #a2# Display only executables
2269 alias lsx='ls -l *(*)'                 # only executables
2270 #a2# Display world-{readable,writable,executable} files
2271 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
2272 #a2# Display the ten biggest files
2273 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
2274 #a2# Only show directories
2275 alias lsd='ls -d *(/)'                 # only show directories
2276 #a2# Only show empty directories
2277 alias lse='ls -d *(/^F)'               # only show empty directories
2278 #a2# Display the ten newest files
2279 alias lsnew="ls -rtlh *(D.om[1,10])"   # display the newest files
2280 #a2# Display the ten oldest files
2281 alias lsold="ls -rtlh *(D.Om[1,10])"   # display the oldest files
2282 #a2# Display the ten smallest files
2283 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
2284 #a2# Display the ten newest directories and ten newest .directories
2285 alias lsnewdir="ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
2286 #a2# Display the ten oldest directories and ten oldest .directories
2287 alias lsolddir="ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
2288
2289 # some useful aliases
2290 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir $OLDCWD}
2291 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2292
2293 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2294 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2295 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2296
2297 # simple webserver
2298 check_com -c python && alias http="python -m SimpleHTTPServer"
2299
2300 # work around non utf8 capable software in utf environment via $LANG and luit
2301 if check_com isutfenv && check_com luit ; then
2302     if check_com -c mrxvt ; then
2303         isutfenv && [[ -n "$LANG" ]] && \
2304             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2305     fi
2306
2307     if check_com -c aterm ; then
2308         isutfenv && [[ -n "$LANG" ]] && \
2309             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2310     fi
2311
2312     if check_com -c centericq ; then
2313         isutfenv && [[ -n "$LANG" ]] && \
2314             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2315     fi
2316 fi
2317
2318 # useful functions
2319
2320 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2321 bk() {
2322     emulate -L zsh
2323     cp -b $1 $1_`date --iso-8601=m`
2324 }
2325
2326 #f5# cd to directoy and list files
2327 cl() {
2328     emulate -L zsh
2329     cd $1 && ls -a
2330 }
2331
2332 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2333 cd() {
2334     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2335         [[ ! -e ${1:h} ]] && return 1
2336         print "Correcting ${1} to ${1:h}"
2337         builtin cd ${1:h}
2338     else
2339         builtin cd "$@"
2340     fi
2341 }
2342
2343 #f5# Create Directoy and \kbd{cd} to it
2344 mkcd() {
2345     mkdir -p "$@" && cd "$@"
2346 }
2347
2348 #f5# Create temporary directory and \kbd{cd} to it
2349 cdt() {
2350     local t
2351     t=$(mktemp -d)
2352     echo "$t"
2353     builtin cd "$t"
2354 }
2355
2356 #f5# Create directory under cursor or the selected area
2357 # Press ctrl-xM to create the directory under the cursor or the selected area.
2358 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2359 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2360 # directory does not exist yet -> press ctrl-XM and problem solved
2361 inplaceMkDirs() {
2362     local PATHTOMKDIR
2363     if ((REGION_ACTIVE==1)); then
2364         local F=$MARK T=$CURSOR
2365         if [[ $F -gt $T ]]; then
2366             F=${CURSOR}
2367             T=${MARK}
2368         fi
2369         # get marked area from buffer and eliminate whitespace
2370         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2371         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2372     else
2373         local bufwords iword
2374         bufwords=(${(z)LBUFFER})
2375         iword=${#bufwords}
2376         bufwords=(${(z)BUFFER})
2377         PATHTOMKDIR="${(Q)bufwords[iword]}"
2378     fi
2379     [[ -z "${PATHTOMKDIR}" ]] && return 1
2380     if [[ -e "${PATHTOMKDIR}" ]]; then
2381         zle -M " path already exists, doing nothing"
2382     else
2383         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2384         zle end-of-line
2385     fi
2386 }
2387 #k# mkdir -p <dir> from string under cursor or marked area
2388 zle -N inplaceMkDirs && bindkey '^XM' inplaceMkDirs
2389
2390 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2391 accessed() {
2392     emulate -L zsh
2393     print -l -- *(a-${1:-1})
2394 }
2395
2396 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2397 changed() {
2398     emulate -L zsh
2399     print -l -- *(c-${1:-1})
2400 }
2401
2402 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2403 modified() {
2404     emulate -L zsh
2405     print -l -- *(m-${1:-1})
2406 }
2407 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2408 check_com new || alias new=modified
2409
2410 # use colors when GNU grep with color-support
2411 #a2# Execute \kbd{grep -{}-color=auto}
2412 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
2413
2414 # Translate DE<=>EN
2415 # 'translate' looks up fot a word in a file with language-to-language
2416 # translations (field separator should be " : "). A typical wordlist looks
2417 # like at follows:
2418 #  | english-word : german-transmission
2419 # It's also only possible to translate english to german but not reciprocal.
2420 # Use the following oneliner to turn back the sort order:
2421 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2422 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2423 #f5# Translates a word
2424 trans() {
2425     emulate -L zsh
2426     case "$1" in
2427         -[dD]*)
2428             translate -l de-en $2
2429             ;;
2430         -[eE]*)
2431             translate -l en-de $2
2432             ;;
2433         *)
2434             echo "Usage: $0 { -D | -E }"
2435             echo "         -D == German to English"
2436             echo "         -E == English to German"
2437     esac
2438 }
2439
2440 # Usage: simple-extract <file>
2441 # Using option -d deletes the original archive file.
2442 #f5# Smart archive extractor
2443 simple-extract() {
2444     emulate -L zsh
2445     setopt extended_glob noclobber
2446     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2447     local RC=0
2448     zparseopts -D -E "d=DELETE_ORIGINAL"
2449     for ARCHIVE in "${@}"; do
2450         case $ARCHIVE in
2451             *.(tar.bz2|tbz2|tbz))
2452                 DECOMP_CMD="tar -xvjf -"
2453                 USES_STDIN=true
2454                 USES_STDOUT=false
2455                 ;;
2456             *.(tar.gz|tgz))
2457                 DECOMP_CMD="tar -xvzf -"
2458                 USES_STDIN=true
2459                 USES_STDOUT=false
2460                 ;;
2461             *.(tar.xz|txz|tar.lzma))
2462                 DECOMP_CMD="tar -xvJf -"
2463                 USES_STDIN=true
2464                 USES_STDOUT=false
2465                 ;;
2466             *.tar)
2467                 DECOMP_CMD="tar -xvf -"
2468                 USES_STDIN=true
2469                 USES_STDOUT=false
2470                 ;;
2471             *.rar)
2472                 DECOMP_CMD="unrar x"
2473                 USES_STDIN=false
2474                 USES_STDOUT=false
2475                 ;;
2476             *.lzh)
2477                 DECOMP_CMD="lha x"
2478                 USES_STDIN=false
2479                 USES_STDOUT=false
2480                 ;;
2481             *.7z)
2482                 DECOMP_CMD="7z x"
2483                 USES_STDIN=false
2484                 USES_STDOUT=false
2485                 ;;
2486             *.(zip|jar))
2487                 DECOMP_CMD="unzip"
2488                 USES_STDIN=false
2489                 USES_STDOUT=false
2490                 ;;
2491             *.deb)
2492                 DECOMP_CMD="ar -x"
2493                 USES_STDIN=false
2494                 USES_STDOUT=false
2495                 ;;
2496             *.bz2)
2497                 DECOMP_CMD="bzip2 -d -c -"
2498                 USES_STDIN=true
2499                 USES_STDOUT=true
2500                 ;;
2501             *.(gz|Z))
2502                 DECOMP_CMD="gzip -d -c -"
2503                 USES_STDIN=true
2504                 USES_STDOUT=true
2505                 ;;
2506             *.(xz|lzma))
2507                 DECOMP_CMD="xz -d -c -"
2508                 USES_STDIN=true
2509                 USES_STDOUT=true
2510                 ;;
2511             *)
2512                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2513                 RC=$((RC+1))
2514                 continue
2515                 ;;
2516         esac
2517
2518         if ! check_com ${DECOMP_CMD[(w)1]}; then
2519             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2520             RC=$((RC+2))
2521             continue
2522         fi
2523
2524         GZTARGET="${ARCHIVE:t:r}"
2525         if [[ -f $ARCHIVE ]] ; then
2526
2527             print "Extracting '$ARCHIVE' ..."
2528             if $USES_STDIN; then
2529                 if $USES_STDOUT; then
2530                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
2531                 else
2532                     ${=DECOMP_CMD} < "$ARCHIVE"
2533                 fi
2534             else
2535                 if $USES_STDOUT; then
2536                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
2537                 else
2538                     ${=DECOMP_CMD} "$ARCHIVE"
2539                 fi
2540             fi
2541             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
2542
2543         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
2544             if check_com curl; then
2545                 WGET_CMD="curl -L -k -s -o -"
2546             elif check_com wget; then
2547                 WGET_CMD="wget -q -O - --no-check-certificate"
2548             else
2549                 print "ERROR: neither wget nor curl is installed" >&2
2550                 RC=$((RC+4))
2551                 continue
2552             fi
2553             print "Downloading and Extracting '$ARCHIVE' ..."
2554             if $USES_STDIN; then
2555                 if $USES_STDOUT; then
2556                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
2557                     RC=$((RC+$?))
2558                 else
2559                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
2560                     RC=$((RC+$?))
2561                 fi
2562             else
2563                 if $USES_STDOUT; then
2564                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
2565                 else
2566                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
2567                 fi
2568             fi
2569
2570         else
2571             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
2572             RC=$((RC+8))
2573         fi
2574     done
2575     return $RC
2576 }
2577
2578 __archive_or_uri()
2579 {
2580     _alternative \
2581         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
2582         '_urls:Remote Archives:_urls'
2583 }
2584
2585 _simple_extract()
2586 {
2587     _arguments \
2588         '-d[delete original archivefile after extraction]' \
2589         '*:Archive Or Uri:__archive_or_uri'
2590 }
2591 compdef _simple_extract simple-extract
2592 alias se=simple-extract
2593
2594 #f5# Set all ulimit parameters to \kbd{unlimited}
2595 allulimit() {
2596     ulimit -c unlimited
2597     ulimit -d unlimited
2598     ulimit -f unlimited
2599     ulimit -l unlimited
2600     ulimit -n unlimited
2601     ulimit -s unlimited
2602     ulimit -t unlimited
2603 }
2604
2605 #f5# Change the xterm title from within GNU-screen
2606 xtrename() {
2607     emulate -L zsh
2608     if [[ $1 != "-f" ]] ; then
2609         if [[ -z ${DISPLAY} ]] ; then
2610             printf 'xtrename only makes sense in X11.\n'
2611             return 1
2612         fi
2613     else
2614         shift
2615     fi
2616     if [[ -z $1 ]] ; then
2617         printf 'usage: xtrename [-f] "title for xterm"\n'
2618         printf '  renames the title of xterm from _within_ screen.\n'
2619         printf '  also works without screen.\n'
2620         printf '  will not work if DISPLAY is unset, use -f to override.\n'
2621         return 0
2622     fi
2623     print -n "\eP\e]0;${1}\C-G\e\\"
2624     return 0
2625 }
2626
2627 # TODO:
2628 # Rewrite this by either using tinyurl.com's API
2629 # or using another shortening service to comply with
2630 # tinyurl.com's policy.
2631 #
2632 # Create small urls via http://tinyurl.com using wget(1).
2633 #function zurl() {
2634 #    emulate -L zsh
2635 #    [[ -z $1 ]] && { print "USAGE: zurl <URL>" ; return 1 }
2636 #
2637 #    local PN url tiny grabber search result preview
2638 #    PN=$0
2639 #    url=$1
2640 ##   Check existence of given URL with the help of ping(1).
2641 ##   N.B. ping(1) only works without an eventual given protocol.
2642 #    ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
2643 #        read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
2644 #
2645 #    if (( $? == 0 )) ; then
2646 ##           Prepend 'http://' to given URL where necessary for later output.
2647 #            [[ ${url} != http(s|)://* ]] && url='http://'${url}
2648 #            tiny='http://tinyurl.com/create.php?url='
2649 #            if check_com -c wget ; then
2650 #                grabber='wget -O- -o/dev/null'
2651 #            else
2652 #                print "wget is not available, but mandatory for ${PN}. Aborting."
2653 #            fi
2654 ##           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
2655 #            search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
2656 #            result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
2657 ##           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
2658 #            preview='http://preview.'${result#http://}
2659 #
2660 #            printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
2661 #            printf '%s\t%s\n\n' 'Given URL:' ${url}
2662 #            printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
2663 #    else
2664 #        return 1
2665 #    fi
2666 #}
2667
2668 #f2# Find history events by search pattern and list them by date.
2669 whatwhen()  {
2670     emulate -L zsh
2671     local usage help ident format_l format_s first_char remain first last
2672     usage='USAGE: whatwhen [options] <searchstring> <search range>'
2673     help='Use `whatwhen -h'\'' for further explanations.'
2674     ident=${(l,${#${:-Usage: }},, ,)}
2675     format_l="${ident}%s\t\t\t%s\n"
2676     format_s="${format_l//(\\t)##/\\t}"
2677     # Make the first char of the word to search for case
2678     # insensitive; e.g. [aA]
2679     first_char=[${(L)1[1]}${(U)1[1]}]
2680     remain=${1[2,-1]}
2681     # Default search range is `-100'.
2682     first=${2:-\-100}
2683     # Optional, just used for `<first> <last>' given.
2684     last=$3
2685     case $1 in
2686         ("")
2687             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
2688             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2689         ;;
2690         (-h)
2691             printf '%s\n\n' ${usage}
2692             print 'OPTIONS:'
2693             printf $format_l '-h' 'show help text'
2694             print '\f'
2695             print 'SEARCH RANGE:'
2696             printf $format_l "'0'" 'the whole history,'
2697             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
2698             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
2699             printf '\n%s\n' 'EXAMPLES:'
2700             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
2701             printf $format_l 'whatwhen zsh -250'
2702             printf $format_l 'whatwhen foo 1 99'
2703         ;;
2704         (\?)
2705             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2706         ;;
2707         (*)
2708             # -l list results on stout rather than invoking $EDITOR.
2709             # -i Print dates as in YYYY-MM-DD.
2710             # -m Search for a - quoted - pattern within the history.
2711             fc -li -m "*${first_char}${remain}*" $first $last
2712         ;;
2713     esac
2714 }
2715
2716 # mercurial related stuff
2717 if check_com -c hg ; then
2718     # gnu like diff for mercurial
2719     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
2720     #f5# GNU like diff for mercurial
2721     hgdi() {
2722         emulate -L zsh
2723         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
2724     }
2725
2726     # build debian package
2727     #a2# Alias for \kbd{hg-buildpackage}
2728     alias hbp='hg-buildpackage'
2729
2730     # execute commands on the versioned patch-queue from the current repos
2731     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
2732
2733     # diffstat for specific version of a mercurial repository
2734     #   hgstat      => display diffstat between last revision and tip
2735     #   hgstat 1234 => display diffstat between revision 1234 and tip
2736     #f5# Diffstat for specific version of a mercurial repos
2737     hgstat() {
2738         emulate -L zsh
2739         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
2740     }
2741
2742 fi # end of check whether we have the 'hg'-executable
2743
2744 # grml-small cleanups
2745
2746 # The following is used to remove zsh-config-items that do not work
2747 # in grml-small by default.
2748 # If you do not want these adjustments (for whatever reason), set
2749 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
2750 # sources if it is there).
2751
2752 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
2753
2754     unset abk[V]
2755     unalias    'V'      &> /dev/null
2756     unfunction vman     &> /dev/null
2757     unfunction viless   &> /dev/null
2758     unfunction 2html    &> /dev/null
2759
2760     # manpages are not in grmlsmall
2761     unfunction manzsh   &> /dev/null
2762     unfunction man2     &> /dev/null
2763
2764 fi
2765
2766 zrclocal
2767
2768 ## genrefcard.pl settings
2769
2770 ### doc strings for external functions from files
2771 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
2772
2773 ### example: split functions-search 8,16,24,32
2774 #@# split functions-search 8
2775
2776 ## END OF FILE #################################################################
2777 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
2778 # Local variables:
2779 # mode: sh
2780 # End: