etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is439(){
 148     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 #f1# Checks whether or not you're running grml
 154 isgrml(){
 155     [[ -f /etc/grml_version ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running a grml cd
 160 isgrmlcd(){
 161     [[ -f /etc/grml_cd ]] && return 0
 162     return 1
 163 }
 164
 165 if isgrml ; then
 166 #f1# Checks whether or not you're running grml-small
 167     isgrmlsmall() {
 168         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 169             return 0
 170         fi
 171         return 1
 172     }
 173 else
 174     isgrmlsmall() { return 1 }
 175 fi
 176
 177 isdarwin(){
 178     [[ $OSTYPE == darwin* ]] && return 0
 179     return 1
 180 }
 181
 182 #f1# are we running within an utf environment?
 183 isutfenv() {
 184     case "$LANG $CHARSET $LANGUAGE" in
 185         *utf*) return 0 ;;
 186         *UTF*) return 0 ;;
 187         *)     return 1 ;;
 188     esac
 189 }
 190
 191 # check for user, if not running as root set $SUDO to sudo
 192 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 193
 194 # change directory to home on first invocation of zsh
 195 # important for rungetty -> autologin
 196 # Thanks go to Bart Schaefer!
 197 isgrml && checkhome() {
 198     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 199         export ALREADY_DID_CD_HOME=$HOME
 200         cd
 201     fi
 202 }
 203
 204 # check for zsh v3.1.7+
 205
 206 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 207      || ${ZSH_VERSION} == 3.<2->.<->*    \
 208      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 209
 210     printf '-!-\n'
 211     printf '-!- In this configuration we try to make use of features, that only\n'
 212     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 213     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 214     printf '-!- advanced features in all supported versions.\n'
 215     printf '-!-\n'
 216     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 217     printf '-!-\n'
 218     printf '-!- While this *may* work, it might as well fail.\n'
 219     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 220     printf '-!-\n'
 221     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 222     printf '-!- If it does today, you'\''ve been lucky.\n'
 223     printf '-!-\n'
 224     printf '-!- Ye been warned!\n'
 225     printf '-!-\n'
 226
 227     function zstyle() { : }
 228 fi
 229
 230 # autoload wrapper - use this one instead of autoload directly
 231 # We need to define this function as early as this, because autoloading
 232 # 'is-at-least()' needs it.
 233 function zrcautoload() {
 234     emulate -L zsh
 235     setopt extended_glob
 236     local fdir ffile
 237     local -i ffound
 238
 239     ffile=$1
 240     (( found = 0 ))
 241     for fdir in ${fpath} ; do
 242         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 243     done
 244
 245     (( ffound == 0 )) && return 1
 246     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 247         autoload -U ${ffile} || return 1
 248     else
 249         autoload ${ffile} || return 1
 250     fi
 251     return 0
 252 }
 253
 254 # Load is-at-least() for more precise version checks Note that this test will
 255 # *always* fail, if the is-at-least function could not be marked for
 256 # autoloading.
 257 zrcautoload is-at-least || is-at-least() { return 1 }
 258
 259 # set some important options (as early as possible)
 260
 261 # append history list to the history file; this is the default but we make sure
 262 # because it's required for share_history.
 263 setopt append_history
 264
 265 # import new commands from the history file also in other zsh-session
 266 is4 && setopt share_history
 267
 268 # save each command's beginning timestamp and the duration to the history file
 269 setopt extended_history
 270
 271 # If a new command line being added to the history list duplicates an older
 272 # one, the older command is removed from the list
 273 is4 && setopt histignorealldups
 274
 275 # remove command lines from the history list when the first character on the
 276 # line is a space
 277 setopt histignorespace
 278
 279 # if a command is issued that can't be executed as a normal command, and the
 280 # command is the name of a directory, perform the cd command to that directory.
 281 setopt auto_cd
 282
 283 # in order to use #, ~ and ^ for filename generation grep word
 284 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 285 # don't forget to quote '^', '~' and '#'!
 286 setopt extended_glob
 287
 288 # display PID when suspending processes as well
 289 setopt longlistjobs
 290
 291 # try to avoid the 'zsh: no matches found...'
 292 setopt nonomatch
 293
 294 # report the status of backgrounds jobs immediately
 295 setopt notify
 296
 297 # whenever a command completion is attempted, make sure the entire command path
 298 # is hashed first.
 299 setopt hash_list_all
 300
 301 # not just at the end
 302 setopt completeinword
 303
 304 # Don't send SIGHUP to background processes when the shell exits.
 305 setopt nohup
 306
 307 # make cd push the old directory onto the directory stack.
 308 setopt auto_pushd
 309
 310 # avoid "beep"ing
 311 setopt nobeep
 312
 313 # don't push the same dir twice.
 314 setopt pushd_ignore_dups
 315
 316 # * shouldn't match dotfiles. ever.
 317 setopt noglobdots
 318
 319 # use zsh style word splitting
 320 setopt noshwordsplit
 321
 322 # don't error out when unset parameters are used
 323 setopt unset
 324
 325 # setting some default values
 326 NOCOR=${NOCOR:-0}
 327 NOMENU=${NOMENU:-0}
 328 NOPRECMD=${NOPRECMD:-0}
 329 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 330 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 331 BATTERY=${BATTERY:-0}
 332 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 333 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 334
 335 typeset -ga ls_options
 336 typeset -ga grep_options
 337 if ls --help 2> /dev/null | grep -q GNU; then
 338     ls_options=( --color=auto )
 339 elif [[ $OSTYPE == freebsd* ]]; then
 340     ls_options=( -G )
 341 fi
 342 if grep --help 2> /dev/null | grep -q GNU || \
 343    [[ $OSTYPE == freebsd* ]]; then
 344     grep_options=( --color=auto )
 345 fi
 346
 347 # utility functions
 348 # this function checks if a command exists and returns either true
 349 # or false. This avoids using 'which' and 'whence', which will
 350 # avoid problems with aliases for which on certain weird systems. :-)
 351 # Usage: check_com [-c|-g] word
 352 #   -c  only checks for external commands
 353 #   -g  does the usual tests and also checks for global aliases
 354 check_com() {
 355     emulate -L zsh
 356     local -i comonly gatoo
 357
 358     if [[ $1 == '-c' ]] ; then
 359         (( comonly = 1 ))
 360         shift
 361     elif [[ $1 == '-g' ]] ; then
 362         (( gatoo = 1 ))
 363     else
 364         (( comonly = 0 ))
 365         (( gatoo = 0 ))
 366     fi
 367
 368     if (( ${#argv} != 1 )) ; then
 369         printf 'usage: check_com [-c] <command>\n' >&2
 370         return 1
 371     fi
 372
 373     if (( comonly > 0 )) ; then
 374         [[ -n ${commands[$1]}  ]] && return 0
 375         return 1
 376     fi
 377
 378     if   [[ -n ${commands[$1]}    ]] \
 379       || [[ -n ${functions[$1]}   ]] \
 380       || [[ -n ${aliases[$1]}     ]] \
 381       || [[ -n ${reswords[(r)$1]} ]] ; then
 382
 383         return 0
 384     fi
 385
 386     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 387         return 0
 388     fi
 389
 390     return 1
 391 }
 392
 393 # creates an alias and precedes the command with
 394 # sudo if $EUID is not zero.
 395 salias() {
 396     emulate -L zsh
 397     local only=0 ; local multi=0
 398     while [[ $1 == -* ]] ; do
 399         case $1 in
 400             (-o) only=1 ;;
 401             (-a) multi=1 ;;
 402             (--) shift ; break ;;
 403             (-h)
 404                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 405                 printf '  -h      shows this help text.\n'
 406                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 407                 printf '          be careful using this option.\n'
 408                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 409                 return 0
 410                 ;;
 411             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 412         esac
 413         shift
 414     done
 415
 416     if (( ${#argv} > 1 )) ; then
 417         printf 'Too many arguments %s\n' "${#argv}"
 418         return 1
 419     fi
 420
 421     key="${1%%\=*}" ;  val="${1#*\=}"
 422     if (( EUID == 0 )) && (( only == 0 )); then
 423         alias -- "${key}=${val}"
 424     elif (( EUID > 0 )) ; then
 425         (( multi > 0 )) && val="${val// ; / ; sudo }"
 426         alias -- "${key}=sudo ${val}"
 427     fi
 428
 429     return 0
 430 }
 431
 432 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 433 # usage: uprint foo
 434 #   Where foo is the *name* of the parameter you want printed.
 435 #   Note that foo is no typo; $foo would be wrong here!
 436 if ! is42 ; then
 437     uprint () {
 438         emulate -L zsh
 439         local -a u
 440         local w
 441         local parameter=$1
 442
 443         if [[ -z ${parameter} ]] ; then
 444             printf 'usage: uprint <parameter>\n'
 445             return 1
 446         fi
 447
 448         for w in ${(P)parameter} ; do
 449             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 450         done
 451
 452         builtin print -l $u
 453     }
 454 fi
 455
 456 # Check if we can read given files and source those we can.
 457 xsource() {
 458     if (( ${#argv} < 1 )) ; then
 459         printf 'usage: xsource FILE(s)...\n' >&2
 460         return 1
 461     fi
 462
 463     while (( ${#argv} > 0 )) ; do
 464         [[ -r "$1" ]] && source "$1"
 465         shift
 466     done
 467     return 0
 468 }
 469
 470 # Check if we can read a given file and 'cat(1)' it.
 471 xcat() {
 472     emulate -L zsh
 473     if (( ${#argv} != 1 )) ; then
 474         printf 'usage: xcat FILE\n' >&2
 475         return 1
 476     fi
 477
 478     [[ -r $1 ]] && cat $1
 479     return 0
 480 }
 481
 482 # Remove these functions again, they are of use only in these
 483 # setup files. This should be called at the end of .zshrc.
 484 xunfunction() {
 485     emulate -L zsh
 486     local -a funcs
 487     funcs=(salias xcat xsource xunfunction zrcautoload)
 488
 489     for func in $funcs ; do
 490         [[ -n ${functions[$func]} ]] \
 491             && unfunction $func
 492     done
 493     return 0
 494 }
 495
 496 # this allows us to stay in sync with grml's zshrc and put own
 497 # modifications in ~/.zshrc.local
 498 zrclocal() {
 499     xsource "/etc/zsh/zshrc.local"
 500     xsource "${HOME}/.zshrc.local"
 501     return 0
 502 }
 503
 504 # locale setup
 505 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 506     xsource "/etc/default/locale"
 507 fi
 508
 509 for var in LANG LC_ALL LC_MESSAGES ; do
 510     [[ -n ${(P)var} ]] && export $var
 511 done
 512
 513 xsource "/etc/sysconfig/keyboard"
 514
 515 TZ=$(xcat /etc/timezone)
 516
 517 # set some variables
 518 if check_com -c vim ; then
 519 #v#
 520     export EDITOR=${EDITOR:-vim}
 521 else
 522     export EDITOR=${EDITOR:-vi}
 523 fi
 524
 525 #v#
 526 export PAGER=${PAGER:-less}
 527
 528 #v#
 529 export MAIL=${MAIL:-/var/mail/$USER}
 530
 531 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 532 export SHELL='/bin/zsh'
 533
 534 # color setup for ls:
 535 check_com -c dircolors && eval $(dircolors -b)
 536 # color setup for ls on OS X:
 537 isdarwin && export CLICOLOR=1
 538
 539 # do MacPorts setup on darwin
 540 if isdarwin && [[ -d /opt/local ]]; then
 541     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 542     # zshenv.
 543     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 544     MANPATH="/opt/local/share/man:$MANPATH"
 545 fi
 546 # do Fink setup on darwin
 547 isdarwin && xsource /sw/bin/init.sh
 548
 549 # load our function and completion directories
 550 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 551     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 552     if [[ ${fpath} == '/usr/share/grml/zsh/functions' ]] ; then
 553         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 554             zrcautoload ${func:t}
 555         done
 556     fi
 557 done
 558 unset fdir func
 559
 560 # support colors in less
 561 export LESS_TERMCAP_mb=$'\E[01;31m'
 562 export LESS_TERMCAP_md=$'\E[01;31m'
 563 export LESS_TERMCAP_me=$'\E[0m'
 564 export LESS_TERMCAP_se=$'\E[0m'
 565 export LESS_TERMCAP_so=$'\E[01;44;33m'
 566 export LESS_TERMCAP_ue=$'\E[0m'
 567 export LESS_TERMCAP_us=$'\E[01;32m'
 568
 569 # mailchecks
 570 MAILCHECK=30
 571
 572 # report about cpu-/system-/user-time of command if running longer than
 573 # 5 seconds
 574 REPORTTIME=5
 575
 576 # watch for everyone but me and root
 577 watch=(notme root)
 578
 579 # automatically remove duplicates from these arrays
 580 typeset -U path cdpath fpath manpath
 581
 582 # keybindings
 583 if [[ "$TERM" != emacs ]] ; then
 584     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 585     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 586     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 587     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 588     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 589     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 590     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 591     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 592     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 593     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 594     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 595     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 596     # ncurses stuff:
 597     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 598     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 599     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 600     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 601     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 602     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 603     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 604     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 605 fi
 606
 607 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 608 # use emacs style per default:
 609 bindkey -e
 610 # use vi style:
 611 # bindkey -v
 612
 613 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 614 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 615 beginning-or-end-of-somewhere() {
 616     local hno=$HISTNO
 617     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 618       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 619         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 620     else
 621         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 622         if (( HISTNO != hno )); then
 623             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 624         fi
 625     fi
 626 }
 627 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 628 zle -N end-of-somewhere beginning-or-end-of-somewhere
 629
 630
 631 #if [[ "$TERM" == screen ]] ; then
 632
 633 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 634 ## to beginning/end of buffer on second keypress
 635 ## and to beginning/end of history on (at most) the third keypress
 636 # terminator & non-debian xterm
 637 bindkey '\eOH' beginning-of-somewhere  # home
 638 bindkey '\eOF' end-of-somewhere        # end
 639 # freebsd console
 640 bindkey '\e[H' beginning-of-somewhere   # home
 641 bindkey '\e[F' end-of-somewhere         # end
 642 # xterm,gnome-terminal,quake,etc
 643 bindkey '^[[1~' beginning-of-somewhere  # home
 644 bindkey '^[[4~' end-of-somewhere        # end
 645 # if terminal type is set to 'rxvt':
 646 bindkey '\e[7~' beginning-of-somewhere  # home
 647 bindkey '\e[8~' end-of-somewhere        # end
 648 #fi
 649
 650 bindkey '\e[A'  up-line-or-search       # cursor up
 651 bindkey '\e[B'  down-line-or-search     # <ESC>-
 652
 653 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 654 bindkey "\e[5C" forward-word
 655 bindkey "\e[5D" backward-word
 656 bindkey "\e[1;5C" forward-word
 657 bindkey "\e[1;5D" backward-word
 658 ## the same for alt-left-arrow and alt-right-arrow
 659 bindkey '^[[1;3C' forward-word
 660 bindkey '^[[1;3D' backward-word
 661
 662 # Search backward in the history for a line beginning with the current
 663 # line up to the cursor and move the cursor to the end of the line then
 664 zle -N history-beginning-search-backward-end history-search-end
 665 zle -N history-beginning-search-forward-end  history-search-end
 666 #k# search history backward for entry beginning with typed text
 667 bindkey '^xp'   history-beginning-search-backward-end
 668 #k# search history forward for entry beginning with typed text
 669 bindkey '^xP'   history-beginning-search-forward-end
 670 #k# search history backward for entry beginning with typed text
 671 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 672 #k# search history forward for entry beginning with typed text
 673 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 674
 675 # bindkey -s '^l' "|less\n"             # ctrl-L pipes to less
 676 # bindkey -s '^b' " &\n"                # ctrl-B runs it in the background
 677
 678 # insert unicode character
 679 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 680 # See for example http://unicode.org/charts/ for unicode characters code
 681 zrcautoload insert-unicode-char
 682 zle -N insert-unicode-char
 683 #k# Insert Unicode character
 684 bindkey '^xi' insert-unicode-char
 685
 686 #m# k Shift-tab Perform backwards menu completion
 687 if [[ -n "$terminfo[kcbt]" ]]; then
 688     bindkey "$terminfo[kcbt]" reverse-menu-complete
 689 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 690     bindkey "$terminfo[cbt]"  reverse-menu-complete
 691 fi
 692
 693 ## toggle the ,. abbreviation feature on/off
 694 # NOABBREVIATION: default abbreviation-state
 695 #                 0 - enabled (default)
 696 #                 1 - disabled
 697 NOABBREVIATION=${NOABBREVIATION:-0}
 698
 699 grml_toggle_abbrev() {
 700     if (( ${NOABBREVIATION} > 0 )) ; then
 701         NOABBREVIATION=0
 702     else
 703         NOABBREVIATION=1
 704     fi
 705 }
 706
 707 #k# Toggle abbreviation expansion on/off
 708 zle -N grml_toggle_abbrev
 709 bindkey '^xA' grml_toggle_abbrev
 710
 711 # add a command line to the shells history without executing it
 712 commit-to-history() {
 713     print -s ${(z)BUFFER}
 714     zle send-break
 715 }
 716 zle -N commit-to-history
 717 bindkey "^x^h" commit-to-history
 718
 719 # only slash should be considered as a word separator:
 720 slash-backward-kill-word() {
 721     local WORDCHARS="${WORDCHARS:s@/@}"
 722     # zle backward-word
 723     zle backward-kill-word
 724 }
 725 zle -N slash-backward-kill-word
 726
 727 #k# Kill left-side word or everything up to next slash
 728 bindkey '\ev' slash-backward-kill-word
 729 #k# Kill left-side word or everything up to next slash
 730 bindkey '\e^h' slash-backward-kill-word
 731 #k# Kill left-side word or everything up to next slash
 732 bindkey '\e^?' slash-backward-kill-word
 733
 734 # use the new *-pattern-* widgets for incremental history search
 735 if is439 ; then
 736     bindkey '^r' history-incremental-pattern-search-backward
 737     bindkey '^s' history-incremental-pattern-search-forward
 738 fi
 739
 740 # a generic accept-line wrapper
 741
 742 # This widget can prevent unwanted autocorrections from command-name
 743 # to _command-name, rehash automatically on enter and call any number
 744 # of builtin and user-defined widgets in different contexts.
 745 #
 746 # For a broader description, see:
 747 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 748 #
 749 # The code is imported from the file 'zsh/functions/accept-line' from
 750 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 751 # distributed under the same terms as zsh itself.
 752
 753 # A newly added command will may not be found or will cause false
 754 # correction attempts, if you got auto-correction set. By setting the
 755 # following style, we force accept-line() to rehash, if it cannot
 756 # find the first word on the command line in the $command[] hash.
 757 zstyle ':acceptline:*' rehash true
 758
 759 function Accept-Line() {
 760     setopt localoptions noksharrays
 761     local -a subs
 762     local -xi aldone
 763     local sub
 764     local alcontext=${1:-$alcontext}
 765
 766     zstyle -a ":acceptline:${alcontext}" actions subs
 767
 768     (( ${#subs} < 1 )) && return 0
 769
 770     (( aldone = 0 ))
 771     for sub in ${subs} ; do
 772         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 773         zle ${sub}
 774
 775         (( aldone > 0 )) && break
 776     done
 777 }
 778
 779 function Accept-Line-getdefault() {
 780     emulate -L zsh
 781     local default_action
 782
 783     zstyle -s ":acceptline:${alcontext}" default_action default_action
 784     case ${default_action} in
 785         ((accept-line|))
 786             printf ".accept-line"
 787             ;;
 788         (*)
 789             printf ${default_action}
 790             ;;
 791     esac
 792 }
 793
 794 function Accept-Line-HandleContext() {
 795     zle Accept-Line
 796
 797     default_action=$(Accept-Line-getdefault)
 798     zstyle -T ":acceptline:${alcontext}" call_default \
 799         && zle ${default_action}
 800 }
 801
 802 function accept-line() {
 803     setopt localoptions noksharrays
 804     local -ax cmdline
 805     local -x alcontext
 806     local buf com fname format msg default_action
 807
 808     alcontext='default'
 809     buf="${BUFFER}"
 810     cmdline=(${(z)BUFFER})
 811     com="${cmdline[1]}"
 812     fname="_${com}"
 813
 814     Accept-Line 'preprocess'
 815
 816     zstyle -t ":acceptline:${alcontext}" rehash \
 817         && [[ -z ${commands[$com]} ]]           \
 818         && rehash
 819
 820     if    [[ -n ${com}               ]] \
 821        && [[ -n ${reswords[(r)$com]} ]] \
 822        || [[ -n ${aliases[$com]}     ]] \
 823        || [[ -n ${functions[$com]}   ]] \
 824        || [[ -n ${builtins[$com]}    ]] \
 825        || [[ -n ${commands[$com]}    ]] ; then
 826
 827         # there is something sensible to execute, just do it.
 828         alcontext='normal'
 829         Accept-Line-HandleContext
 830
 831         return
 832     fi
 833
 834     if    [[ -o correct              ]] \
 835        || [[ -o correctall           ]] \
 836        && [[ -n ${functions[$fname]} ]] ; then
 837
 838         # nothing there to execute but there is a function called
 839         # _command_name; a completion widget. Makes no sense to
 840         # call it on the commandline, but the correct{,all} options
 841         # will ask for it nevertheless, so warn the user.
 842         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 843             # Okay, we warned the user before, he called us again,
 844             # so have it his way.
 845             alcontext='force'
 846             Accept-Line-HandleContext
 847
 848             return
 849         fi
 850
 851         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 852             alcontext='normal'
 853             Accept-Line-HandleContext
 854         else
 855             # prepare warning message for the user, configurable via zstyle.
 856             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 857
 858             if [[ -z ${msg} ]] ; then
 859                 msg="%c will not execute and completion %f exists."
 860             fi
 861
 862             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 863
 864             zle -M -- "${msg}"
 865         fi
 866         return
 867     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 868         # If we are here, the commandline contains something that is not
 869         # executable, which is neither subject to _command_name correction
 870         # and is not empty. might be a variable assignment
 871         alcontext='misc'
 872         Accept-Line-HandleContext
 873
 874         return
 875     fi
 876
 877     # If we got this far, the commandline only contains whitespace, or is empty.
 878     alcontext='empty'
 879     Accept-Line-HandleContext
 880 }
 881
 882 zle -N accept-line
 883 zle -N Accept-Line
 884 zle -N Accept-Line-HandleContext
 885
 886 # power completion - abbreviation expansion
 887 # power completion / abbreviation expansion / buffer expansion
 888 # see http://zshwiki.org/home/examples/zleiab for details
 889 # less risky than the global aliases but powerful as well
 890 # just type the abbreviation key and afterwards ',.' to expand it
 891 declare -A abk
 892 setopt extendedglob
 893 setopt interactivecomments
 894 abk=(
 895 #   key   # value                  (#d additional doc string)
 896 #A# start
 897     '...'  '../..'
 898     '....' '../../..'
 899     'BG'   '& exit'
 900     'C'    '| wc -l'
 901     'G'    '|& grep '${grep_options:+"${grep_options[*]} "}
 902     'H'    '| head'
 903     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 904     'L'    '| less'
 905     'LL'   '|& less -r'
 906     'M'    '| most'
 907     'N'    '&>/dev/null'           #d (No Output)
 908     'R'    '| tr A-z N-za-m'       #d (ROT13)
 909     'SL'   '| sort | less'
 910     'S'    '| sort -u'
 911     'T'    '| tail'
 912     'V'    '|& vim -'
 913 #A# end
 914     'co'   './configure && make && sudo make install'
 915 )
 916
 917 zleiab() {
 918     emulate -L zsh
 919     setopt extendedglob
 920     local MATCH
 921
 922     if (( NOABBREVIATION > 0 )) ; then
 923         LBUFFER="${LBUFFER},."
 924         return 0
 925     fi
 926
 927     matched_chars='[.-|_a-zA-Z0-9]#'
 928     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 929     LBUFFER+=${abk[$MATCH]:-$MATCH}
 930 }
 931
 932 zle -N zleiab && bindkey ",." zleiab
 933
 934 #f# display contents of assoc array $abk
 935 help-show-abk()
 936 {
 937   zle -M "$(print "Type ,. after these abbreviations to expand them:"; print -a -C 2 ${(kv)abk})"
 938 }
 939 #k# Display list of abbreviations that expand when followed by ,.
 940 zle -N help-show-abk && bindkey '^xb' help-show-abk
 941
 942 # autoloading
 943 zrcautoload zmv    # who needs mmv or rename?
 944 zrcautoload history-search-end
 945
 946 # we don't want to quote/espace URLs on our own...
 947 # if autoload -U url-quote-magic ; then
 948 #    zle -N self-insert url-quote-magic
 949 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 950 # else
 951 #    print 'Notice: no url-quote-magic available :('
 952 # fi
 953 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 954
 955 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 956 alias run-help >&/dev/null && unalias run-help
 957 for rh in run-help{,-git,-svk,-svn}; do
 958     zrcautoload $rh
 959 done; unset rh
 960
 961 # completion system
 962 if zrcautoload compinit ; then
 963     compinit || print 'Notice: no compinit available :('
 964 else
 965     print 'Notice: no compinit available :('
 966     function zstyle { }
 967     function compdef { }
 968 fi
 969
 970 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 971
 972 is4 && \
 973 for mod in complist deltochar mathfunc ; do
 974     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 975 done
 976
 977 # autoload zsh modules when they are referenced
 978 if is4 ; then
 979     zmodload -a  zsh/stat    zstat
 980     zmodload -a  zsh/zpty    zpty
 981     zmodload -ap zsh/mapfile mapfile
 982 fi
 983
 984 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 985     #k# Insert files and test globbing
 986     bindkey "^xf" insert-files # C-x-f
 987 fi
 988
 989 bindkey ' '   magic-space    # also do history expansion on space
 990 #k# Trigger menu-complete
 991 bindkey '\ei' menu-complete  # menu completion via esc-i
 992
 993 # press esc-e for editing command line in $EDITOR or $VISUAL
 994 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 995     #k# Edit the current line in \kbd{\$EDITOR}
 996     bindkey '\ee' edit-command-line
 997 fi
 998
 999 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
1000     #k# menu selection: pick item but stay in the menu
1001     bindkey -M menuselect '\e^M' accept-and-menu-complete
1002     # also use + and INSERT since it's easier to press repeatedly
1003     bindkey -M menuselect "+" accept-and-menu-complete
1004     bindkey -M menuselect "^[[2~" accept-and-menu-complete
1005
1006     # accept a completion and try to complete again by using menu
1007     # completion; very useful with completing directories
1008     # by using 'undo' one's got a simple file browser
1009     bindkey -M menuselect '^o' accept-and-infer-next-history
1010 fi
1011
1012 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1013 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1014 zle -N insert-datestamp
1015
1016 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1017 bindkey '^ed' insert-datestamp
1018
1019 # press esc-m for inserting last typed word again (thanks to caphuso!)
1020 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1021 zle -N insert-last-typed-word;
1022
1023 #k# Insert last typed word
1024 bindkey "\em" insert-last-typed-word
1025
1026 function grml-zsh-fg() {
1027   if (( ${#jobstates} )); then
1028     zle .push-input
1029     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1030     BUFFER="${BUFFER}fg"
1031     zle .accept-line
1032   else
1033     zle -M 'No background jobs. Doing nothing.'
1034   fi
1035 }
1036 zle -N grml-zsh-fg
1037 #k# A smart shortcut for \kbd{fg<enter>}
1038 bindkey '^z' grml-zsh-fg
1039
1040 # run command line as user root via sudo:
1041 sudo-command-line() {
1042     [[ -z $BUFFER ]] && zle up-history
1043     if [[ $BUFFER != sudo\ * ]]; then
1044         BUFFER="sudo $BUFFER"
1045         CURSOR=$(( CURSOR+5 ))
1046     fi
1047 }
1048 zle -N sudo-command-line
1049
1050 #k# prepend the current command with "sudo"
1051 bindkey "^os" sudo-command-line
1052
1053 ### jump behind the first word on the cmdline.
1054 ### useful to add options.
1055 function jump_after_first_word() {
1056     local words
1057     words=(${(z)BUFFER})
1058
1059     if (( ${#words} <= 1 )) ; then
1060         CURSOR=${#BUFFER}
1061     else
1062         CURSOR=${#${words[1]}}
1063     fi
1064 }
1065 zle -N jump_after_first_word
1066 #k# jump to after first word (for adding options)
1067 bindkey '^x1' jump_after_first_word
1068
1069 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1070 zle -C hist-complete complete-word _generic
1071 zstyle ':completion:hist-complete:*' completer _history
1072 #k# complete word from history with menu
1073 bindkey "^x^x" hist-complete
1074
1075 ## complete word from currently visible Screen or Tmux buffer.
1076 if check_com -c screen || check_com -c tmux; then
1077     _complete_screen_display() {
1078         [[ "$TERM" != "screen" ]] && return 1
1079
1080         local TMPFILE=$(mktemp)
1081         local -U -a _screen_display_wordlist
1082         trap "rm -f $TMPFILE" EXIT
1083
1084         # fill array with contents from screen hardcopy
1085         if ((${+TMUX})); then
1086             #works, but crashes tmux below version 1.4
1087             #luckily tmux -V option to ask for version, was also added in 1.4
1088             tmux -V &>/dev/null || return
1089             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1090         else
1091             screen -X hardcopy $TMPFILE
1092             # screen sucks, it dumps in latin1, apparently always. so recode it
1093             # to system charset
1094             check_com recode && recode latin1 $TMPFILE
1095         fi
1096         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1097         # remove PREFIX to be completed from that array
1098         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1099         compadd -a _screen_display_wordlist
1100     }
1101     #k# complete word from currently visible GNU screen buffer
1102     bindkey -r "^xS"
1103     compdef -k _complete_screen_display complete-word '^xS'
1104 fi
1105
1106 # history
1107
1108 ZSHDIR=$HOME/.zsh
1109
1110 #v#
1111 HISTFILE=$HOME/.zsh_history
1112 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1113 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1114
1115 # dirstack handling
1116
1117 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1118 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1119
1120 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1121     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1122     # "cd -" won't work after login by just setting $OLDPWD, so
1123     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1124 fi
1125
1126 chpwd() {
1127     local -ax my_stack
1128     my_stack=( ${PWD} ${dirstack} )
1129     if is42 ; then
1130         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1131     else
1132         uprint my_stack >! ${DIRSTACKFILE}
1133     fi
1134 }
1135
1136 # directory based profiles
1137
1138 if is433 ; then
1139
1140 CHPWD_PROFILE='default'
1141 function chpwd_profiles() {
1142     # Say you want certain settings to be active in certain directories.
1143     # This is what you want.
1144     #
1145     # zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1146     # zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1147     #
1148     # When that's done and you enter a directory that matches the pattern
1149     # in the third part of the context, a function called chpwd_profile_grml,
1150     # for example, is called (if it exists).
1151     #
1152     # If no pattern matches (read: no profile is detected) the profile is
1153     # set to 'default', which means chpwd_profile_default is attempted to
1154     # be called.
1155     #
1156     # A word about the context (the ':chpwd:profiles:*' stuff in the zstyle
1157     # command) which is used: The third part in the context is matched against
1158     # ${PWD}. That's why using a pattern such as /foo/bar(|/|/*) makes sense.
1159     # Because that way the profile is detected for all these values of ${PWD}:
1160     #   /foo/bar
1161     #   /foo/bar/
1162     #   /foo/bar/baz
1163     # So, if you want to make double damn sure a profile works in /foo/bar
1164     # and everywhere deeper in that tree, just use (|/|/*) and be happy.
1165     #
1166     # The name of the detected profile will be available in a variable called
1167     # 'profile' in your functions. You don't need to do anything, it'll just
1168     # be there.
1169     #
1170     # Then there is the parameter $CHPWD_PROFILE is set to the profile, that
1171     # was is currently active. That way you can avoid running code for a
1172     # profile that is already active, by running code such as the following
1173     # at the start of your function:
1174     #
1175     # function chpwd_profile_grml() {
1176     #     [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1177     #   ...
1178     # }
1179     #
1180     # The initial value for $CHPWD_PROFILE is 'default'.
1181     #
1182     # Version requirement:
1183     #   This feature requires zsh 4.3.3 or newer.
1184     #   If you use this feature and need to know whether it is active in your
1185     #   current shell, there are several ways to do that. Here are two simple
1186     #   ways:
1187     #
1188     #   a) If knowing if the profiles feature is active when zsh starts is
1189     #      good enough for you, you can put the following snippet into your
1190     #      .zshrc.local:
1191     #
1192     #   (( ${+functions[chpwd_profiles]} )) && print "directory profiles active"
1193     #
1194     #   b) If that is not good enough, and you would prefer to be notified
1195     #      whenever a profile changes, you can solve that by making sure you
1196     #      start *every* profile function you create like this:
1197     #
1198     #   function chpwd_profile_myprofilename() {
1199     #       [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1200     #       print "chpwd(): Switching to profile: $profile"
1201     #     ...
1202     #   }
1203     #
1204     #      That makes sure you only get notified if a profile is *changed*,
1205     #      not everytime you change directory, which would probably piss
1206     #      you off fairly quickly. :-)
1207     #
1208     # There you go. Now have fun with that.
1209     local -x profile
1210
1211     zstyle -s ":chpwd:profiles:${PWD}" profile profile || profile='default'
1212     if (( ${+functions[chpwd_profile_$profile]} )) ; then
1213         chpwd_profile_${profile}
1214     fi
1215
1216     CHPWD_PROFILE="${profile}"
1217     return 0
1218 }
1219 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1220
1221 fi # is433
1222
1223 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1224 if [[ $BATTERY -gt 0 ]] ; then
1225     if ! check_com -c acpi ; then
1226         BATTERY=0
1227     fi
1228 fi
1229
1230 battery() {
1231 if [[ $BATTERY -gt 0 ]] ; then
1232     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1233     if [[ -z "$PERCENT" ]] ; then
1234         PERCENT='acpi not present'
1235     else
1236         if [[ "$PERCENT" -lt 20 ]] ; then
1237             PERCENT="warning: ${PERCENT}%%"
1238         else
1239             PERCENT="${PERCENT}%%"
1240         fi
1241     fi
1242 fi
1243 }
1244 # set colors for use in prompts
1245 if zrcautoload colors && colors 2>/dev/null ; then
1246     BLUE="%{${fg[blue]}%}"
1247     RED="%{${fg_bold[red]}%}"
1248     GREEN="%{${fg[green]}%}"
1249     CYAN="%{${fg[cyan]}%}"
1250     MAGENTA="%{${fg[magenta]}%}"
1251     YELLOW="%{${fg[yellow]}%}"
1252     WHITE="%{${fg[white]}%}"
1253     NO_COLOUR="%{${reset_color}%}"
1254 else
1255     BLUE=$'%{\e[1;34m%}'
1256     RED=$'%{\e[1;31m%}'
1257     GREEN=$'%{\e[1;32m%}'
1258     CYAN=$'%{\e[1;36m%}'
1259     WHITE=$'%{\e[1;37m%}'
1260     MAGENTA=$'%{\e[1;35m%}'
1261     YELLOW=$'%{\e[1;33m%}'
1262     NO_COLOUR=$'%{\e[0m%}'
1263 fi
1264
1265 # gather version control information for inclusion in a prompt
1266
1267 if zrcautoload vcs_info; then
1268     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1269     # function, which can cause a lot of trouble with our directory-based
1270     # profiles. So:
1271     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1272         function VCS_INFO_realpath () {
1273             setopt localoptions NO_shwordsplit chaselinks
1274             ( builtin cd -q $1 2> /dev/null && pwd; )
1275         }
1276     fi
1277
1278     zstyle ':vcs_info:*' max-exports 2
1279
1280     if [[ -o restricted ]]; then
1281         zstyle ':vcs_info:*' enable NONE
1282     fi
1283 fi
1284
1285 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1286 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1287 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1288 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1289 #       to $vcs_info_msg_N_ as soon as we use the included version.
1290 if [[ "$TERM" == dumb ]] ; then
1291     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1292     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1293 else
1294     # these are the same, just with a lot of colours:
1295     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
1296                                        "zsh: %r"
1297     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
1298                                        "zsh: %r"
1299     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1300 fi
1301
1302 # command not found handling
1303
1304 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1305 function command_not_found_handler() {
1306     emulate -L zsh
1307     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1308         ${GRML_ZSH_CNF_HANDLER} $1
1309     fi
1310     return 1
1311 }
1312
1313 # set prompt
1314 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1315     promptinit # people should be able to use their favourite prompt
1316 else
1317     print 'Notice: no promptinit available :('
1318 fi
1319
1320 setopt prompt_subst
1321
1322 # make sure to use right prompt only when not running a command
1323 is41 && setopt transient_rprompt
1324
1325
1326 function ESC_print () {
1327     info_print $'\ek' $'\e\\' "$@"
1328 }
1329 function set_title () {
1330     info_print  $'\e]0;' $'\a' "$@"
1331 }
1332
1333 function info_print () {
1334     local esc_begin esc_end
1335     esc_begin="$1"
1336     esc_end="$2"
1337     shift 2
1338     printf '%s' ${esc_begin}
1339     printf '%s' "$*"
1340     printf '%s' "${esc_end}"
1341 }
1342
1343 # TODO: revise all these NO* variables and especially their documentation
1344 #       in zsh-help() below.
1345 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1346     [[ $NOPRECMD -gt 0 ]] && return 0
1347     # update VCS information
1348     (( ${+functions[vcs_info]} )) && vcs_info
1349
1350     if [[ $TERM == screen* ]] ; then
1351         if [[ -n ${vcs_info_msg_1_} ]] ; then
1352             ESC_print ${vcs_info_msg_1_}
1353         else
1354             ESC_print "zsh"
1355         fi
1356     fi
1357     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1358     if [[ ${DONTSETRPROMPT:-} -eq 0 ]] ; then
1359         if [[ $BATTERY -gt 0 ]] ; then
1360             # update battery (dropped into $PERCENT) information
1361             battery
1362             RPROMPT="%(?..:() ${PERCENT}"
1363         else
1364             RPROMPT="%(?..:() "
1365         fi
1366     fi
1367     # adjust title of xterm
1368     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1369     [[ ${NOTITLE:-} -gt 0 ]] && return 0
1370     case $TERM in
1371         (xterm*|rxvt*)
1372             set_title ${(%):-"%n@%m: %~"}
1373             ;;
1374     esac
1375 }
1376
1377 # preexec() => a function running before every command
1378 is4 && [[ $NOPRECMD -eq 0 ]] && \
1379 preexec () {
1380     [[ $NOPRECMD -gt 0 ]] && return 0
1381 # set hostname if not running on host with name 'grml'
1382     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1383        NAME="@$HOSTNAME"
1384     fi
1385 # get the name of the program currently running and hostname of local machine
1386 # set screen window title if running in a screen
1387     if [[ "$TERM" == screen* ]] ; then
1388         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1389         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1390         ESC_print ${CMD}
1391     fi
1392 # adjust title of xterm
1393     [[ ${NOTITLE} -gt 0 ]] && return 0
1394     case $TERM in
1395         (xterm*|rxvt*)
1396             set_title "${(%):-"%n@%m:"}" "$1"
1397             ;;
1398     esac
1399 }
1400
1401 EXITCODE="%(?..%?%1v )"
1402 # secondary prompt, printed when the shell needs more information to complete a
1403 # command.
1404 PS2='\`%_> '
1405 # selection prompt used within a select loop.
1406 PS3='?# '
1407 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1408 PS4='+%N:%i:%_> '
1409
1410 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1411 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1412     debian_chroot=$(cat /etc/debian_chroot)
1413 fi
1414
1415 # don't use colors on dumb terminals (like emacs):
1416 if [[ "$TERM" == dumb ]] ; then
1417     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
1418 else
1419     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended
1420     # prompt set variable identifying the chroot you work in (used in the
1421     # prompt below)
1422     if [[ $GRMLPROMPT -gt 0 ]] ; then
1423         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1424 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1425     else
1426         # This assembles the primary prompt string
1427         if (( EUID != 0 )); then
1428             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1429         else
1430             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1431         fi
1432     fi
1433 fi
1434
1435 PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
1436
1437 # if we are inside a grml-chroot set a specific prompt theme
1438 if [[ -n "$GRML_CHROOT" ]] ; then
1439     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1440 fi
1441
1442 # 'hash' some often used directories
1443 #d# start
1444 hash -d deb=/var/cache/apt/archives
1445 hash -d doc=/usr/share/doc
1446 hash -d linux=/lib/modules/$(command uname -r)/build/
1447 hash -d log=/var/log
1448 hash -d slog=/var/log/syslog
1449 hash -d src=/usr/src
1450 hash -d templ=/usr/share/doc/grml-templates
1451 hash -d tt=/usr/share/doc/texttools-doc
1452 hash -d www=/var/www
1453 #d# end
1454
1455 # some aliases
1456 if check_com -c screen ; then
1457     if [[ $UID -eq 0 ]] ; then
1458         if [[ -r /etc/grml/screenrc ]]; then
1459             alias screen="${commands[screen]} -c /etc/grml/screenrc"
1460         fi
1461     elif [[ -r $HOME/.screenrc ]] ; then
1462         alias screen="${commands[screen]} -c $HOME/.screenrc"
1463     else
1464         if [[ -r /etc/grml/screenrc_grml ]]; then
1465             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1466         else
1467             if [[ -r /etc/grml/screenrc ]]; then
1468                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
1469             fi
1470         fi
1471     fi
1472 fi
1473
1474 # do we have GNU ls with color-support?
1475 if [[ "$TERM" != dumb ]]; then
1476     #a1# execute \kbd{@a@}:\quad ls with colors
1477     alias ls='ls -b -CF '${ls_options:+"${ls_options[*]} "}
1478     #a1# execute \kbd{@a@}:\quad list all files, with colors
1479     alias la='ls -la '${ls_options:+"${ls_options[*]} "}
1480     #a1# long colored list, without dotfiles (@a@)
1481     alias ll='ls -l '${ls_options:+"${ls_options[*]} "}
1482     #a1# long colored list, human readable sizes (@a@)
1483     alias lh='ls -hAl '${ls_options:+"${ls_options[*]} "}
1484     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1485     alias l='ls -lF '${ls_options:+"${ls_options[*]} "}
1486 else
1487     alias ls='ls -b -CF'
1488     alias la='ls -la'
1489     alias ll='ls -l'
1490     alias lh='ls -hAl'
1491     alias l='ls -lF'
1492 fi
1493
1494 alias mdstat='cat /proc/mdstat'
1495 alias ...='cd ../../'
1496
1497 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1498 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1499     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1500 fi
1501
1502 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1503 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1504 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1505
1506 # make sure it is not assigned yet
1507 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1508 utf2iso() {
1509     if isutfenv ; then
1510         for ENV in $(env | command grep -i '.utf') ; do
1511             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1512         done
1513     fi
1514 }
1515
1516 # make sure it is not assigned yet
1517 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1518 iso2utf() {
1519     if ! isutfenv ; then
1520         for ENV in $(env | command grep -i '\.iso') ; do
1521             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1522         done
1523     fi
1524 }
1525
1526 # especially for roadwarriors using GNU screen and ssh:
1527 if ! check_com asc &>/dev/null ; then
1528   asc() { autossh -t "$@" 'screen -RdU' }
1529   compdef asc=ssh
1530 fi
1531
1532 #f1# Hints for the use of zsh on grml
1533 zsh-help() {
1534     print "$bg[white]$fg[black]
1535 zsh-help - hints for use of zsh on grml
1536 =======================================$reset_color"
1537
1538     print '
1539 Main configuration of zsh happens in /etc/zsh/zshrc.
1540 That file is part of the package grml-etc-core, if you want to
1541 use them on a non-grml-system just get the tar.gz from
1542 http://deb.grml.org/ or (preferably) get it from the git repository:
1543
1544   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1545
1546 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1547 The file is still there, but it is empty for backwards compatibility.
1548
1549 For your own changes use these two files:
1550     $HOME/.zshrc.pre
1551     $HOME/.zshrc.local
1552
1553 The former is sourced very early in our zshrc, the latter is sourced
1554 very lately.
1555
1556 System wide configuration without touching configuration files of grml
1557 can take place in /etc/zsh/zshrc.local.
1558
1559 For information regarding zsh start at http://grml.org/zsh/
1560
1561 Take a look at grml'\''s zsh refcard:
1562 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1563
1564 Check out the main zsh refcard:
1565 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1566
1567 And of course visit the zsh-lovers:
1568 % man zsh-lovers
1569
1570 You can adjust some options through environment variables when
1571 invoking zsh without having to edit configuration files.
1572 Basically meant for bash users who are not used to the power of
1573 the zsh yet. :)
1574
1575   "NOCOR=1    zsh" => deactivate automatic correction
1576   "NOMENU=1   zsh" => do not use auto menu completion
1577                       (note: use ctrl-d for completion instead!)
1578   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1579   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1580                       preexec() and precmd() completely
1581   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1582   "COMMAND_NOT_FOUND=1 zsh"
1583                    => Enable a handler if an external command was not found
1584                       The command called in the handler can be altered by setting
1585                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1586                       "/usr/share/command-not-found/command-not-found"
1587
1588 A value greater than 0 is enables a feature; a value equal to zero
1589 disables it. If you like one or the other of these settings, you can
1590 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1591 zshrc.'
1592
1593     print "
1594 $bg[white]$fg[black]
1595 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1596 Enjoy your grml system with the zsh!$reset_color"
1597 }
1598
1599 # debian stuff
1600 if [[ -r /etc/debian_version ]] ; then
1601     #a3# Execute \kbd{apt-cache search}
1602     alias acs='apt-cache search'
1603     #a3# Execute \kbd{apt-cache show}
1604     alias acsh='apt-cache show'
1605     #a3# Execute \kbd{apt-cache policy}
1606     alias acp='apt-cache policy'
1607     #a3# Execute \kbd{apt-get dist-upgrade}
1608     salias adg="apt-get dist-upgrade"
1609     #a3# Execute \kbd{apt-get install}
1610     salias agi="apt-get install"
1611     #a3# Execute \kbd{aptitude install}
1612     salias ati="aptitude install"
1613     #a3# Execute \kbd{apt-get upgrade}
1614     salias ag="apt-get upgrade"
1615     #a3# Execute \kbd{apt-get update}
1616     salias au="apt-get update"
1617     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1618     salias -a up="aptitude update ; aptitude safe-upgrade"
1619     #a3# Execute \kbd{dpkg-buildpackage}
1620     alias dbp='dpkg-buildpackage'
1621     #a3# Execute \kbd{grep-excuses}
1622     alias ge='grep-excuses'
1623
1624     # get a root shell as normal user in live-cd mode:
1625     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1626        alias su="sudo su"
1627      fi
1628
1629     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1630     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1631     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1632     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1633 fi
1634
1635 # sort installed Debian-packages by size
1636 if check_com -c dpkg-query ; then
1637     #a3# List installed Debian-packages sorted by size
1638     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1639 fi
1640
1641 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1642 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1643     if check_com -c wodim; then
1644         cdrecord() {
1645             cat <<EOMESS
1646 cdrecord is not provided under its original name by Debian anymore.
1647 See #377109 in the BTS of Debian for more details.
1648
1649 Please use the wodim binary instead
1650 EOMESS
1651             return 1
1652         }
1653     fi
1654 fi
1655
1656 # Use hard limits, except for a smaller stack and no core dumps
1657 unlimit
1658 is425 && limit stack 8192
1659 isgrmlcd && limit core 0 # important for a live-cd-system
1660 limit -s
1661
1662 # completion system
1663
1664 # called later (via is4 && grmlcomp)
1665 # note: use 'zstyle' for getting current settings
1666 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
1667 grmlcomp() {
1668     # TODO: This could use some additional information
1669
1670     # allow one error for every three characters typed in approximate completer
1671     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1672
1673     # don't complete backup files as executables
1674     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1675
1676     # start menu completion only if it could find no unambiguous initial string
1677     zstyle ':completion:*:correct:*'       insert-unambiguous true
1678     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1679     zstyle ':completion:*:correct:*'       original true
1680
1681     # activate color-completion
1682     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1683
1684     # format on completion
1685     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1686
1687     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1688     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1689
1690     # insert all expansions for expand completer
1691     zstyle ':completion:*:expand:*'        tag-order all-expansions
1692     zstyle ':completion:*:history-words'   list false
1693
1694     # activate menu
1695     zstyle ':completion:*:history-words'   menu yes
1696
1697     # ignore duplicate entries
1698     zstyle ':completion:*:history-words'   remove-all-dups yes
1699     zstyle ':completion:*:history-words'   stop yes
1700
1701     # match uppercase from lowercase
1702     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1703
1704     # separate matches into groups
1705     zstyle ':completion:*:matches'         group 'yes'
1706     zstyle ':completion:*'                 group-name ''
1707
1708     if [[ "$NOMENU" -eq 0 ]] ; then
1709         # if there are more than 5 options allow selecting from a menu
1710         zstyle ':completion:*'               menu select=5
1711     else
1712         # don't use any menus at all
1713         setopt no_auto_menu
1714     fi
1715
1716     zstyle ':completion:*:messages'        format '%d'
1717     zstyle ':completion:*:options'         auto-description '%d'
1718
1719     # describe options in full
1720     zstyle ':completion:*:options'         description 'yes'
1721
1722     # on processes completion complete all user processes
1723     zstyle ':completion:*:processes'       command 'ps -au$USER'
1724
1725     # offer indexes before parameters in subscripts
1726     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1727
1728     # provide verbose completion information
1729     zstyle ':completion:*'                 verbose true
1730
1731     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1732     # for commands (read: 1st word in the line) that it will list for the user
1733     # to choose from. The following disables that, because it's not exactly fast.
1734     zstyle ':completion:*:-command-:*:'    verbose false
1735
1736     # set format for warnings
1737     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1738
1739     # define files to ignore for zcompile
1740     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1741     zstyle ':completion:correct:'          prompt 'correct to: %e'
1742
1743     # Ignore completion functions for commands you don't have:
1744     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1745
1746     # Provide more processes in completion of programs like killall:
1747     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1748
1749     # complete manual by their section
1750     zstyle ':completion:*:manuals'    separate-sections true
1751     zstyle ':completion:*:manuals.*'  insert-sections   true
1752     zstyle ':completion:*:man:*'      menu yes select
1753
1754     # provide .. as a completion
1755     zstyle ':completion:*' special-dirs ..
1756
1757     # run rehash on completion so new installed program are found automatically:
1758     _force_rehash() {
1759         (( CURRENT == 1 )) && rehash
1760         return 1
1761     }
1762
1763     ## correction
1764     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1765     if [[ "$NOCOR" -gt 0 ]] ; then
1766         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1767         setopt nocorrect
1768     else
1769         # try to be smart about when to use what completer...
1770         setopt correct
1771         zstyle -e ':completion:*' completer '
1772             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1773                 _last_try="$HISTNO$BUFFER$CURSOR"
1774                 reply=(_complete _match _ignored _prefix _files)
1775             else
1776                 if [[ $words[1] == (rm|mv) ]] ; then
1777                     reply=(_complete _files)
1778                 else
1779                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1780                 fi
1781             fi'
1782     fi
1783
1784     # command for process lists, the local web server details and host completion
1785     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1786
1787     # caching
1788     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1789                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1790
1791     # host completion
1792     if is42 ; then
1793         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1794         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1795     else
1796         _ssh_hosts=()
1797         _etc_hosts=()
1798     fi
1799     hosts=(
1800         $(hostname)
1801         "$_ssh_hosts[@]"
1802         "$_etc_hosts[@]"
1803         grml.org
1804         localhost
1805     )
1806     zstyle ':completion:*:hosts' hosts $hosts
1807     # TODO: so, why is this here?
1808     #  zstyle '*' hosts $hosts
1809
1810     # use generic completion system for programs not yet defined; (_gnu_generic works
1811     # with commands that provide a --help option with "standard" gnu-like output.)
1812     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
1813                    pal stow tail uname ; do
1814         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
1815     done; unset compcom
1816
1817     # see upgrade function in this file
1818     compdef _hosts upgrade
1819 }
1820
1821 # grmlstuff
1822 grmlstuff() {
1823 # people should use 'grml-x'!
1824     if check_com -c 915resolution; then
1825         855resolution() {
1826             echo "Please use 915resolution as resolution modifying tool for Intel \
1827 graphic chipset."
1828             return -1
1829         }
1830     fi
1831
1832     #a1# Output version of running grml
1833     alias grml-version='cat /etc/grml_version'
1834
1835     if check_com -c rebuildfstab ; then
1836         #a1# Rebuild /etc/fstab
1837         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1838     fi
1839
1840     if check_com -c grml-debootstrap ; then
1841         debian2hd() {
1842             echo "Installing debian to harddisk is possible by using grml-debootstrap."
1843             return 1
1844         }
1845     fi
1846 }
1847
1848 # now run the functions
1849 isgrml && checkhome
1850 is4    && isgrml    && grmlstuff
1851 is4    && grmlcomp
1852
1853 # keephack
1854 is4 && xsource "/etc/zsh/keephack"
1855
1856 # wonderful idea of using "e" glob qualifier by Peter Stephenson
1857 # You use it as follows:
1858 # $ NTREF=/reference/file
1859 # $ ls -l *(e:nt:)
1860 # This lists all the files in the current directory newer than the reference file.
1861 # You can also specify the reference file inline; note quotes:
1862 # $ ls -l *(e:'nt ~/.zshenv':)
1863 is4 && nt() {
1864     if [[ -n $1 ]] ; then
1865         local NTREF=${~1}
1866     fi
1867     [[ $REPLY -nt $NTREF ]]
1868 }
1869
1870 # shell functions
1871
1872 #f1# Reload an autoloadable function
1873 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1874 compdef _functions freload
1875
1876 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1877 sll() {
1878     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1879     for file in "$@" ; do
1880         while [[ -h "$file" ]] ; do
1881             ls -l $file
1882             file=$(readlink "$file")
1883         done
1884     done
1885 }
1886
1887 # TODO: Is it supported to use pager settings like this?
1888 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
1889 # with respect to wordsplitting. (ie. ${=PAGER})
1890 if check_com -c $PAGER ; then
1891     #f1# View Debian's changelog of a given package
1892     dchange() {
1893         emulate -L zsh
1894         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
1895             $PAGER /usr/share/doc/$1/changelog.Debian.gz
1896         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1897             $PAGER /usr/share/doc/$1/changelog.gz
1898         else
1899             if check_com -c aptitude ; then
1900                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1901                 if isgrml ; then
1902                     aptitude -t unstable changelog $1
1903                 else
1904                     aptitude changelog $1
1905                 fi
1906             else
1907                 echo "No changelog for package $1 found, sorry."
1908                 return 1
1909             fi
1910         fi
1911     }
1912     _dchange() { _files -W /usr/share/doc -/ }
1913     compdef _dchange dchange
1914
1915     #f1# View Debian's NEWS of a given package
1916     dnews() {
1917         emulate -L zsh
1918         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
1919             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
1920         else
1921             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
1922                 $PAGER /usr/share/doc/$1/NEWS.gz
1923             else
1924                 echo "No NEWS file for package $1 found, sorry."
1925                 return 1
1926             fi
1927         fi
1928     }
1929     _dnews() { _files -W /usr/share/doc -/ }
1930     compdef _dnews dnews
1931
1932     #f1# View upstream's changelog of a given package
1933     uchange() {
1934         emulate -L zsh
1935         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1936             $PAGER /usr/share/doc/$1/changelog.gz
1937         else
1938             echo "No changelog for package $1 found, sorry."
1939             return 1
1940         fi
1941     }
1942     _uchange() { _files -W /usr/share/doc -/ }
1943     compdef _uchange uchange
1944 fi
1945
1946 # zsh profiling
1947 profile() {
1948     ZSH_PROFILE_RC=1 $SHELL "$@"
1949 }
1950
1951 #f1# Edit an alias via zle
1952 edalias() {
1953     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1954 }
1955 compdef _aliases edalias
1956
1957 #f1# Edit a function via zle
1958 edfunc() {
1959     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
1960 }
1961 compdef _functions edfunc
1962
1963 # use it e.g. via 'Restart apache2'
1964 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
1965 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
1966 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
1967 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
1968 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
1969 if [[ -d /etc/init.d || -d /etc/service ]] ; then
1970     __start_stop() {
1971         local action_="${1:l}"  # e.g Start/Stop/Restart
1972         local service_="$2"
1973         local param_="$3"
1974
1975         local service_target_="$(readlink /etc/init.d/$service_)"
1976         if [[ $service_target_ == "/usr/bin/sv" ]]; then
1977             # runit
1978             case "${action_}" in
1979                 start) if [[ ! -e /etc/service/$service_ ]]; then
1980                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
1981                        else
1982                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1983                        fi ;;
1984                 # there is no reload in runits sysv emulation
1985                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
1986                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
1987             esac
1988         else
1989             # sysvinit
1990             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1991         fi
1992     }
1993
1994     _grmlinitd() {
1995         local -a scripts
1996         scripts=( /etc/init.d/*(x:t) )
1997         _describe "service startup script" scripts
1998     }
1999
2000     for i in Start Restart Stop Force-Reload Reload ; do
2001         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2002         compdef _grmlinitd $i
2003     done
2004 fi
2005
2006 #f1# Provides useful information on globbing
2007 H-Glob() {
2008     echo -e "
2009     /      directories
2010     .      plain files
2011     @      symbolic links
2012     =      sockets
2013     p      named pipes (FIFOs)
2014     *      executable plain files (0100)
2015     %      device files (character or block special)
2016     %b     block special files
2017     %c     character special files
2018     r      owner-readable files (0400)
2019     w      owner-writable files (0200)
2020     x      owner-executable files (0100)
2021     A      group-readable files (0040)
2022     I      group-writable files (0020)
2023     E      group-executable files (0010)
2024     R      world-readable files (0004)
2025     W      world-writable files (0002)
2026     X      world-executable files (0001)
2027     s      setuid files (04000)
2028     S      setgid files (02000)
2029     t      files with the sticky bit (01000)
2030
2031   print *(m-1)          # Files modified up to a day ago
2032   print *(a1)           # Files accessed a day ago
2033   print *(@)            # Just symlinks
2034   print *(Lk+50)        # Files bigger than 50 kilobytes
2035   print *(Lk-50)        # Files smaller than 50 kilobytes
2036   print **/*.c          # All *.c files recursively starting in \$PWD
2037   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2038   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2039   print *~*.*           # All Files that do not contain a dot
2040   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2041   print -l *(.c|.h)     # Lists *.c and *.h
2042   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2043   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2044 }
2045 alias help-zshglob=H-Glob
2046
2047 #v1# set number of lines to display per page
2048 HELP_LINES_PER_PAGE=20
2049 #v1# set location of help-zle cache file
2050 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
2051 #f1# helper function for help-zle, actually generates the help text
2052 help_zle_parse_keybindings()
2053 {
2054     emulate -L zsh
2055     setopt extendedglob
2056     unsetopt ksharrays  #indexing starts at 1
2057
2058     #v1# choose files that help-zle will parse for keybindings
2059     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
2060
2061     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
2062         local load_cache=0
2063         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
2064         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
2065     fi
2066
2067     #fill with default keybindings, possibly to be overwriten in a file later
2068     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2069     local -A help_zle_keybindings
2070     help_zle_keybindings['<Ctrl>@']="set MARK"
2071     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
2072     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
2073     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
2074     help_zle_keybindings['<Ctrl>_']="undo"
2075     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
2076     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
2077     help_zle_keybindings['<Ctrl>e']="goto end of line"
2078     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2079     help_zle_keybindings['<Alt>t']="transpose words"
2080     help_zle_keybindings['<Alt>s']="spellcheck word"
2081     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
2082     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
2083     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2084     help_zle_keybindings["<Alt>'"]="quote line"
2085     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2086     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2087     help_zle_keybindings['<Alt>u']="make next word Uppercase"
2088     help_zle_keybindings['<Alt>l']="make next word lowercase"
2089     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
2090     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2091     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2092     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2093     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2094     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
2095     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2096     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2097     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
2098
2099     #init global variables
2100     unset help_zle_lines help_zle_sln
2101     typeset -g -a help_zle_lines
2102     typeset -g help_zle_sln=1
2103
2104     local k v
2105     local lastkeybind_desc contents     #last description starting with #k# that we found
2106     local num_lines_elapsed=0            #number of lines between last description and keybinding
2107     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2108     for f in $HELPZLE_KEYBINDING_FILES; do
2109         [[ -r "$f" ]] || continue   #not readable ? skip it
2110         contents="$(<$f)"
2111         for cline in "${(f)contents}"; do
2112             #zsh pattern: matches lines like: #k# ..............
2113             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2114                 lastkeybind_desc="$match[*]"
2115                 num_lines_elapsed=0
2116             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2117             #             ignores lines that are commentend out
2118             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2119             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2120                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2121                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2122                     #substitute keybinding string with something readable
2123                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2124                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2125                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2126                     help_zle_keybindings[${k}]=$lastkeybind_desc
2127                 fi
2128                 lastkeybind_desc=""
2129             else
2130               ((num_lines_elapsed++))
2131             fi
2132         done
2133     done
2134     unset contents
2135     #calculate length of keybinding column
2136     local kstrlen=0
2137     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2138     #convert the assoc array into preformated lines, which we are able to sort
2139     for k v in ${(kv)help_zle_keybindings[@]}; do
2140         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2141         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2142     done
2143     #sort lines alphabetically
2144     help_zle_lines=("${(i)help_zle_lines[@]}")
2145     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2146     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2147     zcompile $HELP_ZLE_CACHE_FILE
2148 }
2149 typeset -g help_zle_sln
2150 typeset -g -a help_zle_lines
2151
2152 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2153 help-zle()
2154 {
2155     emulate -L zsh
2156     unsetopt ksharrays  #indexing starts at 1
2157     #help lines already generated ? no ? then do it
2158     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2159     #already displayed all lines ? go back to the start
2160     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2161     local sln=$help_zle_sln
2162     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2163     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2164     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2165 }
2166 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2167 zle -N help-zle && bindkey '^xz' help-zle
2168
2169 # grep for running process, like: 'any vim'
2170 any() {
2171     emulate -L zsh
2172     unsetopt KSH_ARRAYS
2173     if [[ -z "$1" ]] ; then
2174         echo "any - grep for process(es) by keyword" >&2
2175         echo "Usage: any <keyword>" >&2 ; return 1
2176     else
2177         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
2178     fi
2179 }
2180
2181
2182 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2183 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2184 [[ -r /proc/1/maps ]] && \
2185 deswap() {
2186     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2187     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2188     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2189 }
2190
2191 # a wrapper for vim, that deals with title setting
2192 #   VIM_OPTIONS
2193 #       set this array to a set of options to vim you always want
2194 #       to have set when calling vim (in .zshrc.local), like:
2195 #           VIM_OPTIONS=( -p )
2196 #       This will cause vim to send every file given on the
2197 #       commandline to be send to it's own tab (needs vim7).
2198 vim() {
2199     VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2200 }
2201
2202 # make a backup of a file
2203 bk() {
2204     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2205 }
2206
2207 ssl_hashes=( sha512 sha256 sha1 md5 )
2208
2209 for sh in ${ssl_hashes}; do
2210     eval 'ssl-cert-'${sh}'() {
2211         emulate -L zsh
2212         if [[ -z $1 ]] ; then
2213             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2214             return 1
2215         fi
2216         openssl x509 -noout -fingerprint -'${sh}' -in $1
2217     }'
2218 done; unset sh
2219
2220 ssl-cert-fingerprints() {
2221     emulate -L zsh
2222     local i
2223     if [[ -z $1 ]] ; then
2224         printf 'usage: ssl-cert-fingerprints <file>\n'
2225         return 1
2226     fi
2227     for i in ${ssl_hashes}
2228         do ssl-cert-$i $1;
2229     done
2230 }
2231
2232 ssl-cert-info() {
2233     emulate -L zsh
2234     if [[ -z $1 ]] ; then
2235         printf 'usage: ssl-cert-info <file>\n'
2236         return 1
2237     fi
2238     openssl x509 -noout -text -in $1
2239     ssl-cert-fingerprints $1
2240 }
2241
2242 # make sure our environment is clean regarding colors
2243 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2244
2245 # "persistent history"
2246 # just write important commands you always need to ~/.important_commands
2247 if [[ -r ~/.important_commands ]] ; then
2248     fc -R ~/.important_commands
2249 fi
2250
2251 # load the lookup subsystem if it's available on the system
2252 zrcautoload lookupinit && lookupinit
2253
2254 # variables
2255
2256 # set terminal property (used e.g. by msgid-chooser)
2257 export COLORTERM="yes"
2258
2259 # aliases
2260
2261 # general
2262 #a2# Execute \kbd{du -sch}
2263 alias da='du -sch'
2264 #a2# Execute \kbd{jobs -l}
2265 alias j='jobs -l'
2266
2267 # listing stuff
2268 #a2# Execute \kbd{ls -lSrah}
2269 alias dir="ls -lSrah"
2270 #a2# Only show dot-directories
2271 alias lad='ls -d .*(/)'                # only show dot-directories
2272 #a2# Only show dot-files
2273 alias lsa='ls -a .*(.)'                # only show dot-files
2274 #a2# Only files with setgid/setuid/sticky flag
2275 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
2276 #a2# Only show 1st ten symlinks
2277 alias lsl='ls -l *(@)'                 # only symlinks
2278 #a2# Display only executables
2279 alias lsx='ls -l *(*)'                 # only executables
2280 #a2# Display world-{readable,writable,executable} files
2281 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
2282 #a2# Display the ten biggest files
2283 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
2284 #a2# Only show directories
2285 alias lsd='ls -d *(/)'                 # only show directories
2286 #a2# Only show empty directories
2287 alias lse='ls -d *(/^F)'               # only show empty directories
2288 #a2# Display the ten newest files
2289 alias lsnew="ls -rtlh *(D.om[1,10])"   # display the newest files
2290 #a2# Display the ten oldest files
2291 alias lsold="ls -rtlh *(D.Om[1,10])"   # display the oldest files
2292 #a2# Display the ten smallest files
2293 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
2294 #a2# Display the ten newest directories and ten newest .directories
2295 alias lsnewdir="ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
2296 #a2# Display the ten oldest directories and ten oldest .directories
2297 alias lsolddir="ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
2298
2299 # some useful aliases
2300 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir $OLDCWD}
2301 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2302
2303 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2304 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2305 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2306
2307 # simple webserver
2308 check_com -c python && alias http="python -m SimpleHTTPServer"
2309
2310 # work around non utf8 capable software in utf environment via $LANG and luit
2311 if check_com isutfenv && check_com luit ; then
2312     if check_com -c mrxvt ; then
2313         isutfenv && [[ -n "$LANG" ]] && \
2314             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2315     fi
2316
2317     if check_com -c aterm ; then
2318         isutfenv && [[ -n "$LANG" ]] && \
2319             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2320     fi
2321
2322     if check_com -c centericq ; then
2323         isutfenv && [[ -n "$LANG" ]] && \
2324             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2325     fi
2326 fi
2327
2328 # useful functions
2329
2330 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2331 bk() {
2332     emulate -L zsh
2333     cp -b $1 $1_`date --iso-8601=m`
2334 }
2335
2336 #f5# cd to directoy and list files
2337 cl() {
2338     emulate -L zsh
2339     cd $1 && ls -a
2340 }
2341
2342 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2343 cd() {
2344     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2345         [[ ! -e ${1:h} ]] && return 1
2346         print "Correcting ${1} to ${1:h}"
2347         builtin cd ${1:h}
2348     else
2349         builtin cd "$@"
2350     fi
2351 }
2352
2353 #f5# Create Directoy and \kbd{cd} to it
2354 mkcd() {
2355     mkdir -p "$@" && cd "$@"
2356 }
2357
2358 #f5# Create temporary directory and \kbd{cd} to it
2359 cdt() {
2360     local t
2361     t=$(mktemp -d)
2362     echo "$t"
2363     builtin cd "$t"
2364 }
2365
2366 #f5# Create directory under cursor or the selected area
2367 # Press ctrl-xM to create the directory under the cursor or the selected area.
2368 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2369 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2370 # directory does not exist yet -> press ctrl-XM and problem solved
2371 inplaceMkDirs() {
2372     local PATHTOMKDIR
2373     if ((REGION_ACTIVE==1)); then
2374         local F=$MARK T=$CURSOR
2375         if [[ $F -gt $T ]]; then
2376             F=${CURSOR}
2377             T=${MARK}
2378         fi
2379         # get marked area from buffer and eliminate whitespace
2380         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2381         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2382     else
2383         local bufwords iword
2384         bufwords=(${(z)LBUFFER})
2385         iword=${#bufwords}
2386         bufwords=(${(z)BUFFER})
2387         PATHTOMKDIR="${(Q)bufwords[iword]}"
2388     fi
2389     [[ -z "${PATHTOMKDIR}" ]] && return 1
2390     if [[ -e "${PATHTOMKDIR}" ]]; then
2391         zle -M " path already exists, doing nothing"
2392     else
2393         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2394         zle end-of-line
2395     fi
2396 }
2397 #k# mkdir -p <dir> from string under cursor or marked area
2398 zle -N inplaceMkDirs && bindkey '^xM' inplaceMkDirs
2399
2400 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2401 accessed() {
2402     emulate -L zsh
2403     print -l -- *(a-${1:-1})
2404 }
2405
2406 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2407 changed() {
2408     emulate -L zsh
2409     print -l -- *(c-${1:-1})
2410 }
2411
2412 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2413 modified() {
2414     emulate -L zsh
2415     print -l -- *(m-${1:-1})
2416 }
2417 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2418 check_com new || alias new=modified
2419
2420 # use colors when GNU grep with color-support
2421 #a2# Execute \kbd{grep -{}-color=auto}
2422 (( $#grep_options > 0 )) && alias grep='grep '${grep_options:+"${grep_options[*]} "}'
2423
2424 # Translate DE<=>EN
2425 # 'translate' looks up fot a word in a file with language-to-language
2426 # translations (field separator should be " : "). A typical wordlist looks
2427 # like at follows:
2428 #  | english-word : german-transmission
2429 # It's also only possible to translate english to german but not reciprocal.
2430 # Use the following oneliner to turn back the sort order:
2431 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2432 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2433 #f5# Translates a word
2434 trans() {
2435     emulate -L zsh
2436     case "$1" in
2437         -[dD]*)
2438             translate -l de-en $2
2439             ;;
2440         -[eE]*)
2441             translate -l en-de $2
2442             ;;
2443         *)
2444             echo "Usage: $0 { -D | -E }"
2445             echo "         -D == German to English"
2446             echo "         -E == English to German"
2447     esac
2448 }
2449
2450 # Usage: simple-extract <file>
2451 # Using option -d deletes the original archive file.
2452 #f5# Smart archive extractor
2453 simple-extract() {
2454     emulate -L zsh
2455     setopt extended_glob noclobber
2456     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2457     local RC=0
2458     zparseopts -D -E "d=DELETE_ORIGINAL"
2459     for ARCHIVE in "${@}"; do
2460         case $ARCHIVE in
2461             *.(tar.bz2|tbz2|tbz))
2462                 DECOMP_CMD="tar -xvjf -"
2463                 USES_STDIN=true
2464                 USES_STDOUT=false
2465                 ;;
2466             *.(tar.gz|tgz))
2467                 DECOMP_CMD="tar -xvzf -"
2468                 USES_STDIN=true
2469                 USES_STDOUT=false
2470                 ;;
2471             *.(tar.xz|txz|tar.lzma))
2472                 DECOMP_CMD="tar -xvJf -"
2473                 USES_STDIN=true
2474                 USES_STDOUT=false
2475                 ;;
2476             *.tar)
2477                 DECOMP_CMD="tar -xvf -"
2478                 USES_STDIN=true
2479                 USES_STDOUT=false
2480                 ;;
2481             *.rar)
2482                 DECOMP_CMD="unrar x"
2483                 USES_STDIN=false
2484                 USES_STDOUT=false
2485                 ;;
2486             *.lzh)
2487                 DECOMP_CMD="lha x"
2488                 USES_STDIN=false
2489                 USES_STDOUT=false
2490                 ;;
2491             *.7z)
2492                 DECOMP_CMD="7z x"
2493                 USES_STDIN=false
2494                 USES_STDOUT=false
2495                 ;;
2496             *.(zip|jar))
2497                 DECOMP_CMD="unzip"
2498                 USES_STDIN=false
2499                 USES_STDOUT=false
2500                 ;;
2501             *.deb)
2502                 DECOMP_CMD="ar -x"
2503                 USES_STDIN=false
2504                 USES_STDOUT=false
2505                 ;;
2506             *.bz2)
2507                 DECOMP_CMD="bzip2 -d -c -"
2508                 USES_STDIN=true
2509                 USES_STDOUT=true
2510                 ;;
2511             *.(gz|Z))
2512                 DECOMP_CMD="gzip -d -c -"
2513                 USES_STDIN=true
2514                 USES_STDOUT=true
2515                 ;;
2516             *.(xz|lzma))
2517                 DECOMP_CMD="xz -d -c -"
2518                 USES_STDIN=true
2519                 USES_STDOUT=true
2520                 ;;
2521             *)
2522                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2523                 RC=$((RC+1))
2524                 continue
2525                 ;;
2526         esac
2527
2528         if ! check_com ${DECOMP_CMD[(w)1]}; then
2529             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2530             RC=$((RC+2))
2531             continue
2532         fi
2533
2534         GZTARGET="${ARCHIVE:t:r}"
2535         if [[ -f $ARCHIVE ]] ; then
2536
2537             print "Extracting '$ARCHIVE' ..."
2538             if $USES_STDIN; then
2539                 if $USES_STDOUT; then
2540                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
2541                 else
2542                     ${=DECOMP_CMD} < "$ARCHIVE"
2543                 fi
2544             else
2545                 if $USES_STDOUT; then
2546                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
2547                 else
2548                     ${=DECOMP_CMD} "$ARCHIVE"
2549                 fi
2550             fi
2551             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
2552
2553         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
2554             if check_com curl; then
2555                 WGET_CMD="curl -L -k -s -o -"
2556             elif check_com wget; then
2557                 WGET_CMD="wget -q -O - --no-check-certificate"
2558             else
2559                 print "ERROR: neither wget nor curl is installed" >&2
2560                 RC=$((RC+4))
2561                 continue
2562             fi
2563             print "Downloading and Extracting '$ARCHIVE' ..."
2564             if $USES_STDIN; then
2565                 if $USES_STDOUT; then
2566                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
2567                     RC=$((RC+$?))
2568                 else
2569                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
2570                     RC=$((RC+$?))
2571                 fi
2572             else
2573                 if $USES_STDOUT; then
2574                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
2575                 else
2576                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
2577                 fi
2578             fi
2579
2580         else
2581             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
2582             RC=$((RC+8))
2583         fi
2584     done
2585     return $RC
2586 }
2587
2588 __archive_or_uri()
2589 {
2590     _alternative \
2591         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
2592         '_urls:Remote Archives:_urls'
2593 }
2594
2595 _simple_extract()
2596 {
2597     _arguments \
2598         '-d[delete original archivefile after extraction]' \
2599         '*:Archive Or Uri:__archive_or_uri'
2600 }
2601 compdef _simple_extract simple-extract
2602 alias se=simple-extract
2603
2604 #f5# Set all ulimit parameters to \kbd{unlimited}
2605 allulimit() {
2606     ulimit -c unlimited
2607     ulimit -d unlimited
2608     ulimit -f unlimited
2609     ulimit -l unlimited
2610     ulimit -n unlimited
2611     ulimit -s unlimited
2612     ulimit -t unlimited
2613 }
2614
2615 #f5# Change the xterm title from within GNU-screen
2616 xtrename() {
2617     emulate -L zsh
2618     if [[ $1 != "-f" ]] ; then
2619         if [[ -z ${DISPLAY} ]] ; then
2620             printf 'xtrename only makes sense in X11.\n'
2621             return 1
2622         fi
2623     else
2624         shift
2625     fi
2626     if [[ -z $1 ]] ; then
2627         printf 'usage: xtrename [-f] "title for xterm"\n'
2628         printf '  renames the title of xterm from _within_ screen.\n'
2629         printf '  also works without screen.\n'
2630         printf '  will not work if DISPLAY is unset, use -f to override.\n'
2631         return 0
2632     fi
2633     print -n "\eP\e]0;${1}\C-G\e\\"
2634     return 0
2635 }
2636
2637 # TODO:
2638 # Rewrite this by either using tinyurl.com's API
2639 # or using another shortening service to comply with
2640 # tinyurl.com's policy.
2641 #
2642 # Create small urls via http://tinyurl.com using wget(1).
2643 #function zurl() {
2644 #    emulate -L zsh
2645 #    [[ -z $1 ]] && { print "USAGE: zurl <URL>" ; return 1 }
2646 #
2647 #    local PN url tiny grabber search result preview
2648 #    PN=$0
2649 #    url=$1
2650 ##   Check existence of given URL with the help of ping(1).
2651 ##   N.B. ping(1) only works without an eventual given protocol.
2652 #    ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
2653 #        read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
2654 #
2655 #    if (( $? == 0 )) ; then
2656 ##           Prepend 'http://' to given URL where necessary for later output.
2657 #            [[ ${url} != http(s|)://* ]] && url='http://'${url}
2658 #            tiny='http://tinyurl.com/create.php?url='
2659 #            if check_com -c wget ; then
2660 #                grabber='wget -O- -o/dev/null'
2661 #            else
2662 #                print "wget is not available, but mandatory for ${PN}. Aborting."
2663 #            fi
2664 ##           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
2665 #            search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
2666 #            result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
2667 ##           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
2668 #            preview='http://preview.'${result#http://}
2669 #
2670 #            printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
2671 #            printf '%s\t%s\n\n' 'Given URL:' ${url}
2672 #            printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
2673 #    else
2674 #        return 1
2675 #    fi
2676 #}
2677
2678 #f2# Find history events by search pattern and list them by date.
2679 whatwhen()  {
2680     emulate -L zsh
2681     local usage help ident format_l format_s first_char remain first last
2682     usage='USAGE: whatwhen [options] <searchstring> <search range>'
2683     help='Use `whatwhen -h'\'' for further explanations.'
2684     ident=${(l,${#${:-Usage: }},, ,)}
2685     format_l="${ident}%s\t\t\t%s\n"
2686     format_s="${format_l//(\\t)##/\\t}"
2687     # Make the first char of the word to search for case
2688     # insensitive; e.g. [aA]
2689     first_char=[${(L)1[1]}${(U)1[1]}]
2690     remain=${1[2,-1]}
2691     # Default search range is `-100'.
2692     first=${2:-\-100}
2693     # Optional, just used for `<first> <last>' given.
2694     last=$3
2695     case $1 in
2696         ("")
2697             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
2698             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2699         ;;
2700         (-h)
2701             printf '%s\n\n' ${usage}
2702             print 'OPTIONS:'
2703             printf $format_l '-h' 'show help text'
2704             print '\f'
2705             print 'SEARCH RANGE:'
2706             printf $format_l "'0'" 'the whole history,'
2707             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
2708             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
2709             printf '\n%s\n' 'EXAMPLES:'
2710             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
2711             printf $format_l 'whatwhen zsh -250'
2712             printf $format_l 'whatwhen foo 1 99'
2713         ;;
2714         (\?)
2715             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2716         ;;
2717         (*)
2718             # -l list results on stout rather than invoking $EDITOR.
2719             # -i Print dates as in YYYY-MM-DD.
2720             # -m Search for a - quoted - pattern within the history.
2721             fc -li -m "*${first_char}${remain}*" $first $last
2722         ;;
2723     esac
2724 }
2725
2726 # mercurial related stuff
2727 if check_com -c hg ; then
2728     # gnu like diff for mercurial
2729     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
2730     #f5# GNU like diff for mercurial
2731     hgdi() {
2732         emulate -L zsh
2733         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
2734     }
2735
2736     # build debian package
2737     #a2# Alias for \kbd{hg-buildpackage}
2738     alias hbp='hg-buildpackage'
2739
2740     # execute commands on the versioned patch-queue from the current repos
2741     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
2742
2743     # diffstat for specific version of a mercurial repository
2744     #   hgstat      => display diffstat between last revision and tip
2745     #   hgstat 1234 => display diffstat between revision 1234 and tip
2746     #f5# Diffstat for specific version of a mercurial repos
2747     hgstat() {
2748         emulate -L zsh
2749         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
2750     }
2751
2752 fi # end of check whether we have the 'hg'-executable
2753
2754 # grml-small cleanups
2755
2756 # The following is used to remove zsh-config-items that do not work
2757 # in grml-small by default.
2758 # If you do not want these adjustments (for whatever reason), set
2759 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
2760 # sources if it is there).
2761
2762 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
2763
2764     unset abk[V]
2765     unalias    'V'      &> /dev/null
2766     unfunction vman     &> /dev/null
2767     unfunction viless   &> /dev/null
2768     unfunction 2html    &> /dev/null
2769
2770     # manpages are not in grmlsmall
2771     unfunction manzsh   &> /dev/null
2772     unfunction man2     &> /dev/null
2773
2774 fi
2775
2776 zrclocal
2777
2778 ## genrefcard.pl settings
2779
2780 ### doc strings for external functions from files
2781 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
2782
2783 ### example: split functions-search 8,16,24,32
2784 #@# split functions-search 8
2785
2786 ## END OF FILE #################################################################
2787 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
2788 # Local variables:
2789 # mode: sh
2790 # End: