etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is437(){
 148     [[ $ZSH_VERSION == 4.3.<7->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 is439(){
 154     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 155                                  || $ZSH_VERSION == <5->* ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running grml
 160 isgrml(){
 161     [[ -f /etc/grml_version ]] && return 0
 162     return 1
 163 }
 164
 165 #f1# Checks whether or not you're running a grml cd
 166 isgrmlcd(){
 167     [[ -f /etc/grml_cd ]] && return 0
 168     return 1
 169 }
 170
 171 if isgrml ; then
 172 #f1# Checks whether or not you're running grml-small
 173     isgrmlsmall() {
 174         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 175             return 0
 176         fi
 177         return 1
 178     }
 179 else
 180     isgrmlsmall() { return 1 }
 181 fi
 182
 183 GRML_OSTYPE=$(uname -s)
 184
 185 islinux(){
 186     [[ $GRML_OSTYPE == "Linux" ]]
 187 }
 188
 189 isdarwin(){
 190     [[ $GRML_OSTYPE == "Darwin" ]]
 191 }
 192
 193 isfreebsd(){
 194     [[ $GRML_OSTYPE == "FreeBSD" ]]
 195 }
 196
 197 isopenbsd(){
 198     [[ $GRML_OSTYPE == "OpenBSD" ]]
 199 }
 200
 201 issolaris(){
 202     [[ $GRML_OSTYPE == "SunOS" ]]
 203 }
 204
 205 #f1# are we running within an utf environment?
 206 isutfenv() {
 207     case "$LANG $CHARSET $LANGUAGE" in
 208         *utf*) return 0 ;;
 209         *UTF*) return 0 ;;
 210         *)     return 1 ;;
 211     esac
 212 }
 213
 214 # check for user, if not running as root set $SUDO to sudo
 215 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 216
 217 # change directory to home on first invocation of zsh
 218 # important for rungetty -> autologin
 219 # Thanks go to Bart Schaefer!
 220 isgrml && checkhome() {
 221     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 222         export ALREADY_DID_CD_HOME=$HOME
 223         cd
 224     fi
 225 }
 226
 227 # check for zsh v3.1.7+
 228
 229 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 230      || ${ZSH_VERSION} == 3.<2->.<->*    \
 231      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 232
 233     printf '-!-\n'
 234     printf '-!- In this configuration we try to make use of features, that only\n'
 235     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 236     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 237     printf '-!- advanced features in all supported versions.\n'
 238     printf '-!-\n'
 239     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 240     printf '-!-\n'
 241     printf '-!- While this *may* work, it might as well fail.\n'
 242     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 243     printf '-!-\n'
 244     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 245     printf '-!- If it does today, you'\''ve been lucky.\n'
 246     printf '-!-\n'
 247     printf '-!- Ye been warned!\n'
 248     printf '-!-\n'
 249
 250     function zstyle() { : }
 251 fi
 252
 253 # autoload wrapper - use this one instead of autoload directly
 254 # We need to define this function as early as this, because autoloading
 255 # 'is-at-least()' needs it.
 256 function zrcautoload() {
 257     emulate -L zsh
 258     setopt extended_glob
 259     local fdir ffile
 260     local -i ffound
 261
 262     ffile=$1
 263     (( ffound = 0 ))
 264     for fdir in ${fpath} ; do
 265         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 266     done
 267
 268     (( ffound == 0 )) && return 1
 269     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 270         autoload -U ${ffile} || return 1
 271     else
 272         autoload ${ffile} || return 1
 273     fi
 274     return 0
 275 }
 276
 277 # The following is the ‘add-zsh-hook’ function from zsh upstream. It is
 278 # included here to make the setup work with older versions of zsh (prior to
 279 # 4.3.7) in which this function had a bug that triggers annoying errors during
 280 # shell startup. This is exactly upstreams code from f0068edb4888a4d8fe94def,
 281 # with just a few adjustments in coding style to make the function look more
 282 # compact. This definition can be removed as soon as we raise the minimum
 283 # version requirement to 4.3.7 or newer.
 284 function add-zsh-hook() {
 285     # Add to HOOK the given FUNCTION.
 286     # HOOK is one of chpwd, precmd, preexec, periodic, zshaddhistory,
 287     # zshexit, zsh_directory_name (the _functions subscript is not required).
 288     #
 289     # With -d, remove the function from the hook instead; delete the hook
 290     # variable if it is empty.
 291     #
 292     # -D behaves like -d, but pattern characters are active in the function
 293     # name, so any matching function will be deleted from the hook.
 294     #
 295     # Without -d, the FUNCTION is marked for autoload; -U is passed down to
 296     # autoload if that is given, as are -z and -k. (This is harmless if the
 297     # function is actually defined inline.)
 298     emulate -L zsh
 299     local -a hooktypes
 300     hooktypes=(
 301         chpwd precmd preexec periodic zshaddhistory zshexit
 302         zsh_directory_name
 303     )
 304     local usage="Usage: $0 hook function\nValid hooks are:\n  $hooktypes"
 305     local opt
 306     local -a autoopts
 307     integer del list help
 308     while getopts "dDhLUzk" opt; do
 309         case $opt in
 310         (d) del=1 ;;
 311         (D) del=2 ;;
 312         (h) help=1 ;;
 313         (L) list=1 ;;
 314         ([Uzk]) autoopts+=(-$opt) ;;
 315         (*) return 1 ;;
 316         esac
 317     done
 318     shift $(( OPTIND - 1 ))
 319     if (( list )); then
 320         typeset -mp "(${1:-${(@j:|:)hooktypes}})_functions"
 321         return $?
 322     elif (( help || $# != 2 || ${hooktypes[(I)$1]} == 0 )); then
 323         print -u$(( 2 - help )) $usage
 324         return $(( 1 - help ))
 325     fi
 326     local hook="${1}_functions"
 327     local fn="$2"
 328     if (( del )); then
 329         # delete, if hook is set
 330         if (( ${(P)+hook} )); then
 331             if (( del == 2 )); then
 332                 set -A $hook ${(P)hook:#${~fn}}
 333             else
 334                 set -A $hook ${(P)hook:#$fn}
 335             fi
 336             # unset if no remaining entries --- this can give better
 337             # performance in some cases
 338             if (( ! ${(P)#hook} )); then
 339                 unset $hook
 340             fi
 341         fi
 342     else
 343         if (( ${(P)+hook} )); then
 344             if (( ${${(P)hook}[(I)$fn]} == 0 )); then
 345                 set -A $hook ${(P)hook} $fn
 346             fi
 347         else
 348             set -A $hook $fn
 349         fi
 350         autoload $autoopts -- $fn
 351     fi
 352 }
 353
 354 # Load is-at-least() for more precise version checks Note that this test will
 355 # *always* fail, if the is-at-least function could not be marked for
 356 # autoloading.
 357 zrcautoload is-at-least || is-at-least() { return 1 }
 358
 359 # set some important options (as early as possible)
 360
 361 # append history list to the history file; this is the default but we make sure
 362 # because it's required for share_history.
 363 setopt append_history
 364
 365 # import new commands from the history file also in other zsh-session
 366 is4 && setopt share_history
 367
 368 # save each command's beginning timestamp and the duration to the history file
 369 setopt extended_history
 370
 371 # If a new command line being added to the history list duplicates an older
 372 # one, the older command is removed from the list
 373 is4 && setopt histignorealldups
 374
 375 # remove command lines from the history list when the first character on the
 376 # line is a space
 377 setopt histignorespace
 378
 379 # if a command is issued that can't be executed as a normal command, and the
 380 # command is the name of a directory, perform the cd command to that directory.
 381 setopt auto_cd
 382
 383 # in order to use #, ~ and ^ for filename generation grep word
 384 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 385 # don't forget to quote '^', '~' and '#'!
 386 setopt extended_glob
 387
 388 # display PID when suspending processes as well
 389 setopt longlistjobs
 390
 391 # report the status of backgrounds jobs immediately
 392 setopt notify
 393
 394 # whenever a command completion is attempted, make sure the entire command path
 395 # is hashed first.
 396 setopt hash_list_all
 397
 398 # not just at the end
 399 setopt completeinword
 400
 401 # Don't send SIGHUP to background processes when the shell exits.
 402 setopt nohup
 403
 404 # make cd push the old directory onto the directory stack.
 405 setopt auto_pushd
 406
 407 # avoid "beep"ing
 408 setopt nobeep
 409
 410 # don't push the same dir twice.
 411 setopt pushd_ignore_dups
 412
 413 # * shouldn't match dotfiles. ever.
 414 setopt noglobdots
 415
 416 # use zsh style word splitting
 417 setopt noshwordsplit
 418
 419 # don't error out when unset parameters are used
 420 setopt unset
 421
 422 # setting some default values
 423 NOCOR=${NOCOR:-0}
 424 NOMENU=${NOMENU:-0}
 425 NOPRECMD=${NOPRECMD:-0}
 426 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 427 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 428 GRML_DISPLAY_BATTERY=${GRML_DISPLAY_BATTERY:-${BATTERY:-0}}
 429 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 430 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 431
 432 typeset -ga ls_options
 433 typeset -ga grep_options
 434 if ls --color=auto / >/dev/null 2>&1; then
 435     ls_options+=( --color=auto )
 436 elif ls -G / >/dev/null 2>&1; then
 437     ls_options+=( -G )
 438 fi
 439 if grep --color=auto -q "a" <<< "a" >/dev/null 2>&1; then
 440     grep_options+=( --color=auto )
 441 fi
 442
 443 # utility functions
 444 # this function checks if a command exists and returns either true
 445 # or false. This avoids using 'which' and 'whence', which will
 446 # avoid problems with aliases for which on certain weird systems. :-)
 447 # Usage: check_com [-c|-g] word
 448 #   -c  only checks for external commands
 449 #   -g  does the usual tests and also checks for global aliases
 450 check_com() {
 451     emulate -L zsh
 452     local -i comonly gatoo
 453
 454     if [[ $1 == '-c' ]] ; then
 455         (( comonly = 1 ))
 456         shift
 457     elif [[ $1 == '-g' ]] ; then
 458         (( gatoo = 1 ))
 459     else
 460         (( comonly = 0 ))
 461         (( gatoo = 0 ))
 462     fi
 463
 464     if (( ${#argv} != 1 )) ; then
 465         printf 'usage: check_com [-c] <command>\n' >&2
 466         return 1
 467     fi
 468
 469     if (( comonly > 0 )) ; then
 470         [[ -n ${commands[$1]}  ]] && return 0
 471         return 1
 472     fi
 473
 474     if   [[ -n ${commands[$1]}    ]] \
 475       || [[ -n ${functions[$1]}   ]] \
 476       || [[ -n ${aliases[$1]}     ]] \
 477       || [[ -n ${reswords[(r)$1]} ]] ; then
 478
 479         return 0
 480     fi
 481
 482     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 483         return 0
 484     fi
 485
 486     return 1
 487 }
 488
 489 # creates an alias and precedes the command with
 490 # sudo if $EUID is not zero.
 491 salias() {
 492     emulate -L zsh
 493     local only=0 ; local multi=0
 494     local key val
 495     while getopts ":hao" opt; do
 496         case $opt in
 497             o) only=1 ;;
 498             a) multi=1 ;;
 499             h)
 500                 printf 'usage: salias [-hoa] <alias-expression>\n'
 501                 printf '  -h      shows this help text.\n'
 502                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 503                 printf '          be careful using this option.\n'
 504                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 505                 return 0
 506                 ;;
 507             *) salias -h >&2; return 1 ;;
 508         esac
 509     done
 510     shift "$((OPTIND-1))"
 511
 512     if (( ${#argv} > 1 )) ; then
 513         printf 'Too many arguments %s\n' "${#argv}"
 514         return 1
 515     fi
 516
 517     key="${1%%\=*}" ;  val="${1#*\=}"
 518     if (( EUID == 0 )) && (( only == 0 )); then
 519         alias -- "${key}=${val}"
 520     elif (( EUID > 0 )) ; then
 521         (( multi > 0 )) && val="${val// ; / ; sudo }"
 522         alias -- "${key}=sudo ${val}"
 523     fi
 524
 525     return 0
 526 }
 527
 528 # Check if we can read given files and source those we can.
 529 xsource() {
 530     if (( ${#argv} < 1 )) ; then
 531         printf 'usage: xsource FILE(s)...\n' >&2
 532         return 1
 533     fi
 534
 535     while (( ${#argv} > 0 )) ; do
 536         [[ -r "$1" ]] && source "$1"
 537         shift
 538     done
 539     return 0
 540 }
 541
 542 # Check if we can read a given file and 'cat(1)' it.
 543 xcat() {
 544     emulate -L zsh
 545     if (( ${#argv} != 1 )) ; then
 546         printf 'usage: xcat FILE\n' >&2
 547         return 1
 548     fi
 549
 550     [[ -r $1 ]] && cat $1
 551     return 0
 552 }
 553
 554 # Remove these functions again, they are of use only in these
 555 # setup files. This should be called at the end of .zshrc.
 556 xunfunction() {
 557     emulate -L zsh
 558     local -a funcs
 559     local func
 560     funcs=(salias xcat xsource xunfunction zrcautoload zrcautozle)
 561     for func in $funcs ; do
 562         [[ -n ${functions[$func]} ]] \
 563             && unfunction $func
 564     done
 565     return 0
 566 }
 567
 568 # this allows us to stay in sync with grml's zshrc and put own
 569 # modifications in ~/.zshrc.local
 570 zrclocal() {
 571     xsource "/etc/zsh/zshrc.local"
 572     xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
 573     return 0
 574 }
 575
 576 # locale setup
 577 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 578     xsource "/etc/default/locale"
 579 fi
 580
 581 for var in LANG LC_ALL LC_MESSAGES ; do
 582     [[ -n ${(P)var} ]] && export $var
 583 done
 584 builtin unset -v var
 585
 586 # set some variables
 587 if check_com -c vim ; then
 588 #v#
 589     export EDITOR=${EDITOR:-vim}
 590 else
 591     export EDITOR=${EDITOR:-vi}
 592 fi
 593
 594 #v#
 595 export PAGER=${PAGER:-less}
 596
 597 #v#
 598 export MAIL=${MAIL:-/var/mail/$USER}
 599
 600 # color setup for ls:
 601 check_com -c dircolors && eval $(dircolors -b)
 602 # color setup for ls on OS X / FreeBSD:
 603 isdarwin && export CLICOLOR=1
 604 isfreebsd && export CLICOLOR=1
 605
 606 # do MacPorts setup on darwin
 607 if isdarwin && [[ -d /opt/local ]]; then
 608     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 609     # zshenv.
 610     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 611     MANPATH="/opt/local/share/man:$MANPATH"
 612 fi
 613 # do Fink setup on darwin
 614 isdarwin && xsource /sw/bin/init.sh
 615
 616 # load our function and completion directories
 617 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 618     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 619     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 620         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 621             zrcautoload ${func:t}
 622         done
 623     fi
 624 done
 625 unset fdir func
 626
 627 # support colors in less
 628 export LESS_TERMCAP_mb=$'\E[01;31m'
 629 export LESS_TERMCAP_md=$'\E[01;31m'
 630 export LESS_TERMCAP_me=$'\E[0m'
 631 export LESS_TERMCAP_se=$'\E[0m'
 632 export LESS_TERMCAP_so=$'\E[01;44;33m'
 633 export LESS_TERMCAP_ue=$'\E[0m'
 634 export LESS_TERMCAP_us=$'\E[01;32m'
 635
 636 # mailchecks
 637 MAILCHECK=30
 638
 639 # report about cpu-/system-/user-time of command if running longer than
 640 # 5 seconds
 641 REPORTTIME=5
 642
 643 # watch for everyone but me and root
 644 watch=(notme root)
 645
 646 # automatically remove duplicates from these arrays
 647 typeset -U path cdpath fpath manpath
 648
 649 # Load a few modules
 650 is4 && \
 651 for mod in parameter complist deltochar mathfunc ; do
 652     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 653 done && builtin unset -v mod
 654
 655 # autoload zsh modules when they are referenced
 656 if is4 ; then
 657     zmodload -a  zsh/stat    zstat
 658     zmodload -a  zsh/zpty    zpty
 659     zmodload -ap zsh/mapfile mapfile
 660 fi
 661
 662 # completion system
 663 COMPDUMPFILE=${COMPDUMPFILE:-${ZDOTDIR:-${HOME}}/.zcompdump}
 664 if zrcautoload compinit ; then
 665     compinit -d ${COMPDUMPFILE} || print 'Notice: no compinit available :('
 666 else
 667     print 'Notice: no compinit available :('
 668     function compdef { }
 669 fi
 670
 671 # completion system
 672
 673 # called later (via is4 && grmlcomp)
 674 # note: use 'zstyle' for getting current settings
 675 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
 676 grmlcomp() {
 677     # TODO: This could use some additional information
 678
 679     # Make sure the completion system is initialised
 680     (( ${+_comps} )) || return 1
 681
 682     # allow one error for every three characters typed in approximate completer
 683     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
 684
 685     # don't complete backup files as executables
 686     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
 687
 688     # start menu completion only if it could find no unambiguous initial string
 689     zstyle ':completion:*:correct:*'       insert-unambiguous true
 690     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
 691     zstyle ':completion:*:correct:*'       original true
 692
 693     # activate color-completion
 694     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
 695
 696     # format on completion
 697     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
 698
 699     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
 700     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
 701
 702     # insert all expansions for expand completer
 703     zstyle ':completion:*:expand:*'        tag-order all-expansions
 704     zstyle ':completion:*:history-words'   list false
 705
 706     # activate menu
 707     zstyle ':completion:*:history-words'   menu yes
 708
 709     # ignore duplicate entries
 710     zstyle ':completion:*:history-words'   remove-all-dups yes
 711     zstyle ':completion:*:history-words'   stop yes
 712
 713     # match uppercase from lowercase
 714     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
 715
 716     # separate matches into groups
 717     zstyle ':completion:*:matches'         group 'yes'
 718     zstyle ':completion:*'                 group-name ''
 719
 720     if [[ "$NOMENU" -eq 0 ]] ; then
 721         # if there are more than 5 options allow selecting from a menu
 722         zstyle ':completion:*'               menu select=5
 723     else
 724         # don't use any menus at all
 725         setopt no_auto_menu
 726     fi
 727
 728     zstyle ':completion:*:messages'        format '%d'
 729     zstyle ':completion:*:options'         auto-description '%d'
 730
 731     # describe options in full
 732     zstyle ':completion:*:options'         description 'yes'
 733
 734     # on processes completion complete all user processes
 735     zstyle ':completion:*:processes'       command 'ps -au$USER'
 736
 737     # offer indexes before parameters in subscripts
 738     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
 739
 740     # provide verbose completion information
 741     zstyle ':completion:*'                 verbose true
 742
 743     # recent (as of Dec 2007) zsh versions are able to provide descriptions
 744     # for commands (read: 1st word in the line) that it will list for the user
 745     # to choose from. The following disables that, because it's not exactly fast.
 746     zstyle ':completion:*:-command-:*:'    verbose false
 747
 748     # set format for warnings
 749     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
 750
 751     # define files to ignore for zcompile
 752     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
 753     zstyle ':completion:correct:'          prompt 'correct to: %e'
 754
 755     # Ignore completion functions for commands you don't have:
 756     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
 757
 758     # Provide more processes in completion of programs like killall:
 759     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
 760
 761     # complete manual by their section
 762     zstyle ':completion:*:manuals'    separate-sections true
 763     zstyle ':completion:*:manuals.*'  insert-sections   true
 764     zstyle ':completion:*:man:*'      menu yes select
 765
 766     # Search path for sudo completion
 767     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
 768                                                /usr/local/bin  \
 769                                                /usr/sbin       \
 770                                                /usr/bin        \
 771                                                /sbin           \
 772                                                /bin            \
 773                                                /usr/X11R6/bin
 774
 775     # provide .. as a completion
 776     zstyle ':completion:*' special-dirs ..
 777
 778     # run rehash on completion so new installed program are found automatically:
 779     _force_rehash() {
 780         (( CURRENT == 1 )) && rehash
 781         return 1
 782     }
 783
 784     ## correction
 785     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
 786     if [[ "$NOCOR" -gt 0 ]] ; then
 787         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
 788         setopt nocorrect
 789     else
 790         # try to be smart about when to use what completer...
 791         setopt correct
 792         zstyle -e ':completion:*' completer '
 793             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
 794                 _last_try="$HISTNO$BUFFER$CURSOR"
 795                 reply=(_complete _match _ignored _prefix _files)
 796             else
 797                 if [[ $words[1] == (rm|mv) ]] ; then
 798                     reply=(_complete _files)
 799                 else
 800                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
 801                 fi
 802             fi'
 803     fi
 804
 805     # command for process lists, the local web server details and host completion
 806     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
 807
 808     # caching
 809     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
 810                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
 811
 812     # host completion
 813     if is42 ; then
 814         [[ -r ~/.ssh/config ]] && _ssh_config_hosts=(${${(s: :)${(ps:\t:)${${(@M)${(f)"$(<$HOME/.ssh/config)"}:#Host *}#Host }}}:#*[*?]*}) || _ssh_config_hosts=()
 815         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
 816         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
 817     else
 818         _ssh_config_hosts=()
 819         _ssh_hosts=()
 820         _etc_hosts=()
 821     fi
 822     hosts=(
 823         $(hostname)
 824         "$_ssh_config_hosts[@]"
 825         "$_ssh_hosts[@]"
 826         "$_etc_hosts[@]"
 827         localhost
 828     )
 829     zstyle ':completion:*:hosts' hosts $hosts
 830     # TODO: so, why is this here?
 831     #  zstyle '*' hosts $hosts
 832
 833     # use generic completion system for programs not yet defined; (_gnu_generic works
 834     # with commands that provide a --help option with "standard" gnu-like output.)
 835     for compcom in cp deborphan df feh fetchipac gpasswd head hnb ipacsum mv \
 836                    pal stow uname ; do
 837         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
 838     done; unset compcom
 839
 840     # see upgrade function in this file
 841     compdef _hosts upgrade
 842 }
 843
 844 # Keyboard setup: The following is based on the same code, we wrote for
 845 # debian's setup. It ensures the terminal is in the right mode, when zle is
 846 # active, so the values from $terminfo are valid. Therefore, this setup should
 847 # work on all systems, that have support for `terminfo'. It also requires the
 848 # zsh in use to have the `zsh/terminfo' module built.
 849 #
 850 # If you are customising your `zle-line-init()' or `zle-line-finish()'
 851 # functions, make sure you call the following utility functions in there:
 852 #
 853 #     - zle-line-init():      zle-smkx
 854 #     - zle-line-finish():    zle-rmkx
 855
 856 # Use emacs-like key bindings by default:
 857 bindkey -e
 858
 859 # Custom widgets:
 860
 861 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 862 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 863 beginning-or-end-of-somewhere() {
 864     local hno=$HISTNO
 865     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 866       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 867         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 868     else
 869         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 870         if (( HISTNO != hno )); then
 871             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 872         fi
 873     fi
 874 }
 875 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 876 zle -N end-of-somewhere beginning-or-end-of-somewhere
 877
 878 # add a command line to the shells history without executing it
 879 commit-to-history() {
 880     print -s ${(z)BUFFER}
 881     zle send-break
 882 }
 883 zle -N commit-to-history
 884
 885 # only slash should be considered as a word separator:
 886 slash-backward-kill-word() {
 887     local WORDCHARS="${WORDCHARS:s@/@}"
 888     # zle backward-word
 889     zle backward-kill-word
 890 }
 891 zle -N slash-backward-kill-word
 892
 893 # a generic accept-line wrapper
 894
 895 # This widget can prevent unwanted autocorrections from command-name
 896 # to _command-name, rehash automatically on enter and call any number
 897 # of builtin and user-defined widgets in different contexts.
 898 #
 899 # For a broader description, see:
 900 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 901 #
 902 # The code is imported from the file 'zsh/functions/accept-line' from
 903 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 904 # distributed under the same terms as zsh itself.
 905
 906 # A newly added command will may not be found or will cause false
 907 # correction attempts, if you got auto-correction set. By setting the
 908 # following style, we force accept-line() to rehash, if it cannot
 909 # find the first word on the command line in the $command[] hash.
 910 zstyle ':acceptline:*' rehash true
 911
 912 function Accept-Line() {
 913     setopt localoptions noksharrays
 914     local -a subs
 915     local -xi aldone
 916     local sub
 917     local alcontext=${1:-$alcontext}
 918
 919     zstyle -a ":acceptline:${alcontext}" actions subs
 920
 921     (( ${#subs} < 1 )) && return 0
 922
 923     (( aldone = 0 ))
 924     for sub in ${subs} ; do
 925         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 926         zle ${sub}
 927
 928         (( aldone > 0 )) && break
 929     done
 930 }
 931
 932 function Accept-Line-getdefault() {
 933     emulate -L zsh
 934     local default_action
 935
 936     zstyle -s ":acceptline:${alcontext}" default_action default_action
 937     case ${default_action} in
 938         ((accept-line|))
 939             printf ".accept-line"
 940             ;;
 941         (*)
 942             printf ${default_action}
 943             ;;
 944     esac
 945 }
 946
 947 function Accept-Line-HandleContext() {
 948     zle Accept-Line
 949
 950     default_action=$(Accept-Line-getdefault)
 951     zstyle -T ":acceptline:${alcontext}" call_default \
 952         && zle ${default_action}
 953 }
 954
 955 function accept-line() {
 956     setopt localoptions noksharrays
 957     local -a cmdline
 958     local -x alcontext
 959     local buf com fname format msg default_action
 960
 961     alcontext='default'
 962     buf="${BUFFER}"
 963     cmdline=(${(z)BUFFER})
 964     com="${cmdline[1]}"
 965     fname="_${com}"
 966
 967     Accept-Line 'preprocess'
 968
 969     zstyle -t ":acceptline:${alcontext}" rehash \
 970         && [[ -z ${commands[$com]} ]]           \
 971         && rehash
 972
 973     if    [[ -n ${com}               ]] \
 974        && [[ -n ${reswords[(r)$com]} ]] \
 975        || [[ -n ${aliases[$com]}     ]] \
 976        || [[ -n ${functions[$com]}   ]] \
 977        || [[ -n ${builtins[$com]}    ]] \
 978        || [[ -n ${commands[$com]}    ]] ; then
 979
 980         # there is something sensible to execute, just do it.
 981         alcontext='normal'
 982         Accept-Line-HandleContext
 983
 984         return
 985     fi
 986
 987     if    [[ -o correct              ]] \
 988        || [[ -o correctall           ]] \
 989        && [[ -n ${functions[$fname]} ]] ; then
 990
 991         # nothing there to execute but there is a function called
 992         # _command_name; a completion widget. Makes no sense to
 993         # call it on the commandline, but the correct{,all} options
 994         # will ask for it nevertheless, so warn the user.
 995         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 996             # Okay, we warned the user before, he called us again,
 997             # so have it his way.
 998             alcontext='force'
 999             Accept-Line-HandleContext
1000
1001             return
1002         fi
1003
1004         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
1005             alcontext='normal'
1006             Accept-Line-HandleContext
1007         else
1008             # prepare warning message for the user, configurable via zstyle.
1009             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
1010
1011             if [[ -z ${msg} ]] ; then
1012                 msg="%c will not execute and completion %f exists."
1013             fi
1014
1015             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
1016
1017             zle -M -- "${msg}"
1018         fi
1019         return
1020     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
1021         # If we are here, the commandline contains something that is not
1022         # executable, which is neither subject to _command_name correction
1023         # and is not empty. might be a variable assignment
1024         alcontext='misc'
1025         Accept-Line-HandleContext
1026
1027         return
1028     fi
1029
1030     # If we got this far, the commandline only contains whitespace, or is empty.
1031     alcontext='empty'
1032     Accept-Line-HandleContext
1033 }
1034
1035 zle -N accept-line
1036 zle -N Accept-Line
1037 zle -N Accept-Line-HandleContext
1038
1039 # power completion / abbreviation expansion / buffer expansion
1040 # see http://zshwiki.org/home/examples/zleiab for details
1041 # less risky than the global aliases but powerful as well
1042 # just type the abbreviation key and afterwards 'ctrl-x .' to expand it
1043 declare -A abk
1044 setopt extendedglob
1045 setopt interactivecomments
1046 abk=(
1047 #   key   # value                  (#d additional doc string)
1048 #A# start
1049     '...'  '../..'
1050     '....' '../../..'
1051     'BG'   '& exit'
1052     'C'    '| wc -l'
1053     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
1054     'H'    '| head'
1055     'Hl'   ' --help |& less -r'    #d (Display help in pager)
1056     'L'    '| less'
1057     'LL'   '|& less -r'
1058     'M'    '| most'
1059     'N'    '&>/dev/null'           #d (No Output)
1060     'R'    '| tr A-z N-za-m'       #d (ROT13)
1061     'SL'   '| sort | less'
1062     'S'    '| sort -u'
1063     'T'    '| tail'
1064     'V'    '|& vim -'
1065 #A# end
1066     'co'   './configure && make && sudo make install'
1067 )
1068
1069 zleiab() {
1070     emulate -L zsh
1071     setopt extendedglob
1072     local MATCH
1073
1074     LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
1075     LBUFFER+=${abk[$MATCH]:-$MATCH}
1076 }
1077
1078 zle -N zleiab
1079
1080 help-show-abk()
1081 {
1082   zle -M "$(print "Available abbreviations for expansion:"; print -a -C 2 ${(kv)abk})"
1083 }
1084
1085 zle -N help-show-abk
1086
1087 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1088 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1089 zle -N insert-datestamp
1090
1091 # press esc-m for inserting last typed word again (thanks to caphuso!)
1092 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1093 zle -N insert-last-typed-word;
1094
1095 function grml-zsh-fg() {
1096   if (( ${#jobstates} )); then
1097     zle .push-input
1098     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1099     BUFFER="${BUFFER}fg"
1100     zle .accept-line
1101   else
1102     zle -M 'No background jobs. Doing nothing.'
1103   fi
1104 }
1105 zle -N grml-zsh-fg
1106
1107 # run command line as user root via sudo:
1108 sudo-command-line() {
1109     [[ -z $BUFFER ]] && zle up-history
1110     if [[ $BUFFER != sudo\ * ]]; then
1111         BUFFER="sudo $BUFFER"
1112         CURSOR=$(( CURSOR+5 ))
1113     fi
1114 }
1115 zle -N sudo-command-line
1116
1117 ### jump behind the first word on the cmdline.
1118 ### useful to add options.
1119 function jump_after_first_word() {
1120     local words
1121     words=(${(z)BUFFER})
1122
1123     if (( ${#words} <= 1 )) ; then
1124         CURSOR=${#BUFFER}
1125     else
1126         CURSOR=${#${words[1]}}
1127     fi
1128 }
1129 zle -N jump_after_first_word
1130
1131 #f5# Create directory under cursor or the selected area
1132 inplaceMkDirs() {
1133     # Press ctrl-xM to create the directory under the cursor or the selected area.
1134     # To select an area press ctrl-@ or ctrl-space and use the cursor.
1135     # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
1136     # directory does not exist yet -> press ctrl-XM and problem solved
1137     local PATHTOMKDIR
1138     if ((REGION_ACTIVE==1)); then
1139         local F=$MARK T=$CURSOR
1140         if [[ $F -gt $T ]]; then
1141             F=${CURSOR}
1142             T=${MARK}
1143         fi
1144         # get marked area from buffer and eliminate whitespace
1145         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
1146         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
1147     else
1148         local bufwords iword
1149         bufwords=(${(z)LBUFFER})
1150         iword=${#bufwords}
1151         bufwords=(${(z)BUFFER})
1152         PATHTOMKDIR="${(Q)bufwords[iword]}"
1153     fi
1154     [[ -z "${PATHTOMKDIR}" ]] && return 1
1155     PATHTOMKDIR=${~PATHTOMKDIR}
1156     if [[ -e "${PATHTOMKDIR}" ]]; then
1157         zle -M " path already exists, doing nothing"
1158     else
1159         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
1160         zle end-of-line
1161     fi
1162 }
1163
1164 zle -N inplaceMkDirs
1165
1166 #v1# set number of lines to display per page
1167 HELP_LINES_PER_PAGE=20
1168 #v1# set location of help-zle cache file
1169 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
1170 # helper function for help-zle, actually generates the help text
1171 help_zle_parse_keybindings()
1172 {
1173     emulate -L zsh
1174     setopt extendedglob
1175     unsetopt ksharrays  #indexing starts at 1
1176
1177     #v1# choose files that help-zle will parse for keybindings
1178     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
1179
1180     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
1181         local load_cache=0
1182         local f
1183         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
1184         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
1185     fi
1186
1187     #fill with default keybindings, possibly to be overwriten in a file later
1188     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
1189     local -A help_zle_keybindings
1190     help_zle_keybindings['<Ctrl>@']="set MARK"
1191     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
1192     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
1193     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
1194     help_zle_keybindings['<Ctrl>_']="undo"
1195     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
1196     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
1197     help_zle_keybindings['<Ctrl>e']="goto end of line"
1198     help_zle_keybindings['<Ctrl>t']="transpose charaters"
1199     help_zle_keybindings['<Alt>t']="transpose words"
1200     help_zle_keybindings['<Alt>s']="spellcheck word"
1201     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
1202     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
1203     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
1204     help_zle_keybindings["<Alt>'"]="quote line"
1205     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
1206     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
1207     help_zle_keybindings['<Alt>u']="make next word Uppercase"
1208     help_zle_keybindings['<Alt>l']="make next word lowercase"
1209     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
1210     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
1211     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
1212     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
1213     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
1214     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
1215     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
1216     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
1217     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
1218
1219     #init global variables
1220     unset help_zle_lines help_zle_sln
1221     typeset -g -a help_zle_lines
1222     typeset -g help_zle_sln=1
1223
1224     local k v f cline
1225     local lastkeybind_desc contents     #last description starting with #k# that we found
1226     local num_lines_elapsed=0            #number of lines between last description and keybinding
1227     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
1228     for f in $HELPZLE_KEYBINDING_FILES; do
1229         [[ -r "$f" ]] || continue   #not readable ? skip it
1230         contents="$(<$f)"
1231         for cline in "${(f)contents}"; do
1232             #zsh pattern: matches lines like: #k# ..............
1233             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
1234                 lastkeybind_desc="$match[*]"
1235                 num_lines_elapsed=0
1236             #zsh pattern: matches lines that set a keybinding using bind2map, bindkey or compdef -k
1237             #             ignores lines that are commentend out
1238             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
1239             elif [[ "$cline" == [^#]#(bind2maps[[:space:]](*)-s|bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
1240                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
1241                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
1242                     #substitute keybinding string with something readable
1243                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
1244                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
1245                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
1246                     help_zle_keybindings[${k}]=$lastkeybind_desc
1247                 fi
1248                 lastkeybind_desc=""
1249             else
1250               ((num_lines_elapsed++))
1251             fi
1252         done
1253     done
1254     unset contents
1255     #calculate length of keybinding column
1256     local kstrlen=0
1257     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
1258     #convert the assoc array into preformated lines, which we are able to sort
1259     for k v in ${(kv)help_zle_keybindings[@]}; do
1260         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
1261         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
1262     done
1263     #sort lines alphabetically
1264     help_zle_lines=("${(i)help_zle_lines[@]}")
1265     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
1266     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
1267     zcompile $HELP_ZLE_CACHE_FILE
1268 }
1269 typeset -g help_zle_sln
1270 typeset -g -a help_zle_lines
1271
1272 # Provides (partially autogenerated) help on keybindings and the zsh line editor
1273 help-zle()
1274 {
1275     emulate -L zsh
1276     unsetopt ksharrays  #indexing starts at 1
1277     #help lines already generated ? no ? then do it
1278     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
1279     #already displayed all lines ? go back to the start
1280     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
1281     local sln=$help_zle_sln
1282     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
1283     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
1284     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
1285 }
1286 zle -N help-zle
1287
1288 ## complete word from currently visible Screen or Tmux buffer.
1289 if check_com -c screen || check_com -c tmux; then
1290     _complete_screen_display() {
1291         [[ "$TERM" != "screen" ]] && return 1
1292
1293         local TMPFILE=$(mktemp)
1294         local -U -a _screen_display_wordlist
1295         trap "rm -f $TMPFILE" EXIT
1296
1297         # fill array with contents from screen hardcopy
1298         if ((${+TMUX})); then
1299             #works, but crashes tmux below version 1.4
1300             #luckily tmux -V option to ask for version, was also added in 1.4
1301             tmux -V &>/dev/null || return
1302             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1303         else
1304             screen -X hardcopy $TMPFILE
1305             # screen sucks, it dumps in latin1, apparently always. so recode it
1306             # to system charset
1307             check_com recode && recode latin1 $TMPFILE
1308         fi
1309         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1310         # remove PREFIX to be completed from that array
1311         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1312         compadd -a _screen_display_wordlist
1313     }
1314     #m# k CTRL-x\,\,\,S Complete word from GNU screen buffer
1315     bindkey -r "^xS"
1316     compdef -k _complete_screen_display complete-word '^xS'
1317 fi
1318
1319 # Load a few more functions and tie them to widgets, so they can be bound:
1320
1321 function zrcautozle() {
1322     emulate -L zsh
1323     local fnc=$1
1324     zrcautoload $fnc && zle -N $fnc
1325 }
1326
1327 function zrcgotwidget() {
1328     (( ${+widgets[$1]} ))
1329 }
1330
1331 function zrcgotkeymap() {
1332     [[ -n ${(M)keymaps:#$1} ]]
1333 }
1334
1335 zrcautozle insert-files
1336 zrcautozle edit-command-line
1337 zrcautozle insert-unicode-char
1338 if zrcautoload history-search-end; then
1339     zle -N history-beginning-search-backward-end history-search-end
1340     zle -N history-beginning-search-forward-end  history-search-end
1341 fi
1342 zle -C hist-complete complete-word _generic
1343 zstyle ':completion:hist-complete:*' completer _history
1344
1345 # The actual terminal setup hooks and bindkey-calls:
1346
1347 # An array to note missing features to ease diagnosis in case of problems.
1348 typeset -ga grml_missing_features
1349
1350 function zrcbindkey() {
1351     if (( ARGC )) && zrcgotwidget ${argv[-1]}; then
1352         bindkey "$@"
1353     fi
1354 }
1355
1356 function bind2maps () {
1357     local i sequence widget
1358     local -a maps
1359
1360     while [[ "$1" != "--" ]]; do
1361         maps+=( "$1" )
1362         shift
1363     done
1364     shift
1365
1366     if [[ "$1" == "-s" ]]; then
1367         shift
1368         sequence="$1"
1369     else
1370         sequence="${key[$1]}"
1371     fi
1372     widget="$2"
1373
1374     [[ -z "$sequence" ]] && return 1
1375
1376     for i in "${maps[@]}"; do
1377         zrcbindkey -M "$i" "$sequence" "$widget"
1378     done
1379 }
1380
1381 if (( ${+terminfo[smkx]} )) && (( ${+terminfo[rmkx]} )); then
1382     function zle-smkx () {
1383         emulate -L zsh
1384         printf '%s' ${terminfo[smkx]}
1385     }
1386     function zle-rmkx () {
1387         emulate -L zsh
1388         printf '%s' ${terminfo[rmkx]}
1389     }
1390     function zle-line-init () {
1391         zle-smkx
1392     }
1393     function zle-line-finish () {
1394         zle-rmkx
1395     }
1396     zle -N zle-line-init
1397     zle -N zle-line-finish
1398 else
1399     for i in {s,r}mkx; do
1400         (( ${+terminfo[$i]} )) || grml_missing_features+=($i)
1401     done
1402     unset i
1403 fi
1404
1405 typeset -A key
1406 key=(
1407     Home     "${terminfo[khome]}"
1408     End      "${terminfo[kend]}"
1409     Insert   "${terminfo[kich1]}"
1410     Delete   "${terminfo[kdch1]}"
1411     Up       "${terminfo[kcuu1]}"
1412     Down     "${terminfo[kcud1]}"
1413     Left     "${terminfo[kcub1]}"
1414     Right    "${terminfo[kcuf1]}"
1415     PageUp   "${terminfo[kpp]}"
1416     PageDown "${terminfo[knp]}"
1417     BackTab  "${terminfo[kcbt]}"
1418 )
1419
1420 # Guidelines for adding key bindings:
1421 #
1422 #   - Do not add hardcoded escape sequences, to enable non standard key
1423 #     combinations such as Ctrl-Meta-Left-Cursor. They are not easily portable.
1424 #
1425 #   - Adding Ctrl characters, such as '^b' is okay; note that '^b' and '^B' are
1426 #     the same key.
1427 #
1428 #   - All keys from the $key[] mapping are obviously okay.
1429 #
1430 #   - Most terminals send "ESC x" when Meta-x is pressed. Thus, sequences like
1431 #     '\ex' are allowed in here as well.
1432
1433 bind2maps emacs             -- Home   beginning-of-somewhere
1434 bind2maps       viins vicmd -- Home   vi-beginning-of-line
1435 bind2maps emacs             -- End    end-of-somewhere
1436 bind2maps       viins vicmd -- End    vi-end-of-line
1437 bind2maps emacs viins       -- Insert overwrite-mode
1438 bind2maps             vicmd -- Insert vi-insert
1439 bind2maps emacs             -- Delete delete-char
1440 bind2maps       viins vicmd -- Delete vi-delete-char
1441 bind2maps emacs viins vicmd -- Up     up-line-or-search
1442 bind2maps emacs viins vicmd -- Down   down-line-or-search
1443 bind2maps emacs             -- Left   backward-char
1444 bind2maps       viins vicmd -- Left   vi-backward-char
1445 bind2maps emacs             -- Right  forward-char
1446 bind2maps       viins vicmd -- Right  vi-forward-char
1447 #k# Perform abbreviation expansion
1448 bind2maps emacs viins       -- -s '^x.' zleiab
1449 #k# Display list of abbreviations that would expand
1450 bind2maps emacs viins       -- -s '^xb' help-show-abk
1451 #k# mkdir -p <dir> from string under cursor or marked area
1452 bind2maps emacs viins       -- -s '^xM' inplaceMkDirs
1453 #k# display help for keybindings and ZLE
1454 bind2maps emacs viins       -- -s '^xz' help-zle
1455 #k# Insert files and test globbing
1456 bind2maps emacs viins       -- -s "^xf" insert-files
1457 #k# Edit the current line in \kbd{\$EDITOR}
1458 bind2maps emacs viins       -- -s '\ee' edit-command-line
1459 #k# search history backward for entry beginning with typed text
1460 bind2maps emacs viins       -- -s '^xp' history-beginning-search-backward-end
1461 #k# search history forward for entry beginning with typed text
1462 bind2maps emacs viins       -- -s '^xP' history-beginning-search-forward-end
1463 #k# search history backward for entry beginning with typed text
1464 bind2maps emacs viins       -- PageUp history-beginning-search-backward-end
1465 #k# search history forward for entry beginning with typed text
1466 bind2maps emacs viins       -- PageDown history-beginning-search-forward-end
1467 bind2maps emacs viins       -- -s "^x^h" commit-to-history
1468 #k# Kill left-side word or everything up to next slash
1469 bind2maps emacs viins       -- -s '\ev' slash-backward-kill-word
1470 #k# Kill left-side word or everything up to next slash
1471 bind2maps emacs viins       -- -s '\e^h' slash-backward-kill-word
1472 #k# Kill left-side word or everything up to next slash
1473 bind2maps emacs viins       -- -s '\e^?' slash-backward-kill-word
1474 # Do history expansion on space:
1475 bind2maps emacs viins       -- -s ' ' magic-space
1476 #k# Trigger menu-complete
1477 bind2maps emacs viins       -- -s '\ei' menu-complete  # menu completion via esc-i
1478 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1479 bind2maps emacs viins       -- -s '^ed' insert-datestamp
1480 #k# Insert last typed word
1481 bind2maps emacs viins       -- -s "\em" insert-last-typed-word
1482 #k# A smart shortcut for \kbd{fg<enter>}
1483 bind2maps emacs viins       -- -s '^z' grml-zsh-fg
1484 #k# prepend the current command with "sudo"
1485 bind2maps emacs viins       -- -s "^os" sudo-command-line
1486 #k# jump to after first word (for adding options)
1487 bind2maps emacs viins       -- -s '^x1' jump_after_first_word
1488 #k# complete word from history with menu
1489 bind2maps emacs viins       -- -s "^x^x" hist-complete
1490
1491 # insert unicode character
1492 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
1493 # See for example http://unicode.org/charts/ for unicode characters code
1494 #k# Insert Unicode character
1495 bind2maps emacs viins       -- -s '^xi' insert-unicode-char
1496
1497 # use the new *-pattern-* widgets for incremental history search
1498 if zrcgotwidget history-incremental-pattern-search-backward; then
1499     for seq wid in '^r' history-incremental-pattern-search-backward \
1500                    '^s' history-incremental-pattern-search-forward
1501     do
1502         bind2maps emacs viins vicmd -- -s $seq $wid
1503     done
1504     builtin unset -v seq wid
1505 fi
1506
1507 if zrcgotkeymap menuselect; then
1508     #m# k Shift-tab Perform backwards menu completion
1509     bind2maps menuselect -- BackTab reverse-menu-complete
1510
1511     #k# menu selection: pick item but stay in the menu
1512     bind2maps menuselect -- -s '\e^M' accept-and-menu-complete
1513     # also use + and INSERT since it's easier to press repeatedly
1514     bind2maps menuselect -- -s '+' accept-and-menu-complete
1515     bind2maps menuselect -- Insert accept-and-menu-complete
1516
1517     # accept a completion and try to complete again by using menu
1518     # completion; very useful with completing directories
1519     # by using 'undo' one's got a simple file browser
1520     bind2maps menuselect -- -s '^o' accept-and-infer-next-history
1521 fi
1522
1523 # Finally, here are still a few hardcoded escape sequences; Special sequences
1524 # like Ctrl-<Cursor-key> etc do suck a fair bit, because they are not
1525 # standardised and most of the time are not available in a terminals terminfo
1526 # entry.
1527 #
1528 # While we do not encourage adding bindings like these, we will keep these for
1529 # backward compatibility.
1530
1531 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on
1532 ## the command line.
1533 # URxvt sequences:
1534 bind2maps emacs viins vicmd -- -s '\eOc' forward-word
1535 bind2maps emacs viins vicmd -- -s '\eOd' backward-word
1536 # These are for xterm:
1537 bind2maps emacs viins vicmd -- -s '\e[1;5C' forward-word
1538 bind2maps emacs viins vicmd -- -s '\e[1;5D' backward-word
1539 ## the same for alt-left-arrow and alt-right-arrow
1540 # URxvt again:
1541 bind2maps emacs viins vicmd -- -s '\e\e[C' forward-word
1542 bind2maps emacs viins vicmd -- -s '\e\e[D' backward-word
1543 # Xterm again:
1544 bind2maps emacs viins vicmd -- -s '^[[1;3C' forward-word
1545 bind2maps emacs viins vicmd -- -s '^[[1;3D' backward-word
1546 # Also try ESC Left/Right:
1547 bind2maps emacs viins vicmd -- -s '\e'${key[Right]} forward-word
1548 bind2maps emacs viins vicmd -- -s '\e'${key[Left]}  backward-word
1549
1550 # autoloading
1551
1552 zrcautoload zmv
1553 zrcautoload zed
1554
1555 # we don't want to quote/espace URLs on our own...
1556 # if autoload -U url-quote-magic ; then
1557 #    zle -N self-insert url-quote-magic
1558 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
1559 # else
1560 #    print 'Notice: no url-quote-magic available :('
1561 # fi
1562 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
1563
1564 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
1565 alias run-help >&/dev/null && unalias run-help
1566 for rh in run-help{,-git,-svk,-svn}; do
1567     zrcautoload $rh
1568 done; unset rh
1569
1570 # command not found handling
1571
1572 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1573 function command_not_found_handler() {
1574     emulate -L zsh
1575     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1576         ${GRML_ZSH_CNF_HANDLER} $1
1577     fi
1578     return 1
1579 }
1580
1581 # history
1582
1583 ZSHDIR=${ZDOTDIR:-${HOME}/.zsh}
1584
1585 #v#
1586 HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1587 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1588 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1589
1590 # dirstack handling
1591
1592 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1593 DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1594
1595 typeset -gaU GRML_PERSISTENT_DIRSTACK
1596 function grml_dirstack_filter() {
1597     local -a exclude
1598     local filter entry
1599     if zstyle -s ':grml:chpwd:dirstack' filter filter; then
1600         $filter $1 && return 0
1601     fi
1602     if zstyle -a ':grml:chpwd:dirstack' exclude exclude; then
1603         for entry in "${exclude[@]}"; do
1604             [[ $1 == ${~entry} ]] && return 0
1605         done
1606     fi
1607     return 1
1608 }
1609
1610 chpwd() {
1611     (( $DIRSTACKSIZE <= 0 )) && return
1612     [[ -z $DIRSTACKFILE ]] && return
1613     grml_dirstack_filter $PWD && return
1614     GRML_PERSISTENT_DIRSTACK=(
1615         $PWD "${(@)GRML_PERSISTENT_DIRSTACK[1,$DIRSTACKSIZE]}"
1616     )
1617     builtin print -l ${GRML_PERSISTENT_DIRSTACK} >! ${DIRSTACKFILE}
1618 }
1619
1620 if [[ -f ${DIRSTACKFILE} ]]; then
1621     # Enabling NULL_GLOB via (N) weeds out any non-existing
1622     # directories from the saved dir-stack file.
1623     dirstack=( ${(f)"$(< $DIRSTACKFILE)"}(N) )
1624     # "cd -" won't work after login by just setting $OLDPWD, so
1625     [[ -d $dirstack[1] ]] && cd -q $dirstack[1] && cd -q $OLDPWD
1626 fi
1627
1628 if zstyle -T ':grml:chpwd:dirstack' filter-on-load; then
1629     for i in "${dirstack[@]}"; do
1630         if ! grml_dirstack_filter "$i"; then
1631             GRML_PERSISTENT_DIRSTACK=(
1632                 "${GRML_PERSISTENT_DIRSTACK[@]}"
1633                 $i
1634             )
1635         fi
1636     done
1637 else
1638     GRML_PERSISTENT_DIRSTACK=( "${dirstack[@]}" )
1639 fi
1640
1641 # directory based profiles
1642
1643 if is433 ; then
1644
1645 # chpwd_profiles(): Directory Profiles, Quickstart:
1646 #
1647 # In .zshrc.local:
1648 #
1649 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1650 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1651 #   chpwd_profiles
1652 #
1653 # For details see the `grmlzshrc.5' manual page.
1654 function chpwd_profiles() {
1655     local profile context
1656     local -i reexecute
1657
1658     context=":chpwd:profiles:$PWD"
1659     zstyle -s "$context" profile profile || profile='default'
1660     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1661
1662     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1663         typeset -g CHPWD_PROFILE
1664         local CHPWD_PROFILES_INIT=1
1665         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1666     elif [[ $profile != $CHPWD_PROFILE ]]; then
1667         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1668             && chpwd_leave_profile_${CHPWD_PROFILE}
1669     fi
1670     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1671         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1672     fi
1673
1674     CHPWD_PROFILE="${profile}"
1675     return 0
1676 }
1677
1678 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1679
1680 fi # is433
1681
1682 # Prompt setup for grml:
1683
1684 # set colors for use in prompts (modern zshs allow for the use of %F{red}foo%f
1685 # in prompts to get a red "foo" embedded, but it's good to keep these for
1686 # backwards compatibility).
1687 if is437; then
1688     BLUE="%F{blue}"
1689     RED="%F{red}"
1690     GREEN="%F{green}"
1691     CYAN="%F{cyan}"
1692     MAGENTA="%F{magenta}"
1693     YELLOW="%F{yellow}"
1694     WHITE="%F{white}"
1695     NO_COLOR="%f"
1696 elif zrcautoload colors && colors 2>/dev/null ; then
1697     BLUE="%{${fg[blue]}%}"
1698     RED="%{${fg_bold[red]}%}"
1699     GREEN="%{${fg[green]}%}"
1700     CYAN="%{${fg[cyan]}%}"
1701     MAGENTA="%{${fg[magenta]}%}"
1702     YELLOW="%{${fg[yellow]}%}"
1703     WHITE="%{${fg[white]}%}"
1704     NO_COLOR="%{${reset_color}%}"
1705 else
1706     BLUE=$'%{\e[1;34m%}'
1707     RED=$'%{\e[1;31m%}'
1708     GREEN=$'%{\e[1;32m%}'
1709     CYAN=$'%{\e[1;36m%}'
1710     WHITE=$'%{\e[1;37m%}'
1711     MAGENTA=$'%{\e[1;35m%}'
1712     YELLOW=$'%{\e[1;33m%}'
1713     NO_COLOR=$'%{\e[0m%}'
1714 fi
1715
1716 # First, the easy ones: PS2..4:
1717
1718 # secondary prompt, printed when the shell needs more information to complete a
1719 # command.
1720 PS2='\`%_> '
1721 # selection prompt used within a select loop.
1722 PS3='?# '
1723 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1724 PS4='+%N:%i:%_> '
1725
1726 # Some additional features to use with our prompt:
1727 #
1728 #    - battery status
1729 #    - debian_chroot
1730 #    - vcs_info setup and version specific fixes
1731
1732 # display battery status on right side of prompt using 'GRML_DISPLAY_BATTERY=1' in .zshrc.pre
1733
1734 battery() {
1735 if [[ $GRML_DISPLAY_BATTERY -gt 0 ]] ; then
1736     if islinux ; then
1737         batterylinux
1738     elif isopenbsd ; then
1739         batteryopenbsd
1740     elif isfreebsd ; then
1741         batteryfreebsd
1742     elif isdarwin ; then
1743         batterydarwin
1744     else
1745         #not yet supported
1746         GRML_DISPLAY_BATTERY=0
1747     fi
1748 fi
1749 }
1750
1751 batterylinux(){
1752 GRML_BATTERY_LEVEL=''
1753 local batteries bat capacity
1754 batteries=( /sys/class/power_supply/BAT*(N) )
1755 if (( $#batteries > 0 )) ; then
1756     for bat in $batteries ; do
1757         capacity=$(< $bat/capacity)
1758         case $(< $bat/status) in
1759         Charging)
1760             GRML_BATTERY_LEVEL+=" ^"
1761             ;;
1762         Discharging)
1763             if (( capacity < 20 )) ; then
1764                 GRML_BATTERY_LEVEL+=" !v"
1765             else
1766                 GRML_BATTERY_LEVEL+=" v"
1767             fi
1768             ;;
1769         *) # Full, Unknown
1770             GRML_BATTERY_LEVEL+=" ="
1771             ;;
1772         esac
1773         GRML_BATTERY_LEVEL+="${capacity}%%"
1774     done
1775 fi
1776 }
1777
1778 batteryopenbsd(){
1779 GRML_BATTERY_LEVEL=''
1780 local bat batfull batwarn batnow num
1781 for num in 0 1 ; do
1782     bat=$(sysctl -n hw.sensors.acpibat${num} 2>/dev/null)
1783     if [[ -n $bat ]]; then
1784         batfull=${"$(sysctl -n hw.sensors.acpibat${num}.amphour0)"%% *}
1785         batwarn=${"$(sysctl -n hw.sensors.acpibat${num}.amphour1)"%% *}
1786         batnow=${"$(sysctl -n hw.sensors.acpibat${num}.amphour3)"%% *}
1787         case "$(sysctl -n hw.sensors.acpibat${num}.raw0)" in
1788             *" discharging"*)
1789                 if (( batnow < batwarn )) ; then
1790                     GRML_BATTERY_LEVEL+=" !v"
1791                 else
1792                     GRML_BATTERY_LEVEL+=" v"
1793                 fi
1794                 ;;
1795             *" charging"*)
1796                 GRML_BATTERY_LEVEL+=" ^"
1797                 ;;
1798             *)
1799                 GRML_BATTERY_LEVEL+=" ="
1800                 ;;
1801         esac
1802         GRML_BATTERY_LEVEL+="${$(( 100 * batnow / batfull ))%%.*}%%"
1803     fi
1804 done
1805 }
1806
1807 batteryfreebsd(){
1808 GRML_BATTERY_LEVEL=''
1809 local num
1810 local -A table
1811 for num in 0 1 ; do
1812     table=( ${=${${${${${(M)${(f)"$(acpiconf -i $num 2>&1)"}:#(State|Remaining capacity):*}%%( ##|%)}//:[ $'\t']##/@}// /-}//@/ }} )
1813     if [[ -n $table ]] && [[ $table[State] != "not-present" ]] ; then
1814         case $table[State] in
1815             *discharging*)
1816                 if (( $table[Remaining-capacity] < 20 )) ; then
1817                     GRML_BATTERY_LEVEL+=" !v"
1818                 else
1819                     GRML_BATTERY_LEVEL+=" v"
1820                 fi
1821                 ;;
1822             *charging*)
1823                 GRML_BATTERY_LEVEL+=" ^"
1824                 ;;
1825             *)
1826                 GRML_BATTERY_LEVEL+=" ="
1827                 ;;
1828         esac
1829         GRML_BATTERY_LEVEL+="$table[Remaining-capacity]%%"
1830     fi
1831 done
1832 }
1833
1834 batterydarwin(){
1835 GRML_BATTERY_LEVEL=''
1836 local -a table
1837 table=( ${$(pmset -g ps)[(w)7,8]%%(\%|);} )
1838 if [[ -n $table[2] ]] ; then
1839     case $table[2] in
1840         charging)
1841             GRML_BATTERY_LEVEL+=" ^"
1842             ;;
1843         discharging)
1844             if (( $table[1] < 20 )) ; then
1845                 GRML_BATTERY_LEVEL+=" !v"
1846             else
1847                 GRML_BATTERY_LEVEL+=" v"
1848             fi
1849             ;;
1850         *)
1851             GRML_BATTERY_LEVEL+=" ="
1852             ;;
1853     esac
1854     GRML_BATTERY_LEVEL+="$table[1]%%"
1855 fi
1856 }
1857
1858 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1859 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1860     debian_chroot=$(</etc/debian_chroot)
1861 fi
1862
1863 # gather version control information for inclusion in a prompt
1864
1865 if zrcautoload vcs_info; then
1866     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1867     # function, which can cause a lot of trouble with our directory-based
1868     # profiles. So:
1869     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1870         function VCS_INFO_realpath () {
1871             setopt localoptions NO_shwordsplit chaselinks
1872             ( builtin cd -q $1 2> /dev/null && pwd; )
1873         }
1874     fi
1875
1876     zstyle ':vcs_info:*' max-exports 2
1877
1878     if [[ -o restricted ]]; then
1879         zstyle ':vcs_info:*' enable NONE
1880     fi
1881 fi
1882
1883 typeset -A grml_vcs_coloured_formats
1884 typeset -A grml_vcs_plain_formats
1885
1886 grml_vcs_plain_formats=(
1887     format "(%s%)-[%b] "    "zsh: %r"
1888     actionformat "(%s%)-[%b|%a] " "zsh: %r"
1889     rev-branchformat "%b:%r"
1890 )
1891
1892 grml_vcs_coloured_formats=(
1893     format "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR} "
1894     actionformat "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} "
1895     rev-branchformat "%b${RED}:${YELLOW}%r"
1896 )
1897
1898 typeset GRML_VCS_COLOUR_MODE=xxx
1899
1900 grml_vcs_info_toggle_colour () {
1901     emulate -L zsh
1902     if [[ $GRML_VCS_COLOUR_MODE == plain ]]; then
1903         grml_vcs_info_set_formats coloured
1904     else
1905         grml_vcs_info_set_formats plain
1906     fi
1907     return 0
1908 }
1909
1910 grml_vcs_info_set_formats () {
1911     emulate -L zsh
1912     #setopt localoptions xtrace
1913     local mode=$1 AF F BF
1914     if [[ $mode == coloured ]]; then
1915         AF=${grml_vcs_coloured_formats[actionformat]}
1916         F=${grml_vcs_coloured_formats[format]}
1917         BF=${grml_vcs_coloured_formats[rev-branchformat]}
1918         GRML_VCS_COLOUR_MODE=coloured
1919     else
1920         AF=${grml_vcs_plain_formats[actionformat]}
1921         F=${grml_vcs_plain_formats[format]}
1922         BF=${grml_vcs_plain_formats[rev-branchformat]}
1923         GRML_VCS_COLOUR_MODE=plain
1924     fi
1925
1926     zstyle ':vcs_info:*'              actionformats "$AF" "zsh: %r"
1927     zstyle ':vcs_info:*'              formats       "$F"  "zsh: %r"
1928     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat  "$BF"
1929     return 0
1930 }
1931
1932 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1933 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1934 if [[ "$TERM" == dumb ]] ; then
1935     grml_vcs_info_set_formats plain
1936 else
1937     grml_vcs_info_set_formats coloured
1938 fi
1939
1940 # Now for the fun part: The grml prompt themes in `promptsys' mode of operation
1941
1942 # This actually defines three prompts:
1943 #
1944 #    - grml
1945 #    - grml-large
1946 #    - grml-chroot
1947 #
1948 # They all share the same code and only differ with respect to which items they
1949 # contain. The main source of documentation is the `prompt_grml_help' function
1950 # below, which gets called when the user does this: prompt -h grml
1951
1952 function prompt_grml_help () {
1953     <<__EOF0__
1954   prompt grml
1955
1956     This is the prompt as used by the grml-live system <http://grml.org>. It is
1957     a rather simple one-line prompt, that by default looks something like this:
1958
1959         <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1960
1961     The prompt itself integrates with zsh's prompt themes system (as you are
1962     witnessing right now) and is configurable to a certain degree. In
1963     particular, these aspects are customisable:
1964
1965         - The items used in the prompt (e.g. you can remove \`user' from
1966           the list of activated items, which will cause the user name to
1967           be omitted from the prompt string).
1968
1969         - The attributes used with the items are customisable via strings
1970           used before and after the actual item.
1971
1972     The available items are: at, battery, change-root, date, grml-chroot,
1973     history, host, jobs, newline, path, percent, rc, rc-always, sad-smiley,
1974     shell-level, time, user, vcs
1975
1976     The actual configuration is done via zsh's \`zstyle' mechanism. The
1977     context, that is used while looking up styles is:
1978
1979         ':prompt:grml:<left-or-right>:<subcontext>'
1980
1981     Here <left-or-right> is either \`left' or \`right', signifying whether the
1982     style should affect the left or the right prompt. <subcontext> is either
1983     \`setup' or 'items:<item>', where \`<item>' is one of the available items.
1984
1985     The styles:
1986
1987         - use-rprompt (boolean): If \`true' (the default), print a sad smiley
1988           in $RPROMPT if the last command a returned non-successful error code.
1989           (This in only valid if <left-or-right> is "right"; ignored otherwise)
1990
1991         - items (list): The list of items used in the prompt. If \`vcs' is
1992           present in the list, the theme's code invokes \`vcs_info'
1993           accordingly. Default (left): rc change-root user at host path vcs
1994           percent; Default (right): sad-smiley
1995
1996     Available styles in 'items:<item>' are: pre, post. These are strings that
1997     are inserted before (pre) and after (post) the item in question. Thus, the
1998     following would cause the user name to be printed in red instead of the
1999     default blue:
2000
2001         zstyle ':prompt:grml:*:items:user' pre '%F{red}'
2002
2003     Note, that the \`post' style may remain at its default value, because its
2004     default value is '%f', which turns the foreground text attribute off (which
2005     is exactly, what is still required with the new \`pre' value).
2006 __EOF0__
2007 }
2008
2009 function prompt_grml-chroot_help () {
2010     <<__EOF0__
2011   prompt grml-chroot
2012
2013     This is a variation of the grml prompt, see: prompt -h grml
2014
2015     The main difference is the default value of the \`items' style. The rest
2016     behaves exactly the same. Here are the defaults for \`grml-chroot':
2017
2018         - left: grml-chroot user at host path percent
2019         - right: (empty list)
2020 __EOF0__
2021 }
2022
2023 function prompt_grml-large_help () {
2024     <<__EOF0__
2025   prompt grml-large
2026
2027     This is a variation of the grml prompt, see: prompt -h grml
2028
2029     The main difference is the default value of the \`items' style. In
2030     particular, this theme uses _two_ lines instead of one with the plain
2031     \`grml' theme. The rest behaves exactly the same. Here are the defaults
2032     for \`grml-large':
2033
2034         - left: rc jobs history shell-level change-root time date newline user
2035                 at host path vcs percent
2036         - right: sad-smiley
2037 __EOF0__
2038 }
2039
2040 function grml_prompt_setup () {
2041     emulate -L zsh
2042     autoload -Uz vcs_info
2043     # The following autoload is disabled for now, since this setup includes a
2044     # static version of the ‘add-zsh-hook’ function above. It needs to be
2045     # reenabled as soon as that static definition is removed again.
2046     #autoload -Uz add-zsh-hook
2047     add-zsh-hook precmd prompt_$1_precmd
2048 }
2049
2050 function prompt_grml_setup () {
2051     grml_prompt_setup grml
2052 }
2053
2054 function prompt_grml-chroot_setup () {
2055     grml_prompt_setup grml-chroot
2056 }
2057
2058 function prompt_grml-large_setup () {
2059     grml_prompt_setup grml-large
2060 }
2061
2062 # These maps define default tokens and pre-/post-decoration for items to be
2063 # used within the themes. All defaults may be customised in a context sensitive
2064 # matter by using zsh's `zstyle' mechanism.
2065 typeset -gA grml_prompt_pre_default \
2066             grml_prompt_post_default \
2067             grml_prompt_token_default \
2068             grml_prompt_token_function
2069
2070 grml_prompt_pre_default=(
2071     at                ''
2072     battery           ' '
2073     change-root       ''
2074     date              '%F{blue}'
2075     grml-chroot       '%F{red}'
2076     history           '%F{green}'
2077     host              ''
2078     jobs              '%F{cyan}'
2079     newline           ''
2080     path              '%B'
2081     percent           ''
2082     rc                '%B%F{red}'
2083     rc-always         ''
2084     sad-smiley        ''
2085     shell-level       '%F{red}'
2086     time              '%F{blue}'
2087     user              '%B%F{blue}'
2088     vcs               ''
2089 )
2090
2091 grml_prompt_post_default=(
2092     at                ''
2093     battery           ''
2094     change-root       ''
2095     date              '%f'
2096     grml-chroot       '%f '
2097     history           '%f'
2098     host              ''
2099     jobs              '%f'
2100     newline           ''
2101     path              '%b'
2102     percent           ''
2103     rc                '%f%b'
2104     rc-always         ''
2105     sad-smiley        ''
2106     shell-level       '%f'
2107     time              '%f'
2108     user              '%f%b'
2109     vcs               ''
2110 )
2111
2112 grml_prompt_token_default=(
2113     at                '@'
2114     battery           'GRML_BATTERY_LEVEL'
2115     change-root       'debian_chroot'
2116     date              '%D{%Y-%m-%d}'
2117     grml-chroot       'GRML_CHROOT'
2118     history           '{history#%!} '
2119     host              '%m '
2120     jobs              '[%j running job(s)] '
2121     newline           $'\n'
2122     path              '%40<..<%~%<< '
2123     percent           '%# '
2124     rc                '%(?..%? )'
2125     rc-always         '%?'
2126     sad-smiley        '%(?..:()'
2127     shell-level       '%(3L.+ .)'
2128     time              '%D{%H:%M:%S} '
2129     user              '%n'
2130     vcs               '0'
2131 )
2132
2133 function grml_theme_has_token () {
2134     if (( ARGC != 1 )); then
2135         printf 'usage: grml_theme_has_token <name>\n'
2136         return 1
2137     fi
2138     (( ${+grml_prompt_token_default[$1]} ))
2139 }
2140
2141 function GRML_theme_add_token_usage () {
2142     <<__EOF0__
2143   Usage: grml_theme_add_token <name> [-f|-i] <token/function> [<pre> <post>]
2144
2145     <name> is the name for the newly added token. If the \`-f' or \`-i' options
2146     are used, <token/function> is the name of the function (see below for
2147     details). Otherwise it is the literal token string to be used. <pre> and
2148     <post> are optional.
2149
2150   Options:
2151
2152     -f <function>   Use a function named \`<function>' each time the token
2153                     is to be expanded.
2154
2155     -i <function>   Use a function named \`<function>' to initialise the
2156                     value of the token _once_ at runtime.
2157
2158     The functions are called with one argument: the token's new name. The
2159     return value is expected in the \$REPLY parameter. The use of these
2160     options is mutually exclusive.
2161
2162     There is a utility function \`grml_theme_has_token', which you can use
2163     to test if a token exists before trying to add it. This can be a guard
2164     for situations in which a \`grml_theme_add_token' call may happen more
2165     than once.
2166
2167   Example:
2168
2169     To add a new token \`day' that expands to the current weekday in the
2170     current locale in green foreground colour, use this:
2171
2172       grml_theme_add_token day '%D{%A}' '%F{green}' '%f'
2173
2174     Another example would be support for \$VIRTUAL_ENV:
2175
2176       function virtual_env_prompt () {
2177         REPLY=\${VIRTUAL_ENV+\${VIRTUAL_ENV:t} }
2178       }
2179       grml_theme_add_token virtual-env -f virtual_env_prompt
2180
2181     After that, you will be able to use a changed \`items' style to
2182     assemble your prompt.
2183 __EOF0__
2184 }
2185
2186 function grml_theme_add_token () {
2187     emulate -L zsh
2188     local name token pre post
2189     local -i init funcall
2190
2191     if (( ARGC == 0 )); then
2192         GRML_theme_add_token_usage
2193         return 0
2194     fi
2195
2196     init=0
2197     funcall=0
2198     pre=''
2199     post=''
2200     name=$1
2201     shift
2202     if [[ $1 == '-f' ]]; then
2203         funcall=1
2204         shift
2205     elif [[ $1 == '-i' ]]; then
2206         init=1
2207         shift
2208     fi
2209
2210     if (( ARGC == 0 )); then
2211         printf '
2212 grml_theme_add_token: No token-string/function-name provided!\n\n'
2213         GRML_theme_add_token_usage
2214         return 1
2215     fi
2216     token=$1
2217     shift
2218     if (( ARGC != 0 && ARGC != 2 )); then
2219         printf '
2220 grml_theme_add_token: <pre> and <post> need to by specified _both_!\n\n'
2221         GRML_theme_add_token_usage
2222         return 1
2223     fi
2224     if (( ARGC )); then
2225         pre=$1
2226         post=$2
2227         shift 2
2228     fi
2229
2230     if grml_theme_has_token $name; then
2231         printf '
2232 grml_theme_add_token: Token `%s'\'' exists! Giving up!\n\n' $name
2233         GRML_theme_add_token_usage
2234         return 2
2235     fi
2236     if (( init )); then
2237         $token $name
2238         token=$REPLY
2239     fi
2240     grml_prompt_pre_default[$name]=$pre
2241     grml_prompt_post_default[$name]=$post
2242     if (( funcall )); then
2243         grml_prompt_token_function[$name]=$token
2244         grml_prompt_token_default[$name]=23
2245     else
2246         grml_prompt_token_default[$name]=$token
2247     fi
2248 }
2249
2250 function grml_typeset_and_wrap () {
2251     emulate -L zsh
2252     local target="$1"
2253     local new="$2"
2254     local left="$3"
2255     local right="$4"
2256
2257     if (( ${+parameters[$new]} )); then
2258         typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
2259     fi
2260 }
2261
2262 function grml_prompt_addto () {
2263     emulate -L zsh
2264     local target="$1"
2265     local lr it apre apost new v
2266     local -a items
2267     shift
2268
2269     [[ $target == PS1 ]] && lr=left || lr=right
2270     zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
2271     typeset -g "${target}="
2272     for it in "${items[@]}"; do
2273         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
2274             || apre=${grml_prompt_pre_default[$it]}
2275         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" post apost \
2276             || apost=${grml_prompt_post_default[$it]}
2277         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
2278             || new=${grml_prompt_token_default[$it]}
2279         typeset -g "${target}=${(P)target}${apre}"
2280         if (( ${+grml_prompt_token_function[$it]} )); then
2281             ${grml_prompt_token_function[$it]} $it
2282             typeset -g "${target}=${(P)target}${REPLY}"
2283         else
2284             case $it in
2285             battery)
2286                 grml_typeset_and_wrap $target $new '' ''
2287                 ;;
2288             change-root)
2289                 grml_typeset_and_wrap $target $new '(' ')'
2290                 ;;
2291             grml-chroot)
2292                 if [[ -n ${(P)new} ]]; then
2293                     typeset -g "${target}=${(P)target}(CHROOT)"
2294                 fi
2295                 ;;
2296             vcs)
2297                 v="vcs_info_msg_${new}_"
2298                 if (( ! vcscalled )); then
2299                     vcs_info
2300                     vcscalled=1
2301                 fi
2302                 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
2303                     typeset -g "${target}=${(P)target}${(P)v}"
2304                 fi
2305                 ;;
2306             *) typeset -g "${target}=${(P)target}${new}" ;;
2307             esac
2308         fi
2309         typeset -g "${target}=${(P)target}${apost}"
2310     done
2311 }
2312
2313 function prompt_grml_precmd () {
2314     emulate -L zsh
2315     local grmltheme=grml
2316     local -a left_items right_items
2317     left_items=(rc change-root user at host path vcs percent)
2318     right_items=(sad-smiley)
2319
2320     prompt_grml_precmd_worker
2321 }
2322
2323 function prompt_grml-chroot_precmd () {
2324     emulate -L zsh
2325     local grmltheme=grml-chroot
2326     local -a left_items right_items
2327     left_items=(grml-chroot user at host path percent)
2328     right_items=()
2329
2330     prompt_grml_precmd_worker
2331 }
2332
2333 function prompt_grml-large_precmd () {
2334     emulate -L zsh
2335     local grmltheme=grml-large
2336     local -a left_items right_items
2337     left_items=(rc jobs history shell-level change-root time date newline
2338                 user at host path vcs percent)
2339     right_items=(sad-smiley)
2340
2341     prompt_grml_precmd_worker
2342 }
2343
2344 function prompt_grml_precmd_worker () {
2345     emulate -L zsh
2346     local -i vcscalled=0
2347
2348     grml_prompt_addto PS1 "${left_items[@]}"
2349     if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
2350         grml_prompt_addto RPS1 "${right_items[@]}"
2351     fi
2352 }
2353
2354 grml_prompt_fallback() {
2355     setopt prompt_subst
2356     precmd() {
2357         (( ${+functions[vcs_info]} )) && vcs_info
2358     }
2359
2360     p0="${RED}%(?..%? )${WHITE}${debian_chroot:+($debian_chroot)}"
2361     p1="${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "'${vcs_info_msg_0_}'"%# "
2362     if (( EUID == 0 )); then
2363         PROMPT="${BLUE}${p0}${RED}${p1}"
2364     else
2365         PROMPT="${RED}${p0}${BLUE}${p1}"
2366     fi
2367     unset p0 p1
2368 }
2369
2370 if zrcautoload promptinit && promptinit 2>/dev/null ; then
2371     # Since we define the required functions in here and not in files in
2372     # $fpath, we need to stick the theme's name into `$prompt_themes'
2373     # ourselves, since promptinit does not pick them up otherwise.
2374     prompt_themes+=( grml grml-chroot grml-large )
2375     # Also, keep the array sorted...
2376     prompt_themes=( "${(@on)prompt_themes}" )
2377 else
2378     print 'Notice: no promptinit available :('
2379     grml_prompt_fallback
2380 fi
2381
2382 if is437; then
2383     # The prompt themes use modern features of zsh, that require at least
2384     # version 4.3.7 of the shell. Use the fallback otherwise.
2385     if [[ $GRML_DISPLAY_BATTERY -gt 0 ]]; then
2386         zstyle ':prompt:grml:right:setup' items sad-smiley battery
2387         add-zsh-hook precmd battery
2388     fi
2389     if [[ "$TERM" == dumb ]] ; then
2390         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" pre ''
2391         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" post ' '
2392         for i in rc user path jobs history date time shell-level; do
2393             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" pre ''
2394             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" post ''
2395         done
2396         unset i
2397         zstyle ':prompt:grml(|-large|-chroot):right:setup' use-rprompt false
2398     elif (( EUID == 0 )); then
2399         zstyle ':prompt:grml(|-large|-chroot):*:items:user' pre '%B%F{red}'
2400     fi
2401
2402     # Finally enable one of the prompts.
2403     if [[ -n $GRML_CHROOT ]]; then
2404         prompt grml-chroot
2405     elif [[ $GRMLPROMPT -gt 0 ]]; then
2406         prompt grml-large
2407     else
2408         prompt grml
2409     fi
2410 else
2411     grml_prompt_fallback
2412 fi
2413
2414 # Terminal-title wizardry
2415
2416 function ESC_print () {
2417     info_print $'\ek' $'\e\\' "$@"
2418 }
2419 function set_title () {
2420     info_print  $'\e]0;' $'\a' "$@"
2421 }
2422
2423 function info_print () {
2424     local esc_begin esc_end
2425     esc_begin="$1"
2426     esc_end="$2"
2427     shift 2
2428     printf '%s' ${esc_begin}
2429     printf '%s' "$*"
2430     printf '%s' "${esc_end}"
2431 }
2432
2433 function grml_reset_screen_title () {
2434     # adjust title of xterm
2435     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
2436     [[ ${NOTITLE:-} -gt 0 ]] && return 0
2437     case $TERM in
2438         (xterm*|rxvt*)
2439             set_title ${(%):-"%n@%m: %~"}
2440             ;;
2441     esac
2442 }
2443
2444 function grml_vcs_to_screen_title () {
2445     if [[ $TERM == screen* ]] ; then
2446         if [[ -n ${vcs_info_msg_1_} ]] ; then
2447             ESC_print ${vcs_info_msg_1_}
2448         else
2449             ESC_print "zsh"
2450         fi
2451     fi
2452 }
2453
2454 function grml_maintain_name () {
2455     # set hostname if not running on host with name 'grml'
2456     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
2457        NAME="@$HOSTNAME"
2458     fi
2459 }
2460
2461 function grml_cmd_to_screen_title () {
2462     # get the name of the program currently running and hostname of local
2463     # machine set screen window title if running in a screen
2464     if [[ "$TERM" == screen* ]] ; then
2465         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME"
2466         ESC_print ${CMD}
2467     fi
2468 }
2469
2470 function grml_control_xterm_title () {
2471     case $TERM in
2472         (xterm*|rxvt*)
2473             set_title "${(%):-"%n@%m:"}" "$1"
2474             ;;
2475     esac
2476 }
2477
2478 # The following autoload is disabled for now, since this setup includes a
2479 # static version of the ‘add-zsh-hook’ function above. It needs to be
2480 # reenabled as soon as that static definition is removed again.
2481 #zrcautoload add-zsh-hook || add-zsh-hook () { :; }
2482 if [[ $NOPRECMD -eq 0 ]]; then
2483     add-zsh-hook precmd grml_reset_screen_title
2484     add-zsh-hook precmd grml_vcs_to_screen_title
2485     add-zsh-hook preexec grml_maintain_name
2486     add-zsh-hook preexec grml_cmd_to_screen_title
2487     if [[ $NOTITLE -eq 0 ]]; then
2488         add-zsh-hook preexec grml_control_xterm_title
2489     fi
2490 fi
2491
2492 # 'hash' some often used directories
2493 #d# start
2494 hash -d deb=/var/cache/apt/archives
2495 hash -d doc=/usr/share/doc
2496 hash -d linux=/lib/modules/$(command uname -r)/build/
2497 hash -d log=/var/log
2498 hash -d slog=/var/log/syslog
2499 hash -d src=/usr/src
2500 hash -d www=/var/www
2501 #d# end
2502
2503 # some aliases
2504 if check_com -c screen ; then
2505     if [[ $UID -eq 0 ]] ; then
2506         if [[ -r /etc/grml/screenrc ]]; then
2507             alias screen="${commands[screen]} -c /etc/grml/screenrc"
2508         fi
2509     elif [[ -r $HOME/.screenrc ]] ; then
2510         alias screen="${commands[screen]} -c $HOME/.screenrc"
2511     else
2512         if [[ -r /etc/grml/screenrc_grml ]]; then
2513             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
2514         else
2515             if [[ -r /etc/grml/screenrc ]]; then
2516                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
2517             fi
2518         fi
2519     fi
2520 fi
2521
2522 # do we have GNU ls with color-support?
2523 if [[ "$TERM" != dumb ]]; then
2524     #a1# List files with colors (\kbd{ls \ldots})
2525     alias ls="command ls ${ls_options:+${ls_options[*]}}"
2526     #a1# List all files, with colors (\kbd{ls -la \ldots})
2527     alias la="command ls -la ${ls_options:+${ls_options[*]}}"
2528     #a1# List files with long colored list, without dotfiles (\kbd{ls -l \ldots})
2529     alias ll="command ls -l ${ls_options:+${ls_options[*]}}"
2530     #a1# List files with long colored list, human readable sizes (\kbd{ls -hAl \ldots})
2531     alias lh="command ls -hAl ${ls_options:+${ls_options[*]}}"
2532     #a1# List files with long colored list, append qualifier to filenames (\kbd{ls -l \ldots})\\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2533     alias l="command ls -l ${ls_options:+${ls_options[*]}}"
2534 else
2535     alias la='command ls -la'
2536     alias ll='command ls -l'
2537     alias lh='command ls -hAl'
2538     alias l='command ls -l'
2539 fi
2540
2541 alias mdstat='cat /proc/mdstat'
2542 alias ...='cd ../../'
2543
2544 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2545 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2546     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2547 fi
2548
2549 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2550 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2551 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2552
2553 # make sure it is not assigned yet
2554 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
2555 utf2iso() {
2556     if isutfenv ; then
2557         local ENV
2558         for ENV in $(env | command grep -i '.utf') ; do
2559             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2560         done
2561     fi
2562 }
2563
2564 # make sure it is not assigned yet
2565 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
2566 iso2utf() {
2567     if ! isutfenv ; then
2568         local ENV
2569         for ENV in $(env | command grep -i '\.iso') ; do
2570             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2571         done
2572     fi
2573 }
2574
2575 # especially for roadwarriors using GNU screen and ssh:
2576 if ! check_com asc &>/dev/null ; then
2577   asc() { autossh -t "$@" 'screen -RdU' }
2578   compdef asc=ssh
2579 fi
2580
2581 #f1# Hints for the use of zsh on grml
2582 zsh-help() {
2583     print "$bg[white]$fg[black]
2584 zsh-help - hints for use of zsh on grml
2585 =======================================$reset_color"
2586
2587     print '
2588 Main configuration of zsh happens in /etc/zsh/zshrc.
2589 That file is part of the package grml-etc-core, if you want to
2590 use them on a non-grml-system just get the tar.gz from
2591 http://deb.grml.org/ or (preferably) get it from the git repository:
2592
2593   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2594
2595 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2596 The file is still there, but it is empty for backwards compatibility.
2597
2598 For your own changes use these two files:
2599     $HOME/.zshrc.pre
2600     $HOME/.zshrc.local
2601
2602 The former is sourced very early in our zshrc, the latter is sourced
2603 very lately.
2604
2605 System wide configuration without touching configuration files of grml
2606 can take place in /etc/zsh/zshrc.local.
2607
2608 For information regarding zsh start at http://grml.org/zsh/
2609
2610 Take a look at grml'\''s zsh refcard:
2611 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2612
2613 Check out the main zsh refcard:
2614 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2615
2616 And of course visit the zsh-lovers:
2617 % man zsh-lovers
2618
2619 You can adjust some options through environment variables when
2620 invoking zsh without having to edit configuration files.
2621 Basically meant for bash users who are not used to the power of
2622 the zsh yet. :)
2623
2624   "NOCOR=1    zsh" => deactivate automatic correction
2625   "NOMENU=1   zsh" => do not use auto menu completion
2626                       (note: use ctrl-d for completion instead!)
2627   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2628   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2629                       preexec() and precmd() completely
2630   "GRML_DISPLAY_BATTERY=1  zsh"
2631                    => activate battery status on right side of prompt (WIP)
2632   "COMMAND_NOT_FOUND=1 zsh"
2633                    => Enable a handler if an external command was not found
2634                       The command called in the handler can be altered by setting
2635                       the GRML_ZSH_CNF_HANDLER variable, the default is:
2636                       "/usr/share/command-not-found/command-not-found"
2637
2638 A value greater than 0 is enables a feature; a value equal to zero
2639 disables it. If you like one or the other of these settings, you can
2640 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2641 zshrc.'
2642
2643     print "
2644 $bg[white]$fg[black]
2645 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2646 Enjoy your grml system with the zsh!$reset_color"
2647 }
2648
2649 # debian stuff
2650 if [[ -r /etc/debian_version ]] ; then
2651     #a3# Execute \kbd{apt-cache search}
2652     alias acs='apt-cache search'
2653     #a3# Execute \kbd{apt-cache show}
2654     alias acsh='apt-cache show'
2655     #a3# Execute \kbd{apt-cache policy}
2656     alias acp='apt-cache policy'
2657     #a3# Execute \kbd{apt-get dist-upgrade}
2658     salias adg="apt-get dist-upgrade"
2659     #a3# Execute \kbd{apt-get install}
2660     salias agi="apt-get install"
2661     #a3# Execute \kbd{aptitude install}
2662     salias ati="aptitude install"
2663     #a3# Execute \kbd{apt-get upgrade}
2664     salias ag="apt-get upgrade"
2665     #a3# Execute \kbd{apt-get update}
2666     salias au="apt-get update"
2667     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2668     salias -a up="aptitude update ; aptitude safe-upgrade"
2669     #a3# Execute \kbd{dpkg-buildpackage}
2670     alias dbp='dpkg-buildpackage'
2671     #a3# Execute \kbd{grep-excuses}
2672     alias ge='grep-excuses'
2673
2674     # get a root shell as normal user in live-cd mode:
2675     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2676        alias su="sudo su"
2677     fi
2678
2679     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2680     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2681     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2682     salias tlog="tail -f /var/log/syslog"    # follow the syslog
2683 fi
2684
2685 # sort installed Debian-packages by size
2686 if check_com -c dpkg-query ; then
2687     #a3# List installed Debian-packages sorted by size
2688     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
2689 fi
2690
2691 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2692 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
2693     if check_com -c wodim; then
2694         cdrecord() {
2695             <<__EOF0__
2696 cdrecord is not provided under its original name by Debian anymore.
2697 See #377109 in the BTS of Debian for more details.
2698
2699 Please use the wodim binary instead
2700 __EOF0__
2701             return 1
2702         }
2703     fi
2704 fi
2705
2706 # Use hard limits, except for a smaller stack and no core dumps
2707 unlimit
2708 is425 && limit stack 8192
2709 isgrmlcd && limit core 0 # important for a live-cd-system
2710 limit -s
2711
2712 # grmlstuff
2713 grmlstuff() {
2714 # people should use 'grml-x'!
2715     if check_com -c 915resolution; then
2716         855resolution() {
2717             echo "Please use 915resolution as resolution modifying tool for Intel \
2718 graphic chipset."
2719             return -1
2720         }
2721     fi
2722
2723     #a1# Output version of running grml
2724     alias grml-version='cat /etc/grml_version'
2725
2726     if check_com -c grml-debootstrap ; then
2727         debian2hd() {
2728             echo "Installing debian to harddisk is possible by using grml-debootstrap."
2729             return 1
2730         }
2731     fi
2732 }
2733
2734 # now run the functions
2735 isgrml && checkhome
2736 is4    && isgrml    && grmlstuff
2737 is4    && grmlcomp
2738
2739 # keephack
2740 is4 && xsource "/etc/zsh/keephack"
2741
2742 # wonderful idea of using "e" glob qualifier by Peter Stephenson
2743 # You use it as follows:
2744 # $ NTREF=/reference/file
2745 # $ ls -l *(e:nt:)
2746 # This lists all the files in the current directory newer than the reference file.
2747 # You can also specify the reference file inline; note quotes:
2748 # $ ls -l *(e:'nt ~/.zshenv':)
2749 is4 && nt() {
2750     if [[ -n $1 ]] ; then
2751         local NTREF=${~1}
2752     fi
2753     [[ $REPLY -nt $NTREF ]]
2754 }
2755
2756 # shell functions
2757
2758 #f1# Reload an autoloadable function
2759 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2760 compdef _functions freload
2761
2762 #
2763 # Usage:
2764 #
2765 #      e.g.:   a -> b -> c -> d  ....
2766 #
2767 #      sll a
2768 #
2769 #
2770 #      if parameter is given with leading '=', lookup $PATH for parameter and resolve that
2771 #
2772 #      sll =java
2773 #
2774 #      Note: limit for recursive symlinks on linux:
2775 #            http://git.kernel.org/cgit/linux/kernel/git/torvalds/linux.git/tree/fs/namei.c?id=refs/heads/master#l808
2776 #            This limits recursive symlink follows to 8,
2777 #            while limiting consecutive symlinks to 40.
2778 #
2779 #      When resolving and displaying information about symlinks, no check is made
2780 #      that the displayed information does make any sense on your OS.
2781 #      We leave that decission to the user.
2782 #
2783 #      The zstat module is used to detect symlink loops. zstat is available since zsh4.
2784 #      With an older zsh you will need to abort with <C-c> in that case.
2785 #      When a symlink loop is detected, a warning ist printed and further processing is stopped.
2786 #
2787 #      Module zstat is loaded by default in grml zshrc, no extra action needed for that.
2788 #
2789 #      Known bugs:
2790 #      If you happen to come accross a symlink that points to a destination on an other partition
2791 #      with the same inode number, that will be marked as symlink loop though it is not.
2792 #      Two hints for this situation:
2793 #      I)  Play lottery the same day, as you seem to be rather lucky right now.
2794 #      II) Send patches.
2795 #
2796 #      return status:
2797 #      0 upon success
2798 #      1 file/dir not accesible
2799 #      2 symlink loop detected
2800 #
2801 #f1# List symlinks in detail (more detailed version of 'readlink -f', 'whence -s' and 'namei -l')
2802 sll() {
2803     if [[ -z ${1} ]] ; then
2804         printf 'Usage: %s <symlink(s)>\n' "${0}"
2805         return 1
2806     fi
2807
2808     local file jumpd curdir
2809     local -i RTN LINODE i
2810     local -a SEENINODES
2811     curdir="${PWD}"
2812     RTN=0
2813
2814     for file in "${@}" ; do
2815         SEENINODES=()
2816         ls -l "${file:a}"   || RTN=1
2817
2818         while [[ -h "$file" ]] ; do
2819             if is4 ; then
2820                 LINODE=$(zstat -L +inode "${file}")
2821                 for i in ${SEENINODES} ; do
2822                     if (( ${i} == ${LINODE} )) ; then
2823                         builtin cd "${curdir}"
2824                         print "link loop detected, aborting!"
2825                         return 2
2826                     fi
2827                 done
2828                 SEENINODES+=${LINODE}
2829             fi
2830             jumpd="${file:h}"
2831             file="${file:t}"
2832
2833             if [[ -d ${jumpd} ]] ; then
2834                 builtin cd "${jumpd}"  || RTN=1
2835             fi
2836             file=$(readlink "$file")
2837
2838             jumpd="${file:h}"
2839             file="${file:t}"
2840
2841             if [[ -d ${jumpd} ]] ; then
2842                 builtin cd "${jumpd}"  || RTN=1
2843             fi
2844
2845             ls -l "${PWD}/${file}"     || RTN=1
2846         done
2847         shift 1
2848         if (( ${#} >= 1 )) ; then
2849             print ""
2850         fi
2851         builtin cd "${curdir}"
2852     done
2853     return ${RTN}
2854 }
2855
2856 # TODO: Is it supported to use pager settings like this?
2857 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2858 # with respect to wordsplitting. (ie. ${=PAGER})
2859 if check_com -c $PAGER ; then
2860     #f3# View Debian's changelog of given package(s)
2861     dchange() {
2862         emulate -L zsh
2863         [[ -z "$1" ]] && printf 'Usage: %s <package_name(s)>\n' "$0" && return 1
2864
2865         local package
2866         for package in "$@" ; do
2867             if [[ -r /usr/share/doc/${package}/changelog.Debian.gz ]] ; then
2868                 $PAGER /usr/share/doc/${package}/changelog.Debian.gz
2869             elif [[ -r /usr/share/doc/${package}/changelog.gz ]] ; then
2870                 $PAGER /usr/share/doc/${package}/changelog.gz
2871             elif [[ -r /usr/share/doc/${package}/changelog ]] ; then
2872                 $PAGER /usr/share/doc/${package}/changelog
2873             else
2874                 if check_com -c aptitude ; then
2875                     echo "No changelog for package $package found, using aptitude to retrieve it."
2876                     aptitude changelog "$package"
2877                 elif check_com -c apt-get ; then
2878                     echo "No changelog for package $package found, using apt-get to retrieve it."
2879                     apt-get changelog "$package"
2880                 else
2881                     echo "No changelog for package $package found, sorry."
2882                 fi
2883             fi
2884         done
2885     }
2886     _dchange() { _files -W /usr/share/doc -/ }
2887     compdef _dchange dchange
2888
2889     #f3# View Debian's NEWS of a given package
2890     dnews() {
2891         emulate -L zsh
2892         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2893             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2894         else
2895             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2896                 $PAGER /usr/share/doc/$1/NEWS.gz
2897             else
2898                 echo "No NEWS file for package $1 found, sorry."
2899                 return 1
2900             fi
2901         fi
2902     }
2903     _dnews() { _files -W /usr/share/doc -/ }
2904     compdef _dnews dnews
2905
2906     #f3# View Debian's copyright of a given package
2907     dcopyright() {
2908         emulate -L zsh
2909         if [[ -r /usr/share/doc/$1/copyright ]] ; then
2910             $PAGER /usr/share/doc/$1/copyright
2911         else
2912             echo "No copyright file for package $1 found, sorry."
2913             return 1
2914         fi
2915     }
2916     _dcopyright() { _files -W /usr/share/doc -/ }
2917     compdef _dcopyright dcopyright
2918
2919     #f3# View upstream's changelog of a given package
2920     uchange() {
2921         emulate -L zsh
2922         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2923             $PAGER /usr/share/doc/$1/changelog.gz
2924         else
2925             echo "No changelog for package $1 found, sorry."
2926             return 1
2927         fi
2928     }
2929     _uchange() { _files -W /usr/share/doc -/ }
2930     compdef _uchange uchange
2931 fi
2932
2933 # zsh profiling
2934 profile() {
2935     ZSH_PROFILE_RC=1 zsh "$@"
2936 }
2937
2938 #f1# Edit an alias via zle
2939 edalias() {
2940     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2941 }
2942 compdef _aliases edalias
2943
2944 #f1# Edit a function via zle
2945 edfunc() {
2946     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2947 }
2948 compdef _functions edfunc
2949
2950 # use it e.g. via 'Restart apache2'
2951 #m# f6 Start() \kbd{service \em{process}}\quad\kbd{start}
2952 #m# f6 Restart() \kbd{service \em{process}}\quad\kbd{restart}
2953 #m# f6 Stop() \kbd{service \em{process}}\quad\kbd{stop}
2954 #m# f6 Reload() \kbd{service \em{process}}\quad\kbd{reload}
2955 #m# f6 Force-Reload() \kbd{service \em{process}}\quad\kbd{force-reload}
2956 #m# f6 Status() \kbd{service \em{process}}\quad\kbd{status}
2957 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2958     __start_stop() {
2959         local action_="${1:l}"  # e.g Start/Stop/Restart
2960         local service_="$2"
2961         local param_="$3"
2962
2963         local service_target_="$(readlink /etc/init.d/$service_)"
2964         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2965             # runit
2966             case "${action_}" in
2967                 start) if [[ ! -e /etc/service/$service_ ]]; then
2968                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2969                        else
2970                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2971                        fi ;;
2972                 # there is no reload in runits sysv emulation
2973                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2974                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2975             esac
2976         else
2977             # sysv/sysvinit-utils, upstart
2978             if check_com -c service ; then
2979               $SUDO service "$service_" "${action_}" "$param_"
2980             else
2981               $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2982             fi
2983         fi
2984     }
2985
2986     _grmlinitd() {
2987         local -a scripts
2988         scripts=( /etc/init.d/*(x:t) )
2989         _describe "service startup script" scripts
2990     }
2991
2992     for i in Start Restart Stop Force-Reload Reload Status ; do
2993         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2994         compdef _grmlinitd $i
2995     done
2996     builtin unset -v i
2997 fi
2998
2999 #f1# Provides useful information on globbing
3000 H-Glob() {
3001     echo -e "
3002     /      directories
3003     .      plain files
3004     @      symbolic links
3005     =      sockets
3006     p      named pipes (FIFOs)
3007     *      executable plain files (0100)
3008     %      device files (character or block special)
3009     %b     block special files
3010     %c     character special files
3011     r      owner-readable files (0400)
3012     w      owner-writable files (0200)
3013     x      owner-executable files (0100)
3014     A      group-readable files (0040)
3015     I      group-writable files (0020)
3016     E      group-executable files (0010)
3017     R      world-readable files (0004)
3018     W      world-writable files (0002)
3019     X      world-executable files (0001)
3020     s      setuid files (04000)
3021     S      setgid files (02000)
3022     t      files with the sticky bit (01000)
3023
3024   print *(m-1)          # Files modified up to a day ago
3025   print *(a1)           # Files accessed a day ago
3026   print *(@)            # Just symlinks
3027   print *(Lk+50)        # Files bigger than 50 kilobytes
3028   print *(Lk-50)        # Files smaller than 50 kilobytes
3029   print **/*.c          # All *.c files recursively starting in \$PWD
3030   print **/*.c~file.c   # Same as above, but excluding 'file.c'
3031   print (foo|bar).*     # Files starting with 'foo' or 'bar'
3032   print *~*.*           # All Files that do not contain a dot
3033   chmod 644 *(.^x)      # make all plain non-executable files publically readable
3034   print -l *(.c|.h)     # Lists *.c and *.h
3035   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
3036   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
3037 }
3038 alias help-zshglob=H-Glob
3039
3040 # grep for running process, like: 'any vim'
3041 any() {
3042     emulate -L zsh
3043     unsetopt KSH_ARRAYS
3044     if [[ -z "$1" ]] ; then
3045         echo "any - grep for process(es) by keyword" >&2
3046         echo "Usage: any <keyword>" >&2 ; return 1
3047     else
3048         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
3049     fi
3050 }
3051
3052
3053 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
3054 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
3055 [[ -r /proc/1/maps ]] && \
3056 deswap() {
3057     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
3058     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
3059     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
3060 }
3061
3062 # a wrapper for vim, that deals with title setting
3063 #   VIM_OPTIONS
3064 #       set this array to a set of options to vim you always want
3065 #       to have set when calling vim (in .zshrc.local), like:
3066 #           VIM_OPTIONS=( -p )
3067 #       This will cause vim to send every file given on the
3068 #       commandline to be send to it's own tab (needs vim7).
3069 if check_com vim; then
3070     vim() {
3071         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
3072     }
3073 fi
3074
3075 ssl_hashes=( sha512 sha256 sha1 md5 )
3076
3077 for sh in ${ssl_hashes}; do
3078     eval 'ssl-cert-'${sh}'() {
3079         emulate -L zsh
3080         if [[ -z $1 ]] ; then
3081             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
3082             return 1
3083         fi
3084         openssl x509 -noout -fingerprint -'${sh}' -in $1
3085     }'
3086 done; unset sh
3087
3088 ssl-cert-fingerprints() {
3089     emulate -L zsh
3090     local i
3091     if [[ -z $1 ]] ; then
3092         printf 'usage: ssl-cert-fingerprints <file>\n'
3093         return 1
3094     fi
3095     for i in ${ssl_hashes}
3096         do ssl-cert-$i $1;
3097     done
3098 }
3099
3100 ssl-cert-info() {
3101     emulate -L zsh
3102     if [[ -z $1 ]] ; then
3103         printf 'usage: ssl-cert-info <file>\n'
3104         return 1
3105     fi
3106     openssl x509 -noout -text -in $1
3107     ssl-cert-fingerprints $1
3108 }
3109
3110 # make sure our environment is clean regarding colors
3111 for var in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $var
3112 builtin unset -v var
3113
3114 # "persistent history"
3115 # just write important commands you always need to ~/.important_commands
3116 if [[ -r ~/.important_commands ]] ; then
3117     fc -R ~/.important_commands
3118 fi
3119
3120 # load the lookup subsystem if it's available on the system
3121 zrcautoload lookupinit && lookupinit
3122
3123 # variables
3124
3125 # set terminal property (used e.g. by msgid-chooser)
3126 export COLORTERM="yes"
3127
3128 # aliases
3129
3130 # general
3131 #a2# Execute \kbd{du -sch}
3132 alias da='du -sch'
3133
3134 # listing stuff
3135 #a2# Execute \kbd{ls -lSrah}
3136 alias dir="command ls -lSrah"
3137 #a2# Only show dot-directories
3138 alias lad='command ls -d .*(/)'
3139 #a2# Only show dot-files
3140 alias lsa='command ls -a .*(.)'
3141 #a2# Only files with setgid/setuid/sticky flag
3142 alias lss='command ls -l *(s,S,t)'
3143 #a2# Only show symlinks
3144 alias lsl='command ls -l *(@)'
3145 #a2# Display only executables
3146 alias lsx='command ls -l *(*)'
3147 #a2# Display world-{readable,writable,executable} files
3148 alias lsw='command ls -ld *(R,W,X.^ND/)'
3149 #a2# Display the ten biggest files
3150 alias lsbig="command ls -flh *(.OL[1,10])"
3151 #a2# Only show directories
3152 alias lsd='command ls -d *(/)'
3153 #a2# Only show empty directories
3154 alias lse='command ls -d *(/^F)'
3155 #a2# Display the ten newest files
3156 alias lsnew="command ls -rtlh *(D.om[1,10])"
3157 #a2# Display the ten oldest files
3158 alias lsold="command ls -rtlh *(D.Om[1,10])"
3159 #a2# Display the ten smallest files
3160 alias lssmall="command ls -Srl *(.oL[1,10])"
3161 #a2# Display the ten newest directories and ten newest .directories
3162 alias lsnewdir="command ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
3163 #a2# Display the ten oldest directories and ten oldest .directories
3164 alias lsolddir="command ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
3165
3166 # some useful aliases
3167 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir \$OLDCWD}
3168 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
3169
3170 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3171 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3172 #a2# scp with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3173 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3174
3175 # work around non utf8 capable software in utf environment via $LANG and luit
3176 if check_com isutfenv && check_com luit ; then
3177     if check_com -c mrxvt ; then
3178         isutfenv && [[ -n "$LANG" ]] && \
3179             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3180     fi
3181
3182     if check_com -c aterm ; then
3183         isutfenv && [[ -n "$LANG" ]] && \
3184             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3185     fi
3186
3187     if check_com -c centericq ; then
3188         isutfenv && [[ -n "$LANG" ]] && \
3189             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3190     fi
3191 fi
3192
3193 # useful functions
3194
3195 #f5# Backup \kbd{file_or_folder {\rm to} file_or_folder\_timestamp}
3196 bk() {
3197     emulate -L zsh
3198     local current_date=$(date -u "+%Y-%m-%dT%H:%M:%SZ")
3199     local clean keep move verbose result all to_bk
3200     setopt extended_glob
3201     keep=1
3202     while getopts ":hacmrv" opt; do
3203         case $opt in
3204             a) (( all++ ));;
3205             c) unset move clean && (( ++keep ));;
3206             m) unset keep clean && (( ++move ));;
3207             r) unset move keep && (( ++clean ));;
3208             v) verbose="-v";;
3209             h) <<__EOF0__
3210 bk [-hcmv] FILE [FILE ...]
3211 bk -r [-av] [FILE [FILE ...]]
3212 Backup a file or folder in place and append the timestamp
3213 Remove backups of a file or folder, or all backups in the current directory
3214
3215 Usage:
3216 -h    Display this help text
3217 -c    Keep the file/folder as is, create a copy backup using cp(1) (default)
3218 -m    Move the file/folder, using mv(1)
3219 -r    Remove backups of the specified file or directory, using rm(1). If none
3220       is provided, remove all backups in the current directory.
3221 -a    Remove all (even hidden) backups.
3222 -v    Verbose
3223
3224 The -c, -r and -m options are mutually exclusive. If specified at the same time,
3225 the last one is used.
3226
3227 The return code is the sum of all cp/mv/rm return codes.
3228 __EOF0__
3229 return 0;;
3230             \?) bk -h >&2; return 1;;
3231         esac
3232     done
3233     shift "$((OPTIND-1))"
3234     if (( keep > 0 )); then
3235         if islinux || isfreebsd; then
3236             for to_bk in "$@"; do
3237                 cp $verbose -a "${to_bk%/}" "${to_bk%/}_$current_date"
3238                 (( result += $? ))
3239             done
3240         else
3241             for to_bk in "$@"; do
3242                 cp $verbose -pR "${to_bk%/}" "${to_bk%/}_$current_date"
3243                 (( result += $? ))
3244             done
3245         fi
3246     elif (( move > 0 )); then
3247         while (( $# > 0 )); do
3248             mv $verbose "${1%/}" "${1%/}_$current_date"
3249             (( result += $? ))
3250             shift
3251         done
3252     elif (( clean > 0 )); then
3253         if (( $# > 0 )); then
3254             for to_bk in "$@"; do
3255                 rm $verbose -rf "${to_bk%/}"_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z
3256                 (( result += $? ))
3257             done
3258         else
3259             if (( all > 0 )); then
3260                 rm $verbose -rf *_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z(D)
3261             else
3262                 rm $verbose -rf *_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z
3263             fi
3264             (( result += $? ))
3265         fi
3266     fi
3267     return $result
3268 }
3269
3270 #f5# cd to directoy and list files
3271 cl() {
3272     emulate -L zsh
3273     cd $1 && ls -a
3274 }
3275
3276 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
3277 cd() {
3278     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
3279         [[ ! -e ${1:h} ]] && return 1
3280         print "Correcting ${1} to ${1:h}"
3281         builtin cd ${1:h}
3282     else
3283         builtin cd "$@"
3284     fi
3285 }
3286
3287 #f5# Create Directoy and \kbd{cd} to it
3288 mkcd() {
3289     if (( ARGC != 1 )); then
3290         printf 'usage: mkcd <new-directory>\n'
3291         return 1;
3292     fi
3293     if [[ ! -d "$1" ]]; then
3294         command mkdir -p "$1"
3295     else
3296         printf '`%s'\'' already exists: cd-ing.\n' "$1"
3297     fi
3298     builtin cd "$1"
3299 }
3300
3301 #f5# Create temporary directory and \kbd{cd} to it
3302 cdt() {
3303     builtin cd "$(mktemp -d)"
3304     builtin pwd
3305 }
3306
3307 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
3308 accessed() {
3309     emulate -L zsh
3310     print -l -- *(a-${1:-1})
3311 }
3312
3313 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
3314 changed() {
3315     emulate -L zsh
3316     print -l -- *(c-${1:-1})
3317 }
3318
3319 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
3320 modified() {
3321     emulate -L zsh
3322     print -l -- *(m-${1:-1})
3323 }
3324 # modified() was named new() in earlier versions, add an alias for backwards compatibility
3325 check_com new || alias new=modified
3326
3327 # use colors when GNU grep with color-support
3328 if (( $#grep_options > 0 )); then
3329     o=${grep_options:+"${grep_options[*]}"}
3330     #a2# Execute \kbd{grep -{}-color=auto}
3331     alias grep='grep '$o
3332     alias egrep='egrep '$o
3333     unset o
3334 fi
3335
3336 # Translate DE<=>EN
3337 # 'translate' looks up a word in a file with language-to-language
3338 # translations (field separator should be " : "). A typical wordlist looks
3339 # like the following:
3340 #  | english-word : german-translation
3341 # It's also only possible to translate english to german but not reciprocal.
3342 # Use the following oneliner to reverse the sort order:
3343 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3344 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3345 #f5# Translates a word
3346 trans() {
3347     emulate -L zsh
3348     case "$1" in
3349         -[dD]*)
3350             translate -l de-en $2
3351             ;;
3352         -[eE]*)
3353             translate -l en-de $2
3354             ;;
3355         *)
3356             echo "Usage: $0 { -D | -E }"
3357             echo "         -D == German to English"
3358             echo "         -E == English to German"
3359     esac
3360 }
3361
3362 # Usage: simple-extract <file>
3363 # Using option -d deletes the original archive file.
3364 #f5# Smart archive extractor
3365 simple-extract() {
3366     emulate -L zsh
3367     setopt extended_glob noclobber
3368     local ARCHIVE DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
3369     local RC=0
3370     zparseopts -D -E "d=DELETE_ORIGINAL"
3371     for ARCHIVE in "${@}"; do
3372         case $ARCHIVE in
3373             *(tar.bz2|tbz2|tbz))
3374                 DECOMP_CMD="tar -xvjf -"
3375                 USES_STDIN=true
3376                 USES_STDOUT=false
3377                 ;;
3378             *(tar.gz|tgz))
3379                 DECOMP_CMD="tar -xvzf -"
3380                 USES_STDIN=true
3381                 USES_STDOUT=false
3382                 ;;
3383             *(tar.xz|txz|tar.lzma))
3384                 DECOMP_CMD="tar -xvJf -"
3385                 USES_STDIN=true
3386                 USES_STDOUT=false
3387                 ;;
3388             *tar)
3389                 DECOMP_CMD="tar -xvf -"
3390                 USES_STDIN=true
3391                 USES_STDOUT=false
3392                 ;;
3393             *rar)
3394                 DECOMP_CMD="unrar x"
3395                 USES_STDIN=false
3396                 USES_STDOUT=false
3397                 ;;
3398             *lzh)
3399                 DECOMP_CMD="lha x"
3400                 USES_STDIN=false
3401                 USES_STDOUT=false
3402                 ;;
3403             *7z)
3404                 DECOMP_CMD="7z x"
3405                 USES_STDIN=false
3406                 USES_STDOUT=false
3407                 ;;
3408             *(zip|jar))
3409                 DECOMP_CMD="unzip"
3410                 USES_STDIN=false
3411                 USES_STDOUT=false
3412                 ;;
3413             *deb)
3414                 DECOMP_CMD="ar -x"
3415                 USES_STDIN=false
3416                 USES_STDOUT=false
3417                 ;;
3418             *bz2)
3419                 DECOMP_CMD="bzip2 -d -c -"
3420                 USES_STDIN=true
3421                 USES_STDOUT=true
3422                 ;;
3423             *(gz|Z))
3424                 DECOMP_CMD="gzip -d -c -"
3425                 USES_STDIN=true
3426                 USES_STDOUT=true
3427                 ;;
3428             *(xz|lzma))
3429                 DECOMP_CMD="xz -d -c -"
3430                 USES_STDIN=true
3431                 USES_STDOUT=true
3432                 ;;
3433             *)
3434                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
3435                 RC=$((RC+1))
3436                 continue
3437                 ;;
3438         esac
3439
3440         if ! check_com ${DECOMP_CMD[(w)1]}; then
3441             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
3442             RC=$((RC+2))
3443             continue
3444         fi
3445
3446         GZTARGET="${ARCHIVE:t:r}"
3447         if [[ -f $ARCHIVE ]] ; then
3448
3449             print "Extracting '$ARCHIVE' ..."
3450             if $USES_STDIN; then
3451                 if $USES_STDOUT; then
3452                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
3453                 else
3454                     ${=DECOMP_CMD} < "$ARCHIVE"
3455                 fi
3456             else
3457                 if $USES_STDOUT; then
3458                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
3459                 else
3460                     ${=DECOMP_CMD} "$ARCHIVE"
3461                 fi
3462             fi
3463             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
3464
3465         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
3466             if check_com curl; then
3467                 WGET_CMD="curl -L -s -o -"
3468             elif check_com wget; then
3469                 WGET_CMD="wget -q -O -"
3470             elif check_com fetch; then
3471                 WGET_CMD="fetch -q -o -"
3472             else
3473                 print "ERROR: neither wget, curl nor fetch is installed" >&2
3474                 RC=$((RC+4))
3475                 continue
3476             fi
3477             print "Downloading and Extracting '$ARCHIVE' ..."
3478             if $USES_STDIN; then
3479                 if $USES_STDOUT; then
3480                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
3481                     RC=$((RC+$?))
3482                 else
3483                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
3484                     RC=$((RC+$?))
3485                 fi
3486             else
3487                 if $USES_STDOUT; then
3488                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
3489                 else
3490                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
3491                 fi
3492             fi
3493
3494         else
3495             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
3496             RC=$((RC+8))
3497         fi
3498     done
3499     return $RC
3500 }
3501
3502 __archive_or_uri()
3503 {
3504     _alternative \
3505         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
3506         '_urls:Remote Archives:_urls'
3507 }
3508
3509 _simple_extract()
3510 {
3511     _arguments \
3512         '-d[delete original archivefile after extraction]' \
3513         '*:Archive Or Uri:__archive_or_uri'
3514 }
3515 compdef _simple_extract simple-extract
3516 alias se=simple-extract
3517
3518 #f5# Set all ulimit parameters to \kbd{unlimited}
3519 allulimit() {
3520     ulimit -c unlimited
3521     ulimit -d unlimited
3522     ulimit -f unlimited
3523     ulimit -l unlimited
3524     ulimit -n unlimited
3525     ulimit -s unlimited
3526     ulimit -t unlimited
3527 }
3528
3529 #f5# Change the xterm title from within GNU-screen
3530 xtrename() {
3531     emulate -L zsh
3532     if [[ $1 != "-f" ]] ; then
3533         if [[ -z ${DISPLAY} ]] ; then
3534             printf 'xtrename only makes sense in X11.\n'
3535             return 1
3536         fi
3537     else
3538         shift
3539     fi
3540     if [[ -z $1 ]] ; then
3541         printf 'usage: xtrename [-f] "title for xterm"\n'
3542         printf '  renames the title of xterm from _within_ screen.\n'
3543         printf '  also works without screen.\n'
3544         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3545         return 0
3546     fi
3547     print -n "\eP\e]0;${1}\C-G\e\\"
3548     return 0
3549 }
3550
3551 # Create small urls via http://goo.gl using curl(1).
3552 # API reference: https://code.google.com/apis/urlshortener/
3553 function zurl() {
3554     emulate -L zsh
3555     setopt extended_glob
3556
3557     if [[ -z $1 ]]; then
3558         print "USAGE: zurl <URL>"
3559         return 1
3560     fi
3561
3562     local PN url prog api json contenttype item
3563     local -a data
3564     PN=$0
3565     url=$1
3566
3567     # Prepend 'http://' to given URL where necessary for later output.
3568     if [[ ${url} != http(s|)://* ]]; then
3569         url='http://'${url}
3570     fi
3571
3572     if check_com -c curl; then
3573         prog=curl
3574     else
3575         print "curl is not available, but mandatory for ${PN}. Aborting."
3576         return 1
3577     fi
3578     api='https://www.googleapis.com/urlshortener/v1/url'
3579     contenttype="Content-Type: application/json"
3580     json="{\"longUrl\": \"${url}\"}"
3581     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
3582     # Parse the response
3583     for item in "${data[@]}"; do
3584         case "$item" in
3585             ' '#'"id":'*)
3586                 item=${item#*: \"}
3587                 item=${item%\",*}
3588                 printf '%s\n' "$item"
3589                 return 0
3590                 ;;
3591         esac
3592     done
3593     return 1
3594 }
3595
3596 #f2# Find history events by search pattern and list them by date.
3597 whatwhen()  {
3598     emulate -L zsh
3599     local usage help ident format_l format_s first_char remain first last
3600     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3601     help='Use `whatwhen -h'\'' for further explanations.'
3602     ident=${(l,${#${:-Usage: }},, ,)}
3603     format_l="${ident}%s\t\t\t%s\n"
3604     format_s="${format_l//(\\t)##/\\t}"
3605     # Make the first char of the word to search for case
3606     # insensitive; e.g. [aA]
3607     first_char=[${(L)1[1]}${(U)1[1]}]
3608     remain=${1[2,-1]}
3609     # Default search range is `-100'.
3610     first=${2:-\-100}
3611     # Optional, just used for `<first> <last>' given.
3612     last=$3
3613     case $1 in
3614         ("")
3615             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3616             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3617         ;;
3618         (-h)
3619             printf '%s\n\n' ${usage}
3620             print 'OPTIONS:'
3621             printf $format_l '-h' 'show help text'
3622             print '\f'
3623             print 'SEARCH RANGE:'
3624             printf $format_l "'0'" 'the whole history,'
3625             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
3626             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
3627             printf '\n%s\n' 'EXAMPLES:'
3628             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
3629             printf $format_l 'whatwhen zsh -250'
3630             printf $format_l 'whatwhen foo 1 99'
3631         ;;
3632         (\?)
3633             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3634         ;;
3635         (*)
3636             # -l list results on stout rather than invoking $EDITOR.
3637             # -i Print dates as in YYYY-MM-DD.
3638             # -m Search for a - quoted - pattern within the history.
3639             fc -li -m "*${first_char}${remain}*" $first $last
3640         ;;
3641     esac
3642 }
3643
3644 # mercurial related stuff
3645 if check_com -c hg ; then
3646     # gnu like diff for mercurial
3647     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
3648     #f5# GNU like diff for mercurial
3649     hgdi() {
3650         emulate -L zsh
3651         local i
3652         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
3653     }
3654
3655     # build debian package
3656     #a2# Alias for \kbd{hg-buildpackage}
3657     alias hbp='hg-buildpackage'
3658
3659     # execute commands on the versioned patch-queue from the current repos
3660     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
3661
3662     # diffstat for specific version of a mercurial repository
3663     #   hgstat      => display diffstat between last revision and tip
3664     #   hgstat 1234 => display diffstat between revision 1234 and tip
3665     #f5# Diffstat for specific version of a mercurial repos
3666     hgstat() {
3667         emulate -L zsh
3668         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
3669     }
3670
3671 fi # end of check whether we have the 'hg'-executable
3672
3673 # grml-small cleanups
3674
3675 # The following is used to remove zsh-config-items that do not work
3676 # in grml-small by default.
3677 # If you do not want these adjustments (for whatever reason), set
3678 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
3679 # sources if it is there).
3680
3681 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
3682
3683     unset abk[V]
3684     unalias    'V'      &> /dev/null
3685     unfunction vman     &> /dev/null
3686     unfunction viless   &> /dev/null
3687     unfunction 2html    &> /dev/null
3688
3689     # manpages are not in grmlsmall
3690     unfunction manzsh   &> /dev/null
3691     unfunction man2     &> /dev/null
3692
3693 fi
3694
3695 zrclocal
3696
3697 ## genrefcard.pl settings
3698
3699 ### doc strings for external functions from files
3700 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
3701
3702 ### example: split functions-search 8,16,24,32
3703 #@# split functions-search 8
3704
3705 ## END OF FILE #################################################################
3706 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
3707 # Local variables:
3708 # mode: sh
3709 # End: