etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is437(){
 148     [[ $ZSH_VERSION == 4.3.<7->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 is439(){
 154     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 155                                  || $ZSH_VERSION == <5->* ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running grml
 160 isgrml(){
 161     [[ -f /etc/grml_version ]] && return 0
 162     return 1
 163 }
 164
 165 #f1# Checks whether or not you're running a grml cd
 166 isgrmlcd(){
 167     [[ -f /etc/grml_cd ]] && return 0
 168     return 1
 169 }
 170
 171 if isgrml ; then
 172 #f1# Checks whether or not you're running grml-small
 173     isgrmlsmall() {
 174         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 175             return 0
 176         fi
 177         return 1
 178     }
 179 else
 180     isgrmlsmall() { return 1 }
 181 fi
 182
 183 GRML_OSTYPE=$(uname -s)
 184
 185 islinux(){
 186     [[ $GRML_OSTYPE == "Linux" ]]
 187 }
 188
 189 isdarwin(){
 190     [[ $GRML_OSTYPE == "Darwin" ]]
 191 }
 192
 193 isfreebsd(){
 194     [[ $GRML_OSTYPE == "FreeBSD" ]]
 195 }
 196
 197 isopenbsd(){
 198     [[ $GRML_OSTYPE == "OpenBSD" ]]
 199 }
 200
 201 issolaris(){
 202     [[ $GRML_OSTYPE == "SunOS" ]]
 203 }
 204
 205 #f1# are we running within an utf environment?
 206 isutfenv() {
 207     case "$LANG $CHARSET $LANGUAGE" in
 208         *utf*) return 0 ;;
 209         *UTF*) return 0 ;;
 210         *)     return 1 ;;
 211     esac
 212 }
 213
 214 # check for user, if not running as root set $SUDO to sudo
 215 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 216
 217 # change directory to home on first invocation of zsh
 218 # important for rungetty -> autologin
 219 # Thanks go to Bart Schaefer!
 220 isgrml && checkhome() {
 221     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 222         export ALREADY_DID_CD_HOME=$HOME
 223         cd
 224     fi
 225 }
 226
 227 # check for zsh v3.1.7+
 228
 229 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 230      || ${ZSH_VERSION} == 3.<2->.<->*    \
 231      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 232
 233     printf '-!-\n'
 234     printf '-!- In this configuration we try to make use of features, that only\n'
 235     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 236     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 237     printf '-!- advanced features in all supported versions.\n'
 238     printf '-!-\n'
 239     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 240     printf '-!-\n'
 241     printf '-!- While this *may* work, it might as well fail.\n'
 242     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 243     printf '-!-\n'
 244     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 245     printf '-!- If it does today, you'\''ve been lucky.\n'
 246     printf '-!-\n'
 247     printf '-!- Ye been warned!\n'
 248     printf '-!-\n'
 249
 250     function zstyle() { : }
 251 fi
 252
 253 # autoload wrapper - use this one instead of autoload directly
 254 # We need to define this function as early as this, because autoloading
 255 # 'is-at-least()' needs it.
 256 function zrcautoload() {
 257     emulate -L zsh
 258     setopt extended_glob
 259     local fdir ffile
 260     local -i ffound
 261
 262     ffile=$1
 263     (( ffound = 0 ))
 264     for fdir in ${fpath} ; do
 265         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 266     done
 267
 268     (( ffound == 0 )) && return 1
 269     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 270         autoload -U ${ffile} || return 1
 271     else
 272         autoload ${ffile} || return 1
 273     fi
 274     return 0
 275 }
 276
 277 # The following is the ‘add-zsh-hook’ function from zsh upstream. It is
 278 # included here to make the setup work with older versions of zsh (prior to
 279 # 4.3.7) in which this function had a bug that triggers annoying errors during
 280 # shell startup. This is exactly upstreams code from f0068edb4888a4d8fe94def,
 281 # with just a few adjustments in coding style to make the function look more
 282 # compact. This definition can be removed as soon as we raise the minimum
 283 # version requirement to 4.3.7 or newer.
 284 function add-zsh-hook() {
 285     # Add to HOOK the given FUNCTION.
 286     # HOOK is one of chpwd, precmd, preexec, periodic, zshaddhistory,
 287     # zshexit, zsh_directory_name (the _functions subscript is not required).
 288     #
 289     # With -d, remove the function from the hook instead; delete the hook
 290     # variable if it is empty.
 291     #
 292     # -D behaves like -d, but pattern characters are active in the function
 293     # name, so any matching function will be deleted from the hook.
 294     #
 295     # Without -d, the FUNCTION is marked for autoload; -U is passed down to
 296     # autoload if that is given, as are -z and -k. (This is harmless if the
 297     # function is actually defined inline.)
 298     emulate -L zsh
 299     local -a hooktypes
 300     hooktypes=(
 301         chpwd precmd preexec periodic zshaddhistory zshexit
 302         zsh_directory_name
 303     )
 304     local usage="Usage: $0 hook function\nValid hooks are:\n  $hooktypes"
 305     local opt
 306     local -a autoopts
 307     integer del list help
 308     while getopts "dDhLUzk" opt; do
 309         case $opt in
 310         (d) del=1 ;;
 311         (D) del=2 ;;
 312         (h) help=1 ;;
 313         (L) list=1 ;;
 314         ([Uzk]) autoopts+=(-$opt) ;;
 315         (*) return 1 ;;
 316         esac
 317     done
 318     shift $(( OPTIND - 1 ))
 319     if (( list )); then
 320         typeset -mp "(${1:-${(@j:|:)hooktypes}})_functions"
 321         return $?
 322     elif (( help || $# != 2 || ${hooktypes[(I)$1]} == 0 )); then
 323         print -u$(( 2 - help )) $usage
 324         return $(( 1 - help ))
 325     fi
 326     local hook="${1}_functions"
 327     local fn="$2"
 328     if (( del )); then
 329         # delete, if hook is set
 330         if (( ${(P)+hook} )); then
 331             if (( del == 2 )); then
 332                 set -A $hook ${(P)hook:#${~fn}}
 333             else
 334                 set -A $hook ${(P)hook:#$fn}
 335             fi
 336             # unset if no remaining entries --- this can give better
 337             # performance in some cases
 338             if (( ! ${(P)#hook} )); then
 339                 unset $hook
 340             fi
 341         fi
 342     else
 343         if (( ${(P)+hook} )); then
 344             if (( ${${(P)hook}[(I)$fn]} == 0 )); then
 345                 set -A $hook ${(P)hook} $fn
 346             fi
 347         else
 348             set -A $hook $fn
 349         fi
 350         autoload $autoopts -- $fn
 351     fi
 352 }
 353
 354 # Load is-at-least() for more precise version checks Note that this test will
 355 # *always* fail, if the is-at-least function could not be marked for
 356 # autoloading.
 357 zrcautoload is-at-least || is-at-least() { return 1 }
 358
 359 # set some important options (as early as possible)
 360
 361 # append history list to the history file; this is the default but we make sure
 362 # because it's required for share_history.
 363 setopt append_history
 364
 365 # import new commands from the history file also in other zsh-session
 366 is4 && setopt share_history
 367
 368 # save each command's beginning timestamp and the duration to the history file
 369 setopt extended_history
 370
 371 # If a new command line being added to the history list duplicates an older
 372 # one, the older command is removed from the list
 373 is4 && setopt histignorealldups
 374
 375 # remove command lines from the history list when the first character on the
 376 # line is a space
 377 setopt histignorespace
 378
 379 # if a command is issued that can't be executed as a normal command, and the
 380 # command is the name of a directory, perform the cd command to that directory.
 381 setopt auto_cd
 382
 383 # in order to use #, ~ and ^ for filename generation grep word
 384 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 385 # don't forget to quote '^', '~' and '#'!
 386 setopt extended_glob
 387
 388 # display PID when suspending processes as well
 389 setopt longlistjobs
 390
 391 # report the status of backgrounds jobs immediately
 392 setopt notify
 393
 394 # whenever a command completion is attempted, make sure the entire command path
 395 # is hashed first.
 396 setopt hash_list_all
 397
 398 # not just at the end
 399 setopt completeinword
 400
 401 # Don't send SIGHUP to background processes when the shell exits.
 402 setopt nohup
 403
 404 # make cd push the old directory onto the directory stack.
 405 setopt auto_pushd
 406
 407 # avoid "beep"ing
 408 setopt nobeep
 409
 410 # don't push the same dir twice.
 411 setopt pushd_ignore_dups
 412
 413 # * shouldn't match dotfiles. ever.
 414 setopt noglobdots
 415
 416 # use zsh style word splitting
 417 setopt noshwordsplit
 418
 419 # don't error out when unset parameters are used
 420 setopt unset
 421
 422 # setting some default values
 423 NOCOR=${NOCOR:-0}
 424 NOMENU=${NOMENU:-0}
 425 NOPRECMD=${NOPRECMD:-0}
 426 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 427 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 428 GRML_DISPLAY_BATTERY=${GRML_DISPLAY_BATTERY:-${BATTERY:-0}}
 429 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 430 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 431
 432 typeset -ga ls_options
 433 typeset -ga grep_options
 434 if ls --color=auto / >/dev/null 2>&1; then
 435     ls_options+=( --color=auto )
 436 elif ls -G / >/dev/null 2>&1; then
 437     ls_options+=( -G )
 438 fi
 439 if grep --color=auto -q "a" <<< "a" >/dev/null 2>&1; then
 440     grep_options+=( --color=auto )
 441 fi
 442
 443 # utility functions
 444 # this function checks if a command exists and returns either true
 445 # or false. This avoids using 'which' and 'whence', which will
 446 # avoid problems with aliases for which on certain weird systems. :-)
 447 # Usage: check_com [-c|-g] word
 448 #   -c  only checks for external commands
 449 #   -g  does the usual tests and also checks for global aliases
 450 check_com() {
 451     emulate -L zsh
 452     local -i comonly gatoo
 453     comonly=0
 454     gatoo=0
 455
 456     if [[ $1 == '-c' ]] ; then
 457         comonly=1
 458         shift 1
 459     elif [[ $1 == '-g' ]] ; then
 460         gatoo=1
 461         shift 1
 462     fi
 463
 464     if (( ${#argv} != 1 )) ; then
 465         printf 'usage: check_com [-c|-g] <command>\n' >&2
 466         return 1
 467     fi
 468
 469     if (( comonly > 0 )) ; then
 470         (( ${+commands[$1]}  )) && return 0
 471         return 1
 472     fi
 473
 474     if     (( ${+commands[$1]}    )) \
 475         || (( ${+functions[$1]}   )) \
 476         || (( ${+aliases[$1]}     )) \
 477         || (( ${+reswords[(r)$1]} )) ; then
 478         return 0
 479     fi
 480
 481     if (( gatoo > 0 )) && (( ${+galiases[$1]} )) ; then
 482         return 0
 483     fi
 484
 485     return 1
 486 }
 487
 488 # creates an alias and precedes the command with
 489 # sudo if $EUID is not zero.
 490 salias() {
 491     emulate -L zsh
 492     local only=0 ; local multi=0
 493     local key val
 494     while getopts ":hao" opt; do
 495         case $opt in
 496             o) only=1 ;;
 497             a) multi=1 ;;
 498             h)
 499                 printf 'usage: salias [-hoa] <alias-expression>\n'
 500                 printf '  -h      shows this help text.\n'
 501                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 502                 printf '          be careful using this option.\n'
 503                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 504                 return 0
 505                 ;;
 506             *) salias -h >&2; return 1 ;;
 507         esac
 508     done
 509     shift "$((OPTIND-1))"
 510
 511     if (( ${#argv} > 1 )) ; then
 512         printf 'Too many arguments %s\n' "${#argv}"
 513         return 1
 514     fi
 515
 516     key="${1%%\=*}" ;  val="${1#*\=}"
 517     if (( EUID == 0 )) && (( only == 0 )); then
 518         alias -- "${key}=${val}"
 519     elif (( EUID > 0 )) ; then
 520         (( multi > 0 )) && val="${val// ; / ; sudo }"
 521         alias -- "${key}=sudo ${val}"
 522     fi
 523
 524     return 0
 525 }
 526
 527 # Check if we can read given files and source those we can.
 528 xsource() {
 529     if (( ${#argv} < 1 )) ; then
 530         printf 'usage: xsource FILE(s)...\n' >&2
 531         return 1
 532     fi
 533
 534     while (( ${#argv} > 0 )) ; do
 535         [[ -r "$1" ]] && source "$1"
 536         shift
 537     done
 538     return 0
 539 }
 540
 541 # Check if we can read a given file and 'cat(1)' it.
 542 xcat() {
 543     emulate -L zsh
 544     if (( ${#argv} != 1 )) ; then
 545         printf 'usage: xcat FILE\n' >&2
 546         return 1
 547     fi
 548
 549     [[ -r $1 ]] && cat $1
 550     return 0
 551 }
 552
 553 # Remove these functions again, they are of use only in these
 554 # setup files. This should be called at the end of .zshrc.
 555 xunfunction() {
 556     emulate -L zsh
 557     local -a funcs
 558     local func
 559     funcs=(salias xcat xsource xunfunction zrcautoload zrcautozle)
 560     for func in $funcs ; do
 561         [[ -n ${functions[$func]} ]] \
 562             && unfunction $func
 563     done
 564     return 0
 565 }
 566
 567 # this allows us to stay in sync with grml's zshrc and put own
 568 # modifications in ~/.zshrc.local
 569 zrclocal() {
 570     xsource "/etc/zsh/zshrc.local"
 571     xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
 572     return 0
 573 }
 574
 575 # locale setup
 576 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 577     xsource "/etc/default/locale"
 578 fi
 579
 580 for var in LANG LC_ALL LC_MESSAGES ; do
 581     [[ -n ${(P)var} ]] && export $var
 582 done
 583 builtin unset -v var
 584
 585 # set some variables
 586 if check_com -c vim ; then
 587 #v#
 588     export EDITOR=${EDITOR:-vim}
 589 else
 590     export EDITOR=${EDITOR:-vi}
 591 fi
 592
 593 #v#
 594 export PAGER=${PAGER:-less}
 595
 596 #v#
 597 export MAIL=${MAIL:-/var/mail/$USER}
 598
 599 # color setup for ls:
 600 check_com -c dircolors && eval $(dircolors -b)
 601 # color setup for ls on OS X / FreeBSD:
 602 isdarwin && export CLICOLOR=1
 603 isfreebsd && export CLICOLOR=1
 604
 605 # do MacPorts setup on darwin
 606 if isdarwin && [[ -d /opt/local ]]; then
 607     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 608     # zshenv.
 609     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 610     MANPATH="/opt/local/share/man:$MANPATH"
 611 fi
 612 # do Fink setup on darwin
 613 isdarwin && xsource /sw/bin/init.sh
 614
 615 # load our function and completion directories
 616 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 617     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 618     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 619         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 620             zrcautoload ${func:t}
 621         done
 622     fi
 623 done
 624 unset fdir func
 625
 626 # support colors in less
 627 export LESS_TERMCAP_mb=$'\E[01;31m'
 628 export LESS_TERMCAP_md=$'\E[01;31m'
 629 export LESS_TERMCAP_me=$'\E[0m'
 630 export LESS_TERMCAP_se=$'\E[0m'
 631 export LESS_TERMCAP_so=$'\E[01;44;33m'
 632 export LESS_TERMCAP_ue=$'\E[0m'
 633 export LESS_TERMCAP_us=$'\E[01;32m'
 634
 635 # mailchecks
 636 MAILCHECK=30
 637
 638 # report about cpu-/system-/user-time of command if running longer than
 639 # 5 seconds
 640 REPORTTIME=5
 641
 642 # watch for everyone but me and root
 643 watch=(notme root)
 644
 645 # automatically remove duplicates from these arrays
 646 typeset -U path cdpath fpath manpath
 647
 648 # Load a few modules
 649 is4 && \
 650 for mod in parameter complist deltochar mathfunc ; do
 651     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 652 done && builtin unset -v mod
 653
 654 # autoload zsh modules when they are referenced
 655 if is4 ; then
 656     zmodload -a  zsh/stat    zstat
 657     zmodload -a  zsh/zpty    zpty
 658     zmodload -ap zsh/mapfile mapfile
 659 fi
 660
 661 # completion system
 662 COMPDUMPFILE=${COMPDUMPFILE:-${ZDOTDIR:-${HOME}}/.zcompdump}
 663 if zrcautoload compinit ; then
 664     compinit -d ${COMPDUMPFILE} || print 'Notice: no compinit available :('
 665 else
 666     print 'Notice: no compinit available :('
 667     function compdef { }
 668 fi
 669
 670 # completion system
 671
 672 # called later (via is4 && grmlcomp)
 673 # note: use 'zstyle' for getting current settings
 674 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
 675 grmlcomp() {
 676     # TODO: This could use some additional information
 677
 678     # Make sure the completion system is initialised
 679     (( ${+_comps} )) || return 1
 680
 681     # allow one error for every three characters typed in approximate completer
 682     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
 683
 684     # don't complete backup files as executables
 685     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
 686
 687     # start menu completion only if it could find no unambiguous initial string
 688     zstyle ':completion:*:correct:*'       insert-unambiguous true
 689     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
 690     zstyle ':completion:*:correct:*'       original true
 691
 692     # activate color-completion
 693     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
 694
 695     # format on completion
 696     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
 697
 698     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
 699     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
 700
 701     # insert all expansions for expand completer
 702     zstyle ':completion:*:expand:*'        tag-order all-expansions
 703     zstyle ':completion:*:history-words'   list false
 704
 705     # activate menu
 706     zstyle ':completion:*:history-words'   menu yes
 707
 708     # ignore duplicate entries
 709     zstyle ':completion:*:history-words'   remove-all-dups yes
 710     zstyle ':completion:*:history-words'   stop yes
 711
 712     # match uppercase from lowercase
 713     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
 714
 715     # separate matches into groups
 716     zstyle ':completion:*:matches'         group 'yes'
 717     zstyle ':completion:*'                 group-name ''
 718
 719     if [[ "$NOMENU" -eq 0 ]] ; then
 720         # if there are more than 5 options allow selecting from a menu
 721         zstyle ':completion:*'               menu select=5
 722     else
 723         # don't use any menus at all
 724         setopt no_auto_menu
 725     fi
 726
 727     zstyle ':completion:*:messages'        format '%d'
 728     zstyle ':completion:*:options'         auto-description '%d'
 729
 730     # describe options in full
 731     zstyle ':completion:*:options'         description 'yes'
 732
 733     # on processes completion complete all user processes
 734     zstyle ':completion:*:processes'       command 'ps -au$USER'
 735
 736     # offer indexes before parameters in subscripts
 737     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
 738
 739     # provide verbose completion information
 740     zstyle ':completion:*'                 verbose true
 741
 742     # recent (as of Dec 2007) zsh versions are able to provide descriptions
 743     # for commands (read: 1st word in the line) that it will list for the user
 744     # to choose from. The following disables that, because it's not exactly fast.
 745     zstyle ':completion:*:-command-:*:'    verbose false
 746
 747     # set format for warnings
 748     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
 749
 750     # define files to ignore for zcompile
 751     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
 752     zstyle ':completion:correct:'          prompt 'correct to: %e'
 753
 754     # Ignore completion functions for commands you don't have:
 755     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
 756
 757     # Provide more processes in completion of programs like killall:
 758     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
 759
 760     # complete manual by their section
 761     zstyle ':completion:*:manuals'    separate-sections true
 762     zstyle ':completion:*:manuals.*'  insert-sections   true
 763     zstyle ':completion:*:man:*'      menu yes select
 764
 765     # Search path for sudo completion
 766     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
 767                                                /usr/local/bin  \
 768                                                /usr/sbin       \
 769                                                /usr/bin        \
 770                                                /sbin           \
 771                                                /bin            \
 772                                                /usr/X11R6/bin
 773
 774     # provide .. as a completion
 775     zstyle ':completion:*' special-dirs ..
 776
 777     # run rehash on completion so new installed program are found automatically:
 778     _force_rehash() {
 779         (( CURRENT == 1 )) && rehash
 780         return 1
 781     }
 782
 783     ## correction
 784     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
 785     if [[ "$NOCOR" -gt 0 ]] ; then
 786         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
 787         setopt nocorrect
 788     else
 789         # try to be smart about when to use what completer...
 790         setopt correct
 791         zstyle -e ':completion:*' completer '
 792             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
 793                 _last_try="$HISTNO$BUFFER$CURSOR"
 794                 reply=(_complete _match _ignored _prefix _files)
 795             else
 796                 if [[ $words[1] == (rm|mv) ]] ; then
 797                     reply=(_complete _files)
 798                 else
 799                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
 800                 fi
 801             fi'
 802     fi
 803
 804     # command for process lists, the local web server details and host completion
 805     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
 806
 807     # Some functions, like _apt and _dpkg, are very slow. We can use a cache in
 808     # order to speed things up
 809     if [[ ${GRML_COMP_CACHING:-yes} == yes ]]; then
 810         GRML_COMP_CACHE_DIR=${GRML_COMP_CACHE_DIR:-${ZDOTDIR:-$HOME}/.cache}
 811         if [[ ! -d ${GRML_COMP_CACHE_DIR} ]]; then
 812             command mkdir -p "${GRML_COMP_CACHE_DIR}"
 813         fi
 814         zstyle ':completion:*' use-cache  yes
 815         zstyle ':completion:*:complete:*' cache-path "${GRML_COMP_CACHE_DIR}"
 816     fi
 817
 818     # host completion
 819     if is42 ; then
 820         [[ -r ~/.ssh/config ]] && _ssh_config_hosts=(${${(s: :)${(ps:\t:)${${(@M)${(f)"$(<$HOME/.ssh/config)"}:#Host *}#Host }}}:#*[*?]*}) || _ssh_config_hosts=()
 821         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
 822         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
 823     else
 824         _ssh_config_hosts=()
 825         _ssh_hosts=()
 826         _etc_hosts=()
 827     fi
 828     hosts=(
 829         $(hostname)
 830         "$_ssh_config_hosts[@]"
 831         "$_ssh_hosts[@]"
 832         "$_etc_hosts[@]"
 833         localhost
 834     )
 835     zstyle ':completion:*:hosts' hosts $hosts
 836     # TODO: so, why is this here?
 837     #  zstyle '*' hosts $hosts
 838
 839     # use generic completion system for programs not yet defined; (_gnu_generic works
 840     # with commands that provide a --help option with "standard" gnu-like output.)
 841     for compcom in cp deborphan df feh fetchipac gpasswd head hnb ipacsum mv \
 842                    pal stow uname ; do
 843         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
 844     done; unset compcom
 845
 846     # see upgrade function in this file
 847     compdef _hosts upgrade
 848 }
 849
 850 # Keyboard setup: The following is based on the same code, we wrote for
 851 # debian's setup. It ensures the terminal is in the right mode, when zle is
 852 # active, so the values from $terminfo are valid. Therefore, this setup should
 853 # work on all systems, that have support for `terminfo'. It also requires the
 854 # zsh in use to have the `zsh/terminfo' module built.
 855 #
 856 # If you are customising your `zle-line-init()' or `zle-line-finish()'
 857 # functions, make sure you call the following utility functions in there:
 858 #
 859 #     - zle-line-init():      zle-smkx
 860 #     - zle-line-finish():    zle-rmkx
 861
 862 # Use emacs-like key bindings by default:
 863 bindkey -e
 864
 865 # Custom widgets:
 866
 867 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 868 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 869 beginning-or-end-of-somewhere() {
 870     local hno=$HISTNO
 871     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 872       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 873         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 874     else
 875         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 876         if (( HISTNO != hno )); then
 877             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 878         fi
 879     fi
 880 }
 881 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 882 zle -N end-of-somewhere beginning-or-end-of-somewhere
 883
 884 # add a command line to the shells history without executing it
 885 commit-to-history() {
 886     print -s ${(z)BUFFER}
 887     zle send-break
 888 }
 889 zle -N commit-to-history
 890
 891 # only slash should be considered as a word separator:
 892 slash-backward-kill-word() {
 893     local WORDCHARS="${WORDCHARS:s@/@}"
 894     # zle backward-word
 895     zle backward-kill-word
 896 }
 897 zle -N slash-backward-kill-word
 898
 899 # a generic accept-line wrapper
 900
 901 # This widget can prevent unwanted autocorrections from command-name
 902 # to _command-name, rehash automatically on enter and call any number
 903 # of builtin and user-defined widgets in different contexts.
 904 #
 905 # For a broader description, see:
 906 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 907 #
 908 # The code is imported from the file 'zsh/functions/accept-line' from
 909 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 910 # distributed under the same terms as zsh itself.
 911
 912 # A newly added command will may not be found or will cause false
 913 # correction attempts, if you got auto-correction set. By setting the
 914 # following style, we force accept-line() to rehash, if it cannot
 915 # find the first word on the command line in the $command[] hash.
 916 zstyle ':acceptline:*' rehash true
 917
 918 function Accept-Line() {
 919     setopt localoptions noksharrays
 920     local -a subs
 921     local -xi aldone
 922     local sub
 923     local alcontext=${1:-$alcontext}
 924
 925     zstyle -a ":acceptline:${alcontext}" actions subs
 926
 927     (( ${#subs} < 1 )) && return 0
 928
 929     (( aldone = 0 ))
 930     for sub in ${subs} ; do
 931         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 932         zle ${sub}
 933
 934         (( aldone > 0 )) && break
 935     done
 936 }
 937
 938 function Accept-Line-getdefault() {
 939     emulate -L zsh
 940     local default_action
 941
 942     zstyle -s ":acceptline:${alcontext}" default_action default_action
 943     case ${default_action} in
 944         ((accept-line|))
 945             printf ".accept-line"
 946             ;;
 947         (*)
 948             printf ${default_action}
 949             ;;
 950     esac
 951 }
 952
 953 function Accept-Line-HandleContext() {
 954     zle Accept-Line
 955
 956     default_action=$(Accept-Line-getdefault)
 957     zstyle -T ":acceptline:${alcontext}" call_default \
 958         && zle ${default_action}
 959 }
 960
 961 function accept-line() {
 962     setopt localoptions noksharrays
 963     local -a cmdline
 964     local -x alcontext
 965     local buf com fname format msg default_action
 966
 967     alcontext='default'
 968     buf="${BUFFER}"
 969     cmdline=(${(z)BUFFER})
 970     com="${cmdline[1]}"
 971     fname="_${com}"
 972
 973     Accept-Line 'preprocess'
 974
 975     zstyle -t ":acceptline:${alcontext}" rehash \
 976         && [[ -z ${commands[$com]} ]]           \
 977         && rehash
 978
 979     if    [[ -n ${com}               ]] \
 980        && [[ -n ${reswords[(r)$com]} ]] \
 981        || [[ -n ${aliases[$com]}     ]] \
 982        || [[ -n ${functions[$com]}   ]] \
 983        || [[ -n ${builtins[$com]}    ]] \
 984        || [[ -n ${commands[$com]}    ]] ; then
 985
 986         # there is something sensible to execute, just do it.
 987         alcontext='normal'
 988         Accept-Line-HandleContext
 989
 990         return
 991     fi
 992
 993     if    [[ -o correct              ]] \
 994        || [[ -o correctall           ]] \
 995        && [[ -n ${functions[$fname]} ]] ; then
 996
 997         # nothing there to execute but there is a function called
 998         # _command_name; a completion widget. Makes no sense to
 999         # call it on the commandline, but the correct{,all} options
1000         # will ask for it nevertheless, so warn the user.
1001         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
1002             # Okay, we warned the user before, he called us again,
1003             # so have it his way.
1004             alcontext='force'
1005             Accept-Line-HandleContext
1006
1007             return
1008         fi
1009
1010         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
1011             alcontext='normal'
1012             Accept-Line-HandleContext
1013         else
1014             # prepare warning message for the user, configurable via zstyle.
1015             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
1016
1017             if [[ -z ${msg} ]] ; then
1018                 msg="%c will not execute and completion %f exists."
1019             fi
1020
1021             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
1022
1023             zle -M -- "${msg}"
1024         fi
1025         return
1026     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
1027         # If we are here, the commandline contains something that is not
1028         # executable, which is neither subject to _command_name correction
1029         # and is not empty. might be a variable assignment
1030         alcontext='misc'
1031         Accept-Line-HandleContext
1032
1033         return
1034     fi
1035
1036     # If we got this far, the commandline only contains whitespace, or is empty.
1037     alcontext='empty'
1038     Accept-Line-HandleContext
1039 }
1040
1041 zle -N accept-line
1042 zle -N Accept-Line
1043 zle -N Accept-Line-HandleContext
1044
1045 # power completion / abbreviation expansion / buffer expansion
1046 # see http://zshwiki.org/home/examples/zleiab for details
1047 # less risky than the global aliases but powerful as well
1048 # just type the abbreviation key and afterwards 'ctrl-x .' to expand it
1049 declare -A abk
1050 setopt extendedglob
1051 setopt interactivecomments
1052 abk=(
1053 #   key   # value                  (#d additional doc string)
1054 #A# start
1055     '...'  '../..'
1056     '....' '../../..'
1057     'BG'   '& exit'
1058     'C'    '| wc -l'
1059     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
1060     'H'    '| head'
1061     'Hl'   ' --help |& less -r'    #d (Display help in pager)
1062     'L'    '| less'
1063     'LL'   '|& less -r'
1064     'M'    '| most'
1065     'N'    '&>/dev/null'           #d (No Output)
1066     'R'    '| tr A-z N-za-m'       #d (ROT13)
1067     'SL'   '| sort | less'
1068     'S'    '| sort -u'
1069     'T'    '| tail'
1070     'V'    '|& vim -'
1071 #A# end
1072     'co'   './configure && make && sudo make install'
1073 )
1074
1075 zleiab() {
1076     emulate -L zsh
1077     setopt extendedglob
1078     local MATCH
1079
1080     LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
1081     LBUFFER+=${abk[$MATCH]:-$MATCH}
1082 }
1083
1084 zle -N zleiab
1085
1086 help-show-abk()
1087 {
1088   zle -M "$(print "Available abbreviations for expansion:"; print -a -C 2 ${(kv)abk})"
1089 }
1090
1091 zle -N help-show-abk
1092
1093 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1094 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1095 zle -N insert-datestamp
1096
1097 # press esc-m for inserting last typed word again (thanks to caphuso!)
1098 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1099 zle -N insert-last-typed-word;
1100
1101 function grml-zsh-fg() {
1102   if (( ${#jobstates} )); then
1103     zle .push-input
1104     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1105     BUFFER="${BUFFER}fg"
1106     zle .accept-line
1107   else
1108     zle -M 'No background jobs. Doing nothing.'
1109   fi
1110 }
1111 zle -N grml-zsh-fg
1112
1113 # run command line as user root via sudo:
1114 sudo-command-line() {
1115     [[ -z $BUFFER ]] && zle up-history
1116     if [[ $BUFFER != sudo\ * ]]; then
1117         BUFFER="sudo $BUFFER"
1118         CURSOR=$(( CURSOR+5 ))
1119     fi
1120 }
1121 zle -N sudo-command-line
1122
1123 ### jump behind the first word on the cmdline.
1124 ### useful to add options.
1125 function jump_after_first_word() {
1126     local words
1127     words=(${(z)BUFFER})
1128
1129     if (( ${#words} <= 1 )) ; then
1130         CURSOR=${#BUFFER}
1131     else
1132         CURSOR=${#${words[1]}}
1133     fi
1134 }
1135 zle -N jump_after_first_word
1136
1137 #f5# Create directory under cursor or the selected area
1138 inplaceMkDirs() {
1139     # Press ctrl-xM to create the directory under the cursor or the selected area.
1140     # To select an area press ctrl-@ or ctrl-space and use the cursor.
1141     # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
1142     # directory does not exist yet -> press ctrl-XM and problem solved
1143     local PATHTOMKDIR
1144     if ((REGION_ACTIVE==1)); then
1145         local F=$MARK T=$CURSOR
1146         if [[ $F -gt $T ]]; then
1147             F=${CURSOR}
1148             T=${MARK}
1149         fi
1150         # get marked area from buffer and eliminate whitespace
1151         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
1152         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
1153     else
1154         local bufwords iword
1155         bufwords=(${(z)LBUFFER})
1156         iword=${#bufwords}
1157         bufwords=(${(z)BUFFER})
1158         PATHTOMKDIR="${(Q)bufwords[iword]}"
1159     fi
1160     [[ -z "${PATHTOMKDIR}" ]] && return 1
1161     PATHTOMKDIR=${~PATHTOMKDIR}
1162     if [[ -e "${PATHTOMKDIR}" ]]; then
1163         zle -M " path already exists, doing nothing"
1164     else
1165         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
1166         zle end-of-line
1167     fi
1168 }
1169
1170 zle -N inplaceMkDirs
1171
1172 #v1# set number of lines to display per page
1173 HELP_LINES_PER_PAGE=20
1174 #v1# set location of help-zle cache file
1175 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
1176 # helper function for help-zle, actually generates the help text
1177 help_zle_parse_keybindings()
1178 {
1179     emulate -L zsh
1180     setopt extendedglob
1181     unsetopt ksharrays  #indexing starts at 1
1182
1183     #v1# choose files that help-zle will parse for keybindings
1184     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
1185
1186     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
1187         local load_cache=0
1188         local f
1189         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
1190         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
1191     fi
1192
1193     #fill with default keybindings, possibly to be overwriten in a file later
1194     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
1195     local -A help_zle_keybindings
1196     help_zle_keybindings['<Ctrl>@']="set MARK"
1197     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
1198     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
1199     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
1200     help_zle_keybindings['<Ctrl>_']="undo"
1201     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
1202     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
1203     help_zle_keybindings['<Ctrl>e']="goto end of line"
1204     help_zle_keybindings['<Ctrl>t']="transpose charaters"
1205     help_zle_keybindings['<Alt>t']="transpose words"
1206     help_zle_keybindings['<Alt>s']="spellcheck word"
1207     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
1208     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
1209     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
1210     help_zle_keybindings["<Alt>'"]="quote line"
1211     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
1212     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
1213     help_zle_keybindings['<Alt>u']="make next word Uppercase"
1214     help_zle_keybindings['<Alt>l']="make next word lowercase"
1215     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
1216     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
1217     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
1218     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
1219     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
1220     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
1221     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
1222     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
1223     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
1224
1225     #init global variables
1226     unset help_zle_lines help_zle_sln
1227     typeset -g -a help_zle_lines
1228     typeset -g help_zle_sln=1
1229
1230     local k v f cline
1231     local lastkeybind_desc contents     #last description starting with #k# that we found
1232     local num_lines_elapsed=0            #number of lines between last description and keybinding
1233     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
1234     for f in $HELPZLE_KEYBINDING_FILES; do
1235         [[ -r "$f" ]] || continue   #not readable ? skip it
1236         contents="$(<$f)"
1237         for cline in "${(f)contents}"; do
1238             #zsh pattern: matches lines like: #k# ..............
1239             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
1240                 lastkeybind_desc="$match[*]"
1241                 num_lines_elapsed=0
1242             #zsh pattern: matches lines that set a keybinding using bind2map, bindkey or compdef -k
1243             #             ignores lines that are commentend out
1244             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
1245             elif [[ "$cline" == [^#]#(bind2maps[[:space:]](*)-s|bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
1246                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
1247                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
1248                     #substitute keybinding string with something readable
1249                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
1250                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
1251                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
1252                     help_zle_keybindings[${k}]=$lastkeybind_desc
1253                 fi
1254                 lastkeybind_desc=""
1255             else
1256               ((num_lines_elapsed++))
1257             fi
1258         done
1259     done
1260     unset contents
1261     #calculate length of keybinding column
1262     local kstrlen=0
1263     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
1264     #convert the assoc array into preformated lines, which we are able to sort
1265     for k v in ${(kv)help_zle_keybindings[@]}; do
1266         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
1267         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
1268     done
1269     #sort lines alphabetically
1270     help_zle_lines=("${(i)help_zle_lines[@]}")
1271     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
1272     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
1273     zcompile $HELP_ZLE_CACHE_FILE
1274 }
1275 typeset -g help_zle_sln
1276 typeset -g -a help_zle_lines
1277
1278 # Provides (partially autogenerated) help on keybindings and the zsh line editor
1279 help-zle()
1280 {
1281     emulate -L zsh
1282     unsetopt ksharrays  #indexing starts at 1
1283     #help lines already generated ? no ? then do it
1284     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
1285     #already displayed all lines ? go back to the start
1286     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
1287     local sln=$help_zle_sln
1288     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
1289     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
1290     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
1291 }
1292 zle -N help-zle
1293
1294 ## complete word from currently visible Screen or Tmux buffer.
1295 if check_com -c screen || check_com -c tmux; then
1296     _complete_screen_display() {
1297         [[ "$TERM" != "screen" ]] && return 1
1298
1299         local TMPFILE=$(mktemp)
1300         local -U -a _screen_display_wordlist
1301         trap "rm -f $TMPFILE" EXIT
1302
1303         # fill array with contents from screen hardcopy
1304         if ((${+TMUX})); then
1305             #works, but crashes tmux below version 1.4
1306             #luckily tmux -V option to ask for version, was also added in 1.4
1307             tmux -V &>/dev/null || return
1308             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1309         else
1310             screen -X hardcopy $TMPFILE
1311             # screen sucks, it dumps in latin1, apparently always. so recode it
1312             # to system charset
1313             check_com recode && recode latin1 $TMPFILE
1314         fi
1315         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1316         # remove PREFIX to be completed from that array
1317         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1318         compadd -a _screen_display_wordlist
1319     }
1320     #m# k CTRL-x\,\,\,S Complete word from GNU screen buffer
1321     bindkey -r "^xS"
1322     compdef -k _complete_screen_display complete-word '^xS'
1323 fi
1324
1325 # Load a few more functions and tie them to widgets, so they can be bound:
1326
1327 function zrcautozle() {
1328     emulate -L zsh
1329     local fnc=$1
1330     zrcautoload $fnc && zle -N $fnc
1331 }
1332
1333 function zrcgotwidget() {
1334     (( ${+widgets[$1]} ))
1335 }
1336
1337 function zrcgotkeymap() {
1338     [[ -n ${(M)keymaps:#$1} ]]
1339 }
1340
1341 zrcautozle insert-files
1342 zrcautozle edit-command-line
1343 zrcautozle insert-unicode-char
1344 if zrcautoload history-search-end; then
1345     zle -N history-beginning-search-backward-end history-search-end
1346     zle -N history-beginning-search-forward-end  history-search-end
1347 fi
1348 zle -C hist-complete complete-word _generic
1349 zstyle ':completion:hist-complete:*' completer _history
1350
1351 # The actual terminal setup hooks and bindkey-calls:
1352
1353 # An array to note missing features to ease diagnosis in case of problems.
1354 typeset -ga grml_missing_features
1355
1356 function zrcbindkey() {
1357     if (( ARGC )) && zrcgotwidget ${argv[-1]}; then
1358         bindkey "$@"
1359     fi
1360 }
1361
1362 function bind2maps () {
1363     local i sequence widget
1364     local -a maps
1365
1366     while [[ "$1" != "--" ]]; do
1367         maps+=( "$1" )
1368         shift
1369     done
1370     shift
1371
1372     if [[ "$1" == "-s" ]]; then
1373         shift
1374         sequence="$1"
1375     else
1376         sequence="${key[$1]}"
1377     fi
1378     widget="$2"
1379
1380     [[ -z "$sequence" ]] && return 1
1381
1382     for i in "${maps[@]}"; do
1383         zrcbindkey -M "$i" "$sequence" "$widget"
1384     done
1385 }
1386
1387 if (( ${+terminfo[smkx]} )) && (( ${+terminfo[rmkx]} )); then
1388     function zle-smkx () {
1389         emulate -L zsh
1390         printf '%s' ${terminfo[smkx]}
1391     }
1392     function zle-rmkx () {
1393         emulate -L zsh
1394         printf '%s' ${terminfo[rmkx]}
1395     }
1396     function zle-line-init () {
1397         zle-smkx
1398     }
1399     function zle-line-finish () {
1400         zle-rmkx
1401     }
1402     zle -N zle-line-init
1403     zle -N zle-line-finish
1404 else
1405     for i in {s,r}mkx; do
1406         (( ${+terminfo[$i]} )) || grml_missing_features+=($i)
1407     done
1408     unset i
1409 fi
1410
1411 typeset -A key
1412 key=(
1413     Home     "${terminfo[khome]}"
1414     End      "${terminfo[kend]}"
1415     Insert   "${terminfo[kich1]}"
1416     Delete   "${terminfo[kdch1]}"
1417     Up       "${terminfo[kcuu1]}"
1418     Down     "${terminfo[kcud1]}"
1419     Left     "${terminfo[kcub1]}"
1420     Right    "${terminfo[kcuf1]}"
1421     PageUp   "${terminfo[kpp]}"
1422     PageDown "${terminfo[knp]}"
1423     BackTab  "${terminfo[kcbt]}"
1424 )
1425
1426 # Guidelines for adding key bindings:
1427 #
1428 #   - Do not add hardcoded escape sequences, to enable non standard key
1429 #     combinations such as Ctrl-Meta-Left-Cursor. They are not easily portable.
1430 #
1431 #   - Adding Ctrl characters, such as '^b' is okay; note that '^b' and '^B' are
1432 #     the same key.
1433 #
1434 #   - All keys from the $key[] mapping are obviously okay.
1435 #
1436 #   - Most terminals send "ESC x" when Meta-x is pressed. Thus, sequences like
1437 #     '\ex' are allowed in here as well.
1438
1439 bind2maps emacs             -- Home   beginning-of-somewhere
1440 bind2maps       viins vicmd -- Home   vi-beginning-of-line
1441 bind2maps emacs             -- End    end-of-somewhere
1442 bind2maps       viins vicmd -- End    vi-end-of-line
1443 bind2maps emacs viins       -- Insert overwrite-mode
1444 bind2maps             vicmd -- Insert vi-insert
1445 bind2maps emacs             -- Delete delete-char
1446 bind2maps       viins vicmd -- Delete vi-delete-char
1447 bind2maps emacs viins vicmd -- Up     up-line-or-search
1448 bind2maps emacs viins vicmd -- Down   down-line-or-search
1449 bind2maps emacs             -- Left   backward-char
1450 bind2maps       viins vicmd -- Left   vi-backward-char
1451 bind2maps emacs             -- Right  forward-char
1452 bind2maps       viins vicmd -- Right  vi-forward-char
1453 #k# Perform abbreviation expansion
1454 bind2maps emacs viins       -- -s '^x.' zleiab
1455 #k# Display list of abbreviations that would expand
1456 bind2maps emacs viins       -- -s '^xb' help-show-abk
1457 #k# mkdir -p <dir> from string under cursor or marked area
1458 bind2maps emacs viins       -- -s '^xM' inplaceMkDirs
1459 #k# display help for keybindings and ZLE
1460 bind2maps emacs viins       -- -s '^xz' help-zle
1461 #k# Insert files and test globbing
1462 bind2maps emacs viins       -- -s "^xf" insert-files
1463 #k# Edit the current line in \kbd{\$EDITOR}
1464 bind2maps emacs viins       -- -s '\ee' edit-command-line
1465 #k# search history backward for entry beginning with typed text
1466 bind2maps emacs viins       -- -s '^xp' history-beginning-search-backward-end
1467 #k# search history forward for entry beginning with typed text
1468 bind2maps emacs viins       -- -s '^xP' history-beginning-search-forward-end
1469 #k# search history backward for entry beginning with typed text
1470 bind2maps emacs viins       -- PageUp history-beginning-search-backward-end
1471 #k# search history forward for entry beginning with typed text
1472 bind2maps emacs viins       -- PageDown history-beginning-search-forward-end
1473 bind2maps emacs viins       -- -s "^x^h" commit-to-history
1474 #k# Kill left-side word or everything up to next slash
1475 bind2maps emacs viins       -- -s '\ev' slash-backward-kill-word
1476 #k# Kill left-side word or everything up to next slash
1477 bind2maps emacs viins       -- -s '\e^h' slash-backward-kill-word
1478 #k# Kill left-side word or everything up to next slash
1479 bind2maps emacs viins       -- -s '\e^?' slash-backward-kill-word
1480 # Do history expansion on space:
1481 bind2maps emacs viins       -- -s ' ' magic-space
1482 #k# Trigger menu-complete
1483 bind2maps emacs viins       -- -s '\ei' menu-complete  # menu completion via esc-i
1484 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1485 bind2maps emacs viins       -- -s '^ed' insert-datestamp
1486 #k# Insert last typed word
1487 bind2maps emacs viins       -- -s "\em" insert-last-typed-word
1488 #k# A smart shortcut for \kbd{fg<enter>}
1489 bind2maps emacs viins       -- -s '^z' grml-zsh-fg
1490 #k# prepend the current command with "sudo"
1491 bind2maps emacs viins       -- -s "^os" sudo-command-line
1492 #k# jump to after first word (for adding options)
1493 bind2maps emacs viins       -- -s '^x1' jump_after_first_word
1494 #k# complete word from history with menu
1495 bind2maps emacs viins       -- -s "^x^x" hist-complete
1496
1497 # insert unicode character
1498 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
1499 # See for example http://unicode.org/charts/ for unicode characters code
1500 #k# Insert Unicode character
1501 bind2maps emacs viins       -- -s '^xi' insert-unicode-char
1502
1503 # use the new *-pattern-* widgets for incremental history search
1504 if zrcgotwidget history-incremental-pattern-search-backward; then
1505     for seq wid in '^r' history-incremental-pattern-search-backward \
1506                    '^s' history-incremental-pattern-search-forward
1507     do
1508         bind2maps emacs viins vicmd -- -s $seq $wid
1509     done
1510     builtin unset -v seq wid
1511 fi
1512
1513 if zrcgotkeymap menuselect; then
1514     #m# k Shift-tab Perform backwards menu completion
1515     bind2maps menuselect -- BackTab reverse-menu-complete
1516
1517     #k# menu selection: pick item but stay in the menu
1518     bind2maps menuselect -- -s '\e^M' accept-and-menu-complete
1519     # also use + and INSERT since it's easier to press repeatedly
1520     bind2maps menuselect -- -s '+' accept-and-menu-complete
1521     bind2maps menuselect -- Insert accept-and-menu-complete
1522
1523     # accept a completion and try to complete again by using menu
1524     # completion; very useful with completing directories
1525     # by using 'undo' one's got a simple file browser
1526     bind2maps menuselect -- -s '^o' accept-and-infer-next-history
1527 fi
1528
1529 # Finally, here are still a few hardcoded escape sequences; Special sequences
1530 # like Ctrl-<Cursor-key> etc do suck a fair bit, because they are not
1531 # standardised and most of the time are not available in a terminals terminfo
1532 # entry.
1533 #
1534 # While we do not encourage adding bindings like these, we will keep these for
1535 # backward compatibility.
1536
1537 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on
1538 ## the command line.
1539 # URxvt sequences:
1540 bind2maps emacs viins vicmd -- -s '\eOc' forward-word
1541 bind2maps emacs viins vicmd -- -s '\eOd' backward-word
1542 # These are for xterm:
1543 bind2maps emacs viins vicmd -- -s '\e[1;5C' forward-word
1544 bind2maps emacs viins vicmd -- -s '\e[1;5D' backward-word
1545 ## the same for alt-left-arrow and alt-right-arrow
1546 # URxvt again:
1547 bind2maps emacs viins vicmd -- -s '\e\e[C' forward-word
1548 bind2maps emacs viins vicmd -- -s '\e\e[D' backward-word
1549 # Xterm again:
1550 bind2maps emacs viins vicmd -- -s '^[[1;3C' forward-word
1551 bind2maps emacs viins vicmd -- -s '^[[1;3D' backward-word
1552 # Also try ESC Left/Right:
1553 bind2maps emacs viins vicmd -- -s '\e'${key[Right]} forward-word
1554 bind2maps emacs viins vicmd -- -s '\e'${key[Left]}  backward-word
1555
1556 # autoloading
1557
1558 zrcautoload zmv
1559 zrcautoload zed
1560
1561 # we don't want to quote/espace URLs on our own...
1562 # if autoload -U url-quote-magic ; then
1563 #    zle -N self-insert url-quote-magic
1564 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
1565 # else
1566 #    print 'Notice: no url-quote-magic available :('
1567 # fi
1568 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
1569
1570 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
1571 alias run-help >&/dev/null && unalias run-help
1572 for rh in run-help{,-git,-svk,-svn}; do
1573     zrcautoload $rh
1574 done; unset rh
1575
1576 # command not found handling
1577
1578 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1579 function command_not_found_handler() {
1580     emulate -L zsh
1581     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1582         ${GRML_ZSH_CNF_HANDLER} $1
1583     fi
1584     return 1
1585 }
1586
1587 # history
1588
1589 #v#
1590 HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1591 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1592 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1593
1594 # dirstack handling
1595
1596 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1597 DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1598
1599 if zstyle -T ':grml:chpwd:dirstack' enable; then
1600     typeset -gaU GRML_PERSISTENT_DIRSTACK
1601     function grml_dirstack_filter() {
1602         local -a exclude
1603         local filter entry
1604         if zstyle -s ':grml:chpwd:dirstack' filter filter; then
1605             $filter $1 && return 0
1606         fi
1607         if zstyle -a ':grml:chpwd:dirstack' exclude exclude; then
1608             for entry in "${exclude[@]}"; do
1609                 [[ $1 == ${~entry} ]] && return 0
1610             done
1611         fi
1612         return 1
1613     }
1614
1615     chpwd() {
1616         (( $DIRSTACKSIZE <= 0 )) && return
1617         [[ -z $DIRSTACKFILE ]] && return
1618         grml_dirstack_filter $PWD && return
1619         GRML_PERSISTENT_DIRSTACK=(
1620             $PWD "${(@)GRML_PERSISTENT_DIRSTACK[1,$DIRSTACKSIZE]}"
1621         )
1622         builtin print -l ${GRML_PERSISTENT_DIRSTACK} >! ${DIRSTACKFILE}
1623     }
1624
1625     if [[ -f ${DIRSTACKFILE} ]]; then
1626         # Enabling NULL_GLOB via (N) weeds out any non-existing
1627         # directories from the saved dir-stack file.
1628         dirstack=( ${(f)"$(< $DIRSTACKFILE)"}(N) )
1629         # "cd -" won't work after login by just setting $OLDPWD, so
1630         [[ -d $dirstack[1] ]] && cd -q $dirstack[1] && cd -q $OLDPWD
1631     fi
1632
1633     if zstyle -t ':grml:chpwd:dirstack' filter-on-load; then
1634         for i in "${dirstack[@]}"; do
1635             if ! grml_dirstack_filter "$i"; then
1636                 GRML_PERSISTENT_DIRSTACK=(
1637                     "${GRML_PERSISTENT_DIRSTACK[@]}"
1638                     $i
1639                 )
1640             fi
1641         done
1642     else
1643         GRML_PERSISTENT_DIRSTACK=( "${dirstack[@]}" )
1644     fi
1645 fi
1646
1647 # directory based profiles
1648
1649 if is433 ; then
1650
1651 # chpwd_profiles(): Directory Profiles, Quickstart:
1652 #
1653 # In .zshrc.local:
1654 #
1655 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1656 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1657 #   chpwd_profiles
1658 #
1659 # For details see the `grmlzshrc.5' manual page.
1660 function chpwd_profiles() {
1661     local profile context
1662     local -i reexecute
1663
1664     context=":chpwd:profiles:$PWD"
1665     zstyle -s "$context" profile profile || profile='default'
1666     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1667
1668     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1669         typeset -g CHPWD_PROFILE
1670         local CHPWD_PROFILES_INIT=1
1671         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1672     elif [[ $profile != $CHPWD_PROFILE ]]; then
1673         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1674             && chpwd_leave_profile_${CHPWD_PROFILE}
1675     fi
1676     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1677         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1678     fi
1679
1680     CHPWD_PROFILE="${profile}"
1681     return 0
1682 }
1683
1684 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1685
1686 fi # is433
1687
1688 # Prompt setup for grml:
1689
1690 # set colors for use in prompts (modern zshs allow for the use of %F{red}foo%f
1691 # in prompts to get a red "foo" embedded, but it's good to keep these for
1692 # backwards compatibility).
1693 if is437; then
1694     BLUE="%F{blue}"
1695     RED="%F{red}"
1696     GREEN="%F{green}"
1697     CYAN="%F{cyan}"
1698     MAGENTA="%F{magenta}"
1699     YELLOW="%F{yellow}"
1700     WHITE="%F{white}"
1701     NO_COLOR="%f"
1702 elif zrcautoload colors && colors 2>/dev/null ; then
1703     BLUE="%{${fg[blue]}%}"
1704     RED="%{${fg_bold[red]}%}"
1705     GREEN="%{${fg[green]}%}"
1706     CYAN="%{${fg[cyan]}%}"
1707     MAGENTA="%{${fg[magenta]}%}"
1708     YELLOW="%{${fg[yellow]}%}"
1709     WHITE="%{${fg[white]}%}"
1710     NO_COLOR="%{${reset_color}%}"
1711 else
1712     BLUE=$'%{\e[1;34m%}'
1713     RED=$'%{\e[1;31m%}'
1714     GREEN=$'%{\e[1;32m%}'
1715     CYAN=$'%{\e[1;36m%}'
1716     WHITE=$'%{\e[1;37m%}'
1717     MAGENTA=$'%{\e[1;35m%}'
1718     YELLOW=$'%{\e[1;33m%}'
1719     NO_COLOR=$'%{\e[0m%}'
1720 fi
1721
1722 # First, the easy ones: PS2..4:
1723
1724 # secondary prompt, printed when the shell needs more information to complete a
1725 # command.
1726 PS2='\`%_> '
1727 # selection prompt used within a select loop.
1728 PS3='?# '
1729 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1730 PS4='+%N:%i:%_> '
1731
1732 # Some additional features to use with our prompt:
1733 #
1734 #    - battery status
1735 #    - debian_chroot
1736 #    - vcs_info setup and version specific fixes
1737
1738 # display battery status on right side of prompt using 'GRML_DISPLAY_BATTERY=1' in .zshrc.pre
1739
1740 battery() {
1741 if [[ $GRML_DISPLAY_BATTERY -gt 0 ]] ; then
1742     if islinux ; then
1743         batterylinux
1744     elif isopenbsd ; then
1745         batteryopenbsd
1746     elif isfreebsd ; then
1747         batteryfreebsd
1748     elif isdarwin ; then
1749         batterydarwin
1750     else
1751         #not yet supported
1752         GRML_DISPLAY_BATTERY=0
1753     fi
1754 fi
1755 }
1756
1757 batterylinux(){
1758 GRML_BATTERY_LEVEL=''
1759 local batteries bat capacity
1760 batteries=( /sys/class/power_supply/BAT*(N) )
1761 if (( $#batteries > 0 )) ; then
1762     for bat in $batteries ; do
1763         capacity=$(< $bat/capacity)
1764         case $(< $bat/status) in
1765         Charging)
1766             GRML_BATTERY_LEVEL+=" ^"
1767             ;;
1768         Discharging)
1769             if (( capacity < 20 )) ; then
1770                 GRML_BATTERY_LEVEL+=" !v"
1771             else
1772                 GRML_BATTERY_LEVEL+=" v"
1773             fi
1774             ;;
1775         *) # Full, Unknown
1776             GRML_BATTERY_LEVEL+=" ="
1777             ;;
1778         esac
1779         GRML_BATTERY_LEVEL+="${capacity}%%"
1780     done
1781 fi
1782 }
1783
1784 batteryopenbsd(){
1785 GRML_BATTERY_LEVEL=''
1786 local bat batfull batwarn batnow num
1787 for num in 0 1 ; do
1788     bat=$(sysctl -n hw.sensors.acpibat${num} 2>/dev/null)
1789     if [[ -n $bat ]]; then
1790         batfull=${"$(sysctl -n hw.sensors.acpibat${num}.amphour0)"%% *}
1791         batwarn=${"$(sysctl -n hw.sensors.acpibat${num}.amphour1)"%% *}
1792         batnow=${"$(sysctl -n hw.sensors.acpibat${num}.amphour3)"%% *}
1793         case "$(sysctl -n hw.sensors.acpibat${num}.raw0)" in
1794             *" discharging"*)
1795                 if (( batnow < batwarn )) ; then
1796                     GRML_BATTERY_LEVEL+=" !v"
1797                 else
1798                     GRML_BATTERY_LEVEL+=" v"
1799                 fi
1800                 ;;
1801             *" charging"*)
1802                 GRML_BATTERY_LEVEL+=" ^"
1803                 ;;
1804             *)
1805                 GRML_BATTERY_LEVEL+=" ="
1806                 ;;
1807         esac
1808         GRML_BATTERY_LEVEL+="${$(( 100 * batnow / batfull ))%%.*}%%"
1809     fi
1810 done
1811 }
1812
1813 batteryfreebsd(){
1814 GRML_BATTERY_LEVEL=''
1815 local num
1816 local -A table
1817 for num in 0 1 ; do
1818     table=( ${=${${${${${(M)${(f)"$(acpiconf -i $num 2>&1)"}:#(State|Remaining capacity):*}%%( ##|%)}//:[ $'\t']##/@}// /-}//@/ }} )
1819     if [[ -n $table ]] && [[ $table[State] != "not-present" ]] ; then
1820         case $table[State] in
1821             *discharging*)
1822                 if (( $table[Remaining-capacity] < 20 )) ; then
1823                     GRML_BATTERY_LEVEL+=" !v"
1824                 else
1825                     GRML_BATTERY_LEVEL+=" v"
1826                 fi
1827                 ;;
1828             *charging*)
1829                 GRML_BATTERY_LEVEL+=" ^"
1830                 ;;
1831             *)
1832                 GRML_BATTERY_LEVEL+=" ="
1833                 ;;
1834         esac
1835         GRML_BATTERY_LEVEL+="$table[Remaining-capacity]%%"
1836     fi
1837 done
1838 }
1839
1840 batterydarwin(){
1841 GRML_BATTERY_LEVEL=''
1842 local -a table
1843 table=( ${$(pmset -g ps)[(w)7,8]%%(\%|);} )
1844 if [[ -n $table[2] ]] ; then
1845     case $table[2] in
1846         charging)
1847             GRML_BATTERY_LEVEL+=" ^"
1848             ;;
1849         discharging)
1850             if (( $table[1] < 20 )) ; then
1851                 GRML_BATTERY_LEVEL+=" !v"
1852             else
1853                 GRML_BATTERY_LEVEL+=" v"
1854             fi
1855             ;;
1856         *)
1857             GRML_BATTERY_LEVEL+=" ="
1858             ;;
1859     esac
1860     GRML_BATTERY_LEVEL+="$table[1]%%"
1861 fi
1862 }
1863
1864 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1865 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1866     debian_chroot=$(</etc/debian_chroot)
1867 fi
1868
1869 # gather version control information for inclusion in a prompt
1870
1871 if zrcautoload vcs_info; then
1872     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1873     # function, which can cause a lot of trouble with our directory-based
1874     # profiles. So:
1875     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1876         function VCS_INFO_realpath () {
1877             setopt localoptions NO_shwordsplit chaselinks
1878             ( builtin cd -q $1 2> /dev/null && pwd; )
1879         }
1880     fi
1881
1882     zstyle ':vcs_info:*' max-exports 2
1883
1884     if [[ -o restricted ]]; then
1885         zstyle ':vcs_info:*' enable NONE
1886     fi
1887 fi
1888
1889 typeset -A grml_vcs_coloured_formats
1890 typeset -A grml_vcs_plain_formats
1891
1892 grml_vcs_plain_formats=(
1893     format "(%s%)-[%b] "    "zsh: %r"
1894     actionformat "(%s%)-[%b|%a] " "zsh: %r"
1895     rev-branchformat "%b:%r"
1896 )
1897
1898 grml_vcs_coloured_formats=(
1899     format "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR} "
1900     actionformat "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} "
1901     rev-branchformat "%b${RED}:${YELLOW}%r"
1902 )
1903
1904 typeset GRML_VCS_COLOUR_MODE=xxx
1905
1906 grml_vcs_info_toggle_colour () {
1907     emulate -L zsh
1908     if [[ $GRML_VCS_COLOUR_MODE == plain ]]; then
1909         grml_vcs_info_set_formats coloured
1910     else
1911         grml_vcs_info_set_formats plain
1912     fi
1913     return 0
1914 }
1915
1916 grml_vcs_info_set_formats () {
1917     emulate -L zsh
1918     #setopt localoptions xtrace
1919     local mode=$1 AF F BF
1920     if [[ $mode == coloured ]]; then
1921         AF=${grml_vcs_coloured_formats[actionformat]}
1922         F=${grml_vcs_coloured_formats[format]}
1923         BF=${grml_vcs_coloured_formats[rev-branchformat]}
1924         GRML_VCS_COLOUR_MODE=coloured
1925     else
1926         AF=${grml_vcs_plain_formats[actionformat]}
1927         F=${grml_vcs_plain_formats[format]}
1928         BF=${grml_vcs_plain_formats[rev-branchformat]}
1929         GRML_VCS_COLOUR_MODE=plain
1930     fi
1931
1932     zstyle ':vcs_info:*'              actionformats "$AF" "zsh: %r"
1933     zstyle ':vcs_info:*'              formats       "$F"  "zsh: %r"
1934     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat  "$BF"
1935     return 0
1936 }
1937
1938 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1939 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1940 if [[ "$TERM" == dumb ]] ; then
1941     grml_vcs_info_set_formats plain
1942 else
1943     grml_vcs_info_set_formats coloured
1944 fi
1945
1946 # Now for the fun part: The grml prompt themes in `promptsys' mode of operation
1947
1948 # This actually defines three prompts:
1949 #
1950 #    - grml
1951 #    - grml-large
1952 #    - grml-chroot
1953 #
1954 # They all share the same code and only differ with respect to which items they
1955 # contain. The main source of documentation is the `prompt_grml_help' function
1956 # below, which gets called when the user does this: prompt -h grml
1957
1958 function prompt_grml_help () {
1959     <<__EOF0__
1960   prompt grml
1961
1962     This is the prompt as used by the grml-live system <http://grml.org>. It is
1963     a rather simple one-line prompt, that by default looks something like this:
1964
1965         <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1966
1967     The prompt itself integrates with zsh's prompt themes system (as you are
1968     witnessing right now) and is configurable to a certain degree. In
1969     particular, these aspects are customisable:
1970
1971         - The items used in the prompt (e.g. you can remove \`user' from
1972           the list of activated items, which will cause the user name to
1973           be omitted from the prompt string).
1974
1975         - The attributes used with the items are customisable via strings
1976           used before and after the actual item.
1977
1978     The available items are: at, battery, change-root, date, grml-chroot,
1979     history, host, jobs, newline, path, percent, rc, rc-always, sad-smiley,
1980     shell-level, time, user, vcs
1981
1982     The actual configuration is done via zsh's \`zstyle' mechanism. The
1983     context, that is used while looking up styles is:
1984
1985         ':prompt:grml:<left-or-right>:<subcontext>'
1986
1987     Here <left-or-right> is either \`left' or \`right', signifying whether the
1988     style should affect the left or the right prompt. <subcontext> is either
1989     \`setup' or 'items:<item>', where \`<item>' is one of the available items.
1990
1991     The styles:
1992
1993         - use-rprompt (boolean): If \`true' (the default), print a sad smiley
1994           in $RPROMPT if the last command a returned non-successful error code.
1995           (This in only valid if <left-or-right> is "right"; ignored otherwise)
1996
1997         - items (list): The list of items used in the prompt. If \`vcs' is
1998           present in the list, the theme's code invokes \`vcs_info'
1999           accordingly. Default (left): rc change-root user at host path vcs
2000           percent; Default (right): sad-smiley
2001
2002     Available styles in 'items:<item>' are: pre, post. These are strings that
2003     are inserted before (pre) and after (post) the item in question. Thus, the
2004     following would cause the user name to be printed in red instead of the
2005     default blue:
2006
2007         zstyle ':prompt:grml:*:items:user' pre '%F{red}'
2008
2009     Note, that the \`post' style may remain at its default value, because its
2010     default value is '%f', which turns the foreground text attribute off (which
2011     is exactly, what is still required with the new \`pre' value).
2012 __EOF0__
2013 }
2014
2015 function prompt_grml-chroot_help () {
2016     <<__EOF0__
2017   prompt grml-chroot
2018
2019     This is a variation of the grml prompt, see: prompt -h grml
2020
2021     The main difference is the default value of the \`items' style. The rest
2022     behaves exactly the same. Here are the defaults for \`grml-chroot':
2023
2024         - left: grml-chroot user at host path percent
2025         - right: (empty list)
2026 __EOF0__
2027 }
2028
2029 function prompt_grml-large_help () {
2030     <<__EOF0__
2031   prompt grml-large
2032
2033     This is a variation of the grml prompt, see: prompt -h grml
2034
2035     The main difference is the default value of the \`items' style. In
2036     particular, this theme uses _two_ lines instead of one with the plain
2037     \`grml' theme. The rest behaves exactly the same. Here are the defaults
2038     for \`grml-large':
2039
2040         - left: rc jobs history shell-level change-root time date newline user
2041                 at host path vcs percent
2042         - right: sad-smiley
2043 __EOF0__
2044 }
2045
2046 function grml_prompt_setup () {
2047     emulate -L zsh
2048     autoload -Uz vcs_info
2049     # The following autoload is disabled for now, since this setup includes a
2050     # static version of the ‘add-zsh-hook’ function above. It needs to be
2051     # reenabled as soon as that static definition is removed again.
2052     #autoload -Uz add-zsh-hook
2053     add-zsh-hook precmd prompt_$1_precmd
2054 }
2055
2056 function prompt_grml_setup () {
2057     grml_prompt_setup grml
2058 }
2059
2060 function prompt_grml-chroot_setup () {
2061     grml_prompt_setup grml-chroot
2062 }
2063
2064 function prompt_grml-large_setup () {
2065     grml_prompt_setup grml-large
2066 }
2067
2068 # These maps define default tokens and pre-/post-decoration for items to be
2069 # used within the themes. All defaults may be customised in a context sensitive
2070 # matter by using zsh's `zstyle' mechanism.
2071 typeset -gA grml_prompt_pre_default \
2072             grml_prompt_post_default \
2073             grml_prompt_token_default \
2074             grml_prompt_token_function
2075
2076 grml_prompt_pre_default=(
2077     at                ''
2078     battery           ' '
2079     change-root       ''
2080     date              '%F{blue}'
2081     grml-chroot       '%F{red}'
2082     history           '%F{green}'
2083     host              ''
2084     jobs              '%F{cyan}'
2085     newline           ''
2086     path              '%B'
2087     percent           ''
2088     rc                '%B%F{red}'
2089     rc-always         ''
2090     sad-smiley        ''
2091     shell-level       '%F{red}'
2092     time              '%F{blue}'
2093     user              '%B%F{blue}'
2094     vcs               ''
2095 )
2096
2097 grml_prompt_post_default=(
2098     at                ''
2099     battery           ''
2100     change-root       ''
2101     date              '%f'
2102     grml-chroot       '%f '
2103     history           '%f'
2104     host              ''
2105     jobs              '%f'
2106     newline           ''
2107     path              '%b'
2108     percent           ''
2109     rc                '%f%b'
2110     rc-always         ''
2111     sad-smiley        ''
2112     shell-level       '%f'
2113     time              '%f'
2114     user              '%f%b'
2115     vcs               ''
2116 )
2117
2118 grml_prompt_token_default=(
2119     at                '@'
2120     battery           'GRML_BATTERY_LEVEL'
2121     change-root       'debian_chroot'
2122     date              '%D{%Y-%m-%d}'
2123     grml-chroot       'GRML_CHROOT'
2124     history           '{history#%!} '
2125     host              '%m '
2126     jobs              '[%j running job(s)] '
2127     newline           $'\n'
2128     path              '%40<..<%~%<< '
2129     percent           '%# '
2130     rc                '%(?..%? )'
2131     rc-always         '%?'
2132     sad-smiley        '%(?..:()'
2133     shell-level       '%(3L.+ .)'
2134     time              '%D{%H:%M:%S} '
2135     user              '%n'
2136     vcs               '0'
2137 )
2138
2139 function grml_theme_has_token () {
2140     if (( ARGC != 1 )); then
2141         printf 'usage: grml_theme_has_token <name>\n'
2142         return 1
2143     fi
2144     (( ${+grml_prompt_token_default[$1]} ))
2145 }
2146
2147 function GRML_theme_add_token_usage () {
2148     <<__EOF0__
2149   Usage: grml_theme_add_token <name> [-f|-i] <token/function> [<pre> <post>]
2150
2151     <name> is the name for the newly added token. If the \`-f' or \`-i' options
2152     are used, <token/function> is the name of the function (see below for
2153     details). Otherwise it is the literal token string to be used. <pre> and
2154     <post> are optional.
2155
2156   Options:
2157
2158     -f <function>   Use a function named \`<function>' each time the token
2159                     is to be expanded.
2160
2161     -i <function>   Use a function named \`<function>' to initialise the
2162                     value of the token _once_ at runtime.
2163
2164     The functions are called with one argument: the token's new name. The
2165     return value is expected in the \$REPLY parameter. The use of these
2166     options is mutually exclusive.
2167
2168     There is a utility function \`grml_theme_has_token', which you can use
2169     to test if a token exists before trying to add it. This can be a guard
2170     for situations in which a \`grml_theme_add_token' call may happen more
2171     than once.
2172
2173   Example:
2174
2175     To add a new token \`day' that expands to the current weekday in the
2176     current locale in green foreground colour, use this:
2177
2178       grml_theme_add_token day '%D{%A}' '%F{green}' '%f'
2179
2180     Another example would be support for \$VIRTUAL_ENV:
2181
2182       function virtual_env_prompt () {
2183         REPLY=\${VIRTUAL_ENV+\${VIRTUAL_ENV:t} }
2184       }
2185       grml_theme_add_token virtual-env -f virtual_env_prompt
2186
2187     After that, you will be able to use a changed \`items' style to
2188     assemble your prompt.
2189 __EOF0__
2190 }
2191
2192 function grml_theme_add_token () {
2193     emulate -L zsh
2194     local name token pre post
2195     local -i init funcall
2196
2197     if (( ARGC == 0 )); then
2198         GRML_theme_add_token_usage
2199         return 0
2200     fi
2201
2202     init=0
2203     funcall=0
2204     pre=''
2205     post=''
2206     name=$1
2207     shift
2208     if [[ $1 == '-f' ]]; then
2209         funcall=1
2210         shift
2211     elif [[ $1 == '-i' ]]; then
2212         init=1
2213         shift
2214     fi
2215
2216     if (( ARGC == 0 )); then
2217         printf '
2218 grml_theme_add_token: No token-string/function-name provided!\n\n'
2219         GRML_theme_add_token_usage
2220         return 1
2221     fi
2222     token=$1
2223     shift
2224     if (( ARGC != 0 && ARGC != 2 )); then
2225         printf '
2226 grml_theme_add_token: <pre> and <post> need to by specified _both_!\n\n'
2227         GRML_theme_add_token_usage
2228         return 1
2229     fi
2230     if (( ARGC )); then
2231         pre=$1
2232         post=$2
2233         shift 2
2234     fi
2235
2236     if grml_theme_has_token $name; then
2237         printf '
2238 grml_theme_add_token: Token `%s'\'' exists! Giving up!\n\n' $name
2239         GRML_theme_add_token_usage
2240         return 2
2241     fi
2242     if (( init )); then
2243         $token $name
2244         token=$REPLY
2245     fi
2246     grml_prompt_pre_default[$name]=$pre
2247     grml_prompt_post_default[$name]=$post
2248     if (( funcall )); then
2249         grml_prompt_token_function[$name]=$token
2250         grml_prompt_token_default[$name]=23
2251     else
2252         grml_prompt_token_default[$name]=$token
2253     fi
2254 }
2255
2256 function grml_typeset_and_wrap () {
2257     emulate -L zsh
2258     local target="$1"
2259     local new="$2"
2260     local left="$3"
2261     local right="$4"
2262
2263     if (( ${+parameters[$new]} )); then
2264         typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
2265     fi
2266 }
2267
2268 function grml_prompt_addto () {
2269     emulate -L zsh
2270     local target="$1"
2271     local lr it apre apost new v
2272     local -a items
2273     shift
2274
2275     [[ $target == PS1 ]] && lr=left || lr=right
2276     zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
2277     typeset -g "${target}="
2278     for it in "${items[@]}"; do
2279         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
2280             || apre=${grml_prompt_pre_default[$it]}
2281         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" post apost \
2282             || apost=${grml_prompt_post_default[$it]}
2283         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
2284             || new=${grml_prompt_token_default[$it]}
2285         typeset -g "${target}=${(P)target}${apre}"
2286         if (( ${+grml_prompt_token_function[$it]} )); then
2287             ${grml_prompt_token_function[$it]} $it
2288             typeset -g "${target}=${(P)target}${REPLY}"
2289         else
2290             case $it in
2291             battery)
2292                 grml_typeset_and_wrap $target $new '' ''
2293                 ;;
2294             change-root)
2295                 grml_typeset_and_wrap $target $new '(' ')'
2296                 ;;
2297             grml-chroot)
2298                 if [[ -n ${(P)new} ]]; then
2299                     typeset -g "${target}=${(P)target}(CHROOT)"
2300                 fi
2301                 ;;
2302             vcs)
2303                 v="vcs_info_msg_${new}_"
2304                 if (( ! vcscalled )); then
2305                     vcs_info
2306                     vcscalled=1
2307                 fi
2308                 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
2309                     typeset -g "${target}=${(P)target}${(P)v}"
2310                 fi
2311                 ;;
2312             *) typeset -g "${target}=${(P)target}${new}" ;;
2313             esac
2314         fi
2315         typeset -g "${target}=${(P)target}${apost}"
2316     done
2317 }
2318
2319 function prompt_grml_precmd () {
2320     emulate -L zsh
2321     local grmltheme=grml
2322     local -a left_items right_items
2323     left_items=(rc change-root user at host path vcs percent)
2324     right_items=(sad-smiley)
2325
2326     prompt_grml_precmd_worker
2327 }
2328
2329 function prompt_grml-chroot_precmd () {
2330     emulate -L zsh
2331     local grmltheme=grml-chroot
2332     local -a left_items right_items
2333     left_items=(grml-chroot user at host path percent)
2334     right_items=()
2335
2336     prompt_grml_precmd_worker
2337 }
2338
2339 function prompt_grml-large_precmd () {
2340     emulate -L zsh
2341     local grmltheme=grml-large
2342     local -a left_items right_items
2343     left_items=(rc jobs history shell-level change-root time date newline
2344                 user at host path vcs percent)
2345     right_items=(sad-smiley)
2346
2347     prompt_grml_precmd_worker
2348 }
2349
2350 function prompt_grml_precmd_worker () {
2351     emulate -L zsh
2352     local -i vcscalled=0
2353
2354     grml_prompt_addto PS1 "${left_items[@]}"
2355     if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
2356         grml_prompt_addto RPS1 "${right_items[@]}"
2357     fi
2358 }
2359
2360 grml_prompt_fallback() {
2361     setopt prompt_subst
2362     precmd() {
2363         (( ${+functions[vcs_info]} )) && vcs_info
2364     }
2365
2366     p0="${RED}%(?..%? )${WHITE}${debian_chroot:+($debian_chroot)}"
2367     p1="${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "'${vcs_info_msg_0_}'"%# "
2368     if (( EUID == 0 )); then
2369         PROMPT="${BLUE}${p0}${RED}${p1}"
2370     else
2371         PROMPT="${RED}${p0}${BLUE}${p1}"
2372     fi
2373     unset p0 p1
2374 }
2375
2376 if zrcautoload promptinit && promptinit 2>/dev/null ; then
2377     # Since we define the required functions in here and not in files in
2378     # $fpath, we need to stick the theme's name into `$prompt_themes'
2379     # ourselves, since promptinit does not pick them up otherwise.
2380     prompt_themes+=( grml grml-chroot grml-large )
2381     # Also, keep the array sorted...
2382     prompt_themes=( "${(@on)prompt_themes}" )
2383 else
2384     print 'Notice: no promptinit available :('
2385     grml_prompt_fallback
2386 fi
2387
2388 if is437; then
2389     # The prompt themes use modern features of zsh, that require at least
2390     # version 4.3.7 of the shell. Use the fallback otherwise.
2391     if [[ $GRML_DISPLAY_BATTERY -gt 0 ]]; then
2392         zstyle ':prompt:grml:right:setup' items sad-smiley battery
2393         add-zsh-hook precmd battery
2394     fi
2395     if [[ "$TERM" == dumb ]] ; then
2396         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" pre ''
2397         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" post ' '
2398         for i in rc user path jobs history date time shell-level; do
2399             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" pre ''
2400             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" post ''
2401         done
2402         unset i
2403         zstyle ':prompt:grml(|-large|-chroot):right:setup' use-rprompt false
2404     elif (( EUID == 0 )); then
2405         zstyle ':prompt:grml(|-large|-chroot):*:items:user' pre '%B%F{red}'
2406     fi
2407
2408     # Finally enable one of the prompts.
2409     if [[ -n $GRML_CHROOT ]]; then
2410         prompt grml-chroot
2411     elif [[ $GRMLPROMPT -gt 0 ]]; then
2412         prompt grml-large
2413     else
2414         prompt grml
2415     fi
2416 else
2417     grml_prompt_fallback
2418 fi
2419
2420 # Terminal-title wizardry
2421
2422 function ESC_print () {
2423     info_print $'\ek' $'\e\\' "$@"
2424 }
2425 function set_title () {
2426     info_print  $'\e]0;' $'\a' "$@"
2427 }
2428
2429 function info_print () {
2430     local esc_begin esc_end
2431     esc_begin="$1"
2432     esc_end="$2"
2433     shift 2
2434     printf '%s' ${esc_begin}
2435     printf '%s' "$*"
2436     printf '%s' "${esc_end}"
2437 }
2438
2439 function grml_reset_screen_title () {
2440     # adjust title of xterm
2441     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
2442     [[ ${NOTITLE:-} -gt 0 ]] && return 0
2443     case $TERM in
2444         (xterm*|rxvt*)
2445             set_title ${(%):-"%n@%m: %~"}
2446             ;;
2447     esac
2448 }
2449
2450 function grml_vcs_to_screen_title () {
2451     if [[ $TERM == screen* ]] ; then
2452         if [[ -n ${vcs_info_msg_1_} ]] ; then
2453             ESC_print ${vcs_info_msg_1_}
2454         else
2455             ESC_print "zsh"
2456         fi
2457     fi
2458 }
2459
2460 function grml_maintain_name () {
2461     # set hostname if not running on host with name 'grml'
2462     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
2463        NAME="@$HOSTNAME"
2464     fi
2465 }
2466
2467 function grml_cmd_to_screen_title () {
2468     # get the name of the program currently running and hostname of local
2469     # machine set screen window title if running in a screen
2470     if [[ "$TERM" == screen* ]] ; then
2471         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME"
2472         ESC_print ${CMD}
2473     fi
2474 }
2475
2476 function grml_control_xterm_title () {
2477     case $TERM in
2478         (xterm*|rxvt*)
2479             set_title "${(%):-"%n@%m:"}" "$1"
2480             ;;
2481     esac
2482 }
2483
2484 # The following autoload is disabled for now, since this setup includes a
2485 # static version of the ‘add-zsh-hook’ function above. It needs to be
2486 # reenabled as soon as that static definition is removed again.
2487 #zrcautoload add-zsh-hook || add-zsh-hook () { :; }
2488 if [[ $NOPRECMD -eq 0 ]]; then
2489     add-zsh-hook precmd grml_reset_screen_title
2490     add-zsh-hook precmd grml_vcs_to_screen_title
2491     add-zsh-hook preexec grml_maintain_name
2492     add-zsh-hook preexec grml_cmd_to_screen_title
2493     if [[ $NOTITLE -eq 0 ]]; then
2494         add-zsh-hook preexec grml_control_xterm_title
2495     fi
2496 fi
2497
2498 # 'hash' some often used directories
2499 #d# start
2500 hash -d deb=/var/cache/apt/archives
2501 hash -d doc=/usr/share/doc
2502 hash -d linux=/lib/modules/$(command uname -r)/build/
2503 hash -d log=/var/log
2504 hash -d slog=/var/log/syslog
2505 hash -d src=/usr/src
2506 hash -d www=/var/www
2507 #d# end
2508
2509 # some aliases
2510 if check_com -c screen ; then
2511     if [[ $UID -eq 0 ]] ; then
2512         if [[ -r /etc/grml/screenrc ]]; then
2513             alias screen='screen -c /etc/grml/screenrc'
2514         fi
2515     elif [[ ! -r $HOME/.screenrc ]] ; then
2516         if [[ -r /etc/grml/screenrc_grml ]]; then
2517             alias screen='screen -c /etc/grml/screenrc_grml'
2518         else
2519             if [[ -r /etc/grml/screenrc ]]; then
2520                 alias screen='screen -c /etc/grml/screenrc'
2521             fi
2522         fi
2523     fi
2524 fi
2525
2526 # do we have GNU ls with color-support?
2527 if [[ "$TERM" != dumb ]]; then
2528     #a1# List files with colors (\kbd{ls \ldots})
2529     alias ls="command ls ${ls_options:+${ls_options[*]}}"
2530     #a1# List all files, with colors (\kbd{ls -la \ldots})
2531     alias la="command ls -la ${ls_options:+${ls_options[*]}}"
2532     #a1# List files with long colored list, without dotfiles (\kbd{ls -l \ldots})
2533     alias ll="command ls -l ${ls_options:+${ls_options[*]}}"
2534     #a1# List files with long colored list, human readable sizes (\kbd{ls -hAl \ldots})
2535     alias lh="command ls -hAl ${ls_options:+${ls_options[*]}}"
2536     #a1# List files with long colored list, append qualifier to filenames (\kbd{ls -l \ldots})\\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2537     alias l="command ls -l ${ls_options:+${ls_options[*]}}"
2538 else
2539     alias la='command ls -la'
2540     alias ll='command ls -l'
2541     alias lh='command ls -hAl'
2542     alias l='command ls -l'
2543 fi
2544
2545 alias mdstat='cat /proc/mdstat'
2546 alias ...='cd ../../'
2547
2548 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2549 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2550     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2551 fi
2552
2553 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2554 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2555 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2556
2557 # make sure it is not assigned yet
2558 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
2559 utf2iso() {
2560     if isutfenv ; then
2561         local ENV
2562         for ENV in $(env | command grep -i '.utf') ; do
2563             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2564         done
2565     fi
2566 }
2567
2568 # make sure it is not assigned yet
2569 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
2570 iso2utf() {
2571     if ! isutfenv ; then
2572         local ENV
2573         for ENV in $(env | command grep -i '\.iso') ; do
2574             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2575         done
2576     fi
2577 }
2578
2579 # especially for roadwarriors using GNU screen and ssh:
2580 if ! check_com asc &>/dev/null ; then
2581   asc() { autossh -t "$@" 'screen -RdU' }
2582   compdef asc=ssh
2583 fi
2584
2585 #f1# Hints for the use of zsh on grml
2586 zsh-help() {
2587     print "$bg[white]$fg[black]
2588 zsh-help - hints for use of zsh on grml
2589 =======================================$reset_color"
2590
2591     print '
2592 Main configuration of zsh happens in /etc/zsh/zshrc.
2593 That file is part of the package grml-etc-core, if you want to
2594 use them on a non-grml-system just get the tar.gz from
2595 http://deb.grml.org/ or (preferably) get it from the git repository:
2596
2597   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2598
2599 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2600 The file is still there, but it is empty for backwards compatibility.
2601
2602 For your own changes use these two files:
2603     $HOME/.zshrc.pre
2604     $HOME/.zshrc.local
2605
2606 The former is sourced very early in our zshrc, the latter is sourced
2607 very lately.
2608
2609 System wide configuration without touching configuration files of grml
2610 can take place in /etc/zsh/zshrc.local.
2611
2612 For information regarding zsh start at http://grml.org/zsh/
2613
2614 Take a look at grml'\''s zsh refcard:
2615 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2616
2617 Check out the main zsh refcard:
2618 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2619
2620 And of course visit the zsh-lovers:
2621 % man zsh-lovers
2622
2623 You can adjust some options through environment variables when
2624 invoking zsh without having to edit configuration files.
2625 Basically meant for bash users who are not used to the power of
2626 the zsh yet. :)
2627
2628   "NOCOR=1    zsh" => deactivate automatic correction
2629   "NOMENU=1   zsh" => do not use auto menu completion
2630                       (note: use ctrl-d for completion instead!)
2631   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2632   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2633                       preexec() and precmd() completely
2634   "GRML_DISPLAY_BATTERY=1  zsh"
2635                    => activate battery status on right side of prompt (WIP)
2636   "COMMAND_NOT_FOUND=1 zsh"
2637                    => Enable a handler if an external command was not found
2638                       The command called in the handler can be altered by setting
2639                       the GRML_ZSH_CNF_HANDLER variable, the default is:
2640                       "/usr/share/command-not-found/command-not-found"
2641
2642 A value greater than 0 is enables a feature; a value equal to zero
2643 disables it. If you like one or the other of these settings, you can
2644 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2645 zshrc.'
2646
2647     print "
2648 $bg[white]$fg[black]
2649 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2650 Enjoy your grml system with the zsh!$reset_color"
2651 }
2652
2653 # debian stuff
2654 if [[ -r /etc/debian_version ]] ; then
2655     #a3# Execute \kbd{apt-cache search}
2656     alias acs='apt-cache search'
2657     #a3# Execute \kbd{apt-cache show}
2658     alias acsh='apt-cache show'
2659     #a3# Execute \kbd{apt-cache policy}
2660     alias acp='apt-cache policy'
2661     #a3# Execute \kbd{apt-get dist-upgrade}
2662     salias adg="apt-get dist-upgrade"
2663     #a3# Execute \kbd{apt-get install}
2664     salias agi="apt-get install"
2665     #a3# Execute \kbd{aptitude install}
2666     salias ati="aptitude install"
2667     #a3# Execute \kbd{apt-get upgrade}
2668     salias ag="apt-get upgrade"
2669     #a3# Execute \kbd{apt-get update}
2670     salias au="apt-get update"
2671     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2672     salias -a up="aptitude update ; aptitude safe-upgrade"
2673     #a3# Execute \kbd{dpkg-buildpackage}
2674     alias dbp='dpkg-buildpackage'
2675     #a3# Execute \kbd{grep-excuses}
2676     alias ge='grep-excuses'
2677
2678     # get a root shell as normal user in live-cd mode:
2679     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2680        alias su="sudo su"
2681     fi
2682
2683     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2684     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2685     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2686     salias tlog="tail -f /var/log/syslog"    # follow the syslog
2687 fi
2688
2689 # sort installed Debian-packages by size
2690 if check_com -c dpkg-query ; then
2691     #a3# List installed Debian-packages sorted by size
2692     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
2693 fi
2694
2695 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2696 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
2697     if check_com -c wodim; then
2698         cdrecord() {
2699             <<__EOF0__
2700 cdrecord is not provided under its original name by Debian anymore.
2701 See #377109 in the BTS of Debian for more details.
2702
2703 Please use the wodim binary instead
2704 __EOF0__
2705             return 1
2706         }
2707     fi
2708 fi
2709
2710 if isgrmlcd; then
2711     # No core dumps: important for a live-cd-system
2712     limit -s core 0
2713 fi
2714
2715 # grmlstuff
2716 grmlstuff() {
2717 # people should use 'grml-x'!
2718     if check_com -c 915resolution; then
2719         855resolution() {
2720             echo "Please use 915resolution as resolution modifying tool for Intel \
2721 graphic chipset."
2722             return -1
2723         }
2724     fi
2725
2726     #a1# Output version of running grml
2727     alias grml-version='cat /etc/grml_version'
2728
2729     if check_com -c grml-debootstrap ; then
2730         debian2hd() {
2731             echo "Installing debian to harddisk is possible by using grml-debootstrap."
2732             return 1
2733         }
2734     fi
2735 }
2736
2737 # now run the functions
2738 isgrml && checkhome
2739 is4    && isgrml    && grmlstuff
2740 is4    && grmlcomp
2741
2742 # keephack
2743 is4 && xsource "/etc/zsh/keephack"
2744
2745 # wonderful idea of using "e" glob qualifier by Peter Stephenson
2746 # You use it as follows:
2747 # $ NTREF=/reference/file
2748 # $ ls -l *(e:nt:)
2749 # This lists all the files in the current directory newer than the reference file.
2750 # You can also specify the reference file inline; note quotes:
2751 # $ ls -l *(e:'nt ~/.zshenv':)
2752 is4 && nt() {
2753     if [[ -n $1 ]] ; then
2754         local NTREF=${~1}
2755     fi
2756     [[ $REPLY -nt $NTREF ]]
2757 }
2758
2759 # shell functions
2760
2761 #f1# Reload an autoloadable function
2762 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2763 compdef _functions freload
2764
2765 #
2766 # Usage:
2767 #
2768 #      e.g.:   a -> b -> c -> d  ....
2769 #
2770 #      sll a
2771 #
2772 #
2773 #      if parameter is given with leading '=', lookup $PATH for parameter and resolve that
2774 #
2775 #      sll =java
2776 #
2777 #      Note: limit for recursive symlinks on linux:
2778 #            http://git.kernel.org/cgit/linux/kernel/git/torvalds/linux.git/tree/fs/namei.c?id=refs/heads/master#l808
2779 #            This limits recursive symlink follows to 8,
2780 #            while limiting consecutive symlinks to 40.
2781 #
2782 #      When resolving and displaying information about symlinks, no check is made
2783 #      that the displayed information does make any sense on your OS.
2784 #      We leave that decission to the user.
2785 #
2786 #      The zstat module is used to detect symlink loops. zstat is available since zsh4.
2787 #      With an older zsh you will need to abort with <C-c> in that case.
2788 #      When a symlink loop is detected, a warning ist printed and further processing is stopped.
2789 #
2790 #      Module zstat is loaded by default in grml zshrc, no extra action needed for that.
2791 #
2792 #      Known bugs:
2793 #      If you happen to come accross a symlink that points to a destination on an other partition
2794 #      with the same inode number, that will be marked as symlink loop though it is not.
2795 #      Two hints for this situation:
2796 #      I)  Play lottery the same day, as you seem to be rather lucky right now.
2797 #      II) Send patches.
2798 #
2799 #      return status:
2800 #      0 upon success
2801 #      1 file/dir not accesible
2802 #      2 symlink loop detected
2803 #
2804 #f1# List symlinks in detail (more detailed version of 'readlink -f', 'whence -s' and 'namei -l')
2805 sll() {
2806     if [[ -z ${1} ]] ; then
2807         printf 'Usage: %s <symlink(s)>\n' "${0}"
2808         return 1
2809     fi
2810
2811     local file jumpd curdir
2812     local -i RTN LINODE i
2813     local -a SEENINODES
2814     curdir="${PWD}"
2815     RTN=0
2816
2817     for file in "${@}" ; do
2818         SEENINODES=()
2819         ls -l "${file:a}"   || RTN=1
2820
2821         while [[ -h "$file" ]] ; do
2822             if is4 ; then
2823                 LINODE=$(zstat -L +inode "${file}")
2824                 for i in ${SEENINODES} ; do
2825                     if (( ${i} == ${LINODE} )) ; then
2826                         builtin cd "${curdir}"
2827                         print "link loop detected, aborting!"
2828                         return 2
2829                     fi
2830                 done
2831                 SEENINODES+=${LINODE}
2832             fi
2833             jumpd="${file:h}"
2834             file="${file:t}"
2835
2836             if [[ -d ${jumpd} ]] ; then
2837                 builtin cd "${jumpd}"  || RTN=1
2838             fi
2839             file=$(readlink "$file")
2840
2841             jumpd="${file:h}"
2842             file="${file:t}"
2843
2844             if [[ -d ${jumpd} ]] ; then
2845                 builtin cd "${jumpd}"  || RTN=1
2846             fi
2847
2848             ls -l "${PWD}/${file}"     || RTN=1
2849         done
2850         shift 1
2851         if (( ${#} >= 1 )) ; then
2852             print ""
2853         fi
2854         builtin cd "${curdir}"
2855     done
2856     return ${RTN}
2857 }
2858
2859 # TODO: Is it supported to use pager settings like this?
2860 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2861 # with respect to wordsplitting. (ie. ${=PAGER})
2862 if check_com -c $PAGER ; then
2863     #f3# View Debian's changelog of given package(s)
2864     dchange() {
2865         emulate -L zsh
2866         [[ -z "$1" ]] && printf 'Usage: %s <package_name(s)>\n' "$0" && return 1
2867
2868         local package
2869         for package in "$@" ; do
2870             if [[ -r /usr/share/doc/${package}/changelog.Debian.gz ]] ; then
2871                 $PAGER /usr/share/doc/${package}/changelog.Debian.gz
2872             elif [[ -r /usr/share/doc/${package}/changelog.gz ]] ; then
2873                 $PAGER /usr/share/doc/${package}/changelog.gz
2874             elif [[ -r /usr/share/doc/${package}/changelog ]] ; then
2875                 $PAGER /usr/share/doc/${package}/changelog
2876             else
2877                 if check_com -c aptitude ; then
2878                     echo "No changelog for package $package found, using aptitude to retrieve it."
2879                     aptitude changelog "$package"
2880                 elif check_com -c apt-get ; then
2881                     echo "No changelog for package $package found, using apt-get to retrieve it."
2882                     apt-get changelog "$package"
2883                 else
2884                     echo "No changelog for package $package found, sorry."
2885                 fi
2886             fi
2887         done
2888     }
2889     _dchange() { _files -W /usr/share/doc -/ }
2890     compdef _dchange dchange
2891
2892     #f3# View Debian's NEWS of a given package
2893     dnews() {
2894         emulate -L zsh
2895         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2896             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2897         else
2898             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2899                 $PAGER /usr/share/doc/$1/NEWS.gz
2900             else
2901                 echo "No NEWS file for package $1 found, sorry."
2902                 return 1
2903             fi
2904         fi
2905     }
2906     _dnews() { _files -W /usr/share/doc -/ }
2907     compdef _dnews dnews
2908
2909     #f3# View Debian's copyright of a given package
2910     dcopyright() {
2911         emulate -L zsh
2912         if [[ -r /usr/share/doc/$1/copyright ]] ; then
2913             $PAGER /usr/share/doc/$1/copyright
2914         else
2915             echo "No copyright file for package $1 found, sorry."
2916             return 1
2917         fi
2918     }
2919     _dcopyright() { _files -W /usr/share/doc -/ }
2920     compdef _dcopyright dcopyright
2921
2922     #f3# View upstream's changelog of a given package
2923     uchange() {
2924         emulate -L zsh
2925         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2926             $PAGER /usr/share/doc/$1/changelog.gz
2927         else
2928             echo "No changelog for package $1 found, sorry."
2929             return 1
2930         fi
2931     }
2932     _uchange() { _files -W /usr/share/doc -/ }
2933     compdef _uchange uchange
2934 fi
2935
2936 # zsh profiling
2937 profile() {
2938     ZSH_PROFILE_RC=1 zsh "$@"
2939 }
2940
2941 #f1# Edit an alias via zle
2942 edalias() {
2943     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2944 }
2945 compdef _aliases edalias
2946
2947 #f1# Edit a function via zle
2948 edfunc() {
2949     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2950 }
2951 compdef _functions edfunc
2952
2953 # use it e.g. via 'Restart apache2'
2954 #m# f6 Start() \kbd{service \em{process}}\quad\kbd{start}
2955 #m# f6 Restart() \kbd{service \em{process}}\quad\kbd{restart}
2956 #m# f6 Stop() \kbd{service \em{process}}\quad\kbd{stop}
2957 #m# f6 Reload() \kbd{service \em{process}}\quad\kbd{reload}
2958 #m# f6 Force-Reload() \kbd{service \em{process}}\quad\kbd{force-reload}
2959 #m# f6 Status() \kbd{service \em{process}}\quad\kbd{status}
2960 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2961     __start_stop() {
2962         local action_="${1:l}"  # e.g Start/Stop/Restart
2963         local service_="$2"
2964         local param_="$3"
2965
2966         local service_target_="$(readlink /etc/init.d/$service_)"
2967         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2968             # runit
2969             case "${action_}" in
2970                 start) if [[ ! -e /etc/service/$service_ ]]; then
2971                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2972                        else
2973                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2974                        fi ;;
2975                 # there is no reload in runits sysv emulation
2976                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2977                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2978             esac
2979         else
2980             # sysv/sysvinit-utils, upstart
2981             if check_com -c service ; then
2982               $SUDO service "$service_" "${action_}" "$param_"
2983             else
2984               $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2985             fi
2986         fi
2987     }
2988
2989     _grmlinitd() {
2990         local -a scripts
2991         scripts=( /etc/init.d/*(x:t) )
2992         _describe "service startup script" scripts
2993     }
2994
2995     for i in Start Restart Stop Force-Reload Reload Status ; do
2996         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2997         compdef _grmlinitd $i
2998     done
2999     builtin unset -v i
3000 fi
3001
3002 #f1# Provides useful information on globbing
3003 H-Glob() {
3004     echo -e "
3005     /      directories
3006     .      plain files
3007     @      symbolic links
3008     =      sockets
3009     p      named pipes (FIFOs)
3010     *      executable plain files (0100)
3011     %      device files (character or block special)
3012     %b     block special files
3013     %c     character special files
3014     r      owner-readable files (0400)
3015     w      owner-writable files (0200)
3016     x      owner-executable files (0100)
3017     A      group-readable files (0040)
3018     I      group-writable files (0020)
3019     E      group-executable files (0010)
3020     R      world-readable files (0004)
3021     W      world-writable files (0002)
3022     X      world-executable files (0001)
3023     s      setuid files (04000)
3024     S      setgid files (02000)
3025     t      files with the sticky bit (01000)
3026
3027   print *(m-1)          # Files modified up to a day ago
3028   print *(a1)           # Files accessed a day ago
3029   print *(@)            # Just symlinks
3030   print *(Lk+50)        # Files bigger than 50 kilobytes
3031   print *(Lk-50)        # Files smaller than 50 kilobytes
3032   print **/*.c          # All *.c files recursively starting in \$PWD
3033   print **/*.c~file.c   # Same as above, but excluding 'file.c'
3034   print (foo|bar).*     # Files starting with 'foo' or 'bar'
3035   print *~*.*           # All Files that do not contain a dot
3036   chmod 644 *(.^x)      # make all plain non-executable files publically readable
3037   print -l *(.c|.h)     # Lists *.c and *.h
3038   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
3039   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
3040 }
3041 alias help-zshglob=H-Glob
3042
3043 # grep for running process, like: 'any vim'
3044 any() {
3045     emulate -L zsh
3046     unsetopt KSH_ARRAYS
3047     if [[ -z "$1" ]] ; then
3048         echo "any - grep for process(es) by keyword" >&2
3049         echo "Usage: any <keyword>" >&2 ; return 1
3050     else
3051         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
3052     fi
3053 }
3054
3055
3056 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
3057 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
3058 [[ -r /proc/1/maps ]] && \
3059 deswap() {
3060     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
3061     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
3062     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
3063 }
3064
3065 # a wrapper for vim, that deals with title setting
3066 #   VIM_OPTIONS
3067 #       set this array to a set of options to vim you always want
3068 #       to have set when calling vim (in .zshrc.local), like:
3069 #           VIM_OPTIONS=( -p )
3070 #       This will cause vim to send every file given on the
3071 #       commandline to be send to it's own tab (needs vim7).
3072 if check_com vim; then
3073     vim() {
3074         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
3075     }
3076 fi
3077
3078 ssl_hashes=( sha512 sha256 sha1 md5 )
3079
3080 for sh in ${ssl_hashes}; do
3081     eval 'ssl-cert-'${sh}'() {
3082         emulate -L zsh
3083         if [[ -z $1 ]] ; then
3084             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
3085             return 1
3086         fi
3087         openssl x509 -noout -fingerprint -'${sh}' -in $1
3088     }'
3089 done; unset sh
3090
3091 ssl-cert-fingerprints() {
3092     emulate -L zsh
3093     local i
3094     if [[ -z $1 ]] ; then
3095         printf 'usage: ssl-cert-fingerprints <file>\n'
3096         return 1
3097     fi
3098     for i in ${ssl_hashes}
3099         do ssl-cert-$i $1;
3100     done
3101 }
3102
3103 ssl-cert-info() {
3104     emulate -L zsh
3105     if [[ -z $1 ]] ; then
3106         printf 'usage: ssl-cert-info <file>\n'
3107         return 1
3108     fi
3109     openssl x509 -noout -text -in $1
3110     ssl-cert-fingerprints $1
3111 }
3112
3113 # make sure our environment is clean regarding colors
3114 for var in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $var
3115 builtin unset -v var
3116
3117 # "persistent history"
3118 # just write important commands you always need to ~/.important_commands
3119 if [[ -r ~/.important_commands ]] ; then
3120     fc -R ~/.important_commands
3121 fi
3122
3123 # load the lookup subsystem if it's available on the system
3124 zrcautoload lookupinit && lookupinit
3125
3126 # variables
3127
3128 # set terminal property (used e.g. by msgid-chooser)
3129 export COLORTERM="yes"
3130
3131 # aliases
3132
3133 # general
3134 #a2# Execute \kbd{du -sch}
3135 alias da='du -sch'
3136
3137 # listing stuff
3138 #a2# Execute \kbd{ls -lSrah}
3139 alias dir="command ls -lSrah"
3140 #a2# Only show dot-directories
3141 alias lad='command ls -d .*(/)'
3142 #a2# Only show dot-files
3143 alias lsa='command ls -a .*(.)'
3144 #a2# Only files with setgid/setuid/sticky flag
3145 alias lss='command ls -l *(s,S,t)'
3146 #a2# Only show symlinks
3147 alias lsl='command ls -l *(@)'
3148 #a2# Display only executables
3149 alias lsx='command ls -l *(*)'
3150 #a2# Display world-{readable,writable,executable} files
3151 alias lsw='command ls -ld *(R,W,X.^ND/)'
3152 #a2# Display the ten biggest files
3153 alias lsbig="command ls -flh *(.OL[1,10])"
3154 #a2# Only show directories
3155 alias lsd='command ls -d *(/)'
3156 #a2# Only show empty directories
3157 alias lse='command ls -d *(/^F)'
3158 #a2# Display the ten newest files
3159 alias lsnew="command ls -rtlh *(D.om[1,10])"
3160 #a2# Display the ten oldest files
3161 alias lsold="command ls -rtlh *(D.Om[1,10])"
3162 #a2# Display the ten smallest files
3163 alias lssmall="command ls -Srl *(.oL[1,10])"
3164 #a2# Display the ten newest directories and ten newest .directories
3165 alias lsnewdir="command ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
3166 #a2# Display the ten oldest directories and ten oldest .directories
3167 alias lsolddir="command ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
3168
3169 # some useful aliases
3170 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir \$OLDCWD}
3171 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
3172
3173 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3174 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3175 #a2# scp with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3176 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3177
3178 # work around non utf8 capable software in utf environment via $LANG and luit
3179 if check_com isutfenv && check_com luit ; then
3180     if check_com -c mrxvt ; then
3181         isutfenv && [[ -n "$LANG" ]] && \
3182             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3183     fi
3184
3185     if check_com -c aterm ; then
3186         isutfenv && [[ -n "$LANG" ]] && \
3187             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3188     fi
3189
3190     if check_com -c centericq ; then
3191         isutfenv && [[ -n "$LANG" ]] && \
3192             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3193     fi
3194 fi
3195
3196 # useful functions
3197
3198 #f5# Backup \kbd{file_or_folder {\rm to} file_or_folder\_timestamp}
3199 bk() {
3200     emulate -L zsh
3201     local current_date=$(date -u "+%Y-%m-%dT%H:%M:%SZ")
3202     local clean keep move verbose result all to_bk
3203     setopt extended_glob
3204     keep=1
3205     while getopts ":hacmrv" opt; do
3206         case $opt in
3207             a) (( all++ ));;
3208             c) unset move clean && (( ++keep ));;
3209             m) unset keep clean && (( ++move ));;
3210             r) unset move keep && (( ++clean ));;
3211             v) verbose="-v";;
3212             h) <<__EOF0__
3213 bk [-hcmv] FILE [FILE ...]
3214 bk -r [-av] [FILE [FILE ...]]
3215 Backup a file or folder in place and append the timestamp
3216 Remove backups of a file or folder, or all backups in the current directory
3217
3218 Usage:
3219 -h    Display this help text
3220 -c    Keep the file/folder as is, create a copy backup using cp(1) (default)
3221 -m    Move the file/folder, using mv(1)
3222 -r    Remove backups of the specified file or directory, using rm(1). If none
3223       is provided, remove all backups in the current directory.
3224 -a    Remove all (even hidden) backups.
3225 -v    Verbose
3226
3227 The -c, -r and -m options are mutually exclusive. If specified at the same time,
3228 the last one is used.
3229
3230 The return code is the sum of all cp/mv/rm return codes.
3231 __EOF0__
3232 return 0;;
3233             \?) bk -h >&2; return 1;;
3234         esac
3235     done
3236     shift "$((OPTIND-1))"
3237     if (( keep > 0 )); then
3238         if islinux || isfreebsd; then
3239             for to_bk in "$@"; do
3240                 cp $verbose -a "${to_bk%/}" "${to_bk%/}_$current_date"
3241                 (( result += $? ))
3242             done
3243         else
3244             for to_bk in "$@"; do
3245                 cp $verbose -pR "${to_bk%/}" "${to_bk%/}_$current_date"
3246                 (( result += $? ))
3247             done
3248         fi
3249     elif (( move > 0 )); then
3250         while (( $# > 0 )); do
3251             mv $verbose "${1%/}" "${1%/}_$current_date"
3252             (( result += $? ))
3253             shift
3254         done
3255     elif (( clean > 0 )); then
3256         if (( $# > 0 )); then
3257             for to_bk in "$@"; do
3258                 rm $verbose -rf "${to_bk%/}"_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z
3259                 (( result += $? ))
3260             done
3261         else
3262             if (( all > 0 )); then
3263                 rm $verbose -rf *_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z(D)
3264             else
3265                 rm $verbose -rf *_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z
3266             fi
3267             (( result += $? ))
3268         fi
3269     fi
3270     return $result
3271 }
3272
3273 #f5# cd to directoy and list files
3274 cl() {
3275     emulate -L zsh
3276     cd $1 && ls -a
3277 }
3278
3279 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
3280 cd() {
3281     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
3282         [[ ! -e ${1:h} ]] && return 1
3283         print "Correcting ${1} to ${1:h}"
3284         builtin cd ${1:h}
3285     else
3286         builtin cd "$@"
3287     fi
3288 }
3289
3290 #f5# Create Directoy and \kbd{cd} to it
3291 mkcd() {
3292     if (( ARGC != 1 )); then
3293         printf 'usage: mkcd <new-directory>\n'
3294         return 1;
3295     fi
3296     if [[ ! -d "$1" ]]; then
3297         command mkdir -p "$1"
3298     else
3299         printf '`%s'\'' already exists: cd-ing.\n' "$1"
3300     fi
3301     builtin cd "$1"
3302 }
3303
3304 #f5# Create temporary directory and \kbd{cd} to it
3305 cdt() {
3306     builtin cd "$(mktemp -d)"
3307     builtin pwd
3308 }
3309
3310 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
3311 accessed() {
3312     emulate -L zsh
3313     print -l -- *(a-${1:-1})
3314 }
3315
3316 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
3317 changed() {
3318     emulate -L zsh
3319     print -l -- *(c-${1:-1})
3320 }
3321
3322 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
3323 modified() {
3324     emulate -L zsh
3325     print -l -- *(m-${1:-1})
3326 }
3327 # modified() was named new() in earlier versions, add an alias for backwards compatibility
3328 check_com new || alias new=modified
3329
3330 # use colors when GNU grep with color-support
3331 if (( $#grep_options > 0 )); then
3332     o=${grep_options:+"${grep_options[*]}"}
3333     #a2# Execute \kbd{grep -{}-color=auto}
3334     alias grep='grep '$o
3335     alias egrep='egrep '$o
3336     unset o
3337 fi
3338
3339 # Translate DE<=>EN
3340 # 'translate' looks up a word in a file with language-to-language
3341 # translations (field separator should be " : "). A typical wordlist looks
3342 # like the following:
3343 #  | english-word : german-translation
3344 # It's also only possible to translate english to german but not reciprocal.
3345 # Use the following oneliner to reverse the sort order:
3346 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3347 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3348 #f5# Translates a word
3349 trans() {
3350     emulate -L zsh
3351     case "$1" in
3352         -[dD]*)
3353             translate -l de-en $2
3354             ;;
3355         -[eE]*)
3356             translate -l en-de $2
3357             ;;
3358         *)
3359             echo "Usage: $0 { -D | -E }"
3360             echo "         -D == German to English"
3361             echo "         -E == English to German"
3362     esac
3363 }
3364
3365 # Usage: simple-extract <file>
3366 # Using option -d deletes the original archive file.
3367 #f5# Smart archive extractor
3368 simple-extract() {
3369     emulate -L zsh
3370     setopt extended_glob noclobber
3371     local ARCHIVE DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
3372     local RC=0
3373     zparseopts -D -E "d=DELETE_ORIGINAL"
3374     for ARCHIVE in "${@}"; do
3375         case $ARCHIVE in
3376             *(tar.bz2|tbz2|tbz))
3377                 DECOMP_CMD="tar -xvjf -"
3378                 USES_STDIN=true
3379                 USES_STDOUT=false
3380                 ;;
3381             *(tar.gz|tgz))
3382                 DECOMP_CMD="tar -xvzf -"
3383                 USES_STDIN=true
3384                 USES_STDOUT=false
3385                 ;;
3386             *(tar.xz|txz|tar.lzma))
3387                 DECOMP_CMD="tar -xvJf -"
3388                 USES_STDIN=true
3389                 USES_STDOUT=false
3390                 ;;
3391             *tar)
3392                 DECOMP_CMD="tar -xvf -"
3393                 USES_STDIN=true
3394                 USES_STDOUT=false
3395                 ;;
3396             *rar)
3397                 DECOMP_CMD="unrar x"
3398                 USES_STDIN=false
3399                 USES_STDOUT=false
3400                 ;;
3401             *lzh)
3402                 DECOMP_CMD="lha x"
3403                 USES_STDIN=false
3404                 USES_STDOUT=false
3405                 ;;
3406             *7z)
3407                 DECOMP_CMD="7z x"
3408                 USES_STDIN=false
3409                 USES_STDOUT=false
3410                 ;;
3411             *(zip|jar))
3412                 DECOMP_CMD="unzip"
3413                 USES_STDIN=false
3414                 USES_STDOUT=false
3415                 ;;
3416             *deb)
3417                 DECOMP_CMD="ar -x"
3418                 USES_STDIN=false
3419                 USES_STDOUT=false
3420                 ;;
3421             *bz2)
3422                 DECOMP_CMD="bzip2 -d -c -"
3423                 USES_STDIN=true
3424                 USES_STDOUT=true
3425                 ;;
3426             *(gz|Z))
3427                 DECOMP_CMD="gzip -d -c -"
3428                 USES_STDIN=true
3429                 USES_STDOUT=true
3430                 ;;
3431             *(xz|lzma))
3432                 DECOMP_CMD="xz -d -c -"
3433                 USES_STDIN=true
3434                 USES_STDOUT=true
3435                 ;;
3436             *)
3437                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
3438                 RC=$((RC+1))
3439                 continue
3440                 ;;
3441         esac
3442
3443         if ! check_com ${DECOMP_CMD[(w)1]}; then
3444             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
3445             RC=$((RC+2))
3446             continue
3447         fi
3448
3449         GZTARGET="${ARCHIVE:t:r}"
3450         if [[ -f $ARCHIVE ]] ; then
3451
3452             print "Extracting '$ARCHIVE' ..."
3453             if $USES_STDIN; then
3454                 if $USES_STDOUT; then
3455                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
3456                 else
3457                     ${=DECOMP_CMD} < "$ARCHIVE"
3458                 fi
3459             else
3460                 if $USES_STDOUT; then
3461                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
3462                 else
3463                     ${=DECOMP_CMD} "$ARCHIVE"
3464                 fi
3465             fi
3466             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
3467
3468         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
3469             if check_com curl; then
3470                 WGET_CMD="curl -L -s -o -"
3471             elif check_com wget; then
3472                 WGET_CMD="wget -q -O -"
3473             elif check_com fetch; then
3474                 WGET_CMD="fetch -q -o -"
3475             else
3476                 print "ERROR: neither wget, curl nor fetch is installed" >&2
3477                 RC=$((RC+4))
3478                 continue
3479             fi
3480             print "Downloading and Extracting '$ARCHIVE' ..."
3481             if $USES_STDIN; then
3482                 if $USES_STDOUT; then
3483                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
3484                     RC=$((RC+$?))
3485                 else
3486                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
3487                     RC=$((RC+$?))
3488                 fi
3489             else
3490                 if $USES_STDOUT; then
3491                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
3492                 else
3493                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
3494                 fi
3495             fi
3496
3497         else
3498             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
3499             RC=$((RC+8))
3500         fi
3501     done
3502     return $RC
3503 }
3504
3505 __archive_or_uri()
3506 {
3507     _alternative \
3508         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
3509         '_urls:Remote Archives:_urls'
3510 }
3511
3512 _simple_extract()
3513 {
3514     _arguments \
3515         '-d[delete original archivefile after extraction]' \
3516         '*:Archive Or Uri:__archive_or_uri'
3517 }
3518 compdef _simple_extract simple-extract
3519 alias se=simple-extract
3520
3521 #f5# Change the xterm title from within GNU-screen
3522 xtrename() {
3523     emulate -L zsh
3524     if [[ $1 != "-f" ]] ; then
3525         if [[ -z ${DISPLAY} ]] ; then
3526             printf 'xtrename only makes sense in X11.\n'
3527             return 1
3528         fi
3529     else
3530         shift
3531     fi
3532     if [[ -z $1 ]] ; then
3533         printf 'usage: xtrename [-f] "title for xterm"\n'
3534         printf '  renames the title of xterm from _within_ screen.\n'
3535         printf '  also works without screen.\n'
3536         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3537         return 0
3538     fi
3539     print -n "\eP\e]0;${1}\C-G\e\\"
3540     return 0
3541 }
3542
3543 # Create small urls via http://goo.gl using curl(1).
3544 # API reference: https://code.google.com/apis/urlshortener/
3545 function zurl() {
3546     emulate -L zsh
3547     setopt extended_glob
3548
3549     if [[ -z $1 ]]; then
3550         print "USAGE: zurl <URL>"
3551         return 1
3552     fi
3553
3554     local PN url prog api json contenttype item
3555     local -a data
3556     PN=$0
3557     url=$1
3558
3559     # Prepend 'http://' to given URL where necessary for later output.
3560     if [[ ${url} != http(s|)://* ]]; then
3561         url='http://'${url}
3562     fi
3563
3564     if check_com -c curl; then
3565         prog=curl
3566     else
3567         print "curl is not available, but mandatory for ${PN}. Aborting."
3568         return 1
3569     fi
3570     api='https://www.googleapis.com/urlshortener/v1/url'
3571     contenttype="Content-Type: application/json"
3572     json="{\"longUrl\": \"${url}\"}"
3573     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
3574     # Parse the response
3575     for item in "${data[@]}"; do
3576         case "$item" in
3577             ' '#'"id":'*)
3578                 item=${item#*: \"}
3579                 item=${item%\",*}
3580                 printf '%s\n' "$item"
3581                 return 0
3582                 ;;
3583         esac
3584     done
3585     return 1
3586 }
3587
3588 #f2# Find history events by search pattern and list them by date.
3589 whatwhen()  {
3590     emulate -L zsh
3591     local usage help ident format_l format_s first_char remain first last
3592     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3593     help='Use `whatwhen -h'\'' for further explanations.'
3594     ident=${(l,${#${:-Usage: }},, ,)}
3595     format_l="${ident}%s\t\t\t%s\n"
3596     format_s="${format_l//(\\t)##/\\t}"
3597     # Make the first char of the word to search for case
3598     # insensitive; e.g. [aA]
3599     first_char=[${(L)1[1]}${(U)1[1]}]
3600     remain=${1[2,-1]}
3601     # Default search range is `-100'.
3602     first=${2:-\-100}
3603     # Optional, just used for `<first> <last>' given.
3604     last=$3
3605     case $1 in
3606         ("")
3607             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3608             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3609         ;;
3610         (-h)
3611             printf '%s\n\n' ${usage}
3612             print 'OPTIONS:'
3613             printf $format_l '-h' 'show help text'
3614             print '\f'
3615             print 'SEARCH RANGE:'
3616             printf $format_l "'0'" 'the whole history,'
3617             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
3618             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
3619             printf '\n%s\n' 'EXAMPLES:'
3620             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
3621             printf $format_l 'whatwhen zsh -250'
3622             printf $format_l 'whatwhen foo 1 99'
3623         ;;
3624         (\?)
3625             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3626         ;;
3627         (*)
3628             # -l list results on stout rather than invoking $EDITOR.
3629             # -i Print dates as in YYYY-MM-DD.
3630             # -m Search for a - quoted - pattern within the history.
3631             fc -li -m "*${first_char}${remain}*" $first $last
3632         ;;
3633     esac
3634 }
3635
3636 # mercurial related stuff
3637 if check_com -c hg ; then
3638     # gnu like diff for mercurial
3639     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
3640     #f5# GNU like diff for mercurial
3641     hgdi() {
3642         emulate -L zsh
3643         local i
3644         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
3645     }
3646
3647     # build debian package
3648     #a2# Alias for \kbd{hg-buildpackage}
3649     alias hbp='hg-buildpackage'
3650
3651     # execute commands on the versioned patch-queue from the current repos
3652     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
3653
3654     # diffstat for specific version of a mercurial repository
3655     #   hgstat      => display diffstat between last revision and tip
3656     #   hgstat 1234 => display diffstat between revision 1234 and tip
3657     #f5# Diffstat for specific version of a mercurial repos
3658     hgstat() {
3659         emulate -L zsh
3660         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
3661     }
3662
3663 fi # end of check whether we have the 'hg'-executable
3664
3665 # grml-small cleanups
3666
3667 # The following is used to remove zsh-config-items that do not work
3668 # in grml-small by default.
3669 # If you do not want these adjustments (for whatever reason), set
3670 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
3671 # sources if it is there).
3672
3673 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
3674
3675     unset abk[V]
3676     unalias    'V'      &> /dev/null
3677     unfunction vman     &> /dev/null
3678     unfunction viless   &> /dev/null
3679     unfunction 2html    &> /dev/null
3680
3681     # manpages are not in grmlsmall
3682     unfunction manzsh   &> /dev/null
3683     unfunction man2     &> /dev/null
3684
3685 fi
3686
3687 zrclocal
3688
3689 ## genrefcard.pl settings
3690
3691 ### doc strings for external functions from files
3692 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
3693
3694 ### example: split functions-search 8,16,24,32
3695 #@# split functions-search 8
3696
3697 ## END OF FILE #################################################################
3698 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
3699 # Local variables:
3700 # mode: sh
3701 # End: