Merge branch 'master' of git://git.grml.org/grml-infrastructure
[grml-infrastructure.git] / source-report / get_sources
1 #!/usr/bin/perl
2 # Filename:      get_sources 
3 # Purpose:       Fetches sources and creates to report 
4 # Authors:       grml-team (grml.org), (c) Alexander Wirt
5 # Bug-Reports:   see http://grml.org/bugs/
6 # License:       This file is licensed under the GPL v2.
7 # Latest change: So Mai 06 02:18:45 CEST 2007 [formorer]
8 ################################################################################
9
10 use strict; 
11 use warnings;
12 use English;
13
14 use LWP::Simple qw(!head);
15 use Data::Dumper; 
16 use HTML::Table;
17 use CGI qw/:standard/;
18 use YAML qw( LoadFile );
19 use Params::Validate qw(:all);
20 use File::Copy;
21 use Digest::MD5; 
22
23
24 #validates the configfile
25 sub validate_config ($) {
26         validate_with(
27                         params => \@_,
28                         spec => {
29                                 title => { type => SCALAR },
30                                 statusfile => { type => SCALAR },
31                                 sourcedir => { type => SCALAR },
32                                 sourceslist => { type => SCALAR }, 
33                                 baseurl => { type => SCALAR },
34                                 chroot => { type => SCALAR },
35                                 reportdir => { type => SCALAR },
36                                 debug => { type => SCALAR, regex => qr/^(1|0)$/, optional => 1},
37                                 alternativeurl => { type => HASHREF, optional => 1}, 
38                                 updatesource => { type => SCALAR, regex => qr/^(1|0)$/, optional => 1},
39                                 },
40                         on_fail => sub { print STDERR "Could not validate configfile: @_"; exit -1},
41
42                         )
43 }
44
45 sub md5_from_file($) {
46         my $file = shift;
47         die "'$file' does not exist" unless -f $file;
48         open(my $fh, '<', $file)
49                 or die "Can't open '$file': $!";     
50         binmode($fh); 
51         my $md5sum = Digest::MD5->new->addfile(*$fh)->hexdigest;
52         return $md5sum; 
53 }
54
55 my $configfile = shift; 
56 die "Usage: $0 <configfile>" unless $configfile && -f $configfile; 
57
58 my $config = LoadFile($configfile); 
59 validate_config($config); 
60 my $debug = $config->{debug} || 0; 
61
62 # if we can't write our reports and packages we can die soon ;) 
63 if (! -d $config->{reportdir}) {
64         mkdir $config->{reportdir}
65                 or die "Could not create reportdir '".$config->{reportdir}."':$!"; 
66 } else {
67     #if the sourcedir already exists we have to clean it up first
68     system("rm -rf ".$config->{reportdir}."/*"); 
69     if ($? == -1) {
70         die "Could not remove old reportdir '".$config->{reportdir}.":$!"; 
71     }
72 }
73
74 if (! -d $config->{sourcedir}) {
75         mkdir $config->{sourcedir}
76                 or die "Could not create sourcedir '".$config->{sourcedir}."':$!"; 
77 }
78
79 #fsrst build a package tree 
80 die "Status file '".$config->{statusfile}."' not found" unless -f $config->{statusfile}; 
81
82 open (my $fh, '<', $config->{statusfile}) or die "Could not open status file '".$config->{statusfile}."': $!";
83 my ($package_tree, $package, $version, $source); 
84 my $linenum = 0; 
85 while (my $line = <$fh>) {
86         $linenum++; 
87         chomp $line; 
88         if ($line =~ /^Package: (.*)/) {
89                 $package = $1; 
90         } elsif ($line =~ /^Version: (.*)/){
91                 $version = $1; 
92         } elsif ($line =~ /Source: (.*)/){
93                 if ($1 =~ /^(\S+) \(([^)]+)\)$/) {
94                         $source = $1; 
95                         $version = $2; 
96                 } else {
97                         $source = $1; 
98                 }
99         } elsif ($line =~ /^$/) { #finalizing
100                 $source = $source || $package; 
101         
102                                 #filter out binary nmus 
103                 if ($version =~ /^(.*)\+b/) {
104                         $version = $1;
105                 } elsif ($version =~ /(.*-.*)\.0\.\d+$/) { #old bin nmu 
106                         $version = $1; 
107                 } elsif ($version =~ /(.*-.*\.0)\.\d+$/) { #also old binnmu 
108                         $version = $1; 
109                 }
110                 if ($version && $source && $package) {
111                         $package_tree->{$package}->{'version'} = $version;
112                         $package_tree->{$package}->{'source'} = $source; 
113                 } else {
114                         print STDERR "Finalizing of ($linenum) not possible: package='$package', source='$source', version='$version'";
115                 }
116                 ($source, $package, $version) = '';
117         }
118 }
119
120 close ($fh); 
121
122 #if we provide our own sources list it will be copied into the chroot
123 if ($config->{sourceslist} && -f $config->{sourceslist}) {
124         print "Copy sourceslist into chroot\n" if $debug; 
125         copy($config->{sourceslist},"apt/etc/sources.list") or die "Sources list cannot be copied: $!";
126 }
127
128 #update chroot
129 system ("apt-get -c=apt-config update") if $config->{updatesource}; 
130
131 foreach my $package (keys %{$package_tree}) {
132         print "Working on $package\n" if $debug;
133         my $error = 0; 
134         my $version = $package_tree->{$package}->{'version'}; 
135         my $source = $package_tree->{$package}->{'source'}; 
136         if (exists $config->{alternativeurl}->{$source}) {
137                         print "Alternativ URL for $source => " . $config->{alternativeurl}->{$source} . "\n" if $debug;
138                         $package_tree->{$package}->{'status'} = 'OK/External';
139                         $package_tree->{$package}->{'url'} = $config->{alternativeurl}->{$source};
140                         next; 
141         }
142         $package_tree->{$package}->{'errors'} = (); 
143         open (my $fh, '-|', "apt-get -c=apt-config --print-uris -d source $source=$version 2>&1 ") 
144                 or warn "Could not launch apt-get command:$!"; 
145         while (my $line = <$fh>) {
146                 chomp $line;
147                 if ($line =~ /^'([^']+)'\s+(\S+)\s+(\S+)\s+(\S+)/) {
148                         my $uri = $1;
149                         my $filename = $2;
150                         my $size = $3; 
151                         my $md5sum = $4;
152                         $md5sum =~ s/^MD5Sum://;
153                         print "Filename: $filename\n" if $debug;
154                         if (! -d $config->{reportdir}."/$source") {
155                                 mkdir ($config->{reportdir}."/$source") 
156                                         or die "Could not create package dir '".$config->{reportdir}."/$source':$!"; 
157                         }
158                         if (! -d $config->{sourcedir}."/$source") {
159                                 mkdir ($config->{sourcedir}."/$source") 
160                                         or die "Could not create package dir '".$config->{sourcedir}."/$source':$!"; 
161                         }
162                         my $status = 0; 
163                         if ( -e $config->{sourcedir}."/$source/$filename" ) {
164                                 if ($md5sum eq md5_from_file($config->{sourcedir}."/$source/$filename")) {
165                                         print $config->{sourcedir}."/$source/$filename already downloaded\n" if $debug;
166                                         $status = 1; 
167                                 } else { 
168                                         print $config->{sourcedir}."/$source/$filename corrupt - download again\n" if $debug; 
169                                 }
170                         
171                         }
172                         if ($status == 0)  {
173                                 print "Getting uri '$uri' to ".$config->{sourcedir}. "/$source/$filename\n" if $debug;
174                                 my $ret = getstore($uri, $config->{sourcedir}."/$source/$filename");
175                                 if ($ret != 200) {
176                                         print STDERR "Could not download $uri - Server returned: " . status_message($ret) . "\n"; 
177                                         push @{$package_tree->{$package}->{'errors'}}, "$uri failed: " . status_message($ret); 
178                                         $error =1; 
179                                 } 
180
181                                 if ($md5sum eq md5_from_file($config->{sourcedir}."/$source/$filename") ) {
182                                         open (my $urifh, '>', $config->{sourcedir}."/$source/$filename.md5") 
183                                                 or die "Could not open " . $config->{sourcedir}."/$source/$filename.md5 for writing: $!";
184                                         print $urifh $md5sum; 
185                                         close $urifh;
186                                         open ($urifh, '>', $config->{sourcedir}."/$source/$filename.uri")
187                                                 or die "Could not open " . $config->{sourcedir}."/$source/$filename.uri for writing: $!";
188                                         print $urifh "$uri\n";
189                                         close $urifh; 
190                                 } else {
191                                         print STDERR "md5sum mismatch of $uri\n";
192                                         push @{$package_tree->{$package}->{'errors'}}, "$uri failed: md5sum mismatch";
193                                         $error =1; 
194                                 }
195                         }
196                         if (! $error) {
197                                 print "Creating links\n" if $debug; 
198                                 link $config->{sourcedir}."/$source/$filename",$config->{reportdir}."/$source/$filename";
199                                 link $config->{sourcedir}."/$source/$filename.uri",$config->{reportdir}."/$source/$filename.uri";
200                                 link $config->{sourcedir}."/$source/$filename.md5",$config->{reportdir}."/$source/$filename.md5";
201                         }
202                 } elsif ($line =~ /^E: (.*)/) {
203                         push @{$package_tree->{$package}->{'errors'}}, "$1";
204                         print STDERR "Got an error from apt-get for package $package (Source: $source, Version: $version): $1\n";
205                         $error = 1; 
206                 }
207         }
208         close ($fh);
209         if ($error) {
210                 print "Package $package failed:\n" if $debug;
211                 print join("\n", @{$package_tree->{$package}->{'errors'}}) . "\n" if $debug;
212                 $package_tree->{$package}->{'status'} = 'FAILED';
213         } else {
214                 print "Package $package successfull\n" if $debug;
215                 $package_tree->{$package}->{'status'} = 'OK'; 
216         }
217 }
218
219 my $t = new HTML::Table( 
220                                 -cols => 4, 
221                                 -border=>1,
222                                 -head=> ['Package','Source','Version', 'Status'],
223                         );
224 foreach my $package (sort(keys %{$package_tree})) {
225         if ($package_tree->{$package}->{'status'} eq 'OK') {
226         $t->addRow(     $package,
227                         "<a href='". $package_tree->{$package}->{'source'} . "'>" . $package_tree->{$package}->{'source'} . "</a>",
228                         $package_tree->{$package}->{'version'},
229                         $package_tree->{$package}->{'status'}
230                 );
231         } elsif ($package_tree->{$package}->{'status'} eq 'FAILED') {
232                 open (my $fh, '>', $config->{reportdir}."/$package-error.html") 
233                         or die "Could not create error file '".$config->{reportdir}."/$package-error.html': $!"; 
234                 print $fh start_html("Errors for $package (" . $package_tree->{$package}->{'version'} . ")");
235                 print $fh "<h2>Errors for $package (". $package_tree->{$package}->{'version'} . ")</h2>";
236                 print $fh join("<br>\n", @{$package_tree->{$package}->{'errors'}}); 
237                 print $fh "<br><br><a href='index.html'>Back to index</a>";
238                 print $fh end_html; 
239                 close ($fh); 
240                 $t->addRow(     $package,
241                                 $package_tree->{$package}->{'source'},
242                                 $package_tree->{$package}->{'version'},
243                                 "<a href='$package-error.html'>".$package_tree->{$package}->{'status'}."</a>"
244                         );
245         } elsif ($package_tree->{$package}->{'status'} eq 'OK/External') {
246                 $t->addRow(     $package,
247                                 "<a href='".$package_tree->{$package}->{'url'} . "'>" . $package_tree->{$package}->{'source'} . "</a>",
248                                 $package_tree->{$package}->{'version'},
249                                 $package_tree->{$package}->{'status'}
250                         );
251         }
252 }
253
254
255 copy("apt/etc/sources.list", $config->{reportdir}."/sources.list") or die "Sources list cannot be copied: $!";
256
257 #first some statistics 
258 my $pnum = keys(%{$package_tree}); 
259 my %s_hash; 
260 my $errors = 0;
261 foreach my $package (keys(%{$package_tree})) {
262         $errors++ if $package_tree->{$package}->{'status'} !~ /^OK/; 
263         if (! exists  $s_hash{ $package_tree->{$package}->{'source'} }) {
264                 $s_hash{$package_tree->{$package}->{'source'}} = 1; 
265         }
266 }
267
268 my $snum = keys(%s_hash); 
269 open ($fh, '>', $config->{reportdir}."/index.html") or die "Could not create indexfile '".$config->{reportdir}."/index.html': $!";
270 print $fh start_html("Report for " . $config->{title}); 
271 print $fh "<center><h2>Report for " . $config->{title} . "</h2>";
272 print $fh "<b>Packages:</b> $pnum<br>"; 
273 print $fh "<b>Sources:</b> $snum<br>";
274 print $fh "<b>Errors:</b> $errors (" . $errors/$snum*100 . "%)<br>"; 
275 print $fh "<a href='sources.list'>Sources list of the chroot</a><br><br>"; 
276 print $fh "<b>Use:</b><i> deb-src " . $config->{'baseurl'} . " ./</i><br> "; 
277 print $fh "in your sources.list to get files via apt-get<br><br>";
278 print $fh $t;
279 print $fh end_html;
280 close ($fh); 
281
282 open ($fh, '>', $config->{reportdir}."/status.txt") 
283         or die "Could not create statusfile '".$config->{reportdir}."/status.txt': $!";
284
285 print $fh "Updated: " . localtime() . "\n"; 
286 print $fh "Title: " . $config->{title} . "\n"; 
287 print $fh "Baseurl: " . $config->{baseurl} . "\n"; 
288 print $fh "Packages: $pnum\n";
289 print $fh "Sources: $snum\n";
290 print $fh "Errors: $errors\n"; 
291
292 system ("cd " . $config->{reportdir} . "; dpkg-scansources . | gzip -9 > Sources.gz");