etc/skel/.zshrc

   1 # Filename:      .zshrc
   2 # Purpose:       config file for zsh
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 # Latest change: Don Dez 06 23:27:51 CET 2007 [mika]
   7 ################################################################################
   8
   9 # source ~/.zshrc.global {{{
  10
  11 # see /etc/zsh/zshrc for some general settings
  12 # If you don't have write permissions to /etc/zsh/zshrc on your own
  13 # copy the file to your $HOME as /.zshrc.global and we source it:
  14
  15 # Note, that xsource() is defined in the global file, so here,
  16 # we will have to do the sourcing manually for once:
  17
  18      [[ -z "$ZSHRC_GLOBAL_HAS_BEEN_READ" ]]  \
  19      && [[ -r "${HOME}/.zshrc.global" ]]     \
  20          && source "${HOME}/.zshrc.global"
  21 # }}}
  22
  23 # check whether global file has been read {{{
  24 if [[ -z "$ZSHRC_GLOBAL_HAS_BEEN_READ" ]] ; then
  25     print 'Warning: global zsh config has not been read.' >&2
  26     print '         prepare for possible errors!'         >&2
  27 fi
  28 # }}}
  29
  30 # autoloading stuff {{{
  31 # associate types and extensions (be aware with perl scripts and anwanted behaviour!)
  32 #  check_com zsh-mime-setup || { autoload zsh-mime-setup && zsh-mime-setup }
  33 #  alias -s pl='perl -S'
  34 # }}}
  35
  36 # completion system {{{
  37 # just make sure it is loaded in this file too
  38 check_com compinit || { autoload -U compinit && compinit }
  39 # }}}
  40
  41 # make sure isgrmlsmall is defined {{{
  42 check_com isgrmlsmall || function isgrmlsmall () { return 1 }
  43 # }}}
  44
  45 ## variables {{{
  46
  47 # do you want grmlsmall-specific adjustments?
  48 GRMLSMALL_SPECIFIC=1
  49
  50 # set terminal property (used e.g. by msgid-chooser)
  51 export COLORTERM="yes"
  52
  53 # set default browser
  54 if [[ -z "$BROWSER" ]] ; then
  55     if [[ -n "$DISPLAY" ]] ; then
  56         #v# If X11 is running
  57         check_com -c firefox && export BROWSER=firefox
  58     else
  59         #v# If no X11 is running
  60         check_com -c w3m && export BROWSER=w3m
  61     fi
  62 fi
  63 #v#
  64 (( ${+PAGER} )) || export PAGER="less"
  65
  66 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
  67 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
  68 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
  69
  70 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
  71 #v# [for non-root only]
  72 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
  73 # }}}
  74
  75 ## set options {{{
  76
  77 # Allow comments even in interactive shells i. e.
  78 # $ uname # This command prints system informations
  79 # zsh: bad pattern: #
  80 # $ setopt interactivecomments
  81 # $ uname # This command prints system informations
  82 # Linux
  83 #  setopt interactivecomments
  84
  85 # ctrl-s will no longer freeze the terminal.
  86 #  stty erase "^?"
  87
  88 # }}}
  89
  90 # {{{ global aliases
  91 # These do not have to be at the beginning of the command line.
  92 # Avoid typing cd ../../ for going two dirs down and so on
  93 # Usage, e.g.: "$ cd ...' or just '$ ...' with 'setopt auto_cd'
  94 # Notice: deactivated by 061112 by default, we use another approach
  95 # known as "power completion / abbreviation expansion"
  96 #  alias -g '...'='../..'
  97 #  alias -g '....'='../../..'
  98 #  alias -g BG='& exit'
  99 #  alias -g C='|wc -l'
 100 #  alias -g G='|grep'
 101 #  alias -g H='|head'
 102 #  alias -g Hl=' --help |& less -r'
 103 #  alias -g K='|keep'
 104 #  alias -g L='|less'
 105 #  alias -g LL='|& less -r'
 106 #  alias -g M='|most'
 107 #  alias -g N='&>/dev/null'
 108 #  alias -g R='| tr A-z N-za-m'
 109 #  alias -g SL='| sort | less'
 110 #  alias -g S='| sort'
 111 #  alias -g T='|tail'
 112 #  alias -g V='| vim -'
 113 # }}}
 114
 115 ## aliases {{{
 116
 117 # Xterm resizing-fu.
 118 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
 119 alias hide='echo -en "\033]50;nil2\007"'
 120 alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
 121 alias small='echo -en "\033]50;6x10\007"'
 122 alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
 123 alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
 124 alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
 125 alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
 126 alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
 127 alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
 128 #  if [[ "$TERM" == "xterm" ]] && [[ "$LINES" -ge 50 ]] && [[ "$COLUMNS" -ge 100 ]] && [[ -z "$SSH_CONNECTION" ]] ; then
 129 #          large
 130 #  fi
 131
 132 # general
 133 #a2# Execute \kbd{du -sch}
 134 alias da='du -sch'
 135 #a2# Execute \kbd{jobs -l}
 136 alias j='jobs -l'
 137 #  alias u='translate -i'          # translate
 138
 139 # compile stuff
 140 #a2# Execute \kbd{./configure}
 141 alias CO="./configure"
 142 #a2# Execute \kbd{./configure --help}
 143 alias CH="./configure --help"
 144
 145 # http://conkeror.mozdev.org/
 146 #a2# Run a keyboard driven firefox
 147 alias conkeror='firefox -chrome chrome://conkeror/content'
 148
 149 # arch/tla stuff
 150 if check_com -c tla ; then
 151     #a2# Execute \kbd{tla what-changed --diffs | less}
 152     alias tdi='tla what-changed --diffs | less'
 153     #a2# Execute \kbd{tla-buildpackage}
 154     alias tbp='tla-buildpackage'
 155     #a2# Execute \kbd{tla archive-mirror}
 156     alias tmi='tla archive-mirror'
 157     #a2# Execute \kbd{tla commit}
 158     alias tco='tla commit'
 159     #a2# Execute \kbd{tla star-merge}
 160     alias tme='tla star-merge'
 161 fi
 162
 163 # listing stuff
 164 #a2# Execute \kbd{ls -lSrah}
 165 alias dir="ls -lSrah"
 166 #a2# Only show dot-directories
 167 alias lad='ls -d .*(/)'                # only show dot-directories
 168 #a2# Only show dot-files
 169 alias lsa='ls -a .*(.)'                # only show dot-files
 170 #a2# Only files with setgid/setuid/sticky flag
 171 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
 172 #a2# Only show 1st ten symlinks
 173 alias lsl='ls -l *(@[1,10])'           # only symlinks
 174 #a2# Display only executables
 175 alias lsx='ls -l *(*[1,10])'           # only executables
 176 #a2# Display world-{readable,writable,executable} files
 177 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
 178 #a2# Display the ten biggest files
 179 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
 180 #a2# Only show directories
 181 alias lsd='ls -d *(/)'                 # only show directories
 182 #a2# Only show empty directories
 183 alias lse='ls -d *(/^F)'               # only show empty directories
 184 #a2# Display the ten newest files
 185 alias lsnew="ls -rl *(D.om[1,10])"     # display the newest files
 186 #a2# Display the ten oldest files
 187 alias lsold="ls -rtlh *(D.om[1,10])"   # display the oldest files
 188 #a2# Display the ten smallest files
 189 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
 190
 191 # chmod
 192 #a2# Execute \kbd{chmod 600}
 193 alias rw-='chmod 600'
 194 #a2# Execute \kbd{chmod 700}
 195 alias rwx='chmod 700'
 196 #m# a2 r-{}- Execute \kbd{chmod 644}
 197 alias r--='chmod 644'
 198 #a2# Execute \kbd{chmod 755}
 199 alias r-x='chmod 755'
 200
 201 # some useful aliases
 202 #a2# Execute \kbd{mkdir -o}
 203 alias md='mkdir -p'
 204
 205 check_com -c ipython && alias ips='ipython -p sh'
 206
 207 # console stuff
 208 #a2# Execute \kbd{mplayer -vo fbdev}
 209 alias cmplayer='mplayer -vo fbdev'
 210 #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
 211 alias fbmplayer='mplayer -vo fbdev -fs -zoom'
 212 #a2# Execute \kbd{links2 -driver fb}
 213 alias fblinks='links2 -driver fb'
 214
 215 # ignore ~/.ssh/known_hosts entries
 216 #  alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null" -o "PreferredAuthentications=keyboard-interactive"'
 217 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
 218 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 219 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 220
 221 # Use 'g' instead of 'git':
 222 check_com g || alias g='git'
 223
 224 # use colors when browsing man pages, but only if not using LESS_TERMCAP_* from /etc/zsh/zshenv:
 225 if [[ -z "$LESS_TERMCAP_md" ]] ; then
 226     [[ -d ~/.terminfo/ ]] && alias man='TERMINFO=~/.terminfo/ LESS=C TERM=mostlike PAGER=less man'
 227 fi
 228
 229 # check whether Debian's package management (dpkg) is running
 230 if check_com salias ; then
 231     #a2# Check whether a dpkg instance is currently running
 232     salias check_dpkg_running="dpkg_running"
 233 fi
 234
 235 # work around non utf8 capable software in utf environment via $LANG and luit
 236 if check_com isutfenv && check_com luit ; then
 237     if check_com -c mrxvt ; then
 238         isutfenv && [[ -n "$LANG" ]] && \
 239             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
 240     fi
 241
 242     if check_com -c aterm ; then
 243         isutfenv && [[ -n "$LANG" ]] && \
 244             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
 245     fi
 246
 247     if check_com -c centericq ; then
 248         isutfenv && [[ -n "$LANG" ]] && \
 249             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
 250     fi
 251 fi
 252 # }}}
 253
 254 ## useful functions {{{
 255
 256 # searching
 257 #f4# Search for newspostings from authors
 258 agoogle() { ${=BROWSER} "http://groups.google.com/groups?as_uauthors=$*" ; }
 259 #f4# Search Debian Bug Tracking System by BugID in mbox format
 260 debbug()  { ${=BROWSER} "http://bugs.debian.org/$*" }
 261 #f4# Search Debian Bug Tracking System
 262 debbugm() { bts show --mbox $1 } # provide bugnummer as "$1"
 263 #f4# Search DMOZ
 264 dmoz()    { ${=BROWSER} http://search.dmoz.org/cgi-bin/search\?search=${1// /_} }
 265 #f4# Search German   Wiktionary
 266 dwicti()  { ${=BROWSER} http://de.wiktionary.org/wiki/${(C)1// /_} }
 267 #f4# Search English  Wiktionary
 268 ewicti()  { ${=BROWSER} http://en.wiktionary.org/wiki/${(C)1// /_} }
 269 #f4# Search Google Groups
 270 ggogle()  { ${=BROWSER} "http://groups.google.com/groups?q=$*" }
 271 #f4# Search Google
 272 google()  { ${=BROWSER} "http://www.google.com/search?&num=100&q=$*" }
 273 #f4# Search Google Groups for MsgID
 274 mggogle() { ${=BROWSER} "http://groups.google.com/groups?selm=$*" }
 275 #f4# Search Netcraft
 276 netcraft(){ ${=BROWSER} "http://toolbar.netcraft.com/site_report?url=$1" }
 277 #f4# Use German Wikipedia's full text search
 278 swiki()   { ${=BROWSER} http://de.wikipedia.org/wiki/Spezial:Search/${(C)1} }
 279 #f4# search \kbd{dict.leo.org}
 280 oleo()    { ${=BROWSER} "http://dict.leo.org/?search=$*" }
 281 #f4# Search German   Wikipedia
 282 wikide()  { ${=BROWSER} http://de.wikipedia.org/wiki/"${(C)*}" }
 283 #f4# Search English  Wikipedia
 284 wikien()  { ${=BROWSER} http://en.wikipedia.org/wiki/"${(C)*}" }
 285 #f4# Search official debs
 286 wodeb()   { ${=BROWSER} "http://packages.debian.org/search?keywords=$1&searchon=contents&suite=${2:=unstable}&section=all" }
 287
 288 #m# f4 gex() Exact search via Google
 289 check_com google && gex () { google "\"[ $1]\" $*" } # exact search at google
 290
 291 # misc
 292 #f5# Backup \kbd{file {\rm to} file\_timestamp}
 293 bk()      { cp -b ${1} ${1}_`date --iso-8601=m` }
 294 #f5# Copied diff
 295 cdiff()   { diff -crd "$*" | egrep -v "^Only in |^Binary files " }
 296 #f5# cd to directoy and list files
 297 cl()      { cd $1 && ls -a }        # cd && ls
 298 #f5# Cvs add
 299 cvsa()    { cvs add $* && cvs com -m 'initial checkin' $* }
 300 #f5# Cvs diff
 301 cvsd()    { cvs diff -N $* |& $PAGER }
 302 #f5# Cvs log
 303 cvsl()    { cvs log $* |& $PAGER }
 304 #f5# Cvs update
 305 cvsq()    { cvs -nq update }
 306 #f5# Rcs2log
 307 cvsr()    { rcs2log $* | $PAGER }
 308 #f5# Cvs status
 309 cvss()    { cvs status -v $* }
 310 #f5# Disassemble source files using gcc and as
 311 disassemble(){ gcc -pipe -S -o - -O -g $* | as -aldh -o /dev/null }
 312 #f5# Firefox remote control - open given URL
 313 fir()     { firefox -a firefox -remote "openURL($1)" }
 314 #f5# Create Directoy and \kbd{cd} to it
 315 mcd()     { mkdir -p "$@"; cd "$@" } # mkdir && cd
 316 #f5# Unified diff to timestamped outputfile
 317 mdiff()   { diff -udrP "$1" "$2" > diff.`date "+%Y-%m-%d"`."$1" }
 318 #f5# Memory overview
 319 memusage(){ ps aux | awk '{if (NR > 1) print $5; if (NR > 2) print "+"} END { print "p" }' | dc }
 320 #f5# Show contents of tar file
 321 shtar()   { gunzip -c $1 | tar -tf - -- | $PAGER }
 322 #f5# Show contents of tgz file
 323 shtgz()   { tar -ztf $1 | $PAGER }
 324 #f5# Show contents of zip file
 325 shzip()   { unzip -l $1 | $PAGER }
 326 #f5# Greps signature from file
 327 sig()     { agrep -d '^-- $' "$*" ~/.Signature }
 328 #f5# Unified diff
 329 udiff()   { diff -urd $* | egrep -v "^Only in |^Binary files " }
 330 #f5# (Mis)use \kbd{vim} as \kbd{less}
 331 viless()  { vim --cmd 'let no_plugin_maps = 1' -c "so \$VIMRUNTIME/macros/less.vim" "${@:--}" }
 332
 333 # download video from youtube
 334 ytdl() {
 335     if ! [[ -n "$2" ]] ; then
 336         print "Usage: ydtl http://youtube.com/watch?v=.... outputfile.flv">&2
 337         return 1
 338     else
 339         wget -O${2} "http://youtube.com/get_video?"${${${"$(wget -o/dev/null -O- "${1}" | grep -e watch_fullscreen)"}##*watch_fullscreen\?}%%\&fs=*}
 340     fi
 341 }
 342
 343
 344 # Function Usage: doc packagename
 345 #f5# \kbd{cd} to /usr/share/doc/\textit{package}
 346 doc() { cd /usr/share/doc/$1 && ls }
 347 _doc() { _files -W /usr/share/doc -/ }
 348 check_com compdef && compdef _doc doc
 349
 350 #f5# Make screenshot
 351 sshot() {
 352     [[ ! -d ~/shots  ]] && mkdir ~/shots
 353     #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
 354     cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
 355 }
 356
 357 # list images only
 358 limg() {
 359     local -a images
 360     images=( *.{jpg,gif,png}(.N) )
 361
 362     if [[ $#images -eq 0 ]] ; then
 363         print "No image files found"
 364     else
 365         ls "$@" "$images[@]"
 366     fi
 367 }
 368
 369 #f5# Create PDF file from source code
 370 makereadable() {
 371     output=$1
 372     shift
 373     a2ps --medium A4dj -E -o $output $*
 374     ps2pdf $output
 375 }
 376
 377 # zsh with perl-regex - use it e.g. via:
 378 # regcheck '\s\d\.\d{3}\.\d{3} Euro' ' 1.000.000 Euro'
 379 #f5# Checks whether a regex matches or not.\\&\quad Example: \kbd{regcheck '.\{3\} EUR' '500 EUR'}
 380 regcheck() {
 381     zmodload -i zsh/pcre
 382     pcre_compile $1 && \
 383     pcre_match $2 && echo "regex matches" || echo "regex does not match"
 384 }
 385
 386 #f5# List files which have been modified within the last {\it n} days
 387 new() { print -l *(m-$1) }
 388
 389 #f5# Grep in history
 390 greph() { history 0 | grep $1 }
 391 # use colors when GNU grep with color-support
 392 #a2# Execute \kbd{grep -{}-color=auto}
 393 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
 394 #a2# Execute \kbd{grep -i -{}-color=auto}
 395 alias GREP='grep -i --color=auto'
 396
 397 # one blank line between each line
 398 if [[ -r ~/.terminfo/m/mostlike ]] ; then
 399 #   alias man2='MANPAGER="sed -e G |less" TERMINFO=~/.terminfo TERM=mostlike /usr/bin/man'
 400     #f5# Watch manpages in a stretched style
 401     man2() { PAGER='dash -c "sed G | /usr/bin/less"' TERM=mostlike /usr/bin/man "$@" ; }
 402 fi
 403
 404 # d():Copyright 2005 Nikolai Weibull <nikolai@bitwi.se>
 405 # notice: option AUTO_PUSHD has to be set
 406 #f5# Jump between directories
 407 d() {
 408     emulate -L zsh
 409     autoload -U colors
 410     local color=$fg_bold[blue]
 411     integer i=0
 412     dirs -p | while read dir; do
 413         local num="${$(printf "%-4d " $i)/ /.}"
 414         printf " %s  $color%s$reset_color\n" $num $dir
 415         (( i++ ))
 416     done
 417     integer dir=-1
 418     read -r 'dir?Jump to directory: ' || return
 419     (( dir == -1 )) && return
 420     if (( dir < 0 || dir >= i )); then
 421         echo d: no such directory stack entry: $dir
 422         return 1
 423     fi
 424     cd ~$dir
 425 }
 426
 427 # usage example: 'lcheck strcpy'
 428 #f5# Find out which libs define a symbol
 429 lcheck() {
 430     if [[ -n "$1" ]] ; then
 431         nm -go /usr/lib/lib*.a 2>/dev/null | grep ":[[:xdigit:]]\{8\} . .*$1"
 432     else
 433         echo "Usage: lcheck <function>" >&2
 434     fi
 435 }
 436
 437 #f5# Clean up directory - remove well known tempfiles
 438 purge() {
 439     FILES=(*~(N) .*~(N) \#*\#(N) *.o(N) a.out(N) *.core(N) *.cmo(N) *.cmi(N) .*.swp(N))
 440     NBFILES=${#FILES}
 441     if [[ $NBFILES > 0 ]] ; then
 442         print $FILES
 443         local ans
 444         echo -n "Remove these files? [y/n] "
 445         read -q ans
 446         if [[ $ans == "y" ]] ; then
 447             rm ${FILES}
 448             echo ">> $PWD purged, $NBFILES files removed"
 449         else
 450             echo "Ok. .. than not.."
 451         fi
 452     fi
 453 }
 454
 455 # Translate DE<=>EN
 456 # 'translate' looks up fot a word in a file with language-to-language
 457 # translations (field separator should be " : "). A typical wordlist looks
 458 # like at follows:
 459 #  | english-word : german-transmission
 460 # It's also only possible to translate english to german but not reciprocal.
 461 # Use the following oneliner to turn back the sort order:
 462 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
 463 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
 464 #f5# Translates a word
 465 trans() {
 466     case "$1" in
 467         -[dD]*)
 468             translate -l de-en $2
 469             ;;
 470         -[eE]*)
 471             translate -l en-de $2
 472             ;;
 473         *)
 474             echo "Usage: $0 { -D | -E }"
 475             echo "         -D == German to English"
 476             echo "         -E == English to German"
 477     esac
 478 }
 479
 480 # Some quick Perl-hacks aka /useful/ oneliner
 481 #  bew() { perl -le 'print unpack "B*","'$1'"' }
 482 #  web() { perl -le 'print pack "B*","'$1'"' }
 483 #  hew() { perl -le 'print unpack "H*","'$1'"' }
 484 #  weh() { perl -le 'print pack "H*","'$1'"' }
 485 #  pversion()    { perl -M$1 -le "print $1->VERSION" } # i. e."pversion LWP -> 5.79"
 486 #  getlinks ()   { perl -ne 'while ( m/"((www|ftp|http):\/\/.*?)"/gc ) { print $1, "\n"; }' $* }
 487 #  gethrefs ()   { perl -ne 'while ( m/href="([^"]*)"/gc ) { print $1, "\n"; }' $* }
 488 #  getanames ()  { perl -ne 'while ( m/a name="([^"]*)"/gc ) { print $1, "\n"; }' $* }
 489 #  getforms ()   { perl -ne 'while ( m:(\</?(input|form|select|option).*?\>):gic ) { print $1, "\n"; }' $* }
 490 #  getstrings () { perl -ne 'while ( m/"(.*?)"/gc ) { print $1, "\n"; }' $*}
 491 #  getanchors () { perl -ne 'while ( m/«([^«»\n]+)»/gc ) { print $1, "\n"; }' $* }
 492 #  showINC ()    { perl -e 'for (@INC) { printf "%d %s\n", $i++, $_ }' }
 493 #  vimpm ()      { vim `perldoc -l $1 | sed -e 's/pod$/pm/'` }
 494 #  vimhelp ()    { vim -c "help $1" -c on -c "au! VimEnter *" }
 495
 496 #f5# List all occurrences of programm in current PATH
 497 plap() {
 498     if [[ $# = 0 ]] ; then
 499         echo "Usage:    $0 program"
 500         echo "Example:  $0 zsh"
 501         echo "Lists all occurrences of program in the current PATH."
 502     else
 503         ls -l ${^path}/*$1*(*N)
 504     fi
 505 }
 506
 507 # Found in the mailinglistarchive from Zsh (IIRC ~1996)
 508 #f5# Select items for specific command(s) from history
 509 selhist() {
 510     emulate -L zsh
 511     local TAB=$'\t';
 512     (( $# < 1 )) && {
 513         echo "Usage: $0 command"
 514         return 1
 515     };
 516     cmd=(${(f)"$(grep -w $1 $HISTFILE | sort | uniq | pr -tn)"})
 517     print -l $cmd | less -F
 518     echo -n "enter number of desired command [1 - $(( ${#cmd[@]} - 1 ))]: "
 519     local answer
 520     read answer
 521     print -z "${cmd[$answer]#*$TAB}"
 522 }
 523
 524 # Use vim to convert plaintext to HTML
 525 #f5# Transform files to html with highlighting
 526 2html() { vim -u NONE -n -c ':syntax on' -c ':so $VIMRUNTIME/syntax/2html.vim' -c ':wqa' $1 &>/dev/null }
 527
 528 # Usage: simple-extract <file>
 529 #f5# Smart archive extractor
 530 simple-extract () {
 531     if [[ -f $1 ]] ; then
 532         case $1 in
 533             *.tar.bz2)  bzip2 -v -d $1      ;;
 534             *.tar.gz)   tar -xvzf $1        ;;
 535             *.rar)      unrar $1            ;;
 536             *.deb)      ar -x $1            ;;
 537             *.bz2)      bzip2 -d $1         ;;
 538             *.lzh)      lha x $1            ;;
 539             *.gz)       gunzip -d $1        ;;
 540             *.tar)      tar -xvf $1         ;;
 541             *.tgz)      gunzip -d $1        ;;
 542             *.tbz2)     tar -jxvf $1        ;;
 543             *.zip)      unzip $1            ;;
 544             *.Z)        uncompress $1       ;;
 545             *)          echo "'$1' Error. Please go away" ;;
 546         esac
 547     else
 548         echo "'$1' is not a valid file"
 549     fi
 550 }
 551
 552 # Usage: smartcompress <file> (<type>)
 553 #f5# Smart archive creator
 554 smartcompress() {
 555     if [[ -n $2 ]] ; then
 556         case $2 in
 557             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
 558             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
 559             tar.Z)          tar -Zcvf$1.$2 $1 ;;
 560             tar)            tar -cvf$1.$2  $1 ;;
 561             gz | gzip)      gzip           $1 ;;
 562             bz2 | bzip2)    bzip2          $1 ;;
 563             *)
 564                 echo "Error: $2 is not a valid compression type"
 565                 ;;
 566         esac
 567     else
 568         smartcompress $1 tar.gz
 569     fi
 570 }
 571
 572 # Usage: show-archive <archive>
 573 #f5# List an archive's content
 574 show-archive() {
 575     if [[ -f $1 ]] ; then
 576         case $1 in
 577             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
 578             *.tar)         tar -tf $1 ;;
 579             *.tgz)         tar -ztf $1 ;;
 580             *.zip)         unzip -l $1 ;;
 581             *.bz2)         bzless $1 ;;
 582             *)             echo "'$1' Error. Please go away" ;;
 583         esac
 584     else
 585         echo "'$1' is not a valid archive"
 586     fi
 587 }
 588
 589 # TODO: isn't ssl() like this, but clean?
 590 #       I'd like to remove this, it's a gross hack, IMHO -ft
 591 #f5# Follow symlinks
 592 folsym() {
 593     if [[ -e $1 || -h $1 ]] ; then
 594         file=$1
 595     else
 596         file=`which $1`
 597     fi
 598     if [[ -e $file || -L $file ]] ; then
 599         if [[ -L $file ]] ; then
 600             echo `ls -ld $file | perl -ane 'print $F[7]'` '->'
 601             folsym `perl -le '$file = $ARGV[0];
 602                               $dest = readlink $file;
 603                               if ($dest !~ m{^/}) {
 604                                   $file =~ s{(/?)[^/]*$}{$1$dest};
 605                               } else {
 606                                   $file = $dest;
 607                               }
 608                               $file =~ s{/{2,}}{/}g;
 609                               while ($file =~ s{[^/]+/\.\./}{}) {
 610                                   ;
 611                               }
 612                               $file =~ s{^(/\.\.)+}{};
 613                               print $file' $file`
 614         else
 615             ls -d $file
 616         fi
 617     else
 618         echo $file
 619     fi
 620 }
 621
 622 # It's shameless stolen from <http://www.vim.org/tips/tip.php?tip_id=167>
 623 #f5# Use \kbd{vim} as your manpage reader
 624 vman() { man $* | col -b | view -c 'set ft=man nomod nolist' - }
 625
 626 # function readme() { $PAGER -- (#ia3)readme* }
 627 #f5# View all README-like files in current directory in pager
 628 readme() {
 629     local files
 630     files=(./(#i)*(read*me|lue*m(in|)ut)*(ND))
 631     if (($#files)) ; then
 632         $PAGER $files
 633     else
 634         print 'No README files.'
 635     fi
 636 }
 637
 638 # suidfind() { ls -latg $path | grep '^...s' }
 639 #f5# Find all files in \$PATH with setuid bit set
 640 suidfind() { ls -latg $path/*(sN) }
 641
 642 # See above but this is /better/ ... anywise ..
 643 findsuid() {
 644     print 'Output will be written to ~/suid_* ...'
 645     $SUDO find / -type f \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suidfiles.`date "+%Y-%m-%d"`.out 2>&1
 646     $SUDO find / -type d \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suiddirs.`date "+%Y-%m-%d"`.out 2>&1
 647     $SUDO find / -type f \( -perm -2 -o -perm -20 \) -ls > ~/suid_writefiles.`date "+%Y-%m-%d"`.out 2>&1
 648     $SUDO find / -type d \( -perm -2 -o -perm -20 \) -ls > ~/suid_writedirs.`date "+%Y-%m-%d"`.out 2>&1
 649     print 'Finished'
 650 }
 651
 652 #f5# Reload given functions
 653 refunc() {
 654     for func in $argv ; do
 655         unfunction $func
 656         autoload $func
 657     done
 658 }
 659
 660 # a small check to see which DIR is located on which server/partition.
 661 # stolen and modified from Sven's zshrc.forall
 662 #f5# Report diskusage of a directory
 663 dirspace() {
 664     if [[ -n "$1" ]] ; then
 665         for dir in $* ; do
 666             if [[ -d "$dir" ]] ; then
 667                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
 668             else
 669                 echo "warning: $dir does not exist" >&2
 670             fi
 671         done
 672     else
 673         for dir in $path; do
 674             if [[ -d "$dir" ]] ; then
 675                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
 676             else
 677                 echo "warning: $dir does not exist" >&2
 678             fi
 679         done
 680     fi
 681 }
 682
 683 # % slow_print `cat /etc/passwd`
 684 #f5# Slowly print out parameters
 685 slow_print() {
 686     for argument in "${@}" ; do
 687         for ((i = 1; i <= ${#1} ;i++)) ; do
 688             print -n "${argument[i]}"
 689             sleep 0.08
 690         done
 691         print -n " "
 692     done
 693     print ""
 694 }
 695
 696 #f5# Show some status info
 697 status() {
 698     print ""
 699     print "Date..: "$(date "+%Y-%m-%d %H:%M:%S")""
 700     print "Shell.: Zsh $ZSH_VERSION (PID = $$, $SHLVL nests)"
 701     print "Term..: $TTY ($TERM), $BAUD bauds, $COLUMNS x $LINES cars"
 702     print "Login.: $LOGNAME (UID = $EUID) on $HOST"
 703     print "System: $(cat /etc/[A-Za-z]*[_-][rv]e[lr]*)"
 704     print "Uptime:$(uptime)"
 705     print ""
 706 }
 707
 708 # Rip an audio CD
 709 #f5# Rip an audio CD
 710 audiorip() {
 711     mkdir -p ~/ripps
 712     cd ~/ripps
 713     cdrdao read-cd --device $DEVICE --driver generic-mmc audiocd.toc
 714     cdrdao read-cddb --device $DEVICE --driver generic-mmc audiocd.toc
 715     echo " * Would you like to burn the cd now? (yes/no)"
 716     read input
 717     if [[ "$input" = "yes" ]] ; then
 718         echo " ! Burning Audio CD"
 719         audioburn
 720         echo " * done."
 721     else
 722         echo " ! Invalid response."
 723     fi
 724 }
 725
 726 # and burn it
 727 #f5# Burn an audio CD (in combination with audiorip)
 728 audioburn() {
 729     cd ~/ripps
 730     cdrdao write --device $DEVICE --driver generic-mmc audiocd.toc
 731     echo " * Should I remove the temporary files? (yes/no)"
 732     read input
 733     if [[ "$input" = "yes" ]] ; then
 734         echo " ! Removing Temporary Files."
 735         cd ~
 736         rm -rf ~/ripps
 737         echo " * done."
 738     else
 739         echo " ! Invalid response."
 740     fi
 741 }
 742
 743 #f5# Make an audio CD from all mp3 files
 744 mkaudiocd() {
 745     # TODO: do the renaming more zshish, possibly with zmv()
 746     cd ~/ripps
 747     for i in *.[Mm][Pp]3; do mv "$i" `echo $i | tr '[A-Z]' '[a-z]'`; done
 748     for i in *.mp3; do mv "$i" `echo $i | tr ' ' '_'`; done
 749     for i in *.mp3; do mpg123 -w `basename $i .mp3`.wav $i; done
 750     normalize -m *.wav
 751     for i in *.wav; do sox $i.wav -r 44100 $i.wav resample; done
 752 }
 753
 754 #f5# Create an ISO image. You are prompted for\\&\quad volume name, filename and directory
 755 mkiso() {
 756     echo " * Volume name "
 757     read volume
 758     echo " * ISO Name (ie. tmp.iso)"
 759     read iso
 760     echo " * Directory or File"
 761     read files
 762     mkisofs -o ~/$iso -A $volume -allow-multidot -J -R -iso-level 3 -V $volume -R $files
 763 }
 764
 765 #f5# Simple thumbnails generator
 766 genthumbs() {
 767     rm -rf thumb-* index.html
 768     echo "
 769 <html>
 770   <head>
 771     <title>Images</title>
 772   </head>
 773   <body>" > index.html
 774     for f in *.(gif|jpeg|jpg|png) ; do
 775         convert -size 100x200 "$f" -resize 100x200 thumb-"$f"
 776         echo "    <a href=\"$f\"><img src=\"thumb-$f\"></a>" >> index.html
 777     done
 778     echo "
 779   </body>
 780 </html>" >> index.html
 781 }
 782
 783 #f5# Set all ulimit parameters to \kbd{unlimited}
 784 allulimit() {
 785     ulimit -c unlimited
 786     ulimit -d unlimited
 787     ulimit -f unlimited
 788     ulimit -l unlimited
 789     ulimit -n unlimited
 790     ulimit -s unlimited
 791     ulimit -t unlimited
 792 }
 793
 794 # ogg2mp3 with bitrate of 192
 795 ogg2mp3_192() {
 796     oggdec -o - ${1} | lame -b 192 - ${1:r}.mp3
 797 }
 798
 799 #f5# RFC 2396 URL encoding in Z-Shell
 800 urlencode() {
 801     setopt localoptions extendedglob
 802     input=( ${(s::)1} )
 803     print ${(j::)input/(#b)([^A-Za-z0-9_.!~*\'\(\)-])/%$(([##16]#match))}
 804 }
 805
 806 #f5# Install x-lite (VoIP software)
 807 getxlite() {
 808     setopt local_options
 809     setopt errreturn
 810     [[ -d ~/tmp ]] || mkdir ~/tmp
 811     cd ~/tmp
 812
 813     echo "Downloading http://www.counterpath.com/download/X-Lite_Install.tar.gz and storing it in ~/tmp:"
 814     if wget http://www.counterpath.com/download/X-Lite_Install.tar.gz ; then
 815         unp X-Lite_Install.tar.gz && echo done || echo failed
 816     else
 817         echo "Error while downloading." ; return 1
 818     fi
 819
 820     if [[ -x xten-xlite/xtensoftphone ]] ; then
 821         echo "Execute xten-xlite/xtensoftphone to start xlite."
 822     fi
 823 }
 824
 825 #f5# Install skype
 826 getskype() {
 827     setopt local_options
 828     setopt errreturn
 829     echo "Downloading debian package of skype."
 830     echo "Notice: If you want to use a more recent skype version run 'getskypebeta'."
 831     wget http://www.skype.com/go/getskype-linux-deb
 832     $SUDO dpkg -i skype*.deb && echo "skype installed."
 833 }
 834
 835 #f5# Install beta-version of skype
 836 getskypebeta() {
 837     setopt local_options
 838     setopt errreturn
 839     echo "Downloading debian package of skype (beta version)."
 840     wget http://www.skype.com/go/getskype-linux-beta-deb
 841     $SUDO dpkg -i skype-beta*.deb && echo "skype installed."
 842 }
 843
 844 #f5# Install gizmo (VoIP software)
 845 getgizmo() {
 846     setopt local_options
 847     setopt errreturn
 848     echo "gconf2-common and libgconf2-4 have to be available. Installing therefor."
 849     $SUDO apt-get update
 850     $SUDO apt-get install gconf2-common libgconf2-4
 851     wget $(lynx --dump http://www.gizmoproject.com/download-linux.html | awk '/\.deb/ {print $2" "}' | tr -d '\n')
 852     $SUDO dpkg -i libsipphoneapi*.deb bonjour_*.deb gizmo-*.deb && echo "gizmo installed."
 853 }
 854
 855 #f5# Get and run AIR (Automated Image and Restore)
 856 getair() {
 857     setopt local_options
 858     setopt errreturn
 859     [[ -w . ]] || { echo 'Error: you do not have write permissions in this directory. Exiting.' ; return 1 }
 860     local VER='1.2.8'
 861     wget http://puzzle.dl.sourceforge.net/sourceforge/air-imager/air-$VER.tar.gz
 862     tar zxf air-$VER.tar.gz
 863     cd air-$VER
 864     INTERACTIVE=no $SUDO ./install-air-1.2.8
 865     [[ -x /usr/local/bin/air ]] && [[ -n "$DISPLAY" ]] && $SUDO air
 866 }
 867
 868 #f5# Get specific git commitdiff
 869 git-get-diff() {
 870     if [[ -z $GITTREE ]] ; then
 871         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
 872     fi
 873     if ! [[ -z $1 ]] ; then
 874         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commitdiff;h=$1"
 875     else
 876         echo "Usage: git-get-diff <commit>"
 877     fi
 878 }
 879
 880 #f5# Get specific git commit
 881 git-get-commit() {
 882     if [[ -z $GITTREE ]] ; then
 883         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
 884     fi
 885     if ! [[ -z $1 ]] ; then
 886         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commit;h=$1"
 887     else
 888         echo "Usage: git-get-commit <commit>"
 889     fi
 890 }
 891
 892 #f5# Get specific git diff
 893 git-get-plaindiff() {
 894     if [[ -z $GITTREE ]] ; then
 895         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
 896     fi
 897     if ! [[ -z $1 ]] ; then
 898         wget "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O $1.diff
 899     else
 900         echo 'Usage: git-get-plaindiff '
 901     fi
 902 }
 903
 904 # http://strcat.de/blog/index.php?/archives/335-Software-sauber-deinstallieren...html
 905 #f5# Log 'make install' output
 906 mmake() {
 907     [[ ! -d ~/.errorlogs ]] && mkdir ~/.errorlogs
 908     make -n install > ~/.errorlogs/${PWD##*/}-makelog
 909 }
 910
 911 #f5# Indent source code
 912 smart-indent() {
 913     indent -npro -kr -i8 -ts8 -sob -l80 -ss -ncs $*
 914 }
 915
 916 # highlight important stuff in diff output, usage example: hg diff | hidiff
 917 #m# a2 hidiff \kbd{histring} oneliner for diffs
 918 check_com -c histring && \
 919     alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
 920
 921 # rename pictures based on information found in exif headers
 922 #f5# Rename pictures based on information found in exif headers
 923 exirename() {
 924     if [[ $# -lt 1 ]] ; then
 925         echo 'Usage: jpgrename $FILES' >& 2
 926         return 1
 927     else
 928         echo -n 'Checking for jhead with version newer than 1.9: '
 929         jhead_version=`jhead -h | grep 'used by most Digital Cameras.  v.*' | awk '{print $6}' | tr -d v`
 930         if [[ $jhead_version > '1.9' ]]; then
 931             echo 'success - now running jhead.'
 932             jhead -n%Y-%m-%d_%Hh%M_%f $*
 933         else
 934             echo 'failed - exiting.'
 935         fi
 936     fi
 937 }
 938
 939 # open file in vim and jump to line
 940 # http://www.downgra.de/archives/2007/05/08/T19_21_11/
 941 j2v() {
 942     local -a params
 943     params=(${*//(#m):[0-9]*:/\\n+${MATCH//:/}}) # replace ':23:' to '\n+23'
 944     params=(${(s|\n|)${(j|\n|)params}}) # join array using '\n', then split on all '\n'
 945     vim ${params}
 946 }
 947
 948 # get_ic() - queries imap servers for capabilities; real simple. no imaps
 949 ic_get() {
 950     local port
 951     if [[ ! -z $1 ]] ; then
 952         port=${2:-143}
 953         print "querying imap server on $1:${port}...\n";
 954         print "a1 capability\na2 logout\n" | nc $1 ${port}
 955     else
 956         print "usage:\n  $0 <imap-server> [port]"
 957     fi
 958 }
 959
 960 # creates a Maildir/ with its {new,cur,tmp} subdirs
 961 mkmaildir() {
 962     local root subdir
 963     root=${MAILDIR_ROOT:-${HOME}/Mail}
 964     if [[ -z ${1} ]] ; then print "Usage:\n $0 <dirname>" ; return 1 ; fi
 965     subdir=${1}
 966     mkdir -p ${root}/${subdir}/{cur,new,tmp}
 967 }
 968
 969 # xtrename() rename xterm from within GNU-screen
 970 xtrename() {
 971     if [[ -z ${DISPLAY} ]] ; then
 972         printf 'xtrename only makes sense in X11.\n'
 973         return 1
 974     fi
 975     if [[ -z ${1} ]] ; then
 976         printf 'usage: xtrename() "title for xterm"\n'
 977         printf '  renames the title of xterm from _within_ screen.\n'
 978         printf '  Also works without screen.\n'
 979         return 0
 980     fi
 981     print -n "\eP\e]0;${1}\C-G\e\\"
 982     return 0
 983 }
 984
 985 # hl() highlighted less
 986 # http://ft.bewatermyfriend.org/comp/data/zsh/zfunct.html
 987 if check_com -c highlight ; then
 988     function hl() {
 989         local theme lang
 990         theme=${HL_THEME:-""}
 991         case ${1} in
 992             (-l|--list)
 993                 ( printf 'available languages (syntax parameter):\n\n' ;
 994                     highlight --list-langs ; ) | less -SMr
 995                 ;;
 996             (-t|--themes)
 997                 ( printf 'available themes (style parameter):\n\n' ;
 998                     highlight --list-themes ; ) | less -SMr
 999                 ;;
1000             (-h|--help)
1001                 printf 'usage: hl <syntax[:theme]> <file>\n'
1002                 printf '    available options: --list (-l), --themes (-t), --help (-h)\n\n'
1003                 printf '  Example: hl c main.c\n'
1004                 ;;
1005             (*)
1006                 if [[ -z ${2} ]] || (( ${#argv} > 2 )) ; then
1007                     printf 'usage: hl <syntax[:theme]> <file>\n'
1008                     printf '    available options: --list (-l), --themes (-t), --help (-h)\n'
1009                     (( ${#argv} > 2 )) && printf '  Too many arguments.\n'
1010                     return 1
1011                 fi
1012                 lang=${1%:*}
1013                 [[ ${1} == *:* ]] && [[ -n ${1#*:} ]] && theme=${1#*:}
1014                 if [[ -n ${theme} ]] ; then
1015                     highlight --xterm256 --syntax ${lang} --style ${theme} ${2} | less -SMr
1016                 else
1017                     highlight --ansi --syntax ${lang} ${2} | less -SMr
1018                 fi
1019                 ;;
1020         esac
1021         return 0
1022     }
1023     # ... and a proper completion for hl()
1024     # needs 'highlight' as well, so it fits fine in here.
1025     function _hl_genarg()  {
1026         local expl
1027         if [[ -prefix 1 *: ]] ; then
1028             local themes
1029             themes=(${${${(f)"$(LC_ALL=C highlight --list-themes)"}/ #/}:#*(Installed|Use name)*})
1030             compset -P 1 '*:'
1031             _wanted -C list themes expl theme compadd ${themes}
1032         else
1033             local langs
1034             langs=(${${${(f)"$(LC_ALL=C highlight --list-langs)"}/ #/}:#*(Installed|Use name)*})
1035             _wanted -C list languages expl languages compadd -S ':' -q ${langs}
1036         fi
1037     }
1038     function _hl_complete() {
1039         _arguments -s '1: :_hl_genarg' '2:files:_path_files'
1040     }
1041     compdef _hl_complete hl
1042 fi
1043
1044 # create small urls via tinyurl.com using wget, grep and sed
1045 zurl() {
1046     [[ -z ${1} ]] && print "please give an url to shrink." && return 1
1047     local url=${1}
1048     local tiny="http://tinyurl.com/create.php?url="
1049     #print "${tiny}${url}" ; return
1050     wget  -O-             \
1051           -o/dev/null     \
1052           "${tiny}${url}" \
1053         | grep -Eio 'value="(http://tinyurl.com/.*)"' \
1054         | sed 's/value=//;s/"//g'
1055 }
1056
1057 # change fluxbox keys from 'Alt-#' to 'Alt-F#' and vice versa
1058 fluxkey-change() {
1059     [[ -n "$FLUXKEYS" ]] || local FLUXKEYS="$HOME/.fluxbox/keys"
1060     if ! [[ -r "$FLUXKEYS" ]] ; then
1061         echo "Sorry, \$FLUXKEYS file $FLUXKEYS could not be read - nothing to be done."
1062         return 1
1063     else
1064         if grep -q 'Mod1 F[0-9] :Workspace [0-9]' $FLUXKEYS ; then
1065             echo -n 'Switching to Alt-# mode in ~/.fluxbox/keys: '
1066             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)F\([0-9]\+[: space :]\+:Workspace.*\)|\1\2|' $FLUXKEYS && echo done || echo failed
1067         elif grep -q 'Mod1 [0-9] :Workspace [0-9]' $FLUXKEYS ; then
1068             echo -n 'Switching to Alt-F# mode in ~/.fluxbox/keys: '
1069             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)\([0-9]\+[: space :]\+:Workspace.*\)|\1F\2|' $FLUXKEYS && echo done || echo failed
1070         else
1071             echo 'Sorry, do not know what to do.'
1072             return 1
1073         fi
1074     fi
1075 }
1076
1077 # retrieve weather information on the console
1078 # Usage example: 'weather LOWG'
1079 weather() {
1080     [[ -n "$1" ]] || {
1081         print 'Usage: weather <station_id>' >&2
1082         return 1
1083     }
1084
1085     local PLACE="${1:u}"
1086     local FILE="$HOME/.weather/$PLACE"
1087     local LOG="$HOME/.weather/log"
1088
1089     [[ -d $HOME/.weather ]] || {
1090         print -n "Creating $HOME/.weather: "
1091         mkdir $HOME/.weather
1092         print 'done'
1093     }
1094
1095     print "Retrieving information for ${PLACE}:"
1096     print
1097     wget -T 10 --no-verbose --output-file=$LOG --output-document=$FILE --timestamping http://weather.noaa.gov/pub/data/observations/metar/decoded/$PLACE.TXT
1098
1099     if [[ $? -eq 0 ]] ; then
1100         if [[ -n "$VERBOSE" ]] ; then
1101             cat $FILE
1102         else
1103             DATE=$(grep 'UTC' $FILE | sed 's#.* /##')
1104             TEMPERATURE=$(awk '/Temperature/ { print $4" degree Celcius / " $2" degree Fahrenheit" }' $FILE| tr -d '(')
1105             echo "date: $DATE"
1106             echo "temp:  $TEMPERATURE"
1107         fi
1108     else
1109         print "There was an error retrieving the weather information for $PLACE" >&2
1110         cat $LOG
1111         return 1
1112     fi
1113 }
1114
1115
1116 # }}}
1117
1118 # mercurial related stuff {{{
1119 if check_com -c hg ; then
1120     # gnu like diff for mercurial
1121     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
1122     #f5# GNU like diff for mercurial
1123     hgdi() {
1124         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
1125     }
1126
1127     # build debian package
1128     #a2# Alias for \kbd{hg-buildpackage}
1129     alias hbp='hg-buildpackage'
1130
1131     # execute commands on the versioned patch-queue from the current repos
1132     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
1133
1134     # diffstat for specific version of a mercurial repository
1135     #   hgstat      => display diffstat between last revision and tip
1136     #   hgstat 1234 => display diffstat between revision 1234 and tip
1137     #f5# Diffstat for specific version of a mercurial repos
1138     hgstat() {
1139         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
1140     }
1141
1142     #f5# Get current mercurial tip via hg itself
1143     gethgclone() {
1144         setopt local_options
1145         setopt errreturn
1146         if [[ -f mercurial-tree/.hg ]] ; then
1147             cd mercurial-tree
1148             echo "Running hg pull for retreiving latest version..."
1149             hg pull
1150             echo "Finished update. Building mercurial"
1151             make local
1152             echo "Setting \$PATH to $PWD:\$PATH..."
1153             export PATH="$PWD:$PATH"
1154         else
1155             echo "Downloading mercurial via hg"
1156             hg clone http://selenic.com/repo/hg mercurial-tree
1157             cd mercurial-tree
1158             echo "Building mercurial"
1159             make local
1160             echo "Setting \$PATH to $PWD:\$PATH..."
1161             export PATH="$PWD:$PATH"
1162             echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
1163             # echo "Setting \$PYTHONPATH to PYTHONPATH=\${HOME}/lib/python,"
1164             # export PYTHONPATH=${HOME}/lib/python
1165         fi
1166     }
1167
1168 fi # end of check whether we have the 'hg'-executable
1169
1170 # get current mercurial snapshot
1171 #f5# Get current mercurial snapshot
1172 gethgsnap() {
1173     setopt local_options
1174     setopt errreturn
1175     if [[ -f mercurial-snapshot.tar.gz ]] ; then
1176          echo "mercurial-snapshot.tar.gz exists already, skipping download."
1177     else
1178         echo "Downloading mercurial snapshot"
1179         wget http://www.selenic.com/mercurial/mercurial-snapshot.tar.gz
1180     fi
1181     echo "Unpacking mercurial-snapshot.tar.gz"
1182     tar zxf mercurial-snapshot.tar.gz
1183     cd mercurial-snapshot/
1184     echo "Installing required build-dependencies"
1185     $SUDO apt-get update
1186     $SUDO apt-get install python2.4-dev
1187     echo "Building mercurial"
1188     make local
1189     echo "Setting \$PATH to $PWD:\$PATH..."
1190     export PATH="$PWD:$PATH"
1191     echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
1192 }
1193 # }}}
1194
1195 # some useful commands often hard to remember - let's grep for them {{{
1196
1197 # Work around ion/xterm resize bug.
1198 #if [[ "$SHLVL" -eq 1 ]]; then
1199 #       if check_com -c resize ; then
1200 #               eval `resize </dev/null`
1201 #       fi
1202 #fi
1203
1204 # enable jackd:
1205 #  /usr/bin/jackd -dalsa -dhw:0 -r48000 -p1024 -n2
1206 # now play audio file:
1207 #  alsaplayer -o jack foobar.mp3
1208
1209 # send files via netcat
1210 # on sending side:
1211 #  send() {j=$*; tar cpz ${j/%${!#}/}|nc -w 1 ${!#} 51330;}
1212 #  send dir* $HOST
1213 #  alias receive='nc -vlp 51330 | tar xzvp'
1214
1215 # debian stuff:
1216 # dh_make -e foo@localhost -f $1
1217 # dpkg-buildpackage -rfakeroot
1218 # lintian *.deb
1219 # dpkg-scanpackages ./ /dev/null | gzip > Packages.gz
1220 # dpkg-scansources . | gzip > Sources.gz
1221 # grep-dctrl --field Maintainer $* /var/lib/apt/lists/*
1222
1223 # other stuff:
1224 # convert -geometry 200x200 -interlace LINE -verbose
1225 # ldapsearch -x -b "OU=Bedienstete,O=tug" -h ldap.tugraz.at sn=$1
1226 # ps -ao user,pcpu,start,command
1227 # gpg --keyserver blackhole.pca.dfn.de --recv-keys
1228 # xterm -bg black -fg yellow -fn -misc-fixed-medium-r-normal--14-140-75-75-c-90-iso8859-15 -ah
1229 # nc -vz $1 1-1024   # portscan via netcat
1230 # wget --mirror --no-parent --convert-links
1231 # pal -d `date +%d`
1232 # autoload -U tetris; zle -N tetris; bindkey '...' ; echo "press ... for playing tennis"
1233 #
1234 # modify console cursor
1235 # see http://www.tldp.org/HOWTO/Framebuffer-HOWTO-5.html
1236 # print $'\e[?96;0;64c'
1237 # }}}
1238
1239 # finally source a local zshrc and grmlsmall-specific configuration {{{
1240
1241 # The following file is used to remove zsh-config-items that do not work
1242 # in grml-small by default.
1243 # If you do not want these adjustments (for whatever reason),
1244 # there are three ways to accomplish that:
1245 #  a) at the beginning of this file (variables section), set
1246 #     $GRMLSMALL_SPECIFIC to 0 or comment out the variable definition.
1247 #  b) remove/rename .zshrc.grmlsmall
1248 #  c) comment out the following line
1249 (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall && source ~/.zshrc.grmlsmall
1250
1251 # this allows us to stay in sync with /etc/skel/.zshrc
1252 # through 'ln -s /etc/skel/.zshrc ~/.zshrc' and put own
1253 # modifications in ~/.zshrc.local
1254 xsource "${HOME}/.zshrc.local"
1255
1256 # ...and remove utility functions again.
1257 xunfunction
1258
1259 # }}}
1260
1261 ### doc strings for external functions from files
1262 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
1263 ## END OF FILE #################################################################
1264 # vim:foldmethod=marker autoindent expandtab shiftwidth=4