etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* || $ZSH_VERSION == <5->* ]] && return 0
 143     return 1
 144 }
 145
 146 is439(){
 147     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* || $ZSH_VERSION == <5->* ]] && return 0
 148     return 1
 149 }
 150
 151 #f1# Checks whether or not you're running grml
 152 isgrml(){
 153     [[ -f /etc/grml_version ]] && return 0
 154     return 1
 155 }
 156
 157 #f1# Checks whether or not you're running a grml cd
 158 isgrmlcd(){
 159     [[ -f /etc/grml_cd ]] && return 0
 160     return 1
 161 }
 162
 163 if isgrml ; then
 164 #f1# Checks whether or not you're running grml-small
 165     isgrmlsmall() {
 166         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 167     }
 168 else
 169     isgrmlsmall() { return 1 }
 170 fi
 171
 172 isdarwin(){
 173     [[ $OSTYPE == darwin* ]] && return 0
 174     return 1
 175 }
 176
 177 #f1# are we running within an utf environment?
 178 isutfenv() {
 179     case "$LANG $CHARSET $LANGUAGE" in
 180         *utf*) return 0 ;;
 181         *UTF*) return 0 ;;
 182         *)     return 1 ;;
 183     esac
 184 }
 185
 186 # check for user, if not running as root set $SUDO to sudo
 187 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 188
 189 # change directory to home on first invocation of zsh
 190 # important for rungetty -> autologin
 191 # Thanks go to Bart Schaefer!
 192 isgrml && checkhome() {
 193     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 194         export ALREADY_DID_CD_HOME=$HOME
 195         cd
 196     fi
 197 }
 198
 199 # check for zsh v3.1.7+
 200
 201 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 202      || ${ZSH_VERSION} == 3.<2->.<->*    \
 203      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 204
 205     printf '-!-\n'
 206     printf '-!- In this configuration we try to make use of features, that only\n'
 207     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 208     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 209     printf '-!- advanced features in all supported versions.\n'
 210     printf '-!-\n'
 211     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 212     printf '-!-\n'
 213     printf '-!- While this *may* work, it might as well fail.\n'
 214     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 215     printf '-!-\n'
 216     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 217     printf '-!- If it does today, you'\''ve been lucky.\n'
 218     printf '-!-\n'
 219     printf '-!- Ye been warned!\n'
 220     printf '-!-\n'
 221
 222     function zstyle() { : }
 223 fi
 224
 225 # autoload wrapper - use this one instead of autoload directly
 226 # We need to define this function as early as this, because autoloading
 227 # 'is-at-least()' needs it.
 228 function zrcautoload() {
 229     emulate -L zsh
 230     setopt extended_glob
 231     local fdir ffile
 232     local -i ffound
 233
 234     ffile=$1
 235     (( found = 0 ))
 236     for fdir in ${fpath} ; do
 237         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 238     done
 239
 240     (( ffound == 0 )) && return 1
 241     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 242         autoload -U ${ffile} || return 1
 243     else
 244         autoload ${ffile} || return 1
 245     fi
 246     return 0
 247 }
 248
 249 # Load is-at-least() for more precise version checks
 250 # Note that this test will *always* fail, if the is-at-least
 251 # function could not be marked for autoloading.
 252 zrcautoload is-at-least || is-at-least() { return 1 }
 253
 254 # set some important options (as early as possible)
 255 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 256 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 257 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 258 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 259                             # list duplicates an older one, the older command is removed from the list
 260 setopt histignorespace      # remove command lines from the history list when
 261                             # the first character on the line is a space
 262 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 263                             # and the command is the name of a directory, perform the cd command to that directory
 264 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 265                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 266                             # -> searches for word not in compressed files
 267                             # don't forget to quote '^', '~' and '#'!
 268 setopt longlistjobs         # display PID when suspending processes as well
 269 setopt notify               # report the status of backgrounds jobs immediately
 270 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 271                             # the entire command path is hashed first.
 272 setopt completeinword       # not just at the end
 273 setopt nohup                # and don't kill them, either
 274 setopt auto_pushd           # make cd push the old directory onto the directory stack.
 275 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 276 setopt nobeep               # avoid "beep"ing
 277 setopt pushd_ignore_dups    # don't push the same dir twice.
 278 setopt noglobdots           # * shouldn't match dotfiles. ever.
 279 setopt noshwordsplit        # use zsh style word splitting
 280 setopt unset                # don't error out when unset parameters are used
 281
 282 # setting some default values
 283
 284 NOCOR=${NOCOR:-0}
 285 NOMENU=${NOMENU:-0}
 286 NOPRECMD=${NOPRECMD:-0}
 287 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 288 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 289 BATTERY=${BATTERY:-0}
 290 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 291 GRML_ALWAYS_LOAD_ALL=${GRML_ALWAYS_LOAD_ALL:-0}
 292 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 293
 294 # utility functions
 295 # this function checks if a command exists and returns either true
 296 # or false. This avoids using 'which' and 'whence', which will
 297 # avoid problems with aliases for which on certain weird systems. :-)
 298 # Usage: check_com [-c|-g] word
 299 #   -c  only checks for external commands
 300 #   -g  does the usual tests and also checks for global aliases
 301 check_com() {
 302     emulate -L zsh
 303     local -i comonly gatoo
 304
 305     if [[ $1 == '-c' ]] ; then
 306         (( comonly = 1 ))
 307         shift
 308     elif [[ $1 == '-g' ]] ; then
 309         (( gatoo = 1 ))
 310     else
 311         (( comonly = 0 ))
 312         (( gatoo = 0 ))
 313     fi
 314
 315     if (( ${#argv} != 1 )) ; then
 316         printf 'usage: check_com [-c] <command>\n' >&2
 317         return 1
 318     fi
 319
 320     if (( comonly > 0 )) ; then
 321         [[ -n ${commands[$1]}  ]] && return 0
 322         return 1
 323     fi
 324
 325     if   [[ -n ${commands[$1]}    ]] \
 326       || [[ -n ${functions[$1]}   ]] \
 327       || [[ -n ${aliases[$1]}     ]] \
 328       || [[ -n ${reswords[(r)$1]} ]] ; then
 329
 330         return 0
 331     fi
 332
 333     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 334         return 0
 335     fi
 336
 337     return 1
 338 }
 339
 340 # creates an alias and precedes the command with
 341 # sudo if $EUID is not zero.
 342 salias() {
 343     emulate -L zsh
 344     local only=0 ; local multi=0
 345     while [[ $1 == -* ]] ; do
 346         case $1 in
 347             (-o) only=1 ;;
 348             (-a) multi=1 ;;
 349             (--) shift ; break ;;
 350             (-h)
 351                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 352                 printf '  -h      shows this help text.\n'
 353                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 354                 printf '          be careful using this option.\n'
 355                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 356                 return 0
 357                 ;;
 358             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 359         esac
 360         shift
 361     done
 362
 363     if (( ${#argv} > 1 )) ; then
 364         printf 'Too many arguments %s\n' "${#argv}"
 365         return 1
 366     fi
 367
 368     key="${1%%\=*}" ;  val="${1#*\=}"
 369     if (( EUID == 0 )) && (( only == 0 )); then
 370         alias -- "${key}=${val}"
 371     elif (( EUID > 0 )) ; then
 372         (( multi > 0 )) && val="${val// ; / ; sudo }"
 373         alias -- "${key}=sudo ${val}"
 374     fi
 375
 376     return 0
 377 }
 378
 379 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 380 # usage: uprint foo
 381 #   Where foo is the *name* of the parameter you want printed.
 382 #   Note that foo is no typo; $foo would be wrong here!
 383 if ! is42 ; then
 384     uprint () {
 385         emulate -L zsh
 386         local -a u
 387         local w
 388         local parameter=$1
 389
 390         if [[ -z ${parameter} ]] ; then
 391             printf 'usage: uprint <parameter>\n'
 392             return 1
 393         fi
 394
 395         for w in ${(P)parameter} ; do
 396             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 397         done
 398
 399         builtin print -l $u
 400     }
 401 fi
 402
 403 # Check if we can read given files and source those we can.
 404 xsource() {
 405     if (( ${#argv} < 1 )) ; then
 406         printf 'usage: xsource FILE(s)...\n' >&2
 407         return 1
 408     fi
 409
 410     while (( ${#argv} > 0 )) ; do
 411         [[ -r "$1" ]] && source "$1"
 412         shift
 413     done
 414     return 0
 415 }
 416
 417 # Check if we can read a given file and 'cat(1)' it.
 418 xcat() {
 419     emulate -L zsh
 420     if (( ${#argv} != 1 )) ; then
 421         printf 'usage: xcat FILE\n' >&2
 422         return 1
 423     fi
 424
 425     [[ -r $1 ]] && cat $1
 426     return 0
 427 }
 428
 429 # Remove these functions again, they are of use only in these
 430 # setup files. This should be called at the end of .zshrc.
 431 xunfunction() {
 432     emulate -L zsh
 433     local -a funcs
 434     funcs=(salias xcat xsource xunfunction zrcautoload)
 435
 436     for func in $funcs ; do
 437         [[ -n ${functions[$func]} ]] \
 438             && unfunction $func
 439     done
 440     return 0
 441 }
 442
 443 # this allows us to stay in sync with grml's zshrc and put own
 444 # modifications in ~/.zshrc.local
 445 zrclocal() {
 446     xsource "/etc/zsh/zshrc.local"
 447     xsource "${HOME}/.zshrc.local"
 448     return 0
 449 }
 450
 451 # locale setup
 452 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 453     xsource "/etc/default/locale"
 454 fi
 455
 456 for var in LANG LC_ALL LC_MESSAGES ; do
 457     [[ -n ${(P)var} ]] && export $var
 458 done
 459
 460 xsource "/etc/sysconfig/keyboard"
 461
 462 TZ=$(xcat /etc/timezone)
 463
 464 # set some variables
 465 if check_com -c vim ; then
 466 #v#
 467     export EDITOR=${EDITOR:-vim}
 468 else
 469     export EDITOR=${EDITOR:-vi}
 470 fi
 471
 472 #v#
 473 export PAGER=${PAGER:-less}
 474
 475 #v#
 476 export MAIL=${MAIL:-/var/mail/$USER}
 477
 478 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 479 export SHELL='/bin/zsh'
 480
 481 # color setup for ls:
 482 check_com -c dircolors && eval $(dircolors -b)
 483 # color setup for ls on OS X:
 484 isdarwin && export CLICOLOR=1
 485
 486 # do MacPorts setup on darwin
 487 if isdarwin && [[ -d /opt/local ]]; then
 488     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 489     # zshenv.
 490     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 491     MANPATH="/opt/local/share/man:$MANPATH"
 492 fi
 493 # do Fink setup on darwin
 494 isdarwin && xsource /sw/bin/init.sh
 495
 496 # load our function and completion directories
 497 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 498     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 499     if [[ ${fpath} == '/usr/share/grml/zsh/functions' ]] ; then
 500         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 501             zrcautoload ${func:t}
 502         done
 503     fi
 504 done
 505 unset fdir func
 506
 507 # support colors in less
 508 export LESS_TERMCAP_mb=$'\E[01;31m'
 509 export LESS_TERMCAP_md=$'\E[01;31m'
 510 export LESS_TERMCAP_me=$'\E[0m'
 511 export LESS_TERMCAP_se=$'\E[0m'
 512 export LESS_TERMCAP_so=$'\E[01;44;33m'
 513 export LESS_TERMCAP_ue=$'\E[0m'
 514 export LESS_TERMCAP_us=$'\E[01;32m'
 515
 516 MAILCHECK=30       # mailchecks
 517 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 518 watch=(notme root) # watch for everyone but me and root
 519
 520 # automatically remove duplicates from these arrays
 521 typeset -U path cdpath fpath manpath
 522
 523 # keybindings
 524 if [[ "$TERM" != emacs ]] ; then
 525     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 526     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 527     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 528     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 529     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 530     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 531     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 532     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 533     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 534     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 535     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 536     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 537     # ncurses stuff:
 538     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 539     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 540     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 541     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 542     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 543     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 544     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 545     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 546 fi
 547
 548 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 549 # use emacs style per default:
 550 bindkey -e
 551 # use vi style:
 552 # bindkey -v
 553
 554 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 555 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 556 beginning-or-end-of-somewhere() {
 557     local hno=$HISTNO
 558     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 559       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 560         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 561     else
 562         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 563         if (( HISTNO != hno )); then
 564             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 565         fi
 566     fi
 567 }
 568 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 569 zle -N end-of-somewhere beginning-or-end-of-somewhere
 570
 571
 572 #if [[ "$TERM" == screen ]] ; then
 573
 574 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 575 ## to beginning/end of buffer on second keypress
 576 ## and to beginning/end of history on (at most) the third keypress
 577 # terminator & non-debian xterm
 578 bindkey '\eOH' beginning-of-somewhere  # home
 579 bindkey '\eOF' end-of-somewhere        # end
 580 # freebsd console
 581 bindkey '\e[H' beginning-of-somewhere   # home
 582 bindkey '\e[F' end-of-somewhere         # end
 583 # xterm,gnome-terminal,quake,etc
 584 bindkey '^[[1~' beginning-of-somewhere  # home
 585 bindkey '^[[4~' end-of-somewhere        # end
 586 # if terminal type is set to 'rxvt':
 587 bindkey '\e[7~' beginning-of-somewhere  # home
 588 bindkey '\e[8~' end-of-somewhere        # end
 589 #fi
 590
 591 bindkey '\e[A'  up-line-or-search       # cursor up
 592 bindkey '\e[B'  down-line-or-search     # <ESC>-
 593
 594 ## alt-backspace is already the default for backwards-delete-word
 595 ## let's also set alt-delete for deleting current word (right of cursor)
 596 #k# Kill right-side word
 597 bindkey "3~" delete-word
 598
 599 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 600 bindkey "\e[5C" forward-word
 601 bindkey "\e[5D" backward-word
 602 bindkey "\e[1;5C" forward-word
 603 bindkey "\e[1;5D" backward-word
 604 ## the same for alt-left-arrow and alt-right-arrow
 605 bindkey '^[[1;3C' forward-word
 606 bindkey '^[[1;3D' backward-word
 607
 608 # Search backward in the history for a line beginning with the current
 609 # line up to the cursor and move the cursor to the end of the line then
 610 zle -N history-beginning-search-backward-end history-search-end
 611 zle -N history-beginning-search-forward-end  history-search-end
 612 #k# search history backward for entry beginning with typed text
 613 bindkey '^xp'   history-beginning-search-backward-end
 614 #k# search history forward for entry beginning with typed text
 615 bindkey '^xP'   history-beginning-search-forward-end
 616 #k# search history backward for entry beginning with typed text
 617 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 618 #k# search history forward for entry beginning with typed text
 619 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 620
 621 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 622 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 623
 624 # insert unicode character
 625 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 626 # See for example http://unicode.org/charts/ for unicode characters code
 627 zrcautoload insert-unicode-char
 628 zle -N insert-unicode-char
 629 #k# Insert Unicode character
 630 bindkey '^Xi' insert-unicode-char
 631
 632 #m# k Shift-tab Perform backwards menu completion
 633 if [[ -n "$terminfo[kcbt]" ]]; then
 634     bindkey "$terminfo[kcbt]" reverse-menu-complete
 635 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 636     bindkey "$terminfo[cbt]"  reverse-menu-complete
 637 fi
 638
 639 ## toggle the ,. abbreviation feature on/off
 640 # NOABBREVIATION: default abbreviation-state
 641 #                 0 - enabled (default)
 642 #                 1 - disabled
 643 NOABBREVIATION=${NOABBREVIATION:-0}
 644
 645 grml_toggle_abbrev() {
 646     if (( ${NOABBREVIATION} > 0 )) ; then
 647         NOABBREVIATION=0
 648     else
 649         NOABBREVIATION=1
 650     fi
 651 }
 652
 653 zle -N grml_toggle_abbrev
 654 bindkey '^xA' grml_toggle_abbrev
 655
 656 # add a command line to the shells history without executing it
 657 commit-to-history() {
 658     print -s ${(z)BUFFER}
 659     zle send-break
 660 }
 661 zle -N commit-to-history
 662 bindkey "^x^h" commit-to-history
 663
 664 # only slash should be considered as a word separator:
 665 slash-backward-kill-word() {
 666     local WORDCHARS="${WORDCHARS:s@/@}"
 667     # zle backward-word
 668     zle backward-kill-word
 669 }
 670 zle -N slash-backward-kill-word
 671
 672 #k# Kill left-side word or everything up to next slash
 673 bindkey '\ev' slash-backward-kill-word
 674 #k# Kill left-side word or everything up to next slash
 675 bindkey '\e^h' slash-backward-kill-word
 676 #k# Kill left-side word or everything up to next slash
 677 bindkey '\e^?' slash-backward-kill-word
 678
 679 # use the new *-pattern-* widgets for incremental history search
 680 if is439 ; then
 681     bindkey '^r' history-incremental-pattern-search-backward
 682     bindkey '^s' history-incremental-pattern-search-forward
 683 fi
 684
 685 # a generic accept-line wrapper
 686
 687 # This widget can prevent unwanted autocorrections from command-name
 688 # to _command-name, rehash automatically on enter and call any number
 689 # of builtin and user-defined widgets in different contexts.
 690 #
 691 # For a broader description, see:
 692 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 693 #
 694 # The code is imported from the file 'zsh/functions/accept-line' from
 695 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 696 # distributed under the same terms as zsh itself.
 697
 698 # A newly added command will may not be found or will cause false
 699 # correction attempts, if you got auto-correction set. By setting the
 700 # following style, we force accept-line() to rehash, if it cannot
 701 # find the first word on the command line in the $command[] hash.
 702 zstyle ':acceptline:*' rehash true
 703
 704 function Accept-Line() {
 705     setopt localoptions noksharrays
 706     local -a subs
 707     local -xi aldone
 708     local sub
 709     local alcontext=${1:-$alcontext}
 710
 711     zstyle -a ":acceptline:${alcontext}" actions subs
 712
 713     (( ${#subs} < 1 )) && return 0
 714
 715     (( aldone = 0 ))
 716     for sub in ${subs} ; do
 717         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 718         zle ${sub}
 719
 720         (( aldone > 0 )) && break
 721     done
 722 }
 723
 724 function Accept-Line-getdefault() {
 725     emulate -L zsh
 726     local default_action
 727
 728     zstyle -s ":acceptline:${alcontext}" default_action default_action
 729     case ${default_action} in
 730         ((accept-line|))
 731             printf ".accept-line"
 732             ;;
 733         (*)
 734             printf ${default_action}
 735             ;;
 736     esac
 737 }
 738
 739 function Accept-Line-HandleContext() {
 740     zle Accept-Line
 741
 742     default_action=$(Accept-Line-getdefault)
 743     zstyle -T ":acceptline:${alcontext}" call_default \
 744         && zle ${default_action}
 745 }
 746
 747 function accept-line() {
 748     setopt localoptions noksharrays
 749     local -ax cmdline
 750     local -x alcontext
 751     local buf com fname format msg default_action
 752
 753     alcontext='default'
 754     buf="${BUFFER}"
 755     cmdline=(${(z)BUFFER})
 756     com="${cmdline[1]}"
 757     fname="_${com}"
 758
 759     Accept-Line 'preprocess'
 760
 761     zstyle -t ":acceptline:${alcontext}" rehash \
 762         && [[ -z ${commands[$com]} ]]           \
 763         && rehash
 764
 765     if    [[ -n ${com}               ]] \
 766        && [[ -n ${reswords[(r)$com]} ]] \
 767        || [[ -n ${aliases[$com]}     ]] \
 768        || [[ -n ${functions[$com]}   ]] \
 769        || [[ -n ${builtins[$com]}    ]] \
 770        || [[ -n ${commands[$com]}    ]] ; then
 771
 772         # there is something sensible to execute, just do it.
 773         alcontext='normal'
 774         Accept-Line-HandleContext
 775
 776         return
 777     fi
 778
 779     if    [[ -o correct              ]] \
 780        || [[ -o correctall           ]] \
 781        && [[ -n ${functions[$fname]} ]] ; then
 782
 783         # nothing there to execute but there is a function called
 784         # _command_name; a completion widget. Makes no sense to
 785         # call it on the commandline, but the correct{,all} options
 786         # will ask for it nevertheless, so warn the user.
 787         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 788             # Okay, we warned the user before, he called us again,
 789             # so have it his way.
 790             alcontext='force'
 791             Accept-Line-HandleContext
 792
 793             return
 794         fi
 795
 796         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 797             alcontext='normal'
 798             Accept-Line-HandleContext
 799         else
 800             # prepare warning message for the user, configurable via zstyle.
 801             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 802
 803             if [[ -z ${msg} ]] ; then
 804                 msg="%c will not execute and completion %f exists."
 805             fi
 806
 807             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 808
 809             zle -M -- "${msg}"
 810         fi
 811         return
 812     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 813         # If we are here, the commandline contains something that is not
 814         # executable, which is neither subject to _command_name correction
 815         # and is not empty. might be a variable assignment
 816         alcontext='misc'
 817         Accept-Line-HandleContext
 818
 819         return
 820     fi
 821
 822     # If we got this far, the commandline only contains whitespace, or is empty.
 823     alcontext='empty'
 824     Accept-Line-HandleContext
 825 }
 826
 827 zle -N accept-line
 828 zle -N Accept-Line
 829 zle -N Accept-Line-HandleContext
 830
 831 # power completion - abbreviation expansion
 832 # power completion / abbreviation expansion / buffer expansion
 833 # see http://zshwiki.org/home/examples/zleiab for details
 834 # less risky than the global aliases but powerful as well
 835 # just type the abbreviation key and afterwards ',.' to expand it
 836 declare -A abk
 837 setopt extendedglob
 838 setopt interactivecomments
 839 abk=(
 840 #   key   # value                  (#d additional doc string)
 841 #A# start
 842     '...'  '../..'
 843     '....' '../../..'
 844     'BG'   '& exit'
 845     'C'    '| wc -l'
 846     'G'    '|& grep --color=auto '
 847     'H'    '| head'
 848     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 849     'L'    '| less'
 850     'LL'   '|& less -r'
 851     'M'    '| most'
 852     'N'    '&>/dev/null'           #d (No Output)
 853     'R'    '| tr A-z N-za-m'       #d (ROT13)
 854     'SL'   '| sort | less'
 855     'S'    '| sort -u'
 856     'T'    '| tail'
 857     'V'    '|& vim -'
 858 #A# end
 859     'co'   './configure && make && sudo make install'
 860 )
 861
 862 globalias() {
 863     emulate -L zsh
 864     setopt extendedglob
 865     local MATCH
 866
 867     if (( NOABBREVIATION > 0 )) ; then
 868         LBUFFER="${LBUFFER},."
 869         return 0
 870     fi
 871
 872     matched_chars='[.-|_a-zA-Z0-9]#'
 873     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 874     LBUFFER+=${abk[$MATCH]:-$MATCH}
 875 }
 876
 877 zle -N globalias
 878 bindkey ",." globalias
 879
 880 # autoloading
 881 zrcautoload zmv    # who needs mmv or rename?
 882 zrcautoload history-search-end
 883
 884 # we don't want to quote/espace URLs on our own...
 885 # if autoload -U url-quote-magic ; then
 886 #    zle -N self-insert url-quote-magic
 887 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 888 # else
 889 #    print 'Notice: no url-quote-magic available :('
 890 # fi
 891 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 892
 893 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 894 alias run-help >&/dev/null && unalias run-help
 895 for rh in run-help{,-git,-svk,-svn}; do
 896     zrcautoload $rh
 897 done; unset rh
 898
 899 # completion system
 900 if zrcautoload compinit ; then
 901     compinit || print 'Notice: no compinit available :('
 902 else
 903     print 'Notice: no compinit available :('
 904     function zstyle { }
 905     function compdef { }
 906 fi
 907
 908 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 909
 910 is4 && \
 911 for mod in complist deltochar mathfunc ; do
 912     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 913 done
 914
 915 # autoload zsh modules when they are referenced
 916 if is4 ; then
 917     zmodload -a  zsh/stat    zstat
 918     zmodload -a  zsh/zpty    zpty
 919     zmodload -ap zsh/mapfile mapfile
 920 fi
 921
 922 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 923     #k# Insert files and test globbing
 924     bindkey "^Xf" insert-files # C-x-f
 925 fi
 926
 927 bindkey ' '   magic-space    # also do history expansion on space
 928 #k# Trigger menu-complete
 929 bindkey '\ei' menu-complete  # menu completion via esc-i
 930
 931 # press esc-e for editing command line in $EDITOR or $VISUAL
 932 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 933     #k# Edit the current line in \kbd{\$EDITOR}
 934     bindkey '\ee' edit-command-line
 935 fi
 936
 937 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 938     #k# menu selection: pick item but stay in the menu
 939     bindkey -M menuselect '\e^M' accept-and-menu-complete
 940     # also use + and INSERT since it's easier to press repeatedly
 941     bindkey -M menuselect "+" accept-and-menu-complete
 942     bindkey -M menuselect "^[[2~" accept-and-menu-complete
 943
 944     # accept a completion and try to complete again by using menu
 945     # completion; very useful with completing directories
 946     # by using 'undo' one's got a simple file browser
 947     bindkey -M menuselect '^o' accept-and-infer-next-history
 948 fi
 949
 950 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 951 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
 952 zle -N insert-datestamp
 953
 954 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 955 bindkey '^Ed' insert-datestamp
 956
 957 # press esc-m for inserting last typed word again (thanks to caphuso!)
 958 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 959 zle -N insert-last-typed-word;
 960
 961 #k# Insert last typed word
 962 bindkey "\em" insert-last-typed-word
 963
 964 function grml-zsh-fg() {
 965   if (( ${#jobstates} )); then
 966     zle .push-input
 967     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
 968     BUFFER="${BUFFER}fg"
 969     zle .accept-line
 970   else
 971     zle -M 'No background jobs. Doing nothing.'
 972   fi
 973 }
 974 zle -N grml-zsh-fg
 975 #k# A smart shortcut for \kbd{fg<enter>}
 976 bindkey '^z' grml-zsh-fg
 977
 978 # run command line as user root via sudo:
 979 sudo-command-line() {
 980     [[ -z $BUFFER ]] && zle up-history
 981     if [[ $BUFFER != sudo\ * ]]; then
 982         BUFFER="sudo $BUFFER"
 983         CURSOR=$(( CURSOR+5 ))
 984     fi
 985 }
 986 zle -N sudo-command-line
 987
 988 #k# prepend the current command with "sudo"
 989 bindkey "^Os" sudo-command-line
 990
 991 ### jump behind the first word on the cmdline.
 992 ### useful to add options.
 993 function jump_after_first_word() {
 994     local words
 995     words=(${(z)BUFFER})
 996
 997     if (( ${#words} <= 1 )) ; then
 998         CURSOR=${#BUFFER}
 999     else
1000         CURSOR=${#${words[1]}}
1001     fi
1002 }
1003 zle -N jump_after_first_word
1004 #k# jump to after first word (for adding options)
1005 bindkey '^x1' jump_after_first_word
1006
1007 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1008 zle -C hist-complete complete-word _generic
1009 zstyle ':completion:hist-complete:*' completer _history
1010 #k# complete word from history with menu
1011 bindkey "^X^X" hist-complete
1012
1013 ## complete word from currently visible Screen or Tmux buffer.
1014 if check_com -c screen || check_com -c tmux; then
1015     _complete_screen_display() {
1016         [[ "$TERM" != "screen" ]] && return 1
1017
1018         local TMPFILE=$(mktemp)
1019         local -U -a _screen_display_wordlist
1020         trap "rm -f $TMPFILE" EXIT
1021
1022         # fill array with contents from screen hardcopy
1023         if ((${+TMUX})); then
1024             #works, but crashes tmux below version 1.4
1025             #luckily tmux -V option to ask for version, was also added in 1.4
1026             tmux -V &>/dev/null || return
1027             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1028         else
1029             screen -X hardcopy $TMPFILE
1030             #screen sucks, it dumps in latin1, apparently always. so recode it to system charset
1031             check_com recode && recode latin1 $TMPFILE
1032         fi
1033         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1034         # remove PREFIX to be completed from that array
1035         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1036         compadd -a _screen_display_wordlist
1037     }
1038     #k# complete word from currently visible GNU screen buffer
1039     bindkey -r "^XS"
1040     compdef -k _complete_screen_display complete-word '^XS'
1041 fi
1042
1043 # history
1044
1045 ZSHDIR=$HOME/.zsh
1046
1047 #v#
1048 HISTFILE=$HOME/.zsh_history
1049 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1050 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1051
1052 # dirstack handling
1053
1054 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1055 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1056
1057 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1058     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1059     # "cd -" won't work after login by just setting $OLDPWD, so
1060     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1061 fi
1062
1063 chpwd() {
1064     local -ax my_stack
1065     my_stack=( ${PWD} ${dirstack} )
1066     if is42 ; then
1067         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1068     else
1069         uprint my_stack >! ${DIRSTACKFILE}
1070     fi
1071 }
1072
1073 # directory based profiles
1074
1075 if is433 ; then
1076
1077 CHPWD_PROFILE='default'
1078 function chpwd_profiles() {
1079     # Say you want certain settings to be active in certain directories.
1080     # This is what you want.
1081     #
1082     # zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1083     # zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1084     #
1085     # When that's done and you enter a directory that matches the pattern
1086     # in the third part of the context, a function called chpwd_profile_grml,
1087     # for example, is called (if it exists).
1088     #
1089     # If no pattern matches (read: no profile is detected) the profile is
1090     # set to 'default', which means chpwd_profile_default is attempted to
1091     # be called.
1092     #
1093     # A word about the context (the ':chpwd:profiles:*' stuff in the zstyle
1094     # command) which is used: The third part in the context is matched against
1095     # ${PWD}. That's why using a pattern such as /foo/bar(|/|/*) makes sense.
1096     # Because that way the profile is detected for all these values of ${PWD}:
1097     #   /foo/bar
1098     #   /foo/bar/
1099     #   /foo/bar/baz
1100     # So, if you want to make double damn sure a profile works in /foo/bar
1101     # and everywhere deeper in that tree, just use (|/|/*) and be happy.
1102     #
1103     # The name of the detected profile will be available in a variable called
1104     # 'profile' in your functions. You don't need to do anything, it'll just
1105     # be there.
1106     #
1107     # Then there is the parameter $CHPWD_PROFILE is set to the profile, that
1108     # was is currently active. That way you can avoid running code for a
1109     # profile that is already active, by running code such as the following
1110     # at the start of your function:
1111     #
1112     # function chpwd_profile_grml() {
1113     #     [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1114     #   ...
1115     # }
1116     #
1117     # The initial value for $CHPWD_PROFILE is 'default'.
1118     #
1119     # Version requirement:
1120     #   This feature requires zsh 4.3.3 or newer.
1121     #   If you use this feature and need to know whether it is active in your
1122     #   current shell, there are several ways to do that. Here are two simple
1123     #   ways:
1124     #
1125     #   a) If knowing if the profiles feature is active when zsh starts is
1126     #      good enough for you, you can put the following snippet into your
1127     #      .zshrc.local:
1128     #
1129     #   (( ${+functions[chpwd_profiles]} )) && print "directory profiles active"
1130     #
1131     #   b) If that is not good enough, and you would prefer to be notified
1132     #      whenever a profile changes, you can solve that by making sure you
1133     #      start *every* profile function you create like this:
1134     #
1135     #   function chpwd_profile_myprofilename() {
1136     #       [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1137     #       print "chpwd(): Switching to profile: $profile"
1138     #     ...
1139     #   }
1140     #
1141     #      That makes sure you only get notified if a profile is *changed*,
1142     #      not everytime you change directory, which would probably piss
1143     #      you off fairly quickly. :-)
1144     #
1145     # There you go. Now have fun with that.
1146     local -x profile
1147
1148     zstyle -s ":chpwd:profiles:${PWD}" profile profile || profile='default'
1149     if (( ${+functions[chpwd_profile_$profile]} )) ; then
1150         chpwd_profile_${profile}
1151     fi
1152
1153     CHPWD_PROFILE="${profile}"
1154     return 0
1155 }
1156 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1157
1158 fi # is433
1159
1160 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1161 if [[ $BATTERY -gt 0 ]] ; then
1162     if ! check_com -c acpi ; then
1163         BATTERY=0
1164     fi
1165 fi
1166
1167 battery() {
1168 if [[ $BATTERY -gt 0 ]] ; then
1169     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1170     if [[ -z "$PERCENT" ]] ; then
1171         PERCENT='acpi not present'
1172     else
1173         if [[ "$PERCENT" -lt 20 ]] ; then
1174             PERCENT="warning: ${PERCENT}%%"
1175         else
1176             PERCENT="${PERCENT}%%"
1177         fi
1178     fi
1179 fi
1180 }
1181 # set colors for use in prompts
1182 if zrcautoload colors && colors 2>/dev/null ; then
1183     BLUE="%{${fg[blue]}%}"
1184     RED="%{${fg_bold[red]}%}"
1185     GREEN="%{${fg[green]}%}"
1186     CYAN="%{${fg[cyan]}%}"
1187     MAGENTA="%{${fg[magenta]}%}"
1188     YELLOW="%{${fg[yellow]}%}"
1189     WHITE="%{${fg[white]}%}"
1190     NO_COLOUR="%{${reset_color}%}"
1191 else
1192     BLUE=$'%{\e[1;34m%}'
1193     RED=$'%{\e[1;31m%}'
1194     GREEN=$'%{\e[1;32m%}'
1195     CYAN=$'%{\e[1;36m%}'
1196     WHITE=$'%{\e[1;37m%}'
1197     MAGENTA=$'%{\e[1;35m%}'
1198     YELLOW=$'%{\e[1;33m%}'
1199     NO_COLOUR=$'%{\e[0m%}'
1200 fi
1201
1202 # gather version control information for inclusion in a prompt
1203
1204 if zrcautoload vcs_info; then
1205     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1206     # function, which can cause a lot of trouble with our directory-based
1207     # profiles. So:
1208     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1209         function VCS_INFO_realpath () {
1210             setopt localoptions NO_shwordsplit chaselinks
1211             ( builtin cd -q $1 2> /dev/null && pwd; )
1212         }
1213     fi
1214
1215     zstyle ':vcs_info:*' max-exports 2
1216
1217     if [[ -o restricted ]]; then
1218         zstyle ':vcs_info:*' enable NONE
1219     fi
1220 fi
1221
1222 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1223 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1224 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1225 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1226 #       to $vcs_info_msg_N_ as soon as we use the included version.
1227 if [[ "$TERM" == dumb ]] ; then
1228     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1229     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1230 else
1231     # these are the same, just with a lot of colours:
1232     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
1233                                        "zsh: %r"
1234     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
1235                                        "zsh: %r"
1236     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1237 fi
1238
1239 # command not found handling
1240
1241 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1242 function command_not_found_handler() {
1243     emulate -L zsh
1244     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1245         ${GRML_ZSH_CNF_HANDLER} $1
1246     fi
1247     return 1
1248 }
1249
1250 # set prompt
1251 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1252     promptinit # people should be able to use their favourite prompt
1253 else
1254     print 'Notice: no promptinit available :('
1255 fi
1256
1257 setopt prompt_subst
1258
1259 # make sure to use right prompt only when not running a command
1260 is41 && setopt transient_rprompt
1261
1262
1263 function ESC_print () {
1264     info_print $'\ek' $'\e\\' "$@"
1265 }
1266 function set_title () {
1267     info_print  $'\e]0;' $'\a' "$@"
1268 }
1269
1270 function info_print () {
1271     local esc_begin esc_end
1272     esc_begin="$1"
1273     esc_end="$2"
1274     shift 2
1275     printf '%s' ${esc_begin}
1276     printf '%s' "$*"
1277     printf '%s' "${esc_end}"
1278 }
1279
1280 # TODO: revise all these NO* variables and especially their documentation
1281 #       in zsh-help() below.
1282 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1283     [[ $NOPRECMD -gt 0 ]] && return 0
1284     # update VCS information
1285     (( ${+functions[vcs_info]} )) && vcs_info
1286
1287     if [[ $TERM == screen* ]] ; then
1288         if [[ -n ${vcs_info_msg_1_} ]] ; then
1289             ESC_print ${vcs_info_msg_1_}
1290         else
1291             ESC_print "zsh"
1292         fi
1293     fi
1294     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1295     if [[ ${DONTSETRPROMPT:-} -eq 0 ]] ; then
1296         if [[ $BATTERY -gt 0 ]] ; then
1297             # update battery (dropped into $PERCENT) information
1298             battery
1299             RPROMPT="%(?..:() ${PERCENT}"
1300         else
1301             RPROMPT="%(?..:() "
1302         fi
1303     fi
1304     # adjust title of xterm
1305     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1306     [[ ${NOTITLE:-} -gt 0 ]] && return 0
1307     case $TERM in
1308         (xterm*|rxvt*)
1309             set_title ${(%):-"%n@%m: %~"}
1310             ;;
1311     esac
1312 }
1313
1314 # preexec() => a function running before every command
1315 is4 && [[ $NOPRECMD -eq 0 ]] && \
1316 preexec () {
1317     [[ $NOPRECMD -gt 0 ]] && return 0
1318 # set hostname if not running on host with name 'grml'
1319     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1320        NAME="@$HOSTNAME"
1321     fi
1322 # get the name of the program currently running and hostname of local machine
1323 # set screen window title if running in a screen
1324     if [[ "$TERM" == screen* ]] ; then
1325         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1326         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1327         ESC_print ${CMD}
1328     fi
1329 # adjust title of xterm
1330     [[ ${NOTITLE} -gt 0 ]] && return 0
1331     case $TERM in
1332         (xterm*|rxvt*)
1333             set_title "${(%):-"%n@%m:"}" "$1"
1334             ;;
1335     esac
1336 }
1337
1338 EXITCODE="%(?..%?%1v )"
1339 PS2='\`%_> '      # secondary prompt, printed when the shell needs more information to complete a command.
1340 PS3='?# '         # selection prompt used within a select loop.
1341 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1342
1343 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1344 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1345     debian_chroot=$(cat /etc/debian_chroot)
1346 fi
1347
1348 # don't use colors on dumb terminals (like emacs):
1349 if [[ "$TERM" == dumb ]] ; then
1350     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
1351 else
1352     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
1353     # set variable identifying the chroot you work in (used in the prompt below)
1354     if [[ $GRMLPROMPT -gt 0 ]] ; then
1355         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1356 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1357     else
1358         # This assembles the primary prompt string
1359         if (( EUID != 0 )); then
1360             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1361         else
1362             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1363         fi
1364     fi
1365 fi
1366
1367 PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
1368
1369 # if we are inside a grml-chroot set a specific prompt theme
1370 if [[ -n "$GRML_CHROOT" ]] ; then
1371     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1372 fi
1373
1374 # 'hash' some often used directories
1375 #d# start
1376 hash -d deb=/var/cache/apt/archives
1377 hash -d doc=/usr/share/doc
1378 hash -d linux=/lib/modules/$(command uname -r)/build/
1379 hash -d log=/var/log
1380 hash -d slog=/var/log/syslog
1381 hash -d src=/usr/src
1382 hash -d templ=/usr/share/doc/grml-templates
1383 hash -d tt=/usr/share/doc/texttools-doc
1384 hash -d www=/var/www
1385 #d# end
1386
1387 # some aliases
1388 if check_com -c screen ; then
1389     if [[ $UID -eq 0 ]] ; then
1390         [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
1391     elif [[ -r $HOME/.screenrc ]] ; then
1392         alias screen="${commands[screen]} -c $HOME/.screenrc"
1393     else
1394         if [[ -r /etc/grml/screenrc_grml ]]; then
1395             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1396         else
1397             [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
1398         fi
1399     fi
1400 fi
1401
1402 # do we have GNU ls with color-support?
1403 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
1404     #a1# execute \kbd{@a@}:\quad ls with colors
1405     alias ls='ls -b -CF --color=auto'
1406     #a1# execute \kbd{@a@}:\quad list all files, with colors
1407     alias la='ls -la --color=auto'
1408     #a1# long colored list, without dotfiles (@a@)
1409     alias ll='ls -l --color=auto'
1410     #a1# long colored list, human readable sizes (@a@)
1411     alias lh='ls -hAl --color=auto'
1412     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1413     alias l='ls -lF --color=auto'
1414 else
1415     alias ls='ls -b -CF'
1416     alias la='ls -la'
1417     alias ll='ls -l'
1418     alias lh='ls -hAl'
1419     alias l='ls -lF'
1420 fi
1421
1422 alias mdstat='cat /proc/mdstat'
1423 alias ...='cd ../../'
1424
1425 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1426 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1427     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1428 fi
1429
1430 alias cp='nocorrect cp'         # no spelling correction on cp
1431 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
1432 alias mv='nocorrect mv'         # no spelling correction on mv
1433 alias rm='nocorrect rm'         # no spelling correction on rm
1434
1435 #a1# Execute \kbd{rmdir}
1436 alias rd='rmdir'
1437 #a1# Execute \kbd{mkdir}
1438 alias md='mkdir'
1439
1440 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1441 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1442 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1443
1444 # make sure it is not assigned yet
1445 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1446 utf2iso() {
1447     if isutfenv ; then
1448         for ENV in $(env | command grep -i '.utf') ; do
1449             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1450         done
1451     fi
1452 }
1453
1454 # make sure it is not assigned yet
1455 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1456 iso2utf() {
1457     if ! isutfenv ; then
1458         for ENV in $(env | command grep -i '\.iso') ; do
1459             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1460         done
1461     fi
1462 }
1463
1464 # I like clean prompt, so provide simple way to get that
1465 check_com 0 || alias 0='return 0'
1466
1467 # for really lazy people like mika:
1468 check_com S &>/dev/null || alias S='screen'
1469 check_com s &>/dev/null || alias s='ssh'
1470
1471 # especially for roadwarriors using GNU screen and ssh:
1472 if ! check_com asc &>/dev/null ; then
1473   asc() { autossh -t "$@" 'screen -RdU' }
1474   compdef asc=ssh
1475 fi
1476
1477 # get top 10 shell commands:
1478 alias top10='print -l ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
1479
1480 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
1481 if check_com -c truecrypt ; then
1482     if isutfenv ; then
1483         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
1484     else
1485         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
1486     fi
1487 fi
1488
1489 #f1# Hints for the use of zsh on grml
1490 zsh-help() {
1491     print "$bg[white]$fg[black]
1492 zsh-help - hints for use of zsh on grml
1493 =======================================$reset_color"
1494
1495     print '
1496 Main configuration of zsh happens in /etc/zsh/zshrc.
1497 That file is part of the package grml-etc-core, if you want to
1498 use them on a non-grml-system just get the tar.gz from
1499 http://deb.grml.org/ or (preferably) get it from the git repository:
1500
1501   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1502
1503 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1504 The file is still there, but it is empty for backwards compatibility.
1505
1506 For your own changes use these two files:
1507     $HOME/.zshrc.pre
1508     $HOME/.zshrc.local
1509
1510 The former is sourced very early in our zshrc, the latter is sourced
1511 very lately.
1512
1513 System wide configuration without touching configuration files of grml
1514 can take place in /etc/zsh/zshrc.local.
1515
1516 Normally, the root user (EUID == 0) does not get the whole grml setup.
1517 If you want to force the whole setup for that user, too, set
1518 GRML_ALWAYS_LOAD_ALL=1 in .zshrc.pre in root'\''s home directory.
1519
1520 For information regarding zsh start at http://grml.org/zsh/
1521
1522 Take a look at grml'\''s zsh refcard:
1523 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1524
1525 Check out the main zsh refcard:
1526 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1527
1528 And of course visit the zsh-lovers:
1529 % man zsh-lovers
1530
1531 You can adjust some options through environment variables when
1532 invoking zsh without having to edit configuration files.
1533 Basically meant for bash users who are not used to the power of
1534 the zsh yet. :)
1535
1536   "NOCOR=1    zsh" => deactivate automatic correction
1537   "NOMENU=1   zsh" => do not use auto menu completion (note: use ctrl-d for completion instead!)
1538   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1539   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1540                       preexec() and precmd() completely
1541   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1542   "COMMAND_NOT_FOUND=1 zsh"
1543                    => Enable a handler if an external command was not found
1544                       The command called in the handler can be altered by setting
1545                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1546                       "/usr/share/command-not-found/command-not-found"
1547
1548 A value greater than 0 is enables a feature; a value equal to zero
1549 disables it. If you like one or the other of these settings, you can
1550 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1551 zshrc.'
1552
1553     print "
1554 $bg[white]$fg[black]
1555 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1556 Enjoy your grml system with the zsh!$reset_color"
1557 }
1558
1559 # debian stuff
1560 if [[ -r /etc/debian_version ]] ; then
1561     #a3# Execute \kbd{apt-cache search}
1562     alias acs='apt-cache search'
1563     #a3# Execute \kbd{apt-cache show}
1564     alias acsh='apt-cache show'
1565     #a3# Execute \kbd{apt-cache policy}
1566     alias acp='apt-cache policy'
1567     #a3# Execute \kbd{apt-get dist-upgrade}
1568     salias adg="apt-get dist-upgrade"
1569     #a3# Execute \kbd{apt-get install}
1570     salias agi="apt-get install"
1571     #a3# Execute \kbd{aptitude install}
1572     salias ati="aptitude install"
1573     #a3# Execute \kbd{apt-get upgrade}
1574     salias ag="apt-get upgrade"
1575     #a3# Execute \kbd{apt-get update}
1576     salias au="apt-get update"
1577     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1578     salias -a up="aptitude update ; aptitude safe-upgrade"
1579     #a3# Execute \kbd{dpkg-buildpackage}
1580     alias dbp='dpkg-buildpackage'
1581     #a3# Execute \kbd{grep-excuses}
1582     alias ge='grep-excuses'
1583
1584     # debian upgrade
1585     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
1586     upgrade() {
1587         emulate -L zsh
1588         if [[ -z $1 ]] ; then
1589             $SUDO apt-get update
1590             $SUDO apt-get -u upgrade
1591         else
1592             ssh $1 $SUDO apt-get update
1593             # ask before the upgrade
1594             local dummy
1595             ssh $1 $SUDO apt-get --no-act upgrade
1596             echo -n 'Process the upgrade?'
1597             read -q dummy
1598             if [[ $dummy == "y" ]] ; then
1599                 ssh $1 $SUDO apt-get -u upgrade --yes
1600             fi
1601         fi
1602     }
1603
1604     # get a root shell as normal user in live-cd mode:
1605     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1606        alias su="sudo su"
1607      fi
1608
1609     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1610     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1611     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1612     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1613 fi
1614
1615 # sort installed Debian-packages by size
1616 if check_com -c dpkg-query ; then
1617     #a3# List installed Debian-packages sorted by size
1618     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1619 fi
1620
1621 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1622 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1623     if check_com -c wodim; then
1624         cdrecord() {
1625             cat <<EOMESS
1626 cdrecord is not provided under its original name by Debian anymore.
1627 See #377109 in the BTS of Debian for more details.
1628
1629 Please use the wodim binary instead
1630 EOMESS
1631             return 1
1632         }
1633     fi
1634 fi
1635
1636 # get_tw_cli has been renamed into get_3ware
1637 if check_com -c get_3ware ; then
1638     get_tw_cli() {
1639         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
1640         get_3ware
1641     }
1642 fi
1643
1644 # I hate lacking backward compatibility, so provide an alternative therefore
1645 if ! check_com -c apache2-ssl-certificate ; then
1646
1647     apache2-ssl-certificate() {
1648
1649     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
1650     print 'You might want to take a look at Debian the package ssl-cert as well.'
1651     print 'To generate a certificate for use with apache2 follow the instructions:'
1652
1653     echo '
1654
1655 export RANDFILE=/dev/random
1656 mkdir /etc/apache2/ssl/
1657 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
1658 chmod 600 /etc/apache2/ssl/apache.pem
1659
1660 Run "grml-tips ssl-certificate" if you need further instructions.
1661 '
1662     }
1663 fi
1664
1665 # Use hard limits, except for a smaller stack and no core dumps
1666 unlimit
1667 is425 && limit stack 8192
1668 isgrmlcd && limit core 0 # important for a live-cd-system
1669 limit -s
1670
1671 # completion system
1672
1673 # called later (via is4 && grmlcomp)
1674 # note: use 'zstyle' for getting current settings
1675 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
1676 grmlcomp() {
1677     # TODO: This could use some additional information
1678
1679     # allow one error for every three characters typed in approximate completer
1680     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1681
1682     # don't complete backup files as executables
1683     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1684
1685     # start menu completion only if it could find no unambiguous initial string
1686     zstyle ':completion:*:correct:*'       insert-unambiguous true
1687     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1688     zstyle ':completion:*:correct:*'       original true
1689
1690     # activate color-completion
1691     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1692
1693     # format on completion
1694     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1695
1696     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1697     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1698
1699     # insert all expansions for expand completer
1700     zstyle ':completion:*:expand:*'        tag-order all-expansions
1701     zstyle ':completion:*:history-words'   list false
1702
1703     # activate menu
1704     zstyle ':completion:*:history-words'   menu yes
1705
1706     # ignore duplicate entries
1707     zstyle ':completion:*:history-words'   remove-all-dups yes
1708     zstyle ':completion:*:history-words'   stop yes
1709
1710     # match uppercase from lowercase
1711     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1712
1713     # separate matches into groups
1714     zstyle ':completion:*:matches'         group 'yes'
1715     zstyle ':completion:*'                 group-name ''
1716
1717     if [[ "$NOMENU" -eq 0 ]] ; then
1718         # if there are more than 5 options allow selecting from a menu
1719         zstyle ':completion:*'               menu select=5
1720     else
1721         # don't use any menus at all
1722         setopt no_auto_menu
1723     fi
1724
1725     zstyle ':completion:*:messages'        format '%d'
1726     zstyle ':completion:*:options'         auto-description '%d'
1727
1728     # describe options in full
1729     zstyle ':completion:*:options'         description 'yes'
1730
1731     # on processes completion complete all user processes
1732     zstyle ':completion:*:processes'       command 'ps -au$USER'
1733
1734     # offer indexes before parameters in subscripts
1735     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1736
1737     # provide verbose completion information
1738     zstyle ':completion:*'                 verbose true
1739
1740     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1741     # for commands (read: 1st word in the line) that it will list for the user
1742     # to choose from. The following disables that, because it's not exactly fast.
1743     zstyle ':completion:*:-command-:*:'    verbose false
1744
1745     # set format for warnings
1746     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1747
1748     # define files to ignore for zcompile
1749     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1750     zstyle ':completion:correct:'          prompt 'correct to: %e'
1751
1752     # Ignore completion functions for commands you don't have:
1753     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1754
1755     # Provide more processes in completion of programs like killall:
1756     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1757
1758     # complete manual by their section
1759     zstyle ':completion:*:manuals'    separate-sections true
1760     zstyle ':completion:*:manuals.*'  insert-sections   true
1761     zstyle ':completion:*:man:*'      menu yes select
1762
1763     # provide .. as a completion
1764     zstyle ':completion:*' special-dirs ..
1765
1766     # run rehash on completion so new installed program are found automatically:
1767     _force_rehash() {
1768         (( CURRENT == 1 )) && rehash
1769         return 1
1770     }
1771
1772     ## correction
1773     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1774     if [[ "$NOCOR" -gt 0 ]] ; then
1775         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1776         setopt nocorrect
1777     else
1778         # try to be smart about when to use what completer...
1779         setopt correct
1780         zstyle -e ':completion:*' completer '
1781             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1782                 _last_try="$HISTNO$BUFFER$CURSOR"
1783                 reply=(_complete _match _ignored _prefix _files)
1784             else
1785                 if [[ $words[1] == (rm|mv) ]] ; then
1786                     reply=(_complete _files)
1787                 else
1788                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1789                 fi
1790             fi'
1791     fi
1792
1793     # command for process lists, the local web server details and host completion
1794     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1795
1796     # caching
1797     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1798                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1799
1800     # host completion
1801     if is42 ; then
1802         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1803         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1804     else
1805         _ssh_hosts=()
1806         _etc_hosts=()
1807     fi
1808     hosts=(
1809         $(hostname)
1810         "$_ssh_hosts[@]"
1811         "$_etc_hosts[@]"
1812         grml.org
1813         localhost
1814     )
1815     zstyle ':completion:*:hosts' hosts $hosts
1816     # TODO: so, why is this here?
1817     #  zstyle '*' hosts $hosts
1818
1819     # use generic completion system for programs not yet defined; (_gnu_generic works
1820     # with commands that provide a --help option with "standard" gnu-like output.)
1821     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
1822                    pal stow tail uname ; do
1823         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
1824     done; unset compcom
1825
1826     # see upgrade function in this file
1827     compdef _hosts upgrade
1828 }
1829
1830 # grmlstuff
1831 grmlstuff() {
1832 # people should use 'grml-x'!
1833     if check_com -c 915resolution; then
1834         855resolution() {
1835             echo "Please use 915resolution as resolution modifying tool for Intel \
1836 graphic chipset."
1837             return -1
1838         }
1839     fi
1840
1841     #a1# Output version of running grml
1842     alias grml-version='cat /etc/grml_version'
1843
1844     if check_com -c rebuildfstab ; then
1845         #a1# Rebuild /etc/fstab
1846         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1847     fi
1848
1849     if check_com -c grml-debootstrap ; then
1850         debian2hd() {
1851             echo "Installing debian to harddisk is possible by using grml-debootstrap."
1852             return 1
1853         }
1854     fi
1855 }
1856
1857 # now run the functions
1858 isgrml && checkhome
1859 is4    && isgrml    && grmlstuff
1860 is4    && grmlcomp
1861
1862 # keephack
1863 is4 && xsource "/etc/zsh/keephack"
1864
1865 # wonderful idea of using "e" glob qualifier by Peter Stephenson
1866 # You use it as follows:
1867 # $ NTREF=/reference/file
1868 # $ ls -l *(e:nt:)
1869 # This lists all the files in the current directory newer than the reference file.
1870 # You can also specify the reference file inline; note quotes:
1871 # $ ls -l *(e:'nt ~/.zshenv':)
1872 is4 && nt() {
1873     if [[ -n $1 ]] ; then
1874         local NTREF=${~1}
1875     fi
1876     [[ $REPLY -nt $NTREF ]]
1877 }
1878
1879 # shell functions
1880
1881 #f1# Provide csh compatibility
1882 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
1883
1884 #f1# Reload an autoloadable function
1885 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1886 compdef _functions freload
1887
1888 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1889 sll() {
1890     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1891     for file in "$@" ; do
1892         while [[ -h "$file" ]] ; do
1893             ls -l $file
1894             file=$(readlink "$file")
1895         done
1896     done
1897 }
1898
1899 # TODO: Is it supported to use pager settings like this?
1900 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
1901 # with respect to wordsplitting. (ie. ${=PAGER})
1902 if check_com -c $PAGER ; then
1903     #f1# View Debian's changelog of a given package
1904     dchange() {
1905         emulate -L zsh
1906         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
1907             $PAGER /usr/share/doc/$1/changelog.Debian.gz
1908         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1909             $PAGER /usr/share/doc/$1/changelog.gz
1910         else
1911             if check_com -c aptitude ; then
1912                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1913                 if isgrml ; then
1914                     aptitude -t unstable changelog $1
1915                 else
1916                     aptitude changelog $1
1917                 fi
1918             else
1919                 echo "No changelog for package $1 found, sorry."
1920                 return 1
1921             fi
1922         fi
1923     }
1924     _dchange() { _files -W /usr/share/doc -/ }
1925     compdef _dchange dchange
1926
1927     #f1# View Debian's NEWS of a given package
1928     dnews() {
1929         emulate -L zsh
1930         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
1931             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
1932         else
1933             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
1934                 $PAGER /usr/share/doc/$1/NEWS.gz
1935             else
1936                 echo "No NEWS file for package $1 found, sorry."
1937                 return 1
1938             fi
1939         fi
1940     }
1941     _dnews() { _files -W /usr/share/doc -/ }
1942     compdef _dnews dnews
1943
1944     #f1# View upstream's changelog of a given package
1945     uchange() {
1946         emulate -L zsh
1947         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1948             $PAGER /usr/share/doc/$1/changelog.gz
1949         else
1950             echo "No changelog for package $1 found, sorry."
1951             return 1
1952         fi
1953     }
1954     _uchange() { _files -W /usr/share/doc -/ }
1955     compdef _uchange uchange
1956 fi
1957
1958 # zsh profiling
1959 profile() {
1960     ZSH_PROFILE_RC=1 $SHELL "$@"
1961 }
1962
1963 #f1# Edit an alias via zle
1964 edalias() {
1965     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1966 }
1967 compdef _aliases edalias
1968
1969 #f1# Edit a function via zle
1970 edfunc() {
1971     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
1972 }
1973 compdef _functions edfunc
1974
1975 # use it e.g. via 'Restart apache2'
1976 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
1977 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
1978 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
1979 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
1980 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
1981 if [[ -d /etc/init.d || -d /etc/service ]] ; then
1982     __start_stop() {
1983         local action_="${1:l}"  # e.g Start/Stop/Restart
1984         local service_="$2"
1985         local param_="$3"
1986
1987         local service_target_="$(readlink /etc/init.d/$service_)"
1988         if [[ $service_target_ == "/usr/bin/sv" ]]; then
1989             # runit
1990             case "${action_}" in
1991                 start) if [[ ! -e /etc/service/$service_ ]]; then
1992                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
1993                        else
1994                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1995                        fi ;;
1996                 # there is no reload in runits sysv emulation
1997                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
1998                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
1999             esac
2000         else
2001             # sysvinit
2002             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2003         fi
2004     }
2005
2006     _grmlinitd() {
2007         local -a scripts
2008         scripts=( /etc/init.d/*(x:t) )
2009         _describe "service startup script" scripts
2010     }
2011
2012     for i in Start Restart Stop Force-Reload Reload ; do
2013         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2014         compdef _grmlinitd $i
2015     done
2016 fi
2017
2018 #f1# Provides useful information on globbing
2019 H-Glob() {
2020     echo -e "
2021     /      directories
2022     .      plain files
2023     @      symbolic links
2024     =      sockets
2025     p      named pipes (FIFOs)
2026     *      executable plain files (0100)
2027     %      device files (character or block special)
2028     %b     block special files
2029     %c     character special files
2030     r      owner-readable files (0400)
2031     w      owner-writable files (0200)
2032     x      owner-executable files (0100)
2033     A      group-readable files (0040)
2034     I      group-writable files (0020)
2035     E      group-executable files (0010)
2036     R      world-readable files (0004)
2037     W      world-writable files (0002)
2038     X      world-executable files (0001)
2039     s      setuid files (04000)
2040     S      setgid files (02000)
2041     t      files with the sticky bit (01000)
2042
2043   print *(m-1)          # Files modified up to a day ago
2044   print *(a1)           # Files accessed a day ago
2045   print *(@)            # Just symlinks
2046   print *(Lk+50)        # Files bigger than 50 kilobytes
2047   print *(Lk-50)        # Files smaller than 50 kilobytes
2048   print **/*.c          # All *.c files recursively starting in \$PWD
2049   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2050   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2051   print *~*.*           # All Files that do not contain a dot
2052   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2053   print -l *(.c|.h)     # Lists *.c and *.h
2054   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2055   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2056 }
2057 alias help-zshglob=H-Glob
2058
2059 #v1# set number of lines to display per page
2060 HELP_LINES_PER_PAGE=20
2061 #v1# set location of help-zle cache file
2062 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
2063 #f1# helper function for help-zle, actually generates the help text
2064 help_zle_parse_keybindings()
2065 {
2066     emulate -L zsh
2067     setopt extendedglob
2068     unsetopt ksharrays  #indexing starts at 1
2069
2070     #v1# choose files that help-zle will parse for keybindings
2071     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
2072
2073     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
2074         local load_cache=0
2075         for f ($KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
2076         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
2077     fi
2078
2079     #fill with default keybindings, possibly to be overwriten in a file later
2080     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2081     local -A help_zle_keybindings
2082     help_zle_keybindings['<Ctrl>@']="set MARK"
2083     help_zle_keybindings['<Ctrl>X<Ctrl>J']="vi-join lines"
2084     help_zle_keybindings['<Ctrl>X<Ctrl>B']="jump to matching brace"
2085     help_zle_keybindings['<Ctrl>X<Ctrl>U']="undo"
2086     help_zle_keybindings['<Ctrl>_']="undo"
2087     help_zle_keybindings['<Ctrl>X<Ctrl>F<c>']="find <c> in cmdline"
2088     help_zle_keybindings['<Ctrl>A']="goto beginning of line"
2089     help_zle_keybindings['<Ctrl>E']="goto end of line"
2090     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2091     help_zle_keybindings['<Alt>T']="transpose words"
2092     help_zle_keybindings['<Alt>s']="spellcheck word"
2093     help_zle_keybindings['<Ctrl>K']="backward kill buffer"
2094     help_zle_keybindings['<Ctrl>U']="forward kill buffer"
2095     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2096     help_zle_keybindings["<Alt>'"]="quote line"
2097     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2098     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2099     help_zle_keybindings['<Alt>U']="make next word Uppercase"
2100     help_zle_keybindings['<Alt>l']="make next word lowercase"
2101     help_zle_keybindings['<Ctrl>Xd']="preview expansion under cursor"
2102     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2103     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2104     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2105     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2106     help_zle_keybindings['<Ctrl>V']="insert next keypress symbol literally (e.g. for bindkey)"
2107     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2108     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2109     help_zle_keybindings['<Alt>H']="run help on current command"
2110
2111     #init global variables
2112     unset help_zle_lines help_zle_sln
2113     typeset -g -a help_zle_lines
2114     typeset -g help_zle_sln=1
2115
2116     local k v
2117     local lastkeybind_desc contents     #last description starting with #k# that we found
2118     local num_lines_elapsed=0            #number of lines between last description and keybinding
2119     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2120     for f in $HELPZLE_KEYBINDING_FILES; do
2121         [[ -r "$f" ]] || continue   #not readable ? skip it
2122         contents="$(<$f)"
2123         for cline in "${(f)contents}"; do
2124             #zsh pattern: matches lines like: #k# ..............
2125             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2126                 lastkeybind_desc="$match[*]"
2127                 num_lines_elapsed=0
2128             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2129             #             ignores lines that are commentend out
2130             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2131             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2132                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2133                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2134                     #substitute keybinding string with something readable
2135                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2136                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2137                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2138                     help_zle_keybindings[${k}]=$lastkeybind_desc
2139                 fi
2140                 lastkeybind_desc=""
2141             else
2142               ((num_lines_elapsed++))
2143             fi
2144         done
2145     done
2146     unset contents
2147     #calculate length of keybinding column
2148     local kstrlen=0
2149     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2150     #convert the assoc array into preformated lines, which we are able to sort
2151     for k v in ${(kv)help_zle_keybindings[@]}; do
2152         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2153         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2154     done
2155     #sort lines alphabetically
2156     help_zle_lines=("${(i)help_zle_lines[@]}")
2157     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2158     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2159     zcompile $HELP_ZLE_CACHE_FILE
2160 }
2161 typeset -g help_zle_sln
2162 typeset -g -a help_zle_lines
2163
2164 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2165 help-zle()
2166 {
2167     emulate -L zsh
2168     unsetopt ksharrays  #indexing starts at 1
2169     #help lines already generated ? no ? then do it
2170     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2171     #already displayed all lines ? go back to the start
2172     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2173     local sln=$help_zle_sln
2174     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2175     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2176     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2177 }
2178 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2179 zle -N help-zle && bindkey '^Xz' help-zle
2180
2181 # grep for running process, like: 'any vim'
2182 any() {
2183     emulate -L zsh
2184     unsetopt KSH_ARRAYS
2185     if [[ -z "$1" ]] ; then
2186         echo "any - grep for process(es) by keyword" >&2
2187         echo "Usage: any <keyword>" >&2 ; return 1
2188     else
2189         ps xauwww | grep -i --color=auto "[${1[1]}]${1[2,-1]}"
2190     fi
2191 }
2192
2193
2194 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2195 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2196 [[ -r /proc/1/maps ]] && \
2197 deswap() {
2198     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2199     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2200     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2201 }
2202
2203 # spawn a minimally set up mksh - useful if you want to umount /usr/.
2204 minimal-shell() {
2205     emulate -L zsh
2206     local shell="/bin/mksh"
2207
2208     if [[ ! -x ${shell} ]]; then
2209         printf '`%s'\'' not available, giving up.\n' ${shell} >&2
2210         return 1
2211     fi
2212
2213     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ${shell}
2214 }
2215
2216 # a wrapper for vim, that deals with title setting
2217 #   VIM_OPTIONS
2218 #       set this array to a set of options to vim you always want
2219 #       to have set when calling vim (in .zshrc.local), like:
2220 #           VIM_OPTIONS=( -p )
2221 #       This will cause vim to send every file given on the
2222 #       commandline to be send to it's own tab (needs vim7).
2223 vim() {
2224     VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2225 }
2226
2227 # make a backup of a file
2228 bk() {
2229     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2230 }
2231
2232 ssl_hashes=( sha512 sha256 sha1 md5 )
2233
2234 for sh in ${ssl_hashes}; do
2235     eval 'ssl-cert-'${sh}'() {
2236         emulate -L zsh
2237         if [[ -z $1 ]] ; then
2238             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2239             return 1
2240         fi
2241         openssl x509 -noout -fingerprint -'${sh}' -in $1
2242     }'
2243 done; unset sh
2244
2245 ssl-cert-fingerprints() {
2246     emulate -L zsh
2247     local i
2248     if [[ -z $1 ]] ; then
2249         printf 'usage: ssl-cert-fingerprints <file>\n'
2250         return 1
2251     fi
2252     for i in ${ssl_hashes}
2253         do ssl-cert-$i $1;
2254     done
2255 }
2256
2257 ssl-cert-info() {
2258     emulate -L zsh
2259     if [[ -z $1 ]] ; then
2260         printf 'usage: ssl-cert-info <file>\n'
2261         return 1
2262     fi
2263     openssl x509 -noout -text -in $1
2264     ssl-cert-fingerprints $1
2265 }
2266
2267 # make sure our environment is clean regarding colors
2268 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2269
2270 # "persistent history"
2271 # just write important commands you always need to ~/.important_commands
2272 if [[ -r ~/.important_commands ]] ; then
2273     fc -R ~/.important_commands
2274 fi
2275
2276 # load the lookup subsystem if it's available on the system
2277 zrcautoload lookupinit && lookupinit
2278
2279 ### non-root (EUID != 0) code below
2280 ###
2281
2282 if (( GRML_ALWAYS_LOAD_ALL == 0 )) && (( $EUID == 0 )) ; then
2283     zrclocal
2284     return 0
2285 fi
2286
2287 # variables
2288
2289 # set terminal property (used e.g. by msgid-chooser)
2290 export COLORTERM="yes"
2291
2292 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
2293 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
2294 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
2295
2296 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
2297 #v# [for non-root only]
2298 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
2299
2300 # aliases
2301
2302 # Xterm resizing-fu.
2303 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
2304 alias hide='echo -en "\033]50;nil2\007"'
2305 alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
2306 alias small='echo -en "\033]50;6x10\007"'
2307 alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
2308 alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
2309 alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
2310 alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
2311 alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
2312 alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
2313
2314 # general
2315 #a2# Execute \kbd{du -sch}
2316 alias da='du -sch'
2317 #a2# Execute \kbd{jobs -l}
2318 alias j='jobs -l'
2319
2320 # compile stuff
2321 #a2# Execute \kbd{./configure}
2322 alias CO="./configure"
2323 #a2# Execute \kbd{./configure --help}
2324 alias CH="./configure --help"
2325
2326 # listing stuff
2327 #a2# Execute \kbd{ls -lSrah}
2328 alias dir="ls -lSrah"
2329 #a2# Only show dot-directories
2330 alias lad='ls -d .*(/)'                # only show dot-directories
2331 #a2# Only show dot-files
2332 alias lsa='ls -a .*(.)'                # only show dot-files
2333 #a2# Only files with setgid/setuid/sticky flag
2334 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
2335 #a2# Only show 1st ten symlinks
2336 alias lsl='ls -l *(@)'                 # only symlinks
2337 #a2# Display only executables
2338 alias lsx='ls -l *(*)'                 # only executables
2339 #a2# Display world-{readable,writable,executable} files
2340 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
2341 #a2# Display the ten biggest files
2342 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
2343 #a2# Only show directories
2344 alias lsd='ls -d *(/)'                 # only show directories
2345 #a2# Only show empty directories
2346 alias lse='ls -d *(/^F)'               # only show empty directories
2347 #a2# Display the ten newest files
2348 alias lsnew="ls -rtlh *(D.om[1,10])"   # display the newest files
2349 #a2# Display the ten oldest files
2350 alias lsold="ls -rtlh *(D.Om[1,10])"   # display the oldest files
2351 #a2# Display the ten smallest files
2352 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
2353
2354 # chmod
2355 #a2# Execute \kbd{chmod 600}
2356 alias rw-='chmod 600'
2357 #a2# Execute \kbd{chmod 700}
2358 alias rwx='chmod 700'
2359 #m# a2 r-{}- Execute \kbd{chmod 644}
2360 alias r--='chmod 644'
2361 #a2# Execute \kbd{chmod 755}
2362 alias r-x='chmod 755'
2363
2364 # some useful aliases
2365 #a2# Execute \kbd{mkdir -p}
2366 alias md='mkdir -p'
2367 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir $OLDCWD}
2368 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2369
2370 # console stuff
2371 #a2# Execute \kbd{mplayer -vo fbdev}
2372 alias cmplayer='mplayer -vo fbdev'
2373 #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
2374 alias fbmplayer='mplayer -vo fbdev -fs -zoom'
2375 #a2# Execute \kbd{links2 -driver fb}
2376 alias fblinks='links2 -driver fb'
2377
2378 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2379 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2380 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2381
2382 # simple webserver
2383 check_com -c python && alias http="python -m SimpleHTTPServer"
2384
2385 # Use 'g' instead of 'git':
2386 check_com g || alias g='git'
2387
2388 # work around non utf8 capable software in utf environment via $LANG and luit
2389 if check_com isutfenv && check_com luit ; then
2390     if check_com -c mrxvt ; then
2391         isutfenv && [[ -n "$LANG" ]] && \
2392             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2393     fi
2394
2395     if check_com -c aterm ; then
2396         isutfenv && [[ -n "$LANG" ]] && \
2397             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2398     fi
2399
2400     if check_com -c centericq ; then
2401         isutfenv && [[ -n "$LANG" ]] && \
2402             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2403     fi
2404 fi
2405
2406 # useful functions
2407
2408 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2409 bk() {
2410     emulate -L zsh
2411     cp -b $1 $1_`date --iso-8601=m`
2412 }
2413
2414 #f5# cd to directoy and list files
2415 cl() {
2416     emulate -L zsh
2417     cd $1 && ls -a
2418 }
2419
2420 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2421 cd() {
2422     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2423         [[ ! -e ${1:h} ]] && return 1
2424         print "Correcting ${1} to ${1:h}"
2425         builtin cd ${1:h}
2426     else
2427         builtin cd "$@"
2428     fi
2429 }
2430
2431 #f5# Create Directoy and \kbd{cd} to it
2432 mcd() {
2433     mkdir -p "$@" && cd "$@"
2434 }
2435 #f5# Create temporary directory and \kbd{cd} to it
2436 cdt() {
2437     local t
2438     t=$(mktemp -d)
2439     echo "$t"
2440     builtin cd "$t"
2441 }
2442
2443 #f5# Create directory under cursor or the selected area
2444 # Press ctrl-xM to create the directory under the cursor or the selected area.
2445 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2446 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2447 # directory does not exist yet -> press ctrl-XM and problem solved
2448 inplaceMkDirs() {
2449     local PATHTOMKDIR
2450     if ((REGION_ACTIVE==1)); then
2451         local F=$MARK T=$CURSOR
2452         if [[ $F -gt $T ]]; then
2453             F=${CURSOR}
2454             T=${MARK}
2455         fi
2456         # get marked area from buffer and eliminate whitespace
2457         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2458         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2459     else
2460         local bufwords iword
2461         bufwords=(${(z)LBUFFER})
2462         iword=${#bufwords}
2463         bufwords=(${(z)BUFFER})
2464         PATHTOMKDIR="${(Q)bufwords[iword]}"
2465     fi
2466     [[ -z "${PATHTOMKDIR}" ]] && return 1
2467     if [[ -e "${PATHTOMKDIR}" ]]; then
2468         zle -M " path already exists, doing nothing"
2469     else
2470         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2471         zle end-of-line
2472     fi
2473 }
2474 #k# mkdir -p <dir> from string under cursor or marked area
2475 zle -N inplaceMkDirs && bindkey '^XM' inplaceMkDirs
2476
2477 # Function Usage: doc packagename
2478 #f5# \kbd{cd} to /usr/share/doc/\textit{package}
2479 doc() {
2480     emulate -L zsh
2481     cd /usr/share/doc/$1 && ls
2482 }
2483 _doc() { _files -W /usr/share/doc -/ }
2484 check_com compdef && compdef _doc doc
2485
2486 #f5# Make screenshot
2487 sshot() {
2488     [[ ! -d ~/shots  ]] && mkdir ~/shots
2489     #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
2490     cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
2491 }
2492
2493 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2494 accessed() {
2495     emulate -L zsh
2496     print -l -- *(a-${1:-1})
2497 }
2498
2499 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2500 changed() {
2501     emulate -L zsh
2502     print -l -- *(c-${1:-1})
2503 }
2504
2505 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2506 modified() {
2507     emulate -L zsh
2508     print -l -- *(m-${1:-1})
2509 }
2510 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2511 check_com new || alias new=modified
2512
2513 # use colors when GNU grep with color-support
2514 #a2# Execute \kbd{grep -{}-color=auto}
2515 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
2516 #a2# Execute \kbd{grep -i -{}-color=auto}
2517 alias GREP='grep -i --color=auto'
2518
2519 # Translate DE<=>EN
2520 # 'translate' looks up fot a word in a file with language-to-language
2521 # translations (field separator should be " : "). A typical wordlist looks
2522 # like at follows:
2523 #  | english-word : german-transmission
2524 # It's also only possible to translate english to german but not reciprocal.
2525 # Use the following oneliner to turn back the sort order:
2526 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2527 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2528 #f5# Translates a word
2529 trans() {
2530     emulate -L zsh
2531     case "$1" in
2532         -[dD]*)
2533             translate -l de-en $2
2534             ;;
2535         -[eE]*)
2536             translate -l en-de $2
2537             ;;
2538         *)
2539             echo "Usage: $0 { -D | -E }"
2540             echo "         -D == German to English"
2541             echo "         -E == English to German"
2542     esac
2543 }
2544
2545 # Usage: simple-extract <file>
2546 # Using option -d deletes the original archive file.
2547 #f5# Smart archive extractor
2548 simple-extract() {
2549     emulate -L zsh
2550     setopt extended_glob noclobber
2551     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2552     local RC=0
2553     zparseopts -D -E "d=DELETE_ORIGINAL"
2554     for ARCHIVE in "${@}"; do
2555         case $ARCHIVE in
2556             *.(tar.bz2|tbz2|tbz))
2557                 DECOMP_CMD="tar -xvjf -"
2558                 USES_STDIN=true
2559                 USES_STDOUT=false
2560                 ;;
2561             *.(tar.gz|tgz))
2562                 DECOMP_CMD="tar -xvzf -"
2563                 USES_STDIN=true
2564                 USES_STDOUT=false
2565                 ;;
2566             *.(tar.xz|txz|tar.lzma))
2567                 DECOMP_CMD="tar -xvJf -"
2568                 USES_STDIN=true
2569                 USES_STDOUT=false
2570                 ;;
2571             *.tar)
2572                 DECOMP_CMD="tar -xvf -"
2573                 USES_STDIN=true
2574                 USES_STDOUT=false
2575                 ;;
2576             *.rar)
2577                 DECOMP_CMD="unrar x"
2578                 USES_STDIN=false
2579                 USES_STDOUT=false
2580                 ;;
2581             *.lzh)
2582                 DECOMP_CMD="lha x"
2583                 USES_STDIN=false
2584                 USES_STDOUT=false
2585                 ;;
2586             *.7z)
2587                 DECOMP_CMD="7z x"
2588                 USES_STDIN=false
2589                 USES_STDOUT=false
2590                 ;;
2591             *.(zip|jar))
2592                 DECOMP_CMD="unzip"
2593                 USES_STDIN=false
2594                 USES_STDOUT=false
2595                 ;;
2596             *.deb)
2597                 DECOMP_CMD="ar -x"
2598                 USES_STDIN=false
2599                 USES_STDOUT=false
2600                 ;;
2601             *.bz2)
2602                 DECOMP_CMD="bzip2 -d -c -"
2603                 USES_STDIN=true
2604                 USES_STDOUT=true
2605                 ;;
2606             *.(gz|Z))
2607                 DECOMP_CMD="gzip -d -c -"
2608                 USES_STDIN=true
2609                 USES_STDOUT=true
2610                 ;;
2611             *.(xz|lzma))
2612                 DECOMP_CMD="xz -d -c -"
2613                 USES_STDIN=true
2614                 USES_STDOUT=true
2615                 ;;
2616             *)
2617                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2618                 RC=$((RC+1))
2619                 continue
2620                 ;;
2621         esac
2622
2623         if ! check_com ${DECOMP_CMD[(w)1]}; then
2624             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2625             RC=$((RC+2))
2626             continue
2627         fi
2628
2629         GZTARGET="${ARCHIVE:t:r}"
2630         if [[ -f $ARCHIVE ]] ; then
2631
2632             print "Extracting '$ARCHIVE' ..."
2633             if $USES_STDIN; then
2634                 if $USES_STDOUT; then
2635                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
2636                 else
2637                     ${=DECOMP_CMD} < "$ARCHIVE"
2638                 fi
2639             else
2640                 if $USES_STDOUT; then
2641                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
2642                 else
2643                     ${=DECOMP_CMD} "$ARCHIVE"
2644                 fi
2645             fi
2646             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
2647
2648         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
2649             if check_com curl; then
2650                 WGET_CMD="curl -L -k -s -o -"
2651             elif check_com wget; then
2652                 WGET_CMD="wget -q -O - --no-check-certificate"
2653             else
2654                 print "ERROR: neither wget nor curl is installed" >&2
2655                 RC=$((RC+4))
2656                 continue
2657             fi
2658             print "Downloading and Extracting '$ARCHIVE' ..."
2659             if $USES_STDIN; then
2660                 if $USES_STDOUT; then
2661                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
2662                     RC=$((RC+$?))
2663                 else
2664                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
2665                     RC=$((RC+$?))
2666                 fi
2667             else
2668                 if $USES_STDOUT; then
2669                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
2670                 else
2671                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
2672                 fi
2673             fi
2674
2675         else
2676             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
2677             RC=$((RC+8))
2678         fi
2679     done
2680     return $RC
2681 }
2682
2683 __archive_or_uri()
2684 {
2685     _alternative \
2686         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
2687         '_urls:Remote Archives:_urls'
2688 }
2689
2690 _simple_extract()
2691 {
2692     _arguments \
2693         '-d[delete original archivefile after extraction]' \
2694         '*:Archive Or Uri:__archive_or_uri'
2695 }
2696 compdef _simple_extract simple-extract
2697 alias se=simple-extract
2698
2699 # Usage: smartcompress <file> (<type>)
2700 #f5# Smart archive creator
2701 smartcompress() {
2702     emulate -L zsh
2703     if [[ -n $2 ]] ; then
2704         case $2 in
2705             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
2706             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
2707             tar.Z)          tar -Zcvf$1.$2 $1 ;;
2708             tar)            tar -cvf$1.$2  $1 ;;
2709             gz | gzip)      gzip           $1 ;;
2710             bz2 | bzip2)    bzip2          $1 ;;
2711             *)
2712                 echo "Error: $2 is not a valid compression type"
2713                 ;;
2714         esac
2715     else
2716         smartcompress $1 tar.gz
2717     fi
2718 }
2719
2720 # Usage: show-archive <archive>
2721 #f5# List an archive's content
2722 show-archive() {
2723     emulate -L zsh
2724     if [[ -f $1 ]] ; then
2725         case $1 in
2726             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
2727             *.tar)         tar -tf $1 ;;
2728             *.tgz)         tar -ztf $1 ;;
2729             *.zip)         unzip -l $1 ;;
2730             *.bz2)         bzless $1 ;;
2731             *.deb)         dpkg-deb --fsys-tarfile $1 | tar -tf - -- ;;
2732             *)             echo "'$1' Error. Please go away" ;;
2733         esac
2734     else
2735         echo "'$1' is not a valid archive"
2736     fi
2737 }
2738
2739 # TODO: So, this is the third incarnation of this function!?
2740 #f5# Reload given functions
2741 refunc() {
2742     for func in $argv ; do
2743         unfunction $func
2744         autoload $func
2745     done
2746 }
2747 compdef _functions refunc
2748
2749 #f5# Set all ulimit parameters to \kbd{unlimited}
2750 allulimit() {
2751     ulimit -c unlimited
2752     ulimit -d unlimited
2753     ulimit -f unlimited
2754     ulimit -l unlimited
2755     ulimit -n unlimited
2756     ulimit -s unlimited
2757     ulimit -t unlimited
2758 }
2759
2760 # highlight important stuff in diff output, usage example: hg diff | hidiff
2761 #m# a2 hidiff \kbd{histring} oneliner for diffs
2762 check_com -c histring && \
2763     alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
2764
2765 #f5# Change the xterm title from within GNU-screen
2766 xtrename() {
2767     emulate -L zsh
2768     if [[ $1 != "-f" ]] ; then
2769         if [[ -z ${DISPLAY} ]] ; then
2770             printf 'xtrename only makes sense in X11.\n'
2771             return 1
2772         fi
2773     else
2774         shift
2775     fi
2776     if [[ -z $1 ]] ; then
2777         printf 'usage: xtrename [-f] "title for xterm"\n'
2778         printf '  renames the title of xterm from _within_ screen.\n'
2779         printf '  also works without screen.\n'
2780         printf '  will not work if DISPLAY is unset, use -f to override.\n'
2781         return 0
2782     fi
2783     print -n "\eP\e]0;${1}\C-G\e\\"
2784     return 0
2785 }
2786
2787 # TODO:
2788 # Rewrite this by either using tinyurl.com's API
2789 # or using another shortening service to comply with
2790 # tinyurl.com's policy.
2791 #
2792 # Create small urls via http://tinyurl.com using wget(1).
2793 #function zurl() {
2794 #    emulate -L zsh
2795 #    [[ -z $1 ]] && { print "USAGE: zurl <URL>" ; return 1 }
2796 #
2797 #    local PN url tiny grabber search result preview
2798 #    PN=$0
2799 #    url=$1
2800 ##   Check existence of given URL with the help of ping(1).
2801 ##   N.B. ping(1) only works without an eventual given protocol.
2802 #    ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
2803 #        read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
2804 #
2805 #    if (( $? == 0 )) ; then
2806 ##           Prepend 'http://' to given URL where necessary for later output.
2807 #            [[ ${url} != http(s|)://* ]] && url='http://'${url}
2808 #            tiny='http://tinyurl.com/create.php?url='
2809 #            if check_com -c wget ; then
2810 #                grabber='wget -O- -o/dev/null'
2811 #            else
2812 #                print "wget is not available, but mandatory for ${PN}. Aborting."
2813 #            fi
2814 ##           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
2815 #            search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
2816 #            result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
2817 ##           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
2818 #            preview='http://preview.'${result#http://}
2819 #
2820 #            printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
2821 #            printf '%s\t%s\n\n' 'Given URL:' ${url}
2822 #            printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
2823 #    else
2824 #        return 1
2825 #    fi
2826 #}
2827
2828 #f2# Find history events by search pattern and list them by date.
2829 whatwhen()  {
2830     emulate -L zsh
2831     local usage help ident format_l format_s first_char remain first last
2832     usage='USAGE: whatwhen [options] <searchstring> <search range>'
2833     help='Use `whatwhen -h'\'' for further explanations.'
2834     ident=${(l,${#${:-Usage: }},, ,)}
2835     format_l="${ident}%s\t\t\t%s\n"
2836     format_s="${format_l//(\\t)##/\\t}"
2837     # Make the first char of the word to search for case
2838     # insensitive; e.g. [aA]
2839     first_char=[${(L)1[1]}${(U)1[1]}]
2840     remain=${1[2,-1]}
2841     # Default search range is `-100'.
2842     first=${2:-\-100}
2843     # Optional, just used for `<first> <last>' given.
2844     last=$3
2845     case $1 in
2846         ("")
2847             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
2848             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2849         ;;
2850         (-h)
2851             printf '%s\n\n' ${usage}
2852             print 'OPTIONS:'
2853             printf $format_l '-h' 'show help text'
2854             print '\f'
2855             print 'SEARCH RANGE:'
2856             printf $format_l "'0'" 'the whole history,'
2857             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
2858             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
2859             printf '\n%s\n' 'EXAMPLES:'
2860             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
2861             printf $format_l 'whatwhen zsh -250'
2862             printf $format_l 'whatwhen foo 1 99'
2863         ;;
2864         (\?)
2865             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2866         ;;
2867         (*)
2868             # -l list results on stout rather than invoking $EDITOR.
2869             # -i Print dates as in YYYY-MM-DD.
2870             # -m Search for a - quoted - pattern within the history.
2871             fc -li -m "*${first_char}${remain}*" $first $last
2872         ;;
2873     esac
2874 }
2875
2876 # mercurial related stuff
2877 if check_com -c hg ; then
2878     # gnu like diff for mercurial
2879     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
2880     #f5# GNU like diff for mercurial
2881     hgdi() {
2882         emulate -L zsh
2883         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
2884     }
2885
2886     # build debian package
2887     #a2# Alias for \kbd{hg-buildpackage}
2888     alias hbp='hg-buildpackage'
2889
2890     # execute commands on the versioned patch-queue from the current repos
2891     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
2892
2893     # diffstat for specific version of a mercurial repository
2894     #   hgstat      => display diffstat between last revision and tip
2895     #   hgstat 1234 => display diffstat between revision 1234 and tip
2896     #f5# Diffstat for specific version of a mercurial repos
2897     hgstat() {
2898         emulate -L zsh
2899         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
2900     }
2901
2902 fi # end of check whether we have the 'hg'-executable
2903
2904 # grml-small cleanups
2905
2906 # The following is used to remove zsh-config-items that do not work
2907 # in grml-small by default.
2908 # If you do not want these adjustments (for whatever reason), set
2909 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
2910 # sources if it is there).
2911
2912 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
2913
2914     unset abk[V]
2915     unalias    'V'      &> /dev/null
2916     unfunction vman     &> /dev/null
2917     unfunction viless   &> /dev/null
2918     unfunction 2html    &> /dev/null
2919
2920     # manpages are not in grmlsmall
2921     unfunction manzsh   &> /dev/null
2922     unfunction man2     &> /dev/null
2923
2924 fi
2925
2926 zrclocal
2927
2928 ## genrefcard.pl settings
2929
2930 ### doc strings for external functions from files
2931 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
2932
2933 ### example: split functions-search 8,16,24,32
2934 #@# split functions-search 8
2935
2936 ## END OF FILE #################################################################
2937 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
2938 # Local variables:
2939 # mode: sh
2940 # End: