etc/zsh/zshrc

   1 # Filename:      zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 # Latest change: Mon Feb 11 18:00:55 CET 2008 [mika]
   7 ################################################################################
   8 # This file is sourced only for interactive shells. It
   9 # should contain commands to set up aliases, functions,
  10 # options, key bindings, etc.
  11 #
  12 # Global Order: zshenv, zprofile, zshrc, zlogin
  13 ################################################################################
  14
  15 # zsh-refcard-tag documentation: {{{
  16 #   You may notice strange looking comments in the zshrc (and ~/.zshrc as
  17 #   well). These are there for a purpose. grml's zsh-refcard can now be
  18 #   automatically generated from the contents of the actual configuration
  19 #   files. However, we need a little extra information on which comments
  20 #   and what lines of code to take into account (and for what purpose).
  21 #
  22 # Here is what they mean:
  23 #
  24 # List of tags (comment types) used:
  25 #   #a#     Next line contains an important alias, that should
  26 #           be included in the grml-zsh-refcard.
  27 #           (placement tag: @@INSERT-aliases@@)
  28 #   #f#     Next line contains the beginning of an important function.
  29 #           (placement tag: @@INSERT-functions@@)
  30 #   #v#     Next line contains an important variable.
  31 #           (placement tag: @@INSERT-variables@@)
  32 #   #k#     Next line contains an important keybinding.
  33 #           (placement tag: @@INSERT-keybindings@@)
  34 #   #d#     Hashed directories list generation:
  35 #               start   denotes the start of a list of 'hash -d'
  36 #                       definitions.
  37 #               end     denotes its end.
  38 #           (placement tag: @@INSERT-hasheddirs@@)
  39 #   #A#     Abbreviation expansion list generation:
  40 #               start   denotes the beginning of abbreviations.
  41 #               end     denotes their end.
  42 #           Lines within this section that end in '#d .*' provide
  43 #           extra documentation to be included in the refcard.
  44 #           (placement tag: @@INSERT-abbrev@@)
  45 #   #m#     This tag allows you to manually generate refcard entries
  46 #           for code lines that are hard/impossible to parse.
  47 #               Example:
  48 #                   #m# k ESC-h Call the run-help function
  49 #               That would add a refcard entry in the keybindings table
  50 #               for 'ESC-h' with the given comment.
  51 #           So the syntax is: #m# <section> <argument> <comment>
  52 #   #o#     This tag lets you insert entries to the 'other' hash.
  53 #           Generally, this should not be used. It is there for
  54 #           things that cannot be done easily in another way.
  55 #           (placement tag: @@INSERT-other-foobar@@)
  56 #
  57 #   All of these tags (except for m and o) take two arguments, the first
  58 #   within the tag, the other after the tag:
  59 #
  60 #   #<tag><section># <comment>
  61 #
  62 #   Where <section> is really just a number, which are defined by the
  63 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  64 #   instead of names is, that for the reader, the tag should not differ
  65 #   much from a regular comment. For zsh, it is a regular comment indeed.
  66 #   The numbers have got the following meanings:
  67 #         0 -> "default"
  68 #         1 -> "system"
  69 #         2 -> "user"
  70 #         3 -> "debian"
  71 #         4 -> "search"
  72 #         5 -> "shortcuts"
  73 #         6 -> "services"
  74 #
  75 #   So, the following will add an entry to the 'functions' table in the
  76 #   'system' section, with a (hopefully) descriptive comment:
  77 #       #f1# Edit an alias via zle
  78 #       edalias() {
  79 #
  80 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  81 #   that can be found in 'grml-zsh-refcard.tex.in'.
  82 #   If the section number is omitted, the 'default' section is assumed.
  83 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
  84 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
  85 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
  86 #}}}
  87
  88 # zsh profiling {{{
  89 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
  90 if [[ -n $ZSH_PROFILE_RC ]] ; then
  91     zmodload zsh/zprof
  92 fi
  93 # }}}
  94
  95 # utility functions {{{
  96 # this function checks if a command exists and returns either true
  97 # or false. This avoids using 'which' and 'whence', which will
  98 # avoid problems with aliases for which on certain weird systems. :-)
  99 check_com() {
 100     local -i comonly
 101
 102     if [[ ${1} == '-c' ]] ; then
 103         (( comonly = 1 ))
 104         shift
 105     else
 106         (( comonly = 0 ))
 107     fi
 108
 109     if (( ${#argv} != 1 )) ; then
 110         printf 'usage: check_com [-c] <command>\n' >&2
 111         return 1
 112     fi
 113
 114     if (( comonly > 0 )) ; then
 115         [[ -n ${commands[$1]}  ]] && return 0
 116         return 1
 117     fi
 118
 119     if   [[ -n ${commands[$1]}    ]] \
 120       || [[ -n ${functions[$1]}   ]] \
 121       || [[ -n ${aliases[$1]}     ]] \
 122       || [[ -n ${reswords[(r)$1]} ]] ; then
 123
 124         return 0
 125     fi
 126
 127     return 1
 128 }
 129
 130 # creates an alias and precedes the command with
 131 # sudo if $EUID is not zero.
 132 salias() {
 133     local only=0 ; local multi=0
 134     while [[ ${1} == -* ]] ; do
 135         case ${1} in
 136             (-o) only=1 ;;
 137             (-a) multi=1 ;;
 138             (--) shift ; break ;;
 139             (-h)
 140                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 141                 printf '  -h      shows this help text.\n'
 142                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 143                 printf '          be careful using this option.\n'
 144                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 145                 return 0
 146                 ;;
 147             (*) printf "unkown option: '%s'\n" "${1}" ; return 1 ;;
 148         esac
 149         shift
 150     done
 151
 152     if (( ${#argv} > 1 )) ; then
 153         printf 'Too many arguments %s\n' "${#argv}"
 154         return 1
 155     fi
 156
 157     key="${1%%\=*}" ;  val="${1#*\=}"
 158     if (( EUID == 0 )) && (( only == 0 )); then
 159         alias -- "${key}=${val}"
 160     elif (( EUID > 0 )) ; then
 161         (( multi > 0 )) && val="${val// ; / ; sudo }"
 162         alias -- "${key}=sudo ${val}"
 163     fi
 164
 165     return 0
 166 }
 167
 168 # Check if we can read given files and source those we can.
 169 xsource() {
 170     if (( ${#argv} < 1 )) ; then
 171         printf 'usage: xsource FILE(s)...\n' >&2
 172         return 1
 173     fi
 174
 175     while (( ${#argv} > 0 )) ; do
 176         [[ -r ${1} ]] && source ${1}
 177         shift
 178     done
 179     return 0
 180 }
 181
 182 # Check if we can read a given file and 'cat(1)' it.
 183 xcat() {
 184     if (( ${#argv} != 1 )) ; then
 185         printf 'usage: xcat FILE\n' >&2
 186         return 1
 187     fi
 188
 189     [[ -r ${1} ]] && cat ${1}
 190     return 0
 191 }
 192
 193 # Remove these functions again, they are of use only in these
 194 # setup files. This should be called at the end of .zshrc.
 195 xunfunction() {
 196     local -a funcs
 197     funcs=(check_com salias xcat xsource xunfunction zrcautoload)
 198
 199     for func in $funcs ; do
 200         [[ -n ${functions[$func]} ]] \
 201             && unfunction $func
 202     done
 203     return 0
 204 }
 205
 206 # autoload wrapper - use this one instead of autoload directly
 207 function zrcautoload() {
 208     setopt local_options extended_glob
 209     local fdir ffile
 210     local -i ffound
 211
 212     ffile=${1}
 213     (( found = 0 ))
 214     for fdir in ${fpath} ; do
 215         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 216     done
 217
 218     (( ffound == 0 )) && return 1
 219     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 220         autoload -U ${ffile} || return 1
 221     else
 222         autoload ${ffile} || return 1
 223     fi
 224     return 0
 225 }
 226
 227 #}}}
 228
 229 # locale setup {{{
 230 if [[ -z "$LANG" ]] ; then
 231     xsource "/etc/default/locale"
 232 fi
 233
 234 export LANG=${LANG:-en_US.iso885915}
 235 for var in LC_ALL LC_MESSAGES ; do
 236     [[ -n ${(P)var} ]] && export $var
 237 done
 238
 239 xsource "/etc/sysconfig/keyboard"
 240
 241 TZ=$(xcat /etc/timezone)
 242 # }}}
 243
 244 # check for potentially old files in 'completion.d' {{{
 245 setopt extendedglob
 246 xof=(/etc/zsh/completion.d/*~/etc/zsh/completion.d/_*(N))
 247 if (( ${#xof} > 0 )) ; then
 248     printf '\n -!- INFORMATION\n\n'
 249     printf ' -!- %s file(s) not starting with an underscore (_) found in\n' ${#xof}
 250     printf ' -!- /etc/zsh/completion.d/.\n\n'
 251     printf ' -!- While this has been the case in old versions of grml-etc-core,\n'
 252     printf ' -!- recent versions of the grml-zsh-setup have all these files rewritten\n'
 253     printf ' -!- and renamed. Furthermore, the grml-zsh-setup will *only* add files\n'
 254     printf ' -!- named _* to that directory.\n\n'
 255     printf ' -!- If you added functions to completion.d yourself, please consider\n'
 256     printf ' -!- moving them to /etc/zsh/functions.d/. Files in that directory, not\n'
 257     printf ' -!- starting with an underscore are marked for automatic loading\n'
 258     printf ' -!- by default (so that is quite convenient).\n\n'
 259     printf ' -!- If there are files *not* starting with an underscore from an older\n'
 260     printf ' -!- grml-etc-core in completion.d, you may safely remove them.\n\n'
 261     printf ' -!- Delete the files for example via running:\n\n'
 262     printf "      rm ${xof}\n\n"
 263     printf ' -!- Note, that this message will *not* go away, unless you yourself\n'
 264     printf ' -!- resolve the situation manually.\n\n'
 265     BROKEN_COMPLETION_DIR=1
 266 fi
 267 unset xof
 268 # }}}
 269
 270 # {{{ check for version/system
 271 # check for versions (compatibility reasons)
 272 is4(){
 273     [[ $ZSH_VERSION == <4->* ]] && return 0
 274     return 1
 275 }
 276
 277 is41(){
 278     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 279     return 1
 280 }
 281
 282 is42(){
 283     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 284     return 1
 285 }
 286
 287 is43(){
 288     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 289     return 1
 290 }
 291
 292 #f1# Checks whether or not you're running grml
 293 isgrml(){
 294     [[ -f /etc/grml_version ]] && return 0
 295     return 1
 296 }
 297
 298 #f1# Checks whether or not you're running a grml cd
 299 isgrmlcd(){
 300     [[ -f /etc/grml_cd ]] && return 0
 301     return 1
 302 }
 303
 304 if isgrml ; then
 305 #f1# Checks whether or not you're running grml-small
 306     isgrmlsmall() {
 307         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 308     }
 309 else
 310     isgrmlsmall() { return 1 }
 311 fi
 312
 313 #f1# are we running within an utf environment?
 314 isutfenv() {
 315     case "$LANG $CHARSET $LANGUAGE" in
 316         *utf*) return 0 ;;
 317         *UTF*) return 0 ;;
 318         *)     return 1 ;;
 319     esac
 320 }
 321
 322 # check for user, if not running as root set $SUDO to sudo
 323 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 324
 325 # change directory to home on first invocation of zsh
 326 # important for rungetty -> autologin
 327 # Thanks go to Bart Schaefer!
 328 isgrml && checkhome() {
 329     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 330         export ALREADY_DID_CD_HOME=$HOME
 331         cd
 332     fi
 333 }
 334
 335 # check for zsh v3.1.7+
 336
 337 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 338      || ${ZSH_VERSION} == 3.<2->.<->*    \
 339      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 340
 341     printf '-!-\n'
 342     printf '-!- In this configuration we try to make use of features, that only\n'
 343     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 344     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 345     printf '-!- advanced features in all supported versions.\n'
 346     printf '-!-\n'
 347     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 348     printf '-!-\n'
 349     printf '-!- While this *may* work, it might as well fail.\n'
 350     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 351     printf '-!-\n'
 352     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 353     printf '-!- If it does today, you'\''ve been lucky.\n'
 354     printf '-!-\n'
 355     printf '-!- Ye been warned!\n'
 356     printf '-!-\n'
 357
 358     function zstyle() { : }
 359 fi
 360
 361 # }}}
 362
 363 # {{{ set some variables
 364 if check_com -c vim ; then
 365 #v#
 366     export EDITOR=${EDITOR:-vim}
 367 else
 368     export EDITOR=${EDITOR:-vi}
 369 fi
 370
 371 #v#
 372 (( ${+PAGER} )) || export PAGER="less"
 373
 374 #v#
 375 export MAIL=${MAIL:-/var/mail/$USER}
 376
 377 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 378 export SHELL='/bin/zsh'
 379
 380 # color setup for ls:
 381 check_com -c dircolors && eval $(dircolors -b)
 382
 383 # set width of man pages to 80 for more convenient reading
 384 # (( ${+MANWIDTH} )) || export MANWIDTH=80
 385
 386 # Search path for the cd command
 387 #  cdpath=(.. ~)
 388
 389 # completion functions go to /etc/zsh/completion.d
 390 # function files may be put into /etc/zsh/functions.d, from where they
 391 # will be automatically autoloaded.
 392 if [[ -n "$BROKEN_COMPLETION_DIR" ]] ; then
 393     print 'Warning: not setting completion directories because broken files have been found.' >&2
 394 else
 395     [[ -d /etc/zsh/completion.d ]] && fpath=( $fpath /etc/zsh/completion.d )
 396     if [[ -d /etc/zsh/functions.d ]] ; then
 397         fpath+=( /etc/zsh/functions.d )
 398         for func in /etc/zsh/functions.d/[^_]*[^~] ; do
 399             zrcautoload -U ${func:t}
 400         done
 401     fi
 402 fi
 403
 404 # automatically remove duplicates from these arrays
 405 typeset -U path cdpath fpath manpath
 406 # }}}
 407
 408 # {{{ keybindings
 409 if [[ "$TERM" != emacs ]] ; then
 410     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 411     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 412     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 413     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 414     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 415     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 416     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 417     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 418     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 419     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 420     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 421     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 422     # ncurses stuff:
 423     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 424     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 425     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 426     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 427     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 428     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 429     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 430     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 431 fi
 432
 433 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 434 # use emacs style per default:
 435 bindkey -e
 436 # use vi style:
 437 # bindkey -v
 438
 439 #if [[ "$TERM" == screen ]] ; then
 440 bindkey '\e[1~' beginning-of-line       # home
 441 bindkey '\e[4~' end-of-line             # end
 442 bindkey '\e[A'  up-line-or-search       # cursor up
 443 bindkey '\e[B'  down-line-or-search     # <ESC>-
 444 bindkey '^x'    history-beginning-search-backward # alternative ways of searching the shell history
 445 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 446 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 447 # if terminal type is set to 'rxvt':
 448 bindkey '\e[7~' beginning-of-line       # home
 449 bindkey '\e[8~' end-of-line             # end
 450 #fi
 451
 452 # insert unicode character
 453 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 454 # See for example http://unicode.org/charts/ for unicode characters code
 455 zrcautoload insert-unicode-char
 456 zle -N insert-unicode-char
 457 #k# Insert Unicode character
 458 bindkey '^Xi' insert-unicode-char
 459
 460 # just type 'cd ...' to get 'cd ../..'
 461 #  rationalise-dot() {
 462 #  if [[ $LBUFFER == *.. ]] ; then
 463 #    LBUFFER+=/..
 464 #  else
 465 #    LBUFFER+=.
 466 #  fi
 467 #  }
 468 #  zle -N rationalise-dot
 469 #  bindkey . rationalise-dot
 470
 471 #  bindkey '\eq' push-line-or-edit
 472 # }}}
 473
 474 # a generic accept-line wrapper {{{
 475
 476 # This widget can prevent unwanted autocorrections from command-name
 477 # to _command-name, rehash automatically on enter and call any number
 478 # of builtin and user-defined widgets in different contexts.
 479 #
 480 # For a broader description, see:
 481 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 482 #
 483 # The code is imported from the file 'zsh/functions/accept-line' from
 484 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 485 # distributed under the same terms as zsh itself.
 486
 487 # A newly added command will may not be found or will cause false
 488 # correction attempts, if you got auto-correction set. By setting the
 489 # following style, we force accept-line() to rehash, if it cannot
 490 # find the first word on the command line in the $command[] hash.
 491 zstyle ':acceptline:*' rehash true
 492
 493 function Accept-Line() {
 494     setopt localoptions noksharrays
 495     local -a subs
 496     local -xi aldone
 497     local sub
 498
 499     zstyle -a ":acceptline:${alcontext}" actions subs
 500
 501     (( ${#subs} < 1 )) && return 0
 502
 503     (( aldone = 0 ))
 504     for sub in ${subs} ; do
 505         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 506         zle ${sub}
 507
 508         (( aldone > 0 )) && break
 509     done
 510 }
 511
 512 function Accept-Line-getdefault() {
 513     local default_action
 514
 515     zstyle -s ":acceptline:${alcontext}" default_action default_action
 516     case ${default_action} in
 517         ((accept-line|))
 518             printf ".accept-line"
 519             ;;
 520         (*)
 521             printf ${default_action}
 522             ;;
 523     esac
 524 }
 525
 526 function accept-line() {
 527     setopt localoptions noksharrays
 528     local -a cmdline
 529     local -x alcontext
 530     local buf com fname format msg default_action
 531
 532     alcontext='default'
 533     buf="${BUFFER}"
 534     cmdline=(${(z)BUFFER})
 535     com="${cmdline[1]}"
 536     fname="_${com}"
 537
 538     zstyle -t ":acceptline:${alcontext}" rehash \
 539         && [[ -z ${commands[$com]} ]]           \
 540         && rehash
 541
 542     if    [[ -n ${reswords[(r)$com]} ]] \
 543        || [[ -n ${aliases[$com]}     ]] \
 544        || [[ -n ${functions[$com]}   ]] \
 545        || [[ -n ${builtins[$com]}    ]] \
 546        || [[ -n ${commands[$com]}    ]] ; then
 547
 548         # there is something sensible to execute, just do it.
 549         alcontext='normal'
 550         zle Accept-Line
 551
 552         default_action=$(Accept-Line-getdefault)
 553         zstyle -T ":acceptline:${alcontext}" call_default \
 554             && zle ${default_action}
 555         return
 556     fi
 557
 558     if    [[ -o correct              ]] \
 559        || [[ -o correctall           ]] \
 560        && [[ -n ${functions[$fname]} ]] ; then
 561
 562         # nothing there to execute but there is a function called
 563         # _command_name; a completion widget. Makes no sense to
 564         # call it on the commandline, but the correct{,all} options
 565         # will ask for it nevertheless, so warn the user.
 566         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 567             # Okay, we warned the user before, he called us again,
 568             # so have it his way.
 569             alcontext='force'
 570             zle Accept-Line
 571
 572             default_action=$(Accept-Line-getdefault)
 573             zstyle -T ":acceptline:${alcontext}" call_default \
 574                 && zle ${default_action}
 575             return
 576         fi
 577
 578         # prepare warning message for the user, configurable via zstyle.
 579         zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 580
 581         if [[ -z ${msg} ]] ; then
 582             msg="%c will not execute and completion %f exists."
 583         fi
 584
 585         zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 586
 587         zle -M -- "${msg}"
 588         return
 589     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 590         # If we are here, the commandline contains something that is not
 591         # executable, which is neither subject to _command_name correction
 592         # and is not empty. might be a variable assignment
 593         alcontext='misc'
 594         zle Accept-Line
 595
 596         default_action=$(Accept-Line-getdefault)
 597         zstyle -T ":acceptline:${alcontext}" call_default \
 598             && zle ${default_action}
 599         return
 600     fi
 601
 602     # If we got this far, the commandline only contains whitespace, or is empty.
 603     alcontext='empty'
 604     zle Accept-Line
 605
 606     default_action=$(Accept-Line-getdefault)
 607     zstyle -T ":acceptline:${alcontext}" call_default \
 608         && zle ${default_action}
 609 }
 610
 611 zle -N accept-line
 612 zle -N Accept-Line
 613
 614 # }}}
 615
 616 # power completion - abbreviation expansion {{{
 617 # power completion / abbreviation expansion / buffer expansion
 618 # see http://zshwiki.org/home/examples/zleiab for details
 619 # less risky than the global aliases but powerful as well
 620 # just type the abbreviation key and afterwards ',.' to expand it
 621 declare -A abk
 622 setopt extendedglob
 623 setopt interactivecomments
 624 abk=(
 625 # key  # value                (#d additional doc string)
 626 #A# start
 627     '...' '../..'
 628     '....' '../../..'
 629     'BG' '& exit'
 630     'C' '| wc -l'
 631     'G' '|& grep --color=auto'
 632     'H' '| head'
 633     'Hl' ' --help |& less -r'      #d (Display help in pager)
 634     'L' '| less'
 635     'LL' '|& less -r'
 636     'M' '| most'
 637     'N' '&>/dev/null'              #d (No Output)
 638     'R' '| tr A-z N-za-m'          #d (ROT13)
 639     'SL' '| sort | less'
 640     'S' '| sort -u'
 641     'T' '| tail'
 642     'V' '|& vim -'
 643 #A# end
 644     'hide' "echo -en '\033]50;nil2\007'"
 645     'tiny' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
 646     'small' 'echo -en "\033]50;6x10\007"'
 647     'medium' 'echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
 648     'default' 'echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
 649     'large' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
 650     'huge' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
 651     'smartfont' 'echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
 652     'semifont' 'echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
 653     'da' 'du -sch'
 654     'j' 'jobs -l'
 655     'u' 'translate -i'
 656     'co' "./configure && make && sudo make install"
 657     'CH' "./configure --help"
 658     'conkeror' 'firefox -chrome chrome://conkeror/content'
 659     'dir' 'ls -lSrah'
 660     'lad' $'ls -d .*(/)\n# only show dot-directories'
 661     'lsa' $'ls -a .*(.)\n# only show dot-files'
 662     'lss' $'ls -l *(s,S,t)\n# only files with setgid/setuid/sticky flag'
 663     'lsl' $'ls -l *(@[1,10])\n# only symlinks'
 664     'lsx' $'ls -l *(*[1,10])\n# only executables'
 665     'lsw' $'ls -ld *(R,W,X.^ND/)\n# world-{readable,writable,executable} files'
 666     'lsbig' $'ls -flh *(.OL[1,10])\n# display the biggest files'
 667     'lsd' $'ls -d *(/)\n# only show directories'
 668     'lse' $'ls -d *(/^F)\n# only show empty directories'
 669     'lsnew' $'ls -rl *(D.om[1,10])\n# display the newest files'
 670     'lsold' $'ls -rtlh *(D.om[-11,-1])\n # display the oldest files'
 671     'lssmall' $'ls -Srl *(.oL[1,10])\n# display the smallest files'
 672     'rw-' 'chmod 600'
 673     '600' 'chmod u+rw-x,g-rwx,o-rwx'
 674     'rwx' 'chmod u+rwx'
 675     '700' 'chmod u+rwx,g-rwx,o-rwx'
 676     'r--' 'chmod u+r-wx,g-rwx,o-rwx'
 677     '644' $'chmod u+rw-x,g+r-wx,o+r-wx\n # 4=r,2=w,1=x'
 678     '755' 'chmod u+rwx,g+r-w+x,o+r-w+x'
 679     'md' 'mkdir -p '
 680     'cmplayer' 'mplayer -vo -fs -zoom fbdev'
 681     'fbmplayer' 'mplayer -vo -fs -zoom fbdev'
 682     'fblinks' 'links2 -driver fb'
 683     'insecssh' 'ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 684     'insecscp' 'scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 685     'fori' 'for i ({..}) { }'
 686     'cx' 'chmod +x'
 687     'e'  'print -l'
 688     'se' 'setopt interactivecomments'
 689     'va' 'valac --vapidir=../vapi/ --pkg=gtk+-2.0 gtktest.vala'
 690     'fb2' '=mplayer -vo fbdev -fs -zoom 1>/dev/null -xy 2'
 691     'fb3' '=mplayer -vo fbdev -fs  -zoom 1>/dev/null -xy 3'
 692     'ci' 'centericq'
 693     'D'  'export DISPLAY=:0.0'
 694     'mp' 'mplayer -vo xv -fs -zoom'
 695 )
 696
 697 globalias() {
 698     local MATCH
 699     matched_chars='[.-|_a-zA-Z0-9]#'
 700     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 701     LBUFFER+=${abk[$MATCH]:-$MATCH}
 702 }
 703
 704 zle -N globalias
 705 bindkey ",." globalias
 706 # }}}
 707
 708 # {{{ autoloading
 709 zrcautoload zmv    # who needs mmv or rename?
 710 zrcautoload history-search-end
 711
 712 # we don't want to quote/espace URLs on our own...
 713 # if autoload -U url-quote-magic ; then
 714 #    zle -N self-insert url-quote-magic
 715 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 716 # else
 717 #    print 'Notice: no url-quote-magic available :('
 718 # fi
 719 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 720
 721 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 722 alias run-help >&/dev/null && unalias run-help
 723 zrcautoload run-help # use via 'esc-h'
 724
 725 # completion system
 726 if zrcautoload compinit && compinit 2>/dev/null ; then
 727     compinit 2>/dev/null || print 'Notice: no compinit available :('
 728 else
 729     print 'Notice: no compinit available :('
 730     function zstyle { }
 731     function compdef { }
 732 fi
 733
 734 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 735
 736 is4 && \
 737 for mod in complist deltochar mathfunc ; do
 738     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 739 done
 740
 741 # autoload zsh modules when they are referenced
 742 if is4 ; then
 743     tmpargs=(
 744         a   stat
 745         a   zpty
 746         ap  zprof
 747         ap  mapfile
 748     )
 749
 750     while (( ${#tmpargs} > 0 )) ; do
 751         zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
 752         shift 2 tmpargs
 753     done
 754     unset tmpargs
 755 fi
 756
 757 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 758     #k# Insert files
 759     bindkey "^Xf" insert-files # C-x-f
 760 fi
 761
 762 bindkey ' '   magic-space    # also do history expansion on space
 763 #k# Trigger menu-complete
 764 bindkey '\ei' menu-complete  # menu completion via esc-i
 765
 766 # press esc-e for editing command line in $EDITOR or $VISUAL
 767 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 768     #k# Edit the current line in \kbd{\$EDITOR}
 769     bindkey '\ee' edit-command-line
 770 fi
 771
 772 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 773     #k# menu selection: pick item but stay in the menu
 774     bindkey -M menuselect '\e^M' accept-and-menu-complete
 775
 776     # use the vi navigation keys (hjkl) besides cursor keys in menu completion
 777     #bindkey -M menuselect 'h' vi-backward-char        # left
 778     #bindkey -M menuselect 'k' vi-up-line-or-history   # up
 779     #bindkey -M menuselect 'l' vi-forward-char         # right
 780     #bindkey -M menuselect 'j' vi-down-line-or-history # bottom
 781
 782     # accept a completion and try to complete again by using menu
 783     # completion; very useful with completing directories
 784     # by using 'undo' one's got a simple file browser
 785     bindkey -M menuselect '^o' accept-and-infer-next-history
 786 fi
 787
 788 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 789 _bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
 790 zle -N _bkdate
 791
 792 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 793 bindkey '^Ed' _bkdate
 794
 795 # press esc-m for inserting last typed word again (thanks to caphuso!)
 796 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 797 zle -N insert-last-typed-word;
 798
 799 #k# Insert last typed word
 800 bindkey "\em" insert-last-typed-word
 801
 802 # set command prediction from history, see 'man 1 zshcontrib'
 803 #  is4 && zrcautoload predict-on && \
 804 #  zle -N predict-on         && \
 805 #  zle -N predict-off        && \
 806 #  bindkey "^X^Z" predict-on && \
 807 #  bindkey "^Z" predict-off
 808
 809 #k# Shortcut for \kbd{fg<enter>}
 810 bindkey -s '^z' "fg\n"
 811
 812 # press ctrl-q to quote line:
 813 #  mquote () {
 814 #        zle beginning-of-line
 815 #        zle forward-word
 816 #        # RBUFFER="'$RBUFFER'"
 817 #        RBUFFER=${(q)RBUFFER}
 818 #        zle end-of-line
 819 #  }
 820 #  zle -N mquote && bindkey '^q' mquote
 821
 822 # run command line as user root via sudo:
 823 sudo-command-line() {
 824     [[ -z $BUFFER ]] && zle up-history
 825     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
 826 }
 827 zle -N sudo-command-line
 828
 829 #k# Put the current command line into a \kbd{sudo} call
 830 bindkey "^Os" sudo-command-line
 831
 832 ### jump behind the first word on the cmdline.
 833 ### useful to add options.
 834 function jump_after_first_word() {
 835     local words
 836     words=(${(z)BUFFER})
 837
 838     if (( ${#words} <= 1 )) ; then
 839         CURSOR=${#BUFFER}
 840     else
 841         CURSOR=${#${words[1]}}
 842     fi
 843 }
 844 zle -N jump_after_first_word
 845
 846 bindkey '^x1' jump_after_first_word
 847
 848 # }}}
 849
 850 # {{{ set some important options
 851 # Please update these tags, if you change the umask settings below.
 852 #o# r_umask     002
 853 #o# r_umaskstr  rwxrwxr-x
 854 #o# umask       022
 855 #o# umaskstr    rwxr-xr-x
 856 (( EUID != 0 )) && umask 002 || umask 022
 857
 858 # history:
 859 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 860 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 861 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 862 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 863                             # list duplicates an older one, the older command is removed from the list
 864 setopt histignorespace      # remove command lines from the history list when
 865                             # the first character on the line is a space
 866 #  setopt histallowclobber    # add `|' to output redirections in the history
 867 #  setopt NO_clobber          # warning if file exists ('cat /dev/null > ~/.zshrc')
 868 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 869                             # and the command is the name of a directory, perform the cd command to that directory
 870 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 871                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 872                             # -> searches for word not in compressed files
 873                             # don't forget to quote '^', '~' and '#'!
 874 setopt longlistjobs         # display PID when suspending processes as well
 875 setopt notify               # report the status of backgrounds jobs immediately
 876 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 877                             # the entire command path is hashed first.
 878 setopt completeinword       # not just at the end
 879 # setopt nocheckjobs          # don't warn me about bg processes when exiting
 880 setopt nohup                # and don't kill them, either
 881 # setopt printexitvalue       # alert me if something failed
 882 # setopt dvorak               # with spelling correction, assume dvorak kb
 883 setopt auto_pushd           # make cd push the old directory onto the directory stack.
 884 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 885 setopt nobeep               # avoid "beep"ing
 886 setopt pushd_ignore_dups    # don't push the same dir twice.
 887
 888 MAILCHECK=30       # mailchecks
 889 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 890 watch=(notme root) # watch for everyone but me and root
 891
 892 # define word separators (for stuff like backward-word, forward-word, backward-kill-word,..)
 893 #  WORDCHARS='*?_-.[]~=/&;!#$%^(){}<>' # the default
 894 #  WORDCHARS=.
 895 #  WORDCHARS='*?_[]~=&;!#$%^(){}'
 896 #  WORDCHARS='${WORDCHARS:s@/@}'
 897
 898 # only slash should be considered as a word separator:
 899 slash-backward-kill-word() {
 900     local WORDCHARS="${WORDCHARS:s@/@}"
 901     # zle backward-word
 902     zle backward-kill-word
 903 }
 904 zle -N slash-backward-kill-word
 905
 906 #k# Kill everything in a word up to its last \kbd{/}
 907 bindkey '\ev' slash-backward-kill-word
 908
 909 # }}}
 910
 911 # {{{ history
 912
 913 ZSHDIR=$HOME/.zsh
 914
 915 #v#
 916 HISTFILE=$HOME/.zsh_history
 917 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
 918 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
 919
 920 # }}}
 921
 922 # dirstack handling {{{
 923
 924 DIRSTACKSIZE=20
 925 if [[ -f ~/.zdirs ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
 926     dirstack=( ${(f)"$(< ~/.zdirs)"} )
 927     # "cd -" won't work after login by just setting $OLDPWD, so
 928     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
 929 fi
 930
 931 chpwd() {
 932     builtin print -l ${(u)dirstack} >! ~/.zdirs
 933 }
 934
 935 # }}}
 936
 937 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
 938 if [[ -n "$BATTERY" ]] ; then
 939     if check_com -c acpi ; then
 940         PERCENT="${(C)${(s| |)$(acpi 2>/dev/null)}[4]}"
 941         [[ -z "$PERCENT" ]] && PERCENT='acpi not present'
 942
 943         if [[ "${PERCENT%%%}" -lt 20 ]] ; then
 944             PERCENT="warning: ${PERCENT}%"
 945         fi
 946     fi
 947 fi
 948 # }}}
 949
 950 # display version control information on right side of prompt if $VCS is set {{{
 951 # based on Mike Hommey's http://web.glandium.org/blog/?p=170
 952 __vcs_dir() {
 953     local vcs base_dir sub_dir ref
 954
 955     sub_dir() {
 956       local sub_dir
 957       sub_dir=$(readlink -f "${PWD}")
 958       sub_dir=${sub_dir#$1}
 959       echo ${sub_dir#/}
 960     }
 961
 962     git_dir() {
 963       base_dir=$(git-rev-parse --show-cdup 2>/dev/null) || return 1
 964       base_dir=$(readlink -f "$base_dir/..")
 965       sub_dir=$(git-rev-parse --show-prefix)
 966       sub_dir=${sub_dir%/}
 967       ref=$(git-symbolic-ref -q HEAD || git-name-rev --name-only HEAD 2>/dev/null)
 968       ref=${ref#refs/heads/}
 969       vcs="git"
 970     }
 971
 972     svn_dir() {
 973       [[ -d ".svn" ]] || return 1
 974       base_dir="."
 975       while [[ -d "$base_dir/../.svn" ]]; do base_dir="$base_dir/.."; done
 976       base_dir=$(readlink -f "$base_dir")
 977       sub_dir=$(sub_dir "${base_dir}")
 978       ref=$(svn info "$base_dir" | awk '/^URL/ { sub(".*/","",$0); r=$0 } /^Revision/ { sub("[^0-9]*","",$0); print r":"$0 }')
 979       vcs="svn"
 980     }
 981
 982     svk_dir() {
 983         [[ -f ~/.svk/config ]] || return 1
 984         base_dir=$(awk '/: *$/ { sub(/^ */,"",$0); sub(/: *$/,"",$0); if (match("'${PWD}'", $0"(/|$)")) { print $0; d=1; } } /depotpath/ && d == 1 { sub(".*/","",$0); r=$0 } /revision/ && d == 1 { print r ":" $2; exit 1 }' ~/.svk/config) && return 1
 985         ref=${base_dir##*
 986   }
 987         base_dir=${base_dir%%
 988   *}
 989         sub_dir=$(sub_dir "${base_dir}")
 990         vcs="svk"
 991     }
 992
 993     hg_dir() {
 994         base_dir="."
 995         while [[ ! -d "$base_dir/.hg" ]]; do
 996             base_dir="$base_dir/.."
 997             [[ $(readlink -f "${base_dir}") = "/" ]] && return 1
 998         done
 999         base_dir=$(readlink -f "$base_dir")
1000         sub_dir=$(sub_dir "${base_dir}")
1001         ref=$(< "${base_dir}/.hg/branch")
1002         vcs="hg"
1003     }
1004
1005     hg_dir  ||
1006     git_dir ||
1007     svn_dir ||
1008     svk_dir # ||
1009   #  base_dir="$PWD"
1010   #  echo "${vcs:+($vcs)}${base_dir/$HOME/~}${vcs:+[$ref]${sub_dir}}"
1011     echo "${vcs:+($vcs)}${base_dir}${vcs:+[$ref]${sub_dir}}"
1012 }
1013 # }}}
1014
1015 # {{{ set prompt
1016 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1017     promptinit # people should be able to use their favourite prompt
1018 else
1019     print 'Notice: no promptinit available :('
1020 fi
1021
1022
1023 # precmd() => a function which is executed just before each prompt
1024 # use 'NOPRECMD=1' to disable the precmd + preexec commands
1025
1026 # precmd () { setopt promptsubst; [[ -o interactive ]] && jobs -l;
1027
1028 # make sure to use right prompt only when not running a command
1029 is41 && setopt transient_rprompt
1030
1031 is4 && [[ -z $NOPRECMD ]] && precmd () {
1032     [[ -n $NOPRECMD ]] && return 0
1033     # allow manual overwriting of RPROMPT
1034     if [[ -n $RPROMPT ]] ; then
1035         [[ $TERM == screen* ]] && echo -n $'\ekzsh\e\\'
1036         # return 0
1037     fi
1038     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1039     if [[ -z $DONTSETRPROMPT ]] ; then
1040         if [[ -n $BATTERY ]] ; then
1041             RPROMPT="%(?..:()% ${PERCENT}${SCREENTITLE}"
1042             # RPROMPT="${PERCENT}${SCREENTITLE}"
1043         elif [[ -n $VCS ]] ; then
1044             RPROMPT="%(?..:()% $(__vcs_dir)${SCREENTITLE}"
1045         else
1046             RPROMPT="%(?..:()% ${SCREENTITLE}"
1047             # RPROMPT="${SCREENTITLE}"
1048         fi
1049     fi
1050     # adjust title of xterm
1051     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1052     case $TERM in
1053         (xterm*|rxvt)
1054             print -Pn "\e]0;%n@%m: %~\a"
1055             ;;
1056     esac
1057 }
1058
1059 # chpwd () => a function which is executed whenever the directory is changed
1060
1061 # preexec() => a function running before every command
1062 is4 && [[ -z $NOPRECMD ]] && \
1063 preexec () {
1064     [[ -n $NOPRECMD ]] && return 0
1065 # set hostname if not running on host with name 'grml'
1066     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1067        NAME="@$HOSTNAME"
1068     fi
1069 # get the name of the program currently running and hostname of local machine
1070 # set screen window title if running in a screen
1071     if [[ "$TERM" == screen* ]] ; then
1072         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1073         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1074         echo -ne "\ek$CMD\e\\"
1075     fi
1076 # set the screen title to "zsh" when sitting at the command prompt:
1077     if [[ "$TERM" == screen* ]] ; then
1078         SCREENTITLE=$'%{\ekzsh\e\\%}'
1079     else
1080         SCREENTITLE=''
1081     fi
1082 # adjust title of xterm
1083     case $TERM in
1084         (xterm*|rxvt)
1085             print -Pn "\e]0;%n@%m: $1\a"
1086             ;;
1087     esac
1088 }
1089
1090 # set colors
1091 if zrcautoload colors && colors 2>/dev/null ; then
1092     BLUE="%{${fg[blue]}%}"
1093     RED="%{${fg_bold[red]}%}"
1094     GREEN="%{${fg[green]}%}"
1095     CYAN="%{${fg[cyan]}%}"
1096     WHITE="%{${fg[white]}%}"
1097     NO_COLOUR="%{${reset_color}%}"
1098 else
1099     BLUE=$'%{\e[1;34m%}'
1100     RED=$'%{\e[1;31m%}'
1101     GREEN=$'%{\e[1;32m%}'
1102     CYAN=$'%{\e[1;36m%}'
1103     WHITE=$'%{\e[1;37m%}'
1104     NO_COLOUR=$'%{\e[0m%}'
1105 fi
1106
1107 EXITCODE="%(?..%?%1v )"
1108 PS2='`%_> '       # secondary prompt, printed when the shell needs more information to complete a command.
1109 PS3='?# '         # selection prompt used within a select loop.
1110 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1111
1112 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1113 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1114     debian_chroot=$(cat /etc/debian_chroot)
1115 fi
1116
1117 # don't use colors on dumb terminals (like emacs):
1118 if [[ "$TERM" == dumb ]] ; then
1119     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< %# "
1120 else
1121     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
1122     # set variable identifying the chroot you work in (used in the prompt below)
1123     if [[ -n $GRMLPROMPT ]] ; then
1124         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1125 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# "
1126     else
1127         if (( EUID != 0 )); then
1128             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# " # primary prompt string
1129         else
1130             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# " # primary prompt string
1131         fi
1132     fi
1133 fi
1134
1135 # if we are inside a grml-chroot set a specific prompt theme
1136 if [[ -n "$GRML_CHROOT" ]] ; then
1137     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1138 fi
1139 # }}}
1140
1141 # {{{ 'hash' some often used directories
1142 #d# start
1143 hash -d deb=/var/cache/apt/archives
1144 hash -d doc=/usr/share/doc
1145 hash -d linux=/lib/modules/$(command uname -r)/build/
1146 hash -d log=/var/log
1147 hash -d slog=/var/log/syslog
1148 hash -d src=/usr/src
1149 hash -d templ=/usr/share/doc/grml-templates
1150 hash -d tt=/usr/share/doc/texttools-doc
1151 hash -d www=/var/www
1152 #d# end
1153 # }}}
1154
1155 # {{{ some aliases
1156 if [[ $UID -eq 0 ]] ; then
1157     [[ -r /etc/grml/screenrc ]] && alias screen='/usr/bin/screen -c /etc/grml/screenrc'
1158 elif [[ -r $HOME/.screenrc ]] ; then
1159     alias screen="/usr/bin/screen -c $HOME/.screenrc"
1160 else
1161     [[ -r /etc/grml/screenrc_grml ]] && alias screen='/usr/bin/screen -c /etc/grml/screenrc_grml'
1162 fi
1163
1164 # do we have GNU ls with color-support?
1165 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
1166     #a1# execute \kbd{@a@}:\quad ls with colors
1167     alias ls='ls -b -CF --color=auto'
1168     #a1# execute \kbd{@a@}:\quad list all files, with colors
1169     alias la='ls -la --color=auto'
1170     #a1# long colored list, without dotfiles (@a@)
1171     alias ll='ls -l --color=auto'
1172     #a1# long colored list, human readable sizes (@a@)
1173     alias lh='ls -hAl --color=auto'
1174     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1175     alias l='ls -lF --color=auto'
1176 else
1177     alias ls='ls -b -CF'
1178     alias la='ls -la'
1179     alias ll='ls -l'
1180     alias lh='ls -hAl'
1181     alias l='ls -lF'
1182 fi
1183
1184 alias mdstat='cat /proc/mdstat'
1185 alias ...='cd ../../'
1186
1187 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1188 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1189     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1190 fi
1191
1192 alias cp='nocorrect cp'         # no spelling correction on cp
1193 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
1194 alias mv='nocorrect mv'         # no spelling correction on mv
1195 alias rm='nocorrect rm'         # no spelling correction on rm
1196
1197 #a1# Execute \kbd{rmdir}
1198 alias rd='rmdir'
1199 #a1# Execute \kbd{rmdir}
1200 alias md='mkdir'
1201
1202 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1203 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1204 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1205
1206 # make sure it is not assigned yet
1207 [[ $(whence -w utf2iso &>/dev/null) == 'utf2iso: alias' ]] && unalias utf2iso
1208
1209 utf2iso() {
1210     if isutfenv ; then
1211         for ENV in $(env | command grep -i '.utf') ; do
1212             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1213         done
1214     fi
1215 }
1216
1217 # make sure it is not assigned yet
1218 [[ $(whence -w iso2utf &>/dev/null) == 'iso2utf: alias' ]] && unalias iso2utf
1219 iso2utf() {
1220     if ! isutfenv ; then
1221         for ENV in $(env | command grep -i '\.iso') ; do
1222             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1223         done
1224     fi
1225 }
1226
1227 # set up software synthesizer via speakup
1228 swspeak() {
1229     aumix -w 90 -v 90 -p 90 -m 90
1230     if ! [[ -r /dev/softsynth ]] ; then
1231         flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
1232         return 1
1233     else
1234         setopt singlelinezle
1235         unsetopt prompt_cr
1236         export PS1="%m%# "
1237         nice -n -20 speechd-up
1238         sleep 2
1239         flite -o play -t "Finished setting up software synthesizer"
1240     fi
1241 }
1242
1243 # I like clean prompt, so provide simple way to get that
1244 check_com 0 || alias 0='return 0'
1245
1246 # for really lazy people like mika:
1247 check_com S &>/dev/null || alias S='screen'
1248 check_com s &>/dev/null || alias s='ssh'
1249
1250 # get top 10 shell commands:
1251 alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
1252
1253 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
1254 if check_com -c truecrypt ; then
1255     if isutfenv ; then
1256         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
1257     else
1258         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
1259     fi
1260 fi
1261
1262 #f1# Hints for the use of zsh on grml
1263 zsh-help() {
1264     print "$bg[white]$fg[black]
1265 zsh-help - hints for use of zsh on grml
1266 =======================================$reset_color"
1267
1268     print '
1269 Main configuration of zsh happens in /etc/zsh/zshrc (global)
1270 and /etc/skel/.zshrc which is copied to $HOME/.zshrc once.
1271 The files are part of the package grml-etc-core, if you want to
1272 use them on a non-grml-system just get the tar.gz from
1273 http://deb.grml.org/ or get the files from the mercurial
1274 repository:
1275
1276   http://hg.grml.org/grml-etc-core/raw-file/tip/etc/skel/.zshrc
1277   http://hg.grml.org/grml-etc-core/raw-file/tip/etc/zsh/zshrc
1278
1279 If you want to stay in sync with zsh configuration of grml
1280 run '\''ln -sf /etc/skel/.zshrc $HOME/.zshrc'\'' and configure
1281 your own stuff in $HOME/.zshrc.local. System wide configuration
1282 without touching configuration files of grml can take place
1283 in /etc/zsh/zshrc.local.
1284
1285 If you want to use the configuration of user grml also when
1286 running as user root just run '\''zshskel'\'' which will source
1287 the file /etc/skel/.zshrc.
1288
1289 For information regarding zsh start at http://grml.org/zsh/
1290
1291 Take a look at grml'\''s zsh refcard:
1292 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1293
1294 Check out the main zsh refcard:
1295 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1296
1297 And of course visit the zsh-lovers:
1298 % man zsh-lovers
1299
1300 You can adjust some options through environment variables when
1301 invoking zsh without having to edit configuration files.
1302 Basically meant for bash users who are not used to the power of
1303 the zsh yet. :)
1304
1305   "NOCOR=1    zsh" => deactivate automatic correction
1306   "NOMENU=1   zsh" => do not use menu completion (note: use strg-d for completion instead!)
1307   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1308   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt'
1309
1310     print "
1311 $bg[white]$fg[black]
1312 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1313 Enjoy your grml system with the zsh!$reset_color"
1314 }
1315
1316 # debian stuff
1317 if [[ -r /etc/debian_version ]] ; then
1318     #a3# Execute \kbd{apt-cache search}
1319     alias acs='apt-cache search'
1320     #a3# Execute \kbd{apt-cache show}
1321     alias acsh='apt-cache show'
1322     #a3# Execute \kbd{apt-cache policy}
1323     alias acp='apt-cache policy'
1324     #a3# Execute \kbd{apt-get dist-upgrade}
1325     salias adg="apt-get dist-upgrade"
1326     #a3# Execute \kbd{apt-get install}
1327     salias agi="apt-get install"
1328     #a3# Execute \kbd{aptitude install}
1329     salias ati="aptitude install"
1330     #a3# Execute \kbd{apt-get upgrade}
1331     salias ag="apt-get upgrade"
1332     #a3# Execute \kbd{apt-get update}
1333     salias au="apt-get update"
1334     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1335     salias -a up="aptitude update ; aptitude safe-upgrade"
1336     #a3# Execute \kbd{dpkg-buildpackage}
1337     alias dbp='dpkg-buildpackage'
1338     #a3# Execute \kbd{grep-excuses}
1339     alias ge='grep-excuses'
1340
1341     # debian upgrade
1342     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
1343     upgrade() {
1344         if [[ -z "$1" ]] ; then
1345             $SUDO apt-get update
1346             $SUDO apt-get -u upgrade
1347         else
1348             ssh $1 $SUDO apt-get update
1349             # ask before the upgrade
1350             local dummy
1351             ssh $1 $SUDO apt-get --no-act upgrade
1352             echo -n 'Process the upgrade?'
1353             read -q dummy
1354             if [[ $dummy == "y" ]] ; then
1355                 ssh $1 $SUDO apt-get -u upgrade --yes
1356             fi
1357         fi
1358     }
1359
1360     # get a root shell as normal user in live-cd mode:
1361     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1362        alias su="sudo su"
1363      fi
1364
1365     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1366     alias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1367     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1368     alias tlog="tail -f /var/log/syslog"    # follow the syslog
1369     #a1# (Re)-source \kbd{/etc/skel/.zshrc}
1370     alias zshskel="source /etc/skel/.zshrc" # source skeleton zshrc
1371 fi
1372
1373 # sort installed Debian-packages by size
1374 if check_com -c grep-status ; then
1375     #a3# List installed Debian-packages sorted by size
1376     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
1377 fi
1378
1379 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1380 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord ; then
1381     if check_com -c wodim ; then
1382         alias cdrecord="echo 'cdrecord is not provided under its original name by Debian anymore.
1383 See #377109 in the BTS of Debian for more details.
1384
1385 Please use the wodim binary instead' ; return 1"
1386     fi
1387 fi
1388
1389 # get_tw_cli has been renamed into get_3ware
1390 if check_com -c get_3ware ; then
1391     get_tw_cli() {
1392         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
1393         get_3ware
1394     }
1395 fi
1396
1397 # I hate lacking backward compatibility, so provide an alternative therefore
1398 if ! check_com -c apache2-ssl-certificate ; then
1399
1400     apache2-ssl-certificate() {
1401
1402     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
1403     print 'You might want to take a look at Debian the package ssl-cert as well.'
1404     print 'To generate a certificate for use with apache2 follow the instructions:'
1405
1406     echo '
1407
1408 export RANDFILE=/dev/random
1409 mkdir /etc/apache2/ssl/
1410 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
1411 chmod 600 /etc/apache2/ssl/apache.pem
1412
1413 Run "grml-tips ssl-certificate" if you need further instructions.
1414 '
1415     }
1416 fi
1417 # }}}
1418
1419 # {{{ Use hard limits, except for a smaller stack and no core dumps
1420 unlimit
1421 is4 && limit stack 8192
1422 isgrmlcd && limit core 0 # important for a live-cd-system
1423 limit -s
1424 # }}}
1425
1426 # {{{ completion system
1427
1428 # called later (via is4 && grmlcomp)
1429 # notice: use 'zstyle' for getting current settings
1430 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
1431 grmlcomp() {
1432     # TODO: This could use some additional information
1433
1434     # allow one error for every three characters typed in approximate completer
1435     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1436
1437     # don't complete backup files as executables
1438     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1439
1440     # start menu completion only if it could find no unambiguous initial string
1441     zstyle ':completion:*:correct:*'       insert-unambiguous true
1442     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1443     zstyle ':completion:*:correct:*'       original true
1444
1445     # activate color-completion
1446     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1447
1448     # format on completion
1449     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1450
1451     # complete 'cd -<tab>' with menu
1452     zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1453
1454     # insert all expansions for expand completer
1455     zstyle ':completion:*:expand:*'        tag-order all-expansions
1456     zstyle ':completion:*:history-words'   list false
1457
1458     # activate menu
1459     zstyle ':completion:*:history-words'   menu yes
1460
1461     # ignore duplicate entries
1462     zstyle ':completion:*:history-words'   remove-all-dups yes
1463     zstyle ':completion:*:history-words'   stop yes
1464
1465     # match uppercase from lowercase
1466     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1467
1468     # separate matches into groups
1469     zstyle ':completion:*:matches'         group 'yes'
1470     zstyle ':completion:*'                 group-name ''
1471
1472     if [[ -z "$NOMENU" ]] ; then
1473         # if there are more than 5 options allow selecting from a menu
1474         zstyle ':completion:*'               menu select=5
1475     else
1476         # don't use any menus at all
1477         setopt no_auto_menu
1478     fi
1479
1480     zstyle ':completion:*:messages'        format '%d'
1481     zstyle ':completion:*:options'         auto-description '%d'
1482
1483     # describe options in full
1484     zstyle ':completion:*:options'         description 'yes'
1485
1486     # on processes completion complete all user processes
1487     zstyle ':completion:*:processes'       command 'ps -au$USER'
1488
1489     # offer indexes before parameters in subscripts
1490     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1491
1492     # provide verbose completion information
1493     zstyle ':completion:*'                 verbose true
1494
1495     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1496     # for commands (read: 1st word in the line) that it will list for the user
1497     # to choose from. The following disables that, because it's not exactly fast.
1498     zstyle ':completion:*:-command-:*:'    verbose false
1499
1500     # set format for warnings
1501     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1502
1503     # define files to ignore for zcompile
1504     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1505     zstyle ':completion:correct:'          prompt 'correct to: %e'
1506
1507     # Ignore completion functions for commands you don't have:
1508     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1509
1510     # complete manual by their section
1511     zstyle ':completion:*:manuals'    separate-sections true
1512     zstyle ':completion:*:manuals.*'  insert-sections   true
1513     zstyle ':completion:*:man:*'      menu yes select
1514
1515     # run rehash on completion so new installed program are found automatically:
1516     _force_rehash() {
1517         (( CURRENT == 1 )) && rehash
1518         return 1
1519     }
1520
1521     ## correction
1522     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1523     if [[ -n "$NOCOR" ]] ; then
1524         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1525         setopt nocorrect
1526     else
1527         # try to be smart about when to use what completer...
1528         setopt correct
1529         zstyle -e ':completion:*' completer '
1530             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1531                 _last_try="$HISTNO$BUFFER$CURSOR"
1532                 reply=(_complete _match _ignored _prefix _files)
1533             else
1534                 if [[ $words[1] == (rm|mv) ]] ; then
1535                     reply=(_complete _files)
1536                 else
1537                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1538                 fi
1539             fi'
1540     fi
1541
1542     # zstyle ':completion:*' completer _complete _correct _approximate
1543     # zstyle ':completion:*' expand prefix suffix
1544
1545     # command for process lists, the local web server details and host completion
1546     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1547
1548     # caching
1549     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1550                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1551
1552     # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
1553     if is42 ; then
1554         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1555         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1556     else
1557         _ssh_hosts=()
1558         _etc_hosts=()
1559     fi
1560     hosts=(
1561         $(hostname)
1562         "$_ssh_hosts[@]"
1563         "$_etc_hosts[@]"
1564         grml.org
1565         localhost
1566     )
1567     zstyle ':completion:*:hosts' hosts $hosts
1568     #  zstyle '*' hosts $hosts
1569
1570     # specify your logins:
1571     # my_accounts=(
1572     #  {grml,grml1}@foo.invalid
1573     #  grml-devel@bar.invalid
1574     # )
1575     # other_accounts=(
1576     #  {fred,root}@foo.invalid
1577     #  vera@bar.invalid
1578     # )
1579     # zstyle ':completion:*:my-accounts' users-hosts $my_accounts
1580     # zstyle ':completion:*:other-accounts' users-hosts $other_accounts
1581
1582     # specify specific port/service settings:
1583     #  telnet_users_hosts_ports=(
1584     #    user1@host1:
1585     #    user2@host2:
1586     #    @mail-server:{smtp,pop3}
1587     #    @news-server:nntp
1588     #    @proxy-server:8000
1589     #  )
1590     # zstyle ':completion:*:*:telnet:*' users-hosts-ports $telnet_users_hosts_ports
1591
1592     # use generic completion system for programs not yet defined; (_gnu_generic works
1593     # with commands that provide a --help option with "standard" gnu-like output.)
1594     compdef _gnu_generic tail head feh cp mv df stow uname ipacsum fetchipac
1595
1596     # see upgrade function in this file
1597     compdef _hosts upgrade
1598 }
1599 # }}}
1600
1601 # {{{ grmlstuff
1602 grmlstuff() {
1603 # people should use 'grml-x'!
1604     startx() {
1605         if [[ -e /etc/X11/xorg.conf ]] ; then
1606             [[ -x /usr/bin/startx ]] && /usr/bin/startx "$@" || /usr/X11R6/bin/startx "$@"
1607         else
1608             echo "Please use the script \"grml-x\" for starting the X Window System
1609 because there does not exist /etc/X11/xorg.conf yet.
1610 If you want to use startx anyway please call \"/usr/bin/startx\"."
1611             return -1
1612         fi
1613     }
1614
1615     xinit() {
1616         if [[ -e /etc/X11/xorg.conf ]] ; then
1617             [[ -x /usr/bin/xinit ]] && /usr/bin/xinit || /usr/X11R6/bin/xinit
1618         else
1619             echo "Please use the script \"grml-x\" for starting the X Window System.
1620 because there does not exist /etc/X11/xorg.conf yet.
1621 If you want to use xinit anyway please call \"/usr/bin/xinit\"."
1622             return -1
1623         fi
1624     }
1625
1626     if check_com -c 915resolution ; then
1627         alias 855resolution='echo -e "Please use 915resolution as resolution modify tool for Intel graphic chipset."; return -1'
1628     fi
1629
1630     #a1# Output version of running grml
1631     alias grml-version='cat /etc/grml_version'
1632
1633     if check_com -c rebuildfstab ; then
1634         #a1# Rebuild /etc/fstab
1635         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1636     fi
1637
1638     if check_com -c grml-debootstrap ; then
1639         alias debian2hd='print "Installing debian to harddisk is possible via using grml-debootstrap." ; return 1'
1640     fi
1641 }
1642 # }}}
1643
1644 # {{{ now run the functions
1645 isgrml && checkhome
1646 is4    && isgrml    && grmlstuff
1647 is4    && grmlcomp
1648 # }}}
1649
1650 # {{{ keephack
1651 is4 && xsource "/etc/zsh/keephack"
1652 # }}}
1653
1654 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
1655 # You use it as follows:
1656 # $ NTREF=/reference/file
1657 # $ ls -l *(e:nt:)
1658 # This lists all the files in the current directory newer than the reference file.
1659 # You can also specify the reference file inline; note quotes:
1660 # $ ls -l *(e:'nt ~/.zshenv':)
1661 is4 && nt() {
1662     if [[ -n $1 ]] ; then
1663         local NTREF=${~1}
1664     fi
1665     [[ $REPLY -nt $NTREF ]]
1666 }
1667 # }}}
1668
1669 # shell functions {{{
1670
1671 #f1# Provide csh compatibility
1672 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
1673
1674 #f1# Reload an autoloadable function
1675 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1676
1677 #f1# Reload zsh setup
1678 reload() {
1679     if [[ "$#*" -eq 0 ]] ; then
1680         [[ -r ~/.zshrc ]] && . ~/.zshrc
1681     else
1682         local fn
1683         for fn in "$@"; do
1684             unfunction $fn
1685             autoload -U $fn
1686         done
1687     fi
1688 }
1689 compdef _functions reload freload
1690
1691 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1692 sll() {
1693     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1694     for i in "$@" ; do
1695         file=$i
1696         while [[ -h "$file" ]] ; do
1697             ls -l $file
1698             file=$(readlink "$file")
1699         done
1700     done
1701 }
1702
1703 # fast manual access
1704 if check_com qma ; then
1705     #f1# View the zsh manual
1706     manzsh()  { qma zshall "$1" }
1707     compdef _man qma
1708 else
1709     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
1710     # manzsh()  { /usr/bin/man zshall |  most +/"$1" ; }
1711     # [[ -f ~/.terminfo/m/mostlike ]] && MYLESS='LESS=C TERMINFO=~/.terminfo TERM=mostlike less' || MYLESS='less'
1712     # manzsh()  { man zshall | $MYLESS -p $1 ; }
1713 fi
1714
1715 if check_com -c $PAGER ; then
1716     #f1# View Debian's changelog of a given package
1717     dchange() {
1718         if [[ -r /usr/share/doc/${1}/changelog.Debian.gz ]] ; then
1719             $PAGER /usr/share/doc/${1}/changelog.Debian.gz
1720         elif [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
1721             $PAGER /usr/share/doc/${1}/changelog.gz
1722         else
1723             if check_com -c aptitude ; then
1724                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1725                 if isgrml ; then
1726                     aptitude -t unstable changelog ${1}
1727                 else
1728                     aptitude changelog ${1}
1729                 fi
1730             else
1731                 echo "No changelog for package $1 found, sorry."
1732                 return 1
1733             fi
1734         fi
1735     }
1736     _dchange() { _files -W /usr/share/doc -/ }
1737     compdef _dchange dchange
1738
1739     #f1# View Debian's NEWS of a given package
1740     dnews() {
1741         if [[ -r /usr/share/doc/${1}/NEWS.Debian.gz ]] ; then
1742             $PAGER /usr/share/doc/${1}/NEWS.Debian.gz
1743         else
1744             if [[ -r /usr/share/doc/${1}/NEWS.gz ]] ; then
1745                 $PAGER /usr/share/doc/${1}/NEWS.gz
1746             else
1747                 echo "No NEWS file for package $1 found, sorry."
1748                 return 1
1749             fi
1750         fi
1751     }
1752     _dnews() { _files -W /usr/share/doc -/ }
1753     compdef _dnews dnews
1754
1755     #f1# View upstream's changelog of a given package
1756     uchange() {
1757         if [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
1758             $PAGER /usr/share/doc/${1}/changelog.gz
1759         else
1760             echo "No changelog for package $1 found, sorry."
1761             return 1
1762         fi
1763     }
1764     _uchange() { _files -W /usr/share/doc -/ }
1765     compdef _uchange uchange
1766 fi
1767
1768 # zsh profiling
1769 profile() {
1770     ZSH_PROFILE_RC=1 $SHELL "$@"
1771 }
1772
1773 #f1# Edit an alias via zle
1774 edalias() {
1775     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1776 }
1777 compdef _aliases edalias
1778
1779 #f1# Edit a function via zle
1780 edfunc() {
1781     [[ -z "$1" ]] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
1782 }
1783 compdef _functions edfunc
1784
1785 # use it e.g. via 'Restart apache2'
1786 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
1787 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
1788 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
1789 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
1790 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
1791 if [[ -d /etc/init.d ]] ; then
1792     for i in Start Restart Stop Force-Reload Reload ; do
1793         eval "$i() { $SUDO /etc/init.d/\$1 ${i:l} \$2 ; }"
1794     done
1795 fi
1796
1797 #f1# Provides useful information on globbing
1798 H-Glob() {
1799     echo -e "
1800     /      directories
1801     .      plain files
1802     @      symbolic links
1803     =      sockets
1804     p      named pipes (FIFOs)
1805     *      executable plain files (0100)
1806     %      device files (character or block special)
1807     %b     block special files
1808     %c     character special files
1809     r      owner-readable files (0400)
1810     w      owner-writable files (0200)
1811     x      owner-executable files (0100)
1812     A      group-readable files (0040)
1813     I      group-writable files (0020)
1814     E      group-executable files (0010)
1815     R      world-readable files (0004)
1816     W      world-writable files (0002)
1817     X      world-executable files (0001)
1818     s      setuid files (04000)
1819     S      setgid files (02000)
1820     t      files with the sticky bit (01000)
1821
1822   print *(m-1)          # Files modified up to a day ago
1823   print *(a1)           # Files accessed a day ago
1824   print *(@)            # Just symlinks
1825   print *(Lk+50)        # Files bigger than 50 kilobytes
1826   print *(Lk-50)        # Files smaller than 50 kilobytes
1827   print **/*.c          # All *.c files recursively starting in \$PWD
1828   print **/*.c~file.c   # Same as above, but excluding 'file.c'
1829   print (foo|bar).*     # Files starting with 'foo' or 'bar'
1830   print *~*.*           # All Files that do not contain a dot
1831   chmod 644 *(.^x)      # make all plain non-executable files publically readable
1832   print -l *(.c|.h)     # Lists *.c and *.h
1833   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
1834   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
1835 }
1836 alias help-zshglob=H-Glob
1837
1838 check_com -c qma && alias ?='qma zshall'
1839
1840 # grep for running process, like: 'any vim'
1841 any() {
1842     if [[ -z "$1" ]] ; then
1843         echo "any - grep for process(es) by keyword" >&2
1844         echo "Usage: any <keyword>" >&2 ; return 1
1845     else
1846         local STRING=$1
1847         local LENGTH=$(expr length $STRING)
1848         local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
1849         local REST=$(echo $(expr substr $STRING 2 $LENGTH))
1850         ps xauwww| grep "[$FIRSCHAR]$REST"
1851     fi
1852 }
1853
1854 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
1855 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
1856 [[ -r /proc/1/maps ]] && \
1857 deswap() {
1858     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
1859     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
1860     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
1861 }
1862
1863 # print hex value of a number
1864 hex() {
1865     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
1866 }
1867
1868 # calculate (or eval at all ;-)) with perl => p[erl-]eval
1869 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
1870 peval() {
1871     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
1872     perl -e "print eval($CALC),\"\n\";"
1873 }
1874 functions peval &>/dev/null && alias calc=peval
1875
1876 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
1877 # certain circumstances, so work around it, no matter which environment we have
1878 brltty() {
1879     if [[ -z "$DISPLAY" ]] ; then
1880         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
1881         command brltty "$@"
1882     else
1883         command brltty "$@"
1884     fi
1885 }
1886
1887 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
1888 aoeu() {
1889     echo -n 'Switching to us keyboard layout: '
1890     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
1891     echo 'Done'
1892 }
1893 asdf() {
1894     echo -n 'Switching to dvorak keyboard layout: '
1895     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
1896     echo 'Done'
1897 }
1898 # just press 'asdf' key to toggle from neon layout to us keyboard layout
1899 uiae() {
1900     echo -n 'Switching to us keyboard layout: '
1901     setxkbmap us && echo 'Done' || echo 'Failed'
1902 }
1903
1904 # set up an ipv6 tunnel
1905 ipv6-tunnel() {
1906     case $1 in
1907         start)
1908             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1909                 print 'ipv6 tunnel already set up, nothing to be done.'
1910                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
1911             else
1912                 [[ -n "$PUBLIC_IP" ]] || \
1913                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
1914                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
1915
1916                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
1917                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
1918                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
1919                 ifconfig sit0 tunnel ::192.88.99.1 up
1920                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
1921             fi
1922             ;;
1923         status)
1924             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1925                 print 'ipv6 tunnel available' ; return 0
1926             else
1927                 print 'ipv6 tunnel not available' ; return 1
1928             fi
1929             ;;
1930         stop)
1931             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1932                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
1933                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
1934             else
1935                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
1936             fi
1937             ;;
1938         *)
1939             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
1940             ;;
1941     esac
1942 }
1943
1944 # run dhclient for wireless device
1945 iwclient() {
1946     salias dhclient "$(wavemon -d | awk '/device/{print $2}')"
1947 }
1948
1949 # spawn a minimally set up ksh - useful if you want to umount /usr/.
1950 minimal-shell() {
1951     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ksh
1952 }
1953
1954 # make a backup of a file
1955 bk() {
1956     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
1957 }
1958
1959 # Switching shell safely and efficiently? http://www.zsh.org/mla/workers/2001/msg02410.html
1960 # bash() {
1961 #  NO_SWITCH="yes" command bash "$@"
1962 # }
1963 # restart () {
1964 #  exec $SHELL $SHELL_ARGS "$@"
1965 # }
1966
1967 # }}}
1968
1969 # log out? set timeout in seconds {{{
1970 # TMOUT=1800
1971 # do not log out in some specific terminals:
1972 #  if [[ "${TERM}" == ([Exa]term*|rxvt|dtterm|screen*) ]] ; then
1973 #    unset TMOUT
1974 #  fi
1975 # }}}
1976
1977 # {{{ make sure our environment is clean regarding colors
1978 for color in BLUE RED GREEN CYAN WHITE ; unset $color
1979 # }}}
1980
1981 # source another config file if present {{{
1982 xsource "/etc/zsh/zshrc.local"
1983 # }}}
1984
1985 # "persistent history" {{{
1986 # just write important commands you always need to ~/.important_commands
1987 if [[ -r ~/.important_commands ]] ; then
1988     fc -R ~/.important_commands
1989 fi
1990 # }}}
1991
1992 ## genrefcard.pl settings {{{
1993 ### example: split functions-search 8,16,24,32
1994 #@# split functions-search 8
1995 ## }}}
1996
1997 # add variable to be able to check whether the file has been read {{{
1998 ZSHRC_GLOBAL_HAS_BEEN_READ=1
1999 # }}}
2000
2001 ## END OF FILE #################################################################
2002 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4