etc/zsh/zshrc

   1 # Filename:      zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 # Latest change: Don Dez 06 23:21:21 CET 2007 [mika]
   7 ################################################################################
   8 # This file is sourced only for interactive shells. It
   9 # should contain commands to set up aliases, functions,
  10 # options, key bindings, etc.
  11 #
  12 # Global Order: zshenv, zprofile, zshrc, zlogin
  13 ################################################################################
  14
  15 # zsh-refcard-tag documentation: {{{
  16 #   You may notice strange looking comments in the zshrc (and ~/.zshrc as
  17 #   well). These are there for a purpose. grml's zsh-refcard can now be
  18 #   automatically generated from the contents of the actual configuration
  19 #   files. However, we need a little extra information on which comments
  20 #   and what lines of code to take into account (and for what purpose).
  21 #
  22 # Here is what they mean:
  23 #
  24 # List of tags (comment types) used:
  25 #   #a#     Next line contains an important alias, that should
  26 #           be included in the grml-zsh-refcard.
  27 #           (placement tag: @@INSERT-aliases@@)
  28 #   #f#     Next line contains the beginning of an important function.
  29 #           (placement tag: @@INSERT-functions@@)
  30 #   #v#     Next line contains an important variable.
  31 #           (placement tag: @@INSERT-variables@@)
  32 #   #k#     Next line contains an important keybinding.
  33 #           (placement tag: @@INSERT-keybindings@@)
  34 #   #d#     Hashed directories list generation:
  35 #               start   denotes the start of a list of 'hash -d'
  36 #                       definitions.
  37 #               end     denotes its end.
  38 #           (placement tag: @@INSERT-hasheddirs@@)
  39 #   #A#     Abbreviation expansion list generation:
  40 #               start   denotes the beginning of abbreviations.
  41 #               end     denotes their end.
  42 #           Lines within this section that end in '#d .*' provide
  43 #           extra documentation to be included in the refcard.
  44 #           (placement tag: @@INSERT-abbrev@@)
  45 #   #m#     This tag allows you to manually generate refcard entries
  46 #           for code lines that are hard/impossible to parse.
  47 #               Example:
  48 #                   #m# k ESC-h Call the run-help function
  49 #               That would add a refcard entry in the keybindings table
  50 #               for 'ESC-h' with the given comment.
  51 #           So the syntax is: #m# <section> <argument> <comment>
  52 #   #o#     This tag lets you insert entries to the 'other' hash.
  53 #           Generally, this should not be used. It is there for
  54 #           things that cannot be done easily in another way.
  55 #           (placement tag: @@INSERT-other-foobar@@)
  56 #
  57 #   All of these tags (except for m and o) take two arguments, the first
  58 #   within the tag, the other after the tag:
  59 #
  60 #   #<tag><section># <comment>
  61 #
  62 #   Where <section> is really just a number, which are defined by the
  63 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  64 #   instead of names is, that for the reader, the tag should not differ
  65 #   much from a regular comment. For zsh, it is a regular comment indeed.
  66 #   The numbers have got the following meanings:
  67 #         0 -> "default"
  68 #         1 -> "system"
  69 #         2 -> "user"
  70 #         3 -> "debian"
  71 #         4 -> "search"
  72 #         5 -> "shortcuts"
  73 #         6 -> "services"
  74 #
  75 #   So, the following will add an entry to the 'functions' table in the
  76 #   'system' section, with a (hopefully) descriptive comment:
  77 #       #f1# Edit an alias via zle
  78 #       edalias() {
  79 #
  80 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  81 #   that can be found in 'grml-zsh-refcard.tex.in'.
  82 #   If the section number is omitted, the 'default' section is assumed.
  83 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
  84 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
  85 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
  86 #}}}
  87
  88 # zsh profiling {{{
  89 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
  90 if [[ -n $ZSH_PROFILE_RC ]] ; then
  91     zmodload zsh/zprof
  92 fi
  93 # }}}
  94
  95 # utility functions {{{
  96 # this function checks if a command exists and returns either true
  97 # or false. This avoids using 'which' and 'whence', which will
  98 # avoid problems with aliases for which on certain weird systems. :-)
  99 check_com() {
 100     local -i comonly
 101
 102     if [[ ${1} == '-c' ]] ; then
 103         (( comonly = 1 ))
 104         shift
 105     else
 106         (( comonly = 0 ))
 107     fi
 108
 109     if (( ${#argv} != 1 )) ; then
 110         printf 'usage: check_com [-c] <command>\n' >&2
 111         return 1
 112     fi
 113
 114     if (( comonly > 0 )) ; then
 115         [[ -n ${commands[$1]}  ]] && return 0
 116         return 1
 117     fi
 118
 119     if   [[ -n ${commands[$1]}    ]] \
 120       || [[ -n ${functions[$1]}   ]] \
 121       || [[ -n ${aliases[$1]}     ]] \
 122       || [[ -n ${reswords[(r)$1]} ]] ; then
 123
 124         return 0
 125     fi
 126
 127     return 1
 128 }
 129
 130 # creates an alias and precedes the command with
 131 # sudo if $EUID is not zero.
 132 salias() {
 133     local only=0 ; local multi=0
 134     while [[ ${1} == -* ]] ; do
 135         case ${1} in
 136             (-o) only=1 ;;
 137             (-a) multi=1 ;;
 138             (--) shift ; break ;;
 139             (-h)
 140                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 141                 printf '  -h      shows this help text.\n'
 142                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 143                 printf '          be careful using this option.\n'
 144                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 145                 return 0
 146                 ;;
 147             (*) printf "unkown option: '%s'\n" "${1}" ; return 1 ;;
 148         esac
 149         shift
 150     done
 151
 152     if (( ${#argv} > 1 )) ; then
 153         printf 'Too many arguments %s\n' "${#argv}"
 154         return 1
 155     fi
 156
 157     key="${1%%\=*}" ;  val="${1#*\=}"
 158     if (( EUID == 0 )) && (( only == 0 )); then
 159         alias -- "${key}=${val}"
 160     elif (( EUID > 0 )) ; then
 161         (( multi > 0 )) && val="${val// ; / ; sudo }"
 162         alias -- "${key}=sudo ${val}"
 163     fi
 164
 165     return 0
 166 }
 167
 168 # Check if we can read given files and source those we can.
 169 xsource() {
 170     if (( ${#argv} < 1 )) ; then
 171         printf 'usage: xsource FILE(s)...\n' >&2
 172         return 1
 173     fi
 174
 175     while (( ${#argv} > 0 )) ; do
 176         [[ -r ${1} ]] && source ${1}
 177         shift
 178     done
 179     return 0
 180 }
 181
 182 # Check if we can read a given file and 'cat(1)' it.
 183 xcat() {
 184     if (( ${#argv} != 1 )) ; then
 185         printf 'usage: xcat FILE\n' >&2
 186         return 1
 187     fi
 188
 189     [[ -r ${1} ]] && cat ${1}
 190     return 0
 191 }
 192
 193 # Remove these functions again, they are of use only in these
 194 # setup files. This should be called at the end of .zshrc.
 195 xunfunction() {
 196     local -a funcs
 197     funcs=(check_com salias xcat xsource xunfunction)
 198
 199     for func in $funcs ; do
 200         [[ -n ${functions[$func]} ]] \
 201             && unfunction $func
 202     done
 203     return 0
 204 }
 205 #}}}
 206
 207 # locale setup {{{
 208 if [[ -z "$LANG" ]] ; then
 209     xsource "/etc/default/locale"
 210 fi
 211
 212 export LANG=${LANG:-en_US.iso885915}
 213 for var in LC_ALL LC_MESSAGES ; do
 214     [[ -n ${(P)var} ]] && export $var
 215 done
 216
 217 xsource "/etc/sysconfig/keyboard"
 218
 219 TZ=$(xcat /etc/timezone)
 220 # }}}
 221
 222 # check for potentially old files in 'completion.d' {{{
 223 setopt extendedglob
 224 xof=(/etc/zsh/completion.d/*~/etc/zsh/completion.d/_*(N))
 225 if (( ${#xof} > 0 )) ; then
 226     printf '\n -!- INFORMATION\n\n'
 227     printf ' -!- %s file(s) not starting with an underscore (_) found in\n' ${#xof}
 228     printf ' -!- /etc/zsh/completion.d/.\n\n'
 229     printf ' -!- While this has been the case in old versions of grml-etc-core,\n'
 230     printf ' -!- recent versions of the grml-zsh-setup have all these files rewritten\n'
 231     printf ' -!- and renamed. Furthermore, the grml-zsh-setup will *only* add files\n'
 232     printf ' -!- named _* to that directory.\n\n'
 233     printf ' -!- If you added functions to completion.d yourself, please consider\n'
 234     printf ' -!- moving them to /etc/zsh/functions.d/. Files in that directory, not\n'
 235     printf ' -!- starting with an underscore are marked for automatic loading\n'
 236     printf ' -!- by default (so that is quite convenient).\n\n'
 237     printf ' -!- If there are files *not* starting with an underscore from an older\n'
 238     printf ' -!- grml-etc-core in completion.d, you may safely remove them.\n\n'
 239     printf ' -!- Delete the files for example via running:\n\n'
 240     printf "      rm ${xof}\n\n"
 241     printf ' -!- Note, that this message will *not* go away, unless you yourself\n'
 242     printf ' -!- resolve the situation manually.\n\n'
 243     BROKEN_COMPLETION_DIR=1
 244 fi
 245 unset xof
 246 # }}}
 247
 248 # {{{ check for version/system
 249 # check for versions (compatibility reasons)
 250 if autoload is-at-least && is-at-least 2>/dev/null ; then
 251     is4()  { is-at-least 4 }
 252     is41() { is-at-least 4.1 }
 253     is42() { is-at-least 4.2 }
 254 else
 255     is4(){
 256         [[ $ZSH_VERSION == 4.* ]] && return 0
 257         return 1
 258     }
 259     is42(){
 260         [[ $ZSH_VERSION == 4.<2->* ]] && return 0
 261         return 1
 262     }
 263 fi
 264
 265 #f1# Checks whether or not you're running grml
 266 isgrml(){
 267     [[ -f /etc/grml_version ]] && return 0
 268     return 1
 269 }
 270
 271 #f1# Checks whether or not you're running a grml cd
 272 isgrmlcd(){
 273     [[ -f /etc/grml_cd ]] && return 0
 274     return 1
 275 }
 276
 277 if isgrml ; then
 278 #f1# Checks whether or not you're running grml-small
 279     isgrmlsmall() {
 280         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 281     }
 282 else
 283     isgrmlsmall() { return 1 }
 284 fi
 285
 286 #f1# are we running within an utf environment?
 287 isutfenv() {
 288     case "$LANG $CHARSET $LANGUAGE" in
 289         *utf*) return 0 ;;
 290         *UTF*) return 0 ;;
 291         *)     return 1 ;;
 292     esac
 293 }
 294
 295 # check for user, if not running as root set $SUDO to sudo
 296 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 297
 298 # change directory to home on first invocation of zsh
 299 # important for rungetty -> autologin
 300 # Thanks go to Bart Schaefer!
 301 isgrml && checkhome() {
 302     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 303         export ALREADY_DID_CD_HOME=$HOME
 304         cd
 305     fi
 306 }
 307 # }}}
 308
 309 # {{{ set some variables
 310 #v#
 311 if check_com -c vim ; then
 312     export EDITOR=${EDITOR:-vim}
 313 else
 314     export EDITOR=${EDITOR:-vi}
 315 fi
 316 #v#
 317
 318 export MAIL=${MAIL:-/var/mail/$USER}
 319
 320 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 321 export SHELL='/bin/zsh'
 322
 323 # color setup for ls:
 324 check_com -c dircolors && eval $(dircolors -b)
 325
 326 # set width of man pages to 80 for more convenient reading
 327 # (( ${+MANWIDTH} )) || export MANWIDTH=80
 328
 329 # Search path for the cd command
 330 #  cdpath=(.. ~)
 331
 332 # completion functions go to /etc/zsh/completion.d
 333 # function files may be put into /etc/zsh/functions.d, from where they
 334 # will be automatically autoloaded.
 335 if [[ -n "$BROKEN_COMPLETION_DIR" ]] ; then
 336     print 'Warning: not setting completion directories because broken files have been found.' >&2
 337 else
 338     [[ -d /etc/zsh/completion.d ]] && fpath+=( /etc/zsh/completion.d )
 339     if [[ -d /etc/zsh/functions.d ]] ; then
 340         fpath+=( /etc/zsh/functions.d )
 341         for func in /etc/zsh/functions.d/[^_]*[^~] ; do
 342             autoload -U ${func:t}
 343         done
 344     fi
 345 fi
 346
 347 # automatically remove duplicates from these arrays
 348 typeset -U path cdpath fpath manpath
 349 # }}}
 350
 351 # {{{ keybindings
 352 if [[ "$TERM" != emacs ]] ; then
 353     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 354     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 355     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 356     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 357     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 358     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 359     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 360     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 361     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 362     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 363     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 364     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 365     # ncurses stuff:
 366     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 367     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 368     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 369     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 370     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 371     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 372     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 373     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 374 fi
 375
 376 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 377 # use emacs style per default:
 378 bindkey -e
 379 # use vi style:
 380 # bindkey -v
 381
 382 #if [[ "$TERM" == screen ]] ; then
 383 bindkey '\e[1~' beginning-of-line       # home
 384 bindkey '\e[4~' end-of-line             # end
 385 bindkey '\e[A'  up-line-or-search       # cursor up
 386 bindkey '\e[B'  down-line-or-search     # <ESC>-
 387 bindkey '^x'    history-beginning-search-backward # alternative ways of searching the shell history
 388 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 389 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 390 # if terminal type is set to 'rxvt':
 391 bindkey '\e[7~' beginning-of-line       # home
 392 bindkey '\e[8~' end-of-line             # end
 393 #fi
 394
 395 # insert unicode character
 396 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 397 # See for example http://unicode.org/charts/ for unicode characters code
 398 autoload insert-unicode-char
 399 zle -N insert-unicode-char
 400 #k# Insert Unicode character
 401 bindkey '^Xi' insert-unicode-char
 402
 403 # just type 'cd ...' to get 'cd ../..'
 404 #  rationalise-dot() {
 405 #  if [[ $LBUFFER == *.. ]] ; then
 406 #    LBUFFER+=/..
 407 #  else
 408 #    LBUFFER+=.
 409 #  fi
 410 #  }
 411 #  zle -N rationalise-dot
 412 #  bindkey . rationalise-dot
 413
 414 #  bindkey '\eq' push-line-or-edit
 415
 416 # use the vi navigation keys (hjkl) besides cursor keys in menu selection
 417   bindkey -M menuselect 'h' vi-backward-char                # left
 418   bindkey -M menuselect 'k' vi-up-line-or-history           # up
 419   bindkey -M menuselect 'l' vi-forward-char                 # right
 420   bindkey -M menuselect 'j' vi-down-line-or-history         # bottom
 421 # }}}
 422
 423 # power completion - abbreviation expansion {{{
 424 # power completion / abbreviation expansion / buffer expansion
 425 # see http://zshwiki.org/home/examples/zleiab for details
 426 # less risky than the global aliases but powerful as well
 427 # just type the abbreviation key and afterwards ',.' to expand it
 428 declare -A abk
 429 setopt extendedglob
 430 setopt interactivecomments
 431 abk=(
 432 # key  # value                (#d additional doc string)
 433 #A# start
 434     '...' '../..'
 435     '....' '../../..'
 436     'BG' '& exit'
 437     'C' '| wc -l'
 438     'G' '|& grep --color=auto'
 439     'H' '| head'
 440     'Hl' ' --help |& less -r'      #d (Display help in pager)
 441     'L' '| less'
 442     'LL' '|& less -r'
 443     'M' '| most'
 444     'N' '&>/dev/null'              #d (No Output)
 445     'R' '| tr A-z N-za-m'          #d (ROT13)
 446     'SL' '| sort | less'
 447     'S' '| sort -u'
 448     'T' '| tail'
 449     'V' '|& vim -'
 450 #A# end
 451     'hide' "echo -en '\033]50;nil2\007'"
 452     'tiny' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
 453     'small' 'echo -en "\033]50;6x10\007"'
 454     'medium' 'echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
 455     'default' 'echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
 456     'large' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
 457     'huge' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
 458     'smartfont' 'echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
 459     'semifont' 'echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
 460     'da' 'du -sch'
 461     'j' 'jobs -l'
 462     'u' 'translate -i'
 463     'co' "./configure && make && sudo make install"
 464     'CH' "./configure --help"
 465     'conkeror' 'firefox -chrome chrome://conkeror/content'
 466     'dir' 'ls -lSrah'
 467     'lad' $'ls -d .*(/)\n# only show dot-directories'
 468     'lsa' $'ls -a .*(.)\n# only show dot-files'
 469     'lss' $'ls -l *(s,S,t)\n# only files with setgid/setuid/sticky flag'
 470     'lsl' $'ls -l *(@[1,10])\n# only symlinks'
 471     'lsx' $'ls -l *(*[1,10])\n# only executables'
 472     'lsw' $'ls -ld *(R,W,X.^ND/)\n# world-{readable,writable,executable} files'
 473     'lsbig' $'ls -flh *(.OL[1,10])\n# display the biggest files'
 474     'lsd' $'ls -d *(/)\n# only show directories'
 475     'lse' $'ls -d *(/^F)\n# only show empty directories'
 476     'lsnew' $'ls -rl *(D.om[1,10])\n# display the newest files'
 477     'lsold' $'ls -rtlh *(D.om[-11,-1])\n # display the oldest files'
 478     'lssmall' $'ls -Srl *(.oL[1,10])\n# display the smallest files'
 479     'rw-' 'chmod 600'
 480     '600' 'chmod u+rw-x,g-rwx,o-rwx'
 481     'rwx' 'chmod u+rwx'
 482     '700' 'chmod u+rwx,g-rwx,o-rwx'
 483     'r--' 'chmod u+r-wx,g-rwx,o-rwx'
 484     '644' $'chmod u+rw-x,g+r-wx,o+r-wx\n # 4=r,2=w,1=x'
 485     '755' 'chmod u+rwx,g+r-w+x,o+r-w+x'
 486     'md' 'mkdir -p '
 487     'cmplayer' 'mplayer -vo -fs -zoom fbdev'
 488     'fbmplayer' 'mplayer -vo -fs -zoom fbdev'
 489     'fblinks' 'links2 -driver fb'
 490     'insecssh' 'ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 491     'insecscp' 'scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 492     'fori' 'for i ({..}) { }'
 493     'cx' 'chmod +x'
 494     'e'  'print -l'
 495     'se' 'setopt interactivecomments'
 496     'va' 'valac --vapidir=../vapi/ --pkg=gtk+-2.0 gtktest.vala'
 497     'fb2' '=mplayer -vo fbdev -fs -zoom 1>/dev/null -xy 2'
 498     'fb3' '=mplayer -vo fbdev -fs  -zoom 1>/dev/null -xy 3'
 499     'ci' 'centericq'
 500     'D'  'export DISPLAY=:0.0'
 501     'mp' 'mplayer -vo xv -fs -zoom'
 502 )
 503
 504 globalias() {
 505     local MATCH
 506     matched_chars='[.-|_a-zA-Z0-9]#'
 507     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 508     LBUFFER+=${abk[$MATCH]:-$MATCH}
 509 }
 510
 511 zle -N globalias
 512 bindkey ",." globalias
 513 # }}}
 514
 515 # {{{ autoloading
 516 autoload -U zmv    # who needs mmv or rename?
 517 autoload history-search-end
 518
 519 # we don't want to quote/espace URLs on our own...
 520 # if autoload -U url-quote-magic ; then
 521 #    zle -N self-insert url-quote-magic
 522 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 523 # else
 524 #    print 'Notice: no url-quote-magic available :('
 525 # fi
 526 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 527
 528 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 529 alias run-help >&/dev/null && unalias run-help
 530 autoload run-help # use via 'esc-h'
 531
 532 # completion system
 533 if autoload -U compinit && compinit 2>/dev/null ; then
 534     compinit 2>/dev/null || print 'Notice: no compinit available :('
 535 else
 536     print 'Notice: no compinit available :('
 537     function zstyle { }
 538     function compdef { }
 539 fi
 540
 541 is4 && autoload -U zed # use ZLE editor to edit a file or function
 542
 543 is4 && \
 544 for mod in complist deltochar mathfunc ; do
 545     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 546 done
 547
 548 # autoload zsh modules when they are referenced
 549 if is4 ; then
 550     tmpargs=(
 551         a   stat
 552         a   zpty
 553         ap  zprof
 554         ap  mapfile
 555     )
 556
 557     while (( ${#tmpargs} > 0 )) ; do
 558         zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
 559         shift 2 tmpargs
 560     done
 561     unset tmpargs
 562 fi
 563
 564 if is4 && autoload -U insert-files && zle -N insert-files ; then
 565     #k# Insert files
 566     bindkey "^Xf" insert-files # C-x-f
 567 fi
 568
 569 bindkey ' '   magic-space    # also do history expansion on space
 570 #k# Trigger menu-complete
 571 bindkey '\ei' menu-complete  # menu completion via esc-i
 572
 573 # press esc-e for editing command line in $EDITOR or $VISUAL
 574 if is4 && autoload -U edit-command-line && zle -N edit-command-line ; then
 575     #k# Edit the current line in \kbd{\$EDITOR}
 576     bindkey '\ee' edit-command-line
 577 fi
 578
 579 #k# menu selection: pick item but stay in the menu
 580 is4 && bindkey -M menuselect '\e^M' accept-and-menu-complete
 581
 582 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 583 _bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
 584 zle -N _bkdate
 585
 586 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 587 bindkey '^Ed' _bkdate
 588
 589 # press esc-m for inserting last typed word again (thanks to caphuso!)
 590 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 591 zle -N insert-last-typed-word;
 592
 593 #k# Insert last typed word
 594 bindkey "\em" insert-last-typed-word
 595
 596 # set command prediction from history, see 'man 1 zshcontrib'
 597 #  is4 && autoload -U predict-on && \
 598 #  zle -N predict-on         && \
 599 #  zle -N predict-off        && \
 600 #  bindkey "^X^Z" predict-on && \
 601 #  bindkey "^Z" predict-off
 602
 603 #k# Shortcut for \kbd{fg<enter>}
 604 bindkey -s '^z' "fg\n"
 605
 606 # press ctrl-q to quote line:
 607 #  mquote () {
 608 #        zle beginning-of-line
 609 #        zle forward-word
 610 #        # RBUFFER="'$RBUFFER'"
 611 #        RBUFFER=${(q)RBUFFER}
 612 #        zle end-of-line
 613 #  }
 614 #  zle -N mquote && bindkey '^q' mquote
 615
 616 # run command line as user root via sudo:
 617 sudo-command-line() {
 618     [[ -z $BUFFER ]] && zle up-history
 619     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
 620 }
 621 zle -N sudo-command-line
 622
 623 #k# Put the current command line into a \kbd{sudo} call
 624 bindkey "^Os" sudo-command-line
 625
 626 ### jump behind the first word on the cmdline.
 627 ### useful to add options.
 628 function jump_after_first_word() {
 629     local words
 630     words=(${(z)BUFFER})
 631
 632     if (( ${#words} <= 1 )) ; then
 633         CURSOR=${#BUFFER}
 634     else
 635         CURSOR=${#${words[1]}}
 636     fi
 637 }
 638 zle -N jump_after_first_word
 639
 640 bindkey '^x1' jump_after_first_word
 641
 642 # }}}
 643
 644 # {{{ set some important options
 645 # Please update these tags, if you change the umask settings below.
 646 #o# r_umask     002
 647 #o# r_umaskstr  rwxrwxr-x
 648 #o# umask       022
 649 #o# umaskstr    rwxr-xr-x
 650 (( EUID != 0 )) && umask 002 || umask 022
 651
 652 # history:
 653 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 654 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 655 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 656 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 657                             # list duplicates an older one, the older command is removed from the list
 658 setopt histignorespace      # remove command lines from the history list when
 659                             # the first character on the line is a space
 660 #  setopt histallowclobber    # add `|' to output redirections in the history
 661 #  setopt NO_clobber          # warning if file exists ('cat /dev/null > ~/.zshrc')
 662 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 663                             # and the command is the name of a directory, perform the cd command to that directory
 664 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 665                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 666                             # -> searches for word not in compressed files
 667                             # don't forget to quote '^', '~' and '#'!
 668 setopt notify               # report the status of backgrounds jobs immediately
 669 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 670                             # the entire command path is hashed first.
 671 setopt completeinword       # not just at the end
 672 # setopt nocheckjobs          # don't warn me about bg processes when exiting
 673 setopt nohup                # and don't kill them, either
 674 # setopt printexitvalue       # alert me if something failed
 675 # setopt dvorak               # with spelling correction, assume dvorak kb
 676 setopt auto_pushd           # make cd push the old directory onto the directory stack.
 677 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 678 setopt nobeep               # avoid "beep"ing
 679 setopt pushd_ignore_dups    # don't push the same dir twice.
 680
 681 MAILCHECK=30       # mailchecks
 682 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 683 watch=(notme root) # watch for everyone but me and root
 684
 685 # define word separators (for stuff like backward-word, forward-word, backward-kill-word,..)
 686 #  WORDCHARS='*?_-.[]~=/&;!#$%^(){}<>' # the default
 687 #  WORDCHARS=.
 688 #  WORDCHARS='*?_[]~=&;!#$%^(){}'
 689 #  WORDCHARS='${WORDCHARS:s@/@}'
 690
 691 # only slash should be considered as a word separator:
 692 slash-backward-kill-word() {
 693     local WORDCHARS="${WORDCHARS:s@/@}"
 694     # zle backward-word
 695     zle backward-kill-word
 696 }
 697 zle -N slash-backward-kill-word
 698
 699 #k# Kill everything in a word up to its last \kbd{/}
 700 bindkey '\ev' slash-backward-kill-word
 701
 702 # }}}
 703
 704 # {{{ history
 705
 706 ZSHDIR=$HOME/.zsh
 707
 708 #v#
 709 HISTFILE=$HOME/.zsh_history
 710 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
 711 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
 712
 713 # }}}
 714
 715 # dirstack handling {{{
 716
 717 DIRSTACKSIZE=20
 718 if [[ -f ~/.zdirs ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
 719     dirstack=( ${(f)"$(< ~/.zdirs)"} )
 720     # "cd -" won't work after login by just setting $OLDPWD, so
 721     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
 722 fi
 723
 724 chpwd() {
 725     builtin dirs -pl >! ~/.zdirs
 726 }
 727
 728 # }}}
 729
 730 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
 731 if [[ -n "$BATTERY" ]] ; then
 732     if check_com -c acpi ; then
 733         PERCENT="${(C)${(s| |)$(acpi 2>/dev/null)}[4]}"
 734         [[ -z "$PERCENT" ]] && PERCENT='acpi not present'
 735
 736         if [[ "${PERCENT%%%}" -lt 20 ]] ; then
 737             PERCENT="warning: ${PERCENT}%"
 738         fi
 739     fi
 740 fi
 741 # }}}
 742
 743 # display version control information on right side of prompt if $VCS is set {{{
 744 # based on Mike Hommey's http://web.glandium.org/blog/?p=170
 745 __vcs_dir() {
 746     local vcs base_dir sub_dir ref
 747
 748     sub_dir() {
 749       local sub_dir
 750       sub_dir=$(readlink -f "${PWD}")
 751       sub_dir=${sub_dir#$1}
 752       echo ${sub_dir#/}
 753     }
 754
 755     git_dir() {
 756       base_dir=$(git-rev-parse --show-cdup 2>/dev/null) || return 1
 757       base_dir=$(readlink -f "$base_dir/..")
 758       sub_dir=$(git-rev-parse --show-prefix)
 759       sub_dir=${sub_dir%/}
 760       ref=$(git-symbolic-ref -q HEAD || git-name-rev --name-only HEAD 2>/dev/null)
 761       ref=${ref#refs/heads/}
 762       vcs="git"
 763     }
 764
 765     svn_dir() {
 766       [[ -d ".svn" ]] || return 1
 767       base_dir="."
 768       while [[ -d "$base_dir/../.svn" ]]; do base_dir="$base_dir/.."; done
 769       base_dir=$(readlink -f "$base_dir")
 770       sub_dir=$(sub_dir "${base_dir}")
 771       ref=$(svn info "$base_dir" | awk '/^URL/ { sub(".*/","",$0); r=$0 } /^Revision/ { sub("[^0-9]*","",$0); print r":"$0 }')
 772       vcs="svn"
 773     }
 774
 775     svk_dir() {
 776         [[ -f ~/.svk/config ]] || return 1
 777         base_dir=$(awk '/: *$/ { sub(/^ */,"",$0); sub(/: *$/,"",$0); if (match("'${PWD}'", $0"(/|$)")) { print $0; d=1; } } /depotpath/ && d == 1 { sub(".*/","",$0); r=$0 } /revision/ && d == 1 { print r ":" $2; exit 1 }' ~/.svk/config) && return 1
 778         ref=${base_dir##*
 779   }
 780         base_dir=${base_dir%%
 781   *}
 782         sub_dir=$(sub_dir "${base_dir}")
 783         vcs="svk"
 784     }
 785
 786     hg_dir() {
 787         base_dir="."
 788         while [[ ! -d "$base_dir/.hg" ]]; do
 789             base_dir="$base_dir/.."
 790             [[ $(readlink -f "${base_dir}") = "/" ]] && return 1
 791         done
 792         base_dir=$(readlink -f "$base_dir")
 793         sub_dir=$(sub_dir "${base_dir}")
 794         ref=$(< "${base_dir}/.hg/branch")
 795         vcs="hg"
 796     }
 797
 798     hg_dir  ||
 799     git_dir ||
 800     svn_dir ||
 801     svk_dir # ||
 802   #  base_dir="$PWD"
 803   #  echo "${vcs:+($vcs)}${base_dir/$HOME/~}${vcs:+[$ref]${sub_dir}}"
 804     echo "${vcs:+($vcs)}${base_dir}${vcs:+[$ref]${sub_dir}}"
 805 }
 806 # }}}
 807
 808 # {{{ set prompt
 809 if autoload promptinit && promptinit 2>/dev/null ; then
 810     promptinit # people should be able to use their favourite prompt
 811 else
 812     print 'Notice: no promptinit available :('
 813 fi
 814
 815
 816 # precmd() => a function which is executed just before each prompt
 817 # use 'NOPRECMD=1' to disable the precmd + preexec commands
 818
 819 # precmd () { setopt promptsubst; [[ -o interactive ]] && jobs -l;
 820
 821 # make sure to use right prompt only when not running a command
 822 is41 && setopt transient_rprompt
 823
 824 is4 && [[ -z $NOPRECMD ]] && precmd () {
 825     [[ -n $NOPRECMD ]] && return 0
 826     # allow manual overwriting of RPROMPT
 827     if [[ -n $RPROMPT ]] ; then
 828         [[ $TERM == screen* ]] && echo -n $'\ekzsh\e\\'
 829         # return 0
 830     fi
 831     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
 832     if [[ -z $DONTSETRPROMPT ]] ; then
 833         if [[ -n $BATTERY ]] ; then
 834             RPROMPT="%(?..:()% ${PERCENT}${SCREENTITLE}"
 835             # RPROMPT="${PERCENT}${SCREENTITLE}"
 836         elif [[ -n $VCS ]] ; then
 837             RPROMPT="%(?..:()% $(__vcs_dir)${SCREENTITLE}"
 838         else
 839             RPROMPT="%(?..:()% ${SCREENTITLE}"
 840             # RPROMPT="${SCREENTITLE}"
 841         fi
 842     fi
 843     # adjust title of xterm
 844     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
 845     case $TERM in
 846         (xterm*|rxvt)
 847             print -Pn "\e]0;%n@%m: %~\a"
 848             ;;
 849     esac
 850 }
 851
 852 # chpwd () => a function which is executed whenever the directory is changed
 853
 854 # preexec() => a function running before every command
 855 is4 && [[ -z $NOPRECMD ]] && \
 856 preexec () {
 857     [[ -n $NOPRECMD ]] && return 0
 858 # set hostname if not running on host with name 'grml'
 859     if [[ "$HOSTNAME" != $(hostname) ]] ; then
 860        NAME="@$HOSTNAME"
 861     fi
 862 # get the name of the program currently running and hostname of local machine
 863 # set screen window title if running in a screen
 864     if [[ "$TERM" == screen* ]] ; then
 865         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
 866         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
 867         echo -ne "\ek$CMD\e\\"
 868     fi
 869 # set the screen title to "zsh" when sitting at the command prompt:
 870     if [[ "$TERM" == screen* ]] ; then
 871         SCREENTITLE=$'%{\ekzsh\e\\%}'
 872     else
 873         SCREENTITLE=''
 874     fi
 875 # adjust title of xterm
 876     case $TERM in
 877         (xterm*|rxvt)
 878             print -Pn "\e]0;%n@%m: $1\a"
 879             ;;
 880     esac
 881 }
 882
 883 # set colors
 884 if autoload colors && colors 2>/dev/null ; then
 885     BLUE="%{${fg[blue]}%}"
 886     RED="%{${fg_bold[red]}%}"
 887     GREEN="%{${fg[green]}%}"
 888     CYAN="%{${fg[cyan]}%}"
 889     WHITE="%{${fg[white]}%}"
 890     NO_COLOUR="%{${reset_color}%}"
 891 else
 892     BLUE=$'%{\e[1;34m%}'
 893     RED=$'%{\e[1;31m%}'
 894     GREEN=$'%{\e[1;32m%}'
 895     CYAN=$'%{\e[1;36m%}'
 896     WHITE=$'%{\e[1;37m%}'
 897     NO_COLOUR=$'%{\e[0m%}'
 898 fi
 899
 900 EXITCODE="%(?..%?%1v )"
 901 PS2='`%_> '       # secondary prompt, printed when the shell needs more information to complete a command.
 902 PS3='?# '         # selection prompt used within a select loop.
 903 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
 904
 905 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
 906 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
 907     debian_chroot=$(cat /etc/debian_chroot)
 908 fi
 909
 910 # don't use colors on dumb terminals (like emacs):
 911 if [[ "$TERM" == dumb ]] ; then
 912     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< %# "
 913 else
 914     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
 915     # set variable identifying the chroot you work in (used in the prompt below)
 916     if [[ -n $GRMLPROMPT ]] ; then
 917         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
 918 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# "
 919     else
 920         if (( EUID != 0 )); then
 921             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# " # primary prompt string
 922         else
 923             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# " # primary prompt string
 924         fi
 925     fi
 926 fi
 927
 928 # if we are inside a grml-chroot set a specific prompt theme
 929 if [[ -n "$GRML_CHROOT" ]] ; then
 930     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
 931 fi
 932 # }}}
 933
 934 # {{{ 'hash' some often used directories
 935 #d# start
 936 hash -d deb=/var/cache/apt/archives
 937 hash -d doc=/usr/share/doc
 938 hash -d linux=/lib/modules/$(command uname -r)/build/
 939 hash -d log=/var/log
 940 hash -d slog=/var/log/syslog
 941 hash -d src=/usr/src
 942 hash -d templ=/usr/share/doc/grml-templates
 943 hash -d tt=/usr/share/doc/texttools-doc
 944 hash -d www=/var/www
 945 #d# end
 946 # }}}
 947
 948 # {{{ some aliases
 949 if [[ $UID -eq 0 ]] ; then
 950     [[ -r /etc/grml/screenrc ]] && alias screen='/usr/bin/screen -c /etc/grml/screenrc'
 951 elif [[ -r $HOME/.screenrc ]] ; then
 952     alias screen="/usr/bin/screen -c $HOME/.screenrc"
 953 else
 954     [[ -r /etc/grml/screenrc_grml ]] && alias screen='/usr/bin/screen -c /etc/grml/screenrc_grml'
 955 fi
 956
 957 # do we have GNU ls with color-support?
 958 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
 959     #a1# execute \kbd{@a@}:\quad ls with colors
 960     alias ls='ls -b -CF --color=auto'
 961     #a1# execute \kbd{@a@}:\quad list all files, with colors
 962     alias la='ls -la --color=auto'
 963     #a1# long colored list, without dotfiles (@a@)
 964     alias ll='ls -l --color=auto'
 965     #a1# long colored list, human readable sizes (@a@)
 966     alias lh='ls -hAl --color=auto'
 967     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
 968     alias l='ls -lF --color=auto'
 969 else
 970     alias ls='ls -b -CF'
 971     alias la='ls -la'
 972     alias ll='ls -l'
 973     alias lh='ls -hAl'
 974     alias l='ls -lF'
 975 fi
 976
 977 alias mdstat='cat /proc/mdstat'
 978 alias ...='cd ../../'
 979
 980 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
 981 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
 982     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
 983 fi
 984
 985 alias cp='nocorrect cp'         # no spelling correction on cp
 986 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
 987 alias mv='nocorrect mv'         # no spelling correction on mv
 988 alias rm='nocorrect rm'         # no spelling correction on rm
 989
 990 #a1# Execute \kbd{rmdir}
 991 alias rd='rmdir'
 992 #a1# Execute \kbd{rmdir}
 993 alias md='mkdir'
 994
 995 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
 996 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
 997 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
 998
 999 # make sure it is not assigned yet
1000 [[ $(whence -w utf2iso &>/dev/null) == 'utf2iso: alias' ]] && unalias utf2iso
1001
1002 utf2iso() {
1003     if isutfenv ; then
1004         for ENV in $(env | command grep -i '.utf') ; do
1005             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1006         done
1007     fi
1008 }
1009
1010 # make sure it is not assigned yet
1011 [[ $(whence -w iso2utf &>/dev/null) == 'iso2utf: alias' ]] && unalias iso2utf
1012 iso2utf() {
1013     if ! isutfenv ; then
1014         for ENV in $(env | command grep -i '\.iso') ; do
1015             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1016         done
1017     fi
1018 }
1019
1020 # set up software synthesizer via speakup
1021 # TODO: make this a function?
1022 alias swspeak='
1023   aumix -w 90 -v 90 -p 90 -m 90
1024   if ! [[ -r /dev/softsynth ]] ; then
1025      flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
1026      return 1
1027   else
1028      setopt singlelinezle
1029      unsetopt prompt_cr
1030      export PS1="%m%# "
1031      nice -n -20 speechd-up
1032      sleep 2
1033      flite -o play -t "Finished setting up software synthesizer"
1034   fi
1035 '
1036
1037 # I like clean prompt, so provide simple way to get that
1038 check_com 0 || alias 0='return 0'
1039
1040 # for really lazy people like mika:
1041 check_com S &>/dev/null || alias S='screen'
1042 check_com s &>/dev/null || alias s='ssh'
1043
1044 # get top 10 shell commands:
1045 alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
1046
1047 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
1048 if check_com -c truecrypt ; then
1049     if isutfenv ; then
1050         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
1051     else
1052         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
1053     fi
1054 fi
1055
1056 #f1# Hints for the use of zsh on grml
1057 zsh-help() {
1058     print "$bg[white]$fg[black]
1059 zsh-help - hints for use of zsh on grml
1060 =======================================$reset_color"
1061
1062     print '
1063 Main configuration of zsh happens in /etc/zsh/zshrc (global)
1064 and /etc/skel/.zshrc which is copied to $HOME/.zshrc once.
1065 The files are part of the package grml-etc-core, if you want to
1066 use them on a non-grml-system just get the tar.gz from
1067 http://deb.grml.org/ or get the files from the mercurial
1068 repository:
1069
1070   http://hg.grml.org/grml-etc-core/raw-file/tip/etc/skel/.zshrc
1071   http://hg.grml.org/grml-etc-core/raw-file/tip/etc/zsh/zshrc
1072
1073 If you want to stay in sync with zsh configuration of grml
1074 run '\''ln -sf /etc/skel/.zshrc $HOME/.zshrc'\'' and configure
1075 your own stuff in $HOME/.zshrc.local. System wide configuration
1076 without touching configuration files of grml can take place
1077 in /etc/zsh/zshrc.local.
1078
1079 If you want to use the configuration of user grml also when
1080 running as user root just run '\''zshskel'\'' which will source
1081 the file /etc/skel/.zshrc.
1082
1083 For information regarding zsh start at http://grml.org/zsh/
1084
1085 Take a look at grml'\''s zsh refcard:
1086 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1087
1088 Check out the main zsh refcard:
1089 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1090
1091 And of course visit the zsh-lovers:
1092 % man zsh-lovers
1093
1094 You can adjust some options through environment variables when
1095 invoking zsh without having to edit configuration files.
1096 Basically meant for bash users who are not used to the power of
1097 the zsh yet. :)
1098
1099   "NOCOR=1    zsh" => deactivate automatic correction
1100   "NOMENU=1   zsh" => do not use menu completion (note: use strg-d for completion instead!)
1101   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1102   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt'
1103
1104     print "
1105 $bg[white]$fg[black]
1106 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1107 Enjoy your grml system with the zsh!$reset_color"
1108 }
1109
1110 # debian stuff
1111 if [[ -r /etc/debian_version ]] ; then
1112     #a3# Execute \kbd{apt-cache search}
1113     alias acs='apt-cache search'
1114     #a3# Execute \kbd{apt-cache show}
1115     alias acsh='apt-cache show'
1116     #a3# Execute \kbd{apt-cache policy}
1117     alias acp='apt-cache policy'
1118     #a3# Execute \kbd{apt-get dist-upgrade}
1119     salias adg="apt-get dist-upgrade"
1120     #a3# Execute \kbd{apt-get install}
1121     salias agi="apt-get install"
1122     #a3# Execute \kbd{aptitude install}
1123     salias ati="aptitude install"
1124     #a3# Execute \kbd{apt-get upgrade}
1125     salias ag="apt-get upgrade"
1126     #a3# Execute \kbd{apt-get update}
1127     salias au="apt-get update"
1128     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1129     salias -a up="aptitude update ; aptitude safe-upgrade"
1130     #a3# Execute \kbd{dpkg-buildpackage}
1131     alias dbp='dpkg-buildpackage'
1132     #a3# Execute \kbd{grep-excuses}
1133     alias ge='grep-excuses'
1134
1135     # debian upgrade
1136     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
1137     upgrade() {
1138         if [[ -z "$1" ]] ; then
1139             $SUDO apt-get update
1140             $SUDO apt-get -u upgrade
1141         else
1142             ssh $1 $SUDO apt-get update
1143             # ask before the upgrade
1144             local dummy
1145             ssh $1 $SUDO apt-get --no-act upgrade
1146             echo -n 'Process the upgrade?'
1147             read -q dummy
1148             if [[ $dummy == "y" ]] ; then
1149                 ssh $1 $SUDO apt-get -u upgrade --yes
1150             fi
1151         fi
1152     }
1153
1154     isgrmlcd && alias su="sudo -s"          # get a root shell
1155     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1156     alias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1157     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1158     alias tlog="tail -f /var/log/syslog"    # follow the syslog
1159     #a1# (Re)-source \kbd{/etc/skel/.zshrc}
1160     alias zshskel="source /etc/skel/.zshrc" # source skeleton zshrc
1161 fi
1162
1163 # sort installed Debian-packages by size
1164 if check_com -c grep-status ; then
1165     #a3# List installed Debian-packages sorted by size
1166     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
1167 fi
1168
1169 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1170 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord ; then
1171     if check_com -c wodim ; then
1172         alias cdrecord="echo 'cdrecord is not provided under its original name by Debian anymore.
1173 See #377109 in the BTS of Debian for more details.
1174
1175 Please use the wodim binary instead' ; return 1"
1176     fi
1177 fi
1178
1179 # get_tw_cli has been renamed into get_3ware
1180 if check_com -c get_3ware ; then
1181     get_tw_cli() {
1182         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
1183         get_3ware
1184     }
1185 fi
1186
1187 # I hate lacking backward compatibility, so provide an alternative therefore
1188 if ! check_com -c apache2-ssl-certificate ; then
1189
1190     apache2-ssl-certificate() {
1191
1192     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
1193     print 'You might want to take a look at Debian the package ssl-cert as well.'
1194     print 'To generate a certificate for use with apache2 follow the instructions:'
1195
1196     echo '
1197
1198 export RANDFILE=/dev/random
1199 mkdir /etc/apache2/ssl/
1200 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
1201 chmod 600 /etc/apache2/ssl/apache.pem
1202
1203 Run "grml-tips ssl-certificate" if you need further instructions.
1204 '
1205     }
1206 fi
1207 # }}}
1208
1209 # {{{ Use hard limits, except for a smaller stack and no core dumps
1210 unlimit
1211 limit stack 8192
1212 isgrmlcd && limit core 0 # important for a live-cd-system
1213 limit -s
1214 # }}}
1215
1216 # {{{ completion stuff
1217
1218 # called later (via is4 && grmlcomp)
1219 # notice: use 'zstyle' for getting current settings
1220 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
1221 # TODO: make grmlcomp() readable. :-)
1222 grmlcomp() {
1223 ## completion system
1224 ## no initial indention in grmlcomp(), the lines are long enough already.
1225 zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )' # allow one error for every three characters typed in approximate completer
1226 zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)' # don't complete backup files as executables
1227 zstyle ':completion:*:correct:*'       insert-unambiguous true             # start menu completion only if it could find no unambiguous initial string
1228 zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}' #
1229 zstyle ':completion:*:correct:*'       original true                       #
1230 zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}      # activate color-completion(!)
1231 zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'  # format on completion
1232 zstyle ':completion:*:*:cd:*:directory-stack' menu yes select              # complete 'cd -<tab>' with menu
1233 zstyle ':completion:*:expand:*'        tag-order all-expansions            # insert all expansions for expand completer
1234 zstyle ':completion:*:history-words'   list false                          #
1235 zstyle ':completion:*:history-words'   menu yes                            # activate menu
1236 zstyle ':completion:*:history-words'   remove-all-dups yes                 # ignore duplicate entries
1237 zstyle ':completion:*:history-words'   stop yes                            #
1238 zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'        # match uppercase from lowercase
1239 zstyle ':completion:*:matches'         group 'yes'                         # separate matches into groups
1240 zstyle ':completion:*'                 group-name ''
1241 if [[ -z "$NOMENU" ]] ; then
1242     zstyle ':completion:*'               menu select=5                     # if there are more than 5 options allow selecting from a menu
1243 else
1244     setopt no_auto_menu # don't use any menus at all
1245 fi
1246 zstyle ':completion:*:messages'        format '%d'                         #
1247 zstyle ':completion:*:options'         auto-description '%d'               #
1248 zstyle ':completion:*:options'         description 'yes'                   # describe options in full
1249 zstyle ':completion:*:processes'       command 'ps -au$USER'               # on processes completion complete all user processes
1250 zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters        # offer indexes before parameters in subscripts
1251 zstyle ':completion:*'                 verbose true                        # provide verbose completion information
1252
1253 # recent (as of Dec 2007) zsh versions are able to provide descriptions
1254 # for commands (read: 1st word in the line) that it will list for the user
1255 # to choose from. The following disables that, because it's not exactly fast.
1256 zstyle ':completion:*:-command-:*:'    verbose false
1257
1258 zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d' # set format for warnings
1259 zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'       # define files to ignore for zcompile
1260 zstyle ':completion:correct:'          prompt 'correct to: %e'             #
1261 zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'    # Ignore completion functions for commands you don't have:
1262
1263 # complete manual by their section
1264 zstyle ':completion:*:manuals'    separate-sections true
1265 zstyle ':completion:*:manuals.*'  insert-sections   true
1266 zstyle ':completion:*:man:*'      menu yes select
1267
1268 ## correction
1269 # run rehash on completion so new installed program are found automatically:
1270 _force_rehash() {
1271     (( CURRENT == 1 )) && rehash
1272     return 1 # Because we didn't really complete anything
1273 }
1274 # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1275 if [[ -n "$NOCOR" ]] ; then
1276     zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1277     setopt nocorrect # do not try to correct the spelling if possible
1278 else
1279 #    zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _ignored _correct _approximate _files
1280     setopt correct  # try to correct the spelling if possible
1281     zstyle -e ':completion:*' completer '
1282         if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1283             _last_try="$HISTNO$BUFFER$CURSOR"
1284             reply=(_complete _match _ignored _prefix _files)
1285         else
1286             if [[ $words[1] == (rm|mv) ]] ; then
1287                 reply=(_complete _files)
1288             else
1289                 reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1290             fi
1291         fi'
1292 fi
1293 # zstyle ':completion:*' completer _complete _correct _approximate
1294 # zstyle ':completion:*' expand prefix suffix
1295
1296 # automatic rehash? Credits go to Frank Terbeck
1297 # my_accept() {
1298 #   local buf
1299 #   [[ -z ${BUFFER} ]] && zle accept-line && return
1300 #   buf=( ${(z)BUFFER}  )
1301 #   [[ -z ${commands[${buf[1]}]} ]] && rehash
1302 #   zle accept-line
1303 # }
1304 # zle -N my_accept
1305 # bindkey "^M" my_accept
1306
1307 # command for process lists, the local web server details and host completion
1308 zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1309
1310 # caching
1311 [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1312                           zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1313
1314 # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
1315 if is42 ; then
1316     [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1317     [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1318 else
1319     _ssh_hosts=()
1320     _etc_hosts=()
1321 fi
1322 hosts=(
1323     $(hostname)
1324     "$_ssh_hosts[@]"
1325     "$_etc_hosts[@]"
1326     grml.org
1327     localhost
1328 )
1329 zstyle ':completion:*:hosts' hosts $hosts
1330 #  zstyle '*' hosts $hosts
1331
1332 # specify your logins:
1333 # my_accounts=(
1334 #  {grml,grml1}@foo.invalid
1335 #  grml-devel@bar.invalid
1336 # )
1337 # other_accounts=(
1338 #  {fred,root}@foo.invalid
1339 #  vera@bar.invalid
1340 # )
1341 # zstyle ':completion:*:my-accounts' users-hosts $my_accounts
1342 # zstyle ':completion:*:other-accounts' users-hosts $other_accounts
1343
1344 # specify specific port/service settings:
1345 #  telnet_users_hosts_ports=(
1346 #    user1@host1:
1347 #    user2@host2:
1348 #    @mail-server:{smtp,pop3}
1349 #    @news-server:nntp
1350 #    @proxy-server:8000
1351 #  )
1352 # zstyle ':completion:*:*:telnet:*' users-hosts-ports $telnet_users_hosts_ports
1353
1354 # use generic completion system for programs not yet defined:
1355 compdef _gnu_generic tail head feh cp mv df stow uname ipacsum fetchipac
1356
1357 # see upgrade function in this file
1358 compdef _hosts upgrade
1359 }
1360 # }}}
1361
1362 # {{{ grmlstuff
1363 grmlstuff() {
1364 # people should use 'grml-x'!
1365     startx() {
1366         if [[ -e /etc/X11/xorg.conf ]] ; then
1367             [[ -x /usr/bin/startx ]] && /usr/bin/startx "$@" || /usr/X11R6/bin/startx "$@"
1368         else
1369             echo "Please use the script \"grml-x\" for starting the X Window System
1370 because there does not exist /etc/X11/xorg.conf yet.
1371 If you want to use startx anyway please call \"/usr/bin/startx\"."
1372             return -1
1373         fi
1374     }
1375
1376     xinit() {
1377         if [[ -e /etc/X11/xorg.conf ]] ; then
1378             [[ -x /usr/bin/xinit ]] && /usr/bin/xinit || /usr/X11R6/bin/xinit
1379         else
1380             echo "Please use the script \"grml-x\" for starting the X Window System.
1381 because there does not exist /etc/X11/xorg.conf yet.
1382 If you want to use xinit anyway please call \"/usr/bin/xinit\"."
1383             return -1
1384         fi
1385     }
1386
1387     if check_com -c 915resolution ; then
1388         alias 855resolution='echo -e "Please use 915resolution as resolution modify tool for Intel graphic chipset."; return -1'
1389     fi
1390
1391     #a1# Output version of running grml
1392     alias grml-version='cat /etc/grml_version'
1393
1394     if check_com -c rebuildfstab ; then
1395         #a1# Rebuild /etc/fstab
1396         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1397     fi
1398
1399     if check_com -c grml-debootstrap ; then
1400         alias debian2hd='print "Installing debian to harddisk is possible via using grml-debootstrap." ; return 1'
1401     fi
1402 }
1403 # }}}
1404
1405 # {{{ now run the functions
1406 isgrml && checkhome
1407 is4    && isgrml    && grmlstuff
1408 is4    && grmlcomp
1409 # }}}
1410
1411 # {{{ keephack
1412 is4 && xsource "/etc/zsh/keephack"
1413 # }}}
1414
1415 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
1416 # You use it as follows:
1417 # $ NTREF=/reference/file
1418 # $ ls -l *(e:nt:)
1419 # This lists all the files in the current directory newer than the reference file.
1420 # You can also specify the reference file inline; note quotes:
1421 # $ ls -l *(e:'nt ~/.zshenv':)
1422 is4 && nt() {
1423     if [[ -n $1 ]] ; then
1424         local NTREF=${~1}
1425     fi
1426     [[ $REPLY -nt $NTREF ]]
1427 }
1428 # }}}
1429
1430 # shell functions {{{
1431
1432 #f1# Provide csh compatibility
1433 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
1434
1435 #f1# Reload an autoloadable function
1436 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1437
1438 #f1# Reload zsh setup
1439 reload() {
1440     if [[ "$#*" -eq 0 ]] ; then
1441         [[ -r ~/.zshrc ]] && . ~/.zshrc
1442     else
1443         local fn
1444         for fn in "$@"; do
1445             unfunction $fn
1446             autoload -U $fn
1447         done
1448     fi
1449 }
1450 compdef _functions reload freload
1451
1452 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1453 sll() {
1454     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1455     for i in "$@" ; do
1456         file=$i
1457         while [[ -h "$file" ]] ; do
1458             ls -l $file
1459             file=$(readlink "$file")
1460         done
1461     done
1462 }
1463
1464 # fast manual access
1465 if check_com qma ; then
1466     #f1# View the zsh manual
1467     manzsh()  { qma zshall "$1" }
1468     compdef _man qma
1469 else
1470     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
1471     # manzsh()  { /usr/bin/man zshall |  most +/"$1" ; }
1472     # [[ -f ~/.terminfo/m/mostlike ]] && MYLESS='LESS=C TERMINFO=~/.terminfo TERM=mostlike less' || MYLESS='less'
1473     # manzsh()  { man zshall | $MYLESS -p $1 ; }
1474 fi
1475
1476 if check_com -c most ; then
1477     #f1# View Debian's changelog of a given package
1478     dchange() {
1479         if [[ -r /usr/share/doc/${1}/changelog.Debian.gz ]] ; then
1480             most /usr/share/doc/${1}/changelog.Debian.gz
1481         elif [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
1482             most /usr/share/doc/${1}/changelog.gz
1483         else
1484             if check_com -c aptitude ; then
1485                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1486                 if isgrml ; then
1487                     aptitude -t unstable changelog ${1}
1488                 else
1489                     aptitude changelog ${1}
1490                 fi
1491             else
1492                 echo "No changelog for package $1 found, sorry."
1493                 return 1
1494             fi
1495         fi
1496     }
1497     _dchange() { _files -W /usr/share/doc -/ }
1498     compdef _dchange dchange
1499
1500     #f1# View Debian's NEWS of a given package
1501     dnews() {
1502         if [[ -r /usr/share/doc/${1}/NEWS.Debian.gz ]] ; then
1503             most /usr/share/doc/${1}/NEWS.Debian.gz
1504         else
1505             if [[ -r /usr/share/doc/${1}/NEWS.gz ]] ; then
1506                 most /usr/share/doc/${1}/NEWS.gz
1507             else
1508                 echo "No NEWS file for package $1 found, sorry."
1509                 return 1
1510             fi
1511         fi
1512     }
1513     _dnews() { _files -W /usr/share/doc -/ }
1514     compdef _dnews dnews
1515
1516     #f1# View upstream's changelog of a given package
1517     uchange() {
1518         if [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
1519             most /usr/share/doc/${1}/changelog.gz
1520         else
1521             echo "No changelog for package $1 found, sorry."
1522             return 1
1523         fi
1524     }
1525     _uchange() { _files -W /usr/share/doc -/ }
1526     compdef _uchange uchange
1527 fi
1528
1529 # zsh profiling
1530 profile() {
1531     ZSH_PROFILE_RC=1 $SHELL "$@"
1532 }
1533
1534 #f1# Edit an alias via zle
1535 edalias() {
1536     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1537 }
1538 compdef _aliases edalias
1539
1540 #f1# Edit a function via zle
1541 edfunc() {
1542     [[ -z "$1" ]] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
1543 }
1544 compdef _functions edfunc
1545
1546 # use it e.g. via 'Restart apache2'
1547 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
1548 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
1549 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
1550 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
1551 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
1552 if [[ -d /etc/init.d ]] ; then
1553     for i in Start Restart Stop Force-Reload Reload ; do
1554         eval "$i() { $SUDO /etc/init.d/\$1 ${i:l} \$2 ; }"
1555     done
1556 fi
1557
1558 #f1# Provides useful information on globbing
1559 H-Glob() {
1560     echo -e "
1561     /      directories
1562     .      plain files
1563     @      symbolic links
1564     =      sockets
1565     p      named pipes (FIFOs)
1566     *      executable plain files (0100)
1567     %      device files (character or block special)
1568     %b     block special files
1569     %c     character special files
1570     r      owner-readable files (0400)
1571     w      owner-writable files (0200)
1572     x      owner-executable files (0100)
1573     A      group-readable files (0040)
1574     I      group-writable files (0020)
1575     E      group-executable files (0010)
1576     R      world-readable files (0004)
1577     W      world-writable files (0002)
1578     X      world-executable files (0001)
1579     s      setuid files (04000)
1580     S      setgid files (02000)
1581     t      files with the sticky bit (01000)
1582
1583   print *(m-1)          # Files modified up to a day ago
1584   print *(a1)           # Files accessed a day ago
1585   print *(@)            # Just symlinks
1586   print *(Lk+50)        # Files bigger than 50 kilobytes
1587   print *(Lk-50)        # Files smaller than 50 kilobytes
1588   print **/*.c          # All *.c files recursively starting in \$PWD
1589   print **/*.c~file.c   # Same as above, but excluding 'file.c'
1590   print (foo|bar).*     # Files starting with 'foo' or 'bar'
1591   print *~*.*           # All Files that do not contain a dot
1592   chmod 644 *(.^x)      # make all plain non-executable files publically readable
1593   print -l *(.c|.h)     # Lists *.c and *.h
1594   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
1595   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
1596 }
1597 alias help-zshglob=H-Glob
1598
1599 check_com -c qma && alias ?='qma zshall'
1600
1601 # grep for running process, like: 'any vim'
1602 any() {
1603     if [[ -z "$1" ]] ; then
1604         echo "any - grep for process(es) by keyword" >&2
1605         echo "Usage: any <keyword>" >&2 ; return 1
1606     else
1607         local STRING=$1
1608         local LENGTH=$(expr length $STRING)
1609         local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
1610         local REST=$(echo $(expr substr $STRING 2 $LENGTH))
1611         ps xauwww| grep "[$FIRSCHAR]$REST"
1612     fi
1613 }
1614
1615 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
1616 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
1617 [[ -r /proc/1/maps ]] && \
1618 deswap() {
1619     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
1620     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
1621     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
1622 }
1623
1624 # print hex value of a number
1625 hex() {
1626     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
1627 }
1628
1629 # calculate (or eval at all ;-)) with perl => p[erl-]eval
1630 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
1631 peval() {
1632     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
1633     perl -e "print eval($CALC),\"\n\";"
1634 }
1635 functions peval &>/dev/null && alias calc=peval
1636
1637 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
1638 # certain circumstances, so work around it, no matter which environment we have
1639 brltty() {
1640     if [[ -z "$DISPLAY" ]] ; then
1641         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
1642         command brltty "$@"
1643     else
1644         command brltty "$@"
1645     fi
1646 }
1647
1648 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
1649 aoeu() {
1650     echo -n 'Switching to us keyboard layout: '
1651     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
1652     echo 'Done'
1653 }
1654 asdf() {
1655     echo -n 'Switching to dvorak keyboard layout: '
1656     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
1657     echo 'Done'
1658 }
1659 # just press 'asdf' key to toggle from neon layout to us keyboard layout
1660 uiae() {
1661     echo -n 'Switching to us keyboard layout: '
1662     setxkbmap us && echo 'Done' || echo 'Failed'
1663 }
1664
1665 # set up an ipv6 tunnel
1666 ipv6-tunnel() {
1667     case $1 in
1668         start)
1669             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1670                 print 'ipv6 tunnel already set up, nothing to be done.'
1671                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
1672             else
1673                 [[ -n "$PUBLIC_IP" ]] || \
1674                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
1675                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
1676
1677                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
1678                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
1679                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
1680                 ifconfig sit0 tunnel ::192.88.99.1 up
1681                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
1682             fi
1683             ;;
1684         status)
1685             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1686                 print 'ipv6 tunnel available' ; return 0
1687             else
1688                 print 'ipv6 tunnel not available' ; return 1
1689             fi
1690             ;;
1691         stop)
1692             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1693                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
1694                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
1695             else
1696                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
1697             fi
1698             ;;
1699         *)
1700             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
1701             ;;
1702     esac
1703 }
1704
1705 # run dhclient for wireless device
1706 iwclient() {
1707     salias dhclient "$(wavemon -d | awk '/device/{print $2}')"
1708 }
1709
1710 # spawn a minimally set up ksh - useful if you want to umount /usr/.
1711 minimal-shell() {
1712     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ksh
1713 }
1714
1715 # make a backup of a file
1716 bk() {
1717     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
1718 }
1719
1720 # Switching shell safely and efficiently? http://www.zsh.org/mla/workers/2001/msg02410.html
1721 # bash() {
1722 #  NO_SWITCH="yes" command bash "$@"
1723 # }
1724 # restart () {
1725 #  exec $SHELL $SHELL_ARGS "$@"
1726 # }
1727
1728 # }}}
1729
1730 # log out? set timeout in seconds {{{
1731 # TMOUT=1800
1732 # do not log out in some specific terminals:
1733 #  if [[ "${TERM}" == ([Exa]term*|rxvt|dtterm|screen*) ]] ; then
1734 #    unset TMOUT
1735 #  fi
1736 # }}}
1737
1738 # {{{ make sure our environment is clean regarding colors
1739 for color in BLUE RED GREEN CYAN WHITE ; unset $color
1740 # }}}
1741
1742 # source another config file if present {{{
1743 xsource "/etc/zsh/zshrc.local"
1744 # }}}
1745
1746 # "persistent history" {{{
1747 # just write important commands you always need to ~/.important_commands
1748 if [[ -r ~/.important_commands ]] ; then
1749     fc -R ~/.important_commands
1750 fi
1751 # }}}
1752
1753 ## genrefcard.pl settings {{{
1754 ### example: split functions-search 8,16,24,32
1755 #@# split functions-search 8
1756 ## }}}
1757
1758 # add variable to be able to check whether the file has been read {{{
1759 ZSHRC_GLOBAL_HAS_BEEN_READ=1
1760 # }}}
1761
1762 ## END OF FILE #################################################################
1763 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4