etc/zsh/zshrc

   1 # Filename:      zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 # Latest change: Sam Dez 22 19:17:27 CET 2007 [mika]
   7 ################################################################################
   8 # This file is sourced only for interactive shells. It
   9 # should contain commands to set up aliases, functions,
  10 # options, key bindings, etc.
  11 #
  12 # Global Order: zshenv, zprofile, zshrc, zlogin
  13 ################################################################################
  14
  15 # zsh-refcard-tag documentation: {{{
  16 #   You may notice strange looking comments in the zshrc (and ~/.zshrc as
  17 #   well). These are there for a purpose. grml's zsh-refcard can now be
  18 #   automatically generated from the contents of the actual configuration
  19 #   files. However, we need a little extra information on which comments
  20 #   and what lines of code to take into account (and for what purpose).
  21 #
  22 # Here is what they mean:
  23 #
  24 # List of tags (comment types) used:
  25 #   #a#     Next line contains an important alias, that should
  26 #           be included in the grml-zsh-refcard.
  27 #           (placement tag: @@INSERT-aliases@@)
  28 #   #f#     Next line contains the beginning of an important function.
  29 #           (placement tag: @@INSERT-functions@@)
  30 #   #v#     Next line contains an important variable.
  31 #           (placement tag: @@INSERT-variables@@)
  32 #   #k#     Next line contains an important keybinding.
  33 #           (placement tag: @@INSERT-keybindings@@)
  34 #   #d#     Hashed directories list generation:
  35 #               start   denotes the start of a list of 'hash -d'
  36 #                       definitions.
  37 #               end     denotes its end.
  38 #           (placement tag: @@INSERT-hasheddirs@@)
  39 #   #A#     Abbreviation expansion list generation:
  40 #               start   denotes the beginning of abbreviations.
  41 #               end     denotes their end.
  42 #           Lines within this section that end in '#d .*' provide
  43 #           extra documentation to be included in the refcard.
  44 #           (placement tag: @@INSERT-abbrev@@)
  45 #   #m#     This tag allows you to manually generate refcard entries
  46 #           for code lines that are hard/impossible to parse.
  47 #               Example:
  48 #                   #m# k ESC-h Call the run-help function
  49 #               That would add a refcard entry in the keybindings table
  50 #               for 'ESC-h' with the given comment.
  51 #           So the syntax is: #m# <section> <argument> <comment>
  52 #   #o#     This tag lets you insert entries to the 'other' hash.
  53 #           Generally, this should not be used. It is there for
  54 #           things that cannot be done easily in another way.
  55 #           (placement tag: @@INSERT-other-foobar@@)
  56 #
  57 #   All of these tags (except for m and o) take two arguments, the first
  58 #   within the tag, the other after the tag:
  59 #
  60 #   #<tag><section># <comment>
  61 #
  62 #   Where <section> is really just a number, which are defined by the
  63 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  64 #   instead of names is, that for the reader, the tag should not differ
  65 #   much from a regular comment. For zsh, it is a regular comment indeed.
  66 #   The numbers have got the following meanings:
  67 #         0 -> "default"
  68 #         1 -> "system"
  69 #         2 -> "user"
  70 #         3 -> "debian"
  71 #         4 -> "search"
  72 #         5 -> "shortcuts"
  73 #         6 -> "services"
  74 #
  75 #   So, the following will add an entry to the 'functions' table in the
  76 #   'system' section, with a (hopefully) descriptive comment:
  77 #       #f1# Edit an alias via zle
  78 #       edalias() {
  79 #
  80 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  81 #   that can be found in 'grml-zsh-refcard.tex.in'.
  82 #   If the section number is omitted, the 'default' section is assumed.
  83 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
  84 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
  85 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
  86 #}}}
  87
  88 # zsh profiling {{{
  89 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
  90 if [[ -n $ZSH_PROFILE_RC ]] ; then
  91     zmodload zsh/zprof
  92 fi
  93 # }}}
  94
  95 # utility functions {{{
  96 # this function checks if a command exists and returns either true
  97 # or false. This avoids using 'which' and 'whence', which will
  98 # avoid problems with aliases for which on certain weird systems. :-)
  99 check_com() {
 100     local -i comonly
 101
 102     if [[ ${1} == '-c' ]] ; then
 103         (( comonly = 1 ))
 104         shift
 105     else
 106         (( comonly = 0 ))
 107     fi
 108
 109     if (( ${#argv} != 1 )) ; then
 110         printf 'usage: check_com [-c] <command>\n' >&2
 111         return 1
 112     fi
 113
 114     if (( comonly > 0 )) ; then
 115         [[ -n ${commands[$1]}  ]] && return 0
 116         return 1
 117     fi
 118
 119     if   [[ -n ${commands[$1]}    ]] \
 120       || [[ -n ${functions[$1]}   ]] \
 121       || [[ -n ${aliases[$1]}     ]] \
 122       || [[ -n ${reswords[(r)$1]} ]] ; then
 123
 124         return 0
 125     fi
 126
 127     return 1
 128 }
 129
 130 # creates an alias and precedes the command with
 131 # sudo if $EUID is not zero.
 132 salias() {
 133     local only=0 ; local multi=0
 134     while [[ ${1} == -* ]] ; do
 135         case ${1} in
 136             (-o) only=1 ;;
 137             (-a) multi=1 ;;
 138             (--) shift ; break ;;
 139             (-h)
 140                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 141                 printf '  -h      shows this help text.\n'
 142                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 143                 printf '          be careful using this option.\n'
 144                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 145                 return 0
 146                 ;;
 147             (*) printf "unkown option: '%s'\n" "${1}" ; return 1 ;;
 148         esac
 149         shift
 150     done
 151
 152     if (( ${#argv} > 1 )) ; then
 153         printf 'Too many arguments %s\n' "${#argv}"
 154         return 1
 155     fi
 156
 157     key="${1%%\=*}" ;  val="${1#*\=}"
 158     if (( EUID == 0 )) && (( only == 0 )); then
 159         alias -- "${key}=${val}"
 160     elif (( EUID > 0 )) ; then
 161         (( multi > 0 )) && val="${val// ; / ; sudo }"
 162         alias -- "${key}=sudo ${val}"
 163     fi
 164
 165     return 0
 166 }
 167
 168 # Check if we can read given files and source those we can.
 169 xsource() {
 170     if (( ${#argv} < 1 )) ; then
 171         printf 'usage: xsource FILE(s)...\n' >&2
 172         return 1
 173     fi
 174
 175     while (( ${#argv} > 0 )) ; do
 176         [[ -r ${1} ]] && source ${1}
 177         shift
 178     done
 179     return 0
 180 }
 181
 182 # Check if we can read a given file and 'cat(1)' it.
 183 xcat() {
 184     if (( ${#argv} != 1 )) ; then
 185         printf 'usage: xcat FILE\n' >&2
 186         return 1
 187     fi
 188
 189     [[ -r ${1} ]] && cat ${1}
 190     return 0
 191 }
 192
 193 # Remove these functions again, they are of use only in these
 194 # setup files. This should be called at the end of .zshrc.
 195 xunfunction() {
 196     local -a funcs
 197     funcs=(check_com salias xcat xsource xunfunction zrcautoload)
 198
 199     for func in $funcs ; do
 200         [[ -n ${functions[$func]} ]] \
 201             && unfunction $func
 202     done
 203     return 0
 204 }
 205
 206 # autoload wrapper - use this one instead of autoload directly
 207 function zrcautoload() {
 208     setopt local_options extended_glob
 209     local fdir ffile
 210     local -i ffound
 211
 212     ffile=${1}
 213     (( found = 0 ))
 214     for fdir in ${fpath} ; do
 215         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 216     done
 217
 218     (( ffound == 0 )) && return 1
 219     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 220         autoload -U ${ffile} || return 1
 221     else
 222         autoload ${ffile} || return 1
 223     fi
 224     return 0
 225 }
 226
 227 #}}}
 228
 229 # locale setup {{{
 230 if [[ -z "$LANG" ]] ; then
 231     xsource "/etc/default/locale"
 232 fi
 233
 234 export LANG=${LANG:-en_US.iso885915}
 235 for var in LC_ALL LC_MESSAGES ; do
 236     [[ -n ${(P)var} ]] && export $var
 237 done
 238
 239 xsource "/etc/sysconfig/keyboard"
 240
 241 TZ=$(xcat /etc/timezone)
 242 # }}}
 243
 244 # check for potentially old files in 'completion.d' {{{
 245 setopt extendedglob
 246 xof=(/etc/zsh/completion.d/*~/etc/zsh/completion.d/_*(N))
 247 if (( ${#xof} > 0 )) ; then
 248     printf '\n -!- INFORMATION\n\n'
 249     printf ' -!- %s file(s) not starting with an underscore (_) found in\n' ${#xof}
 250     printf ' -!- /etc/zsh/completion.d/.\n\n'
 251     printf ' -!- While this has been the case in old versions of grml-etc-core,\n'
 252     printf ' -!- recent versions of the grml-zsh-setup have all these files rewritten\n'
 253     printf ' -!- and renamed. Furthermore, the grml-zsh-setup will *only* add files\n'
 254     printf ' -!- named _* to that directory.\n\n'
 255     printf ' -!- If you added functions to completion.d yourself, please consider\n'
 256     printf ' -!- moving them to /etc/zsh/functions.d/. Files in that directory, not\n'
 257     printf ' -!- starting with an underscore are marked for automatic loading\n'
 258     printf ' -!- by default (so that is quite convenient).\n\n'
 259     printf ' -!- If there are files *not* starting with an underscore from an older\n'
 260     printf ' -!- grml-etc-core in completion.d, you may safely remove them.\n\n'
 261     printf ' -!- Delete the files for example via running:\n\n'
 262     printf "      rm ${xof}\n\n"
 263     printf ' -!- Note, that this message will *not* go away, unless you yourself\n'
 264     printf ' -!- resolve the situation manually.\n\n'
 265     BROKEN_COMPLETION_DIR=1
 266 fi
 267 unset xof
 268 # }}}
 269
 270 # {{{ check for version/system
 271 # check for versions (compatibility reasons)
 272 is4(){
 273     [[ $ZSH_VERSION == <4->* ]] && return 0
 274     return 1
 275 }
 276
 277 is41(){
 278     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 279     return 1
 280 }
 281
 282 is42(){
 283     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 284     return 1
 285 }
 286
 287 is43(){
 288     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 289     return 1
 290 }
 291
 292 # Use is-at-least, if you need to check more precisely.
 293 # Note that this test will *always* fail, if the is-at-least
 294 # function could not be marked for autoloading.
 295 zrcautoload is-at-least || is-at-least() { return 1 }
 296
 297 #f1# Checks whether or not you're running grml
 298 isgrml(){
 299     [[ -f /etc/grml_version ]] && return 0
 300     return 1
 301 }
 302
 303 #f1# Checks whether or not you're running a grml cd
 304 isgrmlcd(){
 305     [[ -f /etc/grml_cd ]] && return 0
 306     return 1
 307 }
 308
 309 if isgrml ; then
 310 #f1# Checks whether or not you're running grml-small
 311     isgrmlsmall() {
 312         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 313     }
 314 else
 315     isgrmlsmall() { return 1 }
 316 fi
 317
 318 #f1# are we running within an utf environment?
 319 isutfenv() {
 320     case "$LANG $CHARSET $LANGUAGE" in
 321         *utf*) return 0 ;;
 322         *UTF*) return 0 ;;
 323         *)     return 1 ;;
 324     esac
 325 }
 326
 327 # check for user, if not running as root set $SUDO to sudo
 328 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 329
 330 # change directory to home on first invocation of zsh
 331 # important for rungetty -> autologin
 332 # Thanks go to Bart Schaefer!
 333 isgrml && checkhome() {
 334     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 335         export ALREADY_DID_CD_HOME=$HOME
 336         cd
 337     fi
 338 }
 339
 340 # check for zsh v3.1.7+
 341
 342 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 343      || ${ZSH_VERSION} == 3.<2->.<->*    \
 344      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 345
 346     printf '-!-\n'
 347     printf '-!- In this configuration we try to make use of features, that only\n'
 348     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 349     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 350     printf '-!- advanced features in all supported versions.\n'
 351     printf '-!-\n'
 352     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 353     printf '-!-\n'
 354     printf '-!- While this *may* work, it might as well fail.\n'
 355     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 356     printf '-!-\n'
 357     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 358     printf '-!- If it does today, you'\''ve been lucky.\n'
 359     printf '-!-\n'
 360     printf '-!- Ye been warned!\n'
 361     printf '-!-\n'
 362
 363     function zstyle() { : }
 364 fi
 365
 366 # }}}
 367
 368 # {{{ set some variables
 369 if check_com -c vim ; then
 370 #v#
 371     export EDITOR=${EDITOR:-vim}
 372 else
 373     export EDITOR=${EDITOR:-vi}
 374 fi
 375
 376 #v#
 377 export PAGER=${PAGER:-less}
 378
 379 #v#
 380 export MAIL=${MAIL:-/var/mail/$USER}
 381
 382 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 383 export SHELL='/bin/zsh'
 384
 385 # color setup for ls:
 386 check_com -c dircolors && eval $(dircolors -b)
 387
 388 # set width of man pages to 80 for more convenient reading
 389 # export MANWIDTH=${MANWIDTH:-80}
 390
 391 # Search path for the cd command
 392 #  cdpath=(.. ~)
 393
 394 # completion functions go to /etc/zsh/completion.d
 395 # function files may be put into /etc/zsh/functions.d, from where they
 396 # will be automatically autoloaded.
 397 if [[ -n "$BROKEN_COMPLETION_DIR" ]] ; then
 398     print 'Warning: not setting completion directories because broken files have been found.' >&2
 399 else
 400     [[ -d /etc/zsh/completion.d ]] && fpath=( $fpath /etc/zsh/completion.d )
 401     if [[ -d /etc/zsh/functions.d ]] ; then
 402         fpath+=( /etc/zsh/functions.d )
 403         for func in /etc/zsh/functions.d/[^_]*[^~] ; do
 404             zrcautoload -U ${func:t}
 405         done
 406     fi
 407 fi
 408
 409 # automatically remove duplicates from these arrays
 410 typeset -U path cdpath fpath manpath
 411 # }}}
 412
 413 # {{{ keybindings
 414 if [[ "$TERM" != emacs ]] ; then
 415     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 416     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 417     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 418     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 419     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 420     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 421     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 422     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 423     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 424     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 425     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 426     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 427     # ncurses stuff:
 428     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 429     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 430     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 431     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 432     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 433     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 434     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 435     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 436 fi
 437
 438 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 439 # use emacs style per default:
 440 bindkey -e
 441 # use vi style:
 442 # bindkey -v
 443
 444 #if [[ "$TERM" == screen ]] ; then
 445 bindkey '\e[1~' beginning-of-line       # home
 446 bindkey '\e[4~' end-of-line             # end
 447 bindkey '\e[A'  up-line-or-search       # cursor up
 448 bindkey '\e[B'  down-line-or-search     # <ESC>-
 449 bindkey '^x'    history-beginning-search-backward # alternative ways of searching the shell history
 450 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 451 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 452 # if terminal type is set to 'rxvt':
 453 bindkey '\e[7~' beginning-of-line       # home
 454 bindkey '\e[8~' end-of-line             # end
 455 #fi
 456
 457 # insert unicode character
 458 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 459 # See for example http://unicode.org/charts/ for unicode characters code
 460 zrcautoload insert-unicode-char
 461 zle -N insert-unicode-char
 462 #k# Insert Unicode character
 463 bindkey '^Xi' insert-unicode-char
 464
 465 # just type 'cd ...' to get 'cd ../..'
 466 #  rationalise-dot() {
 467 #  if [[ $LBUFFER == *.. ]] ; then
 468 #    LBUFFER+=/..
 469 #  else
 470 #    LBUFFER+=.
 471 #  fi
 472 #  }
 473 #  zle -N rationalise-dot
 474 #  bindkey . rationalise-dot
 475
 476 #  bindkey '\eq' push-line-or-edit
 477 # }}}
 478
 479 # a generic accept-line wrapper {{{
 480
 481 # This widget can prevent unwanted autocorrections from command-name
 482 # to _command-name, rehash automatically on enter and call any number
 483 # of builtin and user-defined widgets in different contexts.
 484 #
 485 # For a broader description, see:
 486 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 487 #
 488 # The code is imported from the file 'zsh/functions/accept-line' from
 489 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 490 # distributed under the same terms as zsh itself.
 491
 492 # A newly added command will may not be found or will cause false
 493 # correction attempts, if you got auto-correction set. By setting the
 494 # following style, we force accept-line() to rehash, if it cannot
 495 # find the first word on the command line in the $command[] hash.
 496 zstyle ':acceptline:*' rehash true
 497
 498 function Accept-Line() {
 499     setopt localoptions noksharrays
 500     local -a subs
 501     local -xi aldone
 502     local sub
 503
 504     zstyle -a ":acceptline:${alcontext}" actions subs
 505
 506     (( ${#subs} < 1 )) && return 0
 507
 508     (( aldone = 0 ))
 509     for sub in ${subs} ; do
 510         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 511         zle ${sub}
 512
 513         (( aldone > 0 )) && break
 514     done
 515 }
 516
 517 function Accept-Line-getdefault() {
 518     local default_action
 519
 520     zstyle -s ":acceptline:${alcontext}" default_action default_action
 521     case ${default_action} in
 522         ((accept-line|))
 523             printf ".accept-line"
 524             ;;
 525         (*)
 526             printf ${default_action}
 527             ;;
 528     esac
 529 }
 530
 531 function accept-line() {
 532     setopt localoptions noksharrays
 533     local -a cmdline
 534     local -x alcontext
 535     local buf com fname format msg default_action
 536
 537     alcontext='default'
 538     buf="${BUFFER}"
 539     cmdline=(${(z)BUFFER})
 540     com="${cmdline[1]}"
 541     fname="_${com}"
 542
 543     zstyle -t ":acceptline:${alcontext}" rehash \
 544         && [[ -z ${commands[$com]} ]]           \
 545         && rehash
 546
 547     if    [[ -n ${reswords[(r)$com]} ]] \
 548        || [[ -n ${aliases[$com]}     ]] \
 549        || [[ -n ${functions[$com]}   ]] \
 550        || [[ -n ${builtins[$com]}    ]] \
 551        || [[ -n ${commands[$com]}    ]] ; then
 552
 553         # there is something sensible to execute, just do it.
 554         alcontext='normal'
 555         zle Accept-Line
 556
 557         default_action=$(Accept-Line-getdefault)
 558         zstyle -T ":acceptline:${alcontext}" call_default \
 559             && zle ${default_action}
 560         return
 561     fi
 562
 563     if    [[ -o correct              ]] \
 564        || [[ -o correctall           ]] \
 565        && [[ -n ${functions[$fname]} ]] ; then
 566
 567         # nothing there to execute but there is a function called
 568         # _command_name; a completion widget. Makes no sense to
 569         # call it on the commandline, but the correct{,all} options
 570         # will ask for it nevertheless, so warn the user.
 571         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 572             # Okay, we warned the user before, he called us again,
 573             # so have it his way.
 574             alcontext='force'
 575             zle Accept-Line
 576
 577             default_action=$(Accept-Line-getdefault)
 578             zstyle -T ":acceptline:${alcontext}" call_default \
 579                 && zle ${default_action}
 580             return
 581         fi
 582
 583         # prepare warning message for the user, configurable via zstyle.
 584         zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 585
 586         if [[ -z ${msg} ]] ; then
 587             msg="%c will not execute and completion %f exists."
 588         fi
 589
 590         zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 591
 592         zle -M -- "${msg}"
 593         return
 594     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 595         # If we are here, the commandline contains something that is not
 596         # executable, which is neither subject to _command_name correction
 597         # and is not empty. might be a variable assignment
 598         alcontext='misc'
 599         zle Accept-Line
 600
 601         default_action=$(Accept-Line-getdefault)
 602         zstyle -T ":acceptline:${alcontext}" call_default \
 603             && zle ${default_action}
 604         return
 605     fi
 606
 607     # If we got this far, the commandline only contains whitespace, or is empty.
 608     alcontext='empty'
 609     zle Accept-Line
 610
 611     default_action=$(Accept-Line-getdefault)
 612     zstyle -T ":acceptline:${alcontext}" call_default \
 613         && zle ${default_action}
 614 }
 615
 616 zle -N accept-line
 617 zle -N Accept-Line
 618
 619 # }}}
 620
 621 # power completion - abbreviation expansion {{{
 622 # power completion / abbreviation expansion / buffer expansion
 623 # see http://zshwiki.org/home/examples/zleiab for details
 624 # less risky than the global aliases but powerful as well
 625 # just type the abbreviation key and afterwards ',.' to expand it
 626 declare -A abk
 627 setopt extendedglob
 628 setopt interactivecomments
 629 abk=(
 630 # key  # value                (#d additional doc string)
 631 #A# start
 632     '...' '../..'
 633     '....' '../../..'
 634     'BG' '& exit'
 635     'C' '| wc -l'
 636     'G' '|& grep --color=auto'
 637     'H' '| head'
 638     'Hl' ' --help |& less -r'      #d (Display help in pager)
 639     'L' '| less'
 640     'LL' '|& less -r'
 641     'M' '| most'
 642     'N' '&>/dev/null'              #d (No Output)
 643     'R' '| tr A-z N-za-m'          #d (ROT13)
 644     'SL' '| sort | less'
 645     'S' '| sort -u'
 646     'T' '| tail'
 647     'V' '|& vim -'
 648 #A# end
 649     'hide' "echo -en '\033]50;nil2\007'"
 650     'tiny' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
 651     'small' 'echo -en "\033]50;6x10\007"'
 652     'medium' 'echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
 653     'default' 'echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
 654     'large' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
 655     'huge' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
 656     'smartfont' 'echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
 657     'semifont' 'echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
 658     'da' 'du -sch'
 659     'j' 'jobs -l'
 660     'u' 'translate -i'
 661     'co' "./configure && make && sudo make install"
 662     'CH' "./configure --help"
 663     'conkeror' 'firefox -chrome chrome://conkeror/content'
 664     'dir' 'ls -lSrah'
 665     'lad' $'ls -d .*(/)\n# only show dot-directories'
 666     'lsa' $'ls -a .*(.)\n# only show dot-files'
 667     'lss' $'ls -l *(s,S,t)\n# only files with setgid/setuid/sticky flag'
 668     'lsl' $'ls -l *(@[1,10])\n# only symlinks'
 669     'lsx' $'ls -l *(*[1,10])\n# only executables'
 670     'lsw' $'ls -ld *(R,W,X.^ND/)\n# world-{readable,writable,executable} files'
 671     'lsbig' $'ls -flh *(.OL[1,10])\n# display the biggest files'
 672     'lsd' $'ls -d *(/)\n# only show directories'
 673     'lse' $'ls -d *(/^F)\n# only show empty directories'
 674     'lsnew' $'ls -rl *(D.om[1,10])\n# display the newest files'
 675     'lsold' $'ls -rtlh *(D.om[-11,-1])\n # display the oldest files'
 676     'lssmall' $'ls -Srl *(.oL[1,10])\n# display the smallest files'
 677     'rw-' 'chmod 600'
 678     '600' 'chmod u+rw-x,g-rwx,o-rwx'
 679     'rwx' 'chmod u+rwx'
 680     '700' 'chmod u+rwx,g-rwx,o-rwx'
 681     'r--' 'chmod u+r-wx,g-rwx,o-rwx'
 682     '644' $'chmod u+rw-x,g+r-wx,o+r-wx\n # 4=r,2=w,1=x'
 683     '755' 'chmod u+rwx,g+r-w+x,o+r-w+x'
 684     'md' 'mkdir -p '
 685     'cmplayer' 'mplayer -vo -fs -zoom fbdev'
 686     'fbmplayer' 'mplayer -vo -fs -zoom fbdev'
 687     'fblinks' 'links2 -driver fb'
 688     'insecssh' 'ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 689     'insecscp' 'scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 690     'fori' 'for i ({..}) { }'
 691     'cx' 'chmod +x'
 692     'e'  'print -l'
 693     'se' 'setopt interactivecomments'
 694     'va' 'valac --vapidir=../vapi/ --pkg=gtk+-2.0 gtktest.vala'
 695     'fb2' '=mplayer -vo fbdev -fs -zoom 1>/dev/null -xy 2'
 696     'fb3' '=mplayer -vo fbdev -fs  -zoom 1>/dev/null -xy 3'
 697     'ci' 'centericq'
 698     'D'  'export DISPLAY=:0.0'
 699     'mp' 'mplayer -vo xv -fs -zoom'
 700 )
 701
 702 globalias() {
 703     local MATCH
 704     matched_chars='[.-|_a-zA-Z0-9]#'
 705     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 706     LBUFFER+=${abk[$MATCH]:-$MATCH}
 707 }
 708
 709 zle -N globalias
 710 bindkey ",." globalias
 711 # }}}
 712
 713 # {{{ autoloading
 714 zrcautoload zmv    # who needs mmv or rename?
 715 zrcautoload history-search-end
 716
 717 # we don't want to quote/espace URLs on our own...
 718 # if autoload -U url-quote-magic ; then
 719 #    zle -N self-insert url-quote-magic
 720 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 721 # else
 722 #    print 'Notice: no url-quote-magic available :('
 723 # fi
 724 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 725
 726 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 727 alias run-help >&/dev/null && unalias run-help
 728 zrcautoload run-help # use via 'esc-h'
 729
 730 # completion system
 731 if zrcautoload compinit && compinit 2>/dev/null ; then
 732     compinit 2>/dev/null || print 'Notice: no compinit available :('
 733 else
 734     print 'Notice: no compinit available :('
 735     function zstyle { }
 736     function compdef { }
 737 fi
 738
 739 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 740
 741 is4 && \
 742 for mod in complist deltochar mathfunc ; do
 743     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 744 done
 745
 746 # autoload zsh modules when they are referenced
 747 if is4 ; then
 748     tmpargs=(
 749         a   stat
 750         a   zpty
 751         ap  zprof
 752         ap  mapfile
 753     )
 754
 755     while (( ${#tmpargs} > 0 )) ; do
 756         zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
 757         shift 2 tmpargs
 758     done
 759     unset tmpargs
 760 fi
 761
 762 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 763     #k# Insert files
 764     bindkey "^Xf" insert-files # C-x-f
 765 fi
 766
 767 bindkey ' '   magic-space    # also do history expansion on space
 768 #k# Trigger menu-complete
 769 bindkey '\ei' menu-complete  # menu completion via esc-i
 770
 771 # press esc-e for editing command line in $EDITOR or $VISUAL
 772 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 773     #k# Edit the current line in \kbd{\$EDITOR}
 774     bindkey '\ee' edit-command-line
 775 fi
 776
 777 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 778     #k# menu selection: pick item but stay in the menu
 779     bindkey -M menuselect '\e^M' accept-and-menu-complete
 780
 781     # use the vi navigation keys (hjkl) besides cursor keys in menu completion
 782     #bindkey -M menuselect 'h' vi-backward-char        # left
 783     #bindkey -M menuselect 'k' vi-up-line-or-history   # up
 784     #bindkey -M menuselect 'l' vi-forward-char         # right
 785     #bindkey -M menuselect 'j' vi-down-line-or-history # bottom
 786
 787     # accept a completion and try to complete again by using menu
 788     # completion; very useful with completing directories
 789     # by using 'undo' one's got a simple file browser
 790     bindkey -M menuselect '^o' accept-and-infer-next-history
 791 fi
 792
 793 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 794 _bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
 795 zle -N _bkdate
 796
 797 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 798 bindkey '^Ed' _bkdate
 799
 800 # press esc-m for inserting last typed word again (thanks to caphuso!)
 801 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 802 zle -N insert-last-typed-word;
 803
 804 #k# Insert last typed word
 805 bindkey "\em" insert-last-typed-word
 806
 807 # set command prediction from history, see 'man 1 zshcontrib'
 808 #  is4 && zrcautoload predict-on && \
 809 #  zle -N predict-on         && \
 810 #  zle -N predict-off        && \
 811 #  bindkey "^X^Z" predict-on && \
 812 #  bindkey "^Z" predict-off
 813
 814 #k# Shortcut for \kbd{fg<enter>}
 815 bindkey -s '^z' "fg\n"
 816
 817 # press ctrl-q to quote line:
 818 #  mquote () {
 819 #        zle beginning-of-line
 820 #        zle forward-word
 821 #        # RBUFFER="'$RBUFFER'"
 822 #        RBUFFER=${(q)RBUFFER}
 823 #        zle end-of-line
 824 #  }
 825 #  zle -N mquote && bindkey '^q' mquote
 826
 827 # run command line as user root via sudo:
 828 sudo-command-line() {
 829     [[ -z $BUFFER ]] && zle up-history
 830     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
 831 }
 832 zle -N sudo-command-line
 833
 834 #k# Put the current command line into a \kbd{sudo} call
 835 bindkey "^Os" sudo-command-line
 836
 837 ### jump behind the first word on the cmdline.
 838 ### useful to add options.
 839 function jump_after_first_word() {
 840     local words
 841     words=(${(z)BUFFER})
 842
 843     if (( ${#words} <= 1 )) ; then
 844         CURSOR=${#BUFFER}
 845     else
 846         CURSOR=${#${words[1]}}
 847     fi
 848 }
 849 zle -N jump_after_first_word
 850
 851 bindkey '^x1' jump_after_first_word
 852
 853 # }}}
 854
 855 # {{{ set some important options
 856 # Please update these tags, if you change the umask settings below.
 857 #o# r_umask     002
 858 #o# r_umaskstr  rwxrwxr-x
 859 #o# umask       022
 860 #o# umaskstr    rwxr-xr-x
 861 (( EUID != 0 )) && umask 002 || umask 022
 862
 863 # history:
 864 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 865 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 866 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 867 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 868                             # list duplicates an older one, the older command is removed from the list
 869 setopt histignorespace      # remove command lines from the history list when
 870                             # the first character on the line is a space
 871 #  setopt histallowclobber    # add `|' to output redirections in the history
 872 #  setopt NO_clobber          # warning if file exists ('cat /dev/null > ~/.zshrc')
 873 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 874                             # and the command is the name of a directory, perform the cd command to that directory
 875 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 876                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 877                             # -> searches for word not in compressed files
 878                             # don't forget to quote '^', '~' and '#'!
 879 setopt longlistjobs         # display PID when suspending processes as well
 880 setopt notify               # report the status of backgrounds jobs immediately
 881 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 882                             # the entire command path is hashed first.
 883 setopt completeinword       # not just at the end
 884 # setopt nocheckjobs          # don't warn me about bg processes when exiting
 885 setopt nohup                # and don't kill them, either
 886 # setopt printexitvalue       # alert me if something failed
 887 # setopt dvorak               # with spelling correction, assume dvorak kb
 888 setopt auto_pushd           # make cd push the old directory onto the directory stack.
 889 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 890 setopt nobeep               # avoid "beep"ing
 891 setopt pushd_ignore_dups    # don't push the same dir twice.
 892
 893 MAILCHECK=30       # mailchecks
 894 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 895 watch=(notme root) # watch for everyone but me and root
 896
 897 # define word separators (for stuff like backward-word, forward-word, backward-kill-word,..)
 898 #  WORDCHARS='*?_-.[]~=/&;!#$%^(){}<>' # the default
 899 #  WORDCHARS=.
 900 #  WORDCHARS='*?_[]~=&;!#$%^(){}'
 901 #  WORDCHARS='${WORDCHARS:s@/@}'
 902
 903 # only slash should be considered as a word separator:
 904 slash-backward-kill-word() {
 905     local WORDCHARS="${WORDCHARS:s@/@}"
 906     # zle backward-word
 907     zle backward-kill-word
 908 }
 909 zle -N slash-backward-kill-word
 910
 911 #k# Kill everything in a word up to its last \kbd{/}
 912 bindkey '\ev' slash-backward-kill-word
 913
 914 # }}}
 915
 916 # {{{ history
 917
 918 ZSHDIR=$HOME/.zsh
 919
 920 #v#
 921 HISTFILE=$HOME/.zsh_history
 922 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
 923 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
 924
 925 # }}}
 926
 927 # dirstack handling {{{
 928
 929 DIRSTACKSIZE=20
 930 if [[ -f ~/.zdirs ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
 931     dirstack=( ${(f)"$(< ~/.zdirs)"} )
 932     # "cd -" won't work after login by just setting $OLDPWD, so
 933     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
 934 fi
 935
 936 chpwd() {
 937     builtin print -l ${(u)dirstack} >! ~/.zdirs
 938 }
 939
 940 # }}}
 941
 942 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
 943 if [[ -n "$BATTERY" ]] ; then
 944     if check_com -c acpi ; then
 945         PERCENT="${(C)${(s| |)$(acpi 2>/dev/null)}[4]}"
 946         [[ -z "$PERCENT" ]] && PERCENT='acpi not present'
 947
 948         if [[ "${PERCENT%%%}" -lt 20 ]] ; then
 949             PERCENT="warning: ${PERCENT}%"
 950         fi
 951     fi
 952 fi
 953 # }}}
 954
 955 # display version control information on right side of prompt if $VCS is set {{{
 956 # based on Mike Hommey's http://web.glandium.org/blog/?p=170
 957 __vcs_dir() {
 958     local vcs base_dir sub_dir ref
 959
 960     sub_dir() {
 961       local sub_dir
 962       sub_dir=$(readlink -f "${PWD}")
 963       sub_dir=${sub_dir#$1}
 964       echo ${sub_dir#/}
 965     }
 966
 967     git_dir() {
 968       base_dir=$(git-rev-parse --show-cdup 2>/dev/null) || return 1
 969       base_dir=$(readlink -f "$base_dir/..")
 970       sub_dir=$(git-rev-parse --show-prefix)
 971       sub_dir=${sub_dir%/}
 972       ref=$(git-symbolic-ref -q HEAD || git-name-rev --name-only HEAD 2>/dev/null)
 973       ref=${ref#refs/heads/}
 974       vcs="git"
 975     }
 976
 977     svn_dir() {
 978       [[ -d ".svn" ]] || return 1
 979       base_dir="."
 980       while [[ -d "$base_dir/../.svn" ]]; do base_dir="$base_dir/.."; done
 981       base_dir=$(readlink -f "$base_dir")
 982       sub_dir=$(sub_dir "${base_dir}")
 983       ref=$(svn info "$base_dir" | awk '/^URL/ { sub(".*/","",$0); r=$0 } /^Revision/ { sub("[^0-9]*","",$0); print r":"$0 }')
 984       vcs="svn"
 985     }
 986
 987     svk_dir() {
 988         [[ -f ~/.svk/config ]] || return 1
 989         base_dir=$(awk '/: *$/ { sub(/^ */,"",$0); sub(/: *$/,"",$0); if (match("'${PWD}'", $0"(/|$)")) { print $0; d=1; } } /depotpath/ && d == 1 { sub(".*/","",$0); r=$0 } /revision/ && d == 1 { print r ":" $2; exit 1 }' ~/.svk/config) && return 1
 990         ref=${base_dir##*
 991   }
 992         base_dir=${base_dir%%
 993   *}
 994         sub_dir=$(sub_dir "${base_dir}")
 995         vcs="svk"
 996     }
 997
 998     hg_dir() {
 999         base_dir="."
1000         while [[ ! -d "$base_dir/.hg" ]]; do
1001             base_dir="$base_dir/.."
1002             [[ $(readlink -f "${base_dir}") = "/" ]] && return 1
1003         done
1004         base_dir=$(readlink -f "$base_dir")
1005         sub_dir=$(sub_dir "${base_dir}")
1006         ref=$(< "${base_dir}/.hg/branch")
1007         vcs="hg"
1008     }
1009
1010     hg_dir  ||
1011     git_dir ||
1012     svn_dir ||
1013     svk_dir # ||
1014   #  base_dir="$PWD"
1015   #  echo "${vcs:+($vcs)}${base_dir/$HOME/~}${vcs:+[$ref]${sub_dir}}"
1016     echo "${vcs:+($vcs)}${base_dir}${vcs:+[$ref]${sub_dir}}"
1017 }
1018 # }}}
1019
1020 # {{{ set prompt
1021 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1022     promptinit # people should be able to use their favourite prompt
1023 else
1024     print 'Notice: no promptinit available :('
1025 fi
1026
1027
1028 # precmd() => a function which is executed just before each prompt
1029 # use 'NOPRECMD=1' to disable the precmd + preexec commands
1030
1031 # precmd () { setopt promptsubst; [[ -o interactive ]] && jobs -l;
1032
1033 # make sure to use right prompt only when not running a command
1034 is41 && setopt transient_rprompt
1035
1036 is4 && [[ -z $NOPRECMD ]] && precmd () {
1037     [[ -n $NOPRECMD ]] && return 0
1038     # allow manual overwriting of RPROMPT
1039     if [[ -n $RPROMPT ]] ; then
1040         [[ $TERM == screen* ]] && echo -n $'\ekzsh\e\\'
1041         # return 0
1042     fi
1043     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1044     if [[ -z $DONTSETRPROMPT ]] ; then
1045         if [[ -n $BATTERY ]] ; then
1046             RPROMPT="%(?..:()% ${PERCENT}${SCREENTITLE}"
1047             # RPROMPT="${PERCENT}${SCREENTITLE}"
1048         elif [[ -n $VCS ]] ; then
1049             RPROMPT="%(?..:()% $(__vcs_dir)${SCREENTITLE}"
1050         else
1051             RPROMPT="%(?..:()% ${SCREENTITLE}"
1052             # RPROMPT="${SCREENTITLE}"
1053         fi
1054     fi
1055     # adjust title of xterm
1056     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1057     case $TERM in
1058         (xterm*|rxvt)
1059             print -Pn "\e]0;%n@%m: %~\a"
1060             ;;
1061     esac
1062 }
1063
1064 # chpwd () => a function which is executed whenever the directory is changed
1065
1066 # preexec() => a function running before every command
1067 is4 && [[ -z $NOPRECMD ]] && \
1068 preexec () {
1069     [[ -n $NOPRECMD ]] && return 0
1070 # set hostname if not running on host with name 'grml'
1071     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1072        NAME="@$HOSTNAME"
1073     fi
1074 # get the name of the program currently running and hostname of local machine
1075 # set screen window title if running in a screen
1076     if [[ "$TERM" == screen* ]] ; then
1077         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1078         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1079         echo -ne "\ek$CMD\e\\"
1080     fi
1081 # set the screen title to "zsh" when sitting at the command prompt:
1082     if [[ "$TERM" == screen* ]] ; then
1083         SCREENTITLE=$'%{\ekzsh\e\\%}'
1084     else
1085         SCREENTITLE=''
1086     fi
1087 # adjust title of xterm
1088     case $TERM in
1089         (xterm*|rxvt)
1090             print -Pn "\e]0;%n@%m: $1\a"
1091             ;;
1092     esac
1093 }
1094
1095 # set colors
1096 if zrcautoload colors && colors 2>/dev/null ; then
1097     BLUE="%{${fg[blue]}%}"
1098     RED="%{${fg_bold[red]}%}"
1099     GREEN="%{${fg[green]}%}"
1100     CYAN="%{${fg[cyan]}%}"
1101     WHITE="%{${fg[white]}%}"
1102     NO_COLOUR="%{${reset_color}%}"
1103 else
1104     BLUE=$'%{\e[1;34m%}'
1105     RED=$'%{\e[1;31m%}'
1106     GREEN=$'%{\e[1;32m%}'
1107     CYAN=$'%{\e[1;36m%}'
1108     WHITE=$'%{\e[1;37m%}'
1109     NO_COLOUR=$'%{\e[0m%}'
1110 fi
1111
1112 EXITCODE="%(?..%?%1v )"
1113 PS2='`%_> '       # secondary prompt, printed when the shell needs more information to complete a command.
1114 PS3='?# '         # selection prompt used within a select loop.
1115 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1116
1117 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1118 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1119     debian_chroot=$(cat /etc/debian_chroot)
1120 fi
1121
1122 # don't use colors on dumb terminals (like emacs):
1123 if [[ "$TERM" == dumb ]] ; then
1124     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< %# "
1125 else
1126     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
1127     # set variable identifying the chroot you work in (used in the prompt below)
1128     if [[ -n $GRMLPROMPT ]] ; then
1129         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1130 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# "
1131     else
1132         if (( EUID != 0 )); then
1133             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# " # primary prompt string
1134         else
1135             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# " # primary prompt string
1136         fi
1137     fi
1138 fi
1139
1140 # if we are inside a grml-chroot set a specific prompt theme
1141 if [[ -n "$GRML_CHROOT" ]] ; then
1142     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1143 fi
1144 # }}}
1145
1146 # {{{ 'hash' some often used directories
1147 #d# start
1148 hash -d deb=/var/cache/apt/archives
1149 hash -d doc=/usr/share/doc
1150 hash -d linux=/lib/modules/$(command uname -r)/build/
1151 hash -d log=/var/log
1152 hash -d slog=/var/log/syslog
1153 hash -d src=/usr/src
1154 hash -d templ=/usr/share/doc/grml-templates
1155 hash -d tt=/usr/share/doc/texttools-doc
1156 hash -d www=/var/www
1157 #d# end
1158 # }}}
1159
1160 # {{{ some aliases
1161 if [[ $UID -eq 0 ]] ; then
1162     [[ -r /etc/grml/screenrc ]] && alias screen='/usr/bin/screen -c /etc/grml/screenrc'
1163 elif [[ -r $HOME/.screenrc ]] ; then
1164     alias screen="/usr/bin/screen -c $HOME/.screenrc"
1165 else
1166     [[ -r /etc/grml/screenrc_grml ]] && alias screen='/usr/bin/screen -c /etc/grml/screenrc_grml'
1167 fi
1168
1169 # do we have GNU ls with color-support?
1170 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
1171     #a1# execute \kbd{@a@}:\quad ls with colors
1172     alias ls='ls -b -CF --color=auto'
1173     #a1# execute \kbd{@a@}:\quad list all files, with colors
1174     alias la='ls -la --color=auto'
1175     #a1# long colored list, without dotfiles (@a@)
1176     alias ll='ls -l --color=auto'
1177     #a1# long colored list, human readable sizes (@a@)
1178     alias lh='ls -hAl --color=auto'
1179     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1180     alias l='ls -lF --color=auto'
1181 else
1182     alias ls='ls -b -CF'
1183     alias la='ls -la'
1184     alias ll='ls -l'
1185     alias lh='ls -hAl'
1186     alias l='ls -lF'
1187 fi
1188
1189 alias mdstat='cat /proc/mdstat'
1190 alias ...='cd ../../'
1191
1192 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1193 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1194     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1195 fi
1196
1197 alias cp='nocorrect cp'         # no spelling correction on cp
1198 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
1199 alias mv='nocorrect mv'         # no spelling correction on mv
1200 alias rm='nocorrect rm'         # no spelling correction on rm
1201
1202 #a1# Execute \kbd{rmdir}
1203 alias rd='rmdir'
1204 #a1# Execute \kbd{rmdir}
1205 alias md='mkdir'
1206
1207 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1208 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1209 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1210
1211 # make sure it is not assigned yet
1212 [[ $(whence -w utf2iso &>/dev/null) == 'utf2iso: alias' ]] && unalias utf2iso
1213
1214 utf2iso() {
1215     if isutfenv ; then
1216         for ENV in $(env | command grep -i '.utf') ; do
1217             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1218         done
1219     fi
1220 }
1221
1222 # make sure it is not assigned yet
1223 [[ $(whence -w iso2utf &>/dev/null) == 'iso2utf: alias' ]] && unalias iso2utf
1224 iso2utf() {
1225     if ! isutfenv ; then
1226         for ENV in $(env | command grep -i '\.iso') ; do
1227             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1228         done
1229     fi
1230 }
1231
1232 # set up software synthesizer via speakup
1233 swspeak() {
1234     aumix -w 90 -v 90 -p 90 -m 90
1235     if ! [[ -r /dev/softsynth ]] ; then
1236         flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
1237         return 1
1238     else
1239         setopt singlelinezle
1240         unsetopt prompt_cr
1241         export PS1="%m%# "
1242         nice -n -20 speechd-up
1243         sleep 2
1244         flite -o play -t "Finished setting up software synthesizer"
1245     fi
1246 }
1247
1248 # I like clean prompt, so provide simple way to get that
1249 check_com 0 || alias 0='return 0'
1250
1251 # for really lazy people like mika:
1252 check_com S &>/dev/null || alias S='screen'
1253 check_com s &>/dev/null || alias s='ssh'
1254
1255 # get top 10 shell commands:
1256 alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
1257
1258 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
1259 if check_com -c truecrypt ; then
1260     if isutfenv ; then
1261         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
1262     else
1263         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
1264     fi
1265 fi
1266
1267 #f1# Hints for the use of zsh on grml
1268 zsh-help() {
1269     print "$bg[white]$fg[black]
1270 zsh-help - hints for use of zsh on grml
1271 =======================================$reset_color"
1272
1273     print '
1274 Main configuration of zsh happens in /etc/zsh/zshrc (global)
1275 and /etc/skel/.zshrc which is copied to $HOME/.zshrc once.
1276 The files are part of the package grml-etc-core, if you want to
1277 use them on a non-grml-system just get the tar.gz from
1278 http://deb.grml.org/ or get the files from the mercurial
1279 repository:
1280
1281   http://hg.grml.org/grml-etc-core/raw-file/tip/etc/skel/.zshrc
1282   http://hg.grml.org/grml-etc-core/raw-file/tip/etc/zsh/zshrc
1283
1284 If you want to stay in sync with zsh configuration of grml
1285 run '\''ln -sf /etc/skel/.zshrc $HOME/.zshrc'\'' and configure
1286 your own stuff in $HOME/.zshrc.local. System wide configuration
1287 without touching configuration files of grml can take place
1288 in /etc/zsh/zshrc.local.
1289
1290 If you want to use the configuration of user grml also when
1291 running as user root just run '\''zshskel'\'' which will source
1292 the file /etc/skel/.zshrc.
1293
1294 For information regarding zsh start at http://grml.org/zsh/
1295
1296 Take a look at grml'\''s zsh refcard:
1297 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1298
1299 Check out the main zsh refcard:
1300 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1301
1302 And of course visit the zsh-lovers:
1303 % man zsh-lovers
1304
1305 You can adjust some options through environment variables when
1306 invoking zsh without having to edit configuration files.
1307 Basically meant for bash users who are not used to the power of
1308 the zsh yet. :)
1309
1310   "NOCOR=1    zsh" => deactivate automatic correction
1311   "NOMENU=1   zsh" => do not use menu completion (note: use strg-d for completion instead!)
1312   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1313   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt'
1314
1315     print "
1316 $bg[white]$fg[black]
1317 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1318 Enjoy your grml system with the zsh!$reset_color"
1319 }
1320
1321 # debian stuff
1322 if [[ -r /etc/debian_version ]] ; then
1323     #a3# Execute \kbd{apt-cache search}
1324     alias acs='apt-cache search'
1325     #a3# Execute \kbd{apt-cache show}
1326     alias acsh='apt-cache show'
1327     #a3# Execute \kbd{apt-cache policy}
1328     alias acp='apt-cache policy'
1329     #a3# Execute \kbd{apt-get dist-upgrade}
1330     salias adg="apt-get dist-upgrade"
1331     #a3# Execute \kbd{apt-get install}
1332     salias agi="apt-get install"
1333     #a3# Execute \kbd{aptitude install}
1334     salias ati="aptitude install"
1335     #a3# Execute \kbd{apt-get upgrade}
1336     salias ag="apt-get upgrade"
1337     #a3# Execute \kbd{apt-get update}
1338     salias au="apt-get update"
1339     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1340     salias -a up="aptitude update ; aptitude safe-upgrade"
1341     #a3# Execute \kbd{dpkg-buildpackage}
1342     alias dbp='dpkg-buildpackage'
1343     #a3# Execute \kbd{grep-excuses}
1344     alias ge='grep-excuses'
1345
1346     # debian upgrade
1347     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
1348     upgrade() {
1349         if [[ -z "$1" ]] ; then
1350             $SUDO apt-get update
1351             $SUDO apt-get -u upgrade
1352         else
1353             ssh $1 $SUDO apt-get update
1354             # ask before the upgrade
1355             local dummy
1356             ssh $1 $SUDO apt-get --no-act upgrade
1357             echo -n 'Process the upgrade?'
1358             read -q dummy
1359             if [[ $dummy == "y" ]] ; then
1360                 ssh $1 $SUDO apt-get -u upgrade --yes
1361             fi
1362         fi
1363     }
1364
1365     isgrmlcd && alias su="sudo -s"          # get a root shell
1366     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1367     alias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1368     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1369     alias tlog="tail -f /var/log/syslog"    # follow the syslog
1370     #a1# (Re)-source \kbd{/etc/skel/.zshrc}
1371     alias zshskel="source /etc/skel/.zshrc" # source skeleton zshrc
1372 fi
1373
1374 # sort installed Debian-packages by size
1375 if check_com -c grep-status ; then
1376     #a3# List installed Debian-packages sorted by size
1377     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
1378 fi
1379
1380 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1381 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord ; then
1382     if check_com -c wodim ; then
1383         alias cdrecord="echo 'cdrecord is not provided under its original name by Debian anymore.
1384 See #377109 in the BTS of Debian for more details.
1385
1386 Please use the wodim binary instead' ; return 1"
1387     fi
1388 fi
1389
1390 # get_tw_cli has been renamed into get_3ware
1391 if check_com -c get_3ware ; then
1392     get_tw_cli() {
1393         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
1394         get_3ware
1395     }
1396 fi
1397
1398 # I hate lacking backward compatibility, so provide an alternative therefore
1399 if ! check_com -c apache2-ssl-certificate ; then
1400
1401     apache2-ssl-certificate() {
1402
1403     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
1404     print 'You might want to take a look at Debian the package ssl-cert as well.'
1405     print 'To generate a certificate for use with apache2 follow the instructions:'
1406
1407     echo '
1408
1409 export RANDFILE=/dev/random
1410 mkdir /etc/apache2/ssl/
1411 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
1412 chmod 600 /etc/apache2/ssl/apache.pem
1413
1414 Run "grml-tips ssl-certificate" if you need further instructions.
1415 '
1416     }
1417 fi
1418 # }}}
1419
1420 # {{{ Use hard limits, except for a smaller stack and no core dumps
1421 unlimit
1422 is4 && limit stack 8192
1423 isgrmlcd && limit core 0 # important for a live-cd-system
1424 limit -s
1425 # }}}
1426
1427 # {{{ completion system
1428
1429 # called later (via is4 && grmlcomp)
1430 # notice: use 'zstyle' for getting current settings
1431 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
1432 grmlcomp() {
1433     # TODO: This could use some additional information
1434
1435     # allow one error for every three characters typed in approximate completer
1436     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1437
1438     # don't complete backup files as executables
1439     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1440
1441     # start menu completion only if it could find no unambiguous initial string
1442     zstyle ':completion:*:correct:*'       insert-unambiguous true
1443     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1444     zstyle ':completion:*:correct:*'       original true
1445
1446     # activate color-completion
1447     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1448
1449     # format on completion
1450     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1451
1452     # complete 'cd -<tab>' with menu
1453     zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1454
1455     # insert all expansions for expand completer
1456     zstyle ':completion:*:expand:*'        tag-order all-expansions
1457     zstyle ':completion:*:history-words'   list false
1458
1459     # activate menu
1460     zstyle ':completion:*:history-words'   menu yes
1461
1462     # ignore duplicate entries
1463     zstyle ':completion:*:history-words'   remove-all-dups yes
1464     zstyle ':completion:*:history-words'   stop yes
1465
1466     # match uppercase from lowercase
1467     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1468
1469     # separate matches into groups
1470     zstyle ':completion:*:matches'         group 'yes'
1471     zstyle ':completion:*'                 group-name ''
1472
1473     if [[ -z "$NOMENU" ]] ; then
1474         # if there are more than 5 options allow selecting from a menu
1475         zstyle ':completion:*'               menu select=5
1476     else
1477         # don't use any menus at all
1478         setopt no_auto_menu
1479     fi
1480
1481     zstyle ':completion:*:messages'        format '%d'
1482     zstyle ':completion:*:options'         auto-description '%d'
1483
1484     # describe options in full
1485     zstyle ':completion:*:options'         description 'yes'
1486
1487     # on processes completion complete all user processes
1488     zstyle ':completion:*:processes'       command 'ps -au$USER'
1489
1490     # offer indexes before parameters in subscripts
1491     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1492
1493     # provide verbose completion information
1494     zstyle ':completion:*'                 verbose true
1495
1496     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1497     # for commands (read: 1st word in the line) that it will list for the user
1498     # to choose from. The following disables that, because it's not exactly fast.
1499     zstyle ':completion:*:-command-:*:'    verbose false
1500
1501     # set format for warnings
1502     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1503
1504     # define files to ignore for zcompile
1505     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1506     zstyle ':completion:correct:'          prompt 'correct to: %e'
1507
1508     # Ignore completion functions for commands you don't have:
1509     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1510
1511     # complete manual by their section
1512     zstyle ':completion:*:manuals'    separate-sections true
1513     zstyle ':completion:*:manuals.*'  insert-sections   true
1514     zstyle ':completion:*:man:*'      menu yes select
1515
1516     # run rehash on completion so new installed program are found automatically:
1517     _force_rehash() {
1518         (( CURRENT == 1 )) && rehash
1519         return 1
1520     }
1521
1522     ## correction
1523     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1524     if [[ -n "$NOCOR" ]] ; then
1525         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1526         setopt nocorrect
1527     else
1528         # try to be smart about when to use what completer...
1529         setopt correct
1530         zstyle -e ':completion:*' completer '
1531             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1532                 _last_try="$HISTNO$BUFFER$CURSOR"
1533                 reply=(_complete _match _ignored _prefix _files)
1534             else
1535                 if [[ $words[1] == (rm|mv) ]] ; then
1536                     reply=(_complete _files)
1537                 else
1538                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1539                 fi
1540             fi'
1541     fi
1542
1543     # zstyle ':completion:*' completer _complete _correct _approximate
1544     # zstyle ':completion:*' expand prefix suffix
1545
1546     # command for process lists, the local web server details and host completion
1547     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1548
1549     # caching
1550     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1551                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1552
1553     # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
1554     if is42 ; then
1555         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1556         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1557     else
1558         _ssh_hosts=()
1559         _etc_hosts=()
1560     fi
1561     hosts=(
1562         $(hostname)
1563         "$_ssh_hosts[@]"
1564         "$_etc_hosts[@]"
1565         grml.org
1566         localhost
1567     )
1568     zstyle ':completion:*:hosts' hosts $hosts
1569     #  zstyle '*' hosts $hosts
1570
1571     # specify your logins:
1572     # my_accounts=(
1573     #  {grml,grml1}@foo.invalid
1574     #  grml-devel@bar.invalid
1575     # )
1576     # other_accounts=(
1577     #  {fred,root}@foo.invalid
1578     #  vera@bar.invalid
1579     # )
1580     # zstyle ':completion:*:my-accounts' users-hosts $my_accounts
1581     # zstyle ':completion:*:other-accounts' users-hosts $other_accounts
1582
1583     # specify specific port/service settings:
1584     #  telnet_users_hosts_ports=(
1585     #    user1@host1:
1586     #    user2@host2:
1587     #    @mail-server:{smtp,pop3}
1588     #    @news-server:nntp
1589     #    @proxy-server:8000
1590     #  )
1591     # zstyle ':completion:*:*:telnet:*' users-hosts-ports $telnet_users_hosts_ports
1592
1593     # use generic completion system for programs not yet defined; (_gnu_generic works
1594     # with commands that provide a --help option with "standard" gnu-like output.)
1595     compdef _gnu_generic tail head feh cp mv df stow uname ipacsum fetchipac
1596
1597     # see upgrade function in this file
1598     compdef _hosts upgrade
1599 }
1600 # }}}
1601
1602 # {{{ grmlstuff
1603 grmlstuff() {
1604 # people should use 'grml-x'!
1605     startx() {
1606         if [[ -e /etc/X11/xorg.conf ]] ; then
1607             [[ -x /usr/bin/startx ]] && /usr/bin/startx "$@" || /usr/X11R6/bin/startx "$@"
1608         else
1609             echo "Please use the script \"grml-x\" for starting the X Window System
1610 because there does not exist /etc/X11/xorg.conf yet.
1611 If you want to use startx anyway please call \"/usr/bin/startx\"."
1612             return -1
1613         fi
1614     }
1615
1616     xinit() {
1617         if [[ -e /etc/X11/xorg.conf ]] ; then
1618             [[ -x /usr/bin/xinit ]] && /usr/bin/xinit || /usr/X11R6/bin/xinit
1619         else
1620             echo "Please use the script \"grml-x\" for starting the X Window System.
1621 because there does not exist /etc/X11/xorg.conf yet.
1622 If you want to use xinit anyway please call \"/usr/bin/xinit\"."
1623             return -1
1624         fi
1625     }
1626
1627     if check_com -c 915resolution ; then
1628         alias 855resolution='echo -e "Please use 915resolution as resolution modify tool for Intel graphic chipset."; return -1'
1629     fi
1630
1631     #a1# Output version of running grml
1632     alias grml-version='cat /etc/grml_version'
1633
1634     if check_com -c rebuildfstab ; then
1635         #a1# Rebuild /etc/fstab
1636         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1637     fi
1638
1639     if check_com -c grml-debootstrap ; then
1640         alias debian2hd='print "Installing debian to harddisk is possible via using grml-debootstrap." ; return 1'
1641     fi
1642 }
1643 # }}}
1644
1645 # {{{ now run the functions
1646 isgrml && checkhome
1647 is4    && isgrml    && grmlstuff
1648 is4    && grmlcomp
1649 # }}}
1650
1651 # {{{ keephack
1652 is4 && xsource "/etc/zsh/keephack"
1653 # }}}
1654
1655 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
1656 # You use it as follows:
1657 # $ NTREF=/reference/file
1658 # $ ls -l *(e:nt:)
1659 # This lists all the files in the current directory newer than the reference file.
1660 # You can also specify the reference file inline; note quotes:
1661 # $ ls -l *(e:'nt ~/.zshenv':)
1662 is4 && nt() {
1663     if [[ -n $1 ]] ; then
1664         local NTREF=${~1}
1665     fi
1666     [[ $REPLY -nt $NTREF ]]
1667 }
1668 # }}}
1669
1670 # shell functions {{{
1671
1672 #f1# Provide csh compatibility
1673 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
1674
1675 #f1# Reload an autoloadable function
1676 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1677
1678 #f1# Reload zsh setup
1679 reload() {
1680     if [[ "$#*" -eq 0 ]] ; then
1681         [[ -r ~/.zshrc ]] && . ~/.zshrc
1682     else
1683         local fn
1684         for fn in "$@"; do
1685             unfunction $fn
1686             autoload -U $fn
1687         done
1688     fi
1689 }
1690 compdef _functions reload freload
1691
1692 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1693 sll() {
1694     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1695     for i in "$@" ; do
1696         file=$i
1697         while [[ -h "$file" ]] ; do
1698             ls -l $file
1699             file=$(readlink "$file")
1700         done
1701     done
1702 }
1703
1704 # fast manual access
1705 if check_com qma ; then
1706     #f1# View the zsh manual
1707     manzsh()  { qma zshall "$1" }
1708     compdef _man qma
1709 else
1710     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
1711     # manzsh()  { /usr/bin/man zshall |  most +/"$1" ; }
1712     # [[ -f ~/.terminfo/m/mostlike ]] && MYLESS='LESS=C TERMINFO=~/.terminfo TERM=mostlike less' || MYLESS='less'
1713     # manzsh()  { man zshall | $MYLESS -p $1 ; }
1714 fi
1715
1716 if check_com -c $PAGER ; then
1717     #f1# View Debian's changelog of a given package
1718     dchange() {
1719         if [[ -r /usr/share/doc/${1}/changelog.Debian.gz ]] ; then
1720             $PAGER /usr/share/doc/${1}/changelog.Debian.gz
1721         elif [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
1722             $PAGER /usr/share/doc/${1}/changelog.gz
1723         else
1724             if check_com -c aptitude ; then
1725                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1726                 if isgrml ; then
1727                     aptitude -t unstable changelog ${1}
1728                 else
1729                     aptitude changelog ${1}
1730                 fi
1731             else
1732                 echo "No changelog for package $1 found, sorry."
1733                 return 1
1734             fi
1735         fi
1736     }
1737     _dchange() { _files -W /usr/share/doc -/ }
1738     compdef _dchange dchange
1739
1740     #f1# View Debian's NEWS of a given package
1741     dnews() {
1742         if [[ -r /usr/share/doc/${1}/NEWS.Debian.gz ]] ; then
1743             $PAGER /usr/share/doc/${1}/NEWS.Debian.gz
1744         else
1745             if [[ -r /usr/share/doc/${1}/NEWS.gz ]] ; then
1746                 $PAGER /usr/share/doc/${1}/NEWS.gz
1747             else
1748                 echo "No NEWS file for package $1 found, sorry."
1749                 return 1
1750             fi
1751         fi
1752     }
1753     _dnews() { _files -W /usr/share/doc -/ }
1754     compdef _dnews dnews
1755
1756     #f1# View upstream's changelog of a given package
1757     uchange() {
1758         if [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
1759             $PAGER /usr/share/doc/${1}/changelog.gz
1760         else
1761             echo "No changelog for package $1 found, sorry."
1762             return 1
1763         fi
1764     }
1765     _uchange() { _files -W /usr/share/doc -/ }
1766     compdef _uchange uchange
1767 fi
1768
1769 # zsh profiling
1770 profile() {
1771     ZSH_PROFILE_RC=1 $SHELL "$@"
1772 }
1773
1774 #f1# Edit an alias via zle
1775 edalias() {
1776     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1777 }
1778 compdef _aliases edalias
1779
1780 #f1# Edit a function via zle
1781 edfunc() {
1782     [[ -z "$1" ]] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
1783 }
1784 compdef _functions edfunc
1785
1786 # use it e.g. via 'Restart apache2'
1787 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
1788 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
1789 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
1790 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
1791 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
1792 if [[ -d /etc/init.d ]] ; then
1793     for i in Start Restart Stop Force-Reload Reload ; do
1794         eval "$i() { $SUDO /etc/init.d/\$1 ${i:l} \$2 ; }"
1795     done
1796 fi
1797
1798 #f1# Provides useful information on globbing
1799 H-Glob() {
1800     echo -e "
1801     /      directories
1802     .      plain files
1803     @      symbolic links
1804     =      sockets
1805     p      named pipes (FIFOs)
1806     *      executable plain files (0100)
1807     %      device files (character or block special)
1808     %b     block special files
1809     %c     character special files
1810     r      owner-readable files (0400)
1811     w      owner-writable files (0200)
1812     x      owner-executable files (0100)
1813     A      group-readable files (0040)
1814     I      group-writable files (0020)
1815     E      group-executable files (0010)
1816     R      world-readable files (0004)
1817     W      world-writable files (0002)
1818     X      world-executable files (0001)
1819     s      setuid files (04000)
1820     S      setgid files (02000)
1821     t      files with the sticky bit (01000)
1822
1823   print *(m-1)          # Files modified up to a day ago
1824   print *(a1)           # Files accessed a day ago
1825   print *(@)            # Just symlinks
1826   print *(Lk+50)        # Files bigger than 50 kilobytes
1827   print *(Lk-50)        # Files smaller than 50 kilobytes
1828   print **/*.c          # All *.c files recursively starting in \$PWD
1829   print **/*.c~file.c   # Same as above, but excluding 'file.c'
1830   print (foo|bar).*     # Files starting with 'foo' or 'bar'
1831   print *~*.*           # All Files that do not contain a dot
1832   chmod 644 *(.^x)      # make all plain non-executable files publically readable
1833   print -l *(.c|.h)     # Lists *.c and *.h
1834   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
1835   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
1836 }
1837 alias help-zshglob=H-Glob
1838
1839 check_com -c qma && alias ?='qma zshall'
1840
1841 # grep for running process, like: 'any vim'
1842 any() {
1843     if [[ -z "$1" ]] ; then
1844         echo "any - grep for process(es) by keyword" >&2
1845         echo "Usage: any <keyword>" >&2 ; return 1
1846     else
1847         local STRING=$1
1848         local LENGTH=$(expr length $STRING)
1849         local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
1850         local REST=$(echo $(expr substr $STRING 2 $LENGTH))
1851         ps xauwww| grep "[$FIRSCHAR]$REST"
1852     fi
1853 }
1854
1855 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
1856 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
1857 [[ -r /proc/1/maps ]] && \
1858 deswap() {
1859     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
1860     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
1861     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
1862 }
1863
1864 # print hex value of a number
1865 hex() {
1866     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
1867 }
1868
1869 # calculate (or eval at all ;-)) with perl => p[erl-]eval
1870 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
1871 peval() {
1872     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
1873     perl -e "print eval($CALC),\"\n\";"
1874 }
1875 functions peval &>/dev/null && alias calc=peval
1876
1877 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
1878 # certain circumstances, so work around it, no matter which environment we have
1879 brltty() {
1880     if [[ -z "$DISPLAY" ]] ; then
1881         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
1882         command brltty "$@"
1883     else
1884         command brltty "$@"
1885     fi
1886 }
1887
1888 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
1889 aoeu() {
1890     echo -n 'Switching to us keyboard layout: '
1891     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
1892     echo 'Done'
1893 }
1894 asdf() {
1895     echo -n 'Switching to dvorak keyboard layout: '
1896     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
1897     echo 'Done'
1898 }
1899 # just press 'asdf' key to toggle from neon layout to us keyboard layout
1900 uiae() {
1901     echo -n 'Switching to us keyboard layout: '
1902     setxkbmap us && echo 'Done' || echo 'Failed'
1903 }
1904
1905 # set up an ipv6 tunnel
1906 ipv6-tunnel() {
1907     case $1 in
1908         start)
1909             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1910                 print 'ipv6 tunnel already set up, nothing to be done.'
1911                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
1912             else
1913                 [[ -n "$PUBLIC_IP" ]] || \
1914                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
1915                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
1916
1917                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
1918                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
1919                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
1920                 ifconfig sit0 tunnel ::192.88.99.1 up
1921                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
1922             fi
1923             ;;
1924         status)
1925             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1926                 print 'ipv6 tunnel available' ; return 0
1927             else
1928                 print 'ipv6 tunnel not available' ; return 1
1929             fi
1930             ;;
1931         stop)
1932             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1933                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
1934                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
1935             else
1936                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
1937             fi
1938             ;;
1939         *)
1940             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
1941             ;;
1942     esac
1943 }
1944
1945 # run dhclient for wireless device
1946 iwclient() {
1947     salias dhclient "$(wavemon -d | awk '/device/{print $2}')"
1948 }
1949
1950 # spawn a minimally set up ksh - useful if you want to umount /usr/.
1951 minimal-shell() {
1952     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ksh
1953 }
1954
1955 # make a backup of a file
1956 bk() {
1957     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
1958 }
1959
1960 # Switching shell safely and efficiently? http://www.zsh.org/mla/workers/2001/msg02410.html
1961 # bash() {
1962 #  NO_SWITCH="yes" command bash "$@"
1963 # }
1964 # restart () {
1965 #  exec $SHELL $SHELL_ARGS "$@"
1966 # }
1967
1968 # }}}
1969
1970 # log out? set timeout in seconds {{{
1971 # TMOUT=1800
1972 # do not log out in some specific terminals:
1973 #  if [[ "${TERM}" == ([Exa]term*|rxvt|dtterm|screen*) ]] ; then
1974 #    unset TMOUT
1975 #  fi
1976 # }}}
1977
1978 # {{{ make sure our environment is clean regarding colors
1979 for color in BLUE RED GREEN CYAN WHITE ; unset $color
1980 # }}}
1981
1982 # source another config file if present {{{
1983 xsource "/etc/zsh/zshrc.local"
1984 # }}}
1985
1986 # "persistent history" {{{
1987 # just write important commands you always need to ~/.important_commands
1988 if [[ -r ~/.important_commands ]] ; then
1989     fc -R ~/.important_commands
1990 fi
1991 # }}}
1992
1993 ## genrefcard.pl settings {{{
1994 ### example: split functions-search 8,16,24,32
1995 #@# split functions-search 8
1996 ## }}}
1997
1998 # add variable to be able to check whether the file has been read {{{
1999 ZSHRC_GLOBAL_HAS_BEEN_READ=1
2000 # }}}
2001
2002 ## END OF FILE #################################################################
2003 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4