etc/zsh/zshrc

   1 # Filename:      zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 # Latest change: Sam Dez 22 19:17:27 CET 2007 [mika]
   7 ################################################################################
   8 # This file is sourced only for interactive shells. It
   9 # should contain commands to set up aliases, functions,
  10 # options, key bindings, etc.
  11 #
  12 # Global Order: zshenv, zprofile, zshrc, zlogin
  13 ################################################################################
  14
  15 # zsh-refcard-tag documentation: {{{
  16 #   You may notice strange looking comments in the zshrc (and ~/.zshrc as
  17 #   well). These are there for a purpose. grml's zsh-refcard can now be
  18 #   automatically generated from the contents of the actual configuration
  19 #   files. However, we need a little extra information on which comments
  20 #   and what lines of code to take into account (and for what purpose).
  21 #
  22 # Here is what they mean:
  23 #
  24 # List of tags (comment types) used:
  25 #   #a#     Next line contains an important alias, that should
  26 #           be included in the grml-zsh-refcard.
  27 #           (placement tag: @@INSERT-aliases@@)
  28 #   #f#     Next line contains the beginning of an important function.
  29 #           (placement tag: @@INSERT-functions@@)
  30 #   #v#     Next line contains an important variable.
  31 #           (placement tag: @@INSERT-variables@@)
  32 #   #k#     Next line contains an important keybinding.
  33 #           (placement tag: @@INSERT-keybindings@@)
  34 #   #d#     Hashed directories list generation:
  35 #               start   denotes the start of a list of 'hash -d'
  36 #                       definitions.
  37 #               end     denotes its end.
  38 #           (placement tag: @@INSERT-hasheddirs@@)
  39 #   #A#     Abbreviation expansion list generation:
  40 #               start   denotes the beginning of abbreviations.
  41 #               end     denotes their end.
  42 #           Lines within this section that end in '#d .*' provide
  43 #           extra documentation to be included in the refcard.
  44 #           (placement tag: @@INSERT-abbrev@@)
  45 #   #m#     This tag allows you to manually generate refcard entries
  46 #           for code lines that are hard/impossible to parse.
  47 #               Example:
  48 #                   #m# k ESC-h Call the run-help function
  49 #               That would add a refcard entry in the keybindings table
  50 #               for 'ESC-h' with the given comment.
  51 #           So the syntax is: #m# <section> <argument> <comment>
  52 #   #o#     This tag lets you insert entries to the 'other' hash.
  53 #           Generally, this should not be used. It is there for
  54 #           things that cannot be done easily in another way.
  55 #           (placement tag: @@INSERT-other-foobar@@)
  56 #
  57 #   All of these tags (except for m and o) take two arguments, the first
  58 #   within the tag, the other after the tag:
  59 #
  60 #   #<tag><section># <comment>
  61 #
  62 #   Where <section> is really just a number, which are defined by the
  63 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  64 #   instead of names is, that for the reader, the tag should not differ
  65 #   much from a regular comment. For zsh, it is a regular comment indeed.
  66 #   The numbers have got the following meanings:
  67 #         0 -> "default"
  68 #         1 -> "system"
  69 #         2 -> "user"
  70 #         3 -> "debian"
  71 #         4 -> "search"
  72 #         5 -> "shortcuts"
  73 #         6 -> "services"
  74 #
  75 #   So, the following will add an entry to the 'functions' table in the
  76 #   'system' section, with a (hopefully) descriptive comment:
  77 #       #f1# Edit an alias via zle
  78 #       edalias() {
  79 #
  80 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  81 #   that can be found in 'grml-zsh-refcard.tex.in'.
  82 #   If the section number is omitted, the 'default' section is assumed.
  83 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
  84 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
  85 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
  86 #}}}
  87
  88 # zsh profiling {{{
  89 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
  90 if [[ -n $ZSH_PROFILE_RC ]] ; then
  91     zmodload zsh/zprof
  92 fi
  93 # }}}
  94
  95 # utility functions {{{
  96 # this function checks if a command exists and returns either true
  97 # or false. This avoids using 'which' and 'whence', which will
  98 # avoid problems with aliases for which on certain weird systems. :-)
  99 check_com() {
 100     local -i comonly
 101
 102     if [[ ${1} == '-c' ]] ; then
 103         (( comonly = 1 ))
 104         shift
 105     else
 106         (( comonly = 0 ))
 107     fi
 108
 109     if (( ${#argv} != 1 )) ; then
 110         printf 'usage: check_com [-c] <command>\n' >&2
 111         return 1
 112     fi
 113
 114     if (( comonly > 0 )) ; then
 115         [[ -n ${commands[$1]}  ]] && return 0
 116         return 1
 117     fi
 118
 119     if   [[ -n ${commands[$1]}    ]] \
 120       || [[ -n ${functions[$1]}   ]] \
 121       || [[ -n ${aliases[$1]}     ]] \
 122       || [[ -n ${reswords[(r)$1]} ]] ; then
 123
 124         return 0
 125     fi
 126
 127     return 1
 128 }
 129
 130 # creates an alias and precedes the command with
 131 # sudo if $EUID is not zero.
 132 salias() {
 133     local only=0 ; local multi=0
 134     while [[ ${1} == -* ]] ; do
 135         case ${1} in
 136             (-o) only=1 ;;
 137             (-a) multi=1 ;;
 138             (--) shift ; break ;;
 139             (-h)
 140                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 141                 printf '  -h      shows this help text.\n'
 142                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 143                 printf '          be careful using this option.\n'
 144                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 145                 return 0
 146                 ;;
 147             (*) printf "unkown option: '%s'\n" "${1}" ; return 1 ;;
 148         esac
 149         shift
 150     done
 151
 152     if (( ${#argv} > 1 )) ; then
 153         printf 'Too many arguments %s\n' "${#argv}"
 154         return 1
 155     fi
 156
 157     key="${1%%\=*}" ;  val="${1#*\=}"
 158     if (( EUID == 0 )) && (( only == 0 )); then
 159         alias -- "${key}=${val}"
 160     elif (( EUID > 0 )) ; then
 161         (( multi > 0 )) && val="${val// ; / ; sudo }"
 162         alias -- "${key}=sudo ${val}"
 163     fi
 164
 165     return 0
 166 }
 167
 168 # Check if we can read given files and source those we can.
 169 xsource() {
 170     if (( ${#argv} < 1 )) ; then
 171         printf 'usage: xsource FILE(s)...\n' >&2
 172         return 1
 173     fi
 174
 175     while (( ${#argv} > 0 )) ; do
 176         [[ -r ${1} ]] && source ${1}
 177         shift
 178     done
 179     return 0
 180 }
 181
 182 # Check if we can read a given file and 'cat(1)' it.
 183 xcat() {
 184     if (( ${#argv} != 1 )) ; then
 185         printf 'usage: xcat FILE\n' >&2
 186         return 1
 187     fi
 188
 189     [[ -r ${1} ]] && cat ${1}
 190     return 0
 191 }
 192
 193 # Remove these functions again, they are of use only in these
 194 # setup files. This should be called at the end of .zshrc.
 195 xunfunction() {
 196     local -a funcs
 197     funcs=(check_com salias xcat xsource xunfunction)
 198
 199     for func in $funcs ; do
 200         [[ -n ${functions[$func]} ]] \
 201             && unfunction $func
 202     done
 203     return 0
 204 }
 205 #}}}
 206
 207 # locale setup {{{
 208 if [[ -z "$LANG" ]] ; then
 209     xsource "/etc/default/locale"
 210 fi
 211
 212 export LANG=${LANG:-en_US.iso885915}
 213 for var in LC_ALL LC_MESSAGES ; do
 214     [[ -n ${(P)var} ]] && export $var
 215 done
 216
 217 xsource "/etc/sysconfig/keyboard"
 218
 219 TZ=$(xcat /etc/timezone)
 220 # }}}
 221
 222 # check for potentially old files in 'completion.d' {{{
 223 setopt extendedglob
 224 xof=(/etc/zsh/completion.d/*~/etc/zsh/completion.d/_*(N))
 225 if (( ${#xof} > 0 )) ; then
 226     printf '\n -!- INFORMATION\n\n'
 227     printf ' -!- %s file(s) not starting with an underscore (_) found in\n' ${#xof}
 228     printf ' -!- /etc/zsh/completion.d/.\n\n'
 229     printf ' -!- While this has been the case in old versions of grml-etc-core,\n'
 230     printf ' -!- recent versions of the grml-zsh-setup have all these files rewritten\n'
 231     printf ' -!- and renamed. Furthermore, the grml-zsh-setup will *only* add files\n'
 232     printf ' -!- named _* to that directory.\n\n'
 233     printf ' -!- If you added functions to completion.d yourself, please consider\n'
 234     printf ' -!- moving them to /etc/zsh/functions.d/. Files in that directory, not\n'
 235     printf ' -!- starting with an underscore are marked for automatic loading\n'
 236     printf ' -!- by default (so that is quite convenient).\n\n'
 237     printf ' -!- If there are files *not* starting with an underscore from an older\n'
 238     printf ' -!- grml-etc-core in completion.d, you may safely remove them.\n\n'
 239     printf ' -!- Delete the files for example via running:\n\n'
 240     printf "      rm ${xof}\n\n"
 241     printf ' -!- Note, that this message will *not* go away, unless you yourself\n'
 242     printf ' -!- resolve the situation manually.\n\n'
 243     BROKEN_COMPLETION_DIR=1
 244 fi
 245 unset xof
 246 # }}}
 247
 248 # {{{ check for version/system
 249 # check for versions (compatibility reasons)
 250 if autoload is-at-least && is-at-least 2>/dev/null ; then
 251     is4()  { is-at-least 4 }
 252     is41() { is-at-least 4.1 }
 253     is42() { is-at-least 4.2 }
 254 else
 255     is4(){
 256         [[ $ZSH_VERSION == 4.* ]] && return 0
 257         return 1
 258     }
 259     is42(){
 260         [[ $ZSH_VERSION == 4.<2->* ]] && return 0
 261         return 1
 262     }
 263 fi
 264
 265 #f1# Checks whether or not you're running grml
 266 isgrml(){
 267     [[ -f /etc/grml_version ]] && return 0
 268     return 1
 269 }
 270
 271 #f1# Checks whether or not you're running a grml cd
 272 isgrmlcd(){
 273     [[ -f /etc/grml_cd ]] && return 0
 274     return 1
 275 }
 276
 277 if isgrml ; then
 278 #f1# Checks whether or not you're running grml-small
 279     isgrmlsmall() {
 280         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 281     }
 282 else
 283     isgrmlsmall() { return 1 }
 284 fi
 285
 286 #f1# are we running within an utf environment?
 287 isutfenv() {
 288     case "$LANG $CHARSET $LANGUAGE" in
 289         *utf*) return 0 ;;
 290         *UTF*) return 0 ;;
 291         *)     return 1 ;;
 292     esac
 293 }
 294
 295 # check for user, if not running as root set $SUDO to sudo
 296 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 297
 298 # change directory to home on first invocation of zsh
 299 # important for rungetty -> autologin
 300 # Thanks go to Bart Schaefer!
 301 isgrml && checkhome() {
 302     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 303         export ALREADY_DID_CD_HOME=$HOME
 304         cd
 305     fi
 306 }
 307 # }}}
 308
 309 # {{{ set some variables
 310 #v#
 311 if check_com -c vim ; then
 312     export EDITOR=${EDITOR:-vim}
 313 else
 314     export EDITOR=${EDITOR:-vi}
 315 fi
 316 #v#
 317
 318 export MAIL=${MAIL:-/var/mail/$USER}
 319
 320 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 321 export SHELL='/bin/zsh'
 322
 323 # color setup for ls:
 324 check_com -c dircolors && eval $(dircolors -b)
 325
 326 # set width of man pages to 80 for more convenient reading
 327 # (( ${+MANWIDTH} )) || export MANWIDTH=80
 328
 329 # Search path for the cd command
 330 #  cdpath=(.. ~)
 331
 332 # completion functions go to /etc/zsh/completion.d
 333 # function files may be put into /etc/zsh/functions.d, from where they
 334 # will be automatically autoloaded.
 335 if [[ -n "$BROKEN_COMPLETION_DIR" ]] ; then
 336     print 'Warning: not setting completion directories because broken files have been found.' >&2
 337 else
 338     [[ -d /etc/zsh/completion.d ]] && fpath+=( /etc/zsh/completion.d )
 339     if [[ -d /etc/zsh/functions.d ]] ; then
 340         fpath+=( /etc/zsh/functions.d )
 341         for func in /etc/zsh/functions.d/[^_]*[^~] ; do
 342             autoload -U ${func:t}
 343         done
 344     fi
 345 fi
 346
 347 # automatically remove duplicates from these arrays
 348 typeset -U path cdpath fpath manpath
 349 # }}}
 350
 351 # {{{ keybindings
 352 if [[ "$TERM" != emacs ]] ; then
 353     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 354     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 355     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 356     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 357     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 358     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 359     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 360     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 361     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 362     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 363     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 364     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 365     # ncurses stuff:
 366     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 367     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 368     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 369     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 370     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 371     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 372     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 373     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 374 fi
 375
 376 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 377 # use emacs style per default:
 378 bindkey -e
 379 # use vi style:
 380 # bindkey -v
 381
 382 #if [[ "$TERM" == screen ]] ; then
 383 bindkey '\e[1~' beginning-of-line       # home
 384 bindkey '\e[4~' end-of-line             # end
 385 bindkey '\e[A'  up-line-or-search       # cursor up
 386 bindkey '\e[B'  down-line-or-search     # <ESC>-
 387 bindkey '^x'    history-beginning-search-backward # alternative ways of searching the shell history
 388 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 389 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 390 # if terminal type is set to 'rxvt':
 391 bindkey '\e[7~' beginning-of-line       # home
 392 bindkey '\e[8~' end-of-line             # end
 393 #fi
 394
 395 # insert unicode character
 396 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 397 # See for example http://unicode.org/charts/ for unicode characters code
 398 autoload insert-unicode-char
 399 zle -N insert-unicode-char
 400 #k# Insert Unicode character
 401 bindkey '^Xi' insert-unicode-char
 402
 403 # just type 'cd ...' to get 'cd ../..'
 404 #  rationalise-dot() {
 405 #  if [[ $LBUFFER == *.. ]] ; then
 406 #    LBUFFER+=/..
 407 #  else
 408 #    LBUFFER+=.
 409 #  fi
 410 #  }
 411 #  zle -N rationalise-dot
 412 #  bindkey . rationalise-dot
 413
 414 #  bindkey '\eq' push-line-or-edit
 415 # }}}
 416
 417 # power completion - abbreviation expansion {{{
 418 # power completion / abbreviation expansion / buffer expansion
 419 # see http://zshwiki.org/home/examples/zleiab for details
 420 # less risky than the global aliases but powerful as well
 421 # just type the abbreviation key and afterwards ',.' to expand it
 422 declare -A abk
 423 setopt extendedglob
 424 setopt interactivecomments
 425 abk=(
 426 # key  # value                (#d additional doc string)
 427 #A# start
 428     '...' '../..'
 429     '....' '../../..'
 430     'BG' '& exit'
 431     'C' '| wc -l'
 432     'G' '|& grep --color=auto'
 433     'H' '| head'
 434     'Hl' ' --help |& less -r'      #d (Display help in pager)
 435     'L' '| less'
 436     'LL' '|& less -r'
 437     'M' '| most'
 438     'N' '&>/dev/null'              #d (No Output)
 439     'R' '| tr A-z N-za-m'          #d (ROT13)
 440     'SL' '| sort | less'
 441     'S' '| sort -u'
 442     'T' '| tail'
 443     'V' '|& vim -'
 444 #A# end
 445     'hide' "echo -en '\033]50;nil2\007'"
 446     'tiny' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
 447     'small' 'echo -en "\033]50;6x10\007"'
 448     'medium' 'echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
 449     'default' 'echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
 450     'large' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
 451     'huge' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
 452     'smartfont' 'echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
 453     'semifont' 'echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
 454     'da' 'du -sch'
 455     'j' 'jobs -l'
 456     'u' 'translate -i'
 457     'co' "./configure && make && sudo make install"
 458     'CH' "./configure --help"
 459     'conkeror' 'firefox -chrome chrome://conkeror/content'
 460     'dir' 'ls -lSrah'
 461     'lad' $'ls -d .*(/)\n# only show dot-directories'
 462     'lsa' $'ls -a .*(.)\n# only show dot-files'
 463     'lss' $'ls -l *(s,S,t)\n# only files with setgid/setuid/sticky flag'
 464     'lsl' $'ls -l *(@[1,10])\n# only symlinks'
 465     'lsx' $'ls -l *(*[1,10])\n# only executables'
 466     'lsw' $'ls -ld *(R,W,X.^ND/)\n# world-{readable,writable,executable} files'
 467     'lsbig' $'ls -flh *(.OL[1,10])\n# display the biggest files'
 468     'lsd' $'ls -d *(/)\n# only show directories'
 469     'lse' $'ls -d *(/^F)\n# only show empty directories'
 470     'lsnew' $'ls -rl *(D.om[1,10])\n# display the newest files'
 471     'lsold' $'ls -rtlh *(D.om[-11,-1])\n # display the oldest files'
 472     'lssmall' $'ls -Srl *(.oL[1,10])\n# display the smallest files'
 473     'rw-' 'chmod 600'
 474     '600' 'chmod u+rw-x,g-rwx,o-rwx'
 475     'rwx' 'chmod u+rwx'
 476     '700' 'chmod u+rwx,g-rwx,o-rwx'
 477     'r--' 'chmod u+r-wx,g-rwx,o-rwx'
 478     '644' $'chmod u+rw-x,g+r-wx,o+r-wx\n # 4=r,2=w,1=x'
 479     '755' 'chmod u+rwx,g+r-w+x,o+r-w+x'
 480     'md' 'mkdir -p '
 481     'cmplayer' 'mplayer -vo -fs -zoom fbdev'
 482     'fbmplayer' 'mplayer -vo -fs -zoom fbdev'
 483     'fblinks' 'links2 -driver fb'
 484     'insecssh' 'ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 485     'insecscp' 'scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 486     'fori' 'for i ({..}) { }'
 487     'cx' 'chmod +x'
 488     'e'  'print -l'
 489     'se' 'setopt interactivecomments'
 490     'va' 'valac --vapidir=../vapi/ --pkg=gtk+-2.0 gtktest.vala'
 491     'fb2' '=mplayer -vo fbdev -fs -zoom 1>/dev/null -xy 2'
 492     'fb3' '=mplayer -vo fbdev -fs  -zoom 1>/dev/null -xy 3'
 493     'ci' 'centericq'
 494     'D'  'export DISPLAY=:0.0'
 495     'mp' 'mplayer -vo xv -fs -zoom'
 496 )
 497
 498 globalias() {
 499     local MATCH
 500     matched_chars='[.-|_a-zA-Z0-9]#'
 501     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 502     LBUFFER+=${abk[$MATCH]:-$MATCH}
 503 }
 504
 505 zle -N globalias
 506 bindkey ",." globalias
 507 # }}}
 508
 509 # {{{ autoloading
 510 autoload -U zmv    # who needs mmv or rename?
 511 autoload history-search-end
 512
 513 # we don't want to quote/espace URLs on our own...
 514 # if autoload -U url-quote-magic ; then
 515 #    zle -N self-insert url-quote-magic
 516 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 517 # else
 518 #    print 'Notice: no url-quote-magic available :('
 519 # fi
 520 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 521
 522 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 523 alias run-help >&/dev/null && unalias run-help
 524 autoload run-help # use via 'esc-h'
 525
 526 # completion system
 527 if autoload -U compinit && compinit 2>/dev/null ; then
 528     compinit 2>/dev/null || print 'Notice: no compinit available :('
 529 else
 530     print 'Notice: no compinit available :('
 531     function zstyle { }
 532     function compdef { }
 533 fi
 534
 535 is4 && autoload -U zed # use ZLE editor to edit a file or function
 536
 537 is4 && \
 538 for mod in complist deltochar mathfunc ; do
 539     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 540 done
 541
 542 # autoload zsh modules when they are referenced
 543 if is4 ; then
 544     tmpargs=(
 545         a   stat
 546         a   zpty
 547         ap  zprof
 548         ap  mapfile
 549     )
 550
 551     while (( ${#tmpargs} > 0 )) ; do
 552         zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
 553         shift 2 tmpargs
 554     done
 555     unset tmpargs
 556 fi
 557
 558 if is4 && autoload -U insert-files && zle -N insert-files ; then
 559     #k# Insert files
 560     bindkey "^Xf" insert-files # C-x-f
 561 fi
 562
 563 bindkey ' '   magic-space    # also do history expansion on space
 564 #k# Trigger menu-complete
 565 bindkey '\ei' menu-complete  # menu completion via esc-i
 566
 567 # press esc-e for editing command line in $EDITOR or $VISUAL
 568 if is4 && autoload -U edit-command-line && zle -N edit-command-line ; then
 569     #k# Edit the current line in \kbd{\$EDITOR}
 570     bindkey '\ee' edit-command-line
 571 fi
 572
 573 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 574     #k# menu selection: pick item but stay in the menu
 575     bindkey -M menuselect '\e^M' accept-and-menu-complete
 576
 577     # use the vi navigation keys (hjkl) besides cursor keys in menu completion
 578     #bindkey -M menuselect 'h' vi-backward-char        # left
 579     #bindkey -M menuselect 'k' vi-up-line-or-history   # up
 580     #bindkey -M menuselect 'l' vi-forward-char         # right
 581     #bindkey -M menuselect 'j' vi-down-line-or-history # bottom
 582
 583     # accept a completion and try to complete again by using menu
 584     # completion; very useful with completing directories
 585     # by using 'undo' one's got a simple file browser
 586     bindkey -M menuselect '^o' accept-and-infer-next-history
 587 fi
 588
 589 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 590 _bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
 591 zle -N _bkdate
 592
 593 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 594 bindkey '^Ed' _bkdate
 595
 596 # press esc-m for inserting last typed word again (thanks to caphuso!)
 597 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 598 zle -N insert-last-typed-word;
 599
 600 #k# Insert last typed word
 601 bindkey "\em" insert-last-typed-word
 602
 603 # set command prediction from history, see 'man 1 zshcontrib'
 604 #  is4 && autoload -U predict-on && \
 605 #  zle -N predict-on         && \
 606 #  zle -N predict-off        && \
 607 #  bindkey "^X^Z" predict-on && \
 608 #  bindkey "^Z" predict-off
 609
 610 #k# Shortcut for \kbd{fg<enter>}
 611 bindkey -s '^z' "fg\n"
 612
 613 # press ctrl-q to quote line:
 614 #  mquote () {
 615 #        zle beginning-of-line
 616 #        zle forward-word
 617 #        # RBUFFER="'$RBUFFER'"
 618 #        RBUFFER=${(q)RBUFFER}
 619 #        zle end-of-line
 620 #  }
 621 #  zle -N mquote && bindkey '^q' mquote
 622
 623 # run command line as user root via sudo:
 624 sudo-command-line() {
 625     [[ -z $BUFFER ]] && zle up-history
 626     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
 627 }
 628 zle -N sudo-command-line
 629
 630 #k# Put the current command line into a \kbd{sudo} call
 631 bindkey "^Os" sudo-command-line
 632
 633 ### jump behind the first word on the cmdline.
 634 ### useful to add options.
 635 function jump_after_first_word() {
 636     local words
 637     words=(${(z)BUFFER})
 638
 639     if (( ${#words} <= 1 )) ; then
 640         CURSOR=${#BUFFER}
 641     else
 642         CURSOR=${#${words[1]}}
 643     fi
 644 }
 645 zle -N jump_after_first_word
 646
 647 bindkey '^x1' jump_after_first_word
 648
 649 # }}}
 650
 651 # {{{ set some important options
 652 # Please update these tags, if you change the umask settings below.
 653 #o# r_umask     002
 654 #o# r_umaskstr  rwxrwxr-x
 655 #o# umask       022
 656 #o# umaskstr    rwxr-xr-x
 657 (( EUID != 0 )) && umask 002 || umask 022
 658
 659 # history:
 660 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 661 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 662 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 663 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 664                             # list duplicates an older one, the older command is removed from the list
 665 setopt histignorespace      # remove command lines from the history list when
 666                             # the first character on the line is a space
 667 #  setopt histallowclobber    # add `|' to output redirections in the history
 668 #  setopt NO_clobber          # warning if file exists ('cat /dev/null > ~/.zshrc')
 669 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 670                             # and the command is the name of a directory, perform the cd command to that directory
 671 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 672                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 673                             # -> searches for word not in compressed files
 674                             # don't forget to quote '^', '~' and '#'!
 675 setopt notify               # report the status of backgrounds jobs immediately
 676 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 677                             # the entire command path is hashed first.
 678 setopt completeinword       # not just at the end
 679 # setopt nocheckjobs          # don't warn me about bg processes when exiting
 680 setopt nohup                # and don't kill them, either
 681 # setopt printexitvalue       # alert me if something failed
 682 # setopt dvorak               # with spelling correction, assume dvorak kb
 683 setopt auto_pushd           # make cd push the old directory onto the directory stack.
 684 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 685 setopt nobeep               # avoid "beep"ing
 686 setopt pushd_ignore_dups    # don't push the same dir twice.
 687
 688 MAILCHECK=30       # mailchecks
 689 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 690 watch=(notme root) # watch for everyone but me and root
 691
 692 # define word separators (for stuff like backward-word, forward-word, backward-kill-word,..)
 693 #  WORDCHARS='*?_-.[]~=/&;!#$%^(){}<>' # the default
 694 #  WORDCHARS=.
 695 #  WORDCHARS='*?_[]~=&;!#$%^(){}'
 696 #  WORDCHARS='${WORDCHARS:s@/@}'
 697
 698 # only slash should be considered as a word separator:
 699 slash-backward-kill-word() {
 700     local WORDCHARS="${WORDCHARS:s@/@}"
 701     # zle backward-word
 702     zle backward-kill-word
 703 }
 704 zle -N slash-backward-kill-word
 705
 706 #k# Kill everything in a word up to its last \kbd{/}
 707 bindkey '\ev' slash-backward-kill-word
 708
 709 # }}}
 710
 711 # {{{ history
 712
 713 ZSHDIR=$HOME/.zsh
 714
 715 #v#
 716 HISTFILE=$HOME/.zsh_history
 717 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
 718 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
 719
 720 # }}}
 721
 722 # dirstack handling {{{
 723
 724 DIRSTACKSIZE=20
 725 if [[ -f ~/.zdirs ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
 726     dirstack=( ${(f)"$(< ~/.zdirs)"} )
 727     # "cd -" won't work after login by just setting $OLDPWD, so
 728     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
 729 fi
 730
 731 chpwd() {
 732     builtin dirs -pl >! ~/.zdirs
 733 }
 734
 735 # }}}
 736
 737 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
 738 if [[ -n "$BATTERY" ]] ; then
 739     if check_com -c acpi ; then
 740         PERCENT="${(C)${(s| |)$(acpi 2>/dev/null)}[4]}"
 741         [[ -z "$PERCENT" ]] && PERCENT='acpi not present'
 742
 743         if [[ "${PERCENT%%%}" -lt 20 ]] ; then
 744             PERCENT="warning: ${PERCENT}%"
 745         fi
 746     fi
 747 fi
 748 # }}}
 749
 750 # display version control information on right side of prompt if $VCS is set {{{
 751 # based on Mike Hommey's http://web.glandium.org/blog/?p=170
 752 __vcs_dir() {
 753     local vcs base_dir sub_dir ref
 754
 755     sub_dir() {
 756       local sub_dir
 757       sub_dir=$(readlink -f "${PWD}")
 758       sub_dir=${sub_dir#$1}
 759       echo ${sub_dir#/}
 760     }
 761
 762     git_dir() {
 763       base_dir=$(git-rev-parse --show-cdup 2>/dev/null) || return 1
 764       base_dir=$(readlink -f "$base_dir/..")
 765       sub_dir=$(git-rev-parse --show-prefix)
 766       sub_dir=${sub_dir%/}
 767       ref=$(git-symbolic-ref -q HEAD || git-name-rev --name-only HEAD 2>/dev/null)
 768       ref=${ref#refs/heads/}
 769       vcs="git"
 770     }
 771
 772     svn_dir() {
 773       [[ -d ".svn" ]] || return 1
 774       base_dir="."
 775       while [[ -d "$base_dir/../.svn" ]]; do base_dir="$base_dir/.."; done
 776       base_dir=$(readlink -f "$base_dir")
 777       sub_dir=$(sub_dir "${base_dir}")
 778       ref=$(svn info "$base_dir" | awk '/^URL/ { sub(".*/","",$0); r=$0 } /^Revision/ { sub("[^0-9]*","",$0); print r":"$0 }')
 779       vcs="svn"
 780     }
 781
 782     svk_dir() {
 783         [[ -f ~/.svk/config ]] || return 1
 784         base_dir=$(awk '/: *$/ { sub(/^ */,"",$0); sub(/: *$/,"",$0); if (match("'${PWD}'", $0"(/|$)")) { print $0; d=1; } } /depotpath/ && d == 1 { sub(".*/","",$0); r=$0 } /revision/ && d == 1 { print r ":" $2; exit 1 }' ~/.svk/config) && return 1
 785         ref=${base_dir##*
 786   }
 787         base_dir=${base_dir%%
 788   *}
 789         sub_dir=$(sub_dir "${base_dir}")
 790         vcs="svk"
 791     }
 792
 793     hg_dir() {
 794         base_dir="."
 795         while [[ ! -d "$base_dir/.hg" ]]; do
 796             base_dir="$base_dir/.."
 797             [[ $(readlink -f "${base_dir}") = "/" ]] && return 1
 798         done
 799         base_dir=$(readlink -f "$base_dir")
 800         sub_dir=$(sub_dir "${base_dir}")
 801         ref=$(< "${base_dir}/.hg/branch")
 802         vcs="hg"
 803     }
 804
 805     hg_dir  ||
 806     git_dir ||
 807     svn_dir ||
 808     svk_dir # ||
 809   #  base_dir="$PWD"
 810   #  echo "${vcs:+($vcs)}${base_dir/$HOME/~}${vcs:+[$ref]${sub_dir}}"
 811     echo "${vcs:+($vcs)}${base_dir}${vcs:+[$ref]${sub_dir}}"
 812 }
 813 # }}}
 814
 815 # {{{ set prompt
 816 if autoload promptinit && promptinit 2>/dev/null ; then
 817     promptinit # people should be able to use their favourite prompt
 818 else
 819     print 'Notice: no promptinit available :('
 820 fi
 821
 822
 823 # precmd() => a function which is executed just before each prompt
 824 # use 'NOPRECMD=1' to disable the precmd + preexec commands
 825
 826 # precmd () { setopt promptsubst; [[ -o interactive ]] && jobs -l;
 827
 828 # make sure to use right prompt only when not running a command
 829 is41 && setopt transient_rprompt
 830
 831 is4 && [[ -z $NOPRECMD ]] && precmd () {
 832     [[ -n $NOPRECMD ]] && return 0
 833     # allow manual overwriting of RPROMPT
 834     if [[ -n $RPROMPT ]] ; then
 835         [[ $TERM == screen* ]] && echo -n $'\ekzsh\e\\'
 836         # return 0
 837     fi
 838     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
 839     if [[ -z $DONTSETRPROMPT ]] ; then
 840         if [[ -n $BATTERY ]] ; then
 841             RPROMPT="%(?..:()% ${PERCENT}${SCREENTITLE}"
 842             # RPROMPT="${PERCENT}${SCREENTITLE}"
 843         elif [[ -n $VCS ]] ; then
 844             RPROMPT="%(?..:()% $(__vcs_dir)${SCREENTITLE}"
 845         else
 846             RPROMPT="%(?..:()% ${SCREENTITLE}"
 847             # RPROMPT="${SCREENTITLE}"
 848         fi
 849     fi
 850     # adjust title of xterm
 851     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
 852     case $TERM in
 853         (xterm*|rxvt)
 854             print -Pn "\e]0;%n@%m: %~\a"
 855             ;;
 856     esac
 857 }
 858
 859 # chpwd () => a function which is executed whenever the directory is changed
 860
 861 # preexec() => a function running before every command
 862 is4 && [[ -z $NOPRECMD ]] && \
 863 preexec () {
 864     [[ -n $NOPRECMD ]] && return 0
 865 # set hostname if not running on host with name 'grml'
 866     if [[ "$HOSTNAME" != $(hostname) ]] ; then
 867        NAME="@$HOSTNAME"
 868     fi
 869 # get the name of the program currently running and hostname of local machine
 870 # set screen window title if running in a screen
 871     if [[ "$TERM" == screen* ]] ; then
 872         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
 873         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
 874         echo -ne "\ek$CMD\e\\"
 875     fi
 876 # set the screen title to "zsh" when sitting at the command prompt:
 877     if [[ "$TERM" == screen* ]] ; then
 878         SCREENTITLE=$'%{\ekzsh\e\\%}'
 879     else
 880         SCREENTITLE=''
 881     fi
 882 # adjust title of xterm
 883     case $TERM in
 884         (xterm*|rxvt)
 885             print -Pn "\e]0;%n@%m: $1\a"
 886             ;;
 887     esac
 888 }
 889
 890 # set colors
 891 if autoload colors && colors 2>/dev/null ; then
 892     BLUE="%{${fg[blue]}%}"
 893     RED="%{${fg_bold[red]}%}"
 894     GREEN="%{${fg[green]}%}"
 895     CYAN="%{${fg[cyan]}%}"
 896     WHITE="%{${fg[white]}%}"
 897     NO_COLOUR="%{${reset_color}%}"
 898 else
 899     BLUE=$'%{\e[1;34m%}'
 900     RED=$'%{\e[1;31m%}'
 901     GREEN=$'%{\e[1;32m%}'
 902     CYAN=$'%{\e[1;36m%}'
 903     WHITE=$'%{\e[1;37m%}'
 904     NO_COLOUR=$'%{\e[0m%}'
 905 fi
 906
 907 EXITCODE="%(?..%?%1v )"
 908 PS2='`%_> '       # secondary prompt, printed when the shell needs more information to complete a command.
 909 PS3='?# '         # selection prompt used within a select loop.
 910 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
 911
 912 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
 913 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
 914     debian_chroot=$(cat /etc/debian_chroot)
 915 fi
 916
 917 # don't use colors on dumb terminals (like emacs):
 918 if [[ "$TERM" == dumb ]] ; then
 919     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< %# "
 920 else
 921     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
 922     # set variable identifying the chroot you work in (used in the prompt below)
 923     if [[ -n $GRMLPROMPT ]] ; then
 924         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
 925 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# "
 926     else
 927         if (( EUID != 0 )); then
 928             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# " # primary prompt string
 929         else
 930             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# " # primary prompt string
 931         fi
 932     fi
 933 fi
 934
 935 # if we are inside a grml-chroot set a specific prompt theme
 936 if [[ -n "$GRML_CHROOT" ]] ; then
 937     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
 938 fi
 939 # }}}
 940
 941 # {{{ 'hash' some often used directories
 942 #d# start
 943 hash -d deb=/var/cache/apt/archives
 944 hash -d doc=/usr/share/doc
 945 hash -d linux=/lib/modules/$(command uname -r)/build/
 946 hash -d log=/var/log
 947 hash -d slog=/var/log/syslog
 948 hash -d src=/usr/src
 949 hash -d templ=/usr/share/doc/grml-templates
 950 hash -d tt=/usr/share/doc/texttools-doc
 951 hash -d www=/var/www
 952 #d# end
 953 # }}}
 954
 955 # {{{ some aliases
 956 if [[ $UID -eq 0 ]] ; then
 957     [[ -r /etc/grml/screenrc ]] && alias screen='/usr/bin/screen -c /etc/grml/screenrc'
 958 elif [[ -r $HOME/.screenrc ]] ; then
 959     alias screen="/usr/bin/screen -c $HOME/.screenrc"
 960 else
 961     [[ -r /etc/grml/screenrc_grml ]] && alias screen='/usr/bin/screen -c /etc/grml/screenrc_grml'
 962 fi
 963
 964 # do we have GNU ls with color-support?
 965 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
 966     #a1# execute \kbd{@a@}:\quad ls with colors
 967     alias ls='ls -b -CF --color=auto'
 968     #a1# execute \kbd{@a@}:\quad list all files, with colors
 969     alias la='ls -la --color=auto'
 970     #a1# long colored list, without dotfiles (@a@)
 971     alias ll='ls -l --color=auto'
 972     #a1# long colored list, human readable sizes (@a@)
 973     alias lh='ls -hAl --color=auto'
 974     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
 975     alias l='ls -lF --color=auto'
 976 else
 977     alias ls='ls -b -CF'
 978     alias la='ls -la'
 979     alias ll='ls -l'
 980     alias lh='ls -hAl'
 981     alias l='ls -lF'
 982 fi
 983
 984 alias mdstat='cat /proc/mdstat'
 985 alias ...='cd ../../'
 986
 987 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
 988 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
 989     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
 990 fi
 991
 992 alias cp='nocorrect cp'         # no spelling correction on cp
 993 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
 994 alias mv='nocorrect mv'         # no spelling correction on mv
 995 alias rm='nocorrect rm'         # no spelling correction on rm
 996
 997 #a1# Execute \kbd{rmdir}
 998 alias rd='rmdir'
 999 #a1# Execute \kbd{rmdir}
1000 alias md='mkdir'
1001
1002 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1003 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1004 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1005
1006 # make sure it is not assigned yet
1007 [[ $(whence -w utf2iso &>/dev/null) == 'utf2iso: alias' ]] && unalias utf2iso
1008
1009 utf2iso() {
1010     if isutfenv ; then
1011         for ENV in $(env | command grep -i '.utf') ; do
1012             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1013         done
1014     fi
1015 }
1016
1017 # make sure it is not assigned yet
1018 [[ $(whence -w iso2utf &>/dev/null) == 'iso2utf: alias' ]] && unalias iso2utf
1019 iso2utf() {
1020     if ! isutfenv ; then
1021         for ENV in $(env | command grep -i '\.iso') ; do
1022             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1023         done
1024     fi
1025 }
1026
1027 # set up software synthesizer via speakup
1028 swspeak() {
1029     aumix -w 90 -v 90 -p 90 -m 90
1030     if ! [[ -r /dev/softsynth ]] ; then
1031         flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
1032         return 1
1033     else
1034         setopt singlelinezle
1035         unsetopt prompt_cr
1036         export PS1="%m%# "
1037         nice -n -20 speechd-up
1038         sleep 2
1039         flite -o play -t "Finished setting up software synthesizer"
1040     fi
1041 }
1042
1043 # I like clean prompt, so provide simple way to get that
1044 check_com 0 || alias 0='return 0'
1045
1046 # for really lazy people like mika:
1047 check_com S &>/dev/null || alias S='screen'
1048 check_com s &>/dev/null || alias s='ssh'
1049
1050 # get top 10 shell commands:
1051 alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
1052
1053 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
1054 if check_com -c truecrypt ; then
1055     if isutfenv ; then
1056         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
1057     else
1058         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
1059     fi
1060 fi
1061
1062 #f1# Hints for the use of zsh on grml
1063 zsh-help() {
1064     print "$bg[white]$fg[black]
1065 zsh-help - hints for use of zsh on grml
1066 =======================================$reset_color"
1067
1068     print '
1069 Main configuration of zsh happens in /etc/zsh/zshrc (global)
1070 and /etc/skel/.zshrc which is copied to $HOME/.zshrc once.
1071 The files are part of the package grml-etc-core, if you want to
1072 use them on a non-grml-system just get the tar.gz from
1073 http://deb.grml.org/ or get the files from the mercurial
1074 repository:
1075
1076   http://hg.grml.org/grml-etc-core/raw-file/tip/etc/skel/.zshrc
1077   http://hg.grml.org/grml-etc-core/raw-file/tip/etc/zsh/zshrc
1078
1079 If you want to stay in sync with zsh configuration of grml
1080 run '\''ln -sf /etc/skel/.zshrc $HOME/.zshrc'\'' and configure
1081 your own stuff in $HOME/.zshrc.local. System wide configuration
1082 without touching configuration files of grml can take place
1083 in /etc/zsh/zshrc.local.
1084
1085 If you want to use the configuration of user grml also when
1086 running as user root just run '\''zshskel'\'' which will source
1087 the file /etc/skel/.zshrc.
1088
1089 For information regarding zsh start at http://grml.org/zsh/
1090
1091 Take a look at grml'\''s zsh refcard:
1092 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1093
1094 Check out the main zsh refcard:
1095 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1096
1097 And of course visit the zsh-lovers:
1098 % man zsh-lovers
1099
1100 You can adjust some options through environment variables when
1101 invoking zsh without having to edit configuration files.
1102 Basically meant for bash users who are not used to the power of
1103 the zsh yet. :)
1104
1105   "NOCOR=1    zsh" => deactivate automatic correction
1106   "NOMENU=1   zsh" => do not use menu completion (note: use strg-d for completion instead!)
1107   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1108   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt'
1109
1110     print "
1111 $bg[white]$fg[black]
1112 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1113 Enjoy your grml system with the zsh!$reset_color"
1114 }
1115
1116 # debian stuff
1117 if [[ -r /etc/debian_version ]] ; then
1118     #a3# Execute \kbd{apt-cache search}
1119     alias acs='apt-cache search'
1120     #a3# Execute \kbd{apt-cache show}
1121     alias acsh='apt-cache show'
1122     #a3# Execute \kbd{apt-cache policy}
1123     alias acp='apt-cache policy'
1124     #a3# Execute \kbd{apt-get dist-upgrade}
1125     salias adg="apt-get dist-upgrade"
1126     #a3# Execute \kbd{apt-get install}
1127     salias agi="apt-get install"
1128     #a3# Execute \kbd{aptitude install}
1129     salias ati="aptitude install"
1130     #a3# Execute \kbd{apt-get upgrade}
1131     salias ag="apt-get upgrade"
1132     #a3# Execute \kbd{apt-get update}
1133     salias au="apt-get update"
1134     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1135     salias -a up="aptitude update ; aptitude safe-upgrade"
1136     #a3# Execute \kbd{dpkg-buildpackage}
1137     alias dbp='dpkg-buildpackage'
1138     #a3# Execute \kbd{grep-excuses}
1139     alias ge='grep-excuses'
1140
1141     # debian upgrade
1142     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
1143     upgrade() {
1144         if [[ -z "$1" ]] ; then
1145             $SUDO apt-get update
1146             $SUDO apt-get -u upgrade
1147         else
1148             ssh $1 $SUDO apt-get update
1149             # ask before the upgrade
1150             local dummy
1151             ssh $1 $SUDO apt-get --no-act upgrade
1152             echo -n 'Process the upgrade?'
1153             read -q dummy
1154             if [[ $dummy == "y" ]] ; then
1155                 ssh $1 $SUDO apt-get -u upgrade --yes
1156             fi
1157         fi
1158     }
1159
1160     isgrmlcd && alias su="sudo -s"          # get a root shell
1161     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1162     alias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1163     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1164     alias tlog="tail -f /var/log/syslog"    # follow the syslog
1165     #a1# (Re)-source \kbd{/etc/skel/.zshrc}
1166     alias zshskel="source /etc/skel/.zshrc" # source skeleton zshrc
1167 fi
1168
1169 # sort installed Debian-packages by size
1170 if check_com -c grep-status ; then
1171     #a3# List installed Debian-packages sorted by size
1172     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
1173 fi
1174
1175 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1176 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord ; then
1177     if check_com -c wodim ; then
1178         alias cdrecord="echo 'cdrecord is not provided under its original name by Debian anymore.
1179 See #377109 in the BTS of Debian for more details.
1180
1181 Please use the wodim binary instead' ; return 1"
1182     fi
1183 fi
1184
1185 # get_tw_cli has been renamed into get_3ware
1186 if check_com -c get_3ware ; then
1187     get_tw_cli() {
1188         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
1189         get_3ware
1190     }
1191 fi
1192
1193 # I hate lacking backward compatibility, so provide an alternative therefore
1194 if ! check_com -c apache2-ssl-certificate ; then
1195
1196     apache2-ssl-certificate() {
1197
1198     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
1199     print 'You might want to take a look at Debian the package ssl-cert as well.'
1200     print 'To generate a certificate for use with apache2 follow the instructions:'
1201
1202     echo '
1203
1204 export RANDFILE=/dev/random
1205 mkdir /etc/apache2/ssl/
1206 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
1207 chmod 600 /etc/apache2/ssl/apache.pem
1208
1209 Run "grml-tips ssl-certificate" if you need further instructions.
1210 '
1211     }
1212 fi
1213 # }}}
1214
1215 # {{{ Use hard limits, except for a smaller stack and no core dumps
1216 unlimit
1217 limit stack 8192
1218 isgrmlcd && limit core 0 # important for a live-cd-system
1219 limit -s
1220 # }}}
1221
1222 # {{{ completion stuff
1223
1224 # called later (via is4 && grmlcomp)
1225 # notice: use 'zstyle' for getting current settings
1226 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
1227 # TODO: make grmlcomp() readable. :-)
1228 grmlcomp() {
1229 ## completion system
1230 ## no initial indention in grmlcomp(), the lines are long enough already.
1231 zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )' # allow one error for every three characters typed in approximate completer
1232 zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)' # don't complete backup files as executables
1233 zstyle ':completion:*:correct:*'       insert-unambiguous true             # start menu completion only if it could find no unambiguous initial string
1234 zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}' #
1235 zstyle ':completion:*:correct:*'       original true                       #
1236 zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}      # activate color-completion(!)
1237 zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'  # format on completion
1238 zstyle ':completion:*:*:cd:*:directory-stack' menu yes select              # complete 'cd -<tab>' with menu
1239 zstyle ':completion:*:expand:*'        tag-order all-expansions            # insert all expansions for expand completer
1240 zstyle ':completion:*:history-words'   list false                          #
1241 zstyle ':completion:*:history-words'   menu yes                            # activate menu
1242 zstyle ':completion:*:history-words'   remove-all-dups yes                 # ignore duplicate entries
1243 zstyle ':completion:*:history-words'   stop yes                            #
1244 zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'        # match uppercase from lowercase
1245 zstyle ':completion:*:matches'         group 'yes'                         # separate matches into groups
1246 zstyle ':completion:*'                 group-name ''
1247 if [[ -z "$NOMENU" ]] ; then
1248     zstyle ':completion:*'               menu select=5                     # if there are more than 5 options allow selecting from a menu
1249 else
1250     setopt no_auto_menu # don't use any menus at all
1251 fi
1252 zstyle ':completion:*:messages'        format '%d'                         #
1253 zstyle ':completion:*:options'         auto-description '%d'               #
1254 zstyle ':completion:*:options'         description 'yes'                   # describe options in full
1255 zstyle ':completion:*:processes'       command 'ps -au$USER'               # on processes completion complete all user processes
1256 zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters        # offer indexes before parameters in subscripts
1257 zstyle ':completion:*'                 verbose true                        # provide verbose completion information
1258
1259 # recent (as of Dec 2007) zsh versions are able to provide descriptions
1260 # for commands (read: 1st word in the line) that it will list for the user
1261 # to choose from. The following disables that, because it's not exactly fast.
1262 zstyle ':completion:*:-command-:*:'    verbose false
1263
1264 zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d' # set format for warnings
1265 zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'       # define files to ignore for zcompile
1266 zstyle ':completion:correct:'          prompt 'correct to: %e'             #
1267 zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'    # Ignore completion functions for commands you don't have:
1268
1269 # complete manual by their section
1270 zstyle ':completion:*:manuals'    separate-sections true
1271 zstyle ':completion:*:manuals.*'  insert-sections   true
1272 zstyle ':completion:*:man:*'      menu yes select
1273
1274 ## correction
1275 # run rehash on completion so new installed program are found automatically:
1276 _force_rehash() {
1277     (( CURRENT == 1 )) && rehash
1278     return 1 # Because we didn't really complete anything
1279 }
1280 # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1281 if [[ -n "$NOCOR" ]] ; then
1282     zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1283     setopt nocorrect # do not try to correct the spelling if possible
1284 else
1285 #    zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _ignored _correct _approximate _files
1286     setopt correct  # try to correct the spelling if possible
1287     zstyle -e ':completion:*' completer '
1288         if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1289             _last_try="$HISTNO$BUFFER$CURSOR"
1290             reply=(_complete _match _ignored _prefix _files)
1291         else
1292             if [[ $words[1] == (rm|mv) ]] ; then
1293                 reply=(_complete _files)
1294             else
1295                 reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1296             fi
1297         fi'
1298 fi
1299 # zstyle ':completion:*' completer _complete _correct _approximate
1300 # zstyle ':completion:*' expand prefix suffix
1301
1302 # automatic rehash? Credits go to Frank Terbeck
1303 # my_accept() {
1304 #   local buf
1305 #   [[ -z ${BUFFER} ]] && zle accept-line && return
1306 #   buf=( ${(z)BUFFER}  )
1307 #   [[ -z ${commands[${buf[1]}]} ]] && rehash
1308 #   zle accept-line
1309 # }
1310 # zle -N my_accept
1311 # bindkey "^M" my_accept
1312
1313 # command for process lists, the local web server details and host completion
1314 zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1315
1316 # caching
1317 [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1318                           zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1319
1320 # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
1321 if is42 ; then
1322     [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1323     [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1324 else
1325     _ssh_hosts=()
1326     _etc_hosts=()
1327 fi
1328 hosts=(
1329     $(hostname)
1330     "$_ssh_hosts[@]"
1331     "$_etc_hosts[@]"
1332     grml.org
1333     localhost
1334 )
1335 zstyle ':completion:*:hosts' hosts $hosts
1336 #  zstyle '*' hosts $hosts
1337
1338 # specify your logins:
1339 # my_accounts=(
1340 #  {grml,grml1}@foo.invalid
1341 #  grml-devel@bar.invalid
1342 # )
1343 # other_accounts=(
1344 #  {fred,root}@foo.invalid
1345 #  vera@bar.invalid
1346 # )
1347 # zstyle ':completion:*:my-accounts' users-hosts $my_accounts
1348 # zstyle ':completion:*:other-accounts' users-hosts $other_accounts
1349
1350 # specify specific port/service settings:
1351 #  telnet_users_hosts_ports=(
1352 #    user1@host1:
1353 #    user2@host2:
1354 #    @mail-server:{smtp,pop3}
1355 #    @news-server:nntp
1356 #    @proxy-server:8000
1357 #  )
1358 # zstyle ':completion:*:*:telnet:*' users-hosts-ports $telnet_users_hosts_ports
1359
1360 # use generic completion system for programs not yet defined:
1361 compdef _gnu_generic tail head feh cp mv df stow uname ipacsum fetchipac
1362
1363 # see upgrade function in this file
1364 compdef _hosts upgrade
1365 }
1366 # }}}
1367
1368 # {{{ grmlstuff
1369 grmlstuff() {
1370 # people should use 'grml-x'!
1371     startx() {
1372         if [[ -e /etc/X11/xorg.conf ]] ; then
1373             [[ -x /usr/bin/startx ]] && /usr/bin/startx "$@" || /usr/X11R6/bin/startx "$@"
1374         else
1375             echo "Please use the script \"grml-x\" for starting the X Window System
1376 because there does not exist /etc/X11/xorg.conf yet.
1377 If you want to use startx anyway please call \"/usr/bin/startx\"."
1378             return -1
1379         fi
1380     }
1381
1382     xinit() {
1383         if [[ -e /etc/X11/xorg.conf ]] ; then
1384             [[ -x /usr/bin/xinit ]] && /usr/bin/xinit || /usr/X11R6/bin/xinit
1385         else
1386             echo "Please use the script \"grml-x\" for starting the X Window System.
1387 because there does not exist /etc/X11/xorg.conf yet.
1388 If you want to use xinit anyway please call \"/usr/bin/xinit\"."
1389             return -1
1390         fi
1391     }
1392
1393     if check_com -c 915resolution ; then
1394         alias 855resolution='echo -e "Please use 915resolution as resolution modify tool for Intel graphic chipset."; return -1'
1395     fi
1396
1397     #a1# Output version of running grml
1398     alias grml-version='cat /etc/grml_version'
1399
1400     if check_com -c rebuildfstab ; then
1401         #a1# Rebuild /etc/fstab
1402         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1403     fi
1404
1405     if check_com -c grml-debootstrap ; then
1406         alias debian2hd='print "Installing debian to harddisk is possible via using grml-debootstrap." ; return 1'
1407     fi
1408 }
1409 # }}}
1410
1411 # {{{ now run the functions
1412 isgrml && checkhome
1413 is4    && isgrml    && grmlstuff
1414 is4    && grmlcomp
1415 # }}}
1416
1417 # {{{ keephack
1418 is4 && xsource "/etc/zsh/keephack"
1419 # }}}
1420
1421 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
1422 # You use it as follows:
1423 # $ NTREF=/reference/file
1424 # $ ls -l *(e:nt:)
1425 # This lists all the files in the current directory newer than the reference file.
1426 # You can also specify the reference file inline; note quotes:
1427 # $ ls -l *(e:'nt ~/.zshenv':)
1428 is4 && nt() {
1429     if [[ -n $1 ]] ; then
1430         local NTREF=${~1}
1431     fi
1432     [[ $REPLY -nt $NTREF ]]
1433 }
1434 # }}}
1435
1436 # shell functions {{{
1437
1438 #f1# Provide csh compatibility
1439 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
1440
1441 #f1# Reload an autoloadable function
1442 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1443
1444 #f1# Reload zsh setup
1445 reload() {
1446     if [[ "$#*" -eq 0 ]] ; then
1447         [[ -r ~/.zshrc ]] && . ~/.zshrc
1448     else
1449         local fn
1450         for fn in "$@"; do
1451             unfunction $fn
1452             autoload -U $fn
1453         done
1454     fi
1455 }
1456 compdef _functions reload freload
1457
1458 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1459 sll() {
1460     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1461     for i in "$@" ; do
1462         file=$i
1463         while [[ -h "$file" ]] ; do
1464             ls -l $file
1465             file=$(readlink "$file")
1466         done
1467     done
1468 }
1469
1470 # fast manual access
1471 if check_com qma ; then
1472     #f1# View the zsh manual
1473     manzsh()  { qma zshall "$1" }
1474     compdef _man qma
1475 else
1476     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
1477     # manzsh()  { /usr/bin/man zshall |  most +/"$1" ; }
1478     # [[ -f ~/.terminfo/m/mostlike ]] && MYLESS='LESS=C TERMINFO=~/.terminfo TERM=mostlike less' || MYLESS='less'
1479     # manzsh()  { man zshall | $MYLESS -p $1 ; }
1480 fi
1481
1482 if check_com -c most ; then
1483     #f1# View Debian's changelog of a given package
1484     dchange() {
1485         if [[ -r /usr/share/doc/${1}/changelog.Debian.gz ]] ; then
1486             most /usr/share/doc/${1}/changelog.Debian.gz
1487         elif [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
1488             most /usr/share/doc/${1}/changelog.gz
1489         else
1490             if check_com -c aptitude ; then
1491                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1492                 if isgrml ; then
1493                     aptitude -t unstable changelog ${1}
1494                 else
1495                     aptitude changelog ${1}
1496                 fi
1497             else
1498                 echo "No changelog for package $1 found, sorry."
1499                 return 1
1500             fi
1501         fi
1502     }
1503     _dchange() { _files -W /usr/share/doc -/ }
1504     compdef _dchange dchange
1505
1506     #f1# View Debian's NEWS of a given package
1507     dnews() {
1508         if [[ -r /usr/share/doc/${1}/NEWS.Debian.gz ]] ; then
1509             most /usr/share/doc/${1}/NEWS.Debian.gz
1510         else
1511             if [[ -r /usr/share/doc/${1}/NEWS.gz ]] ; then
1512                 most /usr/share/doc/${1}/NEWS.gz
1513             else
1514                 echo "No NEWS file for package $1 found, sorry."
1515                 return 1
1516             fi
1517         fi
1518     }
1519     _dnews() { _files -W /usr/share/doc -/ }
1520     compdef _dnews dnews
1521
1522     #f1# View upstream's changelog of a given package
1523     uchange() {
1524         if [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
1525             most /usr/share/doc/${1}/changelog.gz
1526         else
1527             echo "No changelog for package $1 found, sorry."
1528             return 1
1529         fi
1530     }
1531     _uchange() { _files -W /usr/share/doc -/ }
1532     compdef _uchange uchange
1533 fi
1534
1535 # zsh profiling
1536 profile() {
1537     ZSH_PROFILE_RC=1 $SHELL "$@"
1538 }
1539
1540 #f1# Edit an alias via zle
1541 edalias() {
1542     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1543 }
1544 compdef _aliases edalias
1545
1546 #f1# Edit a function via zle
1547 edfunc() {
1548     [[ -z "$1" ]] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
1549 }
1550 compdef _functions edfunc
1551
1552 # use it e.g. via 'Restart apache2'
1553 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
1554 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
1555 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
1556 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
1557 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
1558 if [[ -d /etc/init.d ]] ; then
1559     for i in Start Restart Stop Force-Reload Reload ; do
1560         eval "$i() { $SUDO /etc/init.d/\$1 ${i:l} \$2 ; }"
1561     done
1562 fi
1563
1564 #f1# Provides useful information on globbing
1565 H-Glob() {
1566     echo -e "
1567     /      directories
1568     .      plain files
1569     @      symbolic links
1570     =      sockets
1571     p      named pipes (FIFOs)
1572     *      executable plain files (0100)
1573     %      device files (character or block special)
1574     %b     block special files
1575     %c     character special files
1576     r      owner-readable files (0400)
1577     w      owner-writable files (0200)
1578     x      owner-executable files (0100)
1579     A      group-readable files (0040)
1580     I      group-writable files (0020)
1581     E      group-executable files (0010)
1582     R      world-readable files (0004)
1583     W      world-writable files (0002)
1584     X      world-executable files (0001)
1585     s      setuid files (04000)
1586     S      setgid files (02000)
1587     t      files with the sticky bit (01000)
1588
1589   print *(m-1)          # Files modified up to a day ago
1590   print *(a1)           # Files accessed a day ago
1591   print *(@)            # Just symlinks
1592   print *(Lk+50)        # Files bigger than 50 kilobytes
1593   print *(Lk-50)        # Files smaller than 50 kilobytes
1594   print **/*.c          # All *.c files recursively starting in \$PWD
1595   print **/*.c~file.c   # Same as above, but excluding 'file.c'
1596   print (foo|bar).*     # Files starting with 'foo' or 'bar'
1597   print *~*.*           # All Files that do not contain a dot
1598   chmod 644 *(.^x)      # make all plain non-executable files publically readable
1599   print -l *(.c|.h)     # Lists *.c and *.h
1600   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
1601   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
1602 }
1603 alias help-zshglob=H-Glob
1604
1605 check_com -c qma && alias ?='qma zshall'
1606
1607 # grep for running process, like: 'any vim'
1608 any() {
1609     if [[ -z "$1" ]] ; then
1610         echo "any - grep for process(es) by keyword" >&2
1611         echo "Usage: any <keyword>" >&2 ; return 1
1612     else
1613         local STRING=$1
1614         local LENGTH=$(expr length $STRING)
1615         local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
1616         local REST=$(echo $(expr substr $STRING 2 $LENGTH))
1617         ps xauwww| grep "[$FIRSCHAR]$REST"
1618     fi
1619 }
1620
1621 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
1622 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
1623 [[ -r /proc/1/maps ]] && \
1624 deswap() {
1625     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
1626     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
1627     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
1628 }
1629
1630 # print hex value of a number
1631 hex() {
1632     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
1633 }
1634
1635 # calculate (or eval at all ;-)) with perl => p[erl-]eval
1636 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
1637 peval() {
1638     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
1639     perl -e "print eval($CALC),\"\n\";"
1640 }
1641 functions peval &>/dev/null && alias calc=peval
1642
1643 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
1644 # certain circumstances, so work around it, no matter which environment we have
1645 brltty() {
1646     if [[ -z "$DISPLAY" ]] ; then
1647         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
1648         command brltty "$@"
1649     else
1650         command brltty "$@"
1651     fi
1652 }
1653
1654 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
1655 aoeu() {
1656     echo -n 'Switching to us keyboard layout: '
1657     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
1658     echo 'Done'
1659 }
1660 asdf() {
1661     echo -n 'Switching to dvorak keyboard layout: '
1662     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
1663     echo 'Done'
1664 }
1665 # just press 'asdf' key to toggle from neon layout to us keyboard layout
1666 uiae() {
1667     echo -n 'Switching to us keyboard layout: '
1668     setxkbmap us && echo 'Done' || echo 'Failed'
1669 }
1670
1671 # set up an ipv6 tunnel
1672 ipv6-tunnel() {
1673     case $1 in
1674         start)
1675             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1676                 print 'ipv6 tunnel already set up, nothing to be done.'
1677                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
1678             else
1679                 [[ -n "$PUBLIC_IP" ]] || \
1680                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
1681                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
1682
1683                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
1684                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
1685                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
1686                 ifconfig sit0 tunnel ::192.88.99.1 up
1687                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
1688             fi
1689             ;;
1690         status)
1691             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1692                 print 'ipv6 tunnel available' ; return 0
1693             else
1694                 print 'ipv6 tunnel not available' ; return 1
1695             fi
1696             ;;
1697         stop)
1698             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1699                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
1700                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
1701             else
1702                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
1703             fi
1704             ;;
1705         *)
1706             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
1707             ;;
1708     esac
1709 }
1710
1711 # run dhclient for wireless device
1712 iwclient() {
1713     salias dhclient "$(wavemon -d | awk '/device/{print $2}')"
1714 }
1715
1716 # spawn a minimally set up ksh - useful if you want to umount /usr/.
1717 minimal-shell() {
1718     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ksh
1719 }
1720
1721 # make a backup of a file
1722 bk() {
1723     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
1724 }
1725
1726 # Switching shell safely and efficiently? http://www.zsh.org/mla/workers/2001/msg02410.html
1727 # bash() {
1728 #  NO_SWITCH="yes" command bash "$@"
1729 # }
1730 # restart () {
1731 #  exec $SHELL $SHELL_ARGS "$@"
1732 # }
1733
1734 # }}}
1735
1736 # log out? set timeout in seconds {{{
1737 # TMOUT=1800
1738 # do not log out in some specific terminals:
1739 #  if [[ "${TERM}" == ([Exa]term*|rxvt|dtterm|screen*) ]] ; then
1740 #    unset TMOUT
1741 #  fi
1742 # }}}
1743
1744 # {{{ make sure our environment is clean regarding colors
1745 for color in BLUE RED GREEN CYAN WHITE ; unset $color
1746 # }}}
1747
1748 # source another config file if present {{{
1749 xsource "/etc/zsh/zshrc.local"
1750 # }}}
1751
1752 # "persistent history" {{{
1753 # just write important commands you always need to ~/.important_commands
1754 if [[ -r ~/.important_commands ]] ; then
1755     fc -R ~/.important_commands
1756 fi
1757 # }}}
1758
1759 ## genrefcard.pl settings {{{
1760 ### example: split functions-search 8,16,24,32
1761 #@# split functions-search 8
1762 ## }}}
1763
1764 # add variable to be able to check whether the file has been read {{{
1765 ZSHRC_GLOBAL_HAS_BEEN_READ=1
1766 # }}}
1767
1768 ## END OF FILE #################################################################
1769 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4