+function prompt_grml_help () {
+ cat <<__EOF0__
+ prompt grml
+
+ This is the prompt as used by the grml-live system <http://grml.org>. It is
+ a rather simple one-line prompt, that by default looks something like this:
+
+ <user>@<host> <current-working-directory>[ <vcs_info-data>]%
+
+ The prompt itself integrates with zsh's prompt themes system (as you are
+ witnessing right now) and is configurable to a certain degree. In
+ particular, these aspects are customisable:
+
+ - The items used in the prompt (e.g. you can remove \`user' from
+ the list of activated items, which will cause the user name to
+ be omitted from the prompt string).
+
+ - The attributes used with the items are customisable via strings
+ used before and after the actual item.
+
+ The available items are: rc, rc-always, change-root, user, at, host, path,
+ vcs, percent, sad-smiley, battery.
+
+ The actual configuration is done via zsh's \`zstyle' mechanism. The
+ context, that is used while looking up styles is:
+
+ ':prompt:grml:<left-or-right>:<subcontext>'
+
+ Here <left-or-right> is either \`left' or \`right', signifying whether the
+ style should affect the left or the right prompt. <subcontext> is either
+ \`setup' or 'items:<item>', where \`<item>' is one of the available items.
+
+ The styles:
+
+ - use-rprompt (boolean): If \`true' (the default), print a sad smiley
+ in $RPROMPT if the last command a returned non-successful error code.
+ (This in only valid if <left-or-right> is "right"; ignored otherwise)
+
+ - items (list): The list of items used in the prompt. If \`vcs' is
+ present in the list, the theme's code invokes \`vcs_info'
+ accordingly. Default: rc user change-root at host path vcs precent
+
+ Available styles in 'items:<item>' are: pre, post. These are strings that
+ are inserted before (pre) and after (post) the item in question. Thus, the
+ following would cause the user name to be printed in red instead of the
+ default blue:
+
+ zstyle ':prompt:grml:*:items:user' pre '%F{red}'
+
+ Note, that the \`post' style may remain at its default value, because its
+ default value is '%f', which turns the foreground text attribute off (which
+ is exactly, what is still required with the new \`pre' value).
+__EOF0__
+}
+
+function grml_prompt_setup () {
+ emulate -L zsh
+ autoload -Uz vcs_info
+ autoload -Uz add-zsh-hook
+ add-zsh-hook precmd prompt_$1_precmd
+}
+
+function prompt_grml_setup () {
+ grml_prompt_setup grml
+}
+
+function prompt_grml-chroot_setup () {
+ grml_prompt_setup grml-chroot
+}
+
+function prompt_grml-large_setup () {
+ grml_prompt_setup grml-large
+}
+
+typeset -gA grml_prompt_pre_default \
+ grml_prompt_post_default \
+ grml_prompt_token_default
+
+grml_prompt_pre_default=(
+ rc '%F{red}'
+ rc-always ''
+ change-root ''
+ user '%B%F{blue}'
+ at ''
+ host ''
+ path '%b'
+ vcs ''
+ percent ''
+ sad-smiley ''
+ battery ' '
+ newline ''
+ jobs '%F{cyan}'
+ history '%F{green}'
+ date '%F{blue}'
+ time '%F{blue}'
+ shell-level '%F{red}'
+ grml-chroot '%F{red}'
+)
+
+grml_prompt_post_default=(
+ rc '%f'
+ rc-always ''
+ change-root ''
+ user '%f%b'
+ at ''
+ host ''
+ path '%B'
+ vcs ''
+ percent ''
+ sad-smiley ''
+ battery ''
+ newline ''
+ jobs '%f'
+ history '%f'
+ date '%f'
+ time '%f'
+ shell-level '%f'
+ grml-chroot '%f '
+)
+
+grml_prompt_token_default=(
+ rc '%(?..%? )'
+ rc-always '%?'
+ change-root 'debian_chroot'
+ user '%n'
+ at '@'
+ host '%m '
+ path '%40<..<%~%<< '
+ vcs '0'
+ percent '%% '
+ sad-smiley '%(?..:()'
+ battery 'PERCENT'
+ newline $'\n'
+ jobs '[%j running job(s)] '
+ history '{history#%!} '
+ date '%D{%Y-%m-%d}'
+ time '%D{%H:%M:%S} '
+ shell-level '%(3L.+ .)'
+ grml-chroot 'GRML_CHROOT'
+)
+
+function grml_typeset_and_wrap () {
+ emulate -L zsh
+ local target="$1"
+ local new="$2"
+ local left="$3"
+ local right="$4"
+
+ if (( ${+parameters[$new]} )); then
+ typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
+ fi
+}
+
+function grml_prompt_addto () {
+ emulate -L zsh
+ local target="$1"
+ local lr it apre apost new v
+ local -a items
+ shift
+
+ [[ $target == PS1 ]] && lr=left || lr=right
+ zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
+ typeset -g "${target}="
+ for it in "${items[@]}"; do
+ zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
+ || apre=${grml_prompt_pre_default[$it]}
+ zstyle -s ":prompt:grml:${grmltheme}:${lr}:$it" post apost \
+ || apost=${grml_prompt_post_default[$it]}
+ zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
+ || new=${grml_prompt_token_default[$it]}
+ typeset -g "${target}=${(P)target}${apre}"
+ case $it in
+ battery)
+ grml_typeset_and_wrap $target $new '' ''
+ ;;
+ change-root)
+ grml_typeset_and_wrap $target $new '(' ')'
+ ;;
+ grml-chroot)
+ if [[ -n ${(P)new} ]]; then
+ typeset -g "${target}=${(P)target}(CHROOT)"
+ fi
+ ;;
+ vcs)
+ v="vcs_info_msg_${new}_"
+ if (( ! vcscalled )); then
+ vcs_info
+ vcscalled=1
+ fi
+ if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
+ typeset -g "${target}=${(P)target}${(P)v}"
+ fi
+ ;;
+ *) typeset -g "${target}=${(P)target}${new}" ;;
+ esac
+ typeset -g "${target}=${(P)target}${apost}"
+ done
+}
+
+function prompt_grml_precmd () {
+ emulate -L zsh
+ local grmltheme=grml
+ local -a left_items right_items
+ left_items=(rc change-root user at host path vcs percent)
+ right_items=(sad-smiley)
+
+ prompt_grml_precmd_worker
+}
+
+function prompt_grml-chroot_precmd () {
+ emulate -L zsh
+ local grmltheme=grml-chroot
+ local -a left_items right_items
+ left_items=(grml-chroot user at host path percent)
+ right_items=()
+
+ prompt_grml_precmd_worker
+}
+
+function prompt_grml-large_precmd () {
+ emulate -L zsh
+ local grmltheme=grml-large
+ local -a left_items right_items
+ left_items=(rc jobs history shell-level change-root time date newline
+ user at host path vcs percent)
+ right_items=(sad-smiley)
+
+ prompt_grml_precmd_worker
+}
+
+function prompt_grml_precmd_worker () {
+ emulate -L zsh
+ local -i vcscalled=0
+
+ grml_prompt_addto PS1 "${left_items[@]}"
+ if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
+ grml_prompt_addto RPS1 "${right_items[@]}"
+ fi
+}
+