etc/zsh/completion.d/_grml-live

   1 #compdef grml-live
   2 # Filename:      /etc/zsh/completion.d/_grml-live
   3 # Purpose:       completion for command grml-live for zsh (z shell)
   4 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   5 # Bug-Reports:   see http://grml.org/bugs/
   6 # License:       This file is licensed under the GPL v2.
   7 # Latest change: Thu, 01 Nov 2007 14:00:40 +0100 [ft]
   8 ################################################################################
   9
  10 _grmllive_flavours() { #{{{
  11   local expl
  12   local -a flavours
  13
  14   flavours=(
  15     grml        grml64
  16     grml-medium grml64-medium
  17     grml-small  grml64-small
  18   )
  19   _wanted list expl 'grml flavour(s)' compadd ${expl} -- ${flavours}
  20 }
  21 #}}}
  22 _grmllive_archs() { #{{{
  23   local expl runningarch
  24   local -a archs
  25
  26   runningarch="$(dpkg --print-architecture)"
  27   archs=( ${runningarch} )
  28   [[ ${runningarch} == 'amd64' ]] && archs=( ${archs} 'i386')
  29   _wanted list expl 'target architecture' compadd ${expl} -- ${archs}
  30 }
  31 #}}}
  32 _grmllive_classes() { #{{{
  33     local expl
  34     local -a already static_classes
  35
  36     static_classes=(
  37         RELEASE LATEX_CLEANUP NO_ONLINE REMOVE_DOCS LOCALES
  38         I386 AMD64
  39     )
  40     compset -P '*,'
  41     already=(${(s<,>)IPREFIX})
  42     _wanted list expl 'classe(s)' compadd -S, -F already -q ${expl} -- \
  43         /etc/grml/fai/config/class/*(.N:t:r) ${static_classes}
  44 }
  45 #}}}
  46 _grmllive_suites() { #{{{
  47   local expl
  48   local -a suites
  49
  50   suites=(
  51     stable  testing unstable
  52     etch    lenny   sid
  53   )
  54   _wanted list expl 'Debian suite' compadd ${expl} -- ${suites}
  55 }
  56 #}}}
  57 arguments=( #{{{
  58   '-F[force execution without prompting for yes/no]'
  59   '-a[specifiy architecture to use]:arch(s):_grmllive_archs'
  60   '-c[available grml-live classes]:classe(s):_grmllive_classes'
  61   '-g[grml flavour to use]:grml flavour(s):_grmllive_flavours'
  62   '-h[display usage information]'
  63   '-i[iso name, ends up in $OUTPUT_DIRECTORY/grml_isos]:iso name:'
  64   '-o[output directory]:output directory:_path_files -/'
  65   '-s[debian suite to be used for live-system]:Debian suite:_grmllive_suites'
  66   '-t[template directory]:template directory:_path_files -/'
  67   '-u[update existing chroot if possible]'
  68   '-V[increase verbosity]'
  69 )
  70 #}}}
  71
  72 _arguments -s $arguments
  73
  74 ## END OF FILE #################################################################
  75 # vim:foldmethod=marker