+
+## toggle the ,. abbreviation feature on/off
+# NOABBREVIATION: default abbreviation-state
+# 0 - enabled (default)
+# 1 - disabled
+NOABBREVIATION=${NOABBREVIATION:-0}
+
+grml_toggle_abbrev() {
+ if (( ${NOABBREVIATION} > 0 )) ; then
+ NOABBREVIATION=0
+ else
+ NOABBREVIATION=1
+ fi
+}
+
+zle -N grml_toggle_abbrev
+bindkey '^xA' grml_toggle_abbrev
+
+# }}}
+
+# a generic accept-line wrapper {{{
+
+# This widget can prevent unwanted autocorrections from command-name
+# to _command-name, rehash automatically on enter and call any number
+# of builtin and user-defined widgets in different contexts.
+#
+# For a broader description, see:
+# <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
+#
+# The code is imported from the file 'zsh/functions/accept-line' from
+# <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
+# distributed under the same terms as zsh itself.
+
+# A newly added command will may not be found or will cause false
+# correction attempts, if you got auto-correction set. By setting the
+# following style, we force accept-line() to rehash, if it cannot
+# find the first word on the command line in the $command[] hash.
+zstyle ':acceptline:*' rehash true
+
+function Accept-Line() {
+ setopt localoptions noksharrays
+ local -a subs
+ local -xi aldone
+ local sub
+
+ zstyle -a ":acceptline:${alcontext}" actions subs
+
+ (( ${#subs} < 1 )) && return 0
+
+ (( aldone = 0 ))
+ for sub in ${subs} ; do
+ [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
+ zle ${sub}
+
+ (( aldone > 0 )) && break
+ done
+}
+
+function Accept-Line-getdefault() {
+ local default_action
+
+ zstyle -s ":acceptline:${alcontext}" default_action default_action
+ case ${default_action} in
+ ((accept-line|))
+ printf ".accept-line"
+ ;;
+ (*)
+ printf ${default_action}
+ ;;
+ esac
+}
+
+function accept-line() {
+ setopt localoptions noksharrays
+ local -a cmdline
+ local -x alcontext
+ local buf com fname format msg default_action
+
+ alcontext='default'
+ buf="${BUFFER}"
+ cmdline=(${(z)BUFFER})
+ com="${cmdline[1]}"
+ fname="_${com}"
+
+ zstyle -t ":acceptline:${alcontext}" rehash \
+ && [[ -z ${commands[$com]} ]] \
+ && rehash
+
+ if [[ -n ${reswords[(r)$com]} ]] \
+ || [[ -n ${aliases[$com]} ]] \
+ || [[ -n ${functions[$com]} ]] \
+ || [[ -n ${builtins[$com]} ]] \
+ || [[ -n ${commands[$com]} ]] ; then
+
+ # there is something sensible to execute, just do it.
+ alcontext='normal'
+ zle Accept-Line
+
+ default_action=$(Accept-Line-getdefault)
+ zstyle -T ":acceptline:${alcontext}" call_default \
+ && zle ${default_action}
+ return
+ fi
+
+ if [[ -o correct ]] \
+ || [[ -o correctall ]] \
+ && [[ -n ${functions[$fname]} ]] ; then
+
+ # nothing there to execute but there is a function called
+ # _command_name; a completion widget. Makes no sense to
+ # call it on the commandline, but the correct{,all} options
+ # will ask for it nevertheless, so warn the user.
+ if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
+ # Okay, we warned the user before, he called us again,
+ # so have it his way.
+ alcontext='force'
+ zle Accept-Line
+
+ default_action=$(Accept-Line-getdefault)
+ zstyle -T ":acceptline:${alcontext}" call_default \
+ && zle ${default_action}
+ return
+ fi
+
+ # prepare warning message for the user, configurable via zstyle.
+ zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
+
+ if [[ -z ${msg} ]] ; then
+ msg="%c will not execute and completion %f exists."
+ fi
+
+ zformat -f msg "${msg}" "c:${com}" "f:${fname}"
+
+ zle -M -- "${msg}"
+ return
+ elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
+ # If we are here, the commandline contains something that is not
+ # executable, which is neither subject to _command_name correction
+ # and is not empty. might be a variable assignment
+ alcontext='misc'
+ zle Accept-Line
+
+ default_action=$(Accept-Line-getdefault)
+ zstyle -T ":acceptline:${alcontext}" call_default \
+ && zle ${default_action}
+ return
+ fi
+
+ # If we got this far, the commandline only contains whitespace, or is empty.
+ alcontext='empty'
+ zle Accept-Line
+
+ default_action=$(Accept-Line-getdefault)
+ zstyle -T ":acceptline:${alcontext}" call_default \
+ && zle ${default_action}
+}
+
+zle -N accept-line
+zle -N Accept-Line
+
+# }}}
+
+# power completion - abbreviation expansion {{{
+# power completion / abbreviation expansion / buffer expansion
+# see http://zshwiki.org/home/examples/zleiab for details
+# less risky than the global aliases but powerful as well
+# just type the abbreviation key and afterwards ',.' to expand it
+declare -A abk
+setopt extendedglob
+setopt interactivecomments
+abk=(
+# key # value (#d additional doc string)
+#A# start
+ '...' '../..'
+ '....' '../../..'
+ 'BG' '& exit'
+ 'C' '| wc -l'
+ 'G' '|& grep --color=auto'
+ 'H' '| head'
+ 'Hl' ' --help |& less -r' #d (Display help in pager)
+ 'L' '| less'
+ 'LL' '|& less -r'
+ 'M' '| most'
+ 'N' '&>/dev/null' #d (No Output)
+ 'R' '| tr A-z N-za-m' #d (ROT13)
+ 'SL' '| sort | less'
+ 'S' '| sort -u'
+ 'T' '| tail'
+ 'V' '|& vim -'
+#A# end
+ 'hide' "echo -en '\033]50;nil2\007'"
+ 'tiny' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
+ 'small' 'echo -en "\033]50;6x10\007"'
+ 'medium' 'echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
+ 'default' 'echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
+ 'large' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
+ 'huge' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
+ 'smartfont' 'echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
+ 'semifont' 'echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
+ 'da' 'du -sch'
+ 'j' 'jobs -l'
+ 'u' 'translate -i'
+ 'co' "./configure && make && sudo make install"
+ 'CH' "./configure --help"
+ 'conkeror' 'firefox -chrome chrome://conkeror/content'
+ 'dir' 'ls -lSrah'
+ 'lad' $'ls -d .*(/)\n# only show dot-directories'
+ 'lsa' $'ls -a .*(.)\n# only show dot-files'
+ 'lss' $'ls -l *(s,S,t)\n# only files with setgid/setuid/sticky flag'
+ 'lsl' $'ls -l *(@[1,10])\n# only symlinks'
+ 'lsx' $'ls -l *(*[1,10])\n# only executables'
+ 'lsw' $'ls -ld *(R,W,X.^ND/)\n# world-{readable,writable,executable} files'
+ 'lsbig' $'ls -flh *(.OL[1,10])\n# display the biggest files'
+ 'lsd' $'ls -d *(/)\n# only show directories'
+ 'lse' $'ls -d *(/^F)\n# only show empty directories'
+ 'lsnew' $'ls -rl *(D.om[1,10])\n# display the newest files'
+ 'lsold' $'ls -rtlh *(D.om[-11,-1])\n # display the oldest files'
+ 'lssmall' $'ls -Srl *(.oL[1,10])\n# display the smallest files'
+ 'rw-' 'chmod 600'
+ '600' 'chmod u+rw-x,g-rwx,o-rwx'
+ 'rwx' 'chmod u+rwx'
+ '700' 'chmod u+rwx,g-rwx,o-rwx'
+ 'r--' 'chmod u+r-wx,g-rwx,o-rwx'
+ '644' $'chmod u+rw-x,g+r-wx,o+r-wx\n # 4=r,2=w,1=x'
+ '755' 'chmod u+rwx,g+r-w+x,o+r-w+x'
+ 'md' 'mkdir -p '
+ 'cmplayer' 'mplayer -vo -fs -zoom fbdev'
+ 'fbmplayer' 'mplayer -vo -fs -zoom fbdev'
+ 'fblinks' 'links2 -driver fb'
+ 'insecssh' 'ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
+ 'insecscp' 'scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
+ 'fori' 'for i ({..}) { }'
+ 'cx' 'chmod +x'
+ 'e' 'print -l'
+ 'se' 'setopt interactivecomments'
+ 'va' 'valac --vapidir=../vapi/ --pkg=gtk+-2.0 gtktest.vala'
+ 'fb2' '=mplayer -vo fbdev -fs -zoom 1>/dev/null -xy 2'
+ 'fb3' '=mplayer -vo fbdev -fs -zoom 1>/dev/null -xy 3'
+ 'ci' 'centericq'
+ 'D' 'export DISPLAY=:0.0'
+ 'mp' 'mplayer -vo xv -fs -zoom'
+)
+
+globalias() {
+ local MATCH
+
+ if (( NOABBREVIATION > 0 )) ; then
+ LBUFFER="${LBUFFER},."
+ return 0
+ fi
+
+ matched_chars='[.-|_a-zA-Z0-9]#'
+ LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
+ LBUFFER+=${abk[$MATCH]:-$MATCH}
+}
+
+zle -N globalias
+bindkey ",." globalias
+# }}}
+
+# {{{ autoloading
+zrcautoload zmv # who needs mmv or rename?
+zrcautoload history-search-end
+
+# we don't want to quote/espace URLs on our own...
+# if autoload -U url-quote-magic ; then
+# zle -N self-insert url-quote-magic
+# zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
+# else
+# print 'Notice: no url-quote-magic available :('
+# fi
+alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
+
+#m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
+alias run-help >&/dev/null && unalias run-help
+zrcautoload run-help # use via 'esc-h'
+
+# completion system
+if zrcautoload compinit && compinit 2>/dev/null ; then
+ compinit 2>/dev/null || print 'Notice: no compinit available :('
+else
+ print 'Notice: no compinit available :('
+ function zstyle { }
+ function compdef { }
+fi
+
+is4 && zrcautoload zed # use ZLE editor to edit a file or function
+
+is4 && \
+for mod in complist deltochar mathfunc ; do
+ zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
+done
+
+# autoload zsh modules when they are referenced
+if is4 ; then
+ tmpargs=(
+ a stat
+ a zpty
+ ap zprof
+ ap mapfile
+ )
+
+ while (( ${#tmpargs} > 0 )) ; do
+ zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
+ shift 2 tmpargs
+ done
+ unset tmpargs
+fi
+
+if is4 && zrcautoload insert-files && zle -N insert-files ; then
+ #k# Insert files
+ bindkey "^Xf" insert-files # C-x-f
+fi
+
+bindkey ' ' magic-space # also do history expansion on space
+#k# Trigger menu-complete
+bindkey '\ei' menu-complete # menu completion via esc-i
+
+# press esc-e for editing command line in $EDITOR or $VISUAL
+if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
+ #k# Edit the current line in \kbd{\$EDITOR}
+ bindkey '\ee' edit-command-line
+fi
+
+if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
+ #k# menu selection: pick item but stay in the menu
+ bindkey -M menuselect '\e^M' accept-and-menu-complete
+
+ # use the vi navigation keys (hjkl) besides cursor keys in menu completion
+ #bindkey -M menuselect 'h' vi-backward-char # left
+ #bindkey -M menuselect 'k' vi-up-line-or-history # up
+ #bindkey -M menuselect 'l' vi-forward-char # right
+ #bindkey -M menuselect 'j' vi-down-line-or-history # bottom
+
+ # accept a completion and try to complete again by using menu
+ # completion; very useful with completing directories
+ # by using 'undo' one's got a simple file browser
+ bindkey -M menuselect '^o' accept-and-infer-next-history
+fi
+
+# press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
+_bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
+zle -N _bkdate
+
+#k# Insert a timestamp on the command line (yyyy-mm-dd)
+bindkey '^Ed' _bkdate
+
+# press esc-m for inserting last typed word again (thanks to caphuso!)
+insert-last-typed-word() { zle insert-last-word -- 0 -1 };
+zle -N insert-last-typed-word;
+
+#k# Insert last typed word
+bindkey "\em" insert-last-typed-word
+
+# set command prediction from history, see 'man 1 zshcontrib'
+# is4 && zrcautoload predict-on && \
+# zle -N predict-on && \
+# zle -N predict-off && \
+# bindkey "^X^Z" predict-on && \
+# bindkey "^Z" predict-off
+
+#k# Shortcut for \kbd{fg<enter>}
+bindkey -s '^z' "fg\n"
+
+# press ctrl-q to quote line:
+# mquote () {
+# zle beginning-of-line
+# zle forward-word
+# # RBUFFER="'$RBUFFER'"
+# RBUFFER=${(q)RBUFFER}
+# zle end-of-line
+# }
+# zle -N mquote && bindkey '^q' mquote
+
+# run command line as user root via sudo:
+sudo-command-line() {
+ [[ -z $BUFFER ]] && zle up-history
+ [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
+}
+zle -N sudo-command-line
+
+#k# Put the current command line into a \kbd{sudo} call
+bindkey "^Os" sudo-command-line
+
+### jump behind the first word on the cmdline.
+### useful to add options.
+function jump_after_first_word() {
+ local words
+ words=(${(z)BUFFER})
+
+ if (( ${#words} <= 1 )) ; then
+ CURSOR=${#BUFFER}
+ else
+ CURSOR=${#${words[1]}}
+ fi
+}
+zle -N jump_after_first_word
+
+bindkey '^x1' jump_after_first_word
+
+# }}}
+
+# {{{ set some important options
+# Please update these tags, if you change the umask settings below.
+#o# r_umask 002
+#o# r_umaskstr rwxrwxr-x
+#o# umask 022
+#o# umaskstr rwxr-xr-x
+(( EUID != 0 )) && umask 002 || umask 022
+
+# history:
+setopt append_history # append history list to the history file (important for multiple parallel zsh sessions!)
+is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
+setopt extended_history # save each command's beginning timestamp and the duration to the history file
+is4 && setopt histignorealldups # If a new command line being added to the history
+ # list duplicates an older one, the older command is removed from the list
+setopt histignorespace # remove command lines from the history list when
+ # the first character on the line is a space
+# setopt histallowclobber # add `|' to output redirections in the history
+# setopt NO_clobber # warning if file exists ('cat /dev/null > ~/.zshrc')
+setopt auto_cd # if a command is issued that can't be executed as a normal command,
+ # and the command is the name of a directory, perform the cd command to that directory
+setopt extended_glob # in order to use #, ~ and ^ for filename generation
+ # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
+ # -> searches for word not in compressed files
+ # don't forget to quote '^', '~' and '#'!
+setopt longlistjobs # display PID when suspending processes as well
+setopt notify # report the status of backgrounds jobs immediately
+setopt hash_list_all # Whenever a command completion is attempted, make sure \
+ # the entire command path is hashed first.
+setopt completeinword # not just at the end
+# setopt nocheckjobs # don't warn me about bg processes when exiting
+setopt nohup # and don't kill them, either
+# setopt printexitvalue # alert me if something failed
+# setopt dvorak # with spelling correction, assume dvorak kb
+setopt auto_pushd # make cd push the old directory onto the directory stack.
+setopt nonomatch # try to avoid the 'zsh: no matches found...'
+setopt nobeep # avoid "beep"ing
+setopt pushd_ignore_dups # don't push the same dir twice.
+
+MAILCHECK=30 # mailchecks
+REPORTTIME=5 # report about cpu-/system-/user-time of command if running longer than 5 seconds
+watch=(notme root) # watch for everyone but me and root
+
+# define word separators (for stuff like backward-word, forward-word, backward-kill-word,..)
+# WORDCHARS='*?_-.[]~=/&;!#$%^(){}<>' # the default
+# WORDCHARS=.
+# WORDCHARS='*?_[]~=&;!#$%^(){}'
+# WORDCHARS='${WORDCHARS:s@/@}'
+
+# only slash should be considered as a word separator:
+slash-backward-kill-word() {
+ local WORDCHARS="${WORDCHARS:s@/@}"
+ # zle backward-word
+ zle backward-kill-word
+}
+zle -N slash-backward-kill-word
+
+#k# Kill everything in a word up to its last \kbd{/}
+bindkey '\ev' slash-backward-kill-word
+
+# }}}
+
+# {{{ history
+
+ZSHDIR=$HOME/.zsh
+
+#v#
+HISTFILE=$HOME/.zsh_history
+isgrmlcd && HISTSIZE=500 || HISTSIZE=5000
+isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
+
+# }}}
+
+# dirstack handling {{{
+
+DIRSTACKSIZE=${DIRSTACKSIZE:-20}
+DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
+
+if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
+ dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
+ # "cd -" won't work after login by just setting $OLDPWD, so
+ [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
+fi
+
+chpwd() {
+ if is42 ; then
+ builtin print -l ${(u)dirstack} >! ${DIRSTACKFILE}
+ else
+ uprint dirstack >! ${DIRSTACKFILE}
+ fi
+}
+
+# }}}
+
+# {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
+if [[ -n "$BATTERY" ]] ; then
+ if check_com -c acpi ; then
+ PERCENT="${(C)${(s| |)$(acpi 2>/dev/null)}[4]}"
+ [[ -z "$PERCENT" ]] && PERCENT='acpi not present'
+
+ if [[ "${PERCENT%%%}" -lt 20 ]] ; then
+ PERCENT="warning: ${PERCENT}%"
+ fi
+ fi
+fi
+# }}}
+
+# set colors for use in prompts {{{
+if zrcautoload colors && colors 2>/dev/null ; then
+ BLUE="%{${fg[blue]}%}"
+ RED="%{${fg_bold[red]}%}"
+ GREEN="%{${fg[green]}%}"
+ CYAN="%{${fg[cyan]}%}"
+ MAGENTA="%{${fg[magenta]}%}"
+ YELLOW="%{${fg[yellow]}%}"
+ WHITE="%{${fg[white]}%}"
+ NO_COLOUR="%{${reset_color}%}"
+else
+ BLUE=$'%{\e[1;34m%}'
+ RED=$'%{\e[1;31m%}'
+ GREEN=$'%{\e[1;32m%}'
+ CYAN=$'%{\e[1;36m%}'
+ WHITE=$'%{\e[1;37m%}'
+ MAGENTA=$'%{\e[1;35m%}'
+ YELLOW=$'%{\e[1;33m%}'
+ NO_COLOUR=$'%{\e[0m%}'
+fi
+
+# }}}
+
+# gather version control information for inclusion in a prompt {{{
+
+# vcs_info() documentation: {{{
+#
+# This functionality requires zsh version >= 4.1.*.
+# To load vcs_info(), copy this file to your $fpath[] and do:
+# % autoload -Uz vcs_info && vcs_info
+#
+# The vcs_info() feature can be configured via zstyle:
+# First, the context in which we are working:
+# :vcs_info:<user-context>:<vcs-string>
+# ...where <vcs-string> is one of:
+# - git, git-svn, hg, darcs, bzr, mtn, svn, cvs or svk
+# ...and <user-context> is a freely configurable string, assignable
+# by the user as the first argument to vcs_info().
+#
+# There is one special value for <vcs-string> named 'init', that
+# is in effect as long as there was no decision what vcs backend to use.
+#
+# There are two pre-defined values for <user-context>:
+# default - the one used if none is specified
+# command - used by vcs_info_lastmsg to lookup its styles.
+# You may *not* use 'print_systems_' as a user-context string,
+# because it is used internally.
+#
+# You can of course use ':vcs_info:*' to match all VCSs in all
+# user-contexts at once.
+#
+# Another special context is 'formats', it is used by the
+# vcs_info_lastmsg() utility function (see below).
+#
+#
+# This is a description of all styles, that are looked up:
+# format - Used in most circumstances.
+# actionformat - Used if a there is a special action going on;
+# (like an interactive rebase or a merge conflict)
+# branchformat - Some backends replace %b in the format and
+# actionformat styles above, not only by a branch
+# name but also by a revision number. This style
+# let's you modify how that string should look like.
+# enable - Check in the 'init' context. If set to false,
+# vcs_info() will do nothing.
+# disable - Provide a list of systems, you don't want
+# the vcs_info() to check for repositories
+# (checked in the 'init' context, too).
+# use-simple - If there are two different ways of gathering
+# information, you can select the simpler one
+# by setting this style to true; the default
+# is to use the not-that-simple code, which is
+# potentially a lot slower but might be more
+# accurate in all possible cases.
+# use-prompt-escapes - determines if we assume that the assembled
+# string from vcs_info() includes prompt escapes.
+# (Used by vcs_info_lastmsg().
+#
+# The use-simple style is currently only available for the bzr backend.
+#
+# The default values for these in all contexts are:
+# format " (%s)-[%b|%a]-"
+# actionformat " (%s)-[%b]-"
+# branchformat "%b:%r" (for bzr, svn and svk)
+# enable true
+# disable (empty list)
+# use-simple false
+# use-prompt-escapes true
+#
+#
+# In format and actionformat, the following replacements are done:
+# %s - The vcs in use (git, hg, svn etc.)
+# %b - Information about the current branch.
+# %a - An identifier, that describes the action.
+# Only makes sense in actionformat.
+# %R - base directory of the repository.
+# %r - repository name
+# If %R is '/foo/bar/repoXY', %r is 'repoXY'.
+#
+#
+# In branchformat these replacements are done:
+# %b - the branch name
+# %r - the current revision number
+#
+# Not all vcs backends have to support all replacements.
+#
+#
+# Function descriptions:
+# vcs_info()
+# The main function, that runs all backends and assembles
+# all data into ${VCS_INFO_message_}. This is the function
+# you want to call from precmd() if you want to include
+# up-to-date information in your prompt (see Variable
+# description, too if you are interested in this).
+#
+# vcs_info_printsys()
+# Prints a list of all supported version control systems.
+# Useful to find out possible contexts or values for the
+# 'disable' style.
+#
+# vcs_info_lastmsg()
+# Outputs the last ${VCS_INFO_message_} value. Takes into account
+# the value of the use-prompt-escapes style in ':vcs_info:formats'.
+#
+#
+# Variable description:
+# ${VCS_INFO_message_} (Note the trailing underscore)
+# This is the storage for the message the last vcs_info()
+# call has assembled.
+#
+#
+# Examples:
+# Don't use vcs_info at all (even though it's in your prompt):
+# % zstyle ':vcs_info:*' enable false
+#
+# Disable the backends for bzr and svk:
+# % zstyle ':vcs_info:*' disable bzr svk
+#
+# Provide a special format for git:
+# % zstyle ':vcs_info:*:git' format ' GIT, BABY! [%b]'
+# % zstyle ':vcs_info:*:git' actionformat ' GIT ACTION! [%b|%a]'
+#
+# Use the quicker bzr backend (if you do, please report if it does
+# the-right-thing[tm] - thanks):
+# % zstyle ':vcs_info:*:bzr' use-simple true
+#
+# Display the revision number in yellow for bzr and svn:
+# % zstyle ':vcs_info:*:(svn|bzr)' branchformat '%b%{'${fg[yellow]}'%}:%r'
+#
+# If you want colors, make sure you enclose the color codes in %{...%},
+# if you want to use the string provided by vcs_info() in prompts.
+#
+# Here is an example of how to include vcs_info in PS1 (*requires*
+# 'setopt prompt_subst'):
+#
+# PS1='%(?..[%?]-)%3~%${VCS_INFO_message_}#'
+# precmd () { vcs_info; }
+#
+# Here is how to print the vcs infomation as a command:
+# alias vcsi='vcs_info command; vcs_info_lastmsg'
+#
+# This way, you can even define different formats for output via
+# vcs_info_lastmsg() in the ':vcs_info:command:*' namespace.
+#
+# }}}
+VCS_INFO_adjust () { #{{{
+ [[ -n ${vcs_comm[overwrite_name]} ]] && vcs=${vcs_comm[overwrite_name]}
+ return 0
+}
+# }}}
+VCS_INFO_check_com () { #{{{
+ (( ${+commands[$1]} )) && [[ -x ${commands[$1]} ]] && return 0
+ return 1
+}
+# }}}
+VCS_INFO_format () { # {{{
+ local msg
+
+ if [[ -n ${1} ]] ; then
+ zstyle -s ":vcs_info:${usercontext}:${vcs}" actionformat msg
+ [[ -z ${msg} ]] && msg=' (%s)-[%b|%a]-'
+ else
+ zstyle -s ":vcs_info:${usercontext}:${vcs}" format msg
+ [[ -z ${msg} ]] && msg=' (%s)-[%b]-'
+ fi
+ printf '%s' ${msg}
+}
+# }}}
+VCS_INFO_realpath () { #{{{
+ # replacing 'readlink -f', which is really not portable.
+ # forcing a subshell, to ensure chpwd() is not removed
+ # from the calling shell (if VCS_INFO_realpath() is called
+ # manually).
+ (
+ (( ${+functions[chpwd]} )) && unfunction chpwd
+ setopt chaselinks
+ cd $1 2>/dev/null && pwd
+ )
+}
+# }}}
+VCS_INFO_git_getaction () { #{{{
+ local gitaction='' gitdir=${1}
+ local tmp
+
+ for tmp in "${gitdir}/rebase-apply" \
+ "${gitdir}/rebase" \
+ "${gitdir}/../.dotest" ; do
+ if [[ -d ${tmp} ]] ; then
+ if [[ -f "${tmp}/rebasing" ]] ; then
+ gitaction="rebase"
+ elif [[ -f "${tmp}/applying" ]] ; then
+ gitaction="am"
+ else
+ gitaction="am/rebase"
+ fi
+ printf '%s' ${gitaction}
+ return 0
+ fi
+ done
+
+ for tmp in "${gitdir}/rebase-merge/interactive" \
+ "${gitdir}/.dotest-merge/interactive" ; do
+ if [[ -f "${tmp}" ]] ; then
+ printf '%s' "rebase-i"
+ return 0
+ fi
+ done
+
+ for tmp in "${gitdir}/rebase-merge" \
+ "${gitdir}/.dotest-merge" ; do
+ if [[ -d "${tmp}" ]] ; then
+ printf '%s' "rebase-m"
+ return 0
+ fi
+ done
+
+ if [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
+ printf '%s' "merge"
+ else
+ if [[ -f "${gitdir}/BISECT_LOG" ]] ; then
+ printf '%s' "bisect"
+ fi
+ fi
+
+ return 1
+}
+# }}}
+VCS_INFO_git_getbranch () { #{{{
+ local gitbranch gitdir=${1}
+ local gitsymref='git symbolic-ref HEAD'
+
+ if [[ -d "${gitdir}/rebase-apply" ]] \
+ || [[ -d "${gitdir}/rebase" ]] \
+ || [[ -d "${gitdir}/../.dotest" ]] \
+ || [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
+ gitbranch="$(${(z)gitsymref} 2> /dev/null)"
+ [[ -z ${gitbranch} ]] && gitbranch="$(< ${gitdir}/rebase-apply/head-name)"
+
+ elif [[ -f "${gitdir}/rebase-merge/interactive" ]] \
+ || [[ -d "${gitdir}/rebase-merge" ]] ; then
+ gitbranch="$(< ${gitdir}/rebase-merge/head-name)"
+
+ elif [[ -f "${gitdir}/.dotest-merge/interactive" ]] \
+ || [[ -d "${gitdir}/.dotest-merge" ]] ; then
+ gitbranch="$(< ${gitdir}/.dotest-merge/head-name)"
+
+ else
+ gitbranch="$(${(z)gitsymref} 2> /dev/null)"
+
+ if [[ $? -ne 0 ]] ; then
+ gitbranch="$(git describe --exact-match HEAD 2>/dev/null)"
+
+ if [[ $? -ne 0 ]] ; then
+ gitbranch="${${"$(< $gitdir/HEAD)"}[1,7]}..."
+ fi
+ fi
+ fi
+
+ printf '%s' "${gitbranch##refs/heads/}"
+}