etc/zsh/zshrc

   1 # Filename:      zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 # Latest change: Mon Feb 11 18:00:55 CET 2008 [mika]
   7 ################################################################################
   8 # This file is sourced only for interactive shells. It
   9 # should contain commands to set up aliases, functions,
  10 # options, key bindings, etc.
  11 #
  12 # Global Order: zshenv, zprofile, zshrc, zlogin
  13 ################################################################################
  14
  15 # zsh-refcard-tag documentation: {{{
  16 #   You may notice strange looking comments in the zshrc (and ~/.zshrc as
  17 #   well). These are there for a purpose. grml's zsh-refcard can now be
  18 #   automatically generated from the contents of the actual configuration
  19 #   files. However, we need a little extra information on which comments
  20 #   and what lines of code to take into account (and for what purpose).
  21 #
  22 # Here is what they mean:
  23 #
  24 # List of tags (comment types) used:
  25 #   #a#     Next line contains an important alias, that should
  26 #           be included in the grml-zsh-refcard.
  27 #           (placement tag: @@INSERT-aliases@@)
  28 #   #f#     Next line contains the beginning of an important function.
  29 #           (placement tag: @@INSERT-functions@@)
  30 #   #v#     Next line contains an important variable.
  31 #           (placement tag: @@INSERT-variables@@)
  32 #   #k#     Next line contains an important keybinding.
  33 #           (placement tag: @@INSERT-keybindings@@)
  34 #   #d#     Hashed directories list generation:
  35 #               start   denotes the start of a list of 'hash -d'
  36 #                       definitions.
  37 #               end     denotes its end.
  38 #           (placement tag: @@INSERT-hasheddirs@@)
  39 #   #A#     Abbreviation expansion list generation:
  40 #               start   denotes the beginning of abbreviations.
  41 #               end     denotes their end.
  42 #           Lines within this section that end in '#d .*' provide
  43 #           extra documentation to be included in the refcard.
  44 #           (placement tag: @@INSERT-abbrev@@)
  45 #   #m#     This tag allows you to manually generate refcard entries
  46 #           for code lines that are hard/impossible to parse.
  47 #               Example:
  48 #                   #m# k ESC-h Call the run-help function
  49 #               That would add a refcard entry in the keybindings table
  50 #               for 'ESC-h' with the given comment.
  51 #           So the syntax is: #m# <section> <argument> <comment>
  52 #   #o#     This tag lets you insert entries to the 'other' hash.
  53 #           Generally, this should not be used. It is there for
  54 #           things that cannot be done easily in another way.
  55 #           (placement tag: @@INSERT-other-foobar@@)
  56 #
  57 #   All of these tags (except for m and o) take two arguments, the first
  58 #   within the tag, the other after the tag:
  59 #
  60 #   #<tag><section># <comment>
  61 #
  62 #   Where <section> is really just a number, which are defined by the
  63 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  64 #   instead of names is, that for the reader, the tag should not differ
  65 #   much from a regular comment. For zsh, it is a regular comment indeed.
  66 #   The numbers have got the following meanings:
  67 #         0 -> "default"
  68 #         1 -> "system"
  69 #         2 -> "user"
  70 #         3 -> "debian"
  71 #         4 -> "search"
  72 #         5 -> "shortcuts"
  73 #         6 -> "services"
  74 #
  75 #   So, the following will add an entry to the 'functions' table in the
  76 #   'system' section, with a (hopefully) descriptive comment:
  77 #       #f1# Edit an alias via zle
  78 #       edalias() {
  79 #
  80 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  81 #   that can be found in 'grml-zsh-refcard.tex.in'.
  82 #   If the section number is omitted, the 'default' section is assumed.
  83 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
  84 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
  85 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
  86 #}}}
  87
  88 # zsh profiling {{{
  89 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
  90 if [[ -n $ZSH_PROFILE_RC ]] ; then
  91     zmodload zsh/zprof
  92 fi
  93 # }}}
  94
  95 # {{{ check for version/system
  96 # check for versions (compatibility reasons)
  97 is4(){
  98     [[ $ZSH_VERSION == <4->* ]] && return 0
  99     return 1
 100 }
 101
 102 is41(){
 103     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 104     return 1
 105 }
 106
 107 is42(){
 108     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 109     return 1
 110 }
 111
 112 is43(){
 113     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 114     return 1
 115 }
 116
 117 #f1# Checks whether or not you're running grml
 118 isgrml(){
 119     [[ -f /etc/grml_version ]] && return 0
 120     return 1
 121 }
 122
 123 #f1# Checks whether or not you're running a grml cd
 124 isgrmlcd(){
 125     [[ -f /etc/grml_cd ]] && return 0
 126     return 1
 127 }
 128
 129 if isgrml ; then
 130 #f1# Checks whether or not you're running grml-small
 131     isgrmlsmall() {
 132         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 133     }
 134 else
 135     isgrmlsmall() { return 1 }
 136 fi
 137
 138 #f1# are we running within an utf environment?
 139 isutfenv() {
 140     case "$LANG $CHARSET $LANGUAGE" in
 141         *utf*) return 0 ;;
 142         *UTF*) return 0 ;;
 143         *)     return 1 ;;
 144     esac
 145 }
 146
 147 # check for user, if not running as root set $SUDO to sudo
 148 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 149
 150 # change directory to home on first invocation of zsh
 151 # important for rungetty -> autologin
 152 # Thanks go to Bart Schaefer!
 153 isgrml && checkhome() {
 154     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 155         export ALREADY_DID_CD_HOME=$HOME
 156         cd
 157     fi
 158 }
 159
 160 # check for zsh v3.1.7+
 161
 162 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 163      || ${ZSH_VERSION} == 3.<2->.<->*    \
 164      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 165
 166     printf '-!-\n'
 167     printf '-!- In this configuration we try to make use of features, that only\n'
 168     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 169     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 170     printf '-!- advanced features in all supported versions.\n'
 171     printf '-!-\n'
 172     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 173     printf '-!-\n'
 174     printf '-!- While this *may* work, it might as well fail.\n'
 175     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 176     printf '-!-\n'
 177     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 178     printf '-!- If it does today, you'\''ve been lucky.\n'
 179     printf '-!-\n'
 180     printf '-!- Ye been warned!\n'
 181     printf '-!-\n'
 182
 183     function zstyle() { : }
 184 fi
 185
 186 # }}}
 187
 188 # utility functions {{{
 189 # this function checks if a command exists and returns either true
 190 # or false. This avoids using 'which' and 'whence', which will
 191 # avoid problems with aliases for which on certain weird systems. :-)
 192 check_com() {
 193     local -i comonly
 194
 195     if [[ ${1} == '-c' ]] ; then
 196         (( comonly = 1 ))
 197         shift
 198     else
 199         (( comonly = 0 ))
 200     fi
 201
 202     if (( ${#argv} != 1 )) ; then
 203         printf 'usage: check_com [-c] <command>\n' >&2
 204         return 1
 205     fi
 206
 207     if (( comonly > 0 )) ; then
 208         [[ -n ${commands[$1]}  ]] && return 0
 209         return 1
 210     fi
 211
 212     if   [[ -n ${commands[$1]}    ]] \
 213       || [[ -n ${functions[$1]}   ]] \
 214       || [[ -n ${aliases[$1]}     ]] \
 215       || [[ -n ${reswords[(r)$1]} ]] ; then
 216
 217         return 0
 218     fi
 219
 220     return 1
 221 }
 222
 223 # creates an alias and precedes the command with
 224 # sudo if $EUID is not zero.
 225 salias() {
 226     local only=0 ; local multi=0
 227     while [[ ${1} == -* ]] ; do
 228         case ${1} in
 229             (-o) only=1 ;;
 230             (-a) multi=1 ;;
 231             (--) shift ; break ;;
 232             (-h)
 233                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 234                 printf '  -h      shows this help text.\n'
 235                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 236                 printf '          be careful using this option.\n'
 237                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 238                 return 0
 239                 ;;
 240             (*) printf "unkown option: '%s'\n" "${1}" ; return 1 ;;
 241         esac
 242         shift
 243     done
 244
 245     if (( ${#argv} > 1 )) ; then
 246         printf 'Too many arguments %s\n' "${#argv}"
 247         return 1
 248     fi
 249
 250     key="${1%%\=*}" ;  val="${1#*\=}"
 251     if (( EUID == 0 )) && (( only == 0 )); then
 252         alias -- "${key}=${val}"
 253     elif (( EUID > 0 )) ; then
 254         (( multi > 0 )) && val="${val// ; / ; sudo }"
 255         alias -- "${key}=sudo ${val}"
 256     fi
 257
 258     return 0
 259 }
 260
 261 # Check if we can read given files and source those we can.
 262 xsource() {
 263     if (( ${#argv} < 1 )) ; then
 264         printf 'usage: xsource FILE(s)...\n' >&2
 265         return 1
 266     fi
 267
 268     while (( ${#argv} > 0 )) ; do
 269         [[ -r ${1} ]] && source ${1}
 270         shift
 271     done
 272     return 0
 273 }
 274
 275 # Check if we can read a given file and 'cat(1)' it.
 276 xcat() {
 277     if (( ${#argv} != 1 )) ; then
 278         printf 'usage: xcat FILE\n' >&2
 279         return 1
 280     fi
 281
 282     [[ -r ${1} ]] && cat ${1}
 283     return 0
 284 }
 285
 286 # Remove these functions again, they are of use only in these
 287 # setup files. This should be called at the end of .zshrc.
 288 xunfunction() {
 289     local -a funcs
 290     funcs=(salias xcat xsource xunfunction zrcautoload)
 291
 292     for func in $funcs ; do
 293         [[ -n ${functions[$func]} ]] \
 294             && unfunction $func
 295     done
 296     return 0
 297 }
 298
 299 # autoload wrapper - use this one instead of autoload directly
 300 function zrcautoload() {
 301     setopt local_options extended_glob
 302     local fdir ffile
 303     local -i ffound
 304
 305     ffile=${1}
 306     (( found = 0 ))
 307     for fdir in ${fpath} ; do
 308         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 309     done
 310
 311     (( ffound == 0 )) && return 1
 312     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 313         autoload -U ${ffile} || return 1
 314     else
 315         autoload ${ffile} || return 1
 316     fi
 317     return 0
 318 }
 319
 320 #}}}
 321
 322 # Load is-at-least() for more precise version checks {{{
 323
 324 # Note that this test will *always* fail, if the is-at-least
 325 # function could not be marked for autoloading.
 326 zrcautoload is-at-least || is-at-least() { return 1 }
 327
 328 # }}}
 329
 330 # locale setup {{{
 331 if [[ -z "$LANG" ]] ; then
 332     xsource "/etc/default/locale"
 333 fi
 334
 335 export LANG=${LANG:-en_US.iso885915}
 336 for var in LC_ALL LC_MESSAGES ; do
 337     [[ -n ${(P)var} ]] && export $var
 338 done
 339
 340 xsource "/etc/sysconfig/keyboard"
 341
 342 TZ=$(xcat /etc/timezone)
 343 # }}}
 344
 345 # check for potentially old files in 'completion.d' {{{
 346 setopt extendedglob
 347 xof=(/etc/zsh/completion.d/*~/etc/zsh/completion.d/_*(N))
 348 if (( ${#xof} > 0 )) ; then
 349     printf '\n -!- INFORMATION\n\n'
 350     printf ' -!- %s file(s) not starting with an underscore (_) found in\n' ${#xof}
 351     printf ' -!- /etc/zsh/completion.d/.\n\n'
 352     printf ' -!- While this has been the case in old versions of grml-etc-core,\n'
 353     printf ' -!- recent versions of the grml-zsh-setup have all these files rewritten\n'
 354     printf ' -!- and renamed. Furthermore, the grml-zsh-setup will *only* add files\n'
 355     printf ' -!- named _* to that directory.\n\n'
 356     printf ' -!- If you added functions to completion.d yourself, please consider\n'
 357     printf ' -!- moving them to /etc/zsh/functions.d/. Files in that directory, not\n'
 358     printf ' -!- starting with an underscore are marked for automatic loading\n'
 359     printf ' -!- by default (so that is quite convenient).\n\n'
 360     printf ' -!- If there are files *not* starting with an underscore from an older\n'
 361     printf ' -!- grml-etc-core in completion.d, you may safely remove them.\n\n'
 362     printf ' -!- Delete the files for example via running:\n\n'
 363     printf "      rm ${xof}\n\n"
 364     printf ' -!- Note, that this message will *not* go away, unless you yourself\n'
 365     printf ' -!- resolve the situation manually.\n\n'
 366     BROKEN_COMPLETION_DIR=1
 367 fi
 368 unset xof
 369 # }}}
 370
 371 # {{{ set some variables
 372 if check_com -c vim ; then
 373 #v#
 374     export EDITOR=${EDITOR:-vim}
 375 else
 376     export EDITOR=${EDITOR:-vi}
 377 fi
 378
 379 #v#
 380 export PAGER=${PAGER:-less}
 381
 382 #v#
 383 export MAIL=${MAIL:-/var/mail/$USER}
 384
 385 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 386 export SHELL='/bin/zsh'
 387
 388 # color setup for ls:
 389 check_com -c dircolors && eval $(dircolors -b)
 390
 391 # set width of man pages to 80 for more convenient reading
 392 # export MANWIDTH=${MANWIDTH:-80}
 393
 394 # Search path for the cd command
 395 #  cdpath=(.. ~)
 396
 397 # completion functions go to /etc/zsh/completion.d
 398 # function files may be put into /etc/zsh/functions.d, from where they
 399 # will be automatically autoloaded.
 400 if [[ -n "$BROKEN_COMPLETION_DIR" ]] ; then
 401     print 'Warning: not setting completion directories because broken files have been found.' >&2
 402 else
 403     [[ -d /etc/zsh/completion.d ]] && fpath=( $fpath /etc/zsh/completion.d )
 404     if [[ -d /etc/zsh/functions.d ]] ; then
 405         fpath+=( /etc/zsh/functions.d )
 406         for func in /etc/zsh/functions.d/[^_]*[^~] ; do
 407             zrcautoload -U ${func:t}
 408         done
 409     fi
 410 fi
 411
 412 # automatically remove duplicates from these arrays
 413 typeset -U path cdpath fpath manpath
 414 # }}}
 415
 416 # {{{ keybindings
 417 if [[ "$TERM" != emacs ]] ; then
 418     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 419     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 420     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 421     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 422     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 423     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 424     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 425     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 426     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 427     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 428     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 429     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 430     # ncurses stuff:
 431     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 432     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 433     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 434     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 435     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 436     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 437     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 438     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 439 fi
 440
 441 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 442 # use emacs style per default:
 443 bindkey -e
 444 # use vi style:
 445 # bindkey -v
 446
 447 #if [[ "$TERM" == screen ]] ; then
 448 bindkey '\e[1~' beginning-of-line       # home
 449 bindkey '\e[4~' end-of-line             # end
 450 bindkey '\e[A'  up-line-or-search       # cursor up
 451 bindkey '\e[B'  down-line-or-search     # <ESC>-
 452
 453 bindkey '^xp'   history-beginning-search-backward
 454 bindkey '^xP'   history-beginning-search-forward
 455 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 456 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 457 # if terminal type is set to 'rxvt':
 458 bindkey '\e[7~' beginning-of-line       # home
 459 bindkey '\e[8~' end-of-line             # end
 460 #fi
 461
 462 # insert unicode character
 463 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 464 # See for example http://unicode.org/charts/ for unicode characters code
 465 zrcautoload insert-unicode-char
 466 zle -N insert-unicode-char
 467 #k# Insert Unicode character
 468 bindkey '^Xi' insert-unicode-char
 469
 470 # just type 'cd ...' to get 'cd ../..'
 471 #  rationalise-dot() {
 472 #  if [[ $LBUFFER == *.. ]] ; then
 473 #    LBUFFER+=/..
 474 #  else
 475 #    LBUFFER+=.
 476 #  fi
 477 #  }
 478 #  zle -N rationalise-dot
 479 #  bindkey . rationalise-dot
 480
 481 #  bindkey '\eq' push-line-or-edit
 482 # }}}
 483
 484 # a generic accept-line wrapper {{{
 485
 486 # This widget can prevent unwanted autocorrections from command-name
 487 # to _command-name, rehash automatically on enter and call any number
 488 # of builtin and user-defined widgets in different contexts.
 489 #
 490 # For a broader description, see:
 491 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 492 #
 493 # The code is imported from the file 'zsh/functions/accept-line' from
 494 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 495 # distributed under the same terms as zsh itself.
 496
 497 # A newly added command will may not be found or will cause false
 498 # correction attempts, if you got auto-correction set. By setting the
 499 # following style, we force accept-line() to rehash, if it cannot
 500 # find the first word on the command line in the $command[] hash.
 501 zstyle ':acceptline:*' rehash true
 502
 503 function Accept-Line() {
 504     setopt localoptions noksharrays
 505     local -a subs
 506     local -xi aldone
 507     local sub
 508
 509     zstyle -a ":acceptline:${alcontext}" actions subs
 510
 511     (( ${#subs} < 1 )) && return 0
 512
 513     (( aldone = 0 ))
 514     for sub in ${subs} ; do
 515         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 516         zle ${sub}
 517
 518         (( aldone > 0 )) && break
 519     done
 520 }
 521
 522 function Accept-Line-getdefault() {
 523     local default_action
 524
 525     zstyle -s ":acceptline:${alcontext}" default_action default_action
 526     case ${default_action} in
 527         ((accept-line|))
 528             printf ".accept-line"
 529             ;;
 530         (*)
 531             printf ${default_action}
 532             ;;
 533     esac
 534 }
 535
 536 function accept-line() {
 537     setopt localoptions noksharrays
 538     local -a cmdline
 539     local -x alcontext
 540     local buf com fname format msg default_action
 541
 542     alcontext='default'
 543     buf="${BUFFER}"
 544     cmdline=(${(z)BUFFER})
 545     com="${cmdline[1]}"
 546     fname="_${com}"
 547
 548     zstyle -t ":acceptline:${alcontext}" rehash \
 549         && [[ -z ${commands[$com]} ]]           \
 550         && rehash
 551
 552     if    [[ -n ${reswords[(r)$com]} ]] \
 553        || [[ -n ${aliases[$com]}     ]] \
 554        || [[ -n ${functions[$com]}   ]] \
 555        || [[ -n ${builtins[$com]}    ]] \
 556        || [[ -n ${commands[$com]}    ]] ; then
 557
 558         # there is something sensible to execute, just do it.
 559         alcontext='normal'
 560         zle Accept-Line
 561
 562         default_action=$(Accept-Line-getdefault)
 563         zstyle -T ":acceptline:${alcontext}" call_default \
 564             && zle ${default_action}
 565         return
 566     fi
 567
 568     if    [[ -o correct              ]] \
 569        || [[ -o correctall           ]] \
 570        && [[ -n ${functions[$fname]} ]] ; then
 571
 572         # nothing there to execute but there is a function called
 573         # _command_name; a completion widget. Makes no sense to
 574         # call it on the commandline, but the correct{,all} options
 575         # will ask for it nevertheless, so warn the user.
 576         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 577             # Okay, we warned the user before, he called us again,
 578             # so have it his way.
 579             alcontext='force'
 580             zle Accept-Line
 581
 582             default_action=$(Accept-Line-getdefault)
 583             zstyle -T ":acceptline:${alcontext}" call_default \
 584                 && zle ${default_action}
 585             return
 586         fi
 587
 588         # prepare warning message for the user, configurable via zstyle.
 589         zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 590
 591         if [[ -z ${msg} ]] ; then
 592             msg="%c will not execute and completion %f exists."
 593         fi
 594
 595         zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 596
 597         zle -M -- "${msg}"
 598         return
 599     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 600         # If we are here, the commandline contains something that is not
 601         # executable, which is neither subject to _command_name correction
 602         # and is not empty. might be a variable assignment
 603         alcontext='misc'
 604         zle Accept-Line
 605
 606         default_action=$(Accept-Line-getdefault)
 607         zstyle -T ":acceptline:${alcontext}" call_default \
 608             && zle ${default_action}
 609         return
 610     fi
 611
 612     # If we got this far, the commandline only contains whitespace, or is empty.
 613     alcontext='empty'
 614     zle Accept-Line
 615
 616     default_action=$(Accept-Line-getdefault)
 617     zstyle -T ":acceptline:${alcontext}" call_default \
 618         && zle ${default_action}
 619 }
 620
 621 zle -N accept-line
 622 zle -N Accept-Line
 623
 624 # }}}
 625
 626 # power completion - abbreviation expansion {{{
 627 # power completion / abbreviation expansion / buffer expansion
 628 # see http://zshwiki.org/home/examples/zleiab for details
 629 # less risky than the global aliases but powerful as well
 630 # just type the abbreviation key and afterwards ',.' to expand it
 631 declare -A abk
 632 setopt extendedglob
 633 setopt interactivecomments
 634 abk=(
 635 # key  # value                (#d additional doc string)
 636 #A# start
 637     '...' '../..'
 638     '....' '../../..'
 639     'BG' '& exit'
 640     'C' '| wc -l'
 641     'G' '|& grep --color=auto'
 642     'H' '| head'
 643     'Hl' ' --help |& less -r'      #d (Display help in pager)
 644     'L' '| less'
 645     'LL' '|& less -r'
 646     'M' '| most'
 647     'N' '&>/dev/null'              #d (No Output)
 648     'R' '| tr A-z N-za-m'          #d (ROT13)
 649     'SL' '| sort | less'
 650     'S' '| sort -u'
 651     'T' '| tail'
 652     'V' '|& vim -'
 653 #A# end
 654     'hide' "echo -en '\033]50;nil2\007'"
 655     'tiny' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
 656     'small' 'echo -en "\033]50;6x10\007"'
 657     'medium' 'echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
 658     'default' 'echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
 659     'large' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
 660     'huge' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
 661     'smartfont' 'echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
 662     'semifont' 'echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
 663     'da' 'du -sch'
 664     'j' 'jobs -l'
 665     'u' 'translate -i'
 666     'co' "./configure && make && sudo make install"
 667     'CH' "./configure --help"
 668     'conkeror' 'firefox -chrome chrome://conkeror/content'
 669     'dir' 'ls -lSrah'
 670     'lad' $'ls -d .*(/)\n# only show dot-directories'
 671     'lsa' $'ls -a .*(.)\n# only show dot-files'
 672     'lss' $'ls -l *(s,S,t)\n# only files with setgid/setuid/sticky flag'
 673     'lsl' $'ls -l *(@[1,10])\n# only symlinks'
 674     'lsx' $'ls -l *(*[1,10])\n# only executables'
 675     'lsw' $'ls -ld *(R,W,X.^ND/)\n# world-{readable,writable,executable} files'
 676     'lsbig' $'ls -flh *(.OL[1,10])\n# display the biggest files'
 677     'lsd' $'ls -d *(/)\n# only show directories'
 678     'lse' $'ls -d *(/^F)\n# only show empty directories'
 679     'lsnew' $'ls -rl *(D.om[1,10])\n# display the newest files'
 680     'lsold' $'ls -rtlh *(D.om[-11,-1])\n # display the oldest files'
 681     'lssmall' $'ls -Srl *(.oL[1,10])\n# display the smallest files'
 682     'rw-' 'chmod 600'
 683     '600' 'chmod u+rw-x,g-rwx,o-rwx'
 684     'rwx' 'chmod u+rwx'
 685     '700' 'chmod u+rwx,g-rwx,o-rwx'
 686     'r--' 'chmod u+r-wx,g-rwx,o-rwx'
 687     '644' $'chmod u+rw-x,g+r-wx,o+r-wx\n # 4=r,2=w,1=x'
 688     '755' 'chmod u+rwx,g+r-w+x,o+r-w+x'
 689     'md' 'mkdir -p '
 690     'cmplayer' 'mplayer -vo -fs -zoom fbdev'
 691     'fbmplayer' 'mplayer -vo -fs -zoom fbdev'
 692     'fblinks' 'links2 -driver fb'
 693     'insecssh' 'ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 694     'insecscp' 'scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 695     'fori' 'for i ({..}) { }'
 696     'cx' 'chmod +x'
 697     'e'  'print -l'
 698     'se' 'setopt interactivecomments'
 699     'va' 'valac --vapidir=../vapi/ --pkg=gtk+-2.0 gtktest.vala'
 700     'fb2' '=mplayer -vo fbdev -fs -zoom 1>/dev/null -xy 2'
 701     'fb3' '=mplayer -vo fbdev -fs  -zoom 1>/dev/null -xy 3'
 702     'ci' 'centericq'
 703     'D'  'export DISPLAY=:0.0'
 704     'mp' 'mplayer -vo xv -fs -zoom'
 705 )
 706
 707 globalias() {
 708     local MATCH
 709     matched_chars='[.-|_a-zA-Z0-9]#'
 710     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 711     LBUFFER+=${abk[$MATCH]:-$MATCH}
 712 }
 713
 714 zle -N globalias
 715 bindkey ",." globalias
 716 # }}}
 717
 718 # {{{ autoloading
 719 zrcautoload zmv    # who needs mmv or rename?
 720 zrcautoload history-search-end
 721
 722 # we don't want to quote/espace URLs on our own...
 723 # if autoload -U url-quote-magic ; then
 724 #    zle -N self-insert url-quote-magic
 725 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 726 # else
 727 #    print 'Notice: no url-quote-magic available :('
 728 # fi
 729 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 730
 731 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 732 alias run-help >&/dev/null && unalias run-help
 733 zrcautoload run-help # use via 'esc-h'
 734
 735 # completion system
 736 if zrcautoload compinit && compinit 2>/dev/null ; then
 737     compinit 2>/dev/null || print 'Notice: no compinit available :('
 738 else
 739     print 'Notice: no compinit available :('
 740     function zstyle { }
 741     function compdef { }
 742 fi
 743
 744 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 745
 746 is4 && \
 747 for mod in complist deltochar mathfunc ; do
 748     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 749 done
 750
 751 # autoload zsh modules when they are referenced
 752 if is4 ; then
 753     tmpargs=(
 754         a   stat
 755         a   zpty
 756         ap  zprof
 757         ap  mapfile
 758     )
 759
 760     while (( ${#tmpargs} > 0 )) ; do
 761         zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
 762         shift 2 tmpargs
 763     done
 764     unset tmpargs
 765 fi
 766
 767 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 768     #k# Insert files
 769     bindkey "^Xf" insert-files # C-x-f
 770 fi
 771
 772 bindkey ' '   magic-space    # also do history expansion on space
 773 #k# Trigger menu-complete
 774 bindkey '\ei' menu-complete  # menu completion via esc-i
 775
 776 # press esc-e for editing command line in $EDITOR or $VISUAL
 777 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 778     #k# Edit the current line in \kbd{\$EDITOR}
 779     bindkey '\ee' edit-command-line
 780 fi
 781
 782 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 783     #k# menu selection: pick item but stay in the menu
 784     bindkey -M menuselect '\e^M' accept-and-menu-complete
 785
 786     # use the vi navigation keys (hjkl) besides cursor keys in menu completion
 787     #bindkey -M menuselect 'h' vi-backward-char        # left
 788     #bindkey -M menuselect 'k' vi-up-line-or-history   # up
 789     #bindkey -M menuselect 'l' vi-forward-char         # right
 790     #bindkey -M menuselect 'j' vi-down-line-or-history # bottom
 791
 792     # accept a completion and try to complete again by using menu
 793     # completion; very useful with completing directories
 794     # by using 'undo' one's got a simple file browser
 795     bindkey -M menuselect '^o' accept-and-infer-next-history
 796 fi
 797
 798 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 799 _bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
 800 zle -N _bkdate
 801
 802 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 803 bindkey '^Ed' _bkdate
 804
 805 # press esc-m for inserting last typed word again (thanks to caphuso!)
 806 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 807 zle -N insert-last-typed-word;
 808
 809 #k# Insert last typed word
 810 bindkey "\em" insert-last-typed-word
 811
 812 # set command prediction from history, see 'man 1 zshcontrib'
 813 #  is4 && zrcautoload predict-on && \
 814 #  zle -N predict-on         && \
 815 #  zle -N predict-off        && \
 816 #  bindkey "^X^Z" predict-on && \
 817 #  bindkey "^Z" predict-off
 818
 819 #k# Shortcut for \kbd{fg<enter>}
 820 bindkey -s '^z' "fg\n"
 821
 822 # press ctrl-q to quote line:
 823 #  mquote () {
 824 #        zle beginning-of-line
 825 #        zle forward-word
 826 #        # RBUFFER="'$RBUFFER'"
 827 #        RBUFFER=${(q)RBUFFER}
 828 #        zle end-of-line
 829 #  }
 830 #  zle -N mquote && bindkey '^q' mquote
 831
 832 # run command line as user root via sudo:
 833 sudo-command-line() {
 834     [[ -z $BUFFER ]] && zle up-history
 835     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
 836 }
 837 zle -N sudo-command-line
 838
 839 #k# Put the current command line into a \kbd{sudo} call
 840 bindkey "^Os" sudo-command-line
 841
 842 ### jump behind the first word on the cmdline.
 843 ### useful to add options.
 844 function jump_after_first_word() {
 845     local words
 846     words=(${(z)BUFFER})
 847
 848     if (( ${#words} <= 1 )) ; then
 849         CURSOR=${#BUFFER}
 850     else
 851         CURSOR=${#${words[1]}}
 852     fi
 853 }
 854 zle -N jump_after_first_word
 855
 856 bindkey '^x1' jump_after_first_word
 857
 858 # }}}
 859
 860 # {{{ set some important options
 861 # Please update these tags, if you change the umask settings below.
 862 #o# r_umask     002
 863 #o# r_umaskstr  rwxrwxr-x
 864 #o# umask       022
 865 #o# umaskstr    rwxr-xr-x
 866 (( EUID != 0 )) && umask 002 || umask 022
 867
 868 # history:
 869 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 870 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 871 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 872 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 873                             # list duplicates an older one, the older command is removed from the list
 874 setopt histignorespace      # remove command lines from the history list when
 875                             # the first character on the line is a space
 876 #  setopt histallowclobber    # add `|' to output redirections in the history
 877 #  setopt NO_clobber          # warning if file exists ('cat /dev/null > ~/.zshrc')
 878 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 879                             # and the command is the name of a directory, perform the cd command to that directory
 880 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 881                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 882                             # -> searches for word not in compressed files
 883                             # don't forget to quote '^', '~' and '#'!
 884 setopt longlistjobs         # display PID when suspending processes as well
 885 setopt notify               # report the status of backgrounds jobs immediately
 886 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 887                             # the entire command path is hashed first.
 888 setopt completeinword       # not just at the end
 889 # setopt nocheckjobs          # don't warn me about bg processes when exiting
 890 setopt nohup                # and don't kill them, either
 891 # setopt printexitvalue       # alert me if something failed
 892 # setopt dvorak               # with spelling correction, assume dvorak kb
 893 setopt auto_pushd           # make cd push the old directory onto the directory stack.
 894 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 895 setopt nobeep               # avoid "beep"ing
 896 setopt pushd_ignore_dups    # don't push the same dir twice.
 897
 898 MAILCHECK=30       # mailchecks
 899 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 900 watch=(notme root) # watch for everyone but me and root
 901
 902 # define word separators (for stuff like backward-word, forward-word, backward-kill-word,..)
 903 #  WORDCHARS='*?_-.[]~=/&;!#$%^(){}<>' # the default
 904 #  WORDCHARS=.
 905 #  WORDCHARS='*?_[]~=&;!#$%^(){}'
 906 #  WORDCHARS='${WORDCHARS:s@/@}'
 907
 908 # only slash should be considered as a word separator:
 909 slash-backward-kill-word() {
 910     local WORDCHARS="${WORDCHARS:s@/@}"
 911     # zle backward-word
 912     zle backward-kill-word
 913 }
 914 zle -N slash-backward-kill-word
 915
 916 #k# Kill everything in a word up to its last \kbd{/}
 917 bindkey '\ev' slash-backward-kill-word
 918
 919 # }}}
 920
 921 # {{{ history
 922
 923 ZSHDIR=$HOME/.zsh
 924
 925 #v#
 926 HISTFILE=$HOME/.zsh_history
 927 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
 928 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
 929
 930 # }}}
 931
 932 # dirstack handling {{{
 933
 934 # TODO: the is42 tests are in place, because (u) requires at least 4.2.0
 935 #       of zsh. We also disable loading potentielly old .zdir files when
 936 #       starting a pre-4.2.0 zsh.
 937 #       Implementing a workaround-(u) for older shells is the obvious
 938 #       solution here, if we want this for all supported shells.
 939
 940 DIRSTACKSIZE=20
 941 if is42 && [[ -f ~/.zdirs ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
 942     dirstack=( ${(f)"$(< ~/.zdirs)"} )
 943     # "cd -" won't work after login by just setting $OLDPWD, so
 944     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
 945 fi
 946
 947 chpwd() {
 948     is42 && builtin print -l ${(u)dirstack} >! ~/.zdirs
 949 }
 950
 951 # }}}
 952
 953 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
 954 if [[ -n "$BATTERY" ]] ; then
 955     if check_com -c acpi ; then
 956         PERCENT="${(C)${(s| |)$(acpi 2>/dev/null)}[4]}"
 957         [[ -z "$PERCENT" ]] && PERCENT='acpi not present'
 958
 959         if [[ "${PERCENT%%%}" -lt 20 ]] ; then
 960             PERCENT="warning: ${PERCENT}%"
 961         fi
 962     fi
 963 fi
 964 # }}}
 965
 966 # display version control information on right side of prompt if $VCS is set {{{
 967 # based on Mike Hommey's http://web.glandium.org/blog/?p=170
 968 __vcs_dir() {
 969     local vcs base_dir sub_dir ref
 970
 971     sub_dir() {
 972       local sub_dir
 973       sub_dir=$(readlink -f "${PWD}")
 974       sub_dir=${sub_dir#$1}
 975       echo ${sub_dir#/}
 976     }
 977
 978     git_dir() {
 979       base_dir=$(git-rev-parse --show-cdup 2>/dev/null) || return 1
 980       base_dir=$(readlink -f "$base_dir/..")
 981       sub_dir=$(git-rev-parse --show-prefix)
 982       sub_dir=${sub_dir%/}
 983       ref=$(git-symbolic-ref -q HEAD || git-name-rev --name-only HEAD 2>/dev/null)
 984       ref=${ref#refs/heads/}
 985       vcs="git"
 986     }
 987
 988     svn_dir() {
 989       [[ -d ".svn" ]] || return 1
 990       base_dir="."
 991       while [[ -d "$base_dir/../.svn" ]]; do base_dir="$base_dir/.."; done
 992       base_dir=$(readlink -f "$base_dir")
 993       sub_dir=$(sub_dir "${base_dir}")
 994       ref=$(svn info "$base_dir" | awk '/^URL/ { sub(".*/","",$0); r=$0 } /^Revision/ { sub("[^0-9]*","",$0); print r":"$0 }')
 995       vcs="svn"
 996     }
 997
 998     svk_dir() {
 999         [[ -f ~/.svk/config ]] || return 1
1000         base_dir=$(awk '/: *$/ { sub(/^ */,"",$0); sub(/: *$/,"",$0); if (match("'${PWD}'", $0"(/|$)")) { print $0; d=1; } } /depotpath/ && d == 1 { sub(".*/","",$0); r=$0 } /revision/ && d == 1 { print r ":" $2; exit 1 }' ~/.svk/config) && return 1
1001         ref=${base_dir##*
1002   }
1003         base_dir=${base_dir%%
1004   *}
1005         sub_dir=$(sub_dir "${base_dir}")
1006         vcs="svk"
1007     }
1008
1009     hg_dir() {
1010         base_dir="."
1011         while [[ ! -d "$base_dir/.hg" ]]; do
1012             base_dir="$base_dir/.."
1013             [[ $(readlink -f "${base_dir}") = "/" ]] && return 1
1014         done
1015         base_dir=$(readlink -f "$base_dir")
1016         sub_dir=$(sub_dir "${base_dir}")
1017         ref=$(< "${base_dir}/.hg/branch")
1018         vcs="hg"
1019     }
1020
1021     hg_dir  ||
1022     git_dir ||
1023     svn_dir ||
1024     svk_dir # ||
1025   #  base_dir="$PWD"
1026   #  echo "${vcs:+($vcs)}${base_dir/$HOME/~}${vcs:+[$ref]${sub_dir}}"
1027     echo "${vcs:+($vcs)}${base_dir}${vcs:+[$ref]${sub_dir}}"
1028 }
1029 # }}}
1030
1031 # {{{ set prompt
1032 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1033     promptinit # people should be able to use their favourite prompt
1034 else
1035     print 'Notice: no promptinit available :('
1036 fi
1037
1038
1039 # precmd() => a function which is executed just before each prompt
1040 # use 'NOPRECMD=1' to disable the precmd + preexec commands
1041
1042 # precmd () { setopt promptsubst; [[ -o interactive ]] && jobs -l;
1043
1044 # make sure to use right prompt only when not running a command
1045 is41 && setopt transient_rprompt
1046
1047 is4 && [[ -z $NOPRECMD ]] && precmd () {
1048     [[ -n $NOPRECMD ]] && return 0
1049     # allow manual overwriting of RPROMPT
1050     if [[ -n $RPROMPT ]] ; then
1051         [[ $TERM == screen* ]] && echo -n $'\ekzsh\e\\'
1052         # return 0
1053     fi
1054     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1055     if [[ -z $DONTSETRPROMPT ]] ; then
1056         if [[ -n $BATTERY ]] ; then
1057             RPROMPT="%(?..:()% ${PERCENT}${SCREENTITLE}"
1058             # RPROMPT="${PERCENT}${SCREENTITLE}"
1059         elif [[ -n $VCS ]] ; then
1060             RPROMPT="%(?..:()% $(__vcs_dir)${SCREENTITLE}"
1061         else
1062             RPROMPT="%(?..:()% ${SCREENTITLE}"
1063             # RPROMPT="${SCREENTITLE}"
1064         fi
1065     fi
1066     # adjust title of xterm
1067     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1068     case $TERM in
1069         (xterm*|rxvt)
1070             print -Pn "\e]0;%n@%m: %~\a"
1071             ;;
1072     esac
1073 }
1074
1075 # chpwd () => a function which is executed whenever the directory is changed
1076
1077 # preexec() => a function running before every command
1078 is4 && [[ -z $NOPRECMD ]] && \
1079 preexec () {
1080     [[ -n $NOPRECMD ]] && return 0
1081 # set hostname if not running on host with name 'grml'
1082     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1083        NAME="@$HOSTNAME"
1084     fi
1085 # get the name of the program currently running and hostname of local machine
1086 # set screen window title if running in a screen
1087     if [[ "$TERM" == screen* ]] ; then
1088         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1089         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1090         echo -ne "\ek$CMD\e\\"
1091     fi
1092 # set the screen title to "zsh" when sitting at the command prompt:
1093     if [[ "$TERM" == screen* ]] ; then
1094         SCREENTITLE=$'%{\ekzsh\e\\%}'
1095     else
1096         SCREENTITLE=''
1097     fi
1098 # adjust title of xterm
1099     case $TERM in
1100         (xterm*|rxvt)
1101             print -Pn "\e]0;%n@%m: $1\a"
1102             ;;
1103     esac
1104 }
1105
1106 # set colors
1107 if zrcautoload colors && colors 2>/dev/null ; then
1108     BLUE="%{${fg[blue]}%}"
1109     RED="%{${fg_bold[red]}%}"
1110     GREEN="%{${fg[green]}%}"
1111     CYAN="%{${fg[cyan]}%}"
1112     WHITE="%{${fg[white]}%}"
1113     NO_COLOUR="%{${reset_color}%}"
1114 else
1115     BLUE=$'%{\e[1;34m%}'
1116     RED=$'%{\e[1;31m%}'
1117     GREEN=$'%{\e[1;32m%}'
1118     CYAN=$'%{\e[1;36m%}'
1119     WHITE=$'%{\e[1;37m%}'
1120     NO_COLOUR=$'%{\e[0m%}'
1121 fi
1122
1123 EXITCODE="%(?..%?%1v )"
1124 PS2='`%_> '       # secondary prompt, printed when the shell needs more information to complete a command.
1125 PS3='?# '         # selection prompt used within a select loop.
1126 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1127
1128 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1129 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1130     debian_chroot=$(cat /etc/debian_chroot)
1131 fi
1132
1133 # don't use colors on dumb terminals (like emacs):
1134 if [[ "$TERM" == dumb ]] ; then
1135     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< %# "
1136 else
1137     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
1138     # set variable identifying the chroot you work in (used in the prompt below)
1139     if [[ -n $GRMLPROMPT ]] ; then
1140         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1141 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# "
1142     else
1143         if (( EUID != 0 )); then
1144             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# " # primary prompt string
1145         else
1146             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# " # primary prompt string
1147         fi
1148     fi
1149 fi
1150
1151 # if we are inside a grml-chroot set a specific prompt theme
1152 if [[ -n "$GRML_CHROOT" ]] ; then
1153     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1154 fi
1155 # }}}
1156
1157 # {{{ 'hash' some often used directories
1158 #d# start
1159 hash -d deb=/var/cache/apt/archives
1160 hash -d doc=/usr/share/doc
1161 hash -d linux=/lib/modules/$(command uname -r)/build/
1162 hash -d log=/var/log
1163 hash -d slog=/var/log/syslog
1164 hash -d src=/usr/src
1165 hash -d templ=/usr/share/doc/grml-templates
1166 hash -d tt=/usr/share/doc/texttools-doc
1167 hash -d www=/var/www
1168 #d# end
1169 # }}}
1170
1171 # {{{ some aliases
1172 if [[ $UID -eq 0 ]] ; then
1173     [[ -r /etc/grml/screenrc ]] && alias screen='/usr/bin/screen -c /etc/grml/screenrc'
1174 elif [[ -r $HOME/.screenrc ]] ; then
1175     alias screen="/usr/bin/screen -c $HOME/.screenrc"
1176 else
1177     [[ -r /etc/grml/screenrc_grml ]] && alias screen='/usr/bin/screen -c /etc/grml/screenrc_grml'
1178 fi
1179
1180 # do we have GNU ls with color-support?
1181 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
1182     #a1# execute \kbd{@a@}:\quad ls with colors
1183     alias ls='ls -b -CF --color=auto'
1184     #a1# execute \kbd{@a@}:\quad list all files, with colors
1185     alias la='ls -la --color=auto'
1186     #a1# long colored list, without dotfiles (@a@)
1187     alias ll='ls -l --color=auto'
1188     #a1# long colored list, human readable sizes (@a@)
1189     alias lh='ls -hAl --color=auto'
1190     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1191     alias l='ls -lF --color=auto'
1192 else
1193     alias ls='ls -b -CF'
1194     alias la='ls -la'
1195     alias ll='ls -l'
1196     alias lh='ls -hAl'
1197     alias l='ls -lF'
1198 fi
1199
1200 alias mdstat='cat /proc/mdstat'
1201 alias ...='cd ../../'
1202
1203 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1204 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1205     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1206 fi
1207
1208 alias cp='nocorrect cp'         # no spelling correction on cp
1209 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
1210 alias mv='nocorrect mv'         # no spelling correction on mv
1211 alias rm='nocorrect rm'         # no spelling correction on rm
1212
1213 #a1# Execute \kbd{rmdir}
1214 alias rd='rmdir'
1215 #a1# Execute \kbd{rmdir}
1216 alias md='mkdir'
1217
1218 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1219 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1220 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1221
1222 # make sure it is not assigned yet
1223 [[ $(whence -w utf2iso &>/dev/null) == 'utf2iso: alias' ]] && unalias utf2iso
1224
1225 utf2iso() {
1226     if isutfenv ; then
1227         for ENV in $(env | command grep -i '.utf') ; do
1228             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1229         done
1230     fi
1231 }
1232
1233 # make sure it is not assigned yet
1234 [[ $(whence -w iso2utf &>/dev/null) == 'iso2utf: alias' ]] && unalias iso2utf
1235 iso2utf() {
1236     if ! isutfenv ; then
1237         for ENV in $(env | command grep -i '\.iso') ; do
1238             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1239         done
1240     fi
1241 }
1242
1243 # set up software synthesizer via speakup
1244 swspeak() {
1245     aumix -w 90 -v 90 -p 90 -m 90
1246     if ! [[ -r /dev/softsynth ]] ; then
1247         flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
1248         return 1
1249     else
1250         setopt singlelinezle
1251         unsetopt prompt_cr
1252         export PS1="%m%# "
1253         nice -n -20 speechd-up
1254         sleep 2
1255         flite -o play -t "Finished setting up software synthesizer"
1256     fi
1257 }
1258
1259 # I like clean prompt, so provide simple way to get that
1260 check_com 0 || alias 0='return 0'
1261
1262 # for really lazy people like mika:
1263 check_com S &>/dev/null || alias S='screen'
1264 check_com s &>/dev/null || alias s='ssh'
1265
1266 # get top 10 shell commands:
1267 alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
1268
1269 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
1270 if check_com -c truecrypt ; then
1271     if isutfenv ; then
1272         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
1273     else
1274         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
1275     fi
1276 fi
1277
1278 #f1# Hints for the use of zsh on grml
1279 zsh-help() {
1280     print "$bg[white]$fg[black]
1281 zsh-help - hints for use of zsh on grml
1282 =======================================$reset_color"
1283
1284     print '
1285 Main configuration of zsh happens in /etc/zsh/zshrc (global)
1286 and /etc/skel/.zshrc which is copied to $HOME/.zshrc once.
1287 The files are part of the package grml-etc-core, if you want to
1288 use them on a non-grml-system just get the tar.gz from
1289 http://deb.grml.org/ or get the files from the mercurial
1290 repository:
1291
1292   http://hg.grml.org/grml-etc-core/raw-file/tip/etc/skel/.zshrc
1293   http://hg.grml.org/grml-etc-core/raw-file/tip/etc/zsh/zshrc
1294
1295 If you want to stay in sync with zsh configuration of grml
1296 run '\''ln -sf /etc/skel/.zshrc $HOME/.zshrc'\'' and configure
1297 your own stuff in $HOME/.zshrc.local. System wide configuration
1298 without touching configuration files of grml can take place
1299 in /etc/zsh/zshrc.local.
1300
1301 If you want to use the configuration of user grml also when
1302 running as user root just run '\''zshskel'\'' which will source
1303 the file /etc/skel/.zshrc.
1304
1305 For information regarding zsh start at http://grml.org/zsh/
1306
1307 Take a look at grml'\''s zsh refcard:
1308 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1309
1310 Check out the main zsh refcard:
1311 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1312
1313 And of course visit the zsh-lovers:
1314 % man zsh-lovers
1315
1316 You can adjust some options through environment variables when
1317 invoking zsh without having to edit configuration files.
1318 Basically meant for bash users who are not used to the power of
1319 the zsh yet. :)
1320
1321   "NOCOR=1    zsh" => deactivate automatic correction
1322   "NOMENU=1   zsh" => do not use menu completion (note: use strg-d for completion instead!)
1323   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1324   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt'
1325
1326     print "
1327 $bg[white]$fg[black]
1328 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1329 Enjoy your grml system with the zsh!$reset_color"
1330 }
1331
1332 # debian stuff
1333 if [[ -r /etc/debian_version ]] ; then
1334     #a3# Execute \kbd{apt-cache search}
1335     alias acs='apt-cache search'
1336     #a3# Execute \kbd{apt-cache show}
1337     alias acsh='apt-cache show'
1338     #a3# Execute \kbd{apt-cache policy}
1339     alias acp='apt-cache policy'
1340     #a3# Execute \kbd{apt-get dist-upgrade}
1341     salias adg="apt-get dist-upgrade"
1342     #a3# Execute \kbd{apt-get install}
1343     salias agi="apt-get install"
1344     #a3# Execute \kbd{aptitude install}
1345     salias ati="aptitude install"
1346     #a3# Execute \kbd{apt-get upgrade}
1347     salias ag="apt-get upgrade"
1348     #a3# Execute \kbd{apt-get update}
1349     salias au="apt-get update"
1350     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1351     salias -a up="aptitude update ; aptitude safe-upgrade"
1352     #a3# Execute \kbd{dpkg-buildpackage}
1353     alias dbp='dpkg-buildpackage'
1354     #a3# Execute \kbd{grep-excuses}
1355     alias ge='grep-excuses'
1356
1357     # debian upgrade
1358     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
1359     upgrade() {
1360         if [[ -z "$1" ]] ; then
1361             $SUDO apt-get update
1362             $SUDO apt-get -u upgrade
1363         else
1364             ssh $1 $SUDO apt-get update
1365             # ask before the upgrade
1366             local dummy
1367             ssh $1 $SUDO apt-get --no-act upgrade
1368             echo -n 'Process the upgrade?'
1369             read -q dummy
1370             if [[ $dummy == "y" ]] ; then
1371                 ssh $1 $SUDO apt-get -u upgrade --yes
1372             fi
1373         fi
1374     }
1375
1376     # get a root shell as normal user in live-cd mode:
1377     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1378        alias su="sudo su"
1379      fi
1380
1381     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1382     alias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1383     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1384     alias tlog="tail -f /var/log/syslog"    # follow the syslog
1385     #a1# (Re)-source \kbd{/etc/skel/.zshrc}
1386     alias zshskel="source /etc/skel/.zshrc" # source skeleton zshrc
1387 fi
1388
1389 # sort installed Debian-packages by size
1390 if check_com -c grep-status ; then
1391     #a3# List installed Debian-packages sorted by size
1392     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
1393 fi
1394
1395 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1396 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord ; then
1397     if check_com -c wodim ; then
1398         alias cdrecord="echo 'cdrecord is not provided under its original name by Debian anymore.
1399 See #377109 in the BTS of Debian for more details.
1400
1401 Please use the wodim binary instead' ; return 1"
1402     fi
1403 fi
1404
1405 # get_tw_cli has been renamed into get_3ware
1406 if check_com -c get_3ware ; then
1407     get_tw_cli() {
1408         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
1409         get_3ware
1410     }
1411 fi
1412
1413 # I hate lacking backward compatibility, so provide an alternative therefore
1414 if ! check_com -c apache2-ssl-certificate ; then
1415
1416     apache2-ssl-certificate() {
1417
1418     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
1419     print 'You might want to take a look at Debian the package ssl-cert as well.'
1420     print 'To generate a certificate for use with apache2 follow the instructions:'
1421
1422     echo '
1423
1424 export RANDFILE=/dev/random
1425 mkdir /etc/apache2/ssl/
1426 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
1427 chmod 600 /etc/apache2/ssl/apache.pem
1428
1429 Run "grml-tips ssl-certificate" if you need further instructions.
1430 '
1431     }
1432 fi
1433 # }}}
1434
1435 # {{{ Use hard limits, except for a smaller stack and no core dumps
1436 unlimit
1437 is4 && limit stack 8192
1438 isgrmlcd && limit core 0 # important for a live-cd-system
1439 limit -s
1440 # }}}
1441
1442 # {{{ completion system
1443
1444 # called later (via is4 && grmlcomp)
1445 # notice: use 'zstyle' for getting current settings
1446 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
1447 grmlcomp() {
1448     # TODO: This could use some additional information
1449
1450     # allow one error for every three characters typed in approximate completer
1451     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1452
1453     # don't complete backup files as executables
1454     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1455
1456     # start menu completion only if it could find no unambiguous initial string
1457     zstyle ':completion:*:correct:*'       insert-unambiguous true
1458     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1459     zstyle ':completion:*:correct:*'       original true
1460
1461     # activate color-completion
1462     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1463
1464     # format on completion
1465     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1466
1467     # complete 'cd -<tab>' with menu
1468     zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1469
1470     # insert all expansions for expand completer
1471     zstyle ':completion:*:expand:*'        tag-order all-expansions
1472     zstyle ':completion:*:history-words'   list false
1473
1474     # activate menu
1475     zstyle ':completion:*:history-words'   menu yes
1476
1477     # ignore duplicate entries
1478     zstyle ':completion:*:history-words'   remove-all-dups yes
1479     zstyle ':completion:*:history-words'   stop yes
1480
1481     # match uppercase from lowercase
1482     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1483
1484     # separate matches into groups
1485     zstyle ':completion:*:matches'         group 'yes'
1486     zstyle ':completion:*'                 group-name ''
1487
1488     if [[ -z "$NOMENU" ]] ; then
1489         # if there are more than 5 options allow selecting from a menu
1490         zstyle ':completion:*'               menu select=5
1491     else
1492         # don't use any menus at all
1493         setopt no_auto_menu
1494     fi
1495
1496     zstyle ':completion:*:messages'        format '%d'
1497     zstyle ':completion:*:options'         auto-description '%d'
1498
1499     # describe options in full
1500     zstyle ':completion:*:options'         description 'yes'
1501
1502     # on processes completion complete all user processes
1503     zstyle ':completion:*:processes'       command 'ps -au$USER'
1504
1505     # offer indexes before parameters in subscripts
1506     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1507
1508     # provide verbose completion information
1509     zstyle ':completion:*'                 verbose true
1510
1511     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1512     # for commands (read: 1st word in the line) that it will list for the user
1513     # to choose from. The following disables that, because it's not exactly fast.
1514     zstyle ':completion:*:-command-:*:'    verbose false
1515
1516     # set format for warnings
1517     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1518
1519     # define files to ignore for zcompile
1520     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1521     zstyle ':completion:correct:'          prompt 'correct to: %e'
1522
1523     # Ignore completion functions for commands you don't have:
1524     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1525
1526     # complete manual by their section
1527     zstyle ':completion:*:manuals'    separate-sections true
1528     zstyle ':completion:*:manuals.*'  insert-sections   true
1529     zstyle ':completion:*:man:*'      menu yes select
1530
1531     # run rehash on completion so new installed program are found automatically:
1532     _force_rehash() {
1533         (( CURRENT == 1 )) && rehash
1534         return 1
1535     }
1536
1537     ## correction
1538     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1539     if [[ -n "$NOCOR" ]] ; then
1540         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1541         setopt nocorrect
1542     else
1543         # try to be smart about when to use what completer...
1544         setopt correct
1545         zstyle -e ':completion:*' completer '
1546             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1547                 _last_try="$HISTNO$BUFFER$CURSOR"
1548                 reply=(_complete _match _ignored _prefix _files)
1549             else
1550                 if [[ $words[1] == (rm|mv) ]] ; then
1551                     reply=(_complete _files)
1552                 else
1553                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1554                 fi
1555             fi'
1556     fi
1557
1558     # zstyle ':completion:*' completer _complete _correct _approximate
1559     # zstyle ':completion:*' expand prefix suffix
1560
1561     # command for process lists, the local web server details and host completion
1562     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1563
1564     # caching
1565     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1566                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1567
1568     # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
1569     if is42 ; then
1570         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1571         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1572     else
1573         _ssh_hosts=()
1574         _etc_hosts=()
1575     fi
1576     hosts=(
1577         $(hostname)
1578         "$_ssh_hosts[@]"
1579         "$_etc_hosts[@]"
1580         grml.org
1581         localhost
1582     )
1583     zstyle ':completion:*:hosts' hosts $hosts
1584     #  zstyle '*' hosts $hosts
1585
1586     # specify your logins:
1587     # my_accounts=(
1588     #  {grml,grml1}@foo.invalid
1589     #  grml-devel@bar.invalid
1590     # )
1591     # other_accounts=(
1592     #  {fred,root}@foo.invalid
1593     #  vera@bar.invalid
1594     # )
1595     # zstyle ':completion:*:my-accounts' users-hosts $my_accounts
1596     # zstyle ':completion:*:other-accounts' users-hosts $other_accounts
1597
1598     # specify specific port/service settings:
1599     #  telnet_users_hosts_ports=(
1600     #    user1@host1:
1601     #    user2@host2:
1602     #    @mail-server:{smtp,pop3}
1603     #    @news-server:nntp
1604     #    @proxy-server:8000
1605     #  )
1606     # zstyle ':completion:*:*:telnet:*' users-hosts-ports $telnet_users_hosts_ports
1607
1608     # use generic completion system for programs not yet defined; (_gnu_generic works
1609     # with commands that provide a --help option with "standard" gnu-like output.)
1610     compdef _gnu_generic tail head feh cp mv df stow uname ipacsum fetchipac
1611
1612     # see upgrade function in this file
1613     compdef _hosts upgrade
1614 }
1615 # }}}
1616
1617 # {{{ grmlstuff
1618 grmlstuff() {
1619 # people should use 'grml-x'!
1620     startx() {
1621         if [[ -e /etc/X11/xorg.conf ]] ; then
1622             [[ -x /usr/bin/startx ]] && /usr/bin/startx "$@" || /usr/X11R6/bin/startx "$@"
1623         else
1624             echo "Please use the script \"grml-x\" for starting the X Window System
1625 because there does not exist /etc/X11/xorg.conf yet.
1626 If you want to use startx anyway please call \"/usr/bin/startx\"."
1627             return -1
1628         fi
1629     }
1630
1631     xinit() {
1632         if [[ -e /etc/X11/xorg.conf ]] ; then
1633             [[ -x /usr/bin/xinit ]] && /usr/bin/xinit || /usr/X11R6/bin/xinit
1634         else
1635             echo "Please use the script \"grml-x\" for starting the X Window System.
1636 because there does not exist /etc/X11/xorg.conf yet.
1637 If you want to use xinit anyway please call \"/usr/bin/xinit\"."
1638             return -1
1639         fi
1640     }
1641
1642     if check_com -c 915resolution ; then
1643         alias 855resolution='echo -e "Please use 915resolution as resolution modify tool for Intel graphic chipset."; return -1'
1644     fi
1645
1646     #a1# Output version of running grml
1647     alias grml-version='cat /etc/grml_version'
1648
1649     if check_com -c rebuildfstab ; then
1650         #a1# Rebuild /etc/fstab
1651         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1652     fi
1653
1654     if check_com -c grml-debootstrap ; then
1655         alias debian2hd='print "Installing debian to harddisk is possible via using grml-debootstrap." ; return 1'
1656     fi
1657 }
1658 # }}}
1659
1660 # {{{ now run the functions
1661 isgrml && checkhome
1662 is4    && isgrml    && grmlstuff
1663 is4    && grmlcomp
1664 # }}}
1665
1666 # {{{ keephack
1667 is4 && xsource "/etc/zsh/keephack"
1668 # }}}
1669
1670 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
1671 # You use it as follows:
1672 # $ NTREF=/reference/file
1673 # $ ls -l *(e:nt:)
1674 # This lists all the files in the current directory newer than the reference file.
1675 # You can also specify the reference file inline; note quotes:
1676 # $ ls -l *(e:'nt ~/.zshenv':)
1677 is4 && nt() {
1678     if [[ -n $1 ]] ; then
1679         local NTREF=${~1}
1680     fi
1681     [[ $REPLY -nt $NTREF ]]
1682 }
1683 # }}}
1684
1685 # shell functions {{{
1686
1687 #f1# Provide csh compatibility
1688 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
1689
1690 #f1# Reload an autoloadable function
1691 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1692
1693 #f1# Reload zsh setup
1694 reload() {
1695     if [[ "$#*" -eq 0 ]] ; then
1696         [[ -r ~/.zshrc ]] && . ~/.zshrc
1697     else
1698         local fn
1699         for fn in "$@"; do
1700             unfunction $fn
1701             autoload -U $fn
1702         done
1703     fi
1704 }
1705 compdef _functions reload freload
1706
1707 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1708 sll() {
1709     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1710     for i in "$@" ; do
1711         file=$i
1712         while [[ -h "$file" ]] ; do
1713             ls -l $file
1714             file=$(readlink "$file")
1715         done
1716     done
1717 }
1718
1719 # fast manual access
1720 if check_com qma ; then
1721     #f1# View the zsh manual
1722     manzsh()  { qma zshall "$1" }
1723     compdef _man qma
1724 else
1725     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
1726     # manzsh()  { /usr/bin/man zshall |  most +/"$1" ; }
1727     # [[ -f ~/.terminfo/m/mostlike ]] && MYLESS='LESS=C TERMINFO=~/.terminfo TERM=mostlike less' || MYLESS='less'
1728     # manzsh()  { man zshall | $MYLESS -p $1 ; }
1729 fi
1730
1731 if check_com -c $PAGER ; then
1732     #f1# View Debian's changelog of a given package
1733     dchange() {
1734         if [[ -r /usr/share/doc/${1}/changelog.Debian.gz ]] ; then
1735             $PAGER /usr/share/doc/${1}/changelog.Debian.gz
1736         elif [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
1737             $PAGER /usr/share/doc/${1}/changelog.gz
1738         else
1739             if check_com -c aptitude ; then
1740                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1741                 if isgrml ; then
1742                     aptitude -t unstable changelog ${1}
1743                 else
1744                     aptitude changelog ${1}
1745                 fi
1746             else
1747                 echo "No changelog for package $1 found, sorry."
1748                 return 1
1749             fi
1750         fi
1751     }
1752     _dchange() { _files -W /usr/share/doc -/ }
1753     compdef _dchange dchange
1754
1755     #f1# View Debian's NEWS of a given package
1756     dnews() {
1757         if [[ -r /usr/share/doc/${1}/NEWS.Debian.gz ]] ; then
1758             $PAGER /usr/share/doc/${1}/NEWS.Debian.gz
1759         else
1760             if [[ -r /usr/share/doc/${1}/NEWS.gz ]] ; then
1761                 $PAGER /usr/share/doc/${1}/NEWS.gz
1762             else
1763                 echo "No NEWS file for package $1 found, sorry."
1764                 return 1
1765             fi
1766         fi
1767     }
1768     _dnews() { _files -W /usr/share/doc -/ }
1769     compdef _dnews dnews
1770
1771     #f1# View upstream's changelog of a given package
1772     uchange() {
1773         if [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
1774             $PAGER /usr/share/doc/${1}/changelog.gz
1775         else
1776             echo "No changelog for package $1 found, sorry."
1777             return 1
1778         fi
1779     }
1780     _uchange() { _files -W /usr/share/doc -/ }
1781     compdef _uchange uchange
1782 fi
1783
1784 # zsh profiling
1785 profile() {
1786     ZSH_PROFILE_RC=1 $SHELL "$@"
1787 }
1788
1789 #f1# Edit an alias via zle
1790 edalias() {
1791     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1792 }
1793 compdef _aliases edalias
1794
1795 #f1# Edit a function via zle
1796 edfunc() {
1797     [[ -z "$1" ]] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
1798 }
1799 compdef _functions edfunc
1800
1801 # use it e.g. via 'Restart apache2'
1802 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
1803 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
1804 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
1805 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
1806 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
1807 if [[ -d /etc/init.d ]] ; then
1808     for i in Start Restart Stop Force-Reload Reload ; do
1809         eval "$i() { $SUDO /etc/init.d/\$1 ${i:l} \$2 ; }"
1810     done
1811 fi
1812
1813 #f1# Provides useful information on globbing
1814 H-Glob() {
1815     echo -e "
1816     /      directories
1817     .      plain files
1818     @      symbolic links
1819     =      sockets
1820     p      named pipes (FIFOs)
1821     *      executable plain files (0100)
1822     %      device files (character or block special)
1823     %b     block special files
1824     %c     character special files
1825     r      owner-readable files (0400)
1826     w      owner-writable files (0200)
1827     x      owner-executable files (0100)
1828     A      group-readable files (0040)
1829     I      group-writable files (0020)
1830     E      group-executable files (0010)
1831     R      world-readable files (0004)
1832     W      world-writable files (0002)
1833     X      world-executable files (0001)
1834     s      setuid files (04000)
1835     S      setgid files (02000)
1836     t      files with the sticky bit (01000)
1837
1838   print *(m-1)          # Files modified up to a day ago
1839   print *(a1)           # Files accessed a day ago
1840   print *(@)            # Just symlinks
1841   print *(Lk+50)        # Files bigger than 50 kilobytes
1842   print *(Lk-50)        # Files smaller than 50 kilobytes
1843   print **/*.c          # All *.c files recursively starting in \$PWD
1844   print **/*.c~file.c   # Same as above, but excluding 'file.c'
1845   print (foo|bar).*     # Files starting with 'foo' or 'bar'
1846   print *~*.*           # All Files that do not contain a dot
1847   chmod 644 *(.^x)      # make all plain non-executable files publically readable
1848   print -l *(.c|.h)     # Lists *.c and *.h
1849   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
1850   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
1851 }
1852 alias help-zshglob=H-Glob
1853
1854 check_com -c qma && alias ?='qma zshall'
1855
1856 # grep for running process, like: 'any vim'
1857 any() {
1858     if [[ -z "$1" ]] ; then
1859         echo "any - grep for process(es) by keyword" >&2
1860         echo "Usage: any <keyword>" >&2 ; return 1
1861     else
1862         local STRING=$1
1863         local LENGTH=$(expr length $STRING)
1864         local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
1865         local REST=$(echo $(expr substr $STRING 2 $LENGTH))
1866         ps xauwww| grep "[$FIRSCHAR]$REST"
1867     fi
1868 }
1869
1870 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
1871 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
1872 [[ -r /proc/1/maps ]] && \
1873 deswap() {
1874     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
1875     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
1876     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
1877 }
1878
1879 # print hex value of a number
1880 hex() {
1881     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
1882 }
1883
1884 # calculate (or eval at all ;-)) with perl => p[erl-]eval
1885 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
1886 peval() {
1887     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
1888     perl -e "print eval($CALC),\"\n\";"
1889 }
1890 functions peval &>/dev/null && alias calc=peval
1891
1892 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
1893 # certain circumstances, so work around it, no matter which environment we have
1894 brltty() {
1895     if [[ -z "$DISPLAY" ]] ; then
1896         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
1897         command brltty "$@"
1898     else
1899         command brltty "$@"
1900     fi
1901 }
1902
1903 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
1904 aoeu() {
1905     echo -n 'Switching to us keyboard layout: '
1906     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
1907     echo 'Done'
1908 }
1909 asdf() {
1910     echo -n 'Switching to dvorak keyboard layout: '
1911     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
1912     echo 'Done'
1913 }
1914 # just press 'asdf' key to toggle from neon layout to us keyboard layout
1915 uiae() {
1916     echo -n 'Switching to us keyboard layout: '
1917     setxkbmap us && echo 'Done' || echo 'Failed'
1918 }
1919
1920 # set up an ipv6 tunnel
1921 ipv6-tunnel() {
1922     case $1 in
1923         start)
1924             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1925                 print 'ipv6 tunnel already set up, nothing to be done.'
1926                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
1927             else
1928                 [[ -n "$PUBLIC_IP" ]] || \
1929                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
1930                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
1931
1932                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
1933                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
1934                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
1935                 ifconfig sit0 tunnel ::192.88.99.1 up
1936                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
1937             fi
1938             ;;
1939         status)
1940             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1941                 print 'ipv6 tunnel available' ; return 0
1942             else
1943                 print 'ipv6 tunnel not available' ; return 1
1944             fi
1945             ;;
1946         stop)
1947             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1948                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
1949                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
1950             else
1951                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
1952             fi
1953             ;;
1954         *)
1955             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
1956             ;;
1957     esac
1958 }
1959
1960 # run dhclient for wireless device
1961 iwclient() {
1962     salias dhclient "$(wavemon -d | awk '/device/{print $2}')"
1963 }
1964
1965 # spawn a minimally set up ksh - useful if you want to umount /usr/.
1966 minimal-shell() {
1967     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ksh
1968 }
1969
1970 # make a backup of a file
1971 bk() {
1972     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
1973 }
1974
1975 # Switching shell safely and efficiently? http://www.zsh.org/mla/workers/2001/msg02410.html
1976 # bash() {
1977 #  NO_SWITCH="yes" command bash "$@"
1978 # }
1979 # restart () {
1980 #  exec $SHELL $SHELL_ARGS "$@"
1981 # }
1982
1983 # }}}
1984
1985 # log out? set timeout in seconds {{{
1986 # TMOUT=1800
1987 # do not log out in some specific terminals:
1988 #  if [[ "${TERM}" == ([Exa]term*|rxvt|dtterm|screen*) ]] ; then
1989 #    unset TMOUT
1990 #  fi
1991 # }}}
1992
1993 # {{{ make sure our environment is clean regarding colors
1994 for color in BLUE RED GREEN CYAN WHITE ; unset $color
1995 # }}}
1996
1997 # source another config file if present {{{
1998 xsource "/etc/zsh/zshrc.local"
1999 # }}}
2000
2001 # "persistent history" {{{
2002 # just write important commands you always need to ~/.important_commands
2003 if [[ -r ~/.important_commands ]] ; then
2004     fc -R ~/.important_commands
2005 fi
2006 # }}}
2007
2008 ## genrefcard.pl settings {{{
2009 ### example: split functions-search 8,16,24,32
2010 #@# split functions-search 8
2011 ## }}}
2012
2013 # add variable to be able to check whether the file has been read {{{
2014 ZSHRC_GLOBAL_HAS_BEEN_READ=1
2015 # }}}
2016
2017 ## END OF FILE #################################################################
2018 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4