etc/zsh/zshrc

   1 # Filename:      zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 # Latest change: Sam Dez 22 19:17:27 CET 2007 [mika]
   7 ################################################################################
   8 # This file is sourced only for interactive shells. It
   9 # should contain commands to set up aliases, functions,
  10 # options, key bindings, etc.
  11 #
  12 # Global Order: zshenv, zprofile, zshrc, zlogin
  13 ################################################################################
  14
  15 # zsh-refcard-tag documentation: {{{
  16 #   You may notice strange looking comments in the zshrc (and ~/.zshrc as
  17 #   well). These are there for a purpose. grml's zsh-refcard can now be
  18 #   automatically generated from the contents of the actual configuration
  19 #   files. However, we need a little extra information on which comments
  20 #   and what lines of code to take into account (and for what purpose).
  21 #
  22 # Here is what they mean:
  23 #
  24 # List of tags (comment types) used:
  25 #   #a#     Next line contains an important alias, that should
  26 #           be included in the grml-zsh-refcard.
  27 #           (placement tag: @@INSERT-aliases@@)
  28 #   #f#     Next line contains the beginning of an important function.
  29 #           (placement tag: @@INSERT-functions@@)
  30 #   #v#     Next line contains an important variable.
  31 #           (placement tag: @@INSERT-variables@@)
  32 #   #k#     Next line contains an important keybinding.
  33 #           (placement tag: @@INSERT-keybindings@@)
  34 #   #d#     Hashed directories list generation:
  35 #               start   denotes the start of a list of 'hash -d'
  36 #                       definitions.
  37 #               end     denotes its end.
  38 #           (placement tag: @@INSERT-hasheddirs@@)
  39 #   #A#     Abbreviation expansion list generation:
  40 #               start   denotes the beginning of abbreviations.
  41 #               end     denotes their end.
  42 #           Lines within this section that end in '#d .*' provide
  43 #           extra documentation to be included in the refcard.
  44 #           (placement tag: @@INSERT-abbrev@@)
  45 #   #m#     This tag allows you to manually generate refcard entries
  46 #           for code lines that are hard/impossible to parse.
  47 #               Example:
  48 #                   #m# k ESC-h Call the run-help function
  49 #               That would add a refcard entry in the keybindings table
  50 #               for 'ESC-h' with the given comment.
  51 #           So the syntax is: #m# <section> <argument> <comment>
  52 #   #o#     This tag lets you insert entries to the 'other' hash.
  53 #           Generally, this should not be used. It is there for
  54 #           things that cannot be done easily in another way.
  55 #           (placement tag: @@INSERT-other-foobar@@)
  56 #
  57 #   All of these tags (except for m and o) take two arguments, the first
  58 #   within the tag, the other after the tag:
  59 #
  60 #   #<tag><section># <comment>
  61 #
  62 #   Where <section> is really just a number, which are defined by the
  63 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  64 #   instead of names is, that for the reader, the tag should not differ
  65 #   much from a regular comment. For zsh, it is a regular comment indeed.
  66 #   The numbers have got the following meanings:
  67 #         0 -> "default"
  68 #         1 -> "system"
  69 #         2 -> "user"
  70 #         3 -> "debian"
  71 #         4 -> "search"
  72 #         5 -> "shortcuts"
  73 #         6 -> "services"
  74 #
  75 #   So, the following will add an entry to the 'functions' table in the
  76 #   'system' section, with a (hopefully) descriptive comment:
  77 #       #f1# Edit an alias via zle
  78 #       edalias() {
  79 #
  80 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  81 #   that can be found in 'grml-zsh-refcard.tex.in'.
  82 #   If the section number is omitted, the 'default' section is assumed.
  83 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
  84 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
  85 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
  86 #}}}
  87
  88 # zsh profiling {{{
  89 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
  90 if [[ -n $ZSH_PROFILE_RC ]] ; then
  91     zmodload zsh/zprof
  92 fi
  93 # }}}
  94
  95 # utility functions {{{
  96 # this function checks if a command exists and returns either true
  97 # or false. This avoids using 'which' and 'whence', which will
  98 # avoid problems with aliases for which on certain weird systems. :-)
  99 check_com() {
 100     local -i comonly
 101
 102     if [[ ${1} == '-c' ]] ; then
 103         (( comonly = 1 ))
 104         shift
 105     else
 106         (( comonly = 0 ))
 107     fi
 108
 109     if (( ${#argv} != 1 )) ; then
 110         printf 'usage: check_com [-c] <command>\n' >&2
 111         return 1
 112     fi
 113
 114     if (( comonly > 0 )) ; then
 115         [[ -n ${commands[$1]}  ]] && return 0
 116         return 1
 117     fi
 118
 119     if   [[ -n ${commands[$1]}    ]] \
 120       || [[ -n ${functions[$1]}   ]] \
 121       || [[ -n ${aliases[$1]}     ]] \
 122       || [[ -n ${reswords[(r)$1]} ]] ; then
 123
 124         return 0
 125     fi
 126
 127     return 1
 128 }
 129
 130 # creates an alias and precedes the command with
 131 # sudo if $EUID is not zero.
 132 salias() {
 133     local only=0 ; local multi=0
 134     while [[ ${1} == -* ]] ; do
 135         case ${1} in
 136             (-o) only=1 ;;
 137             (-a) multi=1 ;;
 138             (--) shift ; break ;;
 139             (-h)
 140                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 141                 printf '  -h      shows this help text.\n'
 142                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 143                 printf '          be careful using this option.\n'
 144                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 145                 return 0
 146                 ;;
 147             (*) printf "unkown option: '%s'\n" "${1}" ; return 1 ;;
 148         esac
 149         shift
 150     done
 151
 152     if (( ${#argv} > 1 )) ; then
 153         printf 'Too many arguments %s\n' "${#argv}"
 154         return 1
 155     fi
 156
 157     key="${1%%\=*}" ;  val="${1#*\=}"
 158     if (( EUID == 0 )) && (( only == 0 )); then
 159         alias -- "${key}=${val}"
 160     elif (( EUID > 0 )) ; then
 161         (( multi > 0 )) && val="${val// ; / ; sudo }"
 162         alias -- "${key}=sudo ${val}"
 163     fi
 164
 165     return 0
 166 }
 167
 168 # Check if we can read given files and source those we can.
 169 xsource() {
 170     if (( ${#argv} < 1 )) ; then
 171         printf 'usage: xsource FILE(s)...\n' >&2
 172         return 1
 173     fi
 174
 175     while (( ${#argv} > 0 )) ; do
 176         [[ -r ${1} ]] && source ${1}
 177         shift
 178     done
 179     return 0
 180 }
 181
 182 # Check if we can read a given file and 'cat(1)' it.
 183 xcat() {
 184     if (( ${#argv} != 1 )) ; then
 185         printf 'usage: xcat FILE\n' >&2
 186         return 1
 187     fi
 188
 189     [[ -r ${1} ]] && cat ${1}
 190     return 0
 191 }
 192
 193 # Remove these functions again, they are of use only in these
 194 # setup files. This should be called at the end of .zshrc.
 195 xunfunction() {
 196     local -a funcs
 197     funcs=(check_com salias xcat xsource xunfunction zrcautoload)
 198
 199     for func in $funcs ; do
 200         [[ -n ${functions[$func]} ]] \
 201             && unfunction $func
 202     done
 203     return 0
 204 }
 205
 206 # autoload wrapper - use this one instead of autoload directly
 207 function zrcautoload() {
 208     setopt local_options extended_glob
 209     local fdir ffile
 210     local -i ffound
 211
 212     ffile=${1}
 213     (( found = 0 ))
 214     for fdir in ${fpath} ; do
 215         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 216     done
 217
 218     (( ffound == 0 )) && return 1
 219     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 220         autoload -U ${ffile} || return 1
 221     else
 222         autoload ${ffile} || return 1
 223     fi
 224     return 0
 225 }
 226
 227 #}}}
 228
 229 # locale setup {{{
 230 if [[ -z "$LANG" ]] ; then
 231     xsource "/etc/default/locale"
 232 fi
 233
 234 export LANG=${LANG:-en_US.iso885915}
 235 for var in LC_ALL LC_MESSAGES ; do
 236     [[ -n ${(P)var} ]] && export $var
 237 done
 238
 239 xsource "/etc/sysconfig/keyboard"
 240
 241 TZ=$(xcat /etc/timezone)
 242 # }}}
 243
 244 # check for potentially old files in 'completion.d' {{{
 245 setopt extendedglob
 246 xof=(/etc/zsh/completion.d/*~/etc/zsh/completion.d/_*(N))
 247 if (( ${#xof} > 0 )) ; then
 248     printf '\n -!- INFORMATION\n\n'
 249     printf ' -!- %s file(s) not starting with an underscore (_) found in\n' ${#xof}
 250     printf ' -!- /etc/zsh/completion.d/.\n\n'
 251     printf ' -!- While this has been the case in old versions of grml-etc-core,\n'
 252     printf ' -!- recent versions of the grml-zsh-setup have all these files rewritten\n'
 253     printf ' -!- and renamed. Furthermore, the grml-zsh-setup will *only* add files\n'
 254     printf ' -!- named _* to that directory.\n\n'
 255     printf ' -!- If you added functions to completion.d yourself, please consider\n'
 256     printf ' -!- moving them to /etc/zsh/functions.d/. Files in that directory, not\n'
 257     printf ' -!- starting with an underscore are marked for automatic loading\n'
 258     printf ' -!- by default (so that is quite convenient).\n\n'
 259     printf ' -!- If there are files *not* starting with an underscore from an older\n'
 260     printf ' -!- grml-etc-core in completion.d, you may safely remove them.\n\n'
 261     printf ' -!- Delete the files for example via running:\n\n'
 262     printf "      rm ${xof}\n\n"
 263     printf ' -!- Note, that this message will *not* go away, unless you yourself\n'
 264     printf ' -!- resolve the situation manually.\n\n'
 265     BROKEN_COMPLETION_DIR=1
 266 fi
 267 unset xof
 268 # }}}
 269
 270 # {{{ check for version/system
 271 # check for versions (compatibility reasons)
 272 is4(){
 273     [[ $ZSH_VERSION == <4->* ]] && return 0
 274     return 1
 275 }
 276
 277 is41(){
 278     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 279     return 1
 280 }
 281
 282 is42(){
 283     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 284     return 1
 285 }
 286
 287 is43(){
 288     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 289     return 1
 290 }
 291
 292 #f1# Checks whether or not you're running grml
 293 isgrml(){
 294     [[ -f /etc/grml_version ]] && return 0
 295     return 1
 296 }
 297
 298 #f1# Checks whether or not you're running a grml cd
 299 isgrmlcd(){
 300     [[ -f /etc/grml_cd ]] && return 0
 301     return 1
 302 }
 303
 304 if isgrml ; then
 305 #f1# Checks whether or not you're running grml-small
 306     isgrmlsmall() {
 307         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 308     }
 309 else
 310     isgrmlsmall() { return 1 }
 311 fi
 312
 313 #f1# are we running within an utf environment?
 314 isutfenv() {
 315     case "$LANG $CHARSET $LANGUAGE" in
 316         *utf*) return 0 ;;
 317         *UTF*) return 0 ;;
 318         *)     return 1 ;;
 319     esac
 320 }
 321
 322 # check for user, if not running as root set $SUDO to sudo
 323 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 324
 325 # change directory to home on first invocation of zsh
 326 # important for rungetty -> autologin
 327 # Thanks go to Bart Schaefer!
 328 isgrml && checkhome() {
 329     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 330         export ALREADY_DID_CD_HOME=$HOME
 331         cd
 332     fi
 333 }
 334
 335 # check for zsh v3.1.7+
 336
 337 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 338      || ${ZSH_VERSION} == 3.<2->.<->*    \
 339      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 340
 341     printf '-!-\n'
 342     printf '-!- In this configuration we try to make use of features, that only\n'
 343     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 344     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 345     printf '-!- advanced features in all supported versions.\n'
 346     printf '-!-\n'
 347     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 348     printf '-!-\n'
 349     printf '-!- While this *may* work, it might as well fail.\n'
 350     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 351     printf '-!-\n'
 352     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 353     printf '-!- If it does today, you'\''ve been lucky.\n'
 354     printf '-!-\n'
 355     printf '-!- Ye been warned!\n'
 356     printf '-!-\n'
 357
 358     function zstyle() { : }
 359 fi
 360
 361 # }}}
 362
 363 # {{{ set some variables
 364 if check_com -c vim ; then
 365 #v#
 366     export EDITOR=${EDITOR:-vim}
 367 else
 368     export EDITOR=${EDITOR:-vi}
 369 fi
 370
 371 #v#
 372 (( ${+PAGER} )) || export PAGER="less"
 373
 374 #v#
 375 export MAIL=${MAIL:-/var/mail/$USER}
 376
 377 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 378 export SHELL='/bin/zsh'
 379
 380 # color setup for ls:
 381 check_com -c dircolors && eval $(dircolors -b)
 382
 383 # set width of man pages to 80 for more convenient reading
 384 # (( ${+MANWIDTH} )) || export MANWIDTH=80
 385
 386 # Search path for the cd command
 387 #  cdpath=(.. ~)
 388
 389 # completion functions go to /etc/zsh/completion.d
 390 # function files may be put into /etc/zsh/functions.d, from where they
 391 # will be automatically autoloaded.
 392 if [[ -n "$BROKEN_COMPLETION_DIR" ]] ; then
 393     print 'Warning: not setting completion directories because broken files have been found.' >&2
 394 else
 395     [[ -d /etc/zsh/completion.d ]] && fpath=( $fpath /etc/zsh/completion.d )
 396     if [[ -d /etc/zsh/functions.d ]] ; then
 397         fpath+=( /etc/zsh/functions.d )
 398         for func in /etc/zsh/functions.d/[^_]*[^~] ; do
 399             zrcautoload -U ${func:t}
 400         done
 401     fi
 402 fi
 403
 404 # automatically remove duplicates from these arrays
 405 typeset -U path cdpath fpath manpath
 406 # }}}
 407
 408 # {{{ keybindings
 409 if [[ "$TERM" != emacs ]] ; then
 410     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 411     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 412     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 413     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 414     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 415     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 416     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 417     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 418     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 419     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 420     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 421     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 422     # ncurses stuff:
 423     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 424     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 425     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 426     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 427     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 428     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 429     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 430     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 431 fi
 432
 433 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 434 # use emacs style per default:
 435 bindkey -e
 436 # use vi style:
 437 # bindkey -v
 438
 439 #if [[ "$TERM" == screen ]] ; then
 440 bindkey '\e[1~' beginning-of-line       # home
 441 bindkey '\e[4~' end-of-line             # end
 442 bindkey '\e[A'  up-line-or-search       # cursor up
 443 bindkey '\e[B'  down-line-or-search     # <ESC>-
 444 bindkey '^x'    history-beginning-search-backward # alternative ways of searching the shell history
 445 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 446 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 447 # if terminal type is set to 'rxvt':
 448 bindkey '\e[7~' beginning-of-line       # home
 449 bindkey '\e[8~' end-of-line             # end
 450 #fi
 451
 452 # insert unicode character
 453 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 454 # See for example http://unicode.org/charts/ for unicode characters code
 455 zrcautoload insert-unicode-char
 456 zle -N insert-unicode-char
 457 #k# Insert Unicode character
 458 bindkey '^Xi' insert-unicode-char
 459
 460 # just type 'cd ...' to get 'cd ../..'
 461 #  rationalise-dot() {
 462 #  if [[ $LBUFFER == *.. ]] ; then
 463 #    LBUFFER+=/..
 464 #  else
 465 #    LBUFFER+=.
 466 #  fi
 467 #  }
 468 #  zle -N rationalise-dot
 469 #  bindkey . rationalise-dot
 470
 471 #  bindkey '\eq' push-line-or-edit
 472 # }}}
 473
 474 # a generic accept-line wrapper {{{
 475
 476 # This widget can prevent unwanted autocorrections from command-name
 477 # to _command-name, rehash automatically on enter and call any number
 478 # of builtin and user-defined widgets in different contexts.
 479 #
 480 # For a broader description, see:
 481 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 482 #
 483 # The code is imported from the file 'zsh/functions/accept-line' from
 484 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 485 # distributed under the same terms as zsh itself.
 486
 487 # A newly added command will may not be found or will cause false
 488 # correction attempts, if you got auto-correction set. By setting the
 489 # following style, we force accept-line() to rehash, if it cannot
 490 # find the first word on the command line in the $command[] hash.
 491 zstyle ':acceptline:*' rehash true
 492
 493 function Accept-Line() {
 494     setopt localoptions noksharrays
 495     local -a subs
 496     local -xi aldone
 497     local sub
 498
 499     zstyle -a ":acceptline:${alcontext}" actions subs
 500
 501     (( ${#subs} < 1 )) && return 0
 502
 503     (( aldone = 0 ))
 504     for sub in ${subs} ; do
 505         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 506         zle ${sub}
 507
 508         (( aldone > 0 )) && break
 509     done
 510 }
 511
 512 function Accept-Line-getdefault() {
 513     local default_action
 514
 515     zstyle -s ":acceptline:${alcontext}" default_action default_action
 516     case ${default_action} in
 517         ((accept-line|))
 518             printf ".accept-line"
 519             ;;
 520         (*)
 521             printf ${default_action}
 522             ;;
 523     esac
 524 }
 525
 526 function accept-line() {
 527     setopt localoptions noksharrays
 528     local -a cmdline
 529     local -x alcontext
 530     local buf com fname format msg default_action
 531
 532     alcontext='default'
 533     buf="${BUFFER}"
 534     cmdline=(${(z)BUFFER})
 535     com="${cmdline[1]}"
 536     fname="_${com}"
 537
 538     zstyle -t ":acceptline:${alcontext}" rehash \
 539         && [[ -z ${commands[$com]} ]]           \
 540         && rehash
 541
 542     if    [[ -n ${reswords[(r)$com]} ]] \
 543        || [[ -n ${aliases[$com]}     ]] \
 544        || [[ -n ${functions[$com]}   ]] \
 545        || [[ -n ${builtins[$com]}    ]] \
 546        || [[ -n ${commands[$com]}    ]] ; then
 547
 548         # there is something sensible to execute, just do it.
 549         alcontext='normal'
 550         zle Accept-Line
 551
 552         default_action=$(Accept-Line-getdefault)
 553         zstyle -T ":acceptline:${alcontext}" call_default \
 554             && zle ${default_action}
 555         return
 556     fi
 557
 558     if    [[ -o correct              ]] \
 559        || [[ -o correctall           ]] \
 560        && [[ -n ${functions[$fname]} ]] ; then
 561
 562         # nothing there to execute but there is a function called
 563         # _command_name; a completion widget. Makes no sense to
 564         # call it on the commandline, but the correct{,all} options
 565         # will ask for it nevertheless, so warn the user.
 566         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 567             # Okay, we warned the user before, he called us again,
 568             # so have it his way.
 569             alcontext='force'
 570             zle Accept-Line
 571
 572             default_action=$(Accept-Line-getdefault)
 573             zstyle -T ":acceptline:${alcontext}" call_default \
 574                 && zle ${default_action}
 575             return
 576         fi
 577
 578         # prepare warning message for the user, configurable via zstyle.
 579         zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 580
 581         if [[ -z ${msg} ]] ; then
 582             msg="%c will not execute and completion %f exists."
 583         fi
 584
 585         zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 586
 587         zle -M -- "${msg}"
 588         return
 589     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 590         # If we are here, the commandline contains something that is not
 591         # executable, which is neither subject to _command_name correction
 592         # and is not empty. might be a variable assignment
 593         alcontext='misc'
 594         zle Accept-Line
 595
 596         default_action=$(Accept-Line-getdefault)
 597         zstyle -T ":acceptline:${alcontext}" call_default \
 598             && zle ${default_action}
 599         return
 600     fi
 601
 602     # If we got this far, the commandline only contains whitespace, or is empty.
 603     alcontext='empty'
 604     zle Accept-Line
 605
 606     default_action=$(Accept-Line-getdefault)
 607     zstyle -T ":acceptline:${alcontext}" call_default \
 608         && zle ${default_action}
 609 }
 610
 611 zle -N accept-line
 612 zle -N Accept-Line
 613
 614 # }}}
 615
 616 # power completion - abbreviation expansion {{{
 617 # power completion / abbreviation expansion / buffer expansion
 618 # see http://zshwiki.org/home/examples/zleiab for details
 619 # less risky than the global aliases but powerful as well
 620 # just type the abbreviation key and afterwards ',.' to expand it
 621 declare -A abk
 622 setopt extendedglob
 623 setopt interactivecomments
 624 abk=(
 625 # key  # value                (#d additional doc string)
 626 #A# start
 627     '...' '../..'
 628     '....' '../../..'
 629     'BG' '& exit'
 630     'C' '| wc -l'
 631     'G' '|& grep --color=auto'
 632     'H' '| head'
 633     'Hl' ' --help |& less -r'      #d (Display help in pager)
 634     'L' '| less'
 635     'LL' '|& less -r'
 636     'M' '| most'
 637     'N' '&>/dev/null'              #d (No Output)
 638     'R' '| tr A-z N-za-m'          #d (ROT13)
 639     'SL' '| sort | less'
 640     'S' '| sort -u'
 641     'T' '| tail'
 642     'V' '|& vim -'
 643 #A# end
 644     'hide' "echo -en '\033]50;nil2\007'"
 645     'tiny' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
 646     'small' 'echo -en "\033]50;6x10\007"'
 647     'medium' 'echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
 648     'default' 'echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
 649     'large' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
 650     'huge' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
 651     'smartfont' 'echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
 652     'semifont' 'echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
 653     'da' 'du -sch'
 654     'j' 'jobs -l'
 655     'u' 'translate -i'
 656     'co' "./configure && make && sudo make install"
 657     'CH' "./configure --help"
 658     'conkeror' 'firefox -chrome chrome://conkeror/content'
 659     'dir' 'ls -lSrah'
 660     'lad' $'ls -d .*(/)\n# only show dot-directories'
 661     'lsa' $'ls -a .*(.)\n# only show dot-files'
 662     'lss' $'ls -l *(s,S,t)\n# only files with setgid/setuid/sticky flag'
 663     'lsl' $'ls -l *(@[1,10])\n# only symlinks'
 664     'lsx' $'ls -l *(*[1,10])\n# only executables'
 665     'lsw' $'ls -ld *(R,W,X.^ND/)\n# world-{readable,writable,executable} files'
 666     'lsbig' $'ls -flh *(.OL[1,10])\n# display the biggest files'
 667     'lsd' $'ls -d *(/)\n# only show directories'
 668     'lse' $'ls -d *(/^F)\n# only show empty directories'
 669     'lsnew' $'ls -rl *(D.om[1,10])\n# display the newest files'
 670     'lsold' $'ls -rtlh *(D.om[-11,-1])\n # display the oldest files'
 671     'lssmall' $'ls -Srl *(.oL[1,10])\n# display the smallest files'
 672     'rw-' 'chmod 600'
 673     '600' 'chmod u+rw-x,g-rwx,o-rwx'
 674     'rwx' 'chmod u+rwx'
 675     '700' 'chmod u+rwx,g-rwx,o-rwx'
 676     'r--' 'chmod u+r-wx,g-rwx,o-rwx'
 677     '644' $'chmod u+rw-x,g+r-wx,o+r-wx\n # 4=r,2=w,1=x'
 678     '755' 'chmod u+rwx,g+r-w+x,o+r-w+x'
 679     'md' 'mkdir -p '
 680     'cmplayer' 'mplayer -vo -fs -zoom fbdev'
 681     'fbmplayer' 'mplayer -vo -fs -zoom fbdev'
 682     'fblinks' 'links2 -driver fb'
 683     'insecssh' 'ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 684     'insecscp' 'scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 685     'fori' 'for i ({..}) { }'
 686     'cx' 'chmod +x'
 687     'e'  'print -l'
 688     'se' 'setopt interactivecomments'
 689     'va' 'valac --vapidir=../vapi/ --pkg=gtk+-2.0 gtktest.vala'
 690     'fb2' '=mplayer -vo fbdev -fs -zoom 1>/dev/null -xy 2'
 691     'fb3' '=mplayer -vo fbdev -fs  -zoom 1>/dev/null -xy 3'
 692     'ci' 'centericq'
 693     'D'  'export DISPLAY=:0.0'
 694     'mp' 'mplayer -vo xv -fs -zoom'
 695 )
 696
 697 globalias() {
 698     local MATCH
 699     matched_chars='[.-|_a-zA-Z0-9]#'
 700     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 701     LBUFFER+=${abk[$MATCH]:-$MATCH}
 702 }
 703
 704 zle -N globalias
 705 bindkey ",." globalias
 706 # }}}
 707
 708 # {{{ autoloading
 709 zrcautoload zmv    # who needs mmv or rename?
 710 zrcautoload history-search-end
 711
 712 # we don't want to quote/espace URLs on our own...
 713 # if autoload -U url-quote-magic ; then
 714 #    zle -N self-insert url-quote-magic
 715 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 716 # else
 717 #    print 'Notice: no url-quote-magic available :('
 718 # fi
 719 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 720
 721 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 722 alias run-help >&/dev/null && unalias run-help
 723 zrcautoload run-help # use via 'esc-h'
 724
 725 # completion system
 726 if zrcautoload compinit && compinit 2>/dev/null ; then
 727     compinit 2>/dev/null || print 'Notice: no compinit available :('
 728 else
 729     print 'Notice: no compinit available :('
 730     function zstyle { }
 731     function compdef { }
 732 fi
 733
 734 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 735
 736 is4 && \
 737 for mod in complist deltochar mathfunc ; do
 738     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 739 done
 740
 741 # autoload zsh modules when they are referenced
 742 if is4 ; then
 743     tmpargs=(
 744         a   stat
 745         a   zpty
 746         ap  zprof
 747         ap  mapfile
 748     )
 749
 750     while (( ${#tmpargs} > 0 )) ; do
 751         zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
 752         shift 2 tmpargs
 753     done
 754     unset tmpargs
 755 fi
 756
 757 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 758     #k# Insert files
 759     bindkey "^Xf" insert-files # C-x-f
 760 fi
 761
 762 bindkey ' '   magic-space    # also do history expansion on space
 763 #k# Trigger menu-complete
 764 bindkey '\ei' menu-complete  # menu completion via esc-i
 765
 766 # press esc-e for editing command line in $EDITOR or $VISUAL
 767 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 768     #k# Edit the current line in \kbd{\$EDITOR}
 769     bindkey '\ee' edit-command-line
 770 fi
 771
 772 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 773     #k# menu selection: pick item but stay in the menu
 774     bindkey -M menuselect '\e^M' accept-and-menu-complete
 775
 776     # use the vi navigation keys (hjkl) besides cursor keys in menu completion
 777     #bindkey -M menuselect 'h' vi-backward-char        # left
 778     #bindkey -M menuselect 'k' vi-up-line-or-history   # up
 779     #bindkey -M menuselect 'l' vi-forward-char         # right
 780     #bindkey -M menuselect 'j' vi-down-line-or-history # bottom
 781
 782     # accept a completion and try to complete again by using menu
 783     # completion; very useful with completing directories
 784     # by using 'undo' one's got a simple file browser
 785     bindkey -M menuselect '^o' accept-and-infer-next-history
 786 fi
 787
 788 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 789 _bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
 790 zle -N _bkdate
 791
 792 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 793 bindkey '^Ed' _bkdate
 794
 795 # press esc-m for inserting last typed word again (thanks to caphuso!)
 796 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 797 zle -N insert-last-typed-word;
 798
 799 #k# Insert last typed word
 800 bindkey "\em" insert-last-typed-word
 801
 802 # set command prediction from history, see 'man 1 zshcontrib'
 803 #  is4 && zrcautoload predict-on && \
 804 #  zle -N predict-on         && \
 805 #  zle -N predict-off        && \
 806 #  bindkey "^X^Z" predict-on && \
 807 #  bindkey "^Z" predict-off
 808
 809 #k# Shortcut for \kbd{fg<enter>}
 810 bindkey -s '^z' "fg\n"
 811
 812 # press ctrl-q to quote line:
 813 #  mquote () {
 814 #        zle beginning-of-line
 815 #        zle forward-word
 816 #        # RBUFFER="'$RBUFFER'"
 817 #        RBUFFER=${(q)RBUFFER}
 818 #        zle end-of-line
 819 #  }
 820 #  zle -N mquote && bindkey '^q' mquote
 821
 822 # run command line as user root via sudo:
 823 sudo-command-line() {
 824     [[ -z $BUFFER ]] && zle up-history
 825     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
 826 }
 827 zle -N sudo-command-line
 828
 829 #k# Put the current command line into a \kbd{sudo} call
 830 bindkey "^Os" sudo-command-line
 831
 832 ### jump behind the first word on the cmdline.
 833 ### useful to add options.
 834 function jump_after_first_word() {
 835     local words
 836     words=(${(z)BUFFER})
 837
 838     if (( ${#words} <= 1 )) ; then
 839         CURSOR=${#BUFFER}
 840     else
 841         CURSOR=${#${words[1]}}
 842     fi
 843 }
 844 zle -N jump_after_first_word
 845
 846 bindkey '^x1' jump_after_first_word
 847
 848 # }}}
 849
 850 # {{{ set some important options
 851 # Please update these tags, if you change the umask settings below.
 852 #o# r_umask     002
 853 #o# r_umaskstr  rwxrwxr-x
 854 #o# umask       022
 855 #o# umaskstr    rwxr-xr-x
 856 (( EUID != 0 )) && umask 002 || umask 022
 857
 858 # history:
 859 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 860 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 861 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 862 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 863                             # list duplicates an older one, the older command is removed from the list
 864 setopt histignorespace      # remove command lines from the history list when
 865                             # the first character on the line is a space
 866 #  setopt histallowclobber    # add `|' to output redirections in the history
 867 #  setopt NO_clobber          # warning if file exists ('cat /dev/null > ~/.zshrc')
 868 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 869                             # and the command is the name of a directory, perform the cd command to that directory
 870 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 871                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 872                             # -> searches for word not in compressed files
 873                             # don't forget to quote '^', '~' and '#'!
 874 setopt notify               # report the status of backgrounds jobs immediately
 875 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 876                             # the entire command path is hashed first.
 877 setopt completeinword       # not just at the end
 878 # setopt nocheckjobs          # don't warn me about bg processes when exiting
 879 setopt nohup                # and don't kill them, either
 880 # setopt printexitvalue       # alert me if something failed
 881 # setopt dvorak               # with spelling correction, assume dvorak kb
 882 setopt auto_pushd           # make cd push the old directory onto the directory stack.
 883 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 884 setopt nobeep               # avoid "beep"ing
 885 setopt pushd_ignore_dups    # don't push the same dir twice.
 886
 887 MAILCHECK=30       # mailchecks
 888 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 889 watch=(notme root) # watch for everyone but me and root
 890
 891 # define word separators (for stuff like backward-word, forward-word, backward-kill-word,..)
 892 #  WORDCHARS='*?_-.[]~=/&;!#$%^(){}<>' # the default
 893 #  WORDCHARS=.
 894 #  WORDCHARS='*?_[]~=&;!#$%^(){}'
 895 #  WORDCHARS='${WORDCHARS:s@/@}'
 896
 897 # only slash should be considered as a word separator:
 898 slash-backward-kill-word() {
 899     local WORDCHARS="${WORDCHARS:s@/@}"
 900     # zle backward-word
 901     zle backward-kill-word
 902 }
 903 zle -N slash-backward-kill-word
 904
 905 #k# Kill everything in a word up to its last \kbd{/}
 906 bindkey '\ev' slash-backward-kill-word
 907
 908 # }}}
 909
 910 # {{{ history
 911
 912 ZSHDIR=$HOME/.zsh
 913
 914 #v#
 915 HISTFILE=$HOME/.zsh_history
 916 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
 917 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
 918
 919 # }}}
 920
 921 # dirstack handling {{{
 922
 923 DIRSTACKSIZE=20
 924 if [[ -f ~/.zdirs ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
 925     dirstack=( ${(f)"$(< ~/.zdirs)"} )
 926     # "cd -" won't work after login by just setting $OLDPWD, so
 927     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
 928 fi
 929
 930 chpwd() {
 931     builtin print -l ${(u)dirstack} >! ~/.zdirs
 932 }
 933
 934 # }}}
 935
 936 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
 937 if [[ -n "$BATTERY" ]] ; then
 938     if check_com -c acpi ; then
 939         PERCENT="${(C)${(s| |)$(acpi 2>/dev/null)}[4]}"
 940         [[ -z "$PERCENT" ]] && PERCENT='acpi not present'
 941
 942         if [[ "${PERCENT%%%}" -lt 20 ]] ; then
 943             PERCENT="warning: ${PERCENT}%"
 944         fi
 945     fi
 946 fi
 947 # }}}
 948
 949 # display version control information on right side of prompt if $VCS is set {{{
 950 # based on Mike Hommey's http://web.glandium.org/blog/?p=170
 951 __vcs_dir() {
 952     local vcs base_dir sub_dir ref
 953
 954     sub_dir() {
 955       local sub_dir
 956       sub_dir=$(readlink -f "${PWD}")
 957       sub_dir=${sub_dir#$1}
 958       echo ${sub_dir#/}
 959     }
 960
 961     git_dir() {
 962       base_dir=$(git-rev-parse --show-cdup 2>/dev/null) || return 1
 963       base_dir=$(readlink -f "$base_dir/..")
 964       sub_dir=$(git-rev-parse --show-prefix)
 965       sub_dir=${sub_dir%/}
 966       ref=$(git-symbolic-ref -q HEAD || git-name-rev --name-only HEAD 2>/dev/null)
 967       ref=${ref#refs/heads/}
 968       vcs="git"
 969     }
 970
 971     svn_dir() {
 972       [[ -d ".svn" ]] || return 1
 973       base_dir="."
 974       while [[ -d "$base_dir/../.svn" ]]; do base_dir="$base_dir/.."; done
 975       base_dir=$(readlink -f "$base_dir")
 976       sub_dir=$(sub_dir "${base_dir}")
 977       ref=$(svn info "$base_dir" | awk '/^URL/ { sub(".*/","",$0); r=$0 } /^Revision/ { sub("[^0-9]*","",$0); print r":"$0 }')
 978       vcs="svn"
 979     }
 980
 981     svk_dir() {
 982         [[ -f ~/.svk/config ]] || return 1
 983         base_dir=$(awk '/: *$/ { sub(/^ */,"",$0); sub(/: *$/,"",$0); if (match("'${PWD}'", $0"(/|$)")) { print $0; d=1; } } /depotpath/ && d == 1 { sub(".*/","",$0); r=$0 } /revision/ && d == 1 { print r ":" $2; exit 1 }' ~/.svk/config) && return 1
 984         ref=${base_dir##*
 985   }
 986         base_dir=${base_dir%%
 987   *}
 988         sub_dir=$(sub_dir "${base_dir}")
 989         vcs="svk"
 990     }
 991
 992     hg_dir() {
 993         base_dir="."
 994         while [[ ! -d "$base_dir/.hg" ]]; do
 995             base_dir="$base_dir/.."
 996             [[ $(readlink -f "${base_dir}") = "/" ]] && return 1
 997         done
 998         base_dir=$(readlink -f "$base_dir")
 999         sub_dir=$(sub_dir "${base_dir}")
1000         ref=$(< "${base_dir}/.hg/branch")
1001         vcs="hg"
1002     }
1003
1004     hg_dir  ||
1005     git_dir ||
1006     svn_dir ||
1007     svk_dir # ||
1008   #  base_dir="$PWD"
1009   #  echo "${vcs:+($vcs)}${base_dir/$HOME/~}${vcs:+[$ref]${sub_dir}}"
1010     echo "${vcs:+($vcs)}${base_dir}${vcs:+[$ref]${sub_dir}}"
1011 }
1012 # }}}
1013
1014 # {{{ set prompt
1015 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1016     promptinit # people should be able to use their favourite prompt
1017 else
1018     print 'Notice: no promptinit available :('
1019 fi
1020
1021
1022 # precmd() => a function which is executed just before each prompt
1023 # use 'NOPRECMD=1' to disable the precmd + preexec commands
1024
1025 # precmd () { setopt promptsubst; [[ -o interactive ]] && jobs -l;
1026
1027 # make sure to use right prompt only when not running a command
1028 is41 && setopt transient_rprompt
1029
1030 is4 && [[ -z $NOPRECMD ]] && precmd () {
1031     [[ -n $NOPRECMD ]] && return 0
1032     # allow manual overwriting of RPROMPT
1033     if [[ -n $RPROMPT ]] ; then
1034         [[ $TERM == screen* ]] && echo -n $'\ekzsh\e\\'
1035         # return 0
1036     fi
1037     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1038     if [[ -z $DONTSETRPROMPT ]] ; then
1039         if [[ -n $BATTERY ]] ; then
1040             RPROMPT="%(?..:()% ${PERCENT}${SCREENTITLE}"
1041             # RPROMPT="${PERCENT}${SCREENTITLE}"
1042         elif [[ -n $VCS ]] ; then
1043             RPROMPT="%(?..:()% $(__vcs_dir)${SCREENTITLE}"
1044         else
1045             RPROMPT="%(?..:()% ${SCREENTITLE}"
1046             # RPROMPT="${SCREENTITLE}"
1047         fi
1048     fi
1049     # adjust title of xterm
1050     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1051     case $TERM in
1052         (xterm*|rxvt)
1053             print -Pn "\e]0;%n@%m: %~\a"
1054             ;;
1055     esac
1056 }
1057
1058 # chpwd () => a function which is executed whenever the directory is changed
1059
1060 # preexec() => a function running before every command
1061 is4 && [[ -z $NOPRECMD ]] && \
1062 preexec () {
1063     [[ -n $NOPRECMD ]] && return 0
1064 # set hostname if not running on host with name 'grml'
1065     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1066        NAME="@$HOSTNAME"
1067     fi
1068 # get the name of the program currently running and hostname of local machine
1069 # set screen window title if running in a screen
1070     if [[ "$TERM" == screen* ]] ; then
1071         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1072         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1073         echo -ne "\ek$CMD\e\\"
1074     fi
1075 # set the screen title to "zsh" when sitting at the command prompt:
1076     if [[ "$TERM" == screen* ]] ; then
1077         SCREENTITLE=$'%{\ekzsh\e\\%}'
1078     else
1079         SCREENTITLE=''
1080     fi
1081 # adjust title of xterm
1082     case $TERM in
1083         (xterm*|rxvt)
1084             print -Pn "\e]0;%n@%m: $1\a"
1085             ;;
1086     esac
1087 }
1088
1089 # set colors
1090 if zrcautoload colors && colors 2>/dev/null ; then
1091     BLUE="%{${fg[blue]}%}"
1092     RED="%{${fg_bold[red]}%}"
1093     GREEN="%{${fg[green]}%}"
1094     CYAN="%{${fg[cyan]}%}"
1095     WHITE="%{${fg[white]}%}"
1096     NO_COLOUR="%{${reset_color}%}"
1097 else
1098     BLUE=$'%{\e[1;34m%}'
1099     RED=$'%{\e[1;31m%}'
1100     GREEN=$'%{\e[1;32m%}'
1101     CYAN=$'%{\e[1;36m%}'
1102     WHITE=$'%{\e[1;37m%}'
1103     NO_COLOUR=$'%{\e[0m%}'
1104 fi
1105
1106 EXITCODE="%(?..%?%1v )"
1107 PS2='`%_> '       # secondary prompt, printed when the shell needs more information to complete a command.
1108 PS3='?# '         # selection prompt used within a select loop.
1109 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1110
1111 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1112 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1113     debian_chroot=$(cat /etc/debian_chroot)
1114 fi
1115
1116 # don't use colors on dumb terminals (like emacs):
1117 if [[ "$TERM" == dumb ]] ; then
1118     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< %# "
1119 else
1120     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
1121     # set variable identifying the chroot you work in (used in the prompt below)
1122     if [[ -n $GRMLPROMPT ]] ; then
1123         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1124 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# "
1125     else
1126         if (( EUID != 0 )); then
1127             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# " # primary prompt string
1128         else
1129             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# " # primary prompt string
1130         fi
1131     fi
1132 fi
1133
1134 # if we are inside a grml-chroot set a specific prompt theme
1135 if [[ -n "$GRML_CHROOT" ]] ; then
1136     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1137 fi
1138 # }}}
1139
1140 # {{{ 'hash' some often used directories
1141 #d# start
1142 hash -d deb=/var/cache/apt/archives
1143 hash -d doc=/usr/share/doc
1144 hash -d linux=/lib/modules/$(command uname -r)/build/
1145 hash -d log=/var/log
1146 hash -d slog=/var/log/syslog
1147 hash -d src=/usr/src
1148 hash -d templ=/usr/share/doc/grml-templates
1149 hash -d tt=/usr/share/doc/texttools-doc
1150 hash -d www=/var/www
1151 #d# end
1152 # }}}
1153
1154 # {{{ some aliases
1155 if [[ $UID -eq 0 ]] ; then
1156     [[ -r /etc/grml/screenrc ]] && alias screen='/usr/bin/screen -c /etc/grml/screenrc'
1157 elif [[ -r $HOME/.screenrc ]] ; then
1158     alias screen="/usr/bin/screen -c $HOME/.screenrc"
1159 else
1160     [[ -r /etc/grml/screenrc_grml ]] && alias screen='/usr/bin/screen -c /etc/grml/screenrc_grml'
1161 fi
1162
1163 # do we have GNU ls with color-support?
1164 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
1165     #a1# execute \kbd{@a@}:\quad ls with colors
1166     alias ls='ls -b -CF --color=auto'
1167     #a1# execute \kbd{@a@}:\quad list all files, with colors
1168     alias la='ls -la --color=auto'
1169     #a1# long colored list, without dotfiles (@a@)
1170     alias ll='ls -l --color=auto'
1171     #a1# long colored list, human readable sizes (@a@)
1172     alias lh='ls -hAl --color=auto'
1173     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1174     alias l='ls -lF --color=auto'
1175 else
1176     alias ls='ls -b -CF'
1177     alias la='ls -la'
1178     alias ll='ls -l'
1179     alias lh='ls -hAl'
1180     alias l='ls -lF'
1181 fi
1182
1183 alias mdstat='cat /proc/mdstat'
1184 alias ...='cd ../../'
1185
1186 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1187 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1188     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1189 fi
1190
1191 alias cp='nocorrect cp'         # no spelling correction on cp
1192 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
1193 alias mv='nocorrect mv'         # no spelling correction on mv
1194 alias rm='nocorrect rm'         # no spelling correction on rm
1195
1196 #a1# Execute \kbd{rmdir}
1197 alias rd='rmdir'
1198 #a1# Execute \kbd{rmdir}
1199 alias md='mkdir'
1200
1201 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1202 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1203 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1204
1205 # make sure it is not assigned yet
1206 [[ $(whence -w utf2iso &>/dev/null) == 'utf2iso: alias' ]] && unalias utf2iso
1207
1208 utf2iso() {
1209     if isutfenv ; then
1210         for ENV in $(env | command grep -i '.utf') ; do
1211             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1212         done
1213     fi
1214 }
1215
1216 # make sure it is not assigned yet
1217 [[ $(whence -w iso2utf &>/dev/null) == 'iso2utf: alias' ]] && unalias iso2utf
1218 iso2utf() {
1219     if ! isutfenv ; then
1220         for ENV in $(env | command grep -i '\.iso') ; do
1221             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1222         done
1223     fi
1224 }
1225
1226 # set up software synthesizer via speakup
1227 swspeak() {
1228     aumix -w 90 -v 90 -p 90 -m 90
1229     if ! [[ -r /dev/softsynth ]] ; then
1230         flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
1231         return 1
1232     else
1233         setopt singlelinezle
1234         unsetopt prompt_cr
1235         export PS1="%m%# "
1236         nice -n -20 speechd-up
1237         sleep 2
1238         flite -o play -t "Finished setting up software synthesizer"
1239     fi
1240 }
1241
1242 # I like clean prompt, so provide simple way to get that
1243 check_com 0 || alias 0='return 0'
1244
1245 # for really lazy people like mika:
1246 check_com S &>/dev/null || alias S='screen'
1247 check_com s &>/dev/null || alias s='ssh'
1248
1249 # get top 10 shell commands:
1250 alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
1251
1252 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
1253 if check_com -c truecrypt ; then
1254     if isutfenv ; then
1255         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
1256     else
1257         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
1258     fi
1259 fi
1260
1261 #f1# Hints for the use of zsh on grml
1262 zsh-help() {
1263     print "$bg[white]$fg[black]
1264 zsh-help - hints for use of zsh on grml
1265 =======================================$reset_color"
1266
1267     print '
1268 Main configuration of zsh happens in /etc/zsh/zshrc (global)
1269 and /etc/skel/.zshrc which is copied to $HOME/.zshrc once.
1270 The files are part of the package grml-etc-core, if you want to
1271 use them on a non-grml-system just get the tar.gz from
1272 http://deb.grml.org/ or get the files from the mercurial
1273 repository:
1274
1275   http://hg.grml.org/grml-etc-core/raw-file/tip/etc/skel/.zshrc
1276   http://hg.grml.org/grml-etc-core/raw-file/tip/etc/zsh/zshrc
1277
1278 If you want to stay in sync with zsh configuration of grml
1279 run '\''ln -sf /etc/skel/.zshrc $HOME/.zshrc'\'' and configure
1280 your own stuff in $HOME/.zshrc.local. System wide configuration
1281 without touching configuration files of grml can take place
1282 in /etc/zsh/zshrc.local.
1283
1284 If you want to use the configuration of user grml also when
1285 running as user root just run '\''zshskel'\'' which will source
1286 the file /etc/skel/.zshrc.
1287
1288 For information regarding zsh start at http://grml.org/zsh/
1289
1290 Take a look at grml'\''s zsh refcard:
1291 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1292
1293 Check out the main zsh refcard:
1294 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1295
1296 And of course visit the zsh-lovers:
1297 % man zsh-lovers
1298
1299 You can adjust some options through environment variables when
1300 invoking zsh without having to edit configuration files.
1301 Basically meant for bash users who are not used to the power of
1302 the zsh yet. :)
1303
1304   "NOCOR=1    zsh" => deactivate automatic correction
1305   "NOMENU=1   zsh" => do not use menu completion (note: use strg-d for completion instead!)
1306   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1307   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt'
1308
1309     print "
1310 $bg[white]$fg[black]
1311 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1312 Enjoy your grml system with the zsh!$reset_color"
1313 }
1314
1315 # debian stuff
1316 if [[ -r /etc/debian_version ]] ; then
1317     #a3# Execute \kbd{apt-cache search}
1318     alias acs='apt-cache search'
1319     #a3# Execute \kbd{apt-cache show}
1320     alias acsh='apt-cache show'
1321     #a3# Execute \kbd{apt-cache policy}
1322     alias acp='apt-cache policy'
1323     #a3# Execute \kbd{apt-get dist-upgrade}
1324     salias adg="apt-get dist-upgrade"
1325     #a3# Execute \kbd{apt-get install}
1326     salias agi="apt-get install"
1327     #a3# Execute \kbd{aptitude install}
1328     salias ati="aptitude install"
1329     #a3# Execute \kbd{apt-get upgrade}
1330     salias ag="apt-get upgrade"
1331     #a3# Execute \kbd{apt-get update}
1332     salias au="apt-get update"
1333     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1334     salias -a up="aptitude update ; aptitude safe-upgrade"
1335     #a3# Execute \kbd{dpkg-buildpackage}
1336     alias dbp='dpkg-buildpackage'
1337     #a3# Execute \kbd{grep-excuses}
1338     alias ge='grep-excuses'
1339
1340     # debian upgrade
1341     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
1342     upgrade() {
1343         if [[ -z "$1" ]] ; then
1344             $SUDO apt-get update
1345             $SUDO apt-get -u upgrade
1346         else
1347             ssh $1 $SUDO apt-get update
1348             # ask before the upgrade
1349             local dummy
1350             ssh $1 $SUDO apt-get --no-act upgrade
1351             echo -n 'Process the upgrade?'
1352             read -q dummy
1353             if [[ $dummy == "y" ]] ; then
1354                 ssh $1 $SUDO apt-get -u upgrade --yes
1355             fi
1356         fi
1357     }
1358
1359     isgrmlcd && alias su="sudo -s"          # get a root shell
1360     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1361     alias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1362     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1363     alias tlog="tail -f /var/log/syslog"    # follow the syslog
1364     #a1# (Re)-source \kbd{/etc/skel/.zshrc}
1365     alias zshskel="source /etc/skel/.zshrc" # source skeleton zshrc
1366 fi
1367
1368 # sort installed Debian-packages by size
1369 if check_com -c grep-status ; then
1370     #a3# List installed Debian-packages sorted by size
1371     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
1372 fi
1373
1374 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1375 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord ; then
1376     if check_com -c wodim ; then
1377         alias cdrecord="echo 'cdrecord is not provided under its original name by Debian anymore.
1378 See #377109 in the BTS of Debian for more details.
1379
1380 Please use the wodim binary instead' ; return 1"
1381     fi
1382 fi
1383
1384 # get_tw_cli has been renamed into get_3ware
1385 if check_com -c get_3ware ; then
1386     get_tw_cli() {
1387         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
1388         get_3ware
1389     }
1390 fi
1391
1392 # I hate lacking backward compatibility, so provide an alternative therefore
1393 if ! check_com -c apache2-ssl-certificate ; then
1394
1395     apache2-ssl-certificate() {
1396
1397     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
1398     print 'You might want to take a look at Debian the package ssl-cert as well.'
1399     print 'To generate a certificate for use with apache2 follow the instructions:'
1400
1401     echo '
1402
1403 export RANDFILE=/dev/random
1404 mkdir /etc/apache2/ssl/
1405 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
1406 chmod 600 /etc/apache2/ssl/apache.pem
1407
1408 Run "grml-tips ssl-certificate" if you need further instructions.
1409 '
1410     }
1411 fi
1412 # }}}
1413
1414 # {{{ Use hard limits, except for a smaller stack and no core dumps
1415 unlimit
1416 is4 && limit stack 8192
1417 isgrmlcd && limit core 0 # important for a live-cd-system
1418 limit -s
1419 # }}}
1420
1421 # {{{ completion system
1422
1423 # called later (via is4 && grmlcomp)
1424 # notice: use 'zstyle' for getting current settings
1425 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
1426 grmlcomp() {
1427     # TODO: This could use some additional information
1428
1429     # allow one error for every three characters typed in approximate completer
1430     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1431
1432     # don't complete backup files as executables
1433     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1434
1435     # start menu completion only if it could find no unambiguous initial string
1436     zstyle ':completion:*:correct:*'       insert-unambiguous true
1437     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1438     zstyle ':completion:*:correct:*'       original true
1439
1440     # activate color-completion
1441     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1442
1443     # format on completion
1444     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1445
1446     # complete 'cd -<tab>' with menu
1447     zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1448
1449     # insert all expansions for expand completer
1450     zstyle ':completion:*:expand:*'        tag-order all-expansions
1451     zstyle ':completion:*:history-words'   list false
1452
1453     # activate menu
1454     zstyle ':completion:*:history-words'   menu yes
1455
1456     # ignore duplicate entries
1457     zstyle ':completion:*:history-words'   remove-all-dups yes
1458     zstyle ':completion:*:history-words'   stop yes
1459
1460     # match uppercase from lowercase
1461     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1462
1463     # separate matches into groups
1464     zstyle ':completion:*:matches'         group 'yes'
1465     zstyle ':completion:*'                 group-name ''
1466
1467     if [[ -z "$NOMENU" ]] ; then
1468         # if there are more than 5 options allow selecting from a menu
1469         zstyle ':completion:*'               menu select=5
1470     else
1471         # don't use any menus at all
1472         setopt no_auto_menu
1473     fi
1474
1475     zstyle ':completion:*:messages'        format '%d'
1476     zstyle ':completion:*:options'         auto-description '%d'
1477
1478     # describe options in full
1479     zstyle ':completion:*:options'         description 'yes'
1480
1481     # on processes completion complete all user processes
1482     zstyle ':completion:*:processes'       command 'ps -au$USER'
1483
1484     # offer indexes before parameters in subscripts
1485     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1486
1487     # provide verbose completion information
1488     zstyle ':completion:*'                 verbose true
1489
1490     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1491     # for commands (read: 1st word in the line) that it will list for the user
1492     # to choose from. The following disables that, because it's not exactly fast.
1493     zstyle ':completion:*:-command-:*:'    verbose false
1494
1495     # set format for warnings
1496     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1497
1498     # define files to ignore for zcompile
1499     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1500     zstyle ':completion:correct:'          prompt 'correct to: %e'
1501
1502     # Ignore completion functions for commands you don't have:
1503     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1504
1505     # complete manual by their section
1506     zstyle ':completion:*:manuals'    separate-sections true
1507     zstyle ':completion:*:manuals.*'  insert-sections   true
1508     zstyle ':completion:*:man:*'      menu yes select
1509
1510     # run rehash on completion so new installed program are found automatically:
1511     _force_rehash() {
1512         (( CURRENT == 1 )) && rehash
1513         return 1
1514     }
1515
1516     ## correction
1517     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1518     if [[ -n "$NOCOR" ]] ; then
1519         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1520         setopt nocorrect
1521     else
1522         # try to be smart about when to use what completer...
1523         setopt correct
1524         zstyle -e ':completion:*' completer '
1525             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1526                 _last_try="$HISTNO$BUFFER$CURSOR"
1527                 reply=(_complete _match _ignored _prefix _files)
1528             else
1529                 if [[ $words[1] == (rm|mv) ]] ; then
1530                     reply=(_complete _files)
1531                 else
1532                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1533                 fi
1534             fi'
1535     fi
1536
1537     # zstyle ':completion:*' completer _complete _correct _approximate
1538     # zstyle ':completion:*' expand prefix suffix
1539
1540     # command for process lists, the local web server details and host completion
1541     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1542
1543     # caching
1544     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1545                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1546
1547     # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
1548     if is42 ; then
1549         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1550         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1551     else
1552         _ssh_hosts=()
1553         _etc_hosts=()
1554     fi
1555     hosts=(
1556         $(hostname)
1557         "$_ssh_hosts[@]"
1558         "$_etc_hosts[@]"
1559         grml.org
1560         localhost
1561     )
1562     zstyle ':completion:*:hosts' hosts $hosts
1563     #  zstyle '*' hosts $hosts
1564
1565     # specify your logins:
1566     # my_accounts=(
1567     #  {grml,grml1}@foo.invalid
1568     #  grml-devel@bar.invalid
1569     # )
1570     # other_accounts=(
1571     #  {fred,root}@foo.invalid
1572     #  vera@bar.invalid
1573     # )
1574     # zstyle ':completion:*:my-accounts' users-hosts $my_accounts
1575     # zstyle ':completion:*:other-accounts' users-hosts $other_accounts
1576
1577     # specify specific port/service settings:
1578     #  telnet_users_hosts_ports=(
1579     #    user1@host1:
1580     #    user2@host2:
1581     #    @mail-server:{smtp,pop3}
1582     #    @news-server:nntp
1583     #    @proxy-server:8000
1584     #  )
1585     # zstyle ':completion:*:*:telnet:*' users-hosts-ports $telnet_users_hosts_ports
1586
1587     # use generic completion system for programs not yet defined; (_gnu_generic works
1588     # with commands that provide a --help option with "standard" gnu-like output.)
1589     compdef _gnu_generic tail head feh cp mv df stow uname ipacsum fetchipac
1590
1591     # see upgrade function in this file
1592     compdef _hosts upgrade
1593 }
1594 # }}}
1595
1596 # {{{ grmlstuff
1597 grmlstuff() {
1598 # people should use 'grml-x'!
1599     startx() {
1600         if [[ -e /etc/X11/xorg.conf ]] ; then
1601             [[ -x /usr/bin/startx ]] && /usr/bin/startx "$@" || /usr/X11R6/bin/startx "$@"
1602         else
1603             echo "Please use the script \"grml-x\" for starting the X Window System
1604 because there does not exist /etc/X11/xorg.conf yet.
1605 If you want to use startx anyway please call \"/usr/bin/startx\"."
1606             return -1
1607         fi
1608     }
1609
1610     xinit() {
1611         if [[ -e /etc/X11/xorg.conf ]] ; then
1612             [[ -x /usr/bin/xinit ]] && /usr/bin/xinit || /usr/X11R6/bin/xinit
1613         else
1614             echo "Please use the script \"grml-x\" for starting the X Window System.
1615 because there does not exist /etc/X11/xorg.conf yet.
1616 If you want to use xinit anyway please call \"/usr/bin/xinit\"."
1617             return -1
1618         fi
1619     }
1620
1621     if check_com -c 915resolution ; then
1622         alias 855resolution='echo -e "Please use 915resolution as resolution modify tool for Intel graphic chipset."; return -1'
1623     fi
1624
1625     #a1# Output version of running grml
1626     alias grml-version='cat /etc/grml_version'
1627
1628     if check_com -c rebuildfstab ; then
1629         #a1# Rebuild /etc/fstab
1630         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1631     fi
1632
1633     if check_com -c grml-debootstrap ; then
1634         alias debian2hd='print "Installing debian to harddisk is possible via using grml-debootstrap." ; return 1'
1635     fi
1636 }
1637 # }}}
1638
1639 # {{{ now run the functions
1640 isgrml && checkhome
1641 is4    && isgrml    && grmlstuff
1642 is4    && grmlcomp
1643 # }}}
1644
1645 # {{{ keephack
1646 is4 && xsource "/etc/zsh/keephack"
1647 # }}}
1648
1649 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
1650 # You use it as follows:
1651 # $ NTREF=/reference/file
1652 # $ ls -l *(e:nt:)
1653 # This lists all the files in the current directory newer than the reference file.
1654 # You can also specify the reference file inline; note quotes:
1655 # $ ls -l *(e:'nt ~/.zshenv':)
1656 is4 && nt() {
1657     if [[ -n $1 ]] ; then
1658         local NTREF=${~1}
1659     fi
1660     [[ $REPLY -nt $NTREF ]]
1661 }
1662 # }}}
1663
1664 # shell functions {{{
1665
1666 #f1# Provide csh compatibility
1667 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
1668
1669 #f1# Reload an autoloadable function
1670 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1671
1672 #f1# Reload zsh setup
1673 reload() {
1674     if [[ "$#*" -eq 0 ]] ; then
1675         [[ -r ~/.zshrc ]] && . ~/.zshrc
1676     else
1677         local fn
1678         for fn in "$@"; do
1679             unfunction $fn
1680             autoload -U $fn
1681         done
1682     fi
1683 }
1684 compdef _functions reload freload
1685
1686 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1687 sll() {
1688     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1689     for i in "$@" ; do
1690         file=$i
1691         while [[ -h "$file" ]] ; do
1692             ls -l $file
1693             file=$(readlink "$file")
1694         done
1695     done
1696 }
1697
1698 # fast manual access
1699 if check_com qma ; then
1700     #f1# View the zsh manual
1701     manzsh()  { qma zshall "$1" }
1702     compdef _man qma
1703 else
1704     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
1705     # manzsh()  { /usr/bin/man zshall |  most +/"$1" ; }
1706     # [[ -f ~/.terminfo/m/mostlike ]] && MYLESS='LESS=C TERMINFO=~/.terminfo TERM=mostlike less' || MYLESS='less'
1707     # manzsh()  { man zshall | $MYLESS -p $1 ; }
1708 fi
1709
1710 if check_com -c $PAGER ; then
1711     #f1# View Debian's changelog of a given package
1712     dchange() {
1713         if [[ -r /usr/share/doc/${1}/changelog.Debian.gz ]] ; then
1714             $PAGER /usr/share/doc/${1}/changelog.Debian.gz
1715         elif [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
1716             $PAGER /usr/share/doc/${1}/changelog.gz
1717         else
1718             if check_com -c aptitude ; then
1719                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1720                 if isgrml ; then
1721                     aptitude -t unstable changelog ${1}
1722                 else
1723                     aptitude changelog ${1}
1724                 fi
1725             else
1726                 echo "No changelog for package $1 found, sorry."
1727                 return 1
1728             fi
1729         fi
1730     }
1731     _dchange() { _files -W /usr/share/doc -/ }
1732     compdef _dchange dchange
1733
1734     #f1# View Debian's NEWS of a given package
1735     dnews() {
1736         if [[ -r /usr/share/doc/${1}/NEWS.Debian.gz ]] ; then
1737             $PAGER /usr/share/doc/${1}/NEWS.Debian.gz
1738         else
1739             if [[ -r /usr/share/doc/${1}/NEWS.gz ]] ; then
1740                 $PAGER /usr/share/doc/${1}/NEWS.gz
1741             else
1742                 echo "No NEWS file for package $1 found, sorry."
1743                 return 1
1744             fi
1745         fi
1746     }
1747     _dnews() { _files -W /usr/share/doc -/ }
1748     compdef _dnews dnews
1749
1750     #f1# View upstream's changelog of a given package
1751     uchange() {
1752         if [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
1753             $PAGER /usr/share/doc/${1}/changelog.gz
1754         else
1755             echo "No changelog for package $1 found, sorry."
1756             return 1
1757         fi
1758     }
1759     _uchange() { _files -W /usr/share/doc -/ }
1760     compdef _uchange uchange
1761 fi
1762
1763 # zsh profiling
1764 profile() {
1765     ZSH_PROFILE_RC=1 $SHELL "$@"
1766 }
1767
1768 #f1# Edit an alias via zle
1769 edalias() {
1770     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1771 }
1772 compdef _aliases edalias
1773
1774 #f1# Edit a function via zle
1775 edfunc() {
1776     [[ -z "$1" ]] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
1777 }
1778 compdef _functions edfunc
1779
1780 # use it e.g. via 'Restart apache2'
1781 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
1782 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
1783 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
1784 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
1785 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
1786 if [[ -d /etc/init.d ]] ; then
1787     for i in Start Restart Stop Force-Reload Reload ; do
1788         eval "$i() { $SUDO /etc/init.d/\$1 ${i:l} \$2 ; }"
1789     done
1790 fi
1791
1792 #f1# Provides useful information on globbing
1793 H-Glob() {
1794     echo -e "
1795     /      directories
1796     .      plain files
1797     @      symbolic links
1798     =      sockets
1799     p      named pipes (FIFOs)
1800     *      executable plain files (0100)
1801     %      device files (character or block special)
1802     %b     block special files
1803     %c     character special files
1804     r      owner-readable files (0400)
1805     w      owner-writable files (0200)
1806     x      owner-executable files (0100)
1807     A      group-readable files (0040)
1808     I      group-writable files (0020)
1809     E      group-executable files (0010)
1810     R      world-readable files (0004)
1811     W      world-writable files (0002)
1812     X      world-executable files (0001)
1813     s      setuid files (04000)
1814     S      setgid files (02000)
1815     t      files with the sticky bit (01000)
1816
1817   print *(m-1)          # Files modified up to a day ago
1818   print *(a1)           # Files accessed a day ago
1819   print *(@)            # Just symlinks
1820   print *(Lk+50)        # Files bigger than 50 kilobytes
1821   print *(Lk-50)        # Files smaller than 50 kilobytes
1822   print **/*.c          # All *.c files recursively starting in \$PWD
1823   print **/*.c~file.c   # Same as above, but excluding 'file.c'
1824   print (foo|bar).*     # Files starting with 'foo' or 'bar'
1825   print *~*.*           # All Files that do not contain a dot
1826   chmod 644 *(.^x)      # make all plain non-executable files publically readable
1827   print -l *(.c|.h)     # Lists *.c and *.h
1828   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
1829   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
1830 }
1831 alias help-zshglob=H-Glob
1832
1833 check_com -c qma && alias ?='qma zshall'
1834
1835 # grep for running process, like: 'any vim'
1836 any() {
1837     if [[ -z "$1" ]] ; then
1838         echo "any - grep for process(es) by keyword" >&2
1839         echo "Usage: any <keyword>" >&2 ; return 1
1840     else
1841         local STRING=$1
1842         local LENGTH=$(expr length $STRING)
1843         local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
1844         local REST=$(echo $(expr substr $STRING 2 $LENGTH))
1845         ps xauwww| grep "[$FIRSCHAR]$REST"
1846     fi
1847 }
1848
1849 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
1850 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
1851 [[ -r /proc/1/maps ]] && \
1852 deswap() {
1853     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
1854     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
1855     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
1856 }
1857
1858 # print hex value of a number
1859 hex() {
1860     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
1861 }
1862
1863 # calculate (or eval at all ;-)) with perl => p[erl-]eval
1864 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
1865 peval() {
1866     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
1867     perl -e "print eval($CALC),\"\n\";"
1868 }
1869 functions peval &>/dev/null && alias calc=peval
1870
1871 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
1872 # certain circumstances, so work around it, no matter which environment we have
1873 brltty() {
1874     if [[ -z "$DISPLAY" ]] ; then
1875         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
1876         command brltty "$@"
1877     else
1878         command brltty "$@"
1879     fi
1880 }
1881
1882 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
1883 aoeu() {
1884     echo -n 'Switching to us keyboard layout: '
1885     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
1886     echo 'Done'
1887 }
1888 asdf() {
1889     echo -n 'Switching to dvorak keyboard layout: '
1890     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
1891     echo 'Done'
1892 }
1893 # just press 'asdf' key to toggle from neon layout to us keyboard layout
1894 uiae() {
1895     echo -n 'Switching to us keyboard layout: '
1896     setxkbmap us && echo 'Done' || echo 'Failed'
1897 }
1898
1899 # set up an ipv6 tunnel
1900 ipv6-tunnel() {
1901     case $1 in
1902         start)
1903             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1904                 print 'ipv6 tunnel already set up, nothing to be done.'
1905                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
1906             else
1907                 [[ -n "$PUBLIC_IP" ]] || \
1908                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
1909                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
1910
1911                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
1912                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
1913                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
1914                 ifconfig sit0 tunnel ::192.88.99.1 up
1915                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
1916             fi
1917             ;;
1918         status)
1919             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1920                 print 'ipv6 tunnel available' ; return 0
1921             else
1922                 print 'ipv6 tunnel not available' ; return 1
1923             fi
1924             ;;
1925         stop)
1926             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1927                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
1928                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
1929             else
1930                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
1931             fi
1932             ;;
1933         *)
1934             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
1935             ;;
1936     esac
1937 }
1938
1939 # run dhclient for wireless device
1940 iwclient() {
1941     salias dhclient "$(wavemon -d | awk '/device/{print $2}')"
1942 }
1943
1944 # spawn a minimally set up ksh - useful if you want to umount /usr/.
1945 minimal-shell() {
1946     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ksh
1947 }
1948
1949 # make a backup of a file
1950 bk() {
1951     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
1952 }
1953
1954 # Switching shell safely and efficiently? http://www.zsh.org/mla/workers/2001/msg02410.html
1955 # bash() {
1956 #  NO_SWITCH="yes" command bash "$@"
1957 # }
1958 # restart () {
1959 #  exec $SHELL $SHELL_ARGS "$@"
1960 # }
1961
1962 # }}}
1963
1964 # log out? set timeout in seconds {{{
1965 # TMOUT=1800
1966 # do not log out in some specific terminals:
1967 #  if [[ "${TERM}" == ([Exa]term*|rxvt|dtterm|screen*) ]] ; then
1968 #    unset TMOUT
1969 #  fi
1970 # }}}
1971
1972 # {{{ make sure our environment is clean regarding colors
1973 for color in BLUE RED GREEN CYAN WHITE ; unset $color
1974 # }}}
1975
1976 # source another config file if present {{{
1977 xsource "/etc/zsh/zshrc.local"
1978 # }}}
1979
1980 # "persistent history" {{{
1981 # just write important commands you always need to ~/.important_commands
1982 if [[ -r ~/.important_commands ]] ; then
1983     fc -R ~/.important_commands
1984 fi
1985 # }}}
1986
1987 ## genrefcard.pl settings {{{
1988 ### example: split functions-search 8,16,24,32
1989 #@# split functions-search 8
1990 ## }}}
1991
1992 # add variable to be able to check whether the file has been read {{{
1993 ZSHRC_GLOBAL_HAS_BEEN_READ=1
1994 # }}}
1995
1996 ## END OF FILE #################################################################
1997 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4