etc/skel/.zshrc

   1 # Filename:      .zshrc
   2 # Purpose:       config file for zsh
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 # Latest change: Don Mai 31 17:19:00 CEST 2007 [mika]
   7 ################################################################################
   8
   9 # source ~/.zshrc.global {{{
  10 # see /etc/zsh/zshrc for some general settings
  11 # If you don't have write permissions to /etc/zsh/zshrc on your own
  12 # copy the file to your $HOME as /.zshrc.global and we source it:
  13   if [ -r ~/.zshrc.global ] ; then
  14      . ~/.zshrc.global
  15   fi
  16 # }}}
  17
  18 # check whether global file has been read {{{
  19   if [ -z "$ZSHRC_GLOBAL_HAS_BEEN_READ" ] ; then
  20      print 'Warning: global zsh config has not been read'>&2
  21   fi
  22 # }}}
  23
  24 # autoloading stuff {{{
  25 # associate types and extensions (be aware with perl scripts and anwanted behaviour!)
  26 #  type zsh-mime-setup &>/dev/null || { autoload zsh-mime-setup && zsh-mime-setup }
  27 #  alias -s pl='perl -S'
  28 # }}}
  29
  30 # completion system {{{
  31 # just make sure it is loaded in this file too
  32   type compinit &>/dev/null || { autoload -U compinit && compinit }
  33 # }}}
  34
  35 # make sure isgrmlsmall is defined {{{
  36   type isgrmlsmall &>/dev/null || function isgrmlsmall () { return 1 }
  37 # }}}
  38
  39 ## variables {{{
  40
  41 # do you want grmlsmall-specific adjustments?
  42   GRMLSMALL_SPECIFIC=1
  43
  44 # set terminal property (used e.g. by msgid-chooser)
  45   export COLORTERM="yes"
  46
  47 # set default browser
  48   if [ -z "$BROWSER" ] ; then
  49      if [ -n "$DISPLAY" ] ; then
  50         #v# If X11 is running
  51         [ -x $(which firefox) ] && export BROWSER=firefox
  52      else
  53         #v# If no X11 is running
  54         [ -x $(which w3m) ] && export BROWSER=w3m
  55      fi
  56   fi
  57   #v#
  58   (( ${+PAGER} ))   || export PAGER="less"
  59
  60 # export qtdir
  61   #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
  62   [ -d /usr/share/qt3 ] && export QTDIR=/usr/share/qt3
  63   [ -d /usr/share/qt4 ] && export QTDIR=/usr/share/qt4
  64
  65 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
  66   #v# [for non-root only]
  67   [ -f /usr/share/classpath/glibj.zip ] && export JIKESPATH=/usr/share/classpath/glibj.zip
  68 # }}}
  69
  70 ## set options {{{
  71
  72 # Allow comments even in interactive shells i. e.
  73 # $ uname # This command prints system informations
  74 # zsh: bad pattern: #
  75 # $ setopt interactivecomments
  76 # $ uname # This command prints system informations
  77 # Linux
  78 #  setopt interactivecomments
  79
  80 # ctrl-s will no longer freeze the terminal.
  81 #  stty erase "^?"
  82
  83 # }}}
  84
  85 # {{{ global aliases
  86 # These do not have to be at the beginning of the command line.
  87 # Avoid typing cd ../../ for going two dirs down and so on
  88 # Usage, e.g.: "$ cd ...' or just '$ ...' with 'setopt auto_cd'
  89 # Notice: deactivated by 061112 by default, we use another approach
  90 # known as "power completion / abbreviation expansion"
  91 #  alias -g '...'='../..'
  92 #  alias -g '....'='../../..'
  93 #  alias -g BG='& exit'
  94 #  alias -g C='|wc -l'
  95 #  alias -g G='|grep'
  96 #  alias -g H='|head'
  97 #  alias -g Hl=' --help |& less -r'
  98 #  alias -g K='|keep'
  99 #  alias -g L='|less'
 100 #  alias -g LL='|& less -r'
 101 #  alias -g M='|most'
 102 #  alias -g N='&>/dev/null'
 103 #  alias -g R='| tr A-z N-za-m'
 104 #  alias -g SL='| sort | less'
 105 #  alias -g S='| sort'
 106 #  alias -g T='|tail'
 107 #  alias -g V='| vim -'
 108 # }}}
 109
 110 ## aliases {{{
 111
 112 # Xterm resizing-fu.
 113 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
 114   alias hide='echo -en "\033]50;nil2\007"'
 115   alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
 116   alias small='echo -en "\033]50;6x10\007"'
 117   alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
 118   alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
 119   alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
 120   alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
 121   alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
 122   alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
 123 #  if [ "$TERM" = "xterm" ] && [ "$LINES" -ge 50 ] && [ "$COLUMNS" -ge 100 ] && [ -z "$SSH_CONNECTION" ]; then
 124 #          large
 125 #  fi
 126
 127 # general
 128   #a2# Execute \kbd{du -sch}
 129   alias da='du -sch'
 130   #a2# Execute \kbd{jobs -l}
 131   alias j='jobs -l'
 132 #  alias u='translate -i'          # translate
 133
 134 # compile stuff
 135   #a2# Execute \kbd{./configure}
 136   alias CO="./configure"
 137   #a2# Execute \kbd{./configure --help}
 138   alias CH="./configure --help"
 139
 140 # http://conkeror.mozdev.org/
 141   #a2# Run a keyboard driven firefox
 142   alias conkeror='firefox -chrome chrome://conkeror/content'
 143
 144 # arch/tla stuff
 145   if type -p tla &>/dev/null ; then
 146      #a2# Execute \kbd{tla what-changed --diffs | less}
 147      alias tdi='tla what-changed --diffs | less'
 148      #a2# Execute \kbd{tla-buildpackage}
 149      alias tbp='tla-buildpackage'
 150      #a2# Execute \kbd{tla archive-mirror}
 151      alias tmi='tla archive-mirror'
 152      #a2# Execute \kbd{tla commit}
 153      alias tco='tla commit'
 154      #a2# Execute \kbd{tla star-merge}
 155      alias tme='tla star-merge'
 156   fi
 157
 158 # listing stuff
 159   #a2# Execute \kbd{ls -lSrah}
 160   alias dir="ls -lSrah"
 161   #a2# Only show dot-directories
 162   alias lad='ls -d .*(/)'                # only show dot-directories
 163   #a2# Only show dot-files
 164   alias lsa='ls -a .*(.)'                # only show dot-files
 165   #a2# Only files with setgid/setuid/sticky flag
 166   alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
 167   #a2# Only show 1st ten symlinks
 168   alias lsl='ls -l *(@[1,10])'           # only symlinks
 169   #a2# Display only executables
 170   alias lsx='ls -l *(*[1,10])'           # only executables
 171   #a2# Display world-{readable,writable,executable} files
 172   alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
 173   #a2# Display the ten biggest files
 174   alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
 175   #a2# Only show directories
 176   alias lsd='ls -d *(/)'                 # only show directories
 177   #a2# Only show empty directories
 178   alias lse='ls -d *(/^F)'               # only show empty directories
 179   #a2# Display the ten newest files
 180   alias lsnew="ls -rl *(D.om[1,10])"     # display the newest files
 181   #a2# Display the ten oldest files
 182   alias lsold="ls -rtlh *(D.om[1,10])"   # display the oldest files
 183   #a2# Display the ten smallest files
 184   alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
 185
 186 # chmod
 187   #a2# Execute \kbd{chmod 600}
 188   alias rw-='chmod 600'
 189   #a2# Execute \kbd{chmod 700}
 190   alias rwx='chmod 700'
 191   #m# a2 r-{}- Execute \kbd{chmod 644}
 192   alias r--='chmod 644'
 193   #a2# Execute \kbd{chmod 755}
 194   alias r-x='chmod 755'
 195
 196 # some useful aliases
 197   #a2# Execute \kbd{mkdir -o}
 198   alias md='mkdir -p'
 199
 200   [ -x $(which ipython) ] && alias ips='ipython -p sh'
 201
 202 # console stuff
 203   #a2# Execute \kbd{mplayer -vo fbdev}
 204   alias cmplayer='mplayer -vo fbdev'
 205   #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
 206   alias fbmplayer='mplayer -vo fbdev -fs -zoom'
 207   #a2# Execute \kbd{links2 -driver fb}
 208   alias fblinks='links2 -driver fb'
 209
 210 # ignore ~/.ssh/known_hosts entries
 211 #  alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null" -o "PreferredAuthentications=keyboard-interactive"'
 212   #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
 213   alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 214   alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 215
 216 # use colors when browsing man pages (if not using pinfo or PAGER=most)
 217   [ -d ~/.terminfo/ ] && alias man='TERMINFO=~/.terminfo/ LESS=C TERM=mostlike PAGER=less man'
 218
 219 # check whether Debian's package management (dpkg) is running
 220   if type salias &>/dev/null ; then
 221     #a2# Check whether a dpkg instance is currently running
 222     salias check_dpkg_running="dpkg_running"
 223   fi
 224
 225 # work around non utf8 capable software in utf environment
 226   if type isutfenv &>/dev/null ; then
 227      if [ -x $(which mrxvt) ] ; then
 228         isutfenv && [ -n "$LANG" ] && alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} mrxvt"
 229      fi
 230
 231      if [ -x $(which aterm) ] ; then
 232         isutfenv && [ -n "$LANG" ] && alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} aterm"
 233      fi
 234
 235      if [ -x $(which centericq) ] ; then
 236         isutfenv && [ -n "$LANG" ] && alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} centericq"
 237      fi
 238   fi
 239 # }}}
 240
 241 ## useful functions {{{
 242
 243 # searching
 244   #f4# Search for newspostings from authors
 245   agoogle() { ${=BROWSER} "http://groups.google.com/groups?as_uauthors=$*" ; }
 246   #f4# Search Debian Bug Tracking System by BugID in mbox format
 247   debbug()  { ${=BROWSER} "http://bugs.debian.org/$*" }
 248   #f4# Search Debian Bug Tracking System
 249   debbugm() { bts show --mbox $1 } # provide bugnummer as "$1"
 250   #f4# Search DMOZ
 251   dmoz()    { ${=BROWSER} http://search.dmoz.org/cgi-bin/search\?search=${1// /_} }
 252   #f4# Search German   Wiktionary
 253   dwicti()  { ${=BROWSER} http://de.wiktionary.org/wiki/${(C)1// /_} }
 254   #f4# Search English  Wiktionary
 255   ewicti()  { ${=BROWSER} http://en.wiktionary.org/wiki/${(C)1// /_} }
 256   #f4# Search Google Groups
 257   ggogle()  { ${=BROWSER} "http://groups.google.com/groups?q=$*" }
 258   #f4# Search Google
 259   google()  { ${=BROWSER} "http://www.google.com/search?&num=100&q=$*" }
 260   #f4# Search Google Groups for MsgID
 261   mggogle() { ${=BROWSER} "http://groups.google.com/groups?selm=$*" }
 262   #f4# Search Netcraft
 263   netcraft(){ ${=BROWSER} "http://toolbar.netcraft.com/site_report?url=$1" }
 264   #f4# Use German Wikipedia's full text search
 265   swiki()   { ${=BROWSER} http://de.wikipedia.org/wiki/Spezial:Search/${(C)1} }
 266   #f4# search \kbd{dict.leo.org}
 267   oleo()    { ${=BROWSER} "http://dict.leo.org/?search=$*" }
 268   #f4# Search German   Wikipedia
 269   wikide () { ${=BROWSER} http://de.wikipedia.org/wiki/"${(C)*}" }
 270   #f4# Search English  Wikipedia
 271   wikien()  { ${=BROWSER} http://en.wikipedia.org/wiki/"$*" }
 272   #f4# Search official debs
 273   wodeb ()  { ${=BROWSER} "http://packages.debian.org/cgi-bin/search_contents.pl?word=$1&version=${2:-unstable}" }
 274   #m# f4 gex() Exact search via Google
 275   which google &>/dev/null && gex () { google "\"[ $1]\" $*" } # exact search at google
 276
 277 # misc
 278   #f5# Backup \kbd{file {\rm to} file\_timestamp}
 279   bk()      { cp -b ${1} ${1}_`date --iso-8601=m` }
 280   #f5# Copied diff
 281   cdiff()   { diff -crd "$*" | egrep -v "^Only in |^Binary files " }
 282   #f5# cd to directoy and list files
 283   cl()      { cd $1 && ls -a }        # cd && ls
 284   #f5# Cvs add
 285   cvsa()    { cvs add $* && cvs com -m 'initial checkin' $* }
 286   #f5# Cvs diff
 287   cvsd()    { cvs diff -N $* |& $PAGER }
 288   #f5# Cvs log
 289   cvsl()    { cvs log $* |& $PAGER }
 290   #f5# Cvs update
 291   cvsq()    { cvs -nq update }
 292   #f5# Rcs2log
 293   cvsr()    { rcs2log $* | $PAGER }
 294   #f5# Cvs status
 295   cvss()    { cvs status -v $* }
 296   #f5# Disassemble source files using gcc and as
 297   disassemble(){ gcc -pipe -S -o - -O -g $* | as -aldh -o /dev/null }
 298   #f5# Firefox remote control - open given URL
 299   fir()     { firefox -a firefox -remote "openURL($1)" }
 300   #f5# Create Directoy and \kbd{cd} to it
 301   mcd()     { mkdir -p "$@"; cd "$@" } # mkdir && cd
 302   #f5# Unified diff to timestamped outputfile
 303   mdiff()   { diff -udrP "$1" "$2" > diff.`date "+%Y-%m-%d"`."$1" }
 304   #f5# Memory overview
 305   memusage(){ ps aux | awk '{if (NR > 1) print $5; if (NR > 2) print "+"} END { print "p" }' | dc }
 306   #f5# Show contents of tar file
 307   shtar()   { gunzip -c $1 | tar -tf - -- | $PAGER }
 308   #f5# Show contents of tgz file
 309   shtgz()   { tar -ztf $1 | $PAGER }
 310   #f5# Show contents of zip file
 311   shzip()   { unzip -l $1 | $PAGER }
 312   #f5# Greps signature from file
 313   sig()     { agrep -d '^-- $' "$*" ~/.Signature }
 314   #f5# Unified diff
 315   udiff()   { diff -urd $* | egrep -v "^Only in |^Binary files " }
 316   #f5# (Mis)use \kbd{vim} as \kbd{less}
 317   viless()  { vim --cmd 'let no_plugin_maps = 1' -c "so \$VIMRUNTIME/macros/less.vim" "${@:--}" }
 318
 319   # download video from youtube
 320   ytdl() {
 321     if ! [ -n "$2" ] ; then
 322        print "Usage: ydtl http://youtube.com/watch?v=.... outputfile.flv">&2
 323        return 1
 324     else
 325        wget -O${2} "http://youtube.com/get_video?"${${${"$(wget -o/dev/null -O- "${1}" | grep -e watch_fullscreen)"}##*watch_fullscreen\?}%%\&fs=*}
 326     fi
 327   }
 328
 329
 330 # Function Usage: doc packagename
 331   #f5# \kbd{cd} to /usr/share/doc/\textit{package}
 332   doc() { cd /usr/share/doc/$1 && ls }
 333   _doc() { _files -W /usr/share/doc -/ }
 334   type compdef &>/dev/null && compdef _doc doc
 335
 336 #f5# Make screenshot
 337   sshot() {
 338         [[ ! -d ~/shots  ]] && mkdir ~/shots
 339         #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
 340         cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
 341   }
 342
 343 # list images only
 344   limg() {
 345     local -a images
 346     images=( *.{jpg,gif,png}(.N) )
 347     if [[ $#images -eq 0 ]] ; then
 348       print "No image files found"
 349     else
 350       ls "$@" "$images[@]"
 351     fi
 352   }
 353
 354 #f5# Create PDF file from source code
 355   makereadable() {
 356      output=$1
 357      shift
 358      a2ps --medium A4dj -E -o $output $*
 359      ps2pdf $output
 360   }
 361
 362 # zsh with perl-regex - use it e.g. via:
 363 # regcheck '\s\d\.\d{3}\.\d{3} Euro' ' 1.000.000 Euro'
 364 #f5# Checks whether a regex matches or not.\\&\quad Example: \kbd{regcheck '.\{3\} EUR' '500 EUR'}
 365   regcheck() {
 366     zmodload -i zsh/pcre
 367     pcre_compile $1 && \
 368     pcre_match $2 && echo "regex matches" || echo "regex does not match"
 369   }
 370
 371 #f5# List files which have been modified within the last {\it n} days
 372   new() { print -l *(m-$1) }
 373
 374 #f5# Grep in history
 375   greph () { history 0 | grep $1 }
 376   # use colors when GNU grep with color-support
 377   #a2# Execute \kbd{grep -{}-color=auto}
 378   (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
 379   #a2# Execute \kbd{grep -i -{}-color=auto}
 380   alias GREP='grep -i --color=auto'
 381
 382 # one blank line between each line
 383   if [ -r ~/.terminfo/m/mostlike ] ; then
 384 #     alias man2='MANPAGER="sed -e G |less" TERMINFO=~/.terminfo TERM=mostlike /usr/bin/man'
 385      #f5# Watch manpages in a stretched style
 386      man2() { PAGER='dash -c "sed G | /usr/bin/less"' TERM=mostlike /usr/bin/man "$@" ; }
 387   fi
 388
 389 # jump between directories
 390 # Copyright 2005 Nikolai Weibull <nikolai@bitwi.se>
 391 # notice: option AUTO_PUSHD has to be set
 392   #f5# Jump between directories
 393   d(){
 394     emulate -L zsh
 395     autoload -U colors
 396     local color=$fg_bold[blue]
 397     integer i=0
 398     dirs -p | while read dir; do
 399       local num="${$(printf "%-4d " $i)/ /.}"
 400       printf " %s  $color%s$reset_color\n" $num $dir
 401       (( i++ ))
 402     done
 403     integer dir=-1
 404     read -r 'dir?Jump to directory: ' || return
 405     (( dir == -1 )) && return
 406     if (( dir < 0 || dir >= i )); then
 407       echo d: no such directory stack entry: $dir
 408       return 1
 409     fi
 410     cd ~$dir
 411   }
 412
 413 # usage example: 'lcheck strcpy'
 414 #f5# Find out which libs define a symbol
 415   lcheck() {
 416      if [ -n "$1" ] ; then
 417         nm -go /usr/lib/lib*.a 2>/dev/null | grep ":[[:xdigit:]]\{8\} . .*$1"
 418       else
 419         echo "Usage: lcheck <function>" >&2
 420      fi
 421   }
 422
 423 #f5# Clean up directory - remove well known tempfiles
 424   purge() {
 425         FILES=(*~(N) .*~(N) \#*\#(N) *.o(N) a.out(N) *.core(N) *.cmo(N) *.cmi(N) .*.swp(N))
 426         NBFILES=${#FILES}
 427         if [[ $NBFILES > 0 ]]; then
 428                 print $FILES
 429                 local ans
 430                 echo -n "Remove these files? [y/n] "
 431                 read -q ans
 432                 if [[ $ans == "y" ]]
 433                 then
 434                         rm ${FILES}
 435                         echo ">> $PWD purged, $NBFILES files removed"
 436                 else
 437                         echo "Ok. .. than not.."
 438                 fi
 439         fi
 440    }
 441
 442 # Translate DE<=>EN
 443 # 'translate' looks up fot a word in a file with language-to-language
 444 # translations (field separator should be " : "). A typical wordlist looks
 445 # like at follows:
 446 #  | english-word : german-transmission
 447 # It's also only possible to translate english to german but not reciprocal.
 448 # Use the following oneliner to turn back the sort order:
 449 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
 450 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
 451 #f5# Translates a word
 452   trans() {
 453         case "$1" in
 454                 -[dD]*) translate -l de-en $2
 455                 ;;
 456                 -[eE]*) translate -l en-de $2
 457                 ;;
 458                 *)
 459                 echo "Usage: $0 { -D | -E }"
 460                 echo "         -D == German to English"
 461                 echo "         -E == English to German"
 462         esac
 463   }
 464
 465 # Some quick Perl-hacks aka /useful/ oneliner
 466 #  bew() { perl -le 'print unpack "B*","'$1'"' }
 467 #  web() { perl -le 'print pack "B*","'$1'"' }
 468 #  hew() { perl -le 'print unpack "H*","'$1'"' }
 469 #  weh() { perl -le 'print pack "H*","'$1'"' }
 470 #  pversion()    { perl -M$1 -le "print $1->VERSION" } # i. e."pversion LWP -> 5.79"
 471 #  getlinks ()   { perl -ne 'while ( m/"((www|ftp|http):\/\/.*?)"/gc ) { print $1, "\n"; }' $* }
 472 #  gethrefs ()   { perl -ne 'while ( m/href="([^"]*)"/gc ) { print $1, "\n"; }' $* }
 473 #  getanames ()  { perl -ne 'while ( m/a name="([^"]*)"/gc ) { print $1, "\n"; }' $* }
 474 #  getforms ()   { perl -ne 'while ( m:(\</?(input|form|select|option).*?\>):gic ) { print $1, "\n"; }' $* }
 475 #  getstrings () { perl -ne 'while ( m/"(.*?)"/gc ) { print $1, "\n"; }' $*}
 476 #  getanchors () { perl -ne 'while ( m/«([^«»\n]+)»/gc ) { print $1, "\n"; }' $* }
 477 #  showINC ()    { perl -e 'for (@INC) { printf "%d %s\n", $i++, $_ }' }
 478 #  vimpm ()      { vim `perldoc -l $1 | sed -e 's/pod$/pm/'` }
 479 #  vimhelp ()    { vim -c "help $1" -c on -c "au! VimEnter *" }
 480
 481 #f5# List all occurrences of programm in current PATH
 482   plap() {
 483         if [[ $# = 0 ]]
 484         then
 485                 echo "Usage:    $0 program"
 486                 echo "Example:  $0 zsh"
 487                 echo "Lists all occurrences of program in the current PATH."
 488         else
 489                 ls -l ${^path}/*$1*(*N)
 490         fi
 491   }
 492
 493 # Found in the mailinglistarchive from Zsh (IIRC ~1996)
 494 #f5# Select items for specific command(s) from history
 495   selhist() {
 496         emulate -L zsh
 497         local TAB=$'\t';
 498         (( $# < 1 )) && {
 499                 echo "Usage: $0 command"
 500                 return 1
 501         };
 502         cmd=(${(f)"$(grep -w $1 $HISTFILE | sort | uniq | pr -tn)"})
 503         print -l $cmd | less -F
 504         echo -n "enter number of desired command [1 - $(( ${#cmd[@]} - 1 ))]: "
 505         local answer
 506         read answer
 507         print -z "${cmd[$answer]#*$TAB}"
 508   }
 509
 510 # Use vim to convert plaintext to HTML
 511   #f5# Transform files to html with highlighting
 512   2html() { vim -u NONE -n -c ':syntax on' -c ':so $VIMRUNTIME/syntax/2html.vim' -c ':wqa' $1 &>/dev/null }
 513
 514 # Usage: simple-extract <file>
 515 #f5# Smart archive extractor
 516   simple-extract () {
 517         if [[ -f $1 ]]
 518         then
 519                 case $1 in
 520                         *.tar.bz2)  bzip2 -v -d $1      ;;
 521                         *.tar.gz)   tar -xvzf $1        ;;
 522                         *.rar)      unrar $1            ;;
 523                         *.deb)      ar -x $1            ;;
 524                         *.bz2)      bzip2 -d $1         ;;
 525                         *.lzh)      lha x $1            ;;
 526                         *.gz)       gunzip -d $1        ;;
 527                         *.tar)      tar -xvf $1         ;;
 528                         *.tgz)      gunzip -d $1        ;;
 529                         *.tbz2)     tar -jxvf $1        ;;
 530                         *.zip)      unzip $1            ;;
 531                         *.Z)        uncompress $1       ;;
 532                         *)          echo "'$1' Error. Please go away" ;;
 533                 esac
 534         else
 535                 echo "'$1' is not a valid file"
 536         fi
 537   }
 538
 539 # Usage: smartcompress <file> (<type>)
 540 #f5# Smart archive creator
 541   smartcompress() {
 542         if [ $2 ]; then
 543                 case $2 in
 544                         tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
 545                         tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
 546                         tar.Z)          tar -Zcvf$1.$2 $1 ;;
 547                         tar)            tar -cvf$1.$2  $1 ;;
 548                         gz | gzip)      gzip           $1 ;;
 549                         bz2 | bzip2)    bzip2          $1 ;;
 550                         *)
 551                         echo "Error: $2 is not a valid compression type"
 552                         ;;
 553                 esac
 554         else
 555                 smartcompress $1 tar.gz
 556         fi
 557   }
 558
 559 # Usage: show-archive <archive>
 560 #f5# List an archive's content
 561   show-archive() {
 562         if [[ -f $1 ]]
 563         then
 564                 case $1 in
 565                         *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
 566                         *.tar)         tar -tf $1 ;;
 567                         *.tgz)         tar -ztf $1 ;;
 568                         *.zip)         unzip -l $1 ;;
 569                         *.bz2)         bzless $1 ;;
 570                         *)             echo "'$1' Error. Please go away" ;;
 571                 esac
 572         else
 573                 echo "'$1' is not a valid archive"
 574         fi
 575   }
 576
 577 #f5# Follow symlinks
 578   folsym() {
 579     if [[ -e $1 || -h $1 ]]; then
 580         file=$1
 581     else
 582         file=`which $1`
 583     fi
 584     if [[ -e $file || -L $file ]]; then
 585         if [[ -L $file ]]; then
 586             echo `ls -ld $file | perl -ane 'print $F[7]'` '->'
 587             folsym `perl -le '$file = $ARGV[0];
 588                               $dest = readlink $file;
 589                               if ($dest !~ m{^/}) {
 590                                   $file =~ s{(/?)[^/]*$}{$1$dest};
 591                               } else {
 592                                   $file = $dest;
 593                               }
 594                               $file =~ s{/{2,}}{/}g;
 595                               while ($file =~ s{[^/]+/\.\./}{}) {
 596                                   ;
 597                               }
 598                               $file =~ s{^(/\.\.)+}{};
 599                               print $file' $file`
 600         else
 601             ls -d $file
 602         fi
 603     else
 604         echo $file
 605     fi
 606   }
 607
 608 # It's shameless stolen from <http://www.vim.org/tips/tip.php?tip_id=167>
 609 #f5# Use \kbd{vim} as your manpage reader
 610   vman() { man $* | col -b | view -c 'set ft=man nomod nolist' - }
 611
 612 # function readme() { $PAGER -- (#ia3)readme* }
 613 #f5# View all README-like files in current directory in pager
 614   readme() {
 615         local files
 616         files=(./(#i)*(read*me|lue*m(in|)ut)*(ND))
 617         if (($#files))
 618         then $PAGER $files
 619         else
 620                 print 'No README files.'
 621         fi
 622   }
 623
 624 # suidfind() { ls -latg $path | grep '^...s' }
 625 #f5# Find all files in \$PATH with setuid bit set
 626   suidfind() { ls -latg $path/*(sN) }
 627
 628 # See above but this is /better/ ... anywise ..
 629   findsuid() {
 630     print 'Output will be written to ~/suid_* ...'
 631     $SUDO find / -type f \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suidfiles.`date "+%Y-%m-%d"`.out 2>&1
 632     $SUDO find / -type d \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suiddirs.`date "+%Y-%m-%d"`.out 2>&1
 633     $SUDO find / -type f \( -perm -2 -o -perm -20 \) -ls > ~/suid_writefiles.`date "+%Y-%m-%d"`.out 2>&1
 634     $SUDO find / -type d \( -perm -2 -o -perm -20 \) -ls > ~/suid_writedirs.`date "+%Y-%m-%d"`.out 2>&1
 635     print 'Finished'
 636   }
 637
 638 #f5# Reload given functions
 639   refunc() {
 640         for func in $argv
 641         do
 642                 unfunction $func
 643                 autoload $func
 644         done
 645   }
 646
 647 # a small check to see which DIR is located on which server/partition.
 648 # stolen and modified from Sven's zshrc.forall
 649   #f5# Report diskusage of a directory
 650   dirspace() {
 651     if [ -n "$1" ] ; then
 652        for dir in $* ; do
 653           if [ -d "$dir" ] ; then
 654              ( cd $dir; echo "-<$dir>"; du -shx .; echo);
 655           else
 656              echo "warning: $dir does not exist" >&2
 657           fi
 658        done
 659     else
 660         for dir in $path; do
 661           if [ -d "$dir" ] ; then
 662              ( cd $dir; echo "-<$dir>"; du -shx .; echo);
 663           else
 664              echo "warning: $dir does not exist" >&2
 665           fi
 666         done
 667     fi
 668   }
 669
 670 # % slow_print `cat /etc/passwd`
 671 #f5# Slowly print out parameters
 672   slow_print() {
 673         for argument in "${@}"
 674         do
 675                 for ((i = 1; i <= ${#1} ;i++)) {
 676                         print -n "${argument[i]}"
 677                         sleep 0.08
 678                 }
 679                 print -n " "
 680         done
 681         print ""
 682   }
 683
 684 #f5# Show some status info
 685   status() {
 686         print ""
 687         print "Date..: "$(date "+%Y-%m-%d %H:%M:%S")""
 688         print "Shell.: Zsh $ZSH_VERSION (PID = $$, $SHLVL nests)"
 689         print "Term..: $TTY ($TERM), $BAUD bauds, $COLUMNS x $LINES cars"
 690         print "Login.: $LOGNAME (UID = $EUID) on $HOST"
 691         print "System: $(cat /etc/[A-Za-z]*[_-][rv]e[lr]*)"
 692         print "Uptime:$(uptime)"
 693         print ""
 694   }
 695
 696 # Rip an audio CD
 697   #f5# Rip an audio CD
 698   audiorip() {
 699         mkdir -p ~/ripps
 700         cd ~/ripps
 701         cdrdao read-cd --device $DEVICE --driver generic-mmc audiocd.toc
 702         cdrdao read-cddb --device $DEVICE --driver generic-mmc audiocd.toc
 703         echo " * Would you like to burn the cd now? (yes/no)"
 704         read input
 705         if
 706                 [ "$input" = "yes" ]; then
 707                 echo " ! Burning Audio CD"
 708                 audioburn
 709                 echo " * done."
 710         else
 711                 echo " ! Invalid response."
 712         fi
 713   }
 714
 715 # and burn it
 716   #f5# Burn an audio CD (in combination with audiorip)
 717   audioburn() {
 718         cd ~/ripps
 719         cdrdao write --device $DEVICE --driver generic-mmc audiocd.toc
 720         echo " * Should I remove the temporary files? (yes/no)"
 721         read input
 722         if [ "$input" = "yes" ]; then
 723                 echo " ! Removing Temporary Files."
 724                 cd ~
 725                 rm -rf ~/ripps
 726                 echo " * done."
 727         else
 728                 echo " ! Invalid response."
 729         fi
 730   }
 731
 732 #f5# Make an audio CD from all mp3 files
 733   mkaudiocd() {
 734         cd ~/ripps
 735         for i in *.[Mm][Pp]3; do mv "$i" `echo $i | tr '[A-Z]' '[a-z]'`; done
 736         for i in *.mp3; do mv "$i" `echo $i | tr ' ' '_'`; done
 737         for i in *.mp3; do mpg123 -w `basename $i .mp3`.wav $i; done
 738         normalize -m *.wav
 739         for i in *.wav; do sox $i.wav -r 44100 $i.wav resample; done
 740   }
 741
 742 #f5# Create an ISO image. You are prompted for\\&\quad volume name, filename and directory
 743   mkiso() {
 744         echo " * Volume name "
 745         read volume
 746         echo " * ISO Name (ie. tmp.iso)"
 747         read iso
 748         echo " * Directory or File"
 749         read files
 750         mkisofs -o ~/$iso -A $volume -allow-multidot -J -R -iso-level 3 -V $volume -R $files
 751   }
 752
 753 #f5# Simple thumbnails generator
 754   genthumbs () {
 755     rm -rf thumb-* index.html
 756     echo "
 757 <html>
 758   <head>
 759     <title>Images</title>
 760   </head>
 761   <body>" > index.html
 762     for f in *.(gif|jpeg|jpg|png)
 763     do
 764         convert -size 100x200 "$f" -resize 100x200 thumb-"$f"
 765         echo "    <a href=\"$f\"><img src=\"thumb-$f\"></a>" >> index.html
 766     done
 767     echo "
 768   </body>
 769 </html>" >> index.html
 770   }
 771
 772 #f5# Set all ulimit parameters to \kbd{unlimited}
 773   allulimit() {
 774     ulimit -c unlimited
 775     ulimit -d unlimited
 776     ulimit -f unlimited
 777     ulimit -l unlimited
 778     ulimit -n unlimited
 779     ulimit -s unlimited
 780     ulimit -t unlimited
 781   }
 782
 783 # ogg2mp3 with bitrate of 192
 784   ogg2mp3_192() {
 785     oggdec -o - ${1} | lame -b 192 - ${1:r}.mp3
 786   }
 787
 788 #f5# RFC 2396 URL encoding in Z-Shell
 789   urlencode() {
 790    setopt localoptions extendedglob
 791    input=( ${(s::)1} )
 792    print ${(j::)input/(#b)([^A-Za-z0-9_.!~*\'\(\)-])/%$(([##16]#match))}
 793   }
 794
 795 #f5# Install x-lite (VoIP software)
 796   getxlite() {
 797     setopt local_options
 798     setopt errreturn
 799     [ -d ~/tmp ] || mkdir ~/tmp
 800     cd ~/tmp
 801     echo "Downloading http://www.counterpath.com/download/X-Lite_Install.tar.gz and storing it in ~/tmp:"
 802     if wget http://www.counterpath.com/download/X-Lite_Install.tar.gz ; then
 803        unp X-Lite_Install.tar.gz && echo done || echo failed
 804     else
 805        echo "Error while downloading." ; return 1
 806     fi
 807     if [ -x xten-xlite/xtensoftphone ] ; then
 808        echo "Execute xten-xlite/xtensoftphone to start xlite."
 809     fi
 810    }
 811
 812 #f5# Install skype
 813   getskype() {
 814     setopt local_options
 815     setopt errreturn
 816     echo "Downloading debian package of skype."
 817     echo "Notice: If you want to use a more recent skype version run 'getskypebeta'."
 818     wget http://www.skype.com/go/getskype-linux-deb
 819     $SUDO dpkg -i skype_debian-*.deb && echo "skype installed."
 820   }
 821
 822 #f5# Install beta-version of skype
 823   getskypebeta() {
 824     setopt local_options
 825     setopt errreturn
 826     echo "Downloading debian package of skype (beta version)."
 827     wget http://www.skype.com/go/getskype-linux-beta-deb
 828     $SUDO dpkg -i skype-beta*.deb && echo "skype installed."
 829   }
 830
 831 #f5# Install gizmo (VoIP software)
 832   getgizmo() {
 833     setopt local_options
 834     setopt errreturn
 835     echo "gconf2-common and libgconf2-4 have to be available. Installing therefor."
 836     $SUDO apt-get update
 837     $SUDO apt-get install gconf2-common libgconf2-4
 838     wget $(lynx --dump http://www.gizmoproject.com/download-linux.html | awk '/\.deb/ {print $2" "}' | tr -d '\n')
 839     $SUDO dpkg -i libsipphoneapi*.deb bonjour_*.deb gizmo-*.deb && echo "gizmo installed."
 840   }
 841
 842 #f5# Get and run AIR (Automated Image and Restore)
 843   getair() {
 844     setopt local_options
 845     setopt errreturn
 846     [ -w . ] || { echo 'Error: you do not have write permissions in this directory. Exiting.' ; return 1 }
 847     local VER='1.2.8'
 848     wget http://puzzle.dl.sourceforge.net/sourceforge/air-imager/air-$VER.tar.gz
 849     tar zxf air-$VER.tar.gz
 850     cd air-$VER
 851     INTERACTIVE=no $SUDO ./install-air-1.2.8
 852     [ -x /usr/local/bin/air ] && [ -n "$DISPLAY" ] && $SUDO air
 853   }
 854
 855 #f5# Get specific git commitdiff
 856   git-get-diff() {
 857     if [ -z $GITTREE ] ; then
 858       GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
 859     fi
 860     if ! [ -z $1 ] ; then
 861      ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commitdiff;h=$1"
 862     else
 863       echo "Usage: git-get-diff <commit>"
 864     fi
 865   }
 866
 867 #f5# Get specific git commit
 868   git-get-commit() {
 869     if [ -z $GITTREE ] ; then
 870       GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
 871     fi
 872     if ! [ -z $1 ] ; then
 873      ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commit;h=$1"
 874     else
 875       echo "Usage: git-get-commit <commit>"
 876     fi
 877   }
 878
 879 #f5# Get specific git diff
 880   git-get-plaindiff() {
 881     if [ -z $GITTREE ] ; then
 882       GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
 883     fi
 884     if ! [ -z $1 ] ; then
 885       wget "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O $1.diff
 886     else
 887       echo 'Usage: git-get-plaindiff '
 888     fi
 889   }
 890
 891 # http://strcat.de/blog/index.php?/archives/335-Software-sauber-deinstallieren...html
 892 #f5# Log 'make install' output
 893   mmake() {
 894     [[ ! -d ~/.errorlogs ]] && mkdir ~/.errorlogs
 895     =make -n install > ~/.errorlogs/${PWD##*/}-makelog
 896   }
 897
 898 #f5# Indent source code
 899   smart-indent() {
 900     indent -npro -kr -i8 -ts8 -sob -l80 -ss -ncs $*
 901   }
 902
 903 # highlight important stuff in diff output, usage example: hg diff | hidiff
 904   #m# a2 hidiff \kbd{histring} oneliner for diffs
 905   [ -x $(which histring) ] && \
 906   alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
 907
 908 # rename pictures based on information found in exif headers
 909   #f5# Rename pictures based on information found in exif headers
 910   exirename() {
 911     if [ $# -lt 1 ] ; then
 912        echo 'Usage: jpgrename $FILES' >& 2
 913        return 1
 914     else
 915        echo -n 'Checking for jhead with version newer than 1.9: '
 916        jhead_version=`jhead -h | grep 'used by most Digital Cameras.  v.*' | awk '{print $6}' | tr -d v`
 917        if [[ $jhead_version > '1.9' ]]; then
 918           echo 'success - now running jhead.'
 919           jhead -n%Y-%m-%d_%Hh%M_%f $*
 920        else
 921           echo 'failed - exiting.'
 922        fi
 923     fi
 924   }
 925
 926 # open file in vim and jump to line
 927 # http://www.downgra.de/archives/2007/05/08/T19_21_11/
 928   j2v() {
 929     local -a params
 930     params=(${*//(#m):[0-9]*:/\\n+${MATCH//:/}}) # replace ':23:' to '\n+23'
 931     params=(${(s|\n|)${(j|\n|)params}}) # join array using '\n', then split on all '\n'
 932     vim ${params}
 933   }
 934
 935 # get_ic() - queries imap servers for capabilities; real simple. no imaps
 936   ic_get() {
 937     local port
 938     if [[ ! -z $1 ]]; then
 939       port=${2:-143}
 940       print "querying imap server on $1:${port}...\n";
 941       print "a1 capability\na2 logout\n" | nc $1 ${port}
 942     else
 943       print "usage:\n  $0 <imap-server> [port]"
 944     fi
 945   }
 946
 947 # creates a Maildir/ with its {new,cur,tmp} subdirs
 948   mkmaildir() {
 949     local root subdir
 950     root=${MAILDIR_ROOT:-${HOME}/Mail}
 951     if [[ -z ${1} ]] ; then print "Usage:\n $0 <dirname>" ; return 1 ; fi
 952     subdir=${1}
 953     mkdir -p ${root}/${subdir}/{cur,new,tmp}
 954   }
 955
 956 # xtrename() rename xterm from within GNU-screen
 957   xtrename() {
 958     if [[ -z ${DISPLAY} ]] ; then
 959       printf 'xtrename only makes sense in X11.\n'
 960       return 1
 961     fi
 962     if [[ -z ${1} ]] ; then
 963       printf 'usage: xtrename() "title for xterm"\n'
 964       printf '  renames the title of xterm from _within_ screen.\n'
 965       printf '  Also works without screen.\n'
 966       return 0
 967     fi
 968     print -n "\eP\e]0;${1}\C-G\e\\"
 969     return 0
 970   }
 971
 972 # hl() highlighted less
 973 # http://ft.bewatermyfriend.org/comp/data/zsh/zfunct.html
 974   if [ -x $(which highlight) ] ; then
 975     function hl() {
 976       local theme lang
 977       theme=${HL_THEME:-""}
 978       case ${1} in
 979         (-l|--list)
 980           ( printf 'available languages (syntax parameter):\n\n' ;
 981             highlight --list-langs ; ) | less -SMr
 982           ;;
 983         (-t|--themes)
 984           ( printf 'available themes (style parameter):\n\n' ;
 985             highlight --list-themes ; ) | less -SMr
 986           ;;
 987         (-h|--help)
 988           printf 'usage: hl <syntax[:theme]> <file>\n'
 989           printf '    available options: --list (-l), --themes (-t), --help (-h)\n\n'
 990           printf '  Example: hl c main.c\n'
 991           ;;
 992         (*)
 993           if [[ -z ${2} ]] || (( ${#argv} > 2 )) ; then
 994             printf 'usage: hl <syntax[:theme]> <file>\n'
 995             printf '    available options: --list (-l), --themes (-t), --help (-h)\n'
 996             (( ${#argv} > 2 )) && printf '  Too many arguments.\n'
 997             return 1
 998           fi
 999           lang=${1%:*}
1000           [[ ${1} == *:* ]] && [[ -n ${1#*:} ]] && theme=${1#*:}
1001           if [[ -n ${theme} ]] ; then
1002             highlight --xterm256 --syntax ${lang} --style ${theme} ${2} | less -SMr
1003           else
1004             highlight --ansi --syntax ${lang} ${2} | less -SMr
1005           fi
1006           ;;
1007       esac
1008       return 0
1009     }
1010     # ... and a proper completion for hl()
1011     # needs 'highlight' as well, so it fits fine in here.
1012     function _hl_genarg()  {
1013       local expl
1014       if [[ -prefix 1 *: ]] ; then
1015         local themes
1016         themes=(${${${(f)"$(LC_ALL=C highlight --list-themes)"}/ #/}:#*(Installed|Use name)*})
1017         compset -P 1 '*:'
1018         _wanted -C list themes expl theme compadd ${themes}
1019       else
1020         local langs
1021         langs=(${${${(f)"$(LC_ALL=C highlight --list-langs)"}/ #/}:#*(Installed|Use name)*})
1022         _wanted -C list languages expl languages compadd -S ':' -q ${langs}
1023       fi
1024     }
1025     function _hl_complete() {
1026       _arguments -s '1: :_hl_genarg' '2:files:_path_files'
1027     }
1028     compdef _hl_complete hl
1029   fi
1030
1031 # create small urls via tinyurl.com using wget, grep and sed
1032   zurl() {
1033   [[ -z ${1} ]] && print "please give an url to shrink." && return 1
1034   local url=${1}
1035   local tiny="http://tinyurl.com/create.php?url="
1036   #print "${tiny}${url}" ; return
1037   wget  -O-             \
1038         -o/dev/null     \
1039         "${tiny}${url}" \
1040     | grep -Eio 'value="(http://tinyurl.com/.*)"' \
1041     | sed 's/value=//;s/"//g'
1042 }
1043
1044 # change fluxbox keys from 'Alt-#' to 'Alt-F#' and vice versa
1045   fluxkey-change() {
1046     [ -n "$FLUXKEYS" ] || local FLUXKEYS="$HOME/.fluxbox/keys"
1047     if ! [ -r "$FLUXKEYS" ] ; then
1048        echo "Sorry, \$FLUXKEYS file $FLUXKEYS could not be read - nothing to be done."
1049        return 1
1050     else
1051        if grep -q 'Mod1 F[0-9] :Workspace [0-9]' $FLUXKEYS ; then
1052           echo -n 'Switching to Alt-# mode in ~/.fluxbox/keys: '
1053           sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)F\([0-9]\+[: space :]\+:Workspace.*\)|\1\2|' $FLUXKEYS && echo done || echo failed
1054        elif grep -q 'Mod1 [0-9] :Workspace [0-9]' $FLUXKEYS ; then
1055           echo -n 'Switching to Alt-F# mode in ~/.fluxbox/keys: '
1056           sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)\([0-9]\+[: space :]\+:Workspace.*\)|\1F\2|' $FLUXKEYS && echo done || echo failed
1057        else
1058           echo 'Sorry, do not know what to do.'
1059           return 1
1060        fi
1061     fi
1062   }
1063
1064 # }}}
1065
1066 # mercurial related stuff {{{
1067   if type -p hg &>/dev/null ; then
1068   # gnu like diff for mercurial
1069   # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
1070     #f5# GNU like diff for mercurial
1071     hgdi() {
1072       for i in `hg status -marn "$@"` ; diff -ubwd <(hg cat "$i") "$i"
1073     }
1074
1075   # build debian package
1076     #a2# Alias for \kbd{hg-buildpackage}
1077     alias hbp='hg-buildpackage'
1078
1079   # execute commands on the versioned patch-queue from the current repos
1080     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
1081
1082   # diffstat for specific version of a mercurial repository
1083   #   hgstat      => display diffstat between last revision and tip
1084   #   hgstat 1234 => display diffstat between revision 1234 and tip
1085     #f5# Diffstat for specific version of a mercurial repos
1086     hgstat() {
1087       [ -n "$1" ] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
1088     }
1089
1090   # get current mercurial tip via hg itself
1091     #f5# Get current mercurial tip via hg itself
1092     gethgclone() {
1093       setopt local_options
1094       setopt errreturn
1095       if [ -f mercurial-tree/.hg ] ; then
1096         cd mercurial-tree
1097         echo "Running hg pull for retreiving latest version..."
1098         hg pull
1099         echo "Finished update. Building mercurial"
1100         make local
1101         echo "Setting \$PATH to $PWD:\$PATH..."
1102         export PATH="$PWD:$PATH"
1103       else
1104         echo "Downloading mercurial via hg"
1105         hg clone http://selenic.com/repo/hg mercurial-tree
1106         cd mercurial-tree
1107         echo "Building mercurial"
1108         make local
1109         echo "Setting \$PATH to $PWD:\$PATH..."
1110         export PATH="$PWD:$PATH"
1111         echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
1112         # echo "Setting \$PYTHONPATH to PYTHONPATH=\${HOME}/lib/python,"
1113         # export PYTHONPATH=${HOME}/lib/python
1114       fi
1115     }
1116
1117   fi # end of check whether we have the 'hg'-executable
1118
1119   # get current mercurial snapshot
1120     #f5# Get current mercurial snapshot
1121     gethgsnap() {
1122       setopt local_options
1123       setopt errreturn
1124       if [ -f mercurial-snapshot.tar.gz ] ; then
1125          echo "mercurial-snapshot.tar.gz exists already, skipping download."
1126       else
1127         echo "Downloading mercurial snapshot"
1128         wget http://www.selenic.com/mercurial/mercurial-snapshot.tar.gz
1129       fi
1130       echo "Unpacking mercurial-snapshot.tar.gz"
1131       tar zxf mercurial-snapshot.tar.gz
1132       cd mercurial-snapshot/
1133       echo "Installing required build-dependencies"
1134       $SUDO apt-get update
1135       $SUDO apt-get install python2.4-dev
1136       echo "Building mercurial"
1137       make local
1138       echo "Setting \$PATH to $PWD:\$PATH..."
1139       export PATH="$PWD:$PATH"
1140       echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
1141     }
1142 # }}}
1143
1144 # some useful commands often hard to remember - let's grep for them {{{
1145
1146 # Work around ion/xterm resize bug.
1147 #if [ "$SHLVL" = 1 ]; then
1148 #       if [ -x $(which resize) ]; then
1149 #               eval `resize </dev/null`
1150 #       fi
1151 #fi
1152
1153 # enable jackd:
1154 #  /usr/bin/jackd -dalsa -dhw:0 -r48000 -p1024 -n2
1155 # now play audio file:
1156 #  alsaplayer -o jack foobar.mp3
1157
1158 # send files via netcat
1159 # on sending side:
1160 #  send() {j=$*; tar cpz ${j/%${!#}/}|nc -w 1 ${!#} 51330;}
1161 #  send dir* $HOST
1162 #  alias receive='nc -vlp 51330 | tar xzvp'
1163
1164 # debian stuff:
1165 # dh_make -e foo@localhost -f $1
1166 # dpkg-buildpackage -rfakeroot
1167 # lintian *.deb
1168 # dpkg-scanpackages ./ /dev/null | gzip > Packages.gz
1169 # dpkg-scansources . | gzip > Sources.gz
1170 # grep-dctrl --field Maintainer $* /var/lib/apt/lists/*
1171
1172 # other stuff:
1173 # convert -geometry 200x200 -interlace LINE -verbose
1174 # ldapsearch -x -b "OU=Bedienstete,O=tug" -h ldap.tugraz.at sn=$1
1175 # ps -ao user,pcpu,start,command
1176 # gpg --keyserver blackhole.pca.dfn.de --recv-keys
1177 # xterm -bg black -fg yellow -fn -misc-fixed-medium-r-normal--14-140-75-75-c-90-iso8859-15 -ah
1178 # nc -vz $1 1-1024   # portscan via netcat
1179 # wget --mirror --no-parent --convert-links
1180 # pal -d `date +%d`
1181 # autoload -U tetris; zle -N tetris; bindkey '...' ; echo "press ... for playing tennis"
1182 #
1183 # modify console cursor
1184 # see http://www.tldp.org/HOWTO/Framebuffer-HOWTO-5.html
1185 # print $'\e[?96;0;64c'
1186 # }}}
1187
1188 # finally source a local zshrc and grmlsmall-specific configuration {{{
1189
1190 # The following file is used to remove zsh-config-items that do not work
1191 # in grml-small by default.
1192 # If you do not want these adjustments (for whatever reason),
1193 # there are three ways to accomplish that:
1194 #  a) at the beginning of this file (variables section), set
1195 #     $GRMLSMALL_SPECIFIC to 0 or comment out the variable definition.
1196 #  b) remove/rename .zshrc.grmlsmall
1197 #  c) comment out the following line
1198   (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall && source ~/.zshrc.grmlsmall
1199
1200 # this allows us to stay in sync with /etc/skel/.zshrc
1201 # through 'ln -s /etc/skel/.zshrc ~/.zshrc' and put own
1202 # modifications in ~/.zshrc.local
1203   if [ -r ~/.zshrc.local ] ; then
1204      . ~/.zshrc.local
1205   fi
1206 # }}}
1207
1208 ### doc strings for external functions from files
1209 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
1210 ## END OF FILE #################################################################
1211 # vim:foldmethod=marker