etc/skel/.zshrc

   1 # Filename:      .zshrc
   2 # Purpose:       config file for zsh
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 # Latest change: Son Dez 09 22:58:07 CET 2007 [mika]
   7 ################################################################################
   8
   9 # source ~/.zshrc.global {{{
  10
  11 # see /etc/zsh/zshrc for some general settings
  12 # If you don't have write permissions to /etc/zsh/zshrc on your own
  13 # copy the file to your $HOME as /.zshrc.global and we source it:
  14
  15 # Note, that xsource() is defined in the global file, so here,
  16 # we will have to do the sourcing manually for once:
  17
  18 [[ -z "$ZSHRC_GLOBAL_HAS_BEEN_READ" ]]  \
  19 && [[ -r "${HOME}/.zshrc.global" ]]     \
  20 && source "${HOME}/.zshrc.global"
  21 # }}}
  22
  23 # check whether global file has been read {{{
  24 if [[ -z "$ZSHRC_GLOBAL_HAS_BEEN_READ" ]] ; then
  25     print 'Warning: global zsh config has not been read.' >&2
  26     print '         prepare for possible errors!'         >&2
  27 fi
  28 # }}}
  29
  30 # autoloading stuff {{{
  31 # associate types and extensions (be aware with perl scripts and anwanted behaviour!)
  32 #  check_com zsh-mime-setup || { autoload zsh-mime-setup && zsh-mime-setup }
  33 #  alias -s pl='perl -S'
  34 # }}}
  35
  36 # completion system {{{
  37 # just make sure it is loaded in this file too
  38 check_com compinit || { autoload -U compinit && compinit }
  39 # }}}
  40
  41 # make sure isgrmlsmall is defined {{{
  42 check_com isgrmlsmall || function isgrmlsmall () { return 1 }
  43 # }}}
  44
  45 ## variables {{{
  46
  47 # do you want grmlsmall-specific adjustments?
  48 GRMLSMALL_SPECIFIC=1
  49
  50 # set terminal property (used e.g. by msgid-chooser)
  51 export COLORTERM="yes"
  52
  53 # set default browser
  54 if [[ -z "$BROWSER" ]] ; then
  55     if [[ -n "$DISPLAY" ]] ; then
  56         #v# If X11 is running
  57         check_com -c firefox && export BROWSER=firefox
  58     else
  59         #v# If no X11 is running
  60         check_com -c w3m && export BROWSER=w3m
  61     fi
  62 fi
  63 #v#
  64 (( ${+PAGER} )) || export PAGER="less"
  65
  66 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
  67 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
  68 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
  69
  70 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
  71 #v# [for non-root only]
  72 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
  73 # }}}
  74
  75 ## set options {{{
  76
  77 # Allow comments even in interactive shells i. e.
  78 # $ uname # This command prints system informations
  79 # zsh: bad pattern: #
  80 # $ setopt interactivecomments
  81 # $ uname # This command prints system informations
  82 # Linux
  83 #  setopt interactivecomments
  84
  85 # ctrl-s will no longer freeze the terminal.
  86 #  stty erase "^?"
  87
  88 # }}}
  89
  90 # {{{ global aliases
  91 # These do not have to be at the beginning of the command line.
  92 # Avoid typing cd ../../ for going two dirs down and so on
  93 # Usage, e.g.: "$ cd ...' or just '$ ...' with 'setopt auto_cd'
  94 # Notice: deactivated by 061112 by default, we use another approach
  95 # known as "power completion / abbreviation expansion"
  96 #  alias -g '...'='../..'
  97 #  alias -g '....'='../../..'
  98 #  alias -g BG='& exit'
  99 #  alias -g C='|wc -l'
 100 #  alias -g G='|grep'
 101 #  alias -g H='|head'
 102 #  alias -g Hl=' --help |& less -r'
 103 #  alias -g K='|keep'
 104 #  alias -g L='|less'
 105 #  alias -g LL='|& less -r'
 106 #  alias -g M='|most'
 107 #  alias -g N='&>/dev/null'
 108 #  alias -g R='| tr A-z N-za-m'
 109 #  alias -g SL='| sort | less'
 110 #  alias -g S='| sort'
 111 #  alias -g T='|tail'
 112 #  alias -g V='| vim -'
 113 # }}}
 114
 115 ## aliases {{{
 116
 117 # Xterm resizing-fu.
 118 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
 119 alias hide='echo -en "\033]50;nil2\007"'
 120 alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
 121 alias small='echo -en "\033]50;6x10\007"'
 122 alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
 123 alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
 124 alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
 125 alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
 126 alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
 127 alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
 128 #  if [[ "$TERM" == "xterm" ]] && [[ "$LINES" -ge 50 ]] && [[ "$COLUMNS" -ge 100 ]] && [[ -z "$SSH_CONNECTION" ]] ; then
 129 #          large
 130 #  fi
 131
 132 # general
 133 #a2# Execute \kbd{du -sch}
 134 alias da='du -sch'
 135 #a2# Execute \kbd{jobs -l}
 136 alias j='jobs -l'
 137 #  alias u='translate -i'          # translate
 138
 139 # compile stuff
 140 #a2# Execute \kbd{./configure}
 141 alias CO="./configure"
 142 #a2# Execute \kbd{./configure --help}
 143 alias CH="./configure --help"
 144
 145 # http://conkeror.mozdev.org/
 146 #a2# Run a keyboard driven firefox
 147 alias conkeror='firefox -chrome chrome://conkeror/content'
 148
 149 # arch/tla stuff
 150 if check_com -c tla ; then
 151     #a2# Execute \kbd{tla what-changed --diffs | less}
 152     alias tdi='tla what-changed --diffs | less'
 153     #a2# Execute \kbd{tla-buildpackage}
 154     alias tbp='tla-buildpackage'
 155     #a2# Execute \kbd{tla archive-mirror}
 156     alias tmi='tla archive-mirror'
 157     #a2# Execute \kbd{tla commit}
 158     alias tco='tla commit'
 159     #a2# Execute \kbd{tla star-merge}
 160     alias tme='tla star-merge'
 161 fi
 162
 163 # listing stuff
 164 #a2# Execute \kbd{ls -lSrah}
 165 alias dir="ls -lSrah"
 166 #a2# Only show dot-directories
 167 alias lad='ls -d .*(/)'                # only show dot-directories
 168 #a2# Only show dot-files
 169 alias lsa='ls -a .*(.)'                # only show dot-files
 170 #a2# Only files with setgid/setuid/sticky flag
 171 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
 172 #a2# Only show 1st ten symlinks
 173 alias lsl='ls -l *(@[1,10])'           # only symlinks
 174 #a2# Display only executables
 175 alias lsx='ls -l *(*[1,10])'           # only executables
 176 #a2# Display world-{readable,writable,executable} files
 177 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
 178 #a2# Display the ten biggest files
 179 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
 180 #a2# Only show directories
 181 alias lsd='ls -d *(/)'                 # only show directories
 182 #a2# Only show empty directories
 183 alias lse='ls -d *(/^F)'               # only show empty directories
 184 #a2# Display the ten newest files
 185 alias lsnew="ls -rl *(D.om[1,10])"     # display the newest files
 186 #a2# Display the ten oldest files
 187 alias lsold="ls -rtlh *(D.om[1,10])"   # display the oldest files
 188 #a2# Display the ten smallest files
 189 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
 190
 191 # chmod
 192 #a2# Execute \kbd{chmod 600}
 193 alias rw-='chmod 600'
 194 #a2# Execute \kbd{chmod 700}
 195 alias rwx='chmod 700'
 196 #m# a2 r-{}- Execute \kbd{chmod 644}
 197 alias r--='chmod 644'
 198 #a2# Execute \kbd{chmod 755}
 199 alias r-x='chmod 755'
 200
 201 # some useful aliases
 202 #a2# Execute \kbd{mkdir -o}
 203 alias md='mkdir -p'
 204
 205 check_com -c ipython && alias ips='ipython -p sh'
 206
 207 # console stuff
 208 #a2# Execute \kbd{mplayer -vo fbdev}
 209 alias cmplayer='mplayer -vo fbdev'
 210 #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
 211 alias fbmplayer='mplayer -vo fbdev -fs -zoom'
 212 #a2# Execute \kbd{links2 -driver fb}
 213 alias fblinks='links2 -driver fb'
 214
 215 # ignore ~/.ssh/known_hosts entries
 216 #  alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null" -o "PreferredAuthentications=keyboard-interactive"'
 217 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
 218 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 219 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 220
 221 # Use 'g' instead of 'git':
 222 check_com g || alias g='git'
 223
 224 # use colors when browsing man pages, but only if not using LESS_TERMCAP_* from /etc/zsh/zshenv:
 225 if [[ -z "$LESS_TERMCAP_md" ]] ; then
 226     [[ -d ~/.terminfo/ ]] && alias man='TERMINFO=~/.terminfo/ LESS=C TERM=mostlike PAGER=less man'
 227 fi
 228
 229 # check whether Debian's package management (dpkg) is running
 230 if check_com salias ; then
 231     #a2# Check whether a dpkg instance is currently running
 232     salias check_dpkg_running="dpkg_running"
 233 fi
 234
 235 # work around non utf8 capable software in utf environment via $LANG and luit
 236 if check_com isutfenv && check_com luit ; then
 237     if check_com -c mrxvt ; then
 238         isutfenv && [[ -n "$LANG" ]] && \
 239             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
 240     fi
 241
 242     if check_com -c aterm ; then
 243         isutfenv && [[ -n "$LANG" ]] && \
 244             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
 245     fi
 246
 247     if check_com -c centericq ; then
 248         isutfenv && [[ -n "$LANG" ]] && \
 249             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
 250     fi
 251 fi
 252 # }}}
 253
 254 ## useful functions {{{
 255
 256 # searching
 257 #f4# Search for newspostings from authors
 258 agoogle() { ${=BROWSER} "http://groups.google.com/groups?as_uauthors=$*" ; }
 259 #f4# Search Debian Bug Tracking System by BugID in mbox format
 260 debbug()  {
 261     setopt localoptions extendedglob
 262     if [[ $# -eq 1 ]]; then
 263         case "$1" in
 264             ([0-9]##)
 265             ${=BROWSER} "http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=$1"
 266             ;;
 267             (*@*)
 268             ${=BROWSER} "http://bugs.debian.org/cgi-bin/pkgreport.cgi?submitter=$1"
 269             ;;
 270             (*)
 271             ${=BROWSER} "http://bugs.debian.org/$*"
 272             ;;
 273         esac
 274     else
 275         print "$0 needs one argument"
 276     fi
 277 }
 278 #f4# Search Debian Bug Tracking System
 279 debbugm() { bts show --mbox $1 } # provide bugnummer as "$1"
 280 #f4# Search DMOZ
 281 dmoz()    { ${=BROWSER} http://search.dmoz.org/cgi-bin/search\?search=${1// /_} }
 282 #f4# Search German   Wiktionary
 283 dwicti()  { ${=BROWSER} http://de.wiktionary.org/wiki/${(C)1// /_} }
 284 #f4# Search English  Wiktionary
 285 ewicti()  { ${=BROWSER} http://en.wiktionary.org/wiki/${(C)1// /_} }
 286 #f4# Search Google Groups
 287 ggogle()  { ${=BROWSER} "http://groups.google.com/groups?q=$*" }
 288 #f4# Search Google
 289 google()  { ${=BROWSER} "http://www.google.com/search?&num=100&q=$*" }
 290 #f4# Search Google Groups for MsgID
 291 mggogle() { ${=BROWSER} "http://groups.google.com/groups?selm=$*" }
 292 #f4# Search Netcraft
 293 netcraft(){ ${=BROWSER} "http://toolbar.netcraft.com/site_report?url=$1" }
 294 #f4# Use German Wikipedia's full text search
 295 swiki()   { ${=BROWSER} http://de.wikipedia.org/wiki/Spezial:Search/${(C)1} }
 296 #f4# search \kbd{dict.leo.org}
 297 oleo()    { ${=BROWSER} "http://dict.leo.org/?search=$*" }
 298 #f4# Search German   Wikipedia
 299 wikide()  { ${=BROWSER} http://de.wikipedia.org/wiki/"${(C)*}" }
 300 #f4# Search English  Wikipedia
 301 wikien()  { ${=BROWSER} http://en.wikipedia.org/wiki/"${(C)*}" }
 302 #f4# Search official debs
 303 wodeb()   { ${=BROWSER} "http://packages.debian.org/search?keywords=$1&searchon=contents&suite=${2:=unstable}&section=all" }
 304
 305 #m# f4 gex() Exact search via Google
 306 check_com google && gex () { google "\"[ $1]\" $*" } # exact search at google
 307
 308 # misc
 309 #f5# Backup \kbd{file {\rm to} file\_timestamp}
 310 bk()      { cp -b ${1} ${1}_`date --iso-8601=m` }
 311 #f5# Copied diff
 312 cdiff()   { diff -crd "$*" | egrep -v "^Only in |^Binary files " }
 313 #f5# cd to directoy and list files
 314 cl()      { cd $1 && ls -a }        # cd && ls
 315 #f5# Cvs add
 316 cvsa()    { cvs add $* && cvs com -m 'initial checkin' $* }
 317 #f5# Cvs diff
 318 cvsd()    { cvs diff -N $* |& $PAGER }
 319 #f5# Cvs log
 320 cvsl()    { cvs log $* |& $PAGER }
 321 #f5# Cvs update
 322 cvsq()    { cvs -nq update }
 323 #f5# Rcs2log
 324 cvsr()    { rcs2log $* | $PAGER }
 325 #f5# Cvs status
 326 cvss()    { cvs status -v $* }
 327 #f5# Disassemble source files using gcc and as
 328 disassemble(){ gcc -pipe -S -o - -O -g $* | as -aldh -o /dev/null }
 329 #f5# Firefox remote control - open given URL
 330 fir()     { firefox -a firefox -remote "openURL($1)" }
 331 #f5# Create Directoy and \kbd{cd} to it
 332 mcd()     { mkdir -p "$@"; cd "$@" } # mkdir && cd
 333 #f5# Unified diff to timestamped outputfile
 334 mdiff()   { diff -udrP "$1" "$2" > diff.`date "+%Y-%m-%d"`."$1" }
 335 #f5# Memory overview
 336 memusage(){ ps aux | awk '{if (NR > 1) print $5; if (NR > 2) print "+"} END { print "p" }' | dc }
 337 #f5# Show contents of tar file
 338 shtar()   { gunzip -c $1 | tar -tf - -- | $PAGER }
 339 #f5# Show contents of tgz file
 340 shtgz()   { tar -ztf $1 | $PAGER }
 341 #f5# Show contents of zip file
 342 shzip()   { unzip -l $1 | $PAGER }
 343 #f5# Greps signature from file
 344 sig()     { agrep -d '^-- $' "$*" ~/.Signature }
 345 #f5# Unified diff
 346 udiff()   { diff -urd $* | egrep -v "^Only in |^Binary files " }
 347 #f5# (Mis)use \kbd{vim} as \kbd{less}
 348 viless()  { vim --cmd 'let no_plugin_maps = 1' -c "so \$VIMRUNTIME/macros/less.vim" "${@:--}" }
 349
 350 # download video from youtube
 351 ytdl() {
 352     if ! [[ -n "$2" ]] ; then
 353         print "Usage: ydtl http://youtube.com/watch?v=.... outputfile.flv">&2
 354         return 1
 355     else
 356         wget -O${2} "http://youtube.com/get_video?"${${${"$(wget -o/dev/null -O- "${1}" | grep -e watch_fullscreen)"}##*watch_fullscreen\?}%%\&fs=*}
 357     fi
 358 }
 359
 360
 361 # Function Usage: doc packagename
 362 #f5# \kbd{cd} to /usr/share/doc/\textit{package}
 363 doc() { cd /usr/share/doc/$1 && ls }
 364 _doc() { _files -W /usr/share/doc -/ }
 365 check_com compdef && compdef _doc doc
 366
 367 #f5# Make screenshot
 368 sshot() {
 369     [[ ! -d ~/shots  ]] && mkdir ~/shots
 370     #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
 371     cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
 372 }
 373
 374 # list images only
 375 limg() {
 376     local -a images
 377     images=( *.{jpg,gif,png}(.N) )
 378
 379     if [[ $#images -eq 0 ]] ; then
 380         print "No image files found"
 381     else
 382         ls "$@" "$images[@]"
 383     fi
 384 }
 385
 386 #f5# Create PDF file from source code
 387 makereadable() {
 388     output=$1
 389     shift
 390     a2ps --medium A4dj -E -o $output $*
 391     ps2pdf $output
 392 }
 393
 394 # zsh with perl-regex - use it e.g. via:
 395 # regcheck '\s\d\.\d{3}\.\d{3} Euro' ' 1.000.000 Euro'
 396 #f5# Checks whether a regex matches or not.\\&\quad Example: \kbd{regcheck '.\{3\} EUR' '500 EUR'}
 397 regcheck() {
 398     zmodload -i zsh/pcre
 399     pcre_compile $1 && \
 400     pcre_match $2 && echo "regex matches" || echo "regex does not match"
 401 }
 402
 403 #f5# List files which have been modified within the last {\it n} days
 404 new() { print -l *(m-$1) }
 405
 406 #f5# Grep in history
 407 greph() { history 0 | grep $1 }
 408 # use colors when GNU grep with color-support
 409 #a2# Execute \kbd{grep -{}-color=auto}
 410 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
 411 #a2# Execute \kbd{grep -i -{}-color=auto}
 412 alias GREP='grep -i --color=auto'
 413
 414 # one blank line between each line
 415 if [[ -r ~/.terminfo/m/mostlike ]] ; then
 416 #   alias man2='MANPAGER="sed -e G |less" TERMINFO=~/.terminfo TERM=mostlike /usr/bin/man'
 417     #f5# Watch manpages in a stretched style
 418     man2() { PAGER='dash -c "sed G | /usr/bin/less"' TERM=mostlike /usr/bin/man "$@" ; }
 419 fi
 420
 421 # d():Copyright 2005 Nikolai Weibull <nikolai@bitwi.se>
 422 # notice: option AUTO_PUSHD has to be set
 423 #f5# Jump between directories
 424 d() {
 425     emulate -L zsh
 426     autoload -U colors
 427     local color=$fg_bold[blue]
 428     integer i=0
 429     dirs -p | while read dir; do
 430         local num="${$(printf "%-4d " $i)/ /.}"
 431         printf " %s  $color%s$reset_color\n" $num $dir
 432         (( i++ ))
 433     done
 434     integer dir=-1
 435     read -r 'dir?Jump to directory: ' || return
 436     (( dir == -1 )) && return
 437     if (( dir < 0 || dir >= i )); then
 438         echo d: no such directory stack entry: $dir
 439         return 1
 440     fi
 441     cd ~$dir
 442 }
 443
 444 # usage example: 'lcheck strcpy'
 445 #f5# Find out which libs define a symbol
 446 lcheck() {
 447     if [[ -n "$1" ]] ; then
 448         nm -go /usr/lib/lib*.a 2>/dev/null | grep ":[[:xdigit:]]\{8\} . .*$1"
 449     else
 450         echo "Usage: lcheck <function>" >&2
 451     fi
 452 }
 453
 454 #f5# Clean up directory - remove well known tempfiles
 455 purge() {
 456     FILES=(*~(N) .*~(N) \#*\#(N) *.o(N) a.out(N) *.core(N) *.cmo(N) *.cmi(N) .*.swp(N))
 457     NBFILES=${#FILES}
 458     if [[ $NBFILES > 0 ]] ; then
 459         print $FILES
 460         local ans
 461         echo -n "Remove these files? [y/n] "
 462         read -q ans
 463         if [[ $ans == "y" ]] ; then
 464             rm ${FILES}
 465             echo ">> $PWD purged, $NBFILES files removed"
 466         else
 467             echo "Ok. .. than not.."
 468         fi
 469     fi
 470 }
 471
 472 # Translate DE<=>EN
 473 # 'translate' looks up fot a word in a file with language-to-language
 474 # translations (field separator should be " : "). A typical wordlist looks
 475 # like at follows:
 476 #  | english-word : german-transmission
 477 # It's also only possible to translate english to german but not reciprocal.
 478 # Use the following oneliner to turn back the sort order:
 479 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
 480 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
 481 #f5# Translates a word
 482 trans() {
 483     case "$1" in
 484         -[dD]*)
 485             translate -l de-en $2
 486             ;;
 487         -[eE]*)
 488             translate -l en-de $2
 489             ;;
 490         *)
 491             echo "Usage: $0 { -D | -E }"
 492             echo "         -D == German to English"
 493             echo "         -E == English to German"
 494     esac
 495 }
 496
 497 # Some quick Perl-hacks aka /useful/ oneliner
 498 #  bew() { perl -le 'print unpack "B*","'$1'"' }
 499 #  web() { perl -le 'print pack "B*","'$1'"' }
 500 #  hew() { perl -le 'print unpack "H*","'$1'"' }
 501 #  weh() { perl -le 'print pack "H*","'$1'"' }
 502 #  pversion()    { perl -M$1 -le "print $1->VERSION" } # i. e."pversion LWP -> 5.79"
 503 #  getlinks ()   { perl -ne 'while ( m/"((www|ftp|http):\/\/.*?)"/gc ) { print $1, "\n"; }' $* }
 504 #  gethrefs ()   { perl -ne 'while ( m/href="([^"]*)"/gc ) { print $1, "\n"; }' $* }
 505 #  getanames ()  { perl -ne 'while ( m/a name="([^"]*)"/gc ) { print $1, "\n"; }' $* }
 506 #  getforms ()   { perl -ne 'while ( m:(\</?(input|form|select|option).*?\>):gic ) { print $1, "\n"; }' $* }
 507 #  getstrings () { perl -ne 'while ( m/"(.*?)"/gc ) { print $1, "\n"; }' $*}
 508 #  getanchors () { perl -ne 'while ( m/«([^«»\n]+)»/gc ) { print $1, "\n"; }' $* }
 509 #  showINC ()    { perl -e 'for (@INC) { printf "%d %s\n", $i++, $_ }' }
 510 #  vimpm ()      { vim `perldoc -l $1 | sed -e 's/pod$/pm/'` }
 511 #  vimhelp ()    { vim -c "help $1" -c on -c "au! VimEnter *" }
 512
 513 #f5# List all occurrences of programm in current PATH
 514 plap() {
 515     if [[ $# = 0 ]] ; then
 516         echo "Usage:    $0 program"
 517         echo "Example:  $0 zsh"
 518         echo "Lists all occurrences of program in the current PATH."
 519     else
 520         ls -l ${^path}/*$1*(*N)
 521     fi
 522 }
 523
 524 # Found in the mailinglistarchive from Zsh (IIRC ~1996)
 525 #f5# Select items for specific command(s) from history
 526 selhist() {
 527     emulate -L zsh
 528     local TAB=$'\t';
 529     (( $# < 1 )) && {
 530         echo "Usage: $0 command"
 531         return 1
 532     };
 533     cmd=(${(f)"$(grep -w $1 $HISTFILE | sort | uniq | pr -tn)"})
 534     print -l $cmd | less -F
 535     echo -n "enter number of desired command [1 - $(( ${#cmd[@]} - 1 ))]: "
 536     local answer
 537     read answer
 538     print -z "${cmd[$answer]#*$TAB}"
 539 }
 540
 541 # Use vim to convert plaintext to HTML
 542 #f5# Transform files to html with highlighting
 543 2html() { vim -u NONE -n -c ':syntax on' -c ':so $VIMRUNTIME/syntax/2html.vim' -c ':wqa' $1 &>/dev/null }
 544
 545 # Usage: simple-extract <file>
 546 #f5# Smart archive extractor
 547 simple-extract () {
 548     if [[ -f $1 ]] ; then
 549         case $1 in
 550             *.tar.bz2)  bzip2 -v -d $1      ;;
 551             *.tar.gz)   tar -xvzf $1        ;;
 552             *.rar)      unrar $1            ;;
 553             *.deb)      ar -x $1            ;;
 554             *.bz2)      bzip2 -d $1         ;;
 555             *.lzh)      lha x $1            ;;
 556             *.gz)       gunzip -d $1        ;;
 557             *.tar)      tar -xvf $1         ;;
 558             *.tgz)      gunzip -d $1        ;;
 559             *.tbz2)     tar -jxvf $1        ;;
 560             *.zip)      unzip $1            ;;
 561             *.Z)        uncompress $1       ;;
 562             *)          echo "'$1' Error. Please go away" ;;
 563         esac
 564     else
 565         echo "'$1' is not a valid file"
 566     fi
 567 }
 568
 569 # Usage: smartcompress <file> (<type>)
 570 #f5# Smart archive creator
 571 smartcompress() {
 572     if [[ -n $2 ]] ; then
 573         case $2 in
 574             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
 575             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
 576             tar.Z)          tar -Zcvf$1.$2 $1 ;;
 577             tar)            tar -cvf$1.$2  $1 ;;
 578             gz | gzip)      gzip           $1 ;;
 579             bz2 | bzip2)    bzip2          $1 ;;
 580             *)
 581                 echo "Error: $2 is not a valid compression type"
 582                 ;;
 583         esac
 584     else
 585         smartcompress $1 tar.gz
 586     fi
 587 }
 588
 589 # Usage: show-archive <archive>
 590 #f5# List an archive's content
 591 show-archive() {
 592     if [[ -f $1 ]] ; then
 593         case $1 in
 594             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
 595             *.tar)         tar -tf $1 ;;
 596             *.tgz)         tar -ztf $1 ;;
 597             *.zip)         unzip -l $1 ;;
 598             *.bz2)         bzless $1 ;;
 599             *)             echo "'$1' Error. Please go away" ;;
 600         esac
 601     else
 602         echo "'$1' is not a valid archive"
 603     fi
 604 }
 605
 606 # TODO: isn't ssl() like this, but clean?
 607 #       I'd like to remove this, it's a gross hack, IMHO -ft
 608 #f5# Follow symlinks
 609 folsym() {
 610     if [[ -e $1 || -h $1 ]] ; then
 611         file=$1
 612     else
 613         file=`which $1`
 614     fi
 615     if [[ -e $file || -L $file ]] ; then
 616         if [[ -L $file ]] ; then
 617             echo `ls -ld $file | perl -ane 'print $F[7]'` '->'
 618             folsym `perl -le '$file = $ARGV[0];
 619                               $dest = readlink $file;
 620                               if ($dest !~ m{^/}) {
 621                                   $file =~ s{(/?)[^/]*$}{$1$dest};
 622                               } else {
 623                                   $file = $dest;
 624                               }
 625                               $file =~ s{/{2,}}{/}g;
 626                               while ($file =~ s{[^/]+/\.\./}{}) {
 627                                   ;
 628                               }
 629                               $file =~ s{^(/\.\.)+}{};
 630                               print $file' $file`
 631         else
 632             ls -d $file
 633         fi
 634     else
 635         echo $file
 636     fi
 637 }
 638
 639 # It's shameless stolen from <http://www.vim.org/tips/tip.php?tip_id=167>
 640 #f5# Use \kbd{vim} as your manpage reader
 641 vman() { man $* | col -b | view -c 'set ft=man nomod nolist' - }
 642
 643 # function readme() { $PAGER -- (#ia3)readme* }
 644 #f5# View all README-like files in current directory in pager
 645 readme() {
 646     local files
 647     files=(./(#i)*(read*me|lue*m(in|)ut)*(ND))
 648     if (($#files)) ; then
 649         $PAGER $files
 650     else
 651         print 'No README files.'
 652     fi
 653 }
 654
 655 # suidfind() { ls -latg $path | grep '^...s' }
 656 #f5# Find all files in \$PATH with setuid bit set
 657 suidfind() { ls -latg $path/*(sN) }
 658
 659 # See above but this is /better/ ... anywise ..
 660 findsuid() {
 661     print 'Output will be written to ~/suid_* ...'
 662     $SUDO find / -type f \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suidfiles.`date "+%Y-%m-%d"`.out 2>&1
 663     $SUDO find / -type d \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suiddirs.`date "+%Y-%m-%d"`.out 2>&1
 664     $SUDO find / -type f \( -perm -2 -o -perm -20 \) -ls > ~/suid_writefiles.`date "+%Y-%m-%d"`.out 2>&1
 665     $SUDO find / -type d \( -perm -2 -o -perm -20 \) -ls > ~/suid_writedirs.`date "+%Y-%m-%d"`.out 2>&1
 666     print 'Finished'
 667 }
 668
 669 #f5# Reload given functions
 670 refunc() {
 671     for func in $argv ; do
 672         unfunction $func
 673         autoload $func
 674     done
 675 }
 676
 677 # a small check to see which DIR is located on which server/partition.
 678 # stolen and modified from Sven's zshrc.forall
 679 #f5# Report diskusage of a directory
 680 dirspace() {
 681     if [[ -n "$1" ]] ; then
 682         for dir in $* ; do
 683             if [[ -d "$dir" ]] ; then
 684                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
 685             else
 686                 echo "warning: $dir does not exist" >&2
 687             fi
 688         done
 689     else
 690         for dir in $path; do
 691             if [[ -d "$dir" ]] ; then
 692                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
 693             else
 694                 echo "warning: $dir does not exist" >&2
 695             fi
 696         done
 697     fi
 698 }
 699
 700 # % slow_print `cat /etc/passwd`
 701 #f5# Slowly print out parameters
 702 slow_print() {
 703     for argument in "${@}" ; do
 704         for ((i = 1; i <= ${#1} ;i++)) ; do
 705             print -n "${argument[i]}"
 706             sleep 0.08
 707         done
 708         print -n " "
 709     done
 710     print ""
 711 }
 712
 713 #f5# Show some status info
 714 status() {
 715     print ""
 716     print "Date..: "$(date "+%Y-%m-%d %H:%M:%S")""
 717     print "Shell.: Zsh $ZSH_VERSION (PID = $$, $SHLVL nests)"
 718     print "Term..: $TTY ($TERM), $BAUD bauds, $COLUMNS x $LINES cars"
 719     print "Login.: $LOGNAME (UID = $EUID) on $HOST"
 720     print "System: $(cat /etc/[A-Za-z]*[_-][rv]e[lr]*)"
 721     print "Uptime:$(uptime)"
 722     print ""
 723 }
 724
 725 # Rip an audio CD
 726 #f5# Rip an audio CD
 727 audiorip() {
 728     mkdir -p ~/ripps
 729     cd ~/ripps
 730     cdrdao read-cd --device $DEVICE --driver generic-mmc audiocd.toc
 731     cdrdao read-cddb --device $DEVICE --driver generic-mmc audiocd.toc
 732     echo " * Would you like to burn the cd now? (yes/no)"
 733     read input
 734     if [[ "$input" = "yes" ]] ; then
 735         echo " ! Burning Audio CD"
 736         audioburn
 737         echo " * done."
 738     else
 739         echo " ! Invalid response."
 740     fi
 741 }
 742
 743 # and burn it
 744 #f5# Burn an audio CD (in combination with audiorip)
 745 audioburn() {
 746     cd ~/ripps
 747     cdrdao write --device $DEVICE --driver generic-mmc audiocd.toc
 748     echo " * Should I remove the temporary files? (yes/no)"
 749     read input
 750     if [[ "$input" = "yes" ]] ; then
 751         echo " ! Removing Temporary Files."
 752         cd ~
 753         rm -rf ~/ripps
 754         echo " * done."
 755     else
 756         echo " ! Invalid response."
 757     fi
 758 }
 759
 760 #f5# Make an audio CD from all mp3 files
 761 mkaudiocd() {
 762     # TODO: do the renaming more zshish, possibly with zmv()
 763     cd ~/ripps
 764     for i in *.[Mm][Pp]3; do mv "$i" `echo $i | tr '[A-Z]' '[a-z]'`; done
 765     for i in *.mp3; do mv "$i" `echo $i | tr ' ' '_'`; done
 766     for i in *.mp3; do mpg123 -w `basename $i .mp3`.wav $i; done
 767     normalize -m *.wav
 768     for i in *.wav; do sox $i.wav -r 44100 $i.wav resample; done
 769 }
 770
 771 #f5# Create an ISO image. You are prompted for\\&\quad volume name, filename and directory
 772 mkiso() {
 773     echo " * Volume name "
 774     read volume
 775     echo " * ISO Name (ie. tmp.iso)"
 776     read iso
 777     echo " * Directory or File"
 778     read files
 779     mkisofs -o ~/$iso -A $volume -allow-multidot -J -R -iso-level 3 -V $volume -R $files
 780 }
 781
 782 #f5# Simple thumbnails generator
 783 genthumbs() {
 784     rm -rf thumb-* index.html
 785     echo "
 786 <html>
 787   <head>
 788     <title>Images</title>
 789   </head>
 790   <body>" > index.html
 791     for f in *.(gif|jpeg|jpg|png) ; do
 792         convert -size 100x200 "$f" -resize 100x200 thumb-"$f"
 793         echo "    <a href=\"$f\"><img src=\"thumb-$f\"></a>" >> index.html
 794     done
 795     echo "
 796   </body>
 797 </html>" >> index.html
 798 }
 799
 800 #f5# Set all ulimit parameters to \kbd{unlimited}
 801 allulimit() {
 802     ulimit -c unlimited
 803     ulimit -d unlimited
 804     ulimit -f unlimited
 805     ulimit -l unlimited
 806     ulimit -n unlimited
 807     ulimit -s unlimited
 808     ulimit -t unlimited
 809 }
 810
 811 # ogg2mp3 with bitrate of 192
 812 ogg2mp3_192() {
 813     oggdec -o - ${1} | lame -b 192 - ${1:r}.mp3
 814 }
 815
 816 #f5# RFC 2396 URL encoding in Z-Shell
 817 urlencode() {
 818     setopt localoptions extendedglob
 819     input=( ${(s::)1} )
 820     print ${(j::)input/(#b)([^A-Za-z0-9_.!~*\'\(\)-])/%$(([##16]#match))}
 821 }
 822
 823 #f5# Install x-lite (VoIP software)
 824 getxlite() {
 825     setopt local_options
 826     setopt errreturn
 827     [[ -d ~/tmp ]] || mkdir ~/tmp
 828     cd ~/tmp
 829
 830     echo "Downloading http://www.counterpath.com/download/X-Lite_Install.tar.gz and storing it in ~/tmp:"
 831     if wget http://www.counterpath.com/download/X-Lite_Install.tar.gz ; then
 832         unp X-Lite_Install.tar.gz && echo done || echo failed
 833     else
 834         echo "Error while downloading." ; return 1
 835     fi
 836
 837     if [[ -x xten-xlite/xtensoftphone ]] ; then
 838         echo "Execute xten-xlite/xtensoftphone to start xlite."
 839     fi
 840 }
 841
 842 #f5# Install skype
 843 getskype() {
 844     setopt local_options
 845     setopt errreturn
 846     echo "Downloading debian package of skype."
 847     echo "Notice: If you want to use a more recent skype version run 'getskypebeta'."
 848     wget http://www.skype.com/go/getskype-linux-deb
 849     $SUDO dpkg -i skype*.deb && echo "skype installed."
 850 }
 851
 852 #f5# Install beta-version of skype
 853 getskypebeta() {
 854     setopt local_options
 855     setopt errreturn
 856     echo "Downloading debian package of skype (beta version)."
 857     wget http://www.skype.com/go/getskype-linux-beta-deb
 858     $SUDO dpkg -i skype-beta*.deb && echo "skype installed."
 859 }
 860
 861 #f5# Install gizmo (VoIP software)
 862 getgizmo() {
 863     setopt local_options
 864     setopt errreturn
 865     echo "gconf2-common and libgconf2-4 have to be available. Installing therefor."
 866     $SUDO apt-get update
 867     $SUDO apt-get install gconf2-common libgconf2-4
 868     wget $(lynx --dump http://www.gizmoproject.com/download-linux.html | awk '/\.deb/ {print $2" "}' | tr -d '\n')
 869     $SUDO dpkg -i libsipphoneapi*.deb bonjour_*.deb gizmo-*.deb && echo "gizmo installed."
 870 }
 871
 872 #f5# Get and run AIR (Automated Image and Restore)
 873 getair() {
 874     setopt local_options
 875     setopt errreturn
 876     [[ -w . ]] || { echo 'Error: you do not have write permissions in this directory. Exiting.' ; return 1 }
 877     local VER='1.2.8'
 878     wget http://puzzle.dl.sourceforge.net/sourceforge/air-imager/air-$VER.tar.gz
 879     tar zxf air-$VER.tar.gz
 880     cd air-$VER
 881     INTERACTIVE=no $SUDO ./install-air-1.2.8
 882     [[ -x /usr/local/bin/air ]] && [[ -n "$DISPLAY" ]] && $SUDO air
 883 }
 884
 885 #f5# Get specific git commitdiff
 886 git-get-diff() {
 887     if [[ -z $GITTREE ]] ; then
 888         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
 889     fi
 890     if ! [[ -z $1 ]] ; then
 891         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commitdiff;h=$1"
 892     else
 893         echo "Usage: git-get-diff <commit>"
 894     fi
 895 }
 896
 897 #f5# Get specific git commit
 898 git-get-commit() {
 899     if [[ -z $GITTREE ]] ; then
 900         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
 901     fi
 902     if ! [[ -z $1 ]] ; then
 903         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commit;h=$1"
 904     else
 905         echo "Usage: git-get-commit <commit>"
 906     fi
 907 }
 908
 909 #f5# Get specific git diff
 910 git-get-plaindiff() {
 911     if [[ -z $GITTREE ]] ; then
 912         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
 913     fi
 914     if ! [[ -z $1 ]] ; then
 915         wget "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O $1.diff
 916     else
 917         echo 'Usage: git-get-plaindiff '
 918     fi
 919 }
 920
 921 # http://strcat.de/blog/index.php?/archives/335-Software-sauber-deinstallieren...html
 922 #f5# Log 'make install' output
 923 mmake() {
 924     [[ ! -d ~/.errorlogs ]] && mkdir ~/.errorlogs
 925     make -n install > ~/.errorlogs/${PWD##*/}-makelog
 926 }
 927
 928 #f5# Indent source code
 929 smart-indent() {
 930     indent -npro -kr -i8 -ts8 -sob -l80 -ss -ncs $*
 931 }
 932
 933 # highlight important stuff in diff output, usage example: hg diff | hidiff
 934 #m# a2 hidiff \kbd{histring} oneliner for diffs
 935 check_com -c histring && \
 936     alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
 937
 938 # rename pictures based on information found in exif headers
 939 #f5# Rename pictures based on information found in exif headers
 940 exirename() {
 941     if [[ $# -lt 1 ]] ; then
 942         echo 'Usage: jpgrename $FILES' >& 2
 943         return 1
 944     else
 945         echo -n 'Checking for jhead with version newer than 1.9: '
 946         jhead_version=`jhead -h | grep 'used by most Digital Cameras.  v.*' | awk '{print $6}' | tr -d v`
 947         if [[ $jhead_version > '1.9' ]]; then
 948             echo 'success - now running jhead.'
 949             jhead -n%Y-%m-%d_%Hh%M_%f $*
 950         else
 951             echo 'failed - exiting.'
 952         fi
 953     fi
 954 }
 955
 956 # open file in vim and jump to line
 957 # http://www.downgra.de/archives/2007/05/08/T19_21_11/
 958 j2v() {
 959     local -a params
 960     params=(${*//(#m):[0-9]*:/\\n+${MATCH//:/}}) # replace ':23:' to '\n+23'
 961     params=(${(s|\n|)${(j|\n|)params}}) # join array using '\n', then split on all '\n'
 962     vim ${params}
 963 }
 964
 965 # get_ic() - queries imap servers for capabilities; real simple. no imaps
 966 ic_get() {
 967     local port
 968     if [[ ! -z $1 ]] ; then
 969         port=${2:-143}
 970         print "querying imap server on $1:${port}...\n";
 971         print "a1 capability\na2 logout\n" | nc $1 ${port}
 972     else
 973         print "usage:\n  $0 <imap-server> [port]"
 974     fi
 975 }
 976
 977 # creates a Maildir/ with its {new,cur,tmp} subdirs
 978 mkmaildir() {
 979     local root subdir
 980     root=${MAILDIR_ROOT:-${HOME}/Mail}
 981     if [[ -z ${1} ]] ; then print "Usage:\n $0 <dirname>" ; return 1 ; fi
 982     subdir=${1}
 983     mkdir -p ${root}/${subdir}/{cur,new,tmp}
 984 }
 985
 986 # xtrename() rename xterm from within GNU-screen
 987 xtrename() {
 988     if [[ -z ${DISPLAY} ]] ; then
 989         printf 'xtrename only makes sense in X11.\n'
 990         return 1
 991     fi
 992     if [[ -z ${1} ]] ; then
 993         printf 'usage: xtrename() "title for xterm"\n'
 994         printf '  renames the title of xterm from _within_ screen.\n'
 995         printf '  Also works without screen.\n'
 996         return 0
 997     fi
 998     print -n "\eP\e]0;${1}\C-G\e\\"
 999     return 0
1000 }
1001
1002 # hl() highlighted less
1003 # http://ft.bewatermyfriend.org/comp/data/zsh/zfunct.html
1004 if check_com -c highlight ; then
1005     function hl() {
1006         local theme lang
1007         theme=${HL_THEME:-""}
1008         case ${1} in
1009             (-l|--list)
1010                 ( printf 'available languages (syntax parameter):\n\n' ;
1011                     highlight --list-langs ; ) | less -SMr
1012                 ;;
1013             (-t|--themes)
1014                 ( printf 'available themes (style parameter):\n\n' ;
1015                     highlight --list-themes ; ) | less -SMr
1016                 ;;
1017             (-h|--help)
1018                 printf 'usage: hl <syntax[:theme]> <file>\n'
1019                 printf '    available options: --list (-l), --themes (-t), --help (-h)\n\n'
1020                 printf '  Example: hl c main.c\n'
1021                 ;;
1022             (*)
1023                 if [[ -z ${2} ]] || (( ${#argv} > 2 )) ; then
1024                     printf 'usage: hl <syntax[:theme]> <file>\n'
1025                     printf '    available options: --list (-l), --themes (-t), --help (-h)\n'
1026                     (( ${#argv} > 2 )) && printf '  Too many arguments.\n'
1027                     return 1
1028                 fi
1029                 lang=${1%:*}
1030                 [[ ${1} == *:* ]] && [[ -n ${1#*:} ]] && theme=${1#*:}
1031                 if [[ -n ${theme} ]] ; then
1032                     highlight --xterm256 --syntax ${lang} --style ${theme} ${2} | less -SMr
1033                 else
1034                     highlight --ansi --syntax ${lang} ${2} | less -SMr
1035                 fi
1036                 ;;
1037         esac
1038         return 0
1039     }
1040     # ... and a proper completion for hl()
1041     # needs 'highlight' as well, so it fits fine in here.
1042     function _hl_genarg()  {
1043         local expl
1044         if [[ -prefix 1 *: ]] ; then
1045             local themes
1046             themes=(${${${(f)"$(LC_ALL=C highlight --list-themes)"}/ #/}:#*(Installed|Use name)*})
1047             compset -P 1 '*:'
1048             _wanted -C list themes expl theme compadd ${themes}
1049         else
1050             local langs
1051             langs=(${${${(f)"$(LC_ALL=C highlight --list-langs)"}/ #/}:#*(Installed|Use name)*})
1052             _wanted -C list languages expl languages compadd -S ':' -q ${langs}
1053         fi
1054     }
1055     function _hl_complete() {
1056         _arguments -s '1: :_hl_genarg' '2:files:_path_files'
1057     }
1058     compdef _hl_complete hl
1059 fi
1060
1061 # create small urls via tinyurl.com using wget, grep and sed
1062 zurl() {
1063     [[ -z ${1} ]] && print "please give an url to shrink." && return 1
1064     local url=${1}
1065     local tiny="http://tinyurl.com/create.php?url="
1066     #print "${tiny}${url}" ; return
1067     wget  -O-             \
1068           -o/dev/null     \
1069           "${tiny}${url}" \
1070         | grep -Eio 'value="(http://tinyurl.com/.*)"' \
1071         | sed 's/value=//;s/"//g'
1072 }
1073
1074 # change fluxbox keys from 'Alt-#' to 'Alt-F#' and vice versa
1075 fluxkey-change() {
1076     [[ -n "$FLUXKEYS" ]] || local FLUXKEYS="$HOME/.fluxbox/keys"
1077     if ! [[ -r "$FLUXKEYS" ]] ; then
1078         echo "Sorry, \$FLUXKEYS file $FLUXKEYS could not be read - nothing to be done."
1079         return 1
1080     else
1081         if grep -q 'Mod1 F[0-9] :Workspace [0-9]' $FLUXKEYS ; then
1082             echo -n 'Switching to Alt-# mode in ~/.fluxbox/keys: '
1083             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)F\([0-9]\+[: space :]\+:Workspace.*\)|\1\2|' $FLUXKEYS && echo done || echo failed
1084         elif grep -q 'Mod1 [0-9] :Workspace [0-9]' $FLUXKEYS ; then
1085             echo -n 'Switching to Alt-F# mode in ~/.fluxbox/keys: '
1086             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)\([0-9]\+[: space :]\+:Workspace.*\)|\1F\2|' $FLUXKEYS && echo done || echo failed
1087         else
1088             echo 'Sorry, do not know what to do.'
1089             return 1
1090         fi
1091     fi
1092 }
1093
1094 # retrieve weather information on the console
1095 # Usage example: 'weather LOWG'
1096 weather() {
1097     [[ -n "$1" ]] || {
1098         print 'Usage: weather <station_id>' >&2
1099         return 1
1100     }
1101
1102     local PLACE="${1:u}"
1103     local FILE="$HOME/.weather/$PLACE"
1104     local LOG="$HOME/.weather/log"
1105
1106     [[ -d $HOME/.weather ]] || {
1107         print -n "Creating $HOME/.weather: "
1108         mkdir $HOME/.weather
1109         print 'done'
1110     }
1111
1112     print "Retrieving information for ${PLACE}:"
1113     print
1114     wget -T 10 --no-verbose --output-file=$LOG --output-document=$FILE --timestamping http://weather.noaa.gov/pub/data/observations/metar/decoded/$PLACE.TXT
1115
1116     if [[ $? -eq 0 ]] ; then
1117         if [[ -n "$VERBOSE" ]] ; then
1118             cat $FILE
1119         else
1120             DATE=$(grep 'UTC' $FILE | sed 's#.* /##')
1121             TEMPERATURE=$(awk '/Temperature/ { print $4" degree Celcius / " $2" degree Fahrenheit" }' $FILE| tr -d '(')
1122             echo "date: $DATE"
1123             echo "temp:  $TEMPERATURE"
1124         fi
1125     else
1126         print "There was an error retrieving the weather information for $PLACE" >&2
1127         cat $LOG
1128         return 1
1129     fi
1130 }
1131
1132
1133 # }}}
1134
1135 # mercurial related stuff {{{
1136 if check_com -c hg ; then
1137     # gnu like diff for mercurial
1138     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
1139     #f5# GNU like diff for mercurial
1140     hgdi() {
1141         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
1142     }
1143
1144     # build debian package
1145     #a2# Alias for \kbd{hg-buildpackage}
1146     alias hbp='hg-buildpackage'
1147
1148     # execute commands on the versioned patch-queue from the current repos
1149     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
1150
1151     # diffstat for specific version of a mercurial repository
1152     #   hgstat      => display diffstat between last revision and tip
1153     #   hgstat 1234 => display diffstat between revision 1234 and tip
1154     #f5# Diffstat for specific version of a mercurial repos
1155     hgstat() {
1156         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
1157     }
1158
1159     #f5# Get current mercurial tip via hg itself
1160     gethgclone() {
1161         setopt local_options
1162         setopt errreturn
1163         if [[ -f mercurial-tree/.hg ]] ; then
1164             cd mercurial-tree
1165             echo "Running hg pull for retreiving latest version..."
1166             hg pull
1167             echo "Finished update. Building mercurial"
1168             make local
1169             echo "Setting \$PATH to $PWD:\$PATH..."
1170             export PATH="$PWD:$PATH"
1171         else
1172             echo "Downloading mercurial via hg"
1173             hg clone http://selenic.com/repo/hg mercurial-tree
1174             cd mercurial-tree
1175             echo "Building mercurial"
1176             make local
1177             echo "Setting \$PATH to $PWD:\$PATH..."
1178             export PATH="$PWD:$PATH"
1179             echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
1180             # echo "Setting \$PYTHONPATH to PYTHONPATH=\${HOME}/lib/python,"
1181             # export PYTHONPATH=${HOME}/lib/python
1182         fi
1183     }
1184
1185 fi # end of check whether we have the 'hg'-executable
1186
1187 # get current mercurial snapshot
1188 #f5# Get current mercurial snapshot
1189 gethgsnap() {
1190     setopt local_options
1191     setopt errreturn
1192     if [[ -f mercurial-snapshot.tar.gz ]] ; then
1193          echo "mercurial-snapshot.tar.gz exists already, skipping download."
1194     else
1195         echo "Downloading mercurial snapshot"
1196         wget http://www.selenic.com/mercurial/mercurial-snapshot.tar.gz
1197     fi
1198     echo "Unpacking mercurial-snapshot.tar.gz"
1199     tar zxf mercurial-snapshot.tar.gz
1200     cd mercurial-snapshot/
1201     echo "Installing required build-dependencies"
1202     $SUDO apt-get update
1203     $SUDO apt-get install python2.4-dev
1204     echo "Building mercurial"
1205     make local
1206     echo "Setting \$PATH to $PWD:\$PATH..."
1207     export PATH="$PWD:$PATH"
1208     echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
1209 }
1210 # }}}
1211
1212 # some useful commands often hard to remember - let's grep for them {{{
1213
1214 # Work around ion/xterm resize bug.
1215 #if [[ "$SHLVL" -eq 1 ]]; then
1216 #       if check_com -c resize ; then
1217 #               eval `resize </dev/null`
1218 #       fi
1219 #fi
1220
1221 # enable jackd:
1222 #  /usr/bin/jackd -dalsa -dhw:0 -r48000 -p1024 -n2
1223 # now play audio file:
1224 #  alsaplayer -o jack foobar.mp3
1225
1226 # send files via netcat
1227 # on sending side:
1228 #  send() {j=$*; tar cpz ${j/%${!#}/}|nc -w 1 ${!#} 51330;}
1229 #  send dir* $HOST
1230 #  alias receive='nc -vlp 51330 | tar xzvp'
1231
1232 # debian stuff:
1233 # dh_make -e foo@localhost -f $1
1234 # dpkg-buildpackage -rfakeroot
1235 # lintian *.deb
1236 # dpkg-scanpackages ./ /dev/null | gzip > Packages.gz
1237 # dpkg-scansources . | gzip > Sources.gz
1238 # grep-dctrl --field Maintainer $* /var/lib/apt/lists/*
1239
1240 # other stuff:
1241 # convert -geometry 200x200 -interlace LINE -verbose
1242 # ldapsearch -x -b "OU=Bedienstete,O=tug" -h ldap.tugraz.at sn=$1
1243 # ps -ao user,pcpu,start,command
1244 # gpg --keyserver blackhole.pca.dfn.de --recv-keys
1245 # xterm -bg black -fg yellow -fn -misc-fixed-medium-r-normal--14-140-75-75-c-90-iso8859-15 -ah
1246 # nc -vz $1 1-1024   # portscan via netcat
1247 # wget --mirror --no-parent --convert-links
1248 # pal -d `date +%d`
1249 # autoload -U tetris; zle -N tetris; bindkey '...' ; echo "press ... for playing tennis"
1250 #
1251 # modify console cursor
1252 # see http://www.tldp.org/HOWTO/Framebuffer-HOWTO-5.html
1253 # print $'\e[?96;0;64c'
1254 # }}}
1255
1256 # finally source a local zshrc and grmlsmall-specific configuration {{{
1257
1258 # The following file is used to remove zsh-config-items that do not work
1259 # in grml-small by default.
1260 # If you do not want these adjustments (for whatever reason),
1261 # there are three ways to accomplish that:
1262 #  a) at the beginning of this file (variables section), set
1263 #     $GRMLSMALL_SPECIFIC to 0 or comment out the variable definition.
1264 #  b) remove/rename .zshrc.grmlsmall
1265 #  c) comment out the following line
1266 (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall && source ~/.zshrc.grmlsmall
1267
1268 # this allows us to stay in sync with /etc/skel/.zshrc
1269 # through 'ln -s /etc/skel/.zshrc ~/.zshrc' and put own
1270 # modifications in ~/.zshrc.local
1271 xsource "${HOME}/.zshrc.local"
1272
1273 # ...and remove utility functions again.
1274 xunfunction
1275
1276 # }}}
1277
1278 ### doc strings for external functions from files
1279 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
1280 ## END OF FILE #################################################################
1281 # vim:foldmethod=marker autoindent expandtab shiftwidth=4