etc/skel/.zshrc

   1 # Filename:      .zshrc
   2 # Purpose:       config file for zsh
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 # Latest change: Mit Aug 08 21:22:03 CEST 2007 [mika]
   7 ################################################################################
   8
   9 # source ~/.zshrc.global {{{
  10 # see /etc/zsh/zshrc for some general settings
  11 # If you don't have write permissions to /etc/zsh/zshrc on your own
  12 # copy the file to your $HOME as /.zshrc.global and we source it:
  13 xsource "${HOME}/.zshrc.global"
  14 # }}}
  15
  16 # check whether global file has been read {{{
  17 if [[ -z "$ZSHRC_GLOBAL_HAS_BEEN_READ" ]] ; then
  18     print 'Warning: global zsh config has not been read'>&2
  19 fi
  20 # }}}
  21
  22 # autoloading stuff {{{
  23 # associate types and extensions (be aware with perl scripts and anwanted behaviour!)
  24 #  check_com zsh-mime-setup || { autoload zsh-mime-setup && zsh-mime-setup }
  25 #  alias -s pl='perl -S'
  26 # }}}
  27
  28 # completion system {{{
  29 # just make sure it is loaded in this file too
  30 check_com compinit || { autoload -U compinit && compinit }
  31 # }}}
  32
  33 # make sure isgrmlsmall is defined {{{
  34 check_com isgrmlsmall || function isgrmlsmall () { return 1 }
  35 # }}}
  36
  37 ## variables {{{
  38
  39 # do you want grmlsmall-specific adjustments?
  40 GRMLSMALL_SPECIFIC=1
  41
  42 # set terminal property (used e.g. by msgid-chooser)
  43 export COLORTERM="yes"
  44
  45 # set default browser
  46 if [[ -z "$BROWSER" ]] ; then
  47     if [[ -n "$DISPLAY" ]] ; then
  48         #v# If X11 is running
  49         check_com -c firefox && export BROWSER=firefox
  50     else
  51         #v# If no X11 is running
  52         check_com -c w3m && export BROWSER=w3m
  53     fi
  54 fi
  55 #v#
  56 (( ${+PAGER} )) || export PAGER="less"
  57
  58 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
  59 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
  60 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
  61
  62 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
  63 #v# [for non-root only]
  64 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
  65 # }}}
  66
  67 ## set options {{{
  68
  69 # Allow comments even in interactive shells i. e.
  70 # $ uname # This command prints system informations
  71 # zsh: bad pattern: #
  72 # $ setopt interactivecomments
  73 # $ uname # This command prints system informations
  74 # Linux
  75 #  setopt interactivecomments
  76
  77 # ctrl-s will no longer freeze the terminal.
  78 #  stty erase "^?"
  79
  80 # }}}
  81
  82 # {{{ global aliases
  83 # These do not have to be at the beginning of the command line.
  84 # Avoid typing cd ../../ for going two dirs down and so on
  85 # Usage, e.g.: "$ cd ...' or just '$ ...' with 'setopt auto_cd'
  86 # Notice: deactivated by 061112 by default, we use another approach
  87 # known as "power completion / abbreviation expansion"
  88 #  alias -g '...'='../..'
  89 #  alias -g '....'='../../..'
  90 #  alias -g BG='& exit'
  91 #  alias -g C='|wc -l'
  92 #  alias -g G='|grep'
  93 #  alias -g H='|head'
  94 #  alias -g Hl=' --help |& less -r'
  95 #  alias -g K='|keep'
  96 #  alias -g L='|less'
  97 #  alias -g LL='|& less -r'
  98 #  alias -g M='|most'
  99 #  alias -g N='&>/dev/null'
 100 #  alias -g R='| tr A-z N-za-m'
 101 #  alias -g SL='| sort | less'
 102 #  alias -g S='| sort'
 103 #  alias -g T='|tail'
 104 #  alias -g V='| vim -'
 105 # }}}
 106
 107 ## aliases {{{
 108
 109 # Xterm resizing-fu.
 110 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
 111 alias hide='echo -en "\033]50;nil2\007"'
 112 alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
 113 alias small='echo -en "\033]50;6x10\007"'
 114 alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
 115 alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
 116 alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
 117 alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
 118 alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
 119 alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
 120 #  if [[ "$TERM" == "xterm" ]] && [[ "$LINES" -ge 50 ]] && [[ "$COLUMNS" -ge 100 ]] && [[ -z "$SSH_CONNECTION" ]] ; then
 121 #          large
 122 #  fi
 123
 124 # general
 125 #a2# Execute \kbd{du -sch}
 126 alias da='du -sch'
 127 #a2# Execute \kbd{jobs -l}
 128 alias j='jobs -l'
 129 #  alias u='translate -i'          # translate
 130
 131 # compile stuff
 132 #a2# Execute \kbd{./configure}
 133 alias CO="./configure"
 134 #a2# Execute \kbd{./configure --help}
 135 alias CH="./configure --help"
 136
 137 # http://conkeror.mozdev.org/
 138 #a2# Run a keyboard driven firefox
 139 alias conkeror='firefox -chrome chrome://conkeror/content'
 140
 141 # arch/tla stuff
 142 if check_com -c tla ; then
 143     #a2# Execute \kbd{tla what-changed --diffs | less}
 144     alias tdi='tla what-changed --diffs | less'
 145     #a2# Execute \kbd{tla-buildpackage}
 146     alias tbp='tla-buildpackage'
 147     #a2# Execute \kbd{tla archive-mirror}
 148     alias tmi='tla archive-mirror'
 149     #a2# Execute \kbd{tla commit}
 150     alias tco='tla commit'
 151     #a2# Execute \kbd{tla star-merge}
 152     alias tme='tla star-merge'
 153 fi
 154
 155 # listing stuff
 156 #a2# Execute \kbd{ls -lSrah}
 157 alias dir="ls -lSrah"
 158 #a2# Only show dot-directories
 159 alias lad='ls -d .*(/)'                # only show dot-directories
 160 #a2# Only show dot-files
 161 alias lsa='ls -a .*(.)'                # only show dot-files
 162 #a2# Only files with setgid/setuid/sticky flag
 163 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
 164 #a2# Only show 1st ten symlinks
 165 alias lsl='ls -l *(@[1,10])'           # only symlinks
 166 #a2# Display only executables
 167 alias lsx='ls -l *(*[1,10])'           # only executables
 168 #a2# Display world-{readable,writable,executable} files
 169 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
 170 #a2# Display the ten biggest files
 171 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
 172 #a2# Only show directories
 173 alias lsd='ls -d *(/)'                 # only show directories
 174 #a2# Only show empty directories
 175 alias lse='ls -d *(/^F)'               # only show empty directories
 176 #a2# Display the ten newest files
 177 alias lsnew="ls -rl *(D.om[1,10])"     # display the newest files
 178 #a2# Display the ten oldest files
 179 alias lsold="ls -rtlh *(D.om[1,10])"   # display the oldest files
 180 #a2# Display the ten smallest files
 181 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
 182
 183 # chmod
 184 #a2# Execute \kbd{chmod 600}
 185 alias rw-='chmod 600'
 186 #a2# Execute \kbd{chmod 700}
 187 alias rwx='chmod 700'
 188 #m# a2 r-{}- Execute \kbd{chmod 644}
 189 alias r--='chmod 644'
 190 #a2# Execute \kbd{chmod 755}
 191 alias r-x='chmod 755'
 192
 193 # some useful aliases
 194 #a2# Execute \kbd{mkdir -o}
 195 alias md='mkdir -p'
 196
 197 check_com -c ipython && alias ips='ipython -p sh'
 198
 199 # console stuff
 200 #a2# Execute \kbd{mplayer -vo fbdev}
 201 alias cmplayer='mplayer -vo fbdev'
 202 #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
 203 alias fbmplayer='mplayer -vo fbdev -fs -zoom'
 204 #a2# Execute \kbd{links2 -driver fb}
 205 alias fblinks='links2 -driver fb'
 206
 207 # ignore ~/.ssh/known_hosts entries
 208 #  alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null" -o "PreferredAuthentications=keyboard-interactive"'
 209 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
 210 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 211 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 212
 213 # Use 'g' instead of 'git':
 214 check_com g || alias g='git'
 215
 216 # use colors when browsing man pages, but only if not using LESS_TERMCAP_* from /etc/zsh/zshenv:
 217 if [[ -z "$LESS_TERMCAP_md" ]] ; then
 218     [[ -d ~/.terminfo/ ]] && alias man='TERMINFO=~/.terminfo/ LESS=C TERM=mostlike PAGER=less man'
 219 fi
 220
 221 # check whether Debian's package management (dpkg) is running
 222 if check_com salias ; then
 223     #a2# Check whether a dpkg instance is currently running
 224     salias check_dpkg_running="dpkg_running"
 225 fi
 226
 227 # work around non utf8 capable software in utf environment via $LANG and luit
 228 if check_com isutfenv && check_com luit ; then
 229     if check_com -c mrxvt ; then
 230         isutfenv && [[ -n "$LANG" ]] && \
 231             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
 232     fi
 233
 234     if check_com -c aterm ; then
 235         isutfenv && [[ -n "$LANG" ]] && \
 236             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
 237     fi
 238
 239     if check_com -c centericq ; then
 240         isutfenv && [[ -n "$LANG" ]] && \
 241             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
 242     fi
 243 fi
 244 # }}}
 245
 246 ## useful functions {{{
 247
 248 # searching
 249 #f4# Search for newspostings from authors
 250 agoogle() { ${=BROWSER} "http://groups.google.com/groups?as_uauthors=$*" ; }
 251 #f4# Search Debian Bug Tracking System by BugID in mbox format
 252 debbug()  { ${=BROWSER} "http://bugs.debian.org/$*" }
 253 #f4# Search Debian Bug Tracking System
 254 debbugm() { bts show --mbox $1 } # provide bugnummer as "$1"
 255 #f4# Search DMOZ
 256 dmoz()    { ${=BROWSER} http://search.dmoz.org/cgi-bin/search\?search=${1// /_} }
 257 #f4# Search German   Wiktionary
 258 dwicti()  { ${=BROWSER} http://de.wiktionary.org/wiki/${(C)1// /_} }
 259 #f4# Search English  Wiktionary
 260 ewicti()  { ${=BROWSER} http://en.wiktionary.org/wiki/${(C)1// /_} }
 261 #f4# Search Google Groups
 262 ggogle()  { ${=BROWSER} "http://groups.google.com/groups?q=$*" }
 263 #f4# Search Google
 264 google()  { ${=BROWSER} "http://www.google.com/search?&num=100&q=$*" }
 265 #f4# Search Google Groups for MsgID
 266 mggogle() { ${=BROWSER} "http://groups.google.com/groups?selm=$*" }
 267 #f4# Search Netcraft
 268 netcraft(){ ${=BROWSER} "http://toolbar.netcraft.com/site_report?url=$1" }
 269 #f4# Use German Wikipedia's full text search
 270 swiki()   { ${=BROWSER} http://de.wikipedia.org/wiki/Spezial:Search/${(C)1} }
 271 #f4# search \kbd{dict.leo.org}
 272 oleo()    { ${=BROWSER} "http://dict.leo.org/?search=$*" }
 273 #f4# Search German   Wikipedia
 274 wikide()  { ${=BROWSER} http://de.wikipedia.org/wiki/"${(C)*}" }
 275 #f4# Search English  Wikipedia
 276 wikien()  { ${=BROWSER} http://en.wikipedia.org/wiki/"${(C)*}" }
 277 #f4# Search official debs
 278 wodeb()   { ${=BROWSER} "http://packages.debian.org/search?keywords=$1&searchon=contents&suite=${2:=unstable}&section=all" }
 279
 280 #m# f4 gex() Exact search via Google
 281 check_com google && gex () { google "\"[ $1]\" $*" } # exact search at google
 282
 283 # misc
 284 #f5# Backup \kbd{file {\rm to} file\_timestamp}
 285 bk()      { cp -b ${1} ${1}_`date --iso-8601=m` }
 286 #f5# Copied diff
 287 cdiff()   { diff -crd "$*" | egrep -v "^Only in |^Binary files " }
 288 #f5# cd to directoy and list files
 289 cl()      { cd $1 && ls -a }        # cd && ls
 290 #f5# Cvs add
 291 cvsa()    { cvs add $* && cvs com -m 'initial checkin' $* }
 292 #f5# Cvs diff
 293 cvsd()    { cvs diff -N $* |& $PAGER }
 294 #f5# Cvs log
 295 cvsl()    { cvs log $* |& $PAGER }
 296 #f5# Cvs update
 297 cvsq()    { cvs -nq update }
 298 #f5# Rcs2log
 299 cvsr()    { rcs2log $* | $PAGER }
 300 #f5# Cvs status
 301 cvss()    { cvs status -v $* }
 302 #f5# Disassemble source files using gcc and as
 303 disassemble(){ gcc -pipe -S -o - -O -g $* | as -aldh -o /dev/null }
 304 #f5# Firefox remote control - open given URL
 305 fir()     { firefox -a firefox -remote "openURL($1)" }
 306 #f5# Create Directoy and \kbd{cd} to it
 307 mcd()     { mkdir -p "$@"; cd "$@" } # mkdir && cd
 308 #f5# Unified diff to timestamped outputfile
 309 mdiff()   { diff -udrP "$1" "$2" > diff.`date "+%Y-%m-%d"`."$1" }
 310 #f5# Memory overview
 311 memusage(){ ps aux | awk '{if (NR > 1) print $5; if (NR > 2) print "+"} END { print "p" }' | dc }
 312 #f5# Show contents of tar file
 313 shtar()   { gunzip -c $1 | tar -tf - -- | $PAGER }
 314 #f5# Show contents of tgz file
 315 shtgz()   { tar -ztf $1 | $PAGER }
 316 #f5# Show contents of zip file
 317 shzip()   { unzip -l $1 | $PAGER }
 318 #f5# Greps signature from file
 319 sig()     { agrep -d '^-- $' "$*" ~/.Signature }
 320 #f5# Unified diff
 321 udiff()   { diff -urd $* | egrep -v "^Only in |^Binary files " }
 322 #f5# (Mis)use \kbd{vim} as \kbd{less}
 323 viless()  { vim --cmd 'let no_plugin_maps = 1' -c "so \$VIMRUNTIME/macros/less.vim" "${@:--}" }
 324
 325 # download video from youtube
 326 ytdl() {
 327     if ! [[ -n "$2" ]] ; then
 328         print "Usage: ydtl http://youtube.com/watch?v=.... outputfile.flv">&2
 329         return 1
 330     else
 331         wget -O${2} "http://youtube.com/get_video?"${${${"$(wget -o/dev/null -O- "${1}" | grep -e watch_fullscreen)"}##*watch_fullscreen\?}%%\&fs=*}
 332     fi
 333 }
 334
 335
 336 # Function Usage: doc packagename
 337 #f5# \kbd{cd} to /usr/share/doc/\textit{package}
 338 doc() { cd /usr/share/doc/$1 && ls }
 339 _doc() { _files -W /usr/share/doc -/ }
 340 check_com compdef && compdef _doc doc
 341
 342 #f5# Make screenshot
 343 sshot() {
 344     [[ ! -d ~/shots  ]] && mkdir ~/shots
 345     #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
 346     cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
 347 }
 348
 349 # list images only
 350 limg() {
 351     local -a images
 352     images=( *.{jpg,gif,png}(.N) )
 353
 354     if [[ $#images -eq 0 ]] ; then
 355         print "No image files found"
 356     else
 357         ls "$@" "$images[@]"
 358     fi
 359 }
 360
 361 #f5# Create PDF file from source code
 362 makereadable() {
 363     output=$1
 364     shift
 365     a2ps --medium A4dj -E -o $output $*
 366     ps2pdf $output
 367 }
 368
 369 # zsh with perl-regex - use it e.g. via:
 370 # regcheck '\s\d\.\d{3}\.\d{3} Euro' ' 1.000.000 Euro'
 371 #f5# Checks whether a regex matches or not.\\&\quad Example: \kbd{regcheck '.\{3\} EUR' '500 EUR'}
 372 regcheck() {
 373     zmodload -i zsh/pcre
 374     pcre_compile $1 && \
 375     pcre_match $2 && echo "regex matches" || echo "regex does not match"
 376 }
 377
 378 #f5# List files which have been modified within the last {\it n} days
 379 new() { print -l *(m-$1) }
 380
 381 #f5# Grep in history
 382 greph() { history 0 | grep $1 }
 383 # use colors when GNU grep with color-support
 384 #a2# Execute \kbd{grep -{}-color=auto}
 385 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
 386 #a2# Execute \kbd{grep -i -{}-color=auto}
 387 alias GREP='grep -i --color=auto'
 388
 389 # one blank line between each line
 390 if [[ -r ~/.terminfo/m/mostlike ]] ; then
 391 #   alias man2='MANPAGER="sed -e G |less" TERMINFO=~/.terminfo TERM=mostlike /usr/bin/man'
 392     #f5# Watch manpages in a stretched style
 393     man2() { PAGER='dash -c "sed G | /usr/bin/less"' TERM=mostlike /usr/bin/man "$@" ; }
 394 fi
 395
 396 # d():Copyright 2005 Nikolai Weibull <nikolai@bitwi.se>
 397 # notice: option AUTO_PUSHD has to be set
 398 #f5# Jump between directories
 399 d() {
 400     emulate -L zsh
 401     autoload -U colors
 402     local color=$fg_bold[blue]
 403     integer i=0
 404     dirs -p | while read dir; do
 405         local num="${$(printf "%-4d " $i)/ /.}"
 406         printf " %s  $color%s$reset_color\n" $num $dir
 407         (( i++ ))
 408     done
 409     integer dir=-1
 410     read -r 'dir?Jump to directory: ' || return
 411     (( dir == -1 )) && return
 412     if (( dir < 0 || dir >= i )); then
 413         echo d: no such directory stack entry: $dir
 414         return 1
 415     fi
 416     cd ~$dir
 417 }
 418
 419 # usage example: 'lcheck strcpy'
 420 #f5# Find out which libs define a symbol
 421 lcheck() {
 422     if [[ -n "$1" ]] ; then
 423         nm -go /usr/lib/lib*.a 2>/dev/null | grep ":[[:xdigit:]]\{8\} . .*$1"
 424     else
 425         echo "Usage: lcheck <function>" >&2
 426     fi
 427 }
 428
 429 #f5# Clean up directory - remove well known tempfiles
 430 purge() {
 431     FILES=(*~(N) .*~(N) \#*\#(N) *.o(N) a.out(N) *.core(N) *.cmo(N) *.cmi(N) .*.swp(N))
 432     NBFILES=${#FILES}
 433     if [[ $NBFILES > 0 ]] ; then
 434         print $FILES
 435         local ans
 436         echo -n "Remove these files? [y/n] "
 437         read -q ans
 438         if [[ $ans == "y" ]] ; then
 439             rm ${FILES}
 440             echo ">> $PWD purged, $NBFILES files removed"
 441         else
 442             echo "Ok. .. than not.."
 443         fi
 444     fi
 445 }
 446
 447 # Translate DE<=>EN
 448 # 'translate' looks up fot a word in a file with language-to-language
 449 # translations (field separator should be " : "). A typical wordlist looks
 450 # like at follows:
 451 #  | english-word : german-transmission
 452 # It's also only possible to translate english to german but not reciprocal.
 453 # Use the following oneliner to turn back the sort order:
 454 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
 455 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
 456 #f5# Translates a word
 457 trans() {
 458     case "$1" in
 459         -[dD]*)
 460             translate -l de-en $2
 461             ;;
 462         -[eE]*)
 463             translate -l en-de $2
 464             ;;
 465         *)
 466             echo "Usage: $0 { -D | -E }"
 467             echo "         -D == German to English"
 468             echo "         -E == English to German"
 469     esac
 470 }
 471
 472 # Some quick Perl-hacks aka /useful/ oneliner
 473 #  bew() { perl -le 'print unpack "B*","'$1'"' }
 474 #  web() { perl -le 'print pack "B*","'$1'"' }
 475 #  hew() { perl -le 'print unpack "H*","'$1'"' }
 476 #  weh() { perl -le 'print pack "H*","'$1'"' }
 477 #  pversion()    { perl -M$1 -le "print $1->VERSION" } # i. e."pversion LWP -> 5.79"
 478 #  getlinks ()   { perl -ne 'while ( m/"((www|ftp|http):\/\/.*?)"/gc ) { print $1, "\n"; }' $* }
 479 #  gethrefs ()   { perl -ne 'while ( m/href="([^"]*)"/gc ) { print $1, "\n"; }' $* }
 480 #  getanames ()  { perl -ne 'while ( m/a name="([^"]*)"/gc ) { print $1, "\n"; }' $* }
 481 #  getforms ()   { perl -ne 'while ( m:(\</?(input|form|select|option).*?\>):gic ) { print $1, "\n"; }' $* }
 482 #  getstrings () { perl -ne 'while ( m/"(.*?)"/gc ) { print $1, "\n"; }' $*}
 483 #  getanchors () { perl -ne 'while ( m/«([^«»\n]+)»/gc ) { print $1, "\n"; }' $* }
 484 #  showINC ()    { perl -e 'for (@INC) { printf "%d %s\n", $i++, $_ }' }
 485 #  vimpm ()      { vim `perldoc -l $1 | sed -e 's/pod$/pm/'` }
 486 #  vimhelp ()    { vim -c "help $1" -c on -c "au! VimEnter *" }
 487
 488 #f5# List all occurrences of programm in current PATH
 489 plap() {
 490     if [[ $# = 0 ]] ; then
 491         echo "Usage:    $0 program"
 492         echo "Example:  $0 zsh"
 493         echo "Lists all occurrences of program in the current PATH."
 494     else
 495         ls -l ${^path}/*$1*(*N)
 496     fi
 497 }
 498
 499 # Found in the mailinglistarchive from Zsh (IIRC ~1996)
 500 #f5# Select items for specific command(s) from history
 501 selhist() {
 502     emulate -L zsh
 503     local TAB=$'\t';
 504     (( $# < 1 )) && {
 505         echo "Usage: $0 command"
 506         return 1
 507     };
 508     cmd=(${(f)"$(grep -w $1 $HISTFILE | sort | uniq | pr -tn)"})
 509     print -l $cmd | less -F
 510     echo -n "enter number of desired command [1 - $(( ${#cmd[@]} - 1 ))]: "
 511     local answer
 512     read answer
 513     print -z "${cmd[$answer]#*$TAB}"
 514 }
 515
 516 # Use vim to convert plaintext to HTML
 517 #f5# Transform files to html with highlighting
 518 2html() { vim -u NONE -n -c ':syntax on' -c ':so $VIMRUNTIME/syntax/2html.vim' -c ':wqa' $1 &>/dev/null }
 519
 520 # Usage: simple-extract <file>
 521 #f5# Smart archive extractor
 522 simple-extract () {
 523     if [[ -f $1 ]] ; then
 524         case $1 in
 525             *.tar.bz2)  bzip2 -v -d $1      ;;
 526             *.tar.gz)   tar -xvzf $1        ;;
 527             *.rar)      unrar $1            ;;
 528             *.deb)      ar -x $1            ;;
 529             *.bz2)      bzip2 -d $1         ;;
 530             *.lzh)      lha x $1            ;;
 531             *.gz)       gunzip -d $1        ;;
 532             *.tar)      tar -xvf $1         ;;
 533             *.tgz)      gunzip -d $1        ;;
 534             *.tbz2)     tar -jxvf $1        ;;
 535             *.zip)      unzip $1            ;;
 536             *.Z)        uncompress $1       ;;
 537             *)          echo "'$1' Error. Please go away" ;;
 538         esac
 539     else
 540         echo "'$1' is not a valid file"
 541     fi
 542 }
 543
 544 # Usage: smartcompress <file> (<type>)
 545 #f5# Smart archive creator
 546 smartcompress() {
 547     if [[ -n $2 ]] ; then
 548         case $2 in
 549             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
 550             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
 551             tar.Z)          tar -Zcvf$1.$2 $1 ;;
 552             tar)            tar -cvf$1.$2  $1 ;;
 553             gz | gzip)      gzip           $1 ;;
 554             bz2 | bzip2)    bzip2          $1 ;;
 555             *)
 556                 echo "Error: $2 is not a valid compression type"
 557                 ;;
 558         esac
 559     else
 560         smartcompress $1 tar.gz
 561     fi
 562 }
 563
 564 # Usage: show-archive <archive>
 565 #f5# List an archive's content
 566 show-archive() {
 567     if [[ -f $1 ]] ; then
 568         case $1 in
 569             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
 570             *.tar)         tar -tf $1 ;;
 571             *.tgz)         tar -ztf $1 ;;
 572             *.zip)         unzip -l $1 ;;
 573             *.bz2)         bzless $1 ;;
 574             *)             echo "'$1' Error. Please go away" ;;
 575         esac
 576     else
 577         echo "'$1' is not a valid archive"
 578     fi
 579 }
 580
 581 # TODO: isn't ssl() like this, but clean?
 582 #       I'd like to remove this, it's a gross hack, IMHO -ft
 583 #f5# Follow symlinks
 584 folsym() {
 585     if [[ -e $1 || -h $1 ]] ; then
 586         file=$1
 587     else
 588         file=`which $1`
 589     fi
 590     if [[ -e $file || -L $file ]] ; then
 591         if [[ -L $file ]] ; then
 592             echo `ls -ld $file | perl -ane 'print $F[7]'` '->'
 593             folsym `perl -le '$file = $ARGV[0];
 594                               $dest = readlink $file;
 595                               if ($dest !~ m{^/}) {
 596                                   $file =~ s{(/?)[^/]*$}{$1$dest};
 597                               } else {
 598                                   $file = $dest;
 599                               }
 600                               $file =~ s{/{2,}}{/}g;
 601                               while ($file =~ s{[^/]+/\.\./}{}) {
 602                                   ;
 603                               }
 604                               $file =~ s{^(/\.\.)+}{};
 605                               print $file' $file`
 606         else
 607             ls -d $file
 608         fi
 609     else
 610         echo $file
 611     fi
 612 }
 613
 614 # It's shameless stolen from <http://www.vim.org/tips/tip.php?tip_id=167>
 615 #f5# Use \kbd{vim} as your manpage reader
 616 vman() { man $* | col -b | view -c 'set ft=man nomod nolist' - }
 617
 618 # function readme() { $PAGER -- (#ia3)readme* }
 619 #f5# View all README-like files in current directory in pager
 620 readme() {
 621     local files
 622     files=(./(#i)*(read*me|lue*m(in|)ut)*(ND))
 623     if (($#files)) ; then
 624         $PAGER $files
 625     else
 626         print 'No README files.'
 627     fi
 628 }
 629
 630 # suidfind() { ls -latg $path | grep '^...s' }
 631 #f5# Find all files in \$PATH with setuid bit set
 632 suidfind() { ls -latg $path/*(sN) }
 633
 634 # See above but this is /better/ ... anywise ..
 635 findsuid() {
 636     print 'Output will be written to ~/suid_* ...'
 637     $SUDO find / -type f \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suidfiles.`date "+%Y-%m-%d"`.out 2>&1
 638     $SUDO find / -type d \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suiddirs.`date "+%Y-%m-%d"`.out 2>&1
 639     $SUDO find / -type f \( -perm -2 -o -perm -20 \) -ls > ~/suid_writefiles.`date "+%Y-%m-%d"`.out 2>&1
 640     $SUDO find / -type d \( -perm -2 -o -perm -20 \) -ls > ~/suid_writedirs.`date "+%Y-%m-%d"`.out 2>&1
 641     print 'Finished'
 642 }
 643
 644 #f5# Reload given functions
 645 refunc() {
 646     for func in $argv ; do
 647         unfunction $func
 648         autoload $func
 649     done
 650 }
 651
 652 # a small check to see which DIR is located on which server/partition.
 653 # stolen and modified from Sven's zshrc.forall
 654 #f5# Report diskusage of a directory
 655 dirspace() {
 656     if [[ -n "$1" ]] ; then
 657         for dir in $* ; do
 658             if [[ -d "$dir" ]] ; then
 659                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
 660             else
 661                 echo "warning: $dir does not exist" >&2
 662             fi
 663         done
 664     else
 665         for dir in $path; do
 666             if [[ -d "$dir" ]] ; then
 667                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
 668             else
 669                 echo "warning: $dir does not exist" >&2
 670             fi
 671         done
 672     fi
 673 }
 674
 675 # % slow_print `cat /etc/passwd`
 676 #f5# Slowly print out parameters
 677 slow_print() {
 678     for argument in "${@}" ; do
 679         for ((i = 1; i <= ${#1} ;i++)) ; do
 680             print -n "${argument[i]}"
 681             sleep 0.08
 682         done
 683         print -n " "
 684     done
 685     print ""
 686 }
 687
 688 #f5# Show some status info
 689 status() {
 690     print ""
 691     print "Date..: "$(date "+%Y-%m-%d %H:%M:%S")""
 692     print "Shell.: Zsh $ZSH_VERSION (PID = $$, $SHLVL nests)"
 693     print "Term..: $TTY ($TERM), $BAUD bauds, $COLUMNS x $LINES cars"
 694     print "Login.: $LOGNAME (UID = $EUID) on $HOST"
 695     print "System: $(cat /etc/[A-Za-z]*[_-][rv]e[lr]*)"
 696     print "Uptime:$(uptime)"
 697     print ""
 698 }
 699
 700 # Rip an audio CD
 701 #f5# Rip an audio CD
 702 audiorip() {
 703     mkdir -p ~/ripps
 704     cd ~/ripps
 705     cdrdao read-cd --device $DEVICE --driver generic-mmc audiocd.toc
 706     cdrdao read-cddb --device $DEVICE --driver generic-mmc audiocd.toc
 707     echo " * Would you like to burn the cd now? (yes/no)"
 708     read input
 709     if [[ "$input" = "yes" ]] ; then
 710         echo " ! Burning Audio CD"
 711         audioburn
 712         echo " * done."
 713     else
 714         echo " ! Invalid response."
 715     fi
 716 }
 717
 718 # and burn it
 719 #f5# Burn an audio CD (in combination with audiorip)
 720 audioburn() {
 721     cd ~/ripps
 722     cdrdao write --device $DEVICE --driver generic-mmc audiocd.toc
 723     echo " * Should I remove the temporary files? (yes/no)"
 724     read input
 725     if [[ "$input" = "yes" ]] ; then
 726         echo " ! Removing Temporary Files."
 727         cd ~
 728         rm -rf ~/ripps
 729         echo " * done."
 730     else
 731         echo " ! Invalid response."
 732     fi
 733 }
 734
 735 #f5# Make an audio CD from all mp3 files
 736 mkaudiocd() {
 737     # TODO: do the renaming more zshish, possibly with zmv()
 738     cd ~/ripps
 739     for i in *.[Mm][Pp]3; do mv "$i" `echo $i | tr '[A-Z]' '[a-z]'`; done
 740     for i in *.mp3; do mv "$i" `echo $i | tr ' ' '_'`; done
 741     for i in *.mp3; do mpg123 -w `basename $i .mp3`.wav $i; done
 742     normalize -m *.wav
 743     for i in *.wav; do sox $i.wav -r 44100 $i.wav resample; done
 744 }
 745
 746 #f5# Create an ISO image. You are prompted for\\&\quad volume name, filename and directory
 747 mkiso() {
 748     echo " * Volume name "
 749     read volume
 750     echo " * ISO Name (ie. tmp.iso)"
 751     read iso
 752     echo " * Directory or File"
 753     read files
 754     mkisofs -o ~/$iso -A $volume -allow-multidot -J -R -iso-level 3 -V $volume -R $files
 755 }
 756
 757 #f5# Simple thumbnails generator
 758 genthumbs() {
 759     rm -rf thumb-* index.html
 760     echo "
 761 <html>
 762   <head>
 763     <title>Images</title>
 764   </head>
 765   <body>" > index.html
 766     for f in *.(gif|jpeg|jpg|png) ; do
 767         convert -size 100x200 "$f" -resize 100x200 thumb-"$f"
 768         echo "    <a href=\"$f\"><img src=\"thumb-$f\"></a>" >> index.html
 769     done
 770     echo "
 771   </body>
 772 </html>" >> index.html
 773 }
 774
 775 #f5# Set all ulimit parameters to \kbd{unlimited}
 776 allulimit() {
 777     ulimit -c unlimited
 778     ulimit -d unlimited
 779     ulimit -f unlimited
 780     ulimit -l unlimited
 781     ulimit -n unlimited
 782     ulimit -s unlimited
 783     ulimit -t unlimited
 784 }
 785
 786 # ogg2mp3 with bitrate of 192
 787 ogg2mp3_192() {
 788     oggdec -o - ${1} | lame -b 192 - ${1:r}.mp3
 789 }
 790
 791 #f5# RFC 2396 URL encoding in Z-Shell
 792 urlencode() {
 793     setopt localoptions extendedglob
 794     input=( ${(s::)1} )
 795     print ${(j::)input/(#b)([^A-Za-z0-9_.!~*\'\(\)-])/%$(([##16]#match))}
 796 }
 797
 798 #f5# Install x-lite (VoIP software)
 799 getxlite() {
 800     setopt local_options
 801     setopt errreturn
 802     [[ -d ~/tmp ]] || mkdir ~/tmp
 803     cd ~/tmp
 804
 805     echo "Downloading http://www.counterpath.com/download/X-Lite_Install.tar.gz and storing it in ~/tmp:"
 806     if wget http://www.counterpath.com/download/X-Lite_Install.tar.gz ; then
 807         unp X-Lite_Install.tar.gz && echo done || echo failed
 808     else
 809         echo "Error while downloading." ; return 1
 810     fi
 811
 812     if [[ -x xten-xlite/xtensoftphone ]] ; then
 813         echo "Execute xten-xlite/xtensoftphone to start xlite."
 814     fi
 815 }
 816
 817 #f5# Install skype
 818 getskype() {
 819     setopt local_options
 820     setopt errreturn
 821     echo "Downloading debian package of skype."
 822     echo "Notice: If you want to use a more recent skype version run 'getskypebeta'."
 823     wget http://www.skype.com/go/getskype-linux-deb
 824     $SUDO dpkg -i skype*.deb && echo "skype installed."
 825 }
 826
 827 #f5# Install beta-version of skype
 828 getskypebeta() {
 829     setopt local_options
 830     setopt errreturn
 831     echo "Downloading debian package of skype (beta version)."
 832     wget http://www.skype.com/go/getskype-linux-beta-deb
 833     $SUDO dpkg -i skype-beta*.deb && echo "skype installed."
 834 }
 835
 836 #f5# Install gizmo (VoIP software)
 837 getgizmo() {
 838     setopt local_options
 839     setopt errreturn
 840     echo "gconf2-common and libgconf2-4 have to be available. Installing therefor."
 841     $SUDO apt-get update
 842     $SUDO apt-get install gconf2-common libgconf2-4
 843     wget $(lynx --dump http://www.gizmoproject.com/download-linux.html | awk '/\.deb/ {print $2" "}' | tr -d '\n')
 844     $SUDO dpkg -i libsipphoneapi*.deb bonjour_*.deb gizmo-*.deb && echo "gizmo installed."
 845 }
 846
 847 #f5# Get and run AIR (Automated Image and Restore)
 848 getair() {
 849     setopt local_options
 850     setopt errreturn
 851     [[ -w . ]] || { echo 'Error: you do not have write permissions in this directory. Exiting.' ; return 1 }
 852     local VER='1.2.8'
 853     wget http://puzzle.dl.sourceforge.net/sourceforge/air-imager/air-$VER.tar.gz
 854     tar zxf air-$VER.tar.gz
 855     cd air-$VER
 856     INTERACTIVE=no $SUDO ./install-air-1.2.8
 857     [[ -x /usr/local/bin/air ]] && [[ -n "$DISPLAY" ]] && $SUDO air
 858 }
 859
 860 #f5# Get specific git commitdiff
 861 git-get-diff() {
 862     if [[ -z $GITTREE ]] ; then
 863         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
 864     fi
 865     if ! [[ -z $1 ]] ; then
 866         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commitdiff;h=$1"
 867     else
 868         echo "Usage: git-get-diff <commit>"
 869     fi
 870 }
 871
 872 #f5# Get specific git commit
 873 git-get-commit() {
 874     if [[ -z $GITTREE ]] ; then
 875         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
 876     fi
 877     if ! [[ -z $1 ]] ; then
 878         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commit;h=$1"
 879     else
 880         echo "Usage: git-get-commit <commit>"
 881     fi
 882 }
 883
 884 #f5# Get specific git diff
 885 git-get-plaindiff() {
 886     if [[ -z $GITTREE ]] ; then
 887         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
 888     fi
 889     if ! [[ -z $1 ]] ; then
 890         wget "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O $1.diff
 891     else
 892         echo 'Usage: git-get-plaindiff '
 893     fi
 894 }
 895
 896 # http://strcat.de/blog/index.php?/archives/335-Software-sauber-deinstallieren...html
 897 #f5# Log 'make install' output
 898 mmake() {
 899     [[ ! -d ~/.errorlogs ]] && mkdir ~/.errorlogs
 900     make -n install > ~/.errorlogs/${PWD##*/}-makelog
 901 }
 902
 903 #f5# Indent source code
 904 smart-indent() {
 905     indent -npro -kr -i8 -ts8 -sob -l80 -ss -ncs $*
 906 }
 907
 908 # highlight important stuff in diff output, usage example: hg diff | hidiff
 909 #m# a2 hidiff \kbd{histring} oneliner for diffs
 910 check_com -c histring && \
 911     alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
 912
 913 # rename pictures based on information found in exif headers
 914 #f5# Rename pictures based on information found in exif headers
 915 exirename() {
 916     if [[ $# -lt 1 ]] ; then
 917         echo 'Usage: jpgrename $FILES' >& 2
 918         return 1
 919     else
 920         echo -n 'Checking for jhead with version newer than 1.9: '
 921         jhead_version=`jhead -h | grep 'used by most Digital Cameras.  v.*' | awk '{print $6}' | tr -d v`
 922         if [[ $jhead_version > '1.9' ]]; then
 923             echo 'success - now running jhead.'
 924             jhead -n%Y-%m-%d_%Hh%M_%f $*
 925         else
 926             echo 'failed - exiting.'
 927         fi
 928     fi
 929 }
 930
 931 # open file in vim and jump to line
 932 # http://www.downgra.de/archives/2007/05/08/T19_21_11/
 933 j2v() {
 934     local -a params
 935     params=(${*//(#m):[0-9]*:/\\n+${MATCH//:/}}) # replace ':23:' to '\n+23'
 936     params=(${(s|\n|)${(j|\n|)params}}) # join array using '\n', then split on all '\n'
 937     vim ${params}
 938 }
 939
 940 # get_ic() - queries imap servers for capabilities; real simple. no imaps
 941 ic_get() {
 942     local port
 943     if [[ ! -z $1 ]] ; then
 944         port=${2:-143}
 945         print "querying imap server on $1:${port}...\n";
 946         print "a1 capability\na2 logout\n" | nc $1 ${port}
 947     else
 948         print "usage:\n  $0 <imap-server> [port]"
 949     fi
 950 }
 951
 952 # creates a Maildir/ with its {new,cur,tmp} subdirs
 953 mkmaildir() {
 954     local root subdir
 955     root=${MAILDIR_ROOT:-${HOME}/Mail}
 956     if [[ -z ${1} ]] ; then print "Usage:\n $0 <dirname>" ; return 1 ; fi
 957     subdir=${1}
 958     mkdir -p ${root}/${subdir}/{cur,new,tmp}
 959 }
 960
 961 # xtrename() rename xterm from within GNU-screen
 962 xtrename() {
 963     if [[ -z ${DISPLAY} ]] ; then
 964         printf 'xtrename only makes sense in X11.\n'
 965         return 1
 966     fi
 967     if [[ -z ${1} ]] ; then
 968         printf 'usage: xtrename() "title for xterm"\n'
 969         printf '  renames the title of xterm from _within_ screen.\n'
 970         printf '  Also works without screen.\n'
 971         return 0
 972     fi
 973     print -n "\eP\e]0;${1}\C-G\e\\"
 974     return 0
 975 }
 976
 977 # hl() highlighted less
 978 # http://ft.bewatermyfriend.org/comp/data/zsh/zfunct.html
 979 if check_com -c highlight ; then
 980     function hl() {
 981         local theme lang
 982         theme=${HL_THEME:-""}
 983         case ${1} in
 984             (-l|--list)
 985                 ( printf 'available languages (syntax parameter):\n\n' ;
 986                     highlight --list-langs ; ) | less -SMr
 987                 ;;
 988             (-t|--themes)
 989                 ( printf 'available themes (style parameter):\n\n' ;
 990                     highlight --list-themes ; ) | less -SMr
 991                 ;;
 992             (-h|--help)
 993                 printf 'usage: hl <syntax[:theme]> <file>\n'
 994                 printf '    available options: --list (-l), --themes (-t), --help (-h)\n\n'
 995                 printf '  Example: hl c main.c\n'
 996                 ;;
 997             (*)
 998                 if [[ -z ${2} ]] || (( ${#argv} > 2 )) ; then
 999                     printf 'usage: hl <syntax[:theme]> <file>\n'
1000                     printf '    available options: --list (-l), --themes (-t), --help (-h)\n'
1001                     (( ${#argv} > 2 )) && printf '  Too many arguments.\n'
1002                     return 1
1003                 fi
1004                 lang=${1%:*}
1005                 [[ ${1} == *:* ]] && [[ -n ${1#*:} ]] && theme=${1#*:}
1006                 if [[ -n ${theme} ]] ; then
1007                     highlight --xterm256 --syntax ${lang} --style ${theme} ${2} | less -SMr
1008                 else
1009                     highlight --ansi --syntax ${lang} ${2} | less -SMr
1010                 fi
1011                 ;;
1012         esac
1013         return 0
1014     }
1015     # ... and a proper completion for hl()
1016     # needs 'highlight' as well, so it fits fine in here.
1017     function _hl_genarg()  {
1018         local expl
1019         if [[ -prefix 1 *: ]] ; then
1020             local themes
1021             themes=(${${${(f)"$(LC_ALL=C highlight --list-themes)"}/ #/}:#*(Installed|Use name)*})
1022             compset -P 1 '*:'
1023             _wanted -C list themes expl theme compadd ${themes}
1024         else
1025             local langs
1026             langs=(${${${(f)"$(LC_ALL=C highlight --list-langs)"}/ #/}:#*(Installed|Use name)*})
1027             _wanted -C list languages expl languages compadd -S ':' -q ${langs}
1028         fi
1029     }
1030     function _hl_complete() {
1031         _arguments -s '1: :_hl_genarg' '2:files:_path_files'
1032     }
1033     compdef _hl_complete hl
1034 fi
1035
1036 # create small urls via tinyurl.com using wget, grep and sed
1037 zurl() {
1038     [[ -z ${1} ]] && print "please give an url to shrink." && return 1
1039     local url=${1}
1040     local tiny="http://tinyurl.com/create.php?url="
1041     #print "${tiny}${url}" ; return
1042     wget  -O-             \
1043           -o/dev/null     \
1044           "${tiny}${url}" \
1045         | grep -Eio 'value="(http://tinyurl.com/.*)"' \
1046         | sed 's/value=//;s/"//g'
1047 }
1048
1049 # change fluxbox keys from 'Alt-#' to 'Alt-F#' and vice versa
1050 fluxkey-change() {
1051     [[ -n "$FLUXKEYS" ]] || local FLUXKEYS="$HOME/.fluxbox/keys"
1052     if ! [[ -r "$FLUXKEYS" ]] ; then
1053         echo "Sorry, \$FLUXKEYS file $FLUXKEYS could not be read - nothing to be done."
1054         return 1
1055     else
1056         if grep -q 'Mod1 F[0-9] :Workspace [0-9]' $FLUXKEYS ; then
1057             echo -n 'Switching to Alt-# mode in ~/.fluxbox/keys: '
1058             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)F\([0-9]\+[: space :]\+:Workspace.*\)|\1\2|' $FLUXKEYS && echo done || echo failed
1059         elif grep -q 'Mod1 [0-9] :Workspace [0-9]' $FLUXKEYS ; then
1060             echo -n 'Switching to Alt-F# mode in ~/.fluxbox/keys: '
1061             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)\([0-9]\+[: space :]\+:Workspace.*\)|\1F\2|' $FLUXKEYS && echo done || echo failed
1062         else
1063             echo 'Sorry, do not know what to do.'
1064             return 1
1065         fi
1066     fi
1067 }
1068
1069 # retrieve weather information on the console
1070 # Usage example: 'weather LOWG'
1071 weather() {
1072     [[ -n "$1" ]] || {
1073         print 'Usage: weather <station_id>' >&2
1074         return 1
1075     }
1076
1077     local PLACE="${1:u}"
1078     local FILE="$HOME/.weather/$PLACE"
1079     local LOG="$HOME/.weather/log"
1080
1081     [[ -d $HOME/.weather ]] || {
1082         print -n "Creating $HOME/.weather: "
1083         mkdir $HOME/.weather
1084         print 'done'
1085     }
1086
1087     print "Retrieving information for ${PLACE}:"
1088     print
1089     wget -T 10 --no-verbose --output-file=$LOG --output-document=$FILE --timestamping http://weather.noaa.gov/pub/data/observations/metar/decoded/$PLACE.TXT
1090
1091     if [[ $? -eq 0 ]] ; then
1092         if [[ -n "$VERBOSE" ]] ; then
1093             cat $FILE
1094         else
1095             DATE=$(grep 'UTC' $FILE | sed 's#.* /##')
1096             TEMPERATURE=$(awk '/Temperature/ { print $4" degree Celcius / " $2" degree Fahrenheit" }' $FILE| tr -d '(')
1097             echo "date: $DATE"
1098             echo "temp:  $TEMPERATURE"
1099         fi
1100     else
1101         print "There was an error retrieving the weather information for $PLACE" >&2
1102         cat $LOG
1103         return 1
1104     fi
1105 }
1106
1107
1108 # }}}
1109
1110 # mercurial related stuff {{{
1111 if check_com -c hg ; then
1112     # gnu like diff for mercurial
1113     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
1114     #f5# GNU like diff for mercurial
1115     hgdi() {
1116         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
1117     }
1118
1119     # build debian package
1120     #a2# Alias for \kbd{hg-buildpackage}
1121     alias hbp='hg-buildpackage'
1122
1123     # execute commands on the versioned patch-queue from the current repos
1124     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
1125
1126     # diffstat for specific version of a mercurial repository
1127     #   hgstat      => display diffstat between last revision and tip
1128     #   hgstat 1234 => display diffstat between revision 1234 and tip
1129     #f5# Diffstat for specific version of a mercurial repos
1130     hgstat() {
1131         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
1132     }
1133
1134     #f5# Get current mercurial tip via hg itself
1135     gethgclone() {
1136         setopt local_options
1137         setopt errreturn
1138         if [[ -f mercurial-tree/.hg ]] ; then
1139             cd mercurial-tree
1140             echo "Running hg pull for retreiving latest version..."
1141             hg pull
1142             echo "Finished update. Building mercurial"
1143             make local
1144             echo "Setting \$PATH to $PWD:\$PATH..."
1145             export PATH="$PWD:$PATH"
1146         else
1147             echo "Downloading mercurial via hg"
1148             hg clone http://selenic.com/repo/hg mercurial-tree
1149             cd mercurial-tree
1150             echo "Building mercurial"
1151             make local
1152             echo "Setting \$PATH to $PWD:\$PATH..."
1153             export PATH="$PWD:$PATH"
1154             echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
1155             # echo "Setting \$PYTHONPATH to PYTHONPATH=\${HOME}/lib/python,"
1156             # export PYTHONPATH=${HOME}/lib/python
1157         fi
1158     }
1159
1160 fi # end of check whether we have the 'hg'-executable
1161
1162 # get current mercurial snapshot
1163 #f5# Get current mercurial snapshot
1164 gethgsnap() {
1165     setopt local_options
1166     setopt errreturn
1167     if [[ -f mercurial-snapshot.tar.gz ]] ; then
1168          echo "mercurial-snapshot.tar.gz exists already, skipping download."
1169     else
1170         echo "Downloading mercurial snapshot"
1171         wget http://www.selenic.com/mercurial/mercurial-snapshot.tar.gz
1172     fi
1173     echo "Unpacking mercurial-snapshot.tar.gz"
1174     tar zxf mercurial-snapshot.tar.gz
1175     cd mercurial-snapshot/
1176     echo "Installing required build-dependencies"
1177     $SUDO apt-get update
1178     $SUDO apt-get install python2.4-dev
1179     echo "Building mercurial"
1180     make local
1181     echo "Setting \$PATH to $PWD:\$PATH..."
1182     export PATH="$PWD:$PATH"
1183     echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
1184 }
1185 # }}}
1186
1187 # some useful commands often hard to remember - let's grep for them {{{
1188
1189 # Work around ion/xterm resize bug.
1190 #if [[ "$SHLVL" -eq 1 ]]; then
1191 #       if check_com -c resize ; then
1192 #               eval `resize </dev/null`
1193 #       fi
1194 #fi
1195
1196 # enable jackd:
1197 #  /usr/bin/jackd -dalsa -dhw:0 -r48000 -p1024 -n2
1198 # now play audio file:
1199 #  alsaplayer -o jack foobar.mp3
1200
1201 # send files via netcat
1202 # on sending side:
1203 #  send() {j=$*; tar cpz ${j/%${!#}/}|nc -w 1 ${!#} 51330;}
1204 #  send dir* $HOST
1205 #  alias receive='nc -vlp 51330 | tar xzvp'
1206
1207 # debian stuff:
1208 # dh_make -e foo@localhost -f $1
1209 # dpkg-buildpackage -rfakeroot
1210 # lintian *.deb
1211 # dpkg-scanpackages ./ /dev/null | gzip > Packages.gz
1212 # dpkg-scansources . | gzip > Sources.gz
1213 # grep-dctrl --field Maintainer $* /var/lib/apt/lists/*
1214
1215 # other stuff:
1216 # convert -geometry 200x200 -interlace LINE -verbose
1217 # ldapsearch -x -b "OU=Bedienstete,O=tug" -h ldap.tugraz.at sn=$1
1218 # ps -ao user,pcpu,start,command
1219 # gpg --keyserver blackhole.pca.dfn.de --recv-keys
1220 # xterm -bg black -fg yellow -fn -misc-fixed-medium-r-normal--14-140-75-75-c-90-iso8859-15 -ah
1221 # nc -vz $1 1-1024   # portscan via netcat
1222 # wget --mirror --no-parent --convert-links
1223 # pal -d `date +%d`
1224 # autoload -U tetris; zle -N tetris; bindkey '...' ; echo "press ... for playing tennis"
1225 #
1226 # modify console cursor
1227 # see http://www.tldp.org/HOWTO/Framebuffer-HOWTO-5.html
1228 # print $'\e[?96;0;64c'
1229 # }}}
1230
1231 # finally source a local zshrc and grmlsmall-specific configuration {{{
1232
1233 # The following file is used to remove zsh-config-items that do not work
1234 # in grml-small by default.
1235 # If you do not want these adjustments (for whatever reason),
1236 # there are three ways to accomplish that:
1237 #  a) at the beginning of this file (variables section), set
1238 #     $GRMLSMALL_SPECIFIC to 0 or comment out the variable definition.
1239 #  b) remove/rename .zshrc.grmlsmall
1240 #  c) comment out the following line
1241 (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall && source ~/.zshrc.grmlsmall
1242
1243 # this allows us to stay in sync with /etc/skel/.zshrc
1244 # through 'ln -s /etc/skel/.zshrc ~/.zshrc' and put own
1245 # modifications in ~/.zshrc.local
1246 if type xsource &>/dev/null ; then
1247     xsource "${HOME}/.zshrc.local"
1248 else
1249     xsource "${HOME}/.zshrc.local"
1250 fi
1251
1252 # ...and remove utility functions again.
1253 xunfunction
1254
1255 # }}}
1256
1257 ### doc strings for external functions from files
1258 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
1259 ## END OF FILE #################################################################
1260 # vim:foldmethod=marker autoindent expandtab shiftwidth=4