etc/zsh/zshenv

   1 # Filename:      zshenv
   2 # Purpose:       system-wide .zshenv file for zsh(1)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced on all invocations of the shell.
   8 # It is the 1st file zsh reads; it's read for every shell,
   9 # even if started with -f (setopt NO_RCS), all other
  10 # initialization files are skipped.
  11 #
  12 # This file should contain commands to set the command
  13 # search path, plus other important environment variables.
  14 # This file should not contain commands that produce
  15 # output or assume the shell is attached to a tty.
  16 #
  17 # Notice: .zshenv is the same, execpt that it's not read
  18 # if zsh is started with -f
  19 #
  20 # Global Order: zshenv, zprofile, zshrc, zlogin
  21 ################################################################################
  22
  23 # language settings (read in /etc/environment before /etc/default/locale as
  24 # the latter one is the default on Debian nowadays)
  25 # no xsource() here because it's only created in zshrc! (which is good)
  26 [[ -r /etc/environment ]] && source /etc/environment
  27
  28 # set environment variables (important for autologin on tty)
  29 export HOSTNAME=${HOSTNAME:-$(hostname)}
  30
  31 # make sure /usr/bin/id is available
  32 if [[ -x /usr/bin/id ]] ; then
  33     [[ -z "$USER" ]]          && export USER=$(/usr/bin/id -un)
  34     [[ $LOGNAME == LOGIN ]] && LOGNAME=$(/usr/bin/id -un)
  35 fi
  36
  37 # workaround for live-cd mode as $HOME is not set via rungetty
  38 if [[ -f /etc/grml_cd ]] ; then
  39     if (( EUID == 0 )); then
  40         export HOME=/root
  41     else
  42         export HOME=/home/$USER
  43     fi
  44 fi
  45
  46 ## set $PATH
  47 # gentoo users have to source /etc/profile.env
  48 if [[ -r /etc/gentoo-release ]] ; then
  49     [[ -r /etc/profile.env ]] && source /etc/profile.env
  50 fi
  51
  52 # support extra scripts/software in special directory outside of squashfs environment in live mode
  53 if [[ -f /etc/grml_cd ]] ; then
  54     [[ -r /lib/live/mount/medium/scripts ]] && ADDONS='/lib/live/mount/medium/scripts'
  55     [[ -r /etc/grml/my_path ]] && ADDONS="$(cat /etc/grml/my_path)"
  56 fi
  57
  58 # Solaris
  59 case $(uname 2>/dev/null) in
  60   SunOS)
  61     path=(
  62       /usr/bin
  63       /usr/sbin
  64       /usr/ccs/bin
  65       /opt/SUNWspro/bin
  66       /usr/ucb
  67       /usr/sfw/bin
  68       /usr/gnu/bin
  69       /usr/openwin/bin
  70       /opt/csw/bin
  71       /sbin
  72       ~/bin
  73     )
  74 esac
  75
  76 # generic $PATH handling
  77 if (( EUID != 0 )); then
  78   path=(
  79     $HOME/bin
  80     /usr/local/bin
  81     /usr/bin
  82     /bin
  83     /usr/local/sbin
  84     /usr/sbin
  85     /sbin
  86     /usr/local/games
  87     /usr/games
  88     "${ADDONS}"
  89     "${path[@]}"
  90   )
  91 else
  92   path=(
  93     /sbin
  94     /bin
  95     /usr/sbin
  96     /usr/bin
  97     /usr/local/sbin
  98     /usr/local/bin
  99     "${ADDONS}"
 100     "${path[@]}"
 101   )
 102 fi
 103
 104 typeset -U path
 105
 106 # less (:=pager) options:
 107 #  export LESS=C
 108 typeset -a lp; lp=( ${^path}/lesspipe(N) )
 109 if (( $#lp > 0 )) && [[ -x $lp[1] ]] ; then
 110     export LESSOPEN="|lesspipe %s"
 111 elif [[ -x /usr/bin/lesspipe.sh ]] ; then
 112     export LESSOPEN="|lesspipe.sh %s"
 113 fi
 114 unset lp
 115
 116 export READNULLCMD=${PAGER:-/usr/bin/pager}
 117
 118 # allow zeroconf for distcc
 119 export DISTCC_HOSTS="+zeroconf"
 120
 121 # MAKEDEV should be usable on udev as well by default:
 122 export WRITE_ON_UDEV=yes
 123
 124 ## END OF FILE #################################################################
 125 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4