etc/zsh/zshenv

   1 # Filename:      zshenv
   2 # Purpose:       system-wide .zshenv file for zsh(1)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced on all invocations of the shell.
   8 # It is the 1st file zsh reads; it's read for every shell,
   9 # even if started with -f (setopt NO_RCS), all other
  10 # initialization files are skipped.
  11 #
  12 # This file should contain commands to set the command
  13 # search path, plus other important environment variables.
  14 # This file should not contain commands that produce
  15 # output or assume the shell is attached to a tty.
  16 #
  17 # Notice: .zshenv is the same, execpt that it's not read
  18 # if zsh is started with -f
  19 #
  20 # Global Order: zshenv, zprofile, zshrc, zlogin
  21 ################################################################################
  22
  23 # language settings (read in /etc/environment before /etc/default/locale as
  24 # the latter one is the default on Debian nowadays)
  25 # no xsource() here because it's only created in zshrc! (which is good)
  26 [[ -r /etc/environment ]] && source /etc/environment
  27
  28 # set environment variables (important for autologin on tty)
  29 if [ -n "${HOSTNAME}" ] ; then
  30   export HOSTNAME="${HOSTNAME}"
  31 elif [[ -x $(which hostname) ]] ; then
  32   export HOSTNAME="$(hostname)"
  33 elif [[ -x $(which hostnamectl) ]] ; then
  34   export HOSTNAME="$(hostnamectl --static)"
  35 fi
  36
  37 # make sure /usr/bin/id is available
  38 if [[ -x /usr/bin/id ]] ; then
  39     [[ -z "$USER" ]]          && export USER=$(/usr/bin/id -un)
  40     [[ $LOGNAME == LOGIN ]] && LOGNAME=$(/usr/bin/id -un)
  41 fi
  42
  43 # workaround for live-cd mode as $HOME is not set via rungetty
  44 if [[ -f /etc/grml_cd ]] ; then
  45     if (( EUID == 0 )); then
  46         export HOME=/root
  47     else
  48         export HOME=/home/$USER
  49     fi
  50 fi
  51
  52 ## set $PATH
  53 # gentoo users have to source /etc/profile.env
  54 if [[ -r /etc/gentoo-release ]] ; then
  55     [[ -r /etc/profile.env ]] && source /etc/profile.env
  56 fi
  57
  58 # support extra scripts/software in special directory outside of squashfs environment in live mode
  59 if [[ -f /etc/grml_cd ]] ; then
  60   [[ -r /run/live/medium/scripts ]] && ADDONS='/run/live/medium/scripts'
  61   [[ -r /etc/grml/my_path ]] && ADDONS="$(cat /etc/grml/my_path)"
  62 fi
  63
  64 # Solaris
  65 case $(uname 2>/dev/null) in
  66   SunOS)
  67     path=(
  68       /usr/bin
  69       /usr/sbin
  70       /usr/ccs/bin
  71       /opt/SUNWspro/bin
  72       /usr/ucb
  73       /usr/sfw/bin
  74       /usr/gnu/bin
  75       /usr/openwin/bin
  76       /opt/csw/bin
  77       /sbin
  78       ~/bin
  79     )
  80 esac
  81
  82 # generic $PATH handling
  83 if (( EUID != 0 )); then
  84   path=(
  85     $HOME/bin
  86     /usr/local/bin
  87     /usr/bin
  88     /bin
  89     /usr/local/sbin
  90     /usr/sbin
  91     /sbin
  92     /usr/local/games
  93     /usr/games
  94     "${ADDONS}"
  95     "${path[@]}"
  96   )
  97 else
  98   path=(
  99     $HOME/bin
 100     /usr/local/sbin
 101     /usr/local/bin
 102     /sbin
 103     /bin
 104     /usr/sbin
 105     /usr/bin
 106     "${ADDONS}"
 107     "${path[@]}"
 108   )
 109 fi
 110
 111 # remove empty components to avoid '::' ending up + resulting in './' being in $PATH
 112 path=( "${path[@]:#}" )
 113
 114 typeset -U path
 115
 116 # less (:=pager) options:
 117 #  export LESS=C
 118 typeset -a lp; lp=( ${^path}/lesspipe(N) )
 119 if (( $#lp > 0 )) && [[ -x $lp[1] ]] ; then
 120     export LESSOPEN="|lesspipe %s"
 121 elif [[ -x /usr/bin/lesspipe.sh ]] ; then
 122     export LESSOPEN="|lesspipe.sh %s"
 123 fi
 124 unset lp
 125
 126 export READNULLCMD=${PAGER:-/usr/bin/pager}
 127
 128 # allow zeroconf for distcc
 129 export DISTCC_HOSTS="+zeroconf"
 130
 131 # MAKEDEV should be usable on udev as well by default:
 132 export WRITE_ON_UDEV=yes
 133
 134 ## END OF FILE #################################################################
 135 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4