etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is439(){
 148     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 #f1# Checks whether or not you're running grml
 154 isgrml(){
 155     [[ -f /etc/grml_version ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running a grml cd
 160 isgrmlcd(){
 161     [[ -f /etc/grml_cd ]] && return 0
 162     return 1
 163 }
 164
 165 if isgrml ; then
 166 #f1# Checks whether or not you're running grml-small
 167     isgrmlsmall() {
 168         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 169             return 0
 170         fi
 171         return 1
 172     }
 173 else
 174     isgrmlsmall() { return 1 }
 175 fi
 176
 177 isdarwin(){
 178     [[ $OSTYPE == darwin* ]] && return 0
 179     return 1
 180 }
 181
 182 isfreebsd(){
 183     [[ $OSTYPE == freebsd* ]] && return 0
 184     return 1
 185 }
 186
 187 #f1# are we running within an utf environment?
 188 isutfenv() {
 189     case "$LANG $CHARSET $LANGUAGE" in
 190         *utf*) return 0 ;;
 191         *UTF*) return 0 ;;
 192         *)     return 1 ;;
 193     esac
 194 }
 195
 196 # check for user, if not running as root set $SUDO to sudo
 197 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 198
 199 # change directory to home on first invocation of zsh
 200 # important for rungetty -> autologin
 201 # Thanks go to Bart Schaefer!
 202 isgrml && checkhome() {
 203     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 204         export ALREADY_DID_CD_HOME=$HOME
 205         cd
 206     fi
 207 }
 208
 209 # check for zsh v3.1.7+
 210
 211 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 212      || ${ZSH_VERSION} == 3.<2->.<->*    \
 213      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 214
 215     printf '-!-\n'
 216     printf '-!- In this configuration we try to make use of features, that only\n'
 217     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 218     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 219     printf '-!- advanced features in all supported versions.\n'
 220     printf '-!-\n'
 221     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 222     printf '-!-\n'
 223     printf '-!- While this *may* work, it might as well fail.\n'
 224     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 225     printf '-!-\n'
 226     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 227     printf '-!- If it does today, you'\''ve been lucky.\n'
 228     printf '-!-\n'
 229     printf '-!- Ye been warned!\n'
 230     printf '-!-\n'
 231
 232     function zstyle() { : }
 233 fi
 234
 235 # autoload wrapper - use this one instead of autoload directly
 236 # We need to define this function as early as this, because autoloading
 237 # 'is-at-least()' needs it.
 238 function zrcautoload() {
 239     emulate -L zsh
 240     setopt extended_glob
 241     local fdir ffile
 242     local -i ffound
 243
 244     ffile=$1
 245     (( ffound = 0 ))
 246     for fdir in ${fpath} ; do
 247         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 248     done
 249
 250     (( ffound == 0 )) && return 1
 251     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 252         autoload -U ${ffile} || return 1
 253     else
 254         autoload ${ffile} || return 1
 255     fi
 256     return 0
 257 }
 258
 259 # Load is-at-least() for more precise version checks Note that this test will
 260 # *always* fail, if the is-at-least function could not be marked for
 261 # autoloading.
 262 zrcautoload is-at-least || is-at-least() { return 1 }
 263
 264 # set some important options (as early as possible)
 265
 266 # append history list to the history file; this is the default but we make sure
 267 # because it's required for share_history.
 268 setopt append_history
 269
 270 # import new commands from the history file also in other zsh-session
 271 is4 && setopt share_history
 272
 273 # save each command's beginning timestamp and the duration to the history file
 274 setopt extended_history
 275
 276 # If a new command line being added to the history list duplicates an older
 277 # one, the older command is removed from the list
 278 is4 && setopt histignorealldups
 279
 280 # remove command lines from the history list when the first character on the
 281 # line is a space
 282 setopt histignorespace
 283
 284 # if a command is issued that can't be executed as a normal command, and the
 285 # command is the name of a directory, perform the cd command to that directory.
 286 setopt auto_cd
 287
 288 # in order to use #, ~ and ^ for filename generation grep word
 289 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 290 # don't forget to quote '^', '~' and '#'!
 291 setopt extended_glob
 292
 293 # display PID when suspending processes as well
 294 setopt longlistjobs
 295
 296 # try to avoid the 'zsh: no matches found...'
 297 setopt nonomatch
 298
 299 # report the status of backgrounds jobs immediately
 300 setopt notify
 301
 302 # whenever a command completion is attempted, make sure the entire command path
 303 # is hashed first.
 304 setopt hash_list_all
 305
 306 # not just at the end
 307 setopt completeinword
 308
 309 # Don't send SIGHUP to background processes when the shell exits.
 310 setopt nohup
 311
 312 # make cd push the old directory onto the directory stack.
 313 setopt auto_pushd
 314
 315 # avoid "beep"ing
 316 setopt nobeep
 317
 318 # don't push the same dir twice.
 319 setopt pushd_ignore_dups
 320
 321 # * shouldn't match dotfiles. ever.
 322 setopt noglobdots
 323
 324 # use zsh style word splitting
 325 setopt noshwordsplit
 326
 327 # don't error out when unset parameters are used
 328 setopt unset
 329
 330 # setting some default values
 331 NOCOR=${NOCOR:-0}
 332 NOMENU=${NOMENU:-0}
 333 NOPRECMD=${NOPRECMD:-0}
 334 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 335 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 336 BATTERY=${BATTERY:-0}
 337 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 338 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 339
 340 typeset -ga ls_options
 341 typeset -ga grep_options
 342 if ls --help 2> /dev/null | grep -q GNU; then
 343     ls_options=( --color=auto )
 344 elif [[ $OSTYPE == freebsd* ]]; then
 345     ls_options=( -G )
 346 fi
 347 if grep --help 2> /dev/null | grep -q GNU || \
 348    [[ $OSTYPE == freebsd* ]]; then
 349     grep_options=( --color=auto )
 350 fi
 351
 352 # utility functions
 353 # this function checks if a command exists and returns either true
 354 # or false. This avoids using 'which' and 'whence', which will
 355 # avoid problems with aliases for which on certain weird systems. :-)
 356 # Usage: check_com [-c|-g] word
 357 #   -c  only checks for external commands
 358 #   -g  does the usual tests and also checks for global aliases
 359 check_com() {
 360     emulate -L zsh
 361     local -i comonly gatoo
 362
 363     if [[ $1 == '-c' ]] ; then
 364         (( comonly = 1 ))
 365         shift
 366     elif [[ $1 == '-g' ]] ; then
 367         (( gatoo = 1 ))
 368     else
 369         (( comonly = 0 ))
 370         (( gatoo = 0 ))
 371     fi
 372
 373     if (( ${#argv} != 1 )) ; then
 374         printf 'usage: check_com [-c] <command>\n' >&2
 375         return 1
 376     fi
 377
 378     if (( comonly > 0 )) ; then
 379         [[ -n ${commands[$1]}  ]] && return 0
 380         return 1
 381     fi
 382
 383     if   [[ -n ${commands[$1]}    ]] \
 384       || [[ -n ${functions[$1]}   ]] \
 385       || [[ -n ${aliases[$1]}     ]] \
 386       || [[ -n ${reswords[(r)$1]} ]] ; then
 387
 388         return 0
 389     fi
 390
 391     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 392         return 0
 393     fi
 394
 395     return 1
 396 }
 397
 398 # creates an alias and precedes the command with
 399 # sudo if $EUID is not zero.
 400 salias() {
 401     emulate -L zsh
 402     local only=0 ; local multi=0
 403     while [[ $1 == -* ]] ; do
 404         case $1 in
 405             (-o) only=1 ;;
 406             (-a) multi=1 ;;
 407             (--) shift ; break ;;
 408             (-h)
 409                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 410                 printf '  -h      shows this help text.\n'
 411                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 412                 printf '          be careful using this option.\n'
 413                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 414                 return 0
 415                 ;;
 416             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 417         esac
 418         shift
 419     done
 420
 421     if (( ${#argv} > 1 )) ; then
 422         printf 'Too many arguments %s\n' "${#argv}"
 423         return 1
 424     fi
 425
 426     key="${1%%\=*}" ;  val="${1#*\=}"
 427     if (( EUID == 0 )) && (( only == 0 )); then
 428         alias -- "${key}=${val}"
 429     elif (( EUID > 0 )) ; then
 430         (( multi > 0 )) && val="${val// ; / ; sudo }"
 431         alias -- "${key}=sudo ${val}"
 432     fi
 433
 434     return 0
 435 }
 436
 437 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 438 # usage: uprint foo
 439 #   Where foo is the *name* of the parameter you want printed.
 440 #   Note that foo is no typo; $foo would be wrong here!
 441 if ! is42 ; then
 442     uprint () {
 443         emulate -L zsh
 444         local -a u
 445         local w
 446         local parameter=$1
 447
 448         if [[ -z ${parameter} ]] ; then
 449             printf 'usage: uprint <parameter>\n'
 450             return 1
 451         fi
 452
 453         for w in ${(P)parameter} ; do
 454             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 455         done
 456
 457         builtin print -l $u
 458     }
 459 fi
 460
 461 # Check if we can read given files and source those we can.
 462 xsource() {
 463     if (( ${#argv} < 1 )) ; then
 464         printf 'usage: xsource FILE(s)...\n' >&2
 465         return 1
 466     fi
 467
 468     while (( ${#argv} > 0 )) ; do
 469         [[ -r "$1" ]] && source "$1"
 470         shift
 471     done
 472     return 0
 473 }
 474
 475 # Check if we can read a given file and 'cat(1)' it.
 476 xcat() {
 477     emulate -L zsh
 478     if (( ${#argv} != 1 )) ; then
 479         printf 'usage: xcat FILE\n' >&2
 480         return 1
 481     fi
 482
 483     [[ -r $1 ]] && cat $1
 484     return 0
 485 }
 486
 487 # Remove these functions again, they are of use only in these
 488 # setup files. This should be called at the end of .zshrc.
 489 xunfunction() {
 490     emulate -L zsh
 491     local -a funcs
 492     funcs=(salias xcat xsource xunfunction zrcautoload)
 493
 494     for func in $funcs ; do
 495         [[ -n ${functions[$func]} ]] \
 496             && unfunction $func
 497     done
 498     return 0
 499 }
 500
 501 # this allows us to stay in sync with grml's zshrc and put own
 502 # modifications in ~/.zshrc.local
 503 zrclocal() {
 504     xsource "/etc/zsh/zshrc.local"
 505     xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
 506     return 0
 507 }
 508
 509 # locale setup
 510 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 511     xsource "/etc/default/locale"
 512 fi
 513
 514 for var in LANG LC_ALL LC_MESSAGES ; do
 515     [[ -n ${(P)var} ]] && export $var
 516 done
 517
 518 xsource "/etc/sysconfig/keyboard"
 519
 520 TZ=$(xcat /etc/timezone)
 521
 522 # set some variables
 523 if check_com -c vim ; then
 524 #v#
 525     export EDITOR=${EDITOR:-vim}
 526 else
 527     export EDITOR=${EDITOR:-vi}
 528 fi
 529
 530 #v#
 531 export PAGER=${PAGER:-less}
 532
 533 #v#
 534 export MAIL=${MAIL:-/var/mail/$USER}
 535
 536 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 537 export SHELL='/bin/zsh'
 538
 539 # color setup for ls:
 540 check_com -c dircolors && eval $(dircolors -b)
 541 # color setup for ls on OS X / FreeBSD:
 542 isdarwin && export CLICOLOR=1
 543 isfreebsd && export CLICOLOR=1
 544
 545 # do MacPorts setup on darwin
 546 if isdarwin && [[ -d /opt/local ]]; then
 547     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 548     # zshenv.
 549     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 550     MANPATH="/opt/local/share/man:$MANPATH"
 551 fi
 552 # do Fink setup on darwin
 553 isdarwin && xsource /sw/bin/init.sh
 554
 555 # load our function and completion directories
 556 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 557     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 558     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 559         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 560             zrcautoload ${func:t}
 561         done
 562     fi
 563 done
 564 unset fdir func
 565
 566 # support colors in less
 567 export LESS_TERMCAP_mb=$'\E[01;31m'
 568 export LESS_TERMCAP_md=$'\E[01;31m'
 569 export LESS_TERMCAP_me=$'\E[0m'
 570 export LESS_TERMCAP_se=$'\E[0m'
 571 export LESS_TERMCAP_so=$'\E[01;44;33m'
 572 export LESS_TERMCAP_ue=$'\E[0m'
 573 export LESS_TERMCAP_us=$'\E[01;32m'
 574
 575 # mailchecks
 576 MAILCHECK=30
 577
 578 # report about cpu-/system-/user-time of command if running longer than
 579 # 5 seconds
 580 REPORTTIME=5
 581
 582 # watch for everyone but me and root
 583 watch=(notme root)
 584
 585 # automatically remove duplicates from these arrays
 586 typeset -U path cdpath fpath manpath
 587
 588 # Remove zle-line-{init,finish} if it looks like it turns smkx. This would be
 589 # better fixed by working with those modes too, but we use way too many
 590 # hardcoded bindings for now.
 591 function remove_widget () {
 592     local name=$1
 593     local cap=$2
 594     if (( ${+functions[$name]} )) && [[ ${functions[$name]} == *${cap}* ]]; then
 595         local w=${widgets[$name]}
 596         zle -D $name
 597         [[ $w == user:* ]] && unfunction ${w#*:}
 598     fi
 599 }
 600 remove_widget zle-line-init smkx
 601 remove_widget zle-line-finish rmkx
 602 unfunction remove_widget
 603
 604 # keybindings
 605 if [[ "$TERM" != emacs ]] ; then
 606     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 607     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 608     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 609     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 610     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 611     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 612     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 613     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 614     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 615     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 616     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 617     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 618     # ncurses stuff:
 619     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 620     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 621     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 622     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 623     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 624     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 625     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 626     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 627 fi
 628
 629 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 630 # use emacs style per default:
 631 bindkey -e
 632 # use vi style:
 633 # bindkey -v
 634
 635 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 636 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 637 beginning-or-end-of-somewhere() {
 638     local hno=$HISTNO
 639     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 640       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 641         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 642     else
 643         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 644         if (( HISTNO != hno )); then
 645             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 646         fi
 647     fi
 648 }
 649 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 650 zle -N end-of-somewhere beginning-or-end-of-somewhere
 651
 652
 653 #if [[ "$TERM" == screen ]] ; then
 654
 655 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 656 ## to beginning/end of buffer on second keypress
 657 ## and to beginning/end of history on (at most) the third keypress
 658 # terminator & non-debian xterm
 659 bindkey '\eOH' beginning-of-somewhere  # home
 660 bindkey '\eOF' end-of-somewhere        # end
 661 # freebsd console
 662 bindkey '\e[H' beginning-of-somewhere   # home
 663 bindkey '\e[F' end-of-somewhere         # end
 664 # xterm,gnome-terminal,quake,etc
 665 bindkey '^[[1~' beginning-of-somewhere  # home
 666 bindkey '^[[4~' end-of-somewhere        # end
 667 # if terminal type is set to 'rxvt':
 668 bindkey '\e[7~' beginning-of-somewhere  # home
 669 bindkey '\e[8~' end-of-somewhere        # end
 670 #fi
 671
 672 bindkey '\e[A'  up-line-or-search       # cursor up
 673 bindkey '\e[B'  down-line-or-search     # <ESC>-
 674
 675 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 676 bindkey "\e[5C" forward-word
 677 bindkey "\e[5D" backward-word
 678 bindkey "\e[1;5C" forward-word
 679 bindkey "\e[1;5D" backward-word
 680 ## the same for alt-left-arrow and alt-right-arrow
 681 bindkey '^[[1;3C' forward-word
 682 bindkey '^[[1;3D' backward-word
 683
 684 # Search backward in the history for a line beginning with the current
 685 # line up to the cursor and move the cursor to the end of the line then
 686 zle -N history-beginning-search-backward-end history-search-end
 687 zle -N history-beginning-search-forward-end  history-search-end
 688 #k# search history backward for entry beginning with typed text
 689 bindkey '^xp'   history-beginning-search-backward-end
 690 #k# search history forward for entry beginning with typed text
 691 bindkey '^xP'   history-beginning-search-forward-end
 692 #k# search history backward for entry beginning with typed text
 693 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 694 #k# search history forward for entry beginning with typed text
 695 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 696
 697 # bindkey -s '^l' "|less\n"             # ctrl-L pipes to less
 698 # bindkey -s '^b' " &\n"                # ctrl-B runs it in the background
 699
 700 # insert unicode character
 701 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 702 # See for example http://unicode.org/charts/ for unicode characters code
 703 zrcautoload insert-unicode-char
 704 zle -N insert-unicode-char
 705 #k# Insert Unicode character
 706 bindkey '^xi' insert-unicode-char
 707
 708 #m# k Shift-tab Perform backwards menu completion
 709 if [[ -n "$terminfo[kcbt]" ]]; then
 710     bindkey "$terminfo[kcbt]" reverse-menu-complete
 711 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 712     bindkey "$terminfo[cbt]"  reverse-menu-complete
 713 fi
 714
 715 ## toggle the ,. abbreviation feature on/off
 716 # NOABBREVIATION: default abbreviation-state
 717 #                 0 - enabled (default)
 718 #                 1 - disabled
 719 NOABBREVIATION=${NOABBREVIATION:-0}
 720
 721 grml_toggle_abbrev() {
 722     if (( ${NOABBREVIATION} > 0 )) ; then
 723         NOABBREVIATION=0
 724     else
 725         NOABBREVIATION=1
 726     fi
 727 }
 728
 729 #k# Toggle abbreviation expansion on/off
 730 zle -N grml_toggle_abbrev
 731 bindkey '^xA' grml_toggle_abbrev
 732
 733 # add a command line to the shells history without executing it
 734 commit-to-history() {
 735     print -s ${(z)BUFFER}
 736     zle send-break
 737 }
 738 zle -N commit-to-history
 739 bindkey "^x^h" commit-to-history
 740
 741 # only slash should be considered as a word separator:
 742 slash-backward-kill-word() {
 743     local WORDCHARS="${WORDCHARS:s@/@}"
 744     # zle backward-word
 745     zle backward-kill-word
 746 }
 747 zle -N slash-backward-kill-word
 748
 749 #k# Kill left-side word or everything up to next slash
 750 bindkey '\ev' slash-backward-kill-word
 751 #k# Kill left-side word or everything up to next slash
 752 bindkey '\e^h' slash-backward-kill-word
 753 #k# Kill left-side word or everything up to next slash
 754 bindkey '\e^?' slash-backward-kill-word
 755
 756 # use the new *-pattern-* widgets for incremental history search
 757 if is439 ; then
 758     bindkey '^r' history-incremental-pattern-search-backward
 759     bindkey '^s' history-incremental-pattern-search-forward
 760 fi
 761
 762 # a generic accept-line wrapper
 763
 764 # This widget can prevent unwanted autocorrections from command-name
 765 # to _command-name, rehash automatically on enter and call any number
 766 # of builtin and user-defined widgets in different contexts.
 767 #
 768 # For a broader description, see:
 769 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 770 #
 771 # The code is imported from the file 'zsh/functions/accept-line' from
 772 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 773 # distributed under the same terms as zsh itself.
 774
 775 # A newly added command will may not be found or will cause false
 776 # correction attempts, if you got auto-correction set. By setting the
 777 # following style, we force accept-line() to rehash, if it cannot
 778 # find the first word on the command line in the $command[] hash.
 779 zstyle ':acceptline:*' rehash true
 780
 781 function Accept-Line() {
 782     setopt localoptions noksharrays
 783     local -a subs
 784     local -xi aldone
 785     local sub
 786     local alcontext=${1:-$alcontext}
 787
 788     zstyle -a ":acceptline:${alcontext}" actions subs
 789
 790     (( ${#subs} < 1 )) && return 0
 791
 792     (( aldone = 0 ))
 793     for sub in ${subs} ; do
 794         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 795         zle ${sub}
 796
 797         (( aldone > 0 )) && break
 798     done
 799 }
 800
 801 function Accept-Line-getdefault() {
 802     emulate -L zsh
 803     local default_action
 804
 805     zstyle -s ":acceptline:${alcontext}" default_action default_action
 806     case ${default_action} in
 807         ((accept-line|))
 808             printf ".accept-line"
 809             ;;
 810         (*)
 811             printf ${default_action}
 812             ;;
 813     esac
 814 }
 815
 816 function Accept-Line-HandleContext() {
 817     zle Accept-Line
 818
 819     default_action=$(Accept-Line-getdefault)
 820     zstyle -T ":acceptline:${alcontext}" call_default \
 821         && zle ${default_action}
 822 }
 823
 824 function accept-line() {
 825     setopt localoptions noksharrays
 826     local -ax cmdline
 827     local -x alcontext
 828     local buf com fname format msg default_action
 829
 830     alcontext='default'
 831     buf="${BUFFER}"
 832     cmdline=(${(z)BUFFER})
 833     com="${cmdline[1]}"
 834     fname="_${com}"
 835
 836     Accept-Line 'preprocess'
 837
 838     zstyle -t ":acceptline:${alcontext}" rehash \
 839         && [[ -z ${commands[$com]} ]]           \
 840         && rehash
 841
 842     if    [[ -n ${com}               ]] \
 843        && [[ -n ${reswords[(r)$com]} ]] \
 844        || [[ -n ${aliases[$com]}     ]] \
 845        || [[ -n ${functions[$com]}   ]] \
 846        || [[ -n ${builtins[$com]}    ]] \
 847        || [[ -n ${commands[$com]}    ]] ; then
 848
 849         # there is something sensible to execute, just do it.
 850         alcontext='normal'
 851         Accept-Line-HandleContext
 852
 853         return
 854     fi
 855
 856     if    [[ -o correct              ]] \
 857        || [[ -o correctall           ]] \
 858        && [[ -n ${functions[$fname]} ]] ; then
 859
 860         # nothing there to execute but there is a function called
 861         # _command_name; a completion widget. Makes no sense to
 862         # call it on the commandline, but the correct{,all} options
 863         # will ask for it nevertheless, so warn the user.
 864         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 865             # Okay, we warned the user before, he called us again,
 866             # so have it his way.
 867             alcontext='force'
 868             Accept-Line-HandleContext
 869
 870             return
 871         fi
 872
 873         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 874             alcontext='normal'
 875             Accept-Line-HandleContext
 876         else
 877             # prepare warning message for the user, configurable via zstyle.
 878             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 879
 880             if [[ -z ${msg} ]] ; then
 881                 msg="%c will not execute and completion %f exists."
 882             fi
 883
 884             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 885
 886             zle -M -- "${msg}"
 887         fi
 888         return
 889     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 890         # If we are here, the commandline contains something that is not
 891         # executable, which is neither subject to _command_name correction
 892         # and is not empty. might be a variable assignment
 893         alcontext='misc'
 894         Accept-Line-HandleContext
 895
 896         return
 897     fi
 898
 899     # If we got this far, the commandline only contains whitespace, or is empty.
 900     alcontext='empty'
 901     Accept-Line-HandleContext
 902 }
 903
 904 zle -N accept-line
 905 zle -N Accept-Line
 906 zle -N Accept-Line-HandleContext
 907
 908 # power completion - abbreviation expansion
 909 # power completion / abbreviation expansion / buffer expansion
 910 # see http://zshwiki.org/home/examples/zleiab for details
 911 # less risky than the global aliases but powerful as well
 912 # just type the abbreviation key and afterwards ',.' to expand it
 913 declare -A abk
 914 setopt extendedglob
 915 setopt interactivecomments
 916 abk=(
 917 #   key   # value                  (#d additional doc string)
 918 #A# start
 919     '...'  '../..'
 920     '....' '../../..'
 921     'BG'   '& exit'
 922     'C'    '| wc -l'
 923     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
 924     'H'    '| head'
 925     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 926     'L'    '| less'
 927     'LL'   '|& less -r'
 928     'M'    '| most'
 929     'N'    '&>/dev/null'           #d (No Output)
 930     'R'    '| tr A-z N-za-m'       #d (ROT13)
 931     'SL'   '| sort | less'
 932     'S'    '| sort -u'
 933     'T'    '| tail'
 934     'V'    '|& vim -'
 935 #A# end
 936     'co'   './configure && make && sudo make install'
 937 )
 938
 939 zleiab() {
 940     emulate -L zsh
 941     setopt extendedglob
 942     local MATCH
 943
 944     if (( NOABBREVIATION > 0 )) ; then
 945         LBUFFER="${LBUFFER},."
 946         return 0
 947     fi
 948
 949     LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
 950     LBUFFER+=${abk[$MATCH]:-$MATCH}
 951 }
 952
 953 zle -N zleiab && bindkey ",." zleiab
 954
 955 #f# display contents of assoc array $abk
 956 help-show-abk()
 957 {
 958   zle -M "$(print "Type ,. after these abbreviations to expand them:"; print -a -C 2 ${(kv)abk})"
 959 }
 960 #k# Display list of abbreviations that expand when followed by ,.
 961 zle -N help-show-abk && bindkey '^xb' help-show-abk
 962
 963 # autoloading
 964 zrcautoload zmv    # who needs mmv or rename?
 965 zrcautoload history-search-end
 966
 967 # we don't want to quote/espace URLs on our own...
 968 # if autoload -U url-quote-magic ; then
 969 #    zle -N self-insert url-quote-magic
 970 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 971 # else
 972 #    print 'Notice: no url-quote-magic available :('
 973 # fi
 974 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 975
 976 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 977 alias run-help >&/dev/null && unalias run-help
 978 for rh in run-help{,-git,-svk,-svn}; do
 979     zrcautoload $rh
 980 done; unset rh
 981
 982 # completion system
 983 if zrcautoload compinit ; then
 984     compinit || print 'Notice: no compinit available :('
 985 else
 986     print 'Notice: no compinit available :('
 987     function compdef { }
 988 fi
 989
 990 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 991
 992 is4 && \
 993 for mod in complist deltochar mathfunc ; do
 994     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 995 done
 996
 997 # autoload zsh modules when they are referenced
 998 if is4 ; then
 999     zmodload -a  zsh/stat    zstat
1000     zmodload -a  zsh/zpty    zpty
1001     zmodload -ap zsh/mapfile mapfile
1002 fi
1003
1004 if is4 && zrcautoload insert-files && zle -N insert-files ; then
1005     #k# Insert files and test globbing
1006     bindkey "^xf" insert-files # C-x-f
1007 fi
1008
1009 bindkey ' '   magic-space    # also do history expansion on space
1010 #k# Trigger menu-complete
1011 bindkey '\ei' menu-complete  # menu completion via esc-i
1012
1013 # press esc-e for editing command line in $EDITOR or $VISUAL
1014 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
1015     #k# Edit the current line in \kbd{\$EDITOR}
1016     bindkey '\ee' edit-command-line
1017 fi
1018
1019 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
1020     #k# menu selection: pick item but stay in the menu
1021     bindkey -M menuselect '\e^M' accept-and-menu-complete
1022     # also use + and INSERT since it's easier to press repeatedly
1023     bindkey -M menuselect "+" accept-and-menu-complete
1024     bindkey -M menuselect "^[[2~" accept-and-menu-complete
1025
1026     # accept a completion and try to complete again by using menu
1027     # completion; very useful with completing directories
1028     # by using 'undo' one's got a simple file browser
1029     bindkey -M menuselect '^o' accept-and-infer-next-history
1030 fi
1031
1032 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1033 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1034 zle -N insert-datestamp
1035
1036 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1037 bindkey '^ed' insert-datestamp
1038
1039 # press esc-m for inserting last typed word again (thanks to caphuso!)
1040 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1041 zle -N insert-last-typed-word;
1042
1043 #k# Insert last typed word
1044 bindkey "\em" insert-last-typed-word
1045
1046 function grml-zsh-fg() {
1047   if (( ${#jobstates} )); then
1048     zle .push-input
1049     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1050     BUFFER="${BUFFER}fg"
1051     zle .accept-line
1052   else
1053     zle -M 'No background jobs. Doing nothing.'
1054   fi
1055 }
1056 zle -N grml-zsh-fg
1057 #k# A smart shortcut for \kbd{fg<enter>}
1058 bindkey '^z' grml-zsh-fg
1059
1060 # run command line as user root via sudo:
1061 sudo-command-line() {
1062     [[ -z $BUFFER ]] && zle up-history
1063     if [[ $BUFFER != sudo\ * ]]; then
1064         BUFFER="sudo $BUFFER"
1065         CURSOR=$(( CURSOR+5 ))
1066     fi
1067 }
1068 zle -N sudo-command-line
1069
1070 #k# prepend the current command with "sudo"
1071 bindkey "^os" sudo-command-line
1072
1073 ### jump behind the first word on the cmdline.
1074 ### useful to add options.
1075 function jump_after_first_word() {
1076     local words
1077     words=(${(z)BUFFER})
1078
1079     if (( ${#words} <= 1 )) ; then
1080         CURSOR=${#BUFFER}
1081     else
1082         CURSOR=${#${words[1]}}
1083     fi
1084 }
1085 zle -N jump_after_first_word
1086 #k# jump to after first word (for adding options)
1087 bindkey '^x1' jump_after_first_word
1088
1089 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1090 zle -C hist-complete complete-word _generic
1091 zstyle ':completion:hist-complete:*' completer _history
1092 #k# complete word from history with menu
1093 bindkey "^x^x" hist-complete
1094
1095 ## complete word from currently visible Screen or Tmux buffer.
1096 if check_com -c screen || check_com -c tmux; then
1097     _complete_screen_display() {
1098         [[ "$TERM" != "screen" ]] && return 1
1099
1100         local TMPFILE=$(mktemp)
1101         local -U -a _screen_display_wordlist
1102         trap "rm -f $TMPFILE" EXIT
1103
1104         # fill array with contents from screen hardcopy
1105         if ((${+TMUX})); then
1106             #works, but crashes tmux below version 1.4
1107             #luckily tmux -V option to ask for version, was also added in 1.4
1108             tmux -V &>/dev/null || return
1109             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1110         else
1111             screen -X hardcopy $TMPFILE
1112             # screen sucks, it dumps in latin1, apparently always. so recode it
1113             # to system charset
1114             check_com recode && recode latin1 $TMPFILE
1115         fi
1116         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1117         # remove PREFIX to be completed from that array
1118         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1119         compadd -a _screen_display_wordlist
1120     }
1121     #k# complete word from currently visible GNU screen buffer
1122     bindkey -r "^xS"
1123     compdef -k _complete_screen_display complete-word '^xS'
1124 fi
1125
1126 # history
1127
1128 ZSHDIR=${ZDOTDIR:-${HOME}/.zsh}
1129
1130 #v#
1131 HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1132 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1133 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1134
1135 # dirstack handling
1136
1137 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1138 DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1139
1140 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1141     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1142     # "cd -" won't work after login by just setting $OLDPWD, so
1143     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1144 fi
1145
1146 chpwd() {
1147     local -ax my_stack
1148     my_stack=( ${PWD} ${dirstack} )
1149     if is42 ; then
1150         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1151     else
1152         uprint my_stack >! ${DIRSTACKFILE}
1153     fi
1154 }
1155
1156 # directory based profiles
1157
1158 if is433 ; then
1159
1160 # chpwd_profiles(): Directory Profiles, Quickstart:
1161 #
1162 # In .zshrc.local:
1163 #
1164 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1165 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1166 #   chpwd_profiles
1167 #
1168 # For details see the `grmlzshrc.5' manual page.
1169 function chpwd_profiles() {
1170     local profile context
1171     local -i reexecute
1172
1173     context=":chpwd:profiles:$PWD"
1174     zstyle -s "$context" profile profile || profile='default'
1175     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1176
1177     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1178         typeset -g CHPWD_PROFILE
1179         local CHPWD_PROFILES_INIT=1
1180         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1181     elif [[ $profile != $CHPWD_PROFILE ]]; then
1182         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1183             && chpwd_leave_profile_${CHPWD_PROFILE}
1184     fi
1185     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1186         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1187     fi
1188
1189     CHPWD_PROFILE="${profile}"
1190     return 0
1191 }
1192
1193 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1194
1195 fi # is433
1196
1197 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1198 if [[ $BATTERY -gt 0 ]] ; then
1199     if ! check_com -c acpi ; then
1200         BATTERY=0
1201     fi
1202 fi
1203
1204 battery() {
1205 if [[ $BATTERY -gt 0 ]] ; then
1206     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1207     if [[ -z "$PERCENT" ]] ; then
1208         PERCENT='acpi not present'
1209     else
1210         if [[ "$PERCENT" -lt 20 ]] ; then
1211             PERCENT="warning: ${PERCENT}%%"
1212         else
1213             PERCENT="${PERCENT}%%"
1214         fi
1215     fi
1216 fi
1217 }
1218 # set colors for use in prompts
1219 if zrcautoload colors && colors 2>/dev/null ; then
1220     BLUE="%{${fg[blue]}%}"
1221     RED="%{${fg_bold[red]}%}"
1222     GREEN="%{${fg[green]}%}"
1223     CYAN="%{${fg[cyan]}%}"
1224     MAGENTA="%{${fg[magenta]}%}"
1225     YELLOW="%{${fg[yellow]}%}"
1226     WHITE="%{${fg[white]}%}"
1227     NO_COLOR="%{${reset_color}%}"
1228 else
1229     BLUE=$'%{\e[1;34m%}'
1230     RED=$'%{\e[1;31m%}'
1231     GREEN=$'%{\e[1;32m%}'
1232     CYAN=$'%{\e[1;36m%}'
1233     WHITE=$'%{\e[1;37m%}'
1234     MAGENTA=$'%{\e[1;35m%}'
1235     YELLOW=$'%{\e[1;33m%}'
1236     NO_COLOR=$'%{\e[0m%}'
1237 fi
1238
1239 # gather version control information for inclusion in a prompt
1240
1241 if zrcautoload vcs_info; then
1242     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1243     # function, which can cause a lot of trouble with our directory-based
1244     # profiles. So:
1245     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1246         function VCS_INFO_realpath () {
1247             setopt localoptions NO_shwordsplit chaselinks
1248             ( builtin cd -q $1 2> /dev/null && pwd; )
1249         }
1250     fi
1251
1252     zstyle ':vcs_info:*' max-exports 2
1253
1254     if [[ -o restricted ]]; then
1255         zstyle ':vcs_info:*' enable NONE
1256     fi
1257 fi
1258
1259 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1260 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1261 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1262 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1263 #       to $vcs_info_msg_N_ as soon as we use the included version.
1264 if [[ "$TERM" == dumb ]] ; then
1265     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1266     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1267 else
1268     # these are the same, just with a lot of colors:
1269     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} " \
1270                                        "zsh: %r"
1271     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR}%} " \
1272                                        "zsh: %r"
1273     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1274 fi
1275
1276 # command not found handling
1277
1278 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1279 function command_not_found_handler() {
1280     emulate -L zsh
1281     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1282         ${GRML_ZSH_CNF_HANDLER} $1
1283     fi
1284     return 1
1285 }
1286
1287 function prompt_grml_help () {
1288     cat <<__EOF0__
1289   prompt grml
1290
1291     This is the prompt as used by the grml-live system <http://grml.org>. It is
1292     a rather simple one-line prompt, that by default looks something like this:
1293
1294         <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1295
1296     The prompt itself integrates with zsh's prompt themes system (as you are
1297     witnessing right now) and is configurable to a certain degree. In
1298     particular, these aspects are customisable:
1299
1300         - The items used in the prompt (e.g. you can remove \`user' from
1301           the list of activated items, which will cause the user name to
1302           be omitted from the prompt string).
1303
1304         - The attributes used with the items are customisable via strings
1305           used before and after the actual item.
1306
1307     The available items are: rc, rc-always, change-root, user, at, host, path,
1308     vcs, percent, sad-smiley.
1309
1310     The actual configuration is done via zsh's \`zstyle' mechanism. The
1311     context, that is used while looking up styles is:
1312
1313         ':prompt:grml:<left-or-right>:<subcontext>'
1314
1315     Here <left-or-right> is either \`left' or \`right', signifying whether the
1316     style should affect the left or the right prompt. <subcontext> is either
1317     \`setup' or 'items:<item>', where \`<item>' is one of the available items.
1318
1319     The styles:
1320
1321         - use-rprompt (boolean): If \`true' (the default), print a sad smiley
1322           in $RPROMPT if the last command a returned non-successful error code.
1323           (This in only valid if <left-or-right> is "right"; ignored otherwise)
1324
1325         - items (list): The list of items used in the prompt. If \`vcs' is
1326           present in the list, the theme's code invokes \`vcs_info'
1327           accordingly. Default: rc user change-root at host path vcs precent
1328
1329     Available styles in 'items:<item>' are: pre, post. These are strings that
1330     are inserted before (pre) and after (post) the item in question. Thus, the
1331     following would cause the user name to be printed in red instead of the
1332     default blue:
1333
1334         zstyle ':prompt:grml:*:items:user' pre '%F{red}'
1335
1336     Note, that the \`post' style may remain at its default value, because its
1337     default value is '%f', which turns the foreground text attribute off (which
1338     is exactly, what is still required with the new \`pre' value).
1339 __EOF0__
1340 }
1341
1342 function prompt_grml_setup () {
1343     emulate -L zsh
1344     autoload -Uz vcs_info
1345     autoload -Uz add-zsh-hook
1346     add-zsh-hook precmd prompt_grml_precmd
1347 }
1348
1349 typeset -gA grml_prompt_pre_default \
1350             grml_prompt_post_default \
1351             grml_prompt_token_default
1352
1353 grml_prompt_pre_default=(
1354     rc                '%F{red}'
1355     rc-always         ''
1356     change-root       ''
1357     user              '%B%F{blue}'
1358     at                ''
1359     host              ''
1360     path              '%b'
1361     vcs               ''
1362     percent           ''
1363     sad-smiley        ''
1364 )
1365
1366 grml_prompt_post_default=(
1367     rc                '%f'
1368     rc-always         ''
1369     change-root       ''
1370     user              '%f%b'
1371     at                ''
1372     host              ' '
1373     path              ' %B'
1374     vcs               ''
1375     percent           ' '
1376     sad-smiley        ''
1377 )
1378
1379 grml_prompt_token_default=(
1380     rc                '%(?..%? )'
1381     rc-always         '%?'
1382     change-root       'debian_chroot'
1383     user              '%n'
1384     at                '@'
1385     host              '%m'
1386     path              '%40<..<%~%<<'
1387     vcs               '0'
1388     percent           '%%'
1389     sad-smiley        '%(?..:()'
1390 )
1391
1392 function grml_prompt_addto () {
1393     emulate -L zsh
1394     local target="$1"
1395     local lr it apre apost new v
1396     local -a items
1397     shift
1398
1399     [[ $target == PS1 ]] && lr=left || lr=right
1400     zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
1401     typeset -g "${target}="
1402     for it in "${items[@]}"; do
1403         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
1404             || apre=${grml_prompt_pre_default[$it]}
1405         zstyle -s ":prompt:grml:${grmltheme}:${lr}:$it" post apost \
1406             || apost=${grml_prompt_post_default[$it]}
1407         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
1408             || new=${grml_prompt_token_default[$it]}
1409         typeset -g "${target}=${(P)target}${apre}"
1410         case $it in
1411             change-root)
1412                 if (( ${+parameters[$new]} )); then
1413                     typeset -g "${target}=${(P)target}${(P)new}"
1414                 fi
1415                 ;;
1416             vcs)
1417                 v="vcs_info_msg_${new}_"
1418                 if (( ! vcscalled )); then
1419                     vcs_info
1420                     vcscalled=1
1421                 fi
1422                 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
1423                     typeset -g "${target}=${(P)target}${(P)v}"
1424                 fi
1425                 ;;
1426             *) typeset -g "${target}=${(P)target}${new}" ;;
1427         esac
1428         typeset -g "${target}=${(P)target}${apost}"
1429     done
1430 }
1431
1432 function prompt_grml_precmd () {
1433     emulate -L zsh
1434     local -i vcscalled=0
1435     local grmltheme=grml
1436
1437     grml_prompt_addto PS1 rc change-root user at host path vcs percent
1438     if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
1439         grml_prompt_addto RPS1 sad-smiley
1440     fi
1441 }
1442
1443 # set prompt
1444 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1445     promptinit # people should be able to use their favourite prompt
1446
1447     # Since we define the required functions in here and not in files in
1448     # $fpath, we need to stick the theme's name into `$prompt_themes'
1449     # ourselves, since promptinit does not pick them up otherwise.
1450     prompt_themes+=( grml )
1451     # Also, keep the array sorted...
1452     prompt_themes=( "${(@on)prompt_themes}" )
1453 else
1454     print 'Notice: no promptinit available :('
1455 fi
1456
1457 setopt prompt_subst
1458
1459 # make sure to use right prompt only when not running a command
1460 is41 && setopt transient_rprompt
1461
1462
1463 function ESC_print () {
1464     info_print $'\ek' $'\e\\' "$@"
1465 }
1466 function set_title () {
1467     info_print  $'\e]0;' $'\a' "$@"
1468 }
1469
1470 function info_print () {
1471     local esc_begin esc_end
1472     esc_begin="$1"
1473     esc_end="$2"
1474     shift 2
1475     printf '%s' ${esc_begin}
1476     printf '%s' "$*"
1477     printf '%s' "${esc_end}"
1478 }
1479
1480 function grml_reset_screen_title () {
1481     # adjust title of xterm
1482     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1483     [[ ${NOTITLE:-} -gt 0 ]] && return 0
1484     case $TERM in
1485         (xterm*|rxvt*)
1486             set_title ${(%):-"%n@%m: %~"}
1487             ;;
1488     esac
1489 }
1490
1491 function grml_vcs_to_screen_title () {
1492     if [[ $TERM == screen* ]] ; then
1493         if [[ -n ${vcs_info_msg_1_} ]] ; then
1494             ESC_print ${vcs_info_msg_1_}
1495         else
1496             ESC_print "zsh"
1497         fi
1498     fi
1499 }
1500
1501 zrcautoload add-zsh-hook || add-zsh-hook () { :; }
1502 if [[ $NOPRECMD -gt 0 ]]; then
1503     add-zsh-hook precmd grml_reset_screen_title
1504     add-zsh-hook precmd grml_vcs_to_screen_title
1505 fi
1506
1507 # TODO: revise all these NO* variables and especially their documentation
1508 #       in zsh-help() below.
1509 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1510     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1511     if [[ ${DONTSETRPROMPT:-} -eq 0 ]] ; then
1512         if [[ $BATTERY -gt 0 ]] ; then
1513             # update battery (dropped into $PERCENT) information
1514             battery
1515             RPROMPT="%(?..:() ${PERCENT}"
1516         else
1517             RPROMPT="%(?..:() "
1518         fi
1519     fi
1520 }
1521
1522 # preexec() => a function running before every command
1523 is4 && [[ $NOPRECMD -eq 0 ]] && \
1524 preexec () {
1525     [[ $NOPRECMD -gt 0 ]] && return 0
1526 # set hostname if not running on host with name 'grml'
1527     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1528        NAME="@$HOSTNAME"
1529     fi
1530 # get the name of the program currently running and hostname of local machine
1531 # set screen window title if running in a screen
1532     if [[ "$TERM" == screen* ]] ; then
1533         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1534         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1535         ESC_print ${CMD}
1536     fi
1537 # adjust title of xterm
1538     [[ ${NOTITLE} -gt 0 ]] && return 0
1539     case $TERM in
1540         (xterm*|rxvt*)
1541             set_title "${(%):-"%n@%m:"}" "$1"
1542             ;;
1543     esac
1544 }
1545
1546 EXITCODE="%(?..%?%1v )"
1547 # secondary prompt, printed when the shell needs more information to complete a
1548 # command.
1549 PS2='\`%_> '
1550 # selection prompt used within a select loop.
1551 PS3='?# '
1552 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1553 PS4='+%N:%i:%_> '
1554
1555 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1556 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1557     debian_chroot=$(cat /etc/debian_chroot)
1558 fi
1559
1560 # don't use colors on dumb terminals (like emacs):
1561 if [[ "$TERM" == dumb ]] ; then
1562     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
1563 else
1564     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended
1565     # prompt set variable identifying the chroot you work in (used in the
1566     # prompt below)
1567     if [[ $GRMLPROMPT -gt 0 ]] ; then
1568         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1569 ${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "
1570     else
1571         # This assembles the primary prompt string
1572         if (( EUID != 0 )); then
1573             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "
1574         else
1575             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "
1576         fi
1577     fi
1578 fi
1579
1580 PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
1581
1582 # if we are inside a grml-chroot set a specific prompt theme
1583 if [[ -n "$GRML_CHROOT" ]] ; then
1584     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1585 fi
1586
1587 # 'hash' some often used directories
1588 #d# start
1589 hash -d deb=/var/cache/apt/archives
1590 hash -d doc=/usr/share/doc
1591 hash -d linux=/lib/modules/$(command uname -r)/build/
1592 hash -d log=/var/log
1593 hash -d slog=/var/log/syslog
1594 hash -d src=/usr/src
1595 hash -d templ=/usr/share/doc/grml-templates
1596 hash -d tt=/usr/share/doc/texttools-doc
1597 hash -d www=/var/www
1598 #d# end
1599
1600 # some aliases
1601 if check_com -c screen ; then
1602     if [[ $UID -eq 0 ]] ; then
1603         if [[ -r /etc/grml/screenrc ]]; then
1604             alias screen="${commands[screen]} -c /etc/grml/screenrc"
1605         fi
1606     elif [[ -r $HOME/.screenrc ]] ; then
1607         alias screen="${commands[screen]} -c $HOME/.screenrc"
1608     else
1609         if [[ -r /etc/grml/screenrc_grml ]]; then
1610             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1611         else
1612             if [[ -r /etc/grml/screenrc ]]; then
1613                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
1614             fi
1615         fi
1616     fi
1617 fi
1618
1619 # do we have GNU ls with color-support?
1620 if [[ "$TERM" != dumb ]]; then
1621     #a1# execute \kbd{@a@}:\quad ls with colors
1622     alias ls='ls -b -CF '${ls_options:+"${ls_options[*]}"}
1623     #a1# execute \kbd{@a@}:\quad list all files, with colors
1624     alias la='ls -la '${ls_options:+"${ls_options[*]}"}
1625     #a1# long colored list, without dotfiles (@a@)
1626     alias ll='ls -l '${ls_options:+"${ls_options[*]}"}
1627     #a1# long colored list, human readable sizes (@a@)
1628     alias lh='ls -hAl '${ls_options:+"${ls_options[*]}"}
1629     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1630     alias l='ls -lF '${ls_options:+"${ls_options[*]}"}
1631 else
1632     alias ls='ls -b -CF'
1633     alias la='ls -la'
1634     alias ll='ls -l'
1635     alias lh='ls -hAl'
1636     alias l='ls -lF'
1637 fi
1638
1639 alias mdstat='cat /proc/mdstat'
1640 alias ...='cd ../../'
1641
1642 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1643 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1644     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1645 fi
1646
1647 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1648 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1649 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1650
1651 # make sure it is not assigned yet
1652 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1653 utf2iso() {
1654     if isutfenv ; then
1655         for ENV in $(env | command grep -i '.utf') ; do
1656             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1657         done
1658     fi
1659 }
1660
1661 # make sure it is not assigned yet
1662 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1663 iso2utf() {
1664     if ! isutfenv ; then
1665         for ENV in $(env | command grep -i '\.iso') ; do
1666             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1667         done
1668     fi
1669 }
1670
1671 # especially for roadwarriors using GNU screen and ssh:
1672 if ! check_com asc &>/dev/null ; then
1673   asc() { autossh -t "$@" 'screen -RdU' }
1674   compdef asc=ssh
1675 fi
1676
1677 #f1# Hints for the use of zsh on grml
1678 zsh-help() {
1679     print "$bg[white]$fg[black]
1680 zsh-help - hints for use of zsh on grml
1681 =======================================$reset_color"
1682
1683     print '
1684 Main configuration of zsh happens in /etc/zsh/zshrc.
1685 That file is part of the package grml-etc-core, if you want to
1686 use them on a non-grml-system just get the tar.gz from
1687 http://deb.grml.org/ or (preferably) get it from the git repository:
1688
1689   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1690
1691 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1692 The file is still there, but it is empty for backwards compatibility.
1693
1694 For your own changes use these two files:
1695     $HOME/.zshrc.pre
1696     $HOME/.zshrc.local
1697
1698 The former is sourced very early in our zshrc, the latter is sourced
1699 very lately.
1700
1701 System wide configuration without touching configuration files of grml
1702 can take place in /etc/zsh/zshrc.local.
1703
1704 For information regarding zsh start at http://grml.org/zsh/
1705
1706 Take a look at grml'\''s zsh refcard:
1707 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1708
1709 Check out the main zsh refcard:
1710 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1711
1712 And of course visit the zsh-lovers:
1713 % man zsh-lovers
1714
1715 You can adjust some options through environment variables when
1716 invoking zsh without having to edit configuration files.
1717 Basically meant for bash users who are not used to the power of
1718 the zsh yet. :)
1719
1720   "NOCOR=1    zsh" => deactivate automatic correction
1721   "NOMENU=1   zsh" => do not use auto menu completion
1722                       (note: use ctrl-d for completion instead!)
1723   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1724   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1725                       preexec() and precmd() completely
1726   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1727   "COMMAND_NOT_FOUND=1 zsh"
1728                    => Enable a handler if an external command was not found
1729                       The command called in the handler can be altered by setting
1730                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1731                       "/usr/share/command-not-found/command-not-found"
1732
1733 A value greater than 0 is enables a feature; a value equal to zero
1734 disables it. If you like one or the other of these settings, you can
1735 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1736 zshrc.'
1737
1738     print "
1739 $bg[white]$fg[black]
1740 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1741 Enjoy your grml system with the zsh!$reset_color"
1742 }
1743
1744 # debian stuff
1745 if [[ -r /etc/debian_version ]] ; then
1746     #a3# Execute \kbd{apt-cache search}
1747     alias acs='apt-cache search'
1748     #a3# Execute \kbd{apt-cache show}
1749     alias acsh='apt-cache show'
1750     #a3# Execute \kbd{apt-cache policy}
1751     alias acp='apt-cache policy'
1752     #a3# Execute \kbd{apt-get dist-upgrade}
1753     salias adg="apt-get dist-upgrade"
1754     #a3# Execute \kbd{apt-get install}
1755     salias agi="apt-get install"
1756     #a3# Execute \kbd{aptitude install}
1757     salias ati="aptitude install"
1758     #a3# Execute \kbd{apt-get upgrade}
1759     salias ag="apt-get upgrade"
1760     #a3# Execute \kbd{apt-get update}
1761     salias au="apt-get update"
1762     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1763     salias -a up="aptitude update ; aptitude safe-upgrade"
1764     #a3# Execute \kbd{dpkg-buildpackage}
1765     alias dbp='dpkg-buildpackage'
1766     #a3# Execute \kbd{grep-excuses}
1767     alias ge='grep-excuses'
1768
1769     # get a root shell as normal user in live-cd mode:
1770     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1771        alias su="sudo su"
1772      fi
1773
1774     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1775     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1776     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1777     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1778 fi
1779
1780 # sort installed Debian-packages by size
1781 if check_com -c dpkg-query ; then
1782     #a3# List installed Debian-packages sorted by size
1783     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1784 fi
1785
1786 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1787 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1788     if check_com -c wodim; then
1789         cdrecord() {
1790             cat <<EOMESS
1791 cdrecord is not provided under its original name by Debian anymore.
1792 See #377109 in the BTS of Debian for more details.
1793
1794 Please use the wodim binary instead
1795 EOMESS
1796             return 1
1797         }
1798     fi
1799 fi
1800
1801 # Use hard limits, except for a smaller stack and no core dumps
1802 unlimit
1803 is425 && limit stack 8192
1804 isgrmlcd && limit core 0 # important for a live-cd-system
1805 limit -s
1806
1807 # completion system
1808
1809 # called later (via is4 && grmlcomp)
1810 # note: use 'zstyle' for getting current settings
1811 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
1812 grmlcomp() {
1813     # TODO: This could use some additional information
1814
1815     # allow one error for every three characters typed in approximate completer
1816     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1817
1818     # don't complete backup files as executables
1819     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1820
1821     # start menu completion only if it could find no unambiguous initial string
1822     zstyle ':completion:*:correct:*'       insert-unambiguous true
1823     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1824     zstyle ':completion:*:correct:*'       original true
1825
1826     # activate color-completion
1827     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1828
1829     # format on completion
1830     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1831
1832     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1833     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1834
1835     # insert all expansions for expand completer
1836     zstyle ':completion:*:expand:*'        tag-order all-expansions
1837     zstyle ':completion:*:history-words'   list false
1838
1839     # activate menu
1840     zstyle ':completion:*:history-words'   menu yes
1841
1842     # ignore duplicate entries
1843     zstyle ':completion:*:history-words'   remove-all-dups yes
1844     zstyle ':completion:*:history-words'   stop yes
1845
1846     # match uppercase from lowercase
1847     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1848
1849     # separate matches into groups
1850     zstyle ':completion:*:matches'         group 'yes'
1851     zstyle ':completion:*'                 group-name ''
1852
1853     if [[ "$NOMENU" -eq 0 ]] ; then
1854         # if there are more than 5 options allow selecting from a menu
1855         zstyle ':completion:*'               menu select=5
1856     else
1857         # don't use any menus at all
1858         setopt no_auto_menu
1859     fi
1860
1861     zstyle ':completion:*:messages'        format '%d'
1862     zstyle ':completion:*:options'         auto-description '%d'
1863
1864     # describe options in full
1865     zstyle ':completion:*:options'         description 'yes'
1866
1867     # on processes completion complete all user processes
1868     zstyle ':completion:*:processes'       command 'ps -au$USER'
1869
1870     # offer indexes before parameters in subscripts
1871     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1872
1873     # provide verbose completion information
1874     zstyle ':completion:*'                 verbose true
1875
1876     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1877     # for commands (read: 1st word in the line) that it will list for the user
1878     # to choose from. The following disables that, because it's not exactly fast.
1879     zstyle ':completion:*:-command-:*:'    verbose false
1880
1881     # set format for warnings
1882     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1883
1884     # define files to ignore for zcompile
1885     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1886     zstyle ':completion:correct:'          prompt 'correct to: %e'
1887
1888     # Ignore completion functions for commands you don't have:
1889     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1890
1891     # Provide more processes in completion of programs like killall:
1892     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1893
1894     # complete manual by their section
1895     zstyle ':completion:*:manuals'    separate-sections true
1896     zstyle ':completion:*:manuals.*'  insert-sections   true
1897     zstyle ':completion:*:man:*'      menu yes select
1898
1899     # Search path for sudo completion
1900     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
1901                                                /usr/local/bin  \
1902                                                /usr/sbin       \
1903                                                /usr/bin        \
1904                                                /sbin           \
1905                                                /bin            \
1906                                                /usr/X11R6/bin
1907
1908     # provide .. as a completion
1909     zstyle ':completion:*' special-dirs ..
1910
1911     # run rehash on completion so new installed program are found automatically:
1912     _force_rehash() {
1913         (( CURRENT == 1 )) && rehash
1914         return 1
1915     }
1916
1917     ## correction
1918     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1919     if [[ "$NOCOR" -gt 0 ]] ; then
1920         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1921         setopt nocorrect
1922     else
1923         # try to be smart about when to use what completer...
1924         setopt correct
1925         zstyle -e ':completion:*' completer '
1926             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1927                 _last_try="$HISTNO$BUFFER$CURSOR"
1928                 reply=(_complete _match _ignored _prefix _files)
1929             else
1930                 if [[ $words[1] == (rm|mv) ]] ; then
1931                     reply=(_complete _files)
1932                 else
1933                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1934                 fi
1935             fi'
1936     fi
1937
1938     # command for process lists, the local web server details and host completion
1939     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1940
1941     # caching
1942     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1943                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1944
1945     # host completion
1946     if is42 ; then
1947         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1948         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1949     else
1950         _ssh_hosts=()
1951         _etc_hosts=()
1952     fi
1953     hosts=(
1954         $(hostname)
1955         "$_ssh_hosts[@]"
1956         "$_etc_hosts[@]"
1957         localhost
1958     )
1959     zstyle ':completion:*:hosts' hosts $hosts
1960     # TODO: so, why is this here?
1961     #  zstyle '*' hosts $hosts
1962
1963     # use generic completion system for programs not yet defined; (_gnu_generic works
1964     # with commands that provide a --help option with "standard" gnu-like output.)
1965     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
1966                    pal stow tail uname ; do
1967         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
1968     done; unset compcom
1969
1970     # see upgrade function in this file
1971     compdef _hosts upgrade
1972 }
1973
1974 # grmlstuff
1975 grmlstuff() {
1976 # people should use 'grml-x'!
1977     if check_com -c 915resolution; then
1978         855resolution() {
1979             echo "Please use 915resolution as resolution modifying tool for Intel \
1980 graphic chipset."
1981             return -1
1982         }
1983     fi
1984
1985     #a1# Output version of running grml
1986     alias grml-version='cat /etc/grml_version'
1987
1988     if check_com -c rebuildfstab ; then
1989         #a1# Rebuild /etc/fstab
1990         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1991     fi
1992
1993     if check_com -c grml-debootstrap ; then
1994         debian2hd() {
1995             echo "Installing debian to harddisk is possible by using grml-debootstrap."
1996             return 1
1997         }
1998     fi
1999 }
2000
2001 # now run the functions
2002 isgrml && checkhome
2003 is4    && isgrml    && grmlstuff
2004 is4    && grmlcomp
2005
2006 # keephack
2007 is4 && xsource "/etc/zsh/keephack"
2008
2009 # wonderful idea of using "e" glob qualifier by Peter Stephenson
2010 # You use it as follows:
2011 # $ NTREF=/reference/file
2012 # $ ls -l *(e:nt:)
2013 # This lists all the files in the current directory newer than the reference file.
2014 # You can also specify the reference file inline; note quotes:
2015 # $ ls -l *(e:'nt ~/.zshenv':)
2016 is4 && nt() {
2017     if [[ -n $1 ]] ; then
2018         local NTREF=${~1}
2019     fi
2020     [[ $REPLY -nt $NTREF ]]
2021 }
2022
2023 # shell functions
2024
2025 #f1# Reload an autoloadable function
2026 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2027 compdef _functions freload
2028
2029 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2030 sll() {
2031     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2032     for file in "$@" ; do
2033         while [[ -h "$file" ]] ; do
2034             ls -l $file
2035             file=$(readlink "$file")
2036         done
2037     done
2038 }
2039
2040 # TODO: Is it supported to use pager settings like this?
2041 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2042 # with respect to wordsplitting. (ie. ${=PAGER})
2043 if check_com -c $PAGER ; then
2044     #f1# View Debian's changelog of a given package
2045     dchange() {
2046         emulate -L zsh
2047         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
2048             $PAGER /usr/share/doc/$1/changelog.Debian.gz
2049         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2050             $PAGER /usr/share/doc/$1/changelog.gz
2051         else
2052             if check_com -c aptitude ; then
2053                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2054                 if isgrml ; then
2055                     aptitude -t unstable changelog $1
2056                 else
2057                     aptitude changelog $1
2058                 fi
2059             else
2060                 echo "No changelog for package $1 found, sorry."
2061                 return 1
2062             fi
2063         fi
2064     }
2065     _dchange() { _files -W /usr/share/doc -/ }
2066     compdef _dchange dchange
2067
2068     #f1# View Debian's NEWS of a given package
2069     dnews() {
2070         emulate -L zsh
2071         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2072             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2073         else
2074             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2075                 $PAGER /usr/share/doc/$1/NEWS.gz
2076             else
2077                 echo "No NEWS file for package $1 found, sorry."
2078                 return 1
2079             fi
2080         fi
2081     }
2082     _dnews() { _files -W /usr/share/doc -/ }
2083     compdef _dnews dnews
2084
2085     #f1# View Debian's copyright of a given package
2086     dcopyright() {
2087         emulate -L zsh
2088         if [[ -r /usr/share/doc/$1/copyright ]] ; then
2089             $PAGER /usr/share/doc/$1/copyright
2090         else
2091             echo "No copyright file for package $1 found, sorry."
2092             return 1
2093         fi
2094     }
2095     _dcopyright() { _files -W /usr/share/doc -/ }
2096     compdef _dcopyright dcopyright
2097
2098     #f1# View upstream's changelog of a given package
2099     uchange() {
2100         emulate -L zsh
2101         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2102             $PAGER /usr/share/doc/$1/changelog.gz
2103         else
2104             echo "No changelog for package $1 found, sorry."
2105             return 1
2106         fi
2107     }
2108     _uchange() { _files -W /usr/share/doc -/ }
2109     compdef _uchange uchange
2110 fi
2111
2112 # zsh profiling
2113 profile() {
2114     ZSH_PROFILE_RC=1 $SHELL "$@"
2115 }
2116
2117 #f1# Edit an alias via zle
2118 edalias() {
2119     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2120 }
2121 compdef _aliases edalias
2122
2123 #f1# Edit a function via zle
2124 edfunc() {
2125     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2126 }
2127 compdef _functions edfunc
2128
2129 # use it e.g. via 'Restart apache2'
2130 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2131 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2132 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2133 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2134 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2135 #m# f6 Status() \kbd{/etc/init.d/\em{process}}\quad\kbd{status}
2136 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2137     __start_stop() {
2138         local action_="${1:l}"  # e.g Start/Stop/Restart
2139         local service_="$2"
2140         local param_="$3"
2141
2142         local service_target_="$(readlink /etc/init.d/$service_)"
2143         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2144             # runit
2145             case "${action_}" in
2146                 start) if [[ ! -e /etc/service/$service_ ]]; then
2147                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2148                        else
2149                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2150                        fi ;;
2151                 # there is no reload in runits sysv emulation
2152                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2153                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2154             esac
2155         else
2156             # sysvinit
2157             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2158         fi
2159     }
2160
2161     _grmlinitd() {
2162         local -a scripts
2163         scripts=( /etc/init.d/*(x:t) )
2164         _describe "service startup script" scripts
2165     }
2166
2167     for i in Start Restart Stop Force-Reload Reload Status ; do
2168         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2169         compdef _grmlinitd $i
2170     done
2171 fi
2172
2173 #f1# Provides useful information on globbing
2174 H-Glob() {
2175     echo -e "
2176     /      directories
2177     .      plain files
2178     @      symbolic links
2179     =      sockets
2180     p      named pipes (FIFOs)
2181     *      executable plain files (0100)
2182     %      device files (character or block special)
2183     %b     block special files
2184     %c     character special files
2185     r      owner-readable files (0400)
2186     w      owner-writable files (0200)
2187     x      owner-executable files (0100)
2188     A      group-readable files (0040)
2189     I      group-writable files (0020)
2190     E      group-executable files (0010)
2191     R      world-readable files (0004)
2192     W      world-writable files (0002)
2193     X      world-executable files (0001)
2194     s      setuid files (04000)
2195     S      setgid files (02000)
2196     t      files with the sticky bit (01000)
2197
2198   print *(m-1)          # Files modified up to a day ago
2199   print *(a1)           # Files accessed a day ago
2200   print *(@)            # Just symlinks
2201   print *(Lk+50)        # Files bigger than 50 kilobytes
2202   print *(Lk-50)        # Files smaller than 50 kilobytes
2203   print **/*.c          # All *.c files recursively starting in \$PWD
2204   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2205   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2206   print *~*.*           # All Files that do not contain a dot
2207   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2208   print -l *(.c|.h)     # Lists *.c and *.h
2209   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2210   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2211 }
2212 alias help-zshglob=H-Glob
2213
2214 #v1# set number of lines to display per page
2215 HELP_LINES_PER_PAGE=20
2216 #v1# set location of help-zle cache file
2217 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
2218 #f1# helper function for help-zle, actually generates the help text
2219 help_zle_parse_keybindings()
2220 {
2221     emulate -L zsh
2222     setopt extendedglob
2223     unsetopt ksharrays  #indexing starts at 1
2224
2225     #v1# choose files that help-zle will parse for keybindings
2226     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
2227
2228     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
2229         local load_cache=0
2230         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
2231         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
2232     fi
2233
2234     #fill with default keybindings, possibly to be overwriten in a file later
2235     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2236     local -A help_zle_keybindings
2237     help_zle_keybindings['<Ctrl>@']="set MARK"
2238     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
2239     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
2240     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
2241     help_zle_keybindings['<Ctrl>_']="undo"
2242     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
2243     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
2244     help_zle_keybindings['<Ctrl>e']="goto end of line"
2245     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2246     help_zle_keybindings['<Alt>t']="transpose words"
2247     help_zle_keybindings['<Alt>s']="spellcheck word"
2248     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
2249     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
2250     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2251     help_zle_keybindings["<Alt>'"]="quote line"
2252     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2253     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2254     help_zle_keybindings['<Alt>u']="make next word Uppercase"
2255     help_zle_keybindings['<Alt>l']="make next word lowercase"
2256     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
2257     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2258     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2259     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2260     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2261     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
2262     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2263     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2264     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
2265
2266     #init global variables
2267     unset help_zle_lines help_zle_sln
2268     typeset -g -a help_zle_lines
2269     typeset -g help_zle_sln=1
2270
2271     local k v
2272     local lastkeybind_desc contents     #last description starting with #k# that we found
2273     local num_lines_elapsed=0            #number of lines between last description and keybinding
2274     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2275     for f in $HELPZLE_KEYBINDING_FILES; do
2276         [[ -r "$f" ]] || continue   #not readable ? skip it
2277         contents="$(<$f)"
2278         for cline in "${(f)contents}"; do
2279             #zsh pattern: matches lines like: #k# ..............
2280             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2281                 lastkeybind_desc="$match[*]"
2282                 num_lines_elapsed=0
2283             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2284             #             ignores lines that are commentend out
2285             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2286             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2287                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2288                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2289                     #substitute keybinding string with something readable
2290                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2291                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2292                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2293                     help_zle_keybindings[${k}]=$lastkeybind_desc
2294                 fi
2295                 lastkeybind_desc=""
2296             else
2297               ((num_lines_elapsed++))
2298             fi
2299         done
2300     done
2301     unset contents
2302     #calculate length of keybinding column
2303     local kstrlen=0
2304     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2305     #convert the assoc array into preformated lines, which we are able to sort
2306     for k v in ${(kv)help_zle_keybindings[@]}; do
2307         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2308         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2309     done
2310     #sort lines alphabetically
2311     help_zle_lines=("${(i)help_zle_lines[@]}")
2312     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2313     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2314     zcompile $HELP_ZLE_CACHE_FILE
2315 }
2316 typeset -g help_zle_sln
2317 typeset -g -a help_zle_lines
2318
2319 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2320 help-zle()
2321 {
2322     emulate -L zsh
2323     unsetopt ksharrays  #indexing starts at 1
2324     #help lines already generated ? no ? then do it
2325     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2326     #already displayed all lines ? go back to the start
2327     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2328     local sln=$help_zle_sln
2329     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2330     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2331     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2332 }
2333 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2334 zle -N help-zle && bindkey '^xz' help-zle
2335
2336 # grep for running process, like: 'any vim'
2337 any() {
2338     emulate -L zsh
2339     unsetopt KSH_ARRAYS
2340     if [[ -z "$1" ]] ; then
2341         echo "any - grep for process(es) by keyword" >&2
2342         echo "Usage: any <keyword>" >&2 ; return 1
2343     else
2344         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
2345     fi
2346 }
2347
2348
2349 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2350 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2351 [[ -r /proc/1/maps ]] && \
2352 deswap() {
2353     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2354     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2355     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2356 }
2357
2358 # a wrapper for vim, that deals with title setting
2359 #   VIM_OPTIONS
2360 #       set this array to a set of options to vim you always want
2361 #       to have set when calling vim (in .zshrc.local), like:
2362 #           VIM_OPTIONS=( -p )
2363 #       This will cause vim to send every file given on the
2364 #       commandline to be send to it's own tab (needs vim7).
2365 if check_com vim; then
2366     vim() {
2367         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2368     }
2369 fi
2370
2371 # make a backup of a file
2372 bk() {
2373     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2374 }
2375
2376 ssl_hashes=( sha512 sha256 sha1 md5 )
2377
2378 for sh in ${ssl_hashes}; do
2379     eval 'ssl-cert-'${sh}'() {
2380         emulate -L zsh
2381         if [[ -z $1 ]] ; then
2382             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2383             return 1
2384         fi
2385         openssl x509 -noout -fingerprint -'${sh}' -in $1
2386     }'
2387 done; unset sh
2388
2389 ssl-cert-fingerprints() {
2390     emulate -L zsh
2391     local i
2392     if [[ -z $1 ]] ; then
2393         printf 'usage: ssl-cert-fingerprints <file>\n'
2394         return 1
2395     fi
2396     for i in ${ssl_hashes}
2397         do ssl-cert-$i $1;
2398     done
2399 }
2400
2401 ssl-cert-info() {
2402     emulate -L zsh
2403     if [[ -z $1 ]] ; then
2404         printf 'usage: ssl-cert-info <file>\n'
2405         return 1
2406     fi
2407     openssl x509 -noout -text -in $1
2408     ssl-cert-fingerprints $1
2409 }
2410
2411 # make sure our environment is clean regarding colors
2412 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2413
2414 # "persistent history"
2415 # just write important commands you always need to ~/.important_commands
2416 if [[ -r ~/.important_commands ]] ; then
2417     fc -R ~/.important_commands
2418 fi
2419
2420 # load the lookup subsystem if it's available on the system
2421 zrcautoload lookupinit && lookupinit
2422
2423 # variables
2424
2425 # set terminal property (used e.g. by msgid-chooser)
2426 export COLORTERM="yes"
2427
2428 # aliases
2429
2430 # general
2431 #a2# Execute \kbd{du -sch}
2432 alias da='du -sch'
2433 #a2# Execute \kbd{jobs -l}
2434 alias j='jobs -l'
2435
2436 # listing stuff
2437 #a2# Execute \kbd{ls -lSrah}
2438 alias dir="ls -lSrah"
2439 #a2# Only show dot-directories
2440 alias lad='ls -d .*(/)'
2441 #a2# Only show dot-files
2442 alias lsa='ls -a .*(.)'
2443 #a2# Only files with setgid/setuid/sticky flag
2444 alias lss='ls -l *(s,S,t)'
2445 #a2# Only show symlinks
2446 alias lsl='ls -l *(@)'
2447 #a2# Display only executables
2448 alias lsx='ls -l *(*)'
2449 #a2# Display world-{readable,writable,executable} files
2450 alias lsw='ls -ld *(R,W,X.^ND/)'
2451 #a2# Display the ten biggest files
2452 alias lsbig="ls -flh *(.OL[1,10])"
2453 #a2# Only show directories
2454 alias lsd='ls -d *(/)'
2455 #a2# Only show empty directories
2456 alias lse='ls -d *(/^F)'
2457 #a2# Display the ten newest files
2458 alias lsnew="ls -rtlh *(D.om[1,10])"
2459 #a2# Display the ten oldest files
2460 alias lsold="ls -rtlh *(D.Om[1,10])"
2461 #a2# Display the ten smallest files
2462 alias lssmall="ls -Srl *(.oL[1,10])"
2463 #a2# Display the ten newest directories and ten newest .directories
2464 alias lsnewdir="ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
2465 #a2# Display the ten oldest directories and ten oldest .directories
2466 alias lsolddir="ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
2467
2468 # some useful aliases
2469 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir $OLDCWD}
2470 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2471
2472 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2473 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2474 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2475
2476 # work around non utf8 capable software in utf environment via $LANG and luit
2477 if check_com isutfenv && check_com luit ; then
2478     if check_com -c mrxvt ; then
2479         isutfenv && [[ -n "$LANG" ]] && \
2480             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2481     fi
2482
2483     if check_com -c aterm ; then
2484         isutfenv && [[ -n "$LANG" ]] && \
2485             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2486     fi
2487
2488     if check_com -c centericq ; then
2489         isutfenv && [[ -n "$LANG" ]] && \
2490             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2491     fi
2492 fi
2493
2494 # useful functions
2495
2496 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2497 bk() {
2498     emulate -L zsh
2499     cp -b $1 $1_`date --iso-8601=m`
2500 }
2501
2502 #f5# cd to directoy and list files
2503 cl() {
2504     emulate -L zsh
2505     cd $1 && ls -a
2506 }
2507
2508 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2509 cd() {
2510     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2511         [[ ! -e ${1:h} ]] && return 1
2512         print "Correcting ${1} to ${1:h}"
2513         builtin cd ${1:h}
2514     else
2515         builtin cd "$@"
2516     fi
2517 }
2518
2519 #f5# Create Directoy and \kbd{cd} to it
2520 mkcd() {
2521     if (( ARGC != 1 )); then
2522         printf 'usage: mkcd <new-directory>\n'
2523         return 1;
2524     fi
2525     if [[ ! -d "$1" ]]; then
2526         command mkdir -p "$1"
2527     else
2528         printf '`%s'\'' already exists: cd-ing.\n' "$1"
2529     fi
2530     builtin cd "$1"
2531 }
2532
2533 #f5# Create temporary directory and \kbd{cd} to it
2534 cdt() {
2535     local t
2536     t=$(mktemp -d)
2537     echo "$t"
2538     builtin cd "$t"
2539 }
2540
2541 #f5# Create directory under cursor or the selected area
2542 # Press ctrl-xM to create the directory under the cursor or the selected area.
2543 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2544 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2545 # directory does not exist yet -> press ctrl-XM and problem solved
2546 inplaceMkDirs() {
2547     local PATHTOMKDIR
2548     if ((REGION_ACTIVE==1)); then
2549         local F=$MARK T=$CURSOR
2550         if [[ $F -gt $T ]]; then
2551             F=${CURSOR}
2552             T=${MARK}
2553         fi
2554         # get marked area from buffer and eliminate whitespace
2555         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2556         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2557     else
2558         local bufwords iword
2559         bufwords=(${(z)LBUFFER})
2560         iword=${#bufwords}
2561         bufwords=(${(z)BUFFER})
2562         PATHTOMKDIR="${(Q)bufwords[iword]}"
2563     fi
2564     [[ -z "${PATHTOMKDIR}" ]] && return 1
2565     PATHTOMKDIR=${~PATHTOMKDIR}
2566     if [[ -e "${PATHTOMKDIR}" ]]; then
2567         zle -M " path already exists, doing nothing"
2568     else
2569         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2570         zle end-of-line
2571     fi
2572 }
2573 #k# mkdir -p <dir> from string under cursor or marked area
2574 zle -N inplaceMkDirs && bindkey '^xM' inplaceMkDirs
2575
2576 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2577 accessed() {
2578     emulate -L zsh
2579     print -l -- *(a-${1:-1})
2580 }
2581
2582 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2583 changed() {
2584     emulate -L zsh
2585     print -l -- *(c-${1:-1})
2586 }
2587
2588 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2589 modified() {
2590     emulate -L zsh
2591     print -l -- *(m-${1:-1})
2592 }
2593 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2594 check_com new || alias new=modified
2595
2596 # use colors when GNU grep with color-support
2597 #a2# Execute \kbd{grep -{}-color=auto}
2598 (( $#grep_options > 0 )) && alias grep='grep '${grep_options:+"${grep_options[*]}"}
2599
2600 # Translate DE<=>EN
2601 # 'translate' looks up fot a word in a file with language-to-language
2602 # translations (field separator should be " : "). A typical wordlist looks
2603 # like at follows:
2604 #  | english-word : german-transmission
2605 # It's also only possible to translate english to german but not reciprocal.
2606 # Use the following oneliner to turn back the sort order:
2607 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2608 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2609 #f5# Translates a word
2610 trans() {
2611     emulate -L zsh
2612     case "$1" in
2613         -[dD]*)
2614             translate -l de-en $2
2615             ;;
2616         -[eE]*)
2617             translate -l en-de $2
2618             ;;
2619         *)
2620             echo "Usage: $0 { -D | -E }"
2621             echo "         -D == German to English"
2622             echo "         -E == English to German"
2623     esac
2624 }
2625
2626 # Usage: simple-extract <file>
2627 # Using option -d deletes the original archive file.
2628 #f5# Smart archive extractor
2629 simple-extract() {
2630     emulate -L zsh
2631     setopt extended_glob noclobber
2632     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2633     local RC=0
2634     zparseopts -D -E "d=DELETE_ORIGINAL"
2635     for ARCHIVE in "${@}"; do
2636         case $ARCHIVE in
2637             *(tar.bz2|tbz2|tbz))
2638                 DECOMP_CMD="tar -xvjf -"
2639                 USES_STDIN=true
2640                 USES_STDOUT=false
2641                 ;;
2642             *(tar.gz|tgz))
2643                 DECOMP_CMD="tar -xvzf -"
2644                 USES_STDIN=true
2645                 USES_STDOUT=false
2646                 ;;
2647             *(tar.xz|txz|tar.lzma))
2648                 DECOMP_CMD="tar -xvJf -"
2649                 USES_STDIN=true
2650                 USES_STDOUT=false
2651                 ;;
2652             *tar)
2653                 DECOMP_CMD="tar -xvf -"
2654                 USES_STDIN=true
2655                 USES_STDOUT=false
2656                 ;;
2657             *rar)
2658                 DECOMP_CMD="unrar x"
2659                 USES_STDIN=false
2660                 USES_STDOUT=false
2661                 ;;
2662             *lzh)
2663                 DECOMP_CMD="lha x"
2664                 USES_STDIN=false
2665                 USES_STDOUT=false
2666                 ;;
2667             *7z)
2668                 DECOMP_CMD="7z x"
2669                 USES_STDIN=false
2670                 USES_STDOUT=false
2671                 ;;
2672             *(zip|jar))
2673                 DECOMP_CMD="unzip"
2674                 USES_STDIN=false
2675                 USES_STDOUT=false
2676                 ;;
2677             *deb)
2678                 DECOMP_CMD="ar -x"
2679                 USES_STDIN=false
2680                 USES_STDOUT=false
2681                 ;;
2682             *bz2)
2683                 DECOMP_CMD="bzip2 -d -c -"
2684                 USES_STDIN=true
2685                 USES_STDOUT=true
2686                 ;;
2687             *(gz|Z))
2688                 DECOMP_CMD="gzip -d -c -"
2689                 USES_STDIN=true
2690                 USES_STDOUT=true
2691                 ;;
2692             *(xz|lzma))
2693                 DECOMP_CMD="xz -d -c -"
2694                 USES_STDIN=true
2695                 USES_STDOUT=true
2696                 ;;
2697             *)
2698                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2699                 RC=$((RC+1))
2700                 continue
2701                 ;;
2702         esac
2703
2704         if ! check_com ${DECOMP_CMD[(w)1]}; then
2705             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2706             RC=$((RC+2))
2707             continue
2708         fi
2709
2710         GZTARGET="${ARCHIVE:t:r}"
2711         if [[ -f $ARCHIVE ]] ; then
2712
2713             print "Extracting '$ARCHIVE' ..."
2714             if $USES_STDIN; then
2715                 if $USES_STDOUT; then
2716                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
2717                 else
2718                     ${=DECOMP_CMD} < "$ARCHIVE"
2719                 fi
2720             else
2721                 if $USES_STDOUT; then
2722                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
2723                 else
2724                     ${=DECOMP_CMD} "$ARCHIVE"
2725                 fi
2726             fi
2727             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
2728
2729         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
2730             if check_com curl; then
2731                 WGET_CMD="curl -L -k -s -o -"
2732             elif check_com wget; then
2733                 WGET_CMD="wget -q -O - --no-check-certificate"
2734             else
2735                 print "ERROR: neither wget nor curl is installed" >&2
2736                 RC=$((RC+4))
2737                 continue
2738             fi
2739             print "Downloading and Extracting '$ARCHIVE' ..."
2740             if $USES_STDIN; then
2741                 if $USES_STDOUT; then
2742                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
2743                     RC=$((RC+$?))
2744                 else
2745                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
2746                     RC=$((RC+$?))
2747                 fi
2748             else
2749                 if $USES_STDOUT; then
2750                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
2751                 else
2752                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
2753                 fi
2754             fi
2755
2756         else
2757             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
2758             RC=$((RC+8))
2759         fi
2760     done
2761     return $RC
2762 }
2763
2764 __archive_or_uri()
2765 {
2766     _alternative \
2767         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
2768         '_urls:Remote Archives:_urls'
2769 }
2770
2771 _simple_extract()
2772 {
2773     _arguments \
2774         '-d[delete original archivefile after extraction]' \
2775         '*:Archive Or Uri:__archive_or_uri'
2776 }
2777 compdef _simple_extract simple-extract
2778 alias se=simple-extract
2779
2780 #f5# Set all ulimit parameters to \kbd{unlimited}
2781 allulimit() {
2782     ulimit -c unlimited
2783     ulimit -d unlimited
2784     ulimit -f unlimited
2785     ulimit -l unlimited
2786     ulimit -n unlimited
2787     ulimit -s unlimited
2788     ulimit -t unlimited
2789 }
2790
2791 #f5# Change the xterm title from within GNU-screen
2792 xtrename() {
2793     emulate -L zsh
2794     if [[ $1 != "-f" ]] ; then
2795         if [[ -z ${DISPLAY} ]] ; then
2796             printf 'xtrename only makes sense in X11.\n'
2797             return 1
2798         fi
2799     else
2800         shift
2801     fi
2802     if [[ -z $1 ]] ; then
2803         printf 'usage: xtrename [-f] "title for xterm"\n'
2804         printf '  renames the title of xterm from _within_ screen.\n'
2805         printf '  also works without screen.\n'
2806         printf '  will not work if DISPLAY is unset, use -f to override.\n'
2807         return 0
2808     fi
2809     print -n "\eP\e]0;${1}\C-G\e\\"
2810     return 0
2811 }
2812
2813 # Create small urls via http://goo.gl using curl(1).
2814 # API reference: https://code.google.com/apis/urlshortener/
2815 function zurl() {
2816     emulate -L zsh
2817     setopt extended_glob
2818
2819     if [[ -z $1 ]]; then
2820         print "USAGE: zurl <URL>"
2821         return 1
2822     fi
2823
2824     local PN url prog api json contenttype item
2825     local -a data
2826     PN=$0
2827     url=$1
2828
2829     # Prepend 'http://' to given URL where necessary for later output.
2830     if [[ ${url} != http(s|)://* ]]; then
2831         url='http://'${url}
2832     fi
2833
2834     if check_com -c curl; then
2835         prog=curl
2836     else
2837         print "curl is not available, but mandatory for ${PN}. Aborting."
2838         return 1
2839     fi
2840     api='https://www.googleapis.com/urlshortener/v1/url'
2841     contenttype="Content-Type: application/json"
2842     json="{\"longUrl\": \"${url}\"}"
2843     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
2844     # Parse the response
2845     for item in "${data[@]}"; do
2846         case "$item" in
2847             ' '#'"id":'*)
2848                 item=${item#*: \"}
2849                 item=${item%\",*}
2850                 printf '%s\n' "$item"
2851                 return 0
2852                 ;;
2853         esac
2854     done
2855     return 1
2856 }
2857
2858 #f2# Find history events by search pattern and list them by date.
2859 whatwhen()  {
2860     emulate -L zsh
2861     local usage help ident format_l format_s first_char remain first last
2862     usage='USAGE: whatwhen [options] <searchstring> <search range>'
2863     help='Use `whatwhen -h'\'' for further explanations.'
2864     ident=${(l,${#${:-Usage: }},, ,)}
2865     format_l="${ident}%s\t\t\t%s\n"
2866     format_s="${format_l//(\\t)##/\\t}"
2867     # Make the first char of the word to search for case
2868     # insensitive; e.g. [aA]
2869     first_char=[${(L)1[1]}${(U)1[1]}]
2870     remain=${1[2,-1]}
2871     # Default search range is `-100'.
2872     first=${2:-\-100}
2873     # Optional, just used for `<first> <last>' given.
2874     last=$3
2875     case $1 in
2876         ("")
2877             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
2878             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2879         ;;
2880         (-h)
2881             printf '%s\n\n' ${usage}
2882             print 'OPTIONS:'
2883             printf $format_l '-h' 'show help text'
2884             print '\f'
2885             print 'SEARCH RANGE:'
2886             printf $format_l "'0'" 'the whole history,'
2887             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
2888             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
2889             printf '\n%s\n' 'EXAMPLES:'
2890             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
2891             printf $format_l 'whatwhen zsh -250'
2892             printf $format_l 'whatwhen foo 1 99'
2893         ;;
2894         (\?)
2895             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2896         ;;
2897         (*)
2898             # -l list results on stout rather than invoking $EDITOR.
2899             # -i Print dates as in YYYY-MM-DD.
2900             # -m Search for a - quoted - pattern within the history.
2901             fc -li -m "*${first_char}${remain}*" $first $last
2902         ;;
2903     esac
2904 }
2905
2906 # mercurial related stuff
2907 if check_com -c hg ; then
2908     # gnu like diff for mercurial
2909     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
2910     #f5# GNU like diff for mercurial
2911     hgdi() {
2912         emulate -L zsh
2913         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
2914     }
2915
2916     # build debian package
2917     #a2# Alias for \kbd{hg-buildpackage}
2918     alias hbp='hg-buildpackage'
2919
2920     # execute commands on the versioned patch-queue from the current repos
2921     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
2922
2923     # diffstat for specific version of a mercurial repository
2924     #   hgstat      => display diffstat between last revision and tip
2925     #   hgstat 1234 => display diffstat between revision 1234 and tip
2926     #f5# Diffstat for specific version of a mercurial repos
2927     hgstat() {
2928         emulate -L zsh
2929         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
2930     }
2931
2932 fi # end of check whether we have the 'hg'-executable
2933
2934 # grml-small cleanups
2935
2936 # The following is used to remove zsh-config-items that do not work
2937 # in grml-small by default.
2938 # If you do not want these adjustments (for whatever reason), set
2939 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
2940 # sources if it is there).
2941
2942 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
2943
2944     unset abk[V]
2945     unalias    'V'      &> /dev/null
2946     unfunction vman     &> /dev/null
2947     unfunction viless   &> /dev/null
2948     unfunction 2html    &> /dev/null
2949
2950     # manpages are not in grmlsmall
2951     unfunction manzsh   &> /dev/null
2952     unfunction man2     &> /dev/null
2953
2954 fi
2955
2956 zrclocal
2957
2958 ## genrefcard.pl settings
2959
2960 ### doc strings for external functions from files
2961 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
2962
2963 ### example: split functions-search 8,16,24,32
2964 #@# split functions-search 8
2965
2966 ## END OF FILE #################################################################
2967 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
2968 # Local variables:
2969 # mode: sh
2970 # End: