etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is439(){
 148     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 #f1# Checks whether or not you're running grml
 154 isgrml(){
 155     [[ -f /etc/grml_version ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running a grml cd
 160 isgrmlcd(){
 161     [[ -f /etc/grml_cd ]] && return 0
 162     return 1
 163 }
 164
 165 if isgrml ; then
 166 #f1# Checks whether or not you're running grml-small
 167     isgrmlsmall() {
 168         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 169             return 0
 170         fi
 171         return 1
 172     }
 173 else
 174     isgrmlsmall() { return 1 }
 175 fi
 176
 177 isdarwin(){
 178     [[ $OSTYPE == darwin* ]] && return 0
 179     return 1
 180 }
 181
 182 isfreebsd(){
 183     [[ $OSTYPE == freebsd* ]] && return 0
 184     return 1
 185 }
 186
 187 #f1# are we running within an utf environment?
 188 isutfenv() {
 189     case "$LANG $CHARSET $LANGUAGE" in
 190         *utf*) return 0 ;;
 191         *UTF*) return 0 ;;
 192         *)     return 1 ;;
 193     esac
 194 }
 195
 196 # check for user, if not running as root set $SUDO to sudo
 197 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 198
 199 # change directory to home on first invocation of zsh
 200 # important for rungetty -> autologin
 201 # Thanks go to Bart Schaefer!
 202 isgrml && checkhome() {
 203     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 204         export ALREADY_DID_CD_HOME=$HOME
 205         cd
 206     fi
 207 }
 208
 209 # check for zsh v3.1.7+
 210
 211 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 212      || ${ZSH_VERSION} == 3.<2->.<->*    \
 213      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 214
 215     printf '-!-\n'
 216     printf '-!- In this configuration we try to make use of features, that only\n'
 217     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 218     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 219     printf '-!- advanced features in all supported versions.\n'
 220     printf '-!-\n'
 221     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 222     printf '-!-\n'
 223     printf '-!- While this *may* work, it might as well fail.\n'
 224     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 225     printf '-!-\n'
 226     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 227     printf '-!- If it does today, you'\''ve been lucky.\n'
 228     printf '-!-\n'
 229     printf '-!- Ye been warned!\n'
 230     printf '-!-\n'
 231
 232     function zstyle() { : }
 233 fi
 234
 235 # autoload wrapper - use this one instead of autoload directly
 236 # We need to define this function as early as this, because autoloading
 237 # 'is-at-least()' needs it.
 238 function zrcautoload() {
 239     emulate -L zsh
 240     setopt extended_glob
 241     local fdir ffile
 242     local -i ffound
 243
 244     ffile=$1
 245     (( ffound = 0 ))
 246     for fdir in ${fpath} ; do
 247         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 248     done
 249
 250     (( ffound == 0 )) && return 1
 251     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 252         autoload -U ${ffile} || return 1
 253     else
 254         autoload ${ffile} || return 1
 255     fi
 256     return 0
 257 }
 258
 259 # Load is-at-least() for more precise version checks Note that this test will
 260 # *always* fail, if the is-at-least function could not be marked for
 261 # autoloading.
 262 zrcautoload is-at-least || is-at-least() { return 1 }
 263
 264 # set some important options (as early as possible)
 265
 266 # append history list to the history file; this is the default but we make sure
 267 # because it's required for share_history.
 268 setopt append_history
 269
 270 # import new commands from the history file also in other zsh-session
 271 is4 && setopt share_history
 272
 273 # save each command's beginning timestamp and the duration to the history file
 274 setopt extended_history
 275
 276 # If a new command line being added to the history list duplicates an older
 277 # one, the older command is removed from the list
 278 is4 && setopt histignorealldups
 279
 280 # remove command lines from the history list when the first character on the
 281 # line is a space
 282 setopt histignorespace
 283
 284 # if a command is issued that can't be executed as a normal command, and the
 285 # command is the name of a directory, perform the cd command to that directory.
 286 setopt auto_cd
 287
 288 # in order to use #, ~ and ^ for filename generation grep word
 289 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 290 # don't forget to quote '^', '~' and '#'!
 291 setopt extended_glob
 292
 293 # display PID when suspending processes as well
 294 setopt longlistjobs
 295
 296 # try to avoid the 'zsh: no matches found...'
 297 setopt nonomatch
 298
 299 # report the status of backgrounds jobs immediately
 300 setopt notify
 301
 302 # whenever a command completion is attempted, make sure the entire command path
 303 # is hashed first.
 304 setopt hash_list_all
 305
 306 # not just at the end
 307 setopt completeinword
 308
 309 # Don't send SIGHUP to background processes when the shell exits.
 310 setopt nohup
 311
 312 # make cd push the old directory onto the directory stack.
 313 setopt auto_pushd
 314
 315 # avoid "beep"ing
 316 setopt nobeep
 317
 318 # don't push the same dir twice.
 319 setopt pushd_ignore_dups
 320
 321 # * shouldn't match dotfiles. ever.
 322 setopt noglobdots
 323
 324 # use zsh style word splitting
 325 setopt noshwordsplit
 326
 327 # don't error out when unset parameters are used
 328 setopt unset
 329
 330 # setting some default values
 331 NOCOR=${NOCOR:-0}
 332 NOMENU=${NOMENU:-0}
 333 NOPRECMD=${NOPRECMD:-0}
 334 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 335 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 336 BATTERY=${BATTERY:-0}
 337 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 338 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 339
 340 typeset -ga ls_options
 341 typeset -ga grep_options
 342 if ls --help 2> /dev/null | grep -q GNU; then
 343     ls_options=( --color=auto )
 344 elif [[ $OSTYPE == freebsd* ]]; then
 345     ls_options=( -G )
 346 fi
 347 if grep --help 2> /dev/null | grep -q GNU || \
 348    [[ $OSTYPE == freebsd* ]]; then
 349     grep_options=( --color=auto )
 350 fi
 351
 352 # utility functions
 353 # this function checks if a command exists and returns either true
 354 # or false. This avoids using 'which' and 'whence', which will
 355 # avoid problems with aliases for which on certain weird systems. :-)
 356 # Usage: check_com [-c|-g] word
 357 #   -c  only checks for external commands
 358 #   -g  does the usual tests and also checks for global aliases
 359 check_com() {
 360     emulate -L zsh
 361     local -i comonly gatoo
 362
 363     if [[ $1 == '-c' ]] ; then
 364         (( comonly = 1 ))
 365         shift
 366     elif [[ $1 == '-g' ]] ; then
 367         (( gatoo = 1 ))
 368     else
 369         (( comonly = 0 ))
 370         (( gatoo = 0 ))
 371     fi
 372
 373     if (( ${#argv} != 1 )) ; then
 374         printf 'usage: check_com [-c] <command>\n' >&2
 375         return 1
 376     fi
 377
 378     if (( comonly > 0 )) ; then
 379         [[ -n ${commands[$1]}  ]] && return 0
 380         return 1
 381     fi
 382
 383     if   [[ -n ${commands[$1]}    ]] \
 384       || [[ -n ${functions[$1]}   ]] \
 385       || [[ -n ${aliases[$1]}     ]] \
 386       || [[ -n ${reswords[(r)$1]} ]] ; then
 387
 388         return 0
 389     fi
 390
 391     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 392         return 0
 393     fi
 394
 395     return 1
 396 }
 397
 398 # creates an alias and precedes the command with
 399 # sudo if $EUID is not zero.
 400 salias() {
 401     emulate -L zsh
 402     local only=0 ; local multi=0
 403     while [[ $1 == -* ]] ; do
 404         case $1 in
 405             (-o) only=1 ;;
 406             (-a) multi=1 ;;
 407             (--) shift ; break ;;
 408             (-h)
 409                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 410                 printf '  -h      shows this help text.\n'
 411                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 412                 printf '          be careful using this option.\n'
 413                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 414                 return 0
 415                 ;;
 416             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 417         esac
 418         shift
 419     done
 420
 421     if (( ${#argv} > 1 )) ; then
 422         printf 'Too many arguments %s\n' "${#argv}"
 423         return 1
 424     fi
 425
 426     key="${1%%\=*}" ;  val="${1#*\=}"
 427     if (( EUID == 0 )) && (( only == 0 )); then
 428         alias -- "${key}=${val}"
 429     elif (( EUID > 0 )) ; then
 430         (( multi > 0 )) && val="${val// ; / ; sudo }"
 431         alias -- "${key}=sudo ${val}"
 432     fi
 433
 434     return 0
 435 }
 436
 437 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 438 # usage: uprint foo
 439 #   Where foo is the *name* of the parameter you want printed.
 440 #   Note that foo is no typo; $foo would be wrong here!
 441 if ! is42 ; then
 442     uprint () {
 443         emulate -L zsh
 444         local -a u
 445         local w
 446         local parameter=$1
 447
 448         if [[ -z ${parameter} ]] ; then
 449             printf 'usage: uprint <parameter>\n'
 450             return 1
 451         fi
 452
 453         for w in ${(P)parameter} ; do
 454             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 455         done
 456
 457         builtin print -l $u
 458     }
 459 fi
 460
 461 # Check if we can read given files and source those we can.
 462 xsource() {
 463     if (( ${#argv} < 1 )) ; then
 464         printf 'usage: xsource FILE(s)...\n' >&2
 465         return 1
 466     fi
 467
 468     while (( ${#argv} > 0 )) ; do
 469         [[ -r "$1" ]] && source "$1"
 470         shift
 471     done
 472     return 0
 473 }
 474
 475 # Check if we can read a given file and 'cat(1)' it.
 476 xcat() {
 477     emulate -L zsh
 478     if (( ${#argv} != 1 )) ; then
 479         printf 'usage: xcat FILE\n' >&2
 480         return 1
 481     fi
 482
 483     [[ -r $1 ]] && cat $1
 484     return 0
 485 }
 486
 487 # Remove these functions again, they are of use only in these
 488 # setup files. This should be called at the end of .zshrc.
 489 xunfunction() {
 490     emulate -L zsh
 491     local -a funcs
 492     funcs=(salias xcat xsource xunfunction zrcautoload)
 493
 494     for func in $funcs ; do
 495         [[ -n ${functions[$func]} ]] \
 496             && unfunction $func
 497     done
 498     return 0
 499 }
 500
 501 # this allows us to stay in sync with grml's zshrc and put own
 502 # modifications in ~/.zshrc.local
 503 zrclocal() {
 504     xsource "/etc/zsh/zshrc.local"
 505     xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
 506     return 0
 507 }
 508
 509 # locale setup
 510 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 511     xsource "/etc/default/locale"
 512 fi
 513
 514 for var in LANG LC_ALL LC_MESSAGES ; do
 515     [[ -n ${(P)var} ]] && export $var
 516 done
 517
 518 xsource "/etc/sysconfig/keyboard"
 519
 520 TZ=$(xcat /etc/timezone)
 521
 522 # set some variables
 523 if check_com -c vim ; then
 524 #v#
 525     export EDITOR=${EDITOR:-vim}
 526 else
 527     export EDITOR=${EDITOR:-vi}
 528 fi
 529
 530 #v#
 531 export PAGER=${PAGER:-less}
 532
 533 #v#
 534 export MAIL=${MAIL:-/var/mail/$USER}
 535
 536 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 537 export SHELL='/bin/zsh'
 538
 539 # color setup for ls:
 540 check_com -c dircolors && eval $(dircolors -b)
 541 # color setup for ls on OS X / FreeBSD:
 542 isdarwin && export CLICOLOR=1
 543 isfreebsd && export CLICOLOR=1
 544
 545 # do MacPorts setup on darwin
 546 if isdarwin && [[ -d /opt/local ]]; then
 547     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 548     # zshenv.
 549     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 550     MANPATH="/opt/local/share/man:$MANPATH"
 551 fi
 552 # do Fink setup on darwin
 553 isdarwin && xsource /sw/bin/init.sh
 554
 555 # load our function and completion directories
 556 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 557     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 558     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 559         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 560             zrcautoload ${func:t}
 561         done
 562     fi
 563 done
 564 unset fdir func
 565
 566 # support colors in less
 567 export LESS_TERMCAP_mb=$'\E[01;31m'
 568 export LESS_TERMCAP_md=$'\E[01;31m'
 569 export LESS_TERMCAP_me=$'\E[0m'
 570 export LESS_TERMCAP_se=$'\E[0m'
 571 export LESS_TERMCAP_so=$'\E[01;44;33m'
 572 export LESS_TERMCAP_ue=$'\E[0m'
 573 export LESS_TERMCAP_us=$'\E[01;32m'
 574
 575 # mailchecks
 576 MAILCHECK=30
 577
 578 # report about cpu-/system-/user-time of command if running longer than
 579 # 5 seconds
 580 REPORTTIME=5
 581
 582 # watch for everyone but me and root
 583 watch=(notme root)
 584
 585 # automatically remove duplicates from these arrays
 586 typeset -U path cdpath fpath manpath
 587
 588 # Remove zle-line-{init,finish} if it looks like it turns smkx. This would be
 589 # better fixed by working with those modes too, but we use way too many
 590 # hardcoded bindings for now.
 591 function remove_widget () {
 592     local name=$1
 593     local cap=$2
 594     if (( ${+functions[$name]} )) && [[ ${functions[$name]} == *${cap}* ]]; then
 595         local w=${widgets[$name]}
 596         zle -D $name
 597         [[ $w == user:* ]] && unfunction ${w#*:}
 598     fi
 599 }
 600 remove_widget zle-line-init smkx
 601 remove_widget zle-line-finish rmkx
 602 unfunction remove_widget
 603
 604 # keybindings
 605 if [[ "$TERM" != emacs ]] ; then
 606     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 607     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 608     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 609     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 610     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 611     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 612     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 613     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 614     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 615     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 616     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 617     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 618     # ncurses stuff:
 619     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 620     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 621     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 622     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 623     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 624     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 625     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 626     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 627 fi
 628
 629 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 630 # use emacs style per default:
 631 bindkey -e
 632 # use vi style:
 633 # bindkey -v
 634
 635 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 636 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 637 beginning-or-end-of-somewhere() {
 638     local hno=$HISTNO
 639     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 640       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 641         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 642     else
 643         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 644         if (( HISTNO != hno )); then
 645             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 646         fi
 647     fi
 648 }
 649 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 650 zle -N end-of-somewhere beginning-or-end-of-somewhere
 651
 652
 653 #if [[ "$TERM" == screen ]] ; then
 654
 655 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 656 ## to beginning/end of buffer on second keypress
 657 ## and to beginning/end of history on (at most) the third keypress
 658 # terminator & non-debian xterm
 659 bindkey '\eOH' beginning-of-somewhere  # home
 660 bindkey '\eOF' end-of-somewhere        # end
 661 # freebsd console
 662 bindkey '\e[H' beginning-of-somewhere   # home
 663 bindkey '\e[F' end-of-somewhere         # end
 664 # xterm,gnome-terminal,quake,etc
 665 bindkey '^[[1~' beginning-of-somewhere  # home
 666 bindkey '^[[4~' end-of-somewhere        # end
 667 # if terminal type is set to 'rxvt':
 668 bindkey '\e[7~' beginning-of-somewhere  # home
 669 bindkey '\e[8~' end-of-somewhere        # end
 670 #fi
 671
 672 bindkey '\e[A'  up-line-or-search       # cursor up
 673 bindkey '\e[B'  down-line-or-search     # <ESC>-
 674
 675 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 676 bindkey "\e[5C" forward-word
 677 bindkey "\e[5D" backward-word
 678 bindkey "\e[1;5C" forward-word
 679 bindkey "\e[1;5D" backward-word
 680 ## the same for alt-left-arrow and alt-right-arrow
 681 bindkey '^[[1;3C' forward-word
 682 bindkey '^[[1;3D' backward-word
 683
 684 # Search backward in the history for a line beginning with the current
 685 # line up to the cursor and move the cursor to the end of the line then
 686 zle -N history-beginning-search-backward-end history-search-end
 687 zle -N history-beginning-search-forward-end  history-search-end
 688 #k# search history backward for entry beginning with typed text
 689 bindkey '^xp'   history-beginning-search-backward-end
 690 #k# search history forward for entry beginning with typed text
 691 bindkey '^xP'   history-beginning-search-forward-end
 692 #k# search history backward for entry beginning with typed text
 693 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 694 #k# search history forward for entry beginning with typed text
 695 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 696
 697 # bindkey -s '^l' "|less\n"             # ctrl-L pipes to less
 698 # bindkey -s '^b' " &\n"                # ctrl-B runs it in the background
 699
 700 # insert unicode character
 701 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 702 # See for example http://unicode.org/charts/ for unicode characters code
 703 zrcautoload insert-unicode-char
 704 zle -N insert-unicode-char
 705 #k# Insert Unicode character
 706 bindkey '^xi' insert-unicode-char
 707
 708 #m# k Shift-tab Perform backwards menu completion
 709 if [[ -n "$terminfo[kcbt]" ]]; then
 710     bindkey "$terminfo[kcbt]" reverse-menu-complete
 711 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 712     bindkey "$terminfo[cbt]"  reverse-menu-complete
 713 fi
 714
 715 ## toggle the ,. abbreviation feature on/off
 716 # NOABBREVIATION: default abbreviation-state
 717 #                 0 - enabled (default)
 718 #                 1 - disabled
 719 NOABBREVIATION=${NOABBREVIATION:-0}
 720
 721 grml_toggle_abbrev() {
 722     if (( ${NOABBREVIATION} > 0 )) ; then
 723         NOABBREVIATION=0
 724     else
 725         NOABBREVIATION=1
 726     fi
 727 }
 728
 729 #k# Toggle abbreviation expansion on/off
 730 zle -N grml_toggle_abbrev
 731 bindkey '^xA' grml_toggle_abbrev
 732
 733 # add a command line to the shells history without executing it
 734 commit-to-history() {
 735     print -s ${(z)BUFFER}
 736     zle send-break
 737 }
 738 zle -N commit-to-history
 739 bindkey "^x^h" commit-to-history
 740
 741 # only slash should be considered as a word separator:
 742 slash-backward-kill-word() {
 743     local WORDCHARS="${WORDCHARS:s@/@}"
 744     # zle backward-word
 745     zle backward-kill-word
 746 }
 747 zle -N slash-backward-kill-word
 748
 749 #k# Kill left-side word or everything up to next slash
 750 bindkey '\ev' slash-backward-kill-word
 751 #k# Kill left-side word or everything up to next slash
 752 bindkey '\e^h' slash-backward-kill-word
 753 #k# Kill left-side word or everything up to next slash
 754 bindkey '\e^?' slash-backward-kill-word
 755
 756 # use the new *-pattern-* widgets for incremental history search
 757 if is439 ; then
 758     bindkey '^r' history-incremental-pattern-search-backward
 759     bindkey '^s' history-incremental-pattern-search-forward
 760 fi
 761
 762 # a generic accept-line wrapper
 763
 764 # This widget can prevent unwanted autocorrections from command-name
 765 # to _command-name, rehash automatically on enter and call any number
 766 # of builtin and user-defined widgets in different contexts.
 767 #
 768 # For a broader description, see:
 769 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 770 #
 771 # The code is imported from the file 'zsh/functions/accept-line' from
 772 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 773 # distributed under the same terms as zsh itself.
 774
 775 # A newly added command will may not be found or will cause false
 776 # correction attempts, if you got auto-correction set. By setting the
 777 # following style, we force accept-line() to rehash, if it cannot
 778 # find the first word on the command line in the $command[] hash.
 779 zstyle ':acceptline:*' rehash true
 780
 781 function Accept-Line() {
 782     setopt localoptions noksharrays
 783     local -a subs
 784     local -xi aldone
 785     local sub
 786     local alcontext=${1:-$alcontext}
 787
 788     zstyle -a ":acceptline:${alcontext}" actions subs
 789
 790     (( ${#subs} < 1 )) && return 0
 791
 792     (( aldone = 0 ))
 793     for sub in ${subs} ; do
 794         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 795         zle ${sub}
 796
 797         (( aldone > 0 )) && break
 798     done
 799 }
 800
 801 function Accept-Line-getdefault() {
 802     emulate -L zsh
 803     local default_action
 804
 805     zstyle -s ":acceptline:${alcontext}" default_action default_action
 806     case ${default_action} in
 807         ((accept-line|))
 808             printf ".accept-line"
 809             ;;
 810         (*)
 811             printf ${default_action}
 812             ;;
 813     esac
 814 }
 815
 816 function Accept-Line-HandleContext() {
 817     zle Accept-Line
 818
 819     default_action=$(Accept-Line-getdefault)
 820     zstyle -T ":acceptline:${alcontext}" call_default \
 821         && zle ${default_action}
 822 }
 823
 824 function accept-line() {
 825     setopt localoptions noksharrays
 826     local -ax cmdline
 827     local -x alcontext
 828     local buf com fname format msg default_action
 829
 830     alcontext='default'
 831     buf="${BUFFER}"
 832     cmdline=(${(z)BUFFER})
 833     com="${cmdline[1]}"
 834     fname="_${com}"
 835
 836     Accept-Line 'preprocess'
 837
 838     zstyle -t ":acceptline:${alcontext}" rehash \
 839         && [[ -z ${commands[$com]} ]]           \
 840         && rehash
 841
 842     if    [[ -n ${com}               ]] \
 843        && [[ -n ${reswords[(r)$com]} ]] \
 844        || [[ -n ${aliases[$com]}     ]] \
 845        || [[ -n ${functions[$com]}   ]] \
 846        || [[ -n ${builtins[$com]}    ]] \
 847        || [[ -n ${commands[$com]}    ]] ; then
 848
 849         # there is something sensible to execute, just do it.
 850         alcontext='normal'
 851         Accept-Line-HandleContext
 852
 853         return
 854     fi
 855
 856     if    [[ -o correct              ]] \
 857        || [[ -o correctall           ]] \
 858        && [[ -n ${functions[$fname]} ]] ; then
 859
 860         # nothing there to execute but there is a function called
 861         # _command_name; a completion widget. Makes no sense to
 862         # call it on the commandline, but the correct{,all} options
 863         # will ask for it nevertheless, so warn the user.
 864         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 865             # Okay, we warned the user before, he called us again,
 866             # so have it his way.
 867             alcontext='force'
 868             Accept-Line-HandleContext
 869
 870             return
 871         fi
 872
 873         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 874             alcontext='normal'
 875             Accept-Line-HandleContext
 876         else
 877             # prepare warning message for the user, configurable via zstyle.
 878             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 879
 880             if [[ -z ${msg} ]] ; then
 881                 msg="%c will not execute and completion %f exists."
 882             fi
 883
 884             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 885
 886             zle -M -- "${msg}"
 887         fi
 888         return
 889     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 890         # If we are here, the commandline contains something that is not
 891         # executable, which is neither subject to _command_name correction
 892         # and is not empty. might be a variable assignment
 893         alcontext='misc'
 894         Accept-Line-HandleContext
 895
 896         return
 897     fi
 898
 899     # If we got this far, the commandline only contains whitespace, or is empty.
 900     alcontext='empty'
 901     Accept-Line-HandleContext
 902 }
 903
 904 zle -N accept-line
 905 zle -N Accept-Line
 906 zle -N Accept-Line-HandleContext
 907
 908 # power completion - abbreviation expansion
 909 # power completion / abbreviation expansion / buffer expansion
 910 # see http://zshwiki.org/home/examples/zleiab for details
 911 # less risky than the global aliases but powerful as well
 912 # just type the abbreviation key and afterwards ',.' to expand it
 913 declare -A abk
 914 setopt extendedglob
 915 setopt interactivecomments
 916 abk=(
 917 #   key   # value                  (#d additional doc string)
 918 #A# start
 919     '...'  '../..'
 920     '....' '../../..'
 921     'BG'   '& exit'
 922     'C'    '| wc -l'
 923     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
 924     'H'    '| head'
 925     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 926     'L'    '| less'
 927     'LL'   '|& less -r'
 928     'M'    '| most'
 929     'N'    '&>/dev/null'           #d (No Output)
 930     'R'    '| tr A-z N-za-m'       #d (ROT13)
 931     'SL'   '| sort | less'
 932     'S'    '| sort -u'
 933     'T'    '| tail'
 934     'V'    '|& vim -'
 935 #A# end
 936     'co'   './configure && make && sudo make install'
 937 )
 938
 939 zleiab() {
 940     emulate -L zsh
 941     setopt extendedglob
 942     local MATCH
 943
 944     if (( NOABBREVIATION > 0 )) ; then
 945         LBUFFER="${LBUFFER},."
 946         return 0
 947     fi
 948
 949     LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
 950     LBUFFER+=${abk[$MATCH]:-$MATCH}
 951 }
 952
 953 zle -N zleiab && bindkey ",." zleiab
 954
 955 #f# display contents of assoc array $abk
 956 help-show-abk()
 957 {
 958   zle -M "$(print "Type ,. after these abbreviations to expand them:"; print -a -C 2 ${(kv)abk})"
 959 }
 960 #k# Display list of abbreviations that expand when followed by ,.
 961 zle -N help-show-abk && bindkey '^xb' help-show-abk
 962
 963 # autoloading
 964 zrcautoload zmv    # who needs mmv or rename?
 965 zrcautoload history-search-end
 966
 967 # we don't want to quote/espace URLs on our own...
 968 # if autoload -U url-quote-magic ; then
 969 #    zle -N self-insert url-quote-magic
 970 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 971 # else
 972 #    print 'Notice: no url-quote-magic available :('
 973 # fi
 974 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 975
 976 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 977 alias run-help >&/dev/null && unalias run-help
 978 for rh in run-help{,-git,-svk,-svn}; do
 979     zrcautoload $rh
 980 done; unset rh
 981
 982 # completion system
 983 if zrcautoload compinit ; then
 984     compinit || print 'Notice: no compinit available :('
 985 else
 986     print 'Notice: no compinit available :('
 987     function compdef { }
 988 fi
 989
 990 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 991
 992 is4 && \
 993 for mod in complist deltochar mathfunc ; do
 994     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 995 done
 996
 997 # autoload zsh modules when they are referenced
 998 if is4 ; then
 999     zmodload -a  zsh/stat    zstat
1000     zmodload -a  zsh/zpty    zpty
1001     zmodload -ap zsh/mapfile mapfile
1002 fi
1003
1004 if is4 && zrcautoload insert-files && zle -N insert-files ; then
1005     #k# Insert files and test globbing
1006     bindkey "^xf" insert-files # C-x-f
1007 fi
1008
1009 bindkey ' '   magic-space    # also do history expansion on space
1010 #k# Trigger menu-complete
1011 bindkey '\ei' menu-complete  # menu completion via esc-i
1012
1013 # press esc-e for editing command line in $EDITOR or $VISUAL
1014 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
1015     #k# Edit the current line in \kbd{\$EDITOR}
1016     bindkey '\ee' edit-command-line
1017 fi
1018
1019 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
1020     #k# menu selection: pick item but stay in the menu
1021     bindkey -M menuselect '\e^M' accept-and-menu-complete
1022     # also use + and INSERT since it's easier to press repeatedly
1023     bindkey -M menuselect "+" accept-and-menu-complete
1024     bindkey -M menuselect "^[[2~" accept-and-menu-complete
1025
1026     # accept a completion and try to complete again by using menu
1027     # completion; very useful with completing directories
1028     # by using 'undo' one's got a simple file browser
1029     bindkey -M menuselect '^o' accept-and-infer-next-history
1030 fi
1031
1032 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1033 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1034 zle -N insert-datestamp
1035
1036 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1037 bindkey '^ed' insert-datestamp
1038
1039 # press esc-m for inserting last typed word again (thanks to caphuso!)
1040 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1041 zle -N insert-last-typed-word;
1042
1043 #k# Insert last typed word
1044 bindkey "\em" insert-last-typed-word
1045
1046 function grml-zsh-fg() {
1047   if (( ${#jobstates} )); then
1048     zle .push-input
1049     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1050     BUFFER="${BUFFER}fg"
1051     zle .accept-line
1052   else
1053     zle -M 'No background jobs. Doing nothing.'
1054   fi
1055 }
1056 zle -N grml-zsh-fg
1057 #k# A smart shortcut for \kbd{fg<enter>}
1058 bindkey '^z' grml-zsh-fg
1059
1060 # run command line as user root via sudo:
1061 sudo-command-line() {
1062     [[ -z $BUFFER ]] && zle up-history
1063     if [[ $BUFFER != sudo\ * ]]; then
1064         BUFFER="sudo $BUFFER"
1065         CURSOR=$(( CURSOR+5 ))
1066     fi
1067 }
1068 zle -N sudo-command-line
1069
1070 #k# prepend the current command with "sudo"
1071 bindkey "^os" sudo-command-line
1072
1073 ### jump behind the first word on the cmdline.
1074 ### useful to add options.
1075 function jump_after_first_word() {
1076     local words
1077     words=(${(z)BUFFER})
1078
1079     if (( ${#words} <= 1 )) ; then
1080         CURSOR=${#BUFFER}
1081     else
1082         CURSOR=${#${words[1]}}
1083     fi
1084 }
1085 zle -N jump_after_first_word
1086 #k# jump to after first word (for adding options)
1087 bindkey '^x1' jump_after_first_word
1088
1089 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1090 zle -C hist-complete complete-word _generic
1091 zstyle ':completion:hist-complete:*' completer _history
1092 #k# complete word from history with menu
1093 bindkey "^x^x" hist-complete
1094
1095 ## complete word from currently visible Screen or Tmux buffer.
1096 if check_com -c screen || check_com -c tmux; then
1097     _complete_screen_display() {
1098         [[ "$TERM" != "screen" ]] && return 1
1099
1100         local TMPFILE=$(mktemp)
1101         local -U -a _screen_display_wordlist
1102         trap "rm -f $TMPFILE" EXIT
1103
1104         # fill array with contents from screen hardcopy
1105         if ((${+TMUX})); then
1106             #works, but crashes tmux below version 1.4
1107             #luckily tmux -V option to ask for version, was also added in 1.4
1108             tmux -V &>/dev/null || return
1109             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1110         else
1111             screen -X hardcopy $TMPFILE
1112             # screen sucks, it dumps in latin1, apparently always. so recode it
1113             # to system charset
1114             check_com recode && recode latin1 $TMPFILE
1115         fi
1116         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1117         # remove PREFIX to be completed from that array
1118         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1119         compadd -a _screen_display_wordlist
1120     }
1121     #k# complete word from currently visible GNU screen buffer
1122     bindkey -r "^xS"
1123     compdef -k _complete_screen_display complete-word '^xS'
1124 fi
1125
1126 # history
1127
1128 ZSHDIR=${ZDOTDIR:-${HOME}/.zsh}
1129
1130 #v#
1131 HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1132 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1133 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1134
1135 # dirstack handling
1136
1137 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1138 DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1139
1140 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1141     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1142     # "cd -" won't work after login by just setting $OLDPWD, so
1143     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1144 fi
1145
1146 chpwd() {
1147     local -ax my_stack
1148     my_stack=( ${PWD} ${dirstack} )
1149     if is42 ; then
1150         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1151     else
1152         uprint my_stack >! ${DIRSTACKFILE}
1153     fi
1154 }
1155
1156 # directory based profiles
1157
1158 if is433 ; then
1159
1160 # chpwd_profiles(): Directory Profiles, Quickstart:
1161 #
1162 # In .zshrc.local:
1163 #
1164 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1165 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1166 #   chpwd_profiles
1167 #
1168 # For details see the `grmlzshrc.5' manual page.
1169 function chpwd_profiles() {
1170     local profile context
1171     local -i reexecute
1172
1173     context=":chpwd:profiles:$PWD"
1174     zstyle -s "$context" profile profile || profile='default'
1175     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1176
1177     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1178         typeset -g CHPWD_PROFILE
1179         local CHPWD_PROFILES_INIT=1
1180         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1181     elif [[ $profile != $CHPWD_PROFILE ]]; then
1182         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1183             && chpwd_leave_profile_${CHPWD_PROFILE}
1184     fi
1185     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1186         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1187     fi
1188
1189     CHPWD_PROFILE="${profile}"
1190     return 0
1191 }
1192
1193 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1194
1195 fi # is433
1196
1197 # Prompt setup for grml:
1198
1199 # set colors for use in prompts (modern zshs allow for the use of %F{red}foo%f
1200 # in prompts to get a red "foo" embedded, but it's good to keep these for
1201 # backwards compatibility).
1202 if zrcautoload colors && colors 2>/dev/null ; then
1203     BLUE="%{${fg[blue]}%}"
1204     RED="%{${fg_bold[red]}%}"
1205     GREEN="%{${fg[green]}%}"
1206     CYAN="%{${fg[cyan]}%}"
1207     MAGENTA="%{${fg[magenta]}%}"
1208     YELLOW="%{${fg[yellow]}%}"
1209     WHITE="%{${fg[white]}%}"
1210     NO_COLOR="%{${reset_color}%}"
1211 else
1212     BLUE=$'%{\e[1;34m%}'
1213     RED=$'%{\e[1;31m%}'
1214     GREEN=$'%{\e[1;32m%}'
1215     CYAN=$'%{\e[1;36m%}'
1216     WHITE=$'%{\e[1;37m%}'
1217     MAGENTA=$'%{\e[1;35m%}'
1218     YELLOW=$'%{\e[1;33m%}'
1219     NO_COLOR=$'%{\e[0m%}'
1220 fi
1221
1222 # First, the easy ones: PS2..4:
1223
1224 # secondary prompt, printed when the shell needs more information to complete a
1225 # command.
1226 PS2='\`%_> '
1227 # selection prompt used within a select loop.
1228 PS3='?# '
1229 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1230 PS4='+%N:%i:%_> '
1231
1232 # Some additional features to use with our prompt:
1233 #
1234 #    - battery status
1235 #    - debian_chroot
1236 #    - vcs_info setup and version specific fixes
1237 #    - command-not-found handling
1238 #      (TODO: This has nothing to do with prompts: move!)
1239
1240 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1241 if [[ $BATTERY -gt 0 ]] ; then
1242     if ! check_com -c acpi ; then
1243         BATTERY=0
1244     fi
1245 fi
1246
1247 battery() {
1248 if [[ $BATTERY -gt 0 ]] ; then
1249     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1250     if [[ -z "$PERCENT" ]] ; then
1251         PERCENT='acpi not present'
1252     else
1253         if [[ "$PERCENT" -lt 20 ]] ; then
1254             PERCENT="warning: ${PERCENT}%%"
1255         else
1256             PERCENT="${PERCENT}%%"
1257         fi
1258     fi
1259 fi
1260 }
1261
1262 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1263 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1264     debian_chroot=$(cat /etc/debian_chroot)
1265 fi
1266
1267 # gather version control information for inclusion in a prompt
1268
1269 if zrcautoload vcs_info; then
1270     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1271     # function, which can cause a lot of trouble with our directory-based
1272     # profiles. So:
1273     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1274         function VCS_INFO_realpath () {
1275             setopt localoptions NO_shwordsplit chaselinks
1276             ( builtin cd -q $1 2> /dev/null && pwd; )
1277         }
1278     fi
1279
1280     zstyle ':vcs_info:*' max-exports 2
1281
1282     if [[ -o restricted ]]; then
1283         zstyle ':vcs_info:*' enable NONE
1284     fi
1285 fi
1286
1287 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1288 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1289 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1290 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1291 #       to $vcs_info_msg_N_ as soon as we use the included version.
1292 if [[ "$TERM" == dumb ]] ; then
1293     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1294     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1295 else
1296     # these are the same, just with a lot of colors:
1297     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} " \
1298                                        "zsh: %r"
1299     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR}%} " \
1300                                        "zsh: %r"
1301     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1302 fi
1303
1304 # command not found handling
1305
1306 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1307 function command_not_found_handler() {
1308     emulate -L zsh
1309     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1310         ${GRML_ZSH_CNF_HANDLER} $1
1311     fi
1312     return 1
1313 }
1314
1315 # Now for the fun part: The grml prompt themes in `promptsys' mode of operation
1316
1317 # This actually defines three prompts:
1318 #
1319 #    - grml
1320 #    - grml-large
1321 #    - grml-chroot
1322 #
1323 # They all share the same code and only differ with respect to which items they
1324 # contain. The main source of documentation is the `prompt_grml_help' function
1325 # below, which gets called when the user does this: prompt -h grml
1326
1327 function prompt_grml_help () {
1328     cat <<__EOF0__
1329   prompt grml
1330
1331     This is the prompt as used by the grml-live system <http://grml.org>. It is
1332     a rather simple one-line prompt, that by default looks something like this:
1333
1334         <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1335
1336     The prompt itself integrates with zsh's prompt themes system (as you are
1337     witnessing right now) and is configurable to a certain degree. In
1338     particular, these aspects are customisable:
1339
1340         - The items used in the prompt (e.g. you can remove \`user' from
1341           the list of activated items, which will cause the user name to
1342           be omitted from the prompt string).
1343
1344         - The attributes used with the items are customisable via strings
1345           used before and after the actual item.
1346
1347     The available items are: rc, rc-always, change-root, user, at, host, path,
1348     vcs, percent, sad-smiley, battery.
1349
1350     The actual configuration is done via zsh's \`zstyle' mechanism. The
1351     context, that is used while looking up styles is:
1352
1353         ':prompt:grml:<left-or-right>:<subcontext>'
1354
1355     Here <left-or-right> is either \`left' or \`right', signifying whether the
1356     style should affect the left or the right prompt. <subcontext> is either
1357     \`setup' or 'items:<item>', where \`<item>' is one of the available items.
1358
1359     The styles:
1360
1361         - use-rprompt (boolean): If \`true' (the default), print a sad smiley
1362           in $RPROMPT if the last command a returned non-successful error code.
1363           (This in only valid if <left-or-right> is "right"; ignored otherwise)
1364
1365         - items (list): The list of items used in the prompt. If \`vcs' is
1366           present in the list, the theme's code invokes \`vcs_info'
1367           accordingly. Default: rc user change-root at host path vcs precent
1368
1369     Available styles in 'items:<item>' are: pre, post. These are strings that
1370     are inserted before (pre) and after (post) the item in question. Thus, the
1371     following would cause the user name to be printed in red instead of the
1372     default blue:
1373
1374         zstyle ':prompt:grml:*:items:user' pre '%F{red}'
1375
1376     Note, that the \`post' style may remain at its default value, because its
1377     default value is '%f', which turns the foreground text attribute off (which
1378     is exactly, what is still required with the new \`pre' value).
1379 __EOF0__
1380 }
1381
1382 function grml_prompt_setup () {
1383     emulate -L zsh
1384     autoload -Uz vcs_info
1385     autoload -Uz add-zsh-hook
1386     add-zsh-hook precmd prompt_$1_precmd
1387 }
1388
1389 function prompt_grml_setup () {
1390     grml_prompt_setup grml
1391 }
1392
1393 function prompt_grml-chroot_setup () {
1394     grml_prompt_setup grml-chroot
1395 }
1396
1397 function prompt_grml-large_setup () {
1398     grml_prompt_setup grml-large
1399 }
1400
1401 # These maps define default tokens and pre-/post-decoration for items to be
1402 # used within the themes. All defaults may be customised in a context sensitive
1403 # matter by using zsh's `zstyle' mechanism.
1404 typeset -gA grml_prompt_pre_default \
1405             grml_prompt_post_default \
1406             grml_prompt_token_default
1407
1408 grml_prompt_pre_default=(
1409     rc                '%F{red}'
1410     rc-always         ''
1411     change-root       ''
1412     user              '%B%F{blue}'
1413     at                ''
1414     host              ''
1415     path              '%b'
1416     vcs               ''
1417     percent           ''
1418     sad-smiley        ''
1419     battery           ' '
1420     newline           ''
1421     jobs              '%F{cyan}'
1422     history           '%F{green}'
1423     date              '%F{blue}'
1424     time              '%F{blue}'
1425     shell-level       '%F{red}'
1426     grml-chroot       '%F{red}'
1427 )
1428
1429 grml_prompt_post_default=(
1430     rc                '%f'
1431     rc-always         ''
1432     change-root       ''
1433     user              '%f%b'
1434     at                ''
1435     host              ''
1436     path              '%B'
1437     vcs               ''
1438     percent           ''
1439     sad-smiley        ''
1440     battery           ''
1441     newline           ''
1442     jobs              '%f'
1443     history           '%f'
1444     date              '%f'
1445     time              '%f'
1446     shell-level       '%f'
1447     grml-chroot       '%f '
1448 )
1449
1450 grml_prompt_token_default=(
1451     rc                '%(?..%? )'
1452     rc-always         '%?'
1453     change-root       'debian_chroot'
1454     user              '%n'
1455     at                '@'
1456     host              '%m '
1457     path              '%40<..<%~%<< '
1458     vcs               '0'
1459     percent           '%% '
1460     sad-smiley        '%(?..:()'
1461     battery           'PERCENT'
1462     newline           $'\n'
1463     jobs              '[%j running job(s)] '
1464     history           '{history#%!} '
1465     date              '%D{%Y-%m-%d}'
1466     time              '%D{%H:%M:%S} '
1467     shell-level       '%(3L.+ .)'
1468     grml-chroot       'GRML_CHROOT'
1469 )
1470
1471 function grml_typeset_and_wrap () {
1472     emulate -L zsh
1473     local target="$1"
1474     local new="$2"
1475     local left="$3"
1476     local right="$4"
1477
1478     if (( ${+parameters[$new]} )); then
1479         typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
1480     fi
1481 }
1482
1483 function grml_prompt_addto () {
1484     emulate -L zsh
1485     local target="$1"
1486     local lr it apre apost new v
1487     local -a items
1488     shift
1489
1490     [[ $target == PS1 ]] && lr=left || lr=right
1491     zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
1492     typeset -g "${target}="
1493     for it in "${items[@]}"; do
1494         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
1495             || apre=${grml_prompt_pre_default[$it]}
1496         zstyle -s ":prompt:grml:${grmltheme}:${lr}:$it" post apost \
1497             || apost=${grml_prompt_post_default[$it]}
1498         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
1499             || new=${grml_prompt_token_default[$it]}
1500         typeset -g "${target}=${(P)target}${apre}"
1501         case $it in
1502             battery)
1503                 grml_typeset_and_wrap $target $new '' ''
1504                 ;;
1505             change-root)
1506                 grml_typeset_and_wrap $target $new '(' ')'
1507                 ;;
1508             grml-chroot)
1509                 if [[ -n ${(P)new} ]]; then
1510                     typeset -g "${target}=${(P)target}(CHROOT)"
1511                 fi
1512                 ;;
1513             vcs)
1514                 v="vcs_info_msg_${new}_"
1515                 if (( ! vcscalled )); then
1516                     vcs_info
1517                     vcscalled=1
1518                 fi
1519                 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
1520                     typeset -g "${target}=${(P)target}${(P)v}"
1521                 fi
1522                 ;;
1523             *) typeset -g "${target}=${(P)target}${new}" ;;
1524         esac
1525         typeset -g "${target}=${(P)target}${apost}"
1526     done
1527 }
1528
1529 function prompt_grml_precmd () {
1530     emulate -L zsh
1531     local grmltheme=grml
1532     local -a left_items right_items
1533     left_items=(rc change-root user at host path vcs percent)
1534     right_items=(sad-smiley)
1535
1536     prompt_grml_precmd_worker
1537 }
1538
1539 function prompt_grml-chroot_precmd () {
1540     emulate -L zsh
1541     local grmltheme=grml-chroot
1542     local -a left_items right_items
1543     left_items=(grml-chroot user at host path percent)
1544     right_items=()
1545
1546     prompt_grml_precmd_worker
1547 }
1548
1549 function prompt_grml-large_precmd () {
1550     emulate -L zsh
1551     local grmltheme=grml-large
1552     local -a left_items right_items
1553     left_items=(rc jobs history shell-level change-root time date newline
1554                 user at host path vcs percent)
1555     right_items=(sad-smiley)
1556
1557     prompt_grml_precmd_worker
1558 }
1559
1560 function prompt_grml_precmd_worker () {
1561     emulate -L zsh
1562     local -i vcscalled=0
1563
1564     grml_prompt_addto PS1 "${left_items[@]}"
1565     if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
1566         grml_prompt_addto RPS1 "${right_items[@]}"
1567     fi
1568 }
1569
1570 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1571     # Since we define the required functions in here and not in files in
1572     # $fpath, we need to stick the theme's name into `$prompt_themes'
1573     # ourselves, since promptinit does not pick them up otherwise.
1574     prompt_themes+=( grml grml-chroot grml-large )
1575     # Also, keep the array sorted...
1576     prompt_themes=( "${(@on)prompt_themes}" )
1577
1578     if [[ $BATTERY -gt 0 ]]; then
1579         zstyle ':prompt:grml:right:setup' items sad-smiley battery
1580         add-zsh-hook precmd battery
1581     fi
1582     if [[ "$TERM" == dumb ]] ; then
1583         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" pre ''
1584         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" post ' '
1585         for i in rc user path jobs history date time shell-level; do
1586             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" pre ''
1587             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" post ''
1588         done
1589         unset i
1590         zstyle ':prompt:grml(|-large|-chroot):right:setup' use-rprompt false
1591     elif (( EUID == 0 )); then
1592         zstyle ':prompt:grml(|-large|-chroot):*:items:user' pre '%F{red}'
1593     fi
1594
1595     # Finally enable one of the prompts.
1596     if [[ -n $GRML_CHROOT ]]; then
1597         prompt grml-chroot
1598     elif [[ $GRMLPROMPT -gt 0 ]]; then
1599         prompt grml-large
1600     else
1601         prompt grml
1602     fi
1603 else
1604     print 'Notice: no promptinit available :('
1605
1606     # Support a fallback, in case promptsys isn't available.
1607     setopt prompt_subst
1608
1609     precmd() { (( ${+functions[vcs_info]} )) && vcs_info; }
1610
1611     p0="${RED}%(?..%? )${WHITE}${debian_chroot:+($debian_chroot)}"
1612     p1="${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "'${vcs_info_msg_0_}'"%# "
1613     if (( EUID == 0 )); then
1614         PROMPT="${BLUE}${p0}${RED}${p1}"
1615     else
1616         PROMPT="${RED}${p0}${BLUE}${p1}"
1617     fi
1618     unset p0 p1
1619 fi
1620
1621 # make sure to use right prompt only when not running a command
1622 is41 && setopt transient_rprompt
1623
1624
1625 function ESC_print () {
1626     info_print $'\ek' $'\e\\' "$@"
1627 }
1628 function set_title () {
1629     info_print  $'\e]0;' $'\a' "$@"
1630 }
1631
1632 function info_print () {
1633     local esc_begin esc_end
1634     esc_begin="$1"
1635     esc_end="$2"
1636     shift 2
1637     printf '%s' ${esc_begin}
1638     printf '%s' "$*"
1639     printf '%s' "${esc_end}"
1640 }
1641
1642 function grml_reset_screen_title () {
1643     # adjust title of xterm
1644     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1645     [[ ${NOTITLE:-} -gt 0 ]] && return 0
1646     case $TERM in
1647         (xterm*|rxvt*)
1648             set_title ${(%):-"%n@%m: %~"}
1649             ;;
1650     esac
1651 }
1652
1653 function grml_vcs_to_screen_title () {
1654     if [[ $TERM == screen* ]] ; then
1655         if [[ -n ${vcs_info_msg_1_} ]] ; then
1656             ESC_print ${vcs_info_msg_1_}
1657         else
1658             ESC_print "zsh"
1659         fi
1660     fi
1661 }
1662
1663 zrcautoload add-zsh-hook || add-zsh-hook () { :; }
1664 if [[ $NOPRECMD -gt 0 ]]; then
1665     add-zsh-hook precmd grml_reset_screen_title
1666     add-zsh-hook precmd grml_vcs_to_screen_title
1667 fi
1668
1669 # preexec() => a function running before every command
1670 is4 && [[ $NOPRECMD -eq 0 ]] && \
1671 preexec () {
1672     [[ $NOPRECMD -gt 0 ]] && return 0
1673 # set hostname if not running on host with name 'grml'
1674     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1675        NAME="@$HOSTNAME"
1676     fi
1677 # get the name of the program currently running and hostname of local machine
1678 # set screen window title if running in a screen
1679     if [[ "$TERM" == screen* ]] ; then
1680         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1681         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1682         ESC_print ${CMD}
1683     fi
1684 # adjust title of xterm
1685     [[ ${NOTITLE} -gt 0 ]] && return 0
1686     case $TERM in
1687         (xterm*|rxvt*)
1688             set_title "${(%):-"%n@%m:"}" "$1"
1689             ;;
1690     esac
1691 }
1692
1693 # 'hash' some often used directories
1694 #d# start
1695 hash -d deb=/var/cache/apt/archives
1696 hash -d doc=/usr/share/doc
1697 hash -d linux=/lib/modules/$(command uname -r)/build/
1698 hash -d log=/var/log
1699 hash -d slog=/var/log/syslog
1700 hash -d src=/usr/src
1701 hash -d templ=/usr/share/doc/grml-templates
1702 hash -d tt=/usr/share/doc/texttools-doc
1703 hash -d www=/var/www
1704 #d# end
1705
1706 # some aliases
1707 if check_com -c screen ; then
1708     if [[ $UID -eq 0 ]] ; then
1709         if [[ -r /etc/grml/screenrc ]]; then
1710             alias screen="${commands[screen]} -c /etc/grml/screenrc"
1711         fi
1712     elif [[ -r $HOME/.screenrc ]] ; then
1713         alias screen="${commands[screen]} -c $HOME/.screenrc"
1714     else
1715         if [[ -r /etc/grml/screenrc_grml ]]; then
1716             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1717         else
1718             if [[ -r /etc/grml/screenrc ]]; then
1719                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
1720             fi
1721         fi
1722     fi
1723 fi
1724
1725 # do we have GNU ls with color-support?
1726 if [[ "$TERM" != dumb ]]; then
1727     #a1# execute \kbd{@a@}:\quad ls with colors
1728     alias ls='ls -b -CF '${ls_options:+"${ls_options[*]}"}
1729     #a1# execute \kbd{@a@}:\quad list all files, with colors
1730     alias la='ls -la '${ls_options:+"${ls_options[*]}"}
1731     #a1# long colored list, without dotfiles (@a@)
1732     alias ll='ls -l '${ls_options:+"${ls_options[*]}"}
1733     #a1# long colored list, human readable sizes (@a@)
1734     alias lh='ls -hAl '${ls_options:+"${ls_options[*]}"}
1735     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1736     alias l='ls -lF '${ls_options:+"${ls_options[*]}"}
1737 else
1738     alias ls='ls -b -CF'
1739     alias la='ls -la'
1740     alias ll='ls -l'
1741     alias lh='ls -hAl'
1742     alias l='ls -lF'
1743 fi
1744
1745 alias mdstat='cat /proc/mdstat'
1746 alias ...='cd ../../'
1747
1748 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1749 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1750     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1751 fi
1752
1753 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1754 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1755 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1756
1757 # make sure it is not assigned yet
1758 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1759 utf2iso() {
1760     if isutfenv ; then
1761         for ENV in $(env | command grep -i '.utf') ; do
1762             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1763         done
1764     fi
1765 }
1766
1767 # make sure it is not assigned yet
1768 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1769 iso2utf() {
1770     if ! isutfenv ; then
1771         for ENV in $(env | command grep -i '\.iso') ; do
1772             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1773         done
1774     fi
1775 }
1776
1777 # especially for roadwarriors using GNU screen and ssh:
1778 if ! check_com asc &>/dev/null ; then
1779   asc() { autossh -t "$@" 'screen -RdU' }
1780   compdef asc=ssh
1781 fi
1782
1783 #f1# Hints for the use of zsh on grml
1784 zsh-help() {
1785     print "$bg[white]$fg[black]
1786 zsh-help - hints for use of zsh on grml
1787 =======================================$reset_color"
1788
1789     print '
1790 Main configuration of zsh happens in /etc/zsh/zshrc.
1791 That file is part of the package grml-etc-core, if you want to
1792 use them on a non-grml-system just get the tar.gz from
1793 http://deb.grml.org/ or (preferably) get it from the git repository:
1794
1795   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1796
1797 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1798 The file is still there, but it is empty for backwards compatibility.
1799
1800 For your own changes use these two files:
1801     $HOME/.zshrc.pre
1802     $HOME/.zshrc.local
1803
1804 The former is sourced very early in our zshrc, the latter is sourced
1805 very lately.
1806
1807 System wide configuration without touching configuration files of grml
1808 can take place in /etc/zsh/zshrc.local.
1809
1810 For information regarding zsh start at http://grml.org/zsh/
1811
1812 Take a look at grml'\''s zsh refcard:
1813 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1814
1815 Check out the main zsh refcard:
1816 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1817
1818 And of course visit the zsh-lovers:
1819 % man zsh-lovers
1820
1821 You can adjust some options through environment variables when
1822 invoking zsh without having to edit configuration files.
1823 Basically meant for bash users who are not used to the power of
1824 the zsh yet. :)
1825
1826   "NOCOR=1    zsh" => deactivate automatic correction
1827   "NOMENU=1   zsh" => do not use auto menu completion
1828                       (note: use ctrl-d for completion instead!)
1829   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1830   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1831                       preexec() and precmd() completely
1832   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1833   "COMMAND_NOT_FOUND=1 zsh"
1834                    => Enable a handler if an external command was not found
1835                       The command called in the handler can be altered by setting
1836                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1837                       "/usr/share/command-not-found/command-not-found"
1838
1839 A value greater than 0 is enables a feature; a value equal to zero
1840 disables it. If you like one or the other of these settings, you can
1841 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1842 zshrc.'
1843
1844     print "
1845 $bg[white]$fg[black]
1846 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1847 Enjoy your grml system with the zsh!$reset_color"
1848 }
1849
1850 # debian stuff
1851 if [[ -r /etc/debian_version ]] ; then
1852     #a3# Execute \kbd{apt-cache search}
1853     alias acs='apt-cache search'
1854     #a3# Execute \kbd{apt-cache show}
1855     alias acsh='apt-cache show'
1856     #a3# Execute \kbd{apt-cache policy}
1857     alias acp='apt-cache policy'
1858     #a3# Execute \kbd{apt-get dist-upgrade}
1859     salias adg="apt-get dist-upgrade"
1860     #a3# Execute \kbd{apt-get install}
1861     salias agi="apt-get install"
1862     #a3# Execute \kbd{aptitude install}
1863     salias ati="aptitude install"
1864     #a3# Execute \kbd{apt-get upgrade}
1865     salias ag="apt-get upgrade"
1866     #a3# Execute \kbd{apt-get update}
1867     salias au="apt-get update"
1868     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1869     salias -a up="aptitude update ; aptitude safe-upgrade"
1870     #a3# Execute \kbd{dpkg-buildpackage}
1871     alias dbp='dpkg-buildpackage'
1872     #a3# Execute \kbd{grep-excuses}
1873     alias ge='grep-excuses'
1874
1875     # get a root shell as normal user in live-cd mode:
1876     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1877        alias su="sudo su"
1878      fi
1879
1880     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1881     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1882     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1883     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1884 fi
1885
1886 # sort installed Debian-packages by size
1887 if check_com -c dpkg-query ; then
1888     #a3# List installed Debian-packages sorted by size
1889     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1890 fi
1891
1892 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1893 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1894     if check_com -c wodim; then
1895         cdrecord() {
1896             cat <<EOMESS
1897 cdrecord is not provided under its original name by Debian anymore.
1898 See #377109 in the BTS of Debian for more details.
1899
1900 Please use the wodim binary instead
1901 EOMESS
1902             return 1
1903         }
1904     fi
1905 fi
1906
1907 # Use hard limits, except for a smaller stack and no core dumps
1908 unlimit
1909 is425 && limit stack 8192
1910 isgrmlcd && limit core 0 # important for a live-cd-system
1911 limit -s
1912
1913 # completion system
1914
1915 # called later (via is4 && grmlcomp)
1916 # note: use 'zstyle' for getting current settings
1917 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
1918 grmlcomp() {
1919     # TODO: This could use some additional information
1920
1921     # allow one error for every three characters typed in approximate completer
1922     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1923
1924     # don't complete backup files as executables
1925     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1926
1927     # start menu completion only if it could find no unambiguous initial string
1928     zstyle ':completion:*:correct:*'       insert-unambiguous true
1929     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1930     zstyle ':completion:*:correct:*'       original true
1931
1932     # activate color-completion
1933     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1934
1935     # format on completion
1936     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1937
1938     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1939     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1940
1941     # insert all expansions for expand completer
1942     zstyle ':completion:*:expand:*'        tag-order all-expansions
1943     zstyle ':completion:*:history-words'   list false
1944
1945     # activate menu
1946     zstyle ':completion:*:history-words'   menu yes
1947
1948     # ignore duplicate entries
1949     zstyle ':completion:*:history-words'   remove-all-dups yes
1950     zstyle ':completion:*:history-words'   stop yes
1951
1952     # match uppercase from lowercase
1953     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1954
1955     # separate matches into groups
1956     zstyle ':completion:*:matches'         group 'yes'
1957     zstyle ':completion:*'                 group-name ''
1958
1959     if [[ "$NOMENU" -eq 0 ]] ; then
1960         # if there are more than 5 options allow selecting from a menu
1961         zstyle ':completion:*'               menu select=5
1962     else
1963         # don't use any menus at all
1964         setopt no_auto_menu
1965     fi
1966
1967     zstyle ':completion:*:messages'        format '%d'
1968     zstyle ':completion:*:options'         auto-description '%d'
1969
1970     # describe options in full
1971     zstyle ':completion:*:options'         description 'yes'
1972
1973     # on processes completion complete all user processes
1974     zstyle ':completion:*:processes'       command 'ps -au$USER'
1975
1976     # offer indexes before parameters in subscripts
1977     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1978
1979     # provide verbose completion information
1980     zstyle ':completion:*'                 verbose true
1981
1982     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1983     # for commands (read: 1st word in the line) that it will list for the user
1984     # to choose from. The following disables that, because it's not exactly fast.
1985     zstyle ':completion:*:-command-:*:'    verbose false
1986
1987     # set format for warnings
1988     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1989
1990     # define files to ignore for zcompile
1991     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1992     zstyle ':completion:correct:'          prompt 'correct to: %e'
1993
1994     # Ignore completion functions for commands you don't have:
1995     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1996
1997     # Provide more processes in completion of programs like killall:
1998     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1999
2000     # complete manual by their section
2001     zstyle ':completion:*:manuals'    separate-sections true
2002     zstyle ':completion:*:manuals.*'  insert-sections   true
2003     zstyle ':completion:*:man:*'      menu yes select
2004
2005     # Search path for sudo completion
2006     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
2007                                                /usr/local/bin  \
2008                                                /usr/sbin       \
2009                                                /usr/bin        \
2010                                                /sbin           \
2011                                                /bin            \
2012                                                /usr/X11R6/bin
2013
2014     # provide .. as a completion
2015     zstyle ':completion:*' special-dirs ..
2016
2017     # run rehash on completion so new installed program are found automatically:
2018     _force_rehash() {
2019         (( CURRENT == 1 )) && rehash
2020         return 1
2021     }
2022
2023     ## correction
2024     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
2025     if [[ "$NOCOR" -gt 0 ]] ; then
2026         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
2027         setopt nocorrect
2028     else
2029         # try to be smart about when to use what completer...
2030         setopt correct
2031         zstyle -e ':completion:*' completer '
2032             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
2033                 _last_try="$HISTNO$BUFFER$CURSOR"
2034                 reply=(_complete _match _ignored _prefix _files)
2035             else
2036                 if [[ $words[1] == (rm|mv) ]] ; then
2037                     reply=(_complete _files)
2038                 else
2039                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
2040                 fi
2041             fi'
2042     fi
2043
2044     # command for process lists, the local web server details and host completion
2045     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
2046
2047     # caching
2048     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
2049                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
2050
2051     # host completion
2052     if is42 ; then
2053         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
2054         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
2055     else
2056         _ssh_hosts=()
2057         _etc_hosts=()
2058     fi
2059     hosts=(
2060         $(hostname)
2061         "$_ssh_hosts[@]"
2062         "$_etc_hosts[@]"
2063         localhost
2064     )
2065     zstyle ':completion:*:hosts' hosts $hosts
2066     # TODO: so, why is this here?
2067     #  zstyle '*' hosts $hosts
2068
2069     # use generic completion system for programs not yet defined; (_gnu_generic works
2070     # with commands that provide a --help option with "standard" gnu-like output.)
2071     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
2072                    pal stow tail uname ; do
2073         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
2074     done; unset compcom
2075
2076     # see upgrade function in this file
2077     compdef _hosts upgrade
2078 }
2079
2080 # grmlstuff
2081 grmlstuff() {
2082 # people should use 'grml-x'!
2083     if check_com -c 915resolution; then
2084         855resolution() {
2085             echo "Please use 915resolution as resolution modifying tool for Intel \
2086 graphic chipset."
2087             return -1
2088         }
2089     fi
2090
2091     #a1# Output version of running grml
2092     alias grml-version='cat /etc/grml_version'
2093
2094     if check_com -c rebuildfstab ; then
2095         #a1# Rebuild /etc/fstab
2096         alias grml-rebuildfstab='rebuildfstab -v -r -config'
2097     fi
2098
2099     if check_com -c grml-debootstrap ; then
2100         debian2hd() {
2101             echo "Installing debian to harddisk is possible by using grml-debootstrap."
2102             return 1
2103         }
2104     fi
2105 }
2106
2107 # now run the functions
2108 isgrml && checkhome
2109 is4    && isgrml    && grmlstuff
2110 is4    && grmlcomp
2111
2112 # keephack
2113 is4 && xsource "/etc/zsh/keephack"
2114
2115 # wonderful idea of using "e" glob qualifier by Peter Stephenson
2116 # You use it as follows:
2117 # $ NTREF=/reference/file
2118 # $ ls -l *(e:nt:)
2119 # This lists all the files in the current directory newer than the reference file.
2120 # You can also specify the reference file inline; note quotes:
2121 # $ ls -l *(e:'nt ~/.zshenv':)
2122 is4 && nt() {
2123     if [[ -n $1 ]] ; then
2124         local NTREF=${~1}
2125     fi
2126     [[ $REPLY -nt $NTREF ]]
2127 }
2128
2129 # shell functions
2130
2131 #f1# Reload an autoloadable function
2132 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2133 compdef _functions freload
2134
2135 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2136 sll() {
2137     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2138     for file in "$@" ; do
2139         while [[ -h "$file" ]] ; do
2140             ls -l $file
2141             file=$(readlink "$file")
2142         done
2143     done
2144 }
2145
2146 # TODO: Is it supported to use pager settings like this?
2147 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2148 # with respect to wordsplitting. (ie. ${=PAGER})
2149 if check_com -c $PAGER ; then
2150     #f1# View Debian's changelog of a given package
2151     dchange() {
2152         emulate -L zsh
2153         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
2154             $PAGER /usr/share/doc/$1/changelog.Debian.gz
2155         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2156             $PAGER /usr/share/doc/$1/changelog.gz
2157         else
2158             if check_com -c aptitude ; then
2159                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2160                 if isgrml ; then
2161                     aptitude -t unstable changelog $1
2162                 else
2163                     aptitude changelog $1
2164                 fi
2165             else
2166                 echo "No changelog for package $1 found, sorry."
2167                 return 1
2168             fi
2169         fi
2170     }
2171     _dchange() { _files -W /usr/share/doc -/ }
2172     compdef _dchange dchange
2173
2174     #f1# View Debian's NEWS of a given package
2175     dnews() {
2176         emulate -L zsh
2177         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2178             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2179         else
2180             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2181                 $PAGER /usr/share/doc/$1/NEWS.gz
2182             else
2183                 echo "No NEWS file for package $1 found, sorry."
2184                 return 1
2185             fi
2186         fi
2187     }
2188     _dnews() { _files -W /usr/share/doc -/ }
2189     compdef _dnews dnews
2190
2191     #f1# View Debian's copyright of a given package
2192     dcopyright() {
2193         emulate -L zsh
2194         if [[ -r /usr/share/doc/$1/copyright ]] ; then
2195             $PAGER /usr/share/doc/$1/copyright
2196         else
2197             echo "No copyright file for package $1 found, sorry."
2198             return 1
2199         fi
2200     }
2201     _dcopyright() { _files -W /usr/share/doc -/ }
2202     compdef _dcopyright dcopyright
2203
2204     #f1# View upstream's changelog of a given package
2205     uchange() {
2206         emulate -L zsh
2207         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2208             $PAGER /usr/share/doc/$1/changelog.gz
2209         else
2210             echo "No changelog for package $1 found, sorry."
2211             return 1
2212         fi
2213     }
2214     _uchange() { _files -W /usr/share/doc -/ }
2215     compdef _uchange uchange
2216 fi
2217
2218 # zsh profiling
2219 profile() {
2220     ZSH_PROFILE_RC=1 $SHELL "$@"
2221 }
2222
2223 #f1# Edit an alias via zle
2224 edalias() {
2225     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2226 }
2227 compdef _aliases edalias
2228
2229 #f1# Edit a function via zle
2230 edfunc() {
2231     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2232 }
2233 compdef _functions edfunc
2234
2235 # use it e.g. via 'Restart apache2'
2236 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2237 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2238 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2239 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2240 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2241 #m# f6 Status() \kbd{/etc/init.d/\em{process}}\quad\kbd{status}
2242 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2243     __start_stop() {
2244         local action_="${1:l}"  # e.g Start/Stop/Restart
2245         local service_="$2"
2246         local param_="$3"
2247
2248         local service_target_="$(readlink /etc/init.d/$service_)"
2249         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2250             # runit
2251             case "${action_}" in
2252                 start) if [[ ! -e /etc/service/$service_ ]]; then
2253                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2254                        else
2255                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2256                        fi ;;
2257                 # there is no reload in runits sysv emulation
2258                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2259                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2260             esac
2261         else
2262             # sysvinit
2263             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2264         fi
2265     }
2266
2267     _grmlinitd() {
2268         local -a scripts
2269         scripts=( /etc/init.d/*(x:t) )
2270         _describe "service startup script" scripts
2271     }
2272
2273     for i in Start Restart Stop Force-Reload Reload Status ; do
2274         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2275         compdef _grmlinitd $i
2276     done
2277 fi
2278
2279 #f1# Provides useful information on globbing
2280 H-Glob() {
2281     echo -e "
2282     /      directories
2283     .      plain files
2284     @      symbolic links
2285     =      sockets
2286     p      named pipes (FIFOs)
2287     *      executable plain files (0100)
2288     %      device files (character or block special)
2289     %b     block special files
2290     %c     character special files
2291     r      owner-readable files (0400)
2292     w      owner-writable files (0200)
2293     x      owner-executable files (0100)
2294     A      group-readable files (0040)
2295     I      group-writable files (0020)
2296     E      group-executable files (0010)
2297     R      world-readable files (0004)
2298     W      world-writable files (0002)
2299     X      world-executable files (0001)
2300     s      setuid files (04000)
2301     S      setgid files (02000)
2302     t      files with the sticky bit (01000)
2303
2304   print *(m-1)          # Files modified up to a day ago
2305   print *(a1)           # Files accessed a day ago
2306   print *(@)            # Just symlinks
2307   print *(Lk+50)        # Files bigger than 50 kilobytes
2308   print *(Lk-50)        # Files smaller than 50 kilobytes
2309   print **/*.c          # All *.c files recursively starting in \$PWD
2310   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2311   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2312   print *~*.*           # All Files that do not contain a dot
2313   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2314   print -l *(.c|.h)     # Lists *.c and *.h
2315   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2316   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2317 }
2318 alias help-zshglob=H-Glob
2319
2320 #v1# set number of lines to display per page
2321 HELP_LINES_PER_PAGE=20
2322 #v1# set location of help-zle cache file
2323 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
2324 #f1# helper function for help-zle, actually generates the help text
2325 help_zle_parse_keybindings()
2326 {
2327     emulate -L zsh
2328     setopt extendedglob
2329     unsetopt ksharrays  #indexing starts at 1
2330
2331     #v1# choose files that help-zle will parse for keybindings
2332     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
2333
2334     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
2335         local load_cache=0
2336         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
2337         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
2338     fi
2339
2340     #fill with default keybindings, possibly to be overwriten in a file later
2341     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2342     local -A help_zle_keybindings
2343     help_zle_keybindings['<Ctrl>@']="set MARK"
2344     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
2345     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
2346     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
2347     help_zle_keybindings['<Ctrl>_']="undo"
2348     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
2349     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
2350     help_zle_keybindings['<Ctrl>e']="goto end of line"
2351     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2352     help_zle_keybindings['<Alt>t']="transpose words"
2353     help_zle_keybindings['<Alt>s']="spellcheck word"
2354     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
2355     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
2356     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2357     help_zle_keybindings["<Alt>'"]="quote line"
2358     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2359     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2360     help_zle_keybindings['<Alt>u']="make next word Uppercase"
2361     help_zle_keybindings['<Alt>l']="make next word lowercase"
2362     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
2363     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2364     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2365     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2366     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2367     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
2368     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2369     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2370     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
2371
2372     #init global variables
2373     unset help_zle_lines help_zle_sln
2374     typeset -g -a help_zle_lines
2375     typeset -g help_zle_sln=1
2376
2377     local k v
2378     local lastkeybind_desc contents     #last description starting with #k# that we found
2379     local num_lines_elapsed=0            #number of lines between last description and keybinding
2380     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2381     for f in $HELPZLE_KEYBINDING_FILES; do
2382         [[ -r "$f" ]] || continue   #not readable ? skip it
2383         contents="$(<$f)"
2384         for cline in "${(f)contents}"; do
2385             #zsh pattern: matches lines like: #k# ..............
2386             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2387                 lastkeybind_desc="$match[*]"
2388                 num_lines_elapsed=0
2389             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2390             #             ignores lines that are commentend out
2391             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2392             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2393                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2394                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2395                     #substitute keybinding string with something readable
2396                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2397                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2398                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2399                     help_zle_keybindings[${k}]=$lastkeybind_desc
2400                 fi
2401                 lastkeybind_desc=""
2402             else
2403               ((num_lines_elapsed++))
2404             fi
2405         done
2406     done
2407     unset contents
2408     #calculate length of keybinding column
2409     local kstrlen=0
2410     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2411     #convert the assoc array into preformated lines, which we are able to sort
2412     for k v in ${(kv)help_zle_keybindings[@]}; do
2413         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2414         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2415     done
2416     #sort lines alphabetically
2417     help_zle_lines=("${(i)help_zle_lines[@]}")
2418     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2419     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2420     zcompile $HELP_ZLE_CACHE_FILE
2421 }
2422 typeset -g help_zle_sln
2423 typeset -g -a help_zle_lines
2424
2425 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2426 help-zle()
2427 {
2428     emulate -L zsh
2429     unsetopt ksharrays  #indexing starts at 1
2430     #help lines already generated ? no ? then do it
2431     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2432     #already displayed all lines ? go back to the start
2433     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2434     local sln=$help_zle_sln
2435     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2436     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2437     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2438 }
2439 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2440 zle -N help-zle && bindkey '^xz' help-zle
2441
2442 # grep for running process, like: 'any vim'
2443 any() {
2444     emulate -L zsh
2445     unsetopt KSH_ARRAYS
2446     if [[ -z "$1" ]] ; then
2447         echo "any - grep for process(es) by keyword" >&2
2448         echo "Usage: any <keyword>" >&2 ; return 1
2449     else
2450         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
2451     fi
2452 }
2453
2454
2455 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2456 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2457 [[ -r /proc/1/maps ]] && \
2458 deswap() {
2459     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2460     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2461     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2462 }
2463
2464 # a wrapper for vim, that deals with title setting
2465 #   VIM_OPTIONS
2466 #       set this array to a set of options to vim you always want
2467 #       to have set when calling vim (in .zshrc.local), like:
2468 #           VIM_OPTIONS=( -p )
2469 #       This will cause vim to send every file given on the
2470 #       commandline to be send to it's own tab (needs vim7).
2471 if check_com vim; then
2472     vim() {
2473         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2474     }
2475 fi
2476
2477 # make a backup of a file
2478 bk() {
2479     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2480 }
2481
2482 ssl_hashes=( sha512 sha256 sha1 md5 )
2483
2484 for sh in ${ssl_hashes}; do
2485     eval 'ssl-cert-'${sh}'() {
2486         emulate -L zsh
2487         if [[ -z $1 ]] ; then
2488             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2489             return 1
2490         fi
2491         openssl x509 -noout -fingerprint -'${sh}' -in $1
2492     }'
2493 done; unset sh
2494
2495 ssl-cert-fingerprints() {
2496     emulate -L zsh
2497     local i
2498     if [[ -z $1 ]] ; then
2499         printf 'usage: ssl-cert-fingerprints <file>\n'
2500         return 1
2501     fi
2502     for i in ${ssl_hashes}
2503         do ssl-cert-$i $1;
2504     done
2505 }
2506
2507 ssl-cert-info() {
2508     emulate -L zsh
2509     if [[ -z $1 ]] ; then
2510         printf 'usage: ssl-cert-info <file>\n'
2511         return 1
2512     fi
2513     openssl x509 -noout -text -in $1
2514     ssl-cert-fingerprints $1
2515 }
2516
2517 # make sure our environment is clean regarding colors
2518 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2519
2520 # "persistent history"
2521 # just write important commands you always need to ~/.important_commands
2522 if [[ -r ~/.important_commands ]] ; then
2523     fc -R ~/.important_commands
2524 fi
2525
2526 # load the lookup subsystem if it's available on the system
2527 zrcautoload lookupinit && lookupinit
2528
2529 # variables
2530
2531 # set terminal property (used e.g. by msgid-chooser)
2532 export COLORTERM="yes"
2533
2534 # aliases
2535
2536 # general
2537 #a2# Execute \kbd{du -sch}
2538 alias da='du -sch'
2539 #a2# Execute \kbd{jobs -l}
2540 alias j='jobs -l'
2541
2542 # listing stuff
2543 #a2# Execute \kbd{ls -lSrah}
2544 alias dir="ls -lSrah"
2545 #a2# Only show dot-directories
2546 alias lad='ls -d .*(/)'
2547 #a2# Only show dot-files
2548 alias lsa='ls -a .*(.)'
2549 #a2# Only files with setgid/setuid/sticky flag
2550 alias lss='ls -l *(s,S,t)'
2551 #a2# Only show symlinks
2552 alias lsl='ls -l *(@)'
2553 #a2# Display only executables
2554 alias lsx='ls -l *(*)'
2555 #a2# Display world-{readable,writable,executable} files
2556 alias lsw='ls -ld *(R,W,X.^ND/)'
2557 #a2# Display the ten biggest files
2558 alias lsbig="ls -flh *(.OL[1,10])"
2559 #a2# Only show directories
2560 alias lsd='ls -d *(/)'
2561 #a2# Only show empty directories
2562 alias lse='ls -d *(/^F)'
2563 #a2# Display the ten newest files
2564 alias lsnew="ls -rtlh *(D.om[1,10])"
2565 #a2# Display the ten oldest files
2566 alias lsold="ls -rtlh *(D.Om[1,10])"
2567 #a2# Display the ten smallest files
2568 alias lssmall="ls -Srl *(.oL[1,10])"
2569 #a2# Display the ten newest directories and ten newest .directories
2570 alias lsnewdir="ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
2571 #a2# Display the ten oldest directories and ten oldest .directories
2572 alias lsolddir="ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
2573
2574 # some useful aliases
2575 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir $OLDCWD}
2576 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2577
2578 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2579 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2580 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2581
2582 # work around non utf8 capable software in utf environment via $LANG and luit
2583 if check_com isutfenv && check_com luit ; then
2584     if check_com -c mrxvt ; then
2585         isutfenv && [[ -n "$LANG" ]] && \
2586             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2587     fi
2588
2589     if check_com -c aterm ; then
2590         isutfenv && [[ -n "$LANG" ]] && \
2591             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2592     fi
2593
2594     if check_com -c centericq ; then
2595         isutfenv && [[ -n "$LANG" ]] && \
2596             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2597     fi
2598 fi
2599
2600 # useful functions
2601
2602 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2603 bk() {
2604     emulate -L zsh
2605     cp -b $1 $1_`date --iso-8601=m`
2606 }
2607
2608 #f5# cd to directoy and list files
2609 cl() {
2610     emulate -L zsh
2611     cd $1 && ls -a
2612 }
2613
2614 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2615 cd() {
2616     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2617         [[ ! -e ${1:h} ]] && return 1
2618         print "Correcting ${1} to ${1:h}"
2619         builtin cd ${1:h}
2620     else
2621         builtin cd "$@"
2622     fi
2623 }
2624
2625 #f5# Create Directoy and \kbd{cd} to it
2626 mkcd() {
2627     if (( ARGC != 1 )); then
2628         printf 'usage: mkcd <new-directory>\n'
2629         return 1;
2630     fi
2631     if [[ ! -d "$1" ]]; then
2632         command mkdir -p "$1"
2633     else
2634         printf '`%s'\'' already exists: cd-ing.\n' "$1"
2635     fi
2636     builtin cd "$1"
2637 }
2638
2639 #f5# Create temporary directory and \kbd{cd} to it
2640 cdt() {
2641     local t
2642     t=$(mktemp -d)
2643     echo "$t"
2644     builtin cd "$t"
2645 }
2646
2647 #f5# Create directory under cursor or the selected area
2648 # Press ctrl-xM to create the directory under the cursor or the selected area.
2649 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2650 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2651 # directory does not exist yet -> press ctrl-XM and problem solved
2652 inplaceMkDirs() {
2653     local PATHTOMKDIR
2654     if ((REGION_ACTIVE==1)); then
2655         local F=$MARK T=$CURSOR
2656         if [[ $F -gt $T ]]; then
2657             F=${CURSOR}
2658             T=${MARK}
2659         fi
2660         # get marked area from buffer and eliminate whitespace
2661         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2662         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2663     else
2664         local bufwords iword
2665         bufwords=(${(z)LBUFFER})
2666         iword=${#bufwords}
2667         bufwords=(${(z)BUFFER})
2668         PATHTOMKDIR="${(Q)bufwords[iword]}"
2669     fi
2670     [[ -z "${PATHTOMKDIR}" ]] && return 1
2671     PATHTOMKDIR=${~PATHTOMKDIR}
2672     if [[ -e "${PATHTOMKDIR}" ]]; then
2673         zle -M " path already exists, doing nothing"
2674     else
2675         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2676         zle end-of-line
2677     fi
2678 }
2679 #k# mkdir -p <dir> from string under cursor or marked area
2680 zle -N inplaceMkDirs && bindkey '^xM' inplaceMkDirs
2681
2682 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2683 accessed() {
2684     emulate -L zsh
2685     print -l -- *(a-${1:-1})
2686 }
2687
2688 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2689 changed() {
2690     emulate -L zsh
2691     print -l -- *(c-${1:-1})
2692 }
2693
2694 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2695 modified() {
2696     emulate -L zsh
2697     print -l -- *(m-${1:-1})
2698 }
2699 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2700 check_com new || alias new=modified
2701
2702 # use colors when GNU grep with color-support
2703 #a2# Execute \kbd{grep -{}-color=auto}
2704 (( $#grep_options > 0 )) && alias grep='grep '${grep_options:+"${grep_options[*]}"}
2705
2706 # Translate DE<=>EN
2707 # 'translate' looks up fot a word in a file with language-to-language
2708 # translations (field separator should be " : "). A typical wordlist looks
2709 # like at follows:
2710 #  | english-word : german-transmission
2711 # It's also only possible to translate english to german but not reciprocal.
2712 # Use the following oneliner to turn back the sort order:
2713 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2714 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2715 #f5# Translates a word
2716 trans() {
2717     emulate -L zsh
2718     case "$1" in
2719         -[dD]*)
2720             translate -l de-en $2
2721             ;;
2722         -[eE]*)
2723             translate -l en-de $2
2724             ;;
2725         *)
2726             echo "Usage: $0 { -D | -E }"
2727             echo "         -D == German to English"
2728             echo "         -E == English to German"
2729     esac
2730 }
2731
2732 # Usage: simple-extract <file>
2733 # Using option -d deletes the original archive file.
2734 #f5# Smart archive extractor
2735 simple-extract() {
2736     emulate -L zsh
2737     setopt extended_glob noclobber
2738     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2739     local RC=0
2740     zparseopts -D -E "d=DELETE_ORIGINAL"
2741     for ARCHIVE in "${@}"; do
2742         case $ARCHIVE in
2743             *(tar.bz2|tbz2|tbz))
2744                 DECOMP_CMD="tar -xvjf -"
2745                 USES_STDIN=true
2746                 USES_STDOUT=false
2747                 ;;
2748             *(tar.gz|tgz))
2749                 DECOMP_CMD="tar -xvzf -"
2750                 USES_STDIN=true
2751                 USES_STDOUT=false
2752                 ;;
2753             *(tar.xz|txz|tar.lzma))
2754                 DECOMP_CMD="tar -xvJf -"
2755                 USES_STDIN=true
2756                 USES_STDOUT=false
2757                 ;;
2758             *tar)
2759                 DECOMP_CMD="tar -xvf -"
2760                 USES_STDIN=true
2761                 USES_STDOUT=false
2762                 ;;
2763             *rar)
2764                 DECOMP_CMD="unrar x"
2765                 USES_STDIN=false
2766                 USES_STDOUT=false
2767                 ;;
2768             *lzh)
2769                 DECOMP_CMD="lha x"
2770                 USES_STDIN=false
2771                 USES_STDOUT=false
2772                 ;;
2773             *7z)
2774                 DECOMP_CMD="7z x"
2775                 USES_STDIN=false
2776                 USES_STDOUT=false
2777                 ;;
2778             *(zip|jar))
2779                 DECOMP_CMD="unzip"
2780                 USES_STDIN=false
2781                 USES_STDOUT=false
2782                 ;;
2783             *deb)
2784                 DECOMP_CMD="ar -x"
2785                 USES_STDIN=false
2786                 USES_STDOUT=false
2787                 ;;
2788             *bz2)
2789                 DECOMP_CMD="bzip2 -d -c -"
2790                 USES_STDIN=true
2791                 USES_STDOUT=true
2792                 ;;
2793             *(gz|Z))
2794                 DECOMP_CMD="gzip -d -c -"
2795                 USES_STDIN=true
2796                 USES_STDOUT=true
2797                 ;;
2798             *(xz|lzma))
2799                 DECOMP_CMD="xz -d -c -"
2800                 USES_STDIN=true
2801                 USES_STDOUT=true
2802                 ;;
2803             *)
2804                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2805                 RC=$((RC+1))
2806                 continue
2807                 ;;
2808         esac
2809
2810         if ! check_com ${DECOMP_CMD[(w)1]}; then
2811             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2812             RC=$((RC+2))
2813             continue
2814         fi
2815
2816         GZTARGET="${ARCHIVE:t:r}"
2817         if [[ -f $ARCHIVE ]] ; then
2818
2819             print "Extracting '$ARCHIVE' ..."
2820             if $USES_STDIN; then
2821                 if $USES_STDOUT; then
2822                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
2823                 else
2824                     ${=DECOMP_CMD} < "$ARCHIVE"
2825                 fi
2826             else
2827                 if $USES_STDOUT; then
2828                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
2829                 else
2830                     ${=DECOMP_CMD} "$ARCHIVE"
2831                 fi
2832             fi
2833             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
2834
2835         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
2836             if check_com curl; then
2837                 WGET_CMD="curl -L -k -s -o -"
2838             elif check_com wget; then
2839                 WGET_CMD="wget -q -O - --no-check-certificate"
2840             else
2841                 print "ERROR: neither wget nor curl is installed" >&2
2842                 RC=$((RC+4))
2843                 continue
2844             fi
2845             print "Downloading and Extracting '$ARCHIVE' ..."
2846             if $USES_STDIN; then
2847                 if $USES_STDOUT; then
2848                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
2849                     RC=$((RC+$?))
2850                 else
2851                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
2852                     RC=$((RC+$?))
2853                 fi
2854             else
2855                 if $USES_STDOUT; then
2856                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
2857                 else
2858                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
2859                 fi
2860             fi
2861
2862         else
2863             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
2864             RC=$((RC+8))
2865         fi
2866     done
2867     return $RC
2868 }
2869
2870 __archive_or_uri()
2871 {
2872     _alternative \
2873         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
2874         '_urls:Remote Archives:_urls'
2875 }
2876
2877 _simple_extract()
2878 {
2879     _arguments \
2880         '-d[delete original archivefile after extraction]' \
2881         '*:Archive Or Uri:__archive_or_uri'
2882 }
2883 compdef _simple_extract simple-extract
2884 alias se=simple-extract
2885
2886 #f5# Set all ulimit parameters to \kbd{unlimited}
2887 allulimit() {
2888     ulimit -c unlimited
2889     ulimit -d unlimited
2890     ulimit -f unlimited
2891     ulimit -l unlimited
2892     ulimit -n unlimited
2893     ulimit -s unlimited
2894     ulimit -t unlimited
2895 }
2896
2897 #f5# Change the xterm title from within GNU-screen
2898 xtrename() {
2899     emulate -L zsh
2900     if [[ $1 != "-f" ]] ; then
2901         if [[ -z ${DISPLAY} ]] ; then
2902             printf 'xtrename only makes sense in X11.\n'
2903             return 1
2904         fi
2905     else
2906         shift
2907     fi
2908     if [[ -z $1 ]] ; then
2909         printf 'usage: xtrename [-f] "title for xterm"\n'
2910         printf '  renames the title of xterm from _within_ screen.\n'
2911         printf '  also works without screen.\n'
2912         printf '  will not work if DISPLAY is unset, use -f to override.\n'
2913         return 0
2914     fi
2915     print -n "\eP\e]0;${1}\C-G\e\\"
2916     return 0
2917 }
2918
2919 # Create small urls via http://goo.gl using curl(1).
2920 # API reference: https://code.google.com/apis/urlshortener/
2921 function zurl() {
2922     emulate -L zsh
2923     setopt extended_glob
2924
2925     if [[ -z $1 ]]; then
2926         print "USAGE: zurl <URL>"
2927         return 1
2928     fi
2929
2930     local PN url prog api json contenttype item
2931     local -a data
2932     PN=$0
2933     url=$1
2934
2935     # Prepend 'http://' to given URL where necessary for later output.
2936     if [[ ${url} != http(s|)://* ]]; then
2937         url='http://'${url}
2938     fi
2939
2940     if check_com -c curl; then
2941         prog=curl
2942     else
2943         print "curl is not available, but mandatory for ${PN}. Aborting."
2944         return 1
2945     fi
2946     api='https://www.googleapis.com/urlshortener/v1/url'
2947     contenttype="Content-Type: application/json"
2948     json="{\"longUrl\": \"${url}\"}"
2949     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
2950     # Parse the response
2951     for item in "${data[@]}"; do
2952         case "$item" in
2953             ' '#'"id":'*)
2954                 item=${item#*: \"}
2955                 item=${item%\",*}
2956                 printf '%s\n' "$item"
2957                 return 0
2958                 ;;
2959         esac
2960     done
2961     return 1
2962 }
2963
2964 #f2# Find history events by search pattern and list them by date.
2965 whatwhen()  {
2966     emulate -L zsh
2967     local usage help ident format_l format_s first_char remain first last
2968     usage='USAGE: whatwhen [options] <searchstring> <search range>'
2969     help='Use `whatwhen -h'\'' for further explanations.'
2970     ident=${(l,${#${:-Usage: }},, ,)}
2971     format_l="${ident}%s\t\t\t%s\n"
2972     format_s="${format_l//(\\t)##/\\t}"
2973     # Make the first char of the word to search for case
2974     # insensitive; e.g. [aA]
2975     first_char=[${(L)1[1]}${(U)1[1]}]
2976     remain=${1[2,-1]}
2977     # Default search range is `-100'.
2978     first=${2:-\-100}
2979     # Optional, just used for `<first> <last>' given.
2980     last=$3
2981     case $1 in
2982         ("")
2983             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
2984             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2985         ;;
2986         (-h)
2987             printf '%s\n\n' ${usage}
2988             print 'OPTIONS:'
2989             printf $format_l '-h' 'show help text'
2990             print '\f'
2991             print 'SEARCH RANGE:'
2992             printf $format_l "'0'" 'the whole history,'
2993             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
2994             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
2995             printf '\n%s\n' 'EXAMPLES:'
2996             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
2997             printf $format_l 'whatwhen zsh -250'
2998             printf $format_l 'whatwhen foo 1 99'
2999         ;;
3000         (\?)
3001             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3002         ;;
3003         (*)
3004             # -l list results on stout rather than invoking $EDITOR.
3005             # -i Print dates as in YYYY-MM-DD.
3006             # -m Search for a - quoted - pattern within the history.
3007             fc -li -m "*${first_char}${remain}*" $first $last
3008         ;;
3009     esac
3010 }
3011
3012 # mercurial related stuff
3013 if check_com -c hg ; then
3014     # gnu like diff for mercurial
3015     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
3016     #f5# GNU like diff for mercurial
3017     hgdi() {
3018         emulate -L zsh
3019         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
3020     }
3021
3022     # build debian package
3023     #a2# Alias for \kbd{hg-buildpackage}
3024     alias hbp='hg-buildpackage'
3025
3026     # execute commands on the versioned patch-queue from the current repos
3027     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
3028
3029     # diffstat for specific version of a mercurial repository
3030     #   hgstat      => display diffstat between last revision and tip
3031     #   hgstat 1234 => display diffstat between revision 1234 and tip
3032     #f5# Diffstat for specific version of a mercurial repos
3033     hgstat() {
3034         emulate -L zsh
3035         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
3036     }
3037
3038 fi # end of check whether we have the 'hg'-executable
3039
3040 # grml-small cleanups
3041
3042 # The following is used to remove zsh-config-items that do not work
3043 # in grml-small by default.
3044 # If you do not want these adjustments (for whatever reason), set
3045 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
3046 # sources if it is there).
3047
3048 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
3049
3050     unset abk[V]
3051     unalias    'V'      &> /dev/null
3052     unfunction vman     &> /dev/null
3053     unfunction viless   &> /dev/null
3054     unfunction 2html    &> /dev/null
3055
3056     # manpages are not in grmlsmall
3057     unfunction manzsh   &> /dev/null
3058     unfunction man2     &> /dev/null
3059
3060 fi
3061
3062 zrclocal
3063
3064 ## genrefcard.pl settings
3065
3066 ### doc strings for external functions from files
3067 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
3068
3069 ### example: split functions-search 8,16,24,32
3070 #@# split functions-search 8
3071
3072 ## END OF FILE #################################################################
3073 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
3074 # Local variables:
3075 # mode: sh
3076 # End: