etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation: {{{
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104 #}}}
 105
 106 # zsh profiling {{{
 107 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 108 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 109     zmodload zsh/zprof
 110 fi
 111 # }}}
 112
 113 # load .zshrc.pre to give the user the chance to overwrite the defaults
 114 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
 115
 116 # {{{ check for version/system
 117 # check for versions (compatibility reasons)
 118 is4(){
 119     [[ $ZSH_VERSION == <4->* ]] && return 0
 120     return 1
 121 }
 122
 123 is41(){
 124     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 125     return 1
 126 }
 127
 128 is42(){
 129     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 130     return 1
 131 }
 132
 133 is425(){
 134     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 135     return 1
 136 }
 137
 138 is43(){
 139     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 140     return 1
 141 }
 142
 143 is433(){
 144     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* || $ZSH_VERSION == <5->* ]] && return 0
 145     return 1
 146 }
 147
 148 is439(){
 149     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 #f1# Checks whether or not you're running grml
 154 isgrml(){
 155     [[ -f /etc/grml_version ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running a grml cd
 160 isgrmlcd(){
 161     [[ -f /etc/grml_cd ]] && return 0
 162     return 1
 163 }
 164
 165 if isgrml ; then
 166 #f1# Checks whether or not you're running grml-small
 167     isgrmlsmall() {
 168         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 169     }
 170 else
 171     isgrmlsmall() { return 1 }
 172 fi
 173
 174 isdarwin(){
 175     [[ $OSTYPE == darwin* ]] && return 0
 176     return 1
 177 }
 178
 179 #f1# are we running within an utf environment?
 180 isutfenv() {
 181     case "$LANG $CHARSET $LANGUAGE" in
 182         *utf*) return 0 ;;
 183         *UTF*) return 0 ;;
 184         *)     return 1 ;;
 185     esac
 186 }
 187
 188 # check for user, if not running as root set $SUDO to sudo
 189 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 190
 191 # change directory to home on first invocation of zsh
 192 # important for rungetty -> autologin
 193 # Thanks go to Bart Schaefer!
 194 isgrml && checkhome() {
 195     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 196         export ALREADY_DID_CD_HOME=$HOME
 197         cd
 198     fi
 199 }
 200
 201 # check for zsh v3.1.7+
 202
 203 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 204      || ${ZSH_VERSION} == 3.<2->.<->*    \
 205      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 206
 207     printf '-!-\n'
 208     printf '-!- In this configuration we try to make use of features, that only\n'
 209     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 210     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 211     printf '-!- advanced features in all supported versions.\n'
 212     printf '-!-\n'
 213     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 214     printf '-!-\n'
 215     printf '-!- While this *may* work, it might as well fail.\n'
 216     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 217     printf '-!-\n'
 218     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 219     printf '-!- If it does today, you'\''ve been lucky.\n'
 220     printf '-!-\n'
 221     printf '-!- Ye been warned!\n'
 222     printf '-!-\n'
 223
 224     function zstyle() { : }
 225 fi
 226
 227 # autoload wrapper - use this one instead of autoload directly
 228 # We need to define this function as early as this, because autoloading
 229 # 'is-at-least()' needs it.
 230 function zrcautoload() {
 231     emulate -L zsh
 232     setopt extended_glob
 233     local fdir ffile
 234     local -i ffound
 235
 236     ffile=$1
 237     (( found = 0 ))
 238     for fdir in ${fpath} ; do
 239         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 240     done
 241
 242     (( ffound == 0 )) && return 1
 243     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 244         autoload -U ${ffile} || return 1
 245     else
 246         autoload ${ffile} || return 1
 247     fi
 248     return 0
 249 }
 250
 251 # Load is-at-least() for more precise version checks
 252 # Note that this test will *always* fail, if the is-at-least
 253 # function could not be marked for autoloading.
 254 zrcautoload is-at-least || is-at-least() { return 1 }
 255
 256 # }}}
 257
 258 # {{{ set some important options (as early as possible)
 259 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 260 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 261 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 262 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 263                             # list duplicates an older one, the older command is removed from the list
 264 setopt histignorespace      # remove command lines from the history list when
 265                             # the first character on the line is a space
 266 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 267                             # and the command is the name of a directory, perform the cd command to that directory
 268 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 269                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 270                             # -> searches for word not in compressed files
 271                             # don't forget to quote '^', '~' and '#'!
 272 setopt longlistjobs         # display PID when suspending processes as well
 273 setopt notify               # report the status of backgrounds jobs immediately
 274 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 275                             # the entire command path is hashed first.
 276 setopt completeinword       # not just at the end
 277 setopt nohup                # and don't kill them, either
 278 setopt auto_pushd           # make cd push the old directory onto the directory stack.
 279 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 280 setopt nobeep               # avoid "beep"ing
 281 setopt pushd_ignore_dups    # don't push the same dir twice.
 282 setopt noglobdots           # * shouldn't match dotfiles. ever.
 283 setopt noshwordsplit        # use zsh style word splitting
 284 setopt unset                # don't error out when unset parameters are used
 285
 286 # }}}
 287
 288 # setting some default values {{{
 289
 290 NOCOR=${NOCOR:-0}
 291 NOMENU=${NOMENU:-0}
 292 NOPRECMD=${NOPRECMD:-0}
 293 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 294 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 295 BATTERY=${BATTERY:-0}
 296 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 297 GRML_ALWAYS_LOAD_ALL=${GRML_ALWAYS_LOAD_ALL:-0}
 298 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 299
 300 # }}}
 301
 302 # utility functions {{{
 303 # this function checks if a command exists and returns either true
 304 # or false. This avoids using 'which' and 'whence', which will
 305 # avoid problems with aliases for which on certain weird systems. :-)
 306 # Usage: check_com [-c|-g] word
 307 #   -c  only checks for external commands
 308 #   -g  does the usual tests and also checks for global aliases
 309 check_com() {
 310     emulate -L zsh
 311     local -i comonly gatoo
 312
 313     if [[ $1 == '-c' ]] ; then
 314         (( comonly = 1 ))
 315         shift
 316     elif [[ $1 == '-g' ]] ; then
 317         (( gatoo = 1 ))
 318     else
 319         (( comonly = 0 ))
 320         (( gatoo = 0 ))
 321     fi
 322
 323     if (( ${#argv} != 1 )) ; then
 324         printf 'usage: check_com [-c] <command>\n' >&2
 325         return 1
 326     fi
 327
 328     if (( comonly > 0 )) ; then
 329         [[ -n ${commands[$1]}  ]] && return 0
 330         return 1
 331     fi
 332
 333     if   [[ -n ${commands[$1]}    ]] \
 334       || [[ -n ${functions[$1]}   ]] \
 335       || [[ -n ${aliases[$1]}     ]] \
 336       || [[ -n ${reswords[(r)$1]} ]] ; then
 337
 338         return 0
 339     fi
 340
 341     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 342         return 0
 343     fi
 344
 345     return 1
 346 }
 347
 348 # creates an alias and precedes the command with
 349 # sudo if $EUID is not zero.
 350 salias() {
 351     emulate -L zsh
 352     local only=0 ; local multi=0
 353     while [[ $1 == -* ]] ; do
 354         case $1 in
 355             (-o) only=1 ;;
 356             (-a) multi=1 ;;
 357             (--) shift ; break ;;
 358             (-h)
 359                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 360                 printf '  -h      shows this help text.\n'
 361                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 362                 printf '          be careful using this option.\n'
 363                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 364                 return 0
 365                 ;;
 366             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 367         esac
 368         shift
 369     done
 370
 371     if (( ${#argv} > 1 )) ; then
 372         printf 'Too many arguments %s\n' "${#argv}"
 373         return 1
 374     fi
 375
 376     key="${1%%\=*}" ;  val="${1#*\=}"
 377     if (( EUID == 0 )) && (( only == 0 )); then
 378         alias -- "${key}=${val}"
 379     elif (( EUID > 0 )) ; then
 380         (( multi > 0 )) && val="${val// ; / ; sudo }"
 381         alias -- "${key}=sudo ${val}"
 382     fi
 383
 384     return 0
 385 }
 386
 387 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 388 # usage: uprint foo
 389 #   Where foo is the *name* of the parameter you want printed.
 390 #   Note that foo is no typo; $foo would be wrong here!
 391 if ! is42 ; then
 392     uprint () {
 393         emulate -L zsh
 394         local -a u
 395         local w
 396         local parameter=$1
 397
 398         if [[ -z ${parameter} ]] ; then
 399             printf 'usage: uprint <parameter>\n'
 400             return 1
 401         fi
 402
 403         for w in ${(P)parameter} ; do
 404             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 405         done
 406
 407         builtin print -l $u
 408     }
 409 fi
 410
 411 # Check if we can read given files and source those we can.
 412 xsource() {
 413     if (( ${#argv} < 1 )) ; then
 414         printf 'usage: xsource FILE(s)...\n' >&2
 415         return 1
 416     fi
 417
 418     while (( ${#argv} > 0 )) ; do
 419         [[ -r "$1" ]] && source "$1"
 420         shift
 421     done
 422     return 0
 423 }
 424
 425 # Check if we can read a given file and 'cat(1)' it.
 426 xcat() {
 427     emulate -L zsh
 428     if (( ${#argv} != 1 )) ; then
 429         printf 'usage: xcat FILE\n' >&2
 430         return 1
 431     fi
 432
 433     [[ -r $1 ]] && cat $1
 434     return 0
 435 }
 436
 437 # Remove these functions again, they are of use only in these
 438 # setup files. This should be called at the end of .zshrc.
 439 xunfunction() {
 440     emulate -L zsh
 441     local -a funcs
 442     funcs=(salias xcat xsource xunfunction zrcautoload)
 443
 444     for func in $funcs ; do
 445         [[ -n ${functions[$func]} ]] \
 446             && unfunction $func
 447     done
 448     return 0
 449 }
 450
 451 # this allows us to stay in sync with grml's zshrc and put own
 452 # modifications in ~/.zshrc.local
 453 zrclocal() {
 454     xsource "/etc/zsh/zshrc.local"
 455     xsource "${HOME}/.zshrc.local"
 456     return 0
 457 }
 458
 459 #}}}
 460
 461 # locale setup {{{
 462 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 463     xsource "/etc/default/locale"
 464 fi
 465
 466 for var in LANG LC_ALL LC_MESSAGES ; do
 467     [[ -n ${(P)var} ]] && export $var
 468 done
 469
 470 xsource "/etc/sysconfig/keyboard"
 471
 472 TZ=$(xcat /etc/timezone)
 473 # }}}
 474
 475 # {{{ set some variables
 476 if check_com -c vim ; then
 477 #v#
 478     export EDITOR=${EDITOR:-vim}
 479 else
 480     export EDITOR=${EDITOR:-vi}
 481 fi
 482
 483 #v#
 484 export PAGER=${PAGER:-less}
 485
 486 #v#
 487 export MAIL=${MAIL:-/var/mail/$USER}
 488
 489 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 490 export SHELL='/bin/zsh'
 491
 492 # color setup for ls:
 493 check_com -c dircolors && eval $(dircolors -b)
 494 # color setup for ls on OS X:
 495 isdarwin && export CLICOLOR=1
 496
 497 # do MacPorts setup on darwin
 498 if isdarwin && [[ -d /opt/local ]]; then
 499     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 500     # zshenv.
 501     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 502     MANPATH="/opt/local/share/man:$MANPATH"
 503 fi
 504 # do Fink setup on darwin
 505 isdarwin && xsource /sw/bin/init.sh
 506
 507 # load our function and completion directories
 508 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 509     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 510     if [[ ${fpath} == '/usr/share/grml/zsh/functions' ]] ; then
 511         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 512             zrcautoload ${func:t}
 513         done
 514     fi
 515 done
 516 unset fdir func
 517
 518 # support colors in less
 519 export LESS_TERMCAP_mb=$'\E[01;31m'
 520 export LESS_TERMCAP_md=$'\E[01;31m'
 521 export LESS_TERMCAP_me=$'\E[0m'
 522 export LESS_TERMCAP_se=$'\E[0m'
 523 export LESS_TERMCAP_so=$'\E[01;44;33m'
 524 export LESS_TERMCAP_ue=$'\E[0m'
 525 export LESS_TERMCAP_us=$'\E[01;32m'
 526
 527 MAILCHECK=30       # mailchecks
 528 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 529 watch=(notme root) # watch for everyone but me and root
 530
 531 # automatically remove duplicates from these arrays
 532 typeset -U path cdpath fpath manpath
 533 # }}}
 534
 535 # {{{ keybindings
 536 if [[ "$TERM" != emacs ]] ; then
 537     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 538     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 539     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 540     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 541     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 542     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 543     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 544     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 545     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 546     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 547     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 548     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 549     # ncurses stuff:
 550     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 551     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 552     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 553     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 554     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 555     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 556     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 557     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 558 fi
 559
 560 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 561 # use emacs style per default:
 562 bindkey -e
 563 # use vi style:
 564 # bindkey -v
 565
 566 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 567 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 568 beginning-or-end-of-somewhere() {
 569     local hno=$HISTNO
 570     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 571       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 572         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 573     else
 574         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 575         if (( HISTNO != hno )); then
 576             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 577         fi
 578     fi
 579 }
 580 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 581 zle -N end-of-somewhere beginning-or-end-of-somewhere
 582
 583
 584 #if [[ "$TERM" == screen ]] ; then
 585
 586 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 587 ## to beginning/end of buffer on second keypress
 588 ## and to beginning/end of history on (at most) the third keypress
 589 # terminator & non-debian xterm
 590 bindkey '\eOH' beginning-of-somewhere  # home
 591 bindkey '\eOF' end-of-somewhere        # end
 592 # freebsd console
 593 bindkey '\e[H' beginning-of-somewhere   # home
 594 bindkey '\e[F' end-of-somewhere         # end
 595 # xterm,gnome-terminal,quake,etc
 596 bindkey '^[[1~' beginning-of-somewhere  # home
 597 bindkey '^[[4~' end-of-somewhere        # end
 598 # if terminal type is set to 'rxvt':
 599 bindkey '\e[7~' beginning-of-somewhere  # home
 600 bindkey '\e[8~' end-of-somewhere        # end
 601 #fi
 602
 603 bindkey '\e[A'  up-line-or-search       # cursor up
 604 bindkey '\e[B'  down-line-or-search     # <ESC>-
 605
 606 ## alt-backspace is already the default for backwards-delete-word
 607 ## let's also set alt-delete for deleting current word (right of cursor)
 608 #k# Kill right-side word
 609 bindkey "3~" delete-word
 610
 611 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 612 bindkey "\e[5C" forward-word
 613 bindkey "\e[5D" backward-word
 614 bindkey "\e[1;5C" forward-word
 615 bindkey "\e[1;5D" backward-word
 616 ## the same for alt-left-arrow and alt-right-arrow
 617 bindkey '^[[1;3C' forward-word
 618 bindkey '^[[1;3D' backward-word
 619
 620 # Search backward in the history for a line beginning with the current
 621 # line up to the cursor and move the cursor to the end of the line then
 622 zle -N history-beginning-search-backward-end history-search-end
 623 zle -N history-beginning-search-forward-end  history-search-end
 624 #k# search history backward for entry beginning with typed text
 625 bindkey '^xp'   history-beginning-search-backward-end
 626 #k# search history forward for entry beginning with typed text
 627 bindkey '^xP'   history-beginning-search-forward-end
 628 #k# search history backward for entry beginning with typed text
 629 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 630 #k# search history forward for entry beginning with typed text
 631 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 632
 633 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 634 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 635
 636 # insert unicode character
 637 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 638 # See for example http://unicode.org/charts/ for unicode characters code
 639 zrcautoload insert-unicode-char
 640 zle -N insert-unicode-char
 641 #k# Insert Unicode character
 642 bindkey '^Xi' insert-unicode-char
 643
 644 #m# k Shift-tab Perform backwards menu completion
 645 if [[ -n "$terminfo[kcbt]" ]]; then
 646     bindkey "$terminfo[kcbt]" reverse-menu-complete
 647 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 648     bindkey "$terminfo[cbt]"  reverse-menu-complete
 649 fi
 650
 651 ## toggle the ,. abbreviation feature on/off
 652 # NOABBREVIATION: default abbreviation-state
 653 #                 0 - enabled (default)
 654 #                 1 - disabled
 655 NOABBREVIATION=${NOABBREVIATION:-0}
 656
 657 grml_toggle_abbrev() {
 658     if (( ${NOABBREVIATION} > 0 )) ; then
 659         NOABBREVIATION=0
 660     else
 661         NOABBREVIATION=1
 662     fi
 663 }
 664
 665 zle -N grml_toggle_abbrev
 666 bindkey '^xA' grml_toggle_abbrev
 667
 668 # add a command line to the shells history without executing it
 669 commit-to-history() {
 670     print -s ${(z)BUFFER}
 671     zle send-break
 672 }
 673 zle -N commit-to-history
 674 bindkey "^x^h" commit-to-history
 675
 676 # only slash should be considered as a word separator:
 677 slash-backward-kill-word() {
 678     local WORDCHARS="${WORDCHARS:s@/@}"
 679     # zle backward-word
 680     zle backward-kill-word
 681 }
 682 zle -N slash-backward-kill-word
 683
 684 #k# Kill left-side word or everything up to next slash
 685 bindkey '\ev' slash-backward-kill-word
 686 #k# Kill left-side word or everything up to next slash
 687 bindkey '\e^h' slash-backward-kill-word
 688 #k# Kill left-side word or everything up to next slash
 689 bindkey '\e^?' slash-backward-kill-word
 690
 691 # use the new *-pattern-* widgets for incremental history search
 692 if is439 ; then
 693     bindkey '^r' history-incremental-pattern-search-backward
 694     bindkey '^s' history-incremental-pattern-search-forward
 695 fi
 696 # }}}
 697
 698 # a generic accept-line wrapper {{{
 699
 700 # This widget can prevent unwanted autocorrections from command-name
 701 # to _command-name, rehash automatically on enter and call any number
 702 # of builtin and user-defined widgets in different contexts.
 703 #
 704 # For a broader description, see:
 705 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 706 #
 707 # The code is imported from the file 'zsh/functions/accept-line' from
 708 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 709 # distributed under the same terms as zsh itself.
 710
 711 # A newly added command will may not be found or will cause false
 712 # correction attempts, if you got auto-correction set. By setting the
 713 # following style, we force accept-line() to rehash, if it cannot
 714 # find the first word on the command line in the $command[] hash.
 715 zstyle ':acceptline:*' rehash true
 716
 717 function Accept-Line() {
 718     setopt localoptions noksharrays
 719     local -a subs
 720     local -xi aldone
 721     local sub
 722     local alcontext=${1:-$alcontext}
 723
 724     zstyle -a ":acceptline:${alcontext}" actions subs
 725
 726     (( ${#subs} < 1 )) && return 0
 727
 728     (( aldone = 0 ))
 729     for sub in ${subs} ; do
 730         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 731         zle ${sub}
 732
 733         (( aldone > 0 )) && break
 734     done
 735 }
 736
 737 function Accept-Line-getdefault() {
 738     emulate -L zsh
 739     local default_action
 740
 741     zstyle -s ":acceptline:${alcontext}" default_action default_action
 742     case ${default_action} in
 743         ((accept-line|))
 744             printf ".accept-line"
 745             ;;
 746         (*)
 747             printf ${default_action}
 748             ;;
 749     esac
 750 }
 751
 752 function Accept-Line-HandleContext() {
 753     zle Accept-Line
 754
 755     default_action=$(Accept-Line-getdefault)
 756     zstyle -T ":acceptline:${alcontext}" call_default \
 757         && zle ${default_action}
 758 }
 759
 760 function accept-line() {
 761     setopt localoptions noksharrays
 762     local -ax cmdline
 763     local -x alcontext
 764     local buf com fname format msg default_action
 765
 766     alcontext='default'
 767     buf="${BUFFER}"
 768     cmdline=(${(z)BUFFER})
 769     com="${cmdline[1]}"
 770     fname="_${com}"
 771
 772     Accept-Line 'preprocess'
 773
 774     zstyle -t ":acceptline:${alcontext}" rehash \
 775         && [[ -z ${commands[$com]} ]]           \
 776         && rehash
 777
 778     if    [[ -n ${com}               ]] \
 779        && [[ -n ${reswords[(r)$com]} ]] \
 780        || [[ -n ${aliases[$com]}     ]] \
 781        || [[ -n ${functions[$com]}   ]] \
 782        || [[ -n ${builtins[$com]}    ]] \
 783        || [[ -n ${commands[$com]}    ]] ; then
 784
 785         # there is something sensible to execute, just do it.
 786         alcontext='normal'
 787         Accept-Line-HandleContext
 788
 789         return
 790     fi
 791
 792     if    [[ -o correct              ]] \
 793        || [[ -o correctall           ]] \
 794        && [[ -n ${functions[$fname]} ]] ; then
 795
 796         # nothing there to execute but there is a function called
 797         # _command_name; a completion widget. Makes no sense to
 798         # call it on the commandline, but the correct{,all} options
 799         # will ask for it nevertheless, so warn the user.
 800         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 801             # Okay, we warned the user before, he called us again,
 802             # so have it his way.
 803             alcontext='force'
 804             Accept-Line-HandleContext
 805
 806             return
 807         fi
 808
 809         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 810             alcontext='normal'
 811             Accept-Line-HandleContext
 812         else
 813             # prepare warning message for the user, configurable via zstyle.
 814             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 815
 816             if [[ -z ${msg} ]] ; then
 817                 msg="%c will not execute and completion %f exists."
 818             fi
 819
 820             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 821
 822             zle -M -- "${msg}"
 823         fi
 824         return
 825     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 826         # If we are here, the commandline contains something that is not
 827         # executable, which is neither subject to _command_name correction
 828         # and is not empty. might be a variable assignment
 829         alcontext='misc'
 830         Accept-Line-HandleContext
 831
 832         return
 833     fi
 834
 835     # If we got this far, the commandline only contains whitespace, or is empty.
 836     alcontext='empty'
 837     Accept-Line-HandleContext
 838 }
 839
 840 zle -N accept-line
 841 zle -N Accept-Line
 842 zle -N Accept-Line-HandleContext
 843
 844 # }}}
 845
 846 # power completion - abbreviation expansion {{{
 847 # power completion / abbreviation expansion / buffer expansion
 848 # see http://zshwiki.org/home/examples/zleiab for details
 849 # less risky than the global aliases but powerful as well
 850 # just type the abbreviation key and afterwards ',.' to expand it
 851 declare -A abk
 852 setopt extendedglob
 853 setopt interactivecomments
 854 abk=(
 855 #   key   # value                  (#d additional doc string)
 856 #A# start
 857     '...'  '../..'
 858     '....' '../../..'
 859     'BG'   '& exit'
 860     'C'    '| wc -l'
 861     'G'    '|& grep --color=auto '
 862     'H'    '| head'
 863     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 864     'L'    '| less'
 865     'LL'   '|& less -r'
 866     'M'    '| most'
 867     'N'    '&>/dev/null'           #d (No Output)
 868     'R'    '| tr A-z N-za-m'       #d (ROT13)
 869     'SL'   '| sort | less'
 870     'S'    '| sort -u'
 871     'T'    '| tail'
 872     'V'    '|& vim -'
 873 #A# end
 874     'co'   './configure && make && sudo make install'
 875 )
 876
 877 globalias() {
 878     emulate -L zsh
 879     setopt extendedglob
 880     local MATCH
 881
 882     if (( NOABBREVIATION > 0 )) ; then
 883         LBUFFER="${LBUFFER},."
 884         return 0
 885     fi
 886
 887     matched_chars='[.-|_a-zA-Z0-9]#'
 888     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 889     LBUFFER+=${abk[$MATCH]:-$MATCH}
 890 }
 891
 892 zle -N globalias
 893 bindkey ",." globalias
 894 # }}}
 895
 896 # {{{ autoloading
 897 zrcautoload zmv    # who needs mmv or rename?
 898 zrcautoload history-search-end
 899
 900 # we don't want to quote/espace URLs on our own...
 901 # if autoload -U url-quote-magic ; then
 902 #    zle -N self-insert url-quote-magic
 903 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 904 # else
 905 #    print 'Notice: no url-quote-magic available :('
 906 # fi
 907 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 908
 909 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 910 alias run-help >&/dev/null && unalias run-help
 911 for rh in run-help{,-git,-svk,-svn}; do
 912     zrcautoload $rh
 913 done; unset rh
 914
 915 # completion system
 916 if zrcautoload compinit ; then
 917     compinit || print 'Notice: no compinit available :('
 918 else
 919     print 'Notice: no compinit available :('
 920     function zstyle { }
 921     function compdef { }
 922 fi
 923
 924 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 925
 926 is4 && \
 927 for mod in complist deltochar mathfunc ; do
 928     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 929 done
 930
 931 # autoload zsh modules when they are referenced
 932 if is4 ; then
 933     zmodload -a  zsh/stat    zstat
 934     zmodload -a  zsh/zpty    zpty
 935     zmodload -ap zsh/mapfile mapfile
 936 fi
 937
 938 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 939     #k# Insert files and test globbing
 940     bindkey "^Xf" insert-files # C-x-f
 941 fi
 942
 943 bindkey ' '   magic-space    # also do history expansion on space
 944 #k# Trigger menu-complete
 945 bindkey '\ei' menu-complete  # menu completion via esc-i
 946
 947 # press esc-e for editing command line in $EDITOR or $VISUAL
 948 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 949     #k# Edit the current line in \kbd{\$EDITOR}
 950     bindkey '\ee' edit-command-line
 951 fi
 952
 953 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 954     #k# menu selection: pick item but stay in the menu
 955     bindkey -M menuselect '\e^M' accept-and-menu-complete
 956     # also use + and INSERT since it's easier to press repeatedly
 957     bindkey -M menuselect "+" accept-and-menu-complete
 958     bindkey -M menuselect "^[[2~" accept-and-menu-complete
 959
 960     # accept a completion and try to complete again by using menu
 961     # completion; very useful with completing directories
 962     # by using 'undo' one's got a simple file browser
 963     bindkey -M menuselect '^o' accept-and-infer-next-history
 964 fi
 965
 966 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 967 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
 968 zle -N insert-datestamp
 969
 970 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 971 bindkey '^Ed' insert-datestamp
 972
 973 # press esc-m for inserting last typed word again (thanks to caphuso!)
 974 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 975 zle -N insert-last-typed-word;
 976
 977 #k# Insert last typed word
 978 bindkey "\em" insert-last-typed-word
 979
 980 function grml-zsh-fg() {
 981   if (( ${#jobstates} )); then
 982     zle .push-input
 983     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
 984     BUFFER="${BUFFER}fg"
 985     zle .accept-line
 986   else
 987     zle -M 'No background jobs. Doing nothing.'
 988   fi
 989 }
 990 zle -N grml-zsh-fg
 991 #k# A smart shortcut for \kbd{fg<enter>}
 992 bindkey '^z' grml-zsh-fg
 993
 994 # run command line as user root via sudo:
 995 sudo-command-line() {
 996     [[ -z $BUFFER ]] && zle up-history
 997     if [[ $BUFFER != sudo\ * ]]; then
 998         BUFFER="sudo $BUFFER"
 999         CURSOR=$(( CURSOR+5 ))
1000     fi
1001 }
1002 zle -N sudo-command-line
1003
1004 #k# prepend the current command with "sudo"
1005 bindkey "^Os" sudo-command-line
1006
1007 ### jump behind the first word on the cmdline.
1008 ### useful to add options.
1009 function jump_after_first_word() {
1010     local words
1011     words=(${(z)BUFFER})
1012
1013     if (( ${#words} <= 1 )) ; then
1014         CURSOR=${#BUFFER}
1015     else
1016         CURSOR=${#${words[1]}}
1017     fi
1018 }
1019 zle -N jump_after_first_word
1020 #k# jump to after first word (for adding options)
1021 bindkey '^x1' jump_after_first_word
1022
1023 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1024 zle -C hist-complete complete-word _generic
1025 zstyle ':completion:hist-complete:*' completer _history
1026 #k# complete word from history with menu
1027 bindkey "^X^X" hist-complete
1028
1029 ## complete word from currently visible Screen or Tmux buffer.
1030 if check_com -c screen || check_com -c tmux; then
1031     _complete_screen_display() {
1032         [[ "$TERM" != "screen" ]] && return 1
1033
1034         local TMPFILE=$(mktemp)
1035         local -U -a _screen_display_wordlist
1036         trap "rm -f $TMPFILE" EXIT
1037
1038         # fill array with contents from screen hardcopy
1039         if ((${+TMUX})); then
1040             #works, but crashes tmux below version 1.4
1041             #luckily tmux -V option to ask for version, was also added in 1.4
1042             tmux -V &>/dev/null || return
1043             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1044         else
1045             screen -X hardcopy $TMPFILE
1046             #screen sucks, it dumps in latin1, apparently always. so recode it to system charset
1047             check_com recode && recode latin1 $TMPFILE
1048         fi
1049         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1050         # remove PREFIX to be completed from that array
1051         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1052         compadd -a _screen_display_wordlist
1053     }
1054     #k# complete word from currently visible GNU screen buffer
1055     bindkey -r "^XS"
1056     compdef -k _complete_screen_display complete-word '^XS'
1057 fi
1058
1059 # }}}
1060
1061 # {{{ history
1062
1063 ZSHDIR=$HOME/.zsh
1064
1065 #v#
1066 HISTFILE=$HOME/.zsh_history
1067 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1068 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1069
1070 # }}}
1071
1072 # dirstack handling {{{
1073
1074 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1075 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1076
1077 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1078     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1079     # "cd -" won't work after login by just setting $OLDPWD, so
1080     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1081 fi
1082
1083 chpwd() {
1084     local -ax my_stack
1085     my_stack=( ${PWD} ${dirstack} )
1086     if is42 ; then
1087         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1088     else
1089         uprint my_stack >! ${DIRSTACKFILE}
1090     fi
1091 }
1092
1093 # }}}
1094
1095 # directory based profiles {{{
1096
1097 if is433 ; then
1098
1099 CHPWD_PROFILE='default'
1100 function chpwd_profiles() {
1101     # Say you want certain settings to be active in certain directories.
1102     # This is what you want.
1103     #
1104     # zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1105     # zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1106     #
1107     # When that's done and you enter a directory that matches the pattern
1108     # in the third part of the context, a function called chpwd_profile_grml,
1109     # for example, is called (if it exists).
1110     #
1111     # If no pattern matches (read: no profile is detected) the profile is
1112     # set to 'default', which means chpwd_profile_default is attempted to
1113     # be called.
1114     #
1115     # A word about the context (the ':chpwd:profiles:*' stuff in the zstyle
1116     # command) which is used: The third part in the context is matched against
1117     # ${PWD}. That's why using a pattern such as /foo/bar(|/|/*) makes sense.
1118     # Because that way the profile is detected for all these values of ${PWD}:
1119     #   /foo/bar
1120     #   /foo/bar/
1121     #   /foo/bar/baz
1122     # So, if you want to make double damn sure a profile works in /foo/bar
1123     # and everywhere deeper in that tree, just use (|/|/*) and be happy.
1124     #
1125     # The name of the detected profile will be available in a variable called
1126     # 'profile' in your functions. You don't need to do anything, it'll just
1127     # be there.
1128     #
1129     # Then there is the parameter $CHPWD_PROFILE is set to the profile, that
1130     # was is currently active. That way you can avoid running code for a
1131     # profile that is already active, by running code such as the following
1132     # at the start of your function:
1133     #
1134     # function chpwd_profile_grml() {
1135     #     [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1136     #   ...
1137     # }
1138     #
1139     # The initial value for $CHPWD_PROFILE is 'default'.
1140     #
1141     # Version requirement:
1142     #   This feature requires zsh 4.3.3 or newer.
1143     #   If you use this feature and need to know whether it is active in your
1144     #   current shell, there are several ways to do that. Here are two simple
1145     #   ways:
1146     #
1147     #   a) If knowing if the profiles feature is active when zsh starts is
1148     #      good enough for you, you can put the following snippet into your
1149     #      .zshrc.local:
1150     #
1151     #   (( ${+functions[chpwd_profiles]} )) && print "directory profiles active"
1152     #
1153     #   b) If that is not good enough, and you would prefer to be notified
1154     #      whenever a profile changes, you can solve that by making sure you
1155     #      start *every* profile function you create like this:
1156     #
1157     #   function chpwd_profile_myprofilename() {
1158     #       [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1159     #       print "chpwd(): Switching to profile: $profile"
1160     #     ...
1161     #   }
1162     #
1163     #      That makes sure you only get notified if a profile is *changed*,
1164     #      not everytime you change directory, which would probably piss
1165     #      you off fairly quickly. :-)
1166     #
1167     # There you go. Now have fun with that.
1168     local -x profile
1169
1170     zstyle -s ":chpwd:profiles:${PWD}" profile profile || profile='default'
1171     if (( ${+functions[chpwd_profile_$profile]} )) ; then
1172         chpwd_profile_${profile}
1173     fi
1174
1175     CHPWD_PROFILE="${profile}"
1176     return 0
1177 }
1178 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1179
1180 fi # is433
1181
1182 # }}}
1183
1184 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
1185 if [[ $BATTERY -gt 0 ]] ; then
1186     if ! check_com -c acpi ; then
1187         BATTERY=0
1188     fi
1189 fi
1190
1191 battery() {
1192 if [[ $BATTERY -gt 0 ]] ; then
1193     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1194     if [[ -z "$PERCENT" ]] ; then
1195         PERCENT='acpi not present'
1196     else
1197         if [[ "$PERCENT" -lt 20 ]] ; then
1198             PERCENT="warning: ${PERCENT}%%"
1199         else
1200             PERCENT="${PERCENT}%%"
1201         fi
1202     fi
1203 fi
1204 }
1205 # }}}
1206
1207 # set colors for use in prompts {{{
1208 if zrcautoload colors && colors 2>/dev/null ; then
1209     BLUE="%{${fg[blue]}%}"
1210     RED="%{${fg_bold[red]}%}"
1211     GREEN="%{${fg[green]}%}"
1212     CYAN="%{${fg[cyan]}%}"
1213     MAGENTA="%{${fg[magenta]}%}"
1214     YELLOW="%{${fg[yellow]}%}"
1215     WHITE="%{${fg[white]}%}"
1216     NO_COLOUR="%{${reset_color}%}"
1217 else
1218     BLUE=$'%{\e[1;34m%}'
1219     RED=$'%{\e[1;31m%}'
1220     GREEN=$'%{\e[1;32m%}'
1221     CYAN=$'%{\e[1;36m%}'
1222     WHITE=$'%{\e[1;37m%}'
1223     MAGENTA=$'%{\e[1;35m%}'
1224     YELLOW=$'%{\e[1;33m%}'
1225     NO_COLOUR=$'%{\e[0m%}'
1226 fi
1227
1228 # }}}
1229
1230 # gather version control information for inclusion in a prompt {{{
1231
1232 if zrcautoload vcs_info; then
1233     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1234     # function, which can cause a lot of trouble with our directory-based
1235     # profiles. So:
1236     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1237         function VCS_INFO_realpath () {
1238             setopt localoptions NO_shwordsplit chaselinks
1239             ( builtin cd -q $1 2> /dev/null && pwd; )
1240         }
1241     fi
1242
1243     zstyle ':vcs_info:*' max-exports 2
1244
1245     if [[ -o restricted ]]; then
1246         zstyle ':vcs_info:*' enable NONE
1247     fi
1248 fi
1249
1250 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1251 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1252 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1253 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1254 #       to $vcs_info_msg_N_ as soon as we use the included version.
1255 if [[ "$TERM" == dumb ]] ; then
1256     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1257     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1258 else
1259     # these are the same, just with a lot of colours:
1260     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
1261                                        "zsh: %r"
1262     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
1263                                        "zsh: %r"
1264     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1265 fi
1266
1267
1268 # }}}
1269
1270 # command not found handling {{{
1271
1272 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1273 function command_not_found_handler() {
1274     emulate -L zsh
1275     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1276         ${GRML_ZSH_CNF_HANDLER} $1
1277     fi
1278     return 1
1279 }
1280
1281 # }}}
1282
1283 # {{{ set prompt
1284 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1285     promptinit # people should be able to use their favourite prompt
1286 else
1287     print 'Notice: no promptinit available :('
1288 fi
1289
1290 setopt prompt_subst
1291
1292 # make sure to use right prompt only when not running a command
1293 is41 && setopt transient_rprompt
1294
1295
1296 function ESC_print () {
1297     info_print $'\ek' $'\e\\' "$@"
1298 }
1299 function set_title () {
1300     info_print  $'\e]0;' $'\a' "$@"
1301 }
1302
1303 function info_print () {
1304     local esc_begin esc_end
1305     esc_begin="$1"
1306     esc_end="$2"
1307     shift 2
1308     printf '%s' ${esc_begin}
1309     printf '%s' "$*"
1310     printf '%s' "${esc_end}"
1311 }
1312
1313 # TODO: revise all these NO* variables and especially their documentation
1314 #       in zsh-help() below.
1315 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1316     [[ $NOPRECMD -gt 0 ]] && return 0
1317     # update VCS information
1318     (( ${+functions[vcs_info]} )) && vcs_info
1319
1320     if [[ $TERM == screen* ]] ; then
1321         if [[ -n ${vcs_info_msg_1_} ]] ; then
1322             ESC_print ${vcs_info_msg_1_}
1323         else
1324             ESC_print "zsh"
1325         fi
1326     fi
1327     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1328     if [[ $DONTSETRPROMPT -eq 0 ]] ; then
1329         if [[ $BATTERY -gt 0 ]] ; then
1330             # update battery (dropped into $PERCENT) information
1331             battery
1332             RPROMPT="%(?..:() ${PERCENT}"
1333         else
1334             RPROMPT="%(?..:() "
1335         fi
1336     fi
1337     # adjust title of xterm
1338     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1339     [[ ${NOTITLE} -gt 0 ]] && return 0
1340     case $TERM in
1341         (xterm*|rxvt*)
1342             set_title ${(%):-"%n@%m: %~"}
1343             ;;
1344     esac
1345 }
1346
1347 # preexec() => a function running before every command
1348 is4 && [[ $NOPRECMD -eq 0 ]] && \
1349 preexec () {
1350     [[ $NOPRECMD -gt 0 ]] && return 0
1351 # set hostname if not running on host with name 'grml'
1352     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1353        NAME="@$HOSTNAME"
1354     fi
1355 # get the name of the program currently running and hostname of local machine
1356 # set screen window title if running in a screen
1357     if [[ "$TERM" == screen* ]] ; then
1358         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1359         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1360         ESC_print ${CMD}
1361     fi
1362 # adjust title of xterm
1363     [[ ${NOTITLE} -gt 0 ]] && return 0
1364     case $TERM in
1365         (xterm*|rxvt*)
1366             set_title "${(%):-"%n@%m:"}" "$1"
1367             ;;
1368     esac
1369 }
1370
1371 EXITCODE="%(?..%?%1v )"
1372 PS2='\`%_> '      # secondary prompt, printed when the shell needs more information to complete a command.
1373 PS3='?# '         # selection prompt used within a select loop.
1374 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1375
1376 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1377 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1378     debian_chroot=$(cat /etc/debian_chroot)
1379 fi
1380
1381 # don't use colors on dumb terminals (like emacs):
1382 if [[ "$TERM" == dumb ]] ; then
1383     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
1384 else
1385     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
1386     # set variable identifying the chroot you work in (used in the prompt below)
1387     if [[ $GRMLPROMPT -gt 0 ]] ; then
1388         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1389 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1390     else
1391         # This assembles the primary prompt string
1392         if (( EUID != 0 )); then
1393             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1394         else
1395             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1396         fi
1397     fi
1398 fi
1399
1400 PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
1401
1402 # if we are inside a grml-chroot set a specific prompt theme
1403 if [[ -n "$GRML_CHROOT" ]] ; then
1404     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1405 fi
1406 # }}}
1407
1408 # {{{ 'hash' some often used directories
1409 #d# start
1410 hash -d deb=/var/cache/apt/archives
1411 hash -d doc=/usr/share/doc
1412 hash -d linux=/lib/modules/$(command uname -r)/build/
1413 hash -d log=/var/log
1414 hash -d slog=/var/log/syslog
1415 hash -d src=/usr/src
1416 hash -d templ=/usr/share/doc/grml-templates
1417 hash -d tt=/usr/share/doc/texttools-doc
1418 hash -d www=/var/www
1419 #d# end
1420 # }}}
1421
1422 # {{{ some aliases
1423 if check_com -c screen ; then
1424     if [[ $UID -eq 0 ]] ; then
1425         [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
1426     elif [[ -r $HOME/.screenrc ]] ; then
1427         alias screen="${commands[screen]} -c $HOME/.screenrc"
1428     else
1429         if [[ -r /etc/grml/screenrc_grml ]]; then
1430             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1431         else
1432             [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
1433         fi
1434     fi
1435 fi
1436
1437 # do we have GNU ls with color-support?
1438 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
1439     #a1# execute \kbd{@a@}:\quad ls with colors
1440     alias ls='ls -b -CF --color=auto'
1441     #a1# execute \kbd{@a@}:\quad list all files, with colors
1442     alias la='ls -la --color=auto'
1443     #a1# long colored list, without dotfiles (@a@)
1444     alias ll='ls -l --color=auto'
1445     #a1# long colored list, human readable sizes (@a@)
1446     alias lh='ls -hAl --color=auto'
1447     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1448     alias l='ls -lF --color=auto'
1449 else
1450     alias ls='ls -b -CF'
1451     alias la='ls -la'
1452     alias ll='ls -l'
1453     alias lh='ls -hAl'
1454     alias l='ls -lF'
1455 fi
1456
1457 alias mdstat='cat /proc/mdstat'
1458 alias ...='cd ../../'
1459
1460 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1461 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1462     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1463 fi
1464
1465 alias cp='nocorrect cp'         # no spelling correction on cp
1466 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
1467 alias mv='nocorrect mv'         # no spelling correction on mv
1468 alias rm='nocorrect rm'         # no spelling correction on rm
1469
1470 #a1# Execute \kbd{rmdir}
1471 alias rd='rmdir'
1472 #a1# Execute \kbd{mkdir}
1473 alias md='mkdir'
1474
1475 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1476 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1477 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1478
1479 # make sure it is not assigned yet
1480 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1481 utf2iso() {
1482     if isutfenv ; then
1483         for ENV in $(env | command grep -i '.utf') ; do
1484             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1485         done
1486     fi
1487 }
1488
1489 # make sure it is not assigned yet
1490 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1491 iso2utf() {
1492     if ! isutfenv ; then
1493         for ENV in $(env | command grep -i '\.iso') ; do
1494             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1495         done
1496     fi
1497 }
1498
1499 # I like clean prompt, so provide simple way to get that
1500 check_com 0 || alias 0='return 0'
1501
1502 # for really lazy people like mika:
1503 check_com S &>/dev/null || alias S='screen'
1504 check_com s &>/dev/null || alias s='ssh'
1505
1506 # especially for roadwarriors using GNU screen and ssh:
1507 if ! check_com asc &>/dev/null ; then
1508   asc() { autossh -t "$@" 'screen -RdU' }
1509   compdef asc=ssh
1510 fi
1511
1512 # get top 10 shell commands:
1513 alias top10='print -l ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
1514
1515 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
1516 if check_com -c truecrypt ; then
1517     if isutfenv ; then
1518         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
1519     else
1520         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
1521     fi
1522 fi
1523
1524 #f1# Hints for the use of zsh on grml
1525 zsh-help() {
1526     print "$bg[white]$fg[black]
1527 zsh-help - hints for use of zsh on grml
1528 =======================================$reset_color"
1529
1530     print '
1531 Main configuration of zsh happens in /etc/zsh/zshrc.
1532 That file is part of the package grml-etc-core, if you want to
1533 use them on a non-grml-system just get the tar.gz from
1534 http://deb.grml.org/ or (preferably) get it from the git repository:
1535
1536   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1537
1538 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1539 The file is still there, but it is empty for backwards compatibility.
1540
1541 For your own changes use these two files:
1542     $HOME/.zshrc.pre
1543     $HOME/.zshrc.local
1544
1545 The former is sourced very early in our zshrc, the latter is sourced
1546 very lately.
1547
1548 System wide configuration without touching configuration files of grml
1549 can take place in /etc/zsh/zshrc.local.
1550
1551 Normally, the root user (EUID == 0) does not get the whole grml setup.
1552 If you want to force the whole setup for that user, too, set
1553 GRML_ALWAYS_LOAD_ALL=1 in .zshrc.pre in root'\''s home directory.
1554
1555 For information regarding zsh start at http://grml.org/zsh/
1556
1557 Take a look at grml'\''s zsh refcard:
1558 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1559
1560 Check out the main zsh refcard:
1561 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1562
1563 And of course visit the zsh-lovers:
1564 % man zsh-lovers
1565
1566 You can adjust some options through environment variables when
1567 invoking zsh without having to edit configuration files.
1568 Basically meant for bash users who are not used to the power of
1569 the zsh yet. :)
1570
1571   "NOCOR=1    zsh" => deactivate automatic correction
1572   "NOMENU=1   zsh" => do not use auto menu completion (note: use ctrl-d for completion instead!)
1573   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1574   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1575                       preexec() and precmd() completely
1576   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1577   "COMMAND_NOT_FOUND=1 zsh"
1578                    => Enable a handler if an external command was not found
1579                       The command called in the handler can be altered by setting
1580                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1581                       "/usr/share/command-not-found/command-not-found"
1582
1583 A value greater than 0 is enables a feature; a value equal to zero
1584 disables it. If you like one or the other of these settings, you can
1585 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1586 zshrc.'
1587
1588     print "
1589 $bg[white]$fg[black]
1590 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1591 Enjoy your grml system with the zsh!$reset_color"
1592 }
1593
1594 # debian stuff
1595 if [[ -r /etc/debian_version ]] ; then
1596     #a3# Execute \kbd{apt-cache search}
1597     alias acs='apt-cache search'
1598     #a3# Execute \kbd{apt-cache show}
1599     alias acsh='apt-cache show'
1600     #a3# Execute \kbd{apt-cache policy}
1601     alias acp='apt-cache policy'
1602     #a3# Execute \kbd{apt-get dist-upgrade}
1603     salias adg="apt-get dist-upgrade"
1604     #a3# Execute \kbd{apt-get install}
1605     salias agi="apt-get install"
1606     #a3# Execute \kbd{aptitude install}
1607     salias ati="aptitude install"
1608     #a3# Execute \kbd{apt-get upgrade}
1609     salias ag="apt-get upgrade"
1610     #a3# Execute \kbd{apt-get update}
1611     salias au="apt-get update"
1612     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1613     salias -a up="aptitude update ; aptitude safe-upgrade"
1614     #a3# Execute \kbd{dpkg-buildpackage}
1615     alias dbp='dpkg-buildpackage'
1616     #a3# Execute \kbd{grep-excuses}
1617     alias ge='grep-excuses'
1618
1619     # debian upgrade
1620     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
1621     upgrade() {
1622         emulate -L zsh
1623         if [[ -z $1 ]] ; then
1624             $SUDO apt-get update
1625             $SUDO apt-get -u upgrade
1626         else
1627             ssh $1 $SUDO apt-get update
1628             # ask before the upgrade
1629             local dummy
1630             ssh $1 $SUDO apt-get --no-act upgrade
1631             echo -n 'Process the upgrade?'
1632             read -q dummy
1633             if [[ $dummy == "y" ]] ; then
1634                 ssh $1 $SUDO apt-get -u upgrade --yes
1635             fi
1636         fi
1637     }
1638
1639     # get a root shell as normal user in live-cd mode:
1640     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1641        alias su="sudo su"
1642      fi
1643
1644     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1645     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1646     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1647     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1648 fi
1649
1650 # sort installed Debian-packages by size
1651 if check_com -c dpkg-query ; then
1652     #a3# List installed Debian-packages sorted by size
1653     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1654 fi
1655
1656 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1657 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1658     if check_com -c wodim; then
1659         cdrecord() {
1660             cat <<EOMESS
1661 cdrecord is not provided under its original name by Debian anymore.
1662 See #377109 in the BTS of Debian for more details.
1663
1664 Please use the wodim binary instead
1665 EOMESS
1666             return 1
1667         }
1668     fi
1669 fi
1670
1671 # get_tw_cli has been renamed into get_3ware
1672 if check_com -c get_3ware ; then
1673     get_tw_cli() {
1674         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
1675         get_3ware
1676     }
1677 fi
1678
1679 # I hate lacking backward compatibility, so provide an alternative therefore
1680 if ! check_com -c apache2-ssl-certificate ; then
1681
1682     apache2-ssl-certificate() {
1683
1684     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
1685     print 'You might want to take a look at Debian the package ssl-cert as well.'
1686     print 'To generate a certificate for use with apache2 follow the instructions:'
1687
1688     echo '
1689
1690 export RANDFILE=/dev/random
1691 mkdir /etc/apache2/ssl/
1692 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
1693 chmod 600 /etc/apache2/ssl/apache.pem
1694
1695 Run "grml-tips ssl-certificate" if you need further instructions.
1696 '
1697     }
1698 fi
1699 # }}}
1700
1701 # {{{ Use hard limits, except for a smaller stack and no core dumps
1702 unlimit
1703 is425 && limit stack 8192
1704 isgrmlcd && limit core 0 # important for a live-cd-system
1705 limit -s
1706 # }}}
1707
1708 # {{{ completion system
1709
1710 # called later (via is4 && grmlcomp)
1711 # note: use 'zstyle' for getting current settings
1712 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
1713 grmlcomp() {
1714     # TODO: This could use some additional information
1715
1716     # allow one error for every three characters typed in approximate completer
1717     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1718
1719     # don't complete backup files as executables
1720     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1721
1722     # start menu completion only if it could find no unambiguous initial string
1723     zstyle ':completion:*:correct:*'       insert-unambiguous true
1724     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1725     zstyle ':completion:*:correct:*'       original true
1726
1727     # activate color-completion
1728     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1729
1730     # format on completion
1731     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1732
1733     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1734     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1735
1736     # insert all expansions for expand completer
1737     zstyle ':completion:*:expand:*'        tag-order all-expansions
1738     zstyle ':completion:*:history-words'   list false
1739
1740     # activate menu
1741     zstyle ':completion:*:history-words'   menu yes
1742
1743     # ignore duplicate entries
1744     zstyle ':completion:*:history-words'   remove-all-dups yes
1745     zstyle ':completion:*:history-words'   stop yes
1746
1747     # match uppercase from lowercase
1748     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1749
1750     # separate matches into groups
1751     zstyle ':completion:*:matches'         group 'yes'
1752     zstyle ':completion:*'                 group-name ''
1753
1754     if [[ "$NOMENU" -eq 0 ]] ; then
1755         # if there are more than 5 options allow selecting from a menu
1756         zstyle ':completion:*'               menu select=5
1757     else
1758         # don't use any menus at all
1759         setopt no_auto_menu
1760     fi
1761
1762     zstyle ':completion:*:messages'        format '%d'
1763     zstyle ':completion:*:options'         auto-description '%d'
1764
1765     # describe options in full
1766     zstyle ':completion:*:options'         description 'yes'
1767
1768     # on processes completion complete all user processes
1769     zstyle ':completion:*:processes'       command 'ps -au$USER'
1770
1771     # offer indexes before parameters in subscripts
1772     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1773
1774     # provide verbose completion information
1775     zstyle ':completion:*'                 verbose true
1776
1777     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1778     # for commands (read: 1st word in the line) that it will list for the user
1779     # to choose from. The following disables that, because it's not exactly fast.
1780     zstyle ':completion:*:-command-:*:'    verbose false
1781
1782     # set format for warnings
1783     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1784
1785     # define files to ignore for zcompile
1786     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1787     zstyle ':completion:correct:'          prompt 'correct to: %e'
1788
1789     # Ignore completion functions for commands you don't have:
1790     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1791
1792     # Provide more processes in completion of programs like killall:
1793     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1794
1795     # complete manual by their section
1796     zstyle ':completion:*:manuals'    separate-sections true
1797     zstyle ':completion:*:manuals.*'  insert-sections   true
1798     zstyle ':completion:*:man:*'      menu yes select
1799
1800     # provide .. as a completion
1801     zstyle ':completion:*' special-dirs ..
1802
1803     # run rehash on completion so new installed program are found automatically:
1804     _force_rehash() {
1805         (( CURRENT == 1 )) && rehash
1806         return 1
1807     }
1808
1809     ## correction
1810     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1811     if [[ "$NOCOR" -gt 0 ]] ; then
1812         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1813         setopt nocorrect
1814     else
1815         # try to be smart about when to use what completer...
1816         setopt correct
1817         zstyle -e ':completion:*' completer '
1818             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1819                 _last_try="$HISTNO$BUFFER$CURSOR"
1820                 reply=(_complete _match _ignored _prefix _files)
1821             else
1822                 if [[ $words[1] == (rm|mv) ]] ; then
1823                     reply=(_complete _files)
1824                 else
1825                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1826                 fi
1827             fi'
1828     fi
1829
1830     # command for process lists, the local web server details and host completion
1831     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1832
1833     # caching
1834     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1835                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1836
1837     # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
1838     if is42 ; then
1839         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1840         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1841     else
1842         _ssh_hosts=()
1843         _etc_hosts=()
1844     fi
1845     hosts=(
1846         $(hostname)
1847         "$_ssh_hosts[@]"
1848         "$_etc_hosts[@]"
1849         grml.org
1850         localhost
1851     )
1852     zstyle ':completion:*:hosts' hosts $hosts
1853     # TODO: so, why is this here?
1854     #  zstyle '*' hosts $hosts
1855
1856     # use generic completion system for programs not yet defined; (_gnu_generic works
1857     # with commands that provide a --help option with "standard" gnu-like output.)
1858     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
1859                    pal stow tail uname ; do
1860         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
1861     done; unset compcom
1862
1863     # see upgrade function in this file
1864     compdef _hosts upgrade
1865 }
1866 # }}}
1867
1868 # {{{ grmlstuff
1869 grmlstuff() {
1870 # people should use 'grml-x'!
1871     if check_com -c 915resolution; then
1872         855resolution() {
1873             echo "Please use 915resolution as resolution modifying tool for Intel \
1874 graphic chipset."
1875             return -1
1876         }
1877     fi
1878
1879     #a1# Output version of running grml
1880     alias grml-version='cat /etc/grml_version'
1881
1882     if check_com -c rebuildfstab ; then
1883         #a1# Rebuild /etc/fstab
1884         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1885     fi
1886
1887     if check_com -c grml-debootstrap ; then
1888         debian2hd() {
1889             echo "Installing debian to harddisk is possible by using grml-debootstrap."
1890             return 1
1891         }
1892     fi
1893 }
1894 # }}}
1895
1896 # {{{ now run the functions
1897 isgrml && checkhome
1898 is4    && isgrml    && grmlstuff
1899 is4    && grmlcomp
1900 # }}}
1901
1902 # {{{ keephack
1903 is4 && xsource "/etc/zsh/keephack"
1904 # }}}
1905
1906 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
1907 # You use it as follows:
1908 # $ NTREF=/reference/file
1909 # $ ls -l *(e:nt:)
1910 # This lists all the files in the current directory newer than the reference file.
1911 # You can also specify the reference file inline; note quotes:
1912 # $ ls -l *(e:'nt ~/.zshenv':)
1913 is4 && nt() {
1914     if [[ -n $1 ]] ; then
1915         local NTREF=${~1}
1916     fi
1917     [[ $REPLY -nt $NTREF ]]
1918 }
1919 # }}}
1920
1921 # shell functions {{{
1922
1923 #f1# Provide csh compatibility
1924 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
1925
1926 #f1# Reload an autoloadable function
1927 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1928 compdef _functions freload
1929
1930 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1931 sll() {
1932     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1933     for file in "$@" ; do
1934         while [[ -h "$file" ]] ; do
1935             ls -l $file
1936             file=$(readlink "$file")
1937         done
1938     done
1939 }
1940
1941 # fast manual access
1942 if check_com qma ; then
1943     #f1# View the zsh manual
1944     manzsh()  { qma zshall "$1" }
1945     compdef _man qma
1946 else
1947     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
1948 fi
1949
1950 # TODO: Is it supported to use pager settings like this?
1951 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
1952 # with respect to wordsplitting. (ie. ${=PAGER})
1953 if check_com -c $PAGER ; then
1954     #f1# View Debian's changelog of a given package
1955     dchange() {
1956         emulate -L zsh
1957         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
1958             $PAGER /usr/share/doc/$1/changelog.Debian.gz
1959         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1960             $PAGER /usr/share/doc/$1/changelog.gz
1961         else
1962             if check_com -c aptitude ; then
1963                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1964                 if isgrml ; then
1965                     aptitude -t unstable changelog $1
1966                 else
1967                     aptitude changelog $1
1968                 fi
1969             else
1970                 echo "No changelog for package $1 found, sorry."
1971                 return 1
1972             fi
1973         fi
1974     }
1975     _dchange() { _files -W /usr/share/doc -/ }
1976     compdef _dchange dchange
1977
1978     #f1# View Debian's NEWS of a given package
1979     dnews() {
1980         emulate -L zsh
1981         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
1982             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
1983         else
1984             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
1985                 $PAGER /usr/share/doc/$1/NEWS.gz
1986             else
1987                 echo "No NEWS file for package $1 found, sorry."
1988                 return 1
1989             fi
1990         fi
1991     }
1992     _dnews() { _files -W /usr/share/doc -/ }
1993     compdef _dnews dnews
1994
1995     #f1# View upstream's changelog of a given package
1996     uchange() {
1997         emulate -L zsh
1998         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1999             $PAGER /usr/share/doc/$1/changelog.gz
2000         else
2001             echo "No changelog for package $1 found, sorry."
2002             return 1
2003         fi
2004     }
2005     _uchange() { _files -W /usr/share/doc -/ }
2006     compdef _uchange uchange
2007 fi
2008
2009 # zsh profiling
2010 profile() {
2011     ZSH_PROFILE_RC=1 $SHELL "$@"
2012 }
2013
2014 #f1# Edit an alias via zle
2015 edalias() {
2016     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2017 }
2018 compdef _aliases edalias
2019
2020 #f1# Edit a function via zle
2021 edfunc() {
2022     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2023 }
2024 compdef _functions edfunc
2025
2026 # use it e.g. via 'Restart apache2'
2027 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2028 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2029 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2030 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2031 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2032 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2033     __start_stop() {
2034         local action_="${1:l}"  # e.g Start/Stop/Restart
2035         local service_="$2"
2036         local param_="$3"
2037
2038         local service_target_="$(readlink /etc/init.d/$service_)"
2039         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2040             # runit
2041             case "${action_}" in
2042                 start) if [[ ! -e /etc/service/$service_ ]]; then
2043                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2044                        else
2045                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2046                        fi ;;
2047                 # there is no reload in runits sysv emulation
2048                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2049                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2050             esac
2051         else
2052             # sysvinit
2053             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2054         fi
2055     }
2056
2057     _grmlinitd() {
2058         local -a scripts
2059         scripts=( /etc/init.d/*(x:t) )
2060         _describe "service startup script" scripts
2061     }
2062
2063     for i in Start Restart Stop Force-Reload Reload ; do
2064         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2065         compdef _grmlinitd $i
2066     done
2067 fi
2068
2069 #f1# Provides useful information on globbing
2070 H-Glob() {
2071     echo -e "
2072     /      directories
2073     .      plain files
2074     @      symbolic links
2075     =      sockets
2076     p      named pipes (FIFOs)
2077     *      executable plain files (0100)
2078     %      device files (character or block special)
2079     %b     block special files
2080     %c     character special files
2081     r      owner-readable files (0400)
2082     w      owner-writable files (0200)
2083     x      owner-executable files (0100)
2084     A      group-readable files (0040)
2085     I      group-writable files (0020)
2086     E      group-executable files (0010)
2087     R      world-readable files (0004)
2088     W      world-writable files (0002)
2089     X      world-executable files (0001)
2090     s      setuid files (04000)
2091     S      setgid files (02000)
2092     t      files with the sticky bit (01000)
2093
2094   print *(m-1)          # Files modified up to a day ago
2095   print *(a1)           # Files accessed a day ago
2096   print *(@)            # Just symlinks
2097   print *(Lk+50)        # Files bigger than 50 kilobytes
2098   print *(Lk-50)        # Files smaller than 50 kilobytes
2099   print **/*.c          # All *.c files recursively starting in \$PWD
2100   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2101   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2102   print *~*.*           # All Files that do not contain a dot
2103   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2104   print -l *(.c|.h)     # Lists *.c and *.h
2105   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2106   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2107 }
2108 alias help-zshglob=H-Glob
2109
2110 #v1# set number of lines to display per page
2111 HELP_LINES_PER_PAGE=20
2112 #v1# set location of help-zle cache file
2113 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
2114 #f1# helper function for help-zle, actually generates the help text
2115 help_zle_parse_keybindings()
2116 {
2117     emulate -L zsh
2118     setopt extendedglob
2119     unsetopt ksharrays  #indexing starts at 1
2120
2121     #v1# choose files that help-zle will parse for keybindings
2122     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
2123
2124     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
2125         local load_cache=0
2126         for f ($KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
2127         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
2128     fi
2129
2130     #fill with default keybindings, possibly to be overwriten in a file later
2131     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2132     local -A help_zle_keybindings
2133     help_zle_keybindings['<Ctrl>@']="set MARK"
2134     help_zle_keybindings['<Ctrl>X<Ctrl>J']="vi-join lines"
2135     help_zle_keybindings['<Ctrl>X<Ctrl>B']="jump to matching brace"
2136     help_zle_keybindings['<Ctrl>X<Ctrl>U']="undo"
2137     help_zle_keybindings['<Ctrl>_']="undo"
2138     help_zle_keybindings['<Ctrl>X<Ctrl>F<c>']="find <c> in cmdline"
2139     help_zle_keybindings['<Ctrl>A']="goto beginning of line"
2140     help_zle_keybindings['<Ctrl>E']="goto end of line"
2141     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2142     help_zle_keybindings['<Alt>T']="transpose words"
2143     help_zle_keybindings['<Alt>s']="spellcheck word"
2144     help_zle_keybindings['<Ctrl>K']="backward kill buffer"
2145     help_zle_keybindings['<Ctrl>U']="forward kill buffer"
2146     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2147     help_zle_keybindings["<Alt>'"]="quote line"
2148     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2149     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2150     help_zle_keybindings['<Alt>U']="make next word Uppercase"
2151     help_zle_keybindings['<Alt>l']="make next word lowercase"
2152     help_zle_keybindings['<Ctrl>Xd']="preview expansion under cursor"
2153     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2154     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2155     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2156     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2157     help_zle_keybindings['<Ctrl>V']="insert next keypress symbol literally (e.g. for bindkey)"
2158     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2159     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2160     help_zle_keybindings['<Alt>H']="run help on current command"
2161
2162     #init global variables
2163     unset help_zle_lines help_zle_sln
2164     typeset -g -a help_zle_lines
2165     typeset -g help_zle_sln=1
2166
2167     local k v
2168     local lastkeybind_desc contents     #last description starting with #k# that we found
2169     local num_lines_elapsed=0            #number of lines between last description and keybinding
2170     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2171     for f in $HELPZLE_KEYBINDING_FILES; do
2172         [[ -r "$f" ]] || continue   #not readable ? skip it
2173         contents="$(<$f)"
2174         for cline in "${(f)contents}"; do
2175             #zsh pattern: matches lines like: #k# ..............
2176             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2177                 lastkeybind_desc="$match[*]"
2178                 num_lines_elapsed=0
2179             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2180             #             ignores lines that are commentend out
2181             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2182             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2183                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2184                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2185                     #substitute keybinding string with something readable
2186                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2187                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2188                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2189                     help_zle_keybindings[${k}]=$lastkeybind_desc
2190                 fi
2191                 lastkeybind_desc=""
2192             else
2193               ((num_lines_elapsed++))
2194             fi
2195         done
2196     done
2197     unset contents
2198     #calculate length of keybinding column
2199     local kstrlen=0
2200     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2201     #convert the assoc array into preformated lines, which we are able to sort
2202     for k v in ${(kv)help_zle_keybindings[@]}; do
2203         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2204         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2205     done
2206     #sort lines alphabetically
2207     help_zle_lines=("${(i)help_zle_lines[@]}")
2208     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2209     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2210     zcompile $HELP_ZLE_CACHE_FILE
2211 }
2212 typeset -g help_zle_sln
2213 typeset -g -a help_zle_lines
2214
2215 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2216 help-zle()
2217 {
2218     emulate -L zsh
2219     unsetopt ksharrays  #indexing starts at 1
2220     #help lines already generated ? no ? then do it
2221     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2222     #already displayed all lines ? go back to the start
2223     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2224     local sln=$help_zle_sln
2225     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2226     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2227     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2228 }
2229 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2230 zle -N help-zle && bindkey '^Xz' help-zle
2231
2232 check_com -c qma && alias ?='qma zshall'
2233
2234 # grep for running process, like: 'any vim'
2235 any() {
2236     emulate -L zsh
2237     unsetopt KSH_ARRAYS
2238     if [[ -z "$1" ]] ; then
2239         echo "any - grep for process(es) by keyword" >&2
2240         echo "Usage: any <keyword>" >&2 ; return 1
2241     else
2242         ps xauwww | grep -i --color=auto "[${1[1]}]${1[2,-1]}"
2243     fi
2244 }
2245
2246
2247 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2248 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2249 [[ -r /proc/1/maps ]] && \
2250 deswap() {
2251     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2252     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2253     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2254 }
2255
2256 # print hex value of a number
2257 hex() {
2258     emulate -L zsh
2259     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
2260 }
2261
2262 # calculate (or eval at all ;-)) with perl => p[erl-]eval
2263 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
2264 peval() {
2265     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
2266     perl -e "print eval($CALC),\"\n\";"
2267 }
2268 functions peval &>/dev/null && alias calc=peval
2269
2270 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
2271 aoeu() {
2272     echo -n 'Switching to us keyboard layout: '
2273     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
2274     echo 'Done'
2275 }
2276 asdf() {
2277     echo -n 'Switching to dvorak keyboard layout: '
2278     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
2279     echo 'Done'
2280 }
2281 # just press 'asdf' key to toggle from neon layout to us keyboard layout
2282 uiae() {
2283     echo -n 'Switching to us keyboard layout: '
2284     setxkbmap us && echo 'Done' || echo 'Failed'
2285 }
2286
2287 # set up an ipv6 tunnel
2288 ipv6-tunnel() {
2289     emulate -L zsh
2290     case $1 in
2291         start)
2292             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2293                 print 'ipv6 tunnel already set up, nothing to be done.'
2294                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
2295             else
2296                 [[ -n "$PUBLIC_IP" ]] || \
2297                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
2298                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
2299
2300                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
2301                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
2302                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
2303                 ifconfig sit0 tunnel ::192.88.99.1 up
2304                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
2305             fi
2306             ;;
2307         status)
2308             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2309                 print 'ipv6 tunnel available' ; return 0
2310             else
2311                 print 'ipv6 tunnel not available' ; return 1
2312             fi
2313             ;;
2314         stop)
2315             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2316                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
2317                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
2318             else
2319                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
2320             fi
2321             ;;
2322         *)
2323             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
2324             ;;
2325     esac
2326 }
2327
2328 # run dhclient for wireless device
2329 iwclient() {
2330     sudo dhclient "$(wavemon -d | awk '/device/{print $3}')"
2331 }
2332
2333 # spawn a minimally set up mksh - useful if you want to umount /usr/.
2334 minimal-shell() {
2335     emulate -L zsh
2336     local shell="/bin/mksh"
2337
2338     if [[ ! -x ${shell} ]]; then
2339         printf '`%s'\'' not available, giving up.\n' ${shell} >&2
2340         return 1
2341     fi
2342
2343     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ${shell}
2344 }
2345
2346 # a wrapper for vim, that deals with title setting
2347 #   VIM_OPTIONS
2348 #       set this array to a set of options to vim you always want
2349 #       to have set when calling vim (in .zshrc.local), like:
2350 #           VIM_OPTIONS=( -p )
2351 #       This will cause vim to send every file given on the
2352 #       commandline to be send to it's own tab (needs vim7).
2353 vim() {
2354     VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2355 }
2356
2357 # make a backup of a file
2358 bk() {
2359     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2360 }
2361
2362 #f1# grep for patterns in grml's zsh setup
2363 zg() {
2364 #{{{
2365     LANG=C perl -e '
2366
2367 sub usage {
2368     print "usage: zg -[anr] <pattern>\n";
2369     print " Search for patterns in grml'\''s zshrc.\n";
2370     print " zg takes no or exactly one option plus a non empty pattern.\n\n";
2371     print "   options:\n";
2372     print "     --  no options (use if your pattern starts in with a dash.\n";
2373     print "     -a  search for the pattern in all code regions\n";
2374     print "     -n  search for the pattern in non-root code only\n";
2375     print "     -r  search in code for everyone (also root) only\n\n";
2376     print "   The default is -a for non-root users and -r for root.\n\n";
2377     print " If you installed the zshrc to a non-default locations (ie *NOT*\n";
2378     print " in /etc/zsh/zshrc) do: export GRML_ZSHRC=\$HOME/.zshrc\n";
2379     print " ...in case you copied the file to that location.\n\n";
2380     exit 1;
2381 }
2382
2383 if ($ENV{GRML_ZSHRC} ne "") {
2384     $RC = $ENV{GRML_ZSHRC};
2385 } else {
2386     $RC = "/etc/zsh/zshrc";
2387 }
2388
2389 usage if ($#ARGV < 0 || $#ARGV > 1);
2390 if ($> == 0) { $mode = "allonly"; }
2391 else { $mode = "all"; }
2392
2393 $opt = $ARGV[0];
2394 if ($opt eq "--")     { shift; }
2395 elsif ($opt eq "-a")  { $mode = "all"; shift; }
2396 elsif ($opt eq "-n")  { $mode = "nonroot"; shift; }
2397 elsif ($opt eq "-r" ) { $mode = "allonly"; shift; }
2398 elsif ($opt =~ m/^-/ || $#ARGV > 0) { usage(); }
2399
2400 $pattern = $ARGV[0];
2401 usage() if ($pattern eq "");
2402
2403 open FH, "<$RC" or die "zg: Could not open $RC: $!\n";
2404 while ($line = <FH>) {
2405     chomp $line;
2406     if ($line =~ m/^#:grep:marker:for:mika:/) { $markerfound = 1; next; }
2407     next if ($mode eq "nonroot" && markerfound == 0);
2408     break if ($mode eq "allonly" && markerfound == 1);
2409     print $line, "\n" if ($line =~ /$pattern/);
2410 }
2411 close FH;
2412 exit 0;
2413
2414     ' -- "$@"
2415 #}}}
2416     return $?
2417 }
2418
2419 ssl_hashes=( sha512 sha256 sha1 md5 )
2420
2421 for sh in ${ssl_hashes}; do
2422     eval 'ssl-cert-'${sh}'() {
2423         emulate -L zsh
2424         if [[ -z $1 ]] ; then
2425             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2426             return 1
2427         fi
2428         openssl x509 -noout -fingerprint -'${sh}' -in $1
2429     }'
2430 done; unset sh
2431
2432 ssl-cert-fingerprints() {
2433     emulate -L zsh
2434     local i
2435     if [[ -z $1 ]] ; then
2436         printf 'usage: ssl-cert-fingerprints <file>\n'
2437         return 1
2438     fi
2439     for i in ${ssl_hashes}
2440         do ssl-cert-$i $1;
2441     done
2442 }
2443
2444 ssl-cert-info() {
2445     emulate -L zsh
2446     if [[ -z $1 ]] ; then
2447         printf 'usage: ssl-cert-info <file>\n'
2448         return 1
2449     fi
2450     openssl x509 -noout -text -in $1
2451     ssl-cert-fingerprints $1
2452 }
2453
2454 # }}}
2455
2456 # {{{ make sure our environment is clean regarding colors
2457 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2458 # }}}
2459
2460 # "persistent history" {{{
2461 # just write important commands you always need to ~/.important_commands
2462 if [[ -r ~/.important_commands ]] ; then
2463     fc -R ~/.important_commands
2464 fi
2465 # }}}
2466
2467 # load the lookup subsystem if it's available on the system
2468 zrcautoload lookupinit && lookupinit
2469
2470 #:grep:marker:for:mika: :-)
2471 ### non-root (EUID != 0) code below
2472 ###
2473
2474 if (( GRML_ALWAYS_LOAD_ALL == 0 )) && (( $EUID == 0 )) ; then
2475     zrclocal
2476     return 0
2477 fi
2478
2479 # variables {{{
2480
2481 # set terminal property (used e.g. by msgid-chooser)
2482 export COLORTERM="yes"
2483
2484 # set default browser
2485 if [[ -z "$BROWSER" ]] ; then
2486     if [[ -n "$DISPLAY" ]] ; then
2487         #v# If X11 is running
2488         check_com -c firefox && export BROWSER=firefox
2489     else
2490         #v# If no X11 is running
2491         check_com -c w3m && export BROWSER=w3m
2492     fi
2493 fi
2494
2495 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
2496 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
2497 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
2498
2499 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
2500 #v# [for non-root only]
2501 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
2502 # }}}
2503
2504 # aliases {{{
2505
2506 # Xterm resizing-fu.
2507 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
2508 alias hide='echo -en "\033]50;nil2\007"'
2509 alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
2510 alias small='echo -en "\033]50;6x10\007"'
2511 alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
2512 alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
2513 alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
2514 alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
2515 alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
2516 alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
2517
2518 # general
2519 #a2# Execute \kbd{du -sch}
2520 alias da='du -sch'
2521 #a2# Execute \kbd{jobs -l}
2522 alias j='jobs -l'
2523
2524 # compile stuff
2525 #a2# Execute \kbd{./configure}
2526 alias CO="./configure"
2527 #a2# Execute \kbd{./configure --help}
2528 alias CH="./configure --help"
2529
2530 # listing stuff
2531 #a2# Execute \kbd{ls -lSrah}
2532 alias dir="ls -lSrah"
2533 #a2# Only show dot-directories
2534 alias lad='ls -d .*(/)'                # only show dot-directories
2535 #a2# Only show dot-files
2536 alias lsa='ls -a .*(.)'                # only show dot-files
2537 #a2# Only files with setgid/setuid/sticky flag
2538 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
2539 #a2# Only show 1st ten symlinks
2540 alias lsl='ls -l *(@)'                 # only symlinks
2541 #a2# Display only executables
2542 alias lsx='ls -l *(*)'                 # only executables
2543 #a2# Display world-{readable,writable,executable} files
2544 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
2545 #a2# Display the ten biggest files
2546 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
2547 #a2# Only show directories
2548 alias lsd='ls -d *(/)'                 # only show directories
2549 #a2# Only show empty directories
2550 alias lse='ls -d *(/^F)'               # only show empty directories
2551 #a2# Display the ten newest files
2552 alias lsnew="ls -rtlh *(D.om[1,10])"   # display the newest files
2553 #a2# Display the ten oldest files
2554 alias lsold="ls -rtlh *(D.Om[1,10])"   # display the oldest files
2555 #a2# Display the ten smallest files
2556 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
2557 #a2# Display the ten newest directories and ten newest .directories
2558 alias lsnewdir="ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
2559 #a2# Display the ten oldest directories and ten oldest .directories
2560 alias lsolddir="ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
2561
2562 # chmod
2563 #a2# Execute \kbd{chmod 600}
2564 alias rw-='chmod 600'
2565 #a2# Execute \kbd{chmod 700}
2566 alias rwx='chmod 700'
2567 #m# a2 r-{}- Execute \kbd{chmod 644}
2568 alias r--='chmod 644'
2569 #a2# Execute \kbd{chmod 755}
2570 alias r-x='chmod 755'
2571
2572 # some useful aliases
2573 #a2# Execute \kbd{mkdir -o}
2574 alias md='mkdir -p'
2575
2576 # console stuff
2577 #a2# Execute \kbd{mplayer -vo fbdev}
2578 alias cmplayer='mplayer -vo fbdev'
2579 #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
2580 alias fbmplayer='mplayer -vo fbdev -fs -zoom'
2581 #a2# Execute \kbd{links2 -driver fb}
2582 alias fblinks='links2 -driver fb'
2583
2584 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2585 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2586 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2587
2588 # simple webserver
2589 check_com -c python && alias http="python -m SimpleHTTPServer"
2590
2591 # Use 'g' instead of 'git':
2592 check_com g || alias g='git'
2593
2594 # work around non utf8 capable software in utf environment via $LANG and luit
2595 if check_com isutfenv && check_com luit ; then
2596     if check_com -c mrxvt ; then
2597         isutfenv && [[ -n "$LANG" ]] && \
2598             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2599     fi
2600
2601     if check_com -c aterm ; then
2602         isutfenv && [[ -n "$LANG" ]] && \
2603             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2604     fi
2605
2606     if check_com -c centericq ; then
2607         isutfenv && [[ -n "$LANG" ]] && \
2608             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2609     fi
2610 fi
2611 # }}}
2612
2613 # useful functions {{{
2614
2615 # searching
2616 #f4# Search for newspostings from authors
2617 agoogle() { ${=BROWSER} "http://groups.google.com/groups?as_uauthors=$*" ; }
2618 #f4# Search Debian Bug Tracking System
2619 debbug()  {
2620     emulate -L zsh
2621     setopt extendedglob
2622     if [[ $# -eq 1 ]]; then
2623         case "$1" in
2624             ([0-9]##)
2625             ${=BROWSER} "http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=$1"
2626             ;;
2627             (*@*)
2628             ${=BROWSER} "http://bugs.debian.org/cgi-bin/pkgreport.cgi?submitter=$1"
2629             ;;
2630             (*)
2631             ${=BROWSER} "http://bugs.debian.org/$*"
2632             ;;
2633         esac
2634     else
2635         print "$0 needs one argument"
2636         return 1
2637     fi
2638 }
2639 #f4# Search Debian Bug Tracking System in mbox format
2640 debbugm() {
2641     emulate -L zsh
2642     bts show --mbox $1
2643 }
2644 #f4# Search DMOZ
2645 dmoz()    {
2646     emulate -L zsh
2647     ${=BROWSER} http://search.dmoz.org/cgi-bin/search\?search=${1// /_}
2648 }
2649 #f4# Search German   Wiktionary
2650 dwicti()  {
2651     emulate -L zsh
2652     ${=BROWSER} http://de.wiktionary.org/wiki/${(C)1// /_}
2653 }
2654 #f4# Search English  Wiktionary
2655 ewicti()  {
2656     emulate -L zsh
2657     ${=BROWSER} http://en.wiktionary.org/wiki/${(C)1// /_}
2658 }
2659 #f4# Search Google Groups
2660 ggogle()  {
2661     emulate -L zsh
2662     ${=BROWSER} "http://groups.google.com/groups?q=$*"
2663 }
2664 #f4# Search Google
2665 google()  {
2666     emulate -L zsh
2667     ${=BROWSER} "http://www.google.com/search?&num=100&q=$*"
2668 }
2669 #f4# Search Google Groups for MsgID
2670 mggogle() {
2671     emulate -L zsh
2672     ${=BROWSER} "http://groups.google.com/groups?selm=$*"
2673 }
2674 #f4# Search Netcraft
2675 netcraft(){
2676     emulate -L zsh
2677     ${=BROWSER} "http://toolbar.netcraft.com/site_report?url=$1"
2678 }
2679 #f4# Use German Wikipedia's full text search
2680 swiki()   {
2681     emulate -L zsh
2682     ${=BROWSER} http://de.wikipedia.org/wiki/Spezial:Search/${(C)1}
2683 }
2684 #f4# search \kbd{dict.leo.org}
2685 oleo()    {
2686     emulate -L zsh
2687     ${=BROWSER} "http://dict.leo.org/?search=$*"
2688 }
2689 #f4# Search German   Wikipedia
2690 wikide()  {
2691     emulate -L zsh
2692     ${=BROWSER} http://de.wikipedia.org/wiki/"${(C)*}"
2693 }
2694 #f4# Search English  Wikipedia
2695 wikien()  {
2696     emulate -L zsh
2697     ${=BROWSER} http://en.wikipedia.org/wiki/"${(C)*}"
2698 }
2699 #f4# Search official debs
2700 wodeb()   {
2701     emulate -L zsh
2702     ${=BROWSER} "http://packages.debian.org/search?keywords=$1&searchon=contents&suite=${2:=unstable}&section=all"
2703 }
2704
2705 #m# f4 gex() Exact search via Google
2706 check_com google && gex () {
2707     google "\"[ $1]\" $*"
2708 }
2709
2710 # misc
2711 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2712 bk() {
2713     emulate -L zsh
2714     cp -b $1 $1_`date --iso-8601=m`
2715 }
2716 #f5# Copied diff
2717 cdiff() {
2718     emulate -L zsh
2719     diff -crd "$@" | egrep -v "^Only in |^Binary files "
2720 }
2721 #f5# cd to directoy and list files
2722 cl() {
2723     emulate -L zsh
2724     cd $1 && ls -a
2725 }
2726 #f5# Cvs add
2727 cvsa() {
2728     emulate -L zsh
2729     cvs add $* && cvs com -m 'initial checkin' $*
2730 }
2731 #f5# Cvs diff
2732 cvsd() {
2733     emulate -L zsh
2734     cvs diff -N $* |& $PAGER
2735 }
2736 #f5# Cvs log
2737 cvsl() {
2738     emulate -L zsh
2739     cvs log $* |& $PAGER
2740 }
2741 #f5# Cvs update
2742 cvsq() {
2743     emulate -L zsh
2744     cvs -nq update
2745 }
2746 #f5# Rcs2log
2747 cvsr() {
2748     emulate -L zsh
2749     rcs2log $* | $PAGER
2750 }
2751 #f5# Cvs status
2752 cvss() {
2753     emulate -L zsh
2754     cvs status -v $*
2755 }
2756 #f5# Disassemble source files using gcc and as
2757 disassemble(){
2758     emulate -L zsh
2759     gcc -pipe -S -o - -O -g $* | as -aldh -o /dev/null
2760 }
2761 #f5# Firefox remote control - open given URL
2762 fir() {
2763     if [ -e /etc/debian_version ]; then
2764         firefox -a iceweasel -remote "openURL($1)" || firefox ${1}&
2765     else
2766         firefox -a firefox -remote "openURL($1)" || firefox ${1}&
2767     fi
2768 }
2769 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2770 cd() {
2771     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2772         [[ ! -e ${1:h} ]] && return 1
2773         print "Correcting ${1} to ${1:h}"
2774         builtin cd ${1:h}
2775     else
2776         builtin cd "$@"
2777     fi
2778 }
2779
2780 #f5# Create Directoy and \kbd{cd} to it
2781 mcd() {
2782     mkdir -p "$@" && cd "$@"
2783 }
2784 #f5# Create temporary directory and \kbd{cd} to it
2785 cdt() {
2786     local t
2787     t=$(mktemp -d)
2788     echo "$t"
2789     builtin cd "$t"
2790 }
2791 #f5# Unified diff to timestamped outputfile
2792 mdiff() {
2793     diff -udrP "$1" "$2" > diff.`date "+%Y-%m-%d"`."$1"
2794 }
2795
2796 #f5# Create directory under cursor or the selected area
2797 # Press ctrl-xM to create the directory under the cursor or the selected area.
2798 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2799 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2800 # directory does not exist yet -> press ctrl-XM and problem solved
2801 inplaceMkDirs() {
2802     local PATHTOMKDIR
2803     if ((REGION_ACTIVE==1)); then
2804         local F=$MARK T=$CURSOR
2805         if [[ $F -gt $T ]]; then
2806             F=${CURSOR}
2807             T=${MARK}
2808         fi
2809         # get marked area from buffer and eliminate whitespace
2810         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2811         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2812     else
2813         local bufwords iword
2814         bufwords=(${(z)LBUFFER})
2815         iword=${#bufwords}
2816         bufwords=(${(z)BUFFER})
2817         PATHTOMKDIR="${(Q)bufwords[iword]}"
2818     fi
2819     [[ -z "${PATHTOMKDIR}" ]] && return 1
2820     if [[ -e "${PATHTOMKDIR}" ]]; then
2821         zle -M " path already exists, doing nothing"
2822     else
2823         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2824         zle end-of-line
2825     fi
2826 }
2827 #k# mkdir -p <dir> from string under cursor or marked area
2828 zle -N inplaceMkDirs && bindkey '^XM' inplaceMkDirs
2829
2830 #f5# Memory overview
2831 memusage() {
2832     ps aux | awk '{if (NR > 1) print $5; if (NR > 2) print "+"} END { print "p" }' | dc
2833 }
2834 #f5# Show contents of gzipped tar file
2835 shtar() {
2836     emulate -L zsh
2837     gunzip -c $1 | tar -tf - -- | $PAGER
2838 }
2839 #f5# Show contents of zip file
2840 shzip() {
2841     emulate -L zsh
2842     unzip -l $1 | $PAGER
2843 }
2844 #f5# Unified diff
2845 udiff() {
2846     emulate -L zsh
2847     diff -urd $* | egrep -v "^Only in |^Binary files "
2848 }
2849 #f5# (Mis)use \kbd{vim} as \kbd{less}
2850 viless() {
2851     emulate -L zsh
2852     vim --cmd 'let no_plugin_maps = 1' -c "so \$VIMRUNTIME/macros/less.vim" "${@:--}"
2853 }
2854
2855 # Function Usage: uopen $URL/$file
2856 #f5# Download a file and display it locally
2857 uopen() {
2858     emulate -L zsh
2859     if ! [[ -n "$1" ]] ; then
2860         print "Usage: uopen \$URL/\$file">&2
2861         return 1
2862     else
2863         FILE=$1
2864         MIME=$(curl --head $FILE | grep Content-Type | cut -d ' ' -f 2 | cut -d\; -f 1)
2865         MIME=${MIME%$'\r'}
2866         curl $FILE | see ${MIME}:-
2867     fi
2868 }
2869
2870 # Function Usage: doc packagename
2871 #f5# \kbd{cd} to /usr/share/doc/\textit{package}
2872 doc() {
2873     emulate -L zsh
2874     cd /usr/share/doc/$1 && ls
2875 }
2876 _doc() { _files -W /usr/share/doc -/ }
2877 check_com compdef && compdef _doc doc
2878
2879 #f5# Make screenshot
2880 sshot() {
2881     [[ ! -d ~/shots  ]] && mkdir ~/shots
2882     #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
2883     cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
2884 }
2885
2886 # list images only
2887 limg() {
2888     local -a images
2889     images=( *.{jpg,gif,png}(.N) )
2890
2891     if [[ $#images -eq 0 ]] ; then
2892         print "No image files found"
2893     else
2894         ls "$images[@]"
2895     fi
2896 }
2897
2898 #f5# Create PDF file from source code
2899 makereadable() {
2900     emulate -L zsh
2901     output=$1
2902     shift
2903     a2ps --medium A4dj -E -o $output $*
2904     ps2pdf $output
2905 }
2906
2907 # zsh with perl-regex - use it e.g. via:
2908 # regcheck '\s\d\.\d{3}\.\d{3} Euro' ' 1.000.000 Euro'
2909 #f5# Checks whether a regex matches or not.\\&\quad Example: \kbd{regcheck '.\{3\} EUR' '500 EUR'}
2910 regcheck() {
2911     emulate -L zsh
2912     zmodload -i zsh/pcre
2913     pcre_compile $1 && \
2914     pcre_match $2 && echo "regex matches" || echo "regex does not match"
2915 }
2916
2917 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2918 accessed() {
2919     emulate -L zsh
2920     print -l -- *(a-${1:-1})
2921 }
2922
2923 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2924 changed() {
2925     emulate -L zsh
2926     print -l -- *(c-${1:-1})
2927 }
2928
2929 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2930 modified() {
2931     emulate -L zsh
2932     print -l -- *(m-${1:-1})
2933 }
2934 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2935 check_com new || alias new=modified
2936
2937 #f5# Grep in history
2938 greph() {
2939     emulate -L zsh
2940     history 0 | grep $1
2941 }
2942 # use colors when GNU grep with color-support
2943 #a2# Execute \kbd{grep -{}-color=auto}
2944 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
2945 #a2# Execute \kbd{grep -i -{}-color=auto}
2946 alias GREP='grep -i --color=auto'
2947
2948 #f5# Watch manpages in a stretched style
2949 man2() { PAGER='dash -c "sed G | /usr/bin/less"' command man "$@" ; }
2950
2951 # usage example: 'lcheck strcpy'
2952 #f5# Find out which libs define a symbol
2953 lcheck() {
2954     if [[ -n "$1" ]] ; then
2955         nm -go /usr/lib/lib*.a 2>/dev/null | grep ":[[:xdigit:]]\{8\} . .*$1"
2956     else
2957         echo "Usage: lcheck <function>" >&2
2958     fi
2959 }
2960
2961 #f5# Clean up directory - remove well known tempfiles
2962 purge() {
2963     emulate -L zsh
2964     setopt HIST_SUBST_PATTERN
2965     local -a TEXTEMPFILES GHCTEMPFILES PYTEMPFILES FILES
2966     TEXTEMPFILES=(*.tex(N:s/%tex/'(log|toc|aux|nav|snm|out|tex.backup|bbl|blg|bib.backup|vrb|lof|lot|hd|idx)(N)'/))
2967     GHCTEMPFILES=(*.(hs|lhs)(N:r:s/%/'.(hi|hc|(p|u|s)_(o|hi))(N)'/))
2968     PYTEMPFILES=(*.py(N:s/%py/'(pyc|pyo)(N)'/))
2969     LONELY_MOOD_FILES=((*.mood)(.NDe:'local -a AF;AF=( ${${REPLY#.}%mood}(mp3|flac|ogg|asf|wmv|aac)(N) ); [[ -z "$AF" ]]':))
2970     ZSH_COMPILED=(*.zwc(.NDe:'[[ -f ${REPLY%.zwc} && ${REPLY%.zwc} -nt ${REPLY} ]]':))
2971     FILES=(*~(.N) \#*\#(.N) *.o(.N) a.out(.N) (*.|)core(.N) *.cmo(.N) *.cmi(.N) .*.swp(.N) *.(orig|rej)(.DN) *.dpkg-(old|dist|new)(DN) ._(cfg|mrg)[0-9][0-9][0-9][0-9]_*(N) ${~TEXTEMPFILES} ${~GHCTEMPFILES} ${~PYTEMPFILES} ${LONELY_MOOD_FILES} ${ZSH_COMPILED} )
2972     local NBFILES=${#FILES}
2973     local CURDIRSUDO=""
2974     [[ ! -w ./ ]] && CURDIRSUDO=$SUDO
2975     if [[ $NBFILES > 0 ]] ; then
2976         print -l $FILES
2977         local ans
2978         echo -n "Remove these files? [y/n] "
2979         read -q ans; echo
2980         if [[ $ans == "y" ]] ; then
2981             $CURDIRSUDO rm ${FILES}
2982             echo ">> $PWD purged, $NBFILES files removed"
2983         else
2984             echo "Ok. .. then not.."
2985         fi
2986     fi
2987 }
2988
2989 #f5# show labels and uuids of disk devices
2990 if is439 && [[ -d /dev/disk/by-id/ ]]; then
2991     lsdisk() {
2992         emulate -L zsh
2993         setopt extendedglob
2994         local -a -U disks
2995         local -A mountinfo
2996         disks=( /dev/disk/by-id/*(@:A) )
2997         [[ -r /proc/mounts ]] && for cline ( "${(f)$(</proc/mounts)[@]}" ) mountinfo["${cline[(w)1]:A}"]="${cline[(w)2,-1]}"
2998         for dev in "$disks[@]"; do
2999             print ${fg_bold[red]}${dev}${reset_color} /dev/disk/by-label/*(@e/'[[ ${REPLY:A} == $dev ]] && REPLY=${fg[blue]}LABEL=${REPLY:t}${reset_color}'/N) /dev/disk/by-uuid/*(@e/'[[ ${REPLY:A} == $dev ]] && REPLY=${fg[green]}UUID=${REPLY:t}${reset_color}'/N)
3000             [[ -n "${mountinfo["$dev"]}" ]] && print -f " Mount: %s -t %s -o %s\n" ${mountinfo["$dev"][(w)1]} ${mountinfo["$dev"][(w)2]} "${mountinfo["$dev"][(w)3,-5]}"
3001             for sysdevsize ( /sys/block/${dev:t}/size(N) /sys/block/${${dev:t}%%<->}/${dev:t}/size(N) ) \
3002                 print -f "  Size: %.3f GiB (%d Byte)\n" $(($(<$sysdevsize)/(2.0*1024.0*1024.0))) $(($(<$sysdevsize)*512))
3003
3004             print -f "    Id: %s\n" /dev/disk/by-id/*(@e/'[[ ${REPLY:A} == $dev ]]'/N:t)
3005         done
3006     }
3007 fi
3008
3009 #f5# run command or function in a list of directories
3010 rundirs() {
3011   local d CMD STARTDIR=$PWD
3012   CMD=$1; shift
3013   ( for d ($@) {cd -q $d && { print cd $d; ${(z)CMD} ; cd -q $STARTDIR }} )
3014 }
3015
3016 # Translate DE<=>EN
3017 # 'translate' looks up fot a word in a file with language-to-language
3018 # translations (field separator should be " : "). A typical wordlist looks
3019 # like at follows:
3020 #  | english-word : german-transmission
3021 # It's also only possible to translate english to german but not reciprocal.
3022 # Use the following oneliner to turn back the sort order:
3023 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3024 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3025 #f5# Translates a word
3026 trans() {
3027     emulate -L zsh
3028     case "$1" in
3029         -[dD]*)
3030             translate -l de-en $2
3031             ;;
3032         -[eE]*)
3033             translate -l en-de $2
3034             ;;
3035         *)
3036             echo "Usage: $0 { -D | -E }"
3037             echo "         -D == German to English"
3038             echo "         -E == English to German"
3039     esac
3040 }
3041
3042 #f5# List all occurrences of programm in current PATH
3043 plap() {
3044     emulate -L zsh
3045     if [[ $# = 0 ]] ; then
3046         echo "Usage:    $0 program"
3047         echo "Example:  $0 zsh"
3048         echo "Lists all occurrences of program in the current PATH."
3049     else
3050         ls -l ${^path}/*$1*(*N)
3051     fi
3052 }
3053
3054 # Found in the mailinglistarchive from Zsh (IIRC ~1996)
3055 #f5# Select items for specific command(s) from history
3056 selhist() {
3057     emulate -L zsh
3058     local TAB=$'\t';
3059     (( $# < 1 )) && {
3060         echo "Usage: $0 command"
3061         return 1
3062     };
3063     cmd=(${(f)"$(grep -w $1 $HISTFILE | sort | uniq | pr -tn)"})
3064     print -l $cmd | less -F
3065     echo -n "enter number of desired command [1 - $(( ${#cmd[@]} - 1 ))]: "
3066     local answer
3067     read answer
3068     print -z "${cmd[$answer]#*$TAB}"
3069 }
3070
3071 # Use vim to convert plaintext to HTML
3072 #f5# Transform files to html with highlighting
3073 2html() {
3074     emulate -L zsh
3075     vim -u NONE -n -c ':syntax on' -c ':so $VIMRUNTIME/syntax/2html.vim' -c ':wqa' $1 &>/dev/null
3076 }
3077
3078 # Usage: simple-extract <file>
3079 # Using option -d deletes the original archive file.
3080 #f5# Smart archive extractor
3081 simple-extract() {
3082     emulate -L zsh
3083     setopt extended_glob noclobber
3084     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
3085     local RC=0
3086     zparseopts -D -E "d=DELETE_ORIGINAL"
3087     for ARCHIVE in "${@}"; do
3088         case $ARCHIVE in
3089             *.(tar.bz2|tbz2|tbz))
3090                 DECOMP_CMD="tar -xvjf -"
3091                 USES_STDIN=true
3092                 USES_STDOUT=false
3093                 ;;
3094             *.(tar.gz|tgz))
3095                 DECOMP_CMD="tar -xvzf -"
3096                 USES_STDIN=true
3097                 USES_STDOUT=false
3098                 ;;
3099             *.(tar.xz|txz|tar.lzma))
3100                 DECOMP_CMD="tar -xvJf -"
3101                 USES_STDIN=true
3102                 USES_STDOUT=false
3103                 ;;
3104             *.tar)
3105                 DECOMP_CMD="tar -xvf -"
3106                 USES_STDIN=true
3107                 USES_STDOUT=false
3108                 ;;
3109             *.rar)
3110                 DECOMP_CMD="unrar x"
3111                 USES_STDIN=false
3112                 USES_STDOUT=false
3113                 ;;
3114             *.lzh)
3115                 DECOMP_CMD="lha x"
3116                 USES_STDIN=false
3117                 USES_STDOUT=false
3118                 ;;
3119             *.7z)
3120                 DECOMP_CMD="7z x"
3121                 USES_STDIN=false
3122                 USES_STDOUT=false
3123                 ;;
3124             *.(zip|jar))
3125                 DECOMP_CMD="unzip"
3126                 USES_STDIN=false
3127                 USES_STDOUT=false
3128                 ;;
3129             *.deb)
3130                 DECOMP_CMD="ar -x"
3131                 USES_STDIN=false
3132                 USES_STDOUT=false
3133                 ;;
3134             *.bz2)
3135                 DECOMP_CMD="bzip2 -d -c -"
3136                 USES_STDIN=true
3137                 USES_STDOUT=true
3138                 ;;
3139             *.(gz|Z))
3140                 DECOMP_CMD="gzip -d -c -"
3141                 USES_STDIN=true
3142                 USES_STDOUT=true
3143                 ;;
3144             *.(xz|lzma))
3145                 DECOMP_CMD="xz -d -c -"
3146                 USES_STDIN=true
3147                 USES_STDOUT=true
3148                 ;;
3149             *)
3150                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
3151                 RC=$((RC+1))
3152                 continue
3153                 ;;
3154         esac
3155
3156         if ! check_com ${DECOMP_CMD[(w)1]}; then
3157             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
3158             RC=$((RC+2))
3159             continue
3160         fi
3161
3162         GZTARGET="${ARCHIVE:t:r}"
3163         if [[ -f $ARCHIVE ]] ; then
3164
3165             print "Extracting '$ARCHIVE' ..."
3166             if $USES_STDIN; then
3167                 if $USES_STDOUT; then
3168                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
3169                 else
3170                     ${=DECOMP_CMD} < "$ARCHIVE"
3171                 fi
3172             else
3173                 if $USES_STDOUT; then
3174                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
3175                 else
3176                     ${=DECOMP_CMD} "$ARCHIVE"
3177                 fi
3178             fi
3179             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
3180
3181         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
3182             if check_com curl; then
3183                 WGET_CMD="curl -k -s -o -"
3184             elif check_com wget; then
3185                 WGET_CMD="wget -q -O - --no-check-certificate"
3186             else
3187                 print "ERROR: neither wget nor curl is installed" >&2
3188                 RC=$((RC+4))
3189                 continue
3190             fi
3191             print "Downloading and Extracting '$ARCHIVE' ..."
3192             if $USES_STDIN; then
3193                 if $USES_STDOUT; then
3194                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
3195                     RC=$((RC+$?))
3196                 else
3197                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
3198                     RC=$((RC+$?))
3199                 fi
3200             else
3201                 if $USES_STDOUT; then
3202                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
3203                 else
3204                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
3205                 fi
3206             fi
3207
3208         else
3209             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
3210             RC=$((RC+8))
3211         fi
3212     done
3213     return $RC
3214 }
3215
3216 __archive_or_uri()
3217 {
3218     _alternative \
3219         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
3220         '_urls:Remote Archives:_urls'
3221 }
3222
3223 _simple_extract()
3224 {
3225     _arguments \
3226         '-d[delete original archivefile after extraction]' \
3227         '*:Archive Or Uri:__archive_or_uri'
3228 }
3229 compdef _simple_extract simple-extract
3230 alias se=simple-extract
3231
3232 # Usage: smartcompress <file> (<type>)
3233 #f5# Smart archive creator
3234 smartcompress() {
3235     emulate -L zsh
3236     if [[ -n $2 ]] ; then
3237         case $2 in
3238             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
3239             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
3240             tar.Z)          tar -Zcvf$1.$2 $1 ;;
3241             tar)            tar -cvf$1.$2  $1 ;;
3242             gz | gzip)      gzip           $1 ;;
3243             bz2 | bzip2)    bzip2          $1 ;;
3244             *)
3245                 echo "Error: $2 is not a valid compression type"
3246                 ;;
3247         esac
3248     else
3249         smartcompress $1 tar.gz
3250     fi
3251 }
3252
3253 # Usage: show-archive <archive>
3254 #f5# List an archive's content
3255 show-archive() {
3256     emulate -L zsh
3257     if [[ -f $1 ]] ; then
3258         case $1 in
3259             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
3260             *.tar)         tar -tf $1 ;;
3261             *.tgz)         tar -ztf $1 ;;
3262             *.zip)         unzip -l $1 ;;
3263             *.bz2)         bzless $1 ;;
3264             *.deb)         dpkg-deb --fsys-tarfile $1 | tar -tf - -- ;;
3265             *)             echo "'$1' Error. Please go away" ;;
3266         esac
3267     else
3268         echo "'$1' is not a valid archive"
3269     fi
3270 }
3271
3272 # It's shameless stolen from <http://www.vim.org/tips/tip.php?tip_id=167>
3273 #f5# Use \kbd{vim} as your manpage reader
3274 vman() {
3275     emulate -L zsh
3276     if (( ${#argv} == 0 )); then
3277         printf 'usage: vman <topic>\n'
3278         return 1
3279     fi
3280     man "$@" | col -b | view -c 'set ft=man nomod nolist' -
3281 }
3282
3283 # function readme() { $PAGER -- (#ia3)readme* }
3284 #f5# View all README-like files in current directory in pager
3285 readme() {
3286     emulate -L zsh
3287     setopt extendedglob
3288     local files
3289     files=(./(#i)*(read*me|lue*m(in|)ut|lies*mich)*(NDr^/=p%))
3290     if (($#files)) ; then
3291         $PAGER $files
3292     else
3293         print 'No README files.'
3294     fi
3295 }
3296
3297 # function ansi-colors()
3298 #f5# Display ANSI colors
3299 ansi-colors() {
3300     typeset esc="\033[" line1 line2
3301     echo " _ _ _40 _ _ _41_ _ _ _42 _ _ 43_ _ _ 44_ _ _45 _ _ _ 46_ _ _ 47_ _ _ 49_ _"
3302     for fore in 30 31 32 33 34 35 36 37; do
3303         line1="$fore "
3304         line2="   "
3305         for back in 40 41 42 43 44 45 46 47 49; do
3306             line1="${line1}${esc}${back};${fore}m Normal ${esc}0m"
3307             line2="${line2}${esc}${back};${fore};1m Bold   ${esc}0m"
3308         done
3309         echo -e "$line1\n$line2"
3310     done
3311 }
3312
3313 #f5# Find all files in \$PATH with setuid bit set
3314 suidfind() { ls -latg $path | grep '^...s' }
3315
3316 # TODO: So, this is the third incarnation of this function!?
3317 #f5# Reload given functions
3318 refunc() {
3319     for func in $argv ; do
3320         unfunction $func
3321         autoload $func
3322     done
3323 }
3324 compdef _functions refunc
3325
3326 # a small check to see which DIR is located on which server/partition.
3327 # stolen and modified from Sven's zshrc.forall
3328 #f5# Report diskusage of a directory
3329 dirspace() {
3330     emulate -L zsh
3331     if [[ -n "$1" ]] ; then
3332         for dir in "$@" ; do
3333             if [[ -d "$dir" ]] ; then
3334                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3335             else
3336                 echo "warning: $dir does not exist" >&2
3337             fi
3338         done
3339     else
3340         for dir in $path; do
3341             if [[ -d "$dir" ]] ; then
3342                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3343             else
3344                 echo "warning: $dir does not exist" >&2
3345             fi
3346         done
3347     fi
3348 }
3349
3350 # % slow_print `cat /etc/passwd`
3351 #f5# Slowly print out parameters
3352 slow_print() {
3353     for argument in "$@" ; do
3354         for ((i = 1; i <= ${#1} ;i++)) ; do
3355             print -n "${argument[i]}"
3356             sleep 0.08
3357         done
3358         print -n " "
3359     done
3360     print ""
3361 }
3362
3363 #f5# Show some status info
3364 status() {
3365     print
3366     print "Date..: "$(date "+%Y-%m-%d %H:%M:%S")
3367     print "Shell.: Zsh $ZSH_VERSION (PID = $$, $SHLVL nests)"
3368     print "Term..: $TTY ($TERM), ${BAUD:+$BAUD bauds, }$COLUMNS x $LINES chars"
3369     print "Login.: $LOGNAME (UID = $EUID) on $HOST"
3370     print "System: $(cat /etc/[A-Za-z]*[_-][rv]e[lr]*)"
3371     print "Uptime:$(uptime)"
3372     print
3373 }
3374
3375 # Rip an audio CD
3376 #f5# Rip an audio CD
3377 audiorip() {
3378     mkdir -p ~/ripps
3379     cd ~/ripps
3380     cdrdao read-cd --device $DEVICE --driver generic-mmc audiocd.toc
3381     cdrdao read-cddb --device $DEVICE --driver generic-mmc audiocd.toc
3382     echo " * Would you like to burn the cd now? (yes/no)"
3383     read input
3384     if [[ "$input" = "yes" ]] ; then
3385         echo " ! Burning Audio CD"
3386         audioburn
3387         echo " * done."
3388     else
3389         echo " ! Invalid response."
3390     fi
3391 }
3392
3393 # and burn it
3394 #f5# Burn an audio CD (in combination with audiorip)
3395 audioburn() {
3396     cd ~/ripps
3397     cdrdao write --device $DEVICE --driver generic-mmc audiocd.toc
3398     echo " * Should I remove the temporary files? (yes/no)"
3399     read input
3400     if [[ "$input" = "yes" ]] ; then
3401         echo " ! Removing Temporary Files."
3402         cd ~
3403         rm -rf ~/ripps
3404         echo " * done."
3405     else
3406         echo " ! Invalid response."
3407     fi
3408 }
3409
3410 #f5# Make an audio CD from all mp3 files
3411 mkaudiocd() {
3412     # TODO: do the renaming more zshish, possibly with zmv()
3413     emulate -L zsh
3414     cd ~/ripps
3415     for i in *.[Mm][Pp]3; do mv "$i" `echo $i | tr '[A-Z]' '[a-z]'`; done
3416     for i in *.mp3; do mv "$i" `echo $i | tr ' ' '_'`; done
3417     for i in *.mp3; do mpg123 -w `basename $i .mp3`.wav $i; done
3418     normalize -m *.wav
3419     for i in *.wav; do sox $i.wav -r 44100 $i.wav resample; done
3420 }
3421
3422 #f5# Create an ISO image. You are prompted for\\&\quad volume name, filename and directory
3423 mkiso() {
3424     emulate -L zsh
3425     echo " * Volume name "
3426     read volume
3427     echo " * ISO Name (ie. tmp.iso)"
3428     read iso
3429     echo " * Directory or File"
3430     read files
3431     mkisofs -o ~/$iso -A $volume -allow-multidot -J -R -iso-level 3 -V $volume -R $files
3432 }
3433
3434 #f5# Simple thumbnails generator
3435 genthumbs() {
3436     rm -rf thumb-* index.html
3437     echo "
3438 <html>
3439   <head>
3440     <title>Images</title>
3441   </head>
3442   <body>" > index.html
3443     for f in *.(gif|jpeg|jpg|png) ; do
3444         convert -size 100x200 "$f" -resize 100x200 thumb-"$f"
3445         echo "    <a href=\"$f\"><img src=\"thumb-$f\"></a>" >> index.html
3446     done
3447     echo "
3448   </body>
3449 </html>" >> index.html
3450 }
3451
3452 #f5# Set all ulimit parameters to \kbd{unlimited}
3453 allulimit() {
3454     ulimit -c unlimited
3455     ulimit -d unlimited
3456     ulimit -f unlimited
3457     ulimit -l unlimited
3458     ulimit -n unlimited
3459     ulimit -s unlimited
3460     ulimit -t unlimited
3461 }
3462
3463 #f5# RFC 2396 URL encoding in Z-Shell
3464 urlencode() {
3465     emulate -L zsh
3466     setopt extendedglob
3467     input=( ${(s::)1} )
3468     print ${(j::)input/(#b)([^A-Za-z0-9_.!~*\'\(\)-])/%${(l:2::0:)$(([##16]#match))}}
3469 }
3470
3471 # http://strcat.de/blog/index.php?/archives/335-Software-sauber-deinstallieren...html
3472 #f5# Log 'make install' output
3473 mmake() {
3474     emulate -L zsh
3475     [[ ! -d ~/.errorlogs ]] && mkdir ~/.errorlogs
3476     make -n install > ~/.errorlogs/${PWD##*/}-makelog
3477 }
3478
3479 #f5# Indent source code
3480 smart-indent() {
3481     indent -npro -kr -i8 -ts8 -sob -l80 -ss -ncs "$@"
3482 }
3483
3484 # highlight important stuff in diff output, usage example: hg diff | hidiff
3485 #m# a2 hidiff \kbd{histring} oneliner for diffs
3486 check_com -c histring && \
3487     alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
3488
3489 # rename pictures based on information found in exif headers
3490 #f5# Rename pictures based on information found in exif headers
3491 exirename() {
3492     emulate -L zsh
3493     if [[ $# -lt 1 ]] ; then
3494         echo 'Usage: jpgrename $FILES' >& 2
3495         return 1
3496     else
3497         echo -n 'Checking for jhead with version newer than 1.9: '
3498         jhead_version=`jhead -h | grep 'used by most Digital Cameras.  v.*' | awk '{print $6}' | tr -d v`
3499         if [[ $jhead_version > '1.9' ]]; then
3500             echo 'success - now running jhead.'
3501             jhead -n%Y-%m-%d_%Hh%M_%f $*
3502         else
3503             echo 'failed - exiting.'
3504         fi
3505     fi
3506 }
3507
3508 # get_ic() - queries imap servers for capabilities; real simple. no imaps
3509 ic_get() {
3510     emulate -L zsh
3511     local port
3512     if [[ ! -z $1 ]] ; then
3513         port=${2:-143}
3514         print "querying imap server on $1:${port}...\n";
3515         print "a1 capability\na2 logout\n" | nc $1 ${port}
3516     else
3517         print "usage:\n  $0 <imap-server> [port]"
3518     fi
3519 }
3520
3521 # creates a Maildir/ with its {new,cur,tmp} subdirs
3522 mkmaildir() {
3523     emulate -L zsh
3524     local root subdir
3525     root=${MAILDIR_ROOT:-${HOME}/Mail}
3526     if [[ -z ${1} ]] ; then print "Usage:\n $0 <dirname>" ; return 1 ; fi
3527     subdir=${1}
3528     mkdir -p ${root}/${subdir}/{cur,new,tmp}
3529 }
3530
3531 #f5# Change the xterm title from within GNU-screen
3532 xtrename() {
3533     emulate -L zsh
3534     if [[ $1 != "-f" ]] ; then
3535         if [[ -z ${DISPLAY} ]] ; then
3536             printf 'xtrename only makes sense in X11.\n'
3537             return 1
3538         fi
3539     else
3540         shift
3541     fi
3542     if [[ -z $1 ]] ; then
3543         printf 'usage: xtrename [-f] "title for xterm"\n'
3544         printf '  renames the title of xterm from _within_ screen.\n'
3545         printf '  also works without screen.\n'
3546         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3547         return 0
3548     fi
3549     print -n "\eP\e]0;${1}\C-G\e\\"
3550     return 0
3551 }
3552
3553 # hl() highlighted less
3554 # http://ft.bewatermyfriend.org/comp/data/zsh/zfunct.html
3555 if check_com -c highlight ; then
3556     function hl() {
3557     emulate -L zsh
3558         local theme lang
3559         theme=${HL_THEME:-""}
3560         case ${1} in
3561             (-l|--list)
3562                 ( printf 'available languages (syntax parameter):\n\n' ;
3563                     highlight --list-langs ; ) | less -SMr
3564                 ;;
3565             (-t|--themes)
3566                 ( printf 'available themes (style parameter):\n\n' ;
3567                     highlight --list-themes ; ) | less -SMr
3568                 ;;
3569             (-h|--help)
3570                 printf 'usage: hl <syntax[:theme]> <file>\n'
3571                 printf '    available options: --list (-l), --themes (-t), --help (-h)\n\n'
3572                 printf '  Example: hl c main.c\n'
3573                 ;;
3574             (*)
3575                 if [[ -z ${2} ]] || (( ${#argv} > 2 )) ; then
3576                     printf 'usage: hl <syntax[:theme]> <file>\n'
3577                     printf '    available options: --list (-l), --themes (-t), --help (-h)\n'
3578                     (( ${#argv} > 2 )) && printf '  Too many arguments.\n'
3579                     return 1
3580                 fi
3581                 lang=${1%:*}
3582                 [[ ${1} == *:* ]] && [[ -n ${1#*:} ]] && theme=${1#*:}
3583                 if [[ -n ${theme} ]] ; then
3584                     highlight -O xterm256 --syntax ${lang} --style ${theme} ${2} | less -SMr
3585                 else
3586                     highlight -O ansi --syntax ${lang} ${2} | less -SMr
3587                 fi
3588                 ;;
3589         esac
3590         return 0
3591     }
3592     # ... and a proper completion for hl()
3593     # needs 'highlight' as well, so it fits fine in here.
3594     function _hl_genarg()  {
3595         local expl
3596         if [[ -prefix 1 *: ]] ; then
3597             local themes
3598             themes=(${${${(f)"$(LC_ALL=C highlight --list-themes)"}/ #/}:#*(Installed|Use name)*})
3599             compset -P 1 '*:'
3600             _wanted -C list themes expl theme compadd ${themes}
3601         else
3602             local langs
3603             langs=(${${${(f)"$(LC_ALL=C highlight --list-langs)"}/ #/}:#*(Installed|Use name)*})
3604             _wanted -C list languages expl languages compadd -S ':' -q ${langs}
3605         fi
3606     }
3607     function _hl_complete() {
3608         _arguments -s '1: :_hl_genarg' '2:files:_path_files'
3609     }
3610     compdef _hl_complete hl
3611 fi
3612
3613 # TODO:
3614 # Rewrite this by either using tinyurl.com's API
3615 # or using another shortening service to comply with
3616 # tinyurl.com's policy.
3617 #
3618 # Create small urls via http://tinyurl.com using wget(1).
3619 #function zurl() {
3620 #    emulate -L zsh
3621 #    [[ -z $1 ]] && { print "USAGE: zurl <URL>" ; return 1 }
3622 #
3623 #    local PN url tiny grabber search result preview
3624 #    PN=$0
3625 #    url=$1
3626 ##   Check existence of given URL with the help of ping(1).
3627 ##   N.B. ping(1) only works without an eventual given protocol.
3628 #    ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
3629 #        read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
3630 #
3631 #    if (( $? == 0 )) ; then
3632 ##           Prepend 'http://' to given URL where necessary for later output.
3633 #            [[ ${url} != http(s|)://* ]] && url='http://'${url}
3634 #            tiny='http://tinyurl.com/create.php?url='
3635 #            if check_com -c wget ; then
3636 #                grabber='wget -O- -o/dev/null'
3637 #            else
3638 #                print "wget is not available, but mandatory for ${PN}. Aborting."
3639 #            fi
3640 ##           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
3641 #            search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
3642 #            result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
3643 ##           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
3644 #            preview='http://preview.'${result#http://}
3645 #
3646 #            printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
3647 #            printf '%s\t%s\n\n' 'Given URL:' ${url}
3648 #            printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
3649 #    else
3650 #        return 1
3651 #    fi
3652 #}
3653
3654 #f2# Print a specific line of file(s).
3655 linenr () {
3656 # {{{
3657     emulate -L zsh
3658     if [ $# -lt 2 ] ; then
3659        print "Usage: linenr <number>[,<number>] <file>" ; return 1
3660     elif [ $# -eq 2 ] ; then
3661          local number=$1
3662          local file=$2
3663          command ed -s $file <<< "${number}n"
3664     else
3665          local number=$1
3666          shift
3667          for file in "$@" ; do
3668              if [ ! -d $file ] ; then
3669                 echo "${file}:"
3670                 command ed -s $file <<< "${number}n" 2> /dev/null
3671              else
3672                 continue
3673              fi
3674          done | less
3675     fi
3676 # }}}
3677 }
3678
3679 #f2# Find history events by search pattern and list them by date.
3680 whatwhen()  {
3681 # {{{
3682     emulate -L zsh
3683     local usage help ident format_l format_s first_char remain first last
3684     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3685     help='Use `whatwhen -h'\'' for further explanations.'
3686     ident=${(l,${#${:-Usage: }},, ,)}
3687     format_l="${ident}%s\t\t\t%s\n"
3688     format_s="${format_l//(\\t)##/\\t}"
3689     # Make the first char of the word to search for case
3690     # insensitive; e.g. [aA]
3691     first_char=[${(L)1[1]}${(U)1[1]}]
3692     remain=${1[2,-1]}
3693     # Default search range is `-100'.
3694     first=${2:-\-100}
3695     # Optional, just used for `<first> <last>' given.
3696     last=$3
3697     case $1 in
3698         ("")
3699             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3700             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3701         ;;
3702         (-h)
3703             printf '%s\n\n' ${usage}
3704             print 'OPTIONS:'
3705             printf $format_l '-h' 'show help text'
3706             print '\f'
3707             print 'SEARCH RANGE:'
3708             printf $format_l "'0'" 'the whole history,'
3709             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
3710             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
3711             printf '\n%s\n' 'EXAMPLES:'
3712             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
3713             printf $format_l 'whatwhen zsh -250'
3714             printf $format_l 'whatwhen foo 1 99'
3715         ;;
3716         (\?)
3717             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3718         ;;
3719         (*)
3720             # -l list results on stout rather than invoking $EDITOR.
3721             # -i Print dates as in YYYY-MM-DD.
3722             # -m Search for a - quoted - pattern within the history.
3723             fc -li -m "*${first_char}${remain}*" $first $last
3724         ;;
3725     esac
3726 # }}}
3727 }
3728
3729 # change fluxbox keys from 'Alt-#' to 'Alt-F#' and vice versa
3730 fluxkey-change() {
3731     emulate -L zsh
3732     [[ -n "$FLUXKEYS" ]] || local FLUXKEYS="$HOME/.fluxbox/keys"
3733     if ! [[ -r "$FLUXKEYS" ]] ; then
3734         echo "Sorry, \$FLUXKEYS file $FLUXKEYS could not be read - nothing to be done."
3735         return 1
3736     else
3737         if grep -q 'Mod1 F[0-9] :Workspace [0-9]' $FLUXKEYS ; then
3738             echo -n 'Switching to Alt-# mode in ~/.fluxbox/keys: '
3739             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)F\([0-9]\+[: space :]\+:Workspace.*\)|\1\2|' $FLUXKEYS && echo done || echo failed
3740         elif grep -q 'Mod1 [0-9] :Workspace [0-9]' $FLUXKEYS ; then
3741             echo -n 'Switching to Alt-F# mode in ~/.fluxbox/keys: '
3742             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)\([0-9]\+[: space :]\+:Workspace.*\)|\1F\2|' $FLUXKEYS && echo done || echo failed
3743         else
3744             echo 'Sorry, do not know what to do.'
3745             return 1
3746         fi
3747     fi
3748 }
3749
3750 # retrieve weather information on the console
3751 # Usage example: 'weather LOWG'
3752 weather() {
3753     emulate -L zsh
3754     [[ -n "$1" ]] || {
3755         print 'Usage: weather <station_id>' >&2
3756         print 'List of stations: http://en.wikipedia.org/wiki/List_of_airports_by_ICAO_code'>&2
3757         return 1
3758     }
3759
3760     local VERBOSE="yes"    # TODO: Make this a command line switch
3761
3762     local ODIR=`pwd`
3763     local PLACE="${1:u}"
3764     local DIR="${HOME}/.weather"
3765     local LOG="${DIR}/log"
3766
3767     [[ -d ${DIR} ]] || {
3768         print -n "Creating ${DIR}: "
3769         mkdir ${DIR}
3770         print 'done'
3771     }
3772
3773     print "Retrieving information for ${PLACE}:"
3774     print
3775     cd ${DIR} && wget -T 10 --no-verbose --output-file=$LOG --timestamping http://weather.noaa.gov/pub/data/observations/metar/decoded/$PLACE.TXT
3776
3777     if [[ $? -eq 0 ]] ; then
3778         if [[ -n "$VERBOSE" ]] ; then
3779             cat ${PLACE}.TXT
3780         else
3781             DATE=$(grep 'UTC' ${PLACE}.TXT | sed 's#.* /##')
3782             TEMPERATURE=$(awk '/Temperature/ { print $4" degree Celcius / " $2" degree Fahrenheit" }' ${PLACE}.TXT | tr -d '(')
3783             echo "date: $DATE"
3784             echo "temp:  $TEMPERATURE"
3785         fi
3786     else
3787         print "There was an error retrieving the weather information for $PLACE" >&2
3788         cat $LOG
3789         cd $ODIR
3790         return 1
3791     fi
3792     cd $ODIR
3793 }
3794 # }}}
3795
3796 # mercurial related stuff {{{
3797 if check_com -c hg ; then
3798     # gnu like diff for mercurial
3799     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
3800     #f5# GNU like diff for mercurial
3801     hgdi() {
3802         emulate -L zsh
3803         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
3804     }
3805
3806     # build debian package
3807     #a2# Alias for \kbd{hg-buildpackage}
3808     alias hbp='hg-buildpackage'
3809
3810     # execute commands on the versioned patch-queue from the current repos
3811     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
3812
3813     # diffstat for specific version of a mercurial repository
3814     #   hgstat      => display diffstat between last revision and tip
3815     #   hgstat 1234 => display diffstat between revision 1234 and tip
3816     #f5# Diffstat for specific version of a mercurial repos
3817     hgstat() {
3818         emulate -L zsh
3819         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
3820     }
3821
3822 fi # end of check whether we have the 'hg'-executable
3823
3824 # }}}
3825
3826 # some useful commands often hard to remember - let's grep for them {{{
3827 # actually use our zg() function now. :)
3828
3829 # Work around ion/xterm resize bug.
3830 #if [[ "$SHLVL" -eq 1 ]]; then
3831 #       if check_com -c resize ; then
3832 #               eval `resize </dev/null`
3833 #       fi
3834 #fi
3835
3836 # enable jackd:
3837 #  /usr/bin/jackd -dalsa -dhw:0 -r48000 -p1024 -n2
3838 # now play audio file:
3839 #  alsaplayer -o jack foobar.mp3
3840
3841 # send files via netcat
3842 # on sending side:
3843 #  send() {j=$*; tar cpz ${j/%${!#}/}|nc -w 1 ${!#} 51330;}
3844 #  send dir* $HOST
3845 #  alias receive='nc -vlp 51330 | tar xzvp'
3846
3847 # debian stuff:
3848 # dh_make -e foo@localhost -f $1
3849 # dpkg-buildpackage -rfakeroot
3850 # lintian *.deb
3851 # dpkg-scanpackages ./ /dev/null | gzip > Packages.gz
3852 # dpkg-scansources . | gzip > Sources.gz
3853 # grep-dctrl --field Maintainer $* /var/lib/apt/lists/*
3854
3855 # other stuff:
3856 # convert -geometry 200x200 -interlace LINE -verbose
3857 # ldapsearch -x -b "OU=Bedienstete,O=tug" -h ldap.tugraz.at sn=$1
3858 # ps -ao user,pcpu,start,command
3859 # gpg --keyserver blackhole.pca.dfn.de --recv-keys
3860 # xterm -bg black -fg yellow -fn -misc-fixed-medium-r-normal--14-140-75-75-c-90-iso8859-15 -ah
3861 # nc -vz $1 1-1024   # portscan via netcat
3862 # wget --mirror --no-parent --convert-links
3863 # pal -d `date +%d`
3864 # autoload -U tetris; zle -N tetris; bindkey '...' ; echo "press ... for playing tennis"
3865 #
3866 # modify console cursor
3867 # see http://www.tldp.org/HOWTO/Framebuffer-HOWTO-5.html
3868 # print $'\e[?96;0;64c'
3869 # }}}
3870
3871 # grml-small cleanups {{{
3872
3873 # The following is used to remove zsh-config-items that do not work
3874 # in grml-small by default.
3875 # If you do not want these adjustments (for whatever reason), set
3876 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
3877 # sources if it is there).
3878
3879 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
3880
3881     unset abk[V]
3882     unalias    'V'      &> /dev/null
3883     unfunction vman     &> /dev/null
3884     unfunction viless   &> /dev/null
3885     unfunction 2html    &> /dev/null
3886
3887     # manpages are not in grmlsmall
3888     unfunction manzsh   &> /dev/null
3889     unfunction man2     &> /dev/null
3890
3891 fi
3892
3893 #}}}
3894
3895 zrclocal
3896
3897 ## genrefcard.pl settings {{{
3898
3899 ### doc strings for external functions from files
3900 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
3901
3902 ### example: split functions-search 8,16,24,32
3903 #@# split functions-search 8
3904
3905 ## }}}
3906
3907 ## END OF FILE #################################################################
3908 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
3909 # Local variables:
3910 # mode: sh
3911 # End: