etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is439(){
 148     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 #f1# Checks whether or not you're running grml
 154 isgrml(){
 155     [[ -f /etc/grml_version ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running a grml cd
 160 isgrmlcd(){
 161     [[ -f /etc/grml_cd ]] && return 0
 162     return 1
 163 }
 164
 165 if isgrml ; then
 166 #f1# Checks whether or not you're running grml-small
 167     isgrmlsmall() {
 168         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 169             return 0
 170         fi
 171         return 1
 172     }
 173 else
 174     isgrmlsmall() { return 1 }
 175 fi
 176
 177 isdarwin(){
 178     [[ $OSTYPE == darwin* ]] && return 0
 179     return 1
 180 }
 181
 182 #f1# are we running within an utf environment?
 183 isutfenv() {
 184     case "$LANG $CHARSET $LANGUAGE" in
 185         *utf*) return 0 ;;
 186         *UTF*) return 0 ;;
 187         *)     return 1 ;;
 188     esac
 189 }
 190
 191 # check for user, if not running as root set $SUDO to sudo
 192 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 193
 194 # change directory to home on first invocation of zsh
 195 # important for rungetty -> autologin
 196 # Thanks go to Bart Schaefer!
 197 isgrml && checkhome() {
 198     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 199         export ALREADY_DID_CD_HOME=$HOME
 200         cd
 201     fi
 202 }
 203
 204 # check for zsh v3.1.7+
 205
 206 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 207      || ${ZSH_VERSION} == 3.<2->.<->*    \
 208      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 209
 210     printf '-!-\n'
 211     printf '-!- In this configuration we try to make use of features, that only\n'
 212     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 213     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 214     printf '-!- advanced features in all supported versions.\n'
 215     printf '-!-\n'
 216     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 217     printf '-!-\n'
 218     printf '-!- While this *may* work, it might as well fail.\n'
 219     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 220     printf '-!-\n'
 221     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 222     printf '-!- If it does today, you'\''ve been lucky.\n'
 223     printf '-!-\n'
 224     printf '-!- Ye been warned!\n'
 225     printf '-!-\n'
 226
 227     function zstyle() { : }
 228 fi
 229
 230 # autoload wrapper - use this one instead of autoload directly
 231 # We need to define this function as early as this, because autoloading
 232 # 'is-at-least()' needs it.
 233 function zrcautoload() {
 234     emulate -L zsh
 235     setopt extended_glob
 236     local fdir ffile
 237     local -i ffound
 238
 239     ffile=$1
 240     (( found = 0 ))
 241     for fdir in ${fpath} ; do
 242         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 243     done
 244
 245     (( ffound == 0 )) && return 1
 246     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 247         autoload -U ${ffile} || return 1
 248     else
 249         autoload ${ffile} || return 1
 250     fi
 251     return 0
 252 }
 253
 254 # Load is-at-least() for more precise version checks Note that this test will
 255 # *always* fail, if the is-at-least function could not be marked for
 256 # autoloading.
 257 zrcautoload is-at-least || is-at-least() { return 1 }
 258
 259 # set some important options (as early as possible)
 260
 261 # append history list to the history file; this is the default but we make sure
 262 # because it's required for share_history.
 263 setopt append_history
 264
 265 # import new commands from the history file also in other zsh-session
 266 is4 && setopt share_history
 267
 268 # save each command's beginning timestamp and the duration to the history file
 269 setopt extended_history
 270
 271 # If a new command line being added to the history list duplicates an older
 272 # one, the older command is removed from the list
 273 is4 && setopt histignorealldups
 274
 275 # remove command lines from the history list when the first character on the
 276 # line is a space
 277 setopt histignorespace
 278
 279 # if a command is issued that can't be executed as a normal command, and the
 280 # command is the name of a directory, perform the cd command to that directory.
 281 setopt auto_cd
 282
 283 # in order to use #, ~ and ^ for filename generation grep word
 284 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 285 # don't forget to quote '^', '~' and '#'!
 286 setopt extended_glob
 287
 288 # display PID when suspending processes as well
 289 setopt longlistjobs
 290
 291 # try to avoid the 'zsh: no matches found...'
 292 setopt nonomatch
 293
 294 # report the status of backgrounds jobs immediately
 295 setopt notify
 296
 297 # whenever a command completion is attempted, make sure the entire command path
 298 # is hashed first.
 299 setopt hash_list_all
 300
 301 # not just at the end
 302 setopt completeinword
 303
 304 # Don't send SIGHUP to background processes when the shell exits.
 305 setopt nohup
 306
 307 # make cd push the old directory onto the directory stack.
 308 setopt auto_pushd
 309
 310 # avoid "beep"ing
 311 setopt nobeep
 312
 313 # don't push the same dir twice.
 314 setopt pushd_ignore_dups
 315
 316 # * shouldn't match dotfiles. ever.
 317 setopt noglobdots
 318
 319 # use zsh style word splitting
 320 setopt noshwordsplit
 321
 322 # don't error out when unset parameters are used
 323 setopt unset
 324
 325 # setting some default values
 326 NOCOR=${NOCOR:-0}
 327 NOMENU=${NOMENU:-0}
 328 NOPRECMD=${NOPRECMD:-0}
 329 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 330 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 331 BATTERY=${BATTERY:-0}
 332 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 333 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 334
 335 typeset -ga ls_options
 336 typeset -ga grep_options
 337 if ls --help 2> /dev/null | grep -q GNU; then
 338     ls_options=( --color=auto )
 339 elif [[ $OSTYPE == freebsd* ]]; then
 340     ls_options=( -G )
 341 fi
 342 if grep --help 2> /dev/null | grep -q GNU || \
 343    [[ $OSTYPE == freebsd* ]]; then
 344     grep_options=( --color=auto )
 345 fi
 346
 347 # utility functions
 348 # this function checks if a command exists and returns either true
 349 # or false. This avoids using 'which' and 'whence', which will
 350 # avoid problems with aliases for which on certain weird systems. :-)
 351 # Usage: check_com [-c|-g] word
 352 #   -c  only checks for external commands
 353 #   -g  does the usual tests and also checks for global aliases
 354 check_com() {
 355     emulate -L zsh
 356     local -i comonly gatoo
 357
 358     if [[ $1 == '-c' ]] ; then
 359         (( comonly = 1 ))
 360         shift
 361     elif [[ $1 == '-g' ]] ; then
 362         (( gatoo = 1 ))
 363     else
 364         (( comonly = 0 ))
 365         (( gatoo = 0 ))
 366     fi
 367
 368     if (( ${#argv} != 1 )) ; then
 369         printf 'usage: check_com [-c] <command>\n' >&2
 370         return 1
 371     fi
 372
 373     if (( comonly > 0 )) ; then
 374         [[ -n ${commands[$1]}  ]] && return 0
 375         return 1
 376     fi
 377
 378     if   [[ -n ${commands[$1]}    ]] \
 379       || [[ -n ${functions[$1]}   ]] \
 380       || [[ -n ${aliases[$1]}     ]] \
 381       || [[ -n ${reswords[(r)$1]} ]] ; then
 382
 383         return 0
 384     fi
 385
 386     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 387         return 0
 388     fi
 389
 390     return 1
 391 }
 392
 393 # creates an alias and precedes the command with
 394 # sudo if $EUID is not zero.
 395 salias() {
 396     emulate -L zsh
 397     local only=0 ; local multi=0
 398     while [[ $1 == -* ]] ; do
 399         case $1 in
 400             (-o) only=1 ;;
 401             (-a) multi=1 ;;
 402             (--) shift ; break ;;
 403             (-h)
 404                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 405                 printf '  -h      shows this help text.\n'
 406                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 407                 printf '          be careful using this option.\n'
 408                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 409                 return 0
 410                 ;;
 411             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 412         esac
 413         shift
 414     done
 415
 416     if (( ${#argv} > 1 )) ; then
 417         printf 'Too many arguments %s\n' "${#argv}"
 418         return 1
 419     fi
 420
 421     key="${1%%\=*}" ;  val="${1#*\=}"
 422     if (( EUID == 0 )) && (( only == 0 )); then
 423         alias -- "${key}=${val}"
 424     elif (( EUID > 0 )) ; then
 425         (( multi > 0 )) && val="${val// ; / ; sudo }"
 426         alias -- "${key}=sudo ${val}"
 427     fi
 428
 429     return 0
 430 }
 431
 432 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 433 # usage: uprint foo
 434 #   Where foo is the *name* of the parameter you want printed.
 435 #   Note that foo is no typo; $foo would be wrong here!
 436 if ! is42 ; then
 437     uprint () {
 438         emulate -L zsh
 439         local -a u
 440         local w
 441         local parameter=$1
 442
 443         if [[ -z ${parameter} ]] ; then
 444             printf 'usage: uprint <parameter>\n'
 445             return 1
 446         fi
 447
 448         for w in ${(P)parameter} ; do
 449             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 450         done
 451
 452         builtin print -l $u
 453     }
 454 fi
 455
 456 # Check if we can read given files and source those we can.
 457 xsource() {
 458     if (( ${#argv} < 1 )) ; then
 459         printf 'usage: xsource FILE(s)...\n' >&2
 460         return 1
 461     fi
 462
 463     while (( ${#argv} > 0 )) ; do
 464         [[ -r "$1" ]] && source "$1"
 465         shift
 466     done
 467     return 0
 468 }
 469
 470 # Check if we can read a given file and 'cat(1)' it.
 471 xcat() {
 472     emulate -L zsh
 473     if (( ${#argv} != 1 )) ; then
 474         printf 'usage: xcat FILE\n' >&2
 475         return 1
 476     fi
 477
 478     [[ -r $1 ]] && cat $1
 479     return 0
 480 }
 481
 482 # Remove these functions again, they are of use only in these
 483 # setup files. This should be called at the end of .zshrc.
 484 xunfunction() {
 485     emulate -L zsh
 486     local -a funcs
 487     funcs=(salias xcat xsource xunfunction zrcautoload)
 488
 489     for func in $funcs ; do
 490         [[ -n ${functions[$func]} ]] \
 491             && unfunction $func
 492     done
 493     return 0
 494 }
 495
 496 # this allows us to stay in sync with grml's zshrc and put own
 497 # modifications in ~/.zshrc.local
 498 zrclocal() {
 499     xsource "/etc/zsh/zshrc.local"
 500     xsource "${HOME}/.zshrc.local"
 501     return 0
 502 }
 503
 504 # locale setup
 505 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 506     xsource "/etc/default/locale"
 507 fi
 508
 509 for var in LANG LC_ALL LC_MESSAGES ; do
 510     [[ -n ${(P)var} ]] && export $var
 511 done
 512
 513 xsource "/etc/sysconfig/keyboard"
 514
 515 TZ=$(xcat /etc/timezone)
 516
 517 # set some variables
 518 if check_com -c vim ; then
 519 #v#
 520     export EDITOR=${EDITOR:-vim}
 521 else
 522     export EDITOR=${EDITOR:-vi}
 523 fi
 524
 525 #v#
 526 export PAGER=${PAGER:-less}
 527
 528 #v#
 529 export MAIL=${MAIL:-/var/mail/$USER}
 530
 531 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 532 export SHELL='/bin/zsh'
 533
 534 # color setup for ls:
 535 check_com -c dircolors && eval $(dircolors -b)
 536 # color setup for ls on OS X:
 537 isdarwin && export CLICOLOR=1
 538
 539 # do MacPorts setup on darwin
 540 if isdarwin && [[ -d /opt/local ]]; then
 541     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 542     # zshenv.
 543     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 544     MANPATH="/opt/local/share/man:$MANPATH"
 545 fi
 546 # do Fink setup on darwin
 547 isdarwin && xsource /sw/bin/init.sh
 548
 549 # load our function and completion directories
 550 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 551     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 552     if [[ ${fpath} == '/usr/share/grml/zsh/functions' ]] ; then
 553         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 554             zrcautoload ${func:t}
 555         done
 556     fi
 557 done
 558 unset fdir func
 559
 560 # support colors in less
 561 export LESS_TERMCAP_mb=$'\E[01;31m'
 562 export LESS_TERMCAP_md=$'\E[01;31m'
 563 export LESS_TERMCAP_me=$'\E[0m'
 564 export LESS_TERMCAP_se=$'\E[0m'
 565 export LESS_TERMCAP_so=$'\E[01;44;33m'
 566 export LESS_TERMCAP_ue=$'\E[0m'
 567 export LESS_TERMCAP_us=$'\E[01;32m'
 568
 569 # mailchecks
 570 MAILCHECK=30
 571
 572 # report about cpu-/system-/user-time of command if running longer than
 573 # 5 seconds
 574 REPORTTIME=5
 575
 576 # watch for everyone but me and root
 577 watch=(notme root)
 578
 579 # automatically remove duplicates from these arrays
 580 typeset -U path cdpath fpath manpath
 581
 582 # keybindings
 583 if [[ "$TERM" != emacs ]] ; then
 584     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 585     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 586     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 587     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 588     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 589     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 590     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 591     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 592     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 593     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 594     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 595     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 596     # ncurses stuff:
 597     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 598     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 599     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 600     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 601     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 602     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 603     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 604     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 605 fi
 606
 607 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 608 # use emacs style per default:
 609 bindkey -e
 610 # use vi style:
 611 # bindkey -v
 612
 613 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 614 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 615 beginning-or-end-of-somewhere() {
 616     local hno=$HISTNO
 617     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 618       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 619         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 620     else
 621         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 622         if (( HISTNO != hno )); then
 623             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 624         fi
 625     fi
 626 }
 627 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 628 zle -N end-of-somewhere beginning-or-end-of-somewhere
 629
 630
 631 #if [[ "$TERM" == screen ]] ; then
 632
 633 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 634 ## to beginning/end of buffer on second keypress
 635 ## and to beginning/end of history on (at most) the third keypress
 636 # terminator & non-debian xterm
 637 bindkey '\eOH' beginning-of-somewhere  # home
 638 bindkey '\eOF' end-of-somewhere        # end
 639 # freebsd console
 640 bindkey '\e[H' beginning-of-somewhere   # home
 641 bindkey '\e[F' end-of-somewhere         # end
 642 # xterm,gnome-terminal,quake,etc
 643 bindkey '^[[1~' beginning-of-somewhere  # home
 644 bindkey '^[[4~' end-of-somewhere        # end
 645 # if terminal type is set to 'rxvt':
 646 bindkey '\e[7~' beginning-of-somewhere  # home
 647 bindkey '\e[8~' end-of-somewhere        # end
 648 #fi
 649
 650 bindkey '\e[A'  up-line-or-search       # cursor up
 651 bindkey '\e[B'  down-line-or-search     # <ESC>-
 652
 653 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 654 bindkey "\e[5C" forward-word
 655 bindkey "\e[5D" backward-word
 656 bindkey "\e[1;5C" forward-word
 657 bindkey "\e[1;5D" backward-word
 658 ## the same for alt-left-arrow and alt-right-arrow
 659 bindkey '^[[1;3C' forward-word
 660 bindkey '^[[1;3D' backward-word
 661
 662 # Search backward in the history for a line beginning with the current
 663 # line up to the cursor and move the cursor to the end of the line then
 664 zle -N history-beginning-search-backward-end history-search-end
 665 zle -N history-beginning-search-forward-end  history-search-end
 666 #k# search history backward for entry beginning with typed text
 667 bindkey '^xp'   history-beginning-search-backward-end
 668 #k# search history forward for entry beginning with typed text
 669 bindkey '^xP'   history-beginning-search-forward-end
 670 #k# search history backward for entry beginning with typed text
 671 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 672 #k# search history forward for entry beginning with typed text
 673 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 674
 675 # bindkey -s '^l' "|less\n"             # ctrl-L pipes to less
 676 # bindkey -s '^b' " &\n"                # ctrl-B runs it in the background
 677
 678 # insert unicode character
 679 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 680 # See for example http://unicode.org/charts/ for unicode characters code
 681 zrcautoload insert-unicode-char
 682 zle -N insert-unicode-char
 683 #k# Insert Unicode character
 684 bindkey '^xi' insert-unicode-char
 685
 686 #m# k Shift-tab Perform backwards menu completion
 687 if [[ -n "$terminfo[kcbt]" ]]; then
 688     bindkey "$terminfo[kcbt]" reverse-menu-complete
 689 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 690     bindkey "$terminfo[cbt]"  reverse-menu-complete
 691 fi
 692
 693 ## toggle the ,. abbreviation feature on/off
 694 # NOABBREVIATION: default abbreviation-state
 695 #                 0 - enabled (default)
 696 #                 1 - disabled
 697 NOABBREVIATION=${NOABBREVIATION:-0}
 698
 699 grml_toggle_abbrev() {
 700     if (( ${NOABBREVIATION} > 0 )) ; then
 701         NOABBREVIATION=0
 702     else
 703         NOABBREVIATION=1
 704     fi
 705 }
 706
 707 #k# Toggle abbreviation expansion on/off
 708 zle -N grml_toggle_abbrev
 709 bindkey '^xA' grml_toggle_abbrev
 710
 711 # add a command line to the shells history without executing it
 712 commit-to-history() {
 713     print -s ${(z)BUFFER}
 714     zle send-break
 715 }
 716 zle -N commit-to-history
 717 bindkey "^x^h" commit-to-history
 718
 719 # only slash should be considered as a word separator:
 720 slash-backward-kill-word() {
 721     local WORDCHARS="${WORDCHARS:s@/@}"
 722     # zle backward-word
 723     zle backward-kill-word
 724 }
 725 zle -N slash-backward-kill-word
 726
 727 #k# Kill left-side word or everything up to next slash
 728 bindkey '\ev' slash-backward-kill-word
 729 #k# Kill left-side word or everything up to next slash
 730 bindkey '\e^h' slash-backward-kill-word
 731 #k# Kill left-side word or everything up to next slash
 732 bindkey '\e^?' slash-backward-kill-word
 733
 734 # use the new *-pattern-* widgets for incremental history search
 735 if is439 ; then
 736     bindkey '^r' history-incremental-pattern-search-backward
 737     bindkey '^s' history-incremental-pattern-search-forward
 738 fi
 739
 740 # a generic accept-line wrapper
 741
 742 # This widget can prevent unwanted autocorrections from command-name
 743 # to _command-name, rehash automatically on enter and call any number
 744 # of builtin and user-defined widgets in different contexts.
 745 #
 746 # For a broader description, see:
 747 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 748 #
 749 # The code is imported from the file 'zsh/functions/accept-line' from
 750 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 751 # distributed under the same terms as zsh itself.
 752
 753 # A newly added command will may not be found or will cause false
 754 # correction attempts, if you got auto-correction set. By setting the
 755 # following style, we force accept-line() to rehash, if it cannot
 756 # find the first word on the command line in the $command[] hash.
 757 zstyle ':acceptline:*' rehash true
 758
 759 function Accept-Line() {
 760     setopt localoptions noksharrays
 761     local -a subs
 762     local -xi aldone
 763     local sub
 764     local alcontext=${1:-$alcontext}
 765
 766     zstyle -a ":acceptline:${alcontext}" actions subs
 767
 768     (( ${#subs} < 1 )) && return 0
 769
 770     (( aldone = 0 ))
 771     for sub in ${subs} ; do
 772         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 773         zle ${sub}
 774
 775         (( aldone > 0 )) && break
 776     done
 777 }
 778
 779 function Accept-Line-getdefault() {
 780     emulate -L zsh
 781     local default_action
 782
 783     zstyle -s ":acceptline:${alcontext}" default_action default_action
 784     case ${default_action} in
 785         ((accept-line|))
 786             printf ".accept-line"
 787             ;;
 788         (*)
 789             printf ${default_action}
 790             ;;
 791     esac
 792 }
 793
 794 function Accept-Line-HandleContext() {
 795     zle Accept-Line
 796
 797     default_action=$(Accept-Line-getdefault)
 798     zstyle -T ":acceptline:${alcontext}" call_default \
 799         && zle ${default_action}
 800 }
 801
 802 function accept-line() {
 803     setopt localoptions noksharrays
 804     local -ax cmdline
 805     local -x alcontext
 806     local buf com fname format msg default_action
 807
 808     alcontext='default'
 809     buf="${BUFFER}"
 810     cmdline=(${(z)BUFFER})
 811     com="${cmdline[1]}"
 812     fname="_${com}"
 813
 814     Accept-Line 'preprocess'
 815
 816     zstyle -t ":acceptline:${alcontext}" rehash \
 817         && [[ -z ${commands[$com]} ]]           \
 818         && rehash
 819
 820     if    [[ -n ${com}               ]] \
 821        && [[ -n ${reswords[(r)$com]} ]] \
 822        || [[ -n ${aliases[$com]}     ]] \
 823        || [[ -n ${functions[$com]}   ]] \
 824        || [[ -n ${builtins[$com]}    ]] \
 825        || [[ -n ${commands[$com]}    ]] ; then
 826
 827         # there is something sensible to execute, just do it.
 828         alcontext='normal'
 829         Accept-Line-HandleContext
 830
 831         return
 832     fi
 833
 834     if    [[ -o correct              ]] \
 835        || [[ -o correctall           ]] \
 836        && [[ -n ${functions[$fname]} ]] ; then
 837
 838         # nothing there to execute but there is a function called
 839         # _command_name; a completion widget. Makes no sense to
 840         # call it on the commandline, but the correct{,all} options
 841         # will ask for it nevertheless, so warn the user.
 842         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 843             # Okay, we warned the user before, he called us again,
 844             # so have it his way.
 845             alcontext='force'
 846             Accept-Line-HandleContext
 847
 848             return
 849         fi
 850
 851         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 852             alcontext='normal'
 853             Accept-Line-HandleContext
 854         else
 855             # prepare warning message for the user, configurable via zstyle.
 856             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 857
 858             if [[ -z ${msg} ]] ; then
 859                 msg="%c will not execute and completion %f exists."
 860             fi
 861
 862             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 863
 864             zle -M -- "${msg}"
 865         fi
 866         return
 867     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 868         # If we are here, the commandline contains something that is not
 869         # executable, which is neither subject to _command_name correction
 870         # and is not empty. might be a variable assignment
 871         alcontext='misc'
 872         Accept-Line-HandleContext
 873
 874         return
 875     fi
 876
 877     # If we got this far, the commandline only contains whitespace, or is empty.
 878     alcontext='empty'
 879     Accept-Line-HandleContext
 880 }
 881
 882 zle -N accept-line
 883 zle -N Accept-Line
 884 zle -N Accept-Line-HandleContext
 885
 886 # power completion - abbreviation expansion
 887 # power completion / abbreviation expansion / buffer expansion
 888 # see http://zshwiki.org/home/examples/zleiab for details
 889 # less risky than the global aliases but powerful as well
 890 # just type the abbreviation key and afterwards ',.' to expand it
 891 declare -A abk
 892 setopt extendedglob
 893 setopt interactivecomments
 894 abk=(
 895 #   key   # value                  (#d additional doc string)
 896 #A# start
 897     '...'  '../..'
 898     '....' '../../..'
 899     'BG'   '& exit'
 900     'C'    '| wc -l'
 901     'G'    '|& grep '${grep_options:+"${grep_options[*]} "}
 902     'H'    '| head'
 903     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 904     'L'    '| less'
 905     'LL'   '|& less -r'
 906     'M'    '| most'
 907     'N'    '&>/dev/null'           #d (No Output)
 908     'R'    '| tr A-z N-za-m'       #d (ROT13)
 909     'SL'   '| sort | less'
 910     'S'    '| sort -u'
 911     'T'    '| tail'
 912     'V'    '|& vim -'
 913 #A# end
 914     'co'   './configure && make && sudo make install'
 915 )
 916
 917 zleiab() {
 918     emulate -L zsh
 919     setopt extendedglob
 920     local MATCH
 921
 922     if (( NOABBREVIATION > 0 )) ; then
 923         LBUFFER="${LBUFFER},."
 924         return 0
 925     fi
 926
 927     matched_chars='[.-|_a-zA-Z0-9]#'
 928     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 929     LBUFFER+=${abk[$MATCH]:-$MATCH}
 930 }
 931
 932 zle -N zleiab && bindkey ",." zleiab
 933
 934 #f# display contents of assoc array $abk
 935 help-show-abk()
 936 {
 937   zle -M "$(print "Type ,. after these abbreviations to expand them:"; print -a -C 2 ${(kv)abk})"
 938 }
 939 #k# Display list of abbreviations that expand when followed by ,.
 940 zle -N help-show-abk && bindkey '^xb' help-show-abk
 941
 942 # autoloading
 943 zrcautoload zmv    # who needs mmv or rename?
 944 zrcautoload history-search-end
 945
 946 # we don't want to quote/espace URLs on our own...
 947 # if autoload -U url-quote-magic ; then
 948 #    zle -N self-insert url-quote-magic
 949 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 950 # else
 951 #    print 'Notice: no url-quote-magic available :('
 952 # fi
 953 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 954
 955 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 956 alias run-help >&/dev/null && unalias run-help
 957 for rh in run-help{,-git,-svk,-svn}; do
 958     zrcautoload $rh
 959 done; unset rh
 960
 961 # completion system
 962 if zrcautoload compinit ; then
 963     compinit || print 'Notice: no compinit available :('
 964 else
 965     print 'Notice: no compinit available :('
 966     function zstyle { }
 967     function compdef { }
 968 fi
 969
 970 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 971
 972 is4 && \
 973 for mod in complist deltochar mathfunc ; do
 974     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 975 done
 976
 977 # autoload zsh modules when they are referenced
 978 if is4 ; then
 979     zmodload -a  zsh/stat    zstat
 980     zmodload -a  zsh/zpty    zpty
 981     zmodload -ap zsh/mapfile mapfile
 982 fi
 983
 984 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 985     #k# Insert files and test globbing
 986     bindkey "^xf" insert-files # C-x-f
 987 fi
 988
 989 bindkey ' '   magic-space    # also do history expansion on space
 990 #k# Trigger menu-complete
 991 bindkey '\ei' menu-complete  # menu completion via esc-i
 992
 993 # press esc-e for editing command line in $EDITOR or $VISUAL
 994 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 995     #k# Edit the current line in \kbd{\$EDITOR}
 996     bindkey '\ee' edit-command-line
 997 fi
 998
 999 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
1000     #k# menu selection: pick item but stay in the menu
1001     bindkey -M menuselect '\e^M' accept-and-menu-complete
1002     # also use + and INSERT since it's easier to press repeatedly
1003     bindkey -M menuselect "+" accept-and-menu-complete
1004     bindkey -M menuselect "^[[2~" accept-and-menu-complete
1005
1006     # accept a completion and try to complete again by using menu
1007     # completion; very useful with completing directories
1008     # by using 'undo' one's got a simple file browser
1009     bindkey -M menuselect '^o' accept-and-infer-next-history
1010 fi
1011
1012 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1013 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1014 zle -N insert-datestamp
1015
1016 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1017 bindkey '^ed' insert-datestamp
1018
1019 # press esc-m for inserting last typed word again (thanks to caphuso!)
1020 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1021 zle -N insert-last-typed-word;
1022
1023 #k# Insert last typed word
1024 bindkey "\em" insert-last-typed-word
1025
1026 function grml-zsh-fg() {
1027   if (( ${#jobstates} )); then
1028     zle .push-input
1029     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1030     BUFFER="${BUFFER}fg"
1031     zle .accept-line
1032   else
1033     zle -M 'No background jobs. Doing nothing.'
1034   fi
1035 }
1036 zle -N grml-zsh-fg
1037 #k# A smart shortcut for \kbd{fg<enter>}
1038 bindkey '^z' grml-zsh-fg
1039
1040 # run command line as user root via sudo:
1041 sudo-command-line() {
1042     [[ -z $BUFFER ]] && zle up-history
1043     if [[ $BUFFER != sudo\ * ]]; then
1044         BUFFER="sudo $BUFFER"
1045         CURSOR=$(( CURSOR+5 ))
1046     fi
1047 }
1048 zle -N sudo-command-line
1049
1050 #k# prepend the current command with "sudo"
1051 bindkey "^os" sudo-command-line
1052
1053 ### jump behind the first word on the cmdline.
1054 ### useful to add options.
1055 function jump_after_first_word() {
1056     local words
1057     words=(${(z)BUFFER})
1058
1059     if (( ${#words} <= 1 )) ; then
1060         CURSOR=${#BUFFER}
1061     else
1062         CURSOR=${#${words[1]}}
1063     fi
1064 }
1065 zle -N jump_after_first_word
1066 #k# jump to after first word (for adding options)
1067 bindkey '^x1' jump_after_first_word
1068
1069 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1070 zle -C hist-complete complete-word _generic
1071 zstyle ':completion:hist-complete:*' completer _history
1072 #k# complete word from history with menu
1073 bindkey "^x^x" hist-complete
1074
1075 ## complete word from currently visible Screen or Tmux buffer.
1076 if check_com -c screen || check_com -c tmux; then
1077     _complete_screen_display() {
1078         [[ "$TERM" != "screen" ]] && return 1
1079
1080         local TMPFILE=$(mktemp)
1081         local -U -a _screen_display_wordlist
1082         trap "rm -f $TMPFILE" EXIT
1083
1084         # fill array with contents from screen hardcopy
1085         if ((${+TMUX})); then
1086             #works, but crashes tmux below version 1.4
1087             #luckily tmux -V option to ask for version, was also added in 1.4
1088             tmux -V &>/dev/null || return
1089             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1090         else
1091             screen -X hardcopy $TMPFILE
1092             # screen sucks, it dumps in latin1, apparently always. so recode it
1093             # to system charset
1094             check_com recode && recode latin1 $TMPFILE
1095         fi
1096         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1097         # remove PREFIX to be completed from that array
1098         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1099         compadd -a _screen_display_wordlist
1100     }
1101     #k# complete word from currently visible GNU screen buffer
1102     bindkey -r "^xS"
1103     compdef -k _complete_screen_display complete-word '^xS'
1104 fi
1105
1106 # history
1107
1108 ZSHDIR=$HOME/.zsh
1109
1110 #v#
1111 HISTFILE=$HOME/.zsh_history
1112 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1113 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1114
1115 # dirstack handling
1116
1117 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1118 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1119
1120 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1121     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1122     # "cd -" won't work after login by just setting $OLDPWD, so
1123     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1124 fi
1125
1126 chpwd() {
1127     local -ax my_stack
1128     my_stack=( ${PWD} ${dirstack} )
1129     if is42 ; then
1130         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1131     else
1132         uprint my_stack >! ${DIRSTACKFILE}
1133     fi
1134 }
1135
1136 # directory based profiles
1137
1138 if is433 ; then
1139
1140 # chpwd_profiles(): Directory Profiles
1141 #
1142 # Say you want certain settings to be active in certain directories. This is
1143 # what you want.
1144 #
1145 # To get it working you will need this function and something along the
1146 # following lines:
1147 #
1148 #   chpwd_functions+=( chpwd_profiles )
1149 #   chpwd_profiles
1150 #
1151 # You will usually want to do that *after* you configured the system. That
1152 # configuration is described below.
1153 #
1154 # zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1155 # zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1156 #
1157 # When that's done and you enter a directory that matches the pattern in the
1158 # third part of the context, a function called chpwd_profile_grml, for example,
1159 # is called (if it exists).
1160 #
1161 # If no pattern patches (read: no profile is detected) the profile is set to
1162 # 'default', which means chpwd_profile_default is attempted to be called.
1163 #
1164 # A word about the context (the ':chpwd:profiles:*' stuff in the zstyle
1165 # command) which is used: The third part in the context is matched against
1166 # ${PWD}. That's why using a pattern such as /foo/bar(|/|/*) makes sense.
1167 # Because that way the profile is detected for all these values of ${PWD}:
1168 #   /foo/bar
1169 #   /foo/bar/
1170 #   /foo/bar/baz
1171 # So, if you want to make double damn sure a profile works in /foo/bar and
1172 # everywhere deeper in that tree, just use (|/|/*) and be happy.
1173 #
1174 # The name of the detected profile will be available in a variable called
1175 # 'profile' in your functions. You don't need to do anything, it'll just be
1176 # there.
1177 #
1178 # Then there is the parameter $CHPWD_PROFILE is set to the profile, that was is
1179 # currently active (the default value is "default"). That way you can avoid
1180 # running code for a profile that is already active, by running code such as
1181 # the following at the start of your function:
1182 #
1183 # function chpwd_profile_grml() {
1184 #     [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1185 #   ...
1186 # }
1187 #
1188 # If you know you are going to do that all the time for each and every
1189 # directory-profile function you are ever going to write, you may also set the
1190 # `re-execute' style to `false' (which only defaults to `true' for backwards
1191 # compatibility), like this:
1192 #
1193 #   zstyle ':chpwd:profiles:*' re-execute false
1194 #
1195 # If you use this feature and need to know whether it is active in your current
1196 # shell, there are several ways to do that. Here are two simple ways:
1197 #
1198 # a) If knowing if the profiles feature is active when zsh starts is good
1199 #    enough for you, you can use the following snippet:
1200 #
1201 # (( ${+functions[chpwd_profiles]} )) && print "directory profiles active"
1202 #
1203 # b) If that is not good enough, and you would prefer to be notified whenever a
1204 #    profile changes, you can solve that by making sure you start *every*
1205 #    profile function you create like this:
1206 #
1207 # function chpwd_profile_myprofilename() {
1208 #     [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1209 #     print "chpwd(): Switching to profile: $profile"
1210 #   ...
1211 # }
1212 #
1213 # That makes sure you only get notified if a profile is *changed*, not
1214 # everytime you change directory. (To avoid this, you may also set the newer
1215 # `re-execute' style like described further above instead of the test on top of
1216 # the function.
1217 #
1218 # If you need to do initialisations the first time `chpwd_profiles' is called
1219 # (which should be in your configuration file), you can do that in a function
1220 # called "chpwd_profiles_init". That function needs to be defined *before*
1221 # `chpwd_profiles' is called for this to work.
1222 #
1223 # During the *first* call of `chpwd_profiles' (and therefore all its profile
1224 # functions) the parameter `$CHPWD_PROFILES_INIT' exists and is set to `1'. In
1225 # all other cases, the parameter does not exist at all.
1226 #
1227 # When the system switches from one profile to another, it executes a function
1228 # named "chpwd_leave_profile_<PREVIOUS-PROFILE-NAME>()" before calling the
1229 # profile-function for the new profile.
1230 #
1231 # There you go. Now have fun with that.
1232 #
1233 # Note: This feature requires zsh 4.3.3 or newer.
1234 function chpwd_profiles() {
1235     local profile context
1236     local -i reexecute
1237
1238     context=":chpwd:profiles:$PWD"
1239     zstyle -s "$context" profile profile || profile='default'
1240     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1241
1242     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1243         typeset -g CHPWD_PROFILE
1244         local CHPWD_PROFILES_INIT=1
1245         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1246     elif [[ $profile != $CHPWD_PROFILE ]]; then
1247         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1248             && chpwd_leave_profile_${CHPWD_PROFILE}
1249     fi
1250     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1251         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1252     fi
1253
1254     CHPWD_PROFILE="${profile}"
1255     return 0
1256 }
1257
1258 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1259
1260 fi # is433
1261
1262 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1263 if [[ $BATTERY -gt 0 ]] ; then
1264     if ! check_com -c acpi ; then
1265         BATTERY=0
1266     fi
1267 fi
1268
1269 battery() {
1270 if [[ $BATTERY -gt 0 ]] ; then
1271     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1272     if [[ -z "$PERCENT" ]] ; then
1273         PERCENT='acpi not present'
1274     else
1275         if [[ "$PERCENT" -lt 20 ]] ; then
1276             PERCENT="warning: ${PERCENT}%%"
1277         else
1278             PERCENT="${PERCENT}%%"
1279         fi
1280     fi
1281 fi
1282 }
1283 # set colors for use in prompts
1284 if zrcautoload colors && colors 2>/dev/null ; then
1285     BLUE="%{${fg[blue]}%}"
1286     RED="%{${fg_bold[red]}%}"
1287     GREEN="%{${fg[green]}%}"
1288     CYAN="%{${fg[cyan]}%}"
1289     MAGENTA="%{${fg[magenta]}%}"
1290     YELLOW="%{${fg[yellow]}%}"
1291     WHITE="%{${fg[white]}%}"
1292     NO_COLOUR="%{${reset_color}%}"
1293 else
1294     BLUE=$'%{\e[1;34m%}'
1295     RED=$'%{\e[1;31m%}'
1296     GREEN=$'%{\e[1;32m%}'
1297     CYAN=$'%{\e[1;36m%}'
1298     WHITE=$'%{\e[1;37m%}'
1299     MAGENTA=$'%{\e[1;35m%}'
1300     YELLOW=$'%{\e[1;33m%}'
1301     NO_COLOUR=$'%{\e[0m%}'
1302 fi
1303
1304 # gather version control information for inclusion in a prompt
1305
1306 if zrcautoload vcs_info; then
1307     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1308     # function, which can cause a lot of trouble with our directory-based
1309     # profiles. So:
1310     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1311         function VCS_INFO_realpath () {
1312             setopt localoptions NO_shwordsplit chaselinks
1313             ( builtin cd -q $1 2> /dev/null && pwd; )
1314         }
1315     fi
1316
1317     zstyle ':vcs_info:*' max-exports 2
1318
1319     if [[ -o restricted ]]; then
1320         zstyle ':vcs_info:*' enable NONE
1321     fi
1322 fi
1323
1324 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1325 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1326 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1327 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1328 #       to $vcs_info_msg_N_ as soon as we use the included version.
1329 if [[ "$TERM" == dumb ]] ; then
1330     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1331     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1332 else
1333     # these are the same, just with a lot of colours:
1334     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
1335                                        "zsh: %r"
1336     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
1337                                        "zsh: %r"
1338     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1339 fi
1340
1341 # command not found handling
1342
1343 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1344 function command_not_found_handler() {
1345     emulate -L zsh
1346     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1347         ${GRML_ZSH_CNF_HANDLER} $1
1348     fi
1349     return 1
1350 }
1351
1352 # set prompt
1353 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1354     promptinit # people should be able to use their favourite prompt
1355 else
1356     print 'Notice: no promptinit available :('
1357 fi
1358
1359 setopt prompt_subst
1360
1361 # make sure to use right prompt only when not running a command
1362 is41 && setopt transient_rprompt
1363
1364
1365 function ESC_print () {
1366     info_print $'\ek' $'\e\\' "$@"
1367 }
1368 function set_title () {
1369     info_print  $'\e]0;' $'\a' "$@"
1370 }
1371
1372 function info_print () {
1373     local esc_begin esc_end
1374     esc_begin="$1"
1375     esc_end="$2"
1376     shift 2
1377     printf '%s' ${esc_begin}
1378     printf '%s' "$*"
1379     printf '%s' "${esc_end}"
1380 }
1381
1382 # TODO: revise all these NO* variables and especially their documentation
1383 #       in zsh-help() below.
1384 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1385     [[ $NOPRECMD -gt 0 ]] && return 0
1386     # update VCS information
1387     (( ${+functions[vcs_info]} )) && vcs_info
1388
1389     if [[ $TERM == screen* ]] ; then
1390         if [[ -n ${vcs_info_msg_1_} ]] ; then
1391             ESC_print ${vcs_info_msg_1_}
1392         else
1393             ESC_print "zsh"
1394         fi
1395     fi
1396     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1397     if [[ ${DONTSETRPROMPT:-} -eq 0 ]] ; then
1398         if [[ $BATTERY -gt 0 ]] ; then
1399             # update battery (dropped into $PERCENT) information
1400             battery
1401             RPROMPT="%(?..:() ${PERCENT}"
1402         else
1403             RPROMPT="%(?..:() "
1404         fi
1405     fi
1406     # adjust title of xterm
1407     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1408     [[ ${NOTITLE:-} -gt 0 ]] && return 0
1409     case $TERM in
1410         (xterm*|rxvt*)
1411             set_title ${(%):-"%n@%m: %~"}
1412             ;;
1413     esac
1414 }
1415
1416 # preexec() => a function running before every command
1417 is4 && [[ $NOPRECMD -eq 0 ]] && \
1418 preexec () {
1419     [[ $NOPRECMD -gt 0 ]] && return 0
1420 # set hostname if not running on host with name 'grml'
1421     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1422        NAME="@$HOSTNAME"
1423     fi
1424 # get the name of the program currently running and hostname of local machine
1425 # set screen window title if running in a screen
1426     if [[ "$TERM" == screen* ]] ; then
1427         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1428         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1429         ESC_print ${CMD}
1430     fi
1431 # adjust title of xterm
1432     [[ ${NOTITLE} -gt 0 ]] && return 0
1433     case $TERM in
1434         (xterm*|rxvt*)
1435             set_title "${(%):-"%n@%m:"}" "$1"
1436             ;;
1437     esac
1438 }
1439
1440 EXITCODE="%(?..%?%1v )"
1441 # secondary prompt, printed when the shell needs more information to complete a
1442 # command.
1443 PS2='\`%_> '
1444 # selection prompt used within a select loop.
1445 PS3='?# '
1446 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1447 PS4='+%N:%i:%_> '
1448
1449 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1450 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1451     debian_chroot=$(cat /etc/debian_chroot)
1452 fi
1453
1454 # don't use colors on dumb terminals (like emacs):
1455 if [[ "$TERM" == dumb ]] ; then
1456     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
1457 else
1458     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended
1459     # prompt set variable identifying the chroot you work in (used in the
1460     # prompt below)
1461     if [[ $GRMLPROMPT -gt 0 ]] ; then
1462         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1463 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1464     else
1465         # This assembles the primary prompt string
1466         if (( EUID != 0 )); then
1467             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1468         else
1469             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1470         fi
1471     fi
1472 fi
1473
1474 PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
1475
1476 # if we are inside a grml-chroot set a specific prompt theme
1477 if [[ -n "$GRML_CHROOT" ]] ; then
1478     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1479 fi
1480
1481 # 'hash' some often used directories
1482 #d# start
1483 hash -d deb=/var/cache/apt/archives
1484 hash -d doc=/usr/share/doc
1485 hash -d linux=/lib/modules/$(command uname -r)/build/
1486 hash -d log=/var/log
1487 hash -d slog=/var/log/syslog
1488 hash -d src=/usr/src
1489 hash -d templ=/usr/share/doc/grml-templates
1490 hash -d tt=/usr/share/doc/texttools-doc
1491 hash -d www=/var/www
1492 #d# end
1493
1494 # some aliases
1495 if check_com -c screen ; then
1496     if [[ $UID -eq 0 ]] ; then
1497         if [[ -r /etc/grml/screenrc ]]; then
1498             alias screen="${commands[screen]} -c /etc/grml/screenrc"
1499         fi
1500     elif [[ -r $HOME/.screenrc ]] ; then
1501         alias screen="${commands[screen]} -c $HOME/.screenrc"
1502     else
1503         if [[ -r /etc/grml/screenrc_grml ]]; then
1504             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1505         else
1506             if [[ -r /etc/grml/screenrc ]]; then
1507                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
1508             fi
1509         fi
1510     fi
1511 fi
1512
1513 # do we have GNU ls with color-support?
1514 if [[ "$TERM" != dumb ]]; then
1515     #a1# execute \kbd{@a@}:\quad ls with colors
1516     alias ls='ls -b -CF '${ls_options:+"${ls_options[*]} "}
1517     #a1# execute \kbd{@a@}:\quad list all files, with colors
1518     alias la='ls -la '${ls_options:+"${ls_options[*]} "}
1519     #a1# long colored list, without dotfiles (@a@)
1520     alias ll='ls -l '${ls_options:+"${ls_options[*]} "}
1521     #a1# long colored list, human readable sizes (@a@)
1522     alias lh='ls -hAl '${ls_options:+"${ls_options[*]} "}
1523     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1524     alias l='ls -lF '${ls_options:+"${ls_options[*]} "}
1525 else
1526     alias ls='ls -b -CF'
1527     alias la='ls -la'
1528     alias ll='ls -l'
1529     alias lh='ls -hAl'
1530     alias l='ls -lF'
1531 fi
1532
1533 alias mdstat='cat /proc/mdstat'
1534 alias ...='cd ../../'
1535
1536 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1537 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1538     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1539 fi
1540
1541 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1542 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1543 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1544
1545 # make sure it is not assigned yet
1546 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1547 utf2iso() {
1548     if isutfenv ; then
1549         for ENV in $(env | command grep -i '.utf') ; do
1550             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1551         done
1552     fi
1553 }
1554
1555 # make sure it is not assigned yet
1556 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1557 iso2utf() {
1558     if ! isutfenv ; then
1559         for ENV in $(env | command grep -i '\.iso') ; do
1560             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1561         done
1562     fi
1563 }
1564
1565 # especially for roadwarriors using GNU screen and ssh:
1566 if ! check_com asc &>/dev/null ; then
1567   asc() { autossh -t "$@" 'screen -RdU' }
1568   compdef asc=ssh
1569 fi
1570
1571 #f1# Hints for the use of zsh on grml
1572 zsh-help() {
1573     print "$bg[white]$fg[black]
1574 zsh-help - hints for use of zsh on grml
1575 =======================================$reset_color"
1576
1577     print '
1578 Main configuration of zsh happens in /etc/zsh/zshrc.
1579 That file is part of the package grml-etc-core, if you want to
1580 use them on a non-grml-system just get the tar.gz from
1581 http://deb.grml.org/ or (preferably) get it from the git repository:
1582
1583   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1584
1585 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1586 The file is still there, but it is empty for backwards compatibility.
1587
1588 For your own changes use these two files:
1589     $HOME/.zshrc.pre
1590     $HOME/.zshrc.local
1591
1592 The former is sourced very early in our zshrc, the latter is sourced
1593 very lately.
1594
1595 System wide configuration without touching configuration files of grml
1596 can take place in /etc/zsh/zshrc.local.
1597
1598 For information regarding zsh start at http://grml.org/zsh/
1599
1600 Take a look at grml'\''s zsh refcard:
1601 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1602
1603 Check out the main zsh refcard:
1604 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1605
1606 And of course visit the zsh-lovers:
1607 % man zsh-lovers
1608
1609 You can adjust some options through environment variables when
1610 invoking zsh without having to edit configuration files.
1611 Basically meant for bash users who are not used to the power of
1612 the zsh yet. :)
1613
1614   "NOCOR=1    zsh" => deactivate automatic correction
1615   "NOMENU=1   zsh" => do not use auto menu completion
1616                       (note: use ctrl-d for completion instead!)
1617   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1618   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1619                       preexec() and precmd() completely
1620   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1621   "COMMAND_NOT_FOUND=1 zsh"
1622                    => Enable a handler if an external command was not found
1623                       The command called in the handler can be altered by setting
1624                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1625                       "/usr/share/command-not-found/command-not-found"
1626
1627 A value greater than 0 is enables a feature; a value equal to zero
1628 disables it. If you like one or the other of these settings, you can
1629 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1630 zshrc.'
1631
1632     print "
1633 $bg[white]$fg[black]
1634 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1635 Enjoy your grml system with the zsh!$reset_color"
1636 }
1637
1638 # debian stuff
1639 if [[ -r /etc/debian_version ]] ; then
1640     #a3# Execute \kbd{apt-cache search}
1641     alias acs='apt-cache search'
1642     #a3# Execute \kbd{apt-cache show}
1643     alias acsh='apt-cache show'
1644     #a3# Execute \kbd{apt-cache policy}
1645     alias acp='apt-cache policy'
1646     #a3# Execute \kbd{apt-get dist-upgrade}
1647     salias adg="apt-get dist-upgrade"
1648     #a3# Execute \kbd{apt-get install}
1649     salias agi="apt-get install"
1650     #a3# Execute \kbd{aptitude install}
1651     salias ati="aptitude install"
1652     #a3# Execute \kbd{apt-get upgrade}
1653     salias ag="apt-get upgrade"
1654     #a3# Execute \kbd{apt-get update}
1655     salias au="apt-get update"
1656     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1657     salias -a up="aptitude update ; aptitude safe-upgrade"
1658     #a3# Execute \kbd{dpkg-buildpackage}
1659     alias dbp='dpkg-buildpackage'
1660     #a3# Execute \kbd{grep-excuses}
1661     alias ge='grep-excuses'
1662
1663     # get a root shell as normal user in live-cd mode:
1664     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1665        alias su="sudo su"
1666      fi
1667
1668     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1669     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1670     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1671     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1672 fi
1673
1674 # sort installed Debian-packages by size
1675 if check_com -c dpkg-query ; then
1676     #a3# List installed Debian-packages sorted by size
1677     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1678 fi
1679
1680 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1681 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1682     if check_com -c wodim; then
1683         cdrecord() {
1684             cat <<EOMESS
1685 cdrecord is not provided under its original name by Debian anymore.
1686 See #377109 in the BTS of Debian for more details.
1687
1688 Please use the wodim binary instead
1689 EOMESS
1690             return 1
1691         }
1692     fi
1693 fi
1694
1695 # Use hard limits, except for a smaller stack and no core dumps
1696 unlimit
1697 is425 && limit stack 8192
1698 isgrmlcd && limit core 0 # important for a live-cd-system
1699 limit -s
1700
1701 # completion system
1702
1703 # called later (via is4 && grmlcomp)
1704 # note: use 'zstyle' for getting current settings
1705 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
1706 grmlcomp() {
1707     # TODO: This could use some additional information
1708
1709     # allow one error for every three characters typed in approximate completer
1710     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1711
1712     # don't complete backup files as executables
1713     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1714
1715     # start menu completion only if it could find no unambiguous initial string
1716     zstyle ':completion:*:correct:*'       insert-unambiguous true
1717     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1718     zstyle ':completion:*:correct:*'       original true
1719
1720     # activate color-completion
1721     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1722
1723     # format on completion
1724     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1725
1726     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1727     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1728
1729     # insert all expansions for expand completer
1730     zstyle ':completion:*:expand:*'        tag-order all-expansions
1731     zstyle ':completion:*:history-words'   list false
1732
1733     # activate menu
1734     zstyle ':completion:*:history-words'   menu yes
1735
1736     # ignore duplicate entries
1737     zstyle ':completion:*:history-words'   remove-all-dups yes
1738     zstyle ':completion:*:history-words'   stop yes
1739
1740     # match uppercase from lowercase
1741     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1742
1743     # separate matches into groups
1744     zstyle ':completion:*:matches'         group 'yes'
1745     zstyle ':completion:*'                 group-name ''
1746
1747     if [[ "$NOMENU" -eq 0 ]] ; then
1748         # if there are more than 5 options allow selecting from a menu
1749         zstyle ':completion:*'               menu select=5
1750     else
1751         # don't use any menus at all
1752         setopt no_auto_menu
1753     fi
1754
1755     zstyle ':completion:*:messages'        format '%d'
1756     zstyle ':completion:*:options'         auto-description '%d'
1757
1758     # describe options in full
1759     zstyle ':completion:*:options'         description 'yes'
1760
1761     # on processes completion complete all user processes
1762     zstyle ':completion:*:processes'       command 'ps -au$USER'
1763
1764     # offer indexes before parameters in subscripts
1765     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1766
1767     # provide verbose completion information
1768     zstyle ':completion:*'                 verbose true
1769
1770     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1771     # for commands (read: 1st word in the line) that it will list for the user
1772     # to choose from. The following disables that, because it's not exactly fast.
1773     zstyle ':completion:*:-command-:*:'    verbose false
1774
1775     # set format for warnings
1776     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1777
1778     # define files to ignore for zcompile
1779     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1780     zstyle ':completion:correct:'          prompt 'correct to: %e'
1781
1782     # Ignore completion functions for commands you don't have:
1783     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1784
1785     # Provide more processes in completion of programs like killall:
1786     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1787
1788     # complete manual by their section
1789     zstyle ':completion:*:manuals'    separate-sections true
1790     zstyle ':completion:*:manuals.*'  insert-sections   true
1791     zstyle ':completion:*:man:*'      menu yes select
1792
1793     # provide .. as a completion
1794     zstyle ':completion:*' special-dirs ..
1795
1796     # run rehash on completion so new installed program are found automatically:
1797     _force_rehash() {
1798         (( CURRENT == 1 )) && rehash
1799         return 1
1800     }
1801
1802     ## correction
1803     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1804     if [[ "$NOCOR" -gt 0 ]] ; then
1805         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1806         setopt nocorrect
1807     else
1808         # try to be smart about when to use what completer...
1809         setopt correct
1810         zstyle -e ':completion:*' completer '
1811             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1812                 _last_try="$HISTNO$BUFFER$CURSOR"
1813                 reply=(_complete _match _ignored _prefix _files)
1814             else
1815                 if [[ $words[1] == (rm|mv) ]] ; then
1816                     reply=(_complete _files)
1817                 else
1818                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1819                 fi
1820             fi'
1821     fi
1822
1823     # command for process lists, the local web server details and host completion
1824     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1825
1826     # caching
1827     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1828                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1829
1830     # host completion
1831     if is42 ; then
1832         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1833         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1834     else
1835         _ssh_hosts=()
1836         _etc_hosts=()
1837     fi
1838     hosts=(
1839         $(hostname)
1840         "$_ssh_hosts[@]"
1841         "$_etc_hosts[@]"
1842         grml.org
1843         localhost
1844     )
1845     zstyle ':completion:*:hosts' hosts $hosts
1846     # TODO: so, why is this here?
1847     #  zstyle '*' hosts $hosts
1848
1849     # use generic completion system for programs not yet defined; (_gnu_generic works
1850     # with commands that provide a --help option with "standard" gnu-like output.)
1851     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
1852                    pal stow tail uname ; do
1853         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
1854     done; unset compcom
1855
1856     # see upgrade function in this file
1857     compdef _hosts upgrade
1858 }
1859
1860 # grmlstuff
1861 grmlstuff() {
1862 # people should use 'grml-x'!
1863     if check_com -c 915resolution; then
1864         855resolution() {
1865             echo "Please use 915resolution as resolution modifying tool for Intel \
1866 graphic chipset."
1867             return -1
1868         }
1869     fi
1870
1871     #a1# Output version of running grml
1872     alias grml-version='cat /etc/grml_version'
1873
1874     if check_com -c rebuildfstab ; then
1875         #a1# Rebuild /etc/fstab
1876         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1877     fi
1878
1879     if check_com -c grml-debootstrap ; then
1880         debian2hd() {
1881             echo "Installing debian to harddisk is possible by using grml-debootstrap."
1882             return 1
1883         }
1884     fi
1885 }
1886
1887 # now run the functions
1888 isgrml && checkhome
1889 is4    && isgrml    && grmlstuff
1890 is4    && grmlcomp
1891
1892 # keephack
1893 is4 && xsource "/etc/zsh/keephack"
1894
1895 # wonderful idea of using "e" glob qualifier by Peter Stephenson
1896 # You use it as follows:
1897 # $ NTREF=/reference/file
1898 # $ ls -l *(e:nt:)
1899 # This lists all the files in the current directory newer than the reference file.
1900 # You can also specify the reference file inline; note quotes:
1901 # $ ls -l *(e:'nt ~/.zshenv':)
1902 is4 && nt() {
1903     if [[ -n $1 ]] ; then
1904         local NTREF=${~1}
1905     fi
1906     [[ $REPLY -nt $NTREF ]]
1907 }
1908
1909 # shell functions
1910
1911 #f1# Reload an autoloadable function
1912 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1913 compdef _functions freload
1914
1915 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1916 sll() {
1917     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1918     for file in "$@" ; do
1919         while [[ -h "$file" ]] ; do
1920             ls -l $file
1921             file=$(readlink "$file")
1922         done
1923     done
1924 }
1925
1926 # TODO: Is it supported to use pager settings like this?
1927 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
1928 # with respect to wordsplitting. (ie. ${=PAGER})
1929 if check_com -c $PAGER ; then
1930     #f1# View Debian's changelog of a given package
1931     dchange() {
1932         emulate -L zsh
1933         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
1934             $PAGER /usr/share/doc/$1/changelog.Debian.gz
1935         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1936             $PAGER /usr/share/doc/$1/changelog.gz
1937         else
1938             if check_com -c aptitude ; then
1939                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1940                 if isgrml ; then
1941                     aptitude -t unstable changelog $1
1942                 else
1943                     aptitude changelog $1
1944                 fi
1945             else
1946                 echo "No changelog for package $1 found, sorry."
1947                 return 1
1948             fi
1949         fi
1950     }
1951     _dchange() { _files -W /usr/share/doc -/ }
1952     compdef _dchange dchange
1953
1954     #f1# View Debian's NEWS of a given package
1955     dnews() {
1956         emulate -L zsh
1957         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
1958             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
1959         else
1960             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
1961                 $PAGER /usr/share/doc/$1/NEWS.gz
1962             else
1963                 echo "No NEWS file for package $1 found, sorry."
1964                 return 1
1965             fi
1966         fi
1967     }
1968     _dnews() { _files -W /usr/share/doc -/ }
1969     compdef _dnews dnews
1970
1971     #f1# View upstream's changelog of a given package
1972     uchange() {
1973         emulate -L zsh
1974         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1975             $PAGER /usr/share/doc/$1/changelog.gz
1976         else
1977             echo "No changelog for package $1 found, sorry."
1978             return 1
1979         fi
1980     }
1981     _uchange() { _files -W /usr/share/doc -/ }
1982     compdef _uchange uchange
1983 fi
1984
1985 # zsh profiling
1986 profile() {
1987     ZSH_PROFILE_RC=1 $SHELL "$@"
1988 }
1989
1990 #f1# Edit an alias via zle
1991 edalias() {
1992     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1993 }
1994 compdef _aliases edalias
1995
1996 #f1# Edit a function via zle
1997 edfunc() {
1998     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
1999 }
2000 compdef _functions edfunc
2001
2002 # use it e.g. via 'Restart apache2'
2003 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2004 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2005 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2006 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2007 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2008 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2009     __start_stop() {
2010         local action_="${1:l}"  # e.g Start/Stop/Restart
2011         local service_="$2"
2012         local param_="$3"
2013
2014         local service_target_="$(readlink /etc/init.d/$service_)"
2015         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2016             # runit
2017             case "${action_}" in
2018                 start) if [[ ! -e /etc/service/$service_ ]]; then
2019                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2020                        else
2021                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2022                        fi ;;
2023                 # there is no reload in runits sysv emulation
2024                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2025                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2026             esac
2027         else
2028             # sysvinit
2029             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2030         fi
2031     }
2032
2033     _grmlinitd() {
2034         local -a scripts
2035         scripts=( /etc/init.d/*(x:t) )
2036         _describe "service startup script" scripts
2037     }
2038
2039     for i in Start Restart Stop Force-Reload Reload ; do
2040         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2041         compdef _grmlinitd $i
2042     done
2043 fi
2044
2045 #f1# Provides useful information on globbing
2046 H-Glob() {
2047     echo -e "
2048     /      directories
2049     .      plain files
2050     @      symbolic links
2051     =      sockets
2052     p      named pipes (FIFOs)
2053     *      executable plain files (0100)
2054     %      device files (character or block special)
2055     %b     block special files
2056     %c     character special files
2057     r      owner-readable files (0400)
2058     w      owner-writable files (0200)
2059     x      owner-executable files (0100)
2060     A      group-readable files (0040)
2061     I      group-writable files (0020)
2062     E      group-executable files (0010)
2063     R      world-readable files (0004)
2064     W      world-writable files (0002)
2065     X      world-executable files (0001)
2066     s      setuid files (04000)
2067     S      setgid files (02000)
2068     t      files with the sticky bit (01000)
2069
2070   print *(m-1)          # Files modified up to a day ago
2071   print *(a1)           # Files accessed a day ago
2072   print *(@)            # Just symlinks
2073   print *(Lk+50)        # Files bigger than 50 kilobytes
2074   print *(Lk-50)        # Files smaller than 50 kilobytes
2075   print **/*.c          # All *.c files recursively starting in \$PWD
2076   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2077   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2078   print *~*.*           # All Files that do not contain a dot
2079   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2080   print -l *(.c|.h)     # Lists *.c and *.h
2081   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2082   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2083 }
2084 alias help-zshglob=H-Glob
2085
2086 #v1# set number of lines to display per page
2087 HELP_LINES_PER_PAGE=20
2088 #v1# set location of help-zle cache file
2089 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
2090 #f1# helper function for help-zle, actually generates the help text
2091 help_zle_parse_keybindings()
2092 {
2093     emulate -L zsh
2094     setopt extendedglob
2095     unsetopt ksharrays  #indexing starts at 1
2096
2097     #v1# choose files that help-zle will parse for keybindings
2098     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
2099
2100     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
2101         local load_cache=0
2102         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
2103         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
2104     fi
2105
2106     #fill with default keybindings, possibly to be overwriten in a file later
2107     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2108     local -A help_zle_keybindings
2109     help_zle_keybindings['<Ctrl>@']="set MARK"
2110     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
2111     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
2112     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
2113     help_zle_keybindings['<Ctrl>_']="undo"
2114     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
2115     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
2116     help_zle_keybindings['<Ctrl>e']="goto end of line"
2117     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2118     help_zle_keybindings['<Alt>t']="transpose words"
2119     help_zle_keybindings['<Alt>s']="spellcheck word"
2120     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
2121     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
2122     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2123     help_zle_keybindings["<Alt>'"]="quote line"
2124     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2125     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2126     help_zle_keybindings['<Alt>u']="make next word Uppercase"
2127     help_zle_keybindings['<Alt>l']="make next word lowercase"
2128     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
2129     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2130     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2131     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2132     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2133     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
2134     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2135     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2136     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
2137
2138     #init global variables
2139     unset help_zle_lines help_zle_sln
2140     typeset -g -a help_zle_lines
2141     typeset -g help_zle_sln=1
2142
2143     local k v
2144     local lastkeybind_desc contents     #last description starting with #k# that we found
2145     local num_lines_elapsed=0            #number of lines between last description and keybinding
2146     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2147     for f in $HELPZLE_KEYBINDING_FILES; do
2148         [[ -r "$f" ]] || continue   #not readable ? skip it
2149         contents="$(<$f)"
2150         for cline in "${(f)contents}"; do
2151             #zsh pattern: matches lines like: #k# ..............
2152             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2153                 lastkeybind_desc="$match[*]"
2154                 num_lines_elapsed=0
2155             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2156             #             ignores lines that are commentend out
2157             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2158             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2159                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2160                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2161                     #substitute keybinding string with something readable
2162                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2163                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2164                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2165                     help_zle_keybindings[${k}]=$lastkeybind_desc
2166                 fi
2167                 lastkeybind_desc=""
2168             else
2169               ((num_lines_elapsed++))
2170             fi
2171         done
2172     done
2173     unset contents
2174     #calculate length of keybinding column
2175     local kstrlen=0
2176     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2177     #convert the assoc array into preformated lines, which we are able to sort
2178     for k v in ${(kv)help_zle_keybindings[@]}; do
2179         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2180         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2181     done
2182     #sort lines alphabetically
2183     help_zle_lines=("${(i)help_zle_lines[@]}")
2184     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2185     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2186     zcompile $HELP_ZLE_CACHE_FILE
2187 }
2188 typeset -g help_zle_sln
2189 typeset -g -a help_zle_lines
2190
2191 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2192 help-zle()
2193 {
2194     emulate -L zsh
2195     unsetopt ksharrays  #indexing starts at 1
2196     #help lines already generated ? no ? then do it
2197     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2198     #already displayed all lines ? go back to the start
2199     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2200     local sln=$help_zle_sln
2201     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2202     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2203     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2204 }
2205 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2206 zle -N help-zle && bindkey '^xz' help-zle
2207
2208 # grep for running process, like: 'any vim'
2209 any() {
2210     emulate -L zsh
2211     unsetopt KSH_ARRAYS
2212     if [[ -z "$1" ]] ; then
2213         echo "any - grep for process(es) by keyword" >&2
2214         echo "Usage: any <keyword>" >&2 ; return 1
2215     else
2216         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
2217     fi
2218 }
2219
2220
2221 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2222 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2223 [[ -r /proc/1/maps ]] && \
2224 deswap() {
2225     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2226     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2227     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2228 }
2229
2230 # a wrapper for vim, that deals with title setting
2231 #   VIM_OPTIONS
2232 #       set this array to a set of options to vim you always want
2233 #       to have set when calling vim (in .zshrc.local), like:
2234 #           VIM_OPTIONS=( -p )
2235 #       This will cause vim to send every file given on the
2236 #       commandline to be send to it's own tab (needs vim7).
2237 vim() {
2238     VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2239 }
2240
2241 # make a backup of a file
2242 bk() {
2243     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2244 }
2245
2246 ssl_hashes=( sha512 sha256 sha1 md5 )
2247
2248 for sh in ${ssl_hashes}; do
2249     eval 'ssl-cert-'${sh}'() {
2250         emulate -L zsh
2251         if [[ -z $1 ]] ; then
2252             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2253             return 1
2254         fi
2255         openssl x509 -noout -fingerprint -'${sh}' -in $1
2256     }'
2257 done; unset sh
2258
2259 ssl-cert-fingerprints() {
2260     emulate -L zsh
2261     local i
2262     if [[ -z $1 ]] ; then
2263         printf 'usage: ssl-cert-fingerprints <file>\n'
2264         return 1
2265     fi
2266     for i in ${ssl_hashes}
2267         do ssl-cert-$i $1;
2268     done
2269 }
2270
2271 ssl-cert-info() {
2272     emulate -L zsh
2273     if [[ -z $1 ]] ; then
2274         printf 'usage: ssl-cert-info <file>\n'
2275         return 1
2276     fi
2277     openssl x509 -noout -text -in $1
2278     ssl-cert-fingerprints $1
2279 }
2280
2281 # make sure our environment is clean regarding colors
2282 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2283
2284 # "persistent history"
2285 # just write important commands you always need to ~/.important_commands
2286 if [[ -r ~/.important_commands ]] ; then
2287     fc -R ~/.important_commands
2288 fi
2289
2290 # load the lookup subsystem if it's available on the system
2291 zrcautoload lookupinit && lookupinit
2292
2293 # variables
2294
2295 # set terminal property (used e.g. by msgid-chooser)
2296 export COLORTERM="yes"
2297
2298 # aliases
2299
2300 # general
2301 #a2# Execute \kbd{du -sch}
2302 alias da='du -sch'
2303 #a2# Execute \kbd{jobs -l}
2304 alias j='jobs -l'
2305
2306 # listing stuff
2307 #a2# Execute \kbd{ls -lSrah}
2308 alias dir="ls -lSrah"
2309 #a2# Only show dot-directories
2310 alias lad='ls -d .*(/)'
2311 #a2# Only show dot-files
2312 alias lsa='ls -a .*(.)'
2313 #a2# Only files with setgid/setuid/sticky flag
2314 alias lss='ls -l *(s,S,t)'
2315 #a2# Only show symlinks
2316 alias lsl='ls -l *(@)'
2317 #a2# Display only executables
2318 alias lsx='ls -l *(*)'
2319 #a2# Display world-{readable,writable,executable} files
2320 alias lsw='ls -ld *(R,W,X.^ND/)'
2321 #a2# Display the ten biggest files
2322 alias lsbig="ls -flh *(.OL[1,10])"
2323 #a2# Only show directories
2324 alias lsd='ls -d *(/)'
2325 #a2# Only show empty directories
2326 alias lse='ls -d *(/^F)'
2327 #a2# Display the ten newest files
2328 alias lsnew="ls -rtlh *(D.om[1,10])"
2329 #a2# Display the ten oldest files
2330 alias lsold="ls -rtlh *(D.Om[1,10])"
2331 #a2# Display the ten smallest files
2332 alias lssmall="ls -Srl *(.oL[1,10])"
2333 #a2# Display the ten newest directories and ten newest .directories
2334 alias lsnewdir="ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
2335 #a2# Display the ten oldest directories and ten oldest .directories
2336 alias lsolddir="ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
2337
2338 # some useful aliases
2339 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir $OLDCWD}
2340 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2341
2342 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2343 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2344 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2345
2346 # work around non utf8 capable software in utf environment via $LANG and luit
2347 if check_com isutfenv && check_com luit ; then
2348     if check_com -c mrxvt ; then
2349         isutfenv && [[ -n "$LANG" ]] && \
2350             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2351     fi
2352
2353     if check_com -c aterm ; then
2354         isutfenv && [[ -n "$LANG" ]] && \
2355             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2356     fi
2357
2358     if check_com -c centericq ; then
2359         isutfenv && [[ -n "$LANG" ]] && \
2360             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2361     fi
2362 fi
2363
2364 # useful functions
2365
2366 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2367 bk() {
2368     emulate -L zsh
2369     cp -b $1 $1_`date --iso-8601=m`
2370 }
2371
2372 #f5# cd to directoy and list files
2373 cl() {
2374     emulate -L zsh
2375     cd $1 && ls -a
2376 }
2377
2378 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2379 cd() {
2380     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2381         [[ ! -e ${1:h} ]] && return 1
2382         print "Correcting ${1} to ${1:h}"
2383         builtin cd ${1:h}
2384     else
2385         builtin cd "$@"
2386     fi
2387 }
2388
2389 #f5# Create Directoy and \kbd{cd} to it
2390 mkcd() {
2391     if (( ARGC != 1 )); then
2392         printf 'usage: mkcd <new-directory>\n'
2393         return 1;
2394     fi
2395     if [[ ! -d "$1" ]]; then
2396         command mkdir -p "$1"
2397     else
2398         printf '`%s'\'' already exists: cd-ing.\n' "$1"
2399     fi
2400     builtin cd "$1"
2401 }
2402
2403 #f5# Create temporary directory and \kbd{cd} to it
2404 cdt() {
2405     local t
2406     t=$(mktemp -d)
2407     echo "$t"
2408     builtin cd "$t"
2409 }
2410
2411 #f5# Create directory under cursor or the selected area
2412 # Press ctrl-xM to create the directory under the cursor or the selected area.
2413 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2414 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2415 # directory does not exist yet -> press ctrl-XM and problem solved
2416 inplaceMkDirs() {
2417     local PATHTOMKDIR
2418     if ((REGION_ACTIVE==1)); then
2419         local F=$MARK T=$CURSOR
2420         if [[ $F -gt $T ]]; then
2421             F=${CURSOR}
2422             T=${MARK}
2423         fi
2424         # get marked area from buffer and eliminate whitespace
2425         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2426         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2427     else
2428         local bufwords iword
2429         bufwords=(${(z)LBUFFER})
2430         iword=${#bufwords}
2431         bufwords=(${(z)BUFFER})
2432         PATHTOMKDIR="${(Q)bufwords[iword]}"
2433     fi
2434     [[ -z "${PATHTOMKDIR}" ]] && return 1
2435     PATHTOMKDIR=${~PATHTOMKDIR}
2436     if [[ -e "${PATHTOMKDIR}" ]]; then
2437         zle -M " path already exists, doing nothing"
2438     else
2439         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2440         zle end-of-line
2441     fi
2442 }
2443 #k# mkdir -p <dir> from string under cursor or marked area
2444 zle -N inplaceMkDirs && bindkey '^xM' inplaceMkDirs
2445
2446 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2447 accessed() {
2448     emulate -L zsh
2449     print -l -- *(a-${1:-1})
2450 }
2451
2452 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2453 changed() {
2454     emulate -L zsh
2455     print -l -- *(c-${1:-1})
2456 }
2457
2458 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2459 modified() {
2460     emulate -L zsh
2461     print -l -- *(m-${1:-1})
2462 }
2463 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2464 check_com new || alias new=modified
2465
2466 # use colors when GNU grep with color-support
2467 #a2# Execute \kbd{grep -{}-color=auto}
2468 (( $#grep_options > 0 )) && alias grep='grep '${grep_options:+"${grep_options[*]} "}
2469
2470 # Translate DE<=>EN
2471 # 'translate' looks up fot a word in a file with language-to-language
2472 # translations (field separator should be " : "). A typical wordlist looks
2473 # like at follows:
2474 #  | english-word : german-transmission
2475 # It's also only possible to translate english to german but not reciprocal.
2476 # Use the following oneliner to turn back the sort order:
2477 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2478 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2479 #f5# Translates a word
2480 trans() {
2481     emulate -L zsh
2482     case "$1" in
2483         -[dD]*)
2484             translate -l de-en $2
2485             ;;
2486         -[eE]*)
2487             translate -l en-de $2
2488             ;;
2489         *)
2490             echo "Usage: $0 { -D | -E }"
2491             echo "         -D == German to English"
2492             echo "         -E == English to German"
2493     esac
2494 }
2495
2496 # Usage: simple-extract <file>
2497 # Using option -d deletes the original archive file.
2498 #f5# Smart archive extractor
2499 simple-extract() {
2500     emulate -L zsh
2501     setopt extended_glob noclobber
2502     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2503     local RC=0
2504     zparseopts -D -E "d=DELETE_ORIGINAL"
2505     for ARCHIVE in "${@}"; do
2506         case $ARCHIVE in
2507             *.(tar.bz2|tbz2|tbz))
2508                 DECOMP_CMD="tar -xvjf -"
2509                 USES_STDIN=true
2510                 USES_STDOUT=false
2511                 ;;
2512             *.(tar.gz|tgz))
2513                 DECOMP_CMD="tar -xvzf -"
2514                 USES_STDIN=true
2515                 USES_STDOUT=false
2516                 ;;
2517             *.(tar.xz|txz|tar.lzma))
2518                 DECOMP_CMD="tar -xvJf -"
2519                 USES_STDIN=true
2520                 USES_STDOUT=false
2521                 ;;
2522             *.tar)
2523                 DECOMP_CMD="tar -xvf -"
2524                 USES_STDIN=true
2525                 USES_STDOUT=false
2526                 ;;
2527             *.rar)
2528                 DECOMP_CMD="unrar x"
2529                 USES_STDIN=false
2530                 USES_STDOUT=false
2531                 ;;
2532             *.lzh)
2533                 DECOMP_CMD="lha x"
2534                 USES_STDIN=false
2535                 USES_STDOUT=false
2536                 ;;
2537             *.7z)
2538                 DECOMP_CMD="7z x"
2539                 USES_STDIN=false
2540                 USES_STDOUT=false
2541                 ;;
2542             *.(zip|jar))
2543                 DECOMP_CMD="unzip"
2544                 USES_STDIN=false
2545                 USES_STDOUT=false
2546                 ;;
2547             *.deb)
2548                 DECOMP_CMD="ar -x"
2549                 USES_STDIN=false
2550                 USES_STDOUT=false
2551                 ;;
2552             *.bz2)
2553                 DECOMP_CMD="bzip2 -d -c -"
2554                 USES_STDIN=true
2555                 USES_STDOUT=true
2556                 ;;
2557             *.(gz|Z))
2558                 DECOMP_CMD="gzip -d -c -"
2559                 USES_STDIN=true
2560                 USES_STDOUT=true
2561                 ;;
2562             *.(xz|lzma))
2563                 DECOMP_CMD="xz -d -c -"
2564                 USES_STDIN=true
2565                 USES_STDOUT=true
2566                 ;;
2567             *)
2568                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2569                 RC=$((RC+1))
2570                 continue
2571                 ;;
2572         esac
2573
2574         if ! check_com ${DECOMP_CMD[(w)1]}; then
2575             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2576             RC=$((RC+2))
2577             continue
2578         fi
2579
2580         GZTARGET="${ARCHIVE:t:r}"
2581         if [[ -f $ARCHIVE ]] ; then
2582
2583             print "Extracting '$ARCHIVE' ..."
2584             if $USES_STDIN; then
2585                 if $USES_STDOUT; then
2586                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
2587                 else
2588                     ${=DECOMP_CMD} < "$ARCHIVE"
2589                 fi
2590             else
2591                 if $USES_STDOUT; then
2592                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
2593                 else
2594                     ${=DECOMP_CMD} "$ARCHIVE"
2595                 fi
2596             fi
2597             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
2598
2599         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
2600             if check_com curl; then
2601                 WGET_CMD="curl -L -k -s -o -"
2602             elif check_com wget; then
2603                 WGET_CMD="wget -q -O - --no-check-certificate"
2604             else
2605                 print "ERROR: neither wget nor curl is installed" >&2
2606                 RC=$((RC+4))
2607                 continue
2608             fi
2609             print "Downloading and Extracting '$ARCHIVE' ..."
2610             if $USES_STDIN; then
2611                 if $USES_STDOUT; then
2612                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
2613                     RC=$((RC+$?))
2614                 else
2615                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
2616                     RC=$((RC+$?))
2617                 fi
2618             else
2619                 if $USES_STDOUT; then
2620                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
2621                 else
2622                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
2623                 fi
2624             fi
2625
2626         else
2627             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
2628             RC=$((RC+8))
2629         fi
2630     done
2631     return $RC
2632 }
2633
2634 __archive_or_uri()
2635 {
2636     _alternative \
2637         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
2638         '_urls:Remote Archives:_urls'
2639 }
2640
2641 _simple_extract()
2642 {
2643     _arguments \
2644         '-d[delete original archivefile after extraction]' \
2645         '*:Archive Or Uri:__archive_or_uri'
2646 }
2647 compdef _simple_extract simple-extract
2648 alias se=simple-extract
2649
2650 #f5# Set all ulimit parameters to \kbd{unlimited}
2651 allulimit() {
2652     ulimit -c unlimited
2653     ulimit -d unlimited
2654     ulimit -f unlimited
2655     ulimit -l unlimited
2656     ulimit -n unlimited
2657     ulimit -s unlimited
2658     ulimit -t unlimited
2659 }
2660
2661 #f5# Change the xterm title from within GNU-screen
2662 xtrename() {
2663     emulate -L zsh
2664     if [[ $1 != "-f" ]] ; then
2665         if [[ -z ${DISPLAY} ]] ; then
2666             printf 'xtrename only makes sense in X11.\n'
2667             return 1
2668         fi
2669     else
2670         shift
2671     fi
2672     if [[ -z $1 ]] ; then
2673         printf 'usage: xtrename [-f] "title for xterm"\n'
2674         printf '  renames the title of xterm from _within_ screen.\n'
2675         printf '  also works without screen.\n'
2676         printf '  will not work if DISPLAY is unset, use -f to override.\n'
2677         return 0
2678     fi
2679     print -n "\eP\e]0;${1}\C-G\e\\"
2680     return 0
2681 }
2682
2683 # Create small urls via http://goo.gl using curl(1).
2684 # API reference: https://code.google.com/apis/urlshortener/
2685 function zurl() {
2686     emulate -L zsh
2687     if [[ -z $1 ]]; then
2688         print "USAGE: zurl <URL>"
2689         return 1
2690     fi
2691
2692     local PN url prog api json data
2693     PN=$0
2694     url=$1
2695
2696     # Prepend 'http://' to given URL where necessary for later output.
2697     if [[ ${url} != http(s|)://* ]]; then
2698         url='http://'${url}
2699     fi
2700
2701     if check_com -c curl; then
2702         prog=curl
2703     else
2704         print "curl is not available, but mandatory for ${PN}. Aborting."
2705         return 1
2706     fi
2707     api='https://www.googleapis.com/urlshortener/v1/url'
2708     contenttype="Content-Type: application/json"
2709     json="{\"longUrl\": \"${url}\"}"
2710     data=$($prog --silent -H ${contenttype} -d ${json} $api)
2711     # Match against a regex and print it
2712     if [[ $data =~ '"id": "(http://goo.gl/[[:alnum:]]+)"' ]]; then
2713         print $match;
2714     fi
2715 }
2716
2717 #f2# Find history events by search pattern and list them by date.
2718 whatwhen()  {
2719     emulate -L zsh
2720     local usage help ident format_l format_s first_char remain first last
2721     usage='USAGE: whatwhen [options] <searchstring> <search range>'
2722     help='Use `whatwhen -h'\'' for further explanations.'
2723     ident=${(l,${#${:-Usage: }},, ,)}
2724     format_l="${ident}%s\t\t\t%s\n"
2725     format_s="${format_l//(\\t)##/\\t}"
2726     # Make the first char of the word to search for case
2727     # insensitive; e.g. [aA]
2728     first_char=[${(L)1[1]}${(U)1[1]}]
2729     remain=${1[2,-1]}
2730     # Default search range is `-100'.
2731     first=${2:-\-100}
2732     # Optional, just used for `<first> <last>' given.
2733     last=$3
2734     case $1 in
2735         ("")
2736             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
2737             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2738         ;;
2739         (-h)
2740             printf '%s\n\n' ${usage}
2741             print 'OPTIONS:'
2742             printf $format_l '-h' 'show help text'
2743             print '\f'
2744             print 'SEARCH RANGE:'
2745             printf $format_l "'0'" 'the whole history,'
2746             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
2747             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
2748             printf '\n%s\n' 'EXAMPLES:'
2749             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
2750             printf $format_l 'whatwhen zsh -250'
2751             printf $format_l 'whatwhen foo 1 99'
2752         ;;
2753         (\?)
2754             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2755         ;;
2756         (*)
2757             # -l list results on stout rather than invoking $EDITOR.
2758             # -i Print dates as in YYYY-MM-DD.
2759             # -m Search for a - quoted - pattern within the history.
2760             fc -li -m "*${first_char}${remain}*" $first $last
2761         ;;
2762     esac
2763 }
2764
2765 # mercurial related stuff
2766 if check_com -c hg ; then
2767     # gnu like diff for mercurial
2768     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
2769     #f5# GNU like diff for mercurial
2770     hgdi() {
2771         emulate -L zsh
2772         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
2773     }
2774
2775     # build debian package
2776     #a2# Alias for \kbd{hg-buildpackage}
2777     alias hbp='hg-buildpackage'
2778
2779     # execute commands on the versioned patch-queue from the current repos
2780     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
2781
2782     # diffstat for specific version of a mercurial repository
2783     #   hgstat      => display diffstat between last revision and tip
2784     #   hgstat 1234 => display diffstat between revision 1234 and tip
2785     #f5# Diffstat for specific version of a mercurial repos
2786     hgstat() {
2787         emulate -L zsh
2788         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
2789     }
2790
2791 fi # end of check whether we have the 'hg'-executable
2792
2793 # grml-small cleanups
2794
2795 # The following is used to remove zsh-config-items that do not work
2796 # in grml-small by default.
2797 # If you do not want these adjustments (for whatever reason), set
2798 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
2799 # sources if it is there).
2800
2801 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
2802
2803     unset abk[V]
2804     unalias    'V'      &> /dev/null
2805     unfunction vman     &> /dev/null
2806     unfunction viless   &> /dev/null
2807     unfunction 2html    &> /dev/null
2808
2809     # manpages are not in grmlsmall
2810     unfunction manzsh   &> /dev/null
2811     unfunction man2     &> /dev/null
2812
2813 fi
2814
2815 zrclocal
2816
2817 ## genrefcard.pl settings
2818
2819 ### doc strings for external functions from files
2820 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
2821
2822 ### example: split functions-search 8,16,24,32
2823 #@# split functions-search 8
2824
2825 ## END OF FILE #################################################################
2826 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
2827 # Local variables:
2828 # mode: sh
2829 # End: