etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is437(){
 148     [[ $ZSH_VERSION == 4.3.<7->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 is439(){
 154     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 155                                  || $ZSH_VERSION == <5->* ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running grml
 160 isgrml(){
 161     [[ -f /etc/grml_version ]] && return 0
 162     return 1
 163 }
 164
 165 #f1# Checks whether or not you're running a grml cd
 166 isgrmlcd(){
 167     [[ -f /etc/grml_cd ]] && return 0
 168     return 1
 169 }
 170
 171 if isgrml ; then
 172 #f1# Checks whether or not you're running grml-small
 173     isgrmlsmall() {
 174         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 175             return 0
 176         fi
 177         return 1
 178     }
 179 else
 180     isgrmlsmall() { return 1 }
 181 fi
 182
 183 GRML_OSTYPE=$(uname -s)
 184
 185 islinux(){
 186     [[ $GRML_OSTYPE == "Linux" ]]
 187 }
 188
 189 isdarwin(){
 190     [[ $GRML_OSTYPE == "Darwin" ]]
 191 }
 192
 193 isfreebsd(){
 194     [[ $GRML_OSTYPE == "FreeBSD" ]]
 195 }
 196
 197 isopenbsd(){
 198     [[ $GRML_OSTYPE == "OpenBSD" ]]
 199 }
 200
 201 issolaris(){
 202     [[ $GRML_OSTYPE == "SunOS" ]]
 203 }
 204
 205 #f1# are we running within an utf environment?
 206 isutfenv() {
 207     case "$LANG $CHARSET $LANGUAGE" in
 208         *utf*) return 0 ;;
 209         *UTF*) return 0 ;;
 210         *)     return 1 ;;
 211     esac
 212 }
 213
 214 # check for user, if not running as root set $SUDO to sudo
 215 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 216
 217 # change directory to home on first invocation of zsh
 218 # important for rungetty -> autologin
 219 # Thanks go to Bart Schaefer!
 220 isgrml && checkhome() {
 221     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 222         export ALREADY_DID_CD_HOME=$HOME
 223         cd
 224     fi
 225 }
 226
 227 # check for zsh v3.1.7+
 228
 229 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 230      || ${ZSH_VERSION} == 3.<2->.<->*    \
 231      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 232
 233     printf '-!-\n'
 234     printf '-!- In this configuration we try to make use of features, that only\n'
 235     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 236     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 237     printf '-!- advanced features in all supported versions.\n'
 238     printf '-!-\n'
 239     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 240     printf '-!-\n'
 241     printf '-!- While this *may* work, it might as well fail.\n'
 242     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 243     printf '-!-\n'
 244     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 245     printf '-!- If it does today, you'\''ve been lucky.\n'
 246     printf '-!-\n'
 247     printf '-!- Ye been warned!\n'
 248     printf '-!-\n'
 249
 250     function zstyle() { : }
 251 fi
 252
 253 # autoload wrapper - use this one instead of autoload directly
 254 # We need to define this function as early as this, because autoloading
 255 # 'is-at-least()' needs it.
 256 function zrcautoload() {
 257     emulate -L zsh
 258     setopt extended_glob
 259     local fdir ffile
 260     local -i ffound
 261
 262     ffile=$1
 263     (( ffound = 0 ))
 264     for fdir in ${fpath} ; do
 265         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 266     done
 267
 268     (( ffound == 0 )) && return 1
 269     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 270         autoload -U ${ffile} || return 1
 271     else
 272         autoload ${ffile} || return 1
 273     fi
 274     return 0
 275 }
 276
 277 # The following is the ‘add-zsh-hook’ function from zsh upstream. It is
 278 # included here to make the setup work with older versions of zsh (prior to
 279 # 4.3.7) in which this function had a bug that triggers annoying errors during
 280 # shell startup. This is exactly upstreams code from f0068edb4888a4d8fe94def,
 281 # with just a few adjustments in coding style to make the function look more
 282 # compact. This definition can be removed as soon as we raise the minimum
 283 # version requirement to 4.3.7 or newer.
 284 function add-zsh-hook() {
 285     # Add to HOOK the given FUNCTION.
 286     # HOOK is one of chpwd, precmd, preexec, periodic, zshaddhistory,
 287     # zshexit, zsh_directory_name (the _functions subscript is not required).
 288     #
 289     # With -d, remove the function from the hook instead; delete the hook
 290     # variable if it is empty.
 291     #
 292     # -D behaves like -d, but pattern characters are active in the function
 293     # name, so any matching function will be deleted from the hook.
 294     #
 295     # Without -d, the FUNCTION is marked for autoload; -U is passed down to
 296     # autoload if that is given, as are -z and -k. (This is harmless if the
 297     # function is actually defined inline.)
 298     emulate -L zsh
 299     local -a hooktypes
 300     hooktypes=(
 301         chpwd precmd preexec periodic zshaddhistory zshexit
 302         zsh_directory_name
 303     )
 304     local usage="Usage: $0 hook function\nValid hooks are:\n  $hooktypes"
 305     local opt
 306     local -a autoopts
 307     integer del list help
 308     while getopts "dDhLUzk" opt; do
 309         case $opt in
 310         (d) del=1 ;;
 311         (D) del=2 ;;
 312         (h) help=1 ;;
 313         (L) list=1 ;;
 314         ([Uzk]) autoopts+=(-$opt) ;;
 315         (*) return 1 ;;
 316         esac
 317     done
 318     shift $(( OPTIND - 1 ))
 319     if (( list )); then
 320         typeset -mp "(${1:-${(@j:|:)hooktypes}})_functions"
 321         return $?
 322     elif (( help || $# != 2 || ${hooktypes[(I)$1]} == 0 )); then
 323         print -u$(( 2 - help )) $usage
 324         return $(( 1 - help ))
 325     fi
 326     local hook="${1}_functions"
 327     local fn="$2"
 328     if (( del )); then
 329         # delete, if hook is set
 330         if (( ${(P)+hook} )); then
 331             if (( del == 2 )); then
 332                 set -A $hook ${(P)hook:#${~fn}}
 333             else
 334                 set -A $hook ${(P)hook:#$fn}
 335             fi
 336             # unset if no remaining entries --- this can give better
 337             # performance in some cases
 338             if (( ! ${(P)#hook} )); then
 339                 unset $hook
 340             fi
 341         fi
 342     else
 343         if (( ${(P)+hook} )); then
 344             if (( ${${(P)hook}[(I)$fn]} == 0 )); then
 345                 set -A $hook ${(P)hook} $fn
 346             fi
 347         else
 348             set -A $hook $fn
 349         fi
 350         autoload $autoopts -- $fn
 351     fi
 352 }
 353
 354 # Load is-at-least() for more precise version checks Note that this test will
 355 # *always* fail, if the is-at-least function could not be marked for
 356 # autoloading.
 357 zrcautoload is-at-least || is-at-least() { return 1 }
 358
 359 # set some important options (as early as possible)
 360
 361 # append history list to the history file; this is the default but we make sure
 362 # because it's required for share_history.
 363 setopt append_history
 364
 365 # import new commands from the history file also in other zsh-session
 366 is4 && setopt share_history
 367
 368 # save each command's beginning timestamp and the duration to the history file
 369 setopt extended_history
 370
 371 # If a new command line being added to the history list duplicates an older
 372 # one, the older command is removed from the list
 373 is4 && setopt histignorealldups
 374
 375 # remove command lines from the history list when the first character on the
 376 # line is a space
 377 setopt histignorespace
 378
 379 # if a command is issued that can't be executed as a normal command, and the
 380 # command is the name of a directory, perform the cd command to that directory.
 381 setopt auto_cd
 382
 383 # in order to use #, ~ and ^ for filename generation grep word
 384 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 385 # don't forget to quote '^', '~' and '#'!
 386 setopt extended_glob
 387
 388 # display PID when suspending processes as well
 389 setopt longlistjobs
 390
 391 # try to avoid the 'zsh: no matches found...'
 392 setopt nonomatch
 393
 394 # report the status of backgrounds jobs immediately
 395 setopt notify
 396
 397 # whenever a command completion is attempted, make sure the entire command path
 398 # is hashed first.
 399 setopt hash_list_all
 400
 401 # not just at the end
 402 setopt completeinword
 403
 404 # Don't send SIGHUP to background processes when the shell exits.
 405 setopt nohup
 406
 407 # make cd push the old directory onto the directory stack.
 408 setopt auto_pushd
 409
 410 # avoid "beep"ing
 411 setopt nobeep
 412
 413 # don't push the same dir twice.
 414 setopt pushd_ignore_dups
 415
 416 # * shouldn't match dotfiles. ever.
 417 setopt noglobdots
 418
 419 # use zsh style word splitting
 420 setopt noshwordsplit
 421
 422 # don't error out when unset parameters are used
 423 setopt unset
 424
 425 # setting some default values
 426 NOCOR=${NOCOR:-0}
 427 NOMENU=${NOMENU:-0}
 428 NOPRECMD=${NOPRECMD:-0}
 429 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 430 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 431 GRML_DISPLAY_BATTERY=${GRML_DISPLAY_BATTERY:-${BATTERY:-0}}
 432 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 433 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 434
 435 typeset -ga ls_options
 436 typeset -ga grep_options
 437 if ls --color=auto / >/dev/null 2>&1; then
 438     ls_options+=( --color=auto )
 439 elif ls -G / >/dev/null 2>&1; then
 440     ls_options+=( -G )
 441 fi
 442 if grep --color=auto -q "a" <<< "a" >/dev/null 2>&1; then
 443     grep_options+=( --color=auto )
 444 fi
 445
 446 # utility functions
 447 # this function checks if a command exists and returns either true
 448 # or false. This avoids using 'which' and 'whence', which will
 449 # avoid problems with aliases for which on certain weird systems. :-)
 450 # Usage: check_com [-c|-g] word
 451 #   -c  only checks for external commands
 452 #   -g  does the usual tests and also checks for global aliases
 453 check_com() {
 454     emulate -L zsh
 455     local -i comonly gatoo
 456
 457     if [[ $1 == '-c' ]] ; then
 458         (( comonly = 1 ))
 459         shift
 460     elif [[ $1 == '-g' ]] ; then
 461         (( gatoo = 1 ))
 462     else
 463         (( comonly = 0 ))
 464         (( gatoo = 0 ))
 465     fi
 466
 467     if (( ${#argv} != 1 )) ; then
 468         printf 'usage: check_com [-c] <command>\n' >&2
 469         return 1
 470     fi
 471
 472     if (( comonly > 0 )) ; then
 473         [[ -n ${commands[$1]}  ]] && return 0
 474         return 1
 475     fi
 476
 477     if   [[ -n ${commands[$1]}    ]] \
 478       || [[ -n ${functions[$1]}   ]] \
 479       || [[ -n ${aliases[$1]}     ]] \
 480       || [[ -n ${reswords[(r)$1]} ]] ; then
 481
 482         return 0
 483     fi
 484
 485     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 486         return 0
 487     fi
 488
 489     return 1
 490 }
 491
 492 # creates an alias and precedes the command with
 493 # sudo if $EUID is not zero.
 494 salias() {
 495     emulate -L zsh
 496     local only=0 ; local multi=0
 497     local key val
 498     while getopts ":hao" opt; do
 499         case $opt in
 500             o) only=1 ;;
 501             a) multi=1 ;;
 502             h)
 503                 printf 'usage: salias [-hoa] <alias-expression>\n'
 504                 printf '  -h      shows this help text.\n'
 505                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 506                 printf '          be careful using this option.\n'
 507                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 508                 return 0
 509                 ;;
 510             *) salias -h >&2; return 1 ;;
 511         esac
 512     done
 513     shift "$((OPTIND-1))"
 514
 515     if (( ${#argv} > 1 )) ; then
 516         printf 'Too many arguments %s\n' "${#argv}"
 517         return 1
 518     fi
 519
 520     key="${1%%\=*}" ;  val="${1#*\=}"
 521     if (( EUID == 0 )) && (( only == 0 )); then
 522         alias -- "${key}=${val}"
 523     elif (( EUID > 0 )) ; then
 524         (( multi > 0 )) && val="${val// ; / ; sudo }"
 525         alias -- "${key}=sudo ${val}"
 526     fi
 527
 528     return 0
 529 }
 530
 531 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 532 # usage: uprint foo
 533 #   Where foo is the *name* of the parameter you want printed.
 534 #   Note that foo is no typo; $foo would be wrong here!
 535 if ! is42 ; then
 536     uprint () {
 537         emulate -L zsh
 538         local -a u
 539         local w
 540         local parameter=$1
 541
 542         if [[ -z ${parameter} ]] ; then
 543             printf 'usage: uprint <parameter>\n'
 544             return 1
 545         fi
 546
 547         for w in ${(P)parameter} ; do
 548             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 549         done
 550
 551         builtin print -l $u
 552     }
 553 fi
 554
 555 # Check if we can read given files and source those we can.
 556 xsource() {
 557     if (( ${#argv} < 1 )) ; then
 558         printf 'usage: xsource FILE(s)...\n' >&2
 559         return 1
 560     fi
 561
 562     while (( ${#argv} > 0 )) ; do
 563         [[ -r "$1" ]] && source "$1"
 564         shift
 565     done
 566     return 0
 567 }
 568
 569 # Check if we can read a given file and 'cat(1)' it.
 570 xcat() {
 571     emulate -L zsh
 572     if (( ${#argv} != 1 )) ; then
 573         printf 'usage: xcat FILE\n' >&2
 574         return 1
 575     fi
 576
 577     [[ -r $1 ]] && cat $1
 578     return 0
 579 }
 580
 581 # Remove these functions again, they are of use only in these
 582 # setup files. This should be called at the end of .zshrc.
 583 xunfunction() {
 584     emulate -L zsh
 585     local -a funcs
 586     local func
 587     funcs=(salias xcat xsource xunfunction zrcautoload zrcautozle)
 588     for func in $funcs ; do
 589         [[ -n ${functions[$func]} ]] \
 590             && unfunction $func
 591     done
 592     return 0
 593 }
 594
 595 # this allows us to stay in sync with grml's zshrc and put own
 596 # modifications in ~/.zshrc.local
 597 zrclocal() {
 598     xsource "/etc/zsh/zshrc.local"
 599     xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
 600     return 0
 601 }
 602
 603 # locale setup
 604 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 605     xsource "/etc/default/locale"
 606 fi
 607
 608 for var in LANG LC_ALL LC_MESSAGES ; do
 609     [[ -n ${(P)var} ]] && export $var
 610 done
 611 builtin unset -v var
 612
 613 # set some variables
 614 if check_com -c vim ; then
 615 #v#
 616     export EDITOR=${EDITOR:-vim}
 617 else
 618     export EDITOR=${EDITOR:-vi}
 619 fi
 620
 621 #v#
 622 export PAGER=${PAGER:-less}
 623
 624 #v#
 625 export MAIL=${MAIL:-/var/mail/$USER}
 626
 627 # color setup for ls:
 628 check_com -c dircolors && eval $(dircolors -b)
 629 # color setup for ls on OS X / FreeBSD:
 630 isdarwin && export CLICOLOR=1
 631 isfreebsd && export CLICOLOR=1
 632
 633 # do MacPorts setup on darwin
 634 if isdarwin && [[ -d /opt/local ]]; then
 635     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 636     # zshenv.
 637     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 638     MANPATH="/opt/local/share/man:$MANPATH"
 639 fi
 640 # do Fink setup on darwin
 641 isdarwin && xsource /sw/bin/init.sh
 642
 643 # load our function and completion directories
 644 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 645     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 646     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 647         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 648             zrcautoload ${func:t}
 649         done
 650     fi
 651 done
 652 unset fdir func
 653
 654 # support colors in less
 655 export LESS_TERMCAP_mb=$'\E[01;31m'
 656 export LESS_TERMCAP_md=$'\E[01;31m'
 657 export LESS_TERMCAP_me=$'\E[0m'
 658 export LESS_TERMCAP_se=$'\E[0m'
 659 export LESS_TERMCAP_so=$'\E[01;44;33m'
 660 export LESS_TERMCAP_ue=$'\E[0m'
 661 export LESS_TERMCAP_us=$'\E[01;32m'
 662
 663 # mailchecks
 664 MAILCHECK=30
 665
 666 # report about cpu-/system-/user-time of command if running longer than
 667 # 5 seconds
 668 REPORTTIME=5
 669
 670 # watch for everyone but me and root
 671 watch=(notme root)
 672
 673 # automatically remove duplicates from these arrays
 674 typeset -U path cdpath fpath manpath
 675
 676 # Load a few modules
 677 is4 && \
 678 for mod in parameter complist deltochar mathfunc ; do
 679     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 680 done && builtin unset -v mod
 681
 682 # autoload zsh modules when they are referenced
 683 if is4 ; then
 684     zmodload -a  zsh/stat    zstat
 685     zmodload -a  zsh/zpty    zpty
 686     zmodload -ap zsh/mapfile mapfile
 687 fi
 688
 689 # completion system
 690 COMPDUMPFILE=${COMPDUMPFILE:-${ZDOTDIR:-${HOME}}/.zcompdump}
 691 if zrcautoload compinit ; then
 692     compinit -d ${COMPDUMPFILE} || print 'Notice: no compinit available :('
 693 else
 694     print 'Notice: no compinit available :('
 695     function compdef { }
 696 fi
 697
 698 # completion system
 699
 700 # called later (via is4 && grmlcomp)
 701 # note: use 'zstyle' for getting current settings
 702 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
 703 grmlcomp() {
 704     # TODO: This could use some additional information
 705
 706     # Make sure the completion system is initialised
 707     (( ${+_comps} )) || return 1
 708
 709     # allow one error for every three characters typed in approximate completer
 710     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
 711
 712     # don't complete backup files as executables
 713     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
 714
 715     # start menu completion only if it could find no unambiguous initial string
 716     zstyle ':completion:*:correct:*'       insert-unambiguous true
 717     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
 718     zstyle ':completion:*:correct:*'       original true
 719
 720     # activate color-completion
 721     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
 722
 723     # format on completion
 724     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
 725
 726     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
 727     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
 728
 729     # insert all expansions for expand completer
 730     zstyle ':completion:*:expand:*'        tag-order all-expansions
 731     zstyle ':completion:*:history-words'   list false
 732
 733     # activate menu
 734     zstyle ':completion:*:history-words'   menu yes
 735
 736     # ignore duplicate entries
 737     zstyle ':completion:*:history-words'   remove-all-dups yes
 738     zstyle ':completion:*:history-words'   stop yes
 739
 740     # match uppercase from lowercase
 741     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
 742
 743     # separate matches into groups
 744     zstyle ':completion:*:matches'         group 'yes'
 745     zstyle ':completion:*'                 group-name ''
 746
 747     if [[ "$NOMENU" -eq 0 ]] ; then
 748         # if there are more than 5 options allow selecting from a menu
 749         zstyle ':completion:*'               menu select=5
 750     else
 751         # don't use any menus at all
 752         setopt no_auto_menu
 753     fi
 754
 755     zstyle ':completion:*:messages'        format '%d'
 756     zstyle ':completion:*:options'         auto-description '%d'
 757
 758     # describe options in full
 759     zstyle ':completion:*:options'         description 'yes'
 760
 761     # on processes completion complete all user processes
 762     zstyle ':completion:*:processes'       command 'ps -au$USER'
 763
 764     # offer indexes before parameters in subscripts
 765     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
 766
 767     # provide verbose completion information
 768     zstyle ':completion:*'                 verbose true
 769
 770     # recent (as of Dec 2007) zsh versions are able to provide descriptions
 771     # for commands (read: 1st word in the line) that it will list for the user
 772     # to choose from. The following disables that, because it's not exactly fast.
 773     zstyle ':completion:*:-command-:*:'    verbose false
 774
 775     # set format for warnings
 776     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
 777
 778     # define files to ignore for zcompile
 779     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
 780     zstyle ':completion:correct:'          prompt 'correct to: %e'
 781
 782     # Ignore completion functions for commands you don't have:
 783     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
 784
 785     # Provide more processes in completion of programs like killall:
 786     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
 787
 788     # complete manual by their section
 789     zstyle ':completion:*:manuals'    separate-sections true
 790     zstyle ':completion:*:manuals.*'  insert-sections   true
 791     zstyle ':completion:*:man:*'      menu yes select
 792
 793     # Search path for sudo completion
 794     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
 795                                                /usr/local/bin  \
 796                                                /usr/sbin       \
 797                                                /usr/bin        \
 798                                                /sbin           \
 799                                                /bin            \
 800                                                /usr/X11R6/bin
 801
 802     # provide .. as a completion
 803     zstyle ':completion:*' special-dirs ..
 804
 805     # run rehash on completion so new installed program are found automatically:
 806     _force_rehash() {
 807         (( CURRENT == 1 )) && rehash
 808         return 1
 809     }
 810
 811     ## correction
 812     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
 813     if [[ "$NOCOR" -gt 0 ]] ; then
 814         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
 815         setopt nocorrect
 816     else
 817         # try to be smart about when to use what completer...
 818         setopt correct
 819         zstyle -e ':completion:*' completer '
 820             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
 821                 _last_try="$HISTNO$BUFFER$CURSOR"
 822                 reply=(_complete _match _ignored _prefix _files)
 823             else
 824                 if [[ $words[1] == (rm|mv) ]] ; then
 825                     reply=(_complete _files)
 826                 else
 827                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
 828                 fi
 829             fi'
 830     fi
 831
 832     # command for process lists, the local web server details and host completion
 833     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
 834
 835     # caching
 836     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
 837                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
 838
 839     # host completion
 840     if is42 ; then
 841         [[ -r ~/.ssh/config ]] && _ssh_config_hosts=(${${(s: :)${(ps:\t:)${${(@M)${(f)"$(<$HOME/.ssh/config)"}:#Host *}#Host }}}:#*[*?]*}) || _ssh_config_hosts=()
 842         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
 843         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
 844     else
 845         _ssh_config_hosts=()
 846         _ssh_hosts=()
 847         _etc_hosts=()
 848     fi
 849     hosts=(
 850         $(hostname)
 851         "$_ssh_config_hosts[@]"
 852         "$_ssh_hosts[@]"
 853         "$_etc_hosts[@]"
 854         localhost
 855     )
 856     zstyle ':completion:*:hosts' hosts $hosts
 857     # TODO: so, why is this here?
 858     #  zstyle '*' hosts $hosts
 859
 860     # use generic completion system for programs not yet defined; (_gnu_generic works
 861     # with commands that provide a --help option with "standard" gnu-like output.)
 862     for compcom in cp deborphan df feh fetchipac gpasswd head hnb ipacsum mv \
 863                    pal stow uname ; do
 864         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
 865     done; unset compcom
 866
 867     # see upgrade function in this file
 868     compdef _hosts upgrade
 869 }
 870
 871 # Keyboard setup: The following is based on the same code, we wrote for
 872 # debian's setup. It ensures the terminal is in the right mode, when zle is
 873 # active, so the values from $terminfo are valid. Therefore, this setup should
 874 # work on all systems, that have support for `terminfo'. It also requires the
 875 # zsh in use to have the `zsh/terminfo' module built.
 876 #
 877 # If you are customising your `zle-line-init()' or `zle-line-finish()'
 878 # functions, make sure you call the following utility functions in there:
 879 #
 880 #     - zle-line-init():      zle-smkx
 881 #     - zle-line-finish():    zle-rmkx
 882
 883 # Use emacs-like key bindings by default:
 884 bindkey -e
 885
 886 # Custom widgets:
 887
 888 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 889 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 890 beginning-or-end-of-somewhere() {
 891     local hno=$HISTNO
 892     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 893       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 894         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 895     else
 896         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 897         if (( HISTNO != hno )); then
 898             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 899         fi
 900     fi
 901 }
 902 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 903 zle -N end-of-somewhere beginning-or-end-of-somewhere
 904
 905 # add a command line to the shells history without executing it
 906 commit-to-history() {
 907     print -s ${(z)BUFFER}
 908     zle send-break
 909 }
 910 zle -N commit-to-history
 911
 912 # only slash should be considered as a word separator:
 913 slash-backward-kill-word() {
 914     local WORDCHARS="${WORDCHARS:s@/@}"
 915     # zle backward-word
 916     zle backward-kill-word
 917 }
 918 zle -N slash-backward-kill-word
 919
 920 # a generic accept-line wrapper
 921
 922 # This widget can prevent unwanted autocorrections from command-name
 923 # to _command-name, rehash automatically on enter and call any number
 924 # of builtin and user-defined widgets in different contexts.
 925 #
 926 # For a broader description, see:
 927 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 928 #
 929 # The code is imported from the file 'zsh/functions/accept-line' from
 930 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 931 # distributed under the same terms as zsh itself.
 932
 933 # A newly added command will may not be found or will cause false
 934 # correction attempts, if you got auto-correction set. By setting the
 935 # following style, we force accept-line() to rehash, if it cannot
 936 # find the first word on the command line in the $command[] hash.
 937 zstyle ':acceptline:*' rehash true
 938
 939 function Accept-Line() {
 940     setopt localoptions noksharrays
 941     local -a subs
 942     local -xi aldone
 943     local sub
 944     local alcontext=${1:-$alcontext}
 945
 946     zstyle -a ":acceptline:${alcontext}" actions subs
 947
 948     (( ${#subs} < 1 )) && return 0
 949
 950     (( aldone = 0 ))
 951     for sub in ${subs} ; do
 952         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 953         zle ${sub}
 954
 955         (( aldone > 0 )) && break
 956     done
 957 }
 958
 959 function Accept-Line-getdefault() {
 960     emulate -L zsh
 961     local default_action
 962
 963     zstyle -s ":acceptline:${alcontext}" default_action default_action
 964     case ${default_action} in
 965         ((accept-line|))
 966             printf ".accept-line"
 967             ;;
 968         (*)
 969             printf ${default_action}
 970             ;;
 971     esac
 972 }
 973
 974 function Accept-Line-HandleContext() {
 975     zle Accept-Line
 976
 977     default_action=$(Accept-Line-getdefault)
 978     zstyle -T ":acceptline:${alcontext}" call_default \
 979         && zle ${default_action}
 980 }
 981
 982 function accept-line() {
 983     setopt localoptions noksharrays
 984     local -ax cmdline
 985     local -x alcontext
 986     local buf com fname format msg default_action
 987
 988     alcontext='default'
 989     buf="${BUFFER}"
 990     cmdline=(${(z)BUFFER})
 991     com="${cmdline[1]}"
 992     fname="_${com}"
 993
 994     Accept-Line 'preprocess'
 995
 996     zstyle -t ":acceptline:${alcontext}" rehash \
 997         && [[ -z ${commands[$com]} ]]           \
 998         && rehash
 999
1000     if    [[ -n ${com}               ]] \
1001        && [[ -n ${reswords[(r)$com]} ]] \
1002        || [[ -n ${aliases[$com]}     ]] \
1003        || [[ -n ${functions[$com]}   ]] \
1004        || [[ -n ${builtins[$com]}    ]] \
1005        || [[ -n ${commands[$com]}    ]] ; then
1006
1007         # there is something sensible to execute, just do it.
1008         alcontext='normal'
1009         Accept-Line-HandleContext
1010
1011         return
1012     fi
1013
1014     if    [[ -o correct              ]] \
1015        || [[ -o correctall           ]] \
1016        && [[ -n ${functions[$fname]} ]] ; then
1017
1018         # nothing there to execute but there is a function called
1019         # _command_name; a completion widget. Makes no sense to
1020         # call it on the commandline, but the correct{,all} options
1021         # will ask for it nevertheless, so warn the user.
1022         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
1023             # Okay, we warned the user before, he called us again,
1024             # so have it his way.
1025             alcontext='force'
1026             Accept-Line-HandleContext
1027
1028             return
1029         fi
1030
1031         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
1032             alcontext='normal'
1033             Accept-Line-HandleContext
1034         else
1035             # prepare warning message for the user, configurable via zstyle.
1036             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
1037
1038             if [[ -z ${msg} ]] ; then
1039                 msg="%c will not execute and completion %f exists."
1040             fi
1041
1042             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
1043
1044             zle -M -- "${msg}"
1045         fi
1046         return
1047     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
1048         # If we are here, the commandline contains something that is not
1049         # executable, which is neither subject to _command_name correction
1050         # and is not empty. might be a variable assignment
1051         alcontext='misc'
1052         Accept-Line-HandleContext
1053
1054         return
1055     fi
1056
1057     # If we got this far, the commandline only contains whitespace, or is empty.
1058     alcontext='empty'
1059     Accept-Line-HandleContext
1060 }
1061
1062 zle -N accept-line
1063 zle -N Accept-Line
1064 zle -N Accept-Line-HandleContext
1065
1066 # power completion / abbreviation expansion / buffer expansion
1067 # see http://zshwiki.org/home/examples/zleiab for details
1068 # less risky than the global aliases but powerful as well
1069 # just type the abbreviation key and afterwards 'ctrl-x .' to expand it
1070 declare -A abk
1071 setopt extendedglob
1072 setopt interactivecomments
1073 abk=(
1074 #   key   # value                  (#d additional doc string)
1075 #A# start
1076     '...'  '../..'
1077     '....' '../../..'
1078     'BG'   '& exit'
1079     'C'    '| wc -l'
1080     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
1081     'H'    '| head'
1082     'Hl'   ' --help |& less -r'    #d (Display help in pager)
1083     'L'    '| less'
1084     'LL'   '|& less -r'
1085     'M'    '| most'
1086     'N'    '&>/dev/null'           #d (No Output)
1087     'R'    '| tr A-z N-za-m'       #d (ROT13)
1088     'SL'   '| sort | less'
1089     'S'    '| sort -u'
1090     'T'    '| tail'
1091     'V'    '|& vim -'
1092 #A# end
1093     'co'   './configure && make && sudo make install'
1094 )
1095
1096 zleiab() {
1097     emulate -L zsh
1098     setopt extendedglob
1099     local MATCH
1100
1101     LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
1102     LBUFFER+=${abk[$MATCH]:-$MATCH}
1103 }
1104
1105 zle -N zleiab
1106
1107 help-show-abk()
1108 {
1109   zle -M "$(print "Available abbreviations for expansion:"; print -a -C 2 ${(kv)abk})"
1110 }
1111
1112 zle -N help-show-abk
1113
1114 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1115 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1116 zle -N insert-datestamp
1117
1118 # press esc-m for inserting last typed word again (thanks to caphuso!)
1119 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1120 zle -N insert-last-typed-word;
1121
1122 function grml-zsh-fg() {
1123   if (( ${#jobstates} )); then
1124     zle .push-input
1125     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1126     BUFFER="${BUFFER}fg"
1127     zle .accept-line
1128   else
1129     zle -M 'No background jobs. Doing nothing.'
1130   fi
1131 }
1132 zle -N grml-zsh-fg
1133
1134 # run command line as user root via sudo:
1135 sudo-command-line() {
1136     [[ -z $BUFFER ]] && zle up-history
1137     if [[ $BUFFER != sudo\ * ]]; then
1138         BUFFER="sudo $BUFFER"
1139         CURSOR=$(( CURSOR+5 ))
1140     fi
1141 }
1142 zle -N sudo-command-line
1143
1144 ### jump behind the first word on the cmdline.
1145 ### useful to add options.
1146 function jump_after_first_word() {
1147     local words
1148     words=(${(z)BUFFER})
1149
1150     if (( ${#words} <= 1 )) ; then
1151         CURSOR=${#BUFFER}
1152     else
1153         CURSOR=${#${words[1]}}
1154     fi
1155 }
1156 zle -N jump_after_first_word
1157
1158 #f5# Create directory under cursor or the selected area
1159 inplaceMkDirs() {
1160     # Press ctrl-xM to create the directory under the cursor or the selected area.
1161     # To select an area press ctrl-@ or ctrl-space and use the cursor.
1162     # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
1163     # directory does not exist yet -> press ctrl-XM and problem solved
1164     local PATHTOMKDIR
1165     if ((REGION_ACTIVE==1)); then
1166         local F=$MARK T=$CURSOR
1167         if [[ $F -gt $T ]]; then
1168             F=${CURSOR}
1169             T=${MARK}
1170         fi
1171         # get marked area from buffer and eliminate whitespace
1172         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
1173         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
1174     else
1175         local bufwords iword
1176         bufwords=(${(z)LBUFFER})
1177         iword=${#bufwords}
1178         bufwords=(${(z)BUFFER})
1179         PATHTOMKDIR="${(Q)bufwords[iword]}"
1180     fi
1181     [[ -z "${PATHTOMKDIR}" ]] && return 1
1182     PATHTOMKDIR=${~PATHTOMKDIR}
1183     if [[ -e "${PATHTOMKDIR}" ]]; then
1184         zle -M " path already exists, doing nothing"
1185     else
1186         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
1187         zle end-of-line
1188     fi
1189 }
1190
1191 zle -N inplaceMkDirs
1192
1193 #v1# set number of lines to display per page
1194 HELP_LINES_PER_PAGE=20
1195 #v1# set location of help-zle cache file
1196 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
1197 # helper function for help-zle, actually generates the help text
1198 help_zle_parse_keybindings()
1199 {
1200     emulate -L zsh
1201     setopt extendedglob
1202     unsetopt ksharrays  #indexing starts at 1
1203
1204     #v1# choose files that help-zle will parse for keybindings
1205     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
1206
1207     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
1208         local load_cache=0
1209         local f
1210         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
1211         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
1212     fi
1213
1214     #fill with default keybindings, possibly to be overwriten in a file later
1215     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
1216     local -A help_zle_keybindings
1217     help_zle_keybindings['<Ctrl>@']="set MARK"
1218     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
1219     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
1220     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
1221     help_zle_keybindings['<Ctrl>_']="undo"
1222     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
1223     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
1224     help_zle_keybindings['<Ctrl>e']="goto end of line"
1225     help_zle_keybindings['<Ctrl>t']="transpose charaters"
1226     help_zle_keybindings['<Alt>t']="transpose words"
1227     help_zle_keybindings['<Alt>s']="spellcheck word"
1228     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
1229     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
1230     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
1231     help_zle_keybindings["<Alt>'"]="quote line"
1232     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
1233     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
1234     help_zle_keybindings['<Alt>u']="make next word Uppercase"
1235     help_zle_keybindings['<Alt>l']="make next word lowercase"
1236     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
1237     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
1238     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
1239     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
1240     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
1241     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
1242     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
1243     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
1244     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
1245
1246     #init global variables
1247     unset help_zle_lines help_zle_sln
1248     typeset -g -a help_zle_lines
1249     typeset -g help_zle_sln=1
1250
1251     local k v f cline
1252     local lastkeybind_desc contents     #last description starting with #k# that we found
1253     local num_lines_elapsed=0            #number of lines between last description and keybinding
1254     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
1255     for f in $HELPZLE_KEYBINDING_FILES; do
1256         [[ -r "$f" ]] || continue   #not readable ? skip it
1257         contents="$(<$f)"
1258         for cline in "${(f)contents}"; do
1259             #zsh pattern: matches lines like: #k# ..............
1260             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
1261                 lastkeybind_desc="$match[*]"
1262                 num_lines_elapsed=0
1263             #zsh pattern: matches lines that set a keybinding using bind2map, bindkey or compdef -k
1264             #             ignores lines that are commentend out
1265             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
1266             elif [[ "$cline" == [^#]#(bind2maps[[:space:]](*)-s|bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
1267                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
1268                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
1269                     #substitute keybinding string with something readable
1270                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
1271                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
1272                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
1273                     help_zle_keybindings[${k}]=$lastkeybind_desc
1274                 fi
1275                 lastkeybind_desc=""
1276             else
1277               ((num_lines_elapsed++))
1278             fi
1279         done
1280     done
1281     unset contents
1282     #calculate length of keybinding column
1283     local kstrlen=0
1284     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
1285     #convert the assoc array into preformated lines, which we are able to sort
1286     for k v in ${(kv)help_zle_keybindings[@]}; do
1287         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
1288         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
1289     done
1290     #sort lines alphabetically
1291     help_zle_lines=("${(i)help_zle_lines[@]}")
1292     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
1293     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
1294     zcompile $HELP_ZLE_CACHE_FILE
1295 }
1296 typeset -g help_zle_sln
1297 typeset -g -a help_zle_lines
1298
1299 # Provides (partially autogenerated) help on keybindings and the zsh line editor
1300 help-zle()
1301 {
1302     emulate -L zsh
1303     unsetopt ksharrays  #indexing starts at 1
1304     #help lines already generated ? no ? then do it
1305     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
1306     #already displayed all lines ? go back to the start
1307     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
1308     local sln=$help_zle_sln
1309     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
1310     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
1311     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
1312 }
1313 zle -N help-zle
1314
1315 ## complete word from currently visible Screen or Tmux buffer.
1316 if check_com -c screen || check_com -c tmux; then
1317     _complete_screen_display() {
1318         [[ "$TERM" != "screen" ]] && return 1
1319
1320         local TMPFILE=$(mktemp)
1321         local -U -a _screen_display_wordlist
1322         trap "rm -f $TMPFILE" EXIT
1323
1324         # fill array with contents from screen hardcopy
1325         if ((${+TMUX})); then
1326             #works, but crashes tmux below version 1.4
1327             #luckily tmux -V option to ask for version, was also added in 1.4
1328             tmux -V &>/dev/null || return
1329             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1330         else
1331             screen -X hardcopy $TMPFILE
1332             # screen sucks, it dumps in latin1, apparently always. so recode it
1333             # to system charset
1334             check_com recode && recode latin1 $TMPFILE
1335         fi
1336         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1337         # remove PREFIX to be completed from that array
1338         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1339         compadd -a _screen_display_wordlist
1340     }
1341     #m# k CTRL-x\,\,\,S Complete word from GNU screen buffer
1342     bindkey -r "^xS"
1343     compdef -k _complete_screen_display complete-word '^xS'
1344 fi
1345
1346 # Load a few more functions and tie them to widgets, so they can be bound:
1347
1348 function zrcautozle() {
1349     emulate -L zsh
1350     local fnc=$1
1351     zrcautoload $fnc && zle -N $fnc
1352 }
1353
1354 function zrcgotwidget() {
1355     (( ${+widgets[$1]} ))
1356 }
1357
1358 function zrcgotkeymap() {
1359     [[ -n ${(M)keymaps:#$1} ]]
1360 }
1361
1362 zrcautozle insert-files
1363 zrcautozle edit-command-line
1364 zrcautozle insert-unicode-char
1365 if zrcautoload history-search-end; then
1366     zle -N history-beginning-search-backward-end history-search-end
1367     zle -N history-beginning-search-forward-end  history-search-end
1368 fi
1369 zle -C hist-complete complete-word _generic
1370 zstyle ':completion:hist-complete:*' completer _history
1371
1372 # The actual terminal setup hooks and bindkey-calls:
1373
1374 # An array to note missing features to ease diagnosis in case of problems.
1375 typeset -ga grml_missing_features
1376
1377 function zrcbindkey() {
1378     if (( ARGC )) && zrcgotwidget ${argv[-1]}; then
1379         bindkey "$@"
1380     fi
1381 }
1382
1383 function bind2maps () {
1384     local i sequence widget
1385     local -a maps
1386
1387     while [[ "$1" != "--" ]]; do
1388         maps+=( "$1" )
1389         shift
1390     done
1391     shift
1392
1393     if [[ "$1" == "-s" ]]; then
1394         shift
1395         sequence="$1"
1396     else
1397         sequence="${key[$1]}"
1398     fi
1399     widget="$2"
1400
1401     [[ -z "$sequence" ]] && return 1
1402
1403     for i in "${maps[@]}"; do
1404         zrcbindkey -M "$i" "$sequence" "$widget"
1405     done
1406 }
1407
1408 if (( ${+terminfo[smkx]} )) && (( ${+terminfo[rmkx]} )); then
1409     function zle-smkx () {
1410         emulate -L zsh
1411         printf '%s' ${terminfo[smkx]}
1412     }
1413     function zle-rmkx () {
1414         emulate -L zsh
1415         printf '%s' ${terminfo[rmkx]}
1416     }
1417     function zle-line-init () {
1418         zle-smkx
1419     }
1420     function zle-line-finish () {
1421         zle-rmkx
1422     }
1423     zle -N zle-line-init
1424     zle -N zle-line-finish
1425 else
1426     for i in {s,r}mkx; do
1427         (( ${+terminfo[$i]} )) || grml_missing_features+=($i)
1428     done
1429     unset i
1430 fi
1431
1432 typeset -A key
1433 key=(
1434     Home     "${terminfo[khome]}"
1435     End      "${terminfo[kend]}"
1436     Insert   "${terminfo[kich1]}"
1437     Delete   "${terminfo[kdch1]}"
1438     Up       "${terminfo[kcuu1]}"
1439     Down     "${terminfo[kcud1]}"
1440     Left     "${terminfo[kcub1]}"
1441     Right    "${terminfo[kcuf1]}"
1442     PageUp   "${terminfo[kpp]}"
1443     PageDown "${terminfo[knp]}"
1444     BackTab  "${terminfo[kcbt]}"
1445 )
1446
1447 # Guidelines for adding key bindings:
1448 #
1449 #   - Do not add hardcoded escape sequences, to enable non standard key
1450 #     combinations such as Ctrl-Meta-Left-Cursor. They are not easily portable.
1451 #
1452 #   - Adding Ctrl characters, such as '^b' is okay; note that '^b' and '^B' are
1453 #     the same key.
1454 #
1455 #   - All keys from the $key[] mapping are obviously okay.
1456 #
1457 #   - Most terminals send "ESC x" when Meta-x is pressed. Thus, sequences like
1458 #     '\ex' are allowed in here as well.
1459
1460 bind2maps emacs             -- Home   beginning-of-somewhere
1461 bind2maps       viins vicmd -- Home   vi-beginning-of-line
1462 bind2maps emacs             -- End    end-of-somewhere
1463 bind2maps       viins vicmd -- End    vi-end-of-line
1464 bind2maps emacs viins       -- Insert overwrite-mode
1465 bind2maps             vicmd -- Insert vi-insert
1466 bind2maps emacs             -- Delete delete-char
1467 bind2maps       viins vicmd -- Delete vi-delete-char
1468 bind2maps emacs viins vicmd -- Up     up-line-or-search
1469 bind2maps emacs viins vicmd -- Down   down-line-or-search
1470 bind2maps emacs             -- Left   backward-char
1471 bind2maps       viins vicmd -- Left   vi-backward-char
1472 bind2maps emacs             -- Right  forward-char
1473 bind2maps       viins vicmd -- Right  vi-forward-char
1474 #k# Perform abbreviation expansion
1475 bind2maps emacs viins       -- -s '^x.' zleiab
1476 #k# Display list of abbreviations that would expand
1477 bind2maps emacs viins       -- -s '^xb' help-show-abk
1478 #k# mkdir -p <dir> from string under cursor or marked area
1479 bind2maps emacs viins       -- -s '^xM' inplaceMkDirs
1480 #k# display help for keybindings and ZLE
1481 bind2maps emacs viins       -- -s '^xz' help-zle
1482 #k# Insert files and test globbing
1483 bind2maps emacs viins       -- -s "^xf" insert-files
1484 #k# Edit the current line in \kbd{\$EDITOR}
1485 bind2maps emacs viins       -- -s '\ee' edit-command-line
1486 #k# search history backward for entry beginning with typed text
1487 bind2maps emacs viins       -- -s '^xp' history-beginning-search-backward-end
1488 #k# search history forward for entry beginning with typed text
1489 bind2maps emacs viins       -- -s '^xP' history-beginning-search-forward-end
1490 #k# search history backward for entry beginning with typed text
1491 bind2maps emacs viins       -- PageUp history-beginning-search-backward-end
1492 #k# search history forward for entry beginning with typed text
1493 bind2maps emacs viins       -- PageDown history-beginning-search-forward-end
1494 bind2maps emacs viins       -- -s "^x^h" commit-to-history
1495 #k# Kill left-side word or everything up to next slash
1496 bind2maps emacs viins       -- -s '\ev' slash-backward-kill-word
1497 #k# Kill left-side word or everything up to next slash
1498 bind2maps emacs viins       -- -s '\e^h' slash-backward-kill-word
1499 #k# Kill left-side word or everything up to next slash
1500 bind2maps emacs viins       -- -s '\e^?' slash-backward-kill-word
1501 # Do history expansion on space:
1502 bind2maps emacs viins       -- -s ' ' magic-space
1503 #k# Trigger menu-complete
1504 bind2maps emacs viins       -- -s '\ei' menu-complete  # menu completion via esc-i
1505 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1506 bind2maps emacs viins       -- -s '^ed' insert-datestamp
1507 #k# Insert last typed word
1508 bind2maps emacs viins       -- -s "\em" insert-last-typed-word
1509 #k# A smart shortcut for \kbd{fg<enter>}
1510 bind2maps emacs viins       -- -s '^z' grml-zsh-fg
1511 #k# prepend the current command with "sudo"
1512 bind2maps emacs viins       -- -s "^os" sudo-command-line
1513 #k# jump to after first word (for adding options)
1514 bind2maps emacs viins       -- -s '^x1' jump_after_first_word
1515 #k# complete word from history with menu
1516 bind2maps emacs viins       -- -s "^x^x" hist-complete
1517
1518 # insert unicode character
1519 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
1520 # See for example http://unicode.org/charts/ for unicode characters code
1521 #k# Insert Unicode character
1522 bind2maps emacs viins       -- -s '^xi' insert-unicode-char
1523
1524 # use the new *-pattern-* widgets for incremental history search
1525 if zrcgotwidget history-incremental-pattern-search-backward; then
1526     for seq wid in '^r' history-incremental-pattern-search-backward \
1527                    '^s' history-incremental-pattern-search-forward
1528     do
1529         bind2maps emacs viins vicmd -- -s $seq $wid
1530     done
1531     builtin unset -v seq wid
1532 fi
1533
1534 if zrcgotkeymap menuselect; then
1535     #m# k Shift-tab Perform backwards menu completion
1536     bind2maps menuselect -- BackTab reverse-menu-complete
1537
1538     #k# menu selection: pick item but stay in the menu
1539     bind2maps menuselect -- -s '\e^M' accept-and-menu-complete
1540     # also use + and INSERT since it's easier to press repeatedly
1541     bind2maps menuselect -- -s '+' accept-and-menu-complete
1542     bind2maps menuselect -- Insert accept-and-menu-complete
1543
1544     # accept a completion and try to complete again by using menu
1545     # completion; very useful with completing directories
1546     # by using 'undo' one's got a simple file browser
1547     bind2maps menuselect -- -s '^o' accept-and-infer-next-history
1548 fi
1549
1550 # Finally, here are still a few hardcoded escape sequences; Special sequences
1551 # like Ctrl-<Cursor-key> etc do suck a fair bit, because they are not
1552 # standardised and most of the time are not available in a terminals terminfo
1553 # entry.
1554 #
1555 # While we do not encourage adding bindings like these, we will keep these for
1556 # backward compatibility.
1557
1558 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on
1559 ## the command line.
1560 # URxvt sequences:
1561 bind2maps emacs viins vicmd -- -s '\eOc' forward-word
1562 bind2maps emacs viins vicmd -- -s '\eOd' backward-word
1563 # These are for xterm:
1564 bind2maps emacs viins vicmd -- -s '\e[1;5C' forward-word
1565 bind2maps emacs viins vicmd -- -s '\e[1;5D' backward-word
1566 ## the same for alt-left-arrow and alt-right-arrow
1567 # URxvt again:
1568 bind2maps emacs viins vicmd -- -s '\e\e[C' forward-word
1569 bind2maps emacs viins vicmd -- -s '\e\e[D' backward-word
1570 # Xterm again:
1571 bind2maps emacs viins vicmd -- -s '^[[1;3C' forward-word
1572 bind2maps emacs viins vicmd -- -s '^[[1;3D' backward-word
1573 # Also try ESC Left/Right:
1574 bind2maps emacs viins vicmd -- -s '\e'${key[Right]} forward-word
1575 bind2maps emacs viins vicmd -- -s '\e'${key[Left]}  backward-word
1576
1577 # autoloading
1578
1579 zrcautoload zmv
1580 zrcautoload zed
1581
1582 # we don't want to quote/espace URLs on our own...
1583 # if autoload -U url-quote-magic ; then
1584 #    zle -N self-insert url-quote-magic
1585 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
1586 # else
1587 #    print 'Notice: no url-quote-magic available :('
1588 # fi
1589 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
1590
1591 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
1592 alias run-help >&/dev/null && unalias run-help
1593 for rh in run-help{,-git,-svk,-svn}; do
1594     zrcautoload $rh
1595 done; unset rh
1596
1597 # command not found handling
1598
1599 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1600 function command_not_found_handler() {
1601     emulate -L zsh
1602     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1603         ${GRML_ZSH_CNF_HANDLER} $1
1604     fi
1605     return 1
1606 }
1607
1608 # history
1609
1610 ZSHDIR=${ZDOTDIR:-${HOME}/.zsh}
1611
1612 #v#
1613 HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1614 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1615 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1616
1617 # dirstack handling
1618
1619 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1620 DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1621
1622 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1623     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1624     # "cd -" won't work after login by just setting $OLDPWD, so
1625     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1626 fi
1627
1628 chpwd() {
1629     if (( $DIRSTACKSIZE <= 0 )) || [[ -z $DIRSTACKFILE ]]; then return; fi
1630     local -ax my_stack
1631     my_stack=( ${PWD} ${dirstack} )
1632     if is42 ; then
1633         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1634     else
1635         uprint my_stack >! ${DIRSTACKFILE}
1636     fi
1637 }
1638
1639 # directory based profiles
1640
1641 if is433 ; then
1642
1643 # chpwd_profiles(): Directory Profiles, Quickstart:
1644 #
1645 # In .zshrc.local:
1646 #
1647 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1648 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1649 #   chpwd_profiles
1650 #
1651 # For details see the `grmlzshrc.5' manual page.
1652 function chpwd_profiles() {
1653     local profile context
1654     local -i reexecute
1655
1656     context=":chpwd:profiles:$PWD"
1657     zstyle -s "$context" profile profile || profile='default'
1658     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1659
1660     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1661         typeset -g CHPWD_PROFILE
1662         local CHPWD_PROFILES_INIT=1
1663         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1664     elif [[ $profile != $CHPWD_PROFILE ]]; then
1665         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1666             && chpwd_leave_profile_${CHPWD_PROFILE}
1667     fi
1668     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1669         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1670     fi
1671
1672     CHPWD_PROFILE="${profile}"
1673     return 0
1674 }
1675
1676 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1677
1678 fi # is433
1679
1680 # Prompt setup for grml:
1681
1682 # set colors for use in prompts (modern zshs allow for the use of %F{red}foo%f
1683 # in prompts to get a red "foo" embedded, but it's good to keep these for
1684 # backwards compatibility).
1685 if is437; then
1686     BLUE="%F{blue}"
1687     RED="%F{red}"
1688     GREEN="%F{green}"
1689     CYAN="%F{cyan}"
1690     MAGENTA="%F{magenta}"
1691     YELLOW="%F{yellow}"
1692     WHITE="%F{white}"
1693     NO_COLOR="%f"
1694 elif zrcautoload colors && colors 2>/dev/null ; then
1695     BLUE="%{${fg[blue]}%}"
1696     RED="%{${fg_bold[red]}%}"
1697     GREEN="%{${fg[green]}%}"
1698     CYAN="%{${fg[cyan]}%}"
1699     MAGENTA="%{${fg[magenta]}%}"
1700     YELLOW="%{${fg[yellow]}%}"
1701     WHITE="%{${fg[white]}%}"
1702     NO_COLOR="%{${reset_color}%}"
1703 else
1704     BLUE=$'%{\e[1;34m%}'
1705     RED=$'%{\e[1;31m%}'
1706     GREEN=$'%{\e[1;32m%}'
1707     CYAN=$'%{\e[1;36m%}'
1708     WHITE=$'%{\e[1;37m%}'
1709     MAGENTA=$'%{\e[1;35m%}'
1710     YELLOW=$'%{\e[1;33m%}'
1711     NO_COLOR=$'%{\e[0m%}'
1712 fi
1713
1714 # First, the easy ones: PS2..4:
1715
1716 # secondary prompt, printed when the shell needs more information to complete a
1717 # command.
1718 PS2='\`%_> '
1719 # selection prompt used within a select loop.
1720 PS3='?# '
1721 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1722 PS4='+%N:%i:%_> '
1723
1724 # Some additional features to use with our prompt:
1725 #
1726 #    - battery status
1727 #    - debian_chroot
1728 #    - vcs_info setup and version specific fixes
1729
1730 # display battery status on right side of prompt using 'GRML_DISPLAY_BATTERY=1' in .zshrc.pre
1731
1732 battery() {
1733 if [[ $GRML_DISPLAY_BATTERY -gt 0 ]] ; then
1734     if islinux ; then
1735         batterylinux
1736     elif isopenbsd ; then
1737         batteryopenbsd
1738     elif isfreebsd ; then
1739         batteryfreebsd
1740     elif isdarwin ; then
1741         batterydarwin
1742     else
1743         #not yet supported
1744         GRML_DISPLAY_BATTERY=0
1745     fi
1746 fi
1747 }
1748
1749 batterylinux(){
1750 GRML_BATTERY_LEVEL=''
1751 local batteries bat capacity
1752 batteries=( /sys/class/power_supply/BAT*(N) )
1753 if (( $#batteries > 0 )) ; then
1754     for bat in $batteries ; do
1755         capacity=$(< $bat/capacity)
1756         case $(< $bat/status) in
1757         Charging)
1758             GRML_BATTERY_LEVEL+=" ^"
1759             ;;
1760         Discharging)
1761             if (( capacity < 20 )) ; then
1762                 GRML_BATTERY_LEVEL+=" !v"
1763             else
1764                 GRML_BATTERY_LEVEL+=" v"
1765             fi
1766             ;;
1767         *) # Full, Unknown
1768             GRML_BATTERY_LEVEL+=" ="
1769             ;;
1770         esac
1771         GRML_BATTERY_LEVEL+="${capacity}%%"
1772     done
1773 fi
1774 }
1775
1776 batteryopenbsd(){
1777 GRML_BATTERY_LEVEL=''
1778 local bat batfull batwarn batnow num
1779 for num in 0 1 ; do
1780     bat=$(sysctl -n hw.sensors.acpibat${num} 2>/dev/null)
1781     if [[ -n $bat ]]; then
1782         batfull=${"$(sysctl -n hw.sensors.acpibat${num}.amphour0)"%% *}
1783         batwarn=${"$(sysctl -n hw.sensors.acpibat${num}.amphour1)"%% *}
1784         batnow=${"$(sysctl -n hw.sensors.acpibat${num}.amphour3)"%% *}
1785         case "$(sysctl -n hw.sensors.acpibat${num}.raw0)" in
1786             *" discharging"*)
1787                 if (( batnow < batwarn )) ; then
1788                     GRML_BATTERY_LEVEL+=" !v"
1789                 else
1790                     GRML_BATTERY_LEVEL+=" v"
1791                 fi
1792                 ;;
1793             *" charging"*)
1794                 GRML_BATTERY_LEVEL+=" ^"
1795                 ;;
1796             *)
1797                 GRML_BATTERY_LEVEL+=" ="
1798                 ;;
1799         esac
1800         GRML_BATTERY_LEVEL+="${$(( 100 * batnow / batfull ))%%.*}%%"
1801     fi
1802 done
1803 }
1804
1805 batteryfreebsd(){
1806 GRML_BATTERY_LEVEL=''
1807 local num
1808 local -A table
1809 for num in 0 1 ; do
1810     table=( ${=${${${${${(M)${(f)"$(acpiconf -i $num 2>&1)"}:#(State|Remaining capacity):*}%%( ##|%)}//:[ $'\t']##/@}// /-}//@/ }} )
1811     if [[ -n $table ]] && [[ $table[State] != "not-present" ]] ; then
1812         case $table[State] in
1813             *discharging*)
1814                 if (( $table[Remaining-capacity] < 20 )) ; then
1815                     GRML_BATTERY_LEVEL+=" !v"
1816                 else
1817                     GRML_BATTERY_LEVEL+=" v"
1818                 fi
1819                 ;;
1820             *charging*)
1821                 GRML_BATTERY_LEVEL+=" ^"
1822                 ;;
1823             *)
1824                 GRML_BATTERY_LEVEL+=" ="
1825                 ;;
1826         esac
1827         GRML_BATTERY_LEVEL+="$table[Remaining-capacity]%%"
1828     fi
1829 done
1830 }
1831
1832 batterydarwin(){
1833 GRML_BATTERY_LEVEL=''
1834 local -a table
1835 table=( ${$(pmset -g ps)[(w)7,8]%%(\%|);} )
1836 if [[ -n $table[2] ]] ; then
1837     case $table[2] in
1838         charging)
1839             GRML_BATTERY_LEVEL+=" ^"
1840             ;;
1841         discharging)
1842             if (( $table[1] < 20 )) ; then
1843                 GRML_BATTERY_LEVEL+=" !v"
1844             else
1845                 GRML_BATTERY_LEVEL+=" v"
1846             fi
1847             ;;
1848         *)
1849             GRML_BATTERY_LEVEL+=" ="
1850             ;;
1851     esac
1852     GRML_BATTERY_LEVEL+="$table[1]%%"
1853 fi
1854 }
1855
1856 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1857 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1858     debian_chroot=$(</etc/debian_chroot)
1859 fi
1860
1861 # gather version control information for inclusion in a prompt
1862
1863 if zrcautoload vcs_info; then
1864     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1865     # function, which can cause a lot of trouble with our directory-based
1866     # profiles. So:
1867     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1868         function VCS_INFO_realpath () {
1869             setopt localoptions NO_shwordsplit chaselinks
1870             ( builtin cd -q $1 2> /dev/null && pwd; )
1871         }
1872     fi
1873
1874     zstyle ':vcs_info:*' max-exports 2
1875
1876     if [[ -o restricted ]]; then
1877         zstyle ':vcs_info:*' enable NONE
1878     fi
1879 fi
1880
1881 typeset -A grml_vcs_coloured_formats
1882 typeset -A grml_vcs_plain_formats
1883
1884 grml_vcs_plain_formats=(
1885     format "(%s%)-[%b] "    "zsh: %r"
1886     actionformat "(%s%)-[%b|%a] " "zsh: %r"
1887     rev-branchformat "%b:%r"
1888 )
1889
1890 grml_vcs_coloured_formats=(
1891     format "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR} "
1892     actionformat "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} "
1893     rev-branchformat "%b${RED}:${YELLOW}%r"
1894 )
1895
1896 typeset GRML_VCS_COLOUR_MODE=xxx
1897
1898 grml_vcs_info_toggle_colour () {
1899     emulate -L zsh
1900     if [[ $GRML_VCS_COLOUR_MODE == plain ]]; then
1901         grml_vcs_info_set_formats coloured
1902     else
1903         grml_vcs_info_set_formats plain
1904     fi
1905     return 0
1906 }
1907
1908 grml_vcs_info_set_formats () {
1909     emulate -L zsh
1910     #setopt localoptions xtrace
1911     local mode=$1 AF F BF
1912     if [[ $mode == coloured ]]; then
1913         AF=${grml_vcs_coloured_formats[actionformat]}
1914         F=${grml_vcs_coloured_formats[format]}
1915         BF=${grml_vcs_coloured_formats[rev-branchformat]}
1916         GRML_VCS_COLOUR_MODE=coloured
1917     else
1918         AF=${grml_vcs_plain_formats[actionformat]}
1919         F=${grml_vcs_plain_formats[format]}
1920         BF=${grml_vcs_plain_formats[rev-branchformat]}
1921         GRML_VCS_COLOUR_MODE=plain
1922     fi
1923
1924     zstyle ':vcs_info:*'              actionformats "$AF" "zsh: %r"
1925     zstyle ':vcs_info:*'              formats       "$F"  "zsh: %r"
1926     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat  "$BF"
1927     return 0
1928 }
1929
1930 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1931 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1932 if [[ "$TERM" == dumb ]] ; then
1933     grml_vcs_info_set_formats plain
1934 else
1935     grml_vcs_info_set_formats coloured
1936 fi
1937
1938 # Now for the fun part: The grml prompt themes in `promptsys' mode of operation
1939
1940 # This actually defines three prompts:
1941 #
1942 #    - grml
1943 #    - grml-large
1944 #    - grml-chroot
1945 #
1946 # They all share the same code and only differ with respect to which items they
1947 # contain. The main source of documentation is the `prompt_grml_help' function
1948 # below, which gets called when the user does this: prompt -h grml
1949
1950 function prompt_grml_help () {
1951     <<__EOF0__
1952   prompt grml
1953
1954     This is the prompt as used by the grml-live system <http://grml.org>. It is
1955     a rather simple one-line prompt, that by default looks something like this:
1956
1957         <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1958
1959     The prompt itself integrates with zsh's prompt themes system (as you are
1960     witnessing right now) and is configurable to a certain degree. In
1961     particular, these aspects are customisable:
1962
1963         - The items used in the prompt (e.g. you can remove \`user' from
1964           the list of activated items, which will cause the user name to
1965           be omitted from the prompt string).
1966
1967         - The attributes used with the items are customisable via strings
1968           used before and after the actual item.
1969
1970     The available items are: at, battery, change-root, date, grml-chroot,
1971     history, host, jobs, newline, path, percent, rc, rc-always, sad-smiley,
1972     shell-level, time, user, vcs
1973
1974     The actual configuration is done via zsh's \`zstyle' mechanism. The
1975     context, that is used while looking up styles is:
1976
1977         ':prompt:grml:<left-or-right>:<subcontext>'
1978
1979     Here <left-or-right> is either \`left' or \`right', signifying whether the
1980     style should affect the left or the right prompt. <subcontext> is either
1981     \`setup' or 'items:<item>', where \`<item>' is one of the available items.
1982
1983     The styles:
1984
1985         - use-rprompt (boolean): If \`true' (the default), print a sad smiley
1986           in $RPROMPT if the last command a returned non-successful error code.
1987           (This in only valid if <left-or-right> is "right"; ignored otherwise)
1988
1989         - items (list): The list of items used in the prompt. If \`vcs' is
1990           present in the list, the theme's code invokes \`vcs_info'
1991           accordingly. Default (left): rc change-root user at host path vcs
1992           percent; Default (right): sad-smiley
1993
1994     Available styles in 'items:<item>' are: pre, post. These are strings that
1995     are inserted before (pre) and after (post) the item in question. Thus, the
1996     following would cause the user name to be printed in red instead of the
1997     default blue:
1998
1999         zstyle ':prompt:grml:*:items:user' pre '%F{red}'
2000
2001     Note, that the \`post' style may remain at its default value, because its
2002     default value is '%f', which turns the foreground text attribute off (which
2003     is exactly, what is still required with the new \`pre' value).
2004 __EOF0__
2005 }
2006
2007 function prompt_grml-chroot_help () {
2008     <<__EOF0__
2009   prompt grml-chroot
2010
2011     This is a variation of the grml prompt, see: prompt -h grml
2012
2013     The main difference is the default value of the \`items' style. The rest
2014     behaves exactly the same. Here are the defaults for \`grml-chroot':
2015
2016         - left: grml-chroot user at host path percent
2017         - right: (empty list)
2018 __EOF0__
2019 }
2020
2021 function prompt_grml-large_help () {
2022     <<__EOF0__
2023   prompt grml-large
2024
2025     This is a variation of the grml prompt, see: prompt -h grml
2026
2027     The main difference is the default value of the \`items' style. In
2028     particular, this theme uses _two_ lines instead of one with the plain
2029     \`grml' theme. The rest behaves exactly the same. Here are the defaults
2030     for \`grml-large':
2031
2032         - left: rc jobs history shell-level change-root time date newline user
2033                 at host path vcs percent
2034         - right: sad-smiley
2035 __EOF0__
2036 }
2037
2038 function grml_prompt_setup () {
2039     emulate -L zsh
2040     autoload -Uz vcs_info
2041     # The following autoload is disabled for now, since this setup includes a
2042     # static version of the ‘add-zsh-hook’ function above. It needs to be
2043     # reenabled as soon as that static definition is removed again.
2044     #autoload -Uz add-zsh-hook
2045     add-zsh-hook precmd prompt_$1_precmd
2046 }
2047
2048 function prompt_grml_setup () {
2049     grml_prompt_setup grml
2050 }
2051
2052 function prompt_grml-chroot_setup () {
2053     grml_prompt_setup grml-chroot
2054 }
2055
2056 function prompt_grml-large_setup () {
2057     grml_prompt_setup grml-large
2058 }
2059
2060 # These maps define default tokens and pre-/post-decoration for items to be
2061 # used within the themes. All defaults may be customised in a context sensitive
2062 # matter by using zsh's `zstyle' mechanism.
2063 typeset -gA grml_prompt_pre_default \
2064             grml_prompt_post_default \
2065             grml_prompt_token_default \
2066             grml_prompt_token_function
2067
2068 grml_prompt_pre_default=(
2069     at                ''
2070     battery           ' '
2071     change-root       ''
2072     date              '%F{blue}'
2073     grml-chroot       '%F{red}'
2074     history           '%F{green}'
2075     host              ''
2076     jobs              '%F{cyan}'
2077     newline           ''
2078     path              '%B'
2079     percent           ''
2080     rc                '%B%F{red}'
2081     rc-always         ''
2082     sad-smiley        ''
2083     shell-level       '%F{red}'
2084     time              '%F{blue}'
2085     user              '%B%F{blue}'
2086     vcs               ''
2087 )
2088
2089 grml_prompt_post_default=(
2090     at                ''
2091     battery           ''
2092     change-root       ''
2093     date              '%f'
2094     grml-chroot       '%f '
2095     history           '%f'
2096     host              ''
2097     jobs              '%f'
2098     newline           ''
2099     path              '%b'
2100     percent           ''
2101     rc                '%f%b'
2102     rc-always         ''
2103     sad-smiley        ''
2104     shell-level       '%f'
2105     time              '%f'
2106     user              '%f%b'
2107     vcs               ''
2108 )
2109
2110 grml_prompt_token_default=(
2111     at                '@'
2112     battery           'GRML_BATTERY_LEVEL'
2113     change-root       'debian_chroot'
2114     date              '%D{%Y-%m-%d}'
2115     grml-chroot       'GRML_CHROOT'
2116     history           '{history#%!} '
2117     host              '%m '
2118     jobs              '[%j running job(s)] '
2119     newline           $'\n'
2120     path              '%40<..<%~%<< '
2121     percent           '%# '
2122     rc                '%(?..%? )'
2123     rc-always         '%?'
2124     sad-smiley        '%(?..:()'
2125     shell-level       '%(3L.+ .)'
2126     time              '%D{%H:%M:%S} '
2127     user              '%n'
2128     vcs               '0'
2129 )
2130
2131 function grml_theme_has_token () {
2132     if (( ARGC != 1 )); then
2133         printf 'usage: grml_theme_has_token <name>\n'
2134         return 1
2135     fi
2136     (( ${+grml_prompt_token_default[$1]} ))
2137 }
2138
2139 function GRML_theme_add_token_usage () {
2140     <<__EOF0__
2141   Usage: grml_theme_add_token <name> [-f|-i] <token/function> [<pre> <post>]
2142
2143     <name> is the name for the newly added token. If the \`-f' or \`-i' options
2144     are used, <token/function> is the name of the function (see below for
2145     details). Otherwise it is the literal token string to be used. <pre> and
2146     <post> are optional.
2147
2148   Options:
2149
2150     -f <function>   Use a function named \`<function>' each time the token
2151                     is to be expanded.
2152
2153     -i <function>   Use a function named \`<function>' to initialise the
2154                     value of the token _once_ at runtime.
2155
2156     The functions are called with one argument: the token's new name. The
2157     return value is expected in the \$REPLY parameter. The use of these
2158     options is mutually exclusive.
2159
2160     There is a utility function \`grml_theme_has_token', which you can use
2161     to test if a token exists before trying to add it. This can be a guard
2162     for situations in which a \`grml_theme_add_token' call may happen more
2163     than once.
2164
2165   Example:
2166
2167     To add a new token \`day' that expands to the current weekday in the
2168     current locale in green foreground colour, use this:
2169
2170       grml_theme_add_token day '%D{%A}' '%F{green}' '%f'
2171
2172     Another example would be support for \$VIRTUAL_ENV:
2173
2174       function virtual_env_prompt () {
2175         REPLY=\${VIRTUAL_ENV+\${VIRTUAL_ENV:t} }
2176       }
2177       grml_theme_add_token virtual-env -f virtual_env_prompt
2178
2179     After that, you will be able to use a changed \`items' style to
2180     assemble your prompt.
2181 __EOF0__
2182 }
2183
2184 function grml_theme_add_token () {
2185     emulate -L zsh
2186     local name token pre post
2187     local -i init funcall
2188
2189     if (( ARGC == 0 )); then
2190         GRML_theme_add_token_usage
2191         return 0
2192     fi
2193
2194     init=0
2195     funcall=0
2196     pre=''
2197     post=''
2198     name=$1
2199     shift
2200     if [[ $1 == '-f' ]]; then
2201         funcall=1
2202         shift
2203     elif [[ $1 == '-i' ]]; then
2204         init=1
2205         shift
2206     fi
2207
2208     if (( ARGC == 0 )); then
2209         printf '
2210 grml_theme_add_token: No token-string/function-name provided!\n\n'
2211         GRML_theme_add_token_usage
2212         return 1
2213     fi
2214     token=$1
2215     shift
2216     if (( ARGC != 0 && ARGC != 2 )); then
2217         printf '
2218 grml_theme_add_token: <pre> and <post> need to by specified _both_!\n\n'
2219         GRML_theme_add_token_usage
2220         return 1
2221     fi
2222     if (( ARGC )); then
2223         pre=$1
2224         post=$2
2225         shift 2
2226     fi
2227
2228     if grml_theme_has_token $name; then
2229         printf '
2230 grml_theme_add_token: Token `%s'\'' exists! Giving up!\n\n' $name
2231         GRML_theme_add_token_usage
2232         return 2
2233     fi
2234     if (( init )); then
2235         $token $name
2236         token=$REPLY
2237     fi
2238     grml_prompt_pre_default[$name]=$pre
2239     grml_prompt_post_default[$name]=$post
2240     if (( funcall )); then
2241         grml_prompt_token_function[$name]=$token
2242         grml_prompt_token_default[$name]=23
2243     else
2244         grml_prompt_token_default[$name]=$token
2245     fi
2246 }
2247
2248 function grml_typeset_and_wrap () {
2249     emulate -L zsh
2250     local target="$1"
2251     local new="$2"
2252     local left="$3"
2253     local right="$4"
2254
2255     if (( ${+parameters[$new]} )); then
2256         typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
2257     fi
2258 }
2259
2260 function grml_prompt_addto () {
2261     emulate -L zsh
2262     local target="$1"
2263     local lr it apre apost new v
2264     local -a items
2265     shift
2266
2267     [[ $target == PS1 ]] && lr=left || lr=right
2268     zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
2269     typeset -g "${target}="
2270     for it in "${items[@]}"; do
2271         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
2272             || apre=${grml_prompt_pre_default[$it]}
2273         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" post apost \
2274             || apost=${grml_prompt_post_default[$it]}
2275         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
2276             || new=${grml_prompt_token_default[$it]}
2277         typeset -g "${target}=${(P)target}${apre}"
2278         if (( ${+grml_prompt_token_function[$it]} )); then
2279             ${grml_prompt_token_function[$it]} $it
2280             typeset -g "${target}=${(P)target}${REPLY}"
2281         else
2282             case $it in
2283             battery)
2284                 grml_typeset_and_wrap $target $new '' ''
2285                 ;;
2286             change-root)
2287                 grml_typeset_and_wrap $target $new '(' ')'
2288                 ;;
2289             grml-chroot)
2290                 if [[ -n ${(P)new} ]]; then
2291                     typeset -g "${target}=${(P)target}(CHROOT)"
2292                 fi
2293                 ;;
2294             vcs)
2295                 v="vcs_info_msg_${new}_"
2296                 if (( ! vcscalled )); then
2297                     vcs_info
2298                     vcscalled=1
2299                 fi
2300                 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
2301                     typeset -g "${target}=${(P)target}${(P)v}"
2302                 fi
2303                 ;;
2304             *) typeset -g "${target}=${(P)target}${new}" ;;
2305             esac
2306         fi
2307         typeset -g "${target}=${(P)target}${apost}"
2308     done
2309 }
2310
2311 function prompt_grml_precmd () {
2312     emulate -L zsh
2313     local grmltheme=grml
2314     local -a left_items right_items
2315     left_items=(rc change-root user at host path vcs percent)
2316     right_items=(sad-smiley)
2317
2318     prompt_grml_precmd_worker
2319 }
2320
2321 function prompt_grml-chroot_precmd () {
2322     emulate -L zsh
2323     local grmltheme=grml-chroot
2324     local -a left_items right_items
2325     left_items=(grml-chroot user at host path percent)
2326     right_items=()
2327
2328     prompt_grml_precmd_worker
2329 }
2330
2331 function prompt_grml-large_precmd () {
2332     emulate -L zsh
2333     local grmltheme=grml-large
2334     local -a left_items right_items
2335     left_items=(rc jobs history shell-level change-root time date newline
2336                 user at host path vcs percent)
2337     right_items=(sad-smiley)
2338
2339     prompt_grml_precmd_worker
2340 }
2341
2342 function prompt_grml_precmd_worker () {
2343     emulate -L zsh
2344     local -i vcscalled=0
2345
2346     grml_prompt_addto PS1 "${left_items[@]}"
2347     if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
2348         grml_prompt_addto RPS1 "${right_items[@]}"
2349     fi
2350 }
2351
2352 grml_prompt_fallback() {
2353     setopt prompt_subst
2354     precmd() {
2355         (( ${+functions[vcs_info]} )) && vcs_info
2356     }
2357
2358     p0="${RED}%(?..%? )${WHITE}${debian_chroot:+($debian_chroot)}"
2359     p1="${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "'${vcs_info_msg_0_}'"%# "
2360     if (( EUID == 0 )); then
2361         PROMPT="${BLUE}${p0}${RED}${p1}"
2362     else
2363         PROMPT="${RED}${p0}${BLUE}${p1}"
2364     fi
2365     unset p0 p1
2366 }
2367
2368 if zrcautoload promptinit && promptinit 2>/dev/null ; then
2369     # Since we define the required functions in here and not in files in
2370     # $fpath, we need to stick the theme's name into `$prompt_themes'
2371     # ourselves, since promptinit does not pick them up otherwise.
2372     prompt_themes+=( grml grml-chroot grml-large )
2373     # Also, keep the array sorted...
2374     prompt_themes=( "${(@on)prompt_themes}" )
2375 else
2376     print 'Notice: no promptinit available :('
2377     grml_prompt_fallback
2378 fi
2379
2380 if is437; then
2381     # The prompt themes use modern features of zsh, that require at least
2382     # version 4.3.7 of the shell. Use the fallback otherwise.
2383     if [[ $GRML_DISPLAY_BATTERY -gt 0 ]]; then
2384         zstyle ':prompt:grml:right:setup' items sad-smiley battery
2385         add-zsh-hook precmd battery
2386     fi
2387     if [[ "$TERM" == dumb ]] ; then
2388         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" pre ''
2389         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" post ' '
2390         for i in rc user path jobs history date time shell-level; do
2391             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" pre ''
2392             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" post ''
2393         done
2394         unset i
2395         zstyle ':prompt:grml(|-large|-chroot):right:setup' use-rprompt false
2396     elif (( EUID == 0 )); then
2397         zstyle ':prompt:grml(|-large|-chroot):*:items:user' pre '%B%F{red}'
2398     fi
2399
2400     # Finally enable one of the prompts.
2401     if [[ -n $GRML_CHROOT ]]; then
2402         prompt grml-chroot
2403     elif [[ $GRMLPROMPT -gt 0 ]]; then
2404         prompt grml-large
2405     else
2406         prompt grml
2407     fi
2408 else
2409     grml_prompt_fallback
2410 fi
2411
2412 # Terminal-title wizardry
2413
2414 function ESC_print () {
2415     info_print $'\ek' $'\e\\' "$@"
2416 }
2417 function set_title () {
2418     info_print  $'\e]0;' $'\a' "$@"
2419 }
2420
2421 function info_print () {
2422     local esc_begin esc_end
2423     esc_begin="$1"
2424     esc_end="$2"
2425     shift 2
2426     printf '%s' ${esc_begin}
2427     printf '%s' "$*"
2428     printf '%s' "${esc_end}"
2429 }
2430
2431 function grml_reset_screen_title () {
2432     # adjust title of xterm
2433     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
2434     [[ ${NOTITLE:-} -gt 0 ]] && return 0
2435     case $TERM in
2436         (xterm*|rxvt*)
2437             set_title ${(%):-"%n@%m: %~"}
2438             ;;
2439     esac
2440 }
2441
2442 function grml_vcs_to_screen_title () {
2443     if [[ $TERM == screen* ]] ; then
2444         if [[ -n ${vcs_info_msg_1_} ]] ; then
2445             ESC_print ${vcs_info_msg_1_}
2446         else
2447             ESC_print "zsh"
2448         fi
2449     fi
2450 }
2451
2452 function grml_maintain_name () {
2453     # set hostname if not running on host with name 'grml'
2454     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
2455        NAME="@$HOSTNAME"
2456     fi
2457 }
2458
2459 function grml_cmd_to_screen_title () {
2460     # get the name of the program currently running and hostname of local
2461     # machine set screen window title if running in a screen
2462     if [[ "$TERM" == screen* ]] ; then
2463         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME"
2464         ESC_print ${CMD}
2465     fi
2466 }
2467
2468 function grml_control_xterm_title () {
2469     case $TERM in
2470         (xterm*|rxvt*)
2471             set_title "${(%):-"%n@%m:"}" "$1"
2472             ;;
2473     esac
2474 }
2475
2476 # The following autoload is disabled for now, since this setup includes a
2477 # static version of the ‘add-zsh-hook’ function above. It needs to be
2478 # reenabled as soon as that static definition is removed again.
2479 #zrcautoload add-zsh-hook || add-zsh-hook () { :; }
2480 if [[ $NOPRECMD -eq 0 ]]; then
2481     add-zsh-hook precmd grml_reset_screen_title
2482     add-zsh-hook precmd grml_vcs_to_screen_title
2483     add-zsh-hook preexec grml_maintain_name
2484     add-zsh-hook preexec grml_cmd_to_screen_title
2485     if [[ $NOTITLE -eq 0 ]]; then
2486         add-zsh-hook preexec grml_control_xterm_title
2487     fi
2488 fi
2489
2490 # 'hash' some often used directories
2491 #d# start
2492 hash -d deb=/var/cache/apt/archives
2493 hash -d doc=/usr/share/doc
2494 hash -d linux=/lib/modules/$(command uname -r)/build/
2495 hash -d log=/var/log
2496 hash -d slog=/var/log/syslog
2497 hash -d src=/usr/src
2498 hash -d www=/var/www
2499 #d# end
2500
2501 # some aliases
2502 if check_com -c screen ; then
2503     if [[ $UID -eq 0 ]] ; then
2504         if [[ -r /etc/grml/screenrc ]]; then
2505             alias screen="${commands[screen]} -c /etc/grml/screenrc"
2506         fi
2507     elif [[ -r $HOME/.screenrc ]] ; then
2508         alias screen="${commands[screen]} -c $HOME/.screenrc"
2509     else
2510         if [[ -r /etc/grml/screenrc_grml ]]; then
2511             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
2512         else
2513             if [[ -r /etc/grml/screenrc ]]; then
2514                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
2515             fi
2516         fi
2517     fi
2518 fi
2519
2520 # do we have GNU ls with color-support?
2521 if [[ "$TERM" != dumb ]]; then
2522     #a1# List files with colors (\kbd{ls \ldots})
2523     alias ls="command ls ${ls_options:+${ls_options[*]}}"
2524     #a1# List all files, with colors (\kbd{ls -la \ldots})
2525     alias la="command ls -la ${ls_options:+${ls_options[*]}}"
2526     #a1# List files with long colored list, without dotfiles (\kbd{ls -l \ldots})
2527     alias ll="command ls -l ${ls_options:+${ls_options[*]}}"
2528     #a1# List files with long colored list, human readable sizes (\kbd{ls -hAl \ldots})
2529     alias lh="command ls -hAl ${ls_options:+${ls_options[*]}}"
2530     #a1# List files with long colored list, append qualifier to filenames (\kbd{ls -l \ldots})\\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2531     alias l="command ls -l ${ls_options:+${ls_options[*]}}"
2532 else
2533     alias la='command ls -la'
2534     alias ll='command ls -l'
2535     alias lh='command ls -hAl'
2536     alias l='command ls -l'
2537 fi
2538
2539 alias mdstat='cat /proc/mdstat'
2540 alias ...='cd ../../'
2541
2542 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2543 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2544     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2545 fi
2546
2547 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2548 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2549 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2550
2551 # make sure it is not assigned yet
2552 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
2553 utf2iso() {
2554     if isutfenv ; then
2555         local ENV
2556         for ENV in $(env | command grep -i '.utf') ; do
2557             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2558         done
2559     fi
2560 }
2561
2562 # make sure it is not assigned yet
2563 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
2564 iso2utf() {
2565     if ! isutfenv ; then
2566         local ENV
2567         for ENV in $(env | command grep -i '\.iso') ; do
2568             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2569         done
2570     fi
2571 }
2572
2573 # especially for roadwarriors using GNU screen and ssh:
2574 if ! check_com asc &>/dev/null ; then
2575   asc() { autossh -t "$@" 'screen -RdU' }
2576   compdef asc=ssh
2577 fi
2578
2579 #f1# Hints for the use of zsh on grml
2580 zsh-help() {
2581     print "$bg[white]$fg[black]
2582 zsh-help - hints for use of zsh on grml
2583 =======================================$reset_color"
2584
2585     print '
2586 Main configuration of zsh happens in /etc/zsh/zshrc.
2587 That file is part of the package grml-etc-core, if you want to
2588 use them on a non-grml-system just get the tar.gz from
2589 http://deb.grml.org/ or (preferably) get it from the git repository:
2590
2591   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2592
2593 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2594 The file is still there, but it is empty for backwards compatibility.
2595
2596 For your own changes use these two files:
2597     $HOME/.zshrc.pre
2598     $HOME/.zshrc.local
2599
2600 The former is sourced very early in our zshrc, the latter is sourced
2601 very lately.
2602
2603 System wide configuration without touching configuration files of grml
2604 can take place in /etc/zsh/zshrc.local.
2605
2606 For information regarding zsh start at http://grml.org/zsh/
2607
2608 Take a look at grml'\''s zsh refcard:
2609 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2610
2611 Check out the main zsh refcard:
2612 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2613
2614 And of course visit the zsh-lovers:
2615 % man zsh-lovers
2616
2617 You can adjust some options through environment variables when
2618 invoking zsh without having to edit configuration files.
2619 Basically meant for bash users who are not used to the power of
2620 the zsh yet. :)
2621
2622   "NOCOR=1    zsh" => deactivate automatic correction
2623   "NOMENU=1   zsh" => do not use auto menu completion
2624                       (note: use ctrl-d for completion instead!)
2625   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2626   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2627                       preexec() and precmd() completely
2628   "GRML_DISPLAY_BATTERY=1  zsh"
2629                    => activate battery status on right side of prompt (WIP)
2630   "COMMAND_NOT_FOUND=1 zsh"
2631                    => Enable a handler if an external command was not found
2632                       The command called in the handler can be altered by setting
2633                       the GRML_ZSH_CNF_HANDLER variable, the default is:
2634                       "/usr/share/command-not-found/command-not-found"
2635
2636 A value greater than 0 is enables a feature; a value equal to zero
2637 disables it. If you like one or the other of these settings, you can
2638 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2639 zshrc.'
2640
2641     print "
2642 $bg[white]$fg[black]
2643 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2644 Enjoy your grml system with the zsh!$reset_color"
2645 }
2646
2647 # debian stuff
2648 if [[ -r /etc/debian_version ]] ; then
2649     #a3# Execute \kbd{apt-cache search}
2650     alias acs='apt-cache search'
2651     #a3# Execute \kbd{apt-cache show}
2652     alias acsh='apt-cache show'
2653     #a3# Execute \kbd{apt-cache policy}
2654     alias acp='apt-cache policy'
2655     #a3# Execute \kbd{apt-get dist-upgrade}
2656     salias adg="apt-get dist-upgrade"
2657     #a3# Execute \kbd{apt-get install}
2658     salias agi="apt-get install"
2659     #a3# Execute \kbd{aptitude install}
2660     salias ati="aptitude install"
2661     #a3# Execute \kbd{apt-get upgrade}
2662     salias ag="apt-get upgrade"
2663     #a3# Execute \kbd{apt-get update}
2664     salias au="apt-get update"
2665     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2666     salias -a up="aptitude update ; aptitude safe-upgrade"
2667     #a3# Execute \kbd{dpkg-buildpackage}
2668     alias dbp='dpkg-buildpackage'
2669     #a3# Execute \kbd{grep-excuses}
2670     alias ge='grep-excuses'
2671
2672     # get a root shell as normal user in live-cd mode:
2673     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2674        alias su="sudo su"
2675     fi
2676
2677     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2678     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2679     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2680     salias tlog="tail -f /var/log/syslog"    # follow the syslog
2681 fi
2682
2683 # sort installed Debian-packages by size
2684 if check_com -c dpkg-query ; then
2685     #a3# List installed Debian-packages sorted by size
2686     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
2687 fi
2688
2689 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2690 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
2691     if check_com -c wodim; then
2692         cdrecord() {
2693             <<__EOF0__
2694 cdrecord is not provided under its original name by Debian anymore.
2695 See #377109 in the BTS of Debian for more details.
2696
2697 Please use the wodim binary instead
2698 __EOF0__
2699             return 1
2700         }
2701     fi
2702 fi
2703
2704 # Use hard limits, except for a smaller stack and no core dumps
2705 unlimit
2706 is425 && limit stack 8192
2707 isgrmlcd && limit core 0 # important for a live-cd-system
2708 limit -s
2709
2710 # grmlstuff
2711 grmlstuff() {
2712 # people should use 'grml-x'!
2713     if check_com -c 915resolution; then
2714         855resolution() {
2715             echo "Please use 915resolution as resolution modifying tool for Intel \
2716 graphic chipset."
2717             return -1
2718         }
2719     fi
2720
2721     #a1# Output version of running grml
2722     alias grml-version='cat /etc/grml_version'
2723
2724     if check_com -c grml-debootstrap ; then
2725         debian2hd() {
2726             echo "Installing debian to harddisk is possible by using grml-debootstrap."
2727             return 1
2728         }
2729     fi
2730 }
2731
2732 # now run the functions
2733 isgrml && checkhome
2734 is4    && isgrml    && grmlstuff
2735 is4    && grmlcomp
2736
2737 # keephack
2738 is4 && xsource "/etc/zsh/keephack"
2739
2740 # wonderful idea of using "e" glob qualifier by Peter Stephenson
2741 # You use it as follows:
2742 # $ NTREF=/reference/file
2743 # $ ls -l *(e:nt:)
2744 # This lists all the files in the current directory newer than the reference file.
2745 # You can also specify the reference file inline; note quotes:
2746 # $ ls -l *(e:'nt ~/.zshenv':)
2747 is4 && nt() {
2748     if [[ -n $1 ]] ; then
2749         local NTREF=${~1}
2750     fi
2751     [[ $REPLY -nt $NTREF ]]
2752 }
2753
2754 # shell functions
2755
2756 #f1# Reload an autoloadable function
2757 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2758 compdef _functions freload
2759
2760 #
2761 # Usage:
2762 #
2763 #      e.g.:   a -> b -> c -> d  ....
2764 #
2765 #      sll a
2766 #
2767 #
2768 #      if parameter is given with leading '=', lookup $PATH for parameter and resolve that
2769 #
2770 #      sll =java
2771 #
2772 #      Note: limit for recursive symlinks on linux:
2773 #            http://git.kernel.org/cgit/linux/kernel/git/torvalds/linux.git/tree/fs/namei.c?id=refs/heads/master#l808
2774 #            This limits recursive symlink follows to 8,
2775 #            while limiting consecutive symlinks to 40.
2776 #
2777 #      When resolving and displaying information about symlinks, no check is made
2778 #      that the displayed information does make any sense on your OS.
2779 #      We leave that decission to the user.
2780 #
2781 #      The zstat module is used to detect symlink loops. zstat is available since zsh4.
2782 #      With an older zsh you will need to abort with <C-c> in that case.
2783 #      When a symlink loop is detected, a warning ist printed and further processing is stopped.
2784 #
2785 #      Module zstat is loaded by default in grml zshrc, no extra action needed for that.
2786 #
2787 #      Known bugs:
2788 #      If you happen to come accross a symlink that points to a destination on an other partition
2789 #      with the same inode number, that will be marked as symlink loop though it is not.
2790 #      Two hints for this situation:
2791 #      I)  Play lottery the same day, as you seem to be rather lucky right now.
2792 #      II) Send patches.
2793 #
2794 #      return status:
2795 #      0 upon success
2796 #      1 file/dir not accesible
2797 #      2 symlink loop detected
2798 #
2799 #f1# List symlinks in detail (more detailed version of 'readlink -f', 'whence -s' and 'namei -l')
2800 sll() {
2801     if [[ -z ${1} ]] ; then
2802         printf 'Usage: %s <symlink(s)>\n' "${0}"
2803         return 1
2804     fi
2805
2806     local file jumpd curdir
2807     local -i RTN LINODE i
2808     local -a SEENINODES
2809     curdir="${PWD}"
2810     RTN=0
2811
2812     for file in "${@}" ; do
2813         SEENINODES=()
2814         ls -l "${file:a}"   || RTN=1
2815
2816         while [[ -h "$file" ]] ; do
2817             if is4 ; then
2818                 LINODE=$(zstat -L +inode "${file}")
2819                 for i in ${SEENINODES} ; do
2820                     if (( ${i} == ${LINODE} )) ; then
2821                         builtin cd "${curdir}"
2822                         print "link loop detected, aborting!"
2823                         return 2
2824                     fi
2825                 done
2826                 SEENINODES+=${LINODE}
2827             fi
2828             jumpd="${file:h}"
2829             file="${file:t}"
2830
2831             if [[ -d ${jumpd} ]] ; then
2832                 builtin cd "${jumpd}"  || RTN=1
2833             fi
2834             file=$(readlink "$file")
2835
2836             jumpd="${file:h}"
2837             file="${file:t}"
2838
2839             if [[ -d ${jumpd} ]] ; then
2840                 builtin cd "${jumpd}"  || RTN=1
2841             fi
2842
2843             ls -l "${PWD}/${file}"     || RTN=1
2844         done
2845         shift 1
2846         if (( ${#} >= 1 )) ; then
2847             print ""
2848         fi
2849         builtin cd "${curdir}"
2850     done
2851     return ${RTN}
2852 }
2853
2854 # TODO: Is it supported to use pager settings like this?
2855 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2856 # with respect to wordsplitting. (ie. ${=PAGER})
2857 if check_com -c $PAGER ; then
2858     #f3# View Debian's changelog of given package(s)
2859     dchange() {
2860         emulate -L zsh
2861         [[ -z "$1" ]] && printf 'Usage: %s <package_name(s)>\n' "$0" && return 1
2862
2863         local package
2864         for package in "$@" ; do
2865             if [[ -r /usr/share/doc/${package}/changelog.Debian.gz ]] ; then
2866                 $PAGER /usr/share/doc/${package}/changelog.Debian.gz
2867             elif [[ -r /usr/share/doc/${package}/changelog.gz ]] ; then
2868                 $PAGER /usr/share/doc/${package}/changelog.gz
2869             elif [[ -r /usr/share/doc/${package}/changelog ]] ; then
2870                 $PAGER /usr/share/doc/${package}/changelog
2871             else
2872                 if check_com -c aptitude ; then
2873                     echo "No changelog for package $package found, using aptitude to retrieve it."
2874                     aptitude changelog "$package"
2875                 elif check_com -c apt-get ; then
2876                     echo "No changelog for package $package found, using apt-get to retrieve it."
2877                     apt-get changelog "$package"
2878                 else
2879                     echo "No changelog for package $package found, sorry."
2880                 fi
2881             fi
2882         done
2883     }
2884     _dchange() { _files -W /usr/share/doc -/ }
2885     compdef _dchange dchange
2886
2887     #f3# View Debian's NEWS of a given package
2888     dnews() {
2889         emulate -L zsh
2890         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2891             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2892         else
2893             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2894                 $PAGER /usr/share/doc/$1/NEWS.gz
2895             else
2896                 echo "No NEWS file for package $1 found, sorry."
2897                 return 1
2898             fi
2899         fi
2900     }
2901     _dnews() { _files -W /usr/share/doc -/ }
2902     compdef _dnews dnews
2903
2904     #f3# View Debian's copyright of a given package
2905     dcopyright() {
2906         emulate -L zsh
2907         if [[ -r /usr/share/doc/$1/copyright ]] ; then
2908             $PAGER /usr/share/doc/$1/copyright
2909         else
2910             echo "No copyright file for package $1 found, sorry."
2911             return 1
2912         fi
2913     }
2914     _dcopyright() { _files -W /usr/share/doc -/ }
2915     compdef _dcopyright dcopyright
2916
2917     #f3# View upstream's changelog of a given package
2918     uchange() {
2919         emulate -L zsh
2920         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2921             $PAGER /usr/share/doc/$1/changelog.gz
2922         else
2923             echo "No changelog for package $1 found, sorry."
2924             return 1
2925         fi
2926     }
2927     _uchange() { _files -W /usr/share/doc -/ }
2928     compdef _uchange uchange
2929 fi
2930
2931 # zsh profiling
2932 profile() {
2933     ZSH_PROFILE_RC=1 zsh "$@"
2934 }
2935
2936 #f1# Edit an alias via zle
2937 edalias() {
2938     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2939 }
2940 compdef _aliases edalias
2941
2942 #f1# Edit a function via zle
2943 edfunc() {
2944     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2945 }
2946 compdef _functions edfunc
2947
2948 # use it e.g. via 'Restart apache2'
2949 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2950 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2951 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2952 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2953 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2954 #m# f6 Status() \kbd{/etc/init.d/\em{process}}\quad\kbd{status}
2955 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2956     __start_stop() {
2957         local action_="${1:l}"  # e.g Start/Stop/Restart
2958         local service_="$2"
2959         local param_="$3"
2960
2961         local service_target_="$(readlink /etc/init.d/$service_)"
2962         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2963             # runit
2964             case "${action_}" in
2965                 start) if [[ ! -e /etc/service/$service_ ]]; then
2966                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2967                        else
2968                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2969                        fi ;;
2970                 # there is no reload in runits sysv emulation
2971                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2972                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2973             esac
2974         else
2975             # sysvinit
2976             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2977         fi
2978     }
2979
2980     _grmlinitd() {
2981         local -a scripts
2982         scripts=( /etc/init.d/*(x:t) )
2983         _describe "service startup script" scripts
2984     }
2985
2986     for i in Start Restart Stop Force-Reload Reload Status ; do
2987         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2988         compdef _grmlinitd $i
2989     done
2990     builtin unset -v i
2991 fi
2992
2993 #f1# Provides useful information on globbing
2994 H-Glob() {
2995     echo -e "
2996     /      directories
2997     .      plain files
2998     @      symbolic links
2999     =      sockets
3000     p      named pipes (FIFOs)
3001     *      executable plain files (0100)
3002     %      device files (character or block special)
3003     %b     block special files
3004     %c     character special files
3005     r      owner-readable files (0400)
3006     w      owner-writable files (0200)
3007     x      owner-executable files (0100)
3008     A      group-readable files (0040)
3009     I      group-writable files (0020)
3010     E      group-executable files (0010)
3011     R      world-readable files (0004)
3012     W      world-writable files (0002)
3013     X      world-executable files (0001)
3014     s      setuid files (04000)
3015     S      setgid files (02000)
3016     t      files with the sticky bit (01000)
3017
3018   print *(m-1)          # Files modified up to a day ago
3019   print *(a1)           # Files accessed a day ago
3020   print *(@)            # Just symlinks
3021   print *(Lk+50)        # Files bigger than 50 kilobytes
3022   print *(Lk-50)        # Files smaller than 50 kilobytes
3023   print **/*.c          # All *.c files recursively starting in \$PWD
3024   print **/*.c~file.c   # Same as above, but excluding 'file.c'
3025   print (foo|bar).*     # Files starting with 'foo' or 'bar'
3026   print *~*.*           # All Files that do not contain a dot
3027   chmod 644 *(.^x)      # make all plain non-executable files publically readable
3028   print -l *(.c|.h)     # Lists *.c and *.h
3029   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
3030   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
3031 }
3032 alias help-zshglob=H-Glob
3033
3034 # grep for running process, like: 'any vim'
3035 any() {
3036     emulate -L zsh
3037     unsetopt KSH_ARRAYS
3038     if [[ -z "$1" ]] ; then
3039         echo "any - grep for process(es) by keyword" >&2
3040         echo "Usage: any <keyword>" >&2 ; return 1
3041     else
3042         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
3043     fi
3044 }
3045
3046
3047 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
3048 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
3049 [[ -r /proc/1/maps ]] && \
3050 deswap() {
3051     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
3052     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
3053     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
3054 }
3055
3056 # a wrapper for vim, that deals with title setting
3057 #   VIM_OPTIONS
3058 #       set this array to a set of options to vim you always want
3059 #       to have set when calling vim (in .zshrc.local), like:
3060 #           VIM_OPTIONS=( -p )
3061 #       This will cause vim to send every file given on the
3062 #       commandline to be send to it's own tab (needs vim7).
3063 if check_com vim; then
3064     vim() {
3065         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
3066     }
3067 fi
3068
3069 ssl_hashes=( sha512 sha256 sha1 md5 )
3070
3071 for sh in ${ssl_hashes}; do
3072     eval 'ssl-cert-'${sh}'() {
3073         emulate -L zsh
3074         if [[ -z $1 ]] ; then
3075             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
3076             return 1
3077         fi
3078         openssl x509 -noout -fingerprint -'${sh}' -in $1
3079     }'
3080 done; unset sh
3081
3082 ssl-cert-fingerprints() {
3083     emulate -L zsh
3084     local i
3085     if [[ -z $1 ]] ; then
3086         printf 'usage: ssl-cert-fingerprints <file>\n'
3087         return 1
3088     fi
3089     for i in ${ssl_hashes}
3090         do ssl-cert-$i $1;
3091     done
3092 }
3093
3094 ssl-cert-info() {
3095     emulate -L zsh
3096     if [[ -z $1 ]] ; then
3097         printf 'usage: ssl-cert-info <file>\n'
3098         return 1
3099     fi
3100     openssl x509 -noout -text -in $1
3101     ssl-cert-fingerprints $1
3102 }
3103
3104 # make sure our environment is clean regarding colors
3105 for var in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $var
3106 builtin unset -v var
3107
3108 # "persistent history"
3109 # just write important commands you always need to ~/.important_commands
3110 if [[ -r ~/.important_commands ]] ; then
3111     fc -R ~/.important_commands
3112 fi
3113
3114 # load the lookup subsystem if it's available on the system
3115 zrcautoload lookupinit && lookupinit
3116
3117 # variables
3118
3119 # set terminal property (used e.g. by msgid-chooser)
3120 export COLORTERM="yes"
3121
3122 # aliases
3123
3124 # general
3125 #a2# Execute \kbd{du -sch}
3126 alias da='du -sch'
3127
3128 # listing stuff
3129 #a2# Execute \kbd{ls -lSrah}
3130 alias dir="command ls -lSrah"
3131 #a2# Only show dot-directories
3132 alias lad='command ls -d .*(/)'
3133 #a2# Only show dot-files
3134 alias lsa='command ls -a .*(.)'
3135 #a2# Only files with setgid/setuid/sticky flag
3136 alias lss='command ls -l *(s,S,t)'
3137 #a2# Only show symlinks
3138 alias lsl='command ls -l *(@)'
3139 #a2# Display only executables
3140 alias lsx='command ls -l *(*)'
3141 #a2# Display world-{readable,writable,executable} files
3142 alias lsw='command ls -ld *(R,W,X.^ND/)'
3143 #a2# Display the ten biggest files
3144 alias lsbig="command ls -flh *(.OL[1,10])"
3145 #a2# Only show directories
3146 alias lsd='command ls -d *(/)'
3147 #a2# Only show empty directories
3148 alias lse='command ls -d *(/^F)'
3149 #a2# Display the ten newest files
3150 alias lsnew="command ls -rtlh *(D.om[1,10])"
3151 #a2# Display the ten oldest files
3152 alias lsold="command ls -rtlh *(D.Om[1,10])"
3153 #a2# Display the ten smallest files
3154 alias lssmall="command ls -Srl *(.oL[1,10])"
3155 #a2# Display the ten newest directories and ten newest .directories
3156 alias lsnewdir="command ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
3157 #a2# Display the ten oldest directories and ten oldest .directories
3158 alias lsolddir="command ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
3159
3160 # some useful aliases
3161 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir \$OLDCWD}
3162 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
3163
3164 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3165 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3166 #a2# scp with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3167 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3168
3169 # work around non utf8 capable software in utf environment via $LANG and luit
3170 if check_com isutfenv && check_com luit ; then
3171     if check_com -c mrxvt ; then
3172         isutfenv && [[ -n "$LANG" ]] && \
3173             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3174     fi
3175
3176     if check_com -c aterm ; then
3177         isutfenv && [[ -n "$LANG" ]] && \
3178             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3179     fi
3180
3181     if check_com -c centericq ; then
3182         isutfenv && [[ -n "$LANG" ]] && \
3183             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3184     fi
3185 fi
3186
3187 # useful functions
3188
3189 #f5# Backup \kbd{file_or_folder {\rm to} file_or_folder\_timestamp}
3190 bk() {
3191     emulate -L zsh
3192     local current_date=$(date -u "+%Y-%m-%dT%H:%M:%SZ")
3193     local clean keep move verbose result all to_bk
3194     setopt extended_glob
3195     keep=1
3196     while getopts ":hacmrv" opt; do
3197         case $opt in
3198             a) (( all++ ));;
3199             c) unset move clean && (( ++keep ));;
3200             m) unset keep clean && (( ++move ));;
3201             r) unset move keep && (( ++clean ));;
3202             v) verbose="-v";;
3203             h) <<__EOF0__
3204 bk [-hcmv] FILE [FILE ...]
3205 bk -r [-av] [FILE [FILE ...]]
3206 Backup a file or folder in place and append the timestamp
3207 Remove backups of a file or folder, or all backups in the current directory
3208
3209 Usage:
3210 -h    Display this help text
3211 -c    Keep the file/folder as is, create a copy backup using cp(1) (default)
3212 -m    Move the file/folder, using mv(1)
3213 -r    Remove backups of the specified file or directory, using rm(1). If none
3214       is provided, remove all backups in the current directory.
3215 -a    Remove all (even hidden) backups.
3216 -v    Verbose
3217
3218 The -c, -r and -m options are mutually exclusive. If specified at the same time,
3219 the last one is used.
3220
3221 The return code is the sum of all cp/mv/rm return codes.
3222 __EOF0__
3223 return 0;;
3224             \?) bk -h >&2; return 1;;
3225         esac
3226     done
3227     shift "$((OPTIND-1))"
3228     if (( keep > 0 )); then
3229         if islinux || isfreebsd; then
3230             for to_bk in "$@"; do
3231                 cp $verbose -a "${to_bk%/}" "${to_bk%/}_$current_date"
3232                 (( result += $? ))
3233             done
3234         else
3235             for to_bk in "$@"; do
3236                 cp $verbose -pR "${to_bk%/}" "${to_bk%/}_$current_date"
3237                 (( result += $? ))
3238             done
3239         fi
3240     elif (( move > 0 )); then
3241         while (( $# > 0 )); do
3242             mv $verbose "${1%/}" "${1%/}_$current_date"
3243             (( result += $? ))
3244             shift
3245         done
3246     elif (( clean > 0 )); then
3247         if (( $# > 0 )); then
3248             for to_bk in "$@"; do
3249                 rm $verbose -rf "${to_bk%/}"_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z
3250                 (( result += $? ))
3251             done
3252         else
3253             if (( all > 0 )); then
3254                 rm $verbose -rf *_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z(D)
3255             else
3256                 rm $verbose -rf *_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z
3257             fi
3258             (( result += $? ))
3259         fi
3260     fi
3261     return $result
3262 }
3263
3264 #f5# cd to directoy and list files
3265 cl() {
3266     emulate -L zsh
3267     cd $1 && ls -a
3268 }
3269
3270 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
3271 cd() {
3272     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
3273         [[ ! -e ${1:h} ]] && return 1
3274         print "Correcting ${1} to ${1:h}"
3275         builtin cd ${1:h}
3276     else
3277         builtin cd "$@"
3278     fi
3279 }
3280
3281 #f5# Create Directoy and \kbd{cd} to it
3282 mkcd() {
3283     if (( ARGC != 1 )); then
3284         printf 'usage: mkcd <new-directory>\n'
3285         return 1;
3286     fi
3287     if [[ ! -d "$1" ]]; then
3288         command mkdir -p "$1"
3289     else
3290         printf '`%s'\'' already exists: cd-ing.\n' "$1"
3291     fi
3292     builtin cd "$1"
3293 }
3294
3295 #f5# Create temporary directory and \kbd{cd} to it
3296 cdt() {
3297     builtin cd "$(mktemp -d)"
3298     builtin pwd
3299 }
3300
3301 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
3302 accessed() {
3303     emulate -L zsh
3304     print -l -- *(a-${1:-1})
3305 }
3306
3307 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
3308 changed() {
3309     emulate -L zsh
3310     print -l -- *(c-${1:-1})
3311 }
3312
3313 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
3314 modified() {
3315     emulate -L zsh
3316     print -l -- *(m-${1:-1})
3317 }
3318 # modified() was named new() in earlier versions, add an alias for backwards compatibility
3319 check_com new || alias new=modified
3320
3321 # use colors when GNU grep with color-support
3322 if (( $#grep_options > 0 )); then
3323     o=${grep_options:+"${grep_options[*]}"}
3324     #a2# Execute \kbd{grep -{}-color=auto}
3325     alias grep='grep '$o
3326     alias egrep='egrep '$o
3327     unset o
3328 fi
3329
3330 # Translate DE<=>EN
3331 # 'translate' looks up a word in a file with language-to-language
3332 # translations (field separator should be " : "). A typical wordlist looks
3333 # like the following:
3334 #  | english-word : german-translation
3335 # It's also only possible to translate english to german but not reciprocal.
3336 # Use the following oneliner to reverse the sort order:
3337 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3338 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3339 #f5# Translates a word
3340 trans() {
3341     emulate -L zsh
3342     case "$1" in
3343         -[dD]*)
3344             translate -l de-en $2
3345             ;;
3346         -[eE]*)
3347             translate -l en-de $2
3348             ;;
3349         *)
3350             echo "Usage: $0 { -D | -E }"
3351             echo "         -D == German to English"
3352             echo "         -E == English to German"
3353     esac
3354 }
3355
3356 # Usage: simple-extract <file>
3357 # Using option -d deletes the original archive file.
3358 #f5# Smart archive extractor
3359 simple-extract() {
3360     emulate -L zsh
3361     setopt extended_glob noclobber
3362     local ARCHIVE DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
3363     local RC=0
3364     zparseopts -D -E "d=DELETE_ORIGINAL"
3365     for ARCHIVE in "${@}"; do
3366         case $ARCHIVE in
3367             *(tar.bz2|tbz2|tbz))
3368                 DECOMP_CMD="tar -xvjf -"
3369                 USES_STDIN=true
3370                 USES_STDOUT=false
3371                 ;;
3372             *(tar.gz|tgz))
3373                 DECOMP_CMD="tar -xvzf -"
3374                 USES_STDIN=true
3375                 USES_STDOUT=false
3376                 ;;
3377             *(tar.xz|txz|tar.lzma))
3378                 DECOMP_CMD="tar -xvJf -"
3379                 USES_STDIN=true
3380                 USES_STDOUT=false
3381                 ;;
3382             *tar)
3383                 DECOMP_CMD="tar -xvf -"
3384                 USES_STDIN=true
3385                 USES_STDOUT=false
3386                 ;;
3387             *rar)
3388                 DECOMP_CMD="unrar x"
3389                 USES_STDIN=false
3390                 USES_STDOUT=false
3391                 ;;
3392             *lzh)
3393                 DECOMP_CMD="lha x"
3394                 USES_STDIN=false
3395                 USES_STDOUT=false
3396                 ;;
3397             *7z)
3398                 DECOMP_CMD="7z x"
3399                 USES_STDIN=false
3400                 USES_STDOUT=false
3401                 ;;
3402             *(zip|jar))
3403                 DECOMP_CMD="unzip"
3404                 USES_STDIN=false
3405                 USES_STDOUT=false
3406                 ;;
3407             *deb)
3408                 DECOMP_CMD="ar -x"
3409                 USES_STDIN=false
3410                 USES_STDOUT=false
3411                 ;;
3412             *bz2)
3413                 DECOMP_CMD="bzip2 -d -c -"
3414                 USES_STDIN=true
3415                 USES_STDOUT=true
3416                 ;;
3417             *(gz|Z))
3418                 DECOMP_CMD="gzip -d -c -"
3419                 USES_STDIN=true
3420                 USES_STDOUT=true
3421                 ;;
3422             *(xz|lzma))
3423                 DECOMP_CMD="xz -d -c -"
3424                 USES_STDIN=true
3425                 USES_STDOUT=true
3426                 ;;
3427             *)
3428                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
3429                 RC=$((RC+1))
3430                 continue
3431                 ;;
3432         esac
3433
3434         if ! check_com ${DECOMP_CMD[(w)1]}; then
3435             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
3436             RC=$((RC+2))
3437             continue
3438         fi
3439
3440         GZTARGET="${ARCHIVE:t:r}"
3441         if [[ -f $ARCHIVE ]] ; then
3442
3443             print "Extracting '$ARCHIVE' ..."
3444             if $USES_STDIN; then
3445                 if $USES_STDOUT; then
3446                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
3447                 else
3448                     ${=DECOMP_CMD} < "$ARCHIVE"
3449                 fi
3450             else
3451                 if $USES_STDOUT; then
3452                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
3453                 else
3454                     ${=DECOMP_CMD} "$ARCHIVE"
3455                 fi
3456             fi
3457             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
3458
3459         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
3460             if check_com curl; then
3461                 WGET_CMD="curl -L -s -o -"
3462             elif check_com wget; then
3463                 WGET_CMD="wget -q -O -"
3464             elif check_com fetch; then
3465                 WGET_CMD="fetch -q -o -"
3466             else
3467                 print "ERROR: neither wget, curl nor fetch is installed" >&2
3468                 RC=$((RC+4))
3469                 continue
3470             fi
3471             print "Downloading and Extracting '$ARCHIVE' ..."
3472             if $USES_STDIN; then
3473                 if $USES_STDOUT; then
3474                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
3475                     RC=$((RC+$?))
3476                 else
3477                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
3478                     RC=$((RC+$?))
3479                 fi
3480             else
3481                 if $USES_STDOUT; then
3482                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
3483                 else
3484                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
3485                 fi
3486             fi
3487
3488         else
3489             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
3490             RC=$((RC+8))
3491         fi
3492     done
3493     return $RC
3494 }
3495
3496 __archive_or_uri()
3497 {
3498     _alternative \
3499         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
3500         '_urls:Remote Archives:_urls'
3501 }
3502
3503 _simple_extract()
3504 {
3505     _arguments \
3506         '-d[delete original archivefile after extraction]' \
3507         '*:Archive Or Uri:__archive_or_uri'
3508 }
3509 compdef _simple_extract simple-extract
3510 alias se=simple-extract
3511
3512 #f5# Set all ulimit parameters to \kbd{unlimited}
3513 allulimit() {
3514     ulimit -c unlimited
3515     ulimit -d unlimited
3516     ulimit -f unlimited
3517     ulimit -l unlimited
3518     ulimit -n unlimited
3519     ulimit -s unlimited
3520     ulimit -t unlimited
3521 }
3522
3523 #f5# Change the xterm title from within GNU-screen
3524 xtrename() {
3525     emulate -L zsh
3526     if [[ $1 != "-f" ]] ; then
3527         if [[ -z ${DISPLAY} ]] ; then
3528             printf 'xtrename only makes sense in X11.\n'
3529             return 1
3530         fi
3531     else
3532         shift
3533     fi
3534     if [[ -z $1 ]] ; then
3535         printf 'usage: xtrename [-f] "title for xterm"\n'
3536         printf '  renames the title of xterm from _within_ screen.\n'
3537         printf '  also works without screen.\n'
3538         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3539         return 0
3540     fi
3541     print -n "\eP\e]0;${1}\C-G\e\\"
3542     return 0
3543 }
3544
3545 # Create small urls via http://goo.gl using curl(1).
3546 # API reference: https://code.google.com/apis/urlshortener/
3547 function zurl() {
3548     emulate -L zsh
3549     setopt extended_glob
3550
3551     if [[ -z $1 ]]; then
3552         print "USAGE: zurl <URL>"
3553         return 1
3554     fi
3555
3556     local PN url prog api json contenttype item
3557     local -a data
3558     PN=$0
3559     url=$1
3560
3561     # Prepend 'http://' to given URL where necessary for later output.
3562     if [[ ${url} != http(s|)://* ]]; then
3563         url='http://'${url}
3564     fi
3565
3566     if check_com -c curl; then
3567         prog=curl
3568     else
3569         print "curl is not available, but mandatory for ${PN}. Aborting."
3570         return 1
3571     fi
3572     api='https://www.googleapis.com/urlshortener/v1/url'
3573     contenttype="Content-Type: application/json"
3574     json="{\"longUrl\": \"${url}\"}"
3575     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
3576     # Parse the response
3577     for item in "${data[@]}"; do
3578         case "$item" in
3579             ' '#'"id":'*)
3580                 item=${item#*: \"}
3581                 item=${item%\",*}
3582                 printf '%s\n' "$item"
3583                 return 0
3584                 ;;
3585         esac
3586     done
3587     return 1
3588 }
3589
3590 #f2# Find history events by search pattern and list them by date.
3591 whatwhen()  {
3592     emulate -L zsh
3593     local usage help ident format_l format_s first_char remain first last
3594     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3595     help='Use `whatwhen -h'\'' for further explanations.'
3596     ident=${(l,${#${:-Usage: }},, ,)}
3597     format_l="${ident}%s\t\t\t%s\n"
3598     format_s="${format_l//(\\t)##/\\t}"
3599     # Make the first char of the word to search for case
3600     # insensitive; e.g. [aA]
3601     first_char=[${(L)1[1]}${(U)1[1]}]
3602     remain=${1[2,-1]}
3603     # Default search range is `-100'.
3604     first=${2:-\-100}
3605     # Optional, just used for `<first> <last>' given.
3606     last=$3
3607     case $1 in
3608         ("")
3609             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3610             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3611         ;;
3612         (-h)
3613             printf '%s\n\n' ${usage}
3614             print 'OPTIONS:'
3615             printf $format_l '-h' 'show help text'
3616             print '\f'
3617             print 'SEARCH RANGE:'
3618             printf $format_l "'0'" 'the whole history,'
3619             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
3620             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
3621             printf '\n%s\n' 'EXAMPLES:'
3622             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
3623             printf $format_l 'whatwhen zsh -250'
3624             printf $format_l 'whatwhen foo 1 99'
3625         ;;
3626         (\?)
3627             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3628         ;;
3629         (*)
3630             # -l list results on stout rather than invoking $EDITOR.
3631             # -i Print dates as in YYYY-MM-DD.
3632             # -m Search for a - quoted - pattern within the history.
3633             fc -li -m "*${first_char}${remain}*" $first $last
3634         ;;
3635     esac
3636 }
3637
3638 # mercurial related stuff
3639 if check_com -c hg ; then
3640     # gnu like diff for mercurial
3641     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
3642     #f5# GNU like diff for mercurial
3643     hgdi() {
3644         emulate -L zsh
3645         local i
3646         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
3647     }
3648
3649     # build debian package
3650     #a2# Alias for \kbd{hg-buildpackage}
3651     alias hbp='hg-buildpackage'
3652
3653     # execute commands on the versioned patch-queue from the current repos
3654     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
3655
3656     # diffstat for specific version of a mercurial repository
3657     #   hgstat      => display diffstat between last revision and tip
3658     #   hgstat 1234 => display diffstat between revision 1234 and tip
3659     #f5# Diffstat for specific version of a mercurial repos
3660     hgstat() {
3661         emulate -L zsh
3662         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
3663     }
3664
3665 fi # end of check whether we have the 'hg'-executable
3666
3667 # grml-small cleanups
3668
3669 # The following is used to remove zsh-config-items that do not work
3670 # in grml-small by default.
3671 # If you do not want these adjustments (for whatever reason), set
3672 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
3673 # sources if it is there).
3674
3675 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
3676
3677     unset abk[V]
3678     unalias    'V'      &> /dev/null
3679     unfunction vman     &> /dev/null
3680     unfunction viless   &> /dev/null
3681     unfunction 2html    &> /dev/null
3682
3683     # manpages are not in grmlsmall
3684     unfunction manzsh   &> /dev/null
3685     unfunction man2     &> /dev/null
3686
3687 fi
3688
3689 zrclocal
3690
3691 ## genrefcard.pl settings
3692
3693 ### doc strings for external functions from files
3694 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
3695
3696 ### example: split functions-search 8,16,24,32
3697 #@# split functions-search 8
3698
3699 ## END OF FILE #################################################################
3700 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
3701 # Local variables:
3702 # mode: sh
3703 # End: