etc/zsh/zshrc

   1 # Filename:      zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 # Latest change: Don Okt 18 10:22:10 CEST 2007 [mika]
   7 ################################################################################
   8 # This file is sourced only for interactive shells. It
   9 # should contain commands to set up aliases, functions,
  10 # options, key bindings, etc.
  11 #
  12 # Global Order: zshenv, zprofile, zshrc, zlogin
  13 ################################################################################
  14
  15 # zsh-refcard-tag documentation: {{{
  16 #   You may notice strange looking comments in the zshrc (and ~/.zshrc as
  17 #   well). These are there for a purpose. grml's zsh-refcard can now be
  18 #   automatically generated from the contents of the actual configuration
  19 #   files. However, we need a little extra information on which comments
  20 #   and what lines of code to take into account (and for what purpose).
  21 #
  22 # Here is what they mean:
  23 #
  24 # List of tags (comment types) used:
  25 #   #a#     Next line contains an important alias, that should
  26 #           be included in the grml-zsh-refcard.
  27 #           (placement tag: @@INSERT-aliases@@)
  28 #   #f#     Next line contains the beginning of an important function.
  29 #           (placement tag: @@INSERT-functions@@)
  30 #   #v#     Next line contains an important variable.
  31 #           (placement tag: @@INSERT-variables@@)
  32 #   #k#     Next line contains an important keybinding.
  33 #           (placement tag: @@INSERT-keybindings@@)
  34 #   #d#     Hashed directories list generation:
  35 #               start   denotes the start of a list of 'hash -d'
  36 #                       definitions.
  37 #               end     denotes its end.
  38 #           (placement tag: @@INSERT-hasheddirs@@)
  39 #   #A#     Abbreviation expansion list generation:
  40 #               start   denotes the beginning of abbreviations.
  41 #               end     denotes their end.
  42 #           Lines within this section that end in '#d .*' provide
  43 #           extra documentation to be included in the refcard.
  44 #           (placement tag: @@INSERT-abbrev@@)
  45 #   #m#     This tag allows you to manually generate refcard entries
  46 #           for code lines that are hard/impossible to parse.
  47 #               Example:
  48 #                   #m# k ESC-h Call the run-help function
  49 #               That would add a refcard entry in the keybindings table
  50 #               for 'ESC-h' with the given comment.
  51 #           So the syntax is: #m# <section> <argument> <comment>
  52 #   #o#     This tag lets you insert entries to the 'other' hash.
  53 #           Generally, this should not be used. It is there for
  54 #           things that cannot be done easily in another way.
  55 #           (placement tag: @@INSERT-other-foobar@@)
  56 #
  57 #   All of these tags (except for m and o) take two arguments, the first
  58 #   within the tag, the other after the tag:
  59 #
  60 #   #<tag><section># <comment>
  61 #
  62 #   Where <section> is really just a number, which are defined by the
  63 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  64 #   instead of names is, that for the reader, the tag should not differ
  65 #   much from a regular comment. For zsh, it is a regular comment indeed.
  66 #   The numbers have got the following meanings:
  67 #         0 -> "default"
  68 #         1 -> "system"
  69 #         2 -> "user"
  70 #         3 -> "debian"
  71 #         4 -> "search"
  72 #         5 -> "shortcuts"
  73 #         6 -> "services"
  74 #
  75 #   So, the following will add an entry to the 'functions' table in the
  76 #   'system' section, with a (hopefully) descriptive comment:
  77 #       #f1# Edit an alias via zle
  78 #       edalias() {
  79 #
  80 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  81 #   that can be found in 'grml-zsh-refcard.tex.in'.
  82 #   If the section number is omitted, the 'default' section is assumed.
  83 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
  84 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
  85 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
  86 #}}}
  87
  88 # zsh profiling {{{
  89 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
  90   if [[ -n $ZSH_PROFILE_RC ]] ; then
  91      zmodload zsh/zprof
  92   fi
  93 # }}}
  94
  95 # locale setup {{{
  96   if [ -n "$LANG" ]  ; then
  97      export LANG
  98   else
  99      [ -r /etc/default/locale ] && source /etc/default/locale
 100   fi
 101   [ -n "$LANG" ]          && export LANG || export LANG="en_US.iso885915"
 102   [ -n "$LC_ALL" ]        && export LC_ALL
 103   [ -n "$LC_MESSAGES" ]   && export LC_MESSAGES
 104
 105   [ -r /etc/sysconfig/keyboard ] && source /etc/sysconfig/keyboard
 106   [ -r /etc/timezone ] && TZ=$(cat /etc/timezone)
 107 # }}}
 108
 109 # check for potentially old files in 'completion.d' {{{
 110   setopt extendedglob
 111   xof=(/etc/zsh/completion.d/*~/etc/zsh/completion.d/_*(N))
 112   if (( ${#xof} > 0 )) ; then
 113     printf '\n -!- INFORMATION\n\n'
 114     printf ' -!- %s file(s) not starting with an underscore (_) found in\n' ${#xof}
 115     printf ' -!- /etc/zsh/completion.d/.\n\n'
 116     printf ' -!- While this has been the case in old versions of grml-etc-core,\n'
 117     printf ' -!- recent versions of the grml-zsh-setup have all these files rewritten\n'
 118     printf ' -!- and renamed. Furthermore, the grml-zsh-setup will *only* add files\n'
 119     printf ' -!- named _* to that directory.\n\n'
 120     printf ' -!- If you added functions to completion.d yourself, please consider\n'
 121     printf ' -!- moving them to /etc/zsh/functions.d/. Files in that directory, not\n'
 122     printf ' -!- starting with an underscore are marked for automatic loading\n'
 123     printf ' -!- by default (so that is quite convenient).\n\n'
 124     printf ' -!- If there are files *not* starting with an underscore from an older\n'
 125     printf ' -!- grml-etc-core in completion.d, you may safely remove them.\n\n'
 126     printf ' -!- Delete the files for example via running:\n\n'
 127     printf "      rm ${xof}\n\n"
 128     printf ' -!- Note, that this message will *not* go away, unless you yourself\n'
 129     printf ' -!- resolve the situation manually.\n\n'
 130     BROKEN_COMPLETION_DIR=1
 131   fi
 132   unset xof
 133 # }}}
 134
 135 # {{{ check for version/system
 136 # check for versions (compatibility reasons)
 137   if autoload is-at-least && is-at-least 2>/dev/null ; then
 138      is4() { is-at-least 4 }
 139      is41() { is-at-least 4.1 }
 140      is42() { is-at-least 4.2 }
 141   else
 142     is4(){
 143       [[ $ZSH_VERSION == 4.* ]] && return 0
 144       return 1
 145     }
 146     is42(){
 147       [[ $ZSH_VERSION == 4.<2->* ]] && return 0
 148       return 1
 149     }
 150   fi
 151
 152 # grml specific stuff
 153 #f1# Checks whether or not you're running grml
 154   isgrml(){
 155     [ -f /etc/grml_version ] && return 0
 156     return 1
 157   }
 158
 159 #f1# Checks whether or not you're running a grml cd
 160   isgrmlcd(){
 161     [ -f /etc/grml_cd ] && return 0
 162     return 1
 163   }
 164
 165   if isgrml ; then
 166   #f1# Checks whether or not you're running grml-small
 167     isgrmlsmall() {
 168     [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 169     }
 170   else
 171     isgrmlsmall() { return 1 }
 172   fi
 173
 174 #f1# are we running within an utf environment?
 175   isutfenv() {
 176     case "$LANG $CHARSET $LANGUAGE" in
 177       *utf*) return 0 ;;
 178       *UTF*) return 0 ;;
 179       *)     return 1 ;;
 180     esac
 181   }
 182
 183 # check for user, if not running as root set $SUDO to sudo
 184  (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 185
 186   salias() {
 187     # creates an alias and precedes the command with
 188     # sudo if $EUID is not zero.
 189     local only=0 ; local multi=0
 190     while [[ ${1} == -* ]] ; do
 191       case ${1} in
 192         (-o) only=1 ;;
 193         (-a) multi=1 ;;
 194         (--) shift ; break ;;
 195         (-h)
 196           printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 197           printf '  -h      shows this help text.\n'
 198           printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 199           printf '          be careful using this option.\n'
 200           printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 201           return 0
 202           ;;
 203         (*) printf "unkown option: '%s'\n" "${1}" ; return 1 ;;
 204       esac
 205       shift
 206     done
 207     if (( ${#argv} > 1 )) ; then
 208       printf 'Too many arguments %s\n' "${#argv}"
 209       return 1
 210     fi
 211     key="${1%%\=*}" ;  val="${1#*\=}"
 212     if (( EUID == 0 )) && (( only == 0 )); then
 213       alias -- "${key}=${val}"
 214     elif (( EUID > 0 )) ; then
 215       (( multi > 0 )) && val="${val// ; / ; sudo }"
 216       alias -- "${key}=sudo ${val}"
 217     fi
 218     return 0
 219   }
 220
 221 # change directory to home on first invocation of zsh
 222 # important for rungetty -> autologin
 223 # Thanks go to Bart Schaefer!
 224   isgrml && checkhome() {
 225   if [[ -z "$ALREADY_DID_CD_HOME" ]]; then
 226      export ALREADY_DID_CD_HOME=$HOME
 227      cd
 228   fi
 229   }
 230 # }}}
 231
 232 # {{{ set some variables
 233   #v#
 234   export EDITOR=${EDITOR:-vim}
 235   #v#
 236   export MAIL=${MAIL:-/var/mail/$USER}
 237   # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 238   export SHELL='/bin/zsh'
 239   [ -x $(which dircolors) ] && eval `dircolors -b`
 240
 241 # Search path for the cd command
 242 #  cdpath=(.. ~)
 243
 244 # completion functions go to /etc/zsh/completion.d
 245 # function files may be put into /etc/zsh/functions.d, from where they
 246 # will be automatically autoloaded.
 247   if [ -n "$BROKEN_COMPLETION_DIR" ] ; then
 248      print 'Warning: not setting completion directories because broken files have been found.'>&2
 249   else
 250      [[ -d /etc/zsh/completion.d ]] && fpath+=( /etc/zsh/completion.d )
 251      if [[ -d /etc/zsh/functions.d ]] ; then
 252        fpath+=( /etc/zsh/functions.d )
 253        for func in /etc/zsh/functions.d/[^_]*[^~] ; do
 254          autoload -U ${func:t}
 255        done
 256      fi
 257   fi
 258
 259 # automatically remove duplicates from these arrays
 260   typeset -U path cdpath fpath manpath
 261 # }}}
 262
 263 # {{{ keybindings
 264  if [[ "$TERM" != emacs ]]; then
 265   [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 266   [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 267   [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 268   [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 269   [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 270   [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 271   [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 272   [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 273   [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 274   [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 275   [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 276   [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 277   # ncurses stuff:
 278   [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 279   [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 280   [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 281   [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 282   [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 283   [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 284   [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 285   [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 286 fi
 287
 288 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 289 # use emacs style per default:
 290   bindkey -e
 291 # use vi style:
 292 # bindkey -v
 293
 294 #if [[ "$TERM" == screen ]]; then
 295   bindkey '\e[1~' beginning-of-line       # home
 296   bindkey '\e[4~' end-of-line             # end
 297   bindkey '\e[A'  up-line-or-search       # cursor up
 298   bindkey '\e[B'  down-line-or-search     # <ESC>-
 299   bindkey '^x'    history-beginning-search-backward # alternative ways of searching the shell history
 300 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 301 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 302 # if terminal type is set to 'rxvt':
 303   bindkey '\e[7~' beginning-of-line       # home
 304   bindkey '\e[8~' end-of-line             # end
 305 #fi
 306
 307 # insert unicode character
 308 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 309 # See for example http://unicode.org/charts/ for unicode characters code
 310   autoload insert-unicode-char
 311   zle -N insert-unicode-char
 312   #k# Insert Unicode character
 313   bindkey '^Xi' insert-unicode-char
 314
 315 # just type 'cd ...' to get 'cd ../..'
 316 #  rationalise-dot() {
 317 #  if [[ $LBUFFER = *.. ]]; then
 318 #    LBUFFER+=/..
 319 #  else
 320 #    LBUFFER+=.
 321 #  fi
 322 #  }
 323 #  zle -N rationalise-dot
 324 #  bindkey . rationalise-dot
 325
 326 #  bindkey '\eq' push-line-or-edit
 327 # }}}
 328
 329 # power completion - abbreviation expansion {{{
 330 # power completion / abbreviation expansion / buffer expansion
 331 # see http://zshwiki.org/home/examples/zleiab for details
 332 # less risky than the global aliases but powerful as well
 333 # just type the abbreviation key and afterwards ',.' to expand it
 334   declare -A abk
 335   setopt extendedglob
 336   setopt interactivecomments
 337   abk=(
 338    # key  # value                (#d additional doc string)
 339 #A# start
 340    '...' '../..'
 341    '....' '../../..'
 342    'BG' '& exit'
 343    'C' '| wc -l'
 344    'G' '|& grep --color=auto'
 345    'H' '| head'
 346    'Hl' ' --help |& less -r'      #d (Display help in pager)
 347    'L' '| less'
 348    'LL' '|& less -r'
 349    'M' '| most'
 350    'N' '&>/dev/null'              #d (No Output)
 351    'R' '| tr A-z N-za-m'          #d (ROT13)
 352    'SL' '| sort | less'
 353    'S' '| sort -u'
 354    'T' '| tail'
 355    'V' '|& vim -'
 356 #A# end
 357    'hide' "echo -en '\033]50;nil2\007'"
 358    'tiny' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
 359    'small' 'echo -en "\033]50;6x10\007"'
 360    'medium' 'echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
 361    'default' 'echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
 362    'large' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
 363    'huge' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
 364    'smartfont' 'echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
 365    'semifont' 'echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
 366    'da' 'du -sch'
 367    'j' 'jobs -l'
 368    'u' 'translate -i'
 369    'co' "./configure && make && sudo make install"
 370    'CH' "./configure --help"
 371    'conkeror' 'firefox -chrome chrome://conkeror/content'
 372    'dir' 'ls -lSrah'
 373    'lad' $'ls -d .*(/)\n# only show dot-directories'
 374    'lsa' $'ls -a .*(.)\n# only show dot-files'
 375    'lss' $'ls -l *(s,S,t)\n# only files with setgid/setuid/sticky flag'
 376    'lsl' $'ls -l *(@[1,10])\n# only symlinks'
 377    'lsx' $'ls -l *(*[1,10])\n# only executables'
 378    'lsw' $'ls -ld *(R,W,X.^ND/)\n# world-{readable,writable,executable} files'
 379    'lsbig' $'ls -flh *(.OL[1,10])\n# display the biggest files'
 380    'lsd' $'ls -d *(/)\n# only show directories'
 381    'lse' $'ls -d *(/^F)\n# only show empty directories'
 382    'lsnew' $'ls -rl *(D.om[1,10])\n# display the newest files'
 383    'lsold' $'ls -rtlh *(D.om[-11,-1])\n # display the oldest files'
 384    'lssmall' $'ls -Srl *(.oL[1,10])\n# display the smallest files'
 385    'rw-' 'chmod 600'
 386    '600' 'chmod u+rw-x,g-rwx,o-rwx'
 387    'rwx' 'chmod u+rwx'
 388    '700' 'chmod u+rwx,g-rwx,o-rwx'
 389    'r--' 'chmod u+r-wx,g-rwx,o-rwx'
 390    '644' $'chmod u+rw-x,g+r-wx,o+r-wx\n # 4=r,2=w,1=x'
 391    '755' 'chmod u+rwx,g+r-w+x,o+r-w+x'
 392    'md' 'mkdir -p '
 393    'cmplayer' 'mplayer -vo -fs -zoom fbdev'
 394    'fbmplayer' 'mplayer -vo -fs -zoom fbdev'
 395    'fblinks' 'links2 -driver fb'
 396    'insecssh' 'ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 397    'insecscp' 'scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 398    'fori' 'for i ({..}) { }'
 399    'cx' 'chmod +x'
 400    'e'  'print -l'
 401    'se' 'setopt interactivecomments'
 402    'va' 'valac --vapidir=../vapi/ --pkg=gtk+-2.0 gtktest.vala'
 403    'fb2' '=mplayer -vo fbdev -fs -zoom 1>/dev/null -xy 2'
 404    'fb3' '=mplayer -vo fbdev -fs  -zoom 1>/dev/null -xy 3'
 405    'ci' 'centericq'
 406    'D'  'export DISPLAY=:0.0'
 407    'mp' 'mplayer -vo xv -fs -zoom'
 408   )
 409
 410   globalias () {
 411         local MATCH
 412         matched_chars='[.-|_a-zA-Z0-9]#'
 413         LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 414         LBUFFER+=${abk[$MATCH]:-$MATCH}
 415   }
 416
 417   zle -N globalias
 418   bindkey ",." globalias
 419 # }}}
 420
 421 # {{{ autoloading
 422   autoload -U zmv    # who needs mmv or rename?
 423   autoload history-search-end
 424
 425   # we don't want to quote/espace URLs on our own...
 426   # if autoload -U url-quote-magic ; then
 427   #    zle -N self-insert url-quote-magic
 428   #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 429   # else
 430   #    print 'Notice: no url-quote-magic available :('
 431   # fi
 432   alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 433
 434   #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 435   alias run-help >&/dev/null && unalias run-help
 436   autoload run-help # use via 'esc-h'
 437
 438 # completion system
 439   if autoload -U compinit && compinit 2>/dev/null ; then
 440      compinit 2>/dev/null || print 'Notice: no compinit available :('
 441    else
 442      print 'Notice: no compinit available :('
 443      function zstyle { }
 444      function compdef { }
 445   fi
 446
 447   is4 && autoload -U zed # use ZLE editor to edit a file or function
 448
 449   is4 && for mod in complist deltochar mathfunc ; do
 450              zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 451          done
 452
 453 # autoload zsh modules when they are referenced
 454   if is4 ; then
 455     tmpargs=(
 456       a   stat
 457       a   zpty
 458       ap  zprof
 459       ap  mapfile
 460     )
 461
 462     while (( ${#tmpargs} > 0 )) ; do
 463       zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
 464       shift 2 tmpargs
 465     done
 466     unset tmpargs
 467   fi
 468
 469   is4 && autoload -U insert-files && \
 470   zle -N insert-files && \
 471   #k# Insert files
 472   bindkey "^Xf" insert-files # C-x-f
 473
 474   bindkey ' '   magic-space    # also do history expansion on space
 475   #k# Trigger menu-complete
 476   bindkey '\ei' menu-complete  # menu completion via esc-i
 477
 478 # press esc-e for editing command line in $EDITOR or $VISUAL
 479   is4 && autoload -U edit-command-line && \
 480   zle -N edit-command-line && \
 481   #k# Edit the current line in \kbd{\$EDITOR}
 482   bindkey '\ee' edit-command-line
 483
 484 #k# menu selection: pick item but stay in the menu
 485   is4 && bindkey -M menuselect '\e^M' accept-and-menu-complete
 486
 487 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 488   _bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
 489   #k# Insert a timestamp on the command line (yyyy-mm-dd)
 490   bindkey '^Ed' _bkdate
 491   zle -N _bkdate
 492
 493 # press esc-m for inserting last typed word again (thanks to caphuso!)
 494   insert-last-typed-word() { zle insert-last-word -- 0 -1 }; \
 495   zle -N insert-last-typed-word;
 496   #k# Insert last typed word
 497   bindkey "\em" insert-last-typed-word
 498
 499 # set command prediction from history, see 'man 1 zshcontrib'
 500 #  is4 && autoload -U predict-on && \
 501 #  zle -N predict-on         && \
 502 #  zle -N predict-off        && \
 503 #  bindkey "^X^Z" predict-on && \
 504 #  bindkey "^Z" predict-off
 505
 506 #k# Shortcut for \kbd{fg<enter>}
 507   bindkey -s '^z' "fg\n"
 508
 509 # press ctrl-q to quote line:
 510 #  mquote () {
 511 #        zle beginning-of-line
 512 #        zle forward-word
 513 #        # RBUFFER="'$RBUFFER'"
 514 #        RBUFFER=${(q)RBUFFER}
 515 #        zle end-of-line
 516 #  }
 517 #  zle -N mquote && bindkey '^q' mquote
 518
 519 # run command line as user root via sudo:
 520   sudo-command-line() {
 521     [[ -z $BUFFER ]] && zle up-history
 522     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
 523   }
 524   zle -N sudo-command-line
 525 #k# Put the current command line into a \kbd{sudo} call
 526   bindkey "^Os" sudo-command-line
 527
 528 ### jump behind the first word on the cmdline.
 529 ### useful to add options.
 530   function jump_after_first_word() {
 531     local words
 532     words=(${(z)BUFFER})
 533     if (( ${#words} <= 1 )) ; then
 534       CURSOR=${#BUFFER}
 535     else
 536       CURSOR=${#${words[1]}}
 537     fi
 538   }
 539   zle -N jump_after_first_word
 540   bindkey '^x1' jump_after_first_word
 541
 542 # }}}
 543
 544 # {{{ set some important options
 545 # Please update these tags, if you change the umask settings below.
 546 #o# r_umask     002
 547 #o# r_umaskstr  rwxrwxr-x
 548 #o# umask       022
 549 #o# umaskstr    rwxr-xr-x
 550   (( EUID != 0 )) && umask 002 || umask 022
 551
 552 # history:
 553   setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 554   is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 555   setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 556   is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 557                               # list duplicates an older one, the older command is removed from the list
 558   setopt histignorespace      # remove command lines from the history list when
 559                               # the first character on the line is a space
 560 #  setopt histallowclobber    # add `|' to output redirections in the history
 561 #  setopt NO_clobber          # warning if file exists ('cat /dev/null > ~/.zshrc')
 562   setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 563                               # and the command is the name of a directory, perform the cd command to that directory
 564   setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 565                               # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 566                               # -> searches for word not in compressed files
 567                               # don't forget to quote '^', '~' and '#'!
 568   setopt notify               # report the status of backgrounds jobs immediately
 569   setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 570                               # the entire command path is hashed first.
 571   setopt completeinword       # not just at the end
 572 # setopt nocheckjobs          # don't warn me about bg processes when exiting
 573   setopt nohup                # and don't kill them, either
 574 # setopt printexitvalue       # alert me if something failed
 575 # setopt dvorak               # with spelling correction, assume dvorak kb
 576   setopt auto_pushd           # make cd push the old directory onto the directory stack.
 577   setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 578   setopt nobeep               # avoid "beep"ing
 579   setopt pushd_ignore_dups    # don't push the same dir twice.
 580
 581   MAILCHECK=30       # mailchecks
 582   REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 583   watch=(notme root) # watch for everyone but me and root
 584
 585 # define word separators (for stuff like backward-word, forward-word, backward-kill-word,..)
 586 #  WORDCHARS='*?_-.[]~=/&;!#$%^(){}<>' # the default
 587 #  WORDCHARS=.
 588 #  WORDCHARS='*?_[]~=&;!#$%^(){}'
 589 #  WORDCHARS='${WORDCHARS:s@/@}'
 590
 591 # only slash should be considered as a word separator:
 592   slash-backward-kill-word() {
 593     local WORDCHARS="${WORDCHARS:s@/@}"
 594     # zle backward-word
 595     zle backward-kill-word
 596   }
 597   zle -N slash-backward-kill-word
 598 # press esc-v to delete a word until its last '/' (not the same as ctrl-w!)
 599 #k# Kill everything in a word up to its last \kbd{/}
 600   bindkey '\ev' slash-backward-kill-word
 601 # }}}
 602
 603 # {{{ history
 604   export ZSHDIR=$HOME/.zsh
 605   #v#
 606   HISTFILE=$HOME/.zsh_history
 607   isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
 608   isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
 609 # }}}
 610
 611 # dirstack handling {{{
 612   DIRSTACKSIZE=20
 613   if [[ -f ~/.zdirs ]] && [[ ${#dirstack[*]} -eq 0 ]]; then
 614      dirstack=( ${(f)"$(< ~/.zdirs)"} )
 615      # "cd -" won't work after login by just setting $OLDPWD, so
 616      [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
 617   fi
 618   chpwd() {
 619     builtin dirs -pl >! ~/.zdirs
 620   }
 621 # }}}
 622
 623 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
 624   if [ -n "$BATTERY" ] ; then
 625      if [ -x $(which acpi) ] ; then
 626         PERCENT="${(C)${(s| |)$(acpi 2>/dev/null)}[4]}"
 627         [ -z "$PERCENT" ] && PERCENT='acpi not present'
 628         if [ "${PERCENT%%%}" -lt 20 ] ; then
 629            PERCENT="warning: ${PERCENT}%"
 630         fi
 631      fi
 632   fi
 633 # }}}
 634
 635 # display version control information on right side of prompt if $VCS is set {{{
 636 # based on Mike Hommey's http://web.glandium.org/blog/?p=170
 637   __vcs_dir() {
 638     local vcs base_dir sub_dir ref
 639     sub_dir() {
 640       local sub_dir
 641       sub_dir=$(readlink -f "${PWD}")
 642       sub_dir=${sub_dir#$1}
 643       echo ${sub_dir#/}
 644     }
 645
 646     git_dir() {
 647       base_dir=$(git-rev-parse --show-cdup 2>/dev/null) || return 1
 648       base_dir=$(readlink -f "$base_dir/..")
 649       sub_dir=$(git-rev-parse --show-prefix)
 650       sub_dir=${sub_dir%/}
 651       ref=$(git-symbolic-ref -q HEAD || git-name-rev --name-only HEAD 2>/dev/null)
 652       ref=${ref#refs/heads/}
 653       vcs="git"
 654     }
 655
 656     svn_dir() {
 657       [ -d ".svn" ] || return 1
 658       base_dir="."
 659       while [ -d "$base_dir/../.svn" ]; do base_dir="$base_dir/.."; done
 660       base_dir=$(readlink -f "$base_dir")
 661       sub_dir=$(sub_dir "${base_dir}")
 662       ref=$(svn info "$base_dir" | awk '/^URL/ { sub(".*/","",$0); r=$0 } /^Revision/ { sub("[^0-9]*","",$0); print r":"$0 }')
 663       vcs="svn"
 664     }
 665
 666     svk_dir() {
 667       [ -f ~/.svk/config ] || return 1
 668       base_dir=$(awk '/: *$/ { sub(/^ */,"",$0); sub(/: *$/,"",$0); if (match("'${PWD}'", $0"(/|$)")) { print $0; d=1; } } /depotpath/ && d == 1 { sub(".*/","",$0); r=$0 } /revision/ && d == 1 { print r ":" $2; exit 1 }' ~/.svk/config) && return 1
 669       ref=${base_dir##*
 670   }
 671       base_dir=${base_dir%%
 672   *}
 673       sub_dir=$(sub_dir "${base_dir}")
 674       vcs="svk"
 675     }
 676
 677     hg_dir() {
 678       base_dir="."
 679       while [ ! -d "$base_dir/.hg" ]; do base_dir="$base_dir/.."; [ $(readlink -f "${base_dir}") = "/" ] && return 1; done
 680       base_dir=$(readlink -f "$base_dir")
 681       sub_dir=$(sub_dir "${base_dir}")
 682       ref=$(< "${base_dir}/.hg/branch")
 683       vcs="hg"
 684     }
 685
 686     hg_dir  ||
 687     git_dir ||
 688     svn_dir ||
 689     svk_dir # ||
 690   #  base_dir="$PWD"
 691   #  echo "${vcs:+($vcs)}${base_dir/$HOME/~}${vcs:+[$ref]${sub_dir}}"
 692     echo "${vcs:+($vcs)}${base_dir}${vcs:+[$ref]${sub_dir}}"
 693   }
 694 # }}}
 695
 696 # {{{ set prompt
 697   if autoload promptinit && promptinit 2>/dev/null ; then
 698      promptinit # people should be able to use their favourite prompt
 699   else
 700      print 'Notice: no promptinit available :('
 701   fi
 702
 703
 704 # precmd() => a function which is executed just before each prompt
 705 # use 'NOPRECMD=1' to disable the precmd + preexec commands
 706
 707   # precmd () { setopt promptsubst; [[ -o interactive ]] && jobs -l;
 708
 709   # make sure to use right prompt only when not running a command
 710   is41 && setopt transient_rprompt
 711
 712   is4 && [[ -z $NOPRECMD ]] && precmd () {
 713       [[ -n $NOPRECMD ]] && return 0
 714       # allow manual overwriting of RPROMPT
 715       if [[ -n $RPROMPT ]] ; then
 716          [[ $TERM == screen* ]] && echo -n $'\ekzsh\e\\'
 717          # return 0
 718       fi
 719       # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
 720       if [[ -z $DONTSETRPROMPT ]] ; then
 721          if [[ -n $BATTERY ]] ; then
 722             RPROMPT="%(?..:()% ${PERCENT}${SCREENTITLE}"
 723             # RPROMPT="${PERCENT}${SCREENTITLE}"
 724          elif [[ -n $VCS ]] ; then
 725             RPROMPT="%(?..:()% $(__vcs_dir)${SCREENTITLE}"
 726          else
 727             RPROMPT="%(?..:()% ${SCREENTITLE}"
 728             # RPROMPT="${SCREENTITLE}"
 729          fi
 730       fi
 731       # adjust title of xterm
 732       # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
 733       case $TERM in (xterm*|rxvt)
 734         print -Pn "\e]0;%n@%m: %~\a"
 735         ;;
 736       esac
 737   }
 738
 739 # chpwd () => a function which is executed whenever the directory is changed
 740
 741 # preexec() => a function running before every command
 742   is4 && [[ -z $NOPRECMD ]] && preexec () {
 743       [[ -n $NOPRECMD ]] && return 0
 744   # set hostname if not running on host with name 'grml'
 745       local HOSTNAME=$(hostname)
 746       if [[ "$HOSTNAME" != grml ]] ; then
 747          NAME="@$HOSTNAME"
 748       fi
 749   # get the name of the program currently running and hostname of local machine
 750   # set screen window title if running in a screen
 751       if [[ "$TERM" == screen* ]]; then
 752          # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
 753          local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
 754          echo -ne "\ek$CMD\e\\"
 755       fi
 756   # set the screen title to "zsh" when sitting at the command prompt:
 757       if [[ "$TERM" == screen* ]]; then
 758          SCREENTITLE=$'%{\ekzsh\e\\%}'
 759       else
 760          SCREENTITLE=''
 761       fi
 762   # adjust title of xterm
 763       case $TERM in (xterm*|rxvt)
 764         print -Pn "\e]0;%n@%m: $1\a"
 765         ;;
 766       esac
 767   }
 768
 769 # set colors
 770   if autoload colors && colors 2>/dev/null ; then
 771      BLUE="%{${fg[blue]}%}"
 772      RED="%{${fg_bold[red]}%}"
 773      GREEN="%{${fg[green]}%}"
 774      CYAN="%{${fg[cyan]}%}"
 775      WHITE="%{${fg[white]}%}"
 776      NO_COLOUR="%{${reset_color}%}"
 777   else
 778      BLUE=$'%{\e[1;34m%}'
 779      RED=$'%{\e[1;31m%}'
 780      GREEN=$'%{\e[1;32m%}'
 781      CYAN=$'%{\e[1;36m%}'
 782      WHITE=$'%{\e[1;37m%}'
 783      NO_COLOUR=$'%{\e[0m%}'
 784   fi
 785
 786   EXITCODE="%(?..%?%1v )"
 787   PS2='`%_> '       # secondary prompt, printed when the shell needs more information to complete a command.
 788   PS3='?# '         # selection prompt used within a select loop.
 789   PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
 790
 791   # set variable debian_chroot if running in a chroot with /etc/debian_chroot
 792   if [ -z "$debian_chroot" ] && [ -r /etc/debian_chroot ]; then
 793     debian_chroot=$(cat /etc/debian_chroot)
 794   fi
 795
 796   # don't use colors on dumb terminals (like emacs):
 797   if [[ "$TERM" == dumb ]] ; then
 798      PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< %# "
 799   else
 800     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
 801     # set variable identifying the chroot you work in (used in the prompt below)
 802     if [[ -n $GRMLPROMPT ]]; then
 803       PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
 804 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# "
 805     else
 806       if (( EUID != 0 )); then
 807         PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# " # primary prompt string
 808       else
 809         PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# " # primary prompt string
 810       fi
 811     fi
 812   fi
 813
 814   # if we are inside a grml-chroot set a specific prompt theme
 815   if [ -n "$GRML_CHROOT" ] ; then
 816      PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
 817   fi
 818 # }}}
 819
 820 # {{{ 'hash' some often used directories
 821   #d# start
 822   hash -d deb=/var/cache/apt/archives
 823   hash -d doc=/usr/share/doc
 824   hash -d linux=/lib/modules/$(command uname -r)/build/
 825   hash -d log=/var/log
 826   hash -d slog=/var/log/syslog
 827   hash -d src=/usr/src
 828   hash -d templ=/usr/share/doc/grml-templates
 829   hash -d tt=/usr/share/doc/texttools-doc
 830   hash -d www=/var/www
 831   #d# end
 832 # }}}
 833
 834 # {{{ some aliases
 835   if [ $UID = 0 ] ; then
 836      [ -r /etc/grml/screenrc ] && alias screen='/usr/bin/screen -c /etc/grml/screenrc'
 837   elif [ -r $HOME/.screenrc ] ; then
 838      alias screen="/usr/bin/screen -c $HOME/.screenrc"
 839   else
 840      [ -r /etc/grml/screenrc_grml ] && alias screen='/usr/bin/screen -c /etc/grml/screenrc_grml'
 841   fi
 842
 843   # do we have GNU ls with color-support?
 844   if ls --help 2>/dev/null |grep -- --color= >/dev/null && [ "$TERM" != dumb ] ; then
 845      #a1# execute \kbd{@a@}:\quad ls with colors
 846      alias ls='ls -b -CF --color=auto'
 847      #a1# execute \kbd{@a@}:\quad list all files, with colors
 848      alias la='ls -la --color=auto'
 849      #a1# long colored list, without dotfiles (@a@)
 850      alias ll='ls -l --color=auto'
 851      #a1# long colored list, human readable sizes (@a@)
 852      alias lh='ls -hAl --color=auto'
 853      #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
 854      alias l='ls -lF --color=auto'
 855   else
 856      alias ls='ls -b -CF'
 857      alias la='ls -la'
 858      alias ll='ls -l'
 859      alias lh='ls -hAl'
 860      alias l='ls -lF'
 861   fi
 862
 863   alias mdstat='cat /proc/mdstat'
 864   alias ...='cd ../../'
 865
 866   # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
 867   if [ -x /sbin/kexec -a -r /proc/cmdline ] ; then
 868      alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
 869   fi
 870
 871   alias cp='nocorrect cp'         # no spelling correction on cp
 872   alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
 873   alias mv='nocorrect mv'         # no spelling correction on mv
 874   alias rm='nocorrect rm'         # no spelling correction on rm
 875
 876   #a1# Execute \kbd{rmdir}
 877   alias rd='rmdir'
 878   #a1# Execute \kbd{rmdir}
 879   alias md='mkdir'
 880
 881   # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
 882   alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
 883   alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
 884
 885   # make sure it is not assigned yet
 886   [[ $(whence -w utf2iso &>/dev/null) == 'utf2iso: alias' ]] && unalias utf2iso
 887   utf2iso() {
 888     if isutfenv ; then
 889        for ENV in $(env | command grep -i '.utf') ; do
 890            eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
 891        done
 892      fi
 893   }
 894
 895   # make sure it is not assigned yet
 896   [[ $(whence -w iso2utf &>/dev/null) == 'iso2utf: alias' ]] && unalias iso2utf
 897   iso2utf() {
 898    if ! isutfenv ; then
 899       for ENV in $(env | command grep -i '\.iso') ; do
 900           eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
 901       done
 902    fi
 903  }
 904
 905 # set up software synthesizer via speakup
 906   alias swspeak='
 907     aumix -w 90 -v 90 -p 90 -m 90
 908     if ! [ -r /dev/softsynth ] ; then
 909        flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
 910        return 1
 911     else
 912        setopt singlelinezle
 913        unsetopt prompt_cr
 914        export PS1="%m%# "
 915        nice -n -20 speechd-up
 916        sleep 2
 917        flite -o play -t "Finished setting up software synthesizer"
 918     fi
 919   '
 920
 921 # I like clean prompt, so provide simple way to get that
 922   alias 0 &>/dev/null || functions 0 &>/dev/null || alias 0='return 0'
 923
 924 # for really lazy people like mika:
 925   type S &>/dev/null || alias S='screen'
 926   type s &>/dev/null || alias s='ssh'
 927
 928 # get top 10 shell commands:
 929   alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
 930
 931 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
 932   if [ -x $(which truecrypt) ] ; then
 933      if isutfenv ; then
 934         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
 935      else
 936         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
 937      fi
 938   fi
 939
 940 #f1# Hints for the use of zsh on grml
 941   zsh-help(){print "$bg[white]$fg[black]
 942 zsh-help - hints for use of zsh on grml
 943 =======================================$reset_color
 944
 945 Main configuration of zsh happens in /etc/zsh/zshrc (global)
 946 and /etc/skel/.zshrc which is copied to \$HOME/.zshrc once.
 947 The files are part of the package grml-etc-core, if you want to
 948 use them on a non-grml-system just get the tar.gz from
 949 http://deb.grml.org/ or get the files from the mercurial
 950 repository:
 951
 952   http://hg.grml.org/grml-etc-core/raw-file/tip/etc/skel/.zshrc
 953   http://hg.grml.org/grml-etc-core/raw-file/tip/etc/zsh/zshrc
 954
 955 If you want to stay in sync with zsh configuration of grml
 956 run 'ln -sf /etc/skel/.zshrc \$HOME/.zshrc' and configure
 957 your own stuff in \$HOME/.zshrc.local. System wide configuration
 958 without touching configuration files of grml can take place
 959 in /etc/zsh/zshrc.local.
 960
 961 If you want to use the configuration of user grml also when
 962 running as user root just run 'zshskel' which will source
 963 the file /etc/skel/.zshrc.
 964
 965 For information regarding zsh start at http://grml.org/zsh/
 966
 967 Take a look at grml's zsh refcard:
 968 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
 969
 970 Check out the main zsh refcard:
 971 % $BROWSER http://www.bash2zsh.com/zsh_refcard/refcard.pdf
 972
 973 And of course visit the zsh-lovers:
 974 % man zsh-lovers
 975
 976 You can adjust some options through environment variables when
 977 invoking zsh without having to edit configuration files.
 978 Basically meant for bash users who are not used to the power of
 979 the zsh yet. :)
 980
 981   \"NOCOR=1    zsh\" => deactivate automatic correction
 982   \"NOMENU=1   zsh\" => do not use menu completion (note: use strg-d for completion instead!)
 983   \"NOPRECMD=1 zsh\" => disable the precmd + preexec commands (set GNU screen title)
 984   \"BATTERY=1  zsh\" => activate battery status (via acpi) on right side of prompt
 985 $bg[white]$fg[black]
 986 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
 987 Enjoy your grml system with the zsh!$reset_color"
 988 }
 989
 990 # debian stuff
 991   if [ -r /etc/debian_version ] ; then
 992     #a3# Execute \kbd{apt-cache search}
 993     alias acs='apt-cache search'
 994     #a3# Execute \kbd{apt-cache show}
 995     alias acsh='apt-cache show'
 996     #a3# Execute \kbd{apt-cache policy}
 997     alias acp='apt-cache policy'
 998     #a3# Execute \kbd{apt-get dist-upgrade}
 999     salias adg="apt-get dist-upgrade"
1000     #a3# Execute \kbd{apt-get install}
1001     salias agi="apt-get install"
1002     #a3# Execute \kbd{aptitude install}
1003     salias ati="aptitude install"
1004     #a3# Execute \kbd{apt-get upgrade}
1005     salias ag="apt-get upgrade"
1006     #a3# Execute \kbd{apt-get update}
1007     salias au="apt-get update"
1008     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1009     salias -a up="aptitude update ; aptitude safe-upgrade"
1010     #a3# Execute \kbd{dpkg-buildpackage}
1011     alias dbp='dpkg-buildpackage'
1012     #a3# Execute \kbd{grep-excuses}
1013     alias ge='grep-excuses'
1014
1015     # debian upgrade
1016     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
1017     upgrade () {
1018       if [ -z "$1" ] ; then
1019           $SUDO apt-get update
1020           $SUDO apt-get -u upgrade
1021       else
1022           ssh $1 $SUDO apt-get update
1023           # ask before the upgrade
1024           local dummy
1025           ssh $1 $SUDO apt-get --no-act upgrade
1026           echo -n 'Process the upgrade?'
1027           read -q dummy
1028           if [[ $dummy == "y" ]] ; then
1029               ssh $1 $SUDO apt-get -u upgrade --yes
1030           fi
1031       fi
1032     }
1033
1034     isgrmlcd && alias su="sudo -s"          # get a root shell
1035     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1036     alias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1037     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1038     alias tlog="tail -f /var/log/syslog"    # follow the syslog
1039     #a1# (Re)-source \kbd{/etc/skel/.zshrc}
1040     alias zshskel="source /etc/skel/.zshrc" # source skeleton zshrc
1041   fi
1042
1043 # sort installed Debian-packages by size
1044   if [ -x $(which grep-status) ] ; then
1045      #a3# List installed Debian-packages sorted by size
1046      alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
1047   fi
1048
1049 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1050   if [ -L /usr/bin/cdrecord -o ! -x $(which cdrecord) ] ; then
1051      if [ -x $(which wodim) ] ; then
1052         alias cdrecord="echo 'cdrecord is not provided under its original name by Debian anymore.
1053 See #377109 in the BTS of Debian for more details.
1054
1055 Please use the wodim binary instead' ; return 1"
1056      fi
1057   fi
1058
1059 # get_tw_cli has been renamed into get_3ware
1060   if [ -x $(which get_3ware) ] ; then
1061      get_tw_cli() {
1062        echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
1063        get_3ware
1064      }
1065   fi
1066
1067 # I hate lacking backward compatibility, so provide an alternative therefore
1068   if ! [ -x $(which apache2-ssl-certificate) ] ; then
1069      apache2-ssl-certificate(){
1070
1071      print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
1072      print 'You might want to take a look at Debian the package ssl-cert as well.'
1073      print 'To generate a certificate for use with apache2 follow the instructions:'
1074
1075      echo '
1076
1077 export RANDFILE=/dev/random
1078 mkdir /etc/apache2/ssl/
1079 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
1080 chmod 600 /etc/apache2/ssl/apache.pem
1081
1082 Run "grml-tips ssl-certificate" if you need further instructions.
1083 '
1084    }
1085   fi
1086 # }}}
1087
1088 # {{{ Use hard limits, except for a smaller stack and no core dumps
1089   unlimit
1090   limit stack 8192
1091   isgrmlcd && limit core 0 # important for a live-cd-system
1092   limit -s
1093 # }}}
1094
1095 # {{{ completion stuff
1096
1097 # called later (via is4 && grmlcomp)
1098 # notice: use 'zstyle' for getting current settings
1099 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
1100 grmlcomp() {
1101 ## completion system
1102   zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )' # allow one error for every three characters typed in approximate completer
1103   zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)' # don't complete backup files as executables
1104   zstyle ':completion:*:correct:*'       insert-unambiguous true             # start menu completion only if it could find no unambiguous initial string
1105   zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}' #
1106   zstyle ':completion:*:correct:*'       original true                       #
1107   zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}      # activate color-completion(!)
1108   zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'  # format on completion
1109   zstyle ':completion:*:*:cd:*:directory-stack' menu yes select              # complete 'cd -<tab>' with menu
1110   zstyle ':completion:*:expand:*'        tag-order all-expansions            # insert all expansions for expand completer
1111   zstyle ':completion:*:history-words'   list false                          #
1112   zstyle ':completion:*:history-words'   menu yes                            # activate menu
1113   zstyle ':completion:*:history-words'   remove-all-dups yes                 # ignore duplicate entries
1114   zstyle ':completion:*:history-words'   stop yes                            #
1115   zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'        # match uppercase from lowercase
1116   zstyle ':completion:*:matches'         group 'yes'                         # separate matches into groups
1117   zstyle ':completion:*'                 group-name ''
1118   if [[ -z "$NOMENU" ]] ; then
1119     zstyle ':completion:*'               menu select=5                       # if there are more than 5 options allow selecting from a menu
1120   else
1121     setopt no_auto_menu # don't use any menus at all
1122   fi
1123   zstyle ':completion:*:messages'        format '%d'                         #
1124   zstyle ':completion:*:options'         auto-description '%d'               #
1125   zstyle ':completion:*:options'         description 'yes'                   # describe options in full
1126   zstyle ':completion:*:processes'       command 'ps -au$USER'               # on processes completion complete all user processes
1127   zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters        # offer indexes before parameters in subscripts
1128   zstyle ':completion:*'                 verbose true                        # provide verbose completion information
1129   zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d' # set format for warnings
1130   zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'       # define files to ignore for zcompile
1131   zstyle ':completion:correct:'          prompt 'correct to: %e'             #
1132   zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'    # Ignore completion functions for commands you don't have:
1133
1134 # complete manual by their section
1135   zstyle ':completion:*:manuals'    separate-sections true
1136   zstyle ':completion:*:manuals.*'  insert-sections   true
1137   zstyle ':completion:*:man:*'      menu yes select
1138
1139 ## correction
1140 # run rehash on completion so new installed program are found automatically:
1141   _force_rehash() {
1142       (( CURRENT == 1 )) && rehash
1143          return 1 # Because we didn't really complete anything
1144     }
1145 # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1146   if [[ -n "$NOCOR" ]] ; then
1147     zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1148     setopt nocorrect # do not try to correct the spelling if possible
1149   else
1150 #    zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _ignored _correct _approximate _files
1151     setopt correct  # try to correct the spelling if possible
1152     zstyle -e ':completion:*' completer '
1153         if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]]; then
1154           _last_try="$HISTNO$BUFFER$CURSOR"
1155           reply=(_complete _match _ignored _prefix _files)
1156         else
1157           if [[ $words[1] = (rm|mv) ]]; then
1158             reply=(_complete _files)
1159           else
1160             reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1161           fi
1162         fi'
1163   fi
1164 # zstyle ':completion:*' completer _complete _correct _approximate
1165 # zstyle ':completion:*' expand prefix suffix
1166
1167 # automatic rehash? Credits go to Frank Terbeck
1168 # my_accept() {
1169 #   local buf
1170 #   [[ -z ${BUFFER} ]] && zle accept-line && return
1171 #   buf=( ${(z)BUFFER}  )
1172 #   [[ -z ${commands[${buf[1]}]} ]] && rehash
1173 #   zle accept-line
1174 # }
1175 # zle -N my_accept
1176 # bindkey "^M" my_accept
1177
1178 # command for process lists, the local web server details and host completion
1179   zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1180
1181 # caching
1182   [ -d $ZSHDIR/cache ] && zstyle ':completion:*' use-cache yes && \
1183                           zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1184
1185 # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
1186   if is42 ; then
1187     [ -r ~/.ssh/known_hosts ] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1188     [ -r /etc/hosts ] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1189   else
1190     _ssh_hosts=()
1191     _etc_hosts=()
1192   fi
1193   hosts=(
1194       `hostname`
1195       "$_ssh_hosts[@]"
1196       "$_etc_hosts[@]"
1197       grml.org
1198       localhost
1199   )
1200   zstyle ':completion:*:hosts' hosts $hosts
1201 #  zstyle '*' hosts $hosts
1202
1203 # specify your logins:
1204 # my_accounts=(
1205 #  {grml,grml1}@foo.invalid
1206 #  grml-devel@bar.invalid
1207 # )
1208 # other_accounts=(
1209 #  {fred,root}@foo.invalid
1210 #  vera@bar.invalid
1211 # )
1212 # zstyle ':completion:*:my-accounts' users-hosts $my_accounts
1213 # zstyle ':completion:*:other-accounts' users-hosts $other_accounts
1214
1215 # specify specific port/service settings:
1216 #  telnet_users_hosts_ports=(
1217 #    user1@host1:
1218 #    user2@host2:
1219 #    @mail-server:{smtp,pop3}
1220 #    @news-server:nntp
1221 #    @proxy-server:8000
1222 #  )
1223 # zstyle ':completion:*:*:telnet:*' users-hosts-ports $telnet_users_hosts_ports
1224
1225 # use generic completion system for programs not yet defined:
1226   compdef _gnu_generic tail head feh cp mv df stow uname ipacsum fetchipac
1227
1228 # see upgrade function in this file
1229   compdef _hosts upgrade
1230 }
1231 # }}}
1232
1233 # {{{ grmlstuff
1234 grmlstuff() {
1235 # people should use 'grml-x'!
1236   startx() {
1237     if [ -e /etc/X11/xorg.conf ] ; then
1238        [ -x /usr/bin/startx ] && /usr/bin/startx "$@" || /usr/X11R6/bin/startx "$@"
1239     else
1240       echo "Please use the script \"grml-x\" for starting the X Window System
1241 because there does not exist /etc/X11/xorg.conf yet.
1242 If you want to use startx anyway please call \"/usr/bin/startx\"."
1243       return -1
1244     fi
1245   }
1246
1247   xinit() {
1248     if [ -e /etc/X11/xorg.conf ] ; then
1249        [ -x /usr/bin/xinit ] && /usr/bin/xinit || /usr/X11R6/bin/xinit
1250     else
1251       echo "Please use the script \"grml-x\" for starting the X Window System.
1252 because there does not exist /etc/X11/xorg.conf yet.
1253 If you want to use xinit anyway please call \"/usr/bin/xinit\"."
1254       return -1
1255     fi
1256   }
1257
1258   if [ -x $(which 915resolution) ] ; then
1259      alias 855resolution='echo -e "Please use 915resolution as resolution modify tool for Intel graphic chipset."; return -1'
1260   fi
1261
1262   #a1# Output version of running grml
1263   alias grml-version='cat /etc/grml_version'
1264
1265   if [ -x $(which rebuildfstab) ] ; then
1266      #a1# Rebuild /etc/fstab
1267      alias grml-rebuildfstab='rebuildfstab -v -r -config'
1268   fi
1269
1270   if [ -x $(which grml-debootstrap) ] ; then
1271      alias debian2hd='print "Installing debian to harddisk is possible via using grml-debootstrap." ; return 1'
1272   fi
1273 }
1274 # }}}
1275
1276 # {{{ now run the functions
1277   isgrml && checkhome
1278   is4    && isgrml    && grmlstuff
1279   is4    && grmlcomp
1280 # }}}
1281
1282 # {{{ keephack
1283   [ -r /etc/zsh/keephack ] && is4 && source /etc/zsh/keephack
1284 # }}}
1285
1286 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
1287 # You use it as follows:
1288 # $ NTREF=/reference/file
1289 # $ ls -l *(e:nt:)
1290 # This lists all the files in the current directory newer than the reference file.
1291 # You can also specify the reference file inline; note quotes:
1292 # $ ls -l *(e:'nt ~/.zshenv':)
1293   is4 && nt() {
1294     if [[ -n $1 ]]; then
1295       local NTREF=${~1}
1296     fi
1297     [[ $REPLY -nt $NTREF ]]
1298   }
1299 # }}}
1300
1301 # shell functions {{{
1302   #f1# Provide csh compatibility
1303   setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
1304   #f1# Reload an autoloadable function
1305   freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1306   #f1# Reload zsh setup
1307   reload () {
1308    if [[ "$#*" -eq 0 ]]; then
1309       [ -r ~/.zshrc ] && . ~/.zshrc
1310    else
1311       local fn
1312       for fn in "$@"; do
1313           unfunction $fn
1314           autoload -U $fn
1315       done
1316    fi
1317   }
1318   compdef _functions reload freload
1319
1320   #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1321   sll() {
1322     [ -z "$1" ] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1323     for i in "$@" ; do
1324       file=$i
1325       while [ -h "$file" ] ; do
1326         ls -l $file
1327         file=$(readlink "$file")
1328       done
1329     done
1330   }
1331
1332   # fast manual access
1333   if type -p qma &>/dev/null ; then
1334   #f1# View the zsh manual
1335      manzsh()  { qma zshall "$1" }
1336      compdef _man qma
1337   else
1338      manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
1339      # manzsh()  { /usr/bin/man zshall |  most +/"$1" ; }
1340      # [[ -f ~/.terminfo/m/mostlike ]] && MYLESS='LESS=C TERMINFO=~/.terminfo TERM=mostlike less' || MYLESS='less'
1341      # manzsh()  { man zshall | $MYLESS -p $1 ; }
1342   fi
1343
1344   if [ -x $(which most) ] ; then
1345   #f1# View Debian's changelog of a given package
1346     dchange() {
1347       if [ -r /usr/share/doc/${1}/changelog.Debian.gz ] ; then
1348          most /usr/share/doc/${1}/changelog.Debian.gz
1349       elif [ -r /usr/share/doc/${1}/changelog.gz ] ; then
1350          most /usr/share/doc/${1}/changelog.gz
1351       else
1352          if type -p aptitude &>/dev/null ; then
1353             echo "No changelog for package $1 found, using aptitude to retrieve it."
1354             if isgrml ; then
1355               aptitude -t unstable changelog ${1}
1356             else
1357               aptitude changelog ${1}
1358             fi
1359          else
1360             echo "No changelog for package $1 found, sorry."
1361             return 1
1362          fi
1363       fi
1364     }
1365     _dchange() { _files -W /usr/share/doc -/ }
1366     compdef _dchange dchange
1367
1368   #f1# View Debian's NEWS of a given package
1369     dnews() {
1370       if [ -r /usr/share/doc/${1}/NEWS.Debian.gz ] ; then
1371          most /usr/share/doc/${1}/NEWS.Debian.gz
1372       else
1373          if [ -r /usr/share/doc/${1}/NEWS.gz ] ; then
1374             most /usr/share/doc/${1}/NEWS.gz
1375          else
1376             echo "No NEWS file for package $1 found, sorry."
1377             return 1
1378          fi
1379       fi
1380     }
1381     _dnews() { _files -W /usr/share/doc -/ }
1382     compdef _dnews dnews
1383
1384   #f1# View upstream's changelog of a given package
1385     uchange() {
1386       if [ -r /usr/share/doc/${1}/changelog.gz ] ; then
1387          most /usr/share/doc/${1}/changelog.gz
1388       else
1389          echo "No changelog for package $1 found, sorry."
1390          return 1
1391       fi
1392     }
1393     _uchange() { _files -W /usr/share/doc -/ }
1394     compdef _uchange uchange
1395   fi
1396
1397 # zsh profiling
1398   profile () {
1399       ZSH_PROFILE_RC=1 $SHELL "$@"
1400   }
1401
1402 #f1# Edit an alias via zle
1403   edalias() {
1404     [ -z "$1" ] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1405   }
1406   compdef _aliases edalias
1407
1408 #f1# Edit a function via zle
1409   edfunc() {
1410     [ -z "$1" ] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
1411   }
1412   compdef _functions edfunc
1413
1414 # use it e.g. via 'Restart apache2'
1415 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
1416 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
1417 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
1418 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
1419 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
1420  if [ -d /etc/init.d ] ; then
1421   for i in Start Restart Stop Force-Reload Reload ; do
1422     eval "$i() { $SUDO /etc/init.d/\$1 ${i:l} \$2 ; }"
1423   done
1424  fi
1425
1426   #f1# Provides useful information on globbing
1427   H-Glob() {
1428   echo -e "
1429       /      directories
1430       .      plain files
1431       @      symbolic links
1432       =      sockets
1433       p      named pipes (FIFOs)
1434       *      executable plain files (0100)
1435       %      device files (character or block special)
1436       %b     block special files
1437       %c     character special files
1438       r      owner-readable files (0400)
1439       w      owner-writable files (0200)
1440       x      owner-executable files (0100)
1441       A      group-readable files (0040)
1442       I      group-writable files (0020)
1443       E      group-executable files (0010)
1444       R      world-readable files (0004)
1445       W      world-writable files (0002)
1446       X      world-executable files (0001)
1447       s      setuid files (04000)
1448       S      setgid files (02000)
1449       t      files with the sticky bit (01000)
1450
1451    print *(m-1)          # Files modified up to a day ago
1452    print *(a1)           # Files accessed a day ago
1453    print *(@)            # Just symlinks
1454    print *(Lk+50)        # Files bigger than 50 kilobytes
1455    print *(Lk-50)        # Files smaller than 50 kilobytes
1456    print **/*.c          # All *.c files recursively starting in \$PWD
1457    print **/*.c~file.c   # Same as above, but excluding 'file.c'
1458    print (foo|bar).*     # Files starting with 'foo' or 'bar'
1459    print *~*.*           # All Files that do not contain a dot
1460    chmod 644 *(.^x)      # make all plain non-executable files publically readable
1461    print -l *(.c|.h)     # Lists *.c and *.h
1462    print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
1463    echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
1464   }
1465   alias help-zshglob=H-Glob
1466
1467   type -p qma &>/dev/null && alias ?='qma zshall'
1468
1469   # grep for running process, like: 'any vim'
1470   any() {
1471   if [ -z "$1" ] ; then
1472      echo "any - grep for process(es) by keyword" >&2
1473      echo "Usage: any <keyword>" >&2 ; return 1
1474   else
1475      local STRING=$1
1476      local LENGTH=$(expr length $STRING)
1477      local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
1478      local REST=$(echo $(expr substr $STRING 2 $LENGTH))
1479      ps xauwww| grep "[$FIRSCHAR]$REST"
1480   fi
1481   }
1482
1483   # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
1484   # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
1485   [ -r /proc/1/maps ] && deswap() {
1486      print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
1487      cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
1488      print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
1489   }
1490
1491   # print hex value of a number
1492   hex() {
1493     [ -n "$1" ] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
1494   }
1495
1496   # calculate (or eval at all ;-)) with perl => p[erl-]eval
1497   # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
1498   peval() {
1499     [ -n "$1" ] && CALC="$*" || print "Usage: calc [expression]"
1500     perl -e "print eval($CALC),\"\n\";"
1501   }
1502   functions peval &>/dev/null && alias calc=peval
1503
1504   # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
1505   # certain circumstances, so work around it, no matter which environment we have
1506   brltty() {
1507     if [ -z "$DISPLAY" ] ; then
1508        consolechars -f /usr/share/consolefonts/default8x16.psf.gz
1509        command brltty "$@"
1510     else
1511        command brltty "$@"
1512     fi
1513   }
1514
1515   # just press 'asdf' keys to toggle between dvorak and us keyboard layout
1516   aoeu() {
1517      echo -n 'Switching to us keyboard layout: '
1518      [ -z "$DISPLAY" ] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
1519      echo 'Done'
1520   }
1521   asdf() {
1522      echo -n 'Switching to dvorak keyboard layout: '
1523      [ -z "$DISPLAY" ] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
1524      echo 'Done'
1525   }
1526   # just press 'asdf' key to toggle from neon layout to us keyboard layout
1527   uiae() {
1528      echo -n 'Switching to us keyboard layout: '
1529      setxkbmap us && echo 'Done' || echo 'Failed'
1530   }
1531
1532   # set up an ipv6 tunnel
1533   ipv6-tunnel() {
1534     case $1 in
1535       start)
1536        if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1537           print 'ipv6 tunnel already set up, nothing to be done.'
1538           print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
1539        else
1540           [ -n "$PUBLIC_IP" ] || local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
1541                                              awk '/inet addr:/ {print $2}' | tr -d 'addr:')
1542           [ -n "$PUBLIC_IP" ] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
1543           local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
1544           print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
1545           ifconfig sit0 tunnel ::192.88.99.1 up
1546           ifconfig sit1 add "$IPV6ADDR" && print done || print failed
1547        fi
1548        ;;
1549       status)
1550        if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1551           print 'ipv6 tunnel available' ; return 0
1552        else
1553           print 'ipv6 tunnel not available' ; return 1
1554        fi
1555        ;;
1556       stop)
1557        if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
1558           print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
1559           ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
1560        else
1561           print 'No ipv6 tunnel found, nothing to be done.' ; return 1
1562        fi
1563        ;;
1564       *)
1565        print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
1566        ;;
1567     esac
1568   }
1569
1570   # run dhclient for wireless device
1571   iwclient() {
1572     salias dhclient "$(wavemon -d | awk '/device/{print $2}')"
1573   }
1574
1575   # spawn a minimally set up ksh - useful if you want to umount /usr/.
1576   minimal-shell() {
1577     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ksh
1578   }
1579
1580   # make a backup of a file
1581   bk() {
1582     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
1583   }
1584
1585   # Switching shell safely and efficiently? http://www.zsh.org/mla/workers/2001/msg02410.html
1586   # bash() {
1587   #  NO_SWITCH="yes" command bash "$@"
1588   # }
1589   # restart () {
1590   #  exec $SHELL $SHELL_ARGS "$@"
1591   # }
1592
1593 # }}}
1594
1595 # log out? set timeout in seconds {{{
1596 # TMOUT=1800
1597 # do not log out in some specific terminals:
1598 #  if [[ "${TERM}" == ([Exa]term*|rxvt|dtterm|screen*) ]]; then
1599 #    unset TMOUT
1600 #  fi
1601 # }}}
1602
1603 # {{{ make sure our environment is clean regarding colors
1604   for color in BLUE RED GREEN CYAN WHITE ; unset $color
1605 # }}}
1606
1607 # source another config file if present {{{
1608   if [ -r /etc/zsh/zshrc.local ]; then
1609    source /etc/zsh/zshrc.local
1610   fi
1611 # }}}
1612
1613 # "persistent history" {{{
1614 # just write important commands you always need to ~/.important_commands
1615   if [ -r ~/.important_commands ] ; then
1616      fc -R ~/.important_commands
1617   fi
1618 # }}}
1619
1620 ## genrefcard.pl settings {{{
1621 ### example: split functions-search 8,16,24,32
1622 #@# split functions-search 8
1623 ## }}}
1624
1625 # add variable to be able to check whether the file has been read {{{
1626   ZSHRC_GLOBAL_HAS_BEEN_READ=1
1627 # }}}
1628
1629 ## END OF FILE #################################################################
1630 # vim:foldmethod=marker expandtab