etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is439(){
 148     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 #f1# Checks whether or not you're running grml
 154 isgrml(){
 155     [[ -f /etc/grml_version ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running a grml cd
 160 isgrmlcd(){
 161     [[ -f /etc/grml_cd ]] && return 0
 162     return 1
 163 }
 164
 165 if isgrml ; then
 166 #f1# Checks whether or not you're running grml-small
 167     isgrmlsmall() {
 168         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 169             return 0
 170         fi
 171         return 1
 172     }
 173 else
 174     isgrmlsmall() { return 1 }
 175 fi
 176
 177 isdarwin(){
 178     [[ $OSTYPE == darwin* ]] && return 0
 179     return 1
 180 }
 181
 182 isfreebsd(){
 183     [[ $OSTYPE == freebsd* ]] && return 0
 184     return 1
 185 }
 186
 187 #f1# are we running within an utf environment?
 188 isutfenv() {
 189     case "$LANG $CHARSET $LANGUAGE" in
 190         *utf*) return 0 ;;
 191         *UTF*) return 0 ;;
 192         *)     return 1 ;;
 193     esac
 194 }
 195
 196 # check for user, if not running as root set $SUDO to sudo
 197 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 198
 199 # change directory to home on first invocation of zsh
 200 # important for rungetty -> autologin
 201 # Thanks go to Bart Schaefer!
 202 isgrml && checkhome() {
 203     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 204         export ALREADY_DID_CD_HOME=$HOME
 205         cd
 206     fi
 207 }
 208
 209 # check for zsh v3.1.7+
 210
 211 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 212      || ${ZSH_VERSION} == 3.<2->.<->*    \
 213      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 214
 215     printf '-!-\n'
 216     printf '-!- In this configuration we try to make use of features, that only\n'
 217     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 218     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 219     printf '-!- advanced features in all supported versions.\n'
 220     printf '-!-\n'
 221     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 222     printf '-!-\n'
 223     printf '-!- While this *may* work, it might as well fail.\n'
 224     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 225     printf '-!-\n'
 226     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 227     printf '-!- If it does today, you'\''ve been lucky.\n'
 228     printf '-!-\n'
 229     printf '-!- Ye been warned!\n'
 230     printf '-!-\n'
 231
 232     function zstyle() { : }
 233 fi
 234
 235 # autoload wrapper - use this one instead of autoload directly
 236 # We need to define this function as early as this, because autoloading
 237 # 'is-at-least()' needs it.
 238 function zrcautoload() {
 239     emulate -L zsh
 240     setopt extended_glob
 241     local fdir ffile
 242     local -i ffound
 243
 244     ffile=$1
 245     (( ffound = 0 ))
 246     for fdir in ${fpath} ; do
 247         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 248     done
 249
 250     (( ffound == 0 )) && return 1
 251     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 252         autoload -U ${ffile} || return 1
 253     else
 254         autoload ${ffile} || return 1
 255     fi
 256     return 0
 257 }
 258
 259 # Load is-at-least() for more precise version checks Note that this test will
 260 # *always* fail, if the is-at-least function could not be marked for
 261 # autoloading.
 262 zrcautoload is-at-least || is-at-least() { return 1 }
 263
 264 # set some important options (as early as possible)
 265
 266 # append history list to the history file; this is the default but we make sure
 267 # because it's required for share_history.
 268 setopt append_history
 269
 270 # import new commands from the history file also in other zsh-session
 271 is4 && setopt share_history
 272
 273 # save each command's beginning timestamp and the duration to the history file
 274 setopt extended_history
 275
 276 # If a new command line being added to the history list duplicates an older
 277 # one, the older command is removed from the list
 278 is4 && setopt histignorealldups
 279
 280 # remove command lines from the history list when the first character on the
 281 # line is a space
 282 setopt histignorespace
 283
 284 # if a command is issued that can't be executed as a normal command, and the
 285 # command is the name of a directory, perform the cd command to that directory.
 286 setopt auto_cd
 287
 288 # in order to use #, ~ and ^ for filename generation grep word
 289 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 290 # don't forget to quote '^', '~' and '#'!
 291 setopt extended_glob
 292
 293 # display PID when suspending processes as well
 294 setopt longlistjobs
 295
 296 # try to avoid the 'zsh: no matches found...'
 297 setopt nonomatch
 298
 299 # report the status of backgrounds jobs immediately
 300 setopt notify
 301
 302 # whenever a command completion is attempted, make sure the entire command path
 303 # is hashed first.
 304 setopt hash_list_all
 305
 306 # not just at the end
 307 setopt completeinword
 308
 309 # Don't send SIGHUP to background processes when the shell exits.
 310 setopt nohup
 311
 312 # make cd push the old directory onto the directory stack.
 313 setopt auto_pushd
 314
 315 # avoid "beep"ing
 316 setopt nobeep
 317
 318 # don't push the same dir twice.
 319 setopt pushd_ignore_dups
 320
 321 # * shouldn't match dotfiles. ever.
 322 setopt noglobdots
 323
 324 # use zsh style word splitting
 325 setopt noshwordsplit
 326
 327 # don't error out when unset parameters are used
 328 setopt unset
 329
 330 # setting some default values
 331 NOCOR=${NOCOR:-0}
 332 NOMENU=${NOMENU:-0}
 333 NOPRECMD=${NOPRECMD:-0}
 334 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 335 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 336 BATTERY=${BATTERY:-0}
 337 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 338 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 339
 340 typeset -ga ls_options
 341 typeset -ga grep_options
 342 if ls --help 2> /dev/null | grep -q GNU; then
 343     ls_options=( --color=auto )
 344 elif [[ $OSTYPE == freebsd* ]]; then
 345     ls_options=( -G )
 346 fi
 347 if grep --help 2> /dev/null | grep -q GNU || \
 348    [[ $OSTYPE == freebsd* ]]; then
 349     grep_options=( --color=auto )
 350 fi
 351
 352 # utility functions
 353 # this function checks if a command exists and returns either true
 354 # or false. This avoids using 'which' and 'whence', which will
 355 # avoid problems with aliases for which on certain weird systems. :-)
 356 # Usage: check_com [-c|-g] word
 357 #   -c  only checks for external commands
 358 #   -g  does the usual tests and also checks for global aliases
 359 check_com() {
 360     emulate -L zsh
 361     local -i comonly gatoo
 362
 363     if [[ $1 == '-c' ]] ; then
 364         (( comonly = 1 ))
 365         shift
 366     elif [[ $1 == '-g' ]] ; then
 367         (( gatoo = 1 ))
 368     else
 369         (( comonly = 0 ))
 370         (( gatoo = 0 ))
 371     fi
 372
 373     if (( ${#argv} != 1 )) ; then
 374         printf 'usage: check_com [-c] <command>\n' >&2
 375         return 1
 376     fi
 377
 378     if (( comonly > 0 )) ; then
 379         [[ -n ${commands[$1]}  ]] && return 0
 380         return 1
 381     fi
 382
 383     if   [[ -n ${commands[$1]}    ]] \
 384       || [[ -n ${functions[$1]}   ]] \
 385       || [[ -n ${aliases[$1]}     ]] \
 386       || [[ -n ${reswords[(r)$1]} ]] ; then
 387
 388         return 0
 389     fi
 390
 391     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 392         return 0
 393     fi
 394
 395     return 1
 396 }
 397
 398 # creates an alias and precedes the command with
 399 # sudo if $EUID is not zero.
 400 salias() {
 401     emulate -L zsh
 402     local only=0 ; local multi=0
 403     while [[ $1 == -* ]] ; do
 404         case $1 in
 405             (-o) only=1 ;;
 406             (-a) multi=1 ;;
 407             (--) shift ; break ;;
 408             (-h)
 409                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 410                 printf '  -h      shows this help text.\n'
 411                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 412                 printf '          be careful using this option.\n'
 413                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 414                 return 0
 415                 ;;
 416             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 417         esac
 418         shift
 419     done
 420
 421     if (( ${#argv} > 1 )) ; then
 422         printf 'Too many arguments %s\n' "${#argv}"
 423         return 1
 424     fi
 425
 426     key="${1%%\=*}" ;  val="${1#*\=}"
 427     if (( EUID == 0 )) && (( only == 0 )); then
 428         alias -- "${key}=${val}"
 429     elif (( EUID > 0 )) ; then
 430         (( multi > 0 )) && val="${val// ; / ; sudo }"
 431         alias -- "${key}=sudo ${val}"
 432     fi
 433
 434     return 0
 435 }
 436
 437 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 438 # usage: uprint foo
 439 #   Where foo is the *name* of the parameter you want printed.
 440 #   Note that foo is no typo; $foo would be wrong here!
 441 if ! is42 ; then
 442     uprint () {
 443         emulate -L zsh
 444         local -a u
 445         local w
 446         local parameter=$1
 447
 448         if [[ -z ${parameter} ]] ; then
 449             printf 'usage: uprint <parameter>\n'
 450             return 1
 451         fi
 452
 453         for w in ${(P)parameter} ; do
 454             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 455         done
 456
 457         builtin print -l $u
 458     }
 459 fi
 460
 461 # Check if we can read given files and source those we can.
 462 xsource() {
 463     if (( ${#argv} < 1 )) ; then
 464         printf 'usage: xsource FILE(s)...\n' >&2
 465         return 1
 466     fi
 467
 468     while (( ${#argv} > 0 )) ; do
 469         [[ -r "$1" ]] && source "$1"
 470         shift
 471     done
 472     return 0
 473 }
 474
 475 # Check if we can read a given file and 'cat(1)' it.
 476 xcat() {
 477     emulate -L zsh
 478     if (( ${#argv} != 1 )) ; then
 479         printf 'usage: xcat FILE\n' >&2
 480         return 1
 481     fi
 482
 483     [[ -r $1 ]] && cat $1
 484     return 0
 485 }
 486
 487 # Remove these functions again, they are of use only in these
 488 # setup files. This should be called at the end of .zshrc.
 489 xunfunction() {
 490     emulate -L zsh
 491     local -a funcs
 492     funcs=(salias xcat xsource xunfunction zrcautoload)
 493
 494     for func in $funcs ; do
 495         [[ -n ${functions[$func]} ]] \
 496             && unfunction $func
 497     done
 498     return 0
 499 }
 500
 501 # this allows us to stay in sync with grml's zshrc and put own
 502 # modifications in ~/.zshrc.local
 503 zrclocal() {
 504     xsource "/etc/zsh/zshrc.local"
 505     xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
 506     return 0
 507 }
 508
 509 # locale setup
 510 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 511     xsource "/etc/default/locale"
 512 fi
 513
 514 for var in LANG LC_ALL LC_MESSAGES ; do
 515     [[ -n ${(P)var} ]] && export $var
 516 done
 517
 518 xsource "/etc/sysconfig/keyboard"
 519
 520 TZ=$(xcat /etc/timezone)
 521
 522 # set some variables
 523 if check_com -c vim ; then
 524 #v#
 525     export EDITOR=${EDITOR:-vim}
 526 else
 527     export EDITOR=${EDITOR:-vi}
 528 fi
 529
 530 #v#
 531 export PAGER=${PAGER:-less}
 532
 533 #v#
 534 export MAIL=${MAIL:-/var/mail/$USER}
 535
 536 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 537 export SHELL='/bin/zsh'
 538
 539 # color setup for ls:
 540 check_com -c dircolors && eval $(dircolors -b)
 541 # color setup for ls on OS X / FreeBSD:
 542 isdarwin && export CLICOLOR=1
 543 isfreebsd && export CLICOLOR=1
 544
 545 # do MacPorts setup on darwin
 546 if isdarwin && [[ -d /opt/local ]]; then
 547     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 548     # zshenv.
 549     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 550     MANPATH="/opt/local/share/man:$MANPATH"
 551 fi
 552 # do Fink setup on darwin
 553 isdarwin && xsource /sw/bin/init.sh
 554
 555 # load our function and completion directories
 556 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 557     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 558     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 559         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 560             zrcautoload ${func:t}
 561         done
 562     fi
 563 done
 564 unset fdir func
 565
 566 # support colors in less
 567 export LESS_TERMCAP_mb=$'\E[01;31m'
 568 export LESS_TERMCAP_md=$'\E[01;31m'
 569 export LESS_TERMCAP_me=$'\E[0m'
 570 export LESS_TERMCAP_se=$'\E[0m'
 571 export LESS_TERMCAP_so=$'\E[01;44;33m'
 572 export LESS_TERMCAP_ue=$'\E[0m'
 573 export LESS_TERMCAP_us=$'\E[01;32m'
 574
 575 # mailchecks
 576 MAILCHECK=30
 577
 578 # report about cpu-/system-/user-time of command if running longer than
 579 # 5 seconds
 580 REPORTTIME=5
 581
 582 # watch for everyone but me and root
 583 watch=(notme root)
 584
 585 # automatically remove duplicates from these arrays
 586 typeset -U path cdpath fpath manpath
 587
 588 # Remove zle-line-{init,finish} if it looks like it turns smkx. This would be
 589 # better fixed by working with those modes too, but we use way too many
 590 # hardcoded bindings for now.
 591 function remove_widget () {
 592     local name=$1
 593     local cap=$2
 594     if (( ${+functions[$name]} )) && [[ ${functions[$name]} == *${cap}* ]]; then
 595         local w=${widgets[$name]}
 596         zle -D $name
 597         [[ $w == user:* ]] && unfunction ${w#*:}
 598     fi
 599 }
 600 remove_widget zle-line-init smkx
 601 remove_widget zle-line-finish rmkx
 602 unfunction remove_widget
 603
 604 # keybindings
 605 if [[ "$TERM" != emacs ]] ; then
 606     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 607     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 608     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 609     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 610     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 611     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 612     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 613     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 614     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 615     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 616     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 617     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 618     # ncurses stuff:
 619     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 620     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 621     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 622     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 623     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 624     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 625     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 626     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 627 fi
 628
 629 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 630 # use emacs style per default:
 631 bindkey -e
 632 # use vi style:
 633 # bindkey -v
 634
 635 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 636 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 637 beginning-or-end-of-somewhere() {
 638     local hno=$HISTNO
 639     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 640       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 641         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 642     else
 643         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 644         if (( HISTNO != hno )); then
 645             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 646         fi
 647     fi
 648 }
 649 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 650 zle -N end-of-somewhere beginning-or-end-of-somewhere
 651
 652
 653 #if [[ "$TERM" == screen ]] ; then
 654
 655 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 656 ## to beginning/end of buffer on second keypress
 657 ## and to beginning/end of history on (at most) the third keypress
 658 # terminator & non-debian xterm
 659 bindkey '\eOH' beginning-of-somewhere  # home
 660 bindkey '\eOF' end-of-somewhere        # end
 661 # freebsd console
 662 bindkey '\e[H' beginning-of-somewhere   # home
 663 bindkey '\e[F' end-of-somewhere         # end
 664 # xterm,gnome-terminal,quake,etc
 665 bindkey '^[[1~' beginning-of-somewhere  # home
 666 bindkey '^[[4~' end-of-somewhere        # end
 667 # if terminal type is set to 'rxvt':
 668 bindkey '\e[7~' beginning-of-somewhere  # home
 669 bindkey '\e[8~' end-of-somewhere        # end
 670 #fi
 671
 672 bindkey '\e[A'  up-line-or-search       # cursor up
 673 bindkey '\e[B'  down-line-or-search     # <ESC>-
 674
 675 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 676 bindkey "\e[5C" forward-word
 677 bindkey "\e[5D" backward-word
 678 bindkey "\e[1;5C" forward-word
 679 bindkey "\e[1;5D" backward-word
 680 ## the same for alt-left-arrow and alt-right-arrow
 681 bindkey '^[[1;3C' forward-word
 682 bindkey '^[[1;3D' backward-word
 683
 684 # Search backward in the history for a line beginning with the current
 685 # line up to the cursor and move the cursor to the end of the line then
 686 zle -N history-beginning-search-backward-end history-search-end
 687 zle -N history-beginning-search-forward-end  history-search-end
 688 #k# search history backward for entry beginning with typed text
 689 bindkey '^xp'   history-beginning-search-backward-end
 690 #k# search history forward for entry beginning with typed text
 691 bindkey '^xP'   history-beginning-search-forward-end
 692 #k# search history backward for entry beginning with typed text
 693 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 694 #k# search history forward for entry beginning with typed text
 695 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 696
 697 # bindkey -s '^l' "|less\n"             # ctrl-L pipes to less
 698 # bindkey -s '^b' " &\n"                # ctrl-B runs it in the background
 699
 700 # insert unicode character
 701 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 702 # See for example http://unicode.org/charts/ for unicode characters code
 703 zrcautoload insert-unicode-char
 704 zle -N insert-unicode-char
 705 #k# Insert Unicode character
 706 bindkey '^xi' insert-unicode-char
 707
 708 #m# k Shift-tab Perform backwards menu completion
 709 if [[ -n "$terminfo[kcbt]" ]]; then
 710     bindkey "$terminfo[kcbt]" reverse-menu-complete
 711 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 712     bindkey "$terminfo[cbt]"  reverse-menu-complete
 713 fi
 714
 715 ## toggle the ,. abbreviation feature on/off
 716 # NOABBREVIATION: default abbreviation-state
 717 #                 0 - enabled (default)
 718 #                 1 - disabled
 719 NOABBREVIATION=${NOABBREVIATION:-0}
 720
 721 grml_toggle_abbrev() {
 722     if (( ${NOABBREVIATION} > 0 )) ; then
 723         NOABBREVIATION=0
 724     else
 725         NOABBREVIATION=1
 726     fi
 727 }
 728
 729 #k# Toggle abbreviation expansion on/off
 730 zle -N grml_toggle_abbrev
 731 bindkey '^xA' grml_toggle_abbrev
 732
 733 # add a command line to the shells history without executing it
 734 commit-to-history() {
 735     print -s ${(z)BUFFER}
 736     zle send-break
 737 }
 738 zle -N commit-to-history
 739 bindkey "^x^h" commit-to-history
 740
 741 # only slash should be considered as a word separator:
 742 slash-backward-kill-word() {
 743     local WORDCHARS="${WORDCHARS:s@/@}"
 744     # zle backward-word
 745     zle backward-kill-word
 746 }
 747 zle -N slash-backward-kill-word
 748
 749 #k# Kill left-side word or everything up to next slash
 750 bindkey '\ev' slash-backward-kill-word
 751 #k# Kill left-side word or everything up to next slash
 752 bindkey '\e^h' slash-backward-kill-word
 753 #k# Kill left-side word or everything up to next slash
 754 bindkey '\e^?' slash-backward-kill-word
 755
 756 # use the new *-pattern-* widgets for incremental history search
 757 if is439 ; then
 758     bindkey '^r' history-incremental-pattern-search-backward
 759     bindkey '^s' history-incremental-pattern-search-forward
 760 fi
 761
 762 # a generic accept-line wrapper
 763
 764 # This widget can prevent unwanted autocorrections from command-name
 765 # to _command-name, rehash automatically on enter and call any number
 766 # of builtin and user-defined widgets in different contexts.
 767 #
 768 # For a broader description, see:
 769 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 770 #
 771 # The code is imported from the file 'zsh/functions/accept-line' from
 772 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 773 # distributed under the same terms as zsh itself.
 774
 775 # A newly added command will may not be found or will cause false
 776 # correction attempts, if you got auto-correction set. By setting the
 777 # following style, we force accept-line() to rehash, if it cannot
 778 # find the first word on the command line in the $command[] hash.
 779 zstyle ':acceptline:*' rehash true
 780
 781 function Accept-Line() {
 782     setopt localoptions noksharrays
 783     local -a subs
 784     local -xi aldone
 785     local sub
 786     local alcontext=${1:-$alcontext}
 787
 788     zstyle -a ":acceptline:${alcontext}" actions subs
 789
 790     (( ${#subs} < 1 )) && return 0
 791
 792     (( aldone = 0 ))
 793     for sub in ${subs} ; do
 794         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 795         zle ${sub}
 796
 797         (( aldone > 0 )) && break
 798     done
 799 }
 800
 801 function Accept-Line-getdefault() {
 802     emulate -L zsh
 803     local default_action
 804
 805     zstyle -s ":acceptline:${alcontext}" default_action default_action
 806     case ${default_action} in
 807         ((accept-line|))
 808             printf ".accept-line"
 809             ;;
 810         (*)
 811             printf ${default_action}
 812             ;;
 813     esac
 814 }
 815
 816 function Accept-Line-HandleContext() {
 817     zle Accept-Line
 818
 819     default_action=$(Accept-Line-getdefault)
 820     zstyle -T ":acceptline:${alcontext}" call_default \
 821         && zle ${default_action}
 822 }
 823
 824 function accept-line() {
 825     setopt localoptions noksharrays
 826     local -ax cmdline
 827     local -x alcontext
 828     local buf com fname format msg default_action
 829
 830     alcontext='default'
 831     buf="${BUFFER}"
 832     cmdline=(${(z)BUFFER})
 833     com="${cmdline[1]}"
 834     fname="_${com}"
 835
 836     Accept-Line 'preprocess'
 837
 838     zstyle -t ":acceptline:${alcontext}" rehash \
 839         && [[ -z ${commands[$com]} ]]           \
 840         && rehash
 841
 842     if    [[ -n ${com}               ]] \
 843        && [[ -n ${reswords[(r)$com]} ]] \
 844        || [[ -n ${aliases[$com]}     ]] \
 845        || [[ -n ${functions[$com]}   ]] \
 846        || [[ -n ${builtins[$com]}    ]] \
 847        || [[ -n ${commands[$com]}    ]] ; then
 848
 849         # there is something sensible to execute, just do it.
 850         alcontext='normal'
 851         Accept-Line-HandleContext
 852
 853         return
 854     fi
 855
 856     if    [[ -o correct              ]] \
 857        || [[ -o correctall           ]] \
 858        && [[ -n ${functions[$fname]} ]] ; then
 859
 860         # nothing there to execute but there is a function called
 861         # _command_name; a completion widget. Makes no sense to
 862         # call it on the commandline, but the correct{,all} options
 863         # will ask for it nevertheless, so warn the user.
 864         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 865             # Okay, we warned the user before, he called us again,
 866             # so have it his way.
 867             alcontext='force'
 868             Accept-Line-HandleContext
 869
 870             return
 871         fi
 872
 873         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 874             alcontext='normal'
 875             Accept-Line-HandleContext
 876         else
 877             # prepare warning message for the user, configurable via zstyle.
 878             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 879
 880             if [[ -z ${msg} ]] ; then
 881                 msg="%c will not execute and completion %f exists."
 882             fi
 883
 884             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 885
 886             zle -M -- "${msg}"
 887         fi
 888         return
 889     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 890         # If we are here, the commandline contains something that is not
 891         # executable, which is neither subject to _command_name correction
 892         # and is not empty. might be a variable assignment
 893         alcontext='misc'
 894         Accept-Line-HandleContext
 895
 896         return
 897     fi
 898
 899     # If we got this far, the commandline only contains whitespace, or is empty.
 900     alcontext='empty'
 901     Accept-Line-HandleContext
 902 }
 903
 904 zle -N accept-line
 905 zle -N Accept-Line
 906 zle -N Accept-Line-HandleContext
 907
 908 # power completion - abbreviation expansion
 909 # power completion / abbreviation expansion / buffer expansion
 910 # see http://zshwiki.org/home/examples/zleiab for details
 911 # less risky than the global aliases but powerful as well
 912 # just type the abbreviation key and afterwards ',.' to expand it
 913 declare -A abk
 914 setopt extendedglob
 915 setopt interactivecomments
 916 abk=(
 917 #   key   # value                  (#d additional doc string)
 918 #A# start
 919     '...'  '../..'
 920     '....' '../../..'
 921     'BG'   '& exit'
 922     'C'    '| wc -l'
 923     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
 924     'H'    '| head'
 925     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 926     'L'    '| less'
 927     'LL'   '|& less -r'
 928     'M'    '| most'
 929     'N'    '&>/dev/null'           #d (No Output)
 930     'R'    '| tr A-z N-za-m'       #d (ROT13)
 931     'SL'   '| sort | less'
 932     'S'    '| sort -u'
 933     'T'    '| tail'
 934     'V'    '|& vim -'
 935 #A# end
 936     'co'   './configure && make && sudo make install'
 937 )
 938
 939 zleiab() {
 940     emulate -L zsh
 941     setopt extendedglob
 942     local MATCH
 943
 944     if (( NOABBREVIATION > 0 )) ; then
 945         LBUFFER="${LBUFFER},."
 946         return 0
 947     fi
 948
 949     LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
 950     LBUFFER+=${abk[$MATCH]:-$MATCH}
 951 }
 952
 953 zle -N zleiab && bindkey ",." zleiab
 954
 955 #f# display contents of assoc array $abk
 956 help-show-abk()
 957 {
 958   zle -M "$(print "Type ,. after these abbreviations to expand them:"; print -a -C 2 ${(kv)abk})"
 959 }
 960 #k# Display list of abbreviations that expand when followed by ,.
 961 zle -N help-show-abk && bindkey '^xb' help-show-abk
 962
 963 # autoloading
 964 zrcautoload zmv    # who needs mmv or rename?
 965 zrcautoload history-search-end
 966
 967 # we don't want to quote/espace URLs on our own...
 968 # if autoload -U url-quote-magic ; then
 969 #    zle -N self-insert url-quote-magic
 970 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 971 # else
 972 #    print 'Notice: no url-quote-magic available :('
 973 # fi
 974 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 975
 976 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 977 alias run-help >&/dev/null && unalias run-help
 978 for rh in run-help{,-git,-svk,-svn}; do
 979     zrcautoload $rh
 980 done; unset rh
 981
 982 # completion system
 983 if zrcautoload compinit ; then
 984     compinit || print 'Notice: no compinit available :('
 985 else
 986     print 'Notice: no compinit available :('
 987     function compdef { }
 988 fi
 989
 990 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 991
 992 is4 && \
 993 for mod in complist deltochar mathfunc ; do
 994     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 995 done
 996
 997 # autoload zsh modules when they are referenced
 998 if is4 ; then
 999     zmodload -a  zsh/stat    zstat
1000     zmodload -a  zsh/zpty    zpty
1001     zmodload -ap zsh/mapfile mapfile
1002 fi
1003
1004 if is4 && zrcautoload insert-files && zle -N insert-files ; then
1005     #k# Insert files and test globbing
1006     bindkey "^xf" insert-files # C-x-f
1007 fi
1008
1009 bindkey ' '   magic-space    # also do history expansion on space
1010 #k# Trigger menu-complete
1011 bindkey '\ei' menu-complete  # menu completion via esc-i
1012
1013 # press esc-e for editing command line in $EDITOR or $VISUAL
1014 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
1015     #k# Edit the current line in \kbd{\$EDITOR}
1016     bindkey '\ee' edit-command-line
1017 fi
1018
1019 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
1020     #k# menu selection: pick item but stay in the menu
1021     bindkey -M menuselect '\e^M' accept-and-menu-complete
1022     # also use + and INSERT since it's easier to press repeatedly
1023     bindkey -M menuselect "+" accept-and-menu-complete
1024     bindkey -M menuselect "^[[2~" accept-and-menu-complete
1025
1026     # accept a completion and try to complete again by using menu
1027     # completion; very useful with completing directories
1028     # by using 'undo' one's got a simple file browser
1029     bindkey -M menuselect '^o' accept-and-infer-next-history
1030 fi
1031
1032 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1033 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1034 zle -N insert-datestamp
1035
1036 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1037 bindkey '^ed' insert-datestamp
1038
1039 # press esc-m for inserting last typed word again (thanks to caphuso!)
1040 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1041 zle -N insert-last-typed-word;
1042
1043 #k# Insert last typed word
1044 bindkey "\em" insert-last-typed-word
1045
1046 function grml-zsh-fg() {
1047   if (( ${#jobstates} )); then
1048     zle .push-input
1049     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1050     BUFFER="${BUFFER}fg"
1051     zle .accept-line
1052   else
1053     zle -M 'No background jobs. Doing nothing.'
1054   fi
1055 }
1056 zle -N grml-zsh-fg
1057 #k# A smart shortcut for \kbd{fg<enter>}
1058 bindkey '^z' grml-zsh-fg
1059
1060 # run command line as user root via sudo:
1061 sudo-command-line() {
1062     [[ -z $BUFFER ]] && zle up-history
1063     if [[ $BUFFER != sudo\ * ]]; then
1064         BUFFER="sudo $BUFFER"
1065         CURSOR=$(( CURSOR+5 ))
1066     fi
1067 }
1068 zle -N sudo-command-line
1069
1070 #k# prepend the current command with "sudo"
1071 bindkey "^os" sudo-command-line
1072
1073 ### jump behind the first word on the cmdline.
1074 ### useful to add options.
1075 function jump_after_first_word() {
1076     local words
1077     words=(${(z)BUFFER})
1078
1079     if (( ${#words} <= 1 )) ; then
1080         CURSOR=${#BUFFER}
1081     else
1082         CURSOR=${#${words[1]}}
1083     fi
1084 }
1085 zle -N jump_after_first_word
1086 #k# jump to after first word (for adding options)
1087 bindkey '^x1' jump_after_first_word
1088
1089 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1090 zle -C hist-complete complete-word _generic
1091 zstyle ':completion:hist-complete:*' completer _history
1092 #k# complete word from history with menu
1093 bindkey "^x^x" hist-complete
1094
1095 ## complete word from currently visible Screen or Tmux buffer.
1096 if check_com -c screen || check_com -c tmux; then
1097     _complete_screen_display() {
1098         [[ "$TERM" != "screen" ]] && return 1
1099
1100         local TMPFILE=$(mktemp)
1101         local -U -a _screen_display_wordlist
1102         trap "rm -f $TMPFILE" EXIT
1103
1104         # fill array with contents from screen hardcopy
1105         if ((${+TMUX})); then
1106             #works, but crashes tmux below version 1.4
1107             #luckily tmux -V option to ask for version, was also added in 1.4
1108             tmux -V &>/dev/null || return
1109             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1110         else
1111             screen -X hardcopy $TMPFILE
1112             # screen sucks, it dumps in latin1, apparently always. so recode it
1113             # to system charset
1114             check_com recode && recode latin1 $TMPFILE
1115         fi
1116         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1117         # remove PREFIX to be completed from that array
1118         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1119         compadd -a _screen_display_wordlist
1120     }
1121     #k# complete word from currently visible GNU screen buffer
1122     bindkey -r "^xS"
1123     compdef -k _complete_screen_display complete-word '^xS'
1124 fi
1125
1126 # history
1127
1128 ZSHDIR=${ZDOTDIR:-${HOME}/.zsh}
1129
1130 #v#
1131 HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1132 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1133 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1134
1135 # dirstack handling
1136
1137 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1138 DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1139
1140 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1141     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1142     # "cd -" won't work after login by just setting $OLDPWD, so
1143     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1144 fi
1145
1146 chpwd() {
1147     local -ax my_stack
1148     my_stack=( ${PWD} ${dirstack} )
1149     if is42 ; then
1150         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1151     else
1152         uprint my_stack >! ${DIRSTACKFILE}
1153     fi
1154 }
1155
1156 # directory based profiles
1157
1158 if is433 ; then
1159
1160 # chpwd_profiles(): Directory Profiles, Quickstart:
1161 #
1162 # In .zshrc.local:
1163 #
1164 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1165 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1166 #   chpwd_profiles
1167 #
1168 # For details see the `grmlzshrc.5' manual page.
1169 function chpwd_profiles() {
1170     local profile context
1171     local -i reexecute
1172
1173     context=":chpwd:profiles:$PWD"
1174     zstyle -s "$context" profile profile || profile='default'
1175     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1176
1177     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1178         typeset -g CHPWD_PROFILE
1179         local CHPWD_PROFILES_INIT=1
1180         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1181     elif [[ $profile != $CHPWD_PROFILE ]]; then
1182         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1183             && chpwd_leave_profile_${CHPWD_PROFILE}
1184     fi
1185     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1186         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1187     fi
1188
1189     CHPWD_PROFILE="${profile}"
1190     return 0
1191 }
1192
1193 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1194
1195 fi # is433
1196
1197 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1198 if [[ $BATTERY -gt 0 ]] ; then
1199     if ! check_com -c acpi ; then
1200         BATTERY=0
1201     fi
1202 fi
1203
1204 battery() {
1205 if [[ $BATTERY -gt 0 ]] ; then
1206     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1207     if [[ -z "$PERCENT" ]] ; then
1208         PERCENT='acpi not present'
1209     else
1210         if [[ "$PERCENT" -lt 20 ]] ; then
1211             PERCENT="warning: ${PERCENT}%%"
1212         else
1213             PERCENT="${PERCENT}%%"
1214         fi
1215     fi
1216 fi
1217 }
1218 # set colors for use in prompts
1219 if zrcautoload colors && colors 2>/dev/null ; then
1220     BLUE="%{${fg[blue]}%}"
1221     RED="%{${fg_bold[red]}%}"
1222     GREEN="%{${fg[green]}%}"
1223     CYAN="%{${fg[cyan]}%}"
1224     MAGENTA="%{${fg[magenta]}%}"
1225     YELLOW="%{${fg[yellow]}%}"
1226     WHITE="%{${fg[white]}%}"
1227     NO_COLOR="%{${reset_color}%}"
1228 else
1229     BLUE=$'%{\e[1;34m%}'
1230     RED=$'%{\e[1;31m%}'
1231     GREEN=$'%{\e[1;32m%}'
1232     CYAN=$'%{\e[1;36m%}'
1233     WHITE=$'%{\e[1;37m%}'
1234     MAGENTA=$'%{\e[1;35m%}'
1235     YELLOW=$'%{\e[1;33m%}'
1236     NO_COLOR=$'%{\e[0m%}'
1237 fi
1238
1239 # gather version control information for inclusion in a prompt
1240
1241 if zrcautoload vcs_info; then
1242     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1243     # function, which can cause a lot of trouble with our directory-based
1244     # profiles. So:
1245     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1246         function VCS_INFO_realpath () {
1247             setopt localoptions NO_shwordsplit chaselinks
1248             ( builtin cd -q $1 2> /dev/null && pwd; )
1249         }
1250     fi
1251
1252     zstyle ':vcs_info:*' max-exports 2
1253
1254     if [[ -o restricted ]]; then
1255         zstyle ':vcs_info:*' enable NONE
1256     fi
1257 fi
1258
1259 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1260 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1261 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1262 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1263 #       to $vcs_info_msg_N_ as soon as we use the included version.
1264 if [[ "$TERM" == dumb ]] ; then
1265     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1266     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1267 else
1268     # these are the same, just with a lot of colors:
1269     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} " \
1270                                        "zsh: %r"
1271     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR}%} " \
1272                                        "zsh: %r"
1273     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1274 fi
1275
1276 # command not found handling
1277
1278 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1279 function command_not_found_handler() {
1280     emulate -L zsh
1281     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1282         ${GRML_ZSH_CNF_HANDLER} $1
1283     fi
1284     return 1
1285 }
1286
1287 function prompt_grml_help () {
1288     cat <<__EOF0__
1289   prompt grml
1290
1291     This is the prompt as used by the grml-live system <http://grml.org>. It is
1292     a rather simple one-line prompt, that by default looks something like this:
1293
1294         <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1295
1296     The prompt itself integrates with zsh's prompt themes system (as you are
1297     witnessing right now) and is configurable to a certain degree. In
1298     particular, these aspects are customisable:
1299
1300         - The items used in the prompt (e.g. you can remove \`user' from
1301           the list of activated items, which will cause the user name to
1302           be omitted from the prompt string).
1303
1304         - The attributes used with the items are customisable via strings
1305           used before and after the actual item.
1306
1307     The available items are: rc, rc-always, change-root, user, at, host, path,
1308     vcs, percent, sad-smiley, battery.
1309
1310     The actual configuration is done via zsh's \`zstyle' mechanism. The
1311     context, that is used while looking up styles is:
1312
1313         ':prompt:grml:<left-or-right>:<subcontext>'
1314
1315     Here <left-or-right> is either \`left' or \`right', signifying whether the
1316     style should affect the left or the right prompt. <subcontext> is either
1317     \`setup' or 'items:<item>', where \`<item>' is one of the available items.
1318
1319     The styles:
1320
1321         - use-rprompt (boolean): If \`true' (the default), print a sad smiley
1322           in $RPROMPT if the last command a returned non-successful error code.
1323           (This in only valid if <left-or-right> is "right"; ignored otherwise)
1324
1325         - items (list): The list of items used in the prompt. If \`vcs' is
1326           present in the list, the theme's code invokes \`vcs_info'
1327           accordingly. Default: rc user change-root at host path vcs precent
1328
1329     Available styles in 'items:<item>' are: pre, post. These are strings that
1330     are inserted before (pre) and after (post) the item in question. Thus, the
1331     following would cause the user name to be printed in red instead of the
1332     default blue:
1333
1334         zstyle ':prompt:grml:*:items:user' pre '%F{red}'
1335
1336     Note, that the \`post' style may remain at its default value, because its
1337     default value is '%f', which turns the foreground text attribute off (which
1338     is exactly, what is still required with the new \`pre' value).
1339 __EOF0__
1340 }
1341
1342 function grml_prompt_setup () {
1343     emulate -L zsh
1344     autoload -Uz vcs_info
1345     autoload -Uz add-zsh-hook
1346     add-zsh-hook precmd prompt_$1_precmd
1347 }
1348
1349 function prompt_grml_setup () {
1350     grml_prompt_setup grml
1351 }
1352
1353 function prompt_grml-chroot_setup () {
1354     grml_prompt_setup grml-chroot
1355 }
1356
1357 function prompt_grml-large_setup () {
1358     grml_prompt_setup grml-large
1359 }
1360
1361 typeset -gA grml_prompt_pre_default \
1362             grml_prompt_post_default \
1363             grml_prompt_token_default
1364
1365 grml_prompt_pre_default=(
1366     rc                '%F{red}'
1367     rc-always         ''
1368     change-root       ''
1369     user              '%B%F{blue}'
1370     at                ''
1371     host              ''
1372     path              '%b'
1373     vcs               ''
1374     percent           ''
1375     sad-smiley        ''
1376     battery           ' '
1377     newline           ''
1378     jobs              '%F{cyan}'
1379     history           '%F{green}'
1380     date              '%F{blue}'
1381     time              '%F{blue}'
1382     shell-level       '%F{red}'
1383     grml-chroot       '%F{red}'
1384 )
1385
1386 grml_prompt_post_default=(
1387     rc                '%f'
1388     rc-always         ''
1389     change-root       ''
1390     user              '%f%b'
1391     at                ''
1392     host              ''
1393     path              '%B'
1394     vcs               ''
1395     percent           ''
1396     sad-smiley        ''
1397     battery           ''
1398     newline           ''
1399     jobs              '%f'
1400     history           '%f'
1401     date              '%f'
1402     time              '%f'
1403     shell-level       '%f'
1404     grml-chroot       '%f '
1405 )
1406
1407 grml_prompt_token_default=(
1408     rc                '%(?..%? )'
1409     rc-always         '%?'
1410     change-root       'debian_chroot'
1411     user              '%n'
1412     at                '@'
1413     host              '%m '
1414     path              '%40<..<%~%<< '
1415     vcs               '0'
1416     percent           '%% '
1417     sad-smiley        '%(?..:()'
1418     battery           'PERCENT'
1419     newline           $'\n'
1420     jobs              '[%j running job(s)] '
1421     history           '{history#%!} '
1422     date              '%D{%Y-%m-%d}'
1423     time              '%D{%H:%M:%S} '
1424     shell-level       '%(3L.+ .)'
1425     grml-chroot       'GRML_CHROOT'
1426 )
1427
1428 function grml_typeset_and_wrap () {
1429     emulate -L zsh
1430     local target="$1"
1431     local new="$2"
1432     local left="$3"
1433     local right="$4"
1434
1435     if (( ${+parameters[$new]} )); then
1436         typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
1437     fi
1438 }
1439
1440 function grml_prompt_addto () {
1441     emulate -L zsh
1442     local target="$1"
1443     local lr it apre apost new v
1444     local -a items
1445     shift
1446
1447     [[ $target == PS1 ]] && lr=left || lr=right
1448     zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
1449     typeset -g "${target}="
1450     for it in "${items[@]}"; do
1451         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
1452             || apre=${grml_prompt_pre_default[$it]}
1453         zstyle -s ":prompt:grml:${grmltheme}:${lr}:$it" post apost \
1454             || apost=${grml_prompt_post_default[$it]}
1455         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
1456             || new=${grml_prompt_token_default[$it]}
1457         typeset -g "${target}=${(P)target}${apre}"
1458         case $it in
1459             battery)
1460                 grml_typeset_and_wrap $target $new '' ''
1461                 ;;
1462             change-root)
1463                 grml_typeset_and_wrap $target $new '(' ')'
1464                 ;;
1465             grml-chroot)
1466                 if [[ -n ${(P)new} ]]; then
1467                     typeset -g "${target}=${(P)target}(CHROOT)"
1468                 fi
1469                 ;;
1470             vcs)
1471                 v="vcs_info_msg_${new}_"
1472                 if (( ! vcscalled )); then
1473                     vcs_info
1474                     vcscalled=1
1475                 fi
1476                 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
1477                     typeset -g "${target}=${(P)target}${(P)v}"
1478                 fi
1479                 ;;
1480             *) typeset -g "${target}=${(P)target}${new}" ;;
1481         esac
1482         typeset -g "${target}=${(P)target}${apost}"
1483     done
1484 }
1485
1486 function prompt_grml_precmd () {
1487     emulate -L zsh
1488     local grmltheme=grml
1489     local -a left_items right_items
1490     left_items=(rc change-root user at host path vcs percent)
1491     right_items=(sad-smiley)
1492
1493     prompt_grml_precmd_worker
1494 }
1495
1496 function prompt_grml-chroot_precmd () {
1497     emulate -L zsh
1498     local grmltheme=grml-chroot
1499     local -a left_items right_items
1500     left_items=(grml-chroot user at host path percent)
1501     right_items=()
1502
1503     prompt_grml_precmd_worker
1504 }
1505
1506 function prompt_grml-large_precmd () {
1507     emulate -L zsh
1508     local grmltheme=grml-large
1509     local -a left_items right_items
1510     left_items=(rc jobs history shell-level change-root time date newline
1511                 user at host path vcs percent)
1512     right_items=(sad-smiley)
1513
1514     prompt_grml_precmd_worker
1515 }
1516
1517 function prompt_grml_precmd_worker () {
1518     emulate -L zsh
1519     local -i vcscalled=0
1520
1521     grml_prompt_addto PS1 "${left_items[@]}"
1522     if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
1523         grml_prompt_addto RPS1 "${right_items[@]}"
1524     fi
1525 }
1526
1527 # set prompt
1528 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1529     promptinit # people should be able to use their favourite prompt
1530
1531     # Since we define the required functions in here and not in files in
1532     # $fpath, we need to stick the theme's name into `$prompt_themes'
1533     # ourselves, since promptinit does not pick them up otherwise.
1534     prompt_themes+=( grml grml-chroot grml-large )
1535     # Also, keep the array sorted...
1536     prompt_themes=( "${(@on)prompt_themes}" )
1537
1538     if [[ $BATTERY -gt 0 ]]; then
1539         zstyle ':prompt:grml:right:setup' items sad-smiley battery
1540         add-zsh-hook precmd battery
1541     fi
1542     if [[ "$TERM" == dumb ]] ; then
1543         for i in rc user path jobs history date time shell-level; do
1544             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" pre ''
1545             zstyle ':prompt:grml(|-large|-chroot):*:items:$i' post ''
1546         done
1547         unset i
1548         zstyle ':prompt:grml(|-large|-chroot):right:setup' use-rprompt false
1549     elif (( EUID != 0 )); then
1550         zstyle ':prompt:grml(|-large|-chroot):*:items:user' pre '%F{red}'
1551     fi
1552 else
1553     print 'Notice: no promptinit available :('
1554 fi
1555
1556 setopt prompt_subst
1557
1558 # make sure to use right prompt only when not running a command
1559 is41 && setopt transient_rprompt
1560
1561
1562 function ESC_print () {
1563     info_print $'\ek' $'\e\\' "$@"
1564 }
1565 function set_title () {
1566     info_print  $'\e]0;' $'\a' "$@"
1567 }
1568
1569 function info_print () {
1570     local esc_begin esc_end
1571     esc_begin="$1"
1572     esc_end="$2"
1573     shift 2
1574     printf '%s' ${esc_begin}
1575     printf '%s' "$*"
1576     printf '%s' "${esc_end}"
1577 }
1578
1579 function grml_reset_screen_title () {
1580     # adjust title of xterm
1581     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1582     [[ ${NOTITLE:-} -gt 0 ]] && return 0
1583     case $TERM in
1584         (xterm*|rxvt*)
1585             set_title ${(%):-"%n@%m: %~"}
1586             ;;
1587     esac
1588 }
1589
1590 function grml_vcs_to_screen_title () {
1591     if [[ $TERM == screen* ]] ; then
1592         if [[ -n ${vcs_info_msg_1_} ]] ; then
1593             ESC_print ${vcs_info_msg_1_}
1594         else
1595             ESC_print "zsh"
1596         fi
1597     fi
1598 }
1599
1600 zrcautoload add-zsh-hook || add-zsh-hook () { :; }
1601 if [[ $NOPRECMD -gt 0 ]]; then
1602     add-zsh-hook precmd grml_reset_screen_title
1603     add-zsh-hook precmd grml_vcs_to_screen_title
1604 fi
1605
1606 # preexec() => a function running before every command
1607 is4 && [[ $NOPRECMD -eq 0 ]] && \
1608 preexec () {
1609     [[ $NOPRECMD -gt 0 ]] && return 0
1610 # set hostname if not running on host with name 'grml'
1611     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1612        NAME="@$HOSTNAME"
1613     fi
1614 # get the name of the program currently running and hostname of local machine
1615 # set screen window title if running in a screen
1616     if [[ "$TERM" == screen* ]] ; then
1617         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1618         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1619         ESC_print ${CMD}
1620     fi
1621 # adjust title of xterm
1622     [[ ${NOTITLE} -gt 0 ]] && return 0
1623     case $TERM in
1624         (xterm*|rxvt*)
1625             set_title "${(%):-"%n@%m:"}" "$1"
1626             ;;
1627     esac
1628 }
1629
1630 EXITCODE="%(?..%?%1v )"
1631 # secondary prompt, printed when the shell needs more information to complete a
1632 # command.
1633 PS2='\`%_> '
1634 # selection prompt used within a select loop.
1635 PS3='?# '
1636 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1637 PS4='+%N:%i:%_> '
1638
1639 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1640 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1641     debian_chroot=$(cat /etc/debian_chroot)
1642 fi
1643
1644 # don't use colors on dumb terminals (like emacs):
1645 if [[ "$TERM" == dumb ]] ; then
1646     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
1647 else
1648     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended
1649     # prompt set variable identifying the chroot you work in (used in the
1650     # prompt below)
1651     if [[ $GRMLPROMPT -gt 0 ]] ; then
1652         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1653 ${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "
1654     else
1655         # This assembles the primary prompt string
1656         if (( EUID != 0 )); then
1657             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "
1658         else
1659             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "
1660         fi
1661     fi
1662 fi
1663
1664 PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
1665
1666 # if we are inside a grml-chroot set a specific prompt theme
1667 if [[ -n "$GRML_CHROOT" ]] ; then
1668     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1669 fi
1670
1671 # 'hash' some often used directories
1672 #d# start
1673 hash -d deb=/var/cache/apt/archives
1674 hash -d doc=/usr/share/doc
1675 hash -d linux=/lib/modules/$(command uname -r)/build/
1676 hash -d log=/var/log
1677 hash -d slog=/var/log/syslog
1678 hash -d src=/usr/src
1679 hash -d templ=/usr/share/doc/grml-templates
1680 hash -d tt=/usr/share/doc/texttools-doc
1681 hash -d www=/var/www
1682 #d# end
1683
1684 # some aliases
1685 if check_com -c screen ; then
1686     if [[ $UID -eq 0 ]] ; then
1687         if [[ -r /etc/grml/screenrc ]]; then
1688             alias screen="${commands[screen]} -c /etc/grml/screenrc"
1689         fi
1690     elif [[ -r $HOME/.screenrc ]] ; then
1691         alias screen="${commands[screen]} -c $HOME/.screenrc"
1692     else
1693         if [[ -r /etc/grml/screenrc_grml ]]; then
1694             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1695         else
1696             if [[ -r /etc/grml/screenrc ]]; then
1697                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
1698             fi
1699         fi
1700     fi
1701 fi
1702
1703 # do we have GNU ls with color-support?
1704 if [[ "$TERM" != dumb ]]; then
1705     #a1# execute \kbd{@a@}:\quad ls with colors
1706     alias ls='ls -b -CF '${ls_options:+"${ls_options[*]}"}
1707     #a1# execute \kbd{@a@}:\quad list all files, with colors
1708     alias la='ls -la '${ls_options:+"${ls_options[*]}"}
1709     #a1# long colored list, without dotfiles (@a@)
1710     alias ll='ls -l '${ls_options:+"${ls_options[*]}"}
1711     #a1# long colored list, human readable sizes (@a@)
1712     alias lh='ls -hAl '${ls_options:+"${ls_options[*]}"}
1713     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1714     alias l='ls -lF '${ls_options:+"${ls_options[*]}"}
1715 else
1716     alias ls='ls -b -CF'
1717     alias la='ls -la'
1718     alias ll='ls -l'
1719     alias lh='ls -hAl'
1720     alias l='ls -lF'
1721 fi
1722
1723 alias mdstat='cat /proc/mdstat'
1724 alias ...='cd ../../'
1725
1726 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1727 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1728     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1729 fi
1730
1731 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1732 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1733 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1734
1735 # make sure it is not assigned yet
1736 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1737 utf2iso() {
1738     if isutfenv ; then
1739         for ENV in $(env | command grep -i '.utf') ; do
1740             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1741         done
1742     fi
1743 }
1744
1745 # make sure it is not assigned yet
1746 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1747 iso2utf() {
1748     if ! isutfenv ; then
1749         for ENV in $(env | command grep -i '\.iso') ; do
1750             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1751         done
1752     fi
1753 }
1754
1755 # especially for roadwarriors using GNU screen and ssh:
1756 if ! check_com asc &>/dev/null ; then
1757   asc() { autossh -t "$@" 'screen -RdU' }
1758   compdef asc=ssh
1759 fi
1760
1761 #f1# Hints for the use of zsh on grml
1762 zsh-help() {
1763     print "$bg[white]$fg[black]
1764 zsh-help - hints for use of zsh on grml
1765 =======================================$reset_color"
1766
1767     print '
1768 Main configuration of zsh happens in /etc/zsh/zshrc.
1769 That file is part of the package grml-etc-core, if you want to
1770 use them on a non-grml-system just get the tar.gz from
1771 http://deb.grml.org/ or (preferably) get it from the git repository:
1772
1773   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1774
1775 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1776 The file is still there, but it is empty for backwards compatibility.
1777
1778 For your own changes use these two files:
1779     $HOME/.zshrc.pre
1780     $HOME/.zshrc.local
1781
1782 The former is sourced very early in our zshrc, the latter is sourced
1783 very lately.
1784
1785 System wide configuration without touching configuration files of grml
1786 can take place in /etc/zsh/zshrc.local.
1787
1788 For information regarding zsh start at http://grml.org/zsh/
1789
1790 Take a look at grml'\''s zsh refcard:
1791 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1792
1793 Check out the main zsh refcard:
1794 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1795
1796 And of course visit the zsh-lovers:
1797 % man zsh-lovers
1798
1799 You can adjust some options through environment variables when
1800 invoking zsh without having to edit configuration files.
1801 Basically meant for bash users who are not used to the power of
1802 the zsh yet. :)
1803
1804   "NOCOR=1    zsh" => deactivate automatic correction
1805   "NOMENU=1   zsh" => do not use auto menu completion
1806                       (note: use ctrl-d for completion instead!)
1807   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1808   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1809                       preexec() and precmd() completely
1810   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1811   "COMMAND_NOT_FOUND=1 zsh"
1812                    => Enable a handler if an external command was not found
1813                       The command called in the handler can be altered by setting
1814                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1815                       "/usr/share/command-not-found/command-not-found"
1816
1817 A value greater than 0 is enables a feature; a value equal to zero
1818 disables it. If you like one or the other of these settings, you can
1819 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1820 zshrc.'
1821
1822     print "
1823 $bg[white]$fg[black]
1824 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1825 Enjoy your grml system with the zsh!$reset_color"
1826 }
1827
1828 # debian stuff
1829 if [[ -r /etc/debian_version ]] ; then
1830     #a3# Execute \kbd{apt-cache search}
1831     alias acs='apt-cache search'
1832     #a3# Execute \kbd{apt-cache show}
1833     alias acsh='apt-cache show'
1834     #a3# Execute \kbd{apt-cache policy}
1835     alias acp='apt-cache policy'
1836     #a3# Execute \kbd{apt-get dist-upgrade}
1837     salias adg="apt-get dist-upgrade"
1838     #a3# Execute \kbd{apt-get install}
1839     salias agi="apt-get install"
1840     #a3# Execute \kbd{aptitude install}
1841     salias ati="aptitude install"
1842     #a3# Execute \kbd{apt-get upgrade}
1843     salias ag="apt-get upgrade"
1844     #a3# Execute \kbd{apt-get update}
1845     salias au="apt-get update"
1846     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1847     salias -a up="aptitude update ; aptitude safe-upgrade"
1848     #a3# Execute \kbd{dpkg-buildpackage}
1849     alias dbp='dpkg-buildpackage'
1850     #a3# Execute \kbd{grep-excuses}
1851     alias ge='grep-excuses'
1852
1853     # get a root shell as normal user in live-cd mode:
1854     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1855        alias su="sudo su"
1856      fi
1857
1858     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1859     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1860     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1861     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1862 fi
1863
1864 # sort installed Debian-packages by size
1865 if check_com -c dpkg-query ; then
1866     #a3# List installed Debian-packages sorted by size
1867     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1868 fi
1869
1870 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1871 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1872     if check_com -c wodim; then
1873         cdrecord() {
1874             cat <<EOMESS
1875 cdrecord is not provided under its original name by Debian anymore.
1876 See #377109 in the BTS of Debian for more details.
1877
1878 Please use the wodim binary instead
1879 EOMESS
1880             return 1
1881         }
1882     fi
1883 fi
1884
1885 # Use hard limits, except for a smaller stack and no core dumps
1886 unlimit
1887 is425 && limit stack 8192
1888 isgrmlcd && limit core 0 # important for a live-cd-system
1889 limit -s
1890
1891 # completion system
1892
1893 # called later (via is4 && grmlcomp)
1894 # note: use 'zstyle' for getting current settings
1895 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
1896 grmlcomp() {
1897     # TODO: This could use some additional information
1898
1899     # allow one error for every three characters typed in approximate completer
1900     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1901
1902     # don't complete backup files as executables
1903     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1904
1905     # start menu completion only if it could find no unambiguous initial string
1906     zstyle ':completion:*:correct:*'       insert-unambiguous true
1907     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1908     zstyle ':completion:*:correct:*'       original true
1909
1910     # activate color-completion
1911     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1912
1913     # format on completion
1914     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1915
1916     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1917     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1918
1919     # insert all expansions for expand completer
1920     zstyle ':completion:*:expand:*'        tag-order all-expansions
1921     zstyle ':completion:*:history-words'   list false
1922
1923     # activate menu
1924     zstyle ':completion:*:history-words'   menu yes
1925
1926     # ignore duplicate entries
1927     zstyle ':completion:*:history-words'   remove-all-dups yes
1928     zstyle ':completion:*:history-words'   stop yes
1929
1930     # match uppercase from lowercase
1931     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1932
1933     # separate matches into groups
1934     zstyle ':completion:*:matches'         group 'yes'
1935     zstyle ':completion:*'                 group-name ''
1936
1937     if [[ "$NOMENU" -eq 0 ]] ; then
1938         # if there are more than 5 options allow selecting from a menu
1939         zstyle ':completion:*'               menu select=5
1940     else
1941         # don't use any menus at all
1942         setopt no_auto_menu
1943     fi
1944
1945     zstyle ':completion:*:messages'        format '%d'
1946     zstyle ':completion:*:options'         auto-description '%d'
1947
1948     # describe options in full
1949     zstyle ':completion:*:options'         description 'yes'
1950
1951     # on processes completion complete all user processes
1952     zstyle ':completion:*:processes'       command 'ps -au$USER'
1953
1954     # offer indexes before parameters in subscripts
1955     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1956
1957     # provide verbose completion information
1958     zstyle ':completion:*'                 verbose true
1959
1960     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1961     # for commands (read: 1st word in the line) that it will list for the user
1962     # to choose from. The following disables that, because it's not exactly fast.
1963     zstyle ':completion:*:-command-:*:'    verbose false
1964
1965     # set format for warnings
1966     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1967
1968     # define files to ignore for zcompile
1969     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1970     zstyle ':completion:correct:'          prompt 'correct to: %e'
1971
1972     # Ignore completion functions for commands you don't have:
1973     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1974
1975     # Provide more processes in completion of programs like killall:
1976     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1977
1978     # complete manual by their section
1979     zstyle ':completion:*:manuals'    separate-sections true
1980     zstyle ':completion:*:manuals.*'  insert-sections   true
1981     zstyle ':completion:*:man:*'      menu yes select
1982
1983     # Search path for sudo completion
1984     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
1985                                                /usr/local/bin  \
1986                                                /usr/sbin       \
1987                                                /usr/bin        \
1988                                                /sbin           \
1989                                                /bin            \
1990                                                /usr/X11R6/bin
1991
1992     # provide .. as a completion
1993     zstyle ':completion:*' special-dirs ..
1994
1995     # run rehash on completion so new installed program are found automatically:
1996     _force_rehash() {
1997         (( CURRENT == 1 )) && rehash
1998         return 1
1999     }
2000
2001     ## correction
2002     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
2003     if [[ "$NOCOR" -gt 0 ]] ; then
2004         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
2005         setopt nocorrect
2006     else
2007         # try to be smart about when to use what completer...
2008         setopt correct
2009         zstyle -e ':completion:*' completer '
2010             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
2011                 _last_try="$HISTNO$BUFFER$CURSOR"
2012                 reply=(_complete _match _ignored _prefix _files)
2013             else
2014                 if [[ $words[1] == (rm|mv) ]] ; then
2015                     reply=(_complete _files)
2016                 else
2017                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
2018                 fi
2019             fi'
2020     fi
2021
2022     # command for process lists, the local web server details and host completion
2023     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
2024
2025     # caching
2026     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
2027                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
2028
2029     # host completion
2030     if is42 ; then
2031         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
2032         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
2033     else
2034         _ssh_hosts=()
2035         _etc_hosts=()
2036     fi
2037     hosts=(
2038         $(hostname)
2039         "$_ssh_hosts[@]"
2040         "$_etc_hosts[@]"
2041         localhost
2042     )
2043     zstyle ':completion:*:hosts' hosts $hosts
2044     # TODO: so, why is this here?
2045     #  zstyle '*' hosts $hosts
2046
2047     # use generic completion system for programs not yet defined; (_gnu_generic works
2048     # with commands that provide a --help option with "standard" gnu-like output.)
2049     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
2050                    pal stow tail uname ; do
2051         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
2052     done; unset compcom
2053
2054     # see upgrade function in this file
2055     compdef _hosts upgrade
2056 }
2057
2058 # grmlstuff
2059 grmlstuff() {
2060 # people should use 'grml-x'!
2061     if check_com -c 915resolution; then
2062         855resolution() {
2063             echo "Please use 915resolution as resolution modifying tool for Intel \
2064 graphic chipset."
2065             return -1
2066         }
2067     fi
2068
2069     #a1# Output version of running grml
2070     alias grml-version='cat /etc/grml_version'
2071
2072     if check_com -c rebuildfstab ; then
2073         #a1# Rebuild /etc/fstab
2074         alias grml-rebuildfstab='rebuildfstab -v -r -config'
2075     fi
2076
2077     if check_com -c grml-debootstrap ; then
2078         debian2hd() {
2079             echo "Installing debian to harddisk is possible by using grml-debootstrap."
2080             return 1
2081         }
2082     fi
2083 }
2084
2085 # now run the functions
2086 isgrml && checkhome
2087 is4    && isgrml    && grmlstuff
2088 is4    && grmlcomp
2089
2090 # keephack
2091 is4 && xsource "/etc/zsh/keephack"
2092
2093 # wonderful idea of using "e" glob qualifier by Peter Stephenson
2094 # You use it as follows:
2095 # $ NTREF=/reference/file
2096 # $ ls -l *(e:nt:)
2097 # This lists all the files in the current directory newer than the reference file.
2098 # You can also specify the reference file inline; note quotes:
2099 # $ ls -l *(e:'nt ~/.zshenv':)
2100 is4 && nt() {
2101     if [[ -n $1 ]] ; then
2102         local NTREF=${~1}
2103     fi
2104     [[ $REPLY -nt $NTREF ]]
2105 }
2106
2107 # shell functions
2108
2109 #f1# Reload an autoloadable function
2110 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2111 compdef _functions freload
2112
2113 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2114 sll() {
2115     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2116     for file in "$@" ; do
2117         while [[ -h "$file" ]] ; do
2118             ls -l $file
2119             file=$(readlink "$file")
2120         done
2121     done
2122 }
2123
2124 # TODO: Is it supported to use pager settings like this?
2125 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2126 # with respect to wordsplitting. (ie. ${=PAGER})
2127 if check_com -c $PAGER ; then
2128     #f1# View Debian's changelog of a given package
2129     dchange() {
2130         emulate -L zsh
2131         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
2132             $PAGER /usr/share/doc/$1/changelog.Debian.gz
2133         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2134             $PAGER /usr/share/doc/$1/changelog.gz
2135         else
2136             if check_com -c aptitude ; then
2137                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2138                 if isgrml ; then
2139                     aptitude -t unstable changelog $1
2140                 else
2141                     aptitude changelog $1
2142                 fi
2143             else
2144                 echo "No changelog for package $1 found, sorry."
2145                 return 1
2146             fi
2147         fi
2148     }
2149     _dchange() { _files -W /usr/share/doc -/ }
2150     compdef _dchange dchange
2151
2152     #f1# View Debian's NEWS of a given package
2153     dnews() {
2154         emulate -L zsh
2155         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2156             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2157         else
2158             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2159                 $PAGER /usr/share/doc/$1/NEWS.gz
2160             else
2161                 echo "No NEWS file for package $1 found, sorry."
2162                 return 1
2163             fi
2164         fi
2165     }
2166     _dnews() { _files -W /usr/share/doc -/ }
2167     compdef _dnews dnews
2168
2169     #f1# View Debian's copyright of a given package
2170     dcopyright() {
2171         emulate -L zsh
2172         if [[ -r /usr/share/doc/$1/copyright ]] ; then
2173             $PAGER /usr/share/doc/$1/copyright
2174         else
2175             echo "No copyright file for package $1 found, sorry."
2176             return 1
2177         fi
2178     }
2179     _dcopyright() { _files -W /usr/share/doc -/ }
2180     compdef _dcopyright dcopyright
2181
2182     #f1# View upstream's changelog of a given package
2183     uchange() {
2184         emulate -L zsh
2185         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2186             $PAGER /usr/share/doc/$1/changelog.gz
2187         else
2188             echo "No changelog for package $1 found, sorry."
2189             return 1
2190         fi
2191     }
2192     _uchange() { _files -W /usr/share/doc -/ }
2193     compdef _uchange uchange
2194 fi
2195
2196 # zsh profiling
2197 profile() {
2198     ZSH_PROFILE_RC=1 $SHELL "$@"
2199 }
2200
2201 #f1# Edit an alias via zle
2202 edalias() {
2203     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2204 }
2205 compdef _aliases edalias
2206
2207 #f1# Edit a function via zle
2208 edfunc() {
2209     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2210 }
2211 compdef _functions edfunc
2212
2213 # use it e.g. via 'Restart apache2'
2214 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2215 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2216 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2217 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2218 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2219 #m# f6 Status() \kbd{/etc/init.d/\em{process}}\quad\kbd{status}
2220 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2221     __start_stop() {
2222         local action_="${1:l}"  # e.g Start/Stop/Restart
2223         local service_="$2"
2224         local param_="$3"
2225
2226         local service_target_="$(readlink /etc/init.d/$service_)"
2227         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2228             # runit
2229             case "${action_}" in
2230                 start) if [[ ! -e /etc/service/$service_ ]]; then
2231                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2232                        else
2233                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2234                        fi ;;
2235                 # there is no reload in runits sysv emulation
2236                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2237                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2238             esac
2239         else
2240             # sysvinit
2241             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2242         fi
2243     }
2244
2245     _grmlinitd() {
2246         local -a scripts
2247         scripts=( /etc/init.d/*(x:t) )
2248         _describe "service startup script" scripts
2249     }
2250
2251     for i in Start Restart Stop Force-Reload Reload Status ; do
2252         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2253         compdef _grmlinitd $i
2254     done
2255 fi
2256
2257 #f1# Provides useful information on globbing
2258 H-Glob() {
2259     echo -e "
2260     /      directories
2261     .      plain files
2262     @      symbolic links
2263     =      sockets
2264     p      named pipes (FIFOs)
2265     *      executable plain files (0100)
2266     %      device files (character or block special)
2267     %b     block special files
2268     %c     character special files
2269     r      owner-readable files (0400)
2270     w      owner-writable files (0200)
2271     x      owner-executable files (0100)
2272     A      group-readable files (0040)
2273     I      group-writable files (0020)
2274     E      group-executable files (0010)
2275     R      world-readable files (0004)
2276     W      world-writable files (0002)
2277     X      world-executable files (0001)
2278     s      setuid files (04000)
2279     S      setgid files (02000)
2280     t      files with the sticky bit (01000)
2281
2282   print *(m-1)          # Files modified up to a day ago
2283   print *(a1)           # Files accessed a day ago
2284   print *(@)            # Just symlinks
2285   print *(Lk+50)        # Files bigger than 50 kilobytes
2286   print *(Lk-50)        # Files smaller than 50 kilobytes
2287   print **/*.c          # All *.c files recursively starting in \$PWD
2288   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2289   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2290   print *~*.*           # All Files that do not contain a dot
2291   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2292   print -l *(.c|.h)     # Lists *.c and *.h
2293   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2294   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2295 }
2296 alias help-zshglob=H-Glob
2297
2298 #v1# set number of lines to display per page
2299 HELP_LINES_PER_PAGE=20
2300 #v1# set location of help-zle cache file
2301 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
2302 #f1# helper function for help-zle, actually generates the help text
2303 help_zle_parse_keybindings()
2304 {
2305     emulate -L zsh
2306     setopt extendedglob
2307     unsetopt ksharrays  #indexing starts at 1
2308
2309     #v1# choose files that help-zle will parse for keybindings
2310     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
2311
2312     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
2313         local load_cache=0
2314         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
2315         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
2316     fi
2317
2318     #fill with default keybindings, possibly to be overwriten in a file later
2319     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2320     local -A help_zle_keybindings
2321     help_zle_keybindings['<Ctrl>@']="set MARK"
2322     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
2323     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
2324     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
2325     help_zle_keybindings['<Ctrl>_']="undo"
2326     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
2327     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
2328     help_zle_keybindings['<Ctrl>e']="goto end of line"
2329     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2330     help_zle_keybindings['<Alt>t']="transpose words"
2331     help_zle_keybindings['<Alt>s']="spellcheck word"
2332     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
2333     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
2334     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2335     help_zle_keybindings["<Alt>'"]="quote line"
2336     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2337     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2338     help_zle_keybindings['<Alt>u']="make next word Uppercase"
2339     help_zle_keybindings['<Alt>l']="make next word lowercase"
2340     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
2341     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2342     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2343     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2344     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2345     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
2346     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2347     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2348     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
2349
2350     #init global variables
2351     unset help_zle_lines help_zle_sln
2352     typeset -g -a help_zle_lines
2353     typeset -g help_zle_sln=1
2354
2355     local k v
2356     local lastkeybind_desc contents     #last description starting with #k# that we found
2357     local num_lines_elapsed=0            #number of lines between last description and keybinding
2358     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2359     for f in $HELPZLE_KEYBINDING_FILES; do
2360         [[ -r "$f" ]] || continue   #not readable ? skip it
2361         contents="$(<$f)"
2362         for cline in "${(f)contents}"; do
2363             #zsh pattern: matches lines like: #k# ..............
2364             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2365                 lastkeybind_desc="$match[*]"
2366                 num_lines_elapsed=0
2367             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2368             #             ignores lines that are commentend out
2369             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2370             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2371                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2372                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2373                     #substitute keybinding string with something readable
2374                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2375                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2376                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2377                     help_zle_keybindings[${k}]=$lastkeybind_desc
2378                 fi
2379                 lastkeybind_desc=""
2380             else
2381               ((num_lines_elapsed++))
2382             fi
2383         done
2384     done
2385     unset contents
2386     #calculate length of keybinding column
2387     local kstrlen=0
2388     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2389     #convert the assoc array into preformated lines, which we are able to sort
2390     for k v in ${(kv)help_zle_keybindings[@]}; do
2391         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2392         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2393     done
2394     #sort lines alphabetically
2395     help_zle_lines=("${(i)help_zle_lines[@]}")
2396     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2397     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2398     zcompile $HELP_ZLE_CACHE_FILE
2399 }
2400 typeset -g help_zle_sln
2401 typeset -g -a help_zle_lines
2402
2403 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2404 help-zle()
2405 {
2406     emulate -L zsh
2407     unsetopt ksharrays  #indexing starts at 1
2408     #help lines already generated ? no ? then do it
2409     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2410     #already displayed all lines ? go back to the start
2411     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2412     local sln=$help_zle_sln
2413     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2414     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2415     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2416 }
2417 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2418 zle -N help-zle && bindkey '^xz' help-zle
2419
2420 # grep for running process, like: 'any vim'
2421 any() {
2422     emulate -L zsh
2423     unsetopt KSH_ARRAYS
2424     if [[ -z "$1" ]] ; then
2425         echo "any - grep for process(es) by keyword" >&2
2426         echo "Usage: any <keyword>" >&2 ; return 1
2427     else
2428         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
2429     fi
2430 }
2431
2432
2433 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2434 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2435 [[ -r /proc/1/maps ]] && \
2436 deswap() {
2437     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2438     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2439     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2440 }
2441
2442 # a wrapper for vim, that deals with title setting
2443 #   VIM_OPTIONS
2444 #       set this array to a set of options to vim you always want
2445 #       to have set when calling vim (in .zshrc.local), like:
2446 #           VIM_OPTIONS=( -p )
2447 #       This will cause vim to send every file given on the
2448 #       commandline to be send to it's own tab (needs vim7).
2449 if check_com vim; then
2450     vim() {
2451         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2452     }
2453 fi
2454
2455 # make a backup of a file
2456 bk() {
2457     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2458 }
2459
2460 ssl_hashes=( sha512 sha256 sha1 md5 )
2461
2462 for sh in ${ssl_hashes}; do
2463     eval 'ssl-cert-'${sh}'() {
2464         emulate -L zsh
2465         if [[ -z $1 ]] ; then
2466             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2467             return 1
2468         fi
2469         openssl x509 -noout -fingerprint -'${sh}' -in $1
2470     }'
2471 done; unset sh
2472
2473 ssl-cert-fingerprints() {
2474     emulate -L zsh
2475     local i
2476     if [[ -z $1 ]] ; then
2477         printf 'usage: ssl-cert-fingerprints <file>\n'
2478         return 1
2479     fi
2480     for i in ${ssl_hashes}
2481         do ssl-cert-$i $1;
2482     done
2483 }
2484
2485 ssl-cert-info() {
2486     emulate -L zsh
2487     if [[ -z $1 ]] ; then
2488         printf 'usage: ssl-cert-info <file>\n'
2489         return 1
2490     fi
2491     openssl x509 -noout -text -in $1
2492     ssl-cert-fingerprints $1
2493 }
2494
2495 # make sure our environment is clean regarding colors
2496 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2497
2498 # "persistent history"
2499 # just write important commands you always need to ~/.important_commands
2500 if [[ -r ~/.important_commands ]] ; then
2501     fc -R ~/.important_commands
2502 fi
2503
2504 # load the lookup subsystem if it's available on the system
2505 zrcautoload lookupinit && lookupinit
2506
2507 # variables
2508
2509 # set terminal property (used e.g. by msgid-chooser)
2510 export COLORTERM="yes"
2511
2512 # aliases
2513
2514 # general
2515 #a2# Execute \kbd{du -sch}
2516 alias da='du -sch'
2517 #a2# Execute \kbd{jobs -l}
2518 alias j='jobs -l'
2519
2520 # listing stuff
2521 #a2# Execute \kbd{ls -lSrah}
2522 alias dir="ls -lSrah"
2523 #a2# Only show dot-directories
2524 alias lad='ls -d .*(/)'
2525 #a2# Only show dot-files
2526 alias lsa='ls -a .*(.)'
2527 #a2# Only files with setgid/setuid/sticky flag
2528 alias lss='ls -l *(s,S,t)'
2529 #a2# Only show symlinks
2530 alias lsl='ls -l *(@)'
2531 #a2# Display only executables
2532 alias lsx='ls -l *(*)'
2533 #a2# Display world-{readable,writable,executable} files
2534 alias lsw='ls -ld *(R,W,X.^ND/)'
2535 #a2# Display the ten biggest files
2536 alias lsbig="ls -flh *(.OL[1,10])"
2537 #a2# Only show directories
2538 alias lsd='ls -d *(/)'
2539 #a2# Only show empty directories
2540 alias lse='ls -d *(/^F)'
2541 #a2# Display the ten newest files
2542 alias lsnew="ls -rtlh *(D.om[1,10])"
2543 #a2# Display the ten oldest files
2544 alias lsold="ls -rtlh *(D.Om[1,10])"
2545 #a2# Display the ten smallest files
2546 alias lssmall="ls -Srl *(.oL[1,10])"
2547 #a2# Display the ten newest directories and ten newest .directories
2548 alias lsnewdir="ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
2549 #a2# Display the ten oldest directories and ten oldest .directories
2550 alias lsolddir="ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
2551
2552 # some useful aliases
2553 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir $OLDCWD}
2554 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2555
2556 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2557 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2558 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2559
2560 # work around non utf8 capable software in utf environment via $LANG and luit
2561 if check_com isutfenv && check_com luit ; then
2562     if check_com -c mrxvt ; then
2563         isutfenv && [[ -n "$LANG" ]] && \
2564             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2565     fi
2566
2567     if check_com -c aterm ; then
2568         isutfenv && [[ -n "$LANG" ]] && \
2569             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2570     fi
2571
2572     if check_com -c centericq ; then
2573         isutfenv && [[ -n "$LANG" ]] && \
2574             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2575     fi
2576 fi
2577
2578 # useful functions
2579
2580 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2581 bk() {
2582     emulate -L zsh
2583     cp -b $1 $1_`date --iso-8601=m`
2584 }
2585
2586 #f5# cd to directoy and list files
2587 cl() {
2588     emulate -L zsh
2589     cd $1 && ls -a
2590 }
2591
2592 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2593 cd() {
2594     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2595         [[ ! -e ${1:h} ]] && return 1
2596         print "Correcting ${1} to ${1:h}"
2597         builtin cd ${1:h}
2598     else
2599         builtin cd "$@"
2600     fi
2601 }
2602
2603 #f5# Create Directoy and \kbd{cd} to it
2604 mkcd() {
2605     if (( ARGC != 1 )); then
2606         printf 'usage: mkcd <new-directory>\n'
2607         return 1;
2608     fi
2609     if [[ ! -d "$1" ]]; then
2610         command mkdir -p "$1"
2611     else
2612         printf '`%s'\'' already exists: cd-ing.\n' "$1"
2613     fi
2614     builtin cd "$1"
2615 }
2616
2617 #f5# Create temporary directory and \kbd{cd} to it
2618 cdt() {
2619     local t
2620     t=$(mktemp -d)
2621     echo "$t"
2622     builtin cd "$t"
2623 }
2624
2625 #f5# Create directory under cursor or the selected area
2626 # Press ctrl-xM to create the directory under the cursor or the selected area.
2627 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2628 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2629 # directory does not exist yet -> press ctrl-XM and problem solved
2630 inplaceMkDirs() {
2631     local PATHTOMKDIR
2632     if ((REGION_ACTIVE==1)); then
2633         local F=$MARK T=$CURSOR
2634         if [[ $F -gt $T ]]; then
2635             F=${CURSOR}
2636             T=${MARK}
2637         fi
2638         # get marked area from buffer and eliminate whitespace
2639         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2640         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2641     else
2642         local bufwords iword
2643         bufwords=(${(z)LBUFFER})
2644         iword=${#bufwords}
2645         bufwords=(${(z)BUFFER})
2646         PATHTOMKDIR="${(Q)bufwords[iword]}"
2647     fi
2648     [[ -z "${PATHTOMKDIR}" ]] && return 1
2649     PATHTOMKDIR=${~PATHTOMKDIR}
2650     if [[ -e "${PATHTOMKDIR}" ]]; then
2651         zle -M " path already exists, doing nothing"
2652     else
2653         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2654         zle end-of-line
2655     fi
2656 }
2657 #k# mkdir -p <dir> from string under cursor or marked area
2658 zle -N inplaceMkDirs && bindkey '^xM' inplaceMkDirs
2659
2660 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2661 accessed() {
2662     emulate -L zsh
2663     print -l -- *(a-${1:-1})
2664 }
2665
2666 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2667 changed() {
2668     emulate -L zsh
2669     print -l -- *(c-${1:-1})
2670 }
2671
2672 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2673 modified() {
2674     emulate -L zsh
2675     print -l -- *(m-${1:-1})
2676 }
2677 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2678 check_com new || alias new=modified
2679
2680 # use colors when GNU grep with color-support
2681 #a2# Execute \kbd{grep -{}-color=auto}
2682 (( $#grep_options > 0 )) && alias grep='grep '${grep_options:+"${grep_options[*]}"}
2683
2684 # Translate DE<=>EN
2685 # 'translate' looks up fot a word in a file with language-to-language
2686 # translations (field separator should be " : "). A typical wordlist looks
2687 # like at follows:
2688 #  | english-word : german-transmission
2689 # It's also only possible to translate english to german but not reciprocal.
2690 # Use the following oneliner to turn back the sort order:
2691 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2692 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2693 #f5# Translates a word
2694 trans() {
2695     emulate -L zsh
2696     case "$1" in
2697         -[dD]*)
2698             translate -l de-en $2
2699             ;;
2700         -[eE]*)
2701             translate -l en-de $2
2702             ;;
2703         *)
2704             echo "Usage: $0 { -D | -E }"
2705             echo "         -D == German to English"
2706             echo "         -E == English to German"
2707     esac
2708 }
2709
2710 # Usage: simple-extract <file>
2711 # Using option -d deletes the original archive file.
2712 #f5# Smart archive extractor
2713 simple-extract() {
2714     emulate -L zsh
2715     setopt extended_glob noclobber
2716     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2717     local RC=0
2718     zparseopts -D -E "d=DELETE_ORIGINAL"
2719     for ARCHIVE in "${@}"; do
2720         case $ARCHIVE in
2721             *(tar.bz2|tbz2|tbz))
2722                 DECOMP_CMD="tar -xvjf -"
2723                 USES_STDIN=true
2724                 USES_STDOUT=false
2725                 ;;
2726             *(tar.gz|tgz))
2727                 DECOMP_CMD="tar -xvzf -"
2728                 USES_STDIN=true
2729                 USES_STDOUT=false
2730                 ;;
2731             *(tar.xz|txz|tar.lzma))
2732                 DECOMP_CMD="tar -xvJf -"
2733                 USES_STDIN=true
2734                 USES_STDOUT=false
2735                 ;;
2736             *tar)
2737                 DECOMP_CMD="tar -xvf -"
2738                 USES_STDIN=true
2739                 USES_STDOUT=false
2740                 ;;
2741             *rar)
2742                 DECOMP_CMD="unrar x"
2743                 USES_STDIN=false
2744                 USES_STDOUT=false
2745                 ;;
2746             *lzh)
2747                 DECOMP_CMD="lha x"
2748                 USES_STDIN=false
2749                 USES_STDOUT=false
2750                 ;;
2751             *7z)
2752                 DECOMP_CMD="7z x"
2753                 USES_STDIN=false
2754                 USES_STDOUT=false
2755                 ;;
2756             *(zip|jar))
2757                 DECOMP_CMD="unzip"
2758                 USES_STDIN=false
2759                 USES_STDOUT=false
2760                 ;;
2761             *deb)
2762                 DECOMP_CMD="ar -x"
2763                 USES_STDIN=false
2764                 USES_STDOUT=false
2765                 ;;
2766             *bz2)
2767                 DECOMP_CMD="bzip2 -d -c -"
2768                 USES_STDIN=true
2769                 USES_STDOUT=true
2770                 ;;
2771             *(gz|Z))
2772                 DECOMP_CMD="gzip -d -c -"
2773                 USES_STDIN=true
2774                 USES_STDOUT=true
2775                 ;;
2776             *(xz|lzma))
2777                 DECOMP_CMD="xz -d -c -"
2778                 USES_STDIN=true
2779                 USES_STDOUT=true
2780                 ;;
2781             *)
2782                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2783                 RC=$((RC+1))
2784                 continue
2785                 ;;
2786         esac
2787
2788         if ! check_com ${DECOMP_CMD[(w)1]}; then
2789             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2790             RC=$((RC+2))
2791             continue
2792         fi
2793
2794         GZTARGET="${ARCHIVE:t:r}"
2795         if [[ -f $ARCHIVE ]] ; then
2796
2797             print "Extracting '$ARCHIVE' ..."
2798             if $USES_STDIN; then
2799                 if $USES_STDOUT; then
2800                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
2801                 else
2802                     ${=DECOMP_CMD} < "$ARCHIVE"
2803                 fi
2804             else
2805                 if $USES_STDOUT; then
2806                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
2807                 else
2808                     ${=DECOMP_CMD} "$ARCHIVE"
2809                 fi
2810             fi
2811             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
2812
2813         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
2814             if check_com curl; then
2815                 WGET_CMD="curl -L -k -s -o -"
2816             elif check_com wget; then
2817                 WGET_CMD="wget -q -O - --no-check-certificate"
2818             else
2819                 print "ERROR: neither wget nor curl is installed" >&2
2820                 RC=$((RC+4))
2821                 continue
2822             fi
2823             print "Downloading and Extracting '$ARCHIVE' ..."
2824             if $USES_STDIN; then
2825                 if $USES_STDOUT; then
2826                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
2827                     RC=$((RC+$?))
2828                 else
2829                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
2830                     RC=$((RC+$?))
2831                 fi
2832             else
2833                 if $USES_STDOUT; then
2834                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
2835                 else
2836                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
2837                 fi
2838             fi
2839
2840         else
2841             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
2842             RC=$((RC+8))
2843         fi
2844     done
2845     return $RC
2846 }
2847
2848 __archive_or_uri()
2849 {
2850     _alternative \
2851         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
2852         '_urls:Remote Archives:_urls'
2853 }
2854
2855 _simple_extract()
2856 {
2857     _arguments \
2858         '-d[delete original archivefile after extraction]' \
2859         '*:Archive Or Uri:__archive_or_uri'
2860 }
2861 compdef _simple_extract simple-extract
2862 alias se=simple-extract
2863
2864 #f5# Set all ulimit parameters to \kbd{unlimited}
2865 allulimit() {
2866     ulimit -c unlimited
2867     ulimit -d unlimited
2868     ulimit -f unlimited
2869     ulimit -l unlimited
2870     ulimit -n unlimited
2871     ulimit -s unlimited
2872     ulimit -t unlimited
2873 }
2874
2875 #f5# Change the xterm title from within GNU-screen
2876 xtrename() {
2877     emulate -L zsh
2878     if [[ $1 != "-f" ]] ; then
2879         if [[ -z ${DISPLAY} ]] ; then
2880             printf 'xtrename only makes sense in X11.\n'
2881             return 1
2882         fi
2883     else
2884         shift
2885     fi
2886     if [[ -z $1 ]] ; then
2887         printf 'usage: xtrename [-f] "title for xterm"\n'
2888         printf '  renames the title of xterm from _within_ screen.\n'
2889         printf '  also works without screen.\n'
2890         printf '  will not work if DISPLAY is unset, use -f to override.\n'
2891         return 0
2892     fi
2893     print -n "\eP\e]0;${1}\C-G\e\\"
2894     return 0
2895 }
2896
2897 # Create small urls via http://goo.gl using curl(1).
2898 # API reference: https://code.google.com/apis/urlshortener/
2899 function zurl() {
2900     emulate -L zsh
2901     setopt extended_glob
2902
2903     if [[ -z $1 ]]; then
2904         print "USAGE: zurl <URL>"
2905         return 1
2906     fi
2907
2908     local PN url prog api json contenttype item
2909     local -a data
2910     PN=$0
2911     url=$1
2912
2913     # Prepend 'http://' to given URL where necessary for later output.
2914     if [[ ${url} != http(s|)://* ]]; then
2915         url='http://'${url}
2916     fi
2917
2918     if check_com -c curl; then
2919         prog=curl
2920     else
2921         print "curl is not available, but mandatory for ${PN}. Aborting."
2922         return 1
2923     fi
2924     api='https://www.googleapis.com/urlshortener/v1/url'
2925     contenttype="Content-Type: application/json"
2926     json="{\"longUrl\": \"${url}\"}"
2927     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
2928     # Parse the response
2929     for item in "${data[@]}"; do
2930         case "$item" in
2931             ' '#'"id":'*)
2932                 item=${item#*: \"}
2933                 item=${item%\",*}
2934                 printf '%s\n' "$item"
2935                 return 0
2936                 ;;
2937         esac
2938     done
2939     return 1
2940 }
2941
2942 #f2# Find history events by search pattern and list them by date.
2943 whatwhen()  {
2944     emulate -L zsh
2945     local usage help ident format_l format_s first_char remain first last
2946     usage='USAGE: whatwhen [options] <searchstring> <search range>'
2947     help='Use `whatwhen -h'\'' for further explanations.'
2948     ident=${(l,${#${:-Usage: }},, ,)}
2949     format_l="${ident}%s\t\t\t%s\n"
2950     format_s="${format_l//(\\t)##/\\t}"
2951     # Make the first char of the word to search for case
2952     # insensitive; e.g. [aA]
2953     first_char=[${(L)1[1]}${(U)1[1]}]
2954     remain=${1[2,-1]}
2955     # Default search range is `-100'.
2956     first=${2:-\-100}
2957     # Optional, just used for `<first> <last>' given.
2958     last=$3
2959     case $1 in
2960         ("")
2961             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
2962             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2963         ;;
2964         (-h)
2965             printf '%s\n\n' ${usage}
2966             print 'OPTIONS:'
2967             printf $format_l '-h' 'show help text'
2968             print '\f'
2969             print 'SEARCH RANGE:'
2970             printf $format_l "'0'" 'the whole history,'
2971             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
2972             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
2973             printf '\n%s\n' 'EXAMPLES:'
2974             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
2975             printf $format_l 'whatwhen zsh -250'
2976             printf $format_l 'whatwhen foo 1 99'
2977         ;;
2978         (\?)
2979             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2980         ;;
2981         (*)
2982             # -l list results on stout rather than invoking $EDITOR.
2983             # -i Print dates as in YYYY-MM-DD.
2984             # -m Search for a - quoted - pattern within the history.
2985             fc -li -m "*${first_char}${remain}*" $first $last
2986         ;;
2987     esac
2988 }
2989
2990 # mercurial related stuff
2991 if check_com -c hg ; then
2992     # gnu like diff for mercurial
2993     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
2994     #f5# GNU like diff for mercurial
2995     hgdi() {
2996         emulate -L zsh
2997         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
2998     }
2999
3000     # build debian package
3001     #a2# Alias for \kbd{hg-buildpackage}
3002     alias hbp='hg-buildpackage'
3003
3004     # execute commands on the versioned patch-queue from the current repos
3005     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
3006
3007     # diffstat for specific version of a mercurial repository
3008     #   hgstat      => display diffstat between last revision and tip
3009     #   hgstat 1234 => display diffstat between revision 1234 and tip
3010     #f5# Diffstat for specific version of a mercurial repos
3011     hgstat() {
3012         emulate -L zsh
3013         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
3014     }
3015
3016 fi # end of check whether we have the 'hg'-executable
3017
3018 # grml-small cleanups
3019
3020 # The following is used to remove zsh-config-items that do not work
3021 # in grml-small by default.
3022 # If you do not want these adjustments (for whatever reason), set
3023 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
3024 # sources if it is there).
3025
3026 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
3027
3028     unset abk[V]
3029     unalias    'V'      &> /dev/null
3030     unfunction vman     &> /dev/null
3031     unfunction viless   &> /dev/null
3032     unfunction 2html    &> /dev/null
3033
3034     # manpages are not in grmlsmall
3035     unfunction manzsh   &> /dev/null
3036     unfunction man2     &> /dev/null
3037
3038 fi
3039
3040 zrclocal
3041
3042 ## genrefcard.pl settings
3043
3044 ### doc strings for external functions from files
3045 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
3046
3047 ### example: split functions-search 8,16,24,32
3048 #@# split functions-search 8
3049
3050 ## END OF FILE #################################################################
3051 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
3052 # Local variables:
3053 # mode: sh
3054 # End: