etc/zsh/zshrc

   1 # Filename:      zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # zsh-refcard-tag documentation: {{{
  15 #   You may notice strange looking comments in this file.
  16 #   These are there for a purpose. grml's zsh-refcard can now be
  17 #   automatically generated from the contents of the actual configuration
  18 #   file. However, we need a little extra information on which comments
  19 #   and what lines of code to take into account (and for what purpose).
  20 #
  21 # Here is what they mean:
  22 #
  23 # List of tags (comment types) used:
  24 #   #a#     Next line contains an important alias, that should
  25 #           be included in the grml-zsh-refcard.
  26 #           (placement tag: @@INSERT-aliases@@)
  27 #   #f#     Next line contains the beginning of an important function.
  28 #           (placement tag: @@INSERT-functions@@)
  29 #   #v#     Next line contains an important variable.
  30 #           (placement tag: @@INSERT-variables@@)
  31 #   #k#     Next line contains an important keybinding.
  32 #           (placement tag: @@INSERT-keybindings@@)
  33 #   #d#     Hashed directories list generation:
  34 #               start   denotes the start of a list of 'hash -d'
  35 #                       definitions.
  36 #               end     denotes its end.
  37 #           (placement tag: @@INSERT-hasheddirs@@)
  38 #   #A#     Abbreviation expansion list generation:
  39 #               start   denotes the beginning of abbreviations.
  40 #               end     denotes their end.
  41 #           Lines within this section that end in '#d .*' provide
  42 #           extra documentation to be included in the refcard.
  43 #           (placement tag: @@INSERT-abbrev@@)
  44 #   #m#     This tag allows you to manually generate refcard entries
  45 #           for code lines that are hard/impossible to parse.
  46 #               Example:
  47 #                   #m# k ESC-h Call the run-help function
  48 #               That would add a refcard entry in the keybindings table
  49 #               for 'ESC-h' with the given comment.
  50 #           So the syntax is: #m# <section> <argument> <comment>
  51 #   #o#     This tag lets you insert entries to the 'other' hash.
  52 #           Generally, this should not be used. It is there for
  53 #           things that cannot be done easily in another way.
  54 #           (placement tag: @@INSERT-other-foobar@@)
  55 #
  56 #   All of these tags (except for m and o) take two arguments, the first
  57 #   within the tag, the other after the tag:
  58 #
  59 #   #<tag><section># <comment>
  60 #
  61 #   Where <section> is really just a number, which are defined by the
  62 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  63 #   instead of names is, that for the reader, the tag should not differ
  64 #   much from a regular comment. For zsh, it is a regular comment indeed.
  65 #   The numbers have got the following meanings:
  66 #         0 -> "default"
  67 #         1 -> "system"
  68 #         2 -> "user"
  69 #         3 -> "debian"
  70 #         4 -> "search"
  71 #         5 -> "shortcuts"
  72 #         6 -> "services"
  73 #
  74 #   So, the following will add an entry to the 'functions' table in the
  75 #   'system' section, with a (hopefully) descriptive comment:
  76 #       #f1# Edit an alias via zle
  77 #       edalias() {
  78 #
  79 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  80 #   that can be found in 'grml-zsh-refcard.tex.in'.
  81 #   If the section number is omitted, the 'default' section is assumed.
  82 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
  83 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
  84 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
  85 #}}}
  86
  87 # zsh profiling {{{
  88 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
  89 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
  90     zmodload zsh/zprof
  91 fi
  92 # }}}
  93
  94 # load .zshrc.pre to give the user the chance to overwrite the defaults
  95 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
  96
  97 # {{{ check for version/system
  98 # check for versions (compatibility reasons)
  99 is4(){
 100     [[ $ZSH_VERSION == <4->* ]] && return 0
 101     return 1
 102 }
 103
 104 is41(){
 105     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 106     return 1
 107 }
 108
 109 is42(){
 110     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 111     return 1
 112 }
 113
 114 is425(){
 115     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 116     return 1
 117 }
 118
 119 is43(){
 120     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 121     return 1
 122 }
 123
 124 #f1# Checks whether or not you're running grml
 125 isgrml(){
 126     [[ -f /etc/grml_version ]] && return 0
 127     return 1
 128 }
 129
 130 #f1# Checks whether or not you're running a grml cd
 131 isgrmlcd(){
 132     [[ -f /etc/grml_cd ]] && return 0
 133     return 1
 134 }
 135
 136 if isgrml ; then
 137 #f1# Checks whether or not you're running grml-small
 138     isgrmlsmall() {
 139         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 140     }
 141 else
 142     isgrmlsmall() { return 1 }
 143 fi
 144
 145 isdarwin(){
 146     [[ $OSTYPE == darwin* ]] && return 0
 147     return 1
 148 }
 149
 150 #f1# are we running within an utf environment?
 151 isutfenv() {
 152     case "$LANG $CHARSET $LANGUAGE" in
 153         *utf*) return 0 ;;
 154         *UTF*) return 0 ;;
 155         *)     return 1 ;;
 156     esac
 157 }
 158
 159 # check for user, if not running as root set $SUDO to sudo
 160 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 161
 162 # change directory to home on first invocation of zsh
 163 # important for rungetty -> autologin
 164 # Thanks go to Bart Schaefer!
 165 isgrml && checkhome() {
 166     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 167         export ALREADY_DID_CD_HOME=$HOME
 168         cd
 169     fi
 170 }
 171
 172 # check for zsh v3.1.7+
 173
 174 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 175      || ${ZSH_VERSION} == 3.<2->.<->*    \
 176      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 177
 178     printf '-!-\n'
 179     printf '-!- In this configuration we try to make use of features, that only\n'
 180     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 181     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 182     printf '-!- advanced features in all supported versions.\n'
 183     printf '-!-\n'
 184     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 185     printf '-!-\n'
 186     printf '-!- While this *may* work, it might as well fail.\n'
 187     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 188     printf '-!-\n'
 189     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 190     printf '-!- If it does today, you'\''ve been lucky.\n'
 191     printf '-!-\n'
 192     printf '-!- Ye been warned!\n'
 193     printf '-!-\n'
 194
 195     function zstyle() { : }
 196 fi
 197
 198 # autoload wrapper - use this one instead of autoload directly
 199 # We need to define this function as early as this, because autoloading
 200 # 'is-at-least()' needs it.
 201 function zrcautoload() {
 202     setopt local_options extended_glob
 203     local fdir ffile
 204     local -i ffound
 205
 206     ffile=${1}
 207     (( found = 0 ))
 208     for fdir in ${fpath} ; do
 209         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 210     done
 211
 212     (( ffound == 0 )) && return 1
 213     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 214         autoload -U ${ffile} || return 1
 215     else
 216         autoload ${ffile} || return 1
 217     fi
 218     return 0
 219 }
 220
 221 # Load is-at-least() for more precise version checks
 222 # Note that this test will *always* fail, if the is-at-least
 223 # function could not be marked for autoloading.
 224 zrcautoload is-at-least || is-at-least() { return 1 }
 225
 226 # }}}
 227
 228 # setting some default values {{{
 229
 230 NOCOR=${NOCOR:-0}
 231 NOMENU=${NOMENU:-0}
 232 NOPRECMD=${NOPRECMD:-0}
 233 BATTERY=${BATTERY:-0}
 234 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 235 GRML_ALWAYS_LOAD_ALL=${GRML_ALWAYS_LOAD_ALL:-0}
 236 GRML_WARN_SKEL=${GRML_WARN_SKEL:-1}
 237
 238 if (( GRML_WARN_SKEL != 0 )) ; then
 239
 240 function grml_warn_skel_main() {
 241     printf '
 242 Dear user,
 243
 244 You updated grml'\''s zshrc which brings a major change.
 245 The configuration is kept only in one file, being the global zshrc.
 246 In the past, the configuration was split in two files, with the
 247 second file being the .zshrc file from /etc/skel.
 248
 249 If you have a .zshrc file in your home directory that originally
 250 came from the skel directory, please remove it. This is also the case
 251 if you followed earlier instructions from the grml-zsh-refcard or
 252 from <http://grml.org/console> on non-grml systems.
 253
 254 Please see the current grml-zsh-refcard for updated installation
 255 information. In short, you don'\''t want a .zshrc.global file. Install
 256 the global zshrc to ~/.zshrc and be done.
 257
 258 If you need changes to the configuration, use ~/.zshrc.pre and
 259 ~/.zshrc.local.
 260
 261 '
 262 }
 263
 264 function grml_warn_skel_remove() {
 265     printf 'To remove this warning execute '\''grml_do_not_warn_skel'\''.\n\n'
 266 }
 267
 268 function grml_do_not_warn_skel() {
 269     printf '# Do not warn about old skel dot-files anymore\n' >>! ~/.zshrc.pre
 270     printf 'GRML_WARN_SKEL=0\n' >>! ~/.zshrc.pre
 271 }
 272
 273 # let's try to guess how the user uses us.
 274 if is-at-least 4.3.7 ; then
 275     # funcsourcetrace requires at least version 4.3.7 of zsh.
 276     GRML_SRC_FILE="${${funcsourcetrace[1]}%:*}"
 277
 278     grml_warn_skel_main
 279     case ${GRML_SRC_FILE} in
 280         (${HOME}/.zshrc.global)
 281             grml_warn_skel_remove
 282             printf '\nIt looks like you copied the grml zshrc to '\''~/.zshrc.global'\''.\n'
 283             printf 'Nowadays you just copy the global zshrc to '\''~/.zshrc'\'' to use\n'
 284             printf 'it on a non-grml-system.\n'
 285             ;;
 286         (${HOME}/.zshrc)
 287             printf '\nIt looks like you copied the grml zshrc to '\''~/.zshrc'\''.\n'
 288             printf 'We'\''ll disable this warning automatically for later sessions.\n'
 289             grml_do_not_warn_skel
 290             ;;
 291         (*)
 292             grml_do_not_warn_skel
 293             ;;
 294     esac
 295 else
 296     grml_warn_skel_main
 297     grml_warn_skel_remove
 298 fi
 299
 300 unfunction grml_warn_skel_remove grml_warn_skel_main
 301
 302 fi # GRML_WARN_SKEL
 303
 304 # }}}
 305
 306 # utility functions {{{
 307 # this function checks if a command exists and returns either true
 308 # or false. This avoids using 'which' and 'whence', which will
 309 # avoid problems with aliases for which on certain weird systems. :-)
 310 check_com() {
 311     local -i comonly
 312
 313     if [[ ${1} == '-c' ]] ; then
 314         (( comonly = 1 ))
 315         shift
 316     else
 317         (( comonly = 0 ))
 318     fi
 319
 320     if (( ${#argv} != 1 )) ; then
 321         printf 'usage: check_com [-c] <command>\n' >&2
 322         return 1
 323     fi
 324
 325     if (( comonly > 0 )) ; then
 326         [[ -n ${commands[$1]}  ]] && return 0
 327         return 1
 328     fi
 329
 330     if   [[ -n ${commands[$1]}    ]] \
 331       || [[ -n ${functions[$1]}   ]] \
 332       || [[ -n ${aliases[$1]}     ]] \
 333       || [[ -n ${reswords[(r)$1]} ]] ; then
 334
 335         return 0
 336     fi
 337
 338     return 1
 339 }
 340
 341 # creates an alias and precedes the command with
 342 # sudo if $EUID is not zero.
 343 salias() {
 344     local only=0 ; local multi=0
 345     while [[ ${1} == -* ]] ; do
 346         case ${1} in
 347             (-o) only=1 ;;
 348             (-a) multi=1 ;;
 349             (--) shift ; break ;;
 350             (-h)
 351                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 352                 printf '  -h      shows this help text.\n'
 353                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 354                 printf '          be careful using this option.\n'
 355                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 356                 return 0
 357                 ;;
 358             (*) printf "unkown option: '%s'\n" "${1}" ; return 1 ;;
 359         esac
 360         shift
 361     done
 362
 363     if (( ${#argv} > 1 )) ; then
 364         printf 'Too many arguments %s\n' "${#argv}"
 365         return 1
 366     fi
 367
 368     key="${1%%\=*}" ;  val="${1#*\=}"
 369     if (( EUID == 0 )) && (( only == 0 )); then
 370         alias -- "${key}=${val}"
 371     elif (( EUID > 0 )) ; then
 372         (( multi > 0 )) && val="${val// ; / ; sudo }"
 373         alias -- "${key}=sudo ${val}"
 374     fi
 375
 376     return 0
 377 }
 378
 379 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 380 # usage: uprint foo
 381 #   Where foo is the *name* of the parameter you want printed.
 382 #   Note that foo is no typo; $foo would be wrong here!
 383 if ! is42 ; then
 384     uprint () {
 385         local -a u
 386         local w
 387         local parameter=${1}
 388
 389         if [[ -z ${parameter} ]] ; then
 390             printf 'usage: uprint <parameter>\n'
 391             return 1
 392         fi
 393
 394         for w in ${(P)parameter} ; do
 395             [[ -z ${(M)u:#${w}} ]] && u=( ${u} ${w} )
 396         done
 397
 398         builtin print -l ${u}
 399     }
 400 fi
 401
 402 # Check if we can read given files and source those we can.
 403 xsource() {
 404     if (( ${#argv} < 1 )) ; then
 405         printf 'usage: xsource FILE(s)...\n' >&2
 406         return 1
 407     fi
 408
 409     while (( ${#argv} > 0 )) ; do
 410         [[ -r ${1} ]] && source ${1}
 411         shift
 412     done
 413     return 0
 414 }
 415
 416 # Check if we can read a given file and 'cat(1)' it.
 417 xcat() {
 418     if (( ${#argv} != 1 )) ; then
 419         printf 'usage: xcat FILE\n' >&2
 420         return 1
 421     fi
 422
 423     [[ -r ${1} ]] && cat ${1}
 424     return 0
 425 }
 426
 427 # Remove these functions again, they are of use only in these
 428 # setup files. This should be called at the end of .zshrc.
 429 xunfunction() {
 430     local -a funcs
 431     funcs=(salias xcat xsource xunfunction zrcautoload)
 432
 433     for func in $funcs ; do
 434         [[ -n ${functions[$func]} ]] \
 435             && unfunction $func
 436     done
 437     return 0
 438 }
 439
 440 #}}}
 441
 442 # locale setup {{{
 443 if [[ -z "$LANG" ]] ; then
 444    xsource "/etc/default/locale"
 445 fi
 446
 447 export LANG=${LANG:-en_US.iso885915}
 448 for var in LC_ALL LC_MESSAGES ; do
 449     [[ -n ${(P)var} ]] && export $var
 450 done
 451
 452 xsource "/etc/sysconfig/keyboard"
 453
 454 TZ=$(xcat /etc/timezone)
 455 # }}}
 456
 457 # check for potentially old files in 'completion.d' {{{
 458 setopt extendedglob
 459 xof=(/etc/zsh/completion.d/*~/etc/zsh/completion.d/_*(N))
 460 if (( ${#xof} > 0 )) ; then
 461     printf '\n -!- INFORMATION\n\n'
 462     printf ' -!- %s file(s) not starting with an underscore (_) found in\n' ${#xof}
 463     printf ' -!- /etc/zsh/completion.d/.\n\n'
 464     printf ' -!- While this has been the case in old versions of grml-etc-core,\n'
 465     printf ' -!- recent versions of the grml-zsh-setup have all these files rewritten\n'
 466     printf ' -!- and renamed. Furthermore, the grml-zsh-setup will *only* add files\n'
 467     printf ' -!- named _* to that directory.\n\n'
 468     printf ' -!- If you added functions to completion.d yourself, please consider\n'
 469     printf ' -!- moving them to /etc/zsh/functions.d/. Files in that directory, not\n'
 470     printf ' -!- starting with an underscore are marked for automatic loading\n'
 471     printf ' -!- by default (so that is quite convenient).\n\n'
 472     printf ' -!- If there are files *not* starting with an underscore from an older\n'
 473     printf ' -!- grml-etc-core in completion.d, you may safely remove them.\n\n'
 474     printf ' -!- Delete the files for example via running:\n\n'
 475     printf "      rm ${xof}\n\n"
 476     printf ' -!- Note, that this message will *not* go away, unless you yourself\n'
 477     printf ' -!- resolve the situation manually.\n\n'
 478     BROKEN_COMPLETION_DIR=1
 479 fi
 480 unset xof
 481 # }}}
 482
 483 # {{{ set some variables
 484 if check_com -c vim ; then
 485 #v#
 486     export EDITOR=${EDITOR:-vim}
 487 else
 488     export EDITOR=${EDITOR:-vi}
 489 fi
 490
 491 #v#
 492 export PAGER=${PAGER:-less}
 493
 494 #v#
 495 export MAIL=${MAIL:-/var/mail/$USER}
 496
 497 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 498 export SHELL='/bin/zsh'
 499
 500 # color setup for ls:
 501 check_com -c dircolors && eval $(dircolors -b)
 502 # color setup for ls on OS X:
 503 isdarwin && export CLICOLOR=1
 504
 505 # do MacPorts setup on darwin
 506 if isdarwin && [[ -d /opt/local ]]; then
 507     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 508     # zshenv.
 509     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 510     MANPATH="/opt/local/share/man:$MANPATH"
 511 fi
 512 # do Fink setup on darwin
 513 isdarwin && xsource /sw/bin/init.sh
 514
 515 # set width of man pages to 80 for more convenient reading
 516 # export MANWIDTH=${MANWIDTH:-80}
 517
 518 # Search path for the cd command
 519 #  cdpath=(.. ~)
 520
 521 # completion functions go to /etc/zsh/completion.d
 522 # function files may be put into /etc/zsh/functions.d, from where they
 523 # will be automatically autoloaded.
 524 if [[ -n "$BROKEN_COMPLETION_DIR" ]] ; then
 525     print 'Warning: not setting completion directories because broken files have been found.' >&2
 526 else
 527     [[ -d /etc/zsh/completion.d ]] && fpath=( $fpath /etc/zsh/completion.d )
 528     if [[ -d /etc/zsh/functions.d ]] ; then
 529         fpath+=( /etc/zsh/functions.d )
 530         for func in /etc/zsh/functions.d/[^_]*[^~](N.) ; do
 531             zrcautoload -U ${func:t}
 532         done
 533     fi
 534 fi
 535
 536 # automatically remove duplicates from these arrays
 537 typeset -U path cdpath fpath manpath
 538 # }}}
 539
 540 # {{{ keybindings
 541 if [[ "$TERM" != emacs ]] ; then
 542     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 543     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 544     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 545     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 546     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 547     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 548     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 549     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 550     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 551     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 552     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 553     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 554     # ncurses stuff:
 555     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 556     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 557     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 558     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 559     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 560     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 561     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 562     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 563 fi
 564
 565 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 566 # use emacs style per default:
 567 bindkey -e
 568 # use vi style:
 569 # bindkey -v
 570
 571 #if [[ "$TERM" == screen ]] ; then
 572 bindkey '\e[1~' beginning-of-line       # home
 573 bindkey '\e[4~' end-of-line             # end
 574 bindkey '\e[A'  up-line-or-search       # cursor up
 575 bindkey '\e[B'  down-line-or-search     # <ESC>-
 576
 577 bindkey '^xp'   history-beginning-search-backward
 578 bindkey '^xP'   history-beginning-search-forward
 579 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 580 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 581 # if terminal type is set to 'rxvt':
 582 bindkey '\e[7~' beginning-of-line       # home
 583 bindkey '\e[8~' end-of-line             # end
 584 #fi
 585
 586 # insert unicode character
 587 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 588 # See for example http://unicode.org/charts/ for unicode characters code
 589 zrcautoload insert-unicode-char
 590 zle -N insert-unicode-char
 591 #k# Insert Unicode character
 592 bindkey '^Xi' insert-unicode-char
 593
 594 # just type 'cd ...' to get 'cd ../..'
 595 #  rationalise-dot() {
 596 #  if [[ $LBUFFER == *.. ]] ; then
 597 #    LBUFFER+=/..
 598 #  else
 599 #    LBUFFER+=.
 600 #  fi
 601 #  }
 602 #  zle -N rationalise-dot
 603 #  bindkey . rationalise-dot
 604
 605 #  bindkey '\eq' push-line-or-edit
 606
 607 ## toggle the ,. abbreviation feature on/off
 608 # NOABBREVIATION: default abbreviation-state
 609 #                 0 - enabled (default)
 610 #                 1 - disabled
 611 NOABBREVIATION=${NOABBREVIATION:-0}
 612
 613 grml_toggle_abbrev() {
 614     if (( ${NOABBREVIATION} > 0 )) ; then
 615         NOABBREVIATION=0
 616     else
 617         NOABBREVIATION=1
 618     fi
 619 }
 620
 621 zle -N grml_toggle_abbrev
 622 bindkey '^xA' grml_toggle_abbrev
 623
 624 # }}}
 625
 626 # a generic accept-line wrapper {{{
 627
 628 # This widget can prevent unwanted autocorrections from command-name
 629 # to _command-name, rehash automatically on enter and call any number
 630 # of builtin and user-defined widgets in different contexts.
 631 #
 632 # For a broader description, see:
 633 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 634 #
 635 # The code is imported from the file 'zsh/functions/accept-line' from
 636 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 637 # distributed under the same terms as zsh itself.
 638
 639 # A newly added command will may not be found or will cause false
 640 # correction attempts, if you got auto-correction set. By setting the
 641 # following style, we force accept-line() to rehash, if it cannot
 642 # find the first word on the command line in the $command[] hash.
 643 zstyle ':acceptline:*' rehash true
 644
 645 function Accept-Line() {
 646     setopt localoptions noksharrays
 647     local -a subs
 648     local -xi aldone
 649     local sub
 650
 651     zstyle -a ":acceptline:${alcontext}" actions subs
 652
 653     (( ${#subs} < 1 )) && return 0
 654
 655     (( aldone = 0 ))
 656     for sub in ${subs} ; do
 657         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 658         zle ${sub}
 659
 660         (( aldone > 0 )) && break
 661     done
 662 }
 663
 664 function Accept-Line-getdefault() {
 665     local default_action
 666
 667     zstyle -s ":acceptline:${alcontext}" default_action default_action
 668     case ${default_action} in
 669         ((accept-line|))
 670             printf ".accept-line"
 671             ;;
 672         (*)
 673             printf ${default_action}
 674             ;;
 675     esac
 676 }
 677
 678 function accept-line() {
 679     setopt localoptions noksharrays
 680     local -a cmdline
 681     local -x alcontext
 682     local buf com fname format msg default_action
 683
 684     alcontext='default'
 685     buf="${BUFFER}"
 686     cmdline=(${(z)BUFFER})
 687     com="${cmdline[1]}"
 688     fname="_${com}"
 689
 690     zstyle -t ":acceptline:${alcontext}" rehash \
 691         && [[ -z ${commands[$com]} ]]           \
 692         && rehash
 693
 694     if    [[ -n ${reswords[(r)$com]} ]] \
 695        || [[ -n ${aliases[$com]}     ]] \
 696        || [[ -n ${functions[$com]}   ]] \
 697        || [[ -n ${builtins[$com]}    ]] \
 698        || [[ -n ${commands[$com]}    ]] ; then
 699
 700         # there is something sensible to execute, just do it.
 701         alcontext='normal'
 702         zle Accept-Line
 703
 704         default_action=$(Accept-Line-getdefault)
 705         zstyle -T ":acceptline:${alcontext}" call_default \
 706             && zle ${default_action}
 707         return
 708     fi
 709
 710     if    [[ -o correct              ]] \
 711        || [[ -o correctall           ]] \
 712        && [[ -n ${functions[$fname]} ]] ; then
 713
 714         # nothing there to execute but there is a function called
 715         # _command_name; a completion widget. Makes no sense to
 716         # call it on the commandline, but the correct{,all} options
 717         # will ask for it nevertheless, so warn the user.
 718         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 719             # Okay, we warned the user before, he called us again,
 720             # so have it his way.
 721             alcontext='force'
 722             zle Accept-Line
 723
 724             default_action=$(Accept-Line-getdefault)
 725             zstyle -T ":acceptline:${alcontext}" call_default \
 726                 && zle ${default_action}
 727             return
 728         fi
 729
 730         # prepare warning message for the user, configurable via zstyle.
 731         zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 732
 733         if [[ -z ${msg} ]] ; then
 734             msg="%c will not execute and completion %f exists."
 735         fi
 736
 737         zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 738
 739         zle -M -- "${msg}"
 740         return
 741     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 742         # If we are here, the commandline contains something that is not
 743         # executable, which is neither subject to _command_name correction
 744         # and is not empty. might be a variable assignment
 745         alcontext='misc'
 746         zle Accept-Line
 747
 748         default_action=$(Accept-Line-getdefault)
 749         zstyle -T ":acceptline:${alcontext}" call_default \
 750             && zle ${default_action}
 751         return
 752     fi
 753
 754     # If we got this far, the commandline only contains whitespace, or is empty.
 755     alcontext='empty'
 756     zle Accept-Line
 757
 758     default_action=$(Accept-Line-getdefault)
 759     zstyle -T ":acceptline:${alcontext}" call_default \
 760         && zle ${default_action}
 761 }
 762
 763 zle -N accept-line
 764 zle -N Accept-Line
 765
 766 # }}}
 767
 768 # power completion - abbreviation expansion {{{
 769 # power completion / abbreviation expansion / buffer expansion
 770 # see http://zshwiki.org/home/examples/zleiab for details
 771 # less risky than the global aliases but powerful as well
 772 # just type the abbreviation key and afterwards ',.' to expand it
 773 declare -A abk
 774 setopt extendedglob
 775 setopt interactivecomments
 776 abk=(
 777 # key  # value                (#d additional doc string)
 778 #A# start
 779     '...' '../..'
 780     '....' '../../..'
 781     'BG' '& exit'
 782     'C' '| wc -l'
 783     'G' '|& grep --color=auto'
 784     'H' '| head'
 785     'Hl' ' --help |& less -r'      #d (Display help in pager)
 786     'L' '| less'
 787     'LL' '|& less -r'
 788     'M' '| most'
 789     'N' '&>/dev/null'              #d (No Output)
 790     'R' '| tr A-z N-za-m'          #d (ROT13)
 791     'SL' '| sort | less'
 792     'S' '| sort -u'
 793     'T' '| tail'
 794     'V' '|& vim -'
 795 #A# end
 796     'hide' "echo -en '\033]50;nil2\007'"
 797     'tiny' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
 798     'small' 'echo -en "\033]50;6x10\007"'
 799     'medium' 'echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
 800     'default' 'echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
 801     'large' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
 802     'huge' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
 803     'smartfont' 'echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
 804     'semifont' 'echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
 805     'da' 'du -sch'
 806     'j' 'jobs -l'
 807     'u' 'translate -i'
 808     'co' "./configure && make && sudo make install"
 809     'CH' "./configure --help"
 810     'conkeror' 'firefox -chrome chrome://conkeror/content'
 811     'dir' 'ls -lSrah'
 812     'lad' $'ls -d .*(/)\n# only show dot-directories'
 813     'lsa' $'ls -a .*(.)\n# only show dot-files'
 814     'lss' $'ls -l *(s,S,t)\n# only files with setgid/setuid/sticky flag'
 815     'lsl' $'ls -l *(@[1,10])\n# only symlinks'
 816     'lsx' $'ls -l *(*[1,10])\n# only executables'
 817     'lsw' $'ls -ld *(R,W,X.^ND/)\n# world-{readable,writable,executable} files'
 818     'lsbig' $'ls -flh *(.OL[1,10])\n# display the biggest files'
 819     'lsd' $'ls -d *(/)\n# only show directories'
 820     'lse' $'ls -d *(/^F)\n# only show empty directories'
 821     'lsnew' $'ls -rl *(D.om[1,10])\n# display the newest files'
 822     'lsold' $'ls -rtlh *(D.om[-11,-1])\n # display the oldest files'
 823     'lssmall' $'ls -Srl *(.oL[1,10])\n# display the smallest files'
 824     'rw-' 'chmod 600'
 825     '600' 'chmod u+rw-x,g-rwx,o-rwx'
 826     'rwx' 'chmod u+rwx'
 827     '700' 'chmod u+rwx,g-rwx,o-rwx'
 828     'r--' 'chmod u+r-wx,g-rwx,o-rwx'
 829     '644' $'chmod u+rw-x,g+r-wx,o+r-wx\n # 4=r,2=w,1=x'
 830     '755' 'chmod u+rwx,g+r-w+x,o+r-w+x'
 831     'md' 'mkdir -p '
 832     'cmplayer' 'mplayer -vo -fs -zoom fbdev'
 833     'fbmplayer' 'mplayer -vo -fs -zoom fbdev'
 834     'fblinks' 'links2 -driver fb'
 835     'insecssh' 'ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 836     'insecscp' 'scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 837     'fori' 'for i ({..}) { }'
 838     'cx' 'chmod +x'
 839     'e'  'print -l'
 840     'se' 'setopt interactivecomments'
 841     'va' 'valac --vapidir=../vapi/ --pkg=gtk+-2.0 gtktest.vala'
 842     'fb2' '=mplayer -vo fbdev -fs -zoom 1>/dev/null -xy 2'
 843     'fb3' '=mplayer -vo fbdev -fs  -zoom 1>/dev/null -xy 3'
 844     'ci' 'centericq'
 845     'D'  'export DISPLAY=:0.0'
 846     'mp' 'mplayer -vo xv -fs -zoom'
 847 )
 848
 849 globalias() {
 850     local MATCH
 851
 852     if (( NOABBREVIATION > 0 )) ; then
 853         LBUFFER="${LBUFFER},."
 854         return 0
 855     fi
 856
 857     matched_chars='[.-|_a-zA-Z0-9]#'
 858     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 859     LBUFFER+=${abk[$MATCH]:-$MATCH}
 860 }
 861
 862 zle -N globalias
 863 bindkey ",." globalias
 864 # }}}
 865
 866 # {{{ autoloading
 867 zrcautoload zmv    # who needs mmv or rename?
 868 zrcautoload history-search-end
 869
 870 # we don't want to quote/espace URLs on our own...
 871 # if autoload -U url-quote-magic ; then
 872 #    zle -N self-insert url-quote-magic
 873 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 874 # else
 875 #    print 'Notice: no url-quote-magic available :('
 876 # fi
 877 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 878
 879 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 880 alias run-help >&/dev/null && unalias run-help
 881 zrcautoload run-help # use via 'esc-h'
 882
 883 # completion system
 884 if zrcautoload compinit && compinit 2>/dev/null ; then
 885     compinit 2>/dev/null || print 'Notice: no compinit available :('
 886 else
 887     print 'Notice: no compinit available :('
 888     function zstyle { }
 889     function compdef { }
 890 fi
 891
 892 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 893
 894 is4 && \
 895 for mod in complist deltochar mathfunc ; do
 896     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 897 done
 898
 899 # autoload zsh modules when they are referenced
 900 if is4 ; then
 901     tmpargs=(
 902         a   stat
 903         a   zpty
 904         ap  mapfile
 905     )
 906
 907     while (( ${#tmpargs} > 0 )) ; do
 908         zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
 909         shift 2 tmpargs
 910     done
 911     unset tmpargs
 912 fi
 913
 914 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 915     #k# Insert files
 916     bindkey "^Xf" insert-files # C-x-f
 917 fi
 918
 919 bindkey ' '   magic-space    # also do history expansion on space
 920 #k# Trigger menu-complete
 921 bindkey '\ei' menu-complete  # menu completion via esc-i
 922
 923 # press esc-e for editing command line in $EDITOR or $VISUAL
 924 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 925     #k# Edit the current line in \kbd{\$EDITOR}
 926     bindkey '\ee' edit-command-line
 927 fi
 928
 929 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 930     #k# menu selection: pick item but stay in the menu
 931     bindkey -M menuselect '\e^M' accept-and-menu-complete
 932
 933     # accept a completion and try to complete again by using menu
 934     # completion; very useful with completing directories
 935     # by using 'undo' one's got a simple file browser
 936     bindkey -M menuselect '^o' accept-and-infer-next-history
 937 fi
 938
 939 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 940 _bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
 941 zle -N _bkdate
 942
 943 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 944 bindkey '^Ed' _bkdate
 945
 946 # press esc-m for inserting last typed word again (thanks to caphuso!)
 947 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 948 zle -N insert-last-typed-word;
 949
 950 #k# Insert last typed word
 951 bindkey "\em" insert-last-typed-word
 952
 953 #k# Shortcut for \kbd{fg<enter>}
 954 bindkey -s '^z' "fg\n"
 955
 956 # run command line as user root via sudo:
 957 sudo-command-line() {
 958     [[ -z $BUFFER ]] && zle up-history
 959     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
 960 }
 961 zle -N sudo-command-line
 962
 963 #k# Put the current command line into a \kbd{sudo} call
 964 bindkey "^Os" sudo-command-line
 965
 966 ### jump behind the first word on the cmdline.
 967 ### useful to add options.
 968 function jump_after_first_word() {
 969     local words
 970     words=(${(z)BUFFER})
 971
 972     if (( ${#words} <= 1 )) ; then
 973         CURSOR=${#BUFFER}
 974     else
 975         CURSOR=${#${words[1]}}
 976     fi
 977 }
 978 zle -N jump_after_first_word
 979
 980 bindkey '^x1' jump_after_first_word
 981
 982 # }}}
 983
 984 # {{{ set some important options
 985 # Please update these tags, if you change the umask settings below.
 986 #o# r_umask     002
 987 #o# r_umaskstr  rwxrwxr-x
 988 #o# umask       022
 989 #o# umaskstr    rwxr-xr-x
 990 (( EUID != 0 )) && umask 002 || umask 022
 991
 992 # history:
 993 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 994 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 995 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 996 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 997                             # list duplicates an older one, the older command is removed from the list
 998 setopt histignorespace      # remove command lines from the history list when
 999                             # the first character on the line is a space
1000 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
1001                             # and the command is the name of a directory, perform the cd command to that directory
1002 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
1003                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
1004                             # -> searches for word not in compressed files
1005                             # don't forget to quote '^', '~' and '#'!
1006 setopt longlistjobs         # display PID when suspending processes as well
1007 setopt notify               # report the status of backgrounds jobs immediately
1008 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
1009                             # the entire command path is hashed first.
1010 setopt completeinword       # not just at the end
1011 setopt nohup                # and don't kill them, either
1012 setopt auto_pushd           # make cd push the old directory onto the directory stack.
1013 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
1014 setopt nobeep               # avoid "beep"ing
1015 setopt pushd_ignore_dups    # don't push the same dir twice.
1016
1017 MAILCHECK=30       # mailchecks
1018 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
1019 watch=(notme root) # watch for everyone but me and root
1020
1021 # only slash should be considered as a word separator:
1022 slash-backward-kill-word() {
1023     local WORDCHARS="${WORDCHARS:s@/@}"
1024     # zle backward-word
1025     zle backward-kill-word
1026 }
1027 zle -N slash-backward-kill-word
1028
1029 #k# Kill everything in a word up to its last \kbd{/}
1030 bindkey '\ev' slash-backward-kill-word
1031
1032 # }}}
1033
1034 # {{{ history
1035
1036 ZSHDIR=$HOME/.zsh
1037
1038 #v#
1039 HISTFILE=$HOME/.zsh_history
1040 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1041 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1042
1043 # }}}
1044
1045 # dirstack handling {{{
1046
1047 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1048 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1049
1050 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1051     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1052     # "cd -" won't work after login by just setting $OLDPWD, so
1053     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
1054 fi
1055
1056 chpwd() {
1057     if is42 ; then
1058         builtin print -l ${(u)dirstack} >! ${DIRSTACKFILE}
1059     else
1060         uprint dirstack >! ${DIRSTACKFILE}
1061     fi
1062 }
1063
1064 # }}}
1065
1066 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
1067 if [[ $BATTERY -gt 0 ]] ; then
1068     if ! check_com -c acpi ; then
1069         BATTERY=0
1070     fi
1071 fi
1072
1073 battery() {
1074 if [[ $BATTERY -gt 0 ]] ; then
1075     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]##Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1076     if [[ -z "$PERCENT" ]] ; then
1077         PERCENT='acpi not present'
1078     else
1079         if [[ "$PERCENT" -lt 20 ]] ; then
1080             PERCENT="warning: ${PERCENT}%%"
1081         else
1082             PERCENT="${PERCENT}%%"
1083         fi
1084     fi
1085 fi
1086 }
1087 # }}}
1088
1089 # set colors for use in prompts {{{
1090 if zrcautoload colors && colors 2>/dev/null ; then
1091     BLUE="%{${fg[blue]}%}"
1092     RED="%{${fg_bold[red]}%}"
1093     GREEN="%{${fg[green]}%}"
1094     CYAN="%{${fg[cyan]}%}"
1095     MAGENTA="%{${fg[magenta]}%}"
1096     YELLOW="%{${fg[yellow]}%}"
1097     WHITE="%{${fg[white]}%}"
1098     NO_COLOUR="%{${reset_color}%}"
1099 else
1100     BLUE=$'%{\e[1;34m%}'
1101     RED=$'%{\e[1;31m%}'
1102     GREEN=$'%{\e[1;32m%}'
1103     CYAN=$'%{\e[1;36m%}'
1104     WHITE=$'%{\e[1;37m%}'
1105     MAGENTA=$'%{\e[1;35m%}'
1106     YELLOW=$'%{\e[1;33m%}'
1107     NO_COLOUR=$'%{\e[0m%}'
1108 fi
1109
1110 # }}}
1111
1112 # gather version control information for inclusion in a prompt {{{
1113
1114 if ! is41 ; then
1115     # Be quiet about version problems in grml's zshrc as the user cannot disable
1116     # loading vcs_info() as it is *in* the zshrc - as you can see. :-)
1117     # Just unset most probable variables and disable vcs_info altogether.
1118     local -i i
1119     for i in {0..9} ; do
1120         unset VCS_INFO_message_${i}_
1121     done
1122     zstyle ':vcs_info:*' enable false
1123 fi
1124
1125 # The following code is imported from the file 'zsh/functions/vcs_info'
1126 # from <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>,
1127 # which distributed under the same terms as zsh itself.
1128
1129 # we will only be using one variable, so let the code know now.
1130 zstyle ':vcs_info:*' max-exports 1
1131
1132 # vcs_info() documentation:
1133 #{{{
1134 # REQUIREMENTS:
1135 #{{{
1136 #     This functionality requires zsh version >= 4.1.*.
1137 #}}}
1138 #
1139 # LOADING:
1140 #{{{
1141 # To load vcs_info(), copy this file to your $fpath[] and do:
1142 #   % autoload -Uz vcs_info && vcs_info
1143 #
1144 # To work, vcs_info() needs 'setopt prompt_subst' in your setup.
1145 #}}}
1146 #
1147 # QUICKSTART:
1148 #{{{
1149 # To get vcs_info() working quickly (including colors), you can do the
1150 # following (assuming, you loaded vcs_info() properly - see above):
1151 #
1152 # % RED=$'%{\e[31m%}'
1153 # % GR=$'%{\e[32m%}'
1154 # % MA=$'%{\e[35m%}'
1155 # % YE=$'%{\e[33m%}'
1156 # % NC=$'%{\e[0m%}'
1157 #
1158 # % zstyle ':vcs_info:*' actionformats \
1159 #       "${MA}(${NC}%s${MA})${YE}-${MA}[${GR}%b${YE}|${RED}%a${MA}]${NC} "
1160 #
1161 # % zstyle ':vcs_info:*' formats       \
1162 #       "${MA}(${NC}%s${MA})${Y}-${MA}[${GR}%b${MA}]${NC}%} "
1163 #
1164 # % zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YE}%r"
1165 #
1166 # % precmd () { vcs_info }
1167 # % PS1='${MA}[${GR}%n${MA}] ${MA}(${RED}%!${MA}) ${YE}%3~ ${VCS_INFO_message_0_}${NC}%# '
1168 #
1169 # Obviously, the las two lines are there for demonstration: You need to
1170 # call vcs_info() from your precmd() function (see 'SPECIAL FUNCTIONS' in
1171 # 'man zshmisc'). Once that is done you need a *single* quoted
1172 # '${VCS_INFO_message_0_}' in your prompt.
1173 #
1174 # Now call the 'vcs_info_printsys' utility from the command line:
1175 #
1176 # % vcs_info_printsys
1177 # # list of supported version control backends:
1178 # # disabled systems are prefixed by a hash sign (#)
1179 # git
1180 # hg
1181 # bzr
1182 # darcs
1183 # svk
1184 # mtn
1185 # svn
1186 # cvs
1187 # cdv
1188 # tla
1189 # # flavours (cannot be used in the disable style; they
1190 # # are disabled with their master [git-svn -> git]):
1191 # git-p4
1192 # git-svn
1193 #
1194 # Ten version control backends as you can see. You may not want all
1195 # of these. Because there is no point in running the code to detect
1196 # systems you do not use. ever. So, there is a way to disable some
1197 # backends altogether:
1198 #
1199 # % zstyle ':vcs_info:*' disable bzr cdv darcs mtn svk tla
1200 #
1201 # If you rerun 'vcs_info_printsys' now, you will see the backends listed
1202 # in the 'disable' style marked as diabled by a hash sign. That means the
1203 # detection of these systems is skipped *completely*. No wasted time there.
1204 #
1205 # For more control, read the reference below.
1206 #}}}
1207 #
1208 # CONFIGURATION:
1209 #{{{
1210 # The vcs_info() feature can be configured via zstyle.
1211 #
1212 # First, the context in which we are working:
1213 #       :vcs_info:<vcs-string>:<user-context>
1214 #
1215 # ...where <vcs-string> is one of:
1216 #   - git, git-svn, git-p4, hg, darcs, bzr, cdv, mtn, svn, cvs, svk or tla.
1217 #
1218 # ...and <user-context> is a freely configurable string, assignable by the
1219 # user as the first argument to vcs_info() (see its description below).
1220 #
1221 # There is are three special values for <vcs-string>: The first is named
1222 # 'init', that is in effect as long as there was no decision what vcs
1223 # backend to use. The second is 'preinit; it is used *before* vcs_info()
1224 # is run, when initializing the data exporting variables. The third
1225 # special value is 'formats' and is used by the 'vcs_info_lastmsg' for
1226 # looking up its styles.
1227 #
1228 # There are two pre-defined values for <user-context>:
1229 #   default  - the one used if none is specified
1230 #   command  - used by vcs_info_lastmsg to lookup its styles.
1231 #
1232 # You may *not* use 'print_systems_' as a user-context string, because it
1233 # is used internally.
1234 #
1235 # You can of course use ':vcs_info:*' to match all VCSs in all
1236 # user-contexts at once.
1237 #
1238 # Another special context is 'formats', which is used by the
1239 # vcs_info_lastmsg() utility function (see below).
1240 #
1241 #
1242 # This is a description of all styles, that are looked up:
1243 #   formats             - A list of formats, used when actionformats is not
1244 #                         used (which is most of the time).
1245 #   actionformats       - A list of formats, used if a there is a special
1246 #                         action going on in your current repository;
1247 #                         (like an interactive rebase or a merge conflict)
1248 #   branchformat        - Some backends replace %b in the formats and
1249 #                         actionformats styles above, not only by a branch
1250 #                         name but also by a revision number. This style
1251 #                         let's you modify how that string should look like.
1252 #   nvcsformats         - These "formats" are exported, when we didn't detect
1253 #                         a version control system for the current directory.
1254 #                         This is useful, if you want vcs_info() to completely
1255 #                         take over the generation of your prompt.
1256 #                         You would do something like
1257 #                           PS1='${VCS_INFO_message_0_}'
1258 #                         to accomplish that.
1259 #   max-exports         - Defines the maximum number if VCS_INFO_message_*_
1260 #                         variables vcs_info() will export.
1261 #   enable              - Checked in the 'init' context. If set to false,
1262 #                         vcs_info() will do nothing.
1263 #   disable             - Provide a list of systems, you don't want
1264 #                         the vcs_info() to check for repositories
1265 #                         (checked in the 'init' context, too).
1266 #   disable-patterns    - A list of patterns that are checked against $PWD.
1267 #                         If the pattern matches, vcs_info will be disabled.
1268 #                         Say, ~/.zsh is a directory under version control,
1269 #                         in which you do not want vcs_info to be active, do:
1270 #                         zstyle ':vcs_info:*' disable-patterns "$HOME/.zsh+(|/*)"
1271 #   use-simple          - If there are two different ways of gathering
1272 #                         information, you can select the simpler one
1273 #                         by setting this style to true; the default
1274 #                         is to use the not-that-simple code, which is
1275 #                         potentially a lot slower but might be more
1276 #                         accurate in all possible cases.
1277 #   use-prompt-escapes  - determines if we assume that the assembled
1278 #                         string from vcs_info() includes prompt escapes.
1279 #                         (Used by vcs_info_lastmsg().
1280 #
1281 # The use-simple style is only available for the bzr backend.
1282 #
1283 # The default values for these in all contexts are:
1284 #   formats             " (%s)-[%b|%a]-"
1285 #   actionformats       " (%s)-[%b]-"
1286 #   branchformat        "%b:%r" (for bzr, svn and svk)
1287 #   nvcsformats         ""
1288 #   max-exports         2
1289 #   enable              true
1290 #   disable             (empty list)
1291 #   disable-patterns    (empty list)
1292 #   use-simple          false
1293 #   use-prompt-escapes  true
1294 #
1295 #
1296 # In normal formats and actionformats, the following replacements
1297 # are done:
1298 #   %s  - The vcs in use (git, hg, svn etc.)
1299 #   %b  - Information about the current branch.
1300 #   %a  - An identifier, that describes the action.
1301 #         Only makes sense in actionformats.
1302 #   %R  - base directory of the repository.
1303 #   %r  - repository name
1304 #         If %R is '/foo/bar/repoXY', %r is 'repoXY'.
1305 #   %S  - subdirectory within a repository. if $PWD is
1306 #         '/foo/bar/reposXY/beer/tasty', %S is 'beer/tasty'.
1307 #
1308 #
1309 # In branchformat these replacements are done:
1310 #   %b  - the branch name
1311 #   %r  - the current revision number
1312 #
1313 # Not all vcs backends have to support all replacements.
1314 # nvcsformat does not perform *any* replacements. It is just a string.
1315 #}}}
1316 #
1317 # ODDITIES:
1318 #{{{
1319 # If you want to use the %b (bold off) prompt expansion in 'formats', which
1320 # expands %b itself, use %%b. That will cause the vcs_info() expansion to
1321 # replace %%b with %b. So zsh's prompt expansion mechanism can handle it.
1322 # Similarly, to hand down %b from branchformat, use %%%%b. Sorry for this
1323 # inconvenience, but it cannot be easily avoided. Luckily we do not clash
1324 # with a lot of prompt expansions and this only needs to be done for those.
1325 # See 'man zshmisc' for details about EXPANSION OF PROMPT SEQUENCES.
1326 #}}}
1327 #
1328 # FUNCTION DESCRIPTIONS (public API):
1329 #{{{
1330 #   vcs_info()
1331 #       The main function, that runs all backends and assembles
1332 #       all data into ${VCS_INFO_message_*_}. This is the function
1333 #       you want to call from precmd() if you want to include
1334 #       up-to-date information in your prompt (see VARIABLE
1335 #       DESCRIPTION below).
1336 #
1337 #   vcs_info_printsys()
1338 #       Prints a list of all supported version control systems.
1339 #       Useful to find out possible contexts (and which of them are enabled)
1340 #       or values for the 'disable' style.
1341 #
1342 #   vcs_info_lastmsg()
1343 #       Outputs the last ${VCS_INFO_message_*_} value. Takes into account
1344 #       the value of the use-prompt-escapes style in ':vcs_info:formats'.
1345 #       It also only prints max-exports values.
1346 #
1347 # All functions named VCS_INFO_* are for internal use only.
1348 #}}}
1349 #
1350 # VARIABLE DESCRIPTION:
1351 #{{{
1352 #   ${VCS_INFO_message_N_}    (Note the trailing underscore)
1353 #       Where 'N' is an integer, eg: VCS_INFO_message_0_
1354 #       These variables are the storage for the informational message the
1355 #       last vcs_info() call has assembled. These are strongly connected
1356 #       to the formats, actionformats and nvcsformats styles described
1357 #       above. Those styles are lists. the first member of that list gets
1358 #       expanded into ${VCS_INFO_message_0_}, the second into
1359 #       ${VCS_INFO_message_1_} and the Nth into ${VCS_INFO_message_N-1_}.
1360 #       These parameters are exported into the environment.
1361 #       (See the max-exports style above.)
1362 #}}}
1363 #
1364 # EXAMPLES:
1365 #{{{
1366 #   Don't use vcs_info at all (even though it's in your prompt):
1367 #   % zstyle ':vcs_info:*' enable false
1368 #
1369 #   Disable the backends for bzr and svk:
1370 #   % zstyle ':vcs_info:*' disable bzr svk
1371 #
1372 #   Provide a special formats for git:
1373 #   % zstyle ':vcs_info:git:*' formats       ' GIT, BABY! [%b]'
1374 #   % zstyle ':vcs_info:git:*' actionformats ' GIT ACTION! [%b|%a]'
1375 #
1376 #   Use the quicker bzr backend (if you do, please report if it does
1377 #   the-right-thing[tm] - thanks):
1378 #   % zstyle ':vcs_info:bzr:*' use-simple true
1379 #
1380 #   Display the revision number in yellow for bzr and svn:
1381 #   % zstyle ':vcs_info:(svn|bzr):*' branchformat '%b%{'${fg[yellow]}'%}:%r'
1382 #
1383 # If you want colors, make sure you enclose the color codes in %{...%},
1384 # if you want to use the string provided by vcs_info() in prompts.
1385 #
1386 # Here is how to print the vcs infomation as a command:
1387 #   % alias vcsi='vcs_info command; vcs_info_lastmsg'
1388 #
1389 #   This way, you can even define different formats for output via
1390 #   vcs_info_lastmsg() in the ':vcs_info:command:*' namespace.
1391 #}}}
1392 #}}}
1393 # utilities
1394 VCS_INFO_adjust () { #{{{
1395     [[ -n ${vcs_comm[overwrite_name]} ]] && vcs=${vcs_comm[overwrite_name]}
1396     return 0
1397 }
1398 # }}}
1399 VCS_INFO_check_com () { #{{{
1400     (( ${+commands[$1]} )) && [[ -x ${commands[$1]} ]] && return 0
1401     return 1
1402 }
1403 # }}}
1404 VCS_INFO_formats () { # {{{
1405     setopt localoptions noksharrays
1406     local action=$1 branch=$2 base=$3
1407     local msg
1408     local -i i
1409
1410     if [[ -n ${action} ]] ; then
1411         zstyle -a ":vcs_info:${vcs}:${usercontext}" actionformats msgs
1412         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b|%a]-'
1413     else
1414         zstyle -a ":vcs_info:${vcs}:${usercontext}" formats msgs
1415         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b]-'
1416     fi
1417
1418     (( ${#msgs} > maxexports )) && msgs[${maxexports},-1]=()
1419     for i in {1..${#msgs}} ; do
1420         zformat -f msg ${msgs[$i]} a:${action} b:${branch} s:${vcs} r:${base:t} R:${base} S:"$(VCS_INFO_reposub ${base})"
1421         msgs[$i]=${msg}
1422     done
1423     return 0
1424 }
1425 # }}}
1426 VCS_INFO_maxexports () { #{{{
1427     local -ix maxexports
1428
1429     zstyle -s ":vcs_info:${vcs}:${usercontext}" "max-exports" maxexports || maxexports=2
1430     if [[ ${maxexports} != <-> ]] || (( maxexports < 1 )); then
1431         printf 'vcs_info(): expecting numeric arg >= 1 for max-exports (got %s).\n' ${maxexports}
1432         printf 'Defaulting to 2.\n'
1433         maxexports=2
1434     fi
1435 }
1436 # }}}
1437 VCS_INFO_nvcsformats () { #{{{
1438     setopt localoptions noksharrays
1439     local c v
1440
1441     if [[ $1 == 'preinit' ]] ; then
1442         c=default
1443         v=preinit
1444     fi
1445     zstyle -a ":vcs_info:${v:-$vcs}:${c:-$usercontext}" nvcsformats msgs
1446     (( ${#msgs} > maxexports )) && msgs[${maxexports},-1]=()
1447 }
1448 # }}}
1449 VCS_INFO_realpath () { #{{{
1450     # a portable 'readlink -f'
1451     # forcing a subshell, to ensure chpwd() is not removed
1452     # from the calling shell (if VCS_INFO_realpath() is called
1453     # manually).
1454     (
1455         (( ${+functions[chpwd]} )) && unfunction chpwd
1456         setopt chaselinks
1457         cd $1 2>/dev/null && pwd
1458     )
1459 }
1460 # }}}
1461 VCS_INFO_reposub () { #{{{
1462     setopt localoptions extendedglob
1463     local base=${1%%/##}
1464
1465     [[ ${PWD} == ${base}/* ]] || {
1466         printf '.'
1467         return 1
1468     }
1469     printf '%s' ${PWD#$base/}
1470     return 0
1471 }
1472 # }}}
1473 VCS_INFO_set () { #{{{
1474     setopt localoptions noksharrays
1475     local -i i j
1476
1477     if [[ $1 == '--clear' ]] ; then
1478         for i in {0..9} ; do
1479             unset VCS_INFO_message_${i}_
1480         done
1481     fi
1482     if [[ $1 == '--nvcs' ]] ; then
1483         [[ $2 == 'preinit' ]] && (( maxexports == 0 )) && (( maxexports = 1 ))
1484         for i in {0..$((maxexports - 1))} ; do
1485             typeset -gx VCS_INFO_message_${i}_=
1486         done
1487         VCS_INFO_nvcsformats $2
1488     fi
1489
1490     (( ${#msgs} - 1 < 0 )) && return 0
1491     for i in {0..$(( ${#msgs} - 1 ))} ; do
1492         (( j = i + 1 ))
1493         typeset -gx VCS_INFO_message_${i}_=${msgs[$j]}
1494     done
1495     return 0
1496 }
1497 # }}}
1498 # information gathering
1499 VCS_INFO_bzr_get_data () { # {{{
1500     setopt localoptions noksharrays
1501     local bzrbase bzrbr
1502     local -a bzrinfo
1503
1504     if zstyle -t ":vcs_info:${vcs}:${usercontext}" "use-simple" ; then
1505         bzrbase=${vcs_comm[basedir]}
1506         bzrinfo[2]=${bzrbase:t}
1507         if [[ -f ${bzrbase}/.bzr/branch/last-revision ]] ; then
1508             bzrinfo[1]=$(< ${bzrbase}/.bzr/branch/last-revision)
1509             bzrinfo[1]=${${bzrinfo[1]}%% *}
1510         fi
1511     else
1512         bzrbase=${${(M)${(f)"$( bzr info )"}:# ##branch\ root:*}/*: ##/}
1513         bzrinfo=( ${${${(M)${(f)"$( bzr version-info )"}:#(#s)(revno|branch-nick)*}/*: /}/*\//} )
1514         bzrbase="$(VCS_INFO_realpath ${bzrbase})"
1515     fi
1516
1517     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat bzrbr || bzrbr="%b:%r"
1518     zformat -f bzrbr "${bzrbr}" "b:${bzrinfo[2]}" "r:${bzrinfo[1]}"
1519     VCS_INFO_formats '' "${bzrbr}" "${bzrbase}"
1520     return 0
1521 }
1522 # }}}
1523 VCS_INFO_cdv_get_data () { # {{{
1524     local cdvbase
1525
1526     cdvbase=${vcs_comm[basedir]}
1527     VCS_INFO_formats '' "${cdvbase:t}" "${cdvbase}"
1528     return 0
1529 }
1530 # }}}
1531 VCS_INFO_cvs_get_data () { # {{{
1532     local cvsbranch cvsbase basename
1533
1534     cvsbase="."
1535     while [[ -d "${cvsbase}/../CVS" ]]; do
1536         cvsbase="${cvsbase}/.."
1537     done
1538     cvsbase="$(VCS_INFO_realpath ${cvsbase})"
1539     cvsbranch=$(< ./CVS/Repository)
1540     basename=${cvsbase:t}
1541     cvsbranch=${cvsbranch##${basename}/}
1542     [[ -z ${cvsbranch} ]] && cvsbranch=${basename}
1543     VCS_INFO_formats '' "${cvsbranch}" "${cvsbase}"
1544     return 0
1545 }
1546 # }}}
1547 VCS_INFO_darcs_get_data () { # {{{
1548     local darcsbase
1549
1550     darcsbase=${vcs_comm[basedir]}
1551     VCS_INFO_formats '' "${darcsbase:t}" "${darcsbase}"
1552     return 0
1553 }
1554 # }}}
1555 VCS_INFO_git_getaction () { #{{{
1556     local gitaction='' gitdir=$1
1557     local tmp
1558
1559     for tmp in "${gitdir}/rebase-apply" \
1560                "${gitdir}/rebase"       \
1561                "${gitdir}/../.dotest" ; do
1562         if [[ -d ${tmp} ]] ; then
1563             if   [[ -f "${tmp}/rebasing" ]] ; then
1564                 gitaction="rebase"
1565             elif [[ -f "${tmp}/applying" ]] ; then
1566                 gitaction="am"
1567             else
1568                 gitaction="am/rebase"
1569             fi
1570             printf '%s' ${gitaction}
1571             return 0
1572         fi
1573     done
1574
1575     for tmp in "${gitdir}/rebase-merge/interactive" \
1576                "${gitdir}/.dotest-merge/interactive" ; do
1577         if [[ -f "${tmp}" ]] ; then
1578             printf '%s' "rebase-i"
1579             return 0
1580         fi
1581     done
1582
1583     for tmp in "${gitdir}/rebase-merge" \
1584                "${gitdir}/.dotest-merge" ; do
1585         if [[ -d "${tmp}" ]] ; then
1586             printf '%s' "rebase-m"
1587             return 0
1588         fi
1589     done
1590
1591     if [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1592         printf '%s' "merge"
1593         return 0
1594     fi
1595
1596     if [[ -f "${gitdir}/BISECT_LOG" ]] ; then
1597         printf '%s' "bisect"
1598         return 0
1599     fi
1600     return 1
1601 }
1602 # }}}
1603 VCS_INFO_git_getbranch () { #{{{
1604     local gitbranch gitdir=$1
1605     local gitsymref='git symbolic-ref HEAD'
1606
1607     if    [[ -d "${gitdir}/rebase-apply" ]] \
1608        || [[ -d "${gitdir}/rebase" ]]       \
1609        || [[ -d "${gitdir}/../.dotest" ]]   \
1610        || [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1611         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1612         [[ -z ${gitbranch} ]] && [[ -r ${gitdir}/rebase-apply/head-name ]] \
1613             && gitbranch="$(< ${gitdir}/rebase-apply/head-name)"
1614
1615     elif   [[ -f "${gitdir}/rebase-merge/interactive" ]] \
1616         || [[ -d "${gitdir}/rebase-merge" ]] ; then
1617         gitbranch="$(< ${gitdir}/rebase-merge/head-name)"
1618
1619     elif   [[ -f "${gitdir}/.dotest-merge/interactive" ]] \
1620         || [[ -d "${gitdir}/.dotest-merge" ]] ; then
1621         gitbranch="$(< ${gitdir}/.dotest-merge/head-name)"
1622
1623     else
1624         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1625
1626         if [[ $? -ne 0 ]] ; then
1627             gitbranch="$(git describe --exact-match HEAD 2>/dev/null)"
1628
1629             if [[ $? -ne 0 ]] ; then
1630                 gitbranch="${${"$(< $gitdir/HEAD)"}[1,7]}..."
1631             fi
1632         fi
1633     fi
1634
1635     printf '%s' "${gitbranch##refs/heads/}"
1636     return 0
1637 }
1638 # }}}
1639 VCS_INFO_git_get_data () { # {{{
1640     setopt localoptions extendedglob
1641     local gitdir gitbase gitbranch gitaction
1642
1643     gitdir=${vcs_comm[gitdir]}
1644     gitbranch="$(VCS_INFO_git_getbranch ${gitdir})"
1645
1646     if [[ -z ${gitdir} ]] || [[ -z ${gitbranch} ]] ; then
1647         return 1
1648     fi
1649
1650     VCS_INFO_adjust
1651     gitaction="$(VCS_INFO_git_getaction ${gitdir})"
1652     gitbase=${PWD%/${$( git rev-parse --show-prefix )%/##}}
1653     VCS_INFO_formats "${gitaction}" "${gitbranch}" "${gitbase}"
1654     return 0
1655 }
1656 # }}}
1657 VCS_INFO_hg_get_data () { # {{{
1658     local hgbranch hgbase
1659
1660     hgbase=${vcs_comm[basedir]}
1661     hgbranch=$(< ${hgbase}/.hg/branch)
1662     VCS_INFO_formats '' "${hgbranch}" "${hgbase}"
1663     return 0
1664 }
1665 # }}}
1666 VCS_INFO_mtn_get_data () { # {{{
1667     local mtnbranch mtnbase
1668
1669     mtnbase=${vcs_comm[basedir]}
1670     mtnbranch=${${(M)${(f)"$( mtn status )"}:#(#s)Current branch:*}/*: /}
1671     VCS_INFO_formats '' "${mtnbranch}" "${mtnbase}"
1672     return 0
1673 }
1674 # }}}
1675 VCS_INFO_svk_get_data () { # {{{
1676     local svkbranch svkbase
1677
1678     svkbase=${vcs_comm[basedir]}
1679     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svkbranch || svkbranch="%b:%r"
1680     zformat -f svkbranch "${svkbranch}" "b:${vcs_comm[branch]}" "r:${vcs_comm[revision]}"
1681     VCS_INFO_formats '' "${svkbranch}" "${svkbase}"
1682     return 0
1683 }
1684 # }}}
1685 VCS_INFO_svn_get_data () { # {{{
1686     setopt localoptions noksharrays
1687     local svnbase svnbranch
1688     local -a svninfo
1689
1690     svnbase="."
1691     while [[ -d "${svnbase}/../.svn" ]]; do
1692         svnbase="${svnbase}/.."
1693     done
1694     svnbase="$(VCS_INFO_realpath ${svnbase})"
1695     svninfo=( ${${${(M)${(f)"$( svn info )"}:#(#s)(URL|Revision)*}/*: /}/*\//} )
1696
1697     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svnbranch || svnbranch="%b:%r"
1698     zformat -f svnbranch "${svnbranch}" "b:${svninfo[1]}" "r:${svninfo[2]}"
1699     VCS_INFO_formats '' "${svnbranch}" "${svnbase}"
1700     return 0
1701 }
1702 # }}}
1703 VCS_INFO_tla_get_data () { # {{{
1704     local tlabase tlabranch
1705
1706     tlabase="$(VCS_INFO_realpath ${vcs_comm[basedir]})"
1707     # tree-id gives us something like 'foo@example.com/demo--1.0--patch-4', so:
1708     tlabranch=${${"$( tla tree-id )"}/*\//}
1709     VCS_INFO_formats '' "${tlabranch}" "${tlabase}"
1710     return 0
1711 }
1712 # }}}
1713 # detection
1714 VCS_INFO_detect_by_dir() { #{{{
1715     local dirname=$1
1716     local basedir="." realbasedir
1717
1718     realbasedir="$(VCS_INFO_realpath ${basedir})"
1719     while [[ ${realbasedir} != '/' ]]; do
1720         if [[ -n ${vcs_comm[detect_need_file]} ]] ; then
1721             [[ -d ${basedir}/${dirname} ]] && \
1722             [[ -f ${basedir}/${dirname}/${vcs_comm[detect_need_file]} ]] && \
1723                 break
1724         else
1725             [[ -d ${basedir}/${dirname} ]] && break
1726         fi
1727
1728         basedir=${basedir}/..
1729         realbasedir="$(VCS_INFO_realpath ${basedir})"
1730     done
1731
1732     [[ ${realbasedir} == "/" ]] && return 1
1733     vcs_comm[basedir]=${realbasedir}
1734     return 0
1735 }
1736 # }}}
1737 VCS_INFO_bzr_detect() { #{{{
1738     VCS_INFO_check_com bzr || return 1
1739     vcs_comm[detect_need_file]=branch/format
1740     VCS_INFO_detect_by_dir '.bzr'
1741     return $?
1742 }
1743 # }}}
1744 VCS_INFO_cdv_detect() { #{{{
1745     VCS_INFO_check_com cdv || return 1
1746     vcs_comm[detect_need_file]=format
1747     VCS_INFO_detect_by_dir '.cdv'
1748     return $?
1749 }
1750 # }}}
1751 VCS_INFO_cvs_detect() { #{{{
1752     VCS_INFO_check_com svn || return 1
1753     [[ -d "./CVS" ]] && [[ -r "./CVS/Repository" ]] && return 0
1754     return 1
1755 }
1756 # }}}
1757 VCS_INFO_darcs_detect() { #{{{
1758     VCS_INFO_check_com darcs || return 1
1759     vcs_comm[detect_need_file]=format
1760     VCS_INFO_detect_by_dir '_darcs'
1761     return $?
1762 }
1763 # }}}
1764 VCS_INFO_git_detect() { #{{{
1765     if VCS_INFO_check_com git && git rev-parse --is-inside-work-tree &> /dev/null ; then
1766         vcs_comm[gitdir]="$(git rev-parse --git-dir 2> /dev/null)" || return 1
1767         if   [[ -d ${vcs_comm[gitdir]}/svn ]]             ; then vcs_comm[overwrite_name]='git-svn'
1768         elif [[ -d ${vcs_comm[gitdir]}/refs/remotes/p4 ]] ; then vcs_comm[overwrite_name]='git-p4' ; fi
1769         return 0
1770     fi
1771     return 1
1772 }
1773 # }}}
1774 VCS_INFO_hg_detect() { #{{{
1775     VCS_INFO_check_com hg || return 1
1776     vcs_comm[detect_need_file]=branch
1777     VCS_INFO_detect_by_dir '.hg'
1778     return $?
1779 }
1780 # }}}
1781 VCS_INFO_mtn_detect() { #{{{
1782     VCS_INFO_check_com mtn || return 1
1783     vcs_comm[detect_need_file]=revision
1784     VCS_INFO_detect_by_dir '_MTN'
1785     return $?
1786 }
1787 # }}}
1788 VCS_INFO_svk_detect() { #{{{
1789     setopt localoptions noksharrays extendedglob
1790     local -a info
1791     local -i fhash
1792     fhash=0
1793
1794     VCS_INFO_check_com svk || return 1
1795     [[ -f ~/.svk/config ]] || return 1
1796
1797     # This detection function is a bit different from the others.
1798     # We need to read svk's config file to detect a svk repository
1799     # in the first place. Therefore, we'll just proceed and read
1800     # the other information, too. This is more then any of the
1801     # other detections do but this takes only one file open for
1802     # svk at most. VCS_INFO_svk_get_data() get simpler, too. :-)
1803     while IFS= read -r line ; do
1804         if [[ -n ${vcs_comm[basedir]} ]] ; then
1805             line=${line## ##}
1806             [[ ${line} == depotpath:* ]] && vcs_comm[branch]=${line##*/}
1807             [[ ${line} == revision:* ]] && vcs_comm[revision]=${line##*[[:space:]]##}
1808             [[ -n ${vcs_comm[branch]} ]] && [[ -n ${vcs_comm[revision]} ]] && break
1809             continue
1810         fi
1811         (( fhash > 0 )) && [[ ${line} == '  '[^[:space:]]*:* ]] && break
1812         [[ ${line} == '  hash:'* ]] && fhash=1 && continue
1813         (( fhash == 0 )) && continue
1814         [[ ${PWD}/ == ${${line## ##}%:*}/* ]] && vcs_comm[basedir]=${${line## ##}%:*}
1815     done < ~/.svk/config
1816
1817     [[ -n ${vcs_comm[basedir]} ]]  && \
1818     [[ -n ${vcs_comm[branch]} ]]   && \
1819     [[ -n ${vcs_comm[revision]} ]] && return 0
1820     return 1
1821 }
1822 # }}}
1823 VCS_INFO_svn_detect() { #{{{
1824     VCS_INFO_check_com svn || return 1
1825     [[ -d ".svn" ]] && return 0
1826     return 1
1827 }
1828 # }}}
1829 VCS_INFO_tla_detect() { #{{{
1830     VCS_INFO_check_com tla || return 1
1831     vcs_comm[basedir]="$(tla tree-root 2> /dev/null)" && return 0
1832     return 1
1833 }
1834 # }}}
1835 # public API
1836 vcs_info_printsys () { # {{{
1837     vcs_info print_systems_
1838 }
1839 # }}}
1840 vcs_info_lastmsg () { # {{{
1841     local -i i
1842
1843     VCS_INFO_maxexports
1844     for i in {0..$((maxexports - 1))} ; do
1845         printf '$VCS_INFO_message_%d_: "' $i
1846         if zstyle -T ':vcs_info:formats:command' use-prompt-escapes ; then
1847             print -nP ${(P)${:-VCS_INFO_message_${i}_}}
1848         else
1849             print -n ${(P)${:-VCS_INFO_message_${i}_}}
1850         fi
1851         printf '"\n'
1852     done
1853 }
1854 # }}}
1855 vcs_info () { # {{{
1856     local pat
1857     local -i found
1858     local -a VCSs disabled dps
1859     local -x vcs usercontext
1860     local -ax msgs
1861     local -Ax vcs_comm
1862
1863     vcs="init"
1864     VCSs=(git hg bzr darcs svk mtn svn cvs cdv tla)
1865     case $1 in
1866         (print_systems_)
1867             zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1868             print -l '# list of supported version control backends:' \
1869                      '# disabled systems are prefixed by a hash sign (#)'
1870             for vcs in ${VCSs} ; do
1871                 [[ -n ${(M)disabled:#${vcs}} ]] && printf '#'
1872                 printf '%s\n' ${vcs}
1873             done
1874             print -l '# flavours (cannot be used in the disable style; they' \
1875                      '# are disabled with their master [git-svn -> git]):'   \
1876                      git-{p4,svn}
1877             return 0
1878             ;;
1879         ('')
1880             [[ -z ${usercontext} ]] && usercontext=default
1881             ;;
1882         (*) [[ -z ${usercontext} ]] && usercontext=$1
1883             ;;
1884     esac
1885
1886     zstyle -T ":vcs_info:${vcs}:${usercontext}" "enable" || {
1887         [[ -n ${VCS_INFO_message_0_} ]] && VCS_INFO_set --clear
1888         return 0
1889     }
1890     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1891
1892     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable-patterns" dps
1893     for pat in ${dps} ; do
1894         if [[ ${PWD} == ${~pat} ]] ; then
1895             [[ -n ${vcs_info_msg_0_} ]] && VCS_INFO_set --clear
1896             return 0
1897         fi
1898     done
1899
1900     VCS_INFO_maxexports
1901
1902     (( found = 0 ))
1903     for vcs in ${VCSs} ; do
1904         [[ -n ${(M)disabled:#${vcs}} ]] && continue
1905         vcs_comm=()
1906         VCS_INFO_${vcs}_detect && (( found = 1 )) && break
1907     done
1908
1909     (( found == 0 )) && {
1910         VCS_INFO_set --nvcs
1911         return 0
1912     }
1913
1914     VCS_INFO_${vcs}_get_data || {
1915         VCS_INFO_set --nvcs
1916         return 1
1917     }
1918
1919     VCS_INFO_set
1920     return 0
1921 }
1922
1923 VCS_INFO_set --nvcs preinit
1924 # }}}
1925
1926 # change vcs_info formats for the grml prompt
1927 if [[ "$TERM" == dumb ]] ; then
1928     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] "
1929     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "
1930 else
1931     # these are the same, just with a lot of colours:
1932     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} "
1933     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} "
1934     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1935 fi
1936
1937 # }}}
1938
1939 # {{{ set prompt
1940 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1941     promptinit # people should be able to use their favourite prompt
1942 else
1943     print 'Notice: no promptinit available :('
1944 fi
1945
1946 setopt prompt_subst
1947
1948 # make sure to use right prompt only when not running a command
1949 is41 && setopt transient_rprompt
1950
1951 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1952     [[ $NOPRECMD -gt 0 ]] && return 0
1953     # update VCS information
1954     vcs_info
1955
1956     # allow manual overwriting of RPROMPT
1957     if [[ -n $RPROMPT ]] ; then
1958         [[ $TERM == screen* ]] && print -nP "\ekzsh\e\\"
1959         # return 0
1960     fi
1961     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1962     if [[ $DONTSETRPROMPT -eq 0 ]] ; then
1963         if [[ $BATTERY -gt 0 ]] ; then
1964             # update BATTERY information
1965             battery
1966             RPROMPT="%(?..:()% ${PERCENT}${SCREENTITLE}"
1967             # RPROMPT="${PERCENT}${SCREENTITLE}"
1968         else
1969             RPROMPT="%(?..:()% ${SCREENTITLE}"
1970             # RPROMPT="${SCREENTITLE}"
1971         fi
1972     fi
1973     # adjust title of xterm
1974     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1975     case $TERM in
1976         (xterm*|rxvt)
1977             print -Pn "\e]0;%n@%m: %~\a"
1978             ;;
1979     esac
1980 }
1981
1982 # preexec() => a function running before every command
1983 is4 && [[ $NOPRECMD -eq 0 ]] && \
1984 preexec () {
1985     [[ $NOPRECMD -gt 0 ]] && return 0
1986 # set hostname if not running on host with name 'grml'
1987     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1988        NAME="@$HOSTNAME"
1989     fi
1990 # get the name of the program currently running and hostname of local machine
1991 # set screen window title if running in a screen
1992     if [[ "$TERM" == screen* ]] ; then
1993         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1994         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1995         echo -ne "\ek$CMD\e\\"
1996     fi
1997 # set the screen title to "zsh" when sitting at the command prompt:
1998     if [[ "$TERM" == screen* ]] ; then
1999         SCREENTITLE=$'%{\ekzsh\e\\%}'
2000     else
2001         SCREENTITLE=''
2002     fi
2003 # adjust title of xterm
2004     case $TERM in
2005         (xterm*|rxvt)
2006             print -Pn "\e]0;%n@%m: $1\a"
2007             ;;
2008     esac
2009 }
2010
2011 EXITCODE="%(?..%?%1v )"
2012 PS2='\`%_> '      # secondary prompt, printed when the shell needs more information to complete a command.
2013 PS3='?# '         # selection prompt used within a select loop.
2014 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
2015
2016 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
2017 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
2018     debian_chroot=$(cat /etc/debian_chroot)
2019 fi
2020
2021 # don't use colors on dumb terminals (like emacs):
2022 if [[ "$TERM" == dumb ]] ; then
2023     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2024 else
2025     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
2026     # set variable identifying the chroot you work in (used in the prompt below)
2027     if [[ $GRMLPROMPT -gt 0 ]] ; then
2028         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
2029 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# "
2030     else
2031         # This assembles the primary prompt string
2032         if (( EUID != 0 )); then
2033             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2034         else
2035             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2036         fi
2037     fi
2038 fi
2039
2040 # if we are inside a grml-chroot set a specific prompt theme
2041 if [[ -n "$GRML_CHROOT" ]] ; then
2042     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
2043 fi
2044 # }}}
2045
2046 # {{{ 'hash' some often used directories
2047 #d# start
2048 hash -d deb=/var/cache/apt/archives
2049 hash -d doc=/usr/share/doc
2050 hash -d linux=/lib/modules/$(command uname -r)/build/
2051 hash -d log=/var/log
2052 hash -d slog=/var/log/syslog
2053 hash -d src=/usr/src
2054 hash -d templ=/usr/share/doc/grml-templates
2055 hash -d tt=/usr/share/doc/texttools-doc
2056 hash -d www=/var/www
2057 #d# end
2058 # }}}
2059
2060 # {{{ some aliases
2061 if [[ $UID -eq 0 ]] ; then
2062     [[ -r /etc/grml/screenrc ]] && alias screen='/usr/bin/screen -c /etc/grml/screenrc'
2063 elif [[ -r $HOME/.screenrc ]] ; then
2064     alias screen="/usr/bin/screen -c $HOME/.screenrc"
2065 else
2066     [[ -r /etc/grml/screenrc_grml ]] && alias screen='/usr/bin/screen -c /etc/grml/screenrc_grml'
2067 fi
2068
2069 # do we have GNU ls with color-support?
2070 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
2071     #a1# execute \kbd{@a@}:\quad ls with colors
2072     alias ls='ls -b -CF --color=auto'
2073     #a1# execute \kbd{@a@}:\quad list all files, with colors
2074     alias la='ls -la --color=auto'
2075     #a1# long colored list, without dotfiles (@a@)
2076     alias ll='ls -l --color=auto'
2077     #a1# long colored list, human readable sizes (@a@)
2078     alias lh='ls -hAl --color=auto'
2079     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2080     alias l='ls -lF --color=auto'
2081 else
2082     alias ls='ls -b -CF'
2083     alias la='ls -la'
2084     alias ll='ls -l'
2085     alias lh='ls -hAl'
2086     alias l='ls -lF'
2087 fi
2088
2089 alias mdstat='cat /proc/mdstat'
2090 alias ...='cd ../../'
2091
2092 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2093 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2094     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2095 fi
2096
2097 alias cp='nocorrect cp'         # no spelling correction on cp
2098 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
2099 alias mv='nocorrect mv'         # no spelling correction on mv
2100 alias rm='nocorrect rm'         # no spelling correction on rm
2101
2102 #a1# Execute \kbd{rmdir}
2103 alias rd='rmdir'
2104 #a1# Execute \kbd{rmdir}
2105 alias md='mkdir'
2106
2107 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2108 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2109 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2110
2111 # make sure it is not assigned yet
2112 [[ $(whence -w utf2iso &>/dev/null) == 'utf2iso: alias' ]] && unalias utf2iso
2113
2114 utf2iso() {
2115     if isutfenv ; then
2116         for ENV in $(env | command grep -i '.utf') ; do
2117             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2118         done
2119     fi
2120 }
2121
2122 # make sure it is not assigned yet
2123 [[ $(whence -w iso2utf &>/dev/null) == 'iso2utf: alias' ]] && unalias iso2utf
2124 iso2utf() {
2125     if ! isutfenv ; then
2126         for ENV in $(env | command grep -i '\.iso') ; do
2127             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2128         done
2129     fi
2130 }
2131
2132 # set up software synthesizer via speakup
2133 swspeak() {
2134     if [ -x /usr/sbin/swspeak-setup ] ; then
2135        setopt singlelinezle
2136        unsetopt prompt_cr
2137        export PS1="%m%# "
2138        /usr/sbin/swspeak-setup $@
2139      else # old version:
2140         aumix -w 90 -v 90 -p 90 -m 90
2141         if ! [[ -r /dev/softsynth ]] ; then
2142             flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
2143             return 1
2144         else
2145            setopt singlelinezle
2146            unsetopt prompt_cr
2147            export PS1="%m%# "
2148             nice -n -20 speechd-up
2149             sleep 2
2150             flite -o play -t "Finished setting up software synthesizer"
2151         fi
2152      fi
2153 }
2154
2155 # I like clean prompt, so provide simple way to get that
2156 check_com 0 || alias 0='return 0'
2157
2158 # for really lazy people like mika:
2159 check_com S &>/dev/null || alias S='screen'
2160 check_com s &>/dev/null || alias s='ssh'
2161
2162 # get top 10 shell commands:
2163 alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
2164
2165 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
2166 if check_com -c truecrypt ; then
2167     if isutfenv ; then
2168         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
2169     else
2170         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
2171     fi
2172 fi
2173
2174 #f1# Hints for the use of zsh on grml
2175 zsh-help() {
2176     print "$bg[white]$fg[black]
2177 zsh-help - hints for use of zsh on grml
2178 =======================================$reset_color"
2179
2180     print '
2181 Main configuration of zsh happens in /etc/zsh/zshrc.
2182 That file is part of the package grml-etc-core, if you want to
2183 use them on a non-grml-system just get the tar.gz from
2184 http://deb.grml.org/ or (preferably) get it from the git repository:
2185
2186   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2187
2188 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2189 The file is still there, but it is empty for backwards compatibility.
2190
2191 For your own changes use these two files:
2192     $HOME/.zshrc.pre
2193     $HOME/.zshrc.local
2194
2195 The former is sourced very early in our zshrc, the latter is sourced
2196 very lately.
2197
2198 System wide configuration without touching configuration files of grml
2199 can take place in /etc/zsh/zshrc.local.
2200
2201 Normally, the root user (EUID == 0) does not get the whole grml setup.
2202 If you want to force the whole setup for that user, too, set
2203 GRML_ALWAYS_LOAD_ALL=1 in .zshrc.pre in root'\''s home directory.
2204
2205 For information regarding zsh start at http://grml.org/zsh/
2206
2207 Take a look at grml'\''s zsh refcard:
2208 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2209
2210 Check out the main zsh refcard:
2211 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2212
2213 And of course visit the zsh-lovers:
2214 % man zsh-lovers
2215
2216 You can adjust some options through environment variables when
2217 invoking zsh without having to edit configuration files.
2218 Basically meant for bash users who are not used to the power of
2219 the zsh yet. :)
2220
2221   "NOCOR=1    zsh" => deactivate automatic correction
2222   "NOMENU=1   zsh" => do not use auto menu completion (note: use ctrl-d for completion instead!)
2223   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2224   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
2225
2226 A value greater than 0 is enables a feature; a value equal to zero
2227 disables it. If you like one or the other of these settings, you can
2228 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2229 zshrc.'
2230
2231     print "
2232 $bg[white]$fg[black]
2233 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2234 Enjoy your grml system with the zsh!$reset_color"
2235 }
2236
2237 # debian stuff
2238 if [[ -r /etc/debian_version ]] ; then
2239     #a3# Execute \kbd{apt-cache search}
2240     alias acs='apt-cache search'
2241     #a3# Execute \kbd{apt-cache show}
2242     alias acsh='apt-cache show'
2243     #a3# Execute \kbd{apt-cache policy}
2244     alias acp='apt-cache policy'
2245     #a3# Execute \kbd{apt-get dist-upgrade}
2246     salias adg="apt-get dist-upgrade"
2247     #a3# Execute \kbd{apt-get install}
2248     salias agi="apt-get install"
2249     #a3# Execute \kbd{aptitude install}
2250     salias ati="aptitude install"
2251     #a3# Execute \kbd{apt-get upgrade}
2252     salias ag="apt-get upgrade"
2253     #a3# Execute \kbd{apt-get update}
2254     salias au="apt-get update"
2255     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2256     salias -a up="aptitude update ; aptitude safe-upgrade"
2257     #a3# Execute \kbd{dpkg-buildpackage}
2258     alias dbp='dpkg-buildpackage'
2259     #a3# Execute \kbd{grep-excuses}
2260     alias ge='grep-excuses'
2261
2262     # debian upgrade
2263     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
2264     upgrade() {
2265         if [[ -z "$1" ]] ; then
2266             $SUDO apt-get update
2267             $SUDO apt-get -u upgrade
2268         else
2269             ssh $1 $SUDO apt-get update
2270             # ask before the upgrade
2271             local dummy
2272             ssh $1 $SUDO apt-get --no-act upgrade
2273             echo -n 'Process the upgrade?'
2274             read -q dummy
2275             if [[ $dummy == "y" ]] ; then
2276                 ssh $1 $SUDO apt-get -u upgrade --yes
2277             fi
2278         fi
2279     }
2280
2281     # get a root shell as normal user in live-cd mode:
2282     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2283        alias su="sudo su"
2284      fi
2285
2286     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2287     alias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2288     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2289     alias tlog="tail -f /var/log/syslog"    # follow the syslog
2290 fi
2291
2292 # sort installed Debian-packages by size
2293 if check_com -c grep-status ; then
2294     #a3# List installed Debian-packages sorted by size
2295     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
2296 fi
2297
2298 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2299 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord ; then
2300     if check_com -c wodim ; then
2301         alias cdrecord="echo 'cdrecord is not provided under its original name by Debian anymore.
2302 See #377109 in the BTS of Debian for more details.
2303
2304 Please use the wodim binary instead' ; return 1"
2305     fi
2306 fi
2307
2308 # get_tw_cli has been renamed into get_3ware
2309 if check_com -c get_3ware ; then
2310     get_tw_cli() {
2311         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
2312         get_3ware
2313     }
2314 fi
2315
2316 # I hate lacking backward compatibility, so provide an alternative therefore
2317 if ! check_com -c apache2-ssl-certificate ; then
2318
2319     apache2-ssl-certificate() {
2320
2321     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
2322     print 'You might want to take a look at Debian the package ssl-cert as well.'
2323     print 'To generate a certificate for use with apache2 follow the instructions:'
2324
2325     echo '
2326
2327 export RANDFILE=/dev/random
2328 mkdir /etc/apache2/ssl/
2329 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
2330 chmod 600 /etc/apache2/ssl/apache.pem
2331
2332 Run "grml-tips ssl-certificate" if you need further instructions.
2333 '
2334     }
2335 fi
2336 # }}}
2337
2338 # {{{ Use hard limits, except for a smaller stack and no core dumps
2339 unlimit
2340 is425 && limit stack 8192
2341 isgrmlcd && limit core 0 # important for a live-cd-system
2342 limit -s
2343 # }}}
2344
2345 # {{{ completion system
2346
2347 # called later (via is4 && grmlcomp)
2348 # notice: use 'zstyle' for getting current settings
2349 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
2350 grmlcomp() {
2351     # TODO: This could use some additional information
2352
2353     # allow one error for every three characters typed in approximate completer
2354     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
2355
2356     # don't complete backup files as executables
2357     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
2358
2359     # start menu completion only if it could find no unambiguous initial string
2360     zstyle ':completion:*:correct:*'       insert-unambiguous true
2361     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
2362     zstyle ':completion:*:correct:*'       original true
2363
2364     # activate color-completion
2365     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
2366
2367     # format on completion
2368     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
2369
2370     # complete 'cd -<tab>' with menu
2371     zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
2372
2373     # insert all expansions for expand completer
2374     zstyle ':completion:*:expand:*'        tag-order all-expansions
2375     zstyle ':completion:*:history-words'   list false
2376
2377     # activate menu
2378     zstyle ':completion:*:history-words'   menu yes
2379
2380     # ignore duplicate entries
2381     zstyle ':completion:*:history-words'   remove-all-dups yes
2382     zstyle ':completion:*:history-words'   stop yes
2383
2384     # match uppercase from lowercase
2385     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
2386
2387     # separate matches into groups
2388     zstyle ':completion:*:matches'         group 'yes'
2389     zstyle ':completion:*'                 group-name ''
2390
2391     if [[ "$NOMENU" -eq 0 ]] ; then
2392         # if there are more than 5 options allow selecting from a menu
2393         zstyle ':completion:*'               menu select=5
2394     else
2395         # don't use any menus at all
2396         setopt no_auto_menu
2397     fi
2398
2399     zstyle ':completion:*:messages'        format '%d'
2400     zstyle ':completion:*:options'         auto-description '%d'
2401
2402     # describe options in full
2403     zstyle ':completion:*:options'         description 'yes'
2404
2405     # on processes completion complete all user processes
2406     zstyle ':completion:*:processes'       command 'ps -au$USER'
2407
2408     # offer indexes before parameters in subscripts
2409     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
2410
2411     # provide verbose completion information
2412     zstyle ':completion:*'                 verbose true
2413
2414     # recent (as of Dec 2007) zsh versions are able to provide descriptions
2415     # for commands (read: 1st word in the line) that it will list for the user
2416     # to choose from. The following disables that, because it's not exactly fast.
2417     zstyle ':completion:*:-command-:*:'    verbose false
2418
2419     # set format for warnings
2420     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
2421
2422     # define files to ignore for zcompile
2423     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
2424     zstyle ':completion:correct:'          prompt 'correct to: %e'
2425
2426     # Ignore completion functions for commands you don't have:
2427     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
2428
2429     # Provide more processes in completion of programs like killall:
2430     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
2431
2432     # complete manual by their section
2433     zstyle ':completion:*:manuals'    separate-sections true
2434     zstyle ':completion:*:manuals.*'  insert-sections   true
2435     zstyle ':completion:*:man:*'      menu yes select
2436
2437     # run rehash on completion so new installed program are found automatically:
2438     _force_rehash() {
2439         (( CURRENT == 1 )) && rehash
2440         return 1
2441     }
2442
2443     ## correction
2444     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
2445     if [[ "$NOCOR" -gt 0 ]] ; then
2446         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
2447         setopt nocorrect
2448     else
2449         # try to be smart about when to use what completer...
2450         setopt correct
2451         zstyle -e ':completion:*' completer '
2452             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
2453                 _last_try="$HISTNO$BUFFER$CURSOR"
2454                 reply=(_complete _match _ignored _prefix _files)
2455             else
2456                 if [[ $words[1] == (rm|mv) ]] ; then
2457                     reply=(_complete _files)
2458                 else
2459                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
2460                 fi
2461             fi'
2462     fi
2463
2464     # command for process lists, the local web server details and host completion
2465     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
2466
2467     # caching
2468     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
2469                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
2470
2471     # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
2472     if is42 ; then
2473         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
2474         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
2475     else
2476         _ssh_hosts=()
2477         _etc_hosts=()
2478     fi
2479     hosts=(
2480         $(hostname)
2481         "$_ssh_hosts[@]"
2482         "$_etc_hosts[@]"
2483         grml.org
2484         localhost
2485     )
2486     zstyle ':completion:*:hosts' hosts $hosts
2487     # TODO: so, why is this here?
2488     #  zstyle '*' hosts $hosts
2489
2490     # use generic completion system for programs not yet defined; (_gnu_generic works
2491     # with commands that provide a --help option with "standard" gnu-like output.)
2492     compdef _gnu_generic tail head feh cp mv df stow uname ipacsum fetchipac
2493
2494     # see upgrade function in this file
2495     compdef _hosts upgrade
2496 }
2497 # }}}
2498
2499 # {{{ grmlstuff
2500 grmlstuff() {
2501 # people should use 'grml-x'!
2502     startx() {
2503         if [[ -e /etc/X11/xorg.conf ]] ; then
2504             [[ -x /usr/bin/startx ]] && /usr/bin/startx "$@" || /usr/X11R6/bin/startx "$@"
2505         else
2506             echo "Please use the script \"grml-x\" for starting the X Window System
2507 because there does not exist /etc/X11/xorg.conf yet.
2508 If you want to use startx anyway please call \"/usr/bin/startx\"."
2509             return -1
2510         fi
2511     }
2512
2513     xinit() {
2514         if [[ -e /etc/X11/xorg.conf ]] ; then
2515             [[ -x /usr/bin/xinit ]] && /usr/bin/xinit || /usr/X11R6/bin/xinit
2516         else
2517             echo "Please use the script \"grml-x\" for starting the X Window System.
2518 because there does not exist /etc/X11/xorg.conf yet.
2519 If you want to use xinit anyway please call \"/usr/bin/xinit\"."
2520             return -1
2521         fi
2522     }
2523
2524     if check_com -c 915resolution ; then
2525         alias 855resolution='echo -e "Please use 915resolution as resolution modify tool for Intel graphic chipset."; return -1'
2526     fi
2527
2528     #a1# Output version of running grml
2529     alias grml-version='cat /etc/grml_version'
2530
2531     if check_com -c rebuildfstab ; then
2532         #a1# Rebuild /etc/fstab
2533         alias grml-rebuildfstab='rebuildfstab -v -r -config'
2534     fi
2535
2536     if check_com -c grml-debootstrap ; then
2537         alias debian2hd='print "Installing debian to harddisk is possible via using grml-debootstrap." ; return 1'
2538     fi
2539 }
2540 # }}}
2541
2542 # {{{ now run the functions
2543 isgrml && checkhome
2544 is4    && isgrml    && grmlstuff
2545 is4    && grmlcomp
2546 # }}}
2547
2548 # {{{ keephack
2549 is4 && xsource "/etc/zsh/keephack"
2550 # }}}
2551
2552 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
2553 # You use it as follows:
2554 # $ NTREF=/reference/file
2555 # $ ls -l *(e:nt:)
2556 # This lists all the files in the current directory newer than the reference file.
2557 # You can also specify the reference file inline; note quotes:
2558 # $ ls -l *(e:'nt ~/.zshenv':)
2559 is4 && nt() {
2560     if [[ -n $1 ]] ; then
2561         local NTREF=${~1}
2562     fi
2563     [[ $REPLY -nt $NTREF ]]
2564 }
2565 # }}}
2566
2567 # shell functions {{{
2568
2569 #f1# Provide csh compatibility
2570 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
2571
2572 #f1# Reload an autoloadable function
2573 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2574
2575 #f1# Reload zsh setup
2576 reload() {
2577     if [[ "$#*" -eq 0 ]] ; then
2578         [[ -r ~/.zshrc ]] && . ~/.zshrc
2579     else
2580         local fn
2581         for fn in "$@"; do
2582             unfunction $fn
2583             autoload -U $fn
2584         done
2585     fi
2586 }
2587 compdef _functions reload freload
2588
2589 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2590 sll() {
2591     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2592     for i in "$@" ; do
2593         file=$i
2594         while [[ -h "$file" ]] ; do
2595             ls -l $file
2596             file=$(readlink "$file")
2597         done
2598     done
2599 }
2600
2601 # fast manual access
2602 if check_com qma ; then
2603     #f1# View the zsh manual
2604     manzsh()  { qma zshall "$1" }
2605     compdef _man qma
2606 else
2607     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
2608 fi
2609
2610 if check_com -c $PAGER ; then
2611     #f1# View Debian's changelog of a given package
2612     dchange() {
2613         if [[ -r /usr/share/doc/${1}/changelog.Debian.gz ]] ; then
2614             $PAGER /usr/share/doc/${1}/changelog.Debian.gz
2615         elif [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2616             $PAGER /usr/share/doc/${1}/changelog.gz
2617         else
2618             if check_com -c aptitude ; then
2619                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2620                 if isgrml ; then
2621                     aptitude -t unstable changelog ${1}
2622                 else
2623                     aptitude changelog ${1}
2624                 fi
2625             else
2626                 echo "No changelog for package $1 found, sorry."
2627                 return 1
2628             fi
2629         fi
2630     }
2631     _dchange() { _files -W /usr/share/doc -/ }
2632     compdef _dchange dchange
2633
2634     #f1# View Debian's NEWS of a given package
2635     dnews() {
2636         if [[ -r /usr/share/doc/${1}/NEWS.Debian.gz ]] ; then
2637             $PAGER /usr/share/doc/${1}/NEWS.Debian.gz
2638         else
2639             if [[ -r /usr/share/doc/${1}/NEWS.gz ]] ; then
2640                 $PAGER /usr/share/doc/${1}/NEWS.gz
2641             else
2642                 echo "No NEWS file for package $1 found, sorry."
2643                 return 1
2644             fi
2645         fi
2646     }
2647     _dnews() { _files -W /usr/share/doc -/ }
2648     compdef _dnews dnews
2649
2650     #f1# View upstream's changelog of a given package
2651     uchange() {
2652         if [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2653             $PAGER /usr/share/doc/${1}/changelog.gz
2654         else
2655             echo "No changelog for package $1 found, sorry."
2656             return 1
2657         fi
2658     }
2659     _uchange() { _files -W /usr/share/doc -/ }
2660     compdef _uchange uchange
2661 fi
2662
2663 # zsh profiling
2664 profile() {
2665     ZSH_PROFILE_RC=1 $SHELL "$@"
2666 }
2667
2668 #f1# Edit an alias via zle
2669 edalias() {
2670     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2671 }
2672 compdef _aliases edalias
2673
2674 #f1# Edit a function via zle
2675 edfunc() {
2676     [[ -z "$1" ]] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
2677 }
2678 compdef _functions edfunc
2679
2680 # use it e.g. via 'Restart apache2'
2681 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2682 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2683 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2684 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2685 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2686 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2687     __start_stop() {
2688         local action_="${1:l}"  # e.g Start/Stop/Restart
2689         local service_="$2"
2690         local param_="$3"
2691
2692         local service_target_="$(readlink /etc/init.d/$service_)"
2693         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2694             # runit
2695             case "${action_}" in
2696                 start) if [[ ! -e /etc/service/$service_ ]]; then
2697                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2698                        else
2699                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2700                        fi ;;
2701                 # there is no reload in runits sysv emulation
2702                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2703                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2704             esac
2705         else
2706             # sysvinit
2707             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2708         fi
2709     }
2710
2711     for i in Start Restart Stop Force-Reload Reload ; do
2712         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2713     done
2714 fi
2715
2716 #f1# Provides useful information on globbing
2717 H-Glob() {
2718     echo -e "
2719     /      directories
2720     .      plain files
2721     @      symbolic links
2722     =      sockets
2723     p      named pipes (FIFOs)
2724     *      executable plain files (0100)
2725     %      device files (character or block special)
2726     %b     block special files
2727     %c     character special files
2728     r      owner-readable files (0400)
2729     w      owner-writable files (0200)
2730     x      owner-executable files (0100)
2731     A      group-readable files (0040)
2732     I      group-writable files (0020)
2733     E      group-executable files (0010)
2734     R      world-readable files (0004)
2735     W      world-writable files (0002)
2736     X      world-executable files (0001)
2737     s      setuid files (04000)
2738     S      setgid files (02000)
2739     t      files with the sticky bit (01000)
2740
2741   print *(m-1)          # Files modified up to a day ago
2742   print *(a1)           # Files accessed a day ago
2743   print *(@)            # Just symlinks
2744   print *(Lk+50)        # Files bigger than 50 kilobytes
2745   print *(Lk-50)        # Files smaller than 50 kilobytes
2746   print **/*.c          # All *.c files recursively starting in \$PWD
2747   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2748   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2749   print *~*.*           # All Files that do not contain a dot
2750   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2751   print -l *(.c|.h)     # Lists *.c and *.h
2752   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2753   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2754 }
2755 alias help-zshglob=H-Glob
2756
2757 check_com -c qma && alias ?='qma zshall'
2758
2759 # grep for running process, like: 'any vim'
2760 any() {
2761     if [[ -z "$1" ]] ; then
2762         echo "any - grep for process(es) by keyword" >&2
2763         echo "Usage: any <keyword>" >&2 ; return 1
2764     else
2765         local STRING=$1
2766         local LENGTH=$(expr length $STRING)
2767         local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
2768         local REST=$(echo $(expr substr $STRING 2 $LENGTH))
2769         ps xauwww| grep "[$FIRSCHAR]$REST"
2770     fi
2771 }
2772
2773 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2774 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2775 [[ -r /proc/1/maps ]] && \
2776 deswap() {
2777     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2778     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2779     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2780 }
2781
2782 # print hex value of a number
2783 hex() {
2784     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
2785 }
2786
2787 # calculate (or eval at all ;-)) with perl => p[erl-]eval
2788 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
2789 peval() {
2790     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
2791     perl -e "print eval($CALC),\"\n\";"
2792 }
2793 functions peval &>/dev/null && alias calc=peval
2794
2795 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
2796 # certain circumstances, so work around it, no matter which environment we have
2797 brltty() {
2798     if [[ -z "$DISPLAY" ]] ; then
2799         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
2800         command brltty "$@"
2801     else
2802         command brltty "$@"
2803     fi
2804 }
2805
2806 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
2807 aoeu() {
2808     echo -n 'Switching to us keyboard layout: '
2809     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
2810     echo 'Done'
2811 }
2812 asdf() {
2813     echo -n 'Switching to dvorak keyboard layout: '
2814     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
2815     echo 'Done'
2816 }
2817 # just press 'asdf' key to toggle from neon layout to us keyboard layout
2818 uiae() {
2819     echo -n 'Switching to us keyboard layout: '
2820     setxkbmap us && echo 'Done' || echo 'Failed'
2821 }
2822
2823 # set up an ipv6 tunnel
2824 ipv6-tunnel() {
2825     case $1 in
2826         start)
2827             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2828                 print 'ipv6 tunnel already set up, nothing to be done.'
2829                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
2830             else
2831                 [[ -n "$PUBLIC_IP" ]] || \
2832                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
2833                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
2834
2835                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
2836                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
2837                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
2838                 ifconfig sit0 tunnel ::192.88.99.1 up
2839                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
2840             fi
2841             ;;
2842         status)
2843             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2844                 print 'ipv6 tunnel available' ; return 0
2845             else
2846                 print 'ipv6 tunnel not available' ; return 1
2847             fi
2848             ;;
2849         stop)
2850             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2851                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
2852                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
2853             else
2854                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
2855             fi
2856             ;;
2857         *)
2858             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
2859             ;;
2860     esac
2861 }
2862
2863 # run dhclient for wireless device
2864 iwclient() {
2865     salias dhclient "$(wavemon -d | awk '/device/{print $2}')"
2866 }
2867
2868 # spawn a minimally set up ksh - useful if you want to umount /usr/.
2869 minimal-shell() {
2870     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ksh
2871 }
2872
2873 # make a backup of a file
2874 bk() {
2875     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2876 }
2877
2878 #f1# grep for patterns in grml's zsh setup
2879 zg() {
2880 #{{{
2881     LANG=C perl -e '
2882
2883 sub usage {
2884     print "usage: zg -[anr] <pattern>\n";
2885     print " Search for patterns in grml'\''s zshrc.\n";
2886     print " zg takes no or exactly one option plus a non empty pattern.\n\n";
2887     print "   options:\n";
2888     print "     --  no options (use if your pattern starts in with a dash.\n";
2889     print "     -a  search for the pattern in all code regions\n";
2890     print "     -n  search for the pattern in non-root code only\n";
2891     print "     -r  search in code for everyone (also root) only\n\n";
2892     print "   The default is -a for non-root users and -r for root.\n\n";
2893     print " If you installed the zshrc to a non-default locations (ie *NOT*\n";
2894     print " in /etc/zsh/zshrc) do: export GRML_ZSHRC=\$HOME/.zshrc\n";
2895     print " ...in case you copied the file to that location.\n\n";
2896     exit 1;
2897 }
2898
2899 if ($ENV{GRML_ZSHRC} ne "") {
2900     $RC = $ENV{GRML_ZSHRC};
2901 } else {
2902     $RC = "/etc/zsh/zshrc";
2903 }
2904
2905 usage if ($#ARGV < 0 || $#ARGV > 1);
2906 if ($> == 0) { $mode = "allonly"; }
2907 else { $mode = "all"; }
2908
2909 $opt = $ARGV[0];
2910 if ($opt eq "--")     { shift; }
2911 elsif ($opt eq "-a")  { $mode = "all"; shift; }
2912 elsif ($opt eq "-n")  { $mode = "nonroot"; shift; }
2913 elsif ($opt eq "-r" ) { $mode = "allonly"; shift; }
2914 elsif ($opt =~ m/^-/ || $#ARGV > 0) { usage(); }
2915
2916 $pattern = $ARGV[0];
2917 usage() if ($pattern eq "");
2918
2919 open FH, "<$RC" or die "zg: Could not open $RC: $!\n";
2920 while ($line = <FH>) {
2921     chomp $line;
2922     if ($line =~ m/^#:grep:marker:for:mika:/) { $markerfound = 1; next; }
2923     next if ($mode eq "nonroot" && markerfound == 0);
2924     break if ($mode eq "allonly" && markerfound == 1);
2925     print $line, "\n" if ($line =~ /$pattern/);
2926 }
2927 close FH;
2928 exit 0;
2929
2930     ' -- "$@"
2931 #}}}
2932     return $?
2933 }
2934
2935 # }}}
2936
2937 # {{{ make sure our environment is clean regarding colors
2938 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2939 # }}}
2940
2941 # source another config file if present {{{
2942 xsource "/etc/zsh/zshrc.local"
2943 # }}}
2944
2945 # "persistent history" {{{
2946 # just write important commands you always need to ~/.important_commands
2947 if [[ -r ~/.important_commands ]] ; then
2948     fc -R ~/.important_commands
2949 fi
2950 # }}}
2951
2952 #:grep:marker:for:mika: :-)
2953 ### non-root (EUID != 0) code below
2954 ###
2955
2956 (( GRML_ALWAYS_LOAD_ALL == 0 )) && (( $EUID == 0 )) && return 0
2957
2958 # variables {{{
2959
2960 # set terminal property (used e.g. by msgid-chooser)
2961 export COLORTERM="yes"
2962
2963 # set default browser
2964 if [[ -z "$BROWSER" ]] ; then
2965     if [[ -n "$DISPLAY" ]] ; then
2966         #v# If X11 is running
2967         check_com -c firefox && export BROWSER=firefox
2968     else
2969         #v# If no X11 is running
2970         check_com -c w3m && export BROWSER=w3m
2971     fi
2972 fi
2973
2974 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
2975 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
2976 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
2977
2978 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
2979 #v# [for non-root only]
2980 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
2981 # }}}
2982
2983 # aliases {{{
2984
2985 # Xterm resizing-fu.
2986 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
2987 alias hide='echo -en "\033]50;nil2\007"'
2988 alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
2989 alias small='echo -en "\033]50;6x10\007"'
2990 alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
2991 alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
2992 alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
2993 alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
2994 alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
2995 alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
2996
2997 # general
2998 #a2# Execute \kbd{du -sch}
2999 alias da='du -sch'
3000 #a2# Execute \kbd{jobs -l}
3001 alias j='jobs -l'
3002
3003 # compile stuff
3004 #a2# Execute \kbd{./configure}
3005 alias CO="./configure"
3006 #a2# Execute \kbd{./configure --help}
3007 alias CH="./configure --help"
3008
3009 # http://conkeror.mozdev.org/
3010 # TODO: I think this should be removed, as conkeror is not a simple extension anymore
3011 #a2# Run a keyboard driven firefox
3012 alias conkeror='firefox -chrome chrome://conkeror/content'
3013
3014 # arch/tla stuff
3015 if check_com -c tla ; then
3016     #a2# Execute \kbd{tla what-changed --diffs | less}
3017     alias tdi='tla what-changed --diffs | less'
3018     #a2# Execute \kbd{tla-buildpackage}
3019     alias tbp='tla-buildpackage'
3020     #a2# Execute \kbd{tla archive-mirror}
3021     alias tmi='tla archive-mirror'
3022     #a2# Execute \kbd{tla commit}
3023     alias tco='tla commit'
3024     #a2# Execute \kbd{tla star-merge}
3025     alias tme='tla star-merge'
3026 fi
3027
3028 # listing stuff
3029 #a2# Execute \kbd{ls -lSrah}
3030 alias dir="ls -lSrah"
3031 #a2# Only show dot-directories
3032 alias lad='ls -d .*(/)'                # only show dot-directories
3033 #a2# Only show dot-files
3034 alias lsa='ls -a .*(.)'                # only show dot-files
3035 #a2# Only files with setgid/setuid/sticky flag
3036 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
3037 #a2# Only show 1st ten symlinks
3038 alias lsl='ls -l *(@[1,10])'           # only symlinks
3039 #a2# Display only executables
3040 alias lsx='ls -l *(*[1,10])'           # only executables
3041 #a2# Display world-{readable,writable,executable} files
3042 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
3043 #a2# Display the ten biggest files
3044 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
3045 #a2# Only show directories
3046 alias lsd='ls -d *(/)'                 # only show directories
3047 #a2# Only show empty directories
3048 alias lse='ls -d *(/^F)'               # only show empty directories
3049 #a2# Display the ten newest files
3050 alias lsnew="ls -rl *(D.om[1,10])"     # display the newest files
3051 #a2# Display the ten oldest files
3052 alias lsold="ls -rtlh *(D.om[1,10])"   # display the oldest files
3053 #a2# Display the ten smallest files
3054 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
3055
3056 # chmod
3057 #a2# Execute \kbd{chmod 600}
3058 alias rw-='chmod 600'
3059 #a2# Execute \kbd{chmod 700}
3060 alias rwx='chmod 700'
3061 #m# a2 r-{}- Execute \kbd{chmod 644}
3062 alias r--='chmod 644'
3063 #a2# Execute \kbd{chmod 755}
3064 alias r-x='chmod 755'
3065
3066 # some useful aliases
3067 #a2# Execute \kbd{mkdir -o}
3068 alias md='mkdir -p'
3069
3070 check_com -c ipython && alias ips='ipython -p sh'
3071
3072 # console stuff
3073 #a2# Execute \kbd{mplayer -vo fbdev}
3074 alias cmplayer='mplayer -vo fbdev'
3075 #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
3076 alias fbmplayer='mplayer -vo fbdev -fs -zoom'
3077 #a2# Execute \kbd{links2 -driver fb}
3078 alias fblinks='links2 -driver fb'
3079
3080 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3081 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3082 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3083
3084 # simple webserver
3085 check_com -c python && alias http="python -m SimpleHTTPServer"
3086
3087 # Use 'g' instead of 'git':
3088 check_com g || alias g='git'
3089
3090 # use colors when browsing man pages, but only if not using LESS_TERMCAP_* from /etc/zsh/zshenv:
3091 if [[ -z "$LESS_TERMCAP_md" ]] ; then
3092     [[ -d ~/.terminfo/ ]] && alias man='TERMINFO=~/.terminfo/ LESS=C TERM=mostlike PAGER=less man'
3093 fi
3094
3095 # check whether Debian's package management (dpkg) is running
3096 if check_com salias ; then
3097     #a2# Check whether a dpkg instance is currently running
3098     salias check_dpkg_running="dpkg_running"
3099 fi
3100
3101 # work around non utf8 capable software in utf environment via $LANG and luit
3102 if check_com isutfenv && check_com luit ; then
3103     if check_com -c mrxvt ; then
3104         isutfenv && [[ -n "$LANG" ]] && \
3105             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3106     fi
3107
3108     if check_com -c aterm ; then
3109         isutfenv && [[ -n "$LANG" ]] && \
3110             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3111     fi
3112
3113     if check_com -c centericq ; then
3114         isutfenv && [[ -n "$LANG" ]] && \
3115             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3116     fi
3117 fi
3118 # }}}
3119
3120 # useful functions {{{
3121
3122 # searching
3123 #f4# Search for newspostings from authors
3124 agoogle() { ${=BROWSER} "http://groups.google.com/groups?as_uauthors=$*" ; }
3125 #f4# Search Debian Bug Tracking System
3126 debbug()  {
3127     setopt localoptions extendedglob
3128     if [[ $# -eq 1 ]]; then
3129         case "$1" in
3130             ([0-9]##)
3131             ${=BROWSER} "http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=$1"
3132             ;;
3133             (*@*)
3134             ${=BROWSER} "http://bugs.debian.org/cgi-bin/pkgreport.cgi?submitter=$1"
3135             ;;
3136             (*)
3137             ${=BROWSER} "http://bugs.debian.org/$*"
3138             ;;
3139         esac
3140     else
3141         print "$0 needs one argument"
3142         return 1
3143     fi
3144 }
3145 #f4# Search Debian Bug Tracking System in mbox format
3146 debbugm() { bts show --mbox $1 } # provide bugnummer as "$1"
3147 #f4# Search DMOZ
3148 dmoz()    { ${=BROWSER} http://search.dmoz.org/cgi-bin/search\?search=${1// /_} }
3149 #f4# Search German   Wiktionary
3150 dwicti()  { ${=BROWSER} http://de.wiktionary.org/wiki/${(C)1// /_} }
3151 #f4# Search English  Wiktionary
3152 ewicti()  { ${=BROWSER} http://en.wiktionary.org/wiki/${(C)1// /_} }
3153 #f4# Search Google Groups
3154 ggogle()  { ${=BROWSER} "http://groups.google.com/groups?q=$*" }
3155 #f4# Search Google
3156 google()  { ${=BROWSER} "http://www.google.com/search?&num=100&q=$*" }
3157 #f4# Search Google Groups for MsgID
3158 mggogle() { ${=BROWSER} "http://groups.google.com/groups?selm=$*" }
3159 #f4# Search Netcraft
3160 netcraft(){ ${=BROWSER} "http://toolbar.netcraft.com/site_report?url=$1" }
3161 #f4# Use German Wikipedia's full text search
3162 swiki()   { ${=BROWSER} http://de.wikipedia.org/wiki/Spezial:Search/${(C)1} }
3163 #f4# search \kbd{dict.leo.org}
3164 oleo()    { ${=BROWSER} "http://dict.leo.org/?search=$*" }
3165 #f4# Search German   Wikipedia
3166 wikide()  { ${=BROWSER} http://de.wikipedia.org/wiki/"${(C)*}" }
3167 #f4# Search English  Wikipedia
3168 wikien()  { ${=BROWSER} http://en.wikipedia.org/wiki/"${(C)*}" }
3169 #f4# Search official debs
3170 wodeb()   { ${=BROWSER} "http://packages.debian.org/search?keywords=$1&searchon=contents&suite=${2:=unstable}&section=all" }
3171
3172 #m# f4 gex() Exact search via Google
3173 check_com google && gex () { google "\"[ $1]\" $*" } # exact search at google
3174
3175 # misc
3176 #f5# Backup \kbd{file {\rm to} file\_timestamp}
3177 bk()      { cp -b ${1} ${1}_`date --iso-8601=m` }
3178 #f5# Copied diff
3179 cdiff()   { diff -crd "$*" | egrep -v "^Only in |^Binary files " }
3180 #f5# cd to directoy and list files
3181 cl()      { cd $1 && ls -a }        # cd && ls
3182 #f5# Cvs add
3183 cvsa()    { cvs add $* && cvs com -m 'initial checkin' $* }
3184 #f5# Cvs diff
3185 cvsd()    { cvs diff -N $* |& $PAGER }
3186 #f5# Cvs log
3187 cvsl()    { cvs log $* |& $PAGER }
3188 #f5# Cvs update
3189 cvsq()    { cvs -nq update }
3190 #f5# Rcs2log
3191 cvsr()    { rcs2log $* | $PAGER }
3192 #f5# Cvs status
3193 cvss()    { cvs status -v $* }
3194 #f5# Disassemble source files using gcc and as
3195 disassemble(){ gcc -pipe -S -o - -O -g $* | as -aldh -o /dev/null }
3196 #f5# Firefox remote control - open given URL
3197 fir()     { firefox -a firefox -remote "openURL($1)" }
3198 #f5# Create Directoy and \kbd{cd} to it
3199 mcd()     { mkdir -p "$@"; cd "$@" } # mkdir && cd
3200 #f5# Unified diff to timestamped outputfile
3201 mdiff()   { diff -udrP "$1" "$2" > diff.`date "+%Y-%m-%d"`."$1" }
3202 #f5# Memory overview
3203 memusage(){ ps aux | awk '{if (NR > 1) print $5; if (NR > 2) print "+"} END { print "p" }' | dc }
3204 #f5# Show contents of tar file
3205 shtar()   { gunzip -c $1 | tar -tf - -- | $PAGER }
3206 #f5# Show contents of tgz file
3207 shtgz()   { tar -ztf $1 | $PAGER }
3208 #f5# Show contents of zip file
3209 shzip()   { unzip -l $1 | $PAGER }
3210 #f5# Greps signature from file
3211 sig()     { agrep -d '^-- $' "$*" ~/.Signature }
3212 #f5# Unified diff
3213 udiff()   { diff -urd $* | egrep -v "^Only in |^Binary files " }
3214 #f5# (Mis)use \kbd{vim} as \kbd{less}
3215 viless()  { vim --cmd 'let no_plugin_maps = 1' -c "so \$VIMRUNTIME/macros/less.vim" "${@:--}" }
3216
3217 # download video from youtube
3218 ytdl() {
3219     if ! [[ -n "$2" ]] ; then
3220         print "Usage: ydtl http://youtube.com/watch?v=.... outputfile.flv">&2
3221         return 1
3222     else
3223         wget -O${2} "http://youtube.com/get_video?"${${${"$(wget -o/dev/null -O- "${1}" | grep -e watch_fullscreen)"}##*watch_fullscreen\?}%%\&fs=*}
3224     fi
3225 }
3226
3227 # Function Usage: uopen $URL/$file
3228 #f5# Download a file and display it locally
3229 uopen() {
3230     if ! [[ -n "$1" ]] ; then
3231         print "Usage: uopen \$URL/\$file">&2
3232         return 1
3233     else
3234         FILE=$1
3235         MIME=$(curl --head $FILE | grep Content-Type | cut -d ' ' -f 2 | cut -d\; -f 1)
3236         MIME=${MIME%$'\r'}
3237         curl $FILE | see ${MIME}:-
3238     fi
3239 }
3240
3241 # Function Usage: doc packagename
3242 #f5# \kbd{cd} to /usr/share/doc/\textit{package}
3243 doc() { cd /usr/share/doc/$1 && ls }
3244 _doc() { _files -W /usr/share/doc -/ }
3245 check_com compdef && compdef _doc doc
3246
3247 #f5# Make screenshot
3248 sshot() {
3249     [[ ! -d ~/shots  ]] && mkdir ~/shots
3250     #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
3251     cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
3252 }
3253
3254 # list images only
3255 limg() {
3256     local -a images
3257     images=( *.{jpg,gif,png}(.N) )
3258
3259     if [[ $#images -eq 0 ]] ; then
3260         print "No image files found"
3261     else
3262         ls "$@" "$images[@]"
3263     fi
3264 }
3265
3266 #f5# Create PDF file from source code
3267 makereadable() {
3268     output=$1
3269     shift
3270     a2ps --medium A4dj -E -o $output $*
3271     ps2pdf $output
3272 }
3273
3274 # zsh with perl-regex - use it e.g. via:
3275 # regcheck '\s\d\.\d{3}\.\d{3} Euro' ' 1.000.000 Euro'
3276 #f5# Checks whether a regex matches or not.\\&\quad Example: \kbd{regcheck '.\{3\} EUR' '500 EUR'}
3277 regcheck() {
3278     zmodload -i zsh/pcre
3279     pcre_compile $1 && \
3280     pcre_match $2 && echo "regex matches" || echo "regex does not match"
3281 }
3282
3283 #f5# List files which have been modified within the last {\it n} days
3284 new() { print -l *(m-$1) }
3285
3286 #f5# Grep in history
3287 greph() { history 0 | grep $1 }
3288 # use colors when GNU grep with color-support
3289 #a2# Execute \kbd{grep -{}-color=auto}
3290 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
3291 #a2# Execute \kbd{grep -i -{}-color=auto}
3292 alias GREP='grep -i --color=auto'
3293
3294 # one blank line between each line
3295 if [[ -r ~/.terminfo/m/mostlike ]] ; then
3296     #f5# Watch manpages in a stretched style
3297     man2() { PAGER='dash -c "sed G | /usr/bin/less"' TERM=mostlike /usr/bin/man "$@" ; }
3298 fi
3299
3300 # d():Copyright 2005 Nikolai Weibull <nikolai@bitwi.se>
3301 # notice: option AUTO_PUSHD has to be set
3302 #f5# Jump between directories
3303 d() {
3304     emulate -L zsh
3305     autoload -U colors
3306     local color=$fg_bold[blue]
3307     integer i=0
3308     dirs -p | while read dir; do
3309         local num="${$(printf "%-4d " $i)/ /.}"
3310         printf " %s  $color%s$reset_color\n" $num $dir
3311         (( i++ ))
3312     done
3313     integer dir=-1
3314     read -r 'dir?Jump to directory: ' || return
3315     (( dir == -1 )) && return
3316     if (( dir < 0 || dir >= i )); then
3317         echo d: no such directory stack entry: $dir
3318         return 1
3319     fi
3320     cd ~$dir
3321 }
3322
3323 # usage example: 'lcheck strcpy'
3324 #f5# Find out which libs define a symbol
3325 lcheck() {
3326     if [[ -n "$1" ]] ; then
3327         nm -go /usr/lib/lib*.a 2>/dev/null | grep ":[[:xdigit:]]\{8\} . .*$1"
3328     else
3329         echo "Usage: lcheck <function>" >&2
3330     fi
3331 }
3332
3333 #f5# Clean up directory - remove well known tempfiles
3334 purge() {
3335     FILES=(*~(N) .*~(N) \#*\#(N) *.o(N) a.out(N) *.core(N) *.cmo(N) *.cmi(N) .*.swp(N))
3336     NBFILES=${#FILES}
3337     if [[ $NBFILES > 0 ]] ; then
3338         print $FILES
3339         local ans
3340         echo -n "Remove these files? [y/n] "
3341         read -q ans
3342         if [[ $ans == "y" ]] ; then
3343             rm ${FILES}
3344             echo ">> $PWD purged, $NBFILES files removed"
3345         else
3346             echo "Ok. .. than not.."
3347         fi
3348     fi
3349 }
3350
3351 # Translate DE<=>EN
3352 # 'translate' looks up fot a word in a file with language-to-language
3353 # translations (field separator should be " : "). A typical wordlist looks
3354 # like at follows:
3355 #  | english-word : german-transmission
3356 # It's also only possible to translate english to german but not reciprocal.
3357 # Use the following oneliner to turn back the sort order:
3358 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3359 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3360 #f5# Translates a word
3361 trans() {
3362     case "$1" in
3363         -[dD]*)
3364             translate -l de-en $2
3365             ;;
3366         -[eE]*)
3367             translate -l en-de $2
3368             ;;
3369         *)
3370             echo "Usage: $0 { -D | -E }"
3371             echo "         -D == German to English"
3372             echo "         -E == English to German"
3373     esac
3374 }
3375
3376 #f5# List all occurrences of programm in current PATH
3377 plap() {
3378     if [[ $# = 0 ]] ; then
3379         echo "Usage:    $0 program"
3380         echo "Example:  $0 zsh"
3381         echo "Lists all occurrences of program in the current PATH."
3382     else
3383         ls -l ${^path}/*$1*(*N)
3384     fi
3385 }
3386
3387 # Found in the mailinglistarchive from Zsh (IIRC ~1996)
3388 #f5# Select items for specific command(s) from history
3389 selhist() {
3390     emulate -L zsh
3391     local TAB=$'\t';
3392     (( $# < 1 )) && {
3393         echo "Usage: $0 command"
3394         return 1
3395     };
3396     cmd=(${(f)"$(grep -w $1 $HISTFILE | sort | uniq | pr -tn)"})
3397     print -l $cmd | less -F
3398     echo -n "enter number of desired command [1 - $(( ${#cmd[@]} - 1 ))]: "
3399     local answer
3400     read answer
3401     print -z "${cmd[$answer]#*$TAB}"
3402 }
3403
3404 # Use vim to convert plaintext to HTML
3405 #f5# Transform files to html with highlighting
3406 2html() { vim -u NONE -n -c ':syntax on' -c ':so $VIMRUNTIME/syntax/2html.vim' -c ':wqa' $1 &>/dev/null }
3407
3408 # Usage: simple-extract <file>
3409 #f5# Smart archive extractor
3410 simple-extract () {
3411     if [[ -f $1 ]] ; then
3412         case $1 in
3413             *.tar.bz2)  bzip2 -v -d $1      ;;
3414             *.tar.gz)   tar -xvzf $1        ;;
3415             *.rar)      unrar $1            ;;
3416             *.deb)      ar -x $1            ;;
3417             *.bz2)      bzip2 -d $1         ;;
3418             *.lzh)      lha x $1            ;;
3419             *.gz)       gunzip -d $1        ;;
3420             *.tar)      tar -xvf $1         ;;
3421             *.tgz)      gunzip -d $1        ;;
3422             *.tbz2)     tar -jxvf $1        ;;
3423             *.zip)      unzip $1            ;;
3424             *.Z)        uncompress $1       ;;
3425             *)          echo "'$1' Error. Please go away" ;;
3426         esac
3427     else
3428         echo "'$1' is not a valid file"
3429     fi
3430 }
3431
3432 # Usage: smartcompress <file> (<type>)
3433 #f5# Smart archive creator
3434 smartcompress() {
3435     if [[ -n $2 ]] ; then
3436         case $2 in
3437             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
3438             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
3439             tar.Z)          tar -Zcvf$1.$2 $1 ;;
3440             tar)            tar -cvf$1.$2  $1 ;;
3441             gz | gzip)      gzip           $1 ;;
3442             bz2 | bzip2)    bzip2          $1 ;;
3443             *)
3444                 echo "Error: $2 is not a valid compression type"
3445                 ;;
3446         esac
3447     else
3448         smartcompress $1 tar.gz
3449     fi
3450 }
3451
3452 # Usage: show-archive <archive>
3453 #f5# List an archive's content
3454 show-archive() {
3455     if [[ -f $1 ]] ; then
3456         case $1 in
3457             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
3458             *.tar)         tar -tf $1 ;;
3459             *.tgz)         tar -ztf $1 ;;
3460             *.zip)         unzip -l $1 ;;
3461             *.bz2)         bzless $1 ;;
3462             *.deb)         dpkg-deb --fsys-tarfile $1 | tar -tf - -- ;;
3463             *)             echo "'$1' Error. Please go away" ;;
3464         esac
3465     else
3466         echo "'$1' is not a valid archive"
3467     fi
3468 }
3469
3470 # It's shameless stolen from <http://www.vim.org/tips/tip.php?tip_id=167>
3471 #f5# Use \kbd{vim} as your manpage reader
3472 vman() { man $* | col -b | view -c 'set ft=man nomod nolist' - }
3473
3474 # function readme() { $PAGER -- (#ia3)readme* }
3475 #f5# View all README-like files in current directory in pager
3476 readme() {
3477     local files
3478     files=(./(#i)*(read*me|lue*m(in|)ut)*(ND))
3479     if (($#files)) ; then
3480         $PAGER $files
3481     else
3482         print 'No README files.'
3483     fi
3484 }
3485
3486 # function ansi-colors()
3487 #f5# Display ANSI colors
3488 ansi-colors() {
3489     typeset esc="\033[" line1 line2
3490     echo " _ _ _40 _ _ _41_ _ _ _42 _ _ 43_ _ _ 44_ _ _45 _ _ _ 46_ _ _ 47_ _ _ 49_ _"
3491     for fore in 30 31 32 33 34 35 36 37; do
3492         line1="$fore "
3493         line2="   "
3494         for back in 40 41 42 43 44 45 46 47 49; do
3495             line1="${line1}${esc}${back};${fore}m Normal ${esc}0m"
3496             line2="${line2}${esc}${back};${fore};1m Bold   ${esc}0m"
3497         done
3498         echo -e "$line1\n$line2"
3499     done
3500 }
3501
3502 # suidfind() { ls -latg $path | grep '^...s' }
3503 #f5# Find all files in \$PATH with setuid bit set
3504 suidfind() { ls -latg $path/*(sN) }
3505
3506 # See above but this is /better/ ... anywise ..
3507 findsuid() {
3508     print 'Output will be written to ~/suid_* ...'
3509     $SUDO find / -type f \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suidfiles.`date "+%Y-%m-%d"`.out 2>&1
3510     $SUDO find / -type d \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suiddirs.`date "+%Y-%m-%d"`.out 2>&1
3511     $SUDO find / -type f \( -perm -2 -o -perm -20 \) -ls > ~/suid_writefiles.`date "+%Y-%m-%d"`.out 2>&1
3512     $SUDO find / -type d \( -perm -2 -o -perm -20 \) -ls > ~/suid_writedirs.`date "+%Y-%m-%d"`.out 2>&1
3513     print 'Finished'
3514 }
3515
3516 #f5# Reload given functions
3517 refunc() {
3518     for func in $argv ; do
3519         unfunction $func
3520         autoload $func
3521     done
3522 }
3523
3524 # a small check to see which DIR is located on which server/partition.
3525 # stolen and modified from Sven's zshrc.forall
3526 #f5# Report diskusage of a directory
3527 dirspace() {
3528     if [[ -n "$1" ]] ; then
3529         for dir in $* ; do
3530             if [[ -d "$dir" ]] ; then
3531                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3532             else
3533                 echo "warning: $dir does not exist" >&2
3534             fi
3535         done
3536     else
3537         for dir in $path; do
3538             if [[ -d "$dir" ]] ; then
3539                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3540             else
3541                 echo "warning: $dir does not exist" >&2
3542             fi
3543         done
3544     fi
3545 }
3546
3547 # % slow_print `cat /etc/passwd`
3548 #f5# Slowly print out parameters
3549 slow_print() {
3550     for argument in "${@}" ; do
3551         for ((i = 1; i <= ${#1} ;i++)) ; do
3552             print -n "${argument[i]}"
3553             sleep 0.08
3554         done
3555         print -n " "
3556     done
3557     print ""
3558 }
3559
3560 #f5# Show some status info
3561 status() {
3562     print ""
3563     print "Date..: "$(date "+%Y-%m-%d %H:%M:%S")""
3564     print "Shell.: Zsh $ZSH_VERSION (PID = $$, $SHLVL nests)"
3565     print "Term..: $TTY ($TERM), ${BAUD:+$BAUD bauds, }$COLUMNS x $LINES cars"
3566     print "Login.: $LOGNAME (UID = $EUID) on $HOST"
3567     print "System: $(cat /etc/[A-Za-z]*[_-][rv]e[lr]*)"
3568     print "Uptime:$(uptime)"
3569     print ""
3570 }
3571
3572 # Rip an audio CD
3573 #f5# Rip an audio CD
3574 audiorip() {
3575     mkdir -p ~/ripps
3576     cd ~/ripps
3577     cdrdao read-cd --device $DEVICE --driver generic-mmc audiocd.toc
3578     cdrdao read-cddb --device $DEVICE --driver generic-mmc audiocd.toc
3579     echo " * Would you like to burn the cd now? (yes/no)"
3580     read input
3581     if [[ "$input" = "yes" ]] ; then
3582         echo " ! Burning Audio CD"
3583         audioburn
3584         echo " * done."
3585     else
3586         echo " ! Invalid response."
3587     fi
3588 }
3589
3590 # and burn it
3591 #f5# Burn an audio CD (in combination with audiorip)
3592 audioburn() {
3593     cd ~/ripps
3594     cdrdao write --device $DEVICE --driver generic-mmc audiocd.toc
3595     echo " * Should I remove the temporary files? (yes/no)"
3596     read input
3597     if [[ "$input" = "yes" ]] ; then
3598         echo " ! Removing Temporary Files."
3599         cd ~
3600         rm -rf ~/ripps
3601         echo " * done."
3602     else
3603         echo " ! Invalid response."
3604     fi
3605 }
3606
3607 #f5# Make an audio CD from all mp3 files
3608 mkaudiocd() {
3609     # TODO: do the renaming more zshish, possibly with zmv()
3610     cd ~/ripps
3611     for i in *.[Mm][Pp]3; do mv "$i" `echo $i | tr '[A-Z]' '[a-z]'`; done
3612     for i in *.mp3; do mv "$i" `echo $i | tr ' ' '_'`; done
3613     for i in *.mp3; do mpg123 -w `basename $i .mp3`.wav $i; done
3614     normalize -m *.wav
3615     for i in *.wav; do sox $i.wav -r 44100 $i.wav resample; done
3616 }
3617
3618 #f5# Create an ISO image. You are prompted for\\&\quad volume name, filename and directory
3619 mkiso() {
3620     echo " * Volume name "
3621     read volume
3622     echo " * ISO Name (ie. tmp.iso)"
3623     read iso
3624     echo " * Directory or File"
3625     read files
3626     mkisofs -o ~/$iso -A $volume -allow-multidot -J -R -iso-level 3 -V $volume -R $files
3627 }
3628
3629 #f5# Simple thumbnails generator
3630 genthumbs() {
3631     rm -rf thumb-* index.html
3632     echo "
3633 <html>
3634   <head>
3635     <title>Images</title>
3636   </head>
3637   <body>" > index.html
3638     for f in *.(gif|jpeg|jpg|png) ; do
3639         convert -size 100x200 "$f" -resize 100x200 thumb-"$f"
3640         echo "    <a href=\"$f\"><img src=\"thumb-$f\"></a>" >> index.html
3641     done
3642     echo "
3643   </body>
3644 </html>" >> index.html
3645 }
3646
3647 #f5# Set all ulimit parameters to \kbd{unlimited}
3648 allulimit() {
3649     ulimit -c unlimited
3650     ulimit -d unlimited
3651     ulimit -f unlimited
3652     ulimit -l unlimited
3653     ulimit -n unlimited
3654     ulimit -s unlimited
3655     ulimit -t unlimited
3656 }
3657
3658 # ogg2mp3 with bitrate of 192
3659 ogg2mp3_192() {
3660     oggdec -o - ${1} | lame -b 192 - ${1:r}.mp3
3661 }
3662
3663 #f5# RFC 2396 URL encoding in Z-Shell
3664 urlencode() {
3665     setopt localoptions extendedglob
3666     input=( ${(s::)1} )
3667     print ${(j::)input/(#b)([^A-Za-z0-9_.!~*\'\(\)-])/%${(l:2::0:)$(([##16]#match))}}
3668 }
3669
3670 #f5# Install x-lite (VoIP software)
3671 getxlite() {
3672     setopt local_options
3673     setopt errreturn
3674     [[ -d ~/tmp ]] || mkdir ~/tmp
3675     cd ~/tmp
3676
3677     echo "Downloading http://www.counterpath.com/download/X-Lite_Install.tar.gz and storing it in ~/tmp:"
3678     if wget http://www.counterpath.com/download/X-Lite_Install.tar.gz ; then
3679         unp X-Lite_Install.tar.gz && echo done || echo failed
3680     else
3681         echo "Error while downloading." ; return 1
3682     fi
3683
3684     if [[ -x xten-xlite/xtensoftphone ]] ; then
3685         echo "Execute xten-xlite/xtensoftphone to start xlite."
3686     fi
3687 }
3688
3689 #f5# Install skype
3690 getskype() {
3691     setopt local_options
3692     setopt errreturn
3693     echo "Downloading debian package of skype."
3694     echo "Notice: If you want to use a more recent skype version run 'getskypebeta'."
3695     wget http://www.skype.com/go/getskype-linux-deb
3696     $SUDO dpkg -i skype*.deb && echo "skype installed."
3697 }
3698
3699 #f5# Install beta-version of skype
3700 getskypebeta() {
3701     setopt local_options
3702     setopt errreturn
3703     echo "Downloading debian package of skype (beta version)."
3704     wget http://www.skype.com/go/getskype-linux-beta-deb
3705     $SUDO dpkg -i skype-beta*.deb && echo "skype installed."
3706 }
3707
3708 #f5# Install gizmo (VoIP software)
3709 getgizmo() {
3710     setopt local_options
3711     setopt errreturn
3712     echo "libgtk2.0-0, gconf2, libstdc++6, libasound2 and zlib1g have to be available. Installing."
3713     $SUDO apt-get update
3714     $SUDO apt-get install libgtk2.0-0 gconf2 libstdc++6 libasound2 zlib1g
3715     wget "$(lynx --dump http://gizmo5.com/pc/download/linux/ | awk '/libstdc\+\+6.*\.deb/ {print $2}')"
3716     $SUDO dpkg -i gizmo-project*.deb && echo "gizmo installed."
3717 }
3718
3719 #f5# Get and run AIR (Automated Image and Restore)
3720 getair() {
3721     setopt local_options
3722     setopt errreturn
3723     [[ -w . ]] || { echo 'Error: you do not have write permissions in this directory. Exiting.' ; return 1 }
3724     local VER='1.2.8'
3725     wget http://puzzle.dl.sourceforge.net/sourceforge/air-imager/air-$VER.tar.gz
3726     tar zxf air-$VER.tar.gz
3727     cd air-$VER
3728     INTERACTIVE=no $SUDO ./install-air-1.2.8
3729     [[ -x /usr/local/bin/air ]] && [[ -n "$DISPLAY" ]] && $SUDO air
3730 }
3731
3732 #f5# Get specific git commitdiff
3733 git-get-diff() {
3734     if [[ -z $GITTREE ]] ; then
3735         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3736     fi
3737     if ! [[ -z $1 ]] ; then
3738         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commitdiff;h=$1"
3739     else
3740         echo "Usage: git-get-diff <commit>"
3741     fi
3742 }
3743
3744 #f5# Get specific git commit
3745 git-get-commit() {
3746     if [[ -z $GITTREE ]] ; then
3747         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3748     fi
3749     if ! [[ -z $1 ]] ; then
3750         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commit;h=$1"
3751     else
3752         echo "Usage: git-get-commit <commit>"
3753     fi
3754 }
3755
3756 #f5# Get specific git diff
3757 git-get-plaindiff () {
3758     if [[ -z $GITTREE ]] ; then
3759        GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3760     fi
3761     if [[ -z $1 ]] ; then
3762        echo 'Usage: git-get-plaindiff '
3763     else
3764        echo -n "Downloading $1.diff ... "
3765        # avoid "generating ..." stuff from kernel.org server:
3766        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O /dev/null
3767        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O $1.diff \
3768             && echo done || echo failed
3769     fi
3770 }
3771
3772
3773 # http://strcat.de/blog/index.php?/archives/335-Software-sauber-deinstallieren...html
3774 #f5# Log 'make install' output
3775 mmake() {
3776     [[ ! -d ~/.errorlogs ]] && mkdir ~/.errorlogs
3777     make -n install > ~/.errorlogs/${PWD##*/}-makelog
3778 }
3779
3780 #f5# Indent source code
3781 smart-indent() {
3782     indent -npro -kr -i8 -ts8 -sob -l80 -ss -ncs $*
3783 }
3784
3785 # highlight important stuff in diff output, usage example: hg diff | hidiff
3786 #m# a2 hidiff \kbd{histring} oneliner for diffs
3787 check_com -c histring && \
3788     alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
3789
3790 # rename pictures based on information found in exif headers
3791 #f5# Rename pictures based on information found in exif headers
3792 exirename() {
3793     if [[ $# -lt 1 ]] ; then
3794         echo 'Usage: jpgrename $FILES' >& 2
3795         return 1
3796     else
3797         echo -n 'Checking for jhead with version newer than 1.9: '
3798         jhead_version=`jhead -h | grep 'used by most Digital Cameras.  v.*' | awk '{print $6}' | tr -d v`
3799         if [[ $jhead_version > '1.9' ]]; then
3800             echo 'success - now running jhead.'
3801             jhead -n%Y-%m-%d_%Hh%M_%f $*
3802         else
3803             echo 'failed - exiting.'
3804         fi
3805     fi
3806 }
3807
3808 # open file in vim and jump to line
3809 # http://www.downgra.de/archives/2007/05/08/T19_21_11/
3810 j2v() {
3811     local -a params
3812     params=(${*//(#m):[0-9]*:/\\n+${MATCH//:/}}) # replace ':23:' to '\n+23'
3813     params=(${(s|\n|)${(j|\n|)params}}) # join array using '\n', then split on all '\n'
3814     vim ${params}
3815 }
3816
3817 # get_ic() - queries imap servers for capabilities; real simple. no imaps
3818 ic_get() {
3819     local port
3820     if [[ ! -z $1 ]] ; then
3821         port=${2:-143}
3822         print "querying imap server on $1:${port}...\n";
3823         print "a1 capability\na2 logout\n" | nc $1 ${port}
3824     else
3825         print "usage:\n  $0 <imap-server> [port]"
3826     fi
3827 }
3828
3829 # creates a Maildir/ with its {new,cur,tmp} subdirs
3830 mkmaildir() {
3831     local root subdir
3832     root=${MAILDIR_ROOT:-${HOME}/Mail}
3833     if [[ -z ${1} ]] ; then print "Usage:\n $0 <dirname>" ; return 1 ; fi
3834     subdir=${1}
3835     mkdir -p ${root}/${subdir}/{cur,new,tmp}
3836 }
3837
3838 # xtrename() rename xterm from within GNU-screen
3839 xtrename() {
3840     if [[ -z ${DISPLAY} ]] ; then
3841         printf 'xtrename only makes sense in X11.\n'
3842         return 1
3843     fi
3844     if [[ -z ${1} ]] ; then
3845         printf 'usage: xtrename() "title for xterm"\n'
3846         printf '  renames the title of xterm from _within_ screen.\n'
3847         printf '  Also works without screen.\n'
3848         return 0
3849     fi
3850     print -n "\eP\e]0;${1}\C-G\e\\"
3851     return 0
3852 }
3853
3854 # hl() highlighted less
3855 # http://ft.bewatermyfriend.org/comp/data/zsh/zfunct.html
3856 if check_com -c highlight ; then
3857     function hl() {
3858         local theme lang
3859         theme=${HL_THEME:-""}
3860         case ${1} in
3861             (-l|--list)
3862                 ( printf 'available languages (syntax parameter):\n\n' ;
3863                     highlight --list-langs ; ) | less -SMr
3864                 ;;
3865             (-t|--themes)
3866                 ( printf 'available themes (style parameter):\n\n' ;
3867                     highlight --list-themes ; ) | less -SMr
3868                 ;;
3869             (-h|--help)
3870                 printf 'usage: hl <syntax[:theme]> <file>\n'
3871                 printf '    available options: --list (-l), --themes (-t), --help (-h)\n\n'
3872                 printf '  Example: hl c main.c\n'
3873                 ;;
3874             (*)
3875                 if [[ -z ${2} ]] || (( ${#argv} > 2 )) ; then
3876                     printf 'usage: hl <syntax[:theme]> <file>\n'
3877                     printf '    available options: --list (-l), --themes (-t), --help (-h)\n'
3878                     (( ${#argv} > 2 )) && printf '  Too many arguments.\n'
3879                     return 1
3880                 fi
3881                 lang=${1%:*}
3882                 [[ ${1} == *:* ]] && [[ -n ${1#*:} ]] && theme=${1#*:}
3883                 if [[ -n ${theme} ]] ; then
3884                     highlight --xterm256 --syntax ${lang} --style ${theme} ${2} | less -SMr
3885                 else
3886                     highlight --ansi --syntax ${lang} ${2} | less -SMr
3887                 fi
3888                 ;;
3889         esac
3890         return 0
3891     }
3892     # ... and a proper completion for hl()
3893     # needs 'highlight' as well, so it fits fine in here.
3894     function _hl_genarg()  {
3895         local expl
3896         if [[ -prefix 1 *: ]] ; then
3897             local themes
3898             themes=(${${${(f)"$(LC_ALL=C highlight --list-themes)"}/ #/}:#*(Installed|Use name)*})
3899             compset -P 1 '*:'
3900             _wanted -C list themes expl theme compadd ${themes}
3901         else
3902             local langs
3903             langs=(${${${(f)"$(LC_ALL=C highlight --list-langs)"}/ #/}:#*(Installed|Use name)*})
3904             _wanted -C list languages expl languages compadd -S ':' -q ${langs}
3905         fi
3906     }
3907     function _hl_complete() {
3908         _arguments -s '1: :_hl_genarg' '2:files:_path_files'
3909     }
3910     compdef _hl_complete hl
3911 fi
3912
3913 # create small urls via tinyurl.com using wget, grep and sed
3914 zurl() {
3915     [[ -z ${1} ]] && print "please give an url to shrink." && return 1
3916     local url=${1}
3917     local tiny="http://tinyurl.com/create.php?url="
3918     #print "${tiny}${url}" ; return
3919     wget  -O-             \
3920           -o/dev/null     \
3921           "${tiny}${url}" \
3922         | grep -Eio 'value="(http://tinyurl.com/.*)"' \
3923         | sed 's/value=//;s/"//g'
3924 }
3925
3926 #f2# Print a specific line of file(s).
3927 linenr () {
3928 # {{{
3929     if [ $# -lt 2 ] ; then
3930        print "Usage: linenr <number>[,<number>] <file>" ; return 1
3931     elif [ $# -eq 2 ] ; then
3932          local number=$1
3933          local file=$2
3934          command ed -s $file <<< "${number}n"
3935     else
3936          local number=$1
3937          shift
3938          for file in "$@" ; do
3939              if [ ! -d $file ] ; then
3940                 echo "${file}:"
3941                 command ed -s $file <<< "${number}n" 2> /dev/null
3942              else
3943                 continue
3944              fi
3945          done | less
3946     fi
3947 # }}}
3948 }
3949
3950 #f2# Find history events by search pattern and list them by date.
3951 whatwhen()  {
3952 # {{{
3953     local usage help ident format_l format_s first_char remain first last
3954     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3955     help='Use' \`'whatwhen -h'\'' for further explanations.'
3956     ident=${(l,${#${:-Usage: }},, ,)}
3957     format_l="${ident}%s\t\t\t%s\n"
3958     format_s="${format_l//(\\t)##/\\t}"
3959     # Make the first char of the word to search for case
3960     # insensitive; e.g. [aA]
3961     first_char=[${(L)1[1]}${(U)1[1]}]
3962     remain=${1[2,-1]}
3963     # Default search range is `-100'.
3964     first=${2:-\-100}
3965     # Optional, just used for `<first> <last>' given.
3966     last=$3
3967     case $1 in
3968         ("")
3969             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3970             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3971         ;;
3972         (-h)
3973             printf '%s\n\n' ${usage}
3974             print 'OPTIONS:'
3975             printf $format_l '-h' 'show help text'
3976             print '\f'
3977             print 'SEARCH RANGE:'
3978             printf $format_l "'0'" 'the whole history,'
3979             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
3980             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
3981             printf '\n%s\n' 'EXAMPLES:'
3982             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
3983             printf $format_l 'whatwhen zsh -250'
3984             printf $format_l 'whatwhen foo 1 99'
3985         ;;
3986         (\?)
3987             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3988         ;;
3989         (*)
3990             # -l list results on stout rather than invoking $EDITOR.
3991             # -i Print dates as in YYYY-MM-DD.
3992             # -m Search for a - quoted - pattern within the history.
3993             fc -li -m "*${first_char}${remain}*" $first $last
3994         ;;
3995     esac
3996 # }}}
3997 }
3998
3999 # change fluxbox keys from 'Alt-#' to 'Alt-F#' and vice versa
4000 fluxkey-change() {
4001     [[ -n "$FLUXKEYS" ]] || local FLUXKEYS="$HOME/.fluxbox/keys"
4002     if ! [[ -r "$FLUXKEYS" ]] ; then
4003         echo "Sorry, \$FLUXKEYS file $FLUXKEYS could not be read - nothing to be done."
4004         return 1
4005     else
4006         if grep -q 'Mod1 F[0-9] :Workspace [0-9]' $FLUXKEYS ; then
4007             echo -n 'Switching to Alt-# mode in ~/.fluxbox/keys: '
4008             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)F\([0-9]\+[: space :]\+:Workspace.*\)|\1\2|' $FLUXKEYS && echo done || echo failed
4009         elif grep -q 'Mod1 [0-9] :Workspace [0-9]' $FLUXKEYS ; then
4010             echo -n 'Switching to Alt-F# mode in ~/.fluxbox/keys: '
4011             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)\([0-9]\+[: space :]\+:Workspace.*\)|\1F\2|' $FLUXKEYS && echo done || echo failed
4012         else
4013             echo 'Sorry, do not know what to do.'
4014             return 1
4015         fi
4016     fi
4017 }
4018
4019 # retrieve weather information on the console
4020 # Usage example: 'weather LOWG'
4021 weather() {
4022     [[ -n "$1" ]] || {
4023         print 'Usage: weather <station_id>' >&2
4024         print 'List of stations: http://en.wikipedia.org/wiki/List_of_airports_by_ICAO_code'>&2
4025         return 1
4026     }
4027
4028     local PLACE="${1:u}"
4029     local FILE="$HOME/.weather/$PLACE"
4030     local LOG="$HOME/.weather/log"
4031
4032     [[ -d $HOME/.weather ]] || {
4033         print -n "Creating $HOME/.weather: "
4034         mkdir $HOME/.weather
4035         print 'done'
4036     }
4037
4038     print "Retrieving information for ${PLACE}:"
4039     print
4040     wget -T 10 --no-verbose --output-file=$LOG --output-document=$FILE --timestamping http://weather.noaa.gov/pub/data/observations/metar/decoded/$PLACE.TXT
4041
4042     if [[ $? -eq 0 ]] ; then
4043         if [[ -n "$VERBOSE" ]] ; then
4044             cat $FILE
4045         else
4046             DATE=$(grep 'UTC' $FILE | sed 's#.* /##')
4047             TEMPERATURE=$(awk '/Temperature/ { print $4" degree Celcius / " $2" degree Fahrenheit" }' $FILE| tr -d '(')
4048             echo "date: $DATE"
4049             echo "temp:  $TEMPERATURE"
4050         fi
4051     else
4052         print "There was an error retrieving the weather information for $PLACE" >&2
4053         cat $LOG
4054         return 1
4055     fi
4056 }
4057 # }}}
4058
4059 # mercurial related stuff {{{
4060 if check_com -c hg ; then
4061     # gnu like diff for mercurial
4062     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
4063     #f5# GNU like diff for mercurial
4064     hgdi() {
4065         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
4066     }
4067
4068     # build debian package
4069     #a2# Alias for \kbd{hg-buildpackage}
4070     alias hbp='hg-buildpackage'
4071
4072     # execute commands on the versioned patch-queue from the current repos
4073     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
4074
4075     # diffstat for specific version of a mercurial repository
4076     #   hgstat      => display diffstat between last revision and tip
4077     #   hgstat 1234 => display diffstat between revision 1234 and tip
4078     #f5# Diffstat for specific version of a mercurial repos
4079     hgstat() {
4080         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
4081     }
4082
4083     #f5# Get current mercurial tip via hg itself
4084     gethgclone() {
4085         setopt local_options
4086         setopt errreturn
4087         if [[ -f mercurial-tree/.hg ]] ; then
4088             cd mercurial-tree
4089             echo "Running hg pull for retreiving latest version..."
4090             hg pull
4091             echo "Finished update. Building mercurial"
4092             make local
4093             echo "Setting \$PATH to $PWD:\$PATH..."
4094             export PATH="$PWD:$PATH"
4095         else
4096             echo "Downloading mercurial via hg"
4097             hg clone http://selenic.com/repo/hg mercurial-tree
4098             cd mercurial-tree
4099             echo "Building mercurial"
4100             make local
4101             echo "Setting \$PATH to $PWD:\$PATH..."
4102             export PATH="$PWD:$PATH"
4103             echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4104             # echo "Setting \$PYTHONPATH to PYTHONPATH=\${HOME}/lib/python,"
4105             # export PYTHONPATH=${HOME}/lib/python
4106         fi
4107     }
4108
4109 fi # end of check whether we have the 'hg'-executable
4110
4111 # get current mercurial snapshot
4112 #f5# Get current mercurial snapshot
4113 gethgsnap() {
4114     setopt local_options
4115     setopt errreturn
4116     if [[ -f mercurial-snapshot.tar.gz ]] ; then
4117          echo "mercurial-snapshot.tar.gz exists already, skipping download."
4118     else
4119         echo "Downloading mercurial snapshot"
4120         wget http://www.selenic.com/mercurial/mercurial-snapshot.tar.gz
4121     fi
4122     echo "Unpacking mercurial-snapshot.tar.gz"
4123     tar zxf mercurial-snapshot.tar.gz
4124     cd mercurial-snapshot/
4125     echo "Installing required build-dependencies"
4126     $SUDO apt-get update
4127     $SUDO apt-get install python2.4-dev
4128     echo "Building mercurial"
4129     make local
4130     echo "Setting \$PATH to $PWD:\$PATH..."
4131     export PATH="$PWD:$PATH"
4132     echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4133 }
4134 # }}}
4135
4136 # some useful commands often hard to remember - let's grep for them {{{
4137 # actually use our zg() function now. :)
4138
4139 # Work around ion/xterm resize bug.
4140 #if [[ "$SHLVL" -eq 1 ]]; then
4141 #       if check_com -c resize ; then
4142 #               eval `resize </dev/null`
4143 #       fi
4144 #fi
4145
4146 # enable jackd:
4147 #  /usr/bin/jackd -dalsa -dhw:0 -r48000 -p1024 -n2
4148 # now play audio file:
4149 #  alsaplayer -o jack foobar.mp3
4150
4151 # send files via netcat
4152 # on sending side:
4153 #  send() {j=$*; tar cpz ${j/%${!#}/}|nc -w 1 ${!#} 51330;}
4154 #  send dir* $HOST
4155 #  alias receive='nc -vlp 51330 | tar xzvp'
4156
4157 # debian stuff:
4158 # dh_make -e foo@localhost -f $1
4159 # dpkg-buildpackage -rfakeroot
4160 # lintian *.deb
4161 # dpkg-scanpackages ./ /dev/null | gzip > Packages.gz
4162 # dpkg-scansources . | gzip > Sources.gz
4163 # grep-dctrl --field Maintainer $* /var/lib/apt/lists/*
4164
4165 # other stuff:
4166 # convert -geometry 200x200 -interlace LINE -verbose
4167 # ldapsearch -x -b "OU=Bedienstete,O=tug" -h ldap.tugraz.at sn=$1
4168 # ps -ao user,pcpu,start,command
4169 # gpg --keyserver blackhole.pca.dfn.de --recv-keys
4170 # xterm -bg black -fg yellow -fn -misc-fixed-medium-r-normal--14-140-75-75-c-90-iso8859-15 -ah
4171 # nc -vz $1 1-1024   # portscan via netcat
4172 # wget --mirror --no-parent --convert-links
4173 # pal -d `date +%d`
4174 # autoload -U tetris; zle -N tetris; bindkey '...' ; echo "press ... for playing tennis"
4175 #
4176 # modify console cursor
4177 # see http://www.tldp.org/HOWTO/Framebuffer-HOWTO-5.html
4178 # print $'\e[?96;0;64c'
4179 # }}}
4180
4181 # grml-small cleanups {{{
4182
4183 # The following is used to remove zsh-config-items that do not work
4184 # in grml-small by default.
4185 # If you do not want these adjustments (for whatever reason), set
4186 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
4187 # sources if it is there).
4188
4189 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
4190
4191     unset abk[V]
4192     unalias    'V'      &> /dev/null
4193     unfunction vman     &> /dev/null
4194     unfunction vimpm    &> /dev/null
4195     unfunction vimhelp  &> /dev/null
4196     unfunction viless   &> /dev/null
4197     unfunction 2html    &> /dev/null
4198
4199     # manpages are not in grmlsmall
4200     unfunction manzsh   &> /dev/null
4201     unalias    man2     &> /dev/null
4202     unalias    man      &> /dev/null
4203     unfunction man2     &> /dev/null
4204
4205 fi
4206
4207 #}}}
4208
4209 # finally source a local zshrc {{{
4210
4211 # this allows us to stay in sync with grml's zshrc and put own
4212 # modifications in ~/.zshrc.local
4213
4214 xsource "${HOME}/.zshrc.local"
4215
4216 # }}}
4217
4218 ## genrefcard.pl settings {{{
4219
4220 ### doc strings for external functions from files
4221 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
4222
4223 ### example: split functions-search 8,16,24,32
4224 #@# split functions-search 8
4225
4226 ## }}}
4227
4228 ## END OF FILE #################################################################
4229 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4