etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* || $ZSH_VERSION == <5->* ]] && return 0
 143     return 1
 144 }
 145
 146 is439(){
 147     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* || $ZSH_VERSION == <5->* ]] && return 0
 148     return 1
 149 }
 150
 151 #f1# Checks whether or not you're running grml
 152 isgrml(){
 153     [[ -f /etc/grml_version ]] && return 0
 154     return 1
 155 }
 156
 157 #f1# Checks whether or not you're running a grml cd
 158 isgrmlcd(){
 159     [[ -f /etc/grml_cd ]] && return 0
 160     return 1
 161 }
 162
 163 if isgrml ; then
 164 #f1# Checks whether or not you're running grml-small
 165     isgrmlsmall() {
 166         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 167     }
 168 else
 169     isgrmlsmall() { return 1 }
 170 fi
 171
 172 isdarwin(){
 173     [[ $OSTYPE == darwin* ]] && return 0
 174     return 1
 175 }
 176
 177 #f1# are we running within an utf environment?
 178 isutfenv() {
 179     case "$LANG $CHARSET $LANGUAGE" in
 180         *utf*) return 0 ;;
 181         *UTF*) return 0 ;;
 182         *)     return 1 ;;
 183     esac
 184 }
 185
 186 # check for user, if not running as root set $SUDO to sudo
 187 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 188
 189 # change directory to home on first invocation of zsh
 190 # important for rungetty -> autologin
 191 # Thanks go to Bart Schaefer!
 192 isgrml && checkhome() {
 193     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 194         export ALREADY_DID_CD_HOME=$HOME
 195         cd
 196     fi
 197 }
 198
 199 # check for zsh v3.1.7+
 200
 201 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 202      || ${ZSH_VERSION} == 3.<2->.<->*    \
 203      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 204
 205     printf '-!-\n'
 206     printf '-!- In this configuration we try to make use of features, that only\n'
 207     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 208     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 209     printf '-!- advanced features in all supported versions.\n'
 210     printf '-!-\n'
 211     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 212     printf '-!-\n'
 213     printf '-!- While this *may* work, it might as well fail.\n'
 214     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 215     printf '-!-\n'
 216     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 217     printf '-!- If it does today, you'\''ve been lucky.\n'
 218     printf '-!-\n'
 219     printf '-!- Ye been warned!\n'
 220     printf '-!-\n'
 221
 222     function zstyle() { : }
 223 fi
 224
 225 # autoload wrapper - use this one instead of autoload directly
 226 # We need to define this function as early as this, because autoloading
 227 # 'is-at-least()' needs it.
 228 function zrcautoload() {
 229     emulate -L zsh
 230     setopt extended_glob
 231     local fdir ffile
 232     local -i ffound
 233
 234     ffile=$1
 235     (( found = 0 ))
 236     for fdir in ${fpath} ; do
 237         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 238     done
 239
 240     (( ffound == 0 )) && return 1
 241     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 242         autoload -U ${ffile} || return 1
 243     else
 244         autoload ${ffile} || return 1
 245     fi
 246     return 0
 247 }
 248
 249 # Load is-at-least() for more precise version checks
 250 # Note that this test will *always* fail, if the is-at-least
 251 # function could not be marked for autoloading.
 252 zrcautoload is-at-least || is-at-least() { return 1 }
 253
 254 # set some important options (as early as possible)
 255 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 256 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 257 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 258 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 259                             # list duplicates an older one, the older command is removed from the list
 260 setopt histignorespace      # remove command lines from the history list when
 261                             # the first character on the line is a space
 262 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 263                             # and the command is the name of a directory, perform the cd command to that directory
 264 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 265                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 266                             # -> searches for word not in compressed files
 267                             # don't forget to quote '^', '~' and '#'!
 268 setopt longlistjobs         # display PID when suspending processes as well
 269 setopt notify               # report the status of backgrounds jobs immediately
 270 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 271                             # the entire command path is hashed first.
 272 setopt completeinword       # not just at the end
 273 setopt nohup                # and don't kill them, either
 274 setopt auto_pushd           # make cd push the old directory onto the directory stack.
 275 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 276 setopt nobeep               # avoid "beep"ing
 277 setopt pushd_ignore_dups    # don't push the same dir twice.
 278 setopt noglobdots           # * shouldn't match dotfiles. ever.
 279 setopt noshwordsplit        # use zsh style word splitting
 280 setopt unset                # don't error out when unset parameters are used
 281
 282 # setting some default values
 283
 284 NOCOR=${NOCOR:-0}
 285 NOMENU=${NOMENU:-0}
 286 NOPRECMD=${NOPRECMD:-0}
 287 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 288 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 289 BATTERY=${BATTERY:-0}
 290 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 291 GRML_ALWAYS_LOAD_ALL=${GRML_ALWAYS_LOAD_ALL:-0}
 292 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 293
 294 # utility functions
 295 # this function checks if a command exists and returns either true
 296 # or false. This avoids using 'which' and 'whence', which will
 297 # avoid problems with aliases for which on certain weird systems. :-)
 298 # Usage: check_com [-c|-g] word
 299 #   -c  only checks for external commands
 300 #   -g  does the usual tests and also checks for global aliases
 301 check_com() {
 302     emulate -L zsh
 303     local -i comonly gatoo
 304
 305     if [[ $1 == '-c' ]] ; then
 306         (( comonly = 1 ))
 307         shift
 308     elif [[ $1 == '-g' ]] ; then
 309         (( gatoo = 1 ))
 310     else
 311         (( comonly = 0 ))
 312         (( gatoo = 0 ))
 313     fi
 314
 315     if (( ${#argv} != 1 )) ; then
 316         printf 'usage: check_com [-c] <command>\n' >&2
 317         return 1
 318     fi
 319
 320     if (( comonly > 0 )) ; then
 321         [[ -n ${commands[$1]}  ]] && return 0
 322         return 1
 323     fi
 324
 325     if   [[ -n ${commands[$1]}    ]] \
 326       || [[ -n ${functions[$1]}   ]] \
 327       || [[ -n ${aliases[$1]}     ]] \
 328       || [[ -n ${reswords[(r)$1]} ]] ; then
 329
 330         return 0
 331     fi
 332
 333     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 334         return 0
 335     fi
 336
 337     return 1
 338 }
 339
 340 # creates an alias and precedes the command with
 341 # sudo if $EUID is not zero.
 342 salias() {
 343     emulate -L zsh
 344     local only=0 ; local multi=0
 345     while [[ $1 == -* ]] ; do
 346         case $1 in
 347             (-o) only=1 ;;
 348             (-a) multi=1 ;;
 349             (--) shift ; break ;;
 350             (-h)
 351                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 352                 printf '  -h      shows this help text.\n'
 353                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 354                 printf '          be careful using this option.\n'
 355                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 356                 return 0
 357                 ;;
 358             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 359         esac
 360         shift
 361     done
 362
 363     if (( ${#argv} > 1 )) ; then
 364         printf 'Too many arguments %s\n' "${#argv}"
 365         return 1
 366     fi
 367
 368     key="${1%%\=*}" ;  val="${1#*\=}"
 369     if (( EUID == 0 )) && (( only == 0 )); then
 370         alias -- "${key}=${val}"
 371     elif (( EUID > 0 )) ; then
 372         (( multi > 0 )) && val="${val// ; / ; sudo }"
 373         alias -- "${key}=sudo ${val}"
 374     fi
 375
 376     return 0
 377 }
 378
 379 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 380 # usage: uprint foo
 381 #   Where foo is the *name* of the parameter you want printed.
 382 #   Note that foo is no typo; $foo would be wrong here!
 383 if ! is42 ; then
 384     uprint () {
 385         emulate -L zsh
 386         local -a u
 387         local w
 388         local parameter=$1
 389
 390         if [[ -z ${parameter} ]] ; then
 391             printf 'usage: uprint <parameter>\n'
 392             return 1
 393         fi
 394
 395         for w in ${(P)parameter} ; do
 396             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 397         done
 398
 399         builtin print -l $u
 400     }
 401 fi
 402
 403 # Check if we can read given files and source those we can.
 404 xsource() {
 405     if (( ${#argv} < 1 )) ; then
 406         printf 'usage: xsource FILE(s)...\n' >&2
 407         return 1
 408     fi
 409
 410     while (( ${#argv} > 0 )) ; do
 411         [[ -r "$1" ]] && source "$1"
 412         shift
 413     done
 414     return 0
 415 }
 416
 417 # Check if we can read a given file and 'cat(1)' it.
 418 xcat() {
 419     emulate -L zsh
 420     if (( ${#argv} != 1 )) ; then
 421         printf 'usage: xcat FILE\n' >&2
 422         return 1
 423     fi
 424
 425     [[ -r $1 ]] && cat $1
 426     return 0
 427 }
 428
 429 # Remove these functions again, they are of use only in these
 430 # setup files. This should be called at the end of .zshrc.
 431 xunfunction() {
 432     emulate -L zsh
 433     local -a funcs
 434     funcs=(salias xcat xsource xunfunction zrcautoload)
 435
 436     for func in $funcs ; do
 437         [[ -n ${functions[$func]} ]] \
 438             && unfunction $func
 439     done
 440     return 0
 441 }
 442
 443 # this allows us to stay in sync with grml's zshrc and put own
 444 # modifications in ~/.zshrc.local
 445 zrclocal() {
 446     xsource "/etc/zsh/zshrc.local"
 447     xsource "${HOME}/.zshrc.local"
 448     return 0
 449 }
 450
 451 # locale setup
 452 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 453     xsource "/etc/default/locale"
 454 fi
 455
 456 for var in LANG LC_ALL LC_MESSAGES ; do
 457     [[ -n ${(P)var} ]] && export $var
 458 done
 459
 460 xsource "/etc/sysconfig/keyboard"
 461
 462 TZ=$(xcat /etc/timezone)
 463
 464 # set some variables
 465 if check_com -c vim ; then
 466 #v#
 467     export EDITOR=${EDITOR:-vim}
 468 else
 469     export EDITOR=${EDITOR:-vi}
 470 fi
 471
 472 #v#
 473 export PAGER=${PAGER:-less}
 474
 475 #v#
 476 export MAIL=${MAIL:-/var/mail/$USER}
 477
 478 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 479 export SHELL='/bin/zsh'
 480
 481 # color setup for ls:
 482 check_com -c dircolors && eval $(dircolors -b)
 483 # color setup for ls on OS X:
 484 isdarwin && export CLICOLOR=1
 485
 486 # do MacPorts setup on darwin
 487 if isdarwin && [[ -d /opt/local ]]; then
 488     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 489     # zshenv.
 490     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 491     MANPATH="/opt/local/share/man:$MANPATH"
 492 fi
 493 # do Fink setup on darwin
 494 isdarwin && xsource /sw/bin/init.sh
 495
 496 # load our function and completion directories
 497 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 498     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 499     if [[ ${fpath} == '/usr/share/grml/zsh/functions' ]] ; then
 500         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 501             zrcautoload ${func:t}
 502         done
 503     fi
 504 done
 505 unset fdir func
 506
 507 # support colors in less
 508 export LESS_TERMCAP_mb=$'\E[01;31m'
 509 export LESS_TERMCAP_md=$'\E[01;31m'
 510 export LESS_TERMCAP_me=$'\E[0m'
 511 export LESS_TERMCAP_se=$'\E[0m'
 512 export LESS_TERMCAP_so=$'\E[01;44;33m'
 513 export LESS_TERMCAP_ue=$'\E[0m'
 514 export LESS_TERMCAP_us=$'\E[01;32m'
 515
 516 MAILCHECK=30       # mailchecks
 517 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 518 watch=(notme root) # watch for everyone but me and root
 519
 520 # automatically remove duplicates from these arrays
 521 typeset -U path cdpath fpath manpath
 522
 523 # keybindings
 524 if [[ "$TERM" != emacs ]] ; then
 525     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 526     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 527     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 528     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 529     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 530     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 531     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 532     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 533     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 534     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 535     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 536     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 537     # ncurses stuff:
 538     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 539     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 540     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 541     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 542     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 543     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 544     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 545     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 546 fi
 547
 548 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 549 # use emacs style per default:
 550 bindkey -e
 551 # use vi style:
 552 # bindkey -v
 553
 554 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 555 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 556 beginning-or-end-of-somewhere() {
 557     local hno=$HISTNO
 558     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 559       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 560         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 561     else
 562         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 563         if (( HISTNO != hno )); then
 564             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 565         fi
 566     fi
 567 }
 568 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 569 zle -N end-of-somewhere beginning-or-end-of-somewhere
 570
 571
 572 #if [[ "$TERM" == screen ]] ; then
 573
 574 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 575 ## to beginning/end of buffer on second keypress
 576 ## and to beginning/end of history on (at most) the third keypress
 577 # terminator & non-debian xterm
 578 bindkey '\eOH' beginning-of-somewhere  # home
 579 bindkey '\eOF' end-of-somewhere        # end
 580 # freebsd console
 581 bindkey '\e[H' beginning-of-somewhere   # home
 582 bindkey '\e[F' end-of-somewhere         # end
 583 # xterm,gnome-terminal,quake,etc
 584 bindkey '^[[1~' beginning-of-somewhere  # home
 585 bindkey '^[[4~' end-of-somewhere        # end
 586 # if terminal type is set to 'rxvt':
 587 bindkey '\e[7~' beginning-of-somewhere  # home
 588 bindkey '\e[8~' end-of-somewhere        # end
 589 #fi
 590
 591 bindkey '\e[A'  up-line-or-search       # cursor up
 592 bindkey '\e[B'  down-line-or-search     # <ESC>-
 593
 594 ## alt-backspace is already the default for backwards-delete-word
 595 ## let's also set alt-delete for deleting current word (right of cursor)
 596 #k# Kill right-side word
 597 bindkey '^[[3~'   delete-word # Modeswitch
 598 bindkey '^[[3;3~' delete-word # Alt_L
 599
 600 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 601 bindkey "\e[5C" forward-word
 602 bindkey "\e[5D" backward-word
 603 bindkey "\e[1;5C" forward-word
 604 bindkey "\e[1;5D" backward-word
 605 ## the same for alt-left-arrow and alt-right-arrow
 606 bindkey '^[[1;3C' forward-word
 607 bindkey '^[[1;3D' backward-word
 608
 609 # Search backward in the history for a line beginning with the current
 610 # line up to the cursor and move the cursor to the end of the line then
 611 zle -N history-beginning-search-backward-end history-search-end
 612 zle -N history-beginning-search-forward-end  history-search-end
 613 #k# search history backward for entry beginning with typed text
 614 bindkey '^xp'   history-beginning-search-backward-end
 615 #k# search history forward for entry beginning with typed text
 616 bindkey '^xP'   history-beginning-search-forward-end
 617 #k# search history backward for entry beginning with typed text
 618 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 619 #k# search history forward for entry beginning with typed text
 620 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 621
 622 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 623 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 624
 625 # insert unicode character
 626 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 627 # See for example http://unicode.org/charts/ for unicode characters code
 628 zrcautoload insert-unicode-char
 629 zle -N insert-unicode-char
 630 #k# Insert Unicode character
 631 bindkey '^Xi' insert-unicode-char
 632
 633 #m# k Shift-tab Perform backwards menu completion
 634 if [[ -n "$terminfo[kcbt]" ]]; then
 635     bindkey "$terminfo[kcbt]" reverse-menu-complete
 636 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 637     bindkey "$terminfo[cbt]"  reverse-menu-complete
 638 fi
 639
 640 ## toggle the ,. abbreviation feature on/off
 641 # NOABBREVIATION: default abbreviation-state
 642 #                 0 - enabled (default)
 643 #                 1 - disabled
 644 NOABBREVIATION=${NOABBREVIATION:-0}
 645
 646 grml_toggle_abbrev() {
 647     if (( ${NOABBREVIATION} > 0 )) ; then
 648         NOABBREVIATION=0
 649     else
 650         NOABBREVIATION=1
 651     fi
 652 }
 653
 654 zle -N grml_toggle_abbrev
 655 bindkey '^xA' grml_toggle_abbrev
 656
 657 # add a command line to the shells history without executing it
 658 commit-to-history() {
 659     print -s ${(z)BUFFER}
 660     zle send-break
 661 }
 662 zle -N commit-to-history
 663 bindkey "^x^h" commit-to-history
 664
 665 # only slash should be considered as a word separator:
 666 slash-backward-kill-word() {
 667     local WORDCHARS="${WORDCHARS:s@/@}"
 668     # zle backward-word
 669     zle backward-kill-word
 670 }
 671 zle -N slash-backward-kill-word
 672
 673 #k# Kill left-side word or everything up to next slash
 674 bindkey '\ev' slash-backward-kill-word
 675 #k# Kill left-side word or everything up to next slash
 676 bindkey '\e^h' slash-backward-kill-word
 677 #k# Kill left-side word or everything up to next slash
 678 bindkey '\e^?' slash-backward-kill-word
 679
 680 # use the new *-pattern-* widgets for incremental history search
 681 if is439 ; then
 682     bindkey '^r' history-incremental-pattern-search-backward
 683     bindkey '^s' history-incremental-pattern-search-forward
 684 fi
 685
 686 # a generic accept-line wrapper
 687
 688 # This widget can prevent unwanted autocorrections from command-name
 689 # to _command-name, rehash automatically on enter and call any number
 690 # of builtin and user-defined widgets in different contexts.
 691 #
 692 # For a broader description, see:
 693 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 694 #
 695 # The code is imported from the file 'zsh/functions/accept-line' from
 696 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 697 # distributed under the same terms as zsh itself.
 698
 699 # A newly added command will may not be found or will cause false
 700 # correction attempts, if you got auto-correction set. By setting the
 701 # following style, we force accept-line() to rehash, if it cannot
 702 # find the first word on the command line in the $command[] hash.
 703 zstyle ':acceptline:*' rehash true
 704
 705 function Accept-Line() {
 706     setopt localoptions noksharrays
 707     local -a subs
 708     local -xi aldone
 709     local sub
 710     local alcontext=${1:-$alcontext}
 711
 712     zstyle -a ":acceptline:${alcontext}" actions subs
 713
 714     (( ${#subs} < 1 )) && return 0
 715
 716     (( aldone = 0 ))
 717     for sub in ${subs} ; do
 718         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 719         zle ${sub}
 720
 721         (( aldone > 0 )) && break
 722     done
 723 }
 724
 725 function Accept-Line-getdefault() {
 726     emulate -L zsh
 727     local default_action
 728
 729     zstyle -s ":acceptline:${alcontext}" default_action default_action
 730     case ${default_action} in
 731         ((accept-line|))
 732             printf ".accept-line"
 733             ;;
 734         (*)
 735             printf ${default_action}
 736             ;;
 737     esac
 738 }
 739
 740 function Accept-Line-HandleContext() {
 741     zle Accept-Line
 742
 743     default_action=$(Accept-Line-getdefault)
 744     zstyle -T ":acceptline:${alcontext}" call_default \
 745         && zle ${default_action}
 746 }
 747
 748 function accept-line() {
 749     setopt localoptions noksharrays
 750     local -ax cmdline
 751     local -x alcontext
 752     local buf com fname format msg default_action
 753
 754     alcontext='default'
 755     buf="${BUFFER}"
 756     cmdline=(${(z)BUFFER})
 757     com="${cmdline[1]}"
 758     fname="_${com}"
 759
 760     Accept-Line 'preprocess'
 761
 762     zstyle -t ":acceptline:${alcontext}" rehash \
 763         && [[ -z ${commands[$com]} ]]           \
 764         && rehash
 765
 766     if    [[ -n ${com}               ]] \
 767        && [[ -n ${reswords[(r)$com]} ]] \
 768        || [[ -n ${aliases[$com]}     ]] \
 769        || [[ -n ${functions[$com]}   ]] \
 770        || [[ -n ${builtins[$com]}    ]] \
 771        || [[ -n ${commands[$com]}    ]] ; then
 772
 773         # there is something sensible to execute, just do it.
 774         alcontext='normal'
 775         Accept-Line-HandleContext
 776
 777         return
 778     fi
 779
 780     if    [[ -o correct              ]] \
 781        || [[ -o correctall           ]] \
 782        && [[ -n ${functions[$fname]} ]] ; then
 783
 784         # nothing there to execute but there is a function called
 785         # _command_name; a completion widget. Makes no sense to
 786         # call it on the commandline, but the correct{,all} options
 787         # will ask for it nevertheless, so warn the user.
 788         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 789             # Okay, we warned the user before, he called us again,
 790             # so have it his way.
 791             alcontext='force'
 792             Accept-Line-HandleContext
 793
 794             return
 795         fi
 796
 797         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 798             alcontext='normal'
 799             Accept-Line-HandleContext
 800         else
 801             # prepare warning message for the user, configurable via zstyle.
 802             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 803
 804             if [[ -z ${msg} ]] ; then
 805                 msg="%c will not execute and completion %f exists."
 806             fi
 807
 808             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 809
 810             zle -M -- "${msg}"
 811         fi
 812         return
 813     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 814         # If we are here, the commandline contains something that is not
 815         # executable, which is neither subject to _command_name correction
 816         # and is not empty. might be a variable assignment
 817         alcontext='misc'
 818         Accept-Line-HandleContext
 819
 820         return
 821     fi
 822
 823     # If we got this far, the commandline only contains whitespace, or is empty.
 824     alcontext='empty'
 825     Accept-Line-HandleContext
 826 }
 827
 828 zle -N accept-line
 829 zle -N Accept-Line
 830 zle -N Accept-Line-HandleContext
 831
 832 # power completion - abbreviation expansion
 833 # power completion / abbreviation expansion / buffer expansion
 834 # see http://zshwiki.org/home/examples/zleiab for details
 835 # less risky than the global aliases but powerful as well
 836 # just type the abbreviation key and afterwards ',.' to expand it
 837 declare -A abk
 838 setopt extendedglob
 839 setopt interactivecomments
 840 abk=(
 841 #   key   # value                  (#d additional doc string)
 842 #A# start
 843     '...'  '../..'
 844     '....' '../../..'
 845     'BG'   '& exit'
 846     'C'    '| wc -l'
 847     'G'    '|& grep --color=auto '
 848     'H'    '| head'
 849     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 850     'L'    '| less'
 851     'LL'   '|& less -r'
 852     'M'    '| most'
 853     'N'    '&>/dev/null'           #d (No Output)
 854     'R'    '| tr A-z N-za-m'       #d (ROT13)
 855     'SL'   '| sort | less'
 856     'S'    '| sort -u'
 857     'T'    '| tail'
 858     'V'    '|& vim -'
 859 #A# end
 860     'co'   './configure && make && sudo make install'
 861 )
 862
 863 zleiab() {
 864     emulate -L zsh
 865     setopt extendedglob
 866     local MATCH
 867
 868     if (( NOABBREVIATION > 0 )) ; then
 869         LBUFFER="${LBUFFER},."
 870         return 0
 871     fi
 872
 873     matched_chars='[.-|_a-zA-Z0-9]#'
 874     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 875     LBUFFER+=${abk[$MATCH]:-$MATCH}
 876 }
 877
 878 zle -N zleiab
 879 bindkey ",." zleiab
 880
 881 # autoloading
 882 zrcautoload zmv    # who needs mmv or rename?
 883 zrcautoload history-search-end
 884
 885 # we don't want to quote/espace URLs on our own...
 886 # if autoload -U url-quote-magic ; then
 887 #    zle -N self-insert url-quote-magic
 888 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 889 # else
 890 #    print 'Notice: no url-quote-magic available :('
 891 # fi
 892 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 893
 894 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 895 alias run-help >&/dev/null && unalias run-help
 896 for rh in run-help{,-git,-svk,-svn}; do
 897     zrcautoload $rh
 898 done; unset rh
 899
 900 # completion system
 901 if zrcautoload compinit ; then
 902     compinit || print 'Notice: no compinit available :('
 903 else
 904     print 'Notice: no compinit available :('
 905     function zstyle { }
 906     function compdef { }
 907 fi
 908
 909 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 910
 911 is4 && \
 912 for mod in complist deltochar mathfunc ; do
 913     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 914 done
 915
 916 # autoload zsh modules when they are referenced
 917 if is4 ; then
 918     zmodload -a  zsh/stat    zstat
 919     zmodload -a  zsh/zpty    zpty
 920     zmodload -ap zsh/mapfile mapfile
 921 fi
 922
 923 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 924     #k# Insert files and test globbing
 925     bindkey "^Xf" insert-files # C-x-f
 926 fi
 927
 928 bindkey ' '   magic-space    # also do history expansion on space
 929 #k# Trigger menu-complete
 930 bindkey '\ei' menu-complete  # menu completion via esc-i
 931
 932 # press esc-e for editing command line in $EDITOR or $VISUAL
 933 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 934     #k# Edit the current line in \kbd{\$EDITOR}
 935     bindkey '\ee' edit-command-line
 936 fi
 937
 938 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 939     #k# menu selection: pick item but stay in the menu
 940     bindkey -M menuselect '\e^M' accept-and-menu-complete
 941     # also use + and INSERT since it's easier to press repeatedly
 942     bindkey -M menuselect "+" accept-and-menu-complete
 943     bindkey -M menuselect "^[[2~" accept-and-menu-complete
 944
 945     # accept a completion and try to complete again by using menu
 946     # completion; very useful with completing directories
 947     # by using 'undo' one's got a simple file browser
 948     bindkey -M menuselect '^o' accept-and-infer-next-history
 949 fi
 950
 951 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 952 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
 953 zle -N insert-datestamp
 954
 955 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 956 bindkey '^Ed' insert-datestamp
 957
 958 # press esc-m for inserting last typed word again (thanks to caphuso!)
 959 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 960 zle -N insert-last-typed-word;
 961
 962 #k# Insert last typed word
 963 bindkey "\em" insert-last-typed-word
 964
 965 function grml-zsh-fg() {
 966   if (( ${#jobstates} )); then
 967     zle .push-input
 968     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
 969     BUFFER="${BUFFER}fg"
 970     zle .accept-line
 971   else
 972     zle -M 'No background jobs. Doing nothing.'
 973   fi
 974 }
 975 zle -N grml-zsh-fg
 976 #k# A smart shortcut for \kbd{fg<enter>}
 977 bindkey '^z' grml-zsh-fg
 978
 979 # run command line as user root via sudo:
 980 sudo-command-line() {
 981     [[ -z $BUFFER ]] && zle up-history
 982     if [[ $BUFFER != sudo\ * ]]; then
 983         BUFFER="sudo $BUFFER"
 984         CURSOR=$(( CURSOR+5 ))
 985     fi
 986 }
 987 zle -N sudo-command-line
 988
 989 #k# prepend the current command with "sudo"
 990 bindkey "^Os" sudo-command-line
 991
 992 ### jump behind the first word on the cmdline.
 993 ### useful to add options.
 994 function jump_after_first_word() {
 995     local words
 996     words=(${(z)BUFFER})
 997
 998     if (( ${#words} <= 1 )) ; then
 999         CURSOR=${#BUFFER}
1000     else
1001         CURSOR=${#${words[1]}}
1002     fi
1003 }
1004 zle -N jump_after_first_word
1005 #k# jump to after first word (for adding options)
1006 bindkey '^x1' jump_after_first_word
1007
1008 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1009 zle -C hist-complete complete-word _generic
1010 zstyle ':completion:hist-complete:*' completer _history
1011 #k# complete word from history with menu
1012 bindkey "^X^X" hist-complete
1013
1014 ## complete word from currently visible Screen or Tmux buffer.
1015 if check_com -c screen || check_com -c tmux; then
1016     _complete_screen_display() {
1017         [[ "$TERM" != "screen" ]] && return 1
1018
1019         local TMPFILE=$(mktemp)
1020         local -U -a _screen_display_wordlist
1021         trap "rm -f $TMPFILE" EXIT
1022
1023         # fill array with contents from screen hardcopy
1024         if ((${+TMUX})); then
1025             #works, but crashes tmux below version 1.4
1026             #luckily tmux -V option to ask for version, was also added in 1.4
1027             tmux -V &>/dev/null || return
1028             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1029         else
1030             screen -X hardcopy $TMPFILE
1031             #screen sucks, it dumps in latin1, apparently always. so recode it to system charset
1032             check_com recode && recode latin1 $TMPFILE
1033         fi
1034         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1035         # remove PREFIX to be completed from that array
1036         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1037         compadd -a _screen_display_wordlist
1038     }
1039     #k# complete word from currently visible GNU screen buffer
1040     bindkey -r "^XS"
1041     compdef -k _complete_screen_display complete-word '^XS'
1042 fi
1043
1044 # history
1045
1046 ZSHDIR=$HOME/.zsh
1047
1048 #v#
1049 HISTFILE=$HOME/.zsh_history
1050 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1051 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1052
1053 # dirstack handling
1054
1055 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1056 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1057
1058 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1059     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1060     # "cd -" won't work after login by just setting $OLDPWD, so
1061     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1062 fi
1063
1064 chpwd() {
1065     local -ax my_stack
1066     my_stack=( ${PWD} ${dirstack} )
1067     if is42 ; then
1068         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1069     else
1070         uprint my_stack >! ${DIRSTACKFILE}
1071     fi
1072 }
1073
1074 # directory based profiles
1075
1076 if is433 ; then
1077
1078 CHPWD_PROFILE='default'
1079 function chpwd_profiles() {
1080     # Say you want certain settings to be active in certain directories.
1081     # This is what you want.
1082     #
1083     # zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1084     # zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1085     #
1086     # When that's done and you enter a directory that matches the pattern
1087     # in the third part of the context, a function called chpwd_profile_grml,
1088     # for example, is called (if it exists).
1089     #
1090     # If no pattern matches (read: no profile is detected) the profile is
1091     # set to 'default', which means chpwd_profile_default is attempted to
1092     # be called.
1093     #
1094     # A word about the context (the ':chpwd:profiles:*' stuff in the zstyle
1095     # command) which is used: The third part in the context is matched against
1096     # ${PWD}. That's why using a pattern such as /foo/bar(|/|/*) makes sense.
1097     # Because that way the profile is detected for all these values of ${PWD}:
1098     #   /foo/bar
1099     #   /foo/bar/
1100     #   /foo/bar/baz
1101     # So, if you want to make double damn sure a profile works in /foo/bar
1102     # and everywhere deeper in that tree, just use (|/|/*) and be happy.
1103     #
1104     # The name of the detected profile will be available in a variable called
1105     # 'profile' in your functions. You don't need to do anything, it'll just
1106     # be there.
1107     #
1108     # Then there is the parameter $CHPWD_PROFILE is set to the profile, that
1109     # was is currently active. That way you can avoid running code for a
1110     # profile that is already active, by running code such as the following
1111     # at the start of your function:
1112     #
1113     # function chpwd_profile_grml() {
1114     #     [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1115     #   ...
1116     # }
1117     #
1118     # The initial value for $CHPWD_PROFILE is 'default'.
1119     #
1120     # Version requirement:
1121     #   This feature requires zsh 4.3.3 or newer.
1122     #   If you use this feature and need to know whether it is active in your
1123     #   current shell, there are several ways to do that. Here are two simple
1124     #   ways:
1125     #
1126     #   a) If knowing if the profiles feature is active when zsh starts is
1127     #      good enough for you, you can put the following snippet into your
1128     #      .zshrc.local:
1129     #
1130     #   (( ${+functions[chpwd_profiles]} )) && print "directory profiles active"
1131     #
1132     #   b) If that is not good enough, and you would prefer to be notified
1133     #      whenever a profile changes, you can solve that by making sure you
1134     #      start *every* profile function you create like this:
1135     #
1136     #   function chpwd_profile_myprofilename() {
1137     #       [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1138     #       print "chpwd(): Switching to profile: $profile"
1139     #     ...
1140     #   }
1141     #
1142     #      That makes sure you only get notified if a profile is *changed*,
1143     #      not everytime you change directory, which would probably piss
1144     #      you off fairly quickly. :-)
1145     #
1146     # There you go. Now have fun with that.
1147     local -x profile
1148
1149     zstyle -s ":chpwd:profiles:${PWD}" profile profile || profile='default'
1150     if (( ${+functions[chpwd_profile_$profile]} )) ; then
1151         chpwd_profile_${profile}
1152     fi
1153
1154     CHPWD_PROFILE="${profile}"
1155     return 0
1156 }
1157 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1158
1159 fi # is433
1160
1161 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1162 if [[ $BATTERY -gt 0 ]] ; then
1163     if ! check_com -c acpi ; then
1164         BATTERY=0
1165     fi
1166 fi
1167
1168 battery() {
1169 if [[ $BATTERY -gt 0 ]] ; then
1170     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1171     if [[ -z "$PERCENT" ]] ; then
1172         PERCENT='acpi not present'
1173     else
1174         if [[ "$PERCENT" -lt 20 ]] ; then
1175             PERCENT="warning: ${PERCENT}%%"
1176         else
1177             PERCENT="${PERCENT}%%"
1178         fi
1179     fi
1180 fi
1181 }
1182 # set colors for use in prompts
1183 if zrcautoload colors && colors 2>/dev/null ; then
1184     BLUE="%{${fg[blue]}%}"
1185     RED="%{${fg_bold[red]}%}"
1186     GREEN="%{${fg[green]}%}"
1187     CYAN="%{${fg[cyan]}%}"
1188     MAGENTA="%{${fg[magenta]}%}"
1189     YELLOW="%{${fg[yellow]}%}"
1190     WHITE="%{${fg[white]}%}"
1191     NO_COLOUR="%{${reset_color}%}"
1192 else
1193     BLUE=$'%{\e[1;34m%}'
1194     RED=$'%{\e[1;31m%}'
1195     GREEN=$'%{\e[1;32m%}'
1196     CYAN=$'%{\e[1;36m%}'
1197     WHITE=$'%{\e[1;37m%}'
1198     MAGENTA=$'%{\e[1;35m%}'
1199     YELLOW=$'%{\e[1;33m%}'
1200     NO_COLOUR=$'%{\e[0m%}'
1201 fi
1202
1203 # gather version control information for inclusion in a prompt
1204
1205 if zrcautoload vcs_info; then
1206     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1207     # function, which can cause a lot of trouble with our directory-based
1208     # profiles. So:
1209     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1210         function VCS_INFO_realpath () {
1211             setopt localoptions NO_shwordsplit chaselinks
1212             ( builtin cd -q $1 2> /dev/null && pwd; )
1213         }
1214     fi
1215
1216     zstyle ':vcs_info:*' max-exports 2
1217
1218     if [[ -o restricted ]]; then
1219         zstyle ':vcs_info:*' enable NONE
1220     fi
1221 fi
1222
1223 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1224 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1225 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1226 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1227 #       to $vcs_info_msg_N_ as soon as we use the included version.
1228 if [[ "$TERM" == dumb ]] ; then
1229     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1230     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1231 else
1232     # these are the same, just with a lot of colours:
1233     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
1234                                        "zsh: %r"
1235     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
1236                                        "zsh: %r"
1237     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1238 fi
1239
1240 # command not found handling
1241
1242 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1243 function command_not_found_handler() {
1244     emulate -L zsh
1245     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1246         ${GRML_ZSH_CNF_HANDLER} $1
1247     fi
1248     return 1
1249 }
1250
1251 # set prompt
1252 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1253     promptinit # people should be able to use their favourite prompt
1254 else
1255     print 'Notice: no promptinit available :('
1256 fi
1257
1258 setopt prompt_subst
1259
1260 # make sure to use right prompt only when not running a command
1261 is41 && setopt transient_rprompt
1262
1263
1264 function ESC_print () {
1265     info_print $'\ek' $'\e\\' "$@"
1266 }
1267 function set_title () {
1268     info_print  $'\e]0;' $'\a' "$@"
1269 }
1270
1271 function info_print () {
1272     local esc_begin esc_end
1273     esc_begin="$1"
1274     esc_end="$2"
1275     shift 2
1276     printf '%s' ${esc_begin}
1277     printf '%s' "$*"
1278     printf '%s' "${esc_end}"
1279 }
1280
1281 # TODO: revise all these NO* variables and especially their documentation
1282 #       in zsh-help() below.
1283 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1284     [[ $NOPRECMD -gt 0 ]] && return 0
1285     # update VCS information
1286     (( ${+functions[vcs_info]} )) && vcs_info
1287
1288     if [[ $TERM == screen* ]] ; then
1289         if [[ -n ${vcs_info_msg_1_} ]] ; then
1290             ESC_print ${vcs_info_msg_1_}
1291         else
1292             ESC_print "zsh"
1293         fi
1294     fi
1295     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1296     if [[ ${DONTSETRPROMPT:-} -eq 0 ]] ; then
1297         if [[ $BATTERY -gt 0 ]] ; then
1298             # update battery (dropped into $PERCENT) information
1299             battery
1300             RPROMPT="%(?..:() ${PERCENT}"
1301         else
1302             RPROMPT="%(?..:() "
1303         fi
1304     fi
1305     # adjust title of xterm
1306     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1307     [[ ${NOTITLE:-} -gt 0 ]] && return 0
1308     case $TERM in
1309         (xterm*|rxvt*)
1310             set_title ${(%):-"%n@%m: %~"}
1311             ;;
1312     esac
1313 }
1314
1315 # preexec() => a function running before every command
1316 is4 && [[ $NOPRECMD -eq 0 ]] && \
1317 preexec () {
1318     [[ $NOPRECMD -gt 0 ]] && return 0
1319 # set hostname if not running on host with name 'grml'
1320     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1321        NAME="@$HOSTNAME"
1322     fi
1323 # get the name of the program currently running and hostname of local machine
1324 # set screen window title if running in a screen
1325     if [[ "$TERM" == screen* ]] ; then
1326         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1327         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1328         ESC_print ${CMD}
1329     fi
1330 # adjust title of xterm
1331     [[ ${NOTITLE} -gt 0 ]] && return 0
1332     case $TERM in
1333         (xterm*|rxvt*)
1334             set_title "${(%):-"%n@%m:"}" "$1"
1335             ;;
1336     esac
1337 }
1338
1339 EXITCODE="%(?..%?%1v )"
1340 PS2='\`%_> '      # secondary prompt, printed when the shell needs more information to complete a command.
1341 PS3='?# '         # selection prompt used within a select loop.
1342 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1343
1344 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1345 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1346     debian_chroot=$(cat /etc/debian_chroot)
1347 fi
1348
1349 # don't use colors on dumb terminals (like emacs):
1350 if [[ "$TERM" == dumb ]] ; then
1351     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
1352 else
1353     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
1354     # set variable identifying the chroot you work in (used in the prompt below)
1355     if [[ $GRMLPROMPT -gt 0 ]] ; then
1356         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1357 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1358     else
1359         # This assembles the primary prompt string
1360         if (( EUID != 0 )); then
1361             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1362         else
1363             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1364         fi
1365     fi
1366 fi
1367
1368 PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
1369
1370 # if we are inside a grml-chroot set a specific prompt theme
1371 if [[ -n "$GRML_CHROOT" ]] ; then
1372     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1373 fi
1374
1375 # 'hash' some often used directories
1376 #d# start
1377 hash -d deb=/var/cache/apt/archives
1378 hash -d doc=/usr/share/doc
1379 hash -d linux=/lib/modules/$(command uname -r)/build/
1380 hash -d log=/var/log
1381 hash -d slog=/var/log/syslog
1382 hash -d src=/usr/src
1383 hash -d templ=/usr/share/doc/grml-templates
1384 hash -d tt=/usr/share/doc/texttools-doc
1385 hash -d www=/var/www
1386 #d# end
1387
1388 # some aliases
1389 if check_com -c screen ; then
1390     if [[ $UID -eq 0 ]] ; then
1391         [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
1392     elif [[ -r $HOME/.screenrc ]] ; then
1393         alias screen="${commands[screen]} -c $HOME/.screenrc"
1394     else
1395         if [[ -r /etc/grml/screenrc_grml ]]; then
1396             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1397         else
1398             [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
1399         fi
1400     fi
1401 fi
1402
1403 # do we have GNU ls with color-support?
1404 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
1405     #a1# execute \kbd{@a@}:\quad ls with colors
1406     alias ls='ls -b -CF --color=auto'
1407     #a1# execute \kbd{@a@}:\quad list all files, with colors
1408     alias la='ls -la --color=auto'
1409     #a1# long colored list, without dotfiles (@a@)
1410     alias ll='ls -l --color=auto'
1411     #a1# long colored list, human readable sizes (@a@)
1412     alias lh='ls -hAl --color=auto'
1413     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1414     alias l='ls -lF --color=auto'
1415 else
1416     alias ls='ls -b -CF'
1417     alias la='ls -la'
1418     alias ll='ls -l'
1419     alias lh='ls -hAl'
1420     alias l='ls -lF'
1421 fi
1422
1423 alias mdstat='cat /proc/mdstat'
1424 alias ...='cd ../../'
1425
1426 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1427 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1428     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1429 fi
1430
1431 #a1# Execute \kbd{rmdir}
1432 alias rd='rmdir'
1433 #a1# Execute \kbd{mkdir}
1434 alias md='mkdir'
1435
1436 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1437 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1438 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1439
1440 # make sure it is not assigned yet
1441 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1442 utf2iso() {
1443     if isutfenv ; then
1444         for ENV in $(env | command grep -i '.utf') ; do
1445             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1446         done
1447     fi
1448 }
1449
1450 # make sure it is not assigned yet
1451 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1452 iso2utf() {
1453     if ! isutfenv ; then
1454         for ENV in $(env | command grep -i '\.iso') ; do
1455             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1456         done
1457     fi
1458 }
1459
1460 # I like clean prompt, so provide simple way to get that
1461 check_com 0 || alias 0='return 0'
1462
1463 # for really lazy people like mika:
1464 check_com S &>/dev/null || alias S='screen'
1465 check_com s &>/dev/null || alias s='ssh'
1466
1467 # especially for roadwarriors using GNU screen and ssh:
1468 if ! check_com asc &>/dev/null ; then
1469   asc() { autossh -t "$@" 'screen -RdU' }
1470   compdef asc=ssh
1471 fi
1472
1473 #f1# Hints for the use of zsh on grml
1474 zsh-help() {
1475     print "$bg[white]$fg[black]
1476 zsh-help - hints for use of zsh on grml
1477 =======================================$reset_color"
1478
1479     print '
1480 Main configuration of zsh happens in /etc/zsh/zshrc.
1481 That file is part of the package grml-etc-core, if you want to
1482 use them on a non-grml-system just get the tar.gz from
1483 http://deb.grml.org/ or (preferably) get it from the git repository:
1484
1485   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1486
1487 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1488 The file is still there, but it is empty for backwards compatibility.
1489
1490 For your own changes use these two files:
1491     $HOME/.zshrc.pre
1492     $HOME/.zshrc.local
1493
1494 The former is sourced very early in our zshrc, the latter is sourced
1495 very lately.
1496
1497 System wide configuration without touching configuration files of grml
1498 can take place in /etc/zsh/zshrc.local.
1499
1500 Normally, the root user (EUID == 0) does not get the whole grml setup.
1501 If you want to force the whole setup for that user, too, set
1502 GRML_ALWAYS_LOAD_ALL=1 in .zshrc.pre in root'\''s home directory.
1503
1504 For information regarding zsh start at http://grml.org/zsh/
1505
1506 Take a look at grml'\''s zsh refcard:
1507 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1508
1509 Check out the main zsh refcard:
1510 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1511
1512 And of course visit the zsh-lovers:
1513 % man zsh-lovers
1514
1515 You can adjust some options through environment variables when
1516 invoking zsh without having to edit configuration files.
1517 Basically meant for bash users who are not used to the power of
1518 the zsh yet. :)
1519
1520   "NOCOR=1    zsh" => deactivate automatic correction
1521   "NOMENU=1   zsh" => do not use auto menu completion (note: use ctrl-d for completion instead!)
1522   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1523   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1524                       preexec() and precmd() completely
1525   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1526   "COMMAND_NOT_FOUND=1 zsh"
1527                    => Enable a handler if an external command was not found
1528                       The command called in the handler can be altered by setting
1529                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1530                       "/usr/share/command-not-found/command-not-found"
1531
1532 A value greater than 0 is enables a feature; a value equal to zero
1533 disables it. If you like one or the other of these settings, you can
1534 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1535 zshrc.'
1536
1537     print "
1538 $bg[white]$fg[black]
1539 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1540 Enjoy your grml system with the zsh!$reset_color"
1541 }
1542
1543 # debian stuff
1544 if [[ -r /etc/debian_version ]] ; then
1545     #a3# Execute \kbd{apt-cache search}
1546     alias acs='apt-cache search'
1547     #a3# Execute \kbd{apt-cache show}
1548     alias acsh='apt-cache show'
1549     #a3# Execute \kbd{apt-cache policy}
1550     alias acp='apt-cache policy'
1551     #a3# Execute \kbd{apt-get dist-upgrade}
1552     salias adg="apt-get dist-upgrade"
1553     #a3# Execute \kbd{apt-get install}
1554     salias agi="apt-get install"
1555     #a3# Execute \kbd{aptitude install}
1556     salias ati="aptitude install"
1557     #a3# Execute \kbd{apt-get upgrade}
1558     salias ag="apt-get upgrade"
1559     #a3# Execute \kbd{apt-get update}
1560     salias au="apt-get update"
1561     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1562     salias -a up="aptitude update ; aptitude safe-upgrade"
1563     #a3# Execute \kbd{dpkg-buildpackage}
1564     alias dbp='dpkg-buildpackage'
1565     #a3# Execute \kbd{grep-excuses}
1566     alias ge='grep-excuses'
1567
1568     # get a root shell as normal user in live-cd mode:
1569     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1570        alias su="sudo su"
1571      fi
1572
1573     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1574     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1575     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1576     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1577 fi
1578
1579 # sort installed Debian-packages by size
1580 if check_com -c dpkg-query ; then
1581     #a3# List installed Debian-packages sorted by size
1582     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1583 fi
1584
1585 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1586 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1587     if check_com -c wodim; then
1588         cdrecord() {
1589             cat <<EOMESS
1590 cdrecord is not provided under its original name by Debian anymore.
1591 See #377109 in the BTS of Debian for more details.
1592
1593 Please use the wodim binary instead
1594 EOMESS
1595             return 1
1596         }
1597     fi
1598 fi
1599
1600 # Use hard limits, except for a smaller stack and no core dumps
1601 unlimit
1602 is425 && limit stack 8192
1603 isgrmlcd && limit core 0 # important for a live-cd-system
1604 limit -s
1605
1606 # completion system
1607
1608 # called later (via is4 && grmlcomp)
1609 # note: use 'zstyle' for getting current settings
1610 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
1611 grmlcomp() {
1612     # TODO: This could use some additional information
1613
1614     # allow one error for every three characters typed in approximate completer
1615     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1616
1617     # don't complete backup files as executables
1618     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1619
1620     # start menu completion only if it could find no unambiguous initial string
1621     zstyle ':completion:*:correct:*'       insert-unambiguous true
1622     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1623     zstyle ':completion:*:correct:*'       original true
1624
1625     # activate color-completion
1626     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1627
1628     # format on completion
1629     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1630
1631     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1632     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1633
1634     # insert all expansions for expand completer
1635     zstyle ':completion:*:expand:*'        tag-order all-expansions
1636     zstyle ':completion:*:history-words'   list false
1637
1638     # activate menu
1639     zstyle ':completion:*:history-words'   menu yes
1640
1641     # ignore duplicate entries
1642     zstyle ':completion:*:history-words'   remove-all-dups yes
1643     zstyle ':completion:*:history-words'   stop yes
1644
1645     # match uppercase from lowercase
1646     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1647
1648     # separate matches into groups
1649     zstyle ':completion:*:matches'         group 'yes'
1650     zstyle ':completion:*'                 group-name ''
1651
1652     if [[ "$NOMENU" -eq 0 ]] ; then
1653         # if there are more than 5 options allow selecting from a menu
1654         zstyle ':completion:*'               menu select=5
1655     else
1656         # don't use any menus at all
1657         setopt no_auto_menu
1658     fi
1659
1660     zstyle ':completion:*:messages'        format '%d'
1661     zstyle ':completion:*:options'         auto-description '%d'
1662
1663     # describe options in full
1664     zstyle ':completion:*:options'         description 'yes'
1665
1666     # on processes completion complete all user processes
1667     zstyle ':completion:*:processes'       command 'ps -au$USER'
1668
1669     # offer indexes before parameters in subscripts
1670     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1671
1672     # provide verbose completion information
1673     zstyle ':completion:*'                 verbose true
1674
1675     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1676     # for commands (read: 1st word in the line) that it will list for the user
1677     # to choose from. The following disables that, because it's not exactly fast.
1678     zstyle ':completion:*:-command-:*:'    verbose false
1679
1680     # set format for warnings
1681     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1682
1683     # define files to ignore for zcompile
1684     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1685     zstyle ':completion:correct:'          prompt 'correct to: %e'
1686
1687     # Ignore completion functions for commands you don't have:
1688     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1689
1690     # Provide more processes in completion of programs like killall:
1691     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1692
1693     # complete manual by their section
1694     zstyle ':completion:*:manuals'    separate-sections true
1695     zstyle ':completion:*:manuals.*'  insert-sections   true
1696     zstyle ':completion:*:man:*'      menu yes select
1697
1698     # provide .. as a completion
1699     zstyle ':completion:*' special-dirs ..
1700
1701     # run rehash on completion so new installed program are found automatically:
1702     _force_rehash() {
1703         (( CURRENT == 1 )) && rehash
1704         return 1
1705     }
1706
1707     ## correction
1708     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1709     if [[ "$NOCOR" -gt 0 ]] ; then
1710         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1711         setopt nocorrect
1712     else
1713         # try to be smart about when to use what completer...
1714         setopt correct
1715         zstyle -e ':completion:*' completer '
1716             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1717                 _last_try="$HISTNO$BUFFER$CURSOR"
1718                 reply=(_complete _match _ignored _prefix _files)
1719             else
1720                 if [[ $words[1] == (rm|mv) ]] ; then
1721                     reply=(_complete _files)
1722                 else
1723                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1724                 fi
1725             fi'
1726     fi
1727
1728     # command for process lists, the local web server details and host completion
1729     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1730
1731     # caching
1732     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1733                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1734
1735     # host completion
1736     if is42 ; then
1737         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1738         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1739     else
1740         _ssh_hosts=()
1741         _etc_hosts=()
1742     fi
1743     hosts=(
1744         $(hostname)
1745         "$_ssh_hosts[@]"
1746         "$_etc_hosts[@]"
1747         grml.org
1748         localhost
1749     )
1750     zstyle ':completion:*:hosts' hosts $hosts
1751     # TODO: so, why is this here?
1752     #  zstyle '*' hosts $hosts
1753
1754     # use generic completion system for programs not yet defined; (_gnu_generic works
1755     # with commands that provide a --help option with "standard" gnu-like output.)
1756     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
1757                    pal stow tail uname ; do
1758         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
1759     done; unset compcom
1760
1761     # see upgrade function in this file
1762     compdef _hosts upgrade
1763 }
1764
1765 # grmlstuff
1766 grmlstuff() {
1767 # people should use 'grml-x'!
1768     if check_com -c 915resolution; then
1769         855resolution() {
1770             echo "Please use 915resolution as resolution modifying tool for Intel \
1771 graphic chipset."
1772             return -1
1773         }
1774     fi
1775
1776     #a1# Output version of running grml
1777     alias grml-version='cat /etc/grml_version'
1778
1779     if check_com -c rebuildfstab ; then
1780         #a1# Rebuild /etc/fstab
1781         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1782     fi
1783
1784     if check_com -c grml-debootstrap ; then
1785         debian2hd() {
1786             echo "Installing debian to harddisk is possible by using grml-debootstrap."
1787             return 1
1788         }
1789     fi
1790 }
1791
1792 # now run the functions
1793 isgrml && checkhome
1794 is4    && isgrml    && grmlstuff
1795 is4    && grmlcomp
1796
1797 # keephack
1798 is4 && xsource "/etc/zsh/keephack"
1799
1800 # wonderful idea of using "e" glob qualifier by Peter Stephenson
1801 # You use it as follows:
1802 # $ NTREF=/reference/file
1803 # $ ls -l *(e:nt:)
1804 # This lists all the files in the current directory newer than the reference file.
1805 # You can also specify the reference file inline; note quotes:
1806 # $ ls -l *(e:'nt ~/.zshenv':)
1807 is4 && nt() {
1808     if [[ -n $1 ]] ; then
1809         local NTREF=${~1}
1810     fi
1811     [[ $REPLY -nt $NTREF ]]
1812 }
1813
1814 # shell functions
1815
1816 #f1# Reload an autoloadable function
1817 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1818 compdef _functions freload
1819
1820 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1821 sll() {
1822     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1823     for file in "$@" ; do
1824         while [[ -h "$file" ]] ; do
1825             ls -l $file
1826             file=$(readlink "$file")
1827         done
1828     done
1829 }
1830
1831 # TODO: Is it supported to use pager settings like this?
1832 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
1833 # with respect to wordsplitting. (ie. ${=PAGER})
1834 if check_com -c $PAGER ; then
1835     #f1# View Debian's changelog of a given package
1836     dchange() {
1837         emulate -L zsh
1838         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
1839             $PAGER /usr/share/doc/$1/changelog.Debian.gz
1840         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1841             $PAGER /usr/share/doc/$1/changelog.gz
1842         else
1843             if check_com -c aptitude ; then
1844                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1845                 if isgrml ; then
1846                     aptitude -t unstable changelog $1
1847                 else
1848                     aptitude changelog $1
1849                 fi
1850             else
1851                 echo "No changelog for package $1 found, sorry."
1852                 return 1
1853             fi
1854         fi
1855     }
1856     _dchange() { _files -W /usr/share/doc -/ }
1857     compdef _dchange dchange
1858
1859     #f1# View Debian's NEWS of a given package
1860     dnews() {
1861         emulate -L zsh
1862         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
1863             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
1864         else
1865             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
1866                 $PAGER /usr/share/doc/$1/NEWS.gz
1867             else
1868                 echo "No NEWS file for package $1 found, sorry."
1869                 return 1
1870             fi
1871         fi
1872     }
1873     _dnews() { _files -W /usr/share/doc -/ }
1874     compdef _dnews dnews
1875
1876     #f1# View upstream's changelog of a given package
1877     uchange() {
1878         emulate -L zsh
1879         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1880             $PAGER /usr/share/doc/$1/changelog.gz
1881         else
1882             echo "No changelog for package $1 found, sorry."
1883             return 1
1884         fi
1885     }
1886     _uchange() { _files -W /usr/share/doc -/ }
1887     compdef _uchange uchange
1888 fi
1889
1890 # zsh profiling
1891 profile() {
1892     ZSH_PROFILE_RC=1 $SHELL "$@"
1893 }
1894
1895 #f1# Edit an alias via zle
1896 edalias() {
1897     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1898 }
1899 compdef _aliases edalias
1900
1901 #f1# Edit a function via zle
1902 edfunc() {
1903     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
1904 }
1905 compdef _functions edfunc
1906
1907 # use it e.g. via 'Restart apache2'
1908 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
1909 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
1910 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
1911 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
1912 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
1913 if [[ -d /etc/init.d || -d /etc/service ]] ; then
1914     __start_stop() {
1915         local action_="${1:l}"  # e.g Start/Stop/Restart
1916         local service_="$2"
1917         local param_="$3"
1918
1919         local service_target_="$(readlink /etc/init.d/$service_)"
1920         if [[ $service_target_ == "/usr/bin/sv" ]]; then
1921             # runit
1922             case "${action_}" in
1923                 start) if [[ ! -e /etc/service/$service_ ]]; then
1924                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
1925                        else
1926                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1927                        fi ;;
1928                 # there is no reload in runits sysv emulation
1929                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
1930                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
1931             esac
1932         else
1933             # sysvinit
1934             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1935         fi
1936     }
1937
1938     _grmlinitd() {
1939         local -a scripts
1940         scripts=( /etc/init.d/*(x:t) )
1941         _describe "service startup script" scripts
1942     }
1943
1944     for i in Start Restart Stop Force-Reload Reload ; do
1945         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
1946         compdef _grmlinitd $i
1947     done
1948 fi
1949
1950 #f1# Provides useful information on globbing
1951 H-Glob() {
1952     echo -e "
1953     /      directories
1954     .      plain files
1955     @      symbolic links
1956     =      sockets
1957     p      named pipes (FIFOs)
1958     *      executable plain files (0100)
1959     %      device files (character or block special)
1960     %b     block special files
1961     %c     character special files
1962     r      owner-readable files (0400)
1963     w      owner-writable files (0200)
1964     x      owner-executable files (0100)
1965     A      group-readable files (0040)
1966     I      group-writable files (0020)
1967     E      group-executable files (0010)
1968     R      world-readable files (0004)
1969     W      world-writable files (0002)
1970     X      world-executable files (0001)
1971     s      setuid files (04000)
1972     S      setgid files (02000)
1973     t      files with the sticky bit (01000)
1974
1975   print *(m-1)          # Files modified up to a day ago
1976   print *(a1)           # Files accessed a day ago
1977   print *(@)            # Just symlinks
1978   print *(Lk+50)        # Files bigger than 50 kilobytes
1979   print *(Lk-50)        # Files smaller than 50 kilobytes
1980   print **/*.c          # All *.c files recursively starting in \$PWD
1981   print **/*.c~file.c   # Same as above, but excluding 'file.c'
1982   print (foo|bar).*     # Files starting with 'foo' or 'bar'
1983   print *~*.*           # All Files that do not contain a dot
1984   chmod 644 *(.^x)      # make all plain non-executable files publically readable
1985   print -l *(.c|.h)     # Lists *.c and *.h
1986   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
1987   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
1988 }
1989 alias help-zshglob=H-Glob
1990
1991 #v1# set number of lines to display per page
1992 HELP_LINES_PER_PAGE=20
1993 #v1# set location of help-zle cache file
1994 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
1995 #f1# helper function for help-zle, actually generates the help text
1996 help_zle_parse_keybindings()
1997 {
1998     emulate -L zsh
1999     setopt extendedglob
2000     unsetopt ksharrays  #indexing starts at 1
2001
2002     #v1# choose files that help-zle will parse for keybindings
2003     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
2004
2005     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
2006         local load_cache=0
2007         for f ($KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
2008         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
2009     fi
2010
2011     #fill with default keybindings, possibly to be overwriten in a file later
2012     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2013     local -A help_zle_keybindings
2014     help_zle_keybindings['<Ctrl>@']="set MARK"
2015     help_zle_keybindings['<Ctrl>X<Ctrl>J']="vi-join lines"
2016     help_zle_keybindings['<Ctrl>X<Ctrl>B']="jump to matching brace"
2017     help_zle_keybindings['<Ctrl>X<Ctrl>U']="undo"
2018     help_zle_keybindings['<Ctrl>_']="undo"
2019     help_zle_keybindings['<Ctrl>X<Ctrl>F<c>']="find <c> in cmdline"
2020     help_zle_keybindings['<Ctrl>A']="goto beginning of line"
2021     help_zle_keybindings['<Ctrl>E']="goto end of line"
2022     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2023     help_zle_keybindings['<Alt>T']="transpose words"
2024     help_zle_keybindings['<Alt>s']="spellcheck word"
2025     help_zle_keybindings['<Ctrl>K']="backward kill buffer"
2026     help_zle_keybindings['<Ctrl>U']="forward kill buffer"
2027     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2028     help_zle_keybindings["<Alt>'"]="quote line"
2029     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2030     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2031     help_zle_keybindings['<Alt>U']="make next word Uppercase"
2032     help_zle_keybindings['<Alt>l']="make next word lowercase"
2033     help_zle_keybindings['<Ctrl>Xd']="preview expansion under cursor"
2034     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2035     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2036     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2037     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2038     help_zle_keybindings['<Ctrl>V']="insert next keypress symbol literally (e.g. for bindkey)"
2039     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2040     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2041     help_zle_keybindings['<Alt>H']="run help on current command"
2042
2043     #init global variables
2044     unset help_zle_lines help_zle_sln
2045     typeset -g -a help_zle_lines
2046     typeset -g help_zle_sln=1
2047
2048     local k v
2049     local lastkeybind_desc contents     #last description starting with #k# that we found
2050     local num_lines_elapsed=0            #number of lines between last description and keybinding
2051     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2052     for f in $HELPZLE_KEYBINDING_FILES; do
2053         [[ -r "$f" ]] || continue   #not readable ? skip it
2054         contents="$(<$f)"
2055         for cline in "${(f)contents}"; do
2056             #zsh pattern: matches lines like: #k# ..............
2057             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2058                 lastkeybind_desc="$match[*]"
2059                 num_lines_elapsed=0
2060             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2061             #             ignores lines that are commentend out
2062             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2063             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2064                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2065                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2066                     #substitute keybinding string with something readable
2067                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2068                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2069                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2070                     help_zle_keybindings[${k}]=$lastkeybind_desc
2071                 fi
2072                 lastkeybind_desc=""
2073             else
2074               ((num_lines_elapsed++))
2075             fi
2076         done
2077     done
2078     unset contents
2079     #calculate length of keybinding column
2080     local kstrlen=0
2081     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2082     #convert the assoc array into preformated lines, which we are able to sort
2083     for k v in ${(kv)help_zle_keybindings[@]}; do
2084         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2085         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2086     done
2087     #sort lines alphabetically
2088     help_zle_lines=("${(i)help_zle_lines[@]}")
2089     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2090     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2091     zcompile $HELP_ZLE_CACHE_FILE
2092 }
2093 typeset -g help_zle_sln
2094 typeset -g -a help_zle_lines
2095
2096 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2097 help-zle()
2098 {
2099     emulate -L zsh
2100     unsetopt ksharrays  #indexing starts at 1
2101     #help lines already generated ? no ? then do it
2102     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2103     #already displayed all lines ? go back to the start
2104     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2105     local sln=$help_zle_sln
2106     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2107     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2108     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2109 }
2110 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2111 zle -N help-zle && bindkey '^Xz' help-zle
2112
2113 # grep for running process, like: 'any vim'
2114 any() {
2115     emulate -L zsh
2116     unsetopt KSH_ARRAYS
2117     if [[ -z "$1" ]] ; then
2118         echo "any - grep for process(es) by keyword" >&2
2119         echo "Usage: any <keyword>" >&2 ; return 1
2120     else
2121         ps xauwww | grep -i --color=auto "[${1[1]}]${1[2,-1]}"
2122     fi
2123 }
2124
2125
2126 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2127 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2128 [[ -r /proc/1/maps ]] && \
2129 deswap() {
2130     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2131     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2132     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2133 }
2134
2135 # a wrapper for vim, that deals with title setting
2136 #   VIM_OPTIONS
2137 #       set this array to a set of options to vim you always want
2138 #       to have set when calling vim (in .zshrc.local), like:
2139 #           VIM_OPTIONS=( -p )
2140 #       This will cause vim to send every file given on the
2141 #       commandline to be send to it's own tab (needs vim7).
2142 vim() {
2143     VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2144 }
2145
2146 # make a backup of a file
2147 bk() {
2148     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2149 }
2150
2151 ssl_hashes=( sha512 sha256 sha1 md5 )
2152
2153 for sh in ${ssl_hashes}; do
2154     eval 'ssl-cert-'${sh}'() {
2155         emulate -L zsh
2156         if [[ -z $1 ]] ; then
2157             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2158             return 1
2159         fi
2160         openssl x509 -noout -fingerprint -'${sh}' -in $1
2161     }'
2162 done; unset sh
2163
2164 ssl-cert-fingerprints() {
2165     emulate -L zsh
2166     local i
2167     if [[ -z $1 ]] ; then
2168         printf 'usage: ssl-cert-fingerprints <file>\n'
2169         return 1
2170     fi
2171     for i in ${ssl_hashes}
2172         do ssl-cert-$i $1;
2173     done
2174 }
2175
2176 ssl-cert-info() {
2177     emulate -L zsh
2178     if [[ -z $1 ]] ; then
2179         printf 'usage: ssl-cert-info <file>\n'
2180         return 1
2181     fi
2182     openssl x509 -noout -text -in $1
2183     ssl-cert-fingerprints $1
2184 }
2185
2186 # make sure our environment is clean regarding colors
2187 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2188
2189 # "persistent history"
2190 # just write important commands you always need to ~/.important_commands
2191 if [[ -r ~/.important_commands ]] ; then
2192     fc -R ~/.important_commands
2193 fi
2194
2195 # load the lookup subsystem if it's available on the system
2196 zrcautoload lookupinit && lookupinit
2197
2198 ### non-root (EUID != 0) code below
2199 ###
2200
2201 if (( GRML_ALWAYS_LOAD_ALL == 0 )) && (( $EUID == 0 )) ; then
2202     zrclocal
2203     return 0
2204 fi
2205
2206 # variables
2207
2208 # set terminal property (used e.g. by msgid-chooser)
2209 export COLORTERM="yes"
2210
2211 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
2212 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
2213 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
2214
2215 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
2216 #v# [for non-root only]
2217 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
2218
2219 # aliases
2220
2221 # general
2222 #a2# Execute \kbd{du -sch}
2223 alias da='du -sch'
2224 #a2# Execute \kbd{jobs -l}
2225 alias j='jobs -l'
2226
2227 # listing stuff
2228 #a2# Execute \kbd{ls -lSrah}
2229 alias dir="ls -lSrah"
2230 #a2# Only show dot-directories
2231 alias lad='ls -d .*(/)'                # only show dot-directories
2232 #a2# Only show dot-files
2233 alias lsa='ls -a .*(.)'                # only show dot-files
2234 #a2# Only files with setgid/setuid/sticky flag
2235 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
2236 #a2# Only show 1st ten symlinks
2237 alias lsl='ls -l *(@)'                 # only symlinks
2238 #a2# Display only executables
2239 alias lsx='ls -l *(*)'                 # only executables
2240 #a2# Display world-{readable,writable,executable} files
2241 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
2242 #a2# Display the ten biggest files
2243 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
2244 #a2# Only show directories
2245 alias lsd='ls -d *(/)'                 # only show directories
2246 #a2# Only show empty directories
2247 alias lse='ls -d *(/^F)'               # only show empty directories
2248 #a2# Display the ten newest files
2249 alias lsnew="ls -rtlh *(D.om[1,10])"   # display the newest files
2250 #a2# Display the ten oldest files
2251 alias lsold="ls -rtlh *(D.Om[1,10])"   # display the oldest files
2252 #a2# Display the ten smallest files
2253 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
2254
2255 # some useful aliases
2256 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir $OLDCWD}
2257 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2258
2259 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2260 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2261 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2262
2263 # simple webserver
2264 check_com -c python && alias http="python -m SimpleHTTPServer"
2265
2266 # Use 'g' instead of 'git':
2267 check_com g || alias g='git'
2268
2269 # work around non utf8 capable software in utf environment via $LANG and luit
2270 if check_com isutfenv && check_com luit ; then
2271     if check_com -c mrxvt ; then
2272         isutfenv && [[ -n "$LANG" ]] && \
2273             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2274     fi
2275
2276     if check_com -c aterm ; then
2277         isutfenv && [[ -n "$LANG" ]] && \
2278             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2279     fi
2280
2281     if check_com -c centericq ; then
2282         isutfenv && [[ -n "$LANG" ]] && \
2283             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2284     fi
2285 fi
2286
2287 # useful functions
2288
2289 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2290 bk() {
2291     emulate -L zsh
2292     cp -b $1 $1_`date --iso-8601=m`
2293 }
2294
2295 #f5# cd to directoy and list files
2296 cl() {
2297     emulate -L zsh
2298     cd $1 && ls -a
2299 }
2300
2301 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2302 cd() {
2303     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2304         [[ ! -e ${1:h} ]] && return 1
2305         print "Correcting ${1} to ${1:h}"
2306         builtin cd ${1:h}
2307     else
2308         builtin cd "$@"
2309     fi
2310 }
2311
2312 #f5# Create Directoy and \kbd{cd} to it
2313 mkcd() {
2314     mkdir -p "$@" && cd "$@"
2315 }
2316
2317 #f5# Create temporary directory and \kbd{cd} to it
2318 cdt() {
2319     local t
2320     t=$(mktemp -d)
2321     echo "$t"
2322     builtin cd "$t"
2323 }
2324
2325 #f5# Create directory under cursor or the selected area
2326 # Press ctrl-xM to create the directory under the cursor or the selected area.
2327 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2328 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2329 # directory does not exist yet -> press ctrl-XM and problem solved
2330 inplaceMkDirs() {
2331     local PATHTOMKDIR
2332     if ((REGION_ACTIVE==1)); then
2333         local F=$MARK T=$CURSOR
2334         if [[ $F -gt $T ]]; then
2335             F=${CURSOR}
2336             T=${MARK}
2337         fi
2338         # get marked area from buffer and eliminate whitespace
2339         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2340         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2341     else
2342         local bufwords iword
2343         bufwords=(${(z)LBUFFER})
2344         iword=${#bufwords}
2345         bufwords=(${(z)BUFFER})
2346         PATHTOMKDIR="${(Q)bufwords[iword]}"
2347     fi
2348     [[ -z "${PATHTOMKDIR}" ]] && return 1
2349     if [[ -e "${PATHTOMKDIR}" ]]; then
2350         zle -M " path already exists, doing nothing"
2351     else
2352         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2353         zle end-of-line
2354     fi
2355 }
2356 #k# mkdir -p <dir> from string under cursor or marked area
2357 zle -N inplaceMkDirs && bindkey '^XM' inplaceMkDirs
2358
2359 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2360 accessed() {
2361     emulate -L zsh
2362     print -l -- *(a-${1:-1})
2363 }
2364
2365 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2366 changed() {
2367     emulate -L zsh
2368     print -l -- *(c-${1:-1})
2369 }
2370
2371 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2372 modified() {
2373     emulate -L zsh
2374     print -l -- *(m-${1:-1})
2375 }
2376 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2377 check_com new || alias new=modified
2378
2379 # use colors when GNU grep with color-support
2380 #a2# Execute \kbd{grep -{}-color=auto}
2381 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
2382
2383 # Translate DE<=>EN
2384 # 'translate' looks up fot a word in a file with language-to-language
2385 # translations (field separator should be " : "). A typical wordlist looks
2386 # like at follows:
2387 #  | english-word : german-transmission
2388 # It's also only possible to translate english to german but not reciprocal.
2389 # Use the following oneliner to turn back the sort order:
2390 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2391 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2392 #f5# Translates a word
2393 trans() {
2394     emulate -L zsh
2395     case "$1" in
2396         -[dD]*)
2397             translate -l de-en $2
2398             ;;
2399         -[eE]*)
2400             translate -l en-de $2
2401             ;;
2402         *)
2403             echo "Usage: $0 { -D | -E }"
2404             echo "         -D == German to English"
2405             echo "         -E == English to German"
2406     esac
2407 }
2408
2409 # Usage: simple-extract <file>
2410 # Using option -d deletes the original archive file.
2411 #f5# Smart archive extractor
2412 simple-extract() {
2413     emulate -L zsh
2414     setopt extended_glob noclobber
2415     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2416     local RC=0
2417     zparseopts -D -E "d=DELETE_ORIGINAL"
2418     for ARCHIVE in "${@}"; do
2419         case $ARCHIVE in
2420             *.(tar.bz2|tbz2|tbz))
2421                 DECOMP_CMD="tar -xvjf -"
2422                 USES_STDIN=true
2423                 USES_STDOUT=false
2424                 ;;
2425             *.(tar.gz|tgz))
2426                 DECOMP_CMD="tar -xvzf -"
2427                 USES_STDIN=true
2428                 USES_STDOUT=false
2429                 ;;
2430             *.(tar.xz|txz|tar.lzma))
2431                 DECOMP_CMD="tar -xvJf -"
2432                 USES_STDIN=true
2433                 USES_STDOUT=false
2434                 ;;
2435             *.tar)
2436                 DECOMP_CMD="tar -xvf -"
2437                 USES_STDIN=true
2438                 USES_STDOUT=false
2439                 ;;
2440             *.rar)
2441                 DECOMP_CMD="unrar x"
2442                 USES_STDIN=false
2443                 USES_STDOUT=false
2444                 ;;
2445             *.lzh)
2446                 DECOMP_CMD="lha x"
2447                 USES_STDIN=false
2448                 USES_STDOUT=false
2449                 ;;
2450             *.7z)
2451                 DECOMP_CMD="7z x"
2452                 USES_STDIN=false
2453                 USES_STDOUT=false
2454                 ;;
2455             *.(zip|jar))
2456                 DECOMP_CMD="unzip"
2457                 USES_STDIN=false
2458                 USES_STDOUT=false
2459                 ;;
2460             *.deb)
2461                 DECOMP_CMD="ar -x"
2462                 USES_STDIN=false
2463                 USES_STDOUT=false
2464                 ;;
2465             *.bz2)
2466                 DECOMP_CMD="bzip2 -d -c -"
2467                 USES_STDIN=true
2468                 USES_STDOUT=true
2469                 ;;
2470             *.(gz|Z))
2471                 DECOMP_CMD="gzip -d -c -"
2472                 USES_STDIN=true
2473                 USES_STDOUT=true
2474                 ;;
2475             *.(xz|lzma))
2476                 DECOMP_CMD="xz -d -c -"
2477                 USES_STDIN=true
2478                 USES_STDOUT=true
2479                 ;;
2480             *)
2481                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2482                 RC=$((RC+1))
2483                 continue
2484                 ;;
2485         esac
2486
2487         if ! check_com ${DECOMP_CMD[(w)1]}; then
2488             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2489             RC=$((RC+2))
2490             continue
2491         fi
2492
2493         GZTARGET="${ARCHIVE:t:r}"
2494         if [[ -f $ARCHIVE ]] ; then
2495
2496             print "Extracting '$ARCHIVE' ..."
2497             if $USES_STDIN; then
2498                 if $USES_STDOUT; then
2499                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
2500                 else
2501                     ${=DECOMP_CMD} < "$ARCHIVE"
2502                 fi
2503             else
2504                 if $USES_STDOUT; then
2505                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
2506                 else
2507                     ${=DECOMP_CMD} "$ARCHIVE"
2508                 fi
2509             fi
2510             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
2511
2512         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
2513             if check_com curl; then
2514                 WGET_CMD="curl -L -k -s -o -"
2515             elif check_com wget; then
2516                 WGET_CMD="wget -q -O - --no-check-certificate"
2517             else
2518                 print "ERROR: neither wget nor curl is installed" >&2
2519                 RC=$((RC+4))
2520                 continue
2521             fi
2522             print "Downloading and Extracting '$ARCHIVE' ..."
2523             if $USES_STDIN; then
2524                 if $USES_STDOUT; then
2525                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
2526                     RC=$((RC+$?))
2527                 else
2528                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
2529                     RC=$((RC+$?))
2530                 fi
2531             else
2532                 if $USES_STDOUT; then
2533                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
2534                 else
2535                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
2536                 fi
2537             fi
2538
2539         else
2540             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
2541             RC=$((RC+8))
2542         fi
2543     done
2544     return $RC
2545 }
2546
2547 __archive_or_uri()
2548 {
2549     _alternative \
2550         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
2551         '_urls:Remote Archives:_urls'
2552 }
2553
2554 _simple_extract()
2555 {
2556     _arguments \
2557         '-d[delete original archivefile after extraction]' \
2558         '*:Archive Or Uri:__archive_or_uri'
2559 }
2560 compdef _simple_extract simple-extract
2561 alias se=simple-extract
2562
2563 # Usage: smartcompress <file> (<type>)
2564 #f5# Smart archive creator
2565 smartcompress() {
2566     emulate -L zsh
2567     if [[ -n $2 ]] ; then
2568         case $2 in
2569             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
2570             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
2571             tar.Z)          tar -Zcvf$1.$2 $1 ;;
2572             tar)            tar -cvf$1.$2  $1 ;;
2573             gz | gzip)      gzip           $1 ;;
2574             bz2 | bzip2)    bzip2          $1 ;;
2575             *)
2576                 echo "Error: $2 is not a valid compression type"
2577                 ;;
2578         esac
2579     else
2580         smartcompress $1 tar.gz
2581     fi
2582 }
2583
2584 # Usage: show-archive <archive>
2585 #f5# List an archive's content
2586 show-archive() {
2587     emulate -L zsh
2588     if [[ -f $1 ]] ; then
2589         case $1 in
2590             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
2591             *.tar)         tar -tf $1 ;;
2592             *.tgz)         tar -ztf $1 ;;
2593             *.zip)         unzip -l $1 ;;
2594             *.bz2)         bzless $1 ;;
2595             *.deb)         dpkg-deb --fsys-tarfile $1 | tar -tf - -- ;;
2596             *)             echo "'$1' Error. Please go away" ;;
2597         esac
2598     else
2599         echo "'$1' is not a valid archive"
2600     fi
2601 }
2602
2603 # TODO: So, this is the third incarnation of this function!?
2604 #f5# Reload given functions
2605 refunc() {
2606     for func in $argv ; do
2607         unfunction $func
2608         autoload $func
2609     done
2610 }
2611 compdef _functions refunc
2612
2613 #f5# Set all ulimit parameters to \kbd{unlimited}
2614 allulimit() {
2615     ulimit -c unlimited
2616     ulimit -d unlimited
2617     ulimit -f unlimited
2618     ulimit -l unlimited
2619     ulimit -n unlimited
2620     ulimit -s unlimited
2621     ulimit -t unlimited
2622 }
2623
2624 #f5# Change the xterm title from within GNU-screen
2625 xtrename() {
2626     emulate -L zsh
2627     if [[ $1 != "-f" ]] ; then
2628         if [[ -z ${DISPLAY} ]] ; then
2629             printf 'xtrename only makes sense in X11.\n'
2630             return 1
2631         fi
2632     else
2633         shift
2634     fi
2635     if [[ -z $1 ]] ; then
2636         printf 'usage: xtrename [-f] "title for xterm"\n'
2637         printf '  renames the title of xterm from _within_ screen.\n'
2638         printf '  also works without screen.\n'
2639         printf '  will not work if DISPLAY is unset, use -f to override.\n'
2640         return 0
2641     fi
2642     print -n "\eP\e]0;${1}\C-G\e\\"
2643     return 0
2644 }
2645
2646 # TODO:
2647 # Rewrite this by either using tinyurl.com's API
2648 # or using another shortening service to comply with
2649 # tinyurl.com's policy.
2650 #
2651 # Create small urls via http://tinyurl.com using wget(1).
2652 #function zurl() {
2653 #    emulate -L zsh
2654 #    [[ -z $1 ]] && { print "USAGE: zurl <URL>" ; return 1 }
2655 #
2656 #    local PN url tiny grabber search result preview
2657 #    PN=$0
2658 #    url=$1
2659 ##   Check existence of given URL with the help of ping(1).
2660 ##   N.B. ping(1) only works without an eventual given protocol.
2661 #    ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
2662 #        read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
2663 #
2664 #    if (( $? == 0 )) ; then
2665 ##           Prepend 'http://' to given URL where necessary for later output.
2666 #            [[ ${url} != http(s|)://* ]] && url='http://'${url}
2667 #            tiny='http://tinyurl.com/create.php?url='
2668 #            if check_com -c wget ; then
2669 #                grabber='wget -O- -o/dev/null'
2670 #            else
2671 #                print "wget is not available, but mandatory for ${PN}. Aborting."
2672 #            fi
2673 ##           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
2674 #            search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
2675 #            result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
2676 ##           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
2677 #            preview='http://preview.'${result#http://}
2678 #
2679 #            printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
2680 #            printf '%s\t%s\n\n' 'Given URL:' ${url}
2681 #            printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
2682 #    else
2683 #        return 1
2684 #    fi
2685 #}
2686
2687 #f2# Find history events by search pattern and list them by date.
2688 whatwhen()  {
2689     emulate -L zsh
2690     local usage help ident format_l format_s first_char remain first last
2691     usage='USAGE: whatwhen [options] <searchstring> <search range>'
2692     help='Use `whatwhen -h'\'' for further explanations.'
2693     ident=${(l,${#${:-Usage: }},, ,)}
2694     format_l="${ident}%s\t\t\t%s\n"
2695     format_s="${format_l//(\\t)##/\\t}"
2696     # Make the first char of the word to search for case
2697     # insensitive; e.g. [aA]
2698     first_char=[${(L)1[1]}${(U)1[1]}]
2699     remain=${1[2,-1]}
2700     # Default search range is `-100'.
2701     first=${2:-\-100}
2702     # Optional, just used for `<first> <last>' given.
2703     last=$3
2704     case $1 in
2705         ("")
2706             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
2707             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2708         ;;
2709         (-h)
2710             printf '%s\n\n' ${usage}
2711             print 'OPTIONS:'
2712             printf $format_l '-h' 'show help text'
2713             print '\f'
2714             print 'SEARCH RANGE:'
2715             printf $format_l "'0'" 'the whole history,'
2716             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
2717             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
2718             printf '\n%s\n' 'EXAMPLES:'
2719             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
2720             printf $format_l 'whatwhen zsh -250'
2721             printf $format_l 'whatwhen foo 1 99'
2722         ;;
2723         (\?)
2724             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2725         ;;
2726         (*)
2727             # -l list results on stout rather than invoking $EDITOR.
2728             # -i Print dates as in YYYY-MM-DD.
2729             # -m Search for a - quoted - pattern within the history.
2730             fc -li -m "*${first_char}${remain}*" $first $last
2731         ;;
2732     esac
2733 }
2734
2735 # mercurial related stuff
2736 if check_com -c hg ; then
2737     # gnu like diff for mercurial
2738     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
2739     #f5# GNU like diff for mercurial
2740     hgdi() {
2741         emulate -L zsh
2742         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
2743     }
2744
2745     # build debian package
2746     #a2# Alias for \kbd{hg-buildpackage}
2747     alias hbp='hg-buildpackage'
2748
2749     # execute commands on the versioned patch-queue from the current repos
2750     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
2751
2752     # diffstat for specific version of a mercurial repository
2753     #   hgstat      => display diffstat between last revision and tip
2754     #   hgstat 1234 => display diffstat between revision 1234 and tip
2755     #f5# Diffstat for specific version of a mercurial repos
2756     hgstat() {
2757         emulate -L zsh
2758         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
2759     }
2760
2761 fi # end of check whether we have the 'hg'-executable
2762
2763 # grml-small cleanups
2764
2765 # The following is used to remove zsh-config-items that do not work
2766 # in grml-small by default.
2767 # If you do not want these adjustments (for whatever reason), set
2768 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
2769 # sources if it is there).
2770
2771 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
2772
2773     unset abk[V]
2774     unalias    'V'      &> /dev/null
2775     unfunction vman     &> /dev/null
2776     unfunction viless   &> /dev/null
2777     unfunction 2html    &> /dev/null
2778
2779     # manpages are not in grmlsmall
2780     unfunction manzsh   &> /dev/null
2781     unfunction man2     &> /dev/null
2782
2783 fi
2784
2785 zrclocal
2786
2787 ## genrefcard.pl settings
2788
2789 ### doc strings for external functions from files
2790 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
2791
2792 ### example: split functions-search 8,16,24,32
2793 #@# split functions-search 8
2794
2795 ## END OF FILE #################################################################
2796 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
2797 # Local variables:
2798 # mode: sh
2799 # End: