etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is437(){
 148     [[ $ZSH_VERSION == 4.3.<7->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 is439(){
 154     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 155                                  || $ZSH_VERSION == <5->* ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running grml
 160 isgrml(){
 161     [[ -f /etc/grml_version ]] && return 0
 162     return 1
 163 }
 164
 165 #f1# Checks whether or not you're running a grml cd
 166 isgrmlcd(){
 167     [[ -f /etc/grml_cd ]] && return 0
 168     return 1
 169 }
 170
 171 if isgrml ; then
 172 #f1# Checks whether or not you're running grml-small
 173     isgrmlsmall() {
 174         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 175             return 0
 176         fi
 177         return 1
 178     }
 179 else
 180     isgrmlsmall() { return 1 }
 181 fi
 182
 183 isdarwin(){
 184     [[ $OSTYPE == darwin* ]] && return 0
 185     return 1
 186 }
 187
 188 isfreebsd(){
 189     [[ $OSTYPE == freebsd* ]] && return 0
 190     return 1
 191 }
 192
 193 #f1# are we running within an utf environment?
 194 isutfenv() {
 195     case "$LANG $CHARSET $LANGUAGE" in
 196         *utf*) return 0 ;;
 197         *UTF*) return 0 ;;
 198         *)     return 1 ;;
 199     esac
 200 }
 201
 202 # check for user, if not running as root set $SUDO to sudo
 203 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 204
 205 # change directory to home on first invocation of zsh
 206 # important for rungetty -> autologin
 207 # Thanks go to Bart Schaefer!
 208 isgrml && checkhome() {
 209     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 210         export ALREADY_DID_CD_HOME=$HOME
 211         cd
 212     fi
 213 }
 214
 215 # check for zsh v3.1.7+
 216
 217 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 218      || ${ZSH_VERSION} == 3.<2->.<->*    \
 219      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 220
 221     printf '-!-\n'
 222     printf '-!- In this configuration we try to make use of features, that only\n'
 223     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 224     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 225     printf '-!- advanced features in all supported versions.\n'
 226     printf '-!-\n'
 227     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 228     printf '-!-\n'
 229     printf '-!- While this *may* work, it might as well fail.\n'
 230     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 231     printf '-!-\n'
 232     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 233     printf '-!- If it does today, you'\''ve been lucky.\n'
 234     printf '-!-\n'
 235     printf '-!- Ye been warned!\n'
 236     printf '-!-\n'
 237
 238     function zstyle() { : }
 239 fi
 240
 241 # autoload wrapper - use this one instead of autoload directly
 242 # We need to define this function as early as this, because autoloading
 243 # 'is-at-least()' needs it.
 244 function zrcautoload() {
 245     emulate -L zsh
 246     setopt extended_glob
 247     local fdir ffile
 248     local -i ffound
 249
 250     ffile=$1
 251     (( ffound = 0 ))
 252     for fdir in ${fpath} ; do
 253         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 254     done
 255
 256     (( ffound == 0 )) && return 1
 257     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 258         autoload -U ${ffile} || return 1
 259     else
 260         autoload ${ffile} || return 1
 261     fi
 262     return 0
 263 }
 264
 265 # Load is-at-least() for more precise version checks Note that this test will
 266 # *always* fail, if the is-at-least function could not be marked for
 267 # autoloading.
 268 zrcautoload is-at-least || is-at-least() { return 1 }
 269
 270 # set some important options (as early as possible)
 271
 272 # append history list to the history file; this is the default but we make sure
 273 # because it's required for share_history.
 274 setopt append_history
 275
 276 # import new commands from the history file also in other zsh-session
 277 is4 && setopt share_history
 278
 279 # save each command's beginning timestamp and the duration to the history file
 280 setopt extended_history
 281
 282 # If a new command line being added to the history list duplicates an older
 283 # one, the older command is removed from the list
 284 is4 && setopt histignorealldups
 285
 286 # remove command lines from the history list when the first character on the
 287 # line is a space
 288 setopt histignorespace
 289
 290 # if a command is issued that can't be executed as a normal command, and the
 291 # command is the name of a directory, perform the cd command to that directory.
 292 setopt auto_cd
 293
 294 # in order to use #, ~ and ^ for filename generation grep word
 295 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 296 # don't forget to quote '^', '~' and '#'!
 297 setopt extended_glob
 298
 299 # display PID when suspending processes as well
 300 setopt longlistjobs
 301
 302 # try to avoid the 'zsh: no matches found...'
 303 setopt nonomatch
 304
 305 # report the status of backgrounds jobs immediately
 306 setopt notify
 307
 308 # whenever a command completion is attempted, make sure the entire command path
 309 # is hashed first.
 310 setopt hash_list_all
 311
 312 # not just at the end
 313 setopt completeinword
 314
 315 # Don't send SIGHUP to background processes when the shell exits.
 316 setopt nohup
 317
 318 # make cd push the old directory onto the directory stack.
 319 setopt auto_pushd
 320
 321 # avoid "beep"ing
 322 setopt nobeep
 323
 324 # don't push the same dir twice.
 325 setopt pushd_ignore_dups
 326
 327 # * shouldn't match dotfiles. ever.
 328 setopt noglobdots
 329
 330 # use zsh style word splitting
 331 setopt noshwordsplit
 332
 333 # don't error out when unset parameters are used
 334 setopt unset
 335
 336 # setting some default values
 337 NOCOR=${NOCOR:-0}
 338 NOMENU=${NOMENU:-0}
 339 NOPRECMD=${NOPRECMD:-0}
 340 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 341 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 342 BATTERY=${BATTERY:-0}
 343 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 344 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 345
 346 typeset -ga ls_options
 347 typeset -ga grep_options
 348 if ls --help 2> /dev/null | grep -q GNU; then
 349     ls_options=( --color=auto )
 350 elif [[ $OSTYPE == freebsd* ]]; then
 351     ls_options=( -G )
 352 fi
 353 if grep --help 2> /dev/null | grep -q GNU || \
 354    [[ $OSTYPE == freebsd* ]]; then
 355     grep_options=( --color=auto )
 356 fi
 357
 358 # utility functions
 359 # this function checks if a command exists and returns either true
 360 # or false. This avoids using 'which' and 'whence', which will
 361 # avoid problems with aliases for which on certain weird systems. :-)
 362 # Usage: check_com [-c|-g] word
 363 #   -c  only checks for external commands
 364 #   -g  does the usual tests and also checks for global aliases
 365 check_com() {
 366     emulate -L zsh
 367     local -i comonly gatoo
 368
 369     if [[ $1 == '-c' ]] ; then
 370         (( comonly = 1 ))
 371         shift
 372     elif [[ $1 == '-g' ]] ; then
 373         (( gatoo = 1 ))
 374     else
 375         (( comonly = 0 ))
 376         (( gatoo = 0 ))
 377     fi
 378
 379     if (( ${#argv} != 1 )) ; then
 380         printf 'usage: check_com [-c] <command>\n' >&2
 381         return 1
 382     fi
 383
 384     if (( comonly > 0 )) ; then
 385         [[ -n ${commands[$1]}  ]] && return 0
 386         return 1
 387     fi
 388
 389     if   [[ -n ${commands[$1]}    ]] \
 390       || [[ -n ${functions[$1]}   ]] \
 391       || [[ -n ${aliases[$1]}     ]] \
 392       || [[ -n ${reswords[(r)$1]} ]] ; then
 393
 394         return 0
 395     fi
 396
 397     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 398         return 0
 399     fi
 400
 401     return 1
 402 }
 403
 404 # creates an alias and precedes the command with
 405 # sudo if $EUID is not zero.
 406 salias() {
 407     emulate -L zsh
 408     local only=0 ; local multi=0
 409     local key val
 410     while [[ $1 == -* ]] ; do
 411         case $1 in
 412             (-o) only=1 ;;
 413             (-a) multi=1 ;;
 414             (--) shift ; break ;;
 415             (-h)
 416                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 417                 printf '  -h      shows this help text.\n'
 418                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 419                 printf '          be careful using this option.\n'
 420                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 421                 return 0
 422                 ;;
 423             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 424         esac
 425         shift
 426     done
 427
 428     if (( ${#argv} > 1 )) ; then
 429         printf 'Too many arguments %s\n' "${#argv}"
 430         return 1
 431     fi
 432
 433     key="${1%%\=*}" ;  val="${1#*\=}"
 434     if (( EUID == 0 )) && (( only == 0 )); then
 435         alias -- "${key}=${val}"
 436     elif (( EUID > 0 )) ; then
 437         (( multi > 0 )) && val="${val// ; / ; sudo }"
 438         alias -- "${key}=sudo ${val}"
 439     fi
 440
 441     return 0
 442 }
 443
 444 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 445 # usage: uprint foo
 446 #   Where foo is the *name* of the parameter you want printed.
 447 #   Note that foo is no typo; $foo would be wrong here!
 448 if ! is42 ; then
 449     uprint () {
 450         emulate -L zsh
 451         local -a u
 452         local w
 453         local parameter=$1
 454
 455         if [[ -z ${parameter} ]] ; then
 456             printf 'usage: uprint <parameter>\n'
 457             return 1
 458         fi
 459
 460         for w in ${(P)parameter} ; do
 461             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 462         done
 463
 464         builtin print -l $u
 465     }
 466 fi
 467
 468 # Check if we can read given files and source those we can.
 469 xsource() {
 470     if (( ${#argv} < 1 )) ; then
 471         printf 'usage: xsource FILE(s)...\n' >&2
 472         return 1
 473     fi
 474
 475     while (( ${#argv} > 0 )) ; do
 476         [[ -r "$1" ]] && source "$1"
 477         shift
 478     done
 479     return 0
 480 }
 481
 482 # Check if we can read a given file and 'cat(1)' it.
 483 xcat() {
 484     emulate -L zsh
 485     if (( ${#argv} != 1 )) ; then
 486         printf 'usage: xcat FILE\n' >&2
 487         return 1
 488     fi
 489
 490     [[ -r $1 ]] && cat $1
 491     return 0
 492 }
 493
 494 # Remove these functions again, they are of use only in these
 495 # setup files. This should be called at the end of .zshrc.
 496 xunfunction() {
 497     emulate -L zsh
 498     local -a funcs
 499     funcs=(salias xcat xsource xunfunction zrcautoload zrcautozle)
 500     for func in $funcs ; do
 501         [[ -n ${functions[$func]} ]] \
 502             && unfunction $func
 503     done
 504     return 0
 505 }
 506
 507 # this allows us to stay in sync with grml's zshrc and put own
 508 # modifications in ~/.zshrc.local
 509 zrclocal() {
 510     xsource "/etc/zsh/zshrc.local"
 511     xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
 512     return 0
 513 }
 514
 515 # locale setup
 516 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 517     xsource "/etc/default/locale"
 518 fi
 519
 520 for var in LANG LC_ALL LC_MESSAGES ; do
 521     [[ -n ${(P)var} ]] && export $var
 522 done
 523
 524 xsource "/etc/sysconfig/keyboard"
 525
 526 TZ=$(xcat /etc/timezone)
 527
 528 # set some variables
 529 if check_com -c vim ; then
 530 #v#
 531     export EDITOR=${EDITOR:-vim}
 532 else
 533     export EDITOR=${EDITOR:-vi}
 534 fi
 535
 536 #v#
 537 export PAGER=${PAGER:-less}
 538
 539 #v#
 540 export MAIL=${MAIL:-/var/mail/$USER}
 541
 542 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 543 export SHELL='/bin/zsh'
 544
 545 # color setup for ls:
 546 check_com -c dircolors && eval $(dircolors -b)
 547 # color setup for ls on OS X / FreeBSD:
 548 isdarwin && export CLICOLOR=1
 549 isfreebsd && export CLICOLOR=1
 550
 551 # do MacPorts setup on darwin
 552 if isdarwin && [[ -d /opt/local ]]; then
 553     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 554     # zshenv.
 555     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 556     MANPATH="/opt/local/share/man:$MANPATH"
 557 fi
 558 # do Fink setup on darwin
 559 isdarwin && xsource /sw/bin/init.sh
 560
 561 # load our function and completion directories
 562 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 563     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 564     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 565         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 566             zrcautoload ${func:t}
 567         done
 568     fi
 569 done
 570 unset fdir func
 571
 572 # support colors in less
 573 export LESS_TERMCAP_mb=$'\E[01;31m'
 574 export LESS_TERMCAP_md=$'\E[01;31m'
 575 export LESS_TERMCAP_me=$'\E[0m'
 576 export LESS_TERMCAP_se=$'\E[0m'
 577 export LESS_TERMCAP_so=$'\E[01;44;33m'
 578 export LESS_TERMCAP_ue=$'\E[0m'
 579 export LESS_TERMCAP_us=$'\E[01;32m'
 580
 581 # mailchecks
 582 MAILCHECK=30
 583
 584 # report about cpu-/system-/user-time of command if running longer than
 585 # 5 seconds
 586 REPORTTIME=5
 587
 588 # watch for everyone but me and root
 589 watch=(notme root)
 590
 591 # automatically remove duplicates from these arrays
 592 typeset -U path cdpath fpath manpath
 593
 594 # Load a few modules
 595 is4 && \
 596 for mod in parameter complist deltochar mathfunc ; do
 597     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 598 done
 599
 600 # autoload zsh modules when they are referenced
 601 if is4 ; then
 602     zmodload -a  zsh/stat    zstat
 603     zmodload -a  zsh/zpty    zpty
 604     zmodload -ap zsh/mapfile mapfile
 605 fi
 606
 607 # completion system
 608 if zrcautoload compinit ; then
 609     compinit || print 'Notice: no compinit available :('
 610 else
 611     print 'Notice: no compinit available :('
 612     function compdef { }
 613 fi
 614
 615 # completion system
 616
 617 # called later (via is4 && grmlcomp)
 618 # note: use 'zstyle' for getting current settings
 619 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
 620 grmlcomp() {
 621     # TODO: This could use some additional information
 622
 623     # Make sure the completion system is initialised
 624     (( ${+_comps} )) || return 1
 625
 626     # allow one error for every three characters typed in approximate completer
 627     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
 628
 629     # don't complete backup files as executables
 630     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
 631
 632     # start menu completion only if it could find no unambiguous initial string
 633     zstyle ':completion:*:correct:*'       insert-unambiguous true
 634     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
 635     zstyle ':completion:*:correct:*'       original true
 636
 637     # activate color-completion
 638     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
 639
 640     # format on completion
 641     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
 642
 643     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
 644     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
 645
 646     # insert all expansions for expand completer
 647     zstyle ':completion:*:expand:*'        tag-order all-expansions
 648     zstyle ':completion:*:history-words'   list false
 649
 650     # activate menu
 651     zstyle ':completion:*:history-words'   menu yes
 652
 653     # ignore duplicate entries
 654     zstyle ':completion:*:history-words'   remove-all-dups yes
 655     zstyle ':completion:*:history-words'   stop yes
 656
 657     # match uppercase from lowercase
 658     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
 659
 660     # separate matches into groups
 661     zstyle ':completion:*:matches'         group 'yes'
 662     zstyle ':completion:*'                 group-name ''
 663
 664     if [[ "$NOMENU" -eq 0 ]] ; then
 665         # if there are more than 5 options allow selecting from a menu
 666         zstyle ':completion:*'               menu select=5
 667     else
 668         # don't use any menus at all
 669         setopt no_auto_menu
 670     fi
 671
 672     zstyle ':completion:*:messages'        format '%d'
 673     zstyle ':completion:*:options'         auto-description '%d'
 674
 675     # describe options in full
 676     zstyle ':completion:*:options'         description 'yes'
 677
 678     # on processes completion complete all user processes
 679     zstyle ':completion:*:processes'       command 'ps -au$USER'
 680
 681     # offer indexes before parameters in subscripts
 682     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
 683
 684     # provide verbose completion information
 685     zstyle ':completion:*'                 verbose true
 686
 687     # recent (as of Dec 2007) zsh versions are able to provide descriptions
 688     # for commands (read: 1st word in the line) that it will list for the user
 689     # to choose from. The following disables that, because it's not exactly fast.
 690     zstyle ':completion:*:-command-:*:'    verbose false
 691
 692     # set format for warnings
 693     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
 694
 695     # define files to ignore for zcompile
 696     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
 697     zstyle ':completion:correct:'          prompt 'correct to: %e'
 698
 699     # Ignore completion functions for commands you don't have:
 700     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
 701
 702     # Provide more processes in completion of programs like killall:
 703     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
 704
 705     # complete manual by their section
 706     zstyle ':completion:*:manuals'    separate-sections true
 707     zstyle ':completion:*:manuals.*'  insert-sections   true
 708     zstyle ':completion:*:man:*'      menu yes select
 709
 710     # Search path for sudo completion
 711     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
 712                                                /usr/local/bin  \
 713                                                /usr/sbin       \
 714                                                /usr/bin        \
 715                                                /sbin           \
 716                                                /bin            \
 717                                                /usr/X11R6/bin
 718
 719     # provide .. as a completion
 720     zstyle ':completion:*' special-dirs ..
 721
 722     # run rehash on completion so new installed program are found automatically:
 723     _force_rehash() {
 724         (( CURRENT == 1 )) && rehash
 725         return 1
 726     }
 727
 728     ## correction
 729     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
 730     if [[ "$NOCOR" -gt 0 ]] ; then
 731         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
 732         setopt nocorrect
 733     else
 734         # try to be smart about when to use what completer...
 735         setopt correct
 736         zstyle -e ':completion:*' completer '
 737             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
 738                 _last_try="$HISTNO$BUFFER$CURSOR"
 739                 reply=(_complete _match _ignored _prefix _files)
 740             else
 741                 if [[ $words[1] == (rm|mv) ]] ; then
 742                     reply=(_complete _files)
 743                 else
 744                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
 745                 fi
 746             fi'
 747     fi
 748
 749     # command for process lists, the local web server details and host completion
 750     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
 751
 752     # caching
 753     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
 754                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
 755
 756     # host completion
 757     if is42 ; then
 758         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
 759         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
 760     else
 761         _ssh_hosts=()
 762         _etc_hosts=()
 763     fi
 764     hosts=(
 765         $(hostname)
 766         "$_ssh_hosts[@]"
 767         "$_etc_hosts[@]"
 768         localhost
 769     )
 770     zstyle ':completion:*:hosts' hosts $hosts
 771     # TODO: so, why is this here?
 772     #  zstyle '*' hosts $hosts
 773
 774     # use generic completion system for programs not yet defined; (_gnu_generic works
 775     # with commands that provide a --help option with "standard" gnu-like output.)
 776     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
 777                    pal stow tail uname ; do
 778         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
 779     done; unset compcom
 780
 781     # see upgrade function in this file
 782     compdef _hosts upgrade
 783 }
 784
 785 # Keyboard setup: The following is based on the same code, we wrote for
 786 # debian's setup. It ensures the terminal is in the right mode, when zle is
 787 # active, so the values from $terminfo are valid. Therefore, this setup should
 788 # work on all systems, that have support for `terminfo'. It also requires the
 789 # zsh in use to have the `zsh/terminfo' module built.
 790 #
 791 # If you are customising your `zle-line-init()' or `zle-line-finish()'
 792 # functions, make sure you call the following utility functions in there:
 793 #
 794 #     - zle-line-init():      zle-smkx
 795 #     - zle-line-finish():    zle-rmkx
 796
 797 # Use emacs-like key bindings by default:
 798 bindkey -e
 799
 800 # Custom widgets:
 801
 802 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 803 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 804 beginning-or-end-of-somewhere() {
 805     local hno=$HISTNO
 806     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 807       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 808         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 809     else
 810         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 811         if (( HISTNO != hno )); then
 812             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 813         fi
 814     fi
 815 }
 816 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 817 zle -N end-of-somewhere beginning-or-end-of-somewhere
 818
 819 ## toggle the ,. abbreviation feature on/off
 820 # NOABBREVIATION: default abbreviation-state
 821 #                 0 - enabled (default)
 822 #                 1 - disabled
 823 NOABBREVIATION=${NOABBREVIATION:-0}
 824
 825 grml_toggle_abbrev() {
 826     if (( ${NOABBREVIATION} > 0 )) ; then
 827         NOABBREVIATION=0
 828     else
 829         NOABBREVIATION=1
 830     fi
 831 }
 832 zle -N grml_toggle_abbrev
 833
 834 # add a command line to the shells history without executing it
 835 commit-to-history() {
 836     print -s ${(z)BUFFER}
 837     zle send-break
 838 }
 839 zle -N commit-to-history
 840
 841 # only slash should be considered as a word separator:
 842 slash-backward-kill-word() {
 843     local WORDCHARS="${WORDCHARS:s@/@}"
 844     # zle backward-word
 845     zle backward-kill-word
 846 }
 847 zle -N slash-backward-kill-word
 848
 849 # a generic accept-line wrapper
 850
 851 # This widget can prevent unwanted autocorrections from command-name
 852 # to _command-name, rehash automatically on enter and call any number
 853 # of builtin and user-defined widgets in different contexts.
 854 #
 855 # For a broader description, see:
 856 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 857 #
 858 # The code is imported from the file 'zsh/functions/accept-line' from
 859 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 860 # distributed under the same terms as zsh itself.
 861
 862 # A newly added command will may not be found or will cause false
 863 # correction attempts, if you got auto-correction set. By setting the
 864 # following style, we force accept-line() to rehash, if it cannot
 865 # find the first word on the command line in the $command[] hash.
 866 zstyle ':acceptline:*' rehash true
 867
 868 function Accept-Line() {
 869     setopt localoptions noksharrays
 870     local -a subs
 871     local -xi aldone
 872     local sub
 873     local alcontext=${1:-$alcontext}
 874
 875     zstyle -a ":acceptline:${alcontext}" actions subs
 876
 877     (( ${#subs} < 1 )) && return 0
 878
 879     (( aldone = 0 ))
 880     for sub in ${subs} ; do
 881         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 882         zle ${sub}
 883
 884         (( aldone > 0 )) && break
 885     done
 886 }
 887
 888 function Accept-Line-getdefault() {
 889     emulate -L zsh
 890     local default_action
 891
 892     zstyle -s ":acceptline:${alcontext}" default_action default_action
 893     case ${default_action} in
 894         ((accept-line|))
 895             printf ".accept-line"
 896             ;;
 897         (*)
 898             printf ${default_action}
 899             ;;
 900     esac
 901 }
 902
 903 function Accept-Line-HandleContext() {
 904     zle Accept-Line
 905
 906     default_action=$(Accept-Line-getdefault)
 907     zstyle -T ":acceptline:${alcontext}" call_default \
 908         && zle ${default_action}
 909 }
 910
 911 function accept-line() {
 912     setopt localoptions noksharrays
 913     local -ax cmdline
 914     local -x alcontext
 915     local buf com fname format msg default_action
 916
 917     alcontext='default'
 918     buf="${BUFFER}"
 919     cmdline=(${(z)BUFFER})
 920     com="${cmdline[1]}"
 921     fname="_${com}"
 922
 923     Accept-Line 'preprocess'
 924
 925     zstyle -t ":acceptline:${alcontext}" rehash \
 926         && [[ -z ${commands[$com]} ]]           \
 927         && rehash
 928
 929     if    [[ -n ${com}               ]] \
 930        && [[ -n ${reswords[(r)$com]} ]] \
 931        || [[ -n ${aliases[$com]}     ]] \
 932        || [[ -n ${functions[$com]}   ]] \
 933        || [[ -n ${builtins[$com]}    ]] \
 934        || [[ -n ${commands[$com]}    ]] ; then
 935
 936         # there is something sensible to execute, just do it.
 937         alcontext='normal'
 938         Accept-Line-HandleContext
 939
 940         return
 941     fi
 942
 943     if    [[ -o correct              ]] \
 944        || [[ -o correctall           ]] \
 945        && [[ -n ${functions[$fname]} ]] ; then
 946
 947         # nothing there to execute but there is a function called
 948         # _command_name; a completion widget. Makes no sense to
 949         # call it on the commandline, but the correct{,all} options
 950         # will ask for it nevertheless, so warn the user.
 951         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 952             # Okay, we warned the user before, he called us again,
 953             # so have it his way.
 954             alcontext='force'
 955             Accept-Line-HandleContext
 956
 957             return
 958         fi
 959
 960         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 961             alcontext='normal'
 962             Accept-Line-HandleContext
 963         else
 964             # prepare warning message for the user, configurable via zstyle.
 965             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 966
 967             if [[ -z ${msg} ]] ; then
 968                 msg="%c will not execute and completion %f exists."
 969             fi
 970
 971             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 972
 973             zle -M -- "${msg}"
 974         fi
 975         return
 976     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 977         # If we are here, the commandline contains something that is not
 978         # executable, which is neither subject to _command_name correction
 979         # and is not empty. might be a variable assignment
 980         alcontext='misc'
 981         Accept-Line-HandleContext
 982
 983         return
 984     fi
 985
 986     # If we got this far, the commandline only contains whitespace, or is empty.
 987     alcontext='empty'
 988     Accept-Line-HandleContext
 989 }
 990
 991 zle -N accept-line
 992 zle -N Accept-Line
 993 zle -N Accept-Line-HandleContext
 994
 995 # power completion - abbreviation expansion
 996 # power completion / abbreviation expansion / buffer expansion
 997 # see http://zshwiki.org/home/examples/zleiab for details
 998 # less risky than the global aliases but powerful as well
 999 # just type the abbreviation key and afterwards ',.' to expand it
1000 declare -A abk
1001 setopt extendedglob
1002 setopt interactivecomments
1003 abk=(
1004 #   key   # value                  (#d additional doc string)
1005 #A# start
1006     '...'  '../..'
1007     '....' '../../..'
1008     'BG'   '& exit'
1009     'C'    '| wc -l'
1010     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
1011     'H'    '| head'
1012     'Hl'   ' --help |& less -r'    #d (Display help in pager)
1013     'L'    '| less'
1014     'LL'   '|& less -r'
1015     'M'    '| most'
1016     'N'    '&>/dev/null'           #d (No Output)
1017     'R'    '| tr A-z N-za-m'       #d (ROT13)
1018     'SL'   '| sort | less'
1019     'S'    '| sort -u'
1020     'T'    '| tail'
1021     'V'    '|& vim -'
1022 #A# end
1023     'co'   './configure && make && sudo make install'
1024 )
1025
1026 zleiab() {
1027     emulate -L zsh
1028     setopt extendedglob
1029     local MATCH
1030
1031     if (( NOABBREVIATION > 0 )) ; then
1032         LBUFFER="${LBUFFER},."
1033         return 0
1034     fi
1035
1036     LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
1037     LBUFFER+=${abk[$MATCH]:-$MATCH}
1038 }
1039
1040 zle -N zleiab
1041
1042 help-show-abk()
1043 {
1044   zle -M "$(print "Type ,. after these abbreviations to expand them:"; print -a -C 2 ${(kv)abk})"
1045 }
1046
1047 zle -N help-show-abk
1048
1049 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1050 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1051 zle -N insert-datestamp
1052
1053 # press esc-m for inserting last typed word again (thanks to caphuso!)
1054 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1055 zle -N insert-last-typed-word;
1056
1057 function grml-zsh-fg() {
1058   if (( ${#jobstates} )); then
1059     zle .push-input
1060     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1061     BUFFER="${BUFFER}fg"
1062     zle .accept-line
1063   else
1064     zle -M 'No background jobs. Doing nothing.'
1065   fi
1066 }
1067 zle -N grml-zsh-fg
1068
1069 # run command line as user root via sudo:
1070 sudo-command-line() {
1071     [[ -z $BUFFER ]] && zle up-history
1072     if [[ $BUFFER != sudo\ * ]]; then
1073         BUFFER="sudo $BUFFER"
1074         CURSOR=$(( CURSOR+5 ))
1075     fi
1076 }
1077 zle -N sudo-command-line
1078
1079 ### jump behind the first word on the cmdline.
1080 ### useful to add options.
1081 function jump_after_first_word() {
1082     local words
1083     words=(${(z)BUFFER})
1084
1085     if (( ${#words} <= 1 )) ; then
1086         CURSOR=${#BUFFER}
1087     else
1088         CURSOR=${#${words[1]}}
1089     fi
1090 }
1091 zle -N jump_after_first_word
1092
1093 #f5# Create directory under cursor or the selected area
1094 inplaceMkDirs() {
1095     # Press ctrl-xM to create the directory under the cursor or the selected area.
1096     # To select an area press ctrl-@ or ctrl-space and use the cursor.
1097     # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
1098     # directory does not exist yet -> press ctrl-XM and problem solved
1099     local PATHTOMKDIR
1100     if ((REGION_ACTIVE==1)); then
1101         local F=$MARK T=$CURSOR
1102         if [[ $F -gt $T ]]; then
1103             F=${CURSOR}
1104             T=${MARK}
1105         fi
1106         # get marked area from buffer and eliminate whitespace
1107         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
1108         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
1109     else
1110         local bufwords iword
1111         bufwords=(${(z)LBUFFER})
1112         iword=${#bufwords}
1113         bufwords=(${(z)BUFFER})
1114         PATHTOMKDIR="${(Q)bufwords[iword]}"
1115     fi
1116     [[ -z "${PATHTOMKDIR}" ]] && return 1
1117     PATHTOMKDIR=${~PATHTOMKDIR}
1118     if [[ -e "${PATHTOMKDIR}" ]]; then
1119         zle -M " path already exists, doing nothing"
1120     else
1121         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
1122         zle end-of-line
1123     fi
1124 }
1125
1126 #k# mkdir -p <dir> from string under cursor or marked area
1127 zle -N inplaceMkDirs
1128
1129 #v1# set number of lines to display per page
1130 HELP_LINES_PER_PAGE=20
1131 #v1# set location of help-zle cache file
1132 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
1133 # helper function for help-zle, actually generates the help text
1134 help_zle_parse_keybindings()
1135 {
1136     emulate -L zsh
1137     setopt extendedglob
1138     unsetopt ksharrays  #indexing starts at 1
1139
1140     #v1# choose files that help-zle will parse for keybindings
1141     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
1142
1143     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
1144         local load_cache=0
1145         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
1146         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
1147     fi
1148
1149     #fill with default keybindings, possibly to be overwriten in a file later
1150     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
1151     local -A help_zle_keybindings
1152     help_zle_keybindings['<Ctrl>@']="set MARK"
1153     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
1154     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
1155     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
1156     help_zle_keybindings['<Ctrl>_']="undo"
1157     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
1158     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
1159     help_zle_keybindings['<Ctrl>e']="goto end of line"
1160     help_zle_keybindings['<Ctrl>t']="transpose charaters"
1161     help_zle_keybindings['<Alt>t']="transpose words"
1162     help_zle_keybindings['<Alt>s']="spellcheck word"
1163     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
1164     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
1165     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
1166     help_zle_keybindings["<Alt>'"]="quote line"
1167     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
1168     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
1169     help_zle_keybindings['<Alt>u']="make next word Uppercase"
1170     help_zle_keybindings['<Alt>l']="make next word lowercase"
1171     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
1172     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
1173     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
1174     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
1175     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
1176     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
1177     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
1178     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
1179     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
1180
1181     #init global variables
1182     unset help_zle_lines help_zle_sln
1183     typeset -g -a help_zle_lines
1184     typeset -g help_zle_sln=1
1185
1186     local k v
1187     local lastkeybind_desc contents     #last description starting with #k# that we found
1188     local num_lines_elapsed=0            #number of lines between last description and keybinding
1189     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
1190     for f in $HELPZLE_KEYBINDING_FILES; do
1191         [[ -r "$f" ]] || continue   #not readable ? skip it
1192         contents="$(<$f)"
1193         for cline in "${(f)contents}"; do
1194             #zsh pattern: matches lines like: #k# ..............
1195             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
1196                 lastkeybind_desc="$match[*]"
1197                 num_lines_elapsed=0
1198             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
1199             #             ignores lines that are commentend out
1200             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
1201             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
1202                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
1203                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
1204                     #substitute keybinding string with something readable
1205                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
1206                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
1207                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
1208                     help_zle_keybindings[${k}]=$lastkeybind_desc
1209                 fi
1210                 lastkeybind_desc=""
1211             else
1212               ((num_lines_elapsed++))
1213             fi
1214         done
1215     done
1216     unset contents
1217     #calculate length of keybinding column
1218     local kstrlen=0
1219     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
1220     #convert the assoc array into preformated lines, which we are able to sort
1221     for k v in ${(kv)help_zle_keybindings[@]}; do
1222         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
1223         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
1224     done
1225     #sort lines alphabetically
1226     help_zle_lines=("${(i)help_zle_lines[@]}")
1227     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
1228     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
1229     zcompile $HELP_ZLE_CACHE_FILE
1230 }
1231 typeset -g help_zle_sln
1232 typeset -g -a help_zle_lines
1233
1234 # Provides (partially autogenerated) help on keybindings and the zsh line editor
1235 help-zle()
1236 {
1237     emulate -L zsh
1238     unsetopt ksharrays  #indexing starts at 1
1239     #help lines already generated ? no ? then do it
1240     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
1241     #already displayed all lines ? go back to the start
1242     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
1243     local sln=$help_zle_sln
1244     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
1245     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
1246     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
1247 }
1248 zle -N help-zle
1249
1250 ## complete word from currently visible Screen or Tmux buffer.
1251 if check_com -c screen || check_com -c tmux; then
1252     _complete_screen_display() {
1253         [[ "$TERM" != "screen" ]] && return 1
1254
1255         local TMPFILE=$(mktemp)
1256         local -U -a _screen_display_wordlist
1257         trap "rm -f $TMPFILE" EXIT
1258
1259         # fill array with contents from screen hardcopy
1260         if ((${+TMUX})); then
1261             #works, but crashes tmux below version 1.4
1262             #luckily tmux -V option to ask for version, was also added in 1.4
1263             tmux -V &>/dev/null || return
1264             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1265         else
1266             screen -X hardcopy $TMPFILE
1267             # screen sucks, it dumps in latin1, apparently always. so recode it
1268             # to system charset
1269             check_com recode && recode latin1 $TMPFILE
1270         fi
1271         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1272         # remove PREFIX to be completed from that array
1273         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1274         compadd -a _screen_display_wordlist
1275     }
1276     #m# k CTRL-x\,\,\,S Complete word from GNU screen buffer
1277     bindkey -r "^xS"
1278     compdef -k _complete_screen_display complete-word '^xS'
1279 fi
1280
1281 # Load a few more functions and tie them to widgets, so they can be bound:
1282
1283 function zrcautozle() {
1284     emulate -L zsh
1285     local fnc=$1
1286     zrcautoload $fnc && zle -N $fnc
1287 }
1288
1289 function zrcgotwidget() {
1290     (( ${+widgets[$1]} ))
1291 }
1292
1293 function zrcgotkeymap() {
1294     [[ -n ${(M)keymaps:#$1} ]]
1295 }
1296
1297 zrcautozle insert-files
1298 zrcautozle edit-command-line
1299 zrcautozle insert-unicode-char
1300 if zrcautoload history-search-end; then
1301     zle -N history-beginning-search-backward-end history-search-end
1302     zle -N history-beginning-search-forward-end  history-search-end
1303 fi
1304 zle -C hist-complete complete-word _generic
1305 zstyle ':completion:hist-complete:*' completer _history
1306
1307 # The actual terminal setup hooks and bindkey-calls:
1308
1309 # An array to note missing features to ease diagnosis in case of problems.
1310 typeset -ga grml_missing_features
1311
1312 function zrcbindkey() {
1313     if (( ARGC )) && zrcgotwidget ${argv[-1]}; then
1314         bindkey "$@"
1315     fi
1316 }
1317
1318 function bind2maps () {
1319     local i sequence widget
1320     local -a maps
1321
1322     while [[ "$1" != "--" ]]; do
1323         maps+=( "$1" )
1324         shift
1325     done
1326     shift
1327
1328     if [[ "$1" == "-s" ]]; then
1329         shift
1330         sequence="$1"
1331     else
1332         sequence="${key[$1]}"
1333     fi
1334     widget="$2"
1335
1336     [[ -z "$sequence" ]] && return 1
1337
1338     for i in "${maps[@]}"; do
1339         zrcbindkey -M "$i" "$sequence" "$widget"
1340     done
1341 }
1342
1343 if (( ${+terminfo[smkx]} )) && (( ${+terminfo[rmkx]} )); then
1344     function zle-smkx () {
1345         printf '%s' ${terminfo[smkx]}
1346     }
1347     function zle-rmkx () {
1348         printf '%s' ${terminfo[rmkx]}
1349     }
1350     function zle-line-init () {
1351         zle-smkx
1352     }
1353     function zle-line-finish () {
1354         zle-rmkx
1355     }
1356     zle -N zle-line-init
1357     zle -N zle-line-finish
1358 else
1359     for i in {s,r}mkx; do
1360         (( ${+terminfo[$i]} )) || grml_missing_features+=($i)
1361     done
1362     unset i
1363 fi
1364
1365 typeset -A key
1366 key=(
1367     Home     "${terminfo[khome]}"
1368     End      "${terminfo[kend]}"
1369     Insert   "${terminfo[kich1]}"
1370     Delete   "${terminfo[kdch1]}"
1371     Up       "${terminfo[kcuu1]}"
1372     Down     "${terminfo[kcud1]}"
1373     Left     "${terminfo[kcub1]}"
1374     Right    "${terminfo[kcuf1]}"
1375     PageUp   "${terminfo[kpp]}"
1376     PageDown "${terminfo[knp]}"
1377     BackTab  "${terminfo[kcbt]}"
1378 )
1379
1380 # Guidelines for adding key bindings:
1381 #
1382 #   - Do not add hardcoded escape sequences, to enable non standard key
1383 #     combinations such as Ctrl-Meta-Left-Cursor. They are not easily portable.
1384 #
1385 #   - Adding Ctrl characters, such as '^b' is okay; note that '^b' and '^B' are
1386 #     the same key.
1387 #
1388 #   - All keys from the $key[] mapping are obviously okay.
1389 #
1390 #   - Most terminals send "ESC x" when Meta-x is pressed. Thus, sequences like
1391 #     '\ex' are allowed in here as well.
1392
1393 bind2maps emacs             -- Home   beginning-of-somewhere
1394 bind2maps       viins vicmd -- Home   vi-beginning-of-line
1395 bind2maps emacs             -- End    end-of-somewhere
1396 bind2maps       viins vicmd -- End    vi-end-of-line
1397 bind2maps emacs viins       -- Insert overwrite-mode
1398 bind2maps             vicmd -- Insert vi-insert
1399 bind2maps emacs             -- Delete delete-char
1400 bind2maps       viins vicmd -- Delete vi-delete-char
1401 bind2maps emacs viins vicmd -- Up     up-line-or-search
1402 bind2maps emacs viins vicmd -- Down   down-line-or-search
1403 bind2maps emacs             -- Left   backward-char
1404 bind2maps       viins vicmd -- Left   vi-backward-char
1405 bind2maps emacs             -- Right  forward-char
1406 bind2maps       viins vicmd -- Right  vi-forward-char
1407 bind2maps       viins vicmd -- Right  vi-forward-char
1408 #k# Display list of abbreviations that expand when followed by ,.
1409 bind2maps emacs viins       -- -s ',.' zleiab
1410 bind2maps emacs viins       -- -s '^xb' help-show-abk
1411 bind2maps emacs viins       -- -s '^xM' inplaceMkDirs
1412 #k# display help for keybindings and ZLE
1413 bind2maps emacs viins       -- -s '^xz' help-zle
1414 #k# Insert files and test globbing
1415 bind2maps emacs viins       -- -s "^xf" insert-files
1416 #k# Edit the current line in \kbd{\$EDITOR}
1417 bind2maps emacs viins       -- -s '\ee' edit-command-line
1418 #k# search history backward for entry beginning with typed text
1419 bind2maps emacs viins       -- -s '^xp' history-beginning-search-backward-end
1420 #k# search history forward for entry beginning with typed text
1421 bind2maps emacs viins       -- -s '^xP' history-beginning-search-forward-end
1422 #k# search history backward for entry beginning with typed text
1423 bind2maps emacs viins       -- PageUp history-beginning-search-backward-end
1424 #k# search history forward for entry beginning with typed text
1425 bind2maps emacs viins       -- PageDown history-beginning-search-forward-end
1426 #k# Toggle abbreviation expansion on/off
1427 bind2maps emacs viins       -- -s '^xA' grml_toggle_abbrev
1428 bind2maps emacs viins       -- -s "^x^h" commit-to-history
1429 #k# Kill left-side word or everything up to next slash
1430 bind2maps emacs viins       -- -s '\ev' slash-backward-kill-word
1431 #k# Kill left-side word or everything up to next slash
1432 bind2maps emacs viins       -- -s '\e^h' slash-backward-kill-word
1433 #k# Kill left-side word or everything up to next slash
1434 bind2maps emacs viins       -- -s '\e^?' slash-backward-kill-word
1435 # Do history expansion on space:
1436 bind2maps emacs viins       -- -s ' ' magic-space
1437 #k# Trigger menu-complete
1438 bind2maps emacs viins       -- -s '\ei' menu-complete  # menu completion via esc-i
1439 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1440 bind2maps emacs viins       -- -s '^ed' insert-datestamp
1441 #k# Insert last typed word
1442 bind2maps emacs viins       -- -s "\em" insert-last-typed-word
1443 #k# A smart shortcut for \kbd{fg<enter>}
1444 bind2maps emacs viins       -- -s '^z' grml-zsh-fg
1445 #k# prepend the current command with "sudo"
1446 bind2maps emacs viins       -- -s "^os" sudo-command-line
1447 #k# jump to after first word (for adding options)
1448 bind2maps emacs viins       -- -s '^x1' jump_after_first_word
1449 #k# complete word from history with menu
1450 bind2maps emacs viins       -- -s "^x^x" hist-complete
1451
1452 # insert unicode character
1453 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
1454 # See for example http://unicode.org/charts/ for unicode characters code
1455 #k# Insert Unicode character
1456 bind2maps emacs viins       -- -s '^xi' insert-unicode-char
1457
1458 # use the new *-pattern-* widgets for incremental history search
1459 if zrcgotwidget history-incremental-pattern-search-backward; then
1460     for seq wid in '^r' history-incremental-pattern-search-backward \
1461                    '^s' history-incremental-pattern-search-forward
1462     do
1463         bind2maps emacs viins vicmd -- -s $seq $wid
1464     done
1465 fi
1466
1467 if zrcgotkeymap menuselect; then
1468     #m# k Shift-tab Perform backwards menu completion
1469     bind2maps menuselect -- BackTab reverse-menu-complete
1470
1471     #k# menu selection: pick item but stay in the menu
1472     bind2maps menuselect -- -s '\e^M' accept-and-menu-complete
1473     # also use + and INSERT since it's easier to press repeatedly
1474     bind2maps menuselect -- -s '+' accept-and-menu-complete
1475     bind2maps menuselect -- Insert accept-and-menu-complete
1476
1477     # accept a completion and try to complete again by using menu
1478     # completion; very useful with completing directories
1479     # by using 'undo' one's got a simple file browser
1480     bind2maps menuselect -- -s '^o' accept-and-infer-next-history
1481 fi
1482
1483 # Finally, here are still a few hardcoded escape sequences; Special sequences
1484 # like Ctrl-<Cursor-key> etc do suck a fair bit, because they are not
1485 # standardised and most of the time are not available in a terminals terminfo
1486 # entry.
1487 #
1488 # While we do not encourage adding bindings like these, we will keep these for
1489 # backward compatibility.
1490
1491 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on
1492 ## the command line.
1493 # URxvt sequences:
1494 bind2maps emacs viins vicmd -- -s '\eOc' forward-word
1495 bind2maps emacs viins vicmd -- -s '\eOd' backward-word
1496 # These are for xterm:
1497 bind2maps emacs viins vicmd -- -s '\e[1;5C' forward-word
1498 bind2maps emacs viins vicmd -- -s '\e[1;5D' backward-word
1499 ## the same for alt-left-arrow and alt-right-arrow
1500 # URxvt again:
1501 bind2maps emacs viins vicmd -- -s '\e\e[C' forward-word
1502 bind2maps emacs viins vicmd -- -s '\e\e[D' backward-word
1503 # Xterm again:
1504 bind2maps emacs viins vicmd -- -s '^[[1;3C' forward-word
1505 bind2maps emacs viins vicmd -- -s '^[[1;3D' backward-word
1506 # Also try ESC Left/Right:
1507 bind2maps emacs viins vicmd -- -s '\e'${key[Right]} forward-word
1508 bind2maps emacs viins vicmd -- -s '\e'${key[Left]}  backward-word
1509
1510 # autoloading
1511
1512 zrcautoload zmv
1513 zrcautoload zed
1514
1515 # we don't want to quote/espace URLs on our own...
1516 # if autoload -U url-quote-magic ; then
1517 #    zle -N self-insert url-quote-magic
1518 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
1519 # else
1520 #    print 'Notice: no url-quote-magic available :('
1521 # fi
1522 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
1523
1524 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
1525 alias run-help >&/dev/null && unalias run-help
1526 for rh in run-help{,-git,-svk,-svn}; do
1527     zrcautoload $rh
1528 done; unset rh
1529
1530 # command not found handling
1531
1532 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1533 function command_not_found_handler() {
1534     emulate -L zsh
1535     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1536         ${GRML_ZSH_CNF_HANDLER} $1
1537     fi
1538     return 1
1539 }
1540
1541 # history
1542
1543 ZSHDIR=${ZDOTDIR:-${HOME}/.zsh}
1544
1545 #v#
1546 HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1547 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1548 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1549
1550 # dirstack handling
1551
1552 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1553 DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1554
1555 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1556     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1557     # "cd -" won't work after login by just setting $OLDPWD, so
1558     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1559 fi
1560
1561 chpwd() {
1562     local -ax my_stack
1563     my_stack=( ${PWD} ${dirstack} )
1564     if is42 ; then
1565         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1566     else
1567         uprint my_stack >! ${DIRSTACKFILE}
1568     fi
1569 }
1570
1571 # directory based profiles
1572
1573 if is433 ; then
1574
1575 # chpwd_profiles(): Directory Profiles, Quickstart:
1576 #
1577 # In .zshrc.local:
1578 #
1579 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1580 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1581 #   chpwd_profiles
1582 #
1583 # For details see the `grmlzshrc.5' manual page.
1584 function chpwd_profiles() {
1585     local profile context
1586     local -i reexecute
1587
1588     context=":chpwd:profiles:$PWD"
1589     zstyle -s "$context" profile profile || profile='default'
1590     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1591
1592     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1593         typeset -g CHPWD_PROFILE
1594         local CHPWD_PROFILES_INIT=1
1595         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1596     elif [[ $profile != $CHPWD_PROFILE ]]; then
1597         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1598             && chpwd_leave_profile_${CHPWD_PROFILE}
1599     fi
1600     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1601         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1602     fi
1603
1604     CHPWD_PROFILE="${profile}"
1605     return 0
1606 }
1607
1608 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1609
1610 fi # is433
1611
1612 # Prompt setup for grml:
1613
1614 # set colors for use in prompts (modern zshs allow for the use of %F{red}foo%f
1615 # in prompts to get a red "foo" embedded, but it's good to keep these for
1616 # backwards compatibility).
1617 if zrcautoload colors && colors 2>/dev/null ; then
1618     BLUE="%{${fg[blue]}%}"
1619     RED="%{${fg_bold[red]}%}"
1620     GREEN="%{${fg[green]}%}"
1621     CYAN="%{${fg[cyan]}%}"
1622     MAGENTA="%{${fg[magenta]}%}"
1623     YELLOW="%{${fg[yellow]}%}"
1624     WHITE="%{${fg[white]}%}"
1625     NO_COLOR="%{${reset_color}%}"
1626 else
1627     BLUE=$'%{\e[1;34m%}'
1628     RED=$'%{\e[1;31m%}'
1629     GREEN=$'%{\e[1;32m%}'
1630     CYAN=$'%{\e[1;36m%}'
1631     WHITE=$'%{\e[1;37m%}'
1632     MAGENTA=$'%{\e[1;35m%}'
1633     YELLOW=$'%{\e[1;33m%}'
1634     NO_COLOR=$'%{\e[0m%}'
1635 fi
1636
1637 # First, the easy ones: PS2..4:
1638
1639 # secondary prompt, printed when the shell needs more information to complete a
1640 # command.
1641 PS2='\`%_> '
1642 # selection prompt used within a select loop.
1643 PS3='?# '
1644 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1645 PS4='+%N:%i:%_> '
1646
1647 # Some additional features to use with our prompt:
1648 #
1649 #    - battery status
1650 #    - debian_chroot
1651 #    - vcs_info setup and version specific fixes
1652
1653 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1654 if [[ $BATTERY -gt 0 ]] ; then
1655     if ! check_com -c acpi ; then
1656         BATTERY=0
1657     fi
1658 fi
1659
1660 battery() {
1661 if [[ $BATTERY -gt 0 ]] ; then
1662     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1663     if [[ -z "$PERCENT" ]] ; then
1664         PERCENT='acpi not present'
1665     else
1666         if [[ "$PERCENT" -lt 20 ]] ; then
1667             PERCENT="warning: ${PERCENT}%%"
1668         else
1669             PERCENT="${PERCENT}%%"
1670         fi
1671     fi
1672 fi
1673 }
1674
1675 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1676 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1677     debian_chroot=$(</etc/debian_chroot)
1678 fi
1679
1680 # gather version control information for inclusion in a prompt
1681
1682 if zrcautoload vcs_info; then
1683     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1684     # function, which can cause a lot of trouble with our directory-based
1685     # profiles. So:
1686     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1687         function VCS_INFO_realpath () {
1688             setopt localoptions NO_shwordsplit chaselinks
1689             ( builtin cd -q $1 2> /dev/null && pwd; )
1690         }
1691     fi
1692
1693     zstyle ':vcs_info:*' max-exports 2
1694
1695     if [[ -o restricted ]]; then
1696         zstyle ':vcs_info:*' enable NONE
1697     fi
1698 fi
1699
1700 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1701 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1702 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1703 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1704 #       to $vcs_info_msg_N_ as soon as we use the included version.
1705 if [[ "$TERM" == dumb ]] ; then
1706     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1707     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1708 else
1709     # these are the same, just with a lot of colors:
1710     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} " \
1711                                        "zsh: %r"
1712     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR}%} " \
1713                                        "zsh: %r"
1714     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1715 fi
1716
1717 # Now for the fun part: The grml prompt themes in `promptsys' mode of operation
1718
1719 # This actually defines three prompts:
1720 #
1721 #    - grml
1722 #    - grml-large
1723 #    - grml-chroot
1724 #
1725 # They all share the same code and only differ with respect to which items they
1726 # contain. The main source of documentation is the `prompt_grml_help' function
1727 # below, which gets called when the user does this: prompt -h grml
1728
1729 function prompt_grml_help () {
1730     cat <<__EOF0__
1731   prompt grml
1732
1733     This is the prompt as used by the grml-live system <http://grml.org>. It is
1734     a rather simple one-line prompt, that by default looks something like this:
1735
1736         <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1737
1738     The prompt itself integrates with zsh's prompt themes system (as you are
1739     witnessing right now) and is configurable to a certain degree. In
1740     particular, these aspects are customisable:
1741
1742         - The items used in the prompt (e.g. you can remove \`user' from
1743           the list of activated items, which will cause the user name to
1744           be omitted from the prompt string).
1745
1746         - The attributes used with the items are customisable via strings
1747           used before and after the actual item.
1748
1749     The available items are: at, battery, change-root, date, grml-chroot,
1750     history, host, jobs, newline, path, percent, rc, rc-always, sad-smiley,
1751     shell-level, time, user, vcs
1752
1753     The actual configuration is done via zsh's \`zstyle' mechanism. The
1754     context, that is used while looking up styles is:
1755
1756         ':prompt:grml:<left-or-right>:<subcontext>'
1757
1758     Here <left-or-right> is either \`left' or \`right', signifying whether the
1759     style should affect the left or the right prompt. <subcontext> is either
1760     \`setup' or 'items:<item>', where \`<item>' is one of the available items.
1761
1762     The styles:
1763
1764         - use-rprompt (boolean): If \`true' (the default), print a sad smiley
1765           in $RPROMPT if the last command a returned non-successful error code.
1766           (This in only valid if <left-or-right> is "right"; ignored otherwise)
1767
1768         - items (list): The list of items used in the prompt. If \`vcs' is
1769           present in the list, the theme's code invokes \`vcs_info'
1770           accordingly. Default (left): rc change-root user at host path vcs
1771           percent; Default (right): sad-smiley
1772
1773     Available styles in 'items:<item>' are: pre, post. These are strings that
1774     are inserted before (pre) and after (post) the item in question. Thus, the
1775     following would cause the user name to be printed in red instead of the
1776     default blue:
1777
1778         zstyle ':prompt:grml:*:items:user' pre '%F{red}'
1779
1780     Note, that the \`post' style may remain at its default value, because its
1781     default value is '%f', which turns the foreground text attribute off (which
1782     is exactly, what is still required with the new \`pre' value).
1783 __EOF0__
1784 }
1785
1786 function prompt_grml-chroot_help () {
1787     cat <<__EOF0__
1788   prompt grml-chroot
1789
1790     This is a variation of the grml prompt, see: prompt -h grml
1791
1792     The main difference is the default value of the \`items' style. The rest
1793     behaves exactly the same. Here are the defaults for \`grml-chroot':
1794
1795         - left: grml-chroot user at host path percent
1796         - right: (empty list)
1797 __EOF0__
1798 }
1799
1800 function prompt_grml-large_help () {
1801     cat <<__EOF0__
1802   prompt grml-large
1803
1804     This is a variation of the grml prompt, see: prompt -h grml
1805
1806     The main difference is the default value of the \`items' style. In
1807     particular, this theme uses _two_ lines instead of one with the plain
1808     \`grml' theme. The rest behaves exactly the same. Here are the defaults
1809     for \`grml-large':
1810
1811         - left: rc jobs history shell-level change-root time date newline user
1812                 at host path vcs percent
1813         - right: sad-smiley
1814 __EOF0__
1815 }
1816
1817 function grml_prompt_setup () {
1818     emulate -L zsh
1819     autoload -Uz vcs_info
1820     autoload -Uz add-zsh-hook
1821     add-zsh-hook precmd prompt_$1_precmd
1822 }
1823
1824 function prompt_grml_setup () {
1825     grml_prompt_setup grml
1826 }
1827
1828 function prompt_grml-chroot_setup () {
1829     grml_prompt_setup grml-chroot
1830 }
1831
1832 function prompt_grml-large_setup () {
1833     grml_prompt_setup grml-large
1834 }
1835
1836 # These maps define default tokens and pre-/post-decoration for items to be
1837 # used within the themes. All defaults may be customised in a context sensitive
1838 # matter by using zsh's `zstyle' mechanism.
1839 typeset -gA grml_prompt_pre_default \
1840             grml_prompt_post_default \
1841             grml_prompt_token_default \
1842             grml_prompt_token_function
1843
1844 grml_prompt_pre_default=(
1845     at                ''
1846     battery           ' '
1847     change-root       ''
1848     date              '%F{blue}'
1849     grml-chroot       '%F{red}'
1850     history           '%F{green}'
1851     host              ''
1852     jobs              '%F{cyan}'
1853     newline           ''
1854     path              '%B'
1855     percent           ''
1856     rc                '%F{red}'
1857     rc-always         ''
1858     sad-smiley        ''
1859     shell-level       '%F{red}'
1860     time              '%F{blue}'
1861     user              '%B%F{blue}'
1862     vcs               ''
1863 )
1864
1865 grml_prompt_post_default=(
1866     at                ''
1867     battery           ''
1868     change-root       ''
1869     date              '%f'
1870     grml-chroot       '%f '
1871     history           '%f'
1872     host              ''
1873     jobs              '%f'
1874     newline           ''
1875     path              '%b'
1876     percent           ''
1877     rc                '%f'
1878     rc-always         ''
1879     sad-smiley        ''
1880     shell-level       '%f'
1881     time              '%f'
1882     user              '%f%b'
1883     vcs               ''
1884 )
1885
1886 grml_prompt_token_default=(
1887     at                '@'
1888     battery           'PERCENT'
1889     change-root       'debian_chroot'
1890     date              '%D{%Y-%m-%d}'
1891     grml-chroot       'GRML_CHROOT'
1892     history           '{history#%!} '
1893     host              '%m '
1894     jobs              '[%j running job(s)] '
1895     newline           $'\n'
1896     path              '%40<..<%~%<< '
1897     percent           '%# '
1898     rc                '%(?..%? )'
1899     rc-always         '%?'
1900     sad-smiley        '%(?..:()'
1901     shell-level       '%(3L.+ .)'
1902     time              '%D{%H:%M:%S} '
1903     user              '%n'
1904     vcs               '0'
1905 )
1906
1907 function GRML_theme_add_token_usage () {
1908     cat <<__EOF__
1909   Usage: grml_theme_add_token <name> [-f|-i] <token/function> [<pre> <post>]
1910
1911     <name> is the name for the newly added token. If the \`-f' or \`-i' options
1912     are used, <token/function> is the name of the function (see below for
1913     details). Otherwise it is the literal token string to be used. <pre> and
1914     <post> are optional.
1915
1916   Options:
1917
1918     -f <function>   Use a function named \`<function>' each time the token
1919                     is to be expanded.
1920
1921     -i <function>   Use a function named \`<function>' to initialise the
1922                     value of the token _once_ at runtime.
1923
1924     The functions are called with one argument: the token's new name. The
1925     return value is expected in the \$REPLY parameter. The use of these
1926     options is mutually exclusive.
1927
1928   Example:
1929
1930     To add a new token \`day' that expands to the current weekday in the
1931     current locale in green foreground colour, use this:
1932
1933       grml_theme_add_token day '%D{%A}' '%F{green}' '%f'
1934
1935     Another example would be support for \$VIRTUAL_ENV:
1936
1937       function virtual_env_prompt () {
1938         REPLY=\${VIRTUAL_ENV+\${VIRTUAL_ENV:t} }
1939       }
1940       grml_theme_add_token virtual-env -f virtual_env_prompt
1941
1942     After that, you will be able to use a changed \`items' style to
1943     assemble your prompt.
1944 __EOF__
1945 }
1946
1947 function grml_theme_add_token () {
1948     emulate -L zsh
1949     local name token pre post
1950     local -i init funcall
1951
1952     if (( ARGC == 0 )); then
1953         GRML_theme_add_token_usage
1954         return 0
1955     fi
1956
1957     init=0
1958     funcall=0
1959     pre=''
1960     post=''
1961     name=$1
1962     shift
1963     if [[ $1 == '-f' ]]; then
1964         funcall=1
1965         shift
1966     elif [[ $1 == '-i' ]]; then
1967         init=1
1968         shift
1969     fi
1970
1971     if (( ARGC == 0 )); then
1972         printf '
1973 grml_theme_add_token: No token-string/function-name provided!\n\n'
1974         GRML_theme_add_token_usage
1975         return 1
1976     fi
1977     token=$1
1978     shift
1979     if (( ARGC != 0 && ARGC != 2 )); then
1980         printf '
1981 grml_theme_add_token: <pre> and <post> need to by specified _both_!\n\n'
1982         GRML_theme_add_token_usage
1983         return 1
1984     fi
1985     if (( ARGC )); then
1986         pre=$1
1987         post=$2
1988         shift 2
1989     fi
1990
1991     if (( ${+grml_prompt_token_default[$name]} )); then
1992         printf '
1993 grml_theme_add_token: Token `%s'\'' exists! Giving up!\n\n' $name
1994         GRML_theme_add_token_usage
1995         return 2
1996     fi
1997     if (( init )); then
1998         $token $name
1999         token=$REPLY
2000     fi
2001     grml_prompt_pre_default[$name]=$pre
2002     grml_prompt_post_default[$name]=$post
2003     if (( funcall )); then
2004         grml_prompt_token_function[$name]=$token
2005         grml_prompt_token_default[$name]=23
2006     else
2007         grml_prompt_token_default[$name]=$token
2008     fi
2009 }
2010
2011 function grml_typeset_and_wrap () {
2012     emulate -L zsh
2013     local target="$1"
2014     local new="$2"
2015     local left="$3"
2016     local right="$4"
2017
2018     if (( ${+parameters[$new]} )); then
2019         typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
2020     fi
2021 }
2022
2023 function grml_prompt_addto () {
2024     emulate -L zsh
2025     local target="$1"
2026     local lr it apre apost new v
2027     local -a items
2028     shift
2029
2030     [[ $target == PS1 ]] && lr=left || lr=right
2031     zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
2032     typeset -g "${target}="
2033     for it in "${items[@]}"; do
2034         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
2035             || apre=${grml_prompt_pre_default[$it]}
2036         zstyle -s ":prompt:grml:${grmltheme}:${lr}:$it" post apost \
2037             || apost=${grml_prompt_post_default[$it]}
2038         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
2039             || new=${grml_prompt_token_default[$it]}
2040         typeset -g "${target}=${(P)target}${apre}"
2041         if (( ${+grml_prompt_token_function[$it]} )); then
2042             ${grml_prompt_token_function[$it]} $it
2043             typeset -g "${target}=${(P)target}${REPLY}"
2044         else
2045             case $it in
2046             battery)
2047                 grml_typeset_and_wrap $target $new '' ''
2048                 ;;
2049             change-root)
2050                 grml_typeset_and_wrap $target $new '(' ')'
2051                 ;;
2052             grml-chroot)
2053                 if [[ -n ${(P)new} ]]; then
2054                     typeset -g "${target}=${(P)target}(CHROOT)"
2055                 fi
2056                 ;;
2057             vcs)
2058                 v="vcs_info_msg_${new}_"
2059                 if (( ! vcscalled )); then
2060                     vcs_info
2061                     vcscalled=1
2062                 fi
2063                 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
2064                     typeset -g "${target}=${(P)target}${(P)v}"
2065                 fi
2066                 ;;
2067             *) typeset -g "${target}=${(P)target}${new}" ;;
2068             esac
2069         fi
2070         typeset -g "${target}=${(P)target}${apost}"
2071     done
2072 }
2073
2074 function prompt_grml_precmd () {
2075     emulate -L zsh
2076     local grmltheme=grml
2077     local -a left_items right_items
2078     left_items=(rc change-root user at host path vcs percent)
2079     right_items=(sad-smiley)
2080
2081     prompt_grml_precmd_worker
2082 }
2083
2084 function prompt_grml-chroot_precmd () {
2085     emulate -L zsh
2086     local grmltheme=grml-chroot
2087     local -a left_items right_items
2088     left_items=(grml-chroot user at host path percent)
2089     right_items=()
2090
2091     prompt_grml_precmd_worker
2092 }
2093
2094 function prompt_grml-large_precmd () {
2095     emulate -L zsh
2096     local grmltheme=grml-large
2097     local -a left_items right_items
2098     left_items=(rc jobs history shell-level change-root time date newline
2099                 user at host path vcs percent)
2100     right_items=(sad-smiley)
2101
2102     prompt_grml_precmd_worker
2103 }
2104
2105 function prompt_grml_precmd_worker () {
2106     emulate -L zsh
2107     local -i vcscalled=0
2108
2109     grml_prompt_addto PS1 "${left_items[@]}"
2110     if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
2111         grml_prompt_addto RPS1 "${right_items[@]}"
2112     fi
2113 }
2114
2115 grml_prompt_fallback() {
2116     setopt prompt_subst
2117     precmd() {
2118         (( ${+functions[vcs_info]} )) && vcs_info
2119     }
2120
2121     p0="${RED}%(?..%? )${WHITE}${debian_chroot:+($debian_chroot)}"
2122     p1="${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "'${vcs_info_msg_0_}'"%# "
2123     if (( EUID == 0 )); then
2124         PROMPT="${BLUE}${p0}${RED}${p1}"
2125     else
2126         PROMPT="${RED}${p0}${BLUE}${p1}"
2127     fi
2128     unset p0 p1
2129 }
2130
2131 if zrcautoload promptinit && promptinit 2>/dev/null ; then
2132     # Since we define the required functions in here and not in files in
2133     # $fpath, we need to stick the theme's name into `$prompt_themes'
2134     # ourselves, since promptinit does not pick them up otherwise.
2135     prompt_themes+=( grml grml-chroot grml-large )
2136     # Also, keep the array sorted...
2137     prompt_themes=( "${(@on)prompt_themes}" )
2138 else
2139     print 'Notice: no promptinit available :('
2140     grml_prompt_fallback
2141 fi
2142
2143 if is437; then
2144     # The prompt themes use modern features of zsh, that require at least
2145     # version 4.3.7 of the shell. Use the fallback otherwise.
2146     if [[ $BATTERY -gt 0 ]]; then
2147         zstyle ':prompt:grml:right:setup' items sad-smiley battery
2148         add-zsh-hook precmd battery
2149     fi
2150     if [[ "$TERM" == dumb ]] ; then
2151         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" pre ''
2152         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" post ' '
2153         for i in rc user path jobs history date time shell-level; do
2154             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" pre ''
2155             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" post ''
2156         done
2157         unset i
2158         zstyle ':prompt:grml(|-large|-chroot):right:setup' use-rprompt false
2159     elif (( EUID == 0 )); then
2160         zstyle ':prompt:grml(|-large|-chroot):*:items:user' pre '%F{red}'
2161     fi
2162
2163     # Finally enable one of the prompts.
2164     if [[ -n $GRML_CHROOT ]]; then
2165         prompt grml-chroot
2166     elif [[ $GRMLPROMPT -gt 0 ]]; then
2167         prompt grml-large
2168     else
2169         prompt grml
2170     fi
2171 else
2172     grml_prompt_fallback
2173 fi
2174
2175 # Terminal-title wizardry
2176
2177 function ESC_print () {
2178     info_print $'\ek' $'\e\\' "$@"
2179 }
2180 function set_title () {
2181     info_print  $'\e]0;' $'\a' "$@"
2182 }
2183
2184 function info_print () {
2185     local esc_begin esc_end
2186     esc_begin="$1"
2187     esc_end="$2"
2188     shift 2
2189     printf '%s' ${esc_begin}
2190     printf '%s' "$*"
2191     printf '%s' "${esc_end}"
2192 }
2193
2194 function grml_reset_screen_title () {
2195     # adjust title of xterm
2196     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
2197     [[ ${NOTITLE:-} -gt 0 ]] && return 0
2198     case $TERM in
2199         (xterm*|rxvt*)
2200             set_title ${(%):-"%n@%m: %~"}
2201             ;;
2202     esac
2203 }
2204
2205 function grml_vcs_to_screen_title () {
2206     if [[ $TERM == screen* ]] ; then
2207         if [[ -n ${vcs_info_msg_1_} ]] ; then
2208             ESC_print ${vcs_info_msg_1_}
2209         else
2210             ESC_print "zsh"
2211         fi
2212     fi
2213 }
2214
2215 function grml_maintain_name () {
2216     # set hostname if not running on host with name 'grml'
2217     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
2218        NAME="@$HOSTNAME"
2219     fi
2220 }
2221
2222 function grml_cmd_to_screen_title () {
2223     # get the name of the program currently running and hostname of local
2224     # machine set screen window title if running in a screen
2225     if [[ "$TERM" == screen* ]] ; then
2226         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME"
2227         ESC_print ${CMD}
2228     fi
2229 }
2230
2231 function grml_control_xterm_title () {
2232     case $TERM in
2233         (xterm*|rxvt*)
2234             set_title "${(%):-"%n@%m:"}" "$1"
2235             ;;
2236     esac
2237 }
2238
2239 zrcautoload add-zsh-hook || add-zsh-hook () { :; }
2240 if [[ $NOPRECMD -eq 0 ]]; then
2241     add-zsh-hook precmd grml_reset_screen_title
2242     add-zsh-hook precmd grml_vcs_to_screen_title
2243     add-zsh-hook preexec grml_maintain_name
2244     add-zsh-hook preexec grml_cmd_to_screen_title
2245     if [[ $NOTITLE -eq 0 ]]; then
2246         add-zsh-hook preexec grml_control_xterm_title
2247     fi
2248 fi
2249
2250 # 'hash' some often used directories
2251 #d# start
2252 hash -d deb=/var/cache/apt/archives
2253 hash -d doc=/usr/share/doc
2254 hash -d linux=/lib/modules/$(command uname -r)/build/
2255 hash -d log=/var/log
2256 hash -d slog=/var/log/syslog
2257 hash -d src=/usr/src
2258 hash -d templ=/usr/share/doc/grml-templates
2259 hash -d tt=/usr/share/doc/texttools-doc
2260 hash -d www=/var/www
2261 #d# end
2262
2263 # some aliases
2264 if check_com -c screen ; then
2265     if [[ $UID -eq 0 ]] ; then
2266         if [[ -r /etc/grml/screenrc ]]; then
2267             alias screen="${commands[screen]} -c /etc/grml/screenrc"
2268         fi
2269     elif [[ -r $HOME/.screenrc ]] ; then
2270         alias screen="${commands[screen]} -c $HOME/.screenrc"
2271     else
2272         if [[ -r /etc/grml/screenrc_grml ]]; then
2273             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
2274         else
2275             if [[ -r /etc/grml/screenrc ]]; then
2276                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
2277             fi
2278         fi
2279     fi
2280 fi
2281
2282 # do we have GNU ls with color-support?
2283 if [[ "$TERM" != dumb ]]; then
2284     #a1# List files with colors (\kbd{ls -b -CF \ldots})
2285     alias ls='ls -b -CF '${ls_options:+"${ls_options[*]}"}
2286     #a1# List all files, with colors (\kbd{ls -la \ldots})
2287     alias la='ls -la '${ls_options:+"${ls_options[*]}"}
2288     #a1# List files with long colored list, without dotfiles (\kbd{ls -l \ldots})
2289     alias ll='ls -l '${ls_options:+"${ls_options[*]}"}
2290     #a1# List files with long colored list, human readable sizes (\kbd{ls -hAl \ldots})
2291     alias lh='ls -hAl '${ls_options:+"${ls_options[*]}"}
2292     #a1# List files with long colored list, append qualifier to filenames (\kbd{ls -lF \ldots})\\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2293     alias l='ls -lF '${ls_options:+"${ls_options[*]}"}
2294 else
2295     alias ls='ls -b -CF'
2296     alias la='ls -la'
2297     alias ll='ls -l'
2298     alias lh='ls -hAl'
2299     alias l='ls -lF'
2300 fi
2301
2302 alias mdstat='cat /proc/mdstat'
2303 alias ...='cd ../../'
2304
2305 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2306 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2307     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2308 fi
2309
2310 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2311 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2312 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2313
2314 # make sure it is not assigned yet
2315 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
2316 utf2iso() {
2317     if isutfenv ; then
2318         for ENV in $(env | command grep -i '.utf') ; do
2319             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2320         done
2321     fi
2322 }
2323
2324 # make sure it is not assigned yet
2325 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
2326 iso2utf() {
2327     if ! isutfenv ; then
2328         for ENV in $(env | command grep -i '\.iso') ; do
2329             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2330         done
2331     fi
2332 }
2333
2334 # especially for roadwarriors using GNU screen and ssh:
2335 if ! check_com asc &>/dev/null ; then
2336   asc() { autossh -t "$@" 'screen -RdU' }
2337   compdef asc=ssh
2338 fi
2339
2340 #f1# Hints for the use of zsh on grml
2341 zsh-help() {
2342     print "$bg[white]$fg[black]
2343 zsh-help - hints for use of zsh on grml
2344 =======================================$reset_color"
2345
2346     print '
2347 Main configuration of zsh happens in /etc/zsh/zshrc.
2348 That file is part of the package grml-etc-core, if you want to
2349 use them on a non-grml-system just get the tar.gz from
2350 http://deb.grml.org/ or (preferably) get it from the git repository:
2351
2352   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2353
2354 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2355 The file is still there, but it is empty for backwards compatibility.
2356
2357 For your own changes use these two files:
2358     $HOME/.zshrc.pre
2359     $HOME/.zshrc.local
2360
2361 The former is sourced very early in our zshrc, the latter is sourced
2362 very lately.
2363
2364 System wide configuration without touching configuration files of grml
2365 can take place in /etc/zsh/zshrc.local.
2366
2367 For information regarding zsh start at http://grml.org/zsh/
2368
2369 Take a look at grml'\''s zsh refcard:
2370 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2371
2372 Check out the main zsh refcard:
2373 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2374
2375 And of course visit the zsh-lovers:
2376 % man zsh-lovers
2377
2378 You can adjust some options through environment variables when
2379 invoking zsh without having to edit configuration files.
2380 Basically meant for bash users who are not used to the power of
2381 the zsh yet. :)
2382
2383   "NOCOR=1    zsh" => deactivate automatic correction
2384   "NOMENU=1   zsh" => do not use auto menu completion
2385                       (note: use ctrl-d for completion instead!)
2386   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2387   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2388                       preexec() and precmd() completely
2389   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
2390   "COMMAND_NOT_FOUND=1 zsh"
2391                    => Enable a handler if an external command was not found
2392                       The command called in the handler can be altered by setting
2393                       the GRML_ZSH_CNF_HANDLER variable, the default is:
2394                       "/usr/share/command-not-found/command-not-found"
2395
2396 A value greater than 0 is enables a feature; a value equal to zero
2397 disables it. If you like one or the other of these settings, you can
2398 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2399 zshrc.'
2400
2401     print "
2402 $bg[white]$fg[black]
2403 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2404 Enjoy your grml system with the zsh!$reset_color"
2405 }
2406
2407 # debian stuff
2408 if [[ -r /etc/debian_version ]] ; then
2409     #a3# Execute \kbd{apt-cache search}
2410     alias acs='apt-cache search'
2411     #a3# Execute \kbd{apt-cache show}
2412     alias acsh='apt-cache show'
2413     #a3# Execute \kbd{apt-cache policy}
2414     alias acp='apt-cache policy'
2415     #a3# Execute \kbd{apt-get dist-upgrade}
2416     salias adg="apt-get dist-upgrade"
2417     #a3# Execute \kbd{apt-get install}
2418     salias agi="apt-get install"
2419     #a3# Execute \kbd{aptitude install}
2420     salias ati="aptitude install"
2421     #a3# Execute \kbd{apt-get upgrade}
2422     salias ag="apt-get upgrade"
2423     #a3# Execute \kbd{apt-get update}
2424     salias au="apt-get update"
2425     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2426     salias -a up="aptitude update ; aptitude safe-upgrade"
2427     #a3# Execute \kbd{dpkg-buildpackage}
2428     alias dbp='dpkg-buildpackage'
2429     #a3# Execute \kbd{grep-excuses}
2430     alias ge='grep-excuses'
2431
2432     # get a root shell as normal user in live-cd mode:
2433     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2434        alias su="sudo su"
2435      fi
2436
2437     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2438     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2439     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2440     salias tlog="tail -f /var/log/syslog"    # follow the syslog
2441 fi
2442
2443 # sort installed Debian-packages by size
2444 if check_com -c dpkg-query ; then
2445     #a3# List installed Debian-packages sorted by size
2446     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
2447 fi
2448
2449 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2450 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
2451     if check_com -c wodim; then
2452         cdrecord() {
2453             cat <<EOMESS
2454 cdrecord is not provided under its original name by Debian anymore.
2455 See #377109 in the BTS of Debian for more details.
2456
2457 Please use the wodim binary instead
2458 EOMESS
2459             return 1
2460         }
2461     fi
2462 fi
2463
2464 # Use hard limits, except for a smaller stack and no core dumps
2465 unlimit
2466 is425 && limit stack 8192
2467 isgrmlcd && limit core 0 # important for a live-cd-system
2468 limit -s
2469
2470 # grmlstuff
2471 grmlstuff() {
2472 # people should use 'grml-x'!
2473     if check_com -c 915resolution; then
2474         855resolution() {
2475             echo "Please use 915resolution as resolution modifying tool for Intel \
2476 graphic chipset."
2477             return -1
2478         }
2479     fi
2480
2481     #a1# Output version of running grml
2482     alias grml-version='cat /etc/grml_version'
2483
2484     if check_com -c grml-debootstrap ; then
2485         debian2hd() {
2486             echo "Installing debian to harddisk is possible by using grml-debootstrap."
2487             return 1
2488         }
2489     fi
2490 }
2491
2492 # now run the functions
2493 isgrml && checkhome
2494 is4    && isgrml    && grmlstuff
2495 is4    && grmlcomp
2496
2497 # keephack
2498 is4 && xsource "/etc/zsh/keephack"
2499
2500 # wonderful idea of using "e" glob qualifier by Peter Stephenson
2501 # You use it as follows:
2502 # $ NTREF=/reference/file
2503 # $ ls -l *(e:nt:)
2504 # This lists all the files in the current directory newer than the reference file.
2505 # You can also specify the reference file inline; note quotes:
2506 # $ ls -l *(e:'nt ~/.zshenv':)
2507 is4 && nt() {
2508     if [[ -n $1 ]] ; then
2509         local NTREF=${~1}
2510     fi
2511     [[ $REPLY -nt $NTREF ]]
2512 }
2513
2514 # shell functions
2515
2516 #f1# Reload an autoloadable function
2517 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2518 compdef _functions freload
2519
2520 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2521 sll() {
2522     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2523     for file in "$@" ; do
2524         while [[ -h "$file" ]] ; do
2525             ls -l $file
2526             file=$(readlink "$file")
2527         done
2528     done
2529 }
2530
2531 # TODO: Is it supported to use pager settings like this?
2532 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2533 # with respect to wordsplitting. (ie. ${=PAGER})
2534 if check_com -c $PAGER ; then
2535     #f3# View Debian's changelog of a given package
2536     dchange() {
2537         emulate -L zsh
2538         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
2539             $PAGER /usr/share/doc/$1/changelog.Debian.gz
2540         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2541             $PAGER /usr/share/doc/$1/changelog.gz
2542         else
2543             if check_com -c aptitude ; then
2544                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2545                 if isgrml ; then
2546                     aptitude -t unstable changelog $1
2547                 else
2548                     aptitude changelog $1
2549                 fi
2550             else
2551                 echo "No changelog for package $1 found, sorry."
2552                 return 1
2553             fi
2554         fi
2555     }
2556     _dchange() { _files -W /usr/share/doc -/ }
2557     compdef _dchange dchange
2558
2559     #f3# View Debian's NEWS of a given package
2560     dnews() {
2561         emulate -L zsh
2562         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2563             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2564         else
2565             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2566                 $PAGER /usr/share/doc/$1/NEWS.gz
2567             else
2568                 echo "No NEWS file for package $1 found, sorry."
2569                 return 1
2570             fi
2571         fi
2572     }
2573     _dnews() { _files -W /usr/share/doc -/ }
2574     compdef _dnews dnews
2575
2576     #f3# View Debian's copyright of a given package
2577     dcopyright() {
2578         emulate -L zsh
2579         if [[ -r /usr/share/doc/$1/copyright ]] ; then
2580             $PAGER /usr/share/doc/$1/copyright
2581         else
2582             echo "No copyright file for package $1 found, sorry."
2583             return 1
2584         fi
2585     }
2586     _dcopyright() { _files -W /usr/share/doc -/ }
2587     compdef _dcopyright dcopyright
2588
2589     #f3# View upstream's changelog of a given package
2590     uchange() {
2591         emulate -L zsh
2592         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2593             $PAGER /usr/share/doc/$1/changelog.gz
2594         else
2595             echo "No changelog for package $1 found, sorry."
2596             return 1
2597         fi
2598     }
2599     _uchange() { _files -W /usr/share/doc -/ }
2600     compdef _uchange uchange
2601 fi
2602
2603 # zsh profiling
2604 profile() {
2605     ZSH_PROFILE_RC=1 $SHELL "$@"
2606 }
2607
2608 #f1# Edit an alias via zle
2609 edalias() {
2610     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2611 }
2612 compdef _aliases edalias
2613
2614 #f1# Edit a function via zle
2615 edfunc() {
2616     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2617 }
2618 compdef _functions edfunc
2619
2620 # use it e.g. via 'Restart apache2'
2621 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2622 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2623 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2624 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2625 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2626 #m# f6 Status() \kbd{/etc/init.d/\em{process}}\quad\kbd{status}
2627 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2628     __start_stop() {
2629         local action_="${1:l}"  # e.g Start/Stop/Restart
2630         local service_="$2"
2631         local param_="$3"
2632
2633         local service_target_="$(readlink /etc/init.d/$service_)"
2634         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2635             # runit
2636             case "${action_}" in
2637                 start) if [[ ! -e /etc/service/$service_ ]]; then
2638                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2639                        else
2640                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2641                        fi ;;
2642                 # there is no reload in runits sysv emulation
2643                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2644                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2645             esac
2646         else
2647             # sysvinit
2648             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2649         fi
2650     }
2651
2652     _grmlinitd() {
2653         local -a scripts
2654         scripts=( /etc/init.d/*(x:t) )
2655         _describe "service startup script" scripts
2656     }
2657
2658     for i in Start Restart Stop Force-Reload Reload Status ; do
2659         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2660         compdef _grmlinitd $i
2661     done
2662 fi
2663
2664 #f1# Provides useful information on globbing
2665 H-Glob() {
2666     echo -e "
2667     /      directories
2668     .      plain files
2669     @      symbolic links
2670     =      sockets
2671     p      named pipes (FIFOs)
2672     *      executable plain files (0100)
2673     %      device files (character or block special)
2674     %b     block special files
2675     %c     character special files
2676     r      owner-readable files (0400)
2677     w      owner-writable files (0200)
2678     x      owner-executable files (0100)
2679     A      group-readable files (0040)
2680     I      group-writable files (0020)
2681     E      group-executable files (0010)
2682     R      world-readable files (0004)
2683     W      world-writable files (0002)
2684     X      world-executable files (0001)
2685     s      setuid files (04000)
2686     S      setgid files (02000)
2687     t      files with the sticky bit (01000)
2688
2689   print *(m-1)          # Files modified up to a day ago
2690   print *(a1)           # Files accessed a day ago
2691   print *(@)            # Just symlinks
2692   print *(Lk+50)        # Files bigger than 50 kilobytes
2693   print *(Lk-50)        # Files smaller than 50 kilobytes
2694   print **/*.c          # All *.c files recursively starting in \$PWD
2695   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2696   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2697   print *~*.*           # All Files that do not contain a dot
2698   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2699   print -l *(.c|.h)     # Lists *.c and *.h
2700   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2701   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2702 }
2703 alias help-zshglob=H-Glob
2704
2705 # grep for running process, like: 'any vim'
2706 any() {
2707     emulate -L zsh
2708     unsetopt KSH_ARRAYS
2709     if [[ -z "$1" ]] ; then
2710         echo "any - grep for process(es) by keyword" >&2
2711         echo "Usage: any <keyword>" >&2 ; return 1
2712     else
2713         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
2714     fi
2715 }
2716
2717
2718 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2719 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2720 [[ -r /proc/1/maps ]] && \
2721 deswap() {
2722     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2723     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2724     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2725 }
2726
2727 # a wrapper for vim, that deals with title setting
2728 #   VIM_OPTIONS
2729 #       set this array to a set of options to vim you always want
2730 #       to have set when calling vim (in .zshrc.local), like:
2731 #           VIM_OPTIONS=( -p )
2732 #       This will cause vim to send every file given on the
2733 #       commandline to be send to it's own tab (needs vim7).
2734 if check_com vim; then
2735     vim() {
2736         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2737     }
2738 fi
2739
2740 # make a backup of a file
2741 bk() {
2742     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2743 }
2744
2745 ssl_hashes=( sha512 sha256 sha1 md5 )
2746
2747 for sh in ${ssl_hashes}; do
2748     eval 'ssl-cert-'${sh}'() {
2749         emulate -L zsh
2750         if [[ -z $1 ]] ; then
2751             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2752             return 1
2753         fi
2754         openssl x509 -noout -fingerprint -'${sh}' -in $1
2755     }'
2756 done; unset sh
2757
2758 ssl-cert-fingerprints() {
2759     emulate -L zsh
2760     local i
2761     if [[ -z $1 ]] ; then
2762         printf 'usage: ssl-cert-fingerprints <file>\n'
2763         return 1
2764     fi
2765     for i in ${ssl_hashes}
2766         do ssl-cert-$i $1;
2767     done
2768 }
2769
2770 ssl-cert-info() {
2771     emulate -L zsh
2772     if [[ -z $1 ]] ; then
2773         printf 'usage: ssl-cert-info <file>\n'
2774         return 1
2775     fi
2776     openssl x509 -noout -text -in $1
2777     ssl-cert-fingerprints $1
2778 }
2779
2780 # make sure our environment is clean regarding colors
2781 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2782
2783 # "persistent history"
2784 # just write important commands you always need to ~/.important_commands
2785 if [[ -r ~/.important_commands ]] ; then
2786     fc -R ~/.important_commands
2787 fi
2788
2789 # load the lookup subsystem if it's available on the system
2790 zrcautoload lookupinit && lookupinit
2791
2792 # variables
2793
2794 # set terminal property (used e.g. by msgid-chooser)
2795 export COLORTERM="yes"
2796
2797 # aliases
2798
2799 # general
2800 #a2# Execute \kbd{du -sch}
2801 alias da='du -sch'
2802 #a2# Execute \kbd{jobs -l}
2803 alias j='jobs -l'
2804
2805 # listing stuff
2806 #a2# Execute \kbd{ls -lSrah}
2807 alias dir="ls -lSrah"
2808 #a2# Only show dot-directories
2809 alias lad='ls -d .*(/)'
2810 #a2# Only show dot-files
2811 alias lsa='ls -a .*(.)'
2812 #a2# Only files with setgid/setuid/sticky flag
2813 alias lss='ls -l *(s,S,t)'
2814 #a2# Only show symlinks
2815 alias lsl='ls -l *(@)'
2816 #a2# Display only executables
2817 alias lsx='ls -l *(*)'
2818 #a2# Display world-{readable,writable,executable} files
2819 alias lsw='ls -ld *(R,W,X.^ND/)'
2820 #a2# Display the ten biggest files
2821 alias lsbig="ls -flh *(.OL[1,10])"
2822 #a2# Only show directories
2823 alias lsd='ls -d *(/)'
2824 #a2# Only show empty directories
2825 alias lse='ls -d *(/^F)'
2826 #a2# Display the ten newest files
2827 alias lsnew="ls -rtlh *(D.om[1,10])"
2828 #a2# Display the ten oldest files
2829 alias lsold="ls -rtlh *(D.Om[1,10])"
2830 #a2# Display the ten smallest files
2831 alias lssmall="ls -Srl *(.oL[1,10])"
2832 #a2# Display the ten newest directories and ten newest .directories
2833 alias lsnewdir="ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
2834 #a2# Display the ten oldest directories and ten oldest .directories
2835 alias lsolddir="ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
2836
2837 # some useful aliases
2838 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir \$OLDCWD}
2839 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2840
2841 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2842 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2843 #a2# scp with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2844 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2845
2846 # work around non utf8 capable software in utf environment via $LANG and luit
2847 if check_com isutfenv && check_com luit ; then
2848     if check_com -c mrxvt ; then
2849         isutfenv && [[ -n "$LANG" ]] && \
2850             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2851     fi
2852
2853     if check_com -c aterm ; then
2854         isutfenv && [[ -n "$LANG" ]] && \
2855             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2856     fi
2857
2858     if check_com -c centericq ; then
2859         isutfenv && [[ -n "$LANG" ]] && \
2860             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2861     fi
2862 fi
2863
2864 # useful functions
2865
2866 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2867 bk() {
2868     emulate -L zsh
2869     cp -b $1 $1_`date --iso-8601=m`
2870 }
2871
2872 #f5# cd to directoy and list files
2873 cl() {
2874     emulate -L zsh
2875     cd $1 && ls -a
2876 }
2877
2878 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2879 cd() {
2880     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2881         [[ ! -e ${1:h} ]] && return 1
2882         print "Correcting ${1} to ${1:h}"
2883         builtin cd ${1:h}
2884     else
2885         builtin cd "$@"
2886     fi
2887 }
2888
2889 #f5# Create Directoy and \kbd{cd} to it
2890 mkcd() {
2891     if (( ARGC != 1 )); then
2892         printf 'usage: mkcd <new-directory>\n'
2893         return 1;
2894     fi
2895     if [[ ! -d "$1" ]]; then
2896         command mkdir -p "$1"
2897     else
2898         printf '`%s'\'' already exists: cd-ing.\n' "$1"
2899     fi
2900     builtin cd "$1"
2901 }
2902
2903 #f5# Create temporary directory and \kbd{cd} to it
2904 cdt() {
2905     local t
2906     t=$(mktemp -d)
2907     echo "$t"
2908     builtin cd "$t"
2909 }
2910
2911 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2912 accessed() {
2913     emulate -L zsh
2914     print -l -- *(a-${1:-1})
2915 }
2916
2917 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2918 changed() {
2919     emulate -L zsh
2920     print -l -- *(c-${1:-1})
2921 }
2922
2923 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2924 modified() {
2925     emulate -L zsh
2926     print -l -- *(m-${1:-1})
2927 }
2928 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2929 check_com new || alias new=modified
2930
2931 # use colors when GNU grep with color-support
2932 #a2# Execute \kbd{grep -{}-color=auto}
2933 (( $#grep_options > 0 )) && alias grep='grep '${grep_options:+"${grep_options[*]}"}
2934
2935 # Translate DE<=>EN
2936 # 'translate' looks up fot a word in a file with language-to-language
2937 # translations (field separator should be " : "). A typical wordlist looks
2938 # like at follows:
2939 #  | english-word : german-transmission
2940 # It's also only possible to translate english to german but not reciprocal.
2941 # Use the following oneliner to turn back the sort order:
2942 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2943 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2944 #f5# Translates a word
2945 trans() {
2946     emulate -L zsh
2947     case "$1" in
2948         -[dD]*)
2949             translate -l de-en $2
2950             ;;
2951         -[eE]*)
2952             translate -l en-de $2
2953             ;;
2954         *)
2955             echo "Usage: $0 { -D | -E }"
2956             echo "         -D == German to English"
2957             echo "         -E == English to German"
2958     esac
2959 }
2960
2961 # Usage: simple-extract <file>
2962 # Using option -d deletes the original archive file.
2963 #f5# Smart archive extractor
2964 simple-extract() {
2965     emulate -L zsh
2966     setopt extended_glob noclobber
2967     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2968     local RC=0
2969     zparseopts -D -E "d=DELETE_ORIGINAL"
2970     for ARCHIVE in "${@}"; do
2971         case $ARCHIVE in
2972             *(tar.bz2|tbz2|tbz))
2973                 DECOMP_CMD="tar -xvjf -"
2974                 USES_STDIN=true
2975                 USES_STDOUT=false
2976                 ;;
2977             *(tar.gz|tgz))
2978                 DECOMP_CMD="tar -xvzf -"
2979                 USES_STDIN=true
2980                 USES_STDOUT=false
2981                 ;;
2982             *(tar.xz|txz|tar.lzma))
2983                 DECOMP_CMD="tar -xvJf -"
2984                 USES_STDIN=true
2985                 USES_STDOUT=false
2986                 ;;
2987             *tar)
2988                 DECOMP_CMD="tar -xvf -"
2989                 USES_STDIN=true
2990                 USES_STDOUT=false
2991                 ;;
2992             *rar)
2993                 DECOMP_CMD="unrar x"
2994                 USES_STDIN=false
2995                 USES_STDOUT=false
2996                 ;;
2997             *lzh)
2998                 DECOMP_CMD="lha x"
2999                 USES_STDIN=false
3000                 USES_STDOUT=false
3001                 ;;
3002             *7z)
3003                 DECOMP_CMD="7z x"
3004                 USES_STDIN=false
3005                 USES_STDOUT=false
3006                 ;;
3007             *(zip|jar))
3008                 DECOMP_CMD="unzip"
3009                 USES_STDIN=false
3010                 USES_STDOUT=false
3011                 ;;
3012             *deb)
3013                 DECOMP_CMD="ar -x"
3014                 USES_STDIN=false
3015                 USES_STDOUT=false
3016                 ;;
3017             *bz2)
3018                 DECOMP_CMD="bzip2 -d -c -"
3019                 USES_STDIN=true
3020                 USES_STDOUT=true
3021                 ;;
3022             *(gz|Z))
3023                 DECOMP_CMD="gzip -d -c -"
3024                 USES_STDIN=true
3025                 USES_STDOUT=true
3026                 ;;
3027             *(xz|lzma))
3028                 DECOMP_CMD="xz -d -c -"
3029                 USES_STDIN=true
3030                 USES_STDOUT=true
3031                 ;;
3032             *)
3033                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
3034                 RC=$((RC+1))
3035                 continue
3036                 ;;
3037         esac
3038
3039         if ! check_com ${DECOMP_CMD[(w)1]}; then
3040             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
3041             RC=$((RC+2))
3042             continue
3043         fi
3044
3045         GZTARGET="${ARCHIVE:t:r}"
3046         if [[ -f $ARCHIVE ]] ; then
3047
3048             print "Extracting '$ARCHIVE' ..."
3049             if $USES_STDIN; then
3050                 if $USES_STDOUT; then
3051                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
3052                 else
3053                     ${=DECOMP_CMD} < "$ARCHIVE"
3054                 fi
3055             else
3056                 if $USES_STDOUT; then
3057                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
3058                 else
3059                     ${=DECOMP_CMD} "$ARCHIVE"
3060                 fi
3061             fi
3062             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
3063
3064         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
3065             if check_com curl; then
3066                 WGET_CMD="curl -L -k -s -o -"
3067             elif check_com wget; then
3068                 WGET_CMD="wget -q -O - --no-check-certificate"
3069             else
3070                 print "ERROR: neither wget nor curl is installed" >&2
3071                 RC=$((RC+4))
3072                 continue
3073             fi
3074             print "Downloading and Extracting '$ARCHIVE' ..."
3075             if $USES_STDIN; then
3076                 if $USES_STDOUT; then
3077                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
3078                     RC=$((RC+$?))
3079                 else
3080                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
3081                     RC=$((RC+$?))
3082                 fi
3083             else
3084                 if $USES_STDOUT; then
3085                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
3086                 else
3087                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
3088                 fi
3089             fi
3090
3091         else
3092             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
3093             RC=$((RC+8))
3094         fi
3095     done
3096     return $RC
3097 }
3098
3099 __archive_or_uri()
3100 {
3101     _alternative \
3102         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
3103         '_urls:Remote Archives:_urls'
3104 }
3105
3106 _simple_extract()
3107 {
3108     _arguments \
3109         '-d[delete original archivefile after extraction]' \
3110         '*:Archive Or Uri:__archive_or_uri'
3111 }
3112 compdef _simple_extract simple-extract
3113 alias se=simple-extract
3114
3115 #f5# Set all ulimit parameters to \kbd{unlimited}
3116 allulimit() {
3117     ulimit -c unlimited
3118     ulimit -d unlimited
3119     ulimit -f unlimited
3120     ulimit -l unlimited
3121     ulimit -n unlimited
3122     ulimit -s unlimited
3123     ulimit -t unlimited
3124 }
3125
3126 #f5# Change the xterm title from within GNU-screen
3127 xtrename() {
3128     emulate -L zsh
3129     if [[ $1 != "-f" ]] ; then
3130         if [[ -z ${DISPLAY} ]] ; then
3131             printf 'xtrename only makes sense in X11.\n'
3132             return 1
3133         fi
3134     else
3135         shift
3136     fi
3137     if [[ -z $1 ]] ; then
3138         printf 'usage: xtrename [-f] "title for xterm"\n'
3139         printf '  renames the title of xterm from _within_ screen.\n'
3140         printf '  also works without screen.\n'
3141         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3142         return 0
3143     fi
3144     print -n "\eP\e]0;${1}\C-G\e\\"
3145     return 0
3146 }
3147
3148 # Create small urls via http://goo.gl using curl(1).
3149 # API reference: https://code.google.com/apis/urlshortener/
3150 function zurl() {
3151     emulate -L zsh
3152     setopt extended_glob
3153
3154     if [[ -z $1 ]]; then
3155         print "USAGE: zurl <URL>"
3156         return 1
3157     fi
3158
3159     local PN url prog api json contenttype item
3160     local -a data
3161     PN=$0
3162     url=$1
3163
3164     # Prepend 'http://' to given URL where necessary for later output.
3165     if [[ ${url} != http(s|)://* ]]; then
3166         url='http://'${url}
3167     fi
3168
3169     if check_com -c curl; then
3170         prog=curl
3171     else
3172         print "curl is not available, but mandatory for ${PN}. Aborting."
3173         return 1
3174     fi
3175     api='https://www.googleapis.com/urlshortener/v1/url'
3176     contenttype="Content-Type: application/json"
3177     json="{\"longUrl\": \"${url}\"}"
3178     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
3179     # Parse the response
3180     for item in "${data[@]}"; do
3181         case "$item" in
3182             ' '#'"id":'*)
3183                 item=${item#*: \"}
3184                 item=${item%\",*}
3185                 printf '%s\n' "$item"
3186                 return 0
3187                 ;;
3188         esac
3189     done
3190     return 1
3191 }
3192
3193 #f2# Find history events by search pattern and list them by date.
3194 whatwhen()  {
3195     emulate -L zsh
3196     local usage help ident format_l format_s first_char remain first last
3197     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3198     help='Use `whatwhen -h'\'' for further explanations.'
3199     ident=${(l,${#${:-Usage: }},, ,)}
3200     format_l="${ident}%s\t\t\t%s\n"
3201     format_s="${format_l//(\\t)##/\\t}"
3202     # Make the first char of the word to search for case
3203     # insensitive; e.g. [aA]
3204     first_char=[${(L)1[1]}${(U)1[1]}]
3205     remain=${1[2,-1]}
3206     # Default search range is `-100'.
3207     first=${2:-\-100}
3208     # Optional, just used for `<first> <last>' given.
3209     last=$3
3210     case $1 in
3211         ("")
3212             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3213             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3214         ;;
3215         (-h)
3216             printf '%s\n\n' ${usage}
3217             print 'OPTIONS:'
3218             printf $format_l '-h' 'show help text'
3219             print '\f'
3220             print 'SEARCH RANGE:'
3221             printf $format_l "'0'" 'the whole history,'
3222             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
3223             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
3224             printf '\n%s\n' 'EXAMPLES:'
3225             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
3226             printf $format_l 'whatwhen zsh -250'
3227             printf $format_l 'whatwhen foo 1 99'
3228         ;;
3229         (\?)
3230             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3231         ;;
3232         (*)
3233             # -l list results on stout rather than invoking $EDITOR.
3234             # -i Print dates as in YYYY-MM-DD.
3235             # -m Search for a - quoted - pattern within the history.
3236             fc -li -m "*${first_char}${remain}*" $first $last
3237         ;;
3238     esac
3239 }
3240
3241 # mercurial related stuff
3242 if check_com -c hg ; then
3243     # gnu like diff for mercurial
3244     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
3245     #f5# GNU like diff for mercurial
3246     hgdi() {
3247         emulate -L zsh
3248         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
3249     }
3250
3251     # build debian package
3252     #a2# Alias for \kbd{hg-buildpackage}
3253     alias hbp='hg-buildpackage'
3254
3255     # execute commands on the versioned patch-queue from the current repos
3256     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
3257
3258     # diffstat for specific version of a mercurial repository
3259     #   hgstat      => display diffstat between last revision and tip
3260     #   hgstat 1234 => display diffstat between revision 1234 and tip
3261     #f5# Diffstat for specific version of a mercurial repos
3262     hgstat() {
3263         emulate -L zsh
3264         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
3265     }
3266
3267 fi # end of check whether we have the 'hg'-executable
3268
3269 # grml-small cleanups
3270
3271 # The following is used to remove zsh-config-items that do not work
3272 # in grml-small by default.
3273 # If you do not want these adjustments (for whatever reason), set
3274 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
3275 # sources if it is there).
3276
3277 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
3278
3279     unset abk[V]
3280     unalias    'V'      &> /dev/null
3281     unfunction vman     &> /dev/null
3282     unfunction viless   &> /dev/null
3283     unfunction 2html    &> /dev/null
3284
3285     # manpages are not in grmlsmall
3286     unfunction manzsh   &> /dev/null
3287     unfunction man2     &> /dev/null
3288
3289 fi
3290
3291 zrclocal
3292
3293 ## genrefcard.pl settings
3294
3295 ### doc strings for external functions from files
3296 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
3297
3298 ### example: split functions-search 8,16,24,32
3299 #@# split functions-search 8
3300
3301 ## END OF FILE #################################################################
3302 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
3303 # Local variables:
3304 # mode: sh
3305 # End: