etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* || $ZSH_VERSION == <5->* ]] && return 0
 143     return 1
 144 }
 145
 146 is439(){
 147     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* || $ZSH_VERSION == <5->* ]] && return 0
 148     return 1
 149 }
 150
 151 #f1# Checks whether or not you're running grml
 152 isgrml(){
 153     [[ -f /etc/grml_version ]] && return 0
 154     return 1
 155 }
 156
 157 #f1# Checks whether or not you're running a grml cd
 158 isgrmlcd(){
 159     [[ -f /etc/grml_cd ]] && return 0
 160     return 1
 161 }
 162
 163 if isgrml ; then
 164 #f1# Checks whether or not you're running grml-small
 165     isgrmlsmall() {
 166         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 167     }
 168 else
 169     isgrmlsmall() { return 1 }
 170 fi
 171
 172 isdarwin(){
 173     [[ $OSTYPE == darwin* ]] && return 0
 174     return 1
 175 }
 176
 177 #f1# are we running within an utf environment?
 178 isutfenv() {
 179     case "$LANG $CHARSET $LANGUAGE" in
 180         *utf*) return 0 ;;
 181         *UTF*) return 0 ;;
 182         *)     return 1 ;;
 183     esac
 184 }
 185
 186 # check for user, if not running as root set $SUDO to sudo
 187 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 188
 189 # change directory to home on first invocation of zsh
 190 # important for rungetty -> autologin
 191 # Thanks go to Bart Schaefer!
 192 isgrml && checkhome() {
 193     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 194         export ALREADY_DID_CD_HOME=$HOME
 195         cd
 196     fi
 197 }
 198
 199 # check for zsh v3.1.7+
 200
 201 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 202      || ${ZSH_VERSION} == 3.<2->.<->*    \
 203      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 204
 205     printf '-!-\n'
 206     printf '-!- In this configuration we try to make use of features, that only\n'
 207     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 208     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 209     printf '-!- advanced features in all supported versions.\n'
 210     printf '-!-\n'
 211     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 212     printf '-!-\n'
 213     printf '-!- While this *may* work, it might as well fail.\n'
 214     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 215     printf '-!-\n'
 216     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 217     printf '-!- If it does today, you'\''ve been lucky.\n'
 218     printf '-!-\n'
 219     printf '-!- Ye been warned!\n'
 220     printf '-!-\n'
 221
 222     function zstyle() { : }
 223 fi
 224
 225 # autoload wrapper - use this one instead of autoload directly
 226 # We need to define this function as early as this, because autoloading
 227 # 'is-at-least()' needs it.
 228 function zrcautoload() {
 229     emulate -L zsh
 230     setopt extended_glob
 231     local fdir ffile
 232     local -i ffound
 233
 234     ffile=$1
 235     (( found = 0 ))
 236     for fdir in ${fpath} ; do
 237         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 238     done
 239
 240     (( ffound == 0 )) && return 1
 241     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 242         autoload -U ${ffile} || return 1
 243     else
 244         autoload ${ffile} || return 1
 245     fi
 246     return 0
 247 }
 248
 249 # Load is-at-least() for more precise version checks
 250 # Note that this test will *always* fail, if the is-at-least
 251 # function could not be marked for autoloading.
 252 zrcautoload is-at-least || is-at-least() { return 1 }
 253
 254 # set some important options (as early as possible)
 255 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 256 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 257 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 258 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 259                             # list duplicates an older one, the older command is removed from the list
 260 setopt histignorespace      # remove command lines from the history list when
 261                             # the first character on the line is a space
 262 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 263                             # and the command is the name of a directory, perform the cd command to that directory
 264 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 265                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 266                             # -> searches for word not in compressed files
 267                             # don't forget to quote '^', '~' and '#'!
 268 setopt longlistjobs         # display PID when suspending processes as well
 269 setopt notify               # report the status of backgrounds jobs immediately
 270 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 271                             # the entire command path is hashed first.
 272 setopt completeinword       # not just at the end
 273 setopt nohup                # and don't kill them, either
 274 setopt auto_pushd           # make cd push the old directory onto the directory stack.
 275 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 276 setopt nobeep               # avoid "beep"ing
 277 setopt pushd_ignore_dups    # don't push the same dir twice.
 278 setopt noglobdots           # * shouldn't match dotfiles. ever.
 279 setopt noshwordsplit        # use zsh style word splitting
 280 setopt unset                # don't error out when unset parameters are used
 281
 282 # setting some default values
 283
 284 NOCOR=${NOCOR:-0}
 285 NOMENU=${NOMENU:-0}
 286 NOPRECMD=${NOPRECMD:-0}
 287 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 288 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 289 BATTERY=${BATTERY:-0}
 290 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 291 GRML_ALWAYS_LOAD_ALL=${GRML_ALWAYS_LOAD_ALL:-0}
 292 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 293
 294 # utility functions
 295 # this function checks if a command exists and returns either true
 296 # or false. This avoids using 'which' and 'whence', which will
 297 # avoid problems with aliases for which on certain weird systems. :-)
 298 # Usage: check_com [-c|-g] word
 299 #   -c  only checks for external commands
 300 #   -g  does the usual tests and also checks for global aliases
 301 check_com() {
 302     emulate -L zsh
 303     local -i comonly gatoo
 304
 305     if [[ $1 == '-c' ]] ; then
 306         (( comonly = 1 ))
 307         shift
 308     elif [[ $1 == '-g' ]] ; then
 309         (( gatoo = 1 ))
 310     else
 311         (( comonly = 0 ))
 312         (( gatoo = 0 ))
 313     fi
 314
 315     if (( ${#argv} != 1 )) ; then
 316         printf 'usage: check_com [-c] <command>\n' >&2
 317         return 1
 318     fi
 319
 320     if (( comonly > 0 )) ; then
 321         [[ -n ${commands[$1]}  ]] && return 0
 322         return 1
 323     fi
 324
 325     if   [[ -n ${commands[$1]}    ]] \
 326       || [[ -n ${functions[$1]}   ]] \
 327       || [[ -n ${aliases[$1]}     ]] \
 328       || [[ -n ${reswords[(r)$1]} ]] ; then
 329
 330         return 0
 331     fi
 332
 333     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 334         return 0
 335     fi
 336
 337     return 1
 338 }
 339
 340 # creates an alias and precedes the command with
 341 # sudo if $EUID is not zero.
 342 salias() {
 343     emulate -L zsh
 344     local only=0 ; local multi=0
 345     while [[ $1 == -* ]] ; do
 346         case $1 in
 347             (-o) only=1 ;;
 348             (-a) multi=1 ;;
 349             (--) shift ; break ;;
 350             (-h)
 351                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 352                 printf '  -h      shows this help text.\n'
 353                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 354                 printf '          be careful using this option.\n'
 355                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 356                 return 0
 357                 ;;
 358             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 359         esac
 360         shift
 361     done
 362
 363     if (( ${#argv} > 1 )) ; then
 364         printf 'Too many arguments %s\n' "${#argv}"
 365         return 1
 366     fi
 367
 368     key="${1%%\=*}" ;  val="${1#*\=}"
 369     if (( EUID == 0 )) && (( only == 0 )); then
 370         alias -- "${key}=${val}"
 371     elif (( EUID > 0 )) ; then
 372         (( multi > 0 )) && val="${val// ; / ; sudo }"
 373         alias -- "${key}=sudo ${val}"
 374     fi
 375
 376     return 0
 377 }
 378
 379 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 380 # usage: uprint foo
 381 #   Where foo is the *name* of the parameter you want printed.
 382 #   Note that foo is no typo; $foo would be wrong here!
 383 if ! is42 ; then
 384     uprint () {
 385         emulate -L zsh
 386         local -a u
 387         local w
 388         local parameter=$1
 389
 390         if [[ -z ${parameter} ]] ; then
 391             printf 'usage: uprint <parameter>\n'
 392             return 1
 393         fi
 394
 395         for w in ${(P)parameter} ; do
 396             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 397         done
 398
 399         builtin print -l $u
 400     }
 401 fi
 402
 403 # Check if we can read given files and source those we can.
 404 xsource() {
 405     if (( ${#argv} < 1 )) ; then
 406         printf 'usage: xsource FILE(s)...\n' >&2
 407         return 1
 408     fi
 409
 410     while (( ${#argv} > 0 )) ; do
 411         [[ -r "$1" ]] && source "$1"
 412         shift
 413     done
 414     return 0
 415 }
 416
 417 # Check if we can read a given file and 'cat(1)' it.
 418 xcat() {
 419     emulate -L zsh
 420     if (( ${#argv} != 1 )) ; then
 421         printf 'usage: xcat FILE\n' >&2
 422         return 1
 423     fi
 424
 425     [[ -r $1 ]] && cat $1
 426     return 0
 427 }
 428
 429 # Remove these functions again, they are of use only in these
 430 # setup files. This should be called at the end of .zshrc.
 431 xunfunction() {
 432     emulate -L zsh
 433     local -a funcs
 434     funcs=(salias xcat xsource xunfunction zrcautoload)
 435
 436     for func in $funcs ; do
 437         [[ -n ${functions[$func]} ]] \
 438             && unfunction $func
 439     done
 440     return 0
 441 }
 442
 443 # this allows us to stay in sync with grml's zshrc and put own
 444 # modifications in ~/.zshrc.local
 445 zrclocal() {
 446     xsource "/etc/zsh/zshrc.local"
 447     xsource "${HOME}/.zshrc.local"
 448     return 0
 449 }
 450
 451 # locale setup
 452 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 453     xsource "/etc/default/locale"
 454 fi
 455
 456 for var in LANG LC_ALL LC_MESSAGES ; do
 457     [[ -n ${(P)var} ]] && export $var
 458 done
 459
 460 xsource "/etc/sysconfig/keyboard"
 461
 462 TZ=$(xcat /etc/timezone)
 463
 464 # set some variables
 465 if check_com -c vim ; then
 466 #v#
 467     export EDITOR=${EDITOR:-vim}
 468 else
 469     export EDITOR=${EDITOR:-vi}
 470 fi
 471
 472 #v#
 473 export PAGER=${PAGER:-less}
 474
 475 #v#
 476 export MAIL=${MAIL:-/var/mail/$USER}
 477
 478 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 479 export SHELL='/bin/zsh'
 480
 481 # color setup for ls:
 482 check_com -c dircolors && eval $(dircolors -b)
 483 # color setup for ls on OS X:
 484 isdarwin && export CLICOLOR=1
 485
 486 # do MacPorts setup on darwin
 487 if isdarwin && [[ -d /opt/local ]]; then
 488     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 489     # zshenv.
 490     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 491     MANPATH="/opt/local/share/man:$MANPATH"
 492 fi
 493 # do Fink setup on darwin
 494 isdarwin && xsource /sw/bin/init.sh
 495
 496 # load our function and completion directories
 497 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 498     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 499     if [[ ${fpath} == '/usr/share/grml/zsh/functions' ]] ; then
 500         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 501             zrcautoload ${func:t}
 502         done
 503     fi
 504 done
 505 unset fdir func
 506
 507 # support colors in less
 508 export LESS_TERMCAP_mb=$'\E[01;31m'
 509 export LESS_TERMCAP_md=$'\E[01;31m'
 510 export LESS_TERMCAP_me=$'\E[0m'
 511 export LESS_TERMCAP_se=$'\E[0m'
 512 export LESS_TERMCAP_so=$'\E[01;44;33m'
 513 export LESS_TERMCAP_ue=$'\E[0m'
 514 export LESS_TERMCAP_us=$'\E[01;32m'
 515
 516 MAILCHECK=30       # mailchecks
 517 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 518 watch=(notme root) # watch for everyone but me and root
 519
 520 # automatically remove duplicates from these arrays
 521 typeset -U path cdpath fpath manpath
 522
 523 # keybindings
 524 if [[ "$TERM" != emacs ]] ; then
 525     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 526     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 527     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 528     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 529     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 530     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 531     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 532     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 533     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 534     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 535     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 536     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 537     # ncurses stuff:
 538     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 539     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 540     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 541     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 542     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 543     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 544     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 545     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 546 fi
 547
 548 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 549 # use emacs style per default:
 550 bindkey -e
 551 # use vi style:
 552 # bindkey -v
 553
 554 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 555 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 556 beginning-or-end-of-somewhere() {
 557     local hno=$HISTNO
 558     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 559       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 560         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 561     else
 562         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 563         if (( HISTNO != hno )); then
 564             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 565         fi
 566     fi
 567 }
 568 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 569 zle -N end-of-somewhere beginning-or-end-of-somewhere
 570
 571
 572 #if [[ "$TERM" == screen ]] ; then
 573
 574 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 575 ## to beginning/end of buffer on second keypress
 576 ## and to beginning/end of history on (at most) the third keypress
 577 # terminator & non-debian xterm
 578 bindkey '\eOH' beginning-of-somewhere  # home
 579 bindkey '\eOF' end-of-somewhere        # end
 580 # freebsd console
 581 bindkey '\e[H' beginning-of-somewhere   # home
 582 bindkey '\e[F' end-of-somewhere         # end
 583 # xterm,gnome-terminal,quake,etc
 584 bindkey '^[[1~' beginning-of-somewhere  # home
 585 bindkey '^[[4~' end-of-somewhere        # end
 586 # if terminal type is set to 'rxvt':
 587 bindkey '\e[7~' beginning-of-somewhere  # home
 588 bindkey '\e[8~' end-of-somewhere        # end
 589 #fi
 590
 591 bindkey '\e[A'  up-line-or-search       # cursor up
 592 bindkey '\e[B'  down-line-or-search     # <ESC>-
 593
 594 ## alt-backspace is already the default for backwards-delete-word
 595 ## let's also set alt-delete for deleting current word (right of cursor)
 596 #k# Kill right-side word
 597 bindkey '^[[3~'   delete-word # Modeswitch
 598 bindkey '^[[3;3~' delete-word # Alt_L
 599
 600 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 601 bindkey "\e[5C" forward-word
 602 bindkey "\e[5D" backward-word
 603 bindkey "\e[1;5C" forward-word
 604 bindkey "\e[1;5D" backward-word
 605 ## the same for alt-left-arrow and alt-right-arrow
 606 bindkey '^[[1;3C' forward-word
 607 bindkey '^[[1;3D' backward-word
 608
 609 # Search backward in the history for a line beginning with the current
 610 # line up to the cursor and move the cursor to the end of the line then
 611 zle -N history-beginning-search-backward-end history-search-end
 612 zle -N history-beginning-search-forward-end  history-search-end
 613 #k# search history backward for entry beginning with typed text
 614 bindkey '^xp'   history-beginning-search-backward-end
 615 #k# search history forward for entry beginning with typed text
 616 bindkey '^xP'   history-beginning-search-forward-end
 617 #k# search history backward for entry beginning with typed text
 618 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 619 #k# search history forward for entry beginning with typed text
 620 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 621
 622 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 623 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 624
 625 # insert unicode character
 626 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 627 # See for example http://unicode.org/charts/ for unicode characters code
 628 zrcautoload insert-unicode-char
 629 zle -N insert-unicode-char
 630 #k# Insert Unicode character
 631 bindkey '^Xi' insert-unicode-char
 632
 633 #m# k Shift-tab Perform backwards menu completion
 634 if [[ -n "$terminfo[kcbt]" ]]; then
 635     bindkey "$terminfo[kcbt]" reverse-menu-complete
 636 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 637     bindkey "$terminfo[cbt]"  reverse-menu-complete
 638 fi
 639
 640 ## toggle the ,. abbreviation feature on/off
 641 # NOABBREVIATION: default abbreviation-state
 642 #                 0 - enabled (default)
 643 #                 1 - disabled
 644 NOABBREVIATION=${NOABBREVIATION:-0}
 645
 646 grml_toggle_abbrev() {
 647     if (( ${NOABBREVIATION} > 0 )) ; then
 648         NOABBREVIATION=0
 649     else
 650         NOABBREVIATION=1
 651     fi
 652 }
 653
 654 zle -N grml_toggle_abbrev
 655 bindkey '^xA' grml_toggle_abbrev
 656
 657 # add a command line to the shells history without executing it
 658 commit-to-history() {
 659     print -s ${(z)BUFFER}
 660     zle send-break
 661 }
 662 zle -N commit-to-history
 663 bindkey "^x^h" commit-to-history
 664
 665 # only slash should be considered as a word separator:
 666 slash-backward-kill-word() {
 667     local WORDCHARS="${WORDCHARS:s@/@}"
 668     # zle backward-word
 669     zle backward-kill-word
 670 }
 671 zle -N slash-backward-kill-word
 672
 673 #k# Kill left-side word or everything up to next slash
 674 bindkey '\ev' slash-backward-kill-word
 675 #k# Kill left-side word or everything up to next slash
 676 bindkey '\e^h' slash-backward-kill-word
 677 #k# Kill left-side word or everything up to next slash
 678 bindkey '\e^?' slash-backward-kill-word
 679
 680 # use the new *-pattern-* widgets for incremental history search
 681 if is439 ; then
 682     bindkey '^r' history-incremental-pattern-search-backward
 683     bindkey '^s' history-incremental-pattern-search-forward
 684 fi
 685
 686 # a generic accept-line wrapper
 687
 688 # This widget can prevent unwanted autocorrections from command-name
 689 # to _command-name, rehash automatically on enter and call any number
 690 # of builtin and user-defined widgets in different contexts.
 691 #
 692 # For a broader description, see:
 693 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 694 #
 695 # The code is imported from the file 'zsh/functions/accept-line' from
 696 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 697 # distributed under the same terms as zsh itself.
 698
 699 # A newly added command will may not be found or will cause false
 700 # correction attempts, if you got auto-correction set. By setting the
 701 # following style, we force accept-line() to rehash, if it cannot
 702 # find the first word on the command line in the $command[] hash.
 703 zstyle ':acceptline:*' rehash true
 704
 705 function Accept-Line() {
 706     setopt localoptions noksharrays
 707     local -a subs
 708     local -xi aldone
 709     local sub
 710     local alcontext=${1:-$alcontext}
 711
 712     zstyle -a ":acceptline:${alcontext}" actions subs
 713
 714     (( ${#subs} < 1 )) && return 0
 715
 716     (( aldone = 0 ))
 717     for sub in ${subs} ; do
 718         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 719         zle ${sub}
 720
 721         (( aldone > 0 )) && break
 722     done
 723 }
 724
 725 function Accept-Line-getdefault() {
 726     emulate -L zsh
 727     local default_action
 728
 729     zstyle -s ":acceptline:${alcontext}" default_action default_action
 730     case ${default_action} in
 731         ((accept-line|))
 732             printf ".accept-line"
 733             ;;
 734         (*)
 735             printf ${default_action}
 736             ;;
 737     esac
 738 }
 739
 740 function Accept-Line-HandleContext() {
 741     zle Accept-Line
 742
 743     default_action=$(Accept-Line-getdefault)
 744     zstyle -T ":acceptline:${alcontext}" call_default \
 745         && zle ${default_action}
 746 }
 747
 748 function accept-line() {
 749     setopt localoptions noksharrays
 750     local -ax cmdline
 751     local -x alcontext
 752     local buf com fname format msg default_action
 753
 754     alcontext='default'
 755     buf="${BUFFER}"
 756     cmdline=(${(z)BUFFER})
 757     com="${cmdline[1]}"
 758     fname="_${com}"
 759
 760     Accept-Line 'preprocess'
 761
 762     zstyle -t ":acceptline:${alcontext}" rehash \
 763         && [[ -z ${commands[$com]} ]]           \
 764         && rehash
 765
 766     if    [[ -n ${com}               ]] \
 767        && [[ -n ${reswords[(r)$com]} ]] \
 768        || [[ -n ${aliases[$com]}     ]] \
 769        || [[ -n ${functions[$com]}   ]] \
 770        || [[ -n ${builtins[$com]}    ]] \
 771        || [[ -n ${commands[$com]}    ]] ; then
 772
 773         # there is something sensible to execute, just do it.
 774         alcontext='normal'
 775         Accept-Line-HandleContext
 776
 777         return
 778     fi
 779
 780     if    [[ -o correct              ]] \
 781        || [[ -o correctall           ]] \
 782        && [[ -n ${functions[$fname]} ]] ; then
 783
 784         # nothing there to execute but there is a function called
 785         # _command_name; a completion widget. Makes no sense to
 786         # call it on the commandline, but the correct{,all} options
 787         # will ask for it nevertheless, so warn the user.
 788         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 789             # Okay, we warned the user before, he called us again,
 790             # so have it his way.
 791             alcontext='force'
 792             Accept-Line-HandleContext
 793
 794             return
 795         fi
 796
 797         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 798             alcontext='normal'
 799             Accept-Line-HandleContext
 800         else
 801             # prepare warning message for the user, configurable via zstyle.
 802             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 803
 804             if [[ -z ${msg} ]] ; then
 805                 msg="%c will not execute and completion %f exists."
 806             fi
 807
 808             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 809
 810             zle -M -- "${msg}"
 811         fi
 812         return
 813     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 814         # If we are here, the commandline contains something that is not
 815         # executable, which is neither subject to _command_name correction
 816         # and is not empty. might be a variable assignment
 817         alcontext='misc'
 818         Accept-Line-HandleContext
 819
 820         return
 821     fi
 822
 823     # If we got this far, the commandline only contains whitespace, or is empty.
 824     alcontext='empty'
 825     Accept-Line-HandleContext
 826 }
 827
 828 zle -N accept-line
 829 zle -N Accept-Line
 830 zle -N Accept-Line-HandleContext
 831
 832 # power completion - abbreviation expansion
 833 # power completion / abbreviation expansion / buffer expansion
 834 # see http://zshwiki.org/home/examples/zleiab for details
 835 # less risky than the global aliases but powerful as well
 836 # just type the abbreviation key and afterwards ',.' to expand it
 837 declare -A abk
 838 setopt extendedglob
 839 setopt interactivecomments
 840 abk=(
 841 #   key   # value                  (#d additional doc string)
 842 #A# start
 843     '...'  '../..'
 844     '....' '../../..'
 845     'BG'   '& exit'
 846     'C'    '| wc -l'
 847     'G'    '|& grep --color=auto '
 848     'H'    '| head'
 849     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 850     'L'    '| less'
 851     'LL'   '|& less -r'
 852     'M'    '| most'
 853     'N'    '&>/dev/null'           #d (No Output)
 854     'R'    '| tr A-z N-za-m'       #d (ROT13)
 855     'SL'   '| sort | less'
 856     'S'    '| sort -u'
 857     'T'    '| tail'
 858     'V'    '|& vim -'
 859 #A# end
 860     'co'   './configure && make && sudo make install'
 861 )
 862
 863 globalias() {
 864     emulate -L zsh
 865     setopt extendedglob
 866     local MATCH
 867
 868     if (( NOABBREVIATION > 0 )) ; then
 869         LBUFFER="${LBUFFER},."
 870         return 0
 871     fi
 872
 873     matched_chars='[.-|_a-zA-Z0-9]#'
 874     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 875     LBUFFER+=${abk[$MATCH]:-$MATCH}
 876 }
 877
 878 zle -N globalias
 879 bindkey ",." globalias
 880
 881 # autoloading
 882 zrcautoload zmv    # who needs mmv or rename?
 883 zrcautoload history-search-end
 884
 885 # we don't want to quote/espace URLs on our own...
 886 # if autoload -U url-quote-magic ; then
 887 #    zle -N self-insert url-quote-magic
 888 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 889 # else
 890 #    print 'Notice: no url-quote-magic available :('
 891 # fi
 892 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 893
 894 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 895 alias run-help >&/dev/null && unalias run-help
 896 for rh in run-help{,-git,-svk,-svn}; do
 897     zrcautoload $rh
 898 done; unset rh
 899
 900 # completion system
 901 if zrcautoload compinit ; then
 902     compinit || print 'Notice: no compinit available :('
 903 else
 904     print 'Notice: no compinit available :('
 905     function zstyle { }
 906     function compdef { }
 907 fi
 908
 909 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 910
 911 is4 && \
 912 for mod in complist deltochar mathfunc ; do
 913     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 914 done
 915
 916 # autoload zsh modules when they are referenced
 917 if is4 ; then
 918     zmodload -a  zsh/stat    zstat
 919     zmodload -a  zsh/zpty    zpty
 920     zmodload -ap zsh/mapfile mapfile
 921 fi
 922
 923 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 924     #k# Insert files and test globbing
 925     bindkey "^Xf" insert-files # C-x-f
 926 fi
 927
 928 bindkey ' '   magic-space    # also do history expansion on space
 929 #k# Trigger menu-complete
 930 bindkey '\ei' menu-complete  # menu completion via esc-i
 931
 932 # press esc-e for editing command line in $EDITOR or $VISUAL
 933 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 934     #k# Edit the current line in \kbd{\$EDITOR}
 935     bindkey '\ee' edit-command-line
 936 fi
 937
 938 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 939     #k# menu selection: pick item but stay in the menu
 940     bindkey -M menuselect '\e^M' accept-and-menu-complete
 941     # also use + and INSERT since it's easier to press repeatedly
 942     bindkey -M menuselect "+" accept-and-menu-complete
 943     bindkey -M menuselect "^[[2~" accept-and-menu-complete
 944
 945     # accept a completion and try to complete again by using menu
 946     # completion; very useful with completing directories
 947     # by using 'undo' one's got a simple file browser
 948     bindkey -M menuselect '^o' accept-and-infer-next-history
 949 fi
 950
 951 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 952 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
 953 zle -N insert-datestamp
 954
 955 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 956 bindkey '^Ed' insert-datestamp
 957
 958 # press esc-m for inserting last typed word again (thanks to caphuso!)
 959 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 960 zle -N insert-last-typed-word;
 961
 962 #k# Insert last typed word
 963 bindkey "\em" insert-last-typed-word
 964
 965 function grml-zsh-fg() {
 966   if (( ${#jobstates} )); then
 967     zle .push-input
 968     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
 969     BUFFER="${BUFFER}fg"
 970     zle .accept-line
 971   else
 972     zle -M 'No background jobs. Doing nothing.'
 973   fi
 974 }
 975 zle -N grml-zsh-fg
 976 #k# A smart shortcut for \kbd{fg<enter>}
 977 bindkey '^z' grml-zsh-fg
 978
 979 # run command line as user root via sudo:
 980 sudo-command-line() {
 981     [[ -z $BUFFER ]] && zle up-history
 982     if [[ $BUFFER != sudo\ * ]]; then
 983         BUFFER="sudo $BUFFER"
 984         CURSOR=$(( CURSOR+5 ))
 985     fi
 986 }
 987 zle -N sudo-command-line
 988
 989 #k# prepend the current command with "sudo"
 990 bindkey "^Os" sudo-command-line
 991
 992 ### jump behind the first word on the cmdline.
 993 ### useful to add options.
 994 function jump_after_first_word() {
 995     local words
 996     words=(${(z)BUFFER})
 997
 998     if (( ${#words} <= 1 )) ; then
 999         CURSOR=${#BUFFER}
1000     else
1001         CURSOR=${#${words[1]}}
1002     fi
1003 }
1004 zle -N jump_after_first_word
1005 #k# jump to after first word (for adding options)
1006 bindkey '^x1' jump_after_first_word
1007
1008 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1009 zle -C hist-complete complete-word _generic
1010 zstyle ':completion:hist-complete:*' completer _history
1011 #k# complete word from history with menu
1012 bindkey "^X^X" hist-complete
1013
1014 ## complete word from currently visible Screen or Tmux buffer.
1015 if check_com -c screen || check_com -c tmux; then
1016     _complete_screen_display() {
1017         [[ "$TERM" != "screen" ]] && return 1
1018
1019         local TMPFILE=$(mktemp)
1020         local -U -a _screen_display_wordlist
1021         trap "rm -f $TMPFILE" EXIT
1022
1023         # fill array with contents from screen hardcopy
1024         if ((${+TMUX})); then
1025             #works, but crashes tmux below version 1.4
1026             #luckily tmux -V option to ask for version, was also added in 1.4
1027             tmux -V &>/dev/null || return
1028             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1029         else
1030             screen -X hardcopy $TMPFILE
1031             #screen sucks, it dumps in latin1, apparently always. so recode it to system charset
1032             check_com recode && recode latin1 $TMPFILE
1033         fi
1034         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1035         # remove PREFIX to be completed from that array
1036         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1037         compadd -a _screen_display_wordlist
1038     }
1039     #k# complete word from currently visible GNU screen buffer
1040     bindkey -r "^XS"
1041     compdef -k _complete_screen_display complete-word '^XS'
1042 fi
1043
1044 # history
1045
1046 ZSHDIR=$HOME/.zsh
1047
1048 #v#
1049 HISTFILE=$HOME/.zsh_history
1050 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1051 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1052
1053 # dirstack handling
1054
1055 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1056 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1057
1058 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1059     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1060     # "cd -" won't work after login by just setting $OLDPWD, so
1061     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1062 fi
1063
1064 chpwd() {
1065     local -ax my_stack
1066     my_stack=( ${PWD} ${dirstack} )
1067     if is42 ; then
1068         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1069     else
1070         uprint my_stack >! ${DIRSTACKFILE}
1071     fi
1072 }
1073
1074 # directory based profiles
1075
1076 if is433 ; then
1077
1078 CHPWD_PROFILE='default'
1079 function chpwd_profiles() {
1080     # Say you want certain settings to be active in certain directories.
1081     # This is what you want.
1082     #
1083     # zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1084     # zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1085     #
1086     # When that's done and you enter a directory that matches the pattern
1087     # in the third part of the context, a function called chpwd_profile_grml,
1088     # for example, is called (if it exists).
1089     #
1090     # If no pattern matches (read: no profile is detected) the profile is
1091     # set to 'default', which means chpwd_profile_default is attempted to
1092     # be called.
1093     #
1094     # A word about the context (the ':chpwd:profiles:*' stuff in the zstyle
1095     # command) which is used: The third part in the context is matched against
1096     # ${PWD}. That's why using a pattern such as /foo/bar(|/|/*) makes sense.
1097     # Because that way the profile is detected for all these values of ${PWD}:
1098     #   /foo/bar
1099     #   /foo/bar/
1100     #   /foo/bar/baz
1101     # So, if you want to make double damn sure a profile works in /foo/bar
1102     # and everywhere deeper in that tree, just use (|/|/*) and be happy.
1103     #
1104     # The name of the detected profile will be available in a variable called
1105     # 'profile' in your functions. You don't need to do anything, it'll just
1106     # be there.
1107     #
1108     # Then there is the parameter $CHPWD_PROFILE is set to the profile, that
1109     # was is currently active. That way you can avoid running code for a
1110     # profile that is already active, by running code such as the following
1111     # at the start of your function:
1112     #
1113     # function chpwd_profile_grml() {
1114     #     [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1115     #   ...
1116     # }
1117     #
1118     # The initial value for $CHPWD_PROFILE is 'default'.
1119     #
1120     # Version requirement:
1121     #   This feature requires zsh 4.3.3 or newer.
1122     #   If you use this feature and need to know whether it is active in your
1123     #   current shell, there are several ways to do that. Here are two simple
1124     #   ways:
1125     #
1126     #   a) If knowing if the profiles feature is active when zsh starts is
1127     #      good enough for you, you can put the following snippet into your
1128     #      .zshrc.local:
1129     #
1130     #   (( ${+functions[chpwd_profiles]} )) && print "directory profiles active"
1131     #
1132     #   b) If that is not good enough, and you would prefer to be notified
1133     #      whenever a profile changes, you can solve that by making sure you
1134     #      start *every* profile function you create like this:
1135     #
1136     #   function chpwd_profile_myprofilename() {
1137     #       [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1138     #       print "chpwd(): Switching to profile: $profile"
1139     #     ...
1140     #   }
1141     #
1142     #      That makes sure you only get notified if a profile is *changed*,
1143     #      not everytime you change directory, which would probably piss
1144     #      you off fairly quickly. :-)
1145     #
1146     # There you go. Now have fun with that.
1147     local -x profile
1148
1149     zstyle -s ":chpwd:profiles:${PWD}" profile profile || profile='default'
1150     if (( ${+functions[chpwd_profile_$profile]} )) ; then
1151         chpwd_profile_${profile}
1152     fi
1153
1154     CHPWD_PROFILE="${profile}"
1155     return 0
1156 }
1157 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1158
1159 fi # is433
1160
1161 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1162 if [[ $BATTERY -gt 0 ]] ; then
1163     if ! check_com -c acpi ; then
1164         BATTERY=0
1165     fi
1166 fi
1167
1168 battery() {
1169 if [[ $BATTERY -gt 0 ]] ; then
1170     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1171     if [[ -z "$PERCENT" ]] ; then
1172         PERCENT='acpi not present'
1173     else
1174         if [[ "$PERCENT" -lt 20 ]] ; then
1175             PERCENT="warning: ${PERCENT}%%"
1176         else
1177             PERCENT="${PERCENT}%%"
1178         fi
1179     fi
1180 fi
1181 }
1182 # set colors for use in prompts
1183 if zrcautoload colors && colors 2>/dev/null ; then
1184     BLUE="%{${fg[blue]}%}"
1185     RED="%{${fg_bold[red]}%}"
1186     GREEN="%{${fg[green]}%}"
1187     CYAN="%{${fg[cyan]}%}"
1188     MAGENTA="%{${fg[magenta]}%}"
1189     YELLOW="%{${fg[yellow]}%}"
1190     WHITE="%{${fg[white]}%}"
1191     NO_COLOUR="%{${reset_color}%}"
1192 else
1193     BLUE=$'%{\e[1;34m%}'
1194     RED=$'%{\e[1;31m%}'
1195     GREEN=$'%{\e[1;32m%}'
1196     CYAN=$'%{\e[1;36m%}'
1197     WHITE=$'%{\e[1;37m%}'
1198     MAGENTA=$'%{\e[1;35m%}'
1199     YELLOW=$'%{\e[1;33m%}'
1200     NO_COLOUR=$'%{\e[0m%}'
1201 fi
1202
1203 # gather version control information for inclusion in a prompt
1204
1205 if zrcautoload vcs_info; then
1206     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1207     # function, which can cause a lot of trouble with our directory-based
1208     # profiles. So:
1209     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1210         function VCS_INFO_realpath () {
1211             setopt localoptions NO_shwordsplit chaselinks
1212             ( builtin cd -q $1 2> /dev/null && pwd; )
1213         }
1214     fi
1215
1216     zstyle ':vcs_info:*' max-exports 2
1217
1218     if [[ -o restricted ]]; then
1219         zstyle ':vcs_info:*' enable NONE
1220     fi
1221 fi
1222
1223 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1224 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1225 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1226 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1227 #       to $vcs_info_msg_N_ as soon as we use the included version.
1228 if [[ "$TERM" == dumb ]] ; then
1229     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1230     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1231 else
1232     # these are the same, just with a lot of colours:
1233     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
1234                                        "zsh: %r"
1235     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
1236                                        "zsh: %r"
1237     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1238 fi
1239
1240 # command not found handling
1241
1242 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1243 function command_not_found_handler() {
1244     emulate -L zsh
1245     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1246         ${GRML_ZSH_CNF_HANDLER} $1
1247     fi
1248     return 1
1249 }
1250
1251 # set prompt
1252 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1253     promptinit # people should be able to use their favourite prompt
1254 else
1255     print 'Notice: no promptinit available :('
1256 fi
1257
1258 setopt prompt_subst
1259
1260 # make sure to use right prompt only when not running a command
1261 is41 && setopt transient_rprompt
1262
1263
1264 function ESC_print () {
1265     info_print $'\ek' $'\e\\' "$@"
1266 }
1267 function set_title () {
1268     info_print  $'\e]0;' $'\a' "$@"
1269 }
1270
1271 function info_print () {
1272     local esc_begin esc_end
1273     esc_begin="$1"
1274     esc_end="$2"
1275     shift 2
1276     printf '%s' ${esc_begin}
1277     printf '%s' "$*"
1278     printf '%s' "${esc_end}"
1279 }
1280
1281 # TODO: revise all these NO* variables and especially their documentation
1282 #       in zsh-help() below.
1283 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1284     [[ $NOPRECMD -gt 0 ]] && return 0
1285     # update VCS information
1286     (( ${+functions[vcs_info]} )) && vcs_info
1287
1288     if [[ $TERM == screen* ]] ; then
1289         if [[ -n ${vcs_info_msg_1_} ]] ; then
1290             ESC_print ${vcs_info_msg_1_}
1291         else
1292             ESC_print "zsh"
1293         fi
1294     fi
1295     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1296     if [[ ${DONTSETRPROMPT:-} -eq 0 ]] ; then
1297         if [[ $BATTERY -gt 0 ]] ; then
1298             # update battery (dropped into $PERCENT) information
1299             battery
1300             RPROMPT="%(?..:() ${PERCENT}"
1301         else
1302             RPROMPT="%(?..:() "
1303         fi
1304     fi
1305     # adjust title of xterm
1306     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1307     [[ ${NOTITLE:-} -gt 0 ]] && return 0
1308     case $TERM in
1309         (xterm*|rxvt*)
1310             set_title ${(%):-"%n@%m: %~"}
1311             ;;
1312     esac
1313 }
1314
1315 # preexec() => a function running before every command
1316 is4 && [[ $NOPRECMD -eq 0 ]] && \
1317 preexec () {
1318     [[ $NOPRECMD -gt 0 ]] && return 0
1319 # set hostname if not running on host with name 'grml'
1320     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1321        NAME="@$HOSTNAME"
1322     fi
1323 # get the name of the program currently running and hostname of local machine
1324 # set screen window title if running in a screen
1325     if [[ "$TERM" == screen* ]] ; then
1326         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1327         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1328         ESC_print ${CMD}
1329     fi
1330 # adjust title of xterm
1331     [[ ${NOTITLE} -gt 0 ]] && return 0
1332     case $TERM in
1333         (xterm*|rxvt*)
1334             set_title "${(%):-"%n@%m:"}" "$1"
1335             ;;
1336     esac
1337 }
1338
1339 EXITCODE="%(?..%?%1v )"
1340 PS2='\`%_> '      # secondary prompt, printed when the shell needs more information to complete a command.
1341 PS3='?# '         # selection prompt used within a select loop.
1342 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1343
1344 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1345 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1346     debian_chroot=$(cat /etc/debian_chroot)
1347 fi
1348
1349 # don't use colors on dumb terminals (like emacs):
1350 if [[ "$TERM" == dumb ]] ; then
1351     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
1352 else
1353     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
1354     # set variable identifying the chroot you work in (used in the prompt below)
1355     if [[ $GRMLPROMPT -gt 0 ]] ; then
1356         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1357 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1358     else
1359         # This assembles the primary prompt string
1360         if (( EUID != 0 )); then
1361             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1362         else
1363             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
1364         fi
1365     fi
1366 fi
1367
1368 PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
1369
1370 # if we are inside a grml-chroot set a specific prompt theme
1371 if [[ -n "$GRML_CHROOT" ]] ; then
1372     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1373 fi
1374
1375 # 'hash' some often used directories
1376 #d# start
1377 hash -d deb=/var/cache/apt/archives
1378 hash -d doc=/usr/share/doc
1379 hash -d linux=/lib/modules/$(command uname -r)/build/
1380 hash -d log=/var/log
1381 hash -d slog=/var/log/syslog
1382 hash -d src=/usr/src
1383 hash -d templ=/usr/share/doc/grml-templates
1384 hash -d tt=/usr/share/doc/texttools-doc
1385 hash -d www=/var/www
1386 #d# end
1387
1388 # some aliases
1389 if check_com -c screen ; then
1390     if [[ $UID -eq 0 ]] ; then
1391         [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
1392     elif [[ -r $HOME/.screenrc ]] ; then
1393         alias screen="${commands[screen]} -c $HOME/.screenrc"
1394     else
1395         if [[ -r /etc/grml/screenrc_grml ]]; then
1396             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1397         else
1398             [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
1399         fi
1400     fi
1401 fi
1402
1403 # do we have GNU ls with color-support?
1404 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
1405     #a1# execute \kbd{@a@}:\quad ls with colors
1406     alias ls='ls -b -CF --color=auto'
1407     #a1# execute \kbd{@a@}:\quad list all files, with colors
1408     alias la='ls -la --color=auto'
1409     #a1# long colored list, without dotfiles (@a@)
1410     alias ll='ls -l --color=auto'
1411     #a1# long colored list, human readable sizes (@a@)
1412     alias lh='ls -hAl --color=auto'
1413     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1414     alias l='ls -lF --color=auto'
1415 else
1416     alias ls='ls -b -CF'
1417     alias la='ls -la'
1418     alias ll='ls -l'
1419     alias lh='ls -hAl'
1420     alias l='ls -lF'
1421 fi
1422
1423 alias mdstat='cat /proc/mdstat'
1424 alias ...='cd ../../'
1425
1426 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1427 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1428     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1429 fi
1430
1431 alias cp='nocorrect cp'         # no spelling correction on cp
1432 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
1433 alias mv='nocorrect mv'         # no spelling correction on mv
1434 alias rm='nocorrect rm'         # no spelling correction on rm
1435
1436 #a1# Execute \kbd{rmdir}
1437 alias rd='rmdir'
1438 #a1# Execute \kbd{mkdir}
1439 alias md='mkdir'
1440
1441 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1442 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1443 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1444
1445 # make sure it is not assigned yet
1446 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1447 utf2iso() {
1448     if isutfenv ; then
1449         for ENV in $(env | command grep -i '.utf') ; do
1450             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1451         done
1452     fi
1453 }
1454
1455 # make sure it is not assigned yet
1456 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1457 iso2utf() {
1458     if ! isutfenv ; then
1459         for ENV in $(env | command grep -i '\.iso') ; do
1460             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1461         done
1462     fi
1463 }
1464
1465 # I like clean prompt, so provide simple way to get that
1466 check_com 0 || alias 0='return 0'
1467
1468 # for really lazy people like mika:
1469 check_com S &>/dev/null || alias S='screen'
1470 check_com s &>/dev/null || alias s='ssh'
1471
1472 # especially for roadwarriors using GNU screen and ssh:
1473 if ! check_com asc &>/dev/null ; then
1474   asc() { autossh -t "$@" 'screen -RdU' }
1475   compdef asc=ssh
1476 fi
1477
1478 # get top 10 shell commands:
1479 alias top10='print -l ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
1480
1481 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
1482 if check_com -c truecrypt ; then
1483     if isutfenv ; then
1484         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
1485     else
1486         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
1487     fi
1488 fi
1489
1490 #f1# Hints for the use of zsh on grml
1491 zsh-help() {
1492     print "$bg[white]$fg[black]
1493 zsh-help - hints for use of zsh on grml
1494 =======================================$reset_color"
1495
1496     print '
1497 Main configuration of zsh happens in /etc/zsh/zshrc.
1498 That file is part of the package grml-etc-core, if you want to
1499 use them on a non-grml-system just get the tar.gz from
1500 http://deb.grml.org/ or (preferably) get it from the git repository:
1501
1502   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1503
1504 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1505 The file is still there, but it is empty for backwards compatibility.
1506
1507 For your own changes use these two files:
1508     $HOME/.zshrc.pre
1509     $HOME/.zshrc.local
1510
1511 The former is sourced very early in our zshrc, the latter is sourced
1512 very lately.
1513
1514 System wide configuration without touching configuration files of grml
1515 can take place in /etc/zsh/zshrc.local.
1516
1517 Normally, the root user (EUID == 0) does not get the whole grml setup.
1518 If you want to force the whole setup for that user, too, set
1519 GRML_ALWAYS_LOAD_ALL=1 in .zshrc.pre in root'\''s home directory.
1520
1521 For information regarding zsh start at http://grml.org/zsh/
1522
1523 Take a look at grml'\''s zsh refcard:
1524 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1525
1526 Check out the main zsh refcard:
1527 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1528
1529 And of course visit the zsh-lovers:
1530 % man zsh-lovers
1531
1532 You can adjust some options through environment variables when
1533 invoking zsh without having to edit configuration files.
1534 Basically meant for bash users who are not used to the power of
1535 the zsh yet. :)
1536
1537   "NOCOR=1    zsh" => deactivate automatic correction
1538   "NOMENU=1   zsh" => do not use auto menu completion (note: use ctrl-d for completion instead!)
1539   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1540   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1541                       preexec() and precmd() completely
1542   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1543   "COMMAND_NOT_FOUND=1 zsh"
1544                    => Enable a handler if an external command was not found
1545                       The command called in the handler can be altered by setting
1546                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1547                       "/usr/share/command-not-found/command-not-found"
1548
1549 A value greater than 0 is enables a feature; a value equal to zero
1550 disables it. If you like one or the other of these settings, you can
1551 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1552 zshrc.'
1553
1554     print "
1555 $bg[white]$fg[black]
1556 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1557 Enjoy your grml system with the zsh!$reset_color"
1558 }
1559
1560 # debian stuff
1561 if [[ -r /etc/debian_version ]] ; then
1562     #a3# Execute \kbd{apt-cache search}
1563     alias acs='apt-cache search'
1564     #a3# Execute \kbd{apt-cache show}
1565     alias acsh='apt-cache show'
1566     #a3# Execute \kbd{apt-cache policy}
1567     alias acp='apt-cache policy'
1568     #a3# Execute \kbd{apt-get dist-upgrade}
1569     salias adg="apt-get dist-upgrade"
1570     #a3# Execute \kbd{apt-get install}
1571     salias agi="apt-get install"
1572     #a3# Execute \kbd{aptitude install}
1573     salias ati="aptitude install"
1574     #a3# Execute \kbd{apt-get upgrade}
1575     salias ag="apt-get upgrade"
1576     #a3# Execute \kbd{apt-get update}
1577     salias au="apt-get update"
1578     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1579     salias -a up="aptitude update ; aptitude safe-upgrade"
1580     #a3# Execute \kbd{dpkg-buildpackage}
1581     alias dbp='dpkg-buildpackage'
1582     #a3# Execute \kbd{grep-excuses}
1583     alias ge='grep-excuses'
1584
1585     # debian upgrade
1586     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
1587     upgrade() {
1588         emulate -L zsh
1589         if [[ -z $1 ]] ; then
1590             $SUDO apt-get update
1591             $SUDO apt-get -u upgrade
1592         else
1593             ssh $1 $SUDO apt-get update
1594             # ask before the upgrade
1595             local dummy
1596             ssh $1 $SUDO apt-get --no-act upgrade
1597             echo -n 'Process the upgrade?'
1598             read -q dummy
1599             if [[ $dummy == "y" ]] ; then
1600                 ssh $1 $SUDO apt-get -u upgrade --yes
1601             fi
1602         fi
1603     }
1604
1605     # get a root shell as normal user in live-cd mode:
1606     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1607        alias su="sudo su"
1608      fi
1609
1610     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1611     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1612     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1613     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1614 fi
1615
1616 # sort installed Debian-packages by size
1617 if check_com -c dpkg-query ; then
1618     #a3# List installed Debian-packages sorted by size
1619     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1620 fi
1621
1622 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1623 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1624     if check_com -c wodim; then
1625         cdrecord() {
1626             cat <<EOMESS
1627 cdrecord is not provided under its original name by Debian anymore.
1628 See #377109 in the BTS of Debian for more details.
1629
1630 Please use the wodim binary instead
1631 EOMESS
1632             return 1
1633         }
1634     fi
1635 fi
1636
1637 # Use hard limits, except for a smaller stack and no core dumps
1638 unlimit
1639 is425 && limit stack 8192
1640 isgrmlcd && limit core 0 # important for a live-cd-system
1641 limit -s
1642
1643 # completion system
1644
1645 # called later (via is4 && grmlcomp)
1646 # note: use 'zstyle' for getting current settings
1647 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
1648 grmlcomp() {
1649     # TODO: This could use some additional information
1650
1651     # allow one error for every three characters typed in approximate completer
1652     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1653
1654     # don't complete backup files as executables
1655     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1656
1657     # start menu completion only if it could find no unambiguous initial string
1658     zstyle ':completion:*:correct:*'       insert-unambiguous true
1659     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1660     zstyle ':completion:*:correct:*'       original true
1661
1662     # activate color-completion
1663     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1664
1665     # format on completion
1666     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1667
1668     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1669     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1670
1671     # insert all expansions for expand completer
1672     zstyle ':completion:*:expand:*'        tag-order all-expansions
1673     zstyle ':completion:*:history-words'   list false
1674
1675     # activate menu
1676     zstyle ':completion:*:history-words'   menu yes
1677
1678     # ignore duplicate entries
1679     zstyle ':completion:*:history-words'   remove-all-dups yes
1680     zstyle ':completion:*:history-words'   stop yes
1681
1682     # match uppercase from lowercase
1683     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1684
1685     # separate matches into groups
1686     zstyle ':completion:*:matches'         group 'yes'
1687     zstyle ':completion:*'                 group-name ''
1688
1689     if [[ "$NOMENU" -eq 0 ]] ; then
1690         # if there are more than 5 options allow selecting from a menu
1691         zstyle ':completion:*'               menu select=5
1692     else
1693         # don't use any menus at all
1694         setopt no_auto_menu
1695     fi
1696
1697     zstyle ':completion:*:messages'        format '%d'
1698     zstyle ':completion:*:options'         auto-description '%d'
1699
1700     # describe options in full
1701     zstyle ':completion:*:options'         description 'yes'
1702
1703     # on processes completion complete all user processes
1704     zstyle ':completion:*:processes'       command 'ps -au$USER'
1705
1706     # offer indexes before parameters in subscripts
1707     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1708
1709     # provide verbose completion information
1710     zstyle ':completion:*'                 verbose true
1711
1712     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1713     # for commands (read: 1st word in the line) that it will list for the user
1714     # to choose from. The following disables that, because it's not exactly fast.
1715     zstyle ':completion:*:-command-:*:'    verbose false
1716
1717     # set format for warnings
1718     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1719
1720     # define files to ignore for zcompile
1721     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1722     zstyle ':completion:correct:'          prompt 'correct to: %e'
1723
1724     # Ignore completion functions for commands you don't have:
1725     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1726
1727     # Provide more processes in completion of programs like killall:
1728     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1729
1730     # complete manual by their section
1731     zstyle ':completion:*:manuals'    separate-sections true
1732     zstyle ':completion:*:manuals.*'  insert-sections   true
1733     zstyle ':completion:*:man:*'      menu yes select
1734
1735     # provide .. as a completion
1736     zstyle ':completion:*' special-dirs ..
1737
1738     # run rehash on completion so new installed program are found automatically:
1739     _force_rehash() {
1740         (( CURRENT == 1 )) && rehash
1741         return 1
1742     }
1743
1744     ## correction
1745     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1746     if [[ "$NOCOR" -gt 0 ]] ; then
1747         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1748         setopt nocorrect
1749     else
1750         # try to be smart about when to use what completer...
1751         setopt correct
1752         zstyle -e ':completion:*' completer '
1753             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1754                 _last_try="$HISTNO$BUFFER$CURSOR"
1755                 reply=(_complete _match _ignored _prefix _files)
1756             else
1757                 if [[ $words[1] == (rm|mv) ]] ; then
1758                     reply=(_complete _files)
1759                 else
1760                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1761                 fi
1762             fi'
1763     fi
1764
1765     # command for process lists, the local web server details and host completion
1766     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1767
1768     # caching
1769     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1770                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1771
1772     # host completion
1773     if is42 ; then
1774         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1775         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1776     else
1777         _ssh_hosts=()
1778         _etc_hosts=()
1779     fi
1780     hosts=(
1781         $(hostname)
1782         "$_ssh_hosts[@]"
1783         "$_etc_hosts[@]"
1784         grml.org
1785         localhost
1786     )
1787     zstyle ':completion:*:hosts' hosts $hosts
1788     # TODO: so, why is this here?
1789     #  zstyle '*' hosts $hosts
1790
1791     # use generic completion system for programs not yet defined; (_gnu_generic works
1792     # with commands that provide a --help option with "standard" gnu-like output.)
1793     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
1794                    pal stow tail uname ; do
1795         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
1796     done; unset compcom
1797
1798     # see upgrade function in this file
1799     compdef _hosts upgrade
1800 }
1801
1802 # grmlstuff
1803 grmlstuff() {
1804 # people should use 'grml-x'!
1805     if check_com -c 915resolution; then
1806         855resolution() {
1807             echo "Please use 915resolution as resolution modifying tool for Intel \
1808 graphic chipset."
1809             return -1
1810         }
1811     fi
1812
1813     #a1# Output version of running grml
1814     alias grml-version='cat /etc/grml_version'
1815
1816     if check_com -c rebuildfstab ; then
1817         #a1# Rebuild /etc/fstab
1818         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1819     fi
1820
1821     if check_com -c grml-debootstrap ; then
1822         debian2hd() {
1823             echo "Installing debian to harddisk is possible by using grml-debootstrap."
1824             return 1
1825         }
1826     fi
1827 }
1828
1829 # now run the functions
1830 isgrml && checkhome
1831 is4    && isgrml    && grmlstuff
1832 is4    && grmlcomp
1833
1834 # keephack
1835 is4 && xsource "/etc/zsh/keephack"
1836
1837 # wonderful idea of using "e" glob qualifier by Peter Stephenson
1838 # You use it as follows:
1839 # $ NTREF=/reference/file
1840 # $ ls -l *(e:nt:)
1841 # This lists all the files in the current directory newer than the reference file.
1842 # You can also specify the reference file inline; note quotes:
1843 # $ ls -l *(e:'nt ~/.zshenv':)
1844 is4 && nt() {
1845     if [[ -n $1 ]] ; then
1846         local NTREF=${~1}
1847     fi
1848     [[ $REPLY -nt $NTREF ]]
1849 }
1850
1851 # shell functions
1852
1853 #f1# Reload an autoloadable function
1854 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1855 compdef _functions freload
1856
1857 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
1858 sll() {
1859     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
1860     for file in "$@" ; do
1861         while [[ -h "$file" ]] ; do
1862             ls -l $file
1863             file=$(readlink "$file")
1864         done
1865     done
1866 }
1867
1868 # TODO: Is it supported to use pager settings like this?
1869 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
1870 # with respect to wordsplitting. (ie. ${=PAGER})
1871 if check_com -c $PAGER ; then
1872     #f1# View Debian's changelog of a given package
1873     dchange() {
1874         emulate -L zsh
1875         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
1876             $PAGER /usr/share/doc/$1/changelog.Debian.gz
1877         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1878             $PAGER /usr/share/doc/$1/changelog.gz
1879         else
1880             if check_com -c aptitude ; then
1881                 echo "No changelog for package $1 found, using aptitude to retrieve it."
1882                 if isgrml ; then
1883                     aptitude -t unstable changelog $1
1884                 else
1885                     aptitude changelog $1
1886                 fi
1887             else
1888                 echo "No changelog for package $1 found, sorry."
1889                 return 1
1890             fi
1891         fi
1892     }
1893     _dchange() { _files -W /usr/share/doc -/ }
1894     compdef _dchange dchange
1895
1896     #f1# View Debian's NEWS of a given package
1897     dnews() {
1898         emulate -L zsh
1899         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
1900             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
1901         else
1902             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
1903                 $PAGER /usr/share/doc/$1/NEWS.gz
1904             else
1905                 echo "No NEWS file for package $1 found, sorry."
1906                 return 1
1907             fi
1908         fi
1909     }
1910     _dnews() { _files -W /usr/share/doc -/ }
1911     compdef _dnews dnews
1912
1913     #f1# View upstream's changelog of a given package
1914     uchange() {
1915         emulate -L zsh
1916         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
1917             $PAGER /usr/share/doc/$1/changelog.gz
1918         else
1919             echo "No changelog for package $1 found, sorry."
1920             return 1
1921         fi
1922     }
1923     _uchange() { _files -W /usr/share/doc -/ }
1924     compdef _uchange uchange
1925 fi
1926
1927 # zsh profiling
1928 profile() {
1929     ZSH_PROFILE_RC=1 $SHELL "$@"
1930 }
1931
1932 #f1# Edit an alias via zle
1933 edalias() {
1934     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
1935 }
1936 compdef _aliases edalias
1937
1938 #f1# Edit a function via zle
1939 edfunc() {
1940     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
1941 }
1942 compdef _functions edfunc
1943
1944 # use it e.g. via 'Restart apache2'
1945 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
1946 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
1947 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
1948 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
1949 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
1950 if [[ -d /etc/init.d || -d /etc/service ]] ; then
1951     __start_stop() {
1952         local action_="${1:l}"  # e.g Start/Stop/Restart
1953         local service_="$2"
1954         local param_="$3"
1955
1956         local service_target_="$(readlink /etc/init.d/$service_)"
1957         if [[ $service_target_ == "/usr/bin/sv" ]]; then
1958             # runit
1959             case "${action_}" in
1960                 start) if [[ ! -e /etc/service/$service_ ]]; then
1961                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
1962                        else
1963                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1964                        fi ;;
1965                 # there is no reload in runits sysv emulation
1966                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
1967                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
1968             esac
1969         else
1970             # sysvinit
1971             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
1972         fi
1973     }
1974
1975     _grmlinitd() {
1976         local -a scripts
1977         scripts=( /etc/init.d/*(x:t) )
1978         _describe "service startup script" scripts
1979     }
1980
1981     for i in Start Restart Stop Force-Reload Reload ; do
1982         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
1983         compdef _grmlinitd $i
1984     done
1985 fi
1986
1987 #f1# Provides useful information on globbing
1988 H-Glob() {
1989     echo -e "
1990     /      directories
1991     .      plain files
1992     @      symbolic links
1993     =      sockets
1994     p      named pipes (FIFOs)
1995     *      executable plain files (0100)
1996     %      device files (character or block special)
1997     %b     block special files
1998     %c     character special files
1999     r      owner-readable files (0400)
2000     w      owner-writable files (0200)
2001     x      owner-executable files (0100)
2002     A      group-readable files (0040)
2003     I      group-writable files (0020)
2004     E      group-executable files (0010)
2005     R      world-readable files (0004)
2006     W      world-writable files (0002)
2007     X      world-executable files (0001)
2008     s      setuid files (04000)
2009     S      setgid files (02000)
2010     t      files with the sticky bit (01000)
2011
2012   print *(m-1)          # Files modified up to a day ago
2013   print *(a1)           # Files accessed a day ago
2014   print *(@)            # Just symlinks
2015   print *(Lk+50)        # Files bigger than 50 kilobytes
2016   print *(Lk-50)        # Files smaller than 50 kilobytes
2017   print **/*.c          # All *.c files recursively starting in \$PWD
2018   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2019   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2020   print *~*.*           # All Files that do not contain a dot
2021   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2022   print -l *(.c|.h)     # Lists *.c and *.h
2023   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2024   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2025 }
2026 alias help-zshglob=H-Glob
2027
2028 #v1# set number of lines to display per page
2029 HELP_LINES_PER_PAGE=20
2030 #v1# set location of help-zle cache file
2031 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
2032 #f1# helper function for help-zle, actually generates the help text
2033 help_zle_parse_keybindings()
2034 {
2035     emulate -L zsh
2036     setopt extendedglob
2037     unsetopt ksharrays  #indexing starts at 1
2038
2039     #v1# choose files that help-zle will parse for keybindings
2040     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
2041
2042     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
2043         local load_cache=0
2044         for f ($KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
2045         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
2046     fi
2047
2048     #fill with default keybindings, possibly to be overwriten in a file later
2049     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2050     local -A help_zle_keybindings
2051     help_zle_keybindings['<Ctrl>@']="set MARK"
2052     help_zle_keybindings['<Ctrl>X<Ctrl>J']="vi-join lines"
2053     help_zle_keybindings['<Ctrl>X<Ctrl>B']="jump to matching brace"
2054     help_zle_keybindings['<Ctrl>X<Ctrl>U']="undo"
2055     help_zle_keybindings['<Ctrl>_']="undo"
2056     help_zle_keybindings['<Ctrl>X<Ctrl>F<c>']="find <c> in cmdline"
2057     help_zle_keybindings['<Ctrl>A']="goto beginning of line"
2058     help_zle_keybindings['<Ctrl>E']="goto end of line"
2059     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2060     help_zle_keybindings['<Alt>T']="transpose words"
2061     help_zle_keybindings['<Alt>s']="spellcheck word"
2062     help_zle_keybindings['<Ctrl>K']="backward kill buffer"
2063     help_zle_keybindings['<Ctrl>U']="forward kill buffer"
2064     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2065     help_zle_keybindings["<Alt>'"]="quote line"
2066     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2067     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2068     help_zle_keybindings['<Alt>U']="make next word Uppercase"
2069     help_zle_keybindings['<Alt>l']="make next word lowercase"
2070     help_zle_keybindings['<Ctrl>Xd']="preview expansion under cursor"
2071     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2072     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2073     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2074     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2075     help_zle_keybindings['<Ctrl>V']="insert next keypress symbol literally (e.g. for bindkey)"
2076     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2077     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2078     help_zle_keybindings['<Alt>H']="run help on current command"
2079
2080     #init global variables
2081     unset help_zle_lines help_zle_sln
2082     typeset -g -a help_zle_lines
2083     typeset -g help_zle_sln=1
2084
2085     local k v
2086     local lastkeybind_desc contents     #last description starting with #k# that we found
2087     local num_lines_elapsed=0            #number of lines between last description and keybinding
2088     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2089     for f in $HELPZLE_KEYBINDING_FILES; do
2090         [[ -r "$f" ]] || continue   #not readable ? skip it
2091         contents="$(<$f)"
2092         for cline in "${(f)contents}"; do
2093             #zsh pattern: matches lines like: #k# ..............
2094             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2095                 lastkeybind_desc="$match[*]"
2096                 num_lines_elapsed=0
2097             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2098             #             ignores lines that are commentend out
2099             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2100             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2101                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2102                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2103                     #substitute keybinding string with something readable
2104                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2105                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2106                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2107                     help_zle_keybindings[${k}]=$lastkeybind_desc
2108                 fi
2109                 lastkeybind_desc=""
2110             else
2111               ((num_lines_elapsed++))
2112             fi
2113         done
2114     done
2115     unset contents
2116     #calculate length of keybinding column
2117     local kstrlen=0
2118     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2119     #convert the assoc array into preformated lines, which we are able to sort
2120     for k v in ${(kv)help_zle_keybindings[@]}; do
2121         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2122         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2123     done
2124     #sort lines alphabetically
2125     help_zle_lines=("${(i)help_zle_lines[@]}")
2126     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2127     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2128     zcompile $HELP_ZLE_CACHE_FILE
2129 }
2130 typeset -g help_zle_sln
2131 typeset -g -a help_zle_lines
2132
2133 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2134 help-zle()
2135 {
2136     emulate -L zsh
2137     unsetopt ksharrays  #indexing starts at 1
2138     #help lines already generated ? no ? then do it
2139     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2140     #already displayed all lines ? go back to the start
2141     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2142     local sln=$help_zle_sln
2143     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2144     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2145     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2146 }
2147 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2148 zle -N help-zle && bindkey '^Xz' help-zle
2149
2150 # grep for running process, like: 'any vim'
2151 any() {
2152     emulate -L zsh
2153     unsetopt KSH_ARRAYS
2154     if [[ -z "$1" ]] ; then
2155         echo "any - grep for process(es) by keyword" >&2
2156         echo "Usage: any <keyword>" >&2 ; return 1
2157     else
2158         ps xauwww | grep -i --color=auto "[${1[1]}]${1[2,-1]}"
2159     fi
2160 }
2161
2162
2163 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2164 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2165 [[ -r /proc/1/maps ]] && \
2166 deswap() {
2167     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2168     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2169     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2170 }
2171
2172 # spawn a minimally set up mksh - useful if you want to umount /usr/.
2173 minimal-shell() {
2174     emulate -L zsh
2175     local shell="/bin/mksh"
2176
2177     if [[ ! -x ${shell} ]]; then
2178         printf '`%s'\'' not available, giving up.\n' ${shell} >&2
2179         return 1
2180     fi
2181
2182     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ${shell}
2183 }
2184
2185 # a wrapper for vim, that deals with title setting
2186 #   VIM_OPTIONS
2187 #       set this array to a set of options to vim you always want
2188 #       to have set when calling vim (in .zshrc.local), like:
2189 #           VIM_OPTIONS=( -p )
2190 #       This will cause vim to send every file given on the
2191 #       commandline to be send to it's own tab (needs vim7).
2192 vim() {
2193     VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2194 }
2195
2196 # make a backup of a file
2197 bk() {
2198     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2199 }
2200
2201 ssl_hashes=( sha512 sha256 sha1 md5 )
2202
2203 for sh in ${ssl_hashes}; do
2204     eval 'ssl-cert-'${sh}'() {
2205         emulate -L zsh
2206         if [[ -z $1 ]] ; then
2207             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2208             return 1
2209         fi
2210         openssl x509 -noout -fingerprint -'${sh}' -in $1
2211     }'
2212 done; unset sh
2213
2214 ssl-cert-fingerprints() {
2215     emulate -L zsh
2216     local i
2217     if [[ -z $1 ]] ; then
2218         printf 'usage: ssl-cert-fingerprints <file>\n'
2219         return 1
2220     fi
2221     for i in ${ssl_hashes}
2222         do ssl-cert-$i $1;
2223     done
2224 }
2225
2226 ssl-cert-info() {
2227     emulate -L zsh
2228     if [[ -z $1 ]] ; then
2229         printf 'usage: ssl-cert-info <file>\n'
2230         return 1
2231     fi
2232     openssl x509 -noout -text -in $1
2233     ssl-cert-fingerprints $1
2234 }
2235
2236 # make sure our environment is clean regarding colors
2237 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2238
2239 # "persistent history"
2240 # just write important commands you always need to ~/.important_commands
2241 if [[ -r ~/.important_commands ]] ; then
2242     fc -R ~/.important_commands
2243 fi
2244
2245 # load the lookup subsystem if it's available on the system
2246 zrcautoload lookupinit && lookupinit
2247
2248 ### non-root (EUID != 0) code below
2249 ###
2250
2251 if (( GRML_ALWAYS_LOAD_ALL == 0 )) && (( $EUID == 0 )) ; then
2252     zrclocal
2253     return 0
2254 fi
2255
2256 # variables
2257
2258 # set terminal property (used e.g. by msgid-chooser)
2259 export COLORTERM="yes"
2260
2261 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
2262 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
2263 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
2264
2265 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
2266 #v# [for non-root only]
2267 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
2268
2269 # aliases
2270
2271 # Xterm resizing-fu.
2272 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
2273 alias hide='echo -en "\033]50;nil2\007"'
2274 alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
2275 alias small='echo -en "\033]50;6x10\007"'
2276 alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
2277 alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
2278 alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
2279 alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
2280 alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
2281 alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
2282
2283 # general
2284 #a2# Execute \kbd{du -sch}
2285 alias da='du -sch'
2286 #a2# Execute \kbd{jobs -l}
2287 alias j='jobs -l'
2288
2289 # compile stuff
2290 #a2# Execute \kbd{./configure}
2291 alias CO="./configure"
2292 #a2# Execute \kbd{./configure --help}
2293 alias CH="./configure --help"
2294
2295 # listing stuff
2296 #a2# Execute \kbd{ls -lSrah}
2297 alias dir="ls -lSrah"
2298 #a2# Only show dot-directories
2299 alias lad='ls -d .*(/)'                # only show dot-directories
2300 #a2# Only show dot-files
2301 alias lsa='ls -a .*(.)'                # only show dot-files
2302 #a2# Only files with setgid/setuid/sticky flag
2303 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
2304 #a2# Only show 1st ten symlinks
2305 alias lsl='ls -l *(@)'                 # only symlinks
2306 #a2# Display only executables
2307 alias lsx='ls -l *(*)'                 # only executables
2308 #a2# Display world-{readable,writable,executable} files
2309 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
2310 #a2# Display the ten biggest files
2311 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
2312 #a2# Only show directories
2313 alias lsd='ls -d *(/)'                 # only show directories
2314 #a2# Only show empty directories
2315 alias lse='ls -d *(/^F)'               # only show empty directories
2316 #a2# Display the ten newest files
2317 alias lsnew="ls -rtlh *(D.om[1,10])"   # display the newest files
2318 #a2# Display the ten oldest files
2319 alias lsold="ls -rtlh *(D.Om[1,10])"   # display the oldest files
2320 #a2# Display the ten smallest files
2321 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
2322
2323 # chmod
2324 #a2# Execute \kbd{chmod 600}
2325 alias rw-='chmod 600'
2326 #a2# Execute \kbd{chmod 700}
2327 alias rwx='chmod 700'
2328 #m# a2 r-{}- Execute \kbd{chmod 644}
2329 alias r--='chmod 644'
2330 #a2# Execute \kbd{chmod 755}
2331 alias r-x='chmod 755'
2332
2333 # some useful aliases
2334 #a2# Execute \kbd{mkdir -p}
2335 alias md='mkdir -p'
2336 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir $OLDCWD}
2337 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2338
2339 # console stuff
2340 #a2# Execute \kbd{mplayer -vo fbdev}
2341 alias cmplayer='mplayer -vo fbdev'
2342 #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
2343 alias fbmplayer='mplayer -vo fbdev -fs -zoom'
2344 #a2# Execute \kbd{links2 -driver fb}
2345 alias fblinks='links2 -driver fb'
2346
2347 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2348 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2349 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2350
2351 # simple webserver
2352 check_com -c python && alias http="python -m SimpleHTTPServer"
2353
2354 # Use 'g' instead of 'git':
2355 check_com g || alias g='git'
2356
2357 # work around non utf8 capable software in utf environment via $LANG and luit
2358 if check_com isutfenv && check_com luit ; then
2359     if check_com -c mrxvt ; then
2360         isutfenv && [[ -n "$LANG" ]] && \
2361             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2362     fi
2363
2364     if check_com -c aterm ; then
2365         isutfenv && [[ -n "$LANG" ]] && \
2366             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2367     fi
2368
2369     if check_com -c centericq ; then
2370         isutfenv && [[ -n "$LANG" ]] && \
2371             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2372     fi
2373 fi
2374
2375 # useful functions
2376
2377 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2378 bk() {
2379     emulate -L zsh
2380     cp -b $1 $1_`date --iso-8601=m`
2381 }
2382
2383 #f5# cd to directoy and list files
2384 cl() {
2385     emulate -L zsh
2386     cd $1 && ls -a
2387 }
2388
2389 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2390 cd() {
2391     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2392         [[ ! -e ${1:h} ]] && return 1
2393         print "Correcting ${1} to ${1:h}"
2394         builtin cd ${1:h}
2395     else
2396         builtin cd "$@"
2397     fi
2398 }
2399
2400 #f5# Create Directoy and \kbd{cd} to it
2401 mcd() {
2402     mkdir -p "$@" && cd "$@"
2403 }
2404 #f5# Create temporary directory and \kbd{cd} to it
2405 cdt() {
2406     local t
2407     t=$(mktemp -d)
2408     echo "$t"
2409     builtin cd "$t"
2410 }
2411
2412 #f5# Create directory under cursor or the selected area
2413 # Press ctrl-xM to create the directory under the cursor or the selected area.
2414 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2415 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2416 # directory does not exist yet -> press ctrl-XM and problem solved
2417 inplaceMkDirs() {
2418     local PATHTOMKDIR
2419     if ((REGION_ACTIVE==1)); then
2420         local F=$MARK T=$CURSOR
2421         if [[ $F -gt $T ]]; then
2422             F=${CURSOR}
2423             T=${MARK}
2424         fi
2425         # get marked area from buffer and eliminate whitespace
2426         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2427         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2428     else
2429         local bufwords iword
2430         bufwords=(${(z)LBUFFER})
2431         iword=${#bufwords}
2432         bufwords=(${(z)BUFFER})
2433         PATHTOMKDIR="${(Q)bufwords[iword]}"
2434     fi
2435     [[ -z "${PATHTOMKDIR}" ]] && return 1
2436     if [[ -e "${PATHTOMKDIR}" ]]; then
2437         zle -M " path already exists, doing nothing"
2438     else
2439         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2440         zle end-of-line
2441     fi
2442 }
2443 #k# mkdir -p <dir> from string under cursor or marked area
2444 zle -N inplaceMkDirs && bindkey '^XM' inplaceMkDirs
2445
2446 # Function Usage: doc packagename
2447 #f5# \kbd{cd} to /usr/share/doc/\textit{package}
2448 doc() {
2449     emulate -L zsh
2450     cd /usr/share/doc/$1 && ls
2451 }
2452 _doc() { _files -W /usr/share/doc -/ }
2453 check_com compdef && compdef _doc doc
2454
2455 #f5# Make screenshot
2456 sshot() {
2457     [[ ! -d ~/shots  ]] && mkdir ~/shots
2458     #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
2459     cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
2460 }
2461
2462 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2463 accessed() {
2464     emulate -L zsh
2465     print -l -- *(a-${1:-1})
2466 }
2467
2468 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2469 changed() {
2470     emulate -L zsh
2471     print -l -- *(c-${1:-1})
2472 }
2473
2474 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2475 modified() {
2476     emulate -L zsh
2477     print -l -- *(m-${1:-1})
2478 }
2479 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2480 check_com new || alias new=modified
2481
2482 # use colors when GNU grep with color-support
2483 #a2# Execute \kbd{grep -{}-color=auto}
2484 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
2485 #a2# Execute \kbd{grep -i -{}-color=auto}
2486 alias GREP='grep -i --color=auto'
2487
2488 # Translate DE<=>EN
2489 # 'translate' looks up fot a word in a file with language-to-language
2490 # translations (field separator should be " : "). A typical wordlist looks
2491 # like at follows:
2492 #  | english-word : german-transmission
2493 # It's also only possible to translate english to german but not reciprocal.
2494 # Use the following oneliner to turn back the sort order:
2495 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2496 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2497 #f5# Translates a word
2498 trans() {
2499     emulate -L zsh
2500     case "$1" in
2501         -[dD]*)
2502             translate -l de-en $2
2503             ;;
2504         -[eE]*)
2505             translate -l en-de $2
2506             ;;
2507         *)
2508             echo "Usage: $0 { -D | -E }"
2509             echo "         -D == German to English"
2510             echo "         -E == English to German"
2511     esac
2512 }
2513
2514 # Usage: simple-extract <file>
2515 # Using option -d deletes the original archive file.
2516 #f5# Smart archive extractor
2517 simple-extract() {
2518     emulate -L zsh
2519     setopt extended_glob noclobber
2520     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2521     local RC=0
2522     zparseopts -D -E "d=DELETE_ORIGINAL"
2523     for ARCHIVE in "${@}"; do
2524         case $ARCHIVE in
2525             *.(tar.bz2|tbz2|tbz))
2526                 DECOMP_CMD="tar -xvjf -"
2527                 USES_STDIN=true
2528                 USES_STDOUT=false
2529                 ;;
2530             *.(tar.gz|tgz))
2531                 DECOMP_CMD="tar -xvzf -"
2532                 USES_STDIN=true
2533                 USES_STDOUT=false
2534                 ;;
2535             *.(tar.xz|txz|tar.lzma))
2536                 DECOMP_CMD="tar -xvJf -"
2537                 USES_STDIN=true
2538                 USES_STDOUT=false
2539                 ;;
2540             *.tar)
2541                 DECOMP_CMD="tar -xvf -"
2542                 USES_STDIN=true
2543                 USES_STDOUT=false
2544                 ;;
2545             *.rar)
2546                 DECOMP_CMD="unrar x"
2547                 USES_STDIN=false
2548                 USES_STDOUT=false
2549                 ;;
2550             *.lzh)
2551                 DECOMP_CMD="lha x"
2552                 USES_STDIN=false
2553                 USES_STDOUT=false
2554                 ;;
2555             *.7z)
2556                 DECOMP_CMD="7z x"
2557                 USES_STDIN=false
2558                 USES_STDOUT=false
2559                 ;;
2560             *.(zip|jar))
2561                 DECOMP_CMD="unzip"
2562                 USES_STDIN=false
2563                 USES_STDOUT=false
2564                 ;;
2565             *.deb)
2566                 DECOMP_CMD="ar -x"
2567                 USES_STDIN=false
2568                 USES_STDOUT=false
2569                 ;;
2570             *.bz2)
2571                 DECOMP_CMD="bzip2 -d -c -"
2572                 USES_STDIN=true
2573                 USES_STDOUT=true
2574                 ;;
2575             *.(gz|Z))
2576                 DECOMP_CMD="gzip -d -c -"
2577                 USES_STDIN=true
2578                 USES_STDOUT=true
2579                 ;;
2580             *.(xz|lzma))
2581                 DECOMP_CMD="xz -d -c -"
2582                 USES_STDIN=true
2583                 USES_STDOUT=true
2584                 ;;
2585             *)
2586                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2587                 RC=$((RC+1))
2588                 continue
2589                 ;;
2590         esac
2591
2592         if ! check_com ${DECOMP_CMD[(w)1]}; then
2593             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2594             RC=$((RC+2))
2595             continue
2596         fi
2597
2598         GZTARGET="${ARCHIVE:t:r}"
2599         if [[ -f $ARCHIVE ]] ; then
2600
2601             print "Extracting '$ARCHIVE' ..."
2602             if $USES_STDIN; then
2603                 if $USES_STDOUT; then
2604                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
2605                 else
2606                     ${=DECOMP_CMD} < "$ARCHIVE"
2607                 fi
2608             else
2609                 if $USES_STDOUT; then
2610                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
2611                 else
2612                     ${=DECOMP_CMD} "$ARCHIVE"
2613                 fi
2614             fi
2615             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
2616
2617         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
2618             if check_com curl; then
2619                 WGET_CMD="curl -L -k -s -o -"
2620             elif check_com wget; then
2621                 WGET_CMD="wget -q -O - --no-check-certificate"
2622             else
2623                 print "ERROR: neither wget nor curl is installed" >&2
2624                 RC=$((RC+4))
2625                 continue
2626             fi
2627             print "Downloading and Extracting '$ARCHIVE' ..."
2628             if $USES_STDIN; then
2629                 if $USES_STDOUT; then
2630                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
2631                     RC=$((RC+$?))
2632                 else
2633                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
2634                     RC=$((RC+$?))
2635                 fi
2636             else
2637                 if $USES_STDOUT; then
2638                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
2639                 else
2640                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
2641                 fi
2642             fi
2643
2644         else
2645             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
2646             RC=$((RC+8))
2647         fi
2648     done
2649     return $RC
2650 }
2651
2652 __archive_or_uri()
2653 {
2654     _alternative \
2655         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
2656         '_urls:Remote Archives:_urls'
2657 }
2658
2659 _simple_extract()
2660 {
2661     _arguments \
2662         '-d[delete original archivefile after extraction]' \
2663         '*:Archive Or Uri:__archive_or_uri'
2664 }
2665 compdef _simple_extract simple-extract
2666 alias se=simple-extract
2667
2668 # Usage: smartcompress <file> (<type>)
2669 #f5# Smart archive creator
2670 smartcompress() {
2671     emulate -L zsh
2672     if [[ -n $2 ]] ; then
2673         case $2 in
2674             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
2675             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
2676             tar.Z)          tar -Zcvf$1.$2 $1 ;;
2677             tar)            tar -cvf$1.$2  $1 ;;
2678             gz | gzip)      gzip           $1 ;;
2679             bz2 | bzip2)    bzip2          $1 ;;
2680             *)
2681                 echo "Error: $2 is not a valid compression type"
2682                 ;;
2683         esac
2684     else
2685         smartcompress $1 tar.gz
2686     fi
2687 }
2688
2689 # Usage: show-archive <archive>
2690 #f5# List an archive's content
2691 show-archive() {
2692     emulate -L zsh
2693     if [[ -f $1 ]] ; then
2694         case $1 in
2695             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
2696             *.tar)         tar -tf $1 ;;
2697             *.tgz)         tar -ztf $1 ;;
2698             *.zip)         unzip -l $1 ;;
2699             *.bz2)         bzless $1 ;;
2700             *.deb)         dpkg-deb --fsys-tarfile $1 | tar -tf - -- ;;
2701             *)             echo "'$1' Error. Please go away" ;;
2702         esac
2703     else
2704         echo "'$1' is not a valid archive"
2705     fi
2706 }
2707
2708 # TODO: So, this is the third incarnation of this function!?
2709 #f5# Reload given functions
2710 refunc() {
2711     for func in $argv ; do
2712         unfunction $func
2713         autoload $func
2714     done
2715 }
2716 compdef _functions refunc
2717
2718 #f5# Set all ulimit parameters to \kbd{unlimited}
2719 allulimit() {
2720     ulimit -c unlimited
2721     ulimit -d unlimited
2722     ulimit -f unlimited
2723     ulimit -l unlimited
2724     ulimit -n unlimited
2725     ulimit -s unlimited
2726     ulimit -t unlimited
2727 }
2728
2729 # highlight important stuff in diff output, usage example: hg diff | hidiff
2730 #m# a2 hidiff \kbd{histring} oneliner for diffs
2731 check_com -c histring && \
2732     alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
2733
2734 #f5# Change the xterm title from within GNU-screen
2735 xtrename() {
2736     emulate -L zsh
2737     if [[ $1 != "-f" ]] ; then
2738         if [[ -z ${DISPLAY} ]] ; then
2739             printf 'xtrename only makes sense in X11.\n'
2740             return 1
2741         fi
2742     else
2743         shift
2744     fi
2745     if [[ -z $1 ]] ; then
2746         printf 'usage: xtrename [-f] "title for xterm"\n'
2747         printf '  renames the title of xterm from _within_ screen.\n'
2748         printf '  also works without screen.\n'
2749         printf '  will not work if DISPLAY is unset, use -f to override.\n'
2750         return 0
2751     fi
2752     print -n "\eP\e]0;${1}\C-G\e\\"
2753     return 0
2754 }
2755
2756 # TODO:
2757 # Rewrite this by either using tinyurl.com's API
2758 # or using another shortening service to comply with
2759 # tinyurl.com's policy.
2760 #
2761 # Create small urls via http://tinyurl.com using wget(1).
2762 #function zurl() {
2763 #    emulate -L zsh
2764 #    [[ -z $1 ]] && { print "USAGE: zurl <URL>" ; return 1 }
2765 #
2766 #    local PN url tiny grabber search result preview
2767 #    PN=$0
2768 #    url=$1
2769 ##   Check existence of given URL with the help of ping(1).
2770 ##   N.B. ping(1) only works without an eventual given protocol.
2771 #    ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
2772 #        read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
2773 #
2774 #    if (( $? == 0 )) ; then
2775 ##           Prepend 'http://' to given URL where necessary for later output.
2776 #            [[ ${url} != http(s|)://* ]] && url='http://'${url}
2777 #            tiny='http://tinyurl.com/create.php?url='
2778 #            if check_com -c wget ; then
2779 #                grabber='wget -O- -o/dev/null'
2780 #            else
2781 #                print "wget is not available, but mandatory for ${PN}. Aborting."
2782 #            fi
2783 ##           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
2784 #            search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
2785 #            result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
2786 ##           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
2787 #            preview='http://preview.'${result#http://}
2788 #
2789 #            printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
2790 #            printf '%s\t%s\n\n' 'Given URL:' ${url}
2791 #            printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
2792 #    else
2793 #        return 1
2794 #    fi
2795 #}
2796
2797 #f2# Find history events by search pattern and list them by date.
2798 whatwhen()  {
2799     emulate -L zsh
2800     local usage help ident format_l format_s first_char remain first last
2801     usage='USAGE: whatwhen [options] <searchstring> <search range>'
2802     help='Use `whatwhen -h'\'' for further explanations.'
2803     ident=${(l,${#${:-Usage: }},, ,)}
2804     format_l="${ident}%s\t\t\t%s\n"
2805     format_s="${format_l//(\\t)##/\\t}"
2806     # Make the first char of the word to search for case
2807     # insensitive; e.g. [aA]
2808     first_char=[${(L)1[1]}${(U)1[1]}]
2809     remain=${1[2,-1]}
2810     # Default search range is `-100'.
2811     first=${2:-\-100}
2812     # Optional, just used for `<first> <last>' given.
2813     last=$3
2814     case $1 in
2815         ("")
2816             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
2817             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2818         ;;
2819         (-h)
2820             printf '%s\n\n' ${usage}
2821             print 'OPTIONS:'
2822             printf $format_l '-h' 'show help text'
2823             print '\f'
2824             print 'SEARCH RANGE:'
2825             printf $format_l "'0'" 'the whole history,'
2826             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
2827             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
2828             printf '\n%s\n' 'EXAMPLES:'
2829             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
2830             printf $format_l 'whatwhen zsh -250'
2831             printf $format_l 'whatwhen foo 1 99'
2832         ;;
2833         (\?)
2834             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2835         ;;
2836         (*)
2837             # -l list results on stout rather than invoking $EDITOR.
2838             # -i Print dates as in YYYY-MM-DD.
2839             # -m Search for a - quoted - pattern within the history.
2840             fc -li -m "*${first_char}${remain}*" $first $last
2841         ;;
2842     esac
2843 }
2844
2845 # mercurial related stuff
2846 if check_com -c hg ; then
2847     # gnu like diff for mercurial
2848     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
2849     #f5# GNU like diff for mercurial
2850     hgdi() {
2851         emulate -L zsh
2852         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
2853     }
2854
2855     # build debian package
2856     #a2# Alias for \kbd{hg-buildpackage}
2857     alias hbp='hg-buildpackage'
2858
2859     # execute commands on the versioned patch-queue from the current repos
2860     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
2861
2862     # diffstat for specific version of a mercurial repository
2863     #   hgstat      => display diffstat between last revision and tip
2864     #   hgstat 1234 => display diffstat between revision 1234 and tip
2865     #f5# Diffstat for specific version of a mercurial repos
2866     hgstat() {
2867         emulate -L zsh
2868         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
2869     }
2870
2871 fi # end of check whether we have the 'hg'-executable
2872
2873 # grml-small cleanups
2874
2875 # The following is used to remove zsh-config-items that do not work
2876 # in grml-small by default.
2877 # If you do not want these adjustments (for whatever reason), set
2878 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
2879 # sources if it is there).
2880
2881 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
2882
2883     unset abk[V]
2884     unalias    'V'      &> /dev/null
2885     unfunction vman     &> /dev/null
2886     unfunction viless   &> /dev/null
2887     unfunction 2html    &> /dev/null
2888
2889     # manpages are not in grmlsmall
2890     unfunction manzsh   &> /dev/null
2891     unfunction man2     &> /dev/null
2892
2893 fi
2894
2895 zrclocal
2896
2897 ## genrefcard.pl settings
2898
2899 ### doc strings for external functions from files
2900 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
2901
2902 ### example: split functions-search 8,16,24,32
2903 #@# split functions-search 8
2904
2905 ## END OF FILE #################################################################
2906 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
2907 # Local variables:
2908 # mode: sh
2909 # End: