etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # zsh-refcard-tag documentation: {{{
  15 #   You may notice strange looking comments in this file.
  16 #   These are there for a purpose. grml's zsh-refcard can now be
  17 #   automatically generated from the contents of the actual configuration
  18 #   file. However, we need a little extra information on which comments
  19 #   and what lines of code to take into account (and for what purpose).
  20 #
  21 # Here is what they mean:
  22 #
  23 # List of tags (comment types) used:
  24 #   #a#     Next line contains an important alias, that should
  25 #           be included in the grml-zsh-refcard.
  26 #           (placement tag: @@INSERT-aliases@@)
  27 #   #f#     Next line contains the beginning of an important function.
  28 #           (placement tag: @@INSERT-functions@@)
  29 #   #v#     Next line contains an important variable.
  30 #           (placement tag: @@INSERT-variables@@)
  31 #   #k#     Next line contains an important keybinding.
  32 #           (placement tag: @@INSERT-keybindings@@)
  33 #   #d#     Hashed directories list generation:
  34 #               start   denotes the start of a list of 'hash -d'
  35 #                       definitions.
  36 #               end     denotes its end.
  37 #           (placement tag: @@INSERT-hasheddirs@@)
  38 #   #A#     Abbreviation expansion list generation:
  39 #               start   denotes the beginning of abbreviations.
  40 #               end     denotes their end.
  41 #           Lines within this section that end in '#d .*' provide
  42 #           extra documentation to be included in the refcard.
  43 #           (placement tag: @@INSERT-abbrev@@)
  44 #   #m#     This tag allows you to manually generate refcard entries
  45 #           for code lines that are hard/impossible to parse.
  46 #               Example:
  47 #                   #m# k ESC-h Call the run-help function
  48 #               That would add a refcard entry in the keybindings table
  49 #               for 'ESC-h' with the given comment.
  50 #           So the syntax is: #m# <section> <argument> <comment>
  51 #   #o#     This tag lets you insert entries to the 'other' hash.
  52 #           Generally, this should not be used. It is there for
  53 #           things that cannot be done easily in another way.
  54 #           (placement tag: @@INSERT-other-foobar@@)
  55 #
  56 #   All of these tags (except for m and o) take two arguments, the first
  57 #   within the tag, the other after the tag:
  58 #
  59 #   #<tag><section># <comment>
  60 #
  61 #   Where <section> is really just a number, which are defined by the
  62 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  63 #   instead of names is, that for the reader, the tag should not differ
  64 #   much from a regular comment. For zsh, it is a regular comment indeed.
  65 #   The numbers have got the following meanings:
  66 #         0 -> "default"
  67 #         1 -> "system"
  68 #         2 -> "user"
  69 #         3 -> "debian"
  70 #         4 -> "search"
  71 #         5 -> "shortcuts"
  72 #         6 -> "services"
  73 #
  74 #   So, the following will add an entry to the 'functions' table in the
  75 #   'system' section, with a (hopefully) descriptive comment:
  76 #       #f1# Edit an alias via zle
  77 #       edalias() {
  78 #
  79 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  80 #   that can be found in 'grml-zsh-refcard.tex.in'.
  81 #   If the section number is omitted, the 'default' section is assumed.
  82 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
  83 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
  84 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
  85 #}}}
  86
  87 # zsh profiling {{{
  88 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
  89 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
  90     zmodload zsh/zprof
  91 fi
  92 # }}}
  93
  94 # load .zshrc.pre to give the user the chance to overwrite the defaults
  95 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
  96
  97 # {{{ check for version/system
  98 # check for versions (compatibility reasons)
  99 is4(){
 100     [[ $ZSH_VERSION == <4->* ]] && return 0
 101     return 1
 102 }
 103
 104 is41(){
 105     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 106     return 1
 107 }
 108
 109 is42(){
 110     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 111     return 1
 112 }
 113
 114 is425(){
 115     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 116     return 1
 117 }
 118
 119 is43(){
 120     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 121     return 1
 122 }
 123
 124 #f1# Checks whether or not you're running grml
 125 isgrml(){
 126     [[ -f /etc/grml_version ]] && return 0
 127     return 1
 128 }
 129
 130 #f1# Checks whether or not you're running a grml cd
 131 isgrmlcd(){
 132     [[ -f /etc/grml_cd ]] && return 0
 133     return 1
 134 }
 135
 136 if isgrml ; then
 137 #f1# Checks whether or not you're running grml-small
 138     isgrmlsmall() {
 139         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 140     }
 141 else
 142     isgrmlsmall() { return 1 }
 143 fi
 144
 145 isdarwin(){
 146     [[ $OSTYPE == darwin* ]] && return 0
 147     return 1
 148 }
 149
 150 #f1# are we running within an utf environment?
 151 isutfenv() {
 152     case "$LANG $CHARSET $LANGUAGE" in
 153         *utf*) return 0 ;;
 154         *UTF*) return 0 ;;
 155         *)     return 1 ;;
 156     esac
 157 }
 158
 159 # check for user, if not running as root set $SUDO to sudo
 160 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 161
 162 # change directory to home on first invocation of zsh
 163 # important for rungetty -> autologin
 164 # Thanks go to Bart Schaefer!
 165 isgrml && checkhome() {
 166     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 167         export ALREADY_DID_CD_HOME=$HOME
 168         cd
 169     fi
 170 }
 171
 172 # check for zsh v3.1.7+
 173
 174 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 175      || ${ZSH_VERSION} == 3.<2->.<->*    \
 176      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 177
 178     printf '-!-\n'
 179     printf '-!- In this configuration we try to make use of features, that only\n'
 180     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 181     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 182     printf '-!- advanced features in all supported versions.\n'
 183     printf '-!-\n'
 184     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 185     printf '-!-\n'
 186     printf '-!- While this *may* work, it might as well fail.\n'
 187     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 188     printf '-!-\n'
 189     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 190     printf '-!- If it does today, you'\''ve been lucky.\n'
 191     printf '-!-\n'
 192     printf '-!- Ye been warned!\n'
 193     printf '-!-\n'
 194
 195     function zstyle() { : }
 196 fi
 197
 198 # autoload wrapper - use this one instead of autoload directly
 199 # We need to define this function as early as this, because autoloading
 200 # 'is-at-least()' needs it.
 201 function zrcautoload() {
 202     setopt local_options extended_glob
 203     local fdir ffile
 204     local -i ffound
 205
 206     ffile=${1}
 207     (( found = 0 ))
 208     for fdir in ${fpath} ; do
 209         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 210     done
 211
 212     (( ffound == 0 )) && return 1
 213     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 214         autoload -U ${ffile} || return 1
 215     else
 216         autoload ${ffile} || return 1
 217     fi
 218     return 0
 219 }
 220
 221 # Load is-at-least() for more precise version checks
 222 # Note that this test will *always* fail, if the is-at-least
 223 # function could not be marked for autoloading.
 224 zrcautoload is-at-least || is-at-least() { return 1 }
 225
 226 # }}}
 227
 228 # setting some default values {{{
 229
 230 NOCOR=${NOCOR:-0}
 231 NOMENU=${NOMENU:-0}
 232 NOPRECMD=${NOPRECMD:-0}
 233 BATTERY=${BATTERY:-0}
 234 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 235 GRML_ALWAYS_LOAD_ALL=${GRML_ALWAYS_LOAD_ALL:-0}
 236 GRML_WARN_SKEL=${GRML_WARN_SKEL:-1}
 237
 238 if (( GRML_WARN_SKEL != 0 )) ; then
 239
 240 function grml_warn_skel_main() {
 241     printf '
 242 Dear user,
 243
 244 You updated grml'\''s zshrc which brings a major change.
 245 The configuration is kept only in one file, being the global zshrc.
 246 In the past, the configuration was split in two files, with the
 247 second file being the .zshrc file from /etc/skel.
 248
 249 If you have a .zshrc file in your home directory that originally
 250 came from the skel directory, please remove it. This is also the case
 251 if you followed earlier instructions from the grml-zsh-refcard or
 252 from <http://grml.org/console/> on non-grml systems.
 253
 254 Please see the current grml-zsh-refcard (available at
 255 <http://grml.org/zsh/>) for updated installation information. In short,
 256 you don'\''t want a .zshrc.global file. Install the global zshrc to
 257 ~/.zshrc and be done.
 258
 259 If you need changes to the configuration, use ~/.zshrc.pre and
 260 ~/.zshrc.local.
 261
 262 '
 263 }
 264
 265 function grml_warn_skel_remove() {
 266     printf 'To remove this warning execute '\''grml_do_not_warn_skel'\''.\n\n'
 267 }
 268
 269 function grml_do_not_warn_skel() {
 270     printf '# Do not warn about old skel dot-files anymore\n' >>! ~/.zshrc.pre
 271     printf 'GRML_WARN_SKEL=0\n' >>! ~/.zshrc.pre
 272 }
 273
 274 # let's try to guess how the user uses us.
 275 if is-at-least 4.3.7 ; then
 276     # funcsourcetrace requires at least version 4.3.7 of zsh.
 277     GRML_SRC_FILE="${${funcsourcetrace[1]}%:*}"
 278
 279     grml_warn_skel_main
 280     case ${GRML_SRC_FILE} in
 281         (${HOME}/.zshrc.global)
 282             grml_warn_skel_remove
 283             printf '\nIt looks like you copied the grml zshrc to '\''~/.zshrc.global'\''.\n'
 284             printf 'Nowadays you just copy the global zshrc to '\''~/.zshrc'\'' to use\n'
 285             printf 'it on a non-grml-system.\n'
 286             ;;
 287         (${HOME}/.zshrc)
 288             printf '\nIt looks like you copied the grml zshrc to '\''~/.zshrc'\''.\n'
 289             printf 'We'\''ll disable this warning automatically for later sessions.\n'
 290             grml_do_not_warn_skel
 291             ;;
 292         (*)
 293             grml_do_not_warn_skel
 294             ;;
 295     esac
 296 else
 297     grml_warn_skel_main
 298     grml_warn_skel_remove
 299 fi
 300
 301 unfunction grml_warn_skel_remove grml_warn_skel_main
 302
 303 fi # GRML_WARN_SKEL
 304
 305 # }}}
 306
 307 # utility functions {{{
 308 # this function checks if a command exists and returns either true
 309 # or false. This avoids using 'which' and 'whence', which will
 310 # avoid problems with aliases for which on certain weird systems. :-)
 311 check_com() {
 312     local -i comonly
 313
 314     if [[ ${1} == '-c' ]] ; then
 315         (( comonly = 1 ))
 316         shift
 317     else
 318         (( comonly = 0 ))
 319     fi
 320
 321     if (( ${#argv} != 1 )) ; then
 322         printf 'usage: check_com [-c] <command>\n' >&2
 323         return 1
 324     fi
 325
 326     if (( comonly > 0 )) ; then
 327         [[ -n ${commands[$1]}  ]] && return 0
 328         return 1
 329     fi
 330
 331     if   [[ -n ${commands[$1]}    ]] \
 332       || [[ -n ${functions[$1]}   ]] \
 333       || [[ -n ${aliases[$1]}     ]] \
 334       || [[ -n ${reswords[(r)$1]} ]] ; then
 335
 336         return 0
 337     fi
 338
 339     return 1
 340 }
 341
 342 # creates an alias and precedes the command with
 343 # sudo if $EUID is not zero.
 344 salias() {
 345     local only=0 ; local multi=0
 346     while [[ ${1} == -* ]] ; do
 347         case ${1} in
 348             (-o) only=1 ;;
 349             (-a) multi=1 ;;
 350             (--) shift ; break ;;
 351             (-h)
 352                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 353                 printf '  -h      shows this help text.\n'
 354                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 355                 printf '          be careful using this option.\n'
 356                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 357                 return 0
 358                 ;;
 359             (*) printf "unkown option: '%s'\n" "${1}" ; return 1 ;;
 360         esac
 361         shift
 362     done
 363
 364     if (( ${#argv} > 1 )) ; then
 365         printf 'Too many arguments %s\n' "${#argv}"
 366         return 1
 367     fi
 368
 369     key="${1%%\=*}" ;  val="${1#*\=}"
 370     if (( EUID == 0 )) && (( only == 0 )); then
 371         alias -- "${key}=${val}"
 372     elif (( EUID > 0 )) ; then
 373         (( multi > 0 )) && val="${val// ; / ; sudo }"
 374         alias -- "${key}=sudo ${val}"
 375     fi
 376
 377     return 0
 378 }
 379
 380 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 381 # usage: uprint foo
 382 #   Where foo is the *name* of the parameter you want printed.
 383 #   Note that foo is no typo; $foo would be wrong here!
 384 if ! is42 ; then
 385     uprint () {
 386         local -a u
 387         local w
 388         local parameter=${1}
 389
 390         if [[ -z ${parameter} ]] ; then
 391             printf 'usage: uprint <parameter>\n'
 392             return 1
 393         fi
 394
 395         for w in ${(P)parameter} ; do
 396             [[ -z ${(M)u:#${w}} ]] && u=( ${u} ${w} )
 397         done
 398
 399         builtin print -l ${u}
 400     }
 401 fi
 402
 403 # Check if we can read given files and source those we can.
 404 xsource() {
 405     if (( ${#argv} < 1 )) ; then
 406         printf 'usage: xsource FILE(s)...\n' >&2
 407         return 1
 408     fi
 409
 410     while (( ${#argv} > 0 )) ; do
 411         [[ -r ${1} ]] && source ${1}
 412         shift
 413     done
 414     return 0
 415 }
 416
 417 # Check if we can read a given file and 'cat(1)' it.
 418 xcat() {
 419     if (( ${#argv} != 1 )) ; then
 420         printf 'usage: xcat FILE\n' >&2
 421         return 1
 422     fi
 423
 424     [[ -r ${1} ]] && cat ${1}
 425     return 0
 426 }
 427
 428 # Remove these functions again, they are of use only in these
 429 # setup files. This should be called at the end of .zshrc.
 430 xunfunction() {
 431     local -a funcs
 432     funcs=(salias xcat xsource xunfunction zrcautoload)
 433
 434     for func in $funcs ; do
 435         [[ -n ${functions[$func]} ]] \
 436             && unfunction $func
 437     done
 438     return 0
 439 }
 440
 441 #}}}
 442
 443 # locale setup {{{
 444 if [[ -z "$LANG" ]] ; then
 445    xsource "/etc/default/locale"
 446 fi
 447
 448 export LANG=${LANG:-en_US.iso885915}
 449 for var in LC_ALL LC_MESSAGES ; do
 450     [[ -n ${(P)var} ]] && export $var
 451 done
 452
 453 xsource "/etc/sysconfig/keyboard"
 454
 455 TZ=$(xcat /etc/timezone)
 456 # }}}
 457
 458 # check for potentially old files in 'completion.d' {{{
 459 setopt extendedglob
 460 xof=(/etc/zsh/completion.d/*~/etc/zsh/completion.d/_*(N))
 461 if (( ${#xof} > 0 )) ; then
 462     printf '\n -!- INFORMATION\n\n'
 463     printf ' -!- %s file(s) not starting with an underscore (_) found in\n' ${#xof}
 464     printf ' -!- /etc/zsh/completion.d/.\n\n'
 465     printf ' -!- While this has been the case in old versions of grml-etc-core,\n'
 466     printf ' -!- recent versions of the grml-zsh-setup have all these files rewritten\n'
 467     printf ' -!- and renamed. Furthermore, the grml-zsh-setup will *only* add files\n'
 468     printf ' -!- named _* to that directory.\n\n'
 469     printf ' -!- If you added functions to completion.d yourself, please consider\n'
 470     printf ' -!- moving them to /etc/zsh/functions.d/. Files in that directory, not\n'
 471     printf ' -!- starting with an underscore are marked for automatic loading\n'
 472     printf ' -!- by default (so that is quite convenient).\n\n'
 473     printf ' -!- If there are files *not* starting with an underscore from an older\n'
 474     printf ' -!- grml-etc-core in completion.d, you may safely remove them.\n\n'
 475     printf ' -!- Delete the files for example via running:\n\n'
 476     printf "      rm ${xof}\n\n"
 477     printf ' -!- Note, that this message will *not* go away, unless you yourself\n'
 478     printf ' -!- resolve the situation manually.\n\n'
 479     BROKEN_COMPLETION_DIR=1
 480 fi
 481 unset xof
 482 # }}}
 483
 484 # {{{ set some variables
 485 if check_com -c vim ; then
 486 #v#
 487     export EDITOR=${EDITOR:-vim}
 488 else
 489     export EDITOR=${EDITOR:-vi}
 490 fi
 491
 492 #v#
 493 export PAGER=${PAGER:-less}
 494
 495 #v#
 496 export MAIL=${MAIL:-/var/mail/$USER}
 497
 498 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 499 export SHELL='/bin/zsh'
 500
 501 # color setup for ls:
 502 check_com -c dircolors && eval $(dircolors -b)
 503 # color setup for ls on OS X:
 504 isdarwin && export CLICOLOR=1
 505
 506 # do MacPorts setup on darwin
 507 if isdarwin && [[ -d /opt/local ]]; then
 508     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 509     # zshenv.
 510     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 511     MANPATH="/opt/local/share/man:$MANPATH"
 512 fi
 513 # do Fink setup on darwin
 514 isdarwin && xsource /sw/bin/init.sh
 515
 516 # completion functions go to /etc/zsh/completion.d
 517 # function files may be put into /etc/zsh/functions.d, from where they
 518 # will be automatically autoloaded.
 519 if [[ -n "$BROKEN_COMPLETION_DIR" ]] ; then
 520     print 'Warning: not setting completion directories because broken files have been found.' >&2
 521 else
 522     [[ -d /etc/zsh/completion.d ]] && fpath=( $fpath /etc/zsh/completion.d )
 523     if [[ -d /etc/zsh/functions.d ]] ; then
 524         fpath+=( /etc/zsh/functions.d )
 525         for func in /etc/zsh/functions.d/[^_]*[^~](N.) ; do
 526             zrcautoload -U ${func:t}
 527         done
 528     fi
 529 fi
 530
 531 # automatically remove duplicates from these arrays
 532 typeset -U path cdpath fpath manpath
 533 # }}}
 534
 535 # {{{ keybindings
 536 if [[ "$TERM" != emacs ]] ; then
 537     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 538     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 539     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 540     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 541     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 542     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 543     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 544     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 545     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 546     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 547     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 548     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 549     # ncurses stuff:
 550     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 551     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 552     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 553     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 554     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 555     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 556     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 557     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 558 fi
 559
 560 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 561 # use emacs style per default:
 562 bindkey -e
 563 # use vi style:
 564 # bindkey -v
 565
 566 #if [[ "$TERM" == screen ]] ; then
 567 bindkey '\e[1~' beginning-of-line       # home
 568 bindkey '\e[4~' end-of-line             # end
 569 bindkey '\e[A'  up-line-or-search       # cursor up
 570 bindkey '\e[B'  down-line-or-search     # <ESC>-
 571
 572 bindkey '^xp'   history-beginning-search-backward
 573 bindkey '^xP'   history-beginning-search-forward
 574 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 575 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 576 # if terminal type is set to 'rxvt':
 577 bindkey '\e[7~' beginning-of-line       # home
 578 bindkey '\e[8~' end-of-line             # end
 579 #fi
 580
 581 # insert unicode character
 582 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 583 # See for example http://unicode.org/charts/ for unicode characters code
 584 zrcautoload insert-unicode-char
 585 zle -N insert-unicode-char
 586 #k# Insert Unicode character
 587 bindkey '^Xi' insert-unicode-char
 588
 589 # just type 'cd ...' to get 'cd ../..'
 590 #  rationalise-dot() {
 591 #  if [[ $LBUFFER == *.. ]] ; then
 592 #    LBUFFER+=/..
 593 #  else
 594 #    LBUFFER+=.
 595 #  fi
 596 #  }
 597 #  zle -N rationalise-dot
 598 #  bindkey . rationalise-dot
 599
 600 #  bindkey '\eq' push-line-or-edit
 601
 602 ## toggle the ,. abbreviation feature on/off
 603 # NOABBREVIATION: default abbreviation-state
 604 #                 0 - enabled (default)
 605 #                 1 - disabled
 606 NOABBREVIATION=${NOABBREVIATION:-0}
 607
 608 grml_toggle_abbrev() {
 609     if (( ${NOABBREVIATION} > 0 )) ; then
 610         NOABBREVIATION=0
 611     else
 612         NOABBREVIATION=1
 613     fi
 614 }
 615
 616 zle -N grml_toggle_abbrev
 617 bindkey '^xA' grml_toggle_abbrev
 618
 619 # }}}
 620
 621 # a generic accept-line wrapper {{{
 622
 623 # This widget can prevent unwanted autocorrections from command-name
 624 # to _command-name, rehash automatically on enter and call any number
 625 # of builtin and user-defined widgets in different contexts.
 626 #
 627 # For a broader description, see:
 628 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 629 #
 630 # The code is imported from the file 'zsh/functions/accept-line' from
 631 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 632 # distributed under the same terms as zsh itself.
 633
 634 # A newly added command will may not be found or will cause false
 635 # correction attempts, if you got auto-correction set. By setting the
 636 # following style, we force accept-line() to rehash, if it cannot
 637 # find the first word on the command line in the $command[] hash.
 638 zstyle ':acceptline:*' rehash true
 639
 640 function Accept-Line() {
 641     setopt localoptions noksharrays
 642     local -a subs
 643     local -xi aldone
 644     local sub
 645
 646     zstyle -a ":acceptline:${alcontext}" actions subs
 647
 648     (( ${#subs} < 1 )) && return 0
 649
 650     (( aldone = 0 ))
 651     for sub in ${subs} ; do
 652         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 653         zle ${sub}
 654
 655         (( aldone > 0 )) && break
 656     done
 657 }
 658
 659 function Accept-Line-getdefault() {
 660     local default_action
 661
 662     zstyle -s ":acceptline:${alcontext}" default_action default_action
 663     case ${default_action} in
 664         ((accept-line|))
 665             printf ".accept-line"
 666             ;;
 667         (*)
 668             printf ${default_action}
 669             ;;
 670     esac
 671 }
 672
 673 function accept-line() {
 674     setopt localoptions noksharrays
 675     local -a cmdline
 676     local -x alcontext
 677     local buf com fname format msg default_action
 678
 679     alcontext='default'
 680     buf="${BUFFER}"
 681     cmdline=(${(z)BUFFER})
 682     com="${cmdline[1]}"
 683     fname="_${com}"
 684
 685     zstyle -t ":acceptline:${alcontext}" rehash \
 686         && [[ -z ${commands[$com]} ]]           \
 687         && rehash
 688
 689     if    [[ -n ${reswords[(r)$com]} ]] \
 690        || [[ -n ${aliases[$com]}     ]] \
 691        || [[ -n ${functions[$com]}   ]] \
 692        || [[ -n ${builtins[$com]}    ]] \
 693        || [[ -n ${commands[$com]}    ]] ; then
 694
 695         # there is something sensible to execute, just do it.
 696         alcontext='normal'
 697         zle Accept-Line
 698
 699         default_action=$(Accept-Line-getdefault)
 700         zstyle -T ":acceptline:${alcontext}" call_default \
 701             && zle ${default_action}
 702         return
 703     fi
 704
 705     if    [[ -o correct              ]] \
 706        || [[ -o correctall           ]] \
 707        && [[ -n ${functions[$fname]} ]] ; then
 708
 709         # nothing there to execute but there is a function called
 710         # _command_name; a completion widget. Makes no sense to
 711         # call it on the commandline, but the correct{,all} options
 712         # will ask for it nevertheless, so warn the user.
 713         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 714             # Okay, we warned the user before, he called us again,
 715             # so have it his way.
 716             alcontext='force'
 717             zle Accept-Line
 718
 719             default_action=$(Accept-Line-getdefault)
 720             zstyle -T ":acceptline:${alcontext}" call_default \
 721                 && zle ${default_action}
 722             return
 723         fi
 724
 725         # prepare warning message for the user, configurable via zstyle.
 726         zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 727
 728         if [[ -z ${msg} ]] ; then
 729             msg="%c will not execute and completion %f exists."
 730         fi
 731
 732         zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 733
 734         zle -M -- "${msg}"
 735         return
 736     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 737         # If we are here, the commandline contains something that is not
 738         # executable, which is neither subject to _command_name correction
 739         # and is not empty. might be a variable assignment
 740         alcontext='misc'
 741         zle Accept-Line
 742
 743         default_action=$(Accept-Line-getdefault)
 744         zstyle -T ":acceptline:${alcontext}" call_default \
 745             && zle ${default_action}
 746         return
 747     fi
 748
 749     # If we got this far, the commandline only contains whitespace, or is empty.
 750     alcontext='empty'
 751     zle Accept-Line
 752
 753     default_action=$(Accept-Line-getdefault)
 754     zstyle -T ":acceptline:${alcontext}" call_default \
 755         && zle ${default_action}
 756 }
 757
 758 zle -N accept-line
 759 zle -N Accept-Line
 760
 761 # }}}
 762
 763 # power completion - abbreviation expansion {{{
 764 # power completion / abbreviation expansion / buffer expansion
 765 # see http://zshwiki.org/home/examples/zleiab for details
 766 # less risky than the global aliases but powerful as well
 767 # just type the abbreviation key and afterwards ',.' to expand it
 768 declare -A abk
 769 setopt extendedglob
 770 setopt interactivecomments
 771 abk=(
 772 # key  # value                (#d additional doc string)
 773 #A# start
 774     '...' '../..'
 775     '....' '../../..'
 776     'BG' '& exit'
 777     'C' '| wc -l'
 778     'G' '|& grep --color=auto'
 779     'H' '| head'
 780     'Hl' ' --help |& less -r'      #d (Display help in pager)
 781     'L' '| less'
 782     'LL' '|& less -r'
 783     'M' '| most'
 784     'N' '&>/dev/null'              #d (No Output)
 785     'R' '| tr A-z N-za-m'          #d (ROT13)
 786     'SL' '| sort | less'
 787     'S' '| sort -u'
 788     'T' '| tail'
 789     'V' '|& vim -'
 790 #A# end
 791     'hide' "echo -en '\033]50;nil2\007'"
 792     'tiny' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
 793     'small' 'echo -en "\033]50;6x10\007"'
 794     'medium' 'echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
 795     'default' 'echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
 796     'large' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
 797     'huge' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
 798     'smartfont' 'echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
 799     'semifont' 'echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
 800     'da' 'du -sch'
 801     'j' 'jobs -l'
 802     'u' 'translate -i'
 803     'co' "./configure && make && sudo make install"
 804     'CH' "./configure --help"
 805     'conkeror' 'firefox -chrome chrome://conkeror/content'
 806     'dir' 'ls -lSrah'
 807     'lad' $'ls -d .*(/)\n# only show dot-directories'
 808     'lsa' $'ls -a .*(.)\n# only show dot-files'
 809     'lss' $'ls -l *(s,S,t)\n# only files with setgid/setuid/sticky flag'
 810     'lsl' $'ls -l *(@[1,10])\n# only symlinks'
 811     'lsx' $'ls -l *(*[1,10])\n# only executables'
 812     'lsw' $'ls -ld *(R,W,X.^ND/)\n# world-{readable,writable,executable} files'
 813     'lsbig' $'ls -flh *(.OL[1,10])\n# display the biggest files'
 814     'lsd' $'ls -d *(/)\n# only show directories'
 815     'lse' $'ls -d *(/^F)\n# only show empty directories'
 816     'lsnew' $'ls -rl *(D.om[1,10])\n# display the newest files'
 817     'lsold' $'ls -rtlh *(D.om[-11,-1])\n # display the oldest files'
 818     'lssmall' $'ls -Srl *(.oL[1,10])\n# display the smallest files'
 819     'rw-' 'chmod 600'
 820     '600' 'chmod u+rw-x,g-rwx,o-rwx'
 821     'rwx' 'chmod u+rwx'
 822     '700' 'chmod u+rwx,g-rwx,o-rwx'
 823     'r--' 'chmod u+r-wx,g-rwx,o-rwx'
 824     '644' $'chmod u+rw-x,g+r-wx,o+r-wx\n # 4=r,2=w,1=x'
 825     '755' 'chmod u+rwx,g+r-w+x,o+r-w+x'
 826     'md' 'mkdir -p '
 827     'cmplayer' 'mplayer -vo -fs -zoom fbdev'
 828     'fbmplayer' 'mplayer -vo -fs -zoom fbdev'
 829     'fblinks' 'links2 -driver fb'
 830     'insecssh' 'ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 831     'insecscp' 'scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 832     'fori' 'for i ({..}) { }'
 833     'cx' 'chmod +x'
 834     'e'  'print -l'
 835     'se' 'setopt interactivecomments'
 836     'va' 'valac --vapidir=../vapi/ --pkg=gtk+-2.0 gtktest.vala'
 837     'fb2' '=mplayer -vo fbdev -fs -zoom 1>/dev/null -xy 2'
 838     'fb3' '=mplayer -vo fbdev -fs  -zoom 1>/dev/null -xy 3'
 839     'ci' 'centericq'
 840     'D'  'export DISPLAY=:0.0'
 841     'mp' 'mplayer -vo xv -fs -zoom'
 842 )
 843
 844 globalias() {
 845     local MATCH
 846
 847     if (( NOABBREVIATION > 0 )) ; then
 848         LBUFFER="${LBUFFER},."
 849         return 0
 850     fi
 851
 852     matched_chars='[.-|_a-zA-Z0-9]#'
 853     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 854     LBUFFER+=${abk[$MATCH]:-$MATCH}
 855 }
 856
 857 zle -N globalias
 858 bindkey ",." globalias
 859 # }}}
 860
 861 # {{{ autoloading
 862 zrcautoload zmv    # who needs mmv or rename?
 863 zrcautoload history-search-end
 864
 865 # we don't want to quote/espace URLs on our own...
 866 # if autoload -U url-quote-magic ; then
 867 #    zle -N self-insert url-quote-magic
 868 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 869 # else
 870 #    print 'Notice: no url-quote-magic available :('
 871 # fi
 872 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 873
 874 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 875 alias run-help >&/dev/null && unalias run-help
 876 zrcautoload run-help # use via 'esc-h'
 877
 878 # completion system
 879 if zrcautoload compinit && compinit 2>/dev/null ; then
 880     compinit 2>/dev/null || print 'Notice: no compinit available :('
 881 else
 882     print 'Notice: no compinit available :('
 883     function zstyle { }
 884     function compdef { }
 885 fi
 886
 887 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 888
 889 is4 && \
 890 for mod in complist deltochar mathfunc ; do
 891     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 892 done
 893
 894 # autoload zsh modules when they are referenced
 895 if is4 ; then
 896     tmpargs=(
 897         a   stat
 898         a   zpty
 899         ap  mapfile
 900     )
 901
 902     while (( ${#tmpargs} > 0 )) ; do
 903         zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
 904         shift 2 tmpargs
 905     done
 906     unset tmpargs
 907 fi
 908
 909 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 910     #k# Insert files
 911     bindkey "^Xf" insert-files # C-x-f
 912 fi
 913
 914 bindkey ' '   magic-space    # also do history expansion on space
 915 #k# Trigger menu-complete
 916 bindkey '\ei' menu-complete  # menu completion via esc-i
 917
 918 # press esc-e for editing command line in $EDITOR or $VISUAL
 919 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 920     #k# Edit the current line in \kbd{\$EDITOR}
 921     bindkey '\ee' edit-command-line
 922 fi
 923
 924 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 925     #k# menu selection: pick item but stay in the menu
 926     bindkey -M menuselect '\e^M' accept-and-menu-complete
 927
 928     # accept a completion and try to complete again by using menu
 929     # completion; very useful with completing directories
 930     # by using 'undo' one's got a simple file browser
 931     bindkey -M menuselect '^o' accept-and-infer-next-history
 932 fi
 933
 934 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 935 _bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
 936 zle -N _bkdate
 937
 938 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 939 bindkey '^Ed' _bkdate
 940
 941 # press esc-m for inserting last typed word again (thanks to caphuso!)
 942 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 943 zle -N insert-last-typed-word;
 944
 945 #k# Insert last typed word
 946 bindkey "\em" insert-last-typed-word
 947
 948 #k# Shortcut for \kbd{fg<enter>}
 949 bindkey -s '^z' "fg\n"
 950
 951 # run command line as user root via sudo:
 952 sudo-command-line() {
 953     [[ -z $BUFFER ]] && zle up-history
 954     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
 955 }
 956 zle -N sudo-command-line
 957
 958 #k# Put the current command line into a \kbd{sudo} call
 959 bindkey "^Os" sudo-command-line
 960
 961 ### jump behind the first word on the cmdline.
 962 ### useful to add options.
 963 function jump_after_first_word() {
 964     local words
 965     words=(${(z)BUFFER})
 966
 967     if (( ${#words} <= 1 )) ; then
 968         CURSOR=${#BUFFER}
 969     else
 970         CURSOR=${#${words[1]}}
 971     fi
 972 }
 973 zle -N jump_after_first_word
 974
 975 bindkey '^x1' jump_after_first_word
 976
 977 # }}}
 978
 979 # {{{ set some important options
 980 # Please update these tags, if you change the umask settings below.
 981 #o# r_umask     002
 982 #o# r_umaskstr  rwxrwxr-x
 983 #o# umask       022
 984 #o# umaskstr    rwxr-xr-x
 985 (( EUID != 0 )) && umask 002 || umask 022
 986
 987 # history:
 988 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 989 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 990 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 991 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 992                             # list duplicates an older one, the older command is removed from the list
 993 setopt histignorespace      # remove command lines from the history list when
 994                             # the first character on the line is a space
 995 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 996                             # and the command is the name of a directory, perform the cd command to that directory
 997 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 998                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 999                             # -> searches for word not in compressed files
1000                             # don't forget to quote '^', '~' and '#'!
1001 setopt longlistjobs         # display PID when suspending processes as well
1002 setopt notify               # report the status of backgrounds jobs immediately
1003 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
1004                             # the entire command path is hashed first.
1005 setopt completeinword       # not just at the end
1006 setopt nohup                # and don't kill them, either
1007 setopt auto_pushd           # make cd push the old directory onto the directory stack.
1008 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
1009 setopt nobeep               # avoid "beep"ing
1010 setopt pushd_ignore_dups    # don't push the same dir twice.
1011
1012 MAILCHECK=30       # mailchecks
1013 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
1014 watch=(notme root) # watch for everyone but me and root
1015
1016 # only slash should be considered as a word separator:
1017 slash-backward-kill-word() {
1018     local WORDCHARS="${WORDCHARS:s@/@}"
1019     # zle backward-word
1020     zle backward-kill-word
1021 }
1022 zle -N slash-backward-kill-word
1023
1024 #k# Kill everything in a word up to its last \kbd{/}
1025 bindkey '\ev' slash-backward-kill-word
1026
1027 # }}}
1028
1029 # {{{ history
1030
1031 ZSHDIR=$HOME/.zsh
1032
1033 #v#
1034 HISTFILE=$HOME/.zsh_history
1035 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1036 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1037
1038 # }}}
1039
1040 # dirstack handling {{{
1041
1042 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1043 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1044
1045 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1046     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1047     # "cd -" won't work after login by just setting $OLDPWD, so
1048     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
1049 fi
1050
1051 chpwd() {
1052     if is42 ; then
1053         builtin print -l ${(u)dirstack} >! ${DIRSTACKFILE}
1054     else
1055         uprint dirstack >! ${DIRSTACKFILE}
1056     fi
1057 }
1058
1059 # }}}
1060
1061 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
1062 if [[ $BATTERY -gt 0 ]] ; then
1063     if ! check_com -c acpi ; then
1064         BATTERY=0
1065     fi
1066 fi
1067
1068 battery() {
1069 if [[ $BATTERY -gt 0 ]] ; then
1070     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]##Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1071     if [[ -z "$PERCENT" ]] ; then
1072         PERCENT='acpi not present'
1073     else
1074         if [[ "$PERCENT" -lt 20 ]] ; then
1075             PERCENT="warning: ${PERCENT}%%"
1076         else
1077             PERCENT="${PERCENT}%%"
1078         fi
1079     fi
1080 fi
1081 }
1082 # }}}
1083
1084 # set colors for use in prompts {{{
1085 if zrcautoload colors && colors 2>/dev/null ; then
1086     BLUE="%{${fg[blue]}%}"
1087     RED="%{${fg_bold[red]}%}"
1088     GREEN="%{${fg[green]}%}"
1089     CYAN="%{${fg[cyan]}%}"
1090     MAGENTA="%{${fg[magenta]}%}"
1091     YELLOW="%{${fg[yellow]}%}"
1092     WHITE="%{${fg[white]}%}"
1093     NO_COLOUR="%{${reset_color}%}"
1094 else
1095     BLUE=$'%{\e[1;34m%}'
1096     RED=$'%{\e[1;31m%}'
1097     GREEN=$'%{\e[1;32m%}'
1098     CYAN=$'%{\e[1;36m%}'
1099     WHITE=$'%{\e[1;37m%}'
1100     MAGENTA=$'%{\e[1;35m%}'
1101     YELLOW=$'%{\e[1;33m%}'
1102     NO_COLOUR=$'%{\e[0m%}'
1103 fi
1104
1105 # }}}
1106
1107 # gather version control information for inclusion in a prompt {{{
1108
1109 if ! is41 ; then
1110     # Be quiet about version problems in grml's zshrc as the user cannot disable
1111     # loading vcs_info() as it is *in* the zshrc - as you can see. :-)
1112     # Just unset most probable variables and disable vcs_info altogether.
1113     local -i i
1114     for i in {0..9} ; do
1115         unset VCS_INFO_message_${i}_
1116     done
1117     zstyle ':vcs_info:*' enable false
1118 fi
1119
1120 # The following code is imported from the file 'zsh/functions/vcs_info'
1121 # from <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>,
1122 # which distributed under the same terms as zsh itself.
1123
1124 # we will only be using one variable, so let the code know now.
1125 zstyle ':vcs_info:*' max-exports 1
1126
1127 # vcs_info() documentation:
1128 #{{{
1129 # REQUIREMENTS:
1130 #{{{
1131 #     This functionality requires zsh version >= 4.1.*.
1132 #}}}
1133 #
1134 # LOADING:
1135 #{{{
1136 # To load vcs_info(), copy this file to your $fpath[] and do:
1137 #   % autoload -Uz vcs_info && vcs_info
1138 #
1139 # To work, vcs_info() needs 'setopt prompt_subst' in your setup.
1140 #}}}
1141 #
1142 # QUICKSTART:
1143 #{{{
1144 # To get vcs_info() working quickly (including colors), you can do the
1145 # following (assuming, you loaded vcs_info() properly - see above):
1146 #
1147 # % RED=$'%{\e[31m%}'
1148 # % GR=$'%{\e[32m%}'
1149 # % MA=$'%{\e[35m%}'
1150 # % YE=$'%{\e[33m%}'
1151 # % NC=$'%{\e[0m%}'
1152 #
1153 # % zstyle ':vcs_info:*' actionformats \
1154 #       "${MA}(${NC}%s${MA})${YE}-${MA}[${GR}%b${YE}|${RED}%a${MA}]${NC} "
1155 #
1156 # % zstyle ':vcs_info:*' formats       \
1157 #       "${MA}(${NC}%s${MA})${Y}-${MA}[${GR}%b${MA}]${NC}%} "
1158 #
1159 # % zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YE}%r"
1160 #
1161 # % precmd () { vcs_info }
1162 # % PS1='${MA}[${GR}%n${MA}] ${MA}(${RED}%!${MA}) ${YE}%3~ ${VCS_INFO_message_0_}${NC}%# '
1163 #
1164 # Obviously, the las two lines are there for demonstration: You need to
1165 # call vcs_info() from your precmd() function (see 'SPECIAL FUNCTIONS' in
1166 # 'man zshmisc'). Once that is done you need a *single* quoted
1167 # '${VCS_INFO_message_0_}' in your prompt.
1168 #
1169 # Now call the 'vcs_info_printsys' utility from the command line:
1170 #
1171 # % vcs_info_printsys
1172 # # list of supported version control backends:
1173 # # disabled systems are prefixed by a hash sign (#)
1174 # git
1175 # hg
1176 # bzr
1177 # darcs
1178 # svk
1179 # mtn
1180 # svn
1181 # cvs
1182 # cdv
1183 # tla
1184 # # flavours (cannot be used in the disable style; they
1185 # # are disabled with their master [git-svn -> git]):
1186 # git-p4
1187 # git-svn
1188 #
1189 # Ten version control backends as you can see. You may not want all
1190 # of these. Because there is no point in running the code to detect
1191 # systems you do not use. ever. So, there is a way to disable some
1192 # backends altogether:
1193 #
1194 # % zstyle ':vcs_info:*' disable bzr cdv darcs mtn svk tla
1195 #
1196 # If you rerun 'vcs_info_printsys' now, you will see the backends listed
1197 # in the 'disable' style marked as diabled by a hash sign. That means the
1198 # detection of these systems is skipped *completely*. No wasted time there.
1199 #
1200 # For more control, read the reference below.
1201 #}}}
1202 #
1203 # CONFIGURATION:
1204 #{{{
1205 # The vcs_info() feature can be configured via zstyle.
1206 #
1207 # First, the context in which we are working:
1208 #       :vcs_info:<vcs-string>:<user-context>
1209 #
1210 # ...where <vcs-string> is one of:
1211 #   - git, git-svn, git-p4, hg, darcs, bzr, cdv, mtn, svn, cvs, svk or tla.
1212 #
1213 # ...and <user-context> is a freely configurable string, assignable by the
1214 # user as the first argument to vcs_info() (see its description below).
1215 #
1216 # There is are three special values for <vcs-string>: The first is named
1217 # 'init', that is in effect as long as there was no decision what vcs
1218 # backend to use. The second is 'preinit; it is used *before* vcs_info()
1219 # is run, when initializing the data exporting variables. The third
1220 # special value is 'formats' and is used by the 'vcs_info_lastmsg' for
1221 # looking up its styles.
1222 #
1223 # There are two pre-defined values for <user-context>:
1224 #   default  - the one used if none is specified
1225 #   command  - used by vcs_info_lastmsg to lookup its styles.
1226 #
1227 # You may *not* use 'print_systems_' as a user-context string, because it
1228 # is used internally.
1229 #
1230 # You can of course use ':vcs_info:*' to match all VCSs in all
1231 # user-contexts at once.
1232 #
1233 # Another special context is 'formats', which is used by the
1234 # vcs_info_lastmsg() utility function (see below).
1235 #
1236 #
1237 # This is a description of all styles, that are looked up:
1238 #   formats             - A list of formats, used when actionformats is not
1239 #                         used (which is most of the time).
1240 #   actionformats       - A list of formats, used if a there is a special
1241 #                         action going on in your current repository;
1242 #                         (like an interactive rebase or a merge conflict)
1243 #   branchformat        - Some backends replace %b in the formats and
1244 #                         actionformats styles above, not only by a branch
1245 #                         name but also by a revision number. This style
1246 #                         let's you modify how that string should look like.
1247 #   nvcsformats         - These "formats" are exported, when we didn't detect
1248 #                         a version control system for the current directory.
1249 #                         This is useful, if you want vcs_info() to completely
1250 #                         take over the generation of your prompt.
1251 #                         You would do something like
1252 #                           PS1='${VCS_INFO_message_0_}'
1253 #                         to accomplish that.
1254 #   max-exports         - Defines the maximum number if VCS_INFO_message_*_
1255 #                         variables vcs_info() will export.
1256 #   enable              - Checked in the 'init' context. If set to false,
1257 #                         vcs_info() will do nothing.
1258 #   disable             - Provide a list of systems, you don't want
1259 #                         the vcs_info() to check for repositories
1260 #                         (checked in the 'init' context, too).
1261 #   disable-patterns    - A list of patterns that are checked against $PWD.
1262 #                         If the pattern matches, vcs_info will be disabled.
1263 #                         Say, ~/.zsh is a directory under version control,
1264 #                         in which you do not want vcs_info to be active, do:
1265 #                         zstyle ':vcs_info:*' disable-patterns "$HOME/.zsh+(|/*)"
1266 #   use-simple          - If there are two different ways of gathering
1267 #                         information, you can select the simpler one
1268 #                         by setting this style to true; the default
1269 #                         is to use the not-that-simple code, which is
1270 #                         potentially a lot slower but might be more
1271 #                         accurate in all possible cases.
1272 #   use-prompt-escapes  - determines if we assume that the assembled
1273 #                         string from vcs_info() includes prompt escapes.
1274 #                         (Used by vcs_info_lastmsg().
1275 #
1276 # The use-simple style is only available for the bzr backend.
1277 #
1278 # The default values for these in all contexts are:
1279 #   formats             " (%s)-[%b|%a]-"
1280 #   actionformats       " (%s)-[%b]-"
1281 #   branchformat        "%b:%r" (for bzr, svn and svk)
1282 #   nvcsformats         ""
1283 #   max-exports         2
1284 #   enable              true
1285 #   disable             (empty list)
1286 #   disable-patterns    (empty list)
1287 #   use-simple          false
1288 #   use-prompt-escapes  true
1289 #
1290 #
1291 # In normal formats and actionformats, the following replacements
1292 # are done:
1293 #   %s  - The vcs in use (git, hg, svn etc.)
1294 #   %b  - Information about the current branch.
1295 #   %a  - An identifier, that describes the action.
1296 #         Only makes sense in actionformats.
1297 #   %R  - base directory of the repository.
1298 #   %r  - repository name
1299 #         If %R is '/foo/bar/repoXY', %r is 'repoXY'.
1300 #   %S  - subdirectory within a repository. if $PWD is
1301 #         '/foo/bar/reposXY/beer/tasty', %S is 'beer/tasty'.
1302 #
1303 #
1304 # In branchformat these replacements are done:
1305 #   %b  - the branch name
1306 #   %r  - the current revision number
1307 #
1308 # Not all vcs backends have to support all replacements.
1309 # nvcsformat does not perform *any* replacements. It is just a string.
1310 #}}}
1311 #
1312 # ODDITIES:
1313 #{{{
1314 # If you want to use the %b (bold off) prompt expansion in 'formats', which
1315 # expands %b itself, use %%b. That will cause the vcs_info() expansion to
1316 # replace %%b with %b. So zsh's prompt expansion mechanism can handle it.
1317 # Similarly, to hand down %b from branchformat, use %%%%b. Sorry for this
1318 # inconvenience, but it cannot be easily avoided. Luckily we do not clash
1319 # with a lot of prompt expansions and this only needs to be done for those.
1320 # See 'man zshmisc' for details about EXPANSION OF PROMPT SEQUENCES.
1321 #}}}
1322 #
1323 # FUNCTION DESCRIPTIONS (public API):
1324 #{{{
1325 #   vcs_info()
1326 #       The main function, that runs all backends and assembles
1327 #       all data into ${VCS_INFO_message_*_}. This is the function
1328 #       you want to call from precmd() if you want to include
1329 #       up-to-date information in your prompt (see VARIABLE
1330 #       DESCRIPTION below).
1331 #
1332 #   vcs_info_printsys()
1333 #       Prints a list of all supported version control systems.
1334 #       Useful to find out possible contexts (and which of them are enabled)
1335 #       or values for the 'disable' style.
1336 #
1337 #   vcs_info_lastmsg()
1338 #       Outputs the last ${VCS_INFO_message_*_} value. Takes into account
1339 #       the value of the use-prompt-escapes style in ':vcs_info:formats'.
1340 #       It also only prints max-exports values.
1341 #
1342 # All functions named VCS_INFO_* are for internal use only.
1343 #}}}
1344 #
1345 # VARIABLE DESCRIPTION:
1346 #{{{
1347 #   ${VCS_INFO_message_N_}    (Note the trailing underscore)
1348 #       Where 'N' is an integer, eg: VCS_INFO_message_0_
1349 #       These variables are the storage for the informational message the
1350 #       last vcs_info() call has assembled. These are strongly connected
1351 #       to the formats, actionformats and nvcsformats styles described
1352 #       above. Those styles are lists. the first member of that list gets
1353 #       expanded into ${VCS_INFO_message_0_}, the second into
1354 #       ${VCS_INFO_message_1_} and the Nth into ${VCS_INFO_message_N-1_}.
1355 #       These parameters are exported into the environment.
1356 #       (See the max-exports style above.)
1357 #}}}
1358 #
1359 # EXAMPLES:
1360 #{{{
1361 #   Don't use vcs_info at all (even though it's in your prompt):
1362 #   % zstyle ':vcs_info:*' enable false
1363 #
1364 #   Disable the backends for bzr and svk:
1365 #   % zstyle ':vcs_info:*' disable bzr svk
1366 #
1367 #   Provide a special formats for git:
1368 #   % zstyle ':vcs_info:git:*' formats       ' GIT, BABY! [%b]'
1369 #   % zstyle ':vcs_info:git:*' actionformats ' GIT ACTION! [%b|%a]'
1370 #
1371 #   Use the quicker bzr backend (if you do, please report if it does
1372 #   the-right-thing[tm] - thanks):
1373 #   % zstyle ':vcs_info:bzr:*' use-simple true
1374 #
1375 #   Display the revision number in yellow for bzr and svn:
1376 #   % zstyle ':vcs_info:(svn|bzr):*' branchformat '%b%{'${fg[yellow]}'%}:%r'
1377 #
1378 # If you want colors, make sure you enclose the color codes in %{...%},
1379 # if you want to use the string provided by vcs_info() in prompts.
1380 #
1381 # Here is how to print the vcs infomation as a command:
1382 #   % alias vcsi='vcs_info command; vcs_info_lastmsg'
1383 #
1384 #   This way, you can even define different formats for output via
1385 #   vcs_info_lastmsg() in the ':vcs_info:command:*' namespace.
1386 #}}}
1387 #}}}
1388 # utilities
1389 VCS_INFO_adjust () { #{{{
1390     [[ -n ${vcs_comm[overwrite_name]} ]] && vcs=${vcs_comm[overwrite_name]}
1391     return 0
1392 }
1393 # }}}
1394 VCS_INFO_check_com () { #{{{
1395     (( ${+commands[$1]} )) && [[ -x ${commands[$1]} ]] && return 0
1396     return 1
1397 }
1398 # }}}
1399 VCS_INFO_formats () { # {{{
1400     setopt localoptions noksharrays
1401     local action=$1 branch=$2 base=$3
1402     local msg
1403     local -i i
1404
1405     if [[ -n ${action} ]] ; then
1406         zstyle -a ":vcs_info:${vcs}:${usercontext}" actionformats msgs
1407         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b|%a]-'
1408     else
1409         zstyle -a ":vcs_info:${vcs}:${usercontext}" formats msgs
1410         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b]-'
1411     fi
1412
1413     (( ${#msgs} > maxexports )) && msgs[${maxexports},-1]=()
1414     for i in {1..${#msgs}} ; do
1415         zformat -f msg ${msgs[$i]} a:${action} b:${branch} s:${vcs} r:${base:t} R:${base} S:"$(VCS_INFO_reposub ${base})"
1416         msgs[$i]=${msg}
1417     done
1418     return 0
1419 }
1420 # }}}
1421 VCS_INFO_maxexports () { #{{{
1422     local -ix maxexports
1423
1424     zstyle -s ":vcs_info:${vcs}:${usercontext}" "max-exports" maxexports || maxexports=2
1425     if [[ ${maxexports} != <-> ]] || (( maxexports < 1 )); then
1426         printf 'vcs_info(): expecting numeric arg >= 1 for max-exports (got %s).\n' ${maxexports}
1427         printf 'Defaulting to 2.\n'
1428         maxexports=2
1429     fi
1430 }
1431 # }}}
1432 VCS_INFO_nvcsformats () { #{{{
1433     setopt localoptions noksharrays
1434     local c v
1435
1436     if [[ $1 == 'preinit' ]] ; then
1437         c=default
1438         v=preinit
1439     fi
1440     zstyle -a ":vcs_info:${v:-$vcs}:${c:-$usercontext}" nvcsformats msgs
1441     (( ${#msgs} > maxexports )) && msgs[${maxexports},-1]=()
1442 }
1443 # }}}
1444 VCS_INFO_realpath () { #{{{
1445     # a portable 'readlink -f'
1446     # forcing a subshell, to ensure chpwd() is not removed
1447     # from the calling shell (if VCS_INFO_realpath() is called
1448     # manually).
1449     (
1450         (( ${+functions[chpwd]} )) && unfunction chpwd
1451         setopt chaselinks
1452         cd $1 2>/dev/null && pwd
1453     )
1454 }
1455 # }}}
1456 VCS_INFO_reposub () { #{{{
1457     setopt localoptions extendedglob
1458     local base=${1%%/##}
1459
1460     [[ ${PWD} == ${base}/* ]] || {
1461         printf '.'
1462         return 1
1463     }
1464     printf '%s' ${PWD#$base/}
1465     return 0
1466 }
1467 # }}}
1468 VCS_INFO_set () { #{{{
1469     setopt localoptions noksharrays
1470     local -i i j
1471
1472     if [[ $1 == '--clear' ]] ; then
1473         for i in {0..9} ; do
1474             unset VCS_INFO_message_${i}_
1475         done
1476     fi
1477     if [[ $1 == '--nvcs' ]] ; then
1478         [[ $2 == 'preinit' ]] && (( maxexports == 0 )) && (( maxexports = 1 ))
1479         for i in {0..$((maxexports - 1))} ; do
1480             typeset -gx VCS_INFO_message_${i}_=
1481         done
1482         VCS_INFO_nvcsformats $2
1483     fi
1484
1485     (( ${#msgs} - 1 < 0 )) && return 0
1486     for i in {0..$(( ${#msgs} - 1 ))} ; do
1487         (( j = i + 1 ))
1488         typeset -gx VCS_INFO_message_${i}_=${msgs[$j]}
1489     done
1490     return 0
1491 }
1492 # }}}
1493 # information gathering
1494 VCS_INFO_bzr_get_data () { # {{{
1495     setopt localoptions noksharrays
1496     local bzrbase bzrbr
1497     local -a bzrinfo
1498
1499     if zstyle -t ":vcs_info:${vcs}:${usercontext}" "use-simple" ; then
1500         bzrbase=${vcs_comm[basedir]}
1501         bzrinfo[2]=${bzrbase:t}
1502         if [[ -f ${bzrbase}/.bzr/branch/last-revision ]] ; then
1503             bzrinfo[1]=$(< ${bzrbase}/.bzr/branch/last-revision)
1504             bzrinfo[1]=${${bzrinfo[1]}%% *}
1505         fi
1506     else
1507         bzrbase=${${(M)${(f)"$( bzr info )"}:# ##branch\ root:*}/*: ##/}
1508         bzrinfo=( ${${${(M)${(f)"$( bzr version-info )"}:#(#s)(revno|branch-nick)*}/*: /}/*\//} )
1509         bzrbase="$(VCS_INFO_realpath ${bzrbase})"
1510     fi
1511
1512     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat bzrbr || bzrbr="%b:%r"
1513     zformat -f bzrbr "${bzrbr}" "b:${bzrinfo[2]}" "r:${bzrinfo[1]}"
1514     VCS_INFO_formats '' "${bzrbr}" "${bzrbase}"
1515     return 0
1516 }
1517 # }}}
1518 VCS_INFO_cdv_get_data () { # {{{
1519     local cdvbase
1520
1521     cdvbase=${vcs_comm[basedir]}
1522     VCS_INFO_formats '' "${cdvbase:t}" "${cdvbase}"
1523     return 0
1524 }
1525 # }}}
1526 VCS_INFO_cvs_get_data () { # {{{
1527     local cvsbranch cvsbase basename
1528
1529     cvsbase="."
1530     while [[ -d "${cvsbase}/../CVS" ]]; do
1531         cvsbase="${cvsbase}/.."
1532     done
1533     cvsbase="$(VCS_INFO_realpath ${cvsbase})"
1534     cvsbranch=$(< ./CVS/Repository)
1535     basename=${cvsbase:t}
1536     cvsbranch=${cvsbranch##${basename}/}
1537     [[ -z ${cvsbranch} ]] && cvsbranch=${basename}
1538     VCS_INFO_formats '' "${cvsbranch}" "${cvsbase}"
1539     return 0
1540 }
1541 # }}}
1542 VCS_INFO_darcs_get_data () { # {{{
1543     local darcsbase
1544
1545     darcsbase=${vcs_comm[basedir]}
1546     VCS_INFO_formats '' "${darcsbase:t}" "${darcsbase}"
1547     return 0
1548 }
1549 # }}}
1550 VCS_INFO_git_getaction () { #{{{
1551     local gitaction='' gitdir=$1
1552     local tmp
1553
1554     for tmp in "${gitdir}/rebase-apply" \
1555                "${gitdir}/rebase"       \
1556                "${gitdir}/../.dotest" ; do
1557         if [[ -d ${tmp} ]] ; then
1558             if   [[ -f "${tmp}/rebasing" ]] ; then
1559                 gitaction="rebase"
1560             elif [[ -f "${tmp}/applying" ]] ; then
1561                 gitaction="am"
1562             else
1563                 gitaction="am/rebase"
1564             fi
1565             printf '%s' ${gitaction}
1566             return 0
1567         fi
1568     done
1569
1570     for tmp in "${gitdir}/rebase-merge/interactive" \
1571                "${gitdir}/.dotest-merge/interactive" ; do
1572         if [[ -f "${tmp}" ]] ; then
1573             printf '%s' "rebase-i"
1574             return 0
1575         fi
1576     done
1577
1578     for tmp in "${gitdir}/rebase-merge" \
1579                "${gitdir}/.dotest-merge" ; do
1580         if [[ -d "${tmp}" ]] ; then
1581             printf '%s' "rebase-m"
1582             return 0
1583         fi
1584     done
1585
1586     if [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1587         printf '%s' "merge"
1588         return 0
1589     fi
1590
1591     if [[ -f "${gitdir}/BISECT_LOG" ]] ; then
1592         printf '%s' "bisect"
1593         return 0
1594     fi
1595     return 1
1596 }
1597 # }}}
1598 VCS_INFO_git_getbranch () { #{{{
1599     local gitbranch gitdir=$1
1600     local gitsymref='git symbolic-ref HEAD'
1601
1602     if    [[ -d "${gitdir}/rebase-apply" ]] \
1603        || [[ -d "${gitdir}/rebase" ]]       \
1604        || [[ -d "${gitdir}/../.dotest" ]]   \
1605        || [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1606         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1607         [[ -z ${gitbranch} ]] && [[ -r ${gitdir}/rebase-apply/head-name ]] \
1608             && gitbranch="$(< ${gitdir}/rebase-apply/head-name)"
1609
1610     elif   [[ -f "${gitdir}/rebase-merge/interactive" ]] \
1611         || [[ -d "${gitdir}/rebase-merge" ]] ; then
1612         gitbranch="$(< ${gitdir}/rebase-merge/head-name)"
1613
1614     elif   [[ -f "${gitdir}/.dotest-merge/interactive" ]] \
1615         || [[ -d "${gitdir}/.dotest-merge" ]] ; then
1616         gitbranch="$(< ${gitdir}/.dotest-merge/head-name)"
1617
1618     else
1619         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1620
1621         if [[ $? -ne 0 ]] ; then
1622             gitbranch="$(git describe --exact-match HEAD 2>/dev/null)"
1623
1624             if [[ $? -ne 0 ]] ; then
1625                 gitbranch="${${"$(< $gitdir/HEAD)"}[1,7]}..."
1626             fi
1627         fi
1628     fi
1629
1630     printf '%s' "${gitbranch##refs/heads/}"
1631     return 0
1632 }
1633 # }}}
1634 VCS_INFO_git_get_data () { # {{{
1635     setopt localoptions extendedglob
1636     local gitdir gitbase gitbranch gitaction
1637
1638     gitdir=${vcs_comm[gitdir]}
1639     gitbranch="$(VCS_INFO_git_getbranch ${gitdir})"
1640
1641     if [[ -z ${gitdir} ]] || [[ -z ${gitbranch} ]] ; then
1642         return 1
1643     fi
1644
1645     VCS_INFO_adjust
1646     gitaction="$(VCS_INFO_git_getaction ${gitdir})"
1647     gitbase=${PWD%/${$( git rev-parse --show-prefix )%/##}}
1648     VCS_INFO_formats "${gitaction}" "${gitbranch}" "${gitbase}"
1649     return 0
1650 }
1651 # }}}
1652 VCS_INFO_hg_get_data () { # {{{
1653     local hgbranch hgbase
1654
1655     hgbase=${vcs_comm[basedir]}
1656     hgbranch=$(< ${hgbase}/.hg/branch)
1657     VCS_INFO_formats '' "${hgbranch}" "${hgbase}"
1658     return 0
1659 }
1660 # }}}
1661 VCS_INFO_mtn_get_data () { # {{{
1662     local mtnbranch mtnbase
1663
1664     mtnbase=${vcs_comm[basedir]}
1665     mtnbranch=${${(M)${(f)"$( mtn status )"}:#(#s)Current branch:*}/*: /}
1666     VCS_INFO_formats '' "${mtnbranch}" "${mtnbase}"
1667     return 0
1668 }
1669 # }}}
1670 VCS_INFO_svk_get_data () { # {{{
1671     local svkbranch svkbase
1672
1673     svkbase=${vcs_comm[basedir]}
1674     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svkbranch || svkbranch="%b:%r"
1675     zformat -f svkbranch "${svkbranch}" "b:${vcs_comm[branch]}" "r:${vcs_comm[revision]}"
1676     VCS_INFO_formats '' "${svkbranch}" "${svkbase}"
1677     return 0
1678 }
1679 # }}}
1680 VCS_INFO_svn_get_data () { # {{{
1681     setopt localoptions noksharrays
1682     local svnbase svnbranch
1683     local -a svninfo
1684
1685     svnbase="."
1686     while [[ -d "${svnbase}/../.svn" ]]; do
1687         svnbase="${svnbase}/.."
1688     done
1689     svnbase="$(VCS_INFO_realpath ${svnbase})"
1690     svninfo=( ${${${(M)${(f)"$( svn info )"}:#(#s)(URL|Revision)*}/*: /}/*\//} )
1691
1692     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svnbranch || svnbranch="%b:%r"
1693     zformat -f svnbranch "${svnbranch}" "b:${svninfo[1]}" "r:${svninfo[2]}"
1694     VCS_INFO_formats '' "${svnbranch}" "${svnbase}"
1695     return 0
1696 }
1697 # }}}
1698 VCS_INFO_tla_get_data () { # {{{
1699     local tlabase tlabranch
1700
1701     tlabase="$(VCS_INFO_realpath ${vcs_comm[basedir]})"
1702     # tree-id gives us something like 'foo@example.com/demo--1.0--patch-4', so:
1703     tlabranch=${${"$( tla tree-id )"}/*\//}
1704     VCS_INFO_formats '' "${tlabranch}" "${tlabase}"
1705     return 0
1706 }
1707 # }}}
1708 # detection
1709 VCS_INFO_detect_by_dir() { #{{{
1710     local dirname=$1
1711     local basedir="." realbasedir
1712
1713     realbasedir="$(VCS_INFO_realpath ${basedir})"
1714     while [[ ${realbasedir} != '/' ]]; do
1715         if [[ -n ${vcs_comm[detect_need_file]} ]] ; then
1716             [[ -d ${basedir}/${dirname} ]] && \
1717             [[ -f ${basedir}/${dirname}/${vcs_comm[detect_need_file]} ]] && \
1718                 break
1719         else
1720             [[ -d ${basedir}/${dirname} ]] && break
1721         fi
1722
1723         basedir=${basedir}/..
1724         realbasedir="$(VCS_INFO_realpath ${basedir})"
1725     done
1726
1727     [[ ${realbasedir} == "/" ]] && return 1
1728     vcs_comm[basedir]=${realbasedir}
1729     return 0
1730 }
1731 # }}}
1732 VCS_INFO_bzr_detect() { #{{{
1733     VCS_INFO_check_com bzr || return 1
1734     vcs_comm[detect_need_file]=branch/format
1735     VCS_INFO_detect_by_dir '.bzr'
1736     return $?
1737 }
1738 # }}}
1739 VCS_INFO_cdv_detect() { #{{{
1740     VCS_INFO_check_com cdv || return 1
1741     vcs_comm[detect_need_file]=format
1742     VCS_INFO_detect_by_dir '.cdv'
1743     return $?
1744 }
1745 # }}}
1746 VCS_INFO_cvs_detect() { #{{{
1747     VCS_INFO_check_com svn || return 1
1748     [[ -d "./CVS" ]] && [[ -r "./CVS/Repository" ]] && return 0
1749     return 1
1750 }
1751 # }}}
1752 VCS_INFO_darcs_detect() { #{{{
1753     VCS_INFO_check_com darcs || return 1
1754     vcs_comm[detect_need_file]=format
1755     VCS_INFO_detect_by_dir '_darcs'
1756     return $?
1757 }
1758 # }}}
1759 VCS_INFO_git_detect() { #{{{
1760     if VCS_INFO_check_com git && git rev-parse --is-inside-work-tree &> /dev/null ; then
1761         vcs_comm[gitdir]="$(git rev-parse --git-dir 2> /dev/null)" || return 1
1762         if   [[ -d ${vcs_comm[gitdir]}/svn ]]             ; then vcs_comm[overwrite_name]='git-svn'
1763         elif [[ -d ${vcs_comm[gitdir]}/refs/remotes/p4 ]] ; then vcs_comm[overwrite_name]='git-p4' ; fi
1764         return 0
1765     fi
1766     return 1
1767 }
1768 # }}}
1769 VCS_INFO_hg_detect() { #{{{
1770     VCS_INFO_check_com hg || return 1
1771     vcs_comm[detect_need_file]=branch
1772     VCS_INFO_detect_by_dir '.hg'
1773     return $?
1774 }
1775 # }}}
1776 VCS_INFO_mtn_detect() { #{{{
1777     VCS_INFO_check_com mtn || return 1
1778     vcs_comm[detect_need_file]=revision
1779     VCS_INFO_detect_by_dir '_MTN'
1780     return $?
1781 }
1782 # }}}
1783 VCS_INFO_svk_detect() { #{{{
1784     setopt localoptions noksharrays extendedglob
1785     local -a info
1786     local -i fhash
1787     fhash=0
1788
1789     VCS_INFO_check_com svk || return 1
1790     [[ -f ~/.svk/config ]] || return 1
1791
1792     # This detection function is a bit different from the others.
1793     # We need to read svk's config file to detect a svk repository
1794     # in the first place. Therefore, we'll just proceed and read
1795     # the other information, too. This is more then any of the
1796     # other detections do but this takes only one file open for
1797     # svk at most. VCS_INFO_svk_get_data() get simpler, too. :-)
1798     while IFS= read -r line ; do
1799         if [[ -n ${vcs_comm[basedir]} ]] ; then
1800             line=${line## ##}
1801             [[ ${line} == depotpath:* ]] && vcs_comm[branch]=${line##*/}
1802             [[ ${line} == revision:* ]] && vcs_comm[revision]=${line##*[[:space:]]##}
1803             [[ -n ${vcs_comm[branch]} ]] && [[ -n ${vcs_comm[revision]} ]] && break
1804             continue
1805         fi
1806         (( fhash > 0 )) && [[ ${line} == '  '[^[:space:]]*:* ]] && break
1807         [[ ${line} == '  hash:'* ]] && fhash=1 && continue
1808         (( fhash == 0 )) && continue
1809         [[ ${PWD}/ == ${${line## ##}%:*}/* ]] && vcs_comm[basedir]=${${line## ##}%:*}
1810     done < ~/.svk/config
1811
1812     [[ -n ${vcs_comm[basedir]} ]]  && \
1813     [[ -n ${vcs_comm[branch]} ]]   && \
1814     [[ -n ${vcs_comm[revision]} ]] && return 0
1815     return 1
1816 }
1817 # }}}
1818 VCS_INFO_svn_detect() { #{{{
1819     VCS_INFO_check_com svn || return 1
1820     [[ -d ".svn" ]] && return 0
1821     return 1
1822 }
1823 # }}}
1824 VCS_INFO_tla_detect() { #{{{
1825     VCS_INFO_check_com tla || return 1
1826     vcs_comm[basedir]="$(tla tree-root 2> /dev/null)" && return 0
1827     return 1
1828 }
1829 # }}}
1830 # public API
1831 vcs_info_printsys () { # {{{
1832     vcs_info print_systems_
1833 }
1834 # }}}
1835 vcs_info_lastmsg () { # {{{
1836     local -i i
1837
1838     VCS_INFO_maxexports
1839     for i in {0..$((maxexports - 1))} ; do
1840         printf '$VCS_INFO_message_%d_: "' $i
1841         if zstyle -T ':vcs_info:formats:command' use-prompt-escapes ; then
1842             print -nP ${(P)${:-VCS_INFO_message_${i}_}}
1843         else
1844             print -n ${(P)${:-VCS_INFO_message_${i}_}}
1845         fi
1846         printf '"\n'
1847     done
1848 }
1849 # }}}
1850 vcs_info () { # {{{
1851     local pat
1852     local -i found
1853     local -a VCSs disabled dps
1854     local -x vcs usercontext
1855     local -ax msgs
1856     local -Ax vcs_comm
1857
1858     vcs="init"
1859     VCSs=(git hg bzr darcs svk mtn svn cvs cdv tla)
1860     case $1 in
1861         (print_systems_)
1862             zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1863             print -l '# list of supported version control backends:' \
1864                      '# disabled systems are prefixed by a hash sign (#)'
1865             for vcs in ${VCSs} ; do
1866                 [[ -n ${(M)disabled:#${vcs}} ]] && printf '#'
1867                 printf '%s\n' ${vcs}
1868             done
1869             print -l '# flavours (cannot be used in the disable style; they' \
1870                      '# are disabled with their master [git-svn -> git]):'   \
1871                      git-{p4,svn}
1872             return 0
1873             ;;
1874         ('')
1875             [[ -z ${usercontext} ]] && usercontext=default
1876             ;;
1877         (*) [[ -z ${usercontext} ]] && usercontext=$1
1878             ;;
1879     esac
1880
1881     zstyle -T ":vcs_info:${vcs}:${usercontext}" "enable" || {
1882         [[ -n ${VCS_INFO_message_0_} ]] && VCS_INFO_set --clear
1883         return 0
1884     }
1885     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1886
1887     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable-patterns" dps
1888     for pat in ${dps} ; do
1889         if [[ ${PWD} == ${~pat} ]] ; then
1890             [[ -n ${vcs_info_msg_0_} ]] && VCS_INFO_set --clear
1891             return 0
1892         fi
1893     done
1894
1895     VCS_INFO_maxexports
1896
1897     (( found = 0 ))
1898     for vcs in ${VCSs} ; do
1899         [[ -n ${(M)disabled:#${vcs}} ]] && continue
1900         vcs_comm=()
1901         VCS_INFO_${vcs}_detect && (( found = 1 )) && break
1902     done
1903
1904     (( found == 0 )) && {
1905         VCS_INFO_set --nvcs
1906         return 0
1907     }
1908
1909     VCS_INFO_${vcs}_get_data || {
1910         VCS_INFO_set --nvcs
1911         return 1
1912     }
1913
1914     VCS_INFO_set
1915     return 0
1916 }
1917
1918 VCS_INFO_set --nvcs preinit
1919 # }}}
1920
1921 # change vcs_info formats for the grml prompt
1922 if [[ "$TERM" == dumb ]] ; then
1923     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] "
1924     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "
1925 else
1926     # these are the same, just with a lot of colours:
1927     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} "
1928     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} "
1929     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1930 fi
1931
1932 # }}}
1933
1934 # {{{ set prompt
1935 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1936     promptinit # people should be able to use their favourite prompt
1937 else
1938     print 'Notice: no promptinit available :('
1939 fi
1940
1941 setopt prompt_subst
1942
1943 # make sure to use right prompt only when not running a command
1944 is41 && setopt transient_rprompt
1945
1946 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1947     [[ $NOPRECMD -gt 0 ]] && return 0
1948     # update VCS information
1949     vcs_info
1950
1951     # allow manual overwriting of RPROMPT
1952     if [[ -n $RPROMPT ]] ; then
1953         [[ $TERM == screen* ]] && print -nP "\ekzsh\e\\"
1954         # return 0
1955     fi
1956     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1957     if [[ $DONTSETRPROMPT -eq 0 ]] ; then
1958         if [[ $BATTERY -gt 0 ]] ; then
1959             # update BATTERY information
1960             battery
1961             RPROMPT="%(?..:()% ${PERCENT}${SCREENTITLE}"
1962             # RPROMPT="${PERCENT}${SCREENTITLE}"
1963         else
1964             RPROMPT="%(?..:()% ${SCREENTITLE}"
1965             # RPROMPT="${SCREENTITLE}"
1966         fi
1967     fi
1968     # adjust title of xterm
1969     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1970     case $TERM in
1971         (xterm*|rxvt)
1972             print -Pn "\e]0;%n@%m: %~\a"
1973             ;;
1974     esac
1975 }
1976
1977 # preexec() => a function running before every command
1978 is4 && [[ $NOPRECMD -eq 0 ]] && \
1979 preexec () {
1980     [[ $NOPRECMD -gt 0 ]] && return 0
1981 # set hostname if not running on host with name 'grml'
1982     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1983        NAME="@$HOSTNAME"
1984     fi
1985 # get the name of the program currently running and hostname of local machine
1986 # set screen window title if running in a screen
1987     if [[ "$TERM" == screen* ]] ; then
1988         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1989         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1990         echo -ne "\ek$CMD\e\\"
1991     fi
1992 # set the screen title to "zsh" when sitting at the command prompt:
1993     if [[ "$TERM" == screen* ]] ; then
1994         SCREENTITLE=$'%{\ekzsh\e\\%}'
1995     else
1996         SCREENTITLE=''
1997     fi
1998 # adjust title of xterm
1999     case $TERM in
2000         (xterm*|rxvt)
2001             print -Pn "\e]0;%n@%m: $1\a"
2002             ;;
2003     esac
2004 }
2005
2006 EXITCODE="%(?..%?%1v )"
2007 PS2='\`%_> '      # secondary prompt, printed when the shell needs more information to complete a command.
2008 PS3='?# '         # selection prompt used within a select loop.
2009 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
2010
2011 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
2012 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
2013     debian_chroot=$(cat /etc/debian_chroot)
2014 fi
2015
2016 # don't use colors on dumb terminals (like emacs):
2017 if [[ "$TERM" == dumb ]] ; then
2018     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2019 else
2020     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
2021     # set variable identifying the chroot you work in (used in the prompt below)
2022     if [[ $GRMLPROMPT -gt 0 ]] ; then
2023         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
2024 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# "
2025     else
2026         # This assembles the primary prompt string
2027         if (( EUID != 0 )); then
2028             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2029         else
2030             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2031         fi
2032     fi
2033 fi
2034
2035 # if we are inside a grml-chroot set a specific prompt theme
2036 if [[ -n "$GRML_CHROOT" ]] ; then
2037     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
2038 fi
2039 # }}}
2040
2041 # {{{ 'hash' some often used directories
2042 #d# start
2043 hash -d deb=/var/cache/apt/archives
2044 hash -d doc=/usr/share/doc
2045 hash -d linux=/lib/modules/$(command uname -r)/build/
2046 hash -d log=/var/log
2047 hash -d slog=/var/log/syslog
2048 hash -d src=/usr/src
2049 hash -d templ=/usr/share/doc/grml-templates
2050 hash -d tt=/usr/share/doc/texttools-doc
2051 hash -d www=/var/www
2052 #d# end
2053 # }}}
2054
2055 # {{{ some aliases
2056 if check_com -c screen ; then
2057     if [[ $UID -eq 0 ]] ; then
2058         [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
2059     elif [[ -r $HOME/.screenrc ]] ; then
2060         alias screen="${commands[screen]} -c $HOME/.screenrc"
2061     else
2062         [[ -r /etc/grml/screenrc_grml ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
2063     fi
2064 fi
2065
2066 # do we have GNU ls with color-support?
2067 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
2068     #a1# execute \kbd{@a@}:\quad ls with colors
2069     alias ls='ls -b -CF --color=auto'
2070     #a1# execute \kbd{@a@}:\quad list all files, with colors
2071     alias la='ls -la --color=auto'
2072     #a1# long colored list, without dotfiles (@a@)
2073     alias ll='ls -l --color=auto'
2074     #a1# long colored list, human readable sizes (@a@)
2075     alias lh='ls -hAl --color=auto'
2076     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2077     alias l='ls -lF --color=auto'
2078 else
2079     alias ls='ls -b -CF'
2080     alias la='ls -la'
2081     alias ll='ls -l'
2082     alias lh='ls -hAl'
2083     alias l='ls -lF'
2084 fi
2085
2086 alias mdstat='cat /proc/mdstat'
2087 alias ...='cd ../../'
2088
2089 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2090 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2091     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2092 fi
2093
2094 alias cp='nocorrect cp'         # no spelling correction on cp
2095 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
2096 alias mv='nocorrect mv'         # no spelling correction on mv
2097 alias rm='nocorrect rm'         # no spelling correction on rm
2098
2099 #a1# Execute \kbd{rmdir}
2100 alias rd='rmdir'
2101 #a1# Execute \kbd{rmdir}
2102 alias md='mkdir'
2103
2104 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2105 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2106 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2107
2108 # make sure it is not assigned yet
2109 [[ $(whence -w utf2iso &>/dev/null) == 'utf2iso: alias' ]] && unalias utf2iso
2110
2111 utf2iso() {
2112     if isutfenv ; then
2113         for ENV in $(env | command grep -i '.utf') ; do
2114             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2115         done
2116     fi
2117 }
2118
2119 # make sure it is not assigned yet
2120 [[ $(whence -w iso2utf &>/dev/null) == 'iso2utf: alias' ]] && unalias iso2utf
2121 iso2utf() {
2122     if ! isutfenv ; then
2123         for ENV in $(env | command grep -i '\.iso') ; do
2124             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2125         done
2126     fi
2127 }
2128
2129 # set up software synthesizer via speakup
2130 swspeak() {
2131     if [ -x /usr/sbin/swspeak-setup ] ; then
2132        setopt singlelinezle
2133        unsetopt prompt_cr
2134        export PS1="%m%# "
2135        /usr/sbin/swspeak-setup $@
2136      else # old version:
2137         aumix -w 90 -v 90 -p 90 -m 90
2138         if ! [[ -r /dev/softsynth ]] ; then
2139             flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
2140             return 1
2141         else
2142            setopt singlelinezle
2143            unsetopt prompt_cr
2144            export PS1="%m%# "
2145             nice -n -20 speechd-up
2146             sleep 2
2147             flite -o play -t "Finished setting up software synthesizer"
2148         fi
2149      fi
2150 }
2151
2152 # I like clean prompt, so provide simple way to get that
2153 check_com 0 || alias 0='return 0'
2154
2155 # for really lazy people like mika:
2156 check_com S &>/dev/null || alias S='screen'
2157 check_com s &>/dev/null || alias s='ssh'
2158
2159 # get top 10 shell commands:
2160 alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
2161
2162 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
2163 if check_com -c truecrypt ; then
2164     if isutfenv ; then
2165         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
2166     else
2167         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
2168     fi
2169 fi
2170
2171 #f1# Hints for the use of zsh on grml
2172 zsh-help() {
2173     print "$bg[white]$fg[black]
2174 zsh-help - hints for use of zsh on grml
2175 =======================================$reset_color"
2176
2177     print '
2178 Main configuration of zsh happens in /etc/zsh/zshrc.
2179 That file is part of the package grml-etc-core, if you want to
2180 use them on a non-grml-system just get the tar.gz from
2181 http://deb.grml.org/ or (preferably) get it from the git repository:
2182
2183   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2184
2185 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2186 The file is still there, but it is empty for backwards compatibility.
2187
2188 For your own changes use these two files:
2189     $HOME/.zshrc.pre
2190     $HOME/.zshrc.local
2191
2192 The former is sourced very early in our zshrc, the latter is sourced
2193 very lately.
2194
2195 System wide configuration without touching configuration files of grml
2196 can take place in /etc/zsh/zshrc.local.
2197
2198 Normally, the root user (EUID == 0) does not get the whole grml setup.
2199 If you want to force the whole setup for that user, too, set
2200 GRML_ALWAYS_LOAD_ALL=1 in .zshrc.pre in root'\''s home directory.
2201
2202 For information regarding zsh start at http://grml.org/zsh/
2203
2204 Take a look at grml'\''s zsh refcard:
2205 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2206
2207 Check out the main zsh refcard:
2208 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2209
2210 And of course visit the zsh-lovers:
2211 % man zsh-lovers
2212
2213 You can adjust some options through environment variables when
2214 invoking zsh without having to edit configuration files.
2215 Basically meant for bash users who are not used to the power of
2216 the zsh yet. :)
2217
2218   "NOCOR=1    zsh" => deactivate automatic correction
2219   "NOMENU=1   zsh" => do not use auto menu completion (note: use ctrl-d for completion instead!)
2220   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2221   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
2222
2223 A value greater than 0 is enables a feature; a value equal to zero
2224 disables it. If you like one or the other of these settings, you can
2225 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2226 zshrc.'
2227
2228     print "
2229 $bg[white]$fg[black]
2230 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2231 Enjoy your grml system with the zsh!$reset_color"
2232 }
2233
2234 # debian stuff
2235 if [[ -r /etc/debian_version ]] ; then
2236     #a3# Execute \kbd{apt-cache search}
2237     alias acs='apt-cache search'
2238     #a3# Execute \kbd{apt-cache show}
2239     alias acsh='apt-cache show'
2240     #a3# Execute \kbd{apt-cache policy}
2241     alias acp='apt-cache policy'
2242     #a3# Execute \kbd{apt-get dist-upgrade}
2243     salias adg="apt-get dist-upgrade"
2244     #a3# Execute \kbd{apt-get install}
2245     salias agi="apt-get install"
2246     #a3# Execute \kbd{aptitude install}
2247     salias ati="aptitude install"
2248     #a3# Execute \kbd{apt-get upgrade}
2249     salias ag="apt-get upgrade"
2250     #a3# Execute \kbd{apt-get update}
2251     salias au="apt-get update"
2252     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2253     salias -a up="aptitude update ; aptitude safe-upgrade"
2254     #a3# Execute \kbd{dpkg-buildpackage}
2255     alias dbp='dpkg-buildpackage'
2256     #a3# Execute \kbd{grep-excuses}
2257     alias ge='grep-excuses'
2258
2259     # debian upgrade
2260     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
2261     upgrade() {
2262         if [[ -z "$1" ]] ; then
2263             $SUDO apt-get update
2264             $SUDO apt-get -u upgrade
2265         else
2266             ssh $1 $SUDO apt-get update
2267             # ask before the upgrade
2268             local dummy
2269             ssh $1 $SUDO apt-get --no-act upgrade
2270             echo -n 'Process the upgrade?'
2271             read -q dummy
2272             if [[ $dummy == "y" ]] ; then
2273                 ssh $1 $SUDO apt-get -u upgrade --yes
2274             fi
2275         fi
2276     }
2277
2278     # get a root shell as normal user in live-cd mode:
2279     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2280        alias su="sudo su"
2281      fi
2282
2283     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2284     alias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2285     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2286     alias tlog="tail -f /var/log/syslog"    # follow the syslog
2287 fi
2288
2289 # sort installed Debian-packages by size
2290 if check_com -c grep-status ; then
2291     #a3# List installed Debian-packages sorted by size
2292     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
2293 fi
2294
2295 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2296 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord ; then
2297     if check_com -c wodim ; then
2298         alias cdrecord="echo 'cdrecord is not provided under its original name by Debian anymore.
2299 See #377109 in the BTS of Debian for more details.
2300
2301 Please use the wodim binary instead' ; return 1"
2302     fi
2303 fi
2304
2305 # get_tw_cli has been renamed into get_3ware
2306 if check_com -c get_3ware ; then
2307     get_tw_cli() {
2308         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
2309         get_3ware
2310     }
2311 fi
2312
2313 # I hate lacking backward compatibility, so provide an alternative therefore
2314 if ! check_com -c apache2-ssl-certificate ; then
2315
2316     apache2-ssl-certificate() {
2317
2318     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
2319     print 'You might want to take a look at Debian the package ssl-cert as well.'
2320     print 'To generate a certificate for use with apache2 follow the instructions:'
2321
2322     echo '
2323
2324 export RANDFILE=/dev/random
2325 mkdir /etc/apache2/ssl/
2326 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
2327 chmod 600 /etc/apache2/ssl/apache.pem
2328
2329 Run "grml-tips ssl-certificate" if you need further instructions.
2330 '
2331     }
2332 fi
2333 # }}}
2334
2335 # {{{ Use hard limits, except for a smaller stack and no core dumps
2336 unlimit
2337 is425 && limit stack 8192
2338 isgrmlcd && limit core 0 # important for a live-cd-system
2339 limit -s
2340 # }}}
2341
2342 # {{{ completion system
2343
2344 # called later (via is4 && grmlcomp)
2345 # note: use 'zstyle' for getting current settings
2346 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
2347 grmlcomp() {
2348     # TODO: This could use some additional information
2349
2350     # allow one error for every three characters typed in approximate completer
2351     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
2352
2353     # don't complete backup files as executables
2354     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
2355
2356     # start menu completion only if it could find no unambiguous initial string
2357     zstyle ':completion:*:correct:*'       insert-unambiguous true
2358     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
2359     zstyle ':completion:*:correct:*'       original true
2360
2361     # activate color-completion
2362     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
2363
2364     # format on completion
2365     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
2366
2367     # complete 'cd -<tab>' with menu
2368     zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
2369
2370     # insert all expansions for expand completer
2371     zstyle ':completion:*:expand:*'        tag-order all-expansions
2372     zstyle ':completion:*:history-words'   list false
2373
2374     # activate menu
2375     zstyle ':completion:*:history-words'   menu yes
2376
2377     # ignore duplicate entries
2378     zstyle ':completion:*:history-words'   remove-all-dups yes
2379     zstyle ':completion:*:history-words'   stop yes
2380
2381     # match uppercase from lowercase
2382     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
2383
2384     # separate matches into groups
2385     zstyle ':completion:*:matches'         group 'yes'
2386     zstyle ':completion:*'                 group-name ''
2387
2388     if [[ "$NOMENU" -eq 0 ]] ; then
2389         # if there are more than 5 options allow selecting from a menu
2390         zstyle ':completion:*'               menu select=5
2391     else
2392         # don't use any menus at all
2393         setopt no_auto_menu
2394     fi
2395
2396     zstyle ':completion:*:messages'        format '%d'
2397     zstyle ':completion:*:options'         auto-description '%d'
2398
2399     # describe options in full
2400     zstyle ':completion:*:options'         description 'yes'
2401
2402     # on processes completion complete all user processes
2403     zstyle ':completion:*:processes'       command 'ps -au$USER'
2404
2405     # offer indexes before parameters in subscripts
2406     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
2407
2408     # provide verbose completion information
2409     zstyle ':completion:*'                 verbose true
2410
2411     # recent (as of Dec 2007) zsh versions are able to provide descriptions
2412     # for commands (read: 1st word in the line) that it will list for the user
2413     # to choose from. The following disables that, because it's not exactly fast.
2414     zstyle ':completion:*:-command-:*:'    verbose false
2415
2416     # set format for warnings
2417     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
2418
2419     # define files to ignore for zcompile
2420     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
2421     zstyle ':completion:correct:'          prompt 'correct to: %e'
2422
2423     # Ignore completion functions for commands you don't have:
2424     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
2425
2426     # Provide more processes in completion of programs like killall:
2427     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
2428
2429     # complete manual by their section
2430     zstyle ':completion:*:manuals'    separate-sections true
2431     zstyle ':completion:*:manuals.*'  insert-sections   true
2432     zstyle ':completion:*:man:*'      menu yes select
2433
2434     # provide .. as a completion
2435     zstyle ':completion:*' special-dirs ..
2436
2437     # run rehash on completion so new installed program are found automatically:
2438     _force_rehash() {
2439         (( CURRENT == 1 )) && rehash
2440         return 1
2441     }
2442
2443     ## correction
2444     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
2445     if [[ "$NOCOR" -gt 0 ]] ; then
2446         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
2447         setopt nocorrect
2448     else
2449         # try to be smart about when to use what completer...
2450         setopt correct
2451         zstyle -e ':completion:*' completer '
2452             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
2453                 _last_try="$HISTNO$BUFFER$CURSOR"
2454                 reply=(_complete _match _ignored _prefix _files)
2455             else
2456                 if [[ $words[1] == (rm|mv) ]] ; then
2457                     reply=(_complete _files)
2458                 else
2459                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
2460                 fi
2461             fi'
2462     fi
2463
2464     # command for process lists, the local web server details and host completion
2465     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
2466
2467     # caching
2468     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
2469                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
2470
2471     # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
2472     if is42 ; then
2473         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
2474         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
2475     else
2476         _ssh_hosts=()
2477         _etc_hosts=()
2478     fi
2479     hosts=(
2480         $(hostname)
2481         "$_ssh_hosts[@]"
2482         "$_etc_hosts[@]"
2483         grml.org
2484         localhost
2485     )
2486     zstyle ':completion:*:hosts' hosts $hosts
2487     # TODO: so, why is this here?
2488     #  zstyle '*' hosts $hosts
2489
2490     # use generic completion system for programs not yet defined; (_gnu_generic works
2491     # with commands that provide a --help option with "standard" gnu-like output.)
2492     compdef _gnu_generic tail head feh cp mv df stow uname ipacsum fetchipac
2493
2494     # see upgrade function in this file
2495     compdef _hosts upgrade
2496 }
2497 # }}}
2498
2499 # {{{ grmlstuff
2500 grmlstuff() {
2501 # people should use 'grml-x'!
2502     startx() {
2503         if [[ -e /etc/X11/xorg.conf ]] ; then
2504             [[ -x /usr/bin/startx ]] && /usr/bin/startx "$@" || /usr/X11R6/bin/startx "$@"
2505         else
2506             echo "Please use the script \"grml-x\" for starting the X Window System
2507 because there does not exist /etc/X11/xorg.conf yet.
2508 If you want to use startx anyway please call \"/usr/bin/startx\"."
2509             return -1
2510         fi
2511     }
2512
2513     xinit() {
2514         if [[ -e /etc/X11/xorg.conf ]] ; then
2515             [[ -x /usr/bin/xinit ]] && /usr/bin/xinit || /usr/X11R6/bin/xinit
2516         else
2517             echo "Please use the script \"grml-x\" for starting the X Window System.
2518 because there does not exist /etc/X11/xorg.conf yet.
2519 If you want to use xinit anyway please call \"/usr/bin/xinit\"."
2520             return -1
2521         fi
2522     }
2523
2524     if check_com -c 915resolution ; then
2525         alias 855resolution='echo -e "Please use 915resolution as resolution modify tool for Intel graphic chipset."; return -1'
2526     fi
2527
2528     #a1# Output version of running grml
2529     alias grml-version='cat /etc/grml_version'
2530
2531     if check_com -c rebuildfstab ; then
2532         #a1# Rebuild /etc/fstab
2533         alias grml-rebuildfstab='rebuildfstab -v -r -config'
2534     fi
2535
2536     if check_com -c grml-debootstrap ; then
2537         alias debian2hd='print "Installing debian to harddisk is possible via using grml-debootstrap." ; return 1'
2538     fi
2539 }
2540 # }}}
2541
2542 # {{{ now run the functions
2543 isgrml && checkhome
2544 is4    && isgrml    && grmlstuff
2545 is4    && grmlcomp
2546 # }}}
2547
2548 # {{{ keephack
2549 is4 && xsource "/etc/zsh/keephack"
2550 # }}}
2551
2552 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
2553 # You use it as follows:
2554 # $ NTREF=/reference/file
2555 # $ ls -l *(e:nt:)
2556 # This lists all the files in the current directory newer than the reference file.
2557 # You can also specify the reference file inline; note quotes:
2558 # $ ls -l *(e:'nt ~/.zshenv':)
2559 is4 && nt() {
2560     if [[ -n $1 ]] ; then
2561         local NTREF=${~1}
2562     fi
2563     [[ $REPLY -nt $NTREF ]]
2564 }
2565 # }}}
2566
2567 # shell functions {{{
2568
2569 #f1# Provide csh compatibility
2570 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
2571
2572 #f1# Reload an autoloadable function
2573 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2574
2575 #f1# Reload zsh setup
2576 reload() {
2577     if [[ "$#*" -eq 0 ]] ; then
2578         [[ -r ~/.zshrc ]] && . ~/.zshrc
2579     else
2580         local fn
2581         for fn in "$@"; do
2582             unfunction $fn
2583             autoload -U $fn
2584         done
2585     fi
2586 }
2587 compdef _functions reload freload
2588
2589 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2590 sll() {
2591     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2592     for i in "$@" ; do
2593         file=$i
2594         while [[ -h "$file" ]] ; do
2595             ls -l $file
2596             file=$(readlink "$file")
2597         done
2598     done
2599 }
2600
2601 # fast manual access
2602 if check_com qma ; then
2603     #f1# View the zsh manual
2604     manzsh()  { qma zshall "$1" }
2605     compdef _man qma
2606 else
2607     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
2608 fi
2609
2610 if check_com -c $PAGER ; then
2611     #f1# View Debian's changelog of a given package
2612     dchange() {
2613         if [[ -r /usr/share/doc/${1}/changelog.Debian.gz ]] ; then
2614             $PAGER /usr/share/doc/${1}/changelog.Debian.gz
2615         elif [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2616             $PAGER /usr/share/doc/${1}/changelog.gz
2617         else
2618             if check_com -c aptitude ; then
2619                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2620                 if isgrml ; then
2621                     aptitude -t unstable changelog ${1}
2622                 else
2623                     aptitude changelog ${1}
2624                 fi
2625             else
2626                 echo "No changelog for package $1 found, sorry."
2627                 return 1
2628             fi
2629         fi
2630     }
2631     _dchange() { _files -W /usr/share/doc -/ }
2632     compdef _dchange dchange
2633
2634     #f1# View Debian's NEWS of a given package
2635     dnews() {
2636         if [[ -r /usr/share/doc/${1}/NEWS.Debian.gz ]] ; then
2637             $PAGER /usr/share/doc/${1}/NEWS.Debian.gz
2638         else
2639             if [[ -r /usr/share/doc/${1}/NEWS.gz ]] ; then
2640                 $PAGER /usr/share/doc/${1}/NEWS.gz
2641             else
2642                 echo "No NEWS file for package $1 found, sorry."
2643                 return 1
2644             fi
2645         fi
2646     }
2647     _dnews() { _files -W /usr/share/doc -/ }
2648     compdef _dnews dnews
2649
2650     #f1# View upstream's changelog of a given package
2651     uchange() {
2652         if [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2653             $PAGER /usr/share/doc/${1}/changelog.gz
2654         else
2655             echo "No changelog for package $1 found, sorry."
2656             return 1
2657         fi
2658     }
2659     _uchange() { _files -W /usr/share/doc -/ }
2660     compdef _uchange uchange
2661 fi
2662
2663 # zsh profiling
2664 profile() {
2665     ZSH_PROFILE_RC=1 $SHELL "$@"
2666 }
2667
2668 #f1# Edit an alias via zle
2669 edalias() {
2670     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2671 }
2672 compdef _aliases edalias
2673
2674 #f1# Edit a function via zle
2675 edfunc() {
2676     [[ -z "$1" ]] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
2677 }
2678 compdef _functions edfunc
2679
2680 # use it e.g. via 'Restart apache2'
2681 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2682 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2683 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2684 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2685 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2686 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2687     __start_stop() {
2688         local action_="${1:l}"  # e.g Start/Stop/Restart
2689         local service_="$2"
2690         local param_="$3"
2691
2692         local service_target_="$(readlink /etc/init.d/$service_)"
2693         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2694             # runit
2695             case "${action_}" in
2696                 start) if [[ ! -e /etc/service/$service_ ]]; then
2697                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2698                        else
2699                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2700                        fi ;;
2701                 # there is no reload in runits sysv emulation
2702                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2703                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2704             esac
2705         else
2706             # sysvinit
2707             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2708         fi
2709     }
2710
2711     for i in Start Restart Stop Force-Reload Reload ; do
2712         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2713     done
2714 fi
2715
2716 #f1# Provides useful information on globbing
2717 H-Glob() {
2718     echo -e "
2719     /      directories
2720     .      plain files
2721     @      symbolic links
2722     =      sockets
2723     p      named pipes (FIFOs)
2724     *      executable plain files (0100)
2725     %      device files (character or block special)
2726     %b     block special files
2727     %c     character special files
2728     r      owner-readable files (0400)
2729     w      owner-writable files (0200)
2730     x      owner-executable files (0100)
2731     A      group-readable files (0040)
2732     I      group-writable files (0020)
2733     E      group-executable files (0010)
2734     R      world-readable files (0004)
2735     W      world-writable files (0002)
2736     X      world-executable files (0001)
2737     s      setuid files (04000)
2738     S      setgid files (02000)
2739     t      files with the sticky bit (01000)
2740
2741   print *(m-1)          # Files modified up to a day ago
2742   print *(a1)           # Files accessed a day ago
2743   print *(@)            # Just symlinks
2744   print *(Lk+50)        # Files bigger than 50 kilobytes
2745   print *(Lk-50)        # Files smaller than 50 kilobytes
2746   print **/*.c          # All *.c files recursively starting in \$PWD
2747   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2748   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2749   print *~*.*           # All Files that do not contain a dot
2750   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2751   print -l *(.c|.h)     # Lists *.c and *.h
2752   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2753   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2754 }
2755 alias help-zshglob=H-Glob
2756
2757 check_com -c qma && alias ?='qma zshall'
2758
2759 # grep for running process, like: 'any vim'
2760 any() {
2761     if [[ -z "$1" ]] ; then
2762         echo "any - grep for process(es) by keyword" >&2
2763         echo "Usage: any <keyword>" >&2 ; return 1
2764     else
2765         local STRING=$1
2766         local LENGTH=$(expr length $STRING)
2767         local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
2768         local REST=$(echo $(expr substr $STRING 2 $LENGTH))
2769         ps xauwww| grep "[$FIRSCHAR]$REST"
2770     fi
2771 }
2772
2773 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2774 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2775 [[ -r /proc/1/maps ]] && \
2776 deswap() {
2777     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2778     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2779     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2780 }
2781
2782 # print hex value of a number
2783 hex() {
2784     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
2785 }
2786
2787 # calculate (or eval at all ;-)) with perl => p[erl-]eval
2788 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
2789 peval() {
2790     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
2791     perl -e "print eval($CALC),\"\n\";"
2792 }
2793 functions peval &>/dev/null && alias calc=peval
2794
2795 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
2796 # certain circumstances, so work around it, no matter which environment we have
2797 brltty() {
2798     if [[ -z "$DISPLAY" ]] ; then
2799         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
2800         command brltty "$@"
2801     else
2802         command brltty "$@"
2803     fi
2804 }
2805
2806 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
2807 aoeu() {
2808     echo -n 'Switching to us keyboard layout: '
2809     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
2810     echo 'Done'
2811 }
2812 asdf() {
2813     echo -n 'Switching to dvorak keyboard layout: '
2814     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
2815     echo 'Done'
2816 }
2817 # just press 'asdf' key to toggle from neon layout to us keyboard layout
2818 uiae() {
2819     echo -n 'Switching to us keyboard layout: '
2820     setxkbmap us && echo 'Done' || echo 'Failed'
2821 }
2822
2823 # set up an ipv6 tunnel
2824 ipv6-tunnel() {
2825     case $1 in
2826         start)
2827             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2828                 print 'ipv6 tunnel already set up, nothing to be done.'
2829                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
2830             else
2831                 [[ -n "$PUBLIC_IP" ]] || \
2832                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
2833                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
2834
2835                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
2836                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
2837                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
2838                 ifconfig sit0 tunnel ::192.88.99.1 up
2839                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
2840             fi
2841             ;;
2842         status)
2843             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2844                 print 'ipv6 tunnel available' ; return 0
2845             else
2846                 print 'ipv6 tunnel not available' ; return 1
2847             fi
2848             ;;
2849         stop)
2850             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2851                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
2852                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
2853             else
2854                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
2855             fi
2856             ;;
2857         *)
2858             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
2859             ;;
2860     esac
2861 }
2862
2863 # run dhclient for wireless device
2864 iwclient() {
2865     salias dhclient "$(wavemon -d | awk '/device/{print $2}')"
2866 }
2867
2868 # spawn a minimally set up ksh - useful if you want to umount /usr/.
2869 minimal-shell() {
2870     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ksh
2871 }
2872
2873 # make a backup of a file
2874 bk() {
2875     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2876 }
2877
2878 #f1# grep for patterns in grml's zsh setup
2879 zg() {
2880 #{{{
2881     LANG=C perl -e '
2882
2883 sub usage {
2884     print "usage: zg -[anr] <pattern>\n";
2885     print " Search for patterns in grml'\''s zshrc.\n";
2886     print " zg takes no or exactly one option plus a non empty pattern.\n\n";
2887     print "   options:\n";
2888     print "     --  no options (use if your pattern starts in with a dash.\n";
2889     print "     -a  search for the pattern in all code regions\n";
2890     print "     -n  search for the pattern in non-root code only\n";
2891     print "     -r  search in code for everyone (also root) only\n\n";
2892     print "   The default is -a for non-root users and -r for root.\n\n";
2893     print " If you installed the zshrc to a non-default locations (ie *NOT*\n";
2894     print " in /etc/zsh/zshrc) do: export GRML_ZSHRC=\$HOME/.zshrc\n";
2895     print " ...in case you copied the file to that location.\n\n";
2896     exit 1;
2897 }
2898
2899 if ($ENV{GRML_ZSHRC} ne "") {
2900     $RC = $ENV{GRML_ZSHRC};
2901 } else {
2902     $RC = "/etc/zsh/zshrc";
2903 }
2904
2905 usage if ($#ARGV < 0 || $#ARGV > 1);
2906 if ($> == 0) { $mode = "allonly"; }
2907 else { $mode = "all"; }
2908
2909 $opt = $ARGV[0];
2910 if ($opt eq "--")     { shift; }
2911 elsif ($opt eq "-a")  { $mode = "all"; shift; }
2912 elsif ($opt eq "-n")  { $mode = "nonroot"; shift; }
2913 elsif ($opt eq "-r" ) { $mode = "allonly"; shift; }
2914 elsif ($opt =~ m/^-/ || $#ARGV > 0) { usage(); }
2915
2916 $pattern = $ARGV[0];
2917 usage() if ($pattern eq "");
2918
2919 open FH, "<$RC" or die "zg: Could not open $RC: $!\n";
2920 while ($line = <FH>) {
2921     chomp $line;
2922     if ($line =~ m/^#:grep:marker:for:mika:/) { $markerfound = 1; next; }
2923     next if ($mode eq "nonroot" && markerfound == 0);
2924     break if ($mode eq "allonly" && markerfound == 1);
2925     print $line, "\n" if ($line =~ /$pattern/);
2926 }
2927 close FH;
2928 exit 0;
2929
2930     ' -- "$@"
2931 #}}}
2932     return $?
2933 }
2934
2935 # }}}
2936
2937 # {{{ make sure our environment is clean regarding colors
2938 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2939 # }}}
2940
2941 # source another config file if present {{{
2942 xsource "/etc/zsh/zshrc.local"
2943 # }}}
2944
2945 # "persistent history" {{{
2946 # just write important commands you always need to ~/.important_commands
2947 if [[ -r ~/.important_commands ]] ; then
2948     fc -R ~/.important_commands
2949 fi
2950 # }}}
2951
2952 #:grep:marker:for:mika: :-)
2953 ### non-root (EUID != 0) code below
2954 ###
2955
2956 (( GRML_ALWAYS_LOAD_ALL == 0 )) && (( $EUID == 0 )) && return 0
2957
2958 # variables {{{
2959
2960 # set terminal property (used e.g. by msgid-chooser)
2961 export COLORTERM="yes"
2962
2963 # set default browser
2964 if [[ -z "$BROWSER" ]] ; then
2965     if [[ -n "$DISPLAY" ]] ; then
2966         #v# If X11 is running
2967         check_com -c firefox && export BROWSER=firefox
2968     else
2969         #v# If no X11 is running
2970         check_com -c w3m && export BROWSER=w3m
2971     fi
2972 fi
2973
2974 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
2975 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
2976 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
2977
2978 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
2979 #v# [for non-root only]
2980 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
2981 # }}}
2982
2983 # aliases {{{
2984
2985 # Xterm resizing-fu.
2986 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
2987 alias hide='echo -en "\033]50;nil2\007"'
2988 alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
2989 alias small='echo -en "\033]50;6x10\007"'
2990 alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
2991 alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
2992 alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
2993 alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
2994 alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
2995 alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
2996
2997 # general
2998 #a2# Execute \kbd{du -sch}
2999 alias da='du -sch'
3000 #a2# Execute \kbd{jobs -l}
3001 alias j='jobs -l'
3002
3003 # compile stuff
3004 #a2# Execute \kbd{./configure}
3005 alias CO="./configure"
3006 #a2# Execute \kbd{./configure --help}
3007 alias CH="./configure --help"
3008
3009 # http://conkeror.mozdev.org/
3010 # TODO: I think this should be removed, as conkeror is not a simple extension anymore
3011 #a2# Run a keyboard driven firefox
3012 alias conkeror='firefox -chrome chrome://conkeror/content'
3013
3014 # arch/tla stuff
3015 if check_com -c tla ; then
3016     #a2# Execute \kbd{tla what-changed --diffs | less}
3017     alias tdi='tla what-changed --diffs | less'
3018     #a2# Execute \kbd{tla-buildpackage}
3019     alias tbp='tla-buildpackage'
3020     #a2# Execute \kbd{tla archive-mirror}
3021     alias tmi='tla archive-mirror'
3022     #a2# Execute \kbd{tla commit}
3023     alias tco='tla commit'
3024     #a2# Execute \kbd{tla star-merge}
3025     alias tme='tla star-merge'
3026 fi
3027
3028 # listing stuff
3029 #a2# Execute \kbd{ls -lSrah}
3030 alias dir="ls -lSrah"
3031 #a2# Only show dot-directories
3032 alias lad='ls -d .*(/)'                # only show dot-directories
3033 #a2# Only show dot-files
3034 alias lsa='ls -a .*(.)'                # only show dot-files
3035 #a2# Only files with setgid/setuid/sticky flag
3036 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
3037 #a2# Only show 1st ten symlinks
3038 alias lsl='ls -l *(@[1,10])'           # only symlinks
3039 #a2# Display only executables
3040 alias lsx='ls -l *(*[1,10])'           # only executables
3041 #a2# Display world-{readable,writable,executable} files
3042 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
3043 #a2# Display the ten biggest files
3044 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
3045 #a2# Only show directories
3046 alias lsd='ls -d *(/)'                 # only show directories
3047 #a2# Only show empty directories
3048 alias lse='ls -d *(/^F)'               # only show empty directories
3049 #a2# Display the ten newest files
3050 alias lsnew="ls -rl *(D.om[1,10])"     # display the newest files
3051 #a2# Display the ten oldest files
3052 alias lsold="ls -rtlh *(D.om[1,10])"   # display the oldest files
3053 #a2# Display the ten smallest files
3054 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
3055
3056 # chmod
3057 #a2# Execute \kbd{chmod 600}
3058 alias rw-='chmod 600'
3059 #a2# Execute \kbd{chmod 700}
3060 alias rwx='chmod 700'
3061 #m# a2 r-{}- Execute \kbd{chmod 644}
3062 alias r--='chmod 644'
3063 #a2# Execute \kbd{chmod 755}
3064 alias r-x='chmod 755'
3065
3066 # some useful aliases
3067 #a2# Execute \kbd{mkdir -o}
3068 alias md='mkdir -p'
3069
3070 check_com -c ipython && alias ips='ipython -p sh'
3071
3072 # console stuff
3073 #a2# Execute \kbd{mplayer -vo fbdev}
3074 alias cmplayer='mplayer -vo fbdev'
3075 #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
3076 alias fbmplayer='mplayer -vo fbdev -fs -zoom'
3077 #a2# Execute \kbd{links2 -driver fb}
3078 alias fblinks='links2 -driver fb'
3079
3080 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3081 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3082 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3083
3084 # simple webserver
3085 check_com -c python && alias http="python -m SimpleHTTPServer"
3086
3087 # Use 'g' instead of 'git':
3088 check_com g || alias g='git'
3089
3090 # use colors when browsing man pages, but only if not using LESS_TERMCAP_* from /etc/zsh/zshenv:
3091 if [[ -z "$LESS_TERMCAP_md" ]] ; then
3092     [[ -d ~/.terminfo/ ]] && alias man='TERMINFO=~/.terminfo/ LESS=C TERM=mostlike PAGER=less man'
3093 fi
3094
3095 # check whether Debian's package management (dpkg) is running
3096 if check_com salias ; then
3097     #a2# Check whether a dpkg instance is currently running
3098     salias check_dpkg_running="dpkg_running"
3099 fi
3100
3101 # work around non utf8 capable software in utf environment via $LANG and luit
3102 if check_com isutfenv && check_com luit ; then
3103     if check_com -c mrxvt ; then
3104         isutfenv && [[ -n "$LANG" ]] && \
3105             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3106     fi
3107
3108     if check_com -c aterm ; then
3109         isutfenv && [[ -n "$LANG" ]] && \
3110             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3111     fi
3112
3113     if check_com -c centericq ; then
3114         isutfenv && [[ -n "$LANG" ]] && \
3115             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3116     fi
3117 fi
3118 # }}}
3119
3120 # useful functions {{{
3121
3122 # searching
3123 #f4# Search for newspostings from authors
3124 agoogle() { ${=BROWSER} "http://groups.google.com/groups?as_uauthors=$*" ; }
3125 #f4# Search Debian Bug Tracking System
3126 debbug()  {
3127     setopt localoptions extendedglob
3128     if [[ $# -eq 1 ]]; then
3129         case "$1" in
3130             ([0-9]##)
3131             ${=BROWSER} "http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=$1"
3132             ;;
3133             (*@*)
3134             ${=BROWSER} "http://bugs.debian.org/cgi-bin/pkgreport.cgi?submitter=$1"
3135             ;;
3136             (*)
3137             ${=BROWSER} "http://bugs.debian.org/$*"
3138             ;;
3139         esac
3140     else
3141         print "$0 needs one argument"
3142         return 1
3143     fi
3144 }
3145 #f4# Search Debian Bug Tracking System in mbox format
3146 debbugm() { bts show --mbox $1 } # provide bugnummer as "$1"
3147 #f4# Search DMOZ
3148 dmoz()    { ${=BROWSER} http://search.dmoz.org/cgi-bin/search\?search=${1// /_} }
3149 #f4# Search German   Wiktionary
3150 dwicti()  { ${=BROWSER} http://de.wiktionary.org/wiki/${(C)1// /_} }
3151 #f4# Search English  Wiktionary
3152 ewicti()  { ${=BROWSER} http://en.wiktionary.org/wiki/${(C)1// /_} }
3153 #f4# Search Google Groups
3154 ggogle()  { ${=BROWSER} "http://groups.google.com/groups?q=$*" }
3155 #f4# Search Google
3156 google()  { ${=BROWSER} "http://www.google.com/search?&num=100&q=$*" }
3157 #f4# Search Google Groups for MsgID
3158 mggogle() { ${=BROWSER} "http://groups.google.com/groups?selm=$*" }
3159 #f4# Search Netcraft
3160 netcraft(){ ${=BROWSER} "http://toolbar.netcraft.com/site_report?url=$1" }
3161 #f4# Use German Wikipedia's full text search
3162 swiki()   { ${=BROWSER} http://de.wikipedia.org/wiki/Spezial:Search/${(C)1} }
3163 #f4# search \kbd{dict.leo.org}
3164 oleo()    { ${=BROWSER} "http://dict.leo.org/?search=$*" }
3165 #f4# Search German   Wikipedia
3166 wikide()  { ${=BROWSER} http://de.wikipedia.org/wiki/"${(C)*}" }
3167 #f4# Search English  Wikipedia
3168 wikien()  { ${=BROWSER} http://en.wikipedia.org/wiki/"${(C)*}" }
3169 #f4# Search official debs
3170 wodeb()   { ${=BROWSER} "http://packages.debian.org/search?keywords=$1&searchon=contents&suite=${2:=unstable}&section=all" }
3171
3172 #m# f4 gex() Exact search via Google
3173 check_com google && gex () { google "\"[ $1]\" $*" } # exact search at google
3174
3175 # misc
3176 #f5# Backup \kbd{file {\rm to} file\_timestamp}
3177 bk()      { cp -b ${1} ${1}_`date --iso-8601=m` }
3178 #f5# Copied diff
3179 cdiff()   { diff -crd "$*" | egrep -v "^Only in |^Binary files " }
3180 #f5# cd to directoy and list files
3181 cl()      { cd $1 && ls -a }        # cd && ls
3182 #f5# Cvs add
3183 cvsa()    { cvs add $* && cvs com -m 'initial checkin' $* }
3184 #f5# Cvs diff
3185 cvsd()    { cvs diff -N $* |& $PAGER }
3186 #f5# Cvs log
3187 cvsl()    { cvs log $* |& $PAGER }
3188 #f5# Cvs update
3189 cvsq()    { cvs -nq update }
3190 #f5# Rcs2log
3191 cvsr()    { rcs2log $* | $PAGER }
3192 #f5# Cvs status
3193 cvss()    { cvs status -v $* }
3194 #f5# Disassemble source files using gcc and as
3195 disassemble(){ gcc -pipe -S -o - -O -g $* | as -aldh -o /dev/null }
3196 #f5# Firefox remote control - open given URL
3197 fir()     { firefox -a firefox -remote "openURL($1)" }
3198 #f5# Create Directoy and \kbd{cd} to it
3199 mcd()     { mkdir -p "$@"; cd "$@" } # mkdir && cd
3200 #f5# Unified diff to timestamped outputfile
3201 mdiff()   { diff -udrP "$1" "$2" > diff.`date "+%Y-%m-%d"`."$1" }
3202 #f5# Memory overview
3203 memusage(){ ps aux | awk '{if (NR > 1) print $5; if (NR > 2) print "+"} END { print "p" }' | dc }
3204 #f5# Show contents of tar file
3205 shtar()   { gunzip -c $1 | tar -tf - -- | $PAGER }
3206 #f5# Show contents of tgz file
3207 shtgz()   { tar -ztf $1 | $PAGER }
3208 #f5# Show contents of zip file
3209 shzip()   { unzip -l $1 | $PAGER }
3210 #f5# Greps signature from file
3211 sig()     { agrep -d '^-- $' "$*" ~/.Signature }
3212 #f5# Unified diff
3213 udiff()   { diff -urd $* | egrep -v "^Only in |^Binary files " }
3214 #f5# (Mis)use \kbd{vim} as \kbd{less}
3215 viless()  { vim --cmd 'let no_plugin_maps = 1' -c "so \$VIMRUNTIME/macros/less.vim" "${@:--}" }
3216
3217 # download video from youtube
3218 ytdl() {
3219     if ! [[ -n "$2" ]] ; then
3220         print "Usage: ydtl http://youtube.com/watch?v=.... outputfile.flv">&2
3221         return 1
3222     else
3223         wget -O${2} "http://youtube.com/get_video?"${${${"$(wget -o/dev/null -O- "${1}" | grep -e watch_fullscreen)"}##*watch_fullscreen\?}%%\&fs=*}
3224     fi
3225 }
3226
3227 # Function Usage: uopen $URL/$file
3228 #f5# Download a file and display it locally
3229 uopen() {
3230     if ! [[ -n "$1" ]] ; then
3231         print "Usage: uopen \$URL/\$file">&2
3232         return 1
3233     else
3234         FILE=$1
3235         MIME=$(curl --head $FILE | grep Content-Type | cut -d ' ' -f 2 | cut -d\; -f 1)
3236         MIME=${MIME%$'\r'}
3237         curl $FILE | see ${MIME}:-
3238     fi
3239 }
3240
3241 # Function Usage: doc packagename
3242 #f5# \kbd{cd} to /usr/share/doc/\textit{package}
3243 doc() { cd /usr/share/doc/$1 && ls }
3244 _doc() { _files -W /usr/share/doc -/ }
3245 check_com compdef && compdef _doc doc
3246
3247 #f5# Make screenshot
3248 sshot() {
3249     [[ ! -d ~/shots  ]] && mkdir ~/shots
3250     #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
3251     cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
3252 }
3253
3254 # list images only
3255 limg() {
3256     local -a images
3257     images=( *.{jpg,gif,png}(.N) )
3258
3259     if [[ $#images -eq 0 ]] ; then
3260         print "No image files found"
3261     else
3262         ls "$@" "$images[@]"
3263     fi
3264 }
3265
3266 #f5# Create PDF file from source code
3267 makereadable() {
3268     output=$1
3269     shift
3270     a2ps --medium A4dj -E -o $output $*
3271     ps2pdf $output
3272 }
3273
3274 # zsh with perl-regex - use it e.g. via:
3275 # regcheck '\s\d\.\d{3}\.\d{3} Euro' ' 1.000.000 Euro'
3276 #f5# Checks whether a regex matches or not.\\&\quad Example: \kbd{regcheck '.\{3\} EUR' '500 EUR'}
3277 regcheck() {
3278     zmodload -i zsh/pcre
3279     pcre_compile $1 && \
3280     pcre_match $2 && echo "regex matches" || echo "regex does not match"
3281 }
3282
3283 #f5# List files which have been modified within the last {\it n} days
3284 new() { print -l *(m-$1) }
3285
3286 #f5# Grep in history
3287 greph() { history 0 | grep $1 }
3288 # use colors when GNU grep with color-support
3289 #a2# Execute \kbd{grep -{}-color=auto}
3290 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
3291 #a2# Execute \kbd{grep -i -{}-color=auto}
3292 alias GREP='grep -i --color=auto'
3293
3294 # one blank line between each line
3295 if [[ -r ~/.terminfo/m/mostlike ]] ; then
3296     #f5# Watch manpages in a stretched style
3297     man2() { PAGER='dash -c "sed G | /usr/bin/less"' TERM=mostlike /usr/bin/man "$@" ; }
3298 fi
3299
3300 # d():Copyright 2005 Nikolai Weibull <nikolai@bitwi.se>
3301 # note: option AUTO_PUSHD has to be set
3302 #f5# Jump between directories
3303 d() {
3304     emulate -L zsh
3305     autoload -U colors
3306     local color=$fg_bold[blue]
3307     integer i=0
3308     dirs -p | while read dir; do
3309         local num="${$(printf "%-4d " $i)/ /.}"
3310         printf " %s  $color%s$reset_color\n" $num $dir
3311         (( i++ ))
3312     done
3313     integer dir=-1
3314     read -r 'dir?Jump to directory: ' || return
3315     (( dir == -1 )) && return
3316     if (( dir < 0 || dir >= i )); then
3317         echo d: no such directory stack entry: $dir
3318         return 1
3319     fi
3320     cd ~$dir
3321 }
3322
3323 # usage example: 'lcheck strcpy'
3324 #f5# Find out which libs define a symbol
3325 lcheck() {
3326     if [[ -n "$1" ]] ; then
3327         nm -go /usr/lib/lib*.a 2>/dev/null | grep ":[[:xdigit:]]\{8\} . .*$1"
3328     else
3329         echo "Usage: lcheck <function>" >&2
3330     fi
3331 }
3332
3333 #f5# Clean up directory - remove well known tempfiles
3334 purge() {
3335     FILES=(*~(N) .*~(N) \#*\#(N) *.o(N) a.out(N) *.core(N) *.cmo(N) *.cmi(N) .*.swp(N))
3336     NBFILES=${#FILES}
3337     if [[ $NBFILES > 0 ]] ; then
3338         print $FILES
3339         local ans
3340         echo -n "Remove these files? [y/n] "
3341         read -q ans
3342         if [[ $ans == "y" ]] ; then
3343             rm ${FILES}
3344             echo ">> $PWD purged, $NBFILES files removed"
3345         else
3346             echo "Ok. .. than not.."
3347         fi
3348     fi
3349 }
3350
3351 # Translate DE<=>EN
3352 # 'translate' looks up fot a word in a file with language-to-language
3353 # translations (field separator should be " : "). A typical wordlist looks
3354 # like at follows:
3355 #  | english-word : german-transmission
3356 # It's also only possible to translate english to german but not reciprocal.
3357 # Use the following oneliner to turn back the sort order:
3358 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3359 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3360 #f5# Translates a word
3361 trans() {
3362     case "$1" in
3363         -[dD]*)
3364             translate -l de-en $2
3365             ;;
3366         -[eE]*)
3367             translate -l en-de $2
3368             ;;
3369         *)
3370             echo "Usage: $0 { -D | -E }"
3371             echo "         -D == German to English"
3372             echo "         -E == English to German"
3373     esac
3374 }
3375
3376 #f5# List all occurrences of programm in current PATH
3377 plap() {
3378     if [[ $# = 0 ]] ; then
3379         echo "Usage:    $0 program"
3380         echo "Example:  $0 zsh"
3381         echo "Lists all occurrences of program in the current PATH."
3382     else
3383         ls -l ${^path}/*$1*(*N)
3384     fi
3385 }
3386
3387 # Found in the mailinglistarchive from Zsh (IIRC ~1996)
3388 #f5# Select items for specific command(s) from history
3389 selhist() {
3390     emulate -L zsh
3391     local TAB=$'\t';
3392     (( $# < 1 )) && {
3393         echo "Usage: $0 command"
3394         return 1
3395     };
3396     cmd=(${(f)"$(grep -w $1 $HISTFILE | sort | uniq | pr -tn)"})
3397     print -l $cmd | less -F
3398     echo -n "enter number of desired command [1 - $(( ${#cmd[@]} - 1 ))]: "
3399     local answer
3400     read answer
3401     print -z "${cmd[$answer]#*$TAB}"
3402 }
3403
3404 # Use vim to convert plaintext to HTML
3405 #f5# Transform files to html with highlighting
3406 2html() { vim -u NONE -n -c ':syntax on' -c ':so $VIMRUNTIME/syntax/2html.vim' -c ':wqa' $1 &>/dev/null }
3407
3408 # Usage: simple-extract <file>
3409 #f5# Smart archive extractor
3410 simple-extract () {
3411     if [[ -f $1 ]] ; then
3412         case $1 in
3413             *.tar.bz2)  bzip2 -v -d $1      ;;
3414             *.tar.gz)   tar -xvzf $1        ;;
3415             *.rar)      unrar $1            ;;
3416             *.deb)      ar -x $1            ;;
3417             *.bz2)      bzip2 -d $1         ;;
3418             *.lzh)      lha x $1            ;;
3419             *.gz)       gunzip -d $1        ;;
3420             *.tar)      tar -xvf $1         ;;
3421             *.tgz)      gunzip -d $1        ;;
3422             *.tbz2)     tar -jxvf $1        ;;
3423             *.zip)      unzip $1            ;;
3424             *.Z)        uncompress $1       ;;
3425             *)          echo "'$1' Error. Please go away" ;;
3426         esac
3427     else
3428         echo "'$1' is not a valid file"
3429     fi
3430 }
3431
3432 # Usage: smartcompress <file> (<type>)
3433 #f5# Smart archive creator
3434 smartcompress() {
3435     if [[ -n $2 ]] ; then
3436         case $2 in
3437             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
3438             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
3439             tar.Z)          tar -Zcvf$1.$2 $1 ;;
3440             tar)            tar -cvf$1.$2  $1 ;;
3441             gz | gzip)      gzip           $1 ;;
3442             bz2 | bzip2)    bzip2          $1 ;;
3443             *)
3444                 echo "Error: $2 is not a valid compression type"
3445                 ;;
3446         esac
3447     else
3448         smartcompress $1 tar.gz
3449     fi
3450 }
3451
3452 # Usage: show-archive <archive>
3453 #f5# List an archive's content
3454 show-archive() {
3455     if [[ -f $1 ]] ; then
3456         case $1 in
3457             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
3458             *.tar)         tar -tf $1 ;;
3459             *.tgz)         tar -ztf $1 ;;
3460             *.zip)         unzip -l $1 ;;
3461             *.bz2)         bzless $1 ;;
3462             *.deb)         dpkg-deb --fsys-tarfile $1 | tar -tf - -- ;;
3463             *)             echo "'$1' Error. Please go away" ;;
3464         esac
3465     else
3466         echo "'$1' is not a valid archive"
3467     fi
3468 }
3469
3470 # It's shameless stolen from <http://www.vim.org/tips/tip.php?tip_id=167>
3471 #f5# Use \kbd{vim} as your manpage reader
3472 vman() { man $* | col -b | view -c 'set ft=man nomod nolist' - }
3473
3474 # function readme() { $PAGER -- (#ia3)readme* }
3475 #f5# View all README-like files in current directory in pager
3476 readme() {
3477     local files
3478     files=(./(#i)*(read*me|lue*m(in|)ut)*(ND))
3479     if (($#files)) ; then
3480         $PAGER $files
3481     else
3482         print 'No README files.'
3483     fi
3484 }
3485
3486 # function ansi-colors()
3487 #f5# Display ANSI colors
3488 ansi-colors() {
3489     typeset esc="\033[" line1 line2
3490     echo " _ _ _40 _ _ _41_ _ _ _42 _ _ 43_ _ _ 44_ _ _45 _ _ _ 46_ _ _ 47_ _ _ 49_ _"
3491     for fore in 30 31 32 33 34 35 36 37; do
3492         line1="$fore "
3493         line2="   "
3494         for back in 40 41 42 43 44 45 46 47 49; do
3495             line1="${line1}${esc}${back};${fore}m Normal ${esc}0m"
3496             line2="${line2}${esc}${back};${fore};1m Bold   ${esc}0m"
3497         done
3498         echo -e "$line1\n$line2"
3499     done
3500 }
3501
3502 # suidfind() { ls -latg $path | grep '^...s' }
3503 #f5# Find all files in \$PATH with setuid bit set
3504 suidfind() { ls -latg $path/*(sN) }
3505
3506 # See above but this is /better/ ... anywise ..
3507 findsuid() {
3508     print 'Output will be written to ~/suid_* ...'
3509     $SUDO find / -type f \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suidfiles.`date "+%Y-%m-%d"`.out 2>&1
3510     $SUDO find / -type d \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suiddirs.`date "+%Y-%m-%d"`.out 2>&1
3511     $SUDO find / -type f \( -perm -2 -o -perm -20 \) -ls > ~/suid_writefiles.`date "+%Y-%m-%d"`.out 2>&1
3512     $SUDO find / -type d \( -perm -2 -o -perm -20 \) -ls > ~/suid_writedirs.`date "+%Y-%m-%d"`.out 2>&1
3513     print 'Finished'
3514 }
3515
3516 #f5# Reload given functions
3517 refunc() {
3518     for func in $argv ; do
3519         unfunction $func
3520         autoload $func
3521     done
3522 }
3523
3524 # a small check to see which DIR is located on which server/partition.
3525 # stolen and modified from Sven's zshrc.forall
3526 #f5# Report diskusage of a directory
3527 dirspace() {
3528     if [[ -n "$1" ]] ; then
3529         for dir in $* ; do
3530             if [[ -d "$dir" ]] ; then
3531                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3532             else
3533                 echo "warning: $dir does not exist" >&2
3534             fi
3535         done
3536     else
3537         for dir in $path; do
3538             if [[ -d "$dir" ]] ; then
3539                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3540             else
3541                 echo "warning: $dir does not exist" >&2
3542             fi
3543         done
3544     fi
3545 }
3546
3547 # % slow_print `cat /etc/passwd`
3548 #f5# Slowly print out parameters
3549 slow_print() {
3550     for argument in "${@}" ; do
3551         for ((i = 1; i <= ${#1} ;i++)) ; do
3552             print -n "${argument[i]}"
3553             sleep 0.08
3554         done
3555         print -n " "
3556     done
3557     print ""
3558 }
3559
3560 #f5# Show some status info
3561 status() {
3562     print ""
3563     print "Date..: "$(date "+%Y-%m-%d %H:%M:%S")""
3564     print "Shell.: Zsh $ZSH_VERSION (PID = $$, $SHLVL nests)"
3565     print "Term..: $TTY ($TERM), ${BAUD:+$BAUD bauds, }$COLUMNS x $LINES cars"
3566     print "Login.: $LOGNAME (UID = $EUID) on $HOST"
3567     print "System: $(cat /etc/[A-Za-z]*[_-][rv]e[lr]*)"
3568     print "Uptime:$(uptime)"
3569     print ""
3570 }
3571
3572 # Rip an audio CD
3573 #f5# Rip an audio CD
3574 audiorip() {
3575     mkdir -p ~/ripps
3576     cd ~/ripps
3577     cdrdao read-cd --device $DEVICE --driver generic-mmc audiocd.toc
3578     cdrdao read-cddb --device $DEVICE --driver generic-mmc audiocd.toc
3579     echo " * Would you like to burn the cd now? (yes/no)"
3580     read input
3581     if [[ "$input" = "yes" ]] ; then
3582         echo " ! Burning Audio CD"
3583         audioburn
3584         echo " * done."
3585     else
3586         echo " ! Invalid response."
3587     fi
3588 }
3589
3590 # and burn it
3591 #f5# Burn an audio CD (in combination with audiorip)
3592 audioburn() {
3593     cd ~/ripps
3594     cdrdao write --device $DEVICE --driver generic-mmc audiocd.toc
3595     echo " * Should I remove the temporary files? (yes/no)"
3596     read input
3597     if [[ "$input" = "yes" ]] ; then
3598         echo " ! Removing Temporary Files."
3599         cd ~
3600         rm -rf ~/ripps
3601         echo " * done."
3602     else
3603         echo " ! Invalid response."
3604     fi
3605 }
3606
3607 #f5# Make an audio CD from all mp3 files
3608 mkaudiocd() {
3609     # TODO: do the renaming more zshish, possibly with zmv()
3610     cd ~/ripps
3611     for i in *.[Mm][Pp]3; do mv "$i" `echo $i | tr '[A-Z]' '[a-z]'`; done
3612     for i in *.mp3; do mv "$i" `echo $i | tr ' ' '_'`; done
3613     for i in *.mp3; do mpg123 -w `basename $i .mp3`.wav $i; done
3614     normalize -m *.wav
3615     for i in *.wav; do sox $i.wav -r 44100 $i.wav resample; done
3616 }
3617
3618 #f5# Create an ISO image. You are prompted for\\&\quad volume name, filename and directory
3619 mkiso() {
3620     echo " * Volume name "
3621     read volume
3622     echo " * ISO Name (ie. tmp.iso)"
3623     read iso
3624     echo " * Directory or File"
3625     read files
3626     mkisofs -o ~/$iso -A $volume -allow-multidot -J -R -iso-level 3 -V $volume -R $files
3627 }
3628
3629 #f5# Simple thumbnails generator
3630 genthumbs() {
3631     rm -rf thumb-* index.html
3632     echo "
3633 <html>
3634   <head>
3635     <title>Images</title>
3636   </head>
3637   <body>" > index.html
3638     for f in *.(gif|jpeg|jpg|png) ; do
3639         convert -size 100x200 "$f" -resize 100x200 thumb-"$f"
3640         echo "    <a href=\"$f\"><img src=\"thumb-$f\"></a>" >> index.html
3641     done
3642     echo "
3643   </body>
3644 </html>" >> index.html
3645 }
3646
3647 #f5# Set all ulimit parameters to \kbd{unlimited}
3648 allulimit() {
3649     ulimit -c unlimited
3650     ulimit -d unlimited
3651     ulimit -f unlimited
3652     ulimit -l unlimited
3653     ulimit -n unlimited
3654     ulimit -s unlimited
3655     ulimit -t unlimited
3656 }
3657
3658 # ogg2mp3 with bitrate of 192
3659 ogg2mp3_192() {
3660     oggdec -o - ${1} | lame -b 192 - ${1:r}.mp3
3661 }
3662
3663 #f5# RFC 2396 URL encoding in Z-Shell
3664 urlencode() {
3665     setopt localoptions extendedglob
3666     input=( ${(s::)1} )
3667     print ${(j::)input/(#b)([^A-Za-z0-9_.!~*\'\(\)-])/%${(l:2::0:)$(([##16]#match))}}
3668 }
3669
3670 #f5# Install x-lite (VoIP software)
3671 getxlite() {
3672     setopt local_options
3673     setopt errreturn
3674     [[ -d ~/tmp ]] || mkdir ~/tmp
3675     cd ~/tmp
3676
3677     echo "Downloading http://www.counterpath.com/download/X-Lite_Install.tar.gz and storing it in ~/tmp:"
3678     if wget http://www.counterpath.com/download/X-Lite_Install.tar.gz ; then
3679         unp X-Lite_Install.tar.gz && echo done || echo failed
3680     else
3681         echo "Error while downloading." ; return 1
3682     fi
3683
3684     if [[ -x xten-xlite/xtensoftphone ]] ; then
3685         echo "Execute xten-xlite/xtensoftphone to start xlite."
3686     fi
3687 }
3688
3689 #f5# Install skype
3690 getskype() {
3691     setopt local_options
3692     setopt errreturn
3693     echo "Downloading debian package of skype."
3694     echo "Notice: If you want to use a more recent skype version run 'getskypebeta'."
3695     wget http://www.skype.com/go/getskype-linux-deb
3696     $SUDO dpkg -i skype*.deb && echo "skype installed."
3697 }
3698
3699 #f5# Install beta-version of skype
3700 getskypebeta() {
3701     setopt local_options
3702     setopt errreturn
3703     echo "Downloading debian package of skype (beta version)."
3704     wget http://www.skype.com/go/getskype-linux-beta-deb
3705     $SUDO dpkg -i skype-beta*.deb && echo "skype installed."
3706 }
3707
3708 #f5# Install gizmo (VoIP software)
3709 getgizmo() {
3710     setopt local_options
3711     setopt errreturn
3712     echo "libgtk2.0-0, gconf2, libstdc++6, libasound2 and zlib1g have to be available. Installing."
3713     $SUDO apt-get update
3714     $SUDO apt-get install libgtk2.0-0 gconf2 libstdc++6 libasound2 zlib1g
3715     wget "$(lynx --dump http://gizmo5.com/pc/download/linux/ | awk '/libstdc\+\+6.*\.deb/ {print $2}')"
3716     $SUDO dpkg -i gizmo-project*.deb && echo "gizmo installed."
3717 }
3718
3719 #f5# Get and run AIR (Automated Image and Restore)
3720 getair() {
3721     setopt local_options
3722     setopt errreturn
3723     [[ -w . ]] || { echo 'Error: you do not have write permissions in this directory. Exiting.' ; return 1 }
3724     local VER='1.2.8'
3725     wget http://puzzle.dl.sourceforge.net/sourceforge/air-imager/air-$VER.tar.gz
3726     tar zxf air-$VER.tar.gz
3727     cd air-$VER
3728     INTERACTIVE=no $SUDO ./install-air-1.2.8
3729     [[ -x /usr/local/bin/air ]] && [[ -n "$DISPLAY" ]] && $SUDO air
3730 }
3731
3732 #f5# Get specific git commitdiff
3733 git-get-diff() {
3734     if [[ -z $GITTREE ]] ; then
3735         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3736     fi
3737     if ! [[ -z $1 ]] ; then
3738         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commitdiff;h=$1"
3739     else
3740         echo "Usage: git-get-diff <commit>"
3741     fi
3742 }
3743
3744 #f5# Get specific git commit
3745 git-get-commit() {
3746     if [[ -z $GITTREE ]] ; then
3747         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3748     fi
3749     if ! [[ -z $1 ]] ; then
3750         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commit;h=$1"
3751     else
3752         echo "Usage: git-get-commit <commit>"
3753     fi
3754 }
3755
3756 #f5# Get specific git diff
3757 git-get-plaindiff () {
3758     if [[ -z $GITTREE ]] ; then
3759        GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3760     fi
3761     if [[ -z $1 ]] ; then
3762        echo 'Usage: git-get-plaindiff '
3763     else
3764        echo -n "Downloading $1.diff ... "
3765        # avoid "generating ..." stuff from kernel.org server:
3766        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O /dev/null
3767        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O $1.diff \
3768             && echo done || echo failed
3769     fi
3770 }
3771
3772
3773 # http://strcat.de/blog/index.php?/archives/335-Software-sauber-deinstallieren...html
3774 #f5# Log 'make install' output
3775 mmake() {
3776     [[ ! -d ~/.errorlogs ]] && mkdir ~/.errorlogs
3777     make -n install > ~/.errorlogs/${PWD##*/}-makelog
3778 }
3779
3780 #f5# Indent source code
3781 smart-indent() {
3782     indent -npro -kr -i8 -ts8 -sob -l80 -ss -ncs $*
3783 }
3784
3785 # highlight important stuff in diff output, usage example: hg diff | hidiff
3786 #m# a2 hidiff \kbd{histring} oneliner for diffs
3787 check_com -c histring && \
3788     alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
3789
3790 # rename pictures based on information found in exif headers
3791 #f5# Rename pictures based on information found in exif headers
3792 exirename() {
3793     if [[ $# -lt 1 ]] ; then
3794         echo 'Usage: jpgrename $FILES' >& 2
3795         return 1
3796     else
3797         echo -n 'Checking for jhead with version newer than 1.9: '
3798         jhead_version=`jhead -h | grep 'used by most Digital Cameras.  v.*' | awk '{print $6}' | tr -d v`
3799         if [[ $jhead_version > '1.9' ]]; then
3800             echo 'success - now running jhead.'
3801             jhead -n%Y-%m-%d_%Hh%M_%f $*
3802         else
3803             echo 'failed - exiting.'
3804         fi
3805     fi
3806 }
3807
3808 # open file in vim and jump to line
3809 # http://www.downgra.de/archives/2007/05/08/T19_21_11/
3810 j2v() {
3811     local -a params
3812     params=(${*//(#m):[0-9]*:/\\n+${MATCH//:/}}) # replace ':23:' to '\n+23'
3813     params=(${(s|\n|)${(j|\n|)params}}) # join array using '\n', then split on all '\n'
3814     vim ${params}
3815 }
3816
3817 # get_ic() - queries imap servers for capabilities; real simple. no imaps
3818 ic_get() {
3819     local port
3820     if [[ ! -z $1 ]] ; then
3821         port=${2:-143}
3822         print "querying imap server on $1:${port}...\n";
3823         print "a1 capability\na2 logout\n" | nc $1 ${port}
3824     else
3825         print "usage:\n  $0 <imap-server> [port]"
3826     fi
3827 }
3828
3829 # creates a Maildir/ with its {new,cur,tmp} subdirs
3830 mkmaildir() {
3831     local root subdir
3832     root=${MAILDIR_ROOT:-${HOME}/Mail}
3833     if [[ -z ${1} ]] ; then print "Usage:\n $0 <dirname>" ; return 1 ; fi
3834     subdir=${1}
3835     mkdir -p ${root}/${subdir}/{cur,new,tmp}
3836 }
3837
3838 #f5# Change the xterm title from within GNU-screen
3839 xtrename() {
3840     if [[ ${1} != "-f" ]] ; then
3841         if [[ -z ${DISPLAY} ]] ; then
3842             printf 'xtrename only makes sense in X11.\n'
3843             return 1
3844         fi
3845     else
3846         shift
3847     fi
3848     if [[ -z ${1} ]] ; then
3849         printf 'usage: xtrename [-f] "title for xterm"\n'
3850         printf '  renames the title of xterm from _within_ screen.\n'
3851         printf '  also works without screen.\n'
3852         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3853         return 0
3854     fi
3855     print -n "\eP\e]0;${1}\C-G\e\\"
3856     return 0
3857 }
3858
3859 # hl() highlighted less
3860 # http://ft.bewatermyfriend.org/comp/data/zsh/zfunct.html
3861 if check_com -c highlight ; then
3862     function hl() {
3863         local theme lang
3864         theme=${HL_THEME:-""}
3865         case ${1} in
3866             (-l|--list)
3867                 ( printf 'available languages (syntax parameter):\n\n' ;
3868                     highlight --list-langs ; ) | less -SMr
3869                 ;;
3870             (-t|--themes)
3871                 ( printf 'available themes (style parameter):\n\n' ;
3872                     highlight --list-themes ; ) | less -SMr
3873                 ;;
3874             (-h|--help)
3875                 printf 'usage: hl <syntax[:theme]> <file>\n'
3876                 printf '    available options: --list (-l), --themes (-t), --help (-h)\n\n'
3877                 printf '  Example: hl c main.c\n'
3878                 ;;
3879             (*)
3880                 if [[ -z ${2} ]] || (( ${#argv} > 2 )) ; then
3881                     printf 'usage: hl <syntax[:theme]> <file>\n'
3882                     printf '    available options: --list (-l), --themes (-t), --help (-h)\n'
3883                     (( ${#argv} > 2 )) && printf '  Too many arguments.\n'
3884                     return 1
3885                 fi
3886                 lang=${1%:*}
3887                 [[ ${1} == *:* ]] && [[ -n ${1#*:} ]] && theme=${1#*:}
3888                 if [[ -n ${theme} ]] ; then
3889                     highlight --xterm256 --syntax ${lang} --style ${theme} ${2} | less -SMr
3890                 else
3891                     highlight --ansi --syntax ${lang} ${2} | less -SMr
3892                 fi
3893                 ;;
3894         esac
3895         return 0
3896     }
3897     # ... and a proper completion for hl()
3898     # needs 'highlight' as well, so it fits fine in here.
3899     function _hl_genarg()  {
3900         local expl
3901         if [[ -prefix 1 *: ]] ; then
3902             local themes
3903             themes=(${${${(f)"$(LC_ALL=C highlight --list-themes)"}/ #/}:#*(Installed|Use name)*})
3904             compset -P 1 '*:'
3905             _wanted -C list themes expl theme compadd ${themes}
3906         else
3907             local langs
3908             langs=(${${${(f)"$(LC_ALL=C highlight --list-langs)"}/ #/}:#*(Installed|Use name)*})
3909             _wanted -C list languages expl languages compadd -S ':' -q ${langs}
3910         fi
3911     }
3912     function _hl_complete() {
3913         _arguments -s '1: :_hl_genarg' '2:files:_path_files'
3914     }
3915     compdef _hl_complete hl
3916 fi
3917
3918 # create small urls via tinyurl.com using wget, grep and sed
3919 zurl() {
3920     [[ -z ${1} ]] && print "please give an url to shrink." && return 1
3921     local url=${1}
3922     local tiny="http://tinyurl.com/create.php?url="
3923     #print "${tiny}${url}" ; return
3924     wget  -O-             \
3925           -o/dev/null     \
3926           "${tiny}${url}" \
3927         | grep -Eio 'value="(http://tinyurl.com/.*)"' \
3928         | sed 's/value=//;s/"//g'
3929 }
3930
3931 #f2# Print a specific line of file(s).
3932 linenr () {
3933 # {{{
3934     if [ $# -lt 2 ] ; then
3935        print "Usage: linenr <number>[,<number>] <file>" ; return 1
3936     elif [ $# -eq 2 ] ; then
3937          local number=$1
3938          local file=$2
3939          command ed -s $file <<< "${number}n"
3940     else
3941          local number=$1
3942          shift
3943          for file in "$@" ; do
3944              if [ ! -d $file ] ; then
3945                 echo "${file}:"
3946                 command ed -s $file <<< "${number}n" 2> /dev/null
3947              else
3948                 continue
3949              fi
3950          done | less
3951     fi
3952 # }}}
3953 }
3954
3955 #f2# Find history events by search pattern and list them by date.
3956 whatwhen()  {
3957 # {{{
3958     local usage help ident format_l format_s first_char remain first last
3959     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3960     help='Use' \`'whatwhen -h'\'' for further explanations.'
3961     ident=${(l,${#${:-Usage: }},, ,)}
3962     format_l="${ident}%s\t\t\t%s\n"
3963     format_s="${format_l//(\\t)##/\\t}"
3964     # Make the first char of the word to search for case
3965     # insensitive; e.g. [aA]
3966     first_char=[${(L)1[1]}${(U)1[1]}]
3967     remain=${1[2,-1]}
3968     # Default search range is `-100'.
3969     first=${2:-\-100}
3970     # Optional, just used for `<first> <last>' given.
3971     last=$3
3972     case $1 in
3973         ("")
3974             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3975             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3976         ;;
3977         (-h)
3978             printf '%s\n\n' ${usage}
3979             print 'OPTIONS:'
3980             printf $format_l '-h' 'show help text'
3981             print '\f'
3982             print 'SEARCH RANGE:'
3983             printf $format_l "'0'" 'the whole history,'
3984             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
3985             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
3986             printf '\n%s\n' 'EXAMPLES:'
3987             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
3988             printf $format_l 'whatwhen zsh -250'
3989             printf $format_l 'whatwhen foo 1 99'
3990         ;;
3991         (\?)
3992             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3993         ;;
3994         (*)
3995             # -l list results on stout rather than invoking $EDITOR.
3996             # -i Print dates as in YYYY-MM-DD.
3997             # -m Search for a - quoted - pattern within the history.
3998             fc -li -m "*${first_char}${remain}*" $first $last
3999         ;;
4000     esac
4001 # }}}
4002 }
4003
4004 # change fluxbox keys from 'Alt-#' to 'Alt-F#' and vice versa
4005 fluxkey-change() {
4006     [[ -n "$FLUXKEYS" ]] || local FLUXKEYS="$HOME/.fluxbox/keys"
4007     if ! [[ -r "$FLUXKEYS" ]] ; then
4008         echo "Sorry, \$FLUXKEYS file $FLUXKEYS could not be read - nothing to be done."
4009         return 1
4010     else
4011         if grep -q 'Mod1 F[0-9] :Workspace [0-9]' $FLUXKEYS ; then
4012             echo -n 'Switching to Alt-# mode in ~/.fluxbox/keys: '
4013             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)F\([0-9]\+[: space :]\+:Workspace.*\)|\1\2|' $FLUXKEYS && echo done || echo failed
4014         elif grep -q 'Mod1 [0-9] :Workspace [0-9]' $FLUXKEYS ; then
4015             echo -n 'Switching to Alt-F# mode in ~/.fluxbox/keys: '
4016             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)\([0-9]\+[: space :]\+:Workspace.*\)|\1F\2|' $FLUXKEYS && echo done || echo failed
4017         else
4018             echo 'Sorry, do not know what to do.'
4019             return 1
4020         fi
4021     fi
4022 }
4023
4024 # retrieve weather information on the console
4025 # Usage example: 'weather LOWG'
4026 weather() {
4027     [[ -n "$1" ]] || {
4028         print 'Usage: weather <station_id>' >&2
4029         print 'List of stations: http://en.wikipedia.org/wiki/List_of_airports_by_ICAO_code'>&2
4030         return 1
4031     }
4032
4033     local PLACE="${1:u}"
4034     local FILE="$HOME/.weather/$PLACE"
4035     local LOG="$HOME/.weather/log"
4036
4037     [[ -d $HOME/.weather ]] || {
4038         print -n "Creating $HOME/.weather: "
4039         mkdir $HOME/.weather
4040         print 'done'
4041     }
4042
4043     print "Retrieving information for ${PLACE}:"
4044     print
4045     wget -T 10 --no-verbose --output-file=$LOG --output-document=$FILE --timestamping http://weather.noaa.gov/pub/data/observations/metar/decoded/$PLACE.TXT
4046
4047     if [[ $? -eq 0 ]] ; then
4048         if [[ -n "$VERBOSE" ]] ; then
4049             cat $FILE
4050         else
4051             DATE=$(grep 'UTC' $FILE | sed 's#.* /##')
4052             TEMPERATURE=$(awk '/Temperature/ { print $4" degree Celcius / " $2" degree Fahrenheit" }' $FILE| tr -d '(')
4053             echo "date: $DATE"
4054             echo "temp:  $TEMPERATURE"
4055         fi
4056     else
4057         print "There was an error retrieving the weather information for $PLACE" >&2
4058         cat $LOG
4059         return 1
4060     fi
4061 }
4062 # }}}
4063
4064 # mercurial related stuff {{{
4065 if check_com -c hg ; then
4066     # gnu like diff for mercurial
4067     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
4068     #f5# GNU like diff for mercurial
4069     hgdi() {
4070         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
4071     }
4072
4073     # build debian package
4074     #a2# Alias for \kbd{hg-buildpackage}
4075     alias hbp='hg-buildpackage'
4076
4077     # execute commands on the versioned patch-queue from the current repos
4078     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
4079
4080     # diffstat for specific version of a mercurial repository
4081     #   hgstat      => display diffstat between last revision and tip
4082     #   hgstat 1234 => display diffstat between revision 1234 and tip
4083     #f5# Diffstat for specific version of a mercurial repos
4084     hgstat() {
4085         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
4086     }
4087
4088     #f5# Get current mercurial tip via hg itself
4089     gethgclone() {
4090         setopt local_options
4091         setopt errreturn
4092         if [[ -f mercurial-tree/.hg ]] ; then
4093             cd mercurial-tree
4094             echo "Running hg pull for retreiving latest version..."
4095             hg pull
4096             echo "Finished update. Building mercurial"
4097             make local
4098             echo "Setting \$PATH to $PWD:\$PATH..."
4099             export PATH="$PWD:$PATH"
4100         else
4101             echo "Downloading mercurial via hg"
4102             hg clone http://selenic.com/repo/hg mercurial-tree
4103             cd mercurial-tree
4104             echo "Building mercurial"
4105             make local
4106             echo "Setting \$PATH to $PWD:\$PATH..."
4107             export PATH="$PWD:$PATH"
4108             echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4109             # echo "Setting \$PYTHONPATH to PYTHONPATH=\${HOME}/lib/python,"
4110             # export PYTHONPATH=${HOME}/lib/python
4111         fi
4112     }
4113
4114 fi # end of check whether we have the 'hg'-executable
4115
4116 # get current mercurial snapshot
4117 #f5# Get current mercurial snapshot
4118 gethgsnap() {
4119     setopt local_options
4120     setopt errreturn
4121     if [[ -f mercurial-snapshot.tar.gz ]] ; then
4122          echo "mercurial-snapshot.tar.gz exists already, skipping download."
4123     else
4124         echo "Downloading mercurial snapshot"
4125         wget http://www.selenic.com/mercurial/mercurial-snapshot.tar.gz
4126     fi
4127     echo "Unpacking mercurial-snapshot.tar.gz"
4128     tar zxf mercurial-snapshot.tar.gz
4129     cd mercurial-snapshot/
4130     echo "Installing required build-dependencies"
4131     $SUDO apt-get update
4132     $SUDO apt-get install python2.4-dev
4133     echo "Building mercurial"
4134     make local
4135     echo "Setting \$PATH to $PWD:\$PATH..."
4136     export PATH="$PWD:$PATH"
4137     echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4138 }
4139 # }}}
4140
4141 # some useful commands often hard to remember - let's grep for them {{{
4142 # actually use our zg() function now. :)
4143
4144 # Work around ion/xterm resize bug.
4145 #if [[ "$SHLVL" -eq 1 ]]; then
4146 #       if check_com -c resize ; then
4147 #               eval `resize </dev/null`
4148 #       fi
4149 #fi
4150
4151 # enable jackd:
4152 #  /usr/bin/jackd -dalsa -dhw:0 -r48000 -p1024 -n2
4153 # now play audio file:
4154 #  alsaplayer -o jack foobar.mp3
4155
4156 # send files via netcat
4157 # on sending side:
4158 #  send() {j=$*; tar cpz ${j/%${!#}/}|nc -w 1 ${!#} 51330;}
4159 #  send dir* $HOST
4160 #  alias receive='nc -vlp 51330 | tar xzvp'
4161
4162 # debian stuff:
4163 # dh_make -e foo@localhost -f $1
4164 # dpkg-buildpackage -rfakeroot
4165 # lintian *.deb
4166 # dpkg-scanpackages ./ /dev/null | gzip > Packages.gz
4167 # dpkg-scansources . | gzip > Sources.gz
4168 # grep-dctrl --field Maintainer $* /var/lib/apt/lists/*
4169
4170 # other stuff:
4171 # convert -geometry 200x200 -interlace LINE -verbose
4172 # ldapsearch -x -b "OU=Bedienstete,O=tug" -h ldap.tugraz.at sn=$1
4173 # ps -ao user,pcpu,start,command
4174 # gpg --keyserver blackhole.pca.dfn.de --recv-keys
4175 # xterm -bg black -fg yellow -fn -misc-fixed-medium-r-normal--14-140-75-75-c-90-iso8859-15 -ah
4176 # nc -vz $1 1-1024   # portscan via netcat
4177 # wget --mirror --no-parent --convert-links
4178 # pal -d `date +%d`
4179 # autoload -U tetris; zle -N tetris; bindkey '...' ; echo "press ... for playing tennis"
4180 #
4181 # modify console cursor
4182 # see http://www.tldp.org/HOWTO/Framebuffer-HOWTO-5.html
4183 # print $'\e[?96;0;64c'
4184 # }}}
4185
4186 # grml-small cleanups {{{
4187
4188 # The following is used to remove zsh-config-items that do not work
4189 # in grml-small by default.
4190 # If you do not want these adjustments (for whatever reason), set
4191 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
4192 # sources if it is there).
4193
4194 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
4195
4196     unset abk[V]
4197     unalias    'V'      &> /dev/null
4198     unfunction vman     &> /dev/null
4199     unfunction vimpm    &> /dev/null
4200     unfunction vimhelp  &> /dev/null
4201     unfunction viless   &> /dev/null
4202     unfunction 2html    &> /dev/null
4203
4204     # manpages are not in grmlsmall
4205     unfunction manzsh   &> /dev/null
4206     unalias    man2     &> /dev/null
4207     unalias    man      &> /dev/null
4208     unfunction man2     &> /dev/null
4209
4210 fi
4211
4212 #}}}
4213
4214 # finally source a local zshrc {{{
4215
4216 # this allows us to stay in sync with grml's zshrc and put own
4217 # modifications in ~/.zshrc.local
4218
4219 xsource "${HOME}/.zshrc.local"
4220
4221 # }}}
4222
4223 ## genrefcard.pl settings {{{
4224
4225 ### doc strings for external functions from files
4226 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
4227
4228 ### example: split functions-search 8,16,24,32
4229 #@# split functions-search 8
4230
4231 ## }}}
4232
4233 ## END OF FILE #################################################################
4234 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4