etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # zsh-refcard-tag documentation: {{{
  15 #   You may notice strange looking comments in this file.
  16 #   These are there for a purpose. grml's zsh-refcard can now be
  17 #   automatically generated from the contents of the actual configuration
  18 #   file. However, we need a little extra information on which comments
  19 #   and what lines of code to take into account (and for what purpose).
  20 #
  21 # Here is what they mean:
  22 #
  23 # List of tags (comment types) used:
  24 #   #a#     Next line contains an important alias, that should
  25 #           be included in the grml-zsh-refcard.
  26 #           (placement tag: @@INSERT-aliases@@)
  27 #   #f#     Next line contains the beginning of an important function.
  28 #           (placement tag: @@INSERT-functions@@)
  29 #   #v#     Next line contains an important variable.
  30 #           (placement tag: @@INSERT-variables@@)
  31 #   #k#     Next line contains an important keybinding.
  32 #           (placement tag: @@INSERT-keybindings@@)
  33 #   #d#     Hashed directories list generation:
  34 #               start   denotes the start of a list of 'hash -d'
  35 #                       definitions.
  36 #               end     denotes its end.
  37 #           (placement tag: @@INSERT-hasheddirs@@)
  38 #   #A#     Abbreviation expansion list generation:
  39 #               start   denotes the beginning of abbreviations.
  40 #               end     denotes their end.
  41 #           Lines within this section that end in '#d .*' provide
  42 #           extra documentation to be included in the refcard.
  43 #           (placement tag: @@INSERT-abbrev@@)
  44 #   #m#     This tag allows you to manually generate refcard entries
  45 #           for code lines that are hard/impossible to parse.
  46 #               Example:
  47 #                   #m# k ESC-h Call the run-help function
  48 #               That would add a refcard entry in the keybindings table
  49 #               for 'ESC-h' with the given comment.
  50 #           So the syntax is: #m# <section> <argument> <comment>
  51 #   #o#     This tag lets you insert entries to the 'other' hash.
  52 #           Generally, this should not be used. It is there for
  53 #           things that cannot be done easily in another way.
  54 #           (placement tag: @@INSERT-other-foobar@@)
  55 #
  56 #   All of these tags (except for m and o) take two arguments, the first
  57 #   within the tag, the other after the tag:
  58 #
  59 #   #<tag><section># <comment>
  60 #
  61 #   Where <section> is really just a number, which are defined by the
  62 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  63 #   instead of names is, that for the reader, the tag should not differ
  64 #   much from a regular comment. For zsh, it is a regular comment indeed.
  65 #   The numbers have got the following meanings:
  66 #         0 -> "default"
  67 #         1 -> "system"
  68 #         2 -> "user"
  69 #         3 -> "debian"
  70 #         4 -> "search"
  71 #         5 -> "shortcuts"
  72 #         6 -> "services"
  73 #
  74 #   So, the following will add an entry to the 'functions' table in the
  75 #   'system' section, with a (hopefully) descriptive comment:
  76 #       #f1# Edit an alias via zle
  77 #       edalias() {
  78 #
  79 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  80 #   that can be found in 'grml-zsh-refcard.tex.in'.
  81 #   If the section number is omitted, the 'default' section is assumed.
  82 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
  83 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
  84 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
  85 #}}}
  86
  87 # zsh profiling {{{
  88 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
  89 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
  90     zmodload zsh/zprof
  91 fi
  92 # }}}
  93
  94 # load .zshrc.pre to give the user the chance to overwrite the defaults
  95 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
  96
  97 # {{{ check for version/system
  98 # check for versions (compatibility reasons)
  99 is4(){
 100     [[ $ZSH_VERSION == <4->* ]] && return 0
 101     return 1
 102 }
 103
 104 is41(){
 105     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 106     return 1
 107 }
 108
 109 is42(){
 110     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 111     return 1
 112 }
 113
 114 is425(){
 115     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 116     return 1
 117 }
 118
 119 is43(){
 120     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 121     return 1
 122 }
 123
 124 #f1# Checks whether or not you're running grml
 125 isgrml(){
 126     [[ -f /etc/grml_version ]] && return 0
 127     return 1
 128 }
 129
 130 #f1# Checks whether or not you're running a grml cd
 131 isgrmlcd(){
 132     [[ -f /etc/grml_cd ]] && return 0
 133     return 1
 134 }
 135
 136 if isgrml ; then
 137 #f1# Checks whether or not you're running grml-small
 138     isgrmlsmall() {
 139         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 140     }
 141 else
 142     isgrmlsmall() { return 1 }
 143 fi
 144
 145 isdarwin(){
 146     [[ $OSTYPE == darwin* ]] && return 0
 147     return 1
 148 }
 149
 150 #f1# are we running within an utf environment?
 151 isutfenv() {
 152     case "$LANG $CHARSET $LANGUAGE" in
 153         *utf*) return 0 ;;
 154         *UTF*) return 0 ;;
 155         *)     return 1 ;;
 156     esac
 157 }
 158
 159 # check for user, if not running as root set $SUDO to sudo
 160 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 161
 162 # change directory to home on first invocation of zsh
 163 # important for rungetty -> autologin
 164 # Thanks go to Bart Schaefer!
 165 isgrml && checkhome() {
 166     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 167         export ALREADY_DID_CD_HOME=$HOME
 168         cd
 169     fi
 170 }
 171
 172 # check for zsh v3.1.7+
 173
 174 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 175      || ${ZSH_VERSION} == 3.<2->.<->*    \
 176      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 177
 178     printf '-!-\n'
 179     printf '-!- In this configuration we try to make use of features, that only\n'
 180     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 181     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 182     printf '-!- advanced features in all supported versions.\n'
 183     printf '-!-\n'
 184     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 185     printf '-!-\n'
 186     printf '-!- While this *may* work, it might as well fail.\n'
 187     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 188     printf '-!-\n'
 189     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 190     printf '-!- If it does today, you'\''ve been lucky.\n'
 191     printf '-!-\n'
 192     printf '-!- Ye been warned!\n'
 193     printf '-!-\n'
 194
 195     function zstyle() { : }
 196 fi
 197
 198 # autoload wrapper - use this one instead of autoload directly
 199 # We need to define this function as early as this, because autoloading
 200 # 'is-at-least()' needs it.
 201 function zrcautoload() {
 202     setopt local_options extended_glob
 203     local fdir ffile
 204     local -i ffound
 205
 206     ffile=${1}
 207     (( found = 0 ))
 208     for fdir in ${fpath} ; do
 209         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 210     done
 211
 212     (( ffound == 0 )) && return 1
 213     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 214         autoload -U ${ffile} || return 1
 215     else
 216         autoload ${ffile} || return 1
 217     fi
 218     return 0
 219 }
 220
 221 # Load is-at-least() for more precise version checks
 222 # Note that this test will *always* fail, if the is-at-least
 223 # function could not be marked for autoloading.
 224 zrcautoload is-at-least || is-at-least() { return 1 }
 225
 226 # }}}
 227
 228 # setting some default values {{{
 229
 230 NOCOR=${NOCOR:-0}
 231 NOMENU=${NOMENU:-0}
 232 NOPRECMD=${NOPRECMD:-0}
 233 BATTERY=${BATTERY:-0}
 234 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 235 GRML_ALWAYS_LOAD_ALL=${GRML_ALWAYS_LOAD_ALL:-0}
 236
 237 if isgrmlcd ; then
 238     GRML_WARN_SKEL=${GRML_WARN_SKEL:-0}
 239 else
 240     GRML_WARN_SKEL=${GRML_WARN_SKEL:-1}
 241 fi
 242
 243 if (( GRML_WARN_SKEL != 0 )) ; then
 244
 245 function grml_warn_skel_main() {
 246     printf '
 247 Dear user,
 248
 249 You updated grml'\''s zshrc which brings a major change.
 250 The configuration is kept only in one file, being the global zshrc.
 251 In the past, the configuration was split in two files, with the
 252 second file being the .zshrc file from /etc/skel.
 253
 254 If you have a .zshrc file in your home directory that originally
 255 came from the skel directory, please remove it. This is also the case
 256 if you followed earlier instructions from the grml-zsh-refcard or
 257 from <http://grml.org/console/> on non-grml systems.
 258
 259 Please see the current grml-zsh-refcard (available at
 260 <http://grml.org/zsh/>) for updated installation information. In short,
 261 you don'\''t want a .zshrc.global file. Install the global zshrc to
 262 ~/.zshrc and be done.
 263
 264 If you need changes to the configuration, use ~/.zshrc.pre and
 265 ~/.zshrc.local.
 266
 267 '
 268 }
 269
 270 function grml_warn_skel_remove() {
 271     printf 'To remove this warning execute '\''grml_do_not_warn_skel'\''.\n\n'
 272 }
 273
 274 function grml_do_not_warn_skel() {
 275     printf '# Do not warn about old skel dot-files anymore\n' >>! ~/.zshrc.pre
 276     printf 'GRML_WARN_SKEL=0\n' >>! ~/.zshrc.pre
 277 }
 278
 279 # let's try to guess how the user uses us.
 280 if is-at-least 4.3.7 ; then
 281     # funcsourcetrace requires at least version 4.3.7 of zsh.
 282     GRML_SRC_FILE="${${funcsourcetrace[1]}%:*}"
 283
 284     grml_warn_skel_main
 285     case ${GRML_SRC_FILE} in
 286         (${HOME}/.zshrc.global)
 287             grml_warn_skel_remove
 288             printf '\nIt looks like you copied the grml zshrc to '\''~/.zshrc.global'\''.\n'
 289             printf 'Nowadays you just copy the global zshrc to '\''~/.zshrc'\'' to use\n'
 290             printf 'it on a non-grml-system.\n'
 291             ;;
 292         (${HOME}/.zshrc)
 293             printf '\nIt looks like you copied the grml zshrc to '\''~/.zshrc'\''.\n'
 294             printf 'We'\''ll disable this warning automatically for later sessions.\n'
 295             grml_do_not_warn_skel
 296             ;;
 297         (*)
 298             grml_do_not_warn_skel
 299             ;;
 300     esac
 301 else
 302     grml_warn_skel_main
 303     grml_warn_skel_remove
 304 fi
 305
 306 unfunction grml_warn_skel_remove grml_warn_skel_main
 307
 308 fi # GRML_WARN_SKEL
 309
 310 # }}}
 311
 312 # utility functions {{{
 313 # this function checks if a command exists and returns either true
 314 # or false. This avoids using 'which' and 'whence', which will
 315 # avoid problems with aliases for which on certain weird systems. :-)
 316 check_com() {
 317     local -i comonly
 318
 319     if [[ ${1} == '-c' ]] ; then
 320         (( comonly = 1 ))
 321         shift
 322     else
 323         (( comonly = 0 ))
 324     fi
 325
 326     if (( ${#argv} != 1 )) ; then
 327         printf 'usage: check_com [-c] <command>\n' >&2
 328         return 1
 329     fi
 330
 331     if (( comonly > 0 )) ; then
 332         [[ -n ${commands[$1]}  ]] && return 0
 333         return 1
 334     fi
 335
 336     if   [[ -n ${commands[$1]}    ]] \
 337       || [[ -n ${functions[$1]}   ]] \
 338       || [[ -n ${aliases[$1]}     ]] \
 339       || [[ -n ${reswords[(r)$1]} ]] ; then
 340
 341         return 0
 342     fi
 343
 344     return 1
 345 }
 346
 347 # creates an alias and precedes the command with
 348 # sudo if $EUID is not zero.
 349 salias() {
 350     local only=0 ; local multi=0
 351     while [[ ${1} == -* ]] ; do
 352         case ${1} in
 353             (-o) only=1 ;;
 354             (-a) multi=1 ;;
 355             (--) shift ; break ;;
 356             (-h)
 357                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 358                 printf '  -h      shows this help text.\n'
 359                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 360                 printf '          be careful using this option.\n'
 361                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 362                 return 0
 363                 ;;
 364             (*) printf "unkown option: '%s'\n" "${1}" ; return 1 ;;
 365         esac
 366         shift
 367     done
 368
 369     if (( ${#argv} > 1 )) ; then
 370         printf 'Too many arguments %s\n' "${#argv}"
 371         return 1
 372     fi
 373
 374     key="${1%%\=*}" ;  val="${1#*\=}"
 375     if (( EUID == 0 )) && (( only == 0 )); then
 376         alias -- "${key}=${val}"
 377     elif (( EUID > 0 )) ; then
 378         (( multi > 0 )) && val="${val// ; / ; sudo }"
 379         alias -- "${key}=sudo ${val}"
 380     fi
 381
 382     return 0
 383 }
 384
 385 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 386 # usage: uprint foo
 387 #   Where foo is the *name* of the parameter you want printed.
 388 #   Note that foo is no typo; $foo would be wrong here!
 389 if ! is42 ; then
 390     uprint () {
 391         local -a u
 392         local w
 393         local parameter=${1}
 394
 395         if [[ -z ${parameter} ]] ; then
 396             printf 'usage: uprint <parameter>\n'
 397             return 1
 398         fi
 399
 400         for w in ${(P)parameter} ; do
 401             [[ -z ${(M)u:#${w}} ]] && u=( ${u} ${w} )
 402         done
 403
 404         builtin print -l ${u}
 405     }
 406 fi
 407
 408 # Check if we can read given files and source those we can.
 409 xsource() {
 410     if (( ${#argv} < 1 )) ; then
 411         printf 'usage: xsource FILE(s)...\n' >&2
 412         return 1
 413     fi
 414
 415     while (( ${#argv} > 0 )) ; do
 416         [[ -r ${1} ]] && source ${1}
 417         shift
 418     done
 419     return 0
 420 }
 421
 422 # Check if we can read a given file and 'cat(1)' it.
 423 xcat() {
 424     if (( ${#argv} != 1 )) ; then
 425         printf 'usage: xcat FILE\n' >&2
 426         return 1
 427     fi
 428
 429     [[ -r ${1} ]] && cat ${1}
 430     return 0
 431 }
 432
 433 # Remove these functions again, they are of use only in these
 434 # setup files. This should be called at the end of .zshrc.
 435 xunfunction() {
 436     local -a funcs
 437     funcs=(salias xcat xsource xunfunction zrcautoload)
 438
 439     for func in $funcs ; do
 440         [[ -n ${functions[$func]} ]] \
 441             && unfunction $func
 442     done
 443     return 0
 444 }
 445
 446 # this allows us to stay in sync with grml's zshrc and put own
 447 # modifications in ~/.zshrc.local
 448 zrclocal() {
 449     xsource "${HOME}/.zshrc.local"
 450     return 0
 451 }
 452
 453 #}}}
 454
 455 # locale setup {{{
 456 xsource "/etc/default/locale"
 457
 458 export LANG=${LANG:-en_US.iso885915}
 459 for var in LC_ALL LC_MESSAGES ; do
 460     [[ -n ${(P)var} ]] && export $var
 461 done
 462
 463 xsource "/etc/sysconfig/keyboard"
 464
 465 TZ=$(xcat /etc/timezone)
 466 # }}}
 467
 468 # check for potentially old files in 'completion.d' {{{
 469 setopt extendedglob
 470 xof=(/etc/zsh/completion.d/*~/etc/zsh/completion.d/_*(N))
 471 if (( ${#xof} > 0 )) ; then
 472     printf '\n -!- INFORMATION\n\n'
 473     printf ' -!- %s file(s) not starting with an underscore (_) found in\n' ${#xof}
 474     printf ' -!- /etc/zsh/completion.d/.\n\n'
 475     printf ' -!- While this has been the case in old versions of grml-etc-core,\n'
 476     printf ' -!- recent versions of the grml-zsh-setup have all these files rewritten\n'
 477     printf ' -!- and renamed. Furthermore, the grml-zsh-setup will *only* add files\n'
 478     printf ' -!- named _* to that directory.\n\n'
 479     printf ' -!- If you added functions to completion.d yourself, please consider\n'
 480     printf ' -!- moving them to /etc/zsh/functions.d/. Files in that directory, not\n'
 481     printf ' -!- starting with an underscore are marked for automatic loading\n'
 482     printf ' -!- by default (so that is quite convenient).\n\n'
 483     printf ' -!- If there are files *not* starting with an underscore from an older\n'
 484     printf ' -!- grml-etc-core in completion.d, you may safely remove them.\n\n'
 485     printf ' -!- Delete the files for example via running:\n\n'
 486     printf "      rm ${xof}\n\n"
 487     printf ' -!- Note, that this message will *not* go away, unless you yourself\n'
 488     printf ' -!- resolve the situation manually.\n\n'
 489     BROKEN_COMPLETION_DIR=1
 490 fi
 491 unset xof
 492 # }}}
 493
 494 # {{{ set some variables
 495 if check_com -c vim ; then
 496 #v#
 497     export EDITOR=${EDITOR:-vim}
 498 else
 499     export EDITOR=${EDITOR:-vi}
 500 fi
 501
 502 #v#
 503 export PAGER=${PAGER:-less}
 504
 505 #v#
 506 export MAIL=${MAIL:-/var/mail/$USER}
 507
 508 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 509 export SHELL='/bin/zsh'
 510
 511 # color setup for ls:
 512 check_com -c dircolors && eval $(dircolors -b)
 513 # color setup for ls on OS X:
 514 isdarwin && export CLICOLOR=1
 515
 516 # do MacPorts setup on darwin
 517 if isdarwin && [[ -d /opt/local ]]; then
 518     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 519     # zshenv.
 520     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 521     MANPATH="/opt/local/share/man:$MANPATH"
 522 fi
 523 # do Fink setup on darwin
 524 isdarwin && xsource /sw/bin/init.sh
 525
 526 # completion functions go to /etc/zsh/completion.d
 527 # function files may be put into /etc/zsh/functions.d, from where they
 528 # will be automatically autoloaded.
 529 if [[ -n "$BROKEN_COMPLETION_DIR" ]] ; then
 530     print 'Warning: not setting completion directories because broken files have been found.' >&2
 531 else
 532     [[ -d /etc/zsh/completion.d ]] && fpath=( $fpath /etc/zsh/completion.d )
 533     if [[ -d /etc/zsh/functions.d ]] ; then
 534         fdir='/etc/zsh/functions.d'
 535         fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 536         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 537             zrcautoload ${func:t}
 538         done
 539         unset fdir
 540     fi
 541 fi
 542
 543 # automatically remove duplicates from these arrays
 544 typeset -U path cdpath fpath manpath
 545 # }}}
 546
 547 # {{{ keybindings
 548 if [[ "$TERM" != emacs ]] ; then
 549     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 550     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 551     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 552     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 553     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 554     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 555     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 556     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 557     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 558     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 559     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 560     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 561     # ncurses stuff:
 562     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 563     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 564     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 565     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 566     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 567     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 568     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 569     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 570 fi
 571
 572 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 573 # use emacs style per default:
 574 bindkey -e
 575 # use vi style:
 576 # bindkey -v
 577
 578 #if [[ "$TERM" == screen ]] ; then
 579 bindkey '\e[1~' beginning-of-line       # home
 580 bindkey '\e[4~' end-of-line             # end
 581 bindkey '\e[A'  up-line-or-search       # cursor up
 582 bindkey '\e[B'  down-line-or-search     # <ESC>-
 583
 584 bindkey '^xp'   history-beginning-search-backward
 585 bindkey '^xP'   history-beginning-search-forward
 586 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 587 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 588 # if terminal type is set to 'rxvt':
 589 bindkey '\e[7~' beginning-of-line       # home
 590 bindkey '\e[8~' end-of-line             # end
 591 #fi
 592
 593 # insert unicode character
 594 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 595 # See for example http://unicode.org/charts/ for unicode characters code
 596 zrcautoload insert-unicode-char
 597 zle -N insert-unicode-char
 598 #k# Insert Unicode character
 599 bindkey '^Xi' insert-unicode-char
 600
 601 # just type 'cd ...' to get 'cd ../..'
 602 #  rationalise-dot() {
 603 #  if [[ $LBUFFER == *.. ]] ; then
 604 #    LBUFFER+=/..
 605 #  else
 606 #    LBUFFER+=.
 607 #  fi
 608 #  }
 609 #  zle -N rationalise-dot
 610 #  bindkey . rationalise-dot
 611
 612 #  bindkey '\eq' push-line-or-edit
 613
 614 ## toggle the ,. abbreviation feature on/off
 615 # NOABBREVIATION: default abbreviation-state
 616 #                 0 - enabled (default)
 617 #                 1 - disabled
 618 NOABBREVIATION=${NOABBREVIATION:-0}
 619
 620 grml_toggle_abbrev() {
 621     if (( ${NOABBREVIATION} > 0 )) ; then
 622         NOABBREVIATION=0
 623     else
 624         NOABBREVIATION=1
 625     fi
 626 }
 627
 628 zle -N grml_toggle_abbrev
 629 bindkey '^xA' grml_toggle_abbrev
 630
 631 # }}}
 632
 633 # a generic accept-line wrapper {{{
 634
 635 # This widget can prevent unwanted autocorrections from command-name
 636 # to _command-name, rehash automatically on enter and call any number
 637 # of builtin and user-defined widgets in different contexts.
 638 #
 639 # For a broader description, see:
 640 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 641 #
 642 # The code is imported from the file 'zsh/functions/accept-line' from
 643 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 644 # distributed under the same terms as zsh itself.
 645
 646 # A newly added command will may not be found or will cause false
 647 # correction attempts, if you got auto-correction set. By setting the
 648 # following style, we force accept-line() to rehash, if it cannot
 649 # find the first word on the command line in the $command[] hash.
 650 zstyle ':acceptline:*' rehash true
 651
 652 function Accept-Line() {
 653     setopt localoptions noksharrays
 654     local -a subs
 655     local -xi aldone
 656     local sub
 657
 658     zstyle -a ":acceptline:${alcontext}" actions subs
 659
 660     (( ${#subs} < 1 )) && return 0
 661
 662     (( aldone = 0 ))
 663     for sub in ${subs} ; do
 664         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 665         zle ${sub}
 666
 667         (( aldone > 0 )) && break
 668     done
 669 }
 670
 671 function Accept-Line-getdefault() {
 672     local default_action
 673
 674     zstyle -s ":acceptline:${alcontext}" default_action default_action
 675     case ${default_action} in
 676         ((accept-line|))
 677             printf ".accept-line"
 678             ;;
 679         (*)
 680             printf ${default_action}
 681             ;;
 682     esac
 683 }
 684
 685 function accept-line() {
 686     setopt localoptions noksharrays
 687     local -a cmdline
 688     local -x alcontext
 689     local buf com fname format msg default_action
 690
 691     alcontext='default'
 692     buf="${BUFFER}"
 693     cmdline=(${(z)BUFFER})
 694     com="${cmdline[1]}"
 695     fname="_${com}"
 696
 697     zstyle -t ":acceptline:${alcontext}" rehash \
 698         && [[ -z ${commands[$com]} ]]           \
 699         && rehash
 700
 701     if    [[ -n ${reswords[(r)$com]} ]] \
 702        || [[ -n ${aliases[$com]}     ]] \
 703        || [[ -n ${functions[$com]}   ]] \
 704        || [[ -n ${builtins[$com]}    ]] \
 705        || [[ -n ${commands[$com]}    ]] ; then
 706
 707         # there is something sensible to execute, just do it.
 708         alcontext='normal'
 709         zle Accept-Line
 710
 711         default_action=$(Accept-Line-getdefault)
 712         zstyle -T ":acceptline:${alcontext}" call_default \
 713             && zle ${default_action}
 714         return
 715     fi
 716
 717     if    [[ -o correct              ]] \
 718        || [[ -o correctall           ]] \
 719        && [[ -n ${functions[$fname]} ]] ; then
 720
 721         # nothing there to execute but there is a function called
 722         # _command_name; a completion widget. Makes no sense to
 723         # call it on the commandline, but the correct{,all} options
 724         # will ask for it nevertheless, so warn the user.
 725         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 726             # Okay, we warned the user before, he called us again,
 727             # so have it his way.
 728             alcontext='force'
 729             zle Accept-Line
 730
 731             default_action=$(Accept-Line-getdefault)
 732             zstyle -T ":acceptline:${alcontext}" call_default \
 733                 && zle ${default_action}
 734             return
 735         fi
 736
 737         # prepare warning message for the user, configurable via zstyle.
 738         zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 739
 740         if [[ -z ${msg} ]] ; then
 741             msg="%c will not execute and completion %f exists."
 742         fi
 743
 744         zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 745
 746         zle -M -- "${msg}"
 747         return
 748     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 749         # If we are here, the commandline contains something that is not
 750         # executable, which is neither subject to _command_name correction
 751         # and is not empty. might be a variable assignment
 752         alcontext='misc'
 753         zle Accept-Line
 754
 755         default_action=$(Accept-Line-getdefault)
 756         zstyle -T ":acceptline:${alcontext}" call_default \
 757             && zle ${default_action}
 758         return
 759     fi
 760
 761     # If we got this far, the commandline only contains whitespace, or is empty.
 762     alcontext='empty'
 763     zle Accept-Line
 764
 765     default_action=$(Accept-Line-getdefault)
 766     zstyle -T ":acceptline:${alcontext}" call_default \
 767         && zle ${default_action}
 768 }
 769
 770 zle -N accept-line
 771 zle -N Accept-Line
 772
 773 # }}}
 774
 775 # power completion - abbreviation expansion {{{
 776 # power completion / abbreviation expansion / buffer expansion
 777 # see http://zshwiki.org/home/examples/zleiab for details
 778 # less risky than the global aliases but powerful as well
 779 # just type the abbreviation key and afterwards ',.' to expand it
 780 declare -A abk
 781 setopt extendedglob
 782 setopt interactivecomments
 783 abk=(
 784 #   key   # value                  (#d additional doc string)
 785 #A# start
 786     '...'  '../..'
 787     '....' '../../..'
 788     'BG'   '& exit'
 789     'C'    '| wc -l'
 790     'G'    '|& grep --color=auto '
 791     'H'    '| head'
 792     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 793     'L'    '| less'
 794     'LL'   '|& less -r'
 795     'M'    '| most'
 796     'N'    '&>/dev/null'           #d (No Output)
 797     'R'    '| tr A-z N-za-m'       #d (ROT13)
 798     'SL'   '| sort | less'
 799     'S'    '| sort -u'
 800     'T'    '| tail'
 801     'V'    '|& vim -'
 802 #A# end
 803     'co'   './configure && make && sudo make install'
 804 )
 805
 806 globalias() {
 807     local MATCH
 808
 809     if (( NOABBREVIATION > 0 )) ; then
 810         LBUFFER="${LBUFFER},."
 811         return 0
 812     fi
 813
 814     matched_chars='[.-|_a-zA-Z0-9]#'
 815     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 816     LBUFFER+=${abk[$MATCH]:-$MATCH}
 817 }
 818
 819 zle -N globalias
 820 bindkey ",." globalias
 821 # }}}
 822
 823 # {{{ autoloading
 824 zrcautoload zmv    # who needs mmv or rename?
 825 zrcautoload history-search-end
 826
 827 # we don't want to quote/espace URLs on our own...
 828 # if autoload -U url-quote-magic ; then
 829 #    zle -N self-insert url-quote-magic
 830 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 831 # else
 832 #    print 'Notice: no url-quote-magic available :('
 833 # fi
 834 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 835
 836 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 837 alias run-help >&/dev/null && unalias run-help
 838 zrcautoload run-help # use via 'esc-h'
 839
 840 # completion system
 841 if zrcautoload compinit && compinit 2>/dev/null ; then
 842     compinit 2>/dev/null || print 'Notice: no compinit available :('
 843 else
 844     print 'Notice: no compinit available :('
 845     function zstyle { }
 846     function compdef { }
 847 fi
 848
 849 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 850
 851 is4 && \
 852 for mod in complist deltochar mathfunc ; do
 853     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 854 done
 855
 856 # autoload zsh modules when they are referenced
 857 if is4 ; then
 858     tmpargs=(
 859         a   stat
 860         a   zpty
 861         ap  mapfile
 862     )
 863
 864     while (( ${#tmpargs} > 0 )) ; do
 865         zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
 866         shift 2 tmpargs
 867     done
 868     unset tmpargs
 869 fi
 870
 871 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 872     #k# Insert files
 873     bindkey "^Xf" insert-files # C-x-f
 874 fi
 875
 876 bindkey ' '   magic-space    # also do history expansion on space
 877 #k# Trigger menu-complete
 878 bindkey '\ei' menu-complete  # menu completion via esc-i
 879
 880 # press esc-e for editing command line in $EDITOR or $VISUAL
 881 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 882     #k# Edit the current line in \kbd{\$EDITOR}
 883     bindkey '\ee' edit-command-line
 884 fi
 885
 886 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 887     #k# menu selection: pick item but stay in the menu
 888     bindkey -M menuselect '\e^M' accept-and-menu-complete
 889
 890     # accept a completion and try to complete again by using menu
 891     # completion; very useful with completing directories
 892     # by using 'undo' one's got a simple file browser
 893     bindkey -M menuselect '^o' accept-and-infer-next-history
 894 fi
 895
 896 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 897 _bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
 898 zle -N _bkdate
 899
 900 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 901 bindkey '^Ed' _bkdate
 902
 903 # press esc-m for inserting last typed word again (thanks to caphuso!)
 904 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 905 zle -N insert-last-typed-word;
 906
 907 #k# Insert last typed word
 908 bindkey "\em" insert-last-typed-word
 909
 910 #k# Shortcut for \kbd{fg<enter>}
 911 bindkey -s '^z' "fg\n"
 912
 913 # run command line as user root via sudo:
 914 sudo-command-line() {
 915     [[ -z $BUFFER ]] && zle up-history
 916     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
 917 }
 918 zle -N sudo-command-line
 919
 920 #k# Put the current command line into a \kbd{sudo} call
 921 bindkey "^Os" sudo-command-line
 922
 923 ### jump behind the first word on the cmdline.
 924 ### useful to add options.
 925 function jump_after_first_word() {
 926     local words
 927     words=(${(z)BUFFER})
 928
 929     if (( ${#words} <= 1 )) ; then
 930         CURSOR=${#BUFFER}
 931     else
 932         CURSOR=${#${words[1]}}
 933     fi
 934 }
 935 zle -N jump_after_first_word
 936
 937 bindkey '^x1' jump_after_first_word
 938
 939 # }}}
 940
 941 # {{{ set some important options
 942 # Please update these tags, if you change the umask settings below.
 943 #o# r_umask     002
 944 #o# r_umaskstr  rwxrwxr-x
 945 #o# umask       022
 946 #o# umaskstr    rwxr-xr-x
 947 (( EUID != 0 )) && umask 002 || umask 022
 948
 949 # history:
 950 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 951 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 952 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 953 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 954                             # list duplicates an older one, the older command is removed from the list
 955 setopt histignorespace      # remove command lines from the history list when
 956                             # the first character on the line is a space
 957 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 958                             # and the command is the name of a directory, perform the cd command to that directory
 959 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 960                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 961                             # -> searches for word not in compressed files
 962                             # don't forget to quote '^', '~' and '#'!
 963 setopt longlistjobs         # display PID when suspending processes as well
 964 setopt notify               # report the status of backgrounds jobs immediately
 965 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 966                             # the entire command path is hashed first.
 967 setopt completeinword       # not just at the end
 968 setopt nohup                # and don't kill them, either
 969 setopt auto_pushd           # make cd push the old directory onto the directory stack.
 970 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 971 setopt nobeep               # avoid "beep"ing
 972 setopt pushd_ignore_dups    # don't push the same dir twice.
 973 setopt noglobdots           # * shouldn't match dotfiles. ever.
 974
 975 MAILCHECK=30       # mailchecks
 976 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 977 watch=(notme root) # watch for everyone but me and root
 978
 979 # only slash should be considered as a word separator:
 980 slash-backward-kill-word() {
 981     local WORDCHARS="${WORDCHARS:s@/@}"
 982     # zle backward-word
 983     zle backward-kill-word
 984 }
 985 zle -N slash-backward-kill-word
 986
 987 #k# Kill everything in a word up to its last \kbd{/}
 988 bindkey '\ev' slash-backward-kill-word
 989
 990 # }}}
 991
 992 # {{{ history
 993
 994 ZSHDIR=$HOME/.zsh
 995
 996 #v#
 997 HISTFILE=$HOME/.zsh_history
 998 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
 999 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1000
1001 # }}}
1002
1003 # dirstack handling {{{
1004
1005 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1006 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1007
1008 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1009     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1010     # "cd -" won't work after login by just setting $OLDPWD, so
1011     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
1012 fi
1013
1014 chpwd() {
1015     if is42 ; then
1016         builtin print -l ${(u)dirstack} >! ${DIRSTACKFILE}
1017     else
1018         uprint dirstack >! ${DIRSTACKFILE}
1019     fi
1020 }
1021
1022 # }}}
1023
1024 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
1025 if [[ $BATTERY -gt 0 ]] ; then
1026     if ! check_com -c acpi ; then
1027         BATTERY=0
1028     fi
1029 fi
1030
1031 battery() {
1032 if [[ $BATTERY -gt 0 ]] ; then
1033     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1034     if [[ -z "$PERCENT" ]] ; then
1035         PERCENT='acpi not present'
1036     else
1037         if [[ "$PERCENT" -lt 20 ]] ; then
1038             PERCENT="warning: ${PERCENT}%%"
1039         else
1040             PERCENT="${PERCENT}%%"
1041         fi
1042     fi
1043 fi
1044 }
1045 # }}}
1046
1047 # set colors for use in prompts {{{
1048 if zrcautoload colors && colors 2>/dev/null ; then
1049     BLUE="%{${fg[blue]}%}"
1050     RED="%{${fg_bold[red]}%}"
1051     GREEN="%{${fg[green]}%}"
1052     CYAN="%{${fg[cyan]}%}"
1053     MAGENTA="%{${fg[magenta]}%}"
1054     YELLOW="%{${fg[yellow]}%}"
1055     WHITE="%{${fg[white]}%}"
1056     NO_COLOUR="%{${reset_color}%}"
1057 else
1058     BLUE=$'%{\e[1;34m%}'
1059     RED=$'%{\e[1;31m%}'
1060     GREEN=$'%{\e[1;32m%}'
1061     CYAN=$'%{\e[1;36m%}'
1062     WHITE=$'%{\e[1;37m%}'
1063     MAGENTA=$'%{\e[1;35m%}'
1064     YELLOW=$'%{\e[1;33m%}'
1065     NO_COLOUR=$'%{\e[0m%}'
1066 fi
1067
1068 # }}}
1069
1070 # gather version control information for inclusion in a prompt {{{
1071
1072 if ! is41 ; then
1073     # Be quiet about version problems in grml's zshrc as the user cannot disable
1074     # loading vcs_info() as it is *in* the zshrc - as you can see. :-)
1075     # Just unset most probable variables and disable vcs_info altogether.
1076     local -i i
1077     for i in {0..9} ; do
1078         unset VCS_INFO_message_${i}_
1079     done
1080     zstyle ':vcs_info:*' enable false
1081 fi
1082
1083 # The following code is imported from the file 'zsh/functions/vcs_info'
1084 # from <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>,
1085 # which distributed under the same terms as zsh itself.
1086
1087 # we will be using two variables, so let the code know now.
1088 zstyle ':vcs_info:*' max-exports 2
1089
1090 # vcs_info() documentation:
1091 #{{{
1092 # REQUIREMENTS:
1093 #{{{
1094 #     This functionality requires zsh version >= 4.1.*.
1095 #}}}
1096 #
1097 # LOADING:
1098 #{{{
1099 # To load vcs_info(), copy this file to your $fpath[] and do:
1100 #   % autoload -Uz vcs_info && vcs_info
1101 #
1102 # To work, vcs_info() needs 'setopt prompt_subst' in your setup.
1103 #}}}
1104 #
1105 # QUICKSTART:
1106 #{{{
1107 # To get vcs_info() working quickly (including colors), you can do the
1108 # following (assuming, you loaded vcs_info() properly - see above):
1109 #
1110 # % RED=$'%{\e[31m%}'
1111 # % GR=$'%{\e[32m%}'
1112 # % MA=$'%{\e[35m%}'
1113 # % YE=$'%{\e[33m%}'
1114 # % NC=$'%{\e[0m%}'
1115 #
1116 # % zstyle ':vcs_info:*' actionformats \
1117 #       "${MA}(${NC}%s${MA})${YE}-${MA}[${GR}%b${YE}|${RED}%a${MA}]${NC} "
1118 #
1119 # % zstyle ':vcs_info:*' formats       \
1120 #       "${MA}(${NC}%s${MA})${Y}-${MA}[${GR}%b${MA}]${NC}%} "
1121 #
1122 # % zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YE}%r"
1123 #
1124 # % precmd () { vcs_info }
1125 # % PS1='${MA}[${GR}%n${MA}] ${MA}(${RED}%!${MA}) ${YE}%3~ ${VCS_INFO_message_0_}${NC}%# '
1126 #
1127 # Obviously, the las two lines are there for demonstration: You need to
1128 # call vcs_info() from your precmd() function (see 'SPECIAL FUNCTIONS' in
1129 # 'man zshmisc'). Once that is done you need a *single* quoted
1130 # '${VCS_INFO_message_0_}' in your prompt.
1131 #
1132 # Now call the 'vcs_info_printsys' utility from the command line:
1133 #
1134 # % vcs_info_printsys
1135 # # list of supported version control backends:
1136 # # disabled systems are prefixed by a hash sign (#)
1137 # git
1138 # hg
1139 # bzr
1140 # darcs
1141 # svk
1142 # mtn
1143 # svn
1144 # cvs
1145 # cdv
1146 # tla
1147 # # flavours (cannot be used in the disable style; they
1148 # # are disabled with their master [git-svn -> git]):
1149 # git-p4
1150 # git-svn
1151 #
1152 # Ten version control backends as you can see. You may not want all
1153 # of these. Because there is no point in running the code to detect
1154 # systems you do not use. ever. So, there is a way to disable some
1155 # backends altogether:
1156 #
1157 # % zstyle ':vcs_info:*' disable bzr cdv darcs mtn svk tla
1158 #
1159 # If you rerun 'vcs_info_printsys' now, you will see the backends listed
1160 # in the 'disable' style marked as diabled by a hash sign. That means the
1161 # detection of these systems is skipped *completely*. No wasted time there.
1162 #
1163 # For more control, read the reference below.
1164 #}}}
1165 #
1166 # CONFIGURATION:
1167 #{{{
1168 # The vcs_info() feature can be configured via zstyle.
1169 #
1170 # First, the context in which we are working:
1171 #       :vcs_info:<vcs-string>:<user-context>
1172 #
1173 # ...where <vcs-string> is one of:
1174 #   - git, git-svn, git-p4, hg, darcs, bzr, cdv, mtn, svn, cvs, svk or tla.
1175 #
1176 # ...and <user-context> is a freely configurable string, assignable by the
1177 # user as the first argument to vcs_info() (see its description below).
1178 #
1179 # There is are three special values for <vcs-string>: The first is named
1180 # 'init', that is in effect as long as there was no decision what vcs
1181 # backend to use. The second is 'preinit; it is used *before* vcs_info()
1182 # is run, when initializing the data exporting variables. The third
1183 # special value is 'formats' and is used by the 'vcs_info_lastmsg' for
1184 # looking up its styles.
1185 #
1186 # There are two pre-defined values for <user-context>:
1187 #   default  - the one used if none is specified
1188 #   command  - used by vcs_info_lastmsg to lookup its styles.
1189 #
1190 # You may *not* use 'print_systems_' as a user-context string, because it
1191 # is used internally.
1192 #
1193 # You can of course use ':vcs_info:*' to match all VCSs in all
1194 # user-contexts at once.
1195 #
1196 # Another special context is 'formats', which is used by the
1197 # vcs_info_lastmsg() utility function (see below).
1198 #
1199 #
1200 # This is a description of all styles, that are looked up:
1201 #   formats             - A list of formats, used when actionformats is not
1202 #                         used (which is most of the time).
1203 #   actionformats       - A list of formats, used if a there is a special
1204 #                         action going on in your current repository;
1205 #                         (like an interactive rebase or a merge conflict)
1206 #   branchformat        - Some backends replace %b in the formats and
1207 #                         actionformats styles above, not only by a branch
1208 #                         name but also by a revision number. This style
1209 #                         let's you modify how that string should look like.
1210 #   nvcsformats         - These "formats" are exported, when we didn't detect
1211 #                         a version control system for the current directory.
1212 #                         This is useful, if you want vcs_info() to completely
1213 #                         take over the generation of your prompt.
1214 #                         You would do something like
1215 #                           PS1='${VCS_INFO_message_0_}'
1216 #                         to accomplish that.
1217 #   max-exports         - Defines the maximum number if VCS_INFO_message_*_
1218 #                         variables vcs_info() will export.
1219 #   enable              - Checked in the 'init' context. If set to false,
1220 #                         vcs_info() will do nothing.
1221 #   disable             - Provide a list of systems, you don't want
1222 #                         the vcs_info() to check for repositories
1223 #                         (checked in the 'init' context, too).
1224 #   disable-patterns    - A list of patterns that are checked against $PWD.
1225 #                         If the pattern matches, vcs_info will be disabled.
1226 #                         Say, ~/.zsh is a directory under version control,
1227 #                         in which you do not want vcs_info to be active, do:
1228 #                         zstyle ':vcs_info:*' disable-patterns "$HOME/.zsh+(|/*)"
1229 #   use-simple          - If there are two different ways of gathering
1230 #                         information, you can select the simpler one
1231 #                         by setting this style to true; the default
1232 #                         is to use the not-that-simple code, which is
1233 #                         potentially a lot slower but might be more
1234 #                         accurate in all possible cases.
1235 #   use-prompt-escapes  - determines if we assume that the assembled
1236 #                         string from vcs_info() includes prompt escapes.
1237 #                         (Used by vcs_info_lastmsg().
1238 #
1239 # The use-simple style is only available for the bzr backend.
1240 #
1241 # The default values for these in all contexts are:
1242 #   formats             " (%s)-[%b|%a]-"
1243 #   actionformats       " (%s)-[%b]-"
1244 #   branchformat        "%b:%r" (for bzr, svn and svk)
1245 #   nvcsformats         ""
1246 #   max-exports         2
1247 #   enable              true
1248 #   disable             (empty list)
1249 #   disable-patterns    (empty list)
1250 #   use-simple          false
1251 #   use-prompt-escapes  true
1252 #
1253 #
1254 # In normal formats and actionformats, the following replacements
1255 # are done:
1256 #   %s  - The vcs in use (git, hg, svn etc.)
1257 #   %b  - Information about the current branch.
1258 #   %a  - An identifier, that describes the action.
1259 #         Only makes sense in actionformats.
1260 #   %R  - base directory of the repository.
1261 #   %r  - repository name
1262 #         If %R is '/foo/bar/repoXY', %r is 'repoXY'.
1263 #   %S  - subdirectory within a repository. if $PWD is
1264 #         '/foo/bar/reposXY/beer/tasty', %S is 'beer/tasty'.
1265 #
1266 #
1267 # In branchformat these replacements are done:
1268 #   %b  - the branch name
1269 #   %r  - the current revision number
1270 #
1271 # Not all vcs backends have to support all replacements.
1272 # nvcsformat does not perform *any* replacements. It is just a string.
1273 #}}}
1274 #
1275 # ODDITIES:
1276 #{{{
1277 # If you want to use the %b (bold off) prompt expansion in 'formats', which
1278 # expands %b itself, use %%b. That will cause the vcs_info() expansion to
1279 # replace %%b with %b. So zsh's prompt expansion mechanism can handle it.
1280 # Similarly, to hand down %b from branchformat, use %%%%b. Sorry for this
1281 # inconvenience, but it cannot be easily avoided. Luckily we do not clash
1282 # with a lot of prompt expansions and this only needs to be done for those.
1283 # See 'man zshmisc' for details about EXPANSION OF PROMPT SEQUENCES.
1284 #}}}
1285 #
1286 # FUNCTION DESCRIPTIONS (public API):
1287 #{{{
1288 #   vcs_info()
1289 #       The main function, that runs all backends and assembles
1290 #       all data into ${VCS_INFO_message_*_}. This is the function
1291 #       you want to call from precmd() if you want to include
1292 #       up-to-date information in your prompt (see VARIABLE
1293 #       DESCRIPTION below).
1294 #
1295 #   vcs_info_printsys()
1296 #       Prints a list of all supported version control systems.
1297 #       Useful to find out possible contexts (and which of them are enabled)
1298 #       or values for the 'disable' style.
1299 #
1300 #   vcs_info_lastmsg()
1301 #       Outputs the last ${VCS_INFO_message_*_} value. Takes into account
1302 #       the value of the use-prompt-escapes style in ':vcs_info:formats'.
1303 #       It also only prints max-exports values.
1304 #
1305 # All functions named VCS_INFO_* are for internal use only.
1306 #}}}
1307 #
1308 # VARIABLE DESCRIPTION:
1309 #{{{
1310 #   ${VCS_INFO_message_N_}    (Note the trailing underscore)
1311 #       Where 'N' is an integer, eg: VCS_INFO_message_0_
1312 #       These variables are the storage for the informational message the
1313 #       last vcs_info() call has assembled. These are strongly connected
1314 #       to the formats, actionformats and nvcsformats styles described
1315 #       above. Those styles are lists. the first member of that list gets
1316 #       expanded into ${VCS_INFO_message_0_}, the second into
1317 #       ${VCS_INFO_message_1_} and the Nth into ${VCS_INFO_message_N-1_}.
1318 #       These parameters are exported into the environment.
1319 #       (See the max-exports style above.)
1320 #}}}
1321 #
1322 # EXAMPLES:
1323 #{{{
1324 #   Don't use vcs_info at all (even though it's in your prompt):
1325 #   % zstyle ':vcs_info:*' enable false
1326 #
1327 #   Disable the backends for bzr and svk:
1328 #   % zstyle ':vcs_info:*' disable bzr svk
1329 #
1330 #   Provide a special formats for git:
1331 #   % zstyle ':vcs_info:git:*' formats       ' GIT, BABY! [%b]'
1332 #   % zstyle ':vcs_info:git:*' actionformats ' GIT ACTION! [%b|%a]'
1333 #
1334 #   Use the quicker bzr backend (if you do, please report if it does
1335 #   the-right-thing[tm] - thanks):
1336 #   % zstyle ':vcs_info:bzr:*' use-simple true
1337 #
1338 #   Display the revision number in yellow for bzr and svn:
1339 #   % zstyle ':vcs_info:(svn|bzr):*' branchformat '%b%{'${fg[yellow]}'%}:%r'
1340 #
1341 # If you want colors, make sure you enclose the color codes in %{...%},
1342 # if you want to use the string provided by vcs_info() in prompts.
1343 #
1344 # Here is how to print the vcs infomation as a command:
1345 #   % alias vcsi='vcs_info command; vcs_info_lastmsg'
1346 #
1347 #   This way, you can even define different formats for output via
1348 #   vcs_info_lastmsg() in the ':vcs_info:command:*' namespace.
1349 #}}}
1350 #}}}
1351 # utilities
1352 VCS_INFO_adjust () { #{{{
1353     [[ -n ${vcs_comm[overwrite_name]} ]] && vcs=${vcs_comm[overwrite_name]}
1354     return 0
1355 }
1356 # }}}
1357 VCS_INFO_check_com () { #{{{
1358     (( ${+commands[$1]} )) && [[ -x ${commands[$1]} ]] && return 0
1359     return 1
1360 }
1361 # }}}
1362 VCS_INFO_formats () { # {{{
1363     setopt localoptions noksharrays
1364     local action=$1 branch=$2 base=$3
1365     local msg
1366     local -i i
1367
1368     if [[ -n ${action} ]] ; then
1369         zstyle -a ":vcs_info:${vcs}:${usercontext}" actionformats msgs
1370         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b|%a]-'
1371     else
1372         zstyle -a ":vcs_info:${vcs}:${usercontext}" formats msgs
1373         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b]-'
1374     fi
1375
1376     (( ${#msgs} > maxexports )) && msgs[$(( maxexports + 1 )),-1]=()
1377     for i in {1..${#msgs}} ; do
1378         zformat -f msg ${msgs[$i]}                      \
1379                         a:${action}                     \
1380                         b:${branch}                     \
1381                         r:${base:t}                     \
1382                         s:${vcs}                        \
1383                         R:${base}                       \
1384                         S:"$(VCS_INFO_reposub ${base})"
1385         msgs[$i]=${msg}
1386     done
1387     return 0
1388 }
1389 # }}}
1390 VCS_INFO_maxexports () { #{{{
1391     zstyle -s ":vcs_info:${vcs}:${usercontext}" "max-exports" maxexports || maxexports=2
1392     if [[ ${maxexports} != <-> ]] || (( maxexports < 1 )); then
1393         printf 'vcs_info(): expecting numeric arg >= 1 for max-exports (got %s).\n' ${maxexports}
1394         printf 'Defaulting to 2.\n'
1395         maxexports=2
1396     fi
1397 }
1398 # }}}
1399 VCS_INFO_nvcsformats () { #{{{
1400     setopt localoptions noksharrays
1401     local c v
1402
1403     if [[ $1 == 'preinit' ]] ; then
1404         c=default
1405         v=preinit
1406     fi
1407     zstyle -a ":vcs_info:${v:-$vcs}:${c:-$usercontext}" nvcsformats msgs
1408     (( ${#msgs} > maxexports )) && msgs[${maxexports},-1]=()
1409 }
1410 # }}}
1411 VCS_INFO_realpath () { #{{{
1412     # a portable 'readlink -f'
1413     # forcing a subshell, to ensure chpwd() is not removed
1414     # from the calling shell (if VCS_INFO_realpath() is called
1415     # manually).
1416     (
1417         (( ${+functions[chpwd]} )) && unfunction chpwd
1418         setopt chaselinks
1419         cd $1 2>/dev/null && pwd
1420     )
1421 }
1422 # }}}
1423 VCS_INFO_reposub () { #{{{
1424     setopt localoptions extendedglob
1425     local base=${1%%/##}
1426
1427     [[ ${PWD} == ${base}/* ]] || {
1428         printf '.'
1429         return 1
1430     }
1431     printf '%s' ${PWD#$base/}
1432     return 0
1433 }
1434 # }}}
1435 VCS_INFO_set () { #{{{
1436     setopt localoptions noksharrays
1437     local -i i j
1438
1439     if [[ $1 == '--clear' ]] ; then
1440         for i in {0..9} ; do
1441             unset VCS_INFO_message_${i}_
1442         done
1443     fi
1444     if [[ $1 == '--nvcs' ]] ; then
1445         [[ $2 == 'preinit' ]] && (( maxexports == 0 )) && (( maxexports = 1 ))
1446         for i in {0..$((maxexports - 1))} ; do
1447             typeset -gx VCS_INFO_message_${i}_=
1448         done
1449         VCS_INFO_nvcsformats $2
1450     fi
1451
1452     (( ${#msgs} - 1 < 0 )) && return 0
1453     for i in {0..$(( ${#msgs} - 1 ))} ; do
1454         (( j = i + 1 ))
1455         typeset -gx VCS_INFO_message_${i}_=${msgs[$j]}
1456     done
1457     return 0
1458 }
1459 # }}}
1460 # information gathering
1461 VCS_INFO_bzr_get_data () { # {{{
1462     setopt localoptions noksharrays
1463     local bzrbase bzrbr
1464     local -a bzrinfo
1465
1466     if zstyle -t ":vcs_info:${vcs}:${usercontext}" "use-simple" ; then
1467         bzrbase=${vcs_comm[basedir]}
1468         bzrinfo[2]=${bzrbase:t}
1469         if [[ -f ${bzrbase}/.bzr/branch/last-revision ]] ; then
1470             bzrinfo[1]=$(< ${bzrbase}/.bzr/branch/last-revision)
1471             bzrinfo[1]=${${bzrinfo[1]}%% *}
1472         fi
1473     else
1474         bzrbase=${${(M)${(f)"$( bzr info )"}:# ##branch\ root:*}/*: ##/}
1475         bzrinfo=( ${${${(M)${(f)"$( bzr version-info )"}:#(#s)(revno|branch-nick)*}/*: /}/*\//} )
1476         bzrbase="$(VCS_INFO_realpath ${bzrbase})"
1477     fi
1478
1479     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat bzrbr || bzrbr="%b:%r"
1480     zformat -f bzrbr "${bzrbr}" "b:${bzrinfo[2]}" "r:${bzrinfo[1]}"
1481     VCS_INFO_formats '' "${bzrbr}" "${bzrbase}"
1482     return 0
1483 }
1484 # }}}
1485 VCS_INFO_cdv_get_data () { # {{{
1486     local cdvbase
1487
1488     cdvbase=${vcs_comm[basedir]}
1489     VCS_INFO_formats '' "${cdvbase:t}" "${cdvbase}"
1490     return 0
1491 }
1492 # }}}
1493 VCS_INFO_cvs_get_data () { # {{{
1494     local cvsbranch cvsbase basename
1495
1496     cvsbase="."
1497     while [[ -d "${cvsbase}/../CVS" ]]; do
1498         cvsbase="${cvsbase}/.."
1499     done
1500     cvsbase="$(VCS_INFO_realpath ${cvsbase})"
1501     cvsbranch=$(< ./CVS/Repository)
1502     basename=${cvsbase:t}
1503     cvsbranch=${cvsbranch##${basename}/}
1504     [[ -z ${cvsbranch} ]] && cvsbranch=${basename}
1505     VCS_INFO_formats '' "${cvsbranch}" "${cvsbase}"
1506     return 0
1507 }
1508 # }}}
1509 VCS_INFO_darcs_get_data () { # {{{
1510     local darcsbase
1511
1512     darcsbase=${vcs_comm[basedir]}
1513     VCS_INFO_formats '' "${darcsbase:t}" "${darcsbase}"
1514     return 0
1515 }
1516 # }}}
1517 VCS_INFO_git_getaction () { #{{{
1518     local gitaction='' gitdir=$1
1519     local tmp
1520
1521     for tmp in "${gitdir}/rebase-apply" \
1522                "${gitdir}/rebase"       \
1523                "${gitdir}/../.dotest" ; do
1524         if [[ -d ${tmp} ]] ; then
1525             if   [[ -f "${tmp}/rebasing" ]] ; then
1526                 gitaction="rebase"
1527             elif [[ -f "${tmp}/applying" ]] ; then
1528                 gitaction="am"
1529             else
1530                 gitaction="am/rebase"
1531             fi
1532             printf '%s' ${gitaction}
1533             return 0
1534         fi
1535     done
1536
1537     for tmp in "${gitdir}/rebase-merge/interactive" \
1538                "${gitdir}/.dotest-merge/interactive" ; do
1539         if [[ -f "${tmp}" ]] ; then
1540             printf '%s' "rebase-i"
1541             return 0
1542         fi
1543     done
1544
1545     for tmp in "${gitdir}/rebase-merge" \
1546                "${gitdir}/.dotest-merge" ; do
1547         if [[ -d "${tmp}" ]] ; then
1548             printf '%s' "rebase-m"
1549             return 0
1550         fi
1551     done
1552
1553     if [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1554         printf '%s' "merge"
1555         return 0
1556     fi
1557
1558     if [[ -f "${gitdir}/BISECT_LOG" ]] ; then
1559         printf '%s' "bisect"
1560         return 0
1561     fi
1562     return 1
1563 }
1564 # }}}
1565 VCS_INFO_git_getbranch () { #{{{
1566     local gitbranch gitdir=$1
1567     local gitsymref='git symbolic-ref HEAD'
1568
1569     if    [[ -d "${gitdir}/rebase-apply" ]] \
1570        || [[ -d "${gitdir}/rebase" ]]       \
1571        || [[ -d "${gitdir}/../.dotest" ]]   \
1572        || [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1573         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1574         [[ -z ${gitbranch} ]] && [[ -r ${gitdir}/rebase-apply/head-name ]] \
1575             && gitbranch="$(< ${gitdir}/rebase-apply/head-name)"
1576
1577     elif   [[ -f "${gitdir}/rebase-merge/interactive" ]] \
1578         || [[ -d "${gitdir}/rebase-merge" ]] ; then
1579         gitbranch="$(< ${gitdir}/rebase-merge/head-name)"
1580
1581     elif   [[ -f "${gitdir}/.dotest-merge/interactive" ]] \
1582         || [[ -d "${gitdir}/.dotest-merge" ]] ; then
1583         gitbranch="$(< ${gitdir}/.dotest-merge/head-name)"
1584
1585     else
1586         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1587
1588         if [[ $? -ne 0 ]] ; then
1589             gitbranch="$(git describe --exact-match HEAD 2>/dev/null)"
1590
1591             if [[ $? -ne 0 ]] ; then
1592                 gitbranch="${${"$(< $gitdir/HEAD)"}[1,7]}..."
1593             fi
1594         fi
1595     fi
1596
1597     printf '%s' "${gitbranch##refs/heads/}"
1598     return 0
1599 }
1600 # }}}
1601 VCS_INFO_git_get_data () { # {{{
1602     setopt localoptions extendedglob
1603     local gitdir gitbase gitbranch gitaction
1604
1605     gitdir=${vcs_comm[gitdir]}
1606     gitbranch="$(VCS_INFO_git_getbranch ${gitdir})"
1607
1608     if [[ -z ${gitdir} ]] || [[ -z ${gitbranch} ]] ; then
1609         return 1
1610     fi
1611
1612     VCS_INFO_adjust
1613     gitaction="$(VCS_INFO_git_getaction ${gitdir})"
1614     gitbase=${PWD%/${$( git rev-parse --show-prefix )%/##}}
1615     VCS_INFO_formats "${gitaction}" "${gitbranch}" "${gitbase}"
1616     return 0
1617 }
1618 # }}}
1619 VCS_INFO_hg_get_data () { # {{{
1620     local hgbranch hgbase
1621
1622     hgbase=${vcs_comm[basedir]}
1623     hgbranch=$(< ${hgbase}/.hg/branch)
1624     VCS_INFO_formats '' "${hgbranch}" "${hgbase}"
1625     return 0
1626 }
1627 # }}}
1628 VCS_INFO_mtn_get_data () { # {{{
1629     local mtnbranch mtnbase
1630
1631     mtnbase=${vcs_comm[basedir]}
1632     mtnbranch=${${(M)${(f)"$( mtn status )"}:#(#s)Current branch:*}/*: /}
1633     VCS_INFO_formats '' "${mtnbranch}" "${mtnbase}"
1634     return 0
1635 }
1636 # }}}
1637 VCS_INFO_svk_get_data () { # {{{
1638     local svkbranch svkbase
1639
1640     svkbase=${vcs_comm[basedir]}
1641     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svkbranch || svkbranch="%b:%r"
1642     zformat -f svkbranch "${svkbranch}" "b:${vcs_comm[branch]}" "r:${vcs_comm[revision]}"
1643     VCS_INFO_formats '' "${svkbranch}" "${svkbase}"
1644     return 0
1645 }
1646 # }}}
1647 VCS_INFO_svn_get_data () { # {{{
1648     setopt localoptions noksharrays
1649     local svnbase svnbranch
1650     local -a svninfo
1651
1652     svnbase="."
1653     while [[ -d "${svnbase}/../.svn" ]]; do
1654         svnbase="${svnbase}/.."
1655     done
1656     svnbase="$(VCS_INFO_realpath ${svnbase})"
1657     svninfo=( ${${${(M)${(f)"$( svn info )"}:#(#s)(URL|Revision)*}/*: /}/*\//} )
1658
1659     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svnbranch || svnbranch="%b:%r"
1660     zformat -f svnbranch "${svnbranch}" "b:${svninfo[1]}" "r:${svninfo[2]}"
1661     VCS_INFO_formats '' "${svnbranch}" "${svnbase}"
1662     return 0
1663 }
1664 # }}}
1665 VCS_INFO_tla_get_data () { # {{{
1666     local tlabase tlabranch
1667
1668     tlabase="$(VCS_INFO_realpath ${vcs_comm[basedir]})"
1669     # tree-id gives us something like 'foo@example.com/demo--1.0--patch-4', so:
1670     tlabranch=${${"$( tla tree-id )"}/*\//}
1671     VCS_INFO_formats '' "${tlabranch}" "${tlabase}"
1672     return 0
1673 }
1674 # }}}
1675 # detection
1676 VCS_INFO_detect_by_dir() { #{{{
1677     local dirname=$1
1678     local basedir="." realbasedir
1679
1680     realbasedir="$(VCS_INFO_realpath ${basedir})"
1681     while [[ ${realbasedir} != '/' ]]; do
1682         if [[ -n ${vcs_comm[detect_need_file]} ]] ; then
1683             [[ -d ${basedir}/${dirname} ]] && \
1684             [[ -f ${basedir}/${dirname}/${vcs_comm[detect_need_file]} ]] && \
1685                 break
1686         else
1687             [[ -d ${basedir}/${dirname} ]] && break
1688         fi
1689
1690         basedir=${basedir}/..
1691         realbasedir="$(VCS_INFO_realpath ${basedir})"
1692     done
1693
1694     [[ ${realbasedir} == "/" ]] && return 1
1695     vcs_comm[basedir]=${realbasedir}
1696     return 0
1697 }
1698 # }}}
1699 VCS_INFO_bzr_detect() { #{{{
1700     VCS_INFO_check_com bzr || return 1
1701     vcs_comm[detect_need_file]=branch/format
1702     VCS_INFO_detect_by_dir '.bzr'
1703     return $?
1704 }
1705 # }}}
1706 VCS_INFO_cdv_detect() { #{{{
1707     VCS_INFO_check_com cdv || return 1
1708     vcs_comm[detect_need_file]=format
1709     VCS_INFO_detect_by_dir '.cdv'
1710     return $?
1711 }
1712 # }}}
1713 VCS_INFO_cvs_detect() { #{{{
1714     VCS_INFO_check_com svn || return 1
1715     [[ -d "./CVS" ]] && [[ -r "./CVS/Repository" ]] && return 0
1716     return 1
1717 }
1718 # }}}
1719 VCS_INFO_darcs_detect() { #{{{
1720     VCS_INFO_check_com darcs || return 1
1721     vcs_comm[detect_need_file]=format
1722     VCS_INFO_detect_by_dir '_darcs'
1723     return $?
1724 }
1725 # }}}
1726 VCS_INFO_git_detect() { #{{{
1727     if VCS_INFO_check_com git && git rev-parse --is-inside-work-tree &> /dev/null ; then
1728         vcs_comm[gitdir]="$(git rev-parse --git-dir 2> /dev/null)" || return 1
1729         if   [[ -d ${vcs_comm[gitdir]}/svn ]]             ; then vcs_comm[overwrite_name]='git-svn'
1730         elif [[ -d ${vcs_comm[gitdir]}/refs/remotes/p4 ]] ; then vcs_comm[overwrite_name]='git-p4' ; fi
1731         return 0
1732     fi
1733     return 1
1734 }
1735 # }}}
1736 VCS_INFO_hg_detect() { #{{{
1737     VCS_INFO_check_com hg || return 1
1738     vcs_comm[detect_need_file]=branch
1739     VCS_INFO_detect_by_dir '.hg'
1740     return $?
1741 }
1742 # }}}
1743 VCS_INFO_mtn_detect() { #{{{
1744     VCS_INFO_check_com mtn || return 1
1745     vcs_comm[detect_need_file]=revision
1746     VCS_INFO_detect_by_dir '_MTN'
1747     return $?
1748 }
1749 # }}}
1750 VCS_INFO_svk_detect() { #{{{
1751     setopt localoptions noksharrays extendedglob
1752     local -a info
1753     local -i fhash
1754     fhash=0
1755
1756     VCS_INFO_check_com svk || return 1
1757     [[ -f ~/.svk/config ]] || return 1
1758
1759     # This detection function is a bit different from the others.
1760     # We need to read svk's config file to detect a svk repository
1761     # in the first place. Therefore, we'll just proceed and read
1762     # the other information, too. This is more then any of the
1763     # other detections do but this takes only one file open for
1764     # svk at most. VCS_INFO_svk_get_data() get simpler, too. :-)
1765     while IFS= read -r line ; do
1766         if [[ -n ${vcs_comm[basedir]} ]] ; then
1767             line=${line## ##}
1768             [[ ${line} == depotpath:* ]] && vcs_comm[branch]=${line##*/}
1769             [[ ${line} == revision:* ]] && vcs_comm[revision]=${line##*[[:space:]]##}
1770             [[ -n ${vcs_comm[branch]} ]] && [[ -n ${vcs_comm[revision]} ]] && break
1771             continue
1772         fi
1773         (( fhash > 0 )) && [[ ${line} == '  '[^[:space:]]*:* ]] && break
1774         [[ ${line} == '  hash:'* ]] && fhash=1 && continue
1775         (( fhash == 0 )) && continue
1776         [[ ${PWD}/ == ${${line## ##}%:*}/* ]] && vcs_comm[basedir]=${${line## ##}%:*}
1777     done < ~/.svk/config
1778
1779     [[ -n ${vcs_comm[basedir]} ]]  && \
1780     [[ -n ${vcs_comm[branch]} ]]   && \
1781     [[ -n ${vcs_comm[revision]} ]] && return 0
1782     return 1
1783 }
1784 # }}}
1785 VCS_INFO_svn_detect() { #{{{
1786     VCS_INFO_check_com svn || return 1
1787     [[ -d ".svn" ]] && return 0
1788     return 1
1789 }
1790 # }}}
1791 VCS_INFO_tla_detect() { #{{{
1792     VCS_INFO_check_com tla || return 1
1793     vcs_comm[basedir]="$(tla tree-root 2> /dev/null)" && return 0
1794     return 1
1795 }
1796 # }}}
1797 # public API
1798 vcs_info_printsys () { # {{{
1799     vcs_info print_systems_
1800 }
1801 # }}}
1802 vcs_info_lastmsg () { # {{{
1803     local -i i
1804
1805     VCS_INFO_maxexports
1806     for i in {0..$((maxexports - 1))} ; do
1807         printf '$VCS_INFO_message_%d_: "' $i
1808         if zstyle -T ':vcs_info:formats:command' use-prompt-escapes ; then
1809             print -nP ${(P)${:-VCS_INFO_message_${i}_}}
1810         else
1811             print -n ${(P)${:-VCS_INFO_message_${i}_}}
1812         fi
1813         printf '"\n'
1814     done
1815 }
1816 # }}}
1817 vcs_info () { # {{{
1818     local pat
1819     local -i found
1820     local -a VCSs disabled dps
1821     local -x vcs usercontext
1822     local -ix maxexports
1823     local -ax msgs
1824     local -Ax vcs_comm
1825
1826     vcs="init"
1827     VCSs=(git hg bzr darcs svk mtn svn cvs cdv tla)
1828     case $1 in
1829         (print_systems_)
1830             zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1831             print -l '# list of supported version control backends:' \
1832                      '# disabled systems are prefixed by a hash sign (#)'
1833             for vcs in ${VCSs} ; do
1834                 [[ -n ${(M)disabled:#${vcs}} ]] && printf '#'
1835                 printf '%s\n' ${vcs}
1836             done
1837             print -l '# flavours (cannot be used in the disable style; they' \
1838                      '# are disabled with their master [git-svn -> git]):'   \
1839                      git-{p4,svn}
1840             return 0
1841             ;;
1842         ('')
1843             [[ -z ${usercontext} ]] && usercontext=default
1844             ;;
1845         (*) [[ -z ${usercontext} ]] && usercontext=$1
1846             ;;
1847     esac
1848
1849     zstyle -T ":vcs_info:${vcs}:${usercontext}" "enable" || {
1850         [[ -n ${VCS_INFO_message_0_} ]] && VCS_INFO_set --clear
1851         return 0
1852     }
1853     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1854
1855     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable-patterns" dps
1856     for pat in ${dps} ; do
1857         if [[ ${PWD} == ${~pat} ]] ; then
1858             [[ -n ${vcs_info_msg_0_} ]] && VCS_INFO_set --clear
1859             return 0
1860         fi
1861     done
1862
1863     VCS_INFO_maxexports
1864
1865     (( found = 0 ))
1866     for vcs in ${VCSs} ; do
1867         [[ -n ${(M)disabled:#${vcs}} ]] && continue
1868         vcs_comm=()
1869         VCS_INFO_${vcs}_detect && (( found = 1 )) && break
1870     done
1871
1872     (( found == 0 )) && {
1873         VCS_INFO_set --nvcs
1874         return 0
1875     }
1876
1877     VCS_INFO_${vcs}_get_data || {
1878         VCS_INFO_set --nvcs
1879         return 1
1880     }
1881
1882     VCS_INFO_set
1883     return 0
1884 }
1885
1886 VCS_INFO_set --nvcs preinit
1887 # }}}
1888
1889 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1890 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1891 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1892 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1893 #       to $vcs_info_msg_N_ as soon as we use the included version.
1894 if [[ "$TERM" == dumb ]] ; then
1895     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1896     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1897 else
1898     # these are the same, just with a lot of colours:
1899     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
1900                                        "zsh: %r"
1901     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
1902                                        "zsh: %r"
1903     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1904 fi
1905
1906 # }}}
1907
1908 # {{{ set prompt
1909 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1910     promptinit # people should be able to use their favourite prompt
1911 else
1912     print 'Notice: no promptinit available :('
1913 fi
1914
1915 setopt prompt_subst
1916
1917 # make sure to use right prompt only when not running a command
1918 is41 && setopt transient_rprompt
1919
1920 # TODO: revise all these NO* variables and especially their documentation
1921 #       in zsh-help() below.
1922 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1923     [[ $NOPRECMD -gt 0 ]] && return 0
1924     # update VCS information
1925     vcs_info
1926
1927     if [[ $TERM == screen* ]] ; then
1928         if [[ -n ${VCS_INFO_message_1_} ]] ; then
1929             print -nP "\ek${VCS_INFO_message_1_}\e\\"
1930         else
1931             print -nP "\ekzsh\e\\"
1932         fi
1933     fi
1934     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1935     if [[ $DONTSETRPROMPT -eq 0 ]] ; then
1936         if [[ $BATTERY -gt 0 ]] ; then
1937             # update battery (dropped into $PERCENT) information
1938             battery
1939             RPROMPT="%(?..:() ${PERCENT}"
1940         else
1941             RPROMPT="%(?..:() "
1942         fi
1943     fi
1944     # adjust title of xterm
1945     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1946     [[ ${NOTITLE} -gt 0 ]] && return 0
1947     case $TERM in
1948         (xterm*|rxvt*)
1949             print -Pn "\e]0;%n@%m: %~\a"
1950             ;;
1951     esac
1952 }
1953
1954 # preexec() => a function running before every command
1955 is4 && [[ $NOPRECMD -eq 0 ]] && \
1956 preexec () {
1957     [[ $NOPRECMD -gt 0 ]] && return 0
1958 # set hostname if not running on host with name 'grml'
1959     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1960        NAME="@$HOSTNAME"
1961     fi
1962 # get the name of the program currently running and hostname of local machine
1963 # set screen window title if running in a screen
1964     if [[ "$TERM" == screen* ]] ; then
1965         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1966         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1967         echo -ne "\ek$CMD\e\\"
1968     fi
1969 # adjust title of xterm
1970     [[ ${NOTITLE} -gt 0 ]] && return 0
1971     case $TERM in
1972         (xterm*|rxvt)
1973             print -Pn "\e]0;%n@%m: $1\a"
1974             ;;
1975     esac
1976 }
1977
1978 EXITCODE="%(?..%?%1v )"
1979 PS2='\`%_> '      # secondary prompt, printed when the shell needs more information to complete a command.
1980 PS3='?# '         # selection prompt used within a select loop.
1981 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1982
1983 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1984 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1985     debian_chroot=$(cat /etc/debian_chroot)
1986 fi
1987
1988 # don't use colors on dumb terminals (like emacs):
1989 if [[ "$TERM" == dumb ]] ; then
1990     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
1991 else
1992     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
1993     # set variable identifying the chroot you work in (used in the prompt below)
1994     if [[ $GRMLPROMPT -gt 0 ]] ; then
1995         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1996 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# "
1997     else
1998         # This assembles the primary prompt string
1999         if (( EUID != 0 )); then
2000             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2001         else
2002             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2003         fi
2004     fi
2005 fi
2006
2007 # if we are inside a grml-chroot set a specific prompt theme
2008 if [[ -n "$GRML_CHROOT" ]] ; then
2009     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
2010 fi
2011 # }}}
2012
2013 # {{{ 'hash' some often used directories
2014 #d# start
2015 hash -d deb=/var/cache/apt/archives
2016 hash -d doc=/usr/share/doc
2017 hash -d linux=/lib/modules/$(command uname -r)/build/
2018 hash -d log=/var/log
2019 hash -d slog=/var/log/syslog
2020 hash -d src=/usr/src
2021 hash -d templ=/usr/share/doc/grml-templates
2022 hash -d tt=/usr/share/doc/texttools-doc
2023 hash -d www=/var/www
2024 #d# end
2025 # }}}
2026
2027 # {{{ some aliases
2028 if check_com -c screen ; then
2029     if [[ $UID -eq 0 ]] ; then
2030         [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
2031     elif [[ -r $HOME/.screenrc ]] ; then
2032         alias screen="${commands[screen]} -c $HOME/.screenrc"
2033     else
2034         [[ -r /etc/grml/screenrc_grml ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
2035     fi
2036 fi
2037
2038 # do we have GNU ls with color-support?
2039 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
2040     #a1# execute \kbd{@a@}:\quad ls with colors
2041     alias ls='ls -b -CF --color=auto'
2042     #a1# execute \kbd{@a@}:\quad list all files, with colors
2043     alias la='ls -la --color=auto'
2044     #a1# long colored list, without dotfiles (@a@)
2045     alias ll='ls -l --color=auto'
2046     #a1# long colored list, human readable sizes (@a@)
2047     alias lh='ls -hAl --color=auto'
2048     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2049     alias l='ls -lF --color=auto'
2050 else
2051     alias ls='ls -b -CF'
2052     alias la='ls -la'
2053     alias ll='ls -l'
2054     alias lh='ls -hAl'
2055     alias l='ls -lF'
2056 fi
2057
2058 alias mdstat='cat /proc/mdstat'
2059 alias ...='cd ../../'
2060
2061 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2062 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2063     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2064 fi
2065
2066 alias cp='nocorrect cp'         # no spelling correction on cp
2067 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
2068 alias mv='nocorrect mv'         # no spelling correction on mv
2069 alias rm='nocorrect rm'         # no spelling correction on rm
2070
2071 #a1# Execute \kbd{rmdir}
2072 alias rd='rmdir'
2073 #a1# Execute \kbd{rmdir}
2074 alias md='mkdir'
2075
2076 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2077 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2078 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2079
2080 # make sure it is not assigned yet
2081 [[ $(whence -w utf2iso &>/dev/null) == 'utf2iso: alias' ]] && unalias utf2iso
2082
2083 utf2iso() {
2084     if isutfenv ; then
2085         for ENV in $(env | command grep -i '.utf') ; do
2086             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2087         done
2088     fi
2089 }
2090
2091 # make sure it is not assigned yet
2092 [[ $(whence -w iso2utf &>/dev/null) == 'iso2utf: alias' ]] && unalias iso2utf
2093 iso2utf() {
2094     if ! isutfenv ; then
2095         for ENV in $(env | command grep -i '\.iso') ; do
2096             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2097         done
2098     fi
2099 }
2100
2101 # set up software synthesizer via speakup
2102 swspeak() {
2103     if [ -x /usr/sbin/swspeak-setup ] ; then
2104        setopt singlelinezle
2105        unsetopt prompt_cr
2106        export PS1="%m%# "
2107        /usr/sbin/swspeak-setup $@
2108      else # old version:
2109         aumix -w 90 -v 90 -p 90 -m 90
2110         if ! [[ -r /dev/softsynth ]] ; then
2111             flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
2112             return 1
2113         else
2114            setopt singlelinezle
2115            unsetopt prompt_cr
2116            export PS1="%m%# "
2117             nice -n -20 speechd-up
2118             sleep 2
2119             flite -o play -t "Finished setting up software synthesizer"
2120         fi
2121      fi
2122 }
2123
2124 # I like clean prompt, so provide simple way to get that
2125 check_com 0 || alias 0='return 0'
2126
2127 # for really lazy people like mika:
2128 check_com S &>/dev/null || alias S='screen'
2129 check_com s &>/dev/null || alias s='ssh'
2130
2131 # get top 10 shell commands:
2132 alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
2133
2134 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
2135 if check_com -c truecrypt ; then
2136     if isutfenv ; then
2137         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
2138     else
2139         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
2140     fi
2141 fi
2142
2143 #f1# Hints for the use of zsh on grml
2144 zsh-help() {
2145     print "$bg[white]$fg[black]
2146 zsh-help - hints for use of zsh on grml
2147 =======================================$reset_color"
2148
2149     print '
2150 Main configuration of zsh happens in /etc/zsh/zshrc.
2151 That file is part of the package grml-etc-core, if you want to
2152 use them on a non-grml-system just get the tar.gz from
2153 http://deb.grml.org/ or (preferably) get it from the git repository:
2154
2155   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2156
2157 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2158 The file is still there, but it is empty for backwards compatibility.
2159
2160 For your own changes use these two files:
2161     $HOME/.zshrc.pre
2162     $HOME/.zshrc.local
2163
2164 The former is sourced very early in our zshrc, the latter is sourced
2165 very lately.
2166
2167 System wide configuration without touching configuration files of grml
2168 can take place in /etc/zsh/zshrc.local.
2169
2170 Normally, the root user (EUID == 0) does not get the whole grml setup.
2171 If you want to force the whole setup for that user, too, set
2172 GRML_ALWAYS_LOAD_ALL=1 in .zshrc.pre in root'\''s home directory.
2173
2174 For information regarding zsh start at http://grml.org/zsh/
2175
2176 Take a look at grml'\''s zsh refcard:
2177 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2178
2179 Check out the main zsh refcard:
2180 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2181
2182 And of course visit the zsh-lovers:
2183 % man zsh-lovers
2184
2185 You can adjust some options through environment variables when
2186 invoking zsh without having to edit configuration files.
2187 Basically meant for bash users who are not used to the power of
2188 the zsh yet. :)
2189
2190   "NOCOR=1    zsh" => deactivate automatic correction
2191   "NOMENU=1   zsh" => do not use auto menu completion (note: use ctrl-d for completion instead!)
2192   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2193   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2194                       preexec() and precmd() completely
2195   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
2196
2197 A value greater than 0 is enables a feature; a value equal to zero
2198 disables it. If you like one or the other of these settings, you can
2199 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2200 zshrc.'
2201
2202     print "
2203 $bg[white]$fg[black]
2204 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2205 Enjoy your grml system with the zsh!$reset_color"
2206 }
2207
2208 # debian stuff
2209 if [[ -r /etc/debian_version ]] ; then
2210     #a3# Execute \kbd{apt-cache search}
2211     alias acs='apt-cache search'
2212     #a3# Execute \kbd{apt-cache show}
2213     alias acsh='apt-cache show'
2214     #a3# Execute \kbd{apt-cache policy}
2215     alias acp='apt-cache policy'
2216     #a3# Execute \kbd{apt-get dist-upgrade}
2217     salias adg="apt-get dist-upgrade"
2218     #a3# Execute \kbd{apt-get install}
2219     salias agi="apt-get install"
2220     #a3# Execute \kbd{aptitude install}
2221     salias ati="aptitude install"
2222     #a3# Execute \kbd{apt-get upgrade}
2223     salias ag="apt-get upgrade"
2224     #a3# Execute \kbd{apt-get update}
2225     salias au="apt-get update"
2226     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2227     salias -a up="aptitude update ; aptitude safe-upgrade"
2228     #a3# Execute \kbd{dpkg-buildpackage}
2229     alias dbp='dpkg-buildpackage'
2230     #a3# Execute \kbd{grep-excuses}
2231     alias ge='grep-excuses'
2232
2233     # debian upgrade
2234     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
2235     upgrade() {
2236         if [[ -z "$1" ]] ; then
2237             $SUDO apt-get update
2238             $SUDO apt-get -u upgrade
2239         else
2240             ssh $1 $SUDO apt-get update
2241             # ask before the upgrade
2242             local dummy
2243             ssh $1 $SUDO apt-get --no-act upgrade
2244             echo -n 'Process the upgrade?'
2245             read -q dummy
2246             if [[ $dummy == "y" ]] ; then
2247                 ssh $1 $SUDO apt-get -u upgrade --yes
2248             fi
2249         fi
2250     }
2251
2252     # get a root shell as normal user in live-cd mode:
2253     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2254        alias su="sudo su"
2255      fi
2256
2257     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2258     alias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2259     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2260     alias tlog="tail -f /var/log/syslog"    # follow the syslog
2261 fi
2262
2263 # sort installed Debian-packages by size
2264 if check_com -c grep-status ; then
2265     #a3# List installed Debian-packages sorted by size
2266     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
2267 fi
2268
2269 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2270 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord ; then
2271     if check_com -c wodim ; then
2272         alias cdrecord="echo 'cdrecord is not provided under its original name by Debian anymore.
2273 See #377109 in the BTS of Debian for more details.
2274
2275 Please use the wodim binary instead' ; return 1"
2276     fi
2277 fi
2278
2279 # get_tw_cli has been renamed into get_3ware
2280 if check_com -c get_3ware ; then
2281     get_tw_cli() {
2282         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
2283         get_3ware
2284     }
2285 fi
2286
2287 # I hate lacking backward compatibility, so provide an alternative therefore
2288 if ! check_com -c apache2-ssl-certificate ; then
2289
2290     apache2-ssl-certificate() {
2291
2292     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
2293     print 'You might want to take a look at Debian the package ssl-cert as well.'
2294     print 'To generate a certificate for use with apache2 follow the instructions:'
2295
2296     echo '
2297
2298 export RANDFILE=/dev/random
2299 mkdir /etc/apache2/ssl/
2300 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
2301 chmod 600 /etc/apache2/ssl/apache.pem
2302
2303 Run "grml-tips ssl-certificate" if you need further instructions.
2304 '
2305     }
2306 fi
2307 # }}}
2308
2309 # {{{ Use hard limits, except for a smaller stack and no core dumps
2310 unlimit
2311 is425 && limit stack 8192
2312 isgrmlcd && limit core 0 # important for a live-cd-system
2313 limit -s
2314 # }}}
2315
2316 # {{{ completion system
2317
2318 # called later (via is4 && grmlcomp)
2319 # note: use 'zstyle' for getting current settings
2320 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
2321 grmlcomp() {
2322     # TODO: This could use some additional information
2323
2324     # allow one error for every three characters typed in approximate completer
2325     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
2326
2327     # don't complete backup files as executables
2328     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
2329
2330     # start menu completion only if it could find no unambiguous initial string
2331     zstyle ':completion:*:correct:*'       insert-unambiguous true
2332     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
2333     zstyle ':completion:*:correct:*'       original true
2334
2335     # activate color-completion
2336     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
2337
2338     # format on completion
2339     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
2340
2341     # complete 'cd -<tab>' with menu
2342     zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
2343
2344     # insert all expansions for expand completer
2345     zstyle ':completion:*:expand:*'        tag-order all-expansions
2346     zstyle ':completion:*:history-words'   list false
2347
2348     # activate menu
2349     zstyle ':completion:*:history-words'   menu yes
2350
2351     # ignore duplicate entries
2352     zstyle ':completion:*:history-words'   remove-all-dups yes
2353     zstyle ':completion:*:history-words'   stop yes
2354
2355     # match uppercase from lowercase
2356     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
2357
2358     # separate matches into groups
2359     zstyle ':completion:*:matches'         group 'yes'
2360     zstyle ':completion:*'                 group-name ''
2361
2362     if [[ "$NOMENU" -eq 0 ]] ; then
2363         # if there are more than 5 options allow selecting from a menu
2364         zstyle ':completion:*'               menu select=5
2365     else
2366         # don't use any menus at all
2367         setopt no_auto_menu
2368     fi
2369
2370     zstyle ':completion:*:messages'        format '%d'
2371     zstyle ':completion:*:options'         auto-description '%d'
2372
2373     # describe options in full
2374     zstyle ':completion:*:options'         description 'yes'
2375
2376     # on processes completion complete all user processes
2377     zstyle ':completion:*:processes'       command 'ps -au$USER'
2378
2379     # offer indexes before parameters in subscripts
2380     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
2381
2382     # provide verbose completion information
2383     zstyle ':completion:*'                 verbose true
2384
2385     # recent (as of Dec 2007) zsh versions are able to provide descriptions
2386     # for commands (read: 1st word in the line) that it will list for the user
2387     # to choose from. The following disables that, because it's not exactly fast.
2388     zstyle ':completion:*:-command-:*:'    verbose false
2389
2390     # set format for warnings
2391     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
2392
2393     # define files to ignore for zcompile
2394     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
2395     zstyle ':completion:correct:'          prompt 'correct to: %e'
2396
2397     # Ignore completion functions for commands you don't have:
2398     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
2399
2400     # Provide more processes in completion of programs like killall:
2401     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
2402
2403     # complete manual by their section
2404     zstyle ':completion:*:manuals'    separate-sections true
2405     zstyle ':completion:*:manuals.*'  insert-sections   true
2406     zstyle ':completion:*:man:*'      menu yes select
2407
2408     # provide .. as a completion
2409     zstyle ':completion:*' special-dirs ..
2410
2411     # run rehash on completion so new installed program are found automatically:
2412     _force_rehash() {
2413         (( CURRENT == 1 )) && rehash
2414         return 1
2415     }
2416
2417     ## correction
2418     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
2419     if [[ "$NOCOR" -gt 0 ]] ; then
2420         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
2421         setopt nocorrect
2422     else
2423         # try to be smart about when to use what completer...
2424         setopt correct
2425         zstyle -e ':completion:*' completer '
2426             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
2427                 _last_try="$HISTNO$BUFFER$CURSOR"
2428                 reply=(_complete _match _ignored _prefix _files)
2429             else
2430                 if [[ $words[1] == (rm|mv) ]] ; then
2431                     reply=(_complete _files)
2432                 else
2433                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
2434                 fi
2435             fi'
2436     fi
2437
2438     # command for process lists, the local web server details and host completion
2439     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
2440
2441     # caching
2442     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
2443                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
2444
2445     # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
2446     if is42 ; then
2447         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
2448         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
2449     else
2450         _ssh_hosts=()
2451         _etc_hosts=()
2452     fi
2453     hosts=(
2454         $(hostname)
2455         "$_ssh_hosts[@]"
2456         "$_etc_hosts[@]"
2457         grml.org
2458         localhost
2459     )
2460     zstyle ':completion:*:hosts' hosts $hosts
2461     # TODO: so, why is this here?
2462     #  zstyle '*' hosts $hosts
2463
2464     # use generic completion system for programs not yet defined; (_gnu_generic works
2465     # with commands that provide a --help option with "standard" gnu-like output.)
2466     compdef _gnu_generic tail head feh cp mv df stow uname ipacsum fetchipac
2467
2468     # see upgrade function in this file
2469     compdef _hosts upgrade
2470 }
2471 # }}}
2472
2473 # {{{ grmlstuff
2474 grmlstuff() {
2475 # people should use 'grml-x'!
2476     startx() {
2477         if [[ -e /etc/X11/xorg.conf ]] ; then
2478             [[ -x /usr/bin/startx ]] && /usr/bin/startx "$@" || /usr/X11R6/bin/startx "$@"
2479         else
2480             echo "Please use the script \"grml-x\" for starting the X Window System
2481 because there does not exist /etc/X11/xorg.conf yet.
2482 If you want to use startx anyway please call \"/usr/bin/startx\"."
2483             return -1
2484         fi
2485     }
2486
2487     xinit() {
2488         if [[ -e /etc/X11/xorg.conf ]] ; then
2489             [[ -x /usr/bin/xinit ]] && /usr/bin/xinit || /usr/X11R6/bin/xinit
2490         else
2491             echo "Please use the script \"grml-x\" for starting the X Window System.
2492 because there does not exist /etc/X11/xorg.conf yet.
2493 If you want to use xinit anyway please call \"/usr/bin/xinit\"."
2494             return -1
2495         fi
2496     }
2497
2498     if check_com -c 915resolution ; then
2499         alias 855resolution='echo -e "Please use 915resolution as resolution modify tool for Intel graphic chipset."; return -1'
2500     fi
2501
2502     #a1# Output version of running grml
2503     alias grml-version='cat /etc/grml_version'
2504
2505     if check_com -c rebuildfstab ; then
2506         #a1# Rebuild /etc/fstab
2507         alias grml-rebuildfstab='rebuildfstab -v -r -config'
2508     fi
2509
2510     if check_com -c grml-debootstrap ; then
2511         alias debian2hd='print "Installing debian to harddisk is possible via using grml-debootstrap." ; return 1'
2512     fi
2513 }
2514 # }}}
2515
2516 # {{{ now run the functions
2517 isgrml && checkhome
2518 is4    && isgrml    && grmlstuff
2519 is4    && grmlcomp
2520 # }}}
2521
2522 # {{{ keephack
2523 is4 && xsource "/etc/zsh/keephack"
2524 # }}}
2525
2526 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
2527 # You use it as follows:
2528 # $ NTREF=/reference/file
2529 # $ ls -l *(e:nt:)
2530 # This lists all the files in the current directory newer than the reference file.
2531 # You can also specify the reference file inline; note quotes:
2532 # $ ls -l *(e:'nt ~/.zshenv':)
2533 is4 && nt() {
2534     if [[ -n $1 ]] ; then
2535         local NTREF=${~1}
2536     fi
2537     [[ $REPLY -nt $NTREF ]]
2538 }
2539 # }}}
2540
2541 # shell functions {{{
2542
2543 #f1# Provide csh compatibility
2544 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
2545
2546 #f1# Reload an autoloadable function
2547 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2548
2549 #f1# Reload zsh setup
2550 reload() {
2551     if [[ "$#*" -eq 0 ]] ; then
2552         [[ -r ~/.zshrc ]] && . ~/.zshrc
2553     else
2554         local fn
2555         for fn in "$@"; do
2556             unfunction $fn
2557             autoload -U $fn
2558         done
2559     fi
2560 }
2561 compdef _functions reload freload
2562
2563 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2564 sll() {
2565     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2566     for i in "$@" ; do
2567         file=$i
2568         while [[ -h "$file" ]] ; do
2569             ls -l $file
2570             file=$(readlink "$file")
2571         done
2572     done
2573 }
2574
2575 # fast manual access
2576 if check_com qma ; then
2577     #f1# View the zsh manual
2578     manzsh()  { qma zshall "$1" }
2579     compdef _man qma
2580 else
2581     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
2582 fi
2583
2584 if check_com -c $PAGER ; then
2585     #f1# View Debian's changelog of a given package
2586     dchange() {
2587         if [[ -r /usr/share/doc/${1}/changelog.Debian.gz ]] ; then
2588             $PAGER /usr/share/doc/${1}/changelog.Debian.gz
2589         elif [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2590             $PAGER /usr/share/doc/${1}/changelog.gz
2591         else
2592             if check_com -c aptitude ; then
2593                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2594                 if isgrml ; then
2595                     aptitude -t unstable changelog ${1}
2596                 else
2597                     aptitude changelog ${1}
2598                 fi
2599             else
2600                 echo "No changelog for package $1 found, sorry."
2601                 return 1
2602             fi
2603         fi
2604     }
2605     _dchange() { _files -W /usr/share/doc -/ }
2606     compdef _dchange dchange
2607
2608     #f1# View Debian's NEWS of a given package
2609     dnews() {
2610         if [[ -r /usr/share/doc/${1}/NEWS.Debian.gz ]] ; then
2611             $PAGER /usr/share/doc/${1}/NEWS.Debian.gz
2612         else
2613             if [[ -r /usr/share/doc/${1}/NEWS.gz ]] ; then
2614                 $PAGER /usr/share/doc/${1}/NEWS.gz
2615             else
2616                 echo "No NEWS file for package $1 found, sorry."
2617                 return 1
2618             fi
2619         fi
2620     }
2621     _dnews() { _files -W /usr/share/doc -/ }
2622     compdef _dnews dnews
2623
2624     #f1# View upstream's changelog of a given package
2625     uchange() {
2626         if [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2627             $PAGER /usr/share/doc/${1}/changelog.gz
2628         else
2629             echo "No changelog for package $1 found, sorry."
2630             return 1
2631         fi
2632     }
2633     _uchange() { _files -W /usr/share/doc -/ }
2634     compdef _uchange uchange
2635 fi
2636
2637 # zsh profiling
2638 profile() {
2639     ZSH_PROFILE_RC=1 $SHELL "$@"
2640 }
2641
2642 #f1# Edit an alias via zle
2643 edalias() {
2644     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2645 }
2646 compdef _aliases edalias
2647
2648 #f1# Edit a function via zle
2649 edfunc() {
2650     [[ -z "$1" ]] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
2651 }
2652 compdef _functions edfunc
2653
2654 # use it e.g. via 'Restart apache2'
2655 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2656 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2657 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2658 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2659 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2660 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2661     __start_stop() {
2662         local action_="${1:l}"  # e.g Start/Stop/Restart
2663         local service_="$2"
2664         local param_="$3"
2665
2666         local service_target_="$(readlink /etc/init.d/$service_)"
2667         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2668             # runit
2669             case "${action_}" in
2670                 start) if [[ ! -e /etc/service/$service_ ]]; then
2671                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2672                        else
2673                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2674                        fi ;;
2675                 # there is no reload in runits sysv emulation
2676                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2677                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2678             esac
2679         else
2680             # sysvinit
2681             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2682         fi
2683     }
2684
2685     for i in Start Restart Stop Force-Reload Reload ; do
2686         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2687     done
2688 fi
2689
2690 #f1# Provides useful information on globbing
2691 H-Glob() {
2692     echo -e "
2693     /      directories
2694     .      plain files
2695     @      symbolic links
2696     =      sockets
2697     p      named pipes (FIFOs)
2698     *      executable plain files (0100)
2699     %      device files (character or block special)
2700     %b     block special files
2701     %c     character special files
2702     r      owner-readable files (0400)
2703     w      owner-writable files (0200)
2704     x      owner-executable files (0100)
2705     A      group-readable files (0040)
2706     I      group-writable files (0020)
2707     E      group-executable files (0010)
2708     R      world-readable files (0004)
2709     W      world-writable files (0002)
2710     X      world-executable files (0001)
2711     s      setuid files (04000)
2712     S      setgid files (02000)
2713     t      files with the sticky bit (01000)
2714
2715   print *(m-1)          # Files modified up to a day ago
2716   print *(a1)           # Files accessed a day ago
2717   print *(@)            # Just symlinks
2718   print *(Lk+50)        # Files bigger than 50 kilobytes
2719   print *(Lk-50)        # Files smaller than 50 kilobytes
2720   print **/*.c          # All *.c files recursively starting in \$PWD
2721   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2722   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2723   print *~*.*           # All Files that do not contain a dot
2724   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2725   print -l *(.c|.h)     # Lists *.c and *.h
2726   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2727   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2728 }
2729 alias help-zshglob=H-Glob
2730
2731 check_com -c qma && alias ?='qma zshall'
2732
2733 # grep for running process, like: 'any vim'
2734 any() {
2735     if [[ -z "$1" ]] ; then
2736         echo "any - grep for process(es) by keyword" >&2
2737         echo "Usage: any <keyword>" >&2 ; return 1
2738     else
2739         local STRING=$1
2740         local LENGTH=$(expr length $STRING)
2741         local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
2742         local REST=$(echo $(expr substr $STRING 2 $LENGTH))
2743         ps xauwww| grep "[$FIRSCHAR]$REST"
2744     fi
2745 }
2746
2747 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2748 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2749 [[ -r /proc/1/maps ]] && \
2750 deswap() {
2751     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2752     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2753     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2754 }
2755
2756 # print hex value of a number
2757 hex() {
2758     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
2759 }
2760
2761 # calculate (or eval at all ;-)) with perl => p[erl-]eval
2762 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
2763 peval() {
2764     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
2765     perl -e "print eval($CALC),\"\n\";"
2766 }
2767 functions peval &>/dev/null && alias calc=peval
2768
2769 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
2770 # certain circumstances, so work around it, no matter which environment we have
2771 brltty() {
2772     if [[ -z "$DISPLAY" ]] ; then
2773         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
2774         command brltty "$@"
2775     else
2776         command brltty "$@"
2777     fi
2778 }
2779
2780 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
2781 aoeu() {
2782     echo -n 'Switching to us keyboard layout: '
2783     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
2784     echo 'Done'
2785 }
2786 asdf() {
2787     echo -n 'Switching to dvorak keyboard layout: '
2788     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
2789     echo 'Done'
2790 }
2791 # just press 'asdf' key to toggle from neon layout to us keyboard layout
2792 uiae() {
2793     echo -n 'Switching to us keyboard layout: '
2794     setxkbmap us && echo 'Done' || echo 'Failed'
2795 }
2796
2797 # set up an ipv6 tunnel
2798 ipv6-tunnel() {
2799     case $1 in
2800         start)
2801             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2802                 print 'ipv6 tunnel already set up, nothing to be done.'
2803                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
2804             else
2805                 [[ -n "$PUBLIC_IP" ]] || \
2806                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
2807                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
2808
2809                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
2810                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
2811                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
2812                 ifconfig sit0 tunnel ::192.88.99.1 up
2813                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
2814             fi
2815             ;;
2816         status)
2817             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2818                 print 'ipv6 tunnel available' ; return 0
2819             else
2820                 print 'ipv6 tunnel not available' ; return 1
2821             fi
2822             ;;
2823         stop)
2824             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2825                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
2826                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
2827             else
2828                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
2829             fi
2830             ;;
2831         *)
2832             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
2833             ;;
2834     esac
2835 }
2836
2837 # run dhclient for wireless device
2838 iwclient() {
2839     salias dhclient "$(wavemon -d | awk '/device/{print $2}')"
2840 }
2841
2842 # spawn a minimally set up ksh - useful if you want to umount /usr/.
2843 minimal-shell() {
2844     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ksh
2845 }
2846
2847 # make a backup of a file
2848 bk() {
2849     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2850 }
2851
2852 #f1# grep for patterns in grml's zsh setup
2853 zg() {
2854 #{{{
2855     LANG=C perl -e '
2856
2857 sub usage {
2858     print "usage: zg -[anr] <pattern>\n";
2859     print " Search for patterns in grml'\''s zshrc.\n";
2860     print " zg takes no or exactly one option plus a non empty pattern.\n\n";
2861     print "   options:\n";
2862     print "     --  no options (use if your pattern starts in with a dash.\n";
2863     print "     -a  search for the pattern in all code regions\n";
2864     print "     -n  search for the pattern in non-root code only\n";
2865     print "     -r  search in code for everyone (also root) only\n\n";
2866     print "   The default is -a for non-root users and -r for root.\n\n";
2867     print " If you installed the zshrc to a non-default locations (ie *NOT*\n";
2868     print " in /etc/zsh/zshrc) do: export GRML_ZSHRC=\$HOME/.zshrc\n";
2869     print " ...in case you copied the file to that location.\n\n";
2870     exit 1;
2871 }
2872
2873 if ($ENV{GRML_ZSHRC} ne "") {
2874     $RC = $ENV{GRML_ZSHRC};
2875 } else {
2876     $RC = "/etc/zsh/zshrc";
2877 }
2878
2879 usage if ($#ARGV < 0 || $#ARGV > 1);
2880 if ($> == 0) { $mode = "allonly"; }
2881 else { $mode = "all"; }
2882
2883 $opt = $ARGV[0];
2884 if ($opt eq "--")     { shift; }
2885 elsif ($opt eq "-a")  { $mode = "all"; shift; }
2886 elsif ($opt eq "-n")  { $mode = "nonroot"; shift; }
2887 elsif ($opt eq "-r" ) { $mode = "allonly"; shift; }
2888 elsif ($opt =~ m/^-/ || $#ARGV > 0) { usage(); }
2889
2890 $pattern = $ARGV[0];
2891 usage() if ($pattern eq "");
2892
2893 open FH, "<$RC" or die "zg: Could not open $RC: $!\n";
2894 while ($line = <FH>) {
2895     chomp $line;
2896     if ($line =~ m/^#:grep:marker:for:mika:/) { $markerfound = 1; next; }
2897     next if ($mode eq "nonroot" && markerfound == 0);
2898     break if ($mode eq "allonly" && markerfound == 1);
2899     print $line, "\n" if ($line =~ /$pattern/);
2900 }
2901 close FH;
2902 exit 0;
2903
2904     ' -- "$@"
2905 #}}}
2906     return $?
2907 }
2908
2909 # }}}
2910
2911 # {{{ make sure our environment is clean regarding colors
2912 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2913 # }}}
2914
2915 # source another config file if present {{{
2916 xsource "/etc/zsh/zshrc.local"
2917 # }}}
2918
2919 # "persistent history" {{{
2920 # just write important commands you always need to ~/.important_commands
2921 if [[ -r ~/.important_commands ]] ; then
2922     fc -R ~/.important_commands
2923 fi
2924 # }}}
2925
2926 #:grep:marker:for:mika: :-)
2927 ### non-root (EUID != 0) code below
2928 ###
2929
2930 if (( GRML_ALWAYS_LOAD_ALL == 0 )) && (( $EUID == 0 )) ; then
2931     zrclocal
2932     return 0
2933 fi
2934
2935
2936 # variables {{{
2937
2938 # set terminal property (used e.g. by msgid-chooser)
2939 export COLORTERM="yes"
2940
2941 # set default browser
2942 if [[ -z "$BROWSER" ]] ; then
2943     if [[ -n "$DISPLAY" ]] ; then
2944         #v# If X11 is running
2945         check_com -c firefox && export BROWSER=firefox
2946     else
2947         #v# If no X11 is running
2948         check_com -c w3m && export BROWSER=w3m
2949     fi
2950 fi
2951
2952 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
2953 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
2954 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
2955
2956 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
2957 #v# [for non-root only]
2958 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
2959 # }}}
2960
2961 # aliases {{{
2962
2963 # Xterm resizing-fu.
2964 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
2965 alias hide='echo -en "\033]50;nil2\007"'
2966 alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
2967 alias small='echo -en "\033]50;6x10\007"'
2968 alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
2969 alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
2970 alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
2971 alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
2972 alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
2973 alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
2974
2975 # general
2976 #a2# Execute \kbd{du -sch}
2977 alias da='du -sch'
2978 #a2# Execute \kbd{jobs -l}
2979 alias j='jobs -l'
2980
2981 # compile stuff
2982 #a2# Execute \kbd{./configure}
2983 alias CO="./configure"
2984 #a2# Execute \kbd{./configure --help}
2985 alias CH="./configure --help"
2986
2987 # http://conkeror.mozdev.org/
2988 # TODO: I think this should be removed, as conkeror is not a simple extension anymore
2989 #a2# Run a keyboard driven firefox
2990 alias conkeror='firefox -chrome chrome://conkeror/content'
2991
2992 # arch/tla stuff
2993 if check_com -c tla ; then
2994     #a2# Execute \kbd{tla what-changed --diffs | less}
2995     alias tdi='tla what-changed --diffs | less'
2996     #a2# Execute \kbd{tla-buildpackage}
2997     alias tbp='tla-buildpackage'
2998     #a2# Execute \kbd{tla archive-mirror}
2999     alias tmi='tla archive-mirror'
3000     #a2# Execute \kbd{tla commit}
3001     alias tco='tla commit'
3002     #a2# Execute \kbd{tla star-merge}
3003     alias tme='tla star-merge'
3004 fi
3005
3006 # listing stuff
3007 #a2# Execute \kbd{ls -lSrah}
3008 alias dir="ls -lSrah"
3009 #a2# Only show dot-directories
3010 alias lad='ls -d .*(/)'                # only show dot-directories
3011 #a2# Only show dot-files
3012 alias lsa='ls -a .*(.)'                # only show dot-files
3013 #a2# Only files with setgid/setuid/sticky flag
3014 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
3015 #a2# Only show 1st ten symlinks
3016 alias lsl='ls -l *(@[1,10])'           # only symlinks
3017 #a2# Display only executables
3018 alias lsx='ls -l *(*[1,10])'           # only executables
3019 #a2# Display world-{readable,writable,executable} files
3020 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
3021 #a2# Display the ten biggest files
3022 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
3023 #a2# Only show directories
3024 alias lsd='ls -d *(/)'                 # only show directories
3025 #a2# Only show empty directories
3026 alias lse='ls -d *(/^F)'               # only show empty directories
3027 #a2# Display the ten newest files
3028 alias lsnew="ls -rl *(D.om[1,10])"     # display the newest files
3029 #a2# Display the ten oldest files
3030 alias lsold="ls -rtlh *(D.om[1,10])"   # display the oldest files
3031 #a2# Display the ten smallest files
3032 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
3033
3034 # chmod
3035 #a2# Execute \kbd{chmod 600}
3036 alias rw-='chmod 600'
3037 #a2# Execute \kbd{chmod 700}
3038 alias rwx='chmod 700'
3039 #m# a2 r-{}- Execute \kbd{chmod 644}
3040 alias r--='chmod 644'
3041 #a2# Execute \kbd{chmod 755}
3042 alias r-x='chmod 755'
3043
3044 # some useful aliases
3045 #a2# Execute \kbd{mkdir -o}
3046 alias md='mkdir -p'
3047
3048 check_com -c ipython && alias ips='ipython -p sh'
3049
3050 # console stuff
3051 #a2# Execute \kbd{mplayer -vo fbdev}
3052 alias cmplayer='mplayer -vo fbdev'
3053 #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
3054 alias fbmplayer='mplayer -vo fbdev -fs -zoom'
3055 #a2# Execute \kbd{links2 -driver fb}
3056 alias fblinks='links2 -driver fb'
3057
3058 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3059 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3060 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3061
3062 # simple webserver
3063 check_com -c python && alias http="python -m SimpleHTTPServer"
3064
3065 # Use 'g' instead of 'git':
3066 check_com g || alias g='git'
3067
3068 # use colors when browsing man pages, but only if not using LESS_TERMCAP_* from /etc/zsh/zshenv:
3069 if [[ -z "$LESS_TERMCAP_md" ]] ; then
3070     [[ -d ~/.terminfo/ ]] && alias man='TERMINFO=~/.terminfo/ LESS=C TERM=mostlike PAGER=less man'
3071 fi
3072
3073 # check whether Debian's package management (dpkg) is running
3074 if check_com salias ; then
3075     #a2# Check whether a dpkg instance is currently running
3076     salias check_dpkg_running="dpkg_running"
3077 fi
3078
3079 # work around non utf8 capable software in utf environment via $LANG and luit
3080 if check_com isutfenv && check_com luit ; then
3081     if check_com -c mrxvt ; then
3082         isutfenv && [[ -n "$LANG" ]] && \
3083             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3084     fi
3085
3086     if check_com -c aterm ; then
3087         isutfenv && [[ -n "$LANG" ]] && \
3088             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3089     fi
3090
3091     if check_com -c centericq ; then
3092         isutfenv && [[ -n "$LANG" ]] && \
3093             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3094     fi
3095 fi
3096 # }}}
3097
3098 # useful functions {{{
3099
3100 # searching
3101 #f4# Search for newspostings from authors
3102 agoogle() { ${=BROWSER} "http://groups.google.com/groups?as_uauthors=$*" ; }
3103 #f4# Search Debian Bug Tracking System
3104 debbug()  {
3105     setopt localoptions extendedglob
3106     if [[ $# -eq 1 ]]; then
3107         case "$1" in
3108             ([0-9]##)
3109             ${=BROWSER} "http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=$1"
3110             ;;
3111             (*@*)
3112             ${=BROWSER} "http://bugs.debian.org/cgi-bin/pkgreport.cgi?submitter=$1"
3113             ;;
3114             (*)
3115             ${=BROWSER} "http://bugs.debian.org/$*"
3116             ;;
3117         esac
3118     else
3119         print "$0 needs one argument"
3120         return 1
3121     fi
3122 }
3123 #f4# Search Debian Bug Tracking System in mbox format
3124 debbugm() { bts show --mbox $1 } # provide bugnummer as "$1"
3125 #f4# Search DMOZ
3126 dmoz()    { ${=BROWSER} http://search.dmoz.org/cgi-bin/search\?search=${1// /_} }
3127 #f4# Search German   Wiktionary
3128 dwicti()  { ${=BROWSER} http://de.wiktionary.org/wiki/${(C)1// /_} }
3129 #f4# Search English  Wiktionary
3130 ewicti()  { ${=BROWSER} http://en.wiktionary.org/wiki/${(C)1// /_} }
3131 #f4# Search Google Groups
3132 ggogle()  { ${=BROWSER} "http://groups.google.com/groups?q=$*" }
3133 #f4# Search Google
3134 google()  { ${=BROWSER} "http://www.google.com/search?&num=100&q=$*" }
3135 #f4# Search Google Groups for MsgID
3136 mggogle() { ${=BROWSER} "http://groups.google.com/groups?selm=$*" }
3137 #f4# Search Netcraft
3138 netcraft(){ ${=BROWSER} "http://toolbar.netcraft.com/site_report?url=$1" }
3139 #f4# Use German Wikipedia's full text search
3140 swiki()   { ${=BROWSER} http://de.wikipedia.org/wiki/Spezial:Search/${(C)1} }
3141 #f4# search \kbd{dict.leo.org}
3142 oleo()    { ${=BROWSER} "http://dict.leo.org/?search=$*" }
3143 #f4# Search German   Wikipedia
3144 wikide()  { ${=BROWSER} http://de.wikipedia.org/wiki/"${(C)*}" }
3145 #f4# Search English  Wikipedia
3146 wikien()  { ${=BROWSER} http://en.wikipedia.org/wiki/"${(C)*}" }
3147 #f4# Search official debs
3148 wodeb()   { ${=BROWSER} "http://packages.debian.org/search?keywords=$1&searchon=contents&suite=${2:=unstable}&section=all" }
3149
3150 #m# f4 gex() Exact search via Google
3151 check_com google && gex () { google "\"[ $1]\" $*" } # exact search at google
3152
3153 # misc
3154 #f5# Backup \kbd{file {\rm to} file\_timestamp}
3155 bk()      { cp -b ${1} ${1}_`date --iso-8601=m` }
3156 #f5# Copied diff
3157 cdiff()   { diff -crd "$*" | egrep -v "^Only in |^Binary files " }
3158 #f5# cd to directoy and list files
3159 cl()      { cd $1 && ls -a }        # cd && ls
3160 #f5# Cvs add
3161 cvsa()    { cvs add $* && cvs com -m 'initial checkin' $* }
3162 #f5# Cvs diff
3163 cvsd()    { cvs diff -N $* |& $PAGER }
3164 #f5# Cvs log
3165 cvsl()    { cvs log $* |& $PAGER }
3166 #f5# Cvs update
3167 cvsq()    { cvs -nq update }
3168 #f5# Rcs2log
3169 cvsr()    { rcs2log $* | $PAGER }
3170 #f5# Cvs status
3171 cvss()    { cvs status -v $* }
3172 #f5# Disassemble source files using gcc and as
3173 disassemble(){ gcc -pipe -S -o - -O -g $* | as -aldh -o /dev/null }
3174 #f5# Firefox remote control - open given URL
3175 fir()     { firefox -a firefox -remote "openURL($1)" }
3176 #f5# Create Directoy and \kbd{cd} to it
3177 mcd()     { mkdir -p "$@"; cd "$@" } # mkdir && cd
3178 #f5# Unified diff to timestamped outputfile
3179 mdiff()   { diff -udrP "$1" "$2" > diff.`date "+%Y-%m-%d"`."$1" }
3180 #f5# Memory overview
3181 memusage(){ ps aux | awk '{if (NR > 1) print $5; if (NR > 2) print "+"} END { print "p" }' | dc }
3182 #f5# Show contents of tar file
3183 shtar()   { gunzip -c $1 | tar -tf - -- | $PAGER }
3184 #f5# Show contents of tgz file
3185 shtgz()   { tar -ztf $1 | $PAGER }
3186 #f5# Show contents of zip file
3187 shzip()   { unzip -l $1 | $PAGER }
3188 #f5# Greps signature from file
3189 sig()     { agrep -d '^-- $' "$*" ~/.Signature }
3190 #f5# Unified diff
3191 udiff()   { diff -urd $* | egrep -v "^Only in |^Binary files " }
3192 #f5# (Mis)use \kbd{vim} as \kbd{less}
3193 viless()  { vim --cmd 'let no_plugin_maps = 1' -c "so \$VIMRUNTIME/macros/less.vim" "${@:--}" }
3194
3195 # download video from youtube
3196 ytdl() {
3197     if ! [[ -n "$2" ]] ; then
3198         print "Usage: ydtl http://youtube.com/watch?v=.... outputfile.flv">&2
3199         return 1
3200     else
3201         wget -O${2} "http://youtube.com/get_video?"${${${"$(wget -o/dev/null -O- "${1}" | grep -e watch_fullscreen)"}##*watch_fullscreen\?}%%\&fs=*}
3202     fi
3203 }
3204
3205 # Function Usage: uopen $URL/$file
3206 #f5# Download a file and display it locally
3207 uopen() {
3208     if ! [[ -n "$1" ]] ; then
3209         print "Usage: uopen \$URL/\$file">&2
3210         return 1
3211     else
3212         FILE=$1
3213         MIME=$(curl --head $FILE | grep Content-Type | cut -d ' ' -f 2 | cut -d\; -f 1)
3214         MIME=${MIME%$'\r'}
3215         curl $FILE | see ${MIME}:-
3216     fi
3217 }
3218
3219 # Function Usage: doc packagename
3220 #f5# \kbd{cd} to /usr/share/doc/\textit{package}
3221 doc() { cd /usr/share/doc/$1 && ls }
3222 _doc() { _files -W /usr/share/doc -/ }
3223 check_com compdef && compdef _doc doc
3224
3225 #f5# Make screenshot
3226 sshot() {
3227     [[ ! -d ~/shots  ]] && mkdir ~/shots
3228     #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
3229     cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
3230 }
3231
3232 # list images only
3233 limg() {
3234     local -a images
3235     images=( *.{jpg,gif,png}(.N) )
3236
3237     if [[ $#images -eq 0 ]] ; then
3238         print "No image files found"
3239     else
3240         ls "$@" "$images[@]"
3241     fi
3242 }
3243
3244 #f5# Create PDF file from source code
3245 makereadable() {
3246     output=$1
3247     shift
3248     a2ps --medium A4dj -E -o $output $*
3249     ps2pdf $output
3250 }
3251
3252 # zsh with perl-regex - use it e.g. via:
3253 # regcheck '\s\d\.\d{3}\.\d{3} Euro' ' 1.000.000 Euro'
3254 #f5# Checks whether a regex matches or not.\\&\quad Example: \kbd{regcheck '.\{3\} EUR' '500 EUR'}
3255 regcheck() {
3256     zmodload -i zsh/pcre
3257     pcre_compile $1 && \
3258     pcre_match $2 && echo "regex matches" || echo "regex does not match"
3259 }
3260
3261 #f5# List files which have been modified within the last {\it n} days
3262 new() { print -l *(m-$1) }
3263
3264 #f5# Grep in history
3265 greph() { history 0 | grep $1 }
3266 # use colors when GNU grep with color-support
3267 #a2# Execute \kbd{grep -{}-color=auto}
3268 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
3269 #a2# Execute \kbd{grep -i -{}-color=auto}
3270 alias GREP='grep -i --color=auto'
3271
3272 # one blank line between each line
3273 if [[ -r ~/.terminfo/m/mostlike ]] ; then
3274     #f5# Watch manpages in a stretched style
3275     man2() { PAGER='dash -c "sed G | /usr/bin/less"' TERM=mostlike /usr/bin/man "$@" ; }
3276 fi
3277
3278 # d():Copyright 2005 Nikolai Weibull <nikolai@bitwi.se>
3279 # note: option AUTO_PUSHD has to be set
3280 #f5# Jump between directories
3281 d() {
3282     emulate -L zsh
3283     autoload -U colors
3284     local color=$fg_bold[blue]
3285     integer i=0
3286     dirs -p | while read dir; do
3287         local num="${$(printf "%-4d " $i)/ /.}"
3288         printf " %s  $color%s$reset_color\n" $num $dir
3289         (( i++ ))
3290     done
3291     integer dir=-1
3292     read -r 'dir?Jump to directory: ' || return
3293     (( dir == -1 )) && return
3294     if (( dir < 0 || dir >= i )); then
3295         echo d: no such directory stack entry: $dir
3296         return 1
3297     fi
3298     cd ~$dir
3299 }
3300
3301 # usage example: 'lcheck strcpy'
3302 #f5# Find out which libs define a symbol
3303 lcheck() {
3304     if [[ -n "$1" ]] ; then
3305         nm -go /usr/lib/lib*.a 2>/dev/null | grep ":[[:xdigit:]]\{8\} . .*$1"
3306     else
3307         echo "Usage: lcheck <function>" >&2
3308     fi
3309 }
3310
3311 #f5# Clean up directory - remove well known tempfiles
3312 purge() {
3313     FILES=(*~(N) .*~(N) \#*\#(N) *.o(N) a.out(N) *.core(N) *.cmo(N) *.cmi(N) .*.swp(N))
3314     NBFILES=${#FILES}
3315     if [[ $NBFILES > 0 ]] ; then
3316         print $FILES
3317         local ans
3318         echo -n "Remove these files? [y/n] "
3319         read -q ans
3320         if [[ $ans == "y" ]] ; then
3321             rm ${FILES}
3322             echo ">> $PWD purged, $NBFILES files removed"
3323         else
3324             echo "Ok. .. than not.."
3325         fi
3326     fi
3327 }
3328
3329 # Translate DE<=>EN
3330 # 'translate' looks up fot a word in a file with language-to-language
3331 # translations (field separator should be " : "). A typical wordlist looks
3332 # like at follows:
3333 #  | english-word : german-transmission
3334 # It's also only possible to translate english to german but not reciprocal.
3335 # Use the following oneliner to turn back the sort order:
3336 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3337 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3338 #f5# Translates a word
3339 trans() {
3340     case "$1" in
3341         -[dD]*)
3342             translate -l de-en $2
3343             ;;
3344         -[eE]*)
3345             translate -l en-de $2
3346             ;;
3347         *)
3348             echo "Usage: $0 { -D | -E }"
3349             echo "         -D == German to English"
3350             echo "         -E == English to German"
3351     esac
3352 }
3353
3354 #f5# List all occurrences of programm in current PATH
3355 plap() {
3356     if [[ $# = 0 ]] ; then
3357         echo "Usage:    $0 program"
3358         echo "Example:  $0 zsh"
3359         echo "Lists all occurrences of program in the current PATH."
3360     else
3361         ls -l ${^path}/*$1*(*N)
3362     fi
3363 }
3364
3365 # Found in the mailinglistarchive from Zsh (IIRC ~1996)
3366 #f5# Select items for specific command(s) from history
3367 selhist() {
3368     emulate -L zsh
3369     local TAB=$'\t';
3370     (( $# < 1 )) && {
3371         echo "Usage: $0 command"
3372         return 1
3373     };
3374     cmd=(${(f)"$(grep -w $1 $HISTFILE | sort | uniq | pr -tn)"})
3375     print -l $cmd | less -F
3376     echo -n "enter number of desired command [1 - $(( ${#cmd[@]} - 1 ))]: "
3377     local answer
3378     read answer
3379     print -z "${cmd[$answer]#*$TAB}"
3380 }
3381
3382 # Use vim to convert plaintext to HTML
3383 #f5# Transform files to html with highlighting
3384 2html() { vim -u NONE -n -c ':syntax on' -c ':so $VIMRUNTIME/syntax/2html.vim' -c ':wqa' $1 &>/dev/null }
3385
3386 # Usage: simple-extract <file>
3387 #f5# Smart archive extractor
3388 simple-extract () {
3389     if [[ -f $1 ]] ; then
3390         case $1 in
3391             *.tar.bz2)  bzip2 -v -d $1      ;;
3392             *.tar.gz)   tar -xvzf $1        ;;
3393             *.rar)      unrar $1            ;;
3394             *.deb)      ar -x $1            ;;
3395             *.bz2)      bzip2 -d $1         ;;
3396             *.lzh)      lha x $1            ;;
3397             *.gz)       gunzip -d $1        ;;
3398             *.tar)      tar -xvf $1         ;;
3399             *.tgz)      gunzip -d $1        ;;
3400             *.tbz2)     tar -jxvf $1        ;;
3401             *.zip)      unzip $1            ;;
3402             *.Z)        uncompress $1       ;;
3403             *)          echo "'$1' Error. Please go away" ;;
3404         esac
3405     else
3406         echo "'$1' is not a valid file"
3407     fi
3408 }
3409
3410 # Usage: smartcompress <file> (<type>)
3411 #f5# Smart archive creator
3412 smartcompress() {
3413     if [[ -n $2 ]] ; then
3414         case $2 in
3415             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
3416             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
3417             tar.Z)          tar -Zcvf$1.$2 $1 ;;
3418             tar)            tar -cvf$1.$2  $1 ;;
3419             gz | gzip)      gzip           $1 ;;
3420             bz2 | bzip2)    bzip2          $1 ;;
3421             *)
3422                 echo "Error: $2 is not a valid compression type"
3423                 ;;
3424         esac
3425     else
3426         smartcompress $1 tar.gz
3427     fi
3428 }
3429
3430 # Usage: show-archive <archive>
3431 #f5# List an archive's content
3432 show-archive() {
3433     if [[ -f $1 ]] ; then
3434         case $1 in
3435             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
3436             *.tar)         tar -tf $1 ;;
3437             *.tgz)         tar -ztf $1 ;;
3438             *.zip)         unzip -l $1 ;;
3439             *.bz2)         bzless $1 ;;
3440             *.deb)         dpkg-deb --fsys-tarfile $1 | tar -tf - -- ;;
3441             *)             echo "'$1' Error. Please go away" ;;
3442         esac
3443     else
3444         echo "'$1' is not a valid archive"
3445     fi
3446 }
3447
3448 # It's shameless stolen from <http://www.vim.org/tips/tip.php?tip_id=167>
3449 #f5# Use \kbd{vim} as your manpage reader
3450 vman() { man $* | col -b | view -c 'set ft=man nomod nolist' - }
3451
3452 # function readme() { $PAGER -- (#ia3)readme* }
3453 #f5# View all README-like files in current directory in pager
3454 readme() {
3455     local files
3456     files=(./(#i)*(read*me|lue*m(in|)ut)*(ND))
3457     if (($#files)) ; then
3458         $PAGER $files
3459     else
3460         print 'No README files.'
3461     fi
3462 }
3463
3464 # function ansi-colors()
3465 #f5# Display ANSI colors
3466 ansi-colors() {
3467     typeset esc="\033[" line1 line2
3468     echo " _ _ _40 _ _ _41_ _ _ _42 _ _ 43_ _ _ 44_ _ _45 _ _ _ 46_ _ _ 47_ _ _ 49_ _"
3469     for fore in 30 31 32 33 34 35 36 37; do
3470         line1="$fore "
3471         line2="   "
3472         for back in 40 41 42 43 44 45 46 47 49; do
3473             line1="${line1}${esc}${back};${fore}m Normal ${esc}0m"
3474             line2="${line2}${esc}${back};${fore};1m Bold   ${esc}0m"
3475         done
3476         echo -e "$line1\n$line2"
3477     done
3478 }
3479
3480 # suidfind() { ls -latg $path | grep '^...s' }
3481 #f5# Find all files in \$PATH with setuid bit set
3482 suidfind() { ls -latg $path/*(sN) }
3483
3484 # See above but this is /better/ ... anywise ..
3485 findsuid() {
3486     print 'Output will be written to ~/suid_* ...'
3487     $SUDO find / -type f \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suidfiles.`date "+%Y-%m-%d"`.out 2>&1
3488     $SUDO find / -type d \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suiddirs.`date "+%Y-%m-%d"`.out 2>&1
3489     $SUDO find / -type f \( -perm -2 -o -perm -20 \) -ls > ~/suid_writefiles.`date "+%Y-%m-%d"`.out 2>&1
3490     $SUDO find / -type d \( -perm -2 -o -perm -20 \) -ls > ~/suid_writedirs.`date "+%Y-%m-%d"`.out 2>&1
3491     print 'Finished'
3492 }
3493
3494 #f5# Reload given functions
3495 refunc() {
3496     for func in $argv ; do
3497         unfunction $func
3498         autoload $func
3499     done
3500 }
3501
3502 # a small check to see which DIR is located on which server/partition.
3503 # stolen and modified from Sven's zshrc.forall
3504 #f5# Report diskusage of a directory
3505 dirspace() {
3506     if [[ -n "$1" ]] ; then
3507         for dir in $* ; do
3508             if [[ -d "$dir" ]] ; then
3509                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3510             else
3511                 echo "warning: $dir does not exist" >&2
3512             fi
3513         done
3514     else
3515         for dir in $path; do
3516             if [[ -d "$dir" ]] ; then
3517                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3518             else
3519                 echo "warning: $dir does not exist" >&2
3520             fi
3521         done
3522     fi
3523 }
3524
3525 # % slow_print `cat /etc/passwd`
3526 #f5# Slowly print out parameters
3527 slow_print() {
3528     for argument in "${@}" ; do
3529         for ((i = 1; i <= ${#1} ;i++)) ; do
3530             print -n "${argument[i]}"
3531             sleep 0.08
3532         done
3533         print -n " "
3534     done
3535     print ""
3536 }
3537
3538 #f5# Show some status info
3539 status() {
3540     print ""
3541     print "Date..: "$(date "+%Y-%m-%d %H:%M:%S")""
3542     print "Shell.: Zsh $ZSH_VERSION (PID = $$, $SHLVL nests)"
3543     print "Term..: $TTY ($TERM), ${BAUD:+$BAUD bauds, }$COLUMNS x $LINES cars"
3544     print "Login.: $LOGNAME (UID = $EUID) on $HOST"
3545     print "System: $(cat /etc/[A-Za-z]*[_-][rv]e[lr]*)"
3546     print "Uptime:$(uptime)"
3547     print ""
3548 }
3549
3550 # Rip an audio CD
3551 #f5# Rip an audio CD
3552 audiorip() {
3553     mkdir -p ~/ripps
3554     cd ~/ripps
3555     cdrdao read-cd --device $DEVICE --driver generic-mmc audiocd.toc
3556     cdrdao read-cddb --device $DEVICE --driver generic-mmc audiocd.toc
3557     echo " * Would you like to burn the cd now? (yes/no)"
3558     read input
3559     if [[ "$input" = "yes" ]] ; then
3560         echo " ! Burning Audio CD"
3561         audioburn
3562         echo " * done."
3563     else
3564         echo " ! Invalid response."
3565     fi
3566 }
3567
3568 # and burn it
3569 #f5# Burn an audio CD (in combination with audiorip)
3570 audioburn() {
3571     cd ~/ripps
3572     cdrdao write --device $DEVICE --driver generic-mmc audiocd.toc
3573     echo " * Should I remove the temporary files? (yes/no)"
3574     read input
3575     if [[ "$input" = "yes" ]] ; then
3576         echo " ! Removing Temporary Files."
3577         cd ~
3578         rm -rf ~/ripps
3579         echo " * done."
3580     else
3581         echo " ! Invalid response."
3582     fi
3583 }
3584
3585 #f5# Make an audio CD from all mp3 files
3586 mkaudiocd() {
3587     # TODO: do the renaming more zshish, possibly with zmv()
3588     cd ~/ripps
3589     for i in *.[Mm][Pp]3; do mv "$i" `echo $i | tr '[A-Z]' '[a-z]'`; done
3590     for i in *.mp3; do mv "$i" `echo $i | tr ' ' '_'`; done
3591     for i in *.mp3; do mpg123 -w `basename $i .mp3`.wav $i; done
3592     normalize -m *.wav
3593     for i in *.wav; do sox $i.wav -r 44100 $i.wav resample; done
3594 }
3595
3596 #f5# Create an ISO image. You are prompted for\\&\quad volume name, filename and directory
3597 mkiso() {
3598     echo " * Volume name "
3599     read volume
3600     echo " * ISO Name (ie. tmp.iso)"
3601     read iso
3602     echo " * Directory or File"
3603     read files
3604     mkisofs -o ~/$iso -A $volume -allow-multidot -J -R -iso-level 3 -V $volume -R $files
3605 }
3606
3607 #f5# Simple thumbnails generator
3608 genthumbs() {
3609     rm -rf thumb-* index.html
3610     echo "
3611 <html>
3612   <head>
3613     <title>Images</title>
3614   </head>
3615   <body>" > index.html
3616     for f in *.(gif|jpeg|jpg|png) ; do
3617         convert -size 100x200 "$f" -resize 100x200 thumb-"$f"
3618         echo "    <a href=\"$f\"><img src=\"thumb-$f\"></a>" >> index.html
3619     done
3620     echo "
3621   </body>
3622 </html>" >> index.html
3623 }
3624
3625 #f5# Set all ulimit parameters to \kbd{unlimited}
3626 allulimit() {
3627     ulimit -c unlimited
3628     ulimit -d unlimited
3629     ulimit -f unlimited
3630     ulimit -l unlimited
3631     ulimit -n unlimited
3632     ulimit -s unlimited
3633     ulimit -t unlimited
3634 }
3635
3636 # ogg2mp3 with bitrate of 192
3637 ogg2mp3_192() {
3638     oggdec -o - ${1} | lame -b 192 - ${1:r}.mp3
3639 }
3640
3641 #f5# RFC 2396 URL encoding in Z-Shell
3642 urlencode() {
3643     setopt localoptions extendedglob
3644     input=( ${(s::)1} )
3645     print ${(j::)input/(#b)([^A-Za-z0-9_.!~*\'\(\)-])/%${(l:2::0:)$(([##16]#match))}}
3646 }
3647
3648 #f5# Install x-lite (VoIP software)
3649 getxlite() {
3650     setopt local_options
3651     setopt errreturn
3652     [[ -d ~/tmp ]] || mkdir ~/tmp
3653     cd ~/tmp
3654
3655     echo "Downloading http://www.counterpath.com/download/X-Lite_Install.tar.gz and storing it in ~/tmp:"
3656     if wget http://www.counterpath.com/download/X-Lite_Install.tar.gz ; then
3657         unp X-Lite_Install.tar.gz && echo done || echo failed
3658     else
3659         echo "Error while downloading." ; return 1
3660     fi
3661
3662     if [[ -x xten-xlite/xtensoftphone ]] ; then
3663         echo "Execute xten-xlite/xtensoftphone to start xlite."
3664     fi
3665 }
3666
3667 #f5# Install skype
3668 getskype() {
3669     setopt local_options
3670     setopt errreturn
3671     echo "Downloading debian package of skype."
3672     echo "Notice: If you want to use a more recent skype version run 'getskypebeta'."
3673     wget http://www.skype.com/go/getskype-linux-deb
3674     $SUDO dpkg -i skype*.deb && echo "skype installed."
3675 }
3676
3677 #f5# Install beta-version of skype
3678 getskypebeta() {
3679     setopt local_options
3680     setopt errreturn
3681     echo "Downloading debian package of skype (beta version)."
3682     wget http://www.skype.com/go/getskype-linux-beta-deb
3683     $SUDO dpkg -i skype-beta*.deb && echo "skype installed."
3684 }
3685
3686 #f5# Install gizmo (VoIP software)
3687 getgizmo() {
3688     setopt local_options
3689     setopt errreturn
3690     echo "libgtk2.0-0, gconf2, libstdc++6, libasound2 and zlib1g have to be available. Installing."
3691     $SUDO apt-get update
3692     $SUDO apt-get install libgtk2.0-0 gconf2 libstdc++6 libasound2 zlib1g
3693     wget "$(lynx --dump http://gizmo5.com/pc/download/linux/ | awk '/libstdc\+\+6.*\.deb/ {print $2}')"
3694     $SUDO dpkg -i gizmo-project*.deb && echo "gizmo installed."
3695 }
3696
3697 #f5# Get and run AIR (Automated Image and Restore)
3698 getair() {
3699     setopt local_options
3700     setopt errreturn
3701     [[ -w . ]] || { echo 'Error: you do not have write permissions in this directory. Exiting.' ; return 1 }
3702     local VER='1.2.8'
3703     wget http://puzzle.dl.sourceforge.net/sourceforge/air-imager/air-$VER.tar.gz
3704     tar zxf air-$VER.tar.gz
3705     cd air-$VER
3706     INTERACTIVE=no $SUDO ./install-air-1.2.8
3707     [[ -x /usr/local/bin/air ]] && [[ -n "$DISPLAY" ]] && $SUDO air
3708 }
3709
3710 #f5# Get specific git commitdiff
3711 git-get-diff() {
3712     if [[ -z $GITTREE ]] ; then
3713         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3714     fi
3715     if ! [[ -z $1 ]] ; then
3716         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commitdiff;h=$1"
3717     else
3718         echo "Usage: git-get-diff <commit>"
3719     fi
3720 }
3721
3722 #f5# Get specific git commit
3723 git-get-commit() {
3724     if [[ -z $GITTREE ]] ; then
3725         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3726     fi
3727     if ! [[ -z $1 ]] ; then
3728         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commit;h=$1"
3729     else
3730         echo "Usage: git-get-commit <commit>"
3731     fi
3732 }
3733
3734 #f5# Get specific git diff
3735 git-get-plaindiff () {
3736     if [[ -z $GITTREE ]] ; then
3737        GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3738     fi
3739     if [[ -z $1 ]] ; then
3740        echo 'Usage: git-get-plaindiff '
3741     else
3742        echo -n "Downloading $1.diff ... "
3743        # avoid "generating ..." stuff from kernel.org server:
3744        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O /dev/null
3745        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O $1.diff \
3746             && echo done || echo failed
3747     fi
3748 }
3749
3750
3751 # http://strcat.de/blog/index.php?/archives/335-Software-sauber-deinstallieren...html
3752 #f5# Log 'make install' output
3753 mmake() {
3754     [[ ! -d ~/.errorlogs ]] && mkdir ~/.errorlogs
3755     make -n install > ~/.errorlogs/${PWD##*/}-makelog
3756 }
3757
3758 #f5# Indent source code
3759 smart-indent() {
3760     indent -npro -kr -i8 -ts8 -sob -l80 -ss -ncs $*
3761 }
3762
3763 # highlight important stuff in diff output, usage example: hg diff | hidiff
3764 #m# a2 hidiff \kbd{histring} oneliner for diffs
3765 check_com -c histring && \
3766     alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
3767
3768 # rename pictures based on information found in exif headers
3769 #f5# Rename pictures based on information found in exif headers
3770 exirename() {
3771     if [[ $# -lt 1 ]] ; then
3772         echo 'Usage: jpgrename $FILES' >& 2
3773         return 1
3774     else
3775         echo -n 'Checking for jhead with version newer than 1.9: '
3776         jhead_version=`jhead -h | grep 'used by most Digital Cameras.  v.*' | awk '{print $6}' | tr -d v`
3777         if [[ $jhead_version > '1.9' ]]; then
3778             echo 'success - now running jhead.'
3779             jhead -n%Y-%m-%d_%Hh%M_%f $*
3780         else
3781             echo 'failed - exiting.'
3782         fi
3783     fi
3784 }
3785
3786 # open file in vim and jump to line
3787 # http://www.downgra.de/archives/2007/05/08/T19_21_11/
3788 j2v() {
3789     local -a params
3790     params=(${*//(#m):[0-9]*:/\\n+${MATCH//:/}}) # replace ':23:' to '\n+23'
3791     params=(${(s|\n|)${(j|\n|)params}}) # join array using '\n', then split on all '\n'
3792     vim ${params}
3793 }
3794
3795 # get_ic() - queries imap servers for capabilities; real simple. no imaps
3796 ic_get() {
3797     local port
3798     if [[ ! -z $1 ]] ; then
3799         port=${2:-143}
3800         print "querying imap server on $1:${port}...\n";
3801         print "a1 capability\na2 logout\n" | nc $1 ${port}
3802     else
3803         print "usage:\n  $0 <imap-server> [port]"
3804     fi
3805 }
3806
3807 # creates a Maildir/ with its {new,cur,tmp} subdirs
3808 mkmaildir() {
3809     local root subdir
3810     root=${MAILDIR_ROOT:-${HOME}/Mail}
3811     if [[ -z ${1} ]] ; then print "Usage:\n $0 <dirname>" ; return 1 ; fi
3812     subdir=${1}
3813     mkdir -p ${root}/${subdir}/{cur,new,tmp}
3814 }
3815
3816 #f5# Change the xterm title from within GNU-screen
3817 xtrename() {
3818     if [[ ${1} != "-f" ]] ; then
3819         if [[ -z ${DISPLAY} ]] ; then
3820             printf 'xtrename only makes sense in X11.\n'
3821             return 1
3822         fi
3823     else
3824         shift
3825     fi
3826     if [[ -z ${1} ]] ; then
3827         printf 'usage: xtrename [-f] "title for xterm"\n'
3828         printf '  renames the title of xterm from _within_ screen.\n'
3829         printf '  also works without screen.\n'
3830         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3831         return 0
3832     fi
3833     print -n "\eP\e]0;${1}\C-G\e\\"
3834     return 0
3835 }
3836
3837 # hl() highlighted less
3838 # http://ft.bewatermyfriend.org/comp/data/zsh/zfunct.html
3839 if check_com -c highlight ; then
3840     function hl() {
3841         local theme lang
3842         theme=${HL_THEME:-""}
3843         case ${1} in
3844             (-l|--list)
3845                 ( printf 'available languages (syntax parameter):\n\n' ;
3846                     highlight --list-langs ; ) | less -SMr
3847                 ;;
3848             (-t|--themes)
3849                 ( printf 'available themes (style parameter):\n\n' ;
3850                     highlight --list-themes ; ) | less -SMr
3851                 ;;
3852             (-h|--help)
3853                 printf 'usage: hl <syntax[:theme]> <file>\n'
3854                 printf '    available options: --list (-l), --themes (-t), --help (-h)\n\n'
3855                 printf '  Example: hl c main.c\n'
3856                 ;;
3857             (*)
3858                 if [[ -z ${2} ]] || (( ${#argv} > 2 )) ; then
3859                     printf 'usage: hl <syntax[:theme]> <file>\n'
3860                     printf '    available options: --list (-l), --themes (-t), --help (-h)\n'
3861                     (( ${#argv} > 2 )) && printf '  Too many arguments.\n'
3862                     return 1
3863                 fi
3864                 lang=${1%:*}
3865                 [[ ${1} == *:* ]] && [[ -n ${1#*:} ]] && theme=${1#*:}
3866                 if [[ -n ${theme} ]] ; then
3867                     highlight --xterm256 --syntax ${lang} --style ${theme} ${2} | less -SMr
3868                 else
3869                     highlight --ansi --syntax ${lang} ${2} | less -SMr
3870                 fi
3871                 ;;
3872         esac
3873         return 0
3874     }
3875     # ... and a proper completion for hl()
3876     # needs 'highlight' as well, so it fits fine in here.
3877     function _hl_genarg()  {
3878         local expl
3879         if [[ -prefix 1 *: ]] ; then
3880             local themes
3881             themes=(${${${(f)"$(LC_ALL=C highlight --list-themes)"}/ #/}:#*(Installed|Use name)*})
3882             compset -P 1 '*:'
3883             _wanted -C list themes expl theme compadd ${themes}
3884         else
3885             local langs
3886             langs=(${${${(f)"$(LC_ALL=C highlight --list-langs)"}/ #/}:#*(Installed|Use name)*})
3887             _wanted -C list languages expl languages compadd -S ':' -q ${langs}
3888         fi
3889     }
3890     function _hl_complete() {
3891         _arguments -s '1: :_hl_genarg' '2:files:_path_files'
3892     }
3893     compdef _hl_complete hl
3894 fi
3895
3896 # Create small urls via http://tinyurl.com using wget(1).
3897 function zurl() {
3898     [[ -z ${1} ]] && { print "USAGE: zurl <URL>" ; return 1 }
3899
3900     local PN url tiny grabber search result preview
3901     PN=${0}
3902     url=${1}
3903 #   Check existence of given URL with the help of ping(1).
3904 #   N.B. ping(1) only works without an eventual given protocol.
3905     ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
3906         read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
3907
3908     if (( $? == 0 )) ; then
3909 #           Prepend 'http://' to given URL where necessary for later output.
3910             [[ ${url} != http(s|)://* ]] && url='http://'${url}
3911             tiny='http://tinyurl.com/create.php?url='
3912             if check_com -c wget ; then
3913                 grabber='wget -O- -o/dev/null'
3914             else
3915                 print "wget is not available, but mandatory for ${PN}. Aborting."
3916             fi
3917 #           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
3918             search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
3919             result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
3920 #           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
3921             preview='http://preview.'${result#http://}
3922
3923             printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
3924             printf '%s\t%s\n\n' 'Given URL:' ${url}
3925             printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
3926     else
3927         return 1
3928     fi
3929 }
3930
3931 #f2# Print a specific line of file(s).
3932 linenr () {
3933 # {{{
3934     if [ $# -lt 2 ] ; then
3935        print "Usage: linenr <number>[,<number>] <file>" ; return 1
3936     elif [ $# -eq 2 ] ; then
3937          local number=$1
3938          local file=$2
3939          command ed -s $file <<< "${number}n"
3940     else
3941          local number=$1
3942          shift
3943          for file in "$@" ; do
3944              if [ ! -d $file ] ; then
3945                 echo "${file}:"
3946                 command ed -s $file <<< "${number}n" 2> /dev/null
3947              else
3948                 continue
3949              fi
3950          done | less
3951     fi
3952 # }}}
3953 }
3954
3955 #f2# Find history events by search pattern and list them by date.
3956 whatwhen()  {
3957 # {{{
3958     local usage help ident format_l format_s first_char remain first last
3959     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3960     help='Use' \`'whatwhen -h'\'' for further explanations.'
3961     ident=${(l,${#${:-Usage: }},, ,)}
3962     format_l="${ident}%s\t\t\t%s\n"
3963     format_s="${format_l//(\\t)##/\\t}"
3964     # Make the first char of the word to search for case
3965     # insensitive; e.g. [aA]
3966     first_char=[${(L)1[1]}${(U)1[1]}]
3967     remain=${1[2,-1]}
3968     # Default search range is `-100'.
3969     first=${2:-\-100}
3970     # Optional, just used for `<first> <last>' given.
3971     last=$3
3972     case $1 in
3973         ("")
3974             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3975             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3976         ;;
3977         (-h)
3978             printf '%s\n\n' ${usage}
3979             print 'OPTIONS:'
3980             printf $format_l '-h' 'show help text'
3981             print '\f'
3982             print 'SEARCH RANGE:'
3983             printf $format_l "'0'" 'the whole history,'
3984             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
3985             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
3986             printf '\n%s\n' 'EXAMPLES:'
3987             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
3988             printf $format_l 'whatwhen zsh -250'
3989             printf $format_l 'whatwhen foo 1 99'
3990         ;;
3991         (\?)
3992             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3993         ;;
3994         (*)
3995             # -l list results on stout rather than invoking $EDITOR.
3996             # -i Print dates as in YYYY-MM-DD.
3997             # -m Search for a - quoted - pattern within the history.
3998             fc -li -m "*${first_char}${remain}*" $first $last
3999         ;;
4000     esac
4001 # }}}
4002 }
4003
4004 # change fluxbox keys from 'Alt-#' to 'Alt-F#' and vice versa
4005 fluxkey-change() {
4006     [[ -n "$FLUXKEYS" ]] || local FLUXKEYS="$HOME/.fluxbox/keys"
4007     if ! [[ -r "$FLUXKEYS" ]] ; then
4008         echo "Sorry, \$FLUXKEYS file $FLUXKEYS could not be read - nothing to be done."
4009         return 1
4010     else
4011         if grep -q 'Mod1 F[0-9] :Workspace [0-9]' $FLUXKEYS ; then
4012             echo -n 'Switching to Alt-# mode in ~/.fluxbox/keys: '
4013             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)F\([0-9]\+[: space :]\+:Workspace.*\)|\1\2|' $FLUXKEYS && echo done || echo failed
4014         elif grep -q 'Mod1 [0-9] :Workspace [0-9]' $FLUXKEYS ; then
4015             echo -n 'Switching to Alt-F# mode in ~/.fluxbox/keys: '
4016             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)\([0-9]\+[: space :]\+:Workspace.*\)|\1F\2|' $FLUXKEYS && echo done || echo failed
4017         else
4018             echo 'Sorry, do not know what to do.'
4019             return 1
4020         fi
4021     fi
4022 }
4023
4024 # retrieve weather information on the console
4025 # Usage example: 'weather LOWG'
4026 weather() {
4027     [[ -n "$1" ]] || {
4028         print 'Usage: weather <station_id>' >&2
4029         print 'List of stations: http://en.wikipedia.org/wiki/List_of_airports_by_ICAO_code'>&2
4030         return 1
4031     }
4032
4033     local PLACE="${1:u}"
4034     local FILE="$HOME/.weather/$PLACE"
4035     local LOG="$HOME/.weather/log"
4036
4037     [[ -d $HOME/.weather ]] || {
4038         print -n "Creating $HOME/.weather: "
4039         mkdir $HOME/.weather
4040         print 'done'
4041     }
4042
4043     print "Retrieving information for ${PLACE}:"
4044     print
4045     wget -T 10 --no-verbose --output-file=$LOG --output-document=$FILE --timestamping http://weather.noaa.gov/pub/data/observations/metar/decoded/$PLACE.TXT
4046
4047     if [[ $? -eq 0 ]] ; then
4048         if [[ -n "$VERBOSE" ]] ; then
4049             cat $FILE
4050         else
4051             DATE=$(grep 'UTC' $FILE | sed 's#.* /##')
4052             TEMPERATURE=$(awk '/Temperature/ { print $4" degree Celcius / " $2" degree Fahrenheit" }' $FILE| tr -d '(')
4053             echo "date: $DATE"
4054             echo "temp:  $TEMPERATURE"
4055         fi
4056     else
4057         print "There was an error retrieving the weather information for $PLACE" >&2
4058         cat $LOG
4059         return 1
4060     fi
4061 }
4062 # }}}
4063
4064 # mercurial related stuff {{{
4065 if check_com -c hg ; then
4066     # gnu like diff for mercurial
4067     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
4068     #f5# GNU like diff for mercurial
4069     hgdi() {
4070         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
4071     }
4072
4073     # build debian package
4074     #a2# Alias for \kbd{hg-buildpackage}
4075     alias hbp='hg-buildpackage'
4076
4077     # execute commands on the versioned patch-queue from the current repos
4078     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
4079
4080     # diffstat for specific version of a mercurial repository
4081     #   hgstat      => display diffstat between last revision and tip
4082     #   hgstat 1234 => display diffstat between revision 1234 and tip
4083     #f5# Diffstat for specific version of a mercurial repos
4084     hgstat() {
4085         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
4086     }
4087
4088     #f5# Get current mercurial tip via hg itself
4089     gethgclone() {
4090         setopt local_options
4091         setopt errreturn
4092         if [[ -f mercurial-tree/.hg ]] ; then
4093             cd mercurial-tree
4094             echo "Running hg pull for retreiving latest version..."
4095             hg pull
4096             echo "Finished update. Building mercurial"
4097             make local
4098             echo "Setting \$PATH to $PWD:\$PATH..."
4099             export PATH="$PWD:$PATH"
4100         else
4101             echo "Downloading mercurial via hg"
4102             hg clone http://selenic.com/repo/hg mercurial-tree
4103             cd mercurial-tree
4104             echo "Building mercurial"
4105             make local
4106             echo "Setting \$PATH to $PWD:\$PATH..."
4107             export PATH="$PWD:$PATH"
4108             echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4109             # echo "Setting \$PYTHONPATH to PYTHONPATH=\${HOME}/lib/python,"
4110             # export PYTHONPATH=${HOME}/lib/python
4111         fi
4112     }
4113
4114 fi # end of check whether we have the 'hg'-executable
4115
4116 # get current mercurial snapshot
4117 #f5# Get current mercurial snapshot
4118 gethgsnap() {
4119     setopt local_options
4120     setopt errreturn
4121     if [[ -f mercurial-snapshot.tar.gz ]] ; then
4122          echo "mercurial-snapshot.tar.gz exists already, skipping download."
4123     else
4124         echo "Downloading mercurial snapshot"
4125         wget http://www.selenic.com/mercurial/mercurial-snapshot.tar.gz
4126     fi
4127     echo "Unpacking mercurial-snapshot.tar.gz"
4128     tar zxf mercurial-snapshot.tar.gz
4129     cd mercurial-snapshot/
4130     echo "Installing required build-dependencies"
4131     $SUDO apt-get update
4132     $SUDO apt-get install python2.4-dev
4133     echo "Building mercurial"
4134     make local
4135     echo "Setting \$PATH to $PWD:\$PATH..."
4136     export PATH="$PWD:$PATH"
4137     echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4138 }
4139 # }}}
4140
4141 # some useful commands often hard to remember - let's grep for them {{{
4142 # actually use our zg() function now. :)
4143
4144 # Work around ion/xterm resize bug.
4145 #if [[ "$SHLVL" -eq 1 ]]; then
4146 #       if check_com -c resize ; then
4147 #               eval `resize </dev/null`
4148 #       fi
4149 #fi
4150
4151 # enable jackd:
4152 #  /usr/bin/jackd -dalsa -dhw:0 -r48000 -p1024 -n2
4153 # now play audio file:
4154 #  alsaplayer -o jack foobar.mp3
4155
4156 # send files via netcat
4157 # on sending side:
4158 #  send() {j=$*; tar cpz ${j/%${!#}/}|nc -w 1 ${!#} 51330;}
4159 #  send dir* $HOST
4160 #  alias receive='nc -vlp 51330 | tar xzvp'
4161
4162 # debian stuff:
4163 # dh_make -e foo@localhost -f $1
4164 # dpkg-buildpackage -rfakeroot
4165 # lintian *.deb
4166 # dpkg-scanpackages ./ /dev/null | gzip > Packages.gz
4167 # dpkg-scansources . | gzip > Sources.gz
4168 # grep-dctrl --field Maintainer $* /var/lib/apt/lists/*
4169
4170 # other stuff:
4171 # convert -geometry 200x200 -interlace LINE -verbose
4172 # ldapsearch -x -b "OU=Bedienstete,O=tug" -h ldap.tugraz.at sn=$1
4173 # ps -ao user,pcpu,start,command
4174 # gpg --keyserver blackhole.pca.dfn.de --recv-keys
4175 # xterm -bg black -fg yellow -fn -misc-fixed-medium-r-normal--14-140-75-75-c-90-iso8859-15 -ah
4176 # nc -vz $1 1-1024   # portscan via netcat
4177 # wget --mirror --no-parent --convert-links
4178 # pal -d `date +%d`
4179 # autoload -U tetris; zle -N tetris; bindkey '...' ; echo "press ... for playing tennis"
4180 #
4181 # modify console cursor
4182 # see http://www.tldp.org/HOWTO/Framebuffer-HOWTO-5.html
4183 # print $'\e[?96;0;64c'
4184 # }}}
4185
4186 # grml-small cleanups {{{
4187
4188 # The following is used to remove zsh-config-items that do not work
4189 # in grml-small by default.
4190 # If you do not want these adjustments (for whatever reason), set
4191 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
4192 # sources if it is there).
4193
4194 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
4195
4196     unset abk[V]
4197     unalias    'V'      &> /dev/null
4198     unfunction vman     &> /dev/null
4199     unfunction vimpm    &> /dev/null
4200     unfunction vimhelp  &> /dev/null
4201     unfunction viless   &> /dev/null
4202     unfunction 2html    &> /dev/null
4203
4204     # manpages are not in grmlsmall
4205     unfunction manzsh   &> /dev/null
4206     unalias    man2     &> /dev/null
4207     unalias    man      &> /dev/null
4208     unfunction man2     &> /dev/null
4209
4210 fi
4211
4212 #}}}
4213
4214 zrclocal
4215
4216 ## genrefcard.pl settings {{{
4217
4218 ### doc strings for external functions from files
4219 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
4220
4221 ### example: split functions-search 8,16,24,32
4222 #@# split functions-search 8
4223
4224 ## }}}
4225
4226 ## END OF FILE #################################################################
4227 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4