etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is437(){
 148     [[ $ZSH_VERSION == 4.3.<7->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 is439(){
 154     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 155                                  || $ZSH_VERSION == <5->* ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running grml
 160 isgrml(){
 161     [[ -f /etc/grml_version ]] && return 0
 162     return 1
 163 }
 164
 165 #f1# Checks whether or not you're running a grml cd
 166 isgrmlcd(){
 167     [[ -f /etc/grml_cd ]] && return 0
 168     return 1
 169 }
 170
 171 if isgrml ; then
 172 #f1# Checks whether or not you're running grml-small
 173     isgrmlsmall() {
 174         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 175             return 0
 176         fi
 177         return 1
 178     }
 179 else
 180     isgrmlsmall() { return 1 }
 181 fi
 182
 183 GRML_OSTYPE=$(uname -s)
 184
 185 islinux(){
 186     [[ $GRML_OSTYPE == "Linux" ]]
 187 }
 188
 189 isdarwin(){
 190     [[ $GRML_OSTYPE == "Darwin" ]]
 191 }
 192
 193 isfreebsd(){
 194     [[ $GRML_OSTYPE == "FreeBSD" ]]
 195 }
 196
 197 isopenbsd(){
 198     [[ $GRML_OSTYPE == "OpenBSD" ]]
 199 }
 200
 201 issolaris(){
 202     [[ $GRML_OSTYPE == "SunOS" ]]
 203 }
 204
 205 #f1# are we running within an utf environment?
 206 isutfenv() {
 207     case "$LANG $CHARSET $LANGUAGE" in
 208         *utf*) return 0 ;;
 209         *UTF*) return 0 ;;
 210         *)     return 1 ;;
 211     esac
 212 }
 213
 214 # check for user, if not running as root set $SUDO to sudo
 215 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 216
 217 # change directory to home on first invocation of zsh
 218 # important for rungetty -> autologin
 219 # Thanks go to Bart Schaefer!
 220 isgrml && checkhome() {
 221     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 222         export ALREADY_DID_CD_HOME=$HOME
 223         cd
 224     fi
 225 }
 226
 227 # check for zsh v3.1.7+
 228
 229 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 230      || ${ZSH_VERSION} == 3.<2->.<->*    \
 231      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 232
 233     printf '-!-\n'
 234     printf '-!- In this configuration we try to make use of features, that only\n'
 235     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 236     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 237     printf '-!- advanced features in all supported versions.\n'
 238     printf '-!-\n'
 239     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 240     printf '-!-\n'
 241     printf '-!- While this *may* work, it might as well fail.\n'
 242     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 243     printf '-!-\n'
 244     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 245     printf '-!- If it does today, you'\''ve been lucky.\n'
 246     printf '-!-\n'
 247     printf '-!- Ye been warned!\n'
 248     printf '-!-\n'
 249
 250     function zstyle() { : }
 251 fi
 252
 253 # autoload wrapper - use this one instead of autoload directly
 254 # We need to define this function as early as this, because autoloading
 255 # 'is-at-least()' needs it.
 256 function zrcautoload() {
 257     emulate -L zsh
 258     setopt extended_glob
 259     local fdir ffile
 260     local -i ffound
 261
 262     ffile=$1
 263     (( ffound = 0 ))
 264     for fdir in ${fpath} ; do
 265         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 266     done
 267
 268     (( ffound == 0 )) && return 1
 269     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 270         autoload -U ${ffile} || return 1
 271     else
 272         autoload ${ffile} || return 1
 273     fi
 274     return 0
 275 }
 276
 277 # The following is the ‘add-zsh-hook’ function from zsh upstream. It is
 278 # included here to make the setup work with older versions of zsh (prior to
 279 # 4.3.7) in which this function had a bug that triggers annoying errors during
 280 # shell startup. This is exactly upstreams code from f0068edb4888a4d8fe94def,
 281 # with just a few adjustments in coding style to make the function look more
 282 # compact. This definition can be removed as soon as we raise the minimum
 283 # version requirement to 4.3.7 or newer.
 284 function add-zsh-hook() {
 285     # Add to HOOK the given FUNCTION.
 286     # HOOK is one of chpwd, precmd, preexec, periodic, zshaddhistory,
 287     # zshexit, zsh_directory_name (the _functions subscript is not required).
 288     #
 289     # With -d, remove the function from the hook instead; delete the hook
 290     # variable if it is empty.
 291     #
 292     # -D behaves like -d, but pattern characters are active in the function
 293     # name, so any matching function will be deleted from the hook.
 294     #
 295     # Without -d, the FUNCTION is marked for autoload; -U is passed down to
 296     # autoload if that is given, as are -z and -k. (This is harmless if the
 297     # function is actually defined inline.)
 298     emulate -L zsh
 299     local -a hooktypes
 300     hooktypes=(
 301         chpwd precmd preexec periodic zshaddhistory zshexit
 302         zsh_directory_name
 303     )
 304     local usage="Usage: $0 hook function\nValid hooks are:\n  $hooktypes"
 305     local opt
 306     local -a autoopts
 307     integer del list help
 308     while getopts "dDhLUzk" opt; do
 309         case $opt in
 310         (d) del=1 ;;
 311         (D) del=2 ;;
 312         (h) help=1 ;;
 313         (L) list=1 ;;
 314         ([Uzk]) autoopts+=(-$opt) ;;
 315         (*) return 1 ;;
 316         esac
 317     done
 318     shift $(( OPTIND - 1 ))
 319     if (( list )); then
 320         typeset -mp "(${1:-${(@j:|:)hooktypes}})_functions"
 321         return $?
 322     elif (( help || $# != 2 || ${hooktypes[(I)$1]} == 0 )); then
 323         print -u$(( 2 - help )) $usage
 324         return $(( 1 - help ))
 325     fi
 326     local hook="${1}_functions"
 327     local fn="$2"
 328     if (( del )); then
 329         # delete, if hook is set
 330         if (( ${(P)+hook} )); then
 331             if (( del == 2 )); then
 332                 set -A $hook ${(P)hook:#${~fn}}
 333             else
 334                 set -A $hook ${(P)hook:#$fn}
 335             fi
 336             # unset if no remaining entries --- this can give better
 337             # performance in some cases
 338             if (( ! ${(P)#hook} )); then
 339                 unset $hook
 340             fi
 341         fi
 342     else
 343         if (( ${(P)+hook} )); then
 344             if (( ${${(P)hook}[(I)$fn]} == 0 )); then
 345                 set -A $hook ${(P)hook} $fn
 346             fi
 347         else
 348             set -A $hook $fn
 349         fi
 350         autoload $autoopts -- $fn
 351     fi
 352 }
 353
 354 # Load is-at-least() for more precise version checks Note that this test will
 355 # *always* fail, if the is-at-least function could not be marked for
 356 # autoloading.
 357 zrcautoload is-at-least || is-at-least() { return 1 }
 358
 359 # set some important options (as early as possible)
 360
 361 # append history list to the history file; this is the default but we make sure
 362 # because it's required for share_history.
 363 setopt append_history
 364
 365 # import new commands from the history file also in other zsh-session
 366 is4 && setopt share_history
 367
 368 # save each command's beginning timestamp and the duration to the history file
 369 setopt extended_history
 370
 371 # If a new command line being added to the history list duplicates an older
 372 # one, the older command is removed from the list
 373 is4 && setopt histignorealldups
 374
 375 # remove command lines from the history list when the first character on the
 376 # line is a space
 377 setopt histignorespace
 378
 379 # if a command is issued that can't be executed as a normal command, and the
 380 # command is the name of a directory, perform the cd command to that directory.
 381 setopt auto_cd
 382
 383 # in order to use #, ~ and ^ for filename generation grep word
 384 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 385 # don't forget to quote '^', '~' and '#'!
 386 setopt extended_glob
 387
 388 # display PID when suspending processes as well
 389 setopt longlistjobs
 390
 391 # report the status of backgrounds jobs immediately
 392 setopt notify
 393
 394 # whenever a command completion is attempted, make sure the entire command path
 395 # is hashed first.
 396 setopt hash_list_all
 397
 398 # not just at the end
 399 setopt completeinword
 400
 401 # Don't send SIGHUP to background processes when the shell exits.
 402 setopt nohup
 403
 404 # make cd push the old directory onto the directory stack.
 405 setopt auto_pushd
 406
 407 # avoid "beep"ing
 408 setopt nobeep
 409
 410 # don't push the same dir twice.
 411 setopt pushd_ignore_dups
 412
 413 # * shouldn't match dotfiles. ever.
 414 setopt noglobdots
 415
 416 # use zsh style word splitting
 417 setopt noshwordsplit
 418
 419 # don't error out when unset parameters are used
 420 setopt unset
 421
 422 # setting some default values
 423 NOCOR=${NOCOR:-0}
 424 NOMENU=${NOMENU:-0}
 425 NOPRECMD=${NOPRECMD:-0}
 426 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 427 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 428 GRML_DISPLAY_BATTERY=${GRML_DISPLAY_BATTERY:-${BATTERY:-0}}
 429 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 430 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 431
 432 typeset -ga ls_options
 433 typeset -ga grep_options
 434 if ls --color=auto / >/dev/null 2>&1; then
 435     ls_options+=( --color=auto )
 436 elif ls -G / >/dev/null 2>&1; then
 437     ls_options+=( -G )
 438 fi
 439 if grep --color=auto -q "a" <<< "a" >/dev/null 2>&1; then
 440     grep_options+=( --color=auto )
 441 fi
 442
 443 # utility functions
 444 # this function checks if a command exists and returns either true
 445 # or false. This avoids using 'which' and 'whence', which will
 446 # avoid problems with aliases for which on certain weird systems. :-)
 447 # Usage: check_com [-c|-g] word
 448 #   -c  only checks for external commands
 449 #   -g  does the usual tests and also checks for global aliases
 450 check_com() {
 451     emulate -L zsh
 452     local -i comonly gatoo
 453     comonly=0
 454     gatoo=0
 455
 456     if [[ $1 == '-c' ]] ; then
 457         comonly=1
 458         shift 1
 459     elif [[ $1 == '-g' ]] ; then
 460         gatoo=1
 461         shift 1
 462     fi
 463
 464     if (( ${#argv} != 1 )) ; then
 465         printf 'usage: check_com [-c|-g] <command>\n' >&2
 466         return 1
 467     fi
 468
 469     if (( comonly > 0 )) ; then
 470         (( ${+commands[$1]}  )) && return 0
 471         return 1
 472     fi
 473
 474     if     (( ${+commands[$1]}    )) \
 475         || (( ${+functions[$1]}   )) \
 476         || (( ${+aliases[$1]}     )) \
 477         || (( ${+reswords[(r)$1]} )) ; then
 478         return 0
 479     fi
 480
 481     if (( gatoo > 0 )) && (( ${+galiases[$1]} )) ; then
 482         return 0
 483     fi
 484
 485     return 1
 486 }
 487
 488 # creates an alias and precedes the command with
 489 # sudo if $EUID is not zero.
 490 salias() {
 491     emulate -L zsh
 492     local only=0 ; local multi=0
 493     local key val
 494     while getopts ":hao" opt; do
 495         case $opt in
 496             o) only=1 ;;
 497             a) multi=1 ;;
 498             h)
 499                 printf 'usage: salias [-hoa] <alias-expression>\n'
 500                 printf '  -h      shows this help text.\n'
 501                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 502                 printf '          be careful using this option.\n'
 503                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 504                 return 0
 505                 ;;
 506             *) salias -h >&2; return 1 ;;
 507         esac
 508     done
 509     shift "$((OPTIND-1))"
 510
 511     if (( ${#argv} > 1 )) ; then
 512         printf 'Too many arguments %s\n' "${#argv}"
 513         return 1
 514     fi
 515
 516     key="${1%%\=*}" ;  val="${1#*\=}"
 517     if (( EUID == 0 )) && (( only == 0 )); then
 518         alias -- "${key}=${val}"
 519     elif (( EUID > 0 )) ; then
 520         (( multi > 0 )) && val="${val// ; / ; sudo }"
 521         alias -- "${key}=sudo ${val}"
 522     fi
 523
 524     return 0
 525 }
 526
 527 # Check if we can read given files and source those we can.
 528 xsource() {
 529     if (( ${#argv} < 1 )) ; then
 530         printf 'usage: xsource FILE(s)...\n' >&2
 531         return 1
 532     fi
 533
 534     while (( ${#argv} > 0 )) ; do
 535         [[ -r "$1" ]] && source "$1"
 536         shift
 537     done
 538     return 0
 539 }
 540
 541 # Check if we can read a given file and 'cat(1)' it.
 542 xcat() {
 543     emulate -L zsh
 544     if (( ${#argv} != 1 )) ; then
 545         printf 'usage: xcat FILE\n' >&2
 546         return 1
 547     fi
 548
 549     [[ -r $1 ]] && cat $1
 550     return 0
 551 }
 552
 553 # Remove these functions again, they are of use only in these
 554 # setup files. This should be called at the end of .zshrc.
 555 xunfunction() {
 556     emulate -L zsh
 557     local -a funcs
 558     local func
 559     funcs=(salias xcat xsource xunfunction zrcautoload zrcautozle)
 560     for func in $funcs ; do
 561         [[ -n ${functions[$func]} ]] \
 562             && unfunction $func
 563     done
 564     return 0
 565 }
 566
 567 # this allows us to stay in sync with grml's zshrc and put own
 568 # modifications in ~/.zshrc.local
 569 zrclocal() {
 570     xsource "/etc/zsh/zshrc.local"
 571     xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
 572     return 0
 573 }
 574
 575 # locale setup
 576 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 577     xsource "/etc/default/locale"
 578 fi
 579
 580 for var in LANG LC_ALL LC_MESSAGES ; do
 581     [[ -n ${(P)var} ]] && export $var
 582 done
 583 builtin unset -v var
 584
 585 # set some variables
 586 if check_com -c vim ; then
 587 #v#
 588     export EDITOR=${EDITOR:-vim}
 589 else
 590     export EDITOR=${EDITOR:-vi}
 591 fi
 592
 593 #v#
 594 export PAGER=${PAGER:-less}
 595
 596 #v#
 597 export MAIL=${MAIL:-/var/mail/$USER}
 598
 599 # color setup for ls:
 600 check_com -c dircolors && eval $(dircolors -b)
 601 # color setup for ls on OS X / FreeBSD:
 602 isdarwin && export CLICOLOR=1
 603 isfreebsd && export CLICOLOR=1
 604
 605 # do MacPorts setup on darwin
 606 if isdarwin && [[ -d /opt/local ]]; then
 607     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 608     # zshenv.
 609     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 610     MANPATH="/opt/local/share/man:$MANPATH"
 611 fi
 612 # do Fink setup on darwin
 613 isdarwin && xsource /sw/bin/init.sh
 614
 615 # load our function and completion directories
 616 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 617     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 618     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 619         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 620             zrcautoload ${func:t}
 621         done
 622     fi
 623 done
 624 unset fdir func
 625
 626 # support colors in less
 627 export LESS_TERMCAP_mb=$'\E[01;31m'
 628 export LESS_TERMCAP_md=$'\E[01;31m'
 629 export LESS_TERMCAP_me=$'\E[0m'
 630 export LESS_TERMCAP_se=$'\E[0m'
 631 export LESS_TERMCAP_so=$'\E[01;44;33m'
 632 export LESS_TERMCAP_ue=$'\E[0m'
 633 export LESS_TERMCAP_us=$'\E[01;32m'
 634
 635 # mailchecks
 636 MAILCHECK=30
 637
 638 # report about cpu-/system-/user-time of command if running longer than
 639 # 5 seconds
 640 REPORTTIME=5
 641
 642 # watch for everyone but me and root
 643 watch=(notme root)
 644
 645 # automatically remove duplicates from these arrays
 646 typeset -U path cdpath fpath manpath
 647
 648 # Load a few modules
 649 is4 && \
 650 for mod in parameter complist deltochar mathfunc ; do
 651     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 652 done && builtin unset -v mod
 653
 654 # autoload zsh modules when they are referenced
 655 if is4 ; then
 656     zmodload -a  zsh/stat    zstat
 657     zmodload -a  zsh/zpty    zpty
 658     zmodload -ap zsh/mapfile mapfile
 659 fi
 660
 661 # completion system
 662 COMPDUMPFILE=${COMPDUMPFILE:-${ZDOTDIR:-${HOME}}/.zcompdump}
 663 if zrcautoload compinit ; then
 664     compinit -d ${COMPDUMPFILE} || print 'Notice: no compinit available :('
 665 else
 666     print 'Notice: no compinit available :('
 667     function compdef { }
 668 fi
 669
 670 # completion system
 671
 672 # called later (via is4 && grmlcomp)
 673 # note: use 'zstyle' for getting current settings
 674 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
 675 grmlcomp() {
 676     # TODO: This could use some additional information
 677
 678     # Make sure the completion system is initialised
 679     (( ${+_comps} )) || return 1
 680
 681     # allow one error for every three characters typed in approximate completer
 682     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
 683
 684     # don't complete backup files as executables
 685     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
 686
 687     # start menu completion only if it could find no unambiguous initial string
 688     zstyle ':completion:*:correct:*'       insert-unambiguous true
 689     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
 690     zstyle ':completion:*:correct:*'       original true
 691
 692     # activate color-completion
 693     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
 694
 695     # format on completion
 696     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
 697
 698     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
 699     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
 700
 701     # insert all expansions for expand completer
 702     zstyle ':completion:*:expand:*'        tag-order all-expansions
 703     zstyle ':completion:*:history-words'   list false
 704
 705     # activate menu
 706     zstyle ':completion:*:history-words'   menu yes
 707
 708     # ignore duplicate entries
 709     zstyle ':completion:*:history-words'   remove-all-dups yes
 710     zstyle ':completion:*:history-words'   stop yes
 711
 712     # match uppercase from lowercase
 713     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
 714
 715     # separate matches into groups
 716     zstyle ':completion:*:matches'         group 'yes'
 717     zstyle ':completion:*'                 group-name ''
 718
 719     if [[ "$NOMENU" -eq 0 ]] ; then
 720         # if there are more than 5 options allow selecting from a menu
 721         zstyle ':completion:*'               menu select=5
 722     else
 723         # don't use any menus at all
 724         setopt no_auto_menu
 725     fi
 726
 727     zstyle ':completion:*:messages'        format '%d'
 728     zstyle ':completion:*:options'         auto-description '%d'
 729
 730     # describe options in full
 731     zstyle ':completion:*:options'         description 'yes'
 732
 733     # on processes completion complete all user processes
 734     zstyle ':completion:*:processes'       command 'ps -au$USER'
 735
 736     # offer indexes before parameters in subscripts
 737     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
 738
 739     # provide verbose completion information
 740     zstyle ':completion:*'                 verbose true
 741
 742     # recent (as of Dec 2007) zsh versions are able to provide descriptions
 743     # for commands (read: 1st word in the line) that it will list for the user
 744     # to choose from. The following disables that, because it's not exactly fast.
 745     zstyle ':completion:*:-command-:*:'    verbose false
 746
 747     # set format for warnings
 748     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
 749
 750     # define files to ignore for zcompile
 751     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
 752     zstyle ':completion:correct:'          prompt 'correct to: %e'
 753
 754     # Ignore completion functions for commands you don't have:
 755     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
 756
 757     # Provide more processes in completion of programs like killall:
 758     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
 759
 760     # complete manual by their section
 761     zstyle ':completion:*:manuals'    separate-sections true
 762     zstyle ':completion:*:manuals.*'  insert-sections   true
 763     zstyle ':completion:*:man:*'      menu yes select
 764
 765     # Search path for sudo completion
 766     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
 767                                                /usr/local/bin  \
 768                                                /usr/sbin       \
 769                                                /usr/bin        \
 770                                                /sbin           \
 771                                                /bin            \
 772                                                /usr/X11R6/bin
 773
 774     # provide .. as a completion
 775     zstyle ':completion:*' special-dirs ..
 776
 777     # run rehash on completion so new installed program are found automatically:
 778     _force_rehash() {
 779         (( CURRENT == 1 )) && rehash
 780         return 1
 781     }
 782
 783     ## correction
 784     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
 785     if [[ "$NOCOR" -gt 0 ]] ; then
 786         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
 787         setopt nocorrect
 788     else
 789         # try to be smart about when to use what completer...
 790         setopt correct
 791         zstyle -e ':completion:*' completer '
 792             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
 793                 _last_try="$HISTNO$BUFFER$CURSOR"
 794                 reply=(_complete _match _ignored _prefix _files)
 795             else
 796                 if [[ $words[1] == (rm|mv) ]] ; then
 797                     reply=(_complete _files)
 798                 else
 799                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
 800                 fi
 801             fi'
 802     fi
 803
 804     # command for process lists, the local web server details and host completion
 805     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
 806
 807     # Some functions, like _apt and _dpkg, are very slow. We can use a cache in
 808     # order to speed things up
 809     if [[ ${GRML_COMP_CACHING:-yes} == yes ]]; then
 810         GRML_COMP_CACHE_DIR=${GRML_COMP_CACHE_DIR:-${ZDOTDIR:-$HOME}/.cache}
 811         if [[ ! -d ${GRML_COMP_CACHE_DIR} ]]; then
 812             command mkdir -p "${GRML_COMP_CACHE_DIR}"
 813         fi
 814         zstyle ':completion:*' use-cache  yes
 815         zstyle ':completion:*:complete:*' cache-path "${GRML_COMP_CACHE_DIR}"
 816     fi
 817
 818     # host completion
 819     if is42 ; then
 820         [[ -r ~/.ssh/config ]] && _ssh_config_hosts=(${${(s: :)${(ps:\t:)${${(@M)${(f)"$(<$HOME/.ssh/config)"}:#Host *}#Host }}}:#*[*?]*}) || _ssh_config_hosts=()
 821         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
 822         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
 823     else
 824         _ssh_config_hosts=()
 825         _ssh_hosts=()
 826         _etc_hosts=()
 827     fi
 828     hosts=(
 829         $(hostname)
 830         "$_ssh_config_hosts[@]"
 831         "$_ssh_hosts[@]"
 832         "$_etc_hosts[@]"
 833         localhost
 834     )
 835     zstyle ':completion:*:hosts' hosts $hosts
 836     # TODO: so, why is this here?
 837     #  zstyle '*' hosts $hosts
 838
 839     # use generic completion system for programs not yet defined; (_gnu_generic works
 840     # with commands that provide a --help option with "standard" gnu-like output.)
 841     for compcom in cp deborphan df feh fetchipac gpasswd head hnb ipacsum mv \
 842                    pal stow uname ; do
 843         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
 844     done; unset compcom
 845
 846     # see upgrade function in this file
 847     compdef _hosts upgrade
 848 }
 849
 850 # Keyboard setup: The following is based on the same code, we wrote for
 851 # debian's setup. It ensures the terminal is in the right mode, when zle is
 852 # active, so the values from $terminfo are valid. Therefore, this setup should
 853 # work on all systems, that have support for `terminfo'. It also requires the
 854 # zsh in use to have the `zsh/terminfo' module built.
 855 #
 856 # If you are customising your `zle-line-init()' or `zle-line-finish()'
 857 # functions, make sure you call the following utility functions in there:
 858 #
 859 #     - zle-line-init():      zle-smkx
 860 #     - zle-line-finish():    zle-rmkx
 861
 862 # Use emacs-like key bindings by default:
 863 bindkey -e
 864
 865 # Custom widgets:
 866
 867 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 868 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 869 beginning-or-end-of-somewhere() {
 870     local hno=$HISTNO
 871     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 872       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 873         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 874     else
 875         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 876         if (( HISTNO != hno )); then
 877             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 878         fi
 879     fi
 880 }
 881 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 882 zle -N end-of-somewhere beginning-or-end-of-somewhere
 883
 884 # add a command line to the shells history without executing it
 885 commit-to-history() {
 886     print -s ${(z)BUFFER}
 887     zle send-break
 888 }
 889 zle -N commit-to-history
 890
 891 # only slash should be considered as a word separator:
 892 slash-backward-kill-word() {
 893     local WORDCHARS="${WORDCHARS:s@/@}"
 894     # zle backward-word
 895     zle backward-kill-word
 896 }
 897 zle -N slash-backward-kill-word
 898
 899 # a generic accept-line wrapper
 900
 901 # This widget can prevent unwanted autocorrections from command-name
 902 # to _command-name, rehash automatically on enter and call any number
 903 # of builtin and user-defined widgets in different contexts.
 904 #
 905 # For a broader description, see:
 906 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 907 #
 908 # The code is imported from the file 'zsh/functions/accept-line' from
 909 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 910 # distributed under the same terms as zsh itself.
 911
 912 # A newly added command will may not be found or will cause false
 913 # correction attempts, if you got auto-correction set. By setting the
 914 # following style, we force accept-line() to rehash, if it cannot
 915 # find the first word on the command line in the $command[] hash.
 916 zstyle ':acceptline:*' rehash true
 917
 918 function Accept-Line() {
 919     setopt localoptions noksharrays
 920     local -a subs
 921     local -xi aldone
 922     local sub
 923     local alcontext=${1:-$alcontext}
 924
 925     zstyle -a ":acceptline:${alcontext}" actions subs
 926
 927     (( ${#subs} < 1 )) && return 0
 928
 929     (( aldone = 0 ))
 930     for sub in ${subs} ; do
 931         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 932         zle ${sub}
 933
 934         (( aldone > 0 )) && break
 935     done
 936 }
 937
 938 function Accept-Line-getdefault() {
 939     emulate -L zsh
 940     local default_action
 941
 942     zstyle -s ":acceptline:${alcontext}" default_action default_action
 943     case ${default_action} in
 944         ((accept-line|))
 945             printf ".accept-line"
 946             ;;
 947         (*)
 948             printf ${default_action}
 949             ;;
 950     esac
 951 }
 952
 953 function Accept-Line-HandleContext() {
 954     zle Accept-Line
 955
 956     default_action=$(Accept-Line-getdefault)
 957     zstyle -T ":acceptline:${alcontext}" call_default \
 958         && zle ${default_action}
 959 }
 960
 961 function accept-line() {
 962     setopt localoptions noksharrays
 963     local -a cmdline
 964     local -x alcontext
 965     local buf com fname format msg default_action
 966
 967     alcontext='default'
 968     buf="${BUFFER}"
 969     cmdline=(${(z)BUFFER})
 970     com="${cmdline[1]}"
 971     fname="_${com}"
 972
 973     Accept-Line 'preprocess'
 974
 975     zstyle -t ":acceptline:${alcontext}" rehash \
 976         && [[ -z ${commands[$com]} ]]           \
 977         && rehash
 978
 979     if    [[ -n ${com}               ]] \
 980        && [[ -n ${reswords[(r)$com]} ]] \
 981        || [[ -n ${aliases[$com]}     ]] \
 982        || [[ -n ${functions[$com]}   ]] \
 983        || [[ -n ${builtins[$com]}    ]] \
 984        || [[ -n ${commands[$com]}    ]] ; then
 985
 986         # there is something sensible to execute, just do it.
 987         alcontext='normal'
 988         Accept-Line-HandleContext
 989
 990         return
 991     fi
 992
 993     if    [[ -o correct              ]] \
 994        || [[ -o correctall           ]] \
 995        && [[ -n ${functions[$fname]} ]] ; then
 996
 997         # nothing there to execute but there is a function called
 998         # _command_name; a completion widget. Makes no sense to
 999         # call it on the commandline, but the correct{,all} options
1000         # will ask for it nevertheless, so warn the user.
1001         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
1002             # Okay, we warned the user before, he called us again,
1003             # so have it his way.
1004             alcontext='force'
1005             Accept-Line-HandleContext
1006
1007             return
1008         fi
1009
1010         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
1011             alcontext='normal'
1012             Accept-Line-HandleContext
1013         else
1014             # prepare warning message for the user, configurable via zstyle.
1015             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
1016
1017             if [[ -z ${msg} ]] ; then
1018                 msg="%c will not execute and completion %f exists."
1019             fi
1020
1021             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
1022
1023             zle -M -- "${msg}"
1024         fi
1025         return
1026     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
1027         # If we are here, the commandline contains something that is not
1028         # executable, which is neither subject to _command_name correction
1029         # and is not empty. might be a variable assignment
1030         alcontext='misc'
1031         Accept-Line-HandleContext
1032
1033         return
1034     fi
1035
1036     # If we got this far, the commandline only contains whitespace, or is empty.
1037     alcontext='empty'
1038     Accept-Line-HandleContext
1039 }
1040
1041 zle -N accept-line
1042 zle -N Accept-Line
1043 zle -N Accept-Line-HandleContext
1044
1045 # power completion / abbreviation expansion / buffer expansion
1046 # see http://zshwiki.org/home/examples/zleiab for details
1047 # less risky than the global aliases but powerful as well
1048 # just type the abbreviation key and afterwards 'ctrl-x .' to expand it
1049 declare -A abk
1050 setopt extendedglob
1051 setopt interactivecomments
1052 abk=(
1053 #   key   # value                  (#d additional doc string)
1054 #A# start
1055     '...'  '../..'
1056     '....' '../../..'
1057     'BG'   '& exit'
1058     'C'    '| wc -l'
1059     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
1060     'H'    '| head'
1061     'Hl'   ' --help |& less -r'    #d (Display help in pager)
1062     'L'    '| less'
1063     'LL'   '|& less -r'
1064     'M'    '| most'
1065     'N'    '&>/dev/null'           #d (No Output)
1066     'R'    '| tr A-z N-za-m'       #d (ROT13)
1067     'SL'   '| sort | less'
1068     'S'    '| sort -u'
1069     'T'    '| tail'
1070     'V'    '|& vim -'
1071 #A# end
1072     'co'   './configure && make && sudo make install'
1073 )
1074
1075 zleiab() {
1076     emulate -L zsh
1077     setopt extendedglob
1078     local MATCH
1079
1080     LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
1081     LBUFFER+=${abk[$MATCH]:-$MATCH}
1082 }
1083
1084 zle -N zleiab
1085
1086 help-show-abk()
1087 {
1088   zle -M "$(print "Available abbreviations for expansion:"; print -a -C 2 ${(kv)abk})"
1089 }
1090
1091 zle -N help-show-abk
1092
1093 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1094 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1095 zle -N insert-datestamp
1096
1097 # press esc-m for inserting last typed word again (thanks to caphuso!)
1098 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1099 zle -N insert-last-typed-word;
1100
1101 function grml-zsh-fg() {
1102   if (( ${#jobstates} )); then
1103     zle .push-input
1104     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1105     BUFFER="${BUFFER}fg"
1106     zle .accept-line
1107   else
1108     zle -M 'No background jobs. Doing nothing.'
1109   fi
1110 }
1111 zle -N grml-zsh-fg
1112
1113 # run command line as user root via sudo:
1114 sudo-command-line() {
1115     [[ -z $BUFFER ]] && zle up-history
1116     if [[ $BUFFER != sudo\ * ]]; then
1117         BUFFER="sudo $BUFFER"
1118         CURSOR=$(( CURSOR+5 ))
1119     fi
1120 }
1121 zle -N sudo-command-line
1122
1123 ### jump behind the first word on the cmdline.
1124 ### useful to add options.
1125 function jump_after_first_word() {
1126     local words
1127     words=(${(z)BUFFER})
1128
1129     if (( ${#words} <= 1 )) ; then
1130         CURSOR=${#BUFFER}
1131     else
1132         CURSOR=${#${words[1]}}
1133     fi
1134 }
1135 zle -N jump_after_first_word
1136
1137 #f5# Create directory under cursor or the selected area
1138 inplaceMkDirs() {
1139     # Press ctrl-xM to create the directory under the cursor or the selected area.
1140     # To select an area press ctrl-@ or ctrl-space and use the cursor.
1141     # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
1142     # directory does not exist yet -> press ctrl-XM and problem solved
1143     local PATHTOMKDIR
1144     if ((REGION_ACTIVE==1)); then
1145         local F=$MARK T=$CURSOR
1146         if [[ $F -gt $T ]]; then
1147             F=${CURSOR}
1148             T=${MARK}
1149         fi
1150         # get marked area from buffer and eliminate whitespace
1151         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
1152         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
1153     else
1154         local bufwords iword
1155         bufwords=(${(z)LBUFFER})
1156         iword=${#bufwords}
1157         bufwords=(${(z)BUFFER})
1158         PATHTOMKDIR="${(Q)bufwords[iword]}"
1159     fi
1160     [[ -z "${PATHTOMKDIR}" ]] && return 1
1161     PATHTOMKDIR=${~PATHTOMKDIR}
1162     if [[ -e "${PATHTOMKDIR}" ]]; then
1163         zle -M " path already exists, doing nothing"
1164     else
1165         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
1166         zle end-of-line
1167     fi
1168 }
1169
1170 zle -N inplaceMkDirs
1171
1172 #v1# set number of lines to display per page
1173 HELP_LINES_PER_PAGE=20
1174 #v1# set location of help-zle cache file
1175 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
1176 # helper function for help-zle, actually generates the help text
1177 help_zle_parse_keybindings()
1178 {
1179     emulate -L zsh
1180     setopt extendedglob
1181     unsetopt ksharrays  #indexing starts at 1
1182
1183     #v1# choose files that help-zle will parse for keybindings
1184     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
1185
1186     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
1187         local load_cache=0
1188         local f
1189         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
1190         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
1191     fi
1192
1193     #fill with default keybindings, possibly to be overwriten in a file later
1194     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
1195     local -A help_zle_keybindings
1196     help_zle_keybindings['<Ctrl>@']="set MARK"
1197     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
1198     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
1199     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
1200     help_zle_keybindings['<Ctrl>_']="undo"
1201     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
1202     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
1203     help_zle_keybindings['<Ctrl>e']="goto end of line"
1204     help_zle_keybindings['<Ctrl>t']="transpose charaters"
1205     help_zle_keybindings['<Alt>t']="transpose words"
1206     help_zle_keybindings['<Alt>s']="spellcheck word"
1207     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
1208     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
1209     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
1210     help_zle_keybindings["<Alt>'"]="quote line"
1211     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
1212     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
1213     help_zle_keybindings['<Alt>u']="make next word Uppercase"
1214     help_zle_keybindings['<Alt>l']="make next word lowercase"
1215     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
1216     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
1217     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
1218     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
1219     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
1220     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
1221     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
1222     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
1223     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
1224
1225     #init global variables
1226     unset help_zle_lines help_zle_sln
1227     typeset -g -a help_zle_lines
1228     typeset -g help_zle_sln=1
1229
1230     local k v f cline
1231     local lastkeybind_desc contents     #last description starting with #k# that we found
1232     local num_lines_elapsed=0            #number of lines between last description and keybinding
1233     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
1234     for f in $HELPZLE_KEYBINDING_FILES; do
1235         [[ -r "$f" ]] || continue   #not readable ? skip it
1236         contents="$(<$f)"
1237         for cline in "${(f)contents}"; do
1238             #zsh pattern: matches lines like: #k# ..............
1239             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
1240                 lastkeybind_desc="$match[*]"
1241                 num_lines_elapsed=0
1242             #zsh pattern: matches lines that set a keybinding using bind2map, bindkey or compdef -k
1243             #             ignores lines that are commentend out
1244             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
1245             elif [[ "$cline" == [^#]#(bind2maps[[:space:]](*)-s|bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
1246                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
1247                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
1248                     #substitute keybinding string with something readable
1249                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
1250                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
1251                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
1252                     help_zle_keybindings[${k}]=$lastkeybind_desc
1253                 fi
1254                 lastkeybind_desc=""
1255             else
1256               ((num_lines_elapsed++))
1257             fi
1258         done
1259     done
1260     unset contents
1261     #calculate length of keybinding column
1262     local kstrlen=0
1263     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
1264     #convert the assoc array into preformated lines, which we are able to sort
1265     for k v in ${(kv)help_zle_keybindings[@]}; do
1266         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
1267         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
1268     done
1269     #sort lines alphabetically
1270     help_zle_lines=("${(i)help_zle_lines[@]}")
1271     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
1272     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
1273     zcompile $HELP_ZLE_CACHE_FILE
1274 }
1275 typeset -g help_zle_sln
1276 typeset -g -a help_zle_lines
1277
1278 # Provides (partially autogenerated) help on keybindings and the zsh line editor
1279 help-zle()
1280 {
1281     emulate -L zsh
1282     unsetopt ksharrays  #indexing starts at 1
1283     #help lines already generated ? no ? then do it
1284     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
1285     #already displayed all lines ? go back to the start
1286     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
1287     local sln=$help_zle_sln
1288     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
1289     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
1290     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
1291 }
1292 zle -N help-zle
1293
1294 ## complete word from currently visible Screen or Tmux buffer.
1295 if check_com -c screen || check_com -c tmux; then
1296     _complete_screen_display() {
1297         [[ "$TERM" != "screen" ]] && return 1
1298
1299         local TMPFILE=$(mktemp)
1300         local -U -a _screen_display_wordlist
1301         trap "rm -f $TMPFILE" EXIT
1302
1303         # fill array with contents from screen hardcopy
1304         if ((${+TMUX})); then
1305             #works, but crashes tmux below version 1.4
1306             #luckily tmux -V option to ask for version, was also added in 1.4
1307             tmux -V &>/dev/null || return
1308             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1309         else
1310             screen -X hardcopy $TMPFILE
1311             # screen sucks, it dumps in latin1, apparently always. so recode it
1312             # to system charset
1313             check_com recode && recode latin1 $TMPFILE
1314         fi
1315         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1316         # remove PREFIX to be completed from that array
1317         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1318         compadd -a _screen_display_wordlist
1319     }
1320     #m# k CTRL-x\,\,\,S Complete word from GNU screen buffer
1321     bindkey -r "^xS"
1322     compdef -k _complete_screen_display complete-word '^xS'
1323 fi
1324
1325 # Load a few more functions and tie them to widgets, so they can be bound:
1326
1327 function zrcautozle() {
1328     emulate -L zsh
1329     local fnc=$1
1330     zrcautoload $fnc && zle -N $fnc
1331 }
1332
1333 function zrcgotwidget() {
1334     (( ${+widgets[$1]} ))
1335 }
1336
1337 function zrcgotkeymap() {
1338     [[ -n ${(M)keymaps:#$1} ]]
1339 }
1340
1341 zrcautozle insert-files
1342 zrcautozle edit-command-line
1343 zrcautozle insert-unicode-char
1344 if zrcautoload history-search-end; then
1345     zle -N history-beginning-search-backward-end history-search-end
1346     zle -N history-beginning-search-forward-end  history-search-end
1347 fi
1348 zle -C hist-complete complete-word _generic
1349 zstyle ':completion:hist-complete:*' completer _history
1350
1351 # The actual terminal setup hooks and bindkey-calls:
1352
1353 # An array to note missing features to ease diagnosis in case of problems.
1354 typeset -ga grml_missing_features
1355
1356 function zrcbindkey() {
1357     if (( ARGC )) && zrcgotwidget ${argv[-1]}; then
1358         bindkey "$@"
1359     fi
1360 }
1361
1362 function bind2maps () {
1363     local i sequence widget
1364     local -a maps
1365
1366     while [[ "$1" != "--" ]]; do
1367         maps+=( "$1" )
1368         shift
1369     done
1370     shift
1371
1372     if [[ "$1" == "-s" ]]; then
1373         shift
1374         sequence="$1"
1375     else
1376         sequence="${key[$1]}"
1377     fi
1378     widget="$2"
1379
1380     [[ -z "$sequence" ]] && return 1
1381
1382     for i in "${maps[@]}"; do
1383         zrcbindkey -M "$i" "$sequence" "$widget"
1384     done
1385 }
1386
1387 if (( ${+terminfo[smkx]} )) && (( ${+terminfo[rmkx]} )); then
1388     function zle-smkx () {
1389         emulate -L zsh
1390         printf '%s' ${terminfo[smkx]}
1391     }
1392     function zle-rmkx () {
1393         emulate -L zsh
1394         printf '%s' ${terminfo[rmkx]}
1395     }
1396     function zle-line-init () {
1397         zle-smkx
1398     }
1399     function zle-line-finish () {
1400         zle-rmkx
1401     }
1402     zle -N zle-line-init
1403     zle -N zle-line-finish
1404 else
1405     for i in {s,r}mkx; do
1406         (( ${+terminfo[$i]} )) || grml_missing_features+=($i)
1407     done
1408     unset i
1409 fi
1410
1411 typeset -A key
1412 key=(
1413     Home     "${terminfo[khome]}"
1414     End      "${terminfo[kend]}"
1415     Insert   "${terminfo[kich1]}"
1416     Delete   "${terminfo[kdch1]}"
1417     Up       "${terminfo[kcuu1]}"
1418     Down     "${terminfo[kcud1]}"
1419     Left     "${terminfo[kcub1]}"
1420     Right    "${terminfo[kcuf1]}"
1421     PageUp   "${terminfo[kpp]}"
1422     PageDown "${terminfo[knp]}"
1423     BackTab  "${terminfo[kcbt]}"
1424 )
1425
1426 # Guidelines for adding key bindings:
1427 #
1428 #   - Do not add hardcoded escape sequences, to enable non standard key
1429 #     combinations such as Ctrl-Meta-Left-Cursor. They are not easily portable.
1430 #
1431 #   - Adding Ctrl characters, such as '^b' is okay; note that '^b' and '^B' are
1432 #     the same key.
1433 #
1434 #   - All keys from the $key[] mapping are obviously okay.
1435 #
1436 #   - Most terminals send "ESC x" when Meta-x is pressed. Thus, sequences like
1437 #     '\ex' are allowed in here as well.
1438
1439 bind2maps emacs             -- Home   beginning-of-somewhere
1440 bind2maps       viins vicmd -- Home   vi-beginning-of-line
1441 bind2maps emacs             -- End    end-of-somewhere
1442 bind2maps       viins vicmd -- End    vi-end-of-line
1443 bind2maps emacs viins       -- Insert overwrite-mode
1444 bind2maps             vicmd -- Insert vi-insert
1445 bind2maps emacs             -- Delete delete-char
1446 bind2maps       viins vicmd -- Delete vi-delete-char
1447 bind2maps emacs viins vicmd -- Up     up-line-or-search
1448 bind2maps emacs viins vicmd -- Down   down-line-or-search
1449 bind2maps emacs             -- Left   backward-char
1450 bind2maps       viins vicmd -- Left   vi-backward-char
1451 bind2maps emacs             -- Right  forward-char
1452 bind2maps       viins vicmd -- Right  vi-forward-char
1453 #k# Perform abbreviation expansion
1454 bind2maps emacs viins       -- -s '^x.' zleiab
1455 #k# Display list of abbreviations that would expand
1456 bind2maps emacs viins       -- -s '^xb' help-show-abk
1457 #k# mkdir -p <dir> from string under cursor or marked area
1458 bind2maps emacs viins       -- -s '^xM' inplaceMkDirs
1459 #k# display help for keybindings and ZLE
1460 bind2maps emacs viins       -- -s '^xz' help-zle
1461 #k# Insert files and test globbing
1462 bind2maps emacs viins       -- -s "^xf" insert-files
1463 #k# Edit the current line in \kbd{\$EDITOR}
1464 bind2maps emacs viins       -- -s '\ee' edit-command-line
1465 #k# search history backward for entry beginning with typed text
1466 bind2maps emacs viins       -- -s '^xp' history-beginning-search-backward-end
1467 #k# search history forward for entry beginning with typed text
1468 bind2maps emacs viins       -- -s '^xP' history-beginning-search-forward-end
1469 #k# search history backward for entry beginning with typed text
1470 bind2maps emacs viins       -- PageUp history-beginning-search-backward-end
1471 #k# search history forward for entry beginning with typed text
1472 bind2maps emacs viins       -- PageDown history-beginning-search-forward-end
1473 bind2maps emacs viins       -- -s "^x^h" commit-to-history
1474 #k# Kill left-side word or everything up to next slash
1475 bind2maps emacs viins       -- -s '\ev' slash-backward-kill-word
1476 #k# Kill left-side word or everything up to next slash
1477 bind2maps emacs viins       -- -s '\e^h' slash-backward-kill-word
1478 #k# Kill left-side word or everything up to next slash
1479 bind2maps emacs viins       -- -s '\e^?' slash-backward-kill-word
1480 # Do history expansion on space:
1481 bind2maps emacs viins       -- -s ' ' magic-space
1482 #k# Trigger menu-complete
1483 bind2maps emacs viins       -- -s '\ei' menu-complete  # menu completion via esc-i
1484 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1485 bind2maps emacs viins       -- -s '^ed' insert-datestamp
1486 #k# Insert last typed word
1487 bind2maps emacs viins       -- -s "\em" insert-last-typed-word
1488 #k# A smart shortcut for \kbd{fg<enter>}
1489 bind2maps emacs viins       -- -s '^z' grml-zsh-fg
1490 #k# prepend the current command with "sudo"
1491 bind2maps emacs viins       -- -s "^os" sudo-command-line
1492 #k# jump to after first word (for adding options)
1493 bind2maps emacs viins       -- -s '^x1' jump_after_first_word
1494 #k# complete word from history with menu
1495 bind2maps emacs viins       -- -s "^x^x" hist-complete
1496
1497 # insert unicode character
1498 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
1499 # See for example http://unicode.org/charts/ for unicode characters code
1500 #k# Insert Unicode character
1501 bind2maps emacs viins       -- -s '^xi' insert-unicode-char
1502
1503 # use the new *-pattern-* widgets for incremental history search
1504 if zrcgotwidget history-incremental-pattern-search-backward; then
1505     for seq wid in '^r' history-incremental-pattern-search-backward \
1506                    '^s' history-incremental-pattern-search-forward
1507     do
1508         bind2maps emacs viins vicmd -- -s $seq $wid
1509     done
1510     builtin unset -v seq wid
1511 fi
1512
1513 if zrcgotkeymap menuselect; then
1514     #m# k Shift-tab Perform backwards menu completion
1515     bind2maps menuselect -- BackTab reverse-menu-complete
1516
1517     #k# menu selection: pick item but stay in the menu
1518     bind2maps menuselect -- -s '\e^M' accept-and-menu-complete
1519     # also use + and INSERT since it's easier to press repeatedly
1520     bind2maps menuselect -- -s '+' accept-and-menu-complete
1521     bind2maps menuselect -- Insert accept-and-menu-complete
1522
1523     # accept a completion and try to complete again by using menu
1524     # completion; very useful with completing directories
1525     # by using 'undo' one's got a simple file browser
1526     bind2maps menuselect -- -s '^o' accept-and-infer-next-history
1527 fi
1528
1529 # Finally, here are still a few hardcoded escape sequences; Special sequences
1530 # like Ctrl-<Cursor-key> etc do suck a fair bit, because they are not
1531 # standardised and most of the time are not available in a terminals terminfo
1532 # entry.
1533 #
1534 # While we do not encourage adding bindings like these, we will keep these for
1535 # backward compatibility.
1536
1537 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on
1538 ## the command line.
1539 # URxvt sequences:
1540 bind2maps emacs viins vicmd -- -s '\eOc' forward-word
1541 bind2maps emacs viins vicmd -- -s '\eOd' backward-word
1542 # These are for xterm:
1543 bind2maps emacs viins vicmd -- -s '\e[1;5C' forward-word
1544 bind2maps emacs viins vicmd -- -s '\e[1;5D' backward-word
1545 ## the same for alt-left-arrow and alt-right-arrow
1546 # URxvt again:
1547 bind2maps emacs viins vicmd -- -s '\e\e[C' forward-word
1548 bind2maps emacs viins vicmd -- -s '\e\e[D' backward-word
1549 # Xterm again:
1550 bind2maps emacs viins vicmd -- -s '^[[1;3C' forward-word
1551 bind2maps emacs viins vicmd -- -s '^[[1;3D' backward-word
1552 # Also try ESC Left/Right:
1553 bind2maps emacs viins vicmd -- -s '\e'${key[Right]} forward-word
1554 bind2maps emacs viins vicmd -- -s '\e'${key[Left]}  backward-word
1555
1556 # autoloading
1557
1558 zrcautoload zmv
1559 zrcautoload zed
1560
1561 # we don't want to quote/espace URLs on our own...
1562 # if autoload -U url-quote-magic ; then
1563 #    zle -N self-insert url-quote-magic
1564 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
1565 # else
1566 #    print 'Notice: no url-quote-magic available :('
1567 # fi
1568 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
1569
1570 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
1571 alias run-help >&/dev/null && unalias run-help
1572 for rh in run-help{,-git,-svk,-svn}; do
1573     zrcautoload $rh
1574 done; unset rh
1575
1576 # command not found handling
1577
1578 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1579 function command_not_found_handler() {
1580     emulate -L zsh
1581     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1582         ${GRML_ZSH_CNF_HANDLER} $1
1583     fi
1584     return 1
1585 }
1586
1587 # history
1588
1589 #v#
1590 HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1591 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1592 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1593
1594 # dirstack handling
1595
1596 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1597 DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1598
1599 if zstyle -T ':grml:chpwd:dirstack' enable; then
1600     typeset -gaU GRML_PERSISTENT_DIRSTACK
1601     function grml_dirstack_filter() {
1602         local -a exclude
1603         local filter entry
1604         if zstyle -s ':grml:chpwd:dirstack' filter filter; then
1605             $filter $1 && return 0
1606         fi
1607         if zstyle -a ':grml:chpwd:dirstack' exclude exclude; then
1608             for entry in "${exclude[@]}"; do
1609                 [[ $1 == ${~entry} ]] && return 0
1610             done
1611         fi
1612         return 1
1613     }
1614
1615     chpwd() {
1616         (( ZSH_SUBSHELL )) && return
1617         (( $DIRSTACKSIZE <= 0 )) && return
1618         [[ -z $DIRSTACKFILE ]] && return
1619         grml_dirstack_filter $PWD && return
1620         GRML_PERSISTENT_DIRSTACK=(
1621             $PWD "${(@)GRML_PERSISTENT_DIRSTACK[1,$DIRSTACKSIZE]}"
1622         )
1623         builtin print -l ${GRML_PERSISTENT_DIRSTACK} >! ${DIRSTACKFILE}
1624     }
1625
1626     if [[ -f ${DIRSTACKFILE} ]]; then
1627         # Enabling NULL_GLOB via (N) weeds out any non-existing
1628         # directories from the saved dir-stack file.
1629         dirstack=( ${(f)"$(< $DIRSTACKFILE)"}(N) )
1630         # "cd -" won't work after login by just setting $OLDPWD, so
1631         [[ -d $dirstack[1] ]] && cd -q $dirstack[1] && cd -q $OLDPWD
1632     fi
1633
1634     if zstyle -t ':grml:chpwd:dirstack' filter-on-load; then
1635         for i in "${dirstack[@]}"; do
1636             if ! grml_dirstack_filter "$i"; then
1637                 GRML_PERSISTENT_DIRSTACK=(
1638                     "${GRML_PERSISTENT_DIRSTACK[@]}"
1639                     $i
1640                 )
1641             fi
1642         done
1643     else
1644         GRML_PERSISTENT_DIRSTACK=( "${dirstack[@]}" )
1645     fi
1646 fi
1647
1648 # directory based profiles
1649
1650 if is433 ; then
1651
1652 # chpwd_profiles(): Directory Profiles, Quickstart:
1653 #
1654 # In .zshrc.local:
1655 #
1656 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1657 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1658 #   chpwd_profiles
1659 #
1660 # For details see the `grmlzshrc.5' manual page.
1661 function chpwd_profiles() {
1662     local profile context
1663     local -i reexecute
1664
1665     context=":chpwd:profiles:$PWD"
1666     zstyle -s "$context" profile profile || profile='default'
1667     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1668
1669     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1670         typeset -g CHPWD_PROFILE
1671         local CHPWD_PROFILES_INIT=1
1672         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1673     elif [[ $profile != $CHPWD_PROFILE ]]; then
1674         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1675             && chpwd_leave_profile_${CHPWD_PROFILE}
1676     fi
1677     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1678         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1679     fi
1680
1681     CHPWD_PROFILE="${profile}"
1682     return 0
1683 }
1684
1685 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1686
1687 fi # is433
1688
1689 # Prompt setup for grml:
1690
1691 # set colors for use in prompts (modern zshs allow for the use of %F{red}foo%f
1692 # in prompts to get a red "foo" embedded, but it's good to keep these for
1693 # backwards compatibility).
1694 if is437; then
1695     BLUE="%F{blue}"
1696     RED="%F{red}"
1697     GREEN="%F{green}"
1698     CYAN="%F{cyan}"
1699     MAGENTA="%F{magenta}"
1700     YELLOW="%F{yellow}"
1701     WHITE="%F{white}"
1702     NO_COLOR="%f"
1703 elif zrcautoload colors && colors 2>/dev/null ; then
1704     BLUE="%{${fg[blue]}%}"
1705     RED="%{${fg_bold[red]}%}"
1706     GREEN="%{${fg[green]}%}"
1707     CYAN="%{${fg[cyan]}%}"
1708     MAGENTA="%{${fg[magenta]}%}"
1709     YELLOW="%{${fg[yellow]}%}"
1710     WHITE="%{${fg[white]}%}"
1711     NO_COLOR="%{${reset_color}%}"
1712 else
1713     BLUE=$'%{\e[1;34m%}'
1714     RED=$'%{\e[1;31m%}'
1715     GREEN=$'%{\e[1;32m%}'
1716     CYAN=$'%{\e[1;36m%}'
1717     WHITE=$'%{\e[1;37m%}'
1718     MAGENTA=$'%{\e[1;35m%}'
1719     YELLOW=$'%{\e[1;33m%}'
1720     NO_COLOR=$'%{\e[0m%}'
1721 fi
1722
1723 # First, the easy ones: PS2..4:
1724
1725 # secondary prompt, printed when the shell needs more information to complete a
1726 # command.
1727 PS2='\`%_> '
1728 # selection prompt used within a select loop.
1729 PS3='?# '
1730 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1731 PS4='+%N:%i:%_> '
1732
1733 # Some additional features to use with our prompt:
1734 #
1735 #    - battery status
1736 #    - debian_chroot
1737 #    - vcs_info setup and version specific fixes
1738
1739 # display battery status on right side of prompt using 'GRML_DISPLAY_BATTERY=1' in .zshrc.pre
1740
1741 battery() {
1742 if [[ $GRML_DISPLAY_BATTERY -gt 0 ]] ; then
1743     if islinux ; then
1744         batterylinux
1745     elif isopenbsd ; then
1746         batteryopenbsd
1747     elif isfreebsd ; then
1748         batteryfreebsd
1749     elif isdarwin ; then
1750         batterydarwin
1751     else
1752         #not yet supported
1753         GRML_DISPLAY_BATTERY=0
1754     fi
1755 fi
1756 }
1757
1758 batterylinux(){
1759 GRML_BATTERY_LEVEL=''
1760 local batteries bat capacity
1761 batteries=( /sys/class/power_supply/BAT*(N) )
1762 if (( $#batteries > 0 )) ; then
1763     for bat in $batteries ; do
1764         if [[ -e $bat/capacity ]]; then
1765             capacity=$(< $bat/capacity)
1766         else
1767             typeset -F energy_full=$(< $bat/energy_full)
1768             typeset -F energy_now=$(< $bat/energy_now)
1769             typeset -i capacity=$(( 100 * $energy_now / $energy_full))
1770         fi
1771         case $(< $bat/status) in
1772         Charging)
1773             GRML_BATTERY_LEVEL+=" ^"
1774             ;;
1775         Discharging)
1776             if (( capacity < 20 )) ; then
1777                 GRML_BATTERY_LEVEL+=" !v"
1778             else
1779                 GRML_BATTERY_LEVEL+=" v"
1780             fi
1781             ;;
1782         *) # Full, Unknown
1783             GRML_BATTERY_LEVEL+=" ="
1784             ;;
1785         esac
1786         GRML_BATTERY_LEVEL+="${capacity}%%"
1787     done
1788 fi
1789 }
1790
1791 batteryopenbsd(){
1792 GRML_BATTERY_LEVEL=''
1793 local bat batfull batwarn batnow num
1794 for num in 0 1 ; do
1795     bat=$(sysctl -n hw.sensors.acpibat${num} 2>/dev/null)
1796     if [[ -n $bat ]]; then
1797         batfull=${"$(sysctl -n hw.sensors.acpibat${num}.amphour0)"%% *}
1798         batwarn=${"$(sysctl -n hw.sensors.acpibat${num}.amphour1)"%% *}
1799         batnow=${"$(sysctl -n hw.sensors.acpibat${num}.amphour3)"%% *}
1800         case "$(sysctl -n hw.sensors.acpibat${num}.raw0)" in
1801             *" discharging"*)
1802                 if (( batnow < batwarn )) ; then
1803                     GRML_BATTERY_LEVEL+=" !v"
1804                 else
1805                     GRML_BATTERY_LEVEL+=" v"
1806                 fi
1807                 ;;
1808             *" charging"*)
1809                 GRML_BATTERY_LEVEL+=" ^"
1810                 ;;
1811             *)
1812                 GRML_BATTERY_LEVEL+=" ="
1813                 ;;
1814         esac
1815         GRML_BATTERY_LEVEL+="${$(( 100 * batnow / batfull ))%%.*}%%"
1816     fi
1817 done
1818 }
1819
1820 batteryfreebsd(){
1821 GRML_BATTERY_LEVEL=''
1822 local num
1823 local -A table
1824 for num in 0 1 ; do
1825     table=( ${=${${${${${(M)${(f)"$(acpiconf -i $num 2>&1)"}:#(State|Remaining capacity):*}%%( ##|%)}//:[ $'\t']##/@}// /-}//@/ }} )
1826     if [[ -n $table ]] && [[ $table[State] != "not-present" ]] ; then
1827         case $table[State] in
1828             *discharging*)
1829                 if (( $table[Remaining-capacity] < 20 )) ; then
1830                     GRML_BATTERY_LEVEL+=" !v"
1831                 else
1832                     GRML_BATTERY_LEVEL+=" v"
1833                 fi
1834                 ;;
1835             *charging*)
1836                 GRML_BATTERY_LEVEL+=" ^"
1837                 ;;
1838             *)
1839                 GRML_BATTERY_LEVEL+=" ="
1840                 ;;
1841         esac
1842         GRML_BATTERY_LEVEL+="$table[Remaining-capacity]%%"
1843     fi
1844 done
1845 }
1846
1847 batterydarwin(){
1848 GRML_BATTERY_LEVEL=''
1849 local -a table
1850 table=( ${$(pmset -g ps)[(w)7,8]%%(\%|);} )
1851 if [[ -n $table[2] ]] ; then
1852     case $table[2] in
1853         charging)
1854             GRML_BATTERY_LEVEL+=" ^"
1855             ;;
1856         discharging)
1857             if (( $table[1] < 20 )) ; then
1858                 GRML_BATTERY_LEVEL+=" !v"
1859             else
1860                 GRML_BATTERY_LEVEL+=" v"
1861             fi
1862             ;;
1863         *)
1864             GRML_BATTERY_LEVEL+=" ="
1865             ;;
1866     esac
1867     GRML_BATTERY_LEVEL+="$table[1]%%"
1868 fi
1869 }
1870
1871 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1872 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1873     debian_chroot=$(</etc/debian_chroot)
1874 fi
1875
1876 # gather version control information for inclusion in a prompt
1877
1878 if zrcautoload vcs_info; then
1879     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1880     # function, which can cause a lot of trouble with our directory-based
1881     # profiles. So:
1882     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1883         function VCS_INFO_realpath () {
1884             setopt localoptions NO_shwordsplit chaselinks
1885             ( builtin cd -q $1 2> /dev/null && pwd; )
1886         }
1887     fi
1888
1889     zstyle ':vcs_info:*' max-exports 2
1890
1891     if [[ -o restricted ]]; then
1892         zstyle ':vcs_info:*' enable NONE
1893     fi
1894 fi
1895
1896 typeset -A grml_vcs_coloured_formats
1897 typeset -A grml_vcs_plain_formats
1898
1899 grml_vcs_plain_formats=(
1900     format "(%s%)-[%b] "    "zsh: %r"
1901     actionformat "(%s%)-[%b|%a] " "zsh: %r"
1902     rev-branchformat "%b:%r"
1903 )
1904
1905 grml_vcs_coloured_formats=(
1906     format "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR} "
1907     actionformat "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} "
1908     rev-branchformat "%b${RED}:${YELLOW}%r"
1909 )
1910
1911 typeset GRML_VCS_COLOUR_MODE=xxx
1912
1913 grml_vcs_info_toggle_colour () {
1914     emulate -L zsh
1915     if [[ $GRML_VCS_COLOUR_MODE == plain ]]; then
1916         grml_vcs_info_set_formats coloured
1917     else
1918         grml_vcs_info_set_formats plain
1919     fi
1920     return 0
1921 }
1922
1923 grml_vcs_info_set_formats () {
1924     emulate -L zsh
1925     #setopt localoptions xtrace
1926     local mode=$1 AF F BF
1927     if [[ $mode == coloured ]]; then
1928         AF=${grml_vcs_coloured_formats[actionformat]}
1929         F=${grml_vcs_coloured_formats[format]}
1930         BF=${grml_vcs_coloured_formats[rev-branchformat]}
1931         GRML_VCS_COLOUR_MODE=coloured
1932     else
1933         AF=${grml_vcs_plain_formats[actionformat]}
1934         F=${grml_vcs_plain_formats[format]}
1935         BF=${grml_vcs_plain_formats[rev-branchformat]}
1936         GRML_VCS_COLOUR_MODE=plain
1937     fi
1938
1939     zstyle ':vcs_info:*'              actionformats "$AF" "zsh: %r"
1940     zstyle ':vcs_info:*'              formats       "$F"  "zsh: %r"
1941     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat  "$BF"
1942     return 0
1943 }
1944
1945 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1946 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1947 if [[ "$TERM" == dumb ]] ; then
1948     grml_vcs_info_set_formats plain
1949 else
1950     grml_vcs_info_set_formats coloured
1951 fi
1952
1953 # Now for the fun part: The grml prompt themes in `promptsys' mode of operation
1954
1955 # This actually defines three prompts:
1956 #
1957 #    - grml
1958 #    - grml-large
1959 #    - grml-chroot
1960 #
1961 # They all share the same code and only differ with respect to which items they
1962 # contain. The main source of documentation is the `prompt_grml_help' function
1963 # below, which gets called when the user does this: prompt -h grml
1964
1965 function prompt_grml_help () {
1966     <<__EOF0__
1967   prompt grml
1968
1969     This is the prompt as used by the grml-live system <http://grml.org>. It is
1970     a rather simple one-line prompt, that by default looks something like this:
1971
1972         <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1973
1974     The prompt itself integrates with zsh's prompt themes system (as you are
1975     witnessing right now) and is configurable to a certain degree. In
1976     particular, these aspects are customisable:
1977
1978         - The items used in the prompt (e.g. you can remove \`user' from
1979           the list of activated items, which will cause the user name to
1980           be omitted from the prompt string).
1981
1982         - The attributes used with the items are customisable via strings
1983           used before and after the actual item.
1984
1985     The available items are: at, battery, change-root, date, grml-chroot,
1986     history, host, jobs, newline, path, percent, rc, rc-always, sad-smiley,
1987     shell-level, time, user, vcs
1988
1989     The actual configuration is done via zsh's \`zstyle' mechanism. The
1990     context, that is used while looking up styles is:
1991
1992         ':prompt:grml:<left-or-right>:<subcontext>'
1993
1994     Here <left-or-right> is either \`left' or \`right', signifying whether the
1995     style should affect the left or the right prompt. <subcontext> is either
1996     \`setup' or 'items:<item>', where \`<item>' is one of the available items.
1997
1998     The styles:
1999
2000         - use-rprompt (boolean): If \`true' (the default), print a sad smiley
2001           in $RPROMPT if the last command a returned non-successful error code.
2002           (This in only valid if <left-or-right> is "right"; ignored otherwise)
2003
2004         - items (list): The list of items used in the prompt. If \`vcs' is
2005           present in the list, the theme's code invokes \`vcs_info'
2006           accordingly. Default (left): rc change-root user at host path vcs
2007           percent; Default (right): sad-smiley
2008
2009     Available styles in 'items:<item>' are: pre, post. These are strings that
2010     are inserted before (pre) and after (post) the item in question. Thus, the
2011     following would cause the user name to be printed in red instead of the
2012     default blue:
2013
2014         zstyle ':prompt:grml:*:items:user' pre '%F{red}'
2015
2016     Note, that the \`post' style may remain at its default value, because its
2017     default value is '%f', which turns the foreground text attribute off (which
2018     is exactly, what is still required with the new \`pre' value).
2019 __EOF0__
2020 }
2021
2022 function prompt_grml-chroot_help () {
2023     <<__EOF0__
2024   prompt grml-chroot
2025
2026     This is a variation of the grml prompt, see: prompt -h grml
2027
2028     The main difference is the default value of the \`items' style. The rest
2029     behaves exactly the same. Here are the defaults for \`grml-chroot':
2030
2031         - left: grml-chroot user at host path percent
2032         - right: (empty list)
2033 __EOF0__
2034 }
2035
2036 function prompt_grml-large_help () {
2037     <<__EOF0__
2038   prompt grml-large
2039
2040     This is a variation of the grml prompt, see: prompt -h grml
2041
2042     The main difference is the default value of the \`items' style. In
2043     particular, this theme uses _two_ lines instead of one with the plain
2044     \`grml' theme. The rest behaves exactly the same. Here are the defaults
2045     for \`grml-large':
2046
2047         - left: rc jobs history shell-level change-root time date newline user
2048                 at host path vcs percent
2049         - right: sad-smiley
2050 __EOF0__
2051 }
2052
2053 function grml_prompt_setup () {
2054     emulate -L zsh
2055     autoload -Uz vcs_info
2056     # The following autoload is disabled for now, since this setup includes a
2057     # static version of the ‘add-zsh-hook’ function above. It needs to be
2058     # reenabled as soon as that static definition is removed again.
2059     #autoload -Uz add-zsh-hook
2060     add-zsh-hook precmd prompt_$1_precmd
2061 }
2062
2063 function prompt_grml_setup () {
2064     grml_prompt_setup grml
2065 }
2066
2067 function prompt_grml-chroot_setup () {
2068     grml_prompt_setup grml-chroot
2069 }
2070
2071 function prompt_grml-large_setup () {
2072     grml_prompt_setup grml-large
2073 }
2074
2075 # These maps define default tokens and pre-/post-decoration for items to be
2076 # used within the themes. All defaults may be customised in a context sensitive
2077 # matter by using zsh's `zstyle' mechanism.
2078 typeset -gA grml_prompt_pre_default \
2079             grml_prompt_post_default \
2080             grml_prompt_token_default \
2081             grml_prompt_token_function
2082
2083 grml_prompt_pre_default=(
2084     at                ''
2085     battery           ' '
2086     change-root       ''
2087     date              '%F{blue}'
2088     grml-chroot       '%F{red}'
2089     history           '%F{green}'
2090     host              ''
2091     jobs              '%F{cyan}'
2092     newline           ''
2093     path              '%B'
2094     percent           ''
2095     rc                '%B%F{red}'
2096     rc-always         ''
2097     sad-smiley        ''
2098     shell-level       '%F{red}'
2099     time              '%F{blue}'
2100     user              '%B%F{blue}'
2101     vcs               ''
2102 )
2103
2104 grml_prompt_post_default=(
2105     at                ''
2106     battery           ''
2107     change-root       ''
2108     date              '%f'
2109     grml-chroot       '%f '
2110     history           '%f'
2111     host              ''
2112     jobs              '%f'
2113     newline           ''
2114     path              '%b'
2115     percent           ''
2116     rc                '%f%b'
2117     rc-always         ''
2118     sad-smiley        ''
2119     shell-level       '%f'
2120     time              '%f'
2121     user              '%f%b'
2122     vcs               ''
2123 )
2124
2125 grml_prompt_token_default=(
2126     at                '@'
2127     battery           'GRML_BATTERY_LEVEL'
2128     change-root       'debian_chroot'
2129     date              '%D{%Y-%m-%d}'
2130     grml-chroot       'GRML_CHROOT'
2131     history           '{history#%!} '
2132     host              '%m '
2133     jobs              '[%j running job(s)] '
2134     newline           $'\n'
2135     path              '%40<..<%~%<< '
2136     percent           '%# '
2137     rc                '%(?..%? )'
2138     rc-always         '%?'
2139     sad-smiley        '%(?..:()'
2140     shell-level       '%(3L.+ .)'
2141     time              '%D{%H:%M:%S} '
2142     user              '%n'
2143     vcs               '0'
2144 )
2145
2146 function grml_theme_has_token () {
2147     if (( ARGC != 1 )); then
2148         printf 'usage: grml_theme_has_token <name>\n'
2149         return 1
2150     fi
2151     (( ${+grml_prompt_token_default[$1]} ))
2152 }
2153
2154 function GRML_theme_add_token_usage () {
2155     <<__EOF0__
2156   Usage: grml_theme_add_token <name> [-f|-i] <token/function> [<pre> <post>]
2157
2158     <name> is the name for the newly added token. If the \`-f' or \`-i' options
2159     are used, <token/function> is the name of the function (see below for
2160     details). Otherwise it is the literal token string to be used. <pre> and
2161     <post> are optional.
2162
2163   Options:
2164
2165     -f <function>   Use a function named \`<function>' each time the token
2166                     is to be expanded.
2167
2168     -i <function>   Use a function named \`<function>' to initialise the
2169                     value of the token _once_ at runtime.
2170
2171     The functions are called with one argument: the token's new name. The
2172     return value is expected in the \$REPLY parameter. The use of these
2173     options is mutually exclusive.
2174
2175     There is a utility function \`grml_theme_has_token', which you can use
2176     to test if a token exists before trying to add it. This can be a guard
2177     for situations in which a \`grml_theme_add_token' call may happen more
2178     than once.
2179
2180   Example:
2181
2182     To add a new token \`day' that expands to the current weekday in the
2183     current locale in green foreground colour, use this:
2184
2185       grml_theme_add_token day '%D{%A}' '%F{green}' '%f'
2186
2187     Another example would be support for \$VIRTUAL_ENV:
2188
2189       function virtual_env_prompt () {
2190         REPLY=\${VIRTUAL_ENV+\${VIRTUAL_ENV:t} }
2191       }
2192       grml_theme_add_token virtual-env -f virtual_env_prompt
2193
2194     After that, you will be able to use a changed \`items' style to
2195     assemble your prompt.
2196 __EOF0__
2197 }
2198
2199 function grml_theme_add_token () {
2200     emulate -L zsh
2201     local name token pre post
2202     local -i init funcall
2203
2204     if (( ARGC == 0 )); then
2205         GRML_theme_add_token_usage
2206         return 0
2207     fi
2208
2209     init=0
2210     funcall=0
2211     pre=''
2212     post=''
2213     name=$1
2214     shift
2215     if [[ $1 == '-f' ]]; then
2216         funcall=1
2217         shift
2218     elif [[ $1 == '-i' ]]; then
2219         init=1
2220         shift
2221     fi
2222
2223     if (( ARGC == 0 )); then
2224         printf '
2225 grml_theme_add_token: No token-string/function-name provided!\n\n'
2226         GRML_theme_add_token_usage
2227         return 1
2228     fi
2229     token=$1
2230     shift
2231     if (( ARGC != 0 && ARGC != 2 )); then
2232         printf '
2233 grml_theme_add_token: <pre> and <post> need to by specified _both_!\n\n'
2234         GRML_theme_add_token_usage
2235         return 1
2236     fi
2237     if (( ARGC )); then
2238         pre=$1
2239         post=$2
2240         shift 2
2241     fi
2242
2243     if grml_theme_has_token $name; then
2244         printf '
2245 grml_theme_add_token: Token `%s'\'' exists! Giving up!\n\n' $name
2246         GRML_theme_add_token_usage
2247         return 2
2248     fi
2249     if (( init )); then
2250         $token $name
2251         token=$REPLY
2252     fi
2253     grml_prompt_pre_default[$name]=$pre
2254     grml_prompt_post_default[$name]=$post
2255     if (( funcall )); then
2256         grml_prompt_token_function[$name]=$token
2257         grml_prompt_token_default[$name]=23
2258     else
2259         grml_prompt_token_default[$name]=$token
2260     fi
2261 }
2262
2263 function grml_typeset_and_wrap () {
2264     emulate -L zsh
2265     local target="$1"
2266     local new="$2"
2267     local left="$3"
2268     local right="$4"
2269
2270     if (( ${+parameters[$new]} )); then
2271         typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
2272     fi
2273 }
2274
2275 function grml_prompt_addto () {
2276     emulate -L zsh
2277     local target="$1"
2278     local lr it apre apost new v
2279     local -a items
2280     shift
2281
2282     [[ $target == PS1 ]] && lr=left || lr=right
2283     zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
2284     typeset -g "${target}="
2285     for it in "${items[@]}"; do
2286         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
2287             || apre=${grml_prompt_pre_default[$it]}
2288         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" post apost \
2289             || apost=${grml_prompt_post_default[$it]}
2290         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
2291             || new=${grml_prompt_token_default[$it]}
2292         typeset -g "${target}=${(P)target}${apre}"
2293         if (( ${+grml_prompt_token_function[$it]} )); then
2294             ${grml_prompt_token_function[$it]} $it
2295             typeset -g "${target}=${(P)target}${REPLY}"
2296         else
2297             case $it in
2298             battery)
2299                 grml_typeset_and_wrap $target $new '' ''
2300                 ;;
2301             change-root)
2302                 grml_typeset_and_wrap $target $new '(' ')'
2303                 ;;
2304             grml-chroot)
2305                 if [[ -n ${(P)new} ]]; then
2306                     typeset -g "${target}=${(P)target}(CHROOT)"
2307                 fi
2308                 ;;
2309             vcs)
2310                 v="vcs_info_msg_${new}_"
2311                 if (( ! vcscalled )); then
2312                     vcs_info
2313                     vcscalled=1
2314                 fi
2315                 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
2316                     typeset -g "${target}=${(P)target}${(P)v}"
2317                 fi
2318                 ;;
2319             *) typeset -g "${target}=${(P)target}${new}" ;;
2320             esac
2321         fi
2322         typeset -g "${target}=${(P)target}${apost}"
2323     done
2324 }
2325
2326 function prompt_grml_precmd () {
2327     emulate -L zsh
2328     local grmltheme=grml
2329     local -a left_items right_items
2330     left_items=(rc change-root user at host path vcs percent)
2331     right_items=(sad-smiley)
2332
2333     prompt_grml_precmd_worker
2334 }
2335
2336 function prompt_grml-chroot_precmd () {
2337     emulate -L zsh
2338     local grmltheme=grml-chroot
2339     local -a left_items right_items
2340     left_items=(grml-chroot user at host path percent)
2341     right_items=()
2342
2343     prompt_grml_precmd_worker
2344 }
2345
2346 function prompt_grml-large_precmd () {
2347     emulate -L zsh
2348     local grmltheme=grml-large
2349     local -a left_items right_items
2350     left_items=(rc jobs history shell-level change-root time date newline
2351                 user at host path vcs percent)
2352     right_items=(sad-smiley)
2353
2354     prompt_grml_precmd_worker
2355 }
2356
2357 function prompt_grml_precmd_worker () {
2358     emulate -L zsh
2359     local -i vcscalled=0
2360
2361     grml_prompt_addto PS1 "${left_items[@]}"
2362     if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
2363         grml_prompt_addto RPS1 "${right_items[@]}"
2364     fi
2365 }
2366
2367 grml_prompt_fallback() {
2368     setopt prompt_subst
2369     local p0 p1
2370
2371     p0="${RED}%(?..%? )${WHITE}${debian_chroot:+($debian_chroot)}"
2372     p1="${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "'${vcs_info_msg_0_}'"%# "
2373     if (( EUID == 0 )); then
2374         PROMPT="${BLUE}${p0}${RED}${p1}"
2375     else
2376         PROMPT="${RED}${p0}${BLUE}${p1}"
2377     fi
2378 }
2379
2380 if zrcautoload promptinit && promptinit 2>/dev/null ; then
2381     # Since we define the required functions in here and not in files in
2382     # $fpath, we need to stick the theme's name into `$prompt_themes'
2383     # ourselves, since promptinit does not pick them up otherwise.
2384     prompt_themes+=( grml grml-chroot grml-large )
2385     # Also, keep the array sorted...
2386     prompt_themes=( "${(@on)prompt_themes}" )
2387 else
2388     print 'Notice: no promptinit available :('
2389     grml_prompt_fallback
2390     precmd() { (( ${+functions[vcs_info]} )) && vcs_info; }
2391 fi
2392
2393 if is437; then
2394     # The prompt themes use modern features of zsh, that require at least
2395     # version 4.3.7 of the shell. Use the fallback otherwise.
2396     if [[ $GRML_DISPLAY_BATTERY -gt 0 ]]; then
2397         zstyle ':prompt:grml:right:setup' items sad-smiley battery
2398         add-zsh-hook precmd battery
2399     fi
2400     if [[ "$TERM" == dumb ]] ; then
2401         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" pre ''
2402         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" post ' '
2403         for i in rc user path jobs history date time shell-level; do
2404             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" pre ''
2405             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" post ''
2406         done
2407         unset i
2408         zstyle ':prompt:grml(|-large|-chroot):right:setup' use-rprompt false
2409     elif (( EUID == 0 )); then
2410         zstyle ':prompt:grml(|-large|-chroot):*:items:user' pre '%B%F{red}'
2411     fi
2412
2413     # Finally enable one of the prompts.
2414     if [[ -n $GRML_CHROOT ]]; then
2415         prompt grml-chroot
2416     elif [[ $GRMLPROMPT -gt 0 ]]; then
2417         prompt grml-large
2418     else
2419         prompt grml
2420     fi
2421 else
2422     grml_prompt_fallback
2423     precmd() { (( ${+functions[vcs_info]} )) && vcs_info; }
2424 fi
2425
2426 # Terminal-title wizardry
2427
2428 function ESC_print () {
2429     info_print $'\ek' $'\e\\' "$@"
2430 }
2431 function set_title () {
2432     info_print  $'\e]0;' $'\a' "$@"
2433 }
2434
2435 function info_print () {
2436     local esc_begin esc_end
2437     esc_begin="$1"
2438     esc_end="$2"
2439     shift 2
2440     printf '%s' ${esc_begin}
2441     printf '%s' "$*"
2442     printf '%s' "${esc_end}"
2443 }
2444
2445 function grml_reset_screen_title () {
2446     # adjust title of xterm
2447     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
2448     [[ ${NOTITLE:-} -gt 0 ]] && return 0
2449     case $TERM in
2450         (xterm*|rxvt*)
2451             set_title ${(%):-"%n@%m: %~"}
2452             ;;
2453     esac
2454 }
2455
2456 function grml_vcs_to_screen_title () {
2457     if [[ $TERM == screen* ]] ; then
2458         if [[ -n ${vcs_info_msg_1_} ]] ; then
2459             ESC_print ${vcs_info_msg_1_}
2460         else
2461             ESC_print "zsh"
2462         fi
2463     fi
2464 }
2465
2466 function grml_maintain_name () {
2467     # set hostname if not running on host with name 'grml'
2468     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
2469        NAME="@$HOSTNAME"
2470     fi
2471 }
2472
2473 function grml_cmd_to_screen_title () {
2474     # get the name of the program currently running and hostname of local
2475     # machine set screen window title if running in a screen
2476     if [[ "$TERM" == screen* ]] ; then
2477         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME"
2478         ESC_print ${CMD}
2479     fi
2480 }
2481
2482 function grml_control_xterm_title () {
2483     case $TERM in
2484         (xterm*|rxvt*)
2485             set_title "${(%):-"%n@%m:"}" "$1"
2486             ;;
2487     esac
2488 }
2489
2490 # The following autoload is disabled for now, since this setup includes a
2491 # static version of the ‘add-zsh-hook’ function above. It needs to be
2492 # reenabled as soon as that static definition is removed again.
2493 #zrcautoload add-zsh-hook || add-zsh-hook () { :; }
2494 if [[ $NOPRECMD -eq 0 ]]; then
2495     add-zsh-hook precmd grml_reset_screen_title
2496     add-zsh-hook precmd grml_vcs_to_screen_title
2497     add-zsh-hook preexec grml_maintain_name
2498     add-zsh-hook preexec grml_cmd_to_screen_title
2499     if [[ $NOTITLE -eq 0 ]]; then
2500         add-zsh-hook preexec grml_control_xterm_title
2501     fi
2502 fi
2503
2504 # 'hash' some often used directories
2505 #d# start
2506 hash -d deb=/var/cache/apt/archives
2507 hash -d doc=/usr/share/doc
2508 hash -d linux=/lib/modules/$(command uname -r)/build/
2509 hash -d log=/var/log
2510 hash -d slog=/var/log/syslog
2511 hash -d src=/usr/src
2512 hash -d www=/var/www
2513 #d# end
2514
2515 # some aliases
2516 if check_com -c screen ; then
2517     if [[ $UID -eq 0 ]] ; then
2518         if [[ -r /etc/grml/screenrc ]]; then
2519             alias screen='screen -c /etc/grml/screenrc'
2520         fi
2521     elif [[ ! -r $HOME/.screenrc ]] ; then
2522         if [[ -r /etc/grml/screenrc_grml ]]; then
2523             alias screen='screen -c /etc/grml/screenrc_grml'
2524         else
2525             if [[ -r /etc/grml/screenrc ]]; then
2526                 alias screen='screen -c /etc/grml/screenrc'
2527             fi
2528         fi
2529     fi
2530 fi
2531
2532 # do we have GNU ls with color-support?
2533 if [[ "$TERM" != dumb ]]; then
2534     #a1# List files with colors (\kbd{ls \ldots})
2535     alias ls="command ls ${ls_options:+${ls_options[*]}}"
2536     #a1# List all files, with colors (\kbd{ls -la \ldots})
2537     alias la="command ls -la ${ls_options:+${ls_options[*]}}"
2538     #a1# List files with long colored list, without dotfiles (\kbd{ls -l \ldots})
2539     alias ll="command ls -l ${ls_options:+${ls_options[*]}}"
2540     #a1# List files with long colored list, human readable sizes (\kbd{ls -hAl \ldots})
2541     alias lh="command ls -hAl ${ls_options:+${ls_options[*]}}"
2542     #a1# List files with long colored list, append qualifier to filenames (\kbd{ls -l \ldots})\\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2543     alias l="command ls -l ${ls_options:+${ls_options[*]}}"
2544 else
2545     alias la='command ls -la'
2546     alias ll='command ls -l'
2547     alias lh='command ls -hAl'
2548     alias l='command ls -l'
2549 fi
2550
2551 if [[ -r /proc/mdstat ]]; then
2552     alias mdstat='cat /proc/mdstat'
2553 fi
2554
2555 alias ...='cd ../../'
2556
2557 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2558 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2559     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2560 fi
2561
2562 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2563 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2564 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2565
2566 # make sure it is not assigned yet
2567 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
2568 utf2iso() {
2569     if isutfenv ; then
2570         local ENV
2571         for ENV in $(env | command grep -i '.utf') ; do
2572             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2573         done
2574     fi
2575 }
2576
2577 # make sure it is not assigned yet
2578 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
2579 iso2utf() {
2580     if ! isutfenv ; then
2581         local ENV
2582         for ENV in $(env | command grep -i '\.iso') ; do
2583             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2584         done
2585     fi
2586 }
2587
2588 # especially for roadwarriors using GNU screen and ssh:
2589 if ! check_com asc &>/dev/null ; then
2590   asc() { autossh -t "$@" 'screen -RdU' }
2591   compdef asc=ssh
2592 fi
2593
2594 #f1# Hints for the use of zsh on grml
2595 zsh-help() {
2596     print "$bg[white]$fg[black]
2597 zsh-help - hints for use of zsh on grml
2598 =======================================$reset_color"
2599
2600     print '
2601 Main configuration of zsh happens in /etc/zsh/zshrc.
2602 That file is part of the package grml-etc-core, if you want to
2603 use them on a non-grml-system just get the tar.gz from
2604 http://deb.grml.org/ or (preferably) get it from the git repository:
2605
2606   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2607
2608 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2609 The file is still there, but it is empty for backwards compatibility.
2610
2611 For your own changes use these two files:
2612     $HOME/.zshrc.pre
2613     $HOME/.zshrc.local
2614
2615 The former is sourced very early in our zshrc, the latter is sourced
2616 very lately.
2617
2618 System wide configuration without touching configuration files of grml
2619 can take place in /etc/zsh/zshrc.local.
2620
2621 For information regarding zsh start at http://grml.org/zsh/
2622
2623 Take a look at grml'\''s zsh refcard:
2624 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2625
2626 Check out the main zsh refcard:
2627 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2628
2629 And of course visit the zsh-lovers:
2630 % man zsh-lovers
2631
2632 You can adjust some options through environment variables when
2633 invoking zsh without having to edit configuration files.
2634 Basically meant for bash users who are not used to the power of
2635 the zsh yet. :)
2636
2637   "NOCOR=1    zsh" => deactivate automatic correction
2638   "NOMENU=1   zsh" => do not use auto menu completion
2639                       (note: use ctrl-d for completion instead!)
2640   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2641   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2642                       preexec() and precmd() completely
2643   "GRML_DISPLAY_BATTERY=1  zsh"
2644                    => activate battery status on right side of prompt (WIP)
2645   "COMMAND_NOT_FOUND=1 zsh"
2646                    => Enable a handler if an external command was not found
2647                       The command called in the handler can be altered by setting
2648                       the GRML_ZSH_CNF_HANDLER variable, the default is:
2649                       "/usr/share/command-not-found/command-not-found"
2650
2651 A value greater than 0 is enables a feature; a value equal to zero
2652 disables it. If you like one or the other of these settings, you can
2653 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2654 zshrc.'
2655
2656     print "
2657 $bg[white]$fg[black]
2658 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2659 Enjoy your grml system with the zsh!$reset_color"
2660 }
2661
2662 # debian stuff
2663 if [[ -r /etc/debian_version ]] ; then
2664     if [[ -z "$GRML_NO_APT_ALIASES" ]]; then
2665         #a3# Execute \kbd{apt-cache search}
2666         alias acs='apt-cache search'
2667         #a3# Execute \kbd{apt-cache show}
2668         alias acsh='apt-cache show'
2669         #a3# Execute \kbd{apt-cache policy}
2670         alias acp='apt-cache policy'
2671         #a3# Execute \kbd{apt-get dist-upgrade}
2672         salias adg="apt-get dist-upgrade"
2673         #a3# Execute \kbd{apt-get install}
2674         salias agi="apt-get install"
2675         #a3# Execute \kbd{aptitude install}
2676         salias ati="aptitude install"
2677         #a3# Execute \kbd{apt-get upgrade}
2678         salias ag="apt-get upgrade"
2679         #a3# Execute \kbd{apt-get update}
2680         salias au="apt-get update"
2681         #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2682         salias -a up="aptitude update ; aptitude safe-upgrade"
2683         #a3# Execute \kbd{dpkg-buildpackage}
2684         alias dbp='dpkg-buildpackage'
2685         #a3# Execute \kbd{grep-excuses}
2686         alias ge='grep-excuses'
2687     fi
2688
2689     # get a root shell as normal user in live-cd mode:
2690     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2691        alias su="sudo su"
2692     fi
2693
2694 fi
2695
2696 # use /var/log/syslog iff present, fallback to journalctl otherwise
2697 if [ -e /var/log/syslog ] ; then
2698   #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog || journalctl}
2699   salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2700   #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog || journalctl}
2701   salias tlog="tail -f /var/log/syslog"    # follow the syslog
2702 elif check_com -c journalctl ; then
2703   salias llog="journalctl"
2704   salias tlog="journalctl -f"
2705 fi
2706
2707 # sort installed Debian-packages by size
2708 if check_com -c dpkg-query ; then
2709     #a3# List installed Debian-packages sorted by size
2710     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
2711 fi
2712
2713 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2714 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
2715     if check_com -c wodim; then
2716         cdrecord() {
2717             <<__EOF0__
2718 cdrecord is not provided under its original name by Debian anymore.
2719 See #377109 in the BTS of Debian for more details.
2720
2721 Please use the wodim binary instead
2722 __EOF0__
2723             return 1
2724         }
2725     fi
2726 fi
2727
2728 if isgrmlcd; then
2729     # No core dumps: important for a live-cd-system
2730     limit -s core 0
2731 fi
2732
2733 # grmlstuff
2734 grmlstuff() {
2735 # people should use 'grml-x'!
2736     if check_com -c 915resolution; then
2737         855resolution() {
2738             echo "Please use 915resolution as resolution modifying tool for Intel \
2739 graphic chipset."
2740             return -1
2741         }
2742     fi
2743
2744     #a1# Output version of running grml
2745     alias grml-version='cat /etc/grml_version'
2746
2747     if check_com -c grml-debootstrap ; then
2748         debian2hd() {
2749             echo "Installing debian to harddisk is possible by using grml-debootstrap."
2750             return 1
2751         }
2752     fi
2753 }
2754
2755 # now run the functions
2756 isgrml && checkhome
2757 is4    && isgrml    && grmlstuff
2758 is4    && grmlcomp
2759
2760 # keephack
2761 is4 && xsource "/etc/zsh/keephack"
2762
2763 # wonderful idea of using "e" glob qualifier by Peter Stephenson
2764 # You use it as follows:
2765 # $ NTREF=/reference/file
2766 # $ ls -l *(e:nt:)
2767 # This lists all the files in the current directory newer than the reference file.
2768 # You can also specify the reference file inline; note quotes:
2769 # $ ls -l *(e:'nt ~/.zshenv':)
2770 is4 && nt() {
2771     if [[ -n $1 ]] ; then
2772         local NTREF=${~1}
2773     fi
2774     [[ $REPLY -nt $NTREF ]]
2775 }
2776
2777 # shell functions
2778
2779 #f1# Reload an autoloadable function
2780 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2781 compdef _functions freload
2782
2783 #
2784 # Usage:
2785 #
2786 #      e.g.:   a -> b -> c -> d  ....
2787 #
2788 #      sll a
2789 #
2790 #
2791 #      if parameter is given with leading '=', lookup $PATH for parameter and resolve that
2792 #
2793 #      sll =java
2794 #
2795 #      Note: limit for recursive symlinks on linux:
2796 #            http://git.kernel.org/cgit/linux/kernel/git/torvalds/linux.git/tree/fs/namei.c?id=refs/heads/master#l808
2797 #            This limits recursive symlink follows to 8,
2798 #            while limiting consecutive symlinks to 40.
2799 #
2800 #      When resolving and displaying information about symlinks, no check is made
2801 #      that the displayed information does make any sense on your OS.
2802 #      We leave that decission to the user.
2803 #
2804 #      The zstat module is used to detect symlink loops. zstat is available since zsh4.
2805 #      With an older zsh you will need to abort with <C-c> in that case.
2806 #      When a symlink loop is detected, a warning ist printed and further processing is stopped.
2807 #
2808 #      Module zstat is loaded by default in grml zshrc, no extra action needed for that.
2809 #
2810 #      Known bugs:
2811 #      If you happen to come accross a symlink that points to a destination on an other partition
2812 #      with the same inode number, that will be marked as symlink loop though it is not.
2813 #      Two hints for this situation:
2814 #      I)  Play lottery the same day, as you seem to be rather lucky right now.
2815 #      II) Send patches.
2816 #
2817 #      return status:
2818 #      0 upon success
2819 #      1 file/dir not accesible
2820 #      2 symlink loop detected
2821 #
2822 #f1# List symlinks in detail (more detailed version of 'readlink -f', 'whence -s' and 'namei -l')
2823 sll() {
2824     if [[ -z ${1} ]] ; then
2825         printf 'Usage: %s <symlink(s)>\n' "${0}"
2826         return 1
2827     fi
2828
2829     local file jumpd curdir
2830     local -i RTN LINODE i
2831     local -a SEENINODES
2832     curdir="${PWD}"
2833     RTN=0
2834
2835     for file in "${@}" ; do
2836         SEENINODES=()
2837         ls -l "${file:a}"   || RTN=1
2838
2839         while [[ -h "$file" ]] ; do
2840             if is4 ; then
2841                 LINODE=$(zstat -L +inode "${file}")
2842                 for i in ${SEENINODES} ; do
2843                     if (( ${i} == ${LINODE} )) ; then
2844                         builtin cd "${curdir}"
2845                         print "link loop detected, aborting!"
2846                         return 2
2847                     fi
2848                 done
2849                 SEENINODES+=${LINODE}
2850             fi
2851             jumpd="${file:h}"
2852             file="${file:t}"
2853
2854             if [[ -d ${jumpd} ]] ; then
2855                 builtin cd "${jumpd}"  || RTN=1
2856             fi
2857             file=$(readlink "$file")
2858
2859             jumpd="${file:h}"
2860             file="${file:t}"
2861
2862             if [[ -d ${jumpd} ]] ; then
2863                 builtin cd "${jumpd}"  || RTN=1
2864             fi
2865
2866             ls -l "${PWD}/${file}"     || RTN=1
2867         done
2868         shift 1
2869         if (( ${#} >= 1 )) ; then
2870             print ""
2871         fi
2872         builtin cd "${curdir}"
2873     done
2874     return ${RTN}
2875 }
2876
2877 # TODO: Is it supported to use pager settings like this?
2878 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2879 # with respect to wordsplitting. (ie. ${=PAGER})
2880 if check_com -c $PAGER ; then
2881     #f3# View Debian's changelog of given package(s)
2882     dchange() {
2883         emulate -L zsh
2884         [[ -z "$1" ]] && printf 'Usage: %s <package_name(s)>\n' "$0" && return 1
2885
2886         local package
2887         for package in "$@" ; do
2888             if [[ -r /usr/share/doc/${package}/changelog.Debian.gz ]] ; then
2889                 $PAGER /usr/share/doc/${package}/changelog.Debian.gz
2890             elif [[ -r /usr/share/doc/${package}/changelog.gz ]] ; then
2891                 $PAGER /usr/share/doc/${package}/changelog.gz
2892             elif [[ -r /usr/share/doc/${package}/changelog ]] ; then
2893                 $PAGER /usr/share/doc/${package}/changelog
2894             else
2895                 if check_com -c aptitude ; then
2896                     echo "No changelog for package $package found, using aptitude to retrieve it."
2897                     aptitude changelog "$package"
2898                 elif check_com -c apt-get ; then
2899                     echo "No changelog for package $package found, using apt-get to retrieve it."
2900                     apt-get changelog "$package"
2901                 else
2902                     echo "No changelog for package $package found, sorry."
2903                 fi
2904             fi
2905         done
2906     }
2907     _dchange() { _files -W /usr/share/doc -/ }
2908     compdef _dchange dchange
2909
2910     #f3# View Debian's NEWS of a given package
2911     dnews() {
2912         emulate -L zsh
2913         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2914             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2915         else
2916             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2917                 $PAGER /usr/share/doc/$1/NEWS.gz
2918             else
2919                 echo "No NEWS file for package $1 found, sorry."
2920                 return 1
2921             fi
2922         fi
2923     }
2924     _dnews() { _files -W /usr/share/doc -/ }
2925     compdef _dnews dnews
2926
2927     #f3# View Debian's copyright of a given package
2928     dcopyright() {
2929         emulate -L zsh
2930         if [[ -r /usr/share/doc/$1/copyright ]] ; then
2931             $PAGER /usr/share/doc/$1/copyright
2932         else
2933             echo "No copyright file for package $1 found, sorry."
2934             return 1
2935         fi
2936     }
2937     _dcopyright() { _files -W /usr/share/doc -/ }
2938     compdef _dcopyright dcopyright
2939
2940     #f3# View upstream's changelog of a given package
2941     uchange() {
2942         emulate -L zsh
2943         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2944             $PAGER /usr/share/doc/$1/changelog.gz
2945         else
2946             echo "No changelog for package $1 found, sorry."
2947             return 1
2948         fi
2949     }
2950     _uchange() { _files -W /usr/share/doc -/ }
2951     compdef _uchange uchange
2952 fi
2953
2954 # zsh profiling
2955 profile() {
2956     ZSH_PROFILE_RC=1 zsh "$@"
2957 }
2958
2959 #f1# Edit an alias via zle
2960 edalias() {
2961     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2962 }
2963 compdef _aliases edalias
2964
2965 #f1# Edit a function via zle
2966 edfunc() {
2967     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2968 }
2969 compdef _functions edfunc
2970
2971 # use it e.g. via 'Restart apache2'
2972 #m# f6 Start() \kbd{service \em{process}}\quad\kbd{start}
2973 #m# f6 Restart() \kbd{service \em{process}}\quad\kbd{restart}
2974 #m# f6 Stop() \kbd{service \em{process}}\quad\kbd{stop}
2975 #m# f6 Reload() \kbd{service \em{process}}\quad\kbd{reload}
2976 #m# f6 Force-Reload() \kbd{service \em{process}}\quad\kbd{force-reload}
2977 #m# f6 Status() \kbd{service \em{process}}\quad\kbd{status}
2978 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2979     __start_stop() {
2980         local action_="${1:l}"  # e.g Start/Stop/Restart
2981         local service_="$2"
2982         local param_="$3"
2983
2984         local service_target_="$(readlink /etc/init.d/$service_)"
2985         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2986             # runit
2987             case "${action_}" in
2988                 start) if [[ ! -e /etc/service/$service_ ]]; then
2989                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2990                        else
2991                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2992                        fi ;;
2993                 # there is no reload in runits sysv emulation
2994                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2995                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2996             esac
2997         else
2998             # sysv/sysvinit-utils, upstart
2999             if check_com -c service ; then
3000               $SUDO service "$service_" "${action_}" "$param_"
3001             else
3002               $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
3003             fi
3004         fi
3005     }
3006
3007     _grmlinitd() {
3008         local -a scripts
3009         scripts=( /etc/init.d/*(x:t) )
3010         _describe "service startup script" scripts
3011     }
3012
3013     for i in Start Restart Stop Force-Reload Reload Status ; do
3014         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
3015         compdef _grmlinitd $i
3016     done
3017     builtin unset -v i
3018 fi
3019
3020 #f1# Provides useful information on globbing
3021 H-Glob() {
3022     echo -e "
3023     /      directories
3024     .      plain files
3025     @      symbolic links
3026     =      sockets
3027     p      named pipes (FIFOs)
3028     *      executable plain files (0100)
3029     %      device files (character or block special)
3030     %b     block special files
3031     %c     character special files
3032     r      owner-readable files (0400)
3033     w      owner-writable files (0200)
3034     x      owner-executable files (0100)
3035     A      group-readable files (0040)
3036     I      group-writable files (0020)
3037     E      group-executable files (0010)
3038     R      world-readable files (0004)
3039     W      world-writable files (0002)
3040     X      world-executable files (0001)
3041     s      setuid files (04000)
3042     S      setgid files (02000)
3043     t      files with the sticky bit (01000)
3044
3045   print *(m-1)          # Files modified up to a day ago
3046   print *(a1)           # Files accessed a day ago
3047   print *(@)            # Just symlinks
3048   print *(Lk+50)        # Files bigger than 50 kilobytes
3049   print *(Lk-50)        # Files smaller than 50 kilobytes
3050   print **/*.c          # All *.c files recursively starting in \$PWD
3051   print **/*.c~file.c   # Same as above, but excluding 'file.c'
3052   print (foo|bar).*     # Files starting with 'foo' or 'bar'
3053   print *~*.*           # All Files that do not contain a dot
3054   chmod 644 *(.^x)      # make all plain non-executable files publically readable
3055   print -l *(.c|.h)     # Lists *.c and *.h
3056   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
3057   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
3058 }
3059 alias help-zshglob=H-Glob
3060
3061 # grep for running process, like: 'any vim'
3062 any() {
3063     emulate -L zsh
3064     unsetopt KSH_ARRAYS
3065     if [[ -z "$1" ]] ; then
3066         echo "any - grep for process(es) by keyword" >&2
3067         echo "Usage: any <keyword>" >&2 ; return 1
3068     else
3069         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
3070     fi
3071 }
3072
3073
3074 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
3075 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
3076 [[ -r /proc/1/maps ]] && \
3077 deswap() {
3078     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
3079     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
3080     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
3081 }
3082
3083 # a wrapper for vim, that deals with title setting
3084 #   VIM_OPTIONS
3085 #       set this array to a set of options to vim you always want
3086 #       to have set when calling vim (in .zshrc.local), like:
3087 #           VIM_OPTIONS=( -p )
3088 #       This will cause vim to send every file given on the
3089 #       commandline to be send to it's own tab (needs vim7).
3090 if check_com vim; then
3091     vim() {
3092         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
3093     }
3094 fi
3095
3096 ssl_hashes=( sha512 sha256 sha1 md5 )
3097
3098 for sh in ${ssl_hashes}; do
3099     eval 'ssl-cert-'${sh}'() {
3100         emulate -L zsh
3101         if [[ -z $1 ]] ; then
3102             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
3103             return 1
3104         fi
3105         openssl x509 -noout -fingerprint -'${sh}' -in $1
3106     }'
3107 done; unset sh
3108
3109 ssl-cert-fingerprints() {
3110     emulate -L zsh
3111     local i
3112     if [[ -z $1 ]] ; then
3113         printf 'usage: ssl-cert-fingerprints <file>\n'
3114         return 1
3115     fi
3116     for i in ${ssl_hashes}
3117         do ssl-cert-$i $1;
3118     done
3119 }
3120
3121 ssl-cert-info() {
3122     emulate -L zsh
3123     if [[ -z $1 ]] ; then
3124         printf 'usage: ssl-cert-info <file>\n'
3125         return 1
3126     fi
3127     openssl x509 -noout -text -in $1
3128     ssl-cert-fingerprints $1
3129 }
3130
3131 # make sure our environment is clean regarding colors
3132 for var in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $var
3133 builtin unset -v var
3134
3135 # "persistent history"
3136 # just write important commands you always need to ~/.important_commands
3137 if [[ -r ~/.important_commands ]] ; then
3138     fc -R ~/.important_commands
3139 fi
3140
3141 # load the lookup subsystem if it's available on the system
3142 zrcautoload lookupinit && lookupinit
3143
3144 # variables
3145
3146 # set terminal property (used e.g. by msgid-chooser)
3147 export COLORTERM="yes"
3148
3149 # aliases
3150
3151 # general
3152 #a2# Execute \kbd{du -sch}
3153 [[ -n "$GRML_NO_SMALL_ALIASES" ]] || alias da='du -sch'
3154
3155 # listing stuff
3156 #a2# Execute \kbd{ls -lSrah}
3157 alias dir="command ls -lSrah"
3158 #a2# Only show dot-directories
3159 alias lad='command ls -d .*(/)'
3160 #a2# Only show dot-files
3161 alias lsa='command ls -a .*(.)'
3162 #a2# Only files with setgid/setuid/sticky flag
3163 alias lss='command ls -l *(s,S,t)'
3164 #a2# Only show symlinks
3165 alias lsl='command ls -l *(@)'
3166 #a2# Display only executables
3167 alias lsx='command ls -l *(*)'
3168 #a2# Display world-{readable,writable,executable} files
3169 alias lsw='command ls -ld *(R,W,X.^ND/)'
3170 #a2# Display the ten biggest files
3171 alias lsbig="command ls -flh *(.OL[1,10])"
3172 #a2# Only show directories
3173 alias lsd='command ls -d *(/)'
3174 #a2# Only show empty directories
3175 alias lse='command ls -d *(/^F)'
3176 #a2# Display the ten newest files
3177 alias lsnew="command ls -rtlh *(D.om[1,10])"
3178 #a2# Display the ten oldest files
3179 alias lsold="command ls -rtlh *(D.Om[1,10])"
3180 #a2# Display the ten smallest files
3181 alias lssmall="command ls -Srl *(.oL[1,10])"
3182 #a2# Display the ten newest directories and ten newest .directories
3183 alias lsnewdir="command ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
3184 #a2# Display the ten oldest directories and ten oldest .directories
3185 alias lsolddir="command ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
3186
3187 # some useful aliases
3188 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir \$OLDCWD}
3189 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
3190
3191 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3192 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3193 #a2# scp with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3194 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3195
3196 # work around non utf8 capable software in utf environment via $LANG and luit
3197 if check_com isutfenv && check_com luit ; then
3198     if check_com -c mrxvt ; then
3199         isutfenv && [[ -n "$LANG" ]] && \
3200             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3201     fi
3202
3203     if check_com -c aterm ; then
3204         isutfenv && [[ -n "$LANG" ]] && \
3205             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3206     fi
3207
3208     if check_com -c centericq ; then
3209         isutfenv && [[ -n "$LANG" ]] && \
3210             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3211     fi
3212 fi
3213
3214 # useful functions
3215
3216 #f5# Backup \kbd{file_or_folder {\rm to} file_or_folder\_timestamp}
3217 bk() {
3218     emulate -L zsh
3219     local current_date=$(date -u "+%Y-%m-%dT%H:%M:%SZ")
3220     local clean keep move verbose result all to_bk
3221     setopt extended_glob
3222     keep=1
3223     while getopts ":hacmrv" opt; do
3224         case $opt in
3225             a) (( all++ ));;
3226             c) unset move clean && (( ++keep ));;
3227             m) unset keep clean && (( ++move ));;
3228             r) unset move keep && (( ++clean ));;
3229             v) verbose="-v";;
3230             h) <<__EOF0__
3231 bk [-hcmv] FILE [FILE ...]
3232 bk -r [-av] [FILE [FILE ...]]
3233 Backup a file or folder in place and append the timestamp
3234 Remove backups of a file or folder, or all backups in the current directory
3235
3236 Usage:
3237 -h    Display this help text
3238 -c    Keep the file/folder as is, create a copy backup using cp(1) (default)
3239 -m    Move the file/folder, using mv(1)
3240 -r    Remove backups of the specified file or directory, using rm(1). If none
3241       is provided, remove all backups in the current directory.
3242 -a    Remove all (even hidden) backups.
3243 -v    Verbose
3244
3245 The -c, -r and -m options are mutually exclusive. If specified at the same time,
3246 the last one is used.
3247
3248 The return code is the sum of all cp/mv/rm return codes.
3249 __EOF0__
3250 return 0;;
3251             \?) bk -h >&2; return 1;;
3252         esac
3253     done
3254     shift "$((OPTIND-1))"
3255     if (( keep > 0 )); then
3256         if islinux || isfreebsd; then
3257             for to_bk in "$@"; do
3258                 cp $verbose -a "${to_bk%/}" "${to_bk%/}_$current_date"
3259                 (( result += $? ))
3260             done
3261         else
3262             for to_bk in "$@"; do
3263                 cp $verbose -pR "${to_bk%/}" "${to_bk%/}_$current_date"
3264                 (( result += $? ))
3265             done
3266         fi
3267     elif (( move > 0 )); then
3268         while (( $# > 0 )); do
3269             mv $verbose "${1%/}" "${1%/}_$current_date"
3270             (( result += $? ))
3271             shift
3272         done
3273     elif (( clean > 0 )); then
3274         if (( $# > 0 )); then
3275             for to_bk in "$@"; do
3276                 rm $verbose -rf "${to_bk%/}"_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z
3277                 (( result += $? ))
3278             done
3279         else
3280             if (( all > 0 )); then
3281                 rm $verbose -rf *_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z(D)
3282             else
3283                 rm $verbose -rf *_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z
3284             fi
3285             (( result += $? ))
3286         fi
3287     fi
3288     return $result
3289 }
3290
3291 #f5# cd to directoy and list files
3292 cl() {
3293     emulate -L zsh
3294     cd $1 && ls -a
3295 }
3296
3297 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
3298 cd() {
3299     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
3300         [[ ! -e ${1:h} ]] && return 1
3301         print "Correcting ${1} to ${1:h}"
3302         builtin cd ${1:h}
3303     else
3304         builtin cd "$@"
3305     fi
3306 }
3307
3308 #f5# Create Directoy and \kbd{cd} to it
3309 mkcd() {
3310     if (( ARGC != 1 )); then
3311         printf 'usage: mkcd <new-directory>\n'
3312         return 1;
3313     fi
3314     if [[ ! -d "$1" ]]; then
3315         command mkdir -p "$1"
3316     else
3317         printf '`%s'\'' already exists: cd-ing.\n' "$1"
3318     fi
3319     builtin cd "$1"
3320 }
3321
3322 #f5# Create temporary directory and \kbd{cd} to it
3323 cdt() {
3324     builtin cd "$(mktemp -d)"
3325     builtin pwd
3326 }
3327
3328 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
3329 accessed() {
3330     emulate -L zsh
3331     print -l -- *(a-${1:-1})
3332 }
3333
3334 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
3335 changed() {
3336     emulate -L zsh
3337     print -l -- *(c-${1:-1})
3338 }
3339
3340 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
3341 modified() {
3342     emulate -L zsh
3343     print -l -- *(m-${1:-1})
3344 }
3345 # modified() was named new() in earlier versions, add an alias for backwards compatibility
3346 check_com new || alias new=modified
3347
3348 # use colors when GNU grep with color-support
3349 if (( $#grep_options > 0 )); then
3350     o=${grep_options:+"${grep_options[*]}"}
3351     #a2# Execute \kbd{grep -{}-color=auto}
3352     alias grep='grep '$o
3353     alias egrep='egrep '$o
3354     unset o
3355 fi
3356
3357 # Translate DE<=>EN
3358 # 'translate' looks up a word in a file with language-to-language
3359 # translations (field separator should be " : "). A typical wordlist looks
3360 # like the following:
3361 #  | english-word : german-translation
3362 # It's also only possible to translate english to german but not reciprocal.
3363 # Use the following oneliner to reverse the sort order:
3364 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3365 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3366 #f5# Translates a word
3367 trans() {
3368     emulate -L zsh
3369     case "$1" in
3370         -[dD]*)
3371             translate -l de-en $2
3372             ;;
3373         -[eE]*)
3374             translate -l en-de $2
3375             ;;
3376         *)
3377             echo "Usage: $0 { -D | -E }"
3378             echo "         -D == German to English"
3379             echo "         -E == English to German"
3380     esac
3381 }
3382
3383 # Usage: simple-extract <file>
3384 # Using option -d deletes the original archive file.
3385 #f5# Smart archive extractor
3386 simple-extract() {
3387     emulate -L zsh
3388     setopt extended_glob noclobber
3389     local ARCHIVE DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
3390     local RC=0
3391     zparseopts -D -E "d=DELETE_ORIGINAL"
3392     for ARCHIVE in "${@}"; do
3393         case $ARCHIVE in
3394             *(tar.bz2|tbz2|tbz))
3395                 DECOMP_CMD="tar -xvjf -"
3396                 USES_STDIN=true
3397                 USES_STDOUT=false
3398                 ;;
3399             *(tar.gz|tgz))
3400                 DECOMP_CMD="tar -xvzf -"
3401                 USES_STDIN=true
3402                 USES_STDOUT=false
3403                 ;;
3404             *(tar.xz|txz|tar.lzma))
3405                 DECOMP_CMD="tar -xvJf -"
3406                 USES_STDIN=true
3407                 USES_STDOUT=false
3408                 ;;
3409             *tar)
3410                 DECOMP_CMD="tar -xvf -"
3411                 USES_STDIN=true
3412                 USES_STDOUT=false
3413                 ;;
3414             *rar)
3415                 DECOMP_CMD="unrar x"
3416                 USES_STDIN=false
3417                 USES_STDOUT=false
3418                 ;;
3419             *lzh)
3420                 DECOMP_CMD="lha x"
3421                 USES_STDIN=false
3422                 USES_STDOUT=false
3423                 ;;
3424             *7z)
3425                 DECOMP_CMD="7z x"
3426                 USES_STDIN=false
3427                 USES_STDOUT=false
3428                 ;;
3429             *(zip|jar))
3430                 DECOMP_CMD="unzip"
3431                 USES_STDIN=false
3432                 USES_STDOUT=false
3433                 ;;
3434             *deb)
3435                 DECOMP_CMD="ar -x"
3436                 USES_STDIN=false
3437                 USES_STDOUT=false
3438                 ;;
3439             *bz2)
3440                 DECOMP_CMD="bzip2 -d -c -"
3441                 USES_STDIN=true
3442                 USES_STDOUT=true
3443                 ;;
3444             *(gz|Z))
3445                 DECOMP_CMD="gzip -d -c -"
3446                 USES_STDIN=true
3447                 USES_STDOUT=true
3448                 ;;
3449             *(xz|lzma))
3450                 DECOMP_CMD="xz -d -c -"
3451                 USES_STDIN=true
3452                 USES_STDOUT=true
3453                 ;;
3454             *)
3455                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
3456                 RC=$((RC+1))
3457                 continue
3458                 ;;
3459         esac
3460
3461         if ! check_com ${DECOMP_CMD[(w)1]}; then
3462             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
3463             RC=$((RC+2))
3464             continue
3465         fi
3466
3467         GZTARGET="${ARCHIVE:t:r}"
3468         if [[ -f $ARCHIVE ]] ; then
3469
3470             print "Extracting '$ARCHIVE' ..."
3471             if $USES_STDIN; then
3472                 if $USES_STDOUT; then
3473                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
3474                 else
3475                     ${=DECOMP_CMD} < "$ARCHIVE"
3476                 fi
3477             else
3478                 if $USES_STDOUT; then
3479                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
3480                 else
3481                     ${=DECOMP_CMD} "$ARCHIVE"
3482                 fi
3483             fi
3484             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
3485
3486         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
3487             if check_com curl; then
3488                 WGET_CMD="curl -L -s -o -"
3489             elif check_com wget; then
3490                 WGET_CMD="wget -q -O -"
3491             elif check_com fetch; then
3492                 WGET_CMD="fetch -q -o -"
3493             else
3494                 print "ERROR: neither wget, curl nor fetch is installed" >&2
3495                 RC=$((RC+4))
3496                 continue
3497             fi
3498             print "Downloading and Extracting '$ARCHIVE' ..."
3499             if $USES_STDIN; then
3500                 if $USES_STDOUT; then
3501                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
3502                     RC=$((RC+$?))
3503                 else
3504                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
3505                     RC=$((RC+$?))
3506                 fi
3507             else
3508                 if $USES_STDOUT; then
3509                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
3510                 else
3511                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
3512                 fi
3513             fi
3514
3515         else
3516             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
3517             RC=$((RC+8))
3518         fi
3519     done
3520     return $RC
3521 }
3522
3523 __archive_or_uri()
3524 {
3525     _alternative \
3526         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
3527         '_urls:Remote Archives:_urls'
3528 }
3529
3530 _simple_extract()
3531 {
3532     _arguments \
3533         '-d[delete original archivefile after extraction]' \
3534         '*:Archive Or Uri:__archive_or_uri'
3535 }
3536 compdef _simple_extract simple-extract
3537 [[ -n "$GRML_NO_SMALL_ALIASES" ]] || alias se=simple-extract
3538
3539 #f5# Change the xterm title from within GNU-screen
3540 xtrename() {
3541     emulate -L zsh
3542     if [[ $1 != "-f" ]] ; then
3543         if [[ -z ${DISPLAY} ]] ; then
3544             printf 'xtrename only makes sense in X11.\n'
3545             return 1
3546         fi
3547     else
3548         shift
3549     fi
3550     if [[ -z $1 ]] ; then
3551         printf 'usage: xtrename [-f] "title for xterm"\n'
3552         printf '  renames the title of xterm from _within_ screen.\n'
3553         printf '  also works without screen.\n'
3554         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3555         return 0
3556     fi
3557     print -n "\eP\e]0;${1}\C-G\e\\"
3558     return 0
3559 }
3560
3561 # Create small urls via http://goo.gl using curl(1).
3562 # API reference: https://code.google.com/apis/urlshortener/
3563 function zurl() {
3564     emulate -L zsh
3565     setopt extended_glob
3566
3567     if [[ -z $1 ]]; then
3568         print "USAGE: zurl <URL>"
3569         return 1
3570     fi
3571
3572     local PN url prog api json contenttype item
3573     local -a data
3574     PN=$0
3575     url=$1
3576
3577     # Prepend 'http://' to given URL where necessary for later output.
3578     if [[ ${url} != http(s|)://* ]]; then
3579         url='http://'${url}
3580     fi
3581
3582     if check_com -c curl; then
3583         prog=curl
3584     else
3585         print "curl is not available, but mandatory for ${PN}. Aborting."
3586         return 1
3587     fi
3588     api='https://www.googleapis.com/urlshortener/v1/url'
3589     contenttype="Content-Type: application/json"
3590     json="{\"longUrl\": \"${url}\"}"
3591     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
3592     # Parse the response
3593     for item in "${data[@]}"; do
3594         case "$item" in
3595             ' '#'"id":'*)
3596                 item=${item#*: \"}
3597                 item=${item%\",*}
3598                 printf '%s\n' "$item"
3599                 return 0
3600                 ;;
3601         esac
3602     done
3603     return 1
3604 }
3605
3606 #f2# Find history events by search pattern and list them by date.
3607 whatwhen()  {
3608     emulate -L zsh
3609     local usage help ident format_l format_s first_char remain first last
3610     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3611     help='Use `whatwhen -h'\'' for further explanations.'
3612     ident=${(l,${#${:-Usage: }},, ,)}
3613     format_l="${ident}%s\t\t\t%s\n"
3614     format_s="${format_l//(\\t)##/\\t}"
3615     # Make the first char of the word to search for case
3616     # insensitive; e.g. [aA]
3617     first_char=[${(L)1[1]}${(U)1[1]}]
3618     remain=${1[2,-1]}
3619     # Default search range is `-100'.
3620     first=${2:-\-100}
3621     # Optional, just used for `<first> <last>' given.
3622     last=$3
3623     case $1 in
3624         ("")
3625             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3626             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3627         ;;
3628         (-h)
3629             printf '%s\n\n' ${usage}
3630             print 'OPTIONS:'
3631             printf $format_l '-h' 'show help text'
3632             print '\f'
3633             print 'SEARCH RANGE:'
3634             printf $format_l "'0'" 'the whole history,'
3635             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
3636             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
3637             printf '\n%s\n' 'EXAMPLES:'
3638             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
3639             printf $format_l 'whatwhen zsh -250'
3640             printf $format_l 'whatwhen foo 1 99'
3641         ;;
3642         (\?)
3643             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3644         ;;
3645         (*)
3646             # -l list results on stout rather than invoking $EDITOR.
3647             # -i Print dates as in YYYY-MM-DD.
3648             # -m Search for a - quoted - pattern within the history.
3649             fc -li -m "*${first_char}${remain}*" $first $last
3650         ;;
3651     esac
3652 }
3653
3654 # mercurial related stuff
3655 if check_com -c hg ; then
3656     # gnu like diff for mercurial
3657     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
3658     #f5# GNU like diff for mercurial
3659     hgdi() {
3660         emulate -L zsh
3661         local i
3662         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
3663     }
3664
3665     # build debian package
3666     #a2# Alias for \kbd{hg-buildpackage}
3667     alias hbp='hg-buildpackage'
3668
3669     # execute commands on the versioned patch-queue from the current repos
3670     [[ -n "$GRML_NO_SMALL_ALIASES" ]] || alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
3671
3672     # diffstat for specific version of a mercurial repository
3673     #   hgstat      => display diffstat between last revision and tip
3674     #   hgstat 1234 => display diffstat between revision 1234 and tip
3675     #f5# Diffstat for specific version of a mercurial repos
3676     hgstat() {
3677         emulate -L zsh
3678         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
3679     }
3680
3681 fi # end of check whether we have the 'hg'-executable
3682
3683 # grml-small cleanups
3684
3685 # The following is used to remove zsh-config-items that do not work
3686 # in grml-small by default.
3687 # If you do not want these adjustments (for whatever reason), set
3688 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
3689 # sources if it is there).
3690
3691 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
3692
3693     unset abk[V]
3694     unalias    'V'      &> /dev/null
3695     unfunction vman     &> /dev/null
3696     unfunction viless   &> /dev/null
3697     unfunction 2html    &> /dev/null
3698
3699     # manpages are not in grmlsmall
3700     unfunction manzsh   &> /dev/null
3701     unfunction man2     &> /dev/null
3702
3703 fi
3704
3705 zrclocal
3706
3707 ## genrefcard.pl settings
3708
3709 ### doc strings for external functions from files
3710 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
3711
3712 ### example: split functions-search 8,16,24,32
3713 #@# split functions-search 8
3714
3715 ## END OF FILE #################################################################
3716 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
3717 # Local variables:
3718 # mode: sh
3719 # End: