etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # zsh-refcard-tag documentation: {{{
  15 #   You may notice strange looking comments in this file.
  16 #   These are there for a purpose. grml's zsh-refcard can now be
  17 #   automatically generated from the contents of the actual configuration
  18 #   file. However, we need a little extra information on which comments
  19 #   and what lines of code to take into account (and for what purpose).
  20 #
  21 # Here is what they mean:
  22 #
  23 # List of tags (comment types) used:
  24 #   #a#     Next line contains an important alias, that should
  25 #           be included in the grml-zsh-refcard.
  26 #           (placement tag: @@INSERT-aliases@@)
  27 #   #f#     Next line contains the beginning of an important function.
  28 #           (placement tag: @@INSERT-functions@@)
  29 #   #v#     Next line contains an important variable.
  30 #           (placement tag: @@INSERT-variables@@)
  31 #   #k#     Next line contains an important keybinding.
  32 #           (placement tag: @@INSERT-keybindings@@)
  33 #   #d#     Hashed directories list generation:
  34 #               start   denotes the start of a list of 'hash -d'
  35 #                       definitions.
  36 #               end     denotes its end.
  37 #           (placement tag: @@INSERT-hasheddirs@@)
  38 #   #A#     Abbreviation expansion list generation:
  39 #               start   denotes the beginning of abbreviations.
  40 #               end     denotes their end.
  41 #           Lines within this section that end in '#d .*' provide
  42 #           extra documentation to be included in the refcard.
  43 #           (placement tag: @@INSERT-abbrev@@)
  44 #   #m#     This tag allows you to manually generate refcard entries
  45 #           for code lines that are hard/impossible to parse.
  46 #               Example:
  47 #                   #m# k ESC-h Call the run-help function
  48 #               That would add a refcard entry in the keybindings table
  49 #               for 'ESC-h' with the given comment.
  50 #           So the syntax is: #m# <section> <argument> <comment>
  51 #   #o#     This tag lets you insert entries to the 'other' hash.
  52 #           Generally, this should not be used. It is there for
  53 #           things that cannot be done easily in another way.
  54 #           (placement tag: @@INSERT-other-foobar@@)
  55 #
  56 #   All of these tags (except for m and o) take two arguments, the first
  57 #   within the tag, the other after the tag:
  58 #
  59 #   #<tag><section># <comment>
  60 #
  61 #   Where <section> is really just a number, which are defined by the
  62 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  63 #   instead of names is, that for the reader, the tag should not differ
  64 #   much from a regular comment. For zsh, it is a regular comment indeed.
  65 #   The numbers have got the following meanings:
  66 #         0 -> "default"
  67 #         1 -> "system"
  68 #         2 -> "user"
  69 #         3 -> "debian"
  70 #         4 -> "search"
  71 #         5 -> "shortcuts"
  72 #         6 -> "services"
  73 #
  74 #   So, the following will add an entry to the 'functions' table in the
  75 #   'system' section, with a (hopefully) descriptive comment:
  76 #       #f1# Edit an alias via zle
  77 #       edalias() {
  78 #
  79 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  80 #   that can be found in 'grml-zsh-refcard.tex.in'.
  81 #   If the section number is omitted, the 'default' section is assumed.
  82 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
  83 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
  84 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
  85 #}}}
  86
  87 # zsh profiling {{{
  88 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
  89 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
  90     zmodload zsh/zprof
  91 fi
  92 # }}}
  93
  94 # load .zshrc.pre to give the user the chance to overwrite the defaults
  95 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
  96
  97 # {{{ check for version/system
  98 # check for versions (compatibility reasons)
  99 is4(){
 100     [[ $ZSH_VERSION == <4->* ]] && return 0
 101     return 1
 102 }
 103
 104 is41(){
 105     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 106     return 1
 107 }
 108
 109 is42(){
 110     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 111     return 1
 112 }
 113
 114 is425(){
 115     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 116     return 1
 117 }
 118
 119 is43(){
 120     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 121     return 1
 122 }
 123
 124 #f1# Checks whether or not you're running grml
 125 isgrml(){
 126     [[ -f /etc/grml_version ]] && return 0
 127     return 1
 128 }
 129
 130 #f1# Checks whether or not you're running a grml cd
 131 isgrmlcd(){
 132     [[ -f /etc/grml_cd ]] && return 0
 133     return 1
 134 }
 135
 136 if isgrml ; then
 137 #f1# Checks whether or not you're running grml-small
 138     isgrmlsmall() {
 139         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 140     }
 141 else
 142     isgrmlsmall() { return 1 }
 143 fi
 144
 145 isdarwin(){
 146     [[ $OSTYPE == darwin* ]] && return 0
 147     return 1
 148 }
 149
 150 #f1# are we running within an utf environment?
 151 isutfenv() {
 152     case "$LANG $CHARSET $LANGUAGE" in
 153         *utf*) return 0 ;;
 154         *UTF*) return 0 ;;
 155         *)     return 1 ;;
 156     esac
 157 }
 158
 159 # check for user, if not running as root set $SUDO to sudo
 160 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 161
 162 # change directory to home on first invocation of zsh
 163 # important for rungetty -> autologin
 164 # Thanks go to Bart Schaefer!
 165 isgrml && checkhome() {
 166     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 167         export ALREADY_DID_CD_HOME=$HOME
 168         cd
 169     fi
 170 }
 171
 172 # check for zsh v3.1.7+
 173
 174 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 175      || ${ZSH_VERSION} == 3.<2->.<->*    \
 176      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 177
 178     printf '-!-\n'
 179     printf '-!- In this configuration we try to make use of features, that only\n'
 180     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 181     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 182     printf '-!- advanced features in all supported versions.\n'
 183     printf '-!-\n'
 184     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 185     printf '-!-\n'
 186     printf '-!- While this *may* work, it might as well fail.\n'
 187     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 188     printf '-!-\n'
 189     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 190     printf '-!- If it does today, you'\''ve been lucky.\n'
 191     printf '-!-\n'
 192     printf '-!- Ye been warned!\n'
 193     printf '-!-\n'
 194
 195     function zstyle() { : }
 196 fi
 197
 198 # autoload wrapper - use this one instead of autoload directly
 199 # We need to define this function as early as this, because autoloading
 200 # 'is-at-least()' needs it.
 201 function zrcautoload() {
 202     setopt local_options extended_glob
 203     local fdir ffile
 204     local -i ffound
 205
 206     ffile=${1}
 207     (( found = 0 ))
 208     for fdir in ${fpath} ; do
 209         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 210     done
 211
 212     (( ffound == 0 )) && return 1
 213     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 214         autoload -U ${ffile} || return 1
 215     else
 216         autoload ${ffile} || return 1
 217     fi
 218     return 0
 219 }
 220
 221 # Load is-at-least() for more precise version checks
 222 # Note that this test will *always* fail, if the is-at-least
 223 # function could not be marked for autoloading.
 224 zrcautoload is-at-least || is-at-least() { return 1 }
 225
 226 # }}}
 227
 228 # setting some default values {{{
 229
 230 NOCOR=${NOCOR:-0}
 231 NOMENU=${NOMENU:-0}
 232 NOPRECMD=${NOPRECMD:-0}
 233 BATTERY=${BATTERY:-0}
 234 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 235 GRML_ALWAYS_LOAD_ALL=${GRML_ALWAYS_LOAD_ALL:-0}
 236
 237 if isgrmlcd ; then
 238     GRML_WARN_SKEL=${GRML_WARN_SKEL:-0}
 239 else
 240     GRML_WARN_SKEL=${GRML_WARN_SKEL:-1}
 241 fi
 242
 243 if (( GRML_WARN_SKEL != 0 )) ; then
 244
 245 function grml_warn_skel_main() {
 246     printf '
 247 Dear user,
 248
 249 You updated grml'\''s zshrc which brings a major change.
 250 The configuration is kept only in one file, being the global zshrc.
 251 In the past, the configuration was split in two files, with the
 252 second file being the .zshrc file from /etc/skel.
 253
 254 If you have a .zshrc file in your home directory that originally
 255 came from the skel directory, please remove it. This is also the case
 256 if you followed earlier instructions from the grml-zsh-refcard or
 257 from <http://grml.org/console/> on non-grml systems.
 258
 259 Please see the current grml-zsh-refcard (available at
 260 <http://grml.org/zsh/>) for updated installation information. In short,
 261 you don'\''t want a .zshrc.global file. Install the global zshrc to
 262 ~/.zshrc and be done.
 263
 264 If you need changes to the configuration, use ~/.zshrc.pre and
 265 ~/.zshrc.local.
 266
 267 '
 268 }
 269
 270 function grml_warn_skel_remove() {
 271     printf 'To remove this warning execute '\''grml_do_not_warn_skel'\''.\n\n'
 272 }
 273
 274 function grml_do_not_warn_skel() {
 275     printf '# Do not warn about old skel dot-files anymore\n' >>! ~/.zshrc.pre
 276     printf 'GRML_WARN_SKEL=0\n' >>! ~/.zshrc.pre
 277 }
 278
 279 # let's try to guess how the user uses us.
 280 if is-at-least 4.3.7 ; then
 281     # funcsourcetrace requires at least version 4.3.7 of zsh.
 282     GRML_SRC_FILE="${${funcsourcetrace[1]}%:*}"
 283
 284     grml_warn_skel_main
 285     case ${GRML_SRC_FILE} in
 286         (${HOME}/.zshrc.global)
 287             grml_warn_skel_remove
 288             printf '\nIt looks like you copied the grml zshrc to '\''~/.zshrc.global'\''.\n'
 289             printf 'Nowadays you just copy the global zshrc to '\''~/.zshrc'\'' to use\n'
 290             printf 'it on a non-grml-system.\n'
 291             ;;
 292         (${HOME}/.zshrc)
 293             printf '\nIt looks like you copied the grml zshrc to '\''~/.zshrc'\''.\n'
 294             printf 'We'\''ll disable this warning automatically for later sessions.\n'
 295             grml_do_not_warn_skel
 296             ;;
 297         (*)
 298             grml_do_not_warn_skel
 299             ;;
 300     esac
 301 else
 302     grml_warn_skel_main
 303     grml_warn_skel_remove
 304 fi
 305
 306 unfunction grml_warn_skel_remove grml_warn_skel_main
 307
 308 fi # GRML_WARN_SKEL
 309
 310 # }}}
 311
 312 # utility functions {{{
 313 # this function checks if a command exists and returns either true
 314 # or false. This avoids using 'which' and 'whence', which will
 315 # avoid problems with aliases for which on certain weird systems. :-)
 316 check_com() {
 317     local -i comonly
 318
 319     if [[ ${1} == '-c' ]] ; then
 320         (( comonly = 1 ))
 321         shift
 322     else
 323         (( comonly = 0 ))
 324     fi
 325
 326     if (( ${#argv} != 1 )) ; then
 327         printf 'usage: check_com [-c] <command>\n' >&2
 328         return 1
 329     fi
 330
 331     if (( comonly > 0 )) ; then
 332         [[ -n ${commands[$1]}  ]] && return 0
 333         return 1
 334     fi
 335
 336     if   [[ -n ${commands[$1]}    ]] \
 337       || [[ -n ${functions[$1]}   ]] \
 338       || [[ -n ${aliases[$1]}     ]] \
 339       || [[ -n ${reswords[(r)$1]} ]] ; then
 340
 341         return 0
 342     fi
 343
 344     return 1
 345 }
 346
 347 # creates an alias and precedes the command with
 348 # sudo if $EUID is not zero.
 349 salias() {
 350     local only=0 ; local multi=0
 351     while [[ ${1} == -* ]] ; do
 352         case ${1} in
 353             (-o) only=1 ;;
 354             (-a) multi=1 ;;
 355             (--) shift ; break ;;
 356             (-h)
 357                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 358                 printf '  -h      shows this help text.\n'
 359                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 360                 printf '          be careful using this option.\n'
 361                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 362                 return 0
 363                 ;;
 364             (*) printf "unkown option: '%s'\n" "${1}" ; return 1 ;;
 365         esac
 366         shift
 367     done
 368
 369     if (( ${#argv} > 1 )) ; then
 370         printf 'Too many arguments %s\n' "${#argv}"
 371         return 1
 372     fi
 373
 374     key="${1%%\=*}" ;  val="${1#*\=}"
 375     if (( EUID == 0 )) && (( only == 0 )); then
 376         alias -- "${key}=${val}"
 377     elif (( EUID > 0 )) ; then
 378         (( multi > 0 )) && val="${val// ; / ; sudo }"
 379         alias -- "${key}=sudo ${val}"
 380     fi
 381
 382     return 0
 383 }
 384
 385 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 386 # usage: uprint foo
 387 #   Where foo is the *name* of the parameter you want printed.
 388 #   Note that foo is no typo; $foo would be wrong here!
 389 if ! is42 ; then
 390     uprint () {
 391         local -a u
 392         local w
 393         local parameter=${1}
 394
 395         if [[ -z ${parameter} ]] ; then
 396             printf 'usage: uprint <parameter>\n'
 397             return 1
 398         fi
 399
 400         for w in ${(P)parameter} ; do
 401             [[ -z ${(M)u:#${w}} ]] && u=( ${u} ${w} )
 402         done
 403
 404         builtin print -l ${u}
 405     }
 406 fi
 407
 408 # Check if we can read given files and source those we can.
 409 xsource() {
 410     if (( ${#argv} < 1 )) ; then
 411         printf 'usage: xsource FILE(s)...\n' >&2
 412         return 1
 413     fi
 414
 415     while (( ${#argv} > 0 )) ; do
 416         [[ -r ${1} ]] && source ${1}
 417         shift
 418     done
 419     return 0
 420 }
 421
 422 # Check if we can read a given file and 'cat(1)' it.
 423 xcat() {
 424     if (( ${#argv} != 1 )) ; then
 425         printf 'usage: xcat FILE\n' >&2
 426         return 1
 427     fi
 428
 429     [[ -r ${1} ]] && cat ${1}
 430     return 0
 431 }
 432
 433 # Remove these functions again, they are of use only in these
 434 # setup files. This should be called at the end of .zshrc.
 435 xunfunction() {
 436     local -a funcs
 437     funcs=(salias xcat xsource xunfunction zrcautoload)
 438
 439     for func in $funcs ; do
 440         [[ -n ${functions[$func]} ]] \
 441             && unfunction $func
 442     done
 443     return 0
 444 }
 445
 446 #}}}
 447
 448 # locale setup {{{
 449 if [[ -z "$LANG" ]] ; then
 450    xsource "/etc/default/locale"
 451 fi
 452
 453 export LANG=${LANG:-en_US.iso885915}
 454 for var in LC_ALL LC_MESSAGES ; do
 455     [[ -n ${(P)var} ]] && export $var
 456 done
 457
 458 xsource "/etc/sysconfig/keyboard"
 459
 460 TZ=$(xcat /etc/timezone)
 461 # }}}
 462
 463 # check for potentially old files in 'completion.d' {{{
 464 setopt extendedglob
 465 xof=(/etc/zsh/completion.d/*~/etc/zsh/completion.d/_*(N))
 466 if (( ${#xof} > 0 )) ; then
 467     printf '\n -!- INFORMATION\n\n'
 468     printf ' -!- %s file(s) not starting with an underscore (_) found in\n' ${#xof}
 469     printf ' -!- /etc/zsh/completion.d/.\n\n'
 470     printf ' -!- While this has been the case in old versions of grml-etc-core,\n'
 471     printf ' -!- recent versions of the grml-zsh-setup have all these files rewritten\n'
 472     printf ' -!- and renamed. Furthermore, the grml-zsh-setup will *only* add files\n'
 473     printf ' -!- named _* to that directory.\n\n'
 474     printf ' -!- If you added functions to completion.d yourself, please consider\n'
 475     printf ' -!- moving them to /etc/zsh/functions.d/. Files in that directory, not\n'
 476     printf ' -!- starting with an underscore are marked for automatic loading\n'
 477     printf ' -!- by default (so that is quite convenient).\n\n'
 478     printf ' -!- If there are files *not* starting with an underscore from an older\n'
 479     printf ' -!- grml-etc-core in completion.d, you may safely remove them.\n\n'
 480     printf ' -!- Delete the files for example via running:\n\n'
 481     printf "      rm ${xof}\n\n"
 482     printf ' -!- Note, that this message will *not* go away, unless you yourself\n'
 483     printf ' -!- resolve the situation manually.\n\n'
 484     BROKEN_COMPLETION_DIR=1
 485 fi
 486 unset xof
 487 # }}}
 488
 489 # {{{ set some variables
 490 if check_com -c vim ; then
 491 #v#
 492     export EDITOR=${EDITOR:-vim}
 493 else
 494     export EDITOR=${EDITOR:-vi}
 495 fi
 496
 497 #v#
 498 export PAGER=${PAGER:-less}
 499
 500 #v#
 501 export MAIL=${MAIL:-/var/mail/$USER}
 502
 503 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 504 export SHELL='/bin/zsh'
 505
 506 # color setup for ls:
 507 check_com -c dircolors && eval $(dircolors -b)
 508 # color setup for ls on OS X:
 509 isdarwin && export CLICOLOR=1
 510
 511 # do MacPorts setup on darwin
 512 if isdarwin && [[ -d /opt/local ]]; then
 513     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 514     # zshenv.
 515     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 516     MANPATH="/opt/local/share/man:$MANPATH"
 517 fi
 518 # do Fink setup on darwin
 519 isdarwin && xsource /sw/bin/init.sh
 520
 521 # completion functions go to /etc/zsh/completion.d
 522 # function files may be put into /etc/zsh/functions.d, from where they
 523 # will be automatically autoloaded.
 524 if [[ -n "$BROKEN_COMPLETION_DIR" ]] ; then
 525     print 'Warning: not setting completion directories because broken files have been found.' >&2
 526 else
 527     [[ -d /etc/zsh/completion.d ]] && fpath=( $fpath /etc/zsh/completion.d )
 528     if [[ -d /etc/zsh/functions.d ]] ; then
 529         fdir='/etc/zsh/functions.d'
 530         fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 531         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 532             zrcautoload ${func:t}
 533         done
 534         unset fdir
 535     fi
 536 fi
 537
 538 # automatically remove duplicates from these arrays
 539 typeset -U path cdpath fpath manpath
 540 # }}}
 541
 542 # {{{ keybindings
 543 if [[ "$TERM" != emacs ]] ; then
 544     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 545     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 546     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 547     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 548     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 549     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 550     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 551     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 552     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 553     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 554     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 555     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 556     # ncurses stuff:
 557     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 558     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 559     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 560     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 561     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 562     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 563     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 564     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 565 fi
 566
 567 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 568 # use emacs style per default:
 569 bindkey -e
 570 # use vi style:
 571 # bindkey -v
 572
 573 #if [[ "$TERM" == screen ]] ; then
 574 bindkey '\e[1~' beginning-of-line       # home
 575 bindkey '\e[4~' end-of-line             # end
 576 bindkey '\e[A'  up-line-or-search       # cursor up
 577 bindkey '\e[B'  down-line-or-search     # <ESC>-
 578
 579 bindkey '^xp'   history-beginning-search-backward
 580 bindkey '^xP'   history-beginning-search-forward
 581 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 582 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 583 # if terminal type is set to 'rxvt':
 584 bindkey '\e[7~' beginning-of-line       # home
 585 bindkey '\e[8~' end-of-line             # end
 586 #fi
 587
 588 # insert unicode character
 589 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 590 # See for example http://unicode.org/charts/ for unicode characters code
 591 zrcautoload insert-unicode-char
 592 zle -N insert-unicode-char
 593 #k# Insert Unicode character
 594 bindkey '^Xi' insert-unicode-char
 595
 596 # just type 'cd ...' to get 'cd ../..'
 597 #  rationalise-dot() {
 598 #  if [[ $LBUFFER == *.. ]] ; then
 599 #    LBUFFER+=/..
 600 #  else
 601 #    LBUFFER+=.
 602 #  fi
 603 #  }
 604 #  zle -N rationalise-dot
 605 #  bindkey . rationalise-dot
 606
 607 #  bindkey '\eq' push-line-or-edit
 608
 609 ## toggle the ,. abbreviation feature on/off
 610 # NOABBREVIATION: default abbreviation-state
 611 #                 0 - enabled (default)
 612 #                 1 - disabled
 613 NOABBREVIATION=${NOABBREVIATION:-0}
 614
 615 grml_toggle_abbrev() {
 616     if (( ${NOABBREVIATION} > 0 )) ; then
 617         NOABBREVIATION=0
 618     else
 619         NOABBREVIATION=1
 620     fi
 621 }
 622
 623 zle -N grml_toggle_abbrev
 624 bindkey '^xA' grml_toggle_abbrev
 625
 626 # }}}
 627
 628 # a generic accept-line wrapper {{{
 629
 630 # This widget can prevent unwanted autocorrections from command-name
 631 # to _command-name, rehash automatically on enter and call any number
 632 # of builtin and user-defined widgets in different contexts.
 633 #
 634 # For a broader description, see:
 635 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 636 #
 637 # The code is imported from the file 'zsh/functions/accept-line' from
 638 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 639 # distributed under the same terms as zsh itself.
 640
 641 # A newly added command will may not be found or will cause false
 642 # correction attempts, if you got auto-correction set. By setting the
 643 # following style, we force accept-line() to rehash, if it cannot
 644 # find the first word on the command line in the $command[] hash.
 645 zstyle ':acceptline:*' rehash true
 646
 647 function Accept-Line() {
 648     setopt localoptions noksharrays
 649     local -a subs
 650     local -xi aldone
 651     local sub
 652
 653     zstyle -a ":acceptline:${alcontext}" actions subs
 654
 655     (( ${#subs} < 1 )) && return 0
 656
 657     (( aldone = 0 ))
 658     for sub in ${subs} ; do
 659         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 660         zle ${sub}
 661
 662         (( aldone > 0 )) && break
 663     done
 664 }
 665
 666 function Accept-Line-getdefault() {
 667     local default_action
 668
 669     zstyle -s ":acceptline:${alcontext}" default_action default_action
 670     case ${default_action} in
 671         ((accept-line|))
 672             printf ".accept-line"
 673             ;;
 674         (*)
 675             printf ${default_action}
 676             ;;
 677     esac
 678 }
 679
 680 function accept-line() {
 681     setopt localoptions noksharrays
 682     local -a cmdline
 683     local -x alcontext
 684     local buf com fname format msg default_action
 685
 686     alcontext='default'
 687     buf="${BUFFER}"
 688     cmdline=(${(z)BUFFER})
 689     com="${cmdline[1]}"
 690     fname="_${com}"
 691
 692     zstyle -t ":acceptline:${alcontext}" rehash \
 693         && [[ -z ${commands[$com]} ]]           \
 694         && rehash
 695
 696     if    [[ -n ${reswords[(r)$com]} ]] \
 697        || [[ -n ${aliases[$com]}     ]] \
 698        || [[ -n ${functions[$com]}   ]] \
 699        || [[ -n ${builtins[$com]}    ]] \
 700        || [[ -n ${commands[$com]}    ]] ; then
 701
 702         # there is something sensible to execute, just do it.
 703         alcontext='normal'
 704         zle Accept-Line
 705
 706         default_action=$(Accept-Line-getdefault)
 707         zstyle -T ":acceptline:${alcontext}" call_default \
 708             && zle ${default_action}
 709         return
 710     fi
 711
 712     if    [[ -o correct              ]] \
 713        || [[ -o correctall           ]] \
 714        && [[ -n ${functions[$fname]} ]] ; then
 715
 716         # nothing there to execute but there is a function called
 717         # _command_name; a completion widget. Makes no sense to
 718         # call it on the commandline, but the correct{,all} options
 719         # will ask for it nevertheless, so warn the user.
 720         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 721             # Okay, we warned the user before, he called us again,
 722             # so have it his way.
 723             alcontext='force'
 724             zle Accept-Line
 725
 726             default_action=$(Accept-Line-getdefault)
 727             zstyle -T ":acceptline:${alcontext}" call_default \
 728                 && zle ${default_action}
 729             return
 730         fi
 731
 732         # prepare warning message for the user, configurable via zstyle.
 733         zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 734
 735         if [[ -z ${msg} ]] ; then
 736             msg="%c will not execute and completion %f exists."
 737         fi
 738
 739         zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 740
 741         zle -M -- "${msg}"
 742         return
 743     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 744         # If we are here, the commandline contains something that is not
 745         # executable, which is neither subject to _command_name correction
 746         # and is not empty. might be a variable assignment
 747         alcontext='misc'
 748         zle Accept-Line
 749
 750         default_action=$(Accept-Line-getdefault)
 751         zstyle -T ":acceptline:${alcontext}" call_default \
 752             && zle ${default_action}
 753         return
 754     fi
 755
 756     # If we got this far, the commandline only contains whitespace, or is empty.
 757     alcontext='empty'
 758     zle Accept-Line
 759
 760     default_action=$(Accept-Line-getdefault)
 761     zstyle -T ":acceptline:${alcontext}" call_default \
 762         && zle ${default_action}
 763 }
 764
 765 zle -N accept-line
 766 zle -N Accept-Line
 767
 768 # }}}
 769
 770 # power completion - abbreviation expansion {{{
 771 # power completion / abbreviation expansion / buffer expansion
 772 # see http://zshwiki.org/home/examples/zleiab for details
 773 # less risky than the global aliases but powerful as well
 774 # just type the abbreviation key and afterwards ',.' to expand it
 775 declare -A abk
 776 setopt extendedglob
 777 setopt interactivecomments
 778 abk=(
 779 # key  # value                (#d additional doc string)
 780 #A# start
 781     '...' '../..'
 782     '....' '../../..'
 783     'BG' '& exit'
 784     'C' '| wc -l'
 785     'G' '|& grep --color=auto'
 786     'H' '| head'
 787     'Hl' ' --help |& less -r'      #d (Display help in pager)
 788     'L' '| less'
 789     'LL' '|& less -r'
 790     'M' '| most'
 791     'N' '&>/dev/null'              #d (No Output)
 792     'R' '| tr A-z N-za-m'          #d (ROT13)
 793     'SL' '| sort | less'
 794     'S' '| sort -u'
 795     'T' '| tail'
 796     'V' '|& vim -'
 797 #A# end
 798     'hide' "echo -en '\033]50;nil2\007'"
 799     'tiny' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
 800     'small' 'echo -en "\033]50;6x10\007"'
 801     'medium' 'echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
 802     'default' 'echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
 803     'large' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
 804     'huge' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
 805     'smartfont' 'echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
 806     'semifont' 'echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
 807     'da' 'du -sch'
 808     'j' 'jobs -l'
 809     'u' 'translate -i'
 810     'co' "./configure && make && sudo make install"
 811     'CH' "./configure --help"
 812     'conkeror' 'firefox -chrome chrome://conkeror/content'
 813     'dir' 'ls -lSrah'
 814     'lad' $'ls -d .*(/)\n# only show dot-directories'
 815     'lsa' $'ls -a .*(.)\n# only show dot-files'
 816     'lss' $'ls -l *(s,S,t)\n# only files with setgid/setuid/sticky flag'
 817     'lsl' $'ls -l *(@[1,10])\n# only symlinks'
 818     'lsx' $'ls -l *(*[1,10])\n# only executables'
 819     'lsw' $'ls -ld *(R,W,X.^ND/)\n# world-{readable,writable,executable} files'
 820     'lsbig' $'ls -flh *(.OL[1,10])\n# display the biggest files'
 821     'lsd' $'ls -d *(/)\n# only show directories'
 822     'lse' $'ls -d *(/^F)\n# only show empty directories'
 823     'lsnew' $'ls -rl *(D.om[1,10])\n# display the newest files'
 824     'lsold' $'ls -rtlh *(D.om[-11,-1])\n # display the oldest files'
 825     'lssmall' $'ls -Srl *(.oL[1,10])\n# display the smallest files'
 826     'rw-' 'chmod 600'
 827     '600' 'chmod u+rw-x,g-rwx,o-rwx'
 828     'rwx' 'chmod u+rwx'
 829     '700' 'chmod u+rwx,g-rwx,o-rwx'
 830     'r--' 'chmod u+r-wx,g-rwx,o-rwx'
 831     '644' $'chmod u+rw-x,g+r-wx,o+r-wx\n # 4=r,2=w,1=x'
 832     '755' 'chmod u+rwx,g+r-w+x,o+r-w+x'
 833     'md' 'mkdir -p '
 834     'cmplayer' 'mplayer -vo -fs -zoom fbdev'
 835     'fbmplayer' 'mplayer -vo -fs -zoom fbdev'
 836     'fblinks' 'links2 -driver fb'
 837     'insecssh' 'ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 838     'insecscp' 'scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 839     'fori' 'for i ({..}) { }'
 840     'cx' 'chmod +x'
 841     'e'  'print -l'
 842     'se' 'setopt interactivecomments'
 843     'va' 'valac --vapidir=../vapi/ --pkg=gtk+-2.0 gtktest.vala'
 844     'fb2' '=mplayer -vo fbdev -fs -zoom 1>/dev/null -xy 2'
 845     'fb3' '=mplayer -vo fbdev -fs  -zoom 1>/dev/null -xy 3'
 846     'ci' 'centericq'
 847     'D'  'export DISPLAY=:0.0'
 848     'mp' 'mplayer -vo xv -fs -zoom'
 849 )
 850
 851 globalias() {
 852     local MATCH
 853
 854     if (( NOABBREVIATION > 0 )) ; then
 855         LBUFFER="${LBUFFER},."
 856         return 0
 857     fi
 858
 859     matched_chars='[.-|_a-zA-Z0-9]#'
 860     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 861     LBUFFER+=${abk[$MATCH]:-$MATCH}
 862 }
 863
 864 zle -N globalias
 865 bindkey ",." globalias
 866 # }}}
 867
 868 # {{{ autoloading
 869 zrcautoload zmv    # who needs mmv or rename?
 870 zrcautoload history-search-end
 871
 872 # we don't want to quote/espace URLs on our own...
 873 # if autoload -U url-quote-magic ; then
 874 #    zle -N self-insert url-quote-magic
 875 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 876 # else
 877 #    print 'Notice: no url-quote-magic available :('
 878 # fi
 879 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 880
 881 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 882 alias run-help >&/dev/null && unalias run-help
 883 zrcautoload run-help # use via 'esc-h'
 884
 885 # completion system
 886 if zrcautoload compinit && compinit 2>/dev/null ; then
 887     compinit 2>/dev/null || print 'Notice: no compinit available :('
 888 else
 889     print 'Notice: no compinit available :('
 890     function zstyle { }
 891     function compdef { }
 892 fi
 893
 894 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 895
 896 is4 && \
 897 for mod in complist deltochar mathfunc ; do
 898     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 899 done
 900
 901 # autoload zsh modules when they are referenced
 902 if is4 ; then
 903     tmpargs=(
 904         a   stat
 905         a   zpty
 906         ap  mapfile
 907     )
 908
 909     while (( ${#tmpargs} > 0 )) ; do
 910         zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
 911         shift 2 tmpargs
 912     done
 913     unset tmpargs
 914 fi
 915
 916 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 917     #k# Insert files
 918     bindkey "^Xf" insert-files # C-x-f
 919 fi
 920
 921 bindkey ' '   magic-space    # also do history expansion on space
 922 #k# Trigger menu-complete
 923 bindkey '\ei' menu-complete  # menu completion via esc-i
 924
 925 # press esc-e for editing command line in $EDITOR or $VISUAL
 926 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 927     #k# Edit the current line in \kbd{\$EDITOR}
 928     bindkey '\ee' edit-command-line
 929 fi
 930
 931 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 932     #k# menu selection: pick item but stay in the menu
 933     bindkey -M menuselect '\e^M' accept-and-menu-complete
 934
 935     # accept a completion and try to complete again by using menu
 936     # completion; very useful with completing directories
 937     # by using 'undo' one's got a simple file browser
 938     bindkey -M menuselect '^o' accept-and-infer-next-history
 939 fi
 940
 941 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 942 _bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
 943 zle -N _bkdate
 944
 945 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 946 bindkey '^Ed' _bkdate
 947
 948 # press esc-m for inserting last typed word again (thanks to caphuso!)
 949 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 950 zle -N insert-last-typed-word;
 951
 952 #k# Insert last typed word
 953 bindkey "\em" insert-last-typed-word
 954
 955 #k# Shortcut for \kbd{fg<enter>}
 956 bindkey -s '^z' "fg\n"
 957
 958 # run command line as user root via sudo:
 959 sudo-command-line() {
 960     [[ -z $BUFFER ]] && zle up-history
 961     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
 962 }
 963 zle -N sudo-command-line
 964
 965 #k# Put the current command line into a \kbd{sudo} call
 966 bindkey "^Os" sudo-command-line
 967
 968 ### jump behind the first word on the cmdline.
 969 ### useful to add options.
 970 function jump_after_first_word() {
 971     local words
 972     words=(${(z)BUFFER})
 973
 974     if (( ${#words} <= 1 )) ; then
 975         CURSOR=${#BUFFER}
 976     else
 977         CURSOR=${#${words[1]}}
 978     fi
 979 }
 980 zle -N jump_after_first_word
 981
 982 bindkey '^x1' jump_after_first_word
 983
 984 # }}}
 985
 986 # {{{ set some important options
 987 # Please update these tags, if you change the umask settings below.
 988 #o# r_umask     002
 989 #o# r_umaskstr  rwxrwxr-x
 990 #o# umask       022
 991 #o# umaskstr    rwxr-xr-x
 992 (( EUID != 0 )) && umask 002 || umask 022
 993
 994 # history:
 995 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 996 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 997 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 998 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 999                             # list duplicates an older one, the older command is removed from the list
1000 setopt histignorespace      # remove command lines from the history list when
1001                             # the first character on the line is a space
1002 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
1003                             # and the command is the name of a directory, perform the cd command to that directory
1004 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
1005                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
1006                             # -> searches for word not in compressed files
1007                             # don't forget to quote '^', '~' and '#'!
1008 setopt longlistjobs         # display PID when suspending processes as well
1009 setopt notify               # report the status of backgrounds jobs immediately
1010 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
1011                             # the entire command path is hashed first.
1012 setopt completeinword       # not just at the end
1013 setopt nohup                # and don't kill them, either
1014 setopt auto_pushd           # make cd push the old directory onto the directory stack.
1015 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
1016 setopt nobeep               # avoid "beep"ing
1017 setopt pushd_ignore_dups    # don't push the same dir twice.
1018
1019 MAILCHECK=30       # mailchecks
1020 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
1021 watch=(notme root) # watch for everyone but me and root
1022
1023 # only slash should be considered as a word separator:
1024 slash-backward-kill-word() {
1025     local WORDCHARS="${WORDCHARS:s@/@}"
1026     # zle backward-word
1027     zle backward-kill-word
1028 }
1029 zle -N slash-backward-kill-word
1030
1031 #k# Kill everything in a word up to its last \kbd{/}
1032 bindkey '\ev' slash-backward-kill-word
1033
1034 # }}}
1035
1036 # {{{ history
1037
1038 ZSHDIR=$HOME/.zsh
1039
1040 #v#
1041 HISTFILE=$HOME/.zsh_history
1042 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1043 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1044
1045 # }}}
1046
1047 # dirstack handling {{{
1048
1049 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1050 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1051
1052 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1053     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1054     # "cd -" won't work after login by just setting $OLDPWD, so
1055     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
1056 fi
1057
1058 chpwd() {
1059     if is42 ; then
1060         builtin print -l ${(u)dirstack} >! ${DIRSTACKFILE}
1061     else
1062         uprint dirstack >! ${DIRSTACKFILE}
1063     fi
1064 }
1065
1066 # }}}
1067
1068 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
1069 if [[ $BATTERY -gt 0 ]] ; then
1070     if ! check_com -c acpi ; then
1071         BATTERY=0
1072     fi
1073 fi
1074
1075 battery() {
1076 if [[ $BATTERY -gt 0 ]] ; then
1077     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]##Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1078     if [[ -z "$PERCENT" ]] ; then
1079         PERCENT='acpi not present'
1080     else
1081         if [[ "$PERCENT" -lt 20 ]] ; then
1082             PERCENT="warning: ${PERCENT}%%"
1083         else
1084             PERCENT="${PERCENT}%%"
1085         fi
1086     fi
1087 fi
1088 }
1089 # }}}
1090
1091 # set colors for use in prompts {{{
1092 if zrcautoload colors && colors 2>/dev/null ; then
1093     BLUE="%{${fg[blue]}%}"
1094     RED="%{${fg_bold[red]}%}"
1095     GREEN="%{${fg[green]}%}"
1096     CYAN="%{${fg[cyan]}%}"
1097     MAGENTA="%{${fg[magenta]}%}"
1098     YELLOW="%{${fg[yellow]}%}"
1099     WHITE="%{${fg[white]}%}"
1100     NO_COLOUR="%{${reset_color}%}"
1101 else
1102     BLUE=$'%{\e[1;34m%}'
1103     RED=$'%{\e[1;31m%}'
1104     GREEN=$'%{\e[1;32m%}'
1105     CYAN=$'%{\e[1;36m%}'
1106     WHITE=$'%{\e[1;37m%}'
1107     MAGENTA=$'%{\e[1;35m%}'
1108     YELLOW=$'%{\e[1;33m%}'
1109     NO_COLOUR=$'%{\e[0m%}'
1110 fi
1111
1112 # }}}
1113
1114 # gather version control information for inclusion in a prompt {{{
1115
1116 if ! is41 ; then
1117     # Be quiet about version problems in grml's zshrc as the user cannot disable
1118     # loading vcs_info() as it is *in* the zshrc - as you can see. :-)
1119     # Just unset most probable variables and disable vcs_info altogether.
1120     local -i i
1121     for i in {0..9} ; do
1122         unset VCS_INFO_message_${i}_
1123     done
1124     zstyle ':vcs_info:*' enable false
1125 fi
1126
1127 # The following code is imported from the file 'zsh/functions/vcs_info'
1128 # from <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>,
1129 # which distributed under the same terms as zsh itself.
1130
1131 # we will only be using one variable, so let the code know now.
1132 zstyle ':vcs_info:*' max-exports 1
1133
1134 # vcs_info() documentation:
1135 #{{{
1136 # REQUIREMENTS:
1137 #{{{
1138 #     This functionality requires zsh version >= 4.1.*.
1139 #}}}
1140 #
1141 # LOADING:
1142 #{{{
1143 # To load vcs_info(), copy this file to your $fpath[] and do:
1144 #   % autoload -Uz vcs_info && vcs_info
1145 #
1146 # To work, vcs_info() needs 'setopt prompt_subst' in your setup.
1147 #}}}
1148 #
1149 # QUICKSTART:
1150 #{{{
1151 # To get vcs_info() working quickly (including colors), you can do the
1152 # following (assuming, you loaded vcs_info() properly - see above):
1153 #
1154 # % RED=$'%{\e[31m%}'
1155 # % GR=$'%{\e[32m%}'
1156 # % MA=$'%{\e[35m%}'
1157 # % YE=$'%{\e[33m%}'
1158 # % NC=$'%{\e[0m%}'
1159 #
1160 # % zstyle ':vcs_info:*' actionformats \
1161 #       "${MA}(${NC}%s${MA})${YE}-${MA}[${GR}%b${YE}|${RED}%a${MA}]${NC} "
1162 #
1163 # % zstyle ':vcs_info:*' formats       \
1164 #       "${MA}(${NC}%s${MA})${Y}-${MA}[${GR}%b${MA}]${NC}%} "
1165 #
1166 # % zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YE}%r"
1167 #
1168 # % precmd () { vcs_info }
1169 # % PS1='${MA}[${GR}%n${MA}] ${MA}(${RED}%!${MA}) ${YE}%3~ ${VCS_INFO_message_0_}${NC}%# '
1170 #
1171 # Obviously, the las two lines are there for demonstration: You need to
1172 # call vcs_info() from your precmd() function (see 'SPECIAL FUNCTIONS' in
1173 # 'man zshmisc'). Once that is done you need a *single* quoted
1174 # '${VCS_INFO_message_0_}' in your prompt.
1175 #
1176 # Now call the 'vcs_info_printsys' utility from the command line:
1177 #
1178 # % vcs_info_printsys
1179 # # list of supported version control backends:
1180 # # disabled systems are prefixed by a hash sign (#)
1181 # git
1182 # hg
1183 # bzr
1184 # darcs
1185 # svk
1186 # mtn
1187 # svn
1188 # cvs
1189 # cdv
1190 # tla
1191 # # flavours (cannot be used in the disable style; they
1192 # # are disabled with their master [git-svn -> git]):
1193 # git-p4
1194 # git-svn
1195 #
1196 # Ten version control backends as you can see. You may not want all
1197 # of these. Because there is no point in running the code to detect
1198 # systems you do not use. ever. So, there is a way to disable some
1199 # backends altogether:
1200 #
1201 # % zstyle ':vcs_info:*' disable bzr cdv darcs mtn svk tla
1202 #
1203 # If you rerun 'vcs_info_printsys' now, you will see the backends listed
1204 # in the 'disable' style marked as diabled by a hash sign. That means the
1205 # detection of these systems is skipped *completely*. No wasted time there.
1206 #
1207 # For more control, read the reference below.
1208 #}}}
1209 #
1210 # CONFIGURATION:
1211 #{{{
1212 # The vcs_info() feature can be configured via zstyle.
1213 #
1214 # First, the context in which we are working:
1215 #       :vcs_info:<vcs-string>:<user-context>
1216 #
1217 # ...where <vcs-string> is one of:
1218 #   - git, git-svn, git-p4, hg, darcs, bzr, cdv, mtn, svn, cvs, svk or tla.
1219 #
1220 # ...and <user-context> is a freely configurable string, assignable by the
1221 # user as the first argument to vcs_info() (see its description below).
1222 #
1223 # There is are three special values for <vcs-string>: The first is named
1224 # 'init', that is in effect as long as there was no decision what vcs
1225 # backend to use. The second is 'preinit; it is used *before* vcs_info()
1226 # is run, when initializing the data exporting variables. The third
1227 # special value is 'formats' and is used by the 'vcs_info_lastmsg' for
1228 # looking up its styles.
1229 #
1230 # There are two pre-defined values for <user-context>:
1231 #   default  - the one used if none is specified
1232 #   command  - used by vcs_info_lastmsg to lookup its styles.
1233 #
1234 # You may *not* use 'print_systems_' as a user-context string, because it
1235 # is used internally.
1236 #
1237 # You can of course use ':vcs_info:*' to match all VCSs in all
1238 # user-contexts at once.
1239 #
1240 # Another special context is 'formats', which is used by the
1241 # vcs_info_lastmsg() utility function (see below).
1242 #
1243 #
1244 # This is a description of all styles, that are looked up:
1245 #   formats             - A list of formats, used when actionformats is not
1246 #                         used (which is most of the time).
1247 #   actionformats       - A list of formats, used if a there is a special
1248 #                         action going on in your current repository;
1249 #                         (like an interactive rebase or a merge conflict)
1250 #   branchformat        - Some backends replace %b in the formats and
1251 #                         actionformats styles above, not only by a branch
1252 #                         name but also by a revision number. This style
1253 #                         let's you modify how that string should look like.
1254 #   nvcsformats         - These "formats" are exported, when we didn't detect
1255 #                         a version control system for the current directory.
1256 #                         This is useful, if you want vcs_info() to completely
1257 #                         take over the generation of your prompt.
1258 #                         You would do something like
1259 #                           PS1='${VCS_INFO_message_0_}'
1260 #                         to accomplish that.
1261 #   max-exports         - Defines the maximum number if VCS_INFO_message_*_
1262 #                         variables vcs_info() will export.
1263 #   enable              - Checked in the 'init' context. If set to false,
1264 #                         vcs_info() will do nothing.
1265 #   disable             - Provide a list of systems, you don't want
1266 #                         the vcs_info() to check for repositories
1267 #                         (checked in the 'init' context, too).
1268 #   disable-patterns    - A list of patterns that are checked against $PWD.
1269 #                         If the pattern matches, vcs_info will be disabled.
1270 #                         Say, ~/.zsh is a directory under version control,
1271 #                         in which you do not want vcs_info to be active, do:
1272 #                         zstyle ':vcs_info:*' disable-patterns "$HOME/.zsh+(|/*)"
1273 #   use-simple          - If there are two different ways of gathering
1274 #                         information, you can select the simpler one
1275 #                         by setting this style to true; the default
1276 #                         is to use the not-that-simple code, which is
1277 #                         potentially a lot slower but might be more
1278 #                         accurate in all possible cases.
1279 #   use-prompt-escapes  - determines if we assume that the assembled
1280 #                         string from vcs_info() includes prompt escapes.
1281 #                         (Used by vcs_info_lastmsg().
1282 #
1283 # The use-simple style is only available for the bzr backend.
1284 #
1285 # The default values for these in all contexts are:
1286 #   formats             " (%s)-[%b|%a]-"
1287 #   actionformats       " (%s)-[%b]-"
1288 #   branchformat        "%b:%r" (for bzr, svn and svk)
1289 #   nvcsformats         ""
1290 #   max-exports         2
1291 #   enable              true
1292 #   disable             (empty list)
1293 #   disable-patterns    (empty list)
1294 #   use-simple          false
1295 #   use-prompt-escapes  true
1296 #
1297 #
1298 # In normal formats and actionformats, the following replacements
1299 # are done:
1300 #   %s  - The vcs in use (git, hg, svn etc.)
1301 #   %b  - Information about the current branch.
1302 #   %a  - An identifier, that describes the action.
1303 #         Only makes sense in actionformats.
1304 #   %R  - base directory of the repository.
1305 #   %r  - repository name
1306 #         If %R is '/foo/bar/repoXY', %r is 'repoXY'.
1307 #   %S  - subdirectory within a repository. if $PWD is
1308 #         '/foo/bar/reposXY/beer/tasty', %S is 'beer/tasty'.
1309 #
1310 #
1311 # In branchformat these replacements are done:
1312 #   %b  - the branch name
1313 #   %r  - the current revision number
1314 #
1315 # Not all vcs backends have to support all replacements.
1316 # nvcsformat does not perform *any* replacements. It is just a string.
1317 #}}}
1318 #
1319 # ODDITIES:
1320 #{{{
1321 # If you want to use the %b (bold off) prompt expansion in 'formats', which
1322 # expands %b itself, use %%b. That will cause the vcs_info() expansion to
1323 # replace %%b with %b. So zsh's prompt expansion mechanism can handle it.
1324 # Similarly, to hand down %b from branchformat, use %%%%b. Sorry for this
1325 # inconvenience, but it cannot be easily avoided. Luckily we do not clash
1326 # with a lot of prompt expansions and this only needs to be done for those.
1327 # See 'man zshmisc' for details about EXPANSION OF PROMPT SEQUENCES.
1328 #}}}
1329 #
1330 # FUNCTION DESCRIPTIONS (public API):
1331 #{{{
1332 #   vcs_info()
1333 #       The main function, that runs all backends and assembles
1334 #       all data into ${VCS_INFO_message_*_}. This is the function
1335 #       you want to call from precmd() if you want to include
1336 #       up-to-date information in your prompt (see VARIABLE
1337 #       DESCRIPTION below).
1338 #
1339 #   vcs_info_printsys()
1340 #       Prints a list of all supported version control systems.
1341 #       Useful to find out possible contexts (and which of them are enabled)
1342 #       or values for the 'disable' style.
1343 #
1344 #   vcs_info_lastmsg()
1345 #       Outputs the last ${VCS_INFO_message_*_} value. Takes into account
1346 #       the value of the use-prompt-escapes style in ':vcs_info:formats'.
1347 #       It also only prints max-exports values.
1348 #
1349 # All functions named VCS_INFO_* are for internal use only.
1350 #}}}
1351 #
1352 # VARIABLE DESCRIPTION:
1353 #{{{
1354 #   ${VCS_INFO_message_N_}    (Note the trailing underscore)
1355 #       Where 'N' is an integer, eg: VCS_INFO_message_0_
1356 #       These variables are the storage for the informational message the
1357 #       last vcs_info() call has assembled. These are strongly connected
1358 #       to the formats, actionformats and nvcsformats styles described
1359 #       above. Those styles are lists. the first member of that list gets
1360 #       expanded into ${VCS_INFO_message_0_}, the second into
1361 #       ${VCS_INFO_message_1_} and the Nth into ${VCS_INFO_message_N-1_}.
1362 #       These parameters are exported into the environment.
1363 #       (See the max-exports style above.)
1364 #}}}
1365 #
1366 # EXAMPLES:
1367 #{{{
1368 #   Don't use vcs_info at all (even though it's in your prompt):
1369 #   % zstyle ':vcs_info:*' enable false
1370 #
1371 #   Disable the backends for bzr and svk:
1372 #   % zstyle ':vcs_info:*' disable bzr svk
1373 #
1374 #   Provide a special formats for git:
1375 #   % zstyle ':vcs_info:git:*' formats       ' GIT, BABY! [%b]'
1376 #   % zstyle ':vcs_info:git:*' actionformats ' GIT ACTION! [%b|%a]'
1377 #
1378 #   Use the quicker bzr backend (if you do, please report if it does
1379 #   the-right-thing[tm] - thanks):
1380 #   % zstyle ':vcs_info:bzr:*' use-simple true
1381 #
1382 #   Display the revision number in yellow for bzr and svn:
1383 #   % zstyle ':vcs_info:(svn|bzr):*' branchformat '%b%{'${fg[yellow]}'%}:%r'
1384 #
1385 # If you want colors, make sure you enclose the color codes in %{...%},
1386 # if you want to use the string provided by vcs_info() in prompts.
1387 #
1388 # Here is how to print the vcs infomation as a command:
1389 #   % alias vcsi='vcs_info command; vcs_info_lastmsg'
1390 #
1391 #   This way, you can even define different formats for output via
1392 #   vcs_info_lastmsg() in the ':vcs_info:command:*' namespace.
1393 #}}}
1394 #}}}
1395 # utilities
1396 VCS_INFO_adjust () { #{{{
1397     [[ -n ${vcs_comm[overwrite_name]} ]] && vcs=${vcs_comm[overwrite_name]}
1398     return 0
1399 }
1400 # }}}
1401 VCS_INFO_check_com () { #{{{
1402     (( ${+commands[$1]} )) && [[ -x ${commands[$1]} ]] && return 0
1403     return 1
1404 }
1405 # }}}
1406 VCS_INFO_formats () { # {{{
1407     setopt localoptions noksharrays
1408     local action=$1 branch=$2 base=$3
1409     local msg
1410     local -i i
1411
1412     if [[ -n ${action} ]] ; then
1413         zstyle -a ":vcs_info:${vcs}:${usercontext}" actionformats msgs
1414         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b|%a]-'
1415     else
1416         zstyle -a ":vcs_info:${vcs}:${usercontext}" formats msgs
1417         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b]-'
1418     fi
1419
1420     (( ${#msgs} > maxexports )) && msgs[${maxexports},-1]=()
1421     for i in {1..${#msgs}} ; do
1422         zformat -f msg ${msgs[$i]} a:${action} b:${branch} s:${vcs} r:${base:t} R:${base} S:"$(VCS_INFO_reposub ${base})"
1423         msgs[$i]=${msg}
1424     done
1425     return 0
1426 }
1427 # }}}
1428 VCS_INFO_maxexports () { #{{{
1429     local -ix maxexports
1430
1431     zstyle -s ":vcs_info:${vcs}:${usercontext}" "max-exports" maxexports || maxexports=2
1432     if [[ ${maxexports} != <-> ]] || (( maxexports < 1 )); then
1433         printf 'vcs_info(): expecting numeric arg >= 1 for max-exports (got %s).\n' ${maxexports}
1434         printf 'Defaulting to 2.\n'
1435         maxexports=2
1436     fi
1437 }
1438 # }}}
1439 VCS_INFO_nvcsformats () { #{{{
1440     setopt localoptions noksharrays
1441     local c v
1442
1443     if [[ $1 == 'preinit' ]] ; then
1444         c=default
1445         v=preinit
1446     fi
1447     zstyle -a ":vcs_info:${v:-$vcs}:${c:-$usercontext}" nvcsformats msgs
1448     (( ${#msgs} > maxexports )) && msgs[${maxexports},-1]=()
1449 }
1450 # }}}
1451 VCS_INFO_realpath () { #{{{
1452     # a portable 'readlink -f'
1453     # forcing a subshell, to ensure chpwd() is not removed
1454     # from the calling shell (if VCS_INFO_realpath() is called
1455     # manually).
1456     (
1457         (( ${+functions[chpwd]} )) && unfunction chpwd
1458         setopt chaselinks
1459         cd $1 2>/dev/null && pwd
1460     )
1461 }
1462 # }}}
1463 VCS_INFO_reposub () { #{{{
1464     setopt localoptions extendedglob
1465     local base=${1%%/##}
1466
1467     [[ ${PWD} == ${base}/* ]] || {
1468         printf '.'
1469         return 1
1470     }
1471     printf '%s' ${PWD#$base/}
1472     return 0
1473 }
1474 # }}}
1475 VCS_INFO_set () { #{{{
1476     setopt localoptions noksharrays
1477     local -i i j
1478
1479     if [[ $1 == '--clear' ]] ; then
1480         for i in {0..9} ; do
1481             unset VCS_INFO_message_${i}_
1482         done
1483     fi
1484     if [[ $1 == '--nvcs' ]] ; then
1485         [[ $2 == 'preinit' ]] && (( maxexports == 0 )) && (( maxexports = 1 ))
1486         for i in {0..$((maxexports - 1))} ; do
1487             typeset -gx VCS_INFO_message_${i}_=
1488         done
1489         VCS_INFO_nvcsformats $2
1490     fi
1491
1492     (( ${#msgs} - 1 < 0 )) && return 0
1493     for i in {0..$(( ${#msgs} - 1 ))} ; do
1494         (( j = i + 1 ))
1495         typeset -gx VCS_INFO_message_${i}_=${msgs[$j]}
1496     done
1497     return 0
1498 }
1499 # }}}
1500 # information gathering
1501 VCS_INFO_bzr_get_data () { # {{{
1502     setopt localoptions noksharrays
1503     local bzrbase bzrbr
1504     local -a bzrinfo
1505
1506     if zstyle -t ":vcs_info:${vcs}:${usercontext}" "use-simple" ; then
1507         bzrbase=${vcs_comm[basedir]}
1508         bzrinfo[2]=${bzrbase:t}
1509         if [[ -f ${bzrbase}/.bzr/branch/last-revision ]] ; then
1510             bzrinfo[1]=$(< ${bzrbase}/.bzr/branch/last-revision)
1511             bzrinfo[1]=${${bzrinfo[1]}%% *}
1512         fi
1513     else
1514         bzrbase=${${(M)${(f)"$( bzr info )"}:# ##branch\ root:*}/*: ##/}
1515         bzrinfo=( ${${${(M)${(f)"$( bzr version-info )"}:#(#s)(revno|branch-nick)*}/*: /}/*\//} )
1516         bzrbase="$(VCS_INFO_realpath ${bzrbase})"
1517     fi
1518
1519     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat bzrbr || bzrbr="%b:%r"
1520     zformat -f bzrbr "${bzrbr}" "b:${bzrinfo[2]}" "r:${bzrinfo[1]}"
1521     VCS_INFO_formats '' "${bzrbr}" "${bzrbase}"
1522     return 0
1523 }
1524 # }}}
1525 VCS_INFO_cdv_get_data () { # {{{
1526     local cdvbase
1527
1528     cdvbase=${vcs_comm[basedir]}
1529     VCS_INFO_formats '' "${cdvbase:t}" "${cdvbase}"
1530     return 0
1531 }
1532 # }}}
1533 VCS_INFO_cvs_get_data () { # {{{
1534     local cvsbranch cvsbase basename
1535
1536     cvsbase="."
1537     while [[ -d "${cvsbase}/../CVS" ]]; do
1538         cvsbase="${cvsbase}/.."
1539     done
1540     cvsbase="$(VCS_INFO_realpath ${cvsbase})"
1541     cvsbranch=$(< ./CVS/Repository)
1542     basename=${cvsbase:t}
1543     cvsbranch=${cvsbranch##${basename}/}
1544     [[ -z ${cvsbranch} ]] && cvsbranch=${basename}
1545     VCS_INFO_formats '' "${cvsbranch}" "${cvsbase}"
1546     return 0
1547 }
1548 # }}}
1549 VCS_INFO_darcs_get_data () { # {{{
1550     local darcsbase
1551
1552     darcsbase=${vcs_comm[basedir]}
1553     VCS_INFO_formats '' "${darcsbase:t}" "${darcsbase}"
1554     return 0
1555 }
1556 # }}}
1557 VCS_INFO_git_getaction () { #{{{
1558     local gitaction='' gitdir=$1
1559     local tmp
1560
1561     for tmp in "${gitdir}/rebase-apply" \
1562                "${gitdir}/rebase"       \
1563                "${gitdir}/../.dotest" ; do
1564         if [[ -d ${tmp} ]] ; then
1565             if   [[ -f "${tmp}/rebasing" ]] ; then
1566                 gitaction="rebase"
1567             elif [[ -f "${tmp}/applying" ]] ; then
1568                 gitaction="am"
1569             else
1570                 gitaction="am/rebase"
1571             fi
1572             printf '%s' ${gitaction}
1573             return 0
1574         fi
1575     done
1576
1577     for tmp in "${gitdir}/rebase-merge/interactive" \
1578                "${gitdir}/.dotest-merge/interactive" ; do
1579         if [[ -f "${tmp}" ]] ; then
1580             printf '%s' "rebase-i"
1581             return 0
1582         fi
1583     done
1584
1585     for tmp in "${gitdir}/rebase-merge" \
1586                "${gitdir}/.dotest-merge" ; do
1587         if [[ -d "${tmp}" ]] ; then
1588             printf '%s' "rebase-m"
1589             return 0
1590         fi
1591     done
1592
1593     if [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1594         printf '%s' "merge"
1595         return 0
1596     fi
1597
1598     if [[ -f "${gitdir}/BISECT_LOG" ]] ; then
1599         printf '%s' "bisect"
1600         return 0
1601     fi
1602     return 1
1603 }
1604 # }}}
1605 VCS_INFO_git_getbranch () { #{{{
1606     local gitbranch gitdir=$1
1607     local gitsymref='git symbolic-ref HEAD'
1608
1609     if    [[ -d "${gitdir}/rebase-apply" ]] \
1610        || [[ -d "${gitdir}/rebase" ]]       \
1611        || [[ -d "${gitdir}/../.dotest" ]]   \
1612        || [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1613         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1614         [[ -z ${gitbranch} ]] && [[ -r ${gitdir}/rebase-apply/head-name ]] \
1615             && gitbranch="$(< ${gitdir}/rebase-apply/head-name)"
1616
1617     elif   [[ -f "${gitdir}/rebase-merge/interactive" ]] \
1618         || [[ -d "${gitdir}/rebase-merge" ]] ; then
1619         gitbranch="$(< ${gitdir}/rebase-merge/head-name)"
1620
1621     elif   [[ -f "${gitdir}/.dotest-merge/interactive" ]] \
1622         || [[ -d "${gitdir}/.dotest-merge" ]] ; then
1623         gitbranch="$(< ${gitdir}/.dotest-merge/head-name)"
1624
1625     else
1626         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1627
1628         if [[ $? -ne 0 ]] ; then
1629             gitbranch="$(git describe --exact-match HEAD 2>/dev/null)"
1630
1631             if [[ $? -ne 0 ]] ; then
1632                 gitbranch="${${"$(< $gitdir/HEAD)"}[1,7]}..."
1633             fi
1634         fi
1635     fi
1636
1637     printf '%s' "${gitbranch##refs/heads/}"
1638     return 0
1639 }
1640 # }}}
1641 VCS_INFO_git_get_data () { # {{{
1642     setopt localoptions extendedglob
1643     local gitdir gitbase gitbranch gitaction
1644
1645     gitdir=${vcs_comm[gitdir]}
1646     gitbranch="$(VCS_INFO_git_getbranch ${gitdir})"
1647
1648     if [[ -z ${gitdir} ]] || [[ -z ${gitbranch} ]] ; then
1649         return 1
1650     fi
1651
1652     VCS_INFO_adjust
1653     gitaction="$(VCS_INFO_git_getaction ${gitdir})"
1654     gitbase=${PWD%/${$( git rev-parse --show-prefix )%/##}}
1655     VCS_INFO_formats "${gitaction}" "${gitbranch}" "${gitbase}"
1656     return 0
1657 }
1658 # }}}
1659 VCS_INFO_hg_get_data () { # {{{
1660     local hgbranch hgbase
1661
1662     hgbase=${vcs_comm[basedir]}
1663     hgbranch=$(< ${hgbase}/.hg/branch)
1664     VCS_INFO_formats '' "${hgbranch}" "${hgbase}"
1665     return 0
1666 }
1667 # }}}
1668 VCS_INFO_mtn_get_data () { # {{{
1669     local mtnbranch mtnbase
1670
1671     mtnbase=${vcs_comm[basedir]}
1672     mtnbranch=${${(M)${(f)"$( mtn status )"}:#(#s)Current branch:*}/*: /}
1673     VCS_INFO_formats '' "${mtnbranch}" "${mtnbase}"
1674     return 0
1675 }
1676 # }}}
1677 VCS_INFO_svk_get_data () { # {{{
1678     local svkbranch svkbase
1679
1680     svkbase=${vcs_comm[basedir]}
1681     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svkbranch || svkbranch="%b:%r"
1682     zformat -f svkbranch "${svkbranch}" "b:${vcs_comm[branch]}" "r:${vcs_comm[revision]}"
1683     VCS_INFO_formats '' "${svkbranch}" "${svkbase}"
1684     return 0
1685 }
1686 # }}}
1687 VCS_INFO_svn_get_data () { # {{{
1688     setopt localoptions noksharrays
1689     local svnbase svnbranch
1690     local -a svninfo
1691
1692     svnbase="."
1693     while [[ -d "${svnbase}/../.svn" ]]; do
1694         svnbase="${svnbase}/.."
1695     done
1696     svnbase="$(VCS_INFO_realpath ${svnbase})"
1697     svninfo=( ${${${(M)${(f)"$( svn info )"}:#(#s)(URL|Revision)*}/*: /}/*\//} )
1698
1699     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svnbranch || svnbranch="%b:%r"
1700     zformat -f svnbranch "${svnbranch}" "b:${svninfo[1]}" "r:${svninfo[2]}"
1701     VCS_INFO_formats '' "${svnbranch}" "${svnbase}"
1702     return 0
1703 }
1704 # }}}
1705 VCS_INFO_tla_get_data () { # {{{
1706     local tlabase tlabranch
1707
1708     tlabase="$(VCS_INFO_realpath ${vcs_comm[basedir]})"
1709     # tree-id gives us something like 'foo@example.com/demo--1.0--patch-4', so:
1710     tlabranch=${${"$( tla tree-id )"}/*\//}
1711     VCS_INFO_formats '' "${tlabranch}" "${tlabase}"
1712     return 0
1713 }
1714 # }}}
1715 # detection
1716 VCS_INFO_detect_by_dir() { #{{{
1717     local dirname=$1
1718     local basedir="." realbasedir
1719
1720     realbasedir="$(VCS_INFO_realpath ${basedir})"
1721     while [[ ${realbasedir} != '/' ]]; do
1722         if [[ -n ${vcs_comm[detect_need_file]} ]] ; then
1723             [[ -d ${basedir}/${dirname} ]] && \
1724             [[ -f ${basedir}/${dirname}/${vcs_comm[detect_need_file]} ]] && \
1725                 break
1726         else
1727             [[ -d ${basedir}/${dirname} ]] && break
1728         fi
1729
1730         basedir=${basedir}/..
1731         realbasedir="$(VCS_INFO_realpath ${basedir})"
1732     done
1733
1734     [[ ${realbasedir} == "/" ]] && return 1
1735     vcs_comm[basedir]=${realbasedir}
1736     return 0
1737 }
1738 # }}}
1739 VCS_INFO_bzr_detect() { #{{{
1740     VCS_INFO_check_com bzr || return 1
1741     vcs_comm[detect_need_file]=branch/format
1742     VCS_INFO_detect_by_dir '.bzr'
1743     return $?
1744 }
1745 # }}}
1746 VCS_INFO_cdv_detect() { #{{{
1747     VCS_INFO_check_com cdv || return 1
1748     vcs_comm[detect_need_file]=format
1749     VCS_INFO_detect_by_dir '.cdv'
1750     return $?
1751 }
1752 # }}}
1753 VCS_INFO_cvs_detect() { #{{{
1754     VCS_INFO_check_com svn || return 1
1755     [[ -d "./CVS" ]] && [[ -r "./CVS/Repository" ]] && return 0
1756     return 1
1757 }
1758 # }}}
1759 VCS_INFO_darcs_detect() { #{{{
1760     VCS_INFO_check_com darcs || return 1
1761     vcs_comm[detect_need_file]=format
1762     VCS_INFO_detect_by_dir '_darcs'
1763     return $?
1764 }
1765 # }}}
1766 VCS_INFO_git_detect() { #{{{
1767     if VCS_INFO_check_com git && git rev-parse --is-inside-work-tree &> /dev/null ; then
1768         vcs_comm[gitdir]="$(git rev-parse --git-dir 2> /dev/null)" || return 1
1769         if   [[ -d ${vcs_comm[gitdir]}/svn ]]             ; then vcs_comm[overwrite_name]='git-svn'
1770         elif [[ -d ${vcs_comm[gitdir]}/refs/remotes/p4 ]] ; then vcs_comm[overwrite_name]='git-p4' ; fi
1771         return 0
1772     fi
1773     return 1
1774 }
1775 # }}}
1776 VCS_INFO_hg_detect() { #{{{
1777     VCS_INFO_check_com hg || return 1
1778     vcs_comm[detect_need_file]=branch
1779     VCS_INFO_detect_by_dir '.hg'
1780     return $?
1781 }
1782 # }}}
1783 VCS_INFO_mtn_detect() { #{{{
1784     VCS_INFO_check_com mtn || return 1
1785     vcs_comm[detect_need_file]=revision
1786     VCS_INFO_detect_by_dir '_MTN'
1787     return $?
1788 }
1789 # }}}
1790 VCS_INFO_svk_detect() { #{{{
1791     setopt localoptions noksharrays extendedglob
1792     local -a info
1793     local -i fhash
1794     fhash=0
1795
1796     VCS_INFO_check_com svk || return 1
1797     [[ -f ~/.svk/config ]] || return 1
1798
1799     # This detection function is a bit different from the others.
1800     # We need to read svk's config file to detect a svk repository
1801     # in the first place. Therefore, we'll just proceed and read
1802     # the other information, too. This is more then any of the
1803     # other detections do but this takes only one file open for
1804     # svk at most. VCS_INFO_svk_get_data() get simpler, too. :-)
1805     while IFS= read -r line ; do
1806         if [[ -n ${vcs_comm[basedir]} ]] ; then
1807             line=${line## ##}
1808             [[ ${line} == depotpath:* ]] && vcs_comm[branch]=${line##*/}
1809             [[ ${line} == revision:* ]] && vcs_comm[revision]=${line##*[[:space:]]##}
1810             [[ -n ${vcs_comm[branch]} ]] && [[ -n ${vcs_comm[revision]} ]] && break
1811             continue
1812         fi
1813         (( fhash > 0 )) && [[ ${line} == '  '[^[:space:]]*:* ]] && break
1814         [[ ${line} == '  hash:'* ]] && fhash=1 && continue
1815         (( fhash == 0 )) && continue
1816         [[ ${PWD}/ == ${${line## ##}%:*}/* ]] && vcs_comm[basedir]=${${line## ##}%:*}
1817     done < ~/.svk/config
1818
1819     [[ -n ${vcs_comm[basedir]} ]]  && \
1820     [[ -n ${vcs_comm[branch]} ]]   && \
1821     [[ -n ${vcs_comm[revision]} ]] && return 0
1822     return 1
1823 }
1824 # }}}
1825 VCS_INFO_svn_detect() { #{{{
1826     VCS_INFO_check_com svn || return 1
1827     [[ -d ".svn" ]] && return 0
1828     return 1
1829 }
1830 # }}}
1831 VCS_INFO_tla_detect() { #{{{
1832     VCS_INFO_check_com tla || return 1
1833     vcs_comm[basedir]="$(tla tree-root 2> /dev/null)" && return 0
1834     return 1
1835 }
1836 # }}}
1837 # public API
1838 vcs_info_printsys () { # {{{
1839     vcs_info print_systems_
1840 }
1841 # }}}
1842 vcs_info_lastmsg () { # {{{
1843     local -i i
1844
1845     VCS_INFO_maxexports
1846     for i in {0..$((maxexports - 1))} ; do
1847         printf '$VCS_INFO_message_%d_: "' $i
1848         if zstyle -T ':vcs_info:formats:command' use-prompt-escapes ; then
1849             print -nP ${(P)${:-VCS_INFO_message_${i}_}}
1850         else
1851             print -n ${(P)${:-VCS_INFO_message_${i}_}}
1852         fi
1853         printf '"\n'
1854     done
1855 }
1856 # }}}
1857 vcs_info () { # {{{
1858     local pat
1859     local -i found
1860     local -a VCSs disabled dps
1861     local -x vcs usercontext
1862     local -ax msgs
1863     local -Ax vcs_comm
1864
1865     vcs="init"
1866     VCSs=(git hg bzr darcs svk mtn svn cvs cdv tla)
1867     case $1 in
1868         (print_systems_)
1869             zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1870             print -l '# list of supported version control backends:' \
1871                      '# disabled systems are prefixed by a hash sign (#)'
1872             for vcs in ${VCSs} ; do
1873                 [[ -n ${(M)disabled:#${vcs}} ]] && printf '#'
1874                 printf '%s\n' ${vcs}
1875             done
1876             print -l '# flavours (cannot be used in the disable style; they' \
1877                      '# are disabled with their master [git-svn -> git]):'   \
1878                      git-{p4,svn}
1879             return 0
1880             ;;
1881         ('')
1882             [[ -z ${usercontext} ]] && usercontext=default
1883             ;;
1884         (*) [[ -z ${usercontext} ]] && usercontext=$1
1885             ;;
1886     esac
1887
1888     zstyle -T ":vcs_info:${vcs}:${usercontext}" "enable" || {
1889         [[ -n ${VCS_INFO_message_0_} ]] && VCS_INFO_set --clear
1890         return 0
1891     }
1892     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1893
1894     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable-patterns" dps
1895     for pat in ${dps} ; do
1896         if [[ ${PWD} == ${~pat} ]] ; then
1897             [[ -n ${vcs_info_msg_0_} ]] && VCS_INFO_set --clear
1898             return 0
1899         fi
1900     done
1901
1902     VCS_INFO_maxexports
1903
1904     (( found = 0 ))
1905     for vcs in ${VCSs} ; do
1906         [[ -n ${(M)disabled:#${vcs}} ]] && continue
1907         vcs_comm=()
1908         VCS_INFO_${vcs}_detect && (( found = 1 )) && break
1909     done
1910
1911     (( found == 0 )) && {
1912         VCS_INFO_set --nvcs
1913         return 0
1914     }
1915
1916     VCS_INFO_${vcs}_get_data || {
1917         VCS_INFO_set --nvcs
1918         return 1
1919     }
1920
1921     VCS_INFO_set
1922     return 0
1923 }
1924
1925 VCS_INFO_set --nvcs preinit
1926 # }}}
1927
1928 # change vcs_info formats for the grml prompt
1929 if [[ "$TERM" == dumb ]] ; then
1930     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] "
1931     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "
1932 else
1933     # these are the same, just with a lot of colours:
1934     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} "
1935     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} "
1936     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1937 fi
1938
1939 # }}}
1940
1941 # {{{ set prompt
1942 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1943     promptinit # people should be able to use their favourite prompt
1944 else
1945     print 'Notice: no promptinit available :('
1946 fi
1947
1948 setopt prompt_subst
1949
1950 # make sure to use right prompt only when not running a command
1951 is41 && setopt transient_rprompt
1952
1953 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1954     [[ $NOPRECMD -gt 0 ]] && return 0
1955     # update VCS information
1956     vcs_info
1957
1958     if [[ $TERM == screen* ]] ; then
1959         print -nP "\ekzsh\e\\"
1960     fi
1961     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1962     if [[ $DONTSETRPROMPT -eq 0 ]] ; then
1963         if [[ $BATTERY -gt 0 ]] ; then
1964             # update battery (dropped into $PERCENT) information
1965             battery
1966             RPROMPT="%(?..:() ${PERCENT}"
1967         else
1968             RPROMPT="%(?..:() "
1969         fi
1970     fi
1971     # adjust title of xterm
1972     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1973     case $TERM in
1974         (xterm*|rxvt*)
1975             print -Pn "\e]0;%n@%m: %~\a"
1976             ;;
1977     esac
1978 }
1979
1980 # preexec() => a function running before every command
1981 is4 && [[ $NOPRECMD -eq 0 ]] && \
1982 preexec () {
1983     [[ $NOPRECMD -gt 0 ]] && return 0
1984 # set hostname if not running on host with name 'grml'
1985     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1986        NAME="@$HOSTNAME"
1987     fi
1988 # get the name of the program currently running and hostname of local machine
1989 # set screen window title if running in a screen
1990     if [[ "$TERM" == screen* ]] ; then
1991         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1992         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1993         echo -ne "\ek$CMD\e\\"
1994     fi
1995 # adjust title of xterm
1996     case $TERM in
1997         (xterm*|rxvt)
1998             print -Pn "\e]0;%n@%m: $1\a"
1999             ;;
2000     esac
2001 }
2002
2003 EXITCODE="%(?..%?%1v )"
2004 PS2='\`%_> '      # secondary prompt, printed when the shell needs more information to complete a command.
2005 PS3='?# '         # selection prompt used within a select loop.
2006 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
2007
2008 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
2009 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
2010     debian_chroot=$(cat /etc/debian_chroot)
2011 fi
2012
2013 # don't use colors on dumb terminals (like emacs):
2014 if [[ "$TERM" == dumb ]] ; then
2015     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2016 else
2017     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
2018     # set variable identifying the chroot you work in (used in the prompt below)
2019     if [[ $GRMLPROMPT -gt 0 ]] ; then
2020         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
2021 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# "
2022     else
2023         # This assembles the primary prompt string
2024         if (( EUID != 0 )); then
2025             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2026         else
2027             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2028         fi
2029     fi
2030 fi
2031
2032 # if we are inside a grml-chroot set a specific prompt theme
2033 if [[ -n "$GRML_CHROOT" ]] ; then
2034     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
2035 fi
2036 # }}}
2037
2038 # {{{ 'hash' some often used directories
2039 #d# start
2040 hash -d deb=/var/cache/apt/archives
2041 hash -d doc=/usr/share/doc
2042 hash -d linux=/lib/modules/$(command uname -r)/build/
2043 hash -d log=/var/log
2044 hash -d slog=/var/log/syslog
2045 hash -d src=/usr/src
2046 hash -d templ=/usr/share/doc/grml-templates
2047 hash -d tt=/usr/share/doc/texttools-doc
2048 hash -d www=/var/www
2049 #d# end
2050 # }}}
2051
2052 # {{{ some aliases
2053 if check_com -c screen ; then
2054     if [[ $UID -eq 0 ]] ; then
2055         [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
2056     elif [[ -r $HOME/.screenrc ]] ; then
2057         alias screen="${commands[screen]} -c $HOME/.screenrc"
2058     else
2059         [[ -r /etc/grml/screenrc_grml ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
2060     fi
2061 fi
2062
2063 # do we have GNU ls with color-support?
2064 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
2065     #a1# execute \kbd{@a@}:\quad ls with colors
2066     alias ls='ls -b -CF --color=auto'
2067     #a1# execute \kbd{@a@}:\quad list all files, with colors
2068     alias la='ls -la --color=auto'
2069     #a1# long colored list, without dotfiles (@a@)
2070     alias ll='ls -l --color=auto'
2071     #a1# long colored list, human readable sizes (@a@)
2072     alias lh='ls -hAl --color=auto'
2073     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2074     alias l='ls -lF --color=auto'
2075 else
2076     alias ls='ls -b -CF'
2077     alias la='ls -la'
2078     alias ll='ls -l'
2079     alias lh='ls -hAl'
2080     alias l='ls -lF'
2081 fi
2082
2083 alias mdstat='cat /proc/mdstat'
2084 alias ...='cd ../../'
2085
2086 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2087 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2088     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2089 fi
2090
2091 alias cp='nocorrect cp'         # no spelling correction on cp
2092 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
2093 alias mv='nocorrect mv'         # no spelling correction on mv
2094 alias rm='nocorrect rm'         # no spelling correction on rm
2095
2096 #a1# Execute \kbd{rmdir}
2097 alias rd='rmdir'
2098 #a1# Execute \kbd{rmdir}
2099 alias md='mkdir'
2100
2101 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2102 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2103 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2104
2105 # make sure it is not assigned yet
2106 [[ $(whence -w utf2iso &>/dev/null) == 'utf2iso: alias' ]] && unalias utf2iso
2107
2108 utf2iso() {
2109     if isutfenv ; then
2110         for ENV in $(env | command grep -i '.utf') ; do
2111             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2112         done
2113     fi
2114 }
2115
2116 # make sure it is not assigned yet
2117 [[ $(whence -w iso2utf &>/dev/null) == 'iso2utf: alias' ]] && unalias iso2utf
2118 iso2utf() {
2119     if ! isutfenv ; then
2120         for ENV in $(env | command grep -i '\.iso') ; do
2121             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2122         done
2123     fi
2124 }
2125
2126 # set up software synthesizer via speakup
2127 swspeak() {
2128     if [ -x /usr/sbin/swspeak-setup ] ; then
2129        setopt singlelinezle
2130        unsetopt prompt_cr
2131        export PS1="%m%# "
2132        /usr/sbin/swspeak-setup $@
2133      else # old version:
2134         aumix -w 90 -v 90 -p 90 -m 90
2135         if ! [[ -r /dev/softsynth ]] ; then
2136             flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
2137             return 1
2138         else
2139            setopt singlelinezle
2140            unsetopt prompt_cr
2141            export PS1="%m%# "
2142             nice -n -20 speechd-up
2143             sleep 2
2144             flite -o play -t "Finished setting up software synthesizer"
2145         fi
2146      fi
2147 }
2148
2149 # I like clean prompt, so provide simple way to get that
2150 check_com 0 || alias 0='return 0'
2151
2152 # for really lazy people like mika:
2153 check_com S &>/dev/null || alias S='screen'
2154 check_com s &>/dev/null || alias s='ssh'
2155
2156 # get top 10 shell commands:
2157 alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
2158
2159 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
2160 if check_com -c truecrypt ; then
2161     if isutfenv ; then
2162         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
2163     else
2164         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
2165     fi
2166 fi
2167
2168 #f1# Hints for the use of zsh on grml
2169 zsh-help() {
2170     print "$bg[white]$fg[black]
2171 zsh-help - hints for use of zsh on grml
2172 =======================================$reset_color"
2173
2174     print '
2175 Main configuration of zsh happens in /etc/zsh/zshrc.
2176 That file is part of the package grml-etc-core, if you want to
2177 use them on a non-grml-system just get the tar.gz from
2178 http://deb.grml.org/ or (preferably) get it from the git repository:
2179
2180   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2181
2182 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2183 The file is still there, but it is empty for backwards compatibility.
2184
2185 For your own changes use these two files:
2186     $HOME/.zshrc.pre
2187     $HOME/.zshrc.local
2188
2189 The former is sourced very early in our zshrc, the latter is sourced
2190 very lately.
2191
2192 System wide configuration without touching configuration files of grml
2193 can take place in /etc/zsh/zshrc.local.
2194
2195 Normally, the root user (EUID == 0) does not get the whole grml setup.
2196 If you want to force the whole setup for that user, too, set
2197 GRML_ALWAYS_LOAD_ALL=1 in .zshrc.pre in root'\''s home directory.
2198
2199 For information regarding zsh start at http://grml.org/zsh/
2200
2201 Take a look at grml'\''s zsh refcard:
2202 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2203
2204 Check out the main zsh refcard:
2205 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2206
2207 And of course visit the zsh-lovers:
2208 % man zsh-lovers
2209
2210 You can adjust some options through environment variables when
2211 invoking zsh without having to edit configuration files.
2212 Basically meant for bash users who are not used to the power of
2213 the zsh yet. :)
2214
2215   "NOCOR=1    zsh" => deactivate automatic correction
2216   "NOMENU=1   zsh" => do not use auto menu completion (note: use ctrl-d for completion instead!)
2217   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2218   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
2219
2220 A value greater than 0 is enables a feature; a value equal to zero
2221 disables it. If you like one or the other of these settings, you can
2222 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2223 zshrc.'
2224
2225     print "
2226 $bg[white]$fg[black]
2227 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2228 Enjoy your grml system with the zsh!$reset_color"
2229 }
2230
2231 # debian stuff
2232 if [[ -r /etc/debian_version ]] ; then
2233     #a3# Execute \kbd{apt-cache search}
2234     alias acs='apt-cache search'
2235     #a3# Execute \kbd{apt-cache show}
2236     alias acsh='apt-cache show'
2237     #a3# Execute \kbd{apt-cache policy}
2238     alias acp='apt-cache policy'
2239     #a3# Execute \kbd{apt-get dist-upgrade}
2240     salias adg="apt-get dist-upgrade"
2241     #a3# Execute \kbd{apt-get install}
2242     salias agi="apt-get install"
2243     #a3# Execute \kbd{aptitude install}
2244     salias ati="aptitude install"
2245     #a3# Execute \kbd{apt-get upgrade}
2246     salias ag="apt-get upgrade"
2247     #a3# Execute \kbd{apt-get update}
2248     salias au="apt-get update"
2249     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2250     salias -a up="aptitude update ; aptitude safe-upgrade"
2251     #a3# Execute \kbd{dpkg-buildpackage}
2252     alias dbp='dpkg-buildpackage'
2253     #a3# Execute \kbd{grep-excuses}
2254     alias ge='grep-excuses'
2255
2256     # debian upgrade
2257     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
2258     upgrade() {
2259         if [[ -z "$1" ]] ; then
2260             $SUDO apt-get update
2261             $SUDO apt-get -u upgrade
2262         else
2263             ssh $1 $SUDO apt-get update
2264             # ask before the upgrade
2265             local dummy
2266             ssh $1 $SUDO apt-get --no-act upgrade
2267             echo -n 'Process the upgrade?'
2268             read -q dummy
2269             if [[ $dummy == "y" ]] ; then
2270                 ssh $1 $SUDO apt-get -u upgrade --yes
2271             fi
2272         fi
2273     }
2274
2275     # get a root shell as normal user in live-cd mode:
2276     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2277        alias su="sudo su"
2278      fi
2279
2280     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2281     alias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2282     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2283     alias tlog="tail -f /var/log/syslog"    # follow the syslog
2284 fi
2285
2286 # sort installed Debian-packages by size
2287 if check_com -c grep-status ; then
2288     #a3# List installed Debian-packages sorted by size
2289     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
2290 fi
2291
2292 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2293 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord ; then
2294     if check_com -c wodim ; then
2295         alias cdrecord="echo 'cdrecord is not provided under its original name by Debian anymore.
2296 See #377109 in the BTS of Debian for more details.
2297
2298 Please use the wodim binary instead' ; return 1"
2299     fi
2300 fi
2301
2302 # get_tw_cli has been renamed into get_3ware
2303 if check_com -c get_3ware ; then
2304     get_tw_cli() {
2305         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
2306         get_3ware
2307     }
2308 fi
2309
2310 # I hate lacking backward compatibility, so provide an alternative therefore
2311 if ! check_com -c apache2-ssl-certificate ; then
2312
2313     apache2-ssl-certificate() {
2314
2315     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
2316     print 'You might want to take a look at Debian the package ssl-cert as well.'
2317     print 'To generate a certificate for use with apache2 follow the instructions:'
2318
2319     echo '
2320
2321 export RANDFILE=/dev/random
2322 mkdir /etc/apache2/ssl/
2323 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
2324 chmod 600 /etc/apache2/ssl/apache.pem
2325
2326 Run "grml-tips ssl-certificate" if you need further instructions.
2327 '
2328     }
2329 fi
2330 # }}}
2331
2332 # {{{ Use hard limits, except for a smaller stack and no core dumps
2333 unlimit
2334 is425 && limit stack 8192
2335 isgrmlcd && limit core 0 # important for a live-cd-system
2336 limit -s
2337 # }}}
2338
2339 # {{{ completion system
2340
2341 # called later (via is4 && grmlcomp)
2342 # note: use 'zstyle' for getting current settings
2343 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
2344 grmlcomp() {
2345     # TODO: This could use some additional information
2346
2347     # allow one error for every three characters typed in approximate completer
2348     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
2349
2350     # don't complete backup files as executables
2351     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
2352
2353     # start menu completion only if it could find no unambiguous initial string
2354     zstyle ':completion:*:correct:*'       insert-unambiguous true
2355     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
2356     zstyle ':completion:*:correct:*'       original true
2357
2358     # activate color-completion
2359     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
2360
2361     # format on completion
2362     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
2363
2364     # complete 'cd -<tab>' with menu
2365     zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
2366
2367     # insert all expansions for expand completer
2368     zstyle ':completion:*:expand:*'        tag-order all-expansions
2369     zstyle ':completion:*:history-words'   list false
2370
2371     # activate menu
2372     zstyle ':completion:*:history-words'   menu yes
2373
2374     # ignore duplicate entries
2375     zstyle ':completion:*:history-words'   remove-all-dups yes
2376     zstyle ':completion:*:history-words'   stop yes
2377
2378     # match uppercase from lowercase
2379     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
2380
2381     # separate matches into groups
2382     zstyle ':completion:*:matches'         group 'yes'
2383     zstyle ':completion:*'                 group-name ''
2384
2385     if [[ "$NOMENU" -eq 0 ]] ; then
2386         # if there are more than 5 options allow selecting from a menu
2387         zstyle ':completion:*'               menu select=5
2388     else
2389         # don't use any menus at all
2390         setopt no_auto_menu
2391     fi
2392
2393     zstyle ':completion:*:messages'        format '%d'
2394     zstyle ':completion:*:options'         auto-description '%d'
2395
2396     # describe options in full
2397     zstyle ':completion:*:options'         description 'yes'
2398
2399     # on processes completion complete all user processes
2400     zstyle ':completion:*:processes'       command 'ps -au$USER'
2401
2402     # offer indexes before parameters in subscripts
2403     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
2404
2405     # provide verbose completion information
2406     zstyle ':completion:*'                 verbose true
2407
2408     # recent (as of Dec 2007) zsh versions are able to provide descriptions
2409     # for commands (read: 1st word in the line) that it will list for the user
2410     # to choose from. The following disables that, because it's not exactly fast.
2411     zstyle ':completion:*:-command-:*:'    verbose false
2412
2413     # set format for warnings
2414     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
2415
2416     # define files to ignore for zcompile
2417     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
2418     zstyle ':completion:correct:'          prompt 'correct to: %e'
2419
2420     # Ignore completion functions for commands you don't have:
2421     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
2422
2423     # Provide more processes in completion of programs like killall:
2424     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
2425
2426     # complete manual by their section
2427     zstyle ':completion:*:manuals'    separate-sections true
2428     zstyle ':completion:*:manuals.*'  insert-sections   true
2429     zstyle ':completion:*:man:*'      menu yes select
2430
2431     # provide .. as a completion
2432     zstyle ':completion:*' special-dirs ..
2433
2434     # run rehash on completion so new installed program are found automatically:
2435     _force_rehash() {
2436         (( CURRENT == 1 )) && rehash
2437         return 1
2438     }
2439
2440     ## correction
2441     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
2442     if [[ "$NOCOR" -gt 0 ]] ; then
2443         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
2444         setopt nocorrect
2445     else
2446         # try to be smart about when to use what completer...
2447         setopt correct
2448         zstyle -e ':completion:*' completer '
2449             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
2450                 _last_try="$HISTNO$BUFFER$CURSOR"
2451                 reply=(_complete _match _ignored _prefix _files)
2452             else
2453                 if [[ $words[1] == (rm|mv) ]] ; then
2454                     reply=(_complete _files)
2455                 else
2456                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
2457                 fi
2458             fi'
2459     fi
2460
2461     # command for process lists, the local web server details and host completion
2462     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
2463
2464     # caching
2465     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
2466                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
2467
2468     # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
2469     if is42 ; then
2470         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
2471         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
2472     else
2473         _ssh_hosts=()
2474         _etc_hosts=()
2475     fi
2476     hosts=(
2477         $(hostname)
2478         "$_ssh_hosts[@]"
2479         "$_etc_hosts[@]"
2480         grml.org
2481         localhost
2482     )
2483     zstyle ':completion:*:hosts' hosts $hosts
2484     # TODO: so, why is this here?
2485     #  zstyle '*' hosts $hosts
2486
2487     # use generic completion system for programs not yet defined; (_gnu_generic works
2488     # with commands that provide a --help option with "standard" gnu-like output.)
2489     compdef _gnu_generic tail head feh cp mv df stow uname ipacsum fetchipac
2490
2491     # see upgrade function in this file
2492     compdef _hosts upgrade
2493 }
2494 # }}}
2495
2496 # {{{ grmlstuff
2497 grmlstuff() {
2498 # people should use 'grml-x'!
2499     startx() {
2500         if [[ -e /etc/X11/xorg.conf ]] ; then
2501             [[ -x /usr/bin/startx ]] && /usr/bin/startx "$@" || /usr/X11R6/bin/startx "$@"
2502         else
2503             echo "Please use the script \"grml-x\" for starting the X Window System
2504 because there does not exist /etc/X11/xorg.conf yet.
2505 If you want to use startx anyway please call \"/usr/bin/startx\"."
2506             return -1
2507         fi
2508     }
2509
2510     xinit() {
2511         if [[ -e /etc/X11/xorg.conf ]] ; then
2512             [[ -x /usr/bin/xinit ]] && /usr/bin/xinit || /usr/X11R6/bin/xinit
2513         else
2514             echo "Please use the script \"grml-x\" for starting the X Window System.
2515 because there does not exist /etc/X11/xorg.conf yet.
2516 If you want to use xinit anyway please call \"/usr/bin/xinit\"."
2517             return -1
2518         fi
2519     }
2520
2521     if check_com -c 915resolution ; then
2522         alias 855resolution='echo -e "Please use 915resolution as resolution modify tool for Intel graphic chipset."; return -1'
2523     fi
2524
2525     #a1# Output version of running grml
2526     alias grml-version='cat /etc/grml_version'
2527
2528     if check_com -c rebuildfstab ; then
2529         #a1# Rebuild /etc/fstab
2530         alias grml-rebuildfstab='rebuildfstab -v -r -config'
2531     fi
2532
2533     if check_com -c grml-debootstrap ; then
2534         alias debian2hd='print "Installing debian to harddisk is possible via using grml-debootstrap." ; return 1'
2535     fi
2536 }
2537 # }}}
2538
2539 # {{{ now run the functions
2540 isgrml && checkhome
2541 is4    && isgrml    && grmlstuff
2542 is4    && grmlcomp
2543 # }}}
2544
2545 # {{{ keephack
2546 is4 && xsource "/etc/zsh/keephack"
2547 # }}}
2548
2549 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
2550 # You use it as follows:
2551 # $ NTREF=/reference/file
2552 # $ ls -l *(e:nt:)
2553 # This lists all the files in the current directory newer than the reference file.
2554 # You can also specify the reference file inline; note quotes:
2555 # $ ls -l *(e:'nt ~/.zshenv':)
2556 is4 && nt() {
2557     if [[ -n $1 ]] ; then
2558         local NTREF=${~1}
2559     fi
2560     [[ $REPLY -nt $NTREF ]]
2561 }
2562 # }}}
2563
2564 # shell functions {{{
2565
2566 #f1# Provide csh compatibility
2567 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
2568
2569 #f1# Reload an autoloadable function
2570 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2571
2572 #f1# Reload zsh setup
2573 reload() {
2574     if [[ "$#*" -eq 0 ]] ; then
2575         [[ -r ~/.zshrc ]] && . ~/.zshrc
2576     else
2577         local fn
2578         for fn in "$@"; do
2579             unfunction $fn
2580             autoload -U $fn
2581         done
2582     fi
2583 }
2584 compdef _functions reload freload
2585
2586 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2587 sll() {
2588     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2589     for i in "$@" ; do
2590         file=$i
2591         while [[ -h "$file" ]] ; do
2592             ls -l $file
2593             file=$(readlink "$file")
2594         done
2595     done
2596 }
2597
2598 # fast manual access
2599 if check_com qma ; then
2600     #f1# View the zsh manual
2601     manzsh()  { qma zshall "$1" }
2602     compdef _man qma
2603 else
2604     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
2605 fi
2606
2607 if check_com -c $PAGER ; then
2608     #f1# View Debian's changelog of a given package
2609     dchange() {
2610         if [[ -r /usr/share/doc/${1}/changelog.Debian.gz ]] ; then
2611             $PAGER /usr/share/doc/${1}/changelog.Debian.gz
2612         elif [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2613             $PAGER /usr/share/doc/${1}/changelog.gz
2614         else
2615             if check_com -c aptitude ; then
2616                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2617                 if isgrml ; then
2618                     aptitude -t unstable changelog ${1}
2619                 else
2620                     aptitude changelog ${1}
2621                 fi
2622             else
2623                 echo "No changelog for package $1 found, sorry."
2624                 return 1
2625             fi
2626         fi
2627     }
2628     _dchange() { _files -W /usr/share/doc -/ }
2629     compdef _dchange dchange
2630
2631     #f1# View Debian's NEWS of a given package
2632     dnews() {
2633         if [[ -r /usr/share/doc/${1}/NEWS.Debian.gz ]] ; then
2634             $PAGER /usr/share/doc/${1}/NEWS.Debian.gz
2635         else
2636             if [[ -r /usr/share/doc/${1}/NEWS.gz ]] ; then
2637                 $PAGER /usr/share/doc/${1}/NEWS.gz
2638             else
2639                 echo "No NEWS file for package $1 found, sorry."
2640                 return 1
2641             fi
2642         fi
2643     }
2644     _dnews() { _files -W /usr/share/doc -/ }
2645     compdef _dnews dnews
2646
2647     #f1# View upstream's changelog of a given package
2648     uchange() {
2649         if [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2650             $PAGER /usr/share/doc/${1}/changelog.gz
2651         else
2652             echo "No changelog for package $1 found, sorry."
2653             return 1
2654         fi
2655     }
2656     _uchange() { _files -W /usr/share/doc -/ }
2657     compdef _uchange uchange
2658 fi
2659
2660 # zsh profiling
2661 profile() {
2662     ZSH_PROFILE_RC=1 $SHELL "$@"
2663 }
2664
2665 #f1# Edit an alias via zle
2666 edalias() {
2667     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2668 }
2669 compdef _aliases edalias
2670
2671 #f1# Edit a function via zle
2672 edfunc() {
2673     [[ -z "$1" ]] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
2674 }
2675 compdef _functions edfunc
2676
2677 # use it e.g. via 'Restart apache2'
2678 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2679 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2680 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2681 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2682 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2683 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2684     __start_stop() {
2685         local action_="${1:l}"  # e.g Start/Stop/Restart
2686         local service_="$2"
2687         local param_="$3"
2688
2689         local service_target_="$(readlink /etc/init.d/$service_)"
2690         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2691             # runit
2692             case "${action_}" in
2693                 start) if [[ ! -e /etc/service/$service_ ]]; then
2694                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2695                        else
2696                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2697                        fi ;;
2698                 # there is no reload in runits sysv emulation
2699                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2700                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2701             esac
2702         else
2703             # sysvinit
2704             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2705         fi
2706     }
2707
2708     for i in Start Restart Stop Force-Reload Reload ; do
2709         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2710     done
2711 fi
2712
2713 #f1# Provides useful information on globbing
2714 H-Glob() {
2715     echo -e "
2716     /      directories
2717     .      plain files
2718     @      symbolic links
2719     =      sockets
2720     p      named pipes (FIFOs)
2721     *      executable plain files (0100)
2722     %      device files (character or block special)
2723     %b     block special files
2724     %c     character special files
2725     r      owner-readable files (0400)
2726     w      owner-writable files (0200)
2727     x      owner-executable files (0100)
2728     A      group-readable files (0040)
2729     I      group-writable files (0020)
2730     E      group-executable files (0010)
2731     R      world-readable files (0004)
2732     W      world-writable files (0002)
2733     X      world-executable files (0001)
2734     s      setuid files (04000)
2735     S      setgid files (02000)
2736     t      files with the sticky bit (01000)
2737
2738   print *(m-1)          # Files modified up to a day ago
2739   print *(a1)           # Files accessed a day ago
2740   print *(@)            # Just symlinks
2741   print *(Lk+50)        # Files bigger than 50 kilobytes
2742   print *(Lk-50)        # Files smaller than 50 kilobytes
2743   print **/*.c          # All *.c files recursively starting in \$PWD
2744   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2745   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2746   print *~*.*           # All Files that do not contain a dot
2747   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2748   print -l *(.c|.h)     # Lists *.c and *.h
2749   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2750   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2751 }
2752 alias help-zshglob=H-Glob
2753
2754 check_com -c qma && alias ?='qma zshall'
2755
2756 # grep for running process, like: 'any vim'
2757 any() {
2758     if [[ -z "$1" ]] ; then
2759         echo "any - grep for process(es) by keyword" >&2
2760         echo "Usage: any <keyword>" >&2 ; return 1
2761     else
2762         local STRING=$1
2763         local LENGTH=$(expr length $STRING)
2764         local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
2765         local REST=$(echo $(expr substr $STRING 2 $LENGTH))
2766         ps xauwww| grep "[$FIRSCHAR]$REST"
2767     fi
2768 }
2769
2770 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2771 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2772 [[ -r /proc/1/maps ]] && \
2773 deswap() {
2774     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2775     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2776     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2777 }
2778
2779 # print hex value of a number
2780 hex() {
2781     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
2782 }
2783
2784 # calculate (or eval at all ;-)) with perl => p[erl-]eval
2785 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
2786 peval() {
2787     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
2788     perl -e "print eval($CALC),\"\n\";"
2789 }
2790 functions peval &>/dev/null && alias calc=peval
2791
2792 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
2793 # certain circumstances, so work around it, no matter which environment we have
2794 brltty() {
2795     if [[ -z "$DISPLAY" ]] ; then
2796         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
2797         command brltty "$@"
2798     else
2799         command brltty "$@"
2800     fi
2801 }
2802
2803 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
2804 aoeu() {
2805     echo -n 'Switching to us keyboard layout: '
2806     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
2807     echo 'Done'
2808 }
2809 asdf() {
2810     echo -n 'Switching to dvorak keyboard layout: '
2811     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
2812     echo 'Done'
2813 }
2814 # just press 'asdf' key to toggle from neon layout to us keyboard layout
2815 uiae() {
2816     echo -n 'Switching to us keyboard layout: '
2817     setxkbmap us && echo 'Done' || echo 'Failed'
2818 }
2819
2820 # set up an ipv6 tunnel
2821 ipv6-tunnel() {
2822     case $1 in
2823         start)
2824             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2825                 print 'ipv6 tunnel already set up, nothing to be done.'
2826                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
2827             else
2828                 [[ -n "$PUBLIC_IP" ]] || \
2829                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
2830                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
2831
2832                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
2833                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
2834                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
2835                 ifconfig sit0 tunnel ::192.88.99.1 up
2836                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
2837             fi
2838             ;;
2839         status)
2840             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2841                 print 'ipv6 tunnel available' ; return 0
2842             else
2843                 print 'ipv6 tunnel not available' ; return 1
2844             fi
2845             ;;
2846         stop)
2847             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2848                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
2849                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
2850             else
2851                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
2852             fi
2853             ;;
2854         *)
2855             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
2856             ;;
2857     esac
2858 }
2859
2860 # run dhclient for wireless device
2861 iwclient() {
2862     salias dhclient "$(wavemon -d | awk '/device/{print $2}')"
2863 }
2864
2865 # spawn a minimally set up ksh - useful if you want to umount /usr/.
2866 minimal-shell() {
2867     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ksh
2868 }
2869
2870 # make a backup of a file
2871 bk() {
2872     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2873 }
2874
2875 #f1# grep for patterns in grml's zsh setup
2876 zg() {
2877 #{{{
2878     LANG=C perl -e '
2879
2880 sub usage {
2881     print "usage: zg -[anr] <pattern>\n";
2882     print " Search for patterns in grml'\''s zshrc.\n";
2883     print " zg takes no or exactly one option plus a non empty pattern.\n\n";
2884     print "   options:\n";
2885     print "     --  no options (use if your pattern starts in with a dash.\n";
2886     print "     -a  search for the pattern in all code regions\n";
2887     print "     -n  search for the pattern in non-root code only\n";
2888     print "     -r  search in code for everyone (also root) only\n\n";
2889     print "   The default is -a for non-root users and -r for root.\n\n";
2890     print " If you installed the zshrc to a non-default locations (ie *NOT*\n";
2891     print " in /etc/zsh/zshrc) do: export GRML_ZSHRC=\$HOME/.zshrc\n";
2892     print " ...in case you copied the file to that location.\n\n";
2893     exit 1;
2894 }
2895
2896 if ($ENV{GRML_ZSHRC} ne "") {
2897     $RC = $ENV{GRML_ZSHRC};
2898 } else {
2899     $RC = "/etc/zsh/zshrc";
2900 }
2901
2902 usage if ($#ARGV < 0 || $#ARGV > 1);
2903 if ($> == 0) { $mode = "allonly"; }
2904 else { $mode = "all"; }
2905
2906 $opt = $ARGV[0];
2907 if ($opt eq "--")     { shift; }
2908 elsif ($opt eq "-a")  { $mode = "all"; shift; }
2909 elsif ($opt eq "-n")  { $mode = "nonroot"; shift; }
2910 elsif ($opt eq "-r" ) { $mode = "allonly"; shift; }
2911 elsif ($opt =~ m/^-/ || $#ARGV > 0) { usage(); }
2912
2913 $pattern = $ARGV[0];
2914 usage() if ($pattern eq "");
2915
2916 open FH, "<$RC" or die "zg: Could not open $RC: $!\n";
2917 while ($line = <FH>) {
2918     chomp $line;
2919     if ($line =~ m/^#:grep:marker:for:mika:/) { $markerfound = 1; next; }
2920     next if ($mode eq "nonroot" && markerfound == 0);
2921     break if ($mode eq "allonly" && markerfound == 1);
2922     print $line, "\n" if ($line =~ /$pattern/);
2923 }
2924 close FH;
2925 exit 0;
2926
2927     ' -- "$@"
2928 #}}}
2929     return $?
2930 }
2931
2932 # }}}
2933
2934 # {{{ make sure our environment is clean regarding colors
2935 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2936 # }}}
2937
2938 # source another config file if present {{{
2939 xsource "/etc/zsh/zshrc.local"
2940 # }}}
2941
2942 # "persistent history" {{{
2943 # just write important commands you always need to ~/.important_commands
2944 if [[ -r ~/.important_commands ]] ; then
2945     fc -R ~/.important_commands
2946 fi
2947 # }}}
2948
2949 #:grep:marker:for:mika: :-)
2950 ### non-root (EUID != 0) code below
2951 ###
2952
2953 (( GRML_ALWAYS_LOAD_ALL == 0 )) && (( $EUID == 0 )) && return 0
2954
2955 # variables {{{
2956
2957 # set terminal property (used e.g. by msgid-chooser)
2958 export COLORTERM="yes"
2959
2960 # set default browser
2961 if [[ -z "$BROWSER" ]] ; then
2962     if [[ -n "$DISPLAY" ]] ; then
2963         #v# If X11 is running
2964         check_com -c firefox && export BROWSER=firefox
2965     else
2966         #v# If no X11 is running
2967         check_com -c w3m && export BROWSER=w3m
2968     fi
2969 fi
2970
2971 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
2972 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
2973 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
2974
2975 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
2976 #v# [for non-root only]
2977 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
2978 # }}}
2979
2980 # aliases {{{
2981
2982 # Xterm resizing-fu.
2983 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
2984 alias hide='echo -en "\033]50;nil2\007"'
2985 alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
2986 alias small='echo -en "\033]50;6x10\007"'
2987 alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
2988 alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
2989 alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
2990 alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
2991 alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
2992 alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
2993
2994 # general
2995 #a2# Execute \kbd{du -sch}
2996 alias da='du -sch'
2997 #a2# Execute \kbd{jobs -l}
2998 alias j='jobs -l'
2999
3000 # compile stuff
3001 #a2# Execute \kbd{./configure}
3002 alias CO="./configure"
3003 #a2# Execute \kbd{./configure --help}
3004 alias CH="./configure --help"
3005
3006 # http://conkeror.mozdev.org/
3007 # TODO: I think this should be removed, as conkeror is not a simple extension anymore
3008 #a2# Run a keyboard driven firefox
3009 alias conkeror='firefox -chrome chrome://conkeror/content'
3010
3011 # arch/tla stuff
3012 if check_com -c tla ; then
3013     #a2# Execute \kbd{tla what-changed --diffs | less}
3014     alias tdi='tla what-changed --diffs | less'
3015     #a2# Execute \kbd{tla-buildpackage}
3016     alias tbp='tla-buildpackage'
3017     #a2# Execute \kbd{tla archive-mirror}
3018     alias tmi='tla archive-mirror'
3019     #a2# Execute \kbd{tla commit}
3020     alias tco='tla commit'
3021     #a2# Execute \kbd{tla star-merge}
3022     alias tme='tla star-merge'
3023 fi
3024
3025 # listing stuff
3026 #a2# Execute \kbd{ls -lSrah}
3027 alias dir="ls -lSrah"
3028 #a2# Only show dot-directories
3029 alias lad='ls -d .*(/)'                # only show dot-directories
3030 #a2# Only show dot-files
3031 alias lsa='ls -a .*(.)'                # only show dot-files
3032 #a2# Only files with setgid/setuid/sticky flag
3033 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
3034 #a2# Only show 1st ten symlinks
3035 alias lsl='ls -l *(@[1,10])'           # only symlinks
3036 #a2# Display only executables
3037 alias lsx='ls -l *(*[1,10])'           # only executables
3038 #a2# Display world-{readable,writable,executable} files
3039 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
3040 #a2# Display the ten biggest files
3041 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
3042 #a2# Only show directories
3043 alias lsd='ls -d *(/)'                 # only show directories
3044 #a2# Only show empty directories
3045 alias lse='ls -d *(/^F)'               # only show empty directories
3046 #a2# Display the ten newest files
3047 alias lsnew="ls -rl *(D.om[1,10])"     # display the newest files
3048 #a2# Display the ten oldest files
3049 alias lsold="ls -rtlh *(D.om[1,10])"   # display the oldest files
3050 #a2# Display the ten smallest files
3051 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
3052
3053 # chmod
3054 #a2# Execute \kbd{chmod 600}
3055 alias rw-='chmod 600'
3056 #a2# Execute \kbd{chmod 700}
3057 alias rwx='chmod 700'
3058 #m# a2 r-{}- Execute \kbd{chmod 644}
3059 alias r--='chmod 644'
3060 #a2# Execute \kbd{chmod 755}
3061 alias r-x='chmod 755'
3062
3063 # some useful aliases
3064 #a2# Execute \kbd{mkdir -o}
3065 alias md='mkdir -p'
3066
3067 check_com -c ipython && alias ips='ipython -p sh'
3068
3069 # console stuff
3070 #a2# Execute \kbd{mplayer -vo fbdev}
3071 alias cmplayer='mplayer -vo fbdev'
3072 #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
3073 alias fbmplayer='mplayer -vo fbdev -fs -zoom'
3074 #a2# Execute \kbd{links2 -driver fb}
3075 alias fblinks='links2 -driver fb'
3076
3077 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3078 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3079 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3080
3081 # simple webserver
3082 check_com -c python && alias http="python -m SimpleHTTPServer"
3083
3084 # Use 'g' instead of 'git':
3085 check_com g || alias g='git'
3086
3087 # use colors when browsing man pages, but only if not using LESS_TERMCAP_* from /etc/zsh/zshenv:
3088 if [[ -z "$LESS_TERMCAP_md" ]] ; then
3089     [[ -d ~/.terminfo/ ]] && alias man='TERMINFO=~/.terminfo/ LESS=C TERM=mostlike PAGER=less man'
3090 fi
3091
3092 # check whether Debian's package management (dpkg) is running
3093 if check_com salias ; then
3094     #a2# Check whether a dpkg instance is currently running
3095     salias check_dpkg_running="dpkg_running"
3096 fi
3097
3098 # work around non utf8 capable software in utf environment via $LANG and luit
3099 if check_com isutfenv && check_com luit ; then
3100     if check_com -c mrxvt ; then
3101         isutfenv && [[ -n "$LANG" ]] && \
3102             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3103     fi
3104
3105     if check_com -c aterm ; then
3106         isutfenv && [[ -n "$LANG" ]] && \
3107             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3108     fi
3109
3110     if check_com -c centericq ; then
3111         isutfenv && [[ -n "$LANG" ]] && \
3112             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3113     fi
3114 fi
3115 # }}}
3116
3117 # useful functions {{{
3118
3119 # searching
3120 #f4# Search for newspostings from authors
3121 agoogle() { ${=BROWSER} "http://groups.google.com/groups?as_uauthors=$*" ; }
3122 #f4# Search Debian Bug Tracking System
3123 debbug()  {
3124     setopt localoptions extendedglob
3125     if [[ $# -eq 1 ]]; then
3126         case "$1" in
3127             ([0-9]##)
3128             ${=BROWSER} "http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=$1"
3129             ;;
3130             (*@*)
3131             ${=BROWSER} "http://bugs.debian.org/cgi-bin/pkgreport.cgi?submitter=$1"
3132             ;;
3133             (*)
3134             ${=BROWSER} "http://bugs.debian.org/$*"
3135             ;;
3136         esac
3137     else
3138         print "$0 needs one argument"
3139         return 1
3140     fi
3141 }
3142 #f4# Search Debian Bug Tracking System in mbox format
3143 debbugm() { bts show --mbox $1 } # provide bugnummer as "$1"
3144 #f4# Search DMOZ
3145 dmoz()    { ${=BROWSER} http://search.dmoz.org/cgi-bin/search\?search=${1// /_} }
3146 #f4# Search German   Wiktionary
3147 dwicti()  { ${=BROWSER} http://de.wiktionary.org/wiki/${(C)1// /_} }
3148 #f4# Search English  Wiktionary
3149 ewicti()  { ${=BROWSER} http://en.wiktionary.org/wiki/${(C)1// /_} }
3150 #f4# Search Google Groups
3151 ggogle()  { ${=BROWSER} "http://groups.google.com/groups?q=$*" }
3152 #f4# Search Google
3153 google()  { ${=BROWSER} "http://www.google.com/search?&num=100&q=$*" }
3154 #f4# Search Google Groups for MsgID
3155 mggogle() { ${=BROWSER} "http://groups.google.com/groups?selm=$*" }
3156 #f4# Search Netcraft
3157 netcraft(){ ${=BROWSER} "http://toolbar.netcraft.com/site_report?url=$1" }
3158 #f4# Use German Wikipedia's full text search
3159 swiki()   { ${=BROWSER} http://de.wikipedia.org/wiki/Spezial:Search/${(C)1} }
3160 #f4# search \kbd{dict.leo.org}
3161 oleo()    { ${=BROWSER} "http://dict.leo.org/?search=$*" }
3162 #f4# Search German   Wikipedia
3163 wikide()  { ${=BROWSER} http://de.wikipedia.org/wiki/"${(C)*}" }
3164 #f4# Search English  Wikipedia
3165 wikien()  { ${=BROWSER} http://en.wikipedia.org/wiki/"${(C)*}" }
3166 #f4# Search official debs
3167 wodeb()   { ${=BROWSER} "http://packages.debian.org/search?keywords=$1&searchon=contents&suite=${2:=unstable}&section=all" }
3168
3169 #m# f4 gex() Exact search via Google
3170 check_com google && gex () { google "\"[ $1]\" $*" } # exact search at google
3171
3172 # misc
3173 #f5# Backup \kbd{file {\rm to} file\_timestamp}
3174 bk()      { cp -b ${1} ${1}_`date --iso-8601=m` }
3175 #f5# Copied diff
3176 cdiff()   { diff -crd "$*" | egrep -v "^Only in |^Binary files " }
3177 #f5# cd to directoy and list files
3178 cl()      { cd $1 && ls -a }        # cd && ls
3179 #f5# Cvs add
3180 cvsa()    { cvs add $* && cvs com -m 'initial checkin' $* }
3181 #f5# Cvs diff
3182 cvsd()    { cvs diff -N $* |& $PAGER }
3183 #f5# Cvs log
3184 cvsl()    { cvs log $* |& $PAGER }
3185 #f5# Cvs update
3186 cvsq()    { cvs -nq update }
3187 #f5# Rcs2log
3188 cvsr()    { rcs2log $* | $PAGER }
3189 #f5# Cvs status
3190 cvss()    { cvs status -v $* }
3191 #f5# Disassemble source files using gcc and as
3192 disassemble(){ gcc -pipe -S -o - -O -g $* | as -aldh -o /dev/null }
3193 #f5# Firefox remote control - open given URL
3194 fir()     { firefox -a firefox -remote "openURL($1)" }
3195 #f5# Create Directoy and \kbd{cd} to it
3196 mcd()     { mkdir -p "$@"; cd "$@" } # mkdir && cd
3197 #f5# Unified diff to timestamped outputfile
3198 mdiff()   { diff -udrP "$1" "$2" > diff.`date "+%Y-%m-%d"`."$1" }
3199 #f5# Memory overview
3200 memusage(){ ps aux | awk '{if (NR > 1) print $5; if (NR > 2) print "+"} END { print "p" }' | dc }
3201 #f5# Show contents of tar file
3202 shtar()   { gunzip -c $1 | tar -tf - -- | $PAGER }
3203 #f5# Show contents of tgz file
3204 shtgz()   { tar -ztf $1 | $PAGER }
3205 #f5# Show contents of zip file
3206 shzip()   { unzip -l $1 | $PAGER }
3207 #f5# Greps signature from file
3208 sig()     { agrep -d '^-- $' "$*" ~/.Signature }
3209 #f5# Unified diff
3210 udiff()   { diff -urd $* | egrep -v "^Only in |^Binary files " }
3211 #f5# (Mis)use \kbd{vim} as \kbd{less}
3212 viless()  { vim --cmd 'let no_plugin_maps = 1' -c "so \$VIMRUNTIME/macros/less.vim" "${@:--}" }
3213
3214 # download video from youtube
3215 ytdl() {
3216     if ! [[ -n "$2" ]] ; then
3217         print "Usage: ydtl http://youtube.com/watch?v=.... outputfile.flv">&2
3218         return 1
3219     else
3220         wget -O${2} "http://youtube.com/get_video?"${${${"$(wget -o/dev/null -O- "${1}" | grep -e watch_fullscreen)"}##*watch_fullscreen\?}%%\&fs=*}
3221     fi
3222 }
3223
3224 # Function Usage: uopen $URL/$file
3225 #f5# Download a file and display it locally
3226 uopen() {
3227     if ! [[ -n "$1" ]] ; then
3228         print "Usage: uopen \$URL/\$file">&2
3229         return 1
3230     else
3231         FILE=$1
3232         MIME=$(curl --head $FILE | grep Content-Type | cut -d ' ' -f 2 | cut -d\; -f 1)
3233         MIME=${MIME%$'\r'}
3234         curl $FILE | see ${MIME}:-
3235     fi
3236 }
3237
3238 # Function Usage: doc packagename
3239 #f5# \kbd{cd} to /usr/share/doc/\textit{package}
3240 doc() { cd /usr/share/doc/$1 && ls }
3241 _doc() { _files -W /usr/share/doc -/ }
3242 check_com compdef && compdef _doc doc
3243
3244 #f5# Make screenshot
3245 sshot() {
3246     [[ ! -d ~/shots  ]] && mkdir ~/shots
3247     #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
3248     cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
3249 }
3250
3251 # list images only
3252 limg() {
3253     local -a images
3254     images=( *.{jpg,gif,png}(.N) )
3255
3256     if [[ $#images -eq 0 ]] ; then
3257         print "No image files found"
3258     else
3259         ls "$@" "$images[@]"
3260     fi
3261 }
3262
3263 #f5# Create PDF file from source code
3264 makereadable() {
3265     output=$1
3266     shift
3267     a2ps --medium A4dj -E -o $output $*
3268     ps2pdf $output
3269 }
3270
3271 # zsh with perl-regex - use it e.g. via:
3272 # regcheck '\s\d\.\d{3}\.\d{3} Euro' ' 1.000.000 Euro'
3273 #f5# Checks whether a regex matches or not.\\&\quad Example: \kbd{regcheck '.\{3\} EUR' '500 EUR'}
3274 regcheck() {
3275     zmodload -i zsh/pcre
3276     pcre_compile $1 && \
3277     pcre_match $2 && echo "regex matches" || echo "regex does not match"
3278 }
3279
3280 #f5# List files which have been modified within the last {\it n} days
3281 new() { print -l *(m-$1) }
3282
3283 #f5# Grep in history
3284 greph() { history 0 | grep $1 }
3285 # use colors when GNU grep with color-support
3286 #a2# Execute \kbd{grep -{}-color=auto}
3287 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
3288 #a2# Execute \kbd{grep -i -{}-color=auto}
3289 alias GREP='grep -i --color=auto'
3290
3291 # one blank line between each line
3292 if [[ -r ~/.terminfo/m/mostlike ]] ; then
3293     #f5# Watch manpages in a stretched style
3294     man2() { PAGER='dash -c "sed G | /usr/bin/less"' TERM=mostlike /usr/bin/man "$@" ; }
3295 fi
3296
3297 # d():Copyright 2005 Nikolai Weibull <nikolai@bitwi.se>
3298 # note: option AUTO_PUSHD has to be set
3299 #f5# Jump between directories
3300 d() {
3301     emulate -L zsh
3302     autoload -U colors
3303     local color=$fg_bold[blue]
3304     integer i=0
3305     dirs -p | while read dir; do
3306         local num="${$(printf "%-4d " $i)/ /.}"
3307         printf " %s  $color%s$reset_color\n" $num $dir
3308         (( i++ ))
3309     done
3310     integer dir=-1
3311     read -r 'dir?Jump to directory: ' || return
3312     (( dir == -1 )) && return
3313     if (( dir < 0 || dir >= i )); then
3314         echo d: no such directory stack entry: $dir
3315         return 1
3316     fi
3317     cd ~$dir
3318 }
3319
3320 # usage example: 'lcheck strcpy'
3321 #f5# Find out which libs define a symbol
3322 lcheck() {
3323     if [[ -n "$1" ]] ; then
3324         nm -go /usr/lib/lib*.a 2>/dev/null | grep ":[[:xdigit:]]\{8\} . .*$1"
3325     else
3326         echo "Usage: lcheck <function>" >&2
3327     fi
3328 }
3329
3330 #f5# Clean up directory - remove well known tempfiles
3331 purge() {
3332     FILES=(*~(N) .*~(N) \#*\#(N) *.o(N) a.out(N) *.core(N) *.cmo(N) *.cmi(N) .*.swp(N))
3333     NBFILES=${#FILES}
3334     if [[ $NBFILES > 0 ]] ; then
3335         print $FILES
3336         local ans
3337         echo -n "Remove these files? [y/n] "
3338         read -q ans
3339         if [[ $ans == "y" ]] ; then
3340             rm ${FILES}
3341             echo ">> $PWD purged, $NBFILES files removed"
3342         else
3343             echo "Ok. .. than not.."
3344         fi
3345     fi
3346 }
3347
3348 # Translate DE<=>EN
3349 # 'translate' looks up fot a word in a file with language-to-language
3350 # translations (field separator should be " : "). A typical wordlist looks
3351 # like at follows:
3352 #  | english-word : german-transmission
3353 # It's also only possible to translate english to german but not reciprocal.
3354 # Use the following oneliner to turn back the sort order:
3355 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3356 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3357 #f5# Translates a word
3358 trans() {
3359     case "$1" in
3360         -[dD]*)
3361             translate -l de-en $2
3362             ;;
3363         -[eE]*)
3364             translate -l en-de $2
3365             ;;
3366         *)
3367             echo "Usage: $0 { -D | -E }"
3368             echo "         -D == German to English"
3369             echo "         -E == English to German"
3370     esac
3371 }
3372
3373 #f5# List all occurrences of programm in current PATH
3374 plap() {
3375     if [[ $# = 0 ]] ; then
3376         echo "Usage:    $0 program"
3377         echo "Example:  $0 zsh"
3378         echo "Lists all occurrences of program in the current PATH."
3379     else
3380         ls -l ${^path}/*$1*(*N)
3381     fi
3382 }
3383
3384 # Found in the mailinglistarchive from Zsh (IIRC ~1996)
3385 #f5# Select items for specific command(s) from history
3386 selhist() {
3387     emulate -L zsh
3388     local TAB=$'\t';
3389     (( $# < 1 )) && {
3390         echo "Usage: $0 command"
3391         return 1
3392     };
3393     cmd=(${(f)"$(grep -w $1 $HISTFILE | sort | uniq | pr -tn)"})
3394     print -l $cmd | less -F
3395     echo -n "enter number of desired command [1 - $(( ${#cmd[@]} - 1 ))]: "
3396     local answer
3397     read answer
3398     print -z "${cmd[$answer]#*$TAB}"
3399 }
3400
3401 # Use vim to convert plaintext to HTML
3402 #f5# Transform files to html with highlighting
3403 2html() { vim -u NONE -n -c ':syntax on' -c ':so $VIMRUNTIME/syntax/2html.vim' -c ':wqa' $1 &>/dev/null }
3404
3405 # Usage: simple-extract <file>
3406 #f5# Smart archive extractor
3407 simple-extract () {
3408     if [[ -f $1 ]] ; then
3409         case $1 in
3410             *.tar.bz2)  bzip2 -v -d $1      ;;
3411             *.tar.gz)   tar -xvzf $1        ;;
3412             *.rar)      unrar $1            ;;
3413             *.deb)      ar -x $1            ;;
3414             *.bz2)      bzip2 -d $1         ;;
3415             *.lzh)      lha x $1            ;;
3416             *.gz)       gunzip -d $1        ;;
3417             *.tar)      tar -xvf $1         ;;
3418             *.tgz)      gunzip -d $1        ;;
3419             *.tbz2)     tar -jxvf $1        ;;
3420             *.zip)      unzip $1            ;;
3421             *.Z)        uncompress $1       ;;
3422             *)          echo "'$1' Error. Please go away" ;;
3423         esac
3424     else
3425         echo "'$1' is not a valid file"
3426     fi
3427 }
3428
3429 # Usage: smartcompress <file> (<type>)
3430 #f5# Smart archive creator
3431 smartcompress() {
3432     if [[ -n $2 ]] ; then
3433         case $2 in
3434             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
3435             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
3436             tar.Z)          tar -Zcvf$1.$2 $1 ;;
3437             tar)            tar -cvf$1.$2  $1 ;;
3438             gz | gzip)      gzip           $1 ;;
3439             bz2 | bzip2)    bzip2          $1 ;;
3440             *)
3441                 echo "Error: $2 is not a valid compression type"
3442                 ;;
3443         esac
3444     else
3445         smartcompress $1 tar.gz
3446     fi
3447 }
3448
3449 # Usage: show-archive <archive>
3450 #f5# List an archive's content
3451 show-archive() {
3452     if [[ -f $1 ]] ; then
3453         case $1 in
3454             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
3455             *.tar)         tar -tf $1 ;;
3456             *.tgz)         tar -ztf $1 ;;
3457             *.zip)         unzip -l $1 ;;
3458             *.bz2)         bzless $1 ;;
3459             *.deb)         dpkg-deb --fsys-tarfile $1 | tar -tf - -- ;;
3460             *)             echo "'$1' Error. Please go away" ;;
3461         esac
3462     else
3463         echo "'$1' is not a valid archive"
3464     fi
3465 }
3466
3467 # It's shameless stolen from <http://www.vim.org/tips/tip.php?tip_id=167>
3468 #f5# Use \kbd{vim} as your manpage reader
3469 vman() { man $* | col -b | view -c 'set ft=man nomod nolist' - }
3470
3471 # function readme() { $PAGER -- (#ia3)readme* }
3472 #f5# View all README-like files in current directory in pager
3473 readme() {
3474     local files
3475     files=(./(#i)*(read*me|lue*m(in|)ut)*(ND))
3476     if (($#files)) ; then
3477         $PAGER $files
3478     else
3479         print 'No README files.'
3480     fi
3481 }
3482
3483 # function ansi-colors()
3484 #f5# Display ANSI colors
3485 ansi-colors() {
3486     typeset esc="\033[" line1 line2
3487     echo " _ _ _40 _ _ _41_ _ _ _42 _ _ 43_ _ _ 44_ _ _45 _ _ _ 46_ _ _ 47_ _ _ 49_ _"
3488     for fore in 30 31 32 33 34 35 36 37; do
3489         line1="$fore "
3490         line2="   "
3491         for back in 40 41 42 43 44 45 46 47 49; do
3492             line1="${line1}${esc}${back};${fore}m Normal ${esc}0m"
3493             line2="${line2}${esc}${back};${fore};1m Bold   ${esc}0m"
3494         done
3495         echo -e "$line1\n$line2"
3496     done
3497 }
3498
3499 # suidfind() { ls -latg $path | grep '^...s' }
3500 #f5# Find all files in \$PATH with setuid bit set
3501 suidfind() { ls -latg $path/*(sN) }
3502
3503 # See above but this is /better/ ... anywise ..
3504 findsuid() {
3505     print 'Output will be written to ~/suid_* ...'
3506     $SUDO find / -type f \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suidfiles.`date "+%Y-%m-%d"`.out 2>&1
3507     $SUDO find / -type d \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suiddirs.`date "+%Y-%m-%d"`.out 2>&1
3508     $SUDO find / -type f \( -perm -2 -o -perm -20 \) -ls > ~/suid_writefiles.`date "+%Y-%m-%d"`.out 2>&1
3509     $SUDO find / -type d \( -perm -2 -o -perm -20 \) -ls > ~/suid_writedirs.`date "+%Y-%m-%d"`.out 2>&1
3510     print 'Finished'
3511 }
3512
3513 #f5# Reload given functions
3514 refunc() {
3515     for func in $argv ; do
3516         unfunction $func
3517         autoload $func
3518     done
3519 }
3520
3521 # a small check to see which DIR is located on which server/partition.
3522 # stolen and modified from Sven's zshrc.forall
3523 #f5# Report diskusage of a directory
3524 dirspace() {
3525     if [[ -n "$1" ]] ; then
3526         for dir in $* ; do
3527             if [[ -d "$dir" ]] ; then
3528                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3529             else
3530                 echo "warning: $dir does not exist" >&2
3531             fi
3532         done
3533     else
3534         for dir in $path; do
3535             if [[ -d "$dir" ]] ; then
3536                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3537             else
3538                 echo "warning: $dir does not exist" >&2
3539             fi
3540         done
3541     fi
3542 }
3543
3544 # % slow_print `cat /etc/passwd`
3545 #f5# Slowly print out parameters
3546 slow_print() {
3547     for argument in "${@}" ; do
3548         for ((i = 1; i <= ${#1} ;i++)) ; do
3549             print -n "${argument[i]}"
3550             sleep 0.08
3551         done
3552         print -n " "
3553     done
3554     print ""
3555 }
3556
3557 #f5# Show some status info
3558 status() {
3559     print ""
3560     print "Date..: "$(date "+%Y-%m-%d %H:%M:%S")""
3561     print "Shell.: Zsh $ZSH_VERSION (PID = $$, $SHLVL nests)"
3562     print "Term..: $TTY ($TERM), ${BAUD:+$BAUD bauds, }$COLUMNS x $LINES cars"
3563     print "Login.: $LOGNAME (UID = $EUID) on $HOST"
3564     print "System: $(cat /etc/[A-Za-z]*[_-][rv]e[lr]*)"
3565     print "Uptime:$(uptime)"
3566     print ""
3567 }
3568
3569 # Rip an audio CD
3570 #f5# Rip an audio CD
3571 audiorip() {
3572     mkdir -p ~/ripps
3573     cd ~/ripps
3574     cdrdao read-cd --device $DEVICE --driver generic-mmc audiocd.toc
3575     cdrdao read-cddb --device $DEVICE --driver generic-mmc audiocd.toc
3576     echo " * Would you like to burn the cd now? (yes/no)"
3577     read input
3578     if [[ "$input" = "yes" ]] ; then
3579         echo " ! Burning Audio CD"
3580         audioburn
3581         echo " * done."
3582     else
3583         echo " ! Invalid response."
3584     fi
3585 }
3586
3587 # and burn it
3588 #f5# Burn an audio CD (in combination with audiorip)
3589 audioburn() {
3590     cd ~/ripps
3591     cdrdao write --device $DEVICE --driver generic-mmc audiocd.toc
3592     echo " * Should I remove the temporary files? (yes/no)"
3593     read input
3594     if [[ "$input" = "yes" ]] ; then
3595         echo " ! Removing Temporary Files."
3596         cd ~
3597         rm -rf ~/ripps
3598         echo " * done."
3599     else
3600         echo " ! Invalid response."
3601     fi
3602 }
3603
3604 #f5# Make an audio CD from all mp3 files
3605 mkaudiocd() {
3606     # TODO: do the renaming more zshish, possibly with zmv()
3607     cd ~/ripps
3608     for i in *.[Mm][Pp]3; do mv "$i" `echo $i | tr '[A-Z]' '[a-z]'`; done
3609     for i in *.mp3; do mv "$i" `echo $i | tr ' ' '_'`; done
3610     for i in *.mp3; do mpg123 -w `basename $i .mp3`.wav $i; done
3611     normalize -m *.wav
3612     for i in *.wav; do sox $i.wav -r 44100 $i.wav resample; done
3613 }
3614
3615 #f5# Create an ISO image. You are prompted for\\&\quad volume name, filename and directory
3616 mkiso() {
3617     echo " * Volume name "
3618     read volume
3619     echo " * ISO Name (ie. tmp.iso)"
3620     read iso
3621     echo " * Directory or File"
3622     read files
3623     mkisofs -o ~/$iso -A $volume -allow-multidot -J -R -iso-level 3 -V $volume -R $files
3624 }
3625
3626 #f5# Simple thumbnails generator
3627 genthumbs() {
3628     rm -rf thumb-* index.html
3629     echo "
3630 <html>
3631   <head>
3632     <title>Images</title>
3633   </head>
3634   <body>" > index.html
3635     for f in *.(gif|jpeg|jpg|png) ; do
3636         convert -size 100x200 "$f" -resize 100x200 thumb-"$f"
3637         echo "    <a href=\"$f\"><img src=\"thumb-$f\"></a>" >> index.html
3638     done
3639     echo "
3640   </body>
3641 </html>" >> index.html
3642 }
3643
3644 #f5# Set all ulimit parameters to \kbd{unlimited}
3645 allulimit() {
3646     ulimit -c unlimited
3647     ulimit -d unlimited
3648     ulimit -f unlimited
3649     ulimit -l unlimited
3650     ulimit -n unlimited
3651     ulimit -s unlimited
3652     ulimit -t unlimited
3653 }
3654
3655 # ogg2mp3 with bitrate of 192
3656 ogg2mp3_192() {
3657     oggdec -o - ${1} | lame -b 192 - ${1:r}.mp3
3658 }
3659
3660 #f5# RFC 2396 URL encoding in Z-Shell
3661 urlencode() {
3662     setopt localoptions extendedglob
3663     input=( ${(s::)1} )
3664     print ${(j::)input/(#b)([^A-Za-z0-9_.!~*\'\(\)-])/%${(l:2::0:)$(([##16]#match))}}
3665 }
3666
3667 #f5# Install x-lite (VoIP software)
3668 getxlite() {
3669     setopt local_options
3670     setopt errreturn
3671     [[ -d ~/tmp ]] || mkdir ~/tmp
3672     cd ~/tmp
3673
3674     echo "Downloading http://www.counterpath.com/download/X-Lite_Install.tar.gz and storing it in ~/tmp:"
3675     if wget http://www.counterpath.com/download/X-Lite_Install.tar.gz ; then
3676         unp X-Lite_Install.tar.gz && echo done || echo failed
3677     else
3678         echo "Error while downloading." ; return 1
3679     fi
3680
3681     if [[ -x xten-xlite/xtensoftphone ]] ; then
3682         echo "Execute xten-xlite/xtensoftphone to start xlite."
3683     fi
3684 }
3685
3686 #f5# Install skype
3687 getskype() {
3688     setopt local_options
3689     setopt errreturn
3690     echo "Downloading debian package of skype."
3691     echo "Notice: If you want to use a more recent skype version run 'getskypebeta'."
3692     wget http://www.skype.com/go/getskype-linux-deb
3693     $SUDO dpkg -i skype*.deb && echo "skype installed."
3694 }
3695
3696 #f5# Install beta-version of skype
3697 getskypebeta() {
3698     setopt local_options
3699     setopt errreturn
3700     echo "Downloading debian package of skype (beta version)."
3701     wget http://www.skype.com/go/getskype-linux-beta-deb
3702     $SUDO dpkg -i skype-beta*.deb && echo "skype installed."
3703 }
3704
3705 #f5# Install gizmo (VoIP software)
3706 getgizmo() {
3707     setopt local_options
3708     setopt errreturn
3709     echo "libgtk2.0-0, gconf2, libstdc++6, libasound2 and zlib1g have to be available. Installing."
3710     $SUDO apt-get update
3711     $SUDO apt-get install libgtk2.0-0 gconf2 libstdc++6 libasound2 zlib1g
3712     wget "$(lynx --dump http://gizmo5.com/pc/download/linux/ | awk '/libstdc\+\+6.*\.deb/ {print $2}')"
3713     $SUDO dpkg -i gizmo-project*.deb && echo "gizmo installed."
3714 }
3715
3716 #f5# Get and run AIR (Automated Image and Restore)
3717 getair() {
3718     setopt local_options
3719     setopt errreturn
3720     [[ -w . ]] || { echo 'Error: you do not have write permissions in this directory. Exiting.' ; return 1 }
3721     local VER='1.2.8'
3722     wget http://puzzle.dl.sourceforge.net/sourceforge/air-imager/air-$VER.tar.gz
3723     tar zxf air-$VER.tar.gz
3724     cd air-$VER
3725     INTERACTIVE=no $SUDO ./install-air-1.2.8
3726     [[ -x /usr/local/bin/air ]] && [[ -n "$DISPLAY" ]] && $SUDO air
3727 }
3728
3729 #f5# Get specific git commitdiff
3730 git-get-diff() {
3731     if [[ -z $GITTREE ]] ; then
3732         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3733     fi
3734     if ! [[ -z $1 ]] ; then
3735         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commitdiff;h=$1"
3736     else
3737         echo "Usage: git-get-diff <commit>"
3738     fi
3739 }
3740
3741 #f5# Get specific git commit
3742 git-get-commit() {
3743     if [[ -z $GITTREE ]] ; then
3744         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3745     fi
3746     if ! [[ -z $1 ]] ; then
3747         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commit;h=$1"
3748     else
3749         echo "Usage: git-get-commit <commit>"
3750     fi
3751 }
3752
3753 #f5# Get specific git diff
3754 git-get-plaindiff () {
3755     if [[ -z $GITTREE ]] ; then
3756        GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3757     fi
3758     if [[ -z $1 ]] ; then
3759        echo 'Usage: git-get-plaindiff '
3760     else
3761        echo -n "Downloading $1.diff ... "
3762        # avoid "generating ..." stuff from kernel.org server:
3763        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O /dev/null
3764        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O $1.diff \
3765             && echo done || echo failed
3766     fi
3767 }
3768
3769
3770 # http://strcat.de/blog/index.php?/archives/335-Software-sauber-deinstallieren...html
3771 #f5# Log 'make install' output
3772 mmake() {
3773     [[ ! -d ~/.errorlogs ]] && mkdir ~/.errorlogs
3774     make -n install > ~/.errorlogs/${PWD##*/}-makelog
3775 }
3776
3777 #f5# Indent source code
3778 smart-indent() {
3779     indent -npro -kr -i8 -ts8 -sob -l80 -ss -ncs $*
3780 }
3781
3782 # highlight important stuff in diff output, usage example: hg diff | hidiff
3783 #m# a2 hidiff \kbd{histring} oneliner for diffs
3784 check_com -c histring && \
3785     alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
3786
3787 # rename pictures based on information found in exif headers
3788 #f5# Rename pictures based on information found in exif headers
3789 exirename() {
3790     if [[ $# -lt 1 ]] ; then
3791         echo 'Usage: jpgrename $FILES' >& 2
3792         return 1
3793     else
3794         echo -n 'Checking for jhead with version newer than 1.9: '
3795         jhead_version=`jhead -h | grep 'used by most Digital Cameras.  v.*' | awk '{print $6}' | tr -d v`
3796         if [[ $jhead_version > '1.9' ]]; then
3797             echo 'success - now running jhead.'
3798             jhead -n%Y-%m-%d_%Hh%M_%f $*
3799         else
3800             echo 'failed - exiting.'
3801         fi
3802     fi
3803 }
3804
3805 # open file in vim and jump to line
3806 # http://www.downgra.de/archives/2007/05/08/T19_21_11/
3807 j2v() {
3808     local -a params
3809     params=(${*//(#m):[0-9]*:/\\n+${MATCH//:/}}) # replace ':23:' to '\n+23'
3810     params=(${(s|\n|)${(j|\n|)params}}) # join array using '\n', then split on all '\n'
3811     vim ${params}
3812 }
3813
3814 # get_ic() - queries imap servers for capabilities; real simple. no imaps
3815 ic_get() {
3816     local port
3817     if [[ ! -z $1 ]] ; then
3818         port=${2:-143}
3819         print "querying imap server on $1:${port}...\n";
3820         print "a1 capability\na2 logout\n" | nc $1 ${port}
3821     else
3822         print "usage:\n  $0 <imap-server> [port]"
3823     fi
3824 }
3825
3826 # creates a Maildir/ with its {new,cur,tmp} subdirs
3827 mkmaildir() {
3828     local root subdir
3829     root=${MAILDIR_ROOT:-${HOME}/Mail}
3830     if [[ -z ${1} ]] ; then print "Usage:\n $0 <dirname>" ; return 1 ; fi
3831     subdir=${1}
3832     mkdir -p ${root}/${subdir}/{cur,new,tmp}
3833 }
3834
3835 #f5# Change the xterm title from within GNU-screen
3836 xtrename() {
3837     if [[ ${1} != "-f" ]] ; then
3838         if [[ -z ${DISPLAY} ]] ; then
3839             printf 'xtrename only makes sense in X11.\n'
3840             return 1
3841         fi
3842     else
3843         shift
3844     fi
3845     if [[ -z ${1} ]] ; then
3846         printf 'usage: xtrename [-f] "title for xterm"\n'
3847         printf '  renames the title of xterm from _within_ screen.\n'
3848         printf '  also works without screen.\n'
3849         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3850         return 0
3851     fi
3852     print -n "\eP\e]0;${1}\C-G\e\\"
3853     return 0
3854 }
3855
3856 # hl() highlighted less
3857 # http://ft.bewatermyfriend.org/comp/data/zsh/zfunct.html
3858 if check_com -c highlight ; then
3859     function hl() {
3860         local theme lang
3861         theme=${HL_THEME:-""}
3862         case ${1} in
3863             (-l|--list)
3864                 ( printf 'available languages (syntax parameter):\n\n' ;
3865                     highlight --list-langs ; ) | less -SMr
3866                 ;;
3867             (-t|--themes)
3868                 ( printf 'available themes (style parameter):\n\n' ;
3869                     highlight --list-themes ; ) | less -SMr
3870                 ;;
3871             (-h|--help)
3872                 printf 'usage: hl <syntax[:theme]> <file>\n'
3873                 printf '    available options: --list (-l), --themes (-t), --help (-h)\n\n'
3874                 printf '  Example: hl c main.c\n'
3875                 ;;
3876             (*)
3877                 if [[ -z ${2} ]] || (( ${#argv} > 2 )) ; then
3878                     printf 'usage: hl <syntax[:theme]> <file>\n'
3879                     printf '    available options: --list (-l), --themes (-t), --help (-h)\n'
3880                     (( ${#argv} > 2 )) && printf '  Too many arguments.\n'
3881                     return 1
3882                 fi
3883                 lang=${1%:*}
3884                 [[ ${1} == *:* ]] && [[ -n ${1#*:} ]] && theme=${1#*:}
3885                 if [[ -n ${theme} ]] ; then
3886                     highlight --xterm256 --syntax ${lang} --style ${theme} ${2} | less -SMr
3887                 else
3888                     highlight --ansi --syntax ${lang} ${2} | less -SMr
3889                 fi
3890                 ;;
3891         esac
3892         return 0
3893     }
3894     # ... and a proper completion for hl()
3895     # needs 'highlight' as well, so it fits fine in here.
3896     function _hl_genarg()  {
3897         local expl
3898         if [[ -prefix 1 *: ]] ; then
3899             local themes
3900             themes=(${${${(f)"$(LC_ALL=C highlight --list-themes)"}/ #/}:#*(Installed|Use name)*})
3901             compset -P 1 '*:'
3902             _wanted -C list themes expl theme compadd ${themes}
3903         else
3904             local langs
3905             langs=(${${${(f)"$(LC_ALL=C highlight --list-langs)"}/ #/}:#*(Installed|Use name)*})
3906             _wanted -C list languages expl languages compadd -S ':' -q ${langs}
3907         fi
3908     }
3909     function _hl_complete() {
3910         _arguments -s '1: :_hl_genarg' '2:files:_path_files'
3911     }
3912     compdef _hl_complete hl
3913 fi
3914
3915 # Create small urls via http://tinyurl.com using wget(1).
3916 function zurl() {
3917     [[ -z ${1} ]] && { print "USAGE: zurl <URL>" ; return 1 }
3918
3919     local PN url tiny grabber search result preview
3920     PN=${0}
3921     url=${1}
3922 #   Check existence of given URL with the help of ping(1).
3923 #   N.B. ping(1) only works without an eventual given protocol.
3924     ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
3925         read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
3926
3927     if (( $? == 0 )) ; then
3928 #           Prepend 'http://' to given URL where necessary for later output.
3929             [[ ${url} != http(s|)://* ]] && url='http://'${url}
3930             tiny='http://tinyurl.com/create.php?url='
3931             if check_com -c wget ; then
3932                 grabber='wget -O- -o/dev/null'
3933             else
3934                 print "wget is not available, but mandatory for ${PN}. Aborting."
3935             fi
3936 #           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
3937             search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
3938             result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
3939 #           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
3940             preview='http://preview.'${result#http://}
3941
3942             printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
3943             printf '%s\t%s\n\n' 'Given URL:' ${url}
3944             printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
3945     else
3946         return 1
3947     fi
3948 }
3949
3950 #f2# Print a specific line of file(s).
3951 linenr () {
3952 # {{{
3953     if [ $# -lt 2 ] ; then
3954        print "Usage: linenr <number>[,<number>] <file>" ; return 1
3955     elif [ $# -eq 2 ] ; then
3956          local number=$1
3957          local file=$2
3958          command ed -s $file <<< "${number}n"
3959     else
3960          local number=$1
3961          shift
3962          for file in "$@" ; do
3963              if [ ! -d $file ] ; then
3964                 echo "${file}:"
3965                 command ed -s $file <<< "${number}n" 2> /dev/null
3966              else
3967                 continue
3968              fi
3969          done | less
3970     fi
3971 # }}}
3972 }
3973
3974 #f2# Find history events by search pattern and list them by date.
3975 whatwhen()  {
3976 # {{{
3977     local usage help ident format_l format_s first_char remain first last
3978     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3979     help='Use' \`'whatwhen -h'\'' for further explanations.'
3980     ident=${(l,${#${:-Usage: }},, ,)}
3981     format_l="${ident}%s\t\t\t%s\n"
3982     format_s="${format_l//(\\t)##/\\t}"
3983     # Make the first char of the word to search for case
3984     # insensitive; e.g. [aA]
3985     first_char=[${(L)1[1]}${(U)1[1]}]
3986     remain=${1[2,-1]}
3987     # Default search range is `-100'.
3988     first=${2:-\-100}
3989     # Optional, just used for `<first> <last>' given.
3990     last=$3
3991     case $1 in
3992         ("")
3993             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3994             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3995         ;;
3996         (-h)
3997             printf '%s\n\n' ${usage}
3998             print 'OPTIONS:'
3999             printf $format_l '-h' 'show help text'
4000             print '\f'
4001             print 'SEARCH RANGE:'
4002             printf $format_l "'0'" 'the whole history,'
4003             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
4004             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
4005             printf '\n%s\n' 'EXAMPLES:'
4006             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
4007             printf $format_l 'whatwhen zsh -250'
4008             printf $format_l 'whatwhen foo 1 99'
4009         ;;
4010         (\?)
4011             printf '%s\n%s\n\n' ${usage} ${help} && return 1
4012         ;;
4013         (*)
4014             # -l list results on stout rather than invoking $EDITOR.
4015             # -i Print dates as in YYYY-MM-DD.
4016             # -m Search for a - quoted - pattern within the history.
4017             fc -li -m "*${first_char}${remain}*" $first $last
4018         ;;
4019     esac
4020 # }}}
4021 }
4022
4023 # change fluxbox keys from 'Alt-#' to 'Alt-F#' and vice versa
4024 fluxkey-change() {
4025     [[ -n "$FLUXKEYS" ]] || local FLUXKEYS="$HOME/.fluxbox/keys"
4026     if ! [[ -r "$FLUXKEYS" ]] ; then
4027         echo "Sorry, \$FLUXKEYS file $FLUXKEYS could not be read - nothing to be done."
4028         return 1
4029     else
4030         if grep -q 'Mod1 F[0-9] :Workspace [0-9]' $FLUXKEYS ; then
4031             echo -n 'Switching to Alt-# mode in ~/.fluxbox/keys: '
4032             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)F\([0-9]\+[: space :]\+:Workspace.*\)|\1\2|' $FLUXKEYS && echo done || echo failed
4033         elif grep -q 'Mod1 [0-9] :Workspace [0-9]' $FLUXKEYS ; then
4034             echo -n 'Switching to Alt-F# mode in ~/.fluxbox/keys: '
4035             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)\([0-9]\+[: space :]\+:Workspace.*\)|\1F\2|' $FLUXKEYS && echo done || echo failed
4036         else
4037             echo 'Sorry, do not know what to do.'
4038             return 1
4039         fi
4040     fi
4041 }
4042
4043 # retrieve weather information on the console
4044 # Usage example: 'weather LOWG'
4045 weather() {
4046     [[ -n "$1" ]] || {
4047         print 'Usage: weather <station_id>' >&2
4048         print 'List of stations: http://en.wikipedia.org/wiki/List_of_airports_by_ICAO_code'>&2
4049         return 1
4050     }
4051
4052     local PLACE="${1:u}"
4053     local FILE="$HOME/.weather/$PLACE"
4054     local LOG="$HOME/.weather/log"
4055
4056     [[ -d $HOME/.weather ]] || {
4057         print -n "Creating $HOME/.weather: "
4058         mkdir $HOME/.weather
4059         print 'done'
4060     }
4061
4062     print "Retrieving information for ${PLACE}:"
4063     print
4064     wget -T 10 --no-verbose --output-file=$LOG --output-document=$FILE --timestamping http://weather.noaa.gov/pub/data/observations/metar/decoded/$PLACE.TXT
4065
4066     if [[ $? -eq 0 ]] ; then
4067         if [[ -n "$VERBOSE" ]] ; then
4068             cat $FILE
4069         else
4070             DATE=$(grep 'UTC' $FILE | sed 's#.* /##')
4071             TEMPERATURE=$(awk '/Temperature/ { print $4" degree Celcius / " $2" degree Fahrenheit" }' $FILE| tr -d '(')
4072             echo "date: $DATE"
4073             echo "temp:  $TEMPERATURE"
4074         fi
4075     else
4076         print "There was an error retrieving the weather information for $PLACE" >&2
4077         cat $LOG
4078         return 1
4079     fi
4080 }
4081 # }}}
4082
4083 # mercurial related stuff {{{
4084 if check_com -c hg ; then
4085     # gnu like diff for mercurial
4086     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
4087     #f5# GNU like diff for mercurial
4088     hgdi() {
4089         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
4090     }
4091
4092     # build debian package
4093     #a2# Alias for \kbd{hg-buildpackage}
4094     alias hbp='hg-buildpackage'
4095
4096     # execute commands on the versioned patch-queue from the current repos
4097     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
4098
4099     # diffstat for specific version of a mercurial repository
4100     #   hgstat      => display diffstat between last revision and tip
4101     #   hgstat 1234 => display diffstat between revision 1234 and tip
4102     #f5# Diffstat for specific version of a mercurial repos
4103     hgstat() {
4104         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
4105     }
4106
4107     #f5# Get current mercurial tip via hg itself
4108     gethgclone() {
4109         setopt local_options
4110         setopt errreturn
4111         if [[ -f mercurial-tree/.hg ]] ; then
4112             cd mercurial-tree
4113             echo "Running hg pull for retreiving latest version..."
4114             hg pull
4115             echo "Finished update. Building mercurial"
4116             make local
4117             echo "Setting \$PATH to $PWD:\$PATH..."
4118             export PATH="$PWD:$PATH"
4119         else
4120             echo "Downloading mercurial via hg"
4121             hg clone http://selenic.com/repo/hg mercurial-tree
4122             cd mercurial-tree
4123             echo "Building mercurial"
4124             make local
4125             echo "Setting \$PATH to $PWD:\$PATH..."
4126             export PATH="$PWD:$PATH"
4127             echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4128             # echo "Setting \$PYTHONPATH to PYTHONPATH=\${HOME}/lib/python,"
4129             # export PYTHONPATH=${HOME}/lib/python
4130         fi
4131     }
4132
4133 fi # end of check whether we have the 'hg'-executable
4134
4135 # get current mercurial snapshot
4136 #f5# Get current mercurial snapshot
4137 gethgsnap() {
4138     setopt local_options
4139     setopt errreturn
4140     if [[ -f mercurial-snapshot.tar.gz ]] ; then
4141          echo "mercurial-snapshot.tar.gz exists already, skipping download."
4142     else
4143         echo "Downloading mercurial snapshot"
4144         wget http://www.selenic.com/mercurial/mercurial-snapshot.tar.gz
4145     fi
4146     echo "Unpacking mercurial-snapshot.tar.gz"
4147     tar zxf mercurial-snapshot.tar.gz
4148     cd mercurial-snapshot/
4149     echo "Installing required build-dependencies"
4150     $SUDO apt-get update
4151     $SUDO apt-get install python2.4-dev
4152     echo "Building mercurial"
4153     make local
4154     echo "Setting \$PATH to $PWD:\$PATH..."
4155     export PATH="$PWD:$PATH"
4156     echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4157 }
4158 # }}}
4159
4160 # some useful commands often hard to remember - let's grep for them {{{
4161 # actually use our zg() function now. :)
4162
4163 # Work around ion/xterm resize bug.
4164 #if [[ "$SHLVL" -eq 1 ]]; then
4165 #       if check_com -c resize ; then
4166 #               eval `resize </dev/null`
4167 #       fi
4168 #fi
4169
4170 # enable jackd:
4171 #  /usr/bin/jackd -dalsa -dhw:0 -r48000 -p1024 -n2
4172 # now play audio file:
4173 #  alsaplayer -o jack foobar.mp3
4174
4175 # send files via netcat
4176 # on sending side:
4177 #  send() {j=$*; tar cpz ${j/%${!#}/}|nc -w 1 ${!#} 51330;}
4178 #  send dir* $HOST
4179 #  alias receive='nc -vlp 51330 | tar xzvp'
4180
4181 # debian stuff:
4182 # dh_make -e foo@localhost -f $1
4183 # dpkg-buildpackage -rfakeroot
4184 # lintian *.deb
4185 # dpkg-scanpackages ./ /dev/null | gzip > Packages.gz
4186 # dpkg-scansources . | gzip > Sources.gz
4187 # grep-dctrl --field Maintainer $* /var/lib/apt/lists/*
4188
4189 # other stuff:
4190 # convert -geometry 200x200 -interlace LINE -verbose
4191 # ldapsearch -x -b "OU=Bedienstete,O=tug" -h ldap.tugraz.at sn=$1
4192 # ps -ao user,pcpu,start,command
4193 # gpg --keyserver blackhole.pca.dfn.de --recv-keys
4194 # xterm -bg black -fg yellow -fn -misc-fixed-medium-r-normal--14-140-75-75-c-90-iso8859-15 -ah
4195 # nc -vz $1 1-1024   # portscan via netcat
4196 # wget --mirror --no-parent --convert-links
4197 # pal -d `date +%d`
4198 # autoload -U tetris; zle -N tetris; bindkey '...' ; echo "press ... for playing tennis"
4199 #
4200 # modify console cursor
4201 # see http://www.tldp.org/HOWTO/Framebuffer-HOWTO-5.html
4202 # print $'\e[?96;0;64c'
4203 # }}}
4204
4205 # grml-small cleanups {{{
4206
4207 # The following is used to remove zsh-config-items that do not work
4208 # in grml-small by default.
4209 # If you do not want these adjustments (for whatever reason), set
4210 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
4211 # sources if it is there).
4212
4213 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
4214
4215     unset abk[V]
4216     unalias    'V'      &> /dev/null
4217     unfunction vman     &> /dev/null
4218     unfunction vimpm    &> /dev/null
4219     unfunction vimhelp  &> /dev/null
4220     unfunction viless   &> /dev/null
4221     unfunction 2html    &> /dev/null
4222
4223     # manpages are not in grmlsmall
4224     unfunction manzsh   &> /dev/null
4225     unalias    man2     &> /dev/null
4226     unalias    man      &> /dev/null
4227     unfunction man2     &> /dev/null
4228
4229 fi
4230
4231 #}}}
4232
4233 # finally source a local zshrc {{{
4234
4235 # this allows us to stay in sync with grml's zshrc and put own
4236 # modifications in ~/.zshrc.local
4237
4238 xsource "${HOME}/.zshrc.local"
4239
4240 # }}}
4241
4242 ## genrefcard.pl settings {{{
4243
4244 ### doc strings for external functions from files
4245 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
4246
4247 ### example: split functions-search 8,16,24,32
4248 #@# split functions-search 8
4249
4250 ## }}}
4251
4252 ## END OF FILE #################################################################
4253 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4