etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation: {{{
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104 #}}}
 105
 106 # zsh profiling {{{
 107 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 108 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 109     zmodload zsh/zprof
 110 fi
 111 # }}}
 112
 113 # load .zshrc.pre to give the user the chance to overwrite the defaults
 114 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
 115
 116 # {{{ check for version/system
 117 # check for versions (compatibility reasons)
 118 is4(){
 119     [[ $ZSH_VERSION == <4->* ]] && return 0
 120     return 1
 121 }
 122
 123 is41(){
 124     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 125     return 1
 126 }
 127
 128 is42(){
 129     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 130     return 1
 131 }
 132
 133 is425(){
 134     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 135     return 1
 136 }
 137
 138 is43(){
 139     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 140     return 1
 141 }
 142
 143 is433(){
 144     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* || $ZSH_VERSION == <5->* ]] && return 0
 145     return 1
 146 }
 147
 148 is439(){
 149     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 #f1# Checks whether or not you're running grml
 154 isgrml(){
 155     [[ -f /etc/grml_version ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running a grml cd
 160 isgrmlcd(){
 161     [[ -f /etc/grml_cd ]] && return 0
 162     return 1
 163 }
 164
 165 if isgrml ; then
 166 #f1# Checks whether or not you're running grml-small
 167     isgrmlsmall() {
 168         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 169     }
 170 else
 171     isgrmlsmall() { return 1 }
 172 fi
 173
 174 isdarwin(){
 175     [[ $OSTYPE == darwin* ]] && return 0
 176     return 1
 177 }
 178
 179 #f1# are we running within an utf environment?
 180 isutfenv() {
 181     case "$LANG $CHARSET $LANGUAGE" in
 182         *utf*) return 0 ;;
 183         *UTF*) return 0 ;;
 184         *)     return 1 ;;
 185     esac
 186 }
 187
 188 # check for user, if not running as root set $SUDO to sudo
 189 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 190
 191 # change directory to home on first invocation of zsh
 192 # important for rungetty -> autologin
 193 # Thanks go to Bart Schaefer!
 194 isgrml && checkhome() {
 195     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 196         export ALREADY_DID_CD_HOME=$HOME
 197         cd
 198     fi
 199 }
 200
 201 # check for zsh v3.1.7+
 202
 203 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 204      || ${ZSH_VERSION} == 3.<2->.<->*    \
 205      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 206
 207     printf '-!-\n'
 208     printf '-!- In this configuration we try to make use of features, that only\n'
 209     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 210     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 211     printf '-!- advanced features in all supported versions.\n'
 212     printf '-!-\n'
 213     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 214     printf '-!-\n'
 215     printf '-!- While this *may* work, it might as well fail.\n'
 216     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 217     printf '-!-\n'
 218     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 219     printf '-!- If it does today, you'\''ve been lucky.\n'
 220     printf '-!-\n'
 221     printf '-!- Ye been warned!\n'
 222     printf '-!-\n'
 223
 224     function zstyle() { : }
 225 fi
 226
 227 # autoload wrapper - use this one instead of autoload directly
 228 # We need to define this function as early as this, because autoloading
 229 # 'is-at-least()' needs it.
 230 function zrcautoload() {
 231     emulate -L zsh
 232     setopt extended_glob
 233     local fdir ffile
 234     local -i ffound
 235
 236     ffile=$1
 237     (( found = 0 ))
 238     for fdir in ${fpath} ; do
 239         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 240     done
 241
 242     (( ffound == 0 )) && return 1
 243     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 244         autoload -U ${ffile} || return 1
 245     else
 246         autoload ${ffile} || return 1
 247     fi
 248     return 0
 249 }
 250
 251 # Load is-at-least() for more precise version checks
 252 # Note that this test will *always* fail, if the is-at-least
 253 # function could not be marked for autoloading.
 254 zrcautoload is-at-least || is-at-least() { return 1 }
 255
 256 # }}}
 257
 258 # {{{ set some important options (as early as possible)
 259 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 260 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 261 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 262 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 263                             # list duplicates an older one, the older command is removed from the list
 264 setopt histignorespace      # remove command lines from the history list when
 265                             # the first character on the line is a space
 266 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 267                             # and the command is the name of a directory, perform the cd command to that directory
 268 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 269                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 270                             # -> searches for word not in compressed files
 271                             # don't forget to quote '^', '~' and '#'!
 272 setopt longlistjobs         # display PID when suspending processes as well
 273 setopt notify               # report the status of backgrounds jobs immediately
 274 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 275                             # the entire command path is hashed first.
 276 setopt completeinword       # not just at the end
 277 setopt nohup                # and don't kill them, either
 278 setopt auto_pushd           # make cd push the old directory onto the directory stack.
 279 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 280 setopt nobeep               # avoid "beep"ing
 281 setopt pushd_ignore_dups    # don't push the same dir twice.
 282 setopt noglobdots           # * shouldn't match dotfiles. ever.
 283 setopt noshwordsplit        # use zsh style word splitting
 284 setopt unset                # don't error out when unset parameters are used
 285
 286 # }}}
 287
 288 # setting some default values {{{
 289
 290 NOCOR=${NOCOR:-0}
 291 NOMENU=${NOMENU:-0}
 292 NOPRECMD=${NOPRECMD:-0}
 293 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 294 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 295 BATTERY=${BATTERY:-0}
 296 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 297 GRML_ALWAYS_LOAD_ALL=${GRML_ALWAYS_LOAD_ALL:-0}
 298 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 299
 300 # }}}
 301
 302 # utility functions {{{
 303 # this function checks if a command exists and returns either true
 304 # or false. This avoids using 'which' and 'whence', which will
 305 # avoid problems with aliases for which on certain weird systems. :-)
 306 # Usage: check_com [-c|-g] word
 307 #   -c  only checks for external commands
 308 #   -g  does the usual tests and also checks for global aliases
 309 check_com() {
 310     emulate -L zsh
 311     local -i comonly gatoo
 312
 313     if [[ $1 == '-c' ]] ; then
 314         (( comonly = 1 ))
 315         shift
 316     elif [[ $1 == '-g' ]] ; then
 317         (( gatoo = 1 ))
 318     else
 319         (( comonly = 0 ))
 320         (( gatoo = 0 ))
 321     fi
 322
 323     if (( ${#argv} != 1 )) ; then
 324         printf 'usage: check_com [-c] <command>\n' >&2
 325         return 1
 326     fi
 327
 328     if (( comonly > 0 )) ; then
 329         [[ -n ${commands[$1]}  ]] && return 0
 330         return 1
 331     fi
 332
 333     if   [[ -n ${commands[$1]}    ]] \
 334       || [[ -n ${functions[$1]}   ]] \
 335       || [[ -n ${aliases[$1]}     ]] \
 336       || [[ -n ${reswords[(r)$1]} ]] ; then
 337
 338         return 0
 339     fi
 340
 341     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 342         return 0
 343     fi
 344
 345     return 1
 346 }
 347
 348 # creates an alias and precedes the command with
 349 # sudo if $EUID is not zero.
 350 salias() {
 351     emulate -L zsh
 352     local only=0 ; local multi=0
 353     while [[ $1 == -* ]] ; do
 354         case $1 in
 355             (-o) only=1 ;;
 356             (-a) multi=1 ;;
 357             (--) shift ; break ;;
 358             (-h)
 359                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 360                 printf '  -h      shows this help text.\n'
 361                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 362                 printf '          be careful using this option.\n'
 363                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 364                 return 0
 365                 ;;
 366             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 367         esac
 368         shift
 369     done
 370
 371     if (( ${#argv} > 1 )) ; then
 372         printf 'Too many arguments %s\n' "${#argv}"
 373         return 1
 374     fi
 375
 376     key="${1%%\=*}" ;  val="${1#*\=}"
 377     if (( EUID == 0 )) && (( only == 0 )); then
 378         alias -- "${key}=${val}"
 379     elif (( EUID > 0 )) ; then
 380         (( multi > 0 )) && val="${val// ; / ; sudo }"
 381         alias -- "${key}=sudo ${val}"
 382     fi
 383
 384     return 0
 385 }
 386
 387 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 388 # usage: uprint foo
 389 #   Where foo is the *name* of the parameter you want printed.
 390 #   Note that foo is no typo; $foo would be wrong here!
 391 if ! is42 ; then
 392     uprint () {
 393         emulate -L zsh
 394         local -a u
 395         local w
 396         local parameter=$1
 397
 398         if [[ -z ${parameter} ]] ; then
 399             printf 'usage: uprint <parameter>\n'
 400             return 1
 401         fi
 402
 403         for w in ${(P)parameter} ; do
 404             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 405         done
 406
 407         builtin print -l $u
 408     }
 409 fi
 410
 411 # Check if we can read given files and source those we can.
 412 xsource() {
 413     if (( ${#argv} < 1 )) ; then
 414         printf 'usage: xsource FILE(s)...\n' >&2
 415         return 1
 416     fi
 417
 418     while (( ${#argv} > 0 )) ; do
 419         [[ -r "$1" ]] && source "$1"
 420         shift
 421     done
 422     return 0
 423 }
 424
 425 # Check if we can read a given file and 'cat(1)' it.
 426 xcat() {
 427     emulate -L zsh
 428     if (( ${#argv} != 1 )) ; then
 429         printf 'usage: xcat FILE\n' >&2
 430         return 1
 431     fi
 432
 433     [[ -r $1 ]] && cat $1
 434     return 0
 435 }
 436
 437 # Remove these functions again, they are of use only in these
 438 # setup files. This should be called at the end of .zshrc.
 439 xunfunction() {
 440     emulate -L zsh
 441     local -a funcs
 442     funcs=(salias xcat xsource xunfunction zrcautoload)
 443
 444     for func in $funcs ; do
 445         [[ -n ${functions[$func]} ]] \
 446             && unfunction $func
 447     done
 448     return 0
 449 }
 450
 451 # this allows us to stay in sync with grml's zshrc and put own
 452 # modifications in ~/.zshrc.local
 453 zrclocal() {
 454     xsource "/etc/zsh/zshrc.local"
 455     xsource "${HOME}/.zshrc.local"
 456     return 0
 457 }
 458
 459 #}}}
 460
 461 # locale setup {{{
 462 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 463     xsource "/etc/default/locale"
 464 fi
 465
 466 for var in LANG LC_ALL LC_MESSAGES ; do
 467     [[ -n ${(P)var} ]] && export $var
 468 done
 469
 470 xsource "/etc/sysconfig/keyboard"
 471
 472 TZ=$(xcat /etc/timezone)
 473 # }}}
 474
 475 # {{{ set some variables
 476 if check_com -c vim ; then
 477 #v#
 478     export EDITOR=${EDITOR:-vim}
 479 else
 480     export EDITOR=${EDITOR:-vi}
 481 fi
 482
 483 #v#
 484 export PAGER=${PAGER:-less}
 485
 486 #v#
 487 export MAIL=${MAIL:-/var/mail/$USER}
 488
 489 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 490 export SHELL='/bin/zsh'
 491
 492 # color setup for ls:
 493 check_com -c dircolors && eval $(dircolors -b)
 494 # color setup for ls on OS X:
 495 isdarwin && export CLICOLOR=1
 496
 497 # do MacPorts setup on darwin
 498 if isdarwin && [[ -d /opt/local ]]; then
 499     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 500     # zshenv.
 501     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 502     MANPATH="/opt/local/share/man:$MANPATH"
 503 fi
 504 # do Fink setup on darwin
 505 isdarwin && xsource /sw/bin/init.sh
 506
 507 # load our function and completion directories
 508 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 509     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 510     if [[ ${fpath} == '/usr/share/grml/zsh/functions' ]] ; then
 511         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 512             zrcautoload ${func:t}
 513         done
 514     fi
 515 done
 516 unset fdir func
 517
 518 # support colors in less
 519 export LESS_TERMCAP_mb=$'\E[01;31m'
 520 export LESS_TERMCAP_md=$'\E[01;31m'
 521 export LESS_TERMCAP_me=$'\E[0m'
 522 export LESS_TERMCAP_se=$'\E[0m'
 523 export LESS_TERMCAP_so=$'\E[01;44;33m'
 524 export LESS_TERMCAP_ue=$'\E[0m'
 525 export LESS_TERMCAP_us=$'\E[01;32m'
 526
 527 MAILCHECK=30       # mailchecks
 528 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 529 watch=(notme root) # watch for everyone but me and root
 530
 531 # automatically remove duplicates from these arrays
 532 typeset -U path cdpath fpath manpath
 533 # }}}
 534
 535 # {{{ keybindings
 536 if [[ "$TERM" != emacs ]] ; then
 537     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 538     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 539     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 540     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 541     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 542     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 543     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 544     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 545     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 546     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 547     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 548     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 549     # ncurses stuff:
 550     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 551     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 552     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 553     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 554     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 555     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 556     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 557     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 558 fi
 559
 560 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 561 # use emacs style per default:
 562 bindkey -e
 563 # use vi style:
 564 # bindkey -v
 565
 566 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 567 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 568 beginning-or-end-of-somewhere() {
 569     local hno=$HISTNO
 570     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 571       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 572         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 573     else
 574         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 575         if (( HISTNO != hno )); then
 576             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 577         fi
 578     fi
 579 }
 580 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 581 zle -N end-of-somewhere beginning-or-end-of-somewhere
 582
 583
 584 #if [[ "$TERM" == screen ]] ; then
 585
 586 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 587 ## to beginning/end of buffer on second keypress
 588 ## and to beginning/end of history on (at most) the third keypress
 589 # terminator & non-debian xterm
 590 bindkey '\eOH' beginning-of-somewhere  # home
 591 bindkey '\eOF' end-of-somewhere        # end
 592 # freebsd console
 593 bindkey '\e[H' beginning-of-somewhere   # home
 594 bindkey '\e[F' end-of-somewhere         # end
 595 # xterm,gnome-terminal,quake,etc
 596 bindkey '^[[1~' beginning-of-somewhere  # home
 597 bindkey '^[[4~' end-of-somewhere        # end
 598 # if terminal type is set to 'rxvt':
 599 bindkey '\e[7~' beginning-of-somewhere  # home
 600 bindkey '\e[8~' end-of-somewhere        # end
 601 #fi
 602
 603 bindkey '\e[A'  up-line-or-search       # cursor up
 604 bindkey '\e[B'  down-line-or-search     # <ESC>-
 605
 606 ## alt-backspace is already the default for backwards-delete-word
 607 ## let's also set alt-delete for deleting current word (right of cursor)
 608 #k# Delete current word
 609 bindkey "3~" delete-word
 610
 611 bindkey '^xp'   history-beginning-search-backward
 612 bindkey '^xP'   history-beginning-search-forward
 613 bindkey "\e[5~" history-beginning-search-backward #PageUp
 614 bindkey "\e[6~" history-beginning-search-forward  #PageDown
 615 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 616 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 617
 618
 619 # insert unicode character
 620 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 621 # See for example http://unicode.org/charts/ for unicode characters code
 622 zrcautoload insert-unicode-char
 623 zle -N insert-unicode-char
 624 #k# Insert Unicode character
 625 bindkey '^Xi' insert-unicode-char
 626
 627 #m# k Shift-tab Perform backwards menu completion
 628 if [[ -n "$terminfo[kcbt]" ]]; then
 629     bindkey "$terminfo[kcbt]" reverse-menu-complete
 630 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 631     bindkey "$terminfo[cbt]"  reverse-menu-complete
 632 fi
 633
 634 ## toggle the ,. abbreviation feature on/off
 635 # NOABBREVIATION: default abbreviation-state
 636 #                 0 - enabled (default)
 637 #                 1 - disabled
 638 NOABBREVIATION=${NOABBREVIATION:-0}
 639
 640 grml_toggle_abbrev() {
 641     if (( ${NOABBREVIATION} > 0 )) ; then
 642         NOABBREVIATION=0
 643     else
 644         NOABBREVIATION=1
 645     fi
 646 }
 647
 648 zle -N grml_toggle_abbrev
 649 bindkey '^xA' grml_toggle_abbrev
 650
 651 # add a command line to the shells history without executing it
 652 commit-to-history() {
 653     print -s ${(z)BUFFER}
 654     zle send-break
 655 }
 656 zle -N commit-to-history
 657 bindkey "^x^h" commit-to-history
 658
 659 # only slash should be considered as a word separator:
 660 slash-backward-kill-word() {
 661     local WORDCHARS="${WORDCHARS:s@/@}"
 662     # zle backward-word
 663     zle backward-kill-word
 664 }
 665 zle -N slash-backward-kill-word
 666
 667 #k# Kill everything in a word up to its last \kbd{/}
 668 bindkey '\ev' slash-backward-kill-word
 669 #k# Kill everything in a word up to its last \kbd{/}
 670 bindkey '\e^h' slash-backward-kill-word
 671 #k# Kill everything in a word up to its last \kbd{/}
 672 bindkey '\e^?' slash-backward-kill-word
 673
 674 # use the new *-pattern-* widgets for incremental history search
 675 if is439 ; then
 676     bindkey '^r' history-incremental-pattern-search-backward
 677     bindkey '^s' history-incremental-pattern-search-forward
 678 fi
 679 # }}}
 680
 681 # a generic accept-line wrapper {{{
 682
 683 # This widget can prevent unwanted autocorrections from command-name
 684 # to _command-name, rehash automatically on enter and call any number
 685 # of builtin and user-defined widgets in different contexts.
 686 #
 687 # For a broader description, see:
 688 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 689 #
 690 # The code is imported from the file 'zsh/functions/accept-line' from
 691 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 692 # distributed under the same terms as zsh itself.
 693
 694 # A newly added command will may not be found or will cause false
 695 # correction attempts, if you got auto-correction set. By setting the
 696 # following style, we force accept-line() to rehash, if it cannot
 697 # find the first word on the command line in the $command[] hash.
 698 zstyle ':acceptline:*' rehash true
 699
 700 function Accept-Line() {
 701     emulate -L zsh
 702     local -a subs
 703     local -xi aldone
 704     local sub
 705
 706     zstyle -a ":acceptline:${alcontext}" actions subs
 707
 708     (( ${#subs} < 1 )) && return 0
 709
 710     (( aldone = 0 ))
 711     for sub in ${subs} ; do
 712         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 713         zle ${sub}
 714
 715         (( aldone > 0 )) && break
 716     done
 717 }
 718
 719 function Accept-Line-getdefault() {
 720     emulate -L zsh
 721     local default_action
 722
 723     zstyle -s ":acceptline:${alcontext}" default_action default_action
 724     case ${default_action} in
 725         ((accept-line|))
 726             printf ".accept-line"
 727             ;;
 728         (*)
 729             printf ${default_action}
 730             ;;
 731     esac
 732 }
 733
 734 function accept-line() {
 735     emulate -L zsh
 736     local -a cmdline
 737     local -x alcontext
 738     local buf com fname format msg default_action
 739
 740     alcontext='default'
 741     buf="${BUFFER}"
 742     cmdline=(${(z)BUFFER})
 743     com="${cmdline[1]}"
 744     fname="_${com}"
 745
 746     zstyle -t ":acceptline:${alcontext}" rehash \
 747         && [[ -z ${commands[$com]} ]]           \
 748         && rehash
 749
 750     if    [[ -n ${reswords[(r)$com]} ]] \
 751        || [[ -n ${aliases[$com]}     ]] \
 752        || [[ -n ${functions[$com]}   ]] \
 753        || [[ -n ${builtins[$com]}    ]] \
 754        || [[ -n ${commands[$com]}    ]] ; then
 755
 756         # there is something sensible to execute, just do it.
 757         alcontext='normal'
 758         zle Accept-Line
 759
 760         default_action=$(Accept-Line-getdefault)
 761         zstyle -T ":acceptline:${alcontext}" call_default \
 762             && zle ${default_action}
 763         return
 764     fi
 765
 766     if    [[ -o correct              ]] \
 767        || [[ -o correctall           ]] \
 768        && [[ -n ${functions[$fname]} ]] ; then
 769
 770         # nothing there to execute but there is a function called
 771         # _command_name; a completion widget. Makes no sense to
 772         # call it on the commandline, but the correct{,all} options
 773         # will ask for it nevertheless, so warn the user.
 774         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 775             # Okay, we warned the user before, he called us again,
 776             # so have it his way.
 777             alcontext='force'
 778             zle Accept-Line
 779
 780             default_action=$(Accept-Line-getdefault)
 781             zstyle -T ":acceptline:${alcontext}" call_default \
 782                 && zle ${default_action}
 783             return
 784         fi
 785
 786         # prepare warning message for the user, configurable via zstyle.
 787         zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 788
 789         if [[ -z ${msg} ]] ; then
 790             msg="%c will not execute and completion %f exists."
 791         fi
 792
 793         zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 794
 795         zle -M -- "${msg}"
 796         return
 797     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 798         # If we are here, the commandline contains something that is not
 799         # executable, which is neither subject to _command_name correction
 800         # and is not empty. might be a variable assignment
 801         alcontext='misc'
 802         zle Accept-Line
 803
 804         default_action=$(Accept-Line-getdefault)
 805         zstyle -T ":acceptline:${alcontext}" call_default \
 806             && zle ${default_action}
 807         return
 808     fi
 809
 810     # If we got this far, the commandline only contains whitespace, or is empty.
 811     alcontext='empty'
 812     zle Accept-Line
 813
 814     default_action=$(Accept-Line-getdefault)
 815     zstyle -T ":acceptline:${alcontext}" call_default \
 816         && zle ${default_action}
 817 }
 818
 819 zle -N accept-line
 820 zle -N Accept-Line
 821
 822 # }}}
 823
 824 # power completion - abbreviation expansion {{{
 825 # power completion / abbreviation expansion / buffer expansion
 826 # see http://zshwiki.org/home/examples/zleiab for details
 827 # less risky than the global aliases but powerful as well
 828 # just type the abbreviation key and afterwards ',.' to expand it
 829 declare -A abk
 830 setopt extendedglob
 831 setopt interactivecomments
 832 abk=(
 833 #   key   # value                  (#d additional doc string)
 834 #A# start
 835     '...'  '../..'
 836     '....' '../../..'
 837     'BG'   '& exit'
 838     'C'    '| wc -l'
 839     'G'    '|& grep --color=auto '
 840     'H'    '| head'
 841     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 842     'L'    '| less'
 843     'LL'   '|& less -r'
 844     'M'    '| most'
 845     'N'    '&>/dev/null'           #d (No Output)
 846     'R'    '| tr A-z N-za-m'       #d (ROT13)
 847     'SL'   '| sort | less'
 848     'S'    '| sort -u'
 849     'T'    '| tail'
 850     'V'    '|& vim -'
 851 #A# end
 852     'co'   './configure && make && sudo make install'
 853 )
 854
 855 globalias() {
 856     emulate -L zsh
 857     setopt extendedglob
 858     local MATCH
 859
 860     if (( NOABBREVIATION > 0 )) ; then
 861         LBUFFER="${LBUFFER},."
 862         return 0
 863     fi
 864
 865     matched_chars='[.-|_a-zA-Z0-9]#'
 866     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 867     LBUFFER+=${abk[$MATCH]:-$MATCH}
 868 }
 869
 870 zle -N globalias
 871 bindkey ",." globalias
 872 # }}}
 873
 874 # {{{ autoloading
 875 zrcautoload zmv    # who needs mmv or rename?
 876 zrcautoload history-search-end
 877
 878 # we don't want to quote/espace URLs on our own...
 879 # if autoload -U url-quote-magic ; then
 880 #    zle -N self-insert url-quote-magic
 881 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 882 # else
 883 #    print 'Notice: no url-quote-magic available :('
 884 # fi
 885 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 886
 887 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 888 alias run-help >&/dev/null && unalias run-help
 889 for rh in run-help{,-git,-svk,-svn}; do
 890     zrcautoload $rh
 891 done; unset rh
 892
 893 # completion system
 894 if zrcautoload compinit ; then
 895     compinit || print 'Notice: no compinit available :('
 896 else
 897     print 'Notice: no compinit available :('
 898     function zstyle { }
 899     function compdef { }
 900 fi
 901
 902 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 903
 904 is4 && \
 905 for mod in complist deltochar mathfunc ; do
 906     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 907 done
 908
 909 # autoload zsh modules when they are referenced
 910 if is4 ; then
 911     zmodload -a  zsh/stat    zstat
 912     zmodload -a  zsh/zpty    zpty
 913     zmodload -ap zsh/mapfile mapfile
 914 fi
 915
 916 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 917     #k# Insert files
 918     bindkey "^Xf" insert-files # C-x-f
 919 fi
 920
 921 bindkey ' '   magic-space    # also do history expansion on space
 922 #k# Trigger menu-complete
 923 bindkey '\ei' menu-complete  # menu completion via esc-i
 924
 925 # press esc-e for editing command line in $EDITOR or $VISUAL
 926 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 927     #k# Edit the current line in \kbd{\$EDITOR}
 928     bindkey '\ee' edit-command-line
 929 fi
 930
 931 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 932     #k# menu selection: pick item but stay in the menu
 933     bindkey -M menuselect '\e^M' accept-and-menu-complete
 934     # also use + and INSERT since it's easier to press repeatedly
 935     bindkey -M menuselect "+" accept-and-menu-complete
 936     bindkey -M menuselect "^[[2~" accept-and-menu-complete
 937
 938     # accept a completion and try to complete again by using menu
 939     # completion; very useful with completing directories
 940     # by using 'undo' one's got a simple file browser
 941     bindkey -M menuselect '^o' accept-and-infer-next-history
 942 fi
 943
 944 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 945 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
 946 zle -N insert-datestamp
 947
 948 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 949 bindkey '^Ed' insert-datestamp
 950
 951 # press esc-m for inserting last typed word again (thanks to caphuso!)
 952 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 953 zle -N insert-last-typed-word;
 954
 955 #k# Insert last typed word
 956 bindkey "\em" insert-last-typed-word
 957
 958 function grml-zsh-fg() {
 959   if (( ${#jobstates} )); then
 960     zle .push-input
 961     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
 962     BUFFER="${BUFFER}fg"
 963     zle .accept-line
 964   else
 965     zle -M 'No background jobs. Doing nothing.'
 966   fi
 967 }
 968 zle -N grml-zsh-fg
 969 #k# A smart shortcut for \kbd{fg<enter>}
 970 bindkey '^z' grml-zsh-fg
 971
 972 # run command line as user root via sudo:
 973 sudo-command-line() {
 974     [[ -z $BUFFER ]] && zle up-history
 975     if [[ $BUFFER != sudo\ * ]]; then
 976         BUFFER="sudo $BUFFER"
 977         CURSOR=$(( CURSOR+5 ))
 978     fi
 979 }
 980 zle -N sudo-command-line
 981
 982 #k# Put the current command line into a \kbd{sudo} call
 983 bindkey "^Os" sudo-command-line
 984
 985 ### jump behind the first word on the cmdline.
 986 ### useful to add options.
 987 function jump_after_first_word() {
 988     local words
 989     words=(${(z)BUFFER})
 990
 991     if (( ${#words} <= 1 )) ; then
 992         CURSOR=${#BUFFER}
 993     else
 994         CURSOR=${#${words[1]}}
 995     fi
 996 }
 997 zle -N jump_after_first_word
 998
 999 bindkey '^x1' jump_after_first_word
1000
1001 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1002 zle -C hist-complete complete-word _generic
1003 zstyle ':completion:hist-complete:*' completer _history
1004 #k# complete word from history with menu
1005 bindkey "^X^X" hist-complete
1006
1007 # }}}
1008
1009 # {{{ history
1010
1011 ZSHDIR=$HOME/.zsh
1012
1013 #v#
1014 HISTFILE=$HOME/.zsh_history
1015 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1016 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1017
1018 # }}}
1019
1020 # dirstack handling {{{
1021
1022 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1023 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1024
1025 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1026     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1027     # "cd -" won't work after login by just setting $OLDPWD, so
1028     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
1029 fi
1030
1031 chpwd() {
1032     local -ax my_stack
1033     my_stack=( ${PWD} ${dirstack} )
1034     if is42 ; then
1035         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1036     else
1037         uprint my_stack >! ${DIRSTACKFILE}
1038     fi
1039 }
1040
1041 # }}}
1042
1043 # directory based profiles {{{
1044
1045 if is433 ; then
1046
1047 CHPWD_PROFILE='default'
1048 function chpwd_profiles() {
1049     # Say you want certain settings to be active in certain directories.
1050     # This is what you want.
1051     #
1052     # zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1053     # zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1054     #
1055     # When that's done and you enter a directory that matches the pattern
1056     # in the third part of the context, a function called chpwd_profile_grml,
1057     # for example, is called (if it exists).
1058     #
1059     # If no pattern matches (read: no profile is detected) the profile is
1060     # set to 'default', which means chpwd_profile_default is attempted to
1061     # be called.
1062     #
1063     # A word about the context (the ':chpwd:profiles:*' stuff in the zstyle
1064     # command) which is used: The third part in the context is matched against
1065     # ${PWD}. That's why using a pattern such as /foo/bar(|/|/*) makes sense.
1066     # Because that way the profile is detected for all these values of ${PWD}:
1067     #   /foo/bar
1068     #   /foo/bar/
1069     #   /foo/bar/baz
1070     # So, if you want to make double damn sure a profile works in /foo/bar
1071     # and everywhere deeper in that tree, just use (|/|/*) and be happy.
1072     #
1073     # The name of the detected profile will be available in a variable called
1074     # 'profile' in your functions. You don't need to do anything, it'll just
1075     # be there.
1076     #
1077     # Then there is the parameter $CHPWD_PROFILE is set to the profile, that
1078     # was is currently active. That way you can avoid running code for a
1079     # profile that is already active, by running code such as the following
1080     # at the start of your function:
1081     #
1082     # function chpwd_profile_grml() {
1083     #     [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1084     #   ...
1085     # }
1086     #
1087     # The initial value for $CHPWD_PROFILE is 'default'.
1088     #
1089     # Version requirement:
1090     #   This feature requires zsh 4.3.3 or newer.
1091     #   If you use this feature and need to know whether it is active in your
1092     #   current shell, there are several ways to do that. Here are two simple
1093     #   ways:
1094     #
1095     #   a) If knowing if the profiles feature is active when zsh starts is
1096     #      good enough for you, you can put the following snippet into your
1097     #      .zshrc.local:
1098     #
1099     #   (( ${+functions[chpwd_profiles]} )) && print "directory profiles active"
1100     #
1101     #   b) If that is not good enough, and you would prefer to be notified
1102     #      whenever a profile changes, you can solve that by making sure you
1103     #      start *every* profile function you create like this:
1104     #
1105     #   function chpwd_profile_myprofilename() {
1106     #       [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1107     #       print "chpwd(): Switching to profile: $profile"
1108     #     ...
1109     #   }
1110     #
1111     #      That makes sure you only get notified if a profile is *changed*,
1112     #      not everytime you change directory, which would probably piss
1113     #      you off fairly quickly. :-)
1114     #
1115     # There you go. Now have fun with that.
1116     local -x profile
1117
1118     zstyle -s ":chpwd:profiles:${PWD}" profile profile || profile='default'
1119     if (( ${+functions[chpwd_profile_$profile]} )) ; then
1120         chpwd_profile_${profile}
1121     fi
1122
1123     CHPWD_PROFILE="${profile}"
1124     return 0
1125 }
1126 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1127
1128 fi # is433
1129
1130 # }}}
1131
1132 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
1133 if [[ $BATTERY -gt 0 ]] ; then
1134     if ! check_com -c acpi ; then
1135         BATTERY=0
1136     fi
1137 fi
1138
1139 battery() {
1140 if [[ $BATTERY -gt 0 ]] ; then
1141     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1142     if [[ -z "$PERCENT" ]] ; then
1143         PERCENT='acpi not present'
1144     else
1145         if [[ "$PERCENT" -lt 20 ]] ; then
1146             PERCENT="warning: ${PERCENT}%%"
1147         else
1148             PERCENT="${PERCENT}%%"
1149         fi
1150     fi
1151 fi
1152 }
1153 # }}}
1154
1155 # set colors for use in prompts {{{
1156 if zrcautoload colors && colors 2>/dev/null ; then
1157     BLUE="%{${fg[blue]}%}"
1158     RED="%{${fg_bold[red]}%}"
1159     GREEN="%{${fg[green]}%}"
1160     CYAN="%{${fg[cyan]}%}"
1161     MAGENTA="%{${fg[magenta]}%}"
1162     YELLOW="%{${fg[yellow]}%}"
1163     WHITE="%{${fg[white]}%}"
1164     NO_COLOUR="%{${reset_color}%}"
1165 else
1166     BLUE=$'%{\e[1;34m%}'
1167     RED=$'%{\e[1;31m%}'
1168     GREEN=$'%{\e[1;32m%}'
1169     CYAN=$'%{\e[1;36m%}'
1170     WHITE=$'%{\e[1;37m%}'
1171     MAGENTA=$'%{\e[1;35m%}'
1172     YELLOW=$'%{\e[1;33m%}'
1173     NO_COLOUR=$'%{\e[0m%}'
1174 fi
1175
1176 # }}}
1177
1178 # gather version control information for inclusion in a prompt {{{
1179
1180 if ! is41 ; then
1181     # Be quiet about version problems in grml's zshrc as the user cannot disable
1182     # loading vcs_info() as it is *in* the zshrc - as you can see. :-)
1183     # Just unset most probable variables and disable vcs_info altogether.
1184     local -i i
1185     for i in {0..9} ; do
1186         unset VCS_INFO_message_${i}_
1187     done
1188     zstyle ':vcs_info:*' enable false
1189 fi
1190
1191 if zrcautoload vcs_info; then
1192     GRML_VCS_INFO=0
1193     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1194     # function, which can cause a lot of trouble with our directory-based
1195     # profiles. So:
1196     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1197         function VCS_INFO_realpath () {
1198             setopt localoptions NO_shwordsplit chaselinks
1199             ( builtin cd -q $1 2> /dev/null && pwd; )
1200         }
1201     fi
1202 else
1203 # I'm not reindenting the whole code below.
1204 GRML_VCS_INFO=1
1205
1206 # The following code is imported from the file 'zsh/functions/vcs_info'
1207 # from <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>,
1208 # which distributed under the same terms as zsh itself.
1209
1210 # we will be using two variables, so let the code know now.
1211 zstyle ':vcs_info:*' max-exports 2
1212
1213 # vcs_info() documentation:
1214 #{{{
1215 # REQUIREMENTS:
1216 #{{{
1217 #     This functionality requires zsh version >= 4.1.*.
1218 #}}}
1219 #
1220 # LOADING:
1221 #{{{
1222 # To load vcs_info(), copy this file to your $fpath[] and do:
1223 #   % autoload -Uz vcs_info && vcs_info
1224 #
1225 # To work, vcs_info() needs 'setopt prompt_subst' in your setup.
1226 #}}}
1227 #
1228 # QUICKSTART:
1229 #{{{
1230 # To get vcs_info() working quickly (including colors), you can do the
1231 # following (assuming, you loaded vcs_info() properly - see above):
1232 #
1233 # % RED=$'%{\e[31m%}'
1234 # % GR=$'%{\e[32m%}'
1235 # % MA=$'%{\e[35m%}'
1236 # % YE=$'%{\e[33m%}'
1237 # % NC=$'%{\e[0m%}'
1238 #
1239 # % zstyle ':vcs_info:*' actionformats \
1240 #       "${MA}(${NC}%s${MA})${YE}-${MA}[${GR}%b${YE}|${RED}%a${MA}]${NC} "
1241 #
1242 # % zstyle ':vcs_info:*' formats       \
1243 #       "${MA}(${NC}%s${MA})${Y}-${MA}[${GR}%b${MA}]${NC}%} "
1244 #
1245 # % zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YE}%r"
1246 #
1247 # % precmd () { vcs_info }
1248 # % PS1='${MA}[${GR}%n${MA}] ${MA}(${RED}%!${MA}) ${YE}%3~ ${VCS_INFO_message_0_}${NC}%# '
1249 #
1250 # Obviously, the las two lines are there for demonstration: You need to
1251 # call vcs_info() from your precmd() function (see 'SPECIAL FUNCTIONS' in
1252 # 'man zshmisc'). Once that is done you need a *single* quoted
1253 # '${VCS_INFO_message_0_}' in your prompt.
1254 #
1255 # Now call the 'vcs_info_printsys' utility from the command line:
1256 #
1257 # % vcs_info_printsys
1258 # # list of supported version control backends:
1259 # # disabled systems are prefixed by a hash sign (#)
1260 # git
1261 # hg
1262 # bzr
1263 # darcs
1264 # svk
1265 # mtn
1266 # svn
1267 # cvs
1268 # cdv
1269 # tla
1270 # # flavours (cannot be used in the disable style; they
1271 # # are disabled with their master [git-svn -> git]):
1272 # git-p4
1273 # git-svn
1274 #
1275 # Ten version control backends as you can see. You may not want all
1276 # of these. Because there is no point in running the code to detect
1277 # systems you do not use. ever. So, there is a way to disable some
1278 # backends altogether:
1279 #
1280 # % zstyle ':vcs_info:*' disable bzr cdv darcs mtn svk tla
1281 #
1282 # If you rerun 'vcs_info_printsys' now, you will see the backends listed
1283 # in the 'disable' style marked as diabled by a hash sign. That means the
1284 # detection of these systems is skipped *completely*. No wasted time there.
1285 #
1286 # For more control, read the reference below.
1287 #}}}
1288 #
1289 # CONFIGURATION:
1290 #{{{
1291 # The vcs_info() feature can be configured via zstyle.
1292 #
1293 # First, the context in which we are working:
1294 #       :vcs_info:<vcs-string>:<user-context>
1295 #
1296 # ...where <vcs-string> is one of:
1297 #   - git, git-svn, git-p4, hg, darcs, bzr, cdv, mtn, svn, cvs, svk or tla.
1298 #
1299 # ...and <user-context> is a freely configurable string, assignable by the
1300 # user as the first argument to vcs_info() (see its description below).
1301 #
1302 # There is are three special values for <vcs-string>: The first is named
1303 # 'init', that is in effect as long as there was no decision what vcs
1304 # backend to use. The second is 'preinit; it is used *before* vcs_info()
1305 # is run, when initializing the data exporting variables. The third
1306 # special value is 'formats' and is used by the 'vcs_info_lastmsg' for
1307 # looking up its styles.
1308 #
1309 # There are two pre-defined values for <user-context>:
1310 #   default  - the one used if none is specified
1311 #   command  - used by vcs_info_lastmsg to lookup its styles.
1312 #
1313 # You may *not* use 'print_systems_' as a user-context string, because it
1314 # is used internally.
1315 #
1316 # You can of course use ':vcs_info:*' to match all VCSs in all
1317 # user-contexts at once.
1318 #
1319 # Another special context is 'formats', which is used by the
1320 # vcs_info_lastmsg() utility function (see below).
1321 #
1322 #
1323 # This is a description of all styles, that are looked up:
1324 #   formats             - A list of formats, used when actionformats is not
1325 #                         used (which is most of the time).
1326 #   actionformats       - A list of formats, used if a there is a special
1327 #                         action going on in your current repository;
1328 #                         (like an interactive rebase or a merge conflict)
1329 #   branchformat        - Some backends replace %b in the formats and
1330 #                         actionformats styles above, not only by a branch
1331 #                         name but also by a revision number. This style
1332 #                         let's you modify how that string should look like.
1333 #   nvcsformats         - These "formats" are exported, when we didn't detect
1334 #                         a version control system for the current directory.
1335 #                         This is useful, if you want vcs_info() to completely
1336 #                         take over the generation of your prompt.
1337 #                         You would do something like
1338 #                           PS1='${VCS_INFO_message_0_}'
1339 #                         to accomplish that.
1340 #   max-exports         - Defines the maximum number if VCS_INFO_message_*_
1341 #                         variables vcs_info() will export.
1342 #   enable              - Checked in the 'init' context. If set to false,
1343 #                         vcs_info() will do nothing.
1344 #   disable             - Provide a list of systems, you don't want
1345 #                         the vcs_info() to check for repositories
1346 #                         (checked in the 'init' context, too).
1347 #   disable-patterns    - A list of patterns that are checked against $PWD.
1348 #                         If the pattern matches, vcs_info will be disabled.
1349 #                         Say, ~/.zsh is a directory under version control,
1350 #                         in which you do not want vcs_info to be active, do:
1351 #                         zstyle ':vcs_info:*' disable-patterns "$HOME/.zsh+(|/*)"
1352 #   use-simple          - If there are two different ways of gathering
1353 #                         information, you can select the simpler one
1354 #                         by setting this style to true; the default
1355 #                         is to use the not-that-simple code, which is
1356 #                         potentially a lot slower but might be more
1357 #                         accurate in all possible cases.
1358 #   use-prompt-escapes  - determines if we assume that the assembled
1359 #                         string from vcs_info() includes prompt escapes.
1360 #                         (Used by vcs_info_lastmsg().
1361 #
1362 # The use-simple style is only available for the bzr backend.
1363 #
1364 # The default values for these in all contexts are:
1365 #   formats             " (%s)-[%b|%a]-"
1366 #   actionformats       " (%s)-[%b]-"
1367 #   branchformat        "%b:%r" (for bzr, svn and svk)
1368 #   nvcsformats         ""
1369 #   max-exports         2
1370 #   enable              true
1371 #   disable             (empty list)
1372 #   disable-patterns    (empty list)
1373 #   use-simple          false
1374 #   use-prompt-escapes  true
1375 #
1376 #
1377 # In normal formats and actionformats, the following replacements
1378 # are done:
1379 #   %s  - The vcs in use (git, hg, svn etc.)
1380 #   %b  - Information about the current branch.
1381 #   %a  - An identifier, that describes the action.
1382 #         Only makes sense in actionformats.
1383 #   %R  - base directory of the repository.
1384 #   %r  - repository name
1385 #         If %R is '/foo/bar/repoXY', %r is 'repoXY'.
1386 #   %S  - subdirectory within a repository. if $PWD is
1387 #         '/foo/bar/reposXY/beer/tasty', %S is 'beer/tasty'.
1388 #
1389 #
1390 # In branchformat these replacements are done:
1391 #   %b  - the branch name
1392 #   %r  - the current revision number
1393 #
1394 # Not all vcs backends have to support all replacements.
1395 # nvcsformat does not perform *any* replacements. It is just a string.
1396 #}}}
1397 #
1398 # ODDITIES:
1399 #{{{
1400 # If you want to use the %b (bold off) prompt expansion in 'formats', which
1401 # expands %b itself, use %%b. That will cause the vcs_info() expansion to
1402 # replace %%b with %b. So zsh's prompt expansion mechanism can handle it.
1403 # Similarly, to hand down %b from branchformat, use %%%%b. Sorry for this
1404 # inconvenience, but it cannot be easily avoided. Luckily we do not clash
1405 # with a lot of prompt expansions and this only needs to be done for those.
1406 # See 'man zshmisc' for details about EXPANSION OF PROMPT SEQUENCES.
1407 #}}}
1408 #
1409 # FUNCTION DESCRIPTIONS (public API):
1410 #{{{
1411 #   vcs_info()
1412 #       The main function, that runs all backends and assembles
1413 #       all data into ${VCS_INFO_message_*_}. This is the function
1414 #       you want to call from precmd() if you want to include
1415 #       up-to-date information in your prompt (see VARIABLE
1416 #       DESCRIPTION below).
1417 #
1418 #   vcs_info_printsys()
1419 #       Prints a list of all supported version control systems.
1420 #       Useful to find out possible contexts (and which of them are enabled)
1421 #       or values for the 'disable' style.
1422 #
1423 #   vcs_info_lastmsg()
1424 #       Outputs the last ${VCS_INFO_message_*_} value. Takes into account
1425 #       the value of the use-prompt-escapes style in ':vcs_info:formats'.
1426 #       It also only prints max-exports values.
1427 #
1428 # All functions named VCS_INFO_* are for internal use only.
1429 #}}}
1430 #
1431 # VARIABLE DESCRIPTION:
1432 #{{{
1433 #   ${VCS_INFO_message_N_}    (Note the trailing underscore)
1434 #       Where 'N' is an integer, eg: VCS_INFO_message_0_
1435 #       These variables are the storage for the informational message the
1436 #       last vcs_info() call has assembled. These are strongly connected
1437 #       to the formats, actionformats and nvcsformats styles described
1438 #       above. Those styles are lists. the first member of that list gets
1439 #       expanded into ${VCS_INFO_message_0_}, the second into
1440 #       ${VCS_INFO_message_1_} and the Nth into ${VCS_INFO_message_N-1_}.
1441 #       These parameters are exported into the environment.
1442 #       (See the max-exports style above.)
1443 #}}}
1444 #
1445 # EXAMPLES:
1446 #{{{
1447 #   Don't use vcs_info at all (even though it's in your prompt):
1448 #   % zstyle ':vcs_info:*' enable false
1449 #
1450 #   Disable the backends for bzr and svk:
1451 #   % zstyle ':vcs_info:*' disable bzr svk
1452 #
1453 #   Provide a special formats for git:
1454 #   % zstyle ':vcs_info:git:*' formats       ' GIT, BABY! [%b]'
1455 #   % zstyle ':vcs_info:git:*' actionformats ' GIT ACTION! [%b|%a]'
1456 #
1457 #   Use the quicker bzr backend (if you do, please report if it does
1458 #   the-right-thing[tm] - thanks):
1459 #   % zstyle ':vcs_info:bzr:*' use-simple true
1460 #
1461 #   Display the revision number in yellow for bzr and svn:
1462 #   % zstyle ':vcs_info:(svn|bzr):*' branchformat '%b%{'${fg[yellow]}'%}:%r'
1463 #
1464 # If you want colors, make sure you enclose the color codes in %{...%},
1465 # if you want to use the string provided by vcs_info() in prompts.
1466 #
1467 # Here is how to print the vcs infomation as a command:
1468 #   % alias vcsi='vcs_info command; vcs_info_lastmsg'
1469 #
1470 #   This way, you can even define different formats for output via
1471 #   vcs_info_lastmsg() in the ':vcs_info:command:*' namespace.
1472 #}}}
1473 #}}}
1474 # utilities
1475 VCS_INFO_adjust () { #{{{
1476     [[ -n ${vcs_comm[overwrite_name]} ]] && vcs=${vcs_comm[overwrite_name]}
1477     return 0
1478 }
1479 # }}}
1480 VCS_INFO_check_com () { #{{{
1481     (( ${+commands[$1]} )) && [[ -x ${commands[$1]} ]] && return 0
1482     return 1
1483 }
1484 # }}}
1485 VCS_INFO_formats () { # {{{
1486     setopt localoptions noksharrays
1487     local action=$1 branch=$2 base=$3
1488     local msg
1489     local -i i
1490
1491     if [[ -n ${action} ]] ; then
1492         zstyle -a ":vcs_info:${vcs}:${usercontext}" actionformats msgs
1493         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b|%a]-'
1494     else
1495         zstyle -a ":vcs_info:${vcs}:${usercontext}" formats msgs
1496         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b]-'
1497     fi
1498
1499     (( ${#msgs} > maxexports )) && msgs[$(( maxexports + 1 )),-1]=()
1500     for i in {1..${#msgs}} ; do
1501         zformat -f msg ${msgs[$i]}                      \
1502                         a:${action}                     \
1503                         b:${branch}                     \
1504                         r:${base:t}                     \
1505                         s:${vcs}                        \
1506                         R:${base}                       \
1507                         S:"$(VCS_INFO_reposub ${base})"
1508         msgs[$i]=${msg}
1509     done
1510     return 0
1511 }
1512 # }}}
1513 VCS_INFO_maxexports () { #{{{
1514     zstyle -s ":vcs_info:${vcs}:${usercontext}" "max-exports" maxexports || maxexports=2
1515     if [[ ${maxexports} != <-> ]] || (( maxexports < 1 )); then
1516         printf 'vcs_info(): expecting numeric arg >= 1 for max-exports (got %s).\n' ${maxexports}
1517         printf 'Defaulting to 2.\n'
1518         maxexports=2
1519     fi
1520 }
1521 # }}}
1522 VCS_INFO_nvcsformats () { #{{{
1523     setopt localoptions noksharrays
1524     local c v
1525
1526     if [[ $1 == 'preinit' ]] ; then
1527         c=default
1528         v=preinit
1529     fi
1530     zstyle -a ":vcs_info:${v:-$vcs}:${c:-$usercontext}" nvcsformats msgs
1531     (( ${#msgs} > maxexports )) && msgs[${maxexports},-1]=()
1532 }
1533 # }}}
1534 VCS_INFO_realpath () { #{{{
1535     # a portable 'readlink -f'
1536     # forcing a subshell, to ensure chpwd() is not removed
1537     # from the calling shell (if VCS_INFO_realpath() is called
1538     # manually).
1539     (
1540         (( ${+functions[chpwd]} )) && unfunction chpwd
1541         setopt chaselinks
1542         cd $1 2>/dev/null && pwd
1543     )
1544 }
1545 # }}}
1546 VCS_INFO_reposub () { #{{{
1547     setopt localoptions extendedglob
1548     local base=${1%%/##}
1549
1550     [[ ${PWD} == ${base}/* ]] || {
1551         printf '.'
1552         return 1
1553     }
1554     printf '%s' ${PWD#$base/}
1555     return 0
1556 }
1557 # }}}
1558 VCS_INFO_set () { #{{{
1559     setopt localoptions noksharrays
1560     local -i i j
1561
1562     if [[ $1 == '--clear' ]] ; then
1563         for i in {0..9} ; do
1564             unset VCS_INFO_message_${i}_
1565         done
1566     fi
1567     if [[ $1 == '--nvcs' ]] ; then
1568         [[ $2 == 'preinit' ]] && (( maxexports == 0 )) && (( maxexports = 1 ))
1569         for i in {0..$((maxexports - 1))} ; do
1570             typeset -gx VCS_INFO_message_${i}_=
1571         done
1572         VCS_INFO_nvcsformats $2
1573     fi
1574
1575     (( ${#msgs} - 1 < 0 )) && return 0
1576     for i in {0..$(( ${#msgs} - 1 ))} ; do
1577         (( j = i + 1 ))
1578         typeset -gx VCS_INFO_message_${i}_=${msgs[$j]}
1579     done
1580     return 0
1581 }
1582 # }}}
1583 # information gathering
1584 VCS_INFO_bzr_get_data () { # {{{
1585     setopt localoptions noksharrays
1586     local bzrbase bzrbr
1587     local -a bzrinfo
1588
1589     if zstyle -t ":vcs_info:${vcs}:${usercontext}" "use-simple" ; then
1590         bzrbase=${vcs_comm[basedir]}
1591         bzrinfo[2]=${bzrbase:t}
1592         if [[ -f ${bzrbase}/.bzr/branch/last-revision ]] ; then
1593             bzrinfo[1]=$(< ${bzrbase}/.bzr/branch/last-revision)
1594             bzrinfo[1]=${${bzrinfo[1]}%% *}
1595         fi
1596     else
1597         bzrbase=${${(M)${(f)"$( bzr info )"}:# ##branch\ root:*}/*: ##/}
1598         bzrinfo=( ${${${(M)${(f)"$( bzr version-info )"}:#(#s)(revno|branch-nick)*}/*: /}/*\//} )
1599         bzrbase="$(VCS_INFO_realpath ${bzrbase})"
1600     fi
1601
1602     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat bzrbr || bzrbr="%b:%r"
1603     zformat -f bzrbr "${bzrbr}" "b:${bzrinfo[2]}" "r:${bzrinfo[1]}"
1604     VCS_INFO_formats '' "${bzrbr}" "${bzrbase}"
1605     return 0
1606 }
1607 # }}}
1608 VCS_INFO_cdv_get_data () { # {{{
1609     local cdvbase
1610
1611     cdvbase=${vcs_comm[basedir]}
1612     VCS_INFO_formats '' "${cdvbase:t}" "${cdvbase}"
1613     return 0
1614 }
1615 # }}}
1616 VCS_INFO_cvs_get_data () { # {{{
1617     local cvsbranch cvsbase basename
1618
1619     cvsbase="."
1620     while [[ -d "${cvsbase}/../CVS" ]]; do
1621         cvsbase="${cvsbase}/.."
1622     done
1623     cvsbase="$(VCS_INFO_realpath ${cvsbase})"
1624     cvsbranch=$(< ./CVS/Repository)
1625     basename=${cvsbase:t}
1626     cvsbranch=${cvsbranch##${basename}/}
1627     [[ -z ${cvsbranch} ]] && cvsbranch=${basename}
1628     VCS_INFO_formats '' "${cvsbranch}" "${cvsbase}"
1629     return 0
1630 }
1631 # }}}
1632 VCS_INFO_darcs_get_data () { # {{{
1633     local darcsbase
1634
1635     darcsbase=${vcs_comm[basedir]}
1636     VCS_INFO_formats '' "${darcsbase:t}" "${darcsbase}"
1637     return 0
1638 }
1639 # }}}
1640 VCS_INFO_git_getaction () { #{{{
1641     local gitaction='' gitdir=$1
1642     local tmp
1643
1644     for tmp in "${gitdir}/rebase-apply" \
1645                "${gitdir}/rebase"       \
1646                "${gitdir}/../.dotest" ; do
1647         if [[ -d ${tmp} ]] ; then
1648             if   [[ -f "${tmp}/rebasing" ]] ; then
1649                 gitaction="rebase"
1650             elif [[ -f "${tmp}/applying" ]] ; then
1651                 gitaction="am"
1652             else
1653                 gitaction="am/rebase"
1654             fi
1655             printf '%s' ${gitaction}
1656             return 0
1657         fi
1658     done
1659
1660     for tmp in "${gitdir}/rebase-merge/interactive" \
1661                "${gitdir}/.dotest-merge/interactive" ; do
1662         if [[ -f "${tmp}" ]] ; then
1663             printf '%s' "rebase-i"
1664             return 0
1665         fi
1666     done
1667
1668     for tmp in "${gitdir}/rebase-merge" \
1669                "${gitdir}/.dotest-merge" ; do
1670         if [[ -d "${tmp}" ]] ; then
1671             printf '%s' "rebase-m"
1672             return 0
1673         fi
1674     done
1675
1676     if [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1677         printf '%s' "merge"
1678         return 0
1679     fi
1680
1681     if [[ -f "${gitdir}/BISECT_LOG" ]] ; then
1682         printf '%s' "bisect"
1683         return 0
1684     fi
1685     return 1
1686 }
1687 # }}}
1688 VCS_INFO_git_getbranch () { #{{{
1689     local gitbranch gitdir=$1 tmp actiondir
1690     local gitsymref='git symbolic-ref HEAD'
1691
1692     actiondir=''
1693     for tmp in "${gitdir}/rebase-apply" \
1694                "${gitdir}/rebase"       \
1695                "${gitdir}/../.dotest"; do
1696         if [[ -d ${tmp} ]]; then
1697             actiondir=${tmp}
1698             break
1699         fi
1700     done
1701     if [[ -n ${actiondir} ]]; then
1702         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1703         [[ -z ${gitbranch} ]] && [[ -r ${actiondir}/head-name ]] \
1704             && gitbranch="$(< ${actiondir}/head-name)"
1705
1706     elif [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1707         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1708         [[ -z ${gitbranch} ]] && gitbranch="$(< ${gitdir}/MERGE_HEAD)"
1709
1710     elif [[ -d "${gitdir}/rebase-merge" ]] ; then
1711         gitbranch="$(< ${gitdir}/rebase-merge/head-name)"
1712
1713     elif [[ -d "${gitdir}/.dotest-merge" ]] ; then
1714         gitbranch="$(< ${gitdir}/.dotest-merge/head-name)"
1715
1716     else
1717         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1718
1719         if [[ $? -ne 0 ]] ; then
1720             gitbranch="refs/tags/$(git describe --exact-match HEAD 2>/dev/null)"
1721
1722             if [[ $? -ne 0 ]] ; then
1723                 gitbranch="${${"$(< $gitdir/HEAD)"}[1,7]}..."
1724             fi
1725         fi
1726     fi
1727
1728     printf '%s' "${gitbranch##refs/[^/]##/}"
1729     return 0
1730 }
1731 # }}}
1732 VCS_INFO_git_get_data () { # {{{
1733     setopt localoptions extendedglob
1734     local gitdir gitbase gitbranch gitaction
1735
1736     gitdir=${vcs_comm[gitdir]}
1737     gitbranch="$(VCS_INFO_git_getbranch ${gitdir})"
1738
1739     if [[ -z ${gitdir} ]] || [[ -z ${gitbranch} ]] ; then
1740         return 1
1741     fi
1742
1743     VCS_INFO_adjust
1744     gitaction="$(VCS_INFO_git_getaction ${gitdir})"
1745     gitbase=${PWD%/${$( git rev-parse --show-prefix )%/##}}
1746     VCS_INFO_formats "${gitaction}" "${gitbranch}" "${gitbase}"
1747     return 0
1748 }
1749 # }}}
1750 VCS_INFO_hg_get_data () { # {{{
1751     local hgbranch hgbase file
1752
1753     hgbase=${vcs_comm[basedir]}
1754
1755     file="${hgbase}/.hg/branch"
1756     if [[ -r ${file} ]] ; then
1757         hgbranch=$(< ${file})
1758     else
1759         hgbranch='default'
1760     fi
1761
1762     VCS_INFO_formats '' "${hgbranch}" "${hgbase}"
1763     return 0
1764 }
1765 # }}}
1766 VCS_INFO_mtn_get_data () { # {{{
1767     local mtnbranch mtnbase
1768
1769     mtnbase=${vcs_comm[basedir]}
1770     mtnbranch=${${(M)${(f)"$( mtn status )"}:#(#s)Current branch:*}/*: /}
1771     VCS_INFO_formats '' "${mtnbranch}" "${mtnbase}"
1772     return 0
1773 }
1774 # }}}
1775 VCS_INFO_svk_get_data () { # {{{
1776     local svkbranch svkbase
1777
1778     svkbase=${vcs_comm[basedir]}
1779     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svkbranch || svkbranch="%b:%r"
1780     zformat -f svkbranch "${svkbranch}" "b:${vcs_comm[branch]}" "r:${vcs_comm[revision]}"
1781     VCS_INFO_formats '' "${svkbranch}" "${svkbase}"
1782     return 0
1783 }
1784 # }}}
1785 VCS_INFO_svn_get_data () { # {{{
1786     setopt localoptions noksharrays
1787     local svnbase svnbranch
1788     local -a svninfo
1789
1790     svnbase="."
1791     while [[ -d "${svnbase}/../.svn" ]]; do
1792         svnbase="${svnbase}/.."
1793     done
1794     svnbase="$(VCS_INFO_realpath ${svnbase})"
1795     svninfo=( ${${${(M)${(f)"$( svn info )"}:#(#s)(URL|Revision)*}/*: /}/*\//} )
1796
1797     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svnbranch || svnbranch="%b:%r"
1798     zformat -f svnbranch "${svnbranch}" "b:${svninfo[1]}" "r:${svninfo[2]}"
1799     VCS_INFO_formats '' "${svnbranch}" "${svnbase}"
1800     return 0
1801 }
1802 # }}}
1803 VCS_INFO_tla_get_data () { # {{{
1804     local tlabase tlabranch
1805
1806     tlabase="$(VCS_INFO_realpath ${vcs_comm[basedir]})"
1807     # tree-id gives us something like 'foo@example.com/demo--1.0--patch-4', so:
1808     tlabranch=${${"$( tla tree-id )"}/*\//}
1809     VCS_INFO_formats '' "${tlabranch}" "${tlabase}"
1810     return 0
1811 }
1812 # }}}
1813 # detection
1814 VCS_INFO_detect_by_dir() { #{{{
1815     local dirname=$1
1816     local basedir="." realbasedir
1817
1818     realbasedir="$(VCS_INFO_realpath ${basedir})"
1819     while [[ ${realbasedir} != '/' ]]; do
1820         [[ -r ${realbasedir} ]] || return 1
1821         if [[ -n ${vcs_comm[detect_need_file]} ]] ; then
1822             [[ -d ${basedir}/${dirname} ]] && \
1823             [[ -e ${basedir}/${dirname}/${vcs_comm[detect_need_file]} ]] && \
1824                 break
1825         else
1826             [[ -d ${basedir}/${dirname} ]] && break
1827         fi
1828
1829         basedir=${basedir}/..
1830         realbasedir="$(VCS_INFO_realpath ${basedir})"
1831     done
1832
1833     [[ ${realbasedir} == "/" ]] && return 1
1834     vcs_comm[basedir]=${realbasedir}
1835     return 0
1836 }
1837 # }}}
1838 VCS_INFO_bzr_detect() { #{{{
1839     VCS_INFO_check_com bzr || return 1
1840     vcs_comm[detect_need_file]=branch/format
1841     VCS_INFO_detect_by_dir '.bzr'
1842     return $?
1843 }
1844 # }}}
1845 VCS_INFO_cdv_detect() { #{{{
1846     VCS_INFO_check_com cdv || return 1
1847     vcs_comm[detect_need_file]=format
1848     VCS_INFO_detect_by_dir '.cdv'
1849     return $?
1850 }
1851 # }}}
1852 VCS_INFO_cvs_detect() { #{{{
1853     VCS_INFO_check_com cvs || return 1
1854     [[ -d "./CVS" ]] && [[ -r "./CVS/Repository" ]] && return 0
1855     return 1
1856 }
1857 # }}}
1858 VCS_INFO_darcs_detect() { #{{{
1859     VCS_INFO_check_com darcs || return 1
1860     vcs_comm[detect_need_file]=format
1861     VCS_INFO_detect_by_dir '_darcs'
1862     return $?
1863 }
1864 # }}}
1865 VCS_INFO_git_detect() { #{{{
1866     if VCS_INFO_check_com git && git rev-parse --is-inside-work-tree &> /dev/null ; then
1867         vcs_comm[gitdir]="$(git rev-parse --git-dir 2> /dev/null)" || return 1
1868         if   [[ -d ${vcs_comm[gitdir]}/svn ]]             ; then vcs_comm[overwrite_name]='git-svn'
1869         elif [[ -d ${vcs_comm[gitdir]}/refs/remotes/p4 ]] ; then vcs_comm[overwrite_name]='git-p4' ; fi
1870         return 0
1871     fi
1872     return 1
1873 }
1874 # }}}
1875 VCS_INFO_hg_detect() { #{{{
1876     VCS_INFO_check_com hg || return 1
1877     vcs_comm[detect_need_file]=store
1878     VCS_INFO_detect_by_dir '.hg'
1879     return $?
1880 }
1881 # }}}
1882 VCS_INFO_mtn_detect() { #{{{
1883     VCS_INFO_check_com mtn || return 1
1884     vcs_comm[detect_need_file]=revision
1885     VCS_INFO_detect_by_dir '_MTN'
1886     return $?
1887 }
1888 # }}}
1889 VCS_INFO_svk_detect() { #{{{
1890     setopt localoptions noksharrays extendedglob
1891     local -a info
1892     local -i fhash
1893     fhash=0
1894
1895     VCS_INFO_check_com svk || return 1
1896     [[ -f ~/.svk/config ]] || return 1
1897
1898     # This detection function is a bit different from the others.
1899     # We need to read svk's config file to detect a svk repository
1900     # in the first place. Therefore, we'll just proceed and read
1901     # the other information, too. This is more then any of the
1902     # other detections do but this takes only one file open for
1903     # svk at most. VCS_INFO_svk_get_data() get simpler, too. :-)
1904     while IFS= read -r line ; do
1905         if [[ -n ${vcs_comm[basedir]} ]] ; then
1906             line=${line## ##}
1907             [[ ${line} == depotpath:* ]] && vcs_comm[branch]=${line##*/}
1908             [[ ${line} == revision:* ]] && vcs_comm[revision]=${line##*[[:space:]]##}
1909             [[ -n ${vcs_comm[branch]} ]] && [[ -n ${vcs_comm[revision]} ]] && break
1910             continue
1911         fi
1912         (( fhash > 0 )) && [[ ${line} == '  '[^[:space:]]*:* ]] && break
1913         [[ ${line} == '  hash:'* ]] && fhash=1 && continue
1914         (( fhash == 0 )) && continue
1915         [[ ${PWD}/ == ${${line## ##}%:*}/* ]] && vcs_comm[basedir]=${${line## ##}%:*}
1916     done < ~/.svk/config
1917
1918     [[ -n ${vcs_comm[basedir]} ]]  && \
1919     [[ -n ${vcs_comm[branch]} ]]   && \
1920     [[ -n ${vcs_comm[revision]} ]] && return 0
1921     return 1
1922 }
1923 # }}}
1924 VCS_INFO_svn_detect() { #{{{
1925     VCS_INFO_check_com svn || return 1
1926     [[ -d ".svn" ]] && return 0
1927     return 1
1928 }
1929 # }}}
1930 VCS_INFO_tla_detect() { #{{{
1931     VCS_INFO_check_com tla || return 1
1932     vcs_comm[basedir]="$(tla tree-root 2> /dev/null)" && return 0
1933     return 1
1934 }
1935 # }}}
1936 # public API
1937 vcs_info_printsys () { # {{{
1938     vcs_info print_systems_
1939 }
1940 # }}}
1941 vcs_info_lastmsg () { # {{{
1942     emulate -L zsh
1943     local -i i
1944
1945     VCS_INFO_maxexports
1946     for i in {0..$((maxexports - 1))} ; do
1947         printf '$VCS_INFO_message_%d_: "' $i
1948         if zstyle -T ':vcs_info:formats:command' use-prompt-escapes ; then
1949             print -nP ${(P)${:-VCS_INFO_message_${i}_}}
1950         else
1951             print -n ${(P)${:-VCS_INFO_message_${i}_}}
1952         fi
1953         printf '"\n'
1954     done
1955 }
1956 # }}}
1957 vcs_info () { # {{{
1958     emulate -L zsh
1959     setopt extendedglob
1960
1961     [[ -r . ]] || return 1
1962
1963     local pat
1964     local -i found
1965     local -a VCSs disabled dps
1966     local -x vcs usercontext
1967     local -ix maxexports
1968     local -ax msgs
1969     local -Ax vcs_comm
1970
1971     vcs="init"
1972     VCSs=(git hg bzr darcs svk mtn svn cvs cdv tla)
1973     case $1 in
1974         (print_systems_)
1975             zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1976             print -l '# list of supported version control backends:' \
1977                      '# disabled systems are prefixed by a hash sign (#)'
1978             for vcs in ${VCSs} ; do
1979                 [[ -n ${(M)disabled:#${vcs}} ]] && printf '#'
1980                 printf '%s\n' ${vcs}
1981             done
1982             print -l '# flavours (cannot be used in the disable style; they' \
1983                      '# are disabled with their master [git-svn -> git]):'   \
1984                      git-{p4,svn}
1985             return 0
1986             ;;
1987         ('')
1988             [[ -z ${usercontext} ]] && usercontext=default
1989             ;;
1990         (*) [[ -z ${usercontext} ]] && usercontext=$1
1991             ;;
1992     esac
1993
1994     zstyle -T ":vcs_info:${vcs}:${usercontext}" "enable" || {
1995         [[ -n ${VCS_INFO_message_0_} ]] && VCS_INFO_set --clear
1996         return 0
1997     }
1998     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1999
2000     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable-patterns" dps
2001     for pat in ${dps} ; do
2002         if [[ ${PWD} == ${~pat} ]] ; then
2003             [[ -n ${vcs_info_msg_0_} ]] && VCS_INFO_set --clear
2004             return 0
2005         fi
2006     done
2007
2008     VCS_INFO_maxexports
2009
2010     (( found = 0 ))
2011     for vcs in ${VCSs} ; do
2012         [[ -n ${(M)disabled:#${vcs}} ]] && continue
2013         vcs_comm=()
2014         VCS_INFO_${vcs}_detect && (( found = 1 )) && break
2015     done
2016
2017     (( found == 0 )) && {
2018         VCS_INFO_set --nvcs
2019         return 0
2020     }
2021
2022     VCS_INFO_${vcs}_get_data || {
2023         VCS_INFO_set --nvcs
2024         return 1
2025     }
2026
2027     VCS_INFO_set
2028     return 0
2029 }
2030
2031 VCS_INFO_set --nvcs preinit
2032 # }}}
2033
2034 fi
2035
2036 # Change vcs_info formats for the grml prompt. The 2nd format sets up
2037 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
2038 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
2039 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
2040 #       to $vcs_info_msg_N_ as soon as we use the included version.
2041 if [[ "$TERM" == dumb ]] ; then
2042     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
2043     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
2044 else
2045     # these are the same, just with a lot of colours:
2046     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
2047                                        "zsh: %r"
2048     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
2049                                        "zsh: %r"
2050     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
2051 fi
2052
2053 if [[ -o restricted ]]; then
2054     zstyle ':vcs_info:*' enable false
2055 fi
2056
2057 # }}}
2058
2059 # command not found handling {{{
2060
2061 (( ${COMMAND_NOT_FOUND} == 1 )) &&
2062 function command_not_found_handler() {
2063     emulate -L zsh
2064     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
2065         ${GRML_ZSH_CNF_HANDLER} $1
2066     fi
2067     return 1
2068 }
2069
2070 # }}}
2071
2072 # {{{ set prompt
2073 if zrcautoload promptinit && promptinit 2>/dev/null ; then
2074     promptinit # people should be able to use their favourite prompt
2075 else
2076     print 'Notice: no promptinit available :('
2077 fi
2078
2079 setopt prompt_subst
2080
2081 # make sure to use right prompt only when not running a command
2082 is41 && setopt transient_rprompt
2083
2084
2085 function ESC_print () {
2086     info_print $'\ek' $'\e\\' "$@"
2087 }
2088 function set_title () {
2089     info_print  $'\e]0;' $'\a' "$@"
2090 }
2091
2092 function info_print () {
2093     local esc_begin esc_end
2094     esc_begin="$1"
2095     esc_end="$2"
2096     shift 2
2097     printf '%s' ${esc_begin}
2098     printf '%s' "$*"
2099     printf '%s' "${esc_end}"
2100 }
2101
2102 # TODO: revise all these NO* variables and especially their documentation
2103 #       in zsh-help() below.
2104 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
2105     [[ $NOPRECMD -gt 0 ]] && return 0
2106     # update VCS information
2107     vcs_info
2108
2109     if [[ $TERM == screen* ]] ; then
2110         if [[ -n ${VCS_INFO_message_1_} ]] ; then
2111             ESC_print ${VCS_INFO_message_1_}
2112         elif [[ -n ${vcs_info_msg_1_} ]] ; then
2113             ESC_print ${vcs_info_msg_1_}
2114         else
2115             ESC_print "zsh"
2116         fi
2117     fi
2118     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
2119     if [[ $DONTSETRPROMPT -eq 0 ]] ; then
2120         if [[ $BATTERY -gt 0 ]] ; then
2121             # update battery (dropped into $PERCENT) information
2122             battery
2123             RPROMPT="%(?..:() ${PERCENT}"
2124         else
2125             RPROMPT="%(?..:() "
2126         fi
2127     fi
2128     # adjust title of xterm
2129     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
2130     [[ ${NOTITLE} -gt 0 ]] && return 0
2131     case $TERM in
2132         (xterm*|rxvt*)
2133             set_title ${(%):-"%n@%m: %~"}
2134             ;;
2135     esac
2136 }
2137
2138 # preexec() => a function running before every command
2139 is4 && [[ $NOPRECMD -eq 0 ]] && \
2140 preexec () {
2141     [[ $NOPRECMD -gt 0 ]] && return 0
2142 # set hostname if not running on host with name 'grml'
2143     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
2144        NAME="@$HOSTNAME"
2145     fi
2146 # get the name of the program currently running and hostname of local machine
2147 # set screen window title if running in a screen
2148     if [[ "$TERM" == screen* ]] ; then
2149         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
2150         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
2151         ESC_print ${CMD}
2152     fi
2153 # adjust title of xterm
2154     [[ ${NOTITLE} -gt 0 ]] && return 0
2155     case $TERM in
2156         (xterm*|rxvt*)
2157             set_title "${(%):-"%n@%m:"}" "$1"
2158             ;;
2159     esac
2160 }
2161
2162 EXITCODE="%(?..%?%1v )"
2163 PS2='\`%_> '      # secondary prompt, printed when the shell needs more information to complete a command.
2164 PS3='?# '         # selection prompt used within a select loop.
2165 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
2166
2167 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
2168 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
2169     debian_chroot=$(cat /etc/debian_chroot)
2170 fi
2171
2172 # don't use colors on dumb terminals (like emacs):
2173 if [[ "$TERM" == dumb ]] ; then
2174     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
2175 else
2176     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
2177     # set variable identifying the chroot you work in (used in the prompt below)
2178     if [[ $GRMLPROMPT -gt 0 ]] ; then
2179         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
2180 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
2181     else
2182         # This assembles the primary prompt string
2183         if (( EUID != 0 )); then
2184             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
2185         else
2186             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
2187         fi
2188     fi
2189 fi
2190
2191 if (( GRML_VCS_INFO )); then
2192     PROMPT="${PROMPT}"'${VCS_INFO_message_0_}'"%# "
2193 else
2194     PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
2195 fi
2196
2197 # if we are inside a grml-chroot set a specific prompt theme
2198 if [[ -n "$GRML_CHROOT" ]] ; then
2199     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
2200 fi
2201 # }}}
2202
2203 # {{{ 'hash' some often used directories
2204 #d# start
2205 hash -d deb=/var/cache/apt/archives
2206 hash -d doc=/usr/share/doc
2207 hash -d linux=/lib/modules/$(command uname -r)/build/
2208 hash -d log=/var/log
2209 hash -d slog=/var/log/syslog
2210 hash -d src=/usr/src
2211 hash -d templ=/usr/share/doc/grml-templates
2212 hash -d tt=/usr/share/doc/texttools-doc
2213 hash -d www=/var/www
2214 #d# end
2215 # }}}
2216
2217 # {{{ some aliases
2218 if check_com -c screen ; then
2219     if [[ $UID -eq 0 ]] ; then
2220         [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
2221     elif [[ -r $HOME/.screenrc ]] ; then
2222         alias screen="${commands[screen]} -c $HOME/.screenrc"
2223     else
2224         if [[ -r /etc/grml/screenrc_grml ]]; then
2225             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
2226         else
2227             [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
2228         fi
2229     fi
2230 fi
2231
2232 # do we have GNU ls with color-support?
2233 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
2234     #a1# execute \kbd{@a@}:\quad ls with colors
2235     alias ls='ls -b -CF --color=auto'
2236     #a1# execute \kbd{@a@}:\quad list all files, with colors
2237     alias la='ls -la --color=auto'
2238     #a1# long colored list, without dotfiles (@a@)
2239     alias ll='ls -l --color=auto'
2240     #a1# long colored list, human readable sizes (@a@)
2241     alias lh='ls -hAl --color=auto'
2242     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2243     alias l='ls -lF --color=auto'
2244 else
2245     alias ls='ls -b -CF'
2246     alias la='ls -la'
2247     alias ll='ls -l'
2248     alias lh='ls -hAl'
2249     alias l='ls -lF'
2250 fi
2251
2252 alias mdstat='cat /proc/mdstat'
2253 alias ...='cd ../../'
2254
2255 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2256 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2257     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2258 fi
2259
2260 alias cp='nocorrect cp'         # no spelling correction on cp
2261 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
2262 alias mv='nocorrect mv'         # no spelling correction on mv
2263 alias rm='nocorrect rm'         # no spelling correction on rm
2264
2265 #a1# Execute \kbd{rmdir}
2266 alias rd='rmdir'
2267 #a1# Execute \kbd{mkdir}
2268 alias md='mkdir'
2269
2270 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2271 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2272 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2273
2274 # make sure it is not assigned yet
2275 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
2276 utf2iso() {
2277     if isutfenv ; then
2278         for ENV in $(env | command grep -i '.utf') ; do
2279             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2280         done
2281     fi
2282 }
2283
2284 # make sure it is not assigned yet
2285 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
2286 iso2utf() {
2287     if ! isutfenv ; then
2288         for ENV in $(env | command grep -i '\.iso') ; do
2289             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2290         done
2291     fi
2292 }
2293
2294 # set up software synthesizer via speakup
2295 swspeak() {
2296     if [ -x /usr/sbin/swspeak-setup ] ; then
2297        setopt singlelinezle
2298        unsetopt prompt_cr
2299        export PS1="%m%# "
2300        /usr/sbin/swspeak-setup $@
2301      else # old version:
2302         if ! [[ -r /dev/softsynth ]] ; then
2303             flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
2304             return 1
2305         else
2306            setopt singlelinezle
2307            unsetopt prompt_cr
2308            export PS1="%m%# "
2309             nice -n -20 speechd-up
2310             sleep 2
2311             flite -o play -t "Finished setting up software synthesizer"
2312         fi
2313      fi
2314 }
2315
2316 # I like clean prompt, so provide simple way to get that
2317 check_com 0 || alias 0='return 0'
2318
2319 # for really lazy people like mika:
2320 check_com S &>/dev/null || alias S='screen'
2321 check_com s &>/dev/null || alias s='ssh'
2322
2323 # especially for roadwarriors using GNU screen and ssh:
2324 if ! check_com asc &>/dev/null ; then
2325   asc() { autossh -t "$@" 'screen -RdU' }
2326   compdef asc=ssh
2327 fi
2328
2329 # get top 10 shell commands:
2330 alias top10='print -l ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
2331
2332 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
2333 if check_com -c truecrypt ; then
2334     if isutfenv ; then
2335         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
2336     else
2337         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
2338     fi
2339 fi
2340
2341 #f1# Hints for the use of zsh on grml
2342 zsh-help() {
2343     print "$bg[white]$fg[black]
2344 zsh-help - hints for use of zsh on grml
2345 =======================================$reset_color"
2346
2347     print '
2348 Main configuration of zsh happens in /etc/zsh/zshrc.
2349 That file is part of the package grml-etc-core, if you want to
2350 use them on a non-grml-system just get the tar.gz from
2351 http://deb.grml.org/ or (preferably) get it from the git repository:
2352
2353   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2354
2355 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2356 The file is still there, but it is empty for backwards compatibility.
2357
2358 For your own changes use these two files:
2359     $HOME/.zshrc.pre
2360     $HOME/.zshrc.local
2361
2362 The former is sourced very early in our zshrc, the latter is sourced
2363 very lately.
2364
2365 System wide configuration without touching configuration files of grml
2366 can take place in /etc/zsh/zshrc.local.
2367
2368 Normally, the root user (EUID == 0) does not get the whole grml setup.
2369 If you want to force the whole setup for that user, too, set
2370 GRML_ALWAYS_LOAD_ALL=1 in .zshrc.pre in root'\''s home directory.
2371
2372 For information regarding zsh start at http://grml.org/zsh/
2373
2374 Take a look at grml'\''s zsh refcard:
2375 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2376
2377 Check out the main zsh refcard:
2378 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2379
2380 And of course visit the zsh-lovers:
2381 % man zsh-lovers
2382
2383 You can adjust some options through environment variables when
2384 invoking zsh without having to edit configuration files.
2385 Basically meant for bash users who are not used to the power of
2386 the zsh yet. :)
2387
2388   "NOCOR=1    zsh" => deactivate automatic correction
2389   "NOMENU=1   zsh" => do not use auto menu completion (note: use ctrl-d for completion instead!)
2390   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2391   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2392                       preexec() and precmd() completely
2393   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
2394   "COMMAND_NOT_FOUND=1 zsh"
2395                    => Enable a handler if an external command was not found
2396                       The command called in the handler can be altered by setting
2397                       the GRML_ZSH_CNF_HANDLER variable, the default is:
2398                       "/usr/share/command-not-found/command-not-found"
2399
2400 A value greater than 0 is enables a feature; a value equal to zero
2401 disables it. If you like one or the other of these settings, you can
2402 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2403 zshrc.'
2404
2405     print "
2406 $bg[white]$fg[black]
2407 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2408 Enjoy your grml system with the zsh!$reset_color"
2409 }
2410
2411 # debian stuff
2412 if [[ -r /etc/debian_version ]] ; then
2413     #a3# Execute \kbd{apt-cache search}
2414     alias acs='apt-cache search'
2415     #a3# Execute \kbd{apt-cache show}
2416     alias acsh='apt-cache show'
2417     #a3# Execute \kbd{apt-cache policy}
2418     alias acp='apt-cache policy'
2419     #a3# Execute \kbd{apt-get dist-upgrade}
2420     salias adg="apt-get dist-upgrade"
2421     #a3# Execute \kbd{apt-get install}
2422     salias agi="apt-get install"
2423     #a3# Execute \kbd{aptitude install}
2424     salias ati="aptitude install"
2425     #a3# Execute \kbd{apt-get upgrade}
2426     salias ag="apt-get upgrade"
2427     #a3# Execute \kbd{apt-get update}
2428     salias au="apt-get update"
2429     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2430     salias -a up="aptitude update ; aptitude safe-upgrade"
2431     #a3# Execute \kbd{dpkg-buildpackage}
2432     alias dbp='dpkg-buildpackage'
2433     #a3# Execute \kbd{grep-excuses}
2434     alias ge='grep-excuses'
2435
2436     # debian upgrade
2437     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
2438     upgrade() {
2439         emulate -L zsh
2440         if [[ -z $1 ]] ; then
2441             $SUDO apt-get update
2442             $SUDO apt-get -u upgrade
2443         else
2444             ssh $1 $SUDO apt-get update
2445             # ask before the upgrade
2446             local dummy
2447             ssh $1 $SUDO apt-get --no-act upgrade
2448             echo -n 'Process the upgrade?'
2449             read -q dummy
2450             if [[ $dummy == "y" ]] ; then
2451                 ssh $1 $SUDO apt-get -u upgrade --yes
2452             fi
2453         fi
2454     }
2455
2456     # get a root shell as normal user in live-cd mode:
2457     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2458        alias su="sudo su"
2459      fi
2460
2461     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2462     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2463     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2464     salias tlog="tail -f /var/log/syslog"    # follow the syslog
2465 fi
2466
2467 # sort installed Debian-packages by size
2468 if check_com -c grep-status ; then
2469     #a3# List installed Debian-packages sorted by size
2470     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
2471 fi
2472
2473 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2474 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
2475     if check_com -c wodim; then
2476         cdrecord() {
2477             cat <<EOMESS
2478 cdrecord is not provided under its original name by Debian anymore.
2479 See #377109 in the BTS of Debian for more details.
2480
2481 Please use the wodim binary instead
2482 EOMESS
2483             return 1
2484         }
2485     fi
2486 fi
2487
2488 # get_tw_cli has been renamed into get_3ware
2489 if check_com -c get_3ware ; then
2490     get_tw_cli() {
2491         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
2492         get_3ware
2493     }
2494 fi
2495
2496 # I hate lacking backward compatibility, so provide an alternative therefore
2497 if ! check_com -c apache2-ssl-certificate ; then
2498
2499     apache2-ssl-certificate() {
2500
2501     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
2502     print 'You might want to take a look at Debian the package ssl-cert as well.'
2503     print 'To generate a certificate for use with apache2 follow the instructions:'
2504
2505     echo '
2506
2507 export RANDFILE=/dev/random
2508 mkdir /etc/apache2/ssl/
2509 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
2510 chmod 600 /etc/apache2/ssl/apache.pem
2511
2512 Run "grml-tips ssl-certificate" if you need further instructions.
2513 '
2514     }
2515 fi
2516 # }}}
2517
2518 # {{{ Use hard limits, except for a smaller stack and no core dumps
2519 unlimit
2520 is425 && limit stack 8192
2521 isgrmlcd && limit core 0 # important for a live-cd-system
2522 limit -s
2523 # }}}
2524
2525 # {{{ completion system
2526
2527 # called later (via is4 && grmlcomp)
2528 # note: use 'zstyle' for getting current settings
2529 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
2530 grmlcomp() {
2531     # TODO: This could use some additional information
2532
2533     # allow one error for every three characters typed in approximate completer
2534     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
2535
2536     # don't complete backup files as executables
2537     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
2538
2539     # start menu completion only if it could find no unambiguous initial string
2540     zstyle ':completion:*:correct:*'       insert-unambiguous true
2541     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
2542     zstyle ':completion:*:correct:*'       original true
2543
2544     # activate color-completion
2545     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
2546
2547     # format on completion
2548     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
2549
2550     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
2551     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
2552
2553     # insert all expansions for expand completer
2554     zstyle ':completion:*:expand:*'        tag-order all-expansions
2555     zstyle ':completion:*:history-words'   list false
2556
2557     # activate menu
2558     zstyle ':completion:*:history-words'   menu yes
2559
2560     # ignore duplicate entries
2561     zstyle ':completion:*:history-words'   remove-all-dups yes
2562     zstyle ':completion:*:history-words'   stop yes
2563
2564     # match uppercase from lowercase
2565     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
2566
2567     # separate matches into groups
2568     zstyle ':completion:*:matches'         group 'yes'
2569     zstyle ':completion:*'                 group-name ''
2570
2571     if [[ "$NOMENU" -eq 0 ]] ; then
2572         # if there are more than 5 options allow selecting from a menu
2573         zstyle ':completion:*'               menu select=5
2574     else
2575         # don't use any menus at all
2576         setopt no_auto_menu
2577     fi
2578
2579     zstyle ':completion:*:messages'        format '%d'
2580     zstyle ':completion:*:options'         auto-description '%d'
2581
2582     # describe options in full
2583     zstyle ':completion:*:options'         description 'yes'
2584
2585     # on processes completion complete all user processes
2586     zstyle ':completion:*:processes'       command 'ps -au$USER'
2587
2588     # offer indexes before parameters in subscripts
2589     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
2590
2591     # provide verbose completion information
2592     zstyle ':completion:*'                 verbose true
2593
2594     # recent (as of Dec 2007) zsh versions are able to provide descriptions
2595     # for commands (read: 1st word in the line) that it will list for the user
2596     # to choose from. The following disables that, because it's not exactly fast.
2597     zstyle ':completion:*:-command-:*:'    verbose false
2598
2599     # set format for warnings
2600     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
2601
2602     # define files to ignore for zcompile
2603     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
2604     zstyle ':completion:correct:'          prompt 'correct to: %e'
2605
2606     # Ignore completion functions for commands you don't have:
2607     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
2608
2609     # Provide more processes in completion of programs like killall:
2610     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
2611
2612     # complete manual by their section
2613     zstyle ':completion:*:manuals'    separate-sections true
2614     zstyle ':completion:*:manuals.*'  insert-sections   true
2615     zstyle ':completion:*:man:*'      menu yes select
2616
2617     # provide .. as a completion
2618     zstyle ':completion:*' special-dirs ..
2619
2620     # run rehash on completion so new installed program are found automatically:
2621     _force_rehash() {
2622         (( CURRENT == 1 )) && rehash
2623         return 1
2624     }
2625
2626     ## correction
2627     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
2628     if [[ "$NOCOR" -gt 0 ]] ; then
2629         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
2630         setopt nocorrect
2631     else
2632         # try to be smart about when to use what completer...
2633         setopt correct
2634         zstyle -e ':completion:*' completer '
2635             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
2636                 _last_try="$HISTNO$BUFFER$CURSOR"
2637                 reply=(_complete _match _ignored _prefix _files)
2638             else
2639                 if [[ $words[1] == (rm|mv) ]] ; then
2640                     reply=(_complete _files)
2641                 else
2642                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
2643                 fi
2644             fi'
2645     fi
2646
2647     # command for process lists, the local web server details and host completion
2648     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
2649
2650     # caching
2651     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
2652                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
2653
2654     # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
2655     if is42 ; then
2656         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
2657         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
2658     else
2659         _ssh_hosts=()
2660         _etc_hosts=()
2661     fi
2662     hosts=(
2663         $(hostname)
2664         "$_ssh_hosts[@]"
2665         "$_etc_hosts[@]"
2666         grml.org
2667         localhost
2668     )
2669     zstyle ':completion:*:hosts' hosts $hosts
2670     # TODO: so, why is this here?
2671     #  zstyle '*' hosts $hosts
2672
2673     # use generic completion system for programs not yet defined; (_gnu_generic works
2674     # with commands that provide a --help option with "standard" gnu-like output.)
2675     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
2676                    pal stow tail uname ; do
2677         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
2678     done; unset compcom
2679
2680     # see upgrade function in this file
2681     compdef _hosts upgrade
2682 }
2683 # }}}
2684
2685 # {{{ grmlstuff
2686 grmlstuff() {
2687 # people should use 'grml-x'!
2688     if check_com -c 915resolution; then
2689         855resolution() {
2690             echo "Please use 915resolution as resolution modifying tool for Intel \
2691 graphic chipset."
2692             return -1
2693         }
2694     fi
2695
2696     #a1# Output version of running grml
2697     alias grml-version='cat /etc/grml_version'
2698
2699     if check_com -c rebuildfstab ; then
2700         #a1# Rebuild /etc/fstab
2701         alias grml-rebuildfstab='rebuildfstab -v -r -config'
2702     fi
2703
2704     if check_com -c grml-debootstrap ; then
2705         debian2hd() {
2706             echo "Installing debian to harddisk is possible by using grml-debootstrap."
2707             return 1
2708         }
2709     fi
2710 }
2711 # }}}
2712
2713 # {{{ now run the functions
2714 isgrml && checkhome
2715 is4    && isgrml    && grmlstuff
2716 is4    && grmlcomp
2717 # }}}
2718
2719 # {{{ keephack
2720 is4 && xsource "/etc/zsh/keephack"
2721 # }}}
2722
2723 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
2724 # You use it as follows:
2725 # $ NTREF=/reference/file
2726 # $ ls -l *(e:nt:)
2727 # This lists all the files in the current directory newer than the reference file.
2728 # You can also specify the reference file inline; note quotes:
2729 # $ ls -l *(e:'nt ~/.zshenv':)
2730 is4 && nt() {
2731     if [[ -n $1 ]] ; then
2732         local NTREF=${~1}
2733     fi
2734     [[ $REPLY -nt $NTREF ]]
2735 }
2736 # }}}
2737
2738 # shell functions {{{
2739
2740 #f1# Provide csh compatibility
2741 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
2742
2743 #f1# Reload an autoloadable function
2744 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2745 compdef _functions freload
2746
2747 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2748 sll() {
2749     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2750     for file in "$@" ; do
2751         while [[ -h "$file" ]] ; do
2752             ls -l $file
2753             file=$(readlink "$file")
2754         done
2755     done
2756 }
2757
2758 # fast manual access
2759 if check_com qma ; then
2760     #f1# View the zsh manual
2761     manzsh()  { qma zshall "$1" }
2762     compdef _man qma
2763 else
2764     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
2765 fi
2766
2767 # TODO: Is it supported to use pager settings like this?
2768 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2769 # with respect to wordsplitting. (ie. ${=PAGER})
2770 if check_com -c $PAGER ; then
2771     #f1# View Debian's changelog of a given package
2772     dchange() {
2773         emulate -L zsh
2774         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
2775             $PAGER /usr/share/doc/$1/changelog.Debian.gz
2776         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2777             $PAGER /usr/share/doc/$1/changelog.gz
2778         else
2779             if check_com -c aptitude ; then
2780                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2781                 if isgrml ; then
2782                     aptitude -t unstable changelog $1
2783                 else
2784                     aptitude changelog $1
2785                 fi
2786             else
2787                 echo "No changelog for package $1 found, sorry."
2788                 return 1
2789             fi
2790         fi
2791     }
2792     _dchange() { _files -W /usr/share/doc -/ }
2793     compdef _dchange dchange
2794
2795     #f1# View Debian's NEWS of a given package
2796     dnews() {
2797         emulate -L zsh
2798         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2799             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2800         else
2801             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2802                 $PAGER /usr/share/doc/$1/NEWS.gz
2803             else
2804                 echo "No NEWS file for package $1 found, sorry."
2805                 return 1
2806             fi
2807         fi
2808     }
2809     _dnews() { _files -W /usr/share/doc -/ }
2810     compdef _dnews dnews
2811
2812     #f1# View upstream's changelog of a given package
2813     uchange() {
2814         emulate -L zsh
2815         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2816             $PAGER /usr/share/doc/$1/changelog.gz
2817         else
2818             echo "No changelog for package $1 found, sorry."
2819             return 1
2820         fi
2821     }
2822     _uchange() { _files -W /usr/share/doc -/ }
2823     compdef _uchange uchange
2824 fi
2825
2826 # zsh profiling
2827 profile() {
2828     ZSH_PROFILE_RC=1 $SHELL "$@"
2829 }
2830
2831 #f1# Edit an alias via zle
2832 edalias() {
2833     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2834 }
2835 compdef _aliases edalias
2836
2837 #f1# Edit a function via zle
2838 edfunc() {
2839     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2840 }
2841 compdef _functions edfunc
2842
2843 # use it e.g. via 'Restart apache2'
2844 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2845 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2846 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2847 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2848 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2849 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2850     __start_stop() {
2851         local action_="${1:l}"  # e.g Start/Stop/Restart
2852         local service_="$2"
2853         local param_="$3"
2854
2855         local service_target_="$(readlink /etc/init.d/$service_)"
2856         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2857             # runit
2858             case "${action_}" in
2859                 start) if [[ ! -e /etc/service/$service_ ]]; then
2860                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2861                        else
2862                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2863                        fi ;;
2864                 # there is no reload in runits sysv emulation
2865                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2866                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2867             esac
2868         else
2869             # sysvinit
2870             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2871         fi
2872     }
2873
2874     for i in Start Restart Stop Force-Reload Reload ; do
2875         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2876     done
2877 fi
2878
2879 #f1# Provides useful information on globbing
2880 H-Glob() {
2881     echo -e "
2882     /      directories
2883     .      plain files
2884     @      symbolic links
2885     =      sockets
2886     p      named pipes (FIFOs)
2887     *      executable plain files (0100)
2888     %      device files (character or block special)
2889     %b     block special files
2890     %c     character special files
2891     r      owner-readable files (0400)
2892     w      owner-writable files (0200)
2893     x      owner-executable files (0100)
2894     A      group-readable files (0040)
2895     I      group-writable files (0020)
2896     E      group-executable files (0010)
2897     R      world-readable files (0004)
2898     W      world-writable files (0002)
2899     X      world-executable files (0001)
2900     s      setuid files (04000)
2901     S      setgid files (02000)
2902     t      files with the sticky bit (01000)
2903
2904   print *(m-1)          # Files modified up to a day ago
2905   print *(a1)           # Files accessed a day ago
2906   print *(@)            # Just symlinks
2907   print *(Lk+50)        # Files bigger than 50 kilobytes
2908   print *(Lk-50)        # Files smaller than 50 kilobytes
2909   print **/*.c          # All *.c files recursively starting in \$PWD
2910   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2911   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2912   print *~*.*           # All Files that do not contain a dot
2913   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2914   print -l *(.c|.h)     # Lists *.c and *.h
2915   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2916   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2917 }
2918 alias help-zshglob=H-Glob
2919
2920 check_com -c qma && alias ?='qma zshall'
2921
2922 # grep for running process, like: 'any vim'
2923 any() {
2924     emulate -L zsh
2925     unsetopt KSH_ARRAYS
2926     if [[ -z "$1" ]] ; then
2927         echo "any - grep for process(es) by keyword" >&2
2928         echo "Usage: any <keyword>" >&2 ; return 1
2929     else
2930         ps xauwww | grep --color=auto "[${1[1]}]${1[2,-1]}"
2931     fi
2932 }
2933
2934
2935 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2936 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2937 [[ -r /proc/1/maps ]] && \
2938 deswap() {
2939     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2940     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2941     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2942 }
2943
2944 # print hex value of a number
2945 hex() {
2946     emulate -L zsh
2947     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
2948 }
2949
2950 # calculate (or eval at all ;-)) with perl => p[erl-]eval
2951 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
2952 peval() {
2953     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
2954     perl -e "print eval($CALC),\"\n\";"
2955 }
2956 functions peval &>/dev/null && alias calc=peval
2957
2958 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
2959 # certain circumstances, so work around it, no matter which environment we have
2960 brltty() {
2961     if [[ -z "$DISPLAY" ]] ; then
2962         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
2963         command brltty "$@"
2964     else
2965         command brltty "$@"
2966     fi
2967 }
2968
2969 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
2970 aoeu() {
2971     echo -n 'Switching to us keyboard layout: '
2972     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
2973     echo 'Done'
2974 }
2975 asdf() {
2976     echo -n 'Switching to dvorak keyboard layout: '
2977     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
2978     echo 'Done'
2979 }
2980 # just press 'asdf' key to toggle from neon layout to us keyboard layout
2981 uiae() {
2982     echo -n 'Switching to us keyboard layout: '
2983     setxkbmap us && echo 'Done' || echo 'Failed'
2984 }
2985
2986 # set up an ipv6 tunnel
2987 ipv6-tunnel() {
2988     emulate -L zsh
2989     case $1 in
2990         start)
2991             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2992                 print 'ipv6 tunnel already set up, nothing to be done.'
2993                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
2994             else
2995                 [[ -n "$PUBLIC_IP" ]] || \
2996                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
2997                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
2998
2999                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
3000                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
3001                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
3002                 ifconfig sit0 tunnel ::192.88.99.1 up
3003                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
3004             fi
3005             ;;
3006         status)
3007             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
3008                 print 'ipv6 tunnel available' ; return 0
3009             else
3010                 print 'ipv6 tunnel not available' ; return 1
3011             fi
3012             ;;
3013         stop)
3014             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
3015                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
3016                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
3017             else
3018                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
3019             fi
3020             ;;
3021         *)
3022             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
3023             ;;
3024     esac
3025 }
3026
3027 # run dhclient for wireless device
3028 iwclient() {
3029     sudo dhclient "$(wavemon -d | awk '/device/{print $3}')"
3030 }
3031
3032 # spawn a minimally set up mksh - useful if you want to umount /usr/.
3033 minimal-shell() {
3034     emulate -L zsh
3035     local shell="/bin/mksh"
3036
3037     if [[ ! -x ${shell} ]]; then
3038         printf '`%s'\'' not available, giving up.\n' ${shell} >&2
3039         return 1
3040     fi
3041
3042     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ${shell}
3043 }
3044
3045 # a wrapper for vim, that deals with title setting
3046 #   VIM_OPTIONS
3047 #       set this array to a set of options to vim you always want
3048 #       to have set when calling vim (in .zshrc.local), like:
3049 #           VIM_OPTIONS=( -p )
3050 #       This will cause vim to send every file given on the
3051 #       commandline to be send to it's own tab (needs vim7).
3052 vim() {
3053     VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
3054 }
3055
3056 # make a backup of a file
3057 bk() {
3058     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
3059 }
3060
3061 #f1# grep for patterns in grml's zsh setup
3062 zg() {
3063 #{{{
3064     LANG=C perl -e '
3065
3066 sub usage {
3067     print "usage: zg -[anr] <pattern>\n";
3068     print " Search for patterns in grml'\''s zshrc.\n";
3069     print " zg takes no or exactly one option plus a non empty pattern.\n\n";
3070     print "   options:\n";
3071     print "     --  no options (use if your pattern starts in with a dash.\n";
3072     print "     -a  search for the pattern in all code regions\n";
3073     print "     -n  search for the pattern in non-root code only\n";
3074     print "     -r  search in code for everyone (also root) only\n\n";
3075     print "   The default is -a for non-root users and -r for root.\n\n";
3076     print " If you installed the zshrc to a non-default locations (ie *NOT*\n";
3077     print " in /etc/zsh/zshrc) do: export GRML_ZSHRC=\$HOME/.zshrc\n";
3078     print " ...in case you copied the file to that location.\n\n";
3079     exit 1;
3080 }
3081
3082 if ($ENV{GRML_ZSHRC} ne "") {
3083     $RC = $ENV{GRML_ZSHRC};
3084 } else {
3085     $RC = "/etc/zsh/zshrc";
3086 }
3087
3088 usage if ($#ARGV < 0 || $#ARGV > 1);
3089 if ($> == 0) { $mode = "allonly"; }
3090 else { $mode = "all"; }
3091
3092 $opt = $ARGV[0];
3093 if ($opt eq "--")     { shift; }
3094 elsif ($opt eq "-a")  { $mode = "all"; shift; }
3095 elsif ($opt eq "-n")  { $mode = "nonroot"; shift; }
3096 elsif ($opt eq "-r" ) { $mode = "allonly"; shift; }
3097 elsif ($opt =~ m/^-/ || $#ARGV > 0) { usage(); }
3098
3099 $pattern = $ARGV[0];
3100 usage() if ($pattern eq "");
3101
3102 open FH, "<$RC" or die "zg: Could not open $RC: $!\n";
3103 while ($line = <FH>) {
3104     chomp $line;
3105     if ($line =~ m/^#:grep:marker:for:mika:/) { $markerfound = 1; next; }
3106     next if ($mode eq "nonroot" && markerfound == 0);
3107     break if ($mode eq "allonly" && markerfound == 1);
3108     print $line, "\n" if ($line =~ /$pattern/);
3109 }
3110 close FH;
3111 exit 0;
3112
3113     ' -- "$@"
3114 #}}}
3115     return $?
3116 }
3117
3118 ssl_hashes=( sha512 sha256 sha1 md5 )
3119
3120 for sh in ${ssl_hashes}; do
3121     eval 'ssl-cert-'${sh}'() {
3122         emulate -L zsh
3123         if [[ -z $1 ]] ; then
3124             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
3125             return 1
3126         fi
3127         openssl x509 -noout -fingerprint -'${sh}' -in $1
3128     }'
3129 done; unset sh
3130
3131 ssl-cert-fingerprints() {
3132     emulate -L zsh
3133     local i
3134     if [[ -z $1 ]] ; then
3135         printf 'usage: ssl-cert-fingerprints <file>\n'
3136         return 1
3137     fi
3138     for i in ${ssl_hashes}
3139         do ssl-cert-$i $1;
3140     done
3141 }
3142
3143 ssl-cert-info() {
3144     emulate -L zsh
3145     if [[ -z $1 ]] ; then
3146         printf 'usage: ssl-cert-info <file>\n'
3147         return 1
3148     fi
3149     openssl x509 -noout -text -in $1
3150     ssl-cert-fingerprints $1
3151 }
3152
3153 # }}}
3154
3155 # {{{ make sure our environment is clean regarding colors
3156 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
3157 # }}}
3158
3159 # "persistent history" {{{
3160 # just write important commands you always need to ~/.important_commands
3161 if [[ -r ~/.important_commands ]] ; then
3162     fc -R ~/.important_commands
3163 fi
3164 # }}}
3165
3166 # load the lookup subsystem if it's available on the system
3167 zrcautoload lookupinit && lookupinit
3168
3169 #:grep:marker:for:mika: :-)
3170 ### non-root (EUID != 0) code below
3171 ###
3172
3173 if (( GRML_ALWAYS_LOAD_ALL == 0 )) && (( $EUID == 0 )) ; then
3174     zrclocal
3175     return 0
3176 fi
3177
3178 # variables {{{
3179
3180 # set terminal property (used e.g. by msgid-chooser)
3181 export COLORTERM="yes"
3182
3183 # set default browser
3184 if [[ -z "$BROWSER" ]] ; then
3185     if [[ -n "$DISPLAY" ]] ; then
3186         #v# If X11 is running
3187         check_com -c firefox && export BROWSER=firefox
3188     else
3189         #v# If no X11 is running
3190         check_com -c w3m && export BROWSER=w3m
3191     fi
3192 fi
3193
3194 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
3195 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
3196 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
3197
3198 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
3199 #v# [for non-root only]
3200 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
3201 # }}}
3202
3203 # aliases {{{
3204
3205 # Xterm resizing-fu.
3206 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
3207 alias hide='echo -en "\033]50;nil2\007"'
3208 alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
3209 alias small='echo -en "\033]50;6x10\007"'
3210 alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
3211 alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
3212 alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
3213 alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
3214 alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
3215 alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
3216
3217 # general
3218 #a2# Execute \kbd{du -sch}
3219 alias da='du -sch'
3220 #a2# Execute \kbd{jobs -l}
3221 alias j='jobs -l'
3222
3223 # compile stuff
3224 #a2# Execute \kbd{./configure}
3225 alias CO="./configure"
3226 #a2# Execute \kbd{./configure --help}
3227 alias CH="./configure --help"
3228
3229 # listing stuff
3230 #a2# Execute \kbd{ls -lSrah}
3231 alias dir="ls -lSrah"
3232 #a2# Only show dot-directories
3233 alias lad='ls -d .*(/)'                # only show dot-directories
3234 #a2# Only show dot-files
3235 alias lsa='ls -a .*(.)'                # only show dot-files
3236 #a2# Only files with setgid/setuid/sticky flag
3237 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
3238 #a2# Only show 1st ten symlinks
3239 alias lsl='ls -l *(@)'                 # only symlinks
3240 #a2# Display only executables
3241 alias lsx='ls -l *(*)'                 # only executables
3242 #a2# Display world-{readable,writable,executable} files
3243 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
3244 #a2# Display the ten biggest files
3245 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
3246 #a2# Only show directories
3247 alias lsd='ls -d *(/)'                 # only show directories
3248 #a2# Only show empty directories
3249 alias lse='ls -d *(/^F)'               # only show empty directories
3250 #a2# Display the ten newest files
3251 alias lsnew="ls -rtlh *(D.om[1,10])"   # display the newest files
3252 #a2# Display the ten oldest files
3253 alias lsold="ls -rtlh *(D.Om[1,10])"   # display the oldest files
3254 #a2# Display the ten smallest files
3255 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
3256
3257 # chmod
3258 #a2# Execute \kbd{chmod 600}
3259 alias rw-='chmod 600'
3260 #a2# Execute \kbd{chmod 700}
3261 alias rwx='chmod 700'
3262 #m# a2 r-{}- Execute \kbd{chmod 644}
3263 alias r--='chmod 644'
3264 #a2# Execute \kbd{chmod 755}
3265 alias r-x='chmod 755'
3266
3267 # some useful aliases
3268 #a2# Execute \kbd{mkdir -o}
3269 alias md='mkdir -p'
3270
3271 # console stuff
3272 #a2# Execute \kbd{mplayer -vo fbdev}
3273 alias cmplayer='mplayer -vo fbdev'
3274 #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
3275 alias fbmplayer='mplayer -vo fbdev -fs -zoom'
3276 #a2# Execute \kbd{links2 -driver fb}
3277 alias fblinks='links2 -driver fb'
3278
3279 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3280 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3281 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3282
3283 # simple webserver
3284 check_com -c python && alias http="python -m SimpleHTTPServer"
3285
3286 # Use 'g' instead of 'git':
3287 check_com g || alias g='git'
3288
3289 # work around non utf8 capable software in utf environment via $LANG and luit
3290 if check_com isutfenv && check_com luit ; then
3291     if check_com -c mrxvt ; then
3292         isutfenv && [[ -n "$LANG" ]] && \
3293             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3294     fi
3295
3296     if check_com -c aterm ; then
3297         isutfenv && [[ -n "$LANG" ]] && \
3298             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3299     fi
3300
3301     if check_com -c centericq ; then
3302         isutfenv && [[ -n "$LANG" ]] && \
3303             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3304     fi
3305 fi
3306 # }}}
3307
3308 # useful functions {{{
3309
3310 # searching
3311 #f4# Search for newspostings from authors
3312 agoogle() { ${=BROWSER} "http://groups.google.com/groups?as_uauthors=$*" ; }
3313 #f4# Search Debian Bug Tracking System
3314 debbug()  {
3315     emulate -L zsh
3316     setopt extendedglob
3317     if [[ $# -eq 1 ]]; then
3318         case "$1" in
3319             ([0-9]##)
3320             ${=BROWSER} "http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=$1"
3321             ;;
3322             (*@*)
3323             ${=BROWSER} "http://bugs.debian.org/cgi-bin/pkgreport.cgi?submitter=$1"
3324             ;;
3325             (*)
3326             ${=BROWSER} "http://bugs.debian.org/$*"
3327             ;;
3328         esac
3329     else
3330         print "$0 needs one argument"
3331         return 1
3332     fi
3333 }
3334 #f4# Search Debian Bug Tracking System in mbox format
3335 debbugm() {
3336     emulate -L zsh
3337     bts show --mbox $1
3338 }
3339 #f4# Search DMOZ
3340 dmoz()    {
3341     emulate -L zsh
3342     ${=BROWSER} http://search.dmoz.org/cgi-bin/search\?search=${1// /_}
3343 }
3344 #f4# Search German   Wiktionary
3345 dwicti()  {
3346     emulate -L zsh
3347     ${=BROWSER} http://de.wiktionary.org/wiki/${(C)1// /_}
3348 }
3349 #f4# Search English  Wiktionary
3350 ewicti()  {
3351     emulate -L zsh
3352     ${=BROWSER} http://en.wiktionary.org/wiki/${(C)1// /_}
3353 }
3354 #f4# Search Google Groups
3355 ggogle()  {
3356     emulate -L zsh
3357     ${=BROWSER} "http://groups.google.com/groups?q=$*"
3358 }
3359 #f4# Search Google
3360 google()  {
3361     emulate -L zsh
3362     ${=BROWSER} "http://www.google.com/search?&num=100&q=$*"
3363 }
3364 #f4# Search Google Groups for MsgID
3365 mggogle() {
3366     emulate -L zsh
3367     ${=BROWSER} "http://groups.google.com/groups?selm=$*"
3368 }
3369 #f4# Search Netcraft
3370 netcraft(){
3371     emulate -L zsh
3372     ${=BROWSER} "http://toolbar.netcraft.com/site_report?url=$1"
3373 }
3374 #f4# Use German Wikipedia's full text search
3375 swiki()   {
3376     emulate -L zsh
3377     ${=BROWSER} http://de.wikipedia.org/wiki/Spezial:Search/${(C)1}
3378 }
3379 #f4# search \kbd{dict.leo.org}
3380 oleo()    {
3381     emulate -L zsh
3382     ${=BROWSER} "http://dict.leo.org/?search=$*"
3383 }
3384 #f4# Search German   Wikipedia
3385 wikide()  {
3386     emulate -L zsh
3387     ${=BROWSER} http://de.wikipedia.org/wiki/"${(C)*}"
3388 }
3389 #f4# Search English  Wikipedia
3390 wikien()  {
3391     emulate -L zsh
3392     ${=BROWSER} http://en.wikipedia.org/wiki/"${(C)*}"
3393 }
3394 #f4# Search official debs
3395 wodeb()   {
3396     emulate -L zsh
3397     ${=BROWSER} "http://packages.debian.org/search?keywords=$1&searchon=contents&suite=${2:=unstable}&section=all"
3398 }
3399
3400 #m# f4 gex() Exact search via Google
3401 check_com google && gex () {
3402     google "\"[ $1]\" $*"
3403 }
3404
3405 # misc
3406 #f5# Backup \kbd{file {\rm to} file\_timestamp}
3407 bk() {
3408     emulate -L zsh
3409     cp -b $1 $1_`date --iso-8601=m`
3410 }
3411 #f5# Copied diff
3412 cdiff() {
3413     emulate -L zsh
3414     diff -crd "$@" | egrep -v "^Only in |^Binary files "
3415 }
3416 #f5# cd to directoy and list files
3417 cl() {
3418     emulate -L zsh
3419     cd $1 && ls -a
3420 }
3421 #f5# Cvs add
3422 cvsa() {
3423     emulate -L zsh
3424     cvs add $* && cvs com -m 'initial checkin' $*
3425 }
3426 #f5# Cvs diff
3427 cvsd() {
3428     emulate -L zsh
3429     cvs diff -N $* |& $PAGER
3430 }
3431 #f5# Cvs log
3432 cvsl() {
3433     emulate -L zsh
3434     cvs log $* |& $PAGER
3435 }
3436 #f5# Cvs update
3437 cvsq() {
3438     emulate -L zsh
3439     cvs -nq update
3440 }
3441 #f5# Rcs2log
3442 cvsr() {
3443     emulate -L zsh
3444     rcs2log $* | $PAGER
3445 }
3446 #f5# Cvs status
3447 cvss() {
3448     emulate -L zsh
3449     cvs status -v $*
3450 }
3451 #f5# Disassemble source files using gcc and as
3452 disassemble(){
3453     emulate -L zsh
3454     gcc -pipe -S -o - -O -g $* | as -aldh -o /dev/null
3455 }
3456 #f5# Firefox remote control - open given URL
3457 fir() {
3458     if [ -e /etc/debian_version ]; then
3459         firefox -a iceweasel -remote "openURL($1)" || firefox ${1}&
3460     else
3461         firefox -a firefox -remote "openURL($1)" || firefox ${1}&
3462     fi
3463 }
3464 #f5# Create Directoy and \kbd{cd} to it
3465 mcd() {
3466     mkdir -p "$@" && cd "$@"
3467 }
3468 #f5# Unified diff to timestamped outputfile
3469 mdiff() {
3470     diff -udrP "$1" "$2" > diff.`date "+%Y-%m-%d"`."$1"
3471 }
3472 #f5# Memory overview
3473 memusage() {
3474     ps aux | awk '{if (NR > 1) print $5; if (NR > 2) print "+"} END { print "p" }' | dc
3475 }
3476 #f5# Show contents of gzipped tar file
3477 shtar() {
3478     emulate -L zsh
3479     gunzip -c $1 | tar -tf - -- | $PAGER
3480 }
3481 #f5# Show contents of zip file
3482 shzip() {
3483     emulate -L zsh
3484     unzip -l $1 | $PAGER
3485 }
3486 #f5# Unified diff
3487 udiff() {
3488     emulate -L zsh
3489     diff -urd $* | egrep -v "^Only in |^Binary files "
3490 }
3491 #f5# (Mis)use \kbd{vim} as \kbd{less}
3492 viless() {
3493     emulate -L zsh
3494     vim --cmd 'let no_plugin_maps = 1' -c "so \$VIMRUNTIME/macros/less.vim" "${@:--}"
3495 }
3496
3497 # Function Usage: uopen $URL/$file
3498 #f5# Download a file and display it locally
3499 uopen() {
3500     emulate -L zsh
3501     if ! [[ -n "$1" ]] ; then
3502         print "Usage: uopen \$URL/\$file">&2
3503         return 1
3504     else
3505         FILE=$1
3506         MIME=$(curl --head $FILE | grep Content-Type | cut -d ' ' -f 2 | cut -d\; -f 1)
3507         MIME=${MIME%$'\r'}
3508         curl $FILE | see ${MIME}:-
3509     fi
3510 }
3511
3512 # Function Usage: doc packagename
3513 #f5# \kbd{cd} to /usr/share/doc/\textit{package}
3514 doc() {
3515     emulate -L zsh
3516     cd /usr/share/doc/$1 && ls
3517 }
3518 _doc() { _files -W /usr/share/doc -/ }
3519 check_com compdef && compdef _doc doc
3520
3521 #f5# Make screenshot
3522 sshot() {
3523     [[ ! -d ~/shots  ]] && mkdir ~/shots
3524     #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
3525     cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
3526 }
3527
3528 # list images only
3529 limg() {
3530     local -a images
3531     images=( *.{jpg,gif,png}(.N) )
3532
3533     if [[ $#images -eq 0 ]] ; then
3534         print "No image files found"
3535     else
3536         ls "$images[@]"
3537     fi
3538 }
3539
3540 #f5# Create PDF file from source code
3541 makereadable() {
3542     emulate -L zsh
3543     output=$1
3544     shift
3545     a2ps --medium A4dj -E -o $output $*
3546     ps2pdf $output
3547 }
3548
3549 # zsh with perl-regex - use it e.g. via:
3550 # regcheck '\s\d\.\d{3}\.\d{3} Euro' ' 1.000.000 Euro'
3551 #f5# Checks whether a regex matches or not.\\&\quad Example: \kbd{regcheck '.\{3\} EUR' '500 EUR'}
3552 regcheck() {
3553     emulate -L zsh
3554     zmodload -i zsh/pcre
3555     pcre_compile $1 && \
3556     pcre_match $2 && echo "regex matches" || echo "regex does not match"
3557 }
3558
3559 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
3560 accessed() {
3561     emulate -L zsh
3562     print -l -- *(a-${1:-1})
3563 }
3564
3565 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
3566 changed() {
3567     emulate -L zsh
3568     print -l -- *(c-${1:-1})
3569 }
3570
3571 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
3572 modified() {
3573     emulate -L zsh
3574     print -l -- *(m-${1:-1})
3575 }
3576 # modified() was named new() in earlier versions, add an alias for backwards compatibility
3577 check_com new || alias new=modified
3578
3579 #f5# Grep in history
3580 greph() {
3581     emulate -L zsh
3582     history 0 | grep $1
3583 }
3584 # use colors when GNU grep with color-support
3585 #a2# Execute \kbd{grep -{}-color=auto}
3586 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
3587 #a2# Execute \kbd{grep -i -{}-color=auto}
3588 alias GREP='grep -i --color=auto'
3589
3590 #f5# Watch manpages in a stretched style
3591 man2() { PAGER='dash -c "sed G | /usr/bin/less"' command man "$@" ; }
3592
3593 # usage example: 'lcheck strcpy'
3594 #f5# Find out which libs define a symbol
3595 lcheck() {
3596     if [[ -n "$1" ]] ; then
3597         nm -go /usr/lib/lib*.a 2>/dev/null | grep ":[[:xdigit:]]\{8\} . .*$1"
3598     else
3599         echo "Usage: lcheck <function>" >&2
3600     fi
3601 }
3602
3603 #f5# Clean up directory - remove well known tempfiles
3604 purge() {
3605     FILES=(*~(N) .*~(N) \#*\#(N) *.o(N) a.out(N) *.core(N) *.cmo(N) *.cmi(N) .*.swp(N))
3606     NBFILES=${#FILES}
3607     if [[ $NBFILES > 0 ]] ; then
3608         print $FILES
3609         local ans
3610         echo -n "Remove these files? [y/n] "
3611         read -q ans
3612         if [[ $ans == "y" ]] ; then
3613             rm ${FILES}
3614             echo ">> $PWD purged, $NBFILES files removed"
3615         else
3616             echo "Ok. .. then not.."
3617         fi
3618     fi
3619 }
3620
3621 #f5# show labels and uuids of disk devices
3622 if is439 && [[ -d /dev/disk/by-id/ ]]; then
3623     lsdisk() {
3624         emulate -L zsh
3625         setopt extendedglob
3626         local -a -U disks
3627         disks=( /dev/disk/by-id/*(@:A) )
3628         for dev in "$disks[@]"; do
3629             print ${fg_bold[red]}${dev}${reset_color} /dev/disk/by-label/*(@e/'[[ ${REPLY:A} == $dev ]] && REPLY=${fg[blue]}LABEL=${REPLY:t}${reset_color}'/N) /dev/disk/by-uuid/*(@e/'[[ ${REPLY:A} == $dev ]] && REPLY=${fg[green]}UUID=${REPLY:t}${reset_color}'/N)
3630             print -f "  %s\n" /dev/disk/by-id/*(@e/'[[ ${REPLY:A} == $dev ]]'/N:t)
3631         done
3632     }
3633 fi
3634
3635 # Translate DE<=>EN
3636 # 'translate' looks up fot a word in a file with language-to-language
3637 # translations (field separator should be " : "). A typical wordlist looks
3638 # like at follows:
3639 #  | english-word : german-transmission
3640 # It's also only possible to translate english to german but not reciprocal.
3641 # Use the following oneliner to turn back the sort order:
3642 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3643 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3644 #f5# Translates a word
3645 trans() {
3646     emulate -L zsh
3647     case "$1" in
3648         -[dD]*)
3649             translate -l de-en $2
3650             ;;
3651         -[eE]*)
3652             translate -l en-de $2
3653             ;;
3654         *)
3655             echo "Usage: $0 { -D | -E }"
3656             echo "         -D == German to English"
3657             echo "         -E == English to German"
3658     esac
3659 }
3660
3661 #f5# List all occurrences of programm in current PATH
3662 plap() {
3663     emulate -L zsh
3664     if [[ $# = 0 ]] ; then
3665         echo "Usage:    $0 program"
3666         echo "Example:  $0 zsh"
3667         echo "Lists all occurrences of program in the current PATH."
3668     else
3669         ls -l ${^path}/*$1*(*N)
3670     fi
3671 }
3672
3673 # Found in the mailinglistarchive from Zsh (IIRC ~1996)
3674 #f5# Select items for specific command(s) from history
3675 selhist() {
3676     emulate -L zsh
3677     local TAB=$'\t';
3678     (( $# < 1 )) && {
3679         echo "Usage: $0 command"
3680         return 1
3681     };
3682     cmd=(${(f)"$(grep -w $1 $HISTFILE | sort | uniq | pr -tn)"})
3683     print -l $cmd | less -F
3684     echo -n "enter number of desired command [1 - $(( ${#cmd[@]} - 1 ))]: "
3685     local answer
3686     read answer
3687     print -z "${cmd[$answer]#*$TAB}"
3688 }
3689
3690 # Use vim to convert plaintext to HTML
3691 #f5# Transform files to html with highlighting
3692 2html() {
3693     emulate -L zsh
3694     vim -u NONE -n -c ':syntax on' -c ':so $VIMRUNTIME/syntax/2html.vim' -c ':wqa' $1 &>/dev/null
3695 }
3696
3697 # Usage: simple-extract <file>
3698 #f5# Smart archive extractor
3699 simple-extract () {
3700     emulate -L zsh
3701     if [[ -f $1 ]] ; then
3702         case $1 in
3703             *.tar.bz2)  bzip2 -v -d $1      ;;
3704             *.tar.gz)   tar -xvzf $1        ;;
3705             *.rar)      unrar $1            ;;
3706             *.deb)      ar -x $1            ;;
3707             *.bz2)      bzip2 -d $1         ;;
3708             *.lzh)      lha x $1            ;;
3709             *.gz)       gunzip -d $1        ;;
3710             *.tar)      tar -xvf $1         ;;
3711             *.tgz)      gunzip -d $1        ;;
3712             *.tbz2)     tar -jxvf $1        ;;
3713             *.zip)      unzip $1            ;;
3714             *.Z)        uncompress $1       ;;
3715             *)          echo "'$1' Error. Please go away" ;;
3716         esac
3717     else
3718         echo "'$1' is not a valid file"
3719     fi
3720 }
3721
3722 # Usage: smartcompress <file> (<type>)
3723 #f5# Smart archive creator
3724 smartcompress() {
3725     emulate -L zsh
3726     if [[ -n $2 ]] ; then
3727         case $2 in
3728             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
3729             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
3730             tar.Z)          tar -Zcvf$1.$2 $1 ;;
3731             tar)            tar -cvf$1.$2  $1 ;;
3732             gz | gzip)      gzip           $1 ;;
3733             bz2 | bzip2)    bzip2          $1 ;;
3734             *)
3735                 echo "Error: $2 is not a valid compression type"
3736                 ;;
3737         esac
3738     else
3739         smartcompress $1 tar.gz
3740     fi
3741 }
3742
3743 # Usage: show-archive <archive>
3744 #f5# List an archive's content
3745 show-archive() {
3746     emulate -L zsh
3747     if [[ -f $1 ]] ; then
3748         case $1 in
3749             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
3750             *.tar)         tar -tf $1 ;;
3751             *.tgz)         tar -ztf $1 ;;
3752             *.zip)         unzip -l $1 ;;
3753             *.bz2)         bzless $1 ;;
3754             *.deb)         dpkg-deb --fsys-tarfile $1 | tar -tf - -- ;;
3755             *)             echo "'$1' Error. Please go away" ;;
3756         esac
3757     else
3758         echo "'$1' is not a valid archive"
3759     fi
3760 }
3761
3762 # It's shameless stolen from <http://www.vim.org/tips/tip.php?tip_id=167>
3763 #f5# Use \kbd{vim} as your manpage reader
3764 vman() {
3765     emulate -L zsh
3766     if (( ${#argv} == 0 )); then
3767         printf 'usage: vman <topic>\n'
3768         return 1
3769     fi
3770     man "$@" | col -b | view -c 'set ft=man nomod nolist' -
3771 }
3772
3773 # function readme() { $PAGER -- (#ia3)readme* }
3774 #f5# View all README-like files in current directory in pager
3775 readme() {
3776     emulate -L zsh
3777     local files
3778     files=(./(#i)*(read*me|lue*m(in|)ut)*(ND))
3779     if (($#files)) ; then
3780         $PAGER $files
3781     else
3782         print 'No README files.'
3783     fi
3784 }
3785
3786 # function ansi-colors()
3787 #f5# Display ANSI colors
3788 ansi-colors() {
3789     typeset esc="\033[" line1 line2
3790     echo " _ _ _40 _ _ _41_ _ _ _42 _ _ 43_ _ _ 44_ _ _45 _ _ _ 46_ _ _ 47_ _ _ 49_ _"
3791     for fore in 30 31 32 33 34 35 36 37; do
3792         line1="$fore "
3793         line2="   "
3794         for back in 40 41 42 43 44 45 46 47 49; do
3795             line1="${line1}${esc}${back};${fore}m Normal ${esc}0m"
3796             line2="${line2}${esc}${back};${fore};1m Bold   ${esc}0m"
3797         done
3798         echo -e "$line1\n$line2"
3799     done
3800 }
3801
3802 #f5# Find all files in \$PATH with setuid bit set
3803 suidfind() { ls -latg $path | grep '^...s' }
3804
3805 # TODO: So, this is the third incarnation of this function!?
3806 #f5# Reload given functions
3807 refunc() {
3808     for func in $argv ; do
3809         unfunction $func
3810         autoload $func
3811     done
3812 }
3813
3814 # a small check to see which DIR is located on which server/partition.
3815 # stolen and modified from Sven's zshrc.forall
3816 #f5# Report diskusage of a directory
3817 dirspace() {
3818     emulate -L zsh
3819     if [[ -n "$1" ]] ; then
3820         for dir in "$@" ; do
3821             if [[ -d "$dir" ]] ; then
3822                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3823             else
3824                 echo "warning: $dir does not exist" >&2
3825             fi
3826         done
3827     else
3828         for dir in $path; do
3829             if [[ -d "$dir" ]] ; then
3830                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3831             else
3832                 echo "warning: $dir does not exist" >&2
3833             fi
3834         done
3835     fi
3836 }
3837
3838 # % slow_print `cat /etc/passwd`
3839 #f5# Slowly print out parameters
3840 slow_print() {
3841     for argument in "$@" ; do
3842         for ((i = 1; i <= ${#1} ;i++)) ; do
3843             print -n "${argument[i]}"
3844             sleep 0.08
3845         done
3846         print -n " "
3847     done
3848     print ""
3849 }
3850
3851 #f5# Show some status info
3852 status() {
3853     print
3854     print "Date..: "$(date "+%Y-%m-%d %H:%M:%S")
3855     print "Shell.: Zsh $ZSH_VERSION (PID = $$, $SHLVL nests)"
3856     print "Term..: $TTY ($TERM), ${BAUD:+$BAUD bauds, }$COLUMNS x $LINES chars"
3857     print "Login.: $LOGNAME (UID = $EUID) on $HOST"
3858     print "System: $(cat /etc/[A-Za-z]*[_-][rv]e[lr]*)"
3859     print "Uptime:$(uptime)"
3860     print
3861 }
3862
3863 # Rip an audio CD
3864 #f5# Rip an audio CD
3865 audiorip() {
3866     mkdir -p ~/ripps
3867     cd ~/ripps
3868     cdrdao read-cd --device $DEVICE --driver generic-mmc audiocd.toc
3869     cdrdao read-cddb --device $DEVICE --driver generic-mmc audiocd.toc
3870     echo " * Would you like to burn the cd now? (yes/no)"
3871     read input
3872     if [[ "$input" = "yes" ]] ; then
3873         echo " ! Burning Audio CD"
3874         audioburn
3875         echo " * done."
3876     else
3877         echo " ! Invalid response."
3878     fi
3879 }
3880
3881 # and burn it
3882 #f5# Burn an audio CD (in combination with audiorip)
3883 audioburn() {
3884     cd ~/ripps
3885     cdrdao write --device $DEVICE --driver generic-mmc audiocd.toc
3886     echo " * Should I remove the temporary files? (yes/no)"
3887     read input
3888     if [[ "$input" = "yes" ]] ; then
3889         echo " ! Removing Temporary Files."
3890         cd ~
3891         rm -rf ~/ripps
3892         echo " * done."
3893     else
3894         echo " ! Invalid response."
3895     fi
3896 }
3897
3898 #f5# Make an audio CD from all mp3 files
3899 mkaudiocd() {
3900     # TODO: do the renaming more zshish, possibly with zmv()
3901     emulate -L zsh
3902     cd ~/ripps
3903     for i in *.[Mm][Pp]3; do mv "$i" `echo $i | tr '[A-Z]' '[a-z]'`; done
3904     for i in *.mp3; do mv "$i" `echo $i | tr ' ' '_'`; done
3905     for i in *.mp3; do mpg123 -w `basename $i .mp3`.wav $i; done
3906     normalize -m *.wav
3907     for i in *.wav; do sox $i.wav -r 44100 $i.wav resample; done
3908 }
3909
3910 #f5# Create an ISO image. You are prompted for\\&\quad volume name, filename and directory
3911 mkiso() {
3912     emulate -L zsh
3913     echo " * Volume name "
3914     read volume
3915     echo " * ISO Name (ie. tmp.iso)"
3916     read iso
3917     echo " * Directory or File"
3918     read files
3919     mkisofs -o ~/$iso -A $volume -allow-multidot -J -R -iso-level 3 -V $volume -R $files
3920 }
3921
3922 #f5# Simple thumbnails generator
3923 genthumbs() {
3924     rm -rf thumb-* index.html
3925     echo "
3926 <html>
3927   <head>
3928     <title>Images</title>
3929   </head>
3930   <body>" > index.html
3931     for f in *.(gif|jpeg|jpg|png) ; do
3932         convert -size 100x200 "$f" -resize 100x200 thumb-"$f"
3933         echo "    <a href=\"$f\"><img src=\"thumb-$f\"></a>" >> index.html
3934     done
3935     echo "
3936   </body>
3937 </html>" >> index.html
3938 }
3939
3940 #f5# Set all ulimit parameters to \kbd{unlimited}
3941 allulimit() {
3942     ulimit -c unlimited
3943     ulimit -d unlimited
3944     ulimit -f unlimited
3945     ulimit -l unlimited
3946     ulimit -n unlimited
3947     ulimit -s unlimited
3948     ulimit -t unlimited
3949 }
3950
3951 # 2mp3 transcodes flac and ogg to mp3 with bitrate of 192 while preserving basic tags
3952 if check_com lame; then
3953     2mp3_192() {
3954         emulate -L zsh
3955         setopt extendedglob
3956         unsetopt ksharrays
3957
3958         local -a DECODE id3tags
3959         local -A tagmap
3960         local tagdata
3961         local RC=0
3962         tagmap=("(#l)title" --tt "(#l)artist" --ta "(#l)tracknumber" --tn "(#l)genre" --tg "(#l)album" --tl)
3963
3964         if [[ ${@[(i)*.ogg]} -le ${#@} ]] && ! check_com oggdec; then
3965             echo "ERROR: please install oggdec" >&2
3966             return 1
3967         fi
3968         if [[ ${@[(i)*.flac]} -le ${#@} ]] && ! check_com flac; then
3969             echo "ERROR: please install flac" >&2
3970             return 1
3971         fi
3972
3973         for af in "$@"; do
3974             id3tags=()
3975             case "$af" in
3976                 (*.flac)
3977                     DECODE=(flac -d -c "$af")
3978                     tagdata="$(metaflac --export-tags-to=- "$af")"
3979                     ;;
3980                 (*.ogg)
3981                     DECODE=(oggdec -Q -o - "$af")
3982                     tagdata="$(ogginfo "$af")"
3983                     ;;
3984                 (*) continue ;;
3985             esac
3986             for line (${(f)tagdata}) \
3987                 [[ "$line" == (#s)[[:space:]]#(#b)([^=]##)=(*)(#e) && -n $tagmap[(k)$match[1]] ]] && \
3988                 id3tags+=($tagmap[(k)$match[1]] "$match[2]")
3989             [[ ${#id3tags} -gt 0 ]] && id3tags=(--add-id3v2 --ignore-tag-errors $id3tags)
3990             $DECODE[*] | lame -b 192 -v -h --replaygain-fast  "${id3tags[@]}" - "${af:r}.mp3" || {RC=$?; print "Error transcoding" "${af}"; }
3991         done
3992         # return 0 if no error or exit code if at least one error happened
3993         return $RC
3994     }
3995     alias ogg2mp3_192 2mp3_192
3996 fi
3997
3998 #f5# RFC 2396 URL encoding in Z-Shell
3999 urlencode() {
4000     emulate -L zsh
4001     setopt extendedglob
4002     input=( ${(s::)1} )
4003     print ${(j::)input/(#b)([^A-Za-z0-9_.!~*\'\(\)-])/%${(l:2::0:)$(([##16]#match))}}
4004 }
4005
4006 # http://strcat.de/blog/index.php?/archives/335-Software-sauber-deinstallieren...html
4007 #f5# Log 'make install' output
4008 mmake() {
4009     emulate -L zsh
4010     [[ ! -d ~/.errorlogs ]] && mkdir ~/.errorlogs
4011     make -n install > ~/.errorlogs/${PWD##*/}-makelog
4012 }
4013
4014 #f5# Indent source code
4015 smart-indent() {
4016     indent -npro -kr -i8 -ts8 -sob -l80 -ss -ncs "$@"
4017 }
4018
4019 # highlight important stuff in diff output, usage example: hg diff | hidiff
4020 #m# a2 hidiff \kbd{histring} oneliner for diffs
4021 check_com -c histring && \
4022     alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
4023
4024 # rename pictures based on information found in exif headers
4025 #f5# Rename pictures based on information found in exif headers
4026 exirename() {
4027     emulate -L zsh
4028     if [[ $# -lt 1 ]] ; then
4029         echo 'Usage: jpgrename $FILES' >& 2
4030         return 1
4031     else
4032         echo -n 'Checking for jhead with version newer than 1.9: '
4033         jhead_version=`jhead -h | grep 'used by most Digital Cameras.  v.*' | awk '{print $6}' | tr -d v`
4034         if [[ $jhead_version > '1.9' ]]; then
4035             echo 'success - now running jhead.'
4036             jhead -n%Y-%m-%d_%Hh%M_%f $*
4037         else
4038             echo 'failed - exiting.'
4039         fi
4040     fi
4041 }
4042
4043 # get_ic() - queries imap servers for capabilities; real simple. no imaps
4044 ic_get() {
4045     emulate -L zsh
4046     local port
4047     if [[ ! -z $1 ]] ; then
4048         port=${2:-143}
4049         print "querying imap server on $1:${port}...\n";
4050         print "a1 capability\na2 logout\n" | nc $1 ${port}
4051     else
4052         print "usage:\n  $0 <imap-server> [port]"
4053     fi
4054 }
4055
4056 # creates a Maildir/ with its {new,cur,tmp} subdirs
4057 mkmaildir() {
4058     emulate -L zsh
4059     local root subdir
4060     root=${MAILDIR_ROOT:-${HOME}/Mail}
4061     if [[ -z ${1} ]] ; then print "Usage:\n $0 <dirname>" ; return 1 ; fi
4062     subdir=${1}
4063     mkdir -p ${root}/${subdir}/{cur,new,tmp}
4064 }
4065
4066 #f5# Change the xterm title from within GNU-screen
4067 xtrename() {
4068     emulate -L zsh
4069     if [[ $1 != "-f" ]] ; then
4070         if [[ -z ${DISPLAY} ]] ; then
4071             printf 'xtrename only makes sense in X11.\n'
4072             return 1
4073         fi
4074     else
4075         shift
4076     fi
4077     if [[ -z $1 ]] ; then
4078         printf 'usage: xtrename [-f] "title for xterm"\n'
4079         printf '  renames the title of xterm from _within_ screen.\n'
4080         printf '  also works without screen.\n'
4081         printf '  will not work if DISPLAY is unset, use -f to override.\n'
4082         return 0
4083     fi
4084     print -n "\eP\e]0;${1}\C-G\e\\"
4085     return 0
4086 }
4087
4088 # hl() highlighted less
4089 # http://ft.bewatermyfriend.org/comp/data/zsh/zfunct.html
4090 if check_com -c highlight ; then
4091     function hl() {
4092     emulate -L zsh
4093         local theme lang
4094         theme=${HL_THEME:-""}
4095         case ${1} in
4096             (-l|--list)
4097                 ( printf 'available languages (syntax parameter):\n\n' ;
4098                     highlight --list-langs ; ) | less -SMr
4099                 ;;
4100             (-t|--themes)
4101                 ( printf 'available themes (style parameter):\n\n' ;
4102                     highlight --list-themes ; ) | less -SMr
4103                 ;;
4104             (-h|--help)
4105                 printf 'usage: hl <syntax[:theme]> <file>\n'
4106                 printf '    available options: --list (-l), --themes (-t), --help (-h)\n\n'
4107                 printf '  Example: hl c main.c\n'
4108                 ;;
4109             (*)
4110                 if [[ -z ${2} ]] || (( ${#argv} > 2 )) ; then
4111                     printf 'usage: hl <syntax[:theme]> <file>\n'
4112                     printf '    available options: --list (-l), --themes (-t), --help (-h)\n'
4113                     (( ${#argv} > 2 )) && printf '  Too many arguments.\n'
4114                     return 1
4115                 fi
4116                 lang=${1%:*}
4117                 [[ ${1} == *:* ]] && [[ -n ${1#*:} ]] && theme=${1#*:}
4118                 if [[ -n ${theme} ]] ; then
4119                     highlight --xterm256 --syntax ${lang} --style ${theme} ${2} | less -SMr
4120                 else
4121                     highlight --ansi --syntax ${lang} ${2} | less -SMr
4122                 fi
4123                 ;;
4124         esac
4125         return 0
4126     }
4127     # ... and a proper completion for hl()
4128     # needs 'highlight' as well, so it fits fine in here.
4129     function _hl_genarg()  {
4130         local expl
4131         if [[ -prefix 1 *: ]] ; then
4132             local themes
4133             themes=(${${${(f)"$(LC_ALL=C highlight --list-themes)"}/ #/}:#*(Installed|Use name)*})
4134             compset -P 1 '*:'
4135             _wanted -C list themes expl theme compadd ${themes}
4136         else
4137             local langs
4138             langs=(${${${(f)"$(LC_ALL=C highlight --list-langs)"}/ #/}:#*(Installed|Use name)*})
4139             _wanted -C list languages expl languages compadd -S ':' -q ${langs}
4140         fi
4141     }
4142     function _hl_complete() {
4143         _arguments -s '1: :_hl_genarg' '2:files:_path_files'
4144     }
4145     compdef _hl_complete hl
4146 fi
4147
4148 # TODO:
4149 # Rewrite this by either using tinyurl.com's API
4150 # or using another shortening service to comply with
4151 # tinyurl.com's policy.
4152 #
4153 # Create small urls via http://tinyurl.com using wget(1).
4154 #function zurl() {
4155 #    emulate -L zsh
4156 #    [[ -z $1 ]] && { print "USAGE: zurl <URL>" ; return 1 }
4157 #
4158 #    local PN url tiny grabber search result preview
4159 #    PN=$0
4160 #    url=$1
4161 ##   Check existence of given URL with the help of ping(1).
4162 ##   N.B. ping(1) only works without an eventual given protocol.
4163 #    ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
4164 #        read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
4165 #
4166 #    if (( $? == 0 )) ; then
4167 ##           Prepend 'http://' to given URL where necessary for later output.
4168 #            [[ ${url} != http(s|)://* ]] && url='http://'${url}
4169 #            tiny='http://tinyurl.com/create.php?url='
4170 #            if check_com -c wget ; then
4171 #                grabber='wget -O- -o/dev/null'
4172 #            else
4173 #                print "wget is not available, but mandatory for ${PN}. Aborting."
4174 #            fi
4175 ##           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
4176 #            search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
4177 #            result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
4178 ##           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
4179 #            preview='http://preview.'${result#http://}
4180 #
4181 #            printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
4182 #            printf '%s\t%s\n\n' 'Given URL:' ${url}
4183 #            printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
4184 #    else
4185 #        return 1
4186 #    fi
4187 #}
4188
4189 #f2# Print a specific line of file(s).
4190 linenr () {
4191 # {{{
4192     emulate -L zsh
4193     if [ $# -lt 2 ] ; then
4194        print "Usage: linenr <number>[,<number>] <file>" ; return 1
4195     elif [ $# -eq 2 ] ; then
4196          local number=$1
4197          local file=$2
4198          command ed -s $file <<< "${number}n"
4199     else
4200          local number=$1
4201          shift
4202          for file in "$@" ; do
4203              if [ ! -d $file ] ; then
4204                 echo "${file}:"
4205                 command ed -s $file <<< "${number}n" 2> /dev/null
4206              else
4207                 continue
4208              fi
4209          done | less
4210     fi
4211 # }}}
4212 }
4213
4214 #f2# Find history events by search pattern and list them by date.
4215 whatwhen()  {
4216 # {{{
4217     emulate -L zsh
4218     local usage help ident format_l format_s first_char remain first last
4219     usage='USAGE: whatwhen [options] <searchstring> <search range>'
4220     help='Use `whatwhen -h'\'' for further explanations.'
4221     ident=${(l,${#${:-Usage: }},, ,)}
4222     format_l="${ident}%s\t\t\t%s\n"
4223     format_s="${format_l//(\\t)##/\\t}"
4224     # Make the first char of the word to search for case
4225     # insensitive; e.g. [aA]
4226     first_char=[${(L)1[1]}${(U)1[1]}]
4227     remain=${1[2,-1]}
4228     # Default search range is `-100'.
4229     first=${2:-\-100}
4230     # Optional, just used for `<first> <last>' given.
4231     last=$3
4232     case $1 in
4233         ("")
4234             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
4235             printf '%s\n%s\n\n' ${usage} ${help} && return 1
4236         ;;
4237         (-h)
4238             printf '%s\n\n' ${usage}
4239             print 'OPTIONS:'
4240             printf $format_l '-h' 'show help text'
4241             print '\f'
4242             print 'SEARCH RANGE:'
4243             printf $format_l "'0'" 'the whole history,'
4244             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
4245             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
4246             printf '\n%s\n' 'EXAMPLES:'
4247             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
4248             printf $format_l 'whatwhen zsh -250'
4249             printf $format_l 'whatwhen foo 1 99'
4250         ;;
4251         (\?)
4252             printf '%s\n%s\n\n' ${usage} ${help} && return 1
4253         ;;
4254         (*)
4255             # -l list results on stout rather than invoking $EDITOR.
4256             # -i Print dates as in YYYY-MM-DD.
4257             # -m Search for a - quoted - pattern within the history.
4258             fc -li -m "*${first_char}${remain}*" $first $last
4259         ;;
4260     esac
4261 # }}}
4262 }
4263
4264 # change fluxbox keys from 'Alt-#' to 'Alt-F#' and vice versa
4265 fluxkey-change() {
4266     emulate -L zsh
4267     [[ -n "$FLUXKEYS" ]] || local FLUXKEYS="$HOME/.fluxbox/keys"
4268     if ! [[ -r "$FLUXKEYS" ]] ; then
4269         echo "Sorry, \$FLUXKEYS file $FLUXKEYS could not be read - nothing to be done."
4270         return 1
4271     else
4272         if grep -q 'Mod1 F[0-9] :Workspace [0-9]' $FLUXKEYS ; then
4273             echo -n 'Switching to Alt-# mode in ~/.fluxbox/keys: '
4274             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)F\([0-9]\+[: space :]\+:Workspace.*\)|\1\2|' $FLUXKEYS && echo done || echo failed
4275         elif grep -q 'Mod1 [0-9] :Workspace [0-9]' $FLUXKEYS ; then
4276             echo -n 'Switching to Alt-F# mode in ~/.fluxbox/keys: '
4277             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)\([0-9]\+[: space :]\+:Workspace.*\)|\1F\2|' $FLUXKEYS && echo done || echo failed
4278         else
4279             echo 'Sorry, do not know what to do.'
4280             return 1
4281         fi
4282     fi
4283 }
4284
4285 # retrieve weather information on the console
4286 # Usage example: 'weather LOWG'
4287 weather() {
4288     emulate -L zsh
4289     [[ -n "$1" ]] || {
4290         print 'Usage: weather <station_id>' >&2
4291         print 'List of stations: http://en.wikipedia.org/wiki/List_of_airports_by_ICAO_code'>&2
4292         return 1
4293     }
4294
4295     local VERBOSE="yes"    # TODO: Make this a command line switch
4296
4297     local ODIR=`pwd`
4298     local PLACE="${1:u}"
4299     local DIR="${HOME}/.weather"
4300     local LOG="${DIR}/log"
4301
4302     [[ -d ${DIR} ]] || {
4303         print -n "Creating ${DIR}: "
4304         mkdir ${DIR}
4305         print 'done'
4306     }
4307
4308     print "Retrieving information for ${PLACE}:"
4309     print
4310     cd ${DIR} && wget -T 10 --no-verbose --output-file=$LOG --timestamping http://weather.noaa.gov/pub/data/observations/metar/decoded/$PLACE.TXT
4311
4312     if [[ $? -eq 0 ]] ; then
4313         if [[ -n "$VERBOSE" ]] ; then
4314             cat ${PLACE}.TXT
4315         else
4316             DATE=$(grep 'UTC' ${PLACE}.TXT | sed 's#.* /##')
4317             TEMPERATURE=$(awk '/Temperature/ { print $4" degree Celcius / " $2" degree Fahrenheit" }' ${PLACE}.TXT | tr -d '(')
4318             echo "date: $DATE"
4319             echo "temp:  $TEMPERATURE"
4320         fi
4321     else
4322         print "There was an error retrieving the weather information for $PLACE" >&2
4323         cat $LOG
4324         cd $ODIR
4325         return 1
4326     fi
4327     cd $ODIR
4328 }
4329 # }}}
4330
4331 # mercurial related stuff {{{
4332 if check_com -c hg ; then
4333     # gnu like diff for mercurial
4334     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
4335     #f5# GNU like diff for mercurial
4336     hgdi() {
4337         emulate -L zsh
4338         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
4339     }
4340
4341     # build debian package
4342     #a2# Alias for \kbd{hg-buildpackage}
4343     alias hbp='hg-buildpackage'
4344
4345     # execute commands on the versioned patch-queue from the current repos
4346     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
4347
4348     # diffstat for specific version of a mercurial repository
4349     #   hgstat      => display diffstat between last revision and tip
4350     #   hgstat 1234 => display diffstat between revision 1234 and tip
4351     #f5# Diffstat for specific version of a mercurial repos
4352     hgstat() {
4353         emulate -L zsh
4354         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
4355     }
4356
4357 fi # end of check whether we have the 'hg'-executable
4358
4359 # }}}
4360
4361 # some useful commands often hard to remember - let's grep for them {{{
4362 # actually use our zg() function now. :)
4363
4364 # Work around ion/xterm resize bug.
4365 #if [[ "$SHLVL" -eq 1 ]]; then
4366 #       if check_com -c resize ; then
4367 #               eval `resize </dev/null`
4368 #       fi
4369 #fi
4370
4371 # enable jackd:
4372 #  /usr/bin/jackd -dalsa -dhw:0 -r48000 -p1024 -n2
4373 # now play audio file:
4374 #  alsaplayer -o jack foobar.mp3
4375
4376 # send files via netcat
4377 # on sending side:
4378 #  send() {j=$*; tar cpz ${j/%${!#}/}|nc -w 1 ${!#} 51330;}
4379 #  send dir* $HOST
4380 #  alias receive='nc -vlp 51330 | tar xzvp'
4381
4382 # debian stuff:
4383 # dh_make -e foo@localhost -f $1
4384 # dpkg-buildpackage -rfakeroot
4385 # lintian *.deb
4386 # dpkg-scanpackages ./ /dev/null | gzip > Packages.gz
4387 # dpkg-scansources . | gzip > Sources.gz
4388 # grep-dctrl --field Maintainer $* /var/lib/apt/lists/*
4389
4390 # other stuff:
4391 # convert -geometry 200x200 -interlace LINE -verbose
4392 # ldapsearch -x -b "OU=Bedienstete,O=tug" -h ldap.tugraz.at sn=$1
4393 # ps -ao user,pcpu,start,command
4394 # gpg --keyserver blackhole.pca.dfn.de --recv-keys
4395 # xterm -bg black -fg yellow -fn -misc-fixed-medium-r-normal--14-140-75-75-c-90-iso8859-15 -ah
4396 # nc -vz $1 1-1024   # portscan via netcat
4397 # wget --mirror --no-parent --convert-links
4398 # pal -d `date +%d`
4399 # autoload -U tetris; zle -N tetris; bindkey '...' ; echo "press ... for playing tennis"
4400 #
4401 # modify console cursor
4402 # see http://www.tldp.org/HOWTO/Framebuffer-HOWTO-5.html
4403 # print $'\e[?96;0;64c'
4404 # }}}
4405
4406 # grml-small cleanups {{{
4407
4408 # The following is used to remove zsh-config-items that do not work
4409 # in grml-small by default.
4410 # If you do not want these adjustments (for whatever reason), set
4411 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
4412 # sources if it is there).
4413
4414 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
4415
4416     unset abk[V]
4417     unalias    'V'      &> /dev/null
4418     unfunction vman     &> /dev/null
4419     unfunction viless   &> /dev/null
4420     unfunction 2html    &> /dev/null
4421
4422     # manpages are not in grmlsmall
4423     unfunction manzsh   &> /dev/null
4424     unfunction man2     &> /dev/null
4425
4426 fi
4427
4428 #}}}
4429
4430 zrclocal
4431
4432 ## genrefcard.pl settings {{{
4433
4434 ### doc strings for external functions from files
4435 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
4436
4437 ### example: split functions-search 8,16,24,32
4438 #@# split functions-search 8
4439
4440 ## }}}
4441
4442 ## END OF FILE #################################################################
4443 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
4444 # Local variables:
4445 # mode: sh
4446 # End: