etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation: {{{
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104 #}}}
 105
 106 # zsh profiling {{{
 107 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 108 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 109     zmodload zsh/zprof
 110 fi
 111 # }}}
 112
 113 # load .zshrc.pre to give the user the chance to overwrite the defaults
 114 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
 115
 116 # {{{ check for version/system
 117 # check for versions (compatibility reasons)
 118 is4(){
 119     [[ $ZSH_VERSION == <4->* ]] && return 0
 120     return 1
 121 }
 122
 123 is41(){
 124     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 125     return 1
 126 }
 127
 128 is42(){
 129     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 130     return 1
 131 }
 132
 133 is425(){
 134     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 135     return 1
 136 }
 137
 138 is43(){
 139     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 140     return 1
 141 }
 142
 143 is433(){
 144     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* || $ZSH_VERSION == <5->* ]] && return 0
 145     return 1
 146 }
 147
 148 is439(){
 149     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 #f1# Checks whether or not you're running grml
 154 isgrml(){
 155     [[ -f /etc/grml_version ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running a grml cd
 160 isgrmlcd(){
 161     [[ -f /etc/grml_cd ]] && return 0
 162     return 1
 163 }
 164
 165 if isgrml ; then
 166 #f1# Checks whether or not you're running grml-small
 167     isgrmlsmall() {
 168         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 169     }
 170 else
 171     isgrmlsmall() { return 1 }
 172 fi
 173
 174 isdarwin(){
 175     [[ $OSTYPE == darwin* ]] && return 0
 176     return 1
 177 }
 178
 179 #f1# are we running within an utf environment?
 180 isutfenv() {
 181     case "$LANG $CHARSET $LANGUAGE" in
 182         *utf*) return 0 ;;
 183         *UTF*) return 0 ;;
 184         *)     return 1 ;;
 185     esac
 186 }
 187
 188 # check for user, if not running as root set $SUDO to sudo
 189 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 190
 191 # change directory to home on first invocation of zsh
 192 # important for rungetty -> autologin
 193 # Thanks go to Bart Schaefer!
 194 isgrml && checkhome() {
 195     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 196         export ALREADY_DID_CD_HOME=$HOME
 197         cd
 198     fi
 199 }
 200
 201 # check for zsh v3.1.7+
 202
 203 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 204      || ${ZSH_VERSION} == 3.<2->.<->*    \
 205      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 206
 207     printf '-!-\n'
 208     printf '-!- In this configuration we try to make use of features, that only\n'
 209     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 210     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 211     printf '-!- advanced features in all supported versions.\n'
 212     printf '-!-\n'
 213     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 214     printf '-!-\n'
 215     printf '-!- While this *may* work, it might as well fail.\n'
 216     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 217     printf '-!-\n'
 218     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 219     printf '-!- If it does today, you'\''ve been lucky.\n'
 220     printf '-!-\n'
 221     printf '-!- Ye been warned!\n'
 222     printf '-!-\n'
 223
 224     function zstyle() { : }
 225 fi
 226
 227 # autoload wrapper - use this one instead of autoload directly
 228 # We need to define this function as early as this, because autoloading
 229 # 'is-at-least()' needs it.
 230 function zrcautoload() {
 231     emulate -L zsh
 232     setopt extended_glob
 233     local fdir ffile
 234     local -i ffound
 235
 236     ffile=$1
 237     (( found = 0 ))
 238     for fdir in ${fpath} ; do
 239         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 240     done
 241
 242     (( ffound == 0 )) && return 1
 243     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 244         autoload -U ${ffile} || return 1
 245     else
 246         autoload ${ffile} || return 1
 247     fi
 248     return 0
 249 }
 250
 251 # Load is-at-least() for more precise version checks
 252 # Note that this test will *always* fail, if the is-at-least
 253 # function could not be marked for autoloading.
 254 zrcautoload is-at-least || is-at-least() { return 1 }
 255
 256 # }}}
 257
 258 # {{{ set some important options (as early as possible)
 259 # Please update these tags, if you change the umask settings below.
 260 #o# r_umask     002
 261 #o# r_umaskstr  rwxrwxr-x
 262 #o# umask       022
 263 #o# umaskstr    rwxr-xr-x
 264 (( EUID != 0 )) && umask 002 || umask 022
 265
 266 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 267 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 268 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 269 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 270                             # list duplicates an older one, the older command is removed from the list
 271 setopt histignorespace      # remove command lines from the history list when
 272                             # the first character on the line is a space
 273 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 274                             # and the command is the name of a directory, perform the cd command to that directory
 275 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 276                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 277                             # -> searches for word not in compressed files
 278                             # don't forget to quote '^', '~' and '#'!
 279 setopt longlistjobs         # display PID when suspending processes as well
 280 setopt notify               # report the status of backgrounds jobs immediately
 281 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 282                             # the entire command path is hashed first.
 283 setopt completeinword       # not just at the end
 284 setopt nohup                # and don't kill them, either
 285 setopt auto_pushd           # make cd push the old directory onto the directory stack.
 286 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 287 setopt nobeep               # avoid "beep"ing
 288 setopt pushd_ignore_dups    # don't push the same dir twice.
 289 setopt noglobdots           # * shouldn't match dotfiles. ever.
 290 setopt noshwordsplit        # use zsh style word splitting
 291 setopt unset                # don't error out when unset parameters are used
 292
 293 # }}}
 294
 295 # setting some default values {{{
 296
 297 NOCOR=${NOCOR:-0}
 298 NOMENU=${NOMENU:-0}
 299 NOPRECMD=${NOPRECMD:-0}
 300 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 301 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 302 BATTERY=${BATTERY:-0}
 303 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 304 GRML_ALWAYS_LOAD_ALL=${GRML_ALWAYS_LOAD_ALL:-0}
 305 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 306
 307 # }}}
 308
 309 # utility functions {{{
 310 # this function checks if a command exists and returns either true
 311 # or false. This avoids using 'which' and 'whence', which will
 312 # avoid problems with aliases for which on certain weird systems. :-)
 313 # Usage: check_com [-c|-g] word
 314 #   -c  only checks for external commands
 315 #   -g  does the usual tests and also checks for global aliases
 316 check_com() {
 317     emulate -L zsh
 318     local -i comonly gatoo
 319
 320     if [[ $1 == '-c' ]] ; then
 321         (( comonly = 1 ))
 322         shift
 323     elif [[ $1 == '-g' ]] ; then
 324         (( gatoo = 1 ))
 325     else
 326         (( comonly = 0 ))
 327         (( gatoo = 0 ))
 328     fi
 329
 330     if (( ${#argv} != 1 )) ; then
 331         printf 'usage: check_com [-c] <command>\n' >&2
 332         return 1
 333     fi
 334
 335     if (( comonly > 0 )) ; then
 336         [[ -n ${commands[$1]}  ]] && return 0
 337         return 1
 338     fi
 339
 340     if   [[ -n ${commands[$1]}    ]] \
 341       || [[ -n ${functions[$1]}   ]] \
 342       || [[ -n ${aliases[$1]}     ]] \
 343       || [[ -n ${reswords[(r)$1]} ]] ; then
 344
 345         return 0
 346     fi
 347
 348     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 349         return 0
 350     fi
 351
 352     return 1
 353 }
 354
 355 # creates an alias and precedes the command with
 356 # sudo if $EUID is not zero.
 357 salias() {
 358     emulate -L zsh
 359     local only=0 ; local multi=0
 360     while [[ $1 == -* ]] ; do
 361         case $1 in
 362             (-o) only=1 ;;
 363             (-a) multi=1 ;;
 364             (--) shift ; break ;;
 365             (-h)
 366                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 367                 printf '  -h      shows this help text.\n'
 368                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 369                 printf '          be careful using this option.\n'
 370                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 371                 return 0
 372                 ;;
 373             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 374         esac
 375         shift
 376     done
 377
 378     if (( ${#argv} > 1 )) ; then
 379         printf 'Too many arguments %s\n' "${#argv}"
 380         return 1
 381     fi
 382
 383     key="${1%%\=*}" ;  val="${1#*\=}"
 384     if (( EUID == 0 )) && (( only == 0 )); then
 385         alias -- "${key}=${val}"
 386     elif (( EUID > 0 )) ; then
 387         (( multi > 0 )) && val="${val// ; / ; sudo }"
 388         alias -- "${key}=sudo ${val}"
 389     fi
 390
 391     return 0
 392 }
 393
 394 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 395 # usage: uprint foo
 396 #   Where foo is the *name* of the parameter you want printed.
 397 #   Note that foo is no typo; $foo would be wrong here!
 398 if ! is42 ; then
 399     uprint () {
 400         emulate -L zsh
 401         local -a u
 402         local w
 403         local parameter=$1
 404
 405         if [[ -z ${parameter} ]] ; then
 406             printf 'usage: uprint <parameter>\n'
 407             return 1
 408         fi
 409
 410         for w in ${(P)parameter} ; do
 411             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 412         done
 413
 414         builtin print -l $u
 415     }
 416 fi
 417
 418 # Check if we can read given files and source those we can.
 419 xsource() {
 420     if (( ${#argv} < 1 )) ; then
 421         printf 'usage: xsource FILE(s)...\n' >&2
 422         return 1
 423     fi
 424
 425     while (( ${#argv} > 0 )) ; do
 426         [[ -r "$1" ]] && source "$1"
 427         shift
 428     done
 429     return 0
 430 }
 431
 432 # Check if we can read a given file and 'cat(1)' it.
 433 xcat() {
 434     emulate -L zsh
 435     if (( ${#argv} != 1 )) ; then
 436         printf 'usage: xcat FILE\n' >&2
 437         return 1
 438     fi
 439
 440     [[ -r $1 ]] && cat $1
 441     return 0
 442 }
 443
 444 # Remove these functions again, they are of use only in these
 445 # setup files. This should be called at the end of .zshrc.
 446 xunfunction() {
 447     emulate -L zsh
 448     local -a funcs
 449     funcs=(salias xcat xsource xunfunction zrcautoload)
 450
 451     for func in $funcs ; do
 452         [[ -n ${functions[$func]} ]] \
 453             && unfunction $func
 454     done
 455     return 0
 456 }
 457
 458 # this allows us to stay in sync with grml's zshrc and put own
 459 # modifications in ~/.zshrc.local
 460 zrclocal() {
 461     xsource "/etc/zsh/zshrc.local"
 462     xsource "${HOME}/.zshrc.local"
 463     return 0
 464 }
 465
 466 #}}}
 467
 468 # locale setup {{{
 469 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 470     xsource "/etc/default/locale"
 471 fi
 472
 473 for var in LANG LC_ALL LC_MESSAGES ; do
 474     [[ -n ${(P)var} ]] && export $var
 475 done
 476
 477 xsource "/etc/sysconfig/keyboard"
 478
 479 TZ=$(xcat /etc/timezone)
 480 # }}}
 481
 482 # {{{ set some variables
 483 if check_com -c vim ; then
 484 #v#
 485     export EDITOR=${EDITOR:-vim}
 486 else
 487     export EDITOR=${EDITOR:-vi}
 488 fi
 489
 490 #v#
 491 export PAGER=${PAGER:-less}
 492
 493 #v#
 494 export MAIL=${MAIL:-/var/mail/$USER}
 495
 496 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 497 export SHELL='/bin/zsh'
 498
 499 # color setup for ls:
 500 check_com -c dircolors && eval $(dircolors -b)
 501 # color setup for ls on OS X:
 502 isdarwin && export CLICOLOR=1
 503
 504 # do MacPorts setup on darwin
 505 if isdarwin && [[ -d /opt/local ]]; then
 506     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 507     # zshenv.
 508     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 509     MANPATH="/opt/local/share/man:$MANPATH"
 510 fi
 511 # do Fink setup on darwin
 512 isdarwin && xsource /sw/bin/init.sh
 513
 514 # load our function and completion directories
 515 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 516     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 517     if [[ ${fpath} == '/usr/share/grml/zsh/functions' ]] ; then
 518         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 519             zrcautoload ${func:t}
 520         done
 521     fi
 522 done
 523 unset fdir func
 524
 525 # support colors in less
 526 export LESS_TERMCAP_mb=$'\E[01;31m'
 527 export LESS_TERMCAP_md=$'\E[01;31m'
 528 export LESS_TERMCAP_me=$'\E[0m'
 529 export LESS_TERMCAP_se=$'\E[0m'
 530 export LESS_TERMCAP_so=$'\E[01;44;33m'
 531 export LESS_TERMCAP_ue=$'\E[0m'
 532 export LESS_TERMCAP_us=$'\E[01;32m'
 533
 534 MAILCHECK=30       # mailchecks
 535 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 536 watch=(notme root) # watch for everyone but me and root
 537
 538 # automatically remove duplicates from these arrays
 539 typeset -U path cdpath fpath manpath
 540 # }}}
 541
 542 # {{{ keybindings
 543 if [[ "$TERM" != emacs ]] ; then
 544     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 545     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 546     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 547     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 548     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 549     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 550     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 551     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 552     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 553     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 554     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 555     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 556     # ncurses stuff:
 557     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 558     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 559     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 560     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 561     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 562     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 563     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 564     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 565 fi
 566
 567 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 568 # use emacs style per default:
 569 bindkey -e
 570 # use vi style:
 571 # bindkey -v
 572
 573 #if [[ "$TERM" == screen ]] ; then
 574 bindkey '\e[1~' beginning-of-line       # home
 575 bindkey '\e[4~' end-of-line             # end
 576 bindkey '\e[A'  up-line-or-search       # cursor up
 577 bindkey '\e[B'  down-line-or-search     # <ESC>-
 578
 579 bindkey '^xp'   history-beginning-search-backward
 580 bindkey '^xP'   history-beginning-search-forward
 581 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 582 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 583 # if terminal type is set to 'rxvt':
 584 bindkey '\e[7~' beginning-of-line       # home
 585 bindkey '\e[8~' end-of-line             # end
 586 #fi
 587
 588 # insert unicode character
 589 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 590 # See for example http://unicode.org/charts/ for unicode characters code
 591 zrcautoload insert-unicode-char
 592 zle -N insert-unicode-char
 593 #k# Insert Unicode character
 594 bindkey '^Xi' insert-unicode-char
 595
 596 #m# k Shift-tab Perform backwards menu completion
 597 if [[ -n "$terminfo[kcbt]" ]]; then
 598     bindkey "$terminfo[kcbt]" reverse-menu-complete
 599 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 600     bindkey "$terminfo[cbt]"  reverse-menu-complete
 601 fi
 602
 603 ## toggle the ,. abbreviation feature on/off
 604 # NOABBREVIATION: default abbreviation-state
 605 #                 0 - enabled (default)
 606 #                 1 - disabled
 607 NOABBREVIATION=${NOABBREVIATION:-0}
 608
 609 grml_toggle_abbrev() {
 610     if (( ${NOABBREVIATION} > 0 )) ; then
 611         NOABBREVIATION=0
 612     else
 613         NOABBREVIATION=1
 614     fi
 615 }
 616
 617 zle -N grml_toggle_abbrev
 618 bindkey '^xA' grml_toggle_abbrev
 619
 620 # add a command line to the shells history without executing it
 621 commit-to-history() {
 622     print -s ${(z)BUFFER}
 623     zle send-break
 624 }
 625 zle -N commit-to-history
 626 bindkey "^x^h" commit-to-history
 627
 628 # only slash should be considered as a word separator:
 629 slash-backward-kill-word() {
 630     local WORDCHARS="${WORDCHARS:s@/@}"
 631     # zle backward-word
 632     zle backward-kill-word
 633 }
 634 zle -N slash-backward-kill-word
 635
 636 #k# Kill everything in a word up to its last \kbd{/}
 637 bindkey '\ev' slash-backward-kill-word
 638 #k# Kill everything in a word up to its last \kbd{/}
 639 bindkey '\e^h' slash-backward-kill-word
 640 #k# Kill everything in a word up to its last \kbd{/}
 641 bindkey '\e^?' slash-backward-kill-word
 642
 643 # use the new *-pattern-* widgets for incremental history search
 644 if is439 ; then
 645     bindkey '^r' history-incremental-pattern-search-backward
 646     bindkey '^s' history-incremental-pattern-search-forward
 647 fi
 648 # }}}
 649
 650 # a generic accept-line wrapper {{{
 651
 652 # This widget can prevent unwanted autocorrections from command-name
 653 # to _command-name, rehash automatically on enter and call any number
 654 # of builtin and user-defined widgets in different contexts.
 655 #
 656 # For a broader description, see:
 657 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 658 #
 659 # The code is imported from the file 'zsh/functions/accept-line' from
 660 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 661 # distributed under the same terms as zsh itself.
 662
 663 # A newly added command will may not be found or will cause false
 664 # correction attempts, if you got auto-correction set. By setting the
 665 # following style, we force accept-line() to rehash, if it cannot
 666 # find the first word on the command line in the $command[] hash.
 667 zstyle ':acceptline:*' rehash true
 668
 669 function Accept-Line() {
 670     emulate -L zsh
 671     local -a subs
 672     local -xi aldone
 673     local sub
 674
 675     zstyle -a ":acceptline:${alcontext}" actions subs
 676
 677     (( ${#subs} < 1 )) && return 0
 678
 679     (( aldone = 0 ))
 680     for sub in ${subs} ; do
 681         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 682         zle ${sub}
 683
 684         (( aldone > 0 )) && break
 685     done
 686 }
 687
 688 function Accept-Line-getdefault() {
 689     emulate -L zsh
 690     local default_action
 691
 692     zstyle -s ":acceptline:${alcontext}" default_action default_action
 693     case ${default_action} in
 694         ((accept-line|))
 695             printf ".accept-line"
 696             ;;
 697         (*)
 698             printf ${default_action}
 699             ;;
 700     esac
 701 }
 702
 703 function accept-line() {
 704     emulate -L zsh
 705     local -a cmdline
 706     local -x alcontext
 707     local buf com fname format msg default_action
 708
 709     alcontext='default'
 710     buf="${BUFFER}"
 711     cmdline=(${(z)BUFFER})
 712     com="${cmdline[1]}"
 713     fname="_${com}"
 714
 715     zstyle -t ":acceptline:${alcontext}" rehash \
 716         && [[ -z ${commands[$com]} ]]           \
 717         && rehash
 718
 719     if    [[ -n ${reswords[(r)$com]} ]] \
 720        || [[ -n ${aliases[$com]}     ]] \
 721        || [[ -n ${functions[$com]}   ]] \
 722        || [[ -n ${builtins[$com]}    ]] \
 723        || [[ -n ${commands[$com]}    ]] ; then
 724
 725         # there is something sensible to execute, just do it.
 726         alcontext='normal'
 727         zle Accept-Line
 728
 729         default_action=$(Accept-Line-getdefault)
 730         zstyle -T ":acceptline:${alcontext}" call_default \
 731             && zle ${default_action}
 732         return
 733     fi
 734
 735     if    [[ -o correct              ]] \
 736        || [[ -o correctall           ]] \
 737        && [[ -n ${functions[$fname]} ]] ; then
 738
 739         # nothing there to execute but there is a function called
 740         # _command_name; a completion widget. Makes no sense to
 741         # call it on the commandline, but the correct{,all} options
 742         # will ask for it nevertheless, so warn the user.
 743         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 744             # Okay, we warned the user before, he called us again,
 745             # so have it his way.
 746             alcontext='force'
 747             zle Accept-Line
 748
 749             default_action=$(Accept-Line-getdefault)
 750             zstyle -T ":acceptline:${alcontext}" call_default \
 751                 && zle ${default_action}
 752             return
 753         fi
 754
 755         # prepare warning message for the user, configurable via zstyle.
 756         zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 757
 758         if [[ -z ${msg} ]] ; then
 759             msg="%c will not execute and completion %f exists."
 760         fi
 761
 762         zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 763
 764         zle -M -- "${msg}"
 765         return
 766     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 767         # If we are here, the commandline contains something that is not
 768         # executable, which is neither subject to _command_name correction
 769         # and is not empty. might be a variable assignment
 770         alcontext='misc'
 771         zle Accept-Line
 772
 773         default_action=$(Accept-Line-getdefault)
 774         zstyle -T ":acceptline:${alcontext}" call_default \
 775             && zle ${default_action}
 776         return
 777     fi
 778
 779     # If we got this far, the commandline only contains whitespace, or is empty.
 780     alcontext='empty'
 781     zle Accept-Line
 782
 783     default_action=$(Accept-Line-getdefault)
 784     zstyle -T ":acceptline:${alcontext}" call_default \
 785         && zle ${default_action}
 786 }
 787
 788 zle -N accept-line
 789 zle -N Accept-Line
 790
 791 # }}}
 792
 793 # power completion - abbreviation expansion {{{
 794 # power completion / abbreviation expansion / buffer expansion
 795 # see http://zshwiki.org/home/examples/zleiab for details
 796 # less risky than the global aliases but powerful as well
 797 # just type the abbreviation key and afterwards ',.' to expand it
 798 declare -A abk
 799 setopt extendedglob
 800 setopt interactivecomments
 801 abk=(
 802 #   key   # value                  (#d additional doc string)
 803 #A# start
 804     '...'  '../..'
 805     '....' '../../..'
 806     'BG'   '& exit'
 807     'C'    '| wc -l'
 808     'G'    '|& grep --color=auto '
 809     'H'    '| head'
 810     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 811     'L'    '| less'
 812     'LL'   '|& less -r'
 813     'M'    '| most'
 814     'N'    '&>/dev/null'           #d (No Output)
 815     'R'    '| tr A-z N-za-m'       #d (ROT13)
 816     'SL'   '| sort | less'
 817     'S'    '| sort -u'
 818     'T'    '| tail'
 819     'V'    '|& vim -'
 820 #A# end
 821     'co'   './configure && make && sudo make install'
 822 )
 823
 824 globalias() {
 825     emulate -L zsh
 826     setopt extendedglob
 827     local MATCH
 828
 829     if (( NOABBREVIATION > 0 )) ; then
 830         LBUFFER="${LBUFFER},."
 831         return 0
 832     fi
 833
 834     matched_chars='[.-|_a-zA-Z0-9]#'
 835     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 836     LBUFFER+=${abk[$MATCH]:-$MATCH}
 837 }
 838
 839 zle -N globalias
 840 bindkey ",." globalias
 841 # }}}
 842
 843 # {{{ autoloading
 844 zrcautoload zmv    # who needs mmv or rename?
 845 zrcautoload history-search-end
 846
 847 # we don't want to quote/espace URLs on our own...
 848 # if autoload -U url-quote-magic ; then
 849 #    zle -N self-insert url-quote-magic
 850 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 851 # else
 852 #    print 'Notice: no url-quote-magic available :('
 853 # fi
 854 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 855
 856 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 857 alias run-help >&/dev/null && unalias run-help
 858 for rh in run-help{,-git,-svk,-svn}; do
 859     zrcautoload $rh
 860 done; unset rh
 861
 862 # completion system
 863 if zrcautoload compinit ; then
 864     compinit || print 'Notice: no compinit available :('
 865 else
 866     print 'Notice: no compinit available :('
 867     function zstyle { }
 868     function compdef { }
 869 fi
 870
 871 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 872
 873 is4 && \
 874 for mod in complist deltochar mathfunc ; do
 875     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 876 done
 877
 878 # autoload zsh modules when they are referenced
 879 if is4 ; then
 880     zmodload -a  zsh/stat    zstat
 881     zmodload -a  zsh/zpty    zpty
 882     zmodload -ap zsh/mapfile mapfile
 883 fi
 884
 885 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 886     #k# Insert files
 887     bindkey "^Xf" insert-files # C-x-f
 888 fi
 889
 890 bindkey ' '   magic-space    # also do history expansion on space
 891 #k# Trigger menu-complete
 892 bindkey '\ei' menu-complete  # menu completion via esc-i
 893
 894 # press esc-e for editing command line in $EDITOR or $VISUAL
 895 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 896     #k# Edit the current line in \kbd{\$EDITOR}
 897     bindkey '\ee' edit-command-line
 898 fi
 899
 900 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 901     #k# menu selection: pick item but stay in the menu
 902     bindkey -M menuselect '\e^M' accept-and-menu-complete
 903
 904     # accept a completion and try to complete again by using menu
 905     # completion; very useful with completing directories
 906     # by using 'undo' one's got a simple file browser
 907     bindkey -M menuselect '^o' accept-and-infer-next-history
 908 fi
 909
 910 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 911 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
 912 zle -N insert-datestamp
 913
 914 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 915 bindkey '^Ed' insert-datestamp
 916
 917 # press esc-m for inserting last typed word again (thanks to caphuso!)
 918 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 919 zle -N insert-last-typed-word;
 920
 921 #k# Insert last typed word
 922 bindkey "\em" insert-last-typed-word
 923
 924 function grml-zsh-fg() {
 925   if (( ${#jobstates} )); then
 926     zle .push-input
 927     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
 928     BUFFER="${BUFFER}fg"
 929     zle .accept-line
 930   else
 931     zle -M 'No background jobs. Doing nothing.'
 932   fi
 933 }
 934 zle -N grml-zsh-fg
 935 #k# A smart shortcut for \kbd{fg<enter>}
 936 bindkey '^z' grml-zsh-fg
 937
 938 # run command line as user root via sudo:
 939 sudo-command-line() {
 940     [[ -z $BUFFER ]] && zle up-history
 941     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
 942 }
 943 zle -N sudo-command-line
 944
 945 #k# Put the current command line into a \kbd{sudo} call
 946 bindkey "^Os" sudo-command-line
 947
 948 ### jump behind the first word on the cmdline.
 949 ### useful to add options.
 950 function jump_after_first_word() {
 951     local words
 952     words=(${(z)BUFFER})
 953
 954     if (( ${#words} <= 1 )) ; then
 955         CURSOR=${#BUFFER}
 956     else
 957         CURSOR=${#${words[1]}}
 958     fi
 959 }
 960 zle -N jump_after_first_word
 961
 962 bindkey '^x1' jump_after_first_word
 963
 964 # }}}
 965
 966 # {{{ history
 967
 968 ZSHDIR=$HOME/.zsh
 969
 970 #v#
 971 HISTFILE=$HOME/.zsh_history
 972 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
 973 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
 974
 975 # }}}
 976
 977 # dirstack handling {{{
 978
 979 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
 980 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
 981
 982 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
 983     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
 984     # "cd -" won't work after login by just setting $OLDPWD, so
 985     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
 986 fi
 987
 988 chpwd() {
 989     local -ax my_stack
 990     my_stack=( ${PWD} ${dirstack} )
 991     if is42 ; then
 992         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
 993     else
 994         uprint my_stack >! ${DIRSTACKFILE}
 995     fi
 996 }
 997
 998 # }}}
 999
1000 # directory based profiles {{{
1001
1002 if is433 ; then
1003
1004 CHPWD_PROFILE='default'
1005 function chpwd_profiles() {
1006     # Say you want certain settings to be active in certain directories.
1007     # This is what you want.
1008     #
1009     # zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1010     # zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1011     #
1012     # When that's done and you enter a directory that matches the pattern
1013     # in the third part of the context, a function called chpwd_profile_grml,
1014     # for example, is called (if it exists).
1015     #
1016     # If no pattern matches (read: no profile is detected) the profile is
1017     # set to 'default', which means chpwd_profile_default is attempted to
1018     # be called.
1019     #
1020     # A word about the context (the ':chpwd:profiles:*' stuff in the zstyle
1021     # command) which is used: The third part in the context is matched against
1022     # ${PWD}. That's why using a pattern such as /foo/bar(|/|/*) makes sense.
1023     # Because that way the profile is detected for all these values of ${PWD}:
1024     #   /foo/bar
1025     #   /foo/bar/
1026     #   /foo/bar/baz
1027     # So, if you want to make double damn sure a profile works in /foo/bar
1028     # and everywhere deeper in that tree, just use (|/|/*) and be happy.
1029     #
1030     # The name of the detected profile will be available in a variable called
1031     # 'profile' in your functions. You don't need to do anything, it'll just
1032     # be there.
1033     #
1034     # Then there is the parameter $CHPWD_PROFILE is set to the profile, that
1035     # was is currently active. That way you can avoid running code for a
1036     # profile that is already active, by running code such as the following
1037     # at the start of your function:
1038     #
1039     # function chpwd_profile_grml() {
1040     #     [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1041     #   ...
1042     # }
1043     #
1044     # The initial value for $CHPWD_PROFILE is 'default'.
1045     #
1046     # Version requirement:
1047     #   This feature requires zsh 4.3.3 or newer.
1048     #   If you use this feature and need to know whether it is active in your
1049     #   current shell, there are several ways to do that. Here are two simple
1050     #   ways:
1051     #
1052     #   a) If knowing if the profiles feature is active when zsh starts is
1053     #      good enough for you, you can put the following snippet into your
1054     #      .zshrc.local:
1055     #
1056     #   (( ${+functions[chpwd_profiles]} )) && print "directory profiles active"
1057     #
1058     #   b) If that is not good enough, and you would prefer to be notified
1059     #      whenever a profile changes, you can solve that by making sure you
1060     #      start *every* profile function you create like this:
1061     #
1062     #   function chpwd_profile_myprofilename() {
1063     #       [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1064     #       print "chpwd(): Switching to profile: $profile"
1065     #     ...
1066     #   }
1067     #
1068     #      That makes sure you only get notified if a profile is *changed*,
1069     #      not everytime you change directory, which would probably piss
1070     #      you off fairly quickly. :-)
1071     #
1072     # There you go. Now have fun with that.
1073     local -x profile
1074
1075     zstyle -s ":chpwd:profiles:${PWD}" profile profile || profile='default'
1076     if (( ${+functions[chpwd_profile_$profile]} )) ; then
1077         chpwd_profile_${profile}
1078     fi
1079
1080     CHPWD_PROFILE="${profile}"
1081     return 0
1082 }
1083 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1084
1085 fi # is433
1086
1087 # }}}
1088
1089 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
1090 if [[ $BATTERY -gt 0 ]] ; then
1091     if ! check_com -c acpi ; then
1092         BATTERY=0
1093     fi
1094 fi
1095
1096 battery() {
1097 if [[ $BATTERY -gt 0 ]] ; then
1098     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1099     if [[ -z "$PERCENT" ]] ; then
1100         PERCENT='acpi not present'
1101     else
1102         if [[ "$PERCENT" -lt 20 ]] ; then
1103             PERCENT="warning: ${PERCENT}%%"
1104         else
1105             PERCENT="${PERCENT}%%"
1106         fi
1107     fi
1108 fi
1109 }
1110 # }}}
1111
1112 # set colors for use in prompts {{{
1113 if zrcautoload colors && colors 2>/dev/null ; then
1114     BLUE="%{${fg[blue]}%}"
1115     RED="%{${fg_bold[red]}%}"
1116     GREEN="%{${fg[green]}%}"
1117     CYAN="%{${fg[cyan]}%}"
1118     MAGENTA="%{${fg[magenta]}%}"
1119     YELLOW="%{${fg[yellow]}%}"
1120     WHITE="%{${fg[white]}%}"
1121     NO_COLOUR="%{${reset_color}%}"
1122 else
1123     BLUE=$'%{\e[1;34m%}'
1124     RED=$'%{\e[1;31m%}'
1125     GREEN=$'%{\e[1;32m%}'
1126     CYAN=$'%{\e[1;36m%}'
1127     WHITE=$'%{\e[1;37m%}'
1128     MAGENTA=$'%{\e[1;35m%}'
1129     YELLOW=$'%{\e[1;33m%}'
1130     NO_COLOUR=$'%{\e[0m%}'
1131 fi
1132
1133 # }}}
1134
1135 # gather version control information for inclusion in a prompt {{{
1136
1137 if ! is41 ; then
1138     # Be quiet about version problems in grml's zshrc as the user cannot disable
1139     # loading vcs_info() as it is *in* the zshrc - as you can see. :-)
1140     # Just unset most probable variables and disable vcs_info altogether.
1141     local -i i
1142     for i in {0..9} ; do
1143         unset VCS_INFO_message_${i}_
1144     done
1145     zstyle ':vcs_info:*' enable false
1146 fi
1147
1148 if zrcautoload vcs_info; then
1149     GRML_VCS_INFO=0
1150     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1151     # function, which can cause a lot of trouble with our directory-based
1152     # profiles. So:
1153     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1154         function VCS_INFO_realpath () {
1155             setopt localoptions NO_shwordsplit chaselinks
1156             ( builtin cd -q $1 2> /dev/null && pwd; )
1157         }
1158     fi
1159 else
1160 # I'm not reindenting the whole code below.
1161 GRML_VCS_INFO=1
1162
1163 # The following code is imported from the file 'zsh/functions/vcs_info'
1164 # from <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>,
1165 # which distributed under the same terms as zsh itself.
1166
1167 # we will be using two variables, so let the code know now.
1168 zstyle ':vcs_info:*' max-exports 2
1169
1170 # vcs_info() documentation:
1171 #{{{
1172 # REQUIREMENTS:
1173 #{{{
1174 #     This functionality requires zsh version >= 4.1.*.
1175 #}}}
1176 #
1177 # LOADING:
1178 #{{{
1179 # To load vcs_info(), copy this file to your $fpath[] and do:
1180 #   % autoload -Uz vcs_info && vcs_info
1181 #
1182 # To work, vcs_info() needs 'setopt prompt_subst' in your setup.
1183 #}}}
1184 #
1185 # QUICKSTART:
1186 #{{{
1187 # To get vcs_info() working quickly (including colors), you can do the
1188 # following (assuming, you loaded vcs_info() properly - see above):
1189 #
1190 # % RED=$'%{\e[31m%}'
1191 # % GR=$'%{\e[32m%}'
1192 # % MA=$'%{\e[35m%}'
1193 # % YE=$'%{\e[33m%}'
1194 # % NC=$'%{\e[0m%}'
1195 #
1196 # % zstyle ':vcs_info:*' actionformats \
1197 #       "${MA}(${NC}%s${MA})${YE}-${MA}[${GR}%b${YE}|${RED}%a${MA}]${NC} "
1198 #
1199 # % zstyle ':vcs_info:*' formats       \
1200 #       "${MA}(${NC}%s${MA})${Y}-${MA}[${GR}%b${MA}]${NC}%} "
1201 #
1202 # % zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YE}%r"
1203 #
1204 # % precmd () { vcs_info }
1205 # % PS1='${MA}[${GR}%n${MA}] ${MA}(${RED}%!${MA}) ${YE}%3~ ${VCS_INFO_message_0_}${NC}%# '
1206 #
1207 # Obviously, the las two lines are there for demonstration: You need to
1208 # call vcs_info() from your precmd() function (see 'SPECIAL FUNCTIONS' in
1209 # 'man zshmisc'). Once that is done you need a *single* quoted
1210 # '${VCS_INFO_message_0_}' in your prompt.
1211 #
1212 # Now call the 'vcs_info_printsys' utility from the command line:
1213 #
1214 # % vcs_info_printsys
1215 # # list of supported version control backends:
1216 # # disabled systems are prefixed by a hash sign (#)
1217 # git
1218 # hg
1219 # bzr
1220 # darcs
1221 # svk
1222 # mtn
1223 # svn
1224 # cvs
1225 # cdv
1226 # tla
1227 # # flavours (cannot be used in the disable style; they
1228 # # are disabled with their master [git-svn -> git]):
1229 # git-p4
1230 # git-svn
1231 #
1232 # Ten version control backends as you can see. You may not want all
1233 # of these. Because there is no point in running the code to detect
1234 # systems you do not use. ever. So, there is a way to disable some
1235 # backends altogether:
1236 #
1237 # % zstyle ':vcs_info:*' disable bzr cdv darcs mtn svk tla
1238 #
1239 # If you rerun 'vcs_info_printsys' now, you will see the backends listed
1240 # in the 'disable' style marked as diabled by a hash sign. That means the
1241 # detection of these systems is skipped *completely*. No wasted time there.
1242 #
1243 # For more control, read the reference below.
1244 #}}}
1245 #
1246 # CONFIGURATION:
1247 #{{{
1248 # The vcs_info() feature can be configured via zstyle.
1249 #
1250 # First, the context in which we are working:
1251 #       :vcs_info:<vcs-string>:<user-context>
1252 #
1253 # ...where <vcs-string> is one of:
1254 #   - git, git-svn, git-p4, hg, darcs, bzr, cdv, mtn, svn, cvs, svk or tla.
1255 #
1256 # ...and <user-context> is a freely configurable string, assignable by the
1257 # user as the first argument to vcs_info() (see its description below).
1258 #
1259 # There is are three special values for <vcs-string>: The first is named
1260 # 'init', that is in effect as long as there was no decision what vcs
1261 # backend to use. The second is 'preinit; it is used *before* vcs_info()
1262 # is run, when initializing the data exporting variables. The third
1263 # special value is 'formats' and is used by the 'vcs_info_lastmsg' for
1264 # looking up its styles.
1265 #
1266 # There are two pre-defined values for <user-context>:
1267 #   default  - the one used if none is specified
1268 #   command  - used by vcs_info_lastmsg to lookup its styles.
1269 #
1270 # You may *not* use 'print_systems_' as a user-context string, because it
1271 # is used internally.
1272 #
1273 # You can of course use ':vcs_info:*' to match all VCSs in all
1274 # user-contexts at once.
1275 #
1276 # Another special context is 'formats', which is used by the
1277 # vcs_info_lastmsg() utility function (see below).
1278 #
1279 #
1280 # This is a description of all styles, that are looked up:
1281 #   formats             - A list of formats, used when actionformats is not
1282 #                         used (which is most of the time).
1283 #   actionformats       - A list of formats, used if a there is a special
1284 #                         action going on in your current repository;
1285 #                         (like an interactive rebase or a merge conflict)
1286 #   branchformat        - Some backends replace %b in the formats and
1287 #                         actionformats styles above, not only by a branch
1288 #                         name but also by a revision number. This style
1289 #                         let's you modify how that string should look like.
1290 #   nvcsformats         - These "formats" are exported, when we didn't detect
1291 #                         a version control system for the current directory.
1292 #                         This is useful, if you want vcs_info() to completely
1293 #                         take over the generation of your prompt.
1294 #                         You would do something like
1295 #                           PS1='${VCS_INFO_message_0_}'
1296 #                         to accomplish that.
1297 #   max-exports         - Defines the maximum number if VCS_INFO_message_*_
1298 #                         variables vcs_info() will export.
1299 #   enable              - Checked in the 'init' context. If set to false,
1300 #                         vcs_info() will do nothing.
1301 #   disable             - Provide a list of systems, you don't want
1302 #                         the vcs_info() to check for repositories
1303 #                         (checked in the 'init' context, too).
1304 #   disable-patterns    - A list of patterns that are checked against $PWD.
1305 #                         If the pattern matches, vcs_info will be disabled.
1306 #                         Say, ~/.zsh is a directory under version control,
1307 #                         in which you do not want vcs_info to be active, do:
1308 #                         zstyle ':vcs_info:*' disable-patterns "$HOME/.zsh+(|/*)"
1309 #   use-simple          - If there are two different ways of gathering
1310 #                         information, you can select the simpler one
1311 #                         by setting this style to true; the default
1312 #                         is to use the not-that-simple code, which is
1313 #                         potentially a lot slower but might be more
1314 #                         accurate in all possible cases.
1315 #   use-prompt-escapes  - determines if we assume that the assembled
1316 #                         string from vcs_info() includes prompt escapes.
1317 #                         (Used by vcs_info_lastmsg().
1318 #
1319 # The use-simple style is only available for the bzr backend.
1320 #
1321 # The default values for these in all contexts are:
1322 #   formats             " (%s)-[%b|%a]-"
1323 #   actionformats       " (%s)-[%b]-"
1324 #   branchformat        "%b:%r" (for bzr, svn and svk)
1325 #   nvcsformats         ""
1326 #   max-exports         2
1327 #   enable              true
1328 #   disable             (empty list)
1329 #   disable-patterns    (empty list)
1330 #   use-simple          false
1331 #   use-prompt-escapes  true
1332 #
1333 #
1334 # In normal formats and actionformats, the following replacements
1335 # are done:
1336 #   %s  - The vcs in use (git, hg, svn etc.)
1337 #   %b  - Information about the current branch.
1338 #   %a  - An identifier, that describes the action.
1339 #         Only makes sense in actionformats.
1340 #   %R  - base directory of the repository.
1341 #   %r  - repository name
1342 #         If %R is '/foo/bar/repoXY', %r is 'repoXY'.
1343 #   %S  - subdirectory within a repository. if $PWD is
1344 #         '/foo/bar/reposXY/beer/tasty', %S is 'beer/tasty'.
1345 #
1346 #
1347 # In branchformat these replacements are done:
1348 #   %b  - the branch name
1349 #   %r  - the current revision number
1350 #
1351 # Not all vcs backends have to support all replacements.
1352 # nvcsformat does not perform *any* replacements. It is just a string.
1353 #}}}
1354 #
1355 # ODDITIES:
1356 #{{{
1357 # If you want to use the %b (bold off) prompt expansion in 'formats', which
1358 # expands %b itself, use %%b. That will cause the vcs_info() expansion to
1359 # replace %%b with %b. So zsh's prompt expansion mechanism can handle it.
1360 # Similarly, to hand down %b from branchformat, use %%%%b. Sorry for this
1361 # inconvenience, but it cannot be easily avoided. Luckily we do not clash
1362 # with a lot of prompt expansions and this only needs to be done for those.
1363 # See 'man zshmisc' for details about EXPANSION OF PROMPT SEQUENCES.
1364 #}}}
1365 #
1366 # FUNCTION DESCRIPTIONS (public API):
1367 #{{{
1368 #   vcs_info()
1369 #       The main function, that runs all backends and assembles
1370 #       all data into ${VCS_INFO_message_*_}. This is the function
1371 #       you want to call from precmd() if you want to include
1372 #       up-to-date information in your prompt (see VARIABLE
1373 #       DESCRIPTION below).
1374 #
1375 #   vcs_info_printsys()
1376 #       Prints a list of all supported version control systems.
1377 #       Useful to find out possible contexts (and which of them are enabled)
1378 #       or values for the 'disable' style.
1379 #
1380 #   vcs_info_lastmsg()
1381 #       Outputs the last ${VCS_INFO_message_*_} value. Takes into account
1382 #       the value of the use-prompt-escapes style in ':vcs_info:formats'.
1383 #       It also only prints max-exports values.
1384 #
1385 # All functions named VCS_INFO_* are for internal use only.
1386 #}}}
1387 #
1388 # VARIABLE DESCRIPTION:
1389 #{{{
1390 #   ${VCS_INFO_message_N_}    (Note the trailing underscore)
1391 #       Where 'N' is an integer, eg: VCS_INFO_message_0_
1392 #       These variables are the storage for the informational message the
1393 #       last vcs_info() call has assembled. These are strongly connected
1394 #       to the formats, actionformats and nvcsformats styles described
1395 #       above. Those styles are lists. the first member of that list gets
1396 #       expanded into ${VCS_INFO_message_0_}, the second into
1397 #       ${VCS_INFO_message_1_} and the Nth into ${VCS_INFO_message_N-1_}.
1398 #       These parameters are exported into the environment.
1399 #       (See the max-exports style above.)
1400 #}}}
1401 #
1402 # EXAMPLES:
1403 #{{{
1404 #   Don't use vcs_info at all (even though it's in your prompt):
1405 #   % zstyle ':vcs_info:*' enable false
1406 #
1407 #   Disable the backends for bzr and svk:
1408 #   % zstyle ':vcs_info:*' disable bzr svk
1409 #
1410 #   Provide a special formats for git:
1411 #   % zstyle ':vcs_info:git:*' formats       ' GIT, BABY! [%b]'
1412 #   % zstyle ':vcs_info:git:*' actionformats ' GIT ACTION! [%b|%a]'
1413 #
1414 #   Use the quicker bzr backend (if you do, please report if it does
1415 #   the-right-thing[tm] - thanks):
1416 #   % zstyle ':vcs_info:bzr:*' use-simple true
1417 #
1418 #   Display the revision number in yellow for bzr and svn:
1419 #   % zstyle ':vcs_info:(svn|bzr):*' branchformat '%b%{'${fg[yellow]}'%}:%r'
1420 #
1421 # If you want colors, make sure you enclose the color codes in %{...%},
1422 # if you want to use the string provided by vcs_info() in prompts.
1423 #
1424 # Here is how to print the vcs infomation as a command:
1425 #   % alias vcsi='vcs_info command; vcs_info_lastmsg'
1426 #
1427 #   This way, you can even define different formats for output via
1428 #   vcs_info_lastmsg() in the ':vcs_info:command:*' namespace.
1429 #}}}
1430 #}}}
1431 # utilities
1432 VCS_INFO_adjust () { #{{{
1433     [[ -n ${vcs_comm[overwrite_name]} ]] && vcs=${vcs_comm[overwrite_name]}
1434     return 0
1435 }
1436 # }}}
1437 VCS_INFO_check_com () { #{{{
1438     (( ${+commands[$1]} )) && [[ -x ${commands[$1]} ]] && return 0
1439     return 1
1440 }
1441 # }}}
1442 VCS_INFO_formats () { # {{{
1443     setopt localoptions noksharrays
1444     local action=$1 branch=$2 base=$3
1445     local msg
1446     local -i i
1447
1448     if [[ -n ${action} ]] ; then
1449         zstyle -a ":vcs_info:${vcs}:${usercontext}" actionformats msgs
1450         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b|%a]-'
1451     else
1452         zstyle -a ":vcs_info:${vcs}:${usercontext}" formats msgs
1453         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b]-'
1454     fi
1455
1456     (( ${#msgs} > maxexports )) && msgs[$(( maxexports + 1 )),-1]=()
1457     for i in {1..${#msgs}} ; do
1458         zformat -f msg ${msgs[$i]}                      \
1459                         a:${action}                     \
1460                         b:${branch}                     \
1461                         r:${base:t}                     \
1462                         s:${vcs}                        \
1463                         R:${base}                       \
1464                         S:"$(VCS_INFO_reposub ${base})"
1465         msgs[$i]=${msg}
1466     done
1467     return 0
1468 }
1469 # }}}
1470 VCS_INFO_maxexports () { #{{{
1471     zstyle -s ":vcs_info:${vcs}:${usercontext}" "max-exports" maxexports || maxexports=2
1472     if [[ ${maxexports} != <-> ]] || (( maxexports < 1 )); then
1473         printf 'vcs_info(): expecting numeric arg >= 1 for max-exports (got %s).\n' ${maxexports}
1474         printf 'Defaulting to 2.\n'
1475         maxexports=2
1476     fi
1477 }
1478 # }}}
1479 VCS_INFO_nvcsformats () { #{{{
1480     setopt localoptions noksharrays
1481     local c v
1482
1483     if [[ $1 == 'preinit' ]] ; then
1484         c=default
1485         v=preinit
1486     fi
1487     zstyle -a ":vcs_info:${v:-$vcs}:${c:-$usercontext}" nvcsformats msgs
1488     (( ${#msgs} > maxexports )) && msgs[${maxexports},-1]=()
1489 }
1490 # }}}
1491 VCS_INFO_realpath () { #{{{
1492     # a portable 'readlink -f'
1493     # forcing a subshell, to ensure chpwd() is not removed
1494     # from the calling shell (if VCS_INFO_realpath() is called
1495     # manually).
1496     (
1497         (( ${+functions[chpwd]} )) && unfunction chpwd
1498         setopt chaselinks
1499         cd $1 2>/dev/null && pwd
1500     )
1501 }
1502 # }}}
1503 VCS_INFO_reposub () { #{{{
1504     setopt localoptions extendedglob
1505     local base=${1%%/##}
1506
1507     [[ ${PWD} == ${base}/* ]] || {
1508         printf '.'
1509         return 1
1510     }
1511     printf '%s' ${PWD#$base/}
1512     return 0
1513 }
1514 # }}}
1515 VCS_INFO_set () { #{{{
1516     setopt localoptions noksharrays
1517     local -i i j
1518
1519     if [[ $1 == '--clear' ]] ; then
1520         for i in {0..9} ; do
1521             unset VCS_INFO_message_${i}_
1522         done
1523     fi
1524     if [[ $1 == '--nvcs' ]] ; then
1525         [[ $2 == 'preinit' ]] && (( maxexports == 0 )) && (( maxexports = 1 ))
1526         for i in {0..$((maxexports - 1))} ; do
1527             typeset -gx VCS_INFO_message_${i}_=
1528         done
1529         VCS_INFO_nvcsformats $2
1530     fi
1531
1532     (( ${#msgs} - 1 < 0 )) && return 0
1533     for i in {0..$(( ${#msgs} - 1 ))} ; do
1534         (( j = i + 1 ))
1535         typeset -gx VCS_INFO_message_${i}_=${msgs[$j]}
1536     done
1537     return 0
1538 }
1539 # }}}
1540 # information gathering
1541 VCS_INFO_bzr_get_data () { # {{{
1542     setopt localoptions noksharrays
1543     local bzrbase bzrbr
1544     local -a bzrinfo
1545
1546     if zstyle -t ":vcs_info:${vcs}:${usercontext}" "use-simple" ; then
1547         bzrbase=${vcs_comm[basedir]}
1548         bzrinfo[2]=${bzrbase:t}
1549         if [[ -f ${bzrbase}/.bzr/branch/last-revision ]] ; then
1550             bzrinfo[1]=$(< ${bzrbase}/.bzr/branch/last-revision)
1551             bzrinfo[1]=${${bzrinfo[1]}%% *}
1552         fi
1553     else
1554         bzrbase=${${(M)${(f)"$( bzr info )"}:# ##branch\ root:*}/*: ##/}
1555         bzrinfo=( ${${${(M)${(f)"$( bzr version-info )"}:#(#s)(revno|branch-nick)*}/*: /}/*\//} )
1556         bzrbase="$(VCS_INFO_realpath ${bzrbase})"
1557     fi
1558
1559     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat bzrbr || bzrbr="%b:%r"
1560     zformat -f bzrbr "${bzrbr}" "b:${bzrinfo[2]}" "r:${bzrinfo[1]}"
1561     VCS_INFO_formats '' "${bzrbr}" "${bzrbase}"
1562     return 0
1563 }
1564 # }}}
1565 VCS_INFO_cdv_get_data () { # {{{
1566     local cdvbase
1567
1568     cdvbase=${vcs_comm[basedir]}
1569     VCS_INFO_formats '' "${cdvbase:t}" "${cdvbase}"
1570     return 0
1571 }
1572 # }}}
1573 VCS_INFO_cvs_get_data () { # {{{
1574     local cvsbranch cvsbase basename
1575
1576     cvsbase="."
1577     while [[ -d "${cvsbase}/../CVS" ]]; do
1578         cvsbase="${cvsbase}/.."
1579     done
1580     cvsbase="$(VCS_INFO_realpath ${cvsbase})"
1581     cvsbranch=$(< ./CVS/Repository)
1582     basename=${cvsbase:t}
1583     cvsbranch=${cvsbranch##${basename}/}
1584     [[ -z ${cvsbranch} ]] && cvsbranch=${basename}
1585     VCS_INFO_formats '' "${cvsbranch}" "${cvsbase}"
1586     return 0
1587 }
1588 # }}}
1589 VCS_INFO_darcs_get_data () { # {{{
1590     local darcsbase
1591
1592     darcsbase=${vcs_comm[basedir]}
1593     VCS_INFO_formats '' "${darcsbase:t}" "${darcsbase}"
1594     return 0
1595 }
1596 # }}}
1597 VCS_INFO_git_getaction () { #{{{
1598     local gitaction='' gitdir=$1
1599     local tmp
1600
1601     for tmp in "${gitdir}/rebase-apply" \
1602                "${gitdir}/rebase"       \
1603                "${gitdir}/../.dotest" ; do
1604         if [[ -d ${tmp} ]] ; then
1605             if   [[ -f "${tmp}/rebasing" ]] ; then
1606                 gitaction="rebase"
1607             elif [[ -f "${tmp}/applying" ]] ; then
1608                 gitaction="am"
1609             else
1610                 gitaction="am/rebase"
1611             fi
1612             printf '%s' ${gitaction}
1613             return 0
1614         fi
1615     done
1616
1617     for tmp in "${gitdir}/rebase-merge/interactive" \
1618                "${gitdir}/.dotest-merge/interactive" ; do
1619         if [[ -f "${tmp}" ]] ; then
1620             printf '%s' "rebase-i"
1621             return 0
1622         fi
1623     done
1624
1625     for tmp in "${gitdir}/rebase-merge" \
1626                "${gitdir}/.dotest-merge" ; do
1627         if [[ -d "${tmp}" ]] ; then
1628             printf '%s' "rebase-m"
1629             return 0
1630         fi
1631     done
1632
1633     if [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1634         printf '%s' "merge"
1635         return 0
1636     fi
1637
1638     if [[ -f "${gitdir}/BISECT_LOG" ]] ; then
1639         printf '%s' "bisect"
1640         return 0
1641     fi
1642     return 1
1643 }
1644 # }}}
1645 VCS_INFO_git_getbranch () { #{{{
1646     local gitbranch gitdir=$1 tmp actiondir
1647     local gitsymref='git symbolic-ref HEAD'
1648
1649     actiondir=''
1650     for tmp in "${gitdir}/rebase-apply" \
1651                "${gitdir}/rebase"       \
1652                "${gitdir}/../.dotest"; do
1653         if [[ -d ${tmp} ]]; then
1654             actiondir=${tmp}
1655             break
1656         fi
1657     done
1658     if [[ -n ${actiondir} ]]; then
1659         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1660         [[ -z ${gitbranch} ]] && [[ -r ${actiondir}/head-name ]] \
1661             && gitbranch="$(< ${actiondir}/head-name)"
1662
1663     elif [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1664         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1665         [[ -z ${gitbranch} ]] && gitbranch="$(< ${gitdir}/MERGE_HEAD)"
1666
1667     elif [[ -d "${gitdir}/rebase-merge" ]] ; then
1668         gitbranch="$(< ${gitdir}/rebase-merge/head-name)"
1669
1670     elif [[ -d "${gitdir}/.dotest-merge" ]] ; then
1671         gitbranch="$(< ${gitdir}/.dotest-merge/head-name)"
1672
1673     else
1674         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1675
1676         if [[ $? -ne 0 ]] ; then
1677             gitbranch="refs/tags/$(git describe --exact-match HEAD 2>/dev/null)"
1678
1679             if [[ $? -ne 0 ]] ; then
1680                 gitbranch="${${"$(< $gitdir/HEAD)"}[1,7]}..."
1681             fi
1682         fi
1683     fi
1684
1685     printf '%s' "${gitbranch##refs/[^/]##/}"
1686     return 0
1687 }
1688 # }}}
1689 VCS_INFO_git_get_data () { # {{{
1690     setopt localoptions extendedglob
1691     local gitdir gitbase gitbranch gitaction
1692
1693     gitdir=${vcs_comm[gitdir]}
1694     gitbranch="$(VCS_INFO_git_getbranch ${gitdir})"
1695
1696     if [[ -z ${gitdir} ]] || [[ -z ${gitbranch} ]] ; then
1697         return 1
1698     fi
1699
1700     VCS_INFO_adjust
1701     gitaction="$(VCS_INFO_git_getaction ${gitdir})"
1702     gitbase=${PWD%/${$( git rev-parse --show-prefix )%/##}}
1703     VCS_INFO_formats "${gitaction}" "${gitbranch}" "${gitbase}"
1704     return 0
1705 }
1706 # }}}
1707 VCS_INFO_hg_get_data () { # {{{
1708     local hgbranch hgbase file
1709
1710     hgbase=${vcs_comm[basedir]}
1711
1712     file="${hgbase}/.hg/branch"
1713     if [[ -r ${file} ]] ; then
1714         hgbranch=$(< ${file})
1715     else
1716         hgbranch='default'
1717     fi
1718
1719     VCS_INFO_formats '' "${hgbranch}" "${hgbase}"
1720     return 0
1721 }
1722 # }}}
1723 VCS_INFO_mtn_get_data () { # {{{
1724     local mtnbranch mtnbase
1725
1726     mtnbase=${vcs_comm[basedir]}
1727     mtnbranch=${${(M)${(f)"$( mtn status )"}:#(#s)Current branch:*}/*: /}
1728     VCS_INFO_formats '' "${mtnbranch}" "${mtnbase}"
1729     return 0
1730 }
1731 # }}}
1732 VCS_INFO_svk_get_data () { # {{{
1733     local svkbranch svkbase
1734
1735     svkbase=${vcs_comm[basedir]}
1736     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svkbranch || svkbranch="%b:%r"
1737     zformat -f svkbranch "${svkbranch}" "b:${vcs_comm[branch]}" "r:${vcs_comm[revision]}"
1738     VCS_INFO_formats '' "${svkbranch}" "${svkbase}"
1739     return 0
1740 }
1741 # }}}
1742 VCS_INFO_svn_get_data () { # {{{
1743     setopt localoptions noksharrays
1744     local svnbase svnbranch
1745     local -a svninfo
1746
1747     svnbase="."
1748     while [[ -d "${svnbase}/../.svn" ]]; do
1749         svnbase="${svnbase}/.."
1750     done
1751     svnbase="$(VCS_INFO_realpath ${svnbase})"
1752     svninfo=( ${${${(M)${(f)"$( svn info )"}:#(#s)(URL|Revision)*}/*: /}/*\//} )
1753
1754     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svnbranch || svnbranch="%b:%r"
1755     zformat -f svnbranch "${svnbranch}" "b:${svninfo[1]}" "r:${svninfo[2]}"
1756     VCS_INFO_formats '' "${svnbranch}" "${svnbase}"
1757     return 0
1758 }
1759 # }}}
1760 VCS_INFO_tla_get_data () { # {{{
1761     local tlabase tlabranch
1762
1763     tlabase="$(VCS_INFO_realpath ${vcs_comm[basedir]})"
1764     # tree-id gives us something like 'foo@example.com/demo--1.0--patch-4', so:
1765     tlabranch=${${"$( tla tree-id )"}/*\//}
1766     VCS_INFO_formats '' "${tlabranch}" "${tlabase}"
1767     return 0
1768 }
1769 # }}}
1770 # detection
1771 VCS_INFO_detect_by_dir() { #{{{
1772     local dirname=$1
1773     local basedir="." realbasedir
1774
1775     realbasedir="$(VCS_INFO_realpath ${basedir})"
1776     while [[ ${realbasedir} != '/' ]]; do
1777         [[ -r ${realbasedir} ]] || return 1
1778         if [[ -n ${vcs_comm[detect_need_file]} ]] ; then
1779             [[ -d ${basedir}/${dirname} ]] && \
1780             [[ -e ${basedir}/${dirname}/${vcs_comm[detect_need_file]} ]] && \
1781                 break
1782         else
1783             [[ -d ${basedir}/${dirname} ]] && break
1784         fi
1785
1786         basedir=${basedir}/..
1787         realbasedir="$(VCS_INFO_realpath ${basedir})"
1788     done
1789
1790     [[ ${realbasedir} == "/" ]] && return 1
1791     vcs_comm[basedir]=${realbasedir}
1792     return 0
1793 }
1794 # }}}
1795 VCS_INFO_bzr_detect() { #{{{
1796     VCS_INFO_check_com bzr || return 1
1797     vcs_comm[detect_need_file]=branch/format
1798     VCS_INFO_detect_by_dir '.bzr'
1799     return $?
1800 }
1801 # }}}
1802 VCS_INFO_cdv_detect() { #{{{
1803     VCS_INFO_check_com cdv || return 1
1804     vcs_comm[detect_need_file]=format
1805     VCS_INFO_detect_by_dir '.cdv'
1806     return $?
1807 }
1808 # }}}
1809 VCS_INFO_cvs_detect() { #{{{
1810     VCS_INFO_check_com cvs || return 1
1811     [[ -d "./CVS" ]] && [[ -r "./CVS/Repository" ]] && return 0
1812     return 1
1813 }
1814 # }}}
1815 VCS_INFO_darcs_detect() { #{{{
1816     VCS_INFO_check_com darcs || return 1
1817     vcs_comm[detect_need_file]=format
1818     VCS_INFO_detect_by_dir '_darcs'
1819     return $?
1820 }
1821 # }}}
1822 VCS_INFO_git_detect() { #{{{
1823     if VCS_INFO_check_com git && git rev-parse --is-inside-work-tree &> /dev/null ; then
1824         vcs_comm[gitdir]="$(git rev-parse --git-dir 2> /dev/null)" || return 1
1825         if   [[ -d ${vcs_comm[gitdir]}/svn ]]             ; then vcs_comm[overwrite_name]='git-svn'
1826         elif [[ -d ${vcs_comm[gitdir]}/refs/remotes/p4 ]] ; then vcs_comm[overwrite_name]='git-p4' ; fi
1827         return 0
1828     fi
1829     return 1
1830 }
1831 # }}}
1832 VCS_INFO_hg_detect() { #{{{
1833     VCS_INFO_check_com hg || return 1
1834     vcs_comm[detect_need_file]=store
1835     VCS_INFO_detect_by_dir '.hg'
1836     return $?
1837 }
1838 # }}}
1839 VCS_INFO_mtn_detect() { #{{{
1840     VCS_INFO_check_com mtn || return 1
1841     vcs_comm[detect_need_file]=revision
1842     VCS_INFO_detect_by_dir '_MTN'
1843     return $?
1844 }
1845 # }}}
1846 VCS_INFO_svk_detect() { #{{{
1847     setopt localoptions noksharrays extendedglob
1848     local -a info
1849     local -i fhash
1850     fhash=0
1851
1852     VCS_INFO_check_com svk || return 1
1853     [[ -f ~/.svk/config ]] || return 1
1854
1855     # This detection function is a bit different from the others.
1856     # We need to read svk's config file to detect a svk repository
1857     # in the first place. Therefore, we'll just proceed and read
1858     # the other information, too. This is more then any of the
1859     # other detections do but this takes only one file open for
1860     # svk at most. VCS_INFO_svk_get_data() get simpler, too. :-)
1861     while IFS= read -r line ; do
1862         if [[ -n ${vcs_comm[basedir]} ]] ; then
1863             line=${line## ##}
1864             [[ ${line} == depotpath:* ]] && vcs_comm[branch]=${line##*/}
1865             [[ ${line} == revision:* ]] && vcs_comm[revision]=${line##*[[:space:]]##}
1866             [[ -n ${vcs_comm[branch]} ]] && [[ -n ${vcs_comm[revision]} ]] && break
1867             continue
1868         fi
1869         (( fhash > 0 )) && [[ ${line} == '  '[^[:space:]]*:* ]] && break
1870         [[ ${line} == '  hash:'* ]] && fhash=1 && continue
1871         (( fhash == 0 )) && continue
1872         [[ ${PWD}/ == ${${line## ##}%:*}/* ]] && vcs_comm[basedir]=${${line## ##}%:*}
1873     done < ~/.svk/config
1874
1875     [[ -n ${vcs_comm[basedir]} ]]  && \
1876     [[ -n ${vcs_comm[branch]} ]]   && \
1877     [[ -n ${vcs_comm[revision]} ]] && return 0
1878     return 1
1879 }
1880 # }}}
1881 VCS_INFO_svn_detect() { #{{{
1882     VCS_INFO_check_com svn || return 1
1883     [[ -d ".svn" ]] && return 0
1884     return 1
1885 }
1886 # }}}
1887 VCS_INFO_tla_detect() { #{{{
1888     VCS_INFO_check_com tla || return 1
1889     vcs_comm[basedir]="$(tla tree-root 2> /dev/null)" && return 0
1890     return 1
1891 }
1892 # }}}
1893 # public API
1894 vcs_info_printsys () { # {{{
1895     vcs_info print_systems_
1896 }
1897 # }}}
1898 vcs_info_lastmsg () { # {{{
1899     emulate -L zsh
1900     local -i i
1901
1902     VCS_INFO_maxexports
1903     for i in {0..$((maxexports - 1))} ; do
1904         printf '$VCS_INFO_message_%d_: "' $i
1905         if zstyle -T ':vcs_info:formats:command' use-prompt-escapes ; then
1906             print -nP ${(P)${:-VCS_INFO_message_${i}_}}
1907         else
1908             print -n ${(P)${:-VCS_INFO_message_${i}_}}
1909         fi
1910         printf '"\n'
1911     done
1912 }
1913 # }}}
1914 vcs_info () { # {{{
1915     emulate -L zsh
1916     setopt extendedglob
1917
1918     [[ -r . ]] || return 1
1919
1920     local pat
1921     local -i found
1922     local -a VCSs disabled dps
1923     local -x vcs usercontext
1924     local -ix maxexports
1925     local -ax msgs
1926     local -Ax vcs_comm
1927
1928     vcs="init"
1929     VCSs=(git hg bzr darcs svk mtn svn cvs cdv tla)
1930     case $1 in
1931         (print_systems_)
1932             zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1933             print -l '# list of supported version control backends:' \
1934                      '# disabled systems are prefixed by a hash sign (#)'
1935             for vcs in ${VCSs} ; do
1936                 [[ -n ${(M)disabled:#${vcs}} ]] && printf '#'
1937                 printf '%s\n' ${vcs}
1938             done
1939             print -l '# flavours (cannot be used in the disable style; they' \
1940                      '# are disabled with their master [git-svn -> git]):'   \
1941                      git-{p4,svn}
1942             return 0
1943             ;;
1944         ('')
1945             [[ -z ${usercontext} ]] && usercontext=default
1946             ;;
1947         (*) [[ -z ${usercontext} ]] && usercontext=$1
1948             ;;
1949     esac
1950
1951     zstyle -T ":vcs_info:${vcs}:${usercontext}" "enable" || {
1952         [[ -n ${VCS_INFO_message_0_} ]] && VCS_INFO_set --clear
1953         return 0
1954     }
1955     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1956
1957     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable-patterns" dps
1958     for pat in ${dps} ; do
1959         if [[ ${PWD} == ${~pat} ]] ; then
1960             [[ -n ${vcs_info_msg_0_} ]] && VCS_INFO_set --clear
1961             return 0
1962         fi
1963     done
1964
1965     VCS_INFO_maxexports
1966
1967     (( found = 0 ))
1968     for vcs in ${VCSs} ; do
1969         [[ -n ${(M)disabled:#${vcs}} ]] && continue
1970         vcs_comm=()
1971         VCS_INFO_${vcs}_detect && (( found = 1 )) && break
1972     done
1973
1974     (( found == 0 )) && {
1975         VCS_INFO_set --nvcs
1976         return 0
1977     }
1978
1979     VCS_INFO_${vcs}_get_data || {
1980         VCS_INFO_set --nvcs
1981         return 1
1982     }
1983
1984     VCS_INFO_set
1985     return 0
1986 }
1987
1988 VCS_INFO_set --nvcs preinit
1989 # }}}
1990
1991 fi
1992
1993 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1994 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1995 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1996 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1997 #       to $vcs_info_msg_N_ as soon as we use the included version.
1998 if [[ "$TERM" == dumb ]] ; then
1999     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
2000     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
2001 else
2002     # these are the same, just with a lot of colours:
2003     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
2004                                        "zsh: %r"
2005     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
2006                                        "zsh: %r"
2007     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
2008 fi
2009
2010 if [[ -o restricted ]]; then
2011     zstyle ':vcs_info:*' enable false
2012 fi
2013
2014 # }}}
2015
2016 # command not found handling {{{
2017
2018 (( ${COMMAND_NOT_FOUND} == 1 )) &&
2019 function command_not_found_handler() {
2020     emulate -L zsh
2021     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
2022         ${GRML_ZSH_CNF_HANDLER} $1
2023     fi
2024     return 1
2025 }
2026
2027 # }}}
2028
2029 # {{{ set prompt
2030 if zrcautoload promptinit && promptinit 2>/dev/null ; then
2031     promptinit # people should be able to use their favourite prompt
2032 else
2033     print 'Notice: no promptinit available :('
2034 fi
2035
2036 setopt prompt_subst
2037
2038 # make sure to use right prompt only when not running a command
2039 is41 && setopt transient_rprompt
2040
2041
2042 function ESC_print () {
2043     info_print $'\ek' $'\e\\' "$@"
2044 }
2045 function set_title () {
2046     info_print  $'\e]0;' $'\a' "$@"
2047 }
2048
2049 function info_print () {
2050     local esc_begin esc_end
2051     esc_begin="$1"
2052     esc_end="$2"
2053     shift 2
2054     printf '%s' ${esc_begin}
2055     for item in "$@" ; do
2056         printf '%s ' "$item"
2057     done
2058     printf '%s' "${esc_end}"
2059 }
2060
2061 # TODO: revise all these NO* variables and especially their documentation
2062 #       in zsh-help() below.
2063 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
2064     [[ $NOPRECMD -gt 0 ]] && return 0
2065     # update VCS information
2066     vcs_info
2067
2068     if [[ $TERM == screen* ]] ; then
2069         if [[ -n ${VCS_INFO_message_1_} ]] ; then
2070             ESC_print ${VCS_INFO_message_1_}
2071         elif [[ -n ${vcs_info_msg_1_} ]] ; then
2072             ESC_print ${vcs_info_msg_1_}
2073         else
2074             ESC_print "zsh"
2075         fi
2076     fi
2077     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
2078     if [[ $DONTSETRPROMPT -eq 0 ]] ; then
2079         if [[ $BATTERY -gt 0 ]] ; then
2080             # update battery (dropped into $PERCENT) information
2081             battery
2082             RPROMPT="%(?..:() ${PERCENT}"
2083         else
2084             RPROMPT="%(?..:() "
2085         fi
2086     fi
2087     # adjust title of xterm
2088     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
2089     [[ ${NOTITLE} -gt 0 ]] && return 0
2090     case $TERM in
2091         (xterm*|rxvt*)
2092             set_title ${(%):-"%n@%m: %~"}
2093             ;;
2094     esac
2095 }
2096
2097 # preexec() => a function running before every command
2098 is4 && [[ $NOPRECMD -eq 0 ]] && \
2099 preexec () {
2100     [[ $NOPRECMD -gt 0 ]] && return 0
2101 # set hostname if not running on host with name 'grml'
2102     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
2103        NAME="@$HOSTNAME"
2104     fi
2105 # get the name of the program currently running and hostname of local machine
2106 # set screen window title if running in a screen
2107     if [[ "$TERM" == screen* ]] ; then
2108         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
2109         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
2110         ESC_print ${CMD}
2111     fi
2112 # adjust title of xterm
2113     [[ ${NOTITLE} -gt 0 ]] && return 0
2114     case $TERM in
2115         (xterm*|rxvt*)
2116             set_title "${(%):-"%n@%m:"}" "$1"
2117             ;;
2118     esac
2119 }
2120
2121 EXITCODE="%(?..%?%1v )"
2122 PS2='\`%_> '      # secondary prompt, printed when the shell needs more information to complete a command.
2123 PS3='?# '         # selection prompt used within a select loop.
2124 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
2125
2126 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
2127 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
2128     debian_chroot=$(cat /etc/debian_chroot)
2129 fi
2130
2131 # don't use colors on dumb terminals (like emacs):
2132 if [[ "$TERM" == dumb ]] ; then
2133     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
2134 else
2135     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
2136     # set variable identifying the chroot you work in (used in the prompt below)
2137     if [[ $GRMLPROMPT -gt 0 ]] ; then
2138         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
2139 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
2140     else
2141         # This assembles the primary prompt string
2142         if (( EUID != 0 )); then
2143             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
2144         else
2145             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "
2146         fi
2147     fi
2148 fi
2149
2150 if (( GRML_VCS_INFO )); then
2151     PROMPT="${PROMPT}"'${VCS_INFO_message_0_}'"%# "
2152 else
2153     PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
2154 fi
2155
2156 # if we are inside a grml-chroot set a specific prompt theme
2157 if [[ -n "$GRML_CHROOT" ]] ; then
2158     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
2159 fi
2160 # }}}
2161
2162 # {{{ 'hash' some often used directories
2163 #d# start
2164 hash -d deb=/var/cache/apt/archives
2165 hash -d doc=/usr/share/doc
2166 hash -d linux=/lib/modules/$(command uname -r)/build/
2167 hash -d log=/var/log
2168 hash -d slog=/var/log/syslog
2169 hash -d src=/usr/src
2170 hash -d templ=/usr/share/doc/grml-templates
2171 hash -d tt=/usr/share/doc/texttools-doc
2172 hash -d www=/var/www
2173 #d# end
2174 # }}}
2175
2176 # {{{ some aliases
2177 if check_com -c screen ; then
2178     if [[ $UID -eq 0 ]] ; then
2179         [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
2180     elif [[ -r $HOME/.screenrc ]] ; then
2181         alias screen="${commands[screen]} -c $HOME/.screenrc"
2182     else
2183         if [[ -r /etc/grml/screenrc_grml ]]; then
2184             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
2185         else
2186             [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
2187         fi
2188     fi
2189 fi
2190
2191 # do we have GNU ls with color-support?
2192 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
2193     #a1# execute \kbd{@a@}:\quad ls with colors
2194     alias ls='ls -b -CF --color=auto'
2195     #a1# execute \kbd{@a@}:\quad list all files, with colors
2196     alias la='ls -la --color=auto'
2197     #a1# long colored list, without dotfiles (@a@)
2198     alias ll='ls -l --color=auto'
2199     #a1# long colored list, human readable sizes (@a@)
2200     alias lh='ls -hAl --color=auto'
2201     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2202     alias l='ls -lF --color=auto'
2203 else
2204     alias ls='ls -b -CF'
2205     alias la='ls -la'
2206     alias ll='ls -l'
2207     alias lh='ls -hAl'
2208     alias l='ls -lF'
2209 fi
2210
2211 alias mdstat='cat /proc/mdstat'
2212 alias ...='cd ../../'
2213
2214 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2215 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2216     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2217 fi
2218
2219 alias cp='nocorrect cp'         # no spelling correction on cp
2220 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
2221 alias mv='nocorrect mv'         # no spelling correction on mv
2222 alias rm='nocorrect rm'         # no spelling correction on rm
2223
2224 #a1# Execute \kbd{rmdir}
2225 alias rd='rmdir'
2226 #a1# Execute \kbd{mkdir}
2227 alias md='mkdir'
2228
2229 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2230 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2231 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2232
2233 # make sure it is not assigned yet
2234 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
2235 utf2iso() {
2236     if isutfenv ; then
2237         for ENV in $(env | command grep -i '.utf') ; do
2238             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2239         done
2240     fi
2241 }
2242
2243 # make sure it is not assigned yet
2244 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
2245 iso2utf() {
2246     if ! isutfenv ; then
2247         for ENV in $(env | command grep -i '\.iso') ; do
2248             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2249         done
2250     fi
2251 }
2252
2253 # set up software synthesizer via speakup
2254 swspeak() {
2255     if [ -x /usr/sbin/swspeak-setup ] ; then
2256        setopt singlelinezle
2257        unsetopt prompt_cr
2258        export PS1="%m%# "
2259        /usr/sbin/swspeak-setup $@
2260      else # old version:
2261         if ! [[ -r /dev/softsynth ]] ; then
2262             flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
2263             return 1
2264         else
2265            setopt singlelinezle
2266            unsetopt prompt_cr
2267            export PS1="%m%# "
2268             nice -n -20 speechd-up
2269             sleep 2
2270             flite -o play -t "Finished setting up software synthesizer"
2271         fi
2272      fi
2273 }
2274
2275 # I like clean prompt, so provide simple way to get that
2276 check_com 0 || alias 0='return 0'
2277
2278 # for really lazy people like mika:
2279 check_com S &>/dev/null || alias S='screen'
2280 check_com s &>/dev/null || alias s='ssh'
2281
2282 # especially for roadwarriors using GNU screen and ssh:
2283 if ! check_com asc &>/dev/null ; then
2284   asc() { autossh -t "$@" 'screen -RdU' }
2285   compdef asc=ssh
2286 fi
2287
2288 # get top 10 shell commands:
2289 alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
2290
2291 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
2292 if check_com -c truecrypt ; then
2293     if isutfenv ; then
2294         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
2295     else
2296         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
2297     fi
2298 fi
2299
2300 #f1# Hints for the use of zsh on grml
2301 zsh-help() {
2302     print "$bg[white]$fg[black]
2303 zsh-help - hints for use of zsh on grml
2304 =======================================$reset_color"
2305
2306     print '
2307 Main configuration of zsh happens in /etc/zsh/zshrc.
2308 That file is part of the package grml-etc-core, if you want to
2309 use them on a non-grml-system just get the tar.gz from
2310 http://deb.grml.org/ or (preferably) get it from the git repository:
2311
2312   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2313
2314 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2315 The file is still there, but it is empty for backwards compatibility.
2316
2317 For your own changes use these two files:
2318     $HOME/.zshrc.pre
2319     $HOME/.zshrc.local
2320
2321 The former is sourced very early in our zshrc, the latter is sourced
2322 very lately.
2323
2324 System wide configuration without touching configuration files of grml
2325 can take place in /etc/zsh/zshrc.local.
2326
2327 Normally, the root user (EUID == 0) does not get the whole grml setup.
2328 If you want to force the whole setup for that user, too, set
2329 GRML_ALWAYS_LOAD_ALL=1 in .zshrc.pre in root'\''s home directory.
2330
2331 For information regarding zsh start at http://grml.org/zsh/
2332
2333 Take a look at grml'\''s zsh refcard:
2334 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2335
2336 Check out the main zsh refcard:
2337 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2338
2339 And of course visit the zsh-lovers:
2340 % man zsh-lovers
2341
2342 You can adjust some options through environment variables when
2343 invoking zsh without having to edit configuration files.
2344 Basically meant for bash users who are not used to the power of
2345 the zsh yet. :)
2346
2347   "NOCOR=1    zsh" => deactivate automatic correction
2348   "NOMENU=1   zsh" => do not use auto menu completion (note: use ctrl-d for completion instead!)
2349   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2350   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2351                       preexec() and precmd() completely
2352   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
2353   "COMMAND_NOT_FOUND=1 zsh"
2354                    => Enable a handler if an external command was not found
2355                       The command called in the handler can be altered by setting
2356                       the GRML_ZSH_CNF_HANDLER variable, the default is:
2357                       "/usr/share/command-not-found/command-not-found"
2358
2359 A value greater than 0 is enables a feature; a value equal to zero
2360 disables it. If you like one or the other of these settings, you can
2361 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2362 zshrc.'
2363
2364     print "
2365 $bg[white]$fg[black]
2366 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2367 Enjoy your grml system with the zsh!$reset_color"
2368 }
2369
2370 # debian stuff
2371 if [[ -r /etc/debian_version ]] ; then
2372     #a3# Execute \kbd{apt-cache search}
2373     alias acs='apt-cache search'
2374     #a3# Execute \kbd{apt-cache show}
2375     alias acsh='apt-cache show'
2376     #a3# Execute \kbd{apt-cache policy}
2377     alias acp='apt-cache policy'
2378     #a3# Execute \kbd{apt-get dist-upgrade}
2379     salias adg="apt-get dist-upgrade"
2380     #a3# Execute \kbd{apt-get install}
2381     salias agi="apt-get install"
2382     #a3# Execute \kbd{aptitude install}
2383     salias ati="aptitude install"
2384     #a3# Execute \kbd{apt-get upgrade}
2385     salias ag="apt-get upgrade"
2386     #a3# Execute \kbd{apt-get update}
2387     salias au="apt-get update"
2388     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2389     salias -a up="aptitude update ; aptitude safe-upgrade"
2390     #a3# Execute \kbd{dpkg-buildpackage}
2391     alias dbp='dpkg-buildpackage'
2392     #a3# Execute \kbd{grep-excuses}
2393     alias ge='grep-excuses'
2394
2395     # debian upgrade
2396     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
2397     upgrade() {
2398         emulate -L zsh
2399         if [[ -z $1 ]] ; then
2400             $SUDO apt-get update
2401             $SUDO apt-get -u upgrade
2402         else
2403             ssh $1 $SUDO apt-get update
2404             # ask before the upgrade
2405             local dummy
2406             ssh $1 $SUDO apt-get --no-act upgrade
2407             echo -n 'Process the upgrade?'
2408             read -q dummy
2409             if [[ $dummy == "y" ]] ; then
2410                 ssh $1 $SUDO apt-get -u upgrade --yes
2411             fi
2412         fi
2413     }
2414
2415     # get a root shell as normal user in live-cd mode:
2416     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2417        alias su="sudo su"
2418      fi
2419
2420     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2421     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2422     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2423     salias tlog="tail -f /var/log/syslog"    # follow the syslog
2424 fi
2425
2426 # sort installed Debian-packages by size
2427 if check_com -c grep-status ; then
2428     #a3# List installed Debian-packages sorted by size
2429     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
2430 fi
2431
2432 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2433 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
2434     if check_com -c wodim; then
2435         cdrecord() {
2436             cat <<EOMESS
2437 cdrecord is not provided under its original name by Debian anymore.
2438 See #377109 in the BTS of Debian for more details.
2439
2440 Please use the wodim binary instead
2441 EOMESS
2442             return 1
2443         }
2444     fi
2445 fi
2446
2447 # get_tw_cli has been renamed into get_3ware
2448 if check_com -c get_3ware ; then
2449     get_tw_cli() {
2450         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
2451         get_3ware
2452     }
2453 fi
2454
2455 # I hate lacking backward compatibility, so provide an alternative therefore
2456 if ! check_com -c apache2-ssl-certificate ; then
2457
2458     apache2-ssl-certificate() {
2459
2460     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
2461     print 'You might want to take a look at Debian the package ssl-cert as well.'
2462     print 'To generate a certificate for use with apache2 follow the instructions:'
2463
2464     echo '
2465
2466 export RANDFILE=/dev/random
2467 mkdir /etc/apache2/ssl/
2468 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
2469 chmod 600 /etc/apache2/ssl/apache.pem
2470
2471 Run "grml-tips ssl-certificate" if you need further instructions.
2472 '
2473     }
2474 fi
2475 # }}}
2476
2477 # {{{ Use hard limits, except for a smaller stack and no core dumps
2478 unlimit
2479 is425 && limit stack 8192
2480 isgrmlcd && limit core 0 # important for a live-cd-system
2481 limit -s
2482 # }}}
2483
2484 # {{{ completion system
2485
2486 # called later (via is4 && grmlcomp)
2487 # note: use 'zstyle' for getting current settings
2488 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
2489 grmlcomp() {
2490     # TODO: This could use some additional information
2491
2492     # allow one error for every three characters typed in approximate completer
2493     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
2494
2495     # don't complete backup files as executables
2496     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
2497
2498     # start menu completion only if it could find no unambiguous initial string
2499     zstyle ':completion:*:correct:*'       insert-unambiguous true
2500     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
2501     zstyle ':completion:*:correct:*'       original true
2502
2503     # activate color-completion
2504     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
2505
2506     # format on completion
2507     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
2508
2509     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
2510     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
2511
2512     # insert all expansions for expand completer
2513     zstyle ':completion:*:expand:*'        tag-order all-expansions
2514     zstyle ':completion:*:history-words'   list false
2515
2516     # activate menu
2517     zstyle ':completion:*:history-words'   menu yes
2518
2519     # ignore duplicate entries
2520     zstyle ':completion:*:history-words'   remove-all-dups yes
2521     zstyle ':completion:*:history-words'   stop yes
2522
2523     # match uppercase from lowercase
2524     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
2525
2526     # separate matches into groups
2527     zstyle ':completion:*:matches'         group 'yes'
2528     zstyle ':completion:*'                 group-name ''
2529
2530     if [[ "$NOMENU" -eq 0 ]] ; then
2531         # if there are more than 5 options allow selecting from a menu
2532         zstyle ':completion:*'               menu select=5
2533     else
2534         # don't use any menus at all
2535         setopt no_auto_menu
2536     fi
2537
2538     zstyle ':completion:*:messages'        format '%d'
2539     zstyle ':completion:*:options'         auto-description '%d'
2540
2541     # describe options in full
2542     zstyle ':completion:*:options'         description 'yes'
2543
2544     # on processes completion complete all user processes
2545     zstyle ':completion:*:processes'       command 'ps -au$USER'
2546
2547     # offer indexes before parameters in subscripts
2548     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
2549
2550     # provide verbose completion information
2551     zstyle ':completion:*'                 verbose true
2552
2553     # recent (as of Dec 2007) zsh versions are able to provide descriptions
2554     # for commands (read: 1st word in the line) that it will list for the user
2555     # to choose from. The following disables that, because it's not exactly fast.
2556     zstyle ':completion:*:-command-:*:'    verbose false
2557
2558     # set format for warnings
2559     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
2560
2561     # define files to ignore for zcompile
2562     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
2563     zstyle ':completion:correct:'          prompt 'correct to: %e'
2564
2565     # Ignore completion functions for commands you don't have:
2566     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
2567
2568     # Provide more processes in completion of programs like killall:
2569     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
2570
2571     # complete manual by their section
2572     zstyle ':completion:*:manuals'    separate-sections true
2573     zstyle ':completion:*:manuals.*'  insert-sections   true
2574     zstyle ':completion:*:man:*'      menu yes select
2575
2576     # provide .. as a completion
2577     zstyle ':completion:*' special-dirs ..
2578
2579     # run rehash on completion so new installed program are found automatically:
2580     _force_rehash() {
2581         (( CURRENT == 1 )) && rehash
2582         return 1
2583     }
2584
2585     ## correction
2586     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
2587     if [[ "$NOCOR" -gt 0 ]] ; then
2588         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
2589         setopt nocorrect
2590     else
2591         # try to be smart about when to use what completer...
2592         setopt correct
2593         zstyle -e ':completion:*' completer '
2594             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
2595                 _last_try="$HISTNO$BUFFER$CURSOR"
2596                 reply=(_complete _match _ignored _prefix _files)
2597             else
2598                 if [[ $words[1] == (rm|mv) ]] ; then
2599                     reply=(_complete _files)
2600                 else
2601                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
2602                 fi
2603             fi'
2604     fi
2605
2606     # command for process lists, the local web server details and host completion
2607     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
2608
2609     # caching
2610     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
2611                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
2612
2613     # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
2614     if is42 ; then
2615         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
2616         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
2617     else
2618         _ssh_hosts=()
2619         _etc_hosts=()
2620     fi
2621     hosts=(
2622         $(hostname)
2623         "$_ssh_hosts[@]"
2624         "$_etc_hosts[@]"
2625         grml.org
2626         localhost
2627     )
2628     zstyle ':completion:*:hosts' hosts $hosts
2629     # TODO: so, why is this here?
2630     #  zstyle '*' hosts $hosts
2631
2632     # use generic completion system for programs not yet defined; (_gnu_generic works
2633     # with commands that provide a --help option with "standard" gnu-like output.)
2634     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
2635                    pal stow tail uname ; do
2636         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
2637     done; unset compcom
2638
2639     # see upgrade function in this file
2640     compdef _hosts upgrade
2641 }
2642 # }}}
2643
2644 # {{{ grmlstuff
2645 grmlstuff() {
2646 # people should use 'grml-x'!
2647     if check_com -c 915resolution; then
2648         855resolution() {
2649             echo "Please use 915resolution as resolution modifying tool for Intel \
2650 graphic chipset."
2651             return -1
2652         }
2653     fi
2654
2655     #a1# Output version of running grml
2656     alias grml-version='cat /etc/grml_version'
2657
2658     if check_com -c rebuildfstab ; then
2659         #a1# Rebuild /etc/fstab
2660         alias grml-rebuildfstab='rebuildfstab -v -r -config'
2661     fi
2662
2663     if check_com -c grml-debootstrap ; then
2664         debian2hd() {
2665             echo "Installing debian to harddisk is possible by using grml-debootstrap."
2666             return 1
2667         }
2668     fi
2669 }
2670 # }}}
2671
2672 # {{{ now run the functions
2673 isgrml && checkhome
2674 is4    && isgrml    && grmlstuff
2675 is4    && grmlcomp
2676 # }}}
2677
2678 # {{{ keephack
2679 is4 && xsource "/etc/zsh/keephack"
2680 # }}}
2681
2682 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
2683 # You use it as follows:
2684 # $ NTREF=/reference/file
2685 # $ ls -l *(e:nt:)
2686 # This lists all the files in the current directory newer than the reference file.
2687 # You can also specify the reference file inline; note quotes:
2688 # $ ls -l *(e:'nt ~/.zshenv':)
2689 is4 && nt() {
2690     if [[ -n $1 ]] ; then
2691         local NTREF=${~1}
2692     fi
2693     [[ $REPLY -nt $NTREF ]]
2694 }
2695 # }}}
2696
2697 # shell functions {{{
2698
2699 #f1# Provide csh compatibility
2700 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
2701
2702 #f1# Reload an autoloadable function
2703 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2704 compdef _functions freload
2705
2706 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2707 sll() {
2708     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2709     for file in "$@" ; do
2710         while [[ -h "$file" ]] ; do
2711             ls -l $file
2712             file=$(readlink "$file")
2713         done
2714     done
2715 }
2716
2717 # fast manual access
2718 if check_com qma ; then
2719     #f1# View the zsh manual
2720     manzsh()  { qma zshall "$1" }
2721     compdef _man qma
2722 else
2723     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
2724 fi
2725
2726 # TODO: Is it supported to use pager settings like this?
2727 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2728 # with respect to wordsplitting. (ie. ${=PAGER})
2729 if check_com -c $PAGER ; then
2730     #f1# View Debian's changelog of a given package
2731     dchange() {
2732         emulate -L zsh
2733         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
2734             $PAGER /usr/share/doc/$1/changelog.Debian.gz
2735         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2736             $PAGER /usr/share/doc/$1/changelog.gz
2737         else
2738             if check_com -c aptitude ; then
2739                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2740                 if isgrml ; then
2741                     aptitude -t unstable changelog $1
2742                 else
2743                     aptitude changelog $1
2744                 fi
2745             else
2746                 echo "No changelog for package $1 found, sorry."
2747                 return 1
2748             fi
2749         fi
2750     }
2751     _dchange() { _files -W /usr/share/doc -/ }
2752     compdef _dchange dchange
2753
2754     #f1# View Debian's NEWS of a given package
2755     dnews() {
2756         emulate -L zsh
2757         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2758             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2759         else
2760             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2761                 $PAGER /usr/share/doc/$1/NEWS.gz
2762             else
2763                 echo "No NEWS file for package $1 found, sorry."
2764                 return 1
2765             fi
2766         fi
2767     }
2768     _dnews() { _files -W /usr/share/doc -/ }
2769     compdef _dnews dnews
2770
2771     #f1# View upstream's changelog of a given package
2772     uchange() {
2773         emulate -L zsh
2774         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2775             $PAGER /usr/share/doc/$1/changelog.gz
2776         else
2777             echo "No changelog for package $1 found, sorry."
2778             return 1
2779         fi
2780     }
2781     _uchange() { _files -W /usr/share/doc -/ }
2782     compdef _uchange uchange
2783 fi
2784
2785 # zsh profiling
2786 profile() {
2787     ZSH_PROFILE_RC=1 $SHELL "$@"
2788 }
2789
2790 #f1# Edit an alias via zle
2791 edalias() {
2792     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2793 }
2794 compdef _aliases edalias
2795
2796 #f1# Edit a function via zle
2797 edfunc() {
2798     [[ -z "$1" ]] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
2799 }
2800 compdef _functions edfunc
2801
2802 # use it e.g. via 'Restart apache2'
2803 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2804 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2805 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2806 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2807 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2808 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2809     __start_stop() {
2810         local action_="${1:l}"  # e.g Start/Stop/Restart
2811         local service_="$2"
2812         local param_="$3"
2813
2814         local service_target_="$(readlink /etc/init.d/$service_)"
2815         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2816             # runit
2817             case "${action_}" in
2818                 start) if [[ ! -e /etc/service/$service_ ]]; then
2819                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2820                        else
2821                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2822                        fi ;;
2823                 # there is no reload in runits sysv emulation
2824                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2825                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2826             esac
2827         else
2828             # sysvinit
2829             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2830         fi
2831     }
2832
2833     for i in Start Restart Stop Force-Reload Reload ; do
2834         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2835     done
2836 fi
2837
2838 #f1# Provides useful information on globbing
2839 H-Glob() {
2840     echo -e "
2841     /      directories
2842     .      plain files
2843     @      symbolic links
2844     =      sockets
2845     p      named pipes (FIFOs)
2846     *      executable plain files (0100)
2847     %      device files (character or block special)
2848     %b     block special files
2849     %c     character special files
2850     r      owner-readable files (0400)
2851     w      owner-writable files (0200)
2852     x      owner-executable files (0100)
2853     A      group-readable files (0040)
2854     I      group-writable files (0020)
2855     E      group-executable files (0010)
2856     R      world-readable files (0004)
2857     W      world-writable files (0002)
2858     X      world-executable files (0001)
2859     s      setuid files (04000)
2860     S      setgid files (02000)
2861     t      files with the sticky bit (01000)
2862
2863   print *(m-1)          # Files modified up to a day ago
2864   print *(a1)           # Files accessed a day ago
2865   print *(@)            # Just symlinks
2866   print *(Lk+50)        # Files bigger than 50 kilobytes
2867   print *(Lk-50)        # Files smaller than 50 kilobytes
2868   print **/*.c          # All *.c files recursively starting in \$PWD
2869   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2870   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2871   print *~*.*           # All Files that do not contain a dot
2872   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2873   print -l *(.c|.h)     # Lists *.c and *.h
2874   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2875   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2876 }
2877 alias help-zshglob=H-Glob
2878
2879 check_com -c qma && alias ?='qma zshall'
2880
2881 # grep for running process, like: 'any vim'
2882 any() {
2883     emulate -L zsh
2884     if [[ -z "$1" ]] ; then
2885         echo "any - grep for process(es) by keyword" >&2
2886         echo "Usage: any <keyword>" >&2 ; return 1
2887     else
2888         local STRING=$1
2889         local LENGTH=$(expr length $STRING)
2890         local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
2891         local REST=$(echo $(expr substr $STRING 2 $LENGTH))
2892         ps xauwww| grep "[$FIRSCHAR]$REST"
2893     fi
2894 }
2895
2896 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2897 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2898 [[ -r /proc/1/maps ]] && \
2899 deswap() {
2900     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2901     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2902     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2903 }
2904
2905 # print hex value of a number
2906 hex() {
2907     emulate -L zsh
2908     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
2909 }
2910
2911 # calculate (or eval at all ;-)) with perl => p[erl-]eval
2912 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
2913 peval() {
2914     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
2915     perl -e "print eval($CALC),\"\n\";"
2916 }
2917 functions peval &>/dev/null && alias calc=peval
2918
2919 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
2920 # certain circumstances, so work around it, no matter which environment we have
2921 brltty() {
2922     if [[ -z "$DISPLAY" ]] ; then
2923         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
2924         command brltty "$@"
2925     else
2926         command brltty "$@"
2927     fi
2928 }
2929
2930 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
2931 aoeu() {
2932     echo -n 'Switching to us keyboard layout: '
2933     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
2934     echo 'Done'
2935 }
2936 asdf() {
2937     echo -n 'Switching to dvorak keyboard layout: '
2938     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
2939     echo 'Done'
2940 }
2941 # just press 'asdf' key to toggle from neon layout to us keyboard layout
2942 uiae() {
2943     echo -n 'Switching to us keyboard layout: '
2944     setxkbmap us && echo 'Done' || echo 'Failed'
2945 }
2946
2947 # set up an ipv6 tunnel
2948 ipv6-tunnel() {
2949     emulate -L zsh
2950     case $1 in
2951         start)
2952             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2953                 print 'ipv6 tunnel already set up, nothing to be done.'
2954                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
2955             else
2956                 [[ -n "$PUBLIC_IP" ]] || \
2957                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
2958                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
2959
2960                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
2961                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
2962                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
2963                 ifconfig sit0 tunnel ::192.88.99.1 up
2964                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
2965             fi
2966             ;;
2967         status)
2968             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2969                 print 'ipv6 tunnel available' ; return 0
2970             else
2971                 print 'ipv6 tunnel not available' ; return 1
2972             fi
2973             ;;
2974         stop)
2975             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2976                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
2977                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
2978             else
2979                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
2980             fi
2981             ;;
2982         *)
2983             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
2984             ;;
2985     esac
2986 }
2987
2988 # run dhclient for wireless device
2989 iwclient() {
2990     sudo dhclient "$(wavemon -d | awk '/device/{print $3}')"
2991 }
2992
2993 # spawn a minimally set up mksh - useful if you want to umount /usr/.
2994 minimal-shell() {
2995     emulate -L zsh
2996     local shell="/bin/mksh"
2997
2998     if [[ ! -x ${shell} ]]; then
2999         printf '`%s'\'' not available, giving up.\n' ${shell} >&2
3000         return 1
3001     fi
3002
3003     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ${shell}
3004 }
3005
3006 # a wrapper for vim, that deals with title setting
3007 #   VIM_OPTIONS
3008 #       set this array to a set of options to vim you always want
3009 #       to have set when calling vim (in .zshrc.local), like:
3010 #           VIM_OPTIONS=( -p )
3011 #       This will cause vim to send every file given on the
3012 #       commandline to be send to it's own tab (needs vim7).
3013 vim() {
3014     VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
3015 }
3016
3017 # make a backup of a file
3018 bk() {
3019     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
3020 }
3021
3022 #f1# grep for patterns in grml's zsh setup
3023 zg() {
3024 #{{{
3025     LANG=C perl -e '
3026
3027 sub usage {
3028     print "usage: zg -[anr] <pattern>\n";
3029     print " Search for patterns in grml'\''s zshrc.\n";
3030     print " zg takes no or exactly one option plus a non empty pattern.\n\n";
3031     print "   options:\n";
3032     print "     --  no options (use if your pattern starts in with a dash.\n";
3033     print "     -a  search for the pattern in all code regions\n";
3034     print "     -n  search for the pattern in non-root code only\n";
3035     print "     -r  search in code for everyone (also root) only\n\n";
3036     print "   The default is -a for non-root users and -r for root.\n\n";
3037     print " If you installed the zshrc to a non-default locations (ie *NOT*\n";
3038     print " in /etc/zsh/zshrc) do: export GRML_ZSHRC=\$HOME/.zshrc\n";
3039     print " ...in case you copied the file to that location.\n\n";
3040     exit 1;
3041 }
3042
3043 if ($ENV{GRML_ZSHRC} ne "") {
3044     $RC = $ENV{GRML_ZSHRC};
3045 } else {
3046     $RC = "/etc/zsh/zshrc";
3047 }
3048
3049 usage if ($#ARGV < 0 || $#ARGV > 1);
3050 if ($> == 0) { $mode = "allonly"; }
3051 else { $mode = "all"; }
3052
3053 $opt = $ARGV[0];
3054 if ($opt eq "--")     { shift; }
3055 elsif ($opt eq "-a")  { $mode = "all"; shift; }
3056 elsif ($opt eq "-n")  { $mode = "nonroot"; shift; }
3057 elsif ($opt eq "-r" ) { $mode = "allonly"; shift; }
3058 elsif ($opt =~ m/^-/ || $#ARGV > 0) { usage(); }
3059
3060 $pattern = $ARGV[0];
3061 usage() if ($pattern eq "");
3062
3063 open FH, "<$RC" or die "zg: Could not open $RC: $!\n";
3064 while ($line = <FH>) {
3065     chomp $line;
3066     if ($line =~ m/^#:grep:marker:for:mika:/) { $markerfound = 1; next; }
3067     next if ($mode eq "nonroot" && markerfound == 0);
3068     break if ($mode eq "allonly" && markerfound == 1);
3069     print $line, "\n" if ($line =~ /$pattern/);
3070 }
3071 close FH;
3072 exit 0;
3073
3074     ' -- "$@"
3075 #}}}
3076     return $?
3077 }
3078
3079 ssl_hashes=( sha512 sha256 sha1 md5 )
3080
3081 for sh in ${ssl_hashes}; do
3082     ssl-cert-${sh}() {
3083         emulate -L zsh
3084         if [[ -z $1 ]] ; then
3085             printf 'usage: %s <file>\n' "ssh-cert-${sh}"
3086             return 1
3087         fi
3088         openssl x509 -noout -fingerprint -${sh} -in $1
3089     }
3090 done; unset sh
3091
3092 ssl-cert-fingerprints() {
3093     emulate -L zsh
3094     local i
3095     if [[ -z $1 ]] ; then
3096         printf 'usage: ssl-cert-fingerprints <file>\n'
3097         return 1
3098     fi
3099     for i in ${ssl_hashes}
3100         do ssl-cert-$i $1;
3101     done
3102 }
3103
3104 ssl-cert-info() {
3105     emulate -L zsh
3106     if [[ -z $1 ]] ; then
3107         printf 'usage: ssl-cert-info <file>\n'
3108         return 1
3109     fi
3110     openssl x509 -noout -text -in $1
3111     ssl-cert-fingerprints $1
3112 }
3113
3114 # }}}
3115
3116 # {{{ make sure our environment is clean regarding colors
3117 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
3118 # }}}
3119
3120 # "persistent history" {{{
3121 # just write important commands you always need to ~/.important_commands
3122 if [[ -r ~/.important_commands ]] ; then
3123     fc -R ~/.important_commands
3124 fi
3125 # }}}
3126
3127 #:grep:marker:for:mika: :-)
3128 ### non-root (EUID != 0) code below
3129 ###
3130
3131 if (( GRML_ALWAYS_LOAD_ALL == 0 )) && (( $EUID == 0 )) ; then
3132     zrclocal
3133     return 0
3134 fi
3135
3136 zrcautoload lookupinit && lookupinit
3137
3138 # variables {{{
3139
3140 # set terminal property (used e.g. by msgid-chooser)
3141 export COLORTERM="yes"
3142
3143 # set default browser
3144 if [[ -z "$BROWSER" ]] ; then
3145     if [[ -n "$DISPLAY" ]] ; then
3146         #v# If X11 is running
3147         check_com -c firefox && export BROWSER=firefox
3148     else
3149         #v# If no X11 is running
3150         check_com -c w3m && export BROWSER=w3m
3151     fi
3152 fi
3153
3154 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
3155 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
3156 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
3157
3158 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
3159 #v# [for non-root only]
3160 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
3161 # }}}
3162
3163 # aliases {{{
3164
3165 # Xterm resizing-fu.
3166 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
3167 alias hide='echo -en "\033]50;nil2\007"'
3168 alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
3169 alias small='echo -en "\033]50;6x10\007"'
3170 alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
3171 alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
3172 alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
3173 alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
3174 alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
3175 alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
3176
3177 # general
3178 #a2# Execute \kbd{du -sch}
3179 alias da='du -sch'
3180 #a2# Execute \kbd{jobs -l}
3181 alias j='jobs -l'
3182
3183 # compile stuff
3184 #a2# Execute \kbd{./configure}
3185 alias CO="./configure"
3186 #a2# Execute \kbd{./configure --help}
3187 alias CH="./configure --help"
3188
3189 # listing stuff
3190 #a2# Execute \kbd{ls -lSrah}
3191 alias dir="ls -lSrah"
3192 #a2# Only show dot-directories
3193 alias lad='ls -d .*(/)'                # only show dot-directories
3194 #a2# Only show dot-files
3195 alias lsa='ls -a .*(.)'                # only show dot-files
3196 #a2# Only files with setgid/setuid/sticky flag
3197 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
3198 #a2# Only show 1st ten symlinks
3199 alias lsl='ls -l *(@)'                 # only symlinks
3200 #a2# Display only executables
3201 alias lsx='ls -l *(*)'                 # only executables
3202 #a2# Display world-{readable,writable,executable} files
3203 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
3204 #a2# Display the ten biggest files
3205 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
3206 #a2# Only show directories
3207 alias lsd='ls -d *(/)'                 # only show directories
3208 #a2# Only show empty directories
3209 alias lse='ls -d *(/^F)'               # only show empty directories
3210 #a2# Display the ten newest files
3211 alias lsnew="ls -rl *(D.om[1,10])"     # display the newest files
3212 #a2# Display the ten oldest files
3213 alias lsold="ls -rtlh *(D.om[1,10])"   # display the oldest files
3214 #a2# Display the ten smallest files
3215 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
3216
3217 # chmod
3218 #a2# Execute \kbd{chmod 600}
3219 alias rw-='chmod 600'
3220 #a2# Execute \kbd{chmod 700}
3221 alias rwx='chmod 700'
3222 #m# a2 r-{}- Execute \kbd{chmod 644}
3223 alias r--='chmod 644'
3224 #a2# Execute \kbd{chmod 755}
3225 alias r-x='chmod 755'
3226
3227 # some useful aliases
3228 #a2# Execute \kbd{mkdir -o}
3229 alias md='mkdir -p'
3230
3231 # console stuff
3232 #a2# Execute \kbd{mplayer -vo fbdev}
3233 alias cmplayer='mplayer -vo fbdev'
3234 #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
3235 alias fbmplayer='mplayer -vo fbdev -fs -zoom'
3236 #a2# Execute \kbd{links2 -driver fb}
3237 alias fblinks='links2 -driver fb'
3238
3239 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3240 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3241 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3242
3243 # simple webserver
3244 check_com -c python && alias http="python -m SimpleHTTPServer"
3245
3246 # Use 'g' instead of 'git':
3247 check_com g || alias g='git'
3248
3249 # work around non utf8 capable software in utf environment via $LANG and luit
3250 if check_com isutfenv && check_com luit ; then
3251     if check_com -c mrxvt ; then
3252         isutfenv && [[ -n "$LANG" ]] && \
3253             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3254     fi
3255
3256     if check_com -c aterm ; then
3257         isutfenv && [[ -n "$LANG" ]] && \
3258             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3259     fi
3260
3261     if check_com -c centericq ; then
3262         isutfenv && [[ -n "$LANG" ]] && \
3263             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3264     fi
3265 fi
3266 # }}}
3267
3268 # useful functions {{{
3269
3270 # searching
3271 #f4# Search for newspostings from authors
3272 agoogle() { ${=BROWSER} "http://groups.google.com/groups?as_uauthors=$*" ; }
3273 #f4# Search Debian Bug Tracking System
3274 debbug()  {
3275     emulate -L zsh
3276     setopt extendedglob
3277     if [[ $# -eq 1 ]]; then
3278         case "$1" in
3279             ([0-9]##)
3280             ${=BROWSER} "http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=$1"
3281             ;;
3282             (*@*)
3283             ${=BROWSER} "http://bugs.debian.org/cgi-bin/pkgreport.cgi?submitter=$1"
3284             ;;
3285             (*)
3286             ${=BROWSER} "http://bugs.debian.org/$*"
3287             ;;
3288         esac
3289     else
3290         print "$0 needs one argument"
3291         return 1
3292     fi
3293 }
3294 #f4# Search Debian Bug Tracking System in mbox format
3295 debbugm() {
3296     emulate -L zsh
3297     bts show --mbox $1
3298 }
3299 #f4# Search DMOZ
3300 dmoz()    {
3301     emulate -L zsh
3302     ${=BROWSER} http://search.dmoz.org/cgi-bin/search\?search=${1// /_}
3303 }
3304 #f4# Search German   Wiktionary
3305 dwicti()  {
3306     emulate -L zsh
3307     ${=BROWSER} http://de.wiktionary.org/wiki/${(C)1// /_}
3308 }
3309 #f4# Search English  Wiktionary
3310 ewicti()  {
3311     emulate -L zsh
3312     ${=BROWSER} http://en.wiktionary.org/wiki/${(C)1// /_}
3313 }
3314 #f4# Search Google Groups
3315 ggogle()  {
3316     emulate -L zsh
3317     ${=BROWSER} "http://groups.google.com/groups?q=$*"
3318 }
3319 #f4# Search Google
3320 google()  {
3321     emulate -L zsh
3322     ${=BROWSER} "http://www.google.com/search?&num=100&q=$*"
3323 }
3324 #f4# Search Google Groups for MsgID
3325 mggogle() {
3326     emulate -L zsh
3327     ${=BROWSER} "http://groups.google.com/groups?selm=$*"
3328 }
3329 #f4# Search Netcraft
3330 netcraft(){
3331     emulate -L zsh
3332     ${=BROWSER} "http://toolbar.netcraft.com/site_report?url=$1"
3333 }
3334 #f4# Use German Wikipedia's full text search
3335 swiki()   {
3336     emulate -L zsh
3337     ${=BROWSER} http://de.wikipedia.org/wiki/Spezial:Search/${(C)1}
3338 }
3339 #f4# search \kbd{dict.leo.org}
3340 oleo()    {
3341     emulate -L zsh
3342     ${=BROWSER} "http://dict.leo.org/?search=$*"
3343 }
3344 #f4# Search German   Wikipedia
3345 wikide()  {
3346     emulate -L zsh
3347     ${=BROWSER} http://de.wikipedia.org/wiki/"${(C)*}"
3348 }
3349 #f4# Search English  Wikipedia
3350 wikien()  {
3351     emulate -L zsh
3352     ${=BROWSER} http://en.wikipedia.org/wiki/"${(C)*}"
3353 }
3354 #f4# Search official debs
3355 wodeb()   {
3356     emulate -L zsh
3357     ${=BROWSER} "http://packages.debian.org/search?keywords=$1&searchon=contents&suite=${2:=unstable}&section=all"
3358 }
3359
3360 #m# f4 gex() Exact search via Google
3361 check_com google && gex () {
3362     google "\"[ $1]\" $*"
3363 }
3364
3365 # misc
3366 #f5# Backup \kbd{file {\rm to} file\_timestamp}
3367 bk() {
3368     emulate -L zsh
3369     cp -b $1 $1_`date --iso-8601=m`
3370 }
3371 #f5# Copied diff
3372 cdiff() {
3373     emulate -L zsh
3374     diff -crd "$@" | egrep -v "^Only in |^Binary files "
3375 }
3376 #f5# cd to directoy and list files
3377 cl() {
3378     emulate -L zsh
3379     cd $1 && ls -a
3380 }
3381 #f5# Cvs add
3382 cvsa() {
3383     emulate -L zsh
3384     cvs add $* && cvs com -m 'initial checkin' $*
3385 }
3386 #f5# Cvs diff
3387 cvsd() {
3388     emulate -L zsh
3389     cvs diff -N $* |& $PAGER
3390 }
3391 #f5# Cvs log
3392 cvsl() {
3393     emulate -L zsh
3394     cvs log $* |& $PAGER
3395 }
3396 #f5# Cvs update
3397 cvsq() {
3398     emulate -L zsh
3399     cvs -nq update
3400 }
3401 #f5# Rcs2log
3402 cvsr() {
3403     emulate -L zsh
3404     rcs2log $* | $PAGER
3405 }
3406 #f5# Cvs status
3407 cvss() {
3408     emulate -L zsh
3409     cvs status -v $*
3410 }
3411 #f5# Disassemble source files using gcc and as
3412 disassemble(){
3413     emulate -L zsh
3414     gcc -pipe -S -o - -O -g $* | as -aldh -o /dev/null
3415 }
3416 #f5# Firefox remote control - open given URL
3417 fir() {
3418     if [ -e /etc/debian_version ]; then
3419         firefox -a iceweasel -remote "openURL($1)" || firefox ${1}&
3420     else
3421         firefox -a firefox -remote "openURL($1)" || firefox ${1}&
3422     fi
3423 }
3424 #f5# Create Directoy and \kbd{cd} to it
3425 mcd() {
3426     mkdir -p "$@" && cd "$@"
3427 }
3428 #f5# Unified diff to timestamped outputfile
3429 mdiff() {
3430     diff -udrP "$1" "$2" > diff.`date "+%Y-%m-%d"`."$1"
3431 }
3432 #f5# Memory overview
3433 memusage() {
3434     ps aux | awk '{if (NR > 1) print $5; if (NR > 2) print "+"} END { print "p" }' | dc
3435 }
3436 #f5# Show contents of gzipped tar file
3437 shtar() {
3438     emulate -L zsh
3439     gunzip -c $1 | tar -tf - -- | $PAGER
3440 }
3441 #f5# Show contents of zip file
3442 shzip() {
3443     emulate -L zsh
3444     unzip -l $1 | $PAGER
3445 }
3446 #f5# Unified diff
3447 udiff() {
3448     emulate -L zsh
3449     diff -urd $* | egrep -v "^Only in |^Binary files "
3450 }
3451 #f5# (Mis)use \kbd{vim} as \kbd{less}
3452 viless() {
3453     emulate -L zsh
3454     vim --cmd 'let no_plugin_maps = 1' -c "so \$VIMRUNTIME/macros/less.vim" "${@:--}"
3455 }
3456
3457 # Function Usage: uopen $URL/$file
3458 #f5# Download a file and display it locally
3459 uopen() {
3460     emulate -L zsh
3461     if ! [[ -n "$1" ]] ; then
3462         print "Usage: uopen \$URL/\$file">&2
3463         return 1
3464     else
3465         FILE=$1
3466         MIME=$(curl --head $FILE | grep Content-Type | cut -d ' ' -f 2 | cut -d\; -f 1)
3467         MIME=${MIME%$'\r'}
3468         curl $FILE | see ${MIME}:-
3469     fi
3470 }
3471
3472 # Function Usage: doc packagename
3473 #f5# \kbd{cd} to /usr/share/doc/\textit{package}
3474 doc() {
3475     emulate -L zsh
3476     cd /usr/share/doc/$1 && ls
3477 }
3478 _doc() { _files -W /usr/share/doc -/ }
3479 check_com compdef && compdef _doc doc
3480
3481 #f5# Make screenshot
3482 sshot() {
3483     [[ ! -d ~/shots  ]] && mkdir ~/shots
3484     #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
3485     cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
3486 }
3487
3488 # list images only
3489 limg() {
3490     local -a images
3491     images=( *.{jpg,gif,png}(.N) )
3492
3493     if [[ $#images -eq 0 ]] ; then
3494         print "No image files found"
3495     else
3496         ls "$images[@]"
3497     fi
3498 }
3499
3500 #f5# Create PDF file from source code
3501 makereadable() {
3502     emulate -L zsh
3503     output=$1
3504     shift
3505     a2ps --medium A4dj -E -o $output $*
3506     ps2pdf $output
3507 }
3508
3509 # zsh with perl-regex - use it e.g. via:
3510 # regcheck '\s\d\.\d{3}\.\d{3} Euro' ' 1.000.000 Euro'
3511 #f5# Checks whether a regex matches or not.\\&\quad Example: \kbd{regcheck '.\{3\} EUR' '500 EUR'}
3512 regcheck() {
3513     emulate -L zsh
3514     zmodload -i zsh/pcre
3515     pcre_compile $1 && \
3516     pcre_match $2 && echo "regex matches" || echo "regex does not match"
3517 }
3518
3519 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
3520 accessed() {
3521     emulate -L zsh
3522     print -l -- *(a-${1:-1})
3523 }
3524
3525 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
3526 changed() {
3527     emulate -L zsh
3528     print -l -- *(c-${1:-1})
3529 }
3530
3531 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
3532 modified() {
3533     emulate -L zsh
3534     print -l -- *(m-${1:-1})
3535 }
3536 # modified() was named new() in earlier versions, add an alias for backwards compatibility
3537 check_com new || alias new=modified
3538
3539 #f5# Grep in history
3540 greph() {
3541     emulate -L zsh
3542     history 0 | grep $1
3543 }
3544 # use colors when GNU grep with color-support
3545 #a2# Execute \kbd{grep -{}-color=auto}
3546 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
3547 #a2# Execute \kbd{grep -i -{}-color=auto}
3548 alias GREP='grep -i --color=auto'
3549
3550 #f5# Watch manpages in a stretched style
3551 man2() { PAGER='dash -c "sed G | /usr/bin/less"' command man "$@" ; }
3552
3553 # usage example: 'lcheck strcpy'
3554 #f5# Find out which libs define a symbol
3555 lcheck() {
3556     if [[ -n "$1" ]] ; then
3557         nm -go /usr/lib/lib*.a 2>/dev/null | grep ":[[:xdigit:]]\{8\} . .*$1"
3558     else
3559         echo "Usage: lcheck <function>" >&2
3560     fi
3561 }
3562
3563 #f5# Clean up directory - remove well known tempfiles
3564 purge() {
3565     FILES=(*~(N) .*~(N) \#*\#(N) *.o(N) a.out(N) *.core(N) *.cmo(N) *.cmi(N) .*.swp(N))
3566     NBFILES=${#FILES}
3567     if [[ $NBFILES > 0 ]] ; then
3568         print $FILES
3569         local ans
3570         echo -n "Remove these files? [y/n] "
3571         read -q ans
3572         if [[ $ans == "y" ]] ; then
3573             rm ${FILES}
3574             echo ">> $PWD purged, $NBFILES files removed"
3575         else
3576             echo "Ok. .. then not.."
3577         fi
3578     fi
3579 }
3580
3581 # Translate DE<=>EN
3582 # 'translate' looks up fot a word in a file with language-to-language
3583 # translations (field separator should be " : "). A typical wordlist looks
3584 # like at follows:
3585 #  | english-word : german-transmission
3586 # It's also only possible to translate english to german but not reciprocal.
3587 # Use the following oneliner to turn back the sort order:
3588 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3589 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3590 #f5# Translates a word
3591 trans() {
3592     emulate -L zsh
3593     case "$1" in
3594         -[dD]*)
3595             translate -l de-en $2
3596             ;;
3597         -[eE]*)
3598             translate -l en-de $2
3599             ;;
3600         *)
3601             echo "Usage: $0 { -D | -E }"
3602             echo "         -D == German to English"
3603             echo "         -E == English to German"
3604     esac
3605 }
3606
3607 #f5# List all occurrences of programm in current PATH
3608 plap() {
3609     emulate -L zsh
3610     if [[ $# = 0 ]] ; then
3611         echo "Usage:    $0 program"
3612         echo "Example:  $0 zsh"
3613         echo "Lists all occurrences of program in the current PATH."
3614     else
3615         ls -l ${^path}/*$1*(*N)
3616     fi
3617 }
3618
3619 # Found in the mailinglistarchive from Zsh (IIRC ~1996)
3620 #f5# Select items for specific command(s) from history
3621 selhist() {
3622     emulate -L zsh
3623     local TAB=$'\t';
3624     (( $# < 1 )) && {
3625         echo "Usage: $0 command"
3626         return 1
3627     };
3628     cmd=(${(f)"$(grep -w $1 $HISTFILE | sort | uniq | pr -tn)"})
3629     print -l $cmd | less -F
3630     echo -n "enter number of desired command [1 - $(( ${#cmd[@]} - 1 ))]: "
3631     local answer
3632     read answer
3633     print -z "${cmd[$answer]#*$TAB}"
3634 }
3635
3636 # Use vim to convert plaintext to HTML
3637 #f5# Transform files to html with highlighting
3638 2html() {
3639     emulate -L zsh
3640     vim -u NONE -n -c ':syntax on' -c ':so $VIMRUNTIME/syntax/2html.vim' -c ':wqa' $1 &>/dev/null
3641 }
3642
3643 # Usage: simple-extract <file>
3644 #f5# Smart archive extractor
3645 simple-extract () {
3646     emulate -L zsh
3647     if [[ -f $1 ]] ; then
3648         case $1 in
3649             *.tar.bz2)  bzip2 -v -d $1      ;;
3650             *.tar.gz)   tar -xvzf $1        ;;
3651             *.rar)      unrar $1            ;;
3652             *.deb)      ar -x $1            ;;
3653             *.bz2)      bzip2 -d $1         ;;
3654             *.lzh)      lha x $1            ;;
3655             *.gz)       gunzip -d $1        ;;
3656             *.tar)      tar -xvf $1         ;;
3657             *.tgz)      gunzip -d $1        ;;
3658             *.tbz2)     tar -jxvf $1        ;;
3659             *.zip)      unzip $1            ;;
3660             *.Z)        uncompress $1       ;;
3661             *)          echo "'$1' Error. Please go away" ;;
3662         esac
3663     else
3664         echo "'$1' is not a valid file"
3665     fi
3666 }
3667
3668 # Usage: smartcompress <file> (<type>)
3669 #f5# Smart archive creator
3670 smartcompress() {
3671     emulate -L zsh
3672     if [[ -n $2 ]] ; then
3673         case $2 in
3674             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
3675             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
3676             tar.Z)          tar -Zcvf$1.$2 $1 ;;
3677             tar)            tar -cvf$1.$2  $1 ;;
3678             gz | gzip)      gzip           $1 ;;
3679             bz2 | bzip2)    bzip2          $1 ;;
3680             *)
3681                 echo "Error: $2 is not a valid compression type"
3682                 ;;
3683         esac
3684     else
3685         smartcompress $1 tar.gz
3686     fi
3687 }
3688
3689 # Usage: show-archive <archive>
3690 #f5# List an archive's content
3691 show-archive() {
3692     emulate -L zsh
3693     if [[ -f $1 ]] ; then
3694         case $1 in
3695             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
3696             *.tar)         tar -tf $1 ;;
3697             *.tgz)         tar -ztf $1 ;;
3698             *.zip)         unzip -l $1 ;;
3699             *.bz2)         bzless $1 ;;
3700             *.deb)         dpkg-deb --fsys-tarfile $1 | tar -tf - -- ;;
3701             *)             echo "'$1' Error. Please go away" ;;
3702         esac
3703     else
3704         echo "'$1' is not a valid archive"
3705     fi
3706 }
3707
3708 # It's shameless stolen from <http://www.vim.org/tips/tip.php?tip_id=167>
3709 #f5# Use \kbd{vim} as your manpage reader
3710 vman() {
3711     emulate -L zsh
3712     man $* | col -b | view -c 'set ft=man nomod nolist' -
3713 }
3714
3715 # function readme() { $PAGER -- (#ia3)readme* }
3716 #f5# View all README-like files in current directory in pager
3717 readme() {
3718     emulate -L zsh
3719     local files
3720     files=(./(#i)*(read*me|lue*m(in|)ut)*(ND))
3721     if (($#files)) ; then
3722         $PAGER $files
3723     else
3724         print 'No README files.'
3725     fi
3726 }
3727
3728 # function ansi-colors()
3729 #f5# Display ANSI colors
3730 ansi-colors() {
3731     typeset esc="\033[" line1 line2
3732     echo " _ _ _40 _ _ _41_ _ _ _42 _ _ 43_ _ _ 44_ _ _45 _ _ _ 46_ _ _ 47_ _ _ 49_ _"
3733     for fore in 30 31 32 33 34 35 36 37; do
3734         line1="$fore "
3735         line2="   "
3736         for back in 40 41 42 43 44 45 46 47 49; do
3737             line1="${line1}${esc}${back};${fore}m Normal ${esc}0m"
3738             line2="${line2}${esc}${back};${fore};1m Bold   ${esc}0m"
3739         done
3740         echo -e "$line1\n$line2"
3741     done
3742 }
3743
3744 #f5# Find all files in \$PATH with setuid bit set
3745 suidfind() { ls -latg $path | grep '^...s' }
3746
3747 # TODO: So, this is the third incarnation of this function!?
3748 #f5# Reload given functions
3749 refunc() {
3750     for func in $argv ; do
3751         unfunction $func
3752         autoload $func
3753     done
3754 }
3755
3756 # a small check to see which DIR is located on which server/partition.
3757 # stolen and modified from Sven's zshrc.forall
3758 #f5# Report diskusage of a directory
3759 dirspace() {
3760     emulate -L zsh
3761     if [[ -n "$1" ]] ; then
3762         for dir in "$@" ; do
3763             if [[ -d "$dir" ]] ; then
3764                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3765             else
3766                 echo "warning: $dir does not exist" >&2
3767             fi
3768         done
3769     else
3770         for dir in $path; do
3771             if [[ -d "$dir" ]] ; then
3772                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3773             else
3774                 echo "warning: $dir does not exist" >&2
3775             fi
3776         done
3777     fi
3778 }
3779
3780 # % slow_print `cat /etc/passwd`
3781 #f5# Slowly print out parameters
3782 slow_print() {
3783     for argument in "$@" ; do
3784         for ((i = 1; i <= ${#1} ;i++)) ; do
3785             print -n "${argument[i]}"
3786             sleep 0.08
3787         done
3788         print -n " "
3789     done
3790     print ""
3791 }
3792
3793 #f5# Show some status info
3794 status() {
3795     print
3796     print "Date..: "$(date "+%Y-%m-%d %H:%M:%S")
3797     print "Shell.: Zsh $ZSH_VERSION (PID = $$, $SHLVL nests)"
3798     print "Term..: $TTY ($TERM), ${BAUD:+$BAUD bauds, }$COLUMNS x $LINES chars"
3799     print "Login.: $LOGNAME (UID = $EUID) on $HOST"
3800     print "System: $(cat /etc/[A-Za-z]*[_-][rv]e[lr]*)"
3801     print "Uptime:$(uptime)"
3802     print
3803 }
3804
3805 # Rip an audio CD
3806 #f5# Rip an audio CD
3807 audiorip() {
3808     mkdir -p ~/ripps
3809     cd ~/ripps
3810     cdrdao read-cd --device $DEVICE --driver generic-mmc audiocd.toc
3811     cdrdao read-cddb --device $DEVICE --driver generic-mmc audiocd.toc
3812     echo " * Would you like to burn the cd now? (yes/no)"
3813     read input
3814     if [[ "$input" = "yes" ]] ; then
3815         echo " ! Burning Audio CD"
3816         audioburn
3817         echo " * done."
3818     else
3819         echo " ! Invalid response."
3820     fi
3821 }
3822
3823 # and burn it
3824 #f5# Burn an audio CD (in combination with audiorip)
3825 audioburn() {
3826     cd ~/ripps
3827     cdrdao write --device $DEVICE --driver generic-mmc audiocd.toc
3828     echo " * Should I remove the temporary files? (yes/no)"
3829     read input
3830     if [[ "$input" = "yes" ]] ; then
3831         echo " ! Removing Temporary Files."
3832         cd ~
3833         rm -rf ~/ripps
3834         echo " * done."
3835     else
3836         echo " ! Invalid response."
3837     fi
3838 }
3839
3840 #f5# Make an audio CD from all mp3 files
3841 mkaudiocd() {
3842     # TODO: do the renaming more zshish, possibly with zmv()
3843     emulate -L zsh
3844     cd ~/ripps
3845     for i in *.[Mm][Pp]3; do mv "$i" `echo $i | tr '[A-Z]' '[a-z]'`; done
3846     for i in *.mp3; do mv "$i" `echo $i | tr ' ' '_'`; done
3847     for i in *.mp3; do mpg123 -w `basename $i .mp3`.wav $i; done
3848     normalize -m *.wav
3849     for i in *.wav; do sox $i.wav -r 44100 $i.wav resample; done
3850 }
3851
3852 #f5# Create an ISO image. You are prompted for\\&\quad volume name, filename and directory
3853 mkiso() {
3854     emulate -L zsh
3855     echo " * Volume name "
3856     read volume
3857     echo " * ISO Name (ie. tmp.iso)"
3858     read iso
3859     echo " * Directory or File"
3860     read files
3861     mkisofs -o ~/$iso -A $volume -allow-multidot -J -R -iso-level 3 -V $volume -R $files
3862 }
3863
3864 #f5# Simple thumbnails generator
3865 genthumbs() {
3866     rm -rf thumb-* index.html
3867     echo "
3868 <html>
3869   <head>
3870     <title>Images</title>
3871   </head>
3872   <body>" > index.html
3873     for f in *.(gif|jpeg|jpg|png) ; do
3874         convert -size 100x200 "$f" -resize 100x200 thumb-"$f"
3875         echo "    <a href=\"$f\"><img src=\"thumb-$f\"></a>" >> index.html
3876     done
3877     echo "
3878   </body>
3879 </html>" >> index.html
3880 }
3881
3882 #f5# Set all ulimit parameters to \kbd{unlimited}
3883 allulimit() {
3884     ulimit -c unlimited
3885     ulimit -d unlimited
3886     ulimit -f unlimited
3887     ulimit -l unlimited
3888     ulimit -n unlimited
3889     ulimit -s unlimited
3890     ulimit -t unlimited
3891 }
3892
3893 # ogg2mp3 with bitrate of 192
3894 ogg2mp3_192() {
3895     emulate -L zsh
3896     oggdec -o - $1 | lame -b 192 - ${1:r}.mp3
3897 }
3898
3899 #f5# RFC 2396 URL encoding in Z-Shell
3900 urlencode() {
3901     emulate -L zsh
3902     setopt extendedglob
3903     input=( ${(s::)1} )
3904     print ${(j::)input/(#b)([^A-Za-z0-9_.!~*\'\(\)-])/%${(l:2::0:)$(([##16]#match))}}
3905 }
3906
3907 # http://strcat.de/blog/index.php?/archives/335-Software-sauber-deinstallieren...html
3908 #f5# Log 'make install' output
3909 mmake() {
3910     emulate -L zsh
3911     [[ ! -d ~/.errorlogs ]] && mkdir ~/.errorlogs
3912     make -n install > ~/.errorlogs/${PWD##*/}-makelog
3913 }
3914
3915 #f5# Indent source code
3916 smart-indent() {
3917     indent -npro -kr -i8 -ts8 -sob -l80 -ss -ncs "$@"
3918 }
3919
3920 # highlight important stuff in diff output, usage example: hg diff | hidiff
3921 #m# a2 hidiff \kbd{histring} oneliner for diffs
3922 check_com -c histring && \
3923     alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
3924
3925 # rename pictures based on information found in exif headers
3926 #f5# Rename pictures based on information found in exif headers
3927 exirename() {
3928     emulate -L zsh
3929     if [[ $# -lt 1 ]] ; then
3930         echo 'Usage: jpgrename $FILES' >& 2
3931         return 1
3932     else
3933         echo -n 'Checking for jhead with version newer than 1.9: '
3934         jhead_version=`jhead -h | grep 'used by most Digital Cameras.  v.*' | awk '{print $6}' | tr -d v`
3935         if [[ $jhead_version > '1.9' ]]; then
3936             echo 'success - now running jhead.'
3937             jhead -n%Y-%m-%d_%Hh%M_%f $*
3938         else
3939             echo 'failed - exiting.'
3940         fi
3941     fi
3942 }
3943
3944 # get_ic() - queries imap servers for capabilities; real simple. no imaps
3945 ic_get() {
3946     emulate -L zsh
3947     local port
3948     if [[ ! -z $1 ]] ; then
3949         port=${2:-143}
3950         print "querying imap server on $1:${port}...\n";
3951         print "a1 capability\na2 logout\n" | nc $1 ${port}
3952     else
3953         print "usage:\n  $0 <imap-server> [port]"
3954     fi
3955 }
3956
3957 # creates a Maildir/ with its {new,cur,tmp} subdirs
3958 mkmaildir() {
3959     emulate -L zsh
3960     local root subdir
3961     root=${MAILDIR_ROOT:-${HOME}/Mail}
3962     if [[ -z ${1} ]] ; then print "Usage:\n $0 <dirname>" ; return 1 ; fi
3963     subdir=${1}
3964     mkdir -p ${root}/${subdir}/{cur,new,tmp}
3965 }
3966
3967 #f5# Change the xterm title from within GNU-screen
3968 xtrename() {
3969     emulate -L zsh
3970     if [[ $1 != "-f" ]] ; then
3971         if [[ -z ${DISPLAY} ]] ; then
3972             printf 'xtrename only makes sense in X11.\n'
3973             return 1
3974         fi
3975     else
3976         shift
3977     fi
3978     if [[ -z $1 ]] ; then
3979         printf 'usage: xtrename [-f] "title for xterm"\n'
3980         printf '  renames the title of xterm from _within_ screen.\n'
3981         printf '  also works without screen.\n'
3982         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3983         return 0
3984     fi
3985     print -n "\eP\e]0;${1}\C-G\e\\"
3986     return 0
3987 }
3988
3989 # hl() highlighted less
3990 # http://ft.bewatermyfriend.org/comp/data/zsh/zfunct.html
3991 if check_com -c highlight ; then
3992     function hl() {
3993     emulate -L zsh
3994         local theme lang
3995         theme=${HL_THEME:-""}
3996         case ${1} in
3997             (-l|--list)
3998                 ( printf 'available languages (syntax parameter):\n\n' ;
3999                     highlight --list-langs ; ) | less -SMr
4000                 ;;
4001             (-t|--themes)
4002                 ( printf 'available themes (style parameter):\n\n' ;
4003                     highlight --list-themes ; ) | less -SMr
4004                 ;;
4005             (-h|--help)
4006                 printf 'usage: hl <syntax[:theme]> <file>\n'
4007                 printf '    available options: --list (-l), --themes (-t), --help (-h)\n\n'
4008                 printf '  Example: hl c main.c\n'
4009                 ;;
4010             (*)
4011                 if [[ -z ${2} ]] || (( ${#argv} > 2 )) ; then
4012                     printf 'usage: hl <syntax[:theme]> <file>\n'
4013                     printf '    available options: --list (-l), --themes (-t), --help (-h)\n'
4014                     (( ${#argv} > 2 )) && printf '  Too many arguments.\n'
4015                     return 1
4016                 fi
4017                 lang=${1%:*}
4018                 [[ ${1} == *:* ]] && [[ -n ${1#*:} ]] && theme=${1#*:}
4019                 if [[ -n ${theme} ]] ; then
4020                     highlight --xterm256 --syntax ${lang} --style ${theme} ${2} | less -SMr
4021                 else
4022                     highlight --ansi --syntax ${lang} ${2} | less -SMr
4023                 fi
4024                 ;;
4025         esac
4026         return 0
4027     }
4028     # ... and a proper completion for hl()
4029     # needs 'highlight' as well, so it fits fine in here.
4030     function _hl_genarg()  {
4031         local expl
4032         if [[ -prefix 1 *: ]] ; then
4033             local themes
4034             themes=(${${${(f)"$(LC_ALL=C highlight --list-themes)"}/ #/}:#*(Installed|Use name)*})
4035             compset -P 1 '*:'
4036             _wanted -C list themes expl theme compadd ${themes}
4037         else
4038             local langs
4039             langs=(${${${(f)"$(LC_ALL=C highlight --list-langs)"}/ #/}:#*(Installed|Use name)*})
4040             _wanted -C list languages expl languages compadd -S ':' -q ${langs}
4041         fi
4042     }
4043     function _hl_complete() {
4044         _arguments -s '1: :_hl_genarg' '2:files:_path_files'
4045     }
4046     compdef _hl_complete hl
4047 fi
4048
4049 # TODO:
4050 # Rewrite this by either using tinyurl.com's API
4051 # or using another shortening service to comply with
4052 # tinyurl.com's policy.
4053 #
4054 # Create small urls via http://tinyurl.com using wget(1).
4055 #function zurl() {
4056 #    emulate -L zsh
4057 #    [[ -z $1 ]] && { print "USAGE: zurl <URL>" ; return 1 }
4058 #
4059 #    local PN url tiny grabber search result preview
4060 #    PN=$0
4061 #    url=$1
4062 ##   Check existence of given URL with the help of ping(1).
4063 ##   N.B. ping(1) only works without an eventual given protocol.
4064 #    ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
4065 #        read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
4066 #
4067 #    if (( $? == 0 )) ; then
4068 ##           Prepend 'http://' to given URL where necessary for later output.
4069 #            [[ ${url} != http(s|)://* ]] && url='http://'${url}
4070 #            tiny='http://tinyurl.com/create.php?url='
4071 #            if check_com -c wget ; then
4072 #                grabber='wget -O- -o/dev/null'
4073 #            else
4074 #                print "wget is not available, but mandatory for ${PN}. Aborting."
4075 #            fi
4076 ##           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
4077 #            search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
4078 #            result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
4079 ##           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
4080 #            preview='http://preview.'${result#http://}
4081 #
4082 #            printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
4083 #            printf '%s\t%s\n\n' 'Given URL:' ${url}
4084 #            printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
4085 #    else
4086 #        return 1
4087 #    fi
4088 #}
4089
4090 #f2# Print a specific line of file(s).
4091 linenr () {
4092 # {{{
4093     emulate -L zsh
4094     if [ $# -lt 2 ] ; then
4095        print "Usage: linenr <number>[,<number>] <file>" ; return 1
4096     elif [ $# -eq 2 ] ; then
4097          local number=$1
4098          local file=$2
4099          command ed -s $file <<< "${number}n"
4100     else
4101          local number=$1
4102          shift
4103          for file in "$@" ; do
4104              if [ ! -d $file ] ; then
4105                 echo "${file}:"
4106                 command ed -s $file <<< "${number}n" 2> /dev/null
4107              else
4108                 continue
4109              fi
4110          done | less
4111     fi
4112 # }}}
4113 }
4114
4115 #f2# Find history events by search pattern and list them by date.
4116 whatwhen()  {
4117 # {{{
4118     emulate -L zsh
4119     local usage help ident format_l format_s first_char remain first last
4120     usage='USAGE: whatwhen [options] <searchstring> <search range>'
4121     help='Use `whatwhen -h'\'' for further explanations.'
4122     ident=${(l,${#${:-Usage: }},, ,)}
4123     format_l="${ident}%s\t\t\t%s\n"
4124     format_s="${format_l//(\\t)##/\\t}"
4125     # Make the first char of the word to search for case
4126     # insensitive; e.g. [aA]
4127     first_char=[${(L)1[1]}${(U)1[1]}]
4128     remain=${1[2,-1]}
4129     # Default search range is `-100'.
4130     first=${2:-\-100}
4131     # Optional, just used for `<first> <last>' given.
4132     last=$3
4133     case $1 in
4134         ("")
4135             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
4136             printf '%s\n%s\n\n' ${usage} ${help} && return 1
4137         ;;
4138         (-h)
4139             printf '%s\n\n' ${usage}
4140             print 'OPTIONS:'
4141             printf $format_l '-h' 'show help text'
4142             print '\f'
4143             print 'SEARCH RANGE:'
4144             printf $format_l "'0'" 'the whole history,'
4145             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
4146             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
4147             printf '\n%s\n' 'EXAMPLES:'
4148             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
4149             printf $format_l 'whatwhen zsh -250'
4150             printf $format_l 'whatwhen foo 1 99'
4151         ;;
4152         (\?)
4153             printf '%s\n%s\n\n' ${usage} ${help} && return 1
4154         ;;
4155         (*)
4156             # -l list results on stout rather than invoking $EDITOR.
4157             # -i Print dates as in YYYY-MM-DD.
4158             # -m Search for a - quoted - pattern within the history.
4159             fc -li -m "*${first_char}${remain}*" $first $last
4160         ;;
4161     esac
4162 # }}}
4163 }
4164
4165 # change fluxbox keys from 'Alt-#' to 'Alt-F#' and vice versa
4166 fluxkey-change() {
4167     emulate -L zsh
4168     [[ -n "$FLUXKEYS" ]] || local FLUXKEYS="$HOME/.fluxbox/keys"
4169     if ! [[ -r "$FLUXKEYS" ]] ; then
4170         echo "Sorry, \$FLUXKEYS file $FLUXKEYS could not be read - nothing to be done."
4171         return 1
4172     else
4173         if grep -q 'Mod1 F[0-9] :Workspace [0-9]' $FLUXKEYS ; then
4174             echo -n 'Switching to Alt-# mode in ~/.fluxbox/keys: '
4175             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)F\([0-9]\+[: space :]\+:Workspace.*\)|\1\2|' $FLUXKEYS && echo done || echo failed
4176         elif grep -q 'Mod1 [0-9] :Workspace [0-9]' $FLUXKEYS ; then
4177             echo -n 'Switching to Alt-F# mode in ~/.fluxbox/keys: '
4178             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)\([0-9]\+[: space :]\+:Workspace.*\)|\1F\2|' $FLUXKEYS && echo done || echo failed
4179         else
4180             echo 'Sorry, do not know what to do.'
4181             return 1
4182         fi
4183     fi
4184 }
4185
4186 # retrieve weather information on the console
4187 # Usage example: 'weather LOWG'
4188 weather() {
4189     emulate -L zsh
4190     [[ -n "$1" ]] || {
4191         print 'Usage: weather <station_id>' >&2
4192         print 'List of stations: http://en.wikipedia.org/wiki/List_of_airports_by_ICAO_code'>&2
4193         return 1
4194     }
4195
4196     local VERBOSE="yes"    # TODO: Make this a command line switch
4197
4198     local ODIR=`pwd`
4199     local PLACE="${1:u}"
4200     local DIR="${HOME}/.weather"
4201     local LOG="${DIR}/log"
4202
4203     [[ -d ${DIR} ]] || {
4204         print -n "Creating ${DIR}: "
4205         mkdir ${DIR}
4206         print 'done'
4207     }
4208
4209     print "Retrieving information for ${PLACE}:"
4210     print
4211     cd ${DIR} && wget -T 10 --no-verbose --output-file=$LOG --timestamping http://weather.noaa.gov/pub/data/observations/metar/decoded/$PLACE.TXT
4212
4213     if [[ $? -eq 0 ]] ; then
4214         if [[ -n "$VERBOSE" ]] ; then
4215             cat ${PLACE}.TXT
4216         else
4217             DATE=$(grep 'UTC' ${PLACE}.TXT | sed 's#.* /##')
4218             TEMPERATURE=$(awk '/Temperature/ { print $4" degree Celcius / " $2" degree Fahrenheit" }' ${PLACE}.TXT | tr -d '(')
4219             echo "date: $DATE"
4220             echo "temp:  $TEMPERATURE"
4221         fi
4222     else
4223         print "There was an error retrieving the weather information for $PLACE" >&2
4224         cat $LOG
4225         cd $ODIR
4226         return 1
4227     fi
4228     cd $ODIR
4229 }
4230 # }}}
4231
4232 # mercurial related stuff {{{
4233 if check_com -c hg ; then
4234     # gnu like diff for mercurial
4235     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
4236     #f5# GNU like diff for mercurial
4237     hgdi() {
4238         emulate -L zsh
4239         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
4240     }
4241
4242     # build debian package
4243     #a2# Alias for \kbd{hg-buildpackage}
4244     alias hbp='hg-buildpackage'
4245
4246     # execute commands on the versioned patch-queue from the current repos
4247     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
4248
4249     # diffstat for specific version of a mercurial repository
4250     #   hgstat      => display diffstat between last revision and tip
4251     #   hgstat 1234 => display diffstat between revision 1234 and tip
4252     #f5# Diffstat for specific version of a mercurial repos
4253     hgstat() {
4254         emulate -L zsh
4255         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
4256     }
4257
4258 fi # end of check whether we have the 'hg'-executable
4259
4260 # }}}
4261
4262 # some useful commands often hard to remember - let's grep for them {{{
4263 # actually use our zg() function now. :)
4264
4265 # Work around ion/xterm resize bug.
4266 #if [[ "$SHLVL" -eq 1 ]]; then
4267 #       if check_com -c resize ; then
4268 #               eval `resize </dev/null`
4269 #       fi
4270 #fi
4271
4272 # enable jackd:
4273 #  /usr/bin/jackd -dalsa -dhw:0 -r48000 -p1024 -n2
4274 # now play audio file:
4275 #  alsaplayer -o jack foobar.mp3
4276
4277 # send files via netcat
4278 # on sending side:
4279 #  send() {j=$*; tar cpz ${j/%${!#}/}|nc -w 1 ${!#} 51330;}
4280 #  send dir* $HOST
4281 #  alias receive='nc -vlp 51330 | tar xzvp'
4282
4283 # debian stuff:
4284 # dh_make -e foo@localhost -f $1
4285 # dpkg-buildpackage -rfakeroot
4286 # lintian *.deb
4287 # dpkg-scanpackages ./ /dev/null | gzip > Packages.gz
4288 # dpkg-scansources . | gzip > Sources.gz
4289 # grep-dctrl --field Maintainer $* /var/lib/apt/lists/*
4290
4291 # other stuff:
4292 # convert -geometry 200x200 -interlace LINE -verbose
4293 # ldapsearch -x -b "OU=Bedienstete,O=tug" -h ldap.tugraz.at sn=$1
4294 # ps -ao user,pcpu,start,command
4295 # gpg --keyserver blackhole.pca.dfn.de --recv-keys
4296 # xterm -bg black -fg yellow -fn -misc-fixed-medium-r-normal--14-140-75-75-c-90-iso8859-15 -ah
4297 # nc -vz $1 1-1024   # portscan via netcat
4298 # wget --mirror --no-parent --convert-links
4299 # pal -d `date +%d`
4300 # autoload -U tetris; zle -N tetris; bindkey '...' ; echo "press ... for playing tennis"
4301 #
4302 # modify console cursor
4303 # see http://www.tldp.org/HOWTO/Framebuffer-HOWTO-5.html
4304 # print $'\e[?96;0;64c'
4305 # }}}
4306
4307 # grml-small cleanups {{{
4308
4309 # The following is used to remove zsh-config-items that do not work
4310 # in grml-small by default.
4311 # If you do not want these adjustments (for whatever reason), set
4312 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
4313 # sources if it is there).
4314
4315 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
4316
4317     unset abk[V]
4318     unalias    'V'      &> /dev/null
4319     unfunction vman     &> /dev/null
4320     unfunction viless   &> /dev/null
4321     unfunction 2html    &> /dev/null
4322
4323     # manpages are not in grmlsmall
4324     unfunction manzsh   &> /dev/null
4325     unfunction man2     &> /dev/null
4326
4327 fi
4328
4329 #}}}
4330
4331 zrclocal
4332
4333 ## genrefcard.pl settings {{{
4334
4335 ### doc strings for external functions from files
4336 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
4337
4338 ### example: split functions-search 8,16,24,32
4339 #@# split functions-search 8
4340
4341 ## }}}
4342
4343 ## END OF FILE #################################################################
4344 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
4345 # Local variables:
4346 # mode: sh
4347 # End: