etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is439(){
 148     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 #f1# Checks whether or not you're running grml
 154 isgrml(){
 155     [[ -f /etc/grml_version ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running a grml cd
 160 isgrmlcd(){
 161     [[ -f /etc/grml_cd ]] && return 0
 162     return 1
 163 }
 164
 165 if isgrml ; then
 166 #f1# Checks whether or not you're running grml-small
 167     isgrmlsmall() {
 168         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 169             return 0
 170         fi
 171         return 1
 172     }
 173 else
 174     isgrmlsmall() { return 1 }
 175 fi
 176
 177 isdarwin(){
 178     [[ $OSTYPE == darwin* ]] && return 0
 179     return 1
 180 }
 181
 182 isfreebsd(){
 183     [[ $OSTYPE == freebsd* ]] && return 0
 184     return 1
 185 }
 186
 187 #f1# are we running within an utf environment?
 188 isutfenv() {
 189     case "$LANG $CHARSET $LANGUAGE" in
 190         *utf*) return 0 ;;
 191         *UTF*) return 0 ;;
 192         *)     return 1 ;;
 193     esac
 194 }
 195
 196 # check for user, if not running as root set $SUDO to sudo
 197 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 198
 199 # change directory to home on first invocation of zsh
 200 # important for rungetty -> autologin
 201 # Thanks go to Bart Schaefer!
 202 isgrml && checkhome() {
 203     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 204         export ALREADY_DID_CD_HOME=$HOME
 205         cd
 206     fi
 207 }
 208
 209 # check for zsh v3.1.7+
 210
 211 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 212      || ${ZSH_VERSION} == 3.<2->.<->*    \
 213      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 214
 215     printf '-!-\n'
 216     printf '-!- In this configuration we try to make use of features, that only\n'
 217     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 218     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 219     printf '-!- advanced features in all supported versions.\n'
 220     printf '-!-\n'
 221     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 222     printf '-!-\n'
 223     printf '-!- While this *may* work, it might as well fail.\n'
 224     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 225     printf '-!-\n'
 226     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 227     printf '-!- If it does today, you'\''ve been lucky.\n'
 228     printf '-!-\n'
 229     printf '-!- Ye been warned!\n'
 230     printf '-!-\n'
 231
 232     function zstyle() { : }
 233 fi
 234
 235 # autoload wrapper - use this one instead of autoload directly
 236 # We need to define this function as early as this, because autoloading
 237 # 'is-at-least()' needs it.
 238 function zrcautoload() {
 239     emulate -L zsh
 240     setopt extended_glob
 241     local fdir ffile
 242     local -i ffound
 243
 244     ffile=$1
 245     (( ffound = 0 ))
 246     for fdir in ${fpath} ; do
 247         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 248     done
 249
 250     (( ffound == 0 )) && return 1
 251     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 252         autoload -U ${ffile} || return 1
 253     else
 254         autoload ${ffile} || return 1
 255     fi
 256     return 0
 257 }
 258
 259 # Load is-at-least() for more precise version checks Note that this test will
 260 # *always* fail, if the is-at-least function could not be marked for
 261 # autoloading.
 262 zrcautoload is-at-least || is-at-least() { return 1 }
 263
 264 # set some important options (as early as possible)
 265
 266 # append history list to the history file; this is the default but we make sure
 267 # because it's required for share_history.
 268 setopt append_history
 269
 270 # import new commands from the history file also in other zsh-session
 271 is4 && setopt share_history
 272
 273 # save each command's beginning timestamp and the duration to the history file
 274 setopt extended_history
 275
 276 # If a new command line being added to the history list duplicates an older
 277 # one, the older command is removed from the list
 278 is4 && setopt histignorealldups
 279
 280 # remove command lines from the history list when the first character on the
 281 # line is a space
 282 setopt histignorespace
 283
 284 # if a command is issued that can't be executed as a normal command, and the
 285 # command is the name of a directory, perform the cd command to that directory.
 286 setopt auto_cd
 287
 288 # in order to use #, ~ and ^ for filename generation grep word
 289 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 290 # don't forget to quote '^', '~' and '#'!
 291 setopt extended_glob
 292
 293 # display PID when suspending processes as well
 294 setopt longlistjobs
 295
 296 # try to avoid the 'zsh: no matches found...'
 297 setopt nonomatch
 298
 299 # report the status of backgrounds jobs immediately
 300 setopt notify
 301
 302 # whenever a command completion is attempted, make sure the entire command path
 303 # is hashed first.
 304 setopt hash_list_all
 305
 306 # not just at the end
 307 setopt completeinword
 308
 309 # Don't send SIGHUP to background processes when the shell exits.
 310 setopt nohup
 311
 312 # make cd push the old directory onto the directory stack.
 313 setopt auto_pushd
 314
 315 # avoid "beep"ing
 316 setopt nobeep
 317
 318 # don't push the same dir twice.
 319 setopt pushd_ignore_dups
 320
 321 # * shouldn't match dotfiles. ever.
 322 setopt noglobdots
 323
 324 # use zsh style word splitting
 325 setopt noshwordsplit
 326
 327 # don't error out when unset parameters are used
 328 setopt unset
 329
 330 # setting some default values
 331 NOCOR=${NOCOR:-0}
 332 NOMENU=${NOMENU:-0}
 333 NOPRECMD=${NOPRECMD:-0}
 334 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 335 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 336 BATTERY=${BATTERY:-0}
 337 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 338 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 339
 340 typeset -ga ls_options
 341 typeset -ga grep_options
 342 if ls --help 2> /dev/null | grep -q GNU; then
 343     ls_options=( --color=auto )
 344 elif [[ $OSTYPE == freebsd* ]]; then
 345     ls_options=( -G )
 346 fi
 347 if grep --help 2> /dev/null | grep -q GNU || \
 348    [[ $OSTYPE == freebsd* ]]; then
 349     grep_options=( --color=auto )
 350 fi
 351
 352 # utility functions
 353 # this function checks if a command exists and returns either true
 354 # or false. This avoids using 'which' and 'whence', which will
 355 # avoid problems with aliases for which on certain weird systems. :-)
 356 # Usage: check_com [-c|-g] word
 357 #   -c  only checks for external commands
 358 #   -g  does the usual tests and also checks for global aliases
 359 check_com() {
 360     emulate -L zsh
 361     local -i comonly gatoo
 362
 363     if [[ $1 == '-c' ]] ; then
 364         (( comonly = 1 ))
 365         shift
 366     elif [[ $1 == '-g' ]] ; then
 367         (( gatoo = 1 ))
 368     else
 369         (( comonly = 0 ))
 370         (( gatoo = 0 ))
 371     fi
 372
 373     if (( ${#argv} != 1 )) ; then
 374         printf 'usage: check_com [-c] <command>\n' >&2
 375         return 1
 376     fi
 377
 378     if (( comonly > 0 )) ; then
 379         [[ -n ${commands[$1]}  ]] && return 0
 380         return 1
 381     fi
 382
 383     if   [[ -n ${commands[$1]}    ]] \
 384       || [[ -n ${functions[$1]}   ]] \
 385       || [[ -n ${aliases[$1]}     ]] \
 386       || [[ -n ${reswords[(r)$1]} ]] ; then
 387
 388         return 0
 389     fi
 390
 391     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 392         return 0
 393     fi
 394
 395     return 1
 396 }
 397
 398 # creates an alias and precedes the command with
 399 # sudo if $EUID is not zero.
 400 salias() {
 401     emulate -L zsh
 402     local only=0 ; local multi=0
 403     while [[ $1 == -* ]] ; do
 404         case $1 in
 405             (-o) only=1 ;;
 406             (-a) multi=1 ;;
 407             (--) shift ; break ;;
 408             (-h)
 409                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 410                 printf '  -h      shows this help text.\n'
 411                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 412                 printf '          be careful using this option.\n'
 413                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 414                 return 0
 415                 ;;
 416             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 417         esac
 418         shift
 419     done
 420
 421     if (( ${#argv} > 1 )) ; then
 422         printf 'Too many arguments %s\n' "${#argv}"
 423         return 1
 424     fi
 425
 426     key="${1%%\=*}" ;  val="${1#*\=}"
 427     if (( EUID == 0 )) && (( only == 0 )); then
 428         alias -- "${key}=${val}"
 429     elif (( EUID > 0 )) ; then
 430         (( multi > 0 )) && val="${val// ; / ; sudo }"
 431         alias -- "${key}=sudo ${val}"
 432     fi
 433
 434     return 0
 435 }
 436
 437 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 438 # usage: uprint foo
 439 #   Where foo is the *name* of the parameter you want printed.
 440 #   Note that foo is no typo; $foo would be wrong here!
 441 if ! is42 ; then
 442     uprint () {
 443         emulate -L zsh
 444         local -a u
 445         local w
 446         local parameter=$1
 447
 448         if [[ -z ${parameter} ]] ; then
 449             printf 'usage: uprint <parameter>\n'
 450             return 1
 451         fi
 452
 453         for w in ${(P)parameter} ; do
 454             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 455         done
 456
 457         builtin print -l $u
 458     }
 459 fi
 460
 461 # Check if we can read given files and source those we can.
 462 xsource() {
 463     if (( ${#argv} < 1 )) ; then
 464         printf 'usage: xsource FILE(s)...\n' >&2
 465         return 1
 466     fi
 467
 468     while (( ${#argv} > 0 )) ; do
 469         [[ -r "$1" ]] && source "$1"
 470         shift
 471     done
 472     return 0
 473 }
 474
 475 # Check if we can read a given file and 'cat(1)' it.
 476 xcat() {
 477     emulate -L zsh
 478     if (( ${#argv} != 1 )) ; then
 479         printf 'usage: xcat FILE\n' >&2
 480         return 1
 481     fi
 482
 483     [[ -r $1 ]] && cat $1
 484     return 0
 485 }
 486
 487 # Remove these functions again, they are of use only in these
 488 # setup files. This should be called at the end of .zshrc.
 489 xunfunction() {
 490     emulate -L zsh
 491     local -a funcs
 492     funcs=(salias xcat xsource xunfunction zrcautoload)
 493
 494     for func in $funcs ; do
 495         [[ -n ${functions[$func]} ]] \
 496             && unfunction $func
 497     done
 498     return 0
 499 }
 500
 501 # this allows us to stay in sync with grml's zshrc and put own
 502 # modifications in ~/.zshrc.local
 503 zrclocal() {
 504     xsource "/etc/zsh/zshrc.local"
 505     xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
 506     return 0
 507 }
 508
 509 # locale setup
 510 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 511     xsource "/etc/default/locale"
 512 fi
 513
 514 for var in LANG LC_ALL LC_MESSAGES ; do
 515     [[ -n ${(P)var} ]] && export $var
 516 done
 517
 518 xsource "/etc/sysconfig/keyboard"
 519
 520 TZ=$(xcat /etc/timezone)
 521
 522 # set some variables
 523 if check_com -c vim ; then
 524 #v#
 525     export EDITOR=${EDITOR:-vim}
 526 else
 527     export EDITOR=${EDITOR:-vi}
 528 fi
 529
 530 #v#
 531 export PAGER=${PAGER:-less}
 532
 533 #v#
 534 export MAIL=${MAIL:-/var/mail/$USER}
 535
 536 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 537 export SHELL='/bin/zsh'
 538
 539 # color setup for ls:
 540 check_com -c dircolors && eval $(dircolors -b)
 541 # color setup for ls on OS X / FreeBSD:
 542 isdarwin && export CLICOLOR=1
 543 isfreebsd && export CLICOLOR=1
 544
 545 # do MacPorts setup on darwin
 546 if isdarwin && [[ -d /opt/local ]]; then
 547     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 548     # zshenv.
 549     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 550     MANPATH="/opt/local/share/man:$MANPATH"
 551 fi
 552 # do Fink setup on darwin
 553 isdarwin && xsource /sw/bin/init.sh
 554
 555 # load our function and completion directories
 556 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 557     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 558     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 559         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 560             zrcautoload ${func:t}
 561         done
 562     fi
 563 done
 564 unset fdir func
 565
 566 # support colors in less
 567 export LESS_TERMCAP_mb=$'\E[01;31m'
 568 export LESS_TERMCAP_md=$'\E[01;31m'
 569 export LESS_TERMCAP_me=$'\E[0m'
 570 export LESS_TERMCAP_se=$'\E[0m'
 571 export LESS_TERMCAP_so=$'\E[01;44;33m'
 572 export LESS_TERMCAP_ue=$'\E[0m'
 573 export LESS_TERMCAP_us=$'\E[01;32m'
 574
 575 # mailchecks
 576 MAILCHECK=30
 577
 578 # report about cpu-/system-/user-time of command if running longer than
 579 # 5 seconds
 580 REPORTTIME=5
 581
 582 # watch for everyone but me and root
 583 watch=(notme root)
 584
 585 # automatically remove duplicates from these arrays
 586 typeset -U path cdpath fpath manpath
 587
 588 # Remove zle-line-{init,finish} if it looks like it turns smkx. This would be
 589 # better fixed by working with those modes too, but we use way too many
 590 # hardcoded bindings for now.
 591 function remove_widget () {
 592     local name=$1
 593     local cap=$2
 594     if (( ${+functions[$name]} )) && [[ ${functions[$name]} == *${cap}* ]]; then
 595         local w=${widgets[$name]}
 596         zle -D $name
 597         [[ $w == user:* ]] && unfunction ${w#*:}
 598     fi
 599 }
 600 remove_widget zle-line-init smkx
 601 remove_widget zle-line-finish rmkx
 602 unfunction remove_widget
 603
 604 # keybindings
 605 if [[ "$TERM" != emacs ]] ; then
 606     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 607     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 608     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 609     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 610     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 611     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 612     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 613     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 614     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 615     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 616     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 617     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 618     # ncurses stuff:
 619     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 620     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 621     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 622     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 623     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 624     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 625     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 626     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 627 fi
 628
 629 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 630 # use emacs style per default:
 631 bindkey -e
 632 # use vi style:
 633 # bindkey -v
 634
 635 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 636 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 637 beginning-or-end-of-somewhere() {
 638     local hno=$HISTNO
 639     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 640       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 641         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 642     else
 643         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 644         if (( HISTNO != hno )); then
 645             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 646         fi
 647     fi
 648 }
 649 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 650 zle -N end-of-somewhere beginning-or-end-of-somewhere
 651
 652
 653 #if [[ "$TERM" == screen ]] ; then
 654
 655 ## with HOME/END, move to beginning/end of line (on multiline) on first keypress
 656 ## to beginning/end of buffer on second keypress
 657 ## and to beginning/end of history on (at most) the third keypress
 658 # terminator & non-debian xterm
 659 bindkey '\eOH' beginning-of-somewhere  # home
 660 bindkey '\eOF' end-of-somewhere        # end
 661 # freebsd console
 662 bindkey '\e[H' beginning-of-somewhere   # home
 663 bindkey '\e[F' end-of-somewhere         # end
 664 # xterm,gnome-terminal,quake,etc
 665 bindkey '^[[1~' beginning-of-somewhere  # home
 666 bindkey '^[[4~' end-of-somewhere        # end
 667 # if terminal type is set to 'rxvt':
 668 bindkey '\e[7~' beginning-of-somewhere  # home
 669 bindkey '\e[8~' end-of-somewhere        # end
 670 #fi
 671
 672 bindkey '\e[A'  up-line-or-search       # cursor up
 673 bindkey '\e[B'  down-line-or-search     # <ESC>-
 674
 675 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on the CL
 676 bindkey "\e[5C" forward-word
 677 bindkey "\e[5D" backward-word
 678 bindkey "\e[1;5C" forward-word
 679 bindkey "\e[1;5D" backward-word
 680 ## the same for alt-left-arrow and alt-right-arrow
 681 bindkey '^[[1;3C' forward-word
 682 bindkey '^[[1;3D' backward-word
 683
 684 # Search backward in the history for a line beginning with the current
 685 # line up to the cursor and move the cursor to the end of the line then
 686 zle -N history-beginning-search-backward-end history-search-end
 687 zle -N history-beginning-search-forward-end  history-search-end
 688 #k# search history backward for entry beginning with typed text
 689 bindkey '^xp'   history-beginning-search-backward-end
 690 #k# search history forward for entry beginning with typed text
 691 bindkey '^xP'   history-beginning-search-forward-end
 692 #k# search history backward for entry beginning with typed text
 693 bindkey "\e[5~" history-beginning-search-backward-end # PageUp
 694 #k# search history forward for entry beginning with typed text
 695 bindkey "\e[6~" history-beginning-search-forward-end  # PageDown
 696
 697 # bindkey -s '^l' "|less\n"             # ctrl-L pipes to less
 698 # bindkey -s '^b' " &\n"                # ctrl-B runs it in the background
 699
 700 # insert unicode character
 701 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 702 # See for example http://unicode.org/charts/ for unicode characters code
 703 zrcautoload insert-unicode-char
 704 zle -N insert-unicode-char
 705 #k# Insert Unicode character
 706 bindkey '^xi' insert-unicode-char
 707
 708 #m# k Shift-tab Perform backwards menu completion
 709 if [[ -n "$terminfo[kcbt]" ]]; then
 710     bindkey "$terminfo[kcbt]" reverse-menu-complete
 711 elif [[ -n "$terminfo[cbt]" ]]; then # required for GNU screen
 712     bindkey "$terminfo[cbt]"  reverse-menu-complete
 713 fi
 714
 715 ## toggle the ,. abbreviation feature on/off
 716 # NOABBREVIATION: default abbreviation-state
 717 #                 0 - enabled (default)
 718 #                 1 - disabled
 719 NOABBREVIATION=${NOABBREVIATION:-0}
 720
 721 grml_toggle_abbrev() {
 722     if (( ${NOABBREVIATION} > 0 )) ; then
 723         NOABBREVIATION=0
 724     else
 725         NOABBREVIATION=1
 726     fi
 727 }
 728
 729 #k# Toggle abbreviation expansion on/off
 730 zle -N grml_toggle_abbrev
 731 bindkey '^xA' grml_toggle_abbrev
 732
 733 # add a command line to the shells history without executing it
 734 commit-to-history() {
 735     print -s ${(z)BUFFER}
 736     zle send-break
 737 }
 738 zle -N commit-to-history
 739 bindkey "^x^h" commit-to-history
 740
 741 # only slash should be considered as a word separator:
 742 slash-backward-kill-word() {
 743     local WORDCHARS="${WORDCHARS:s@/@}"
 744     # zle backward-word
 745     zle backward-kill-word
 746 }
 747 zle -N slash-backward-kill-word
 748
 749 #k# Kill left-side word or everything up to next slash
 750 bindkey '\ev' slash-backward-kill-word
 751 #k# Kill left-side word or everything up to next slash
 752 bindkey '\e^h' slash-backward-kill-word
 753 #k# Kill left-side word or everything up to next slash
 754 bindkey '\e^?' slash-backward-kill-word
 755
 756 # use the new *-pattern-* widgets for incremental history search
 757 if is439 ; then
 758     bindkey '^r' history-incremental-pattern-search-backward
 759     bindkey '^s' history-incremental-pattern-search-forward
 760 fi
 761
 762 # a generic accept-line wrapper
 763
 764 # This widget can prevent unwanted autocorrections from command-name
 765 # to _command-name, rehash automatically on enter and call any number
 766 # of builtin and user-defined widgets in different contexts.
 767 #
 768 # For a broader description, see:
 769 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 770 #
 771 # The code is imported from the file 'zsh/functions/accept-line' from
 772 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 773 # distributed under the same terms as zsh itself.
 774
 775 # A newly added command will may not be found or will cause false
 776 # correction attempts, if you got auto-correction set. By setting the
 777 # following style, we force accept-line() to rehash, if it cannot
 778 # find the first word on the command line in the $command[] hash.
 779 zstyle ':acceptline:*' rehash true
 780
 781 function Accept-Line() {
 782     setopt localoptions noksharrays
 783     local -a subs
 784     local -xi aldone
 785     local sub
 786     local alcontext=${1:-$alcontext}
 787
 788     zstyle -a ":acceptline:${alcontext}" actions subs
 789
 790     (( ${#subs} < 1 )) && return 0
 791
 792     (( aldone = 0 ))
 793     for sub in ${subs} ; do
 794         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 795         zle ${sub}
 796
 797         (( aldone > 0 )) && break
 798     done
 799 }
 800
 801 function Accept-Line-getdefault() {
 802     emulate -L zsh
 803     local default_action
 804
 805     zstyle -s ":acceptline:${alcontext}" default_action default_action
 806     case ${default_action} in
 807         ((accept-line|))
 808             printf ".accept-line"
 809             ;;
 810         (*)
 811             printf ${default_action}
 812             ;;
 813     esac
 814 }
 815
 816 function Accept-Line-HandleContext() {
 817     zle Accept-Line
 818
 819     default_action=$(Accept-Line-getdefault)
 820     zstyle -T ":acceptline:${alcontext}" call_default \
 821         && zle ${default_action}
 822 }
 823
 824 function accept-line() {
 825     setopt localoptions noksharrays
 826     local -ax cmdline
 827     local -x alcontext
 828     local buf com fname format msg default_action
 829
 830     alcontext='default'
 831     buf="${BUFFER}"
 832     cmdline=(${(z)BUFFER})
 833     com="${cmdline[1]}"
 834     fname="_${com}"
 835
 836     Accept-Line 'preprocess'
 837
 838     zstyle -t ":acceptline:${alcontext}" rehash \
 839         && [[ -z ${commands[$com]} ]]           \
 840         && rehash
 841
 842     if    [[ -n ${com}               ]] \
 843        && [[ -n ${reswords[(r)$com]} ]] \
 844        || [[ -n ${aliases[$com]}     ]] \
 845        || [[ -n ${functions[$com]}   ]] \
 846        || [[ -n ${builtins[$com]}    ]] \
 847        || [[ -n ${commands[$com]}    ]] ; then
 848
 849         # there is something sensible to execute, just do it.
 850         alcontext='normal'
 851         Accept-Line-HandleContext
 852
 853         return
 854     fi
 855
 856     if    [[ -o correct              ]] \
 857        || [[ -o correctall           ]] \
 858        && [[ -n ${functions[$fname]} ]] ; then
 859
 860         # nothing there to execute but there is a function called
 861         # _command_name; a completion widget. Makes no sense to
 862         # call it on the commandline, but the correct{,all} options
 863         # will ask for it nevertheless, so warn the user.
 864         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 865             # Okay, we warned the user before, he called us again,
 866             # so have it his way.
 867             alcontext='force'
 868             Accept-Line-HandleContext
 869
 870             return
 871         fi
 872
 873         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 874             alcontext='normal'
 875             Accept-Line-HandleContext
 876         else
 877             # prepare warning message for the user, configurable via zstyle.
 878             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 879
 880             if [[ -z ${msg} ]] ; then
 881                 msg="%c will not execute and completion %f exists."
 882             fi
 883
 884             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 885
 886             zle -M -- "${msg}"
 887         fi
 888         return
 889     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 890         # If we are here, the commandline contains something that is not
 891         # executable, which is neither subject to _command_name correction
 892         # and is not empty. might be a variable assignment
 893         alcontext='misc'
 894         Accept-Line-HandleContext
 895
 896         return
 897     fi
 898
 899     # If we got this far, the commandline only contains whitespace, or is empty.
 900     alcontext='empty'
 901     Accept-Line-HandleContext
 902 }
 903
 904 zle -N accept-line
 905 zle -N Accept-Line
 906 zle -N Accept-Line-HandleContext
 907
 908 # power completion - abbreviation expansion
 909 # power completion / abbreviation expansion / buffer expansion
 910 # see http://zshwiki.org/home/examples/zleiab for details
 911 # less risky than the global aliases but powerful as well
 912 # just type the abbreviation key and afterwards ',.' to expand it
 913 declare -A abk
 914 setopt extendedglob
 915 setopt interactivecomments
 916 abk=(
 917 #   key   # value                  (#d additional doc string)
 918 #A# start
 919     '...'  '../..'
 920     '....' '../../..'
 921     'BG'   '& exit'
 922     'C'    '| wc -l'
 923     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
 924     'H'    '| head'
 925     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 926     'L'    '| less'
 927     'LL'   '|& less -r'
 928     'M'    '| most'
 929     'N'    '&>/dev/null'           #d (No Output)
 930     'R'    '| tr A-z N-za-m'       #d (ROT13)
 931     'SL'   '| sort | less'
 932     'S'    '| sort -u'
 933     'T'    '| tail'
 934     'V'    '|& vim -'
 935 #A# end
 936     'co'   './configure && make && sudo make install'
 937 )
 938
 939 zleiab() {
 940     emulate -L zsh
 941     setopt extendedglob
 942     local MATCH
 943
 944     if (( NOABBREVIATION > 0 )) ; then
 945         LBUFFER="${LBUFFER},."
 946         return 0
 947     fi
 948
 949     LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
 950     LBUFFER+=${abk[$MATCH]:-$MATCH}
 951 }
 952
 953 zle -N zleiab && bindkey ",." zleiab
 954
 955 #f# display contents of assoc array $abk
 956 help-show-abk()
 957 {
 958   zle -M "$(print "Type ,. after these abbreviations to expand them:"; print -a -C 2 ${(kv)abk})"
 959 }
 960 #k# Display list of abbreviations that expand when followed by ,.
 961 zle -N help-show-abk && bindkey '^xb' help-show-abk
 962
 963 # autoloading
 964 zrcautoload zmv    # who needs mmv or rename?
 965 zrcautoload history-search-end
 966
 967 # we don't want to quote/espace URLs on our own...
 968 # if autoload -U url-quote-magic ; then
 969 #    zle -N self-insert url-quote-magic
 970 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 971 # else
 972 #    print 'Notice: no url-quote-magic available :('
 973 # fi
 974 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 975
 976 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 977 alias run-help >&/dev/null && unalias run-help
 978 for rh in run-help{,-git,-svk,-svn}; do
 979     zrcautoload $rh
 980 done; unset rh
 981
 982 # completion system
 983 if zrcautoload compinit ; then
 984     compinit || print 'Notice: no compinit available :('
 985 else
 986     print 'Notice: no compinit available :('
 987     function compdef { }
 988 fi
 989
 990 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 991
 992 is4 && \
 993 for mod in complist deltochar mathfunc ; do
 994     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 995 done
 996
 997 # autoload zsh modules when they are referenced
 998 if is4 ; then
 999     zmodload -a  zsh/stat    zstat
1000     zmodload -a  zsh/zpty    zpty
1001     zmodload -ap zsh/mapfile mapfile
1002 fi
1003
1004 if is4 && zrcautoload insert-files && zle -N insert-files ; then
1005     #k# Insert files and test globbing
1006     bindkey "^xf" insert-files # C-x-f
1007 fi
1008
1009 bindkey ' '   magic-space    # also do history expansion on space
1010 #k# Trigger menu-complete
1011 bindkey '\ei' menu-complete  # menu completion via esc-i
1012
1013 # press esc-e for editing command line in $EDITOR or $VISUAL
1014 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
1015     #k# Edit the current line in \kbd{\$EDITOR}
1016     bindkey '\ee' edit-command-line
1017 fi
1018
1019 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
1020     #k# menu selection: pick item but stay in the menu
1021     bindkey -M menuselect '\e^M' accept-and-menu-complete
1022     # also use + and INSERT since it's easier to press repeatedly
1023     bindkey -M menuselect "+" accept-and-menu-complete
1024     bindkey -M menuselect "^[[2~" accept-and-menu-complete
1025
1026     # accept a completion and try to complete again by using menu
1027     # completion; very useful with completing directories
1028     # by using 'undo' one's got a simple file browser
1029     bindkey -M menuselect '^o' accept-and-infer-next-history
1030 fi
1031
1032 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1033 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1034 zle -N insert-datestamp
1035
1036 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1037 bindkey '^ed' insert-datestamp
1038
1039 # press esc-m for inserting last typed word again (thanks to caphuso!)
1040 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1041 zle -N insert-last-typed-word;
1042
1043 #k# Insert last typed word
1044 bindkey "\em" insert-last-typed-word
1045
1046 function grml-zsh-fg() {
1047   if (( ${#jobstates} )); then
1048     zle .push-input
1049     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1050     BUFFER="${BUFFER}fg"
1051     zle .accept-line
1052   else
1053     zle -M 'No background jobs. Doing nothing.'
1054   fi
1055 }
1056 zle -N grml-zsh-fg
1057 #k# A smart shortcut for \kbd{fg<enter>}
1058 bindkey '^z' grml-zsh-fg
1059
1060 # run command line as user root via sudo:
1061 sudo-command-line() {
1062     [[ -z $BUFFER ]] && zle up-history
1063     if [[ $BUFFER != sudo\ * ]]; then
1064         BUFFER="sudo $BUFFER"
1065         CURSOR=$(( CURSOR+5 ))
1066     fi
1067 }
1068 zle -N sudo-command-line
1069
1070 #k# prepend the current command with "sudo"
1071 bindkey "^os" sudo-command-line
1072
1073 ### jump behind the first word on the cmdline.
1074 ### useful to add options.
1075 function jump_after_first_word() {
1076     local words
1077     words=(${(z)BUFFER})
1078
1079     if (( ${#words} <= 1 )) ; then
1080         CURSOR=${#BUFFER}
1081     else
1082         CURSOR=${#${words[1]}}
1083     fi
1084 }
1085 zle -N jump_after_first_word
1086 #k# jump to after first word (for adding options)
1087 bindkey '^x1' jump_after_first_word
1088
1089 # complete word from history with menu (from Book: ZSH, OpenSource-Press)
1090 zle -C hist-complete complete-word _generic
1091 zstyle ':completion:hist-complete:*' completer _history
1092 #k# complete word from history with menu
1093 bindkey "^x^x" hist-complete
1094
1095 ## complete word from currently visible Screen or Tmux buffer.
1096 if check_com -c screen || check_com -c tmux; then
1097     _complete_screen_display() {
1098         [[ "$TERM" != "screen" ]] && return 1
1099
1100         local TMPFILE=$(mktemp)
1101         local -U -a _screen_display_wordlist
1102         trap "rm -f $TMPFILE" EXIT
1103
1104         # fill array with contents from screen hardcopy
1105         if ((${+TMUX})); then
1106             #works, but crashes tmux below version 1.4
1107             #luckily tmux -V option to ask for version, was also added in 1.4
1108             tmux -V &>/dev/null || return
1109             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1110         else
1111             screen -X hardcopy $TMPFILE
1112             # screen sucks, it dumps in latin1, apparently always. so recode it
1113             # to system charset
1114             check_com recode && recode latin1 $TMPFILE
1115         fi
1116         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1117         # remove PREFIX to be completed from that array
1118         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1119         compadd -a _screen_display_wordlist
1120     }
1121     #k# complete word from currently visible GNU screen buffer
1122     bindkey -r "^xS"
1123     compdef -k _complete_screen_display complete-word '^xS'
1124 fi
1125
1126 # history
1127
1128 ZSHDIR=${ZDOTDIR:-${HOME}/.zsh}
1129
1130 #v#
1131 HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1132 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1133 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1134
1135 # dirstack handling
1136
1137 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1138 DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1139
1140 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1141     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1142     # "cd -" won't work after login by just setting $OLDPWD, so
1143     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1144 fi
1145
1146 chpwd() {
1147     local -ax my_stack
1148     my_stack=( ${PWD} ${dirstack} )
1149     if is42 ; then
1150         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1151     else
1152         uprint my_stack >! ${DIRSTACKFILE}
1153     fi
1154 }
1155
1156 # directory based profiles
1157
1158 if is433 ; then
1159
1160 # chpwd_profiles(): Directory Profiles, Quickstart:
1161 #
1162 # In .zshrc.local:
1163 #
1164 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1165 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1166 #   chpwd_profiles
1167 #
1168 # For details see the `grmlzshrc.5' manual page.
1169 function chpwd_profiles() {
1170     local profile context
1171     local -i reexecute
1172
1173     context=":chpwd:profiles:$PWD"
1174     zstyle -s "$context" profile profile || profile='default'
1175     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1176
1177     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1178         typeset -g CHPWD_PROFILE
1179         local CHPWD_PROFILES_INIT=1
1180         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1181     elif [[ $profile != $CHPWD_PROFILE ]]; then
1182         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1183             && chpwd_leave_profile_${CHPWD_PROFILE}
1184     fi
1185     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1186         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1187     fi
1188
1189     CHPWD_PROFILE="${profile}"
1190     return 0
1191 }
1192
1193 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1194
1195 fi # is433
1196
1197 # display battery status on right side of prompt via running 'BATTERY=1 zsh'
1198 if [[ $BATTERY -gt 0 ]] ; then
1199     if ! check_com -c acpi ; then
1200         BATTERY=0
1201     fi
1202 fi
1203
1204 battery() {
1205 if [[ $BATTERY -gt 0 ]] ; then
1206     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1207     if [[ -z "$PERCENT" ]] ; then
1208         PERCENT='acpi not present'
1209     else
1210         if [[ "$PERCENT" -lt 20 ]] ; then
1211             PERCENT="warning: ${PERCENT}%%"
1212         else
1213             PERCENT="${PERCENT}%%"
1214         fi
1215     fi
1216 fi
1217 }
1218 # set colors for use in prompts
1219 if zrcautoload colors && colors 2>/dev/null ; then
1220     BLUE="%{${fg[blue]}%}"
1221     RED="%{${fg_bold[red]}%}"
1222     GREEN="%{${fg[green]}%}"
1223     CYAN="%{${fg[cyan]}%}"
1224     MAGENTA="%{${fg[magenta]}%}"
1225     YELLOW="%{${fg[yellow]}%}"
1226     WHITE="%{${fg[white]}%}"
1227     NO_COLOR="%{${reset_color}%}"
1228 else
1229     BLUE=$'%{\e[1;34m%}'
1230     RED=$'%{\e[1;31m%}'
1231     GREEN=$'%{\e[1;32m%}'
1232     CYAN=$'%{\e[1;36m%}'
1233     WHITE=$'%{\e[1;37m%}'
1234     MAGENTA=$'%{\e[1;35m%}'
1235     YELLOW=$'%{\e[1;33m%}'
1236     NO_COLOR=$'%{\e[0m%}'
1237 fi
1238
1239 # gather version control information for inclusion in a prompt
1240
1241 if zrcautoload vcs_info; then
1242     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1243     # function, which can cause a lot of trouble with our directory-based
1244     # profiles. So:
1245     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1246         function VCS_INFO_realpath () {
1247             setopt localoptions NO_shwordsplit chaselinks
1248             ( builtin cd -q $1 2> /dev/null && pwd; )
1249         }
1250     fi
1251
1252     zstyle ':vcs_info:*' max-exports 2
1253
1254     if [[ -o restricted ]]; then
1255         zstyle ':vcs_info:*' enable NONE
1256     fi
1257 fi
1258
1259 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1260 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1261 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1262 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1263 #       to $vcs_info_msg_N_ as soon as we use the included version.
1264 if [[ "$TERM" == dumb ]] ; then
1265     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1266     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1267 else
1268     # these are the same, just with a lot of colors:
1269     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} " \
1270                                        "zsh: %r"
1271     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR}%} " \
1272                                        "zsh: %r"
1273     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1274 fi
1275
1276 # command not found handling
1277
1278 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1279 function command_not_found_handler() {
1280     emulate -L zsh
1281     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1282         ${GRML_ZSH_CNF_HANDLER} $1
1283     fi
1284     return 1
1285 }
1286
1287 function prompt_grml_help () {
1288     cat <<__EOF0__
1289   prompt grml
1290
1291     This is the prompt as used by the grml-live system <http://grml.org>. It is
1292     a rather simple one-line prompt, that by default looks something like this:
1293
1294         <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1295
1296     The prompt itself integrates with zsh's prompt themes system (as you are
1297     witnessing right now) and is configurable to a certain degree. In
1298     particular, these aspects are customisable:
1299
1300         - The items used in the prompt (e.g. you can remove \`user' from
1301           the list of activated items, which will cause the user name to
1302           be omitted from the prompt string).
1303
1304         - The attributes used with the items are customisable via strings
1305           used before and after the actual item.
1306
1307     The available items are: rc, rc-always, change-root, user, at, host, path,
1308     vcs, percent, sad-smiley, battery.
1309
1310     The actual configuration is done via zsh's \`zstyle' mechanism. The
1311     context, that is used while looking up styles is:
1312
1313         ':prompt:grml:<left-or-right>:<subcontext>'
1314
1315     Here <left-or-right> is either \`left' or \`right', signifying whether the
1316     style should affect the left or the right prompt. <subcontext> is either
1317     \`setup' or 'items:<item>', where \`<item>' is one of the available items.
1318
1319     The styles:
1320
1321         - use-rprompt (boolean): If \`true' (the default), print a sad smiley
1322           in $RPROMPT if the last command a returned non-successful error code.
1323           (This in only valid if <left-or-right> is "right"; ignored otherwise)
1324
1325         - items (list): The list of items used in the prompt. If \`vcs' is
1326           present in the list, the theme's code invokes \`vcs_info'
1327           accordingly. Default: rc user change-root at host path vcs precent
1328
1329     Available styles in 'items:<item>' are: pre, post. These are strings that
1330     are inserted before (pre) and after (post) the item in question. Thus, the
1331     following would cause the user name to be printed in red instead of the
1332     default blue:
1333
1334         zstyle ':prompt:grml:*:items:user' pre '%F{red}'
1335
1336     Note, that the \`post' style may remain at its default value, because its
1337     default value is '%f', which turns the foreground text attribute off (which
1338     is exactly, what is still required with the new \`pre' value).
1339 __EOF0__
1340 }
1341
1342 function grml_prompt_setup () {
1343     emulate -L zsh
1344     autoload -Uz vcs_info
1345     autoload -Uz add-zsh-hook
1346     add-zsh-hook precmd prompt_$1_precmd
1347 }
1348
1349 function prompt_grml_setup () {
1350     grml_prompt_setup grml
1351 }
1352
1353 function prompt_grml-chroot_setup () {
1354     grml_prompt_setup grml-chroot
1355 }
1356
1357 function prompt_grml-large_setup () {
1358     grml_prompt_setup grml-large
1359 }
1360
1361 typeset -gA grml_prompt_pre_default \
1362             grml_prompt_post_default \
1363             grml_prompt_token_default
1364
1365 grml_prompt_pre_default=(
1366     rc                '%F{red}'
1367     rc-always         ''
1368     change-root       ''
1369     user              '%B%F{blue}'
1370     at                ''
1371     host              ''
1372     path              '%b'
1373     vcs               ''
1374     percent           ''
1375     sad-smiley        ''
1376     battery           ' '
1377     newline           ''
1378     jobs              '%F{cyan}'
1379     history           '%F{green}'
1380     date              '%F{blue}'
1381     time              '%F{blue}'
1382     shell-level       '%F{red}'
1383     grml-chroot       '%F{red}'
1384 )
1385
1386 grml_prompt_post_default=(
1387     rc                '%f'
1388     rc-always         ''
1389     change-root       ''
1390     user              '%f%b'
1391     at                ''
1392     host              ''
1393     path              '%B'
1394     vcs               ''
1395     percent           ''
1396     sad-smiley        ''
1397     battery           ''
1398     newline           ''
1399     jobs              '%f'
1400     history           '%f'
1401     date              '%f'
1402     time              '%f'
1403     shell-level       '%f'
1404     grml-chroot       '%f '
1405 )
1406
1407 grml_prompt_token_default=(
1408     rc                '%(?..%? )'
1409     rc-always         '%?'
1410     change-root       'debian_chroot'
1411     user              '%n'
1412     at                '@'
1413     host              '%m '
1414     path              '%40<..<%~%<< '
1415     vcs               '0'
1416     percent           '%% '
1417     sad-smiley        '%(?..:()'
1418     battery           'PERCENT'
1419     newline           $'\n'
1420     jobs              '[%j running job(s)] '
1421     history           '{history#%!} '
1422     date              '%D{%Y-%m-%d}'
1423     time              '%D{%H:%M:%S} '
1424     shell-level       '%(3L.+ .)'
1425     grml-chroot       'GRML_CHROOT'
1426 )
1427
1428 function grml_typeset_and_wrap () {
1429     emulate -L zsh
1430     local target="$1"
1431     local new="$2"
1432     local left="$3"
1433     local right="$4"
1434
1435     if (( ${+parameters[$new]} )); then
1436         typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
1437     fi
1438 }
1439
1440 function grml_prompt_addto () {
1441     emulate -L zsh
1442     local target="$1"
1443     local lr it apre apost new v
1444     local -a items
1445     shift
1446
1447     [[ $target == PS1 ]] && lr=left || lr=right
1448     zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
1449     typeset -g "${target}="
1450     for it in "${items[@]}"; do
1451         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
1452             || apre=${grml_prompt_pre_default[$it]}
1453         zstyle -s ":prompt:grml:${grmltheme}:${lr}:$it" post apost \
1454             || apost=${grml_prompt_post_default[$it]}
1455         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
1456             || new=${grml_prompt_token_default[$it]}
1457         typeset -g "${target}=${(P)target}${apre}"
1458         case $it in
1459             battery)
1460                 grml_typeset_and_wrap $target $new '' ''
1461                 ;;
1462             change-root)
1463                 grml_typeset_and_wrap $target $new '(' ')'
1464                 ;;
1465             grml-chroot)
1466                 if [[ -n ${(P)new} ]]; then
1467                     typeset -g "${target}=${(P)target}(CHROOT)"
1468                 fi
1469                 ;;
1470             vcs)
1471                 v="vcs_info_msg_${new}_"
1472                 if (( ! vcscalled )); then
1473                     vcs_info
1474                     vcscalled=1
1475                 fi
1476                 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
1477                     typeset -g "${target}=${(P)target}${(P)v}"
1478                 fi
1479                 ;;
1480             *) typeset -g "${target}=${(P)target}${new}" ;;
1481         esac
1482         typeset -g "${target}=${(P)target}${apost}"
1483     done
1484 }
1485
1486 function prompt_grml_precmd () {
1487     emulate -L zsh
1488     local grmltheme=grml
1489     local -a left_items right_items
1490     left_items=(rc change-root user at host path vcs percent)
1491     right_items=(sad-smiley)
1492
1493     prompt_grml_precmd_worker
1494 }
1495
1496 function prompt_grml-chroot_precmd () {
1497     emulate -L zsh
1498     local grmltheme=grml-chroot
1499     local -a left_items right_items
1500     left_items=(grml-chroot user at host path percent)
1501     right_items=()
1502
1503     prompt_grml_precmd_worker
1504 }
1505
1506 function prompt_grml-large_precmd () {
1507     emulate -L zsh
1508     local grmltheme=grml-large
1509     local -a left_items right_items
1510     left_items=(rc jobs history shell-level change-root time date newline
1511                 user at host path vcs percent)
1512     right_items=(sad-smiley)
1513
1514     prompt_grml_precmd_worker
1515 }
1516
1517 function prompt_grml_precmd_worker () {
1518     emulate -L zsh
1519     local -i vcscalled=0
1520
1521     grml_prompt_addto PS1 "${left_items[@]}"
1522     if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
1523         grml_prompt_addto RPS1 "${right_items[@]}"
1524     fi
1525 }
1526
1527 # set prompt
1528 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1529     promptinit # people should be able to use their favourite prompt
1530
1531     # Since we define the required functions in here and not in files in
1532     # $fpath, we need to stick the theme's name into `$prompt_themes'
1533     # ourselves, since promptinit does not pick them up otherwise.
1534     prompt_themes+=( grml grml-chroot grml-large )
1535     # Also, keep the array sorted...
1536     prompt_themes=( "${(@on)prompt_themes}" )
1537
1538     if [[ $BATTERY -gt 0 ]]; then
1539         zstyle ':prompt:grml:right:setup' items sad-smiley battery
1540         add-zsh-hook precmd battery
1541     fi
1542     if [[ "$TERM" == dumb ]] ; then
1543         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" pre ''
1544         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" post ' '
1545         for i in rc user path jobs history date time shell-level; do
1546             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" pre ''
1547             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" post ''
1548         done
1549         unset i
1550         zstyle ':prompt:grml(|-large|-chroot):right:setup' use-rprompt false
1551     elif (( EUID == 0 )); then
1552         zstyle ':prompt:grml(|-large|-chroot):*:items:user' pre '%F{red}'
1553     fi
1554
1555     # Finally enable one of the prompts.
1556     if [[ -n $GRML_CHROOT ]]; then
1557         prompt grml-chroot
1558     elif [[ $GRMLPROMPT -gt 0 ]]; then
1559         prompt grml-large
1560     else
1561         prompt grml
1562     fi
1563 else
1564     print 'Notice: no promptinit available :('
1565 fi
1566
1567 setopt prompt_subst
1568
1569 # make sure to use right prompt only when not running a command
1570 is41 && setopt transient_rprompt
1571
1572
1573 function ESC_print () {
1574     info_print $'\ek' $'\e\\' "$@"
1575 }
1576 function set_title () {
1577     info_print  $'\e]0;' $'\a' "$@"
1578 }
1579
1580 function info_print () {
1581     local esc_begin esc_end
1582     esc_begin="$1"
1583     esc_end="$2"
1584     shift 2
1585     printf '%s' ${esc_begin}
1586     printf '%s' "$*"
1587     printf '%s' "${esc_end}"
1588 }
1589
1590 function grml_reset_screen_title () {
1591     # adjust title of xterm
1592     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1593     [[ ${NOTITLE:-} -gt 0 ]] && return 0
1594     case $TERM in
1595         (xterm*|rxvt*)
1596             set_title ${(%):-"%n@%m: %~"}
1597             ;;
1598     esac
1599 }
1600
1601 function grml_vcs_to_screen_title () {
1602     if [[ $TERM == screen* ]] ; then
1603         if [[ -n ${vcs_info_msg_1_} ]] ; then
1604             ESC_print ${vcs_info_msg_1_}
1605         else
1606             ESC_print "zsh"
1607         fi
1608     fi
1609 }
1610
1611 zrcautoload add-zsh-hook || add-zsh-hook () { :; }
1612 if [[ $NOPRECMD -gt 0 ]]; then
1613     add-zsh-hook precmd grml_reset_screen_title
1614     add-zsh-hook precmd grml_vcs_to_screen_title
1615 fi
1616
1617 # preexec() => a function running before every command
1618 is4 && [[ $NOPRECMD -eq 0 ]] && \
1619 preexec () {
1620     [[ $NOPRECMD -gt 0 ]] && return 0
1621 # set hostname if not running on host with name 'grml'
1622     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1623        NAME="@$HOSTNAME"
1624     fi
1625 # get the name of the program currently running and hostname of local machine
1626 # set screen window title if running in a screen
1627     if [[ "$TERM" == screen* ]] ; then
1628         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1629         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1630         ESC_print ${CMD}
1631     fi
1632 # adjust title of xterm
1633     [[ ${NOTITLE} -gt 0 ]] && return 0
1634     case $TERM in
1635         (xterm*|rxvt*)
1636             set_title "${(%):-"%n@%m:"}" "$1"
1637             ;;
1638     esac
1639 }
1640
1641 EXITCODE="%(?..%?%1v )"
1642 # secondary prompt, printed when the shell needs more information to complete a
1643 # command.
1644 PS2='\`%_> '
1645 # selection prompt used within a select loop.
1646 PS3='?# '
1647 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1648 PS4='+%N:%i:%_> '
1649
1650 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1651 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1652     debian_chroot=$(cat /etc/debian_chroot)
1653 fi
1654
1655 # don't use colors on dumb terminals (like emacs):
1656 if [[ "$TERM" == dumb ]] ; then
1657     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "
1658 else
1659     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended
1660     # prompt set variable identifying the chroot you work in (used in the
1661     # prompt below)
1662     if [[ $GRMLPROMPT -gt 0 ]] ; then
1663         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1664 ${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "
1665     else
1666         # This assembles the primary prompt string
1667         if (( EUID != 0 )); then
1668             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "
1669         else
1670             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "
1671         fi
1672     fi
1673 fi
1674
1675 PROMPT="${PROMPT}"'${vcs_info_msg_0_}'"%# "
1676
1677 # if we are inside a grml-chroot set a specific prompt theme
1678 if [[ -n "$GRML_CHROOT" ]] ; then
1679     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1680 fi
1681
1682 # 'hash' some often used directories
1683 #d# start
1684 hash -d deb=/var/cache/apt/archives
1685 hash -d doc=/usr/share/doc
1686 hash -d linux=/lib/modules/$(command uname -r)/build/
1687 hash -d log=/var/log
1688 hash -d slog=/var/log/syslog
1689 hash -d src=/usr/src
1690 hash -d templ=/usr/share/doc/grml-templates
1691 hash -d tt=/usr/share/doc/texttools-doc
1692 hash -d www=/var/www
1693 #d# end
1694
1695 # some aliases
1696 if check_com -c screen ; then
1697     if [[ $UID -eq 0 ]] ; then
1698         if [[ -r /etc/grml/screenrc ]]; then
1699             alias screen="${commands[screen]} -c /etc/grml/screenrc"
1700         fi
1701     elif [[ -r $HOME/.screenrc ]] ; then
1702         alias screen="${commands[screen]} -c $HOME/.screenrc"
1703     else
1704         if [[ -r /etc/grml/screenrc_grml ]]; then
1705             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
1706         else
1707             if [[ -r /etc/grml/screenrc ]]; then
1708                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
1709             fi
1710         fi
1711     fi
1712 fi
1713
1714 # do we have GNU ls with color-support?
1715 if [[ "$TERM" != dumb ]]; then
1716     #a1# execute \kbd{@a@}:\quad ls with colors
1717     alias ls='ls -b -CF '${ls_options:+"${ls_options[*]}"}
1718     #a1# execute \kbd{@a@}:\quad list all files, with colors
1719     alias la='ls -la '${ls_options:+"${ls_options[*]}"}
1720     #a1# long colored list, without dotfiles (@a@)
1721     alias ll='ls -l '${ls_options:+"${ls_options[*]}"}
1722     #a1# long colored list, human readable sizes (@a@)
1723     alias lh='ls -hAl '${ls_options:+"${ls_options[*]}"}
1724     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1725     alias l='ls -lF '${ls_options:+"${ls_options[*]}"}
1726 else
1727     alias ls='ls -b -CF'
1728     alias la='ls -la'
1729     alias ll='ls -l'
1730     alias lh='ls -hAl'
1731     alias l='ls -lF'
1732 fi
1733
1734 alias mdstat='cat /proc/mdstat'
1735 alias ...='cd ../../'
1736
1737 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1738 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1739     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1740 fi
1741
1742 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1743 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1744 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1745
1746 # make sure it is not assigned yet
1747 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
1748 utf2iso() {
1749     if isutfenv ; then
1750         for ENV in $(env | command grep -i '.utf') ; do
1751             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1752         done
1753     fi
1754 }
1755
1756 # make sure it is not assigned yet
1757 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
1758 iso2utf() {
1759     if ! isutfenv ; then
1760         for ENV in $(env | command grep -i '\.iso') ; do
1761             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1762         done
1763     fi
1764 }
1765
1766 # especially for roadwarriors using GNU screen and ssh:
1767 if ! check_com asc &>/dev/null ; then
1768   asc() { autossh -t "$@" 'screen -RdU' }
1769   compdef asc=ssh
1770 fi
1771
1772 #f1# Hints for the use of zsh on grml
1773 zsh-help() {
1774     print "$bg[white]$fg[black]
1775 zsh-help - hints for use of zsh on grml
1776 =======================================$reset_color"
1777
1778     print '
1779 Main configuration of zsh happens in /etc/zsh/zshrc.
1780 That file is part of the package grml-etc-core, if you want to
1781 use them on a non-grml-system just get the tar.gz from
1782 http://deb.grml.org/ or (preferably) get it from the git repository:
1783
1784   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
1785
1786 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
1787 The file is still there, but it is empty for backwards compatibility.
1788
1789 For your own changes use these two files:
1790     $HOME/.zshrc.pre
1791     $HOME/.zshrc.local
1792
1793 The former is sourced very early in our zshrc, the latter is sourced
1794 very lately.
1795
1796 System wide configuration without touching configuration files of grml
1797 can take place in /etc/zsh/zshrc.local.
1798
1799 For information regarding zsh start at http://grml.org/zsh/
1800
1801 Take a look at grml'\''s zsh refcard:
1802 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1803
1804 Check out the main zsh refcard:
1805 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1806
1807 And of course visit the zsh-lovers:
1808 % man zsh-lovers
1809
1810 You can adjust some options through environment variables when
1811 invoking zsh without having to edit configuration files.
1812 Basically meant for bash users who are not used to the power of
1813 the zsh yet. :)
1814
1815   "NOCOR=1    zsh" => deactivate automatic correction
1816   "NOMENU=1   zsh" => do not use auto menu completion
1817                       (note: use ctrl-d for completion instead!)
1818   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1819   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
1820                       preexec() and precmd() completely
1821   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
1822   "COMMAND_NOT_FOUND=1 zsh"
1823                    => Enable a handler if an external command was not found
1824                       The command called in the handler can be altered by setting
1825                       the GRML_ZSH_CNF_HANDLER variable, the default is:
1826                       "/usr/share/command-not-found/command-not-found"
1827
1828 A value greater than 0 is enables a feature; a value equal to zero
1829 disables it. If you like one or the other of these settings, you can
1830 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
1831 zshrc.'
1832
1833     print "
1834 $bg[white]$fg[black]
1835 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1836 Enjoy your grml system with the zsh!$reset_color"
1837 }
1838
1839 # debian stuff
1840 if [[ -r /etc/debian_version ]] ; then
1841     #a3# Execute \kbd{apt-cache search}
1842     alias acs='apt-cache search'
1843     #a3# Execute \kbd{apt-cache show}
1844     alias acsh='apt-cache show'
1845     #a3# Execute \kbd{apt-cache policy}
1846     alias acp='apt-cache policy'
1847     #a3# Execute \kbd{apt-get dist-upgrade}
1848     salias adg="apt-get dist-upgrade"
1849     #a3# Execute \kbd{apt-get install}
1850     salias agi="apt-get install"
1851     #a3# Execute \kbd{aptitude install}
1852     salias ati="aptitude install"
1853     #a3# Execute \kbd{apt-get upgrade}
1854     salias ag="apt-get upgrade"
1855     #a3# Execute \kbd{apt-get update}
1856     salias au="apt-get update"
1857     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1858     salias -a up="aptitude update ; aptitude safe-upgrade"
1859     #a3# Execute \kbd{dpkg-buildpackage}
1860     alias dbp='dpkg-buildpackage'
1861     #a3# Execute \kbd{grep-excuses}
1862     alias ge='grep-excuses'
1863
1864     # get a root shell as normal user in live-cd mode:
1865     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1866        alias su="sudo su"
1867      fi
1868
1869     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1870     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1871     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1872     salias tlog="tail -f /var/log/syslog"    # follow the syslog
1873 fi
1874
1875 # sort installed Debian-packages by size
1876 if check_com -c dpkg-query ; then
1877     #a3# List installed Debian-packages sorted by size
1878     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
1879 fi
1880
1881 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1882 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
1883     if check_com -c wodim; then
1884         cdrecord() {
1885             cat <<EOMESS
1886 cdrecord is not provided under its original name by Debian anymore.
1887 See #377109 in the BTS of Debian for more details.
1888
1889 Please use the wodim binary instead
1890 EOMESS
1891             return 1
1892         }
1893     fi
1894 fi
1895
1896 # Use hard limits, except for a smaller stack and no core dumps
1897 unlimit
1898 is425 && limit stack 8192
1899 isgrmlcd && limit core 0 # important for a live-cd-system
1900 limit -s
1901
1902 # completion system
1903
1904 # called later (via is4 && grmlcomp)
1905 # note: use 'zstyle' for getting current settings
1906 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
1907 grmlcomp() {
1908     # TODO: This could use some additional information
1909
1910     # allow one error for every three characters typed in approximate completer
1911     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1912
1913     # don't complete backup files as executables
1914     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1915
1916     # start menu completion only if it could find no unambiguous initial string
1917     zstyle ':completion:*:correct:*'       insert-unambiguous true
1918     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1919     zstyle ':completion:*:correct:*'       original true
1920
1921     # activate color-completion
1922     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1923
1924     # format on completion
1925     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1926
1927     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
1928     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1929
1930     # insert all expansions for expand completer
1931     zstyle ':completion:*:expand:*'        tag-order all-expansions
1932     zstyle ':completion:*:history-words'   list false
1933
1934     # activate menu
1935     zstyle ':completion:*:history-words'   menu yes
1936
1937     # ignore duplicate entries
1938     zstyle ':completion:*:history-words'   remove-all-dups yes
1939     zstyle ':completion:*:history-words'   stop yes
1940
1941     # match uppercase from lowercase
1942     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1943
1944     # separate matches into groups
1945     zstyle ':completion:*:matches'         group 'yes'
1946     zstyle ':completion:*'                 group-name ''
1947
1948     if [[ "$NOMENU" -eq 0 ]] ; then
1949         # if there are more than 5 options allow selecting from a menu
1950         zstyle ':completion:*'               menu select=5
1951     else
1952         # don't use any menus at all
1953         setopt no_auto_menu
1954     fi
1955
1956     zstyle ':completion:*:messages'        format '%d'
1957     zstyle ':completion:*:options'         auto-description '%d'
1958
1959     # describe options in full
1960     zstyle ':completion:*:options'         description 'yes'
1961
1962     # on processes completion complete all user processes
1963     zstyle ':completion:*:processes'       command 'ps -au$USER'
1964
1965     # offer indexes before parameters in subscripts
1966     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1967
1968     # provide verbose completion information
1969     zstyle ':completion:*'                 verbose true
1970
1971     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1972     # for commands (read: 1st word in the line) that it will list for the user
1973     # to choose from. The following disables that, because it's not exactly fast.
1974     zstyle ':completion:*:-command-:*:'    verbose false
1975
1976     # set format for warnings
1977     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1978
1979     # define files to ignore for zcompile
1980     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1981     zstyle ':completion:correct:'          prompt 'correct to: %e'
1982
1983     # Ignore completion functions for commands you don't have:
1984     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1985
1986     # Provide more processes in completion of programs like killall:
1987     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1988
1989     # complete manual by their section
1990     zstyle ':completion:*:manuals'    separate-sections true
1991     zstyle ':completion:*:manuals.*'  insert-sections   true
1992     zstyle ':completion:*:man:*'      menu yes select
1993
1994     # Search path for sudo completion
1995     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
1996                                                /usr/local/bin  \
1997                                                /usr/sbin       \
1998                                                /usr/bin        \
1999                                                /sbin           \
2000                                                /bin            \
2001                                                /usr/X11R6/bin
2002
2003     # provide .. as a completion
2004     zstyle ':completion:*' special-dirs ..
2005
2006     # run rehash on completion so new installed program are found automatically:
2007     _force_rehash() {
2008         (( CURRENT == 1 )) && rehash
2009         return 1
2010     }
2011
2012     ## correction
2013     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
2014     if [[ "$NOCOR" -gt 0 ]] ; then
2015         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
2016         setopt nocorrect
2017     else
2018         # try to be smart about when to use what completer...
2019         setopt correct
2020         zstyle -e ':completion:*' completer '
2021             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
2022                 _last_try="$HISTNO$BUFFER$CURSOR"
2023                 reply=(_complete _match _ignored _prefix _files)
2024             else
2025                 if [[ $words[1] == (rm|mv) ]] ; then
2026                     reply=(_complete _files)
2027                 else
2028                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
2029                 fi
2030             fi'
2031     fi
2032
2033     # command for process lists, the local web server details and host completion
2034     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
2035
2036     # caching
2037     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
2038                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
2039
2040     # host completion
2041     if is42 ; then
2042         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
2043         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
2044     else
2045         _ssh_hosts=()
2046         _etc_hosts=()
2047     fi
2048     hosts=(
2049         $(hostname)
2050         "$_ssh_hosts[@]"
2051         "$_etc_hosts[@]"
2052         localhost
2053     )
2054     zstyle ':completion:*:hosts' hosts $hosts
2055     # TODO: so, why is this here?
2056     #  zstyle '*' hosts $hosts
2057
2058     # use generic completion system for programs not yet defined; (_gnu_generic works
2059     # with commands that provide a --help option with "standard" gnu-like output.)
2060     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
2061                    pal stow tail uname ; do
2062         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
2063     done; unset compcom
2064
2065     # see upgrade function in this file
2066     compdef _hosts upgrade
2067 }
2068
2069 # grmlstuff
2070 grmlstuff() {
2071 # people should use 'grml-x'!
2072     if check_com -c 915resolution; then
2073         855resolution() {
2074             echo "Please use 915resolution as resolution modifying tool for Intel \
2075 graphic chipset."
2076             return -1
2077         }
2078     fi
2079
2080     #a1# Output version of running grml
2081     alias grml-version='cat /etc/grml_version'
2082
2083     if check_com -c rebuildfstab ; then
2084         #a1# Rebuild /etc/fstab
2085         alias grml-rebuildfstab='rebuildfstab -v -r -config'
2086     fi
2087
2088     if check_com -c grml-debootstrap ; then
2089         debian2hd() {
2090             echo "Installing debian to harddisk is possible by using grml-debootstrap."
2091             return 1
2092         }
2093     fi
2094 }
2095
2096 # now run the functions
2097 isgrml && checkhome
2098 is4    && isgrml    && grmlstuff
2099 is4    && grmlcomp
2100
2101 # keephack
2102 is4 && xsource "/etc/zsh/keephack"
2103
2104 # wonderful idea of using "e" glob qualifier by Peter Stephenson
2105 # You use it as follows:
2106 # $ NTREF=/reference/file
2107 # $ ls -l *(e:nt:)
2108 # This lists all the files in the current directory newer than the reference file.
2109 # You can also specify the reference file inline; note quotes:
2110 # $ ls -l *(e:'nt ~/.zshenv':)
2111 is4 && nt() {
2112     if [[ -n $1 ]] ; then
2113         local NTREF=${~1}
2114     fi
2115     [[ $REPLY -nt $NTREF ]]
2116 }
2117
2118 # shell functions
2119
2120 #f1# Reload an autoloadable function
2121 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2122 compdef _functions freload
2123
2124 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2125 sll() {
2126     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2127     for file in "$@" ; do
2128         while [[ -h "$file" ]] ; do
2129             ls -l $file
2130             file=$(readlink "$file")
2131         done
2132     done
2133 }
2134
2135 # TODO: Is it supported to use pager settings like this?
2136 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2137 # with respect to wordsplitting. (ie. ${=PAGER})
2138 if check_com -c $PAGER ; then
2139     #f1# View Debian's changelog of a given package
2140     dchange() {
2141         emulate -L zsh
2142         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
2143             $PAGER /usr/share/doc/$1/changelog.Debian.gz
2144         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2145             $PAGER /usr/share/doc/$1/changelog.gz
2146         else
2147             if check_com -c aptitude ; then
2148                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2149                 if isgrml ; then
2150                     aptitude -t unstable changelog $1
2151                 else
2152                     aptitude changelog $1
2153                 fi
2154             else
2155                 echo "No changelog for package $1 found, sorry."
2156                 return 1
2157             fi
2158         fi
2159     }
2160     _dchange() { _files -W /usr/share/doc -/ }
2161     compdef _dchange dchange
2162
2163     #f1# View Debian's NEWS of a given package
2164     dnews() {
2165         emulate -L zsh
2166         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2167             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2168         else
2169             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2170                 $PAGER /usr/share/doc/$1/NEWS.gz
2171             else
2172                 echo "No NEWS file for package $1 found, sorry."
2173                 return 1
2174             fi
2175         fi
2176     }
2177     _dnews() { _files -W /usr/share/doc -/ }
2178     compdef _dnews dnews
2179
2180     #f1# View Debian's copyright of a given package
2181     dcopyright() {
2182         emulate -L zsh
2183         if [[ -r /usr/share/doc/$1/copyright ]] ; then
2184             $PAGER /usr/share/doc/$1/copyright
2185         else
2186             echo "No copyright file for package $1 found, sorry."
2187             return 1
2188         fi
2189     }
2190     _dcopyright() { _files -W /usr/share/doc -/ }
2191     compdef _dcopyright dcopyright
2192
2193     #f1# View upstream's changelog of a given package
2194     uchange() {
2195         emulate -L zsh
2196         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2197             $PAGER /usr/share/doc/$1/changelog.gz
2198         else
2199             echo "No changelog for package $1 found, sorry."
2200             return 1
2201         fi
2202     }
2203     _uchange() { _files -W /usr/share/doc -/ }
2204     compdef _uchange uchange
2205 fi
2206
2207 # zsh profiling
2208 profile() {
2209     ZSH_PROFILE_RC=1 $SHELL "$@"
2210 }
2211
2212 #f1# Edit an alias via zle
2213 edalias() {
2214     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2215 }
2216 compdef _aliases edalias
2217
2218 #f1# Edit a function via zle
2219 edfunc() {
2220     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2221 }
2222 compdef _functions edfunc
2223
2224 # use it e.g. via 'Restart apache2'
2225 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2226 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2227 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2228 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2229 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2230 #m# f6 Status() \kbd{/etc/init.d/\em{process}}\quad\kbd{status}
2231 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2232     __start_stop() {
2233         local action_="${1:l}"  # e.g Start/Stop/Restart
2234         local service_="$2"
2235         local param_="$3"
2236
2237         local service_target_="$(readlink /etc/init.d/$service_)"
2238         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2239             # runit
2240             case "${action_}" in
2241                 start) if [[ ! -e /etc/service/$service_ ]]; then
2242                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2243                        else
2244                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2245                        fi ;;
2246                 # there is no reload in runits sysv emulation
2247                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2248                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2249             esac
2250         else
2251             # sysvinit
2252             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2253         fi
2254     }
2255
2256     _grmlinitd() {
2257         local -a scripts
2258         scripts=( /etc/init.d/*(x:t) )
2259         _describe "service startup script" scripts
2260     }
2261
2262     for i in Start Restart Stop Force-Reload Reload Status ; do
2263         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2264         compdef _grmlinitd $i
2265     done
2266 fi
2267
2268 #f1# Provides useful information on globbing
2269 H-Glob() {
2270     echo -e "
2271     /      directories
2272     .      plain files
2273     @      symbolic links
2274     =      sockets
2275     p      named pipes (FIFOs)
2276     *      executable plain files (0100)
2277     %      device files (character or block special)
2278     %b     block special files
2279     %c     character special files
2280     r      owner-readable files (0400)
2281     w      owner-writable files (0200)
2282     x      owner-executable files (0100)
2283     A      group-readable files (0040)
2284     I      group-writable files (0020)
2285     E      group-executable files (0010)
2286     R      world-readable files (0004)
2287     W      world-writable files (0002)
2288     X      world-executable files (0001)
2289     s      setuid files (04000)
2290     S      setgid files (02000)
2291     t      files with the sticky bit (01000)
2292
2293   print *(m-1)          # Files modified up to a day ago
2294   print *(a1)           # Files accessed a day ago
2295   print *(@)            # Just symlinks
2296   print *(Lk+50)        # Files bigger than 50 kilobytes
2297   print *(Lk-50)        # Files smaller than 50 kilobytes
2298   print **/*.c          # All *.c files recursively starting in \$PWD
2299   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2300   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2301   print *~*.*           # All Files that do not contain a dot
2302   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2303   print -l *(.c|.h)     # Lists *.c and *.h
2304   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2305   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2306 }
2307 alias help-zshglob=H-Glob
2308
2309 #v1# set number of lines to display per page
2310 HELP_LINES_PER_PAGE=20
2311 #v1# set location of help-zle cache file
2312 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
2313 #f1# helper function for help-zle, actually generates the help text
2314 help_zle_parse_keybindings()
2315 {
2316     emulate -L zsh
2317     setopt extendedglob
2318     unsetopt ksharrays  #indexing starts at 1
2319
2320     #v1# choose files that help-zle will parse for keybindings
2321     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
2322
2323     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
2324         local load_cache=0
2325         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
2326         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
2327     fi
2328
2329     #fill with default keybindings, possibly to be overwriten in a file later
2330     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
2331     local -A help_zle_keybindings
2332     help_zle_keybindings['<Ctrl>@']="set MARK"
2333     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
2334     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
2335     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
2336     help_zle_keybindings['<Ctrl>_']="undo"
2337     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
2338     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
2339     help_zle_keybindings['<Ctrl>e']="goto end of line"
2340     help_zle_keybindings['<Ctrl>t']="transpose charaters"
2341     help_zle_keybindings['<Alt>t']="transpose words"
2342     help_zle_keybindings['<Alt>s']="spellcheck word"
2343     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
2344     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
2345     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
2346     help_zle_keybindings["<Alt>'"]="quote line"
2347     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
2348     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
2349     help_zle_keybindings['<Alt>u']="make next word Uppercase"
2350     help_zle_keybindings['<Alt>l']="make next word lowercase"
2351     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
2352     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
2353     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
2354     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
2355     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
2356     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
2357     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
2358     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
2359     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
2360
2361     #init global variables
2362     unset help_zle_lines help_zle_sln
2363     typeset -g -a help_zle_lines
2364     typeset -g help_zle_sln=1
2365
2366     local k v
2367     local lastkeybind_desc contents     #last description starting with #k# that we found
2368     local num_lines_elapsed=0            #number of lines between last description and keybinding
2369     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
2370     for f in $HELPZLE_KEYBINDING_FILES; do
2371         [[ -r "$f" ]] || continue   #not readable ? skip it
2372         contents="$(<$f)"
2373         for cline in "${(f)contents}"; do
2374             #zsh pattern: matches lines like: #k# ..............
2375             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
2376                 lastkeybind_desc="$match[*]"
2377                 num_lines_elapsed=0
2378             #zsh pattern: matches lines that set a keybinding using bindkey or compdef -k
2379             #             ignores lines that are commentend out
2380             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
2381             elif [[ "$cline" == [^#]#(bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
2382                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
2383                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
2384                     #substitute keybinding string with something readable
2385                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
2386                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
2387                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
2388                     help_zle_keybindings[${k}]=$lastkeybind_desc
2389                 fi
2390                 lastkeybind_desc=""
2391             else
2392               ((num_lines_elapsed++))
2393             fi
2394         done
2395     done
2396     unset contents
2397     #calculate length of keybinding column
2398     local kstrlen=0
2399     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
2400     #convert the assoc array into preformated lines, which we are able to sort
2401     for k v in ${(kv)help_zle_keybindings[@]}; do
2402         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
2403         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
2404     done
2405     #sort lines alphabetically
2406     help_zle_lines=("${(i)help_zle_lines[@]}")
2407     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
2408     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
2409     zcompile $HELP_ZLE_CACHE_FILE
2410 }
2411 typeset -g help_zle_sln
2412 typeset -g -a help_zle_lines
2413
2414 #f1# Provides (partially autogenerated) help on keybindings and the zsh line editor
2415 help-zle()
2416 {
2417     emulate -L zsh
2418     unsetopt ksharrays  #indexing starts at 1
2419     #help lines already generated ? no ? then do it
2420     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
2421     #already displayed all lines ? go back to the start
2422     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
2423     local sln=$help_zle_sln
2424     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
2425     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
2426     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
2427 }
2428 #k# display help for keybindings and ZLE (cycle pages with consecutive use)
2429 zle -N help-zle && bindkey '^xz' help-zle
2430
2431 # grep for running process, like: 'any vim'
2432 any() {
2433     emulate -L zsh
2434     unsetopt KSH_ARRAYS
2435     if [[ -z "$1" ]] ; then
2436         echo "any - grep for process(es) by keyword" >&2
2437         echo "Usage: any <keyword>" >&2 ; return 1
2438     else
2439         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
2440     fi
2441 }
2442
2443
2444 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2445 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2446 [[ -r /proc/1/maps ]] && \
2447 deswap() {
2448     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2449     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2450     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2451 }
2452
2453 # a wrapper for vim, that deals with title setting
2454 #   VIM_OPTIONS
2455 #       set this array to a set of options to vim you always want
2456 #       to have set when calling vim (in .zshrc.local), like:
2457 #           VIM_OPTIONS=( -p )
2458 #       This will cause vim to send every file given on the
2459 #       commandline to be send to it's own tab (needs vim7).
2460 if check_com vim; then
2461     vim() {
2462         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2463     }
2464 fi
2465
2466 # make a backup of a file
2467 bk() {
2468     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2469 }
2470
2471 ssl_hashes=( sha512 sha256 sha1 md5 )
2472
2473 for sh in ${ssl_hashes}; do
2474     eval 'ssl-cert-'${sh}'() {
2475         emulate -L zsh
2476         if [[ -z $1 ]] ; then
2477             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2478             return 1
2479         fi
2480         openssl x509 -noout -fingerprint -'${sh}' -in $1
2481     }'
2482 done; unset sh
2483
2484 ssl-cert-fingerprints() {
2485     emulate -L zsh
2486     local i
2487     if [[ -z $1 ]] ; then
2488         printf 'usage: ssl-cert-fingerprints <file>\n'
2489         return 1
2490     fi
2491     for i in ${ssl_hashes}
2492         do ssl-cert-$i $1;
2493     done
2494 }
2495
2496 ssl-cert-info() {
2497     emulate -L zsh
2498     if [[ -z $1 ]] ; then
2499         printf 'usage: ssl-cert-info <file>\n'
2500         return 1
2501     fi
2502     openssl x509 -noout -text -in $1
2503     ssl-cert-fingerprints $1
2504 }
2505
2506 # make sure our environment is clean regarding colors
2507 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2508
2509 # "persistent history"
2510 # just write important commands you always need to ~/.important_commands
2511 if [[ -r ~/.important_commands ]] ; then
2512     fc -R ~/.important_commands
2513 fi
2514
2515 # load the lookup subsystem if it's available on the system
2516 zrcautoload lookupinit && lookupinit
2517
2518 # variables
2519
2520 # set terminal property (used e.g. by msgid-chooser)
2521 export COLORTERM="yes"
2522
2523 # aliases
2524
2525 # general
2526 #a2# Execute \kbd{du -sch}
2527 alias da='du -sch'
2528 #a2# Execute \kbd{jobs -l}
2529 alias j='jobs -l'
2530
2531 # listing stuff
2532 #a2# Execute \kbd{ls -lSrah}
2533 alias dir="ls -lSrah"
2534 #a2# Only show dot-directories
2535 alias lad='ls -d .*(/)'
2536 #a2# Only show dot-files
2537 alias lsa='ls -a .*(.)'
2538 #a2# Only files with setgid/setuid/sticky flag
2539 alias lss='ls -l *(s,S,t)'
2540 #a2# Only show symlinks
2541 alias lsl='ls -l *(@)'
2542 #a2# Display only executables
2543 alias lsx='ls -l *(*)'
2544 #a2# Display world-{readable,writable,executable} files
2545 alias lsw='ls -ld *(R,W,X.^ND/)'
2546 #a2# Display the ten biggest files
2547 alias lsbig="ls -flh *(.OL[1,10])"
2548 #a2# Only show directories
2549 alias lsd='ls -d *(/)'
2550 #a2# Only show empty directories
2551 alias lse='ls -d *(/^F)'
2552 #a2# Display the ten newest files
2553 alias lsnew="ls -rtlh *(D.om[1,10])"
2554 #a2# Display the ten oldest files
2555 alias lsold="ls -rtlh *(D.Om[1,10])"
2556 #a2# Display the ten smallest files
2557 alias lssmall="ls -Srl *(.oL[1,10])"
2558 #a2# Display the ten newest directories and ten newest .directories
2559 alias lsnewdir="ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
2560 #a2# Display the ten oldest directories and ten oldest .directories
2561 alias lsolddir="ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
2562
2563 # some useful aliases
2564 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir $OLDCWD}
2565 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2566
2567 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2568 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2569 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2570
2571 # work around non utf8 capable software in utf environment via $LANG and luit
2572 if check_com isutfenv && check_com luit ; then
2573     if check_com -c mrxvt ; then
2574         isutfenv && [[ -n "$LANG" ]] && \
2575             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2576     fi
2577
2578     if check_com -c aterm ; then
2579         isutfenv && [[ -n "$LANG" ]] && \
2580             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2581     fi
2582
2583     if check_com -c centericq ; then
2584         isutfenv && [[ -n "$LANG" ]] && \
2585             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2586     fi
2587 fi
2588
2589 # useful functions
2590
2591 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2592 bk() {
2593     emulate -L zsh
2594     cp -b $1 $1_`date --iso-8601=m`
2595 }
2596
2597 #f5# cd to directoy and list files
2598 cl() {
2599     emulate -L zsh
2600     cd $1 && ls -a
2601 }
2602
2603 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2604 cd() {
2605     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2606         [[ ! -e ${1:h} ]] && return 1
2607         print "Correcting ${1} to ${1:h}"
2608         builtin cd ${1:h}
2609     else
2610         builtin cd "$@"
2611     fi
2612 }
2613
2614 #f5# Create Directoy and \kbd{cd} to it
2615 mkcd() {
2616     if (( ARGC != 1 )); then
2617         printf 'usage: mkcd <new-directory>\n'
2618         return 1;
2619     fi
2620     if [[ ! -d "$1" ]]; then
2621         command mkdir -p "$1"
2622     else
2623         printf '`%s'\'' already exists: cd-ing.\n' "$1"
2624     fi
2625     builtin cd "$1"
2626 }
2627
2628 #f5# Create temporary directory and \kbd{cd} to it
2629 cdt() {
2630     local t
2631     t=$(mktemp -d)
2632     echo "$t"
2633     builtin cd "$t"
2634 }
2635
2636 #f5# Create directory under cursor or the selected area
2637 # Press ctrl-xM to create the directory under the cursor or the selected area.
2638 # To select an area press ctrl-@ or ctrl-space and use the cursor.
2639 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
2640 # directory does not exist yet -> press ctrl-XM and problem solved
2641 inplaceMkDirs() {
2642     local PATHTOMKDIR
2643     if ((REGION_ACTIVE==1)); then
2644         local F=$MARK T=$CURSOR
2645         if [[ $F -gt $T ]]; then
2646             F=${CURSOR}
2647             T=${MARK}
2648         fi
2649         # get marked area from buffer and eliminate whitespace
2650         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
2651         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
2652     else
2653         local bufwords iword
2654         bufwords=(${(z)LBUFFER})
2655         iword=${#bufwords}
2656         bufwords=(${(z)BUFFER})
2657         PATHTOMKDIR="${(Q)bufwords[iword]}"
2658     fi
2659     [[ -z "${PATHTOMKDIR}" ]] && return 1
2660     PATHTOMKDIR=${~PATHTOMKDIR}
2661     if [[ -e "${PATHTOMKDIR}" ]]; then
2662         zle -M " path already exists, doing nothing"
2663     else
2664         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
2665         zle end-of-line
2666     fi
2667 }
2668 #k# mkdir -p <dir> from string under cursor or marked area
2669 zle -N inplaceMkDirs && bindkey '^xM' inplaceMkDirs
2670
2671 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2672 accessed() {
2673     emulate -L zsh
2674     print -l -- *(a-${1:-1})
2675 }
2676
2677 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2678 changed() {
2679     emulate -L zsh
2680     print -l -- *(c-${1:-1})
2681 }
2682
2683 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2684 modified() {
2685     emulate -L zsh
2686     print -l -- *(m-${1:-1})
2687 }
2688 # modified() was named new() in earlier versions, add an alias for backwards compatibility
2689 check_com new || alias new=modified
2690
2691 # use colors when GNU grep with color-support
2692 #a2# Execute \kbd{grep -{}-color=auto}
2693 (( $#grep_options > 0 )) && alias grep='grep '${grep_options:+"${grep_options[*]}"}
2694
2695 # Translate DE<=>EN
2696 # 'translate' looks up fot a word in a file with language-to-language
2697 # translations (field separator should be " : "). A typical wordlist looks
2698 # like at follows:
2699 #  | english-word : german-transmission
2700 # It's also only possible to translate english to german but not reciprocal.
2701 # Use the following oneliner to turn back the sort order:
2702 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2703 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2704 #f5# Translates a word
2705 trans() {
2706     emulate -L zsh
2707     case "$1" in
2708         -[dD]*)
2709             translate -l de-en $2
2710             ;;
2711         -[eE]*)
2712             translate -l en-de $2
2713             ;;
2714         *)
2715             echo "Usage: $0 { -D | -E }"
2716             echo "         -D == German to English"
2717             echo "         -E == English to German"
2718     esac
2719 }
2720
2721 # Usage: simple-extract <file>
2722 # Using option -d deletes the original archive file.
2723 #f5# Smart archive extractor
2724 simple-extract() {
2725     emulate -L zsh
2726     setopt extended_glob noclobber
2727     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2728     local RC=0
2729     zparseopts -D -E "d=DELETE_ORIGINAL"
2730     for ARCHIVE in "${@}"; do
2731         case $ARCHIVE in
2732             *(tar.bz2|tbz2|tbz))
2733                 DECOMP_CMD="tar -xvjf -"
2734                 USES_STDIN=true
2735                 USES_STDOUT=false
2736                 ;;
2737             *(tar.gz|tgz))
2738                 DECOMP_CMD="tar -xvzf -"
2739                 USES_STDIN=true
2740                 USES_STDOUT=false
2741                 ;;
2742             *(tar.xz|txz|tar.lzma))
2743                 DECOMP_CMD="tar -xvJf -"
2744                 USES_STDIN=true
2745                 USES_STDOUT=false
2746                 ;;
2747             *tar)
2748                 DECOMP_CMD="tar -xvf -"
2749                 USES_STDIN=true
2750                 USES_STDOUT=false
2751                 ;;
2752             *rar)
2753                 DECOMP_CMD="unrar x"
2754                 USES_STDIN=false
2755                 USES_STDOUT=false
2756                 ;;
2757             *lzh)
2758                 DECOMP_CMD="lha x"
2759                 USES_STDIN=false
2760                 USES_STDOUT=false
2761                 ;;
2762             *7z)
2763                 DECOMP_CMD="7z x"
2764                 USES_STDIN=false
2765                 USES_STDOUT=false
2766                 ;;
2767             *(zip|jar))
2768                 DECOMP_CMD="unzip"
2769                 USES_STDIN=false
2770                 USES_STDOUT=false
2771                 ;;
2772             *deb)
2773                 DECOMP_CMD="ar -x"
2774                 USES_STDIN=false
2775                 USES_STDOUT=false
2776                 ;;
2777             *bz2)
2778                 DECOMP_CMD="bzip2 -d -c -"
2779                 USES_STDIN=true
2780                 USES_STDOUT=true
2781                 ;;
2782             *(gz|Z))
2783                 DECOMP_CMD="gzip -d -c -"
2784                 USES_STDIN=true
2785                 USES_STDOUT=true
2786                 ;;
2787             *(xz|lzma))
2788                 DECOMP_CMD="xz -d -c -"
2789                 USES_STDIN=true
2790                 USES_STDOUT=true
2791                 ;;
2792             *)
2793                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2794                 RC=$((RC+1))
2795                 continue
2796                 ;;
2797         esac
2798
2799         if ! check_com ${DECOMP_CMD[(w)1]}; then
2800             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2801             RC=$((RC+2))
2802             continue
2803         fi
2804
2805         GZTARGET="${ARCHIVE:t:r}"
2806         if [[ -f $ARCHIVE ]] ; then
2807
2808             print "Extracting '$ARCHIVE' ..."
2809             if $USES_STDIN; then
2810                 if $USES_STDOUT; then
2811                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
2812                 else
2813                     ${=DECOMP_CMD} < "$ARCHIVE"
2814                 fi
2815             else
2816                 if $USES_STDOUT; then
2817                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
2818                 else
2819                     ${=DECOMP_CMD} "$ARCHIVE"
2820                 fi
2821             fi
2822             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
2823
2824         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
2825             if check_com curl; then
2826                 WGET_CMD="curl -L -k -s -o -"
2827             elif check_com wget; then
2828                 WGET_CMD="wget -q -O - --no-check-certificate"
2829             else
2830                 print "ERROR: neither wget nor curl is installed" >&2
2831                 RC=$((RC+4))
2832                 continue
2833             fi
2834             print "Downloading and Extracting '$ARCHIVE' ..."
2835             if $USES_STDIN; then
2836                 if $USES_STDOUT; then
2837                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
2838                     RC=$((RC+$?))
2839                 else
2840                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
2841                     RC=$((RC+$?))
2842                 fi
2843             else
2844                 if $USES_STDOUT; then
2845                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
2846                 else
2847                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
2848                 fi
2849             fi
2850
2851         else
2852             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
2853             RC=$((RC+8))
2854         fi
2855     done
2856     return $RC
2857 }
2858
2859 __archive_or_uri()
2860 {
2861     _alternative \
2862         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
2863         '_urls:Remote Archives:_urls'
2864 }
2865
2866 _simple_extract()
2867 {
2868     _arguments \
2869         '-d[delete original archivefile after extraction]' \
2870         '*:Archive Or Uri:__archive_or_uri'
2871 }
2872 compdef _simple_extract simple-extract
2873 alias se=simple-extract
2874
2875 #f5# Set all ulimit parameters to \kbd{unlimited}
2876 allulimit() {
2877     ulimit -c unlimited
2878     ulimit -d unlimited
2879     ulimit -f unlimited
2880     ulimit -l unlimited
2881     ulimit -n unlimited
2882     ulimit -s unlimited
2883     ulimit -t unlimited
2884 }
2885
2886 #f5# Change the xterm title from within GNU-screen
2887 xtrename() {
2888     emulate -L zsh
2889     if [[ $1 != "-f" ]] ; then
2890         if [[ -z ${DISPLAY} ]] ; then
2891             printf 'xtrename only makes sense in X11.\n'
2892             return 1
2893         fi
2894     else
2895         shift
2896     fi
2897     if [[ -z $1 ]] ; then
2898         printf 'usage: xtrename [-f] "title for xterm"\n'
2899         printf '  renames the title of xterm from _within_ screen.\n'
2900         printf '  also works without screen.\n'
2901         printf '  will not work if DISPLAY is unset, use -f to override.\n'
2902         return 0
2903     fi
2904     print -n "\eP\e]0;${1}\C-G\e\\"
2905     return 0
2906 }
2907
2908 # Create small urls via http://goo.gl using curl(1).
2909 # API reference: https://code.google.com/apis/urlshortener/
2910 function zurl() {
2911     emulate -L zsh
2912     setopt extended_glob
2913
2914     if [[ -z $1 ]]; then
2915         print "USAGE: zurl <URL>"
2916         return 1
2917     fi
2918
2919     local PN url prog api json contenttype item
2920     local -a data
2921     PN=$0
2922     url=$1
2923
2924     # Prepend 'http://' to given URL where necessary for later output.
2925     if [[ ${url} != http(s|)://* ]]; then
2926         url='http://'${url}
2927     fi
2928
2929     if check_com -c curl; then
2930         prog=curl
2931     else
2932         print "curl is not available, but mandatory for ${PN}. Aborting."
2933         return 1
2934     fi
2935     api='https://www.googleapis.com/urlshortener/v1/url'
2936     contenttype="Content-Type: application/json"
2937     json="{\"longUrl\": \"${url}\"}"
2938     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
2939     # Parse the response
2940     for item in "${data[@]}"; do
2941         case "$item" in
2942             ' '#'"id":'*)
2943                 item=${item#*: \"}
2944                 item=${item%\",*}
2945                 printf '%s\n' "$item"
2946                 return 0
2947                 ;;
2948         esac
2949     done
2950     return 1
2951 }
2952
2953 #f2# Find history events by search pattern and list them by date.
2954 whatwhen()  {
2955     emulate -L zsh
2956     local usage help ident format_l format_s first_char remain first last
2957     usage='USAGE: whatwhen [options] <searchstring> <search range>'
2958     help='Use `whatwhen -h'\'' for further explanations.'
2959     ident=${(l,${#${:-Usage: }},, ,)}
2960     format_l="${ident}%s\t\t\t%s\n"
2961     format_s="${format_l//(\\t)##/\\t}"
2962     # Make the first char of the word to search for case
2963     # insensitive; e.g. [aA]
2964     first_char=[${(L)1[1]}${(U)1[1]}]
2965     remain=${1[2,-1]}
2966     # Default search range is `-100'.
2967     first=${2:-\-100}
2968     # Optional, just used for `<first> <last>' given.
2969     last=$3
2970     case $1 in
2971         ("")
2972             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
2973             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2974         ;;
2975         (-h)
2976             printf '%s\n\n' ${usage}
2977             print 'OPTIONS:'
2978             printf $format_l '-h' 'show help text'
2979             print '\f'
2980             print 'SEARCH RANGE:'
2981             printf $format_l "'0'" 'the whole history,'
2982             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
2983             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
2984             printf '\n%s\n' 'EXAMPLES:'
2985             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
2986             printf $format_l 'whatwhen zsh -250'
2987             printf $format_l 'whatwhen foo 1 99'
2988         ;;
2989         (\?)
2990             printf '%s\n%s\n\n' ${usage} ${help} && return 1
2991         ;;
2992         (*)
2993             # -l list results on stout rather than invoking $EDITOR.
2994             # -i Print dates as in YYYY-MM-DD.
2995             # -m Search for a - quoted - pattern within the history.
2996             fc -li -m "*${first_char}${remain}*" $first $last
2997         ;;
2998     esac
2999 }
3000
3001 # mercurial related stuff
3002 if check_com -c hg ; then
3003     # gnu like diff for mercurial
3004     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
3005     #f5# GNU like diff for mercurial
3006     hgdi() {
3007         emulate -L zsh
3008         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
3009     }
3010
3011     # build debian package
3012     #a2# Alias for \kbd{hg-buildpackage}
3013     alias hbp='hg-buildpackage'
3014
3015     # execute commands on the versioned patch-queue from the current repos
3016     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
3017
3018     # diffstat for specific version of a mercurial repository
3019     #   hgstat      => display diffstat between last revision and tip
3020     #   hgstat 1234 => display diffstat between revision 1234 and tip
3021     #f5# Diffstat for specific version of a mercurial repos
3022     hgstat() {
3023         emulate -L zsh
3024         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
3025     }
3026
3027 fi # end of check whether we have the 'hg'-executable
3028
3029 # grml-small cleanups
3030
3031 # The following is used to remove zsh-config-items that do not work
3032 # in grml-small by default.
3033 # If you do not want these adjustments (for whatever reason), set
3034 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
3035 # sources if it is there).
3036
3037 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
3038
3039     unset abk[V]
3040     unalias    'V'      &> /dev/null
3041     unfunction vman     &> /dev/null
3042     unfunction viless   &> /dev/null
3043     unfunction 2html    &> /dev/null
3044
3045     # manpages are not in grmlsmall
3046     unfunction manzsh   &> /dev/null
3047     unfunction man2     &> /dev/null
3048
3049 fi
3050
3051 zrclocal
3052
3053 ## genrefcard.pl settings
3054
3055 ### doc strings for external functions from files
3056 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
3057
3058 ### example: split functions-search 8,16,24,32
3059 #@# split functions-search 8
3060
3061 ## END OF FILE #################################################################
3062 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
3063 # Local variables:
3064 # mode: sh
3065 # End: